This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
[inseparable changes from patch from perl5.003_24 to perl5.003_25]
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar and list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one list argument.)  For instance, splice() has three scalar
19 arguments followed by a list.
20
21 In the syntax descriptions that follow, list operators that expect a
22 list (and provide list context for the elements of the list) are shown
23 with LIST as an argument.  Such a list may consist of any combination
24 of scalar arguments or list values; the list values will be included
25 in the list as if each individual element were interpolated at that
26 point in the list, forming a longer single-dimensional list value.
27 Elements of the LIST should be separated by commas.
28
29 Any function in the list below may be used either with or without
30 parentheses around its arguments.  (The syntax descriptions omit the
31 parentheses.)  If you use the parentheses, the simple (but occasionally
32 surprising) rule is this: It I<LOOKS> like a function, therefore it I<IS> a
33 function, and precedence doesn't matter.  Otherwise it's a list
34 operator or unary operator, and precedence does matter.  And whitespace
35 between the function and left parenthesis doesn't count--so you need to
36 be careful sometimes:
37
38     print 1+2+3;        # Prints 6.
39     print(1+2) + 3;     # Prints 3.
40     print (1+2)+3;      # Also prints 3!
41     print +(1+2)+3;     # Prints 6.
42     print ((1+2)+3);    # Prints 6.
43
44 If you run Perl with the B<-w> switch it can warn you about this.  For
45 example, the third line above produces:
46
47     print (...) interpreted as function at - line 1.
48     Useless use of integer addition in void context at - line 1.
49
50 For functions that can be used in either a scalar or list context,
51 non-abortive failure is generally indicated in a scalar context by
52 returning the undefined value, and in a list context by returning the
53 null list.
54
55 Remember the following rule:
56
57 =over 8
58
59 =item  I<THERE IS NO GENERAL RULE FOR CONVERTING A LIST INTO A SCALAR!>
60
61 =back
62
63 Each operator and function decides which sort of value it would be most
64 appropriate to return in a scalar context.  Some operators return the
65 length of the list that would have been returned in a list context.  Some
66 operators return the first value in the list.  Some operators return the
67 last value in the list.  Some operators return a count of successful
68 operations.  In general, they do what you want, unless you want
69 consistency.
70
71 =head2 Perl Functions by Category
72
73 Here are Perl's functions (including things that look like
74 functions, like some of the keywords and named operators)
75 arranged by category.  Some functions appear in more
76 than one place.
77
78 =over
79
80 =item Functions for SCALARs or strings
81
82 chomp, chop, chr, crypt, hex, index, lc, lcfirst, length,
83 oct, ord, pack, q/STRING/, qq/STRING/, reverse, rindex,
84 sprintf, substr, tr///, uc, ucfirst, y///
85
86 =item Regular expressions and pattern matching
87
88 m//, pos, quotemeta, s///, split, study
89
90 =item Numeric functions
91
92 abs, atan2, cos, exp, hex, int, log, oct, rand, sin, sqrt,
93 srand
94
95 =item Functions for real @ARRAYs
96
97 pop, push, shift, splice, unshift
98
99 =item Functions for list data
100
101 grep, join, map, qw/STRING/, reverse, sort, unpack
102
103 =item Functions for real %HASHes
104
105 delete, each, exists, keys, values
106
107 =item Input and output functions
108
109 binmode, close, closedir, dbmclose, dbmopen, die, eof,
110 fileno, flock, format, getc, print, printf, read, readdir,
111 rewinddir, seek, seekdir, select, syscall, sysread,
112 syswrite, tell, telldir, truncate, warn, write
113
114 =item Functions for fixed length data or records
115
116 pack, read, syscall, sysread, syswrite, unpack, vec
117
118 =item Functions for filehandles, files, or directories
119
120 I<-X>, chdir, chmod, chown, chroot, fcntl, glob, ioctl, link,
121 lstat, mkdir, open, opendir, readlink, rename, rmdir,
122 stat, symlink, umask, unlink, utime
123
124 =item Keywords related to the control flow of your perl program
125
126 caller, continue, die, do, dump, eval, exit, goto, last,
127 next, redo, return, sub, wantarray
128
129 =item Keywords related to scoping 
130
131 caller, import, local, my, package, use
132
133 =item Miscellaneous functions
134
135 defined, dump, eval, formline, local, my, reset, scalar,
136 undef, wantarray
137
138 =item Functions for processes and process groups
139
140 alarm, exec, fork, getpgrp, getppid, getpriority, kill,
141 pipe, qx/STRING/, setpgrp, setpriority, sleep, system,
142 times, wait, waitpid
143
144 =item Keywords related to perl modules
145
146 do, import, no, package, require, use
147
148 =item Keywords related to classes and object-orientedness
149
150 bless, dbmclose, dbmopen, package, ref, tie, tied, untie, use
151
152 =item Low-level socket functions
153
154 accept, bind, connect, getpeername, getsockname,
155 getsockopt, listen, recv, send, setsockopt, shutdown,
156 socket, socketpair
157
158 =item System V interprocess communication functions
159
160 msgctl, msgget, msgrcv, msgsnd, semctl, semget, semop,
161 shmctl, shmget, shmread, shmwrite
162
163 =item Fetching user and group info
164
165 endgrent, endhostent, endnetent, endpwent, getgrent,
166 getgrgid, getgrnam, getlogin, getpwent, getpwnam,
167 getpwuid, setgrent, setpwent
168
169 =item Fetching network info
170
171 endprotoent, endservent, gethostbyaddr, gethostbyname,
172 gethostent, getnetbyaddr, getnetbyname, getnetent,
173 getprotobyname, getprotobynumber, getprotoent,
174 getservbyname, getservbyport, getservent, sethostent,
175 setnetent, setprotoent, setservent
176
177 =item Time-related functions
178
179 gmtime, localtime, time, times
180
181 =item Functions new in perl5
182
183 abs, bless, chomp, chr, exists, formline, glob, import, lc,
184 lcfirst, map, my, no, prototype, qx, qw, readline, readpipe,
185 ref, sub*, sysopen, tie, tied, uc, ucfirst, untie, use
186
187 * - C<sub> was a keyword in perl4, but in perl5 it is an
188 operator which can be used in expressions.
189
190 =item Functions obsoleted in perl5
191
192 dbmclose, dbmopen
193
194 =back
195
196 =head2 Alphabetical Listing of Perl Functions
197
198 =over 8
199
200 =item -X FILEHANDLE
201
202 =item -X EXPR
203
204 =item -X
205
206 A file test, where X is one of the letters listed below.  This unary
207 operator takes one argument, either a filename or a filehandle, and
208 tests the associated file to see if something is true about it.  If the
209 argument is omitted, tests $_, except for C<-t>, which tests STDIN.
210 Unless otherwise documented, it returns C<1> for TRUE and C<''> for FALSE, or
211 the undefined value if the file doesn't exist.  Despite the funny
212 names, precedence is the same as any other named unary operator, and
213 the argument may be parenthesized like any other unary operator.  The
214 operator may be any of:
215
216     -r  File is readable by effective uid/gid.
217     -w  File is writable by effective uid/gid.
218     -x  File is executable by effective uid/gid.
219     -o  File is owned by effective uid.
220
221     -R  File is readable by real uid/gid.
222     -W  File is writable by real uid/gid.
223     -X  File is executable by real uid/gid.
224     -O  File is owned by real uid.
225
226     -e  File exists.
227     -z  File has zero size.
228     -s  File has non-zero size (returns size).
229
230     -f  File is a plain file.
231     -d  File is a directory.
232     -l  File is a symbolic link.
233     -p  File is a named pipe (FIFO).
234     -S  File is a socket.
235     -b  File is a block special file.
236     -c  File is a character special file.
237     -t  Filehandle is opened to a tty.
238
239     -u  File has setuid bit set.
240     -g  File has setgid bit set.
241     -k  File has sticky bit set.
242
243     -T  File is a text file.
244     -B  File is a binary file (opposite of -T).
245
246     -M  Age of file in days when script started.
247     -A  Same for access time.
248     -C  Same for inode change time.
249
250 The interpretation of the file permission operators C<-r>, C<-R>, C<-w>,
251 C<-W>, C<-x>, and C<-X> is based solely on the mode of the file and the
252 uids and gids of the user.  There may be other reasons you can't actually
253 read, write or execute the file.  Also note that, for the superuser,
254 C<-r>, C<-R>, C<-w>, and C<-W> always return 1, and C<-x> and C<-X> return
255 1 if any execute bit is set in the mode.  Scripts run by the superuser may
256 thus need to do a stat() to determine the actual mode of the
257 file, or temporarily set the uid to something else.
258
259 Example:
260
261     while (<>) {
262         chop;
263         next unless -f $_;      # ignore specials
264         ...
265     }
266
267 Note that C<-s/a/b/> does not do a negated substitution.  Saying
268 C<-exp($foo)> still works as expected, however--only single letters
269 following a minus are interpreted as file tests.
270
271 The C<-T> and C<-B> switches work as follows.  The first block or so of the
272 file is examined for odd characters such as strange control codes or
273 characters with the high bit set.  If too many odd characters (E<gt>30%)
274 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
275 containing null in the first block is considered a binary file.  If C<-T>
276 or C<-B> is used on a filehandle, the current stdio buffer is examined
277 rather than the first block.  Both C<-T> and C<-B> return TRUE on a null
278 file, or a file at EOF when testing a filehandle.  Because you have to 
279 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
280 against the file first, as in C<next unless -f $file && -T $file>.
281
282 If any of the file tests (or either the stat() or lstat() operators) are given
283 the special filehandle consisting of a solitary underline, then the stat
284 structure of the previous file test (or stat operator) is used, saving
285 a system call.  (This doesn't work with C<-t>, and you need to remember
286 that lstat() and C<-l> will leave values in the stat structure for the
287 symbolic link, not the real file.)  Example:
288
289     print "Can do.\n" if -r $a || -w _ || -x _;
290
291     stat($filename);
292     print "Readable\n" if -r _;
293     print "Writable\n" if -w _;
294     print "Executable\n" if -x _;
295     print "Setuid\n" if -u _;
296     print "Setgid\n" if -g _;
297     print "Sticky\n" if -k _;
298     print "Text\n" if -T _;
299     print "Binary\n" if -B _;
300
301 =item abs VALUE
302
303 =item abs 
304
305 Returns the absolute value of its argument.
306 If VALUE is omitted, uses $_.
307
308 =item accept NEWSOCKET,GENERICSOCKET
309
310 Accepts an incoming socket connect, just as the accept(2) system call
311 does.  Returns the packed address if it succeeded, FALSE otherwise.
312 See example in L<perlipc/"Sockets: Client/Server Communication">.
313
314 =item alarm SECONDS
315
316 =item alarm 
317
318 Arranges to have a SIGALRM delivered to this process after the
319 specified number of seconds have elapsed.  If SECONDS is not specified,
320 the value stored in $_ is used. (On some machines,
321 unfortunately, the elapsed time may be up to one second less than you
322 specified because of how seconds are counted.)  Only one timer may be
323 counting at once.  Each call disables the previous timer, and an
324 argument of 0 may be supplied to cancel the previous timer without
325 starting a new one.  The returned value is the amount of time remaining
326 on the previous timer.
327
328 For delays of finer granularity than one second, you may use Perl's
329 syscall() interface to access setitimer(2) if your system supports it, 
330 or else see L</select()> below.  It is not advised to intermix alarm() 
331 and sleep() calls.
332
333 If you want to use alarm() to time out a system call you need to use an
334 eval/die pair. You can't rely on the alarm causing the system call to
335 fail with $! set to EINTR because Perl sets up signal handlers to
336 restart system calls on some systems.  Using eval/die always works.
337
338     eval {
339         local $SIG{ALRM} = sub { die "alarm\n" };       # NB \n required
340         alarm $timeout;
341         $nread = sysread SOCKET, $buffer, $size;
342         alarm 0;
343     };
344     die if $@ && $@ ne "alarm\n";       # propagate errors
345     if ($@) {
346         # timed out
347     }
348     else {
349         # didn't
350     }
351
352 =item atan2 Y,X
353
354 Returns the arctangent of Y/X in the range -PI to PI.
355
356 For the tangent operation, you may use the POSIX::tan()
357 function, or use the familiar relation:
358
359     sub tan { sin($_[0]) / cos($_[0])  }
360
361 =item bind SOCKET,NAME
362
363 Binds a network address to a socket, just as the bind system call
364 does.  Returns TRUE if it succeeded, FALSE otherwise.  NAME should be a
365 packed address of the appropriate type for the socket.  See the examples in
366 L<perlipc/"Sockets: Client/Server Communication">.
367
368 =item binmode FILEHANDLE
369
370 Arranges for the file to be read or written in "binary" mode in operating
371 systems that distinguish between binary and text files.  Files that are
372 not in binary mode have CR LF sequences translated to LF on input and LF
373 translated to CR LF on output.  Binmode has no effect under Unix; in DOS
374 and similarly archaic systems, it may be imperative--otherwise your
375 DOS-damaged C library may mangle your file.  The key distinction between
376 systems that need binmode and those that don't is their text file
377 formats.  Systems like Unix and Plan9 that delimit lines with a single
378 character, and that encode that character in C as '\n', do not need
379 C<binmode>.  The rest need it.  If FILEHANDLE is an expression, the value
380 is taken as the name of the filehandle.
381
382 =item bless REF,CLASSNAME
383
384 =item bless REF
385
386 This function tells the thingy referenced by REF that it is now
387 an object in the CLASSNAME package--or the current package if no CLASSNAME
388 is specified, which is often the case.  It returns the reference for
389 convenience, because a bless() is often the last thing in a constructor.
390 Always use the two-argument version if the function doing the blessing
391 might be inherited by a derived class.  See L<perlobj> for more about the
392 blessing (and blessings) of objects.
393
394 =item caller EXPR
395
396 =item caller
397
398 Returns the context of the current subroutine call.  In a scalar context,
399 returns the caller's package name if there is a caller, that is, if
400 we're in a subroutine or eval() or require(), and the undefined value
401 otherwise.  In a list context, returns
402
403     ($package, $filename, $line) = caller;
404
405 With EXPR, it returns some extra information that the debugger uses to
406 print a stack trace.  The value of EXPR indicates how many call frames
407 to go back before the current one.
408
409     ($package, $filename, $line, $subroutine, 
410      $hasargs, $wantarray, $evaltext, $is_require) = caller($i);
411
412 Here $subroutine may be C<"(eval)"> if the frame is not a subroutine
413 call, but C<L<eval>>. In such a case additional elements $evaltext and
414 $is_require are set: $is_require is true if the frame is created by
415 C<L<require>> or C<L<use>> statement, $evaltext contains the text of
416 C<L<eval EXPR>> statement. In particular, for C<L<eval BLOCK>>
417 statement $filename is C<"(eval)">, but $evaltext is undefined. (Note
418 also that C<L<use>> statement creates a C<L<require>> frame inside
419 an C<L<eval EXPR>>) frame.
420
421 Furthermore, when called from within the DB package, caller returns more
422 detailed information: it sets the list variable @DB::args to be the
423 arguments with which that subroutine was invoked.
424
425 =item chdir EXPR
426
427 Changes the working directory to EXPR, if possible.  If EXPR is
428 omitted, changes to home directory.  Returns TRUE upon success, FALSE
429 otherwise.  See example under die().
430
431 =item chmod LIST
432
433 Changes the permissions of a list of files.  The first element of the
434 list must be the numerical mode, which should probably be an octal
435 number.  Returns the number of files successfully changed.
436
437     $cnt = chmod 0755, 'foo', 'bar';
438     chmod 0755, @executables;
439
440 =item chomp VARIABLE
441
442 =item chomp LIST
443
444 =item chomp
445
446 This is a slightly safer version of chop (see below).  It removes any
447 line ending that corresponds to the current value of C<$/> (also known as
448 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
449 number of characters removed from all its arguments.  It's often used to
450 remove the newline from the end of an input record when you're worried
451 that the final record may be missing its newline.  When in paragraph mode
452 (C<$/ = "">), it removes all trailing newlines from the string.  If
453 VARIABLE is omitted, it chomps $_.  Example:
454
455     while (<>) {
456         chomp;  # avoid \n on last field
457         @array = split(/:/);
458         ...
459     }
460
461 You can actually chomp anything that's an lvalue, including an assignment:
462
463     chomp($cwd = `pwd`);
464     chomp($answer = <STDIN>);
465
466 If you chomp a list, each element is chomped, and the total number of
467 characters removed is returned.
468
469 =item chop VARIABLE
470
471 =item chop LIST
472
473 =item chop
474
475 Chops off the last character of a string and returns the character
476 chopped.  It's used primarily to remove the newline from the end of an
477 input record, but is much more efficient than C<s/\n//> because it neither
478 scans nor copies the string.  If VARIABLE is omitted, chops $_.
479 Example:
480
481     while (<>) {
482         chop;   # avoid \n on last field
483         @array = split(/:/);
484         ...
485     }
486
487 You can actually chop anything that's an lvalue, including an assignment:
488
489     chop($cwd = `pwd`);
490     chop($answer = <STDIN>);
491
492 If you chop a list, each element is chopped.  Only the value of the
493 last chop is returned.
494
495 Note that chop returns the last character.  To return all but the last
496 character, use C<substr($string, 0, -1)>.
497
498 =item chown LIST
499
500 Changes the owner (and group) of a list of files.  The first two
501 elements of the list must be the I<NUMERICAL> uid and gid, in that order.
502 Returns the number of files successfully changed.
503
504     $cnt = chown $uid, $gid, 'foo', 'bar';
505     chown $uid, $gid, @filenames;
506
507 Here's an example that looks up non-numeric uids in the passwd file:
508
509     print "User: ";
510     chop($user = <STDIN>);
511     print "Files: "
512     chop($pattern = <STDIN>);
513
514     ($login,$pass,$uid,$gid) = getpwnam($user)
515         or die "$user not in passwd file";
516
517     @ary = <${pattern}>;        # expand filenames
518     chown $uid, $gid, @ary;
519
520 On most systems, you are not allowed to change the ownership of the 
521 file unless you're the superuser, although you should be able to change
522 the group to any of your secondary groups.  On insecure systems, these
523 restrictions may be relaxed, but this is not a portable assumption.
524
525 =item chr NUMBER
526
527 =item chr 
528
529 Returns the character represented by that NUMBER in the character set.
530 For example, C<chr(65)> is "A" in ASCII.
531
532 If NUMBER is omitted, uses $_.
533
534 =item chroot FILENAME
535
536 =item chroot 
537
538 This function works as the system call by the same name: it makes the
539 named directory the new root directory for all further pathnames that
540 begin with a "/" by your process and all of its children.  (It doesn't
541 change your current working directory, which is unaffected.)  For security
542 reasons, this call is restricted to the superuser.  If FILENAME is
543 omitted, does chroot to $_.
544
545 =item close FILEHANDLE
546
547 Closes the file or pipe associated with the file handle, returning TRUE
548 only if stdio successfully flushes buffers and closes the system file
549 descriptor.  You don't have to close FILEHANDLE if you are immediately
550 going to do another open() on it, because open() will close it for you.  (See
551 open().)  However, an explicit close on an input file resets the line
552 counter ($.), while the implicit close done by open() does not.  Also,
553 closing a pipe will wait for the process executing on the pipe to
554 complete, in case you want to look at the output of the pipe
555 afterwards.  Closing a pipe explicitly also puts the status value of
556 the command into C<$?>.  Example:
557
558     open(OUTPUT, '|sort >foo'); # pipe to sort
559     ...                         # print stuff to output
560     close OUTPUT;               # wait for sort to finish
561     open(INPUT, 'foo');         # get sort's results
562
563 FILEHANDLE may be an expression whose value gives the real filehandle name.
564
565 =item closedir DIRHANDLE
566
567 Closes a directory opened by opendir().
568
569 =item connect SOCKET,NAME
570
571 Attempts to connect to a remote socket, just as the connect system call
572 does.  Returns TRUE if it succeeded, FALSE otherwise.  NAME should be a
573 packed address of the appropriate type for the socket.  See the examples in
574 L<perlipc/"Sockets: Client/Server Communication">.
575
576 =item continue BLOCK
577
578 Actually a flow control statement rather than a function.  If there is a
579 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
580 C<foreach>), it is always executed just before the conditional is about to
581 be evaluated again, just like the third part of a C<for> loop in C.  Thus
582 it can be used to increment a loop variable, even when the loop has been
583 continued via the C<next> statement (which is similar to the C C<continue>
584 statement).
585
586 =item cos EXPR
587
588 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted
589 takes cosine of $_.
590
591 For the inverse cosine operation, you may use the POSIX::acos()
592 function, or use this relation:
593
594     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
595
596 =item crypt PLAINTEXT,SALT
597
598 Encrypts a string exactly like the crypt(3) function in the C library
599 (assuming that you actually have a version there that has not been
600 extirpated as a potential munition).  This can prove useful for checking
601 the password file for lousy passwords, amongst other things.  Only the
602 guys wearing white hats should do this.
603
604 Here's an example that makes sure that whoever runs this program knows
605 their own password:
606
607     $pwd = (getpwuid($<))[1];
608     $salt = substr($pwd, 0, 2);
609
610     system "stty -echo";
611     print "Password: ";
612     chop($word = <STDIN>);
613     print "\n";
614     system "stty echo";
615
616     if (crypt($word, $salt) ne $pwd) {
617         die "Sorry...\n";
618     } else {
619         print "ok\n";
620     } 
621
622 Of course, typing in your own password to whomever asks you 
623 for it is unwise.
624
625 =item dbmclose ASSOC_ARRAY
626
627 [This function has been superseded by the untie() function.]
628
629 Breaks the binding between a DBM file and an associative array.
630
631 =item dbmopen ASSOC,DBNAME,MODE
632
633 [This function has been superseded by the tie() function.]
634
635 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(), or Berkeley DB file to an
636 associative array.  ASSOC is the name of the associative array.  (Unlike
637 normal open, the first argument is I<NOT> a filehandle, even though it
638 looks like one).  DBNAME is the name of the database (without the F<.dir>
639 or F<.pag> extension if any).  If the database does not exist, it is
640 created with protection specified by MODE (as modified by the umask()).
641 If your system supports only the older DBM functions, you may perform only
642 one dbmopen() in your program.  In older versions of Perl, if your system
643 had neither DBM nor ndbm, calling dbmopen() produced a fatal error; it now
644 falls back to sdbm(3).
645
646 If you don't have write access to the DBM file, you can only read
647 associative array variables, not set them.  If you want to test whether
648 you can write, either use file tests or try setting a dummy array entry
649 inside an eval(), which will trap the error.
650
651 Note that functions such as keys() and values() may return huge array
652 values when used on large DBM files.  You may prefer to use the each()
653 function to iterate over large DBM files.  Example:
654
655     # print out history file offsets
656     dbmopen(%HIST,'/usr/lib/news/history',0666);
657     while (($key,$val) = each %HIST) {
658         print $key, ' = ', unpack('L',$val), "\n";
659     }
660     dbmclose(%HIST);
661
662 See also L<AnyDBM_File> for a more general description of the pros and
663 cons of the various dbm approaches, as well as L<DB_File> for a particularly
664 rich implementation.
665
666 =item defined EXPR
667
668 =item defined 
669
670 Returns a boolean value saying whether EXPR has a real value
671 or not. If EXPR is not present, $_ will be checked. Many operations
672 return the undefined value under exceptional conditions, such as end of
673 file, uninitialized variable, system error and such.  This function
674 allows you to distinguish between an undefined
675 null scalar and a defined null scalar with operations that might return
676 a real null string, such as referencing elements of an array.  You may
677 also check to see if arrays or subroutines exist.  Use of defined on
678 predefined variables is not guaranteed to produce intuitive results.
679
680 When used on a hash array element, it tells you whether the value
681 is defined, not whether the key exists in the hash.  Use exists() for that.
682
683 Examples:
684
685     print if defined $switch{'D'};
686     print "$val\n" while defined($val = pop(@ary));
687     die "Can't readlink $sym: $!"
688         unless defined($value = readlink $sym);
689     eval '@foo = ()' if defined(@foo);
690     die "No XYZ package defined" unless defined %_XYZ;
691     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
692
693 See also undef().
694
695 Note: many folks tend to overuse defined(), and then are surprised to
696 discover that the number 0 and the null string are, in fact, defined
697 concepts.  For example, if you say
698
699     "ab" =~ /a(.*)b/;
700
701 the pattern match succeeds, and $1 is defined, despite the fact that it
702 matched "nothing".  But it didn't really match nothing--rather, it
703 matched something that happened to be 0 characters long.  This is all
704 very above-board and honest.  When a function returns an undefined value,
705 it's an admission that it couldn't give you an honest answer.  So
706 you should use defined() only when you're questioning the integrity
707 of what you're trying to do.  At other times, a simple comparison to
708 0 or "" is what you want.
709
710 Another surprise is that using defined() on an entire array or 
711 hash reports whether memory for that aggregate has ever been
712 allocated.  So an array you set to the empty list appears undefined
713 initially, and one that once was full and that you then set to 
714 the empty list still appears defined.  You should instead use a 
715 simple test for size:
716
717     if (@an_array) { print "has array elements\n" }
718     if (%a_hash)   { print "has hash members\n"   }
719
720 Using undef() on these, however, does clear their memory and then report
721 them as not defined anymore, but you shoudln't do that unless you don't
722 plan to use them again, because it saves time when you load them up
723 again to have memory already ready to be filled.
724
725 This counter-intuitive behaviour of defined() on aggregates may be
726 changed, fixed, or broken in a future release of Perl.
727
728 =item delete EXPR
729
730 Deletes the specified key(s) and their associated values from a hash
731 array.  For each key, returns the deleted value associated with that key,
732 or the undefined value if there was no such key.  Deleting from C<$ENV{}>
733 modifies the environment.  Deleting from an array tied to a DBM file
734 deletes the entry from the DBM file.  (But deleting from a tie()d hash
735 doesn't necessarily return anything.)
736
737 The following deletes all the values of an associative array:
738
739     foreach $key (keys %HASH) {
740         delete $HASH{$key};
741     }
742
743 And so does this:
744
745     delete @HASH{keys %HASH}
746
747 (But both of these are slower than the undef() command.)  Note that the
748 EXPR can be arbitrarily complicated as long as the final operation is a
749 hash element lookup or hash slice:
750
751     delete $ref->[$x][$y]{$key};
752     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
753
754 =item die LIST
755
756 Outside of an eval(), prints the value of LIST to C<STDERR> and exits with
757 the current value of C<$!> (errno).  If C<$!> is 0, exits with the value of
758 C<($? E<gt>E<gt> 8)> (back-tick `command` status).  If C<($? E<gt>E<gt> 8)>
759 is 0, exits with 255.  Inside an eval(), the error message is stuffed into
760 C<$@>, and the eval() is terminated with the undefined value; this makes
761 die() the way to raise an exception.
762
763 Equivalent examples:
764
765     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
766     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n" 
767
768 If the value of EXPR does not end in a newline, the current script line
769 number and input line number (if any) are also printed, and a newline
770 is supplied.  Hint: sometimes appending ", stopped" to your message
771 will cause it to make better sense when the string "at foo line 123" is
772 appended.  Suppose you are running script "canasta".
773
774     die "/etc/games is no good";
775     die "/etc/games is no good, stopped";
776
777 produce, respectively
778
779     /etc/games is no good at canasta line 123.
780     /etc/games is no good, stopped at canasta line 123.
781
782 See also exit() and warn().
783
784 You can arrange for a callback to be called just before the die() does
785 its deed, by setting the C<$SIG{__DIE__}> hook.  The associated handler
786 will be called with the error text and can change the error message, if
787 it sees fit, by calling die() again.  See L<perlvar> for details on
788 setting C<%SIG> entries, and eval() for some examples.
789
790 =item do BLOCK
791
792 Not really a function.  Returns the value of the last command in the
793 sequence of commands indicated by BLOCK.  When modified by a loop
794 modifier, executes the BLOCK once before testing the loop condition.
795 (On other statements the loop modifiers test the conditional first.)
796
797 =item do SUBROUTINE(LIST)
798
799 A deprecated form of subroutine call.  See L<perlsub>.
800
801 =item do EXPR
802
803 Uses the value of EXPR as a filename and executes the contents of the
804 file as a Perl script.  Its primary use is to include subroutines
805 from a Perl subroutine library.
806
807     do 'stat.pl';
808
809 is just like
810
811     eval `cat stat.pl`;
812
813 except that it's more efficient, more concise, keeps track of the
814 current filename for error messages, and searches all the B<-I>
815 libraries if the file isn't in the current directory (see also the @INC
816 array in L<perlvar/Predefined Names>).  It's the same, however, in that it does
817 re-parse the file every time you call it, so you probably don't want to
818 do this inside a loop.
819
820 Note that inclusion of library modules is better done with the
821 use() and require() operators, which also do error checking
822 and raise an exception if there's a problem.
823
824 =item dump LABEL
825
826 This causes an immediate core dump.  Primarily this is so that you can
827 use the B<undump> program to turn your core dump into an executable binary
828 after having initialized all your variables at the beginning of the
829 program.  When the new binary is executed it will begin by executing a
830 C<goto LABEL> (with all the restrictions that C<goto> suffers).  Think of
831 it as a goto with an intervening core dump and reincarnation.  If LABEL
832 is omitted, restarts the program from the top.  WARNING: any files
833 opened at the time of the dump will NOT be open any more when the
834 program is reincarnated, with possible resulting confusion on the part
835 of Perl.  See also B<-u> option in L<perlrun>.
836
837 Example:
838
839     #!/usr/bin/perl
840     require 'getopt.pl';
841     require 'stat.pl';
842     %days = (
843         'Sun' => 1,
844         'Mon' => 2,
845         'Tue' => 3,
846         'Wed' => 4,
847         'Thu' => 5,
848         'Fri' => 6,
849         'Sat' => 7,
850     );
851
852     dump QUICKSTART if $ARGV[0] eq '-d';
853
854     QUICKSTART:
855     Getopt('f');
856
857 =item each ASSOC_ARRAY
858
859 When called in a list context, returns a 2-element array consisting
860 of the key and value for the next element of an associative array,
861 so that you can iterate over it.  When called in a scalar context,
862 returns the key for only the next element in the associative array.
863 Entries are returned in an apparently random order.  When the array is
864 entirely read, a null array is returned in list context (which when
865 assigned produces a FALSE (0) value), and C<undef> is returned in a
866 scalar context.  The next call to each() after that will start
867 iterating again.  The iterator can be reset only by reading all the
868 elements from the array.  You should not add elements to an array while
869 you're iterating over it.  There is a single iterator for each
870 associative array, shared by all each(), keys(), and values() function
871 calls in the program.  The following prints out your environment like
872 the printenv(1) program, only in a different order:
873
874     while (($key,$value) = each %ENV) {
875         print "$key=$value\n";
876     }
877
878 See also keys() and values().
879
880 =item eof FILEHANDLE
881
882 =item eof ()
883
884 =item eof
885
886 Returns 1 if the next read on FILEHANDLE will return end of file, or if
887 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
888 gives the real filehandle name.  (Note that this function actually
889 reads a character and then ungetc()s it, so it is not very useful in an
890 interactive context.)  Do not read from a terminal file (or call
891 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  Filetypes such
892 as terminals may lose the end-of-file condition if you do.
893
894 An C<eof> without an argument uses the last file read as argument.
895 Empty parentheses () may be used to indicate
896 the pseudo file formed of the files listed on the command line, i.e.,
897 C<eof()> is reasonable to use inside a while (E<lt>E<gt>) loop to detect the end
898 of only the last file.  Use C<eof(ARGV)> or eof without the parentheses to
899 test I<EACH> file in a while (E<lt>E<gt>) loop.  Examples:
900
901     # reset line numbering on each input file
902     while (<>) {
903         print "$.\t$_";
904         close(ARGV) if (eof);   # Not eof().
905     }
906
907     # insert dashes just before last line of last file
908     while (<>) {
909         if (eof()) {
910             print "--------------\n";
911             close(ARGV);        # close or break; is needed if we
912                                 # are reading from the terminal
913         }
914         print;
915     }
916
917 Practical hint: you almost never need to use C<eof> in Perl, because the
918 input operators return undef when they run out of data.  
919
920 =item eval EXPR
921
922 =item eval BLOCK
923
924 EXPR is parsed and executed as if it were a little Perl program.  It
925 is executed in the context of the current Perl program, so that any
926 variable settings or subroutine and format definitions remain afterwards.
927 The value returned is the value of the last expression evaluated, or a
928 return statement may be used, just as with subroutines.  The last
929 expression is evaluated in scalar or array context, depending on the
930 context of the eval.
931
932 If there is a syntax error or runtime error, or a die() statement is
933 executed, an undefined value is returned by eval(), and C<$@> is set to the
934 error message.  If there was no error, C<$@> is guaranteed to be a null
935 string.  If EXPR is omitted, evaluates C<$_>.  The final semicolon, if
936 any, may be omitted from the expression.  Beware that using eval()
937 neither silences perl from printing warnings to STDERR, nor does it
938 stuff the text of warning messages into C<$@>.  To do either of those,
939 you have to use the C<$SIG{__WARN__}> facility.  See warn() and L<perlvar>.
940
941 Note that, because eval() traps otherwise-fatal errors, it is useful for
942 determining whether a particular feature (such as socket() or symlink())
943 is implemented.  It is also Perl's exception trapping mechanism, where
944 the die operator is used to raise exceptions.
945
946 If the code to be executed doesn't vary, you may use the eval-BLOCK
947 form to trap run-time errors without incurring the penalty of
948 recompiling each time.  The error, if any, is still returned in C<$@>.
949 Examples:
950
951     # make divide-by-zero non-fatal
952     eval { $answer = $a / $b; }; warn $@ if $@;
953
954     # same thing, but less efficient
955     eval '$answer = $a / $b'; warn $@ if $@;
956
957     # a compile-time error
958     eval { $answer = };
959
960     # a run-time error
961     eval '$answer =';   # sets $@
962
963 When using the eval{} form as an exception trap in libraries, you may
964 wish not to trigger any C<__DIE__> hooks that user code may have
965 installed.  You can use the C<local $SIG{__DIE__}> construct for this
966 purpose, as shown in this example:
967
968     # a very private exception trap for divide-by-zero
969     eval { local $SIG{'__DIE__'}; $answer = $a / $b; }; warn $@ if $@;
970
971 This is especially significant, given that C<__DIE__> hooks can call
972 die() again, which has the effect of changing their error messages:
973
974     # __DIE__ hooks may modify error messages
975     {
976        local $SIG{'__DIE__'} = sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
977        eval { die "foo foofs here" };
978        print $@ if $@;                # prints "bar barfs here"
979     }
980
981 With an eval(), you should be especially careful to remember what's 
982 being looked at when:
983
984     eval $x;            # CASE 1
985     eval "$x";          # CASE 2
986
987     eval '$x';          # CASE 3
988     eval { $x };        # CASE 4
989
990     eval "\$$x++"       # CASE 5
991     $$x++;              # CASE 6
992
993 Cases 1 and 2 above behave identically: they run the code contained in the
994 variable $x.  (Although case 2 has misleading double quotes making the
995 reader wonder what else might be happening (nothing is).) Cases 3 and 4
996 likewise behave in the same way: they run the code E<lt>$xE<gt>, which does
997 nothing at all.  (Case 4 is preferred for purely visual reasons.) Case 5
998 is a place where normally you I<WOULD> like to use double quotes, except
999 that in that particular situation, you can just use symbolic references
1000 instead, as in case 6.
1001
1002 =item exec LIST
1003
1004 The exec() function executes a system command I<AND NEVER RETURNS>,
1005 unless the command does not exist and is executed directly instead of
1006 via C</bin/sh -c> (see below).  Use system() instead of exec() if you
1007 want it to return.
1008
1009 If there is more than one argument in LIST, or if LIST is an array with
1010 more than one value, calls execvp(3) with the arguments in LIST.  If
1011 there is only one scalar argument, the argument is checked for shell
1012 metacharacters.  If there are any, the entire argument is passed to
1013 C</bin/sh -c> for parsing.  If there are none, the argument is split
1014 into words and passed directly to execvp(), which is more efficient.
1015 Note: exec() and system() do not flush your output buffer, so you may
1016 need to set C<$|> to avoid lost output.  Examples:
1017
1018     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1019     exec "sort $outfile | uniq";
1020
1021 If you don't really want to execute the first argument, but want to lie
1022 to the program you are executing about its own name, you can specify
1023 the program you actually want to run as an "indirect object" (without a
1024 comma) in front of the LIST.  (This always forces interpretation of the
1025 LIST as a multi-valued list, even if there is only a single scalar in
1026 the list.)  Example:
1027
1028     $shell = '/bin/csh';
1029     exec $shell '-sh';          # pretend it's a login shell
1030
1031 or, more directly,
1032
1033     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1034
1035 =item exists EXPR
1036
1037 Returns TRUE if the specified hash key exists in its hash array, even
1038 if the corresponding value is undefined.
1039
1040     print "Exists\n" if exists $array{$key};
1041     print "Defined\n" if defined $array{$key};
1042     print "True\n" if $array{$key};
1043
1044 A hash element can be TRUE only if it's defined, and defined if
1045 it exists, but the reverse doesn't necessarily hold true.
1046
1047 Note that the EXPR can be arbitrarily complicated as long as the final
1048 operation is a hash key lookup:
1049
1050     if (exists $ref->[$x][$y]{$key}) { ... }
1051
1052 =item exit EXPR
1053
1054 Evaluates EXPR and exits immediately with that value.  (Actually, it
1055 calls any defined C<END> routines first, but the C<END> routines may not
1056 abort the exit.  Likewise any object destructors that need to be called
1057 are called before exit.)  Example:
1058
1059     $ans = <STDIN>;
1060     exit 0 if $ans =~ /^[Xx]/;
1061
1062 See also die().  If EXPR is omitted, exits with 0 status.  The only
1063 univerally portable values for EXPR are 0 for success and 1 for error;
1064 all other values are subject to unpredictable interpretation depending
1065 on the environment in which the Perl program is running.
1066
1067 You shouldn't use exit() to abort a subroutine if there's any chance that
1068 someone might want to trap whatever error happened.  Use die() instead,
1069 which can be trapped by an eval().
1070
1071 =item exp EXPR
1072
1073 =item exp 
1074
1075 Returns I<e> (the natural logarithm base) to the power of EXPR.  
1076 If EXPR is omitted, gives C<exp($_)>.
1077
1078 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1079
1080 Implements the fcntl(2) function.  You'll probably have to say
1081
1082     use Fcntl;
1083
1084 first to get the correct function definitions.  Argument processing and
1085 value return works just like ioctl() below.  Note that fcntl() will produce
1086 a fatal error if used on a machine that doesn't implement fcntl(2).
1087 For example:
1088
1089     use Fcntl;
1090     fcntl($filehandle, F_GETLK, $packed_return_buffer);
1091
1092 =item fileno FILEHANDLE
1093
1094 Returns the file descriptor for a filehandle.  This is useful for
1095 constructing bitmaps for select().  If FILEHANDLE is an expression, the
1096 value is taken as the name of the filehandle.
1097
1098 =item flock FILEHANDLE,OPERATION
1099
1100 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns TRUE for
1101 success, FALSE on failure.  Will produce a fatal error if used on a
1102 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1103 flock() is Perl's portable file locking interface, although it will lock
1104 only entire files, not records.
1105
1106 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1107 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1108 you can use the symbolic names if you pull them in with an explicit
1109 request to the Fcntl module.  The names can be requested as a group with
1110 the :flock tag (or they can be requested individually, of course).
1111 LOCK_SH requests a shared lock, LOCK_EX requests an exclusive lock, and
1112 LOCK_UN releases a previously requested lock.  If LOCK_NB is added to
1113 LOCK_SH or LOCK_EX then flock() will return immediately rather than
1114 blocking waiting for the lock (check the return status to see if you got
1115 it).
1116
1117 Note that the emulation built with lockf(3) doesn't provide shared
1118 locks, and it requires that FILEHANDLE be open with write intent.  These
1119 are the semantics that lockf(3) implements.  Most (all?) systems
1120 implement lockf(3) in terms of fcntl(2) locking, though, so the
1121 differing semantics shouldn't bite too many people.
1122
1123 Note also that some versions of flock() cannot lock things over the
1124 network; you would need to use the more system-specific fcntl() for
1125 that.  If you like you can force Perl to ignore your system's flock(2)
1126 function, and so provide its own fcntl(2)-based emulation, by passing
1127 the switch C<-Ud_flock> to the F<Configure> program when you configure
1128 perl.
1129
1130 Here's a mailbox appender for BSD systems.
1131
1132     use Fcntl ':flock'; # import LOCK_* constants
1133
1134     sub lock {
1135         flock(MBOX,LOCK_EX);
1136         # and, in case someone appended
1137         # while we were waiting...
1138         seek(MBOX, 0, 2);
1139     }
1140
1141     sub unlock {
1142         flock(MBOX,LOCK_UN);
1143     }
1144
1145     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1146             or die "Can't open mailbox: $!";
1147
1148     lock();
1149     print MBOX $msg,"\n\n";
1150     unlock();
1151
1152 See also L<DB_File> for other flock() examples.
1153
1154 =item fork
1155
1156 Does a fork(2) system call.  Returns the child pid to the parent process
1157 and 0 to the child process, or C<undef> if the fork is unsuccessful.
1158 Note: unflushed buffers remain unflushed in both processes, which means
1159 you may need to set C<$|> ($AUTOFLUSH in English) or call the autoflush()
1160 method of IO::Handle to avoid duplicate output.
1161
1162 If you fork() without ever waiting on your children, you will accumulate
1163 zombies:
1164
1165     $SIG{CHLD} = sub { wait };
1166
1167 There's also the double-fork trick (error checking on 
1168 fork() returns omitted);
1169
1170     unless ($pid = fork) {
1171         unless (fork) {
1172             exec "what you really wanna do";
1173             die "no exec";
1174             # ... or ...
1175             ## (some_perl_code_here)
1176             exit 0;
1177         }
1178         exit 0;
1179     }
1180     waitpid($pid,0);
1181
1182 See also L<perlipc> for more examples of forking and reaping
1183 moribund children.
1184
1185 Note that if your forked child inherits system file descriptors like
1186 STDIN and STDOUT that are actually connected by a pipe or socket, even
1187 if you exit, the remote server (such as, say, httpd or rsh) won't think
1188 you're done.  You should reopen those to /dev/null if it's any issue.
1189
1190 =item format
1191
1192 Declare a picture format with use by the write() function.  For
1193 example:
1194
1195     format Something = 
1196         Test: @<<<<<<<< @||||| @>>>>>
1197               $str,     $%,    '$' . int($num)
1198     .
1199
1200     $str = "widget";
1201     $num = $cost/$quantity;
1202     $~ = 'Something';
1203     write;
1204
1205 See L<perlform> for many details and examples.
1206
1207
1208 =item formline PICTURE, LIST
1209
1210 This is an internal function used by C<format>s, though you may call it
1211 too.  It formats (see L<perlform>) a list of values according to the
1212 contents of PICTURE, placing the output into the format output
1213 accumulator, C<$^A> (or $ACCUMULATOR in English).
1214 Eventually, when a write() is done, the contents of
1215 C<$^A> are written to some filehandle, but you could also read C<$^A>
1216 yourself and then set C<$^A> back to "".  Note that a format typically
1217 does one formline() per line of form, but the formline() function itself
1218 doesn't care how many newlines are embedded in the PICTURE.  This means
1219 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1220 You may therefore need to use multiple formlines to implement a single
1221 record format, just like the format compiler.
1222
1223 Be careful if you put double quotes around the picture, because an "C<@>"
1224 character may be taken to mean the beginning of an array name.
1225 formline() always returns TRUE.  See L<perlform> for other examples.
1226
1227 =item getc FILEHANDLE
1228
1229 =item getc
1230
1231 Returns the next character from the input file attached to FILEHANDLE,
1232 or a null string at end of file.  If FILEHANDLE is omitted, reads from STDIN.
1233 This is not particularly efficient.  It cannot be used to get unbuffered
1234 single-characters, however.  For that, try something more like:
1235
1236     if ($BSD_STYLE) {
1237         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1238     }
1239     else {
1240         system "stty", '-icanon', 'eol', "\001"; 
1241     }
1242
1243     $key = getc(STDIN);
1244
1245     if ($BSD_STYLE) {
1246         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1247     }
1248     else {
1249         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1250     }
1251     print "\n";
1252
1253 Determination of whether $BSD_STYLE should be set 
1254 is left as an exercise to the reader.  
1255
1256 The POSIX::getattr() function can do this more portably on systems
1257 alleging POSIX compliance.
1258 See also the C<Term::ReadKey> module from your nearest CPAN site;
1259 details on CPAN can be found on L<perlmod/CPAN>.  
1260
1261 =item getlogin
1262
1263 Returns the current login from F</etc/utmp>, if any.  If null, use
1264 getpwuid().  
1265
1266     $login = getlogin || getpwuid($<) || "Kilroy";
1267
1268 Do not consider getlogin() for authentication: it is not as
1269 secure as getpwuid().
1270
1271 =item getpeername SOCKET
1272
1273 Returns the packed sockaddr address of other end of the SOCKET connection.
1274
1275     use Socket;
1276     $hersockaddr    = getpeername(SOCK);
1277     ($port, $iaddr) = unpack_sockaddr_in($hersockaddr);
1278     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1279     $herstraddr     = inet_ntoa($iaddr);
1280
1281 =item getpgrp PID
1282
1283 Returns the current process group for the specified PID.  Use
1284 a PID of 0 to get the current process group for the
1285 current process.  Will raise an exception if used on a machine that
1286 doesn't implement getpgrp(2).  If PID is omitted, returns process
1287 group of current process.  Note that the POSIX version of getpgrp()
1288 does not accept a PID argument, so only PID==0 is truly portable.
1289
1290 =item getppid
1291
1292 Returns the process id of the parent process.
1293
1294 =item getpriority WHICH,WHO
1295
1296 Returns the current priority for a process, a process group, or a user.
1297 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1298 machine that doesn't implement getpriority(2).
1299
1300 =item getpwnam NAME
1301
1302 =item getgrnam NAME
1303
1304 =item gethostbyname NAME
1305
1306 =item getnetbyname NAME
1307
1308 =item getprotobyname NAME
1309
1310 =item getpwuid UID
1311
1312 =item getgrgid GID
1313
1314 =item getservbyname NAME,PROTO
1315
1316 =item gethostbyaddr ADDR,ADDRTYPE
1317
1318 =item getnetbyaddr ADDR,ADDRTYPE
1319
1320 =item getprotobynumber NUMBER
1321
1322 =item getservbyport PORT,PROTO
1323
1324 =item getpwent
1325
1326 =item getgrent
1327
1328 =item gethostent
1329
1330 =item getnetent
1331
1332 =item getprotoent
1333
1334 =item getservent
1335
1336 =item setpwent
1337
1338 =item setgrent
1339
1340 =item sethostent STAYOPEN
1341
1342 =item setnetent STAYOPEN
1343
1344 =item setprotoent STAYOPEN
1345
1346 =item setservent STAYOPEN
1347
1348 =item endpwent
1349
1350 =item endgrent
1351
1352 =item endhostent
1353
1354 =item endnetent
1355
1356 =item endprotoent
1357
1358 =item endservent
1359
1360 These routines perform the same functions as their counterparts in the
1361 system library.  Within a list context, the return values from the
1362 various get routines are as follows:
1363
1364     ($name,$passwd,$uid,$gid,
1365        $quota,$comment,$gcos,$dir,$shell) = getpw*
1366     ($name,$passwd,$gid,$members) = getgr*
1367     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1368     ($name,$aliases,$addrtype,$net) = getnet*
1369     ($name,$aliases,$proto) = getproto*
1370     ($name,$aliases,$port,$proto) = getserv*
1371
1372 (If the entry doesn't exist you get a null list.)
1373
1374 Within a scalar context, you get the name, unless the function was a
1375 lookup by name, in which case you get the other thing, whatever it is.
1376 (If the entry doesn't exist you get the undefined value.)  For example:
1377
1378     $uid = getpwnam
1379     $name = getpwuid
1380     $name = getpwent
1381     $gid = getgrnam
1382     $name = getgrgid
1383     $name = getgrent
1384     etc.
1385
1386 The $members value returned by I<getgr*()> is a space separated list of
1387 the login names of the members of the group.
1388
1389 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1390 C, it will be returned to you via C<$?> if the function call fails.  The
1391 @addrs value returned by a successful call is a list of the raw
1392 addresses returned by the corresponding system library call.  In the
1393 Internet domain, each address is four bytes long and you can unpack it
1394 by saying something like:
1395
1396     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1397
1398 =item getsockname SOCKET
1399
1400 Returns the packed sockaddr address of this end of the SOCKET connection.
1401
1402     use Socket;
1403     $mysockaddr = getsockname(SOCK);
1404     ($port, $myaddr) = unpack_sockaddr_in($mysockaddr);
1405
1406 =item getsockopt SOCKET,LEVEL,OPTNAME
1407
1408 Returns the socket option requested, or undefined if there is an error.
1409
1410 =item glob EXPR
1411
1412 =item glob
1413
1414 Returns the value of EXPR with filename expansions such as a shell
1415 would do.  This is the internal function implementing the E<lt>*.*E<gt>
1416 operator, except it's easier to use.
1417 If EXPR is omitted, $_ is used.
1418
1419 =item gmtime EXPR
1420
1421 Converts a time as returned by the time function to a 9-element array
1422 with the time localized for the standard Greenwich time zone.  
1423 Typically used as follows:
1424
1425
1426     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
1427                                             gmtime(time);
1428
1429 All array elements are numeric, and come straight out of a struct tm.
1430 In particular this means that $mon has the range 0..11 and $wday has
1431 the range 0..6.  If EXPR is omitted, does C<gmtime(time())>.
1432
1433 In a scalar context, prints out the ctime(3) value:
1434
1435     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
1436
1437 Also see the F<timegm.pl> library, and the strftime(3) function available
1438 via the POSIX module.
1439
1440 =item goto LABEL
1441
1442 =item goto EXPR
1443
1444 =item goto &NAME
1445
1446 The goto-LABEL form finds the statement labeled with LABEL and resumes
1447 execution there.  It may not be used to go into any construct that
1448 requires initialization, such as a subroutine or a foreach loop.  It
1449 also can't be used to go into a construct that is optimized away,
1450 or to get out of a block or subroutine given to sort().
1451 It can be used to go almost anywhere else within the dynamic scope,
1452 including out of subroutines, but it's usually better to use some other
1453 construct such as last or die.  The author of Perl has never felt the
1454 need to use this form of goto (in Perl, that is--C is another matter).
1455
1456 The goto-EXPR form expects a label name, whose scope will be resolved
1457 dynamically.  This allows for computed gotos per FORTRAN, but isn't
1458 necessarily recommended if you're optimizing for maintainability:
1459
1460     goto ("FOO", "BAR", "GLARCH")[$i];
1461
1462 The goto-&NAME form is highly magical, and substitutes a call to the
1463 named subroutine for the currently running subroutine.  This is used by
1464 AUTOLOAD subroutines that wish to load another subroutine and then
1465 pretend that the other subroutine had been called in the first place
1466 (except that any modifications to @_ in the current subroutine are
1467 propagated to the other subroutine.)  After the goto, not even caller()
1468 will be able to tell that this routine was called first.
1469
1470 =item grep BLOCK LIST
1471
1472 =item grep EXPR,LIST
1473
1474 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
1475 $_ to each element) and returns the list value consisting of those
1476 elements for which the expression evaluated to TRUE.  In a scalar
1477 context, returns the number of times the expression was TRUE.
1478
1479     @foo = grep(!/^#/, @bar);    # weed out comments
1480
1481 or equivalently,
1482
1483     @foo = grep {!/^#/} @bar;    # weed out comments
1484
1485 Note that, because $_ is a reference into the list value, it can be used
1486 to modify the elements of the array.  While this is useful and
1487 supported, it can cause bizarre results if the LIST is not a named
1488 array.
1489
1490 =item hex EXPR
1491
1492 =item hex 
1493
1494 Interprets EXPR as a hex string and returns the corresponding decimal
1495 value.  (To convert strings that might start with 0 or 0x see
1496 oct().)  If EXPR is omitted, uses $_.
1497
1498 =item import
1499
1500 There is no built-in import() function.  It is merely an ordinary
1501 method (subroutine) defined (or inherited) by modules that wish to export
1502 names to another module.  The use() function calls the import() method
1503 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
1504
1505 =item index STR,SUBSTR,POSITION
1506
1507 =item index STR,SUBSTR
1508
1509 Returns the position of the first occurrence of SUBSTR in STR at or after
1510 POSITION.  If POSITION is omitted, starts searching from the beginning of
1511 the string.  The return value is based at 0 (or whatever you've set the C<$[>
1512 variable to--but don't do that).  If the substring is not found, returns
1513 one less than the base, ordinarily -1.
1514
1515 =item int EXPR
1516
1517 =item int 
1518
1519 Returns the integer portion of EXPR.  If EXPR is omitted, uses $_.
1520
1521 =item ioctl FILEHANDLE,FUNCTION,SCALAR
1522
1523 Implements the ioctl(2) function.  You'll probably have to say
1524
1525     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
1526
1527 first to get the correct function definitions.  If F<ioctl.ph> doesn't
1528 exist or doesn't have the correct definitions you'll have to roll your
1529 own, based on your C header files such as F<E<lt>sys/ioctl.hE<gt>>.
1530 (There is a Perl script called B<h2ph> that comes with the Perl kit which
1531 may help you in this, but it's non-trivial.)  SCALAR will be read and/or
1532 written depending on the FUNCTION--a pointer to the string value of SCALAR
1533 will be passed as the third argument of the actual ioctl call.  (If SCALAR
1534 has no string value but does have a numeric value, that value will be
1535 passed rather than a pointer to the string value.  To guarantee this to be
1536 TRUE, add a 0 to the scalar before using it.)  The pack() and unpack()
1537 functions are useful for manipulating the values of structures used by
1538 ioctl().  The following example sets the erase character to DEL.
1539
1540     require 'ioctl.ph';
1541     $getp = &TIOCGETP;
1542     die "NO TIOCGETP" if $@ || !$getp;
1543     $sgttyb_t = "ccccs";                # 4 chars and a short
1544     if (ioctl(STDIN,$getp,$sgttyb)) {
1545         @ary = unpack($sgttyb_t,$sgttyb);
1546         $ary[2] = 127;
1547         $sgttyb = pack($sgttyb_t,@ary);
1548         ioctl(STDIN,&TIOCSETP,$sgttyb)
1549             || die "Can't ioctl: $!";
1550     }
1551
1552 The return value of ioctl (and fcntl) is as follows:
1553
1554         if OS returns:          then Perl returns:
1555             -1                    undefined value
1556              0                  string "0 but true"
1557         anything else               that number
1558
1559 Thus Perl returns TRUE on success and FALSE on failure, yet you can
1560 still easily determine the actual value returned by the operating
1561 system:
1562
1563     ($retval = ioctl(...)) || ($retval = -1);
1564     printf "System returned %d\n", $retval;
1565
1566 =item join EXPR,LIST
1567
1568 Joins the separate strings of LIST or ARRAY into a single string with
1569 fields separated by the value of EXPR, and returns the string.
1570 Example:
1571
1572     $_ = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
1573
1574 See L<perlfunc/split>.
1575
1576 =item keys ASSOC_ARRAY
1577
1578 Returns a normal array consisting of all the keys of the named
1579 associative array.  (In a scalar context, returns the number of keys.)
1580 The keys are returned in an apparently random order, but it is the same
1581 order as either the values() or each() function produces (given that
1582 the associative array has not been modified).  Here is yet another way
1583 to print your environment:
1584
1585     @keys = keys %ENV;
1586     @values = values %ENV;
1587     while ($#keys >= 0) {
1588         print pop(@keys), '=', pop(@values), "\n";
1589     }
1590
1591 or how about sorted by key:
1592
1593     foreach $key (sort(keys %ENV)) {
1594         print $key, '=', $ENV{$key}, "\n";
1595     }
1596
1597 To sort an array by value, you'll need to use a C<sort{}>
1598 function.  Here's a descending numeric sort of a hash by its values:
1599
1600     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash)) {
1601         printf "%4d %s\n", $hash{$key}, $key;
1602     }
1603
1604 As an lvalue C<keys> allows you to increase the number of hash buckets
1605 allocated for the given associative array.  This can gain you a measure
1606 of efficiency if you know the hash is going to get big.  (This is
1607 similar to pre-extending an array by assigning a larger number to
1608 $#array.)  If you say
1609
1610     keys %hash = 200;
1611
1612 then C<%hash> will have at least 200 buckets allocated for it.  These
1613 buckets will be retained even if you do C<%hash = ()>, use C<undef
1614 %hash> if you want to free the storage while C<%hash> is still in scope.
1615 You can't shrink the number of buckets allocated for the hash using
1616 C<keys> in this way (but you needn't worry about doing this by accident,
1617 as trying has no effect).
1618
1619 =item kill LIST
1620
1621 Sends a signal to a list of processes.  The first element of 
1622 the list must be the signal to send.  Returns the number of 
1623 processes successfully signaled.
1624
1625     $cnt = kill 1, $child1, $child2;
1626     kill 9, @goners;
1627
1628 Unlike in the shell, in Perl if the I<SIGNAL> is negative, it kills
1629 process groups instead of processes.  (On System V, a negative I<PROCESS>
1630 number will also kill process groups, but that's not portable.)  That
1631 means you usually want to use positive not negative signals.  You may also
1632 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
1633
1634 =item last LABEL
1635
1636 =item last
1637
1638 The C<last> command is like the C<break> statement in C (as used in
1639 loops); it immediately exits the loop in question.  If the LABEL is
1640 omitted, the command refers to the innermost enclosing loop.  The
1641 C<continue> block, if any, is not executed:
1642
1643     LINE: while (<STDIN>) {
1644         last LINE if /^$/;      # exit when done with header
1645         ...
1646     }
1647
1648 =item lc EXPR
1649
1650 =item lc 
1651
1652 Returns an lowercased version of EXPR.  This is the internal function
1653 implementing the \L escape in double-quoted strings.  
1654 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
1655
1656 If EXPR is omitted, uses $_.
1657
1658 =item lcfirst EXPR
1659
1660 =item lcfirst 
1661
1662 Returns the value of EXPR with the first character lowercased.  This is
1663 the internal function implementing the \l escape in double-quoted strings.
1664 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
1665
1666 If EXPR is omitted, uses $_.
1667
1668 =item length EXPR
1669
1670 =item length 
1671
1672 Returns the length in characters of the value of EXPR.  If EXPR is
1673 omitted, returns length of $_.
1674
1675 =item link OLDFILE,NEWFILE
1676
1677 Creates a new filename linked to the old filename.  Returns 1 for
1678 success, 0 otherwise.
1679
1680 =item listen SOCKET,QUEUESIZE
1681
1682 Does the same thing that the listen system call does.  Returns TRUE if
1683 it succeeded, FALSE otherwise.  See example in L<perlipc/"Sockets: Client/Server Communication">.
1684
1685 =item local EXPR
1686
1687 A local modifies the listed variables to be local to the enclosing block,
1688 subroutine, C<eval{}>, or C<do>.  If more than one value is listed, the
1689 list must be placed in parentheses.  See L<perlsub/"Temporary Values via
1690 local()"> for details.
1691
1692 But you really probably want to be using my() instead, because local() isn't
1693 what most people think of as "local").  See L<perlsub/"Private Variables
1694 via my()"> for details.
1695
1696 =item localtime EXPR
1697
1698 Converts a time as returned by the time function to a 9-element array
1699 with the time analyzed for the local time zone.  Typically used as
1700 follows:
1701
1702     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
1703                                                 localtime(time);
1704
1705 All array elements are numeric, and come straight out of a struct tm.
1706 In particular this means that $mon has the range 0..11 and $wday has
1707 the range 0..6 and $year is year-1900, that is, $year is 123 in year
1708 2023.  If EXPR is omitted, uses the current time ("localtime(time)").
1709
1710 In a scalar context, returns the ctime(3) value:
1711
1712     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
1713
1714 Also see the Time::Local module, and the strftime(3) function available
1715 via the POSIX module.
1716
1717 =item log EXPR
1718
1719 =item log 
1720
1721 Returns logarithm (base I<e>) of EXPR.  If EXPR is omitted, returns log
1722 of $_.
1723
1724 =item lstat FILEHANDLE
1725
1726 =item lstat EXPR
1727
1728 =item lstat 
1729
1730 Does the same thing as the stat() function, but stats a symbolic link
1731 instead of the file the symbolic link points to.  If symbolic links are
1732 unimplemented on your system, a normal stat() is done.
1733
1734 If EXPR is omitted, stats $_.
1735
1736 =item m//
1737
1738 The match operator.  See L<perlop>.
1739
1740 =item map BLOCK LIST
1741
1742 =item map EXPR,LIST
1743
1744 Evaluates the BLOCK or EXPR for each element of LIST (locally setting $_ to each
1745 element) and returns the list value composed of the results of each such
1746 evaluation.  Evaluates BLOCK or EXPR in a list context, so each element of LIST
1747 may produce zero, one, or more elements in the returned value.
1748
1749     @chars = map(chr, @nums);
1750
1751 translates a list of numbers to the corresponding characters.  And
1752
1753     %hash = map { getkey($_) => $_ } @array;
1754
1755 is just a funny way to write
1756
1757     %hash = ();
1758     foreach $_ (@array) {
1759         $hash{getkey($_)} = $_;
1760     }
1761
1762 =item mkdir FILENAME,MODE
1763
1764 Creates the directory specified by FILENAME, with permissions specified
1765 by MODE (as modified by umask).  If it succeeds it returns 1, otherwise
1766 it returns 0 and sets C<$!> (errno).
1767
1768 =item msgctl ID,CMD,ARG
1769
1770 Calls the System V IPC function msgctl(2).  If CMD is &IPC_STAT, then ARG
1771 must be a variable which will hold the returned msqid_ds structure.
1772 Returns like ioctl: the undefined value for error, "0 but true" for
1773 zero, or the actual return value otherwise.
1774
1775 =item msgget KEY,FLAGS
1776
1777 Calls the System V IPC function msgget(2).  Returns the message queue id,
1778 or the undefined value if there is an error.
1779
1780 =item msgsnd ID,MSG,FLAGS
1781
1782 Calls the System V IPC function msgsnd to send the message MSG to the
1783 message queue ID.  MSG must begin with the long integer message type,
1784 which may be created with C<pack("l", $type)>.  Returns TRUE if
1785 successful, or FALSE if there is an error.
1786
1787 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
1788
1789 Calls the System V IPC function msgrcv to receive a message from
1790 message queue ID into variable VAR with a maximum message size of
1791 SIZE.  Note that if a message is received, the message type will be the
1792 first thing in VAR, and the maximum length of VAR is SIZE plus the size
1793 of the message type.  Returns TRUE if successful, or FALSE if there is
1794 an error.
1795
1796 =item my EXPR
1797
1798 A "my" declares the listed variables to be local (lexically) to the
1799 enclosing block, subroutine, C<eval>, or C<do/require/use>'d file.  If
1800 more than one value is listed, the list must be placed in parentheses.  See
1801 L<perlsub/"Private Variables via my()"> for details.
1802
1803 =item next LABEL
1804
1805 =item next
1806
1807 The C<next> command is like the C<continue> statement in C; it starts
1808 the next iteration of the loop:
1809
1810     LINE: while (<STDIN>) {
1811         next LINE if /^#/;      # discard comments
1812         ...
1813     }
1814
1815 Note that if there were a C<continue> block on the above, it would get
1816 executed even on discarded lines.  If the LABEL is omitted, the command
1817 refers to the innermost enclosing loop.
1818
1819 =item no Module LIST
1820
1821 See the "use" function, which "no" is the opposite of.
1822
1823 =item oct EXPR
1824
1825 =item oct 
1826
1827 Interprets EXPR as an octal string and returns the corresponding
1828 decimal value.  (If EXPR happens to start off with 0x, interprets it as
1829 a hex string instead.)  The following will handle decimal, octal, and
1830 hex in the standard Perl or C notation:
1831
1832     $val = oct($val) if $val =~ /^0/;
1833
1834 If EXPR is omitted, uses $_.
1835
1836 =item open FILEHANDLE,EXPR
1837
1838 =item open FILEHANDLE
1839
1840 Opens the file whose filename is given by EXPR, and associates it with
1841 FILEHANDLE.  If FILEHANDLE is an expression, its value is used as the
1842 name of the real filehandle wanted.  If EXPR is omitted, the scalar
1843 variable of the same name as the FILEHANDLE contains the filename.
1844 (Note that lexical variables--those declared with C<my>--will not work
1845 for this purpose; so if you're using C<my>, specify EXPR in your call
1846 to open.)
1847
1848 If the filename begins with '<' or nothing, the file is opened for input.
1849 If the filename begins with '>', the file is truncated and opened for
1850 output.  If the filename begins with '>>', the file is opened for
1851 appending.  You can put a '+' in front of the '>' or '<' to indicate that
1852 you want both read and write access to the file; thus '+<' is almost
1853 always preferred for read/write updates--the '+>' mode would clobber the
1854 file first.  The prefix and the filename may be separated with spaces.
1855 These various prefixes correspond to the fopen(3) modes of 'r', 'r+', 'w',
1856 'w+', 'a', and 'a+'.
1857
1858 If the filename begins with "|", the filename is interpreted as a command
1859 to which output is to be piped, and if the filename ends with a "|", the
1860 filename is interpreted See L<perlipc/"Using open() for IPC"> for more
1861 examples of this.  as command which pipes input to us.  (You may not have
1862 a raw open() to a command that pipes both in I<and> out, but see
1863 L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
1864 for alternatives.)
1865
1866 Opening '-' opens STDIN and opening 'E<gt>-' opens STDOUT.  Open returns
1867 non-zero upon success, the undefined value otherwise.  If the open
1868 involved a pipe, the return value happens to be the pid of the
1869 subprocess.  
1870
1871 If you're unfortunate enough to be running Perl on a system that
1872 distinguishes between text files and binary files (modern operating
1873 systems don't care), then you should check out L</binmode> for tips for
1874 dealing with this.  The key distinction between systems that need binmode
1875 and those that don't is their text file formats.  Systems like Unix and
1876 Plan9 that delimit lines with a single character, and that encode that
1877 character in C as '\n', do not need C<binmode>.  The rest need it.
1878
1879 Examples:
1880
1881     $ARTICLE = 100;
1882     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
1883     while (<ARTICLE>) {...
1884
1885     open(LOG, '>>/usr/spool/news/twitlog'); # (log is reserved)
1886
1887     open(DBASE, '+<dbase.mine');            # open for update
1888
1889     open(ARTICLE, "caesar <$article |");    # decrypt article
1890
1891     open(EXTRACT, "|sort >/tmp/Tmp$$");     # $$ is our process id
1892
1893     # process argument list of files along with any includes
1894
1895     foreach $file (@ARGV) {
1896         process($file, 'fh00');
1897     }
1898
1899     sub process {
1900         local($filename, $input) = @_;
1901         $input++;               # this is a string increment
1902         unless (open($input, $filename)) {
1903             print STDERR "Can't open $filename: $!\n";
1904             return;
1905         }
1906
1907         while (<$input>) {              # note use of indirection
1908             if (/^#include "(.*)"/) {
1909                 process($1, $input);
1910                 next;
1911             }
1912             ...         # whatever
1913         }
1914     }
1915
1916 You may also, in the Bourne shell tradition, specify an EXPR beginning
1917 with "E<gt>&", in which case the rest of the string is interpreted as the
1918 name of a filehandle (or file descriptor, if numeric) which is to be
1919 duped and opened.  You may use & after E<gt>, E<gt>E<gt>, E<lt>, +E<gt>,
1920 +E<gt>E<gt>, and +E<lt>.  The
1921 mode you specify should match the mode of the original filehandle.
1922 (Duping a filehandle does not take into account any existing contents of
1923 stdio buffers.)
1924 Here is a script that saves, redirects, and restores STDOUT and
1925 STDERR:
1926
1927     #!/usr/bin/perl
1928     open(SAVEOUT, ">&STDOUT");
1929     open(SAVEERR, ">&STDERR");
1930
1931     open(STDOUT, ">foo.out") || die "Can't redirect stdout";
1932     open(STDERR, ">&STDOUT") || die "Can't dup stdout";
1933
1934     select(STDERR); $| = 1;     # make unbuffered
1935     select(STDOUT); $| = 1;     # make unbuffered
1936
1937     print STDOUT "stdout 1\n";  # this works for
1938     print STDERR "stderr 1\n";  # subprocesses too
1939
1940     close(STDOUT);
1941     close(STDERR);
1942
1943     open(STDOUT, ">&SAVEOUT");
1944     open(STDERR, ">&SAVEERR");
1945
1946     print STDOUT "stdout 2\n";
1947     print STDERR "stderr 2\n";
1948
1949
1950 If you specify "E<lt>&=N", where N is a number, then Perl will do an
1951 equivalent of C's fdopen() of that file descriptor; this is more
1952 parsimonious of file descriptors.  For example:
1953
1954     open(FILEHANDLE, "<&=$fd")
1955
1956 If you open a pipe on the command "-", i.e., either "|-" or "-|", then
1957 there is an implicit fork done, and the return value of open is the pid
1958 of the child within the parent process, and 0 within the child
1959 process.  (Use C<defined($pid)> to determine whether the open was successful.)
1960 The filehandle behaves normally for the parent, but i/o to that
1961 filehandle is piped from/to the STDOUT/STDIN of the child process.
1962 In the child process the filehandle isn't opened--i/o happens from/to
1963 the new STDOUT or STDIN.  Typically this is used like the normal
1964 piped open when you want to exercise more control over just how the
1965 pipe command gets executed, such as when you are running setuid, and
1966 don't want to have to scan shell commands for metacharacters.  
1967 The following pairs are more or less equivalent:
1968
1969     open(FOO, "|tr '[a-z]' '[A-Z]'");
1970     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
1971
1972     open(FOO, "cat -n '$file'|");
1973     open(FOO, "-|") || exec 'cat', '-n', $file;
1974
1975 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
1976
1977 Explicitly closing any piped filehandle causes the parent process to
1978 wait for the child to finish, and returns the status value in C<$?>.
1979 Note: on any operation which may do a fork, unflushed buffers remain
1980 unflushed in both processes, which means you may need to set C<$|> to
1981 avoid duplicate output.
1982
1983 Using the constructor from the IO::Handle package (or one of its
1984 subclasses, such as IO::File or IO::Socket),
1985 you can generate anonymous filehandles which have the scope of whatever
1986 variables hold references to them, and automatically close whenever
1987 and however you leave that scope:
1988
1989     use IO::File;
1990     ...
1991     sub read_myfile_munged {
1992         my $ALL = shift;
1993         my $handle = new IO::File;
1994         open($handle, "myfile") or die "myfile: $!";
1995         $first = <$handle>
1996             or return ();     # Automatically closed here.
1997         mung $first or die "mung failed";       # Or here.
1998         return $first, <$handle> if $ALL;       # Or here.
1999         $first;                                 # Or here.
2000     }
2001
2002 The filename that is passed to open will have leading and trailing
2003 whitespace deleted.  To open a file with arbitrary weird
2004 characters in it, it's necessary to protect any leading and trailing
2005 whitespace thusly:
2006
2007     $file =~ s#^(\s)#./$1#;
2008     open(FOO, "< $file\0");
2009
2010 If you want a "real" C open() (see L<open(2)> on your system), then
2011 you should use the sysopen() function.  This is another way to
2012 protect your filenames from interpretation.  For example:
2013
2014     use IO::Handle;
2015     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL, 0700)
2016         or die "sysopen $path: $!";
2017     HANDLE->autoflush(1);
2018     HANDLE->print("stuff $$\n");
2019     seek(HANDLE, 0, 0);
2020     print "File contains: ", <HANDLE>;
2021
2022 See L</seek()> for some details about mixing reading and writing.
2023
2024 =item opendir DIRHANDLE,EXPR
2025
2026 Opens a directory named EXPR for processing by readdir(), telldir(),
2027 seekdir(), rewinddir(), and closedir().  Returns TRUE if successful.
2028 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
2029
2030 =item ord EXPR
2031
2032 =item ord 
2033
2034 Returns the numeric ascii value of the first character of EXPR.  If
2035 EXPR is omitted, uses $_.
2036
2037 =item pack TEMPLATE,LIST
2038
2039 Takes an array or list of values and packs it into a binary structure,
2040 returning the string containing the structure.  The TEMPLATE is a
2041 sequence of characters that give the order and type of values, as
2042 follows:
2043
2044     A   An ascii string, will be space padded.
2045     a   An ascii string, will be null padded.
2046     b   A bit string (ascending bit order, like vec()).
2047     B   A bit string (descending bit order).
2048     h   A hex string (low nybble first).
2049     H   A hex string (high nybble first).
2050
2051     c   A signed char value.
2052     C   An unsigned char value.
2053     s   A signed short value.
2054     S   An unsigned short value.
2055     i   A signed integer value.
2056     I   An unsigned integer value.
2057     l   A signed long value.
2058     L   An unsigned long value.
2059
2060     n   A short in "network" order.
2061     N   A long in "network" order.
2062     v   A short in "VAX" (little-endian) order.
2063     V   A long in "VAX" (little-endian) order.
2064
2065     f   A single-precision float in the native format.
2066     d   A double-precision float in the native format.
2067
2068     p   A pointer to a null-terminated string.
2069     P   A pointer to a structure (fixed-length string).
2070
2071     u   A uuencoded string.
2072
2073     w A BER compressed integer. Bytes give an unsigned integer base
2074       128, most significant digit first, with as few digits as
2075       possible, and with the bit 8 of each byte except the last set
2076       to "1."
2077
2078     x   A null byte.
2079     X   Back up a byte.
2080     @   Null fill to absolute position.
2081
2082 Each letter may optionally be followed by a number which gives a repeat
2083 count.  With all types except "a", "A", "b", "B", "h", "H", and "P" the
2084 pack function will gobble up that many values from the LIST.  A * for the
2085 repeat count means to use however many items are left.  The "a" and "A"
2086 types gobble just one value, but pack it as a string of length count,
2087 padding with nulls or spaces as necessary.  (When unpacking, "A" strips
2088 trailing spaces and nulls, but "a" does not.)  Likewise, the "b" and "B"
2089 fields pack a string that many bits long.  The "h" and "H" fields pack a
2090 string that many nybbles long.  The "P" packs a pointer to a structure of
2091 the size indicated by the length.  Real numbers (floats and doubles) are
2092 in the native machine format only; due to the multiplicity of floating
2093 formats around, and the lack of a standard "network" representation, no
2094 facility for interchange has been made.  This means that packed floating
2095 point data written on one machine may not be readable on another - even if
2096 both use IEEE floating point arithmetic (as the endian-ness of the memory
2097 representation is not part of the IEEE spec).  Note that Perl uses doubles
2098 internally for all numeric calculation, and converting from double into
2099 float and thence back to double again will lose precision (i.e.,
2100 C<unpack("f", pack("f", $foo)>) will not in general equal $foo).
2101
2102 Examples:
2103
2104     $foo = pack("cccc",65,66,67,68);
2105     # foo eq "ABCD"
2106     $foo = pack("c4",65,66,67,68);
2107     # same thing
2108
2109     $foo = pack("ccxxcc",65,66,67,68);
2110     # foo eq "AB\0\0CD"
2111
2112     $foo = pack("s2",1,2);
2113     # "\1\0\2\0" on little-endian
2114     # "\0\1\0\2" on big-endian
2115
2116     $foo = pack("a4","abcd","x","y","z");
2117     # "abcd"
2118
2119     $foo = pack("aaaa","abcd","x","y","z");
2120     # "axyz"
2121
2122     $foo = pack("a14","abcdefg");
2123     # "abcdefg\0\0\0\0\0\0\0"
2124
2125     $foo = pack("i9pl", gmtime);
2126     # a real struct tm (on my system anyway)
2127
2128     sub bintodec {
2129         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
2130     }
2131
2132 The same template may generally also be used in the unpack function.
2133
2134 =item package NAMESPACE
2135
2136 Declares the compilation unit as being in the given namespace.  The scope
2137 of the package declaration is from the declaration itself through the end of
2138 the enclosing block (the same scope as the local() operator).  All further
2139 unqualified dynamic identifiers will be in this namespace.  A package
2140 statement affects only dynamic variables--including those you've used
2141 local() on--but I<not> lexical variables created with my().  Typically it
2142 would be the first declaration in a file to be included by the C<require>
2143 or C<use> operator.  You can switch into a package in more than one place;
2144 it influences merely which symbol table is used by the compiler for the
2145 rest of that block.  You can refer to variables and filehandles in other
2146 packages by prefixing the identifier with the package name and a double
2147 colon:  C<$Package::Variable>.  If the package name is null, the C<main>
2148 package as assumed.  That is, C<$::sail> is equivalent to C<$main::sail>.
2149
2150 See L<perlmod/"Packages"> for more information about packages, modules,
2151 and classes.  See L<perlsub> for other scoping issues.
2152
2153 =item pipe READHANDLE,WRITEHANDLE
2154
2155 Opens a pair of connected pipes like the corresponding system call.
2156 Note that if you set up a loop of piped processes, deadlock can occur
2157 unless you are very careful.  In addition, note that Perl's pipes use
2158 stdio buffering, so you may need to set C<$|> to flush your WRITEHANDLE
2159 after each command, depending on the application.
2160
2161 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
2162 for examples of such things.
2163
2164 =item pop ARRAY
2165
2166 =item pop 
2167
2168 Pops and returns the last value of the array, shortening the array by
2169 1.  Has a similar effect to
2170
2171     $tmp = $ARRAY[$#ARRAY--];
2172
2173 If there are no elements in the array, returns the undefined value.
2174 If ARRAY is omitted, pops the
2175 @ARGV array in the main program, and the @_ array in subroutines, just
2176 like shift().
2177
2178 =item pos SCALAR
2179
2180 =item pos 
2181
2182 Returns the offset of where the last C<m//g> search left off for the variable
2183 is in question ($_ is used when the variable is not specified). May be
2184 modified to change that offset.  Such modification will also influence
2185 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
2186 L<perlop>.
2187
2188 =item print FILEHANDLE LIST
2189
2190 =item print LIST
2191
2192 =item print
2193
2194 Prints a string or a comma-separated list of strings.  Returns TRUE
2195 if successful.  FILEHANDLE may be a scalar variable name, in which case
2196 the variable contains the name of or a reference to the filehandle, thus introducing one
2197 level of indirection.  (NOTE: If FILEHANDLE is a variable and the next
2198 token is a term, it may be misinterpreted as an operator unless you
2199 interpose a + or put parentheses around the arguments.)  If FILEHANDLE is
2200 omitted, prints by default to standard output (or to the last selected
2201 output channel--see L</select>).  If LIST is also omitted, prints $_ to
2202 STDOUT.  To set the default output channel to something other than
2203 STDOUT use the select operation.  Note that, because print takes a
2204 LIST, anything in the LIST is evaluated in a list context, and any
2205 subroutine that you call will have one or more of its expressions
2206 evaluated in a list context.  Also be careful not to follow the print
2207 keyword with a left parenthesis unless you want the corresponding right
2208 parenthesis to terminate the arguments to the print--interpose a + or
2209 put parentheses around all the arguments.
2210
2211 Note that if you're storing FILEHANDLES in an array or other expression,
2212 you will have to use a block returning its value instead:
2213
2214     print { $files[$i] } "stuff\n";
2215     print { $OK ? STDOUT : STDERR } "stuff\n";
2216
2217 =item printf FILEHANDLE FORMAT, LIST
2218
2219 =item printf FORMAT, LIST
2220
2221 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>.  The first argument
2222 of the list will be interpreted as the printf format.  If C<use locale> is
2223 in effect, the character used for the decimal point in formatted real numbers
2224 is affected by the LC_NUMERIC locale.  See L<perllocale>.
2225
2226 Don't fall into the trap of using a printf() when a simple
2227 print() would do.  The print() is more efficient, and less
2228 error prone.
2229
2230 =item prototype FUNCTION
2231
2232 Returns the prototype of a function as a string (or C<undef> if the
2233 function has no prototype).  FUNCTION is a reference to, or the name of,
2234 the function whose prototype you want to retrieve.
2235
2236 =item push ARRAY,LIST
2237
2238 Treats ARRAY as a stack, and pushes the values of LIST
2239 onto the end of ARRAY.  The length of ARRAY increases by the length of
2240 LIST.  Has the same effect as
2241
2242     for $value (LIST) {
2243         $ARRAY[++$#ARRAY] = $value;
2244     }
2245
2246 but is more efficient.  Returns the new number of elements in the array.
2247
2248 =item q/STRING/
2249
2250 =item qq/STRING/
2251
2252 =item qx/STRING/
2253
2254 =item qw/STRING/
2255
2256 Generalized quotes.  See L<perlop>.
2257
2258 =item quotemeta EXPR
2259
2260 =item quotemeta 
2261
2262 Returns the value of EXPR with with all non-alphanumeric
2263 characters backslashed.  (That is, all characters not matching
2264 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
2265 returned string, regardless of any locale settings.)
2266 This is the internal function implementing
2267 the \Q escape in double-quoted strings.
2268
2269 If EXPR is omitted, uses $_.
2270
2271 =item rand EXPR
2272
2273 =item rand
2274
2275 Returns a random fractional number between 0 and the value of EXPR.
2276 (EXPR should be positive.)  If EXPR is omitted, returns a value between 
2277 0 and 1.  This function produces repeatable sequences unless srand() 
2278 is invoked.  See also srand().
2279
2280 (Note: if your rand function consistently returns numbers that are too
2281 large or too small, then your version of Perl was probably compiled
2282 with the wrong number of RANDBITS.  As a workaround, you can usually
2283 multiply EXPR by the correct power of 2 to get the range you want.
2284 This will make your script unportable, however.  It's better to recompile
2285 if you can.)
2286
2287 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
2288
2289 =item read FILEHANDLE,SCALAR,LENGTH
2290
2291 Attempts to read LENGTH bytes of data into variable SCALAR from the
2292 specified FILEHANDLE.  Returns the number of bytes actually read, or
2293 undef if there was an error.  SCALAR will be grown or shrunk to the
2294 length actually read.  An OFFSET may be specified to place the read
2295 data at some other place than the beginning of the string.  This call
2296 is actually implemented in terms of stdio's fread call.  To get a true
2297 read system call, see sysread().
2298
2299 =item readdir DIRHANDLE
2300
2301 Returns the next directory entry for a directory opened by opendir().
2302 If used in a list context, returns all the rest of the entries in the
2303 directory.  If there are no more entries, returns an undefined value in
2304 a scalar context or a null list in a list context.
2305
2306 If you're planning to filetest the return values out of a readdir(), you'd
2307 better prepend the directory in question.  Otherwise, because we didn't
2308 chdir() there, it would have been testing the wrong file.
2309
2310     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
2311     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
2312     closedir DIR;
2313
2314 =item readlink EXPR
2315
2316 =item readlink 
2317
2318 Returns the value of a symbolic link, if symbolic links are
2319 implemented.  If not, gives a fatal error.  If there is some system
2320 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
2321 omitted, uses $_.
2322
2323 =item recv SOCKET,SCALAR,LEN,FLAGS
2324
2325 Receives a message on a socket.  Attempts to receive LENGTH bytes of
2326 data into variable SCALAR from the specified SOCKET filehandle.
2327 Actually does a C recvfrom(), so that it can returns the address of the
2328 sender.  Returns the undefined value if there's an error.  SCALAR will
2329 be grown or shrunk to the length actually read.  Takes the same flags
2330 as the system call of the same name.  
2331 See L<perlipc/"UDP: Message Passing"> for examples.
2332
2333 =item redo LABEL
2334
2335 =item redo
2336
2337 The C<redo> command restarts the loop block without evaluating the
2338 conditional again.  The C<continue> block, if any, is not executed.  If
2339 the LABEL is omitted, the command refers to the innermost enclosing
2340 loop.  This command is normally used by programs that want to lie to
2341 themselves about what was just input:
2342
2343     # a simpleminded Pascal comment stripper
2344     # (warning: assumes no { or } in strings)
2345     LINE: while (<STDIN>) {
2346         while (s|({.*}.*){.*}|$1 |) {}
2347         s|{.*}| |;
2348         if (s|{.*| |) {
2349             $front = $_;
2350             while (<STDIN>) {
2351                 if (/}/) {      # end of comment?
2352                     s|^|$front{|;
2353                     redo LINE;
2354                 }
2355             }
2356         }
2357         print;
2358     }
2359
2360 =item ref EXPR
2361
2362 =item ref 
2363
2364 Returns a TRUE value if EXPR is a reference, FALSE otherwise. If EXPR
2365 is not specified, $_ will be used. The value returned depends on the
2366 type of thing the reference is a reference to.
2367 Builtin types include:
2368
2369     REF
2370     SCALAR
2371     ARRAY
2372     HASH
2373     CODE
2374     GLOB
2375
2376 If the referenced object has been blessed into a package, then that package 
2377 name is returned instead.  You can think of ref() as a typeof() operator.
2378
2379     if (ref($r) eq "HASH") {
2380         print "r is a reference to an associative array.\n";
2381     } 
2382     if (!ref ($r) {
2383         print "r is not a reference at all.\n";
2384     } 
2385
2386 See also L<perlref>.
2387
2388 =item rename OLDNAME,NEWNAME
2389
2390 Changes the name of a file.  Returns 1 for success, 0 otherwise.  Will
2391 not work across file system boundaries.
2392
2393 =item require EXPR
2394
2395 =item require
2396
2397 Demands some semantics specified by EXPR, or by $_ if EXPR is not
2398 supplied.  If EXPR is numeric, demands that the current version of Perl
2399 (C<$]> or $PERL_VERSION) be equal or greater than EXPR.
2400
2401 Otherwise, demands that a library file be included if it hasn't already
2402 been included.  The file is included via the do-FILE mechanism, which is
2403 essentially just a variety of eval().  Has semantics similar to the following
2404 subroutine:
2405
2406     sub require {
2407         local($filename) = @_;
2408         return 1 if $INC{$filename};
2409         local($realfilename,$result);
2410         ITER: {
2411             foreach $prefix (@INC) {
2412                 $realfilename = "$prefix/$filename";
2413                 if (-f $realfilename) {
2414                     $result = do $realfilename;
2415                     last ITER;
2416                 }
2417             }
2418             die "Can't find $filename in \@INC";
2419         }
2420         die $@ if $@;
2421         die "$filename did not return true value" unless $result;
2422         $INC{$filename} = $realfilename;
2423         $result;
2424     }
2425
2426 Note that the file will not be included twice under the same specified
2427 name.  The file must return TRUE as the last statement to indicate
2428 successful execution of any initialization code, so it's customary to
2429 end such a file with "1;" unless you're sure it'll return TRUE
2430 otherwise.  But it's better just to put the "C<1;>", in case you add more
2431 statements.
2432
2433 If EXPR is a bare word, the require assumes a "F<.pm>" extension and
2434 replaces "F<::>" with "F</>" in the filename for you,
2435 to make it easy to load standard modules.  This form of loading of 
2436 modules does not risk altering your namespace.
2437
2438 For a yet-more-powerful import facility, see L</use> and 
2439 L<perlmod>.
2440
2441 =item reset EXPR
2442
2443 =item reset
2444
2445 Generally used in a C<continue> block at the end of a loop to clear
2446 variables and reset ?? searches so that they work again.  The
2447 expression is interpreted as a list of single characters (hyphens
2448 allowed for ranges).  All variables and arrays beginning with one of
2449 those letters are reset to their pristine state.  If the expression is
2450 omitted, one-match searches (?pattern?) are reset to match again.  Resets
2451 only variables or searches in the current package.  Always returns
2452 1.  Examples:
2453
2454     reset 'X';          # reset all X variables
2455     reset 'a-z';        # reset lower case variables
2456     reset;              # just reset ?? searches
2457
2458 Resetting "A-Z" is not recommended because you'll wipe out your
2459 ARGV and ENV arrays.  Resets only package variables--lexical variables
2460 are unaffected, but they clean themselves up on scope exit anyway,
2461 so you'll probably want to use them instead.  See L</my>.
2462
2463 =item return LIST
2464
2465 Returns from a subroutine or eval with the value specified.  (Note that
2466 in the absence of a return a subroutine or eval() will automatically
2467 return the value of the last expression evaluated.)
2468
2469 =item reverse LIST
2470
2471 In a list context, returns a list value consisting of the elements
2472 of LIST in the opposite order.  In a scalar context, returns a string
2473 value consisting of the bytes of the first element of LIST in the
2474 opposite order.   
2475
2476     print reverse <>;                   # line tac 
2477
2478     undef $/;
2479     print scalar reverse scalar <>;     # byte tac
2480
2481 =item rewinddir DIRHANDLE
2482
2483 Sets the current position to the beginning of the directory for the
2484 readdir() routine on DIRHANDLE.
2485
2486 =item rindex STR,SUBSTR,POSITION
2487
2488 =item rindex STR,SUBSTR
2489
2490 Works just like index except that it returns the position of the LAST
2491 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
2492 last occurrence at or before that position.
2493
2494 =item rmdir FILENAME
2495
2496 =item rmdir 
2497
2498 Deletes the directory specified by FILENAME if it is empty.  If it
2499 succeeds it returns 1, otherwise it returns 0 and sets C<$!> (errno).  If
2500 FILENAME is omitted, uses $_.
2501
2502 =item s///
2503
2504 The substitution operator.  See L<perlop>.
2505
2506 =item scalar EXPR
2507
2508 Forces EXPR to be interpreted in a scalar context and returns the value
2509 of EXPR.  
2510
2511     @counts = ( scalar @a, scalar @b, scalar @c );
2512
2513 There is no equivalent operator to force an expression to 
2514 be interpolated in a list context because it's in practice never
2515 needed.  If you really wanted to do so, however, you could use
2516 the construction C<@{[ (some expression) ]}>, but usually a simple
2517 C<(some expression)> suffices.
2518
2519 =item seek FILEHANDLE,POSITION,WHENCE
2520
2521 Randomly positions the file pointer for FILEHANDLE, just like the fseek()
2522 call of stdio.  FILEHANDLE may be an expression whose value gives the name
2523 of the filehandle.  The values for WHENCE are 0 to set the file pointer to
2524 POSITION, 1 to set the it to current plus POSITION, and 2 to set it to EOF
2525 plus offset.  You may use the values SEEK_SET, SEEK_CUR, and SEEK_END for
2526 this from POSIX module.  Returns 1 upon success, 0 otherwise.
2527
2528 On some systems you have to do a seek whenever you switch between reading
2529 and writing.  Amongst other things, this may have the effect of calling
2530 stdio's clearerr(3).  A "whence" of 1 (SEEK_CUR) is useful for not moving
2531 the file pointer:
2532
2533     seek(TEST,0,1);
2534
2535 This is also useful for applications emulating C<tail -f>.  Once you hit
2536 EOF on your read, and then sleep for a while, you might have to stick in a
2537 seek() to reset things.  First the simple trick listed above to clear the
2538 filepointer.  The seek() doesn't change the current position, but it
2539 I<does> clear the end-of-file condition on the handle, so that the next
2540 C<E<lt>FILEE<gt>> makes Perl try again to read something.  We hope.
2541
2542 If that doesn't work (some stdios are particularly cantankerous), then
2543 you may need something more like this:
2544
2545     for (;;) {
2546         for ($curpos = tell(FILE); $_ = <FILE>; $curpos = tell(FILE)) {
2547             # search for some stuff and put it into files
2548         }
2549         sleep($for_a_while);
2550         seek(FILE, $curpos, 0);
2551     }
2552
2553 =item seekdir DIRHANDLE,POS
2554
2555 Sets the current position for the readdir() routine on DIRHANDLE.  POS
2556 must be a value returned by telldir().  Has the same caveats about
2557 possible directory compaction as the corresponding system library
2558 routine.
2559
2560 =item select FILEHANDLE
2561
2562 =item select
2563
2564 Returns the currently selected filehandle.  Sets the current default
2565 filehandle for output, if FILEHANDLE is supplied.  This has two
2566 effects: first, a C<write> or a C<print> without a filehandle will
2567 default to this FILEHANDLE.  Second, references to variables related to
2568 output will refer to this output channel.  For example, if you have to
2569 set the top of form format for more than one output channel, you might
2570 do the following:
2571
2572     select(REPORT1);
2573     $^ = 'report1_top';
2574     select(REPORT2);
2575     $^ = 'report2_top';
2576
2577 FILEHANDLE may be an expression whose value gives the name of the
2578 actual filehandle.  Thus:
2579
2580     $oldfh = select(STDERR); $| = 1; select($oldfh);
2581
2582 Some programmers may prefer to think of filehandles as objects with
2583 methods, preferring to write the last example as:
2584
2585     use IO::Handle;
2586     STDERR->autoflush(1);
2587
2588 =item select RBITS,WBITS,EBITS,TIMEOUT
2589
2590 This calls the select(2) system call with the bit masks specified, which
2591 can be constructed using fileno() and vec(), along these lines:
2592
2593     $rin = $win = $ein = '';
2594     vec($rin,fileno(STDIN),1) = 1;
2595     vec($win,fileno(STDOUT),1) = 1;
2596     $ein = $rin | $win;
2597
2598 If you want to select on many filehandles you might wish to write a
2599 subroutine:
2600
2601     sub fhbits {
2602         local(@fhlist) = split(' ',$_[0]);
2603         local($bits);
2604         for (@fhlist) {
2605             vec($bits,fileno($_),1) = 1;
2606         }
2607         $bits;
2608     }
2609     $rin = fhbits('STDIN TTY SOCK');
2610
2611 The usual idiom is:
2612
2613     ($nfound,$timeleft) =
2614       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
2615
2616 or to block until something becomes ready just do this 
2617
2618     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
2619
2620 Most systems do not bother to return anything useful in $timeleft, so
2621 calling select() in a scalar context just returns $nfound.
2622
2623 Any of the bit masks can also be undef.  The timeout, if specified, is
2624 in seconds, which may be fractional.  Note: not all implementations are
2625 capable of returning the $timeleft.  If not, they always return
2626 $timeleft equal to the supplied $timeout.
2627
2628 You can effect a sleep of 250 milliseconds this way:
2629
2630     select(undef, undef, undef, 0.25);
2631
2632 B<WARNING>: Do not attempt to mix buffered I/O (like read() or E<lt>FHE<gt>)
2633 with select().  You have to use sysread() instead.
2634
2635 =item semctl ID,SEMNUM,CMD,ARG
2636
2637 Calls the System V IPC function semctl.  If CMD is &IPC_STAT or
2638 &GETALL, then ARG must be a variable which will hold the returned
2639 semid_ds structure or semaphore value array.  Returns like ioctl: the
2640 undefined value for error, "0 but true" for zero, or the actual return
2641 value otherwise.
2642
2643 =item semget KEY,NSEMS,FLAGS
2644
2645 Calls the System V IPC function semget.  Returns the semaphore id, or
2646 the undefined value if there is an error.
2647
2648 =item semop KEY,OPSTRING
2649
2650 Calls the System V IPC function semop to perform semaphore operations
2651 such as signaling and waiting.  OPSTRING must be a packed array of
2652 semop structures.  Each semop structure can be generated with
2653 C<pack("sss", $semnum, $semop, $semflag)>.  The number of semaphore
2654 operations is implied by the length of OPSTRING.  Returns TRUE if
2655 successful, or FALSE if there is an error.  As an example, the
2656 following code waits on semaphore $semnum of semaphore id $semid:
2657
2658     $semop = pack("sss", $semnum, -1, 0);
2659     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
2660
2661 To signal the semaphore, replace "-1" with "1".
2662
2663 =item send SOCKET,MSG,FLAGS,TO
2664
2665 =item send SOCKET,MSG,FLAGS
2666
2667 Sends a message on a socket.  Takes the same flags as the system call
2668 of the same name.  On unconnected sockets you must specify a
2669 destination to send TO, in which case it does a C sendto().  Returns
2670 the number of characters sent, or the undefined value if there is an
2671 error.
2672 See L<perlipc/"UDP: Message Passing"> for examples.
2673
2674 =item setpgrp PID,PGRP
2675
2676 Sets the current process group for the specified PID, 0 for the current
2677 process.  Will produce a fatal error if used on a machine that doesn't
2678 implement setpgrp(2).  If the arguments are omitted, it defaults to
2679 0,0.  Note that the POSIX version of setpgrp() does not accept any
2680 arguments, so only setpgrp 0,0 is portable.
2681
2682 =item setpriority WHICH,WHO,PRIORITY
2683
2684 Sets the current priority for a process, a process group, or a user.
2685 (See setpriority(2).)  Will produce a fatal error if used on a machine
2686 that doesn't implement setpriority(2).
2687
2688 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
2689
2690 Sets the socket option requested.  Returns undefined if there is an
2691 error.  OPTVAL may be specified as undef if you don't want to pass an
2692 argument.
2693
2694 =item shift ARRAY
2695
2696 =item shift
2697
2698 Shifts the first value of the array off and returns it, shortening the
2699 array by 1 and moving everything down.  If there are no elements in the
2700 array, returns the undefined value.  If ARRAY is omitted, shifts the
2701 @ARGV array in the main program, and the @_ array in subroutines.
2702 (This is determined lexically.)  See also unshift(), push(), and pop().
2703 Shift() and unshift() do the same thing to the left end of an array
2704 that push() and pop() do to the right end.
2705
2706 =item shmctl ID,CMD,ARG
2707
2708 Calls the System V IPC function shmctl.  If CMD is &IPC_STAT, then ARG
2709 must be a variable which will hold the returned shmid_ds structure.
2710 Returns like ioctl: the undefined value for error, "0 but true" for
2711 zero, or the actual return value otherwise.
2712
2713 =item shmget KEY,SIZE,FLAGS
2714
2715 Calls the System V IPC function shmget.  Returns the shared memory
2716 segment id, or the undefined value if there is an error.
2717
2718 =item shmread ID,VAR,POS,SIZE
2719
2720 =item shmwrite ID,STRING,POS,SIZE
2721
2722 Reads or writes the System V shared memory segment ID starting at
2723 position POS for size SIZE by attaching to it, copying in/out, and
2724 detaching from it.  When reading, VAR must be a variable which will
2725 hold the data read.  When writing, if STRING is too long, only SIZE
2726 bytes are used; if STRING is too short, nulls are written to fill out
2727 SIZE bytes.  Return TRUE if successful, or FALSE if there is an error.
2728
2729 =item shutdown SOCKET,HOW
2730
2731 Shuts down a socket connection in the manner indicated by HOW, which
2732 has the same interpretation as in the system call of the same name.
2733
2734 =item sin EXPR
2735
2736 =item sin 
2737
2738 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
2739 returns sine of $_.
2740
2741 For the inverse sine operation, you may use the POSIX::sin()
2742 function, or use this relation:
2743
2744     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
2745
2746 =item sleep EXPR
2747
2748 =item sleep
2749
2750 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
2751 May be interrupted by sending the process a SIGALRM.  Returns the
2752 number of seconds actually slept.  You probably cannot mix alarm() and
2753 sleep() calls, because sleep() is often implemented using alarm().
2754
2755 On some older systems, it may sleep up to a full second less than what
2756 you requested, depending on how it counts seconds.  Most modern systems
2757 always sleep the full amount.
2758
2759 For delays of finer granularity than one second, you may use Perl's
2760 syscall() interface to access setitimer(2) if your system supports it, 
2761 or else see L</select()> below.  
2762
2763 See also the POSIX module's sigpause() function.
2764
2765 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
2766
2767 Opens a socket of the specified kind and attaches it to filehandle
2768 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for the
2769 system call of the same name.  You should "use Socket;" first to get
2770 the proper definitions imported.  See the example in L<perlipc/"Sockets: Client/Server Communication">.
2771
2772 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
2773
2774 Creates an unnamed pair of sockets in the specified domain, of the
2775 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
2776 for the system call of the same name.  If unimplemented, yields a fatal
2777 error.  Returns TRUE if successful.
2778
2779 =item sort SUBNAME LIST
2780
2781 =item sort BLOCK LIST
2782
2783 =item sort LIST
2784
2785 Sorts the LIST and returns the sorted list value.  Nonexistent values
2786 of arrays are stripped out.  If SUBNAME or BLOCK is omitted, sorts
2787 in standard string comparison order.  If SUBNAME is specified, it
2788 gives the name of a subroutine that returns an integer less than, equal
2789 to, or greater than 0, depending on how the elements of the array are
2790 to be ordered.  (The E<lt>=E<gt> and cmp operators are extremely useful in such
2791 routines.)  SUBNAME may be a scalar variable name, in which case the
2792 value provides the name of the subroutine to use.  In place of a
2793 SUBNAME, you can provide a BLOCK as an anonymous, in-line sort
2794 subroutine.
2795
2796 In the interests of efficiency the normal calling code for subroutines is
2797 bypassed, with the following effects: the subroutine may not be a
2798 recursive subroutine, and the two elements to be compared are passed into
2799 the subroutine not via @_ but as the package global variables $a and
2800 $b (see example below).  They are passed by reference, so don't
2801 modify $a and $b.  And don't try to declare them as lexicals either.
2802
2803 You also cannot exit out of the sort block or subroutine using any of the
2804 loop control operators described in L<perlsyn> or with goto().
2805
2806 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
2807 current collation locale.  See L<perllocale>.
2808
2809 Examples:
2810
2811     # sort lexically
2812     @articles = sort @files;
2813
2814     # same thing, but with explicit sort routine
2815     @articles = sort {$a cmp $b} @files;
2816
2817     # now case-insensitively
2818     @articles = sort { uc($a) cmp uc($b)} @files;
2819
2820     # same thing in reversed order
2821     @articles = sort {$b cmp $a} @files;
2822
2823     # sort numerically ascending
2824     @articles = sort {$a <=> $b} @files;
2825
2826     # sort numerically descending
2827     @articles = sort {$b <=> $a} @files;
2828
2829     # sort using explicit subroutine name
2830     sub byage {
2831         $age{$a} <=> $age{$b};  # presuming integers
2832     }
2833     @sortedclass = sort byage @class;
2834
2835     # this sorts the %age associative arrays by value 
2836     # instead of key using an in-line function
2837     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
2838
2839     sub backwards { $b cmp $a; }
2840     @harry = ('dog','cat','x','Cain','Abel');
2841     @george = ('gone','chased','yz','Punished','Axed');
2842     print sort @harry;
2843             # prints AbelCaincatdogx
2844     print sort backwards @harry;
2845             # prints xdogcatCainAbel
2846     print sort @george, 'to', @harry;
2847             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
2848
2849     # inefficiently sort by descending numeric compare using 
2850     # the first integer after the first = sign, or the 
2851     # whole record case-insensitively otherwise
2852
2853     @new = sort {
2854         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
2855                             ||
2856                     uc($a)  cmp  uc($b)
2857     } @old;
2858
2859     # same thing, but much more efficiently;
2860     # we'll build auxiliary indices instead
2861     # for speed
2862     @nums = @caps = ();
2863     for (@old) { 
2864         push @nums, /=(\d+)/;
2865         push @caps, uc($_);
2866     } 
2867
2868     @new = @old[ sort {
2869                         $nums[$b] <=> $nums[$a]
2870                                  ||
2871                         $caps[$a] cmp $caps[$b]
2872                        } 0..$#old
2873                ];
2874
2875     # same thing using a Schwartzian Transform (no temps)
2876     @new = map { $_->[0] }
2877         sort { $b->[1] <=> $a->[1]
2878                         ||
2879                $a->[2] cmp $b->[2]
2880         } map { [$_, /=(\d+)/, uc($_)] } @old;
2881
2882 If you're using strict, you I<MUST NOT> declare $a
2883 and $b as lexicals.  They are package globals.  That means
2884 if you're in the C<main> package, it's
2885
2886     @articles = sort {$main::b <=> $main::a} @files;
2887
2888 or just
2889
2890     @articles = sort {$::b <=> $::a} @files;
2891
2892 but if you're in the C<FooPack> package, it's
2893
2894     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
2895
2896 The comparison function is required to behave.  If it returns
2897 inconsistent results (sometimes saying $x[1] is less than $x[2] and
2898 sometimes saying the opposite, for example) the Perl interpreter will
2899 probably crash and dump core.  This is entirely due to and dependent
2900 upon your system's qsort(3) library routine; this routine often avoids
2901 sanity checks in the interest of speed.
2902
2903 =item splice ARRAY,OFFSET,LENGTH,LIST
2904
2905 =item splice ARRAY,OFFSET,LENGTH
2906
2907 =item splice ARRAY,OFFSET
2908
2909 Removes the elements designated by OFFSET and LENGTH from an array, and
2910 replaces them with the elements of LIST, if any.  Returns the elements
2911 removed from the array.  The array grows or shrinks as necessary.  If
2912 LENGTH is omitted, removes everything from OFFSET onward.  The
2913 following equivalences hold (assuming C<$[ == 0>):
2914
2915     push(@a,$x,$y)      splice(@a,$#a+1,0,$x,$y)
2916     pop(@a)             splice(@a,-1)
2917     shift(@a)           splice(@a,0,1)
2918     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
2919     $a[$x] = $y         splice(@a,$x,1,$y);
2920
2921 Example, assuming array lengths are passed before arrays:
2922
2923     sub aeq {   # compare two list values
2924         local(@a) = splice(@_,0,shift);
2925         local(@b) = splice(@_,0,shift);
2926         return 0 unless @a == @b;       # same len?
2927         while (@a) {
2928             return 0 if pop(@a) ne pop(@b);
2929         }
2930         return 1;
2931     }
2932     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
2933
2934 =item split /PATTERN/,EXPR,LIMIT
2935
2936 =item split /PATTERN/,EXPR
2937
2938 =item split /PATTERN/
2939
2940 =item split
2941
2942 Splits a string into an array of strings, and returns it.
2943
2944 If not in a list context, returns the number of fields found and splits into
2945 the @_ array.  (In a list context, you can force the split into @_ by
2946 using C<??> as the pattern delimiters, but it still returns the array
2947 value.)  The use of implicit split to @_ is deprecated, however.
2948
2949 If EXPR is omitted, splits the $_ string.  If PATTERN is also omitted,
2950 splits on whitespace (after skipping any leading whitespace).  Anything
2951 matching PATTERN is taken to be a delimiter separating the fields.  (Note
2952 that the delimiter may be longer than one character.)  If LIMIT is
2953 specified and is not negative, splits into no more than that many fields
2954 (though it may split into fewer).  If LIMIT is unspecified, trailing null
2955 fields are stripped (which potential users of pop() would do well to
2956 remember).  If LIMIT is negative, it is treated as if an arbitrarily large
2957 LIMIT had been specified.
2958
2959 A pattern matching the null string (not to be confused with
2960 a null pattern C<//>, which is just one member of the set of patterns
2961 matching a null string) will split the value of EXPR into separate
2962 characters at each point it matches that way.  For example:
2963
2964     print join(':', split(/ */, 'hi there'));
2965
2966 produces the output 'h:i:t:h:e:r:e'.
2967
2968 The LIMIT parameter can be used to split a line partially
2969
2970     ($login, $passwd, $remainder) = split(/:/, $_, 3);
2971
2972 When assigning to a list, if LIMIT is omitted, Perl supplies a LIMIT
2973 one larger than the number of variables in the list, to avoid
2974 unnecessary work.  For the list above LIMIT would have been 4 by
2975 default.  In time critical applications it behooves you not to split
2976 into more fields than you really need.
2977
2978 If the PATTERN contains parentheses, additional array elements are
2979 created from each matching substring in the delimiter.
2980
2981     split(/([,-])/, "1-10,20", 3);
2982
2983 produces the list value
2984
2985     (1, '-', 10, ',', 20)
2986
2987 If you had the entire header of a normal Unix email message in $header, 
2988 you could split it up into fields and their values this way:
2989
2990     $header =~ s/\n\s+/ /g;  # fix continuation lines
2991     %hdrs   =  (UNIX_FROM => split /^(.*?):\s*/m, $header);
2992
2993 The pattern C</PATTERN/> may be replaced with an expression to specify
2994 patterns that vary at runtime.  (To do runtime compilation only once,
2995 use C</$variable/o>.)
2996
2997 As a special case, specifying a PATTERN of space (C<' '>) will split on
2998 white space just as split with no arguments does.  Thus, split(' ') can
2999 be used to emulate B<awk>'s default behavior, whereas C<split(/ /)>
3000 will give you as many null initial fields as there are leading spaces.
3001 A split on /\s+/ is like a split(' ') except that any leading
3002 whitespace produces a null first field.  A split with no arguments
3003 really does a C<split(' ', $_)> internally.
3004
3005 Example:
3006
3007     open(passwd, '/etc/passwd');
3008     while (<passwd>) {
3009         ($login, $passwd, $uid, $gid, $gcos, 
3010             $home, $shell) = split(/:/);
3011         ...
3012     }
3013
3014 (Note that $shell above will still have a newline on it.  See L</chop>, 
3015 L</chomp>, and L</join>.)
3016
3017 =item sprintf FORMAT, LIST
3018
3019 Returns a string formatted by the usual printf conventions of the C
3020 language.  See L<sprintf(3)> or L<printf(3)> on your system for details.
3021 (The * character for an indirectly specified length is not
3022 supported, but you can get the same effect by interpolating a variable
3023 into the pattern.)  If C<use locale> is
3024 in effect, the character used for the decimal point in formatted real numbers
3025 is affected by the LC_NUMERIC locale.  See L<perllocale>.
3026 Some C libraries' implementations of sprintf() can
3027 dump core when fed ludicrous arguments.
3028
3029 =item sqrt EXPR
3030
3031 =item sqrt 
3032
3033 Return the square root of EXPR.  If EXPR is omitted, returns square
3034 root of $_.
3035
3036 =item srand EXPR
3037
3038 Sets the random number seed for the C<rand> operator.  If EXPR is omitted,
3039 uses a semi-random value based on the current time and process ID, among
3040 other things.  In versions of Perl prior to 5.004 the default seed was
3041 just the current time().  This isn't a particularly good seed, so many
3042 old programs supply their own seed value (often C<time ^ $$> or C<time ^
3043 ($$ + ($$ << 15))>), but that isn't necessary any more.
3044
3045 You need something much more random than the default seed for
3046 cryptographic purposes, though.  Checksumming the compressed output of
3047 one or more rapidly changing operating system status programs is the
3048 usual method. For example:
3049
3050     srand (time ^ $$ ^ unpack "%L*", `ps axww | gzip`);
3051
3052 If you're particularly concerned with this, see the Math::TrulyRandom
3053 module in CPAN.
3054
3055 Do I<not> call srand() multiple times in your program unless you know
3056 exactly what you're doing and why you're doing it.  The point of the
3057 function is to "seed" the rand() function so that rand() can produce
3058 a different sequence each time you run your program.  Just do it once at the
3059 top of your program, or you I<won't> get random numbers out of rand()!
3060
3061 Frequently called programs (like CGI scripts) that simply use 
3062
3063     time ^ $$
3064
3065 for a seed can fall prey to the mathematical property that 
3066
3067     a^b == (a+1)^(b+1)
3068
3069 one-third of the time.  So don't do that.
3070
3071 =item stat FILEHANDLE
3072
3073 =item stat EXPR
3074
3075 =item stat 
3076
3077 Returns a 13-element array giving the status info for a file, either the
3078 file opened via FILEHANDLE, or named by EXPR. If EXPR is omitted, it
3079 stats $_.  Returns a null list if the stat fails.  Typically used as
3080 follows:
3081
3082
3083     ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
3084        $atime,$mtime,$ctime,$blksize,$blocks)
3085            = stat($filename);
3086
3087 Not all fields are supported on all filesystem types.  Here are the 
3088 meaning of the fields:
3089
3090   dev       device number of filesystem 
3091   ino       inode number 
3092   mode      file mode  (type and permissions)
3093   nlink     number of (hard) links to the file 
3094   uid       numeric user ID of file's owner 
3095   gid       numeric group ID of file's owner 
3096   rdev      the device identifier (special files only)
3097   size      total size of file, in bytes 
3098   atime     last access time since the epoch
3099   mtime     last modify time since the epoch
3100   ctime     inode change time (NOT creation time!) since the epoch
3101   blksize   preferred block size for file system I/O
3102   blocks    actual number of blocks allocated
3103
3104 (The epoch was at 00:00 January 1, 1970 GMT.)
3105
3106 If stat is passed the special filehandle consisting of an underline, no
3107 stat is done, but the current contents of the stat structure from the
3108 last stat or filetest are returned.  Example:
3109
3110     if (-x $file && (($d) = stat(_)) && $d < 0) {
3111         print "$file is executable NFS file\n";
3112     }
3113
3114 (This works on machines only for which the device number is negative under NFS.)
3115
3116 =item study SCALAR
3117
3118 =item study
3119
3120 Takes extra time to study SCALAR (C<$_> if unspecified) in anticipation of
3121 doing many pattern matches on the string before it is next modified.
3122 This may or may not save time, depending on the nature and number of
3123 patterns you are searching on, and on the distribution of character
3124 frequencies in the string to be searched--you probably want to compare
3125 run times with and without it to see which runs faster.  Those loops
3126 which scan for many short constant strings (including the constant
3127 parts of more complex patterns) will benefit most.  You may have only
3128 one study active at a time--if you study a different scalar the first
3129 is "unstudied".  (The way study works is this: a linked list of every
3130 character in the string to be searched is made, so we know, for
3131 example, where all the 'k' characters are.  From each search string,
3132 the rarest character is selected, based on some static frequency tables
3133 constructed from some C programs and English text.  Only those places
3134 that contain this "rarest" character are examined.)
3135
3136 For example, here is a loop which inserts index producing entries
3137 before any line containing a certain pattern:
3138
3139     while (<>) {
3140         study;
3141         print ".IX foo\n" if /\bfoo\b/;
3142         print ".IX bar\n" if /\bbar\b/;
3143         print ".IX blurfl\n" if /\bblurfl\b/;
3144         ...
3145         print;
3146     }
3147
3148 In searching for /\bfoo\b/, only those locations in $_ that contain "f"
3149 will be looked at, because "f" is rarer than "o".  In general, this is
3150 a big win except in pathological cases.  The only question is whether
3151 it saves you more time than it took to build the linked list in the
3152 first place.
3153
3154 Note that if you have to look for strings that you don't know till
3155 runtime, you can build an entire loop as a string and eval that to
3156 avoid recompiling all your patterns all the time.  Together with
3157 undefining $/ to input entire files as one record, this can be very
3158 fast, often faster than specialized programs like fgrep(1).  The following
3159 scans a list of files (C<@files>) for a list of words (C<@words>), and prints
3160 out the names of those files that contain a match:
3161
3162     $search = 'while (<>) { study;';
3163     foreach $word (@words) {
3164         $search .= "++\$seen{\$ARGV} if /\\b$word\\b/;\n";
3165     }
3166     $search .= "}";
3167     @ARGV = @files;
3168     undef $/;
3169     eval $search;               # this screams
3170     $/ = "\n";          # put back to normal input delimiter
3171     foreach $file (sort keys(%seen)) {
3172         print $file, "\n";
3173     }
3174
3175 =item sub BLOCK
3176
3177 =item sub NAME
3178
3179 =item sub NAME BLOCK
3180
3181 This is subroutine definition, not a real function I<per se>.  With just a
3182 NAME (and possibly prototypes), it's just a forward declaration.  Without
3183 a NAME, it's an anonymous function declaration, and does actually return a
3184 value: the CODE ref of the closure you just created. See L<perlsub> and
3185 L<perlref> for details.
3186
3187 =item substr EXPR,OFFSET,LEN
3188
3189 =item substr EXPR,OFFSET
3190
3191 Extracts a substring out of EXPR and returns it.  First character is at
3192 offset 0, or whatever you've set $[ to.  If OFFSET is negative, starts
3193 that far from the end of the string.  If LEN is omitted, returns
3194 everything to the end of the string.  If LEN is negative, leaves that
3195 many characters off the end of the string.
3196
3197 You can use the substr() function
3198 as an lvalue, in which case EXPR must be an lvalue.  If you assign
3199 something shorter than LEN, the string will shrink, and if you assign
3200 something longer than LEN, the string will grow to accommodate it.  To
3201 keep the string the same length you may need to pad or chop your value
3202 using sprintf().
3203
3204 =item symlink OLDFILE,NEWFILE
3205
3206 Creates a new filename symbolically linked to the old filename.
3207 Returns 1 for success, 0 otherwise.  On systems that don't support
3208 symbolic links, produces a fatal error at run time.  To check for that,
3209 use eval:
3210
3211     $symlink_exists = (eval 'symlink("","");', $@ eq '');
3212
3213 =item syscall LIST
3214
3215 Calls the system call specified as the first element of the list,
3216 passing the remaining elements as arguments to the system call.  If
3217 unimplemented, produces a fatal error.  The arguments are interpreted
3218 as follows: if a given argument is numeric, the argument is passed as
3219 an int.  If not, the pointer to the string value is passed.  You are
3220 responsible to make sure a string is pre-extended long enough to
3221 receive any result that might be written into a string.  If your
3222 integer arguments are not literals and have never been interpreted in a
3223 numeric context, you may need to add 0 to them to force them to look
3224 like numbers.
3225
3226     require 'syscall.ph';               # may need to run h2ph
3227     syscall(&SYS_write, fileno(STDOUT), "hi there\n", 9);
3228
3229 Note that Perl supports passing of up to only 14 arguments to your system call,
3230 which in practice should usually suffice.
3231
3232 =item sysopen FILEHANDLE,FILENAME,MODE
3233
3234 =item sysopen FILEHANDLE,FILENAME,MODE,PERMS
3235
3236 Opens the file whose filename is given by FILENAME, and associates it
3237 with FILEHANDLE.  If FILEHANDLE is an expression, its value is used as
3238 the name of the real filehandle wanted.  This function calls the
3239 underlying operating system's C<open> function with the parameters
3240 FILENAME, MODE, PERMS.
3241
3242 The possible values and flag bits of the MODE parameter are
3243 system-dependent; they are available via the standard module C<Fcntl>.
3244 However, for historical reasons, some values are universal: zero means
3245 read-only, one means write-only, and two means read/write.
3246
3247 If the file named by FILENAME does not exist and the C<open> call
3248 creates it (typically because MODE includes the O_CREAT flag), then
3249 the value of PERMS specifies the permissions of the newly created
3250 file.  If PERMS is omitted, the default value is 0666, which allows
3251 read and write for all.  This default is reasonable: see C<umask>.
3252
3253 The IO::File module provides a more object-oriented approach, if you're
3254 into that kind of thing.
3255
3256 =item sysread FILEHANDLE,SCALAR,LENGTH,OFFSET
3257
3258 =item sysread FILEHANDLE,SCALAR,LENGTH
3259
3260 Attempts to read LENGTH bytes of data into variable SCALAR from the
3261 specified FILEHANDLE, using the system call read(2).  It bypasses
3262 stdio, so mixing this with other kinds of reads may cause confusion.
3263 Returns the number of bytes actually read, or undef if there was an
3264 error.  SCALAR will be grown or shrunk so that the last byte actually
3265 read is the last byte of the scalar after the read.
3266
3267 An OFFSET may be specified to place the read data at some place in the
3268 string other than the beginning.  A negative OFFSET specifies
3269 placement at that many bytes counting backwards from the end of the
3270 string.  A positive OFFSET greater than the length of SCALAR results
3271 in the string being padded to the required size with "\0" bytes before
3272 the result of the read is appended.
3273
3274 =item system LIST
3275
3276 Does exactly the same thing as "exec LIST" except that a fork is done
3277 first, and the parent process waits for the child process to complete.
3278 Note that argument processing varies depending on the number of
3279 arguments.  The return value is the exit status of the program as
3280 returned by the wait() call.  To get the actual exit value divide by
3281 256.  See also L</exec>.  This is I<NOT> what you want to use to capture 
3282 the output from a command, for that you should use merely back-ticks or
3283 qx//, as described in L<perlop/"`STRING`">.
3284
3285 Because system() and back-ticks block SIGINT and SIGQUIT, killing the
3286 program they're running doesn't actually interrupt your program.
3287
3288     @args = ("command", "arg1", "arg2");
3289     system(@args) == 0 
3290          or die "system @args failed: $?" 
3291
3292 Here's a more elaborate example of analysing the return value from
3293 system() on a UNIX system to check for all possibilities, including for
3294 signals and coredumps.
3295
3296     $rc = 0xffff & system @args;
3297     printf "system(%s) returned %#04x: ", "@args", $rc;
3298     if ($rc == 0) {
3299         print "ran with normal exit\n";
3300     } 
3301     elsif ($rc == 0xff00) {
3302         print "command failed: $!\n";
3303     } 
3304     elsif ($rc > 0x80) {
3305         $rc >>= 8;
3306         print "ran with non-zero exit status $rc\n";
3307     } 
3308     else {
3309         print "ran with ";
3310         if ($rc &   0x80) {
3311             $rc &= ~0x80;
3312             print "coredump from ";
3313         } 
3314         print "signal $rc\n"
3315     } 
3316     $ok = ($rc != 0);
3317
3318 =item syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET
3319
3320 =item syswrite FILEHANDLE,SCALAR,LENGTH
3321
3322 Attempts to write LENGTH bytes of data from variable SCALAR to the
3323 specified FILEHANDLE, using the system call write(2).  It bypasses
3324 stdio, so mixing this with prints may cause confusion.  Returns the
3325 number of bytes actually written, or undef if there was an error.
3326 If the length is greater than the available data, only as much data as
3327 is available will be written.
3328
3329 An OFFSET may be specified to write the data from some part of the
3330 string other than the beginning.  A negative OFFSET specifies writing
3331 from that many bytes counting backwards from the end of the string.
3332
3333 =item tell FILEHANDLE
3334
3335 =item tell
3336
3337 Returns the current file position for FILEHANDLE.  FILEHANDLE may be an
3338 expression whose value gives the name of the actual filehandle.  If
3339 FILEHANDLE is omitted, assumes the file last read.
3340
3341 =item telldir DIRHANDLE
3342
3343 Returns the current position of the readdir() routines on DIRHANDLE.
3344 Value may be given to seekdir() to access a particular location in a
3345 directory.  Has the same caveats about possible directory compaction as
3346 the corresponding system library routine.
3347
3348 =item tie VARIABLE,CLASSNAME,LIST
3349
3350 This function binds a variable to a package class that will provide the
3351 implementation for the variable.  VARIABLE is the name of the variable
3352 to be enchanted.  CLASSNAME is the name of a class implementing objects
3353 of correct type.  Any additional arguments are passed to the "new"
3354 method of the class (meaning TIESCALAR, TIEARRAY, or TIEHASH).
3355 Typically these are arguments such as might be passed to the dbm_open()
3356 function of C.  The object returned by the "new" method is also
3357 returned by the tie() function, which would be useful if you want to
3358 access other methods in CLASSNAME.
3359
3360 Note that functions such as keys() and values() may return huge array
3361 values when used on large objects, like DBM files.  You may prefer to
3362 use the each() function to iterate over such.  Example:
3363
3364     # print out history file offsets
3365     use NDBM_File;
3366     tie(%HIST, 'NDBM_File', '/usr/lib/news/history', 1, 0);
3367     while (($key,$val) = each %HIST) {
3368         print $key, ' = ', unpack('L',$val), "\n";
3369     }
3370     untie(%HIST);
3371
3372 A class implementing an associative array should have the following
3373 methods:
3374
3375     TIEHASH classname, LIST
3376     DESTROY this
3377     FETCH this, key
3378     STORE this, key, value
3379     DELETE this, key
3380     EXISTS this, key
3381     FIRSTKEY this
3382     NEXTKEY this, lastkey
3383
3384 A class implementing an ordinary array should have the following methods:
3385
3386     TIEARRAY classname, LIST
3387     DESTROY this
3388     FETCH this, key
3389     STORE this, key, value
3390     [others TBD]
3391
3392 A class implementing a scalar should have the following methods:
3393
3394     TIESCALAR classname, LIST
3395     DESTROY this
3396     FETCH this, 
3397     STORE this, value
3398
3399 Unlike dbmopen(), the tie() function will not use or require a module
3400 for you--you need to do that explicitly yourself.  See L<DB_File>
3401 or the F<Config> module for interesting tie() implementations.
3402
3403 =item tied VARIABLE
3404
3405 Returns a reference to the object underlying VARIABLE (the same value
3406 that was originally returned by the tie() call which bound the variable
3407 to a package.)  Returns the undefined value if VARIABLE isn't tied to a
3408 package.
3409
3410 =item time
3411
3412 Returns the number of non-leap seconds since whatever time the system
3413 considers to be the epoch (that's 00:00:00, January 1, 1904 for MacOS,
3414 and 00:00:00 UTC, January 1, 1970 for most other systems).
3415 Suitable for feeding to gmtime() and localtime().
3416
3417 =item times
3418
3419 Returns a four-element array giving the user and system times, in
3420 seconds, for this process and the children of this process.
3421
3422     ($user,$system,$cuser,$csystem) = times;
3423
3424 =item tr///
3425
3426 The translation operator.  See L<perlop>.
3427
3428 =item truncate FILEHANDLE,LENGTH
3429
3430 =item truncate EXPR,LENGTH
3431
3432 Truncates the file opened on FILEHANDLE, or named by EXPR, to the
3433 specified length.  Produces a fatal error if truncate isn't implemented
3434 on your system.
3435
3436 =item uc EXPR
3437
3438 =item uc 
3439
3440 Returns an uppercased version of EXPR.  This is the internal function
3441 implementing the \U escape in double-quoted strings.
3442 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
3443
3444 If EXPR is omitted, uses $_.
3445
3446 =item ucfirst EXPR
3447
3448 =item ucfirst 
3449
3450 Returns the value of EXPR with the first character uppercased.  This is
3451 the internal function implementing the \u escape in double-quoted strings.
3452 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
3453
3454 If EXPR is omitted, uses $_.
3455
3456 =item umask EXPR
3457
3458 =item umask
3459
3460 Sets the umask for the process and returns the old one.  If EXPR is
3461 omitted, returns merely the current umask.
3462
3463 =item undef EXPR
3464
3465 =item undef
3466
3467 Undefines the value of EXPR, which must be an lvalue.  Use on only a
3468 scalar value, an entire array, or a subroutine name (using "&").  (Using undef()
3469 will probably not do what you expect on most predefined variables or
3470 DBM list values, so don't do that.)  Always returns the undefined value.  You can omit
3471 the EXPR, in which case nothing is undefined, but you still get an
3472 undefined value that you could, for instance, return from a
3473 subroutine.  Examples:
3474
3475     undef $foo;
3476     undef $bar{'blurfl'};
3477     undef @ary;
3478     undef %assoc;
3479     undef &mysub;
3480     return (wantarray ? () : undef) if $they_blew_it;
3481
3482 =item unlink LIST
3483
3484 =item unlink 
3485
3486 Deletes a list of files.  Returns the number of files successfully
3487 deleted.
3488
3489     $cnt = unlink 'a', 'b', 'c';
3490     unlink @goners;
3491     unlink <*.bak>;
3492
3493 Note: unlink will not delete directories unless you are superuser and
3494 the B<-U> flag is supplied to Perl.  Even if these conditions are
3495 met, be warned that unlinking a directory can inflict damage on your
3496 filesystem.  Use rmdir instead.
3497
3498 If LIST is omitted, uses $_.
3499
3500 =item unpack TEMPLATE,EXPR
3501
3502 Unpack does the reverse of pack: it takes a string representing a
3503 structure and expands it out into a list value, returning the array
3504 value.  (In a scalar context, it returns merely the first value
3505 produced.)  The TEMPLATE has the same format as in the pack function.
3506 Here's a subroutine that does substring:
3507
3508     sub substr {
3509         local($what,$where,$howmuch) = @_;
3510         unpack("x$where a$howmuch", $what);
3511     }
3512
3513 and then there's
3514
3515     sub ordinal { unpack("c",$_[0]); } # same as ord()
3516
3517 In addition, you may prefix a field with a %E<lt>numberE<gt> to indicate that
3518 you want a E<lt>numberE<gt>-bit checksum of the items instead of the items
3519 themselves.  Default is a 16-bit checksum.  For example, the following
3520 computes the same number as the System V sum program:
3521
3522     while (<>) {
3523         $checksum += unpack("%16C*", $_);
3524     }
3525     $checksum %= 65536;
3526
3527 The following efficiently counts the number of set bits in a bit vector:
3528
3529     $setbits = unpack("%32b*", $selectmask);
3530
3531 =item untie VARIABLE
3532
3533 Breaks the binding between a variable and a package.  (See tie().)
3534
3535 =item unshift ARRAY,LIST
3536
3537 Does the opposite of a C<shift>.  Or the opposite of a C<push>,
3538 depending on how you look at it.  Prepends list to the front of the
3539 array, and returns the new number of elements in the array.
3540
3541     unshift(ARGV, '-e') unless $ARGV[0] =~ /^-/;
3542
3543 Note the LIST is prepended whole, not one element at a time, so the
3544 prepended elements stay in the same order.  Use reverse to do the
3545 reverse.
3546
3547 =item use Module LIST
3548
3549 =item use Module
3550
3551 =item use Module VERSION LIST
3552
3553 =item use VERSION
3554
3555 Imports some semantics into the current package from the named module,
3556 generally by aliasing certain subroutine or variable names into your
3557 package.  It is exactly equivalent to
3558
3559     BEGIN { require Module; import Module LIST; }
3560
3561 except that Module I<must> be a bare word.
3562
3563 If the first argument to C<use> is a number, it is treated as a version
3564 number instead of a module name.  If the version of the Perl interpreter
3565 is less than VERSION, then an error message is printed and Perl exits
3566 immediately.  This is often useful if you need to check the current
3567 Perl version before C<use>ing library modules which have changed in
3568 incompatible ways from older versions of Perl.  (We try not to do
3569 this more than we have to.)
3570
3571 The BEGIN forces the require and import to happen at compile time.  The
3572 require makes sure the module is loaded into memory if it hasn't been
3573 yet.  The import is not a builtin--it's just an ordinary static method
3574 call into the "Module" package to tell the module to import the list of
3575 features back into the current package.  The module can implement its
3576 import method any way it likes, though most modules just choose to
3577 derive their import method via inheritance from the Exporter class that
3578 is defined in the Exporter module. See L<Exporter>.  If no import
3579 method can be found then the error is currently silently ignored. This
3580 may change to a fatal error in a future version.
3581
3582 If you don't want your namespace altered, explicitly supply an empty list:
3583
3584     use Module ();
3585
3586 That is exactly equivalent to
3587
3588     BEGIN { require Module; }
3589
3590 If the VERSION argument is present between Module and LIST, then the
3591 C<use> will call the VERSION method in class Module with the given
3592 version as an argument.  The default VERSION method, inherited from
3593 the Universal class, croaks if the given version is larger than the
3594 value of the variable $Module::VERSION.  (Note that there is not a
3595 comma after VERSION!)
3596
3597 Because this is a wide-open interface, pragmas (compiler directives)
3598 are also implemented this way.  Currently implemented pragmas are:
3599
3600     use integer;
3601     use diagnostics;
3602     use sigtrap qw(SEGV BUS);
3603     use strict  qw(subs vars refs);
3604     use subs    qw(afunc blurfl);
3605
3606 These pseudo-modules import semantics into the current block scope, unlike
3607 ordinary modules, which import symbols into the current package (which are
3608 effective through the end of the file).
3609
3610 There's a corresponding "no" command that unimports meanings imported
3611 by use, i.e., it calls C<unimport Module LIST> instead of C<import>.
3612
3613     no integer;
3614     no strict 'refs';
3615
3616 If no unimport method can be found the call fails with a fatal error.
3617
3618 See L<perlmod> for a list of standard modules and pragmas.
3619
3620 =item utime LIST
3621
3622 Changes the access and modification times on each file of a list of
3623 files.  The first two elements of the list must be the NUMERICAL access
3624 and modification times, in that order.  Returns the number of files
3625 successfully changed.  The inode modification time of each file is set
3626 to the current time.  Example of a "touch" command:
3627
3628     #!/usr/bin/perl
3629     $now = time;
3630     utime $now, $now, @ARGV;
3631
3632 =item values ASSOC_ARRAY
3633
3634 Returns a normal array consisting of all the values of the named
3635 associative array.  (In a scalar context, returns the number of
3636 values.)  The values are returned in an apparently random order, but it
3637 is the same order as either the keys() or each() function would produce
3638 on the same array.  See also keys(), each(), and sort().
3639
3640 =item vec EXPR,OFFSET,BITS
3641
3642 Treats the string in EXPR as a vector of unsigned integers, and
3643 returns the value of the bit field specified by OFFSET.  BITS specifies
3644 the number of bits that are reserved for each entry in the bit
3645 vector. This must be a power of two from 1 to 32. vec() may also be
3646 assigned to, in which case parentheses are needed to give the expression
3647 the correct precedence as in
3648
3649     vec($image, $max_x * $x + $y, 8) = 3;
3650
3651 Vectors created with vec() can also be manipulated with the logical
3652 operators |, &, and ^, which will assume a bit vector operation is
3653 desired when both operands are strings.
3654
3655 To transform a bit vector into a string or array of 0's and 1's, use these:
3656
3657     $bits = unpack("b*", $vector);
3658     @bits = split(//, unpack("b*", $vector));
3659
3660 If you know the exact length in bits, it can be used in place of the *.
3661
3662 =item wait
3663
3664 Waits for a child process to terminate and returns the pid of the
3665 deceased process, or -1 if there are no child processes.  The status is
3666 returned in C<$?>.
3667
3668 =item waitpid PID,FLAGS
3669
3670 Waits for a particular child process to terminate and returns the pid
3671 of the deceased process, or -1 if there is no such child process.  The
3672 status is returned in C<$?>.  If you say
3673
3674     use POSIX ":sys_wait_h";
3675     ...
3676     waitpid(-1,&WNOHANG);
3677
3678 then you can do a non-blocking wait for any process.  Non-blocking wait
3679 is available on machines supporting either the waitpid(2) or
3680 wait4(2) system calls.  However, waiting for a particular pid with
3681 FLAGS of 0 is implemented everywhere.  (Perl emulates the system call
3682 by remembering the status values of processes that have exited but have
3683 not been harvested by the Perl script yet.)
3684
3685 =item wantarray
3686
3687 Returns TRUE if the context of the currently executing subroutine is
3688 looking for a list value.  Returns FALSE if the context is looking
3689 for a scalar.
3690
3691     return wantarray ? () : undef;
3692
3693 =item warn LIST
3694
3695 Produces a message on STDERR just like die(), but doesn't exit or throw
3696 an exception.
3697
3698 No message is printed if there is a C<$SIG{__WARN__}> handler
3699 installed.  It is the handler's responsibility to deal with the message
3700 as it sees fit (like, for instance, converting it into a die()).  Most
3701 handlers must therefore make arrangements to actually display the
3702 warnings that they are not prepared to deal with, by calling warn()
3703 again in the handler.  Note that this is quite safe and will not
3704 produce an endless loop, since C<__WARN__> hooks are not called from
3705 inside one.
3706
3707 You will find this behavior is slightly different from that of
3708 C<$SIG{__DIE__}> handlers (which don't suppress the error text, but can
3709 instead call die() again to change it).
3710
3711 Using a C<__WARN__> handler provides a powerful way to silence all
3712 warnings (even the so-called mandatory ones).  An example:
3713
3714     # wipe out *all* compile-time warnings
3715     BEGIN { $SIG{'__WARN__'} = sub { warn $_[0] if $DOWARN } }
3716     my $foo = 10;
3717     my $foo = 20;          # no warning about duplicate my $foo,
3718                            # but hey, you asked for it!
3719     # no compile-time or run-time warnings before here
3720     $DOWARN = 1;
3721
3722     # run-time warnings enabled after here
3723     warn "\$foo is alive and $foo!";     # does show up
3724
3725 See L<perlvar> for details on setting C<%SIG> entries, and for more
3726 examples.
3727
3728 =item write FILEHANDLE
3729
3730 =item write EXPR
3731
3732 =item write
3733
3734 Writes a formatted record (possibly multi-line) to the specified file,
3735 using the format associated with that file.  By default the format for
3736 a file is the one having the same name is the filehandle, but the
3737 format for the current output channel (see the select() function) may be set
3738 explicitly by assigning the name of the format to the C<$~> variable.
3739
3740 Top of form processing is handled automatically:  if there is
3741 insufficient room on the current page for the formatted record, the
3742 page is advanced by writing a form feed, a special top-of-page format
3743 is used to format the new page header, and then the record is written.
3744 By default the top-of-page format is the name of the filehandle with
3745 "_TOP" appended, but it may be dynamically set to the format of your
3746 choice by assigning the name to the C<$^> variable while the filehandle is
3747 selected.  The number of lines remaining on the current page is in
3748 variable C<$->, which can be set to 0 to force a new page.
3749
3750 If FILEHANDLE is unspecified, output goes to the current default output
3751 channel, which starts out as STDOUT but may be changed by the
3752 C<select> operator.  If the FILEHANDLE is an EXPR, then the expression
3753 is evaluated and the resulting string is used to look up the name of
3754 the FILEHANDLE at run time.  For more on formats, see L<perlform>.
3755
3756 Note that write is I<NOT> the opposite of read.  Unfortunately.
3757
3758 =item y///
3759
3760 The translation operator.  See L<perlop>.
3761
3762 =back