This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
f830478d230bfe0568dd56f594e2c9a8d7186ce7
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 An named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<umask>,
140 C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<prototype>, C<qx>,
204 C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostent>,
228 C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<socket>, C<socketpair>, C<stat>, C<symlink>, C<syscall>,
238 C<sysopen>, C<system>, C<times>, C<truncate>, C<umask>, C<unlink>,
239 C<utime>, C<wait>, C<waitpid>
240
241 For more information about the portability of these functions, see
242 L<perlport> and other available platform-specific documentation.
243
244 =head2 Alphabetical Listing of Perl Functions
245
246 =over 8
247
248 =item I<-X> FILEHANDLE
249
250 =item I<-X> EXPR
251
252 =item I<-X>
253
254 A file test, where X is one of the letters listed below.  This unary
255 operator takes one argument, either a filename or a filehandle, and
256 tests the associated file to see if something is true about it.  If the
257 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
258 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
259 the undefined value if the file doesn't exist.  Despite the funny
260 names, precedence is the same as any other named unary operator, and
261 the argument may be parenthesized like any other unary operator.  The
262 operator may be any of:
263 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
264 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
265
266     -r  File is readable by effective uid/gid.
267     -w  File is writable by effective uid/gid.
268     -x  File is executable by effective uid/gid.
269     -o  File is owned by effective uid.
270
271     -R  File is readable by real uid/gid.
272     -W  File is writable by real uid/gid.
273     -X  File is executable by real uid/gid.
274     -O  File is owned by real uid.
275
276     -e  File exists.
277     -z  File has zero size.
278     -s  File has nonzero size (returns size).
279
280     -f  File is a plain file.
281     -d  File is a directory.
282     -l  File is a symbolic link.
283     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
284     -S  File is a socket.
285     -b  File is a block special file.
286     -c  File is a character special file.
287     -t  Filehandle is opened to a tty.
288
289     -u  File has setuid bit set.
290     -g  File has setgid bit set.
291     -k  File has sticky bit set.
292
293     -T  File is an ASCII text file.
294     -B  File is a "binary" file (opposite of -T).
295
296     -M  Age of file in days when script started.
297     -A  Same for access time.
298     -C  Same for inode change time.
299
300 Example:
301
302     while (<>) {
303         chop;
304         next unless -f $_;      # ignore specials
305         #...
306     }
307
308 The interpretation of the file permission operators C<-r>, C<-R>,
309 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
310 of the file and the uids and gids of the user.  There may be other
311 reasons you can't actually read, write, or execute the file.  Such
312 reasons may be for example network filesystem access controls, ACLs
313 (access control lists), read-only filesystems, and unrecognized
314 executable formats.
315
316 Also note that, for the superuser on the local filesystems, the C<-r>,
317 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
318 if any execute bit is set in the mode.  Scripts run by the superuser
319 may thus need to do a stat() to determine the actual mode of the file,
320 or temporarily set their effective uid to something else.
321
322 If you are using ACLs, there is a pragma called C<filetest> that may
323 produce more accurate results than the bare stat() mode bits.
324 When under the C<use filetest 'access'> the above-mentioned filetests
325 will test whether the permission can (not) be granted using the
326 access() family of system calls.  Also note that the C<-x> and C<-X> may
327 under this pragma return true even if there are no execute permission
328 bits set (nor any extra execute permission ACLs).  This strangeness is
329 due to the underlying system calls' definitions.  Read the
330 documentation for the C<filetest> pragma for more information.
331
332 Note that C<-s/a/b/> does not do a negated substitution.  Saying
333 C<-exp($foo)> still works as expected, however--only single letters
334 following a minus are interpreted as file tests.
335
336 The C<-T> and C<-B> switches work as follows.  The first block or so of the
337 file is examined for odd characters such as strange control codes or
338 characters with the high bit set.  If too many strange characters (E<gt>30%)
339 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
340 containing null in the first block is considered a binary file.  If C<-T>
341 or C<-B> is used on a filehandle, the current stdio buffer is examined
342 rather than the first block.  Both C<-T> and C<-B> return true on a null
343 file, or a file at EOF when testing a filehandle.  Because you have to
344 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
345 against the file first, as in C<next unless -f $file && -T $file>.
346
347 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
348 the special filehandle consisting of a solitary underline, then the stat
349 structure of the previous file test (or stat operator) is used, saving
350 a system call.  (This doesn't work with C<-t>, and you need to remember
351 that lstat() and C<-l> will leave values in the stat structure for the
352 symbolic link, not the real file.)  Example:
353
354     print "Can do.\n" if -r $a || -w _ || -x _;
355
356     stat($filename);
357     print "Readable\n" if -r _;
358     print "Writable\n" if -w _;
359     print "Executable\n" if -x _;
360     print "Setuid\n" if -u _;
361     print "Setgid\n" if -g _;
362     print "Sticky\n" if -k _;
363     print "Text\n" if -T _;
364     print "Binary\n" if -B _;
365
366 =item abs VALUE
367
368 =item abs
369
370 Returns the absolute value of its argument.
371 If VALUE is omitted, uses C<$_>.
372
373 =item accept NEWSOCKET,GENERICSOCKET
374
375 Accepts an incoming socket connect, just as the accept(2) system call
376 does.  Returns the packed address if it succeeded, false otherwise.
377 See the example in L<perlipc/"Sockets: Client/Server Communication">.
378
379 =item alarm SECONDS
380
381 =item alarm
382
383 Arranges to have a SIGALRM delivered to this process after the
384 specified number of seconds have elapsed.  If SECONDS is not specified,
385 the value stored in C<$_> is used. (On some machines,
386 unfortunately, the elapsed time may be up to one second less than you
387 specified because of how seconds are counted.)  Only one timer may be
388 counting at once.  Each call disables the previous timer, and an
389 argument of C<0> may be supplied to cancel the previous timer without
390 starting a new one.  The returned value is the amount of time remaining
391 on the previous timer.
392
393 For delays of finer granularity than one second, you may use Perl's
394 four-argument version of select() leaving the first three arguments
395 undefined, or you might be able to use the C<syscall> interface to
396 access setitimer(2) if your system supports it.  The Time::HiRes module
397 from CPAN may also prove useful.
398
399 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
400 (C<sleep> may be internally implemented in your system with C<alarm>)
401
402 If you want to use C<alarm> to time out a system call you need to use an
403 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
404 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
405 restart system calls on some systems.  Using C<eval>/C<die> always works,
406 modulo the caveats given in L<perlipc/"Signals">.
407
408     eval {
409         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
410         alarm $timeout;
411         $nread = sysread SOCKET, $buffer, $size;
412         alarm 0;
413     };
414     if ($@) {
415         die unless $@ eq "alarm\n";   # propagate unexpected errors
416         # timed out
417     }
418     else {
419         # didn't
420     }
421
422 =item atan2 Y,X
423
424 Returns the arctangent of Y/X in the range -PI to PI.
425
426 For the tangent operation, you may use the C<POSIX::tan()>
427 function, or use the familiar relation:
428
429     sub tan { sin($_[0]) / cos($_[0])  }
430
431 =item bind SOCKET,NAME
432
433 Binds a network address to a socket, just as the bind system call
434 does.  Returns true if it succeeded, false otherwise.  NAME should be a
435 packed address of the appropriate type for the socket.  See the examples in
436 L<perlipc/"Sockets: Client/Server Communication">.
437
438 =item binmode FILEHANDLE
439
440 Arranges for FILEHANDLE to be read or written in "binary" mode on
441 systems whose run-time libraries force the programmer to guess
442 between binary and text files.  If FILEHANDLE is an expression, the
443 value is taken as the name of the filehandle.  binmode() should be
444 called after the C<open> but before any I/O is done on the filehandle.
445 The only way to reset binary mode on a filehandle is to reopen the
446 file.
447
448 The operating system, device drivers, C libraries, and Perl run-time
449 system all conspire to let the programmer conveniently treat a
450 simple, one-byte C<\n> as the line terminator, irrespective of its
451 external representation.  On Unix and its brethren, the native file
452 representation exactly matches the internal representation, making
453 everyone's lives unbelievably simpler.  Consequently, L<binmode>
454 has no effect under Unix, Plan9, or Mac OS, all of which use C<\n>
455 to end each line.  (Unix and Plan9 think C<\n> means C<\cJ> and
456 C<\r> means C<\cM>, whereas the Mac goes the other way--it uses
457 C<\cM> for c<\n> and C<\cJ> to mean C<\r>.  But that's ok, because
458 it's only one byte, and the internal and external representations
459 match.)
460
461 In legacy systems like MS-DOS and its embellishments, your program
462 sees a C<\n> as a simple C<\cJ> (just as in Unix), but oddly enough,
463 that's not what's physically stored on disk.  What's worse, these
464 systems refuse to help you with this; it's up to you to remember
465 what to do.  And you mustn't go applying binmode() with wild abandon,
466 either, because if your system does care about binmode(), then using
467 it when you shouldn't is just as perilous as failing to use it when
468 you should.
469
470 That means that on any version of Microsoft WinXX that you might
471 care to name (or not), binmode() causes C<\cM\cJ> sequences on disk
472 to be converted to C<\n> when read into your program, and causes
473 any C<\n> in your program to be converted back to C<\cM\cJ> on
474 output to disk.  This sad discrepancy leads to no end of
475 problems in not just the readline operator, but also when using
476 seek(), tell(), and read() calls.  See L<perlport> for other painful
477 details.  See the C<$/> and C<$\> variables in L<perlvar> for how
478 to manually set your input and output line-termination sequences.
479
480 =item bless REF,CLASSNAME
481
482 =item bless REF
483
484 This function tells the thingy referenced by REF that it is now an object
485 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
486 is used.  Because a C<bless> is often the last thing in a constructor,
487 it returns the reference for convenience.  Always use the two-argument
488 version if the function doing the blessing might be inherited by a
489 derived class.  See L<perltoot> and L<perlobj> for more about the blessing
490 (and blessings) of objects.
491
492 Consider always blessing objects in CLASSNAMEs that are mixed case.
493 Namespaces with all lowercase names are considered reserved for
494 Perl pragmata.  Builtin types have all uppercase names, so to prevent
495 confusion, you may wish to avoid such package names as well.  Make sure
496 that CLASSNAME is a true value.
497
498 See L<perlmod/"Perl Modules">.
499
500 =item caller EXPR
501
502 =item caller
503
504 Returns the context of the current subroutine call.  In scalar context,
505 returns the caller's package name if there is a caller, that is, if
506 we're in a subroutine or C<eval> or C<require>, and the undefined value
507 otherwise.  In list context, returns
508
509     ($package, $filename, $line) = caller;
510
511 With EXPR, it returns some extra information that the debugger uses to
512 print a stack trace.  The value of EXPR indicates how many call frames
513 to go back before the current one.
514
515     ($package, $filename, $line, $subroutine, $hasargs,
516     $wantarray, $evaltext, $is_require, $hints) = caller($i);
517
518 Here $subroutine may be C<"(eval)"> if the frame is not a subroutine
519 call, but an C<eval>.  In such a case additional elements $evaltext and
520 C<$is_require> are set: C<$is_require> is true if the frame is created by a
521 C<require> or C<use> statement, $evaltext contains the text of the
522 C<eval EXPR> statement.  In particular, for a C<eval BLOCK> statement,
523 $filename is C<"(eval)">, but $evaltext is undefined.  (Note also that
524 each C<use> statement creates a C<require> frame inside an C<eval EXPR>)
525 frame.  C<$hints> contains pragmatic hints that the caller was
526 compiled with.  It currently only reflects the hint corresponding to
527 C<use utf8>.
528
529 Furthermore, when called from within the DB package, caller returns more
530 detailed information: it sets the list variable C<@DB::args> to be the
531 arguments with which the subroutine was invoked.
532
533 Be aware that the optimizer might have optimized call frames away before
534 C<caller> had a chance to get the information.  That means that C<caller(N)>
535 might not return information about the call frame you expect it do, for
536 C<N E<gt> 1>.  In particular, C<@DB::args> might have information from the 
537 previous time C<caller> was called.
538
539 =item chdir EXPR
540
541 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
542 changes to the user's home directory.  Returns true upon success,
543 false otherwise.  See the example under C<die>.
544
545 =item chmod LIST
546
547 Changes the permissions of a list of files.  The first element of the
548 list must be the numerical mode, which should probably be an octal
549 number, and which definitely should I<not> a string of octal digits:
550 C<0644> is okay, C<'0644'> is not.  Returns the number of files
551 successfully changed.  See also L</oct>, if all you have is a string.
552
553     $cnt = chmod 0755, 'foo', 'bar';
554     chmod 0755, @executables;
555     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
556                                              # --w----r-T
557     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
558     $mode = 0644;   chmod $mode, 'foo';      # this is best
559
560 =item chomp VARIABLE
561
562 =item chomp LIST
563
564 =item chomp
565
566 This safer version of L</chop> removes any trailing string
567 that corresponds to the current value of C<$/> (also known as
568 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
569 number of characters removed from all its arguments.  It's often used to
570 remove the newline from the end of an input record when you're worried
571 that the final record may be missing its newline.  When in paragraph
572 mode (C<$/ = "">), it removes all trailing newlines from the string.
573 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
574 a reference to an integer or the like, see L<perlvar>) chomp() won't
575 remove anything.  
576 If VARIABLE is omitted, it chomps C<$_>.  Example:
577
578     while (<>) {
579         chomp;  # avoid \n on last field
580         @array = split(/:/);
581         # ...
582     }
583
584 You can actually chomp anything that's an lvalue, including an assignment:
585
586     chomp($cwd = `pwd`);
587     chomp($answer = <STDIN>);
588
589 If you chomp a list, each element is chomped, and the total number of
590 characters removed is returned.
591
592 =item chop VARIABLE
593
594 =item chop LIST
595
596 =item chop
597
598 Chops off the last character of a string and returns the character
599 chopped.  It's used primarily to remove the newline from the end of an
600 input record, but is much more efficient than C<s/\n//> because it neither
601 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
602 Example:
603
604     while (<>) {
605         chop;   # avoid \n on last field
606         @array = split(/:/);
607         #...
608     }
609
610 You can actually chop anything that's an lvalue, including an assignment:
611
612     chop($cwd = `pwd`);
613     chop($answer = <STDIN>);
614
615 If you chop a list, each element is chopped.  Only the value of the
616 last C<chop> is returned.
617
618 Note that C<chop> returns the last character.  To return all but the last
619 character, use C<substr($string, 0, -1)>.
620
621 =item chown LIST
622
623 Changes the owner (and group) of a list of files.  The first two
624 elements of the list must be the I<numeric> uid and gid, in that
625 order.  A value of -1 in either position is interpreted by most
626 systems to leave that value unchanged.  Returns the number of files
627 successfully changed.
628
629     $cnt = chown $uid, $gid, 'foo', 'bar';
630     chown $uid, $gid, @filenames;
631
632 Here's an example that looks up nonnumeric uids in the passwd file:
633
634     print "User: ";
635     chomp($user = <STDIN>);
636     print "Files: ";
637     chomp($pattern = <STDIN>);
638
639     ($login,$pass,$uid,$gid) = getpwnam($user)
640         or die "$user not in passwd file";
641
642     @ary = glob($pattern);      # expand filenames
643     chown $uid, $gid, @ary;
644
645 On most systems, you are not allowed to change the ownership of the
646 file unless you're the superuser, although you should be able to change
647 the group to any of your secondary groups.  On insecure systems, these
648 restrictions may be relaxed, but this is not a portable assumption.
649 On POSIX systems, you can detect this condition this way:
650
651     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
652     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
653
654 =item chr NUMBER
655
656 =item chr
657
658 Returns the character represented by that NUMBER in the character set.
659 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
660 chr(0x263a) is a Unicode smiley face (but only within the scope of
661 a C<use utf8>).  For the reverse, use L</ord>.  
662 See L<utf8> for more about Unicode.
663
664 If NUMBER is omitted, uses C<$_>.
665
666 =item chroot FILENAME
667
668 =item chroot
669
670 This function works like the system call by the same name: it makes the
671 named directory the new root directory for all further pathnames that
672 begin with a C<"/"> by your process and all its children.  (It doesn't
673 change your current working directory, which is unaffected.)  For security
674 reasons, this call is restricted to the superuser.  If FILENAME is
675 omitted, does a C<chroot> to C<$_>.
676
677 =item close FILEHANDLE
678
679 =item close
680
681 Closes the file or pipe associated with the file handle, returning true
682 only if stdio successfully flushes buffers and closes the system file
683 descriptor.  Closes the currently selected filehandle if the argument
684 is omitted.
685
686 You don't have to close FILEHANDLE if you are immediately going to do
687 another C<open> on it, because C<open> will close it for you.  (See
688 C<open>.)  However, an explicit C<close> on an input file resets the line
689 counter (C<$.>), while the implicit close done by C<open> does not.
690
691 If the file handle came from a piped open C<close> will additionally
692 return false if one of the other system calls involved fails or if the
693 program exits with non-zero status.  (If the only problem was that the
694 program exited non-zero C<$!> will be set to C<0>.)  Closing a pipe 
695 also waits for the process executing on the pipe to complete, in case you
696 want to look at the output of the pipe afterwards, and 
697 implicitly puts the exit status value of that command into C<$?>.
698
699 Prematurely closing the read end of a pipe (i.e. before the process
700 writing to it at the other end has closed it) will result in a
701 SIGPIPE being delivered to the writer.  If the other end can't
702 handle that, be sure to read all the data before closing the pipe.
703
704 Example:
705
706     open(OUTPUT, '|sort >foo')  # pipe to sort
707         or die "Can't start sort: $!";
708     #...                        # print stuff to output
709     close OUTPUT                # wait for sort to finish
710         or warn $! ? "Error closing sort pipe: $!"
711                    : "Exit status $? from sort";
712     open(INPUT, 'foo')          # get sort's results
713         or die "Can't open 'foo' for input: $!";
714
715 FILEHANDLE may be an expression whose value can be used as an indirect
716 filehandle, usually the real filehandle name.
717
718 =item closedir DIRHANDLE
719
720 Closes a directory opened by C<opendir> and returns the success of that
721 system call.
722
723 DIRHANDLE may be an expression whose value can be used as an indirect
724 dirhandle, usually the real dirhandle name.
725
726 =item connect SOCKET,NAME
727
728 Attempts to connect to a remote socket, just as the connect system call
729 does.  Returns true if it succeeded, false otherwise.  NAME should be a
730 packed address of the appropriate type for the socket.  See the examples in
731 L<perlipc/"Sockets: Client/Server Communication">.
732
733 =item continue BLOCK
734
735 Actually a flow control statement rather than a function.  If there is a
736 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
737 C<foreach>), it is always executed just before the conditional is about to
738 be evaluated again, just like the third part of a C<for> loop in C.  Thus
739 it can be used to increment a loop variable, even when the loop has been
740 continued via the C<next> statement (which is similar to the C C<continue>
741 statement).
742
743 C<last>, C<next>, or C<redo> may appear within a C<continue>
744 block.  C<last> and C<redo> will behave as if they had been executed within
745 the main block.  So will C<next>, but since it will execute a C<continue>
746 block, it may be more entertaining.
747
748     while (EXPR) {
749         ### redo always comes here
750         do_something;
751     } continue {
752         ### next always comes here
753         do_something_else;
754         # then back the top to re-check EXPR
755     }
756     ### last always comes here
757
758 Omitting the C<continue> section is semantically equivalent to using an
759 empty one, logically enough.  In that case, C<next> goes directly back
760 to check the condition at the top of the loop.
761
762 =item cos EXPR
763
764 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
765 takes cosine of C<$_>.
766
767 For the inverse cosine operation, you may use the C<POSIX::acos()>
768 function, or use this relation:
769
770     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
771
772 =item crypt PLAINTEXT,SALT
773
774 Encrypts a string exactly like the crypt(3) function in the C library
775 (assuming that you actually have a version there that has not been
776 extirpated as a potential munition).  This can prove useful for checking
777 the password file for lousy passwords, amongst other things.  Only the
778 guys wearing white hats should do this.
779
780 Note that C<crypt> is intended to be a one-way function, much like breaking
781 eggs to make an omelette.  There is no (known) corresponding decrypt
782 function.  As a result, this function isn't all that useful for
783 cryptography.  (For that, see your nearby CPAN mirror.)
784
785 When verifying an existing encrypted string you should use the encrypted
786 text as the salt (like C<crypt($plain, $crypted) eq $crypted>).  This
787 allows your code to work with the standard C<crypt> and with more
788 exotic implementations.  When choosing a new salt create a random two
789 character string whose characters come from the set C<[./0-9A-Za-z]>
790 (like C<join '', ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).
791
792 Here's an example that makes sure that whoever runs this program knows
793 their own password:
794
795     $pwd = (getpwuid($<))[1];
796
797     system "stty -echo";
798     print "Password: ";
799     chomp($word = <STDIN>);
800     print "\n";
801     system "stty echo";
802
803     if (crypt($word, $pwd) ne $pwd) {
804         die "Sorry...\n";
805     } else {
806         print "ok\n";
807     }
808
809 Of course, typing in your own password to whoever asks you
810 for it is unwise.
811
812 The L<crypt> function is unsuitable for encrypting large quantities
813 of data, not least of all because you can't get the information
814 back.  Look at the F<by-module/Crypt> and F<by-module/PGP> directories
815 on your favorite CPAN mirror for a slew of potentially useful
816 modules.
817
818 =item dbmclose HASH
819
820 [This function has been largely superseded by the C<untie> function.]
821
822 Breaks the binding between a DBM file and a hash.
823
824 =item dbmopen HASH,DBNAME,MASK
825
826 [This function has been largely superseded by the C<tie> function.]
827
828 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
829 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
830 argument is I<not> a filehandle, even though it looks like one).  DBNAME
831 is the name of the database (without the F<.dir> or F<.pag> extension if
832 any).  If the database does not exist, it is created with protection
833 specified by MASK (as modified by the C<umask>).  If your system supports
834 only the older DBM functions, you may perform only one C<dbmopen> in your
835 program.  In older versions of Perl, if your system had neither DBM nor
836 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
837 sdbm(3).
838
839 If you don't have write access to the DBM file, you can only read hash
840 variables, not set them.  If you want to test whether you can write,
841 either use file tests or try setting a dummy hash entry inside an C<eval>,
842 which will trap the error.
843
844 Note that functions such as C<keys> and C<values> may return huge lists
845 when used on large DBM files.  You may prefer to use the C<each>
846 function to iterate over large DBM files.  Example:
847
848     # print out history file offsets
849     dbmopen(%HIST,'/usr/lib/news/history',0666);
850     while (($key,$val) = each %HIST) {
851         print $key, ' = ', unpack('L',$val), "\n";
852     }
853     dbmclose(%HIST);
854
855 See also L<AnyDBM_File> for a more general description of the pros and
856 cons of the various dbm approaches, as well as L<DB_File> for a particularly
857 rich implementation.
858
859 You can control which DBM library you use by loading that library
860 before you call dbmopen():
861
862     use DB_File;
863     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
864         or die "Can't open netscape history file: $!";
865
866 =item defined EXPR
867
868 =item defined
869
870 Returns a Boolean value telling whether EXPR has a value other than
871 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
872 checked.
873
874 Many operations return C<undef> to indicate failure, end of file,
875 system error, uninitialized variable, and other exceptional
876 conditions.  This function allows you to distinguish C<undef> from
877 other values.  (A simple Boolean test will not distinguish among
878 C<undef>, zero, the empty string, and C<"0">, which are all equally
879 false.)  Note that since C<undef> is a valid scalar, its presence
880 doesn't I<necessarily> indicate an exceptional condition: C<pop>
881 returns C<undef> when its argument is an empty array, I<or> when the
882 element to return happens to be C<undef>.
883
884 You may also use C<defined(&func)> to check whether subroutine C<&func>
885 has ever been defined.  The return value is unaffected by any forward
886 declarations of C<&foo>.
887
888 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
889 used to report whether memory for that aggregate has ever been
890 allocated.  This behavior may disappear in future versions of Perl.
891 You should instead use a simple test for size:
892
893     if (@an_array) { print "has array elements\n" }
894     if (%a_hash)   { print "has hash members\n"   }
895
896 When used on a hash element, it tells you whether the value is defined,
897 not whether the key exists in the hash.  Use L</exists> for the latter
898 purpose.
899
900 Examples:
901
902     print if defined $switch{'D'};
903     print "$val\n" while defined($val = pop(@ary));
904     die "Can't readlink $sym: $!"
905         unless defined($value = readlink $sym);
906     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
907     $debugging = 0 unless defined $debugging;
908
909 Note:  Many folks tend to overuse C<defined>, and then are surprised to
910 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
911 defined values.  For example, if you say
912
913     "ab" =~ /a(.*)b/;
914
915 The pattern match succeeds, and C<$1> is defined, despite the fact that it
916 matched "nothing".  But it didn't really match nothing--rather, it
917 matched something that happened to be zero characters long.  This is all
918 very above-board and honest.  When a function returns an undefined value,
919 it's an admission that it couldn't give you an honest answer.  So you
920 should use C<defined> only when you're questioning the integrity of what
921 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
922 what you want.
923
924 See also L</undef>, L</exists>, L</ref>.
925
926 =item delete EXPR
927
928 Deletes the specified key(s) and their associated values from a hash.
929 For each key, returns the deleted value associated with that key, or
930 the undefined value if there was no such key.  Deleting from C<$ENV{}>
931 modifies the environment.  Deleting from a hash tied to a DBM file
932 deletes the entry from the DBM file.  (But deleting from a C<tie>d hash
933 doesn't necessarily return anything.)
934
935 The following deletes all the values of a hash:
936
937     foreach $key (keys %HASH) {
938         delete $HASH{$key};
939     }
940
941 And so does this:
942
943     delete @HASH{keys %HASH}
944
945 But both of these are slower than just assigning the empty list
946 or undefining it:
947
948     %hash = ();         # completely empty %hash
949     undef %hash;        # forget %hash every existed
950
951 Note that the EXPR can be arbitrarily complicated as long as the final
952 operation is a hash element lookup or hash slice:
953
954     delete $ref->[$x][$y]{$key};
955     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
956
957 =item die LIST
958
959 Outside an C<eval>, prints the value of LIST to C<STDERR> and
960 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
961 exits with the value of C<($? E<gt>E<gt> 8)> (backtick `command`
962 status).  If C<($? E<gt>E<gt> 8)> is C<0>, exits with C<255>.  Inside
963 an C<eval(),> the error message is stuffed into C<$@> and the
964 C<eval> is terminated with the undefined value.  This makes
965 C<die> the way to raise an exception.
966
967 Equivalent examples:
968
969     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
970     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
971
972 If the value of EXPR does not end in a newline, the current script line
973 number and input line number (if any) are also printed, and a newline
974 is supplied.  Note that the "input line number" (also known as "chunk")
975 is subject to whatever notion of "line" happens to be currently in
976 effect, and is also available as the special variable C<$.>.
977 See L<perlvar/"$/"> and L<perlvar/"$.">.
978
979 Hint: sometimes appending C<", stopped"> to your message
980 will cause it to make better sense when the string C<"at foo line 123"> is
981 appended.  Suppose you are running script "canasta".
982
983     die "/etc/games is no good";
984     die "/etc/games is no good, stopped";
985
986 produce, respectively
987
988     /etc/games is no good at canasta line 123.
989     /etc/games is no good, stopped at canasta line 123.
990
991 See also exit(), warn(), and the Carp module.
992
993 If LIST is empty and C<$@> already contains a value (typically from a
994 previous eval) that value is reused after appending C<"\t...propagated">.
995 This is useful for propagating exceptions:
996
997     eval { ... };
998     die unless $@ =~ /Expected exception/;
999
1000 If C<$@> is empty then the string C<"Died"> is used.
1001
1002 die() can also be called with a reference argument.  If this happens to be
1003 trapped within an eval(), $@ contains the reference.  This behavior permits
1004 a more elaborate exception handling implementation using objects that
1005 maintain arbitary state about the nature of the exception.  Such a scheme
1006 is sometimes preferable to matching particular string values of $@ using
1007 regular expressions.  Here's an example:
1008
1009     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1010     if ($@) {
1011         if (ref($@) && UNIVERSAL::isa($@,"Some::Module::Exception")) {
1012             # handle Some::Module::Exception
1013         }
1014         else {
1015             # handle all other possible exceptions
1016         }
1017     }
1018
1019 Because perl will stringify uncaught exception messages before displaying
1020 them, you may want to overload stringification operations on such custom
1021 exception objects.  See L<overload> for details about that.
1022
1023 You can arrange for a callback to be run just before the C<die>
1024 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1025 handler will be called with the error text and can change the error
1026 message, if it sees fit, by calling C<die> again.  See
1027 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1028 L<"eval BLOCK"> for some examples.  Although this feature was meant
1029 to be run only right before your program was to exit, this is not
1030 currently the case--the C<$SIG{__DIE__}> hook is currently called
1031 even inside eval()ed blocks/strings!  If one wants the hook to do
1032 nothing in such situations, put
1033
1034         die @_ if $^S;
1035
1036 as the first line of the handler (see L<perlvar/$^S>).  Because
1037 this promotes strange action at a distance, this counterintuitive
1038 behavior may be fixed in a future release.  
1039
1040 =item do BLOCK
1041
1042 Not really a function.  Returns the value of the last command in the
1043 sequence of commands indicated by BLOCK.  When modified by a loop
1044 modifier, executes the BLOCK once before testing the loop condition.
1045 (On other statements the loop modifiers test the conditional first.)
1046
1047 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1048 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1049 See L<perlsyn> for alternative strategies.
1050
1051 =item do SUBROUTINE(LIST)
1052
1053 A deprecated form of subroutine call.  See L<perlsub>.
1054
1055 =item do EXPR
1056
1057 Uses the value of EXPR as a filename and executes the contents of the
1058 file as a Perl script.  Its primary use is to include subroutines
1059 from a Perl subroutine library.
1060
1061     do 'stat.pl';
1062
1063 is just like
1064
1065     scalar eval `cat stat.pl`;
1066
1067 except that it's more efficient and concise, keeps track of the current
1068 filename for error messages, searches the @INC libraries, and updates
1069 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1070 variables.  It also differs in that code evaluated with C<do FILENAME>
1071 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1072 same, however, in that it does reparse the file every time you call it,
1073 so you probably don't want to do this inside a loop.
1074
1075 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1076 error.  If C<do> can read the file but cannot compile it, it
1077 returns undef and sets an error message in C<$@>.   If the file is
1078 successfully compiled, C<do> returns the value of the last expression
1079 evaluated.
1080
1081 Note that inclusion of library modules is better done with the
1082 C<use> and C<require> operators, which also do automatic error checking
1083 and raise an exception if there's a problem.
1084
1085 You might like to use C<do> to read in a program configuration
1086 file.  Manual error checking can be done this way:
1087
1088     # read in config files: system first, then user 
1089     for $file ("/share/prog/defaults.rc",
1090                "$ENV{HOME}/.someprogrc") 
1091    {
1092         unless ($return = do $file) {
1093             warn "couldn't parse $file: $@" if $@;
1094             warn "couldn't do $file: $!"    unless defined $return;
1095             warn "couldn't run $file"       unless $return;
1096         }
1097     }
1098
1099 =item dump LABEL
1100
1101 =item dump
1102
1103 This function causes an immediate core dump.  See also the B<-u>
1104 command-line switch in L<perlrun>, which does the same thing.
1105 Primarily this is so that you can use the B<undump> program (not
1106 supplied) to turn your core dump into an executable binary after
1107 having initialized all your variables at the beginning of the
1108 program.  When the new binary is executed it will begin by executing
1109 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1110 Think of it as a goto with an intervening core dump and reincarnation.
1111 If C<LABEL> is omitted, restarts the program from the top.
1112
1113 B<WARNING>: Any files opened at the time of the dump will I<not>
1114 be open any more when the program is reincarnated, with possible
1115 resulting confusion on the part of Perl.  
1116
1117 This function is now largely obsolete, partly because it's very
1118 hard to convert a core file into an executable, and because the
1119 real compiler backends for generating portable bytecode and compilable
1120 C code have superseded it.
1121
1122 If you're looking to use L<dump> to speed up your program, consider
1123 generating bytecode or native C code as described in L<perlcc>.  If
1124 you're just trying to accelerate a CGI script, consider using the
1125 C<mod_perl> extension to B<Apache>, or the CPAN module, Fast::CGI.
1126 You might also consider autoloading or selfloading, which at least
1127 make your program I<appear> to run faster.  
1128
1129 =item each HASH
1130
1131 When called in list context, returns a 2-element list consisting of the
1132 key and value for the next element of a hash, so that you can iterate over
1133 it.  When called in scalar context, returns the key for only the "next"
1134 element in the hash.  (Note: Keys may be C<"0"> or C<"">, which are logically
1135 false; you may wish to avoid constructs like C<while ($k = each %foo) {}>
1136 for this reason.)
1137
1138 Entries are returned in an apparently random order.  The actual random
1139 order is subject to change in future versions of perl, but it is guaranteed
1140 to be in the same order as either the C<keys> or C<values> function
1141 would produce on the same (unmodified) hash.
1142
1143 When the hash is entirely read, a null array is returned in list context
1144 (which when assigned produces a false (C<0>) value), and C<undef> in
1145 scalar context.  The next call to C<each> after that will start iterating
1146 again.  There is a single iterator for each hash, shared by all C<each>,
1147 C<keys>, and C<values> function calls in the program; it can be reset by
1148 reading all the elements from the hash, or by evaluating C<keys HASH> or
1149 C<values HASH>.  If you add or delete elements of a hash while you're
1150 iterating over it, you may get entries skipped or duplicated, so don't.
1151
1152 The following prints out your environment like the printenv(1) program,
1153 only in a different order:
1154
1155     while (($key,$value) = each %ENV) {
1156         print "$key=$value\n";
1157     }
1158
1159 See also C<keys>, C<values> and C<sort>.
1160
1161 =item eof FILEHANDLE
1162
1163 =item eof ()
1164
1165 =item eof
1166
1167 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1168 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1169 gives the real filehandle.  (Note that this function actually
1170 reads a character and then C<ungetc>s it, so isn't very useful in an
1171 interactive context.)  Do not read from a terminal file (or call
1172 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1173 as terminals may lose the end-of-file condition if you do.
1174
1175 An C<eof> without an argument uses the last file read as argument.
1176 Using C<eof()> with empty parentheses is very different.  It indicates
1177 the pseudo file formed of the files listed on the command line,
1178 i.e., C<eof()> is reasonable to use inside a C<while (E<lt>E<gt>)>
1179 loop to detect the end of only the last file.  Use C<eof(ARGV)> or
1180 C<eof> without the parentheses to test I<each> file in a while
1181 (E<lt>E<gt>) loop.  Examples:
1182
1183     # reset line numbering on each input file
1184     while (<>) {
1185         next if /^\s*#/;        # skip comments 
1186         print "$.\t$_";
1187     } continue {
1188         close ARGV  if eof;     # Not eof()!
1189     }
1190
1191     # insert dashes just before last line of last file
1192     while (<>) {
1193         if (eof()) {            # check for end of current file
1194             print "--------------\n";
1195             close(ARGV);        # close or last; is needed if we
1196                                 # are reading from the terminal
1197         }
1198         print;
1199     }
1200
1201 Practical hint: you almost never need to use C<eof> in Perl, because the
1202 input operators return false values when they run out of data, or if there
1203 was an error.
1204
1205 =item eval EXPR
1206
1207 =item eval BLOCK
1208
1209 In the first form, the return value of EXPR is parsed and executed as if it
1210 were a little Perl program.  The value of the expression (which is itself
1211 determined within scalar context) is first parsed, and if there weren't any
1212 errors, executed in the context of the current Perl program, so that any
1213 variable settings or subroutine and format definitions remain afterwards.
1214 Note that the value is parsed every time the eval executes.  If EXPR is
1215 omitted, evaluates C<$_>.  This form is typically used to delay parsing
1216 and subsequent execution of the text of EXPR until run time.
1217
1218 In the second form, the code within the BLOCK is parsed only once--at the
1219 same time the code surrounding the eval itself was parsed--and executed
1220 within the context of the current Perl program.  This form is typically
1221 used to trap exceptions more efficiently than the first (see below), while
1222 also providing the benefit of checking the code within BLOCK at compile
1223 time.
1224
1225 The final semicolon, if any, may be omitted from the value of EXPR or within
1226 the BLOCK.
1227
1228 In both forms, the value returned is the value of the last expression
1229 evaluated inside the mini-program; a return statement may be also used, just
1230 as with subroutines.  The expression providing the return value is evaluated
1231 in void, scalar, or list context, depending on the context of the eval itself.
1232 See L</wantarray> for more on how the evaluation context can be determined.
1233
1234 If there is a syntax error or runtime error, or a C<die> statement is
1235 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1236 error message.  If there was no error, C<$@> is guaranteed to be a null
1237 string.  Beware that using C<eval> neither silences perl from printing
1238 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1239 To do either of those, you have to use the C<$SIG{__WARN__}> facility.  See
1240 L</warn> and L<perlvar>.
1241
1242 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1243 determining whether a particular feature (such as C<socket> or C<symlink>)
1244 is implemented.  It is also Perl's exception trapping mechanism, where
1245 the die operator is used to raise exceptions.
1246
1247 If the code to be executed doesn't vary, you may use the eval-BLOCK
1248 form to trap run-time errors without incurring the penalty of
1249 recompiling each time.  The error, if any, is still returned in C<$@>.
1250 Examples:
1251
1252     # make divide-by-zero nonfatal
1253     eval { $answer = $a / $b; }; warn $@ if $@;
1254
1255     # same thing, but less efficient
1256     eval '$answer = $a / $b'; warn $@ if $@;
1257
1258     # a compile-time error
1259     eval { $answer = };                 # WRONG
1260
1261     # a run-time error
1262     eval '$answer =';   # sets $@
1263
1264 Due to the current arguably broken state of C<__DIE__> hooks, when using
1265 the C<eval{}> form as an exception trap in libraries, you may wish not
1266 to trigger any C<__DIE__> hooks that user code may have installed.
1267 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1268 as shown in this example:
1269
1270     # a very private exception trap for divide-by-zero
1271     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1272     warn $@ if $@;
1273
1274 This is especially significant, given that C<__DIE__> hooks can call
1275 C<die> again, which has the effect of changing their error messages:
1276
1277     # __DIE__ hooks may modify error messages
1278     {
1279        local $SIG{'__DIE__'} =
1280               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1281        eval { die "foo lives here" };
1282        print $@ if $@;                # prints "bar lives here"
1283     }
1284
1285 Because this promotes action at a distance, this counterintuitive behavior
1286 may be fixed in a future release.
1287
1288 With an C<eval>, you should be especially careful to remember what's
1289 being looked at when:
1290
1291     eval $x;            # CASE 1
1292     eval "$x";          # CASE 2
1293
1294     eval '$x';          # CASE 3
1295     eval { $x };        # CASE 4
1296
1297     eval "\$$x++";      # CASE 5
1298     $$x++;              # CASE 6
1299
1300 Cases 1 and 2 above behave identically: they run the code contained in
1301 the variable $x.  (Although case 2 has misleading double quotes making
1302 the reader wonder what else might be happening (nothing is).)  Cases 3
1303 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1304 does nothing but return the value of $x.  (Case 4 is preferred for
1305 purely visual reasons, but it also has the advantage of compiling at
1306 compile-time instead of at run-time.)  Case 5 is a place where
1307 normally you I<would> like to use double quotes, except that in this
1308 particular situation, you can just use symbolic references instead, as
1309 in case 6.
1310
1311 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1312 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1313
1314 =item exec LIST
1315
1316 =item exec PROGRAM LIST
1317
1318 The C<exec> function executes a system command I<and never returns>--
1319 use C<system> instead of C<exec> if you want it to return.  It fails and
1320 returns false only if the command does not exist I<and> it is executed
1321 directly instead of via your system's command shell (see below).
1322
1323 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1324 warns you if there is a following statement which isn't C<die>, C<warn>,
1325 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1326 I<really> want to follow an C<exec> with some other statement, you
1327 can use one of these styles to avoid the warning:
1328
1329     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1330     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1331
1332 If there is more than one argument in LIST, or if LIST is an array
1333 with more than one value, calls execvp(3) with the arguments in LIST.
1334 If there is only one scalar argument or an array with one element in it,
1335 the argument is checked for shell metacharacters, and if there are any,
1336 the entire argument is passed to the system's command shell for parsing
1337 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1338 If there are no shell metacharacters in the argument, it is split into
1339 words and passed directly to C<execvp>, which is more efficient.  
1340 Examples:
1341
1342     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1343     exec "sort $outfile | uniq";
1344
1345 If you don't really want to execute the first argument, but want to lie
1346 to the program you are executing about its own name, you can specify
1347 the program you actually want to run as an "indirect object" (without a
1348 comma) in front of the LIST.  (This always forces interpretation of the
1349 LIST as a multivalued list, even if there is only a single scalar in
1350 the list.)  Example:
1351
1352     $shell = '/bin/csh';
1353     exec $shell '-sh';          # pretend it's a login shell
1354
1355 or, more directly,
1356
1357     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1358
1359 When the arguments get executed via the system shell, results will
1360 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1361 for details.
1362
1363 Using an indirect object with C<exec> or C<system> is also more
1364 secure.  This usage (which also works fine with system()) forces
1365 interpretation of the arguments as a multivalued list, even if the
1366 list had just one argument.  That way you're safe from the shell
1367 expanding wildcards or splitting up words with whitespace in them.
1368
1369     @args = ( "echo surprise" );
1370
1371     exec @args;               # subject to shell escapes
1372                                 # if @args == 1
1373     exec { $args[0] } @args;  # safe even with one-arg list
1374
1375 The first version, the one without the indirect object, ran the I<echo>
1376 program, passing it C<"surprise"> an argument.  The second version
1377 didn't--it tried to run a program literally called I<"echo surprise">,
1378 didn't find it, and set C<$?> to a non-zero value indicating failure.
1379
1380 Note that C<exec> will not call your C<END> blocks, nor will it call
1381 any C<DESTROY> methods in your objects.
1382
1383 =item exists EXPR
1384
1385 Returns true if the specified hash key exists in its hash, even
1386 if the corresponding value is undefined.
1387
1388     print "Exists\n"    if exists $array{$key};
1389     print "Defined\n"   if defined $array{$key};
1390     print "True\n"      if $array{$key};
1391
1392 A hash element can be true only if it's defined, and defined if
1393 it exists, but the reverse doesn't necessarily hold true.
1394
1395 Note that the EXPR can be arbitrarily complicated as long as the final
1396 operation is a hash key lookup:
1397
1398     if (exists $ref->{A}->{B}->{$key})  { }
1399     if (exists $hash{A}{B}{$key})       { }
1400
1401 Although the last element will not spring into existence just because
1402 its existence was tested, intervening ones will.  Thus C<$ref-E<gt>{"A"}>
1403 and C<$ref-E<gt>{"A"}-E<gt>{"B"}> will spring into existence due to the
1404 existence test for a $key element.  This happens anywhere the arrow
1405 operator is used, including even 
1406
1407     undef $ref;
1408     if (exists $ref->{"Some key"})      { }
1409     print $ref;             # prints HASH(0x80d3d5c)
1410
1411 This surprising autovivification in what does not at first--or even
1412 second--glance appear to be an lvalue context may be fixed in a future
1413 release.
1414
1415 =item exit EXPR
1416
1417 Evaluates EXPR and exits immediately with that value.    Example:
1418
1419     $ans = <STDIN>;
1420     exit 0 if $ans =~ /^[Xx]/;
1421
1422 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1423 universally recognized values for EXPR are C<0> for success and C<1>
1424 for error; other values are subject to interpretation depending on the
1425 environment in which the Perl program is running.  For example, exiting
1426 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1427 the mailer to return the item undelivered, but that's not true everywhere.
1428
1429 Don't use C<exit> to abort a subroutine if there's any chance that
1430 someone might want to trap whatever error happened.  Use C<die> instead,
1431 which can be trapped by an C<eval>.
1432
1433 The exit() function does not always exit immediately.  It calls any
1434 defined C<END> routines first, but these C<END> routines may not
1435 themselves abort the exit.  Likewise any object destructors that need to
1436 be called are called before the real exit.  If this is a problem, you
1437 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1438 See L<perlmod> for details.
1439
1440 =item exp EXPR
1441
1442 =item exp
1443
1444 Returns I<e> (the natural logarithm base) to the power of EXPR.  
1445 If EXPR is omitted, gives C<exp($_)>.
1446
1447 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1448
1449 Implements the fcntl(2) function.  You'll probably have to say
1450
1451     use Fcntl;
1452
1453 first to get the correct constant definitions.  Argument processing and
1454 value return works just like C<ioctl> below.  
1455 For example:
1456
1457     use Fcntl;
1458     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1459         or die "can't fcntl F_GETFL: $!";
1460
1461 You don't have to check for C<defined> on the return from C<fnctl>.
1462 Like C<ioctl>, it maps a C<0> return from the system call into C<"0
1463 but true"> in Perl.  This string is true in boolean context and C<0>
1464 in numeric context.  It is also exempt from the normal B<-w> warnings
1465 on improper numeric conversions.
1466
1467 Note that C<fcntl> will produce a fatal error if used on a machine that
1468 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1469 manpage to learn what functions are available on your system.
1470
1471 =item fileno FILEHANDLE
1472
1473 Returns the file descriptor for a filehandle, or undefined if the
1474 filehandle is not open.  This is mainly useful for constructing
1475 bitmaps for C<select> and low-level POSIX tty-handling operations.
1476 If FILEHANDLE is an expression, the value is taken as an indirect
1477 filehandle, generally its name.
1478
1479 You can use this to find out whether two handles refer to the 
1480 same underlying descriptor:
1481
1482     if (fileno(THIS) == fileno(THAT)) {
1483         print "THIS and THAT are dups\n";
1484     } 
1485
1486 =item flock FILEHANDLE,OPERATION
1487
1488 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1489 for success, false on failure.  Produces a fatal error if used on a
1490 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1491 C<flock> is Perl's portable file locking interface, although it locks
1492 only entire files, not records.
1493
1494 Two potentially non-obvious but traditional C<flock> semantics are
1495 that it waits indefinitely until the lock is granted, and that its locks
1496 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1497 fewer guarantees.  This means that files locked with C<flock> may be
1498 modified by programs that do not also use C<flock>.  See L<perlport>,
1499 your port's specific documentation, or your system-specific local manpages
1500 for details.  It's best to assume traditional behavior if you're writing
1501 portable programs.  (But if you're not, you should as always feel perfectly
1502 free to write for your own system's idiosyncrasies (sometimes called
1503 "features").  Slavish adherence to portability concerns shouldn't get
1504 in the way of your getting your job done.)
1505
1506 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1507 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1508 you can use the symbolic names if import them from the Fcntl module,
1509 either individually, or as a group using the ':flock' tag.  LOCK_SH
1510 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1511 releases a previously requested lock.  If LOCK_NB is added to LOCK_SH or
1512 LOCK_EX then C<flock> will return immediately rather than blocking
1513 waiting for the lock (check the return status to see if you got it).
1514
1515 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1516 before locking or unlocking it.
1517
1518 Note that the emulation built with lockf(3) doesn't provide shared
1519 locks, and it requires that FILEHANDLE be open with write intent.  These
1520 are the semantics that lockf(3) implements.  Most if not all systems
1521 implement lockf(3) in terms of fcntl(2) locking, though, so the
1522 differing semantics shouldn't bite too many people.
1523
1524 Note also that some versions of C<flock> cannot lock things over the
1525 network; you would need to use the more system-specific C<fcntl> for
1526 that.  If you like you can force Perl to ignore your system's flock(2)
1527 function, and so provide its own fcntl(2)-based emulation, by passing
1528 the switch C<-Ud_flock> to the F<Configure> program when you configure
1529 perl.
1530
1531 Here's a mailbox appender for BSD systems.
1532
1533     use Fcntl ':flock'; # import LOCK_* constants
1534
1535     sub lock {
1536         flock(MBOX,LOCK_EX);
1537         # and, in case someone appended
1538         # while we were waiting...
1539         seek(MBOX, 0, 2);
1540     }
1541
1542     sub unlock {
1543         flock(MBOX,LOCK_UN);
1544     }
1545
1546     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1547             or die "Can't open mailbox: $!";
1548
1549     lock();
1550     print MBOX $msg,"\n\n";
1551     unlock();
1552
1553 On systems that support a real flock(), locks are inherited across fork()
1554 calls, whereas those that must resort to the more capricious fcntl()
1555 function lose the locks, making it harder to write servers.
1556
1557 See also L<DB_File> for other flock() examples.
1558
1559 =item fork
1560
1561 Does a fork(2) system call to create a new process running the
1562 same program at the same point.  It returns the child pid to the
1563 parent process, C<0> to the child process, or C<undef> if the fork is
1564 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1565 are shared, while everything else is copied.  On most systems supporting
1566 fork(), great care has gone into making it extremely efficient (for
1567 example, using copy-on-write technology on data pages), making it the
1568 dominant paradigm for multitasking over the last few decades.
1569
1570 All files opened for output are flushed before forking the child process.
1571
1572 If you C<fork> without ever waiting on your children, you will
1573 accumulate zombies.  On some systems, you can avoid this by setting
1574 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1575 forking and reaping moribund children.
1576
1577 Note that if your forked child inherits system file descriptors like
1578 STDIN and STDOUT that are actually connected by a pipe or socket, even
1579 if you exit, then the remote server (such as, say, a CGI script or a
1580 backgrounded job launched from a remote shell) won't think you're done.
1581 You should reopen those to F</dev/null> if it's any issue.
1582
1583 =item format
1584
1585 Declare a picture format for use by the C<write> function.  For
1586 example:
1587
1588     format Something =
1589         Test: @<<<<<<<< @||||| @>>>>>
1590               $str,     $%,    '$' . int($num)
1591     .
1592
1593     $str = "widget";
1594     $num = $cost/$quantity;
1595     $~ = 'Something';
1596     write;
1597
1598 See L<perlform> for many details and examples.
1599
1600 =item formline PICTURE,LIST
1601
1602 This is an internal function used by C<format>s, though you may call it,
1603 too.  It formats (see L<perlform>) a list of values according to the
1604 contents of PICTURE, placing the output into the format output
1605 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1606 Eventually, when a C<write> is done, the contents of
1607 C<$^A> are written to some filehandle, but you could also read C<$^A>
1608 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1609 does one C<formline> per line of form, but the C<formline> function itself
1610 doesn't care how many newlines are embedded in the PICTURE.  This means
1611 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1612 You may therefore need to use multiple formlines to implement a single
1613 record format, just like the format compiler.
1614
1615 Be careful if you put double quotes around the picture, because an C<@>
1616 character may be taken to mean the beginning of an array name.
1617 C<formline> always returns true.  See L<perlform> for other examples.
1618
1619 =item getc FILEHANDLE
1620
1621 =item getc
1622
1623 Returns the next character from the input file attached to FILEHANDLE,
1624 or the undefined value at end of file, or if there was an error.
1625 If FILEHANDLE is omitted, reads from STDIN.  This is not particularly
1626 efficient.  However, it cannot be used by itself to fetch single
1627 characters without waiting for the user to hit enter.  For that, try
1628 something more like:
1629
1630     if ($BSD_STYLE) {
1631         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1632     }
1633     else {
1634         system "stty", '-icanon', 'eol', "\001";
1635     }
1636
1637     $key = getc(STDIN);
1638
1639     if ($BSD_STYLE) {
1640         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1641     }
1642     else {
1643         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1644     }
1645     print "\n";
1646
1647 Determination of whether $BSD_STYLE should be set
1648 is left as an exercise to the reader.
1649
1650 The C<POSIX::getattr> function can do this more portably on
1651 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1652 module from your nearest CPAN site; details on CPAN can be found on
1653 L<perlmodlib/CPAN>.
1654
1655 =item getlogin
1656
1657 Implements the C library function of the same name, which on most
1658 systems returns the current login from F</etc/utmp>, if any.  If null,
1659 use C<getpwuid>.
1660
1661     $login = getlogin || getpwuid($<) || "Kilroy";
1662
1663 Do not consider C<getlogin> for authentication: it is not as
1664 secure as C<getpwuid>.
1665
1666 =item getpeername SOCKET
1667
1668 Returns the packed sockaddr address of other end of the SOCKET connection.
1669
1670     use Socket;
1671     $hersockaddr    = getpeername(SOCK);
1672     ($port, $iaddr) = sockaddr_in($hersockaddr);
1673     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1674     $herstraddr     = inet_ntoa($iaddr);
1675
1676 =item getpgrp PID
1677
1678 Returns the current process group for the specified PID.  Use
1679 a PID of C<0> to get the current process group for the
1680 current process.  Will raise an exception if used on a machine that
1681 doesn't implement getpgrp(2).  If PID is omitted, returns process
1682 group of current process.  Note that the POSIX version of C<getpgrp>
1683 does not accept a PID argument, so only C<PID==0> is truly portable.
1684
1685 =item getppid
1686
1687 Returns the process id of the parent process.
1688
1689 =item getpriority WHICH,WHO
1690
1691 Returns the current priority for a process, a process group, or a user.
1692 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1693 machine that doesn't implement getpriority(2).
1694
1695 =item getpwnam NAME
1696
1697 =item getgrnam NAME
1698
1699 =item gethostbyname NAME
1700
1701 =item getnetbyname NAME
1702
1703 =item getprotobyname NAME
1704
1705 =item getpwuid UID
1706
1707 =item getgrgid GID
1708
1709 =item getservbyname NAME,PROTO
1710
1711 =item gethostbyaddr ADDR,ADDRTYPE
1712
1713 =item getnetbyaddr ADDR,ADDRTYPE
1714
1715 =item getprotobynumber NUMBER
1716
1717 =item getservbyport PORT,PROTO
1718
1719 =item getpwent
1720
1721 =item getgrent
1722
1723 =item gethostent
1724
1725 =item getnetent
1726
1727 =item getprotoent
1728
1729 =item getservent
1730
1731 =item setpwent
1732
1733 =item setgrent
1734
1735 =item sethostent STAYOPEN
1736
1737 =item setnetent STAYOPEN
1738
1739 =item setprotoent STAYOPEN
1740
1741 =item setservent STAYOPEN
1742
1743 =item endpwent
1744
1745 =item endgrent
1746
1747 =item endhostent
1748
1749 =item endnetent
1750
1751 =item endprotoent
1752
1753 =item endservent
1754
1755 These routines perform the same functions as their counterparts in the
1756 system library.  In list context, the return values from the
1757 various get routines are as follows:
1758
1759     ($name,$passwd,$uid,$gid,
1760        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1761     ($name,$passwd,$gid,$members) = getgr*
1762     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1763     ($name,$aliases,$addrtype,$net) = getnet*
1764     ($name,$aliases,$proto) = getproto*
1765     ($name,$aliases,$port,$proto) = getserv*
1766
1767 (If the entry doesn't exist you get a null list.)
1768
1769 In scalar context, you get the name, unless the function was a
1770 lookup by name, in which case you get the other thing, whatever it is.
1771 (If the entry doesn't exist you get the undefined value.)  For example:
1772
1773     $uid   = getpwnam($name);
1774     $name  = getpwuid($num);
1775     $name  = getpwent();
1776     $gid   = getgrnam($name);
1777     $name  = getgrgid($num;
1778     $name  = getgrent();
1779     #etc.
1780
1781 In I<getpw*()> the fields $quota, $comment, and $expire are
1782 special cases in the sense that in many systems they are unsupported.
1783 If the $quota is unsupported, it is an empty scalar.  If it is
1784 supported, it usually encodes the disk quota.  If the $comment
1785 field is unsupported, it is an empty scalar.  If it is supported it
1786 usually encodes some administrative comment about the user.  In some
1787 systems the $quota field may be $change or $age, fields that have
1788 to do with password aging.  In some systems the $comment field may
1789 be $class.  The $expire field, if present, encodes the expiration
1790 period of the account or the password.  For the availability and the
1791 exact meaning of these fields in your system, please consult your
1792 getpwnam(3) documentation and your F<pwd.h> file.  You can also find
1793 out from within Perl what your $quota and $comment fields mean
1794 and whether you have the $expire field by using the C<Config> module
1795 and the values C<d_pwquota>, C<d_pwage>, C<d_pwchange>, C<d_pwcomment>,
1796 and C<d_pwexpire>.  Shadow password files are only supported if your
1797 vendor has implemented them in the intuitive fashion that calling the
1798 regular C library routines gets the shadow versions if you're running
1799 under privilege.  Those that incorrectly implement a separate library
1800 call are not supported.
1801
1802 The $members value returned by I<getgr*()> is a space separated list of
1803 the login names of the members of the group.
1804
1805 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1806 C, it will be returned to you via C<$?> if the function call fails.  The
1807 C<@addrs> value returned by a successful call is a list of the raw
1808 addresses returned by the corresponding system library call.  In the
1809 Internet domain, each address is four bytes long and you can unpack it
1810 by saying something like:
1811
1812     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1813
1814 The Socket library makes this slightly easier:
1815
1816     use Socket;
1817     $iaddr = inet_aton("127.1"); # or whatever address
1818     $name  = gethostbyaddr($iaddr, AF_INET);
1819
1820     # or going the other way
1821     $straddr = inet_ntoa($iaddr);
1822
1823 If you get tired of remembering which element of the return list
1824 contains which return value, by-name interfaces are provided
1825 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
1826 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
1827 and C<User::grent>.  These override the normal built-ins, supplying
1828 versions that return objects with the appropriate names
1829 for each field.  For example:
1830
1831    use File::stat;
1832    use User::pwent;
1833    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
1834
1835 Even though it looks like they're the same method calls (uid), 
1836 they aren't, because a C<File::stat> object is different from 
1837 a C<User::pwent> object.
1838
1839 =item getsockname SOCKET
1840
1841 Returns the packed sockaddr address of this end of the SOCKET connection,
1842 in case you don't know the address because you have several different
1843 IPs that the connection might have come in on.
1844
1845     use Socket;
1846     $mysockaddr = getsockname(SOCK);
1847     ($port, $myaddr) = sockaddr_in($mysockaddr);
1848     printf "Connect to %s [%s]\n", 
1849        scalar gethostbyaddr($myaddr, AF_INET),
1850        inet_ntoa($myaddr);
1851
1852 =item getsockopt SOCKET,LEVEL,OPTNAME
1853
1854 Returns the socket option requested, or undef if there is an error.
1855
1856 =item glob EXPR
1857
1858 =item glob
1859
1860 Returns the value of EXPR with filename expansions such as the
1861 standard Unix shell F</bin/csh> would do.  This is the internal function
1862 implementing the C<E<lt>*.cE<gt>> operator, but you can use it directly.
1863 If EXPR is omitted, C<$_> is used.  The C<E<lt>*.cE<gt>> operator is
1864 discussed in more detail in L<perlop/"I/O Operators">.
1865
1866 =item gmtime EXPR
1867
1868 Converts a time as returned by the time function to a 9-element list
1869 with the time localized for the standard Greenwich time zone.
1870 Typically used as follows:
1871
1872     #  0    1    2     3     4    5     6     7     8
1873     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
1874                                             gmtime(time);
1875
1876 All list elements are numeric, and come straight out of a struct tm.
1877 In particular this means that $mon has the range C<0..11> and $wday
1878 has the range C<0..6> with sunday as day C<0>.  Also, $year is the
1879 number of years since 1900, that is, $year is C<123> in year 2023,
1880 I<not> simply the last two digits of the year.  If you assume it is,
1881 then you create non-Y2K-compliant programs--and you wouldn't want to do
1882 that, would you?
1883
1884 If EXPR is omitted, does C<gmtime(time())>.
1885
1886 In scalar context, returns the ctime(3) value:
1887
1888     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
1889
1890 Also see the C<timegm> function provided by the C<Time::Local> module,
1891 and the strftime(3) function available via the POSIX module.
1892
1893 This scalar value is B<not> locale dependent (see L<perllocale>), but
1894 is instead a Perl builtin.  Also see the C<Time::Local> module, and the
1895 strftime(3) and mktime(3) functions available via the POSIX module.  To
1896 get somewhat similar but locale dependent date strings, set up your
1897 locale environment variables appropriately (please see L<perllocale>)
1898 and try for example:
1899
1900     use POSIX qw(strftime);
1901     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
1902
1903 Note that the C<%a> and C<%b> escapes, which represent the short forms
1904 of the day of the week and the month of the year, may not necessarily
1905 be three characters wide in all locales.
1906
1907 =item goto LABEL
1908
1909 =item goto EXPR
1910
1911 =item goto &NAME
1912
1913 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
1914 execution there.  It may not be used to go into any construct that
1915 requires initialization, such as a subroutine or a C<foreach> loop.  It
1916 also can't be used to go into a construct that is optimized away,
1917 or to get out of a block or subroutine given to C<sort>.
1918 It can be used to go almost anywhere else within the dynamic scope,
1919 including out of subroutines, but it's usually better to use some other
1920 construct such as C<last> or C<die>.  The author of Perl has never felt the
1921 need to use this form of C<goto> (in Perl, that is--C is another matter).
1922
1923 The C<goto-EXPR> form expects a label name, whose scope will be resolved
1924 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
1925 necessarily recommended if you're optimizing for maintainability:
1926
1927     goto ("FOO", "BAR", "GLARCH")[$i];
1928
1929 The C<goto-&NAME> form is highly magical, and substitutes a call to the
1930 named subroutine for the currently running subroutine.  This is used by
1931 C<AUTOLOAD> subroutines that wish to load another subroutine and then
1932 pretend that the other subroutine had been called in the first place
1933 (except that any modifications to C<@_> in the current subroutine are
1934 propagated to the other subroutine.)  After the C<goto>, not even C<caller>
1935 will be able to tell that this routine was called first.
1936
1937 =item grep BLOCK LIST
1938
1939 =item grep EXPR,LIST
1940
1941 This is similar in spirit to, but not the same as, grep(1) and its
1942 relatives.  In particular, it is not limited to using regular expressions.
1943
1944 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
1945 C<$_> to each element) and returns the list value consisting of those
1946 elements for which the expression evaluated to true.  In scalar
1947 context, returns the number of times the expression was true.
1948
1949     @foo = grep(!/^#/, @bar);    # weed out comments
1950
1951 or equivalently,
1952
1953     @foo = grep {!/^#/} @bar;    # weed out comments
1954
1955 Note that, because C<$_> is a reference into the list value, it can
1956 be used to modify the elements of the array.  While this is useful and
1957 supported, it can cause bizarre results if the LIST is not a named array.
1958 Similarly, grep returns aliases into the original list, much as a for
1959 loop's index variable aliases the list elements.  That is, modifying an
1960 element of a list returned by grep (for example, in a C<foreach>, C<map>
1961 or another C<grep>) actually modifies the element in the original list.
1962 This is usually something to be avoided when writing clear code.
1963
1964 See also L</map> for a list composed of the results of the BLOCK or EXPR.
1965
1966 =item hex EXPR
1967
1968 =item hex
1969
1970 Interprets EXPR as a hex string and returns the corresponding value.
1971 (To convert strings that might start with either 0, 0x, or 0b, see
1972 L</oct>.)  If EXPR is omitted, uses C<$_>.
1973
1974     print hex '0xAf'; # prints '175'
1975     print hex 'aF';   # same
1976
1977 Hex strings may only represent integers.  Strings that would cause
1978 integer overflow trigger a mandatory error message.
1979
1980 =item import
1981
1982 There is no builtin C<import> function.  It is just an ordinary
1983 method (subroutine) defined (or inherited) by modules that wish to export
1984 names to another module.  The C<use> function calls the C<import> method
1985 for the package used.  See also L</use()>, L<perlmod>, and L<Exporter>.
1986
1987 =item index STR,SUBSTR,POSITION
1988
1989 =item index STR,SUBSTR
1990
1991 The index function searches for one string within another, but without
1992 the wildcard-like behavior of a full regular-expression pattern match.
1993 It returns the position of the first occurrence of SUBSTR in STR at
1994 or after POSITION.  If POSITION is omitted, starts searching from the
1995 beginning of the string.  The return value is based at C<0> (or whatever
1996 you've set the C<$[> variable to--but don't do that).  If the substring
1997 is not found, returns one less than the base, ordinarily C<-1>.
1998
1999 =item int EXPR
2000
2001 =item int
2002
2003 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2004 You should not use this function for rounding: one because it truncates
2005 towards C<0>, and two because machine representations of floating point
2006 numbers can sometimes produce counterintuitive results.  For example,
2007 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2008 because it's really more like -268.99999999999994315658 instead.  Usually,
2009 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2010 functions will serve you better than will int().
2011
2012 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2013
2014 Implements the ioctl(2) function.  You'll probably first have to say
2015
2016     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
2017
2018 to get the correct function definitions.  If F<ioctl.ph> doesn't
2019 exist or doesn't have the correct definitions you'll have to roll your
2020 own, based on your C header files such as F<E<lt>sys/ioctl.hE<gt>>.
2021 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2022 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2023 written depending on the FUNCTION--a pointer to the string value of SCALAR
2024 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2025 has no string value but does have a numeric value, that value will be
2026 passed rather than a pointer to the string value.  To guarantee this to be
2027 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2028 functions may be needed to manipulate the values of structures used by
2029 C<ioctl>.  
2030
2031 The return value of C<ioctl> (and C<fcntl>) is as follows:
2032
2033         if OS returns:          then Perl returns:
2034             -1                    undefined value
2035              0                  string "0 but true"
2036         anything else               that number
2037
2038 Thus Perl returns true on success and false on failure, yet you can
2039 still easily determine the actual value returned by the operating
2040 system:
2041
2042     $retval = ioctl(...) || -1;
2043     printf "System returned %d\n", $retval;
2044
2045 The special string "C<0> but true" is exempt from B<-w> complaints
2046 about improper numeric conversions.
2047
2048 Here's an example of setting a filehandle named C<REMOTE> to be
2049 non-blocking at the system level.  You'll have to negotiate C<$|>
2050 on your own, though.
2051
2052     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2053
2054     $flags = fcntl(REMOTE, F_GETFL, 0)
2055                 or die "Can't get flags for the socket: $!\n";
2056
2057     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2058                 or die "Can't set flags for the socket: $!\n";
2059
2060 =item join EXPR,LIST
2061
2062 Joins the separate strings of LIST into a single string with fields
2063 separated by the value of EXPR, and returns that new string.  Example:
2064
2065     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2066
2067 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2068 first argument.  Compare L</split>.
2069
2070 =item keys HASH
2071
2072 Returns a list consisting of all the keys of the named hash.  (In
2073 scalar context, returns the number of keys.)  The keys are returned in
2074 an apparently random order.  The actual random order is subject to
2075 change in future versions of perl, but it is guaranteed to be the same
2076 order as either the C<values> or C<each> function produces (given
2077 that the hash has not been modified).  As a side effect, it resets
2078 HASH's iterator.
2079
2080 Here is yet another way to print your environment:
2081
2082     @keys = keys %ENV;
2083     @values = values %ENV;
2084     while (@keys) { 
2085         print pop(@keys), '=', pop(@values), "\n";
2086     }
2087
2088 or how about sorted by key:
2089
2090     foreach $key (sort(keys %ENV)) {
2091         print $key, '=', $ENV{$key}, "\n";
2092     }
2093
2094 To sort a hash by value, you'll need to use a C<sort> function.
2095 Here's a descending numeric sort of a hash by its values:
2096
2097     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2098         printf "%4d %s\n", $hash{$key}, $key;
2099     }
2100
2101 As an lvalue C<keys> allows you to increase the number of hash buckets
2102 allocated for the given hash.  This can gain you a measure of efficiency if
2103 you know the hash is going to get big.  (This is similar to pre-extending
2104 an array by assigning a larger number to $#array.)  If you say
2105
2106     keys %hash = 200;
2107
2108 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2109 in fact, since it rounds up to the next power of two.  These
2110 buckets will be retained even if you do C<%hash = ()>, use C<undef
2111 %hash> if you want to free the storage while C<%hash> is still in scope.
2112 You can't shrink the number of buckets allocated for the hash using
2113 C<keys> in this way (but you needn't worry about doing this by accident,
2114 as trying has no effect).
2115
2116 See also C<each>, C<values> and C<sort>.
2117
2118 =item kill LIST
2119
2120 Sends a signal to a list of processes.  The first element of
2121 the list must be the signal to send.  Returns the number of
2122 processes successfully signaled (which is not necessarily the
2123 same as the number actually killed).
2124
2125     $cnt = kill 1, $child1, $child2;
2126     kill 9, @goners;
2127
2128 Unlike in the shell, in Perl if the I<SIGNAL> is negative, it kills
2129 process groups instead of processes.  (On System V, a negative I<PROCESS>
2130 number will also kill process groups, but that's not portable.)  That
2131 means you usually want to use positive not negative signals.  You may also
2132 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
2133
2134 =item last LABEL
2135
2136 =item last
2137
2138 The C<last> command is like the C<break> statement in C (as used in
2139 loops); it immediately exits the loop in question.  If the LABEL is
2140 omitted, the command refers to the innermost enclosing loop.  The
2141 C<continue> block, if any, is not executed:
2142
2143     LINE: while (<STDIN>) {
2144         last LINE if /^$/;      # exit when done with header
2145         #...
2146     }
2147
2148 C<last> cannot be used to exit a block which returns a value such as
2149 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2150 a grep() or map() operation.
2151
2152 See also L</continue> for an illustration of how C<last>, C<next>, and
2153 C<redo> work.
2154
2155 =item lc EXPR
2156
2157 =item lc
2158
2159 Returns an lowercased version of EXPR.  This is the internal function
2160 implementing the C<\L> escape in double-quoted strings.
2161 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2162 and L<utf8>.
2163
2164 If EXPR is omitted, uses C<$_>.
2165
2166 =item lcfirst EXPR
2167
2168 =item lcfirst
2169
2170 Returns the value of EXPR with the first character lowercased.  This is
2171 the internal function implementing the C<\l> escape in double-quoted strings.
2172 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
2173
2174 If EXPR is omitted, uses C<$_>.
2175
2176 =item length EXPR
2177
2178 =item length
2179
2180 Returns the length in characters of the value of EXPR.  If EXPR is
2181 omitted, returns length of C<$_>.  Note that this cannot be used on 
2182 an entire array or hash to find out how many elements these have.
2183 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2184
2185 =item link OLDFILE,NEWFILE
2186
2187 Creates a new filename linked to the old filename.  Returns true for
2188 success, false otherwise. 
2189
2190 =item listen SOCKET,QUEUESIZE
2191
2192 Does the same thing that the listen system call does.  Returns true if
2193 it succeeded, false otherwise.  See the example in L<perlipc/"Sockets: Client/Server Communication">.
2194
2195 =item local EXPR
2196
2197 You really probably want to be using C<my> instead, because C<local> isn't
2198 what most people think of as "local".  See L<perlsub/"Private Variables
2199 via my()"> for details.
2200
2201 A local modifies the listed variables to be local to the enclosing
2202 block, file, or eval.  If more than one value is listed, the list must
2203 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2204 for details, including issues with tied arrays and hashes.
2205
2206 =item localtime EXPR
2207
2208 Converts a time as returned by the time function to a 9-element list
2209 with the time analyzed for the local time zone.  Typically used as
2210 follows:
2211
2212     #  0    1    2     3     4    5     6     7     8
2213     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2214                                                 localtime(time);
2215
2216 All list elements are numeric, and come straight out of a struct tm.
2217 In particular this means that $mon has the range C<0..11> and $wday
2218 has the range C<0..6> with sunday as day C<0>.  Also, $year is the
2219 number of years since 1900, that is, $year is C<123> in year 2023,
2220 and I<not> simply the last two digits of the year.  If you assume it is,
2221 then you create non-Y2K-compliant programs--and you wouldn't want to do
2222 that, would you?
2223
2224 If EXPR is omitted, uses the current time (C<localtime(time)>).
2225
2226 In scalar context, returns the ctime(3) value:
2227
2228     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2229
2230 This scalar value is B<not> locale dependent, see L<perllocale>, but
2231 instead a Perl builtin.  Also see the C<Time::Local> module
2232 (to convert the second, minutes, hours, ... back to seconds since the
2233 stroke of midnight the 1st of January 1970, the value returned by
2234 time()), and the strftime(3) and mktime(3) function available via the
2235 POSIX module.  To get somewhat similar but locale dependent date
2236 strings, set up your locale environment variables appropriately
2237 (please see L<perllocale>) and try for example:
2238
2239     use POSIX qw(strftime);
2240     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2241
2242 Note that the C<%a> and C<%b>, the short forms of the day of the week
2243 and the month of the year, may not necessarily be three characters wide.
2244
2245 =item lock
2246
2247     lock I<THING>
2248
2249 This function places an advisory lock on a variable, subroutine,
2250 or referenced object contained in I<THING> until the lock goes out
2251 of scope.  This is a built-in function only if your version of Perl
2252 was built with threading enabled, and if you've said C<use Threads>.
2253 Otherwise a user-defined function by this name will be called.  See
2254 L<Thread>.
2255
2256 =item log EXPR
2257
2258 =item log
2259
2260 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2261 returns log of C<$_>.  To get the log of another base, use basic algebra:
2262 The base-N log of a number is equal to the natural log of that number
2263 divided by the natural log of N.  For example:
2264
2265     sub log10 {
2266         my $n = shift;
2267         return log($n)/log(10);
2268     } 
2269
2270 See also L</exp> for the inverse operation.
2271
2272 =item lstat FILEHANDLE
2273
2274 =item lstat EXPR
2275
2276 =item lstat
2277
2278 Does the same thing as the C<stat> function (including setting the
2279 special C<_> filehandle) but stats a symbolic link instead of the file
2280 the symbolic link points to.  If symbolic links are unimplemented on
2281 your system, a normal C<stat> is done.
2282
2283 If EXPR is omitted, stats C<$_>.
2284
2285 =item m//
2286
2287 The match operator.  See L<perlop>.
2288
2289 =item map BLOCK LIST
2290
2291 =item map EXPR,LIST
2292
2293 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2294 C<$_> to each element) and returns the list value composed of the
2295 results of each such evaluation.  In scalar context, returns the
2296 total number of elements so generated.  Evaluates BLOCK or EXPR in
2297 list context, so each element of LIST may produce zero, one, or
2298 more elements in the returned value.
2299
2300     @chars = map(chr, @nums);
2301
2302 translates a list of numbers to the corresponding characters.  And
2303
2304     %hash = map { getkey($_) => $_ } @array;
2305
2306 is just a funny way to write
2307
2308     %hash = ();
2309     foreach $_ (@array) {
2310         $hash{getkey($_)} = $_;
2311     }
2312
2313 Note that, because C<$_> is a reference into the list value, it can
2314 be used to modify the elements of the array.  While this is useful and
2315 supported, it can cause bizarre results if the LIST is not a named array.
2316 Using a regular C<foreach> loop for this purpose would be clearer in
2317 most cases.  See also L</grep> for an array composed of those items of
2318 the original list for which the BLOCK or EXPR evaluates to true.
2319
2320 =item mkdir FILENAME,MASK
2321
2322 Creates the directory specified by FILENAME, with permissions
2323 specified by MASK (as modified by C<umask>).  If it succeeds it
2324 returns true, otherwise it returns false and sets C<$!> (errno).
2325
2326 In general, it is better to create directories with permissive MASK,
2327 and let the user modify that with their C<umask>, than it is to supply
2328 a restrictive MASK and give the user no way to be more permissive.
2329 The exceptions to this rule are when the file or directory should be
2330 kept private (mail files, for instance).  The perlfunc(1) entry on
2331 C<umask> discusses the choice of MASK in more detail.
2332
2333 =item msgctl ID,CMD,ARG
2334
2335 Calls the System V IPC function msgctl(2).  You'll probably have to say
2336
2337     use IPC::SysV;
2338
2339 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2340 then ARG must be a variable which will hold the returned C<msqid_ds>
2341 structure.  Returns like C<ioctl>: the undefined value for error, C<"0 but
2342 true"> for zero, or the actual return value otherwise.  See also
2343 C<IPC::SysV> and C<IPC::Semaphore> documentation.
2344
2345 =item msgget KEY,FLAGS
2346
2347 Calls the System V IPC function msgget(2).  Returns the message queue
2348 id, or the undefined value if there is an error.  See also C<IPC::SysV>
2349 and C<IPC::Msg> documentation.
2350
2351 =item msgsnd ID,MSG,FLAGS
2352
2353 Calls the System V IPC function msgsnd to send the message MSG to the
2354 message queue ID.  MSG must begin with the long integer message type,
2355 which may be created with C<pack("l", $type)>.  Returns true if
2356 successful, or false if there is an error.  See also C<IPC::SysV>
2357 and C<IPC::SysV::Msg> documentation.
2358
2359 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2360
2361 Calls the System V IPC function msgrcv to receive a message from
2362 message queue ID into variable VAR with a maximum message size of
2363 SIZE.  Note that if a message is received, the message type will be
2364 the first thing in VAR, and the maximum length of VAR is SIZE plus the
2365 size of the message type.  Returns true if successful, or false if
2366 there is an error.  See also C<IPC::SysV> and C<IPC::SysV::Msg> documentation.
2367
2368 =item my EXPR
2369
2370 =item my EXPR : ATTRIBUTES
2371
2372 A C<my> declares the listed variables to be local (lexically) to the
2373 enclosing block, file, or C<eval>.  If
2374 more than one value is listed, the list must be placed in parentheses.  See
2375 L<perlsub/"Private Variables via my()"> for details.
2376
2377 =item next LABEL
2378
2379 =item next
2380
2381 The C<next> command is like the C<continue> statement in C; it starts
2382 the next iteration of the loop:
2383
2384     LINE: while (<STDIN>) {
2385         next LINE if /^#/;      # discard comments
2386         #...
2387     }
2388
2389 Note that if there were a C<continue> block on the above, it would get
2390 executed even on discarded lines.  If the LABEL is omitted, the command
2391 refers to the innermost enclosing loop.
2392
2393 C<next> cannot be used to exit a block which returns a value such as
2394 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2395 a grep() or map() operation.
2396
2397 See also L</continue> for an illustration of how C<last>, C<next>, and
2398 C<redo> work.
2399
2400 =item no Module LIST
2401
2402 See the L</use> function, which C<no> is the opposite of.
2403
2404 =item oct EXPR
2405
2406 =item oct
2407
2408 Interprets EXPR as an octal string and returns the corresponding
2409 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2410 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2411 binary string.)  The following will handle decimal, binary, octal, and
2412 hex in the standard Perl or C notation:
2413
2414     $val = oct($val) if $val =~ /^0/;
2415
2416 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2417 in octal), use sprintf() or printf():
2418
2419     $perms = (stat("filename"))[2] & 07777;
2420     $oct_perms = sprintf "%lo", $perms;
2421
2422 The oct() function is commonly used when a string such as C<644> needs
2423 to be converted into a file mode, for example. (Although perl will
2424 automatically convert strings into numbers as needed, this automatic
2425 conversion assumes base 10.)
2426
2427 =item open FILEHANDLE,MODE,EXPR
2428
2429 =item open FILEHANDLE,EXPR
2430
2431 =item open FILEHANDLE
2432
2433 Opens the file whose filename is given by EXPR, and associates it with
2434 FILEHANDLE.  If FILEHANDLE is an expression, its value is used as the
2435 name of the real filehandle wanted.  If EXPR is omitted, the scalar
2436 variable of the same name as the FILEHANDLE contains the filename.
2437 (Note that lexical variables--those declared with C<my>--will not work
2438 for this purpose; so if you're using C<my>, specify EXPR in your call
2439 to open.)  See L<perlopentut> for a kinder, gentler explanation of opening
2440 files.
2441
2442 If MODE is C<'E<lt>'> or nothing, the file is opened for input.
2443 If MODE is C<'E<gt>'>, the file is truncated and opened for
2444 output, being created if necessary.  If MODE is C<'E<gt>E<gt>'>,
2445 the file is opened for appending, again being created if necessary. 
2446 You can put a C<'+'> in front of the C<'E<gt>'> or C<'E<lt>'> to indicate that
2447 you want both read and write access to the file; thus C<'+E<lt>'> is almost
2448 always preferred for read/write updates--the C<'+E<gt>'> mode would clobber the
2449 file first.  You can't usually use either read-write mode for updating
2450 textfiles, since they have variable length records.  See the B<-i>
2451 switch in L<perlrun> for a better approach.  The file is created with
2452 permissions of C<0666> modified by the process' C<umask> value.
2453
2454 These various prefixes correspond to the fopen(3) modes of C<'r'>, C<'r+'>, C<'w'>,
2455 C<'w+'>, C<'a'>, and C<'a+'>.
2456
2457 In the 2-arguments (and 1-argument) form of the call the mode and
2458 filename should be concatenated (in this order), possibly separated by
2459 spaces.  It is possible to omit the mode if the mode is C<'E<lt>'>.
2460
2461 If the filename begins with C<'|'>, the filename is interpreted as a
2462 command to which output is to be piped, and if the filename ends with a
2463 C<'|'>, the filename is interpreted as a command which pipes output to
2464 us.  See L<perlipc/"Using open() for IPC">
2465 for more examples of this.  (You are not allowed to C<open> to a command
2466 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2467 and L<perlipc/"Bidirectional Communication"> for alternatives.)
2468
2469 If MODE is C<'|-'>, the filename is interpreted as a
2470 command to which output is to be piped, and if MODE is
2471 C<'-|'>, the filename is interpreted as a command which pipes output to
2472 us.  In the 2-arguments (and 1-argument) form one should replace dash
2473 (C<'-'>) with the command.  See L<perlipc/"Using open() for IPC">
2474 for more examples of this.  (You are not allowed to C<open> to a command
2475 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2476 and L<perlipc/"Bidirectional Communication"> for alternatives.)
2477
2478 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2479 and opening C<'E<gt>-'> opens STDOUT.  
2480
2481 Open returns
2482 nonzero upon success, the undefined value otherwise.  If the C<open>
2483 involved a pipe, the return value happens to be the pid of the
2484 subprocess.
2485
2486 If you're unfortunate enough to be running Perl on a system that
2487 distinguishes between text files and binary files (modern operating
2488 systems don't care), then you should check out L</binmode> for tips for
2489 dealing with this.  The key distinction between systems that need C<binmode>
2490 and those that don't is their text file formats.  Systems like Unix, MacOS, and
2491 Plan9, which delimit lines with a single character, and which encode that
2492 character in C as C<"\n">, do not need C<binmode>.  The rest need it.
2493
2494 When opening a file, it's usually a bad idea to continue normal execution
2495 if the request failed, so C<open> is frequently used in connection with
2496 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2497 where you want to make a nicely formatted error message (but there are
2498 modules that can help with that problem)) you should always check
2499 the return value from opening a file.  The infrequent exception is when
2500 working with an unopened filehandle is actually what you want to do.
2501
2502 Examples:
2503
2504     $ARTICLE = 100;
2505     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2506     while (<ARTICLE>) {...
2507
2508     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
2509     # if the open fails, output is discarded
2510
2511     open(DBASE, '+<', 'dbase.mine')             # open for update
2512         or die "Can't open 'dbase.mine' for update: $!";
2513
2514     open(DBASE, '+<dbase.mine')                 # ditto
2515         or die "Can't open 'dbase.mine' for update: $!";
2516
2517     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
2518         or die "Can't start caesar: $!";
2519
2520     open(ARTICLE, "caesar <$article |")         # ditto
2521         or die "Can't start caesar: $!";
2522
2523     open(EXTRACT, "|sort >/tmp/Tmp$$")          # $$ is our process id
2524         or die "Can't start sort: $!";
2525
2526     # process argument list of files along with any includes
2527
2528     foreach $file (@ARGV) {
2529         process($file, 'fh00');
2530     }
2531
2532     sub process {
2533         my($filename, $input) = @_;
2534         $input++;               # this is a string increment
2535         unless (open($input, $filename)) {
2536             print STDERR "Can't open $filename: $!\n";
2537             return;
2538         }
2539
2540         local $_;
2541         while (<$input>) {              # note use of indirection
2542             if (/^#include "(.*)"/) {
2543                 process($1, $input);
2544                 next;
2545             }
2546             #...                # whatever
2547         }
2548     }
2549
2550 You may also, in the Bourne shell tradition, specify an EXPR beginning
2551 with C<'E<gt>&'>, in which case the rest of the string is interpreted as the
2552 name of a filehandle (or file descriptor, if numeric) to be
2553 duped and opened.  You may use C<&> after C<E<gt>>, C<E<gt>E<gt>>,
2554 C<E<lt>>, C<+E<gt>>, C<+E<gt>E<gt>>, and C<+E<lt>>.  The
2555 mode you specify should match the mode of the original filehandle.
2556 (Duping a filehandle does not take into account any existing contents of
2557 stdio buffers.)  Duping file handles is not yet supported for 3-argument
2558 open().
2559
2560 Here is a script that saves, redirects, and restores STDOUT and
2561 STDERR:
2562
2563     #!/usr/bin/perl
2564     open(OLDOUT, ">&STDOUT");
2565     open(OLDERR, ">&STDERR");
2566
2567     open(STDOUT, '>', "foo.out") || die "Can't redirect stdout";
2568     open(STDERR, ">&STDOUT")     || die "Can't dup stdout";
2569
2570     select(STDERR); $| = 1;     # make unbuffered
2571     select(STDOUT); $| = 1;     # make unbuffered
2572
2573     print STDOUT "stdout 1\n";  # this works for
2574     print STDERR "stderr 1\n";  # subprocesses too
2575
2576     close(STDOUT);
2577     close(STDERR);
2578
2579     open(STDOUT, ">&OLDOUT");
2580     open(STDERR, ">&OLDERR");
2581
2582     print STDOUT "stdout 2\n";
2583     print STDERR "stderr 2\n";
2584
2585 If you specify C<'E<lt>&=N'>, where C<N> is a number, then Perl will do an
2586 equivalent of C's C<fdopen> of that file descriptor; this is more
2587 parsimonious of file descriptors.  For example:
2588
2589     open(FILEHANDLE, "<&=$fd")
2590
2591 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
2592 with 2-arguments (or 1-argument) form of open(), then
2593 there is an implicit fork done, and the return value of open is the pid
2594 of the child within the parent process, and C<0> within the child
2595 process.  (Use C<defined($pid)> to determine whether the open was successful.)
2596 The filehandle behaves normally for the parent, but i/o to that
2597 filehandle is piped from/to the STDOUT/STDIN of the child process.
2598 In the child process the filehandle isn't opened--i/o happens from/to
2599 the new STDOUT or STDIN.  Typically this is used like the normal
2600 piped open when you want to exercise more control over just how the
2601 pipe command gets executed, such as when you are running setuid, and
2602 don't want to have to scan shell commands for metacharacters.
2603 The following triples are more or less equivalent:
2604
2605     open(FOO, "|tr '[a-z]' '[A-Z]'");
2606     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
2607     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
2608
2609     open(FOO, "cat -n '$file'|");
2610     open(FOO, '-|', "cat -n '$file'");
2611     open(FOO, '-|') || exec 'cat', '-n', $file;
2612
2613 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
2614
2615 NOTE: On any operation that may do a fork, all files opened for output
2616 are flushed before the fork is attempted.  On systems that support a
2617 close-on-exec flag on files, the flag will be set for the newly opened
2618 file descriptor as determined by the value of $^F.  See L<perlvar/$^F>.
2619
2620 Closing any piped filehandle causes the parent process to wait for the
2621 child to finish, and returns the status value in C<$?>.
2622
2623 The filename passed to 2-argument (or 1-argument) form of open()
2624 will have leading and trailing
2625 whitespace deleted, and the normal redirection characters
2626 honored.  This property, known as "magic open", 
2627 can often be used to good effect.  A user could specify a filename of
2628 F<"rsh cat file |">, or you could change certain filenames as needed:
2629
2630     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
2631     open(FH, $filename) or die "Can't open $filename: $!";
2632
2633 Use 3-argument form to open a file with arbitrary weird characters in it,
2634
2635     open(FOO, '<', $file);
2636
2637 otherwise it's necessary to protect any leading and trailing whitespace:
2638
2639     $file =~ s#^(\s)#./$1#;
2640     open(FOO, "< $file\0");
2641
2642 (this may not work on some bizzare filesystems).  One should
2643 conscientiously choose between the the I<magic> and 3-arguments form
2644 of open():
2645
2646     open IN, $ARGV[0];
2647
2648 will allow the user to specify an argument of the form C<"rsh cat file |">,
2649 but will not work on a filename which happens to have a trailing space, while
2650
2651     open IN, '<', $ARGV[0];
2652
2653 will have exactly the opposite restrictions.
2654
2655 If you want a "real" C C<open> (see L<open(2)> on your system), then you
2656 should use the C<sysopen> function, which involves no such magic (but
2657 may use subtly different filemodes than Perl open(), which is mapped
2658 to C fopen()).  This is
2659 another way to protect your filenames from interpretation.  For example:
2660
2661     use IO::Handle;
2662     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
2663         or die "sysopen $path: $!";
2664     $oldfh = select(HANDLE); $| = 1; select($oldfh);
2665     print HANDLE "stuff $$\n");
2666     seek(HANDLE, 0, 0);
2667     print "File contains: ", <HANDLE>;
2668
2669 Using the constructor from the C<IO::Handle> package (or one of its
2670 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
2671 filehandles that have the scope of whatever variables hold references to
2672 them, and automatically close whenever and however you leave that scope:
2673
2674     use IO::File;
2675     #...
2676     sub read_myfile_munged {
2677         my $ALL = shift;
2678         my $handle = new IO::File;
2679         open($handle, "myfile") or die "myfile: $!";
2680         $first = <$handle>
2681             or return ();     # Automatically closed here.
2682         mung $first or die "mung failed";       # Or here.
2683         return $first, <$handle> if $ALL;       # Or here.
2684         $first;                                 # Or here.
2685     }
2686
2687 See L</seek> for some details about mixing reading and writing.
2688
2689 =item opendir DIRHANDLE,EXPR
2690
2691 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
2692 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
2693 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
2694
2695 =item ord EXPR
2696
2697 =item ord
2698
2699 Returns the numeric (ASCII or Unicode) value of the first character of EXPR.  If
2700 EXPR is omitted, uses C<$_>.  For the reverse, see L</chr>.
2701 See L<utf8> for more about Unicode.
2702
2703 =item pack TEMPLATE,LIST
2704
2705 Takes a list of values and packs it into a binary structure,
2706 returning the string containing the structure.  The TEMPLATE is a
2707 sequence of characters that give the order and type of values, as
2708 follows:
2709
2710     a   A string with arbitrary binary data, will be null padded.
2711     A   An ascii string, will be space padded.
2712     Z   A null terminated (asciz) string, will be null padded.
2713
2714     b   A bit string (ascending bit order, like vec()).
2715     B   A bit string (descending bit order).
2716     h   A hex string (low nybble first).
2717     H   A hex string (high nybble first).
2718
2719     c   A signed char value.
2720     C   An unsigned char value.  Only does bytes.  See U for Unicode.
2721
2722     s   A signed short value.
2723     S   An unsigned short value.
2724           (This 'short' is _exactly_ 16 bits, which may differ from
2725            what a local C compiler calls 'short'.  If you want
2726            native-length shorts, use the '!' suffix.)
2727
2728     i   A signed integer value.
2729     I   An unsigned integer value.
2730           (This 'integer' is _at_least_ 32 bits wide.  Its exact
2731            size depends on what a local C compiler calls 'int',
2732            and may even be larger than the 'long' described in
2733            the next item.)
2734
2735     l   A signed long value.
2736     L   An unsigned long value.
2737           (This 'long' is _exactly_ 32 bits, which may differ from
2738            what a local C compiler calls 'long'.  If you want
2739            native-length longs, use the '!' suffix.)
2740
2741     n   A short in "network" (big-endian) order.
2742     N   A long in "network" (big-endian) order.
2743     v   A short in "VAX" (little-endian) order.
2744     V   A long in "VAX" (little-endian) order.
2745           (These 'shorts' and 'longs' are _exactly_ 16 bits and
2746            _exactly_ 32 bits, respectively.)
2747
2748     q   A signed quad (64-bit) value.
2749     Q   An unsigned quad value.
2750           (Quads are available only if your system supports 64-bit
2751            integer values _and_ if Perl has been compiled to support those.
2752            Causes a fatal error otherwise.)
2753
2754     f   A single-precision float in the native format.
2755     d   A double-precision float in the native format.
2756
2757     p   A pointer to a null-terminated string.
2758     P   A pointer to a structure (fixed-length string).
2759
2760     u   A uuencoded string.
2761     U   A Unicode character number.  Encodes to UTF-8 internally.
2762         Works even if C<use utf8> is not in effect.
2763
2764     w   A BER compressed integer.  Its bytes represent an unsigned
2765         integer in base 128, most significant digit first, with as
2766         few digits as possible.  Bit eight (the high bit) is set
2767         on each byte except the last.
2768
2769     x   A null byte.
2770     X   Back up a byte.
2771     @   Null fill to absolute position.
2772
2773 The following rules apply:
2774
2775 =over 8
2776
2777 =item *
2778
2779 Each letter may optionally be followed by a number giving a repeat
2780 count.  With all types except C<"a">, C<"A">, C<"Z">, C<"b">, C<"B">, C<"h">,
2781 C<"H">, and C<"P"> the pack function will gobble up that many values from
2782 the LIST.  A C<*> for the repeat count means to use however many items are
2783 left.
2784
2785 =item *
2786
2787 The C<"a">, C<"A">, and C<"Z"> types gobble just one value, but pack it as a
2788 string of length count, padding with nulls or spaces as necessary.  When
2789 unpacking, C<"A"> strips trailing spaces and nulls, C<"Z"> strips everything
2790 after the first null, and C<"a"> returns data verbatim.
2791
2792 =item *
2793
2794 Likewise, the C<"b"> and C<"B"> fields pack a string that many bits long.
2795
2796 =item *
2797
2798 The C<"h"> and C<"H"> fields pack a string that many nybbles (4-bit groups,
2799 representable as hexadecimal digits, 0-9a-f) long.
2800
2801 =item *
2802
2803 The C<"p"> type packs a pointer to a null-terminated string.  You are
2804 responsible for ensuring the string is not a temporary value (which can
2805 potentially get deallocated before you get around to using the packed result).
2806 The C<"P"> type packs a pointer to a structure of the size indicated by the
2807 length.  A NULL pointer is created if the corresponding value for C<"p"> or
2808 C<"P"> is C<undef>.
2809
2810 =item *
2811
2812 The C<"#"> character allows packing and unpacking of strings where the
2813 packed structure contains a byte count followed by the string itself.
2814 You write I<length-item>C<#>I<string-item>.
2815
2816 The I<length-item> can be any C<pack> template letter,
2817 and describes how the length value is packed.
2818 The ones likely to be of most use are integer-packing ones like
2819 C<"n"> (for Java strings), C<"w"> (for ASN.1 or SNMP)
2820 and C<"N"> (for Sun XDR).
2821
2822 The I<string-item> must, at present, be C<"A*">, C<"a*"> or C<"Z*">.
2823 For C<unpack> the length of the string is obtained from the I<length-item>,
2824 but if you put in the '*' it will be ignored.
2825
2826     unpack 'C#a', "\04Gurusamy";        gives 'Guru'
2827     unpack 'a3#A* A*', '007 Bond  J ';  gives (' Bond','J')
2828     pack 'n#a* w#a*','hello,','world';  gives "\000\006hello,\005world"
2829
2830 The I<length-item> is not returned explicitly from C<unpack>.
2831
2832 Adding a count to the I<length-item> letter
2833 is unlikely to do anything useful,
2834 unless that letter is C<"A">, C<"a"> or C<"Z">.
2835 Packing with a I<length-item> of C<"a"> or C<"Z">
2836 may introduce C<"\000"> characters,
2837 which Perl does not regard as legal in numeric strings.
2838
2839 =item *
2840
2841 The integer types C<"s">, C<"S">, C<"l">, and C<"L"> may be
2842 immediately followed by a C<"!"> suffix to signify native shorts or
2843 longs--as you can see from above for example a bare C<"l"> does mean
2844 exactly 32 bits, the native C<long> (as seen by the local C compiler)
2845 may be larger.  This is an issue mainly in 64-bit platforms.  You can
2846 see whether using C<"!"> makes any difference by
2847
2848         print length(pack("s")), " ", length(pack("s!")), "\n";
2849         print length(pack("l")), " ", length(pack("l!")), "\n";
2850
2851 C<"i!"> and C<"I!"> also work but only because of completeness;
2852 they are identical to C<"i"> and C<"I">.
2853
2854 The actual sizes (in bytes) of native shorts, ints, longs, and long
2855 longs on the platform where Perl was built are also available via
2856 L<Config>:
2857
2858        use Config;
2859        print $Config{shortsize},    "\n";
2860        print $Config{intsize},      "\n";
2861        print $Config{longsize},     "\n";
2862        print $Config{longlongsize}, "\n";
2863
2864 (The C<$Config{longlongsize}> will be empty if your system does
2865 not support long longs.) 
2866
2867 =item *
2868
2869 The integer formats C<"s">, C<"S">, C<"i">, C<"I">, C<"l">, and C<"L">
2870 are inherently non-portable between processors and operating systems
2871 because they obey the native byteorder and endianness.  For example a
2872 4-byte integer 0x87654321 (2271560481 decimal) be ordered natively
2873 (arranged in and handled by the CPU registers) into bytes as
2874  
2875         0x12 0x34 0x56 0x78     # little-endian
2876         0x78 0x56 0x34 0x12     # big-endian
2877  
2878 Basically, the Intel, Alpha, and VAX CPUs and little-endian, while
2879 everybody else, for example Motorola m68k/88k, PPC, Sparc, HP PA,
2880 Power, and Cray are big-endian.  MIPS can be either: Digital used it
2881 in little-endian mode; SGI uses it in big-endian mode.
2882
2883 The names `big-endian' and `little-endian' are comic references to
2884 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
2885 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
2886 the egg-eating habits of the Lilliputians.
2887  
2888 Some systems may even have weird byte orders such as
2889  
2890         0x56 0x78 0x12 0x34
2891         0x34 0x12 0x78 0x56
2892  
2893 You can see your system's preference with
2894
2895         print join(" ", map { sprintf "%#02x", $_ }
2896                             unpack("C*",pack("L",0x12345678))), "\n";
2897
2898 The byteorder on the platform where Perl was built is also available
2899 via L<Config>:
2900
2901         use Config;
2902         print $Config{byteorder}, "\n";
2903
2904 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
2905 and C<'87654321'> are big-endian.
2906
2907 If you want portable packed integers use the formats C<"n">, C<"N">,
2908 C<"v">, and C<"V">, their byte endianness and size is known.
2909 See also L<perlport>.
2910
2911 =item *
2912
2913 Real numbers (floats and doubles) are in the native machine format only;
2914 due to the multiplicity of floating formats around, and the lack of a
2915 standard "network" representation, no facility for interchange has been
2916 made.  This means that packed floating point data written on one machine
2917 may not be readable on another - even if both use IEEE floating point
2918 arithmetic (as the endian-ness of the memory representation is not part
2919 of the IEEE spec).  See also L<perlport>.
2920
2921 Note that Perl uses doubles internally for all numeric calculation, and
2922 converting from double into float and thence back to double again will
2923 lose precision (i.e., C<unpack("f", pack("f", $foo)>) will not in general
2924 equal $foo).
2925
2926 =item *
2927
2928 You must yourself do any alignment or padding by inserting for example
2929 enough C<'x'>es while packing.  There is no way to pack() and unpack()
2930 could know where the bytes are going to or coming from.  Therefore
2931 C<pack> (and C<unpack>) handle their output and input as flat
2932 sequences of bytes.
2933
2934 =back
2935
2936 Examples:
2937
2938     $foo = pack("CCCC",65,66,67,68);
2939     # foo eq "ABCD"
2940     $foo = pack("C4",65,66,67,68);
2941     # same thing
2942     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
2943     # same thing with Unicode circled letters
2944
2945     $foo = pack("ccxxcc",65,66,67,68);
2946     # foo eq "AB\0\0CD"
2947
2948     # note: the above examples featuring "C" and "c" are true
2949     # only on ASCII and ASCII-derived systems such as ISO Latin 1
2950     # and UTF-8.  In EBCDIC the first example would be
2951     # $foo = pack("CCCC",193,194,195,196);
2952
2953     $foo = pack("s2",1,2);
2954     # "\1\0\2\0" on little-endian
2955     # "\0\1\0\2" on big-endian
2956
2957     $foo = pack("a4","abcd","x","y","z");
2958     # "abcd"
2959
2960     $foo = pack("aaaa","abcd","x","y","z");
2961     # "axyz"
2962
2963     $foo = pack("a14","abcdefg");
2964     # "abcdefg\0\0\0\0\0\0\0"
2965
2966     $foo = pack("i9pl", gmtime);
2967     # a real struct tm (on my system anyway)
2968
2969     $utmp_template = "Z8 Z8 Z16 L";
2970     $utmp = pack($utmp_template, @utmp1);
2971     # a struct utmp (BSDish)
2972
2973     @utmp2 = unpack($utmp_template, $utmp);
2974     # "@utmp1" eq "@utmp2"
2975
2976     sub bintodec {
2977         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
2978     }
2979
2980     $foo = pack('sx2l', 12, 34);
2981     # short 12, two zero bytes padding, long 34
2982     $bar = pack('s@4l', 12, 34);
2983     # short 12, zero fill to position 4, long 34
2984     # $foo eq $bar
2985
2986 The same template may generally also be used in unpack().
2987
2988 =item package 
2989
2990 =item package NAMESPACE
2991
2992 Declares the compilation unit as being in the given namespace.  The scope
2993 of the package declaration is from the declaration itself through the end
2994 of the enclosing block, file, or eval (the same as the C<my> operator).
2995 All further unqualified dynamic identifiers will be in this namespace.
2996 A package statement affects only dynamic variables--including those
2997 you've used C<local> on--but I<not> lexical variables, which are created
2998 with C<my>.  Typically it would be the first declaration in a file to
2999 be included by the C<require> or C<use> operator.  You can switch into a
3000 package in more than one place; it merely influences which symbol table
3001 is used by the compiler for the rest of that block.  You can refer to
3002 variables and filehandles in other packages by prefixing the identifier
3003 with the package name and a double colon:  C<$Package::Variable>.
3004 If the package name is null, the C<main> package as assumed.  That is,
3005 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3006 still seen in older code).
3007
3008 If NAMESPACE is omitted, then there is no current package, and all
3009 identifiers must be fully qualified or lexicals.  This is stricter
3010 than C<use strict>, since it also extends to function names.
3011
3012 See L<perlmod/"Packages"> for more information about packages, modules,
3013 and classes.  See L<perlsub> for other scoping issues.
3014
3015 =item pipe READHANDLE,WRITEHANDLE
3016
3017 Opens a pair of connected pipes like the corresponding system call.
3018 Note that if you set up a loop of piped processes, deadlock can occur
3019 unless you are very careful.  In addition, note that Perl's pipes use
3020 stdio buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3021 after each command, depending on the application.
3022
3023 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3024 for examples of such things.
3025
3026 On systems that support a close-on-exec flag on files, the flag will be set
3027 for the newly opened file descriptors as determined by the value of $^F.
3028 See L<perlvar/$^F>.
3029
3030 =item pop ARRAY
3031
3032 =item pop
3033
3034 Pops and returns the last value of the array, shortening the array by
3035 one element.  Has an effect similar to
3036
3037     $ARRAY[$#ARRAY--]
3038
3039 If there are no elements in the array, returns the undefined value
3040 (although this may happen at other times as well).  If ARRAY is
3041 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3042 array in subroutines, just like C<shift>.
3043
3044 =item pos SCALAR
3045
3046 =item pos
3047
3048 Returns the offset of where the last C<m//g> search left off for the variable
3049 is in question (C<$_> is used when the variable is not specified).  May be
3050 modified to change that offset.  Such modification will also influence
3051 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
3052 L<perlop>.
3053
3054 =item print FILEHANDLE LIST
3055
3056 =item print LIST
3057
3058 =item print
3059
3060 Prints a string or a list of strings.  Returns true if successful.
3061 FILEHANDLE may be a scalar variable name, in which case the variable
3062 contains the name of or a reference to the filehandle, thus introducing
3063 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3064 the next token is a term, it may be misinterpreted as an operator
3065 unless you interpose a C<+> or put parentheses around the arguments.)
3066 If FILEHANDLE is omitted, prints by default to standard output (or
3067 to the last selected output channel--see L</select>).  If LIST is
3068 also omitted, prints C<$_> to the currently selected output channel.
3069 To set the default output channel to something other than STDOUT
3070 use the select operation.  The current value of C<$,> (if any) is
3071 printed between each LIST item.  The current value of C<$\> (if
3072 any) is printed after the entire LIST has been printed.  Because
3073 print takes a LIST, anything in the LIST is evaluated in list
3074 context, and any subroutine that you call will have one or more of
3075 its expressions evaluated in list context.  Also be careful not to
3076 follow the print keyword with a left parenthesis unless you want
3077 the corresponding right parenthesis to terminate the arguments to
3078 the print--interpose a C<+> or put parentheses around all the
3079 arguments.
3080
3081 Note that if you're storing FILEHANDLES in an array or other expression,
3082 you will have to use a block returning its value instead:
3083
3084     print { $files[$i] } "stuff\n";
3085     print { $OK ? STDOUT : STDERR } "stuff\n";
3086
3087 =item printf FILEHANDLE FORMAT, LIST
3088
3089 =item printf FORMAT, LIST
3090
3091 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3092 (the output record separator) is not appended.  The first argument
3093 of the list will be interpreted as the C<printf> format.  If C<use locale> is
3094 in effect, the character used for the decimal point in formatted real numbers
3095 is affected by the LC_NUMERIC locale.  See L<perllocale>.
3096
3097 Don't fall into the trap of using a C<printf> when a simple
3098 C<print> would do.  The C<print> is more efficient and less
3099 error prone.
3100
3101 =item prototype FUNCTION
3102
3103 Returns the prototype of a function as a string (or C<undef> if the
3104 function has no prototype).  FUNCTION is a reference to, or the name of,
3105 the function whose prototype you want to retrieve.
3106
3107 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
3108 name for Perl builtin.  If the builtin is not I<overridable> (such as
3109 C<qw//>) or its arguments cannot be expressed by a prototype (such as
3110 C<system>) returns C<undef> because the builtin does not really behave
3111 like a Perl function.  Otherwise, the string describing the equivalent
3112 prototype is returned.
3113
3114 =item push ARRAY,LIST
3115
3116 Treats ARRAY as a stack, and pushes the values of LIST
3117 onto the end of ARRAY.  The length of ARRAY increases by the length of
3118 LIST.  Has the same effect as
3119
3120     for $value (LIST) {
3121         $ARRAY[++$#ARRAY] = $value;
3122     }
3123
3124 but is more efficient.  Returns the new number of elements in the array.
3125
3126 =item q/STRING/
3127
3128 =item qq/STRING/
3129
3130 =item qr/STRING/
3131
3132 =item qx/STRING/
3133
3134 =item qw/STRING/
3135
3136 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
3137
3138 =item quotemeta EXPR
3139
3140 =item quotemeta
3141
3142 Returns the value of EXPR with all non-alphanumeric
3143 characters backslashed.  (That is, all characters not matching
3144 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
3145 returned string, regardless of any locale settings.)
3146 This is the internal function implementing
3147 the C<\Q> escape in double-quoted strings.
3148
3149 If EXPR is omitted, uses C<$_>.
3150
3151 =item rand EXPR
3152
3153 =item rand
3154
3155 Returns a random fractional number greater than or equal to C<0> and less
3156 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
3157 omitted, the value C<1> is used.  Automatically calls C<srand> unless
3158 C<srand> has already been called.  See also C<srand>.
3159
3160 (Note: If your rand function consistently returns numbers that are too
3161 large or too small, then your version of Perl was probably compiled
3162 with the wrong number of RANDBITS.)
3163
3164 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
3165
3166 =item read FILEHANDLE,SCALAR,LENGTH
3167
3168 Attempts to read LENGTH bytes of data into variable SCALAR from the
3169 specified FILEHANDLE.  Returns the number of bytes actually read,
3170 C<0> at end of file, or undef if there was an error.  SCALAR will be grown
3171 or shrunk to the length actually read.  An OFFSET may be specified to
3172 place the read data at some other place than the beginning of the
3173 string.  This call is actually implemented in terms of stdio's fread(3)
3174 call.  To get a true read(2) system call, see C<sysread>.
3175
3176 =item readdir DIRHANDLE
3177
3178 Returns the next directory entry for a directory opened by C<opendir>.
3179 If used in list context, returns all the rest of the entries in the
3180 directory.  If there are no more entries, returns an undefined value in
3181 scalar context or a null list in list context.
3182
3183 If you're planning to filetest the return values out of a C<readdir>, you'd
3184 better prepend the directory in question.  Otherwise, because we didn't
3185 C<chdir> there, it would have been testing the wrong file.
3186
3187     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
3188     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
3189     closedir DIR;
3190
3191 =item readline EXPR
3192
3193 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
3194 context, each call reads and returns the next line, until end-of-file is
3195 reached, whereupon the subsequent call returns undef.  In list context,
3196 reads until end-of-file is reached and returns a list of lines.  Note that
3197 the notion of "line" used here is however you may have defined it
3198 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
3199
3200 When C<$/> is set to C<undef>, when readline() is in scalar
3201 context (i.e. file slurp mode), and when an empty file is read, it
3202 returns C<''> the first time, followed by C<undef> subsequently.
3203
3204 This is the internal function implementing the C<E<lt>EXPRE<gt>>
3205 operator, but you can use it directly.  The C<E<lt>EXPRE<gt>>
3206 operator is discussed in more detail in L<perlop/"I/O Operators">.
3207
3208     $line = <STDIN>;
3209     $line = readline(*STDIN);           # same thing
3210
3211 =item readlink EXPR
3212
3213 =item readlink
3214
3215 Returns the value of a symbolic link, if symbolic links are
3216 implemented.  If not, gives a fatal error.  If there is some system
3217 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
3218 omitted, uses C<$_>.
3219
3220 =item readpipe EXPR
3221
3222 EXPR is executed as a system command.
3223 The collected standard output of the command is returned.
3224 In scalar context, it comes back as a single (potentially
3225 multi-line) string.  In list context, returns a list of lines
3226 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
3227 This is the internal function implementing the C<qx/EXPR/>
3228 operator, but you can use it directly.  The C<qx/EXPR/>
3229 operator is discussed in more detail in L<perlop/"I/O Operators">.
3230
3231 =item recv SOCKET,SCALAR,LENGTH,FLAGS
3232
3233 Receives a message on a socket.  Attempts to receive LENGTH bytes of
3234 data into variable SCALAR from the specified SOCKET filehandle.
3235 Actually does a C C<recvfrom>, so that it can return the address of the
3236 sender.  Returns the undefined value if there's an error.  SCALAR will
3237 be grown or shrunk to the length actually read.  Takes the same flags
3238 as the system call of the same name.
3239 See L<perlipc/"UDP: Message Passing"> for examples.
3240
3241 =item redo LABEL
3242
3243 =item redo
3244
3245 The C<redo> command restarts the loop block without evaluating the
3246 conditional again.  The C<continue> block, if any, is not executed.  If
3247 the LABEL is omitted, the command refers to the innermost enclosing
3248 loop.  This command is normally used by programs that want to lie to
3249 themselves about what was just input:
3250
3251     # a simpleminded Pascal comment stripper
3252     # (warning: assumes no { or } in strings)
3253     LINE: while (<STDIN>) {
3254         while (s|({.*}.*){.*}|$1 |) {}
3255         s|{.*}| |;
3256         if (s|{.*| |) {
3257             $front = $_;
3258             while (<STDIN>) {
3259                 if (/}/) {      # end of comment?
3260                     s|^|$front\{|;
3261                     redo LINE;
3262                 }
3263             }
3264         }
3265         print;
3266     }
3267
3268 C<redo> cannot be used to retry a block which returns a value such as
3269 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
3270 a grep() or map() operation.
3271
3272 See also L</continue> for an illustration of how C<last>, C<next>, and
3273 C<redo> work.
3274
3275 =item ref EXPR
3276
3277 =item ref
3278
3279 Returns a true value if EXPR is a reference, false otherwise.  If EXPR
3280 is not specified, C<$_> will be used.  The value returned depends on the
3281 type of thing the reference is a reference to.
3282 Builtin types include:
3283
3284     SCALAR
3285     ARRAY
3286     HASH
3287     CODE
3288     REF
3289     GLOB
3290     LVALUE
3291
3292 If the referenced object has been blessed into a package, then that package
3293 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
3294
3295     if (ref($r) eq "HASH") {
3296         print "r is a reference to a hash.\n";
3297     }
3298     unless (ref($r)) {
3299         print "r is not a reference at all.\n";
3300     }
3301     if (UNIVERSAL::isa($r, "HASH")) {  # for subclassing
3302         print "r is a reference to something that isa hash.\n";
3303     } 
3304
3305 See also L<perlref>.
3306
3307 =item rename OLDNAME,NEWNAME
3308
3309 Changes the name of a file; an existing file NEWNAME will be
3310 clobbered.  Returns true for success, false otherwise.
3311
3312 Behavior of this function varies wildly depending on your system
3313 implementation.  For example, it will usually not work across file system
3314 boundaries, even though the system I<mv> command sometimes compensates
3315 for this.  Other restrictions include whether it works on directories,
3316 open files, or pre-existing files.  Check L<perlport> and either the
3317 rename(2) manpage or equivalent system documentation for details.
3318
3319 =item require EXPR
3320
3321 =item require
3322
3323 Demands some semantics specified by EXPR, or by C<$_> if EXPR is not
3324 supplied.  If EXPR is numeric, demands that the current version of Perl
3325 (C<$]> or $PERL_VERSION) be equal or greater than EXPR.
3326
3327 Otherwise, demands that a library file be included if it hasn't already
3328 been included.  The file is included via the do-FILE mechanism, which is
3329 essentially just a variety of C<eval>.  Has semantics similar to the following
3330 subroutine:
3331
3332     sub require {
3333         my($filename) = @_;
3334         return 1 if $INC{$filename};
3335         my($realfilename,$result);
3336         ITER: {
3337             foreach $prefix (@INC) {
3338                 $realfilename = "$prefix/$filename";
3339                 if (-f $realfilename) {
3340                     $result = do $realfilename;
3341                     last ITER;
3342                 }
3343             }
3344             die "Can't find $filename in \@INC";
3345         }
3346         die $@ if $@;
3347         die "$filename did not return true value" unless $result;
3348         $INC{$filename} = $realfilename;
3349         return $result;
3350     }
3351
3352 Note that the file will not be included twice under the same specified
3353 name.  The file must return true as the last statement to indicate
3354 successful execution of any initialization code, so it's customary to
3355 end such a file with C<1;> unless you're sure it'll return true
3356 otherwise.  But it's better just to put the C<1;>, in case you add more
3357 statements.
3358
3359 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
3360 replaces "F<::>" with "F</>" in the filename for you,
3361 to make it easy to load standard modules.  This form of loading of
3362 modules does not risk altering your namespace.
3363
3364 In other words, if you try this:
3365
3366         require Foo::Bar;    # a splendid bareword 
3367
3368 The require function will actually look for the "F<Foo/Bar.pm>" file in the 
3369 directories specified in the C<@INC> array.
3370
3371 But if you try this:
3372
3373         $class = 'Foo::Bar';
3374         require $class;      # $class is not a bareword
3375     #or
3376         require "Foo::Bar";  # not a bareword because of the ""
3377
3378 The require function will look for the "F<Foo::Bar>" file in the @INC array and 
3379 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
3380
3381         eval "require $class";
3382
3383 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
3384
3385 =item reset EXPR
3386
3387 =item reset
3388
3389 Generally used in a C<continue> block at the end of a loop to clear
3390 variables and reset C<??> searches so that they work again.  The
3391 expression is interpreted as a list of single characters (hyphens
3392 allowed for ranges).  All variables and arrays beginning with one of
3393 those letters are reset to their pristine state.  If the expression is
3394 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
3395 only variables or searches in the current package.  Always returns
3396 1.  Examples:
3397
3398     reset 'X';          # reset all X variables
3399     reset 'a-z';        # reset lower case variables
3400     reset;              # just reset ?one-time? searches
3401
3402 Resetting C<"A-Z"> is not recommended because you'll wipe out your
3403 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
3404 variables--lexical variables are unaffected, but they clean themselves
3405 up on scope exit anyway, so you'll probably want to use them instead.
3406 See L</my>.
3407
3408 =item return EXPR
3409
3410 =item return
3411
3412 Returns from a subroutine, C<eval>, or C<do FILE> with the value 
3413 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
3414 context, depending on how the return value will be used, and the context
3415 may vary from one execution to the next (see C<wantarray>).  If no EXPR
3416 is given, returns an empty list in list context, the undefined value in
3417 scalar context, and (of course) nothing at all in a void context.
3418
3419 (Note that in the absence of a explicit C<return>, a subroutine, eval,
3420 or do FILE will automatically return the value of the last expression
3421 evaluated.)
3422
3423 =item reverse LIST
3424
3425 In list context, returns a list value consisting of the elements
3426 of LIST in the opposite order.  In scalar context, concatenates the
3427 elements of LIST and returns a string value with all characters
3428 in the opposite order.
3429
3430     print reverse <>;           # line tac, last line first
3431
3432     undef $/;                   # for efficiency of <>
3433     print scalar reverse <>;    # character tac, last line tsrif
3434
3435 This operator is also handy for inverting a hash, although there are some
3436 caveats.  If a value is duplicated in the original hash, only one of those
3437 can be represented as a key in the inverted hash.  Also, this has to
3438 unwind one hash and build a whole new one, which may take some time
3439 on a large hash, such as from a DBM file.
3440
3441     %by_name = reverse %by_address;     # Invert the hash
3442
3443 =item rewinddir DIRHANDLE
3444
3445 Sets the current position to the beginning of the directory for the
3446 C<readdir> routine on DIRHANDLE.
3447
3448 =item rindex STR,SUBSTR,POSITION
3449
3450 =item rindex STR,SUBSTR
3451
3452 Works just like index() except that it returns the position of the LAST
3453 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
3454 last occurrence at or before that position.
3455
3456 =item rmdir FILENAME
3457
3458 =item rmdir
3459
3460 Deletes the directory specified by FILENAME if that directory is empty.  If it
3461 succeeds it returns true, otherwise it returns false and sets C<$!> (errno).  If
3462 FILENAME is omitted, uses C<$_>.
3463
3464 =item s///
3465
3466 The substitution operator.  See L<perlop>.
3467
3468 =item scalar EXPR
3469
3470 Forces EXPR to be interpreted in scalar context and returns the value
3471 of EXPR.
3472
3473     @counts = ( scalar @a, scalar @b, scalar @c );
3474
3475 There is no equivalent operator to force an expression to
3476 be interpolated in list context because in practice, this is never
3477 needed.  If you really wanted to do so, however, you could use
3478 the construction C<@{[ (some expression) ]}>, but usually a simple
3479 C<(some expression)> suffices.
3480
3481 Because C<scalar> is unary operator, if you accidentally use for EXPR a
3482 parenthesized list, this behaves as a scalar comma expression, evaluating
3483 all but the last element in void context and returning the final element
3484 evaluated in scalar context.  This is seldom what you want.
3485
3486 The following single statement:
3487
3488         print uc(scalar(&foo,$bar)),$baz;
3489
3490 is the moral equivalent of these two:
3491
3492         &foo;
3493         print(uc($bar),$baz);
3494
3495 See L<perlop> for more details on unary operators and the comma operator.
3496
3497 =item seek FILEHANDLE,POSITION,WHENCE
3498
3499 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
3500 FILEHANDLE may be an expression whose value gives the name of the
3501 filehandle.  The values for WHENCE are C<0> to set the new position to
3502 POSITION, C<1> to set it to the current position plus POSITION, and
3503 C<2> to set it to EOF plus POSITION (typically negative).  For WHENCE
3504 you may use the constants C<SEEK_SET>, C<SEEK_CUR>, and C<SEEK_END>
3505 (start of the file, current position, end of the file) from any of the
3506 modules Fcntl, C<IO::Seekable>, or POSIX.  Returns C<1> upon success,
3507 C<0> otherwise.
3508
3509 If you want to position file for C<sysread> or C<syswrite>, don't use
3510 C<seek>--buffering makes its effect on the file's system position
3511 unpredictable and non-portable.  Use C<sysseek> instead.
3512
3513 Due to the rules and rigors of ANSI C, on some systems you have to do a
3514 seek whenever you switch between reading and writing.  Amongst other
3515 things, this may have the effect of calling stdio's clearerr(3).
3516 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
3517
3518     seek(TEST,0,1);
3519
3520 This is also useful for applications emulating C<tail -f>.  Once you hit
3521 EOF on your read, and then sleep for a while, you might have to stick in a
3522 seek() to reset things.  The C<seek> doesn't change the current position,
3523 but it I<does> clear the end-of-file condition on the handle, so that the
3524 next C<E<lt>FILEE<gt>> makes Perl try again to read something.  We hope.
3525
3526 If that doesn't work (some stdios are particularly cantankerous), then
3527 you may need something more like this:
3528
3529     for (;;) {
3530         for ($curpos = tell(FILE); $_ = <FILE>;
3531              $curpos = tell(FILE)) {
3532             # search for some stuff and put it into files
3533         }
3534         sleep($for_a_while);
3535         seek(FILE, $curpos, 0);
3536     }
3537
3538 =item seekdir DIRHANDLE,POS
3539
3540 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
3541 must be a value returned by C<telldir>.  Has the same caveats about
3542 possible directory compaction as the corresponding system library
3543 routine.
3544
3545 =item select FILEHANDLE
3546
3547 =item select
3548
3549 Returns the currently selected filehandle.  Sets the current default
3550 filehandle for output, if FILEHANDLE is supplied.  This has two
3551 effects: first, a C<write> or a C<print> without a filehandle will
3552 default to this FILEHANDLE.  Second, references to variables related to
3553 output will refer to this output channel.  For example, if you have to
3554 set the top of form format for more than one output channel, you might
3555 do the following:
3556
3557     select(REPORT1);
3558     $^ = 'report1_top';
3559     select(REPORT2);
3560     $^ = 'report2_top';
3561
3562 FILEHANDLE may be an expression whose value gives the name of the
3563 actual filehandle.  Thus:
3564
3565     $oldfh = select(STDERR); $| = 1; select($oldfh);
3566
3567 Some programmers may prefer to think of filehandles as objects with
3568 methods, preferring to write the last example as:
3569
3570     use IO::Handle;
3571     STDERR->autoflush(1);
3572
3573 =item select RBITS,WBITS,EBITS,TIMEOUT
3574
3575 This calls the select(2) system call with the bit masks specified, which
3576 can be constructed using C<fileno> and C<vec>, along these lines:
3577
3578     $rin = $win = $ein = '';
3579     vec($rin,fileno(STDIN),1) = 1;
3580     vec($win,fileno(STDOUT),1) = 1;
3581     $ein = $rin | $win;
3582
3583 If you want to select on many filehandles you might wish to write a
3584 subroutine:
3585
3586     sub fhbits {
3587         my(@fhlist) = split(' ',$_[0]);
3588         my($bits);
3589         for (@fhlist) {
3590             vec($bits,fileno($_),1) = 1;
3591         }
3592         $bits;
3593     }
3594     $rin = fhbits('STDIN TTY SOCK');
3595
3596 The usual idiom is:
3597
3598     ($nfound,$timeleft) =
3599       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
3600
3601 or to block until something becomes ready just do this
3602
3603     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
3604
3605 Most systems do not bother to return anything useful in $timeleft, so
3606 calling select() in scalar context just returns $nfound.
3607
3608 Any of the bit masks can also be undef.  The timeout, if specified, is
3609 in seconds, which may be fractional.  Note: not all implementations are
3610 capable of returning the$timeleft.  If not, they always return
3611 $timeleft equal to the supplied $timeout.
3612
3613 You can effect a sleep of 250 milliseconds this way:
3614
3615     select(undef, undef, undef, 0.25);
3616
3617 B<WARNING>: One should not attempt to mix buffered I/O (like C<read>
3618 or E<lt>FHE<gt>) with C<select>, except as permitted by POSIX, and even
3619 then only on POSIX systems.  You have to use C<sysread> instead.
3620
3621 =item semctl ID,SEMNUM,CMD,ARG
3622
3623 Calls the System V IPC function C<semctl>.  You'll probably have to say
3624
3625     use IPC::SysV;
3626
3627 first to get the correct constant definitions.  If CMD is IPC_STAT or
3628 GETALL, then ARG must be a variable which will hold the returned
3629 semid_ds structure or semaphore value array.  Returns like C<ioctl>: the
3630 undefined value for error, "C<0 but true>" for zero, or the actual return
3631 value otherwise.  See also C<IPC::SysV> and C<IPC::Semaphore> documentation.
3632
3633 =item semget KEY,NSEMS,FLAGS
3634
3635 Calls the System V IPC function semget.  Returns the semaphore id, or
3636 the undefined value if there is an error.  See also C<IPC::SysV> and
3637 C<IPC::SysV::Semaphore> documentation.
3638
3639 =item semop KEY,OPSTRING
3640
3641 Calls the System V IPC function semop to perform semaphore operations
3642 such as signaling and waiting.  OPSTRING must be a packed array of
3643 semop structures.  Each semop structure can be generated with
3644 C<pack("sss", $semnum, $semop, $semflag)>.  The number of semaphore
3645 operations is implied by the length of OPSTRING.  Returns true if
3646 successful, or false if there is an error.  As an example, the
3647 following code waits on semaphore $semnum of semaphore id $semid:
3648
3649     $semop = pack("sss", $semnum, -1, 0);
3650     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
3651
3652 To signal the semaphore, replace C<-1> with C<1>.  See also C<IPC::SysV>
3653 and C<IPC::SysV::Semaphore> documentation.
3654
3655 =item send SOCKET,MSG,FLAGS,TO
3656
3657 =item send SOCKET,MSG,FLAGS
3658
3659 Sends a message on a socket.  Takes the same flags as the system call
3660 of the same name.  On unconnected sockets you must specify a
3661 destination to send TO, in which case it does a C C<sendto>.  Returns
3662 the number of characters sent, or the undefined value if there is an
3663 error.  The C system call sendmsg(2) is currently unimplemented.
3664 See L<perlipc/"UDP: Message Passing"> for examples.
3665
3666 =item setpgrp PID,PGRP
3667
3668 Sets the current process group for the specified PID, C<0> for the current
3669 process.  Will produce a fatal error if used on a machine that doesn't
3670 implement setpgrp(2).  If the arguments are omitted, it defaults to
3671 C<0,0>.  Note that the POSIX version of C<setpgrp> does not accept any
3672 arguments, so only C<setpgrp(0,0)> is portable.  See also C<POSIX::setsid()>.
3673
3674 =item setpriority WHICH,WHO,PRIORITY
3675
3676 Sets the current priority for a process, a process group, or a user.
3677 (See setpriority(2).)  Will produce a fatal error if used on a machine
3678 that doesn't implement setpriority(2).
3679
3680 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
3681
3682 Sets the socket option requested.  Returns undefined if there is an
3683 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
3684 argument.
3685
3686 =item shift ARRAY
3687
3688 =item shift
3689
3690 Shifts the first value of the array off and returns it, shortening the
3691 array by 1 and moving everything down.  If there are no elements in the
3692 array, returns the undefined value.  If ARRAY is omitted, shifts the
3693 C<@_> array within the lexical scope of subroutines and formats, and the
3694 C<@ARGV> array at file scopes or within the lexical scopes established by
3695 the C<eval ''>, C<BEGIN {}>, C<END {}>, and C<INIT {}> constructs.
3696 See also C<unshift>, C<push>, and C<pop>.  C<Shift()> and C<unshift> do the
3697 same thing to the left end of an array that C<pop> and C<push> do to the
3698 right end.
3699
3700 =item shmctl ID,CMD,ARG
3701
3702 Calls the System V IPC function shmctl.  You'll probably have to say
3703
3704     use IPC::SysV;
3705
3706 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3707 then ARG must be a variable which will hold the returned C<shmid_ds>
3708 structure.  Returns like ioctl: the undefined value for error, "C<0> but
3709 true" for zero, or the actual return value otherwise.
3710 See also C<IPC::SysV> documentation.
3711
3712 =item shmget KEY,SIZE,FLAGS
3713
3714 Calls the System V IPC function shmget.  Returns the shared memory
3715 segment id, or the undefined value if there is an error.
3716 See also C<IPC::SysV> documentation.
3717
3718 =item shmread ID,VAR,POS,SIZE
3719
3720 =item shmwrite ID,STRING,POS,SIZE
3721
3722 Reads or writes the System V shared memory segment ID starting at
3723 position POS for size SIZE by attaching to it, copying in/out, and
3724 detaching from it.  When reading, VAR must be a variable that will
3725 hold the data read.  When writing, if STRING is too long, only SIZE
3726 bytes are used; if STRING is too short, nulls are written to fill out
3727 SIZE bytes.  Return true if successful, or false if there is an error.
3728 See also C<IPC::SysV> documentation and the C<IPC::Shareable> module
3729 from CPAN.
3730
3731 =item shutdown SOCKET,HOW
3732
3733 Shuts down a socket connection in the manner indicated by HOW, which
3734 has the same interpretation as in the system call of the same name.
3735
3736     shutdown(SOCKET, 0);    # I/we have stopped reading data
3737     shutdown(SOCKET, 1);    # I/we have stopped writing data
3738     shutdown(SOCKET, 2);    # I/we have stopped using this socket
3739
3740 This is useful with sockets when you want to tell the other
3741 side you're done writing but not done reading, or vice versa.
3742 It's also a more insistent form of close because it also 
3743 disables the file descriptor in any forked copies in other
3744 processes.
3745
3746 =item sin EXPR
3747
3748 =item sin
3749
3750 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
3751 returns sine of C<$_>.
3752
3753 For the inverse sine operation, you may use the C<POSIX::asin>
3754 function, or use this relation:
3755
3756     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
3757
3758 =item sleep EXPR
3759
3760 =item sleep
3761
3762 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
3763 May be interrupted if the process receives a signal such as C<SIGALRM>.
3764 Returns the number of seconds actually slept.  You probably cannot
3765 mix C<alarm> and C<sleep> calls, because C<sleep> is often implemented
3766 using C<alarm>.
3767
3768 On some older systems, it may sleep up to a full second less than what
3769 you requested, depending on how it counts seconds.  Most modern systems
3770 always sleep the full amount.  They may appear to sleep longer than that,
3771 however, because your process might not be scheduled right away in a
3772 busy multitasking system.
3773
3774 For delays of finer granularity than one second, you may use Perl's
3775 C<syscall> interface to access setitimer(2) if your system supports
3776 it, or else see L</select> above.  The Time::HiRes module from CPAN
3777 may also help.
3778
3779 See also the POSIX module's C<sigpause> function.
3780
3781 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
3782
3783 Opens a socket of the specified kind and attaches it to filehandle
3784 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for
3785 the system call of the same name.  You should C<use Socket> first
3786 to get the proper definitions imported.  See the examples in
3787 L<perlipc/"Sockets: Client/Server Communication">.
3788
3789 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
3790
3791 Creates an unnamed pair of sockets in the specified domain, of the
3792 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
3793 for the system call of the same name.  If unimplemented, yields a fatal
3794 error.  Returns true if successful.
3795
3796 Some systems defined C<pipe> in terms of C<socketpair>, in which a call
3797 to C<pipe(Rdr, Wtr)> is essentially:
3798
3799     use Socket;
3800     socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
3801     shutdown(Rdr, 1);        # no more writing for reader
3802     shutdown(Wtr, 0);        # no more reading for writer
3803
3804 See L<perlipc> for an example of socketpair use.
3805
3806 =item sort SUBNAME LIST
3807
3808 =item sort BLOCK LIST
3809
3810 =item sort LIST
3811
3812 Sorts the LIST and returns the sorted list value.  If SUBNAME or BLOCK
3813 is omitted, C<sort>s in standard string comparison order.  If SUBNAME is
3814 specified, it gives the name of a subroutine that returns an integer
3815 less than, equal to, or greater than C<0>, depending on how the elements
3816 of the list are to be ordered.  (The C<E<lt>=E<gt>> and C<cmp>
3817 operators are extremely useful in such routines.)  SUBNAME may be a
3818 scalar variable name (unsubscripted), in which case the value provides
3819 the name of (or a reference to) the actual subroutine to use.  In place
3820 of a SUBNAME, you can provide a BLOCK as an anonymous, in-line sort
3821 subroutine.
3822
3823 In the interests of efficiency the normal calling code for subroutines is
3824 bypassed, with the following effects: the subroutine may not be a
3825 recursive subroutine, and the two elements to be compared are passed into
3826 the subroutine not via C<@_> but as the package global variables $a and
3827 $b (see example below).  They are passed by reference, so don't
3828 modify $a and $b.  And don't try to declare them as lexicals either.
3829
3830 You also cannot exit out of the sort block or subroutine using any of the
3831 loop control operators described in L<perlsyn> or with C<goto>.
3832
3833 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
3834 current collation locale.  See L<perllocale>.
3835
3836 Examples:
3837
3838     # sort lexically
3839     @articles = sort @files;
3840
3841     # same thing, but with explicit sort routine
3842     @articles = sort {$a cmp $b} @files;
3843
3844     # now case-insensitively
3845     @articles = sort {uc($a) cmp uc($b)} @files;
3846
3847     # same thing in reversed order
3848     @articles = sort {$b cmp $a} @files;
3849
3850     # sort numerically ascending
3851     @articles = sort {$a <=> $b} @files;
3852
3853     # sort numerically descending
3854     @articles = sort {$b <=> $a} @files;
3855
3856     # this sorts the %age hash by value instead of key
3857     # using an in-line function
3858     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
3859
3860     # sort using explicit subroutine name
3861     sub byage {
3862         $age{$a} <=> $age{$b};  # presuming numeric
3863     }
3864     @sortedclass = sort byage @class;
3865
3866     sub backwards { $b cmp $a }
3867     @harry  = qw(dog cat x Cain Abel);
3868     @george = qw(gone chased yz Punished Axed);
3869     print sort @harry;
3870             # prints AbelCaincatdogx
3871     print sort backwards @harry;
3872             # prints xdogcatCainAbel
3873     print sort @george, 'to', @harry;
3874             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
3875
3876     # inefficiently sort by descending numeric compare using
3877     # the first integer after the first = sign, or the
3878     # whole record case-insensitively otherwise
3879
3880     @new = sort {
3881         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
3882                             ||
3883                     uc($a)  cmp  uc($b)
3884     } @old;
3885
3886     # same thing, but much more efficiently;
3887     # we'll build auxiliary indices instead
3888     # for speed
3889     @nums = @caps = ();
3890     for (@old) {
3891         push @nums, /=(\d+)/;
3892         push @caps, uc($_);
3893     }
3894
3895     @new = @old[ sort {
3896                         $nums[$b] <=> $nums[$a]
3897                                  ||
3898                         $caps[$a] cmp $caps[$b]
3899                        } 0..$#old
3900                ];
3901
3902     # same thing, but without any temps
3903     @new = map { $_->[0] }
3904            sort { $b->[1] <=> $a->[1]
3905                            ||
3906                   $a->[2] cmp $b->[2]
3907            } map { [$_, /=(\d+)/, uc($_)] } @old;
3908
3909 If you're using strict, you I<must not> declare $a
3910 and $b as lexicals.  They are package globals.  That means
3911 if you're in the C<main> package, it's
3912
3913     @articles = sort {$main::b <=> $main::a} @files;
3914
3915 or just
3916
3917     @articles = sort {$::b <=> $::a} @files;
3918
3919 but if you're in the C<FooPack> package, it's
3920
3921     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
3922
3923 The comparison function is required to behave.  If it returns
3924 inconsistent results (sometimes saying C<$x[1]> is less than C<$x[2]> and
3925 sometimes saying the opposite, for example) the results are not
3926 well-defined.
3927
3928 =item splice ARRAY,OFFSET,LENGTH,LIST
3929
3930 =item splice ARRAY,OFFSET,LENGTH
3931
3932 =item splice ARRAY,OFFSET
3933
3934 Removes the elements designated by OFFSET and LENGTH from an array, and
3935 replaces them with the elements of LIST, if any.  In list context,
3936 returns the elements removed from the array.  In scalar context,
3937 returns the last element removed, or C<undef> if no elements are
3938 removed.  The array grows or shrinks as necessary.
3939 If OFFSET is negative then it starts that far from the end of the array.
3940 If LENGTH is omitted, removes everything from OFFSET onward.
3941 If LENGTH is negative, leave that many elements off the end of the array.
3942 The following equivalences hold (assuming C<$[ == 0>):
3943
3944     push(@a,$x,$y)      splice(@a,@a,0,$x,$y)
3945     pop(@a)             splice(@a,-1)
3946     shift(@a)           splice(@a,0,1)
3947     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
3948     $a[$x] = $y         splice(@a,$x,1,$y)
3949
3950 Example, assuming array lengths are passed before arrays:
3951
3952     sub aeq {   # compare two list values
3953         my(@a) = splice(@_,0,shift);
3954         my(@b) = splice(@_,0,shift);
3955         return 0 unless @a == @b;       # same len?
3956         while (@a) {
3957             return 0 if pop(@a) ne pop(@b);
3958         }
3959         return 1;
3960     }
3961     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
3962
3963 =item split /PATTERN/,EXPR,LIMIT
3964
3965 =item split /PATTERN/,EXPR
3966
3967 =item split /PATTERN/
3968
3969 =item split
3970
3971 Splits a string into a list of strings and returns that list.  By default,
3972 empty leading fields are preserved, and empty trailing ones are deleted.
3973
3974 If not in list context, returns the number of fields found and splits into
3975 the C<@_> array.  (In list context, you can force the split into C<@_> by
3976 using C<??> as the pattern delimiters, but it still returns the list
3977 value.)  The use of implicit split to C<@_> is deprecated, however, because
3978 it clobbers your subroutine arguments.
3979
3980 If EXPR is omitted, splits the C<$_> string.  If PATTERN is also omitted,
3981 splits on whitespace (after skipping any leading whitespace).  Anything
3982 matching PATTERN is taken to be a delimiter separating the fields.  (Note
3983 that the delimiter may be longer than one character.)
3984
3985 If LIMIT is specified and positive, splits into no more than that
3986 many fields (though it may split into fewer).  If LIMIT is unspecified
3987 or zero, trailing null fields are stripped (which potential users
3988 of C<pop> would do well to remember).  If LIMIT is negative, it is
3989 treated as if an arbitrarily large LIMIT had been specified.
3990
3991 A pattern matching the null string (not to be confused with
3992 a null pattern C<//>, which is just one member of the set of patterns
3993 matching a null string) will split the value of EXPR into separate
3994 characters at each point it matches that way.  For example:
3995
3996     print join(':', split(/ */, 'hi there'));
3997
3998 produces the output 'h:i:t:h:e:r:e'.
3999
4000 The LIMIT parameter can be used to split a line partially
4001
4002     ($login, $passwd, $remainder) = split(/:/, $_, 3);
4003
4004 When assigning to a list, if LIMIT is omitted, Perl supplies a LIMIT
4005 one larger than the number of variables in the list, to avoid
4006 unnecessary work.  For the list above LIMIT would have been 4 by
4007 default.  In time critical applications it behooves you not to split
4008 into more fields than you really need.
4009
4010 If the PATTERN contains parentheses, additional list elements are
4011 created from each matching substring in the delimiter.
4012
4013     split(/([,-])/, "1-10,20", 3);
4014
4015 produces the list value
4016
4017     (1, '-', 10, ',', 20)
4018
4019 If you had the entire header of a normal Unix email message in $header,
4020 you could split it up into fields and their values this way:
4021
4022     $header =~ s/\n\s+/ /g;  # fix continuation lines
4023     %hdrs   =  (UNIX_FROM => split /^(\S*?):\s*/m, $header);
4024
4025 The pattern C</PATTERN/> may be replaced with an expression to specify
4026 patterns that vary at runtime.  (To do runtime compilation only once,
4027 use C</$variable/o>.)
4028
4029 As a special case, specifying a PATTERN of space (C<' '>) will split on
4030 white space just as C<split> with no arguments does.  Thus, C<split(' ')> can
4031 be used to emulate B<awk>'s default behavior, whereas C<split(/ /)>
4032 will give you as many null initial fields as there are leading spaces.
4033 A C<split> on C</\s+/> is like a C<split(' ')> except that any leading
4034 whitespace produces a null first field.  A C<split> with no arguments
4035 really does a C<split(' ', $_)> internally.
4036
4037 Example:
4038
4039     open(PASSWD, '/etc/passwd');
4040     while (<PASSWD>) {
4041         ($login, $passwd, $uid, $gid,
4042          $gcos, $home, $shell) = split(/:/);
4043         #...
4044     }
4045
4046 (Note that $shell above will still have a newline on it.  See L</chop>,
4047 L</chomp>, and L</join>.)
4048
4049 =item sprintf FORMAT, LIST
4050
4051 Returns a string formatted by the usual C<printf> conventions of the
4052 C library function C<sprintf>.  See L<sprintf(3)> or L<printf(3)>
4053 on your system for an explanation of the general principles.
4054
4055 Perl does its own C<sprintf> formatting--it emulates the C
4056 function C<sprintf>, but it doesn't use it (except for floating-point
4057 numbers, and even then only the standard modifiers are allowed).  As a
4058 result, any non-standard extensions in your local C<sprintf> are not
4059 available from Perl.
4060
4061 Perl's C<sprintf> permits the following universally-known conversions:
4062
4063    %%   a percent sign
4064    %c   a character with the given number
4065    %s   a string
4066    %d   a signed integer, in decimal
4067    %u   an unsigned integer, in decimal
4068    %o   an unsigned integer, in octal
4069    %x   an unsigned integer, in hexadecimal
4070    %e   a floating-point number, in scientific notation
4071    %f   a floating-point number, in fixed decimal notation
4072    %g   a floating-point number, in %e or %f notation
4073
4074 In addition, Perl permits the following widely-supported conversions:
4075
4076    %X   like %x, but using upper-case letters
4077    %E   like %e, but using an upper-case "E"
4078    %G   like %g, but with an upper-case "E" (if applicable)
4079    %b   an unsigned integer, in binary
4080    %p   a pointer (outputs the Perl value's address in hexadecimal)
4081    %n   special: *stores* the number of characters output so far
4082         into the next variable in the parameter list 
4083
4084 Finally, for backward (and we do mean "backward") compatibility, Perl
4085 permits these unnecessary but widely-supported conversions:
4086
4087    %i   a synonym for %d
4088    %D   a synonym for %ld
4089    %U   a synonym for %lu
4090    %O   a synonym for %lo
4091    %F   a synonym for %f
4092
4093 Perl permits the following universally-known flags between the C<%>
4094 and the conversion letter:
4095
4096    space   prefix positive number with a space
4097    +       prefix positive number with a plus sign
4098    -       left-justify within the field
4099    0       use zeros, not spaces, to right-justify
4100    #       prefix non-zero octal with "0", non-zero hex with "0x"
4101    number  minimum field width
4102    .number "precision": digits after decimal point for
4103            floating-point, max length for string, minimum length
4104            for integer
4105    l       interpret integer as C type "long" or "unsigned long"
4106    h       interpret integer as C type "short" or "unsigned short"
4107
4108 There is also one Perl-specific flag:
4109
4110    V       interpret integer as Perl's standard integer type
4111
4112 Where a number would appear in the flags, an asterisk (C<*>) may be
4113 used instead, in which case Perl uses the next item in the parameter
4114 list as the given number (that is, as the field width or precision).
4115 If a field width obtained through C<*> is negative, it has the same
4116 effect as the C<-> flag: left-justification.
4117
4118 If C<use locale> is in effect, the character used for the decimal
4119 point in formatted real numbers is affected by the LC_NUMERIC locale.
4120 See L<perllocale>.
4121
4122 If Perl understands "quads" (64-bit integers) (this requires
4123 either that the platform natively supports quads or that Perl
4124 has been specifically compiled to support quads), the flags
4125
4126         d u o x X b i D U O
4127
4128 print quads, and they may optionally be preceded by
4129
4130         ll L q
4131
4132 For example
4133
4134         %lld %16LX %qo
4135
4136 You can find out whether your Perl supports quads via L<Config>:
4137
4138         use Config;
4139         ($Config{use64bits} eq 'define' || $Config{longsize} == 8) &&
4140                 print "quads\n";
4141
4142 If Perl understands "long doubles" (this requires that the platform
4143 supports long doubles), the flags
4144
4145         e f g E F G
4146
4147 may optionally be preceded by
4148
4149         ll L
4150
4151 For example
4152
4153         %llf %Lg
4154
4155 You can find out whether your Perl supports long doubles via L<Config>:
4156
4157         use Config;
4158         $Config{d_longdbl} eq 'define' && print "long doubles\n";
4159
4160 =item sqrt EXPR
4161
4162 =item sqrt
4163
4164 Return the square root of EXPR.  If EXPR is omitted, returns square
4165 root of C<$_>.  Only works on non-negative operands, unless you've
4166 loaded the standard Math::Complex module.
4167
4168     use Math::Complex;
4169     print sqrt(-2);    # prints 1.4142135623731i
4170
4171 =item srand EXPR
4172
4173 =item srand
4174
4175 Sets the random number seed for the C<rand> operator.  If EXPR is
4176 omitted, uses a semi-random value supplied by the kernel (if it supports
4177 the F</dev/urandom> device) or based on the current time and process
4178 ID, among other things.  In versions of Perl prior to 5.004 the default
4179 seed was just the current C<time>.  This isn't a particularly good seed,
4180 so many old programs supply their own seed value (often C<time ^ $$> or
4181 C<time ^ ($$ + ($$ E<lt>E<lt> 15))>), but that isn't necessary any more.
4182
4183 In fact, it's usually not necessary to call C<srand> at all, because if
4184 it is not called explicitly, it is called implicitly at the first use of
4185 the C<rand> operator.  However, this was not the case in version of Perl
4186 before 5.004, so if your script will run under older Perl versions, it
4187 should call C<srand>.
4188
4189 Note that you need something much more random than the default seed for
4190 cryptographic purposes.  Checksumming the compressed output of one or more
4191 rapidly changing operating system status programs is the usual method.  For
4192 example:
4193
4194     srand (time ^ $$ ^ unpack "%L*", `ps axww | gzip`);
4195
4196 If you're particularly concerned with this, see the C<Math::TrulyRandom>
4197 module in CPAN.
4198
4199 Do I<not> call C<srand> multiple times in your program unless you know
4200 exactly what you're doing and why you're doing it.  The point of the
4201 function is to "seed" the C<rand> function so that C<rand> can produce
4202 a different sequence each time you run your program.  Just do it once at the
4203 top of your program, or you I<won't> get random numbers out of C<rand>!
4204
4205 Frequently called programs (like CGI scripts) that simply use
4206
4207     time ^ $$
4208
4209 for a seed can fall prey to the mathematical property that
4210
4211     a^b == (a+1)^(b+1)
4212
4213 one-third of the time.  So don't do that.
4214
4215 =item stat FILEHANDLE
4216
4217 =item stat EXPR
4218
4219 =item stat
4220
4221 Returns a 13-element list giving the status info for a file, either
4222 the file opened via FILEHANDLE, or named by EXPR.  If EXPR is omitted,
4223 it stats C<$_>.  Returns a null list if the stat fails.  Typically used
4224 as follows:
4225
4226     ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
4227        $atime,$mtime,$ctime,$blksize,$blocks)
4228            = stat($filename);
4229
4230 Not all fields are supported on all filesystem types.  Here are the
4231 meaning of the fields:
4232
4233   0 dev      device number of filesystem
4234   1 ino      inode number
4235   2 mode     file mode  (type and permissions)
4236   3 nlink    number of (hard) links to the file
4237   4 uid      numeric user ID of file's owner
4238   5 gid      numeric group ID of file's owner
4239   6 rdev     the device identifier (special files only)
4240   7 size     total size of file, in bytes
4241   8 atime    last access time since the epoch
4242   9 mtime    last modify time since the epoch
4243  10 ctime    inode change time (NOT creation time!) since the epoch
4244  11 blksize  preferred block size for file system I/O
4245  12 blocks   actual number of blocks allocated
4246
4247 (The epoch was at 00:00 January 1, 1970 GMT.)
4248
4249 If stat is passed the special filehandle consisting of an underline, no
4250 stat is done, but the current contents of the stat structure from the
4251 last stat or filetest are returned.  Example:
4252
4253     if (-x $file && (($d) = stat(_)) && $d < 0) {
4254         print "$file is executable NFS file\n";
4255     }
4256
4257 (This works on machines only for which the device number is negative under NFS.)
4258
4259 Because the mode contains both the file type and its permissions, you
4260 should mask off the file type portion and (s)printf using a C<"%o"> 
4261 if you want to see the real permissions.
4262
4263     $mode = (stat($filename))[2];
4264     printf "Permissions are %04o\n", $mode & 07777;
4265
4266 In scalar context, C<stat> returns a boolean value indicating success
4267 or failure, and, if successful, sets the information associated with
4268 the special filehandle C<_>.
4269
4270 The File::stat module provides a convenient, by-name access mechanism:
4271
4272     use File::stat;
4273     $sb = stat($filename);
4274     printf "File is %s, size is %s, perm %04o, mtime %s\n", 
4275         $filename, $sb->size, $sb->mode & 07777,
4276         scalar localtime $sb->mtime;
4277
4278 =item study SCALAR
4279
4280 =item study
4281
4282 Takes extra time to study SCALAR (C<$_> if unspecified) in anticipation of
4283 doing many pattern matches on the string before it is next modified.
4284 This may or may not save time, depending on the nature and number of
4285 patterns you are searching on, and on the distribution of character
4286 frequencies in the string to be searched--you probably want to compare
4287 run times with and without it to see which runs faster.  Those loops
4288 which scan for many short constant strings (including the constant
4289 parts of more complex patterns) will benefit most.  You may have only
4290 one C<study> active at a time--if you study a different scalar the first
4291 is "unstudied".  (The way C<study> works is this: a linked list of every
4292 character in the string to be searched is made, so we know, for
4293 example, where all the C<'k'> characters are.  From each search string,
4294 the rarest character is selected, based on some static frequency tables
4295 constructed from some C programs and English text.  Only those places
4296 that contain this "rarest" character are examined.)
4297
4298 For example, here is a loop that inserts index producing entries
4299 before any line containing a certain pattern:
4300
4301     while (<>) {
4302         study;
4303         print ".IX foo\n"       if /\bfoo\b/;
4304         print ".IX bar\n"       if /\bbar\b/;
4305         print ".IX blurfl\n"    if /\bblurfl\b/;
4306         # ...
4307         print;
4308     }
4309
4310 In searching for C</\bfoo\b/>, only those locations in C<$_> that contain C<"f">
4311 will be looked at, because C<"f"> is rarer than C<"o">.  In general, this is
4312 a big win except in pathological cases.  The only question is whether
4313 it saves you more time than it took to build the linked list in the
4314 first place.
4315
4316 Note that if you have to look for strings that you don't know till
4317 runtime, you can build an entire loop as a string and C<eval> that to
4318 avoid recompiling all your patterns all the time.  Together with
4319 undefining C<$/> to input entire files as one record, this can be very
4320 fast, often faster than specialized programs like fgrep(1).  The following
4321 scans a list of files (C<@files>) for a list of words (C<@words>), and prints
4322 out the names of those files that contain a match:
4323
4324     $search = 'while (<>) { study;';
4325     foreach $word (@words) {
4326         $search .= "++\$seen{\$ARGV} if /\\b$word\\b/;\n";
4327     }
4328     $search .= "}";
4329     @ARGV = @files;
4330     undef $/;
4331     eval $search;               # this screams
4332     $/ = "\n";          # put back to normal input delimiter
4333     foreach $file (sort keys(%seen)) {
4334         print $file, "\n";
4335     }
4336
4337 =item sub BLOCK
4338
4339 =item sub NAME
4340
4341 =item sub NAME BLOCK
4342
4343 This is subroutine definition, not a real function I<per se>.  With just a
4344 NAME (and possibly prototypes or attributes), it's just a forward declaration.
4345 Without a NAME, it's an anonymous function declaration, and does actually
4346 return a value: the CODE ref of the closure you just created.  See L<perlsub>
4347 and L<perlref> for details.
4348
4349 =item substr EXPR,OFFSET,LENGTH,REPLACEMENT
4350
4351 =item substr EXPR,OFFSET,LENGTH
4352
4353 =item substr EXPR,OFFSET
4354
4355 Extracts a substring out of EXPR and returns it.  First character is at
4356 offset C<0>, or whatever you've set C<$[> to (but don't do that).
4357 If OFFSET is negative (or more precisely, less than C<$[>), starts
4358 that far from the end of the string.  If LENGTH is omitted, returns
4359 everything to the end of the string.  If LENGTH is negative, leaves that
4360 many characters off the end of the string.
4361
4362 You can use the substr() function as an lvalue, in which case EXPR
4363 must itself be an lvalue.  If you assign something shorter than LENGTH,
4364 the string will shrink, and if you assign something longer than LENGTH,
4365 the string will grow to accommodate it.  To keep the string the same
4366 length you may need to pad or chop your value using C<sprintf>.
4367
4368 If OFFSET and LENGTH specify a substring that is partly outside the
4369 string, only the part within the string is returned.  If the substring
4370 is beyond either end of the string, substr() returns the undefined
4371 value and produces a warning.  When used as an lvalue, specifying a
4372 substring that is entirely outside the string is a fatal error.
4373 Here's an example showing the behavior for boundary cases:
4374
4375     my $name = 'fred';
4376     substr($name, 4) = 'dy';            # $name is now 'freddy'
4377     my $null = substr $name, 6, 2;      # returns '' (no warning)
4378     my $oops = substr $name, 7;         # returns undef, with warning
4379     substr($name, 7) = 'gap';           # fatal error
4380
4381 An alternative to using substr() as an lvalue is to specify the
4382 replacement string as the 4th argument.  This allows you to replace
4383 parts of the EXPR and return what was there before in one operation,
4384 just as you can with splice().
4385
4386 =item symlink OLDFILE,NEWFILE
4387
4388 Creates a new filename symbolically linked to the old filename.
4389 Returns C<1> for success, C<0> otherwise.  On systems that don't support
4390 symbolic links, produces a fatal error at run time.  To check for that,
4391 use eval:
4392
4393     $symlink_exists = eval { symlink("",""); 1 };
4394
4395 =item syscall LIST
4396
4397 Calls the system call specified as the first element of the list,
4398 passing the remaining elements as arguments to the system call.  If
4399 unimplemented, produces a fatal error.  The arguments are interpreted
4400 as follows: if a given argument is numeric, the argument is passed as
4401 an int.  If not, the pointer to the string value is passed.  You are
4402 responsible to make sure a string is pre-extended long enough to
4403 receive any result that might be written into a string.  You can't use a
4404 string literal (or other read-only string) as an argument to C<syscall>
4405 because Perl has to assume that any string pointer might be written
4406 through.  If your
4407 integer arguments are not literals and have never been interpreted in a
4408 numeric context, you may need to add C<0> to them to force them to look
4409 like numbers.  This emulates the C<syswrite> function (or vice versa):
4410
4411     require 'syscall.ph';               # may need to run h2ph
4412     $s = "hi there\n";
4413     syscall(&SYS_write, fileno(STDOUT), $s, length $s);
4414
4415 Note that Perl supports passing of up to only 14 arguments to your system call,
4416 which in practice should usually suffice.
4417
4418 Syscall returns whatever value returned by the system call it calls.
4419 If the system call fails, C<syscall> returns C<-1> and sets C<$!> (errno).
4420 Note that some system calls can legitimately return C<-1>.  The proper
4421 way to handle such calls is to assign C<$!=0;> before the call and
4422 check the value of C<$!> if syscall returns C<-1>.
4423
4424 There's a problem with C<syscall(&SYS_pipe)>: it returns the file
4425 number of the read end of the pipe it creates.  There is no way
4426 to retrieve the file number of the other end.  You can avoid this 
4427 problem by using C<pipe> instead.
4428
4429 =item sysopen FILEHANDLE,FILENAME,MODE
4430
4431 =item sysopen FILEHANDLE,FILENAME,MODE,PERMS
4432
4433 Opens the file whose filename is given by FILENAME, and associates it
4434 with FILEHANDLE.  If FILEHANDLE is an expression, its value is used as
4435 the name of the real filehandle wanted.  This function calls the
4436 underlying operating system's C<open> function with the parameters
4437 FILENAME, MODE, PERMS.
4438
4439 The possible values and flag bits of the MODE parameter are
4440 system-dependent; they are available via the standard module C<Fcntl>.
4441 See the documentation of your operating system's C<open> to see which
4442 values and flag bits are available.  You may combine several flags
4443 using the C<|>-operator.
4444
4445 Some of the most common values are C<O_RDONLY> for opening the file in
4446 read-only mode, C<O_WRONLY> for opening the file in write-only mode,
4447 and C<O_RDWR> for opening the file in read-write mode, and.
4448
4449 For historical reasons, some values work on almost every system
4450 supported by perl: zero means read-only, one means write-only, and two
4451 means read/write.  We know that these values do I<not> work under
4452 OS/390 & VM/ESA Unix and on the Macintosh; you probably don't want to
4453 se them in new code, use thhe constants discussed in the preceding
4454 paragraph.
4455
4456 If the file named by FILENAME does not exist and the C<open> call creates
4457 it (typically because MODE includes the C<O_CREAT> flag), then the value of
4458 PERMS specifies the permissions of the newly created file.  If you omit
4459 the PERMS argument to C<sysopen>, Perl uses the octal value C<0666>.
4460 These permission values need to be in octal, and are modified by your
4461 process's current C<umask>.
4462
4463 In many systems the C<O_EXCL> flag is available for opening files in
4464 exclusive mode.  This is B<not> locking: exclusiveness means here that
4465 if the file already exists, sysopen() fails.  The C<O_EXCL> wins
4466 C<O_TRUNC>.
4467
4468 Sometimes you may want to truncate an already-existing file: C<O_TRUNC>.
4469
4470 You should seldom if ever use C<0644> as argument to C<sysopen>, because
4471 that takes away the user's option to have a more permissive umask.
4472 Better to omit it.  See the perlfunc(1) entry on C<umask> for more
4473 on this.
4474
4475 See L<perlopentut> for a kinder, gentler explanation of opening files.
4476
4477 =item sysread FILEHANDLE,SCALAR,LENGTH,OFFSET
4478
4479 =item sysread FILEHANDLE,SCALAR,LENGTH
4480
4481 Attempts to read LENGTH bytes of data into variable SCALAR from the
4482 specified FILEHANDLE, using the system call read(2).  It bypasses stdio,
4483 so mixing this with other kinds of reads, C<print>, C<write>,
4484 C<seek>, C<tell>, or C<eof> can cause confusion because stdio
4485 usually buffers data.  Returns the number of bytes actually read, C<0>
4486 at end of file, or undef if there was an error.  SCALAR will be grown or
4487 shrunk so that the last byte actually read is the last byte of the
4488 scalar after the read.
4489
4490 An OFFSET may be specified to place the read data at some place in the
4491 string other than the beginning.  A negative OFFSET specifies
4492 placement at that many bytes counting backwards from the end of the
4493 string.  A positive OFFSET greater than the length of SCALAR results
4494 in the string being padded to the required size with C<"\0"> bytes before
4495 the result of the read is appended.
4496
4497 There is no syseof() function, which is ok, since eof() doesn't work
4498 very well on device files (like ttys) anyway.  Use sysread() and check
4499 for a return value for 0 to decide whether you're done.
4500
4501 =item sysseek FILEHANDLE,POSITION,WHENCE
4502
4503 Sets FILEHANDLE's system position using the system call lseek(2).  It
4504 bypasses stdio, so mixing this with reads (other than C<sysread>),
4505 C<print>, C<write>, C<seek>, C<tell>, or C<eof> may cause confusion.
4506 FILEHANDLE may be an expression whose value gives the name of the
4507 filehandle.  The values for WHENCE are C<0> to set the new position to
4508 POSITION, C<1> to set the it to the current position plus POSITION,
4509 and C<2> to set it to EOF plus POSITION (typically negative).  For
4510 WHENCE, you may also use the constants C<SEEK_SET>, C<SEEK_CUR>, and
4511 C<SEEK_END> (start of the file, current position, end of the file)
4512 from any of the modules Fcntl, C<IO::Seekable>, or POSIX.
4513
4514 Returns the new position, or the undefined value on failure.  A position
4515 of zero is returned as the string C<"0 but true">; thus C<sysseek> returns
4516 true on success and false on failure, yet you can still easily determine
4517 the new position.
4518
4519 =item system LIST
4520
4521 =item system PROGRAM LIST
4522
4523 Does exactly the same thing as C<exec LIST>, except that a fork is
4524 done first, and the parent process waits for the child process to
4525 complete.  Note that argument processing varies depending on the
4526 number of arguments.  If there is more than one argument in LIST,
4527 or if LIST is an array with more than one value, starts the program
4528 given by the first element of the list with arguments given by the
4529 rest of the list.  If there is only one scalar argument, the argument
4530 is checked for shell metacharacters, and if there are any, the
4531 entire argument is passed to the system's command shell for parsing
4532 (this is C</bin/sh -c> on Unix platforms, but varies on other
4533 platforms).  If there are no shell metacharacters in the argument,
4534 it is split into words and passed directly to C<execvp>, which is
4535 more efficient.
4536
4537 All files opened for output are flushed before attempting the exec().
4538
4539 The return value is the exit status of the program as
4540 returned by the C<wait> call.  To get the actual exit value divide by
4541 256.  See also L</exec>.  This is I<not> what you want to use to capture
4542 the output from a command, for that you should use merely backticks or
4543 C<qx//>, as described in L<perlop/"`STRING`">.  Return value of -1
4544 indicates a failure to start the program (inspect $! for the reason).
4545
4546 Like C<exec>, C<system> allows you to lie to a program about its name if
4547 you use the C<system PROGRAM LIST> syntax.  Again, see L</exec>.
4548
4549 Because C<system> and backticks block C<SIGINT> and C<SIGQUIT>, killing the
4550 program they're running doesn't actually interrupt your program.
4551
4552     @args = ("command", "arg1", "arg2");
4553     system(@args) == 0
4554          or die "system @args failed: $?"
4555
4556 You can check all the failure possibilities by inspecting
4557 C<$?> like this:
4558
4559     $exit_value  = $? >> 8;
4560     $signal_num  = $? & 127;
4561     $dumped_core = $? & 128;
4562
4563 When the arguments get executed via the system shell, results
4564 and return codes will be subject to its quirks and capabilities.
4565 See L<perlop/"`STRING`"> and L</exec> for details.
4566
4567 =item syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET
4568
4569 =item syswrite FILEHANDLE,SCALAR,LENGTH
4570
4571 =item syswrite FILEHANDLE,SCALAR
4572
4573 Attempts to write LENGTH bytes of data from variable SCALAR to the
4574 specified FILEHANDLE, using the system call write(2).  If LENGTH
4575 is not specified, writes whole SCALAR.  It bypasses stdio, so mixing
4576 this with reads (other than C<sysread())>, C<print>, C<write>,
4577 C<seek>, C<tell>, or C<eof> may cause confusion because stdio
4578 usually buffers data.  Returns the number of bytes actually written,
4579 or C<undef> if there was an error.  If the LENGTH is greater than
4580 the available data in the SCALAR after the OFFSET, only as much
4581 data as is available will be written.
4582
4583 An OFFSET may be specified to write the data from some part of the
4584 string other than the beginning.  A negative OFFSET specifies writing
4585 that many bytes counting backwards from the end of the string.  In the
4586 case the SCALAR is empty you can use OFFSET but only zero offset.
4587
4588 =item tell FILEHANDLE
4589
4590 =item tell
4591
4592 Returns the current position for FILEHANDLE.  FILEHANDLE may be an
4593 expression whose value gives the name of the actual filehandle.  If
4594 FILEHANDLE is omitted, assumes the file last read.  
4595
4596 There is no C<systell> function.  Use C<sysseek(FH, 0, 1)> for that.
4597
4598 =item telldir DIRHANDLE
4599
4600 Returns the current position of the C<readdir> routines on DIRHANDLE.
4601 Value may be given to C<seekdir> to access a particular location in a
4602 directory.  Has the same caveats about possible directory compaction as
4603 the corresponding system library routine.
4604
4605 =item tie VARIABLE,CLASSNAME,LIST
4606
4607 This function binds a variable to a package class that will provide the
4608 implementation for the variable.  VARIABLE is the name of the variable
4609 to be enchanted.  CLASSNAME is the name of a class implementing objects
4610 of correct type.  Any additional arguments are passed to the C<new>
4611 method of the class (meaning C<TIESCALAR>, C<TIEHANDLE>, C<TIEARRAY>,
4612 or C<TIEHASH>).  Typically these are arguments such as might be passed
4613 to the C<dbm_open()> function of C.  The object returned by the C<new>
4614 method is also returned by the C<tie> function, which would be useful
4615 if you want to access other methods in CLASSNAME.
4616
4617 Note that functions such as C<keys> and C<values> may return huge lists
4618 when used on large objects, like DBM files.  You may prefer to use the
4619 C<each> function to iterate over such.  Example:
4620
4621     # print out history file offsets
4622     use NDBM_File;
4623     tie(%HIST, 'NDBM_File', '/usr/lib/news/history', 1, 0);
4624     while (($key,$val) = each %HIST) {
4625         print $key, ' = ', unpack('L',$val), "\n";
4626     }
4627     untie(%HIST);
4628
4629 A class implementing a hash should have the following methods:
4630
4631     TIEHASH classname, LIST
4632     FETCH this, key
4633     STORE this, key, value
4634     DELETE this, key
4635     CLEAR this
4636     EXISTS this, key
4637     FIRSTKEY this
4638     NEXTKEY this, lastkey
4639     DESTROY this
4640
4641 A class implementing an ordinary array should have the following methods:
4642
4643     TIEARRAY classname, LIST
4644     FETCH this, key
4645     STORE this, key, value
4646     FETCHSIZE this