This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
f825754b8e98b1bfc0685cdf537f4cc7edcf9099
[perl5.git] / pod / perlvar.pod
1 =head1 NAME
2
3 perlvar - Perl predefined variables
4
5 =head1 DESCRIPTION
6
7 =head2 The Syntax of Variable Names
8
9 Variable names in Perl can have several formats.  Usually, they
10 must begin with a letter or underscore, in which case they can be
11 arbitrarily long (up to an internal limit of 251 characters) and
12 may contain letters, digits, underscores, or the special sequence
13 C<::> or C<'>.  In this case, the part before the last C<::> or
14 C<'> is taken to be a I<package qualifier>; see L<perlmod>.
15 A Unicode letter that is not ASCII is not considered to be a letter
16 unless S<C<"use utf8">> is in effect, and somewhat more complicated
17 rules apply; see L<perldata/Identifier parsing> for details.
18
19 Perl variable names may also be a sequence of digits, a single
20 punctuation character, or the two-character sequence: C<^> (caret or
21 CIRCUMFLEX ACCENT) followed by any one of the characters C<[][A-Z^_?\]>.
22 These names are all reserved for
23 special uses by Perl; for example, the all-digits names are used
24 to hold data captured by backreferences after a regular expression
25 match.
26
27 Since Perl v5.6.0, Perl variable names may also be alphanumeric strings
28 preceded by a caret.  These must all be written in the form C<${^Foo}>;
29 the braces are not optional.  C<${^Foo}> denotes the scalar variable
30 whose name is considered to be a control-C<F> followed by two C<o>'s.
31 These variables are
32 reserved for future special uses by Perl, except for the ones that
33 begin with C<^_> (caret-underscore).  No
34 name that begins with C<^_> will acquire a special
35 meaning in any future version of Perl; such names may therefore be
36 used safely in programs.  C<$^_> itself, however, I<is> reserved.
37
38 Perl identifiers that begin with digits or
39 punctuation characters are exempt from the effects of the C<package>
40 declaration and are always forced to be in package C<main>; they are
41 also exempt from C<strict 'vars'> errors.  A few other names are also
42 exempt in these ways:
43
44     ENV      STDIN
45     INC      STDOUT
46     ARGV     STDERR
47     ARGVOUT
48     SIG
49
50 In particular, the special C<${^_XYZ}> variables are always taken
51 to be in package C<main>, regardless of any C<package> declarations
52 presently in scope.
53
54 =head1 SPECIAL VARIABLES
55
56 The following names have special meaning to Perl.  Most punctuation
57 names have reasonable mnemonics, or analogs in the shells.
58 Nevertheless, if you wish to use long variable names, you need only say:
59
60     use English;
61
62 at the top of your program.  This aliases all the short names to the long
63 names in the current package.  Some even have medium names, generally
64 borrowed from B<awk>.  For more info, please see L<English>.
65
66 Before you continue, note the sort order for variables.  In general, we
67 first list the variables in case-insensitive, almost-lexigraphical
68 order (ignoring the C<{> or C<^> preceding words, as in C<${^UNICODE}>
69 or C<$^T>), although C<$_> and C<@_> move up to the top of the pile.
70 For variables with the same identifier, we list it in order of scalar,
71 array, hash, and bareword.
72
73 =head2 General Variables
74
75 =over 8
76
77 =item $ARG
78
79 =item $_
80 X<$_> X<$ARG>
81
82 The default input and pattern-searching space.  The following pairs are
83 equivalent:
84
85     while (<>) {...}    # equivalent only in while!
86     while (defined($_ = <>)) {...}
87
88     /^Subject:/
89     $_ =~ /^Subject:/
90
91     tr/a-z/A-Z/
92     $_ =~ tr/a-z/A-Z/
93
94     chomp
95     chomp($_)
96
97 Here are the places where Perl will assume C<$_> even if you don't use it:
98
99 =over 3
100
101 =item *
102
103 The following functions use C<$_> as a default argument:
104
105 abs, alarm, chomp, chop, chr, chroot,
106 cos, defined, eval, evalbytes, exp, fc, glob, hex, int, lc,
107 lcfirst, length, log, lstat, mkdir, oct, ord, pos, print, printf,
108 quotemeta, readlink, readpipe, ref, require, reverse (in scalar context only),
109 rmdir, say, sin, split (for its second
110 argument), sqrt, stat, study, uc, ucfirst,
111 unlink, unpack.
112
113 =item *
114
115 All file tests (C<-f>, C<-d>) except for C<-t>, which defaults to STDIN.
116 See L<perlfunc/-X>
117
118 =item *
119
120 The pattern matching operations C<m//>, C<s///> and C<tr///> (aka C<y///>)
121 when used without an C<=~> operator.
122
123 =item *
124
125 The default iterator variable in a C<foreach> loop if no other
126 variable is supplied.
127
128 =item *
129
130 The implicit iterator variable in the C<grep()> and C<map()> functions.
131
132 =item *
133
134 The implicit variable of C<given()>.
135
136 =item *
137
138 The default place to put the next value or input record
139 when a C<< <FH> >>, C<readline>, C<readdir> or C<each>
140 operation's result is tested by itself as the sole criterion of a C<while>
141 test.  Outside a C<while> test, this will not happen.
142
143 =back
144
145 C<$_> is by default a global variable.  However, as
146 of perl v5.10.0, you can use a lexical version of
147 C<$_> by declaring it in a file or in a block with C<my>.  Moreover,
148 declaring C<our $_> restores the global C<$_> in the current scope.  Though
149 this seemed like a good idea at the time it was introduced, lexical C<$_>
150 actually causes more problems than it solves.  If you call a function that
151 expects to be passed information via C<$_>, it may or may not work,
152 depending on how the function is written, there not being any easy way to
153 solve this.  Just avoid lexical C<$_>, unless you are feeling particularly
154 masochistic.  For this reason lexical C<$_> is still experimental and will
155 produce a warning unless warnings have been disabled.  As with other
156 experimental features, the behavior of lexical C<$_> is subject to change
157 without notice, including change into a fatal error.
158
159 Mnemonic: underline is understood in certain operations.
160
161 =item @ARG
162
163 =item @_
164 X<@_> X<@ARG>
165
166 Within a subroutine the array C<@_> contains the parameters passed to
167 that subroutine.  Inside a subroutine, C<@_> is the default array for
168 the array operators C<pop> and C<shift>.
169
170 See L<perlsub>.
171
172 =item $LIST_SEPARATOR
173
174 =item $"
175 X<$"> X<$LIST_SEPARATOR>
176
177 When an array or an array slice is interpolated into a double-quoted
178 string or a similar context such as C</.../>, its elements are
179 separated by this value.  Default is a space.  For example, this:
180
181     print "The array is: @array\n";
182
183 is equivalent to this:
184
185     print "The array is: " . join($", @array) . "\n";
186
187 Mnemonic: works in double-quoted context.
188
189 =item $PROCESS_ID
190
191 =item $PID
192
193 =item $$
194 X<$$> X<$PID> X<$PROCESS_ID>
195
196 The process number of the Perl running this script.  Though you I<can> set
197 this variable, doing so is generally discouraged, although it can be
198 invaluable for some testing purposes.  It will be reset automatically
199 across C<fork()> calls.
200
201 Note for Linux and Debian GNU/kFreeBSD users: Before Perl v5.16.0 perl
202 would emulate POSIX semantics on Linux systems using LinuxThreads, a
203 partial implementation of POSIX Threads that has since been superseded
204 by the Native POSIX Thread Library (NPTL).
205
206 LinuxThreads is now obsolete on Linux, and caching C<getpid()>
207 like this made embedding perl unnecessarily complex (since you'd have
208 to manually update the value of $$), so now C<$$> and C<getppid()>
209 will always return the same values as the underlying C library.
210
211 Debian GNU/kFreeBSD systems also used LinuxThreads up until and
212 including the 6.0 release, but after that moved to FreeBSD thread
213 semantics, which are POSIX-like.
214
215 To see if your system is affected by this discrepancy check if
216 C<getconf GNU_LIBPTHREAD_VERSION | grep -q NPTL> returns a false
217 value.  NTPL threads preserve the POSIX semantics.
218
219 Mnemonic: same as shells.
220
221 =item $PROGRAM_NAME
222
223 =item $0
224 X<$0> X<$PROGRAM_NAME>
225
226 Contains the name of the program being executed.
227
228 On some (but not all) operating systems assigning to C<$0> modifies
229 the argument area that the C<ps> program sees.  On some platforms you
230 may have to use special C<ps> options or a different C<ps> to see the
231 changes.  Modifying the C<$0> is more useful as a way of indicating the
232 current program state than it is for hiding the program you're
233 running.
234
235 Note that there are platform-specific limitations on the maximum
236 length of C<$0>.  In the most extreme case it may be limited to the
237 space occupied by the original C<$0>.
238
239 In some platforms there may be arbitrary amount of padding, for
240 example space characters, after the modified name as shown by C<ps>.
241 In some platforms this padding may extend all the way to the original
242 length of the argument area, no matter what you do (this is the case
243 for example with Linux 2.2).
244
245 Note for BSD users: setting C<$0> does not completely remove "perl"
246 from the ps(1) output.  For example, setting C<$0> to C<"foobar"> may
247 result in C<"perl: foobar (perl)"> (whether both the C<"perl: "> prefix
248 and the " (perl)" suffix are shown depends on your exact BSD variant
249 and version).  This is an operating system feature, Perl cannot help it.
250
251 In multithreaded scripts Perl coordinates the threads so that any
252 thread may modify its copy of the C<$0> and the change becomes visible
253 to ps(1) (assuming the operating system plays along).  Note that
254 the view of C<$0> the other threads have will not change since they
255 have their own copies of it.
256
257 If the program has been given to perl via the switches C<-e> or C<-E>,
258 C<$0> will contain the string C<"-e">.
259
260 On Linux as of perl v5.14.0 the legacy process name will be set with
261 C<prctl(2)>, in addition to altering the POSIX name via C<argv[0]> as
262 perl has done since version 4.000.  Now system utilities that read the
263 legacy process name such as ps, top and killall will recognize the
264 name you set when assigning to C<$0>.  The string you supply will be
265 cut off at 16 bytes, this is a limitation imposed by Linux.
266
267 Mnemonic: same as B<sh> and B<ksh>.
268
269 =item $REAL_GROUP_ID
270
271 =item $GID
272
273 =item $(
274 X<$(> X<$GID> X<$REAL_GROUP_ID>
275
276 The real gid of this process.  If you are on a machine that supports
277 membership in multiple groups simultaneously, gives a space separated
278 list of groups you are in.  The first number is the one returned by
279 C<getgid()>, and the subsequent ones by C<getgroups()>, one of which may be
280 the same as the first number.
281
282 However, a value assigned to C<$(> must be a single number used to
283 set the real gid.  So the value given by C<$(> should I<not> be assigned
284 back to C<$(> without being forced numeric, such as by adding zero.  Note
285 that this is different to the effective gid (C<$)>) which does take a
286 list.
287
288 You can change both the real gid and the effective gid at the same
289 time by using C<POSIX::setgid()>.  Changes
290 to C<$(> require a check to C<$!>
291 to detect any possible errors after an attempted change.
292
293 Mnemonic: parentheses are used to I<group> things.  The real gid is the
294 group you I<left>, if you're running setgid.
295
296 =item $EFFECTIVE_GROUP_ID
297
298 =item $EGID
299
300 =item $)
301 X<$)> X<$EGID> X<$EFFECTIVE_GROUP_ID>
302
303 The effective gid of this process.  If you are on a machine that
304 supports membership in multiple groups simultaneously, gives a space
305 separated list of groups you are in.  The first number is the one
306 returned by C<getegid()>, and the subsequent ones by C<getgroups()>,
307 one of which may be the same as the first number.
308
309 Similarly, a value assigned to C<$)> must also be a space-separated
310 list of numbers.  The first number sets the effective gid, and
311 the rest (if any) are passed to C<setgroups()>.  To get the effect of an
312 empty list for C<setgroups()>, just repeat the new effective gid; that is,
313 to force an effective gid of 5 and an effectively empty C<setgroups()>
314 list, say C< $) = "5 5" >.
315
316 You can change both the effective gid and the real gid at the same
317 time by using C<POSIX::setgid()> (use only a single numeric argument).
318 Changes to C<$)> require a check to C<$!> to detect any possible errors
319 after an attempted change.
320
321 C<< $< >>, C<< $> >>, C<$(> and C<$)> can be set only on
322 machines that support the corresponding I<set[re][ug]id()> routine.  C<$(>
323 and C<$)> can be swapped only on machines supporting C<setregid()>.
324
325 Mnemonic: parentheses are used to I<group> things.  The effective gid
326 is the group that's I<right> for you, if you're running setgid.
327
328 =item $REAL_USER_ID
329
330 =item $UID
331
332 =item $<
333 X<< $< >> X<$UID> X<$REAL_USER_ID>
334
335 The real uid of this process.  You can change both the real uid and the
336 effective uid at the same time by using C<POSIX::setuid()>.  Since
337 changes to C<< $< >> require a system call, check C<$!> after a change
338 attempt to detect any possible errors.
339
340 Mnemonic: it's the uid you came I<from>, if you're running setuid.
341
342 =item $EFFECTIVE_USER_ID
343
344 =item $EUID
345
346 =item $>
347 X<< $> >> X<$EUID> X<$EFFECTIVE_USER_ID>
348
349 The effective uid of this process.  For example:
350
351     $< = $>;            # set real to effective uid
352     ($<,$>) = ($>,$<);  # swap real and effective uids
353
354 You can change both the effective uid and the real uid at the same
355 time by using C<POSIX::setuid()>.  Changes to C<< $> >> require a check
356 to C<$!> to detect any possible errors after an attempted change.
357
358 C<< $< >> and C<< $> >> can be swapped only on machines
359 supporting C<setreuid()>.
360
361 Mnemonic: it's the uid you went I<to>, if you're running setuid.
362
363 =item $SUBSCRIPT_SEPARATOR
364
365 =item $SUBSEP
366
367 =item $;
368 X<$;> X<$SUBSEP> X<SUBSCRIPT_SEPARATOR>
369
370 The subscript separator for multidimensional array emulation.  If you
371 refer to a hash element as
372
373     $foo{$x,$y,$z}
374
375 it really means
376
377     $foo{join($;, $x, $y, $z)}
378
379 But don't put
380
381     @foo{$x,$y,$z}      # a slice--note the @
382
383 which means
384
385     ($foo{$x},$foo{$y},$foo{$z})
386
387 Default is "\034", the same as SUBSEP in B<awk>.  If your keys contain
388 binary data there might not be any safe value for C<$;>.
389
390 Consider using "real" multidimensional arrays as described
391 in L<perllol>.
392
393 Mnemonic: comma (the syntactic subscript separator) is a semi-semicolon.
394
395 =item $a
396
397 =item $b
398 X<$a> X<$b>
399
400 Special package variables when using C<sort()>, see L<perlfunc/sort>.
401 Because of this specialness C<$a> and C<$b> don't need to be declared
402 (using C<use vars>, or C<our()>) even when using the C<strict 'vars'>
403 pragma.  Don't lexicalize them with C<my $a> or C<my $b> if you want to
404 be able to use them in the C<sort()> comparison block or function.
405
406 =item %ENV
407 X<%ENV>
408
409 The hash C<%ENV> contains your current environment.  Setting a
410 value in C<ENV> changes the environment for any child processes
411 you subsequently C<fork()> off.
412
413 As of v5.18.0, both keys and values stored in C<%ENV> are stringified.
414
415     my $foo = 1;
416     $ENV{'bar'} = \$foo;
417     if( ref $ENV{'bar'} ) {
418         say "Pre 5.18.0 Behaviour";
419     } else {
420         say "Post 5.18.0 Behaviour";
421     }
422
423 Previously, only child processes received stringified values:
424
425     my $foo = 1;
426     $ENV{'bar'} = \$foo;
427
428     # Always printed 'non ref'
429     system($^X, '-e',
430            q/print ( ref $ENV{'bar'}  ? 'ref' : 'non ref' ) /);
431
432 This happens because you can't really share arbitrary data structures with
433 foreign processes.
434
435 =item $OLD_PERL_VERSION
436
437 =item $]
438 X<$]> X<$OLD_PERL_VERSION>
439
440 The revision, version, and subversion of the Perl interpreter, represented
441 as a decimal of the form 5.XXXYYY, where XXX is the version / 1e3 and YYY
442 is the subversion / 1e6.  For example, Perl v5.10.1 would be "5.010001".
443
444 This variable can be used to determine whether the Perl interpreter
445 executing a script is in the right range of versions:
446
447     warn "No PerlIO!\n" if $] lt '5.008';
448
449 When comparing C<$]>, string comparison operators are B<highly
450 recommended>.  The inherent limitations of binary floating point
451 representation can sometimes lead to incorrect comparisons for some
452 numbers on some architectures.
453
454 See also the documentation of C<use VERSION> and C<require VERSION>
455 for a convenient way to fail if the running Perl interpreter is too old.
456
457 See L</$^V> for a representation of the Perl version as a L<version>
458 object, which allows more flexible string comparisons.
459
460 The main advantage of C<$]> over C<$^V> is that it works the same on any
461 version of Perl.  The disadvantages are that it can't easily be compared
462 to versions in other formats (e.g. literal v-strings, "v1.2.3" or
463 version objects) and numeric comparisons can occasionally fail; it's good
464 for string literal version checks and bad for comparing to a variable
465 that hasn't been sanity-checked.
466
467 Mnemonic: Is this version of perl in the right bracket?
468
469 The C<$OLD_PERL_VERSION> form was added in Perl v5.20.0.
470
471 =item $SYSTEM_FD_MAX
472
473 =item $^F
474 X<$^F> X<$SYSTEM_FD_MAX>
475
476 The maximum system file descriptor, ordinarily 2.  System file
477 descriptors are passed to C<exec()>ed processes, while higher file
478 descriptors are not.  Also, during an
479 C<open()>, system file descriptors are
480 preserved even if the C<open()> fails (ordinary file descriptors are
481 closed before the C<open()> is attempted).  The close-on-exec
482 status of a file descriptor will be decided according to the value of
483 C<$^F> when the corresponding file, pipe, or socket was opened, not the
484 time of the C<exec()>.
485
486 =item @F
487 X<@F>
488
489 The array C<@F> contains the fields of each line read in when autosplit
490 mode is turned on.  See L<perlrun> for the B<-a> switch.  This array
491 is package-specific, and must be declared or given a full package name
492 if not in package main when running under C<strict 'vars'>.
493
494 =item @INC
495 X<@INC>
496
497 The array C<@INC> contains the list of places that the C<do EXPR>,
498 C<require>, or C<use> constructs look for their library files.  It
499 initially consists of the arguments to any B<-I> command-line
500 switches, followed by the default Perl library, probably
501 F</usr/local/lib/perl>, followed by ".", to represent the current
502 directory.  ("." will not be appended if taint checks are enabled,
503 either by C<-T> or by C<-t>.)  If you need to modify this at runtime,
504 you should use the C<use lib> pragma to get the machine-dependent
505 library properly loaded also:
506
507     use lib '/mypath/libdir/';
508     use SomeMod;
509
510 You can also insert hooks into the file inclusion system by putting Perl
511 code directly into C<@INC>.  Those hooks may be subroutine references,
512 array references or blessed objects.  See L<perlfunc/require> for details.
513
514 =item %INC
515 X<%INC>
516
517 The hash C<%INC> contains entries for each filename included via the
518 C<do>, C<require>, or C<use> operators.  The key is the filename
519 you specified (with module names converted to pathnames), and the
520 value is the location of the file found.  The C<require>
521 operator uses this hash to determine whether a particular file has
522 already been included.
523
524 If the file was loaded via a hook (e.g. a subroutine reference, see
525 L<perlfunc/require> for a description of these hooks), this hook is
526 by default inserted into C<%INC> in place of a filename.  Note, however,
527 that the hook may have set the C<%INC> entry by itself to provide some more
528 specific info.
529
530 =item $INPLACE_EDIT
531
532 =item $^I
533 X<$^I> X<$INPLACE_EDIT>
534
535 The current value of the inplace-edit extension.  Use C<undef> to disable
536 inplace editing.
537
538 Mnemonic: value of B<-i> switch.
539
540 =item $^M
541 X<$^M>
542
543 By default, running out of memory is an untrappable, fatal error.
544 However, if suitably built, Perl can use the contents of C<$^M>
545 as an emergency memory pool after C<die()>ing.  Suppose that your Perl
546 were compiled with C<-DPERL_EMERGENCY_SBRK> and used Perl's malloc.
547 Then
548
549     $^M = 'a' x (1 << 16);
550
551 would allocate a 64K buffer for use in an emergency.  See the
552 F<INSTALL> file in the Perl distribution for information on how to
553 add custom C compilation flags when compiling perl.  To discourage casual
554 use of this advanced feature, there is no L<English|English> long name for
555 this variable.
556
557 This variable was added in Perl 5.004.
558
559 =item $OSNAME
560
561 =item $^O
562 X<$^O> X<$OSNAME>
563
564 The name of the operating system under which this copy of Perl was
565 built, as determined during the configuration process.  For examples
566 see L<perlport/PLATFORMS>.
567
568 The value is identical to C<$Config{'osname'}>.  See also L<Config>
569 and the B<-V> command-line switch documented in L<perlrun>.
570
571 In Windows platforms, C<$^O> is not very helpful: since it is always
572 C<MSWin32>, it doesn't tell the difference between
573 95/98/ME/NT/2000/XP/CE/.NET.  Use C<Win32::GetOSName()> or
574 Win32::GetOSVersion() (see L<Win32> and L<perlport>) to distinguish
575 between the variants.
576
577 This variable was added in Perl 5.003.
578
579 =item %SIG
580 X<%SIG>
581
582 The hash C<%SIG> contains signal handlers for signals.  For example:
583
584     sub handler {   # 1st argument is signal name
585         my($sig) = @_;
586         print "Caught a SIG$sig--shutting down\n";
587         close(LOG);
588         exit(0);
589         }
590
591     $SIG{'INT'}  = \&handler;
592     $SIG{'QUIT'} = \&handler;
593     ...
594     $SIG{'INT'}  = 'DEFAULT';   # restore default action
595     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
596
597 Using a value of C<'IGNORE'> usually has the effect of ignoring the
598 signal, except for the C<CHLD> signal.  See L<perlipc> for more about
599 this special case.
600
601 Here are some other examples:
602
603     $SIG{"PIPE"} = "Plumber";   # assumes main::Plumber (not
604                                 # recommended)
605     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current
606                                 # Plumber
607     $SIG{"PIPE"} = *Plumber;    # somewhat esoteric
608     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber()
609                                 # return??
610
611 Be sure not to use a bareword as the name of a signal handler,
612 lest you inadvertently call it.
613
614 If your system has the C<sigaction()> function then signal handlers
615 are installed using it.  This means you get reliable signal handling.
616
617 The default delivery policy of signals changed in Perl v5.8.0 from
618 immediate (also known as "unsafe") to deferred, also known as "safe
619 signals".  See L<perlipc> for more information.
620
621 Certain internal hooks can be also set using the C<%SIG> hash.  The
622 routine indicated by C<$SIG{__WARN__}> is called when a warning
623 message is about to be printed.  The warning message is passed as the
624 first argument.  The presence of a C<__WARN__> hook causes the
625 ordinary printing of warnings to C<STDERR> to be suppressed.  You can
626 use this to save warnings in a variable, or turn warnings into fatal
627 errors, like this:
628
629     local $SIG{__WARN__} = sub { die $_[0] };
630     eval $proggie;
631
632 As the C<'IGNORE'> hook is not supported by C<__WARN__>, you can
633 disable warnings using the empty subroutine:
634
635     local $SIG{__WARN__} = sub {};
636
637 The routine indicated by C<$SIG{__DIE__}> is called when a fatal
638 exception is about to be thrown.  The error message is passed as the
639 first argument.  When a C<__DIE__> hook routine returns, the exception
640 processing continues as it would have in the absence of the hook,
641 unless the hook routine itself exits via a C<goto &sub>, a loop exit,
642 or a C<die()>.  The C<__DIE__> handler is explicitly disabled during
643 the call, so that you can die from a C<__DIE__> handler.  Similarly
644 for C<__WARN__>.
645
646 Due to an implementation glitch, the C<$SIG{__DIE__}> hook is called
647 even inside an C<eval()>.  Do not use this to rewrite a pending
648 exception in C<$@>, or as a bizarre substitute for overriding
649 C<CORE::GLOBAL::die()>.  This strange action at a distance may be fixed
650 in a future release so that C<$SIG{__DIE__}> is only called if your
651 program is about to exit, as was the original intent.  Any other use is
652 deprecated.
653
654 C<__DIE__>/C<__WARN__> handlers are very special in one respect: they
655 may be called to report (probable) errors found by the parser.  In such
656 a case the parser may be in inconsistent state, so any attempt to
657 evaluate Perl code from such a handler will probably result in a
658 segfault.  This means that warnings or errors that result from parsing
659 Perl should be used with extreme caution, like this:
660
661     require Carp if defined $^S;
662     Carp::confess("Something wrong") if defined &Carp::confess;
663     die "Something wrong, but could not load Carp to give "
664       . "backtrace...\n\t"
665       . "To see backtrace try starting Perl with -MCarp switch";
666
667 Here the first line will load C<Carp> I<unless> it is the parser who
668 called the handler.  The second line will print backtrace and die if
669 C<Carp> was available.  The third line will be executed only if C<Carp> was
670 not available.
671
672 Having to even think about the C<$^S> variable in your exception
673 handlers is simply wrong.  C<$SIG{__DIE__}> as currently implemented
674 invites grievous and difficult to track down errors.  Avoid it
675 and use an C<END{}> or CORE::GLOBAL::die override instead.
676
677 See L<perlfunc/die>, L<perlfunc/warn>, L<perlfunc/eval>, and
678 L<warnings> for additional information.
679
680 =item $BASETIME
681
682 =item $^T
683 X<$^T> X<$BASETIME>
684
685 The time at which the program began running, in seconds since the
686 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>,
687 and B<-C> filetests are based on this value.
688
689 =item $PERL_VERSION
690
691 =item $^V
692 X<$^V> X<$PERL_VERSION>
693
694 The revision, version, and subversion of the Perl interpreter,
695 represented as a L<version> object.
696
697 This variable first appeared in perl v5.6.0; earlier versions of perl
698 will see an undefined value.  Before perl v5.10.0 C<$^V> was represented
699 as a v-string rather than a L<version> object.
700
701 C<$^V> can be used to determine whether the Perl interpreter executing
702 a script is in the right range of versions.  For example:
703
704     warn "Hashes not randomized!\n" if !$^V or $^V lt v5.8.1
705
706 While version objects overload stringification, to portably convert
707 C<$^V> into its string representation, use C<sprintf()>'s C<"%vd">
708 conversion, which works for both v-strings or version objects:
709
710     printf "version is v%vd\n", $^V;  # Perl's version
711
712 See the documentation of C<use VERSION> and C<require VERSION>
713 for a convenient way to fail if the running Perl interpreter is too old.
714
715 See also C<$]> for a decimal representation of the Perl version.
716
717 The main advantage of C<$^V> over C<$]> is that, for Perl v5.10.0 or
718 later, it overloads operators, allowing easy comparison against other
719 version representations (e.g. decimal, literal v-string, "v1.2.3", or
720 objects).  The disadvantage is that prior to v5.10.0, it was only a
721 literal v-string, which can't be easily printed or compared.
722
723 Mnemonic: use ^V for a version object.
724
725 =item ${^WIN32_SLOPPY_STAT}
726 X<${^WIN32_SLOPPY_STAT}> X<sitecustomize> X<sitecustomize.pl>
727
728 If this variable is set to a true value, then C<stat()> on Windows will
729 not try to open the file.  This means that the link count cannot be
730 determined and file attributes may be out of date if additional
731 hardlinks to the file exist.  On the other hand, not opening the file
732 is considerably faster, especially for files on network drives.
733
734 This variable could be set in the F<sitecustomize.pl> file to
735 configure the local Perl installation to use "sloppy" C<stat()> by
736 default.  See the documentation for B<-f> in
737 L<perlrun|perlrun/"Command Switches"> for more information about site
738 customization.
739
740 This variable was added in Perl v5.10.0.
741
742 =item $EXECUTABLE_NAME
743
744 =item $^X
745 X<$^X> X<$EXECUTABLE_NAME>
746
747 The name used to execute the current copy of Perl, from C's
748 C<argv[0]> or (where supported) F</proc/self/exe>.
749
750 Depending on the host operating system, the value of C<$^X> may be
751 a relative or absolute pathname of the perl program file, or may
752 be the string used to invoke perl but not the pathname of the
753 perl program file.  Also, most operating systems permit invoking
754 programs that are not in the PATH environment variable, so there
755 is no guarantee that the value of C<$^X> is in PATH.  For VMS, the
756 value may or may not include a version number.
757
758 You usually can use the value of C<$^X> to re-invoke an independent
759 copy of the same perl that is currently running, e.g.,
760
761     @first_run = `$^X -le "print int rand 100 for 1..100"`;
762
763 But recall that not all operating systems support forking or
764 capturing of the output of commands, so this complex statement
765 may not be portable.
766
767 It is not safe to use the value of C<$^X> as a path name of a file,
768 as some operating systems that have a mandatory suffix on
769 executable files do not require use of the suffix when invoking
770 a command.  To convert the value of C<$^X> to a path name, use the
771 following statements:
772
773     # Build up a set of file names (not command names).
774     use Config;
775     my $this_perl = $^X;
776     if ($^O ne 'VMS') {
777         $this_perl .= $Config{_exe}
778           unless $this_perl =~ m/$Config{_exe}$/i;
779         }
780
781 Because many operating systems permit anyone with read access to
782 the Perl program file to make a copy of it, patch the copy, and
783 then execute the copy, the security-conscious Perl programmer
784 should take care to invoke the installed copy of perl, not the
785 copy referenced by C<$^X>.  The following statements accomplish
786 this goal, and produce a pathname that can be invoked as a
787 command or referenced as a file.
788
789     use Config;
790     my $secure_perl_path = $Config{perlpath};
791     if ($^O ne 'VMS') {
792         $secure_perl_path .= $Config{_exe}
793             unless $secure_perl_path =~ m/$Config{_exe}$/i;
794         }
795
796 =back
797
798 =head2 Variables related to regular expressions
799
800 Most of the special variables related to regular expressions are side
801 effects.  Perl sets these variables when it has a successful match, so
802 you should check the match result before using them.  For instance:
803
804     if( /P(A)TT(ER)N/ ) {
805         print "I found $1 and $2\n";
806         }
807
808 These variables are read-only and dynamically-scoped, unless we note
809 otherwise.
810
811 The dynamic nature of the regular expression variables means that
812 their value is limited to the block that they are in, as demonstrated
813 by this bit of code:
814
815     my $outer = 'Wallace and Grommit';
816     my $inner = 'Mutt and Jeff';
817
818     my $pattern = qr/(\S+) and (\S+)/;
819
820     sub show_n { print "\$1 is $1; \$2 is $2\n" }
821
822     {
823     OUTER:
824         show_n() if $outer =~ m/$pattern/;
825
826         INNER: {
827             show_n() if $inner =~ m/$pattern/;
828             }
829
830         show_n();
831     }
832
833 The output shows that while in the C<OUTER> block, the values of C<$1>
834 and C<$2> are from the match against C<$outer>.  Inside the C<INNER>
835 block, the values of C<$1> and C<$2> are from the match against
836 C<$inner>, but only until the end of the block (i.e. the dynamic
837 scope).  After the C<INNER> block completes, the values of C<$1> and
838 C<$2> return to the values for the match against C<$outer> even though
839 we have not made another match:
840
841     $1 is Wallace; $2 is Grommit
842     $1 is Mutt; $2 is Jeff
843     $1 is Wallace; $2 is Grommit
844
845 =head3 Performance issues
846
847 Traditionally in Perl, any use of any of the three variables  C<$`>, C<$&>
848 or C<$'> (or their C<use English> equivalents) anywhere in the code, caused
849 all subsequent successful pattern matches to make a copy of the matched
850 string, in case the code might subsequently access one of those variables.
851 This imposed a considerable performance penalty across the whole program,
852 so generally the use of these variables has been discouraged.
853
854 In Perl 5.6.0 the C<@-> and C<@+> dynamic arrays were introduced that
855 supply the indices of successful matches. So you could for example do
856 this:
857
858     $str =~ /pattern/;
859
860     print $`, $&, $'; # bad: perfomance hit
861
862     print             # good: no perfomance hit
863         substr($str, 0,     $-[0]),
864         substr($str, $-[0], $+[0]-$-[0]),
865         substr($str, $+[0]);
866
867 In Perl 5.10.0 the C</p> match operator flag and the C<${^PREMATCH}>,
868 C<${^MATCH}>, and C<${^POSTMATCH}> variables were introduced, that allowed
869 you to suffer the penalties only on patterns marked with C</p>.
870
871 In Perl 5.18.0 onwards, perl started noting the presence of each of the
872 three variables separately, and only copied that part of the string
873 required; so in
874
875     $`; $&; "abcdefgh" =~ /d/
876
877 perl would only copy the "abcd" part of the string. That could make a big
878 difference in something like
879
880     $str = 'x' x 1_000_000;
881     $&; # whoops
882     $str =~ /x/g # one char copied a million times, not a million chars
883
884 In Perl 5.20.0 a new copy-on-write system was enabled by default, which
885 finally fixes all performance issues with these three variables, and makes
886 them safe to use anywhere.
887
888 The C<Devel::NYTProf> and C<Devel::FindAmpersand> modules can help you
889 find uses of these problematic match variables in your code.
890
891 =over 8
892
893 =item $<I<digits>> ($1, $2, ...)
894 X<$1> X<$2> X<$3>
895
896 Contains the subpattern from the corresponding set of capturing
897 parentheses from the last successful pattern match, not counting patterns
898 matched in nested blocks that have been exited already.
899
900 These variables are read-only and dynamically-scoped.
901
902 Mnemonic: like \digits.
903
904 =item $MATCH
905
906 =item $&
907 X<$&> X<$MATCH>
908
909 The string matched by the last successful pattern match (not counting
910 any matches hidden within a BLOCK or C<eval()> enclosed by the current
911 BLOCK).
912
913 See L</Performance issues> above for the serious performance implications
914 of using this variable (even once) in your code.
915
916 This variable is read-only and dynamically-scoped.
917
918 Mnemonic: like C<&> in some editors.
919
920 =item ${^MATCH}
921 X<${^MATCH}>
922
923 This is similar to C<$&> (C<$MATCH>) except that it does not incur the
924 performance penalty associated with that variable.
925
926 See L</Performance issues> above.
927
928 In Perl v5.18 and earlier, it is only guaranteed
929 to return a defined value when the pattern was compiled or executed with
930 the C</p> modifier.  In Perl v5.20, the C</p> modifier does nothing, so
931 C<${^MATCH}> does the same thing as C<$MATCH>.
932
933 This variable was added in Perl v5.10.0.
934
935 This variable is read-only and dynamically-scoped.
936
937 =item $PREMATCH
938
939 =item $`
940 X<$`> X<$PREMATCH> X<${^PREMATCH}>
941
942 The string preceding whatever was matched by the last successful
943 pattern match, not counting any matches hidden within a BLOCK or C<eval>
944 enclosed by the current BLOCK.
945
946 See L</Performance issues> above for the serious performance implications
947 of using this variable (even once) in your code.
948
949 This variable is read-only and dynamically-scoped.
950
951 Mnemonic: C<`> often precedes a quoted string.
952
953 =item ${^PREMATCH}
954 X<$`> X<${^PREMATCH}>
955
956 This is similar to C<$`> ($PREMATCH) except that it does not incur the
957 performance penalty associated with that variable.
958
959 See L</Performance issues> above.
960
961 In Perl v5.18 and earlier, it is only guaranteed
962 to return a defined value when the pattern was compiled or executed with
963 the C</p> modifier.  In Perl v5.20, the C</p> modifier does nothing, so
964 C<${^PREMATCH}> does the same thing as C<$PREMATCH>.
965
966 This variable was added in Perl v5.10.0.
967
968 This variable is read-only and dynamically-scoped.
969
970 =item $POSTMATCH
971
972 =item $'
973 X<$'> X<$POSTMATCH> X<${^POSTMATCH}> X<@->
974
975 The string following whatever was matched by the last successful
976 pattern match (not counting any matches hidden within a BLOCK or C<eval()>
977 enclosed by the current BLOCK).  Example:
978
979     local $_ = 'abcdefghi';
980     /def/;
981     print "$`:$&:$'\n";         # prints abc:def:ghi
982
983 See L</Performance issues> above for the serious performance implications
984 of using this variable (even once) in your code.
985
986 This variable is read-only and dynamically-scoped.
987
988 Mnemonic: C<'> often follows a quoted string.
989
990 =item ${^POSTMATCH}
991 X<${^POSTMATCH}> X<$'> X<$POSTMATCH>
992
993 This is similar to C<$'> (C<$POSTMATCH>) except that it does not incur the
994 performance penalty associated with that variable.
995
996 See L</Performance issues> above.
997
998 In Perl v5.18 and earlier, it is only guaranteed
999 to return a defined value when the pattern was compiled or executed with
1000 the C</p> modifier.  In Perl v5.20, the C</p> modifier does nothing, so
1001 C<${^POSTMATCH}> does the same thing as C<$POSTMATCH>.
1002
1003 This variable was added in Perl v5.10.0.
1004
1005 This variable is read-only and dynamically-scoped.
1006
1007 =item $LAST_PAREN_MATCH
1008
1009 =item $+
1010 X<$+> X<$LAST_PAREN_MATCH>
1011
1012 The text matched by the last bracket of the last successful search pattern.
1013 This is useful if you don't know which one of a set of alternative patterns
1014 matched.  For example:
1015
1016     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
1017
1018 This variable is read-only and dynamically-scoped.
1019
1020 Mnemonic: be positive and forward looking.
1021
1022 =item $LAST_SUBMATCH_RESULT
1023
1024 =item $^N
1025 X<$^N> X<$LAST_SUBMATCH_RESULT>
1026
1027 The text matched by the used group most-recently closed (i.e. the group
1028 with the rightmost closing parenthesis) of the last successful search
1029 pattern.
1030
1031 This is primarily used inside C<(?{...})> blocks for examining text
1032 recently matched.  For example, to effectively capture text to a variable
1033 (in addition to C<$1>, C<$2>, etc.), replace C<(...)> with
1034
1035     (?:(...)(?{ $var = $^N }))
1036
1037 By setting and then using C<$var> in this way relieves you from having to
1038 worry about exactly which numbered set of parentheses they are.
1039
1040 This variable was added in Perl v5.8.0.
1041
1042 Mnemonic: the (possibly) Nested parenthesis that most recently closed.
1043
1044 =item @LAST_MATCH_END
1045
1046 =item @+
1047 X<@+> X<@LAST_MATCH_END>
1048
1049 This array holds the offsets of the ends of the last successful
1050 submatches in the currently active dynamic scope.  C<$+[0]> is
1051 the offset into the string of the end of the entire match.  This
1052 is the same value as what the C<pos> function returns when called
1053 on the variable that was matched against.  The I<n>th element
1054 of this array holds the offset of the I<n>th submatch, so
1055 C<$+[1]> is the offset past where C<$1> ends, C<$+[2]> the offset
1056 past where C<$2> ends, and so on.  You can use C<$#+> to determine
1057 how many subgroups were in the last successful match.  See the
1058 examples given for the C<@-> variable.
1059
1060 This variable was added in Perl v5.6.0.
1061
1062 =item %LAST_PAREN_MATCH
1063
1064 =item %+
1065 X<%+> X<%LAST_PAREN_MATCH>
1066
1067 Similar to C<@+>, the C<%+> hash allows access to the named capture
1068 buffers, should they exist, in the last successful match in the
1069 currently active dynamic scope.
1070
1071 For example, C<$+{foo}> is equivalent to C<$1> after the following match:
1072
1073     'foo' =~ /(?<foo>foo)/;
1074
1075 The keys of the C<%+> hash list only the names of buffers that have
1076 captured (and that are thus associated to defined values).
1077
1078 The underlying behaviour of C<%+> is provided by the
1079 L<Tie::Hash::NamedCapture> module.
1080
1081 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
1082 associated with the last successful regular expression.  Therefore mixing
1083 iterative access to them via C<each> may have unpredictable results.
1084 Likewise, if the last successful match changes, then the results may be
1085 surprising.
1086
1087 This variable was added in Perl v5.10.0.
1088
1089 This variable is read-only and dynamically-scoped.
1090
1091 =item @LAST_MATCH_START
1092
1093 =item @-
1094 X<@-> X<@LAST_MATCH_START>
1095
1096 C<$-[0]> is the offset of the start of the last successful match.
1097 C<$-[>I<n>C<]> is the offset of the start of the substring matched by
1098 I<n>-th subpattern, or undef if the subpattern did not match.
1099
1100 Thus, after a match against C<$_>, C<$&> coincides with C<substr $_, $-[0],
1101 $+[0] - $-[0]>.  Similarly, $I<n> coincides with C<substr $_, $-[n],
1102 $+[n] - $-[n]> if C<$-[n]> is defined, and $+ coincides with
1103 C<substr $_, $-[$#-], $+[$#-] - $-[$#-]>.  One can use C<$#-> to find the
1104 last matched subgroup in the last successful match.  Contrast with
1105 C<$#+>, the number of subgroups in the regular expression.  Compare
1106 with C<@+>.
1107
1108 This array holds the offsets of the beginnings of the last
1109 successful submatches in the currently active dynamic scope.
1110 C<$-[0]> is the offset into the string of the beginning of the
1111 entire match.  The I<n>th element of this array holds the offset
1112 of the I<n>th submatch, so C<$-[1]> is the offset where C<$1>
1113 begins, C<$-[2]> the offset where C<$2> begins, and so on.
1114
1115 After a match against some variable C<$var>:
1116
1117 =over 5
1118
1119 =item C<$`> is the same as C<substr($var, 0, $-[0])>
1120
1121 =item C<$&> is the same as C<substr($var, $-[0], $+[0] - $-[0])>
1122
1123 =item C<$'> is the same as C<substr($var, $+[0])>
1124
1125 =item C<$1> is the same as C<substr($var, $-[1], $+[1] - $-[1])>
1126
1127 =item C<$2> is the same as C<substr($var, $-[2], $+[2] - $-[2])>
1128
1129 =item C<$3> is the same as C<substr($var, $-[3], $+[3] - $-[3])>
1130
1131 =back
1132
1133 This variable was added in Perl v5.6.0.
1134
1135 =item %LAST_MATCH_START
1136
1137 =item %-
1138 X<%-> X<%LAST_MATCH_START>
1139
1140 Similar to C<%+>, this variable allows access to the named capture groups
1141 in the last successful match in the currently active dynamic scope.  To
1142 each capture group name found in the regular expression, it associates a
1143 reference to an array containing the list of values captured by all
1144 buffers with that name (should there be several of them), in the order
1145 where they appear.
1146
1147 Here's an example:
1148
1149     if ('1234' =~ /(?<A>1)(?<B>2)(?<A>3)(?<B>4)/) {
1150         foreach my $bufname (sort keys %-) {
1151             my $ary = $-{$bufname};
1152             foreach my $idx (0..$#$ary) {
1153                 print "\$-{$bufname}[$idx] : ",
1154                       (defined($ary->[$idx])
1155                           ? "'$ary->[$idx]'"
1156                           : "undef"),
1157                       "\n";
1158             }
1159         }
1160     }
1161
1162 would print out:
1163
1164     $-{A}[0] : '1'
1165     $-{A}[1] : '3'
1166     $-{B}[0] : '2'
1167     $-{B}[1] : '4'
1168
1169 The keys of the C<%-> hash correspond to all buffer names found in
1170 the regular expression.
1171
1172 The behaviour of C<%-> is implemented via the
1173 L<Tie::Hash::NamedCapture> module.
1174
1175 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
1176 associated with the last successful regular expression.  Therefore mixing
1177 iterative access to them via C<each> may have unpredictable results.
1178 Likewise, if the last successful match changes, then the results may be
1179 surprising.
1180
1181 This variable was added in Perl v5.10.0.
1182
1183 This variable is read-only and dynamically-scoped.
1184
1185 =item $LAST_REGEXP_CODE_RESULT
1186
1187 =item $^R
1188 X<$^R> X<$LAST_REGEXP_CODE_RESULT>
1189
1190 The result of evaluation of the last successful C<(?{ code })>
1191 regular expression assertion (see L<perlre>).  May be written to.
1192
1193 This variable was added in Perl 5.005.
1194
1195 =item ${^RE_DEBUG_FLAGS}
1196 X<${^RE_DEBUG_FLAGS}>
1197
1198 The current value of the regex debugging flags.  Set to 0 for no debug output
1199 even when the C<re 'debug'> module is loaded.  See L<re> for details.
1200
1201 This variable was added in Perl v5.10.0.
1202
1203 =item ${^RE_TRIE_MAXBUF}
1204 X<${^RE_TRIE_MAXBUF}>
1205
1206 Controls how certain regex optimisations are applied and how much memory they
1207 utilize.  This value by default is 65536 which corresponds to a 512kB
1208 temporary cache.  Set this to a higher value to trade
1209 memory for speed when matching large alternations.  Set
1210 it to a lower value if you want the optimisations to
1211 be as conservative of memory as possible but still occur, and set it to a
1212 negative value to prevent the optimisation and conserve the most memory.
1213 Under normal situations this variable should be of no interest to you.
1214
1215 This variable was added in Perl v5.10.0.
1216
1217 =back
1218
1219 =head2 Variables related to filehandles
1220
1221 Variables that depend on the currently selected filehandle may be set
1222 by calling an appropriate object method on the C<IO::Handle> object,
1223 although this is less efficient than using the regular built-in
1224 variables.  (Summary lines below for this contain the word HANDLE.)
1225 First you must say
1226
1227     use IO::Handle;
1228
1229 after which you may use either
1230
1231     method HANDLE EXPR
1232
1233 or more safely,
1234
1235     HANDLE->method(EXPR)
1236
1237 Each method returns the old value of the C<IO::Handle> attribute.  The
1238 methods each take an optional EXPR, which, if supplied, specifies the
1239 new value for the C<IO::Handle> attribute in question.  If not
1240 supplied, most methods do nothing to the current value--except for
1241 C<autoflush()>, which will assume a 1 for you, just to be different.
1242
1243 Because loading in the C<IO::Handle> class is an expensive operation,
1244 you should learn how to use the regular built-in variables.
1245
1246 A few of these variables are considered "read-only".  This means that
1247 if you try to assign to this variable, either directly or indirectly
1248 through a reference, you'll raise a run-time exception.
1249
1250 You should be very careful when modifying the default values of most
1251 special variables described in this document.  In most cases you want
1252 to localize these variables before changing them, since if you don't,
1253 the change may affect other modules which rely on the default values
1254 of the special variables that you have changed.  This is one of the
1255 correct ways to read the whole file at once:
1256
1257     open my $fh, "<", "foo" or die $!;
1258     local $/; # enable localized slurp mode
1259     my $content = <$fh>;
1260     close $fh;
1261
1262 But the following code is quite bad:
1263
1264     open my $fh, "<", "foo" or die $!;
1265     undef $/; # enable slurp mode
1266     my $content = <$fh>;
1267     close $fh;
1268
1269 since some other module, may want to read data from some file in the
1270 default "line mode", so if the code we have just presented has been
1271 executed, the global value of C<$/> is now changed for any other code
1272 running inside the same Perl interpreter.
1273
1274 Usually when a variable is localized you want to make sure that this
1275 change affects the shortest scope possible.  So unless you are already
1276 inside some short C<{}> block, you should create one yourself.  For
1277 example:
1278
1279     my $content = '';
1280     open my $fh, "<", "foo" or die $!;
1281     {
1282         local $/;
1283         $content = <$fh>;
1284     }
1285     close $fh;
1286
1287 Here is an example of how your own code can go broken:
1288
1289     for ( 1..3 ){
1290         $\ = "\r\n";
1291         nasty_break();
1292         print "$_";
1293     }
1294
1295     sub nasty_break {
1296         $\ = "\f";
1297         # do something with $_
1298     }
1299
1300 You probably expect this code to print the equivalent of
1301
1302     "1\r\n2\r\n3\r\n"
1303
1304 but instead you get:
1305
1306     "1\f2\f3\f"
1307
1308 Why? Because C<nasty_break()> modifies C<$\> without localizing it
1309 first.  The value you set in  C<nasty_break()> is still there when you
1310 return.  The fix is to add C<local()> so the value doesn't leak out of
1311 C<nasty_break()>:
1312
1313     local $\ = "\f";
1314
1315 It's easy to notice the problem in such a short example, but in more
1316 complicated code you are looking for trouble if you don't localize
1317 changes to the special variables.
1318
1319 =over 8
1320
1321 =item $ARGV
1322 X<$ARGV>
1323
1324 Contains the name of the current file when reading from C<< <> >>.
1325
1326 =item @ARGV
1327 X<@ARGV>
1328
1329 The array C<@ARGV> contains the command-line arguments intended for
1330 the script.  C<$#ARGV> is generally the number of arguments minus
1331 one, because C<$ARGV[0]> is the first argument, I<not> the program's
1332 command name itself.  See L</$0> for the command name.
1333
1334 =item ARGV
1335 X<ARGV>
1336
1337 The special filehandle that iterates over command-line filenames in
1338 C<@ARGV>.  Usually written as the null filehandle in the angle operator
1339 C<< <> >>.  Note that currently C<ARGV> only has its magical effect
1340 within the C<< <> >> operator; elsewhere it is just a plain filehandle
1341 corresponding to the last file opened by C<< <> >>.  In particular,
1342 passing C<\*ARGV> as a parameter to a function that expects a filehandle
1343 may not cause your function to automatically read the contents of all the
1344 files in C<@ARGV>.
1345
1346 =item ARGVOUT
1347 X<ARGVOUT>
1348
1349 The special filehandle that points to the currently open output file
1350 when doing edit-in-place processing with B<-i>.  Useful when you have
1351 to do a lot of inserting and don't want to keep modifying C<$_>.  See
1352 L<perlrun> for the B<-i> switch.
1353
1354 =item IO::Handle->output_field_separator( EXPR )
1355
1356 =item $OUTPUT_FIELD_SEPARATOR
1357
1358 =item $OFS
1359
1360 =item $,
1361 X<$,> X<$OFS> X<$OUTPUT_FIELD_SEPARATOR>
1362
1363 The output field separator for the print operator.  If defined, this
1364 value is printed between each of print's arguments.  Default is C<undef>.
1365
1366 You cannot call C<output_field_separator()> on a handle, only as a
1367 static method.  See L<IO::Handle|IO::Handle>.
1368
1369 Mnemonic: what is printed when there is a "," in your print statement.
1370
1371 =item HANDLE->input_line_number( EXPR )
1372
1373 =item $INPUT_LINE_NUMBER
1374
1375 =item $NR
1376
1377 =item $.
1378 X<$.> X<$NR> X<$INPUT_LINE_NUMBER> X<line number>
1379
1380 Current line number for the last filehandle accessed.
1381
1382 Each filehandle in Perl counts the number of lines that have been read
1383 from it.  (Depending on the value of C<$/>, Perl's idea of what
1384 constitutes a line may not match yours.)  When a line is read from a
1385 filehandle (via C<readline()> or C<< <> >>), or when C<tell()> or
1386 C<seek()> is called on it, C<$.> becomes an alias to the line counter
1387 for that filehandle.
1388
1389 You can adjust the counter by assigning to C<$.>, but this will not
1390 actually move the seek pointer.  I<Localizing C<$.> will not localize
1391 the filehandle's line count>.  Instead, it will localize perl's notion
1392 of which filehandle C<$.> is currently aliased to.
1393
1394 C<$.> is reset when the filehandle is closed, but B<not> when an open
1395 filehandle is reopened without an intervening C<close()>.  For more
1396 details, see L<perlop/"IE<sol>O Operators">.  Because C<< <> >> never does
1397 an explicit close, line numbers increase across C<ARGV> files (but see
1398 examples in L<perlfunc/eof>).
1399
1400 You can also use C<< HANDLE->input_line_number(EXPR) >> to access the
1401 line counter for a given filehandle without having to worry about
1402 which handle you last accessed.
1403
1404 Mnemonic: many programs use "." to mean the current line number.
1405
1406 =item IO::Handle->input_record_separator( EXPR )
1407
1408 =item $INPUT_RECORD_SEPARATOR
1409
1410 =item $RS
1411
1412 =item $/
1413 X<$/> X<$RS> X<$INPUT_RECORD_SEPARATOR>
1414
1415 The input record separator, newline by default.  This influences Perl's
1416 idea of what a "line" is.  Works like B<awk>'s RS variable, including
1417 treating empty lines as a terminator if set to the null string (an
1418 empty line cannot contain any spaces or tabs).  You may set it to a
1419 multi-character string to match a multi-character terminator, or to
1420 C<undef> to read through the end of file.  Setting it to C<"\n\n">
1421 means something slightly different than setting to C<"">, if the file
1422 contains consecutive empty lines.  Setting to C<""> will treat two or
1423 more consecutive empty lines as a single empty line.  Setting to
1424 C<"\n\n"> will blindly assume that the next input character belongs to
1425 the next paragraph, even if it's a newline.
1426
1427     local $/;           # enable "slurp" mode
1428     local $_ = <FH>;    # whole file now here
1429     s/\n[ \t]+/ /g;
1430
1431 Remember: the value of C<$/> is a string, not a regex.  B<awk> has to
1432 be better for something. :-)
1433
1434 Setting C<$/> to a reference to an integer, scalar containing an
1435 integer, or scalar that's convertible to an integer will attempt to
1436 read records instead of lines, with the maximum record size being the
1437 referenced integer number of characters.  So this:
1438
1439     local $/ = \32768; # or \"32768", or \$var_containing_32768
1440     open my $fh, "<", $myfile or die $!;
1441     local $_ = <$fh>;
1442
1443 will read a record of no more than 32768 characters from $fh.  If you're
1444 not reading from a record-oriented file (or your OS doesn't have
1445 record-oriented files), then you'll likely get a full chunk of data
1446 with every read.  If a record is larger than the record size you've
1447 set, you'll get the record back in pieces.  Trying to set the record
1448 size to zero or less is deprecated and will cause $/ to have the value
1449 of "undef", which will cause reading in the (rest of the) whole file.
1450
1451 As of 5.19.9 setting C<$/> to any other form of reference will throw a
1452 fatal exception. This is in preparation for supporting new ways to set
1453 C<$/> in the future.
1454
1455 On VMS only, record reads bypass PerlIO layers and any associated
1456 buffering, so you must not mix record and non-record reads on the
1457 same filehandle.  Record mode mixes with line mode only when the
1458 same buffering layer is in use for both modes.
1459
1460 You cannot call C<input_record_separator()> on a handle, only as a
1461 static method.  See L<IO::Handle|IO::Handle>.
1462
1463 See also L<perlport/"Newlines">.  Also see L</$.>.
1464
1465 Mnemonic: / delimits line boundaries when quoting poetry.
1466
1467 =item IO::Handle->output_record_separator( EXPR )
1468
1469 =item $OUTPUT_RECORD_SEPARATOR
1470
1471 =item $ORS
1472
1473 =item $\
1474 X<$\> X<$ORS> X<$OUTPUT_RECORD_SEPARATOR>
1475
1476 The output record separator for the print operator.  If defined, this
1477 value is printed after the last of print's arguments.  Default is C<undef>.
1478
1479 You cannot call C<output_record_separator()> on a handle, only as a
1480 static method.  See L<IO::Handle|IO::Handle>.
1481
1482 Mnemonic: you set C<$\> instead of adding "\n" at the end of the print.
1483 Also, it's just like C<$/>, but it's what you get "back" from Perl.
1484
1485 =item HANDLE->autoflush( EXPR )
1486
1487 =item $OUTPUT_AUTOFLUSH
1488
1489 =item $|
1490 X<$|> X<autoflush> X<flush> X<$OUTPUT_AUTOFLUSH>
1491
1492 If set to nonzero, forces a flush right away and after every write or
1493 print on the currently selected output channel.  Default is 0
1494 (regardless of whether the channel is really buffered by the system or
1495 not; C<$|> tells you only whether you've asked Perl explicitly to
1496 flush after each write).  STDOUT will typically be line buffered if
1497 output is to the terminal and block buffered otherwise.  Setting this
1498 variable is useful primarily when you are outputting to a pipe or
1499 socket, such as when you are running a Perl program under B<rsh> and
1500 want to see the output as it's happening.  This has no effect on input
1501 buffering.  See L<perlfunc/getc> for that.  See L<perlfunc/select> on
1502 how to select the output channel.  See also L<IO::Handle>.
1503
1504 Mnemonic: when you want your pipes to be piping hot.
1505
1506 =item ${^LAST_FH}
1507 X<${^LAST_FH}>
1508
1509 This read-only variable contains a reference to the last-read filehandle.
1510 This is set by C<< <HANDLE> >>, C<readline>, C<tell>, C<eof> and C<seek>.
1511 This is the same handle that C<$.> and C<tell> and C<eof> without arguments
1512 use.  It is also the handle used when Perl appends ", <STDIN> line 1" to
1513 an error or warning message.
1514
1515 This variable was added in Perl v5.18.0.
1516
1517 =back
1518
1519 =head3 Variables related to formats
1520
1521 The special variables for formats are a subset of those for
1522 filehandles.  See L<perlform> for more information about Perl's
1523 formats.
1524
1525 =over 8
1526
1527 =item $ACCUMULATOR
1528
1529 =item $^A
1530 X<$^A> X<$ACCUMULATOR>
1531
1532 The current value of the C<write()> accumulator for C<format()> lines.
1533 A format contains C<formline()> calls that put their result into
1534 C<$^A>.  After calling its format, C<write()> prints out the contents
1535 of C<$^A> and empties.  So you never really see the contents of C<$^A>
1536 unless you call C<formline()> yourself and then look at it.  See
1537 L<perlform> and L<perlfunc/"formline PICTURE,LIST">.
1538
1539 =item IO::Handle->format_formfeed(EXPR)
1540
1541 =item $FORMAT_FORMFEED
1542
1543 =item $^L
1544 X<$^L> X<$FORMAT_FORMFEED>
1545
1546 What formats output as a form feed.  The default is C<\f>.
1547
1548 You cannot call C<format_formfeed()> on a handle, only as a static
1549 method.  See L<IO::Handle|IO::Handle>.
1550
1551 =item HANDLE->format_page_number(EXPR)
1552
1553 =item $FORMAT_PAGE_NUMBER
1554
1555 =item $%
1556 X<$%> X<$FORMAT_PAGE_NUMBER>
1557
1558 The current page number of the currently selected output channel.
1559
1560 Mnemonic: C<%> is page number in B<nroff>.
1561
1562 =item HANDLE->format_lines_left(EXPR)
1563
1564 =item $FORMAT_LINES_LEFT
1565
1566 =item $-
1567 X<$-> X<$FORMAT_LINES_LEFT>
1568
1569 The number of lines left on the page of the currently selected output
1570 channel.
1571
1572 Mnemonic: lines_on_page - lines_printed.
1573
1574 =item IO::Handle->format_line_break_characters EXPR
1575
1576 =item $FORMAT_LINE_BREAK_CHARACTERS
1577
1578 =item $:
1579 X<$:> X<FORMAT_LINE_BREAK_CHARACTERS>
1580
1581 The current set of characters after which a string may be broken to
1582 fill continuation fields (starting with C<^>) in a format.  The default is
1583 S<" \n-">, to break on a space, newline, or a hyphen.
1584
1585 You cannot call C<format_line_break_characters()> on a handle, only as
1586 a static method.  See L<IO::Handle|IO::Handle>.
1587
1588 Mnemonic: a "colon" in poetry is a part of a line.
1589
1590 =item HANDLE->format_lines_per_page(EXPR)
1591
1592 =item $FORMAT_LINES_PER_PAGE
1593
1594 =item $=
1595 X<$=> X<$FORMAT_LINES_PER_PAGE>
1596
1597 The current page length (printable lines) of the currently selected
1598 output channel.  The default is 60.
1599
1600 Mnemonic: = has horizontal lines.
1601
1602 =item HANDLE->format_top_name(EXPR)
1603
1604 =item $FORMAT_TOP_NAME
1605
1606 =item $^
1607 X<$^> X<$FORMAT_TOP_NAME>
1608
1609 The name of the current top-of-page format for the currently selected
1610 output channel.  The default is the name of the filehandle with C<_TOP>
1611 appended.  For example, the default format top name for the C<STDOUT>
1612 filehandle is C<STDOUT_TOP>.
1613
1614 Mnemonic: points to top of page.
1615
1616 =item HANDLE->format_name(EXPR)
1617
1618 =item $FORMAT_NAME
1619
1620 =item $~
1621 X<$~> X<$FORMAT_NAME>
1622
1623 The name of the current report format for the currently selected
1624 output channel.  The default format name is the same as the filehandle
1625 name.  For example, the default format name for the C<STDOUT>
1626 filehandle is just C<STDOUT>.
1627
1628 Mnemonic: brother to C<$^>.
1629
1630 =back
1631
1632 =head2 Error Variables
1633 X<error> X<exception>
1634
1635 The variables C<$@>, C<$!>, C<$^E>, and C<$?> contain information
1636 about different types of error conditions that may appear during
1637 execution of a Perl program.  The variables are shown ordered by
1638 the "distance" between the subsystem which reported the error and
1639 the Perl process.  They correspond to errors detected by the Perl
1640 interpreter, C library, operating system, or an external program,
1641 respectively.
1642
1643 To illustrate the differences between these variables, consider the
1644 following Perl expression, which uses a single-quoted string.  After
1645 execution of this statement, perl may have set all four special error
1646 variables:
1647
1648     eval q{
1649         open my $pipe, "/cdrom/install |" or die $!;
1650         my @res = <$pipe>;
1651         close $pipe or die "bad pipe: $?, $!";
1652     };
1653
1654 When perl executes the C<eval()> expression, it translates the
1655 C<open()>, C<< <PIPE> >>, and C<close> calls in the C run-time library
1656 and thence to the operating system kernel.  perl sets C<$!> to
1657 the C library's C<errno> if one of these calls fails.
1658
1659 C<$@> is set if the string to be C<eval>-ed did not compile (this may
1660 happen if C<open> or C<close> were imported with bad prototypes), or
1661 if Perl code executed during evaluation C<die()>d.  In these cases the
1662 value of C<$@> is the compile error, or the argument to C<die> (which
1663 will interpolate C<$!> and C<$?>).  (See also L<Fatal>, though.)
1664
1665 Under a few operating systems, C<$^E> may contain a more verbose error
1666 indicator, such as in this case, "CDROM tray not closed."  Systems that
1667 do not support extended error messages leave C<$^E> the same as C<$!>.
1668
1669 Finally, C<$?> may be set to non-0 value if the external program
1670 F</cdrom/install> fails.  The upper eight bits reflect specific error
1671 conditions encountered by the program (the program's C<exit()> value).
1672 The lower eight bits reflect mode of failure, like signal death and
1673 core dump information.  See L<wait(2)> for details.  In contrast to
1674 C<$!> and C<$^E>, which are set only if error condition is detected,
1675 the variable C<$?> is set on each C<wait> or pipe C<close>,
1676 overwriting the old value.  This is more like C<$@>, which on every
1677 C<eval()> is always set on failure and cleared on success.
1678
1679 For more details, see the individual descriptions at C<$@>, C<$!>,
1680 C<$^E>, and C<$?>.
1681
1682 =over 8
1683
1684 =item ${^CHILD_ERROR_NATIVE}
1685 X<$^CHILD_ERROR_NATIVE>
1686
1687 The native status returned by the last pipe close, backtick (C<``>)
1688 command, successful call to C<wait()> or C<waitpid()>, or from the
1689 C<system()> operator.  On POSIX-like systems this value can be decoded
1690 with the WIFEXITED, WEXITSTATUS, WIFSIGNALED, WTERMSIG, WIFSTOPPED,
1691 WSTOPSIG and WIFCONTINUED functions provided by the L<POSIX> module.
1692
1693 Under VMS this reflects the actual VMS exit status; i.e. it is the
1694 same as C<$?> when the pragma C<use vmsish 'status'> is in effect.
1695
1696 This variable was added in Perl v5.10.0.
1697
1698 =item $EXTENDED_OS_ERROR
1699
1700 =item $^E
1701 X<$^E> X<$EXTENDED_OS_ERROR>
1702
1703 Error information specific to the current operating system.  At the
1704 moment, this differs from C<$!> under only VMS, OS/2, and Win32 (and
1705 for MacPerl).  On all other platforms, C<$^E> is always just the same
1706 as C<$!>.
1707
1708 Under VMS, C<$^E> provides the VMS status value from the last system
1709 error.  This is more specific information about the last system error
1710 than that provided by C<$!>.  This is particularly important when C<$!>
1711 is set to B<EVMSERR>.
1712
1713 Under OS/2, C<$^E> is set to the error code of the last call to OS/2
1714 API either via CRT, or directly from perl.
1715
1716 Under Win32, C<$^E> always returns the last error information reported
1717 by the Win32 call C<GetLastError()> which describes the last error
1718 from within the Win32 API.  Most Win32-specific code will report errors
1719 via C<$^E>.  ANSI C and Unix-like calls set C<errno> and so most
1720 portable Perl code will report errors via C<$!>.
1721
1722 Caveats mentioned in the description of C<$!> generally apply to
1723 C<$^E>, also.
1724
1725 This variable was added in Perl 5.003.
1726
1727 Mnemonic: Extra error explanation.
1728
1729 =item $EXCEPTIONS_BEING_CAUGHT
1730
1731 =item $^S
1732 X<$^S> X<$EXCEPTIONS_BEING_CAUGHT>
1733
1734 Current state of the interpreter.
1735
1736         $^S         State
1737         ---------   -------------------------------------
1738         undef       Parsing module, eval, or main program
1739         true (1)    Executing an eval
1740         false (0)   Otherwise
1741
1742 The first state may happen in C<$SIG{__DIE__}> and C<$SIG{__WARN__}>
1743 handlers.
1744
1745 The English name $EXCEPTIONS_BEING_CAUGHT is slightly misleading, because
1746 the C<undef> value does not indicate whether exceptions are being caught,
1747 since compilation of the main program does not catch exceptions.
1748
1749 This variable was added in Perl 5.004.
1750
1751 =item $WARNING
1752
1753 =item $^W
1754 X<$^W> X<$WARNING>
1755
1756 The current value of the warning switch, initially true if B<-w> was
1757 used, false otherwise, but directly modifiable.
1758
1759 See also L<warnings>.
1760
1761 Mnemonic: related to the B<-w> switch.
1762
1763 =item ${^WARNING_BITS}
1764 X<${^WARNING_BITS}>
1765
1766 The current set of warning checks enabled by the C<use warnings> pragma.
1767 It has the same scoping as the C<$^H> and C<%^H> variables.  The exact
1768 values are considered internal to the L<warnings> pragma and may change
1769 between versions of Perl.
1770
1771 This variable was added in Perl v5.6.0.
1772
1773 =item $OS_ERROR
1774
1775 =item $ERRNO
1776
1777 =item $!
1778 X<$!> X<$ERRNO> X<$OS_ERROR>
1779
1780 When referenced, C<$!> retrieves the current value
1781 of the C C<errno> integer variable.
1782 If C<$!> is assigned a numerical value, that value is stored in C<errno>.
1783 When referenced as a string, C<$!> yields the system error string
1784 corresponding to C<errno>.
1785
1786 Many system or library calls set C<errno> if they fail,
1787 to indicate the cause of failure.  They usually do B<not>
1788 set C<errno> to zero if they succeed.  This means C<errno>,
1789 hence C<$!>, is meaningful only I<immediately> after a B<failure>:
1790
1791     if (open my $fh, "<", $filename) {
1792                 # Here $! is meaningless.
1793                 ...
1794     }
1795     else {
1796                 # ONLY here is $! meaningful.
1797                 ...
1798                 # Already here $! might be meaningless.
1799     }
1800     # Since here we might have either success or failure,
1801     # $! is meaningless.
1802
1803 Here, I<meaningless> means that C<$!> may be unrelated to the outcome
1804 of the C<open()> operator.  Assignment to C<$!> is similarly ephemeral.
1805 It can be used immediately before invoking the C<die()> operator,
1806 to set the exit value, or to inspect the system error string
1807 corresponding to error I<n>, or to restore C<$!> to a meaningful state.
1808
1809 Mnemonic: What just went bang?
1810
1811 =item %OS_ERROR
1812
1813 =item %ERRNO
1814
1815 =item %!
1816 X<%!> X<%OS_ERROR> X<%ERRNO>
1817
1818 Each element of C<%!> has a true value only if C<$!> is set to that
1819 value.  For example, C<$!{ENOENT}> is true if and only if the current
1820 value of C<$!> is C<ENOENT>; that is, if the most recent error was "No
1821 such file or directory" (or its moral equivalent: not all operating
1822 systems give that exact error, and certainly not all languages).  To
1823 check if a particular key is meaningful on your system, use C<exists
1824 $!{the_key}>; for a list of legal keys, use C<keys %!>.  See L<Errno>
1825 for more information, and also see L</$!>.
1826
1827 This variable was added in Perl 5.005.
1828
1829 =item $CHILD_ERROR
1830
1831 =item $?
1832 X<$?> X<$CHILD_ERROR>
1833
1834 The status returned by the last pipe close, backtick (C<``>) command,
1835 successful call to C<wait()> or C<waitpid()>, or from the C<system()>
1836 operator.  This is just the 16-bit status word returned by the
1837 traditional Unix C<wait()> system call (or else is made up to look
1838 like it).  Thus, the exit value of the subprocess is really (C<<< $? >>
1839 8 >>>), and C<$? & 127> gives which signal, if any, the process died
1840 from, and C<$? & 128> reports whether there was a core dump.
1841
1842 Additionally, if the C<h_errno> variable is supported in C, its value
1843 is returned via C<$?> if any C<gethost*()> function fails.
1844
1845 If you have installed a signal handler for C<SIGCHLD>, the
1846 value of C<$?> will usually be wrong outside that handler.
1847
1848 Inside an C<END> subroutine C<$?> contains the value that is going to be
1849 given to C<exit()>.  You can modify C<$?> in an C<END> subroutine to
1850 change the exit status of your program.  For example:
1851
1852     END {
1853         $? = 1 if $? == 255;  # die would make it 255
1854     }
1855
1856 Under VMS, the pragma C<use vmsish 'status'> makes C<$?> reflect the
1857 actual VMS exit status, instead of the default emulation of POSIX
1858 status; see L<perlvms/$?> for details.
1859
1860 Mnemonic: similar to B<sh> and B<ksh>.
1861
1862 =item $EVAL_ERROR
1863
1864 =item $@
1865 X<$@> X<$EVAL_ERROR>
1866
1867 The Perl syntax error message from the
1868 last C<eval()> operator.  If C<$@> is
1869 the null string, the last C<eval()> parsed and executed correctly
1870 (although the operations you invoked may have failed in the normal
1871 fashion).
1872
1873 Warning messages are not collected in this variable.  You can, however,
1874 set up a routine to process warnings by setting C<$SIG{__WARN__}> as
1875 described in L</%SIG>.
1876
1877 Mnemonic: Where was the syntax error "at"?
1878
1879 =back
1880
1881 =head2 Variables related to the interpreter state
1882
1883 These variables provide information about the current interpreter state.
1884
1885 =over 8
1886
1887 =item $COMPILING
1888
1889 =item $^C
1890 X<$^C> X<$COMPILING>
1891
1892 The current value of the flag associated with the B<-c> switch.
1893 Mainly of use with B<-MO=...> to allow code to alter its behavior
1894 when being compiled, such as for example to C<AUTOLOAD> at compile
1895 time rather than normal, deferred loading.  Setting
1896 C<$^C = 1> is similar to calling C<B::minus_c>.
1897
1898 This variable was added in Perl v5.6.0.
1899
1900 =item $DEBUGGING
1901
1902 =item $^D
1903 X<$^D> X<$DEBUGGING>
1904
1905 The current value of the debugging flags.  May be read or set.  Like its
1906 command-line equivalent, you can use numeric or symbolic values, eg
1907 C<$^D = 10> or C<$^D = "st">.
1908
1909 Mnemonic: value of B<-D> switch.
1910
1911 =item ${^ENCODING}
1912 X<${^ENCODING}>
1913
1914 DEPRECATED!!!
1915
1916 The I<object reference> to the C<Encode> object that is used to convert
1917 the source code to Unicode.  Thanks to this variable your Perl script
1918 does not have to be written in UTF-8.  Default is C<undef>.
1919
1920 Setting this variable to any other value than C<undef> is deprecated due
1921 to fundamental defects in its design and implementation.  It is planned
1922 to remove it from a future Perl version.  Its purpose was to allow your
1923 non-ASCII Perl scripts to not have to be written in UTF-8; this was
1924 useful before editors that worked on UTF-8 encoded text were common, but
1925 that was long ago.  It causes problems, such as affecting the operation
1926 of other modules that aren't expecting it, causing general mayhem.  Its
1927 use can lead to segfaults.
1928
1929 If you need something like this functionality, you should use the
1930 L<encoding> pragma, which is also deprecated, but has fewer nasty side
1931 effects.
1932
1933 If you are coming here because code of yours is being adversely affected
1934 by someone's use of this variable, you can usually work around it by
1935 doing this:
1936
1937  local ${^ENCODING};
1938
1939 near the beginning of the functions that are getting broken.  This
1940 undefines the variable during the scope of execution of the including
1941 function.
1942
1943 This variable was added in Perl 5.8.2.
1944
1945 =item ${^GLOBAL_PHASE}
1946 X<${^GLOBAL_PHASE}>
1947
1948 The current phase of the perl interpreter.
1949
1950 Possible values are:
1951
1952 =over 8
1953
1954 =item CONSTRUCT
1955
1956 The C<PerlInterpreter*> is being constructed via C<perl_construct>.  This
1957 value is mostly there for completeness and for use via the
1958 underlying C variable C<PL_phase>.  It's not really possible for Perl
1959 code to be executed unless construction of the interpreter is
1960 finished.
1961
1962 =item START
1963
1964 This is the global compile-time.  That includes, basically, every
1965 C<BEGIN> block executed directly or indirectly from during the
1966 compile-time of the top-level program.
1967
1968 This phase is not called "BEGIN" to avoid confusion with
1969 C<BEGIN>-blocks, as those are executed during compile-time of any
1970 compilation unit, not just the top-level program.  A new, localised
1971 compile-time entered at run-time, for example by constructs as
1972 C<eval "use SomeModule"> are not global interpreter phases, and
1973 therefore aren't reflected by C<${^GLOBAL_PHASE}>.
1974
1975 =item CHECK
1976
1977 Execution of any C<CHECK> blocks.
1978
1979 =item INIT
1980
1981 Similar to "CHECK", but for C<INIT>-blocks, not C<CHECK> blocks.
1982
1983 =item RUN
1984
1985 The main run-time, i.e. the execution of C<PL_main_root>.
1986
1987 =item END
1988
1989 Execution of any C<END> blocks.
1990
1991 =item DESTRUCT
1992
1993 Global destruction.
1994
1995 =back
1996
1997 Also note that there's no value for UNITCHECK-blocks.  That's because
1998 those are run for each compilation unit individually, and therefore is
1999 not a global interpreter phase.
2000
2001 Not every program has to go through each of the possible phases, but
2002 transition from one phase to another can only happen in the order
2003 described in the above list.
2004
2005 An example of all of the phases Perl code can see:
2006
2007     BEGIN { print "compile-time: ${^GLOBAL_PHASE}\n" }
2008
2009     INIT  { print "init-time: ${^GLOBAL_PHASE}\n" }
2010
2011     CHECK { print "check-time: ${^GLOBAL_PHASE}\n" }
2012
2013     {
2014         package Print::Phase;
2015
2016         sub new {
2017             my ($class, $time) = @_;
2018             return bless \$time, $class;
2019         }
2020
2021         sub DESTROY {
2022             my $self = shift;
2023             print "$$self: ${^GLOBAL_PHASE}\n";
2024         }
2025     }
2026
2027     print "run-time: ${^GLOBAL_PHASE}\n";
2028
2029     my $runtime = Print::Phase->new(
2030         "lexical variables are garbage collected before END"
2031     );
2032
2033     END   { print "end-time: ${^GLOBAL_PHASE}\n" }
2034
2035     our $destruct = Print::Phase->new(
2036         "package variables are garbage collected after END"
2037     );
2038
2039 This will print out
2040
2041     compile-time: START
2042     check-time: CHECK
2043     init-time: INIT
2044     run-time: RUN
2045     lexical variables are garbage collected before END: RUN
2046     end-time: END
2047     package variables are garbage collected after END: DESTRUCT
2048
2049 This variable was added in Perl 5.14.0.
2050
2051 =item $^H
2052 X<$^H>
2053
2054 WARNING: This variable is strictly for
2055 internal use only.  Its availability,
2056 behavior, and contents are subject to change without notice.
2057
2058 This variable contains compile-time hints for the Perl interpreter.  At the
2059 end of compilation of a BLOCK the value of this variable is restored to the
2060 value when the interpreter started to compile the BLOCK.
2061
2062 When perl begins to parse any block construct that provides a lexical scope
2063 (e.g., eval body, required file, subroutine body, loop body, or conditional
2064 block), the existing value of C<$^H> is saved, but its value is left unchanged.
2065 When the compilation of the block is completed, it regains the saved value.
2066 Between the points where its value is saved and restored, code that
2067 executes within BEGIN blocks is free to change the value of C<$^H>.
2068
2069 This behavior provides the semantic of lexical scoping, and is used in,
2070 for instance, the C<use strict> pragma.
2071
2072 The contents should be an integer; different bits of it are used for
2073 different pragmatic flags.  Here's an example:
2074
2075     sub add_100 { $^H |= 0x100 }
2076
2077     sub foo {
2078         BEGIN { add_100() }
2079         bar->baz($boon);
2080     }
2081
2082 Consider what happens during execution of the BEGIN block.  At this point
2083 the BEGIN block has already been compiled, but the body of C<foo()> is still
2084 being compiled.  The new value of C<$^H>
2085 will therefore be visible only while
2086 the body of C<foo()> is being compiled.
2087
2088 Substitution of C<BEGIN { add_100() }> block with:
2089
2090     BEGIN { require strict; strict->import('vars') }
2091
2092 demonstrates how C<use strict 'vars'> is implemented.  Here's a conditional
2093 version of the same lexical pragma:
2094
2095     BEGIN {
2096         require strict; strict->import('vars') if $condition
2097     }
2098
2099 This variable was added in Perl 5.003.
2100
2101 =item %^H
2102 X<%^H>
2103
2104 The C<%^H> hash provides the same scoping semantic as C<$^H>.  This makes
2105 it useful for implementation of lexically scoped pragmas.  See
2106 L<perlpragma>.   All the entries are stringified when accessed at
2107 runtime, so only simple values can be accommodated.  This means no
2108 pointers to objects, for example.
2109
2110 When putting items into C<%^H>, in order to avoid conflicting with other
2111 users of the hash there is a convention regarding which keys to use.
2112 A module should use only keys that begin with the module's name (the
2113 name of its main package) and a "/" character.  For example, a module
2114 C<Foo::Bar> should use keys such as C<Foo::Bar/baz>.
2115
2116 This variable was added in Perl v5.6.0.
2117
2118 =item ${^OPEN}
2119 X<${^OPEN}>
2120
2121 An internal variable used by PerlIO.  A string in two parts, separated
2122 by a C<\0> byte, the first part describes the input layers, the second
2123 part describes the output layers.
2124
2125 This variable was added in Perl v5.8.0.
2126
2127 =item $PERLDB
2128
2129 =item $^P
2130 X<$^P> X<$PERLDB>
2131
2132 The internal variable for debugging support.  The meanings of the
2133 various bits are subject to change, but currently indicate:
2134
2135 =over 6
2136
2137 =item 0x01
2138
2139 Debug subroutine enter/exit.
2140
2141 =item 0x02
2142
2143 Line-by-line debugging.  Causes C<DB::DB()> subroutine to be called for
2144 each statement executed.  Also causes saving source code lines (like
2145 0x400).
2146
2147 =item 0x04
2148
2149 Switch off optimizations.
2150
2151 =item 0x08
2152
2153 Preserve more data for future interactive inspections.
2154
2155 =item 0x10
2156
2157 Keep info about source lines on which a subroutine is defined.
2158
2159 =item 0x20
2160
2161 Start with single-step on.
2162
2163 =item 0x40
2164
2165 Use subroutine address instead of name when reporting.
2166
2167 =item 0x80
2168
2169 Report C<goto &subroutine> as well.
2170
2171 =item 0x100
2172
2173 Provide informative "file" names for evals based on the place they were compiled.
2174
2175 =item 0x200
2176
2177 Provide informative names to anonymous subroutines based on the place they
2178 were compiled.
2179
2180 =item 0x400
2181
2182 Save source code lines into C<@{"_<$filename"}>.
2183
2184 =item 0x800
2185
2186 When saving source, include evals that generate no subroutines.
2187
2188 =item 0x1000
2189
2190 When saving source, include source that did not compile.
2191
2192 =back
2193
2194 Some bits may be relevant at compile-time only, some at
2195 run-time only.  This is a new mechanism and the details may change.
2196 See also L<perldebguts>.
2197
2198 =item ${^TAINT}
2199 X<${^TAINT}>
2200
2201 Reflects if taint mode is on or off.  1 for on (the program was run with
2202 B<-T>), 0 for off, -1 when only taint warnings are enabled (i.e. with
2203 B<-t> or B<-TU>).
2204
2205 This variable is read-only.
2206
2207 This variable was added in Perl v5.8.0.
2208
2209 =item ${^UNICODE}
2210 X<${^UNICODE}>
2211
2212 Reflects certain Unicode settings of Perl.  See L<perlrun>
2213 documentation for the C<-C> switch for more information about
2214 the possible values.
2215
2216 This variable is set during Perl startup and is thereafter read-only.
2217
2218 This variable was added in Perl v5.8.2.
2219
2220 =item ${^UTF8CACHE}
2221 X<${^UTF8CACHE}>
2222
2223 This variable controls the state of the internal UTF-8 offset caching code.
2224 1 for on (the default), 0 for off, -1 to debug the caching code by checking
2225 all its results against linear scans, and panicking on any discrepancy.
2226
2227 This variable was added in Perl v5.8.9.  It is subject to change or
2228 removal without notice, but is currently used to avoid recalculating the
2229 boundaries of multi-byte UTF-8-encoded characters.
2230
2231 =item ${^UTF8LOCALE}
2232 X<${^UTF8LOCALE}>
2233
2234 This variable indicates whether a UTF-8 locale was detected by perl at
2235 startup.  This information is used by perl when it's in
2236 adjust-utf8ness-to-locale mode (as when run with the C<-CL> command-line
2237 switch); see L<perlrun> for more info on this.
2238
2239 This variable was added in Perl v5.8.8.
2240
2241 =back
2242
2243 =head2 Deprecated and removed variables
2244
2245 Deprecating a variable announces the intent of the perl maintainers to
2246 eventually remove the variable from the language.  It may still be
2247 available despite its status.  Using a deprecated variable triggers
2248 a warning.
2249
2250 Once a variable is removed, its use triggers an error telling you
2251 the variable is unsupported.
2252
2253 See L<perldiag> for details about error messages.
2254
2255 =over 8
2256
2257 =item $#
2258 X<$#>
2259
2260 C<$#> was a variable that could be used to format printed numbers.
2261 After a deprecation cycle, its magic was removed in Perl v5.10.0 and
2262 using it now triggers a warning: C<$# is no longer supported>.
2263
2264 This is not the sigil you use in front of an array name to get the
2265 last index, like C<$#array>.  That's still how you get the last index
2266 of an array in Perl.  The two have nothing to do with each other.
2267
2268 Deprecated in Perl 5.
2269
2270 Removed in Perl v5.10.0.
2271
2272 =item $*
2273 X<$*>
2274
2275 C<$*> was a variable that you could use to enable multiline matching.
2276 After a deprecation cycle, its magic was removed in Perl v5.10.0.
2277 Using it now triggers a warning: C<$* is no longer supported>.
2278 You should use the C</s> and C</m> regexp modifiers instead.
2279
2280 Deprecated in Perl 5.
2281
2282 Removed in Perl v5.10.0.
2283
2284 =item $[
2285 X<$[>
2286
2287 This variable stores the index of the first element in an array, and
2288 of the first character in a substring.  The default is 0, but you could
2289 theoretically set it to 1 to make Perl behave more like B<awk> (or Fortran)
2290 when subscripting and when evaluating the index() and substr() functions.
2291
2292 As of release 5 of Perl, assignment to C<$[> is treated as a compiler
2293 directive, and cannot influence the behavior of any other file.
2294 (That's why you can only assign compile-time constants to it.)
2295 Its use is highly discouraged.
2296
2297 Prior to Perl v5.10.0, assignment to C<$[> could be seen from outer lexical
2298 scopes in the same file, unlike other compile-time directives (such as
2299 L<strict>).  Using local() on it would bind its value strictly to a lexical
2300 block.  Now it is always lexically scoped.
2301
2302 As of Perl v5.16.0, it is implemented by the L<arybase> module.  See
2303 L<arybase> for more details on its behaviour.
2304
2305 Under C<use v5.16>, or C<no feature "array_base">, C<$[> no longer has any
2306 effect, and always contains 0.  Assigning 0 to it is permitted, but any
2307 other value will produce an error.
2308
2309 Mnemonic: [ begins subscripts.
2310
2311 Deprecated in Perl v5.12.0.
2312
2313 =back
2314
2315 =cut