This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
SvRX() and SvRXOK() macros
[perl5.git] / ext / re / re.pm
1 package re;
2
3 # pragma for controlling the regex engine
4 use strict;
5 use warnings;
6
7 our $VERSION     = "0.08";
8 our @ISA         = qw(Exporter);
9 our @EXPORT_OK   = qw(is_regexp regexp_pattern regmust 
10                       regname regnames regnames_count);
11 our %EXPORT_OK = map { $_ => 1 } @EXPORT_OK;
12
13 # *** WARNING *** WARNING *** WARNING *** WARNING *** WARNING ***
14 #
15 # If you modify these values see comment below!
16
17 my %bitmask = (
18     taint   => 0x00100000, # HINT_RE_TAINT
19     eval    => 0x00200000, # HINT_RE_EVAL
20 );
21
22 # - File::Basename contains a literal for 'taint' as a fallback.  If
23 # taint is changed here, File::Basename must be updated as well.
24 #
25 # - ExtUtils::ParseXS uses a hardcoded 
26 # BEGIN { $^H |= 0x00200000 } 
27 # in it to allow re.xs to be built. So if 'eval' is changed here then
28 # ExtUtils::ParseXS must be changed as well.
29 #
30 # *** WARNING *** WARNING *** WARNING *** WARNING *** WARNING ***
31
32 sub setcolor {
33  eval {                         # Ignore errors
34   require Term::Cap;
35
36   my $terminal = Tgetent Term::Cap ({OSPEED => 9600}); # Avoid warning.
37   my $props = $ENV{PERL_RE_TC} || 'md,me,so,se,us,ue';
38   my @props = split /,/, $props;
39   my $colors = join "\t", map {$terminal->Tputs($_,1)} @props;
40
41   $colors =~ s/\0//g;
42   $ENV{PERL_RE_COLORS} = $colors;
43  };
44  if ($@) {
45     $ENV{PERL_RE_COLORS} ||= qq'\t\t> <\t> <\t\t';
46  }
47
48 }
49
50 my %flags = (
51     COMPILE         => 0x0000FF,
52     PARSE           => 0x000001,
53     OPTIMISE        => 0x000002,
54     TRIEC           => 0x000004,
55     DUMP            => 0x000008,
56
57     EXECUTE         => 0x00FF00,
58     INTUIT          => 0x000100,
59     MATCH           => 0x000200,
60     TRIEE           => 0x000400,
61
62     EXTRA           => 0xFF0000,
63     TRIEM           => 0x010000,
64     OFFSETS         => 0x020000,
65     OFFSETSDBG      => 0x040000,
66     STATE           => 0x080000,
67     OPTIMISEM       => 0x100000,
68     STACK           => 0x280000,
69     BUFFERS         => 0x400000,
70 );
71 $flags{ALL} = -1 & ~($flags{OFFSETS}|$flags{OFFSETSDBG}|$flags{BUFFERS});
72 $flags{All} = $flags{all} = $flags{DUMP} | $flags{EXECUTE};
73 $flags{Extra} = $flags{EXECUTE} | $flags{COMPILE};
74 $flags{More} = $flags{MORE} = $flags{All} | $flags{TRIEC} | $flags{TRIEM} | $flags{STATE};
75 $flags{State} = $flags{DUMP} | $flags{EXECUTE} | $flags{STATE};
76 $flags{TRIE} = $flags{DUMP} | $flags{EXECUTE} | $flags{TRIEC};
77
78 my $installed;
79 my $installed_error;
80
81 sub _do_install {
82     if ( ! defined($installed) ) {
83         require XSLoader;
84         $installed = eval { XSLoader::load('re', $VERSION) } || 0;
85         $installed_error = $@;
86     }
87 }
88
89 sub _load_unload {
90     my ($on)= @_;
91     if ($on) {
92         _do_install();        
93         if ( ! $installed ) {
94             die "'re' not installed!? ($installed_error)";
95         } else {
96             # We call install() every time, as if we didn't, we wouldn't
97             # "see" any changes to the color environment var since
98             # the last time it was called.
99
100             # install() returns an integer, which if casted properly
101             # in C resolves to a structure containing the regex
102             # hooks. Setting it to a random integer will guarantee
103             # segfaults.
104             $^H{regcomp} = install();
105         }
106     } else {
107         delete $^H{regcomp};
108     }
109 }
110
111 sub bits {
112     my $on = shift;
113     my $bits = 0;
114     unless (@_) {
115         require Carp;
116         Carp::carp("Useless use of \"re\" pragma"); 
117     }
118     foreach my $idx (0..$#_){
119         my $s=$_[$idx];
120         if ($s eq 'Debug' or $s eq 'Debugcolor') {
121             setcolor() if $s =~/color/i;
122             ${^RE_DEBUG_FLAGS} = 0 unless defined ${^RE_DEBUG_FLAGS};
123             for my $idx ($idx+1..$#_) {
124                 if ($flags{$_[$idx]}) {
125                     if ($on) {
126                         ${^RE_DEBUG_FLAGS} |= $flags{$_[$idx]};
127                     } else {
128                         ${^RE_DEBUG_FLAGS} &= ~ $flags{$_[$idx]};
129                     }
130                 } else {
131                     require Carp;
132                     Carp::carp("Unknown \"re\" Debug flag '$_[$idx]', possible flags: ",
133                                join(", ",sort keys %flags ) );
134                 }
135             }
136             _load_unload($on ? 1 : ${^RE_DEBUG_FLAGS});
137             last;
138         } elsif ($s eq 'debug' or $s eq 'debugcolor') {
139             setcolor() if $s =~/color/i;
140             _load_unload($on);
141             last;
142         } elsif (exists $bitmask{$s}) {
143             $bits |= $bitmask{$s};
144         } elsif ($EXPORT_OK{$s}) {
145             _do_install();
146             require Exporter;
147             re->export_to_level(2, 're', $s);
148         } else {
149             require Carp;
150             Carp::carp("Unknown \"re\" subpragma '$s' (known ones are: ",
151                        join(', ', map {qq('$_')} 'debug', 'debugcolor', sort keys %bitmask),
152                        ")");
153         }
154     }
155     $bits;
156 }
157
158 sub import {
159     shift;
160     $^H |= bits(1, @_);
161 }
162
163 sub unimport {
164     shift;
165     $^H &= ~ bits(0, @_);
166 }
167
168 1;
169
170 __END__
171
172 =head1 NAME
173
174 re - Perl pragma to alter regular expression behaviour
175
176 =head1 SYNOPSIS
177
178     use re 'taint';
179     ($x) = ($^X =~ /^(.*)$/s);     # $x is tainted here
180
181     $pat = '(?{ $foo = 1 })';
182     use re 'eval';
183     /foo${pat}bar/;                # won't fail (when not under -T switch)
184
185     {
186         no re 'taint';             # the default
187         ($x) = ($^X =~ /^(.*)$/s); # $x is not tainted here
188
189         no re 'eval';              # the default
190         /foo${pat}bar/;            # disallowed (with or without -T switch)
191     }
192
193     use re 'debug';                # output debugging info during
194     /^(.*)$/s;                     #     compile and run time
195
196
197     use re 'debugcolor';           # same as 'debug', but with colored output
198     ...
199
200     use re qw(Debug All);          # Finer tuned debugging options.
201     use re qw(Debug More);
202     no re qw(Debug ALL);           # Turn of all re debugging in this scope
203
204     use re qw(is_regexp regexp_pattern); # import utility functions
205     my ($pat,$mods)=regexp_pattern(qr/foo/i);
206     if (is_regexp($obj)) { 
207         print "Got regexp: ",
208             scalar regexp_pattern($obj); # just as perl would stringify it
209     }                                    # but no hassle with blessed re's.
210
211 (We use $^X in these examples because it's tainted by default.)
212
213 =head1 DESCRIPTION
214
215 =head2 'taint' mode
216
217 When C<use re 'taint'> is in effect, and a tainted string is the target
218 of a regex, the regex memories (or values returned by the m// operator
219 in list context) are tainted.  This feature is useful when regex operations
220 on tainted data aren't meant to extract safe substrings, but to perform
221 other transformations.
222
223 =head2 'eval' mode
224
225 When C<use re 'eval'> is in effect, a regex is allowed to contain
226 C<(?{ ... })> zero-width assertions even if regular expression contains
227 variable interpolation.  That is normally disallowed, since it is a
228 potential security risk.  Note that this pragma is ignored when the regular
229 expression is obtained from tainted data, i.e.  evaluation is always
230 disallowed with tainted regular expressions.  See L<perlre/(?{ code })>.
231
232 For the purpose of this pragma, interpolation of precompiled regular
233 expressions (i.e., the result of C<qr//>) is I<not> considered variable
234 interpolation.  Thus:
235
236     /foo${pat}bar/
237
238 I<is> allowed if $pat is a precompiled regular expression, even
239 if $pat contains C<(?{ ... })> assertions.
240
241 =head2 'debug' mode
242
243 When C<use re 'debug'> is in effect, perl emits debugging messages when
244 compiling and using regular expressions.  The output is the same as that
245 obtained by running a C<-DDEBUGGING>-enabled perl interpreter with the
246 B<-Dr> switch. It may be quite voluminous depending on the complexity
247 of the match.  Using C<debugcolor> instead of C<debug> enables a
248 form of output that can be used to get a colorful display on terminals
249 that understand termcap color sequences.  Set C<$ENV{PERL_RE_TC}> to a
250 comma-separated list of C<termcap> properties to use for highlighting
251 strings on/off, pre-point part on/off.
252 See L<perldebug/"Debugging regular expressions"> for additional info.
253
254 As of 5.9.5 the directive C<use re 'debug'> and its equivalents are
255 lexically scoped, as the other directives are.  However they have both 
256 compile-time and run-time effects.
257
258 See L<perlmodlib/Pragmatic Modules>.
259
260 =head2 'Debug' mode
261
262 Similarly C<use re 'Debug'> produces debugging output, the difference
263 being that it allows the fine tuning of what debugging output will be
264 emitted. Options are divided into three groups, those related to
265 compilation, those related to execution and those related to special
266 purposes. The options are as follows:
267
268 =over 4
269
270 =item Compile related options
271
272 =over 4
273
274 =item COMPILE
275
276 Turns on all compile related debug options.
277
278 =item PARSE
279
280 Turns on debug output related to the process of parsing the pattern.
281
282 =item OPTIMISE
283
284 Enables output related to the optimisation phase of compilation.
285
286 =item TRIEC
287
288 Detailed info about trie compilation.
289
290 =item DUMP
291
292 Dump the final program out after it is compiled and optimised.
293
294 =back
295
296 =item Execute related options
297
298 =over 4
299
300 =item EXECUTE
301
302 Turns on all execute related debug options.
303
304 =item MATCH
305
306 Turns on debugging of the main matching loop.
307
308 =item TRIEE
309
310 Extra debugging of how tries execute.
311
312 =item INTUIT
313
314 Enable debugging of start point optimisations.
315
316 =back
317
318 =item Extra debugging options
319
320 =over 4
321
322 =item EXTRA
323
324 Turns on all "extra" debugging options.
325
326 =item BUFFERS
327
328 Enable debugging the capture buffer storage during match. Warning,
329 this can potentially produce extremely large output.
330
331 =item TRIEM
332
333 Enable enhanced TRIE debugging. Enhances both TRIEE
334 and TRIEC.
335
336 =item STATE
337
338 Enable debugging of states in the engine.
339
340 =item STACK
341
342 Enable debugging of the recursion stack in the engine. Enabling
343 or disabling this option automatically does the same for debugging
344 states as well. This output from this can be quite large.
345
346 =item OPTIMISEM
347
348 Enable enhanced optimisation debugging and start point optimisations.
349 Probably not useful except when debugging the regex engine itself.
350
351 =item OFFSETS
352
353 Dump offset information. This can be used to see how regops correlate
354 to the pattern. Output format is
355
356    NODENUM:POSITION[LENGTH]
357
358 Where 1 is the position of the first char in the string. Note that position
359 can be 0, or larger than the actual length of the pattern, likewise length
360 can be zero.
361
362 =item OFFSETSDBG
363
364 Enable debugging of offsets information. This emits copious
365 amounts of trace information and doesn't mesh well with other
366 debug options.
367
368 Almost definitely only useful to people hacking
369 on the offsets part of the debug engine.
370
371 =back
372
373 =item Other useful flags
374
375 These are useful shortcuts to save on the typing.
376
377 =over 4
378
379 =item ALL
380
381 Enable all options at once except OFFSETS, OFFSETSDBG and BUFFERS
382
383 =item All
384
385 Enable DUMP and all execute options. Equivalent to:
386
387   use re 'debug';
388
389 =item MORE
390
391 =item More
392
393 Enable TRIEM and all execute compile and execute options.
394
395 =back
396
397 =back
398
399 As of 5.9.5 the directive C<use re 'debug'> and its equivalents are
400 lexically scoped, as the other directives are.  However they have both
401 compile-time and run-time effects.
402
403 =head2 Exportable Functions
404
405 As of perl 5.9.5 're' debug contains a number of utility functions that
406 may be optionally exported into the caller's namespace. They are listed
407 below.
408
409 =over 4
410
411 =item is_regexp($ref)
412
413 Returns true if the argument is a compiled regular expression as returned
414 by C<qr//>, false if it is not.
415
416 This function will not be confused by overloading or blessing. In
417 internals terms, this extracts the regexp pointer out of the
418 PERL_MAGIC_qr structure so it it cannot be fooled.
419
420 =item regexp_pattern($ref)
421
422 If the argument is a compiled regular expression as returned by C<qr//>,
423 then this function returns the pattern.
424
425 In list context it returns a two element list, the first element
426 containing the pattern and the second containing the modifiers used when
427 the pattern was compiled.
428
429   my ($pat, $mods) = regexp_pattern($ref);
430
431 In scalar context it returns the same as perl would when strigifying a raw
432 C<qr//> with the same pattern inside.  If the argument is not a compiled
433 reference then this routine returns false but defined in scalar context,
434 and the empty list in list context. Thus the following
435
436     if (regexp_pattern($ref) eq '(?i-xsm:foo)')
437
438 will be warning free regardless of what $ref actually is.
439
440 Like C<is_regexp> this function will not be confused by overloading
441 or blessing of the object.
442
443 =item regmust($ref)
444
445 If the argument is a compiled regular expression as returned by C<qr//>,
446 then this function returns what the optimiser consiers to be the longest
447 anchored fixed string and longest floating fixed string in the pattern.
448
449 A I<fixed string> is defined as being a substring that must appear for the
450 pattern to match. An I<anchored fixed string> is a fixed string that must
451 appear at a particular offset from the beginning of the match. A I<floating
452 fixed string> is defined as a fixed string that can appear at any point in
453 a range of positions relative to the start of the match. For example,
454
455     my $qr = qr/here .* there/x;
456     my ($anchored, $floating) = regmust($qr);
457     print "anchored:'$anchored'\nfloating:'$floating'\n";
458
459 results in
460
461     anchored:'here'
462     floating:'there'
463
464 Because the C<here> is before the C<.*> in the pattern, its position
465 can be determined exactly. That's not true, however, for the C<there>;
466 it could appear at any point after where the anchored string appeared.
467 Perl uses both for its optimisations, prefering the longer, or, if they are
468 equal, the floating.
469
470 B<NOTE:> This may not necessarily be the definitive longest anchored and
471 floating string. This will be what the optimiser of the Perl that you
472 are using thinks is the longest. If you believe that the result is wrong
473 please report it via the L<perlbug> utility.
474
475 =item regname($name,$all)
476
477 Returns the contents of a named buffer of the last successful match. If
478 $all is true, then returns an array ref containing one entry per buffer,
479 otherwise returns the first defined buffer.
480
481 =item regnames($all)
482
483 Returns a list of all of the named buffers defined in the last successful
484 match. If $all is true, then it returns all names defined, if not it returns
485 only names which were involved in the match.
486
487 =item regnames_count()
488
489 Returns the number of distinct names defined in the pattern used
490 for the last successful match.
491
492 B<Note:> this result is always the actual number of distinct
493 named buffers defined, it may not actually match that which is
494 returned by C<regnames()> and related routines when those routines
495 have not been called with the $all parameter set.
496
497 =back
498
499 =head1 SEE ALSO
500
501 L<perlmodlib/Pragmatic Modules>.
502
503 =cut