pod/perlrecharclass.pod

   1 =head1 NAME
   2 X<character class>
   3
   4 perlrecharclass - Perl Regular Expression Character Classes
   5
   6 =head1 DESCRIPTION
   7
   8 The top level documentation about Perl regular expressions
   9 is found in L<perlre>.
  10
  11 This manual page discusses the syntax and use of character
  12 classes in Perl regular expressions.
  13
  14 A character class is a way of denoting a set of characters
  15 in such a way that one character of the set is matched.
  16 It's important to remember that: matching a character class
  17 consumes exactly one character in the source string. (The source
  18 string is the string the regular expression is matched against.)
  19
  20 There are three types of character classes in Perl regular
  21 expressions: the dot, backslash sequences, and the form enclosed in square
  22 brackets.  Keep in mind, though, that often the term "character class" is used
  23 to mean just the bracketed form.  Certainly, most Perl documentation does that.
  24
  25 =head2 The dot
  26
  27 The dot (or period), C<.> is probably the most used, and certainly
  28 the most well-known character class. By default, a dot matches any
  29 character, except for the newline. The default can be changed to
  30 add matching the newline by using the I<single line> modifier: either
  31 for the entire regular expression with the C</s> modifier, or
  32 locally with C<(?s)>.  (The experimental C<\N> backslash sequence, described
  33 below, matches any character except newline without regard to the
  34 I<single line> modifier.)
  35
  36 Here are some examples:
  37
  38  "a"  =~  /./       # Match
  39  "."  =~  /./       # Match
  40  ""   =~  /./       # No match (dot has to match a character)
  41  "\n" =~  /./       # No match (dot does not match a newline)
  42  "\n" =~  /./s      # Match (global 'single line' modifier)
  43  "\n" =~  /(?s:.)/  # Match (local 'single line' modifier)
  44  "ab" =~  /^.$/     # No match (dot matches one character)
  45
  46 =head2 Backslash sequences
  47 X<\w> X<\W> X<\s> X<\S> X<\d> X<\D> X<\p> X<\P>
  48 X<\N> X<\v> X<\V> X<\h> X<\H>
  49 X<word> X<whitespace>
  50
  51 A backslash sequence is a sequence of characters, the first one of which is a
  52 backslash.  Perl ascribes special meaning to many such sequences, and some of
  53 these are character classes.  That is, they match a single character each,
  54 provided that the character belongs to the specific set of characters defined
  55 by the sequence.
  56
  57 Here's a list of the backslash sequences that are character classes.  They
  58 are discussed in more detail below.  (For the backslash sequences that aren't
  59 character classes, see L<perlrebackslash>.)
  60
  61  \d             Match a decimal digit character.
  62  \D             Match a non-decimal-digit character.
  63  \w             Match a "word" character.
  64  \W             Match a non-"word" character.
  65  \s             Match a whitespace character.
  66  \S             Match a non-whitespace character.
  67  \h             Match a horizontal whitespace character.
  68  \H             Match a character that isn't horizontal whitespace.
  69  \v             Match a vertical whitespace character.
  70  \V             Match a character that isn't vertical whitespace.
  71  \N             Match a character that isn't a newline.  Experimental.
  72  \pP, \p{Prop}  Match a character that has the given Unicode property.
  73  \PP, \P{Prop}  Match a character that doesn't have the Unicode property
  74
  75 =head3 Digits
  76
  77 C<\d> matches a single character that is considered to be a decimal I<digit>.
  78 What is considered a decimal digit depends on several factors, detailed
  79 below in L</Locale, EBCDIC, Unicode and UTF-8>.  If those factors
  80 indicate a Unicode interpretation, C<\d> not only matches the digits
  81 '0' - '9', but also Arabic, Devanagari and digits from other languages.
  82 Otherwise, if there is a locale in effect, it will match whatever
  83 characters the locale considers decimal digits.  Without a locale, C<\d>
  84 matches just the digits '0' to '9'.
  85
  86 Unicode digits may cause some confusion, and some security issues.  In UTF-8
  87 strings, unless the C<"a"> regular expression modifier is specified,
  88 C<\d> matches the same characters matched by
  89 C<\p{General_Category=Decimal_Number}>, or synonymously,
  90 C<\p{General_Category=Digit}>.  Starting with Unicode version 4.1, this is the
  91 same set of characters matched by C<\p{Numeric_Type=Decimal}>.
  92
  93 But Unicode also has a different property with a similar name,
  94 C<\p{Numeric_Type=Digit}>, which matches a completely different set of
  95 characters.  These characters are things such as subscripts.
  96
  97 The design intent is for C<\d> to match all the digits (and no other characters)
  98 that can be used with "normal" big-endian positional decimal syntax, whereby a
  99 sequence of such digits {N0, N1, N2, ...Nn} has the numeric value (...(N0 * 10
 100 + N1) * 10 + N2) * 10 ... + Nn).  In Unicode 5.2, the Tamil digits (U+0BE6 -
 101 U+0BEF) can also legally be used in old-style Tamil numbers in which they would
 102 appear no more than one in a row, separated by characters that mean "times 10",
 103 "times 100", etc.  (See L<http://www.unicode.org/notes/tn21>.)
 104
 105 Some of the non-European digits that C<\d> matches look like European ones, but
 106 have different values.  For example, BENGALI DIGIT FOUR (U+09EA) looks
 107 very much like an ASCII DIGIT EIGHT (U+0038).
 108
 109 It may be useful for security purposes for an application to require that all
 110 digits in a row be from the same script.   See L<Unicode::UCD/charscript()>.
 111
 112 Any character that isn't matched by C<\d> will be matched by C<\D>.
 113
 114 =head3 Word characters
 115
 116 A C<\w> matches a single alphanumeric character (an alphabetic character, or a
 117 decimal digit) or a connecting punctuation character, such as an
 118 underscore ("_").  It does not match a whole word.  To match a whole
 119 word, use C<\w+>.  This isn't the same thing as matching an English word, but
 120 in the ASCII range it is the same as a string of Perl-identifier
 121 characters.  What is considered a
 122 word character depends on several factors, detailed below in L</Locale,
 123 EBCDIC, Unicode and UTF-8>.  If those factors indicate a Unicode
 124 interpretation, C<\w> matches the characters that are considered word
 125 characters in the Unicode database. That is, it not only matches ASCII letters,
 126 but also Thai letters, Greek letters, etc.  This includes connector
 127 punctuation (like the underscore) which connect two words together, or
 128 marks, such as a C<COMBINING TILDE>, which are generally used to add
 129 diacritical marks to letters.   If a Unicode interpretation
 130 is not indicated, C<\w> matches those characters that are considered
 131 word characters by the current locale or EBCDIC code page.  Without a
 132 locale or EBCDIC code page, C<\w> matches the ASCII letters, digits and
 133 the underscore.
 134
 135 There are a number of security issues with the full Unicode list of word
 136 characters.  See L<http://unicode.org/reports/tr36>.
 137
 138 Also, for a somewhat finer-grained set of characters that are in programming
 139 language identifiers beyond the ASCII range, you may wish to instead use the
 140 more customized Unicode properties, "ID_Start", ID_Continue", "XID_Start", and
 141 "XID_Continue".  See L<http://unicode.org/reports/tr31>.
 142
 143 Any character that isn't matched by C<\w> will be matched by C<\W>.
 144
 145 =head3 Whitespace
 146
 147 C<\s> matches any single character that is considered whitespace.  The exact
 148 set of characters matched by C<\s> depends on several factors, detailed
 149 below in L</Locale, EBCDIC, Unicode and UTF-8>.  If those factors
 150 indicate a Unicode interpretation, C<\s> matches what is considered
 151 whitespace in the Unicode database; the complete list is in the table
 152 below. Otherwise, if there is a locale or EBCDIC code page in effect,
 153 C<\s> matches whatever is considered whitespace by the current locale or
 154 EBCDIC code page. Without a locale or EBCDIC code page, C<\s> matches
 155 the horizontal tab (C<\t>), the newline (C<\n>), the form feed (C<\f>),
 156 the carriage return (C<\r>), and the space.  (Note that it doesn't match
 157 the vertical tab, C<\cK>.)  Perhaps the most notable possible surprise
 158 is that C<\s> matches a non-breaking space only if a Unicode
 159 interpretation is indicated, or the locale or EBCDIC code page that is
 160 in effect has that character.
 161
 162 Any character that isn't matched by C<\s> will be matched by C<\S>.
 163
 164 C<\h> will match any character that is considered horizontal whitespace;
 165 this includes the space and the tab characters and a number other characters,
 166 all of which are listed in the table below.  C<\H> will match any character
 167 that is not considered horizontal whitespace.
 168
 169 C<\v> will match any character that is considered vertical whitespace;
 170 this includes the carriage return and line feed characters (newline) plus several
 171 other characters, all listed in the table below.
 172 C<\V> will match any character that is not considered vertical whitespace.
 173
 174 C<\R> matches anything that can be considered a newline under Unicode
 175 rules. It's not a character class, as it can match a multi-character
 176 sequence. Therefore, it cannot be used inside a bracketed character
 177 class; use C<\v> instead (vertical whitespace).
 178 Details are discussed in L<perlrebackslash>.
 179
 180 Note that unlike C<\s>, C<\d> and C<\w>, C<\h> and C<\v> always match
 181 the same characters, without regard to other factors, such as if the
 182 source string is in UTF-8 format or not.
 183
 184 One might think that C<\s> is equivalent to C<[\h\v]>. This is not true.  The
 185 vertical tab (C<"\x0b">) is not matched by C<\s>, it is however considered
 186 vertical whitespace. Furthermore, if the source string is not in UTF-8 format,
 187 and any locale or EBCDIC code page that is in effect doesn't include them, the
 188 next line (ASCII-platform C<"\x85">) and the no-break space (ASCII-platform
 189 C<"\xA0">) characters are not matched by C<\s>, but are by C<\v> and C<\h>
 190 respectively.  If the C<"a"> modifier is not in effect, and the source
 191 string is in UTF-8 format, both the next line and
 192 the no-break space are matched by C<\s>.
 193
 194 The following table is a complete listing of characters matched by
 195 C<\s>, C<\h> and C<\v> as of Unicode 5.2.
 196
 197 The first column gives the code point of the character (in hex format),
 198 the second column gives the (Unicode) name. The third column indicates
 199 by which class(es) the character is matched (assuming no locale or EBCDIC code
 200 page is in effect that changes the C<\s> matching).
 201
 202  0x00009        CHARACTER TABULATION   h s
 203  0x0000a              LINE FEED (LF)    vs
 204  0x0000b             LINE TABULATION    v
 205  0x0000c              FORM FEED (FF)    vs
 206  0x0000d        CARRIAGE RETURN (CR)    vs
 207  0x00020                       SPACE   h s
 208  0x00085             NEXT LINE (NEL)    vs  [1]
 209  0x000a0              NO-BREAK SPACE   h s  [1]
 210  0x01680            OGHAM SPACE MARK   h s
 211  0x0180e   MONGOLIAN VOWEL SEPARATOR   h s
 212  0x02000                     EN QUAD   h s
 213  0x02001                     EM QUAD   h s
 214  0x02002                    EN SPACE   h s
 215  0x02003                    EM SPACE   h s
 216  0x02004          THREE-PER-EM SPACE   h s
 217  0x02005           FOUR-PER-EM SPACE   h s
 218  0x02006            SIX-PER-EM SPACE   h s
 219  0x02007                FIGURE SPACE   h s
 220  0x02008           PUNCTUATION SPACE   h s
 221  0x02009                  THIN SPACE   h s
 222  0x0200a                  HAIR SPACE   h s
 223  0x02028              LINE SEPARATOR    vs
 224  0x02029         PARAGRAPH SEPARATOR    vs
 225  0x0202f       NARROW NO-BREAK SPACE   h s
 226  0x0205f   MEDIUM MATHEMATICAL SPACE   h s
 227  0x03000           IDEOGRAPHIC SPACE   h s
 228
 229 =over 4
 230
 231 =item [1]
 232
 233 NEXT LINE and NO-BREAK SPACE only match C<\s> if the source string is in
 234 UTF-8 format and the C<"a"> modifier is not in effect; or the locale or
 235 EBCDIC code page that is in effect includes them.
 236
 237 =back
 238
 239 It is worth noting that C<\d>, C<\w>, etc, match single characters, not
 240 complete numbers or words. To match a number (that consists of digits),
 241 use C<\d+>; to match a word, use C<\w+>.
 242
 243 =head3 \N
 244
 245 C<\N> is new in 5.12, and is experimental.  It, like the dot, will match any
 246 character that is not a newline. The difference is that C<\N> is not influenced
 247 by the I<single line> regular expression modifier (see L</The dot> above).  Note
 248 that the form C<\N{...}> may mean something completely different.  When the
 249 C<{...}> is a L<quantifier|perlre/Quantifiers>, it means to match a non-newline
 250 character that many times.  For example, C<\N{3}> means to match 3
 251 non-newlines; C<\N{5,}> means to match 5 or more non-newlines.  But if C<{...}>
 252 is not a legal quantifier, it is presumed to be a named character.  See
 253 L<charnames> for those.  For example, none of C<\N{COLON}>, C<\N{4F}>, and
 254 C<\N{F4}> contain legal quantifiers, so Perl will try to find characters whose
 255 names are, respectively, C<COLON>, C<4F>, and C<F4>.
 256
 257 =head3 Unicode Properties
 258
 259 C<\pP> and C<\p{Prop}> are character classes to match characters that fit given
 260 Unicode properties.  One letter property names can be used in the C<\pP> form,
 261 with the property name following the C<\p>, otherwise, braces are required.
 262 When using braces, there is a single form, which is just the property name
 263 enclosed in the braces, and a compound form which looks like C<\p{name=value}>,
 264 which means to match if the property "name" for the character has the particular
 265 "value".
 266 For instance, a match for a number can be written as C</\pN/> or as
 267 C</\p{Number}/>, or as C</\p{Number=True}/>.
 268 Lowercase letters are matched by the property I<Lowercase_Letter> which
 269 has as short form I<Ll>. They need the braces, so are written as C</\p{Ll}/> or
 270 C</\p{Lowercase_Letter}/>, or C</\p{General_Category=Lowercase_Letter}/>
 271 (the underscores are optional).
 272 C</\pLl/> is valid, but means something different.
 273 It matches a two character string: a letter (Unicode property C<\pL>),
 274 followed by a lowercase C<l>.
 275
 276 For more details, see L<perlunicode/Unicode Character Properties>; for a
 277 complete list of possible properties, see
 278 L<perluniprops/Properties accessible through \p{} and \P{}>.
 279 It is also possible to define your own properties. This is discussed in
 280 L<perlunicode/User-Defined Character Properties>.
 281
 282
 283 =head4 Examples
 284
 285  "a"  =~  /\w/      # Match, "a" is a 'word' character.
 286  "7"  =~  /\w/      # Match, "7" is a 'word' character as well.
 287  "a"  =~  /\d/      # No match, "a" isn't a digit.
 288  "7"  =~  /\d/      # Match, "7" is a digit.
 289  " "  =~  /\s/      # Match, a space is whitespace.
 290  "a"  =~  /\D/      # Match, "a" is a non-digit.
 291  "7"  =~  /\D/      # No match, "7" is not a non-digit.
 292  " "  =~  /\S/      # No match, a space is not non-whitespace.
 293
 294  " "  =~  /\h/      # Match, space is horizontal whitespace.
 295  " "  =~  /\v/      # No match, space is not vertical whitespace.
 296  "\r" =~  /\v/      # Match, a return is vertical whitespace.
 297
 298  "a"  =~  /\pL/     # Match, "a" is a letter.
 299  "a"  =~  /\p{Lu}/  # No match, /\p{Lu}/ matches upper case letters.
 300
 301  "\x{0e0b}" =~ /\p{Thai}/  # Match, \x{0e0b} is the character
 302                            # 'THAI CHARACTER SO SO', and that's in
 303                            # Thai Unicode class.
 304  "a"  =~  /\P{Lao}/ # Match, as "a" is not a Laotian character.
 305
 306
 307 =head2 Bracketed Character Classes
 308
 309 The third form of character class you can use in Perl regular expressions
 310 is the bracketed character class.  In its simplest form, it lists the characters
 311 that may be matched, surrounded by square brackets, like this: C<[aeiou]>.
 312 This matches one of C<a>, C<e>, C<i>, C<o> or C<u>.  Like the other
 313 character classes, exactly one character will be matched. To match
 314 a longer string consisting of characters mentioned in the character
 315 class, follow the character class with a L<quantifier|perlre/Quantifiers>.  For
 316 instance, C<[aeiou]+> matches a string of one or more lowercase English vowels.
 317
 318 Repeating a character in a character class has no
 319 effect; it's considered to be in the set only once.
 320
 321 Examples:
 322
 323  "e"  =~  /[aeiou]/        # Match, as "e" is listed in the class.
 324  "p"  =~  /[aeiou]/        # No match, "p" is not listed in the class.
 325  "ae" =~  /^[aeiou]$/      # No match, a character class only matches
 326                            # a single character.
 327  "ae" =~  /^[aeiou]+$/     # Match, due to the quantifier.
 328
 329 =head3 Special Characters Inside a Bracketed Character Class
 330
 331 Most characters that are meta characters in regular expressions (that
 332 is, characters that carry a special meaning like C<.>, C<*>, or C<(>) lose
 333 their special meaning and can be used inside a character class without
 334 the need to escape them. For instance, C<[()]> matches either an opening
 335 parenthesis, or a closing parenthesis, and the parens inside the character
 336 class don't group or capture.
 337
 338 Characters that may carry a special meaning inside a character class are:
 339 C<\>, C<^>, C<->, C<[> and C<]>, and are discussed below. They can be
 340 escaped with a backslash, although this is sometimes not needed, in which
 341 case the backslash may be omitted.
 342
 343 The sequence C<\b> is special inside a bracketed character class. While
 344 outside the character class, C<\b> is an assertion indicating a point
 345 that does not have either two word characters or two non-word characters
 346 on either side, inside a bracketed character class, C<\b> matches a
 347 backspace character.
 348
 349 The sequences
 350 C<\a>,
 351 C<\c>,
 352 C<\e>,
 353 C<\f>,
 354 C<\n>,
 355 C<\N{I<NAME>}>,
 356 C<\N{U+I<hex char>}>,
 357 C<\r>,
 358 C<\t>,
 359 and
 360 C<\x>
 361 are also special and have the same meanings as they do outside a
 362 bracketed character class.  (However, inside a bracketed character
 363 class, if C<\N{I<NAME>}> expands to a sequence of characters, only the first
 364 one in the sequence is used, with a warning.)
 365
 366 Also, a backslash followed by two or three octal digits is considered an octal
 367 number.
 368
 369 A C<[> is not special inside a character class, unless it's the start of a
 370 POSIX character class (see L</POSIX Character Classes> below). It normally does
 371 not need escaping.
 372
 373 A C<]> is normally either the end of a POSIX character class (see
 374 L</POSIX Character Classes> below), or it signals the end of the bracketed
 375 character class.  If you want to include a C<]> in the set of characters, you
 376 must generally escape it.
 377 However, if the C<]> is the I<first> (or the second if the first
 378 character is a caret) character of a bracketed character class, it
 379 does not denote the end of the class (as you cannot have an empty class)
 380 and is considered part of the set of characters that can be matched without
 381 escaping.
 382
 383 Examples:
 384
 385  "+"   =~ /[+?*]/     #  Match, "+" in a character class is not special.
 386  "\cH" =~ /[\b]/      #  Match, \b inside in a character class
 387                       #  is equivalent to a backspace.
 388  "]"   =~ /[][]/      #  Match, as the character class contains.
 389                       #  both [ and ].
 390  "[]"  =~ /[[]]/      #  Match, the pattern contains a character class
 391                       #  containing just ], and the character class is
 392                       #  followed by a ].
 393
 394 =head3 Character Ranges
 395
 396 It is not uncommon to want to match a range of characters. Luckily, instead
 397 of listing all the characters in the range, one may use the hyphen (C<->).
 398 If inside a bracketed character class you have two characters separated
 399 by a hyphen, it's treated as if all the characters between the two are in
 400 the class. For instance, C<[0-9]> matches any ASCII digit, and C<[a-m]>
 401 matches any lowercase letter from the first half of the ASCII alphabet.
 402
 403 Note that the two characters on either side of the hyphen are not
 404 necessarily both letters or both digits. Any character is possible,
 405 although not advisable.  C<['-?]> contains a range of characters, but
 406 most people will not know which characters that will be. Furthermore,
 407 such ranges may lead to portability problems if the code has to run on
 408 a platform that uses a different character set, such as EBCDIC.
 409
 410 If a hyphen in a character class cannot syntactically be part of a range, for
 411 instance because it is the first or the last character of the character class,
 412 or if it immediately follows a range, the hyphen isn't special, and will be
 413 considered a character that is to be matched literally. You have to escape the
 414 hyphen with a backslash if you want to have a hyphen in your set of characters
 415 to be matched, and its position in the class is such that it could be
 416 considered part of a range.
 417
 418 Examples:
 419
 420  [a-z]       #  Matches a character that is a lower case ASCII letter.
 421  [a-fz]      #  Matches any letter between 'a' and 'f' (inclusive) or
 422              #  the letter 'z'.
 423  [-z]        #  Matches either a hyphen ('-') or the letter 'z'.
 424  [a-f-m]     #  Matches any letter between 'a' and 'f' (inclusive), the
 425              #  hyphen ('-'), or the letter 'm'.
 426  ['-?]       #  Matches any of the characters  '()*+,-./0123456789:;<=>?
 427              #  (But not on an EBCDIC platform).
 428
 429
 430 =head3 Negation
 431
 432 It is also possible to instead list the characters you do not want to
 433 match. You can do so by using a caret (C<^>) as the first character in the
 434 character class. For instance, C<[^a-z]> matches a character that is not a
 435 lowercase ASCII letter.
 436
 437 This syntax make the caret a special character inside a bracketed character
 438 class, but only if it is the first character of the class. So if you want
 439 to have the caret as one of the characters you want to match, you either
 440 have to escape the caret, or not list it first.
 441
 442 Examples:
 443
 444  "e"  =~  /[^aeiou]/   #  No match, the 'e' is listed.
 445  "x"  =~  /[^aeiou]/   #  Match, as 'x' isn't a lowercase vowel.
 446  "^"  =~  /[^^]/       #  No match, matches anything that isn't a caret.
 447  "^"  =~  /[x^]/       #  Match, caret is not special here.
 448
 449 =head3 Backslash Sequences
 450
 451 You can put any backslash sequence character class (with the exception of
 452 C<\N> and C<\R>) inside a bracketed character class, and it will act just
 453 as if you put all the characters matched by the backslash sequence inside the
 454 character class. For instance, C<[a-f\d]> will match any decimal digit, or any
 455 of the lowercase letters between 'a' and 'f' inclusive.
 456
 457 C<\N> within a bracketed character class must be of the forms C<\N{I<name>}>
 458 or C<\N{U+I<hex char>}>, and NOT be the form that matches non-newlines,
 459 for the same reason that a dot C<.> inside a bracketed character class loses
 460 its special meaning: it matches nearly anything, which generally isn't what you
 461 want to happen.
 462
 463
 464 Examples:
 465
 466  /[\p{Thai}\d]/     # Matches a character that is either a Thai
 467                     # character, or a digit.
 468  /[^\p{Arabic}()]/  # Matches a character that is neither an Arabic
 469                     # character, nor a parenthesis.
 470
 471 Backslash sequence character classes cannot form one of the endpoints
 472 of a range.  Thus, you can't say:
 473
 474  /[\p{Thai}-\d]/     # Wrong!
 475
 476 =head3 POSIX Character Classes
 477 X<character class> X<\p> X<\p{}>
 478 X<alpha> X<alnum> X<ascii> X<blank> X<cntrl> X<digit> X<graph>
 479 X<lower> X<print> X<punct> X<space> X<upper> X<word> X<xdigit>
 480
 481 POSIX character classes have the form C<[:class:]>, where I<class> is
 482 name, and the C<[:> and C<:]> delimiters. POSIX character classes only appear
 483 I<inside> bracketed character classes, and are a convenient and descriptive
 484 way of listing a group of characters, though they can suffer from
 485 portability issues (see below and L<Locale, EBCDIC, Unicode and UTF-8>).
 486
 487 Be careful about the syntax,
 488
 489  # Correct:
 490  $string =~ /[[:alpha:]]/
 491
 492  # Incorrect (will warn):
 493  $string =~ /[:alpha:]/
 494
 495 The latter pattern would be a character class consisting of a colon,
 496 and the letters C<a>, C<l>, C<p> and C<h>.
 497 POSIX character classes can be part of a larger bracketed character class.  For
 498 example,
 499
 500  [01[:alpha:]%]
 501
 502 is valid and matches '0', '1', any alphabetic character, and the percent sign.
 503
 504 Perl recognizes the following POSIX character classes:
 505
 506  alpha  Any alphabetical character ("[A-Za-z]").
 507  alnum  Any alphanumerical character. ("[A-Za-z0-9]")
 508  ascii  Any character in the ASCII character set.
 509  blank  A GNU extension, equal to a space or a horizontal tab ("\t").
 510  cntrl  Any control character.  See Note [2] below.
 511  digit  Any decimal digit ("[0-9]"), equivalent to "\d".
 512  graph  Any printable character, excluding a space.  See Note [3] below.
 513  lower  Any lowercase character ("[a-z]").
 514  print  Any printable character, including a space.  See Note [4] below.
 515  punct  Any graphical character excluding "word" characters.  Note [5].
 516  space  Any whitespace character. "\s" plus the vertical tab ("\cK").
 517  upper  Any uppercase character ("[A-Z]").
 518  word   A Perl extension ("[A-Za-z0-9_]"), equivalent to "\w".
 519  xdigit Any hexadecimal digit ("[0-9a-fA-F]").
 520
 521 Most POSIX character classes have two Unicode-style C<\p> property
 522 counterparts.  (They are not official Unicode properties, but Perl extensions
 523 derived from official Unicode properties.)  The table below shows the relation
 524 between POSIX character classes and these counterparts.
 525
 526 One counterpart, in the column labelled "ASCII-range Unicode" in
 527 the table, will only match characters in the ASCII character set.
 528
 529 The other counterpart, in the column labelled "Full-range Unicode", matches any
 530 appropriate characters in the full Unicode character set.  For example,
 531 C<\p{Alpha}> will match not just the ASCII alphabetic characters, but any
 532 character in the entire Unicode character set that is considered to be
 533 alphabetic.  The column labelled "backslash sequence" is a (short) synonym for
 534 the Full-range Unicode form.
 535
 536 (Each of the counterparts has various synonyms as well.
 537 L<perluniprops/Properties accessible through \p{} and \P{}> lists all the
 538 synonyms, plus all the characters matched by each of the ASCII-range
 539 properties.  For example C<\p{AHex}> is a synonym for C<\p{ASCII_Hex_Digit}>,
 540 and any C<\p> property name can be prefixed with "Is" such as C<\p{IsAlpha}>.)
 541
 542 Both the C<\p> forms are unaffected by any locale that is in effect, or whether
 543 the string is in UTF-8 format or not, or whether the platform is EBCDIC or not.
 544 In contrast, the POSIX character classes are affected, unless the
 545 regular expression is compiled with the C<"a"> modifier.  If the C<"a">
 546 modifier is not in effect, and the source string is in UTF-8 format, the
 547 POSIX classes behave like their "Full-range" Unicode counterparts.  If
 548 C<"a"> modifier is in effect; or the source string is not in UTF-8
 549 format, and no locale is in effect, and the platform is not EBCDIC, all
 550 the POSIX classes behave like their ASCII-range counterparts.
 551 Otherwise, they behave based on the rules of the locale or EBCDIC code
 552 page.
 553
 554 It is proposed to change this behavior in a future release of Perl so that the
 555 the UTF-8-ness of the source string will be irrelevant to the behavior of the
 556 POSIX character classes.  This means they will always behave in strict
 557 accordance with the official POSIX standard.  That is, if either locale or
 558 EBCDIC code page is present, they will behave in accordance with those; if
 559 absent, the classes will match only their ASCII-range counterparts.  If you
 560 wish to comment on this proposal, send email to C<perl5-porters@perl.org>.
 561
 562  [[:...:]]      ASCII-range          Full-range  backslash  Note
 563                  Unicode              Unicode     sequence
 564  -----------------------------------------------------
 565    alpha      \p{PosixAlpha}       \p{XPosixAlpha}
 566    alnum      \p{PosixAlnum}       \p{XPosixAlnum}
 567    ascii      \p{ASCII}
 568    blank      \p{PosixBlank}       \p{XPosixBlank}  \h      [1]
 569                                    or \p{HorizSpace}        [1]
 570    cntrl      \p{PosixCntrl}       \p{XPosixCntrl}          [2]
 571    digit      \p{PosixDigit}       \p{XPosixDigit}  \d
 572    graph      \p{PosixGraph}       \p{XPosixGraph}          [3]
 573    lower      \p{PosixLower}       \p{XPosixLower}
 574    print      \p{PosixPrint}       \p{XPosixPrint}          [4]
 575    punct      \p{PosixPunct}       \p{XPosixPunct}          [5]
 576               \p{PerlSpace}        \p{XPerlSpace}   \s      [6]
 577    space      \p{PosixSpace}       \p{XPosixSpace}          [6]
 578    upper      \p{PosixUpper}       \p{XPosixUpper}
 579    word       \p{PosixWord}        \p{XPosixWord}   \w
 580    xdigit     \p{ASCII_Hex_Digit}  \p{XPosixXDigit}
 581
 582 =over 4
 583
 584 =item [1]
 585
 586 C<\p{Blank}> and C<\p{HorizSpace}> are synonyms.
 587
 588 =item [2]
 589
 590 Control characters don't produce output as such, but instead usually control
 591 the terminal somehow: for example newline and backspace are control characters.
 592 In the ASCII range, characters whose ordinals are between 0 and 31 inclusive,
 593 plus 127 (C<DEL>) are control characters.
 594
 595 On EBCDIC platforms, it is likely that the code page will define C<[[:cntrl:]]>
 596 to be the EBCDIC equivalents of the ASCII controls, plus the controls
 597 that in Unicode have ordinals from 128 through 159.
 598
 599 =item [3]
 600
 601 Any character that is I<graphical>, that is, visible. This class consists
 602 of all the alphanumerical characters and all punctuation characters.
 603
 604 =item [4]
 605
 606 All printable characters, which is the set of all the graphical characters
 607 plus whitespace characters that are not also controls.
 608
 609 =item [5]
 610
 611 C<\p{PosixPunct}> and C<[[:punct:]]> in the ASCII range match all the
 612 non-controls, non-alphanumeric, non-space characters:
 613 C<[-!"#$%&'()*+,./:;<=E<gt>?@[\\\]^_`{|}~]> (although if a locale is in effect,
 614 it could alter the behavior of C<[[:punct:]]>).
 615
 616 The similarly named property, C<\p{Punct}>, matches a somewhat different
 617 set in the ASCII range, namely
 618 C<[-!"#%&'()*,./:;?@[\\\]_{}]>.  That is, it is missing C<[$+E<lt>=E<gt>^`|~]>.
 619 This is because Unicode splits what POSIX considers to be punctuation into two
 620 categories, Punctuation and Symbols.
 621
 622 C<\p{XPosixPunct}> and (in Unicode mode) C<[[:punct:]]>, match what
 623 C<\p{PosixPunct}> matches in the ASCII range, plus what C<\p{Punct}>
 624 matches.  This is different than strictly matching according to
 625 C<\p{Punct}>.  Another way to say it is that
 626 for a UTF-8 string, C<[[:punct:]]> matches all the characters that Unicode
 627 considers to be punctuation, plus all the ASCII-range characters that Unicode
 628 considers to be symbols.
 629
 630 =item [6]
 631
 632 C<\p{SpacePerl}> and C<\p{Space}> differ only in that C<\p{Space}> additionally
 633 matches the vertical tab, C<\cK>.   Same for the two ASCII-only range forms.
 634
 635 =back
 636
 637 There are various other synonyms that can be used for these besides
 638 C<\p{HorizSpace}> and \C<\p{XPosixBlank}>.  For example
 639 C<\p{PosixAlpha}> can be written as C<\p{Alpha}>.  All are listed
 640 in L<perluniprops/Properties accessible through \p{} and \P{}>.
 641
 642 =head4 Negation
 643 X<character class, negation>
 644
 645 A Perl extension to the POSIX character class is the ability to
 646 negate it. This is done by prefixing the class name with a caret (C<^>).
 647 Some examples:
 648
 649      POSIX         ASCII-range     Full-range  backslash
 650                     Unicode         Unicode    sequence
 651  -----------------------------------------------------
 652  [[:^digit:]]   \P{PosixDigit}  \P{XPosixDigit}   \D
 653  [[:^space:]]   \P{PosixSpace}  \P{XPosixSpace}
 654                 \P{PerlSpace}   \P{XPerlSpace}    \S
 655  [[:^word:]]    \P{PerlWord}    \P{XPosixWord}    \W
 656
 657 The backslash sequence can mean either ASCII- or Full-range Unicode,
 658 depending on various factors.  See L</Locale, EBCDIC, Unicode and UTF-8>
 659 below.
 660
 661 =head4 [= =] and [. .]
 662
 663 Perl will recognize the POSIX character classes C<[=class=]>, and
 664 C<[.class.]>, but does not (yet?) support them.  Use of
 665 such a construct will lead to an error.
 666
 667
 668 =head4 Examples
 669
 670  /[[:digit:]]/            # Matches a character that is a digit.
 671  /[01[:lower:]]/          # Matches a character that is either a
 672                           # lowercase letter, or '0' or '1'.
 673  /[[:digit:][:^xdigit:]]/ # Matches a character that can be anything
 674                           # except the letters 'a' to 'f'.  This is
 675                           # because the main character class is composed
 676                           # of two POSIX character classes that are ORed
 677                           # together, one that matches any digit, and
 678                           # the other that matches anything that isn't a
 679                           # hex digit.  The result matches all
 680                           # characters except the letters 'a' to 'f' and
 681                           # 'A' to 'F'.
 682
 683
 684 =head2 Locale, EBCDIC, Unicode and UTF-8
 685
 686 Some of the character classes have a somewhat different behaviour
 687 depending on the internal encoding of the source string, if the regular
 688 expression is marked as having Unicode semantics, the locale that is in
 689 effect, and if the program is running on an EBCDIC platform.
 690
 691 C<\w>, C<\d>, C<\s> and the POSIX character classes (and their
 692 negations, including C<\W>, C<\D>, C<\S>) have this behaviour.  (Since
 693 the backslash sequences C<\b> and C<\B> are defined in terms of C<\w>
 694 and C<\W>, they also are affected.)
 695
 696 Starting in Perl 5.14, if the regular expression is compiled with the
 697 C<"a"> modifier, the behavior doesn't differ regardless of any other
 698 factors.  C<\d> matches the 10 digits 0-9; C<\D> any character but those
 699 10; C<\s>, exactly the five characters "[ \f\n\r\t]"; C<\w> only the 63
 700 characters "[A-Za-z0-9_]"; and the C<"[[:posix:]]"> classes only the
 701 appropriate ASCII characters, the same characters as are matched by the
 702 corresponding C<\p{}> property given in the "ASCII-range Unicode" column
 703 in the table above.  (The behavior of all of their complements follows
 704 the same paradigm.)
 705
 706 Otherwise, a regular expression is marked for Unicode semantics if it is
 707 encoded in utf8 (usually as a result of including a literal character
 708 whose code point is above 255), or if it contains a C<\N{U+...}> or
 709 C<\N{I<name>}> construct, or (starting in Perl 5.14) if it was compiled
 710 in the scope of a C<S<use feature "unicode_strings">> pragma and not in
 711 the scope of a C<S<use locale>> pragma, or has the C<"u"> regular
 712 expression modifier.
 713
 714 Note that one can specify C<"use re '/l'"> for example, for any regular
 715 expression modifier, and this has precedence over either of the
 716 C<S<use feature "unicode_strings">> or C<S<use locale>> pragmas.
 717
 718 The differences in behavior between locale and non-locale semantics
 719 can affect any character whose code point is 255 or less.  The
 720 differences in behavior between Unicode and non-Unicode semantics
 721 affects only ASCII platforms, and only when matching against characters
 722 whose code points are between 128 and 255 inclusive.  See
 723 L<perlunicode/The "Unicode Bug">.
 724
 725 For portability reasons, unless the C<"a"> modifier is specified,
 726 it may be better to not use C<\w>, C<\d>, C<\s> or the POSIX character
 727 classes and use the Unicode properties instead.
 728 That way you can control whether you want matching of just characters in
 729 the ASCII character set, or any Unicode characters.
 730 C<S<use feature "unicode_strings">> will allow seamless Unicode behavior
 731 no matter what the internal encodings are, but won't allow restricting
 732 to just the ASCII characters.
 733
 734 =head4 Examples
 735
 736  $str =  "\xDF";      # $str is not in UTF-8 format.
 737  $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
 738  $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
 739  $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
 740  chop $str;
 741  $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
 742
 743 =cut