t/TEST

   1 #!./perl
   2
   3 # This is written in a peculiar style, since we're trying to avoid
   4 # most of the constructs we'll be testing for.  (This comment is
   5 # probably obsolete on the avoidance side, though still currrent
   6 # on the peculiarity side.)
   7
   8 # t/TEST and t/harness need to share code. The logical way to do this would be
   9 # to have the common code in a file both require or use. However, t/TEST needs
  10 # to still work, to generate test results, even if require isn't working, so
  11 # we cannot do that. t/harness has no such restriction, so it is quite
  12 # acceptable to have it require t/TEST.
  13
  14 # In which case, we need to stop t/TEST actually running tests, as all
  15 # t/harness needs are its subroutines.
  16
  17
  18 # directories with special sets of test switches
  19 my %dir_to_switch =
  20     (base => '',
  21      comp => '',
  22      run => '',
  23      '../ext/File-Glob/t' => '-I.. -MTestInit', # FIXME - tests assume t/
  24      );
  25
  26 # "not absolute" is the the default, as it saves some fakery within TestInit
  27 # which can peturb tests, and takes CPU. Working with the upstream author of
  28 # any of these, to figure out how to remove them from this list, considered
  29 # "a good thing".
  30 my %abs = (
  31            '../cpan/Archive-Extract' => 1,
  32            '../cpan/Archive-Tar' => 1,
  33            '../cpan/AutoLoader' => 1,
  34            '../cpan/CPAN' => 1,
  35            '../cpan/Class-ISA' => 1,
  36            '../cpan/Devel-PPPort' => 1,
  37            '../cpan/Encode' => 1,
  38            '../cpan/ExtUtils-Constant' => 1,
  39            '../cpan/ExtUtils-MakeMaker' => 1,
  40            '../cpan/File-Fetch' => 1,
  41            '../cpan/IPC-Cmd' => 1,
  42            '../cpan/IPC-SysV' => 1,
  43            '../cpan/Locale-Codes' => 1,
  44            '../cpan/Log-Message' => 1,
  45            '../cpan/Module-Build' => 1,
  46            '../cpan/Module-Load' => 1,
  47            '../cpan/Module-Load-Conditional' => 1,
  48            '../cpan/Object-Accessor' => 1,
  49            '../cpan/Package-Constants' => 1,
  50            '../cpan/Parse-CPAN-Meta' => 1,
  51            '../cpan/Pod-Simple' => 1,
  52            '../cpan/Term-UI' => 1,
  53            '../cpan/Test-Simple' => 1,
  54            '../cpan/Tie-File' => 1,
  55            '../cpan/podlators' => 1,
  56            '../dist/Cwd' => 1,
  57            '../dist/ExtUtils-Command' => 1,
  58            '../dist/ExtUtils-Install' => 1,
  59            '../dist/ExtUtils-Manifest' => 1,
  60            '../dist/ExtUtils-ParseXS' => 1,
  61           );
  62
  63 my %temp_no_core =
  64     ('../cpan/B-Debug' => 1,
  65      '../cpan/Compress-Raw-Bzip2' => 1,
  66      '../cpan/Compress-Raw-Zlib' => 1,
  67      '../cpan/Devel-PPPort' => 1,
  68      '../cpan/Getopt-Long' => 1,
  69      '../cpan/IO-Compress' => 1,
  70      '../cpan/MIME-Base64' => 1,
  71      '../cpan/parent' => 1,
  72      '../cpan/Parse-CPAN-Meta' => 1,
  73      '../cpan/Pod-Simple' => 1,
  74      '../cpan/podlators' => 1,
  75      '../cpan/Test-Simple' => 1,
  76      '../cpan/Tie-RefHash' => 1,
  77      '../cpan/Unicode-Collate' => 1,
  78      '../cpan/Unicode-Normalize' => 1,
  79     );
  80
  81 # delete env vars that may influence the results
  82 # but allow override via *_TEST env var if wanted
  83 # (e.g. PERL5OPT_TEST=-d:NYTProf)
  84 for my $envname (qw(PERL5LIB PERLLIB PERL5OPT)) {
  85     my $override = $ENV{"${envname}_TEST"};
  86     if (defined $override) {
  87         warn "$0: $envname=$override\n";
  88         $ENV{$envname} = $override;
  89     }
  90     else {
  91         delete $ENV{$envname};
  92     }
  93 }
  94
  95 if ($::do_nothing) {
  96     return 1;
  97 }
  98
  99 # Location to put the Valgrind log.
 100 our $Valgrind_Log;
 101
 102 $| = 1;
 103
 104 # for testing TEST only
 105 #BEGIN { require '../lib/strict.pm'; "strict"->import() };
 106 #BEGIN { require '../lib/warnings.pm'; "warnings"->import() };
 107
 108 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
 109 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
 110 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
 111
 112 # Cheesy version of Getopt::Std.  We can't replace it with that, because we
 113 # can't rely on require working.
 114 {
 115     my @argv = ();
 116     foreach my $idx (0..$#ARGV) {
 117         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
 118         $::benchmark = 1 if $1 eq 'benchmark';
 119         $::core    = 1 if $1 eq 'core';
 120         $::verbose = 1 if $1 eq 'v';
 121         $::torture = 1 if $1 eq 'torture';
 122         $::with_utf8 = 1 if $1 eq 'utf8';
 123         $::with_utf16 = 1 if $1 eq 'utf16';
 124         $::taintwarn = 1 if $1 eq 'taintwarn';
 125         if ($1 =~ /^deparse(,.+)?$/) {
 126             $::deparse = 1;
 127             $::deparse_opts = $1;
 128         }
 129     }
 130     @ARGV = @argv;
 131 }
 132
 133 chdir 't' if -f 't/TEST';
 134 if (-f 'TEST' && -f 'harness' && -d '../lib') {
 135     @INC = '../lib';
 136 }
 137
 138 die "You need to run \"make test\" first to set things up.\n"
 139   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
 140
 141 if ($ENV{PERL_3LOG}) { # Tru64 third(1) tool, see perlhack
 142     unless (-x 'perl.third') {
 143         unless (-x '../perl.third') {
 144             die "You need to run \"make perl.third first.\n";
 145         }
 146         else {
 147             print "Symlinking ../perl.third as perl.third...\n";
 148             die "Failed to symlink: $!\n"
 149                 unless symlink("../perl.third", "perl.third");
 150             die "Symlinked but no executable perl.third: $!\n"
 151                 unless -x 'perl.third';
 152         }
 153     }
 154 }
 155
 156 # check leakage for embedders
 157 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
 158
 159 $ENV{EMXSHELL} = 'sh';        # For OS/2
 160
 161 if ($show_elapsed_time) { require Time::HiRes }
 162
 163 my %skip = (
 164             '.' => 1,
 165             '..' => 1,
 166             'CVS' => 1,
 167             'RCS' => 1,
 168             'SCCS' => 1,
 169             '.svn' => 1,
 170            );
 171
 172 # Roll your own File::Find!
 173 sub _find_tests {
 174     my($dir) = @_;
 175     opendir DIR, $dir or die "Trouble opening $dir: $!";
 176     foreach my $f (sort { $a cmp $b } readdir DIR) {
 177         next if $skip{$f};
 178
 179         my $fullpath = "$dir/$f";
 180
 181         if (-d $fullpath) {
 182             _find_tests($fullpath);
 183         } elsif ($f =~ /\.t$/) {
 184             push @ARGV, $fullpath;
 185         }
 186     }
 187 }
 188
 189
 190 # Scan the text of the test program to find switches and special options
 191 # we might need to apply.
 192 sub _scan_test {
 193     my($test, $type) = @_;
 194
 195     open(my $script, "<", $test) or die "Can't read $test.\n";
 196     my $first_line = <$script>;
 197
 198     $first_line =~ tr/\0//d if $::with_utf16;
 199
 200     my $switch = "";
 201     if ($first_line =~ /#!.*\bperl.*\s-\w*([tT])/) {
 202         $switch = "-$1";
 203     } else {
 204         if ($::taintwarn) {
 205             # not all tests are expected to pass with this option
 206             $switch = '-t';
 207         } else {
 208             $switch = '';
 209         }
 210     }
 211
 212     my $file_opts = "";
 213     if ($type eq 'deparse') {
 214         # Look for #line directives which change the filename
 215         while (<$script>) {
 216             $file_opts = $file_opts . ",-f$3$4"
 217               if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
 218         }
 219     }
 220
 221     close $script;
 222
 223     my $perl = './perl';
 224     my $lib  = '../lib';
 225     my $run_dir;
 226     my $return_dir;
 227
 228     $test =~ /^(.+)\/[^\/]+/;
 229     my $dir = $1;
 230     my $testswitch = $dir_to_switch{$dir};
 231     if (!defined $testswitch) {
 232         if ($test =~ s!^(\.\./(cpan|dist|ext)/[^/]+)/t!t!) {
 233             $run_dir = $1;
 234             $return_dir = '../../t';
 235             $lib = '../../lib';
 236             $perl = '../../t/perl';
 237             $testswitch = "-I../.. -MTestInit=U2T";
 238             if ($2 eq 'cpan' || $2 eq 'dist') {
 239                 if($abs{$run_dir}) {
 240                     $testswitch = $testswitch . ',A';
 241                 }
 242                 if ($temp_no_core{$run_dir}) {
 243                     $testswitch = $testswitch . ',NC';
 244                 }
 245             }
 246         } elsif ($test =~ m!^\.\./lib!) {
 247             $testswitch = '-I.. -MTestInit=U1'; # -T will remove . from @INC
 248         } else {
 249             $testswitch = '-I.. -MTestInit';  # -T will remove . from @INC
 250         }
 251     }
 252
 253     my $utf8 = ($::with_utf8 || $::with_utf16) ? "-I$lib -Mutf8" : '';
 254
 255     my %options = (
 256         perl => $perl,
 257         lib => $lib,
 258         test => $test,
 259         run_dir => $run_dir,
 260         return_dir => $return_dir,
 261         testswitch => $testswitch,
 262         utf8 => $utf8,
 263         file => $file_opts,
 264         switch => $switch,
 265     );
 266
 267     return \%options;
 268 }
 269
 270 sub _cmd {
 271     my($options, $type) = @_;
 272
 273     my $test = $options->{test};
 274
 275     my $cmd;
 276     if ($type eq 'deparse') {
 277         my $perl = "$options->{perl} $options->{testswitch}";
 278         my $lib = $options->{lib};
 279
 280         $cmd = (
 281           "$perl $options->{switch} -I$lib -MO=-qq,Deparse,-sv1.,".
 282           "-l$::deparse_opts$options->{file} ".
 283           "$test > $test.dp ".
 284           "&& $perl $options->{switch} -I$lib $test.dp"
 285         );
 286     }
 287     elsif ($type eq 'perl') {
 288         my $perl = $options->{perl};
 289         my $redir = $^O eq 'VMS' ? '2>&1' : '';
 290
 291         if ($ENV{PERL_VALGRIND}) {
 292             my $perl_supp = $options->{return_dir} ? "$options->{return_dir}/perl.supp" : "perl.supp";
 293             my $valgrind = $ENV{VALGRIND} // 'valgrind';
 294             my $vg_opts = $ENV{VG_OPTS}
 295               //  "--suppressions=$perl_supp --leak-check=yes "
 296                 . "--leak-resolution=high --show-reachable=yes "
 297                   . "--num-callers=50 --track-origins=yes";
 298             $perl = "$valgrind --log-fd=3 $vg_opts $perl";
 299             $redir = "3>$Valgrind_Log";
 300             if ($options->{run_dir}) {
 301                 $Valgrind_Log = "$options->{run_dir}/$Valgrind_Log";
 302             }
 303         }
 304
 305         my $args = "$options->{testswitch} $options->{switch} $options->{utf8}";
 306         $cmd = $perl . _quote_args($args) . " $test $redir";
 307     }
 308
 309     return $cmd;
 310 }
 311
 312 sub _before_fork {
 313     my ($options) = @_;
 314
 315     if ($options->{run_dir}) {
 316         my $run_dir = $options->{run_dir};
 317         chdir $run_dir or die "Can't chdir to '$run_dir': $!";
 318     }
 319
 320     return;
 321 }
 322
 323 sub _after_fork {
 324     my ($options) = @_;
 325
 326     if ($options->{return_dir}) {
 327         my $return_dir = $options->{return_dir};
 328         chdir $return_dir
 329            or die "Can't chdir from '$options->{run_dir}' to '$return_dir': $!";
 330     }
 331
 332     return;
 333 }
 334
 335 sub _run_test {
 336     my ($test, $type) = @_;
 337
 338     my $options = _scan_test($test, $type);
 339     # $test might have changed if we're in ext/Foo, so don't use it anymore
 340     # from now on. Use $options->{test} instead.
 341
 342     _before_fork($options);
 343
 344     my $cmd = _cmd($options, $type);
 345
 346     open(my $results, "$cmd |") or print "can't run '$cmd': $!.\n";
 347
 348     _after_fork($options);
 349
 350     # Our environment may force us to use UTF-8, but we can't be sure that
 351     # anything we're reading from will be generating (well formed) UTF-8
 352     # This may not be the best way - possibly we should unset ${^OPEN} up
 353     # top?
 354     binmode $results;
 355
 356     return $results;
 357 }
 358
 359 sub _quote_args {
 360     my ($args) = @_;
 361     my $argstring = '';
 362
 363     foreach (split(/\s+/,$args)) {
 364        # In VMS protect with doublequotes because otherwise
 365        # DCL will lowercase -- unless already doublequoted.
 366        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
 367        $argstring = $argstring . ' ' . $_;
 368     }
 369     return $argstring;
 370 }
 371
 372 sub _populate_hash {
 373     return unless defined $_[0];
 374     return map {$_, 1} split /\s+/, $_[0];
 375 }
 376
 377 sub _tests_from_manifest {
 378     my ($extensions, $known_extensions) = @_;
 379     my %skip;
 380     my %extensions = _populate_hash($extensions);
 381     my %known_extensions = _populate_hash($known_extensions);
 382
 383     foreach (keys %known_extensions) {
 384         $skip{$_} = 1 unless $extensions{$_};
 385     }
 386
 387     my @results;
 388     my $mani = '../MANIFEST';
 389     if (open(MANI, $mani)) {
 390         while (<MANI>) {
 391             if (m!^((?:cpan|dist|ext)/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
 392                 my $t = $1;
 393                 my $extension = $2;
 394                 if (!$::core || $t =~ m!^lib/[a-z]!) {
 395                     if (defined $extension) {
 396                         $extension =~ s!/t(:?/\S+)*$!!;
 397                         # XXX Do I want to warn that I'm skipping these?
 398                         next if $skip{$extension};
 399                         my $flat_extension = $extension;
 400                         $flat_extension =~ s!-!/!g;
 401                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
 402                     }
 403                     my $path = "../$t";
 404                     push @results, $path;
 405                     $::path_to_name{$path} = $t;
 406                 }
 407             }
 408         }
 409         close MANI;
 410     } else {
 411         warn "$0: cannot open $mani: $!\n";
 412     }
 413     return @results;
 414 }
 415
 416 unless (@ARGV) {
 417     # base first, as TEST bails out if that can't run
 418     # then comp, to validate that require works
 419     # then run, to validate that -M works
 420     # then we know we can -MTestInit for everything else, making life simpler
 421     foreach my $dir (qw(base comp run cmd io re op uni mro)) {
 422         _find_tests($dir);
 423     }
 424     _find_tests("lib") unless $::core;
 425     # Config.pm may be broken for make minitest. And this is only a refinement
 426     # for skipping tests on non-default builds, so it is allowed to fail.
 427     # What we want to to is make a list of extensions which we did not build.
 428     my $configsh = '../config.sh';
 429     my ($extensions, $known_extensions);
 430     if (-f $configsh) {
 431         open FH, $configsh or die "Can't open $configsh: $!";
 432         while (<FH>) {
 433             if (/^extensions=['"](.*)['"]$/) {
 434                 $extensions = $1;
 435             }
 436             elsif (/^known_extensions=['"](.*)['"]$/) {
 437                 $known_extensions = $1;
 438             }
 439         }
 440         if (!defined $known_extensions) {
 441             warn "No known_extensions line found in $configsh";
 442         }
 443         if (!defined $extensions) {
 444             warn "No extensions line found in $configsh";
 445         }
 446     }
 447     # The "complex" constructions of list return from a subroutine, and push of
 448     # a list, might fail if perl is really hosed, but they aren't needed for
 449     # make minitest, and the building of extensions will likely also fail if
 450     # something is that badly wrong.
 451     push @ARGV, _tests_from_manifest($extensions, $known_extensions);
 452     unless ($::core) {
 453         _find_tests('x2p');
 454         _find_tests('porting');
 455         _find_tests('japh') if $::torture;
 456         _find_tests('t/benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
 457     }
 458 }
 459
 460 if ($::deparse) {
 461     _testprogs('deparse', '',   @ARGV);
 462 }
 463 elsif ($::with_utf16) {
 464     for my $e (0, 1) {
 465         for my $b (0, 1) {
 466             print STDERR "# ENDIAN $e BOM $b\n";
 467             my @UARGV;
 468             for my $a (@ARGV) {
 469                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
 470                 my $f = $e ? "v" : "n";
 471                 push @UARGV, $u;
 472                 unlink($u);
 473                 if (open(A, $a)) {
 474                     if (open(U, ">$u")) {
 475                         print U pack("$f", 0xFEFF) if $b;
 476                         while (<A>) {
 477                             print U pack("$f*", unpack("C*", $_));
 478                         }
 479                         close(U);
 480                     }
 481                     close(A);
 482                 }
 483             }
 484             _testprogs('perl', '', @UARGV);
 485             unlink(@UARGV);
 486         }
 487     }
 488 }
 489 else {
 490     _testprogs('perl',    '',   @ARGV);
 491 }
 492
 493 sub _testprogs {
 494     my ($type, $args, @tests) = @_;
 495
 496     print <<'EOT' if ($type eq 'deparse');
 497 ------------------------------------------------------------------------------
 498 TESTING DEPARSER
 499 ------------------------------------------------------------------------------
 500 EOT
 501
 502     $::bad_files = 0;
 503
 504     foreach my $t (@tests) {
 505       unless (exists $::path_to_name{$t}) {
 506         my $tname = "t/$t";
 507         $::path_to_name{$t} = $tname;
 508       }
 509     }
 510     my $maxlen = 0;
 511     foreach (@::path_to_name{@tests}) {
 512         s/\.\w+\z/ /; # space gives easy doubleclick to select fname
 513         my $len = length ;
 514         $maxlen = $len if $len > $maxlen;
 515     }
 516     # + 3 : we want three dots between the test name and the "ok"
 517     my $dotdotdot = $maxlen + 3 ;
 518     my $valgrind = 0;
 519     my $total_files = @tests;
 520     my $good_files = 0;
 521     my $tested_files  = 0;
 522     my $totmax = 0;
 523     my %failed_tests;
 524
 525     while (my $test = shift @tests) {
 526         my $test_start_time = $show_elapsed_time ? Time::HiRes::time() : 0;
 527
 528         if ($test =~ /^$/) {
 529             next;
 530         }
 531         if ($type eq 'deparse') {
 532             if ($test eq "comp/redef.t") {
 533                 # Redefinition happens at compile time
 534                 next;
 535             }
 536             elsif ($test =~ m{lib/Switch/t/}) {
 537                 # B::Deparse doesn't support source filtering
 538                 next;
 539             }
 540         }
 541         my $te = $::path_to_name{$test} . '.'
 542                     x ($dotdotdot - length($::path_to_name{$test})) .' ';
 543
 544         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
 545             print $te;
 546             $te = '';
 547         }
 548
 549         (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
 550         my $results = _run_test($test, $type);
 551
 552         my $failure;
 553         my $next = 0;
 554         my $seen_leader = 0;
 555         my $seen_ok = 0;
 556         my $trailing_leader = 0;
 557         my $max;
 558         my %todo;
 559         while (<$results>) {
 560             next if /^\s*$/; # skip blank lines
 561             if (/^1..$/ && ($^O eq 'VMS')) {
 562                 # VMS pipe bug inserts blank lines.
 563                 my $l2 = <RESULTS>;
 564                 if ($l2 =~ /^\s*$/) {
 565                     $l2 = <RESULTS>;
 566                 }
 567                 $_ = '1..' . $l2;
 568             }
 569             if ($::verbose) {
 570                 print $_;
 571             }
 572             unless (/^\#/) {
 573                 if ($trailing_leader) {
 574                     # shouldn't be anything following a postfix 1..n
 575                     $failure = 'FAILED--extra output after trailing 1..n';
 576                     last;
 577                 }
 578                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
 579                     if ($seen_leader) {
 580                         $failure = 'FAILED--seen duplicate leader';
 581                         last;
 582                     }
 583                     $max = $1;
 584                     %todo = map { $_ => 1 } split / /, $3 if $3;
 585                     $totmax = $totmax + $max;
 586                     $tested_files = $tested_files + 1;
 587                     if ($seen_ok) {
 588                         # 1..n appears at end of file
 589                         $trailing_leader = 1;
 590                         if ($next != $max) {
 591                             $failure = "FAILED--expected $max tests, saw $next";
 592                             last;
 593                         }
 594                     }
 595                     else {
 596                         $next = 0;
 597                     }
 598                     $seen_leader = 1;
 599                 }
 600                 else {
 601                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
 602                         unless ($seen_leader) {
 603                             unless ($seen_ok) {
 604                                 $next = 0;
 605                             }
 606                         }
 607                         $seen_ok = 1;
 608                         $next = $next + 1;
 609                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
 610                         $num = $next unless $num;
 611
 612                         if ($num == $next) {
 613
 614                             # SKIP is essentially the same as TODO for t/TEST
 615                             # this still conforms to TAP:
 616                             # http://testanything.org/wiki/index.php/TAP_specification
 617                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
 618                             $istodo = 1 if $todo{$num};
 619
 620                             if( $not && !$istodo ) {
 621                                 $failure = "FAILED at test $num";
 622                                 last;
 623                             }
 624                         }
 625                         else {
 626                             $failure ="FAILED--expected test $next, saw test $num";
 627                             last;
 628                         }
 629                     }
 630                     elsif (/^Bail out!\s*(.*)/i) { # magic words
 631                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
 632                     }
 633                     else {
 634                         # module tests are allowed extra output,
 635                         # because Test::Harness allows it
 636                         next if $test =~ /^\W*(cpan|dist|ext|lib)\b/;
 637                         $failure = "FAILED--unexpected output at test $next";
 638                         last;
 639                     }
 640                 }
 641             }
 642         }
 643         close $results;
 644
 645         if (not defined $failure) {
 646             $failure = 'FAILED--no leader found' unless $seen_leader;
 647         }
 648
 649         if ($ENV{PERL_VALGRIND}) {
 650             my @valgrind;
 651             if (-e $Valgrind_Log) {
 652                 if (open(V, $Valgrind_Log)) {
 653                     @valgrind = <V>;
 654                     close V;
 655                 } else {
 656                     warn "$0: Failed to open '$Valgrind_Log': $!\n";
 657                 }
 658             }
 659             if ($ENV{VG_OPTS} =~ /cachegrind/) {
 660                 if (rename $Valgrind_Log, "$test.valgrind") {
 661                     $valgrind = $valgrind + 1;
 662                 } else {
 663                     warn "$0: Failed to create '$test.valgrind': $!\n";
 664                 }
 665             }
 666             elsif (@valgrind) {
 667                 my $leaks = 0;
 668                 my $errors = 0;
 669                 for my $i (0..$#valgrind) {
 670                     local $_ = $valgrind[$i];
 671                     if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
 672                         $errors = $errors + $1;   # there may be multiple error summaries
 673                     } elsif (/^==\d+== LEAK SUMMARY:/) {
 674                         for my $off (1 .. 4) {
 675                             if ($valgrind[$i+$off] =~
 676                                 /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
 677                                 $leaks = $leaks + $1;
 678                             }
 679                         }
 680                     }
 681                 }
 682                 if ($errors or $leaks) {
 683                     if (rename $Valgrind_Log, "$test.valgrind") {
 684                         $valgrind = $valgrind + 1;
 685                     } else {
 686                         warn "$0: Failed to create '$test.valgrind': $!\n";
 687                     }
 688                 }
 689             } else {
 690                 warn "No valgrind output?\n";
 691             }
 692             if (-e $Valgrind_Log) {
 693                 unlink $Valgrind_Log
 694                     or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
 695             }
 696         }
 697         if ($type eq 'deparse') {
 698             unlink "./$test.dp";
 699         }
 700         if ($ENV{PERL_3LOG}) {
 701             my $tpp = $test;
 702             $tpp =~ s:^\.\./::;
 703             $tpp =~ s:/:_:g;
 704             $tpp =~ s:\.t$:.3log:;
 705             rename("perl.3log", $tpp) ||
 706                 die "rename: perl3.log to $tpp: $!\n";
 707         }
 708         if (not defined $failure and $next != $max) {
 709             $failure="FAILED--expected $max tests, saw $next";
 710         }
 711
 712         if( !defined $failure  # don't mask a test failure
 713             and $? )
 714         {
 715             $failure = "FAILED--non-zero wait status: $?";
 716         }
 717
 718         if (defined $failure) {
 719             print "${te}$failure\n";
 720             $::bad_files = $::bad_files + 1;
 721             if ($test =~ /^base/) {
 722                 die "Failed a basic test ($test) -- cannot continue.\n";
 723             }
 724             $failed_tests{$test} = 1;
 725         }
 726         else {
 727             if ($max) {
 728                 my $elapsed;
 729                 if ( $show_elapsed_time ) {
 730                     $elapsed = sprintf( " %8.0f ms", (Time::HiRes::time() - $test_start_time) * 1000 );
 731                 }
 732                 else {
 733                     $elapsed = "";
 734                 }
 735                 print "${te}ok$elapsed\n";
 736                 $good_files = $good_files + 1;
 737             }
 738             else {
 739                 print "${te}skipped\n";
 740                 $tested_files = $tested_files - 1;
 741             }
 742         }
 743     } # while tests
 744
 745     if ($::bad_files == 0) {
 746         if ($good_files) {
 747             print "All tests successful.\n";
 748             # XXX add mention of 'perlbug -ok' ?
 749         }
 750         else {
 751             die "FAILED--no tests were run for some reason.\n";
 752         }
 753     }
 754     else {
 755         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
 756         my $s = $::bad_files == 1 ? "" : "s";
 757         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
 758         for my $test ( sort keys %failed_tests ) {
 759             print "\t$test\n";
 760         }
 761         warn <<'SHRDLU_1';
 762 ### Since not all tests were successful, you may want to run some of
 763 ### them individually and examine any diagnostic messages they produce.
 764 ### See the INSTALL document's section on "make test".
 765 SHRDLU_1
 766         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
 767 ### You have a good chance to get more information by running
 768 ###   ./perl harness
 769 ### in the 't' directory since most (>=80%) of the tests succeeded.
 770 SHRDLU_2
 771         if (eval {require Config; import Config; 1}) {
 772             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
 773                 warn <<SHRDLU_3;
 774 ### You may have to set your dynamic library search path,
 775 ### $p, to point to the build directory:
 776 SHRDLU_3
 777                 if (exists $ENV{$p} && $ENV{$p} ne '') {
 778                     warn <<SHRDLU_4a;
 779 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
 780 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
 781 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
 782 SHRDLU_4a
 783                 } else {
 784                     warn <<SHRDLU_4b;
 785 ###   setenv $p `pwd`; cd t; ./perl harness
 786 ###   $p=`pwd`; export $p; cd t; ./perl harness
 787 ###   export $p=`pwd`; cd t; ./perl harness
 788 SHRDLU_4b
 789                 }
 790                 warn <<SHRDLU_5;
 791 ### for csh-style shells, like tcsh; or for traditional/modern
 792 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
 793 SHRDLU_5
 794             }
 795         }
 796     }
 797     my ($user,$sys,$cuser,$csys) = times;
 798     print sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d\n",
 799         $user,$sys,$cuser,$csys,$tested_files,$totmax);
 800     if ($ENV{PERL_VALGRIND}) {
 801         my $s = $valgrind == 1 ? '' : 's';
 802         print "$valgrind valgrind report$s created.\n", ;
 803     }
 804 }
 805 exit ($::bad_files != 0);
 806
 807 # ex: set ts=8 sts=4 sw=4 noet: