This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
f6fdc29eeabbcd7be7c9bdc1e0cd1de21b65184a
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2
3 perlre - Perl regular expressions
4
5 =head1 DESCRIPTION
6
7 This page describes the syntax of regular expressions in Perl.  For a
8 description of how to I<use> regular expressions in matching
9 operations, plus various examples of the same, see discussion
10 of C<m//>, C<s///>, and C<??> in L<perlop/Regexp Quote-Like Operators>.
11
12 The matching operations can have various modifiers.  The modifiers
13 that relate to the interpretation of the regular expression inside
14 are listed below.  For the modifiers that alter the way regular expression
15 is used by Perl, see L<perlop/Regexp Quote-Like Operators>.
16
17 =over 4
18
19 =item i
20
21 Do case-insensitive pattern matching.
22
23 If C<use locale> is in effect, the case map is taken from the current
24 locale.  See L<perllocale>.
25
26 =item m
27
28 Treat string as multiple lines.  That is, change "^" and "$" from matching
29 at only the very start or end of the string to the start or end of any
30 line anywhere within the string,
31
32 =item s
33
34 Treat string as single line.  That is, change "." to match any character
35 whatsoever, even a newline, which it normally would not match.
36
37 The C</s> and C</m> modifiers both override the C<$*> setting.  That is, no matter
38 what C<$*> contains, C</s> without C</m> will force "^" to match only at the
39 beginning of the string and "$" to match only at the end (or just before a
40 newline at the end) of the string.  Together, as /ms, they let the "." match
41 any character whatsoever, while yet allowing "^" and "$" to match,
42 respectively, just after and just before newlines within the string.
43
44 =item x
45
46 Extend your pattern's legibility by permitting whitespace and comments.
47
48 =back
49
50 These are usually written as "the C</x> modifier", even though the delimiter
51 in question might not actually be a slash.  In fact, any of these
52 modifiers may also be embedded within the regular expression itself using
53 the new C<(?...)> construct.  See below.
54
55 The C</x> modifier itself needs a little more explanation.  It tells
56 the regular expression parser to ignore whitespace that is neither
57 backslashed nor within a character class.  You can use this to break up
58 your regular expression into (slightly) more readable parts.  The C<#>
59 character is also treated as a metacharacter introducing a comment,
60 just as in ordinary Perl code.  This also means that if you want real
61 whitespace or C<#> characters in the pattern (outside of a character
62 class, where they are unaffected by C</x>), that you'll either have to 
63 escape them or encode them using octal or hex escapes.  Taken together,
64 these features go a long way towards making Perl's regular expressions
65 more readable.  Note that you have to be careful not to include the
66 pattern delimiter in the comment--perl has no way of knowing you did
67 not intend to close the pattern early.  See the C-comment deletion code
68 in L<perlop>.
69
70 =head2 Regular Expressions
71
72 The patterns used in pattern matching are regular expressions such as
73 those supplied in the Version 8 regex routines.  (In fact, the
74 routines are derived (distantly) from Henry Spencer's freely
75 redistributable reimplementation of the V8 routines.)
76 See L<Version 8 Regular Expressions> for details.
77
78 In particular the following metacharacters have their standard I<egrep>-ish
79 meanings:
80
81     \   Quote the next metacharacter
82     ^   Match the beginning of the line
83     .   Match any character (except newline)
84     $   Match the end of the line (or before newline at the end)
85     |   Alternation
86     ()  Grouping
87     []  Character class
88
89 By default, the "^" character is guaranteed to match at only the
90 beginning of the string, the "$" character at only the end (or before the
91 newline at the end) and Perl does certain optimizations with the
92 assumption that the string contains only one line.  Embedded newlines
93 will not be matched by "^" or "$".  You may, however, wish to treat a
94 string as a multi-line buffer, such that the "^" will match after any
95 newline within the string, and "$" will match before any newline.  At the
96 cost of a little more overhead, you can do this by using the /m modifier
97 on the pattern match operator.  (Older programs did this by setting C<$*>,
98 but this practice is now deprecated.)
99
100 To facilitate multi-line substitutions, the "." character never matches a
101 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
102 the string is a single line--even if it isn't.  The C</s> modifier also
103 overrides the setting of C<$*>, in case you have some (badly behaved) older
104 code that sets it in another module.
105
106 The following standard quantifiers are recognized:
107
108     *      Match 0 or more times
109     +      Match 1 or more times
110     ?      Match 1 or 0 times
111     {n}    Match exactly n times
112     {n,}   Match at least n times
113     {n,m}  Match at least n but not more than m times
114
115 (If a curly bracket occurs in any other context, it is treated
116 as a regular character.)  The "*" modifier is equivalent to C<{0,}>, the "+"
117 modifier to C<{1,}>, and the "?" modifier to C<{0,1}>.  n and m are limited
118 to integral values less than 65536.
119
120 By default, a quantified subpattern is "greedy", that is, it will match as
121 many times as possible (given a particular starting location) while still
122 allowing the rest of the pattern to match.  If you want it to match the
123 minimum number of times possible, follow the quantifier with a "?".  Note
124 that the meanings don't change, just the "greediness":
125
126     *?     Match 0 or more times
127     +?     Match 1 or more times
128     ??     Match 0 or 1 time
129     {n}?   Match exactly n times
130     {n,}?  Match at least n times
131     {n,m}? Match at least n but not more than m times
132
133 Because patterns are processed as double quoted strings, the following
134 also work:
135
136     \t          tab                   (HT, TAB)
137     \n          newline               (LF, NL)
138     \r          return                (CR)
139     \f          form feed             (FF)
140     \a          alarm (bell)          (BEL)
141     \e          escape (think troff)  (ESC)
142     \033        octal char (think of a PDP-11)
143     \x1B        hex char
144     \c[         control char
145     \l          lowercase next char (think vi)
146     \u          uppercase next char (think vi)
147     \L          lowercase till \E (think vi)
148     \U          uppercase till \E (think vi)
149     \E          end case modification (think vi)
150     \Q          quote (disable) pattern metacharacters till \E
151
152 If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
153 and C<\U> is taken from the current locale.  See L<perllocale>.
154
155 You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
156 An unescaped C<$> or C<@> interpolates the corresponding variable,
157 while escaping will cause the literal string C<\$> to be matched.
158 You'll need to write something like C<m/\Quser\E\@\Qhost/>.
159
160 In addition, Perl defines the following:
161
162     \w  Match a "word" character (alphanumeric plus "_")
163     \W  Match a non-word character
164     \s  Match a whitespace character
165     \S  Match a non-whitespace character
166     \d  Match a digit character
167     \D  Match a non-digit character
168
169 A C<\w> matches a single alphanumeric character, not a whole
170 word.  To match a word you'd need to say C<\w+>.  If C<use locale> is in
171 effect, the list of alphabetic characters generated by C<\w> is taken
172 from the current locale.  See L<perllocale>. You may use C<\w>, C<\W>,
173 C<\s>, C<\S>, C<\d>, and C<\D> within character classes (though not as
174 either end of a range).
175
176 Perl defines the following zero-width assertions:
177
178     \b  Match a word boundary
179     \B  Match a non-(word boundary)
180     \A  Match only at beginning of string
181     \Z  Match only at end of string, or before newline at the end
182     \z  Match only at end of string
183     \G  Match only where previous m//g left off (works only with /g)
184
185 A word boundary (C<\b>) is defined as a spot between two characters that
186 has a C<\w> on one side of it and a C<\W> on the other side of it (in
187 either order), counting the imaginary characters off the beginning and
188 end of the string as matching a C<\W>.  (Within character classes C<\b>
189 represents backspace rather than a word boundary.)  The C<\A> and C<\Z> are
190 just like "^" and "$", except that they won't match multiple times when the
191 C</m> modifier is used, while "^" and "$" will match at every internal line
192 boundary.  To match the actual end of the string, not ignoring newline,
193 you can use C<\z>.  The C<\G> assertion can be used to chain global
194 matches (using C<m//g>), as described in
195 L<perlop/"Regexp Quote-Like Operators">.
196
197 It is also useful when writing C<lex>-like scanners, when you have several
198 patterns that you want to match against consequent substrings of your
199 string, see the previous reference.
200 The actual location where C<\G> will match can also be influenced
201 by using C<pos()> as an lvalue.  See L<perlfunc/pos>.
202
203 When the bracketing construct C<( ... )> is used, \E<lt>digitE<gt> matches the
204 digit'th substring.  Outside of the pattern, always use "$" instead of "\"
205 in front of the digit.  (While the \E<lt>digitE<gt> notation can on rare occasion work
206 outside the current pattern, this should not be relied upon.  See the
207 WARNING below.) The scope of $E<lt>digitE<gt> (and C<$`>, C<$&>, and C<$'>)
208 extends to the end of the enclosing BLOCK or eval string, or to the next
209 successful pattern match, whichever comes first.  If you want to use
210 parentheses to delimit a subpattern (e.g., a set of alternatives) without
211 saving it as a subpattern, follow the ( with a ?:.
212
213 You may have as many parentheses as you wish.  If you have more
214 than 9 substrings, the variables $10, $11, ... refer to the
215 corresponding substring.  Within the pattern, \10, \11, etc. refer back
216 to substrings if there have been at least that many left parentheses before
217 the backreference.  Otherwise (for backward compatibility) \10 is the
218 same as \010, a backspace, and \11 the same as \011, a tab.  And so
219 on.  (\1 through \9 are always backreferences.)
220
221 C<$+> returns whatever the last bracket match matched.  C<$&> returns the
222 entire matched string.  (C<$0> used to return the same thing, but not any
223 more.)  C<$`> returns everything before the matched string.  C<$'> returns
224 everything after the matched string.  Examples:
225
226     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
227
228     if (/Time: (..):(..):(..)/) {
229         $hours = $1;
230         $minutes = $2;
231         $seconds = $3;
232     }
233
234 Once perl sees that you need one of C<$&>, C<$`> or C<$'> anywhere in
235 the program, it has to provide them on each and every pattern match.
236 This can slow your program down.  The same mechanism that handles
237 these provides for the use of $1, $2, etc., so you pay the same price
238 for each pattern that contains capturing parentheses. But if you never
239 use $&, etc., in your script, then patterns I<without> capturing
240 parentheses won't be penalized. So avoid $&, $', and $` if you can,
241 but if you can't (and some algorithms really appreciate them), once
242 you've used them once, use them at will, because you've already paid
243 the price.  As of 5.005, $& is not so costly as the other two.
244
245 Backslashed metacharacters in Perl are
246 alphanumeric, such as C<\b>, C<\w>, C<\n>.  Unlike some other regular
247 expression languages, there are no backslashed symbols that aren't
248 alphanumeric.  So anything that looks like \\, \(, \), \E<lt>, \E<gt>,
249 \{, or \} is always interpreted as a literal character, not a
250 metacharacter.  This was once used in a common idiom to disable or
251 quote the special meanings of regular expression metacharacters in a
252 string that you want to use for a pattern. Simply quote all
253 non-alphanumeric characters:
254
255     $pattern =~ s/(\W)/\\$1/g;
256
257 Now it is much more common to see either the quotemeta() function or
258 the C<\Q> escape sequence used to disable all metacharacters' special
259 meanings like this:
260
261     /$unquoted\Q$quoted\E$unquoted/
262
263 Perl defines a consistent extension syntax for regular expressions.
264 The syntax is a pair of parentheses with a question mark as the first
265 thing within the parentheses (this was a syntax error in older
266 versions of Perl).  The character after the question mark gives the
267 function of the extension.  Several extensions are already supported:
268
269 =over 10
270
271 =item C<(?#text)>
272
273 A comment.  The text is ignored.  If the C</x> switch is used to enable
274 whitespace formatting, a simple C<#> will suffice.  Note that perl closes
275 the comment as soon as it sees a C<)>, so there is no way to put a literal
276 C<)> in the comment.
277
278 =item C<(?:pattern)>
279
280 This is for clustering, not capturing; it groups subexpressions like
281 "()", but doesn't make backreferences as "()" does.  So
282
283     @fields = split(/\b(?:a|b|c)\b/)
284
285 is like
286
287     @fields = split(/\b(a|b|c)\b/)
288
289 but doesn't spit out extra fields.
290
291 =item C<(?=pattern)>
292
293 A zero-width positive lookahead assertion.  For example, C</\w+(?=\t)/>
294 matches a word followed by a tab, without including the tab in C<$&>.
295
296 =item C<(?!pattern)>
297
298 A zero-width negative lookahead assertion.  For example C</foo(?!bar)/>
299 matches any occurrence of "foo" that isn't followed by "bar".  Note
300 however that lookahead and lookbehind are NOT the same thing.  You cannot
301 use this for lookbehind.
302
303 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
304 will not do what you want.  That's because the C<(?!foo)> is just saying that
305 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
306 match.  You would have to do something like C</(?!foo)...bar/> for that.   We
307 say "like" because there's the case of your "bar" not having three characters
308 before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
309 Sometimes it's still easier just to say:
310
311     if (/bar/ && $` !~ /foo$/)
312
313 For lookbehind see below.
314
315 =item C<(?E<lt>=pattern)>
316
317 A zero-width positive lookbehind assertion.  For example, C</(?E<lt>=\t)\w+/>
318 matches a word following a tab, without including the tab in C<$&>.
319 Works only for fixed-width lookbehind.
320
321 =item C<(?<!pattern)>
322
323 A zero-width negative lookbehind assertion.  For example C</(?<!bar)foo/>
324 matches any occurrence of "foo" that isn't following "bar".  
325 Works only for fixed-width lookbehind.
326
327 =item C<(?{ code })>
328
329 Experimental "evaluate any Perl code" zero-width assertion.  Always
330 succeeds.  C<code> is not interpolated.  Currently the rules to
331 determine where the C<code> ends are somewhat convoluted.
332
333 Owing to the risks to security, this is only available when the
334 C<use re 'eval'> pragma is used, and then only for patterns that don't
335 have any variables that must be interpolated at run time.
336
337 The C<code> is properly scoped in the following sense: if the assertion
338 is backtracked (compare L<"Backtracking">), all the changes introduced after
339 C<local>isation are undone, so
340
341   $_ = 'a' x 8;
342   m< 
343      (?{ $cnt = 0 })                    # Initialize $cnt.
344      (
345        a 
346        (?{
347            local $cnt = $cnt + 1;       # Update $cnt, backtracking-safe.
348        })
349      )*  
350      aaaa
351      (?{ $res = $cnt })                 # On success copy to non-localized
352                                         # location.
353    >x;
354
355 will set C<$res = 4>.  Note that after the match $cnt returns to the globally
356 introduced value 0, since the scopes which restrict C<local> statements
357 are unwound.
358
359 This assertion may be used as L<C<(?(condition)yes-pattern|no-pattern)>>
360 switch.  If I<not> used in this way, the result of evaluation of C<code>
361 is put into variable $^R.  This happens immediately, so $^R can be used from
362 other C<(?{ code })> assertions inside the same regular expression.
363
364 The above assignment to $^R is properly localized, thus the old value of $^R
365 is restored if the assertion is backtracked (compare L<"Backtracking">).
366
367 =item C<(?E<gt>pattern)>
368
369 An "independent" subexpression.  Matches the substring that a
370 I<standalone> C<pattern> would match if anchored at the given position,
371 B<and only this substring>.
372
373 Say, C<^(?E<gt>a*)ab> will never match, since C<(?E<gt>a*)> (anchored
374 at the beginning of string, as above) will match I<all> characters
375 C<a> at the beginning of string, leaving no C<a> for C<ab> to match.
376 In contrast, C<a*ab> will match the same as C<a+b>, since the match of
377 the subgroup C<a*> is influenced by the following group C<ab> (see
378 L<"Backtracking">).  In particular, C<a*> inside C<a*ab> will match
379 less characters that a standalone C<a*>, since this makes the tail match.
380
381 An effect similar to C<(?E<gt>pattern)> may be achieved by
382
383    (?=(pattern))\1
384
385 since the lookahead is in I<"logical"> context, thus matches the same
386 substring as a standalone C<a+>.  The following C<\1> eats the matched
387 string, thus making a zero-length assertion into an analogue of
388 C<(?>...)>.  (The difference between these two constructs is that the
389 second one uses a catching group, thus shifting ordinals of
390 backreferences in the rest of a regular expression.)
391
392 This construct is useful for optimizations of "eternal"
393 matches, because it will not backtrack (see L<"Backtracking">).  
394
395     m{  \( ( 
396          [^()]+ 
397        | 
398          \( [^()]* \)
399        )+
400         \) 
401     }x
402
403 That will efficiently match a nonempty group with matching
404 two-or-less-level-deep parentheses.  However, if there is no such group,
405 it will take virtually forever on a long string.  That's because there are
406 so many different ways to split a long string into several substrings.
407 This is essentially what C<(.+)+> is doing, and this is a subpattern
408 of the above pattern.  Consider that C<((()aaaaaaaaaaaaaaaaaa> on the
409 pattern above detects no-match in several seconds, but that  each extra
410 letter doubles this time.  This exponential performance will make it
411 appear that your program has hung.
412
413 However, a tiny modification of this pattern 
414
415     m{ \( ( 
416          (?> [^()]+ )
417        | 
418          \( [^()]* \)
419        )+
420         \) 
421     }x
422
423 which uses C<(?E<gt>...)> matches exactly when the one above does (verifying
424 this yourself would be a productive exercise), but finishes in a fourth
425 the time when used on a similar string with 1000000 C<a>s.  Be aware,
426 however, that this pattern currently triggers a warning message under
427 B<-w> saying it C<"matches the null string many times">):
428
429 On simple groups, such as the pattern C<(?> [^()]+ )>, a comparable
430 effect may be achieved by negative lookahead, as in C<[^()]+ (?! [^()] )>.
431 This was only 4 times slower on a string with 1000000 C<a>s.
432
433 =item C<(?(condition)yes-pattern|no-pattern)>
434
435 =item C<(?(condition)yes-pattern)>
436
437 Conditional expression.  C<(condition)> should be either an integer in
438 parentheses (which is valid if the corresponding pair of parentheses
439 matched), or lookahead/lookbehind/evaluate zero-width assertion.
440
441 Say,
442
443     m{ ( \( )? 
444       [^()]+ 
445        (?(1) \) ) 
446     }x
447
448 matches a chunk of non-parentheses, possibly included in parentheses
449 themselves.
450
451 =item C<(?imsx)>
452
453 One or more embedded pattern-match modifiers.  This is particularly
454 useful for patterns that are specified in a table somewhere, some of
455 which want to be case sensitive, and some of which don't.  The case
456 insensitive ones need to include merely C<(?i)> at the front of the
457 pattern.  For example:
458
459     $pattern = "foobar";
460     if ( /$pattern/i ) { } 
461
462     # more flexible:
463
464     $pattern = "(?i)foobar";
465     if ( /$pattern/ ) { } 
466
467 These modifiers are localized inside an enclosing group (if any).  Say,
468
469     ( (?i) blah ) \s+ \1
470
471 (assuming C<x> modifier, and no C<i> modifier outside of this group)
472 will match a repeated (I<including the case>!) word C<blah> in any
473 case.
474
475 =back
476
477 A question mark was chosen for this and for the new minimal-matching
478 construct because 1) question mark is pretty rare in older regular
479 expressions, and 2) whenever you see one, you should stop and "question"
480 exactly what is going on.  That's psychology...
481
482 =head2 Backtracking
483
484 A fundamental feature of regular expression matching involves the
485 notion called I<backtracking>, which is currently used (when needed)
486 by all regular expression quantifiers, namely C<*>, C<*?>, C<+>,
487 C<+?>, C<{n,m}>, and C<{n,m}?>.
488
489 For a regular expression to match, the I<entire> regular expression must
490 match, not just part of it.  So if the beginning of a pattern containing a
491 quantifier succeeds in a way that causes later parts in the pattern to
492 fail, the matching engine backs up and recalculates the beginning
493 part--that's why it's called backtracking.
494
495 Here is an example of backtracking:  Let's say you want to find the
496 word following "foo" in the string "Food is on the foo table.":
497
498     $_ = "Food is on the foo table.";
499     if ( /\b(foo)\s+(\w+)/i ) {
500         print "$2 follows $1.\n";
501     }
502
503 When the match runs, the first part of the regular expression (C<\b(foo)>)
504 finds a possible match right at the beginning of the string, and loads up
505 $1 with "Foo".  However, as soon as the matching engine sees that there's
506 no whitespace following the "Foo" that it had saved in $1, it realizes its
507 mistake and starts over again one character after where it had the
508 tentative match.  This time it goes all the way until the next occurrence
509 of "foo". The complete regular expression matches this time, and you get
510 the expected output of "table follows foo."
511
512 Sometimes minimal matching can help a lot.  Imagine you'd like to match
513 everything between "foo" and "bar".  Initially, you write something
514 like this:
515
516     $_ =  "The food is under the bar in the barn.";
517     if ( /foo(.*)bar/ ) {
518         print "got <$1>\n";
519     }
520
521 Which perhaps unexpectedly yields:
522
523   got <d is under the bar in the >
524
525 That's because C<.*> was greedy, so you get everything between the
526 I<first> "foo" and the I<last> "bar".  In this case, it's more effective
527 to use minimal matching to make sure you get the text between a "foo"
528 and the first "bar" thereafter.
529
530     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
531   got <d is under the >
532
533 Here's another example: let's say you'd like to match a number at the end
534 of a string, and you also want to keep the preceding part the match.
535 So you write this:
536
537     $_ = "I have 2 numbers: 53147";
538     if ( /(.*)(\d*)/ ) {                                # Wrong!
539         print "Beginning is <$1>, number is <$2>.\n";
540     }
541
542 That won't work at all, because C<.*> was greedy and gobbled up the
543 whole string. As C<\d*> can match on an empty string the complete
544 regular expression matched successfully.
545
546     Beginning is <I have 2 numbers: 53147>, number is <>.
547
548 Here are some variants, most of which don't work:
549
550     $_ = "I have 2 numbers: 53147";
551     @pats = qw{
552         (.*)(\d*)
553         (.*)(\d+)
554         (.*?)(\d*)
555         (.*?)(\d+)
556         (.*)(\d+)$
557         (.*?)(\d+)$
558         (.*)\b(\d+)$
559         (.*\D)(\d+)$
560     };
561
562     for $pat (@pats) {
563         printf "%-12s ", $pat;
564         if ( /$pat/ ) {
565             print "<$1> <$2>\n";
566         } else {
567             print "FAIL\n";
568         }
569     }
570
571 That will print out:
572
573     (.*)(\d*)    <I have 2 numbers: 53147> <>
574     (.*)(\d+)    <I have 2 numbers: 5314> <7>
575     (.*?)(\d*)   <> <>
576     (.*?)(\d+)   <I have > <2>
577     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
578     (.*?)(\d+)$  <I have 2 numbers: > <53147>
579     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
580     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
581
582 As you see, this can be a bit tricky.  It's important to realize that a
583 regular expression is merely a set of assertions that gives a definition
584 of success.  There may be 0, 1, or several different ways that the
585 definition might succeed against a particular string.  And if there are
586 multiple ways it might succeed, you need to understand backtracking to
587 know which variety of success you will achieve.
588
589 When using lookahead assertions and negations, this can all get even
590 tricker.  Imagine you'd like to find a sequence of non-digits not
591 followed by "123".  You might try to write that as
592
593         $_ = "ABC123";
594         if ( /^\D*(?!123)/ ) {                          # Wrong!
595             print "Yup, no 123 in $_\n";
596         }
597
598 But that isn't going to match; at least, not the way you're hoping.  It
599 claims that there is no 123 in the string.  Here's a clearer picture of
600 why it that pattern matches, contrary to popular expectations:
601
602     $x = 'ABC123' ;
603     $y = 'ABC445' ;
604
605     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/ ;
606     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/ ;
607
608     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/ ;
609     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/ ;
610
611 This prints
612
613     2: got ABC
614     3: got AB
615     4: got ABC
616
617 You might have expected test 3 to fail because it seems to a more
618 general purpose version of test 1.  The important difference between
619 them is that test 3 contains a quantifier (C<\D*>) and so can use
620 backtracking, whereas test 1 will not.  What's happening is
621 that you've asked "Is it true that at the start of $x, following 0 or more
622 non-digits, you have something that's not 123?"  If the pattern matcher had
623 let C<\D*> expand to "ABC", this would have caused the whole pattern to
624 fail.
625 The search engine will initially match C<\D*> with "ABC".  Then it will
626 try to match C<(?!123> with "123", which of course fails.  But because
627 a quantifier (C<\D*>) has been used in the regular expression, the
628 search engine can backtrack and retry the match differently
629 in the hope of matching the complete regular expression.
630
631 The pattern really, I<really> wants to succeed, so it uses the
632 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
633 time.  Now there's indeed something following "AB" that is not
634 "123".  It's in fact "C123", which suffices.
635
636 We can deal with this by using both an assertion and a negation.  We'll
637 say that the first part in $1 must be followed by a digit, and in fact, it
638 must also be followed by something that's not "123".  Remember that the
639 lookaheads are zero-width expressions--they only look, but don't consume
640 any of the string in their match.  So rewriting this way produces what
641 you'd expect; that is, case 5 will fail, but case 6 succeeds:
642
643     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/ ;
644     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/ ;
645
646     6: got ABC
647
648 In other words, the two zero-width assertions next to each other work as though
649 they're ANDed together, just as you'd use any builtin assertions:  C</^$/>
650 matches only if you're at the beginning of the line AND the end of the
651 line simultaneously.  The deeper underlying truth is that juxtaposition in
652 regular expressions always means AND, except when you write an explicit OR
653 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
654 although the attempted matches are made at different positions because "a"
655 is not a zero-width assertion, but a one-width assertion.
656
657 One warning: particularly complicated regular expressions can take
658 exponential time to solve due to the immense number of possible ways they
659 can use backtracking to try match.  For example this will take a very long
660 time to run
661
662     /((a{0,5}){0,5}){0,5}/
663
664 And if you used C<*>'s instead of limiting it to 0 through 5 matches, then
665 it would take literally forever--or until you ran out of stack space.
666
667 A powerful tool for optimizing such beasts is "independent" groups,
668 which do not backtrace (see L<C<(?E<gt>pattern)>>).  Note also that
669 zero-length lookahead/lookbehind assertions will not backtrace to make
670 the tail match, since they are in "logical" context: only the fact
671 whether they match or not is considered relevant.  For an example
672 where side-effects of a lookahead I<might> have influenced the
673 following match, see L<C<(?E<gt>pattern)>>.
674
675 =head2 Version 8 Regular Expressions
676
677 In case you're not familiar with the "regular" Version 8 regex
678 routines, here are the pattern-matching rules not described above.
679
680 Any single character matches itself, unless it is a I<metacharacter>
681 with a special meaning described here or above.  You can cause
682 characters that normally function as metacharacters to be interpreted
683 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
684 character; "\\" matches a "\").  A series of characters matches that
685 series of characters in the target string, so the pattern C<blurfl>
686 would match "blurfl" in the target string.
687
688 You can specify a character class, by enclosing a list of characters
689 in C<[]>, which will match any one character from the list.  If the
690 first character after the "[" is "^", the class matches any character not
691 in the list.  Within a list, the "-" character is used to specify a
692 range, so that C<a-z> represents all characters between "a" and "z",
693 inclusive.  If you want "-" itself to be a member of a class, put it
694 at the start or end of the list, or escape it with a backslash.  (The
695 following all specify the same class of three characters: C<[-az]>,
696 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
697 specifies a class containing twenty-six characters.)
698
699 Characters may be specified using a metacharacter syntax much like that
700 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
701 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
702 of octal digits, matches the character whose ASCII value is I<nnn>.
703 Similarly, \xI<nn>, where I<nn> are hexadecimal digits, matches the
704 character whose ASCII value is I<nn>. The expression \cI<x> matches the
705 ASCII character control-I<x>.  Finally, the "." metacharacter matches any
706 character except "\n" (unless you use C</s>).
707
708 You can specify a series of alternatives for a pattern using "|" to
709 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
710 or "foe" in the target string (as would C<f(e|i|o)e>).  The
711 first alternative includes everything from the last pattern delimiter
712 ("(", "[", or the beginning of the pattern) up to the first "|", and
713 the last alternative contains everything from the last "|" to the next
714 pattern delimiter.  For this reason, it's common practice to include
715 alternatives in parentheses, to minimize confusion about where they
716 start and end.
717
718 Alternatives are tried from left to right, so the first
719 alternative found for which the entire expression matches, is the one that
720 is chosen. This means that alternatives are not necessarily greedy. For
721 example: when mathing C<foo|foot> against "barefoot", only the "foo"
722 part will match, as that is the first alternative tried, and it successfully
723 matches the target string. (This might not seem important, but it is
724 important when you are capturing matched text using parentheses.)
725
726 Also remember that "|" is interpreted as a literal within square brackets,
727 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
728
729 Within a pattern, you may designate subpatterns for later reference by
730 enclosing them in parentheses, and you may refer back to the I<n>th
731 subpattern later in the pattern using the metacharacter \I<n>.
732 Subpatterns are numbered based on the left to right order of their
733 opening parenthesis.  A backreference matches whatever
734 actually matched the subpattern in the string being examined, not the
735 rules for that subpattern.  Therefore, C<(0|0x)\d*\s\1\d*> will
736 match "0x1234 0x4321", but not "0x1234 01234", because subpattern 1
737 actually matched "0x", even though the rule C<0|0x> could
738 potentially match the leading 0 in the second number.
739
740 =head2 WARNING on \1 vs $1
741
742 Some people get too used to writing things like:
743
744     $pattern =~ s/(\W)/\\\1/g;
745
746 This is grandfathered for the RHS of a substitute to avoid shocking the
747 B<sed> addicts, but it's a dirty habit to get into.  That's because in
748 PerlThink, the righthand side of a C<s///> is a double-quoted string.  C<\1> in
749 the usual double-quoted string means a control-A.  The customary Unix
750 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
751 of doing that, you get yourself into trouble if you then add an C</e>
752 modifier.
753
754     s/(\d+)/ \1 + 1 /eg;        # causes warning under -w
755
756 Or if you try to do
757
758     s/(\d+)/\1000/;
759
760 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
761 C<${1}000>.  Basically, the operation of interpolation should not be confused
762 with the operation of matching a backreference.  Certainly they mean two
763 different things on the I<left> side of the C<s///>.
764
765 =head2 SEE ALSO
766
767 L<perlop/"Regexp Quote-Like Operators">.
768
769 L<perlfunc/pos>.
770
771 L<perllocale>.
772
773 I<Mastering Regular Expressions> (see L<perlbook>) by Jeffrey Friedl.