This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Debugger prints lines to the remote port when it forks and openes a new port
[perl5.git] / lib / perl5db.pl
1
2 =head1 NAME 
3
4 perl5db.pl - the perl debugger
5
6 =head1 SYNOPSIS
7
8     perl -d  your_Perl_script
9
10 =head1 DESCRIPTION
11
12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
13 you invoke a script with C<perl -d>. This documentation tries to outline the
14 structure and services provided by C<perl5db.pl>, and to describe how you
15 can use them.
16
17 =head1 GENERAL NOTES
18
19 The debugger can look pretty forbidding to many Perl programmers. There are
20 a number of reasons for this, many stemming out of the debugger's history.
21
22 When the debugger was first written, Perl didn't have a lot of its nicer
23 features - no references, no lexical variables, no closures, no object-oriented
24 programming. So a lot of the things one would normally have done using such
25 features was done using global variables, globs and the C<local()> operator 
26 in creative ways.
27
28 Some of these have survived into the current debugger; a few of the more
29 interesting and still-useful idioms are noted in this section, along with notes
30 on the comments themselves.
31
32 =head2 Why not use more lexicals?
33
34 Experienced Perl programmers will note that the debugger code tends to use
35 mostly package globals rather than lexically-scoped variables. This is done
36 to allow a significant amount of control of the debugger from outside the
37 debugger itself.       
38
39 Unfortunately, though the variables are accessible, they're not well
40 documented, so it's generally been a decision that hasn't made a lot of
41 difference to most users. Where appropriate, comments have been added to
42 make variables more accessible and usable, with the understanding that these
43 I<are> debugger internals, and are therefore subject to change. Future
44 development should probably attempt to replace the globals with a well-defined
45 API, but for now, the variables are what we've got.
46
47 =head2 Automated variable stacking via C<local()>
48
49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a 
50 temporary copy of a variable in the current scope. When the scope ends, the
51 old copy is restored. This is often used in the debugger to handle the 
52 automatic stacking of variables during recursive calls:
53
54      sub foo {
55         local $some_global++;
56
57         # Do some stuff, then ...
58         return;
59      }
60
61 What happens is that on entry to the subroutine, C<$some_global> is localized,
62 then altered. When the subroutine returns, Perl automatically undoes the 
63 localization, restoring the previous value. Voila, automatic stack management.
64
65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>, 
66 which lets the debugger get control inside of C<eval>'ed code. The debugger
67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep 
70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
71
72 In any case, watch for this pattern. It occurs fairly often.
73
74 =head2 The C<^> trick
75
76 This is used to cleverly reverse the sense of a logical test depending on 
77 the value of an auxiliary variable. For instance, the debugger's C<S>
78 (search for subroutines by pattern) allows you to negate the pattern 
79 like this:
80
81    # Find all non-'foo' subs:
82    S !/foo/      
83
84 Boolean algebra states that the truth table for XOR looks like this:
85
86 =over 4
87
88 =item * 0 ^ 0 = 0 
89
90 (! not present and no match) --> false, don't print
91
92 =item * 0 ^ 1 = 1 
93
94 (! not present and matches) --> true, print
95
96 =item * 1 ^ 0 = 1 
97
98 (! present and no match) --> true, print
99
100 =item * 1 ^ 1 = 0 
101
102 (! present and matches) --> false, don't print
103
104 =back
105
106 As you can see, the first pair applies when C<!> isn't supplied, and
107 the second pair applies when it is. The XOR simply allows us to
108 compact a more complicated if-then-elseif-else into a more elegant 
109 (but perhaps overly clever) single test. After all, it needed this
110 explanation...
111
112 =head2 FLAGS, FLAGS, FLAGS
113
114 There is a certain C programming legacy in the debugger. Some variables,
115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
117 of state to be stored independently in a single scalar. 
118
119 A test like
120
121     if ($scalar & 4) ...
122
123 is checking to see if the appropriate bit is on. Since each bit can be 
124 "addressed" independently in this way, C<$scalar> is acting sort of like
125 an array of bits. Obviously, since the contents of C<$scalar> are just a 
126 bit-pattern, we can save and restore it easily (it will just look like
127 a number).
128
129 The problem, is of course, that this tends to leave magic numbers scattered
130 all over your program whenever a bit is set, cleared, or checked. So why do 
131 it?
132
133 =over 4
134
135 =item *
136
137 First, doing an arithmetical or bitwise operation on a scalar is
138 just about the fastest thing you can do in Perl: C<use constant> actually
139 creates a subroutine call, and array and hash lookups are much slower. Is
140 this over-optimization at the expense of readability? Possibly, but the 
141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
142 probably have to benchmark alternate implementations and see which is the
143 best balance of readability and speed, and then document how it actually 
144 works.
145
146 =item *
147
148 Second, it's very easy to serialize a scalar number. This is done in 
149 the restart code; the debugger state variables are saved in C<%ENV> and then
150 restored when the debugger is restarted. Having them be just numbers makes
151 this trivial. 
152
153 =item *
154
155 Third, some of these variables are being shared with the Perl core 
156 smack in the middle of the interpreter's execution loop. It's much faster for 
157 a C program (like the interpreter) to check a bit in a scalar than to access 
158 several different variables (or a Perl array).
159
160 =back
161
162 =head2 What are those C<XXX> comments for?
163
164 Any comment containing C<XXX> means that the comment is either somewhat
165 speculative - it's not exactly clear what a given variable or chunk of 
166 code is doing, or that it is incomplete - the basics may be clear, but the
167 subtleties are not completely documented.
168
169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
170
171 =head1 DATA STRUCTURES MAINTAINED BY CORE         
172
173 There are a number of special data structures provided to the debugger by
174 the Perl interpreter.
175
176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
177 via glob assignment) contains the text from C<$filename>, with each
178 element corresponding to a single line of C<$filename>. Additionally,
179 breakable lines will be dualvars with the numeric component being the
180 memory address of a COP node. Non-breakable lines are dualvar to 0.
181
182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob 
183 assignment) contains breakpoints and actions.  The keys are line numbers; 
184 you can set individual values, but not the whole hash. The Perl interpreter 
185 uses this hash to determine where breakpoints have been set. Any true value is
186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
188
189 The scalar C<${"_<$filename"}> simply contains the string C<_<$filename>.
190 This is also the case for evaluated strings that contain subroutines, or
191 which are currently being executed.  The $filename for C<eval>ed strings looks
192 like C<(eval 34)> or C<(re_eval 19)>.
193
194 =head1 DEBUGGER STARTUP
195
196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
198 of options. In addition, this file may define a subroutine C<&afterinit>
199 that will be executed (in the debugger's context) after the debugger has 
200 initialized itself.
201
202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its 
203 contents as the argument of a C<o> command in the debugger.
204
205 =head2 STARTUP-ONLY OPTIONS
206
207 The following options can only be specified at startup.
208 To set them in your rcfile, add a call to
209 C<&parse_options("optionName=new_value")>.
210
211 =over 4
212
213 =item * TTY 
214
215 the TTY to use for debugging i/o.
216
217 =item * noTTY 
218
219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
221 Term::Rendezvous.  Current variant is to have the name of TTY in this
222 file.
223
224 =item * ReadLine 
225
226 if false, a dummy ReadLine is used, so you can debug
227 ReadLine applications.
228
229 =item * NonStop 
230
231 if true, no i/o is performed until interrupt.
232
233 =item * LineInfo 
234
235 file or pipe to print line number info to.  If it is a
236 pipe, a short "emacs like" message is used.
237
238 =item * RemotePort 
239
240 host:port to connect to on remote host for remote debugging.
241
242 =item * HistFile
243
244 file to store session history to. There is no default and so no
245 history file is written unless this variable is explicitly set.
246
247 =item * HistSize
248
249 number of commands to store to the file specified in C<HistFile>.
250 Default is 100.
251
252 =back
253
254 =head3 SAMPLE RCFILE
255
256  &parse_options("NonStop=1 LineInfo=db.out");
257   sub afterinit { $trace = 1; }
258
259 The script will run without human intervention, putting trace
260 information into C<db.out>.  (If you interrupt it, you had better
261 reset C<LineInfo> to something I<interactive>!)
262
263 =head1 INTERNALS DESCRIPTION
264
265 =head2 DEBUGGER INTERFACE VARIABLES
266
267 Perl supplies the values for C<%sub>.  It effectively inserts
268 a C<&DB::DB();> in front of each place that can have a
269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
271 {require 'perl5db.pl'}> before the first line.
272
273 After each C<require>d file is compiled, but before it is executed, a
274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
275 is the expanded name of the C<require>d file (as found via C<%INC>).
276
277 =head3 IMPORTANT INTERNAL VARIABLES
278
279 =head4 C<$CreateTTY>
280
281 Used to control when the debugger will attempt to acquire another TTY to be
282 used for input. 
283
284 =over   
285
286 =item * 1 -  on C<fork()>
287
288 =item * 2 - debugger is started inside debugger
289
290 =item * 4 -  on startup
291
292 =back
293
294 =head4 C<$doret>
295
296 The value -2 indicates that no return value should be printed.
297 Any other positive value causes C<DB::sub> to print return values.
298
299 =head4 C<$evalarg>
300
301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
302 contents of C<@_> when C<DB::eval> is called.
303
304 =head4 C<$frame>
305
306 Determines what messages (if any) will get printed when a subroutine (or eval)
307 is entered or exited. 
308
309 =over 4
310
311 =item * 0 -  No enter/exit messages
312
313 =item * 1 - Print I<entering> messages on subroutine entry
314
315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
316
317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
318
319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
320
321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
322
323 =back
324
325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
326 The debugger internally juggles the value of C<$frame> during execution to
327 protect external modules that the debugger uses from getting traced.
328
329 =head4 C<$level>
330
331 Tracks current debugger nesting level. Used to figure out how many 
332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger 
333 outputs a prompt. Also used to help determine if the program has finished
334 during command parsing.
335
336 =head4 C<$onetimeDump>
337
338 Controls what (if anything) C<DB::eval()> will print after evaluating an
339 expression.
340
341 =over 4
342
343 =item * C<undef> - don't print anything
344
345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
346
347 =item * C<methods> - print the methods callable on the first item returned
348
349 =back
350
351 =head4 C<$onetimeDumpDepth>
352
353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
354 dumping a structure. Numeric. If C<undef>, print all levels.
355
356 =head4 C<$signal>
357
358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
359 which is called before every statement, checks this and puts the user into
360 command mode if it finds C<$signal> set to a true value.
361
362 =head4 C<$single>
363
364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
365 each subroutine; popped again at the end of each subroutine.
366
367 =over 4 
368
369 =item * 0 - run continuously.
370
371 =item * 1 - single-step, go into subs. The C<s> command.
372
373 =item * 2 - single-step, don't go into subs. The C<n> command.
374
375 =item * 4 - print current sub depth (turned on to force this when C<too much
376 recursion> occurs.
377
378 =back
379
380 =head4 C<$trace>
381
382 Controls the output of trace information. 
383
384 =over 4
385
386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
387
388 =item * 2 - watch expressions are active
389
390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
391
392 =back
393
394 =head4 C<$slave_editor>
395
396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
397
398 =head4 C<@cmdfhs>
399
400 Stack of filehandles that C<DB::readline()> will read commands from.
401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
402
403 =head4 C<@dbline>
404
405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> , 
406 supplied by the Perl interpreter to the debugger. Contains the source.
407
408 =head4 C<@old_watch>
409
410 Previous values of watch expressions. First set when the expression is
411 entered; reset whenever the watch expression changes.
412
413 =head4 C<@saved>
414
415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
416 so that the debugger can substitute safe values while it's running, and
417 restore them when it returns control.
418
419 =head4 C<@stack>
420
421 Saves the current value of C<$single> on entry to a subroutine.
422 Manipulated by the C<c> command to turn off tracing in all subs above the
423 current one.
424
425 =head4 C<@to_watch>
426
427 The 'watch' expressions: to be evaluated before each line is executed.
428
429 =head4 C<@typeahead>
430
431 The typeahead buffer, used by C<DB::readline>.
432
433 =head4 C<%alias>
434
435 Command aliases. Stored as character strings to be substituted for a command
436 entered.
437
438 =head4 C<%break_on_load>
439
440 Keys are file names, values are 1 (break when this file is loaded) or undef
441 (don't break when it is loaded).
442
443 =head4 C<%dbline>
444
445 Keys are line numbers, values are C<condition\0action>. If used in numeric
446 context, values are 0 if not breakable, 1 if breakable, no matter what is
447 in the actual hash entry.
448
449 =head4 C<%had_breakpoints>
450
451 Keys are file names; values are bitfields:
452
453 =over 4 
454
455 =item * 1 - file has a breakpoint in it.
456
457 =item * 2 - file has an action in it.
458
459 =back
460
461 A zero or undefined value means this file has neither.
462
463 =head4 C<%option>
464
465 Stores the debugger options. These are character string values.
466
467 =head4 C<%postponed>
468
469 Saves breakpoints for code that hasn't been compiled yet.
470 Keys are subroutine names, values are:
471
472 =over 4
473
474 =item * C<compile> - break when this sub is compiled
475
476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
477
478 =back
479
480 =head4 C<%postponed_file>
481
482 This hash keeps track of breakpoints that need to be set for files that have
483 not yet been compiled. Keys are filenames; values are references to hashes.
484 Each of these hashes is keyed by line number, and its values are breakpoint
485 definitions (C<condition\0action>).
486
487 =head1 DEBUGGER INITIALIZATION
488
489 The debugger's initialization actually jumps all over the place inside this
490 package. This is because there are several BEGIN blocks (which of course 
491 execute immediately) spread through the code. Why is that? 
492
493 The debugger needs to be able to change some things and set some things up 
494 before the debugger code is compiled; most notably, the C<$deep> variable that
495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
496 debugger has to turn off warnings while the debugger code is compiled, but then
497 restore them to their original setting before the program being debugged begins
498 executing.
499
500 The first C<BEGIN> block simply turns off warnings by saving the current
501 setting of C<$^W> and then setting it to zero. The second one initializes
502 the debugger variables that are needed before the debugger begins executing.
503 The third one puts C<$^X> back to its former value. 
504
505 We'll detail the second C<BEGIN> block later; just remember that if you need
506 to initialize something before the debugger starts really executing, that's
507 where it has to go.
508
509 =cut
510
511 package DB;
512
513 BEGIN {eval 'use IO::Handle'};  # Needed for flush only? breaks under miniperl
514
515 # Debugger for Perl 5.00x; perl5db.pl patch level:
516 $VERSION = '1.33';
517
518 $header = "perl5db.pl version $VERSION";
519
520 =head1 DEBUGGER ROUTINES
521
522 =head2 C<DB::eval()>
523
524 This function replaces straight C<eval()> inside the debugger; it simplifies
525 the process of evaluating code in the user's context.
526
527 The code to be evaluated is passed via the package global variable 
528 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
529
530 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
531 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
532 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
533 user's current package, grabbed when C<DB::DB> got control.  This causes the
534 proper context to be used when the eval is actually done.  Afterward, we
535 restore C<$trace>, C<$single>, and C<$^D>.
536
537 Next we need to handle C<$@> without getting confused. We save C<$@> in a
538 local lexical, localize C<$saved[0]> (which is where C<save()> will put 
539 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>, 
540 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
541 considered sane by the debugger. If there was an C<eval()> error, we print 
542 it on the debugger's output. If C<$onetimedump> is defined, we call 
543 C<dumpit> if it's set to 'dump', or C<methods> if it's set to 
544 'methods'. Setting it to something else causes the debugger to do the eval 
545 but not print the result - handy if you want to do something else with it 
546 (the "watch expressions" code does this to get the value of the watch
547 expression but not show it unless it matters).
548
549 In any case, we then return the list of output from C<eval> to the caller, 
550 and unwinding restores the former version of C<$@> in C<@saved> as well 
551 (the localization of C<$saved[0]> goes away at the end of this scope).
552
553 =head3 Parameters and variables influencing execution of DB::eval()
554
555 C<DB::eval> isn't parameterized in the standard way; this is to keep the
556 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
557 The variables listed below influence C<DB::eval()>'s execution directly. 
558
559 =over 4
560
561 =item C<$evalarg> - the thing to actually be eval'ed
562
563 =item C<$trace> - Current state of execution tracing
564
565 =item C<$single> - Current state of single-stepping
566
567 =item C<$onetimeDump> - what is to be displayed after the evaluation 
568
569 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
570
571 =back
572
573 The following variables are altered by C<DB::eval()> during its execution. They
574 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>. 
575
576 =over 4
577
578 =item C<@res> - used to capture output from actual C<eval>.
579
580 =item C<$otrace> - saved value of C<$trace>.
581
582 =item C<$osingle> - saved value of C<$single>.      
583
584 =item C<$od> - saved value of C<$^D>.
585
586 =item C<$saved[0]> - saved value of C<$@>.
587
588 =item $\ - for output of C<$@> if there is an evaluation error.      
589
590 =back
591
592 =head3 The problem of lexicals
593
594 The context of C<DB::eval()> presents us with some problems. Obviously,
595 we want to be 'sandboxed' away from the debugger's internals when we do
596 the eval, but we need some way to control how punctuation variables and
597 debugger globals are used. 
598
599 We can't use local, because the code inside C<DB::eval> can see localized
600 variables; and we can't use C<my> either for the same reason. The code
601 in this routine compromises and uses C<my>.
602
603 After this routine is over, we don't have user code executing in the debugger's
604 context, so we can use C<my> freely.
605
606 =cut
607
608 ############################################## Begin lexical danger zone
609
610 # 'my' variables used here could leak into (that is, be visible in)
611 # the context that the code being evaluated is executing in. This means that
612 # the code could modify the debugger's variables.
613 #
614 # Fiddling with the debugger's context could be Bad. We insulate things as
615 # much as we can.
616
617 sub eval {
618
619     # 'my' would make it visible from user code
620     #    but so does local! --tchrist
621     # Remember: this localizes @DB::res, not @main::res.
622     local @res;
623     {
624
625         # Try to keep the user code from messing  with us. Save these so that
626         # even if the eval'ed code changes them, we can put them back again.
627         # Needed because the user could refer directly to the debugger's
628         # package globals (and any 'my' variables in this containing scope)
629         # inside the eval(), and we want to try to stay safe.
630         local $otrace  = $trace;
631         local $osingle = $single;
632         local $od      = $^D;
633
634         # Untaint the incoming eval() argument.
635         { ($evalarg) = $evalarg =~ /(.*)/s; }
636
637         # $usercontext built in DB::DB near the comment
638         # "set up the context for DB::eval ..."
639         # Evaluate and save any results.
640         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
641
642         # Restore those old values.
643         $trace  = $otrace;
644         $single = $osingle;
645         $^D     = $od;
646     }
647
648     # Save the current value of $@, and preserve it in the debugger's copy
649     # of the saved precious globals.
650     my $at = $@;
651
652     # Since we're only saving $@, we only have to localize the array element
653     # that it will be stored in.
654     local $saved[0];    # Preserve the old value of $@
655     eval { &DB::save };
656
657     # Now see whether we need to report an error back to the user.
658     if ($at) {
659         local $\ = '';
660         print $OUT $at;
661     }
662
663     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
664     # are package globals.
665     elsif ($onetimeDump) {
666         if ( $onetimeDump eq 'dump' ) {
667             local $option{dumpDepth} = $onetimedumpDepth
668               if defined $onetimedumpDepth;
669             dumpit( $OUT, \@res );
670         }
671         elsif ( $onetimeDump eq 'methods' ) {
672             methods( $res[0] );
673         }
674     } ## end elsif ($onetimeDump)
675     @res;
676 } ## end sub eval
677
678 ############################################## End lexical danger zone
679
680 # After this point it is safe to introduce lexicals.
681 # The code being debugged will be executing in its own context, and
682 # can't see the inside of the debugger.
683 #
684 # However, one should not overdo it: leave as much control from outside as
685 # possible. If you make something a lexical, it's not going to be addressable
686 # from outside the debugger even if you know its name.
687
688 # This file is automatically included if you do perl -d.
689 # It's probably not useful to include this yourself.
690 #
691 # Before venturing further into these twisty passages, it is
692 # wise to read the perldebguts man page or risk the ire of dragons.
693 #
694 # (It should be noted that perldebguts will tell you a lot about
695 # the underlying mechanics of how the debugger interfaces into the
696 # Perl interpreter, but not a lot about the debugger itself. The new
697 # comments in this code try to address this problem.)
698
699 # Note that no subroutine call is possible until &DB::sub is defined
700 # (for subroutines defined outside of the package DB). In fact the same is
701 # true if $deep is not defined.
702
703 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
704
705 # modified Perl debugger, to be run from Emacs in perldb-mode
706 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
707 # Johan Vromans -- upgrade to 4.0 pl 10
708 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
709
710 # (We have made efforts to  clarify the comments in the change log
711 # in other places; some of them may seem somewhat obscure as they
712 # were originally written, and explaining them away from the code
713 # in question seems conterproductive.. -JM)
714
715 ########################################################################
716 # Changes: 0.94
717 #   + A lot of things changed after 0.94. First of all, core now informs
718 #     debugger about entry into XSUBs, overloaded operators, tied operations,
719 #     BEGIN and END. Handy with `O f=2'.
720 #   + This can make debugger a little bit too verbose, please be patient
721 #     and report your problems promptly.
722 #   + Now the option frame has 3 values: 0,1,2. XXX Document!
723 #   + Note that if DESTROY returns a reference to the object (or object),
724 #     the deletion of data may be postponed until the next function call,
725 #     due to the need to examine the return value.
726 #
727 # Changes: 0.95
728 #   + `v' command shows versions.
729 #
730 # Changes: 0.96
731 #   + `v' command shows version of readline.
732 #     primitive completion works (dynamic variables, subs for `b' and `l',
733 #     options). Can `p %var'
734 #   + Better help (`h <' now works). New commands <<, >>, {, {{.
735 #     {dump|print}_trace() coded (to be able to do it from <<cmd).
736 #   + `c sub' documented.
737 #   + At last enough magic combined to stop after the end of debuggee.
738 #   + !! should work now (thanks to Emacs bracket matching an extra
739 #     `]' in a regexp is caught).
740 #   + `L', `D' and `A' span files now (as documented).
741 #   + Breakpoints in `require'd code are possible (used in `R').
742 #   +  Some additional words on internal work of debugger.
743 #   + `b load filename' implemented.
744 #   + `b postpone subr' implemented.
745 #   + now only `q' exits debugger (overwritable on $inhibit_exit).
746 #   + When restarting debugger breakpoints/actions persist.
747 #   + Buglet: When restarting debugger only one breakpoint/action per
748 #             autoloaded function persists.
749 #
750 # Changes: 0.97: NonStop will not stop in at_exit().
751 #   + Option AutoTrace implemented.
752 #   + Trace printed differently if frames are printed too.
753 #   + new `inhibitExit' option.
754 #   + printing of a very long statement interruptible.
755 # Changes: 0.98: New command `m' for printing possible methods
756 #   + 'l -' is a synonym for `-'.
757 #   + Cosmetic bugs in printing stack trace.
758 #   +  `frame' & 8 to print "expanded args" in stack trace.
759 #   + Can list/break in imported subs.
760 #   + new `maxTraceLen' option.
761 #   + frame & 4 and frame & 8 granted.
762 #   + new command `m'
763 #   + nonstoppable lines do not have `:' near the line number.
764 #   + `b compile subname' implemented.
765 #   + Will not use $` any more.
766 #   + `-' behaves sane now.
767 # Changes: 0.99: Completion for `f', `m'.
768 #   +  `m' will remove duplicate names instead of duplicate functions.
769 #   + `b load' strips trailing whitespace.
770 #     completion ignores leading `|'; takes into account current package
771 #     when completing a subroutine name (same for `l').
772 # Changes: 1.07: Many fixed by tchrist 13-March-2000
773 #   BUG FIXES:
774 #   + Added bare minimal security checks on perldb rc files, plus
775 #     comments on what else is needed.
776 #   + Fixed the ornaments that made "|h" completely unusable.
777 #     They are not used in print_help if they will hurt.  Strip pod
778 #     if we're paging to less.
779 #   + Fixed mis-formatting of help messages caused by ornaments
780 #     to restore Larry's original formatting.
781 #   + Fixed many other formatting errors.  The code is still suboptimal,
782 #     and needs a lot of work at restructuring.  It's also misindented
783 #     in many places.
784 #   + Fixed bug where trying to look at an option like your pager
785 #     shows "1".
786 #   + Fixed some $? processing.  Note: if you use csh or tcsh, you will
787 #     lose.  You should consider shell escapes not using their shell,
788 #     or else not caring about detailed status.  This should really be
789 #     unified into one place, too.
790 #   + Fixed bug where invisible trailing whitespace on commands hoses you,
791 #     tricking Perl into thinking you weren't calling a debugger command!
792 #   + Fixed bug where leading whitespace on commands hoses you.  (One
793 #     suggests a leading semicolon or any other irrelevant non-whitespace
794 #     to indicate literal Perl code.)
795 #   + Fixed bugs that ate warnings due to wrong selected handle.
796 #   + Fixed a precedence bug on signal stuff.
797 #   + Fixed some unseemly wording.
798 #   + Fixed bug in help command trying to call perl method code.
799 #   + Fixed to call dumpvar from exception handler.  SIGPIPE killed us.
800 #   ENHANCEMENTS:
801 #   + Added some comments.  This code is still nasty spaghetti.
802 #   + Added message if you clear your pre/post command stacks which was
803 #     very easy to do if you just typed a bare >, <, or {.  (A command
804 #     without an argument should *never* be a destructive action; this
805 #     API is fundamentally screwed up; likewise option setting, which
806 #     is equally buggered.)
807 #   + Added command stack dump on argument of "?" for >, <, or {.
808 #   + Added a semi-built-in doc viewer command that calls man with the
809 #     proper %Config::Config path (and thus gets caching, man -k, etc),
810 #     or else perldoc on obstreperous platforms.
811 #   + Added to and rearranged the help information.
812 #   + Detected apparent misuse of { ... } to declare a block; this used
813 #     to work but now is a command, and mysteriously gave no complaint.
814 #
815 # Changes: 1.08: Apr 25, 2001  Jon Eveland <jweveland@yahoo.com>
816 #   BUG FIX:
817 #   + This patch to perl5db.pl cleans up formatting issues on the help
818 #     summary (h h) screen in the debugger.  Mostly columnar alignment
819 #     issues, plus converted the printed text to use all spaces, since
820 #     tabs don't seem to help much here.
821 #
822 # Changes: 1.09: May 19, 2001  Ilya Zakharevich <ilya@math.ohio-state.edu>
823 #   Minor bugs corrected;
824 #   + Support for auto-creation of new TTY window on startup, either
825 #     unconditionally, or if started as a kid of another debugger session;
826 #   + New `O'ption CreateTTY
827 #       I<CreateTTY>      bits control attempts to create a new TTY on events:
828 #                         1: on fork()
829 #                         2: debugger is started inside debugger
830 #                         4: on startup
831 #   + Code to auto-create a new TTY window on OS/2 (currently one
832 #     extra window per session - need named pipes to have more...);
833 #   + Simplified interface for custom createTTY functions (with a backward
834 #     compatibility hack); now returns the TTY name to use; return of ''
835 #     means that the function reset the I/O handles itself;
836 #   + Better message on the semantic of custom createTTY function;
837 #   + Convert the existing code to create a TTY into a custom createTTY
838 #     function;
839 #   + Consistent support for TTY names of the form "TTYin,TTYout";
840 #   + Switch line-tracing output too to the created TTY window;
841 #   + make `b fork' DWIM with CORE::GLOBAL::fork;
842 #   + High-level debugger API cmd_*():
843 #      cmd_b_load($filenamepart)            # b load filenamepart
844 #      cmd_b_line($lineno [, $cond])        # b lineno [cond]
845 #      cmd_b_sub($sub [, $cond])            # b sub [cond]
846 #      cmd_stop()                           # Control-C
847 #      cmd_d($lineno)                       # d lineno (B)
848 #      The cmd_*() API returns FALSE on failure; in this case it outputs
849 #      the error message to the debugging output.
850 #   + Low-level debugger API
851 #      break_on_load($filename)             # b load filename
852 #      @files = report_break_on_load()      # List files with load-breakpoints
853 #      breakable_line_in_filename($name, $from [, $to])
854 #                                           # First breakable line in the
855 #                                           # range $from .. $to.  $to defaults
856 #                                           # to $from, and may be less than
857 #                                           # $to
858 #      breakable_line($from [, $to])        # Same for the current file
859 #      break_on_filename_line($name, $lineno [, $cond])
860 #                                           # Set breakpoint,$cond defaults to
861 #                                           # 1
862 #      break_on_filename_line_range($name, $from, $to [, $cond])
863 #                                           # As above, on the first
864 #                                           # breakable line in range
865 #      break_on_line($lineno [, $cond])     # As above, in the current file
866 #      break_subroutine($sub [, $cond])     # break on the first breakable line
867 #      ($name, $from, $to) = subroutine_filename_lines($sub)
868 #                                           # The range of lines of the text
869 #      The low-level API returns TRUE on success, and die()s on failure.
870 #
871 # Changes: 1.10: May 23, 2001  Daniel Lewart <d-lewart@uiuc.edu>
872 #   BUG FIXES:
873 #   + Fixed warnings generated by "perl -dWe 42"
874 #   + Corrected spelling errors
875 #   + Squeezed Help (h) output into 80 columns
876 #
877 # Changes: 1.11: May 24, 2001  David Dyck <dcd@tc.fluke.com>
878 #   + Made "x @INC" work like it used to
879 #
880 # Changes: 1.12: May 24, 2001  Daniel Lewart <d-lewart@uiuc.edu>
881 #   + Fixed warnings generated by "O" (Show debugger options)
882 #   + Fixed warnings generated by "p 42" (Print expression)
883 # Changes: 1.13: Jun 19, 2001 Scott.L.Miller@compaq.com
884 #   + Added windowSize option
885 # Changes: 1.14: Oct  9, 2001 multiple
886 #   + Clean up after itself on VMS (Charles Lane in 12385)
887 #   + Adding "@ file" syntax (Peter Scott in 12014)
888 #   + Debug reloading selfloaded stuff (Ilya Zakharevich in 11457)
889 #   + $^S and other debugger fixes (Ilya Zakharevich in 11120)
890 #   + Forgot a my() declaration (Ilya Zakharevich in 11085)
891 # Changes: 1.15: Nov  6, 2001 Michael G Schwern <schwern@pobox.com>
892 #   + Updated 1.14 change log
893 #   + Added *dbline explainatory comments
894 #   + Mentioning perldebguts man page
895 # Changes: 1.16: Feb 15, 2002 Mark-Jason Dominus <mjd@plover.com>
896 #   + $onetimeDump improvements
897 # Changes: 1.17: Feb 20, 2002 Richard Foley <richard.foley@rfi.net>
898 #   Moved some code to cmd_[.]()'s for clarity and ease of handling,
899 #   rationalised the following commands and added cmd_wrapper() to
900 #   enable switching between old and frighteningly consistent new
901 #   behaviours for diehards: 'o CommandSet=pre580' (sigh...)
902 #     a(add),       A(del)            # action expr   (added del by line)
903 #   + b(add),       B(del)            # break  [line] (was b,D)
904 #   + w(add),       W(del)            # watch  expr   (was W,W)
905 #                                     # added del by expr
906 #   + h(summary), h h(long)           # help (hh)     (was h h,h)
907 #   + m(methods),   M(modules)        # ...           (was m,v)
908 #   + o(option)                       # lc            (was O)
909 #   + v(view code), V(view Variables) # ...           (was w,V)
910 # Changes: 1.18: Mar 17, 2002 Richard Foley <richard.foley@rfi.net>
911 #   + fixed missing cmd_O bug
912 # Changes: 1.19: Mar 29, 2002 Spider Boardman
913 #   + Added missing local()s -- DB::DB is called recursively.
914 # Changes: 1.20: Feb 17, 2003 Richard Foley <richard.foley@rfi.net>
915 #   + pre'n'post commands no longer trashed with no args
916 #   + watch val joined out of eval()
917 # Changes: 1.21: Jun 04, 2003 Joe McMahon <mcmahon@ibiblio.org>
918 #   + Added comments and reformatted source. No bug fixes/enhancements.
919 #   + Includes cleanup by Robin Barker and Jarkko Hietaniemi.
920 # Changes: 1.22  Jun 09, 2003 Alex Vandiver <alexmv@MIT.EDU>
921 #   + Flush stdout/stderr before the debugger prompt is printed.
922 # Changes: 1.23: Dec 21, 2003 Dominique Quatravaux
923 #   + Fix a side-effect of bug #24674 in the perl debugger ("odd taint bug")
924 # Changes: 1.24: Mar 03, 2004 Richard Foley <richard.foley@rfi.net>
925 #   + Added command to save all debugger commands for sourcing later.
926 #   + Added command to display parent inheritance tree of given class.
927 #   + Fixed minor newline in history bug.
928 # Changes: 1.25: Apr 17, 2004 Richard Foley <richard.foley@rfi.net>
929 #   + Fixed option bug (setting invalid options + not recognising valid short forms)
930 # Changes: 1.26: Apr 22, 2004 Richard Foley <richard.foley@rfi.net>
931 #   + unfork the 5.8.x and 5.9.x debuggers.
932 #   + whitespace and assertions call cleanup across versions 
933 #   + H * deletes (resets) history
934 #   + i now handles Class + blessed objects
935 # Changes: 1.27: May 09, 2004 Richard Foley <richard.foley@rfi.net>
936 #   + updated pod page references - clunky.
937 #   + removed windowid restriction for forking into an xterm.
938 #   + more whitespace again.
939 #   + wrapped restart and enabled rerun [-n] (go back n steps) command.
940 # Changes: 1.28: Oct 12, 2004 Richard Foley <richard.foley@rfi.net>
941 #   + Added threads support (inc. e and E commands)
942 # Changes: 1.29: Nov 28, 2006 Bo Lindbergh <blgl@hagernas.com> 
943 #   + Added macosx_get_fork_TTY support 
944 # Changes: 1.30: Mar 06, 2007 Andreas Koenig <andk@cpan.org>
945 #   + Added HistFile, HistSize
946 # Changes: 1.31
947 #   + Remove support for assertions and -A
948 #   + stop NEXT::AUTOLOAD from emitting warnings under the debugger. RT #25053
949 #   + "update for Mac OS X 10.5" [finding the tty device]
950 #   + "What I needed to get the forked debugger to work" [on VMS]
951 #   + [perl #57016] debugger: o warn=0 die=0 ignored
952 #   + Note, but don't use, PERLDBf_SAVESRC
953 #   + Fix #7013: lvalue subs not working inside debugger
954 # Changes: 1.32: Jun 03, 2009 Jonathan Leto <jonathan@leto.net>
955 #   + Fix bug where a key _< with undefined value was put into the symbol table
956 #   +   when the $filename variable is not set
957 # Changes: x.xx: Josh ben Jore <jjore@cpan.org>
958 #   + TODO
959 ########################################################################
960
961 =head1 DEBUGGER INITIALIZATION
962
963 The debugger starts up in phases.
964
965 =head2 BASIC SETUP
966
967 First, it initializes the environment it wants to run in: turning off
968 warnings during its own compilation, defining variables which it will need
969 to avoid warnings later, setting itself up to not exit when the program
970 terminates, and defaulting to printing return values for the C<r> command.
971
972 =cut
973
974 # Needed for the statement after exec():
975 #
976 # This BEGIN block is simply used to switch off warnings during debugger
977 # compiliation. Probably it would be better practice to fix the warnings,
978 # but this is how it's done at the moment.
979
980 BEGIN {
981     $ini_warn = $^W;
982     $^W       = 0;
983 }    # Switch compilation warnings off until another BEGIN.
984
985 local ($^W) = 0;    # Switch run-time warnings off during init.
986
987 =head2 THREADS SUPPORT
988
989 If we are running under a threaded Perl, we require threads and threads::shared
990 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
991 threaded debugger control.  C<-dt> can also be used to set this.
992
993 Each new thread will be announced and the debugger prompt will always inform
994 you of each new thread created.  It will also indicate the thread id in which
995 we are currently running within the prompt like this:
996
997         [tid] DB<$i>
998
999 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
1000 command prompt.  The prompt will show: C<[0]> when running under threads, but
1001 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
1002
1003 While running under threads, when you set or delete a breakpoint (etc.), this
1004 will apply to all threads, not just the currently running one.  When you are 
1005 in a currently executing thread, you will stay there until it completes.  With
1006 the current implementation it is not currently possible to hop from one thread
1007 to another.
1008
1009 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
1010
1011 Note that threading support was built into the debugger as of Perl version
1012 C<5.8.6> and debugger version C<1.2.8>.
1013
1014 =cut
1015
1016 BEGIN {
1017   # ensure we can share our non-threaded variables or no-op
1018   if ($ENV{PERL5DB_THREADED}) {
1019         require threads;
1020         require threads::shared;
1021         import threads::shared qw(share);
1022         $DBGR;
1023         share(\$DBGR);
1024         lock($DBGR);
1025         print "Threads support enabled\n";
1026   } else {
1027         *lock  = sub(*) {};
1028         *share = sub(*) {};
1029   }
1030 }
1031
1032 # This would probably be better done with "use vars", but that wasn't around
1033 # when this code was originally written. (Neither was "use strict".) And on
1034 # the principle of not fiddling with something that was working, this was
1035 # left alone.
1036 warn(               # Do not ;-)
1037     # These variables control the execution of 'dumpvar.pl'.
1038     $dumpvar::hashDepth,
1039     $dumpvar::arrayDepth,
1040     $dumpvar::dumpDBFiles,
1041     $dumpvar::dumpPackages,
1042     $dumpvar::quoteHighBit,
1043     $dumpvar::printUndef,
1044     $dumpvar::globPrint,
1045     $dumpvar::usageOnly,
1046
1047     # used to save @ARGV and extract any debugger-related flags.
1048     @ARGS,
1049
1050     # used to control die() reporting in diesignal()
1051     $Carp::CarpLevel,
1052
1053     # used to prevent multiple entries to diesignal()
1054     # (if for instance diesignal() itself dies)
1055     $panic,
1056
1057     # used to prevent the debugger from running nonstop
1058     # after a restart
1059     $second_time,
1060   )
1061   if 0;
1062
1063 # without threads, $filename is not defined until DB::DB is called
1064 foreach my $k (keys (%INC)) {
1065         &share(\$main::{'_<'.$filename}) if defined $filename;
1066 };
1067
1068 # Command-line + PERLLIB:
1069 # Save the contents of @INC before they are modified elsewhere.
1070 @ini_INC = @INC;
1071
1072 # This was an attempt to clear out the previous values of various
1073 # trapped errors. Apparently it didn't help. XXX More info needed!
1074 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
1075
1076 # We set these variables to safe values. We don't want to blindly turn
1077 # off warnings, because other packages may still want them.
1078 $trace = $signal = $single = 0;    # Uninitialized warning suppression
1079                                    # (local $^W cannot help - other packages!).
1080
1081 # Default to not exiting when program finishes; print the return
1082 # value when the 'r' command is used to return from a subroutine.
1083 $inhibit_exit = $option{PrintRet} = 1;
1084
1085 =head1 OPTION PROCESSING
1086
1087 The debugger's options are actually spread out over the debugger itself and 
1088 C<dumpvar.pl>; some of these are variables to be set, while others are 
1089 subs to be called with a value. To try to make this a little easier to
1090 manage, the debugger uses a few data structures to define what options
1091 are legal and how they are to be processed.
1092
1093 First, the C<@options> array defines the I<names> of all the options that
1094 are to be accepted.
1095
1096 =cut
1097
1098 @options = qw(
1099   CommandSet   HistFile      HistSize
1100   hashDepth    arrayDepth    dumpDepth
1101   DumpDBFiles  DumpPackages  DumpReused
1102   compactDump  veryCompact   quote
1103   HighBit      undefPrint    globPrint
1104   PrintRet     UsageOnly     frame
1105   AutoTrace    TTY           noTTY
1106   ReadLine     NonStop       LineInfo
1107   maxTraceLen  recallCommand ShellBang
1108   pager        tkRunning     ornaments
1109   signalLevel  warnLevel     dieLevel
1110   inhibit_exit ImmediateStop bareStringify
1111   CreateTTY    RemotePort    windowSize
1112   DollarCaretP
1113 );
1114
1115 @RememberOnROptions = qw(DollarCaretP);
1116
1117 =pod
1118
1119 Second, C<optionVars> lists the variables that each option uses to save its
1120 state.
1121
1122 =cut
1123
1124 %optionVars = (
1125     hashDepth     => \$dumpvar::hashDepth,
1126     arrayDepth    => \$dumpvar::arrayDepth,
1127     CommandSet    => \$CommandSet,
1128     DumpDBFiles   => \$dumpvar::dumpDBFiles,
1129     DumpPackages  => \$dumpvar::dumpPackages,
1130     DumpReused    => \$dumpvar::dumpReused,
1131     HighBit       => \$dumpvar::quoteHighBit,
1132     undefPrint    => \$dumpvar::printUndef,
1133     globPrint     => \$dumpvar::globPrint,
1134     UsageOnly     => \$dumpvar::usageOnly,
1135     CreateTTY     => \$CreateTTY,
1136     bareStringify => \$dumpvar::bareStringify,
1137     frame         => \$frame,
1138     AutoTrace     => \$trace,
1139     inhibit_exit  => \$inhibit_exit,
1140     maxTraceLen   => \$maxtrace,
1141     ImmediateStop => \$ImmediateStop,
1142     RemotePort    => \$remoteport,
1143     windowSize    => \$window,
1144     HistFile      => \$histfile,
1145     HistSize      => \$histsize,
1146 );
1147
1148 =pod
1149
1150 Third, C<%optionAction> defines the subroutine to be called to process each
1151 option.
1152
1153 =cut 
1154
1155 %optionAction = (
1156     compactDump   => \&dumpvar::compactDump,
1157     veryCompact   => \&dumpvar::veryCompact,
1158     quote         => \&dumpvar::quote,
1159     TTY           => \&TTY,
1160     noTTY         => \&noTTY,
1161     ReadLine      => \&ReadLine,
1162     NonStop       => \&NonStop,
1163     LineInfo      => \&LineInfo,
1164     recallCommand => \&recallCommand,
1165     ShellBang     => \&shellBang,
1166     pager         => \&pager,
1167     signalLevel   => \&signalLevel,
1168     warnLevel     => \&warnLevel,
1169     dieLevel      => \&dieLevel,
1170     tkRunning     => \&tkRunning,
1171     ornaments     => \&ornaments,
1172     RemotePort    => \&RemotePort,
1173     DollarCaretP  => \&DollarCaretP,
1174 );
1175
1176 =pod
1177
1178 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1179 option is used.
1180
1181 =cut
1182
1183 # Note that this list is not complete: several options not listed here
1184 # actually require that dumpvar.pl be loaded for them to work, but are
1185 # not in the table. A subsequent patch will correct this problem; for
1186 # the moment, we're just recommenting, and we are NOT going to change
1187 # function.
1188 %optionRequire = (
1189     compactDump => 'dumpvar.pl',
1190     veryCompact => 'dumpvar.pl',
1191     quote       => 'dumpvar.pl',
1192 );
1193
1194 =pod
1195
1196 There are a number of initialization-related variables which can be set
1197 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1198 variable. These are:
1199
1200 =over 4
1201
1202 =item C<$rl> - readline control XXX needs more explanation
1203
1204 =item C<$warnLevel> - whether or not debugger takes over warning handling
1205
1206 =item C<$dieLevel> - whether or not debugger takes over die handling
1207
1208 =item C<$signalLevel> - whether or not debugger takes over signal handling
1209
1210 =item C<$pre> - preprompt actions (array reference)
1211
1212 =item C<$post> - postprompt actions (array reference)
1213
1214 =item C<$pretype>
1215
1216 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1217
1218 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1219
1220 =back
1221
1222 =cut
1223
1224 # These guys may be defined in $ENV{PERL5DB} :
1225 $rl          = 1     unless defined $rl;
1226 $warnLevel   = 1     unless defined $warnLevel;
1227 $dieLevel    = 1     unless defined $dieLevel;
1228 $signalLevel = 1     unless defined $signalLevel;
1229 $pre         = []    unless defined $pre;
1230 $post        = []    unless defined $post;
1231 $pretype     = []    unless defined $pretype;
1232 $CreateTTY   = 3     unless defined $CreateTTY;
1233 $CommandSet  = '580' unless defined $CommandSet;
1234
1235 share($rl);
1236 share($warnLevel);
1237 share($dieLevel);
1238 share($signalLevel);
1239 share($pre);
1240 share($post);
1241 share($pretype);
1242 share($rl);
1243 share($CreateTTY);
1244 share($CommandSet);
1245
1246 =pod
1247
1248 The default C<die>, C<warn>, and C<signal> handlers are set up.
1249
1250 =cut
1251
1252 warnLevel($warnLevel);
1253 dieLevel($dieLevel);
1254 signalLevel($signalLevel);
1255
1256 =pod
1257
1258 The pager to be used is needed next. We try to get it from the
1259 environment first.  If it's not defined there, we try to find it in
1260 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1261 then call the C<pager()> function to save the pager name.
1262
1263 =cut
1264
1265 # This routine makes sure $pager is set up so that '|' can use it.
1266 pager(
1267
1268     # If PAGER is defined in the environment, use it.
1269     defined $ENV{PAGER}
1270     ? $ENV{PAGER}
1271
1272       # If not, see if Config.pm defines it.
1273     : eval { require Config }
1274       && defined $Config::Config{pager}
1275     ? $Config::Config{pager}
1276
1277       # If not, fall back to 'more'.
1278     : 'more'
1279   )
1280   unless defined $pager;
1281
1282 =pod
1283
1284 We set up the command to be used to access the man pages, the command
1285 recall character (C<!> unless otherwise defined) and the shell escape
1286 character (C<!> unless otherwise defined). Yes, these do conflict, and
1287 neither works in the debugger at the moment.
1288
1289 =cut
1290
1291 setman();
1292
1293 # Set up defaults for command recall and shell escape (note:
1294 # these currently don't work in linemode debugging).
1295 &recallCommand("!") unless defined $prc;
1296 &shellBang("!")     unless defined $psh;
1297
1298 =pod
1299
1300 We then set up the gigantic string containing the debugger help.
1301 We also set the limit on the number of arguments we'll display during a
1302 trace.
1303
1304 =cut
1305
1306 sethelp();
1307
1308 # If we didn't get a default for the length of eval/stack trace args,
1309 # set it here.
1310 $maxtrace = 400 unless defined $maxtrace;
1311
1312 =head2 SETTING UP THE DEBUGGER GREETING
1313
1314 The debugger I<greeting> helps to inform the user how many debuggers are
1315 running, and whether the current debugger is the primary or a child.
1316
1317 If we are the primary, we just hang onto our pid so we'll have it when
1318 or if we start a child debugger. If we are a child, we'll set things up
1319 so we'll have a unique greeting and so the parent will give us our own
1320 TTY later.
1321
1322 We save the current contents of the C<PERLDB_PIDS> environment variable
1323 because we mess around with it. We'll also need to hang onto it because
1324 we'll need it if we restart.
1325
1326 Child debuggers make a label out of the current PID structure recorded in
1327 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1328 yet so the parent will give them one later via C<resetterm()>.
1329
1330 =cut
1331
1332 # Save the current contents of the environment; we're about to
1333 # much with it. We'll need this if we have to restart.
1334 $ini_pids = $ENV{PERLDB_PIDS};
1335
1336 if ( defined $ENV{PERLDB_PIDS} ) {
1337
1338     # We're a child. Make us a label out of the current PID structure
1339     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1340     # a term yet so the parent will give us one later via resetterm().
1341
1342     my $env_pids = $ENV{PERLDB_PIDS};
1343     $pids = "[$env_pids]";
1344
1345     # Unless we are on OpenVMS, all programs under the DCL shell run under
1346     # the same PID.
1347
1348     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1349         $term_pid         = $$;
1350     }
1351     else {
1352         $ENV{PERLDB_PIDS} .= "->$$";
1353         $term_pid = -1;
1354     }
1355
1356 } ## end if (defined $ENV{PERLDB_PIDS...
1357 else {
1358
1359     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1360     # child debugger, and mark us as the parent, so we'll know to set up
1361     # more TTY's is we have to.
1362     $ENV{PERLDB_PIDS} = "$$";
1363     $pids             = "[pid=$$]";
1364     $term_pid         = $$;
1365 }
1366
1367 $pidprompt = '';
1368
1369 # Sets up $emacs as a synonym for $slave_editor.
1370 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1371
1372 =head2 READING THE RC FILE
1373
1374 The debugger will read a file of initialization options if supplied. If    
1375 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1376
1377 =cut      
1378
1379 # As noted, this test really doesn't check accurately that the debugger
1380 # is running at a terminal or not.
1381
1382 my $dev_tty = '/dev/tty';
1383    $dev_tty = 'TT:' if ($^O eq 'VMS');
1384 if ( -e $dev_tty ) {                      # this is the wrong metric!
1385     $rcfile = ".perldb";
1386 }
1387 else {
1388     $rcfile = "perldb.ini";
1389 }
1390
1391 =pod
1392
1393 The debugger does a safety test of the file to be read. It must be owned
1394 either by the current user or root, and must only be writable by the owner.
1395
1396 =cut
1397
1398 # This wraps a safety test around "do" to read and evaluate the init file.
1399 #
1400 # This isn't really safe, because there's a race
1401 # between checking and opening.  The solution is to
1402 # open and fstat the handle, but then you have to read and
1403 # eval the contents.  But then the silly thing gets
1404 # your lexical scope, which is unfortunate at best.
1405 sub safe_do {
1406     my $file = shift;
1407
1408     # Just exactly what part of the word "CORE::" don't you understand?
1409     local $SIG{__WARN__};
1410     local $SIG{__DIE__};
1411
1412     unless ( is_safe_file($file) ) {
1413         CORE::warn <<EO_GRIPE;
1414 perldb: Must not source insecure rcfile $file.
1415         You or the superuser must be the owner, and it must not 
1416         be writable by anyone but its owner.
1417 EO_GRIPE
1418         return;
1419     } ## end unless (is_safe_file($file...
1420
1421     do $file;
1422     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1423 } ## end sub safe_do
1424
1425 # This is the safety test itself.
1426 #
1427 # Verifies that owner is either real user or superuser and that no
1428 # one but owner may write to it.  This function is of limited use
1429 # when called on a path instead of upon a handle, because there are
1430 # no guarantees that filename (by dirent) whose file (by ino) is
1431 # eventually accessed is the same as the one tested.
1432 # Assumes that the file's existence is not in doubt.
1433 sub is_safe_file {
1434     my $path = shift;
1435     stat($path) || return;    # mysteriously vaporized
1436     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1437
1438     return 0 if $uid != 0 && $uid != $<;
1439     return 0 if $mode & 022;
1440     return 1;
1441 } ## end sub is_safe_file
1442
1443 # If the rcfile (whichever one we decided was the right one to read)
1444 # exists, we safely do it.
1445 if ( -f $rcfile ) {
1446     safe_do("./$rcfile");
1447 }
1448
1449 # If there isn't one here, try the user's home directory.
1450 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1451     safe_do("$ENV{HOME}/$rcfile");
1452 }
1453
1454 # Else try the login directory.
1455 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1456     safe_do("$ENV{LOGDIR}/$rcfile");
1457 }
1458
1459 # If the PERLDB_OPTS variable has options in it, parse those out next.
1460 if ( defined $ENV{PERLDB_OPTS} ) {
1461     parse_options( $ENV{PERLDB_OPTS} );
1462 }
1463
1464 =pod
1465
1466 The last thing we do during initialization is determine which subroutine is
1467 to be used to obtain a new terminal when a new debugger is started. Right now,
1468 the debugger only handles TCP sockets, X Windows, OS/2, amd Mac OS X
1469 (darwin).
1470
1471 =cut
1472
1473 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1474 # Works if you're running an xterm or xterm-like window, or you're on
1475 # OS/2, or on Mac OS X. This may need some expansion.
1476
1477 if (not defined &get_fork_TTY)       # only if no routine exists
1478 {
1479     if ( defined $remoteport ) {                 
1480                                                  # Expect an inetd-like server
1481         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1482     }
1483     elsif (defined $ENV{TERM}                    # If we know what kind
1484                                                  # of terminal this is,
1485         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1486         and defined $ENV{DISPLAY}                # and what display it's on,
1487       )
1488     {
1489         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1490     }
1491     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1492         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1493     }
1494     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1495             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1496             and $ENV{TERM_PROGRAM}
1497                 eq 'Apple_Terminal'              # Terminal.app
1498             )
1499     {
1500         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1501     }
1502 } ## end if (not defined &get_fork_TTY...
1503
1504 # untaint $^O, which may have been tainted by the last statement.
1505 # see bug [perl #24674]
1506 $^O =~ m/^(.*)\z/;
1507 $^O = $1;
1508
1509 # Here begin the unreadable code.  It needs fixing.
1510
1511 =head2 RESTART PROCESSING
1512
1513 This section handles the restart command. When the C<R> command is invoked, it
1514 tries to capture all of the state it can into environment variables, and
1515 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1516 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1517 the R command stuffed into the environment variables.
1518
1519   PERLDB_RESTART   - flag only, contains no restart data itself.       
1520   PERLDB_HIST      - command history, if it's available
1521   PERLDB_ON_LOAD   - breakpoints set by the rc file
1522   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1523   PERLDB_VISITED   - files that had breakpoints
1524   PERLDB_FILE_...  - breakpoints for a file
1525   PERLDB_OPT       - active options
1526   PERLDB_INC       - the original @INC
1527   PERLDB_PRETYPE   - preprompt debugger actions
1528   PERLDB_PRE       - preprompt Perl code
1529   PERLDB_POST      - post-prompt Perl code
1530   PERLDB_TYPEAHEAD - typeahead captured by readline()
1531
1532 We chug through all these variables and plug the values saved in them
1533 back into the appropriate spots in the debugger.
1534
1535 =cut
1536
1537 if ( exists $ENV{PERLDB_RESTART} ) {
1538
1539     # We're restarting, so we don't need the flag that says to restart anymore.
1540     delete $ENV{PERLDB_RESTART};
1541
1542     # $restart = 1;
1543     @hist          = get_list('PERLDB_HIST');
1544     %break_on_load = get_list("PERLDB_ON_LOAD");
1545     %postponed     = get_list("PERLDB_POSTPONE");
1546
1547         share(@hist);
1548         share(@truehist);
1549         share(%break_on_load);
1550         share(%postponed);
1551
1552     # restore breakpoints/actions
1553     my @had_breakpoints = get_list("PERLDB_VISITED");
1554     for ( 0 .. $#had_breakpoints ) {
1555         my %pf = get_list("PERLDB_FILE_$_");
1556         $postponed_file{ $had_breakpoints[$_] } = \%pf if %pf;
1557     }
1558
1559     # restore options
1560     my %opt = get_list("PERLDB_OPT");
1561     my ( $opt, $val );
1562     while ( ( $opt, $val ) = each %opt ) {
1563         $val =~ s/[\\\']/\\$1/g;
1564         parse_options("$opt'$val'");
1565     }
1566
1567     # restore original @INC
1568     @INC     = get_list("PERLDB_INC");
1569     @ini_INC = @INC;
1570
1571     # return pre/postprompt actions and typeahead buffer
1572     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1573     $pre       = [ get_list("PERLDB_PRE") ];
1574     $post      = [ get_list("PERLDB_POST") ];
1575     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1576 } ## end if (exists $ENV{PERLDB_RESTART...
1577
1578 =head2 SETTING UP THE TERMINAL
1579
1580 Now, we'll decide how the debugger is going to interact with the user.
1581 If there's no TTY, we set the debugger to run non-stop; there's not going
1582 to be anyone there to enter commands.
1583
1584 =cut
1585
1586 if ($notty) {
1587     $runnonstop = 1;
1588         share($runnonstop);
1589 }
1590
1591 =pod
1592
1593 If there is a TTY, we have to determine who it belongs to before we can
1594 proceed. If this is a slave editor or graphical debugger (denoted by
1595 the first command-line switch being '-emacs'), we shift this off and
1596 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1597
1598 =cut
1599
1600 else {
1601
1602     # Is Perl being run from a slave editor or graphical debugger?
1603     # If so, don't use readline, and set $slave_editor = 1.
1604     $slave_editor =
1605       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1606     $rl = 0, shift(@main::ARGV) if $slave_editor;
1607
1608     #require Term::ReadLine;
1609
1610 =pod
1611
1612 We then determine what the console should be on various systems:
1613
1614 =over 4
1615
1616 =item * Cygwin - We use C<stdin> instead of a separate device.
1617
1618 =cut
1619
1620     if ( $^O eq 'cygwin' ) {
1621
1622         # /dev/tty is binary. use stdin for textmode
1623         undef $console;
1624     }
1625
1626 =item * Unix - use C</dev/tty>.
1627
1628 =cut
1629
1630     elsif ( -e "/dev/tty" ) {
1631         $console = "/dev/tty";
1632     }
1633
1634 =item * Windows or MSDOS - use C<con>.
1635
1636 =cut
1637
1638     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1639         $console = "con";
1640     }
1641
1642 =item * VMS - use C<sys$command>.
1643
1644 =cut
1645
1646     else {
1647
1648         # everything else is ...
1649         $console = "sys\$command";
1650     }
1651
1652 =pod
1653
1654 =back
1655
1656 Several other systems don't use a specific console. We C<undef $console>
1657 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1658 with a slave editor, Epoc).
1659
1660 =cut
1661
1662     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1663
1664         # /dev/tty is binary. use stdin for textmode
1665         $console = undef;
1666     }
1667
1668     if ( $^O eq 'NetWare' ) {
1669
1670         # /dev/tty is binary. use stdin for textmode
1671         $console = undef;
1672     }
1673
1674     # In OS/2, we need to use STDIN to get textmode too, even though
1675     # it pretty much looks like Unix otherwise.
1676     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1677     {    # In OS/2
1678         $console = undef;
1679     }
1680
1681     # EPOC also falls into the 'got to use STDIN' camp.
1682     if ( $^O eq 'epoc' ) {
1683         $console = undef;
1684     }
1685
1686 =pod
1687
1688 If there is a TTY hanging around from a parent, we use that as the console.
1689
1690 =cut
1691
1692     $console = $tty if defined $tty;
1693
1694 =head2 SOCKET HANDLING   
1695
1696 The debugger is capable of opening a socket and carrying out a debugging
1697 session over the socket.
1698
1699 If C<RemotePort> was defined in the options, the debugger assumes that it
1700 should try to start a debugging session on that port. It builds the socket
1701 and then tries to connect the input and output filehandles to it.
1702
1703 =cut
1704
1705     # Handle socket stuff.
1706
1707     if ( defined $remoteport ) {
1708
1709         # If RemotePort was defined in the options, connect input and output
1710         # to the socket.
1711         $IN = $OUT = connect_remoteport();
1712     } ## end if (defined $remoteport)
1713
1714 =pod
1715
1716 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1717 this is probably a situation where multiple debuggers are running (for example,
1718 a backticked command that starts up another debugger). We create a new IN and
1719 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1720 and if we can.
1721
1722 =cut
1723
1724     # Non-socket.
1725     else {
1726
1727         # Two debuggers running (probably a system or a backtick that invokes
1728         # the debugger itself under the running one). create a new IN and OUT
1729         # filehandle, and do the necessary mojo to create a new tty if we
1730         # know how, and we can.
1731         create_IN_OUT(4) if $CreateTTY & 4;
1732         if ($console) {
1733
1734             # If we have a console, check to see if there are separate ins and
1735             # outs to open. (They are assumed identical if not.)
1736
1737             my ( $i, $o ) = split /,/, $console;
1738             $o = $i unless defined $o;
1739
1740             # read/write on in, or just read, or read on STDIN.
1741             open( IN,      "+<$i" )
1742               || open( IN, "<$i" )
1743               || open( IN, "<&STDIN" );
1744
1745             # read/write/create/clobber out, or write/create/clobber out,
1746             # or merge with STDERR, or merge with STDOUT.
1747                  open( OUT, "+>$o" )
1748               || open( OUT, ">$o" )
1749               || open( OUT, ">&STDERR" )
1750               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1751
1752         } ## end if ($console)
1753         elsif ( not defined $console ) {
1754
1755             # No console. Open STDIN.
1756             open( IN, "<&STDIN" );
1757
1758             # merge with STDERR, or with STDOUT.
1759             open( OUT,      ">&STDERR" )
1760               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1761             $console = 'STDIN/OUT';
1762         } ## end elsif (not defined $console)
1763
1764         # Keep copies of the filehandles so that when the pager runs, it
1765         # can close standard input without clobbering ours.
1766         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1767     } ## end elsif (from if(defined $remoteport))
1768
1769     # Unbuffer DB::OUT. We need to see responses right away.
1770     my $previous = select($OUT);
1771     $| = 1;                                  # for DB::OUT
1772     select($previous);
1773
1774     # Line info goes to debugger output unless pointed elsewhere.
1775     # Pointing elsewhere makes it possible for slave editors to
1776     # keep track of file and position. We have both a filehandle
1777     # and a I/O description to keep track of.
1778     $LINEINFO = $OUT     unless defined $LINEINFO;
1779     $lineinfo = $console unless defined $lineinfo;
1780         # share($LINEINFO); # <- unable to share globs
1781         share($lineinfo);   # 
1782
1783 =pod
1784
1785 To finish initialization, we show the debugger greeting,
1786 and then call the C<afterinit()> subroutine if there is one.
1787
1788 =cut
1789
1790     # Show the debugger greeting.
1791     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1792     unless ($runnonstop) {
1793         local $\ = '';
1794         local $, = '';
1795         if ( $term_pid eq '-1' ) {
1796             print $OUT "\nDaughter DB session started...\n";
1797         }
1798         else {
1799             print $OUT "\nLoading DB routines from $header\n";
1800             print $OUT (
1801                 "Editor support ",
1802                 $slave_editor ? "enabled" : "available", ".\n"
1803             );
1804             print $OUT
1805 "\nEnter h or `h h' for help, or `$doccmd perldebug' for more help.\n\n";
1806         } ## end else [ if ($term_pid eq '-1')
1807     } ## end unless ($runnonstop)
1808 } ## end else [ if ($notty)
1809
1810 # XXX This looks like a bug to me.
1811 # Why copy to @ARGS and then futz with @args?
1812 @ARGS = @ARGV;
1813 for (@args) {
1814     # Make sure backslashes before single quotes are stripped out, and
1815     # keep args unless they are numeric (XXX why?)
1816     # s/\'/\\\'/g;                      # removed while not justified understandably
1817     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1818 }
1819
1820 # If there was an afterinit() sub defined, call it. It will get
1821 # executed in our scope, so it can fiddle with debugger globals.
1822 if ( defined &afterinit ) {    # May be defined in $rcfile
1823     &afterinit();
1824 }
1825
1826 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1827 $I_m_init = 1;
1828
1829 ############################################################ Subroutines
1830
1831 =head1 SUBROUTINES
1832
1833 =head2 DB
1834
1835 This gigantic subroutine is the heart of the debugger. Called before every
1836 statement, its job is to determine if a breakpoint has been reached, and
1837 stop if so; read commands from the user, parse them, and execute
1838 them, and then send execution off to the next statement.
1839
1840 Note that the order in which the commands are processed is very important;
1841 some commands earlier in the loop will actually alter the C<$cmd> variable
1842 to create other commands to be executed later. This is all highly I<optimized>
1843 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1844 see what's happening in any given command.
1845
1846 =cut
1847
1848 sub DB {
1849
1850     # lock the debugger and get the thread id for the prompt
1851         lock($DBGR);
1852         my $tid;
1853         if ($ENV{PERL5DB_THREADED}) {
1854                 $tid = eval { "[".threads->tid."]" };
1855         }
1856
1857     # Check for whether we should be running continuously or not.
1858     # _After_ the perl program is compiled, $single is set to 1:
1859     if ( $single and not $second_time++ ) {
1860
1861         # Options say run non-stop. Run until we get an interrupt.
1862         if ($runnonstop) {    # Disable until signal
1863                 # If there's any call stack in place, turn off single
1864                 # stepping into subs throughout the stack.
1865             for ( $i = 0 ; $i <= $stack_depth ; ) {
1866                 $stack[ $i++ ] &= ~1;
1867             }
1868
1869             # And we are now no longer in single-step mode.
1870             $single = 0;
1871
1872             # If we simply returned at this point, we wouldn't get
1873             # the trace info. Fall on through.
1874             # return;
1875         } ## end if ($runnonstop)
1876
1877         elsif ($ImmediateStop) {
1878
1879             # We are supposed to stop here; XXX probably a break.
1880             $ImmediateStop = 0;    # We've processed it; turn it off
1881             $signal        = 1;    # Simulate an interrupt to force
1882                                    # us into the command loop
1883         }
1884     } ## end if ($single and not $second_time...
1885
1886     # If we're in single-step mode, or an interrupt (real or fake)
1887     # has occurred, turn off non-stop mode.
1888     $runnonstop = 0 if $single or $signal;
1889
1890     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1891     # The code being debugged may have altered them.
1892     &save;
1893
1894     # Since DB::DB gets called after every line, we can use caller() to
1895     # figure out where we last were executing. Sneaky, eh? This works because
1896     # caller is returning all the extra information when called from the
1897     # debugger.
1898     local ( $package, $filename, $line ) = caller;
1899     local $filename_ini = $filename;
1900
1901     # set up the context for DB::eval, so it can properly execute
1902     # code on behalf of the user. We add the package in so that the
1903     # code is eval'ed in the proper package (not in the debugger!).
1904     local $usercontext =
1905       '($@, $!, $^E, $,, $/, $\, $^W) = @saved;' . "package $package;";
1906
1907     # Create an alias to the active file magical array to simplify
1908     # the code here.
1909     local (*dbline) = $main::{ '_<' . $filename };
1910
1911     # Last line in the program.
1912     local $max = $#dbline;
1913
1914     # if we have something here, see if we should break.
1915     if ( $dbline{$line}
1916         && ( ( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1917     {
1918
1919         # Stop if the stop criterion says to just stop.
1920         if ( $stop eq '1' ) {
1921             $signal |= 1;
1922         }
1923
1924         # It's a conditional stop; eval it in the user's context and
1925         # see if we should stop. If so, remove the one-time sigil.
1926         elsif ($stop) {
1927             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1928             &eval;
1929             $dbline{$line} =~ s/;9($|\0)/$1/;
1930         }
1931     } ## end if ($dbline{$line} && ...
1932
1933     # Preserve the current stop-or-not, and see if any of the W
1934     # (watch expressions) has changed.
1935     my $was_signal = $signal;
1936
1937     # If we have any watch expressions ...
1938     if ( $trace & 2 ) {
1939         for ( my $n = 0 ; $n <= $#to_watch ; $n++ ) {
1940             $evalarg = $to_watch[$n];
1941             local $onetimeDump;    # Tell DB::eval() to not output results
1942
1943             # Fix context DB::eval() wants to return an array, but
1944             # we need a scalar here.
1945             my ($val) = join( "', '", &eval );
1946             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1947
1948             # Did it change?
1949             if ( $val ne $old_watch[$n] ) {
1950
1951                 # Yep! Show the difference, and fake an interrupt.
1952                 $signal = 1;
1953                 print $OUT <<EOP;
1954 Watchpoint $n:\t$to_watch[$n] changed:
1955     old value:\t$old_watch[$n]
1956     new value:\t$val
1957 EOP
1958                 $old_watch[$n] = $val;
1959             } ## end if ($val ne $old_watch...
1960         } ## end for (my $n = 0 ; $n <= ...
1961     } ## end if ($trace & 2)
1962
1963 =head2 C<watchfunction()>
1964
1965 C<watchfunction()> is a function that can be defined by the user; it is a
1966 function which will be run on each entry to C<DB::DB>; it gets the 
1967 current package, filename, and line as its parameters.
1968
1969 The watchfunction can do anything it likes; it is executing in the 
1970 debugger's context, so it has access to all of the debugger's internal
1971 data structures and functions.
1972
1973 C<watchfunction()> can control the debugger's actions. Any of the following
1974 will cause the debugger to return control to the user's program after
1975 C<watchfunction()> executes:
1976
1977 =over 4 
1978
1979 =item *
1980
1981 Returning a false value from the C<watchfunction()> itself.
1982
1983 =item *
1984
1985 Altering C<$single> to a false value.
1986
1987 =item *
1988
1989 Altering C<$signal> to a false value.
1990
1991 =item *
1992
1993 Turning off the C<4> bit in C<$trace> (this also disables the
1994 check for C<watchfunction()>. This can be done with
1995
1996     $trace &= ~4;
1997
1998 =back
1999
2000 =cut
2001
2002     # If there's a user-defined DB::watchfunction, call it with the
2003     # current package, filename, and line. The function executes in
2004     # the DB:: package.
2005     if ( $trace & 4 ) {    # User-installed watch
2006         return
2007           if watchfunction( $package, $filename, $line )
2008           and not $single
2009           and not $was_signal
2010           and not( $trace & ~4 );
2011     } ## end if ($trace & 4)
2012
2013     # Pick up any alteration to $signal in the watchfunction, and
2014     # turn off the signal now.
2015     $was_signal = $signal;
2016     $signal     = 0;
2017
2018 =head2 GETTING READY TO EXECUTE COMMANDS
2019
2020 The debugger decides to take control if single-step mode is on, the
2021 C<t> command was entered, or the user generated a signal. If the program
2022 has fallen off the end, we set things up so that entering further commands
2023 won't cause trouble, and we say that the program is over.
2024
2025 =cut
2026
2027     # Check to see if we should grab control ($single true,
2028     # trace set appropriately, or we got a signal).
2029     if ( $single || ( $trace & 1 ) || $was_signal ) {
2030
2031         # Yes, grab control.
2032         if ($slave_editor) {
2033
2034             # Tell the editor to update its position.
2035             $position = "\032\032$filename:$line:0\n";
2036             print_lineinfo($position);
2037         }
2038
2039 =pod
2040
2041 Special check: if we're in package C<DB::fake>, we've gone through the 
2042 C<END> block at least once. We set up everything so that we can continue
2043 to enter commands and have a valid context to be in.
2044
2045 =cut
2046
2047         elsif ( $package eq 'DB::fake' ) {
2048
2049             # Fallen off the end already.
2050             $term || &setterm;
2051             print_help(<<EOP);
2052 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
2053   use B<o> I<inhibit_exit> to avoid stopping after program termination,
2054   B<h q>, B<h R> or B<h o> to get additional info.  
2055 EOP
2056
2057             # Set the DB::eval context appropriately.
2058             $package     = 'main';
2059             $usercontext =
2060                 '($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
2061               . "package $package;";    # this won't let them modify, alas
2062         } ## end elsif ($package eq 'DB::fake')
2063
2064 =pod
2065
2066 If the program hasn't finished executing, we scan forward to the
2067 next executable line, print that out, build the prompt from the file and line
2068 number information, and print that.   
2069
2070 =cut
2071
2072         else {
2073
2074             # Still somewhere in the midst of execution. Set up the
2075             #  debugger prompt.
2076             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
2077                                  # Perl 5 ones (sorry, we don't print Klingon
2078                                  #module names)
2079
2080             $prefix = $sub =~ /::/ ? "" : "${'package'}::";
2081             $prefix .= "$sub($filename:";
2082             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
2083
2084             # Break up the prompt if it's really long.
2085             if ( length($prefix) > 30 ) {
2086                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
2087                 $prefix   = "";
2088                 $infix    = ":\t";
2089             }
2090             else {
2091                 $infix    = "):\t";
2092                 $position = "$prefix$line$infix$dbline[$line]$after";
2093             }
2094
2095             # Print current line info, indenting if necessary.
2096             if ($frame) {
2097                 print_lineinfo( ' ' x $stack_depth,
2098                     "$line:\t$dbline[$line]$after" );
2099             }
2100             else {
2101                 print_lineinfo($position);
2102             }
2103
2104             # Scan forward, stopping at either the end or the next
2105             # unbreakable line.
2106             for ( $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
2107             {    #{ vi
2108
2109                 # Drop out on null statements, block closers, and comments.
2110                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
2111
2112                 # Drop out if the user interrupted us.
2113                 last if $signal;
2114
2115                 # Append a newline if the line doesn't have one. Can happen
2116                 # in eval'ed text, for instance.
2117                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
2118
2119                 # Next executable line.
2120                 $incr_pos = "$prefix$i$infix$dbline[$i]$after";
2121                 $position .= $incr_pos;
2122                 if ($frame) {
2123
2124                     # Print it indented if tracing is on.
2125                     print_lineinfo( ' ' x $stack_depth,
2126                         "$i:\t$dbline[$i]$after" );
2127                 }
2128                 else {
2129                     print_lineinfo($incr_pos);
2130                 }
2131             } ## end for ($i = $line + 1 ; $i...
2132         } ## end else [ if ($slave_editor)
2133     } ## end if ($single || ($trace...
2134
2135 =pod
2136
2137 If there's an action to be executed for the line we stopped at, execute it.
2138 If there are any preprompt actions, execute those as well.      
2139
2140 =cut
2141
2142     # If there's an action, do it now.
2143     $evalarg = $action, &eval if $action;
2144
2145     # Are we nested another level (e.g., did we evaluate a function
2146     # that had a breakpoint in it at the debugger prompt)?
2147     if ( $single || $was_signal ) {
2148
2149         # Yes, go down a level.
2150         local $level = $level + 1;
2151
2152         # Do any pre-prompt actions.
2153         foreach $evalarg (@$pre) {
2154             &eval;
2155         }
2156
2157         # Complain about too much recursion if we passed the limit.
2158         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
2159           if $single & 4;
2160
2161         # The line we're currently on. Set $incr to -1 to stay here
2162         # until we get a command that tells us to advance.
2163         $start = $line;
2164         $incr  = -1;      # for backward motion.
2165
2166         # Tack preprompt debugger actions ahead of any actual input.
2167         @typeahead = ( @$pretype, @typeahead );
2168
2169 =head2 WHERE ARE WE?
2170
2171 XXX Relocate this section?
2172
2173 The debugger normally shows the line corresponding to the current line of
2174 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2175 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2176
2177 C<$incr> controls by how many lines the I<current> line should move forward
2178 after a command is executed. If set to -1, this indicates that the I<current>
2179 line shouldn't change.
2180
2181 C<$start> is the I<current> line. It is used for things like knowing where to
2182 move forwards or backwards from when doing an C<L> or C<-> command.
2183
2184 C<$max> tells the debugger where the last line of the current file is. It's
2185 used to terminate loops most often.
2186
2187 =head2 THE COMMAND LOOP
2188
2189 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2190 in two parts:
2191
2192 =over 4
2193
2194 =item *
2195
2196 The outer part of the loop, starting at the C<CMD> label. This loop
2197 reads a command and then executes it.
2198
2199 =item *
2200
2201 The inner part of the loop, starting at the C<PIPE> label. This part
2202 is wholly contained inside the C<CMD> block and only executes a command.
2203 Used to handle commands running inside a pager.
2204
2205 =back
2206
2207 So why have two labels to restart the loop? Because sometimes, it's easier to
2208 have a command I<generate> another command and then re-execute the loop to do
2209 the new command. This is faster, but perhaps a bit more convoluted.
2210
2211 =cut
2212
2213         # The big command dispatch loop. It keeps running until the
2214         # user yields up control again.
2215         #
2216         # If we have a terminal for input, and we get something back
2217         # from readline(), keep on processing.
2218       CMD:
2219         while (
2220
2221             # We have a terminal, or can get one ...
2222             ( $term || &setterm ),
2223
2224             # ... and it belogs to this PID or we get one for this PID ...
2225             ( $term_pid == $$ or resetterm(1) ),
2226
2227             # ... and we got a line of command input ...
2228             defined(
2229                 $cmd = &readline(
2230                         "$pidprompt $tid DB"
2231                       . ( '<' x $level )
2232                       . ( $#hist + 1 )
2233                       . ( '>' x $level ) . " "
2234                 )
2235             )
2236           )
2237         {
2238
2239                         share($cmd);
2240             # ... try to execute the input as debugger commands.
2241
2242             # Don't stop running.
2243             $single = 0;
2244
2245             # No signal is active.
2246             $signal = 0;
2247
2248             # Handle continued commands (ending with \):
2249             $cmd =~ s/\\$/\n/ && do {
2250                 $cmd .= &readline("  cont: ");
2251                 redo CMD;
2252             };
2253
2254 =head4 The null command
2255
2256 A newline entered by itself means I<re-execute the last command>. We grab the
2257 command out of C<$laststep> (where it was recorded previously), and copy it
2258 back into C<$cmd> to be executed below. If there wasn't any previous command,
2259 we'll do nothing below (no command will match). If there was, we also save it
2260 in the command history and fall through to allow the command parsing to pick
2261 it up.
2262
2263 =cut
2264
2265             # Empty input means repeat the last command.
2266             $cmd =~ /^$/ && ( $cmd = $laststep );
2267             chomp($cmd);    # get rid of the annoying extra newline
2268             push( @hist, $cmd ) if length($cmd) > 1;
2269             push( @truehist, $cmd );
2270                         share(@hist);
2271                         share(@truehist);
2272
2273             # This is a restart point for commands that didn't arrive
2274             # via direct user input. It allows us to 'redo PIPE' to
2275             # re-execute command processing without reading a new command.
2276           PIPE: {
2277                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2278                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2279                 ($i) = split( /\s+/, $cmd );
2280
2281 =head3 COMMAND ALIASES
2282
2283 The debugger can create aliases for commands (these are stored in the
2284 C<%alias> hash). Before a command is executed, the command loop looks it up
2285 in the alias hash and substitutes the contents of the alias for the command,
2286 completely replacing it.
2287
2288 =cut
2289
2290                 # See if there's an alias for the command, and set it up if so.
2291                 if ( $alias{$i} ) {
2292
2293                     # Squelch signal handling; we want to keep control here
2294                     # if something goes loco during the alias eval.
2295                     local $SIG{__DIE__};
2296                     local $SIG{__WARN__};
2297
2298                     # This is a command, so we eval it in the DEBUGGER's
2299                     # scope! Otherwise, we can't see the special debugger
2300                     # variables, or get to the debugger's subs. (Well, we
2301                     # _could_, but why make it even more complicated?)
2302                     eval "\$cmd =~ $alias{$i}";
2303                     if ($@) {
2304                         local $\ = '';
2305                         print $OUT "Couldn't evaluate `$i' alias: $@";
2306                         next CMD;
2307                     }
2308                 } ## end if ($alias{$i})
2309
2310 =head3 MAIN-LINE COMMANDS
2311
2312 All of these commands work up to and after the program being debugged has
2313 terminated. 
2314
2315 =head4 C<q> - quit
2316
2317 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't 
2318 try to execute further, cleaning any restart-related stuff out of the
2319 environment, and executing with the last value of C<$?>.
2320
2321 =cut
2322
2323                 $cmd =~ /^q$/ && do {
2324                     $fall_off_end = 1;
2325                     clean_ENV();
2326                     exit $?;
2327                 };
2328
2329 =head4 C<t> - trace
2330
2331 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2332
2333 =cut
2334
2335                 $cmd =~ /^t$/ && do {
2336                     $trace ^= 1;
2337                     local $\ = '';
2338                     print $OUT "Trace = "
2339                       . ( ( $trace & 1 ) ? "on" : "off" ) . "\n";
2340                     next CMD;
2341                 };
2342
2343 =head4 C<S> - list subroutines matching/not matching a pattern
2344
2345 Walks through C<%sub>, checking to see whether or not to print the name.
2346
2347 =cut
2348
2349                 $cmd =~ /^S(\s+(!)?(.+))?$/ && do {
2350
2351                     $Srev     = defined $2;     # Reverse scan?
2352                     $Spatt    = $3;             # The pattern (if any) to use.
2353                     $Snocheck = !defined $1;    # No args - print all subs.
2354
2355                     # Need to make these sane here.
2356                     local $\ = '';
2357                     local $, = '';
2358
2359                     # Search through the debugger's magical hash of subs.
2360                     # If $nocheck is true, just print the sub name.
2361                     # Otherwise, check it against the pattern. We then use
2362                     # the XOR trick to reverse the condition as required.
2363                     foreach $subname ( sort( keys %sub ) ) {
2364                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2365                             print $OUT $subname, "\n";
2366                         }
2367                     }
2368                     next CMD;
2369                 };
2370
2371 =head4 C<X> - list variables in current package
2372
2373 Since the C<V> command actually processes this, just change this to the 
2374 appropriate C<V> command and fall through.
2375
2376 =cut
2377
2378                 $cmd =~ s/^X\b/V $package/;
2379
2380 =head4 C<V> - list variables
2381
2382 Uses C<dumpvar.pl> to dump out the current values for selected variables. 
2383
2384 =cut
2385
2386                 # Bare V commands get the currently-being-debugged package
2387                 # added.
2388                 $cmd =~ /^V$/ && do {
2389                     $cmd = "V $package";
2390                 };
2391
2392                 # V - show variables in package.
2393                 $cmd =~ /^V\b\s*(\S+)\s*(.*)/ && do {
2394
2395                     # Save the currently selected filehandle and
2396                     # force output to debugger's filehandle (dumpvar
2397                     # just does "print" for output).
2398                     local ($savout) = select($OUT);
2399
2400                     # Grab package name and variables to dump.
2401                     $packname = $1;
2402                     @vars     = split( ' ', $2 );
2403
2404                     # If main::dumpvar isn't here, get it.
2405                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2406                     if ( defined &main::dumpvar ) {
2407
2408                         # We got it. Turn off subroutine entry/exit messages
2409                         # for the moment, along with return values.
2410                         local $frame = 0;
2411                         local $doret = -2;
2412
2413                         # must detect sigpipe failures  - not catching
2414                         # then will cause the debugger to die.
2415                         eval {
2416                             &main::dumpvar(
2417                                 $packname,
2418                                 defined $option{dumpDepth}
2419                                 ? $option{dumpDepth}
2420                                 : -1,    # assume -1 unless specified
2421                                 @vars
2422                             );
2423                         };
2424
2425                         # The die doesn't need to include the $@, because
2426                         # it will automatically get propagated for us.
2427                         if ($@) {
2428                             die unless $@ =~ /dumpvar print failed/;
2429                         }
2430                     } ## end if (defined &main::dumpvar)
2431                     else {
2432
2433                         # Couldn't load dumpvar.
2434                         print $OUT "dumpvar.pl not available.\n";
2435                     }
2436
2437                     # Restore the output filehandle, and go round again.
2438                     select($savout);
2439                     next CMD;
2440                 };
2441
2442 =head4 C<x> - evaluate and print an expression
2443
2444 Hands the expression off to C<DB::eval>, setting it up to print the value
2445 via C<dumpvar.pl> instead of just printing it directly.
2446
2447 =cut
2448
2449                 $cmd =~ s/^x\b/ / && do {    # Remainder gets done by DB::eval()
2450                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2451
2452                     # handle special  "x 3 blah" syntax XXX propagate
2453                     # doc back to special variables.
2454                     if ( $cmd =~ s/^\s*(\d+)(?=\s)/ / ) {
2455                         $onetimedumpDepth = $1;
2456                     }
2457                 };
2458
2459 =head4 C<m> - print methods
2460
2461 Just uses C<DB::methods> to determine what methods are available.
2462
2463 =cut
2464
2465                 $cmd =~ s/^m\s+([\w:]+)\s*$/ / && do {
2466                     methods($1);
2467                     next CMD;
2468                 };
2469
2470                 # m expr - set up DB::eval to do the work
2471                 $cmd =~ s/^m\b/ / && do {    # Rest gets done by DB::eval()
2472                     $onetimeDump = 'methods';   #  method output gets used there
2473                 };
2474
2475 =head4 C<f> - switch files
2476
2477 =cut
2478
2479                 $cmd =~ /^f\b\s*(.*)/ && do {
2480                     $file = $1;
2481                     $file =~ s/\s+$//;
2482
2483                     # help for no arguments (old-style was return from sub).
2484                     if ( !$file ) {
2485                         print $OUT
2486                           "The old f command is now the r command.\n";    # hint
2487                         print $OUT "The new f command switches filenames.\n";
2488                         next CMD;
2489                     } ## end if (!$file)
2490
2491                     # if not in magic file list, try a close match.
2492                     if ( !defined $main::{ '_<' . $file } ) {
2493                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2494                             {
2495                                 $try = substr( $try, 2 );
2496                                 print $OUT "Choosing $try matching `$file':\n";
2497                                 $file = $try;
2498                             }
2499                         } ## end if (($try) = grep(m#^_<.*$file#...
2500                     } ## end if (!defined $main::{ ...
2501
2502                     # If not successfully switched now, we failed.
2503                     if ( !defined $main::{ '_<' . $file } ) {
2504                         print $OUT "No file matching `$file' is loaded.\n";
2505                         next CMD;
2506                     }
2507
2508                     # We switched, so switch the debugger internals around.
2509                     elsif ( $file ne $filename ) {
2510                         *dbline   = $main::{ '_<' . $file };
2511                         $max      = $#dbline;
2512                         $filename = $file;
2513                         $start    = 1;
2514                         $cmd      = "l";
2515                     } ## end elsif ($file ne $filename)
2516
2517                     # We didn't switch; say we didn't.
2518                     else {
2519                         print $OUT "Already in $file.\n";
2520                         next CMD;
2521                     }
2522                 };
2523
2524 =head4 C<.> - return to last-executed line.
2525
2526 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2527 and then we look up the line in the magical C<%dbline> hash.
2528
2529 =cut
2530
2531                 # . command.
2532                 $cmd =~ /^\.$/ && do {
2533                     $incr = -1;    # stay at current line
2534
2535                     # Reset everything to the old location.
2536                     $start    = $line;
2537                     $filename = $filename_ini;
2538                     *dbline   = $main::{ '_<' . $filename };
2539                     $max      = $#dbline;
2540
2541                     # Now where are we?
2542                     print_lineinfo($position);
2543                     next CMD;
2544                 };
2545
2546 =head4 C<-> - back one window
2547
2548 We change C<$start> to be one window back; if we go back past the first line,
2549 we set it to be the first line. We ser C<$incr> to put us back at the
2550 currently-executing line, and then put a C<l $start +> (list one window from
2551 C<$start>) in C<$cmd> to be executed later.
2552
2553 =cut
2554
2555                 # - - back a window.
2556                 $cmd =~ /^-$/ && do {
2557
2558                     # back up by a window; go to 1 if back too far.
2559                     $start -= $incr + $window + 1;
2560                     $start = 1 if $start <= 0;
2561                     $incr  = $window - 1;
2562
2563                     # Generate and execute a "l +" command (handled below).
2564                     $cmd = 'l ' . ($start) . '+';
2565                 };
2566
2567 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2568
2569 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2570 problems, most notably that the default case of several commands destroying
2571 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2572 retain the old commands for those who were used to using them or who preferred
2573 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2574 deal with them instead of processing them in-line.
2575
2576 =cut
2577
2578                 # All of these commands were remapped in perl 5.8.0;
2579                 # we send them off to the secondary dispatcher (see below).
2580                 $cmd =~ /^([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so && do {
2581                     &cmd_wrapper( $1, $2, $line );
2582                     next CMD;
2583                 };
2584
2585 =head4 C<y> - List lexicals in higher scope
2586
2587 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope    
2588 above the current one and then displays then using C<dumpvar.pl>.
2589
2590 =cut
2591
2592                 $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/ && do {
2593
2594                     # See if we've got the necessary support.
2595                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2596                       or &warn(
2597                         $@ =~ /locate/
2598                         ? "PadWalker module not found - please install\n"
2599                         : $@
2600                       )
2601                       and next CMD;
2602
2603                     # Load up dumpvar if we don't have it. If we can, that is.
2604                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2605                     defined &main::dumpvar
2606                       or print $OUT "dumpvar.pl not available.\n"
2607                       and next CMD;
2608
2609                     # Got all the modules we need. Find them and print them.
2610                     my @vars = split( ' ', $2 || '' );
2611
2612                     # Find the pad.
2613                     my $h = eval { PadWalker::peek_my( ( $1 || 0 ) + 1 ) };
2614
2615                     # Oops. Can't find it.
2616                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2617
2618                     # Show the desired vars with dumplex().
2619                     my $savout = select($OUT);
2620
2621                     # Have dumplex dump the lexicals.
2622                     dumpvar::dumplex( $_, $h->{$_},
2623                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2624                         @vars )
2625                       for sort keys %$h;
2626                     select($savout);
2627                     next CMD;
2628                 };
2629
2630 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2631
2632 All of the commands below this point don't work after the program being
2633 debugged has ended. All of them check to see if the program has ended; this
2634 allows the commands to be relocated without worrying about a 'line of
2635 demarcation' above which commands can be entered anytime, and below which
2636 they can't.
2637
2638 =head4 C<n> - single step, but don't trace down into subs
2639
2640 Done by setting C<$single> to 2, which forces subs to execute straight through
2641 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2642 so a null command knows what to re-execute. 
2643
2644 =cut
2645
2646                 # n - next
2647                 $cmd =~ /^n$/ && do {
2648                     end_report(), next CMD if $finished and $level <= 1;
2649
2650                     # Single step, but don't enter subs.
2651                     $single = 2;
2652
2653                     # Save for empty command (repeat last).
2654                     $laststep = $cmd;
2655                     last CMD;
2656                 };
2657
2658 =head4 C<s> - single-step, entering subs
2659
2660 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside     
2661 subs. Also saves C<s> as C<$lastcmd>.
2662
2663 =cut
2664
2665                 # s - single step.
2666                 $cmd =~ /^s$/ && do {
2667
2668                     # Get out and restart the command loop if program
2669                     # has finished.
2670                     end_report(), next CMD if $finished and $level <= 1;
2671
2672                     # Single step should enter subs.
2673                     $single = 1;
2674
2675                     # Save for empty command (repeat last).
2676                     $laststep = $cmd;
2677                     last CMD;
2678                 };
2679
2680 =head4 C<c> - run continuously, setting an optional breakpoint
2681
2682 Most of the code for this command is taken up with locating the optional
2683 breakpoint, which is either a subroutine name or a line number. We set
2684 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2685 in this and all call levels above this one.
2686
2687 =cut
2688
2689                 # c - start continuous execution.
2690                 $cmd =~ /^c\b\s*([\w:]*)\s*$/ && do {
2691
2692                     # Hey, show's over. The debugged program finished
2693                     # executing already.
2694                     end_report(), next CMD if $finished and $level <= 1;
2695
2696                     # Capture the place to put a one-time break.
2697                     $subname = $i = $1;
2698
2699                     #  Probably not needed, since we finish an interactive
2700                     #  sub-session anyway...
2701                     # local $filename = $filename;
2702                     # local *dbline = *dbline; # XXX Would this work?!
2703                     #
2704                     # The above question wonders if localizing the alias
2705                     # to the magic array works or not. Since it's commented
2706                     # out, we'll just leave that to speculation for now.
2707
2708                     # If the "subname" isn't all digits, we'll assume it
2709                     # is a subroutine name, and try to find it.
2710                     if ( $subname =~ /\D/ ) {    # subroutine name
2711                             # Qualify it to the current package unless it's
2712                             # already qualified.
2713                         $subname = $package . "::" . $subname
2714                           unless $subname =~ /::/;
2715
2716                         # find_sub will return "file:line_number" corresponding
2717                         # to where the subroutine is defined; we call find_sub,
2718                         # break up the return value, and assign it in one
2719                         # operation.
2720                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2721
2722                         # Force the line number to be numeric.
2723                         $i += 0;
2724
2725                         # If we got a line number, we found the sub.
2726                         if ($i) {
2727
2728                             # Switch all the debugger's internals around so
2729                             # we're actually working with that file.
2730                             $filename = $file;
2731                             *dbline   = $main::{ '_<' . $filename };
2732
2733                             # Mark that there's a breakpoint in this file.
2734                             $had_breakpoints{$filename} |= 1;
2735
2736                             # Scan forward to the first executable line
2737                             # after the 'sub whatever' line.
2738                             $max = $#dbline;
2739                             ++$i while $dbline[$i] == 0 && $i < $max;
2740                         } ## end if ($i)
2741
2742                         # We didn't find a sub by that name.
2743                         else {
2744                             print $OUT "Subroutine $subname not found.\n";
2745                             next CMD;
2746                         }
2747                     } ## end if ($subname =~ /\D/)
2748
2749                     # At this point, either the subname was all digits (an
2750                     # absolute line-break request) or we've scanned through
2751                     # the code following the definition of the sub, looking
2752                     # for an executable, which we may or may not have found.
2753                     #
2754                     # If $i (which we set $subname from) is non-zero, we
2755                     # got a request to break at some line somewhere. On
2756                     # one hand, if there wasn't any real subroutine name
2757                     # involved, this will be a request to break in the current
2758                     # file at the specified line, so we have to check to make
2759                     # sure that the line specified really is breakable.
2760                     #
2761                     # On the other hand, if there was a subname supplied, the
2762                     # preceding block has moved us to the proper file and
2763                     # location within that file, and then scanned forward
2764                     # looking for the next executable line. We have to make
2765                     # sure that one was found.
2766                     #
2767                     # On the gripping hand, we can't do anything unless the
2768                     # current value of $i points to a valid breakable line.
2769                     # Check that.
2770                     if ($i) {
2771
2772                         # Breakable?
2773                         if ( $dbline[$i] == 0 ) {
2774                             print $OUT "Line $i not breakable.\n";
2775                             next CMD;
2776                         }
2777
2778                         # Yes. Set up the one-time-break sigil.
2779                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2780                     } ## end if ($i)
2781
2782                     # Turn off stack tracing from here up.
2783                     for ( $i = 0 ; $i <= $stack_depth ; ) {
2784                         $stack[ $i++ ] &= ~1;
2785                     }
2786                     last CMD;
2787                 };
2788
2789 =head4 C<r> - return from a subroutine
2790
2791 For C<r> to work properly, the debugger has to stop execution again
2792 immediately after the return is executed. This is done by forcing
2793 single-stepping to be on in the call level above the current one. If
2794 we are printing return values when a C<r> is executed, set C<$doret>
2795 appropriately, and force us out of the command loop.
2796
2797 =cut
2798
2799                 # r - return from the current subroutine.
2800                 $cmd =~ /^r$/ && do {
2801
2802                     # Can't do anythign if the program's over.
2803                     end_report(), next CMD if $finished and $level <= 1;
2804
2805                     # Turn on stack trace.
2806                     $stack[$stack_depth] |= 1;
2807
2808                     # Print return value unless the stack is empty.
2809                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2810                     last CMD;
2811                 };
2812
2813 =head4 C<T> - stack trace
2814
2815 Just calls C<DB::print_trace>.
2816
2817 =cut
2818
2819                 $cmd =~ /^T$/ && do {
2820                     print_trace( $OUT, 1 );    # skip DB
2821                     next CMD;
2822                 };
2823
2824 =head4 C<w> - List window around current line.
2825
2826 Just calls C<DB::cmd_w>.
2827
2828 =cut
2829
2830                 $cmd =~ /^w\b\s*(.*)/s && do { &cmd_w( 'w', $1 ); next CMD; };
2831
2832 =head4 C<W> - watch-expression processing.
2833
2834 Just calls C<DB::cmd_W>. 
2835
2836 =cut
2837
2838                 $cmd =~ /^W\b\s*(.*)/s && do { &cmd_W( 'W', $1 ); next CMD; };
2839
2840 =head4 C</> - search forward for a string in the source
2841
2842 We take the argument and treat it as a pattern. If it turns out to be a 
2843 bad one, we return the error we got from trying to C<eval> it and exit.
2844 If not, we create some code to do the search and C<eval> it so it can't 
2845 mess us up.
2846
2847 =cut
2848
2849                 $cmd =~ /^\/(.*)$/ && do {
2850
2851                     # The pattern as a string.
2852                     $inpat = $1;
2853
2854                     # Remove the final slash.
2855                     $inpat =~ s:([^\\])/$:$1:;
2856
2857                     # If the pattern isn't null ...
2858                     if ( $inpat ne "" ) {
2859
2860                         # Turn of warn and die procesing for a bit.
2861                         local $SIG{__DIE__};
2862                         local $SIG{__WARN__};
2863
2864                         # Create the pattern.
2865                         eval '$inpat =~ m' . "\a$inpat\a";
2866                         if ( $@ ne "" ) {
2867
2868                             # Oops. Bad pattern. No biscuit.
2869                             # Print the eval error and go back for more
2870                             # commands.
2871                             print $OUT "$@";
2872                             next CMD;
2873                         }
2874                         $pat = $inpat;
2875                     } ## end if ($inpat ne "")
2876
2877                     # Set up to stop on wrap-around.
2878                     $end = $start;
2879
2880                     # Don't move off the current line.
2881                     $incr = -1;
2882
2883                     # Done in eval so nothing breaks if the pattern
2884                     # does something weird.
2885                     eval '
2886                         for (;;) {
2887                             # Move ahead one line.
2888                             ++$start;
2889
2890                             # Wrap if we pass the last line.
2891                             $start = 1 if ($start > $max);
2892
2893                             # Stop if we have gotten back to this line again,
2894                             last if ($start == $end);
2895
2896                             # A hit! (Note, though, that we are doing
2897                             # case-insensitive matching. Maybe a qr//
2898                             # expression would be better, so the user could
2899                             # do case-sensitive matching if desired.
2900                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2901                                 if ($slave_editor) {
2902                                     # Handle proper escaping in the slave.
2903                                     print $OUT "\032\032$filename:$start:0\n";
2904                                 } 
2905                                 else {
2906                                     # Just print the line normally.
2907                                     print $OUT "$start:\t",$dbline[$start],"\n";
2908                                 }
2909                                 # And quit since we found something.
2910                                 last;
2911                             }
2912                          } ';
2913
2914                     # If we wrapped, there never was a match.
2915                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2916                     next CMD;
2917                 };
2918
2919 =head4 C<?> - search backward for a string in the source
2920
2921 Same as for C</>, except the loop runs backwards.
2922
2923 =cut
2924
2925                 # ? - backward pattern search.
2926                 $cmd =~ /^\?(.*)$/ && do {
2927
2928                     # Get the pattern, remove trailing question mark.
2929                     $inpat = $1;
2930                     $inpat =~ s:([^\\])\?$:$1:;
2931
2932                     # If we've got one ...
2933                     if ( $inpat ne "" ) {
2934
2935                         # Turn off die & warn handlers.
2936                         local $SIG{__DIE__};
2937                         local $SIG{__WARN__};
2938                         eval '$inpat =~ m' . "\a$inpat\a";
2939
2940                         if ( $@ ne "" ) {
2941
2942                             # Ouch. Not good. Print the error.
2943                             print $OUT $@;
2944                             next CMD;
2945                         }
2946                         $pat = $inpat;
2947                     } ## end if ($inpat ne "")
2948
2949                     # Where we are now is where to stop after wraparound.
2950                     $end = $start;
2951
2952                     # Don't move away from this line.
2953                     $incr = -1;
2954
2955                     # Search inside the eval to prevent pattern badness
2956                     # from killing us.
2957                     eval '
2958                         for (;;) {
2959                             # Back up a line.
2960                             --$start;
2961
2962                             # Wrap if we pass the first line.
2963
2964                             $start = $max if ($start <= 0);
2965
2966                             # Quit if we get back where we started,
2967                             last if ($start == $end);
2968
2969                             # Match?
2970                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2971                                 if ($slave_editor) {
2972                                     # Yep, follow slave editor requirements.
2973                                     print $OUT "\032\032$filename:$start:0\n";
2974                                 } 
2975                                 else {
2976                                     # Yep, just print normally.
2977                                     print $OUT "$start:\t",$dbline[$start],"\n";
2978                                 }
2979
2980                                 # Found, so done.
2981                                 last;
2982                             }
2983                         } ';
2984
2985                     # Say we failed if the loop never found anything,
2986                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2987                     next CMD;
2988                 };
2989
2990 =head4 C<$rc> - Recall command
2991
2992 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2993 that the terminal supports history). It find the the command required, puts it
2994 into C<$cmd>, and redoes the loop to execute it.
2995
2996 =cut
2997
2998                 # $rc - recall command.
2999                 $cmd =~ /^$rc+\s*(-)?(\d+)?$/ && do {
3000
3001                     # No arguments, take one thing off history.
3002                     pop(@hist) if length($cmd) > 1;
3003
3004                     # Relative (- found)?
3005                     #  Y - index back from most recent (by 1 if bare minus)
3006                     #  N - go to that particular command slot or the last
3007                     #      thing if nothing following.
3008                     $i = $1 ? ( $#hist - ( $2 || 1 ) ) : ( $2 || $#hist );
3009
3010                     # Pick out the command desired.
3011                     $cmd = $hist[$i];
3012
3013                     # Print the command to be executed and restart the loop
3014                     # with that command in the buffer.
3015                     print $OUT $cmd, "\n";
3016                     redo CMD;
3017                 };
3018
3019 =head4 C<$sh$sh> - C<system()> command
3020
3021 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
3022 C<STDOUT> from getting messed up.
3023
3024 =cut
3025
3026                 # $sh$sh - run a shell command (if it's all ASCII).
3027                 # Can't run shell commands with Unicode in the debugger, hmm.
3028                 $cmd =~ /^$sh$sh\s*([\x00-\xff]*)/ && do {
3029
3030                     # System it.
3031                     &system($1);
3032                     next CMD;
3033                 };
3034
3035 =head4 C<$rc I<pattern> $rc> - Search command history
3036
3037 Another command to manipulate C<@hist>: this one searches it with a pattern.
3038 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
3039
3040 =cut
3041
3042                 # $rc pattern $rc - find a command in the history.
3043                 $cmd =~ /^$rc([^$rc].*)$/ && do {
3044
3045                     # Create the pattern to use.
3046                     $pat = "^$1";
3047
3048                     # Toss off last entry if length is >1 (and it always is).
3049                     pop(@hist) if length($cmd) > 1;
3050
3051                     # Look backward through the history.
3052                     for ( $i = $#hist ; $i ; --$i ) {
3053
3054                         # Stop if we find it.
3055                         last if $hist[$i] =~ /$pat/;
3056                     }
3057
3058                     if ( !$i ) {
3059
3060                         # Never found it.
3061                         print $OUT "No such command!\n\n";
3062                         next CMD;
3063                     }
3064
3065                     # Found it. Put it in the buffer, print it, and process it.
3066                     $cmd = $hist[$i];
3067                     print $OUT $cmd, "\n";
3068                     redo CMD;
3069                 };
3070
3071 =head4 C<$sh> - Invoke a shell     
3072
3073 Uses C<DB::system> to invoke a shell.
3074
3075 =cut
3076
3077                 # $sh - start a shell.
3078                 $cmd =~ /^$sh$/ && do {
3079
3080                     # Run the user's shell. If none defined, run Bourne.
3081                     # We resume execution when the shell terminates.
3082                     &system( $ENV{SHELL} || "/bin/sh" );
3083                     next CMD;
3084                 };
3085
3086 =head4 C<$sh I<command>> - Force execution of a command in a shell
3087
3088 Like the above, but the command is passed to the shell. Again, we use
3089 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
3090
3091 =cut
3092
3093                 # $sh command - start a shell and run a command in it.
3094                 $cmd =~ /^$sh\s*([\x00-\xff]*)/ && do {
3095
3096                     # XXX: using csh or tcsh destroys sigint retvals!
3097                     #&system($1);  # use this instead
3098
3099                     # use the user's shell, or Bourne if none defined.
3100                     &system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3101                     next CMD;
3102                 };
3103
3104 =head4 C<H> - display commands in history
3105
3106 Prints the contents of C<@hist> (if any).
3107
3108 =cut
3109
3110                 $cmd =~ /^H\b\s*\*/ && do {
3111                     @hist = @truehist = ();
3112                     print $OUT "History cleansed\n";
3113                     next CMD;
3114                 };
3115
3116                 $cmd =~ /^H\b\s*(-(\d+))?/ && do {
3117
3118                     # Anything other than negative numbers is ignored by
3119                     # the (incorrect) pattern, so this test does nothing.
3120                     $end = $2 ? ( $#hist - $2 ) : 0;
3121
3122                     # Set to the minimum if less than zero.
3123                     $hist = 0 if $hist < 0;
3124
3125                     # Start at the end of the array.
3126                     # Stay in while we're still above the ending value.
3127                     # Tick back by one each time around the loop.
3128                     for ( $i = $#hist ; $i > $end ; $i-- ) {
3129
3130                         # Print the command  unless it has no arguments.
3131                         print $OUT "$i: ", $hist[$i], "\n"
3132                           unless $hist[$i] =~ /^.?$/;
3133                     }
3134                     next CMD;
3135                 };
3136
3137 =head4 C<man, doc, perldoc> - look up documentation
3138
3139 Just calls C<runman()> to print the appropriate document.
3140
3141 =cut
3142
3143                 # man, perldoc, doc - show manual pages.
3144                 $cmd =~ /^(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?$/ && do {
3145                     runman($1);
3146                     next CMD;
3147                 };
3148
3149 =head4 C<p> - print
3150
3151 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3152 the bottom of the loop.
3153
3154 =cut
3155
3156                 # p - print (no args): print $_.
3157                 $cmd =~ s/^p$/print {\$DB::OUT} \$_/;
3158
3159                 # p - print the given expression.
3160                 $cmd =~ s/^p\b/print {\$DB::OUT} /;
3161
3162 =head4 C<=> - define command alias
3163
3164 Manipulates C<%alias> to add or list command aliases.
3165
3166 =cut
3167
3168                 # = - set up a command alias.
3169                 $cmd =~ s/^=\s*// && do {
3170                     my @keys;
3171                     if ( length $cmd == 0 ) {
3172
3173                         # No args, get current aliases.
3174                         @keys = sort keys %alias;
3175                     }
3176                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3177
3178                         # Creating a new alias. $k is alias name, $v is
3179                         # alias value.
3180
3181                         # can't use $_ or kill //g state
3182                         for my $x ( $k, $v ) {
3183
3184                             # Escape "alarm" characters.
3185                             $x =~ s/\a/\\a/g;
3186                         }
3187
3188                         # Substitute key for value, using alarm chars
3189                         # as separators (which is why we escaped them in
3190                         # the command).
3191                         $alias{$k} = "s\a$k\a$v\a";
3192
3193                         # Turn off standard warn and die behavior.
3194                         local $SIG{__DIE__};
3195                         local $SIG{__WARN__};
3196
3197                         # Is it valid Perl?
3198                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3199
3200                             # Nope. Bad alias. Say so and get out.
3201                             print $OUT "Can't alias $k to $v: $@\n";
3202                             delete $alias{$k};
3203                             next CMD;
3204                         }
3205
3206                         # We'll only list the new one.
3207                         @keys = ($k);
3208                     } ## end elsif (my ($k, $v) = ($cmd...
3209
3210                     # The argument is the alias to list.
3211                     else {
3212                         @keys = ($cmd);
3213                     }
3214
3215                     # List aliases.
3216                     for my $k (@keys) {
3217
3218                         # Messy metaquoting: Trim the substiution code off.
3219                         # We use control-G as the delimiter because it's not
3220                         # likely to appear in the alias.
3221                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3222
3223                             # Print the alias.
3224                             print $OUT "$k\t= $1\n";
3225                         }
3226                         elsif ( defined $alias{$k} ) {
3227
3228                             # Couldn't trim it off; just print the alias code.
3229                             print $OUT "$k\t$alias{$k}\n";
3230                         }
3231                         else {
3232
3233                             # No such, dude.
3234                             print "No alias for $k\n";
3235                         }
3236                     } ## end for my $k (@keys)
3237                     next CMD;
3238                 };
3239
3240 =head4 C<source> - read commands from a file.
3241
3242 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3243 pick it up.
3244
3245 =cut
3246
3247                 # source - read commands from a file (or pipe!) and execute.
3248                 $cmd =~ /^source\s+(.*\S)/ && do {
3249                     if ( open my $fh, $1 ) {
3250
3251                         # Opened OK; stick it in the list of file handles.
3252                         push @cmdfhs, $fh;
3253                     }
3254                     else {
3255
3256                         # Couldn't open it.
3257                         &warn("Can't execute `$1': $!\n");
3258                     }
3259                     next CMD;
3260                 };
3261
3262 =head4 C<save> - send current history to a file
3263
3264 Takes the complete history, (not the shrunken version you see with C<H>),
3265 and saves it to the given filename, so it can be replayed using C<source>.
3266
3267 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3268
3269 =cut
3270
3271                 # save source - write commands to a file for later use
3272                 $cmd =~ /^save\s*(.*)$/ && do {
3273                     my $file = $1 || '.perl5dbrc';    # default?
3274                     if ( open my $fh, "> $file" ) {
3275
3276                        # chomp to remove extraneous newlines from source'd files
3277                         chomp( my @truelist =
3278                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3279                               @truehist );
3280                         print $fh join( "\n", @truelist );
3281                         print "commands saved in $file\n";
3282                     }
3283                     else {
3284                         &warn("Can't save debugger commands in '$1': $!\n");
3285                     }
3286                     next CMD;
3287                 };
3288
3289 =head4 C<R> - restart
3290
3291 Restart the debugger session. 
3292
3293 =head4 C<rerun> - rerun the current session
3294
3295 Return to any given position in the B<true>-history list
3296
3297 =cut
3298
3299                 # R - restart execution.
3300                 # rerun - controlled restart execution.
3301                 $cmd =~ /^(R|rerun\s*(.*))$/ && do {
3302                     my @args = ($1 eq 'R' ? restart() : rerun($2));
3303
3304                     # Close all non-system fds for a clean restart.  A more
3305                     # correct method would be to close all fds that were not
3306                     # open when the process started, but this seems to be
3307                     # hard.  See "debugger 'R'estart and open database
3308                     # connections" on p5p.
3309
3310                     my $max_fd = 1024; # default if POSIX can't be loaded
3311                     if (eval { require POSIX }) {
3312                         $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX());
3313                     }
3314
3315                     if (defined $max_fd) {
3316                         foreach ($^F+1 .. $max_fd-1) {
3317                             next unless open FD_TO_CLOSE, "<&=$_";
3318                             close(FD_TO_CLOSE);
3319                         }
3320                     }
3321
3322                     # And run Perl again.  We use exec() to keep the
3323                     # PID stable (and that way $ini_pids is still valid).
3324                     exec(@args) || print $OUT "exec failed: $!\n";
3325
3326                     last CMD;
3327                 };
3328
3329 =head4 C<|, ||> - pipe output through the pager.
3330
3331 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3332 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3333 pipe to the pager (restoring the output filehandles if this fails). If this
3334 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply 
3335 set C<$signal>, sending us back into the debugger.
3336
3337 We then trim off the pipe symbols and C<redo> the command loop at the
3338 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3339 reading another.
3340
3341 =cut
3342
3343                 # || - run command in the pager, with output to DB::OUT.
3344                 $cmd =~ /^\|\|?\s*[^|]/ && do {
3345                     if ( $pager =~ /^\|/ ) {
3346
3347                         # Default pager is into a pipe. Redirect I/O.
3348                         open( SAVEOUT, ">&STDOUT" )
3349                           || &warn("Can't save STDOUT");
3350                         open( STDOUT, ">&OUT" )
3351                           || &warn("Can't redirect STDOUT");
3352                     } ## end if ($pager =~ /^\|/)
3353                     else {
3354
3355                         # Not into a pipe. STDOUT is safe.
3356                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3357                     }
3358
3359                     # Fix up environment to record we have less if so.
3360                     fix_less();
3361
3362                     unless ( $piped = open( OUT, $pager ) ) {
3363
3364                         # Couldn't open pipe to pager.
3365                         &warn("Can't pipe output to `$pager'");
3366                         if ( $pager =~ /^\|/ ) {
3367
3368                             # Redirect I/O back again.
3369                             open( OUT, ">&STDOUT" )    # XXX: lost message
3370                               || &warn("Can't restore DB::OUT");
3371                             open( STDOUT, ">&SAVEOUT" )
3372                               || &warn("Can't restore STDOUT");
3373                             close(SAVEOUT);
3374                         } ## end if ($pager =~ /^\|/)
3375                         else {
3376
3377                             # Redirect I/O. STDOUT already safe.
3378                             open( OUT, ">&STDOUT" )    # XXX: lost message
3379                               || &warn("Can't restore DB::OUT");
3380                         }
3381                         next CMD;
3382                     } ## end unless ($piped = open(OUT,...
3383
3384                     # Set up broken-pipe handler if necessary.
3385                     $SIG{PIPE} = \&DB::catch
3386                       if $pager =~ /^\|/
3387                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3388
3389                     # Save current filehandle, unbuffer out, and put it back.
3390                     $selected = select(OUT);
3391                     $|        = 1;
3392
3393                     # Don't put it back if pager was a pipe.
3394                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3395
3396                     # Trim off the pipe symbols and run the command now.
3397                     $cmd =~ s/^\|+\s*//;
3398                     redo PIPE;
3399                 };
3400
3401 =head3 END OF COMMAND PARSING
3402
3403 Anything left in C<$cmd> at this point is a Perl expression that we want to 
3404 evaluate. We'll always evaluate in the user's context, and fully qualify 
3405 any variables we might want to address in the C<DB> package.
3406
3407 =cut
3408
3409                 # t - turn trace on.
3410                 $cmd =~ s/^t\s/\$DB::trace |= 1;\n/;
3411
3412                 # s - single-step. Remember the last command was 's'.
3413                 $cmd =~ s/^s\s/\$DB::single = 1;\n/ && do { $laststep = 's' };
3414
3415                 # n - single-step, but not into subs. Remember last command
3416                 # was 'n'.
3417                 $cmd =~ s/^n\s/\$DB::single = 2;\n/ && do { $laststep = 'n' };
3418
3419             }    # PIPE:
3420
3421             # Make sure the flag that says "the debugger's running" is
3422             # still on, to make sure we get control again.
3423             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3424
3425             # Run *our* eval that executes in the caller's context.
3426             &eval;
3427
3428             # Turn off the one-time-dump stuff now.
3429             if ($onetimeDump) {
3430                 $onetimeDump      = undef;
3431                 $onetimedumpDepth = undef;
3432             }
3433             elsif ( $term_pid == $$ ) {
3434                 eval {          # May run under miniperl, when not available...
3435                     STDOUT->flush();
3436                     STDERR->flush();
3437                 };
3438
3439                 # XXX If this is the master pid, print a newline.
3440                 print $OUT "\n";
3441             }
3442         } ## end while (($term || &setterm...
3443
3444 =head3 POST-COMMAND PROCESSING
3445
3446 After each command, we check to see if the command output was piped anywhere.
3447 If so, we go through the necessary code to unhook the pipe and go back to
3448 our standard filehandles for input and output.
3449
3450 =cut
3451
3452         continue {    # CMD:
3453
3454             # At the end of every command:
3455             if ($piped) {
3456
3457                 # Unhook the pipe mechanism now.
3458                 if ( $pager =~ /^\|/ ) {
3459
3460                     # No error from the child.
3461                     $? = 0;
3462
3463                     # we cannot warn here: the handle is missing --tchrist
3464                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3465
3466                     # most of the $? crud was coping with broken cshisms
3467                     # $? is explicitly set to 0, so this never runs.
3468                     if ($?) {
3469                         print SAVEOUT "Pager `$pager' failed: ";
3470                         if ( $? == -1 ) {
3471                             print SAVEOUT "shell returned -1\n";
3472                         }
3473                         elsif ( $? >> 8 ) {
3474                             print SAVEOUT ( $? & 127 )
3475                               ? " (SIG#" . ( $? & 127 ) . ")"
3476                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3477                         }
3478                         else {
3479                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3480                         }
3481                     } ## end if ($?)
3482
3483                     # Reopen filehandle for our output (if we can) and
3484                     # restore STDOUT (if we can).
3485                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3486                     open( STDOUT, ">&SAVEOUT" )
3487                       || &warn("Can't restore STDOUT");
3488
3489                     # Turn off pipe exception handler if necessary.
3490                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3491
3492                     # Will stop ignoring SIGPIPE if done like nohup(1)
3493                     # does SIGINT but Perl doesn't give us a choice.
3494                 } ## end if ($pager =~ /^\|/)
3495                 else {
3496
3497                     # Non-piped "pager". Just restore STDOUT.
3498                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3499                 }
3500
3501                 # Close filehandle pager was using, restore the normal one
3502                 # if necessary,
3503                 close(SAVEOUT);
3504                 select($selected), $selected = "" unless $selected eq "";
3505
3506                 # No pipes now.
3507                 $piped = "";
3508             } ## end if ($piped)
3509         }    # CMD:
3510
3511 =head3 COMMAND LOOP TERMINATION
3512
3513 When commands have finished executing, we come here. If the user closed the
3514 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3515 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3516 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3517 The interpreter will then execute the next line and then return control to us
3518 again.
3519
3520 =cut
3521
3522         # No more commands? Quit.
3523         $fall_off_end = 1 unless defined $cmd;    # Emulate `q' on EOF
3524
3525         # Evaluate post-prompt commands.
3526         foreach $evalarg (@$post) {
3527             &eval;
3528         }
3529     }    # if ($single || $signal)
3530
3531     # Put the user's globals back where you found them.
3532     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3533     ();
3534 } ## end sub DB
3535
3536 # The following code may be executed now:
3537 # BEGIN {warn 4}
3538
3539 =head2 sub
3540
3541 C<sub> is called whenever a subroutine call happens in the program being 
3542 debugged. The variable C<$DB::sub> contains the name of the subroutine
3543 being called.
3544
3545 The core function of this subroutine is to actually call the sub in the proper
3546 context, capturing its output. This of course causes C<DB::DB> to get called
3547 again, repeating until the subroutine ends and returns control to C<DB::sub>
3548 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3549 return value, and returns its captured copy of the return value as its own
3550 return value. The value then feeds back into the program being debugged as if
3551 C<DB::sub> hadn't been there at all.
3552
3553 C<sub> does all the work of printing the subroutine entry and exit messages
3554 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3555 and also prints the return value if needed (for the C<r> command and if 
3556 the 16 bit is set in C<$frame>).
3557
3558 It also tracks the subroutine call depth by saving the current setting of
3559 C<$single> in the C<@stack> package global; if this exceeds the value in
3560 C<$deep>, C<sub> automatically turns on printing of the current depth by
3561 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3562 of stop/don't stop on entry to subs set as it currently is set.
3563
3564 =head3 C<caller()> support
3565
3566 If C<caller()> is called from the package C<DB>, it provides some
3567 additional data, in the following order:
3568
3569 =over 4
3570
3571 =item * C<$package>
3572
3573 The package name the sub was in
3574
3575 =item * C<$filename>
3576
3577 The filename it was defined in
3578
3579 =item * C<$line>
3580
3581 The line number it was defined on
3582
3583 =item * C<$subroutine>
3584
3585 The subroutine name; C<(eval)> if an C<eval>().
3586
3587 =item * C<$hasargs>
3588
3589 1 if it has arguments, 0 if not
3590
3591 =item * C<$wantarray>
3592
3593 1 if array context, 0 if scalar context
3594
3595 =item * C<$evaltext>
3596
3597 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3598
3599 =item * C<$is_require>
3600
3601 frame was created by a C<use> or C<require> statement
3602
3603 =item * C<$hints>
3604
3605 pragma information; subject to change between versions
3606
3607 =item * C<$bitmask>
3608
3609 pragma information; subject to change between versions
3610
3611 =item * C<@DB::args>
3612
3613 arguments with which the subroutine was invoked
3614
3615 =back
3616
3617 =cut
3618
3619 sub sub {
3620         # Do not use a regex in this subroutine -> results in corrupted memory
3621         # See: [perl #66110]
3622
3623         # lock ourselves under threads
3624         lock($DBGR);
3625
3626     # Whether or not the autoloader was running, a scalar to put the
3627     # sub's return value in (if needed), and an array to put the sub's
3628     # return value in (if needed).
3629     my ( $al, $ret, @ret ) = "";
3630         if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3631                 print "creating new thread\n"; 
3632         }
3633
3634     # If the last ten characters are '::AUTOLOAD', note we've traced
3635     # into AUTOLOAD for $sub.
3636     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3637         $al = " for $$sub" if defined $$sub;
3638     }
3639
3640     # We stack the stack pointer and then increment it to protect us
3641     # from a situation that might unwind a whole bunch of call frames
3642     # at once. Localizing the stack pointer means that it will automatically
3643     # unwind the same amount when multiple stack frames are unwound.
3644     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3645
3646     # Expand @stack.
3647     $#stack = $stack_depth;
3648
3649     # Save current single-step setting.
3650     $stack[-1] = $single;
3651
3652     # Turn off all flags except single-stepping.
3653     $single &= 1;
3654
3655     # If we've gotten really deeply recursed, turn on the flag that will
3656     # make us stop with the 'deep recursion' message.
3657     $single |= 4 if $stack_depth == $deep;
3658
3659     # If frame messages are on ...
3660     (
3661         $frame & 4    # Extended frame entry message
3662         ? (
3663             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3664
3665             # Why -1? But it works! :-(
3666             # Because print_trace will call add 1 to it and then call
3667             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3668             # in dump_trace.
3669             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3670           )
3671         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3672
3673           # standard frame entry message
3674       )
3675       if $frame;
3676
3677     # Determine the sub's return type,and capture approppriately.
3678     if (wantarray) {
3679
3680         # Called in array context. call sub and capture output.
3681         # DB::DB will recursively get control again if appropriate; we'll come
3682         # back here when the sub is finished.
3683         @ret = &$sub;
3684
3685         # Pop the single-step value back off the stack.
3686         $single |= $stack[ $stack_depth-- ];
3687
3688         # Check for exit trace messages...
3689         (
3690             $frame & 4    # Extended exit message
3691             ? (
3692                 print_lineinfo( ' ' x $stack_depth, "out " ),
3693                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3694               )
3695             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3696
3697               # Standard exit message
3698           )
3699           if $frame & 2;
3700
3701         # Print the return info if we need to.
3702         if ( $doret eq $stack_depth or $frame & 16 ) {
3703
3704             # Turn off output record separator.
3705             local $\ = '';
3706             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3707
3708             # Indent if we're printing because of $frame tracing.
3709             print $fh ' ' x $stack_depth if $frame & 16;
3710
3711             # Print the return value.
3712             print $fh "list context return from $sub:\n";
3713             dumpit( $fh, \@ret );
3714
3715             # And don't print it again.
3716             $doret = -2;
3717         } ## end if ($doret eq $stack_depth...
3718             # And we have to return the return value now.
3719         @ret;
3720     } ## end if (wantarray)
3721
3722     # Scalar context.
3723     else {
3724         if ( defined wantarray ) {
3725
3726             # Save the value if it's wanted at all.
3727             $ret = &$sub;
3728         }
3729         else {
3730
3731             # Void return, explicitly.
3732             &$sub;
3733             undef $ret;
3734         }
3735
3736         # Pop the single-step value off the stack.
3737         $single |= $stack[ $stack_depth-- ];
3738
3739         # If we're doing exit messages...
3740         (
3741             $frame & 4    # Extended messsages
3742             ? (
3743                 print_lineinfo( ' ' x $stack_depth, "out " ),
3744                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3745               )
3746             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3747
3748               # Standard messages
3749           )
3750           if $frame & 2;
3751
3752         # If we are supposed to show the return value... same as before.
3753         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3754             local $\ = '';
3755             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3756             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3757             print $fh (
3758                 defined wantarray
3759                 ? "scalar context return from $sub: "
3760                 : "void context return from $sub\n"
3761             );
3762             dumpit( $fh, $ret ) if defined wantarray;
3763             $doret = -2;
3764         } ## end if ($doret eq $stack_depth...
3765
3766         # Return the appropriate scalar value.
3767         $ret;
3768     } ## end else [ if (wantarray)
3769 } ## end sub sub
3770
3771 sub lsub : lvalue {
3772
3773         # lock ourselves under threads
3774         lock($DBGR);
3775
3776     # Whether or not the autoloader was running, a scalar to put the
3777     # sub's return value in (if needed), and an array to put the sub's
3778     # return value in (if needed).
3779     my ( $al, $ret, @ret ) = "";
3780         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3781                 print "creating new thread\n";
3782         }
3783
3784     # If the last ten characters are C'::AUTOLOAD', note we've traced
3785     # into AUTOLOAD for $sub.
3786     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3787         $al = " for $$sub";
3788     }
3789
3790     # We stack the stack pointer and then increment it to protect us
3791     # from a situation that might unwind a whole bunch of call frames
3792     # at once. Localizing the stack pointer means that it will automatically
3793     # unwind the same amount when multiple stack frames are unwound.
3794     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3795
3796     # Expand @stack.
3797     $#stack = $stack_depth;
3798
3799     # Save current single-step setting.
3800     $stack[-1] = $single;
3801
3802     # Turn off all flags except single-stepping.
3803     $single &= 1;
3804
3805     # If we've gotten really deeply recursed, turn on the flag that will
3806     # make us stop with the 'deep recursion' message.
3807     $single |= 4 if $stack_depth == $deep;
3808
3809     # If frame messages are on ...
3810     (
3811         $frame & 4    # Extended frame entry message
3812         ? (
3813             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3814
3815             # Why -1? But it works! :-(
3816             # Because print_trace will call add 1 to it and then call
3817             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3818             # in dump_trace.
3819             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3820           )
3821         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3822
3823           # standard frame entry message
3824       )
3825       if $frame;
3826
3827     # Pop the single-step value back off the stack.
3828     $single |= $stack[ $stack_depth-- ];
3829
3830     # call the original lvalue sub.
3831     &$sub;
3832 }
3833
3834 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3835
3836 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3837 Most of the changes were to systematize the command structure and to eliminate
3838 commands that threw away user input without checking.
3839
3840 The following sections describe the code added to make it easy to support 
3841 multiple command sets with conflicting command names. This section is a start 
3842 at unifying all command processing to make it simpler to develop commands.
3843
3844 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line 
3845 number, and C<$dbline> (the current line) as arguments.
3846
3847 Support functions in this section which have multiple modes of failure C<die> 
3848 on error; the rest simply return a false value.
3849
3850 The user-interface functions (all of the C<cmd_*> functions) just output
3851 error messages.
3852
3853 =head2 C<%set>
3854
3855 The C<%set> hash defines the mapping from command letter to subroutine
3856 name suffix. 
3857
3858 C<%set> is a two-level hash, indexed by set name and then by command name.
3859 Note that trying to set the CommandSet to C<foobar> simply results in the
3860 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3861
3862 =cut 
3863
3864 ### The API section
3865
3866 my %set = (    #
3867     'pre580' => {
3868         'a' => 'pre580_a',
3869         'A' => 'pre580_null',
3870         'b' => 'pre580_b',
3871         'B' => 'pre580_null',
3872         'd' => 'pre580_null',
3873         'D' => 'pre580_D',
3874         'h' => 'pre580_h',
3875         'M' => 'pre580_null',
3876         'O' => 'o',
3877         'o' => 'pre580_null',
3878         'v' => 'M',
3879         'w' => 'v',
3880         'W' => 'pre580_W',
3881     },
3882     'pre590' => {
3883         '<'  => 'pre590_prepost',
3884         '<<' => 'pre590_prepost',
3885         '>'  => 'pre590_prepost',
3886         '>>' => 'pre590_prepost',
3887         '{'  => 'pre590_prepost',
3888         '{{' => 'pre590_prepost',
3889     },
3890 );
3891
3892 =head2 C<cmd_wrapper()> (API)
3893
3894 C<cmd_wrapper()> allows the debugger to switch command sets 
3895 depending on the value of the C<CommandSet> option. 
3896
3897 It tries to look up the command in the C<%set> package-level I<lexical>
3898 (which means external entities can't fiddle with it) and create the name of 
3899 the sub to call based on the value found in the hash (if it's there). I<All> 
3900 of the commands to be handled in a set have to be added to C<%set>; if they 
3901 aren't found, the 5.8.0 equivalent is called (if there is one).
3902
3903 This code uses symbolic references. 
3904
3905 =cut
3906
3907 sub cmd_wrapper {
3908     my $cmd      = shift;
3909     my $line     = shift;
3910     my $dblineno = shift;
3911
3912     # Assemble the command subroutine's name by looking up the
3913     # command set and command name in %set. If we can't find it,
3914     # default to the older version of the command.
3915     my $call = 'cmd_'
3916       . ( $set{$CommandSet}{$cmd}
3917           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
3918
3919     # Call the command subroutine, call it by name.
3920     return &$call( $cmd, $line, $dblineno );
3921 } ## end sub cmd_wrapper
3922
3923 =head3 C<cmd_a> (command)
3924
3925 The C<a> command handles pre-execution actions. These are associated with a
3926 particular line, so they're stored in C<%dbline>. We default to the current 
3927 line if none is specified. 
3928
3929 =cut
3930
3931 sub cmd_a {
3932     my $cmd    = shift;
3933     my $line   = shift || '';    # [.|line] expr
3934     my $dbline = shift;
3935
3936     # If it's dot (here), or not all digits,  use the current line.
3937     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
3938
3939     # Should be a line number followed by an expression.
3940     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
3941         my ( $lineno, $expr ) = ( $1, $2 );
3942
3943         # If we have an expression ...
3944         if ( length $expr ) {
3945
3946             # ... but the line isn't breakable, complain.
3947             if ( $dbline[$lineno] == 0 ) {
3948                 print $OUT
3949                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
3950             }
3951             else {
3952
3953                 # It's executable. Record that the line has an action.
3954                 $had_breakpoints{$filename} |= 2;
3955
3956                 # Remove any action, temp breakpoint, etc.
3957                 $dbline{$lineno} =~ s/\0[^\0]*//;
3958
3959                 # Add the action to the line.
3960                 $dbline{$lineno} .= "\0" . action($expr);
3961             }
3962         } ## end if (length $expr)
3963     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
3964     else {
3965
3966         # Syntax wrong.
3967         print $OUT
3968           "Adding an action requires an optional lineno and an expression\n"
3969           ;    # hint
3970     }
3971 } ## end sub cmd_a
3972
3973 =head3 C<cmd_A> (command)
3974
3975 Delete actions. Similar to above, except the delete code is in a separate
3976 subroutine, C<delete_action>.
3977
3978 =cut
3979
3980 sub cmd_A {
3981     my $cmd    = shift;
3982     my $line   = shift || '';
3983     my $dbline = shift;
3984
3985     # Dot is this line.
3986     $line =~ s/^\./$dbline/;
3987
3988     # Call delete_action with a null param to delete them all.
3989     # The '1' forces the eval to be true. It'll be false only
3990     # if delete_action blows up for some reason, in which case
3991     # we print $@ and get out.
3992     if ( $line eq '*' ) {
3993         eval { &delete_action(); 1 } or print $OUT $@ and return;
3994     }
3995
3996     # There's a real line  number. Pass it to delete_action.
3997     # Error trapping is as above.
3998     elsif ( $line =~ /^(\S.*)/ ) {
3999         eval { &delete_action($1); 1 } or print $OUT $@ and return;
4000     }
4001
4002     # Swing and a miss. Bad syntax.
4003     else {
4004         print $OUT
4005           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4006     }
4007 } ## end sub cmd_A
4008
4009 =head3 C<delete_action> (API)
4010
4011 C<delete_action> accepts either a line number or C<undef>. If a line number
4012 is specified, we check for the line being executable (if it's not, it 
4013 couldn't have had an  action). If it is, we just take the action off (this
4014 will get any kind of an action, including breakpoints).
4015
4016 =cut
4017
4018 sub delete_action {
4019     my $i = shift;
4020     if ( defined($i) ) {
4021
4022         # Can there be one?
4023         die "Line $i has no action .\n" if $dbline[$i] == 0;
4024
4025         # Nuke whatever's there.
4026         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4027         delete $dbline{$i} if $dbline{$i} eq '';
4028     }
4029     else {
4030         print $OUT "Deleting all actions...\n";
4031         for my $file ( keys %had_breakpoints ) {
4032             local *dbline = $main::{ '_<' . $file };
4033             my $max = $#dbline;
4034             my $was;
4035             for ( $i = 1 ; $i <= $max ; $i++ ) {
4036                 if ( defined $dbline{$i} ) {
4037                     $dbline{$i} =~ s/\0[^\0]*//;
4038                     delete $dbline{$i} if $dbline{$i} eq '';
4039                 }
4040                 unless ( $had_breakpoints{$file} &= ~2 ) {
4041                     delete $had_breakpoints{$file};
4042                 }
4043             } ## end for ($i = 1 ; $i <= $max...
4044         } ## end for my $file (keys %had_breakpoints)
4045     } ## end else [ if (defined($i))
4046 } ## end sub delete_action
4047
4048 =head3 C<cmd_b> (command)
4049
4050 Set breakpoints. Since breakpoints can be set in so many places, in so many
4051 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4052 we try to parse the command type, and then shuttle it off to an appropriate
4053 subroutine to actually do the work of setting the breakpoint in the right
4054 place.
4055
4056 =cut
4057
4058 sub cmd_b {
4059     my $cmd    = shift;
4060     my $line   = shift;    # [.|line] [cond]
4061     my $dbline = shift;
4062
4063     # Make . the current line number if it's there..
4064     $line =~ s/^\./$dbline/;
4065
4066     # No line number, no condition. Simple break on current line.
4067     if ( $line =~ /^\s*$/ ) {
4068         &cmd_b_line( $dbline, 1 );
4069     }
4070
4071     # Break on load for a file.
4072     elsif ( $line =~ /^load\b\s*(.*)/ ) {
4073         my $file = $1;
4074         $file =~ s/\s+$//;
4075         &cmd_b_load($file);
4076     }
4077
4078     # b compile|postpone <some sub> [<condition>]
4079     # The interpreter actually traps this one for us; we just put the
4080     # necessary condition in the %postponed hash.
4081     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4082
4083         # Capture the condition if there is one. Make it true if none.
4084         my $cond = length $3 ? $3 : '1';
4085
4086         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
4087         # if it was 'compile'.
4088         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
4089
4090         # De-Perl4-ify the name - ' separators to ::.
4091         $subname =~ s/\'/::/g;
4092
4093         # Qualify it into the current package unless it's already qualified.
4094         $subname = "${'package'}::" . $subname unless $subname =~ /::/;
4095
4096         # Add main if it starts with ::.
4097         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4098
4099         # Save the break type for this sub.
4100         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
4101     } ## end elsif ($line =~ ...
4102
4103     # b <sub name> [<condition>]
4104     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4105
4106         #
4107         $subname = $1;
4108         $cond = length $2 ? $2 : '1';
4109         &cmd_b_sub( $subname, $cond );
4110     }
4111
4112     # b <line> [<condition>].
4113     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4114
4115         # Capture the line. If none, it's the current line.
4116         $line = $1 || $dbline;
4117
4118         # If there's no condition, make it '1'.
4119         $cond = length $2 ? $2 : '1';
4120
4121         # Break on line.
4122         &cmd_b_line( $line, $cond );
4123     }
4124
4125     # Line didn't make sense.
4126     else {
4127         print "confused by line($line)?\n";
4128     }
4129 } ## end sub cmd_b
4130
4131 =head3 C<break_on_load> (API)
4132
4133 We want to break when this file is loaded. Mark this file in the
4134 C<%break_on_load> hash, and note that it has a breakpoint in 
4135 C<%had_breakpoints>.
4136
4137 =cut
4138
4139 sub break_on_load {
4140     my $file = shift;
4141     $break_on_load{$file} = 1;
4142     $had_breakpoints{$file} |= 1;
4143 }
4144
4145 =head3 C<report_break_on_load> (API)
4146
4147 Gives us an array of filenames that are set to break on load. Note that 
4148 only files with break-on-load are in here, so simply showing the keys
4149 suffices.
4150
4151 =cut
4152
4153 sub report_break_on_load {
4154     sort keys %break_on_load;
4155 }
4156
4157 =head3 C<cmd_b_load> (command)
4158
4159 We take the file passed in and try to find it in C<%INC> (which maps modules
4160 to files they came from). We mark those files for break-on-load via 
4161 C<break_on_load> and then report that it was done.
4162
4163 =cut
4164
4165 sub cmd_b_load {
4166     my $file = shift;
4167     my @files;
4168
4169     # This is a block because that way we can use a redo inside it
4170     # even without there being any looping structure at all outside it.
4171     {
4172
4173         # Save short name and full path if found.
4174         push @files, $file;
4175         push @files, $::INC{$file} if $::INC{$file};
4176
4177         # Tack on .pm and do it again unless there was a '.' in the name
4178         # already.
4179         $file .= '.pm', redo unless $file =~ /\./;
4180     }
4181
4182     # Do the real work here.
4183     break_on_load($_) for @files;
4184
4185     # All the files that have break-on-load breakpoints.
4186     @files = report_break_on_load;
4187
4188     # Normalize for the purposes of our printing this.
4189     local $\ = '';
4190     local $" = ' ';
4191     print $OUT "Will stop on load of `@files'.\n";
4192 } ## end sub cmd_b_load
4193
4194 =head3 C<$filename_error> (API package global)
4195
4196 Several of the functions we need to implement in the API need to work both
4197 on the current file and on other files. We don't want to duplicate code, so
4198 C<$filename_error> is used to contain the name of the file that's being 
4199 worked on (if it's not the current one).
4200
4201 We can now build functions in pairs: the basic function works on the current
4202 file, and uses C<$filename_error> as part of its error message. Since this is
4203 initialized to C<"">, no filename will appear when we are working on the
4204 current file.
4205
4206 The second function is a wrapper which does the following:
4207
4208 =over 4 
4209
4210 =item *
4211
4212 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4213
4214 =item *
4215
4216 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process. 
4217
4218 =item *
4219
4220 Calls the first function. 
4221
4222 The first function works on the I<current> file (i.e., the one we changed to),
4223 and prints C<$filename_error> in the error message (the name of the other file)
4224 if it needs to. When the functions return, C<*dbline> is restored to point
4225 to the actual current file (the one we're executing in) and
4226 C<$filename_error> is restored to C<"">. This restores everything to
4227 the way it was before the second function was called at all.
4228
4229 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4230 details.
4231
4232 =back
4233
4234 =cut
4235
4236 $filename_error = '';
4237
4238 =head3 breakable_line(from, to) (API)
4239
4240 The subroutine decides whether or not a line in the current file is breakable.
4241 It walks through C<@dbline> within the range of lines specified, looking for
4242 the first line that is breakable.
4243
4244 If C<$to> is greater than C<$from>, the search moves forwards, finding the 
4245 first line I<after> C<$to> that's breakable, if there is one.
4246
4247 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4248 first line I<before> C<$to> that's breakable, if there is one.
4249
4250 =cut
4251
4252 sub breakable_line {
4253
4254     my ( $from, $to ) = @_;
4255
4256     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4257     my $i = $from;
4258
4259     # If there are at least 2 arguments, we're trying to search a range.
4260     if ( @_ >= 2 ) {
4261
4262         # $delta is positive for a forward search, negative for a backward one.
4263         my $delta = $from < $to ? +1 : -1;
4264
4265         # Keep us from running off the ends of the file.
4266         my $limit = $delta > 0 ? $#dbline : 1;
4267
4268         # Clever test. If you're a mathematician, it's obvious why this
4269         # test works. If not:
4270         # If $delta is positive (going forward), $limit will be $#dbline.
4271         #    If $to is less than $limit, ($limit - $to) will be positive, times
4272         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4273         #    as the stopping point.
4274         #
4275         #    If $to is greater than $limit, ($limit - $to) is negative,
4276         #    times $delta of 1 (positive), so the result is < 0 and we should
4277         #    use $limit ($#dbline) as the stopping point.
4278         #
4279         # If $delta is negative (going backward), $limit will be 1.
4280         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4281         #    (negative) so the result is > 0, and we use $to as the stopping
4282         #    point.
4283         #
4284         #    If $to is less than zero, ($limit - $to) will be positive,
4285         #    times $delta of -1 (negative), so the result is not > 0, and
4286         #    we use $limit (1) as the stopping point.
4287         #
4288         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4289         #    (negative), still giving zero; the result is not > 0, and
4290         #    we use $limit (1) as the stopping point.
4291         #
4292         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4293         #    (negative), giving a positive (>0) value, so we'll set $limit to
4294         #    $to.
4295
4296         $limit = $to if ( $limit - $to ) * $delta > 0;
4297
4298         # The real search loop.
4299         # $i starts at $from (the point we want to start searching from).
4300         # We move through @dbline in the appropriate direction (determined
4301         # by $delta: either -1 (back) or +1 (ahead).
4302         # We stay in as long as we haven't hit an executable line
4303         # ($dbline[$i] == 0 means not executable) and we haven't reached
4304         # the limit yet (test similar to the above).
4305         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4306
4307     } ## end if (@_ >= 2)
4308
4309     # If $i points to a line that is executable, return that.
4310     return $i unless $dbline[$i] == 0;
4311
4312     # Format the message and print it: no breakable lines in range.
4313     my ( $pl, $upto ) = ( '', '' );
4314     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4315
4316     # If there's a filename in filename_error, we'll see it.
4317     # If not, not.
4318     die "Line$pl $from$upto$filename_error not breakable\n";
4319 } ## end sub breakable_line
4320
4321 =head3 breakable_line_in_filename(file, from, to) (API)
4322
4323 Like C<breakable_line>, but look in another file.
4324
4325 =cut
4326
4327 sub breakable_line_in_filename {
4328
4329     # Capture the file name.
4330     my ($f) = shift;
4331
4332     # Swap the magic line array over there temporarily.
4333     local *dbline = $main::{ '_<' . $f };
4334
4335     # If there's an error, it's in this other file.
4336     local $filename_error = " of `$f'";
4337
4338     # Find the breakable line.
4339     breakable_line(@_);
4340
4341     # *dbline and $filename_error get restored when this block ends.
4342
4343 } ## end sub breakable_line_in_filename
4344
4345 =head3 break_on_line(lineno, [condition]) (API)
4346
4347 Adds a breakpoint with the specified condition (or 1 if no condition was 
4348 specified) to the specified line. Dies if it can't.
4349
4350 =cut
4351
4352 sub break_on_line {
4353     my ( $i, $cond ) = @_;
4354
4355     # Always true if no condition supplied.
4356     $cond = 1 unless @_ >= 2;
4357
4358     my $inii  = $i;
4359     my $after = '';
4360     my $pl    = '';
4361
4362     # Woops, not a breakable line. $filename_error allows us to say
4363     # if it was in a different file.
4364     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4365
4366     # Mark this file as having breakpoints in it.
4367     $had_breakpoints{$filename} |= 1;
4368
4369     # If there is an action or condition here already ...
4370     if ( $dbline{$i} ) {
4371
4372         # ... swap this condition for the existing one.
4373         $dbline{$i} =~ s/^[^\0]*/$cond/;
4374     }
4375     else {
4376
4377         # Nothing here - just add the condition.
4378         $dbline{$i} = $cond;
4379     }
4380 } ## end sub break_on_line
4381
4382 =head3 cmd_b_line(line, [condition]) (command)
4383
4384 Wrapper for C<break_on_line>. Prints the failure message if it 
4385 doesn't work.
4386
4387 =cut 
4388
4389 sub cmd_b_line {
4390     eval { break_on_line(@_); 1 } or do {
4391         local $\ = '';
4392         print $OUT $@ and return;
4393     };
4394 } ## end sub cmd_b_line
4395
4396 =head3 break_on_filename_line(file, line, [condition]) (API)
4397
4398 Switches to the file specified and then calls C<break_on_line> to set 
4399 the breakpoint.
4400
4401 =cut
4402
4403 sub break_on_filename_line {
4404     my ( $f, $i, $cond ) = @_;
4405
4406     # Always true if condition left off.
4407     $cond = 1 unless @_ >= 3;
4408
4409     # Switch the magical hash temporarily.
4410     local *dbline = $main::{ '_<' . $f };
4411
4412     # Localize the variables that break_on_line uses to make its message.
4413     local $filename_error = " of `$f'";
4414     local $filename       = $f;
4415
4416     # Add the breakpoint.
4417     break_on_line( $i, $cond );
4418 } ## end sub break_on_filename_line
4419
4420 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4421
4422 Switch to another file, search the range of lines specified for an 
4423 executable one, and put a breakpoint on the first one you find.
4424
4425 =cut
4426
4427 sub break_on_filename_line_range {
4428     my ( $f, $from, $to, $cond ) = @_;
4429
4430     # Find a breakable line if there is one.
4431     my $i = breakable_line_in_filename( $f, $from, $to );
4432
4433     # Always true if missing.
4434     $cond = 1 unless @_ >= 3;
4435
4436     # Add the breakpoint.
4437     break_on_filename_line( $f, $i, $cond );
4438 } ## end sub break_on_filename_line_range
4439
4440 =head3 subroutine_filename_lines(subname, [condition]) (API)
4441
4442 Search for a subroutine within a given file. The condition is ignored.
4443 Uses C<find_sub> to locate the desired subroutine.
4444
4445 =cut
4446
4447 sub subroutine_filename_lines {
4448     my ( $subname, $cond ) = @_;
4449
4450     # Returned value from find_sub() is fullpathname:startline-endline.
4451     # The match creates the list (fullpathname, start, end). Falling off
4452     # the end of the subroutine returns this implicitly.
4453     find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/;
4454 } ## end sub subroutine_filename_lines
4455
4456 =head3 break_subroutine(subname) (API)
4457