This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
f584882196a36fc9c4bf103798a6d4bf1f005c40
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # Needs 'no overloading' to run faster on miniperl.  Code commented out at the
8 # subroutine objaddr can be used instead to work as far back (untested) as
9 # 5.8: needs pack "U".  But almost all occurrences of objaddr have been
10 # removed in favor of using 'no overloading'.  You also would have to go
11 # through and replace occurrences like:
12 #       my $addr = do { no overloading; pack 'J', $self; }
13 # with
14 #       my $addr = main::objaddr $self;
15 # (or reverse commit 9b01bafde4b022706c3d6f947a0963f821b2e50b
16 # that instituted the change to main::objaddr, and subsequent commits that
17 # changed 0+$self to pack 'J', $self.)
18
19 my $start_time;
20 BEGIN { # Get the time the script started running; do it at compiliation to
21         # get it as close as possible
22     $start_time= time;
23 }
24
25
26 require 5.010_001;
27 use strict;
28 use warnings;
29 use Carp;
30 use File::Find;
31 use File::Path;
32 use File::Spec;
33 use Text::Tabs;
34
35 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
36
37 ##########################################################################
38 #
39 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
40 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
41 # a pod file and a .t file
42 #
43 # The structure of this file is:
44 #   First these introductory comments; then
45 #   code needed for everywhere, such as debugging stuff; then
46 #   code to handle input parameters; then
47 #   data structures likely to be of external interest (some of which depend on
48 #       the input parameters, so follows them; then
49 #   more data structures and subroutine and package (class) definitions; then
50 #   the small actual loop to process the input files and finish up; then
51 #   a __DATA__ section, for the .t tests
52 #
53 # This program works on all releases of Unicode through at least 6.0.  The
54 # outputs have been scrutinized most intently for release 5.1.  The others
55 # have been checked for somewhat more than just sanity.  It can handle all
56 # existing Unicode character properties in those releases.
57 #
58 # This program is mostly about Unicode character (or code point) properties.
59 # A property describes some attribute or quality of a code point, like if it
60 # is lowercase or not, its name, what version of Unicode it was first defined
61 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
62 # possibilities by making all properties into mappings from each code point
63 # into some corresponding value.  In the case of it being lowercase or not,
64 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
65 # property maps each Unicode code point to a single value, called a "property
66 # value".  (Hence each Unicode property is a true mathematical function with
67 # exactly one value per code point.)
68 #
69 # When using a property in a regular expression, what is desired isn't the
70 # mapping of the code point to its property's value, but the reverse (or the
71 # mathematical "inverse relation"): starting with the property value, "Does a
72 # code point map to it?"  These are written in a "compound" form:
73 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
74 # files containing the lists of code points that map to each such regular
75 # expression property value, one file per list
76 #
77 # There is also a single form shortcut that Perl adds for many of the commonly
78 # used properties.  This happens for all binary properties, plus script,
79 # general_category, and block properties.
80 #
81 # Thus the outputs of this program are files.  There are map files, mostly in
82 # the 'To' directory; and there are list files for use in regular expression
83 # matching, all in subdirectories of the 'lib' directory, with each
84 # subdirectory being named for the property that the lists in it are for.
85 # Bookkeeping, test, and documentation files are also generated.
86
87 my $matches_directory = 'lib';   # Where match (\p{}) files go.
88 my $map_directory = 'To';        # Where map files go.
89
90 # DATA STRUCTURES
91 #
92 # The major data structures of this program are Property, of course, but also
93 # Table.  There are two kinds of tables, very similar to each other.
94 # "Match_Table" is the data structure giving the list of code points that have
95 # a particular property value, mentioned above.  There is also a "Map_Table"
96 # data structure which gives the property's mapping from code point to value.
97 # There are two structures because the match tables need to be combined in
98 # various ways, such as constructing unions, intersections, complements, etc.,
99 # and the map ones don't.  And there would be problems, perhaps subtle, if
100 # a map table were inadvertently operated on in some of those ways.
101 # The use of separate classes with operations defined on one but not the other
102 # prevents accidentally confusing the two.
103 #
104 # At the heart of each table's data structure is a "Range_List", which is just
105 # an ordered list of "Ranges", plus ancillary information, and methods to
106 # operate on them.  A Range is a compact way to store property information.
107 # Each range has a starting code point, an ending code point, and a value that
108 # is meant to apply to all the code points between the two end points,
109 # inclusive.  For a map table, this value is the property value for those
110 # code points.  Two such ranges could be written like this:
111 #   0x41 .. 0x5A, 'Upper',
112 #   0x61 .. 0x7A, 'Lower'
113 #
114 # Each range also has a type used as a convenience to classify the values.
115 # Most ranges in this program will be Type 0, or normal, but there are some
116 # ranges that have a non-zero type.  These are used only in map tables, and
117 # are for mappings that don't fit into the normal scheme of things.  Mappings
118 # that require a hash entry to communicate with utf8.c are one example;
119 # another example is mappings for charnames.pm to use which indicate a name
120 # that is algorithmically determinable from its code point (and vice-versa).
121 # These are used to significantly compact these tables, instead of listing
122 # each one of the tens of thousands individually.
123 #
124 # In a match table, the value of a range is irrelevant (and hence the type as
125 # well, which will always be 0), and arbitrarily set to the null string.
126 # Using the example above, there would be two match tables for those two
127 # entries, one named Upper would contain the 0x41..0x5A range, and the other
128 # named Lower would contain 0x61..0x7A.
129 #
130 # Actually, there are two types of range lists, "Range_Map" is the one
131 # associated with map tables, and "Range_List" with match tables.
132 # Again, this is so that methods can be defined on one and not the other so as
133 # to prevent operating on them in incorrect ways.
134 #
135 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
136 # in the perl core.  All tables could in theory be written, but some are
137 # suppressed because there is no current practical use for them.  It is easy
138 # to change which get written by changing various lists that are near the top
139 # of the actual code in this file.  The table data structures contain enough
140 # ancillary information to allow them to be treated as separate entities for
141 # writing, such as the path to each one's file.  There is a heading in each
142 # map table that gives the format of its entries, and what the map is for all
143 # the code points missing from it.  (This allows tables to be more compact.)
144 #
145 # The Property data structure contains one or more tables.  All properties
146 # contain a map table (except the $perl property which is a
147 # pseudo-property containing only match tables), and any properties that
148 # are usable in regular expression matches also contain various matching
149 # tables, one for each value the property can have.  A binary property can
150 # have two values, True and False (or Y and N, which are preferred by Unicode
151 # terminology).  Thus each of these properties will have a map table that
152 # takes every code point and maps it to Y or N (but having ranges cuts the
153 # number of entries in that table way down), and two match tables, one
154 # which has a list of all the code points that map to Y, and one for all the
155 # code points that map to N.  (For each of these, a third table is also
156 # generated for the pseudo Perl property.  It contains the identical code
157 # points as the Y table, but can be written, not in the compound form, but in
158 # a "single" form like \p{IsUppercase}.)  Many properties are binary, but some
159 # properties have several possible values, some have many, and properties like
160 # Name have a different value for every named code point.  Those will not,
161 # unless the controlling lists are changed, have their match tables written
162 # out.  But all the ones which can be used in regular expression \p{} and \P{}
163 # constructs will.  Generally a property will have either its map table or its
164 # match tables written but not both.  Again, what gets written is controlled
165 # by lists which can easily be changed.
166 #
167 # For information about the Unicode properties, see Unicode's UAX44 document:
168
169 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
170
171 # As stated earlier, this program will work on any release of Unicode so far.
172 # Most obvious problems in earlier data have NOT been corrected except when
173 # necessary to make Perl or this program work reasonably.  For example, no
174 # folding information was given in early releases, so this program uses the
175 # substitute of lower case, just so that a regular expression with the /i
176 # option will do something that actually gives the right results in many
177 # cases.  There are also a couple other corrections for version 1.1.5,
178 # commented at the point they are made.  As an example of corrections that
179 # weren't made (but could be) is this statement from DerivedAge.txt: "The
180 # supplementary private use code points and the non-character code points were
181 # assigned in version 2.0, but not specifically listed in the UCD until
182 # versions 3.0 and 3.1 respectively."  (To be precise it was 3.0.1 not 3.0.0)
183 # More information on Unicode version glitches is further down in these
184 # introductory comments.
185 #
186 # This program works on all non-provisional properties as of 6.0, though the
187 # files for some are suppressed from apparent lack of demand for them.  You
188 # can change which are output by changing lists in this program.
189 #
190 # The old version of mktables emphasized the term "Fuzzy" to mean Unocde's
191 # loose matchings rules (from Unicode TR18):
192 #
193 #    The recommended names for UCD properties and property values are in
194 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
195 #    [PropValue]. There are both abbreviated names and longer, more
196 #    descriptive names. It is strongly recommended that both names be
197 #    recognized, and that loose matching of property names be used,
198 #    whereby the case distinctions, whitespace, hyphens, and underbar
199 #    are ignored.
200 # The program still allows Fuzzy to override its determination of if loose
201 # matching should be used, but it isn't currently used, as it is no longer
202 # needed; the calculations it makes are good enough.
203 #
204 # SUMMARY OF HOW IT WORKS:
205 #
206 #   Process arguments
207 #
208 #   A list is constructed containing each input file that is to be processed
209 #
210 #   Each file on the list is processed in a loop, using the associated handler
211 #   code for each:
212 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
213 #            first.  These files name the properties and property values.
214 #            Objects are created of all the property and property value names
215 #            that the rest of the input should expect, including all synonyms.
216 #        The other input files give mappings from properties to property
217 #           values.  That is, they list code points and say what the mapping
218 #           is under the given property.  Some files give the mappings for
219 #           just one property; and some for many.  This program goes through
220 #           each file and populates the properties from them.  Some properties
221 #           are listed in more than one file, and Unicode has set up a
222 #           precedence as to which has priority if there is a conflict.  Thus
223 #           the order of processing matters, and this program handles the
224 #           conflict possibility by processing the overriding input files
225 #           last, so that if necessary they replace earlier values.
226 #        After this is all done, the program creates the property mappings not
227 #            furnished by Unicode, but derivable from what it does give.
228 #        The tables of code points that match each property value in each
229 #            property that is accessible by regular expressions are created.
230 #        The Perl-defined properties are created and populated.  Many of these
231 #            require data determined from the earlier steps
232 #        Any Perl-defined synonyms are created, and name clashes between Perl
233 #            and Unicode are reconciled and warned about.
234 #        All the properties are written to files
235 #        Any other files are written, and final warnings issued.
236 #
237 # For clarity, a number of operators have been overloaded to work on tables:
238 #   ~ means invert (take all characters not in the set).  The more
239 #       conventional '!' is not used because of the possibility of confusing
240 #       it with the actual boolean operation.
241 #   + means union
242 #   - means subtraction
243 #   & means intersection
244 # The precedence of these is the order listed.  Parentheses should be
245 # copiously used.  These are not a general scheme.  The operations aren't
246 # defined for a number of things, deliberately, to avoid getting into trouble.
247 # Operations are done on references and affect the underlying structures, so
248 # that the copy constructors for them have been overloaded to not return a new
249 # clone, but the input object itself.
250 #
251 # The bool operator is deliberately not overloaded to avoid confusion with
252 # "should it mean if the object merely exists, or also is non-empty?".
253 #
254 # WHY CERTAIN DESIGN DECISIONS WERE MADE
255 #
256 # This program needs to be able to run under miniperl.  Therefore, it uses a
257 # minimum of other modules, and hence implements some things itself that could
258 # be gotten from CPAN
259 #
260 # This program uses inputs published by the Unicode Consortium.  These can
261 # change incompatibly between releases without the Perl maintainers realizing
262 # it.  Therefore this program is now designed to try to flag these.  It looks
263 # at the directories where the inputs are, and flags any unrecognized files.
264 # It keeps track of all the properties in the files it handles, and flags any
265 # that it doesn't know how to handle.  It also flags any input lines that
266 # don't match the expected syntax, among other checks.
267 #
268 # It is also designed so if a new input file matches one of the known
269 # templates, one hopefully just needs to add it to a list to have it
270 # processed.
271 #
272 # As mentioned earlier, some properties are given in more than one file.  In
273 # particular, the files in the extracted directory are supposedly just
274 # reformattings of the others.  But they contain information not easily
275 # derivable from the other files, including results for Unihan, which this
276 # program doesn't ordinarily look at, and for unassigned code points.  They
277 # also have historically had errors or been incomplete.  In an attempt to
278 # create the best possible data, this program thus processes them first to
279 # glean information missing from the other files; then processes those other
280 # files to override any errors in the extracted ones.  Much of the design was
281 # driven by this need to store things and then possibly override them.
282 #
283 # It tries to keep fatal errors to a minimum, to generate something usable for
284 # testing purposes.  It always looks for files that could be inputs, and will
285 # warn about any that it doesn't know how to handle (the -q option suppresses
286 # the warning).
287 #
288 # Why have files written out for binary 'N' matches?
289 #   For binary properties, if you know the mapping for either Y or N; the
290 #   other is trivial to construct, so could be done at Perl run-time by just
291 #   complementing the result, instead of having a file for it.  That is, if
292 #   someone types in \p{foo: N}, Perl could translate that to \P{foo: Y} and
293 #   not need a file.   The problem is communicating to Perl that a given
294 #   property is binary.  Perl can't figure it out from looking at the N (or
295 #   No), as some non-binary properties have these as property values.  So
296 #   rather than inventing a way to communicate this info back to the core,
297 #   which would have required changes there as well, it was simpler just to
298 #   add the extra tables.
299 #
300 # Why is there more than one type of range?
301 #   This simplified things.  There are some very specialized code points that
302 #   have to be handled specially for output, such as Hangul syllable names.
303 #   By creating a range type (done late in the development process), it
304 #   allowed this to be stored with the range, and overridden by other input.
305 #   Originally these were stored in another data structure, and it became a
306 #   mess trying to decide if a second file that was for the same property was
307 #   overriding the earlier one or not.
308 #
309 # Why are there two kinds of tables, match and map?
310 #   (And there is a base class shared by the two as well.)  As stated above,
311 #   they actually are for different things.  Development proceeded much more
312 #   smoothly when I (khw) realized the distinction.  Map tables are used to
313 #   give the property value for every code point (actually every code point
314 #   that doesn't map to a default value).  Match tables are used for regular
315 #   expression matches, and are essentially the inverse mapping.  Separating
316 #   the two allows more specialized methods, and error checks so that one
317 #   can't just take the intersection of two map tables, for example, as that
318 #   is nonsensical.
319 #
320 # There are no match tables generated for matches of the null string.  These
321 # would look like qr/\p{JSN=}/ currently without modifying the regex code.
322 # Perhaps something like them could be added if necessary.  The JSN does have
323 # a real code point U+110B that maps to the null string, but it is a
324 # contributory property, and therefore not output by default.  And it's easily
325 # handled so far by making the null string the default where it is a
326 # possibility.
327 #
328 # DEBUGGING
329 #
330 # This program is written so it will run under miniperl.  Occasionally changes
331 # will cause an error where the backtrace doesn't work well under miniperl.
332 # To diagnose the problem, you can instead run it under regular perl, if you
333 # have one compiled.
334 #
335 # There is a good trace facility.  To enable it, first sub DEBUG must be set
336 # to return true.  Then a line like
337 #
338 # local $to_trace = 1 if main::DEBUG;
339 #
340 # can be added to enable tracing in its lexical scope or until you insert
341 # another line:
342 #
343 # local $to_trace = 0 if main::DEBUG;
344 #
345 # then use a line like "trace $a, @b, %c, ...;
346 #
347 # Some of the more complex subroutines already have trace statements in them.
348 # Permanent trace statements should be like:
349 #
350 # trace ... if main::DEBUG && $to_trace;
351 #
352 # If there is just one or a few files that you're debugging, you can easily
353 # cause most everything else to be skipped.  Change the line
354 #
355 # my $debug_skip = 0;
356 #
357 # to 1, and every file whose object is in @input_file_objects and doesn't have
358 # a, 'non_skip => 1,' in its constructor will be skipped.
359 #
360 # To compare the output tables, it may be useful to specify the -annotate
361 # flag.  This causes the tables to expand so there is one entry for each
362 # non-algorithmically named code point giving, currently its name, and its
363 # graphic representation if printable (and you have a font that knows about
364 # it).  This makes it easier to see what the particular code points are in
365 # each output table.  The tables are usable, but because they don't have
366 # ranges (for the most part), a Perl using them will run slower.  Non-named
367 # code points are annotated with a description of their status, and contiguous
368 # ones with the same description will be output as a range rather than
369 # individually.  Algorithmically named characters are also output as ranges,
370 # except when there are just a few contiguous ones.
371 #
372 # FUTURE ISSUES
373 #
374 # The program would break if Unicode were to change its names so that
375 # interior white space, underscores, or dashes differences were significant
376 # within property and property value names.
377 #
378 # It might be easier to use the xml versions of the UCD if this program ever
379 # would need heavy revision, and the ability to handle old versions was not
380 # required.
381 #
382 # There is the potential for name collisions, in that Perl has chosen names
383 # that Unicode could decide it also likes.  There have been such collisions in
384 # the past, with mostly Perl deciding to adopt the Unicode definition of the
385 # name.  However in the 5.2 Unicode beta testing, there were a number of such
386 # collisions, which were withdrawn before the final release, because of Perl's
387 # and other's protests.  These all involved new properties which began with
388 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
389 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
390 # Unicode document, so they are unlikely to be used by Unicode for another
391 # purpose.  However, they might try something beginning with 'In', or use any
392 # of the other Perl-defined properties.  This program will warn you of name
393 # collisions, and refuse to generate tables with them, but manual intervention
394 # will be required in this event.  One scheme that could be implemented, if
395 # necessary, would be to have this program generate another file, or add a
396 # field to mktables.lst that gives the date of first definition of a property.
397 # Each new release of Unicode would use that file as a basis for the next
398 # iteration.  And the Perl synonym addition code could sort based on the age
399 # of the property, so older properties get priority, and newer ones that clash
400 # would be refused; hence existing code would not be impacted, and some other
401 # synonym would have to be used for the new property.  This is ugly, and
402 # manual intervention would certainly be easier to do in the short run; lets
403 # hope it never comes to this.
404 #
405 # A NOTE ON UNIHAN
406 #
407 # This program can generate tables from the Unihan database.  But it doesn't
408 # by default, letting the CPAN module Unicode::Unihan handle them.  Prior to
409 # version 5.2, this database was in a single file, Unihan.txt.  In 5.2 the
410 # database was split into 8 different files, all beginning with the letters
411 # 'Unihan'.  This program will read those file(s) if present, but it needs to
412 # know which of the many properties in the file(s) should have tables created
413 # for them.  It will create tables for any properties listed in
414 # PropertyAliases.txt and PropValueAliases.txt, plus any listed in the
415 # @cjk_properties array and the @cjk_property_values array.  Thus, if a
416 # property you want is not in those files of the release you are building
417 # against, you must add it to those two arrays.  Starting in 4.0, the
418 # Unicode_Radical_Stroke was listed in those files, so if the Unihan database
419 # is present in the directory, a table will be generated for that property.
420 # In 5.2, several more properties were added.  For your convenience, the two
421 # arrays are initialized with all the 6.0 listed properties that are also in
422 # earlier releases.  But these are commented out.  You can just uncomment the
423 # ones you want, or use them as a template for adding entries for other
424 # properties.
425 #
426 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
427 # and filter_unihan_line() are the functions where this is done.  This program
428 # already does some adjusting to make the lines look more like the rest of the
429 # Unicode DB;  You can see what that is in filter_unihan_line()
430 #
431 # There is a bug in the 3.2 data file in which some values for the
432 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
433 # could be added for these; or for a particular installation, the Unihan.txt
434 # file could be edited to fix them.
435 #
436 # HOW TO ADD A FILE TO BE PROCESSED
437 #
438 # A new file from Unicode needs to have an object constructed for it in
439 # @input_file_objects, probably at the end or at the end of the extracted
440 # ones.  The program should warn you if its name will clash with others on
441 # restrictive file systems, like DOS.  If so, figure out a better name, and
442 # add lines to the README.perl file giving that.  If the file is a character
443 # property, it should be in the format that Unicode has by default
444 # standardized for such files for the more recently introduced ones.
445 # If so, the Input_file constructor for @input_file_objects can just be the
446 # file name and release it first appeared in.  If not, then it should be
447 # possible to construct an each_line_handler() to massage the line into the
448 # standardized form.
449 #
450 # For non-character properties, more code will be needed.  You can look at
451 # the existing entries for clues.
452 #
453 # UNICODE VERSIONS NOTES
454 #
455 # The Unicode UCD has had a number of errors in it over the versions.  And
456 # these remain, by policy, in the standard for that version.  Therefore it is
457 # risky to correct them, because code may be expecting the error.  So this
458 # program doesn't generally make changes, unless the error breaks the Perl
459 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
460 # for U+1105, which causes real problems for the algorithms for Jamo
461 # calculations, so it is changed here.
462 #
463 # But it isn't so clear cut as to what to do about concepts that are
464 # introduced in a later release; should they extend back to earlier releases
465 # where the concept just didn't exist?  It was easier to do this than to not,
466 # so that's what was done.  For example, the default value for code points not
467 # in the files for various properties was probably undefined until changed by
468 # some version.  No_Block for blocks is such an example.  This program will
469 # assign No_Block even in Unicode versions that didn't have it.  This has the
470 # benefit that code being written doesn't have to special case earlier
471 # versions; and the detriment that it doesn't match the Standard precisely for
472 # the affected versions.
473 #
474 # Here are some observations about some of the issues in early versions:
475 #
476 # The number of code points in \p{alpha} halve in 2.1.9.  It turns out that
477 # the reason is that the CJK block starting at 4E00 was removed from PropList,
478 # and was not put back in until 3.1.0
479 #
480 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
481 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
482 # reason is that 3.2 introduced U+205F=medium math space, which was not
483 # classed as white space, but Perl figured out that it should have been. 4.0
484 # reclassified it correctly.
485 #
486 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
487 # this was erroneously a synonym for 202.  In 4.0, ATB became 202, and ATBL
488 # was left with no code points, as all the ones that mapped to 202 stayed
489 # mapped to 202.  Thus if your program used the numeric name for the class,
490 # it would not have been affected, but if it used the mnemonic, it would have
491 # been.
492 #
493 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that code
494 # points which eventually came to have this script property value, instead
495 # mapped to "Unknown".  But in the next release all these code points were
496 # moved to \p{sc=common} instead.
497 #
498 # The default for missing code points for BidiClass is complicated.  Starting
499 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
500 # tries to do the best it can for earlier releases.  It is done in
501 # process_PropertyAliases()
502 #
503 ##############################################################################
504
505 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
506                         # and errors
507 my $MAX_LINE_WIDTH = 78;
508
509 # Debugging aid to skip most files so as to not be distracted by them when
510 # concentrating on the ones being debugged.  Add
511 # non_skip => 1,
512 # to the constructor for those files you want processed when you set this.
513 # Files with a first version number of 0 are special: they are always
514 # processed regardless of the state of this flag.
515 my $debug_skip = 0;
516
517 # Set to 1 to enable tracing.
518 our $to_trace = 0;
519
520 { # Closure for trace: debugging aid
521     my $print_caller = 1;        # ? Include calling subroutine name
522     my $main_with_colon = 'main::';
523     my $main_colon_length = length($main_with_colon);
524
525     sub trace {
526         return unless $to_trace;        # Do nothing if global flag not set
527
528         my @input = @_;
529
530         local $DB::trace = 0;
531         $DB::trace = 0;          # Quiet 'used only once' message
532
533         my $line_number;
534
535         # Loop looking up the stack to get the first non-trace caller
536         my $caller_line;
537         my $caller_name;
538         my $i = 0;
539         do {
540             $line_number = $caller_line;
541             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
542             $caller = $main_with_colon unless defined $caller;
543
544             $caller_name = $caller;
545
546             # get rid of pkg
547             $caller_name =~ s/.*:://;
548             if (substr($caller_name, 0, $main_colon_length)
549                 eq $main_with_colon)
550             {
551                 $caller_name = substr($caller_name, $main_colon_length);
552             }
553
554         } until ($caller_name ne 'trace');
555
556         # If the stack was empty, we were called from the top level
557         $caller_name = 'main' if ($caller_name eq ""
558                                     || $caller_name eq 'trace');
559
560         my $output = "";
561         foreach my $string (@input) {
562             #print STDERR __LINE__, ": ", join ", ", @input, "\n";
563             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
564                 $output .= simple_dumper($string);
565             }
566             else {
567                 $string = "$string" if ref $string;
568                 $string = $UNDEF unless defined $string;
569                 chomp $string;
570                 $string = '""' if $string eq "";
571                 $output .= " " if $output ne ""
572                                 && $string ne ""
573                                 && substr($output, -1, 1) ne " "
574                                 && substr($string, 0, 1) ne " ";
575                 $output .= $string;
576             }
577         }
578
579         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
580         print STDERR "$caller_name: " if $print_caller;
581         print STDERR $output, "\n";
582         return;
583     }
584 }
585
586 # This is for a rarely used development feature that allows you to compare two
587 # versions of the Unicode standard without having to deal with changes caused
588 # by the code points introduced in the later verson.  Change the 0 to a SINGLE
589 # dotted Unicode release number (e.g. 2.1).  Only code points introduced in
590 # that release and earlier will be used; later ones are thrown away.  You use
591 # the version number of the earliest one you want to compare; then run this
592 # program on directory structures containing each release, and compare the
593 # outputs.  These outputs will therefore include only the code points common
594 # to both releases, and you can see the changes caused just by the underlying
595 # release semantic changes.  For versions earlier than 3.2, you must copy a
596 # version of DAge.txt into the directory.
597 my $string_compare_versions = DEBUG && 0; #  e.g., v2.1;
598 my $compare_versions = DEBUG
599                        && $string_compare_versions
600                        && pack "C*", split /\./, $string_compare_versions;
601
602 sub uniques {
603     # Returns non-duplicated input values.  From "Perl Best Practices:
604     # Encapsulated Cleverness".  p. 455 in first edition.
605
606     my %seen;
607     # Arguably this breaks encapsulation, if the goal is to permit multiple
608     # distinct objects to stringify to the same value, and be interchangeable.
609     # However, for this program, no two objects stringify identically, and all
610     # lists passed to this function are either objects or strings. So this
611     # doesn't affect correctness, but it does give a couple of percent speedup.
612     no overloading;
613     return grep { ! $seen{$_}++ } @_;
614 }
615
616 $0 = File::Spec->canonpath($0);
617
618 my $make_test_script = 0;      # ? Should we output a test script
619 my $write_unchanged_files = 0; # ? Should we update the output files even if
620                                #    we don't think they have changed
621 my $use_directory = "";        # ? Should we chdir somewhere.
622 my $pod_directory;             # input directory to store the pod file.
623 my $pod_file = 'perluniprops';
624 my $t_path;                     # Path to the .t test file
625 my $file_list = 'mktables.lst'; # File to store input and output file names.
626                                # This is used to speed up the build, by not
627                                # executing the main body of the program if
628                                # nothing on the list has changed since the
629                                # previous build
630 my $make_list = 1;             # ? Should we write $file_list.  Set to always
631                                # make a list so that when the pumpking is
632                                # preparing a release, s/he won't have to do
633                                # special things
634 my $glob_list = 0;             # ? Should we try to include unknown .txt files
635                                # in the input.
636 my $output_range_counts = 1;   # ? Should we include the number of code points
637                                # in ranges in the output
638 my $annotate = 0;              # ? Should character names be in the output
639
640 # Verbosity levels; 0 is quiet
641 my $NORMAL_VERBOSITY = 1;
642 my $PROGRESS = 2;
643 my $VERBOSE = 3;
644
645 my $verbosity = $NORMAL_VERBOSITY;
646
647 # Process arguments
648 while (@ARGV) {
649     my $arg = shift @ARGV;
650     if ($arg eq '-v') {
651         $verbosity = $VERBOSE;
652     }
653     elsif ($arg eq '-p') {
654         $verbosity = $PROGRESS;
655         $| = 1;     # Flush buffers as we go.
656     }
657     elsif ($arg eq '-q') {
658         $verbosity = 0;
659     }
660     elsif ($arg eq '-w') {
661         $write_unchanged_files = 1; # update the files even if havent changed
662     }
663     elsif ($arg eq '-check') {
664         my $this = shift @ARGV;
665         my $ok = shift @ARGV;
666         if ($this ne $ok) {
667             print "Skipping as check params are not the same.\n";
668             exit(0);
669         }
670     }
671     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
672         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
673     }
674     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
675     {
676         $make_test_script = 1;
677     }
678     elsif ($arg eq '-makelist') {
679         $make_list = 1;
680     }
681     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
682         -d $use_directory or croak "Unknown directory '$use_directory'";
683     }
684     elsif ($arg eq '-L') {
685
686         # Existence not tested until have chdir'd
687         $file_list = shift;
688     }
689     elsif ($arg eq '-globlist') {
690         $glob_list = 1;
691     }
692     elsif ($arg eq '-c') {
693         $output_range_counts = ! $output_range_counts
694     }
695     elsif ($arg eq '-annotate') {
696         $annotate = 1;
697     }
698     else {
699         my $with_c = 'with';
700         $with_c .= 'out' if $output_range_counts;   # Complements the state
701         croak <<END;
702 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
703           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
704           [-check A B ]
705   -c          : Output comments $with_c number of code points in ranges
706   -q          : Quiet Mode: Only output serious warnings.
707   -p          : Set verbosity level to normal plus show progress.
708   -v          : Set Verbosity level high:  Show progress and non-serious
709                 warnings
710   -w          : Write files regardless
711   -C dir      : Change to this directory before proceeding. All relative paths
712                 except those specified by the -P and -T options will be done
713                 with respect to this directory.
714   -P dir      : Output $pod_file file to directory 'dir'.
715   -T path     : Create a test script as 'path'; overrides -maketest
716   -L filelist : Use alternate 'filelist' instead of standard one
717   -globlist   : Take as input all non-Test *.txt files in current and sub
718                 directories
719   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
720                 overrides -T
721   -makelist   : Rewrite the file list $file_list based on current setup
722   -annotate   : Output an annotation for each character in the table files;
723                 useful for debugging mktables, looking at diffs; but is slow,
724                 memory intensive; resulting tables are usable but slow and
725                 very large.
726   -check A B  : Executes $0 only if A and B are the same
727 END
728     }
729 }
730
731 # Stores the most-recently changed file.  If none have changed, can skip the
732 # build
733 my $most_recent = (stat $0)[9];   # Do this before the chdir!
734
735 # Change directories now, because need to read 'version' early.
736 if ($use_directory) {
737     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
738         $pod_directory = File::Spec->rel2abs($pod_directory);
739     }
740     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
741         $t_path = File::Spec->rel2abs($t_path);
742     }
743     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
744     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
745         $pod_directory = File::Spec->abs2rel($pod_directory);
746     }
747     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
748         $t_path = File::Spec->abs2rel($t_path);
749     }
750 }
751
752 # Get Unicode version into regular and v-string.  This is done now because
753 # various tables below get populated based on it.  These tables are populated
754 # here to be near the top of the file, and so easily seeable by those needing
755 # to modify things.
756 open my $VERSION, "<", "version"
757                     or croak "$0: can't open required file 'version': $!\n";
758 my $string_version = <$VERSION>;
759 close $VERSION;
760 chomp $string_version;
761 my $v_version = pack "C*", split /\./, $string_version;        # v string
762
763 # The following are the complete names of properties with property values that
764 # are known to not match any code points in some versions of Unicode, but that
765 # may change in the future so they should be matchable, hence an empty file is
766 # generated for them.
767 my @tables_that_may_be_empty = (
768                                 'Joining_Type=Left_Joining',
769                                 );
770 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
771 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
772 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
773                                                     if $v_version ge v4.1.0;
774
775 # The lists below are hashes, so the key is the item in the list, and the
776 # value is the reason why it is in the list.  This makes generation of
777 # documentation easier.
778
779 my %why_suppressed;  # No file generated for these.
780
781 # Files aren't generated for empty extraneous properties.  This is arguable.
782 # Extraneous properties generally come about because a property is no longer
783 # used in a newer version of Unicode.  If we generated a file without code
784 # points, programs that used to work on that property will still execute
785 # without errors.  It just won't ever match (or will always match, with \P{}).
786 # This means that the logic is now likely wrong.  I (khw) think its better to
787 # find this out by getting an error message.  Just move them to the table
788 # above to change this behavior
789 my %why_suppress_if_empty_warn_if_not = (
790
791    # It is the only property that has ever officially been removed from the
792    # Standard.  The database never contained any code points for it.
793    'Special_Case_Condition' => 'Obsolete',
794
795    # Apparently never official, but there were code points in some versions of
796    # old-style PropList.txt
797    'Non_Break' => 'Obsolete',
798 );
799
800 # These would normally go in the warn table just above, but they were changed
801 # a long time before this program was written, so warnings about them are
802 # moot.
803 if ($v_version gt v3.2.0) {
804     push @tables_that_may_be_empty,
805                                 'Canonical_Combining_Class=Attached_Below_Left'
806 }
807
808 # These are listed in the Property aliases file in 6.0, but Unihan is ignored
809 # unless explicitly added.
810 if ($v_version ge v5.2.0) {
811     my $unihan = 'Unihan; remove from list if using Unihan';
812     foreach my $table (qw (
813                            kAccountingNumeric
814                            kOtherNumeric
815                            kPrimaryNumeric
816                            kCompatibilityVariant
817                            kIICore
818                            kIRG_GSource
819                            kIRG_HSource
820                            kIRG_JSource
821                            kIRG_KPSource
822                            kIRG_MSource
823                            kIRG_KSource
824                            kIRG_TSource
825                            kIRG_USource
826                            kIRG_VSource
827                            kRSUnicode
828                         ))
829     {
830         $why_suppress_if_empty_warn_if_not{$table} = $unihan;
831     }
832 }
833
834 # Properties that this program ignores.
835 my @unimplemented_properties = (
836 'Unicode_Radical_Stroke'    # Remove if changing to handle this one.
837 );
838
839 # There are several types of obsolete properties defined by Unicode.  These
840 # must be hand-edited for every new Unicode release.
841 my %why_deprecated;  # Generates a deprecated warning message if used.
842 my %why_stabilized;  # Documentation only
843 my %why_obsolete;    # Documentation only
844
845 {   # Closure
846     my $simple = 'Perl uses the more complete version of this property';
847     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
848
849     my $other_properties = 'other properties';
850     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
851     my $why_no_expand  = "Deprecated by Unicode: less useful than UTF-specific calculations",
852
853     %why_deprecated = (
854         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
855         'Jamo_Short_Name' => $contributory,
856         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
857         'Other_Alphabetic' => $contributory,
858         'Other_Default_Ignorable_Code_Point' => $contributory,
859         'Other_Grapheme_Extend' => $contributory,
860         'Other_ID_Continue' => $contributory,
861         'Other_ID_Start' => $contributory,
862         'Other_Lowercase' => $contributory,
863         'Other_Math' => $contributory,
864         'Other_Uppercase' => $contributory,
865     );
866
867     %why_suppressed = (
868         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
869         # contains the same information, but without the algorithmically
870         # determinable Hangul syllables'.  This file is not published, so it's
871         # existence is not noted in the comment.
872         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize',
873
874         'ISO_Comment' => 'Apparently no demand for it, but can access it through Unicode::UCD::charinfo.  Obsoleted, and code points for it removed in Unicode 5.2',
875         'Unicode_1_Name' => "$simple, and no apparent demand for it, but can access it through Unicode::UCD::charinfo.  If there is no later name for a code point, then this one is used instead in charnames",
876
877         'Simple_Case_Folding' => "$simple.  Can access this through Unicode::UCD::casefold",
878         'Simple_Lowercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
879         'Simple_Titlecase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
880         'Simple_Uppercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
881
882         'Name' => "Accessible via 'use charnames;'",
883         'Name_Alias' => "Accessible via 'use charnames;'",
884
885         FC_NFKC_Closure => 'Supplanted in usage by NFKC_Casefold; otherwise not useful',
886         Expands_On_NFC => $why_no_expand,
887         Expands_On_NFD => $why_no_expand,
888         Expands_On_NFKC => $why_no_expand,
889         Expands_On_NFKD => $why_no_expand,
890     );
891
892     # The following are suppressed because they were made contributory or
893     # deprecated by Unicode before Perl ever thought about supporting them.
894     foreach my $property ('Jamo_Short_Name', 'Grapheme_Link') {
895         $why_suppressed{$property} = $why_deprecated{$property};
896     }
897
898     # Customize the message for all the 'Other_' properties
899     foreach my $property (keys %why_deprecated) {
900         next if (my $main_property = $property) !~ s/^Other_//;
901         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
902     }
903 }
904
905 if ($v_version ge 4.0.0) {
906     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
907     if ($v_version ge 6.0.0) {
908         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
909     }
910 }
911 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
912     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
913     if ($v_version ge 6.0.0) {
914         $why_deprecated{'ISO_Comment'} = 'No longer needed for chart generation; otherwise not useful, and code points for it have been removed';
915     }
916 }
917
918 # Probably obsolete forever
919 if ($v_version ge v4.1.0) {
920     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common"';
921 }
922
923 # This program can create files for enumerated-like properties, such as
924 # 'Numeric_Type'.  This file would be the same format as for a string
925 # property, with a mapping from code point to its value, so you could look up,
926 # for example, the script a code point is in.  But no one so far wants this
927 # mapping, or they have found another way to get it since this is a new
928 # feature.  So no file is generated except if it is in this list.
929 my @output_mapped_properties = split "\n", <<END;
930 END
931
932 # If you are using the Unihan database, you need to add the properties that
933 # you want to extract from it to this table.  For your convenience, the
934 # properties in the 6.0 PropertyAliases.txt file are listed, commented out
935 my @cjk_properties = split "\n", <<'END';
936 #cjkAccountingNumeric; kAccountingNumeric
937 #cjkOtherNumeric; kOtherNumeric
938 #cjkPrimaryNumeric; kPrimaryNumeric
939 #cjkCompatibilityVariant; kCompatibilityVariant
940 #cjkIICore ; kIICore
941 #cjkIRG_GSource; kIRG_GSource
942 #cjkIRG_HSource; kIRG_HSource
943 #cjkIRG_JSource; kIRG_JSource
944 #cjkIRG_KPSource; kIRG_KPSource
945 #cjkIRG_KSource; kIRG_KSource
946 #cjkIRG_TSource; kIRG_TSource
947 #cjkIRG_USource; kIRG_USource
948 #cjkIRG_VSource; kIRG_VSource
949 #cjkRSUnicode; kRSUnicode                ; Unicode_Radical_Stroke; URS
950 END
951
952 # Similarly for the property values.  For your convenience, the lines in the
953 # 6.0 PropertyAliases.txt file are listed.  Just remove the first BUT NOT both
954 # '#' marks
955 my @cjk_property_values = split "\n", <<'END';
956 ## @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
957 ## @missing: 0000..10FFFF; cjkCompatibilityVariant; <code point>
958 ## @missing: 0000..10FFFF; cjkIICore; <none>
959 ## @missing: 0000..10FFFF; cjkIRG_GSource; <none>
960 ## @missing: 0000..10FFFF; cjkIRG_HSource; <none>
961 ## @missing: 0000..10FFFF; cjkIRG_JSource; <none>
962 ## @missing: 0000..10FFFF; cjkIRG_KPSource; <none>
963 ## @missing: 0000..10FFFF; cjkIRG_KSource; <none>
964 ## @missing: 0000..10FFFF; cjkIRG_TSource; <none>
965 ## @missing: 0000..10FFFF; cjkIRG_USource; <none>
966 ## @missing: 0000..10FFFF; cjkIRG_VSource; <none>
967 ## @missing: 0000..10FFFF; cjkOtherNumeric; NaN
968 ## @missing: 0000..10FFFF; cjkPrimaryNumeric; NaN
969 ## @missing: 0000..10FFFF; cjkRSUnicode; <none>
970 END
971
972 # The input files don't list every code point.  Those not listed are to be
973 # defaulted to some value.  Below are hard-coded what those values are for
974 # non-binary properties as of 5.1.  Starting in 5.0, there are
975 # machine-parsable comment lines in the files the give the defaults; so this
976 # list shouldn't have to be extended.  The claim is that all missing entries
977 # for binary properties will default to 'N'.  Unicode tried to change that in
978 # 5.2, but the beta period produced enough protest that they backed off.
979 #
980 # The defaults for the fields that appear in UnicodeData.txt in this hash must
981 # be in the form that it expects.  The others may be synonyms.
982 my $CODE_POINT = '<code point>';
983 my %default_mapping = (
984     Age => "Unassigned",
985     # Bidi_Class => Complicated; set in code
986     Bidi_Mirroring_Glyph => "",
987     Block => 'No_Block',
988     Canonical_Combining_Class => 0,
989     Case_Folding => $CODE_POINT,
990     Decomposition_Mapping => $CODE_POINT,
991     Decomposition_Type => 'None',
992     East_Asian_Width => "Neutral",
993     FC_NFKC_Closure => $CODE_POINT,
994     General_Category => 'Cn',
995     Grapheme_Cluster_Break => 'Other',
996     Hangul_Syllable_Type => 'NA',
997     ISO_Comment => "",
998     Jamo_Short_Name => "",
999     Joining_Group => "No_Joining_Group",
1000     # Joining_Type => Complicated; set in code
1001     kIICore => 'N',   #                       Is converted to binary
1002     #Line_Break => Complicated; set in code
1003     Lowercase_Mapping => $CODE_POINT,
1004     Name => "",
1005     Name_Alias => "",
1006     NFC_QC => 'Yes',
1007     NFD_QC => 'Yes',
1008     NFKC_QC => 'Yes',
1009     NFKD_QC => 'Yes',
1010     Numeric_Type => 'None',
1011     Numeric_Value => 'NaN',
1012     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1013     Sentence_Break => 'Other',
1014     Simple_Case_Folding => $CODE_POINT,
1015     Simple_Lowercase_Mapping => $CODE_POINT,
1016     Simple_Titlecase_Mapping => $CODE_POINT,
1017     Simple_Uppercase_Mapping => $CODE_POINT,
1018     Titlecase_Mapping => $CODE_POINT,
1019     Unicode_1_Name => "",
1020     Unicode_Radical_Stroke => "",
1021     Uppercase_Mapping => $CODE_POINT,
1022     Word_Break => 'Other',
1023 );
1024
1025 # Below are files that Unicode furnishes, but this program ignores, and why
1026 my %ignored_files = (
1027     'CJKRadicals.txt' => 'Unihan data',
1028     'Index.txt' => 'An index, not actual data',
1029     'NamedSqProv.txt' => 'Not officially part of the Unicode standard; Append it to NamedSequences.txt if you want to process the contents.',
1030     'NamesList.txt' => 'Just adds commentary',
1031     'NormalizationCorrections.txt' => 'Data is already in other files.',
1032     'Props.txt' => 'Adds nothing to PropList.txt; only in very early releases',
1033     'ReadMe.txt' => 'Just comments',
1034     'README.TXT' => 'Just comments',
1035     'StandardizedVariants.txt' => 'Only for glyph changes, not a Unicode character property.  Does not fit into current scheme where one code point is mapped',
1036     'EmojiSources.txt' => 'Not of general utility: for Japanese legacy cell-phone applications',
1037     'IndicMatraCategory.txt' => 'Provisional',
1038     'IndicSyllabicCategory.txt' => 'Provisional',
1039     'ScriptExtensions.txt' => 'Provisional',
1040 );
1041
1042 ### End of externally interesting definitions, except for @input_file_objects
1043
1044 my $HEADER=<<"EOF";
1045 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1046 # This file is machine-generated by $0 from the Unicode
1047 # database, Version $string_version.  Any changes made here will be lost!
1048 EOF
1049
1050 my $INTERNAL_ONLY=<<"EOF";
1051
1052 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1053 # This file is for internal use by the Perl program only.  The format and even
1054 # the name or existence of this file are subject to change without notice.
1055 # Don't use it directly.
1056 EOF
1057
1058 my $DEVELOPMENT_ONLY=<<"EOF";
1059 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1060 # This file contains information artificially constrained to code points
1061 # present in Unicode release $string_compare_versions.
1062 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1063 # not be used for production.
1064
1065 EOF
1066
1067 my $LAST_UNICODE_CODEPOINT_STRING = "10FFFF";
1068 my $LAST_UNICODE_CODEPOINT = hex $LAST_UNICODE_CODEPOINT_STRING;
1069 my $MAX_UNICODE_CODEPOINTS = $LAST_UNICODE_CODEPOINT + 1;
1070
1071 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1072 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1073 # to decrease backtracking
1074 my $code_point_re =
1075         qr/ \b (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1076
1077 # This matches the beginning of the line in the Unicode db files that give the
1078 # defaults for code points not listed (i.e., missing) in the file.  The code
1079 # depends on this ending with a semi-colon, so it can assume it is a valid
1080 # field when the line is split() by semi-colons
1081 my $missing_defaults_prefix =
1082             qr/^#\s+\@missing:\s+0000\.\.$LAST_UNICODE_CODEPOINT_STRING\s*;/;
1083
1084 # Property types.  Unicode has more types, but these are sufficient for our
1085 # purposes.
1086 my $UNKNOWN = -1;   # initialized to illegal value
1087 my $NON_STRING = 1; # Either binary or enum
1088 my $BINARY = 2;
1089 my $ENUM = 3;       # Include catalog
1090 my $STRING = 4;     # Anything else: string or misc
1091
1092 # Some input files have lines that give default values for code points not
1093 # contained in the file.  Sometimes these should be ignored.
1094 my $NO_DEFAULTS = 0;        # Must evaluate to false
1095 my $NOT_IGNORED = 1;
1096 my $IGNORED = 2;
1097
1098 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1099 # and will appear in the main body of the tables in the output files, but
1100 # there are other types of ranges as well, listed below, that are specially
1101 # handled.   There are pseudo-types as well that will never be stored as a
1102 # type, but will affect the calculation of the type.
1103
1104 # 0 is for normal, non-specials
1105 my $MULTI_CP = 1;           # Sequence of more than code point
1106 my $HANGUL_SYLLABLE = 2;
1107 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1108 my $NULL = 4;               # The map is to the null string; utf8.c can't
1109                             # handle these, nor is there an accepted syntax
1110                             # for them in \p{} constructs
1111 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1112                              # otherwise be $MULTI_CP type are instead type 0
1113
1114 # process_generic_property_file() can accept certain overrides in its input.
1115 # Each of these must begin AND end with $CMD_DELIM.
1116 my $CMD_DELIM = "\a";
1117 my $REPLACE_CMD = 'replace';    # Override the Replace
1118 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1119
1120 my $NO = 0;
1121 my $YES = 1;
1122
1123 # Values for the Replace argument to add_range.
1124 # $NO                      # Don't replace; add only the code points not
1125                            # already present.
1126 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1127                            # the comments at the subroutine definition.
1128 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1129 my $MULTIPLE = 4;          # Don't replace, but add a duplicate record if
1130                            # already there
1131
1132 # Flags to give property statuses.  The phrases are to remind maintainers that
1133 # if the flag is changed, the indefinite article referring to it in the
1134 # documentation may need to be as well.
1135 my $NORMAL = "";
1136 my $SUPPRESSED = 'z';   # The character should never actually be seen, since
1137                         # it is suppressed
1138 my $PLACEHOLDER = 'P';  # Implies no pod entry generated
1139 my $DEPRECATED = 'D';
1140 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1141 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1142 my $DISCOURAGED = 'X';
1143 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1144 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1145 my $STRICTER = 'T';
1146 my $a_bold_stricter = "a 'B<$STRICTER>'";
1147 my $A_bold_stricter = "A 'B<$STRICTER>'";
1148 my $STABILIZED = 'S';
1149 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1150 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1151 my $OBSOLETE = 'O';
1152 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1153 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1154
1155 my %status_past_participles = (
1156     $DISCOURAGED => 'discouraged',
1157     $SUPPRESSED => 'should never be generated',
1158     $STABILIZED => 'stabilized',
1159     $OBSOLETE => 'obsolete',
1160     $DEPRECATED => 'deprecated',
1161 );
1162
1163 # The format of the values of the tables:
1164 my $EMPTY_FORMAT = "";
1165 my $BINARY_FORMAT = 'b';
1166 my $DECIMAL_FORMAT = 'd';
1167 my $FLOAT_FORMAT = 'f';
1168 my $INTEGER_FORMAT = 'i';
1169 my $HEX_FORMAT = 'x';
1170 my $RATIONAL_FORMAT = 'r';
1171 my $STRING_FORMAT = 's';
1172 my $DECOMP_STRING_FORMAT = 'c';
1173
1174 my %map_table_formats = (
1175     $BINARY_FORMAT => 'binary',
1176     $DECIMAL_FORMAT => 'single decimal digit',
1177     $FLOAT_FORMAT => 'floating point number',
1178     $INTEGER_FORMAT => 'integer',
1179     $HEX_FORMAT => 'positive hex whole number; a code point',
1180     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1181     $STRING_FORMAT => 'string',
1182     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1183 );
1184
1185 # Unicode didn't put such derived files in a separate directory at first.
1186 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1187 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1188 my $AUXILIARY = 'auxiliary';
1189
1190 # Hashes that will eventually go into Heavy.pl for the use of utf8_heavy.pl
1191 my %loose_to_file_of;       # loosely maps table names to their respective
1192                             # files
1193 my %stricter_to_file_of;    # same; but for stricter mapping.
1194 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1195                              # their rational equivalent
1196 my %loose_property_name_of; # Loosely maps property names to standard form
1197
1198 # These constants names and values were taken from the Unicode standard,
1199 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1200 # syllables.  The '_string' versions are so generated tables can retain the
1201 # hex format, which is the more familiar value
1202 my $SBase_string = "0xAC00";
1203 my $SBase = CORE::hex $SBase_string;
1204 my $LBase_string = "0x1100";
1205 my $LBase = CORE::hex $LBase_string;
1206 my $VBase_string = "0x1161";
1207 my $VBase = CORE::hex $VBase_string;
1208 my $TBase_string = "0x11A7";
1209 my $TBase = CORE::hex $TBase_string;
1210 my $SCount = 11172;
1211 my $LCount = 19;
1212 my $VCount = 21;
1213 my $TCount = 28;
1214 my $NCount = $VCount * $TCount;
1215
1216 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1217 # with the above published constants.
1218 my %Jamo;
1219 my %Jamo_L;     # Leading consonants
1220 my %Jamo_V;     # Vowels
1221 my %Jamo_T;     # Trailing consonants
1222
1223 my @backslash_X_tests;     # List of tests read in for testing \X
1224 my @unhandled_properties;  # Will contain a list of properties found in
1225                            # the input that we didn't process.
1226 my @match_properties;      # Properties that have match tables, to be
1227                            # listed in the pod
1228 my @map_properties;        # Properties that get map files written
1229 my @named_sequences;       # NamedSequences.txt contents.
1230 my %potential_files;       # Generated list of all .txt files in the directory
1231                            # structure so we can warn if something is being
1232                            # ignored.
1233 my @files_actually_output; # List of files we generated.
1234 my @more_Names;            # Some code point names are compound; this is used
1235                            # to store the extra components of them.
1236 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1237                            # the minimum before we consider it equivalent to a
1238                            # candidate rational
1239 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1240
1241 # These store references to certain commonly used property objects
1242 my $gc;
1243 my $perl;
1244 my $block;
1245 my $perl_charname;
1246 my $print;
1247
1248 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1249 my $has_In_conflicts = 0;
1250 my $has_Is_conflicts = 0;
1251
1252 sub internal_file_to_platform ($) {
1253     # Convert our file paths which have '/' separators to those of the
1254     # platform.
1255
1256     my $file = shift;
1257     return undef unless defined $file;
1258
1259     return File::Spec->join(split '/', $file);
1260 }
1261
1262 sub file_exists ($) {   # platform independent '-e'.  This program internally
1263                         # uses slash as a path separator.
1264     my $file = shift;
1265     return 0 if ! defined $file;
1266     return -e internal_file_to_platform($file);
1267 }
1268
1269 sub objaddr($) {
1270     # Returns the address of the blessed input object.
1271     # It doesn't check for blessedness because that would do a string eval
1272     # every call, and the program is structured so that this is never called
1273     # for a non-blessed object.
1274
1275     no overloading; # If overloaded, numifying below won't work.
1276
1277     # Numifying a ref gives its address.
1278     return pack 'J', $_[0];
1279 }
1280
1281 # These are used only if $annotate is true.
1282 # The entire range of Unicode characters is examined to populate these
1283 # after all the input has been processed.  But most can be skipped, as they
1284 # have the same descriptive phrases, such as being unassigned
1285 my @viacode;            # Contains the 1 million character names
1286 my @printable;          # boolean: And are those characters printable?
1287 my @annotate_char_type; # Contains a type of those characters, specifically
1288                         # for the purposes of annotation.
1289 my $annotate_ranges;    # A map of ranges of code points that have the same
1290                         # name for the purposes of annoation.  They map to the
1291                         # upper edge of the range, so that the end point can
1292                         # be immediately found.  This is used to skip ahead to
1293                         # the end of a range, and avoid processing each
1294                         # individual code point in it.
1295 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1296                                    # characters, but excluding those which are
1297                                    # also noncharacter code points
1298
1299 # The annotation types are an extension of the regular range types, though
1300 # some of the latter are folded into one.  Make the new types negative to
1301 # avoid conflicting with the regular types
1302 my $SURROGATE_TYPE = -1;
1303 my $UNASSIGNED_TYPE = -2;
1304 my $PRIVATE_USE_TYPE = -3;
1305 my $NONCHARACTER_TYPE = -4;
1306 my $CONTROL_TYPE = -5;
1307 my $UNKNOWN_TYPE = -6;  # Used only if there is a bug in this program
1308
1309 sub populate_char_info ($) {
1310     # Used only with the $annotate option.  Populates the arrays with the
1311     # input code point's info that are needed for outputting more detailed
1312     # comments.  If calling context wants a return, it is the end point of
1313     # any contiguous range of characters that share essentially the same info
1314
1315     my $i = shift;
1316     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1317
1318     $viacode[$i] = $perl_charname->value_of($i) || "";
1319
1320     # A character is generally printable if Unicode says it is,
1321     # but below we make sure that most Unicode general category 'C' types
1322     # aren't.
1323     $printable[$i] = $print->contains($i);
1324
1325     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1326
1327     # Only these two regular types are treated specially for annotations
1328     # purposes
1329     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1330                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1331
1332     # Give a generic name to all code points that don't have a real name.
1333     # We output ranges, if applicable, for these.  Also calculate the end
1334     # point of the range.
1335     my $end;
1336     if (! $viacode[$i]) {
1337         if ($gc-> table('Surrogate')->contains($i)) {
1338             $viacode[$i] = 'Surrogate';
1339             $annotate_char_type[$i] = $SURROGATE_TYPE;
1340             $printable[$i] = 0;
1341             $end = $gc->table('Surrogate')->containing_range($i)->end;
1342         }
1343         elsif ($gc-> table('Private_use')->contains($i)) {
1344             $viacode[$i] = 'Private Use';
1345             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1346             $printable[$i] = 0;
1347             $end = $gc->table('Private_Use')->containing_range($i)->end;
1348         }
1349         elsif (Property::property_ref('Noncharacter_Code_Point')-> table('Y')->
1350                                                                 contains($i))
1351         {
1352             $viacode[$i] = 'Noncharacter';
1353             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1354             $printable[$i] = 0;
1355             $end = property_ref('Noncharacter_Code_Point')->table('Y')->
1356                                                     containing_range($i)->end;
1357         }
1358         elsif ($gc-> table('Control')->contains($i)) {
1359             $viacode[$i] = 'Control';
1360             $annotate_char_type[$i] = $CONTROL_TYPE;
1361             $printable[$i] = 0;
1362             $end = 0x81 if $i == 0x80;  # Hard-code this one known case
1363         }
1364         elsif ($gc-> table('Unassigned')->contains($i)) {
1365             $viacode[$i] = 'Unassigned, block=' . $block-> value_of($i);
1366             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1367             $printable[$i] = 0;
1368
1369             # Because we name the unassigned by the blocks they are in, it
1370             # can't go past the end of that block, and it also can't go past
1371             # the unassigned range it is in.  The special table makes sure
1372             # that the non-characters, which are unassigned, are separated
1373             # out.
1374             $end = min($block->containing_range($i)->end,
1375                        $unassigned_sans_noncharacters-> containing_range($i)->
1376                                                                          end);
1377         } else {
1378             my_carp_bug("Can't figure out how to annotate"
1379                         . sprintf("U+%04X", $i)
1380                         . "Proceeding anyway.");
1381             $viacode[$i] = 'UNKNOWN';
1382             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1383             $printable[$i] = 0;
1384         }
1385     }
1386
1387     # Here, has a name, but if it's one in which the code point number is
1388     # appended to the name, do that.
1389     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1390         $viacode[$i] .= sprintf("-%04X", $i);
1391         $end = $perl_charname->containing_range($i)->end;
1392     }
1393
1394     # And here, has a name, but if it's a hangul syllable one, replace it with
1395     # the correct name from the Unicode algorithm
1396     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1397         use integer;
1398         my $SIndex = $i - $SBase;
1399         my $L = $LBase + $SIndex / $NCount;
1400         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1401         my $T = $TBase + $SIndex % $TCount;
1402         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1403         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1404         $end = $perl_charname->containing_range($i)->end;
1405     }
1406
1407     return if ! defined wantarray;
1408     return $i if ! defined $end;    # If not a range, return the input
1409
1410     # Save this whole range so can find the end point quickly
1411     $annotate_ranges->add_map($i, $end, $end);
1412
1413     return $end;
1414 }
1415
1416 # Commented code below should work on Perl 5.8.
1417 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1418 ## the native perl version of it (which is what would operate under miniperl)
1419 ## is extremely slow, as it does a string eval every call.
1420 #my $has_fast_scalar_util = $\18 !~ /miniperl/
1421 #                            && defined eval "require Scalar::Util";
1422 #
1423 #sub objaddr($) {
1424 #    # Returns the address of the blessed input object.  Uses the XS version if
1425 #    # available.  It doesn't check for blessedness because that would do a
1426 #    # string eval every call, and the program is structured so that this is
1427 #    # never called for a non-blessed object.
1428 #
1429 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1430 #
1431 #    # Check at least that is a ref.
1432 #    my $pkg = ref($_[0]) or return undef;
1433 #
1434 #    # Change to a fake package to defeat any overloaded stringify
1435 #    bless $_[0], 'main::Fake';
1436 #
1437 #    # Numifying a ref gives its address.
1438 #    my $addr = pack 'J', $_[0];
1439 #
1440 #    # Return to original class
1441 #    bless $_[0], $pkg;
1442 #    return $addr;
1443 #}
1444
1445 sub max ($$) {
1446     my $a = shift;
1447     my $b = shift;
1448     return $a if $a >= $b;
1449     return $b;
1450 }
1451
1452 sub min ($$) {
1453     my $a = shift;
1454     my $b = shift;
1455     return $a if $a <= $b;
1456     return $b;
1457 }
1458
1459 sub clarify_number ($) {
1460     # This returns the input number with underscores inserted every 3 digits
1461     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1462     # checked.
1463
1464     my $number = shift;
1465     my $pos = length($number) - 3;
1466     return $number if $pos <= 1;
1467     while ($pos > 0) {
1468         substr($number, $pos, 0) = '_';
1469         $pos -= 3;
1470     }
1471     return $number;
1472 }
1473
1474
1475 package Carp;
1476
1477 # These routines give a uniform treatment of messages in this program.  They
1478 # are placed in the Carp package to cause the stack trace to not include them,
1479 # although an alternative would be to use another package and set @CARP_NOT
1480 # for it.
1481
1482 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1483
1484 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1485 # and overload trying to load Scalar:Util under miniperl.  See
1486 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1487 undef $overload::VERSION;
1488
1489 sub my_carp {
1490     my $message = shift || "";
1491     my $nofold = shift || 0;
1492
1493     if ($message) {
1494         $message = main::join_lines($message);
1495         $message =~ s/^$0: *//;     # Remove initial program name
1496         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1497         $message = "\n$0: $message;";
1498
1499         # Fold the message with program name, semi-colon end punctuation
1500         # (which looks good with the message that carp appends to it), and a
1501         # hanging indent for continuation lines.
1502         $message = main::simple_fold($message, "", 4) unless $nofold;
1503         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1504                                     # appends is to the same line
1505     }
1506
1507     return $message if defined wantarray;   # If a caller just wants the msg
1508
1509     carp $message;
1510     return;
1511 }
1512
1513 sub my_carp_bug {
1514     # This is called when it is clear that the problem is caused by a bug in
1515     # this program.
1516
1517     my $message = shift;
1518     $message =~ s/^$0: *//;
1519     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1520     carp $message;
1521     return;
1522 }
1523
1524 sub carp_too_few_args {
1525     if (@_ != 2) {
1526         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1527         return;
1528     }
1529
1530     my $args_ref = shift;
1531     my $count = shift;
1532
1533     my_carp_bug("Need at least $count arguments to "
1534         . (caller 1)[3]
1535         . ".  Instead got: '"
1536         . join ', ', @$args_ref
1537         . "'.  No action taken.");
1538     return;
1539 }
1540
1541 sub carp_extra_args {
1542     my $args_ref = shift;
1543     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1544
1545     unless (ref $args_ref) {
1546         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1547         return;
1548     }
1549     my ($package, $file, $line) = caller;
1550     my $subroutine = (caller 1)[3];
1551
1552     my $list;
1553     if (ref $args_ref eq 'HASH') {
1554         foreach my $key (keys %$args_ref) {
1555             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1556         }
1557         $list = join ', ', each %{$args_ref};
1558     }
1559     elsif (ref $args_ref eq 'ARRAY') {
1560         foreach my $arg (@$args_ref) {
1561             $arg = $UNDEF unless defined $arg;
1562         }
1563         $list = join ', ', @$args_ref;
1564     }
1565     else {
1566         my_carp_bug("Can't cope with ref "
1567                 . ref($args_ref)
1568                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1569         return;
1570     }
1571
1572     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1573     return;
1574 }
1575
1576 package main;
1577
1578 { # Closure
1579
1580     # This program uses the inside-out method for objects, as recommended in
1581     # "Perl Best Practices".  This closure aids in generating those.  There
1582     # are two routines.  setup_package() is called once per package to set
1583     # things up, and then set_access() is called for each hash representing a
1584     # field in the object.  These routines arrange for the object to be
1585     # properly destroyed when no longer used, and for standard accessor
1586     # functions to be generated.  If you need more complex accessors, just
1587     # write your own and leave those accesses out of the call to set_access().
1588     # More details below.
1589
1590     my %constructor_fields; # fields that are to be used in constructors; see
1591                             # below
1592
1593     # The values of this hash will be the package names as keys to other
1594     # hashes containing the name of each field in the package as keys, and
1595     # references to their respective hashes as values.
1596     my %package_fields;
1597
1598     sub setup_package {
1599         # Sets up the package, creating standard DESTROY and dump methods
1600         # (unless already defined).  The dump method is used in debugging by
1601         # simple_dumper().
1602         # The optional parameters are:
1603         #   a)  a reference to a hash, that gets populated by later
1604         #       set_access() calls with one of the accesses being
1605         #       'constructor'.  The caller can then refer to this, but it is
1606         #       not otherwise used by these two routines.
1607         #   b)  a reference to a callback routine to call during destruction
1608         #       of the object, before any fields are actually destroyed
1609
1610         my %args = @_;
1611         my $constructor_ref = delete $args{'Constructor_Fields'};
1612         my $destroy_callback = delete $args{'Destroy_Callback'};
1613         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1614
1615         my %fields;
1616         my $package = (caller)[0];
1617
1618         $package_fields{$package} = \%fields;
1619         $constructor_fields{$package} = $constructor_ref;
1620
1621         unless ($package->can('DESTROY')) {
1622             my $destroy_name = "${package}::DESTROY";
1623             no strict "refs";
1624
1625             # Use typeglob to give the anonymous subroutine the name we want
1626             *$destroy_name = sub {
1627                 my $self = shift;
1628                 my $addr = do { no overloading; pack 'J', $self; };
1629
1630                 $self->$destroy_callback if $destroy_callback;
1631                 foreach my $field (keys %{$package_fields{$package}}) {
1632                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1633                     delete $package_fields{$package}{$field}{$addr};
1634                 }
1635                 return;
1636             }
1637         }
1638
1639         unless ($package->can('dump')) {
1640             my $dump_name = "${package}::dump";
1641             no strict "refs";
1642             *$dump_name = sub {
1643                 my $self = shift;
1644                 return dump_inside_out($self, $package_fields{$package}, @_);
1645             }
1646         }
1647         return;
1648     }
1649
1650     sub set_access {
1651         # Arrange for the input field to be garbage collected when no longer
1652         # needed.  Also, creates standard accessor functions for the field
1653         # based on the optional parameters-- none if none of these parameters:
1654         #   'addable'    creates an 'add_NAME()' accessor function.
1655         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1656         #                function.
1657         #   'settable'   creates a 'set_NAME()' accessor function.
1658         #   'constructor' doesn't create an accessor function, but adds the
1659         #                field to the hash that was previously passed to
1660         #                setup_package();
1661         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1662         # 'add' etc. all mean 'addable'.
1663         # The read accessor function will work on both array and scalar
1664         # values.  If another accessor in the parameter list is 'a', the read
1665         # access assumes an array.  You can also force it to be array access
1666         # by specifying 'readable_array' instead of 'readable'
1667         #
1668         # A sort-of 'protected' access can be set-up by preceding the addable,
1669         # readable or settable with some initial portion of 'protected_' (but,
1670         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1671         # "protection" is only by convention.  All that happens is that the
1672         # accessor functions' names begin with an underscore.  So instead of
1673         # calling set_foo, the call is _set_foo.  (Real protection could be
1674         # accomplished by having a new subroutine, end_package, called at the
1675         # end of each package, and then storing the __LINE__ ranges and
1676         # checking them on every accessor.  But that is way overkill.)
1677
1678         # We create anonymous subroutines as the accessors and then use
1679         # typeglobs to assign them to the proper package and name
1680
1681         my $name = shift;   # Name of the field
1682         my $field = shift;  # Reference to the inside-out hash containing the
1683                             # field
1684
1685         my $package = (caller)[0];
1686
1687         if (! exists $package_fields{$package}) {
1688             croak "$0: Must call 'setup_package' before 'set_access'";
1689         }
1690
1691         # Stash the field so DESTROY can get it.
1692         $package_fields{$package}{$name} = $field;
1693
1694         # Remaining arguments are the accessors.  For each...
1695         foreach my $access (@_) {
1696             my $access = lc $access;
1697
1698             my $protected = "";
1699
1700             # Match the input as far as it goes.
1701             if ($access =~ /^(p[^_]*)_/) {
1702                 $protected = $1;
1703                 if (substr('protected_', 0, length $protected)
1704                     eq $protected)
1705                 {
1706
1707                     # Add 1 for the underscore not included in $protected
1708                     $access = substr($access, length($protected) + 1);
1709                     $protected = '_';
1710                 }
1711                 else {
1712                     $protected = "";
1713                 }
1714             }
1715
1716             if (substr('addable', 0, length $access) eq $access) {
1717                 my $subname = "${package}::${protected}add_$name";
1718                 no strict "refs";
1719
1720                 # add_ accessor.  Don't add if already there, which we
1721                 # determine using 'eq' for scalars and '==' otherwise.
1722                 *$subname = sub {
1723                     use strict "refs";
1724                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1725                     my $self = shift;
1726                     my $value = shift;
1727                     my $addr = do { no overloading; pack 'J', $self; };
1728                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1729                     if (ref $value) {
1730                         return if grep { $value == $_ } @{$field->{$addr}};
1731                     }
1732                     else {
1733                         return if grep { $value eq $_ } @{$field->{$addr}};
1734                     }
1735                     push @{$field->{$addr}}, $value;
1736                     return;
1737                 }
1738             }
1739             elsif (substr('constructor', 0, length $access) eq $access) {
1740                 if ($protected) {
1741                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
1742                 }
1743                 else {
1744                     $constructor_fields{$package}{$name} = $field;
1745                 }
1746             }
1747             elsif (substr('readable_array', 0, length $access) eq $access) {
1748
1749                 # Here has read access.  If one of the other parameters for
1750                 # access is array, or this one specifies array (by being more
1751                 # than just 'readable_'), then create a subroutine that
1752                 # assumes the data is an array.  Otherwise just a scalar
1753                 my $subname = "${package}::${protected}$name";
1754                 if (grep { /^a/i } @_
1755                     or length($access) > length('readable_'))
1756                 {
1757                     no strict "refs";
1758                     *$subname = sub {
1759                         use strict "refs";
1760                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1761                         my $addr = do { no overloading; pack 'J', $_[0]; };
1762                         if (ref $field->{$addr} ne 'ARRAY') {
1763                             my $type = ref $field->{$addr};
1764                             $type = 'scalar' unless $type;
1765                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
1766                             return;
1767                         }
1768                         return scalar @{$field->{$addr}} unless wantarray;
1769
1770                         # Make a copy; had problems with caller modifying the
1771                         # original otherwise
1772                         my @return = @{$field->{$addr}};
1773                         return @return;
1774                     }
1775                 }
1776                 else {
1777
1778                     # Here not an array value, a simpler function.
1779                     no strict "refs";
1780                     *$subname = sub {
1781                         use strict "refs";
1782                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1783                         no overloading;
1784                         return $field->{pack 'J', $_[0]};
1785                     }
1786                 }
1787             }
1788             elsif (substr('settable', 0, length $access) eq $access) {
1789                 my $subname = "${package}::${protected}set_$name";
1790                 no strict "refs";
1791                 *$subname = sub {
1792                     use strict "refs";
1793                     if (main::DEBUG) {
1794                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
1795                         Carp::carp_extra_args(\@_) if @_ > 2;
1796                     }
1797                     # $self is $_[0]; $value is $_[1]
1798                     no overloading;
1799                     $field->{pack 'J', $_[0]} = $_[1];
1800                     return;
1801                 }
1802             }
1803             else {
1804                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
1805             }
1806         }
1807         return;
1808     }
1809 }
1810
1811 package Input_file;
1812
1813 # All input files use this object, which stores various attributes about them,
1814 # and provides for convenient, uniform handling.  The run method wraps the
1815 # processing.  It handles all the bookkeeping of opening, reading, and closing
1816 # the file, returning only significant input lines.
1817 #
1818 # Each object gets a handler which processes the body of the file, and is
1819 # called by run().  Most should use the generic, default handler, which has
1820 # code scrubbed to handle things you might not expect.  A handler should
1821 # basically be a while(next_line()) {...} loop.
1822 #
1823 # You can also set up handlers to
1824 #   1) call before the first line is read for pre processing
1825 #   2) call to adjust each line of the input before the main handler gets them
1826 #   3) call upon EOF before the main handler exits its loop
1827 #   4) call at the end for post processing
1828 #
1829 # $_ is used to store the input line, and is to be filtered by the
1830 # each_line_handler()s.  So, if the format of the line is not in the desired
1831 # format for the main handler, these are used to do that adjusting.  They can
1832 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
1833 # so the $_ output of one is used as the input to the next.  None of the other
1834 # handlers are stackable, but could easily be changed to be so.
1835 #
1836 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
1837 # which insert the parameters as lines to be processed before the next input
1838 # file line is read.  This allows the EOF handler to flush buffers, for
1839 # example.  The difference between the two routines is that the lines inserted
1840 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
1841 # called it from such a handler, you would get infinite recursion.)  Lines
1842 # inserted by insert_adjusted_lines() go directly to the main handler without
1843 # any adjustments.  If the  post-processing handler calls any of these, there
1844 # will be no effect.  Some error checking for these conditions could be added,
1845 # but it hasn't been done.
1846 #
1847 # carp_bad_line() should be called to warn of bad input lines, which clears $_
1848 # to prevent further processing of the line.  This routine will output the
1849 # message as a warning once, and then keep a count of the lines that have the
1850 # same message, and output that count at the end of the file's processing.
1851 # This keeps the number of messages down to a manageable amount.
1852 #
1853 # get_missings() should be called to retrieve any @missing input lines.
1854 # Messages will be raised if this isn't done if the options aren't to ignore
1855 # missings.
1856
1857 sub trace { return main::trace(@_); }
1858
1859 { # Closure
1860     # Keep track of fields that are to be put into the constructor.
1861     my %constructor_fields;
1862
1863     main::setup_package(Constructor_Fields => \%constructor_fields);
1864
1865     my %file; # Input file name, required
1866     main::set_access('file', \%file, qw{ c r });
1867
1868     my %first_released; # Unicode version file was first released in, required
1869     main::set_access('first_released', \%first_released, qw{ c r });
1870
1871     my %handler;    # Subroutine to process the input file, defaults to
1872                     # 'process_generic_property_file'
1873     main::set_access('handler', \%handler, qw{ c });
1874
1875     my %property;
1876     # name of property this file is for.  defaults to none, meaning not
1877     # applicable, or is otherwise determinable, for example, from each line.
1878     main::set_access('property', \%property, qw{ c });
1879
1880     my %optional;
1881     # If this is true, the file is optional.  If not present, no warning is
1882     # output.  If it is present, the string given by this parameter is
1883     # evaluated, and if false the file is not processed.
1884     main::set_access('optional', \%optional, 'c', 'r');
1885
1886     my %non_skip;
1887     # This is used for debugging, to skip processing of all but a few input
1888     # files.  Add 'non_skip => 1' to the constructor for those files you want
1889     # processed when you set the $debug_skip global.
1890     main::set_access('non_skip', \%non_skip, 'c');
1891
1892     my %skip;
1893     # This is used to skip processing of this input file semi-permanently.
1894     # It is used for files that we aren't planning to process anytime soon,
1895     # but want to allow to be in the directory and not raise a message that we
1896     # are not handling.  Mostly for test files.  This is in contrast to the
1897     # non_skip element, which is supposed to be used very temporarily for
1898     # debugging.  Sets 'optional' to 1
1899     main::set_access('skip', \%skip, 'c');
1900
1901     my %each_line_handler;
1902     # list of subroutines to look at and filter each non-comment line in the
1903     # file.  defaults to none.  The subroutines are called in order, each is
1904     # to adjust $_ for the next one, and the final one adjusts it for
1905     # 'handler'
1906     main::set_access('each_line_handler', \%each_line_handler, 'c');
1907
1908     my %has_missings_defaults;
1909     # ? Are there lines in the file giving default values for code points
1910     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
1911     # the norm, but IGNORED means it has such lines, but the handler doesn't
1912     # use them.  Having these three states allows us to catch changes to the
1913     # UCD that this program should track
1914     main::set_access('has_missings_defaults',
1915                                         \%has_missings_defaults, qw{ c r });
1916
1917     my %pre_handler;
1918     # Subroutine to call before doing anything else in the file.  If undef, no
1919     # such handler is called.
1920     main::set_access('pre_handler', \%pre_handler, qw{ c });
1921
1922     my %eof_handler;
1923     # Subroutine to call upon getting an EOF on the input file, but before
1924     # that is returned to the main handler.  This is to allow buffers to be
1925     # flushed.  The handler is expected to call insert_lines() or
1926     # insert_adjusted() with the buffered material
1927     main::set_access('eof_handler', \%eof_handler, qw{ c r });
1928
1929     my %post_handler;
1930     # Subroutine to call after all the lines of the file are read in and
1931     # processed.  If undef, no such handler is called.
1932     main::set_access('post_handler', \%post_handler, qw{ c });
1933
1934     my %progress_message;
1935     # Message to print to display progress in lieu of the standard one
1936     main::set_access('progress_message', \%progress_message, qw{ c });
1937
1938     my %handle;
1939     # cache open file handle, internal.  Is undef if file hasn't been
1940     # processed at all, empty if has;
1941     main::set_access('handle', \%handle);
1942
1943     my %added_lines;
1944     # cache of lines added virtually to the file, internal
1945     main::set_access('added_lines', \%added_lines);
1946
1947     my %errors;
1948     # cache of errors found, internal
1949     main::set_access('errors', \%errors);
1950
1951     my %missings;
1952     # storage of '@missing' defaults lines
1953     main::set_access('missings', \%missings);
1954
1955     sub new {
1956         my $class = shift;
1957
1958         my $self = bless \do{ my $anonymous_scalar }, $class;
1959         my $addr = do { no overloading; pack 'J', $self; };
1960
1961         # Set defaults
1962         $handler{$addr} = \&main::process_generic_property_file;
1963         $non_skip{$addr} = 0;
1964         $skip{$addr} = 0;
1965         $has_missings_defaults{$addr} = $NO_DEFAULTS;
1966         $handle{$addr} = undef;
1967         $added_lines{$addr} = [ ];
1968         $each_line_handler{$addr} = [ ];
1969         $errors{$addr} = { };
1970         $missings{$addr} = [ ];
1971
1972         # Two positional parameters.
1973         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1974         $file{$addr} = main::internal_file_to_platform(shift);
1975         $first_released{$addr} = shift;
1976
1977         # The rest of the arguments are key => value pairs
1978         # %constructor_fields has been set up earlier to list all possible
1979         # ones.  Either set or push, depending on how the default has been set
1980         # up just above.
1981         my %args = @_;
1982         foreach my $key (keys %args) {
1983             my $argument = $args{$key};
1984
1985             # Note that the fields are the lower case of the constructor keys
1986             my $hash = $constructor_fields{lc $key};
1987             if (! defined $hash) {
1988                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
1989                 next;
1990             }
1991             if (ref $hash->{$addr} eq 'ARRAY') {
1992                 if (ref $argument eq 'ARRAY') {
1993                     foreach my $argument (@{$argument}) {
1994                         next if ! defined $argument;
1995                         push @{$hash->{$addr}}, $argument;
1996                     }
1997                 }
1998                 else {
1999                     push @{$hash->{$addr}}, $argument if defined $argument;
2000                 }
2001             }
2002             else {
2003                 $hash->{$addr} = $argument;
2004             }
2005             delete $args{$key};
2006         };
2007
2008         # If the file has a property for it, it means that the property is not
2009         # listed in the file's entries.  So add a handler to the list of line
2010         # handlers to insert the property name into the lines, to provide a
2011         # uniform interface to the final processing subroutine.
2012         # the final code doesn't have to worry about that.
2013         if ($property{$addr}) {
2014             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2015         }
2016
2017         if ($non_skip{$addr} && ! $debug_skip && $verbosity) {
2018             print "Warning: " . __PACKAGE__ . " constructor for $file{$addr} has useless 'non_skip' in it\n";
2019         }
2020
2021         $optional{$addr} = 1 if $skip{$addr};
2022
2023         return $self;
2024     }
2025
2026
2027     use overload
2028         fallback => 0,
2029         qw("") => "_operator_stringify",
2030         "." => \&main::_operator_dot,
2031     ;
2032
2033     sub _operator_stringify {
2034         my $self = shift;
2035
2036         return __PACKAGE__ . " object for " . $self->file;
2037     }
2038
2039     # flag to make sure extracted files are processed early
2040     my $seen_non_extracted_non_age = 0;
2041
2042     sub run {
2043         # Process the input object $self.  This opens and closes the file and
2044         # calls all the handlers for it.  Currently,  this can only be called
2045         # once per file, as it destroy's the EOF handler
2046
2047         my $self = shift;
2048         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2049
2050         my $addr = do { no overloading; pack 'J', $self; };
2051
2052         my $file = $file{$addr};
2053
2054         # Don't process if not expecting this file (because released later
2055         # than this Unicode version), and isn't there.  This means if someone
2056         # copies it into an earlier version's directory, we will go ahead and
2057         # process it.
2058         return if $first_released{$addr} gt $v_version && ! -e $file;
2059
2060         # If in debugging mode and this file doesn't have the non-skip
2061         # flag set, and isn't one of the critical files, skip it.
2062         if ($debug_skip
2063             && $first_released{$addr} ne v0
2064             && ! $non_skip{$addr})
2065         {
2066             print "Skipping $file in debugging\n" if $verbosity;
2067             return;
2068         }
2069
2070         # File could be optional
2071         if ($optional{$addr}) {
2072             return unless -e $file;
2073             my $result = eval $optional{$addr};
2074             if (! defined $result) {
2075                 Carp::my_carp_bug("Got '$@' when tried to eval $optional{$addr}.  $file Skipped.");
2076                 return;
2077             }
2078             if (! $result) {
2079                 if ($verbosity) {
2080                     print STDERR "Skipping processing input file '$file' because '$optional{$addr}' is not true\n";
2081                 }
2082                 return;
2083             }
2084         }
2085
2086         if (! defined $file || ! -e $file) {
2087
2088             # If the file doesn't exist, see if have internal data for it
2089             # (based on first_released being 0).
2090             if ($first_released{$addr} eq v0) {
2091                 $handle{$addr} = 'pretend_is_open';
2092             }
2093             else {
2094                 if (! $optional{$addr}  # File could be optional
2095                     && $v_version ge $first_released{$addr})
2096                 {
2097                     print STDERR "Skipping processing input file '$file' because not found\n" if $v_version ge $first_released{$addr};
2098                 }
2099                 return;
2100             }
2101         }
2102         else {
2103
2104             # Here, the file exists.  Some platforms may change the case of
2105             # its name
2106             if ($seen_non_extracted_non_age) {
2107                 if ($file =~ /$EXTRACTED/i) {
2108                     Carp::my_carp_bug(join_lines(<<END
2109 $file should be processed just after the 'Prop...Alias' files, and before
2110 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2111 have subtle problems
2112 END
2113                     ));
2114                 }
2115             }
2116             elsif ($EXTRACTED_DIR
2117                     && $first_released{$addr} ne v0
2118                     && $file !~ /$EXTRACTED/i
2119                     && lc($file) ne 'dage.txt')
2120             {
2121                 # We don't set this (by the 'if' above) if we have no
2122                 # extracted directory, so if running on an early version,
2123                 # this test won't work.  Not worth worrying about.
2124                 $seen_non_extracted_non_age = 1;
2125             }
2126
2127             # And mark the file as having being processed, and warn if it
2128             # isn't a file we are expecting.  As we process the files,
2129             # they are deleted from the hash, so any that remain at the
2130             # end of the program are files that we didn't process.
2131             my $fkey = File::Spec->rel2abs($file);
2132             my $expecting = delete $potential_files{$fkey};
2133             $expecting = delete $potential_files{lc($fkey)} unless defined $expecting;
2134             Carp::my_carp("Was not expecting '$file'.") if
2135                     ! $expecting
2136                     && ! defined $handle{$addr};
2137
2138             # Having deleted from expected files, we can quit if not to do
2139             # anything.  Don't print progress unless really want verbosity
2140             if ($skip{$addr}) {
2141                 print "Skipping $file.\n" if $verbosity >= $VERBOSE;
2142                 return;
2143             }
2144
2145             # Open the file, converting the slashes used in this program
2146             # into the proper form for the OS
2147             my $file_handle;
2148             if (not open $file_handle, "<", $file) {
2149                 Carp::my_carp("Can't open $file.  Skipping: $!");
2150                 return 0;
2151             }
2152             $handle{$addr} = $file_handle; # Cache the open file handle
2153         }
2154
2155         if ($verbosity >= $PROGRESS) {
2156             if ($progress_message{$addr}) {
2157                 print "$progress_message{$addr}\n";
2158             }
2159             else {
2160                 # If using a virtual file, say so.
2161                 print "Processing ", (-e $file)
2162                                        ? $file
2163                                        : "substitute $file",
2164                                      "\n";
2165             }
2166         }
2167
2168
2169         # Call any special handler for before the file.
2170         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2171
2172         # Then the main handler
2173         &{$handler{$addr}}($self);
2174
2175         # Then any special post-file handler.
2176         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2177
2178         # If any errors have been accumulated, output the counts (as the first
2179         # error message in each class was output when it was encountered).
2180         if ($errors{$addr}) {
2181             my $total = 0;
2182             my $types = 0;
2183             foreach my $error (keys %{$errors{$addr}}) {
2184                 $total += $errors{$addr}->{$error};
2185                 delete $errors{$addr}->{$error};
2186                 $types++;
2187             }
2188             if ($total > 1) {
2189                 my $message
2190                         = "A total of $total lines had errors in $file.  ";
2191
2192                 $message .= ($types == 1)
2193                             ? '(Only the first one was displayed.)'
2194                             : '(Only the first of each type was displayed.)';
2195                 Carp::my_carp($message);
2196             }
2197         }
2198
2199         if (@{$missings{$addr}}) {
2200             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2201         }
2202
2203         # If a real file handle, close it.
2204         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2205                                                         ref $handle{$addr};
2206         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2207                                # the file, as opposed to undef
2208         return;
2209     }
2210
2211     sub next_line {
2212         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2213         # if such a line exists.  'logical' means that any lines that have
2214         # been added via insert_lines() will be returned in $_ before the file
2215         # is read again.
2216
2217         my $self = shift;
2218         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2219
2220         my $addr = do { no overloading; pack 'J', $self; };
2221
2222         # Here the file is open (or if the handle is not a ref, is an open
2223         # 'virtual' file).  Get the next line; any inserted lines get priority
2224         # over the file itself.
2225         my $adjusted;
2226
2227         LINE:
2228         while (1) { # Loop until find non-comment, non-empty line
2229             #local $to_trace = 1 if main::DEBUG;
2230             my $inserted_ref = shift @{$added_lines{$addr}};
2231             if (defined $inserted_ref) {
2232                 ($adjusted, $_) = @{$inserted_ref};
2233                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2234                 return 1 if $adjusted;
2235             }
2236             else {
2237                 last if ! ref $handle{$addr}; # Don't read unless is real file
2238                 last if ! defined ($_ = readline $handle{$addr});
2239             }
2240             chomp;
2241             trace $_ if main::DEBUG && $to_trace;
2242
2243             # See if this line is the comment line that defines what property
2244             # value that code points that are not listed in the file should
2245             # have.  The format or existence of these lines is not guaranteed
2246             # by Unicode since they are comments, but the documentation says
2247             # that this was added for machine-readability, so probably won't
2248             # change.  This works starting in Unicode Version 5.0.  They look
2249             # like:
2250             #
2251             # @missing: 0000..10FFFF; Not_Reordered
2252             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2253             # @missing: 0000..10FFFF; ; NaN
2254             #
2255             # Save the line for a later get_missings() call.
2256             if (/$missing_defaults_prefix/) {
2257                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2258                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2259                 }
2260                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2261                     my @defaults = split /\s* ; \s*/x, $_;
2262
2263                     # The first field is the @missing, which ends in a
2264                     # semi-colon, so can safely shift.
2265                     shift @defaults;
2266
2267                     # Some of these lines may have empty field placeholders
2268                     # which get in the way.  An example is:
2269                     # @missing: 0000..10FFFF; ; NaN
2270                     # Remove them.  Process starting from the top so the
2271                     # splice doesn't affect things still to be looked at.
2272                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2273                         next if $defaults[$i] ne "";
2274                         splice @defaults, $i, 1;
2275                     }
2276
2277                     # What's left should be just the property (maybe) and the
2278                     # default.  Having only one element means it doesn't have
2279                     # the property.
2280                     my $default;
2281                     my $property;
2282                     if (@defaults >= 1) {
2283                         if (@defaults == 1) {
2284                             $default = $defaults[0];
2285                         }
2286                         else {
2287                             $property = $defaults[0];
2288                             $default = $defaults[1];
2289                         }
2290                     }
2291
2292                     if (@defaults < 1
2293                         || @defaults > 2
2294                         || ($default =~ /^</
2295                             && $default !~ /^<code *point>$/i
2296                             && $default !~ /^<none>$/i))
2297                     {
2298                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2299                     }
2300                     else {
2301
2302                         # If the property is missing from the line, it should
2303                         # be the one for the whole file
2304                         $property = $property{$addr} if ! defined $property;
2305
2306                         # Change <none> to the null string, which is what it
2307                         # really means.  If the default is the code point
2308                         # itself, set it to <code point>, which is what
2309                         # Unicode uses (but sometimes they've forgotten the
2310                         # space)
2311                         if ($default =~ /^<none>$/i) {
2312                             $default = "";
2313                         }
2314                         elsif ($default =~ /^<code *point>$/i) {
2315                             $default = $CODE_POINT;
2316                         }
2317
2318                         # Store them as a sub-arrays with both components.
2319                         push @{$missings{$addr}}, [ $default, $property ];
2320                     }
2321                 }
2322
2323                 # There is nothing for the caller to process on this comment
2324                 # line.
2325                 next;
2326             }
2327
2328             # Remove comments and trailing space, and skip this line if the
2329             # result is empty
2330             s/#.*//;
2331             s/\s+$//;
2332             next if /^$/;
2333
2334             # Call any handlers for this line, and skip further processing of
2335             # the line if the handler sets the line to null.
2336             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2337                 &{$sub_ref}($self);
2338                 next LINE if /^$/;
2339             }
2340
2341             # Here the line is ok.  return success.
2342             return 1;
2343         } # End of looping through lines.
2344
2345         # If there is an EOF handler, call it (only once) and if it generates
2346         # more lines to process go back in the loop to handle them.
2347         if ($eof_handler{$addr}) {
2348             &{$eof_handler{$addr}}($self);
2349             $eof_handler{$addr} = "";   # Currently only get one shot at it.
2350             goto LINE if $added_lines{$addr};
2351         }
2352
2353         # Return failure -- no more lines.
2354         return 0;
2355
2356     }
2357
2358 #   Not currently used, not fully tested.
2359 #    sub peek {
2360 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
2361 #        # record.  Not callable from an each_line_handler(), nor does it call
2362 #        # an each_line_handler() on the line.
2363 #
2364 #        my $self = shift;
2365 #        my $addr = do { no overloading; pack 'J', $self; };
2366 #
2367 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
2368 #            my ($adjusted, $line) = @{$inserted_ref};
2369 #            next if $adjusted;
2370 #
2371 #            # Remove comments and trailing space, and return a non-empty
2372 #            # resulting line
2373 #            $line =~ s/#.*//;
2374 #            $line =~ s/\s+$//;
2375 #            return $line if $line ne "";
2376 #        }
2377 #
2378 #        return if ! ref $handle{$addr}; # Don't read unless is real file
2379 #        while (1) { # Loop until find non-comment, non-empty line
2380 #            local $to_trace = 1 if main::DEBUG;
2381 #            trace $_ if main::DEBUG && $to_trace;
2382 #            return if ! defined (my $line = readline $handle{$addr});
2383 #            chomp $line;
2384 #            push @{$added_lines{$addr}}, [ 0, $line ];
2385 #
2386 #            $line =~ s/#.*//;
2387 #            $line =~ s/\s+$//;
2388 #            return $line if $line ne "";
2389 #        }
2390 #
2391 #        return;
2392 #    }
2393
2394
2395     sub insert_lines {
2396         # Lines can be inserted so that it looks like they were in the input
2397         # file at the place it was when this routine is called.  See also
2398         # insert_adjusted_lines().  Lines inserted via this routine go through
2399         # any each_line_handler()
2400
2401         my $self = shift;
2402
2403         # Each inserted line is an array, with the first element being 0 to
2404         # indicate that this line hasn't been adjusted, and needs to be
2405         # processed.
2406         no overloading;
2407         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
2408         return;
2409     }
2410
2411     sub insert_adjusted_lines {
2412         # Lines can be inserted so that it looks like they were in the input
2413         # file at the place it was when this routine is called.  See also
2414         # insert_lines().  Lines inserted via this routine are already fully
2415         # adjusted, ready to be processed; each_line_handler()s handlers will
2416         # not be called.  This means this is not a completely general
2417         # facility, as only the last each_line_handler on the stack should
2418         # call this.  It could be made more general, by passing to each of the
2419         # line_handlers their position on the stack, which they would pass on
2420         # to this routine, and that would replace the boolean first element in
2421         # the anonymous array pushed here, so that the next_line routine could
2422         # use that to call only those handlers whose index is after it on the
2423         # stack.  But this is overkill for what is needed now.
2424
2425         my $self = shift;
2426         trace $_[0] if main::DEBUG && $to_trace;
2427
2428         # Each inserted line is an array, with the first element being 1 to
2429         # indicate that this line has been adjusted
2430         no overloading;
2431         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
2432         return;
2433     }
2434
2435     sub get_missings {
2436         # Returns the stored up @missings lines' values, and clears the list.
2437         # The values are in an array, consisting of the default in the first
2438         # element, and the property in the 2nd.  However, since these lines
2439         # can be stacked up, the return is an array of all these arrays.
2440
2441         my $self = shift;
2442         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2443
2444         my $addr = do { no overloading; pack 'J', $self; };
2445
2446         # If not accepting a list return, just return the first one.
2447         return shift @{$missings{$addr}} unless wantarray;
2448
2449         my @return = @{$missings{$addr}};
2450         undef @{$missings{$addr}};
2451         return @return;
2452     }
2453
2454     sub _insert_property_into_line {
2455         # Add a property field to $_, if this file requires it.
2456
2457         my $self = shift;
2458         my $addr = do { no overloading; pack 'J', $self; };
2459         my $property = $property{$addr};
2460         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2461
2462         $_ =~ s/(;|$)/; $property$1/;
2463         return;
2464     }
2465
2466     sub carp_bad_line {
2467         # Output consistent error messages, using either a generic one, or the
2468         # one given by the optional parameter.  To avoid gazillions of the
2469         # same message in case the syntax of a  file is way off, this routine
2470         # only outputs the first instance of each message, incrementing a
2471         # count so the totals can be output at the end of the file.
2472
2473         my $self = shift;
2474         my $message = shift;
2475         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2476
2477         my $addr = do { no overloading; pack 'J', $self; };
2478
2479         $message = 'Unexpected line' unless $message;
2480
2481         # No trailing punctuation so as to fit with our addenda.
2482         $message =~ s/[.:;,]$//;
2483
2484         # If haven't seen this exact message before, output it now.  Otherwise
2485         # increment the count of how many times it has occurred
2486         unless ($errors{$addr}->{$message}) {
2487             Carp::my_carp("$message in '$_' in "
2488                             . $file{$addr}
2489                             . " at line $..  Skipping this line;");
2490             $errors{$addr}->{$message} = 1;
2491         }
2492         else {
2493             $errors{$addr}->{$message}++;
2494         }
2495
2496         # Clear the line to prevent any further (meaningful) processing of it.
2497         $_ = "";
2498
2499         return;
2500     }
2501 } # End closure
2502
2503 package Multi_Default;
2504
2505 # Certain properties in early versions of Unicode had more than one possible
2506 # default for code points missing from the files.  In these cases, one
2507 # default applies to everything left over after all the others are applied,
2508 # and for each of the others, there is a description of which class of code
2509 # points applies to it.  This object helps implement this by storing the
2510 # defaults, and for all but that final default, an eval string that generates
2511 # the class that it applies to.
2512
2513
2514 {   # Closure
2515
2516     main::setup_package();
2517
2518     my %class_defaults;
2519     # The defaults structure for the classes
2520     main::set_access('class_defaults', \%class_defaults);
2521
2522     my %other_default;
2523     # The default that applies to everything left over.
2524     main::set_access('other_default', \%other_default, 'r');
2525
2526
2527     sub new {
2528         # The constructor is called with default => eval pairs, terminated by
2529         # the left-over default. e.g.
2530         # Multi_Default->new(
2531         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
2532         #               -  0x200D',
2533         #        'R' => 'some other expression that evaluates to code points',
2534         #        .
2535         #        .
2536         #        .
2537         #        'U'));
2538
2539         my $class = shift;
2540
2541         my $self = bless \do{my $anonymous_scalar}, $class;
2542         my $addr = do { no overloading; pack 'J', $self; };
2543
2544         while (@_ > 1) {
2545             my $default = shift;
2546             my $eval = shift;
2547             $class_defaults{$addr}->{$default} = $eval;
2548         }
2549
2550         $other_default{$addr} = shift;
2551
2552         return $self;
2553     }
2554
2555     sub get_next_defaults {
2556         # Iterates and returns the next class of defaults.
2557         my $self = shift;
2558         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2559
2560         my $addr = do { no overloading; pack 'J', $self; };
2561
2562         return each %{$class_defaults{$addr}};
2563     }
2564 }
2565
2566 package Alias;
2567
2568 # An alias is one of the names that a table goes by.  This class defines them
2569 # including some attributes.  Everything is currently setup in the
2570 # constructor.
2571
2572
2573 {   # Closure
2574
2575     main::setup_package();
2576
2577     my %name;
2578     main::set_access('name', \%name, 'r');
2579
2580     my %loose_match;
2581     # Determined by the constructor code if this name should match loosely or
2582     # not.  The constructor parameters can override this, but it isn't fully
2583     # implemented, as should have ability to override Unicode one's via
2584     # something like a set_loose_match()
2585     main::set_access('loose_match', \%loose_match, 'r');
2586
2587     my %make_pod_entry;
2588     # Some aliases should not get their own entries because they are covered
2589     # by a wild-card, and some we want to discourage use of.  Binary
2590     main::set_access('make_pod_entry', \%make_pod_entry, 'r');
2591
2592     my %status;
2593     # Aliases have a status, like deprecated, or even suppressed (which means
2594     # they don't appear in documentation).  Enum
2595     main::set_access('status', \%status, 'r');
2596
2597     my %externally_ok;
2598     # Similarly, some aliases should not be considered as usable ones for
2599     # external use, such as file names, or we don't want documentation to
2600     # recommend them.  Boolean
2601     main::set_access('externally_ok', \%externally_ok, 'r');
2602
2603     sub new {
2604         my $class = shift;
2605
2606         my $self = bless \do { my $anonymous_scalar }, $class;
2607         my $addr = do { no overloading; pack 'J', $self; };
2608
2609         $name{$addr} = shift;
2610         $loose_match{$addr} = shift;
2611         $make_pod_entry{$addr} = shift;
2612         $externally_ok{$addr} = shift;
2613         $status{$addr} = shift;
2614
2615         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2616
2617         # Null names are never ok externally
2618         $externally_ok{$addr} = 0 if $name{$addr} eq "";
2619
2620         return $self;
2621     }
2622 }
2623
2624 package Range;
2625
2626 # A range is the basic unit for storing code points, and is described in the
2627 # comments at the beginning of the program.  Each range has a starting code
2628 # point; an ending code point (not less than the starting one); a value
2629 # that applies to every code point in between the two end-points, inclusive;
2630 # and an enum type that applies to the value.  The type is for the user's
2631 # convenience, and has no meaning here, except that a non-zero type is
2632 # considered to not obey the normal Unicode rules for having standard forms.
2633 #
2634 # The same structure is used for both map and match tables, even though in the
2635 # latter, the value (and hence type) is irrelevant and could be used as a
2636 # comment.  In map tables, the value is what all the code points in the range
2637 # map to.  Type 0 values have the standardized version of the value stored as
2638 # well, so as to not have to recalculate it a lot.
2639
2640 sub trace { return main::trace(@_); }
2641
2642 {   # Closure
2643
2644     main::setup_package();
2645
2646     my %start;
2647     main::set_access('start', \%start, 'r', 's');
2648
2649     my %end;
2650     main::set_access('end', \%end, 'r', 's');
2651
2652     my %value;
2653     main::set_access('value', \%value, 'r');
2654
2655     my %type;
2656     main::set_access('type', \%type, 'r');
2657
2658     my %standard_form;
2659     # The value in internal standard form.  Defined only if the type is 0.
2660     main::set_access('standard_form', \%standard_form);
2661
2662     # Note that if these fields change, the dump() method should as well
2663
2664     sub new {
2665         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
2666         my $class = shift;
2667
2668         my $self = bless \do { my $anonymous_scalar }, $class;
2669         my $addr = do { no overloading; pack 'J', $self; };
2670
2671         $start{$addr} = shift;
2672         $end{$addr} = shift;
2673
2674         my %args = @_;
2675
2676         my $value = delete $args{'Value'};  # Can be 0
2677         $value = "" unless defined $value;
2678         $value{$addr} = $value;
2679
2680         $type{$addr} = delete $args{'Type'} || 0;
2681
2682         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2683
2684         if (! $type{$addr}) {
2685             $standard_form{$addr} = main::standardize($value);
2686         }
2687
2688         return $self;
2689     }
2690
2691     use overload
2692         fallback => 0,
2693         qw("") => "_operator_stringify",
2694         "." => \&main::_operator_dot,
2695     ;
2696
2697     sub _operator_stringify {
2698         my $self = shift;
2699         my $addr = do { no overloading; pack 'J', $self; };
2700
2701         # Output it like '0041..0065 (value)'
2702         my $return = sprintf("%04X", $start{$addr})
2703                         .  '..'
2704                         . sprintf("%04X", $end{$addr});
2705         my $value = $value{$addr};
2706         my $type = $type{$addr};
2707         $return .= ' (';
2708         $return .= "$value";
2709         $return .= ", Type=$type" if $type != 0;
2710         $return .= ')';
2711
2712         return $return;
2713     }
2714
2715     sub standard_form {
2716         # The standard form is the value itself if the standard form is
2717         # undefined (that is if the value is special)
2718
2719         my $self = shift;
2720         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2721
2722         my $addr = do { no overloading; pack 'J', $self; };
2723
2724         return $standard_form{$addr} if defined $standard_form{$addr};
2725         return $value{$addr};
2726     }
2727
2728     sub dump {
2729         # Human, not machine readable.  For machine readable, comment out this
2730         # entire routine and let the standard one take effect.
2731         my $self = shift;
2732         my $indent = shift;
2733         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2734
2735         my $addr = do { no overloading; pack 'J', $self; };
2736
2737         my $return = $indent
2738                     . sprintf("%04X", $start{$addr})
2739                     . '..'
2740                     . sprintf("%04X", $end{$addr})
2741                     . " '$value{$addr}';";
2742         if (! defined $standard_form{$addr}) {
2743             $return .= "(type=$type{$addr})";
2744         }
2745         elsif ($standard_form{$addr} ne $value{$addr}) {
2746             $return .= "(standard '$standard_form{$addr}')";
2747         }
2748         return $return;
2749     }
2750 } # End closure
2751
2752 package _Range_List_Base;
2753
2754 # Base class for range lists.  A range list is simply an ordered list of
2755 # ranges, so that the ranges with the lowest starting numbers are first in it.
2756 #
2757 # When a new range is added that is adjacent to an existing range that has the
2758 # same value and type, it merges with it to form a larger range.
2759 #
2760 # Ranges generally do not overlap, except that there can be multiple entries
2761 # of single code point ranges.  This is because of NameAliases.txt.
2762 #
2763 # In this program, there is a standard value such that if two different
2764 # values, have the same standard value, they are considered equivalent.  This
2765 # value was chosen so that it gives correct results on Unicode data
2766
2767 # There are a number of methods to manipulate range lists, and some operators
2768 # are overloaded to handle them.
2769
2770 sub trace { return main::trace(@_); }
2771
2772 { # Closure
2773
2774     our $addr;
2775
2776     main::setup_package();
2777
2778     my %ranges;
2779     # The list of ranges
2780     main::set_access('ranges', \%ranges, 'readable_array');
2781
2782     my %max;
2783     # The highest code point in the list.  This was originally a method, but
2784     # actual measurements said it was used a lot.
2785     main::set_access('max', \%max, 'r');
2786
2787     my %each_range_iterator;
2788     # Iterator position for each_range()
2789     main::set_access('each_range_iterator', \%each_range_iterator);
2790
2791     my %owner_name_of;
2792     # Name of parent this is attached to, if any.  Solely for better error
2793     # messages.
2794     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
2795
2796     my %_search_ranges_cache;
2797     # A cache of the previous result from _search_ranges(), for better
2798     # performance
2799     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
2800
2801     sub new {
2802         my $class = shift;
2803         my %args = @_;
2804
2805         # Optional initialization data for the range list.
2806         my $initialize = delete $args{'Initialize'};
2807
2808         my $self;
2809
2810         # Use _union() to initialize.  _union() returns an object of this
2811         # class, which means that it will call this constructor recursively.
2812         # But it won't have this $initialize parameter so that it won't
2813         # infinitely loop on this.
2814         return _union($class, $initialize, %args) if defined $initialize;
2815
2816         $self = bless \do { my $anonymous_scalar }, $class;
2817         my $addr = do { no overloading; pack 'J', $self; };
2818
2819         # Optional parent object, only for debug info.
2820         $owner_name_of{$addr} = delete $args{'Owner'};
2821         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
2822
2823         # Stringify, in case it is an object.
2824         $owner_name_of{$addr} = "$owner_name_of{$addr}";
2825
2826         # This is used only for error messages, and so a colon is added
2827         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
2828
2829         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2830
2831         # Max is initialized to a negative value that isn't adjacent to 0,
2832         # for simpler tests
2833         $max{$addr} = -2;
2834
2835         $_search_ranges_cache{$addr} = 0;
2836         $ranges{$addr} = [];
2837
2838         return $self;
2839     }
2840
2841     use overload
2842         fallback => 0,
2843         qw("") => "_operator_stringify",
2844         "." => \&main::_operator_dot,
2845     ;
2846
2847     sub _operator_stringify {
2848         my $self = shift;
2849         my $addr = do { no overloading; pack 'J', $self; };
2850
2851         return "Range_List attached to '$owner_name_of{$addr}'"
2852                                                 if $owner_name_of{$addr};
2853         return "anonymous Range_List " . \$self;
2854     }
2855
2856     sub _union {
2857         # Returns the union of the input code points.  It can be called as
2858         # either a constructor or a method.  If called as a method, the result
2859         # will be a new() instance of the calling object, containing the union
2860         # of that object with the other parameter's code points;  if called as
2861         # a constructor, the first parameter gives the class the new object
2862         # should be, and the second parameter gives the code points to go into
2863         # it.
2864         # In either case, there are two parameters looked at by this routine;
2865         # any additional parameters are passed to the new() constructor.
2866         #
2867         # The code points can come in the form of some object that contains
2868         # ranges, and has a conventionally named method to access them; or
2869         # they can be an array of individual code points (as integers); or
2870         # just a single code point.
2871         #
2872         # If they are ranges, this routine doesn't make any effort to preserve
2873         # the range values of one input over the other.  Therefore this base
2874         # class should not allow _union to be called from other than
2875         # initialization code, so as to prevent two tables from being added
2876         # together where the range values matter.  The general form of this
2877         # routine therefore belongs in a derived class, but it was moved here
2878         # to avoid duplication of code.  The failure to overload this in this
2879         # class keeps it safe.
2880         #
2881
2882         my $self;
2883         my @args;   # Arguments to pass to the constructor
2884
2885         my $class = shift;
2886
2887         # If a method call, will start the union with the object itself, and
2888         # the class of the new object will be the same as self.
2889         if (ref $class) {
2890             $self = $class;
2891             $class = ref $self;
2892             push @args, $self;
2893         }
2894
2895         # Add the other required parameter.
2896         push @args, shift;
2897         # Rest of parameters are passed on to the constructor
2898
2899         # Accumulate all records from both lists.
2900         my @records;
2901         for my $arg (@args) {
2902             #local $to_trace = 0 if main::DEBUG;
2903             trace "argument = $arg" if main::DEBUG && $to_trace;
2904             if (! defined $arg) {
2905                 my $message = "";
2906                 if (defined $self) {
2907                     no overloading;
2908                     $message .= $owner_name_of{pack 'J', $self};
2909                 }
2910                 Carp::my_carp_bug($message .= "Undefined argument to _union.  No union done.");
2911                 return;
2912             }
2913             $arg = [ $arg ] if ! ref $arg;
2914             my $type = ref $arg;
2915             if ($type eq 'ARRAY') {
2916                 foreach my $element (@$arg) {
2917                     push @records, Range->new($element, $element);
2918                 }
2919             }
2920             elsif ($arg->isa('Range')) {
2921                 push @records, $arg;
2922             }
2923             elsif ($arg->can('ranges')) {
2924                 push @records, $arg->ranges;
2925             }
2926             else {
2927                 my $message = "";
2928                 if (defined $self) {
2929                     no overloading;
2930                     $message .= $owner_name_of{pack 'J', $self};
2931                 }
2932                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
2933                 return;
2934             }
2935         }
2936
2937         # Sort with the range containing the lowest ordinal first, but if
2938         # two ranges start at the same code point, sort with the bigger range
2939         # of the two first, because it takes fewer cycles.
2940         @records = sort { ($a->start <=> $b->start)
2941                                       or
2942                                     # if b is shorter than a, b->end will be
2943                                     # less than a->end, and we want to select
2944                                     # a, so want to return -1
2945                                     ($b->end <=> $a->end)
2946                                    } @records;
2947
2948         my $new = $class->new(@_);
2949
2950         # Fold in records so long as they add new information.
2951         for my $set (@records) {
2952             my $start = $set->start;
2953             my $end   = $set->end;
2954             my $value   = $set->value;
2955             if ($start > $new->max) {
2956                 $new->_add_delete('+', $start, $end, $value);
2957             }
2958             elsif ($end > $new->max) {
2959                 $new->_add_delete('+', $new->max +1, $end, $value);
2960             }
2961         }
2962
2963         return $new;
2964     }
2965
2966     sub range_count {        # Return the number of ranges in the range list
2967         my $self = shift;
2968         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2969
2970         no overloading;
2971         return scalar @{$ranges{pack 'J', $self}};
2972     }
2973
2974     sub min {
2975         # Returns the minimum code point currently in the range list, or if
2976         # the range list is empty, 2 beyond the max possible.  This is a
2977         # method because used so rarely, that not worth saving between calls,
2978         # and having to worry about changing it as ranges are added and
2979         # deleted.
2980
2981         my $self = shift;
2982         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2983
2984         my $addr = do { no overloading; pack 'J', $self; };
2985
2986         # If the range list is empty, return a large value that isn't adjacent
2987         # to any that could be in the range list, for simpler tests
2988         return $LAST_UNICODE_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
2989         return $ranges{$addr}->[0]->start;
2990     }
2991
2992     sub contains {
2993         # Boolean: Is argument in the range list?  If so returns $i such that:
2994         #   range[$i]->end < $codepoint <= range[$i+1]->end
2995         # which is one beyond what you want; this is so that the 0th range
2996         # doesn't return false
2997         my $self = shift;
2998         my $codepoint = shift;
2999         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3000
3001         my $i = $self->_search_ranges($codepoint);
3002         return 0 unless defined $i;
3003
3004         # The search returns $i, such that
3005         #   range[$i-1]->end < $codepoint <= range[$i]->end
3006         # So is in the table if and only iff it is at least the start position
3007         # of range $i.
3008         no overloading;
3009         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3010         return $i + 1;
3011     }
3012
3013     sub containing_range {
3014         # Returns the range object that contains the code point, undef if none
3015
3016         my $self = shift;
3017         my $codepoint = shift;
3018         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3019
3020         my $i = $self->contains($codepoint);
3021         return unless $i;
3022
3023         # contains() returns 1 beyond where we should look
3024         no overloading;
3025         return $ranges{pack 'J', $self}->[$i-1];
3026     }
3027
3028     sub value_of {
3029         # Returns the value associated with the code point, undef if none
3030
3031         my $self = shift;
3032         my $codepoint = shift;
3033         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3034
3035         my $range = $self->containing_range($codepoint);
3036         return unless defined $range;
3037
3038         return $range->value;
3039     }
3040
3041     sub type_of {
3042         # Returns the type of the range containing the code point, undef if
3043         # the code point is not in the table
3044
3045         my $self = shift;
3046         my $codepoint = shift;
3047         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3048
3049         my $range = $self->containing_range($codepoint);
3050         return unless defined $range;
3051
3052         return $range->type;
3053     }
3054
3055     sub _search_ranges {
3056         # Find the range in the list which contains a code point, or where it
3057         # should go if were to add it.  That is, it returns $i, such that:
3058         #   range[$i-1]->end < $codepoint <= range[$i]->end
3059         # Returns undef if no such $i is possible (e.g. at end of table), or
3060         # if there is an error.
3061
3062         my $self = shift;
3063         my $code_point = shift;
3064         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3065
3066         my $addr = do { no overloading; pack 'J', $self; };
3067
3068         return if $code_point > $max{$addr};
3069         my $r = $ranges{$addr};                # The current list of ranges
3070         my $range_list_size = scalar @$r;
3071         my $i;
3072
3073         use integer;        # want integer division
3074
3075         # Use the cached result as the starting guess for this one, because,
3076         # an experiment on 5.1 showed that 90% of the time the cache was the
3077         # same as the result on the next call (and 7% it was one less).
3078         $i = $_search_ranges_cache{$addr};
3079         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
3080                                             # from an intervening deletion
3081         #local $to_trace = 1 if main::DEBUG;
3082         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
3083         return $i if $code_point <= $r->[$i]->end
3084                      && ($i == 0 || $r->[$i-1]->end < $code_point);
3085
3086         # Here the cache doesn't yield the correct $i.  Try adding 1.
3087         if ($i < $range_list_size - 1
3088             && $r->[$i]->end < $code_point &&
3089             $code_point <= $r->[$i+1]->end)
3090         {
3091             $i++;
3092             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
3093             $_search_ranges_cache{$addr} = $i;
3094             return $i;
3095         }
3096
3097         # Here, adding 1 also didn't work.  We do a binary search to
3098         # find the correct position, starting with current $i
3099         my $lower = 0;
3100         my $upper = $range_list_size - 1;
3101         while (1) {
3102             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
3103
3104             if ($code_point <= $r->[$i]->end) {
3105
3106                 # Here we have met the upper constraint.  We can quit if we
3107                 # also meet the lower one.
3108                 last if $i == 0 || $r->[$i-1]->end < $code_point;
3109
3110                 $upper = $i;        # Still too high.
3111
3112             }
3113             else {
3114
3115                 # Here, $r[$i]->end < $code_point, so look higher up.
3116                 $lower = $i;
3117             }
3118
3119             # Split search domain in half to try again.
3120             my $temp = ($upper + $lower) / 2;
3121
3122             # No point in continuing unless $i changes for next time
3123             # in the loop.
3124             if ($temp == $i) {
3125
3126                 # We can't reach the highest element because of the averaging.
3127                 # So if one below the upper edge, force it there and try one
3128                 # more time.
3129                 if ($i == $range_list_size - 2) {
3130
3131                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
3132                     $i = $range_list_size - 1;
3133
3134                     # Change $lower as well so if fails next time through,
3135                     # taking the average will yield the same $i, and we will
3136                     # quit with the error message just below.
3137                     $lower = $i;
3138                     next;
3139                 }
3140                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
3141                 return;
3142             }
3143             $i = $temp;
3144         } # End of while loop
3145
3146         if (main::DEBUG && $to_trace) {
3147             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
3148             trace "i=  [ $i ]", $r->[$i];
3149             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
3150         }
3151
3152         # Here we have found the offset.  Cache it as a starting point for the
3153         # next call.
3154         $_search_ranges_cache{$addr} = $i;
3155         return $i;
3156     }
3157
3158     sub _add_delete {
3159         # Add, replace or delete ranges to or from a list.  The $type
3160         # parameter gives which:
3161         #   '+' => insert or replace a range, returning a list of any changed
3162         #          ranges.
3163         #   '-' => delete a range, returning a list of any deleted ranges.
3164         #
3165         # The next three parameters give respectively the start, end, and
3166         # value associated with the range.  'value' should be null unless the
3167         # operation is '+';
3168         #
3169         # The range list is kept sorted so that the range with the lowest
3170         # starting position is first in the list, and generally, adjacent
3171         # ranges with the same values are merged into a single larger one (see
3172         # exceptions below).
3173         #
3174         # There are more parameters; all are key => value pairs:
3175         #   Type    gives the type of the value.  It is only valid for '+'.
3176         #           All ranges have types; if this parameter is omitted, 0 is
3177         #           assumed.  Ranges with type 0 are assumed to obey the
3178         #           Unicode rules for casing, etc; ranges with other types are
3179         #           not.  Otherwise, the type is arbitrary, for the caller's
3180         #           convenience, and looked at only by this routine to keep
3181         #           adjacent ranges of different types from being merged into
3182         #           a single larger range, and when Replace =>
3183         #           $IF_NOT_EQUIVALENT is specified (see just below).
3184         #   Replace  determines what to do if the range list already contains
3185         #            ranges which coincide with all or portions of the input
3186         #            range.  It is only valid for '+':
3187         #       => $NO            means that the new value is not to replace
3188         #                         any existing ones, but any empty gaps of the
3189         #                         range list coinciding with the input range
3190         #                         will be filled in with the new value.
3191         #       => $UNCONDITIONALLY  means to replace the existing values with
3192         #                         this one unconditionally.  However, if the
3193         #                         new and old values are identical, the
3194         #                         replacement is skipped to save cycles
3195         #       => $IF_NOT_EQUIVALENT means to replace the existing values
3196         #                         with this one if they are not equivalent.
3197         #                         Ranges are equivalent if their types are the
3198         #                         same, and they are the same string; or if
3199         #                         both are type 0 ranges, if their Unicode
3200         #                         standard forms are identical.  In this last
3201         #                         case, the routine chooses the more "modern"
3202         #                         one to use.  This is because some of the
3203         #                         older files are formatted with values that
3204         #                         are, for example, ALL CAPs, whereas the
3205         #                         derived files have a more modern style,
3206         #                         which looks better.  By looking for this
3207         #                         style when the pre-existing and replacement
3208         #                         standard forms are the same, we can move to
3209         #                         the modern style
3210         #       => $MULTIPLE      means that if this range duplicates an
3211         #                         existing one, but has a different value,
3212         #                         don't replace the existing one, but insert
3213         #                         this, one so that the same range can occur
3214         #                         multiple times.  They are stored LIFO, so
3215         #                         that the final one inserted is the first one
3216         #                         returned in an ordered search of the table.
3217         #       => anything else  is the same as => $IF_NOT_EQUIVALENT
3218         #
3219         # "same value" means identical for non-type-0 ranges, and it means
3220         # having the same standard forms for type-0 ranges.
3221
3222         return Carp::carp_too_few_args(\@_, 5) if main::DEBUG && @_ < 5;
3223
3224         my $self = shift;
3225         my $operation = shift;   # '+' for add/replace; '-' for delete;
3226         my $start = shift;
3227         my $end   = shift;
3228         my $value = shift;
3229
3230         my %args = @_;
3231
3232         $value = "" if not defined $value;        # warning: $value can be "0"
3233
3234         my $replace = delete $args{'Replace'};
3235         $replace = $IF_NOT_EQUIVALENT unless defined $replace;
3236
3237         my $type = delete $args{'Type'};
3238         $type = 0 unless defined $type;
3239
3240         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3241
3242         my $addr = do { no overloading; pack 'J', $self; };
3243
3244         if ($operation ne '+' && $operation ne '-') {
3245             Carp::my_carp_bug("$owner_name_of{$addr}First parameter to _add_delete must be '+' or '-'.  No action taken.");
3246             return;
3247         }
3248         unless (defined $start && defined $end) {
3249             Carp::my_carp_bug("$owner_name_of{$addr}Undefined start and/or end to _add_delete.  No action taken.");
3250             return;
3251         }
3252         unless ($end >= $start) {
3253             Carp::my_carp_bug("$owner_name_of{$addr}End of range (" . sprintf("%04X", $end) . ") must not be before start (" . sprintf("%04X", $start) . ").  No action taken.");
3254             return;
3255         }
3256         #local $to_trace = 1 if main::DEBUG;
3257
3258         if ($operation eq '-') {
3259             if ($replace != $IF_NOT_EQUIVALENT) {
3260                 Carp::my_carp_bug("$owner_name_of{$addr}Replace => \$IF_NOT_EQUIVALENT is required when deleting a range from a range list.  Assuming Replace => \$IF_NOT_EQUIVALENT.");
3261                 $replace = $IF_NOT_EQUIVALENT;
3262             }
3263             if ($type) {
3264                 Carp::my_carp_bug("$owner_name_of{$addr}Type => 0 is required when deleting a range from a range list.  Assuming Type => 0.");
3265                 $type = 0;
3266             }
3267             if ($value ne "") {
3268                 Carp::my_carp_bug("$owner_name_of{$addr}Value => \"\" is required when deleting a range from a range list.  Assuming Value => \"\".");
3269                 $value = "";
3270             }
3271         }
3272
3273         my $r = $ranges{$addr};               # The current list of ranges
3274         my $range_list_size = scalar @$r;     # And its size
3275         my $max = $max{$addr};                # The current high code point in
3276                                               # the list of ranges
3277
3278         # Do a special case requiring fewer machine cycles when the new range
3279         # starts after the current highest point.  The Unicode input data is
3280         # structured so this is common.
3281         if ($start > $max) {
3282
3283             trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) type=$type" if main::DEBUG && $to_trace;
3284             return if $operation eq '-'; # Deleting a non-existing range is a
3285                                          # no-op
3286
3287             # If the new range doesn't logically extend the current final one
3288             # in the range list, create a new range at the end of the range
3289             # list.  (max cleverly is initialized to a negative number not
3290             # adjacent to 0 if the range list is empty, so even adding a range
3291             # to an empty range list starting at 0 will have this 'if'
3292             # succeed.)
3293             if ($start > $max + 1        # non-adjacent means can't extend.
3294                 || @{$r}[-1]->value ne $value # values differ, can't extend.
3295                 || @{$r}[-1]->type != $type # types differ, can't extend.
3296             ) {
3297                 push @$r, Range->new($start, $end,
3298                                      Value => $value,
3299                                      Type => $type);
3300             }
3301             else {
3302
3303                 # Here, the new range starts just after the current highest in
3304                 # the range list, and they have the same type and value.
3305                 # Extend the current range to incorporate the new one.
3306                 @{$r}[-1]->set_end($end);
3307             }
3308
3309             # This becomes the new maximum.
3310             $max{$addr} = $end;
3311
3312             return;
3313         }
3314         #local $to_trace = 0 if main::DEBUG;
3315
3316         trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) replace=$replace" if main::DEBUG && $to_trace;
3317
3318         # Here, the input range isn't after the whole rest of the range list.
3319         # Most likely 'splice' will be needed.  The rest of the routine finds
3320         # the needed splice parameters, and if necessary, does the splice.
3321         # First, find the offset parameter needed by the splice function for
3322         # the input range.  Note that the input range may span multiple
3323         # existing ones, but we'll worry about that later.  For now, just find
3324         # the beginning.  If the input range is to be inserted starting in a
3325         # position not currently in the range list, it must (obviously) come
3326         # just after the range below it, and just before the range above it.
3327         # Slightly less obviously, it will occupy the position currently
3328         # occupied by the range that is to come after it.  More formally, we
3329         # are looking for the position, $i, in the array of ranges, such that:
3330         #
3331         # r[$i-1]->start <= r[$i-1]->end < $start < r[$i]->start <= r[$i]->end
3332         #
3333         # (The ordered relationships within existing ranges are also shown in
3334         # the equation above).  However, if the start of the input range is
3335         # within an existing range, the splice offset should point to that
3336         # existing range's position in the list; that is $i satisfies a
3337         # somewhat different equation, namely:
3338         #
3339         #r[$i-1]->start <= r[$i-1]->end < r[$i]->start <= $start <= r[$i]->end
3340         #
3341         # More briefly, $start can come before or after r[$i]->start, and at
3342         # this point, we don't know which it will be.  However, these
3343         # two equations share these constraints:
3344         #
3345         #   r[$i-1]->end < $start <= r[$i]->end
3346         #
3347         # And that is good enough to find $i.
3348
3349         my $i = $self->_search_ranges($start);
3350         if (! defined $i) {
3351             Carp::my_carp_bug("Searching $self for range beginning with $start unexpectedly returned undefined.  Operation '$operation' not performed");
3352             return;
3353         }
3354
3355         # The search function returns $i such that:
3356         #
3357         # r[$i-1]->end < $start <= r[$i]->end
3358         #
3359         # That means that $i points to the first range in the range list
3360         # that could possibly be affected by this operation.  We still don't
3361         # know if the start of the input range is within r[$i], or if it
3362         # points to empty space between r[$i-1] and r[$i].
3363         trace "[$i] is the beginning splice point.  Existing range there is ", $r->[$i] if main::DEBUG && $to_trace;
3364
3365         # Special case the insertion of data that is not to replace any
3366         # existing data.
3367         if ($replace == $NO) {  # If $NO, has to be operation '+'
3368             #local $to_trace = 1 if main::DEBUG;
3369             trace "Doesn't replace" if main::DEBUG && $to_trace;
3370
3371             # Here, the new range is to take effect only on those code points
3372             # that aren't already in an existing range.  This can be done by
3373             # looking through the existing range list and finding the gaps in
3374             # the ranges that this new range affects, and then calling this
3375             # function recursively on each of those gaps, leaving untouched
3376             # anything already in the list.  Gather up a list of the changed
3377             # gaps first so that changes to the internal state as new ranges
3378             # are added won't be a problem.
3379             my @gap_list;
3380
3381             # First, if the starting point of the input range is outside an
3382             # existing one, there is a gap from there to the beginning of the
3383             # existing range -- add a span to fill the part that this new
3384             # range occupies
3385             if ($start < $r->[$i]->start) {
3386                 push @gap_list, Range->new($start,
3387                                            main::min($end,
3388                                                      $r->[$i]->start - 1),
3389                                            Type => $type);
3390                 trace "gap before $r->[$i] [$i], will add", $gap_list[-1] if main::DEBUG && $to_trace;
3391             }
3392
3393             # Then look through the range list for other gaps until we reach
3394             # the highest range affected by the input one.
3395             my $j;
3396             for ($j = $i+1; $j < $range_list_size; $j++) {
3397                 trace "j=[$j]", $r->[$j] if main::DEBUG && $to_trace;
3398                 last if $end < $r->[$j]->start;
3399
3400                 # If there is a gap between when this range starts and the
3401                 # previous one ends, add a span to fill it.  Note that just
3402                 # because there are two ranges doesn't mean there is a
3403                 # non-zero gap between them.  It could be that they have
3404                 # different values or types
3405                 if ($r->[$j-1]->end + 1 != $r->[$j]->start) {
3406                     push @gap_list,
3407                         Range->new($r->[$j-1]->end + 1,
3408                                    $r->[$j]->start - 1,
3409                                    Type => $type);
3410                     trace "gap between $r->[$j-1] and $r->[$j] [$j], will add: $gap_list[-1]" if main::DEBUG && $to_trace;
3411                 }
3412             }
3413
3414             # Here, we have either found an existing range in the range list,
3415             # beyond the area affected by the input one, or we fell off the
3416             # end of the loop because the input range affects the whole rest
3417             # of the range list.  In either case, $j is 1 higher than the
3418             # highest affected range.  If $j == $i, it means that there are no
3419             # affected ranges, that the entire insertion is in the gap between
3420             # r[$i-1], and r[$i], which we already have taken care of before
3421             # the loop.
3422             # On the other hand, if there are affected ranges, it might be
3423             # that there is a gap that needs filling after the final such
3424             # range to the end of the input range
3425             if ($r->[$j-1]->end < $end) {
3426                     push @gap_list, Range->new(main::max($start,
3427                                                          $r->[$j-1]->end + 1),
3428                                                $end,
3429                                                Type => $type);
3430                     trace "gap after $r->[$j-1], will add $gap_list[-1]" if main::DEBUG && $to_trace;
3431             }
3432
3433             # Call recursively to fill in all the gaps.
3434             foreach my $gap (@gap_list) {
3435                 $self->_add_delete($operation,
3436                                    $gap->start,
3437                                    $gap->end,
3438                                    $value,
3439                                    Type => $type);
3440             }
3441
3442             return;
3443         }
3444
3445         # Here, we have taken care of the case where $replace is $NO.
3446         # Remember that here, r[$i-1]->end < $start <= r[$i]->end
3447         # If inserting a multiple record, this is where it goes, before the
3448         # first (if any) existing one.  This implies an insertion, and no
3449         # change to any existing ranges.  Note that $i can be -1 if this new
3450         # range doesn't actually duplicate any existing, and comes at the
3451         # beginning of the list.
3452         if ($replace == $MULTIPLE) {
3453
3454             if ($start != $end) {
3455                 Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the range ($start..$end) contains more than one code point.  No action taken.");
3456                 return;
3457             }
3458
3459             # Don't add an exact duplicate, as it isn't really a multiple
3460             if ($end >= $r->[$i]->start) {
3461                 if ($r->[$i]->start != $r->[$i]->end) {
3462                     Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the other range ($r->[$i]) contains more than one code point.  No action taken.");
3463                     return;
3464                 }
3465                 return if $value eq $r->[$i]->value && $type eq $r->[$i]->type;
3466             }
3467
3468             trace "Adding multiple record at $i with $start..$end, $value" if main::DEBUG && $to_trace;
3469             my @return = splice @$r,
3470                                 $i,
3471                                 0,
3472                                 Range->new($start,
3473                                            $end,
3474                                            Value => $value,
3475                                            Type => $type);
3476             if (main::DEBUG && $to_trace) {
3477                 trace "After splice:";
3478                 trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3479                 trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3480                 trace "i  =[", $i, "]", $r->[$i] if $i >= 0;
3481                 trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3482                 trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3483                 trace 'i+3=[', $i+3, ']', $r->[$i+3] if $i < @$r - 3;
3484             }
3485             return @return;
3486         }
3487
3488         # Here, we have taken care of $NO and $MULTIPLE replaces.  This leaves
3489         # delete, insert, and replace either unconditionally or if not
3490         # equivalent.  $i still points to the first potential affected range.
3491         # Now find the highest range affected, which will determine the length
3492         # parameter to splice.  (The input range can span multiple existing
3493         # ones.)  If this isn't a deletion, while we are looking through the
3494         # range list, see also if this is a replacement rather than a clean
3495         # insertion; that is if it will change the values of at least one
3496         # existing range.  Start off assuming it is an insert, until find it
3497         # isn't.
3498         my $clean_insert = $operation eq '+';
3499         my $j;        # This will point to the highest affected range
3500
3501         # For non-zero types, the standard form is the value itself;
3502         my $standard_form = ($type) ? $value : main::standardize($value);
3503
3504         for ($j = $i; $j < $range_list_size; $j++) {
3505             trace "Looking for highest affected range; the one at $j is ", $r->[$j] if main::DEBUG && $to_trace;
3506
3507             # If find a range that it doesn't overlap into, we can stop
3508             # searching
3509             last if $end < $r->[$j]->start;
3510
3511             # Here, overlaps the range at $j.  If the values don't match,
3512             # and so far we think this is a clean insertion, it becomes a
3513             # non-clean insertion, i.e., a 'change' or 'replace' instead.
3514             if ($clean_insert) {
3515                 if ($r->[$j]->standard_form ne $standard_form) {
3516                     $clean_insert = 0;
3517                 }
3518                 else {
3519
3520                     # Here, the two values are essentially the same.  If the
3521                     # two are actually identical, replacing wouldn't change
3522                     # anything so skip it.
3523                     my $pre_existing = $r->[$j]->value;
3524                     if ($pre_existing ne $value) {
3525
3526                         # Here the new and old standardized values are the
3527                         # same, but the non-standardized values aren't.  If
3528                         # replacing unconditionally, then replace
3529                         if( $replace == $UNCONDITIONALLY) {
3530                             $clean_insert = 0;
3531                         }
3532                         else {
3533
3534                             # Here, are replacing conditionally.  Decide to
3535                             # replace or not based on which appears to look
3536                             # the "nicest".  If one is mixed case and the
3537                             # other isn't, choose the mixed case one.
3538                             my $new_mixed = $value =~ /[A-Z]/
3539                                             && $value =~ /[a-z]/;
3540                             my $old_mixed = $pre_existing =~ /[A-Z]/
3541                                             && $pre_existing =~ /[a-z]/;
3542
3543                             if ($old_mixed != $new_mixed) {
3544                                 $clean_insert = 0 if $new_mixed;
3545                                 if (main::DEBUG && $to_trace) {
3546                                     if ($clean_insert) {
3547                                         trace "Retaining $pre_existing over $value";
3548                                     }
3549                                     else {
3550                                         trace "Replacing $pre_existing with $value";
3551                                     }
3552                                 }
3553                             }
3554                             else {
3555
3556                                 # Here casing wasn't different between the two.
3557                                 # If one has hyphens or underscores and the
3558                                 # other doesn't, choose the one with the
3559                                 # punctuation.
3560                                 my $new_punct = $value =~ /[-_]/;
3561                                 my $old_punct = $pre_existing =~ /[-_]/;
3562
3563                                 if ($old_punct != $new_punct) {
3564                                     $clean_insert = 0 if $new_punct;
3565                                     if (main::DEBUG && $to_trace) {
3566                                         if ($clean_insert) {
3567                                             trace "Retaining $pre_existing over $value";
3568                                         }
3569                                         else {
3570                                             trace "Replacing $pre_existing with $value";
3571                                         }
3572                                     }
3573                                 }   # else existing one is just as "good";
3574                                     # retain it to save cycles.
3575                             }
3576                         }
3577                     }
3578                 }
3579             }
3580         } # End of loop looking for highest affected range.
3581
3582         # Here, $j points to one beyond the highest range that this insertion
3583         # affects (hence to beyond the range list if that range is the final
3584         # one in the range list).
3585
3586         # The splice length is all the affected ranges.  Get it before
3587         # subtracting, for efficiency, so we don't have to later add 1.
3588         my $length = $j - $i;
3589
3590         $j--;        # $j now points to the highest affected range.
3591         trace "Final affected range is $j: $r->[$j]" if main::DEBUG && $to_trace;
3592
3593         # Here, have taken care of $NO and $MULTIPLE replaces.
3594         # $j points to the highest affected range.  But it can be < $i or even
3595         # -1.  These happen only if the insertion is entirely in the gap
3596         # between r[$i-1] and r[$i].  Here's why: j < i means that the j loop
3597         # above exited first time through with $end < $r->[$i]->start.  (And
3598         # then we subtracted one from j)  This implies also that $start <
3599         # $r->[$i]->start, but we know from above that $r->[$i-1]->end <
3600         # $start, so the entire input range is in the gap.
3601         if ($j < $i) {
3602
3603             # Here the entire input range is in the gap before $i.
3604
3605             if (main::DEBUG && $to_trace) {
3606                 if ($i) {
3607                     trace "Entire range is between $r->[$i-1] and $r->[$i]";
3608                 }
3609                 else {
3610                     trace "Entire range is before $r->[$i]";
3611                 }
3612             }
3613             return if $operation ne '+'; # Deletion of a non-existent range is
3614                                          # a no-op
3615         }
3616         else {
3617
3618             # Here part of the input range is not in the gap before $i.  Thus,
3619             # there is at least one affected one, and $j points to the highest
3620             # such one.
3621
3622             # At this point, here is the situation:
3623             # This is not an insertion of a multiple, nor of tentative ($NO)
3624             # data.
3625             #   $i  points to the first element in the current range list that
3626             #            may be affected by this operation.  In fact, we know
3627             #            that the range at $i is affected because we are in
3628             #            the else branch of this 'if'
3629             #   $j  points to the highest affected range.
3630             # In other words,
3631             #   r[$i-1]->end < $start <= r[$i]->end
3632             # And:
3633             #   r[$i-1]->end < $start <= $end <= r[$j]->end
3634             #
3635             # Also:
3636             #   $clean_insert is a boolean which is set true if and only if
3637             #        this is a "clean insertion", i.e., not a change nor a
3638             #        deletion (multiple was handled above).
3639
3640             # We now have enough information to decide if this call is a no-op
3641             # or not.  It is a no-op if this is an insertion of already
3642             # existing data.
3643
3644             if (main::DEBUG && $to_trace && $clean_insert
3645                                          && $i == $j
3646                                          && $start >= $r->[$i]->start)
3647             {
3648                     trace "no-op";
3649             }
3650             return if $clean_insert
3651                       && $i == $j # more than one affected range => not no-op
3652
3653                       # Here, r[$i-1]->end < $start <= $end <= r[$i]->end
3654                       # Further, $start and/or $end is >= r[$i]->start
3655                       # The test below hence guarantees that
3656                       #     r[$i]->start < $start <= $end <= r[$i]->end
3657                       # This means the input range is contained entirely in
3658                       # the one at $i, so is a no-op
3659                       && $start >= $r->[$i]->start;
3660         }
3661
3662         # Here, we know that some action will have to be taken.  We have
3663         # calculated the offset and length (though adjustments may be needed)
3664         # for the splice.  Now start constructing the replacement list.
3665         my @replacement;
3666         my $splice_start = $i;
3667
3668         my $extends_below;
3669         my $extends_above;
3670
3671         # See if should extend any adjacent ranges.
3672         if ($operation eq '-') { # Don't extend deletions
3673             $extends_below = $extends_above = 0;
3674         }
3675         else {  # Here, should extend any adjacent ranges.  See if there are
3676                 # any.
3677             $extends_below = ($i > 0
3678                             # can't extend unless adjacent
3679                             && $r->[$i-1]->end == $start -1
3680                             # can't extend unless are same standard value
3681                             && $r->[$i-1]->standard_form eq $standard_form
3682                             # can't extend unless share type
3683                             && $r->[$i-1]->type == $type);
3684             $extends_above = ($j+1 < $range_list_size
3685                             && $r->[$j+1]->start == $end +1
3686                             && $r->[$j+1]->standard_form eq $standard_form
3687                             && $r->[$j+1]->type == $type);
3688         }
3689         if ($extends_below && $extends_above) { # Adds to both
3690             $splice_start--;     # start replace at element below
3691             $length += 2;        # will replace on both sides
3692             trace "Extends both below and above ranges" if main::DEBUG && $to_trace;
3693
3694             # The result will fill in any gap, replacing both sides, and
3695             # create one large range.
3696             @replacement = Range->new($r->[$i-1]->start,
3697                                       $r->[$j+1]->end,
3698                                       Value => $value,
3699                                       Type => $type);
3700         }
3701         else {
3702
3703             # Here we know that the result won't just be the conglomeration of
3704             # a new range with both its adjacent neighbors.  But it could
3705             # extend one of them.
3706
3707             if ($extends_below) {
3708
3709                 # Here the new element adds to the one below, but not to the
3710                 # one above.  If inserting, and only to that one range,  can
3711                 # just change its ending to include the new one.
3712                 if ($length == 0 && $clean_insert) {
3713                     $r->[$i-1]->set_end($end);
3714                     trace "inserted range extends range to below so it is now $r->[$i-1]" if main::DEBUG && $to_trace;
3715                     return;
3716                 }
3717                 else {
3718                     trace "Changing inserted range to start at ", sprintf("%04X",  $r->[$i-1]->start), " instead of ", sprintf("%04X", $start) if main::DEBUG && $to_trace;
3719                     $splice_start--;        # start replace at element below
3720                     $length++;              # will replace the element below
3721                     $start = $r->[$i-1]->start;
3722                 }
3723             }
3724             elsif ($extends_above) {
3725
3726                 # Here the new element adds to the one above, but not below.
3727                 # Mirror the code above
3728                 if ($length == 0 && $clean_insert) {
3729                     $r->[$j+1]->set_start($start);
3730                     trace "inserted range extends range to above so it is now $r->[$j+1]" if main::DEBUG && $to_trace;
3731                     return;
3732                 }
3733                 else {
3734                     trace "Changing inserted range to end at ", sprintf("%04X",  $r->[$j+1]->end), " instead of ", sprintf("%04X", $end) if main::DEBUG && $to_trace;
3735                     $length++;        # will replace the element above
3736                     $end = $r->[$j+1]->end;
3737                 }
3738             }
3739
3740             trace "Range at $i is $r->[$i]" if main::DEBUG && $to_trace;
3741
3742             # Finally, here we know there will have to be a splice.
3743             # If the change or delete affects only the highest portion of the
3744             # first affected range, the range will have to be split.  The
3745             # splice will remove the whole range, but will replace it by a new
3746             # range containing just the unaffected part.  So, in this case,
3747             # add to the replacement list just this unaffected portion.
3748             if (! $extends_below
3749                 && $start > $r->[$i]->start && $start <= $r->[$i]->end)
3750             {
3751                 push @replacement,
3752                     Range->new($r->[$i]->start,
3753                                $start - 1,
3754                                Value => $r->[$i]->value,
3755                                Type => $r->[$i]->type);
3756             }
3757
3758             # In the case of an insert or change, but not a delete, we have to
3759             # put in the new stuff;  this comes next.
3760             if ($operation eq '+') {
3761                 push @replacement, Range->new($start,
3762                                               $end,
3763                                               Value => $value,
3764                                               Type => $type);
3765             }
3766
3767             trace "Range at $j is $r->[$j]" if main::DEBUG && $to_trace && $j != $i;
3768             #trace "$end >=", $r->[$j]->start, " && $end <", $r->[$j]->end if main::DEBUG && $to_trace;
3769
3770             # And finally, if we're changing or deleting only a portion of the
3771             # highest affected range, it must be split, as the lowest one was.
3772             if (! $extends_above
3773                 && $j >= 0  # Remember that j can be -1 if before first
3774                             # current element
3775                 && $end >= $r->[$j]->start
3776                 && $end < $r->[$j]->end)
3777             {
3778                 push @replacement,
3779                     Range->new($end + 1,
3780                                $r->[$j]->end,
3781                                Value => $r->[$j]->value,
3782                                Type => $r->[$j]->type);
3783             }
3784         }
3785
3786         # And do the splice, as calculated above
3787         if (main::DEBUG && $to_trace) {
3788             trace "replacing $length element(s) at $i with ";
3789             foreach my $replacement (@replacement) {
3790                 trace "    $replacement";
3791             }
3792             trace "Before splice:";
3793             trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3794             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3795             trace "i  =[", $i, "]", $r->[$i];
3796             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3797             trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3798         }
3799
3800         my @return = splice @$r, $splice_start, $length, @replacement;
3801
3802         if (main::DEBUG && $to_trace) {
3803             trace "After splice:";
3804             trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3805             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3806             trace "i  =[", $i, "]", $r->[$i];
3807             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3808             trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3809             trace "removed @return";
3810         }
3811
3812         # An actual deletion could have changed the maximum in the list.
3813         # There was no deletion if the splice didn't return something, but
3814         # otherwise recalculate it.  This is done too rarely to worry about
3815         # performance.
3816         if ($operation eq '-' && @return) {
3817             $max{$addr} = $r->[-1]->end;
3818         }
3819         return @return;
3820     }
3821
3822     sub reset_each_range {  # reset the iterator for each_range();
3823         my $self = shift;
3824         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3825
3826         no overloading;
3827         undef $each_range_iterator{pack 'J', $self};
3828         return;
3829     }
3830
3831     sub each_range {
3832         # Iterate over each range in a range list.  Results are undefined if
3833         # the range list is changed during the iteration.
3834
3835         my $self = shift;
3836         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3837
3838         my $addr = do { no overloading; pack 'J', $self; };
3839
3840         return if $self->is_empty;
3841
3842         $each_range_iterator{$addr} = -1
3843                                 if ! defined $each_range_iterator{$addr};
3844         $each_range_iterator{$addr}++;
3845         return $ranges{$addr}->[$each_range_iterator{$addr}]
3846                         if $each_range_iterator{$addr} < @{$ranges{$addr}};
3847         undef $each_range_iterator{$addr};
3848         return;
3849     }
3850
3851     sub count {        # Returns count of code points in range list
3852         my $self = shift;
3853         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3854
3855         my $addr = do { no overloading; pack 'J', $self; };
3856
3857         my $count = 0;
3858         foreach my $range (@{$ranges{$addr}}) {
3859             $count += $range->end - $range->start + 1;
3860         }
3861         return $count;
3862     }
3863
3864     sub delete_range {    # Delete a range
3865         my $self = shift;
3866         my $start = shift;
3867         my $end = shift;
3868
3869         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3870
3871         return $self->_add_delete('-', $start, $end, "");
3872     }
3873
3874     sub is_empty { # Returns boolean as to if a range list is empty
3875         my $self = shift;
3876         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3877
3878         no overloading;
3879         return scalar @{$ranges{pack 'J', $self}} == 0;
3880     }
3881
3882     sub hash {
3883         # Quickly returns a scalar suitable for separating tables into
3884         # buckets, i.e. it is a hash function of the contents of a table, so
3885         # there are relatively few conflicts.
3886
3887         my $self = shift;
3888         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3889
3890         my $addr = do { no overloading; pack 'J', $self; };
3891
3892         # These are quickly computable.  Return looks like 'min..max;count'
3893         return $self->min . "..$max{$addr};" . scalar @{$ranges{$addr}};
3894     }
3895 } # End closure for _Range_List_Base
3896
3897 package Range_List;
3898 use base '_Range_List_Base';
3899
3900 # A Range_List is a range list for match tables; i.e. the range values are
3901 # not significant.  Thus a number of operations can be safely added to it,
3902 # such as inversion, intersection.  Note that union is also an unsafe
3903 # operation when range values are cared about, and that method is in the base
3904 # class, not here.  But things are set up so that that method is callable only
3905 # during initialization.  Only in this derived class, is there an operation
3906 # that combines two tables.  A Range_Map can thus be used to initialize a
3907 # Range_List, and its mappings will be in the list, but are not significant to
3908 # this class.
3909
3910 sub trace { return main::trace(@_); }
3911
3912 { # Closure
3913
3914     use overload
3915         fallback => 0,
3916         '+' => sub { my $self = shift;
3917                     my $other = shift;
3918
3919                     return $self->_union($other)
3920                 },
3921         '&' => sub { my $self = shift;
3922                     my $other = shift;
3923
3924                     return $self->_intersect($other, 0);
3925                 },
3926         '~' => "_invert",
3927         '-' => "_subtract",
3928     ;
3929
3930     sub _invert {
3931         # Returns a new Range_List that gives all code points not in $self.
3932
3933         my $self = shift;
3934
3935         my $new = Range_List->new;
3936
3937         # Go through each range in the table, finding the gaps between them
3938         my $max = -1;   # Set so no gap before range beginning at 0
3939         for my $range ($self->ranges) {
3940             my $start = $range->start;
3941             my $end   = $range->end;
3942
3943             # If there is a gap before this range, the inverse will contain
3944             # that gap.
3945             if ($start > $max + 1) {
3946                 $new->add_range($max + 1, $start - 1);
3947             }
3948             $max = $end;
3949         }
3950
3951         # And finally, add the gap from the end of the table to the max
3952         # possible code point
3953         if ($max < $LAST_UNICODE_CODEPOINT) {
3954             $new->add_range($max + 1, $LAST_UNICODE_CODEPOINT);
3955         }
3956         return $new;
3957     }
3958
3959     sub _subtract {
3960         # Returns a new Range_List with the argument deleted from it.  The
3961         # argument can be a single code point, a range, or something that has
3962         # a range, with the _range_list() method on it returning them
3963
3964         my $self = shift;
3965         my $other = shift;
3966         my $reversed = shift;
3967         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3968
3969         if ($reversed) {
3970             Carp::my_carp_bug("Can't cope with a "
3971              .  __PACKAGE__
3972              . " being the second parameter in a '-'.  Subtraction ignored.");
3973             return $self;
3974         }
3975
3976         my $new = Range_List->new(Initialize => $self);
3977
3978         if (! ref $other) { # Single code point
3979             $new->delete_range($other, $other);
3980         }
3981         elsif ($other->isa('Range')) {
3982             $new->delete_range($other->start, $other->end);
3983         }
3984         elsif ($other->can('_range_list')) {
3985             foreach my $range ($other->_range_list->ranges) {
3986                 $new->delete_range($range->start, $range->end);
3987             }
3988         }
3989         else {
3990             Carp::my_carp_bug("Can't cope with a "
3991                         . ref($other)