This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
f416f29560969d1b2300e55c275d0f1f99ae1cb5
[perl5.git] / t / op / regexp.t
1 #!./perl
2
3 # The tests are in a separate file 't/op/re_tests'.
4 # Each line in that file is a separate test.
5 # There are five columns, separated by tabs.
6 #
7 # Column 1 contains the pattern, optionally enclosed in C<''>.
8 # Modifiers can be put after the closing C<'>.
9 #
10 # Column 2 contains the string to be matched.
11 #
12 # Column 3 contains the expected result:
13 #       y       expect a match
14 #       n       expect no match
15 #       c       expect an error
16 #       B       test exposes a known bug in Perl, should be skipped
17 #       b       test exposes a known bug in Perl, should be skipped if noamp
18 #
19 # Columns 4 and 5 are used only if column 3 contains C<y> or C<c>.
20 #
21 # Column 4 contains a string, usually C<$&>.
22 #
23 # Column 5 contains the expected result of double-quote
24 # interpolating that string after the match, or start of error message.
25 #
26 # Column 6, if present, contains a reason why the test is skipped.
27 # This is printed with "skipped", for harness to pick up.
28 #
29 # \n in the tests are interpolated, as are variables of the form ${\w+}.
30 #
31 # Blanks lines are treated as PASSING tests to keep the line numbers
32 # linked to the test number.
33 #
34 # If you want to add a regular expression test that can't be expressed
35 # in this format, don't add it here: put it in op/pat.t instead.
36 #
37 # Note that columns 2,3 and 5 are all enclosed in double quotes and then
38 # evalled; so something like a\"\x{100}$1 has length 3+length($1).
39
40 BEGIN {
41     chdir 't' if -d 't';
42     @INC = '../lib';
43 }
44 use strict;
45 use vars qw($iters $numtests $bang $ffff $nulnul $OP);
46 use vars qw($qr $skip_amp $qr_embed); # set by our callers
47
48 $iters = shift || 1;            # Poor man performance suite, 10000 is OK.
49
50 open(TESTS,'op/re_tests') || open(TESTS,'t/op/re_tests') || open(TESTS,':op:re_tests') ||
51         die "Can't open re_tests";
52
53 while (<TESTS>) { }
54 $numtests = $.;
55 seek(TESTS,0,0);
56 $. = 0;
57
58 $bang = sprintf "\\%03o", ord "!"; # \41 would not be portable.
59 $ffff  = chr(0xff) x 2;
60 $nulnul = "\0" x 2;
61 $OP = $qr ? 'qr' : 'm';
62
63 $| = 1;
64 print "1..$numtests\n# $iters iterations\n";
65 TEST:
66 while (<TESTS>) {
67     if (!/\S/ || /^\s*#/) {
68         print "ok $. # (Blank line or comment)\n";
69         if (/\S/) { print $_ };
70         next;
71     }
72     chomp;
73     s/\\n/\n/g;
74     my ($pat, $subject, $result, $repl, $expect, $reason) = split(/\t/,$_,6);
75     my $input = join(':',$pat,$subject,$result,$repl,$expect);
76     $pat = "'$pat'" unless $pat =~ /^[:'\/]/;
77     $pat =~ s/(\$\{\w+\})/$1/eeg;
78     $pat =~ s/\\n/\n/g;
79     $subject = eval qq("$subject");
80     $expect  = eval qq("$expect");
81     $expect = $repl = '-' if $skip_amp and $input =~ /\$[&\`\']/;
82     my $skip = ($skip_amp ? ($result =~ s/B//i) : ($result =~ s/B//));
83     $reason = 'skipping $&' if $reason eq  '' && $skip_amp;
84     $result =~ s/B//i unless $skip;
85
86     for my $study ('', 'study $subject') {
87         my $c = $iters;
88         my ($code, $match, $got);
89         if ($repl eq 'pos') {
90             $code= <<EOFCODE;
91                 $study;
92                 pos(\$subject)=0;
93                 \$match = ( \$subject =~ m${pat}g );
94                 \$got = pos(\$subject);
95 EOFCODE
96         }
97         elsif ($qr_embed) {
98             $code= <<EOFCODE;
99                 my \$RE = qr$pat;
100                 $study;
101                 \$match = (\$subject =~ /(?:)\$RE(?:)/) while \$c--;
102                 \$got = "$repl";
103 EOFCODE
104         }
105         else {
106             $code= <<EOFCODE;
107                 $study;
108                 \$match = (\$subject =~ $OP$pat) while \$c--;
109                 \$got = "$repl";
110 EOFCODE
111         }
112         eval $code;
113         chomp( my $err = $@ );
114         if ($result eq 'c') {
115             if ($err !~ m!^\Q$expect!) { print "not ok $. (compile) $input => `$err'\n"; next TEST }
116             last;  # no need to study a syntax error
117         }
118         elsif ( $skip ) {
119             print "ok $. # skipped", length($reason) ? " $reason" : '', "\n";
120             next TEST;
121         }
122         elsif ($@) {
123             print "not ok $. $input => error `$err'\n$code\n$@\n"; next TEST;
124         }
125         elsif ($result eq 'n') {
126             if ($match) { print "not ok $. ($study) $input => false positive\n"; next TEST }
127         }
128         else {
129             if (!$match || $got ne $expect) {
130                 eval { require Data::Dumper };
131                 if ($@) {
132                     print "not ok $. ($study) $input => `$got', match=$match\n$code\n";
133                 }
134                 else { # better diagnostics
135                     my $s = Data::Dumper->new([$subject],['subject'])->Useqq(1)->Dump;
136                     my $g = Data::Dumper->new([$got],['got'])->Useqq(1)->Dump;
137                     print "not ok $. ($study) $input => `$got', match=$match\n$s\n$g\n$code\n";
138                 }
139                 next TEST;
140             }
141         }
142     }
143     print "ok $.\n";
144 }
145
146 close(TESTS);