This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
rewrite "ref" documentation for clarity
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance,
20 L<C<splice>|/splice ARRAY,OFFSET,LENGTH,LIST> has three scalar arguments
21 followed by a list, whereas L<C<gethostbyname>|/gethostbyname NAME> has
22 four scalar arguments.
23
24 In the syntax descriptions that follow, list operators that expect a
25 list (and provide list context for elements of the list) are shown
26 with LIST as an argument.  Such a list may consist of any combination
27 of scalar arguments or list values; the list values will be included
28 in the list as if each individual element were interpolated at that
29 point in the list, forming a longer single-dimensional list value.
30 Commas should separate literal elements of the LIST.
31
32 Any function in the list below may be used either with or without
33 parentheses around its arguments.  (The syntax descriptions omit the
34 parentheses.)  If you use parentheses, the simple but occasionally
35 surprising rule is this: It I<looks> like a function, therefore it I<is> a
36 function, and precedence doesn't matter.  Otherwise it's a list
37 operator or unary operator, and precedence does matter.  Whitespace
38 between the function and left parenthesis doesn't count, so sometimes
39 you need to be careful:
40
41     print 1+2+4;      # Prints 7.
42     print(1+2) + 4;   # Prints 3.
43     print (1+2)+4;    # Also prints 3!
44     print +(1+2)+4;   # Prints 7.
45     print ((1+2)+4);  # Prints 7.
46
47 If you run Perl with the L<C<use warnings>|warnings> pragma, it can warn
48 you about this.  For example, the third line above produces:
49
50     print (...) interpreted as function at - line 1.
51     Useless use of integer addition in void context at - line 1.
52
53 A few functions take no arguments at all, and therefore work as neither
54 unary nor list operators.  These include such functions as
55 L<C<time>|/time> and L<C<endpwent>|/endpwent>.  For example,
56 C<time+86_400> always means C<time() + 86_400>.
57
58 For functions that can be used in either a scalar or list context,
59 nonabortive failure is generally indicated in scalar context by
60 returning the undefined value, and in list context by returning the
61 empty list.
62
63 Remember the following important rule: There is B<no rule> that relates
64 the behavior of an expression in list context to its behavior in scalar
65 context, or vice versa.  It might do two totally different things.
66 Each operator and function decides which sort of value would be most
67 appropriate to return in scalar context.  Some operators return the
68 length of the list that would have been returned in list context.  Some
69 operators return the first value in the list.  Some operators return the
70 last value in the list.  Some operators return a count of successful
71 operations.  In general, they do what you want, unless you want
72 consistency.
73 X<context>
74
75 A named array in scalar context is quite different from what would at
76 first glance appear to be a list in scalar context.  You can't get a list
77 like C<(1,2,3)> into being in scalar context, because the compiler knows
78 the context at compile time.  It would generate the scalar comma operator
79 there, not the list concatenation version of the comma.  That means it
80 was never a list to start with.
81
82 In general, functions in Perl that serve as wrappers for system calls
83 ("syscalls") of the same name (like L<chown(2)>, L<fork(2)>,
84 L<closedir(2)>, etc.) return true when they succeed and
85 L<C<undef>|/undef EXPR> otherwise, as is usually mentioned in the
86 descriptions below.  This is different from the C interfaces, which
87 return C<-1> on failure.  Exceptions to this rule include
88 L<C<wait>|/wait>, L<C<waitpid>|/waitpid PID,FLAGS>, and
89 L<C<syscall>|/syscall NUMBER, LIST>.  System calls also set the special
90 L<C<$!>|perlvar/$!> variable on failure.  Other functions do not, except
91 accidentally.
92
93 Extension modules can also hook into the Perl parser to define new
94 kinds of keyword-headed expression.  These may look like functions, but
95 may also look completely different.  The syntax following the keyword
96 is defined entirely by the extension.  If you are an implementor, see
97 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
98 a module, see the module's documentation for details of the syntax that
99 it defines.
100
101 =head2 Perl Functions by Category
102 X<function>
103
104 Here are Perl's functions (including things that look like
105 functions, like some keywords and named operators)
106 arranged by category.  Some functions appear in more
107 than one place.  Any warnings, including those produced by
108 +keywords, are described in L<perldiag> and L<warnings>.
109
110 =over 4
111
112 =item Functions for SCALARs or strings
113 X<scalar> X<string> X<character>
114
115 =for Pod::Functions =String
116
117 L<C<chomp>|/chomp VARIABLE>, L<C<chop>|/chop VARIABLE>,
118 L<C<chr>|/chr NUMBER>, L<C<crypt>|/crypt PLAINTEXT,SALT>,
119 L<C<fc>|/fc EXPR>, L<C<hex>|/hex EXPR>,
120 L<C<index>|/index STR,SUBSTR,POSITION>, L<C<lc>|/lc EXPR>,
121 L<C<lcfirst>|/lcfirst EXPR>, L<C<length>|/length EXPR>,
122 L<C<oct>|/oct EXPR>, L<C<ord>|/ord EXPR>,
123 L<C<pack>|/pack TEMPLATE,LIST>,
124 L<C<qE<sol>E<sol>>|/qE<sol>STRINGE<sol>>,
125 L<C<qqE<sol>E<sol>>|/qqE<sol>STRINGE<sol>>, L<C<reverse>|/reverse LIST>,
126 L<C<rindex>|/rindex STR,SUBSTR,POSITION>,
127 L<C<sprintf>|/sprintf FORMAT, LIST>,
128 L<C<substr>|/substr EXPR,OFFSET,LENGTH,REPLACEMENT>,
129 L<C<trE<sol>E<sol>E<sol>>|/trE<sol>E<sol>E<sol>>, L<C<uc>|/uc EXPR>,
130 L<C<ucfirst>|/ucfirst EXPR>,
131 L<C<yE<sol>E<sol>E<sol>>|/yE<sol>E<sol>E<sol>>
132
133 L<C<fc>|/fc EXPR> is available only if the
134 L<C<"fc"> feature|feature/The 'fc' feature> is enabled or if it is
135 prefixed with C<CORE::>.  The
136 L<C<"fc"> feature|feature/The 'fc' feature> is enabled automatically
137 with a C<use v5.16> (or higher) declaration in the current scope.
138
139 =item Regular expressions and pattern matching
140 X<regular expression> X<regex> X<regexp>
141
142 =for Pod::Functions =Regexp
143
144 L<C<mE<sol>E<sol>>|/mE<sol>E<sol>>, L<C<pos>|/pos SCALAR>,
145 L<C<qrE<sol>E<sol>>|/qrE<sol>STRINGE<sol>>,
146 L<C<quotemeta>|/quotemeta EXPR>,
147 L<C<sE<sol>E<sol>E<sol>>|/sE<sol>E<sol>E<sol>>,
148 L<C<split>|/split E<sol>PATTERNE<sol>,EXPR,LIMIT>,
149 L<C<study>|/study SCALAR>
150
151 =item Numeric functions
152 X<numeric> X<number> X<trigonometric> X<trigonometry>
153
154 =for Pod::Functions =Math
155
156 L<C<abs>|/abs VALUE>, L<C<atan2>|/atan2 Y,X>, L<C<cos>|/cos EXPR>,
157 L<C<exp>|/exp EXPR>, L<C<hex>|/hex EXPR>, L<C<int>|/int EXPR>,
158 L<C<log>|/log EXPR>, L<C<oct>|/oct EXPR>, L<C<rand>|/rand EXPR>,
159 L<C<sin>|/sin EXPR>, L<C<sqrt>|/sqrt EXPR>, L<C<srand>|/srand EXPR>
160
161 =item Functions for real @ARRAYs
162 X<array>
163
164 =for Pod::Functions =ARRAY
165
166 L<C<each>|/each HASH>, L<C<keys>|/keys HASH>, L<C<pop>|/pop ARRAY>,
167 L<C<push>|/push ARRAY,LIST>, L<C<shift>|/shift ARRAY>,
168 L<C<splice>|/splice ARRAY,OFFSET,LENGTH,LIST>,
169 L<C<unshift>|/unshift ARRAY,LIST>, L<C<values>|/values HASH>
170
171 =item Functions for list data
172 X<list>
173
174 =for Pod::Functions =LIST
175
176 L<C<grep>|/grep BLOCK LIST>, L<C<join>|/join EXPR,LIST>,
177 L<C<map>|/map BLOCK LIST>, L<C<qwE<sol>E<sol>>|/qwE<sol>STRINGE<sol>>,
178 L<C<reverse>|/reverse LIST>, L<C<sort>|/sort SUBNAME LIST>,
179 L<C<unpack>|/unpack TEMPLATE,EXPR>
180
181 =item Functions for real %HASHes
182 X<hash>
183
184 =for Pod::Functions =HASH
185
186 L<C<delete>|/delete EXPR>, L<C<each>|/each HASH>,
187 L<C<exists>|/exists EXPR>, L<C<keys>|/keys HASH>,
188 L<C<values>|/values HASH>
189
190 =item Input and output functions
191 X<I/O> X<input> X<output> X<dbm>
192
193 =for Pod::Functions =I/O
194
195 L<C<binmode>|/binmode FILEHANDLE, LAYER>, L<C<close>|/close FILEHANDLE>,
196 L<C<closedir>|/closedir DIRHANDLE>, L<C<dbmclose>|/dbmclose HASH>,
197 L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK>, L<C<die>|/die LIST>,
198 L<C<eof>|/eof FILEHANDLE>, L<C<fileno>|/fileno FILEHANDLE>,
199 L<C<flock>|/flock FILEHANDLE,OPERATION>, L<C<format>|/format>,
200 L<C<getc>|/getc FILEHANDLE>, L<C<print>|/print FILEHANDLE LIST>,
201 L<C<printf>|/printf FILEHANDLE FORMAT, LIST>,
202 L<C<read>|/read FILEHANDLE,SCALAR,LENGTH,OFFSET>,
203 L<C<readdir>|/readdir DIRHANDLE>, L<C<readline>|/readline EXPR>,
204 L<C<rewinddir>|/rewinddir DIRHANDLE>, L<C<say>|/say FILEHANDLE LIST>,
205 L<C<seek>|/seek FILEHANDLE,POSITION,WHENCE>,
206 L<C<seekdir>|/seekdir DIRHANDLE,POS>,
207 L<C<select>|/select RBITS,WBITS,EBITS,TIMEOUT>,
208 L<C<syscall>|/syscall NUMBER, LIST>,
209 L<C<sysread>|/sysread FILEHANDLE,SCALAR,LENGTH,OFFSET>,
210 L<C<sysseek>|/sysseek FILEHANDLE,POSITION,WHENCE>,
211 L<C<syswrite>|/syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET>,
212 L<C<tell>|/tell FILEHANDLE>, L<C<telldir>|/telldir DIRHANDLE>,
213 L<C<truncate>|/truncate FILEHANDLE,LENGTH>, L<C<warn>|/warn LIST>,
214 L<C<write>|/write FILEHANDLE>
215
216 L<C<say>|/say FILEHANDLE LIST> is available only if the
217 L<C<"say"> feature|feature/The 'say' feature> is enabled or if it is
218 prefixed with C<CORE::>.  The
219 L<C<"say"> feature|feature/The 'say' feature> is enabled automatically
220 with a C<use v5.10> (or higher) declaration in the current scope.
221
222 =item Functions for fixed-length data or records
223
224 =for Pod::Functions =Binary
225
226 L<C<pack>|/pack TEMPLATE,LIST>,
227 L<C<read>|/read FILEHANDLE,SCALAR,LENGTH,OFFSET>,
228 L<C<syscall>|/syscall NUMBER, LIST>,
229 L<C<sysread>|/sysread FILEHANDLE,SCALAR,LENGTH,OFFSET>,
230 L<C<sysseek>|/sysseek FILEHANDLE,POSITION,WHENCE>,
231 L<C<syswrite>|/syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET>,
232 L<C<unpack>|/unpack TEMPLATE,EXPR>, L<C<vec>|/vec EXPR,OFFSET,BITS>
233
234 =item Functions for filehandles, files, or directories
235 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
236
237 =for Pod::Functions =File
238
239 L<C<-I<X>>|/-X FILEHANDLE>, L<C<chdir>|/chdir EXPR>,
240 L<C<chmod>|/chmod LIST>, L<C<chown>|/chown LIST>,
241 L<C<chroot>|/chroot FILENAME>,
242 L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR>, L<C<glob>|/glob EXPR>,
243 L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR>,
244 L<C<link>|/link OLDFILE,NEWFILE>, L<C<lstat>|/lstat FILEHANDLE>,
245 L<C<mkdir>|/mkdir FILENAME,MODE>, L<C<open>|/open FILEHANDLE,EXPR>,
246 L<C<opendir>|/opendir DIRHANDLE,EXPR>, L<C<readlink>|/readlink EXPR>,
247 L<C<rename>|/rename OLDNAME,NEWNAME>, L<C<rmdir>|/rmdir FILENAME>,
248 L<C<select>|/select FILEHANDLE>, L<C<stat>|/stat FILEHANDLE>,
249 L<C<symlink>|/symlink OLDFILE,NEWFILE>,
250 L<C<sysopen>|/sysopen FILEHANDLE,FILENAME,MODE>,
251 L<C<umask>|/umask EXPR>, L<C<unlink>|/unlink LIST>,
252 L<C<utime>|/utime LIST>
253
254 =item Keywords related to the control flow of your Perl program
255 X<control flow>
256
257 =for Pod::Functions =Flow
258
259 L<C<break>|/break>, L<C<caller>|/caller EXPR>,
260 L<C<continue>|/continue BLOCK>, L<C<die>|/die LIST>, L<C<do>|/do BLOCK>,
261 L<C<dump>|/dump LABEL>, L<C<eval>|/eval EXPR>,
262 L<C<evalbytes>|/evalbytes EXPR>, L<C<exit>|/exit EXPR>,
263 L<C<__FILE__>|/__FILE__>, L<C<goto>|/goto LABEL>,
264 L<C<last>|/last LABEL>, L<C<__LINE__>|/__LINE__>,
265 L<C<next>|/next LABEL>, L<C<__PACKAGE__>|/__PACKAGE__>,
266 L<C<redo>|/redo LABEL>, L<C<return>|/return EXPR>,
267 L<C<sub>|/sub NAME BLOCK>, L<C<__SUB__>|/__SUB__>,
268 L<C<wantarray>|/wantarray>
269
270 L<C<break>|/break> is available only if you enable the experimental
271 L<C<"switch"> feature|feature/The 'switch' feature> or use the C<CORE::>
272 prefix.  The L<C<"switch"> feature|feature/The 'switch' feature> also
273 enables the C<default>, C<given> and C<when> statements, which are
274 documented in L<perlsyn/"Switch Statements">.
275 The L<C<"switch"> feature|feature/The 'switch' feature> is enabled
276 automatically with a C<use v5.10> (or higher) declaration in the current
277 scope.  In Perl v5.14 and earlier, L<C<continue>|/continue BLOCK>
278 required the L<C<"switch"> feature|feature/The 'switch' feature>, like
279 the other keywords.
280
281 L<C<evalbytes>|/evalbytes EXPR> is only available with the
282 L<C<"evalbytes"> feature|feature/The 'unicode_eval' and 'evalbytes' features>
283 (see L<feature>) or if prefixed with C<CORE::>.  L<C<__SUB__>|/__SUB__>
284 is only available with the
285 L<C<"current_sub"> feature|feature/The 'current_sub' feature> or if
286 prefixed with C<CORE::>.  Both the
287 L<C<"evalbytes">|feature/The 'unicode_eval' and 'evalbytes' features>
288 and L<C<"current_sub">|feature/The 'current_sub' feature> features are
289 enabled automatically with a C<use v5.16> (or higher) declaration in the
290 current scope.
291
292 =item Keywords related to scoping
293
294 =for Pod::Functions =Namespace
295
296 L<C<caller>|/caller EXPR>, L<C<import>|/import LIST>,
297 L<C<local>|/local EXPR>, L<C<my>|/my VARLIST>, L<C<our>|/our VARLIST>,
298 L<C<package>|/package NAMESPACE>, L<C<state>|/state VARLIST>,
299 L<C<use>|/use Module VERSION LIST>
300
301 L<C<state>|/state VARLIST> is available only if the
302 L<C<"state"> feature|feature/The 'state' feature> is enabled or if it is
303 prefixed with C<CORE::>.  The
304 L<C<"state"> feature|feature/The 'state' feature> is enabled
305 automatically with a C<use v5.10> (or higher) declaration in the current
306 scope.
307
308 =item Miscellaneous functions
309
310 =for Pod::Functions =Misc
311
312 L<C<defined>|/defined EXPR>, L<C<formline>|/formline PICTURE,LIST>,
313 L<C<lock>|/lock THING>, L<C<prototype>|/prototype FUNCTION>,
314 L<C<reset>|/reset EXPR>, L<C<scalar>|/scalar EXPR>,
315 L<C<undef>|/undef EXPR>
316
317 =item Functions for processes and process groups
318 X<process> X<pid> X<process id>
319
320 =for Pod::Functions =Process
321
322 L<C<alarm>|/alarm SECONDS>, L<C<exec>|/exec LIST>, L<C<fork>|/fork>,
323 L<C<getpgrp>|/getpgrp PID>, L<C<getppid>|/getppid>,
324 L<C<getpriority>|/getpriority WHICH,WHO>, L<C<kill>|/kill SIGNAL, LIST>,
325 L<C<pipe>|/pipe READHANDLE,WRITEHANDLE>,
326 L<C<qxE<sol>E<sol>>|/qxE<sol>STRINGE<sol>>,
327 L<C<readpipe>|/readpipe EXPR>, L<C<setpgrp>|/setpgrp PID,PGRP>,
328 L<C<setpriority>|/setpriority WHICH,WHO,PRIORITY>,
329 L<C<sleep>|/sleep EXPR>, L<C<system>|/system LIST>, L<C<times>|/times>,
330 L<C<wait>|/wait>, L<C<waitpid>|/waitpid PID,FLAGS>
331
332 =item Keywords related to Perl modules
333 X<module>
334
335 =for Pod::Functions =Modules
336
337 L<C<do>|/do EXPR>, L<C<import>|/import LIST>,
338 L<C<no>|/no MODULE VERSION LIST>, L<C<package>|/package NAMESPACE>,
339 L<C<require>|/require VERSION>, L<C<use>|/use Module VERSION LIST>
340
341 =item Keywords related to classes and object-orientation
342 X<object> X<class> X<package>
343
344 =for Pod::Functions =Objects
345
346 L<C<bless>|/bless REF,CLASSNAME>, L<C<dbmclose>|/dbmclose HASH>,
347 L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK>,
348 L<C<package>|/package NAMESPACE>, L<C<ref>|/ref EXPR>,
349 L<C<tie>|/tie VARIABLE,CLASSNAME,LIST>, L<C<tied>|/tied VARIABLE>,
350 L<C<untie>|/untie VARIABLE>, L<C<use>|/use Module VERSION LIST>
351
352 =item Low-level socket functions
353 X<socket> X<sock>
354
355 =for Pod::Functions =Socket
356
357 L<C<accept>|/accept NEWSOCKET,GENERICSOCKET>,
358 L<C<bind>|/bind SOCKET,NAME>, L<C<connect>|/connect SOCKET,NAME>,
359 L<C<getpeername>|/getpeername SOCKET>,
360 L<C<getsockname>|/getsockname SOCKET>,
361 L<C<getsockopt>|/getsockopt SOCKET,LEVEL,OPTNAME>,
362 L<C<listen>|/listen SOCKET,QUEUESIZE>,
363 L<C<recv>|/recv SOCKET,SCALAR,LENGTH,FLAGS>,
364 L<C<send>|/send SOCKET,MSG,FLAGS,TO>,
365 L<C<setsockopt>|/setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL>,
366 L<C<shutdown>|/shutdown SOCKET,HOW>,
367 L<C<socket>|/socket SOCKET,DOMAIN,TYPE,PROTOCOL>,
368 L<C<socketpair>|/socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL>
369
370 =item System V interprocess communication functions
371 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
372
373 =for Pod::Functions =SysV
374
375 L<C<msgctl>|/msgctl ID,CMD,ARG>, L<C<msgget>|/msgget KEY,FLAGS>,
376 L<C<msgrcv>|/msgrcv ID,VAR,SIZE,TYPE,FLAGS>,
377 L<C<msgsnd>|/msgsnd ID,MSG,FLAGS>,
378 L<C<semctl>|/semctl ID,SEMNUM,CMD,ARG>,
379 L<C<semget>|/semget KEY,NSEMS,FLAGS>, L<C<semop>|/semop KEY,OPSTRING>,
380 L<C<shmctl>|/shmctl ID,CMD,ARG>, L<C<shmget>|/shmget KEY,SIZE,FLAGS>,
381 L<C<shmread>|/shmread ID,VAR,POS,SIZE>,
382 L<C<shmwrite>|/shmwrite ID,STRING,POS,SIZE>
383
384 =item Fetching user and group info
385 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
386
387 =for Pod::Functions =User
388
389 L<C<endgrent>|/endgrent>, L<C<endhostent>|/endhostent>,
390 L<C<endnetent>|/endnetent>, L<C<endpwent>|/endpwent>,
391 L<C<getgrent>|/getgrent>, L<C<getgrgid>|/getgrgid GID>,
392 L<C<getgrnam>|/getgrnam NAME>, L<C<getlogin>|/getlogin>,
393 L<C<getpwent>|/getpwent>, L<C<getpwnam>|/getpwnam NAME>,
394 L<C<getpwuid>|/getpwuid UID>, L<C<setgrent>|/setgrent>,
395 L<C<setpwent>|/setpwent>
396
397 =item Fetching network info
398 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
399
400 =for Pod::Functions =Network
401
402 L<C<endprotoent>|/endprotoent>, L<C<endservent>|/endservent>,
403 L<C<gethostbyaddr>|/gethostbyaddr ADDR,ADDRTYPE>,
404 L<C<gethostbyname>|/gethostbyname NAME>, L<C<gethostent>|/gethostent>,
405 L<C<getnetbyaddr>|/getnetbyaddr ADDR,ADDRTYPE>,
406 L<C<getnetbyname>|/getnetbyname NAME>, L<C<getnetent>|/getnetent>,
407 L<C<getprotobyname>|/getprotobyname NAME>,
408 L<C<getprotobynumber>|/getprotobynumber NUMBER>,
409 L<C<getprotoent>|/getprotoent>,
410 L<C<getservbyname>|/getservbyname NAME,PROTO>,
411 L<C<getservbyport>|/getservbyport PORT,PROTO>,
412 L<C<getservent>|/getservent>, L<C<sethostent>|/sethostent STAYOPEN>,
413 L<C<setnetent>|/setnetent STAYOPEN>,
414 L<C<setprotoent>|/setprotoent STAYOPEN>,
415 L<C<setservent>|/setservent STAYOPEN>
416
417 =item Time-related functions
418 X<time> X<date>
419
420 =for Pod::Functions =Time
421
422 L<C<gmtime>|/gmtime EXPR>, L<C<localtime>|/localtime EXPR>,
423 L<C<time>|/time>, L<C<times>|/times>
424
425 =item Non-function keywords
426
427 =for Pod::Functions =!Non-functions
428
429 C<and>, C<AUTOLOAD>, C<BEGIN>, C<CHECK>, C<cmp>, C<CORE>, C<__DATA__>,
430 C<default>, C<DESTROY>, C<else>, C<elseif>, C<elsif>, C<END>, C<__END__>,
431 C<eq>, C<for>, C<foreach>, C<ge>, C<given>, C<gt>, C<if>, C<INIT>, C<le>,
432 C<lt>, C<ne>, C<not>, C<or>, C<UNITCHECK>, C<unless>, C<until>, C<when>,
433 C<while>, C<x>, C<xor>
434
435 =back
436
437 =head2 Portability
438 X<portability> X<Unix> X<portable>
439
440 Perl was born in Unix and can therefore access all common Unix
441 system calls.  In non-Unix environments, the functionality of some
442 Unix system calls may not be available or details of the available
443 functionality may differ slightly.  The Perl functions affected
444 by this are:
445
446 L<C<-I<X>>|/-X FILEHANDLE>, L<C<binmode>|/binmode FILEHANDLE, LAYER>,
447 L<C<chmod>|/chmod LIST>, L<C<chown>|/chown LIST>,
448 L<C<chroot>|/chroot FILENAME>, L<C<crypt>|/crypt PLAINTEXT,SALT>,
449 L<C<dbmclose>|/dbmclose HASH>, L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK>,
450 L<C<dump>|/dump LABEL>, L<C<endgrent>|/endgrent>,
451 L<C<endhostent>|/endhostent>, L<C<endnetent>|/endnetent>,
452 L<C<endprotoent>|/endprotoent>, L<C<endpwent>|/endpwent>,
453 L<C<endservent>|/endservent>, L<C<exec>|/exec LIST>,
454 L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR>,
455 L<C<flock>|/flock FILEHANDLE,OPERATION>, L<C<fork>|/fork>,
456 L<C<getgrent>|/getgrent>, L<C<getgrgid>|/getgrgid GID>,
457 L<C<gethostbyname>|/gethostbyname NAME>, L<C<gethostent>|/gethostent>,
458 L<C<getlogin>|/getlogin>,
459 L<C<getnetbyaddr>|/getnetbyaddr ADDR,ADDRTYPE>,
460 L<C<getnetbyname>|/getnetbyname NAME>, L<C<getnetent>|/getnetent>,
461 L<C<getppid>|/getppid>, L<C<getpgrp>|/getpgrp PID>,
462 L<C<getpriority>|/getpriority WHICH,WHO>,
463 L<C<getprotobynumber>|/getprotobynumber NUMBER>,
464 L<C<getprotoent>|/getprotoent>, L<C<getpwent>|/getpwent>,
465 L<C<getpwnam>|/getpwnam NAME>, L<C<getpwuid>|/getpwuid UID>,
466 L<C<getservbyport>|/getservbyport PORT,PROTO>,
467 L<C<getservent>|/getservent>,
468 L<C<getsockopt>|/getsockopt SOCKET,LEVEL,OPTNAME>,
469 L<C<glob>|/glob EXPR>, L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR>,
470 L<C<kill>|/kill SIGNAL, LIST>, L<C<link>|/link OLDFILE,NEWFILE>,
471 L<C<lstat>|/lstat FILEHANDLE>, L<C<msgctl>|/msgctl ID,CMD,ARG>,
472 L<C<msgget>|/msgget KEY,FLAGS>,
473 L<C<msgrcv>|/msgrcv ID,VAR,SIZE,TYPE,FLAGS>,
474 L<C<msgsnd>|/msgsnd ID,MSG,FLAGS>, L<C<open>|/open FILEHANDLE,EXPR>,
475 L<C<pipe>|/pipe READHANDLE,WRITEHANDLE>, L<C<readlink>|/readlink EXPR>,
476 L<C<rename>|/rename OLDNAME,NEWNAME>,
477 L<C<select>|/select RBITS,WBITS,EBITS,TIMEOUT>,
478 L<C<semctl>|/semctl ID,SEMNUM,CMD,ARG>,
479 L<C<semget>|/semget KEY,NSEMS,FLAGS>, L<C<semop>|/semop KEY,OPSTRING>,
480 L<C<setgrent>|/setgrent>, L<C<sethostent>|/sethostent STAYOPEN>,
481 L<C<setnetent>|/setnetent STAYOPEN>, L<C<setpgrp>|/setpgrp PID,PGRP>,
482 L<C<setpriority>|/setpriority WHICH,WHO,PRIORITY>,
483 L<C<setprotoent>|/setprotoent STAYOPEN>, L<C<setpwent>|/setpwent>,
484 L<C<setservent>|/setservent STAYOPEN>,
485 L<C<setsockopt>|/setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL>,
486 L<C<shmctl>|/shmctl ID,CMD,ARG>, L<C<shmget>|/shmget KEY,SIZE,FLAGS>,
487 L<C<shmread>|/shmread ID,VAR,POS,SIZE>,
488 L<C<shmwrite>|/shmwrite ID,STRING,POS,SIZE>,
489 L<C<socket>|/socket SOCKET,DOMAIN,TYPE,PROTOCOL>,
490 L<C<socketpair>|/socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL>,
491 L<C<stat>|/stat FILEHANDLE>, L<C<symlink>|/symlink OLDFILE,NEWFILE>,
492 L<C<syscall>|/syscall NUMBER, LIST>,
493 L<C<sysopen>|/sysopen FILEHANDLE,FILENAME,MODE>,
494 L<C<system>|/system LIST>, L<C<times>|/times>,
495 L<C<truncate>|/truncate FILEHANDLE,LENGTH>, L<C<umask>|/umask EXPR>,
496 L<C<unlink>|/unlink LIST>, L<C<utime>|/utime LIST>, L<C<wait>|/wait>,
497 L<C<waitpid>|/waitpid PID,FLAGS>
498
499 For more information about the portability of these functions, see
500 L<perlport> and other available platform-specific documentation.
501
502 =head2 Alphabetical Listing of Perl Functions
503
504 =over
505
506 =item -X FILEHANDLE
507 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
508 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
509
510 =item -X EXPR
511
512 =item -X DIRHANDLE
513
514 =item -X
515
516 =for Pod::Functions a file test (-r, -x, etc)
517
518 A file test, where X is one of the letters listed below.  This unary
519 operator takes one argument, either a filename, a filehandle, or a dirhandle,
520 and tests the associated file to see if something is true about it.  If the
521 argument is omitted, tests L<C<$_>|perlvar/$_>, except for C<-t>, which
522 tests STDIN.  Unless otherwise documented, it returns C<1> for true and
523 C<''> for false.  If the file doesn't exist or can't be examined, it
524 returns L<C<undef>|/undef EXPR> and sets L<C<$!>|perlvar/$!> (errno).
525 Despite the funny names, precedence is the same as any other named unary
526 operator.  The operator may be any of:
527
528     -r  File is readable by effective uid/gid.
529     -w  File is writable by effective uid/gid.
530     -x  File is executable by effective uid/gid.
531     -o  File is owned by effective uid.
532
533     -R  File is readable by real uid/gid.
534     -W  File is writable by real uid/gid.
535     -X  File is executable by real uid/gid.
536     -O  File is owned by real uid.
537
538     -e  File exists.
539     -z  File has zero size (is empty).
540     -s  File has nonzero size (returns size in bytes).
541
542     -f  File is a plain file.
543     -d  File is a directory.
544     -l  File is a symbolic link (false if symlinks aren't
545         supported by the file system).
546     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
547     -S  File is a socket.
548     -b  File is a block special file.
549     -c  File is a character special file.
550     -t  Filehandle is opened to a tty.
551
552     -u  File has setuid bit set.
553     -g  File has setgid bit set.
554     -k  File has sticky bit set.
555
556     -T  File is an ASCII or UTF-8 text file (heuristic guess).
557     -B  File is a "binary" file (opposite of -T).
558
559     -M  Script start time minus file modification time, in days.
560     -A  Same for access time.
561     -C  Same for inode change time (Unix, may differ for other
562         platforms)
563
564 Example:
565
566     while (<>) {
567         chomp;
568         next unless -f $_;  # ignore specials
569         #...
570     }
571
572 Note that C<-s/a/b/> does not do a negated substitution.  Saying
573 C<-exp($foo)> still works as expected, however: only single letters
574 following a minus are interpreted as file tests.
575
576 These operators are exempt from the "looks like a function rule" described
577 above.  That is, an opening parenthesis after the operator does not affect
578 how much of the following code constitutes the argument.  Put the opening
579 parentheses before the operator to separate it from code that follows (this
580 applies only to operators with higher precedence than unary operators, of
581 course):
582
583     -s($file) + 1024   # probably wrong; same as -s($file + 1024)
584     (-s $file) + 1024  # correct
585
586 The interpretation of the file permission operators C<-r>, C<-R>,
587 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
588 of the file and the uids and gids of the user.  There may be other
589 reasons you can't actually read, write, or execute the file: for
590 example network filesystem access controls, ACLs (access control lists),
591 read-only filesystems, and unrecognized executable formats.  Note
592 that the use of these six specific operators to verify if some operation
593 is possible is usually a mistake, because it may be open to race
594 conditions.
595
596 Also note that, for the superuser on the local filesystems, the C<-r>,
597 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
598 if any execute bit is set in the mode.  Scripts run by the superuser
599 may thus need to do a L<C<stat>|/stat FILEHANDLE> to determine the
600 actual mode of the file, or temporarily set their effective uid to
601 something else.
602
603 If you are using ACLs, there is a pragma called L<C<filetest>|filetest>
604 that may produce more accurate results than the bare
605 L<C<stat>|/stat FILEHANDLE> mode bits.
606 When under C<use filetest 'access'>, the above-mentioned filetests
607 test whether the permission can(not) be granted using the L<access(2)>
608 family of system calls.  Also note that the C<-x> and C<-X> tests may
609 under this pragma return true even if there are no execute permission
610 bits set (nor any extra execute permission ACLs).  This strangeness is
611 due to the underlying system calls' definitions.  Note also that, due to
612 the implementation of C<use filetest 'access'>, the C<_> special
613 filehandle won't cache the results of the file tests when this pragma is
614 in effect.  Read the documentation for the L<C<filetest>|filetest>
615 pragma for more information.
616
617 The C<-T> and C<-B> tests work as follows.  The first block or so of
618 the file is examined to see if it is valid UTF-8 that includes non-ASCII
619 characters.  If so, it's a C<-T> file.  Otherwise, that same portion of
620 the file is examined for odd characters such as strange control codes or
621 characters with the high bit set.  If more than a third of the
622 characters are strange, it's a C<-B> file; otherwise it's a C<-T> file.
623 Also, any file containing a zero byte in the examined portion is
624 considered a binary file.  (If executed within the scope of a L<S<use
625 locale>|perllocale> which includes C<LC_CTYPE>, odd characters are
626 anything that isn't a printable nor space in the current locale.)  If
627 C<-T> or C<-B> is used on a filehandle, the current IO buffer is
628 examined
629 rather than the first block.  Both C<-T> and C<-B> return true on an empty
630 file, or a file at EOF when testing a filehandle.  Because you have to
631 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
632 against the file first, as in C<next unless -f $file && -T $file>.
633
634 If any of the file tests (or either the L<C<stat>|/stat FILEHANDLE> or
635 L<C<lstat>|/lstat FILEHANDLE> operator) is given the special filehandle
636 consisting of a solitary underline, then the stat structure of the
637 previous file test (or L<C<stat>|/stat FILEHANDLE> operator) is used,
638 saving a system call.  (This doesn't work with C<-t>, and you need to
639 remember that L<C<lstat>|/lstat FILEHANDLE> and C<-l> leave values in
640 the stat structure for the symbolic link, not the real file.)  (Also, if
641 the stat buffer was filled by an L<C<lstat>|/lstat FILEHANDLE> call,
642 C<-T> and C<-B> will reset it with the results of C<stat _>).
643 Example:
644
645     print "Can do.\n" if -r $a || -w _ || -x _;
646
647     stat($filename);
648     print "Readable\n" if -r _;
649     print "Writable\n" if -w _;
650     print "Executable\n" if -x _;
651     print "Setuid\n" if -u _;
652     print "Setgid\n" if -g _;
653     print "Sticky\n" if -k _;
654     print "Text\n" if -T _;
655     print "Binary\n" if -B _;
656
657 As of Perl 5.10.0, as a form of purely syntactic sugar, you can stack file
658 test operators, in a way that C<-f -w -x $file> is equivalent to
659 C<-x $file && -w _ && -f _>.  (This is only fancy syntax: if you use
660 the return value of C<-f $file> as an argument to another filetest
661 operator, no special magic will happen.)
662
663 Portability issues: L<perlport/-X>.
664
665 To avoid confusing would-be users of your code with mysterious
666 syntax errors, put something like this at the top of your script:
667
668     use 5.010;  # so filetest ops can stack
669
670 =item abs VALUE
671 X<abs> X<absolute>
672
673 =item abs
674
675 =for Pod::Functions absolute value function
676
677 Returns the absolute value of its argument.
678 If VALUE is omitted, uses L<C<$_>|perlvar/$_>.
679
680 =item accept NEWSOCKET,GENERICSOCKET
681 X<accept>
682
683 =for Pod::Functions accept an incoming socket connect
684
685 Accepts an incoming socket connect, just as L<accept(2)>
686 does.  Returns the packed address if it succeeded, false otherwise.
687 See the example in L<perlipc/"Sockets: Client/Server Communication">.
688
689 On systems that support a close-on-exec flag on files, the flag will
690 be set for the newly opened file descriptor, as determined by the
691 value of L<C<$^F>|perlvar/$^F>.  See L<perlvar/$^F>.
692
693 =item alarm SECONDS
694 X<alarm>
695 X<SIGALRM>
696 X<timer>
697
698 =item alarm
699
700 =for Pod::Functions schedule a SIGALRM
701
702 Arranges to have a SIGALRM delivered to this process after the
703 specified number of wallclock seconds has elapsed.  If SECONDS is not
704 specified, the value stored in L<C<$_>|perlvar/$_> is used.  (On some
705 machines, unfortunately, the elapsed time may be up to one second less
706 or more than you specified because of how seconds are counted, and
707 process scheduling may delay the delivery of the signal even further.)
708
709 Only one timer may be counting at once.  Each call disables the
710 previous timer, and an argument of C<0> may be supplied to cancel the
711 previous timer without starting a new one.  The returned value is the
712 amount of time remaining on the previous timer.
713
714 For delays of finer granularity than one second, the L<Time::HiRes> module
715 (from CPAN, and starting from Perl 5.8 part of the standard
716 distribution) provides
717 L<C<ualarm>|Time::HiRes/ualarm ( $useconds [, $interval_useconds ] )>.
718 You may also use Perl's four-argument version of
719 L<C<select>|/select RBITS,WBITS,EBITS,TIMEOUT> leaving the first three
720 arguments undefined, or you might be able to use the
721 L<C<syscall>|/syscall NUMBER, LIST> interface to access L<setitimer(2)>
722 if your system supports it.  See L<perlfaq8> for details.
723
724 It is usually a mistake to intermix L<C<alarm>|/alarm SECONDS> and
725 L<C<sleep>|/sleep EXPR> calls, because L<C<sleep>|/sleep EXPR> may be
726 internally implemented on your system with L<C<alarm>|/alarm SECONDS>.
727
728 If you want to use L<C<alarm>|/alarm SECONDS> to time out a system call
729 you need to use an L<C<eval>|/eval EXPR>/L<C<die>|/die LIST> pair.  You
730 can't rely on the alarm causing the system call to fail with
731 L<C<$!>|perlvar/$!> set to C<EINTR> because Perl sets up signal handlers
732 to restart system calls on some systems.  Using
733 L<C<eval>|/eval EXPR>/L<C<die>|/die LIST> always works, modulo the
734 caveats given in L<perlipc/"Signals">.
735
736     eval {
737         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
738         alarm $timeout;
739         my $nread = sysread $socket, $buffer, $size;
740         alarm 0;
741     };
742     if ($@) {
743         die unless $@ eq "alarm\n";   # propagate unexpected errors
744         # timed out
745     }
746     else {
747         # didn't
748     }
749
750 For more information see L<perlipc>.
751
752 Portability issues: L<perlport/alarm>.
753
754 =item atan2 Y,X
755 X<atan2> X<arctangent> X<tan> X<tangent>
756
757 =for Pod::Functions arctangent of Y/X in the range -PI to PI
758
759 Returns the arctangent of Y/X in the range -PI to PI.
760
761 For the tangent operation, you may use the
762 L<C<Math::Trig::tan>|Math::Trig/B<tan>> function, or use the familiar
763 relation:
764
765     sub tan { sin($_[0]) / cos($_[0])  }
766
767 The return value for C<atan2(0,0)> is implementation-defined; consult
768 your L<atan2(3)> manpage for more information.
769
770 Portability issues: L<perlport/atan2>.
771
772 =item bind SOCKET,NAME
773 X<bind>
774
775 =for Pod::Functions binds an address to a socket
776
777 Binds a network address to a socket, just as L<bind(2)>
778 does.  Returns true if it succeeded, false otherwise.  NAME should be a
779 packed address of the appropriate type for the socket.  See the examples in
780 L<perlipc/"Sockets: Client/Server Communication">.
781
782 =item binmode FILEHANDLE, LAYER
783 X<binmode> X<binary> X<text> X<DOS> X<Windows>
784
785 =item binmode FILEHANDLE
786
787 =for Pod::Functions prepare binary files for I/O
788
789 Arranges for FILEHANDLE to be read or written in "binary" or "text"
790 mode on systems where the run-time libraries distinguish between
791 binary and text files.  If FILEHANDLE is an expression, the value is
792 taken as the name of the filehandle.  Returns true on success,
793 otherwise it returns L<C<undef>|/undef EXPR> and sets
794 L<C<$!>|perlvar/$!> (errno).
795
796 On some systems (in general, DOS- and Windows-based systems)
797 L<C<binmode>|/binmode FILEHANDLE, LAYER> is necessary when you're not
798 working with a text file.  For the sake of portability it is a good idea
799 always to use it when appropriate, and never to use it when it isn't
800 appropriate.  Also, people can set their I/O to be by default
801 UTF8-encoded Unicode, not bytes.
802
803 In other words: regardless of platform, use
804 L<C<binmode>|/binmode FILEHANDLE, LAYER> on binary data, like images,
805 for example.
806
807 If LAYER is present it is a single string, but may contain multiple
808 directives.  The directives alter the behaviour of the filehandle.
809 When LAYER is present, using binmode on a text file makes sense.
810
811 If LAYER is omitted or specified as C<:raw> the filehandle is made
812 suitable for passing binary data.  This includes turning off possible CRLF
813 translation and marking it as bytes (as opposed to Unicode characters).
814 Note that, despite what may be implied in I<"Programming Perl"> (the
815 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
816 Other layers that would affect the binary nature of the stream are
817 I<also> disabled.  See L<PerlIO>, L<perlrun>, and the discussion about the
818 PERLIO environment variable.
819
820 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
821 form C<:...>, are called I/O I<layers>.  The L<open> pragma can be used to
822 establish default I/O layers.
823
824 I<The LAYER parameter of the L<C<binmode>|/binmode FILEHANDLE, LAYER>
825 function is described as "DISCIPLINE" in "Programming Perl, 3rd
826 Edition".  However, since the publishing of this book, by many known as
827 "Camel III", the consensus of the naming of this functionality has moved
828 from "discipline" to "layer".  All documentation of this version of Perl
829 therefore refers to "layers" rather than to "disciplines".  Now back to
830 the regularly scheduled documentation...>
831
832 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(UTF-8)>.
833 C<:utf8> just marks the data as UTF-8 without further checking,
834 while C<:encoding(UTF-8)> checks the data for actually being valid
835 UTF-8.  More details can be found in L<PerlIO::encoding>.
836
837 In general, L<C<binmode>|/binmode FILEHANDLE, LAYER> should be called
838 after L<C<open>|/open FILEHANDLE,EXPR> but before any I/O is done on the
839 filehandle.  Calling L<C<binmode>|/binmode FILEHANDLE, LAYER> normally
840 flushes any pending buffered output data (and perhaps pending input
841 data) on the handle.  An exception to this is the C<:encoding> layer
842 that changes the default character encoding of the handle.
843 The C<:encoding> layer sometimes needs to be called in
844 mid-stream, and it doesn't flush the stream.  C<:encoding>
845 also implicitly pushes on top of itself the C<:utf8> layer because
846 internally Perl operates on UTF8-encoded Unicode characters.
847
848 The operating system, device drivers, C libraries, and Perl run-time
849 system all conspire to let the programmer treat a single
850 character (C<\n>) as the line terminator, irrespective of external
851 representation.  On many operating systems, the native text file
852 representation matches the internal representation, but on some
853 platforms the external representation of C<\n> is made up of more than
854 one character.
855
856 All variants of Unix, Mac OS (old and new), and Stream_LF files on VMS use
857 a single character to end each line in the external representation of text
858 (even though that single character is CARRIAGE RETURN on old, pre-Darwin
859 flavors of Mac OS, and is LINE FEED on Unix and most VMS files).  In other
860 systems like OS/2, DOS, and the various flavors of MS-Windows, your program
861 sees a C<\n> as a simple C<\cJ>, but what's stored in text files are the
862 two characters C<\cM\cJ>.  That means that if you don't use
863 L<C<binmode>|/binmode FILEHANDLE, LAYER> on these systems, C<\cM\cJ>
864 sequences on disk will be converted to C<\n> on input, and any C<\n> in
865 your program will be converted back to C<\cM\cJ> on output.  This is
866 what you want for text files, but it can be disastrous for binary files.
867
868 Another consequence of using L<C<binmode>|/binmode FILEHANDLE, LAYER>
869 (on some systems) is that special end-of-file markers will be seen as
870 part of the data stream.  For systems from the Microsoft family this
871 means that, if your binary data contain C<\cZ>, the I/O subsystem will
872 regard it as the end of the file, unless you use
873 L<C<binmode>|/binmode FILEHANDLE, LAYER>.
874
875 L<C<binmode>|/binmode FILEHANDLE, LAYER> is important not only for
876 L<C<readline>|/readline EXPR> and L<C<print>|/print FILEHANDLE LIST>
877 operations, but also when using
878 L<C<read>|/read FILEHANDLE,SCALAR,LENGTH,OFFSET>,
879 L<C<seek>|/seek FILEHANDLE,POSITION,WHENCE>,
880 L<C<sysread>|/sysread FILEHANDLE,SCALAR,LENGTH,OFFSET>,
881 L<C<syswrite>|/syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET> and
882 L<C<tell>|/tell FILEHANDLE> (see L<perlport> for more details).  See the
883 L<C<$E<sol>>|perlvar/$E<sol>> and L<C<$\>|perlvar/$\> variables in
884 L<perlvar> for how to manually set your input and output
885 line-termination sequences.
886
887 Portability issues: L<perlport/binmode>.
888
889 =item bless REF,CLASSNAME
890 X<bless>
891
892 =item bless REF
893
894 =for Pod::Functions create an object
895
896 This function tells the thingy referenced by REF that it is now an object
897 in the CLASSNAME package.  If CLASSNAME is an empty string, it is
898 interpreted as referring to the C<main> package.
899 If CLASSNAME is omitted, the current package
900 is used.  Because a L<C<bless>|/bless REF,CLASSNAME> is often the last
901 thing in a constructor, it returns the reference for convenience.
902 Always use the two-argument version if a derived class might inherit the
903 method doing the blessing.  See L<perlobj> for more about the blessing
904 (and blessings) of objects.
905
906 Consider always blessing objects in CLASSNAMEs that are mixed case.
907 Namespaces with all lowercase names are considered reserved for
908 Perl pragmas.  Builtin types have all uppercase names.  To prevent
909 confusion, you may wish to avoid such package names as well.
910 It is advised to avoid the class name C<0>, because much code erroneously
911 uses the result of L<C<ref>|/ref EXPR> as a truth value.
912
913 See L<perlmod/"Perl Modules">.
914
915 =item break
916
917 =for Pod::Functions +switch break out of a C<given> block
918
919 Break out of a C<given> block.
920
921 L<C<break>|/break> is available only if the
922 L<C<"switch"> feature|feature/The 'switch' feature> is enabled or if it
923 is prefixed with C<CORE::>. The
924 L<C<"switch"> feature|feature/The 'switch' feature> is enabled
925 automatically with a C<use v5.10> (or higher) declaration in the current
926 scope.
927
928 =item caller EXPR
929 X<caller> X<call stack> X<stack> X<stack trace>
930
931 =item caller
932
933 =for Pod::Functions get context of the current subroutine call
934
935 Returns the context of the current pure perl subroutine call.  In scalar
936 context, returns the caller's package name if there I<is> a caller (that is, if
937 we're in a subroutine or L<C<eval>|/eval EXPR> or
938 L<C<require>|/require VERSION>) and the undefined value otherwise.
939 caller never returns XS subs and they are skipped.  The next pure perl
940 sub will appear instead of the XS sub in caller's return values.  In
941 list context, caller returns
942
943        # 0         1          2
944     my ($package, $filename, $line) = caller;
945
946 With EXPR, it returns some extra information that the debugger uses to
947 print a stack trace.  The value of EXPR indicates how many call frames
948 to go back before the current one.
949
950     #  0         1          2      3            4
951  my ($package, $filename, $line, $subroutine, $hasargs,
952
953     #  5          6          7            8       9         10
954     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
955   = caller($i);
956
957 Here, $subroutine is the function that the caller called (rather than the
958 function containing the caller).  Note that $subroutine may be C<(eval)> if
959 the frame is not a subroutine call, but an L<C<eval>|/eval EXPR>.  In
960 such a case additional elements $evaltext and C<$is_require> are set:
961 C<$is_require> is true if the frame is created by a
962 L<C<require>|/require VERSION> or L<C<use>|/use Module VERSION LIST>
963 statement, $evaltext contains the text of the C<eval EXPR> statement.
964 In particular, for an C<eval BLOCK> statement, $subroutine is C<(eval)>,
965 but $evaltext is undefined.  (Note also that each
966 L<C<use>|/use Module VERSION LIST> statement creates a
967 L<C<require>|/require VERSION> frame inside an C<eval EXPR> frame.)
968 $subroutine may also be C<(unknown)> if this particular subroutine
969 happens to have been deleted from the symbol table.  C<$hasargs> is true
970 if a new instance of L<C<@_>|perlvar/@_> was set up for the frame.
971 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
972 compiled with.  C<$hints> corresponds to L<C<$^H>|perlvar/$^H>, and
973 C<$bitmask> corresponds to
974 L<C<${^WARNING_BITS}>|perlvar/${^WARNING_BITS}>.  The C<$hints> and
975 C<$bitmask> values are subject to change between versions of Perl, and
976 are not meant for external use.
977
978 C<$hinthash> is a reference to a hash containing the value of
979 L<C<%^H>|perlvar/%^H> when the caller was compiled, or
980 L<C<undef>|/undef EXPR> if L<C<%^H>|perlvar/%^H> was empty.  Do not
981 modify the values of this hash, as they are the actual values stored in
982 the optree.
983
984 Furthermore, when called from within the DB package in
985 list context, and with an argument, caller returns more
986 detailed information: it sets the list variable C<@DB::args> to be the
987 arguments with which the subroutine was invoked.
988
989 Be aware that the optimizer might have optimized call frames away before
990 L<C<caller>|/caller EXPR> had a chance to get the information.  That
991 means that C<caller(N)> might not return information about the call
992 frame you expect it to, for C<< N > 1 >>.  In particular, C<@DB::args>
993 might have information from the previous time L<C<caller>|/caller EXPR>
994 was called.
995
996 Be aware that setting C<@DB::args> is I<best effort>, intended for
997 debugging or generating backtraces, and should not be relied upon.  In
998 particular, as L<C<@_>|perlvar/@_> contains aliases to the caller's
999 arguments, Perl does not take a copy of L<C<@_>|perlvar/@_>, so
1000 C<@DB::args> will contain modifications the subroutine makes to
1001 L<C<@_>|perlvar/@_> or its contents, not the original values at call
1002 time.  C<@DB::args>, like L<C<@_>|perlvar/@_>, does not hold explicit
1003 references to its elements, so under certain cases its elements may have
1004 become freed and reallocated for other variables or temporary values.
1005 Finally, a side effect of the current implementation is that the effects
1006 of C<shift @_> can I<normally> be undone (but not C<pop @_> or other
1007 splicing, I<and> not if a reference to L<C<@_>|perlvar/@_> has been
1008 taken, I<and> subject to the caveat about reallocated elements), so
1009 C<@DB::args> is actually a hybrid of the current state and initial state
1010 of L<C<@_>|perlvar/@_>.  Buyer beware.
1011
1012 =item chdir EXPR
1013 X<chdir>
1014 X<cd>
1015 X<directory, change>
1016
1017 =item chdir FILEHANDLE
1018
1019 =item chdir DIRHANDLE
1020
1021 =item chdir
1022
1023 =for Pod::Functions change your current working directory
1024
1025 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
1026 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
1027 changes to the directory specified by C<$ENV{LOGDIR}>.  (Under VMS, the
1028 variable C<$ENV{'SYS$LOGIN'}> is also checked, and used if it is set.)  If
1029 neither is set, L<C<chdir>|/chdir EXPR> does nothing and fails.  It
1030 returns true on success, false otherwise.  See the example under
1031 L<C<die>|/die LIST>.
1032
1033 On systems that support L<fchdir(2)>, you may pass a filehandle or
1034 directory handle as the argument.  On systems that don't support L<fchdir(2)>,
1035 passing handles raises an exception.
1036
1037 =item chmod LIST
1038 X<chmod> X<permission> X<mode>
1039
1040 =for Pod::Functions changes the permissions on a list of files
1041
1042 Changes the permissions of a list of files.  The first element of the
1043 list must be the numeric mode, which should probably be an octal
1044 number, and which definitely should I<not> be a string of octal digits:
1045 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
1046 successfully changed.  See also L<C<oct>|/oct EXPR> if all you have is a
1047 string.
1048
1049     my $cnt = chmod 0755, "foo", "bar";
1050     chmod 0755, @executables;
1051     my $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
1052                                                 # --w----r-T
1053     my $mode = "0644"; chmod oct($mode), "foo"; # this is better
1054     my $mode = 0644;   chmod $mode, "foo";      # this is best
1055
1056 On systems that support L<fchmod(2)>, you may pass filehandles among the
1057 files.  On systems that don't support L<fchmod(2)>, passing filehandles raises
1058 an exception.  Filehandles must be passed as globs or glob references to be
1059 recognized; barewords are considered filenames.
1060
1061     open(my $fh, "<", "foo");
1062     my $perm = (stat $fh)[2] & 07777;
1063     chmod($perm | 0600, $fh);
1064
1065 You can also import the symbolic C<S_I*> constants from the
1066 L<C<Fcntl>|Fcntl> module:
1067
1068     use Fcntl qw( :mode );
1069     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
1070     # Identical to the chmod 0755 of the example above.
1071
1072 Portability issues: L<perlport/chmod>.
1073
1074 =item chomp VARIABLE
1075 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
1076
1077 =item chomp( LIST )
1078
1079 =item chomp
1080
1081 =for Pod::Functions remove a trailing record separator from a string
1082
1083 This safer version of L<C<chop>|/chop VARIABLE> removes any trailing
1084 string that corresponds to the current value of
1085 L<C<$E<sol>>|perlvar/$E<sol>> (also known as C<$INPUT_RECORD_SEPARATOR>
1086 in the L<C<English>|English> module).  It returns the total
1087 number of characters removed from all its arguments.  It's often used to
1088 remove the newline from the end of an input record when you're worried
1089 that the final record may be missing its newline.  When in paragraph
1090 mode (C<$/ = ''>), it removes all trailing newlines from the string.
1091 When in slurp mode (C<$/ = undef>) or fixed-length record mode
1092 (L<C<$E<sol>>|perlvar/$E<sol>> is a reference to an integer or the like;
1093 see L<perlvar>), L<C<chomp>|/chomp VARIABLE> won't remove anything.
1094 If VARIABLE is omitted, it chomps L<C<$_>|perlvar/$_>.  Example:
1095
1096     while (<>) {
1097         chomp;  # avoid \n on last field
1098         my @array = split(/:/);
1099         # ...
1100     }
1101
1102 If VARIABLE is a hash, it chomps the hash's values, but not its keys,
1103 resetting the L<C<each>|/each HASH> iterator in the process.
1104
1105 You can actually chomp anything that's an lvalue, including an assignment:
1106
1107     chomp(my $cwd = `pwd`);
1108     chomp(my $answer = <STDIN>);
1109
1110 If you chomp a list, each element is chomped, and the total number of
1111 characters removed is returned.
1112
1113 Note that parentheses are necessary when you're chomping anything
1114 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
1115 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
1116 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
1117 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
1118 as C<chomp($a, $b)>.
1119
1120 =item chop VARIABLE
1121 X<chop>
1122
1123 =item chop( LIST )
1124
1125 =item chop
1126
1127 =for Pod::Functions remove the last character from a string
1128
1129 Chops off the last character of a string and returns the character
1130 chopped.  It is much more efficient than C<s/.$//s> because it neither
1131 scans nor copies the string.  If VARIABLE is omitted, chops
1132 L<C<$_>|perlvar/$_>.
1133 If VARIABLE is a hash, it chops the hash's values, but not its keys,
1134 resetting the L<C<each>|/each HASH> iterator in the process.
1135
1136 You can actually chop anything that's an lvalue, including an assignment.
1137
1138 If you chop a list, each element is chopped.  Only the value of the
1139 last L<C<chop>|/chop VARIABLE> is returned.
1140
1141 Note that L<C<chop>|/chop VARIABLE> returns the last character.  To
1142 return all but the last character, use C<substr($string, 0, -1)>.
1143
1144 See also L<C<chomp>|/chomp VARIABLE>.
1145
1146 =item chown LIST
1147 X<chown> X<owner> X<user> X<group>
1148
1149 =for Pod::Functions change the ownership on a list of files
1150
1151 Changes the owner (and group) of a list of files.  The first two
1152 elements of the list must be the I<numeric> uid and gid, in that
1153 order.  A value of -1 in either position is interpreted by most
1154 systems to leave that value unchanged.  Returns the number of files
1155 successfully changed.
1156
1157     my $cnt = chown $uid, $gid, 'foo', 'bar';
1158     chown $uid, $gid, @filenames;
1159
1160 On systems that support L<fchown(2)>, you may pass filehandles among the
1161 files.  On systems that don't support L<fchown(2)>, passing filehandles raises
1162 an exception.  Filehandles must be passed as globs or glob references to be
1163 recognized; barewords are considered filenames.
1164
1165 Here's an example that looks up nonnumeric uids in the passwd file:
1166
1167     print "User: ";
1168     chomp(my $user = <STDIN>);
1169     print "Files: ";
1170     chomp(my $pattern = <STDIN>);
1171
1172     my ($login,$pass,$uid,$gid) = getpwnam($user)
1173         or die "$user not in passwd file";
1174
1175     my @ary = glob($pattern);  # expand filenames
1176     chown $uid, $gid, @ary;
1177
1178 On most systems, you are not allowed to change the ownership of the
1179 file unless you're the superuser, although you should be able to change
1180 the group to any of your secondary groups.  On insecure systems, these
1181 restrictions may be relaxed, but this is not a portable assumption.
1182 On POSIX systems, you can detect this condition this way:
1183
1184     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
1185     my $can_chown_giveaway = ! sysconf(_PC_CHOWN_RESTRICTED);
1186
1187 Portability issues: L<perlport/chown>.
1188
1189 =item chr NUMBER
1190 X<chr> X<character> X<ASCII> X<Unicode>
1191
1192 =item chr
1193
1194 =for Pod::Functions get character this number represents
1195
1196 Returns the character represented by that NUMBER in the character set.
1197 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
1198 chr(0x263a) is a Unicode smiley face.
1199
1200 Negative values give the Unicode replacement character (chr(0xfffd)),
1201 except under the L<bytes> pragma, where the low eight bits of the value
1202 (truncated to an integer) are used.
1203
1204 If NUMBER is omitted, uses L<C<$_>|perlvar/$_>.
1205
1206 For the reverse, use L<C<ord>|/ord EXPR>.
1207
1208 Note that characters from 128 to 255 (inclusive) are by default
1209 internally not encoded as UTF-8 for backward compatibility reasons.
1210
1211 See L<perlunicode> for more about Unicode.
1212
1213 =item chroot FILENAME
1214 X<chroot> X<root>
1215
1216 =item chroot
1217
1218 =for Pod::Functions make directory new root for path lookups
1219
1220 This function works like the system call by the same name: it makes the
1221 named directory the new root directory for all further pathnames that
1222 begin with a C</> by your process and all its children.  (It doesn't
1223 change your current working directory, which is unaffected.)  For security
1224 reasons, this call is restricted to the superuser.  If FILENAME is
1225 omitted, does a L<C<chroot>|/chroot FILENAME> to L<C<$_>|perlvar/$_>.
1226
1227 B<NOTE:>  It is good security practice to do C<chdir("/")>
1228 (L<C<chdir>|/chdir EXPR> to the root directory) immediately after a
1229 L<C<chroot>|/chroot FILENAME>.
1230
1231 Portability issues: L<perlport/chroot>.
1232
1233 =item close FILEHANDLE
1234 X<close>
1235
1236 =item close
1237
1238 =for Pod::Functions close file (or pipe or socket) handle
1239
1240 Closes the file or pipe associated with the filehandle, flushes the IO
1241 buffers, and closes the system file descriptor.  Returns true if those
1242 operations succeed and if no error was reported by any PerlIO
1243 layer.  Closes the currently selected filehandle if the argument is
1244 omitted.
1245
1246 You don't have to close FILEHANDLE if you are immediately going to do
1247 another L<C<open>|/open FILEHANDLE,EXPR> on it, because
1248 L<C<open>|/open FILEHANDLE,EXPR> closes it for you.  (See
1249 L<C<open>|/open FILEHANDLE,EXPR>.) However, an explicit
1250 L<C<close>|/close FILEHANDLE> on an input file resets the line counter
1251 (L<C<$.>|perlvar/$.>), while the implicit close done by
1252 L<C<open>|/open FILEHANDLE,EXPR> does not.
1253
1254 If the filehandle came from a piped open, L<C<close>|/close FILEHANDLE>
1255 returns false if one of the other syscalls involved fails or if its
1256 program exits with non-zero status.  If the only problem was that the
1257 program exited non-zero, L<C<$!>|perlvar/$!> will be set to C<0>.
1258 Closing a pipe also waits for the process executing on the pipe to
1259 exit--in case you wish to look at the output of the pipe afterwards--and
1260 implicitly puts the exit status value of that command into
1261 L<C<$?>|perlvar/$?> and
1262 L<C<${^CHILD_ERROR_NATIVE}>|perlvar/${^CHILD_ERROR_NATIVE}>.
1263
1264 If there are multiple threads running, L<C<close>|/close FILEHANDLE> on
1265 a filehandle from a piped open returns true without waiting for the
1266 child process to terminate, if the filehandle is still open in another
1267 thread.
1268
1269 Closing the read end of a pipe before the process writing to it at the
1270 other end is done writing results in the writer receiving a SIGPIPE.  If
1271 the other end can't handle that, be sure to read all the data before
1272 closing the pipe.
1273
1274 Example:
1275
1276     open(OUTPUT, '|sort >foo')  # pipe to sort
1277         or die "Can't start sort: $!";
1278     #...                        # print stuff to output
1279     close OUTPUT                # wait for sort to finish
1280         or warn $! ? "Error closing sort pipe: $!"
1281                    : "Exit status $? from sort";
1282     open(INPUT, 'foo')          # get sort's results
1283         or die "Can't open 'foo' for input: $!";
1284
1285 FILEHANDLE may be an expression whose value can be used as an indirect
1286 filehandle, usually the real filehandle name or an autovivified handle.
1287
1288 =item closedir DIRHANDLE
1289 X<closedir>
1290
1291 =for Pod::Functions close directory handle
1292
1293 Closes a directory opened by L<C<opendir>|/opendir DIRHANDLE,EXPR> and
1294 returns the success of that system call.
1295
1296 =item connect SOCKET,NAME
1297 X<connect>
1298
1299 =for Pod::Functions connect to a remote socket
1300
1301 Attempts to connect to a remote socket, just like L<connect(2)>.
1302 Returns true if it succeeded, false otherwise.  NAME should be a
1303 packed address of the appropriate type for the socket.  See the examples in
1304 L<perlipc/"Sockets: Client/Server Communication">.
1305
1306 =item continue BLOCK
1307 X<continue>
1308
1309 =item continue
1310
1311 =for Pod::Functions optional trailing block in a while or foreach
1312
1313 When followed by a BLOCK, L<C<continue>|/continue BLOCK> is actually a
1314 flow control statement rather than a function.  If there is a
1315 L<C<continue>|/continue BLOCK> BLOCK attached to a BLOCK (typically in a
1316 C<while> or C<foreach>), it is always executed just before the
1317 conditional is about to be evaluated again, just like the third part of
1318 a C<for> loop in C.  Thus it can be used to increment a loop variable,
1319 even when the loop has been continued via the L<C<next>|/next LABEL>
1320 statement (which is similar to the C L<C<continue>|/continue BLOCK>
1321 statement).
1322
1323 L<C<last>|/last LABEL>, L<C<next>|/next LABEL>, or
1324 L<C<redo>|/redo LABEL> may appear within a
1325 L<C<continue>|/continue BLOCK> block; L<C<last>|/last LABEL> and
1326 L<C<redo>|/redo LABEL> behave as if they had been executed within the
1327 main block.  So will L<C<next>|/next LABEL>, but since it will execute a
1328 L<C<continue>|/continue BLOCK> block, it may be more entertaining.
1329
1330     while (EXPR) {
1331         ### redo always comes here
1332         do_something;
1333     } continue {
1334         ### next always comes here
1335         do_something_else;
1336         # then back the top to re-check EXPR
1337     }
1338     ### last always comes here
1339
1340 Omitting the L<C<continue>|/continue BLOCK> section is equivalent to
1341 using an empty one, logically enough, so L<C<next>|/next LABEL> goes
1342 directly back to check the condition at the top of the loop.
1343
1344 When there is no BLOCK, L<C<continue>|/continue BLOCK> is a function
1345 that falls through the current C<when> or C<default> block instead of
1346 iterating a dynamically enclosing C<foreach> or exiting a lexically
1347 enclosing C<given>.  In Perl 5.14 and earlier, this form of
1348 L<C<continue>|/continue BLOCK> was only available when the
1349 L<C<"switch"> feature|feature/The 'switch' feature> was enabled.  See
1350 L<feature> and L<perlsyn/"Switch Statements"> for more information.
1351
1352 =item cos EXPR
1353 X<cos> X<cosine> X<acos> X<arccosine>
1354
1355 =item cos
1356
1357 =for Pod::Functions cosine function
1358
1359 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
1360 takes the cosine of L<C<$_>|perlvar/$_>.
1361
1362 For the inverse cosine operation, you may use the
1363 L<C<Math::Trig::acos>|Math::Trig> function, or use this relation:
1364
1365     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
1366
1367 =item crypt PLAINTEXT,SALT
1368 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
1369 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1370
1371 =for Pod::Functions one-way passwd-style encryption
1372
1373 Creates a digest string exactly like the L<crypt(3)> function in the C
1374 library (assuming that you actually have a version there that has not
1375 been extirpated as a potential munition).
1376
1377 L<C<crypt>|/crypt PLAINTEXT,SALT> is a one-way hash function.  The
1378 PLAINTEXT and SALT are turned
1379 into a short string, called a digest, which is returned.  The same
1380 PLAINTEXT and SALT will always return the same string, but there is no
1381 (known) way to get the original PLAINTEXT from the hash.  Small
1382 changes in the PLAINTEXT or SALT will result in large changes in the
1383 digest.
1384
1385 There is no decrypt function.  This function isn't all that useful for
1386 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1387 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1388 primarily used to check if two pieces of text are the same without
1389 having to transmit or store the text itself.  An example is checking
1390 if a correct password is given.  The digest of the password is stored,
1391 not the password itself.  The user types in a password that is
1392 L<C<crypt>|/crypt PLAINTEXT,SALT>'d with the same salt as the stored
1393 digest.  If the two digests match, the password is correct.
1394
1395 When verifying an existing digest string you should use the digest as
1396 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1397 to create the digest is visible as part of the digest.  This ensures
1398 L<C<crypt>|/crypt PLAINTEXT,SALT> will hash the new string with the same
1399 salt as the digest.  This allows your code to work with the standard
1400 L<C<crypt>|/crypt PLAINTEXT,SALT> and with more exotic implementations.
1401 In other words, assume nothing about the returned string itself nor
1402 about how many bytes of SALT may matter.
1403
1404 Traditionally the result is a string of 13 bytes: two first bytes of
1405 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1406 the first eight bytes of PLAINTEXT mattered.  But alternative
1407 hashing schemes (like MD5), higher level security schemes (like C2),
1408 and implementations on non-Unix platforms may produce different
1409 strings.
1410
1411 When choosing a new salt create a random two character string whose
1412 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1413 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1414 characters is just a recommendation; the characters allowed in
1415 the salt depend solely on your system's crypt library, and Perl can't
1416 restrict what salts L<C<crypt>|/crypt PLAINTEXT,SALT> accepts.
1417
1418 Here's an example that makes sure that whoever runs this program knows
1419 their password:
1420
1421     my $pwd = (getpwuid($<))[1];
1422
1423     system "stty -echo";
1424     print "Password: ";
1425     chomp(my $word = <STDIN>);
1426     print "\n";
1427     system "stty echo";
1428
1429     if (crypt($word, $pwd) ne $pwd) {
1430         die "Sorry...\n";
1431     } else {
1432         print "ok\n";
1433     }
1434
1435 Of course, typing in your own password to whoever asks you
1436 for it is unwise.
1437
1438 The L<C<crypt>|/crypt PLAINTEXT,SALT> function is unsuitable for hashing
1439 large quantities of data, not least of all because you can't get the
1440 information back.  Look at the L<Digest> module for more robust
1441 algorithms.
1442
1443 If using L<C<crypt>|/crypt PLAINTEXT,SALT> on a Unicode string (which
1444 I<potentially> has characters with codepoints above 255), Perl tries to
1445 make sense of the situation by trying to downgrade (a copy of) the
1446 string back to an eight-bit byte string before calling
1447 L<C<crypt>|/crypt PLAINTEXT,SALT> (on that copy).  If that works, good.
1448 If not, L<C<crypt>|/crypt PLAINTEXT,SALT> dies with
1449 L<C<Wide character in crypt>|perldiag/Wide character in %s>.
1450
1451 Portability issues: L<perlport/crypt>.
1452
1453 =item dbmclose HASH
1454 X<dbmclose>
1455
1456 =for Pod::Functions breaks binding on a tied dbm file
1457
1458 [This function has been largely superseded by the
1459 L<C<untie>|/untie VARIABLE> function.]
1460
1461 Breaks the binding between a DBM file and a hash.
1462
1463 Portability issues: L<perlport/dbmclose>.
1464
1465 =item dbmopen HASH,DBNAME,MASK
1466 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1467
1468 =for Pod::Functions create binding on a tied dbm file
1469
1470 [This function has been largely superseded by the
1471 L<C<tie>|/tie VARIABLE,CLASSNAME,LIST> function.]
1472
1473 This binds a L<dbm(3)>, L<ndbm(3)>, L<sdbm(3)>, L<gdbm(3)>, or Berkeley
1474 DB file to a hash.  HASH is the name of the hash.  (Unlike normal
1475 L<C<open>|/open FILEHANDLE,EXPR>, the first argument is I<not> a
1476 filehandle, even though it looks like one).  DBNAME is the name of the
1477 database (without the F<.dir> or F<.pag> extension if any).  If the
1478 database does not exist, it is created with protection specified by MASK
1479 (as modified by the L<C<umask>|/umask EXPR>).  To prevent creation of
1480 the database if it doesn't exist, you may specify a MODE of 0, and the
1481 function will return a false value if it can't find an existing
1482 database.  If your system supports only the older DBM functions, you may
1483 make only one L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK> call in your
1484 program.  In older versions of Perl, if your system had neither DBM nor
1485 ndbm, calling L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK> produced a fatal
1486 error; it now falls back to L<sdbm(3)>.
1487
1488 If you don't have write access to the DBM file, you can only read hash
1489 variables, not set them.  If you want to test whether you can write,
1490 either use file tests or try setting a dummy hash entry inside an
1491 L<C<eval>|/eval EXPR> to trap the error.
1492
1493 Note that functions such as L<C<keys>|/keys HASH> and
1494 L<C<values>|/values HASH> may return huge lists when used on large DBM
1495 files.  You may prefer to use the L<C<each>|/each HASH> function to
1496 iterate over large DBM files.  Example:
1497
1498     # print out history file offsets
1499     dbmopen(%HIST,'/usr/lib/news/history',0666);
1500     while (($key,$val) = each %HIST) {
1501         print $key, ' = ', unpack('L',$val), "\n";
1502     }
1503     dbmclose(%HIST);
1504
1505 See also L<AnyDBM_File> for a more general description of the pros and
1506 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1507 rich implementation.
1508
1509 You can control which DBM library you use by loading that library
1510 before you call L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK>:
1511
1512     use DB_File;
1513     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1514         or die "Can't open netscape history file: $!";
1515
1516 Portability issues: L<perlport/dbmopen>.
1517
1518 =item defined EXPR
1519 X<defined> X<undef> X<undefined>
1520
1521 =item defined
1522
1523 =for Pod::Functions test whether a value, variable, or function is defined
1524
1525 Returns a Boolean value telling whether EXPR has a value other than the
1526 undefined value L<C<undef>|/undef EXPR>.  If EXPR is not present,
1527 L<C<$_>|perlvar/$_> is checked.
1528
1529 Many operations return L<C<undef>|/undef EXPR> to indicate failure, end
1530 of file, system error, uninitialized variable, and other exceptional
1531 conditions.  This function allows you to distinguish
1532 L<C<undef>|/undef EXPR> from other values.  (A simple Boolean test will
1533 not distinguish among L<C<undef>|/undef EXPR>, zero, the empty string,
1534 and C<"0">, which are all equally false.)  Note that since
1535 L<C<undef>|/undef EXPR> is a valid scalar, its presence doesn't
1536 I<necessarily> indicate an exceptional condition: L<C<pop>|/pop ARRAY>
1537 returns L<C<undef>|/undef EXPR> when its argument is an empty array,
1538 I<or> when the element to return happens to be L<C<undef>|/undef EXPR>.
1539
1540 You may also use C<defined(&func)> to check whether subroutine C<func>
1541 has ever been defined.  The return value is unaffected by any forward
1542 declarations of C<func>.  A subroutine that is not defined
1543 may still be callable: its package may have an C<AUTOLOAD> method that
1544 makes it spring into existence the first time that it is called; see
1545 L<perlsub>.
1546
1547 Use of L<C<defined>|/defined EXPR> on aggregates (hashes and arrays) is
1548 no longer supported. It used to report whether memory for that
1549 aggregate had ever been allocated.  You should instead use a simple
1550 test for size:
1551
1552     if (@an_array) { print "has array elements\n" }
1553     if (%a_hash)   { print "has hash members\n"   }
1554
1555 When used on a hash element, it tells you whether the value is defined,
1556 not whether the key exists in the hash.  Use L<C<exists>|/exists EXPR>
1557 for the latter purpose.
1558
1559 Examples:
1560
1561     print if defined $switch{D};
1562     print "$val\n" while defined($val = pop(@ary));
1563     die "Can't readlink $sym: $!"
1564         unless defined($value = readlink $sym);
1565     sub foo { defined &$bar ? $bar->(@_) : die "No bar"; }
1566     $debugging = 0 unless defined $debugging;
1567
1568 Note:  Many folks tend to overuse L<C<defined>|/defined EXPR> and are
1569 then surprised to discover that the number C<0> and C<""> (the
1570 zero-length string) are, in fact, defined values.  For example, if you
1571 say
1572
1573     "ab" =~ /a(.*)b/;
1574
1575 The pattern match succeeds and C<$1> is defined, although it
1576 matched "nothing".  It didn't really fail to match anything.  Rather, it
1577 matched something that happened to be zero characters long.  This is all
1578 very above-board and honest.  When a function returns an undefined value,
1579 it's an admission that it couldn't give you an honest answer.  So you
1580 should use L<C<defined>|/defined EXPR> only when questioning the
1581 integrity of what you're trying to do.  At other times, a simple
1582 comparison to C<0> or C<""> is what you want.
1583
1584 See also L<C<undef>|/undef EXPR>, L<C<exists>|/exists EXPR>,
1585 L<C<ref>|/ref EXPR>.
1586
1587 =item delete EXPR
1588 X<delete>
1589
1590 =for Pod::Functions deletes a value from a hash
1591
1592 Given an expression that specifies an element or slice of a hash,
1593 L<C<delete>|/delete EXPR> deletes the specified elements from that hash
1594 so that L<C<exists>|/exists EXPR> on that element no longer returns
1595 true.  Setting a hash element to the undefined value does not remove its
1596 key, but deleting it does; see L<C<exists>|/exists EXPR>.
1597
1598 In list context, returns the value or values deleted, or the last such
1599 element in scalar context.  The return list's length always matches that of
1600 the argument list: deleting non-existent elements returns the undefined value
1601 in their corresponding positions.
1602
1603 L<C<delete>|/delete EXPR> may also be used on arrays and array slices,
1604 but its behavior is less straightforward.  Although
1605 L<C<exists>|/exists EXPR> will return false for deleted entries,
1606 deleting array elements never changes indices of existing values; use
1607 L<C<shift>|/shift ARRAY> or L<C<splice>|/splice
1608 ARRAY,OFFSET,LENGTH,LIST> for that.  However, if any deleted elements
1609 fall at the end of an array, the array's size shrinks to the position of
1610 the highest element that still tests true for L<C<exists>|/exists EXPR>,
1611 or to 0 if none do.  In other words, an array won't have trailing
1612 nonexistent elements after a delete.
1613
1614 B<WARNING:> Calling L<C<delete>|/delete EXPR> on array values is
1615 strongly discouraged.  The
1616 notion of deleting or checking the existence of Perl array elements is not
1617 conceptually coherent, and can lead to surprising behavior.
1618
1619 Deleting from L<C<%ENV>|perlvar/%ENV> modifies the environment.
1620 Deleting from a hash tied to a DBM file deletes the entry from the DBM
1621 file.  Deleting from a L<C<tied>|/tied VARIABLE> hash or array may not
1622 necessarily return anything; it depends on the implementation of the
1623 L<C<tied>|/tied VARIABLE> package's DELETE method, which may do whatever
1624 it pleases.
1625
1626 The C<delete local EXPR> construct localizes the deletion to the current
1627 block at run time.  Until the block exits, elements locally deleted
1628 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1629 of composite types">.
1630
1631     my %hash = (foo => 11, bar => 22, baz => 33);
1632     my $scalar = delete $hash{foo};         # $scalar is 11
1633     $scalar = delete @hash{qw(foo bar)}; # $scalar is 22
1634     my @array  = delete @hash{qw(foo baz)}; # @array  is (undef,33)
1635
1636 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1637
1638     foreach my $key (keys %HASH) {
1639         delete $HASH{$key};
1640     }
1641
1642     foreach my $index (0 .. $#ARRAY) {
1643         delete $ARRAY[$index];
1644     }
1645
1646 And so do these:
1647
1648     delete @HASH{keys %HASH};
1649
1650     delete @ARRAY[0 .. $#ARRAY];
1651
1652 But both are slower than assigning the empty list
1653 or undefining %HASH or @ARRAY, which is the customary
1654 way to empty out an aggregate:
1655
1656     %HASH = ();     # completely empty %HASH
1657     undef %HASH;    # forget %HASH ever existed
1658
1659     @ARRAY = ();    # completely empty @ARRAY
1660     undef @ARRAY;   # forget @ARRAY ever existed
1661
1662 The EXPR can be arbitrarily complicated provided its
1663 final operation is an element or slice of an aggregate:
1664
1665     delete $ref->[$x][$y]{$key};
1666     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1667
1668     delete $ref->[$x][$y][$index];
1669     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1670
1671 =item die LIST
1672 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1673
1674 =for Pod::Functions raise an exception or bail out
1675
1676 L<C<die>|/die LIST> raises an exception.  Inside an
1677 L<C<eval>|/eval EXPR> the error message is stuffed into
1678 L<C<$@>|perlvar/$@> and the L<C<eval>|/eval EXPR> is terminated with the
1679 undefined value.  If the exception is outside of all enclosing
1680 L<C<eval>|/eval EXPR>s, then the uncaught exception prints LIST to
1681 C<STDERR> and exits with a non-zero value.  If you need to exit the
1682 process with a specific exit code, see L<C<exit>|/exit EXPR>.
1683
1684 Equivalent examples:
1685
1686     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1687     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1688
1689 If the last element of LIST does not end in a newline, the current
1690 script line number and input line number (if any) are also printed,
1691 and a newline is supplied.  Note that the "input line number" (also
1692 known as "chunk") is subject to whatever notion of "line" happens to
1693 be currently in effect, and is also available as the special variable
1694 L<C<$.>|perlvar/$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1695
1696 Hint: sometimes appending C<", stopped"> to your message will cause it
1697 to make better sense when the string C<"at foo line 123"> is appended.
1698 Suppose you are running script "canasta".
1699
1700     die "/etc/games is no good";
1701     die "/etc/games is no good, stopped";
1702
1703 produce, respectively
1704
1705     /etc/games is no good at canasta line 123.
1706     /etc/games is no good, stopped at canasta line 123.
1707
1708 If the output is empty and L<C<$@>|perlvar/$@> already contains a value
1709 (typically from a previous L<C<eval>|/eval EXPR>) that value is reused after
1710 appending C<"\t...propagated">.  This is useful for propagating exceptions:
1711
1712     eval { ... };
1713     die unless $@ =~ /Expected exception/;
1714
1715 If the output is empty and L<C<$@>|perlvar/$@> contains an object
1716 reference that has a C<PROPAGATE> method, that method will be called
1717 with additional file and line number parameters.  The return value
1718 replaces the value in L<C<$@>|perlvar/$@>;  i.e., as if
1719 C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >> were called.
1720
1721 If L<C<$@>|perlvar/$@> is empty, then the string C<"Died"> is used.
1722
1723 If an uncaught exception results in interpreter exit, the exit code is
1724 determined from the values of L<C<$!>|perlvar/$!> and
1725 L<C<$?>|perlvar/$?> with this pseudocode:
1726
1727     exit $! if $!;              # errno
1728     exit $? >> 8 if $? >> 8;    # child exit status
1729     exit 255;                   # last resort
1730
1731 As with L<C<exit>|/exit EXPR>, L<C<$?>|perlvar/$?> is set prior to
1732 unwinding the call stack; any C<DESTROY> or C<END> handlers can then
1733 alter this value, and thus Perl's exit code.
1734
1735 The intent is to squeeze as much possible information about the likely cause
1736 into the limited space of the system exit code.  However, as
1737 L<C<$!>|perlvar/$!> is the value of C's C<errno>, which can be set by
1738 any system call, this means that the value of the exit code used by
1739 L<C<die>|/die LIST> can be non-predictable, so should not be relied
1740 upon, other than to be non-zero.
1741
1742 You can also call L<C<die>|/die LIST> with a reference argument, and if
1743 this is trapped within an L<C<eval>|/eval EXPR>, L<C<$@>|perlvar/$@>
1744 contains that reference.  This permits more elaborate exception handling
1745 using objects that maintain arbitrary state about the exception.  Such a
1746 scheme is sometimes preferable to matching particular string values of
1747 L<C<$@>|perlvar/$@> with regular expressions.  Because
1748 L<C<$@>|perlvar/$@> is a global variable and L<C<eval>|/eval EXPR> may
1749 be used within object implementations, be careful that analyzing the
1750 error object doesn't replace the reference in the global variable.  It's
1751 easiest to make a local copy of the reference before any manipulations.
1752 Here's an example:
1753
1754     use Scalar::Util "blessed";
1755
1756     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1757     if (my $ev_err = $@) {
1758         if (blessed($ev_err)
1759             && $ev_err->isa("Some::Module::Exception")) {
1760             # handle Some::Module::Exception
1761         }
1762         else {
1763             # handle all other possible exceptions
1764         }
1765     }
1766
1767 Because Perl stringifies uncaught exception messages before display,
1768 you'll probably want to overload stringification operations on
1769 exception objects.  See L<overload> for details about that.
1770
1771 You can arrange for a callback to be run just before the
1772 L<C<die>|/die LIST> does its deed, by setting the
1773 L<C<$SIG{__DIE__}>|perlvar/%SIG> hook.  The associated handler is called
1774 with the error text and can change the error message, if it sees fit, by
1775 calling L<C<die>|/die LIST> again.  See L<perlvar/%SIG> for details on
1776 setting L<C<%SIG>|perlvar/%SIG> entries, and L<C<eval>|/eval EXPR> for some
1777 examples.  Although this feature was to be run only right before your
1778 program was to exit, this is not currently so: the
1779 L<C<$SIG{__DIE__}>|perlvar/%SIG> hook is currently called even inside
1780 L<C<eval>|/eval EXPR>ed blocks/strings!  If one wants the hook to do
1781 nothing in such situations, put
1782
1783     die @_ if $^S;
1784
1785 as the first line of the handler (see L<perlvar/$^S>).  Because
1786 this promotes strange action at a distance, this counterintuitive
1787 behavior may be fixed in a future release.
1788
1789 See also L<C<exit>|/exit EXPR>, L<C<warn>|/warn LIST>, and the L<Carp>
1790 module.
1791
1792 =item do BLOCK
1793 X<do> X<block>
1794
1795 =for Pod::Functions turn a BLOCK into a TERM
1796
1797 Not really a function.  Returns the value of the last command in the
1798 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1799 C<until> loop modifier, executes the BLOCK once before testing the loop
1800 condition.  (On other statements the loop modifiers test the conditional
1801 first.)
1802
1803 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1804 L<C<next>|/next LABEL>, L<C<last>|/last LABEL>, or
1805 L<C<redo>|/redo LABEL> cannot be used to leave or restart the block.
1806 See L<perlsyn> for alternative strategies.
1807
1808 =item do EXPR
1809 X<do>
1810
1811 Uses the value of EXPR as a filename and executes the contents of the
1812 file as a Perl script:
1813
1814     # load the exact specified file (./ and ../ special-cased)
1815     do '/foo/stat.pl';
1816     do './stat.pl';
1817     do '../foo/stat.pl';
1818
1819     # search for the named file within @INC
1820     do 'stat.pl';
1821     do 'foo/stat.pl';
1822
1823 C<do './stat.pl'> is largely like
1824
1825     eval `cat stat.pl`;
1826
1827 except that it's more concise, runs no external processes, and keeps
1828 track of the current filename for error messages. It also differs in that
1829 code evaluated with C<do FILE> cannot see lexicals in the enclosing
1830 scope; C<eval STRING> does.  It's the same, however, in that it does
1831 reparse the file every time you call it, so you probably don't want
1832 to do this inside a loop.
1833
1834 Using C<do> with a relative path (except for F<./> and F<../>), like
1835
1836     do 'foo/stat.pl';
1837
1838 will search the L<C<@INC>|perlvar/@INC> directories, and update
1839 L<C<%INC>|perlvar/%INC> if the file is found.  See L<perlvar/@INC>
1840 and L<perlvar/%INC> for these variables. In particular, note that
1841 whilst historically L<C<@INC>|perlvar/@INC> contained '.' (the
1842 current directory) making these two cases equivalent, that is no
1843 longer necessarily the case, as '.' is not included in C<@INC> by default
1844 in perl versions 5.26.0 onwards. Instead, perl will now warn:
1845
1846     do "stat.pl" failed, '.' is no longer in @INC;
1847     did you mean do "./stat.pl"?
1848
1849 If L<C<do>|/do EXPR> can read the file but cannot compile it, it
1850 returns L<C<undef>|/undef EXPR> and sets an error message in
1851 L<C<$@>|perlvar/$@>.  If L<C<do>|/do EXPR> cannot read the file, it
1852 returns undef and sets L<C<$!>|perlvar/$!> to the error.  Always check
1853 L<C<$@>|perlvar/$@> first, as compilation could fail in a way that also
1854 sets L<C<$!>|perlvar/$!>.  If the file is successfully compiled,
1855 L<C<do>|/do EXPR> returns the value of the last expression evaluated.
1856
1857 Inclusion of library modules is better done with the
1858 L<C<use>|/use Module VERSION LIST> and L<C<require>|/require VERSION>
1859 operators, which also do automatic error checking and raise an exception
1860 if there's a problem.
1861
1862 You might like to use L<C<do>|/do EXPR> to read in a program
1863 configuration file.  Manual error checking can be done this way:
1864
1865     # Read in config files: system first, then user.
1866     # Beware of using relative pathnames here.
1867     for $file ("/share/prog/defaults.rc",
1868                "$ENV{HOME}/.someprogrc")
1869     {
1870         unless ($return = do $file) {
1871             warn "couldn't parse $file: $@" if $@;
1872             warn "couldn't do $file: $!"    unless defined $return;
1873             warn "couldn't run $file"       unless $return;
1874         }
1875     }
1876
1877 =item dump LABEL
1878 X<dump> X<core> X<undump>
1879
1880 =item dump EXPR
1881
1882 =item dump
1883
1884 =for Pod::Functions create an immediate core dump
1885
1886 This function causes an immediate core dump.  See also the B<-u>
1887 command-line switch in L<perlrun>, which does the same thing.
1888 Primarily this is so that you can use the B<undump> program (not
1889 supplied) to turn your core dump into an executable binary after
1890 having initialized all your variables at the beginning of the
1891 program.  When the new binary is executed it will begin by executing
1892 a C<goto LABEL> (with all the restrictions that L<C<goto>|/goto LABEL>
1893 suffers).
1894 Think of it as a goto with an intervening core dump and reincarnation.
1895 If C<LABEL> is omitted, restarts the program from the top.  The
1896 C<dump EXPR> form, available starting in Perl 5.18.0, allows a name to be
1897 computed at run time, being otherwise identical to C<dump LABEL>.
1898
1899 B<WARNING>: Any files opened at the time of the dump will I<not>
1900 be open any more when the program is reincarnated, with possible
1901 resulting confusion by Perl.
1902
1903 This function is now largely obsolete, mostly because it's very hard to
1904 convert a core file into an executable.  That's why you should now invoke
1905 it as C<CORE::dump()> if you don't want to be warned against a possible
1906 typo.
1907
1908 Unlike most named operators, this has the same precedence as assignment.
1909 It is also exempt from the looks-like-a-function rule, so
1910 C<dump ("foo")."bar"> will cause "bar" to be part of the argument to
1911 L<C<dump>|/dump LABEL>.
1912
1913 Portability issues: L<perlport/dump>.
1914
1915 =item each HASH
1916 X<each> X<hash, iterator>
1917
1918 =item each ARRAY
1919 X<array, iterator>
1920
1921 =for Pod::Functions retrieve the next key/value pair from a hash
1922
1923 When called on a hash in list context, returns a 2-element list
1924 consisting of the key and value for the next element of a hash.  In Perl
1925 5.12 and later only, it will also return the index and value for the next
1926 element of an array so that you can iterate over it; older Perls consider
1927 this a syntax error.  When called in scalar context, returns only the key
1928 (not the value) in a hash, or the index in an array.
1929
1930 Hash entries are returned in an apparently random order.  The actual random
1931 order is specific to a given hash; the exact same series of operations
1932 on two hashes may result in a different order for each hash.  Any insertion
1933 into the hash may change the order, as will any deletion, with the exception
1934 that the most recent key returned by L<C<each>|/each HASH> or
1935 L<C<keys>|/keys HASH> may be deleted without changing the order.  So
1936 long as a given hash is unmodified you may rely on
1937 L<C<keys>|/keys HASH>, L<C<values>|/values HASH> and
1938 L<C<each>|/each HASH> to repeatedly return the same order
1939 as each other.  See L<perlsec/"Algorithmic Complexity Attacks"> for
1940 details on why hash order is randomized.  Aside from the guarantees
1941 provided here the exact details of Perl's hash algorithm and the hash
1942 traversal order are subject to change in any release of Perl.
1943
1944 After L<C<each>|/each HASH> has returned all entries from the hash or
1945 array, the next call to L<C<each>|/each HASH> returns the empty list in
1946 list context and L<C<undef>|/undef EXPR> in scalar context; the next
1947 call following I<that> one restarts iteration.  Each hash or array has
1948 its own internal iterator, accessed by L<C<each>|/each HASH>,
1949 L<C<keys>|/keys HASH>, and L<C<values>|/values HASH>.  The iterator is
1950 implicitly reset when L<C<each>|/each HASH> has reached the end as just
1951 described; it can be explicitly reset by calling L<C<keys>|/keys HASH>
1952 or L<C<values>|/values HASH> on the hash or array.  If you add or delete
1953 a hash's elements while iterating over it, the effect on the iterator is
1954 unspecified; for example, entries may be skipped or duplicated--so don't
1955 do that.  Exception: It is always safe to delete the item most recently
1956 returned by L<C<each>|/each HASH>, so the following code works properly:
1957
1958     while (my ($key, $value) = each %hash) {
1959         print $key, "\n";
1960         delete $hash{$key};   # This is safe
1961     }
1962
1963 Tied hashes may have a different ordering behaviour to perl's hash
1964 implementation.
1965
1966 This prints out your environment like the L<printenv(1)> program,
1967 but in a different order:
1968
1969     while (my ($key,$value) = each %ENV) {
1970         print "$key=$value\n";
1971     }
1972
1973 Starting with Perl 5.14, an experimental feature allowed
1974 L<C<each>|/each HASH> to take a scalar expression. This experiment has
1975 been deemed unsuccessful, and was removed as of Perl 5.24.
1976
1977 As of Perl 5.18 you can use a bare L<C<each>|/each HASH> in a C<while>
1978 loop, which will set L<C<$_>|perlvar/$_> on every iteration.
1979
1980     while (each %ENV) {
1981         print "$_=$ENV{$_}\n";
1982     }
1983
1984 To avoid confusing would-be users of your code who are running earlier
1985 versions of Perl with mysterious syntax errors, put this sort of thing at
1986 the top of your file to signal that your code will work I<only> on Perls of
1987 a recent vintage:
1988
1989     use 5.012;  # so keys/values/each work on arrays
1990     use 5.018;  # so each assigns to $_ in a lone while test
1991
1992 See also L<C<keys>|/keys HASH>, L<C<values>|/values HASH>, and
1993 L<C<sort>|/sort SUBNAME LIST>.
1994
1995 =item eof FILEHANDLE
1996 X<eof>
1997 X<end of file>
1998 X<end-of-file>
1999
2000 =item eof ()
2001
2002 =item eof
2003
2004 =for Pod::Functions test a filehandle for its end
2005
2006 Returns 1 if the next read on FILEHANDLE will return end of file I<or> if
2007 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
2008 gives the real filehandle.  (Note that this function actually
2009 reads a character and then C<ungetc>s it, so isn't useful in an
2010 interactive context.)  Do not read from a terminal file (or call
2011 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
2012 as terminals may lose the end-of-file condition if you do.
2013
2014 An L<C<eof>|/eof FILEHANDLE> without an argument uses the last file
2015 read.  Using L<C<eof()>|/eof FILEHANDLE> with empty parentheses is
2016 different.  It refers to the pseudo file formed from the files listed on
2017 the command line and accessed via the C<< <> >> operator.  Since
2018 C<< <> >> isn't explicitly opened, as a normal filehandle is, an
2019 L<C<eof()>|/eof FILEHANDLE> before C<< <> >> has been used will cause
2020 L<C<@ARGV>|perlvar/@ARGV> to be examined to determine if input is
2021 available.   Similarly, an L<C<eof()>|/eof FILEHANDLE> after C<< <> >>
2022 has returned end-of-file will assume you are processing another
2023 L<C<@ARGV>|perlvar/@ARGV> list, and if you haven't set
2024 L<C<@ARGV>|perlvar/@ARGV>, will read input from C<STDIN>; see
2025 L<perlop/"I/O Operators">.
2026
2027 In a C<< while (<>) >> loop, L<C<eof>|/eof FILEHANDLE> or C<eof(ARGV)>
2028 can be used to detect the end of each file, whereas
2029 L<C<eof()>|/eof FILEHANDLE> will detect the end of the very last file
2030 only.  Examples:
2031
2032     # reset line numbering on each input file
2033     while (<>) {
2034         next if /^\s*#/;  # skip comments
2035         print "$.\t$_";
2036     } continue {
2037         close ARGV if eof;  # Not eof()!
2038     }
2039
2040     # insert dashes just before last line of last file
2041     while (<>) {
2042         if (eof()) {  # check for end of last file
2043             print "--------------\n";
2044         }
2045         print;
2046         last if eof();     # needed if we're reading from a terminal
2047     }
2048
2049 Practical hint: you almost never need to use L<C<eof>|/eof FILEHANDLE>
2050 in Perl, because the input operators typically return L<C<undef>|/undef
2051 EXPR> when they run out of data or encounter an error.
2052
2053 =item eval EXPR
2054 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
2055 X<error, handling> X<exception, handling>
2056
2057 =item eval BLOCK
2058
2059 =item eval
2060
2061 =for Pod::Functions catch exceptions or compile and run code
2062
2063 C<eval> in all its forms is used to execute a little Perl program,
2064 trapping any errors encountered so they don't crash the calling program.
2065
2066 Plain C<eval> with no argument is just C<eval EXPR>, where the
2067 expression is understood to be contained in L<C<$_>|perlvar/$_>.  Thus
2068 there are only two real C<eval> forms; the one with an EXPR is often
2069 called "string eval".  In a string eval, the value of the expression
2070 (which is itself determined within scalar context) is first parsed, and
2071 if there were no errors, executed as a block within the lexical context
2072 of the current Perl program.  This form is typically used to delay
2073 parsing and subsequent execution of the text of EXPR until run time.
2074 Note that the value is parsed every time the C<eval> executes.
2075
2076 The other form is called "block eval".  It is less general than string
2077 eval, but the code within the BLOCK is parsed only once (at the same
2078 time the code surrounding the C<eval> itself was parsed) and executed
2079 within the context of the current Perl program.  This form is typically
2080 used to trap exceptions more efficiently than the first, while also
2081 providing the benefit of checking the code within BLOCK at compile time.
2082 BLOCK is parsed and compiled just once.  Since errors are trapped, it
2083 often is used to check if a given feature is available.
2084
2085 In both forms, the value returned is the value of the last expression
2086 evaluated inside the mini-program; a return statement may also be used, just
2087 as with subroutines.  The expression providing the return value is evaluated
2088 in void, scalar, or list context, depending on the context of the
2089 C<eval> itself.  See L<C<wantarray>|/wantarray> for more
2090 on how the evaluation context can be determined.
2091
2092 If there is a syntax error or runtime error, or a L<C<die>|/die LIST>
2093 statement is executed, C<eval> returns
2094 L<C<undef>|/undef EXPR> in scalar context, or an empty list in list
2095 context, and L<C<$@>|perlvar/$@> is set to the error message.  (Prior to
2096 5.16, a bug caused L<C<undef>|/undef EXPR> to be returned in list
2097 context for syntax errors, but not for runtime errors.) If there was no
2098 error, L<C<$@>|perlvar/$@> is set to the empty string.  A control flow
2099 operator like L<C<last>|/last LABEL> or L<C<goto>|/goto LABEL> can
2100 bypass the setting of L<C<$@>|perlvar/$@>.  Beware that using
2101 C<eval> neither silences Perl from printing warnings to
2102 STDERR, nor does it stuff the text of warning messages into
2103 L<C<$@>|perlvar/$@>.  To do either of those, you have to use the
2104 L<C<$SIG{__WARN__}>|perlvar/%SIG> facility, or turn off warnings inside
2105 the BLOCK or EXPR using S<C<no warnings 'all'>>.  See
2106 L<C<warn>|/warn LIST>, L<perlvar>, and L<warnings>.
2107
2108 Note that, because C<eval> traps otherwise-fatal errors,
2109 it is useful for determining whether a particular feature (such as
2110 L<C<socket>|/socket SOCKET,DOMAIN,TYPE,PROTOCOL> or
2111 L<C<symlink>|/symlink OLDFILE,NEWFILE>) is implemented.  It is also
2112 Perl's exception-trapping mechanism, where the L<C<die>|/die LIST>
2113 operator is used to raise exceptions.
2114
2115 Before Perl 5.14, the assignment to L<C<$@>|perlvar/$@> occurred before
2116 restoration
2117 of localized variables, which means that for your code to run on older
2118 versions, a temporary is required if you want to mask some, but not all
2119 errors:
2120
2121  # alter $@ on nefarious repugnancy only
2122  {
2123     my $e;
2124     {
2125       local $@; # protect existing $@
2126       eval { test_repugnancy() };
2127       # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only
2128       $@ =~ /nefarious/ and $e = $@;
2129     }
2130     die $e if defined $e
2131  }
2132
2133 There are some different considerations for each form:
2134
2135 =over 4
2136
2137 =item String eval
2138
2139 Since the return value of EXPR is executed as a block within the lexical
2140 context of the current Perl program, any outer lexical variables are
2141 visible to it, and any package variable settings or subroutine and
2142 format definitions remain afterwards.
2143
2144 =over 4
2145
2146 =item Under the L<C<"unicode_eval"> feature|feature/The 'unicode_eval' and 'evalbytes' features>
2147
2148 If this feature is enabled (which is the default under a C<use 5.16> or
2149 higher declaration), EXPR is considered to be
2150 in the same encoding as the surrounding program.  Thus if
2151 S<L<C<use utf8>|utf8>> is in effect, the string will be treated as being
2152 UTF-8 encoded.  Otherwise, the string is considered to be a sequence of
2153 independent bytes.  Bytes that correspond to ASCII-range code points
2154 will have their normal meanings for operators in the string.  The
2155 treatment of the other bytes depends on if the
2156 L<C<'unicode_strings"> feature|feature/The 'unicode_strings' feature> is
2157 in effect.
2158
2159 In a plain C<eval> without an EXPR argument, being in S<C<use utf8>> or
2160 not is irrelevant; the UTF-8ness of C<$_> itself determines the
2161 behavior.
2162
2163 Any S<C<use utf8>> or S<C<no utf8>> declarations within the string have
2164 no effect, and source filters are forbidden.  (C<unicode_strings>,
2165 however, can appear within the string.)  See also the
2166 L<C<evalbytes>|/evalbytes EXPR> operator, which works properly with
2167 source filters.
2168
2169 Variables defined outside the C<eval> and used inside it retain their
2170 original UTF-8ness.  Everything inside the string follows the normal
2171 rules for a Perl program with the given state of S<C<use utf8>>.
2172
2173 =item Outside the C<"unicode_eval"> feature
2174
2175 In this case, the behavior is problematic and is not so easily
2176 described.  Here are two bugs that cannot easily be fixed without
2177 breaking existing programs:
2178
2179 =over 4
2180
2181 =item *
2182
2183 It can lose track of whether something should be encoded as UTF-8 or
2184 not.
2185
2186 =item *
2187
2188 Source filters activated within C<eval> leak out into whichever file
2189 scope is currently being compiled.  To give an example with the CPAN module
2190 L<Semi::Semicolons>:
2191
2192  BEGIN { eval "use Semi::Semicolons; # not filtered" }
2193  # filtered here!
2194
2195 L<C<evalbytes>|/evalbytes EXPR> fixes that to work the way one would
2196 expect:
2197
2198  use feature "evalbytes";
2199  BEGIN { evalbytes "use Semi::Semicolons; # filtered" }
2200  # not filtered
2201
2202 =back
2203
2204 =back
2205
2206 Problems can arise if the string expands a scalar containing a floating
2207 point number.  That scalar can expand to letters, such as C<"NaN"> or
2208 C<"Infinity">; or, within the scope of a L<C<use locale>|locale>, the
2209 decimal point character may be something other than a dot (such as a
2210 comma).  None of these are likely to parse as you are likely expecting.
2211
2212 You should be especially careful to remember what's being looked at
2213 when:
2214
2215     eval $x;        # CASE 1
2216     eval "$x";      # CASE 2
2217
2218     eval '$x';      # CASE 3
2219     eval { $x };    # CASE 4
2220
2221     eval "\$$x++";  # CASE 5
2222     $$x++;          # CASE 6
2223
2224 Cases 1 and 2 above behave identically: they run the code contained in
2225 the variable $x.  (Although case 2 has misleading double quotes making
2226 the reader wonder what else might be happening (nothing is).)  Cases 3
2227 and 4 likewise behave in the same way: they run the code C<'$x'>, which
2228 does nothing but return the value of $x.  (Case 4 is preferred for
2229 purely visual reasons, but it also has the advantage of compiling at
2230 compile-time instead of at run-time.)  Case 5 is a place where
2231 normally you I<would> like to use double quotes, except that in this
2232 particular situation, you can just use symbolic references instead, as
2233 in case 6.
2234
2235 An C<eval ''> executed within a subroutine defined
2236 in the C<DB> package doesn't see the usual
2237 surrounding lexical scope, but rather the scope of the first non-DB piece
2238 of code that called it.  You don't normally need to worry about this unless
2239 you are writing a Perl debugger.
2240
2241 The final semicolon, if any, may be omitted from the value of EXPR.
2242
2243 =item Block eval
2244
2245 If the code to be executed doesn't vary, you may use the eval-BLOCK
2246 form to trap run-time errors without incurring the penalty of
2247 recompiling each time.  The error, if any, is still returned in
2248 L<C<$@>|perlvar/$@>.
2249 Examples:
2250
2251     # make divide-by-zero nonfatal
2252     eval { $answer = $a / $b; }; warn $@ if $@;
2253
2254     # same thing, but less efficient
2255     eval '$answer = $a / $b'; warn $@ if $@;
2256
2257     # a compile-time error
2258     eval { $answer = }; # WRONG
2259
2260     # a run-time error
2261     eval '$answer =';   # sets $@
2262
2263 If you want to trap errors when loading an XS module, some problems with
2264 the binary interface (such as Perl version skew) may be fatal even with
2265 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set.  See
2266 L<perlrun>.
2267
2268 Using the C<eval {}> form as an exception trap in libraries does have some
2269 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
2270 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
2271 You can use the C<local $SIG{__DIE__}> construct for this purpose,
2272 as this example shows:
2273
2274     # a private exception trap for divide-by-zero
2275     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
2276     warn $@ if $@;
2277
2278 This is especially significant, given that C<__DIE__> hooks can call
2279 L<C<die>|/die LIST> again, which has the effect of changing their error
2280 messages:
2281
2282     # __DIE__ hooks may modify error messages
2283     {
2284        local $SIG{'__DIE__'} =
2285               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
2286        eval { die "foo lives here" };
2287        print $@ if $@;                # prints "bar lives here"
2288     }
2289
2290 Because this promotes action at a distance, this counterintuitive behavior
2291 may be fixed in a future release.
2292
2293 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
2294 L<C<next>|/next LABEL>, L<C<last>|/last LABEL>, or
2295 L<C<redo>|/redo LABEL> cannot be used to leave or restart the block.
2296
2297 The final semicolon, if any, may be omitted from within the BLOCK.
2298
2299 =back
2300
2301 =item evalbytes EXPR
2302 X<evalbytes>
2303
2304 =item evalbytes
2305
2306 =for Pod::Functions +evalbytes similar to string eval, but intend to parse a bytestream
2307
2308 This function is similar to a L<string eval|/eval EXPR>, except it
2309 always parses its argument (or L<C<$_>|perlvar/$_> if EXPR is omitted)
2310 as a string of independent bytes.
2311
2312 If called when S<C<use utf8>> is in effect, the string will be assumed
2313 to be encoded in UTF-8, and C<evalbytes> will make a temporary copy to
2314 work from, downgraded to non-UTF-8.  If this is not possible
2315 (because one or more characters in it require UTF-8), the C<evalbytes>
2316 will fail with the error stored in C<$@>.
2317
2318 Bytes that correspond to ASCII-range code points will have their normal
2319 meanings for operators in the string.  The treatment of the other bytes
2320 depends on if the L<C<'unicode_strings"> feature|feature/The
2321 'unicode_strings' feature> is in effect.
2322
2323 Of course, variables that are UTF-8 and are referred to in the string
2324 retain that:
2325
2326  my $a = "\x{100}";
2327  evalbytes 'print ord $a, "\n"';
2328
2329 prints
2330
2331  256
2332
2333 and C<$@> is empty.
2334
2335 Source filters activated within the evaluated code apply to the code
2336 itself.
2337
2338 L<C<evalbytes>|/evalbytes EXPR> is available starting in Perl v5.16.  To
2339 access it, you must say C<CORE::evalbytes>, but you can omit the
2340 C<CORE::> if the
2341 L<C<"evalbytes"> feature|feature/The 'unicode_eval' and 'evalbytes' features>
2342 is enabled.  This is enabled automatically with a C<use v5.16> (or
2343 higher) declaration in the current scope.
2344
2345 =item exec LIST
2346 X<exec> X<execute>
2347
2348 =item exec PROGRAM LIST
2349
2350 =for Pod::Functions abandon this program to run another
2351
2352 The L<C<exec>|/exec LIST> function executes a system command I<and never
2353 returns>; use L<C<system>|/system LIST> instead of L<C<exec>|/exec LIST>
2354 if you want it to return.  It fails and
2355 returns false only if the command does not exist I<and> it is executed
2356 directly instead of via your system's command shell (see below).
2357
2358 Since it's a common mistake to use L<C<exec>|/exec LIST> instead of
2359 L<C<system>|/system LIST>, Perl warns you if L<C<exec>|/exec LIST> is
2360 called in void context and if there is a following statement that isn't
2361 L<C<die>|/die LIST>, L<C<warn>|/warn LIST>, or L<C<exit>|/exit EXPR> (if
2362 L<warnings> are enabled--but you always do that, right?).  If you
2363 I<really> want to follow an L<C<exec>|/exec LIST> with some other
2364 statement, you can use one of these styles to avoid the warning:
2365
2366     exec ('foo')   or print STDERR "couldn't exec foo: $!";
2367     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
2368
2369 If there is more than one argument in LIST, this calls L<execvp(3)> with the
2370 arguments in LIST.  If there is only one element in LIST, the argument is
2371 checked for shell metacharacters, and if there are any, the entire
2372 argument is passed to the system's command shell for parsing (this is
2373 C</bin/sh -c> on Unix platforms, but varies on other platforms).  If
2374 there are no shell metacharacters in the argument, it is split into words
2375 and passed directly to C<execvp>, which is more efficient.  Examples:
2376
2377     exec '/bin/echo', 'Your arguments are: ', @ARGV;
2378     exec "sort $outfile | uniq";
2379
2380 If you don't really want to execute the first argument, but want to lie
2381 to the program you are executing about its own name, you can specify
2382 the program you actually want to run as an "indirect object" (without a
2383 comma) in front of the LIST, as in C<exec PROGRAM LIST>.  (This always
2384 forces interpretation of the LIST as a multivalued list, even if there
2385 is only a single scalar in the list.)  Example:
2386
2387     my $shell = '/bin/csh';
2388     exec $shell '-sh';    # pretend it's a login shell
2389
2390 or, more directly,
2391
2392     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
2393
2394 When the arguments get executed via the system shell, results are
2395 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
2396 for details.
2397
2398 Using an indirect object with L<C<exec>|/exec LIST> or
2399 L<C<system>|/system LIST> is also more secure.  This usage (which also
2400 works fine with L<C<system>|/system LIST>) forces
2401 interpretation of the arguments as a multivalued list, even if the
2402 list had just one argument.  That way you're safe from the shell
2403 expanding wildcards or splitting up words with whitespace in them.
2404
2405     my @args = ( "echo surprise" );
2406
2407     exec @args;               # subject to shell escapes
2408                                 # if @args == 1
2409     exec { $args[0] } @args;  # safe even with one-arg list
2410
2411 The first version, the one without the indirect object, ran the I<echo>
2412 program, passing it C<"surprise"> an argument.  The second version didn't;
2413 it tried to run a program named I<"echo surprise">, didn't find it, and set
2414 L<C<$?>|perlvar/$?> to a non-zero value indicating failure.
2415
2416 On Windows, only the C<exec PROGRAM LIST> indirect object syntax will
2417 reliably avoid using the shell; C<exec LIST>, even with more than one
2418 element, will fall back to the shell if the first spawn fails.
2419
2420 Perl attempts to flush all files opened for output before the exec,
2421 but this may not be supported on some platforms (see L<perlport>).
2422 To be safe, you may need to set L<C<$E<verbar>>|perlvar/$E<verbar>>
2423 (C<$AUTOFLUSH> in L<English>) or call the C<autoflush> method of
2424 L<C<IO::Handle>|IO::Handle/METHODS> on any open handles to avoid lost
2425 output.
2426
2427 Note that L<C<exec>|/exec LIST> will not call your C<END> blocks, nor
2428 will it invoke C<DESTROY> methods on your objects.
2429
2430 Portability issues: L<perlport/exec>.
2431
2432 =item exists EXPR
2433 X<exists> X<autovivification>
2434
2435 =for Pod::Functions test whether a hash key is present
2436
2437 Given an expression that specifies an element of a hash, returns true if the
2438 specified element in the hash has ever been initialized, even if the
2439 corresponding value is undefined.
2440
2441     print "Exists\n"    if exists $hash{$key};
2442     print "Defined\n"   if defined $hash{$key};
2443     print "True\n"      if $hash{$key};
2444
2445 exists may also be called on array elements, but its behavior is much less
2446 obvious and is strongly tied to the use of L<C<delete>|/delete EXPR> on
2447 arrays.
2448
2449 B<WARNING:> Calling L<C<exists>|/exists EXPR> on array values is
2450 strongly discouraged.  The
2451 notion of deleting or checking the existence of Perl array elements is not
2452 conceptually coherent, and can lead to surprising behavior.
2453
2454     print "Exists\n"    if exists $array[$index];
2455     print "Defined\n"   if defined $array[$index];
2456     print "True\n"      if $array[$index];
2457
2458 A hash or array element can be true only if it's defined and defined only if
2459 it exists, but the reverse doesn't necessarily hold true.
2460
2461 Given an expression that specifies the name of a subroutine,
2462 returns true if the specified subroutine has ever been declared, even
2463 if it is undefined.  Mentioning a subroutine name for exists or defined
2464 does not count as declaring it.  Note that a subroutine that does not
2465 exist may still be callable: its package may have an C<AUTOLOAD>
2466 method that makes it spring into existence the first time that it is
2467 called; see L<perlsub>.
2468
2469     print "Exists\n"  if exists &subroutine;
2470     print "Defined\n" if defined &subroutine;
2471
2472 Note that the EXPR can be arbitrarily complicated as long as the final
2473 operation is a hash or array key lookup or subroutine name:
2474
2475     if (exists $ref->{A}->{B}->{$key})  { }
2476     if (exists $hash{A}{B}{$key})       { }
2477
2478     if (exists $ref->{A}->{B}->[$ix])   { }
2479     if (exists $hash{A}{B}[$ix])        { }
2480
2481     if (exists &{$ref->{A}{B}{$key}})   { }
2482
2483 Although the most deeply nested array or hash element will not spring into
2484 existence just because its existence was tested, any intervening ones will.
2485 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
2486 into existence due to the existence test for the C<$key> element above.
2487 This happens anywhere the arrow operator is used, including even here:
2488
2489     undef $ref;
2490     if (exists $ref->{"Some key"})    { }
2491     print $ref;  # prints HASH(0x80d3d5c)
2492
2493 Use of a subroutine call, rather than a subroutine name, as an argument
2494 to L<C<exists>|/exists EXPR> is an error.
2495
2496     exists &sub;    # OK
2497     exists &sub();  # Error
2498
2499 =item exit EXPR
2500 X<exit> X<terminate> X<abort>
2501
2502 =item exit
2503
2504 =for Pod::Functions terminate this program
2505
2506 Evaluates EXPR and exits immediately with that value.    Example:
2507
2508     my $ans = <STDIN>;
2509     exit 0 if $ans =~ /^[Xx]/;
2510
2511 See also L<C<die>|/die LIST>.  If EXPR is omitted, exits with C<0>
2512 status.  The only
2513 universally recognized values for EXPR are C<0> for success and C<1>
2514 for error; other values are subject to interpretation depending on the
2515 environment in which the Perl program is running.  For example, exiting
2516 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
2517 the mailer to return the item undelivered, but that's not true everywhere.
2518
2519 Don't use L<C<exit>|/exit EXPR> to abort a subroutine if there's any
2520 chance that someone might want to trap whatever error happened.  Use
2521 L<C<die>|/die LIST> instead, which can be trapped by an
2522 L<C<eval>|/eval EXPR>.
2523
2524 The L<C<exit>|/exit EXPR> function does not always exit immediately.  It
2525 calls any defined C<END> routines first, but these C<END> routines may
2526 not themselves abort the exit.  Likewise any object destructors that
2527 need to be called are called before the real exit.  C<END> routines and
2528 destructors can change the exit status by modifying L<C<$?>|perlvar/$?>.
2529 If this is a problem, you can call
2530 L<C<POSIX::_exit($status)>|POSIX/C<_exit>> to avoid C<END> and destructor
2531 processing.  See L<perlmod> for details.
2532
2533 Portability issues: L<perlport/exit>.
2534
2535 =item exp EXPR
2536 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
2537
2538 =item exp
2539
2540 =for Pod::Functions raise I<e> to a power
2541
2542 Returns I<e> (the natural logarithm base) to the power of EXPR.
2543 If EXPR is omitted, gives C<exp($_)>.
2544
2545 =item fc EXPR
2546 X<fc> X<foldcase> X<casefold> X<fold-case> X<case-fold>
2547
2548 =item fc
2549
2550 =for Pod::Functions +fc return casefolded version of a string
2551
2552 Returns the casefolded version of EXPR.  This is the internal function
2553 implementing the C<\F> escape in double-quoted strings.
2554
2555 Casefolding is the process of mapping strings to a form where case
2556 differences are erased; comparing two strings in their casefolded
2557 form is effectively a way of asking if two strings are equal,
2558 regardless of case.
2559
2560 Roughly, if you ever found yourself writing this
2561
2562     lc($this) eq lc($that)    # Wrong!
2563         # or
2564     uc($this) eq uc($that)    # Also wrong!
2565         # or
2566     $this =~ /^\Q$that\E\z/i  # Right!
2567
2568 Now you can write
2569
2570     fc($this) eq fc($that)
2571
2572 And get the correct results.
2573
2574 Perl only implements the full form of casefolding, but you can access
2575 the simple folds using L<Unicode::UCD/B<casefold()>> and
2576 L<Unicode::UCD/B<prop_invmap()>>.
2577 For further information on casefolding, refer to
2578 the Unicode Standard, specifically sections 3.13 C<Default Case Operations>,
2579 4.2 C<Case-Normative>, and 5.18 C<Case Mappings>,
2580 available at L<http://www.unicode.org/versions/latest/>, as well as the
2581 Case Charts available at L<http://www.unicode.org/charts/case/>.
2582
2583 If EXPR is omitted, uses L<C<$_>|perlvar/$_>.
2584
2585 This function behaves the same way under various pragmas, such as within
2586 L<S<C<"use feature 'unicode_strings">>|feature/The 'unicode_strings' feature>,
2587 as L<C<lc>|/lc EXPR> does, with the single exception of
2588 L<C<fc>|/fc EXPR> of I<LATIN CAPITAL LETTER SHARP S> (U+1E9E) within the
2589 scope of L<S<C<use locale>>|locale>.  The foldcase of this character
2590 would normally be C<"ss">, but as explained in the L<C<lc>|/lc EXPR>
2591 section, case
2592 changes that cross the 255/256 boundary are problematic under locales,
2593 and are hence prohibited.  Therefore, this function under locale returns
2594 instead the string C<"\x{17F}\x{17F}">, which is the I<LATIN SMALL LETTER
2595 LONG S>.  Since that character itself folds to C<"s">, the string of two
2596 of them together should be equivalent to a single U+1E9E when foldcased.
2597
2598 While the Unicode Standard defines two additional forms of casefolding,
2599 one for Turkic languages and one that never maps one character into multiple
2600 characters, these are not provided by the Perl core.  However, the CPAN module
2601 L<C<Unicode::Casing>|Unicode::Casing> may be used to provide an implementation.
2602
2603 L<C<fc>|/fc EXPR> is available only if the
2604 L<C<"fc"> feature|feature/The 'fc' feature> is enabled or if it is
2605 prefixed with C<CORE::>.  The
2606 L<C<"fc"> feature|feature/The 'fc' feature> is enabled automatically
2607 with a C<use v5.16> (or higher) declaration in the current scope.
2608
2609 =item fcntl FILEHANDLE,FUNCTION,SCALAR
2610 X<fcntl>
2611
2612 =for Pod::Functions file control system call
2613
2614 Implements the L<fcntl(2)> function.  You'll probably have to say
2615
2616     use Fcntl;
2617
2618 first to get the correct constant definitions.  Argument processing and
2619 value returned work just like L<C<ioctl>|/ioctl
2620 FILEHANDLE,FUNCTION,SCALAR> below.  For example:
2621
2622     use Fcntl;
2623     my $flags = fcntl($filehandle, F_GETFL, 0)
2624         or die "Can't fcntl F_GETFL: $!";
2625
2626 You don't have to check for L<C<defined>|/defined EXPR> on the return
2627 from L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR>.  Like
2628 L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR>, it maps a C<0> return
2629 from the system call into C<"0 but true"> in Perl.  This string is true
2630 in boolean context and C<0> in numeric context.  It is also exempt from
2631 the normal
2632 L<C<Argument "..." isn't numeric>|perldiag/Argument "%s" isn't numeric%s>
2633 L<warnings> on improper numeric conversions.
2634
2635 Note that L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR> raises an
2636 exception if used on a machine that doesn't implement L<fcntl(2)>.  See
2637 the L<Fcntl> module or your L<fcntl(2)> manpage to learn what functions
2638 are available on your system.
2639
2640 Here's an example of setting a filehandle named C<$REMOTE> to be
2641 non-blocking at the system level.  You'll have to negotiate
2642 L<C<$E<verbar>>|perlvar/$E<verbar>> on your own, though.
2643
2644     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2645
2646     my $flags = fcntl($REMOTE, F_GETFL, 0)
2647         or die "Can't get flags for the socket: $!\n";
2648
2649     fcntl($REMOTE, F_SETFL, $flags | O_NONBLOCK)
2650         or die "Can't set flags for the socket: $!\n";
2651
2652 Portability issues: L<perlport/fcntl>.
2653
2654 =item __FILE__
2655 X<__FILE__>
2656
2657 =for Pod::Functions the name of the current source file
2658
2659 A special token that returns the name of the file in which it occurs.
2660
2661 =item fileno FILEHANDLE
2662 X<fileno>
2663
2664 =item fileno DIRHANDLE
2665
2666 =for Pod::Functions return file descriptor from filehandle
2667
2668 Returns the file descriptor for a filehandle or directory handle,
2669 or undefined if the
2670 filehandle is not open.  If there is no real file descriptor at the OS
2671 level, as can happen with filehandles connected to memory objects via
2672 L<C<open>|/open FILEHANDLE,EXPR> with a reference for the third
2673 argument, -1 is returned.
2674
2675 This is mainly useful for constructing bitmaps for
2676 L<C<select>|/select RBITS,WBITS,EBITS,TIMEOUT> and low-level POSIX
2677 tty-handling operations.
2678 If FILEHANDLE is an expression, the value is taken as an indirect
2679 filehandle, generally its name.
2680
2681 You can use this to find out whether two handles refer to the
2682 same underlying descriptor:
2683
2684     if (fileno($this) != -1 && fileno($this) == fileno($that)) {
2685         print "\$this and \$that are dups\n";
2686     } elsif (fileno($this) != -1 && fileno($that) != -1) {
2687         print "\$this and \$that have different " .
2688             "underlying file descriptors\n";
2689     } else {
2690         print "At least one of \$this and \$that does " .
2691             "not have a real file descriptor\n";
2692     }
2693
2694 The behavior of L<C<fileno>|/fileno FILEHANDLE> on a directory handle
2695 depends on the operating system.  On a system with L<dirfd(3)> or
2696 similar, L<C<fileno>|/fileno FILEHANDLE> on a directory
2697 handle returns the underlying file descriptor associated with the
2698 handle; on systems with no such support, it returns the undefined value,
2699 and sets L<C<$!>|perlvar/$!> (errno).
2700
2701 =item flock FILEHANDLE,OPERATION
2702 X<flock> X<lock> X<locking>
2703
2704 =for Pod::Functions lock an entire file with an advisory lock
2705
2706 Calls L<flock(2)>, or an emulation of it, on FILEHANDLE.  Returns true
2707 for success, false on failure.  Produces a fatal error if used on a
2708 machine that doesn't implement L<flock(2)>, L<fcntl(2)> locking, or
2709 L<lockf(3)>.  L<C<flock>|/flock FILEHANDLE,OPERATION> is Perl's portable
2710 file-locking interface, although it locks entire files only, not
2711 records.
2712
2713 Two potentially non-obvious but traditional L<C<flock>|/flock
2714 FILEHANDLE,OPERATION> semantics are
2715 that it waits indefinitely until the lock is granted, and that its locks
2716 are B<merely advisory>.  Such discretionary locks are more flexible, but
2717 offer fewer guarantees.  This means that programs that do not also use
2718 L<C<flock>|/flock FILEHANDLE,OPERATION> may modify files locked with
2719 L<C<flock>|/flock FILEHANDLE,OPERATION>.  See L<perlport>,
2720 your port's specific documentation, and your system-specific local manpages
2721 for details.  It's best to assume traditional behavior if you're writing
2722 portable programs.  (But if you're not, you should as always feel perfectly
2723 free to write for your own system's idiosyncrasies (sometimes called
2724 "features").  Slavish adherence to portability concerns shouldn't get
2725 in the way of your getting your job done.)
2726
2727 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
2728 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
2729 you can use the symbolic names if you import them from the L<Fcntl> module,
2730 either individually, or as a group using the C<:flock> tag.  LOCK_SH
2731 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
2732 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
2733 LOCK_SH or LOCK_EX, then L<C<flock>|/flock FILEHANDLE,OPERATION> returns
2734 immediately rather than blocking waiting for the lock; check the return
2735 status to see if you got it.
2736
2737 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
2738 before locking or unlocking it.
2739
2740 Note that the emulation built with L<lockf(3)> doesn't provide shared
2741 locks, and it requires that FILEHANDLE be open with write intent.  These
2742 are the semantics that L<lockf(3)> implements.  Most if not all systems
2743 implement L<lockf(3)> in terms of L<fcntl(2)> locking, though, so the
2744 differing semantics shouldn't bite too many people.
2745
2746 Note that the L<fcntl(2)> emulation of L<flock(3)> requires that FILEHANDLE
2747 be open with read intent to use LOCK_SH and requires that it be open
2748 with write intent to use LOCK_EX.
2749
2750 Note also that some versions of L<C<flock>|/flock FILEHANDLE,OPERATION>
2751 cannot lock things over the network; you would need to use the more
2752 system-specific L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR> for
2753 that.  If you like you can force Perl to ignore your system's L<flock(2)>
2754 function, and so provide its own L<fcntl(2)>-based emulation, by passing
2755 the switch C<-Ud_flock> to the F<Configure> program when you configure
2756 and build a new Perl.
2757
2758 Here's a mailbox appender for BSD systems.
2759
2760     # import LOCK_* and SEEK_END constants
2761     use Fcntl qw(:flock SEEK_END);
2762
2763     sub lock {
2764         my ($fh) = @_;
2765         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
2766         # and, in case we're running on a very old UNIX
2767         # variant without the modern O_APPEND semantics...
2768         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
2769     }
2770
2771     sub unlock {
2772         my ($fh) = @_;
2773         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
2774     }
2775
2776     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
2777         or die "Can't open mailbox: $!";
2778
2779     lock($mbox);
2780     print $mbox $msg,"\n\n";
2781     unlock($mbox);
2782
2783 On systems that support a real L<flock(2)>, locks are inherited across
2784 L<C<fork>|/fork> calls, whereas those that must resort to the more
2785 capricious L<fcntl(2)> function lose their locks, making it seriously
2786 harder to write servers.
2787
2788 See also L<DB_File> for other L<C<flock>|/flock FILEHANDLE,OPERATION>
2789 examples.
2790
2791 Portability issues: L<perlport/flock>.
2792
2793 =item fork
2794 X<fork> X<child> X<parent>
2795
2796 =for Pod::Functions create a new process just like this one
2797
2798 Does a L<fork(2)> system call to create a new process running the
2799 same program at the same point.  It returns the child pid to the
2800 parent process, C<0> to the child process, or L<C<undef>|/undef EXPR> if
2801 the fork is
2802 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2803 are shared, while everything else is copied.  On most systems supporting
2804 L<fork(2)>, great care has gone into making it extremely efficient (for
2805 example, using copy-on-write technology on data pages), making it the
2806 dominant paradigm for multitasking over the last few decades.
2807
2808 Perl attempts to flush all files opened for output before forking the
2809 child process, but this may not be supported on some platforms (see
2810 L<perlport>).  To be safe, you may need to set
2811 L<C<$E<verbar>>|perlvar/$E<verbar>> (C<$AUTOFLUSH> in L<English>) or
2812 call the C<autoflush> method of L<C<IO::Handle>|IO::Handle/METHODS> on
2813 any open handles to avoid duplicate output.
2814
2815 If you L<C<fork>|/fork> without ever waiting on your children, you will
2816 accumulate zombies.  On some systems, you can avoid this by setting
2817 L<C<$SIG{CHLD}>|perlvar/%SIG> to C<"IGNORE">.  See also L<perlipc> for
2818 more examples of forking and reaping moribund children.
2819
2820 Note that if your forked child inherits system file descriptors like
2821 STDIN and STDOUT that are actually connected by a pipe or socket, even
2822 if you exit, then the remote server (such as, say, a CGI script or a
2823 backgrounded job launched from a remote shell) won't think you're done.
2824 You should reopen those to F</dev/null> if it's any issue.
2825
2826 On some platforms such as Windows, where the L<fork(2)> system call is
2827 not available, Perl can be built to emulate L<C<fork>|/fork> in the Perl
2828 interpreter.  The emulation is designed, at the level of the Perl
2829 program, to be as compatible as possible with the "Unix" L<fork(2)>.
2830 However it has limitations that have to be considered in code intended
2831 to be portable.  See L<perlfork> for more details.
2832
2833 Portability issues: L<perlport/fork>.
2834
2835 =item format
2836 X<format>
2837
2838 =for Pod::Functions declare a picture format with use by the write() function
2839
2840 Declare a picture format for use by the L<C<write>|/write FILEHANDLE>
2841 function.  For example:
2842
2843     format Something =
2844         Test: @<<<<<<<< @||||| @>>>>>
2845               $str,     $%,    '$' . int($num)
2846     .
2847
2848     $str = "widget";
2849     $num = $cost/$quantity;
2850     $~ = 'Something';
2851     write;
2852
2853 See L<perlform> for many details and examples.
2854
2855 =item formline PICTURE,LIST
2856 X<formline>
2857
2858 =for Pod::Functions internal function used for formats
2859
2860 This is an internal function used by L<C<format>|/format>s, though you
2861 may call it, too.  It formats (see L<perlform>) a list of values
2862 according to the contents of PICTURE, placing the output into the format
2863 output accumulator, L<C<$^A>|perlvar/$^A> (or C<$ACCUMULATOR> in
2864 L<English>).  Eventually, when a L<C<write>|/write FILEHANDLE> is done,
2865 the contents of L<C<$^A>|perlvar/$^A> are written to some filehandle.
2866 You could also read L<C<$^A>|perlvar/$^A> and then set
2867 L<C<$^A>|perlvar/$^A> back to C<"">.  Note that a format typically does
2868 one L<C<formline>|/formline PICTURE,LIST> per line of form, but the
2869 L<C<formline>|/formline PICTURE,LIST> function itself doesn't care how
2870 many newlines are embedded in the PICTURE.  This means that the C<~> and
2871 C<~~> tokens treat the entire PICTURE as a single line.  You may
2872 therefore need to use multiple formlines to implement a single record
2873 format, just like the L<C<format>|/format> compiler.
2874
2875 Be careful if you put double quotes around the picture, because an C<@>
2876 character may be taken to mean the beginning of an array name.
2877 L<C<formline>|/formline PICTURE,LIST> always returns true.  See
2878 L<perlform> for other examples.
2879
2880 If you are trying to use this instead of L<C<write>|/write FILEHANDLE>
2881 to capture the output, you may find it easier to open a filehandle to a
2882 scalar (C<< open my $fh, ">", \$output >>) and write to that instead.
2883
2884 =item getc FILEHANDLE
2885 X<getc> X<getchar> X<character> X<file, read>
2886
2887 =item getc
2888
2889 =for Pod::Functions get the next character from the filehandle
2890
2891 Returns the next character from the input file attached to FILEHANDLE,
2892 or the undefined value at end of file or if there was an error (in
2893 the latter case L<C<$!>|perlvar/$!> is set).  If FILEHANDLE is omitted,
2894 reads from
2895 STDIN.  This is not particularly efficient.  However, it cannot be
2896 used by itself to fetch single characters without waiting for the user
2897 to hit enter.  For that, try something more like:
2898
2899     if ($BSD_STYLE) {
2900         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2901     }
2902     else {
2903         system "stty", '-icanon', 'eol', "\001";
2904     }
2905
2906     my $key = getc(STDIN);
2907
2908     if ($BSD_STYLE) {
2909         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2910     }
2911     else {
2912         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2913     }
2914     print "\n";
2915
2916 Determination of whether C<$BSD_STYLE> should be set is left as an
2917 exercise to the reader.
2918
2919 The L<C<POSIX::getattr>|POSIX/C<getattr>> function can do this more
2920 portably on systems purporting POSIX compliance.  See also the
2921 L<C<Term::ReadKey>|Term::ReadKey> module on CPAN.
2922
2923 =item getlogin
2924 X<getlogin> X<login>
2925
2926 =for Pod::Functions return who logged in at this tty
2927
2928 This implements the C library function of the same name, which on most
2929 systems returns the current login from F</etc/utmp>, if any.  If it
2930 returns the empty string, use L<C<getpwuid>|/getpwuid UID>.
2931
2932     my $login = getlogin || getpwuid($<) || "Kilroy";
2933
2934 Do not consider L<C<getlogin>|/getlogin> for authentication: it is not
2935 as secure as L<C<getpwuid>|/getpwuid UID>.
2936
2937 Portability issues: L<perlport/getlogin>.
2938
2939 =item getpeername SOCKET
2940 X<getpeername> X<peer>
2941
2942 =for Pod::Functions find the other end of a socket connection
2943
2944 Returns the packed sockaddr address of the other end of the SOCKET
2945 connection.
2946
2947     use Socket;
2948     my $hersockaddr    = getpeername($sock);
2949     my ($port, $iaddr) = sockaddr_in($hersockaddr);
2950     my $herhostname    = gethostbyaddr($iaddr, AF_INET);
2951     my $herstraddr     = inet_ntoa($iaddr);
2952
2953 =item getpgrp PID
2954 X<getpgrp> X<group>
2955
2956 =for Pod::Functions get process group
2957
2958 Returns the current process group for the specified PID.  Use
2959 a PID of C<0> to get the current process group for the
2960 current process.  Will raise an exception if used on a machine that
2961 doesn't implement L<getpgrp(2)>.  If PID is omitted, returns the process
2962 group of the current process.  Note that the POSIX version of
2963 L<C<getpgrp>|/getpgrp PID> does not accept a PID argument, so only
2964 C<PID==0> is truly portable.
2965
2966 Portability issues: L<perlport/getpgrp>.
2967
2968 =item getppid
2969 X<getppid> X<parent> X<pid>
2970
2971 =for Pod::Functions get parent process ID
2972
2973 Returns the process id of the parent process.
2974
2975 Note for Linux users: Between v5.8.1 and v5.16.0 Perl would work
2976 around non-POSIX thread semantics the minority of Linux systems (and
2977 Debian GNU/kFreeBSD systems) that used LinuxThreads, this emulation
2978 has since been removed.  See the documentation for L<$$|perlvar/$$> for
2979 details.
2980
2981 Portability issues: L<perlport/getppid>.
2982
2983 =item getpriority WHICH,WHO
2984 X<getpriority> X<priority> X<nice>
2985
2986 =for Pod::Functions get current nice value
2987
2988 Returns the current priority for a process, a process group, or a user.
2989 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2990 machine that doesn't implement L<getpriority(2)>.
2991
2992 C<WHICH> can be any of C<PRIO_PROCESS>, C<PRIO_PGRP> or C<PRIO_USER>
2993 imported from L<POSIX/RESOURCE CONSTANTS>.
2994
2995 Portability issues: L<perlport/getpriority>.
2996
2997 =item getpwnam NAME
2998 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2999 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
3000 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
3001 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
3002 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
3003 X<endnetent> X<endprotoent> X<endservent>
3004
3005 =for Pod::Functions get passwd record given user login name
3006
3007 =item getgrnam NAME
3008
3009 =for Pod::Functions get group record given group name
3010
3011 =item gethostbyname NAME
3012
3013 =for Pod::Functions get host record given name
3014
3015 =item getnetbyname NAME
3016
3017 =for Pod::Functions get networks record given name
3018
3019 =item getprotobyname NAME
3020
3021 =for Pod::Functions get protocol record given name
3022
3023 =item getpwuid UID
3024
3025 =for Pod::Functions get passwd record given user ID
3026
3027 =item getgrgid GID
3028
3029 =for Pod::Functions get group record given group user ID
3030
3031 =item getservbyname NAME,PROTO
3032
3033 =for Pod::Functions get services record given its name
3034
3035 =item gethostbyaddr ADDR,ADDRTYPE
3036
3037 =for Pod::Functions get host record given its address
3038
3039 =item getnetbyaddr ADDR,ADDRTYPE
3040
3041 =for Pod::Functions get network record given its address
3042
3043 =item getprotobynumber NUMBER
3044
3045 =for Pod::Functions get protocol record numeric protocol
3046
3047 =item getservbyport PORT,PROTO
3048
3049 =for Pod::Functions get services record given numeric port
3050
3051 =item getpwent
3052
3053 =for Pod::Functions get next passwd record
3054
3055 =item getgrent
3056
3057 =for Pod::Functions get next group record
3058
3059 =item gethostent
3060
3061 =for Pod::Functions get next hosts record
3062
3063 =item getnetent
3064
3065 =for Pod::Functions get next networks record
3066
3067 =item getprotoent
3068
3069 =for Pod::Functions get next protocols record
3070
3071 =item getservent
3072
3073 =for Pod::Functions get next services record
3074
3075 =item setpwent
3076
3077 =for Pod::Functions prepare passwd file for use
3078
3079 =item setgrent
3080
3081 =for Pod::Functions prepare group file for use
3082
3083 =item sethostent STAYOPEN
3084
3085 =for Pod::Functions prepare hosts file for use
3086
3087 =item setnetent STAYOPEN
3088
3089 =for Pod::Functions prepare networks file for use
3090
3091 =item setprotoent STAYOPEN
3092
3093 =for Pod::Functions prepare protocols file for use
3094
3095 =item setservent STAYOPEN
3096
3097 =for Pod::Functions prepare services file for use
3098
3099 =item endpwent
3100
3101 =for Pod::Functions be done using passwd file
3102
3103 =item endgrent
3104
3105 =for Pod::Functions be done using group file
3106
3107 =item endhostent
3108
3109 =for Pod::Functions be done using hosts file
3110
3111 =item endnetent
3112
3113 =for Pod::Functions be done using networks file
3114
3115 =item endprotoent
3116
3117 =for Pod::Functions be done using protocols file
3118
3119 =item endservent
3120
3121 =for Pod::Functions be done using services file
3122
3123 These routines are the same as their counterparts in the
3124 system C library.  In list context, the return values from the
3125 various get routines are as follows:
3126
3127  #    0        1          2           3         4
3128  my ( $name,   $passwd,   $gid,       $members  ) = getgr*
3129  my ( $name,   $aliases,  $addrtype,  $net      ) = getnet*
3130  my ( $name,   $aliases,  $port,      $proto    ) = getserv*
3131  my ( $name,   $aliases,  $proto                ) = getproto*
3132  my ( $name,   $aliases,  $addrtype,  $length,  @addrs ) = gethost*
3133  my ( $name,   $passwd,   $uid,       $gid,     $quota,
3134     $comment,  $gcos,     $dir,       $shell,   $expire ) = getpw*
3135  #    5        6          7           8         9
3136
3137 (If the entry doesn't exist, the return value is a single meaningless true
3138 value.)
3139
3140 The exact meaning of the $gcos field varies but it usually contains
3141 the real name of the user (as opposed to the login name) and other
3142 information pertaining to the user.  Beware, however, that in many
3143 system users are able to change this information and therefore it
3144 cannot be trusted and therefore the $gcos is tainted (see
3145 L<perlsec>).  The $passwd and $shell, user's encrypted password and
3146 login shell, are also tainted, for the same reason.
3147
3148 In scalar context, you get the name, unless the function was a
3149 lookup by name, in which case you get the other thing, whatever it is.
3150 (If the entry doesn't exist you get the undefined value.)  For example:
3151
3152     my $uid   = getpwnam($name);
3153     my $name  = getpwuid($num);
3154     my $name  = getpwent();
3155     my $gid   = getgrnam($name);
3156     my $name  = getgrgid($num);
3157     my $name  = getgrent();
3158     # etc.
3159
3160 In I<getpw*()> the fields $quota, $comment, and $expire are special
3161 in that they are unsupported on many systems.  If the
3162 $quota is unsupported, it is an empty scalar.  If it is supported, it
3163 usually encodes the disk quota.  If the $comment field is unsupported,
3164 it is an empty scalar.  If it is supported it usually encodes some
3165 administrative comment about the user.  In some systems the $quota
3166 field may be $change or $age, fields that have to do with password
3167 aging.  In some systems the $comment field may be $class.  The $expire
3168 field, if present, encodes the expiration period of the account or the
3169 password.  For the availability and the exact meaning of these fields
3170 in your system, please consult L<getpwnam(3)> and your system's
3171 F<pwd.h> file.  You can also find out from within Perl what your
3172 $quota and $comment fields mean and whether you have the $expire field
3173 by using the L<C<Config>|Config> module and the values C<d_pwquota>, C<d_pwage>,
3174 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
3175 files are supported only if your vendor has implemented them in the
3176 intuitive fashion that calling the regular C library routines gets the
3177 shadow versions if you're running under privilege or if there exists
3178 the L<shadow(3)> functions as found in System V (this includes Solaris
3179 and Linux).  Those systems that implement a proprietary shadow password
3180 facility are unlikely to be supported.
3181
3182 The $members value returned by I<getgr*()> is a space-separated list of
3183 the login names of the members of the group.
3184
3185 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
3186 C, it will be returned to you via L<C<$?>|perlvar/$?> if the function
3187 call fails.  The
3188 C<@addrs> value returned by a successful call is a list of raw
3189 addresses returned by the corresponding library call.  In the
3190 Internet domain, each address is four bytes long; you can unpack it
3191 by saying something like:
3192
3193     my ($w,$x,$y,$z) = unpack('W4',$addr[0]);
3194
3195 The Socket library makes this slightly easier:
3196
3197     use Socket;
3198     my $iaddr = inet_aton("127.1"); # or whatever address
3199     my $name  = gethostbyaddr($iaddr, AF_INET);
3200
3201     # or going the other way
3202     my $straddr = inet_ntoa($iaddr);
3203
3204 In the opposite way, to resolve a hostname to the IP address
3205 you can write this:
3206
3207     use Socket;
3208     my $packed_ip = gethostbyname("www.perl.org");
3209     my $ip_address;
3210     if (defined $packed_ip) {
3211         $ip_address = inet_ntoa($packed_ip);
3212     }
3213
3214 Make sure L<C<gethostbyname>|/gethostbyname NAME> is called in SCALAR
3215 context and that its return value is checked for definedness.
3216
3217 The L<C<getprotobynumber>|/getprotobynumber NUMBER> function, even
3218 though it only takes one argument, has the precedence of a list
3219 operator, so beware:
3220
3221     getprotobynumber $number eq 'icmp'   # WRONG
3222     getprotobynumber($number eq 'icmp')  # actually means this
3223     getprotobynumber($number) eq 'icmp'  # better this way
3224
3225 If you get tired of remembering which element of the return list
3226 contains which return value, by-name interfaces are provided in standard
3227 modules: L<C<File::stat>|File::stat>, L<C<Net::hostent>|Net::hostent>,
3228 L<C<Net::netent>|Net::netent>, L<C<Net::protoent>|Net::protoent>,
3229 L<C<Net::servent>|Net::servent>, L<C<Time::gmtime>|Time::gmtime>,
3230 L<C<Time::localtime>|Time::localtime>, and
3231 L<C<User::grent>|User::grent>.  These override the normal built-ins,
3232 supplying versions that return objects with the appropriate names for
3233 each field.  For example:
3234
3235    use File::stat;
3236    use User::pwent;
3237    my $is_his = (stat($filename)->uid == pwent($whoever)->uid);
3238
3239 Even though it looks as though they're the same method calls (uid),
3240 they aren't, because a C<File::stat> object is different from
3241 a C<User::pwent> object.
3242
3243 Many of these functions are not safe in a multi-threaded environment
3244 where more than one thread can be using them.  In particular, functions
3245 like C<getpwent()> iterate per-process and not per-thread, so if two
3246 threads are simultaneously iterating, neither will get all the records.
3247
3248 Some systems have thread-safe versions of some of the functions, such as
3249 C<getpwnam_r()> instead of C<getpwnam()>.  There, Perl automatically and
3250 invisibly substitutes the thread-safe version, without notice.  This
3251 means that code that safely runs on some systems can fail on others that
3252 lack the thread-safe versions.
3253
3254 Portability issues: L<perlport/getpwnam> to L<perlport/endservent>.
3255
3256 =item getsockname SOCKET
3257 X<getsockname>
3258
3259 =for Pod::Functions retrieve the sockaddr for a given socket
3260
3261 Returns the packed sockaddr address of this end of the SOCKET connection,
3262 in case you don't know the address because you have several different
3263 IPs that the connection might have come in on.
3264
3265     use Socket;
3266     my $mysockaddr = getsockname($sock);
3267     my ($port, $myaddr) = sockaddr_in($mysockaddr);
3268     printf "Connect to %s [%s]\n",
3269        scalar gethostbyaddr($myaddr, AF_INET),
3270        inet_ntoa($myaddr);
3271
3272 =item getsockopt SOCKET,LEVEL,OPTNAME
3273 X<getsockopt>
3274
3275 =for Pod::Functions get socket options on a given socket
3276
3277 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
3278 Options may exist at multiple protocol levels depending on the socket
3279 type, but at least the uppermost socket level SOL_SOCKET (defined in the
3280 L<C<Socket>|Socket> module) will exist.  To query options at another
3281 level the protocol number of the appropriate protocol controlling the
3282 option should be supplied.  For example, to indicate that an option is
3283 to be interpreted by the TCP protocol, LEVEL should be set to the
3284 protocol number of TCP, which you can get using
3285 L<C<getprotobyname>|/getprotobyname NAME>.
3286
3287 The function returns a packed string representing the requested socket
3288 option, or L<C<undef>|/undef EXPR> on error, with the reason for the
3289 error placed in L<C<$!>|perlvar/$!>.  Just what is in the packed string
3290 depends on LEVEL and OPTNAME; consult L<getsockopt(2)> for details.  A
3291 common case is that the option is an integer, in which case the result
3292 is a packed integer, which you can decode using
3293 L<C<unpack>|/unpack TEMPLATE,EXPR> with the C<i> (or C<I>) format.
3294
3295 Here's an example to test whether Nagle's algorithm is enabled on a socket:
3296
3297     use Socket qw(:all);
3298
3299     defined(my $tcp = getprotobyname("tcp"))
3300         or die "Could not determine the protocol number for tcp";
3301     # my $tcp = IPPROTO_TCP; # Alternative
3302     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
3303         or die "getsockopt TCP_NODELAY: $!";
3304     my $nodelay = unpack("I", $packed);
3305     print "Nagle's algorithm is turned ",
3306            $nodelay ? "off\n" : "on\n";
3307
3308 Portability issues: L<perlport/getsockopt>.
3309
3310 =item glob EXPR
3311 X<glob> X<wildcard> X<filename, expansion> X<expand>
3312
3313 =item glob
3314
3315 =for Pod::Functions expand filenames using wildcards
3316
3317 In list context, returns a (possibly empty) list of filename expansions on
3318 the value of EXPR such as the standard Unix shell F</bin/csh> would do.  In
3319 scalar context, glob iterates through such filename expansions, returning
3320 undef when the list is exhausted.  This is the internal function
3321 implementing the C<< <*.c> >> operator, but you can use it directly.  If
3322 EXPR is omitted, L<C<$_>|perlvar/$_> is used.  The C<< <*.c> >> operator
3323 is discussed in more detail in L<perlop/"I/O Operators">.
3324
3325 Note that L<C<glob>|/glob EXPR> splits its arguments on whitespace and
3326 treats
3327 each segment as separate pattern.  As such, C<glob("*.c *.h")>
3328 matches all files with a F<.c> or F<.h> extension.  The expression
3329 C<glob(".* *")> matches all files in the current working directory.
3330 If you want to glob filenames that might contain whitespace, you'll
3331 have to use extra quotes around the spacey filename to protect it.
3332 For example, to glob filenames that have an C<e> followed by a space
3333 followed by an C<f>, use one of:
3334
3335     my @spacies = <"*e f*">;
3336     my @spacies = glob '"*e f*"';
3337     my @spacies = glob q("*e f*");
3338
3339 If you had to get a variable through, you could do this:
3340
3341     my @spacies = glob "'*${var}e f*'";
3342     my @spacies = glob qq("*${var}e f*");
3343
3344 If non-empty braces are the only wildcard characters used in the
3345 L<C<glob>|/glob EXPR>, no filenames are matched, but potentially many
3346 strings are returned.  For example, this produces nine strings, one for
3347 each pairing of fruits and colors:
3348
3349     my @many = glob "{apple,tomato,cherry}={green,yellow,red}";
3350
3351 This operator is implemented using the standard C<File::Glob> extension.
3352 See L<File::Glob> for details, including
3353 L<C<bsd_glob>|File::Glob/C<bsd_glob>>, which does not treat whitespace
3354 as a pattern separator.
3355
3356 Portability issues: L<perlport/glob>.
3357
3358 =item gmtime EXPR
3359 X<gmtime> X<UTC> X<Greenwich>
3360
3361 =item gmtime
3362
3363 =for Pod::Functions convert UNIX time into record or string using Greenwich time
3364
3365 Works just like L<C<localtime>|/localtime EXPR> but the returned values
3366 are localized for the standard Greenwich time zone.
3367
3368 Note: When called in list context, $isdst, the last value
3369 returned by gmtime, is always C<0>.  There is no
3370 Daylight Saving Time in GMT.
3371
3372 Portability issues: L<perlport/gmtime>.
3373
3374 =item goto LABEL
3375 X<goto> X<jump> X<jmp>
3376
3377 =item goto EXPR
3378
3379 =item goto &NAME
3380
3381 =for Pod::Functions create spaghetti code
3382
3383 The C<goto LABEL> form finds the statement labeled with LABEL and
3384 resumes execution there.  It can't be used to get out of a block or
3385 subroutine given to L<C<sort>|/sort SUBNAME LIST>.  It can be used to go
3386 almost anywhere else within the dynamic scope, including out of
3387 subroutines, but it's usually better to use some other construct such as
3388 L<C<last>|/last LABEL> or L<C<die>|/die LIST>.  The author of Perl has
3389 never felt the need to use this form of L<C<goto>|/goto LABEL> (in Perl,
3390 that is; C is another matter).  (The difference is that C does not offer
3391 named loops combined with loop control.  Perl does, and this replaces
3392 most structured uses of L<C<goto>|/goto LABEL> in other languages.)
3393
3394 The C<goto EXPR> form expects to evaluate C<EXPR> to a code reference or
3395 a label name.  If it evaluates to a code reference, it will be handled
3396 like C<goto &NAME>, below.  This is especially useful for implementing
3397 tail recursion via C<goto __SUB__>.
3398
3399 If the expression evaluates to a label name, its scope will be resolved
3400 dynamically.  This allows for computed L<C<goto>|/goto LABEL>s per
3401 FORTRAN, but isn't necessarily recommended if you're optimizing for
3402 maintainability:
3403
3404     goto ("FOO", "BAR", "GLARCH")[$i];
3405
3406 As shown in this example, C<goto EXPR> is exempt from the "looks like a
3407 function" rule.  A pair of parentheses following it does not (necessarily)
3408 delimit its argument.  C<goto("NE")."XT"> is equivalent to C<goto NEXT>.
3409 Also, unlike most named operators, this has the same precedence as
3410 assignment.
3411
3412 Use of C<goto LABEL> or C<goto EXPR> to jump into a construct is
3413 deprecated and will issue a warning.  Even then, it may not be used to
3414 go into any construct that requires initialization, such as a
3415 subroutine, a C<foreach> loop, or a C<given>
3416 block.  It also can't be used to go into a
3417 construct that is optimized away.
3418
3419 The C<goto &NAME> form is quite different from the other forms of
3420 L<C<goto>|/goto LABEL>.  In fact, it isn't a goto in the normal sense at
3421 all, and doesn't have the stigma associated with other gotos.  Instead,
3422 it exits the current subroutine (losing any changes set by
3423 L<C<local>|/local EXPR>) and immediately calls in its place the named
3424 subroutine using the current value of L<C<@_>|perlvar/@_>.  This is used
3425 by C<AUTOLOAD> subroutines that wish to load another subroutine and then
3426 pretend that the other subroutine had been called in the first place
3427 (except that any modifications to L<C<@_>|perlvar/@_> in the current
3428 subroutine are propagated to the other subroutine.) After the
3429 L<C<goto>|/goto LABEL>, not even L<C<caller>|/caller EXPR> will be able
3430 to tell that this routine was called first.
3431
3432 NAME needn't be the name of a subroutine; it can be a scalar variable
3433 containing a code reference or a block that evaluates to a code
3434 reference.
3435
3436 =item grep BLOCK LIST
3437 X<grep>
3438
3439 =item grep EXPR,LIST
3440
3441 =for Pod::Functions locate elements in a list test true against a given criterion
3442
3443 This is similar in spirit to, but not the same as, L<grep(1)> and its
3444 relatives.  In particular, it is not limited to using regular expressions.
3445
3446 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
3447 L<C<$_>|perlvar/$_> to each element) and returns the list value
3448 consisting of those
3449 elements for which the expression evaluated to true.  In scalar
3450 context, returns the number of times the expression was true.
3451
3452     my @foo = grep(!/^#/, @bar);    # weed out comments
3453
3454 or equivalently,
3455
3456     my @foo = grep {!/^#/} @bar;    # weed out comments
3457
3458 Note that L<C<$_>|perlvar/$_> is an alias to the list value, so it can
3459 be used to
3460 modify the elements of the LIST.  While this is useful and supported,
3461 it can cause bizarre results if the elements of LIST are not variables.
3462 Similarly, grep returns aliases into the original list, much as a for
3463 loop's index variable aliases the list elements.  That is, modifying an
3464 element of a list returned by grep (for example, in a C<foreach>,
3465 L<C<map>|/map BLOCK LIST> or another L<C<grep>|/grep BLOCK LIST>)
3466 actually modifies the element in the original list.
3467 This is usually something to be avoided when writing clear code.
3468
3469 See also L<C<map>|/map BLOCK LIST> for a list composed of the results of
3470 the BLOCK or EXPR.
3471
3472 =item hex EXPR
3473 X<hex> X<hexadecimal>
3474
3475 =item hex
3476
3477 =for Pod::Functions convert a hexadecimal string to a number
3478
3479 Interprets EXPR as a hex string and returns the corresponding numeric value.
3480 If EXPR is omitted, uses L<C<$_>|perlvar/$_>.
3481
3482     print hex '0xAf'; # prints '175'
3483     print hex 'aF';   # same
3484     $valid_input =~ /\A(?:0?[xX])?(?:_?[0-9a-fA-F])*\z/
3485
3486 A hex string consists of hex digits and an optional C<0x> or C<x> prefix.
3487 Each hex digit may be preceded by a single underscore, which will be ignored.
3488 Any other character triggers a warning and causes the rest of the string
3489 to be ignored (even leading whitespace, unlike L<C<oct>|/oct EXPR>).
3490 Only integers can be represented, and integer overflow triggers a warning.
3491
3492 To convert strings that might start with any of C<0>, C<0x>, or C<0b>,
3493 see L<C<oct>|/oct EXPR>.  To present something as hex, look into
3494 L<C<printf>|/printf FILEHANDLE FORMAT, LIST>,
3495 L<C<sprintf>|/sprintf FORMAT, LIST>, and
3496 L<C<unpack>|/unpack TEMPLATE,EXPR>.
3497
3498 =item import LIST
3499 X<import>
3500
3501 =for Pod::Functions patch a module's namespace into your own
3502
3503 There is no builtin L<C<import>|/import LIST> function.  It is just an
3504 ordinary method (subroutine) defined (or inherited) by modules that wish
3505 to export names to another module.  The
3506 L<C<use>|/use Module VERSION LIST> function calls the
3507 L<C<import>|/import LIST> method for the package used.  See also
3508 L<C<use>|/use Module VERSION LIST>, L<perlmod>, and L<Exporter>.
3509
3510 =item index STR,SUBSTR,POSITION
3511 X<index> X<indexOf> X<InStr>
3512
3513 =item index STR,SUBSTR
3514
3515 =for Pod::Functions find a substring within a string
3516
3517 The index function searches for one string within another, but without
3518 the wildcard-like behavior of a full regular-expression pattern match.
3519 It returns the position of the first occurrence of SUBSTR in STR at
3520 or after POSITION.  If POSITION is omitted, starts searching from the
3521 beginning of the string.  POSITION before the beginning of the string
3522 or after its end is treated as if it were the beginning or the end,
3523 respectively.  POSITION and the return value are based at zero.
3524 If the substring is not found, L<C<index>|/index STR,SUBSTR,POSITION>
3525 returns -1.
3526
3527 =item int EXPR
3528 X<int> X<integer> X<truncate> X<trunc> X<floor>
3529
3530 =item int
3531
3532 =for Pod::Functions get the integer portion of a number
3533
3534 Returns the integer portion of EXPR.  If EXPR is omitted, uses
3535 L<C<$_>|perlvar/$_>.
3536 You should not use this function for rounding: one because it truncates
3537 towards C<0>, and two because machine representations of floating-point
3538 numbers can sometimes produce counterintuitive results.  For example,
3539 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
3540 because it's really more like -268.99999999999994315658 instead.  Usually,
3541 the L<C<sprintf>|/sprintf FORMAT, LIST>,
3542 L<C<printf>|/printf FILEHANDLE FORMAT, LIST>, or the
3543 L<C<POSIX::floor>|POSIX/C<floor>> and L<C<POSIX::ceil>|POSIX/C<ceil>>
3544 functions will serve you better than will L<C<int>|/int EXPR>.
3545
3546 =item ioctl FILEHANDLE,FUNCTION,SCALAR
3547 X<ioctl>
3548
3549 =for Pod::Functions system-dependent device control system call
3550
3551 Implements the L<ioctl(2)> function.  You'll probably first have to say
3552
3553     require "sys/ioctl.ph";  # probably in
3554                              # $Config{archlib}/sys/ioctl.ph
3555
3556 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
3557 exist or doesn't have the correct definitions you'll have to roll your
3558 own, based on your C header files such as F<< <sys/ioctl.h> >>.
3559 (There is a Perl script called B<h2ph> that comes with the Perl kit that
3560 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
3561 written depending on the FUNCTION; a C pointer to the string value of SCALAR
3562 will be passed as the third argument of the actual
3563 L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR> call.  (If SCALAR
3564 has no string value but does have a numeric value, that value will be
3565 passed rather than a pointer to the string value.  To guarantee this to be
3566 true, add a C<0> to the scalar before using it.)  The
3567 L<C<pack>|/pack TEMPLATE,LIST> and L<C<unpack>|/unpack TEMPLATE,EXPR>
3568 functions may be needed to manipulate the values of structures used by
3569 L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR>.
3570
3571 The return value of L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR> (and
3572 L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR>) is as follows:
3573
3574     if OS returns:      then Perl returns:
3575         -1               undefined value
3576          0              string "0 but true"
3577     anything else           that number
3578
3579 Thus Perl returns true on success and false on failure, yet you can
3580 still easily determine the actual value returned by the operating
3581 system:
3582
3583     my $retval = ioctl(...) || -1;
3584     printf "System returned %d\n", $retval;
3585
3586 The special string C<"0 but true"> is exempt from
3587 L<C<Argument "..." isn't numeric>|perldiag/Argument "%s" isn't numeric%s>
3588 L<warnings> on improper numeric conversions.
3589
3590 Portability issues: L<perlport/ioctl>.
3591
3592 =item join EXPR,LIST
3593 X<join>
3594
3595 =for Pod::Functions join a list into a string using a separator
3596
3597 Joins the separate strings of LIST into a single string with fields
3598 separated by the value of EXPR, and returns that new string.  Example:
3599
3600    my $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
3601
3602 Beware that unlike L<C<split>|/split E<sol>PATTERNE<sol>,EXPR,LIMIT>,
3603 L<C<join>|/join EXPR,LIST> doesn't take a pattern as its first argument.
3604 Compare L<C<split>|/split E<sol>PATTERNE<sol>,EXPR,LIMIT>.
3605
3606 =item keys HASH
3607 X<keys> X<key>
3608
3609 =item keys ARRAY
3610
3611 =for Pod::Functions retrieve list of indices from a hash
3612
3613 Called in list context, returns a list consisting of all the keys of the
3614 named hash, or in Perl 5.12 or later only, the indices of an array.  Perl
3615 releases prior to 5.12 will produce a syntax error if you try to use an
3616 array argument.  In scalar context, returns the number of keys or indices.
3617
3618 Hash entries are returned in an apparently random order.  The actual random
3619 order is specific to a given hash; the exact same series of operations
3620 on two hashes may result in a different order for each hash.  Any insertion
3621 into the hash may change the order, as will any deletion, with the exception
3622 that the most recent key returned by L<C<each>|/each HASH> or
3623 L<C<keys>|/keys HASH> may be deleted without changing the order.  So
3624 long as a given hash is unmodified you may rely on
3625 L<C<keys>|/keys HASH>, L<C<values>|/values HASH> and L<C<each>|/each
3626 HASH> to repeatedly return the same order
3627 as each other.  See L<perlsec/"Algorithmic Complexity Attacks"> for
3628 details on why hash order is randomized.  Aside from the guarantees
3629 provided here the exact details of Perl's hash algorithm and the hash
3630 traversal order are subject to change in any release of Perl.  Tied hashes
3631 may behave differently to Perl's hashes with respect to changes in order on
3632 insertion and deletion of items.
3633
3634 As a side effect, calling L<C<keys>|/keys HASH> resets the internal
3635 iterator of the HASH or ARRAY (see L<C<each>|/each HASH>).  In
3636 particular, calling L<C<keys>|/keys HASH> in void context resets the
3637 iterator with no other overhead.
3638
3639 Here is yet another way to print your environment:
3640
3641     my @keys = keys %ENV;
3642     my @values = values %ENV;
3643     while (@keys) {
3644         print pop(@keys), '=', pop(@values), "\n";
3645     }
3646
3647 or how about sorted by key:
3648
3649     foreach my $key (sort(keys %ENV)) {
3650         print $key, '=', $ENV{$key}, "\n";
3651     }
3652
3653 The returned values are copies of the original keys in the hash, so
3654 modifying them will not affect the original hash.  Compare
3655 L<C<values>|/values HASH>.
3656
3657 To sort a hash by value, you'll need to use a
3658 L<C<sort>|/sort SUBNAME LIST> function.  Here's a descending numeric
3659 sort of a hash by its values:
3660
3661     foreach my $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
3662         printf "%4d %s\n", $hash{$key}, $key;
3663     }
3664
3665 Used as an lvalue, L<C<keys>|/keys HASH> allows you to increase the
3666 number of hash buckets
3667 allocated for the given hash.  This can gain you a measure of efficiency if
3668 you know the hash is going to get big.  (This is similar to pre-extending
3669 an array by assigning a larger number to $#array.)  If you say
3670
3671     keys %hash = 200;
3672
3673 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
3674 in fact, since it rounds up to the next power of two.  These
3675 buckets will be retained even if you do C<%hash = ()>, use C<undef
3676 %hash> if you want to free the storage while C<%hash> is still in scope.
3677 You can't shrink the number of buckets allocated for the hash using
3678 L<C<keys>|/keys HASH> in this way (but you needn't worry about doing
3679 this by accident, as trying has no effect).  C<keys @array> in an lvalue
3680 context is a syntax error.
3681
3682 Starting with Perl 5.14, an experimental feature allowed
3683 L<C<keys>|/keys HASH> to take a scalar expression. This experiment has
3684 been deemed unsuccessful, and was removed as of Perl 5.24.
3685
3686 To avoid confusing would-be users of your code who are running earlier
3687 versions of Perl with mysterious syntax errors, put this sort of thing at
3688 the top of your file to signal that your code will work I<only> on Perls of
3689 a recent vintage:
3690
3691     use 5.012;  # so keys/values/each work on arrays
3692
3693 See also L<C<each>|/each HASH>, L<C<values>|/values HASH>, and
3694 L<C<sort>|/sort SUBNAME LIST>.
3695
3696 =item kill SIGNAL, LIST
3697
3698 =item kill SIGNAL
3699 X<kill> X<signal>
3700
3701 =for Pod::Functions send a signal to a process or process group
3702
3703 Sends a signal to a list of processes.  Returns the number of arguments
3704 that were successfully used to signal (which is not necessarily the same
3705 as the number of processes actually killed, e.g. where a process group is
3706 killed).
3707
3708     my $cnt = kill 'HUP', $child1, $child2;
3709     kill 'KILL', @goners;
3710
3711 SIGNAL may be either a signal name (a string) or a signal number.  A signal
3712 name may start with a C<SIG> prefix, thus C<FOO> and C<SIGFOO> refer to the
3713 same signal.  The string form of SIGNAL is recommended for portability because
3714 the same signal may have different numbers in different operating systems.
3715
3716 A list of signal names supported by the current platform can be found in
3717 C<$Config{sig_name}>, which is provided by the L<C<Config>|Config>
3718 module.  See L<Config> for more details.
3719
3720 A negative signal name is the same as a negative signal number, killing process
3721 groups instead of processes.  For example, C<kill '-KILL', $pgrp> and
3722 C<kill -9, $pgrp> will send C<SIGKILL> to
3723 the entire process group specified.  That
3724 means you usually want to use positive not negative signals.
3725
3726 If SIGNAL is either the number 0 or the string C<ZERO> (or C<SIGZERO>),
3727 no signal is sent to the process, but L<C<kill>|/kill SIGNAL, LIST>
3728 checks whether it's I<possible> to send a signal to it
3729 (that means, to be brief, that the process is owned by the same user, or we are
3730 the super-user).  This is useful to check that a child process is still
3731 alive (even if only as a zombie) and hasn't changed its UID.  See
3732 L<perlport> for notes on the portability of this construct.
3733
3734 The behavior of kill when a I<PROCESS> number is zero or negative depends on
3735 the operating system.  For example, on POSIX-conforming systems, zero will
3736 signal the current process group, -1 will signal all processes, and any
3737 other negative PROCESS number will act as a negative signal number and
3738 kill the entire process group specified.
3739
3740 If both the SIGNAL and the PROCESS are negative, the results are undefined.
3741 A warning may be produced in a future version.
3742
3743 See L<perlipc/"Signals"> for more details.
3744
3745 On some platforms such as Windows where the L<fork(2)> system call is not
3746 available, Perl can be built to emulate L<C<fork>|/fork> at the
3747 interpreter level.
3748 This emulation has limitations related to kill that have to be considered,
3749 for code running on Windows and in code intended to be portable.
3750
3751 See L<perlfork> for more details.
3752
3753 If there is no I<LIST> of processes, no signal is sent, and the return
3754 value is 0.  This form is sometimes used, however, because it causes
3755 tainting checks to be run.  But see
3756 L<perlsec/Laundering and Detecting Tainted Data>.
3757
3758 Portability issues: L<perlport/kill>.
3759
3760 =item last LABEL
3761 X<last> X<break>
3762
3763 =item last EXPR
3764
3765 =item last
3766
3767 =for Pod::Functions exit a block prematurely
3768
3769 The L<C<last>|/last LABEL> command is like the C<break> statement in C
3770 (as used in
3771 loops); it immediately exits the loop in question.  If the LABEL is
3772 omitted, the command refers to the innermost enclosing
3773 loop.  The C<last EXPR> form, available starting in Perl
3774 5.18.0, allows a label name to be computed at run time,
3775 and is otherwise identical to C<last LABEL>.  The
3776 L<C<continue>|/continue BLOCK> block, if any, is not executed:
3777
3778     LINE: while (<STDIN>) {
3779         last LINE if /^$/;  # exit when done with header
3780         #...
3781     }
3782
3783 L<C<last>|/last LABEL> cannot be used to exit a block that returns a
3784 value such as C<eval {}>, C<sub {}>, or C<do {}>, and should not be used
3785 to exit a L<C<grep>|/grep BLOCK LIST> or L<C<map>|/map BLOCK LIST>
3786 operation.
3787
3788 Note that a block by itself is semantically identical to a loop
3789 that executes once.  Thus L<C<last>|/last LABEL> can be used to effect
3790 an early exit out of such a block.
3791
3792 See also L<C<continue>|/continue BLOCK> for an illustration of how
3793 L<C<last>|/last LABEL>, L<C<next>|/next LABEL>, and
3794 L<C<redo>|/redo LABEL> work.
3795
3796 Unlike most named operators, this has the same precedence as assignment.
3797 It is also exempt from the looks-like-a-function rule, so
3798 C<last ("foo")."bar"> will cause "bar" to be part of the argument to
3799 L<C<last>|/last LABEL>.
3800
3801 =item lc EXPR
3802 X<lc> X<lowercase>
3803
3804 =item lc
3805
3806 =for Pod::Functions return lower-case version of a string
3807
3808 Returns a lowercased version of EXPR.  This is the internal function
3809 implementing the C<\L> escape in double-quoted strings.
3810
3811 If EXPR is omitted, uses L<C<$_>|perlvar/$_>.
3812
3813 What gets returned depends on several factors:
3814
3815 =over
3816
3817 =item If C<use bytes> is in effect:
3818
3819 The results follow ASCII rules.  Only the characters C<A-Z> change,
3820 to C<a-z> respectively.
3821
3822 =item Otherwise, if C<use locale> for C<LC_CTYPE> is in effect:
3823
3824 Respects current C<LC_CTYPE> locale for code points < 256; and uses Unicode
3825 rules for the remaining code points (this last can only happen if
3826 the UTF8 flag is also set).  See L<perllocale>.
3827
3828 Starting in v5.20, Perl uses full Unicode rules if the locale is
3829 UTF-8.  Otherwise, there is a deficiency in this scheme, which is that
3830 case changes that cross the 255/256
3831 boundary are not well-defined.  For example, the lower case of LATIN CAPITAL
3832 LETTER SHARP S (U+1E9E) in Unicode rules is U+00DF (on ASCII
3833 platforms).   But under C<use locale> (prior to v5.20 or not a UTF-8
3834 locale), the lower case of U+1E9E is
3835 itself, because 0xDF may not be LATIN SMALL LETTER SHARP S in the
3836 current locale, and Perl has no way of knowing if that character even
3837 exists in the locale, much less what code point it is.  Perl returns
3838 a result that is above 255 (almost always the input character unchanged),
3839 for all instances (and there aren't many) where the 255/256 boundary
3840 would otherwise be crossed; and starting in v5.22, it raises a
3841 L<locale|perldiag/Can't do %s("%s") on non-UTF-8 locale; resolved to "%s".> warning.
3842
3843 =item Otherwise, If EXPR has the UTF8 flag set:
3844
3845 Unicode rules are used for the case change.
3846
3847 =item Otherwise, if C<use feature 'unicode_strings'> or C<use locale ':not_characters'> is in effect:
3848
3849 Unicode rules are used for the case change.
3850
3851 =item Otherwise:
3852
3853 ASCII rules are used for the case change.  The lowercase of any character
3854 outside the ASCII range is the character itself.
3855
3856 =back
3857
3858 =item lcfirst EXPR
3859 X<lcfirst> X<lowercase>
3860
3861 =item lcfirst
3862
3863 =for Pod::Functions return a string with just the next letter in lower case
3864
3865 Returns the value of EXPR with the first character lowercased.  This
3866 is the internal function implementing the C<\l> escape in
3867 double-quoted strings.
3868
3869 If EXPR is omitted, uses L<C<$_>|perlvar/$_>.
3870
3871 This function behaves the same way under various pragmas, such as in a locale,
3872 as L<C<lc>|/lc EXPR> does.
3873
3874 =item length EXPR
3875 X<length> X<size>
3876
3877 =item length
3878
3879 =for Pod::Functions return the number of characters in a string
3880
3881 Returns the length in I<characters> of the value of EXPR.  If EXPR is
3882 omitted, returns the length of L<C<$_>|perlvar/$_>.  If EXPR is
3883 undefined, returns L<C<undef>|/undef EXPR>.
3884
3885 This function cannot be used on an entire array or hash to find out how
3886 many elements these have.  For that, use C<scalar @array> and C<scalar keys
3887 %hash>, respectively.
3888
3889 Like all Perl character operations, L<C<length>|/length EXPR> normally
3890 deals in logical
3891 characters, not physical bytes.  For how many bytes a string encoded as
3892 UTF-8 would take up, use C<length(Encode::encode('UTF-8', EXPR))>
3893 (you'll have to C<use Encode> first).  See L<Encode> and L<perlunicode>.
3894
3895 =item __LINE__
3896 X<__LINE__>
3897
3898 =for Pod::Functions the current source line number
3899
3900 A special token that compiles to the current line number.
3901
3902 =item link OLDFILE,NEWFILE
3903 X<link>
3904
3905 =for Pod::Functions create a hard link in the filesystem
3906
3907 Creates a new filename linked to the old filename.  Returns true for
3908 success, false otherwise.
3909
3910 Portability issues: L<perlport/link>.
3911
3912 =item listen SOCKET,QUEUESIZE
3913 X<listen>
3914
3915 =for Pod::Functions register your socket as a server
3916
3917 Does the same thing that the L<listen(2)> system call does.  Returns true if
3918 it succeeded, false otherwise.  See the example in
3919 L<perlipc/"Sockets: Client/Server Communication">.
3920
3921 =item local EXPR
3922 X<local>
3923
3924 =for Pod::Functions create a temporary value for a global variable (dynamic scoping)
3925
3926 You really probably want to be using L<C<my>|/my VARLIST> instead,
3927 because L<C<local>|/local EXPR> isn't what most people think of as
3928 "local".  See L<perlsub/"Private Variables via my()"> for details.
3929
3930 A local modifies the listed variables to be local to the enclosing
3931 block, file, or eval.  If more than one value is listed, the list must
3932 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
3933 for details, including issues with tied arrays and hashes.
3934
3935 The C<delete local EXPR> construct can also be used to localize the deletion
3936 of array/hash elements to the current block.
3937 See L<perlsub/"Localized deletion of elements of composite types">.
3938
3939 =item localtime EXPR
3940 X<localtime> X<ctime>
3941
3942 =item localtime
3943
3944 =for Pod::Functions convert UNIX time into record or string using local time
3945
3946 Converts a time as returned by the time function to a 9-element list
3947 with the time analyzed for the local time zone.  Typically used as
3948 follows:
3949
3950     #     0    1    2     3     4    5     6     7     8
3951     my ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
3952                                                 localtime(time);
3953
3954 All list elements are numeric and come straight out of the C `struct
3955 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
3956 of the specified time.
3957
3958 C<$mday> is the day of the month and C<$mon> the month in
3959 the range C<0..11>, with 0 indicating January and 11 indicating December.
3960 This makes it easy to get a month name from a list:
3961
3962     my @abbr = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
3963     print "$abbr[$mon] $mday";
3964     # $mon=9, $mday=18 gives "Oct 18"
3965
3966 C<$year> contains the number of years since 1900.  To get a 4-digit
3967 year write:
3968
3969     $year += 1900;
3970
3971 To get the last two digits of the year (e.g., "01" in 2001) do:
3972
3973     $year = sprintf("%02d", $year % 100);
3974
3975 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
3976 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
3977 (or C<0..365> in leap years.)
3978
3979 C<$isdst> is true if the specified time occurs during Daylight Saving
3980 Time, false otherwise.
3981
3982 If EXPR is omitted, L<C<localtime>|/localtime EXPR> uses the current
3983 time (as returned by L<C<time>|/time>).
3984
3985 In scalar context, L<C<localtime>|/localtime EXPR> returns the
3986 L<ctime(3)> value:
3987
3988     my $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
3989
3990 The format of this scalar value is B<not> locale-dependent but built
3991 into Perl.  For GMT instead of local time use the
3992 L<C<gmtime>|/gmtime EXPR> builtin.  See also the
3993 L<C<Time::Local>|Time::Local> module (for converting seconds, minutes,
3994 hours, and such back to the integer value returned by L<C<time>|/time>),
3995 and the L<POSIX> module's L<C<strftime>|POSIX/C<strftime>> and
3996 L<C<mktime>|POSIX/C<mktime>> functions.
3997
3998 To get somewhat similar but locale-dependent date strings, set up your
3999 locale environment variables appropriately (please see L<perllocale>) and
4000 try for example:
4001
4002     use POSIX qw(strftime);
4003     my $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
4004     # or for GMT formatted appropriately for your locale:
4005     my $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
4006
4007 Note that C<%a> and C<%b>, the short forms of the day of the week
4008 and the month of the year, may not necessarily be three characters wide.
4009
4010 The L<Time::gmtime> and L<Time::localtime> modules provide a convenient,
4011 by-name access mechanism to the L<C<gmtime>|/gmtime EXPR> and
4012 L<C<localtime>|/localtime EXPR> functions, respectively.
4013
4014 For a comprehensive date and time representation look at the
4015 L<DateTime> module on CPAN.
4016
4017 Portability issues: L<perlport/localtime>.
4018
4019 =item lock THING
4020 X<lock>
4021
4022 =for Pod::Functions +5.005 get a thread lock on a variable, subroutine, or method
4023
4024 This function places an advisory lock on a shared variable or referenced
4025 object contained in I<THING> until the lock goes out of scope.
4026
4027 The value returned is the scalar itself, if the argument is a scalar, or a
4028 reference, if the argument is a hash, array or subroutine.
4029
4030 L<C<lock>|/lock THING> is a "weak keyword"; this means that if you've
4031 defined a function
4032 by this name (before any calls to it), that function will be called
4033 instead.  If you are not under C<use threads::shared> this does nothing.
4034 See L<threads::shared>.
4035
4036 =item log EXPR
4037 X<log> X<logarithm> X<e> X<ln> X<base>
4038
4039 =item log
4040
4041 =for Pod::Functions retrieve the natural logarithm for a number
4042
4043 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
4044 returns the log of L<C<$_>|perlvar/$_>.  To get the
4045 log of another base, use basic algebra:
4046 The base-N log of a number is equal to the natural log of that number
4047 divided by the natural log of N.  For example:
4048
4049     sub log10 {
4050         my $n = shift;
4051         return log($n)/log(10);
4052     }
4053
4054 See also L<C<exp>|/exp EXPR> for the inverse operation.
4055
4056 =item lstat FILEHANDLE
4057 X<lstat>
4058
4059 =item lstat EXPR
4060
4061 =item lstat DIRHANDLE
4062
4063 =item lstat
4064
4065 =for Pod::Functions stat a symbolic link
4066
4067 Does the same thing as the L<C<stat>|/stat FILEHANDLE> function
4068 (including setting the special C<_> filehandle) but stats a symbolic
4069 link instead of the file the symbolic link points to.  If symbolic links
4070 are unimplemented on your system, a normal L<C<stat>|/stat FILEHANDLE>
4071 is done.  For much more detailed information, please see the
4072 documentation for L<C<stat>|/stat FILEHANDLE>.
4073
4074 If EXPR is omitted, stats L<C<$_>|perlvar/$_>.
4075
4076 Portability issues: L<perlport/lstat>.
4077
4078 =item m//
4079
4080 =for Pod::Functions match a string with a regular expression pattern
4081
4082 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
4083
4084 =item map BLOCK LIST
4085 X<map>
4086
4087 =item map EXPR,LIST
4088
4089 =for Pod::Functions apply a change to a list to get back a new list with the changes
4090
4091 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
4092 L<C<$_>|perlvar/$_> to each element) and composes a list of the results of
4093 each such evaluation.  Each element of LIST may produce zero, one, or more
4094 elements in the generated list, so the number of elements in the generated
4095 list may differ from that in LIST.  In scalar context, returns the total
4096 number of elements so generated.  In list context, returns the generated list.
4097
4098     my @chars = map(chr, @numbers);
4099
4100 translates a list of numbers to the corresponding characters.
4101
4102     my @squares = map { $_ * $_ } @numbers;
4103
4104 translates a list of numbers to their squared values.
4105
4106     my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;
4107
4108 shows that number of returned elements can differ from the number of
4109 input elements.  To omit an element, return an empty list ().
4110 This could also be achieved by writing
4111
4112     my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;
4113
4114 which makes the intention more clear.
4115
4116 Map always returns a list, which can be
4117 assigned to a hash such that the elements
4118 become key/value pairs.  See L<perldata> for more details.
4119
4120     my %hash = map { get_a_key_for($_) => $_ } @array;
4121
4122 is just a funny way to write
4123
4124     my %hash;
4125     foreach (@array) {
4126         $hash{get_a_key_for($_)} = $_;
4127     }
4128
4129 Note that L<C<$_>|perlvar/$_> is an alias to the list value, so it can
4130 be used to modify the elements of the LIST.  While this is useful and
4131 supported, it can cause bizarre results if the elements of LIST are not
4132 variables.  Using a regular C<foreach> loop for this purpose would be
4133 clearer in most cases.  See also L<C<grep>|/grep BLOCK LIST> for a
4134 list composed of those items of the original list for which the BLOCK
4135 or EXPR evaluates to true.
4136
4137 C<{> starts both hash references and blocks, so C<map { ...> could be either
4138 the start of map BLOCK LIST or map EXPR, LIST.  Because Perl doesn't look
4139 ahead for the closing C<}> it has to take a guess at which it's dealing with
4140 based on what it finds just after the
4141 C<{>.  Usually it gets it right, but if it
4142 doesn't it won't realize something is wrong until it gets to the C<}> and
4143 encounters the missing (or unexpected) comma.  The syntax error will be
4144 reported close to the C<}>, but you'll need to change something near the C<{>
4145 such as using a unary C<+> or semicolon to give Perl some help:
4146
4147  my %hash = map {  "\L$_" => 1  } @array # perl guesses EXPR. wrong
4148  my %hash = map { +"\L$_" => 1  } @array # perl guesses BLOCK. right
4149  my %hash = map {; "\L$_" => 1  } @array # this also works
4150  my %hash = map { ("\L$_" => 1) } @array # as does this
4151  my %hash = map {  lc($_) => 1  } @array # and this.
4152  my %hash = map +( lc($_) => 1 ), @array # this is EXPR and works!
4153
4154  my %hash = map  ( lc($_), 1 ),   @array # evaluates to (1, @array)
4155
4156 or to force an anon hash constructor use C<+{>:
4157
4158     my @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs
4159                                               # comma at end
4160
4161 to get a list of anonymous hashes each with only one entry apiece.
4162
4163 =item mkdir FILENAME,MODE
4164 X<mkdir> X<md> X<directory, create>
4165
4166 =item mkdir FILENAME
4167
4168 =item mkdir
4169
4170 =for Pod::Functions create a directory
4171
4172 Creates the directory specified by FILENAME, with permissions
4173 specified by MODE (as modified by L<C<umask>|/umask EXPR>).  If it
4174 succeeds it returns true; otherwise it returns false and sets
4175 L<C<$!>|perlvar/$!> (errno).
4176 MODE defaults to 0777 if omitted, and FILENAME defaults
4177 to L<C<$_>|perlvar/$_> if omitted.
4178
4179 In general, it is better to create directories with a permissive MODE
4180 and let the user modify that with their L<C<umask>|/umask EXPR> than it
4181 is to supply
4182 a restrictive MODE and give the user no way to be more permissive.
4183 The exceptions to this rule are when the file or directory should be
4184 kept private (mail files, for instance).  The documentation for
4185 L<C<umask>|/umask EXPR> discusses the choice of MODE in more detail.
4186
4187 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
4188 number of trailing slashes.  Some operating and filesystems do not get
4189 this right, so Perl automatically removes all trailing slashes to keep
4190 everyone happy.
4191
4192 To recursively create a directory structure, look at
4193 the L<C<make_path>|File::Path/make_path( $dir1, $dir2, .... )> function
4194 of the L<File::Path> module.
4195
4196 =item msgctl ID,CMD,ARG
4197 X<msgctl>
4198
4199 =for Pod::Functions SysV IPC message control operations
4200
4201 Calls the System V IPC function L<msgctl(2)>.  You'll probably have to say
4202
4203     use IPC::SysV;
4204
4205 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
4206 then ARG must be a variable that will hold the returned C<msqid_ds>
4207 structure.  Returns like L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR>:
4208 the undefined value for error, C<"0 but true"> for zero, or the actual
4209 return value otherwise.  See also L<perlipc/"SysV IPC"> and the
4210 documentation for L<C<IPC::SysV>|IPC::SysV> and
4211 L<C<IPC::Semaphore>|IPC::Semaphore>.
4212
4213 Portability issues: L<perlport/msgctl>.
4214
4215 =item msgget KEY,FLAGS
4216 X<msgget>
4217
4218 =for Pod::Functions get SysV IPC message queue
4219
4220 Calls the System V IPC function L<msgget(2)>.  Returns the message queue
4221 id, or L<C<undef>|/undef EXPR> on error.  See also L<perlipc/"SysV IPC">
4222 and the documentation for L<C<IPC::SysV>|IPC::SysV> and
4223 L<C<IPC::Msg>|IPC::Msg>.
4224
4225 Portability issues: L<perlport/msgget>.
4226
4227 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
4228 X<msgrcv>
4229
4230 =for Pod::Functions receive a SysV IPC message from a message queue
4231
4232 Calls the System V IPC function msgrcv to receive a message from
4233 message queue ID into variable VAR with a maximum message size of
4234 SIZE.  Note that when a message is received, the message type as a
4235 native long integer will be the first thing in VAR, followed by the
4236 actual message.  This packing may be opened with C<unpack("l! a*")>.
4237 Taints the variable.  Returns true if successful, false
4238 on error.  See also L<perlipc/"SysV IPC"> and the documentation for
4239 L<C<IPC::SysV>|IPC::SysV> and L<C<IPC::Msg>|IPC::Msg>.
4240
4241 Portability issues: L<perlport/msgrcv>.
4242
4243 =item msgsnd ID,MSG,FLAGS
4244 X<msgsnd>
4245
4246 =for Pod::Functions send a SysV IPC message to a message queue
4247
4248 Calls the System V IPC function msgsnd to send the message MSG to the
4249 message queue ID.  MSG must begin with the native long integer message
4250 type, be followed by the length of the actual message, and then finally
4251 the message itself.  This kind of packing can be achieved with
4252 C<pack("l! a*", $type, $message)>.  Returns true if successful,
4253 false on error.  See also L<perlipc/"SysV IPC"> and the documentation
4254 for L<C<IPC::SysV>|IPC::SysV> and L<C<IPC::Msg>|IPC::Msg>.
4255
4256 Portability issues: L<perlport/msgsnd>.
4257
4258 =item my VARLIST
4259 X<my>
4260
4261 =item my TYPE VARLIST
4262
4263 =item my VARLIST : ATTRS
4264
4265 =item my TYPE VARLIST : ATTRS
4266
4267 =for Pod::Functions declare and assign a local variable (lexical scoping)
4268
4269 A L<C<my>|/my VARLIST> declares the listed variables to be local
4270 (lexically) to the enclosing block, file, or L<C<eval>|/eval EXPR>.  If
4271 more than one variable is listed, the list must be placed in
4272 parentheses.
4273
4274 The exact semantics and interface of TYPE and ATTRS are still
4275 evolving.  TYPE may be a bareword, a constant declared
4276 with L<C<use constant>|constant>, or L<C<__PACKAGE__>|/__PACKAGE__>.  It
4277 is
4278 currently bound to the use of the L<fields> pragma,
4279 and attributes are handled using the L<attributes> pragma, or starting
4280 from Perl 5.8.0 also via the L<Attribute::Handlers> module.  See
4281 L<perlsub/"Private Variables via my()"> for details.
4282
4283 Note that with a parenthesised list, L<C<undef>|/undef EXPR> can be used
4284 as a dummy placeholder, for example to skip assignment of initial
4285 values:
4286
4287     my ( undef, $min, $hour ) = localtime;
4288
4289 =item next LABEL
4290 X<next> X<continue>
4291
4292 =item next EXPR
4293
4294 =item next
4295
4296 =for Pod::Functions iterate a block prematurely
4297
4298 The L<C<next>|/next LABEL> command is like the C<continue> statement in
4299 C; it starts the next iteration of the loop:
4300
4301     LINE: while (<STDIN>) {
4302         next LINE if /^#/;  # discard comments
4303         #...
4304     }
4305
4306 Note that if there were a L<C<continue>|/continue BLOCK> block on the
4307 above, it would get
4308 executed even on discarded lines.  If LABEL is omitted, the command
4309 refers to the innermost enclosing loop.  The C<next EXPR> form, available
4310 as of Perl 5.18.0, allows a label name to be computed at run time, being
4311 otherwise identical to C<next LABEL>.
4312
4313 L<C<next>|/next LABEL> cannot be used to exit a block which returns a
4314 value such as C<eval {}>, C<sub {}>, or C<do {}>, and should not be used
4315 to exit a L<C<grep>|/grep BLOCK LIST> or L<C<map>|/map BLOCK LIST>
4316 operation.
4317
4318 Note that a block by itself is semantically identical to a loop
4319 that executes once.  Thus L<C<next>|/next LABEL> will exit such a block
4320 early.
4321
4322 See also L<C<continue>|/continue BLOCK> for an illustration of how
4323 L<C<last>|/last LABEL>, L<C<next>|/next LABEL>, and
4324 L<C<redo>|/redo LABEL> work.
4325
4326 Unlike most named operators, this has the same precedence as assignment.
4327 It is also exempt from the looks-like-a-function rule, so
4328 C<next ("foo")."bar"> will cause "bar" to be part of the argument to
4329 L<C<next>|/next LABEL>.
4330
4331 =item no MODULE VERSION LIST
4332 X<no declarations>
4333 X<unimporting>
4334
4335 =item no MODULE VERSION
4336
4337 =item no MODULE LIST
4338
4339 =item no MODULE
4340
4341 =item no VERSION
4342
4343 =for Pod::Functions unimport some module symbols or semantics at compile time
4344
4345 See the L<C<use>|/use Module VERSION LIST> function, of which
4346 L<C<no>|/no MODULE VERSION LIST> is the opposite.
4347
4348 =item oct EXPR
4349 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
4350
4351 =item oct
4352
4353 =for Pod::Functions convert a string to an octal number
4354
4355 Interprets EXPR as an octal string and returns the corresponding
4356 value.  (If EXPR happens to start off with C<0x>, interprets it as a
4357 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
4358 binary string.  Leading whitespace is ignored in all three cases.)
4359 The following will handle decimal, binary, octal, and hex in standard
4360 Perl notation:
4361
4362     $val = oct($val) if $val =~ /^0/;
4363
4364 If EXPR is omitted, uses L<C<$_>|perlvar/$_>.   To go the other way
4365 (produce a number in octal), use L<C<sprintf>|/sprintf FORMAT, LIST> or
4366 L<C<printf>|/printf FILEHANDLE FORMAT, LIST>:
4367
4368     my $dec_perms = (stat("filename"))[2] & 07777;
4369     my $oct_perm_str = sprintf "%o", $perms;
4370
4371 The L<C<oct>|/oct EXPR> function is commonly used when a string such as
4372 C<644> needs
4373 to be converted into a file mode, for example.  Although Perl
4374 automatically converts strings into numbers as needed, this automatic
4375 conversion assumes base 10.
4376
4377 Leading white space is ignored without warning, as too are any trailing
4378 non-digits, such as a decimal point (L<C<oct>|/oct EXPR> only handles
4379 non-negative integers, not negative integers or floating point).
4380
4381 =item open FILEHANDLE,EXPR
4382 X<open> X<pipe> X<file, open> X<fopen>
4383
4384 =item open FILEHANDLE,MODE,EXPR
4385
4386 =item open FILEHANDLE,MODE,EXPR,LIST
4387
4388 =item open FILEHANDLE,MODE,REFERENCE
4389
4390 =item open FILEHANDLE
4391
4392 =for Pod::Functions open a file, pipe, or descriptor
4393
4394 Opens the file whose filename is given by EXPR, and associates it with
4395 FILEHANDLE.
4396
4397 Simple examples to open a file for reading:
4398
4399     open(my $fh, "<", "input.txt")
4400         or die "Can't open < input.txt: $!";
4401
4402 and for writing:
4403
4404     open(my $fh, ">", "output.txt")
4405         or die "Can't open > output.txt: $!";
4406
4407 (The following is a comprehensive reference to
4408 L<C<open>|/open FILEHANDLE,EXPR>: for a gentler introduction you may
4409 consider L<perlopentut>.)
4410
4411 If FILEHANDLE is an undefined scalar variable (or array or hash element), a
4412 new filehandle is autovivified, meaning that the variable is assigned a
4413 reference to a newly allocated anonymous filehandle.  Otherwise if
4414 FILEHANDLE is an expression, its value is the real filehandle.  (This is
4415 considered a symbolic reference, so C<use strict "refs"> should I<not> be
4416 in effect.)
4417
4418 If three (or more) arguments are specified, the open mode (including
4419 optional encoding) in the second argument are distinct from the filename in
4420 the third.  If MODE is C<< < >> or nothing, the file is opened for input.
4421 If MODE is C<< > >>, the file is opened for output, with existing files
4422 first being truncated ("clobbered") and nonexisting files newly created.
4423 If MODE is C<<< >> >>>, the file is opened for appending, again being
4424 created if necessary.
4425
4426 You can put a C<+> in front of the C<< > >> or C<< < >> to
4427 indicate that you want both read and write access to the file; thus
4428 C<< +< >> is almost always preferred for read/write updates--the
4429 C<< +> >> mode would clobber the file first.  You can't usually use
4430 either read-write mode for updating textfiles, since they have
4431 variable-length records.  See the B<-i> switch in L<perlrun> for a
4432 better approach.  The file is created with permissions of C<0666>
4433 modified by the process's L<C<umask>|/umask EXPR> value.
4434
4435 These various prefixes correspond to the L<fopen(3)> modes of C<r>,
4436 C<r+>, C<w>, C<w+>, C<a>, and C<a+>.
4437
4438 In the one- and two-argument forms of the call, the mode and filename
4439 should be concatenated (in that order), preferably separated by white
4440 space.  You can--but shouldn't--omit the mode in these forms when that mode
4441 is C<< < >>.  It is safe to use the two-argument form of
4442 L<C<open>|/open FILEHANDLE,EXPR> if the filename argument is a known literal.
4443
4444 For three or more arguments if MODE is C<|->, the filename is
4445 interpreted as a command to which output is to be piped, and if MODE
4446 is C<-|>, the filename is interpreted as a command that pipes
4447 output to us.  In the two-argument (and one-argument) form, one should
4448 replace dash (C<->) with the command.
4449 See L<perlipc/"Using open() for IPC"> for more examples of this.
4450 (You are not allowed to L<C<open>|/open FILEHANDLE,EXPR> to a command
4451 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>, and
4452 L<perlipc/"Bidirectional Communication with Another Process"> for
4453 alternatives.)
4454
4455 In the form of pipe opens taking three or more arguments, if LIST is specified
4456 (extra arguments after the command name) then LIST becomes arguments
4457 to the command invoked if the platform supports it.  The meaning of
4458 L<C<open>|/open FILEHANDLE,EXPR> with more than three arguments for
4459 non-pipe modes is not yet defined, but experimental "layers" may give
4460 extra LIST arguments meaning.
4461
4462 In the two-argument (and one-argument) form, opening C<< <- >>
4463 or C<-> opens STDIN and opening C<< >- >> opens STDOUT.
4464
4465 You may (and usually should) use the three-argument form of open to specify
4466 I/O layers (sometimes referred to as "disciplines") to apply to the handle
4467 that affect how the input and output are processed (see L<open> and
4468 L<PerlIO> for more details).  For example:
4469
4470   open(my $fh, "<:encoding(UTF-8)", $filename)
4471     || die "Can't open UTF-8 encoded $filename: $!";
4472
4473 opens the UTF8-encoded file containing Unicode characters;
4474 see L<perluniintro>.  Note that if layers are specified in the
4475 three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>;
4476 usually set by the L<open> pragma or the switch C<-CioD>) are ignored.
4477 Those layers will also be ignored if you specify a colon with no name
4478 following it.  In that case the default layer for the operating system
4479 (:raw on Unix, :crlf on Windows) is used.
4480
4481 Open returns nonzero on success, the undefined value otherwise.  If
4482 the L<C<open>|/open FILEHANDLE,EXPR> involved a pipe, the return value
4483 happens to be the pid of the subprocess.
4484
4485 On some systems (in general, DOS- and Windows-based systems)
4486 L<C<binmode>|/binmode FILEHANDLE, LAYER> is necessary when you're not
4487 working with a text file.  For the sake of portability it is a good idea
4488 always to use it when appropriate, and never to use it when it isn't
4489 appropriate.  Also, people can set their I/O to be by default
4490 UTF8-encoded Unicode, not bytes.
4491
4492 When opening a file, it's seldom a good idea to continue
4493 if the request failed, so L<C<open>|/open FILEHANDLE,EXPR> is frequently
4494 used with L<C<die>|/die LIST>.  Even if L<C<die>|/die LIST> won't do
4495 what you want (say, in a CGI script,
4496 where you want to format a suitable error message (but there are
4497 modules that can help with that problem)) always check
4498 the return value from opening a file.
4499
4500 The filehandle will be closed when its reference count reaches zero.
4501 If it is a lexically scoped variable declared with L<C<my>|/my VARLIST>,
4502 that usually
4503 means the end of the enclosing scope.  However, this automatic close
4504 does not check for errors, so it is better to explicitly close
4505 filehandles, especially those used for writing:
4506
4507     close($handle)
4508        || warn "close failed: $!";
4509
4510 An older style is to use a bareword as the filehandle, as
4511
4512     open(FH, "<", "input.txt")
4513        or die "Can't open < input.txt: $!";
4514
4515 Then you can use C<FH> as the filehandle, in C<< close FH >> and C<<
4516 <FH> >> and so on.  Note that it's a global variable, so this form is
4517 not recommended in new code.
4518
4519 As a shortcut a one-argument call takes the filename from the global
4520 scalar variable of the same name as the filehandle:
4521
4522     $ARTICLE = 100;
4523     open(ARTICLE) or die "Can't find article $ARTICLE: $!\n";
4524
4525 Here C<$ARTICLE> must be a global (package) scalar variable - not one
4526 declared with L<C<my>|/my VARLIST> or L<C<state>|/state VARLIST>.
4527
4528 As a special case the three-argument form with a read/write mode and the third
4529 argument being L<C<undef>|/undef EXPR>:
4530
4531     open(my $tmp, "+>", undef) or die ...
4532
4533 opens a filehandle to a newly created empty anonymous temporary file.
4534 (This happens under any mode, which makes C<< +> >> the only useful and
4535 sensible mode to use.)  You will need to
4536 L<C<seek>|/seek FILEHANDLE,POSITION,WHENCE> to do the reading.
4537
4538 Perl is built using PerlIO by default.  Unless you've
4539 changed this (such as building Perl with C<Configure -Uuseperlio>), you can
4540 open filehandles directly to Perl scalars via:
4541
4542     open(my $fh, ">", \$variable) || ..
4543
4544 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
4545
4546     close STDOUT;
4547     open(STDOUT, ">", \$variable)
4548         or die "Can't open STDOUT: $!";
4549
4550 The scalars for in-memory files are treated as octet strings: unless
4551 the file is being opened with truncation the scalar may not contain
4552 any code points over 0xFF.
4553
4554 Opening in-memory files I<can> fail for a variety of reasons.  As with
4555 any other C<open>, check the return value for success.
4556
4557 See L<perliol> for detailed info on PerlIO.
4558
4559 General examples:
4560
4561  open(my $log, ">>", "/usr/spool/news/twitlog");
4562  # if the open fails, output is discarded
4563
4564  open(my $dbase, "+<", "dbase.mine")      # open for update
4565      or die "Can't open 'dbase.mine' for update: $!";
4566
4567  open(my $dbase, "+<dbase.mine")          # ditto
4568      or die "Can't open 'dbase.mine' for update: $!";
4569
4570  open(my $article_fh, "-|", "caesar <$article")  # decrypt
4571                                                  # article
4572      or die "Can't start caesar: $!";
4573
4574  open(my $article_fh, "caesar <$article |")      # ditto
4575      or die "Can't start caesar: $!";
4576
4577  open(my $out_fh, "|-", "sort >Tmp$$")    # $$ is our process id
4578      or die "Can't start sort: $!";
4579
4580  # in-memory files
4581  open(my $memory, ">", \$var)
4582      or die "Can't open memory file: $!";
4583  print $memory "foo!\n";              # output will appear in $var
4584
4585 You may also, in the Bourne shell tradition, specify an EXPR beginning
4586 with C<< >& >>, in which case the rest of the string is interpreted
4587 as the name of a filehandle (or file descriptor, if numeric) to be
4588 duped (as in L<dup(2)>) and opened.  You may use C<&> after C<< > >>,
4589 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
4590 The mode you specify should match the mode of the original filehandle.
4591 (Duping a filehandle does not take into account any existing contents
4592 of IO buffers.)  If you use the three-argument
4593 form, then you can pass either a
4594 number, the name of a filehandle, or the normal "reference to a glob".
4595
4596 Here is a script that saves, redirects, and restores C<STDOUT> and
4597 C<STDERR> using various methods:
4598
4599     #!/usr/bin/perl
4600     open(my $oldout, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4601     open(OLDERR,     ">&", \*STDERR) or die "Can't dup STDERR: $!";
4602
4603     open(STDOUT, '>', "foo.out") or die "Can't redirect STDOUT: $!";
4604     open(STDERR, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4605
4606     select STDERR; $| = 1;  # make unbuffered
4607     select STDOUT; $| = 1;  # make unbuffered
4608
4609     print STDOUT "stdout 1\n";  # this works for
4610     print STDERR "stderr 1\n";  # subprocesses too
4611
4612     open(STDOUT, ">&", $oldout) or die "Can't dup \$oldout: $!";
4613     open(STDERR, ">&OLDERR")    or die "Can't dup OLDERR: $!";
4614
4615     print STDOUT "stdout 2\n";
4616     print STDERR "stderr 2\n";
4617
4618 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
4619 or a filehandle, then Perl will do an equivalent of C's L<fdopen(3)> of
4620 that file descriptor (and not call L<dup(2)>); this is more
4621 parsimonious of file descriptors.  For example:
4622
4623     # open for input, reusing the fileno of $fd
4624     open(my $fh, "<&=", $fd)
4625
4626 or
4627
4628     open(my $fh, "<&=$fd")
4629
4630 or
4631
4632     # open for append, using the fileno of $oldfh
4633     open(my $fh, ">>&=", $oldfh)
4634
4635 Being parsimonious on filehandles is also useful (besides being
4636 parsimonious) for example when something is dependent on file
4637 descriptors, like for example locking using
4638 L<C<flock>|/flock FILEHANDLE,OPERATION>.  If you do just
4639 C<< open(my $A, ">>&", $B) >>, the filehandle C<$A> will not have the
4640 same file descriptor as C<$B>, and therefore C<flock($A)> will not
4641 C<flock($B)> nor vice versa.  But with C<< open(my $A, ">>&=", $B) >>,
4642 the filehandles will share the same underlying system file descriptor.
4643
4644 Note that under Perls older than 5.8.0, Perl uses the standard C library's'
4645 L<fdopen(3)> to implement the C<=> functionality.  On many Unix systems,
4646 L<fdopen(3)> fails when file descriptors exceed a certain value, typically 255.
4647 For Perls 5.8.0 and later, PerlIO is (most often) the default.
4648
4649 You can see whether your Perl was built with PerlIO by running
4650 C<perl -V:useperlio>.  If it says C<'define'>, you have PerlIO;
4651 otherwise you don't.
4652
4653 If you open a pipe on the command C<-> (that is, specify either C<|-> or C<-|>
4654 with the one- or two-argument forms of
4655 L<C<open>|/open FILEHANDLE,EXPR>), an implicit L<C<fork>|/fork> is done,
4656 so L<C<open>|/open FILEHANDLE,EXPR> returns twice: in the parent process
4657 it returns the pid
4658 of the child process, and in the child process it returns (a defined) C<0>.
4659 Use C<defined($pid)> or C<//> to determine whether the open was successful.
4660
4661 For example, use either
4662
4663    my $child_pid = open(my $from_kid, "-|") // die "Can't fork: $!";
4664
4665 or
4666
4667    my $child_pid = open(my $to_kid,   "|-") // die "Can't fork: $!";
4668
4669 followed by
4670
4671     if ($child_pid) {
4672         # am the parent:
4673         # either write $to_kid or else read $from_kid
4674         ...
4675        waitpid $child_pid, 0;
4676     } else {
4677         # am the child; use STDIN/STDOUT normally
4678         ...
4679         exit;
4680     }
4681
4682 The filehandle behaves normally for the parent, but I/O to that
4683 filehandle is piped from/to the STDOUT/STDIN of the child process.
4684 In the child process, the filehandle isn't opened--I/O happens from/to
4685 the new STDOUT/STDIN.  Typically this is used like the normal
4686 piped open when you want to exercise more control over just how the
4687 pipe command gets executed, such as when running setuid and
4688 you don't want to have to scan shell commands for metacharacters.
4689
4690 The following blocks are more or less equivalent:
4691
4692     open(my $fh, "|tr '[a-z]' '[A-Z]'");
4693     open(my $fh, "|-", "tr '[a-z]' '[A-Z]'");
4694     open(my $fh, "|-") || exec 'tr', '[a-z]', '[A-Z]';
4695     open(my $fh, "|-", "tr", '[a-z]', '[A-Z]');
4696
4697     open(my $fh, "cat -n '$file'|");
4698     open(my $fh, "-|", "cat -n '$file'&