This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
POD nitpicks.
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments 
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate literal elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use parentheses, the simple but occasionally 
34 surprising rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  Whitespace
37 between the function and left parenthesis doesn't count, so sometimes
38 you need to be careful:
39
40     print 1+2+4;      # Prints 7.
41     print(1+2) + 4;   # Prints 3.
42     print (1+2)+4;    # Also prints 3!
43     print +(1+2)+4;   # Prints 7.
44     print ((1+2)+4);  # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in scalar context by
59 returning the undefined value, and in list context by returning the
60 empty list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls ("syscalls")
82 of the same name (like chown(2), fork(2), closedir(2), etc.) return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule include C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 Extension modules can also hook into the Perl parser to define new
90 kinds of keyword-headed expression.  These may look like functions, but
91 may also look completely different.  The syntax following the keyword
92 is defined entirely by the extension.  If you are an implementor, see
93 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
94 a module, see the module's documentation for details of the syntax that
95 it defines.
96
97 =head2 Perl Functions by Category
98 X<function>
99
100 Here are Perl's functions (including things that look like
101 functions, like some keywords and named operators)
102 arranged by category.  Some functions appear in more
103 than one place.
104
105 =over 4
106
107 =item Functions for SCALARs or strings
108 X<scalar> X<string> X<character>
109
110 =for Pod::Functions =String
111
112 C<chomp>, C<chop>, C<chr>, C<crypt>, C<fc>, C<hex>, C<index>, C<lc>,
113 C<lcfirst>, C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
114 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
115
116 C<fc> is available only if the C<"fc"> feature is enabled or if it is
117 prefixed with C<CORE::>.  The C<"fc"> feature is enabled automatically
118 with a C<use v5.16> (or higher) declaration in the current scope.
119
120
121 =item Regular expressions and pattern matching
122 X<regular expression> X<regex> X<regexp>
123
124 =for Pod::Functions =Regexp
125
126 C<m//>, C<pos>, C<qr//>, C<quotemeta>, C<s///>, C<split>, C<study>
127
128 =item Numeric functions
129 X<numeric> X<number> X<trigonometric> X<trigonometry>
130
131 =for Pod::Functions =Math
132
133 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
134 C<sin>, C<sqrt>, C<srand>
135
136 =item Functions for real @ARRAYs
137 X<array>
138
139 =for Pod::Functions =ARRAY
140
141 C<each>, C<keys>, C<pop>, C<push>, C<shift>, C<splice>, C<unshift>, C<values>
142
143 =item Functions for list data
144 X<list>
145
146 =for Pod::Functions =LIST
147
148 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
149
150 =item Functions for real %HASHes
151 X<hash>
152
153 =for Pod::Functions =HASH
154
155 C<delete>, C<each>, C<exists>, C<keys>, C<values>
156
157 =item Input and output functions
158 X<I/O> X<input> X<output> X<dbm>
159
160 =for Pod::Functions =I/O
161
162 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
163 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
164 C<readdir>, C<readline> C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>,
165 C<syscall>, C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>,
166 C<truncate>, C<warn>, C<write>
167
168 C<say> is available only if the C<"say"> feature is enabled or if it is
169 prefixed with C<CORE::>.  The C<"say"> feature is enabled automatically
170 with a C<use v5.10> (or higher) declaration in the current scope.
171
172 =item Functions for fixed-length data or records
173
174 =for Pod::Functions =Binary
175
176 C<pack>, C<read>, C<syscall>, C<sysread>, C<sysseek>, C<syswrite>, C<unpack>,
177 C<vec>
178
179 =item Functions for filehandles, files, or directories
180 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
181
182 =for Pod::Functions =File
183
184 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
185 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
186 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
187 C<umask>, C<unlink>, C<utime>
188
189 =item Keywords related to the control flow of your Perl program
190 X<control flow>
191
192 =for Pod::Functions =Flow
193
194 C<break>, C<caller>, C<continue>, C<die>, C<do>,
195 C<dump>, C<eval>, C<evalbytes> C<exit>,
196 C<__FILE__>, C<goto>, C<last>, C<__LINE__>, C<next>, C<__PACKAGE__>,
197 C<redo>, C<return>, C<sub>, C<__SUB__>, C<wantarray>
198
199 C<break> is available only if you enable the experimental C<"switch">
200 feature or use the C<CORE::> prefix. The C<"switch"> feature also enables
201 the C<default>, C<given> and C<when> statements, which are documented in
202 L<perlsyn/"Switch Statements">. The C<"switch"> feature is enabled
203 automatically with a C<use v5.10> (or higher) declaration in the current
204 scope. In Perl v5.14 and earlier, C<continue> required the C<"switch">
205 feature, like the other keywords.
206
207 C<evalbytes> is only available with the C<"evalbytes"> feature (see
208 L<feature>) or if prefixed with C<CORE::>.  C<__SUB__> is only available
209 with the C<"current_sub"> feature or if prefixed with C<CORE::>. Both
210 the C<"evalbytes"> and C<"current_sub"> features are enabled automatically
211 with a C<use v5.16> (or higher) declaration in the current scope.
212
213 =item Keywords related to scoping
214
215 =for Pod::Functions =Namespace
216
217 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<state>, C<use>
218
219 C<state> is available only if the C<"state"> feature is enabled or if it is
220 prefixed with C<CORE::>.  The C<"state"> feature is enabled automatically
221 with a C<use v5.10> (or higher) declaration in the current scope.
222
223 =item Miscellaneous functions
224
225 =for Pod::Functions =Misc
226
227 C<defined>, C<formline>, C<lock>, C<prototype>, C<reset>, C<scalar>, C<undef>
228
229 =item Functions for processes and process groups
230 X<process> X<pid> X<process id>
231
232 =for Pod::Functions =Process
233
234 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
235 C<pipe>, C<qx//>, C<readpipe>, C<setpgrp>,
236 C<setpriority>, C<sleep>, C<system>,
237 C<times>, C<wait>, C<waitpid>
238
239 =item Keywords related to Perl modules
240 X<module>
241
242 =for Pod::Functions =Modules
243
244 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
245
246 =item Keywords related to classes and object-orientation
247 X<object> X<class> X<package>
248
249 =for Pod::Functions =Objects
250
251 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
252 C<untie>, C<use>
253
254 =item Low-level socket functions
255 X<socket> X<sock>
256
257 =for Pod::Functions =Socket
258
259 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
260 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
261 C<socket>, C<socketpair>
262
263 =item System V interprocess communication functions
264 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
265
266 =for Pod::Functions =SysV
267
268 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
269 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
270
271 =item Fetching user and group info
272 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
273
274 =for Pod::Functions =User
275
276 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
277 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
278 C<getpwuid>, C<setgrent>, C<setpwent>
279
280 =item Fetching network info
281 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
282
283 =for Pod::Functions =Network
284
285 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
286 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
287 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
288 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
289 C<setnetent>, C<setprotoent>, C<setservent>
290
291 =item Time-related functions
292 X<time> X<date>
293
294 =for Pod::Functions =Time
295
296 C<gmtime>, C<localtime>, C<time>, C<times>
297
298 =item Non-function keywords
299
300 =for Pod::Functions =!Non-functions
301
302 C<and>, C<AUTOLOAD>, C<BEGIN>, C<CHECK>, C<cmp>, C<CORE>, C<__DATA__>,
303 C<default>, C<DESTROY>, C<else>, C<elseif>, C<elsif>, C<END>, C<__END__>,
304 C<eq>, C<for>, C<foreach>, C<ge>, C<given>, C<gt>, C<if>, C<INIT>, C<le>,
305 C<lt>, C<ne>, C<not>, C<or>, C<UNITCHECK>, C<unless>, C<until>, C<when>,
306 C<while>, C<x>, C<xor>
307
308 =back
309
310 =head2 Portability
311 X<portability> X<Unix> X<portable>
312
313 Perl was born in Unix and can therefore access all common Unix
314 system calls.  In non-Unix environments, the functionality of some
315 Unix system calls may not be available or details of the available
316 functionality may differ slightly.  The Perl functions affected
317 by this are:
318
319 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
320 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
321 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
322 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
323 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
324 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
325 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
326 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
327 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
328 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
329 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
330 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
331 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
332 C<shmwrite>, C<socket>, C<socketpair>,
333 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
334 C<times>, C<truncate>, C<umask>, C<unlink>,
335 C<utime>, C<wait>, C<waitpid>
336
337 For more information about the portability of these functions, see
338 L<perlport> and other available platform-specific documentation.
339
340 =head2 Alphabetical Listing of Perl Functions
341
342 =over 
343
344 =item -X FILEHANDLE
345 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
346 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
347
348 =item -X EXPR
349
350 =item -X DIRHANDLE
351
352 =item -X
353
354 =for Pod::Functions a file test (-r, -x, etc)
355
356 A file test, where X is one of the letters listed below.  This unary
357 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
358 and tests the associated file to see if something is true about it.  If the
359 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
360 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
361 the undefined value if the file doesn't exist.  Despite the funny
362 names, precedence is the same as any other named unary operator.  The
363 operator may be any of:
364
365     -r  File is readable by effective uid/gid.
366     -w  File is writable by effective uid/gid.
367     -x  File is executable by effective uid/gid.
368     -o  File is owned by effective uid.
369
370     -R  File is readable by real uid/gid.
371     -W  File is writable by real uid/gid.
372     -X  File is executable by real uid/gid.
373     -O  File is owned by real uid.
374
375     -e  File exists.
376     -z  File has zero size (is empty).
377     -s  File has nonzero size (returns size in bytes).
378
379     -f  File is a plain file.
380     -d  File is a directory.
381     -l  File is a symbolic link.
382     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
383     -S  File is a socket.
384     -b  File is a block special file.
385     -c  File is a character special file.
386     -t  Filehandle is opened to a tty.
387
388     -u  File has setuid bit set.
389     -g  File has setgid bit set.
390     -k  File has sticky bit set.
391
392     -T  File is an ASCII text file (heuristic guess).
393     -B  File is a "binary" file (opposite of -T).
394
395     -M  Script start time minus file modification time, in days.
396     -A  Same for access time.
397     -C  Same for inode change time (Unix, may differ for other
398         platforms)
399
400 Example:
401
402     while (<>) {
403         chomp;
404         next unless -f $_;  # ignore specials
405         #...
406     }
407
408 Note that C<-s/a/b/> does not do a negated substitution.  Saying
409 C<-exp($foo)> still works as expected, however: only single letters
410 following a minus are interpreted as file tests.
411
412 These operators are exempt from the "looks like a function rule" described
413 above.  That is, an opening parenthesis after the operator does not affect
414 how much of the following code constitutes the argument.  Put the opening
415 parentheses before the operator to separate it from code that follows (this
416 applies only to operators with higher precedence than unary operators, of
417 course):
418
419     -s($file) + 1024   # probably wrong; same as -s($file + 1024)
420     (-s $file) + 1024  # correct
421
422 The interpretation of the file permission operators C<-r>, C<-R>,
423 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
424 of the file and the uids and gids of the user.  There may be other
425 reasons you can't actually read, write, or execute the file: for
426 example network filesystem access controls, ACLs (access control lists),
427 read-only filesystems, and unrecognized executable formats.  Note
428 that the use of these six specific operators to verify if some operation
429 is possible is usually a mistake, because it may be open to race
430 conditions.
431
432 Also note that, for the superuser on the local filesystems, the C<-r>,
433 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
434 if any execute bit is set in the mode.  Scripts run by the superuser
435 may thus need to do a stat() to determine the actual mode of the file,
436 or temporarily set their effective uid to something else.
437
438 If you are using ACLs, there is a pragma called C<filetest> that may
439 produce more accurate results than the bare stat() mode bits.
440 When under C<use filetest 'access'> the above-mentioned filetests
441 test whether the permission can(not) be granted using the
442 access(2) family of system calls.  Also note that the C<-x> and C<-X> may
443 under this pragma return true even if there are no execute permission
444 bits set (nor any extra execute permission ACLs).  This strangeness is
445 due to the underlying system calls' definitions.  Note also that, due to
446 the implementation of C<use filetest 'access'>, the C<_> special
447 filehandle won't cache the results of the file tests when this pragma is
448 in effect.  Read the documentation for the C<filetest> pragma for more
449 information.
450
451 The C<-T> and C<-B> switches work as follows.  The first block or so of the
452 file is examined for odd characters such as strange control codes or
453 characters with the high bit set.  If too many strange characters (>30%)
454 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
455 containing a zero byte in the first block is considered a binary file.  If C<-T>
456 or C<-B> is used on a filehandle, the current IO buffer is examined
457 rather than the first block.  Both C<-T> and C<-B> return true on an empty
458 file, or a file at EOF when testing a filehandle.  Because you have to
459 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
460 against the file first, as in C<next unless -f $file && -T $file>.
461
462 If any of the file tests (or either the C<stat> or C<lstat> operator) is given
463 the special filehandle consisting of a solitary underline, then the stat
464 structure of the previous file test (or stat operator) is used, saving
465 a system call.  (This doesn't work with C<-t>, and you need to remember
466 that lstat() and C<-l> leave values in the stat structure for the
467 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
468 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
469 Example:
470
471     print "Can do.\n" if -r $a || -w _ || -x _;
472
473     stat($filename);
474     print "Readable\n" if -r _;
475     print "Writable\n" if -w _;
476     print "Executable\n" if -x _;
477     print "Setuid\n" if -u _;
478     print "Setgid\n" if -g _;
479     print "Sticky\n" if -k _;
480     print "Text\n" if -T _;
481     print "Binary\n" if -B _;
482
483 As of Perl 5.10.0, as a form of purely syntactic sugar, you can stack file
484 test operators, in a way that C<-f -w -x $file> is equivalent to
485 C<-x $file && -w _ && -f _>.  (This is only fancy fancy: if you use
486 the return value of C<-f $file> as an argument to another filetest
487 operator, no special magic will happen.)
488
489 Portability issues: L<perlport/-X>.
490
491 To avoid confusing would-be users of your code with mysterious
492 syntax errors, put something like this at the top of your script:
493
494     use 5.010;  # so filetest ops can stack
495
496 =item abs VALUE
497 X<abs> X<absolute>
498
499 =item abs
500
501 =for Pod::Functions absolute value function
502
503 Returns the absolute value of its argument.
504 If VALUE is omitted, uses C<$_>.
505
506 =item accept NEWSOCKET,GENERICSOCKET
507 X<accept>
508
509 =for Pod::Functions accept an incoming socket connect
510
511 Accepts an incoming socket connect, just as accept(2) 
512 does.  Returns the packed address if it succeeded, false otherwise.
513 See the example in L<perlipc/"Sockets: Client/Server Communication">.
514
515 On systems that support a close-on-exec flag on files, the flag will
516 be set for the newly opened file descriptor, as determined by the
517 value of $^F.  See L<perlvar/$^F>.
518
519 =item alarm SECONDS
520 X<alarm>
521 X<SIGALRM>
522 X<timer>
523
524 =item alarm
525
526 =for Pod::Functions schedule a SIGALRM
527
528 Arranges to have a SIGALRM delivered to this process after the
529 specified number of wallclock seconds has elapsed.  If SECONDS is not
530 specified, the value stored in C<$_> is used.  (On some machines,
531 unfortunately, the elapsed time may be up to one second less or more
532 than you specified because of how seconds are counted, and process
533 scheduling may delay the delivery of the signal even further.)
534
535 Only one timer may be counting at once.  Each call disables the
536 previous timer, and an argument of C<0> may be supplied to cancel the
537 previous timer without starting a new one.  The returned value is the
538 amount of time remaining on the previous timer.
539
540 For delays of finer granularity than one second, the Time::HiRes module
541 (from CPAN, and starting from Perl 5.8 part of the standard
542 distribution) provides ualarm().  You may also use Perl's four-argument
543 version of select() leaving the first three arguments undefined, or you
544 might be able to use the C<syscall> interface to access setitimer(2) if
545 your system supports it.  See L<perlfaq8> for details.
546
547 It is usually a mistake to intermix C<alarm> and C<sleep> calls, because
548 C<sleep> may be internally implemented on your system with C<alarm>.
549
550 If you want to use C<alarm> to time out a system call you need to use an
551 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
552 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
553 restart system calls on some systems.  Using C<eval>/C<die> always works,
554 modulo the caveats given in L<perlipc/"Signals">.
555
556     eval {
557         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
558         alarm $timeout;
559         $nread = sysread SOCKET, $buffer, $size;
560         alarm 0;
561     };
562     if ($@) {
563         die unless $@ eq "alarm\n";   # propagate unexpected errors
564         # timed out
565     }
566     else {
567         # didn't
568     }
569
570 For more information see L<perlipc>.
571
572 Portability issues: L<perlport/alarm>.
573
574 =item atan2 Y,X
575 X<atan2> X<arctangent> X<tan> X<tangent>
576
577 =for Pod::Functions arctangent of Y/X in the range -PI to PI
578
579 Returns the arctangent of Y/X in the range -PI to PI.
580
581 For the tangent operation, you may use the C<Math::Trig::tan>
582 function, or use the familiar relation:
583
584     sub tan { sin($_[0]) / cos($_[0])  }
585
586 The return value for C<atan2(0,0)> is implementation-defined; consult
587 your atan2(3) manpage for more information.
588
589 Portability issues: L<perlport/atan2>.
590
591 =item bind SOCKET,NAME
592 X<bind>
593
594 =for Pod::Functions binds an address to a socket
595
596 Binds a network address to a socket, just as bind(2)
597 does.  Returns true if it succeeded, false otherwise.  NAME should be a
598 packed address of the appropriate type for the socket.  See the examples in
599 L<perlipc/"Sockets: Client/Server Communication">.
600
601 =item binmode FILEHANDLE, LAYER
602 X<binmode> X<binary> X<text> X<DOS> X<Windows>
603
604 =item binmode FILEHANDLE
605
606 =for Pod::Functions prepare binary files for I/O
607
608 Arranges for FILEHANDLE to be read or written in "binary" or "text"
609 mode on systems where the run-time libraries distinguish between
610 binary and text files.  If FILEHANDLE is an expression, the value is
611 taken as the name of the filehandle.  Returns true on success,
612 otherwise it returns C<undef> and sets C<$!> (errno).
613
614 On some systems (in general, DOS- and Windows-based systems) binmode()
615 is necessary when you're not working with a text file.  For the sake
616 of portability it is a good idea always to use it when appropriate,
617 and never to use it when it isn't appropriate.  Also, people can
618 set their I/O to be by default UTF8-encoded Unicode, not bytes.
619
620 In other words: regardless of platform, use binmode() on binary data,
621 like images, for example.
622
623 If LAYER is present it is a single string, but may contain multiple
624 directives.  The directives alter the behaviour of the filehandle.
625 When LAYER is present, using binmode on a text file makes sense.
626
627 If LAYER is omitted or specified as C<:raw> the filehandle is made
628 suitable for passing binary data.  This includes turning off possible CRLF
629 translation and marking it as bytes (as opposed to Unicode characters).
630 Note that, despite what may be implied in I<"Programming Perl"> (the
631 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
632 Other layers that would affect the binary nature of the stream are
633 I<also> disabled.  See L<PerlIO>, L<perlrun>, and the discussion about the
634 PERLIO environment variable.
635
636 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
637 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
638 establish default I/O layers.  See L<open>.
639
640 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
641 in "Programming Perl, 3rd Edition".  However, since the publishing of this
642 book, by many known as "Camel III", the consensus of the naming of this
643 functionality has moved from "discipline" to "layer".  All documentation
644 of this version of Perl therefore refers to "layers" rather than to
645 "disciplines".  Now back to the regularly scheduled documentation...>
646
647 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(UTF-8)>.
648 C<:utf8> just marks the data as UTF-8 without further checking,
649 while C<:encoding(UTF-8)> checks the data for actually being valid
650 UTF-8.  More details can be found in L<PerlIO::encoding>.
651
652 In general, binmode() should be called after open() but before any I/O
653 is done on the filehandle.  Calling binmode() normally flushes any
654 pending buffered output data (and perhaps pending input data) on the
655 handle.  An exception to this is the C<:encoding> layer that
656 changes the default character encoding of the handle; see L</open>.
657 The C<:encoding> layer sometimes needs to be called in
658 mid-stream, and it doesn't flush the stream.  The C<:encoding>
659 also implicitly pushes on top of itself the C<:utf8> layer because
660 internally Perl operates on UTF8-encoded Unicode characters.
661
662 The operating system, device drivers, C libraries, and Perl run-time
663 system all conspire to let the programmer treat a single
664 character (C<\n>) as the line terminator, irrespective of external
665 representation.  On many operating systems, the native text file
666 representation matches the internal representation, but on some
667 platforms the external representation of C<\n> is made up of more than
668 one character.
669
670 All variants of Unix, Mac OS (old and new), and Stream_LF files on VMS use
671 a single character to end each line in the external representation of text
672 (even though that single character is CARRIAGE RETURN on old, pre-Darwin
673 flavors of Mac OS, and is LINE FEED on Unix and most VMS files).  In other
674 systems like OS/2, DOS, and the various flavors of MS-Windows, your program
675 sees a C<\n> as a simple C<\cJ>, but what's stored in text files are the
676 two characters C<\cM\cJ>.  That means that if you don't use binmode() on
677 these systems, C<\cM\cJ> sequences on disk will be converted to C<\n> on
678 input, and any C<\n> in your program will be converted back to C<\cM\cJ> on
679 output.  This is what you want for text files, but it can be disastrous for
680 binary files.
681
682 Another consequence of using binmode() (on some systems) is that
683 special end-of-file markers will be seen as part of the data stream.
684 For systems from the Microsoft family this means that, if your binary
685 data contain C<\cZ>, the I/O subsystem will regard it as the end of
686 the file, unless you use binmode().
687
688 binmode() is important not only for readline() and print() operations,
689 but also when using read(), seek(), sysread(), syswrite() and tell()
690 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
691 in L<perlvar> for how to manually set your input and output
692 line-termination sequences.
693
694 Portability issues: L<perlport/binmode>.
695
696 =item bless REF,CLASSNAME
697 X<bless>
698
699 =item bless REF
700
701 =for Pod::Functions create an object
702
703 This function tells the thingy referenced by REF that it is now an object
704 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
705 is used.  Because a C<bless> is often the last thing in a constructor,
706 it returns the reference for convenience.  Always use the two-argument
707 version if a derived class might inherit the function doing the blessing.
708 See L<perlobj> for more about the blessing (and blessings) of objects.
709
710 Consider always blessing objects in CLASSNAMEs that are mixed case.
711 Namespaces with all lowercase names are considered reserved for
712 Perl pragmata.  Builtin types have all uppercase names.  To prevent
713 confusion, you may wish to avoid such package names as well.  Make sure
714 that CLASSNAME is a true value.
715
716 See L<perlmod/"Perl Modules">.
717
718 =item break
719
720 =for Pod::Functions +switch break out of a C<given> block
721
722 Break out of a C<given()> block.
723
724 This keyword is enabled by the C<"switch"> feature; see L<feature> for
725 more information on C<"switch">.  You can also access it by prefixing it
726 with C<CORE::>.  Alternatively, include a C<use v5.10> or later to the
727 current scope.
728
729 =item caller EXPR
730 X<caller> X<call stack> X<stack> X<stack trace>
731
732 =item caller
733
734 =for Pod::Functions get context of the current subroutine call
735
736 Returns the context of the current subroutine call.  In scalar context,
737 returns the caller's package name if there I<is> a caller (that is, if
738 we're in a subroutine or C<eval> or C<require>) and the undefined value
739 otherwise.  In list context, returns
740
741     # 0         1          2
742     ($package, $filename, $line) = caller;
743
744 With EXPR, it returns some extra information that the debugger uses to
745 print a stack trace.  The value of EXPR indicates how many call frames
746 to go back before the current one.
747
748     #  0         1          2      3            4
749     ($package, $filename, $line, $subroutine, $hasargs,
750
751     #  5          6          7            8       9         10
752     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
753      = caller($i);
754
755 Here $subroutine may be C<(eval)> if the frame is not a subroutine
756 call, but an C<eval>.  In such a case additional elements $evaltext and
757 C<$is_require> are set: C<$is_require> is true if the frame is created by a
758 C<require> or C<use> statement, $evaltext contains the text of the
759 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
760 $subroutine is C<(eval)>, but $evaltext is undefined.  (Note also that
761 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
762 frame.)  $subroutine may also be C<(unknown)> if this particular
763 subroutine happens to have been deleted from the symbol table.
764 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
765 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
766 compiled with.  C<$hints> corresponds to C<$^H>, and C<$bitmask>
767 corresponds to C<${^WARNING_BITS}>.  The
768 C<$hints> and C<$bitmask> values are subject
769 to change between versions of Perl, and are not meant for external use.
770
771 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
772 caller was compiled, or C<undef> if C<%^H> was empty.  Do not modify the values
773 of this hash, as they are the actual values stored in the optree.
774
775 Furthermore, when called from within the DB package in
776 list context, and with an argument, caller returns more
777 detailed information: it sets the list variable C<@DB::args> to be the
778 arguments with which the subroutine was invoked.
779
780 Be aware that the optimizer might have optimized call frames away before
781 C<caller> had a chance to get the information.  That means that C<caller(N)>
782 might not return information about the call frame you expect it to, for
783 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
784 previous time C<caller> was called.
785
786 Be aware that setting C<@DB::args> is I<best effort>, intended for
787 debugging or generating backtraces, and should not be relied upon.  In
788 particular, as C<@_> contains aliases to the caller's arguments, Perl does
789 not take a copy of C<@_>, so C<@DB::args> will contain modifications the
790 subroutine makes to C<@_> or its contents, not the original values at call
791 time.  C<@DB::args>, like C<@_>, does not hold explicit references to its
792 elements, so under certain cases its elements may have become freed and
793 reallocated for other variables or temporary values.  Finally, a side effect
794 of the current implementation is that the effects of C<shift @_> can
795 I<normally> be undone (but not C<pop @_> or other splicing, I<and> not if a
796 reference to C<@_> has been taken, I<and> subject to the caveat about reallocated
797 elements), so C<@DB::args> is actually a hybrid of the current state and
798 initial state of C<@_>.  Buyer beware.
799
800 =item chdir EXPR
801 X<chdir>
802 X<cd>
803 X<directory, change>
804
805 =item chdir FILEHANDLE
806
807 =item chdir DIRHANDLE
808
809 =item chdir
810
811 =for Pod::Functions change your current working directory
812
813 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
814 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
815 changes to the directory specified by C<$ENV{LOGDIR}>.  (Under VMS, the
816 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.)  If
817 neither is set, C<chdir> does nothing.  It returns true on success,
818 false otherwise.  See the example under C<die>.
819
820 On systems that support fchdir(2), you may pass a filehandle or
821 directory handle as the argument.  On systems that don't support fchdir(2),
822 passing handles raises an exception.
823
824 =item chmod LIST
825 X<chmod> X<permission> X<mode>
826
827 =for Pod::Functions changes the permissions on a list of files
828
829 Changes the permissions of a list of files.  The first element of the
830 list must be the numeric mode, which should probably be an octal
831 number, and which definitely should I<not> be a string of octal digits:
832 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
833 successfully changed.  See also L</oct> if all you have is a string.
834
835     $cnt = chmod 0755, "foo", "bar";
836     chmod 0755, @executables;
837     $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
838                                              # --w----r-T
839     $mode = "0644"; chmod oct($mode), "foo"; # this is better
840     $mode = 0644;   chmod $mode, "foo";      # this is best
841
842 On systems that support fchmod(2), you may pass filehandles among the
843 files.  On systems that don't support fchmod(2), passing filehandles raises
844 an exception.  Filehandles must be passed as globs or glob references to be
845 recognized; barewords are considered filenames.
846
847     open(my $fh, "<", "foo");
848     my $perm = (stat $fh)[2] & 07777;
849     chmod($perm | 0600, $fh);
850
851 You can also import the symbolic C<S_I*> constants from the C<Fcntl>
852 module:
853
854     use Fcntl qw( :mode );
855     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
856     # Identical to the chmod 0755 of the example above.
857
858 Portability issues: L<perlport/chmod>.
859
860 =item chomp VARIABLE
861 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
862
863 =item chomp( LIST )
864
865 =item chomp
866
867 =for Pod::Functions remove a trailing record separator from a string
868
869 This safer version of L</chop> removes any trailing string
870 that corresponds to the current value of C<$/> (also known as
871 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
872 number of characters removed from all its arguments.  It's often used to
873 remove the newline from the end of an input record when you're worried
874 that the final record may be missing its newline.  When in paragraph
875 mode (C<$/ = "">), it removes all trailing newlines from the string.
876 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
877 a reference to an integer or the like; see L<perlvar>) chomp() won't
878 remove anything.
879 If VARIABLE is omitted, it chomps C<$_>.  Example:
880
881     while (<>) {
882         chomp;  # avoid \n on last field
883         @array = split(/:/);
884         # ...
885     }
886
887 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
888
889 You can actually chomp anything that's an lvalue, including an assignment:
890
891     chomp($cwd = `pwd`);
892     chomp($answer = <STDIN>);
893
894 If you chomp a list, each element is chomped, and the total number of
895 characters removed is returned.
896
897 Note that parentheses are necessary when you're chomping anything
898 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
899 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
900 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
901 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
902 as C<chomp($a, $b)>.
903
904 =item chop VARIABLE
905 X<chop>
906
907 =item chop( LIST )
908
909 =item chop
910
911 =for Pod::Functions remove the last character from a string
912
913 Chops off the last character of a string and returns the character
914 chopped.  It is much more efficient than C<s/.$//s> because it neither
915 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
916 If VARIABLE is a hash, it chops the hash's values, but not its keys.
917
918 You can actually chop anything that's an lvalue, including an assignment.
919
920 If you chop a list, each element is chopped.  Only the value of the
921 last C<chop> is returned.
922
923 Note that C<chop> returns the last character.  To return all but the last
924 character, use C<substr($string, 0, -1)>.
925
926 See also L</chomp>.
927
928 =item chown LIST
929 X<chown> X<owner> X<user> X<group>
930
931 =for Pod::Functions change the ownership on a list of files
932
933 Changes the owner (and group) of a list of files.  The first two
934 elements of the list must be the I<numeric> uid and gid, in that
935 order.  A value of -1 in either position is interpreted by most
936 systems to leave that value unchanged.  Returns the number of files
937 successfully changed.
938
939     $cnt = chown $uid, $gid, 'foo', 'bar';
940     chown $uid, $gid, @filenames;
941
942 On systems that support fchown(2), you may pass filehandles among the
943 files.  On systems that don't support fchown(2), passing filehandles raises
944 an exception.  Filehandles must be passed as globs or glob references to be
945 recognized; barewords are considered filenames.
946
947 Here's an example that looks up nonnumeric uids in the passwd file:
948
949     print "User: ";
950     chomp($user = <STDIN>);
951     print "Files: ";
952     chomp($pattern = <STDIN>);
953
954     ($login,$pass,$uid,$gid) = getpwnam($user)
955         or die "$user not in passwd file";
956
957     @ary = glob($pattern);  # expand filenames
958     chown $uid, $gid, @ary;
959
960 On most systems, you are not allowed to change the ownership of the
961 file unless you're the superuser, although you should be able to change
962 the group to any of your secondary groups.  On insecure systems, these
963 restrictions may be relaxed, but this is not a portable assumption.
964 On POSIX systems, you can detect this condition this way:
965
966     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
967     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
968
969 Portability issues: L<perlport/chmod>.
970
971 =item chr NUMBER
972 X<chr> X<character> X<ASCII> X<Unicode>
973
974 =item chr
975
976 =for Pod::Functions get character this number represents
977
978 Returns the character represented by that NUMBER in the character set.
979 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
980 chr(0x263a) is a Unicode smiley face.  
981
982 Negative values give the Unicode replacement character (chr(0xfffd)),
983 except under the L<bytes> pragma, where the low eight bits of the value
984 (truncated to an integer) are used.
985
986 If NUMBER is omitted, uses C<$_>.
987
988 For the reverse, use L</ord>.
989
990 Note that characters from 128 to 255 (inclusive) are by default
991 internally not encoded as UTF-8 for backward compatibility reasons.
992
993 See L<perlunicode> for more about Unicode.
994
995 =item chroot FILENAME
996 X<chroot> X<root>
997
998 =item chroot
999
1000 =for Pod::Functions make directory new root for path lookups
1001
1002 This function works like the system call by the same name: it makes the
1003 named directory the new root directory for all further pathnames that
1004 begin with a C</> by your process and all its children.  (It doesn't
1005 change your current working directory, which is unaffected.)  For security
1006 reasons, this call is restricted to the superuser.  If FILENAME is
1007 omitted, does a C<chroot> to C<$_>.
1008
1009 Portability issues: L<perlport/chroot>.
1010
1011 =item close FILEHANDLE
1012 X<close>
1013
1014 =item close
1015
1016 =for Pod::Functions close file (or pipe or socket) handle
1017
1018 Closes the file or pipe associated with the filehandle, flushes the IO
1019 buffers, and closes the system file descriptor.  Returns true if those
1020 operations succeed and if no error was reported by any PerlIO
1021 layer.  Closes the currently selected filehandle if the argument is
1022 omitted.
1023
1024 You don't have to close FILEHANDLE if you are immediately going to do
1025 another C<open> on it, because C<open> closes it for you.  (See
1026 L<open|/open FILEHANDLE>.)  However, an explicit C<close> on an input file resets the line
1027 counter (C<$.>), while the implicit close done by C<open> does not.
1028
1029 If the filehandle came from a piped open, C<close> returns false if one of
1030 the other syscalls involved fails or if its program exits with non-zero
1031 status.  If the only problem was that the program exited non-zero, C<$!>
1032 will be set to C<0>.  Closing a pipe also waits for the process executing
1033 on the pipe to exit--in case you wish to look at the output of the pipe
1034 afterwards--and implicitly puts the exit status value of that command into
1035 C<$?> and C<${^CHILD_ERROR_NATIVE}>.
1036
1037 If there are multiple threads running, C<close> on a filehandle from a
1038 piped open returns true without waiting for the child process to terminate,
1039 if the filehandle is still open in another thread.
1040
1041 Closing the read end of a pipe before the process writing to it at the
1042 other end is done writing results in the writer receiving a SIGPIPE.  If
1043 the other end can't handle that, be sure to read all the data before
1044 closing the pipe.
1045
1046 Example:
1047
1048     open(OUTPUT, '|sort >foo')  # pipe to sort
1049         or die "Can't start sort: $!";
1050     #...                        # print stuff to output
1051     close OUTPUT                # wait for sort to finish
1052         or warn $! ? "Error closing sort pipe: $!"
1053                    : "Exit status $? from sort";
1054     open(INPUT, 'foo')          # get sort's results
1055         or die "Can't open 'foo' for input: $!";
1056
1057 FILEHANDLE may be an expression whose value can be used as an indirect
1058 filehandle, usually the real filehandle name or an autovivified handle.
1059
1060 =item closedir DIRHANDLE
1061 X<closedir>
1062
1063 =for Pod::Functions close directory handle
1064
1065 Closes a directory opened by C<opendir> and returns the success of that
1066 system call.
1067
1068 =item connect SOCKET,NAME
1069 X<connect>
1070
1071 =for Pod::Functions connect to a remote socket
1072
1073 Attempts to connect to a remote socket, just like connect(2).
1074 Returns true if it succeeded, false otherwise.  NAME should be a
1075 packed address of the appropriate type for the socket.  See the examples in
1076 L<perlipc/"Sockets: Client/Server Communication">.
1077
1078 =item continue BLOCK
1079 X<continue>
1080
1081 =item continue
1082
1083 =for Pod::Functions optional trailing block in a while or foreach
1084
1085 When followed by a BLOCK, C<continue> is actually a
1086 flow control statement rather than a function.  If
1087 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
1088 C<foreach>), it is always executed just before the conditional is about to
1089 be evaluated again, just like the third part of a C<for> loop in C.  Thus
1090 it can be used to increment a loop variable, even when the loop has been
1091 continued via the C<next> statement (which is similar to the C C<continue>
1092 statement).
1093
1094 C<last>, C<next>, or C<redo> may appear within a C<continue>
1095 block; C<last> and C<redo> behave as if they had been executed within
1096 the main block.  So will C<next>, but since it will execute a C<continue>
1097 block, it may be more entertaining.
1098
1099     while (EXPR) {
1100         ### redo always comes here
1101         do_something;
1102     } continue {
1103         ### next always comes here
1104         do_something_else;
1105         # then back the top to re-check EXPR
1106     }
1107     ### last always comes here
1108
1109 Omitting the C<continue> section is equivalent to using an
1110 empty one, logically enough, so C<next> goes directly back
1111 to check the condition at the top of the loop.
1112
1113 When there is no BLOCK, C<continue> is a function that
1114 falls through the current C<when> or C<default> block instead of iterating
1115 a dynamically enclosing C<foreach> or exiting a lexically enclosing C<given>.
1116 In Perl 5.14 and earlier, this form of C<continue> was
1117 only available when the C<"switch"> feature was enabled.
1118 See L<feature> and L<perlsyn/"Switch Statements"> for more
1119 information.
1120
1121 =item cos EXPR
1122 X<cos> X<cosine> X<acos> X<arccosine>
1123
1124 =item cos
1125
1126 =for Pod::Functions cosine function
1127
1128 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
1129 takes the cosine of C<$_>.
1130
1131 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
1132 function, or use this relation:
1133
1134     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
1135
1136 =item crypt PLAINTEXT,SALT
1137 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
1138 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1139
1140 =for Pod::Functions one-way passwd-style encryption
1141
1142 Creates a digest string exactly like the crypt(3) function in the C
1143 library (assuming that you actually have a version there that has not
1144 been extirpated as a potential munition).
1145
1146 crypt() is a one-way hash function.  The PLAINTEXT and SALT are turned
1147 into a short string, called a digest, which is returned.  The same
1148 PLAINTEXT and SALT will always return the same string, but there is no
1149 (known) way to get the original PLAINTEXT from the hash.  Small
1150 changes in the PLAINTEXT or SALT will result in large changes in the
1151 digest.
1152
1153 There is no decrypt function.  This function isn't all that useful for
1154 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1155 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1156 primarily used to check if two pieces of text are the same without
1157 having to transmit or store the text itself.  An example is checking
1158 if a correct password is given.  The digest of the password is stored,
1159 not the password itself.  The user types in a password that is
1160 crypt()'d with the same salt as the stored digest.  If the two digests
1161 match, the password is correct.
1162
1163 When verifying an existing digest string you should use the digest as
1164 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1165 to create the digest is visible as part of the digest.  This ensures
1166 crypt() will hash the new string with the same salt as the digest.
1167 This allows your code to work with the standard L<crypt|/crypt> and
1168 with more exotic implementations.  In other words, assume
1169 nothing about the returned string itself nor about how many bytes 
1170 of SALT may matter.
1171
1172 Traditionally the result is a string of 13 bytes: two first bytes of
1173 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1174 the first eight bytes of PLAINTEXT mattered.  But alternative
1175 hashing schemes (like MD5), higher level security schemes (like C2),
1176 and implementations on non-Unix platforms may produce different
1177 strings.
1178
1179 When choosing a new salt create a random two character string whose
1180 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1181 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1182 characters is just a recommendation; the characters allowed in
1183 the salt depend solely on your system's crypt library, and Perl can't
1184 restrict what salts C<crypt()> accepts.
1185
1186 Here's an example that makes sure that whoever runs this program knows
1187 their password:
1188
1189     $pwd = (getpwuid($<))[1];
1190
1191     system "stty -echo";
1192     print "Password: ";
1193     chomp($word = <STDIN>);
1194     print "\n";
1195     system "stty echo";
1196
1197     if (crypt($word, $pwd) ne $pwd) {
1198         die "Sorry...\n";
1199     } else {
1200         print "ok\n";
1201     }
1202
1203 Of course, typing in your own password to whoever asks you
1204 for it is unwise.
1205
1206 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1207 of data, not least of all because you can't get the information
1208 back.  Look at the L<Digest> module for more robust algorithms.
1209
1210 If using crypt() on a Unicode string (which I<potentially> has
1211 characters with codepoints above 255), Perl tries to make sense
1212 of the situation by trying to downgrade (a copy of)
1213 the string back to an eight-bit byte string before calling crypt()
1214 (on that copy).  If that works, good.  If not, crypt() dies with
1215 C<Wide character in crypt>.
1216
1217 Portability issues: L<perlport/crypt>.
1218
1219 =item dbmclose HASH
1220 X<dbmclose>
1221
1222 =for Pod::Functions breaks binding on a tied dbm file
1223
1224 [This function has been largely superseded by the C<untie> function.]
1225
1226 Breaks the binding between a DBM file and a hash.
1227
1228 Portability issues: L<perlport/dbmclose>.
1229
1230 =item dbmopen HASH,DBNAME,MASK
1231 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1232
1233 =for Pod::Functions create binding on a tied dbm file
1234
1235 [This function has been largely superseded by the
1236 L<tie|/tie VARIABLE,CLASSNAME,LIST> function.]
1237
1238 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1239 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1240 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1241 is the name of the database (without the F<.dir> or F<.pag> extension if
1242 any).  If the database does not exist, it is created with protection
1243 specified by MASK (as modified by the C<umask>).  To prevent creation of
1244 the database if it doesn't exist, you may specify a MODE
1245 of 0, and the function will return a false value if it
1246 can't find an existing database.  If your system supports
1247 only the older DBM functions, you may make only one C<dbmopen> call in your
1248 program.  In older versions of Perl, if your system had neither DBM nor
1249 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1250 sdbm(3).
1251
1252 If you don't have write access to the DBM file, you can only read hash
1253 variables, not set them.  If you want to test whether you can write,
1254 either use file tests or try setting a dummy hash entry inside an C<eval> 
1255 to trap the error.
1256
1257 Note that functions such as C<keys> and C<values> may return huge lists
1258 when used on large DBM files.  You may prefer to use the C<each>
1259 function to iterate over large DBM files.  Example:
1260
1261     # print out history file offsets
1262     dbmopen(%HIST,'/usr/lib/news/history',0666);
1263     while (($key,$val) = each %HIST) {
1264         print $key, ' = ', unpack('L',$val), "\n";
1265     }
1266     dbmclose(%HIST);
1267
1268 See also L<AnyDBM_File> for a more general description of the pros and
1269 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1270 rich implementation.
1271
1272 You can control which DBM library you use by loading that library
1273 before you call dbmopen():
1274
1275     use DB_File;
1276     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1277         or die "Can't open netscape history file: $!";
1278
1279 Portability issues: L<perlport/dbmopen>.
1280
1281 =item defined EXPR
1282 X<defined> X<undef> X<undefined>
1283
1284 =item defined
1285
1286 =for Pod::Functions test whether a value, variable, or function is defined
1287
1288 Returns a Boolean value telling whether EXPR has a value other than
1289 the undefined value C<undef>.  If EXPR is not present, C<$_> is
1290 checked.
1291
1292 Many operations return C<undef> to indicate failure, end of file,
1293 system error, uninitialized variable, and other exceptional
1294 conditions.  This function allows you to distinguish C<undef> from
1295 other values.  (A simple Boolean test will not distinguish among
1296 C<undef>, zero, the empty string, and C<"0">, which are all equally
1297 false.)  Note that since C<undef> is a valid scalar, its presence
1298 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1299 returns C<undef> when its argument is an empty array, I<or> when the
1300 element to return happens to be C<undef>.
1301
1302 You may also use C<defined(&func)> to check whether subroutine C<&func>
1303 has ever been defined.  The return value is unaffected by any forward
1304 declarations of C<&func>.  A subroutine that is not defined
1305 may still be callable: its package may have an C<AUTOLOAD> method that
1306 makes it spring into existence the first time that it is called; see
1307 L<perlsub>.
1308
1309 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1310 used to report whether memory for that aggregate had ever been
1311 allocated.  This behavior may disappear in future versions of Perl.
1312 You should instead use a simple test for size:
1313
1314     if (@an_array) { print "has array elements\n" }
1315     if (%a_hash)   { print "has hash members\n"   }
1316
1317 When used on a hash element, it tells you whether the value is defined,
1318 not whether the key exists in the hash.  Use L</exists> for the latter
1319 purpose.
1320
1321 Examples:
1322
1323     print if defined $switch{D};
1324     print "$val\n" while defined($val = pop(@ary));
1325     die "Can't readlink $sym: $!"
1326         unless defined($value = readlink $sym);
1327     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1328     $debugging = 0 unless defined $debugging;
1329
1330 Note:  Many folks tend to overuse C<defined> and are then surprised to
1331 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1332 defined values.  For example, if you say
1333
1334     "ab" =~ /a(.*)b/;
1335
1336 The pattern match succeeds and C<$1> is defined, although it
1337 matched "nothing".  It didn't really fail to match anything.  Rather, it
1338 matched something that happened to be zero characters long.  This is all
1339 very above-board and honest.  When a function returns an undefined value,
1340 it's an admission that it couldn't give you an honest answer.  So you
1341 should use C<defined> only when questioning the integrity of what
1342 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1343 what you want.
1344
1345 See also L</undef>, L</exists>, L</ref>.
1346
1347 =item delete EXPR
1348 X<delete>
1349
1350 =for Pod::Functions deletes a value from a hash
1351
1352 Given an expression that specifies an element or slice of a hash, C<delete>
1353 deletes the specified elements from that hash so that exists() on that element
1354 no longer returns true.  Setting a hash element to the undefined value does
1355 not remove its key, but deleting it does; see L</exists>.
1356
1357 In list context, returns the value or values deleted, or the last such
1358 element in scalar context.  The return list's length always matches that of
1359 the argument list: deleting non-existent elements returns the undefined value
1360 in their corresponding positions.
1361
1362 delete() may also be used on arrays and array slices, but its behavior is less
1363 straightforward.  Although exists() will return false for deleted entries,
1364 deleting array elements never changes indices of existing values; use shift()
1365 or splice() for that.  However, if all deleted elements fall at the end of an
1366 array, the array's size shrinks to the position of the highest element that
1367 still tests true for exists(), or to 0 if none do.
1368
1369 B<WARNING:> Calling delete on array values is deprecated and likely to
1370 be removed in a future version of Perl.
1371
1372 Deleting from C<%ENV> modifies the environment.  Deleting from a hash tied to
1373 a DBM file deletes the entry from the DBM file.  Deleting from a C<tied> hash
1374 or array may not necessarily return anything; it depends on the implementation
1375 of the C<tied> package's DELETE method, which may do whatever it pleases.
1376
1377 The C<delete local EXPR> construct localizes the deletion to the current
1378 block at run time.  Until the block exits, elements locally deleted
1379 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1380 of composite types">.
1381
1382     %hash = (foo => 11, bar => 22, baz => 33);
1383     $scalar = delete $hash{foo};         # $scalar is 11
1384     $scalar = delete @hash{qw(foo bar)}; # $scalar is 22
1385     @array  = delete @hash{qw(foo baz)}; # @array  is (undef,33)
1386
1387 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1388
1389     foreach $key (keys %HASH) {
1390         delete $HASH{$key};
1391     }
1392
1393     foreach $index (0 .. $#ARRAY) {
1394         delete $ARRAY[$index];
1395     }
1396
1397 And so do these:
1398
1399     delete @HASH{keys %HASH};
1400
1401     delete @ARRAY[0 .. $#ARRAY];
1402
1403 But both are slower than assigning the empty list
1404 or undefining %HASH or @ARRAY, which is the customary 
1405 way to empty out an aggregate:
1406
1407     %HASH = ();     # completely empty %HASH
1408     undef %HASH;    # forget %HASH ever existed
1409
1410     @ARRAY = ();    # completely empty @ARRAY
1411     undef @ARRAY;   # forget @ARRAY ever existed
1412
1413 The EXPR can be arbitrarily complicated provided its
1414 final operation is an element or slice of an aggregate:
1415
1416     delete $ref->[$x][$y]{$key};
1417     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1418
1419     delete $ref->[$x][$y][$index];
1420     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1421
1422 =item die LIST
1423 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1424
1425 =for Pod::Functions raise an exception or bail out
1426
1427 C<die> raises an exception.  Inside an C<eval> the error message is stuffed
1428 into C<$@> and the C<eval> is terminated with the undefined value.
1429 If the exception is outside of all enclosing C<eval>s, then the uncaught
1430 exception prints LIST to C<STDERR> and exits with a non-zero value.  If you
1431 need to exit the process with a specific exit code, see L</exit>.
1432
1433 Equivalent examples:
1434
1435     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1436     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1437
1438 If the last element of LIST does not end in a newline, the current
1439 script line number and input line number (if any) are also printed,
1440 and a newline is supplied.  Note that the "input line number" (also
1441 known as "chunk") is subject to whatever notion of "line" happens to
1442 be currently in effect, and is also available as the special variable
1443 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1444
1445 Hint: sometimes appending C<", stopped"> to your message will cause it
1446 to make better sense when the string C<"at foo line 123"> is appended.
1447 Suppose you are running script "canasta".
1448
1449     die "/etc/games is no good";
1450     die "/etc/games is no good, stopped";
1451
1452 produce, respectively
1453
1454     /etc/games is no good at canasta line 123.
1455     /etc/games is no good, stopped at canasta line 123.
1456
1457 If the output is empty and C<$@> already contains a value (typically from a
1458 previous eval) that value is reused after appending C<"\t...propagated">.
1459 This is useful for propagating exceptions:
1460
1461     eval { ... };
1462     die unless $@ =~ /Expected exception/;
1463
1464 If the output is empty and C<$@> contains an object reference that has a
1465 C<PROPAGATE> method, that method will be called with additional file
1466 and line number parameters.  The return value replaces the value in
1467 C<$@>;  i.e., as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1468 were called.
1469
1470 If C<$@> is empty then the string C<"Died"> is used.
1471
1472 If an uncaught exception results in interpreter exit, the exit code is
1473 determined from the values of C<$!> and C<$?> with this pseudocode:
1474
1475     exit $! if $!;              # errno
1476     exit $? >> 8 if $? >> 8;    # child exit status
1477     exit 255;                   # last resort
1478
1479 The intent is to squeeze as much possible information about the likely cause
1480 into the limited space of the system exit
1481 code.  However, as C<$!> is the value
1482 of C's C<errno>, which can be set by any system call, this means that the value
1483 of the exit code used by C<die> can be non-predictable, so should not be relied
1484 upon, other than to be non-zero.
1485
1486 You can also call C<die> with a reference argument, and if this is trapped
1487 within an C<eval>, C<$@> contains that reference.  This permits more
1488 elaborate exception handling using objects that maintain arbitrary state
1489 about the exception.  Such a scheme is sometimes preferable to matching
1490 particular string values of C<$@> with regular expressions.  Because C<$@> 
1491 is a global variable and C<eval> may be used within object implementations,
1492 be careful that analyzing the error object doesn't replace the reference in
1493 the global variable.  It's easiest to make a local copy of the reference
1494 before any manipulations.  Here's an example:
1495
1496     use Scalar::Util "blessed";
1497
1498     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1499     if (my $ev_err = $@) {
1500         if (blessed($ev_err)
1501             && $ev_err->isa("Some::Module::Exception")) {
1502             # handle Some::Module::Exception
1503         }
1504         else {
1505             # handle all other possible exceptions
1506         }
1507     }
1508
1509 Because Perl stringifies uncaught exception messages before display,
1510 you'll probably want to overload stringification operations on
1511 exception objects.  See L<overload> for details about that.
1512
1513 You can arrange for a callback to be run just before the C<die>
1514 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1515 handler is called with the error text and can change the error
1516 message, if it sees fit, by calling C<die> again.  See
1517 L<perlvar/%SIG> for details on setting C<%SIG> entries, and
1518 L<"eval BLOCK"> for some examples.  Although this feature was 
1519 to be run only right before your program was to exit, this is not
1520 currently so: the C<$SIG{__DIE__}> hook is currently called
1521 even inside eval()ed blocks/strings!  If one wants the hook to do
1522 nothing in such situations, put
1523
1524     die @_ if $^S;
1525
1526 as the first line of the handler (see L<perlvar/$^S>).  Because
1527 this promotes strange action at a distance, this counterintuitive
1528 behavior may be fixed in a future release.
1529
1530 See also exit(), warn(), and the Carp module.
1531
1532 =item do BLOCK
1533 X<do> X<block>
1534
1535 =for Pod::Functions turn a BLOCK into a TERM
1536
1537 Not really a function.  Returns the value of the last command in the
1538 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1539 C<until> loop modifier, executes the BLOCK once before testing the loop
1540 condition.  (On other statements the loop modifiers test the conditional
1541 first.)
1542
1543 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1544 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1545 See L<perlsyn> for alternative strategies.
1546
1547 =item do SUBROUTINE(LIST)
1548 X<do>
1549
1550 This form of subroutine call is deprecated.  SUBROUTINE can be a bareword
1551 or scalar variable.
1552
1553 =item do EXPR
1554 X<do>
1555
1556 Uses the value of EXPR as a filename and executes the contents of the
1557 file as a Perl script.
1558
1559     do 'stat.pl';
1560
1561 is largely like
1562
1563     eval `cat stat.pl`;
1564
1565 except that it's more concise, runs no external processes, keeps track of
1566 the current
1567 filename for error messages, searches the C<@INC> directories, and updates
1568 C<%INC> if the file is found.  See L<perlvar/@INC> and L<perlvar/%INC> for
1569 these variables.  It also differs in that code evaluated with C<do FILENAME>
1570 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1571 same, however, in that it does reparse the file every time you call it,
1572 so you probably don't want to do this inside a loop.
1573
1574 If C<do> can read the file but cannot compile it, it returns C<undef> and sets
1575 an error message in C<$@>.  If C<do> cannot read the file, it returns undef
1576 and sets C<$!> to the error.  Always check C<$@> first, as compilation
1577 could fail in a way that also sets C<$!>.  If the file is successfully
1578 compiled, C<do> returns the value of the last expression evaluated.
1579
1580 Inclusion of library modules is better done with the
1581 C<use> and C<require> operators, which also do automatic error checking
1582 and raise an exception if there's a problem.
1583
1584 You might like to use C<do> to read in a program configuration
1585 file.  Manual error checking can be done this way:
1586
1587     # read in config files: system first, then user
1588     for $file ("/share/prog/defaults.rc",
1589                "$ENV{HOME}/.someprogrc")
1590     {
1591         unless ($return = do $file) {
1592             warn "couldn't parse $file: $@" if $@;
1593             warn "couldn't do $file: $!"    unless defined $return;
1594             warn "couldn't run $file"       unless $return;
1595         }
1596     }
1597
1598 =item dump LABEL
1599 X<dump> X<core> X<undump>
1600
1601 =item dump EXPR
1602
1603 =item dump
1604
1605 =for Pod::Functions create an immediate core dump
1606
1607 This function causes an immediate core dump.  See also the B<-u>
1608 command-line switch in L<perlrun>, which does the same thing.
1609 Primarily this is so that you can use the B<undump> program (not
1610 supplied) to turn your core dump into an executable binary after
1611 having initialized all your variables at the beginning of the
1612 program.  When the new binary is executed it will begin by executing
1613 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1614 Think of it as a goto with an intervening core dump and reincarnation.
1615 If C<LABEL> is omitted, restarts the program from the top.  The
1616 C<dump EXPR> form, available starting in Perl 5.18.0, allows a name to be
1617 computed at run time, being otherwise identical to C<dump LABEL>.
1618
1619 B<WARNING>: Any files opened at the time of the dump will I<not>
1620 be open any more when the program is reincarnated, with possible
1621 resulting confusion by Perl.
1622
1623 This function is now largely obsolete, mostly because it's very hard to
1624 convert a core file into an executable.  That's why you should now invoke
1625 it as C<CORE::dump()>, if you don't want to be warned against a possible
1626 typo.
1627
1628 Unlike most named operators, this has the same precedence as assignment.
1629 It is also exempt from the looks-like-a-function rule, so
1630 C<dump ("foo")."bar"> will cause "bar" to be part of the argument to
1631 C<dump>.
1632
1633 Portability issues: L<perlport/dump>.
1634
1635 =item each HASH
1636 X<each> X<hash, iterator>
1637
1638 =item each ARRAY
1639 X<array, iterator>
1640
1641 =item each EXPR
1642
1643 =for Pod::Functions retrieve the next key/value pair from a hash
1644
1645 When called on a hash in list context, returns a 2-element list
1646 consisting of the key and value for the next element of a hash.  In Perl
1647 5.12 and later only, it will also return the index and value for the next
1648 element of an array so that you can iterate over it; older Perls consider
1649 this a syntax error.  When called in scalar context, returns only the key
1650 (not the value) in a hash, or the index in an array.
1651
1652 Hash entries are returned in an apparently random order.  The actual random
1653 order is specific to a given hash; the exact same series of operations
1654 on two hashes may result in a different order for each hash. Any insertion
1655 into the hash may change the order, as will any deletion, with the exception
1656 that the most recent key returned by C<each> or C<keys> may be deleted
1657 without changing the order. So long as a given hash is unmodified you may
1658 rely on C<keys>, C<values> and C<each> to repeatedly return the same order
1659 as each other. See L<perlsec/"Algorithmic Complexity Attacks"> for
1660 details on why hash order is randomized. Aside from the guarantees
1661 provided here the exact details of Perl's hash algorithm and the hash
1662 traversal order are subject to change in any release of Perl.
1663
1664 After C<each> has returned all entries from the hash or array, the next
1665 call to C<each> returns the empty list in list context and C<undef> in
1666 scalar context; the next call following I<that> one restarts iteration.
1667 Each hash or array has its own internal iterator, accessed by C<each>,
1668 C<keys>, and C<values>.  The iterator is implicitly reset when C<each> has
1669 reached the end as just described; it can be explicitly reset by calling
1670 C<keys> or C<values> on the hash or array.  If you add or delete a hash's
1671 elements while iterating over it, entries may be skipped or duplicated--so
1672 don't do that.  Exception: In the current implementation, it is always safe
1673 to delete the item most recently returned by C<each()>, so the following
1674 code works properly:
1675
1676         while (($key, $value) = each %hash) {
1677           print $key, "\n";
1678           delete $hash{$key};   # This is safe
1679         }
1680
1681 This prints out your environment like the printenv(1) program,
1682 but in a different order:
1683
1684     while (($key,$value) = each %ENV) {
1685         print "$key=$value\n";
1686     }
1687
1688 Starting with Perl 5.14, C<each> can take a scalar EXPR, which must hold
1689 reference to an unblessed hash or array.  The argument will be dereferenced
1690 automatically.  This aspect of C<each> is considered highly experimental.
1691 The exact behaviour may change in a future version of Perl.
1692
1693     while (($key,$value) = each $hashref) { ... }
1694
1695 As of Perl 5.18 you can use a bare C<each> in a C<while> loop,
1696 which will set C<$_> on every iteration.
1697
1698     while(each %ENV) {
1699         print "$_=$ENV{$_}\n";
1700     }
1701
1702 To avoid confusing would-be users of your code who are running earlier
1703 versions of Perl with mysterious syntax errors, put this sort of thing at
1704 the top of your file to signal that your code will work I<only> on Perls of
1705 a recent vintage:
1706
1707     use 5.012;  # so keys/values/each work on arrays
1708     use 5.014;  # so keys/values/each work on scalars (experimental)
1709     use 5.018;  # so each assigns to $_ in a lone while test
1710
1711 See also C<keys>, C<values>, and C<sort>.
1712
1713 =item eof FILEHANDLE
1714 X<eof>
1715 X<end of file>
1716 X<end-of-file>
1717
1718 =item eof ()
1719
1720 =item eof
1721
1722 =for Pod::Functions test a filehandle for its end
1723
1724 Returns 1 if the next read on FILEHANDLE will return end of file I<or> if
1725 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1726 gives the real filehandle.  (Note that this function actually
1727 reads a character and then C<ungetc>s it, so isn't useful in an
1728 interactive context.)  Do not read from a terminal file (or call
1729 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1730 as terminals may lose the end-of-file condition if you do.
1731
1732 An C<eof> without an argument uses the last file read.  Using C<eof()>
1733 with empty parentheses is different.  It refers to the pseudo file
1734 formed from the files listed on the command line and accessed via the
1735 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1736 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1737 used will cause C<@ARGV> to be examined to determine if input is
1738 available.   Similarly, an C<eof()> after C<< <> >> has returned
1739 end-of-file will assume you are processing another C<@ARGV> list,
1740 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1741 see L<perlop/"I/O Operators">.
1742
1743 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1744 detect the end of each file, whereas C<eof()> will detect the end 
1745 of the very last file only.  Examples:
1746
1747     # reset line numbering on each input file
1748     while (<>) {
1749         next if /^\s*#/;  # skip comments
1750         print "$.\t$_";
1751     } continue {
1752         close ARGV if eof;  # Not eof()!
1753     }
1754
1755     # insert dashes just before last line of last file
1756     while (<>) {
1757         if (eof()) {  # check for end of last file
1758             print "--------------\n";
1759         }
1760         print;
1761         last if eof();     # needed if we're reading from a terminal
1762     }
1763
1764 Practical hint: you almost never need to use C<eof> in Perl, because the
1765 input operators typically return C<undef> when they run out of data or 
1766 encounter an error.
1767
1768 =item eval EXPR
1769 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1770 X<error, handling> X<exception, handling>
1771
1772 =item eval BLOCK
1773
1774 =item eval
1775
1776 =for Pod::Functions catch exceptions or compile and run code
1777
1778 In the first form, the return value of EXPR is parsed and executed as if it
1779 were a little Perl program.  The value of the expression (which is itself
1780 determined within scalar context) is first parsed, and if there were no
1781 errors, executed as a block within the lexical context of the current Perl
1782 program.  This means, that in particular, any outer lexical variables are
1783 visible to it, and any package variable settings or subroutine and format
1784 definitions remain afterwards.
1785
1786 Note that the value is parsed every time the C<eval> executes.
1787 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1788 delay parsing and subsequent execution of the text of EXPR until run time.
1789
1790 If the C<unicode_eval> feature is enabled (which is the default under a
1791 C<use 5.16> or higher declaration), EXPR or C<$_> is treated as a string of
1792 characters, so C<use utf8> declarations have no effect, and source filters
1793 are forbidden.  In the absence of the C<unicode_eval> feature, the string
1794 will sometimes be treated as characters and sometimes as bytes, depending
1795 on the internal encoding, and source filters activated within the C<eval>
1796 exhibit the erratic, but historical, behaviour of affecting some outer file
1797 scope that is still compiling.  See also the L</evalbytes> keyword, which
1798 always treats its input as a byte stream and works properly with source
1799 filters, and the L<feature> pragma.
1800
1801 In the second form, the code within the BLOCK is parsed only once--at the
1802 same time the code surrounding the C<eval> itself was parsed--and executed
1803 within the context of the current Perl program.  This form is typically
1804 used to trap exceptions more efficiently than the first (see below), while
1805 also providing the benefit of checking the code within BLOCK at compile
1806 time.
1807
1808 The final semicolon, if any, may be omitted from the value of EXPR or within
1809 the BLOCK.
1810
1811 In both forms, the value returned is the value of the last expression
1812 evaluated inside the mini-program; a return statement may be also used, just
1813 as with subroutines.  The expression providing the return value is evaluated
1814 in void, scalar, or list context, depending on the context of the C<eval> 
1815 itself.  See L</wantarray> for more on how the evaluation context can be 
1816 determined.
1817
1818 If there is a syntax error or runtime error, or a C<die> statement is
1819 executed, C<eval> returns C<undef> in scalar context
1820 or an empty list in list context, and C<$@> is set to the error
1821 message.  (Prior to 5.16, a bug caused C<undef> to be returned
1822 in list context for syntax errors, but not for runtime errors.)
1823 If there was no error, C<$@> is set to the empty string.  A
1824 control flow operator like C<last> or C<goto> can bypass the setting of
1825 C<$@>.  Beware that using C<eval> neither silences Perl from printing
1826 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1827 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1828 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1829 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1830
1831 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1832 determining whether a particular feature (such as C<socket> or C<symlink>)
1833 is implemented.  It is also Perl's exception-trapping mechanism, where
1834 the die operator is used to raise exceptions.
1835
1836 If you want to trap errors when loading an XS module, some problems with
1837 the binary interface (such as Perl version skew) may be fatal even with
1838 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set.  See L<perlrun>.
1839
1840 If the code to be executed doesn't vary, you may use the eval-BLOCK
1841 form to trap run-time errors without incurring the penalty of
1842 recompiling each time.  The error, if any, is still returned in C<$@>.
1843 Examples:
1844
1845     # make divide-by-zero nonfatal
1846     eval { $answer = $a / $b; }; warn $@ if $@;
1847
1848     # same thing, but less efficient
1849     eval '$answer = $a / $b'; warn $@ if $@;
1850
1851     # a compile-time error
1852     eval { $answer = }; # WRONG
1853
1854     # a run-time error
1855     eval '$answer =';   # sets $@
1856
1857 Using the C<eval{}> form as an exception trap in libraries does have some
1858 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1859 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1860 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1861 as this example shows:
1862
1863     # a private exception trap for divide-by-zero
1864     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1865     warn $@ if $@;
1866
1867 This is especially significant, given that C<__DIE__> hooks can call
1868 C<die> again, which has the effect of changing their error messages:
1869
1870     # __DIE__ hooks may modify error messages
1871     {
1872        local $SIG{'__DIE__'} =
1873               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1874        eval { die "foo lives here" };
1875        print $@ if $@;                # prints "bar lives here"
1876     }
1877
1878 Because this promotes action at a distance, this counterintuitive behavior
1879 may be fixed in a future release.
1880
1881 With an C<eval>, you should be especially careful to remember what's
1882 being looked at when:
1883
1884     eval $x;        # CASE 1
1885     eval "$x";      # CASE 2
1886
1887     eval '$x';      # CASE 3
1888     eval { $x };    # CASE 4
1889
1890     eval "\$$x++";  # CASE 5
1891     $$x++;          # CASE 6
1892
1893 Cases 1 and 2 above behave identically: they run the code contained in
1894 the variable $x.  (Although case 2 has misleading double quotes making
1895 the reader wonder what else might be happening (nothing is).)  Cases 3
1896 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1897 does nothing but return the value of $x.  (Case 4 is preferred for
1898 purely visual reasons, but it also has the advantage of compiling at
1899 compile-time instead of at run-time.)  Case 5 is a place where
1900 normally you I<would> like to use double quotes, except that in this
1901 particular situation, you can just use symbolic references instead, as
1902 in case 6.
1903
1904 Before Perl 5.14, the assignment to C<$@> occurred before restoration 
1905 of localized variables, which means that for your code to run on older
1906 versions, a temporary is required if you want to mask some but not all
1907 errors:
1908
1909     # alter $@ on nefarious repugnancy only
1910     {
1911        my $e;
1912        {
1913          local $@; # protect existing $@
1914          eval { test_repugnancy() };
1915          # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only
1916          $@ =~ /nefarious/ and $e = $@;
1917        }
1918        die $e if defined $e
1919     }
1920
1921 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1922 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1923
1924 An C<eval ''> executed within a subroutine defined
1925 in the C<DB> package doesn't see the usual
1926 surrounding lexical scope, but rather the scope of the first non-DB piece
1927 of code that called it.  You don't normally need to worry about this unless
1928 you are writing a Perl debugger.
1929
1930 =item evalbytes EXPR
1931 X<evalbytes>
1932
1933 =item evalbytes
1934
1935 =for Pod::Functions +evalbytes similar to string eval, but intend to parse a bytestream
1936
1937 This function is like L</eval> with a string argument, except it always
1938 parses its argument, or C<$_> if EXPR is omitted, as a string of bytes.  A
1939 string containing characters whose ordinal value exceeds 255 results in an
1940 error.  Source filters activated within the evaluated code apply to the
1941 code itself.
1942
1943 This function is only available under the C<evalbytes> feature, a
1944 C<use v5.16> (or higher) declaration, or with a C<CORE::> prefix.  See
1945 L<feature> for more information.
1946
1947 =item exec LIST
1948 X<exec> X<execute>
1949
1950 =item exec PROGRAM LIST
1951
1952 =for Pod::Functions abandon this program to run another
1953
1954 The C<exec> function executes a system command I<and never returns>;
1955 use C<system> instead of C<exec> if you want it to return.  It fails and
1956 returns false only if the command does not exist I<and> it is executed
1957 directly instead of via your system's command shell (see below).
1958
1959 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1960 warns you if C<exec> is called in void context and if there is a following
1961 statement that isn't C<die>, C<warn>, or C<exit> (if C<-w> is set--but
1962 you always do that, right?).  If you I<really> want to follow an C<exec>
1963 with some other statement, you can use one of these styles to avoid the warning:
1964
1965     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1966     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1967
1968 If there is more than one argument in LIST, or if LIST is an array
1969 with more than one value, calls execvp(3) with the arguments in LIST.
1970 If there is only one scalar argument or an array with one element in it,
1971 the argument is checked for shell metacharacters, and if there are any,
1972 the entire argument is passed to the system's command shell for parsing
1973 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1974 If there are no shell metacharacters in the argument, it is split into
1975 words and passed directly to C<execvp>, which is more efficient.
1976 Examples:
1977
1978     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1979     exec "sort $outfile | uniq";
1980
1981 If you don't really want to execute the first argument, but want to lie
1982 to the program you are executing about its own name, you can specify
1983 the program you actually want to run as an "indirect object" (without a
1984 comma) in front of the LIST.  (This always forces interpretation of the
1985 LIST as a multivalued list, even if there is only a single scalar in
1986 the list.)  Example:
1987
1988     $shell = '/bin/csh';
1989     exec $shell '-sh';    # pretend it's a login shell
1990
1991 or, more directly,
1992
1993     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
1994
1995 When the arguments get executed via the system shell, results are
1996 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1997 for details.
1998
1999 Using an indirect object with C<exec> or C<system> is also more
2000 secure.  This usage (which also works fine with system()) forces
2001 interpretation of the arguments as a multivalued list, even if the
2002 list had just one argument.  That way you're safe from the shell
2003 expanding wildcards or splitting up words with whitespace in them.
2004
2005     @args = ( "echo surprise" );
2006
2007     exec @args;               # subject to shell escapes
2008                                 # if @args == 1
2009     exec { $args[0] } @args;  # safe even with one-arg list
2010
2011 The first version, the one without the indirect object, ran the I<echo>
2012 program, passing it C<"surprise"> an argument.  The second version didn't;
2013 it tried to run a program named I<"echo surprise">, didn't find it, and set
2014 C<$?> to a non-zero value indicating failure.
2015
2016 Perl attempts to flush all files opened for output before the exec,
2017 but this may not be supported on some platforms (see L<perlport>).
2018 To be safe, you may need to set C<$|> ($AUTOFLUSH in English) or
2019 call the C<autoflush()> method of C<IO::Handle> on any open handles
2020 to avoid lost output.
2021
2022 Note that C<exec> will not call your C<END> blocks, nor will it invoke
2023 C<DESTROY> methods on your objects.
2024
2025 Portability issues: L<perlport/exec>.
2026
2027 =item exists EXPR
2028 X<exists> X<autovivification>
2029
2030 =for Pod::Functions test whether a hash key is present
2031
2032 Given an expression that specifies an element of a hash, returns true if the
2033 specified element in the hash has ever been initialized, even if the
2034 corresponding value is undefined.
2035
2036     print "Exists\n"    if exists $hash{$key};
2037     print "Defined\n"   if defined $hash{$key};
2038     print "True\n"      if $hash{$key};
2039
2040 exists may also be called on array elements, but its behavior is much less
2041 obvious and is strongly tied to the use of L</delete> on arrays.  B<Be aware>
2042 that calling exists on array values is deprecated and likely to be removed in
2043 a future version of Perl.
2044
2045     print "Exists\n"    if exists $array[$index];
2046     print "Defined\n"   if defined $array[$index];
2047     print "True\n"      if $array[$index];
2048
2049 A hash or array element can be true only if it's defined and defined only if
2050 it exists, but the reverse doesn't necessarily hold true.
2051
2052 Given an expression that specifies the name of a subroutine,
2053 returns true if the specified subroutine has ever been declared, even
2054 if it is undefined.  Mentioning a subroutine name for exists or defined
2055 does not count as declaring it.  Note that a subroutine that does not
2056 exist may still be callable: its package may have an C<AUTOLOAD>
2057 method that makes it spring into existence the first time that it is
2058 called; see L<perlsub>.
2059
2060     print "Exists\n"  if exists &subroutine;
2061     print "Defined\n" if defined &subroutine;
2062
2063 Note that the EXPR can be arbitrarily complicated as long as the final
2064 operation is a hash or array key lookup or subroutine name:
2065
2066     if (exists $ref->{A}->{B}->{$key})  { }
2067     if (exists $hash{A}{B}{$key})       { }
2068
2069     if (exists $ref->{A}->{B}->[$ix])   { }
2070     if (exists $hash{A}{B}[$ix])        { }
2071
2072     if (exists &{$ref->{A}{B}{$key}})   { }
2073
2074 Although the most deeply nested array or hash element will not spring into
2075 existence just because its existence was tested, any intervening ones will.
2076 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
2077 into existence due to the existence test for the $key element above.
2078 This happens anywhere the arrow operator is used, including even here:
2079
2080     undef $ref;
2081     if (exists $ref->{"Some key"})    { }
2082     print $ref;  # prints HASH(0x80d3d5c)
2083
2084 This surprising autovivification in what does not at first--or even
2085 second--glance appear to be an lvalue context may be fixed in a future
2086 release.
2087
2088 Use of a subroutine call, rather than a subroutine name, as an argument
2089 to exists() is an error.
2090
2091     exists &sub;    # OK
2092     exists &sub();  # Error
2093
2094 =item exit EXPR
2095 X<exit> X<terminate> X<abort>
2096
2097 =item exit
2098
2099 =for Pod::Functions terminate this program
2100
2101 Evaluates EXPR and exits immediately with that value.    Example:
2102
2103     $ans = <STDIN>;
2104     exit 0 if $ans =~ /^[Xx]/;
2105
2106 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
2107 universally recognized values for EXPR are C<0> for success and C<1>
2108 for error; other values are subject to interpretation depending on the
2109 environment in which the Perl program is running.  For example, exiting
2110 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
2111 the mailer to return the item undelivered, but that's not true everywhere.
2112
2113 Don't use C<exit> to abort a subroutine if there's any chance that
2114 someone might want to trap whatever error happened.  Use C<die> instead,
2115 which can be trapped by an C<eval>.
2116
2117 The exit() function does not always exit immediately.  It calls any
2118 defined C<END> routines first, but these C<END> routines may not
2119 themselves abort the exit.  Likewise any object destructors that need to
2120 be called are called before the real exit.  C<END> routines and destructors
2121 can change the exit status by modifying C<$?>.  If this is a problem, you
2122 can call C<POSIX::_exit($status)> to avoid END and destructor processing.
2123 See L<perlmod> for details.
2124
2125 Portability issues: L<perlport/exit>.
2126
2127 =item exp EXPR
2128 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
2129
2130 =item exp
2131
2132 =for Pod::Functions raise I<e> to a power
2133
2134 Returns I<e> (the natural logarithm base) to the power of EXPR.
2135 If EXPR is omitted, gives C<exp($_)>.
2136
2137 =item fc EXPR
2138 X<fc> X<foldcase> X<casefold> X<fold-case> X<case-fold>
2139
2140 =item fc
2141
2142 =for Pod::Functions +fc return casefolded version of a string
2143
2144 Returns the casefolded version of EXPR.  This is the internal function
2145 implementing the C<\F> escape in double-quoted strings.
2146
2147 Casefolding is the process of mapping strings to a form where case
2148 differences are erased; comparing two strings in their casefolded
2149 form is effectively a way of asking if two strings are equal,
2150 regardless of case.
2151
2152 Roughly, if you ever found yourself writing this
2153
2154     lc($this) eq lc($that)    # Wrong!
2155         # or
2156     uc($this) eq uc($that)    # Also wrong!
2157         # or
2158     $this =~ /^\Q$that\E\z/i  # Right!
2159
2160 Now you can write
2161
2162     fc($this) eq fc($that)
2163
2164 And get the correct results.
2165
2166 Perl only implements the full form of casefolding,
2167 but you can access the simple folds using L<Unicode::UCD/casefold()> and
2168 L<Unicode::UCD/prop_invmap()>.
2169 For further information on casefolding, refer to
2170 the Unicode Standard, specifically sections 3.13 C<Default Case Operations>,
2171 4.2 C<Case-Normative>, and 5.18 C<Case Mappings>,
2172 available at L<http://www.unicode.org/versions/latest/>, as well as the
2173 Case Charts available at L<http://www.unicode.org/charts/case/>.
2174
2175 If EXPR is omitted, uses C<$_>.
2176
2177 This function behaves the same way under various pragma, such as in a locale,
2178 as L</lc> does.
2179
2180 While the Unicode Standard defines two additional forms of casefolding,
2181 one for Turkic languages and one that never maps one character into multiple
2182 characters, these are not provided by the Perl core; However, the CPAN module
2183 C<Unicode::Casing> may be used to provide an implementation.
2184
2185 This keyword is available only when the C<"fc"> feature is enabled,
2186 or when prefixed with C<CORE::>; See L<feature>. Alternately,
2187 include a C<use v5.16> or later to the current scope.
2188
2189 =item fcntl FILEHANDLE,FUNCTION,SCALAR
2190 X<fcntl>
2191
2192 =for Pod::Functions file control system call
2193
2194 Implements the fcntl(2) function.  You'll probably have to say
2195
2196     use Fcntl;
2197
2198 first to get the correct constant definitions.  Argument processing and
2199 value returned work just like C<ioctl> below.
2200 For example:
2201
2202     use Fcntl;
2203     fcntl($filehandle, F_GETFL, $packed_return_buffer)
2204         or die "can't fcntl F_GETFL: $!";
2205
2206 You don't have to check for C<defined> on the return from C<fcntl>.
2207 Like C<ioctl>, it maps a C<0> return from the system call into
2208 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
2209 in numeric context.  It is also exempt from the normal B<-w> warnings
2210 on improper numeric conversions.
2211
2212 Note that C<fcntl> raises an exception if used on a machine that
2213 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
2214 manpage to learn what functions are available on your system.
2215
2216 Here's an example of setting a filehandle named C<REMOTE> to be
2217 non-blocking at the system level.  You'll have to negotiate C<$|>
2218 on your own, though.
2219
2220     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2221
2222     $flags = fcntl(REMOTE, F_GETFL, 0)
2223                 or die "Can't get flags for the socket: $!\n";
2224
2225     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2226                 or die "Can't set flags for the socket: $!\n";
2227
2228 Portability issues: L<perlport/fcntl>.
2229
2230 =item __FILE__
2231 X<__FILE__>
2232
2233 =for Pod::Functions the name of the current source file
2234
2235 A special token that returns the name of the file in which it occurs.
2236
2237 =item fileno FILEHANDLE
2238 X<fileno>
2239
2240 =for Pod::Functions return file descriptor from filehandle
2241
2242 Returns the file descriptor for a filehandle, or undefined if the
2243 filehandle is not open.  If there is no real file descriptor at the OS
2244 level, as can happen with filehandles connected to memory objects via
2245 C<open> with a reference for the third argument, -1 is returned.
2246
2247 This is mainly useful for constructing
2248 bitmaps for C<select> and low-level POSIX tty-handling operations.
2249 If FILEHANDLE is an expression, the value is taken as an indirect
2250 filehandle, generally its name.
2251
2252 You can use this to find out whether two handles refer to the
2253 same underlying descriptor:
2254
2255     if (fileno(THIS) == fileno(THAT)) {
2256         print "THIS and THAT are dups\n";
2257     }
2258
2259 =item flock FILEHANDLE,OPERATION
2260 X<flock> X<lock> X<locking>
2261
2262 =for Pod::Functions lock an entire file with an advisory lock
2263
2264 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
2265 for success, false on failure.  Produces a fatal error if used on a
2266 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
2267 C<flock> is Perl's portable file-locking interface, although it locks
2268 entire files only, not records.
2269
2270 Two potentially non-obvious but traditional C<flock> semantics are
2271 that it waits indefinitely until the lock is granted, and that its locks
2272 are B<merely advisory>.  Such discretionary locks are more flexible, but
2273 offer fewer guarantees.  This means that programs that do not also use
2274 C<flock> may modify files locked with C<flock>.  See L<perlport>, 
2275 your port's specific documentation, and your system-specific local manpages
2276 for details.  It's best to assume traditional behavior if you're writing
2277 portable programs.  (But if you're not, you should as always feel perfectly
2278 free to write for your own system's idiosyncrasies (sometimes called
2279 "features").  Slavish adherence to portability concerns shouldn't get
2280 in the way of your getting your job done.)
2281
2282 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
2283 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
2284 you can use the symbolic names if you import them from the L<Fcntl> module,
2285 either individually, or as a group using the C<:flock> tag.  LOCK_SH
2286 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
2287 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
2288 LOCK_SH or LOCK_EX, then C<flock> returns immediately rather than blocking
2289 waiting for the lock; check the return status to see if you got it.
2290
2291 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
2292 before locking or unlocking it.
2293
2294 Note that the emulation built with lockf(3) doesn't provide shared
2295 locks, and it requires that FILEHANDLE be open with write intent.  These
2296 are the semantics that lockf(3) implements.  Most if not all systems
2297 implement lockf(3) in terms of fcntl(2) locking, though, so the
2298 differing semantics shouldn't bite too many people.
2299
2300 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
2301 be open with read intent to use LOCK_SH and requires that it be open
2302 with write intent to use LOCK_EX.
2303
2304 Note also that some versions of C<flock> cannot lock things over the
2305 network; you would need to use the more system-specific C<fcntl> for
2306 that.  If you like you can force Perl to ignore your system's flock(2)
2307 function, and so provide its own fcntl(2)-based emulation, by passing
2308 the switch C<-Ud_flock> to the F<Configure> program when you configure
2309 and build a new Perl.
2310
2311 Here's a mailbox appender for BSD systems.
2312
2313     # import LOCK_* and SEEK_END constants
2314     use Fcntl qw(:flock SEEK_END);
2315
2316     sub lock {
2317         my ($fh) = @_;
2318         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
2319
2320         # and, in case someone appended while we were waiting...
2321         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
2322     }
2323
2324     sub unlock {
2325         my ($fh) = @_;
2326         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
2327     }
2328
2329     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
2330         or die "Can't open mailbox: $!";
2331
2332     lock($mbox);
2333     print $mbox $msg,"\n\n";
2334     unlock($mbox);
2335
2336 On systems that support a real flock(2), locks are inherited across fork()
2337 calls, whereas those that must resort to the more capricious fcntl(2)
2338 function lose their locks, making it seriously harder to write servers.
2339
2340 See also L<DB_File> for other flock() examples.
2341
2342 Portability issues: L<perlport/flock>.
2343
2344 =item fork
2345 X<fork> X<child> X<parent>
2346
2347 =for Pod::Functions create a new process just like this one
2348
2349 Does a fork(2) system call to create a new process running the
2350 same program at the same point.  It returns the child pid to the
2351 parent process, C<0> to the child process, or C<undef> if the fork is
2352 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2353 are shared, while everything else is copied.  On most systems supporting
2354 fork(), great care has gone into making it extremely efficient (for
2355 example, using copy-on-write technology on data pages), making it the
2356 dominant paradigm for multitasking over the last few decades.
2357
2358 Perl attempts to flush all files opened for
2359 output before forking the child process, but this may not be supported
2360 on some platforms (see L<perlport>).  To be safe, you may need to set
2361 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2362 C<IO::Handle> on any open handles to avoid duplicate output.
2363
2364 If you C<fork> without ever waiting on your children, you will
2365 accumulate zombies.  On some systems, you can avoid this by setting
2366 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
2367 forking and reaping moribund children.
2368
2369 Note that if your forked child inherits system file descriptors like
2370 STDIN and STDOUT that are actually connected by a pipe or socket, even
2371 if you exit, then the remote server (such as, say, a CGI script or a
2372 backgrounded job launched from a remote shell) won't think you're done.
2373 You should reopen those to F</dev/null> if it's any issue.
2374
2375 On some platforms such as Windows, where the fork() system call is not available,
2376 Perl can be built to emulate fork() in the Perl interpreter.
2377 The emulation is designed, at the level of the Perl program,
2378 to be as compatible as possible with the "Unix" fork().
2379 However it has limitations that have to be considered in code intended to be portable.
2380 See L<perlfork> for more details.
2381
2382 Portability issues: L<perlport/fork>.
2383
2384 =item format
2385 X<format>
2386
2387 =for Pod::Functions declare a picture format with use by the write() function
2388
2389 Declare a picture format for use by the C<write> function.  For
2390 example:
2391
2392     format Something =
2393         Test: @<<<<<<<< @||||| @>>>>>
2394               $str,     $%,    '$' . int($num)
2395     .
2396
2397     $str = "widget";
2398     $num = $cost/$quantity;
2399     $~ = 'Something';
2400     write;
2401
2402 See L<perlform> for many details and examples.
2403
2404 =item formline PICTURE,LIST
2405 X<formline>
2406
2407 =for Pod::Functions internal function used for formats
2408
2409 This is an internal function used by C<format>s, though you may call it,
2410 too.  It formats (see L<perlform>) a list of values according to the
2411 contents of PICTURE, placing the output into the format output
2412 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2413 Eventually, when a C<write> is done, the contents of
2414 C<$^A> are written to some filehandle.  You could also read C<$^A>
2415 and then set C<$^A> back to C<"">.  Note that a format typically
2416 does one C<formline> per line of form, but the C<formline> function itself
2417 doesn't care how many newlines are embedded in the PICTURE.  This means
2418 that the C<~> and C<~~> tokens treat the entire PICTURE as a single line.
2419 You may therefore need to use multiple formlines to implement a single
2420 record format, just like the C<format> compiler.
2421
2422 Be careful if you put double quotes around the picture, because an C<@>
2423 character may be taken to mean the beginning of an array name.
2424 C<formline> always returns true.  See L<perlform> for other examples.
2425
2426 If you are trying to use this instead of C<write> to capture the output,
2427 you may find it easier to open a filehandle to a scalar
2428 (C<< open $fh, ">", \$output >>) and write to that instead.
2429
2430 =item getc FILEHANDLE
2431 X<getc> X<getchar> X<character> X<file, read>
2432
2433 =item getc
2434
2435 =for Pod::Functions get the next character from the filehandle
2436
2437 Returns the next character from the input file attached to FILEHANDLE,
2438 or the undefined value at end of file or if there was an error (in
2439 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2440 STDIN.  This is not particularly efficient.  However, it cannot be
2441 used by itself to fetch single characters without waiting for the user
2442 to hit enter.  For that, try something more like:
2443
2444     if ($BSD_STYLE) {
2445         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2446     }
2447     else {
2448         system "stty", '-icanon', 'eol', "\001";
2449     }
2450
2451     $key = getc(STDIN);
2452
2453     if ($BSD_STYLE) {
2454         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2455     }
2456     else {
2457         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2458     }
2459     print "\n";
2460
2461 Determination of whether $BSD_STYLE should be set
2462 is left as an exercise to the reader.
2463
2464 The C<POSIX::getattr> function can do this more portably on
2465 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2466 module from your nearest CPAN site; details on CPAN can be found under
2467 L<perlmodlib/CPAN>.
2468
2469 =item getlogin
2470 X<getlogin> X<login>
2471
2472 =for Pod::Functions return who logged in at this tty
2473
2474 This implements the C library function of the same name, which on most
2475 systems returns the current login from F</etc/utmp>, if any.  If it
2476 returns the empty string, use C<getpwuid>.
2477
2478     $login = getlogin || getpwuid($<) || "Kilroy";
2479
2480 Do not consider C<getlogin> for authentication: it is not as
2481 secure as C<getpwuid>.
2482
2483 Portability issues: L<perlport/getlogin>.
2484
2485 =item getpeername SOCKET
2486 X<getpeername> X<peer>
2487
2488 =for Pod::Functions find the other end of a socket connection
2489
2490 Returns the packed sockaddr address of the other end of the SOCKET
2491 connection.
2492
2493     use Socket;
2494     $hersockaddr    = getpeername(SOCK);
2495     ($port, $iaddr) = sockaddr_in($hersockaddr);
2496     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2497     $herstraddr     = inet_ntoa($iaddr);
2498
2499 =item getpgrp PID
2500 X<getpgrp> X<group>
2501
2502 =for Pod::Functions get process group
2503
2504 Returns the current process group for the specified PID.  Use
2505 a PID of C<0> to get the current process group for the
2506 current process.  Will raise an exception if used on a machine that
2507 doesn't implement getpgrp(2).  If PID is omitted, returns the process
2508 group of the current process.  Note that the POSIX version of C<getpgrp>
2509 does not accept a PID argument, so only C<PID==0> is truly portable.
2510
2511 Portability issues: L<perlport/getpgrp>.
2512
2513 =item getppid
2514 X<getppid> X<parent> X<pid>
2515
2516 =for Pod::Functions get parent process ID
2517
2518 Returns the process id of the parent process.
2519
2520 Note for Linux users: Between v5.8.1 and v5.16.0 Perl would work
2521 around non-POSIX thread semantics the minority of Linux systems (and
2522 Debian GNU/kFreeBSD systems) that used LinuxThreads, this emulation
2523 has since been removed. See the documentation for L<$$|perlvar/$$> for
2524 details.
2525
2526 Portability issues: L<perlport/getppid>.
2527
2528 =item getpriority WHICH,WHO
2529 X<getpriority> X<priority> X<nice>
2530
2531 =for Pod::Functions get current nice value
2532
2533 Returns the current priority for a process, a process group, or a user.
2534 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2535 machine that doesn't implement getpriority(2).
2536
2537 Portability issues: L<perlport/getpriority>.
2538
2539 =item getpwnam NAME
2540 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2541 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2542 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2543 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2544 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2545 X<endnetent> X<endprotoent> X<endservent> 
2546
2547 =for Pod::Functions get passwd record given user login name
2548
2549 =item getgrnam NAME
2550
2551 =for Pod::Functions get group record given group name
2552
2553 =item gethostbyname NAME
2554
2555 =for Pod::Functions get host record given name
2556
2557 =item getnetbyname NAME
2558
2559 =for Pod::Functions get networks record given name
2560
2561 =item getprotobyname NAME
2562
2563 =for Pod::Functions get protocol record given name
2564
2565 =item getpwuid UID
2566
2567 =for Pod::Functions get passwd record given user ID
2568
2569 =item getgrgid GID
2570
2571 =for Pod::Functions get group record given group user ID
2572
2573 =item getservbyname NAME,PROTO
2574
2575 =for Pod::Functions get services record given its name
2576
2577 =item gethostbyaddr ADDR,ADDRTYPE
2578
2579 =for Pod::Functions get host record given its address
2580
2581 =item getnetbyaddr ADDR,ADDRTYPE
2582
2583 =for Pod::Functions get network record given its address
2584
2585 =item getprotobynumber NUMBER
2586
2587 =for Pod::Functions get protocol record numeric protocol
2588
2589 =item getservbyport PORT,PROTO
2590
2591 =for Pod::Functions get services record given numeric port
2592
2593 =item getpwent
2594
2595 =for Pod::Functions get next passwd record
2596
2597 =item getgrent
2598
2599 =for Pod::Functions get next group record
2600
2601 =item gethostent
2602
2603 =for Pod::Functions get next hosts record
2604
2605 =item getnetent
2606
2607 =for Pod::Functions get next networks record
2608
2609 =item getprotoent
2610
2611 =for Pod::Functions get next protocols record
2612
2613 =item getservent
2614
2615 =for Pod::Functions get next services record
2616
2617 =item setpwent
2618
2619 =for Pod::Functions prepare passwd file for use
2620
2621 =item setgrent
2622
2623 =for Pod::Functions prepare group file for use
2624
2625 =item sethostent STAYOPEN
2626
2627 =for Pod::Functions prepare hosts file for use
2628
2629 =item setnetent STAYOPEN
2630
2631 =for Pod::Functions prepare networks file for use
2632
2633 =item setprotoent STAYOPEN
2634
2635 =for Pod::Functions prepare protocols file for use
2636
2637 =item setservent STAYOPEN
2638
2639 =for Pod::Functions prepare services file for use
2640
2641 =item endpwent
2642
2643 =for Pod::Functions be done using passwd file
2644
2645 =item endgrent
2646
2647 =for Pod::Functions be done using group file
2648
2649 =item endhostent
2650
2651 =for Pod::Functions be done using hosts file
2652
2653 =item endnetent
2654
2655 =for Pod::Functions be done using networks file
2656
2657 =item endprotoent
2658
2659 =for Pod::Functions be done using protocols file
2660
2661 =item endservent
2662
2663 =for Pod::Functions be done using services file
2664
2665 These routines are the same as their counterparts in the
2666 system C library.  In list context, the return values from the
2667 various get routines are as follows:
2668
2669     ($name,$passwd,$uid,$gid,
2670        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2671     ($name,$passwd,$gid,$members) = getgr*
2672     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2673     ($name,$aliases,$addrtype,$net) = getnet*
2674     ($name,$aliases,$proto) = getproto*
2675     ($name,$aliases,$port,$proto) = getserv*
2676
2677 (If the entry doesn't exist you get an empty list.)
2678
2679 The exact meaning of the $gcos field varies but it usually contains
2680 the real name of the user (as opposed to the login name) and other
2681 information pertaining to the user.  Beware, however, that in many
2682 system users are able to change this information and therefore it
2683 cannot be trusted and therefore the $gcos is tainted (see
2684 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2685 login shell, are also tainted, for the same reason.
2686
2687 In scalar context, you get the name, unless the function was a
2688 lookup by name, in which case you get the other thing, whatever it is.
2689 (If the entry doesn't exist you get the undefined value.)  For example:
2690
2691     $uid   = getpwnam($name);
2692     $name  = getpwuid($num);
2693     $name  = getpwent();
2694     $gid   = getgrnam($name);
2695     $name  = getgrgid($num);
2696     $name  = getgrent();
2697     #etc.
2698
2699 In I<getpw*()> the fields $quota, $comment, and $expire are special
2700 in that they are unsupported on many systems.  If the
2701 $quota is unsupported, it is an empty scalar.  If it is supported, it
2702 usually encodes the disk quota.  If the $comment field is unsupported,
2703 it is an empty scalar.  If it is supported it usually encodes some
2704 administrative comment about the user.  In some systems the $quota
2705 field may be $change or $age, fields that have to do with password
2706 aging.  In some systems the $comment field may be $class.  The $expire
2707 field, if present, encodes the expiration period of the account or the
2708 password.  For the availability and the exact meaning of these fields
2709 in your system, please consult getpwnam(3) and your system's 
2710 F<pwd.h> file.  You can also find out from within Perl what your
2711 $quota and $comment fields mean and whether you have the $expire field
2712 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2713 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2714 files are supported only if your vendor has implemented them in the
2715 intuitive fashion that calling the regular C library routines gets the
2716 shadow versions if you're running under privilege or if there exists
2717 the shadow(3) functions as found in System V (this includes Solaris
2718 and Linux).  Those systems that implement a proprietary shadow password
2719 facility are unlikely to be supported.
2720
2721 The $members value returned by I<getgr*()> is a space-separated list of
2722 the login names of the members of the group.
2723
2724 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2725 C, it will be returned to you via C<$?> if the function call fails.  The
2726 C<@addrs> value returned by a successful call is a list of raw
2727 addresses returned by the corresponding library call.  In the
2728 Internet domain, each address is four bytes long; you can unpack it
2729 by saying something like:
2730
2731     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2732
2733 The Socket library makes this slightly easier:
2734
2735     use Socket;
2736     $iaddr = inet_aton("127.1"); # or whatever address
2737     $name  = gethostbyaddr($iaddr, AF_INET);
2738
2739     # or going the other way
2740     $straddr = inet_ntoa($iaddr);
2741
2742 In the opposite way, to resolve a hostname to the IP address
2743 you can write this:
2744
2745     use Socket;
2746     $packed_ip = gethostbyname("www.perl.org");
2747     if (defined $packed_ip) {
2748         $ip_address = inet_ntoa($packed_ip);
2749     }
2750
2751 Make sure C<gethostbyname()> is called in SCALAR context and that
2752 its return value is checked for definedness.
2753
2754 The C<getprotobynumber> function, even though it only takes one argument,
2755 has the precedence of a list operator, so beware:
2756
2757     getprotobynumber $number eq 'icmp'   # WRONG
2758     getprotobynumber($number eq 'icmp')  # actually means this
2759     getprotobynumber($number) eq 'icmp'  # better this way
2760
2761 If you get tired of remembering which element of the return list
2762 contains which return value, by-name interfaces are provided
2763 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2764 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2765 and C<User::grent>.  These override the normal built-ins, supplying
2766 versions that return objects with the appropriate names
2767 for each field.  For example:
2768
2769    use File::stat;
2770    use User::pwent;
2771    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2772
2773 Even though it looks as though they're the same method calls (uid),
2774 they aren't, because a C<File::stat> object is different from
2775 a C<User::pwent> object.
2776
2777 Portability issues: L<perlport/getpwnam> to L<perlport/endservent>.
2778
2779 =item getsockname SOCKET
2780 X<getsockname>
2781
2782 =for Pod::Functions retrieve the sockaddr for a given socket
2783
2784 Returns the packed sockaddr address of this end of the SOCKET connection,
2785 in case you don't know the address because you have several different
2786 IPs that the connection might have come in on.
2787
2788     use Socket;
2789     $mysockaddr = getsockname(SOCK);
2790     ($port, $myaddr) = sockaddr_in($mysockaddr);
2791     printf "Connect to %s [%s]\n",
2792        scalar gethostbyaddr($myaddr, AF_INET),
2793        inet_ntoa($myaddr);
2794
2795 =item getsockopt SOCKET,LEVEL,OPTNAME
2796 X<getsockopt>
2797
2798 =for Pod::Functions get socket options on a given socket
2799
2800 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2801 Options may exist at multiple protocol levels depending on the socket
2802 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2803 C<Socket> module) will exist.  To query options at another level the
2804 protocol number of the appropriate protocol controlling the option
2805 should be supplied.  For example, to indicate that an option is to be
2806 interpreted by the TCP protocol, LEVEL should be set to the protocol
2807 number of TCP, which you can get using C<getprotobyname>.
2808
2809 The function returns a packed string representing the requested socket
2810 option, or C<undef> on error, with the reason for the error placed in
2811 C<$!>.  Just what is in the packed string depends on LEVEL and OPTNAME;
2812 consult getsockopt(2) for details.  A common case is that the option is an
2813 integer, in which case the result is a packed integer, which you can decode
2814 using C<unpack> with the C<i> (or C<I>) format.
2815
2816 Here's an example to test whether Nagle's algorithm is enabled on a socket:
2817
2818     use Socket qw(:all);
2819
2820     defined(my $tcp = getprotobyname("tcp"))
2821         or die "Could not determine the protocol number for tcp";
2822     # my $tcp = IPPROTO_TCP; # Alternative
2823     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2824         or die "getsockopt TCP_NODELAY: $!";
2825     my $nodelay = unpack("I", $packed);
2826     print "Nagle's algorithm is turned ",
2827            $nodelay ? "off\n" : "on\n";
2828
2829 Portability issues: L<perlport/getsockopt>.
2830
2831 =item glob EXPR
2832 X<glob> X<wildcard> X<filename, expansion> X<expand>
2833
2834 =item glob
2835
2836 =for Pod::Functions expand filenames using wildcards
2837
2838 In list context, returns a (possibly empty) list of filename expansions on
2839 the value of EXPR such as the standard Unix shell F</bin/csh> would do.  In
2840 scalar context, glob iterates through such filename expansions, returning
2841 undef when the list is exhausted.  This is the internal function
2842 implementing the C<< <*.c> >> operator, but you can use it directly.  If
2843 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2844 more detail in L<perlop/"I/O Operators">.
2845
2846 Note that C<glob> splits its arguments on whitespace and treats
2847 each segment as separate pattern.  As such, C<glob("*.c *.h")> 
2848 matches all files with a F<.c> or F<.h> extension.  The expression
2849 C<glob(".* *")> matches all files in the current working directory.
2850 If you want to glob filenames that might contain whitespace, you'll
2851 have to use extra quotes around the spacey filename to protect it.
2852 For example, to glob filenames that have an C<e> followed by a space
2853 followed by an C<f>, use either of:
2854
2855     @spacies = <"*e f*">;
2856     @spacies = glob '"*e f*"';
2857     @spacies = glob q("*e f*");
2858
2859 If you had to get a variable through, you could do this:
2860
2861     @spacies = glob "'*${var}e f*'";
2862     @spacies = glob qq("*${var}e f*");
2863
2864 If non-empty braces are the only wildcard characters used in the
2865 C<glob>, no filenames are matched, but potentially many strings
2866 are returned.  For example, this produces nine strings, one for
2867 each pairing of fruits and colors:
2868
2869     @many =  glob "{apple,tomato,cherry}={green,yellow,red}";
2870
2871 This operator is implemented using the standard
2872 C<File::Glob> extension.  See L<File::Glob> for details, including
2873 C<bsd_glob> which does not treat whitespace as a pattern separator.
2874
2875 Portability issues: L<perlport/glob>.
2876
2877 =item gmtime EXPR
2878 X<gmtime> X<UTC> X<Greenwich>
2879
2880 =item gmtime
2881
2882 =for Pod::Functions convert UNIX time into record or string using Greenwich time
2883
2884 Works just like L</localtime> but the returned values are
2885 localized for the standard Greenwich time zone.
2886
2887 Note: When called in list context, $isdst, the last value
2888 returned by gmtime, is always C<0>.  There is no
2889 Daylight Saving Time in GMT.
2890
2891 Portability issues: L<perlport/gmtime>.
2892
2893 =item goto LABEL
2894 X<goto> X<jump> X<jmp>
2895
2896 =item goto EXPR
2897
2898 =item goto &NAME
2899
2900 =for Pod::Functions create spaghetti code
2901
2902 The C<goto-LABEL> form finds the statement labeled with LABEL and
2903 resumes execution there.  It can't be used to get out of a block or
2904 subroutine given to C<sort>.  It can be used to go almost anywhere
2905 else within the dynamic scope, including out of subroutines, but it's
2906 usually better to use some other construct such as C<last> or C<die>.
2907 The author of Perl has never felt the need to use this form of C<goto>
2908 (in Perl, that is; C is another matter).  (The difference is that C
2909 does not offer named loops combined with loop control.  Perl does, and
2910 this replaces most structured uses of C<goto> in other languages.)
2911
2912 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2913 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2914 necessarily recommended if you're optimizing for maintainability:
2915
2916     goto ("FOO", "BAR", "GLARCH")[$i];
2917
2918 As shown in this example, C<goto-EXPR> is exempt from the "looks like a
2919 function" rule.  A pair of parentheses following it does not (necessarily)
2920 delimit its argument.  C<goto("NE")."XT"> is equivalent to C<goto NEXT>.
2921 Also, unlike most named operators, this has the same precedence as
2922 assignment.
2923
2924 Use of C<goto-LABEL> or C<goto-EXPR> to jump into a construct is
2925 deprecated and will issue a warning.  Even then, it may not be used to
2926 go into any construct that requires initialization, such as a
2927 subroutine or a C<foreach> loop.  It also can't be used to go into a
2928 construct that is optimized away.
2929
2930 The C<goto-&NAME> form is quite different from the other forms of
2931 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2932 doesn't have the stigma associated with other gotos.  Instead, it
2933 exits the current subroutine (losing any changes set by local()) and
2934 immediately calls in its place the named subroutine using the current
2935 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2936 load another subroutine and then pretend that the other subroutine had
2937 been called in the first place (except that any modifications to C<@_>
2938 in the current subroutine are propagated to the other subroutine.)
2939 After the C<goto>, not even C<caller> will be able to tell that this
2940 routine was called first.
2941
2942 NAME needn't be the name of a subroutine; it can be a scalar variable
2943 containing a code reference or a block that evaluates to a code
2944 reference.
2945
2946 =item grep BLOCK LIST
2947 X<grep>
2948
2949 =item grep EXPR,LIST
2950
2951 =for Pod::Functions locate elements in a list test true against a given criterion
2952
2953 This is similar in spirit to, but not the same as, grep(1) and its
2954 relatives.  In particular, it is not limited to using regular expressions.
2955
2956 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2957 C<$_> to each element) and returns the list value consisting of those
2958 elements for which the expression evaluated to true.  In scalar
2959 context, returns the number of times the expression was true.
2960
2961     @foo = grep(!/^#/, @bar);    # weed out comments
2962
2963 or equivalently,
2964
2965     @foo = grep {!/^#/} @bar;    # weed out comments
2966
2967 Note that C<$_> is an alias to the list value, so it can be used to
2968 modify the elements of the LIST.  While this is useful and supported,
2969 it can cause bizarre results if the elements of LIST are not variables.
2970 Similarly, grep returns aliases into the original list, much as a for
2971 loop's index variable aliases the list elements.  That is, modifying an
2972 element of a list returned by grep (for example, in a C<foreach>, C<map>
2973 or another C<grep>) actually modifies the element in the original list.
2974 This is usually something to be avoided when writing clear code.
2975
2976 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2977 been declared with the deprecated C<my $_> construct)
2978 then, in addition to being locally aliased to
2979 the list elements, C<$_> keeps being lexical inside the block; i.e., it
2980 can't be seen from the outside, avoiding any potential side-effects.
2981
2982 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2983
2984 =item hex EXPR
2985 X<hex> X<hexadecimal>
2986
2987 =item hex
2988
2989 =for Pod::Functions convert a string to a hexadecimal number
2990
2991 Interprets EXPR as a hex string and returns the corresponding value.
2992 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2993 L</oct>.)  If EXPR is omitted, uses C<$_>.
2994
2995     print hex '0xAf'; # prints '175'
2996     print hex 'aF';   # same
2997
2998 Hex strings may only represent integers.  Strings that would cause
2999 integer overflow trigger a warning.  Leading whitespace is not stripped,
3000 unlike oct().  To present something as hex, look into L</printf>,
3001 L</sprintf>, and L</unpack>.
3002
3003 =item import LIST
3004 X<import>
3005
3006 =for Pod::Functions patch a module's namespace into your own
3007
3008 There is no builtin C<import> function.  It is just an ordinary
3009 method (subroutine) defined (or inherited) by modules that wish to export
3010 names to another module.  The C<use> function calls the C<import> method
3011 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
3012
3013 =item index STR,SUBSTR,POSITION
3014 X<index> X<indexOf> X<InStr>
3015
3016 =item index STR,SUBSTR
3017
3018 =for Pod::Functions find a substring within a string
3019
3020 The index function searches for one string within another, but without
3021 the wildcard-like behavior of a full regular-expression pattern match.
3022 It returns the position of the first occurrence of SUBSTR in STR at
3023 or after POSITION.  If POSITION is omitted, starts searching from the
3024 beginning of the string.  POSITION before the beginning of the string
3025 or after its end is treated as if it were the beginning or the end,
3026 respectively.  POSITION and the return value are based at zero.
3027 If the substring is not found, C<index> returns -1.
3028
3029 =item int EXPR
3030 X<int> X<integer> X<truncate> X<trunc> X<floor>
3031
3032 =item int
3033
3034 =for Pod::Functions get the integer portion of a number
3035
3036 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
3037 You should not use this function for rounding: one because it truncates
3038 towards C<0>, and two because machine representations of floating-point
3039 numbers can sometimes produce counterintuitive results.  For example,
3040 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
3041 because it's really more like -268.99999999999994315658 instead.  Usually,
3042 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
3043 functions will serve you better than will int().
3044
3045 =item ioctl FILEHANDLE,FUNCTION,SCALAR
3046 X<ioctl>
3047
3048 =for Pod::Functions system-dependent device control system call
3049
3050 Implements the ioctl(2) function.  You'll probably first have to say
3051
3052     require "sys/ioctl.ph";  # probably in
3053                              # $Config{archlib}/sys/ioctl.ph
3054
3055 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
3056 exist or doesn't have the correct definitions you'll have to roll your
3057 own, based on your C header files such as F<< <sys/ioctl.h> >>.
3058 (There is a Perl script called B<h2ph> that comes with the Perl kit that
3059 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
3060 written depending on the FUNCTION; a C pointer to the string value of SCALAR
3061 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
3062 has no string value but does have a numeric value, that value will be
3063 passed rather than a pointer to the string value.  To guarantee this to be
3064 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
3065 functions may be needed to manipulate the values of structures used by
3066 C<ioctl>.
3067
3068 The return value of C<ioctl> (and C<fcntl>) is as follows:
3069
3070     if OS returns:      then Perl returns:
3071         -1               undefined value
3072          0              string "0 but true"
3073     anything else           that number
3074
3075 Thus Perl returns true on success and false on failure, yet you can
3076 still easily determine the actual value returned by the operating
3077 system:
3078
3079     $retval = ioctl(...) || -1;
3080     printf "System returned %d\n", $retval;
3081
3082 The special string C<"0 but true"> is exempt from B<-w> complaints
3083 about improper numeric conversions.
3084
3085 Portability issues: L<perlport/ioctl>.
3086
3087 =item join EXPR,LIST
3088 X<join>
3089
3090 =for Pod::Functions join a list into a string using a separator
3091
3092 Joins the separate strings of LIST into a single string with fields
3093 separated by the value of EXPR, and returns that new string.  Example:
3094
3095     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
3096
3097 Beware that unlike C<split>, C<join> doesn't take a pattern as its
3098 first argument.  Compare L</split>.
3099
3100 =item keys HASH
3101 X<keys> X<key>
3102
3103 =item keys ARRAY
3104
3105 =item keys EXPR
3106
3107 =for Pod::Functions retrieve list of indices from a hash
3108
3109 Called in list context, returns a list consisting of all the keys of the
3110 named hash, or in Perl 5.12 or later only, the indices of an array.  Perl
3111 releases prior to 5.12 will produce a syntax error if you try to use an
3112 array argument.  In scalar context, returns the number of keys or indices.
3113
3114 Hash entries are returned in an apparently random order.  The actual random
3115 order is specific to a given hash; the exact same series of operations
3116 on two hashes may result in a different order for each hash. Any insertion
3117 into the hash may change the order, as will any deletion, with the exception
3118 that the most recent key returned by C<each> or C<keys> may be deleted
3119 without changing the order. So long as a given hash is unmodified you may
3120 rely on C<keys>, C<values> and C<each> to repeatedly return the same order
3121 as each other. See L<perlsec/"Algorithmic Complexity Attacks"> for
3122 details on why hash order is randomized. Aside from the guarantees
3123 provided here the exact details of Perl's hash algorithm and the hash
3124 traversal order are subject to change in any release of Perl.
3125
3126 As a side effect, calling keys() resets the internal iterator of the HASH or
3127 ARRAY (see L</each>).  In particular, calling keys() in void context resets
3128 the iterator with no other overhead.
3129
3130 Here is yet another way to print your environment:
3131
3132     @keys = keys %ENV;
3133     @values = values %ENV;
3134     while (@keys) {
3135         print pop(@keys), '=', pop(@values), "\n";
3136     }
3137
3138 or how about sorted by key:
3139
3140     foreach $key (sort(keys %ENV)) {
3141         print $key, '=', $ENV{$key}, "\n";
3142     }
3143
3144 The returned values are copies of the original keys in the hash, so
3145 modifying them will not affect the original hash.  Compare L</values>.
3146
3147 To sort a hash by value, you'll need to use a C<sort> function.
3148 Here's a descending numeric sort of a hash by its values:
3149
3150     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
3151         printf "%4d %s\n", $hash{$key}, $key;
3152     }
3153
3154 Used as an lvalue, C<keys> allows you to increase the number of hash buckets
3155 allocated for the given hash.  This can gain you a measure of efficiency if
3156 you know the hash is going to get big.  (This is similar to pre-extending
3157 an array by assigning a larger number to $#array.)  If you say
3158
3159     keys %hash = 200;
3160
3161 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
3162 in fact, since it rounds up to the next power of two.  These
3163 buckets will be retained even if you do C<%hash = ()>, use C<undef
3164 %hash> if you want to free the storage while C<%hash> is still in scope.
3165 You can't shrink the number of buckets allocated for the hash using
3166 C<keys> in this way (but you needn't worry about doing this by accident,
3167 as trying has no effect).  C<keys @array> in an lvalue context is a syntax
3168 error.
3169
3170 Starting with Perl 5.14, C<keys> can take a scalar EXPR, which must contain
3171 a reference to an unblessed hash or array.  The argument will be
3172 dereferenced automatically.  This aspect of C<keys> is considered highly
3173 experimental.  The exact behaviour may change in a future version of Perl.
3174
3175     for (keys $hashref) { ... }
3176     for (keys $obj->get_arrayref) { ... }
3177
3178 To avoid confusing would-be users of your code who are running earlier
3179 versions of Perl with mysterious syntax errors, put this sort of thing at
3180 the top of your file to signal that your code will work I<only> on Perls of
3181 a recent vintage:
3182
3183     use 5.012;  # so keys/values/each work on arrays
3184     use 5.014;  # so keys/values/each work on scalars (experimental)
3185
3186 See also C<each>, C<values>, and C<sort>.
3187
3188 =item kill SIGNAL, LIST
3189
3190 =item kill SIGNAL
3191 X<kill> X<signal>
3192
3193 =for Pod::Functions send a signal to a process or process group
3194
3195 Sends a signal to a list of processes.  Returns the number of
3196 processes successfully signaled (which is not necessarily the
3197 same as the number actually killed).
3198
3199     $cnt = kill 'HUP', $child1, $child2;
3200     kill 'KILL', @goners;
3201
3202 SIGNAL may be either a signal name (a string) or a signal number.  A signal
3203 name may start with a C<SIG> prefix, thus C<FOO> and C<SIGFOO> refer to the
3204 same signal.  The string form of SIGNAL is recommended for portability because
3205 the same signal may have different numbers in different operating systems.
3206
3207 A list of signal names supported by the current platform can be found in
3208 C<$Config{sig_name}>, which is provided by the C<Config> module. See L<Config>
3209 for more details.
3210
3211 A negative signal name is the same as a negative signal number, killing process
3212 groups instead of processes.  For example, C<kill '-KILL', $pgrp> and
3213 C<kill -9, $pgrp> will send C<SIGKILL> to the entire process group specified. That
3214 means you usually want to use positive not negative signals.
3215
3216 If SIGNAL is either the number 0 or the string C<ZERO> (or C<SIGZZERO>),
3217 no signal is sent to
3218 the process, but C<kill> checks whether it's I<possible> to send a signal to it
3219 (that means, to be brief, that the process is owned by the same user, or we are
3220 the super-user).  This is useful to check that a child process is still
3221 alive (even if only as a zombie) and hasn't changed its UID.  See
3222 L<perlport> for notes on the portability of this construct.
3223
3224 The behavior of kill when a I<PROCESS> number is zero or negative depends on
3225 the operating system.  For example, on POSIX-conforming systems, zero will
3226 signal the current process group, -1 will signal all processes, and any
3227 other negative PROCESS number will act as a negative signal number and
3228 kill the entire process group specified.
3229
3230 If both the SIGNAL and the PROCESS are negative, the results are undefined.
3231 A warning may be produced in a future version.
3232
3233 See L<perlipc/"Signals"> for more details.
3234
3235 On some platforms such as Windows where the fork() system call is not available.
3236 Perl can be built to emulate fork() at the interpreter level.
3237 This emulation has limitations related to kill that have to be considered,
3238 for code running on Windows and in code intended to be portable.
3239
3240 See L<perlfork> for more details.
3241
3242 If there is no I<LIST> of processes, no signal is sent, and the return
3243 value is 0.  This form is sometimes used, however, because it causes
3244 tainting checks to be run.  But see
3245 L<perlsec/Laundering and Detecting Tainted Data>.
3246
3247 Portability issues: L<perlport/kill>.
3248
3249 =item last LABEL
3250 X<last> X<break>
3251
3252 =item last EXPR
3253
3254 =item last
3255
3256 =for Pod::Functions exit a block prematurely
3257
3258 The C<last> command is like the C<break> statement in C (as used in
3259 loops); it immediately exits the loop in question.  If the LABEL is
3260 omitted, the command refers to the innermost enclosing
3261 loop.  The C<last EXPR> form, available starting in Perl
3262 5.18.0, allows a label name to be computed at run time,
3263 and is otherwise identical to C<last LABEL>.  The
3264 C<continue> block, if any, is not executed:
3265
3266     LINE: while (<STDIN>) {
3267         last LINE if /^$/;  # exit when done with header
3268         #...
3269     }
3270
3271 C<last> cannot be used to exit a block that returns a value such as
3272 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3273 a grep() or map() operation.
3274
3275 Note that a block by itself is semantically identical to a loop
3276 that executes once.  Thus C<last> can be used to effect an early
3277 exit out of such a block.
3278
3279 See also L</continue> for an illustration of how C<last>, C<next>, and
3280 C<redo> work.
3281
3282 Unlike most named operators, this has the same precedence as assignment.
3283 It is also exempt from the looks-like-a-function rule, so
3284 C<last ("foo")."bar"> will cause "bar" to be part of the argument to
3285 C<last>.
3286
3287 =item lc EXPR
3288 X<lc> X<lowercase>
3289
3290 =item lc
3291
3292 =for Pod::Functions return lower-case version of a string
3293
3294 Returns a lowercased version of EXPR.  This is the internal function
3295 implementing the C<\L> escape in double-quoted strings.
3296
3297 If EXPR is omitted, uses C<$_>.
3298
3299 What gets returned depends on several factors:
3300
3301 =over
3302
3303 =item If C<use bytes> is in effect:
3304
3305 The results follow ASCII semantics.  Only characters C<A-Z> change, to C<a-z>
3306 respectively.
3307
3308 =item Otherwise, if C<use locale> (but not C<use locale ':not_characters'>) is in effect:
3309
3310 Respects current LC_CTYPE locale for code points < 256; and uses Unicode
3311 semantics for the remaining code points (this last can only happen if
3312 the UTF8 flag is also set).  See L<perllocale>.
3313
3314 A deficiency in this is that case changes that cross the 255/256
3315 boundary are not well-defined.  For example, the lower case of LATIN CAPITAL
3316 LETTER SHARP S (U+1E9E) in Unicode semantics is U+00DF (on ASCII
3317 platforms).   But under C<use locale>, the lower case of U+1E9E is
3318 itself, because 0xDF may not be LATIN SMALL LETTER SHARP S in the
3319 current locale, and Perl has no way of knowing if that character even
3320 exists in the locale, much less what code point it is.  Perl returns
3321 the input character unchanged, for all instances (and there aren't
3322 many) where the 255/256 boundary would otherwise be crossed.
3323
3324 =item Otherwise, If EXPR has the UTF8 flag set:
3325
3326 Unicode semantics are used for the case change.
3327
3328 =item Otherwise, if C<use feature 'unicode_strings'> or C<use locale ':not_characters'> is in effect:
3329
3330 Unicode semantics are used for the case change.
3331
3332 =item Otherwise:
3333
3334 ASCII semantics are used for the case change.  The lowercase of any character
3335 outside the ASCII range is the character itself.
3336
3337 =back
3338
3339 =item lcfirst EXPR
3340 X<lcfirst> X<lowercase>
3341
3342 =item lcfirst
3343
3344 =for Pod::Functions return a string with just the next letter in lower case
3345
3346 Returns the value of EXPR with the first character lowercased.  This
3347 is the internal function implementing the C<\l> escape in
3348 double-quoted strings.
3349
3350 If EXPR is omitted, uses C<$_>.
3351
3352 This function behaves the same way under various pragmata, such as in a locale,
3353 as L</lc> does.
3354
3355 =item length EXPR
3356 X<length> X<size>
3357
3358 =item length
3359
3360 =for Pod::Functions return the number of characters in a string
3361
3362 Returns the length in I<characters> of the value of EXPR.  If EXPR is
3363 omitted, returns the length of C<$_>.  If EXPR is undefined, returns
3364 C<undef>.
3365
3366 This function cannot be used on an entire array or hash to find out how
3367 many elements these have.  For that, use C<scalar @array> and C<scalar keys
3368 %hash>, respectively.
3369
3370 Like all Perl character operations, length() normally deals in logical
3371 characters, not physical bytes.  For how many bytes a string encoded as
3372 UTF-8 would take up, use C<length(Encode::encode_utf8(EXPR))> (you'll have
3373 to C<use Encode> first).  See L<Encode> and L<perlunicode>.
3374
3375 =item __LINE__
3376 X<__LINE__>
3377
3378 =for Pod::Functions the current source line number
3379
3380 A special token that compiles to the current line number.
3381
3382 =item link OLDFILE,NEWFILE
3383 X<link>
3384
3385 =for Pod::Functions create a hard link in the filesystem
3386
3387 Creates a new filename linked to the old filename.  Returns true for
3388 success, false otherwise.
3389
3390 Portability issues: L<perlport/link>.
3391
3392 =item listen SOCKET,QUEUESIZE
3393 X<listen>
3394
3395 =for Pod::Functions register your socket as a server
3396
3397 Does the same thing that the listen(2) system call does.  Returns true if
3398 it succeeded, false otherwise.  See the example in
3399 L<perlipc/"Sockets: Client/Server Communication">.
3400
3401 =item local EXPR
3402 X<local>
3403
3404 =for Pod::Functions create a temporary value for a global variable (dynamic scoping)
3405
3406 You really probably want to be using C<my> instead, because C<local> isn't
3407 what most people think of as "local".  See
3408 L<perlsub/"Private Variables via my()"> for details.
3409
3410 A local modifies the listed variables to be local to the enclosing
3411 block, file, or eval.  If more than one value is listed, the list must
3412 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
3413 for details, including issues with tied arrays and hashes.
3414
3415 The C<delete local EXPR> construct can also be used to localize the deletion
3416 of array/hash elements to the current block.
3417 See L<perlsub/"Localized deletion of elements of composite types">.
3418
3419 =item localtime EXPR
3420 X<localtime> X<ctime>
3421
3422 =item localtime
3423
3424 =for Pod::Functions convert UNIX time into record or string using local time
3425
3426 Converts a time as returned by the time function to a 9-element list
3427 with the time analyzed for the local time zone.  Typically used as
3428 follows:
3429
3430     #  0    1    2     3     4    5     6     7     8
3431     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
3432                                                 localtime(time);
3433
3434 All list elements are numeric and come straight out of the C `struct
3435 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
3436 of the specified time.
3437
3438 C<$mday> is the day of the month and C<$mon> the month in
3439 the range C<0..11>, with 0 indicating January and 11 indicating December.
3440 This makes it easy to get a month name from a list:
3441
3442     my @abbr = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
3443     print "$abbr[$mon] $mday";
3444     # $mon=9, $mday=18 gives "Oct 18"
3445
3446 C<$year> contains the number of years since 1900.  To get a 4-digit
3447 year write:
3448
3449     $year += 1900;
3450
3451 To get the last two digits of the year (e.g., "01" in 2001) do:
3452
3453     $year = sprintf("%02d", $year % 100);
3454
3455 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
3456 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
3457 (or C<0..365> in leap years.)
3458
3459 C<$isdst> is true if the specified time occurs during Daylight Saving
3460 Time, false otherwise.
3461
3462 If EXPR is omitted, C<localtime()> uses the current time (as returned
3463 by time(3)).
3464
3465 In scalar context, C<localtime()> returns the ctime(3) value:
3466
3467     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
3468
3469 The format of this scalar value is B<not> locale-dependent
3470 but built into Perl.  For GMT instead of local
3471 time use the L</gmtime> builtin.  See also the
3472 C<Time::Local> module (for converting seconds, minutes, hours, and such back to
3473 the integer value returned by time()), and the L<POSIX> module's strftime(3)
3474 and mktime(3) functions.
3475
3476 To get somewhat similar but locale-dependent date strings, set up your
3477 locale environment variables appropriately (please see L<perllocale>) and
3478 try for example:
3479
3480     use POSIX qw(strftime);
3481     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
3482     # or for GMT formatted appropriately for your locale:
3483     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
3484
3485 Note that the C<%a> and C<%b>, the short forms of the day of the week
3486 and the month of the year, may not necessarily be three characters wide.
3487
3488 The L<Time::gmtime> and L<Time::localtime> modules provide a convenient,
3489 by-name access mechanism to the gmtime() and localtime() functions,
3490 respectively.
3491
3492 For a comprehensive date and time representation look at the
3493 L<DateTime> module on CPAN.
3494
3495 Portability issues: L<perlport/localtime>.
3496
3497 =item lock THING
3498 X<lock>
3499
3500 =for Pod::Functions +5.005 get a thread lock on a variable, subroutine, or method
3501
3502 This function places an advisory lock on a shared variable or referenced
3503 object contained in I<THING> until the lock goes out of scope.
3504
3505 The value returned is the scalar itself, if the argument is a scalar, or a
3506 reference, if the argument is a hash, array or subroutine.
3507
3508 lock() is a "weak keyword" : this means that if you've defined a function
3509 by this name (before any calls to it), that function will be called
3510 instead.  If you are not under C<use threads::shared> this does nothing.
3511 See L<threads::shared>.
3512
3513 =item log EXPR
3514 X<log> X<logarithm> X<e> X<ln> X<base>
3515
3516 =item log
3517
3518 =for Pod::Functions retrieve the natural logarithm for a number
3519
3520 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
3521 returns the log of C<$_>.  To get the
3522 log of another base, use basic algebra:
3523 The base-N log of a number is equal to the natural log of that number
3524 divided by the natural log of N.  For example:
3525
3526     sub log10 {
3527         my $n = shift;
3528         return log($n)/log(10);
3529     }
3530
3531 See also L</exp> for the inverse operation.
3532
3533 =item lstat FILEHANDLE
3534 X<lstat>
3535
3536 =item lstat EXPR
3537
3538 =item lstat DIRHANDLE
3539
3540 =item lstat
3541
3542 =for Pod::Functions stat a symbolic link
3543
3544 Does the same thing as the C<stat> function (including setting the
3545 special C<_> filehandle) but stats a symbolic link instead of the file
3546 the symbolic link points to.  If symbolic links are unimplemented on
3547 your system, a normal C<stat> is done.  For much more detailed
3548 information, please see the documentation for C<stat>.
3549
3550 If EXPR is omitted, stats C<$_>.
3551
3552 Portability issues: L<perlport/lstat>.
3553
3554 =item m//
3555
3556 =for Pod::Functions match a string with a regular expression pattern
3557
3558 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
3559
3560 =item map BLOCK LIST
3561 X<map>
3562
3563 =item map EXPR,LIST
3564
3565 =for Pod::Functions apply a change to a list to get back a new list with the changes
3566
3567 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
3568 C<$_> to each element) and returns the list value composed of the
3569 results of each such evaluation.  In scalar context, returns the
3570 total number of elements so generated.  Evaluates BLOCK or EXPR in
3571 list context, so each element of LIST may produce zero, one, or
3572 more elements in the returned value.
3573
3574     @chars = map(chr, @numbers);
3575
3576 translates a list of numbers to the corresponding characters.
3577
3578     my @squares = map { $_ * $_ } @numbers;
3579
3580 translates a list of numbers to their squared values.
3581
3582     my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;
3583
3584 shows that number of returned elements can differ from the number of
3585 input elements.  To omit an element, return an empty list ().
3586 This could also be achieved by writing
3587
3588     my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;
3589
3590 which makes the intention more clear.
3591
3592 Map always returns a list, which can be
3593 assigned to a hash such that the elements
3594 become key/value pairs.  See L<perldata> for more details.
3595
3596     %hash = map { get_a_key_for($_) => $_ } @array;
3597
3598 is just a funny way to write
3599
3600     %hash = ();
3601     foreach (@array) {
3602         $hash{get_a_key_for($_)} = $_;
3603     }
3604
3605 Note that C<$_> is an alias to the list value, so it can be used to
3606 modify the elements of the LIST.  While this is useful and supported,
3607 it can cause bizarre results if the elements of LIST are not variables.
3608 Using a regular C<foreach> loop for this purpose would be clearer in
3609 most cases.  See also L</grep> for an array composed of those items of
3610 the original list for which the BLOCK or EXPR evaluates to true.
3611
3612 If C<$_> is lexical in the scope where the C<map> appears (because it has
3613 been declared with the deprecated C<my $_> construct),
3614 then, in addition to being locally aliased to
3615 the list elements, C<$_> keeps being lexical inside the block; that is, it
3616 can't be seen from the outside, avoiding any potential side-effects.
3617
3618 C<{> starts both hash references and blocks, so C<map { ...> could be either
3619 the start of map BLOCK LIST or map EXPR, LIST.  Because Perl doesn't look
3620 ahead for the closing C<}> it has to take a guess at which it's dealing with
3621 based on what it finds just after the
3622 C<{>.  Usually it gets it right, but if it
3623 doesn't it won't realize something is wrong until it gets to the C<}> and
3624 encounters the missing (or unexpected) comma.  The syntax error will be
3625 reported close to the C<}>, but you'll need to change something near the C<{>
3626 such as using a unary C<+> to give Perl some help:
3627
3628     %hash = map {  "\L$_" => 1  } @array # perl guesses EXPR. wrong
3629     %hash = map { +"\L$_" => 1  } @array # perl guesses BLOCK. right
3630     %hash = map { ("\L$_" => 1) } @array # this also works
3631     %hash = map {  lc($_) => 1  } @array # as does this.
3632     %hash = map +( lc($_) => 1 ), @array # this is EXPR and works!
3633
3634     %hash = map  ( lc($_), 1 ),   @array # evaluates to (1, @array)
3635
3636 or to force an anon hash constructor use C<+{>:
3637
3638     @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs
3639                                            # comma at end
3640
3641 to get a list of anonymous hashes each with only one entry apiece.
3642
3643 =item mkdir FILENAME,MASK
3644 X<mkdir> X<md> X<directory, create>
3645
3646 =item mkdir FILENAME
3647
3648 =item mkdir
3649
3650 =for Pod::Functions create a directory
3651
3652 Creates the directory specified by FILENAME, with permissions
3653 specified by MASK (as modified by C<umask>).  If it succeeds it
3654 returns true; otherwise it returns false and sets C<$!> (errno).
3655 MASK defaults to 0777 if omitted, and FILENAME defaults
3656 to C<$_> if omitted.
3657
3658 In general, it is better to create directories with a permissive MASK
3659 and let the user modify that with their C<umask> than it is to supply
3660 a restrictive MASK and give the user no way to be more permissive.
3661 The exceptions to this rule are when the file or directory should be
3662 kept private (mail files, for instance).  The perlfunc(1) entry on
3663 C<umask> discusses the choice of MASK in more detail.
3664
3665 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
3666 number of trailing slashes.  Some operating and filesystems do not get
3667 this right, so Perl automatically removes all trailing slashes to keep
3668 everyone happy.
3669
3670 To recursively create a directory structure, look at
3671 the C<mkpath> function of the L<File::Path> module.
3672
3673 =item msgctl ID,CMD,ARG
3674 X<msgctl>
3675
3676 =for Pod::Functions SysV IPC message control operations
3677
3678 Calls the System V IPC function msgctl(2).  You'll probably have to say
3679
3680     use IPC::SysV;
3681
3682 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3683 then ARG must be a variable that will hold the returned C<msqid_ds>
3684 structure.  Returns like C<ioctl>: the undefined value for error,
3685 C<"0 but true"> for zero, or the actual return value otherwise.  See also
3686 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3687 C<IPC::Semaphore>.
3688
3689 Portability issues: L<perlport/msgctl>.
3690
3691 =item msgget KEY,FLAGS
3692 X<msgget>
3693
3694 =for Pod::Functions get SysV IPC message queue
3695
3696 Calls the System V IPC function msgget(2).  Returns the message queue
3697 id, or C<undef> on error.  See also
3698 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3699 C<IPC::Msg>.
3700
3701 Portability issues: L<perlport/msgget>.
3702
3703 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
3704 X<msgrcv>
3705
3706 =for Pod::Functions receive a SysV IPC message from a message queue
3707
3708 Calls the System V IPC function msgrcv to receive a message from
3709 message queue ID into variable VAR with a maximum message size of
3710 SIZE.  Note that when a message is received, the message type as a
3711 native long integer will be the first thing in VAR, followed by the
3712 actual message.  This packing may be opened with C<unpack("l! a*")>.
3713 Taints the variable.  Returns true if successful, false 
3714 on error.  See also L<perlipc/"SysV IPC"> and the documentation for
3715 C<IPC::SysV> and C<IPC::SysV::Msg>.
3716
3717 Portability issues: L<perlport/msgrcv>.
3718
3719 =item msgsnd ID,MSG,FLAGS
3720 X<msgsnd>
3721
3722 =for Pod::Functions send a SysV IPC message to a message queue
3723
3724 Calls the System V IPC function msgsnd to send the message MSG to the
3725 message queue ID.  MSG must begin with the native long integer message
3726 type, be followed by the length of the actual message, and then finally
3727 the message itself.  This kind of packing can be achieved with
3728 C<pack("l! a*", $type, $message)>.  Returns true if successful,
3729 false on error.  See also the C<IPC::SysV>
3730 and C<IPC::SysV::Msg> documentation.
3731
3732 Portability issues: L<perlport/msgsnd>.
3733
3734 =item my EXPR
3735 X<my>
3736
3737 =item my TYPE EXPR
3738
3739 =item my EXPR : ATTRS
3740
3741 =item my TYPE EXPR : ATTRS
3742
3743 =for Pod::Functions declare and assign a local variable (lexical scoping)
3744
3745 A C<my> declares the listed variables to be local (lexically) to the
3746 enclosing block, file, or C<eval>.  If more than one value is listed,
3747 the list must be placed in parentheses.
3748
3749 The exact semantics and interface of TYPE and ATTRS are still
3750 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
3751 and attributes are handled using the C<attributes> pragma, or starting
3752 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3753 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3754 L<attributes>, and L<Attribute::Handlers>.
3755
3756 =item next LABEL
3757 X<next> X<continue>
3758
3759 =item next EXPR
3760
3761 =item next
3762
3763 =for Pod::Functions iterate a block prematurely
3764
3765 The C<next> command is like the C<continue> statement in C; it starts
3766 the next iteration of the loop:
3767
3768     LINE: while (<STDIN>) {
3769         next LINE if /^#/;  # discard comments
3770         #...
3771     }
3772
3773 Note that if there were a C<continue> block on the above, it would get
3774 executed even on discarded lines.  If LABEL is omitted, the command
3775 refers to the innermost enclosing loop.  The C<next EXPR> form, available
3776 as of Perl 5.18.0, allows a label name to be computed at run time, being
3777 otherwise identical to C<next LABEL>.
3778
3779 C<next> cannot be used to exit a block which returns a value such as
3780 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3781 a grep() or map() operation.
3782
3783 Note that a block by itself is semantically identical to a loop
3784 that executes once.  Thus C<next> will exit such a block early.
3785
3786 See also L</continue> for an illustration of how C<last>, C<next>, and
3787 C<redo> work.
3788
3789 Unlike most named operators, this has the same precedence as assignment.
3790 It is also exempt from the looks-like-a-function rule, so
3791 C<next ("foo")."bar"> will cause "bar" to be part of the argument to
3792 C<next>.
3793
3794 =item no MODULE VERSION LIST
3795 X<no declarations>
3796 X<unimporting>
3797
3798 =item no MODULE VERSION
3799
3800 =item no MODULE LIST
3801
3802 =item no MODULE
3803
3804 =item no VERSION
3805
3806 =for Pod::Functions unimport some module symbols or semantics at compile time
3807
3808 See the C<use> function, of which C<no> is the opposite.
3809
3810 =item oct EXPR
3811 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3812
3813 =item oct
3814
3815 =for Pod::Functions convert a string to an octal number
3816
3817 Interprets EXPR as an octal string and returns the corresponding
3818 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3819 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3820 binary string.  Leading whitespace is ignored in all three cases.)
3821 The following will handle decimal, binary, octal, and hex in standard
3822 Perl notation:
3823
3824     $val = oct($val) if $val =~ /^0/;
3825
3826 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3827 in octal), use sprintf() or printf():
3828
3829     $dec_perms = (stat("filename"))[2] & 07777;
3830     $oct_perm_str = sprintf "%o", $perms;
3831
3832 The oct() function is commonly used when a string such as C<644> needs
3833 to be converted into a file mode, for example.  Although Perl 
3834 automatically converts strings into numbers as needed, this automatic
3835 conversion assumes base 10.
3836
3837 Leading white space is ignored without warning, as too are any trailing 
3838 non-digits, such as a decimal point (C<oct> only handles non-negative
3839 integers, not negative integers or floating point).
3840
3841 =item open FILEHANDLE,EXPR
3842 X<open> X<pipe> X<file, open> X<fopen>
3843
3844 =item open FILEHANDLE,MODE,EXPR
3845
3846 =item open FILEHANDLE,MODE,EXPR,LIST
3847
3848 =item open FILEHANDLE,MODE,REFERENCE
3849
3850 =item open FILEHANDLE
3851
3852 =for Pod::Functions open a file, pipe, or descriptor
3853
3854 Opens the file whose filename is given by EXPR, and associates it with
3855 FILEHANDLE.
3856
3857 Simple examples to open a file for reading:
3858
3859     open(my $fh, "<", "input.txt") 
3860         or die "cannot open < input.txt: $!";
3861
3862 and for writing:
3863
3864     open(my $fh, ">", "output.txt") 
3865         or die "cannot open > output.txt: $!";
3866
3867 (The following is a comprehensive reference to open(): for a gentler
3868 introduction you may consider L<perlopentut>.)
3869
3870 If FILEHANDLE is an undefined scalar variable (or array or hash element), a
3871 new filehandle is autovivified, meaning that the variable is assigned a
3872 reference to a newly allocated anonymous filehandle.  Otherwise if
3873 FILEHANDLE is an expression, its value is the real filehandle.  (This is
3874 considered a symbolic reference, so C<use strict "refs"> should I<not> be
3875 in effect.)
3876
3877 If EXPR is omitted, the global (package) scalar variable of the same
3878 name as the FILEHANDLE contains the filename.  (Note that lexical 
3879 variables--those declared with C<my> or C<state>--will not work for this
3880 purpose; so if you're using C<my> or C<state>, specify EXPR in your
3881 call to open.)
3882
3883 If three (or more) arguments are specified, the open mode (including
3884 optional encoding) in the second argument are distinct from the filename in
3885 the third.  If MODE is C<< < >> or nothing, the file is opened for input.
3886 If MODE is C<< > >>, the file is opened for output, with existing files
3887 first being truncated ("clobbered") and nonexisting files newly created.
3888 If MODE is C<<< >> >>>, the file is opened for appending, again being
3889 created if necessary.
3890
3891 You can put a C<+> in front of the C<< > >> or C<< < >> to
3892 indicate that you want both read and write access to the file; thus
3893 C<< +< >> is almost always preferred for read/write updates--the 
3894 C<< +> >> mode would clobber the file first.  You can't usually use
3895 either read-write mode for updating textfiles, since they have
3896 variable-length records.  See the B<-i> switch in L<perlrun> for a
3897 better approach.  The file is created with permissions of C<0666>
3898 modified by the process's C<umask> value.
3899
3900 These various prefixes correspond to the fopen(3) modes of C<r>,
3901 C<r+>, C<w>, C<w+>, C<a>, and C<a+>.
3902
3903 In the one- and two-argument forms of the call, the mode and filename
3904 should be concatenated (in that order), preferably separated by white
3905 space.  You can--but shouldn't--omit the mode in these forms when that mode
3906 is C<< < >>.  It is always safe to use the two-argument form of C<open> if
3907 the filename argument is a known literal.
3908
3909 For three or more arguments if MODE is C<|->, the filename is
3910 interpreted as a command to which output is to be piped, and if MODE
3911 is C<-|>, the filename is interpreted as a command that pipes
3912 output to us.  In the two-argument (and one-argument) form, one should
3913 replace dash (C<->) with the command.
3914 See L<perlipc/"Using open() for IPC"> for more examples of this.
3915 (You are not allowed to C<open> to a command that pipes both in I<and>
3916 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3917 L<perlipc/"Bidirectional Communication with Another Process"> for
3918 alternatives.)
3919
3920 In the form of pipe opens taking three or more arguments, if LIST is specified
3921 (extra arguments after the command name) then LIST becomes arguments
3922 to the command invoked if the platform supports it.  The meaning of
3923 C<open> with more than three arguments for non-pipe modes is not yet
3924 defined, but experimental "layers" may give extra LIST arguments
3925 meaning.
3926
3927 In the two-argument (and one-argument) form, opening C<< <- >> 
3928 or C<-> opens STDIN and opening C<< >- >> opens STDOUT.
3929
3930 You may (and usually should) use the three-argument form of open to specify
3931 I/O layers (sometimes referred to as "disciplines") to apply to the handle
3932 that affect how the input and output are processed (see L<open> and
3933 L<PerlIO> for more details).  For example:
3934
3935   open(my $fh, "<:encoding(UTF-8)", "filename")
3936     || die "can't open UTF-8 encoded filename: $!";
3937
3938 opens the UTF8-encoded file containing Unicode characters;
3939 see L<perluniintro>.  Note that if layers are specified in the
3940 three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>;
3941 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3942 Those layers will also be ignored if you specifying a colon with no name
3943 following it.  In that case the default layer for the operating system
3944 (:raw on Unix, :crlf on Windows) is used.
3945
3946 Open returns nonzero on success, the undefined value otherwise.  If
3947 the C<open> involved a pipe, the return value happens to be the pid of
3948 the subprocess.
3949
3950 If you're running Perl on a system that distinguishes between text
3951 files and binary files, then you should check out L</binmode> for tips
3952 for dealing with this.  The key distinction between systems that need
3953 C<binmode> and those that don't is their text file formats.  Systems
3954 like Unix, Mac OS, and Plan 9, that end lines with a single
3955 character and encode that character in C as C<"\n"> do not
3956 need C<binmode>.  The rest need it.
3957
3958 When opening a file, it's seldom a good idea to continue 
3959 if the request failed, so C<open> is frequently used with
3960 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3961 where you want to format a suitable error message (but there are
3962 modules that can help with that problem)) always check
3963 the return value from opening a file.  
3964
3965 As a special case the three-argument form with a read/write mode and the third
3966 argument being C<undef>:
3967
3968     open(my $tmp, "+>", undef) or die ...
3969
3970 opens a filehandle to an anonymous temporary file.  Also using C<< +< >>
3971 works for symmetry, but you really should consider writing something
3972 to the temporary file first.  You will need to seek() to do the
3973 reading.
3974
3975 Perl is built using PerlIO by default; Unless you've
3976 changed this (such as building Perl with C<Configure -Uuseperlio>), you can
3977 open filehandles directly to Perl scalars via:
3978
3979     open($fh, ">", \$variable) || ..
3980
3981 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
3982
3983     close STDOUT;
3984     open(STDOUT, ">", \$variable)
3985         or die "Can't open STDOUT: $!";
3986
3987 General examples:
3988
3989     $ARTICLE = 100;
3990     open(ARTICLE) or die "Can't find article $ARTICLE: $!\n";
3991     while (<ARTICLE>) {...
3992
3993     open(LOG, ">>/usr/spool/news/twitlog");  # (log is reserved)
3994     # if the open fails, output is discarded
3995
3996     open(my $dbase, "+<", "dbase.mine")      # open for update
3997         or die "Can't open 'dbase.mine' for update: $!";
3998
3999     open(my $dbase, "+<dbase.mine")          # ditto
4000         or die "Can't open 'dbase.mine' for update: $!";
4001
4002     open(ARTICLE, "-|", "caesar <$article")  # decrypt article
4003         or die "Can't start caesar: $!";
4004
4005     open(ARTICLE, "caesar <$article |")      # ditto
4006         or die "Can't start caesar: $!";
4007
4008     open(EXTRACT, "|sort >Tmp$$")            # $$ is our process id
4009         or die "Can't start sort: $!";
4010
4011     # in-memory files
4012     open(MEMORY, ">", \$var)
4013         or die "Can't open memory file: $!";
4014     print MEMORY "foo!\n";              # output will appear in $var
4015
4016     # process argument list of files along with any includes
4017
4018     foreach $file (@ARGV) {
4019         process($file, "fh00");
4020     }
4021
4022     sub process {
4023         my($filename, $input) = @_;
4024         $input++;    # this is a string increment
4025         unless (open($input, "<", $filename)) {
4026             print STDERR "Can't open $filename: $!\n";
4027             return;
4028         }
4029
4030         local $_;
4031         while (<$input>) {    # note use of indirection
4032             if (/^#include "(.*)"/) {
4033                 process($1, $input);
4034                 next;
4035             }
4036             #...          # whatever
4037         }
4038     }
4039
4040 See L<perliol> for detailed info on PerlIO.
4041
4042 You may also, in the Bourne shell tradition, specify an EXPR beginning
4043 with C<< >& >>, in which case the rest of the string is interpreted
4044 as the name of a filehandle (or file descriptor, if numeric) to be
4045 duped (as C<dup(2)>) and opened.  You may use C<&> after C<< > >>,
4046 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
4047 The mode you specify should match the mode of the original filehandle.
4048 (Duping a filehandle does not take into account any existing contents
4049 of IO buffers.)  If you use the three-argument
4050 form, then you can pass either a
4051 number, the name of a filehandle, or the normal "reference to a glob".
4052
4053 Here is a script that saves, redirects, and restores C<STDOUT> and
4054 C<STDERR> using various methods:
4055
4056     #!/usr/bin/perl
4057     open(my $oldout, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4058     open(OLDERR,     ">&", \*STDERR) or die "Can't dup STDERR: $!";
4059
4060     open(STDOUT, '>', "foo.out") or die "Can't redirect STDOUT: $!";
4061     open(STDERR, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4062
4063     select STDERR; $| = 1;  # make unbuffered
4064     select STDOUT; $| = 1;  # make unbuffered
4065
4066     print STDOUT "stdout 1\n";  # this works for
4067     print STDERR "stderr 1\n";  # subprocesses too
4068
4069     open(STDOUT, ">&", $oldout) or die "Can't dup \$oldout: $!";
4070     open(STDERR, ">&OLDERR")    or die "Can't dup OLDERR: $!";
4071
4072     print STDOUT "stdout 2\n";
4073     print STDERR "stderr 2\n";
4074
4075 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
4076 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
4077 that file descriptor (and not call C<dup(2)>); this is more
4078 parsimonious of file descriptors.  For example:
4079
4080     # open for input, reusing the fileno of $fd
4081     open(FILEHANDLE, "<&=$fd")
4082
4083 or
4084
4085     open(FILEHANDLE, "<&=", $fd)
4086
4087 or
4088
4089     # open for append, using the fileno of OLDFH
4090     open(FH, ">>&=", OLDFH)
4091
4092 or
4093
4094     open(FH, ">>&=OLDFH")
4095
4096 Being parsimonious on filehandles is also useful (besides being
4097 parsimonious) for example when something is dependent on file
4098 descriptors, like for example locking using flock().  If you do just
4099 C<< open(A, ">>&B") >>, the filehandle A will not have the same file
4100 descriptor as B, and therefore flock(A) will not flock(B) nor vice
4101 versa.  But with C<< open(A, ">>&=B") >>, the filehandles will share
4102 the same underlying system file descriptor.
4103
4104 Note that under Perls older than 5.8.0, Perl uses the standard C library's'
4105 fdopen() to implement the C<=> functionality.  On many Unix systems,
4106 fdopen() fails when file descriptors exceed a certain value, typically 255.
4107 For Perls 5.8.0 and later, PerlIO is (most often) the default.
4108
4109 You can see whether your Perl was built with PerlIO by running C<perl -V>
4110 and looking for the C<useperlio=> line.  If C<useperlio> is C<define>, you
4111 have PerlIO; otherwise you don't.
4112
4113 If you open a pipe on the command C<-> (that is, specify either C<|-> or C<-|>
4114 with the one- or two-argument forms of C<open>), 
4115 an implicit C<fork> is done, so C<open> returns twice: in the parent
4116 process it returns the pid
4117 of the child process, and in the child process it returns (a defined) C<0>.
4118 Use C<defined($pid)> or C<//> to determine whether the open was successful.
4119
4120 For example, use either
4121
4122     $child_pid = open(FROM_KID, "-|")   // die "can't fork: $!";
4123
4124 or
4125
4126     $child_pid = open(TO_KID,   "|-")   // die "can't fork: $!";
4127
4128 followed by 
4129
4130     if ($child_pid) {
4131         # am the parent:
4132         # either write TO_KID or else read FROM_KID
4133         ...
4134        waitpid $child_pid, 0;
4135     } else {
4136         # am the child; use STDIN/STDOUT normally
4137         ...
4138         exit;
4139     } 
4140
4141 The filehandle behaves normally for the parent, but I/O to that
4142 filehandle is piped from/to the STDOUT/STDIN of the child process.
4143 In the child process, the filehandle isn't opened--I/O happens from/to
4144 the new STDOUT/STDIN.  Typically this is used like the normal
4145 piped open when you want to exercise more control over just how the
4146 pipe command gets executed, such as when running setuid and
4147 you don't want to have to scan shell commands for metacharacters.
4148
4149 The following blocks are more or less equivalent:
4150
4151     open(FOO, "|tr '[a-z]' '[A-Z]'");
4152     open(FOO, "|-", "tr '[a-z]' '[A-Z]'");
4153     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
4154     open(FOO, "|-", "tr", '[a-z]', '[A-Z]');
4155
4156     open(FOO, "cat -n '$file'|");
4157     open(FOO, "-|", "cat -n '$file'");
4158     open(FOO, "-|") || exec "cat", "-n", $file;
4159     open(FOO, "-|", "cat", "-n", $file);
4160
4161 The last two examples in each block show the pipe as "list form", which is
4162 not yet supported on all platforms.  A good rule of thumb is that if
4163 your platform has a real C<fork()> (in other words, if your platform is
4164 Unix, including Linux and MacOS X), you can use the list form.  You would 
4165 want to use the list form of the pipe so you can pass literal arguments
4166 to the command without risk of the shell interpreting any shell metacharacters
4167 in them.  However, this also bars you from opening pipes to commands
4168 that intentionally contain shell metacharacters, such as:
4169
4170     open(FOO, "|cat -n | expand -4 | lpr")
4171         // die "Can't open pipeline to lpr: $!";
4172
4173 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
4174
4175 Perl will attempt to flush all files opened for
4176 output before any operation that may do a fork, but this may not be
4177 supported on some platforms (see L<perlport>).  To be safe, you may need
4178 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
4179 of C<IO::Handle> on any open handles.
4180
4181 On systems that support a close-on-exec flag on files, the flag will
4182 be set for the newly opened file descriptor as determined by the value
4183 of C<$^F>.  See L<perlvar/$^F>.
4184
4185 Closing any piped filehandle causes the parent process to wait for the
4186 child to finish, then returns the status value in C<$?> and
4187 C<${^CHILD_ERROR_NATIVE}>.
4188
4189 The filename passed to the one- and two-argument forms of open() will
4190 have leading and trailing whitespace deleted and normal
4191 redirection characters honored.  This property, known as "magic open",
4192 can often be used to good effect.  A user could specify a filename of
4193 F<"rsh cat file |">, or you could change certain filenames as needed:
4194
4195     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
4196     open(FH, $filename) or die "Can't open $filename: $!";
4197
4198 Use the three-argument form to open a file with arbitrary weird characters in it,
4199
4200     open(FOO, "<", $file)
4201         || die "can't open < $file: $!";
4202
4203 otherwise it's necessary to protect any leading and trailing whitespace:
4204
4205     $file =~ s#^(\s)#./$1#;
4206     open(FOO, "< $file\0")
4207         || die "open failed: $!";
4208
4209 (this may not work on some bizarre filesystems).  One should
4210 conscientiously choose between the I<magic> and I<three-argument> form
4211 of open():
4212
4213     open(IN, $ARGV[0]) || die "can't open $ARGV[0]: $!";
4214
4215 will allow the user to specify an argument of the form C<"rsh cat file |">,
4216 but will not work on a filename that happens to have a trailing space, while
4217
4218     open(IN, "<", $ARGV[0])
4219         || die "can't open < $ARGV[0]: $!";
4220
4221 will have exactly the opposite restrictions.
4222
4223 If you want a "real" C C<open> (see L<open(2)> on your system), then you
4224 should use the C<sysopen> function, which involves no such magic (but may
4225 use subtly different filemodes than Perl open(), which is mapped to C
4226 fopen()).  This is another way to protect your filenames from
4227 interpretation.  For example:
4228
4229     use IO::Handle;
4230     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
4231         or die "sysopen $path: $!";
4232     $oldfh = select(HANDLE); $| = 1; select($oldfh);
4233     print HANDLE "stuff $$\n";
4234     seek(HANDLE, 0, 0);
4235     print "File contains: ", <HANDLE>;
4236
4237 Using the constructor from the C<IO::Handle> package (or one of its
4238 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
4239 filehandles that have the scope of the variables used to hold them, then
4240 automatically (but silently) close once their reference counts become
4241 zero, typically at scope exit:
4242
4243     use IO::File;
4244     #...
4245     sub read_myfile_munged {
4246         my $ALL = shift;
4247         # or just leave it undef to autoviv
4248         my $handle = IO::File->new;
4249         open($handle, "<", "myfile") or die "myfile: $!";
4250         $first = <$handle>
4251             or return ();     # Automatically closed here.
4252         mung($first) or die "mung failed";  # Or here.
4253         return (first, <$handle>) if $ALL;  # Or here.
4254         return $first;                      # Or here.
4255     }
4256
4257 B<WARNING:> The previous example has a bug because the automatic
4258 close that happens when the refcount on C<handle> reaches zero does not
4259 properly detect and report failures.  I<Always> close the handle
4260 yourself and inspect the return value.
4261
4262     close($handle) 
4263         || warn "close failed: $!";
4264
4265 See L</seek> for some details about mixing reading and writing.
4266
4267 Portability issues: L<perlport/open>.
4268
4269 =item opendir DIRHANDLE,EXPR
4270 X<opendir>
4271
4272 =for Pod::Functions open a directory
4273
4274 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
4275 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
4276 DIRHANDLE may be an expression whose value can be used as an indirect
4277 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
4278 scalar variable (or array or hash element), the variable is assigned a
4279 reference to a new anonymous dirhandle; that is, it's autovivified.
4280 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
4281
4282 See the example at C<readdir>.
4283
4284 =item ord EXPR
4285 X<ord> X<encoding>
4286
4287 =item ord
4288
4289 =for Pod::Functions find a character's numeric representation
4290
4291 Returns the numeric value of the first character of EXPR.
4292 If EXPR is an empty string, returns 0.  If EXPR is omitted, uses C<$_>.
4293 (Note I<character>, not byte.)
4294
4295 For the reverse, see L</chr>.
4296 See L<perlunicode> for more about Unicode.
4297
4298 =item our EXPR
4299 X<our> X<global>
4300
4301 =item our TYPE EXPR
4302
4303 =item our EXPR : ATTRS
4304
4305 =item our TYPE EXPR : ATTRS
4306
4307 =for Pod::Functions +5.6.0 declare and assign a package variable (lexical scoping)
4308
4309 C<our> makes a lexical alias to a package variable of the same name in the current
4310 package for use within the current lexical scope.
4311
4312 C<our> has the same scoping rules as C<my> or C<state>, but C<our> only
4313 declares an alias, whereas C<my> or C<state> both declare a variable name and
4314 allocate storage for that name within the current scope.
4315
4316 This means that when C<use strict 'vars'> is in effect, C<our> lets you use
4317 a package variable without qualifying it with the package name, but only within
4318 the lexical scope of the C<our> declaration.  In this way, C<our> differs from
4319 C<use vars>, which allows use of an unqualified name I<only> within the
4320 affected package, but across scopes.
4321
4322 If more than one value is listed, the list must be placed
4323 in parentheses.
4324
4325     our $foo;
4326     our($bar, $baz);
4327
4328 An C<our> declaration declares an alias for a package variable that will be visible
4329 across its entire lexical scope, even across package boundaries.  The
4330 package in which the variable is entered is determined at the point
4331 of the declaration, not at the point of use.  This means the following
4332 behavior holds:
4333
4334     package Foo;
4335     our $bar;      # declares $Foo::bar for rest of lexical scope
4336     $bar = 20;
4337
4338     package Bar;
4339     print $bar;    # prints 20, as it refers to $Foo::bar
4340
4341 Multiple C<our> declarations with the same name in the same lexical
4342 scope are allowed if they are in different packages.  If they happen
4343 to be in the same package, Perl will emit warnings if you have asked
4344 for them, just like multiple C<my> declarations.  Unlike a second
4345 C<my> declaration, which will bind the name to a fresh variable, a
4346 second C<our> declaration in the same package, in the same scope, is
4347 merely redundant.
4348
4349     use warnings;
4350     package Foo;
4351     our $bar;      # declares $Foo::bar for rest of lexical scope
4352     $bar = 20;
4353
4354     package Bar;
4355     our $bar = 30; # declares $Bar::bar for rest of lexical scope
4356     print $bar;    # prints 30
4357
4358     our $bar;      # emits warning but has no other effect
4359     print $bar;    # still prints 30
4360
4361 An C<our> declaration may also have a list of attributes associated
4362 with it.
4363
4364 The exact semantics and interface of TYPE and ATTRS are still
4365 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
4366 and attributes are handled using the C<attributes> pragma, or, starting
4367 from Perl 5.8.0, also via the C<Attribute::Handlers> module.  See
4368 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
4369 L<attributes>, and L<Attribute::Handlers>.
4370
4371 =item pack TEMPLATE,LIST
4372 X<pack>
4373
4374 =for Pod::Functions convert a list into a binary representation
4375
4376 Takes a LIST of values and converts it into a string using the rules
4377 given by the TEMPLATE.  The resulting string is the concatenation of
4378 the converted values.  Typically, each converted value looks
4379 like its machine-level representation.  For example, on 32-bit machines
4380 an integer may be represented by a sequence of 4 bytes, which  will in
4381 Perl be presented as a string that's 4 characters long. 
4382
4383 See L<perlpacktut> for an introduction to this function.
4384
4385 The TEMPLATE is a sequence of characters that give the order and type
4386 of values, as follows:
4387
4388     a  A string with arbitrary binary data, will be null padded.
4389     A  A text (ASCII) string, will be space padded.
4390     Z  A null-terminated (ASCIZ) string, will be null padded.
4391
4392     b  A bit string (ascending bit order inside each byte,
4393        like vec()).
4394     B  A bit string (descending bit order inside each byte).
4395     h  A hex string (low nybble first).
4396     H  A hex string (high nybble first).
4397
4398     c  A signed char (8-bit) value.
4399     C  An unsigned char (octet) value.
4400     W  An unsigned char value (can be greater than 255).
4401
4402     s  A signed short (16-bit) value.
4403     S  An unsigned short value.
4404
4405     l  A signed long (32-bit) value.
4406     L  An unsigned long value.
4407
4408     q  A signed quad (64-bit) value.
4409     Q  An unsigned quad value.
4410          (Quads are available only if your system supports 64-bit
4411           integer values _and_ if Perl has been compiled to support
4412           those.  Raises an exception otherwise.)
4413
4414     i  A signed integer value.
4415     I  A unsigned integer value.
4416          (This 'integer' is _at_least_ 32 bits wide.  Its exact
4417           size depends on what a local C compiler calls 'int'.)
4418
4419     n  An unsigned short (16-bit) in "network" (big-endian) order.
4420     N  An unsigned long (32-bit) in "network" (big-endian) order.
4421     v  An unsigned short (16-bit) in "VAX" (little-endian) order.
4422     V  An unsigned long (32-bit) in "VAX" (little-endian) order.
4423
4424     j  A Perl internal signed integer value (IV).
4425     J  A Perl internal unsigned integer value (UV).
4426
4427     f  A single-precision float in native format.
4428     d  A double-precision float in native format.
4429
4430     F  A Perl internal floating-point value (NV) in native format
4431     D  A float of long-double precision in native format.
4432          (Long doubles are available only if your system supports
4433           long double values _and_ if Perl has been compiled to
4434           support those.  Raises an exception otherwise.)
4435
4436     p  A pointer to a null-terminated string.
4437     P  A pointer to a structure (fixed-length string).
4438
4439     u  A uuencoded string.
4440     U  A Unicode character number.  Encodes to a character in char-
4441        acter mode and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in
4442        byte mode.
4443
4444     w  A BER compressed integer (not an ASN.1 BER, see perlpacktut
4445        for details).  Its bytes represent an unsigned integer in
4446        base 128, most significant digit first, with as few digits
4447        as possible.  Bit eight (the high bit) is set on each byte
4448        except the last.
4449
4450     x  A null byte (a.k.a ASCII NUL, "\000", chr(0))
4451     X  Back up a byte.
4452     @  Null-fill or truncate to absolute position, counted from the
4453        start of the innermost ()-group.
4454     .  Null-fill or truncate to absolute position specified by
4455        the value.
4456     (  Start of a ()-group.
4457
4458 One or more modifiers below may optionally follow certain letters in the
4459 TEMPLATE (the second column lists letters for which the modifier is valid):
4460
4461     !   sSlLiI     Forces native (short, long, int) sizes instead
4462                    of fixed (16-/32-bit) sizes.
4463
4464         xX         Make x and X act as alignment commands.
4465
4466         nNvV       Treat integers as signed instead of unsigned.
4467
4468         @.         Specify position as byte offset in the internal
4469                    representation of the packed string.  Efficient
4470                    but dangerous.
4471
4472     >   sSiIlLqQ   Force big-endian byte-order on the type.
4473         jJfFdDpP   (The "big end" touches the construct.)
4474
4475     <   sSiIlLqQ   Force little-endian byte-order on the type.
4476         jJfFdDpP   (The "little end" touches the construct.)
4477
4478 The C<< > >> and C<< < >> modifiers can also be used on C<()> groups 
4479 to force a particular byte-order on all components in that group, 
4480 including all its subgroups.
4481
4482 =begin comment
4483
4484 Larry recalls that the hex and bit string formats (H, h, B, b) were added to
4485 pack for processing data from NASA's Magellan probe. Magellan was in an
4486 elliptical orbit, using the antenna for the radar mapping when close to
4487 Venus and for communicating data back to Earth for the rest of the orbit.
4488 There were two transmission units, but one of these failed, and then the
4489 other developed a fault whereby it would randomly flip the sense of all the
4490 bits. It was easy to automatically detect complete records with the correct
4491 sense, and complete records with all the bits flipped. However, this didn't
4492 recover the records where the sense flipped midway. A colleague of Larry's
4493 was able to pretty much eyeball where the records flipped, so they wrote an
4494 editor named kybble (a pun on the dog food Kibbles 'n Bits) to enable him to
4495 manually correct the records and recover the data. For this purpose pack
4496 gained the hex and bit string format specifiers.
4497
4498 git shows that they were added to perl 3.0 in patch #44 (Jan 1991, commit
4499 27e2fb84680b9cc1), but the patch description makes no mention of their
4500 addition, let alone the story behind them.
4501
4502 =end comment
4503
4504 The following rules apply:
4505
4506 =over 
4507
4508 =item *
4509
4510 Each letter may optionally be followed by a number indicating the repeat
4511 count.  A numeric repeat count may optionally be enclosed in brackets, as
4512 in C<pack("C[80]", @arr)>.  The repeat count gobbles that many values from
4513 the LIST when used with all format types other than C<a>, C<A>, C<Z>, C<b>,
4514 C<B>, C<h>, C<H>, C<@>, C<.>, C<x>, C<X>, and C<P>, where it means
4515 something else, described below.  Supplying a C<*> for the repeat count
4516 instead of a number means to use however many items are left, except for:
4517
4518 =over 
4519
4520 =item * 
4521
4522 C<@>, C<x>, and C<X>, where it is equivalent to C<0>.
4523
4524 =item * 
4525
4526 <.>, where it means relative to the start of the string.
4527
4528 =item * 
4529
4530 C<u>, where it is equivalent to 1 (or 45, which here is equivalent).
4531
4532 =back 
4533
4534 One can replace a numeric repeat count with a template letter enclosed in
4535 brackets to use the packed byte length of the bracketed template for the
4536 repeat count.
4537
4538 For example, the template C<x[L]> skips as many bytes as in a packed long,
4539 and the template C<"$t X[$t] $t"> unpacks twice whatever $t (when
4540 variable-expanded) unpacks.  If the template in brackets contains alignment
4541 commands (such as C<x![d]>), its packed length is calculated as if the
4542 start of the template had the maximal possible alignment.
4543
4544 When used with C<Z>, a C<*> as the repeat count is guaranteed to add a
4545 trailing null byte, so the resulting string is always one byte longer than
4546 the byte length of the item itself.
4547
4548 When used with C<@>, the repeat count represents an offset from the start
4549 of the innermost C<()> group.
4550
4551 When used with C<.>, the repeat count determines the starting position to
4552 calculate the value offset as follows:
4553
4554 =over 
4555
4556 =item *
4557
4558 If the repeat count is C<0>, it's relative to the current position.
4559
4560 =item *
4561
4562 If the repeat count is C<*>, the offset is relative to the start of the
4563 packed string.
4564
4565 =item *
4566
4567 And if it's an integer I<n>, the offset is relative to the start of the
4568 I<n>th innermost C<( )> group, or to the start of the string if I<n> is
4569 bigger then the group level.
4570
4571 =back
4572
4573 The repeat count for C<u> is interpreted as the maximal number of bytes
4574 to encode per line of output, with 0, 1 and 2 replaced by 45.  The repeat 
4575 count should not be more than 65.
4576
4577 =item *
4578
4579 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
4580 string of length count, padding with nulls or spaces as needed.  When
4581 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
4582 after the first null, and C<a> returns data with no stripping at all.
4583
4584 If the value to pack is too long, the result is truncated.  If it's too
4585 long and an explicit count is provided, C<Z> packs only C<$count-1> bytes,
4586 followed by a null byte.  Thus C<Z> always packs a trailing null, except
4587 when the count is 0.
4588
4589 =item *
4590
4591 Likewise, the C<b> and C<B> formats pack a string that's that many bits long.
4592 Each such format generates 1 bit of the result.  These are typically followed
4593 by a repeat count like C<B8> or C<B64>.
4594
4595 Each result bit is based on the least-significant bit of the corresponding
4596 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
4597 and C<"1"> generate bits 0 and 1, as do characters C<"\000"> and C<"\001">.
4598
4599 Starting from the beginning of the input string, each 8-tuple
4600 of characters is converted to 1 character of output.  With format C<b>,
4601 the first character of the 8-tuple determines the least-significant bit of a
4602 character; with format C<B>, it determines the most-significant bit of
4603 a character.
4604
4605 If the length of the input string is not evenly divisible by 8, the
4606 remainder is packed as if the input string were padded by null characters
4607 at the end.  Similarly during unpacking, "extra" bits are ignored.
4608
4609 If the input string is longer than needed, remaining characters are ignored.
4610
4611 A C<*> for the repeat count uses all characters of the input field.  
4612 On unpacking, bits are converted to a string of C<0>s and C<1>s.
4613
4614 =item *
4615
4616 The C<h> and C<H> formats pack a string that many nybbles (4-bit groups,
4617 representable as hexadecimal digits, C<"0".."9"> C<"a".."f">) long.
4618
4619 For each such format, pack() generates 4 bits of result.
4620 With non-alphabetical characters, the result is based on the 4 least-significant
4621 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
4622 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
4623 C<"\000"> and C<"\001">.  For characters C<"a".."f"> and C<"A".."F">, the result
4624 is compatible with the usual hexadecimal digits, so that C<"a"> and
4625 C<"A"> both generate the nybble C<0xA==10>.  Use only these specific hex 
4626 characters with this format.
4627
4628 Starting from the beginning of the template to pack(), each pair
4629 of characters is converted to 1 character of output.  With format C<h>, the
4630 first character of the pair determines the least-significant nybble of the
4631 output character; with format C<H>, it determines the most-significant
4632 nybble.
4633
4634 If the length of the input string is not even, it behaves as if padded by
4635 a null character at the end.  Similarly, "extra" nybbles are ignored during
4636 unpacking.
4637
4638 If the input string is longer than needed, extra characters are ignored.
4639
4640 A C<*> for the repeat count uses all characters of the input field.  For
4641 unpack(), nybbles are converted to a string of hexadecimal digits.
4642
4643 =item *
4644
4645 The C<p> format packs a pointer to a null-terminated string.  You are
4646 responsible for ensuring that the string is not a temporary value, as that
4647 could potentially get deallocated before you got around to using the packed
4648 result.  The C<P> format packs a pointer to a structure of the size indicated
4649 by the length.  A null pointer is created if the corresponding value for
4650 C<p> or C<P> is C<undef>; similarly with unpack(), where a null pointer
4651 unpacks into C<undef>.
4652
4653 If your system has a strange pointer size--meaning a pointer is neither as
4654 big as an int nor as big as a long--it may not be possible to pack or
4655 unpack pointers in big- or little-endian byte order.  Attempting to do
4656 so raises an exception.
4657
4658 =item *
4659
4660 The C</> template character allows packing and unpacking of a sequence of
4661 items where the packed structure contains a packed item count followed by
4662 the packed items themselves.  This is useful when the structure you're
4663 unpacking has encoded the sizes or repeat counts for some of its fields
4664 within the structure itself as separate fields.
4665
4666 For C<pack>, you write I<length-item>C</>I<sequence-item>, and the
4667 I<length-item> describes how the length value is packed.  Formats likely
4668 to be of most use are integer-packing ones like C<n> for Java strings,
4669 C<w> for ASN.1 or SNMP, and C<N> for Sun XDR.
4670
4671 For C<pack>, I<sequence-item> may have a repeat count, in which case
4672 the minimum of that and the number of available items is used as the argument
4673 for I<length-item>.  If it has no repeat count or uses a '*', the number
4674 of available items is used.
4675
4676 For C<unpack>, an internal stack of integer arguments unpacked so far is
4677 used.  You write C</>I<sequence-item> and the repeat count is obtained by
4678 popping off the last element from the stack.  The I<sequence-item> must not
4679 have a repeat count.
4680
4681 If I<sequence-item> refers to a string type (C<"A">, C<"a">, or C<"Z">),
4682 the I<length-item> is the string length, not the number of strings.  With
4683 an explicit repeat count for pack, the packed string is adjusted to that
4684 length.  For example:
4685
4686  This code:                             gives this result:
4687
4688  unpack("W/a", "\004Gurusamy")          ("Guru")
4689  unpack("a3/A A*", "007 Bond  J ")      (" Bond", "J")
4690  unpack("a3 x2 /A A*", "007: Bond, J.") ("Bond, J", ".")
4691
4692  pack("n/a* w/a","hello,","world")     "\000\006hello,\005world"
4693  pack("a/W2", ord("a") .. ord("z"))    "2ab"
4694
4695 The I<length-item> is not returned explicitly from C<unpack>.
4696
4697 Supplying a count to the I<length-item> format&nbs