ext/DynaLoader/DynaLoader_pm.PL

   1 use Config;
   2
   3 sub to_string {
   4     my ($value) = @_;
   5     $value =~ s/\\/\\\\/g;
   6     $value =~ s/'/\\'/g;
   7     return "'$value'";
   8 }
   9
  10 #
  11 # subroutine expand_os_specific expands $^O-specific preprocessing information
  12 # so that it will not be re-calculated at runtime in Dynaloader.pm
  13 #
  14 # Syntax of preprocessor should be kept extremely simple:
  15 #  - directives are in double angle brackets <<...>>
  16 #  - <<=string>> will be just evaluated
  17 #  - for $^O-specific there are two forms:
  18 #   <<$^O-eq-osname>>
  19 #   <<$^O-ne-osname>>
  20 #  this directive should be closed with respectively
  21 #   <</$^O-eq-osname>>
  22 #   <</$^O-ne-osname>>
  23 #  construct <<|$^O-ne-osname>> means #else
  24 #  nested <<$^O...>>-constructs are allowed but nested values must be for
  25 #   different OS-names!
  26 #
  27 #  -- added by VKON, 03-10-2004 to separate $^O-specific between OSes
  28 #     (so that Win32 never checks for $^O eq 'VMS' for example)
  29 #
  30 # The $^O tests test both for $^O and for $Config{osname}.
  31 # The latter is better for some for cross-compilation setups.
  32 #
  33 sub expand_os_specific {
  34     my $s = shift;
  35     for ($s) {
  36         s/<<=(.*?)>>/$1/gee;
  37         s/<<\$\^O-(eq|ne)-(\w+)>>(.*?)<<\/\$\^O-\1-\2>>/
  38           my ($op, $os, $expr) = ($1,$2,$3);
  39           if ($op ne 'eq' and $op ne 'ne') {die "wrong eq-ne arg in $&"};
  40           if ($expr =~ m[^(.*?)<<\|\$\^O-$op-$os>>(.*?)$]s) {
  41               # #if;#else;#endif
  42               my ($if,$el) = ($1,$2);
  43               if (($op eq 'eq' and ($^O eq $os || $Config{osname} eq $os)) || ($op eq 'ne' and ($^O ne $os || $Config{osname} ne $os))) {
  44                   $if
  45               }
  46               else {
  47                   $el
  48               }
  49           }
  50           else {
  51               # #if;#endif
  52               if (($op eq 'eq' and ($^O eq $os || $Config{osname} eq $os)) || ($op eq 'ne' and ($^O ne $os || $Config{osname} ne $os))) {
  53                   $expr
  54               }
  55               else {
  56                   ""
  57               }
  58           }
  59         /ges;
  60         if (/<<(=|\$\^O-)/) {die "bad <<\$^O-eq/ne-osname>> expression.".
  61             " Unclosed brackets?";
  62         }
  63     }
  64     $s;
  65 }
  66
  67 unlink "DynaLoader.pm" if -f "DynaLoader.pm";
  68 open OUT, ">DynaLoader.pm" or die $!;
  69 print OUT <<'EOT';
  70
  71 # Generated from DynaLoader_pm.PL, this file is unique for every OS
  72
  73 package DynaLoader;
  74
  75 #   And Gandalf said: 'Many folk like to know beforehand what is to
  76 #   be set on the table; but those who have laboured to prepare the
  77 #   feast like to keep their secret; for wonder makes the words of
  78 #   praise louder.'
  79
  80 #   (Quote from Tolkien suggested by Anno Siegel.)
  81 #
  82 # See pod text at end of file for documentation.
  83 # See also ext/DynaLoader/README in source tree for other information.
  84 #
  85 # Tim.Bunce@ig.co.uk, August 1994
  86
  87 BEGIN {
  88     $VERSION = '1.36';
  89 }
  90
  91 EOT
  92
  93 if (!$ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
  94     print OUT "use Config;\n";
  95 }
  96
  97 print OUT <<'EOT';
  98
  99 # enable debug/trace messages from DynaLoader perl code
 100 $dl_debug = $ENV{PERL_DL_DEBUG} || 0 unless defined $dl_debug;
 101
 102 #
 103 # Flags to alter dl_load_file behaviour.  Assigned bits:
 104 #   0x01  make symbols available for linking later dl_load_file's.
 105 #         (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
 106 #         (ignored under VMS; effect is built-in to image linking)
 107 #         (ignored under Android; the linker always uses RTLD_LOCAL)
 108 #
 109 # This is called as a class method $module->dl_load_flags.  The
 110 # definition here will be inherited and result on "default" loading
 111 # behaviour unless a sub-class of DynaLoader defines its own version.
 112 #
 113
 114 sub dl_load_flags { 0x00 }
 115
 116 EOT
 117
 118 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
 119     print OUT "(\$dl_dlext, \$dl_so, \$dlsrc) = (",
 120               to_string($Config{'dlext'}), ",",
 121               to_string($Config{'so'}), ",",
 122               to_string($Config{'dlsrc'}), ")\n;" ;
 123 }
 124 else {
 125     print OUT <<'EOT';
 126 ($dl_dlext, $dl_so, $dlsrc) = @Config::Config{qw(dlext so dlsrc)};
 127 EOT
 128 }
 129
 130 print OUT expand_os_specific(<<'EOT');
 131
 132 <<$^O-eq-VMS>>
 133 # Some systems need special handling to expand file specifications
 134 # (VMS support by Charles Bailey <bailey@HMIVAX.HUMGEN.UPENN.EDU>)
 135 # See dl_expandspec() for more details. Should be harmless but
 136 # inefficient to define on systems that don't need it.
 137 $Is_VMS    = $^O eq 'VMS';
 138 <</$^O-eq-VMS>>
 139 $do_expand = <<$^O-eq-VMS>>1<<|$^O-eq-VMS>>0<</$^O-eq-VMS>>;
 140
 141 @dl_require_symbols = ();       # names of symbols we need<<$^O-eq-freemint>>
 142 @dl_resolve_using   = ();       # names of files to link with<</$^O-eq-freemint>><<$^O-eq-hpux>>
 143 @dl_resolve_using   = ();       # names of files to link with<</$^O-eq-hpux>>
 144 @dl_library_path    = ();       # path to look for files
 145
 146 #XSLoader.pm may have added elements before we were required
 147 #@dl_shared_objects  = ();       # shared objects for symbols we have
 148 #@dl_librefs         = ();       # things we have loaded
 149 #@dl_modules         = ();       # Modules we have loaded
 150
 151 EOT
 152
 153 my $cfg_dl_library_path = <<'EOT';
 154 push(@dl_library_path, split(' ', $Config::Config{libpth}));
 155 EOT
 156
 157 sub dquoted_comma_list {
 158     join(", ", map {'"'.quotemeta($_).'"'} @_);
 159 }
 160
 161 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
 162     eval $cfg_dl_library_path;
 163     if (!$ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
 164         my $dl_library_path = dquoted_comma_list(@dl_library_path);
 165         print OUT <<EOT;
 166 # The below \@dl_library_path has been expanded (%Config) in Perl build time.
 167
 168 \@dl_library_path = ($dl_library_path);
 169
 170 EOT
 171     }
 172 }
 173 else {
 174     print OUT <<EOT;
 175 # Initialise \@dl_library_path with the 'standard' library path
 176 # for this platform as determined by Configure.
 177
 178 $cfg_dl_library_path
 179
 180 EOT
 181 }
 182
 183 my $ldlibpthname;
 184 my $ldlibpthname_defined;
 185 my $pthsep;
 186
 187 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
 188     $ldlibpthname         = to_string($Config::Config{ldlibpthname});
 189     $ldlibpthname_defined = to_string(defined $Config::Config{ldlibpthname} ? 1 : 0);
 190     $pthsep               = to_string($Config::Config{path_sep});
 191 }
 192 else {
 193     $ldlibpthname         = q($Config::Config{ldlibpthname});
 194     $ldlibpthname_defined = q(defined $Config::Config{ldlibpthname});
 195     $pthsep               = q($Config::Config{path_sep});
 196 }
 197 print OUT <<EOT;
 198 my \$ldlibpthname         = $ldlibpthname;
 199 my \$ldlibpthname_defined = $ldlibpthname_defined;
 200 my \$pthsep               = $pthsep;
 201
 202 EOT
 203
 204 my $env_dl_library_path = <<'EOT';
 205 if ($ldlibpthname_defined &&
 206     exists $ENV{$ldlibpthname}) {
 207     push(@dl_library_path, split(/$pthsep/, $ENV{$ldlibpthname}));
 208 }
 209
 210 # E.g. HP-UX supports both its native SHLIB_PATH *and* LD_LIBRARY_PATH.
 211
 212 if ($ldlibpthname_defined &&
 213     $ldlibpthname ne 'LD_LIBRARY_PATH' &&
 214     exists $ENV{LD_LIBRARY_PATH}) {
 215     push(@dl_library_path, split(/$pthsep/, $ENV{LD_LIBRARY_PATH}));
 216 }
 217 EOT
 218
 219 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS} && $ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
 220     eval $env_dl_library_path;
 221 }
 222 else {
 223     print OUT <<EOT;
 224 # Add to \@dl_library_path any extra directories we can gather from environment
 225 # during runtime.
 226
 227 $env_dl_library_path
 228
 229 EOT
 230 }
 231
 232 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS} && $ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
 233     my $dl_library_path = dquoted_comma_list(@dl_library_path);
 234     print OUT <<EOT;
 235 # The below \@dl_library_path has been expanded (%Config, %ENV)
 236 # in Perl build time.
 237
 238 \@dl_library_path = ($dl_library_path);
 239
 240 EOT
 241 }
 242
 243 if ( $Config::Config{d_libname_unique} ) {
 244     printf OUT <<'EOT', length($Config::Config{dlext}) + 1;
 245 sub mod2fname {
 246     my $parts = shift;
 247     my $so_len = %d;
 248     my $name_max = 255; # No easy way to get this here
 249
 250     my $libname = "PL_" .  join("__", @$parts);
 251
 252     return $libname if (length($libname)+$so_len) <= $name_max;
 253
 254     # It's too darned big, so we need to go strip. We use the same
 255     # algorithm as xsubpp does. First, strip out doubled __
 256     $libname =~ s/__/_/g;
 257     return $libname if (length($libname)+$so_len) <= $name_max;
 258
 259     # Strip duplicate letters
 260     1 while $libname =~ s/(.)\1/\U$1/i;
 261     return $libname if (length($libname)+$so_len) <= $name_max;
 262
 263     # Still too long. Truncate.
 264     $libname = substr($libname, 0, $name_max - $so_len);
 265     return $libname;
 266 }
 267 EOT
 268 }
 269
 270 # following long string contains $^O-specific stuff, which is factored out
 271 print OUT expand_os_specific(<<'EOT');
 272 # No prizes for guessing why we don't say 'bootstrap DynaLoader;' here.
 273 # NOTE: All dl_*.xs (including dl_none.xs) define a dl_error() XSUB
 274 boot_DynaLoader('DynaLoader') if defined(&boot_DynaLoader) &&
 275                                 !defined(&dl_error);
 276
 277 if ($dl_debug) {
 278     print STDERR "DynaLoader.pm loaded (@INC, @dl_library_path)\n";
 279     print STDERR "DynaLoader not linked into this perl\n"
 280             unless defined(&boot_DynaLoader);
 281 }
 282
 283 1; # End of main code
 284
 285
 286 sub croak   { require Carp; Carp::croak(@_)   }
 287
 288 sub bootstrap_inherit {
 289     my $module = $_[0];
 290     local *isa = *{"$module\::ISA"};
 291     local @isa = (@isa, 'DynaLoader');
 292     # Cannot goto due to delocalization.  Will report errors on a wrong line?
 293     bootstrap(@_);
 294 }
 295
 296 sub bootstrap {
 297     # use local vars to enable $module.bs script to edit values
 298     local(@args) = @_;
 299     local($module) = $args[0];
 300     local(@dirs, $file);
 301
 302     unless ($module) {
 303         require Carp;
 304         Carp::confess("Usage: DynaLoader::bootstrap(module)");
 305     }
 306
 307     # A common error on platforms which don't support dynamic loading.
 308     # Since it's fatal and potentially confusing we give a detailed message.
 309     croak("Can't load module $module, dynamic loading not available in this perl.\n".
 310         "  (You may need to build a new perl executable which either supports\n".
 311         "  dynamic loading or has the $module module statically linked into it.)\n")
 312         unless defined(&dl_load_file);
 313
 314
 315     <<$^O-eq-os2>>
 316     # Can dynaload, but cannot dynaload Perl modules...
 317     die 'Dynaloaded Perl modules are not available in this build of Perl' if $OS2::is_static;
 318
 319     <</$^O-eq-os2>>
 320     my @modparts = split(/::/,$module);
 321     my $modfname = $modparts[-1];
 322
 323     # Some systems have restrictions on files names for DLL's etc.
 324     # mod2fname returns appropriate file base name (typically truncated)
 325     # It may also edit @modparts if required.
 326     $modfname = &mod2fname(\@modparts) if defined &mod2fname;
 327
 328     <<$^O-eq-NetWare>>
 329     # Truncate the module name to 8.3 format for NetWare
 330         if ((length($modfname) > 8)) {
 331                 $modfname = substr($modfname, 0, 8);
 332         }
 333     <</$^O-eq-NetWare>>
 334
 335     my $modpname = join('/',@modparts);
 336
 337     print STDERR "DynaLoader::bootstrap for $module ",
 338                        "(auto/$modpname/$modfname.$dl_dlext)\n"
 339         if $dl_debug;
 340
 341     foreach (@INC) {
 342         <<$^O-eq-VMS>>chop($_ = VMS::Filespec::unixpath($_));<</$^O-eq-VMS>>
 343             my $dir = "$_/auto/$modpname";
 344
 345         next unless -d $dir; # skip over uninteresting directories
 346
 347         # check for common cases to avoid autoload of dl_findfile
 348         my $try = "$dir/$modfname.$dl_dlext";
 349         last if $file = ($do_expand) ? dl_expandspec($try) : ((-f $try) && $try);
 350
 351         # no luck here, save dir for possible later dl_findfile search
 352         push @dirs, $dir;
 353     }
 354     # last resort, let dl_findfile have a go in all known locations
 355     $file = dl_findfile(map("-L$_",@dirs,@INC), $modfname) unless $file;
 356
 357     croak("Can't locate loadable object for module $module in \@INC (\@INC contains: @INC)")
 358         unless $file;   # wording similar to error from 'require'
 359
 360     <<$^O-eq-VMS>>$file = uc($file) if $Config::Config{d_vms_case_sensitive_symbols};<</$^O-eq-VMS>>
 361     my $bootname = "boot_$module";
 362     $bootname =~ s/\W/_/g;
 363     @dl_require_symbols = ($bootname);
 364
 365     # Execute optional '.bootstrap' perl script for this module.
 366     # The .bs file can be used to configure @dl_resolve_using etc to
 367     # match the needs of the individual module on this architecture.
 368     my $bs = $file;
 369     $bs =~ s/(\.\w+)?(;\d*)?$/\.bs/; # look for .bs 'beside' the library
 370     if (-s $bs) { # only read file if it's not empty
 371         print STDERR "BS: $bs ($^O, $dlsrc)\n" if $dl_debug;
 372         eval { do $bs; };
 373         warn "$bs: $@\n" if $@;
 374     }
 375
 376     my $boot_symbol_ref;
 377
 378     <<$^O-eq-darwin>>
 379     if ($boot_symbol_ref = dl_find_symbol(0, $bootname)) {
 380         goto boot; #extension library has already been loaded, e.g. darwin
 381     }
 382     <</$^O-eq-darwin>>
 383
 384     # Many dynamic extension loading problems will appear to come from
 385     # this section of code: XYZ failed at line 123 of DynaLoader.pm.
 386     # Often these errors are actually occurring in the initialisation
 387     # C code of the extension XS file. Perl reports the error as being
 388     # in this perl code simply because this was the last perl code
 389     # it executed.
 390
 391     my $flags = $module->dl_load_flags;
 392     <<$^O-eq-android>>
 393     # See the note above regarding the linker.
 394     $flags = 0x00;
 395     <</$^O-eq-android>>
 396     my $libref = dl_load_file($file, $flags) or
 397         croak("Can't load '$file' for module $module: ".dl_error());
 398
 399     push(@dl_librefs,$libref);  # record loaded object
 400 <<$^O-eq-freemint>>
 401     my @unresolved = dl_undef_symbols();
 402     if (@unresolved) {
 403         require Carp;
 404         Carp::carp("Undefined symbols present after loading $file: @unresolved\n");
 405     }
 406 <</$^O-eq-freemint>>
 407     $boot_symbol_ref = dl_find_symbol($libref, $bootname) or
 408          croak("Can't find '$bootname' symbol in $file\n");
 409
 410     push(@dl_modules, $module); # record loaded module
 411
 412   boot:
 413     my $xs = dl_install_xsub("${module}::bootstrap", $boot_symbol_ref, $file);
 414
 415     # See comment block above
 416
 417         push(@dl_shared_objects, $file); # record files loaded
 418
 419     &$xs(@args);
 420 }
 421
 422 sub dl_findfile {
 423     # This function does not automatically consider the architecture
 424     # or the perl library auto directories.
 425     my (@args) = @_;
 426     my (@dirs,  $dir);   # which directories to search
 427     my (@found);         # full paths to real files we have found
 428     #my $dl_ext= <<=to_string($Config::Config{'dlext'})>>; # $Config::Config{'dlext'} suffix for perl extensions
 429     #my $dl_so = <<=to_string($Config::Config{'so'})>>; # $Config::Config{'so'} suffix for shared libraries
 430
 431     print STDERR "dl_findfile(@args)\n" if $dl_debug;
 432
 433     # accumulate directories but process files as they appear
 434     arg: foreach(@args) {
 435         #  Special fast case: full filepath requires no search
 436         <<$^O-eq-VMS>>
 437         if (m%[:>/\]]% && -f $_) {
 438             push(@found,dl_expandspec(VMS::Filespec::vmsify($_)));
 439             last arg unless wantarray;
 440             next;
 441         }
 442         <</$^O-eq-VMS>>
 443         <<$^O-ne-VMS>>
 444         if (m:/: && -f $_) {
 445             push(@found,$_);
 446             last arg unless wantarray;
 447             next;
 448         }
 449         <</$^O-ne-VMS>>
 450
 451         # Deal with directories first:
 452         #  Using a -L prefix is the preferred option (faster and more robust)
 453         if (m:^-L:) { s/^-L//; push(@dirs, $_); next; }
 454
 455         #  Otherwise we try to try to spot directories by a heuristic
 456         #  (this is a more complicated issue than it first appears)
 457         if (m:/: && -d $_) {   push(@dirs, $_); next; }
 458
 459         <<$^O-eq-VMS>>
 460         # VMS: we may be using native VMS directory syntax instead of
 461         # Unix emulation, so check this as well
 462         if (/[:>\]]/ && -d $_) {   push(@dirs, $_); next; }
 463         <</$^O-eq-VMS>>
 464
 465         #  Only files should get this far...
 466         my(@names, $name);    # what filenames to look for
 467         if (m:-l: ) {          # convert -lname to appropriate library name
 468             s/-l//;
 469             push(@names,"lib$_.$dl_so");
 470             push(@names,"lib$_.a");
 471         } else {                # Umm, a bare name. Try various alternatives:
 472             # these should be ordered with the most likely first
 473             push(@names,"$_.$dl_dlext")    unless m/\.$dl_dlext$/o;
 474             push(@names,"$_.$dl_so")     unless m/\.$dl_so$/o;
 475             <<$^O-eq-cygwin>>
 476             push(@names,"cyg$_.$dl_so")  unless m:/:;
 477             <</$^O-eq-cygwin>>
 478             push(@names,"lib$_.$dl_so")  unless m:/:;
 479             push(@names, $_);
 480         }
 481         my $dirsep = '/';
 482         <<$^O-eq-symbian>>
 483         $dirsep = '\\';
 484         if ($0 =~ /^([a-z]):/i) {
 485             my $drive = $1;
 486             @dirs = map { "$drive:$_" } @dirs;
 487             @dl_library_path = map { "$drive:$_" } @dl_library_path;
 488         }
 489         <</$^O-eq-symbian>>
 490         foreach $dir (@dirs, @dl_library_path) {
 491             next unless -d $dir;
 492             <<$^O-eq-VMS>>
 493             chop($dir = VMS::Filespec::unixpath($dir));
 494             <</$^O-eq-VMS>>
 495             foreach $name (@names) {
 496                 my($file) = "$dir$dirsep$name";
 497                 print STDERR " checking in $dir for $name\n" if $dl_debug;
 498                 $file = ($do_expand) ? dl_expandspec($file) : (-f $file && $file);
 499                 #$file = _check_file($file);
 500                 if ($file) {
 501                     push(@found, $file);
 502                     next arg; # no need to look any further
 503                 }
 504             }
 505         }
 506     }
 507     if ($dl_debug) {
 508         foreach(@dirs) {
 509             print STDERR " dl_findfile ignored non-existent directory: $_\n" unless -d $_;
 510         }
 511         print STDERR "dl_findfile found: @found\n";
 512     }
 513     return $found[0] unless wantarray;
 514     @found;
 515 }
 516
 517
 518 <<$^O-eq-VMS>>
 519 # dl_expandspec should be defined in dl_vms.xs
 520 <<|$^O-eq-VMS>>
 521 sub dl_expandspec {
 522     my($spec) = @_;
 523     # Optional function invoked if DynaLoader.pm sets $do_expand.
 524     # Most systems do not require or use this function.
 525     # Some systems may implement it in the dl_*.xs file in which case
 526     # this Perl version should be excluded at build time.
 527
 528     # This function is designed to deal with systems which treat some
 529     # 'filenames' in a special way. For example VMS 'Logical Names'
 530     # (something like unix environment variables - but different).
 531     # This function should recognise such names and expand them into
 532     # full file paths.
 533     # Must return undef if $spec is invalid or file does not exist.
 534
 535     my $file = $spec; # default output to input
 536
 537         return undef unless -f $file;
 538     print STDERR "dl_expandspec($spec) => $file\n" if $dl_debug;
 539     $file;
 540 }
 541 <</$^O-eq-VMS>>
 542
 543 sub dl_find_symbol_anywhere
 544 {
 545     my $sym = shift;
 546     my $libref;
 547     foreach $libref (@dl_librefs) {
 548         my $symref = dl_find_symbol($libref,$sym);
 549         return $symref if $symref;
 550     }
 551     return undef;
 552 }
 553
 554 __END__
 555
 556 =head1 NAME
 557
 558 DynaLoader - Dynamically load C libraries into Perl code
 559
 560 =head1 SYNOPSIS
 561
 562     package YourPackage;
 563     require DynaLoader;
 564     @ISA = qw(... DynaLoader ...);
 565     bootstrap YourPackage;
 566
 567     # optional method for 'global' loading
 568     sub dl_load_flags { 0x01 }
 569
 570
 571 =head1 DESCRIPTION
 572
 573 This document defines a standard generic interface to the dynamic
 574 linking mechanisms available on many platforms.  Its primary purpose is
 575 to implement automatic dynamic loading of Perl modules.
 576
 577 This document serves as both a specification for anyone wishing to
 578 implement the DynaLoader for a new platform and as a guide for
 579 anyone wishing to use the DynaLoader directly in an application.
 580
 581 The DynaLoader is designed to be a very simple high-level
 582 interface that is sufficiently general to cover the requirements
 583 of SunOS, HP-UX, Linux, VMS and other platforms.
 584
 585 It is also hoped that the interface will cover the needs of OS/2, NT
 586 etc and also allow pseudo-dynamic linking (using C<ld -A> at runtime).
 587
 588 It must be stressed that the DynaLoader, by itself, is practically
 589 useless for accessing non-Perl libraries because it provides almost no
 590 Perl-to-C 'glue'.  There is, for example, no mechanism for calling a C
 591 library function or supplying arguments.  A C::DynaLib module
 592 is available from CPAN sites which performs that function for some
 593 common system types.  And since the year 2000, there's also Inline::C,
 594 a module that allows you to write Perl subroutines in C.  Also available
 595 from your local CPAN site.
 596
 597 DynaLoader Interface Summary
 598
 599   @dl_library_path
 600   @dl_resolve_using
 601   @dl_require_symbols
 602   $dl_debug
 603   $dl_dlext
 604   @dl_librefs
 605   @dl_modules
 606   @dl_shared_objects
 607                                                   Implemented in:
 608   bootstrap($modulename)                               Perl
 609   @filepaths = dl_findfile(@names)                     Perl
 610   $flags = $modulename->dl_load_flags                  Perl
 611   $symref  = dl_find_symbol_anywhere($symbol)          Perl
 612
 613   $libref  = dl_load_file($filename, $flags)           C
 614   $status  = dl_unload_file($libref)                   C
 615   $symref  = dl_find_symbol($libref, $symbol)          C
 616   @symbols = dl_undef_symbols()                        C
 617   dl_install_xsub($name, $symref [, $filename])        C
 618   $message = dl_error                                  C
 619
 620 =over 4
 621
 622 =item @dl_library_path
 623
 624 The standard/default list of directories in which dl_findfile() will
 625 search for libraries etc.  Directories are searched in order:
 626 $dl_library_path[0], [1], ... etc
 627
 628 @dl_library_path is initialised to hold the list of 'normal' directories
 629 (F</usr/lib>, etc) determined by B<Configure> (C<$Config{'libpth'}>).  This should
 630 ensure portability across a wide range of platforms.
 631
 632 @dl_library_path should also be initialised with any other directories
 633 that can be determined from the environment at runtime (such as
 634 LD_LIBRARY_PATH for SunOS).
 635
 636 After initialisation @dl_library_path can be manipulated by an
 637 application using push and unshift before calling dl_findfile().
 638 Unshift can be used to add directories to the front of the search order
 639 either to save search time or to override libraries with the same name
 640 in the 'normal' directories.
 641
 642 The load function that dl_load_file() calls may require an absolute
 643 pathname.  The dl_findfile() function and @dl_library_path can be
 644 used to search for and return the absolute pathname for the
 645 library/object that you wish to load.
 646
 647 =item @dl_resolve_using
 648
 649 A list of additional libraries or other shared objects which can be
 650 used to resolve any undefined symbols that might be generated by a
 651 later call to load_file().
 652
 653 This is only required on some platforms which do not handle dependent
 654 libraries automatically.  For example the Socket Perl extension
 655 library (F<auto/Socket/Socket.so>) contains references to many socket
 656 functions which need to be resolved when it's loaded.  Most platforms
 657 will automatically know where to find the 'dependent' library (e.g.,
 658 F</usr/lib/libsocket.so>).  A few platforms need to be told the
 659 location of the dependent library explicitly.  Use @dl_resolve_using
 660 for this.
 661
 662 Example usage:
 663
 664     @dl_resolve_using = dl_findfile('-lsocket');
 665
 666 =item @dl_require_symbols
 667
 668 A list of one or more symbol names that are in the library/object file
 669 to be dynamically loaded.  This is only required on some platforms.
 670
 671 =item @dl_librefs
 672
 673 An array of the handles returned by successful calls to dl_load_file(),
 674 made by bootstrap, in the order in which they were loaded.
 675 Can be used with dl_find_symbol() to look for a symbol in any of
 676 the loaded files.
 677
 678 =item @dl_modules
 679
 680 An array of module (package) names that have been bootstrap'ed.
 681
 682 =item @dl_shared_objects
 683
 684 An array of file names for the shared objects that were loaded.
 685
 686 =item dl_error()
 687
 688 Syntax:
 689
 690     $message = dl_error();
 691
 692 Error message text from the last failed DynaLoader function.  Note
 693 that, similar to errno in unix, a successful function call does not
 694 reset this message.
 695
 696 Implementations should detect the error as soon as it occurs in any of
 697 the other functions and save the corresponding message for later
 698 retrieval.  This will avoid problems on some platforms (such as SunOS)
 699 where the error message is very temporary (e.g., dlerror()).
 700
 701 =item $dl_debug
 702
 703 Internal debugging messages are enabled when $dl_debug is set true.
 704 Currently setting $dl_debug only affects the Perl side of the
 705 DynaLoader.  These messages should help an application developer to
 706 resolve any DynaLoader usage problems.
 707
 708 $dl_debug is set to C<$ENV{'PERL_DL_DEBUG'}> if defined.
 709
 710 For the DynaLoader developer/porter there is a similar debugging
 711 variable added to the C code (see dlutils.c) and enabled if Perl was
 712 built with the B<-DDEBUGGING> flag.  This can also be set via the
 713 PERL_DL_DEBUG environment variable.  Set to 1 for minimal information or
 714 higher for more.
 715
 716 =item $dl_dlext
 717
 718 When specified (localised) in a module's F<.pm> file, indicates the extension
 719 which the module's loadable object will have. For example:
 720
 721     local $DynaLoader::dl_dlext = 'unusual_ext';
 722
 723 would indicate that the module's loadable object has an extension of
 724 C<unusual_ext> instead of the more usual C<$Config{dlext}>.  NOTE: This also
 725 requires that the module's F<Makefile.PL> specify (in C<WriteMakefile()>):
 726
 727     DLEXT => 'unusual_ext',
 728
 729 =item dl_findfile()
 730
 731 Syntax:
 732
 733     @filepaths = dl_findfile(@names)
 734
 735 Determine the full paths (including file suffix) of one or more
 736 loadable files given their generic names and optionally one or more
 737 directories.  Searches directories in @dl_library_path by default and
 738 returns an empty list if no files were found.
 739
 740 Names can be specified in a variety of platform independent forms.  Any
 741 names in the form B<-lname> are converted into F<libname.*>, where F<.*> is
 742 an appropriate suffix for the platform.
 743
 744 If a name does not already have a suitable prefix and/or suffix then
 745 the corresponding file will be searched for by trying combinations of
 746 prefix and suffix appropriate to the platform: "$name.o", "lib$name.*"
 747 and "$name".
 748
 749 If any directories are included in @names they are searched before
 750 @dl_library_path.  Directories may be specified as B<-Ldir>.  Any other
 751 names are treated as filenames to be searched for.
 752
 753 Using arguments of the form C<-Ldir> and C<-lname> is recommended.
 754
 755 Example:
 756
 757     @dl_resolve_using = dl_findfile(qw(-L/usr/5lib -lposix));
 758
 759
 760 =item dl_expandspec()
 761
 762 Syntax:
 763
 764     $filepath = dl_expandspec($spec)
 765
 766 Some unusual systems, such as VMS, require special filename handling in
 767 order to deal with symbolic names for files (i.e., VMS's Logical Names).
 768
 769 To support these systems a dl_expandspec() function can be implemented
 770 either in the F<dl_*.xs> file or code can be added to the dl_expandspec()
 771 function in F<DynaLoader.pm>.  See F<DynaLoader_pm.PL> for more information.
 772
 773 =item dl_load_file()
 774
 775 Syntax:
 776
 777     $libref = dl_load_file($filename, $flags)
 778
 779 Dynamically load $filename, which must be the path to a shared object
 780 or library.  An opaque 'library reference' is returned as a handle for
 781 the loaded object.  Returns undef on error.
 782
 783 The $flags argument to alters dl_load_file behaviour.
 784 Assigned bits:
 785
 786  0x01  make symbols available for linking later dl_load_file's.
 787        (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
 788        (ignored under VMS; this is a normal part of image linking)
 789
 790 (On systems that provide a handle for the loaded object such as SunOS
 791 and HPUX, $libref will be that handle.  On other systems $libref will
 792 typically be $filename or a pointer to a buffer containing $filename.
 793 The application should not examine or alter $libref in any way.)
 794
 795 This is the function that does the real work.  It should use the
 796 current values of @dl_require_symbols and @dl_resolve_using if required.
 797
 798     SunOS: dlopen($filename)
 799     HP-UX: shl_load($filename)
 800     Linux: dld_create_reference(@dl_require_symbols); dld_link($filename)
 801     VMS:   lib$find_image_symbol($filename,$dl_require_symbols[0])
 802
 803 (The dlopen() function is also used by Solaris and some versions of
 804 Linux, and is a common choice when providing a "wrapper" on other
 805 mechanisms as is done in the OS/2 port.)
 806
 807 =item dl_unload_file()
 808
 809 Syntax:
 810
 811     $status = dl_unload_file($libref)
 812
 813 Dynamically unload $libref, which must be an opaque 'library reference' as
 814 returned from dl_load_file.  Returns one on success and zero on failure.
 815 This function is optional and may not necessarily be provided on all platforms.
 816
 817 If it is defined and perl is compiled with the C macro C<DL_UNLOAD_ALL_AT_EXIT>
 818 defined, then it is called automatically when the interpreter exits for
 819 every shared object or library loaded by DynaLoader::bootstrap.  All such
 820 library references are stored in @dl_librefs by DynaLoader::Bootstrap as it
 821 loads the libraries.  The files are unloaded in last-in, first-out order.
 822
 823 This unloading is usually necessary when embedding a shared-object perl (e.g.
 824 one configured with -Duseshrplib) within a larger application, and the perl
 825 interpreter is created and destroyed several times within the lifetime of the
 826 application.  In this case it is possible that the system dynamic linker will
 827 unload and then subsequently reload the shared libperl without relocating any
 828 references to it from any files DynaLoaded by the previous incarnation of the
 829 interpreter.  As a result, any shared objects opened by DynaLoader may point to
 830 a now invalid 'ghost' of the libperl shared object, causing apparently random
 831 memory corruption and crashes.  This behaviour is most commonly seen when using
 832 Apache and mod_perl built with the APXS mechanism.
 833
 834     SunOS: dlclose($libref)
 835     HP-UX: ???
 836     Linux: ???
 837     VMS:   ???
 838
 839 (The dlclose() function is also used by Solaris and some versions of
 840 Linux, and is a common choice when providing a "wrapper" on other
 841 mechanisms as is done in the OS/2 port.)
 842
 843 =item dl_load_flags()
 844
 845 Syntax:
 846
 847     $flags = dl_load_flags $modulename;
 848
 849 Designed to be a method call, and to be overridden by a derived class
 850 (i.e. a class which has DynaLoader in its @ISA).  The definition in
 851 DynaLoader itself returns 0, which produces standard behavior from
 852 dl_load_file().
 853
 854 =item dl_find_symbol()
 855
 856 Syntax:
 857
 858     $symref = dl_find_symbol($libref, $symbol)
 859
 860 Return the address of the symbol $symbol or C<undef> if not found.  If the
 861 target system has separate functions to search for symbols of different
 862 types then dl_find_symbol() should search for function symbols first and
 863 then other types.
 864
 865 The exact manner in which the address is returned in $symref is not
 866 currently defined.  The only initial requirement is that $symref can
 867 be passed to, and understood by, dl_install_xsub().
 868
 869     SunOS: dlsym($libref, $symbol)
 870     HP-UX: shl_findsym($libref, $symbol)
 871     Linux: dld_get_func($symbol) and/or dld_get_symbol($symbol)
 872     VMS:   lib$find_image_symbol($libref,$symbol)
 873
 874
 875 =item dl_find_symbol_anywhere()
 876
 877 Syntax:
 878
 879     $symref = dl_find_symbol_anywhere($symbol)
 880
 881 Applies dl_find_symbol() to the members of @dl_librefs and returns
 882 the first match found.
 883
 884 =item dl_undef_symbols()
 885
 886 Example
 887
 888     @symbols = dl_undef_symbols()
 889
 890 Return a list of symbol names which remain undefined after load_file().
 891 Returns C<()> if not known.  Don't worry if your platform does not provide
 892 a mechanism for this.  Most do not need it and hence do not provide it,
 893 they just return an empty list.
 894
 895
 896 =item dl_install_xsub()
 897
 898 Syntax:
 899
 900     dl_install_xsub($perl_name, $symref [, $filename])
 901
 902 Create a new Perl external subroutine named $perl_name using $symref as
 903 a pointer to the function which implements the routine.  This is simply
 904 a direct call to newXS()/newXS_flags().  Returns a reference to the installed
 905 function.
 906
 907 The $filename parameter is used by Perl to identify the source file for
 908 the function if required by die(), caller() or the debugger.  If
 909 $filename is not defined then "DynaLoader" will be used.
 910
 911
 912 =item bootstrap()
 913
 914 Syntax:
 915
 916 bootstrap($module [...])
 917
 918 This is the normal entry point for automatic dynamic loading in Perl.
 919
 920 It performs the following actions:
 921
 922 =over 8
 923
 924 =item *
 925
 926 locates an auto/$module directory by searching @INC
 927
 928 =item *
 929
 930 uses dl_findfile() to determine the filename to load
 931
 932 =item *
 933
 934 sets @dl_require_symbols to C<("boot_$module")>
 935
 936 =item *
 937
 938 executes an F<auto/$module/$module.bs> file if it exists
 939 (typically used to add to @dl_resolve_using any files which
 940 are required to load the module on the current platform)
 941
 942 =item *
 943
 944 calls dl_load_flags() to determine how to load the file.
 945
 946 =item *
 947
 948 calls dl_load_file() to load the file
 949
 950 =item *
 951
 952 calls dl_undef_symbols() and warns if any symbols are undefined
 953
 954 =item *
 955
 956 calls dl_find_symbol() for "boot_$module"
 957
 958 =item *
 959
 960 calls dl_install_xsub() to install it as "${module}::bootstrap"
 961
 962 =item *
 963
 964 calls &{"${module}::bootstrap"} to bootstrap the module (actually
 965 it uses the function reference returned by dl_install_xsub for speed)
 966
 967 =back
 968
 969 All arguments to bootstrap() are passed to the module's bootstrap function.
 970 The default code generated by F<xsubpp> expects $module [, $version]
 971 If the optional $version argument is not given, it defaults to
 972 C<$XS_VERSION // $VERSION> in the module's symbol table. The default code
 973 compares the Perl-space version with the version of the compiled XS code,
 974 and croaks with an error if they do not match.
 975
 976 =back
 977
 978
 979 =head1 AUTHOR
 980
 981 Tim Bunce, 11 August 1994.
 982
 983 This interface is based on the work and comments of (in no particular
 984 order): Larry Wall, Robert Sanders, Dean Roehrich, Jeff Okamoto, Anno
 985 Siegel, Thomas Neumann, Paul Marquess, Charles Bailey, myself and others.
 986
 987 Larry Wall designed the elegant inherited bootstrap mechanism and
 988 implemented the first Perl 5 dynamic loader using it.
 989
 990 Solaris global loading added by Nick Ing-Simmons with design/coding
 991 assistance from Tim Bunce, January 1996.
 992
 993 =cut
 994 EOT
 995
 996 close OUT or die $!;
 997