This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Pods: Standardize on one pattern mod style
[perl5.git] / pod / perlretut.pod
1 =head1 NAME
2
3 perlretut - Perl regular expressions tutorial
4
5 =head1 DESCRIPTION
6
7 This page provides a basic tutorial on understanding, creating and
8 using regular expressions in Perl.  It serves as a complement to the
9 reference page on regular expressions L<perlre>.  Regular expressions
10 are an integral part of the C<m//>, C<s///>, C<qr//> and C<split>
11 operators and so this tutorial also overlaps with
12 L<perlop/"Regexp Quote-Like Operators"> and L<perlfunc/split>.
13
14 Perl is widely renowned for excellence in text processing, and regular
15 expressions are one of the big factors behind this fame.  Perl regular
16 expressions display an efficiency and flexibility unknown in most
17 other computer languages.  Mastering even the basics of regular
18 expressions will allow you to manipulate text with surprising ease.
19
20 What is a regular expression?  At its most basic, a regular expression
21 is a template that is used to determine if a string has certain
22 characteristics.  The string is most often some text, such as a line,
23 sentence, web page, or even a whole book, but less commonly it could be
24 some binary data as well.
25 Suppose we want to determine if the text in variable, C<$var> contains
26 the sequence of characters C<m> C<u> C<s> C<h> C<r> C<o> C<o> C<m>
27 (blanks added for legibility).  We can write in Perl
28
29  $var =~ m/mushroom/
30
31 The value of this expression will be TRUE if C<$var> contains that
32 sequence of characters, and FALSE otherwise.  The portion enclosed in
33 C<"E<sol>"> characters denotes the characteristic we are looking for.
34 We use the term I<pattern> for it.  The process of looking to see if the
35 pattern occurs in the string is called I<matching>, and the C<"=~">
36 operator along with the C<"m//"> tell Perl to try to match the pattern
37 against the string.  Note that the pattern is also a string, but a very
38 special kind of one, as we will see.  Patterns are in common use these
39 days;
40 examples are the patterns typed into a search engine to find web pages
41 and the patterns used to list files in a directory, e.g., C<ls *.txt>
42 or C<dir *.*>.  In Perl, the patterns described by regular expressions
43 are used not only to search strings, but to also extract desired parts
44 of strings, and to do search and replace operations.
45
46 Regular expressions have the undeserved reputation of being abstract
47 and difficult to understand.  This really stems simply because the
48 notation used to express them tends to be terse and dense, and not
49 because of inherent complexity.  We recommend using the C</x> regular
50 expression modifier (described below) along with plenty of white space
51 to make them less dense, and easier to read.  Regular expressions are
52 constructed using
53 simple concepts like conditionals and loops and are no more difficult
54 to understand than the corresponding C<if> conditionals and C<while>
55 loops in the Perl language itself.
56
57 This tutorial flattens the learning curve by discussing regular
58 expression concepts, along with their notation, one at a time and with
59 many examples.  The first part of the tutorial will progress from the
60 simplest word searches to the basic regular expression concepts.  If
61 you master the first part, you will have all the tools needed to solve
62 about 98% of your needs.  The second part of the tutorial is for those
63 comfortable with the basics and hungry for more power tools.  It
64 discusses the more advanced regular expression operators and
65 introduces the latest cutting-edge innovations.
66
67 A note: to save time, 'regular expression' is often abbreviated as
68 regexp or regex.  Regexp is a more natural abbreviation than regex, but
69 is harder to pronounce.  The Perl pod documentation is evenly split on
70 regexp vs regex; in Perl, there is more than one way to abbreviate it.
71 We'll use regexp in this tutorial.
72
73 New in v5.22, L<C<use re 'strict'>|re/'strict' mode> applies stricter
74 rules than otherwise when compiling regular expression patterns.  It can
75 find things that, while legal, may not be what you intended.
76
77 =head1 Part 1: The basics
78
79 =head2 Simple word matching
80
81 The simplest regexp is simply a word, or more generally, a string of
82 characters.  A regexp consisting of just a word matches any string that
83 contains that word:
84
85     "Hello World" =~ /World/;  # matches
86
87 What is this Perl statement all about? C<"Hello World"> is a simple
88 double-quoted string.  C<World> is the regular expression and the
89 C<//> enclosing C</World/> tells Perl to search a string for a match.
90 The operator C<=~> associates the string with the regexp match and
91 produces a true value if the regexp matched, or false if the regexp
92 did not match.  In our case, C<World> matches the second word in
93 C<"Hello World">, so the expression is true.  Expressions like this
94 are useful in conditionals:
95
96     if ("Hello World" =~ /World/) {
97         print "It matches\n";
98     }
99     else {
100         print "It doesn't match\n";
101     }
102
103 There are useful variations on this theme.  The sense of the match can
104 be reversed by using the C<!~> operator:
105
106     if ("Hello World" !~ /World/) {
107         print "It doesn't match\n";
108     }
109     else {
110         print "It matches\n";
111     }
112
113 The literal string in the regexp can be replaced by a variable:
114
115     $greeting = "World";
116     if ("Hello World" =~ /$greeting/) {
117         print "It matches\n";
118     }
119     else {
120         print "It doesn't match\n";
121     }
122
123 If you're matching against the special default variable C<$_>, the
124 C<$_ =~> part can be omitted:
125
126     $_ = "Hello World";
127     if (/World/) {
128         print "It matches\n";
129     }
130     else {
131         print "It doesn't match\n";
132     }
133
134 And finally, the C<//> default delimiters for a match can be changed
135 to arbitrary delimiters by putting an C<'m'> out front:
136
137     "Hello World" =~ m!World!;   # matches, delimited by '!'
138     "Hello World" =~ m{World};   # matches, note the matching '{}'
139     "/usr/bin/perl" =~ m"/perl"; # matches after '/usr/bin',
140                                  # '/' becomes an ordinary char
141
142 C</World/>, C<m!World!>, and C<m{World}> all represent the
143 same thing.  When, e.g., the quote (C<">) is used as a delimiter, the forward
144 slash C<'/'> becomes an ordinary character and can be used in this regexp
145 without trouble.
146
147 Let's consider how different regexps would match C<"Hello World">:
148
149     "Hello World" =~ /world/;  # doesn't match
150     "Hello World" =~ /o W/;    # matches
151     "Hello World" =~ /oW/;     # doesn't match
152     "Hello World" =~ /World /; # doesn't match
153
154 The first regexp C<world> doesn't match because regexps are
155 case-sensitive.  The second regexp matches because the substring
156 S<C<'o W'>> occurs in the string S<C<"Hello World">>.  The space
157 character ' ' is treated like any other character in a regexp and is
158 needed to match in this case.  The lack of a space character is the
159 reason the third regexp C<'oW'> doesn't match.  The fourth regexp
160 C<'World '> doesn't match because there is a space at the end of the
161 regexp, but not at the end of the string.  The lesson here is that
162 regexps must match a part of the string I<exactly> in order for the
163 statement to be true.
164
165 If a regexp matches in more than one place in the string, Perl will
166 always match at the earliest possible point in the string:
167
168     "Hello World" =~ /o/;       # matches 'o' in 'Hello'
169     "That hat is red" =~ /hat/; # matches 'hat' in 'That'
170
171 With respect to character matching, there are a few more points you
172 need to know about.   First of all, not all characters can be used 'as
173 is' in a match.  Some characters, called I<metacharacters>, are reserved
174 for use in regexp notation.  The metacharacters are
175
176     {}[]()^$.|*+?\
177
178 The significance of each of these will be explained
179 in the rest of the tutorial, but for now, it is important only to know
180 that a metacharacter can be matched by putting a backslash before it:
181
182     "2+2=4" =~ /2+2/;    # doesn't match, + is a metacharacter
183     "2+2=4" =~ /2\+2/;   # matches, \+ is treated like an ordinary +
184     "The interval is [0,1)." =~ /[0,1)./     # is a syntax error!
185     "The interval is [0,1)." =~ /\[0,1\)\./  # matches
186     "#!/usr/bin/perl" =~ /#!\/usr\/bin\/perl/;  # matches
187
188 In the last regexp, the forward slash C<'/'> is also backslashed,
189 because it is used to delimit the regexp.  This can lead to LTS
190 (leaning toothpick syndrome), however, and it is often more readable
191 to change delimiters.
192
193     "#!/usr/bin/perl" =~ m!#\!/usr/bin/perl!;  # easier to read
194
195 The backslash character C<'\'> is a metacharacter itself and needs to
196 be backslashed:
197
198     'C:\WIN32' =~ /C:\\WIN/;   # matches
199
200 In situations where it doesn't make sense for a particular metacharacter
201 to mean what it normally does, it automatically loses its
202 metacharacter-ness and becomes an ordinary character that is to be
203 matched literally.  For example, the C<'}'> is a metacharacter only when
204 it is the mate of a C<'{'> metacharacter.  Otherwise it is treated as a
205 literal RIGHT CURLY BRACKET.  This may lead to unexpected results.
206 L<C<use re 'strict'>|re/'strict' mode> can catch some of these.
207
208 In addition to the metacharacters, there are some ASCII characters
209 which don't have printable character equivalents and are instead
210 represented by I<escape sequences>.  Common examples are C<\t> for a
211 tab, C<\n> for a newline, C<\r> for a carriage return and C<\a> for a
212 bell (or alert).  If your string is better thought of as a sequence of arbitrary
213 bytes, the octal escape sequence, e.g., C<\033>, or hexadecimal escape
214 sequence, e.g., C<\x1B> may be a more natural representation for your
215 bytes.  Here are some examples of escapes:
216
217     "1000\t2000" =~ m(0\t2)   # matches
218     "1000\n2000" =~ /0\n20/   # matches
219     "1000\t2000" =~ /\000\t2/ # doesn't match, "0" ne "\000"
220     "cat"   =~ /\o{143}\x61\x74/ # matches in ASCII, but a weird way
221                                  # to spell cat
222
223 If you've been around Perl a while, all this talk of escape sequences
224 may seem familiar.  Similar escape sequences are used in double-quoted
225 strings and in fact the regexps in Perl are mostly treated as
226 double-quoted strings.  This means that variables can be used in
227 regexps as well.  Just like double-quoted strings, the values of the
228 variables in the regexp will be substituted in before the regexp is
229 evaluated for matching purposes.  So we have:
230
231     $foo = 'house';
232     'housecat' =~ /$foo/;      # matches
233     'cathouse' =~ /cat$foo/;   # matches
234     'housecat' =~ /${foo}cat/; # matches
235
236 So far, so good.  With the knowledge above you can already perform
237 searches with just about any literal string regexp you can dream up.
238 Here is a I<very simple> emulation of the Unix grep program:
239
240     % cat > simple_grep
241     #!/usr/bin/perl
242     $regexp = shift;
243     while (<>) {
244         print if /$regexp/;
245     }
246     ^D
247
248     % chmod +x simple_grep
249
250     % simple_grep abba /usr/dict/words
251     Babbage
252     cabbage
253     cabbages
254     sabbath
255     Sabbathize
256     Sabbathizes
257     sabbatical
258     scabbard
259     scabbards
260
261 This program is easy to understand.  C<#!/usr/bin/perl> is the standard
262 way to invoke a perl program from the shell.
263 S<C<$regexp = shift;>> saves the first command line argument as the
264 regexp to be used, leaving the rest of the command line arguments to
265 be treated as files.  S<C<< while (<>) >>> loops over all the lines in
266 all the files.  For each line, S<C<print if /$regexp/;>> prints the
267 line if the regexp matches the line.  In this line, both C<print> and
268 C</$regexp/> use the default variable C<$_> implicitly.
269
270 With all of the regexps above, if the regexp matched anywhere in the
271 string, it was considered a match.  Sometimes, however, we'd like to
272 specify I<where> in the string the regexp should try to match.  To do
273 this, we would use the I<anchor> metacharacters C<^> and C<$>.  The
274 anchor C<^> means match at the beginning of the string and the anchor
275 C<$> means match at the end of the string, or before a newline at the
276 end of the string.  Here is how they are used:
277
278     "housekeeper" =~ /keeper/;    # matches
279     "housekeeper" =~ /^keeper/;   # doesn't match
280     "housekeeper" =~ /keeper$/;   # matches
281     "housekeeper\n" =~ /keeper$/; # matches
282
283 The second regexp doesn't match because C<^> constrains C<keeper> to
284 match only at the beginning of the string, but C<"housekeeper"> has
285 keeper starting in the middle.  The third regexp does match, since the
286 C<$> constrains C<keeper> to match only at the end of the string.
287
288 When both C<^> and C<$> are used at the same time, the regexp has to
289 match both the beginning and the end of the string, i.e., the regexp
290 matches the whole string.  Consider
291
292     "keeper" =~ /^keep$/;      # doesn't match
293     "keeper" =~ /^keeper$/;    # matches
294     ""       =~ /^$/;          # ^$ matches an empty string
295
296 The first regexp doesn't match because the string has more to it than
297 C<keep>.  Since the second regexp is exactly the string, it
298 matches.  Using both C<^> and C<$> in a regexp forces the complete
299 string to match, so it gives you complete control over which strings
300 match and which don't.  Suppose you are looking for a fellow named
301 bert, off in a string by himself:
302
303     "dogbert" =~ /bert/;   # matches, but not what you want
304
305     "dilbert" =~ /^bert/;  # doesn't match, but ..
306     "bertram" =~ /^bert/;  # matches, so still not good enough
307
308     "bertram" =~ /^bert$/; # doesn't match, good
309     "dilbert" =~ /^bert$/; # doesn't match, good
310     "bert"    =~ /^bert$/; # matches, perfect
311
312 Of course, in the case of a literal string, one could just as easily
313 use the string comparison S<C<$string eq 'bert'>> and it would be
314 more efficient.   The  C<^...$> regexp really becomes useful when we
315 add in the more powerful regexp tools below.
316
317 =head2 Using character classes
318
319 Although one can already do quite a lot with the literal string
320 regexps above, we've only scratched the surface of regular expression
321 technology.  In this and subsequent sections we will introduce regexp
322 concepts (and associated metacharacter notations) that will allow a
323 regexp to represent not just a single character sequence, but a I<whole
324 class> of them.
325
326 One such concept is that of a I<character class>.  A character class
327 allows a set of possible characters, rather than just a single
328 character, to match at a particular point in a regexp.  You can define
329 your own custom character classes.  These
330 are denoted by brackets C<[...]>, with the set of characters
331 to be possibly matched inside.  Here are some examples:
332
333     /cat/;       # matches 'cat'
334     /[bcr]at/;   # matches 'bat, 'cat', or 'rat'
335     /item[0123456789]/;  # matches 'item0' or ... or 'item9'
336     "abc" =~ /[cab]/;    # matches 'a'
337
338 In the last statement, even though C<'c'> is the first character in
339 the class, C<'a'> matches because the first character position in the
340 string is the earliest point at which the regexp can match.
341
342     /[yY][eE][sS]/;      # match 'yes' in a case-insensitive way
343                          # 'yes', 'Yes', 'YES', etc.
344
345 This regexp displays a common task: perform a case-insensitive
346 match.  Perl provides a way of avoiding all those brackets by simply
347 appending an C<'i'> to the end of the match.  Then C</[yY][eE][sS]/;>
348 can be rewritten as C</yes/i;>.  The C<'i'> stands for
349 case-insensitive and is an example of a I<modifier> of the matching
350 operation.  We will meet other modifiers later in the tutorial.
351
352 We saw in the section above that there were ordinary characters, which
353 represented themselves, and special characters, which needed a
354 backslash C<\> to represent themselves.  The same is true in a
355 character class, but the sets of ordinary and special characters
356 inside a character class are different than those outside a character
357 class.  The special characters for a character class are C<-]\^$> (and
358 the pattern delimiter, whatever it is).
359 C<]> is special because it denotes the end of a character class.  C<$> is
360 special because it denotes a scalar variable.  C<\> is special because
361 it is used in escape sequences, just like above.  Here is how the
362 special characters C<]$\> are handled:
363
364    /[\]c]def/; # matches ']def' or 'cdef'
365    $x = 'bcr';
366    /[$x]at/;   # matches 'bat', 'cat', or 'rat'
367    /[\$x]at/;  # matches '$at' or 'xat'
368    /[\\$x]at/; # matches '\at', 'bat, 'cat', or 'rat'
369
370 The last two are a little tricky.  In C<[\$x]>, the backslash protects
371 the dollar sign, so the character class has two members C<$> and C<x>.
372 In C<[\\$x]>, the backslash is protected, so C<$x> is treated as a
373 variable and substituted in double quote fashion.
374
375 The special character C<'-'> acts as a range operator within character
376 classes, so that a contiguous set of characters can be written as a
377 range.  With ranges, the unwieldy C<[0123456789]> and C<[abc...xyz]>
378 become the svelte C<[0-9]> and C<[a-z]>.  Some examples are
379
380     /item[0-9]/;  # matches 'item0' or ... or 'item9'
381     /[0-9bx-z]aa/;  # matches '0aa', ..., '9aa',
382                     # 'baa', 'xaa', 'yaa', or 'zaa'
383     /[0-9a-fA-F]/;  # matches a hexadecimal digit
384     /[0-9a-zA-Z_]/; # matches a "word" character,
385                     # like those in a Perl variable name
386
387 If C<'-'> is the first or last character in a character class, it is
388 treated as an ordinary character; C<[-ab]>, C<[ab-]> and C<[a\-b]> are
389 all equivalent.
390
391 The special character C<^> in the first position of a character class
392 denotes a I<negated character class>, which matches any character but
393 those in the brackets.  Both C<[...]> and C<[^...]> must match a
394 character, or the match fails.  Then
395
396     /[^a]at/;  # doesn't match 'aat' or 'at', but matches
397                # all other 'bat', 'cat, '0at', '%at', etc.
398     /[^0-9]/;  # matches a non-numeric character
399     /[a^]at/;  # matches 'aat' or '^at'; here '^' is ordinary
400
401 Now, even C<[0-9]> can be a bother to write multiple times, so in the
402 interest of saving keystrokes and making regexps more readable, Perl
403 has several abbreviations for common character classes, as shown below.
404 Since the introduction of Unicode, unless the C</a> modifier is in
405 effect, these character classes match more than just a few characters in
406 the ASCII range.
407
408 =over 4
409
410 =item *
411
412 \d matches a digit, not just [0-9] but also digits from non-roman scripts
413
414 =item *
415
416 \s matches a whitespace character, the set [\ \t\r\n\f] and others
417
418 =item *
419
420 \w matches a word character (alphanumeric or _), not just [0-9a-zA-Z_]
421 but also digits and characters from non-roman scripts
422
423 =item *
424
425 \D is a negated \d; it represents any other character than a digit, or [^\d]
426
427 =item *
428
429 \S is a negated \s; it represents any non-whitespace character [^\s]
430
431 =item *
432
433 \W is a negated \w; it represents any non-word character [^\w]
434
435 =item *
436
437 The period '.' matches any character but "\n" (unless the modifier C</s> is
438 in effect, as explained below).
439
440 =item *
441
442 \N, like the period, matches any character but "\n", but it does so
443 regardless of whether the modifier C</s> is in effect.
444
445 =back
446
447 The C</a> modifier, available starting in Perl 5.14,  is used to
448 restrict the matches of \d, \s, and \w to just those in the ASCII range.
449 It is useful to keep your program from being needlessly exposed to full
450 Unicode (and its accompanying security considerations) when all you want
451 is to process English-like text.  (The "a" may be doubled, C</aa>, to
452 provide even more restrictions, preventing case-insensitive matching of
453 ASCII with non-ASCII characters; otherwise a Unicode "Kelvin Sign"
454 would caselessly match a "k" or "K".)
455
456 The C<\d\s\w\D\S\W> abbreviations can be used both inside and outside
457 of bracketed character classes.  Here are some in use:
458
459     /\d\d:\d\d:\d\d/; # matches a hh:mm:ss time format
460     /[\d\s]/;         # matches any digit or whitespace character
461     /\w\W\w/;         # matches a word char, followed by a
462                       # non-word char, followed by a word char
463     /..rt/;           # matches any two chars, followed by 'rt'
464     /end\./;          # matches 'end.'
465     /end[.]/;         # same thing, matches 'end.'
466
467 Because a period is a metacharacter, it needs to be escaped to match
468 as an ordinary period. Because, for example, C<\d> and C<\w> are sets
469 of characters, it is incorrect to think of C<[^\d\w]> as C<[\D\W]>; in
470 fact C<[^\d\w]> is the same as C<[^\w]>, which is the same as
471 C<[\W]>. Think DeMorgan's laws.
472
473 In actuality, the period and C<\d\s\w\D\S\W> abbreviations are
474 themselves types of character classes, so the ones surrounded by
475 brackets are just one type of character class.  When we need to make a
476 distinction, we refer to them as "bracketed character classes."
477
478 An anchor useful in basic regexps is the I<word anchor>
479 C<\b>.  This matches a boundary between a word character and a non-word
480 character C<\w\W> or C<\W\w>:
481
482     $x = "Housecat catenates house and cat";
483     $x =~ /cat/;    # matches cat in 'housecat'
484     $x =~ /\bcat/;  # matches cat in 'catenates'
485     $x =~ /cat\b/;  # matches cat in 'housecat'
486     $x =~ /\bcat\b/;  # matches 'cat' at end of string
487
488 Note in the last example, the end of the string is considered a word
489 boundary.
490
491 For natural language processing (so that, for example, apostrophes are
492 included in words), use instead C<\b{wb}>
493
494     "don't" =~ / .+? \b{wb} /x;  # matches the whole string
495
496 You might wonder why C<'.'> matches everything but C<"\n"> - why not
497 every character? The reason is that often one is matching against
498 lines and would like to ignore the newline characters.  For instance,
499 while the string C<"\n"> represents one line, we would like to think
500 of it as empty.  Then
501
502     ""   =~ /^$/;    # matches
503     "\n" =~ /^$/;    # matches, $ anchors before "\n"
504
505     ""   =~ /./;      # doesn't match; it needs a char
506     ""   =~ /^.$/;    # doesn't match; it needs a char
507     "\n" =~ /^.$/;    # doesn't match; it needs a char other than "\n"
508     "a"  =~ /^.$/;    # matches
509     "a\n"  =~ /^.$/;  # matches, $ anchors before "\n"
510
511 This behavior is convenient, because we usually want to ignore
512 newlines when we count and match characters in a line.  Sometimes,
513 however, we want to keep track of newlines.  We might even want C<^>
514 and C<$> to anchor at the beginning and end of lines within the
515 string, rather than just the beginning and end of the string.  Perl
516 allows us to choose between ignoring and paying attention to newlines
517 by using the C</s> and C</m> modifiers.  C</s> and C</m> stand for
518 single line and multi-line and they determine whether a string is to
519 be treated as one continuous string, or as a set of lines.  The two
520 modifiers affect two aspects of how the regexp is interpreted: 1) how
521 the C<'.'> character class is defined, and 2) where the anchors C<^>
522 and C<$> are able to match.  Here are the four possible combinations:
523
524 =over 4
525
526 =item *
527
528 no modifiers: Default behavior.  C<'.'> matches any character
529 except C<"\n">.  C<^> matches only at the beginning of the string and
530 C<$> matches only at the end or before a newline at the end.
531
532 =item *
533
534 s modifier (C</s>): Treat string as a single long line.  C<'.'> matches
535 any character, even C<"\n">.  C<^> matches only at the beginning of
536 the string and C<$> matches only at the end or before a newline at the
537 end.
538
539 =item *
540
541 m modifier (C</m>): Treat string as a set of multiple lines.  C<'.'>
542 matches any character except C<"\n">.  C<^> and C<$> are able to match
543 at the start or end of I<any> line within the string.
544
545 =item *
546
547 both s and m modifiers (C</sm>): Treat string as a single long line, but
548 detect multiple lines.  C<'.'> matches any character, even
549 C<"\n">.  C<^> and C<$>, however, are able to match at the start or end
550 of I<any> line within the string.
551
552 =back
553
554 Here are examples of C</s> and C</m> in action:
555
556     $x = "There once was a girl\nWho programmed in Perl\n";
557
558     $x =~ /^Who/;   # doesn't match, "Who" not at start of string
559     $x =~ /^Who/s;  # doesn't match, "Who" not at start of string
560     $x =~ /^Who/m;  # matches, "Who" at start of second line
561     $x =~ /^Who/sm; # matches, "Who" at start of second line
562
563     $x =~ /girl.Who/;   # doesn't match, "." doesn't match "\n"
564     $x =~ /girl.Who/s;  # matches, "." matches "\n"
565     $x =~ /girl.Who/m;  # doesn't match, "." doesn't match "\n"
566     $x =~ /girl.Who/sm; # matches, "." matches "\n"
567
568 Most of the time, the default behavior is what is wanted, but C</s> and
569 C</m> are occasionally very useful.  If C</m> is being used, the start
570 of the string can still be matched with C<\A> and the end of the string
571 can still be matched with the anchors C<\Z> (matches both the end and
572 the newline before, like C<$>), and C<\z> (matches only the end):
573
574     $x =~ /^Who/m;   # matches, "Who" at start of second line
575     $x =~ /\AWho/m;  # doesn't match, "Who" is not at start of string
576
577     $x =~ /girl$/m;  # matches, "girl" at end of first line
578     $x =~ /girl\Z/m; # doesn't match, "girl" is not at end of string
579
580     $x =~ /Perl\Z/m; # matches, "Perl" is at newline before end
581     $x =~ /Perl\z/m; # doesn't match, "Perl" is not at end of string
582
583 We now know how to create choices among classes of characters in a
584 regexp.  What about choices among words or character strings? Such
585 choices are described in the next section.
586
587 =head2 Matching this or that
588
589 Sometimes we would like our regexp to be able to match different
590 possible words or character strings.  This is accomplished by using
591 the I<alternation> metacharacter C<|>.  To match C<dog> or C<cat>, we
592 form the regexp C<dog|cat>.  As before, Perl will try to match the
593 regexp at the earliest possible point in the string.  At each
594 character position, Perl will first try to match the first
595 alternative, C<dog>.  If C<dog> doesn't match, Perl will then try the
596 next alternative, C<cat>.  If C<cat> doesn't match either, then the
597 match fails and Perl moves to the next position in the string.  Some
598 examples:
599
600     "cats and dogs" =~ /cat|dog|bird/;  # matches "cat"
601     "cats and dogs" =~ /dog|cat|bird/;  # matches "cat"
602
603 Even though C<dog> is the first alternative in the second regexp,
604 C<cat> is able to match earlier in the string.
605
606     "cats"          =~ /c|ca|cat|cats/; # matches "c"
607     "cats"          =~ /cats|cat|ca|c/; # matches "cats"
608
609 Here, all the alternatives match at the first string position, so the
610 first alternative is the one that matches.  If some of the
611 alternatives are truncations of the others, put the longest ones first
612 to give them a chance to match.
613
614     "cab" =~ /a|b|c/ # matches "c"
615                      # /a|b|c/ == /[abc]/
616
617 The last example points out that character classes are like
618 alternations of characters.  At a given character position, the first
619 alternative that allows the regexp match to succeed will be the one
620 that matches.
621
622 =head2 Grouping things and hierarchical matching
623
624 Alternation allows a regexp to choose among alternatives, but by
625 itself it is unsatisfying.  The reason is that each alternative is a whole
626 regexp, but sometime we want alternatives for just part of a
627 regexp.  For instance, suppose we want to search for housecats or
628 housekeepers.  The regexp C<housecat|housekeeper> fits the bill, but is
629 inefficient because we had to type C<house> twice.  It would be nice to
630 have parts of the regexp be constant, like C<house>, and some
631 parts have alternatives, like C<cat|keeper>.
632
633 The I<grouping> metacharacters C<()> solve this problem.  Grouping
634 allows parts of a regexp to be treated as a single unit.  Parts of a
635 regexp are grouped by enclosing them in parentheses.  Thus we could solve
636 the C<housecat|housekeeper> by forming the regexp as
637 C<house(cat|keeper)>.  The regexp C<house(cat|keeper)> means match
638 C<house> followed by either C<cat> or C<keeper>.  Some more examples
639 are
640
641     /(a|b)b/;    # matches 'ab' or 'bb'
642     /(ac|b)b/;   # matches 'acb' or 'bb'
643     /(^a|b)c/;   # matches 'ac' at start of string or 'bc' anywhere
644     /(a|[bc])d/; # matches 'ad', 'bd', or 'cd'
645
646     /house(cat|)/;  # matches either 'housecat' or 'house'
647     /house(cat(s|)|)/;  # matches either 'housecats' or 'housecat' or
648                         # 'house'.  Note groups can be nested.
649
650     /(19|20|)\d\d/;  # match years 19xx, 20xx, or the Y2K problem, xx
651     "20" =~ /(19|20|)\d\d/;  # matches the null alternative '()\d\d',
652                              # because '20\d\d' can't match
653
654 Alternations behave the same way in groups as out of them: at a given
655 string position, the leftmost alternative that allows the regexp to
656 match is taken.  So in the last example at the first string position,
657 C<"20"> matches the second alternative, but there is nothing left over
658 to match the next two digits C<\d\d>.  So Perl moves on to the next
659 alternative, which is the null alternative and that works, since
660 C<"20"> is two digits.
661
662 The process of trying one alternative, seeing if it matches, and
663 moving on to the next alternative, while going back in the string
664 from where the previous alternative was tried, if it doesn't, is called
665 I<backtracking>.  The term 'backtracking' comes from the idea that
666 matching a regexp is like a walk in the woods.  Successfully matching
667 a regexp is like arriving at a destination.  There are many possible
668 trailheads, one for each string position, and each one is tried in
669 order, left to right.  From each trailhead there may be many paths,
670 some of which get you there, and some which are dead ends.  When you
671 walk along a trail and hit a dead end, you have to backtrack along the
672 trail to an earlier point to try another trail.  If you hit your
673 destination, you stop immediately and forget about trying all the
674 other trails.  You are persistent, and only if you have tried all the
675 trails from all the trailheads and not arrived at your destination, do
676 you declare failure.  To be concrete, here is a step-by-step analysis
677 of what Perl does when it tries to match the regexp
678
679     "abcde" =~ /(abd|abc)(df|d|de)/;
680
681 =over 4
682
683 =item Z<>0
684
685 Start with the first letter in the string 'a'.
686
687 =item Z<>1
688
689 Try the first alternative in the first group 'abd'.
690
691 =item Z<>2
692
693 Match 'a' followed by 'b'. So far so good.
694
695 =item Z<>3
696
697 'd' in the regexp doesn't match 'c' in the string - a dead
698 end.  So backtrack two characters and pick the second alternative in
699 the first group 'abc'.
700
701 =item Z<>4
702
703 Match 'a' followed by 'b' followed by 'c'.  We are on a roll
704 and have satisfied the first group. Set $1 to 'abc'.
705
706 =item Z<>5
707
708 Move on to the second group and pick the first alternative
709 'df'.
710
711 =item Z<>6
712
713 Match the 'd'.
714
715 =item Z<>7
716
717 'f' in the regexp doesn't match 'e' in the string, so a dead
718 end.  Backtrack one character and pick the second alternative in the
719 second group 'd'.
720
721 =item Z<>8
722
723 'd' matches. The second grouping is satisfied, so set $2 to
724 'd'.
725
726 =item Z<>9
727
728 We are at the end of the regexp, so we are done! We have
729 matched 'abcd' out of the string "abcde".
730
731 =back
732
733 There are a couple of things to note about this analysis.  First, the
734 third alternative in the second group 'de' also allows a match, but we
735 stopped before we got to it - at a given character position, leftmost
736 wins.  Second, we were able to get a match at the first character
737 position of the string 'a'.  If there were no matches at the first
738 position, Perl would move to the second character position 'b' and
739 attempt the match all over again.  Only when all possible paths at all
740 possible character positions have been exhausted does Perl give
741 up and declare S<C<$string =~ /(abd|abc)(df|d|de)/;>> to be false.
742
743 Even with all this work, regexp matching happens remarkably fast.  To
744 speed things up, Perl compiles the regexp into a compact sequence of
745 opcodes that can often fit inside a processor cache.  When the code is
746 executed, these opcodes can then run at full throttle and search very
747 quickly.
748
749 =head2 Extracting matches
750
751 The grouping metacharacters C<()> also serve another completely
752 different function: they allow the extraction of the parts of a string
753 that matched.  This is very useful to find out what matched and for
754 text processing in general.  For each grouping, the part that matched
755 inside goes into the special variables C<$1>, C<$2>, etc.  They can be
756 used just as ordinary variables:
757
758     # extract hours, minutes, seconds
759     if ($time =~ /(\d\d):(\d\d):(\d\d)/) {    # match hh:mm:ss format
760         $hours = $1;
761         $minutes = $2;
762         $seconds = $3;
763     }
764
765 Now, we know that in scalar context,
766 S<C<$time =~ /(\d\d):(\d\d):(\d\d)/>> returns a true or false
767 value.  In list context, however, it returns the list of matched values
768 C<($1,$2,$3)>.  So we could write the code more compactly as
769
770     # extract hours, minutes, seconds
771     ($hours, $minutes, $second) = ($time =~ /(\d\d):(\d\d):(\d\d)/);
772
773 If the groupings in a regexp are nested, C<$1> gets the group with the
774 leftmost opening parenthesis, C<$2> the next opening parenthesis,
775 etc.  Here is a regexp with nested groups:
776
777     /(ab(cd|ef)((gi)|j))/;
778      1  2      34
779
780 If this regexp matches, C<$1> contains a string starting with
781 C<'ab'>, C<$2> is either set to C<'cd'> or C<'ef'>, C<$3> equals either
782 C<'gi'> or C<'j'>, and C<$4> is either set to C<'gi'>, just like C<$3>,
783 or it remains undefined.
784
785 For convenience, Perl sets C<$+> to the string held by the highest numbered
786 C<$1>, C<$2>,... that got assigned (and, somewhat related, C<$^N> to the
787 value of the C<$1>, C<$2>,... most-recently assigned; i.e. the C<$1>,
788 C<$2>,... associated with the rightmost closing parenthesis used in the
789 match).
790
791
792 =head2 Backreferences
793
794 Closely associated with the matching variables C<$1>, C<$2>, ... are
795 the I<backreferences> C<\g1>, C<\g2>,...  Backreferences are simply
796 matching variables that can be used I<inside> a regexp.  This is a
797 really nice feature; what matches later in a regexp is made to depend on
798 what matched earlier in the regexp.  Suppose we wanted to look
799 for doubled words in a text, like 'the the'.  The following regexp finds
800 all 3-letter doubles with a space in between:
801
802     /\b(\w\w\w)\s\g1\b/;
803
804 The grouping assigns a value to \g1, so that the same 3-letter sequence
805 is used for both parts.
806
807 A similar task is to find words consisting of two identical parts:
808
809     % simple_grep '^(\w\w\w\w|\w\w\w|\w\w|\w)\g1$' /usr/dict/words
810     beriberi
811     booboo
812     coco
813     mama
814     murmur
815     papa
816
817 The regexp has a single grouping which considers 4-letter
818 combinations, then 3-letter combinations, etc., and uses C<\g1> to look for
819 a repeat.  Although C<$1> and C<\g1> represent the same thing, care should be
820 taken to use matched variables C<$1>, C<$2>,... only I<outside> a regexp
821 and backreferences C<\g1>, C<\g2>,... only I<inside> a regexp; not doing
822 so may lead to surprising and unsatisfactory results.
823
824
825 =head2 Relative backreferences
826
827 Counting the opening parentheses to get the correct number for a
828 backreference is error-prone as soon as there is more than one
829 capturing group.  A more convenient technique became available
830 with Perl 5.10: relative backreferences. To refer to the immediately
831 preceding capture group one now may write C<\g{-1}>, the next but
832 last is available via C<\g{-2}>, and so on.
833
834 Another good reason in addition to readability and maintainability
835 for using relative backreferences is illustrated by the following example,
836 where a simple pattern for matching peculiar strings is used:
837
838     $a99a = '([a-z])(\d)\g2\g1';   # matches a11a, g22g, x33x, etc.
839
840 Now that we have this pattern stored as a handy string, we might feel
841 tempted to use it as a part of some other pattern:
842
843     $line = "code=e99e";
844     if ($line =~ /^(\w+)=$a99a$/){   # unexpected behavior!
845         print "$1 is valid\n";
846     } else {
847         print "bad line: '$line'\n";
848     }
849
850 But this doesn't match, at least not the way one might expect. Only
851 after inserting the interpolated C<$a99a> and looking at the resulting
852 full text of the regexp is it obvious that the backreferences have
853 backfired. The subexpression C<(\w+)> has snatched number 1 and
854 demoted the groups in C<$a99a> by one rank. This can be avoided by
855 using relative backreferences:
856
857     $a99a = '([a-z])(\d)\g{-1}\g{-2}';  # safe for being interpolated
858
859
860 =head2 Named backreferences
861
862 Perl 5.10 also introduced named capture groups and named backreferences.
863 To attach a name to a capturing group, you write either
864 C<< (?<name>...) >> or C<< (?'name'...) >>.  The backreference may
865 then be written as C<\g{name}>.  It is permissible to attach the
866 same name to more than one group, but then only the leftmost one of the
867 eponymous set can be referenced.  Outside of the pattern a named
868 capture group is accessible through the C<%+> hash.
869
870 Assuming that we have to match calendar dates which may be given in one
871 of the three formats yyyy-mm-dd, mm/dd/yyyy or dd.mm.yyyy, we can write
872 three suitable patterns where we use 'd', 'm' and 'y' respectively as the
873 names of the groups capturing the pertaining components of a date. The
874 matching operation combines the three patterns as alternatives:
875
876     $fmt1 = '(?<y>\d\d\d\d)-(?<m>\d\d)-(?<d>\d\d)';
877     $fmt2 = '(?<m>\d\d)/(?<d>\d\d)/(?<y>\d\d\d\d)';
878     $fmt3 = '(?<d>\d\d)\.(?<m>\d\d)\.(?<y>\d\d\d\d)';
879     for my $d qw( 2006-10-21 15.01.2007 10/31/2005 ){
880         if ( $d =~ m{$fmt1|$fmt2|$fmt3} ){
881             print "day=$+{d} month=$+{m} year=$+{y}\n";
882         }
883     }
884
885 If any of the alternatives matches, the hash C<%+> is bound to contain the
886 three key-value pairs.
887
888
889 =head2 Alternative capture group numbering
890
891 Yet another capturing group numbering technique (also as from Perl 5.10)
892 deals with the problem of referring to groups within a set of alternatives.
893 Consider a pattern for matching a time of the day, civil or military style:
894
895     if ( $time =~ /(\d\d|\d):(\d\d)|(\d\d)(\d\d)/ ){
896         # process hour and minute
897     }
898
899 Processing the results requires an additional if statement to determine
900 whether C<$1> and C<$2> or C<$3> and C<$4> contain the goodies. It would
901 be easier if we could use group numbers 1 and 2 in second alternative as
902 well, and this is exactly what the parenthesized construct C<(?|...)>,
903 set around an alternative achieves. Here is an extended version of the
904 previous pattern:
905
906   if($time =~ /(?|(\d\d|\d):(\d\d)|(\d\d)(\d\d))\s+([A-Z][A-Z][A-Z])/){
907       print "hour=$1 minute=$2 zone=$3\n";
908   }
909
910 Within the alternative numbering group, group numbers start at the same
911 position for each alternative. After the group, numbering continues
912 with one higher than the maximum reached across all the alternatives.
913
914 =head2 Position information
915
916 In addition to what was matched, Perl also provides the
917 positions of what was matched as contents of the C<@-> and C<@+>
918 arrays. C<$-[0]> is the position of the start of the entire match and
919 C<$+[0]> is the position of the end. Similarly, C<$-[n]> is the
920 position of the start of the C<$n> match and C<$+[n]> is the position
921 of the end. If C<$n> is undefined, so are C<$-[n]> and C<$+[n]>. Then
922 this code
923
924     $x = "Mmm...donut, thought Homer";
925     $x =~ /^(Mmm|Yech)\.\.\.(donut|peas)/; # matches
926     foreach $exp (1..$#-) {
927         print "Match $exp: '${$exp}' at position ($-[$exp],$+[$exp])\n";
928     }
929
930 prints
931
932     Match 1: 'Mmm' at position (0,3)
933     Match 2: 'donut' at position (6,11)
934
935 Even if there are no groupings in a regexp, it is still possible to
936 find out what exactly matched in a string.  If you use them, Perl
937 will set C<$`> to the part of the string before the match, will set C<$&>
938 to the part of the string that matched, and will set C<$'> to the part
939 of the string after the match.  An example:
940
941     $x = "the cat caught the mouse";
942     $x =~ /cat/;  # $` = 'the ', $& = 'cat', $' = ' caught the mouse'
943     $x =~ /the/;  # $` = '', $& = 'the', $' = ' cat caught the mouse'
944
945 In the second match, C<$`> equals C<''> because the regexp matched at the
946 first character position in the string and stopped; it never saw the
947 second 'the'.
948
949 If your code is to run on Perl versions earlier than
950 5.20, it is worthwhile to note that using C<$`> and C<$'>
951 slows down regexp matching quite a bit, while C<$&> slows it down to a
952 lesser extent, because if they are used in one regexp in a program,
953 they are generated for I<all> regexps in the program.  So if raw
954 performance is a goal of your application, they should be avoided.
955 If you need to extract the corresponding substrings, use C<@-> and
956 C<@+> instead:
957
958     $` is the same as substr( $x, 0, $-[0] )
959     $& is the same as substr( $x, $-[0], $+[0]-$-[0] )
960     $' is the same as substr( $x, $+[0] )
961
962 As of Perl 5.10, the C<${^PREMATCH}>, C<${^MATCH}> and C<${^POSTMATCH}>
963 variables may be used.  These are only set if the C</p> modifier is
964 present.  Consequently they do not penalize the rest of the program.  In
965 Perl 5.20, C<${^PREMATCH}>, C<${^MATCH}> and C<${^POSTMATCH}> are available
966 whether the C</p> has been used or not (the modifier is ignored), and
967 C<$`>, C<$'> and C<$&> do not cause any speed difference.
968
969 =head2 Non-capturing groupings
970
971 A group that is required to bundle a set of alternatives may or may not be
972 useful as a capturing group.  If it isn't, it just creates a superfluous
973 addition to the set of available capture group values, inside as well as
974 outside the regexp.  Non-capturing groupings, denoted by C<(?:regexp)>,
975 still allow the regexp to be treated as a single unit, but don't establish
976 a capturing group at the same time.  Both capturing and non-capturing
977 groupings are allowed to co-exist in the same regexp.  Because there is
978 no extraction, non-capturing groupings are faster than capturing
979 groupings.  Non-capturing groupings are also handy for choosing exactly
980 which parts of a regexp are to be extracted to matching variables:
981
982     # match a number, $1-$4 are set, but we only want $1
983     /([+-]?\ *(\d+(\.\d*)?|\.\d+)([eE][+-]?\d+)?)/;
984
985     # match a number faster , only $1 is set
986     /([+-]?\ *(?:\d+(?:\.\d*)?|\.\d+)(?:[eE][+-]?\d+)?)/;
987
988     # match a number, get $1 = whole number, $2 = exponent
989     /([+-]?\ *(?:\d+(?:\.\d*)?|\.\d+)(?:[eE]([+-]?\d+))?)/;
990
991 Non-capturing groupings are also useful for removing nuisance
992 elements gathered from a split operation where parentheses are
993 required for some reason:
994
995     $x = '12aba34ba5';
996     @num = split /(a|b)+/, $x;    # @num = ('12','a','34','a','5')
997     @num = split /(?:a|b)+/, $x;  # @num = ('12','34','5')
998
999 In Perl 5.22 and later, all groups within a regexp can be set to
1000 non-capturing by using the new C</n> flag:
1001
1002     "hello" =~ /(hi|hello)/n; # $1 is not set!
1003
1004 See L<perlre/"n"> for more information.
1005
1006 =head2 Matching repetitions
1007
1008 The examples in the previous section display an annoying weakness.  We
1009 were only matching 3-letter words, or chunks of words of 4 letters or
1010 less.  We'd like to be able to match words or, more generally, strings
1011 of any length, without writing out tedious alternatives like
1012 C<\w\w\w\w|\w\w\w|\w\w|\w>.
1013
1014 This is exactly the problem the I<quantifier> metacharacters C<?>,
1015 C<*>, C<+>, and C<{}> were created for.  They allow us to delimit the
1016 number of repeats for a portion of a regexp we consider to be a
1017 match.  Quantifiers are put immediately after the character, character
1018 class, or grouping that we want to specify.  They have the following
1019 meanings:
1020
1021 =over 4
1022
1023 =item *
1024
1025 C<a?> means: match 'a' 1 or 0 times
1026
1027 =item *
1028
1029 C<a*> means: match 'a' 0 or more times, i.e., any number of times
1030
1031 =item *
1032
1033 C<a+> means: match 'a' 1 or more times, i.e., at least once
1034
1035 =item *
1036
1037 C<a{n,m}> means: match at least C<n> times, but not more than C<m>
1038 times.
1039
1040 =item *
1041
1042 C<a{n,}> means: match at least C<n> or more times
1043
1044 =item *
1045
1046 C<a{n}> means: match exactly C<n> times
1047
1048 =back
1049
1050 Here are some examples:
1051
1052     /[a-z]+\s+\d*/;  # match a lowercase word, at least one space, and
1053                      # any number of digits
1054     /(\w+)\s+\g1/;    # match doubled words of arbitrary length
1055     /y(es)?/i;       # matches 'y', 'Y', or a case-insensitive 'yes'
1056     $year =~ /^\d{2,4}$/;  # make sure year is at least 2 but not more
1057                            # than 4 digits
1058     $year =~ /^\d{4}$|^\d{2}$/; # better match; throw out 3-digit dates
1059     $year =~ /^\d{2}(\d{2})?$/; # same thing written differently.
1060                                 # However, this captures the last two
1061                                 # digits in $1 and the other does not.
1062
1063     % simple_grep '^(\w+)\g1$' /usr/dict/words   # isn't this easier?
1064     beriberi
1065     booboo
1066     coco
1067     mama
1068     murmur
1069     papa
1070
1071 For all of these quantifiers, Perl will try to match as much of the
1072 string as possible, while still allowing the regexp to succeed.  Thus
1073 with C</a?.../>, Perl will first try to match the regexp with the C<a>
1074 present; if that fails, Perl will try to match the regexp without the
1075 C<a> present.  For the quantifier C<*>, we get the following:
1076
1077     $x = "the cat in the hat";
1078     $x =~ /^(.*)(cat)(.*)$/; # matches,
1079                              # $1 = 'the '
1080                              # $2 = 'cat'
1081                              # $3 = ' in the hat'
1082
1083 Which is what we might expect, the match finds the only C<cat> in the
1084 string and locks onto it.  Consider, however, this regexp:
1085
1086     $x =~ /^(.*)(at)(.*)$/; # matches,
1087                             # $1 = 'the cat in the h'
1088                             # $2 = 'at'
1089                             # $3 = ''   (0 characters match)
1090
1091 One might initially guess that Perl would find the C<at> in C<cat> and
1092 stop there, but that wouldn't give the longest possible string to the
1093 first quantifier C<.*>.  Instead, the first quantifier C<.*> grabs as
1094 much of the string as possible while still having the regexp match.  In
1095 this example, that means having the C<at> sequence with the final C<at>
1096 in the string.  The other important principle illustrated here is that,
1097 when there are two or more elements in a regexp, the I<leftmost>
1098 quantifier, if there is one, gets to grab as much of the string as
1099 possible, leaving the rest of the regexp to fight over scraps.  Thus in
1100 our example, the first quantifier C<.*> grabs most of the string, while
1101 the second quantifier C<.*> gets the empty string.   Quantifiers that
1102 grab as much of the string as possible are called I<maximal match> or
1103 I<greedy> quantifiers.
1104
1105 When a regexp can match a string in several different ways, we can use
1106 the principles above to predict which way the regexp will match:
1107
1108 =over 4
1109
1110 =item *
1111
1112 Principle 0: Taken as a whole, any regexp will be matched at the
1113 earliest possible position in the string.
1114
1115 =item *
1116
1117 Principle 1: In an alternation C<a|b|c...>, the leftmost alternative
1118 that allows a match for the whole regexp will be the one used.
1119
1120 =item *
1121
1122 Principle 2: The maximal matching quantifiers C<?>, C<*>, C<+> and
1123 C<{n,m}> will in general match as much of the string as possible while
1124 still allowing the whole regexp to match.
1125
1126 =item *
1127
1128 Principle 3: If there are two or more elements in a regexp, the
1129 leftmost greedy quantifier, if any, will match as much of the string
1130 as possible while still allowing the whole regexp to match.  The next
1131 leftmost greedy quantifier, if any, will try to match as much of the
1132 string remaining available to it as possible, while still allowing the
1133 whole regexp to match.  And so on, until all the regexp elements are
1134 satisfied.
1135
1136 =back
1137
1138 As we have seen above, Principle 0 overrides the others. The regexp
1139 will be matched as early as possible, with the other principles
1140 determining how the regexp matches at that earliest character
1141 position.
1142
1143 Here is an example of these principles in action:
1144
1145     $x = "The programming republic of Perl";
1146     $x =~ /^(.+)(e|r)(.*)$/;  # matches,
1147                               # $1 = 'The programming republic of Pe'
1148                               # $2 = 'r'
1149                               # $3 = 'l'
1150
1151 This regexp matches at the earliest string position, C<'T'>.  One
1152 might think that C<e>, being leftmost in the alternation, would be
1153 matched, but C<r> produces the longest string in the first quantifier.
1154
1155     $x =~ /(m{1,2})(.*)$/;  # matches,
1156                             # $1 = 'mm'
1157                             # $2 = 'ing republic of Perl'
1158
1159 Here, The earliest possible match is at the first C<'m'> in
1160 C<programming>. C<m{1,2}> is the first quantifier, so it gets to match
1161 a maximal C<mm>.
1162
1163     $x =~ /.*(m{1,2})(.*)$/;  # matches,
1164                               # $1 = 'm'
1165                               # $2 = 'ing republic of Perl'
1166
1167 Here, the regexp matches at the start of the string. The first
1168 quantifier C<.*> grabs as much as possible, leaving just a single
1169 C<'m'> for the second quantifier C<m{1,2}>.
1170
1171     $x =~ /(.?)(m{1,2})(.*)$/;  # matches,
1172                                 # $1 = 'a'
1173                                 # $2 = 'mm'
1174                                 # $3 = 'ing republic of Perl'
1175
1176 Here, C<.?> eats its maximal one character at the earliest possible
1177 position in the string, C<'a'> in C<programming>, leaving C<m{1,2}>
1178 the opportunity to match both C<m>'s. Finally,
1179
1180     "aXXXb" =~ /(X*)/; # matches with $1 = ''
1181
1182 because it can match zero copies of C<'X'> at the beginning of the
1183 string.  If you definitely want to match at least one C<'X'>, use
1184 C<X+>, not C<X*>.
1185
1186 Sometimes greed is not good.  At times, we would like quantifiers to
1187 match a I<minimal> piece of string, rather than a maximal piece.  For
1188 this purpose, Larry Wall created the I<minimal match> or
1189 I<non-greedy> quantifiers C<??>, C<*?>, C<+?>, and C<{}?>.  These are
1190 the usual quantifiers with a C<?> appended to them.  They have the
1191 following meanings:
1192
1193 =over 4
1194
1195 =item *
1196
1197 C<a??> means: match 'a' 0 or 1 times. Try 0 first, then 1.
1198
1199 =item *
1200
1201 C<a*?> means: match 'a' 0 or more times, i.e., any number of times,
1202 but as few times as possible
1203
1204 =item *
1205
1206 C<a+?> means: match 'a' 1 or more times, i.e., at least once, but
1207 as few times as possible
1208
1209 =item *
1210
1211 C<a{n,m}?> means: match at least C<n> times, not more than C<m>
1212 times, as few times as possible
1213
1214 =item *
1215
1216 C<a{n,}?> means: match at least C<n> times, but as few times as
1217 possible
1218
1219 =item *
1220
1221 C<a{n}?> means: match exactly C<n> times.  Because we match exactly
1222 C<n> times, C<a{n}?> is equivalent to C<a{n}> and is just there for
1223 notational consistency.
1224
1225 =back
1226
1227 Let's look at the example above, but with minimal quantifiers:
1228
1229     $x = "The programming republic of Perl";
1230     $x =~ /^(.+?)(e|r)(.*)$/; # matches,
1231                               # $1 = 'Th'
1232                               # $2 = 'e'
1233                               # $3 = ' programming republic of Perl'
1234
1235 The minimal string that will allow both the start of the string C<^>
1236 and the alternation to match is C<Th>, with the alternation C<e|r>
1237 matching C<e>.  The second quantifier C<.*> is free to gobble up the
1238 rest of the string.
1239
1240     $x =~ /(m{1,2}?)(.*?)$/;  # matches,
1241                               # $1 = 'm'
1242                               # $2 = 'ming republic of Perl'
1243
1244 The first string position that this regexp can match is at the first
1245 C<'m'> in C<programming>. At this position, the minimal C<m{1,2}?>
1246 matches just one C<'m'>.  Although the second quantifier C<.*?> would
1247 prefer to match no characters, it is constrained by the end-of-string
1248 anchor C<$> to match the rest of the string.
1249
1250     $x =~ /(.*?)(m{1,2}?)(.*)$/;  # matches,
1251                                   # $1 = 'The progra'
1252                                   # $2 = 'm'
1253                                   # $3 = 'ming republic of Perl'
1254
1255 In this regexp, you might expect the first minimal quantifier C<.*?>
1256 to match the empty string, because it is not constrained by a C<^>
1257 anchor to match the beginning of the word.  Principle 0 applies here,
1258 however.  Because it is possible for the whole regexp to match at the
1259 start of the string, it I<will> match at the start of the string.  Thus
1260 the first quantifier has to match everything up to the first C<m>.  The
1261 second minimal quantifier matches just one C<m> and the third
1262 quantifier matches the rest of the string.
1263
1264     $x =~ /(.??)(m{1,2})(.*)$/;  # matches,
1265                                  # $1 = 'a'
1266                                  # $2 = 'mm'
1267                                  # $3 = 'ing republic of Perl'
1268
1269 Just as in the previous regexp, the first quantifier C<.??> can match
1270 earliest at position C<'a'>, so it does.  The second quantifier is
1271 greedy, so it matches C<mm>, and the third matches the rest of the
1272 string.
1273
1274 We can modify principle 3 above to take into account non-greedy
1275 quantifiers:
1276
1277 =over 4
1278
1279 =item *
1280
1281 Principle 3: If there are two or more elements in a regexp, the
1282 leftmost greedy (non-greedy) quantifier, if any, will match as much
1283 (little) of the string as possible while still allowing the whole
1284 regexp to match.  The next leftmost greedy (non-greedy) quantifier, if
1285 any, will try to match as much (little) of the string remaining
1286 available to it as possible, while still allowing the whole regexp to
1287 match.  And so on, until all the regexp elements are satisfied.
1288
1289 =back
1290
1291 Just like alternation, quantifiers are also susceptible to
1292 backtracking.  Here is a step-by-step analysis of the example
1293
1294     $x = "the cat in the hat";
1295     $x =~ /^(.*)(at)(.*)$/; # matches,
1296                             # $1 = 'the cat in the h'
1297                             # $2 = 'at'
1298                             # $3 = ''   (0 matches)
1299
1300 =over 4
1301
1302 =item Z<>0
1303
1304 Start with the first letter in the string 't'.
1305
1306 =item Z<>1
1307
1308 The first quantifier '.*' starts out by matching the whole
1309 string 'the cat in the hat'.
1310
1311 =item Z<>2
1312
1313 'a' in the regexp element 'at' doesn't match the end of the
1314 string.  Backtrack one character.
1315
1316 =item Z<>3
1317
1318 'a' in the regexp element 'at' still doesn't match the last
1319 letter of the string 't', so backtrack one more character.
1320
1321 =item Z<>4
1322
1323 Now we can match the 'a' and the 't'.
1324
1325 =item Z<>5
1326
1327 Move on to the third element '.*'.  Since we are at the end of
1328 the string and '.*' can match 0 times, assign it the empty string.
1329
1330 =item Z<>6
1331
1332 We are done!
1333
1334 =back
1335
1336 Most of the time, all this moving forward and backtracking happens
1337 quickly and searching is fast. There are some pathological regexps,
1338 however, whose execution time exponentially grows with the size of the
1339 string.  A typical structure that blows up in your face is of the form
1340
1341     /(a|b+)*/;
1342
1343 The problem is the nested indeterminate quantifiers.  There are many
1344 different ways of partitioning a string of length n between the C<+>
1345 and C<*>: one repetition with C<b+> of length n, two repetitions with
1346 the first C<b+> length k and the second with length n-k, m repetitions
1347 whose bits add up to length n, etc.  In fact there are an exponential
1348 number of ways to partition a string as a function of its length.  A
1349 regexp may get lucky and match early in the process, but if there is
1350 no match, Perl will try I<every> possibility before giving up.  So be
1351 careful with nested C<*>'s, C<{n,m}>'s, and C<+>'s.  The book
1352 I<Mastering Regular Expressions> by Jeffrey Friedl gives a wonderful
1353 discussion of this and other efficiency issues.
1354
1355
1356 =head2 Possessive quantifiers
1357
1358 Backtracking during the relentless search for a match may be a waste
1359 of time, particularly when the match is bound to fail.  Consider
1360 the simple pattern
1361
1362     /^\w+\s+\w+$/; # a word, spaces, a word
1363
1364 Whenever this is applied to a string which doesn't quite meet the
1365 pattern's expectations such as S<C<"abc  ">> or S<C<"abc  def ">>,
1366 the regex engine will backtrack, approximately once for each character
1367 in the string.  But we know that there is no way around taking I<all>
1368 of the initial word characters to match the first repetition, that I<all>
1369 spaces must be eaten by the middle part, and the same goes for the second
1370 word.
1371
1372 With the introduction of the I<possessive quantifiers> in Perl 5.10, we
1373 have a way of instructing the regex engine not to backtrack, with the
1374 usual quantifiers with a C<+> appended to them.  This makes them greedy as
1375 well as stingy; once they succeed they won't give anything back to permit
1376 another solution. They have the following meanings:
1377
1378 =over 4
1379
1380 =item *
1381
1382 C<a{n,m}+> means: match at least C<n> times, not more than C<m> times,
1383 as many times as possible, and don't give anything up. C<a?+> is short
1384 for C<a{0,1}+>
1385
1386 =item *
1387
1388 C<a{n,}+> means: match at least C<n> times, but as many times as possible,
1389 and don't give anything up. C<a*+> is short for C<a{0,}+> and C<a++> is
1390 short for C<a{1,}+>.
1391
1392 =item *
1393
1394 C<a{n}+> means: match exactly C<n> times.  It is just there for
1395 notational consistency.
1396
1397 =back
1398
1399 These possessive quantifiers represent a special case of a more general
1400 concept, the I<independent subexpression>, see below.
1401
1402 As an example where a possessive quantifier is suitable we consider
1403 matching a quoted string, as it appears in several programming languages.
1404 The backslash is used as an escape character that indicates that the
1405 next character is to be taken literally, as another character for the
1406 string.  Therefore, after the opening quote, we expect a (possibly
1407 empty) sequence of alternatives: either some character except an
1408 unescaped quote or backslash or an escaped character.
1409
1410     /"(?:[^"\\]++|\\.)*+"/;
1411
1412
1413 =head2 Building a regexp
1414
1415 At this point, we have all the basic regexp concepts covered, so let's
1416 give a more involved example of a regular expression.  We will build a
1417 regexp that matches numbers.
1418
1419 The first task in building a regexp is to decide what we want to match
1420 and what we want to exclude.  In our case, we want to match both
1421 integers and floating point numbers and we want to reject any string
1422 that isn't a number.
1423
1424 The next task is to break the problem down into smaller problems that
1425 are easily converted into a regexp.
1426
1427 The simplest case is integers.  These consist of a sequence of digits,
1428 with an optional sign in front.  The digits we can represent with
1429 C<\d+> and the sign can be matched with C<[+-]>.  Thus the integer
1430 regexp is
1431
1432     /[+-]?\d+/;  # matches integers
1433
1434 A floating point number potentially has a sign, an integral part, a
1435 decimal point, a fractional part, and an exponent.  One or more of these
1436 parts is optional, so we need to check out the different
1437 possibilities.  Floating point numbers which are in proper form include
1438 123., 0.345, .34, -1e6, and 25.4E-72.  As with integers, the sign out
1439 front is completely optional and can be matched by C<[+-]?>.  We can
1440 see that if there is no exponent, floating point numbers must have a
1441 decimal point, otherwise they are integers.  We might be tempted to
1442 model these with C<\d*\.\d*>, but this would also match just a single
1443 decimal point, which is not a number.  So the three cases of floating
1444 point number without exponent are
1445
1446    /[+-]?\d+\./;  # 1., 321., etc.
1447    /[+-]?\.\d+/;  # .1, .234, etc.
1448    /[+-]?\d+\.\d+/;  # 1.0, 30.56, etc.
1449
1450 These can be combined into a single regexp with a three-way alternation:
1451
1452    /[+-]?(\d+\.\d+|\d+\.|\.\d+)/;  # floating point, no exponent
1453
1454 In this alternation, it is important to put C<'\d+\.\d+'> before
1455 C<'\d+\.'>.  If C<'\d+\.'> were first, the regexp would happily match that
1456 and ignore the fractional part of the number.
1457
1458 Now consider floating point numbers with exponents.  The key
1459 observation here is that I<both> integers and numbers with decimal
1460 points are allowed in front of an exponent.  Then exponents, like the
1461 overall sign, are independent of whether we are matching numbers with
1462 or without decimal points, and can be 'decoupled' from the
1463 mantissa.  The overall form of the regexp now becomes clear:
1464
1465     /^(optional sign)(integer | f.p. mantissa)(optional exponent)$/;
1466
1467 The exponent is an C<e> or C<E>, followed by an integer.  So the
1468 exponent regexp is
1469
1470    /[eE][+-]?\d+/;  # exponent
1471
1472 Putting all the parts together, we get a regexp that matches numbers:
1473
1474    /^[+-]?(\d+\.\d+|\d+\.|\.\d+|\d+)([eE][+-]?\d+)?$/;  # Ta da!
1475
1476 Long regexps like this may impress your friends, but can be hard to
1477 decipher.  In complex situations like this, the C</x> modifier for a
1478 match is invaluable.  It allows one to put nearly arbitrary whitespace
1479 and comments into a regexp without affecting their meaning.  Using it,
1480 we can rewrite our 'extended' regexp in the more pleasing form
1481
1482    /^
1483       [+-]?         # first, match an optional sign
1484       (             # then match integers or f.p. mantissas:
1485           \d+\.\d+  # mantissa of the form a.b
1486          |\d+\.     # mantissa of the form a.
1487          |\.\d+     # mantissa of the form .b
1488          |\d+       # integer of the form a
1489       )
1490       ( [eE] [+-]? \d+ )?  # finally, optionally match an exponent
1491    $/x;
1492
1493 If whitespace is mostly irrelevant, how does one include space
1494 characters in an extended regexp? The answer is to backslash it
1495 S<C<'\ '>> or put it in a character class S<C<[ ]>>.  The same thing
1496 goes for pound signs: use C<\#> or C<[#]>.  For instance, Perl allows
1497 a space between the sign and the mantissa or integer, and we could add
1498 this to our regexp as follows:
1499
1500    /^
1501       [+-]?\ *      # first, match an optional sign *and space*
1502       (             # then match integers or f.p. mantissas:
1503           \d+\.\d+  # mantissa of the form a.b
1504          |\d+\.     # mantissa of the form a.
1505          |\.\d+     # mantissa of the form .b
1506          |\d+       # integer of the form a
1507       )
1508       ( [eE] [+-]? \d+ )?  # finally, optionally match an exponent
1509    $/x;
1510
1511 In this form, it is easier to see a way to simplify the
1512 alternation.  Alternatives 1, 2, and 4 all start with C<\d+>, so it
1513 could be factored out:
1514
1515    /^
1516       [+-]?\ *      # first, match an optional sign
1517       (             # then match integers or f.p. mantissas:
1518           \d+       # start out with a ...
1519           (
1520               \.\d* # mantissa of the form a.b or a.
1521           )?        # ? takes care of integers of the form a
1522          |\.\d+     # mantissa of the form .b
1523       )
1524       ( [eE] [+-]? \d+ )?  # finally, optionally match an exponent
1525    $/x;
1526
1527 Starting in Perl v5.26, specifying C</xx> changes the square-bracketed
1528 portions of a pattern to ignore tabs and space characters unless they
1529 are escaped by preceding them with a backslash.  So, we could write
1530
1531    /^
1532       [ + - ]?\ *   # first, match an optional sign
1533       (             # then match integers or f.p. mantissas:
1534           \d+       # start out with a ...
1535           (
1536               \.\d* # mantissa of the form a.b or a.
1537           )?        # ? takes care of integers of the form a
1538          |\.\d+     # mantissa of the form .b
1539       )
1540       ( [ e E ] [ + - ]? \d+ )?  # finally, optionally match an exponent
1541    $/xx;
1542
1543 This doesn't really improve the legibility of this example, but it's
1544 available in case you want it.  Squashing the pattern down to the
1545 compact form, we have
1546
1547     /^[+-]?\ *(\d+(\.\d*)?|\.\d+)([eE][+-]?\d+)?$/;
1548
1549 This is our final regexp.  To recap, we built a regexp by
1550
1551 =over 4
1552
1553 =item *
1554
1555 specifying the task in detail,
1556
1557 =item *
1558
1559 breaking down the problem into smaller parts,
1560
1561 =item *
1562
1563 translating the small parts into regexps,
1564
1565 =item *
1566
1567 combining the regexps,
1568
1569 =item *
1570
1571 and optimizing the final combined regexp.
1572
1573 =back
1574
1575 These are also the typical steps involved in writing a computer
1576 program.  This makes perfect sense, because regular expressions are
1577 essentially programs written in a little computer language that specifies
1578 patterns.
1579
1580 =head2 Using regular expressions in Perl
1581
1582 The last topic of Part 1 briefly covers how regexps are used in Perl
1583 programs.  Where do they fit into Perl syntax?
1584
1585 We have already introduced the matching operator in its default
1586 C</regexp/> and arbitrary delimiter C<m!regexp!> forms.  We have used
1587 the binding operator C<=~> and its negation C<!~> to test for string
1588 matches.  Associated with the matching operator, we have discussed the
1589 single line C</s>, multi-line C</m>, case-insensitive C</i> and
1590 extended C</x> modifiers.  There are a few more things you might
1591 want to know about matching operators.
1592
1593 =head3 Prohibiting substitution
1594
1595 If you change C<$pattern> after the first substitution happens, Perl
1596 will ignore it.  If you don't want any substitutions at all, use the
1597 special delimiter C<m''>:
1598
1599     @pattern = ('Seuss');
1600     while (<>) {
1601         print if m'@pattern';  # matches literal '@pattern', not 'Seuss'
1602     }
1603
1604 Similar to strings, C<m''> acts like apostrophes on a regexp; all other
1605 C<m> delimiters act like quotes.  If the regexp evaluates to the empty string,
1606 the regexp in the I<last successful match> is used instead.  So we have
1607
1608     "dog" =~ /d/;  # 'd' matches
1609     "dogbert =~ //;  # this matches the 'd' regexp used before
1610
1611
1612 =head3 Global matching
1613
1614 The final two modifiers we will discuss here,
1615 C</g> and C</c>, concern multiple matches.
1616 The modifier C</g> stands for global matching and allows the
1617 matching operator to match within a string as many times as possible.
1618 In scalar context, successive invocations against a string will have
1619 C</g> jump from match to match, keeping track of position in the
1620 string as it goes along.  You can get or set the position with the
1621 C<pos()> function.
1622
1623 The use of C</g> is shown in the following example.  Suppose we have
1624 a string that consists of words separated by spaces.  If we know how
1625 many words there are in advance, we could extract the words using
1626 groupings:
1627
1628     $x = "cat dog house"; # 3 words
1629     $x =~ /^\s*(\w+)\s+(\w+)\s+(\w+)\s*$/; # matches,
1630                                            # $1 = 'cat'
1631                                            # $2 = 'dog'
1632                                            # $3 = 'house'
1633
1634 But what if we had an indeterminate number of words? This is the sort
1635 of task C</g> was made for.  To extract all words, form the simple
1636 regexp C<(\w+)> and loop over all matches with C</(\w+)/g>:
1637
1638     while ($x =~ /(\w+)/g) {
1639         print "Word is $1, ends at position ", pos $x, "\n";
1640     }
1641
1642 prints
1643
1644     Word is cat, ends at position 3
1645     Word is dog, ends at position 7
1646     Word is house, ends at position 13
1647
1648 A failed match or changing the target string resets the position.  If
1649 you don't want the position reset after failure to match, add the
1650 C</c>, as in C</regexp/gc>.  The current position in the string is
1651 associated with the string, not the regexp.  This means that different
1652 strings have different positions and their respective positions can be
1653 set or read independently.
1654
1655 In list context, C</g> returns a list of matched groupings, or if
1656 there are no groupings, a list of matches to the whole regexp.  So if
1657 we wanted just the words, we could use
1658
1659     @words = ($x =~ /(\w+)/g);  # matches,
1660                                 # $words[0] = 'cat'
1661                                 # $words[1] = 'dog'
1662                                 # $words[2] = 'house'
1663
1664 Closely associated with the C</g> modifier is the C<\G> anchor.  The
1665 C<\G> anchor matches at the point where the previous C</g> match left
1666 off.  C<\G> allows us to easily do context-sensitive matching:
1667
1668     $metric = 1;  # use metric units
1669     ...
1670     $x = <FILE>;  # read in measurement
1671     $x =~ /^([+-]?\d+)\s*/g;  # get magnitude
1672     $weight = $1;
1673     if ($metric) { # error checking
1674         print "Units error!" unless $x =~ /\Gkg\./g;
1675     }
1676     else {
1677         print "Units error!" unless $x =~ /\Glbs\./g;
1678     }
1679     $x =~ /\G\s+(widget|sprocket)/g;  # continue processing
1680
1681 The combination of C</g> and C<\G> allows us to process the string a
1682 bit at a time and use arbitrary Perl logic to decide what to do next.
1683 Currently, the C<\G> anchor is only fully supported when used to anchor
1684 to the start of the pattern.
1685
1686 C<\G> is also invaluable in processing fixed-length records with
1687 regexps.  Suppose we have a snippet of coding region DNA, encoded as
1688 base pair letters C<ATCGTTGAAT...> and we want to find all the stop
1689 codons C<TGA>.  In a coding region, codons are 3-letter sequences, so
1690 we can think of the DNA snippet as a sequence of 3-letter records.  The
1691 naive regexp
1692
1693     # expanded, this is "ATC GTT GAA TGC AAA TGA CAT GAC"
1694     $dna = "ATCGTTGAATGCAAATGACATGAC";
1695     $dna =~ /TGA/;
1696
1697 doesn't work; it may match a C<TGA>, but there is no guarantee that
1698 the match is aligned with codon boundaries, e.g., the substring
1699 S<C<GTT GAA>> gives a match.  A better solution is
1700
1701     while ($dna =~ /(\w\w\w)*?TGA/g) {  # note the minimal *?
1702         print "Got a TGA stop codon at position ", pos $dna, "\n";
1703     }
1704
1705 which prints
1706
1707     Got a TGA stop codon at position 18
1708     Got a TGA stop codon at position 23
1709
1710 Position 18 is good, but position 23 is bogus.  What happened?
1711
1712 The answer is that our regexp works well until we get past the last
1713 real match.  Then the regexp will fail to match a synchronized C<TGA>
1714 and start stepping ahead one character position at a time, not what we
1715 want.  The solution is to use C<\G> to anchor the match to the codon
1716 alignment:
1717
1718     while ($dna =~ /\G(\w\w\w)*?TGA/g) {
1719         print "Got a TGA stop codon at position ", pos $dna, "\n";
1720     }
1721
1722 This prints
1723
1724     Got a TGA stop codon at position 18
1725
1726 which is the correct answer.  This example illustrates that it is
1727 important not only to match what is desired, but to reject what is not
1728 desired.
1729
1730 (There are other regexp modifiers that are available, such as
1731 C</o>, but their specialized uses are beyond the
1732 scope of this introduction.  )
1733
1734 =head3 Search and replace
1735
1736 Regular expressions also play a big role in I<search and replace>
1737 operations in Perl.  Search and replace is accomplished with the
1738 C<s///> operator.  The general form is
1739 C<s/regexp/replacement/modifiers>, with everything we know about
1740 regexps and modifiers applying in this case as well.  The
1741 C<replacement> is a Perl double-quoted string that replaces in the
1742 string whatever is matched with the C<regexp>.  The operator C<=~> is
1743 also used here to associate a string with C<s///>.  If matching
1744 against C<$_>, the S<C<$_ =~>> can be dropped.  If there is a match,
1745 C<s///> returns the number of substitutions made; otherwise it returns
1746 false.  Here are a few examples:
1747
1748     $x = "Time to feed the cat!";
1749     $x =~ s/cat/hacker/;   # $x contains "Time to feed the hacker!"
1750     if ($x =~ s/^(Time.*hacker)!$/$1 now!/) {
1751         $more_insistent = 1;
1752     }
1753     $y = "'quoted words'";
1754     $y =~ s/^'(.*)'$/$1/;  # strip single quotes,
1755                            # $y contains "quoted words"
1756
1757 In the last example, the whole string was matched, but only the part
1758 inside the single quotes was grouped.  With the C<s///> operator, the
1759 matched variables C<$1>, C<$2>, etc. are immediately available for use
1760 in the replacement expression, so we use C<$1> to replace the quoted
1761 string with just what was quoted.  With the global modifier, C<s///g>
1762 will search and replace all occurrences of the regexp in the string:
1763
1764     $x = "I batted 4 for 4";
1765     $x =~ s/4/four/;   # doesn't do it all:
1766                        # $x contains "I batted four for 4"
1767     $x = "I batted 4 for 4";
1768     $x =~ s/4/four/g;  # does it all:
1769                        # $x contains "I batted four for four"
1770
1771 If you prefer 'regex' over 'regexp' in this tutorial, you could use
1772 the following program to replace it:
1773
1774     % cat > simple_replace
1775     #!/usr/bin/perl
1776     $regexp = shift;
1777     $replacement = shift;
1778     while (<>) {
1779         s/$regexp/$replacement/g;
1780         print;
1781     }
1782     ^D
1783
1784     % simple_replace regexp regex perlretut.pod
1785
1786 In C<simple_replace> we used the C<s///g> modifier to replace all
1787 occurrences of the regexp on each line.  (Even though the regular
1788 expression appears in a loop, Perl is smart enough to compile it
1789 only once.)  As with C<simple_grep>, both the
1790 C<print> and the C<s/$regexp/$replacement/g> use C<$_> implicitly.
1791
1792 If you don't want C<s///> to change your original variable you can use
1793 the non-destructive substitute modifier, C<s///r>.  This changes the
1794 behavior so that C<s///r> returns the final substituted string
1795 (instead of the number of substitutions):
1796
1797     $x = "I like dogs.";
1798     $y = $x =~ s/dogs/cats/r;
1799     print "$x $y\n";
1800
1801 That example will print "I like dogs. I like cats". Notice the original
1802 C<$x> variable has not been affected. The overall
1803 result of the substitution is instead stored in C<$y>. If the
1804 substitution doesn't affect anything then the original string is
1805 returned:
1806
1807     $x = "I like dogs.";
1808     $y = $x =~ s/elephants/cougars/r;
1809     print "$x $y\n"; # prints "I like dogs. I like dogs."
1810
1811 One other interesting thing that the C<s///r> flag allows is chaining
1812 substitutions:
1813
1814     $x = "Cats are great.";
1815     print $x =~ s/Cats/Dogs/r =~ s/Dogs/Frogs/r =~
1816         s/Frogs/Hedgehogs/r, "\n";
1817     # prints "Hedgehogs are great."
1818
1819 A modifier available specifically to search and replace is the
1820 C<s///e> evaluation modifier.  C<s///e> treats the
1821 replacement text as Perl code, rather than a double-quoted
1822 string.  The value that the code returns is substituted for the
1823 matched substring.  C<s///e> is useful if you need to do a bit of
1824 computation in the process of replacing text.  This example counts
1825 character frequencies in a line:
1826
1827     $x = "Bill the cat";
1828     $x =~ s/(.)/$chars{$1}++;$1/eg; # final $1 replaces char with itself
1829     print "frequency of '$_' is $chars{$_}\n"
1830         foreach (sort {$chars{$b} <=> $chars{$a}} keys %chars);
1831
1832 This prints
1833
1834     frequency of ' ' is 2
1835     frequency of 't' is 2
1836     frequency of 'l' is 2
1837     frequency of 'B' is 1
1838     frequency of 'c' is 1
1839     frequency of 'e' is 1
1840     frequency of 'h' is 1
1841     frequency of 'i' is 1
1842     frequency of 'a' is 1
1843
1844 As with the match C<m//> operator, C<s///> can use other delimiters,
1845 such as C<s!!!> and C<s{}{}>, and even C<s{}//>.  If single quotes are
1846 used C<s'''>, then the regexp and replacement are
1847 treated as single-quoted strings and there are no
1848 variable substitutions.  C<s///> in list context
1849 returns the same thing as in scalar context, i.e., the number of
1850 matches.
1851
1852 =head3 The split function
1853
1854 The C<split()> function is another place where a regexp is used.
1855 C<split /regexp/, string, limit> separates the C<string> operand into
1856 a list of substrings and returns that list.  The regexp must be designed
1857 to match whatever constitutes the separators for the desired substrings.
1858 The C<limit>, if present, constrains splitting into no more than C<limit>
1859 number of strings.  For example, to split a string into words, use
1860
1861     $x = "Calvin and Hobbes";
1862     @words = split /\s+/, $x;  # $word[0] = 'Calvin'
1863                                # $word[1] = 'and'
1864                                # $word[2] = 'Hobbes'
1865
1866 If the empty regexp C<//> is used, the regexp always matches and
1867 the string is split into individual characters.  If the regexp has
1868 groupings, then the resulting list contains the matched substrings from the
1869 groupings as well.  For instance,
1870
1871     $x = "/usr/bin/perl";
1872     @dirs = split m!/!, $x;  # $dirs[0] = ''
1873                              # $dirs[1] = 'usr'
1874                              # $dirs[2] = 'bin'
1875                              # $dirs[3] = 'perl'
1876     @parts = split m!(/)!, $x;  # $parts[0] = ''
1877                                 # $parts[1] = '/'
1878                                 # $parts[2] = 'usr'
1879                                 # $parts[3] = '/'
1880                                 # $parts[4] = 'bin'
1881                                 # $parts[5] = '/'
1882                                 # $parts[6] = 'perl'
1883
1884 Since the first character of $x matched the regexp, C<split> prepended
1885 an empty initial element to the list.
1886
1887 If you have read this far, congratulations! You now have all the basic
1888 tools needed to use regular expressions to solve a wide range of text
1889 processing problems.  If this is your first time through the tutorial,
1890 why not stop here and play around with regexps a while....  S<Part 2>
1891 concerns the more esoteric aspects of regular expressions and those
1892 concepts certainly aren't needed right at the start.
1893
1894 =head1 Part 2: Power tools
1895
1896 OK, you know the basics of regexps and you want to know more.  If
1897 matching regular expressions is analogous to a walk in the woods, then
1898 the tools discussed in Part 1 are analogous to topo maps and a
1899 compass, basic tools we use all the time.  Most of the tools in part 2
1900 are analogous to flare guns and satellite phones.  They aren't used
1901 too often on a hike, but when we are stuck, they can be invaluable.
1902
1903 What follows are the more advanced, less used, or sometimes esoteric
1904 capabilities of Perl regexps.  In Part 2, we will assume you are
1905 comfortable with the basics and concentrate on the advanced features.
1906
1907 =head2 More on characters, strings, and character classes
1908
1909 There are a number of escape sequences and character classes that we
1910 haven't covered yet.
1911
1912 There are several escape sequences that convert characters or strings
1913 between upper and lower case, and they are also available within
1914 patterns.  C<\l> and C<\u> convert the next character to lower or
1915 upper case, respectively:
1916
1917     $x = "perl";
1918     $string =~ /\u$x/;  # matches 'Perl' in $string
1919     $x = "M(rs?|s)\\."; # note the double backslash
1920     $string =~ /\l$x/;  # matches 'mr.', 'mrs.', and 'ms.',
1921
1922 A C<\L> or C<\U> indicates a lasting conversion of case, until
1923 terminated by C<\E> or thrown over by another C<\U> or C<\L>:
1924
1925     $x = "This word is in lower case:\L SHOUT\E";
1926     $x =~ /shout/;       # matches
1927     $x = "I STILL KEYPUNCH CARDS FOR MY 360"
1928     $x =~ /\Ukeypunch/;  # matches punch card string
1929
1930 If there is no C<\E>, case is converted until the end of the
1931 string. The regexps C<\L\u$word> or C<\u\L$word> convert the first
1932 character of C<$word> to uppercase and the rest of the characters to
1933 lowercase.
1934
1935 Control characters can be escaped with C<\c>, so that a control-Z
1936 character would be matched with C<\cZ>.  The escape sequence
1937 C<\Q>...C<\E> quotes, or protects most non-alphabetic characters.   For
1938 instance,
1939
1940     $x = "\QThat !^*&%~& cat!";
1941     $x =~ /\Q!^*&%~&\E/;  # check for rough language
1942
1943 It does not protect C<$> or C<@>, so that variables can still be
1944 substituted.
1945
1946 C<\Q>, C<\L>, C<\l>, C<\U>, C<\u> and C<\E> are actually part of
1947 double-quotish syntax, and not part of regexp syntax proper.  They will
1948 work if they appear in a regular expression embedded directly in a
1949 program, but not when contained in a string that is interpolated in a
1950 pattern.
1951
1952 Perl regexps can handle more than just the
1953 standard ASCII character set.  Perl supports I<Unicode>, a standard
1954 for representing the alphabets from virtually all of the world's written
1955 languages, and a host of symbols.  Perl's text strings are Unicode strings, so
1956 they can contain characters with a value (codepoint or character number) higher
1957 than 255.
1958
1959 What does this mean for regexps? Well, regexp users don't need to know
1960 much about Perl's internal representation of strings.  But they do need
1961 to know 1) how to represent Unicode characters in a regexp and 2) that
1962 a matching operation will treat the string to be searched as a sequence
1963 of characters, not bytes.  The answer to 1) is that Unicode characters
1964 greater than C<chr(255)> are represented using the C<\x{hex}> notation, because
1965 \x hex (without curly braces) doesn't go further than 255.  (Starting in Perl
1966 5.14, if you're an octal fan, you can also use C<\o{oct}>.)
1967
1968     /\x{263a}/;  # match a Unicode smiley face :)
1969
1970 B<NOTE>: In Perl 5.6.0 it used to be that one needed to say C<use
1971 utf8> to use any Unicode features.  This is no more the case: for
1972 almost all Unicode processing, the explicit C<utf8> pragma is not
1973 needed.  (The only case where it matters is if your Perl script is in
1974 Unicode and encoded in UTF-8, then an explicit C<use utf8> is needed.)
1975
1976 Figuring out the hexadecimal sequence of a Unicode character you want
1977 or deciphering someone else's hexadecimal Unicode regexp is about as
1978 much fun as programming in machine code.  So another way to specify
1979 Unicode characters is to use the I<named character> escape
1980 sequence C<\N{I<name>}>.  I<name> is a name for the Unicode character, as
1981 specified in the Unicode standard.  For instance, if we wanted to
1982 represent or match the astrological sign for the planet Mercury, we
1983 could use
1984
1985     $x = "abc\N{MERCURY}def";
1986     $x =~ /\N{MERCURY}/;   # matches
1987
1988 One can also use "short" names:
1989
1990     print "\N{GREEK SMALL LETTER SIGMA} is called sigma.\n";
1991     print "\N{greek:Sigma} is an upper-case sigma.\n";
1992
1993 You can also restrict names to a certain alphabet by specifying the
1994 L<charnames> pragma:
1995
1996     use charnames qw(greek);
1997     print "\N{sigma} is Greek sigma\n";
1998
1999 An index of character names is available on-line from the Unicode
2000 Consortium, L<http://www.unicode.org/charts/charindex.html>; explanatory
2001 material with links to other resources at
2002 L<http://www.unicode.org/standard/where>.
2003
2004 The answer to requirement 2) is that a regexp (mostly)
2005 uses Unicode characters.  The "mostly" is for messy backward
2006 compatibility reasons, but starting in Perl 5.14, any regex compiled in
2007 the scope of a C<use feature 'unicode_strings'> (which is automatically
2008 turned on within the scope of a C<use 5.012> or higher) will turn that
2009 "mostly" into "always".  If you want to handle Unicode properly, you
2010 should ensure that C<'unicode_strings'> is turned on.
2011 Internally, this is encoded to bytes using either UTF-8 or a native 8
2012 bit encoding, depending on the history of the string, but conceptually
2013 it is a sequence of characters, not bytes. See L<perlunitut> for a
2014 tutorial about that.
2015
2016 Let us now discuss Unicode character classes, most usually called
2017 "character properties".  These are represented by the
2018 C<\p{name}> escape sequence.  Closely associated is the C<\P{name}>
2019 property, which is the negation of the C<\p{name}> one.  For
2020 example, to match lower and uppercase characters,
2021
2022     $x = "BOB";
2023     $x =~ /^\p{IsUpper}/;   # matches, uppercase char class
2024     $x =~ /^\P{IsUpper}/;   # doesn't match, char class sans uppercase
2025     $x =~ /^\p{IsLower}/;   # doesn't match, lowercase char class
2026     $x =~ /^\P{IsLower}/;   # matches, char class sans lowercase
2027
2028 (The "Is" is optional.)
2029
2030 There are many, many Unicode character properties.  For the full list
2031 see L<perluniprops>.  Most of them have synonyms with shorter names,
2032 also listed there.  Some synonyms are a single character.  For these,
2033 you can drop the braces.  For instance, C<\pM> is the same thing as
2034 C<\p{Mark}>, meaning things like accent marks.
2035
2036 The Unicode C<\p{Script}> and C<\p{Script_Extensions}> properties are
2037 used to categorize every Unicode character into the language script it
2038 is written in.  (C<Script_Extensions> is an improved version of
2039 C<Script>, which is retained for backward compatibility, and so you
2040 should generally use C<Script_Extensions>.)
2041 For example,
2042 English, French, and a bunch of other European languages are written in
2043 the Latin script.  But there is also the Greek script, the Thai script,
2044 the Katakana script, etc.  You can test whether a character is in a
2045 particular script (based on C<Script_Extensions>) with, for example
2046 C<\p{Latin}>, C<\p{Greek}>, or C<\p{Katakana}>.  To test if it isn't in
2047 the Balinese script, you would use C<\P{Balinese}>.
2048
2049 What we have described so far is the single form of the C<\p{...}> character
2050 classes.  There is also a compound form which you may run into.  These
2051 look like C<\p{name=value}> or C<\p{name:value}> (the equals sign and colon
2052 can be used interchangeably).  These are more general than the single form,
2053 and in fact most of the single forms are just Perl-defined shortcuts for common
2054 compound forms.  For example, the script examples in the previous paragraph
2055 could be written equivalently as C<\p{Script_Extensions=Latin}>, C<\p{Script_Extensions:Greek}>,
2056 C<\p{script_extensions=katakana}>, and C<\P{script_extensions=balinese}> (case is irrelevant
2057 between the C<{}> braces).  You may
2058 never have to use the compound forms, but sometimes it is necessary, and their
2059 use can make your code easier to understand.
2060
2061 C<\X> is an abbreviation for a character class that comprises
2062 a Unicode I<extended grapheme cluster>.  This represents a "logical character":
2063 what appears to be a single character, but may be represented internally by more
2064 than one.  As an example, using the Unicode full names, e.g., S<C<A + COMBINING
2065 RING>> is a grapheme cluster with base character C<A> and combining character
2066 S<C<COMBINING RING>>, which translates in Danish to A with the circle atop it,
2067 as in the word E<Aring>ngstrom.
2068
2069 For the full and latest information about Unicode see the latest
2070 Unicode standard, or the Unicode Consortium's website L<http://www.unicode.org>
2071
2072 As if all those classes weren't enough, Perl also defines POSIX-style
2073 character classes.  These have the form C<[:name:]>, with C<name> the
2074 name of the POSIX class.  The POSIX classes are C<alpha>, C<alnum>,
2075 C<ascii>, C<cntrl>, C<digit>, C<graph>, C<lower>, C<print>, C<punct>,
2076 C<space>, C<upper>, and C<xdigit>, and two extensions, C<word> (a Perl
2077 extension to match C<\w>), and C<blank> (a GNU extension).  The C</a>
2078 modifier restricts these to matching just in the ASCII range; otherwise
2079 they can match the same as their corresponding Perl Unicode classes:
2080 C<[:upper:]> is the same as C<\p{IsUpper}>, etc.  (There are some
2081 exceptions and gotchas with this; see L<perlrecharclass> for a full
2082 discussion.) The C<[:digit:]>, C<[:word:]>, and
2083 C<[:space:]> correspond to the familiar C<\d>, C<\w>, and C<\s>
2084 character classes.  To negate a POSIX class, put a C<^> in front of
2085 the name, so that, e.g., C<[:^digit:]> corresponds to C<\D> and, under
2086 Unicode, C<\P{IsDigit}>.  The Unicode and POSIX character classes can
2087 be used just like C<\d>, with the exception that POSIX character
2088 classes can only be used inside of a character class:
2089
2090     /\s+[abc[:digit:]xyz]\s*/;  # match a,b,c,x,y,z, or a digit
2091     /^=item\s[[:digit:]]/;      # match '=item',
2092                                 # followed by a space and a digit
2093     /\s+[abc\p{IsDigit}xyz]\s+/;  # match a,b,c,x,y,z, or a digit
2094     /^=item\s\p{IsDigit}/;        # match '=item',
2095                                   # followed by a space and a digit
2096
2097 Whew! That is all the rest of the characters and character classes.
2098
2099 =head2 Compiling and saving regular expressions
2100
2101 In Part 1 we mentioned that Perl compiles a regexp into a compact
2102 sequence of opcodes.  Thus, a compiled regexp is a data structure
2103 that can be stored once and used again and again.  The regexp quote
2104 C<qr//> does exactly that: C<qr/string/> compiles the C<string> as a
2105 regexp and transforms the result into a form that can be assigned to a
2106 variable:
2107
2108     $reg = qr/foo+bar?/;  # reg contains a compiled regexp
2109
2110 Then C<$reg> can be used as a regexp:
2111
2112     $x = "fooooba";
2113     $x =~ $reg;     # matches, just like /foo+bar?/
2114     $x =~ /$reg/;   # same thing, alternate form
2115
2116 C<$reg> can also be interpolated into a larger regexp:
2117
2118     $x =~ /(abc)?$reg/;  # still matches
2119
2120 As with the matching operator, the regexp quote can use different
2121 delimiters, e.g., C<qr!!>, C<qr{}> or C<qr~~>.  Apostrophes
2122 as delimiters (C<qr''>) inhibit any interpolation.
2123
2124 Pre-compiled regexps are useful for creating dynamic matches that
2125 don't need to be recompiled each time they are encountered.  Using
2126 pre-compiled regexps, we write a C<grep_step> program which greps
2127 for a sequence of patterns, advancing to the next pattern as soon
2128 as one has been satisfied.
2129
2130     % cat > grep_step
2131     #!/usr/bin/perl
2132     # grep_step - match <number> regexps, one after the other
2133     # usage: multi_grep <number> regexp1 regexp2 ... file1 file2 ...
2134
2135     $number = shift;
2136     $regexp[$_] = shift foreach (0..$number-1);
2137     @compiled = map qr/$_/, @regexp;
2138     while ($line = <>) {
2139         if ($line =~ /$compiled[0]/) {
2140             print $line;
2141             shift @compiled;
2142             last unless @compiled;
2143         }
2144     }
2145     ^D
2146
2147     % grep_step 3 shift print last grep_step
2148     $number = shift;
2149             print $line;
2150             last unless @compiled;
2151
2152 Storing pre-compiled regexps in an array C<@compiled> allows us to
2153 simply loop through the regexps without any recompilation, thus gaining
2154 flexibility without sacrificing speed.
2155
2156
2157 =head2 Composing regular expressions at runtime
2158
2159 Backtracking is more efficient than repeated tries with different regular
2160 expressions.  If there are several regular expressions and a match with
2161 any of them is acceptable, then it is possible to combine them into a set
2162 of alternatives.  If the individual expressions are input data, this
2163 can be done by programming a join operation.  We'll exploit this idea in
2164 an improved version of the C<simple_grep> program: a program that matches
2165 multiple patterns:
2166
2167     % cat > multi_grep
2168     #!/usr/bin/perl
2169     # multi_grep - match any of <number> regexps
2170     # usage: multi_grep <number> regexp1 regexp2 ... file1 file2 ...
2171
2172     $number = shift;
2173     $regexp[$_] = shift foreach (0..$number-1);
2174     $pattern = join '|', @regexp;
2175
2176     while ($line = <>) {
2177         print $line if $line =~ /$pattern/;
2178     }
2179     ^D
2180
2181     % multi_grep 2 shift for multi_grep
2182     $number = shift;
2183     $regexp[$_] = shift foreach (0..$number-1);
2184
2185 Sometimes it is advantageous to construct a pattern from the I<input>
2186 that is to be analyzed and use the permissible values on the left
2187 hand side of the matching operations.  As an example for this somewhat
2188 paradoxical situation, let's assume that our input contains a command
2189 verb which should match one out of a set of available command verbs,
2190 with the additional twist that commands may be abbreviated as long as
2191 the given string is unique. The program below demonstrates the basic
2192 algorithm.
2193
2194     % cat > keymatch
2195     #!/usr/bin/perl
2196     $kwds = 'copy compare list print';
2197     while( $cmd = <> ){
2198         $cmd =~ s/^\s+|\s+$//g;  # trim leading and trailing spaces
2199         if( ( @matches = $kwds =~ /\b$cmd\w*/g ) == 1 ){
2200             print "command: '@matches'\n";
2201         } elsif( @matches == 0 ){
2202             print "no such command: '$cmd'\n";
2203         } else {
2204             print "not unique: '$cmd' (could be one of: @matches)\n";
2205         }
2206     }
2207     ^D
2208
2209     % keymatch
2210     li
2211     command: 'list'
2212     co
2213     not unique: 'co' (could be one of: copy compare)
2214     printer
2215     no such command: 'printer'
2216
2217 Rather than trying to match the input against the keywords, we match the
2218 combined set of keywords against the input.  The pattern matching
2219 operation S<C<$kwds =~ /\b($cmd\w*)/g>> does several things at the
2220 same time. It makes sure that the given command begins where a keyword
2221 begins (C<\b>). It tolerates abbreviations due to the added C<\w*>. It
2222 tells us the number of matches (C<scalar @matches>) and all the keywords
2223 that were actually matched.  You could hardly ask for more.
2224
2225 =head2 Embedding comments and modifiers in a regular expression
2226
2227 Starting with this section, we will be discussing Perl's set of
2228 I<extended patterns>.  These are extensions to the traditional regular
2229 expression syntax that provide powerful new tools for pattern
2230 matching.  We have already seen extensions in the form of the minimal
2231 matching constructs C<??>, C<*?>, C<+?>, C<{n,m}?>, and C<{n,}?>.  Most
2232 of the extensions below have the form C<(?char...)>, where the
2233 C<char> is a character that determines the type of extension.
2234
2235 The first extension is an embedded comment C<(?#text)>.  This embeds a
2236 comment into the regular expression without affecting its meaning.  The
2237 comment should not have any closing parentheses in the text.  An
2238 example is
2239
2240     /(?# Match an integer:)[+-]?\d+/;
2241
2242 This style of commenting has been largely superseded by the raw,
2243 freeform commenting that is allowed with the C</x> modifier.
2244
2245 Most modifiers, such as C</i>, C</m>, C</s> and C</x> (or any
2246 combination thereof) can also be embedded in
2247 a regexp using C<(?i)>, C<(?m)>, C<(?s)>, and C<(?x)>.  For instance,
2248
2249     /(?i)yes/;  # match 'yes' case insensitively
2250     /yes/i;     # same thing
2251     /(?x)(          # freeform version of an integer regexp
2252              [+-]?  # match an optional sign
2253              \d+    # match a sequence of digits
2254          )
2255     /x;
2256
2257 Embedded modifiers can have two important advantages over the usual
2258 modifiers.  Embedded modifiers allow a custom set of modifiers to
2259 I<each> regexp pattern.  This is great for matching an array of regexps
2260 that must have different modifiers:
2261
2262     $pattern[0] = '(?i)doctor';
2263     $pattern[1] = 'Johnson';
2264     ...
2265     while (<>) {
2266         foreach $patt (@pattern) {
2267             print if /$patt/;
2268         }
2269     }
2270
2271 The second advantage is that embedded modifiers (except C</p>, which
2272 modifies the entire regexp) only affect the regexp
2273 inside the group the embedded modifier is contained in.  So grouping
2274 can be used to localize the modifier's effects:
2275
2276     /Answer: ((?i)yes)/;  # matches 'Answer: yes', 'Answer: YES', etc.
2277
2278 Embedded modifiers can also turn off any modifiers already present
2279 by using, e.g., C<(?-i)>.  Modifiers can also be combined into
2280 a single expression, e.g., C<(?s-i)> turns on single line mode and
2281 turns off case insensitivity.
2282
2283 Embedded modifiers may also be added to a non-capturing grouping.
2284 C<(?i-m:regexp)> is a non-capturing grouping that matches C<regexp>
2285 case insensitively and turns off multi-line mode.
2286
2287
2288 =head2 Looking ahead and looking behind
2289
2290 This section concerns the lookahead and lookbehind assertions.  First,
2291 a little background.
2292
2293 In Perl regular expressions, most regexp elements 'eat up' a certain
2294 amount of string when they match.  For instance, the regexp element
2295 C<[abc]> eats up one character of the string when it matches, in the
2296 sense that Perl moves to the next character position in the string
2297 after the match.  There are some elements, however, that don't eat up
2298 characters (advance the character position) if they match.  The examples
2299 we have seen so far are the anchors.  The anchor C<^> matches the
2300 beginning of the line, but doesn't eat any characters.  Similarly, the
2301 word boundary anchor C<\b> matches wherever a character matching C<\w>
2302 is next to a character that doesn't, but it doesn't eat up any
2303 characters itself.  Anchors are examples of I<zero-width assertions>:
2304 zero-width, because they consume
2305 no characters, and assertions, because they test some property of the
2306 string.  In the context of our walk in the woods analogy to regexp
2307 matching, most regexp elements move us along a trail, but anchors have
2308 us stop a moment and check our surroundings.  If the local environment
2309 checks out, we can proceed forward.  But if the local environment
2310 doesn't satisfy us, we must backtrack.
2311
2312 Checking the environment entails either looking ahead on the trail,
2313 looking behind, or both.  C<^> looks behind, to see that there are no
2314 characters before.  C<$> looks ahead, to see that there are no
2315 characters after.  C<\b> looks both ahead and behind, to see if the
2316 characters on either side differ in their "word-ness".
2317
2318 The lookahead and lookbehind assertions are generalizations of the
2319 anchor concept.  Lookahead and lookbehind are zero-width assertions
2320 that let us specify which characters we want to test for.  The
2321 lookahead assertion is denoted by C<(?=regexp)> and the lookbehind
2322 assertion is denoted by C<< (?<=fixed-regexp) >>.  Some examples are
2323
2324     $x = "I catch the housecat 'Tom-cat' with catnip";
2325     $x =~ /cat(?=\s)/;   # matches 'cat' in 'housecat'
2326     @catwords = ($x =~ /(?<=\s)cat\w+/g);  # matches,
2327                                            # $catwords[0] = 'catch'
2328                                            # $catwords[1] = 'catnip'
2329     $x =~ /\bcat\b/;  # matches 'cat' in 'Tom-cat'
2330     $x =~ /(?<=\s)cat(?=\s)/; # doesn't match; no isolated 'cat' in
2331                               # middle of $x
2332
2333 Note that the parentheses in C<(?=regexp)> and C<< (?<=regexp) >> are
2334 non-capturing, since these are zero-width assertions.  Thus in the
2335 second regexp, the substrings captured are those of the whole regexp
2336 itself.  Lookahead C<(?=regexp)> can match arbitrary regexps, but
2337 lookbehind C<< (?<=fixed-regexp) >> only works for regexps of fixed
2338 width, i.e., a fixed number of characters long.  Thus
2339 C<< (?<=(ab|bc)) >> is fine, but C<< (?<=(ab)*) >> is not.  The
2340 negated versions of the lookahead and lookbehind assertions are
2341 denoted by C<(?!regexp)> and C<< (?<!fixed-regexp) >> respectively.
2342 They evaluate true if the regexps do I<not> match:
2343
2344     $x = "foobar";
2345     $x =~ /foo(?!bar)/;  # doesn't match, 'bar' follows 'foo'
2346     $x =~ /foo(?!baz)/;  # matches, 'baz' doesn't follow 'foo'
2347     $x =~ /(?<!\s)foo/;  # matches, there is no \s before 'foo'
2348
2349 Here is an example where a string containing blank-separated words,
2350 numbers and single dashes is to be split into its components.
2351 Using C</\s+/> alone won't work, because spaces are not required between
2352 dashes, or a word or a dash. Additional places for a split are established
2353 by looking ahead and behind:
2354
2355     $str = "one two - --6-8";
2356     @toks = split / \s+              # a run of spaces
2357                   | (?<=\S) (?=-)    # any non-space followed by '-'
2358                   | (?<=-)  (?=\S)   # a '-' followed by any non-space
2359                   /x, $str;          # @toks = qw(one two - - - 6 - 8)
2360
2361
2362 =head2 Using independent subexpressions to prevent backtracking
2363
2364 I<Independent subexpressions> are regular expressions, in the
2365 context of a larger regular expression, that function independently of
2366 the larger regular expression.  That is, they consume as much or as
2367 little of the string as they wish without regard for the ability of
2368 the larger regexp to match.  Independent subexpressions are represented
2369 by C<< (?>regexp) >>.  We can illustrate their behavior by first
2370 considering an ordinary regexp:
2371
2372     $x = "ab";
2373     $x =~ /a*ab/;  # matches
2374
2375 This obviously matches, but in the process of matching, the
2376 subexpression C<a*> first grabbed the C<a>.  Doing so, however,
2377 wouldn't allow the whole regexp to match, so after backtracking, C<a*>
2378 eventually gave back the C<a> and matched the empty string.  Here, what
2379 C<a*> matched was I<dependent> on what the rest of the regexp matched.
2380
2381 Contrast that with an independent subexpression:
2382
2383     $x =~ /(?>a*)ab/;  # doesn't match!
2384
2385 The independent subexpression C<< (?>a*) >> doesn't care about the rest
2386 of the regexp, so it sees an C<a> and grabs it.  Then the rest of the
2387 regexp C<ab> cannot match.  Because C<< (?>a*) >> is independent, there
2388 is no backtracking and the independent subexpression does not give
2389 up its C<a>.  Thus the match of the regexp as a whole fails.  A similar
2390 behavior occurs with completely independent regexps:
2391
2392     $x = "ab";
2393     $x =~ /a*/g;   # matches, eats an 'a'
2394     $x =~ /\Gab/g; # doesn't match, no 'a' available
2395
2396 Here C</g> and C<\G> create a 'tag team' handoff of the string from
2397 one regexp to the other.  Regexps with an independent subexpression are
2398 much like this, with a handoff of the string to the independent
2399 subexpression, and a handoff of the string back to the enclosing
2400 regexp.
2401
2402 The ability of an independent subexpression to prevent backtracking
2403 can be quite useful.  Suppose we want to match a non-empty string
2404 enclosed in parentheses up to two levels deep.  Then the following
2405 regexp matches:
2406
2407     $x = "abc(de(fg)h";  # unbalanced parentheses
2408     $x =~ /\( ( [ ^ () ]+ | \( [ ^ () ]* \) )+ \)/xx;
2409
2410 The regexp matches an open parenthesis, one or more copies of an
2411 alternation, and a close parenthesis.  The alternation is two-way, with
2412 the first alternative C<[^()]+> matching a substring with no
2413 parentheses and the second alternative C<\([^()]*\)>  matching a
2414 substring delimited by parentheses.  The problem with this regexp is
2415 that it is pathological: it has nested indeterminate quantifiers
2416 of the form C<(a+|b)+>.  We discussed in Part 1 how nested quantifiers
2417 like this could take an exponentially long time to execute if there
2418 was no match possible.  To prevent the exponential blowup, we need to
2419 prevent useless backtracking at some point.  This can be done by
2420 enclosing the inner quantifier as an independent subexpression:
2421
2422     $x =~ /\( ( (?> [ ^ () ]+ ) | \([ ^ () ]* \) )+ \)/xx;
2423
2424 Here, C<< (?>[^()]+) >> breaks the degeneracy of string partitioning
2425 by gobbling up as much of the string as possible and keeping it.   Then
2426 match failures fail much more quickly.
2427
2428
2429 =head2 Conditional expressions
2430
2431 A I<conditional expression> is a form of if-then-else statement
2432 that allows one to choose which patterns are to be matched, based on
2433 some condition.  There are two types of conditional expression:
2434 C<(?(condition)yes-regexp)> and
2435 C<(?(condition)yes-regexp|no-regexp)>.  C<(?(condition)yes-regexp)> is
2436 like an S<C<'if () {}'>> statement in Perl.  If the C<condition> is true,
2437 the C<yes-regexp> will be matched.  If the C<condition> is false, the
2438 C<yes-regexp> will be skipped and Perl will move onto the next regexp
2439 element.  The second form is like an S<C<'if () {} else {}'>> statement
2440 in Perl.  If the C<condition> is true, the C<yes-regexp> will be
2441 matched, otherwise the C<no-regexp> will be matched.
2442
2443 The C<condition> can have several forms.  The first form is simply an
2444 integer in parentheses C<(integer)>.  It is true if the corresponding
2445 backreference C<\integer> matched earlier in the regexp.  The same
2446 thing can be done with a name associated with a capture group, written
2447 as C<< (<name>) >> or C<< ('name') >>.  The second form is a bare
2448 zero-width assertion C<(?...)>, either a lookahead, a lookbehind, or a
2449 code assertion (discussed in the next section).  The third set of forms
2450 provides tests that return true if the expression is executed within
2451 a recursion (C<(R)>) or is being called from some capturing group,
2452 referenced either by number (C<(R1)>, C<(R2)>,...) or by name
2453 (C<(R&name)>).
2454
2455 The integer or name form of the C<condition> allows us to choose,
2456 with more flexibility, what to match based on what matched earlier in the
2457 regexp. This searches for words of the form C<"$x$x"> or C<"$x$y$y$x">:
2458
2459     % simple_grep '^(\w+)(\w+)?(?(2)\g2\g1|\g1)$' /usr/dict/words
2460     beriberi
2461     coco
2462     couscous
2463     deed
2464     ...
2465     toot
2466     toto
2467     tutu
2468
2469 The lookbehind C<condition> allows, along with backreferences,
2470 an earlier part of the match to influence a later part of the
2471 match.  For instance,
2472
2473     /[ATGC]+(?(?<=AA)G|C)$/;
2474
2475 matches a DNA sequence such that it either ends in C<AAG>, or some
2476 other base pair combination and C<C>.  Note that the form is
2477 C<< (?(?<=AA)G|C) >> and not C<< (?((?<=AA))G|C) >>; for the
2478 lookahead, lookbehind or code assertions, the parentheses around the
2479 conditional are not needed.
2480
2481
2482 =head2 Defining named patterns
2483
2484 Some regular expressions use identical subpatterns in several places.
2485 Starting with Perl 5.10, it is possible to define named subpatterns in
2486 a section of the pattern so that they can be called up by name
2487 anywhere in the pattern.  This syntactic pattern for this definition
2488 group is C<< (?(DEFINE)(?<name>pattern)...) >>.  An insertion
2489 of a named pattern is written as C<(?&name)>.
2490
2491 The example below illustrates this feature using the pattern for
2492 floating point numbers that was presented earlier on.  The three
2493 subpatterns that are used more than once are the optional sign, the
2494 digit sequence for an integer and the decimal fraction.  The DEFINE
2495 group at the end of the pattern contains their definition.  Notice
2496 that the decimal fraction pattern is the first place where we can
2497 reuse the integer pattern.
2498
2499    /^ (?&osg)\ * ( (?&int)(?&dec)? | (?&dec) )
2500       (?: [eE](?&osg)(?&int) )?
2501     $
2502     (?(DEFINE)
2503       (?<osg>[-+]?)         # optional sign
2504       (?<int>\d++)          # integer
2505       (?<dec>\.(?&int))     # decimal fraction
2506     )/x
2507
2508
2509 =head2 Recursive patterns
2510
2511 This feature (introduced in Perl 5.10) significantly extends the
2512 power of Perl's pattern matching.  By referring to some other
2513 capture group anywhere in the pattern with the construct
2514 C<(?group-ref)>, the I<pattern> within the referenced group is used
2515 as an independent subpattern in place of the group reference itself.
2516 Because the group reference may be contained I<within> the group it
2517 refers to, it is now possible to apply pattern matching to tasks that
2518 hitherto required a recursive parser.
2519
2520 To illustrate this feature, we'll design a pattern that matches if
2521 a string contains a palindrome. (This is a word or a sentence that,
2522 while ignoring spaces, interpunctuation and case, reads the same backwards
2523 as forwards. We begin by observing that the empty string or a string
2524 containing just one word character is a palindrome. Otherwise it must
2525 have a word character up front and the same at its end, with another
2526 palindrome in between.
2527
2528     /(?: (\w) (?...Here be a palindrome...) \g{-1} | \w? )/x
2529
2530 Adding C<\W*> at either end to eliminate what is to be ignored, we already
2531 have the full pattern:
2532
2533     my $pp = qr/^(\W* (?: (\w) (?1) \g{-1} | \w? ) \W*)$/ix;
2534     for $s ( "saippuakauppias", "A man, a plan, a canal: Panama!" ){
2535         print "'$s' is a palindrome\n" if $s =~ /$pp/;
2536     }
2537
2538 In C<(?...)> both absolute and relative backreferences may be used.
2539 The entire pattern can be reinserted with C<(?R)> or C<(?0)>.
2540 If you prefer to name your groups, you can use C<(?&name)> to
2541 recurse into that group.
2542
2543
2544 =head2 A bit of magic: executing Perl code in a regular expression
2545
2546 Normally, regexps are a part of Perl expressions.
2547 I<Code evaluation> expressions turn that around by allowing
2548 arbitrary Perl code to be a part of a regexp.  A code evaluation
2549 expression is denoted C<(?{code})>, with I<code> a string of Perl
2550 statements.
2551
2552 Be warned that this feature is considered experimental, and may be
2553 changed without notice.
2554
2555 Code expressions are zero-width assertions, and the value they return
2556 depends on their environment.  There are two possibilities: either the
2557 code expression is used as a conditional in a conditional expression
2558 C<(?(condition)...)>, or it is not.  If the code expression is a
2559 conditional, the code is evaluated and the result (i.e., the result of
2560 the last statement) is used to determine truth or falsehood.  If the
2561 code expression is not used as a conditional, the assertion always
2562 evaluates true and the result is put into the special variable
2563 C<$^R>.  The variable C<$^R> can then be used in code expressions later
2564 in the regexp.  Here are some silly examples:
2565
2566     $x = "abcdef";
2567     $x =~ /abc(?{print "Hi Mom!";})def/; # matches,
2568                                          # prints 'Hi Mom!'
2569     $x =~ /aaa(?{print "Hi Mom!";})def/; # doesn't match,
2570                                          # no 'Hi Mom!'
2571
2572 Pay careful attention to the next example:
2573
2574     $x =~ /abc(?{print "Hi Mom!";})ddd/; # doesn't match,
2575                                          # no 'Hi Mom!'
2576                                          # but why not?
2577
2578 At first glance, you'd think that it shouldn't print, because obviously
2579 the C<ddd> isn't going to match the target string. But look at this
2580 example:
2581
2582     $x =~ /abc(?{print "Hi Mom!";})[dD]dd/; # doesn't match,
2583                                             # but _does_ print
2584
2585 Hmm. What happened here? If you've been following along, you know that
2586 the above pattern should be effectively (almost) the same as the last one;
2587 enclosing the C<d> in a character class isn't going to change what it
2588 matches. So why does the first not print while the second one does?
2589
2590 The answer lies in the optimizations the regex engine makes. In the first
2591 case, all the engine sees are plain old characters (aside from the
2592 C<?{}> construct). It's smart enough to realize that the string 'ddd'
2593 doesn't occur in our target string before actually running the pattern
2594 through. But in the second case, we've tricked it into thinking that our
2595 pattern is more complicated. It takes a look, sees our
2596 character class, and decides that it will have to actually run the
2597 pattern to determine whether or not it matches, and in the process of
2598 running it hits the print statement before it discovers that we don't
2599 have a match.
2600
2601 To take a closer look at how the engine does optimizations, see the
2602 section L</"Pragmas and debugging"> below.
2603
2604 More fun with C<?{}>:
2605
2606     $x =~ /(?{print "Hi Mom!";})/;       # matches,
2607                                          # prints 'Hi Mom!'
2608     $x =~ /(?{$c = 1;})(?{print "$c";})/;  # matches,
2609                                            # prints '1'
2610     $x =~ /(?{$c = 1;})(?{print "$^R";})/; # matches,
2611                                            # prints '1'
2612
2613 The bit of magic mentioned in the section title occurs when the regexp
2614 backtracks in the process of searching for a match.  If the regexp
2615 backtracks over a code expression and if the variables used within are
2616 localized using C<local>, the changes in the variables produced by the
2617 code expression are undone! Thus, if we wanted to count how many times
2618 a character got matched inside a group, we could use, e.g.,
2619
2620     $x = "aaaa";
2621     $count = 0;  # initialize 'a' count
2622     $c = "bob";  # test if $c gets clobbered
2623     $x =~ /(?{local $c = 0;})         # initialize count
2624            ( a                        # match 'a'
2625              (?{local $c = $c + 1;})  # increment count
2626            )*                         # do this any number of times,
2627            aa                         # but match 'aa' at the end
2628            (?{$count = $c;})          # copy local $c var into $count
2629           /x;
2630     print "'a' count is $count, \$c variable is '$c'\n";
2631
2632 This prints
2633
2634     'a' count is 2, $c variable is 'bob'
2635
2636 If we replace the S<C< (?{local $c = $c + 1;})>> with
2637 S<C< (?{$c = $c + 1;})>>, the variable changes are I<not> undone
2638 during backtracking, and we get
2639
2640     'a' count is 4, $c variable is 'bob'
2641
2642 Note that only localized variable changes are undone.  Other side
2643 effects of code expression execution are permanent.  Thus
2644
2645     $x = "aaaa";
2646     $x =~ /(a(?{print "Yow\n";}))*aa/;
2647
2648 produces
2649
2650    Yow
2651    Yow
2652    Yow
2653    Yow
2654
2655 The result C<$^R> is automatically localized, so that it will behave
2656 properly in the presence of backtracking.
2657
2658 This example uses a code expression in a conditional to match a
2659 definite article, either 'the' in English or 'der|die|das' in German:
2660
2661     $lang = 'DE';  # use German
2662     ...
2663     $text = "das";
2664     print "matched\n"
2665         if $text =~ /(?(?{
2666                           $lang eq 'EN'; # is the language English?
2667                          })
2668                        the |             # if so, then match 'the'
2669                        (der|die|das)     # else, match 'der|die|das'
2670                      )
2671                     /xi;
2672
2673 Note that the syntax here is C<(?(?{...})yes-regexp|no-regexp)>, not
2674 C<(?((?{...}))yes-regexp|no-regexp)>.  In other words, in the case of a
2675 code expression, we don't need the extra parentheses around the
2676 conditional.
2677
2678 If you try to use code expressions where the code text is contained within
2679 an interpolated variable, rather than appearing literally in the pattern,
2680 Perl may surprise you:
2681
2682     $bar = 5;
2683     $pat = '(?{ 1 })';
2684     /foo(?{ $bar })bar/; # compiles ok, $bar not interpolated
2685     /foo(?{ 1 })$bar/;   # compiles ok, $bar interpolated
2686     /foo${pat}bar/;      # compile error!
2687
2688     $pat = qr/(?{ $foo = 1 })/;  # precompile code regexp
2689     /foo${pat}bar/;      # compiles ok
2690
2691 If a regexp has a variable that interpolates a code expression, Perl
2692 treats the regexp as an error. If the code expression is precompiled into
2693 a variable, however, interpolating is ok. The question is, why is this an
2694 error?
2695
2696 The reason is that variable interpolation and code expressions
2697 together pose a security risk.  The combination is dangerous because
2698 many programmers who write search engines often take user input and
2699 plug it directly into a regexp:
2700
2701     $regexp = <>;       # read user-supplied regexp
2702     $chomp $regexp;     # get rid of possible newline
2703     $text =~ /$regexp/; # search $text for the $regexp
2704
2705 If the C<$regexp> variable contains a code expression, the user could
2706 then execute arbitrary Perl code.  For instance, some joker could
2707 search for S<C<system('rm -rf *');>> to erase your files.  In this
2708 sense, the combination of interpolation and code expressions I<taints>
2709 your regexp.  So by default, using both interpolation and code
2710 expressions in the same regexp is not allowed.  If you're not
2711 concerned about malicious users, it is possible to bypass this
2712 security check by invoking S<C<use re 'eval'>>:
2713
2714     use re 'eval';       # throw caution out the door
2715     $bar = 5;
2716     $pat = '(?{ 1 })';
2717     /foo${pat}bar/;      # compiles ok
2718
2719 Another form of code expression is the I<pattern code expression>.
2720 The pattern code expression is like a regular code expression, except
2721 that the result of the code evaluation is treated as a regular
2722 expression and matched immediately.  A simple example is
2723
2724     $length = 5;
2725     $char = 'a';
2726     $x = 'aaaaabb';
2727     $x =~ /(??{$char x $length})/x; # matches, there are 5 of 'a'
2728
2729
2730 This final example contains both ordinary and pattern code
2731 expressions.  It detects whether a binary string C<1101010010001...> has a
2732 Fibonacci spacing 0,1,1,2,3,5,...  of the C<1>'s:
2733
2734     $x = "1101010010001000001";
2735     $z0 = ''; $z1 = '0';   # initial conditions
2736     print "It is a Fibonacci sequence\n"
2737         if $x =~ /^1         # match an initial '1'
2738                     (?:
2739                        ((??{ $z0 })) # match some '0'
2740                        1             # and then a '1'
2741                        (?{ $z0 = $z1; $z1 .= $^N; })
2742                     )+   # repeat as needed
2743                   $      # that is all there is
2744                  /x;
2745     printf "Largest sequence matched was %d\n", length($z1)-length($z0);
2746
2747 Remember that C<$^N> is set to whatever was matched by the last
2748 completed capture group. This prints
2749
2750     It is a Fibonacci sequence
2751     Largest sequence matched was 5
2752
2753 Ha! Try that with your garden variety regexp package...
2754
2755 Note that the variables C<$z0> and C<$z1> are not substituted when the
2756 regexp is compiled, as happens for ordinary variables outside a code
2757 expression.  Rather, the whole code block is parsed as perl code at the
2758 same time as perl is compiling the code containing the literal regexp
2759 pattern.
2760
2761 The regexp without the C</x> modifier is
2762
2763     /^1(?:((??{ $z0 }))1(?{ $z0 = $z1; $z1 .= $^N; }))+$/
2764
2765 which shows that spaces are still possible in the code parts. Nevertheless,
2766 when working with code and conditional expressions, the extended form of
2767 regexps is almost necessary in creating and debugging regexps.
2768
2769
2770 =head2 Backtracking control verbs
2771
2772 Perl 5.10 introduced a number of control verbs intended to provide
2773 detailed control over the backtracking process, by directly influencing
2774 the regexp engine and by providing monitoring techniques.  As all
2775 the features in this group are experimental and subject to change or
2776 removal in a future version of Perl, the interested reader is
2777 referred to L<perlre/"Special Backtracking Control Verbs"> for a
2778 detailed description.
2779
2780 Below is just one example, illustrating the control verb C<(*FAIL)>,
2781 which may be abbreviated as C<(*F)>. If this is inserted in a regexp
2782 it will cause it to fail, just as it would at some
2783 mismatch between the pattern and the string. Processing
2784 of the regexp continues as it would after any "normal"
2785 failure, so that, for instance, the next position in the string or another
2786 alternative will be tried. As failing to match doesn't preserve capture
2787 groups or produce results, it may be necessary to use this in
2788 combination with embedded code.
2789
2790    %count = ();
2791    "supercalifragilisticexpialidocious" =~
2792        /([aeiou])(?{ $count{$1}++; })(*FAIL)/i;
2793    printf "%3d '%s'\n", $count{$_}, $_ for (sort keys %count);
2794
2795 The pattern begins with a class matching a subset of letters.  Whenever
2796 this matches, a statement like C<$count{'a'}++;> is executed, incrementing
2797 the letter's counter. Then C<(*FAIL)> does what it says, and
2798 the regexp engine proceeds according to the book: as long as the end of
2799 the string hasn't been reached, the position is advanced before looking
2800 for another vowel. Thus, match or no match makes no difference, and the
2801 regexp engine proceeds until the entire string has been inspected.
2802 (It's remarkable that an alternative solution using something like
2803
2804    $count{lc($_)}++ for split('', "supercalifragilisticexpialidocious");
2805    printf "%3d '%s'\n", $count2{$_}, $_ for ( qw{ a e i o u } );
2806
2807 is considerably slower.)
2808
2809
2810 =head2 Pragmas and debugging
2811
2812 Speaking of debugging, there are several pragmas available to control
2813 and debug regexps in Perl.  We have already encountered one pragma in
2814 the previous section, S<C<use re 'eval';>>, that allows variable
2815 interpolation and code expressions to coexist in a regexp.  The other
2816 pragmas are
2817
2818     use re 'taint';
2819     $tainted = <>;
2820     @parts = ($tainted =~ /(\w+)\s+(\w+)/; # @parts is now tainted
2821
2822 The C<taint> pragma causes any substrings from a match with a tainted
2823 variable to be tainted as well.  This is not normally the case, as
2824 regexps are often used to extract the safe bits from a tainted
2825 variable.  Use C<taint> when you are not extracting safe bits, but are
2826 performing some other processing.  Both C<taint> and C<eval> pragmas
2827 are lexically scoped, which means they are in effect only until
2828 the end of the block enclosing the pragmas.
2829
2830     use re '/m';  # or any other flags
2831     $multiline_string =~ /^foo/; # /m is implied
2832
2833 The C<re '/flags'> pragma (introduced in Perl
2834 5.14) turns on the given regular expression flags
2835 until the end of the lexical scope.  See
2836 L<re/"'E<sol>flags' mode"> for more
2837 detail.
2838
2839     use re 'debug';
2840     /^(.*)$/s;       # output debugging info
2841
2842     use re 'debugcolor';
2843     /^(.*)$/s;       # output debugging info in living color
2844
2845 The global C<debug> and C<debugcolor> pragmas allow one to get
2846 detailed debugging info about regexp compilation and
2847 execution.  C<debugcolor> is the same as debug, except the debugging
2848 information is displayed in color on terminals that can display
2849 termcap color sequences.  Here is example output:
2850
2851     % perl -e 'use re "debug"; "abc" =~ /a*b+c/;'
2852     Compiling REx 'a*b+c'
2853     size 9 first at 1
2854        1: STAR(4)
2855        2:   EXACT <a>(0)
2856        4: PLUS(7)
2857        5:   EXACT <b>(0)
2858        7: EXACT <c>(9)
2859        9: END(0)
2860     floating 'bc' at 0..2147483647 (checking floating) minlen 2
2861     Guessing start of match, REx 'a*b+c' against 'abc'...
2862     Found floating substr 'bc' at offset 1...
2863     Guessed: match at offset 0
2864     Matching REx 'a*b+c' against 'abc'
2865       Setting an EVAL scope, savestack=3
2866        0 <> <abc>           |  1:  STAR
2867                              EXACT <a> can match 1 times out of 32767...
2868       Setting an EVAL scope, savestack=3
2869        1 <a> <bc>           |  4:    PLUS
2870                              EXACT <b> can match 1 times out of 32767...
2871       Setting an EVAL scope, savestack=3
2872        2 <ab> <c>           |  7:      EXACT <c>
2873        3 <abc> <>           |  9:      END
2874     Match successful!
2875     Freeing REx: 'a*b+c'
2876
2877 If you have gotten this far into the tutorial, you can probably guess
2878 what the different parts of the debugging output tell you.  The first
2879 part
2880
2881     Compiling REx 'a*b+c'
2882     size 9 first at 1
2883        1: STAR(4)
2884        2:   EXACT <a>(0)
2885        4: PLUS(7)
2886        5:   EXACT <b>(0)
2887        7: EXACT <c>(9)
2888        9: END(0)
2889
2890 describes the compilation stage.  C<STAR(4)> means that there is a
2891 starred object, in this case C<'a'>, and if it matches, goto line 4,
2892 i.e., C<PLUS(7)>.  The middle lines describe some heuristics and
2893 optimizations performed before a match:
2894
2895     floating 'bc' at 0..2147483647 (checking floating) minlen 2
2896     Guessing start of match, REx 'a*b+c' against 'abc'...
2897     Found floating substr 'bc' at offset 1...
2898     Guessed: match at offset 0
2899
2900 Then the match is executed and the remaining lines describe the
2901 process:
2902
2903     Matching REx 'a*b+c' against 'abc'
2904       Setting an EVAL scope, savestack=3
2905        0 <> <abc>           |  1:  STAR
2906                              EXACT <a> can match 1 times out of 32767...
2907       Setting an EVAL scope, savestack=3
2908        1 <a> <bc>           |  4:    PLUS
2909                              EXACT <b> can match 1 times out of 32767...
2910       Setting an EVAL scope, savestack=3
2911        2 <ab> <c>           |  7:      EXACT <c>
2912        3 <abc> <>           |  9:      END
2913     Match successful!
2914     Freeing REx: 'a*b+c'
2915
2916 Each step is of the form S<C<< n <x> <y> >>>, with C<< <x> >> the
2917 part of the string matched and C<< <y> >> the part not yet
2918 matched.  The S<C<< |  1:  STAR >>> says that Perl is at line number 1
2919 in the compilation list above.  See
2920 L<perldebguts/"Debugging Regular Expressions"> for much more detail.
2921
2922 An alternative method of debugging regexps is to embed C<print>
2923 statements within the regexp.  This provides a blow-by-blow account of
2924 the backtracking in an alternation:
2925
2926     "that this" =~ m@(?{print "Start at position ", pos, "\n";})
2927                      t(?{print "t1\n";})
2928                      h(?{print "h1\n";})
2929                      i(?{print "i1\n";})
2930                      s(?{print "s1\n";})
2931                          |
2932                      t(?{print "t2\n";})
2933                      h(?{print "h2\n";})
2934                      a(?{print "a2\n";})
2935                      t(?{print "t2\n";})
2936                      (?{print "Done at position ", pos, "\n";})
2937                     @x;
2938
2939 prints
2940
2941     Start at position 0
2942     t1
2943     h1
2944     t2
2945     h2
2946     a2
2947     t2
2948     Done at position 4
2949
2950 =head1 BUGS
2951
2952 Code expressions, conditional expressions, and independent expressions
2953 are I<experimental>.  Don't use them in production code.  Yet.
2954
2955 =head1 SEE ALSO
2956
2957 This is just a tutorial.  For the full story on Perl regular
2958 expressions, see the L<perlre> regular expressions reference page.
2959
2960 For more information on the matching C<m//> and substitution C<s///>
2961 operators, see L<perlop/"Regexp Quote-Like Operators">.  For
2962 information on the C<split> operation, see L<perlfunc/split>.
2963
2964 For an excellent all-around resource on the care and feeding of
2965 regular expressions, see the book I<Mastering Regular Expressions> by
2966 Jeffrey Friedl (published by O'Reilly, ISBN 1556592-257-3).
2967
2968 =head1 AUTHOR AND COPYRIGHT
2969
2970 Copyright (c) 2000 Mark Kvale
2971 All rights reserved.
2972
2973 This document may be distributed under the same terms as Perl itself.
2974
2975 =head2 Acknowledgments
2976
2977 The inspiration for the stop codon DNA example came from the ZIP
2978 code example in chapter 7 of I<Mastering Regular Expressions>.
2979
2980 The author would like to thank Jeff Pinyan, Andrew Johnson, Peter
2981 Haworth, Ronald J Kimball, and Joe Smith for all their helpful
2982 comments.
2983
2984 =cut
2985