This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
test.pl: Add skip_without_dynamic_extension
[perl5.git] / t / test.pl
1 #
2 # t/test.pl - most of Test::More functionality without the fuss, plus
3 # has mappings native_to_latin1 and latin1_to_native so that fewer tests
4 # on non ASCII-ish platforms need to be skipped
5
6
7 # NOTE:
8 #
9 # Increment ($x++) has a certain amount of cleverness for things like
10 #
11 #   $x = 'zz';
12 #   $x++; # $x eq 'aaa';
13 #
14 # stands more chance of breaking than just a simple
15 #
16 #   $x = $x + 1
17 #
18 # In this file, we use the latter "Baby Perl" approach, and increment
19 # will be worked over by t/op/inc.t
20
21 $Level = 1;
22 my $test = 1;
23 my $planned;
24 my $noplan;
25 my $Perl;       # Safer version of $^X set by which_perl()
26
27 # This defines ASCII/UTF-8 vs EBCDIC/UTF-EBCDIC
28 $::IS_ASCII  = ord 'A' ==  65;
29 $::IS_EBCDIC = ord 'A' == 193;
30
31 $TODO = 0;
32 $NO_ENDING = 0;
33 $Tests_Are_Passing = 1;
34
35 # Use this instead of print to avoid interference while testing globals.
36 sub _print {
37     local($\, $", $,) = (undef, ' ', '');
38     print STDOUT @_;
39 }
40
41 sub _print_stderr {
42     local($\, $", $,) = (undef, ' ', '');
43     print STDERR @_;
44 }
45
46 sub plan {
47     my $n;
48     if (@_ == 1) {
49         $n = shift;
50         if ($n eq 'no_plan') {
51           undef $n;
52           $noplan = 1;
53         }
54     } else {
55         my %plan = @_;
56         $n = $plan{tests};
57     }
58     _print "1..$n\n" unless $noplan;
59     $planned = $n;
60 }
61
62
63 # Set the plan at the end.  See Test::More::done_testing.
64 sub done_testing {
65     my $n = $test - 1;
66     $n = shift if @_;
67
68     _print "1..$n\n";
69     $planned = $n;
70 }
71
72
73 END {
74     my $ran = $test - 1;
75     if (!$NO_ENDING) {
76         if (defined $planned && $planned != $ran) {
77             _print_stderr
78                 "# Looks like you planned $planned tests but ran $ran.\n";
79         } elsif ($noplan) {
80             _print "1..$ran\n";
81         }
82     }
83 }
84
85 sub _diag {
86     return unless @_;
87     my @mess = _comment(@_);
88     $TODO ? _print(@mess) : _print_stderr(@mess);
89 }
90
91 # Use this instead of "print STDERR" when outputting failure diagnostic
92 # messages
93 sub diag {
94     _diag(@_);
95 }
96
97 # Use this instead of "print" when outputting informational messages
98 sub note {
99     return unless @_;
100     _print( _comment(@_) );
101 }
102
103 sub is_miniperl {
104     return !defined &DynaLoader::boot_DynaLoader;
105 }
106
107 sub _comment {
108     return map { /^#/ ? "$_\n" : "# $_\n" }
109            map { split /\n/ } @_;
110 }
111
112 sub _have_dynamic_extension {
113     my $extension = shift;
114     unless (eval {require Config; 1}) {
115         warn "test.pl had problems loading Config: $@";
116         return 1;
117     }
118     $extension =~ s!::!/!g;
119     return 1 if ($Config::Config{extensions} =~ /\b$extension\b/);
120 }
121
122 sub skip_all {
123     if (@_) {
124         _print "1..0 # Skip @_\n";
125     } else {
126         _print "1..0\n";
127     }
128     exit(0);
129 }
130
131 sub skip_all_if_miniperl {
132     skip_all(@_) if is_miniperl();
133 }
134
135 sub skip_all_without_dynamic_extension {
136     my ($extension) = @_;
137     skip_all("no dynamic loading on miniperl, no $extension") if is_miniperl();
138     return if &_have_dynamic_extension;
139     skip_all("$extension was not built");
140 }
141
142 sub skip_all_without_perlio {
143     skip_all('no PerlIO') unless PerlIO::Layer->find('perlio');
144 }
145
146 sub skip_all_without_config {
147     unless (eval {require Config; 1}) {
148         warn "test.pl had problems loading Config: $@";
149         return;
150     }
151     foreach (@_) {
152         next if $Config::Config{$_};
153         my $key = $_; # Need to copy, before trying to modify.
154         $key =~ s/^use//;
155         $key =~ s/^d_//;
156         skip_all("no $key");
157     }
158 }
159
160 sub find_git_or_skip {
161     my ($source_dir, $reason);
162     if (-d '.git') {
163         $source_dir = '.';
164     } elsif (-l 'MANIFEST' && -l 'AUTHORS') {
165         my $where = readlink 'MANIFEST';
166         die "Can't readling MANIFEST: $!" unless defined $where;
167         die "Confusing symlink target for MANIFEST, '$where'"
168             unless $where =~ s!/MANIFEST\z!!;
169         if (-d "$where/.git") {
170             # Looks like we are in a symlink tree
171             if (exists $ENV{GIT_DIR}) {
172                 diag("Found source tree at $where, but \$ENV{GIT_DIR} is $ENV{GIT_DIR}. Not changing it");
173             } else {
174                 note("Found source tree at $where, setting \$ENV{GIT_DIR}");
175                 $ENV{GIT_DIR} = "$where/.git";
176             }
177             $source_dir = $where;
178         }
179     }
180     if ($source_dir) {
181         my $version_string = `git --version`;
182         if (defined $version_string
183               && $version_string =~ /\Agit version (\d+\.\d+\.\d+)(.*)/) {
184             return $source_dir if eval "v$1 ge v1.5.0";
185             # If you have earlier than 1.5.0 and it works, change this test
186             $reason = "in git checkout, but git version '$1$2' too old";
187         } else {
188             $reason = "in git checkout, but cannot run git";
189         }
190     } else {
191         $reason = 'not being run from a git checkout';
192     }
193     skip_all($reason) if $_[0] && $_[0] eq 'all';
194     skip($reason, @_);
195 }
196
197 sub BAIL_OUT {
198     my ($reason) = @_;
199     _print("Bail out!  $reason\n");
200     exit 255;
201 }
202
203 sub _ok {
204     my ($pass, $where, $name, @mess) = @_;
205     # Do not try to microoptimize by factoring out the "not ".
206     # VMS will avenge.
207     my $out;
208     if ($name) {
209         # escape out '#' or it will interfere with '# skip' and such
210         $name =~ s/#/\\#/g;
211         $out = $pass ? "ok $test - $name" : "not ok $test - $name";
212     } else {
213         $out = $pass ? "ok $test" : "not ok $test";
214     }
215
216     if ($TODO) {
217         $out = $out . " # TODO $TODO";
218     } else {
219         $Tests_Are_Passing = 0 unless $pass;
220     }
221
222     _print "$out\n";
223
224     if ($pass) {
225         note @mess; # Ensure that the message is properly escaped.
226     }
227     else {
228         my $msg = "# Failed test $test - ";
229         $msg.= "$name " if $name;
230         $msg .= "$where\n";
231         _diag $msg;
232         _diag @mess;
233     }
234
235     $test = $test + 1; # don't use ++
236
237     return $pass;
238 }
239
240 sub _where {
241     my @caller = caller($Level);
242     return "at $caller[1] line $caller[2]";
243 }
244
245 # DON'T use this for matches. Use like() instead.
246 sub ok ($@) {
247     my ($pass, $name, @mess) = @_;
248     _ok($pass, _where(), $name, @mess);
249 }
250
251 sub _q {
252     my $x = shift;
253     return 'undef' unless defined $x;
254     my $q = $x;
255     $q =~ s/\\/\\\\/g;
256     $q =~ s/'/\\'/g;
257     return "'$q'";
258 }
259
260 sub _qq {
261     my $x = shift;
262     return defined $x ? '"' . display ($x) . '"' : 'undef';
263 };
264
265 # keys are the codes \n etc map to, values are 2 char strings such as \n
266 my %backslash_escape;
267 foreach my $x (split //, 'nrtfa\\\'"') {
268     $backslash_escape{ord eval "\"\\$x\""} = "\\$x";
269 }
270 # A way to display scalars containing control characters and Unicode.
271 # Trying to avoid setting $_, or relying on local $_ to work.
272 sub display {
273     my @result;
274     foreach my $x (@_) {
275         if (defined $x and not ref $x) {
276             my $y = '';
277             foreach my $c (unpack("U*", $x)) {
278                 if ($c > 255) {
279                     $y = $y . sprintf "\\x{%x}", $c;
280                 } elsif ($backslash_escape{$c}) {
281                     $y = $y . $backslash_escape{$c};
282                 } else {
283                     my $z = chr $c; # Maybe we can get away with a literal...
284                     if ($z =~ /[[:^print:]]/) {
285
286                         # Use octal for characters traditionally expressed as
287                         # such: the low controls
288                         if ($c <= 037) {
289                             $z = sprintf "\\%03o", $c;
290                         } else {
291                             $z = sprintf "\\x{%x}", $c;
292                         }
293                     }
294                     $y = $y . $z;
295                 }
296             }
297             $x = $y;
298         }
299         return $x unless wantarray;
300         push @result, $x;
301     }
302     return @result;
303 }
304
305 sub is ($$@) {
306     my ($got, $expected, $name, @mess) = @_;
307
308     my $pass;
309     if( !defined $got || !defined $expected ) {
310         # undef only matches undef
311         $pass = !defined $got && !defined $expected;
312     }
313     else {
314         $pass = $got eq $expected;
315     }
316
317     unless ($pass) {
318         unshift(@mess, "#      got "._qq($got)."\n",
319                        "# expected "._qq($expected)."\n");
320     }
321     _ok($pass, _where(), $name, @mess);
322 }
323
324 sub isnt ($$@) {
325     my ($got, $isnt, $name, @mess) = @_;
326
327     my $pass;
328     if( !defined $got || !defined $isnt ) {
329         # undef only matches undef
330         $pass = defined $got || defined $isnt;
331     }
332     else {
333         $pass = $got ne $isnt;
334     }
335
336     unless( $pass ) {
337         unshift(@mess, "# it should not be "._qq($got)."\n",
338                        "# but it is.\n");
339     }
340     _ok($pass, _where(), $name, @mess);
341 }
342
343 sub cmp_ok ($$$@) {
344     my($got, $type, $expected, $name, @mess) = @_;
345
346     my $pass;
347     {
348         local $^W = 0;
349         local($@,$!);   # don't interfere with $@
350                         # eval() sometimes resets $!
351         $pass = eval "\$got $type \$expected";
352     }
353     unless ($pass) {
354         # It seems Irix long doubles can have 2147483648 and 2147483648
355         # that stringify to the same thing but are actually numerically
356         # different. Display the numbers if $type isn't a string operator,
357         # and the numbers are stringwise the same.
358         # (all string operators have alphabetic names, so tr/a-z// is true)
359         # This will also show numbers for some unneeded cases, but will
360         # definitely be helpful for things such as == and <= that fail
361         if ($got eq $expected and $type !~ tr/a-z//) {
362             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
363         }
364         unshift(@mess, "#      got "._qq($got)."\n",
365                        "# expected $type "._qq($expected)."\n");
366     }
367     _ok($pass, _where(), $name, @mess);
368 }
369
370 # Check that $got is within $range of $expected
371 # if $range is 0, then check it's exact
372 # else if $expected is 0, then $range is an absolute value
373 # otherwise $range is a fractional error.
374 # Here $range must be numeric, >= 0
375 # Non numeric ranges might be a useful future extension. (eg %)
376 sub within ($$$@) {
377     my ($got, $expected, $range, $name, @mess) = @_;
378     my $pass;
379     if (!defined $got or !defined $expected or !defined $range) {
380         # This is a fail, but doesn't need extra diagnostics
381     } elsif ($got !~ tr/0-9// or $expected !~ tr/0-9// or $range !~ tr/0-9//) {
382         # This is a fail
383         unshift @mess, "# got, expected and range must be numeric\n";
384     } elsif ($range < 0) {
385         # This is also a fail
386         unshift @mess, "# range must not be negative\n";
387     } elsif ($range == 0) {
388         # Within 0 is ==
389         $pass = $got == $expected;
390     } elsif ($expected == 0) {
391         # If expected is 0, treat range as absolute
392         $pass = ($got <= $range) && ($got >= - $range);
393     } else {
394         my $diff = $got - $expected;
395         $pass = abs ($diff / $expected) < $range;
396     }
397     unless ($pass) {
398         if ($got eq $expected) {
399             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
400         }
401         unshift@mess, "#      got "._qq($got)."\n",
402                       "# expected "._qq($expected)." (within "._qq($range).")\n";
403     }
404     _ok($pass, _where(), $name, @mess);
405 }
406
407 # Note: this isn't quite as fancy as Test::More::like().
408
409 sub like   ($$@) { like_yn (0,@_) }; # 0 for -
410 sub unlike ($$@) { like_yn (1,@_) }; # 1 for un-
411
412 sub like_yn ($$$@) {
413     my ($flip, undef, $expected, $name, @mess) = @_;
414     my $pass;
415     $pass = $_[1] =~ /$expected/ if !$flip;
416     $pass = $_[1] !~ /$expected/ if $flip;
417     unless ($pass) {
418         unshift(@mess, "#      got '$_[1]'\n",
419                 $flip
420                 ? "# expected !~ /$expected/\n" : "# expected /$expected/\n");
421     }
422     local $Level = $Level + 1;
423     _ok($pass, _where(), $name, @mess);
424 }
425
426 sub pass {
427     _ok(1, '', @_);
428 }
429
430 sub fail {
431     _ok(0, _where(), @_);
432 }
433
434 sub curr_test {
435     $test = shift if @_;
436     return $test;
437 }
438
439 sub next_test {
440   my $retval = $test;
441   $test = $test + 1; # don't use ++
442   $retval;
443 }
444
445 # Note: can't pass multipart messages since we try to
446 # be compatible with Test::More::skip().
447 sub skip {
448     my $why = shift;
449     my $n    = @_ ? shift : 1;
450     for (1..$n) {
451         _print "ok $test # skip $why\n";
452         $test = $test + 1;
453     }
454     local $^W = 0;
455     last SKIP;
456 }
457
458 sub skip_if_miniperl {
459     skip(@_) if is_miniperl();
460 }
461
462 sub skip_without_dynamic_extension {
463     my ($extension) = @_;
464     skip("no dynamic loading on miniperl, no $extension") if is_miniperl();
465     return if &_have_dynamic_extension;
466     skip_all("$extension was not built");
467 }
468
469 sub todo_skip {
470     my $why = shift;
471     my $n   = @_ ? shift : 1;
472
473     for (1..$n) {
474         _print "not ok $test # TODO & SKIP $why\n";
475         $test = $test + 1;
476     }
477     local $^W = 0;
478     last TODO;
479 }
480
481 sub eq_array {
482     my ($ra, $rb) = @_;
483     return 0 unless $#$ra == $#$rb;
484     for my $i (0..$#$ra) {
485         next     if !defined $ra->[$i] && !defined $rb->[$i];
486         return 0 if !defined $ra->[$i];
487         return 0 if !defined $rb->[$i];
488         return 0 unless $ra->[$i] eq $rb->[$i];
489     }
490     return 1;
491 }
492
493 sub eq_hash {
494   my ($orig, $suspect) = @_;
495   my $fail;
496   while (my ($key, $value) = each %$suspect) {
497     # Force a hash recompute if this perl's internals can cache the hash key.
498     $key = "" . $key;
499     if (exists $orig->{$key}) {
500       if ($orig->{$key} ne $value) {
501         _print "# key ", _qq($key), " was ", _qq($orig->{$key}),
502                      " now ", _qq($value), "\n";
503         $fail = 1;
504       }
505     } else {
506       _print "# key ", _qq($key), " is ", _qq($value),
507                    ", not in original.\n";
508       $fail = 1;
509     }
510   }
511   foreach (keys %$orig) {
512     # Force a hash recompute if this perl's internals can cache the hash key.
513     $_ = "" . $_;
514     next if (exists $suspect->{$_});
515     _print "# key ", _qq($_), " was ", _qq($orig->{$_}), " now missing.\n";
516     $fail = 1;
517   }
518   !$fail;
519 }
520
521 # We only provide a subset of the Test::More functionality.
522 sub require_ok ($) {
523     my ($require) = @_;
524     if ($require =~ tr/[A-Za-z0-9:.]//c) {
525         fail("Invalid character in \"$require\", passed to require_ok");
526     } else {
527         eval <<REQUIRE_OK;
528 require $require;
529 REQUIRE_OK
530         is($@, '', _where(), "require $require");
531     }
532 }
533
534 sub use_ok ($) {
535     my ($use) = @_;
536     if ($use =~ tr/[A-Za-z0-9:.]//c) {
537         fail("Invalid character in \"$use\", passed to use");
538     } else {
539         eval <<USE_OK;
540 use $use;
541 USE_OK
542         is($@, '', _where(), "use $use");
543     }
544 }
545
546 # runperl - Runs a separate perl interpreter.
547 # Arguments :
548 #   switches => [ command-line switches ]
549 #   nolib    => 1 # don't use -I../lib (included by default)
550 #   non_portable => Don't warn if a one liner contains quotes
551 #   prog     => one-liner (avoid quotes)
552 #   progs    => [ multi-liner (avoid quotes) ]
553 #   progfile => perl script
554 #   stdin    => string to feed the stdin
555 #   stderr   => redirect stderr to stdout
556 #   args     => [ command-line arguments to the perl program ]
557 #   verbose  => print the command line
558
559 my $is_mswin    = $^O eq 'MSWin32';
560 my $is_netware  = $^O eq 'NetWare';
561 my $is_vms      = $^O eq 'VMS';
562 my $is_cygwin   = $^O eq 'cygwin';
563
564 sub _quote_args {
565     my ($runperl, $args) = @_;
566
567     foreach (@$args) {
568         # In VMS protect with doublequotes because otherwise
569         # DCL will lowercase -- unless already doublequoted.
570        $_ = q(").$_.q(") if $is_vms && !/^\"/ && length($_) > 0;
571        $runperl = $runperl . ' ' . $_;
572     }
573     return $runperl;
574 }
575
576 sub _create_runperl { # Create the string to qx in runperl().
577     my %args = @_;
578     my $runperl = which_perl();
579     if ($runperl =~ m/\s/) {
580         $runperl = qq{"$runperl"};
581     }
582     #- this allows, for example, to set PERL_RUNPERL_DEBUG=/usr/bin/valgrind
583     if ($ENV{PERL_RUNPERL_DEBUG}) {
584         $runperl = "$ENV{PERL_RUNPERL_DEBUG} $runperl";
585     }
586     unless ($args{nolib}) {
587         $runperl = $runperl . ' "-I../lib"'; # doublequotes because of VMS
588     }
589     if ($args{switches}) {
590         local $Level = 2;
591         die "test.pl:runperl(): 'switches' must be an ARRAYREF " . _where()
592             unless ref $args{switches} eq "ARRAY";
593         $runperl = _quote_args($runperl, $args{switches});
594     }
595     if (defined $args{prog}) {
596         die "test.pl:runperl(): both 'prog' and 'progs' cannot be used " . _where()
597             if defined $args{progs};
598         $args{progs} = [$args{prog}]
599     }
600     if (defined $args{progs}) {
601         die "test.pl:runperl(): 'progs' must be an ARRAYREF " . _where()
602             unless ref $args{progs} eq "ARRAY";
603         foreach my $prog (@{$args{progs}}) {
604             if ($prog =~ tr/'"// && !$args{non_portable}) {
605                 warn "quotes in prog >>$prog<< are not portable";
606             }
607             if ($is_mswin || $is_netware || $is_vms) {
608                 $runperl = $runperl . qq ( -e "$prog" );
609             }
610             else {
611                 $runperl = $runperl . qq ( -e '$prog' );
612             }
613         }
614     } elsif (defined $args{progfile}) {
615         $runperl = $runperl . qq( "$args{progfile}");
616     } else {
617         # You probably didn't want to be sucking in from the upstream stdin
618         die "test.pl:runperl(): none of prog, progs, progfile, args, "
619             . " switches or stdin specified"
620             unless defined $args{args} or defined $args{switches}
621                 or defined $args{stdin};
622     }
623     if (defined $args{stdin}) {
624         # so we don't try to put literal newlines and crs onto the
625         # command line.
626         $args{stdin} =~ s/\n/\\n/g;
627         $args{stdin} =~ s/\r/\\r/g;
628
629         if ($is_mswin || $is_netware || $is_vms) {
630             $runperl = qq{$Perl -e "print qq(} .
631                 $args{stdin} . q{)" | } . $runperl;
632         }
633         else {
634             $runperl = qq{$Perl -e 'print qq(} .
635                 $args{stdin} . q{)' | } . $runperl;
636         }
637     }
638     if (defined $args{args}) {
639         $runperl = _quote_args($runperl, $args{args});
640     }
641     $runperl = $runperl . ' 2>&1' if $args{stderr};
642     if ($args{verbose}) {
643         my $runperldisplay = $runperl;
644         $runperldisplay =~ s/\n/\n\#/g;
645         _print_stderr "# $runperldisplay\n";
646     }
647     return $runperl;
648 }
649
650 sub runperl {
651     die "test.pl:runperl() does not take a hashref"
652         if ref $_[0] and ref $_[0] eq 'HASH';
653     my $runperl = &_create_runperl;
654     my $result;
655
656     my $tainted = ${^TAINT};
657     my %args = @_;
658     exists $args{switches} && grep m/^-T$/, @{$args{switches}} and $tainted = $tainted + 1;
659
660     if ($tainted) {
661         # We will assume that if you're running under -T, you really mean to
662         # run a fresh perl, so we'll brute force launder everything for you
663         my $sep;
664
665         if (! eval {require Config; 1}) {
666             warn "test.pl had problems loading Config: $@";
667             $sep = ':';
668         } else {
669             $sep = $Config::Config{path_sep};
670         }
671
672         my @keys = grep {exists $ENV{$_}} qw(CDPATH IFS ENV BASH_ENV);
673         local @ENV{@keys} = ();
674         # Untaint, plus take out . and empty string:
675         local $ENV{'DCL$PATH'} = $1 if $is_vms && exists($ENV{'DCL$PATH'}) && ($ENV{'DCL$PATH'} =~ /(.*)/s);
676         $ENV{PATH} =~ /(.*)/s;
677         local $ENV{PATH} =
678             join $sep, grep { $_ ne "" and $_ ne "." and -d $_ and
679                 ($is_mswin or $is_vms or !(stat && (stat _)[2]&0022)) }
680                     split quotemeta ($sep), $1;
681         if ($is_cygwin) {   # Must have /bin under Cygwin
682             if (length $ENV{PATH}) {
683                 $ENV{PATH} = $ENV{PATH} . $sep;
684             }
685             $ENV{PATH} = $ENV{PATH} . '/bin';
686         }
687         $runperl =~ /(.*)/s;
688         $runperl = $1;
689
690         $result = `$runperl`;
691     } else {
692         $result = `$runperl`;
693     }
694     $result =~ s/\n\n/\n/ if $is_vms; # XXX pipes sometimes double these
695     return $result;
696 }
697
698 # Nice alias
699 *run_perl = *run_perl = \&runperl; # shut up "used only once" warning
700
701 sub DIE {
702     _print_stderr "# @_\n";
703     exit 1;
704 }
705
706 # A somewhat safer version of the sometimes wrong $^X.
707 sub which_perl {
708     unless (defined $Perl) {
709         $Perl = $^X;
710
711         # VMS should have 'perl' aliased properly
712         return $Perl if $is_vms;
713
714         my $exe;
715         if (! eval {require Config; 1}) {
716             warn "test.pl had problems loading Config: $@";
717             $exe = '';
718         } else {
719             $exe = $Config::Config{_exe};
720         }
721        $exe = '' unless defined $exe;
722
723         # This doesn't absolutize the path: beware of future chdirs().
724         # We could do File::Spec->abs2rel() but that does getcwd()s,
725         # which is a bit heavyweight to do here.
726
727         if ($Perl =~ /^perl\Q$exe\E$/i) {
728             my $perl = "perl$exe";
729             if (! eval {require File::Spec; 1}) {
730                 warn "test.pl had problems loading File::Spec: $@";
731                 $Perl = "./$perl";
732             } else {
733                 $Perl = File::Spec->catfile(File::Spec->curdir(), $perl);
734             }
735         }
736
737         # Build up the name of the executable file from the name of
738         # the command.
739
740         if ($Perl !~ /\Q$exe\E$/i) {
741             $Perl = $Perl . $exe;
742         }
743
744         warn "which_perl: cannot find $Perl from $^X" unless -f $Perl;
745
746         # For subcommands to use.
747         $ENV{PERLEXE} = $Perl;
748     }
749     return $Perl;
750 }
751
752 sub unlink_all {
753     my $count = 0;
754     foreach my $file (@_) {
755         1 while unlink $file;
756         if( -f $file ){
757             _print_stderr "# Couldn't unlink '$file': $!\n";
758         }else{
759             ++$count;
760         }
761     }
762     $count;
763 }
764
765 my %tmpfiles;
766 END { unlink_all keys %tmpfiles }
767
768 # A regexp that matches the tempfile names
769 $::tempfile_regexp = 'tmp\d+[A-Z][A-Z]?';
770
771 # Avoid ++, avoid ranges, avoid split //
772 my @letters = qw(A B C D E F G H I J K L M N O P Q R S T U V W X Y Z);
773 sub tempfile {
774     my $count = 0;
775     do {
776         my $temp = $count;
777         my $try = "tmp$$";
778         do {
779             $try = $try . $letters[$temp % 26];
780             $temp = int ($temp / 26);
781         } while $temp;
782         # Need to note all the file names we allocated, as a second request may
783         # come before the first is created.
784         if (!-e $try && !$tmpfiles{$try}) {
785             # We have a winner
786             $tmpfiles{$try} = 1;
787             return $try;
788         }
789         $count = $count + 1;
790     } while $count < 26 * 26;
791     die "Can't find temporary file name starting 'tmp$$'";
792 }
793
794 # This is the temporary file for _fresh_perl
795 my $tmpfile = tempfile();
796
797 sub _fresh_perl {
798     my($prog, $action, $expect, $runperl_args, $name) = @_;
799
800     # Given the choice of the mis-parsable {}
801     # (we want an anon hash, but a borked lexer might think that it's a block)
802     # or relying on taking a reference to a lexical
803     # (\ might be mis-parsed, and the reference counting on the pad may go
804     #  awry)
805     # it feels like the least-worse thing is to assume that auto-vivification
806     # works. At least, this is only going to be a run-time failure, so won't
807     # affect tests using this file but not this function.
808     $runperl_args->{progfile} ||= $tmpfile;
809     $runperl_args->{stderr}     = 1 unless exists $runperl_args->{stderr};
810
811     open TEST, ">$tmpfile" or die "Cannot open $tmpfile: $!";
812
813     # VMS adjustments
814     if( $is_vms ) {
815         $prog =~ s#/dev/null#NL:#;
816
817         # VMS file locking
818         $prog =~ s{if \(-e _ and -f _ and -r _\)}
819                   {if (-e _ and -f _)}
820     }
821
822     print TEST $prog;
823     close TEST or die "Cannot close $tmpfile: $!";
824
825     my $results = runperl(%$runperl_args);
826     my $status = $?;
827
828     # Clean up the results into something a bit more predictable.
829     $results  =~ s/\n+$//;
830     $results =~ s/at\s+$::tempfile_regexp\s+line/at - line/g;
831     $results =~ s/of\s+$::tempfile_regexp\s+aborted/of - aborted/g;
832
833     # bison says 'parse error' instead of 'syntax error',
834     # various yaccs may or may not capitalize 'syntax'.
835     $results =~ s/^(syntax|parse) error/syntax error/mig;
836
837     if ($is_vms) {
838         # some tests will trigger VMS messages that won't be expected
839         $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
840
841         # pipes double these sometimes
842         $results =~ s/\n\n/\n/g;
843     }
844
845     # Use the first line of the program as a name if none was given
846     unless( $name ) {
847         ($first_line, $name) = $prog =~ /^((.{1,50}).*)/;
848         $name = $name . '...' if length $first_line > length $name;
849     }
850
851     # Historically this was implemented using a closure, but then that means
852     # that the tests for closures avoid using this code. Given that there
853     # are exactly two callers, doing exactly two things, the simpler approach
854     # feels like a better trade off.
855     my $pass;
856     if ($action eq 'eq') {
857         $pass = is($results, $expect, $name);
858     } elsif ($action eq '=~') {
859         $pass = like($results, $expect, $name);
860     } else {
861         die "_fresh_perl can't process action '$action'";
862     }
863         
864     unless ($pass) {
865         _diag "# PROG: \n$prog\n";
866         _diag "# STATUS: $status\n";
867     }
868
869     return $pass;
870 }
871
872 #
873 # fresh_perl_is
874 #
875 # Combination of run_perl() and is().
876 #
877
878 sub fresh_perl_is {
879     my($prog, $expected, $runperl_args, $name) = @_;
880
881     # _fresh_perl() is going to clip the trailing newlines off the result.
882     # This will make it so the test author doesn't have to know that.
883     $expected =~ s/\n+$//;
884
885     local $Level = 2;
886     _fresh_perl($prog, 'eq', $expected, $runperl_args, $name);
887 }
888
889 #
890 # fresh_perl_like
891 #
892 # Combination of run_perl() and like().
893 #
894
895 sub fresh_perl_like {
896     my($prog, $expected, $runperl_args, $name) = @_;
897     local $Level = 2;
898     _fresh_perl($prog, '=~', $expected, $runperl_args, $name);
899 }
900
901 # Many tests use the same format in __DATA__ or external files to specify a
902 # sequence of (fresh) tests to run, extra files they may temporarily need, and
903 # what the expected output is. So have excatly one copy of the code to run that
904 #
905 # Each program is source code to run followed by an "EXPECT" line, followed
906 # by the expected output.
907 #
908 # The code to run may contain (note the '# ' on each):
909 #   # TODO reason for todo
910 #   # SKIP reason for skip
911 #   # SKIP ?code to test if this should be skipped
912 #   # NAME name of the test (as with ok($ok, $name))
913 #
914 # The expected output may contain:
915 #   OPTION list of options
916 #   OPTIONS list of options
917 #   PREFIX
918 #     indicates that the supplied output is only a prefix to the
919 #     expected output
920 #
921 # The possible options for OPTION may be:
922 #   regex - the expected output is a regular expression
923 #   random - all lines match but in any order
924 #   fatal - the code will fail fatally (croak, die)
925 #
926 # If the actual output contains a line "SKIPPED" the test will be
927 # skipped.
928 #
929 # If the global variable $FATAL is true then OPTION fatal is the
930 # default.
931
932 sub run_multiple_progs {
933     my $up = shift;
934     my @prgs;
935     if ($up) {
936         # The tests in lib run in a temporary subdirectory of t, and always
937         # pass in a list of "programs" to run
938         @prgs = @_;
939     } else {
940         # The tests below t run in t and pass in a file handle.
941         my $fh = shift;
942         local $/;
943         @prgs = split "\n########\n", <$fh>;
944     }
945
946     my $tmpfile = tempfile();
947
948     for (@prgs){
949         unless (/\n/) {
950             print "# From $_\n";
951             next;
952         }
953         my $switch = "";
954         my @temps ;
955         my @temp_path;
956         if (s/^(\s*-\w+)//) {
957             $switch = $1;
958         }
959         my ($prog, $expected) = split(/\nEXPECT(?:\n|$)/, $_, 2);
960
961         my %reason;
962         foreach my $what (qw(skip todo)) {
963             $prog =~ s/^#\s*\U$what\E\s*(.*)\n//m and $reason{$what} = $1;
964             # If the SKIP reason starts ? then it's taken as a code snippet to
965             # evaluate. This provides the flexibility to have conditional SKIPs
966             if ($reason{$what} && $reason{$what} =~ s/^\?//) {
967                 my $temp = eval $reason{$what};
968                 if ($@) {
969                     die "# In \U$what\E code reason:\n# $reason{$what}\n$@";
970                 }
971                 $reason{$what} = $temp;
972             }
973         }
974         my $name = '';
975         if ($prog =~ s/^#\s*NAME\s+(.+)\n//m) {
976             $name = $1;
977         }
978
979         if ($prog =~ /--FILE--/) {
980             my @files = split(/\n--FILE--\s*([^\s\n]*)\s*\n/, $prog) ;
981             shift @files ;
982             die "Internal error: test $_ didn't split into pairs, got " .
983                 scalar(@files) . "[" . join("%%%%", @files) ."]\n"
984                     if @files % 2;
985             while (@files > 2) {
986                 my $filename = shift @files;
987                 my $code = shift @files;
988                 push @temps, $filename;
989                 if ($filename =~ m#(.*)/# && $filename !~ m#^\.\./#) {
990                     require File::Path;
991                     File::Path::mkpath($1);
992                     push(@temp_path, $1);
993                 }
994                 open my $fh, '>', $filename or die "Cannot open $filename: $!\n";
995                 print $fh $code;
996                 close $fh or die "Cannot close $filename: $!\n";
997             }
998             shift @files;
999             $prog = shift @files;
1000         }
1001
1002         open my $fh, '>', $tmpfile or die "Cannot open >$tmpfile: $!";
1003         print $fh q{
1004         BEGIN {
1005             open STDERR, '>&', STDOUT
1006               or die "Can't dup STDOUT->STDERR: $!;";
1007         }
1008         };
1009         print $fh "\n#line 1\n";  # So the line numbers don't get messed up.
1010         print $fh $prog,"\n";
1011         close $fh or die "Cannot close $tmpfile: $!";
1012         my $results = runperl( stderr => 1, progfile => $tmpfile, $up
1013                                ? (switches => ["-I$up/lib", $switch], nolib => 1)
1014                                : (switches => [$switch])
1015                                 );
1016         my $status = $?;
1017         $results =~ s/\n+$//;
1018         # allow expected output to be written as if $prog is on STDIN
1019         $results =~ s/$::tempfile_regexp/-/g;
1020         if ($^O eq 'VMS') {
1021             # some tests will trigger VMS messages that won't be expected
1022             $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
1023
1024             # pipes double these sometimes
1025             $results =~ s/\n\n/\n/g;
1026         }
1027         # bison says 'parse error' instead of 'syntax error',
1028         # various yaccs may or may not capitalize 'syntax'.
1029         $results =~ s/^(syntax|parse) error/syntax error/mig;
1030         # allow all tests to run when there are leaks
1031         $results =~ s/Scalars leaked: \d+\n//g;
1032
1033         $expected =~ s/\n+$//;
1034         my $prefix = ($results =~ s#^PREFIX(\n|$)##) ;
1035         # any special options? (OPTIONS foo bar zap)
1036         my $option_regex = 0;
1037         my $option_random = 0;
1038         my $fatal = $FATAL;
1039         if ($expected =~ s/^OPTIONS? (.+)\n//) {
1040             foreach my $option (split(' ', $1)) {
1041                 if ($option eq 'regex') { # allow regular expressions
1042                     $option_regex = 1;
1043                 }
1044                 elsif ($option eq 'random') { # all lines match, but in any order
1045                     $option_random = 1;
1046                 }
1047                 elsif ($option eq 'fatal') { # perl should fail
1048                     $fatal = 1;
1049                 }
1050                 else {
1051                     die "$0: Unknown OPTION '$option'\n";
1052                 }
1053             }
1054         }
1055         die "$0: can't have OPTION regex and random\n"
1056             if $option_regex + $option_random > 1;
1057         my $ok = 0;
1058         if ($results =~ s/^SKIPPED\n//) {
1059             print "$results\n" ;
1060             $ok = 1;
1061         }
1062         else {
1063             if ($option_random) {
1064                 my @got = sort split "\n", $results;
1065                 my @expected = sort split "\n", $expected;
1066
1067                 $ok = "@got" eq "@expected";
1068             }
1069             elsif ($option_regex) {
1070                 $ok = $results =~ /^$expected/;
1071             }
1072             elsif ($prefix) {
1073                 $ok = $results =~ /^\Q$expected/;
1074             }
1075             else {
1076                 $ok = $results eq $expected;
1077             }
1078
1079             if ($ok && $fatal && !($status >> 8)) {
1080                 $ok = 0;
1081             }
1082         }
1083
1084         local $::TODO = $reason{todo};
1085
1086         unless ($ok) {
1087             my $err_line = "PROG: $switch\n$prog\n" .
1088                            "EXPECTED:\n$expected\n";
1089             $err_line   .= "EXIT STATUS: != 0\n" if $fatal;
1090             $err_line   .= "GOT:\n$results\n";
1091             $err_line   .= "EXIT STATUS: " . ($status >> 8) . "\n" if $fatal;
1092             if ($::TODO) {
1093                 $err_line =~ s/^/# /mg;
1094                 print $err_line;  # Harness can't filter it out from STDERR.
1095             }
1096             else {
1097                 print STDERR $err_line;
1098             }
1099         }
1100
1101         ok($ok, $name);
1102
1103         foreach (@temps) {
1104             unlink $_ if $_;
1105         }
1106         foreach (@temp_path) {
1107             File::Path::rmtree $_ if -d $_;
1108         }
1109     }
1110 }
1111
1112 sub can_ok ($@) {
1113     my($proto, @methods) = @_;
1114     my $class = ref $proto || $proto;
1115
1116     unless( @methods ) {
1117         return _ok( 0, _where(), "$class->can(...)" );
1118     }
1119
1120     my @nok = ();
1121     foreach my $method (@methods) {
1122         local($!, $@);  # don't interfere with caller's $@
1123                         # eval sometimes resets $!
1124         eval { $proto->can($method) } || push @nok, $method;
1125     }
1126
1127     my $name;
1128     $name = @methods == 1 ? "$class->can('$methods[0]')"
1129                           : "$class->can(...)";
1130
1131     _ok( !@nok, _where(), $name );
1132 }
1133
1134
1135 # Call $class->new( @$args ); and run the result through object_ok.
1136 # See Test::More::new_ok
1137 sub new_ok {
1138     my($class, $args, $obj_name) = @_;
1139     $args ||= [];
1140     $object_name = "The object" unless defined $obj_name;
1141
1142     local $Level = $Level + 1;
1143
1144     my $obj;
1145     my $ok = eval { $obj = $class->new(@$args); 1 };
1146     my $error = $@;
1147
1148     if($ok) {
1149         object_ok($obj, $class, $object_name);
1150     }
1151     else {
1152         ok( 0, "new() died" );
1153         diag("Error was:  $@");
1154     }
1155
1156     return $obj;
1157
1158 }
1159
1160
1161 sub isa_ok ($$;$) {
1162     my($object, $class, $obj_name) = @_;
1163
1164     my $diag;
1165     $obj_name = 'The object' unless defined $obj_name;
1166     my $name = "$obj_name isa $class";
1167     if( !defined $object ) {
1168         $diag = "$obj_name isn't defined";
1169     }
1170     else {
1171         my $whatami = ref $object ? 'object' : 'class';
1172
1173         # We can't use UNIVERSAL::isa because we want to honor isa() overrides
1174         local($@, $!);  # eval sometimes resets $!
1175         my $rslt = eval { $object->isa($class) };
1176         my $error = $@;  # in case something else blows away $@
1177
1178         if( $error ) {
1179             if( $error =~ /^Can't call method "isa" on unblessed reference/ ) {
1180                 # It's an unblessed reference
1181                 $obj_name = 'The reference' unless defined $obj_name;
1182                 if( !UNIVERSAL::isa($object, $class) ) {
1183                     my $ref = ref $object;
1184                     $diag = "$obj_name isn't a '$class' it's a '$ref'";
1185                 }
1186             }
1187             elsif( $error =~ /Can't call method "isa" without a package/ ) {
1188                 # It's something that can't even be a class
1189                 $obj_name = 'The thing' unless defined $obj_name;
1190                 $diag = "$obj_name isn't a class or reference";
1191             }
1192             else {
1193                 die <<WHOA;
1194 WHOA! I tried to call ->isa on your object and got some weird error.
1195 This should never happen.  Please contact the author immediately.
1196 Here's the error.
1197 $@
1198 WHOA
1199             }
1200         }
1201         elsif( !$rslt ) {
1202             $obj_name = "The $whatami" unless defined $obj_name;
1203             my $ref = ref $object;
1204             $diag = "$obj_name isn't a '$class' it's a '$ref'";
1205         }
1206     }
1207
1208     _ok( !$diag, _where(), $name );
1209 }
1210
1211
1212 sub class_ok {
1213     my($class, $isa, $class_name) = @_;
1214
1215     # Written so as to count as one test
1216     local $Level = $Level + 1;
1217     if( ref $class ) {
1218         ok( 0, "$class is a refrence, not a class name" );
1219     }
1220     else {
1221         isa_ok($class, $isa, $class_name);
1222     }
1223 }
1224
1225
1226 sub object_ok {
1227     my($obj, $isa, $obj_name) = @_;
1228
1229     local $Level = $Level + 1;
1230     if( !ref $obj ) {
1231         ok( 0, "$obj is not a reference" );
1232     }
1233     else {
1234         isa_ok($obj, $isa, $obj_name);
1235     }
1236 }
1237
1238
1239 # Purposefully avoiding a closure.
1240 sub __capture {
1241     push @::__capture, join "", @_;
1242 }
1243     
1244 sub capture_warnings {
1245     my $code = shift;
1246
1247     local @::__capture;
1248     local $SIG {__WARN__} = \&__capture;
1249     &$code;
1250     return @::__capture;
1251 }
1252
1253 # This will generate a variable number of tests.
1254 # Use done_testing() instead of a fixed plan.
1255 sub warnings_like {
1256     my ($code, $expect, $name) = @_;
1257     local $Level = $Level + 1;
1258
1259     my @w = capture_warnings($code);
1260
1261     cmp_ok(scalar @w, '==', scalar @$expect, $name);
1262     foreach my $e (@$expect) {
1263         if (ref $e) {
1264             like(shift @w, $e, $name);
1265         } else {
1266             is(shift @w, $e, $name);
1267         }
1268     }
1269     if (@w) {
1270         diag("Saw these additional warnings:");
1271         diag($_) foreach @w;
1272     }
1273 }
1274
1275 sub _fail_excess_warnings {
1276     my($expect, $got, $name) = @_;
1277     local $Level = $Level + 1;
1278     # This will fail, and produce diagnostics
1279     is($expect, scalar @$got, $name);
1280     diag("Saw these warnings:");
1281     diag($_) foreach @$got;
1282 }
1283
1284 sub warning_is {
1285     my ($code, $expect, $name) = @_;
1286     die sprintf "Expect must be a string or undef, not a %s reference", ref $expect
1287         if ref $expect;
1288     local $Level = $Level + 1;
1289     my @w = capture_warnings($code);
1290     if (@w > 1) {
1291         _fail_excess_warnings(0 + defined $expect, \@w, $name);
1292     } else {
1293         is($w[0], $expect, $name);
1294     }
1295 }
1296
1297 sub warning_like {
1298     my ($code, $expect, $name) = @_;
1299     die sprintf "Expect must be a regexp object"
1300         unless ref $expect eq 'Regexp';
1301     local $Level = $Level + 1;
1302     my @w = capture_warnings($code);
1303     if (@w > 1) {
1304         _fail_excess_warnings(0 + defined $expect, \@w, $name);
1305     } else {
1306         like($w[0], $expect, $name);
1307     }
1308 }
1309
1310 # Set a watchdog to timeout the entire test file
1311 # NOTE:  If the test file uses 'threads', then call the watchdog() function
1312 #        _AFTER_ the 'threads' module is loaded.
1313 sub watchdog ($;$)
1314 {
1315     my $timeout = shift;
1316     my $method  = shift || "";
1317     my $timeout_msg = 'Test process timed out - terminating';
1318
1319     # Valgrind slows perl way down so give it more time before dying.
1320     $timeout *= 10 if $ENV{PERL_VALGRIND};
1321
1322     my $pid_to_kill = $$;   # PID for this process
1323
1324     if ($method eq "alarm") {
1325         goto WATCHDOG_VIA_ALARM;
1326     }
1327
1328     # shut up use only once warning
1329     my $threads_on = $threads::threads && $threads::threads;
1330
1331     # Don't use a watchdog process if 'threads' is loaded -
1332     #   use a watchdog thread instead
1333     if (!$threads_on || $method eq "process") {
1334
1335         # On Windows and VMS, try launching a watchdog process
1336         #   using system(1, ...) (see perlport.pod)
1337         if ($is_mswin || $is_vms) {
1338             # On Windows, try to get the 'real' PID
1339             if ($is_mswin) {
1340                 eval { require Win32; };
1341                 if (defined(&Win32::GetCurrentProcessId)) {
1342                     $pid_to_kill = Win32::GetCurrentProcessId();
1343                 }
1344             }
1345
1346             # If we still have a fake PID, we can't use this method at all
1347             return if ($pid_to_kill <= 0);
1348
1349             # Launch watchdog process
1350             my $watchdog;
1351             eval {
1352                 local $SIG{'__WARN__'} = sub {
1353                     _diag("Watchdog warning: $_[0]");
1354                 };
1355                 my $sig = $is_vms ? 'TERM' : 'KILL';
1356                 my $cmd = _create_runperl( prog =>  "sleep($timeout);" .
1357                                                     "warn qq/# $timeout_msg" . '\n/;' .
1358                                                     "kill($sig, $pid_to_kill);");
1359                 $watchdog = system(1, $cmd);
1360             };
1361             if ($@ || ($watchdog <= 0)) {
1362                 _diag('Failed to start watchdog');
1363                 _diag($@) if $@;
1364                 undef($watchdog);
1365                 return;
1366             }
1367
1368             # Add END block to parent to terminate and
1369             #   clean up watchdog process
1370             eval "END { local \$! = 0; local \$? = 0;
1371                         wait() if kill('KILL', $watchdog); };";
1372             return;
1373         }
1374
1375         # Try using fork() to generate a watchdog process
1376         my $watchdog;
1377         eval { $watchdog = fork() };
1378         if (defined($watchdog)) {
1379             if ($watchdog) {   # Parent process
1380                 # Add END block to parent to terminate and
1381                 #   clean up watchdog process
1382                 eval "END { local \$! = 0; local \$? = 0;
1383                             wait() if kill('KILL', $watchdog); };";
1384                 return;
1385             }
1386
1387             ### Watchdog process code
1388
1389             # Load POSIX if available
1390             eval { require POSIX; };
1391
1392             # Execute the timeout
1393             sleep($timeout - 2) if ($timeout > 2);   # Workaround for perlbug #49073
1394             sleep(2);
1395
1396             # Kill test process if still running
1397             if (kill(0, $pid_to_kill)) {
1398                 _diag($timeout_msg);
1399                 kill('KILL', $pid_to_kill);
1400                 if ($is_cygwin) {
1401                     # sometimes the above isn't enough on cygwin
1402                     sleep 1; # wait a little, it might have worked after all
1403                     system("/bin/kill -f $pid_to_kill");
1404                 }
1405             }
1406
1407             # Don't execute END block (added at beginning of this file)
1408             $NO_ENDING = 1;
1409
1410             # Terminate ourself (i.e., the watchdog)
1411             POSIX::_exit(1) if (defined(&POSIX::_exit));
1412             exit(1);
1413         }
1414
1415         # fork() failed - fall through and try using a thread
1416     }
1417
1418     # Use a watchdog thread because either 'threads' is loaded,
1419     #   or fork() failed
1420     if (eval {require threads; 1}) {
1421         'threads'->create(sub {
1422                 # Load POSIX if available
1423                 eval { require POSIX; };
1424
1425                 # Execute the timeout
1426                 my $time_left = $timeout;
1427                 do {
1428                     $time_left = $time_left - sleep($time_left);
1429                 } while ($time_left > 0);
1430
1431                 # Kill the parent (and ourself)
1432                 select(STDERR); $| = 1;
1433                 _diag($timeout_msg);
1434                 POSIX::_exit(1) if (defined(&POSIX::_exit));
1435                 my $sig = $is_vms ? 'TERM' : 'KILL';
1436                 kill($sig, $pid_to_kill);
1437             })->detach();
1438         return;
1439     }
1440
1441     # If everything above fails, then just use an alarm timeout
1442 WATCHDOG_VIA_ALARM:
1443     if (eval { alarm($timeout); 1; }) {
1444         # Load POSIX if available
1445         eval { require POSIX; };
1446
1447         # Alarm handler will do the actual 'killing'
1448         $SIG{'ALRM'} = sub {
1449             select(STDERR); $| = 1;
1450             _diag($timeout_msg);
1451             POSIX::_exit(1) if (defined(&POSIX::_exit));
1452             my $sig = $is_vms ? 'TERM' : 'KILL';
1453             kill($sig, $pid_to_kill);
1454         };
1455     }
1456 }
1457
1458 my $cp_0037 =   # EBCDIC code page 0037
1459     '\x00\x01\x02\x03\x37\x2D\x2E\x2F\x16\x05\x25\x0B\x0C\x0D\x0E\x0F' .
1460     '\x10\x11\x12\x13\x3C\x3D\x32\x26\x18\x19\x3F\x27\x1C\x1D\x1E\x1F' .
1461     '\x40\x5A\x7F\x7B\x5B\x6C\x50\x7D\x4D\x5D\x5C\x4E\x6B\x60\x4B\x61' .
1462     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\x7A\x5E\x4C\x7E\x6E\x6F' .
1463     '\x7C\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xD1\xD2\xD3\xD4\xD5\xD6' .
1464     '\xD7\xD8\xD9\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xBA\xE0\xBB\xB0\x6D' .
1465     '\x79\x81\x82\x83\x84\x85\x86\x87\x88\x89\x91\x92\x93\x94\x95\x96' .
1466     '\x97\x98\x99\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xC0\x4F\xD0\xA1\x07' .
1467     '\x20\x21\x22\x23\x24\x15\x06\x17\x28\x29\x2A\x2B\x2C\x09\x0A\x1B' .
1468     '\x30\x31\x1A\x33\x34\x35\x36\x08\x38\x39\x3A\x3B\x04\x14\x3E\xFF' .
1469     '\x41\xAA\x4A\xB1\x9F\xB2\x6A\xB5\xBD\xB4\x9A\x8A\x5F\xCA\xAF\xBC' .
1470     '\x90\x8F\xEA\xFA\xBE\xA0\xB6\xB3\x9D\xDA\x9B\x8B\xB7\xB8\xB9\xAB' .
1471     '\x64\x65\x62\x66\x63\x67\x9E\x68\x74\x71\x72\x73\x78\x75\x76\x77' .
1472     '\xAC\x69\xED\xEE\xEB\xEF\xEC\xBF\x80\xFD\xFE\xFB\xFC\xAD\xAE\x59' .
1473     '\x44\x45\x42\x46\x43\x47\x9C\x48\x54\x51\x52\x53\x58\x55\x56\x57' .
1474     '\x8C\x49\xCD\xCE\xCB\xCF\xCC\xE1\x70\xDD\xDE\xDB\xDC\x8D\x8E\xDF';
1475
1476 my $cp_1047 =   # EBCDIC code page 1047
1477     '\x00\x01\x02\x03\x37\x2D\x2E\x2F\x16\x05\x15\x0B\x0C\x0D\x0E\x0F' .
1478     '\x10\x11\x12\x13\x3C\x3D\x32\x26\x18\x19\x3F\x27\x1C\x1D\x1E\x1F' .
1479     '\x40\x5A\x7F\x7B\x5B\x6C\x50\x7D\x4D\x5D\x5C\x4E\x6B\x60\x4B\x61' .
1480     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\x7A\x5E\x4C\x7E\x6E\x6F' .
1481     '\x7C\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xD1\xD2\xD3\xD4\xD5\xD6' .
1482     '\xD7\xD8\xD9\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xAD\xE0\xBD\x5F\x6D' .
1483     '\x79\x81\x82\x83\x84\x85\x86\x87\x88\x89\x91\x92\x93\x94\x95\x96' .
1484     '\x97\x98\x99\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xC0\x4F\xD0\xA1\x07' .
1485     '\x20\x21\x22\x23\x24\x25\x06\x17\x28\x29\x2A\x2B\x2C\x09\x0A\x1B' .
1486     '\x30\x31\x1A\x33\x34\x35\x36\x08\x38\x39\x3A\x3B\x04\x14\x3E\xFF' .
1487     '\x41\xAA\x4A\xB1\x9F\xB2\x6A\xB5\xBB\xB4\x9A\x8A\xB0\xCA\xAF\xBC' .
1488     '\x90\x8F\xEA\xFA\xBE\xA0\xB6\xB3\x9D\xDA\x9B\x8B\xB7\xB8\xB9\xAB' .
1489     '\x64\x65\x62\x66\x63\x67\x9E\x68\x74\x71\x72\x73\x78\x75\x76\x77' .
1490     '\xAC\x69\xED\xEE\xEB\xEF\xEC\xBF\x80\xFD\xFE\xFB\xFC\xBA\xAE\x59' .
1491     '\x44\x45\x42\x46\x43\x47\x9C\x48\x54\x51\x52\x53\x58\x55\x56\x57' .
1492     '\x8C\x49\xCD\xCE\xCB\xCF\xCC\xE1\x70\xDD\xDE\xDB\xDC\x8D\x8E\xDF';
1493
1494 my $cp_bc = # EBCDIC code page POSiX-BC
1495     '\x00\x01\x02\x03\x37\x2D\x2E\x2F\x16\x05\x15\x0B\x0C\x0D\x0E\x0F' .
1496     '\x10\x11\x12\x13\x3C\x3D\x32\x26\x18\x19\x3F\x27\x1C\x1D\x1E\x1F' .
1497     '\x40\x5A\x7F\x7B\x5B\x6C\x50\x7D\x4D\x5D\x5C\x4E\x6B\x60\x4B\x61' .
1498     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\x7A\x5E\x4C\x7E\x6E\x6F' .
1499     '\x7C\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xD1\xD2\xD3\xD4\xD5\xD6' .
1500     '\xD7\xD8\xD9\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xBB\xBC\xBD\x6A\x6D' .
1501     '\x4A\x81\x82\x83\x84\x85\x86\x87\x88\x89\x91\x92\x93\x94\x95\x96' .
1502     '\x97\x98\x99\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xFB\x4F\xFD\xFF\x07' .
1503     '\x20\x21\x22\x23\x24\x25\x06\x17\x28\x29\x2A\x2B\x2C\x09\x0A\x1B' .
1504     '\x30\x31\x1A\x33\x34\x35\x36\x08\x38\x39\x3A\x3B\x04\x14\x3E\x5F' .
1505     '\x41\xAA\xB0\xB1\x9F\xB2\xD0\xB5\x79\xB4\x9A\x8A\xBA\xCA\xAF\xA1' .
1506     '\x90\x8F\xEA\xFA\xBE\xA0\xB6\xB3\x9D\xDA\x9B\x8B\xB7\xB8\xB9\xAB' .
1507     '\x64\x65\x62\x66\x63\x67\x9E\x68\x74\x71\x72\x73\x78\x75\x76\x77' .
1508     '\xAC\x69\xED\xEE\xEB\xEF\xEC\xBF\x80\xE0\xFE\xDD\xFC\xAD\xAE\x59' .
1509     '\x44\x45\x42\x46\x43\x47\x9C\x48\x54\x51\x52\x53\x58\x55\x56\x57' .
1510     '\x8C\x49\xCD\xCE\xCB\xCF\xCC\xE1\x70\xC0\xDE\xDB\xDC\x8D\x8E\xDF';
1511
1512 my $straight =  # Avoid ranges
1513     '\x00\x01\x02\x03\x04\x05\x06\x07\x08\x09\x0A\x0B\x0C\x0D\x0E\x0F' .
1514     '\x10\x11\x12\x13\x14\x15\x16\x17\x18\x19\x1A\x1B\x1C\x1D\x1E\x1F' .
1515     '\x20\x21\x22\x23\x24\x25\x26\x27\x28\x29\x2A\x2B\x2C\x2D\x2E\x2F' .
1516     '\x30\x31\x32\x33\x34\x35\x36\x37\x38\x39\x3A\x3B\x3C\x3D\x3E\x3F' .
1517     '\x40\x41\x42\x43\x44\x45\x46\x47\x48\x49\x4A\x4B\x4C\x4D\x4E\x4F' .
1518     '\x50\x51\x52\x53\x54\x55\x56\x57\x58\x59\x5A\x5B\x5C\x5D\x5E\x5F' .
1519     '\x60\x61\x62\x63\x64\x65\x66\x67\x68\x69\x6A\x6B\x6C\x6D\x6E\x6F' .
1520     '\x70\x71\x72\x73\x74\x75\x76\x77\x78\x79\x7A\x7B\x7C\x7D\x7E\x7F' .
1521     '\x80\x81\x82\x83\x84\x85\x86\x87\x88\x89\x8A\x8B\x8C\x8D\x8E\x8F' .
1522     '\x90\x91\x92\x93\x94\x95\x96\x97\x98\x99\x9A\x9B\x9C\x9D\x9E\x9F' .
1523     '\xA0\xA1\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xAA\xAB\xAC\xAD\xAE\xAF' .
1524     '\xB0\xB1\xB2\xB3\xB4\xB5\xB6\xB7\xB8\xB9\xBA\xBB\xBC\xBD\xBE\xBF' .
1525     '\xC0\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xCA\xCB\xCC\xCD\xCE\xCF' .
1526     '\xD0\xD1\xD2\xD3\xD4\xD5\xD6\xD7\xD8\xD9\xDA\xDB\xDC\xDD\xDE\xDF' .
1527     '\xE0\xE1\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xEA\xEB\xEC\xED\xEE\xEF' .
1528     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\xFA\xFB\xFC\xFD\xFE\xFF';
1529
1530 # The following 2 functions allow tests to work on both EBCDIC and
1531 # ASCII-ish platforms.  They convert string scalars between the native
1532 # character set and the set of 256 characters which is usually called
1533 # Latin1.
1534 #
1535 # These routines don't work on UTF-EBCDIC and UTF-8.
1536
1537 sub native_to_latin1($) {
1538     my $string = shift;
1539
1540     return $string if ord('^') == 94;   # ASCII, Latin1
1541     my $cp;
1542     if (ord('^') == 95) {    # EBCDIC 1047
1543         $cp = \$cp_1047;
1544     }
1545     elsif (ord('^') == 106) {   # EBCDIC POSIX-BC
1546         $cp = \$cp_bc;
1547     }
1548     elsif (ord('^') == 176)  {   # EBCDIC 037 */
1549         $cp = \$cp_0037;
1550     }
1551     else {
1552         die "Unknown native character set";
1553     }
1554
1555     eval '$string =~ tr/' . $$cp . '/' . $straight . '/';
1556     return $string;
1557 }
1558
1559 sub latin1_to_native($) {
1560     my $string = shift;
1561
1562     return $string if ord('^') == 94;   # ASCII, Latin1
1563     my $cp;
1564     if (ord('^') == 95) {    # EBCDIC 1047
1565         $cp = \$cp_1047;
1566     }
1567     elsif (ord('^') == 106) {   # EBCDIC POSIX-BC
1568         $cp = \$cp_bc;
1569     }
1570     elsif (ord('^') == 176)  {   # EBCDIC 037 */
1571         $cp = \$cp_0037;
1572     }
1573     else {
1574         die "Unknown native character set";
1575     }
1576
1577     eval '$string =~ tr/' . $straight . '/' . $$cp . '/';
1578     return $string;
1579 }
1580
1581 sub ord_latin1_to_native {
1582     # given an input code point, return the platform's native
1583     # equivalent value.  Anything above latin1 is itself.
1584
1585     my $ord = shift;
1586     return $ord if $ord > 255;
1587     return ord latin1_to_native(chr $ord);
1588 }
1589
1590 sub ord_native_to_latin1 {
1591     # given an input platform code point, return the latin1 equivalent value.
1592     # Anything above latin1 is itself.
1593
1594     my $ord = shift;
1595     return $ord if $ord > 255;
1596     return ord native_to_latin1(chr $ord);
1597 }
1598
1599 1;