This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
f07c6bc6f1a64e79e88021db2714f69f5a8b9589
[perl5.git] / pod / perlop.pod
1 =head1 NAME
2 X<operator>
3
4 perlop - Perl operators and precedence
5
6 =head1 DESCRIPTION
7
8 In Perl, the operator determines what operation is performed,
9 independent of the type of the operands.  For example S<C<$x + $y>>
10 is always a numeric addition, and if C<$x> or C<$y> do not contain
11 numbers, an attempt is made to convert them to numbers first.
12
13 This is in contrast to many other dynamic languages, where the
14 operation is determined by the type of the first argument.  It also
15 means that Perl has two versions of some operators, one for numeric
16 and one for string comparison.  For example S<C<$x == $y>> compares
17 two numbers for equality, and S<C<$x eq $y>> compares two strings.
18
19 There are a few exceptions though: C<x> can be either string
20 repetition or list repetition, depending on the type of the left
21 operand, and C<&>, C<|>, C<^> and C<~> can be either string or numeric bit
22 operations.
23
24 =head2 Operator Precedence and Associativity
25 X<operator, precedence> X<precedence> X<associativity>
26
27 Operator precedence and associativity work in Perl more or less like
28 they do in mathematics.
29
30 I<Operator precedence> means some operators group more tightly than others.
31 For example, in C<2 + 4 * 5>, the multiplication has higher precedence, so C<4
32 * 5> is grouped together as the right-hand operand of the addition, rather
33 than C<2 + 4> being grouped together as the left-hand operand of the
34 multiplication. It is as if the expression were written C<2 + (4 * 5)>, not
35 C<(2 + 4) * 5>. So the expression yields C<2 + 20 == 22>, rather than
36 C<6 * 5 == 30>.
37
38 I<Operator associativity> defines what happens if a sequence of the same
39 operators is used one after another:
40 usually that they will be grouped at the left
41 or the right. For example, in C<9 - 3 - 2>, subtraction is left associative,
42 so C<9 - 3> is grouped together as the left-hand operand of the second
43 subtraction, rather than C<3 - 2> being grouped together as the right-hand
44 operand of the first subtraction. It is as if the expression were written
45 C<(9 - 3) - 2>, not C<9 - (3 - 2)>. So the expression yields C<6 - 2 == 4>,
46 rather than C<9 - 1 == 8>.
47
48 For simple operators that evaluate all their operands and then combine the
49 values in some way, precedence and associativity (and parentheses) imply some
50 ordering requirements on those combining operations. For example, in C<2 + 4 *
51 5>, the grouping implied by precedence means that the multiplication of 4 and
52 5 must be performed before the addition of 2 and 20, simply because the result
53 of that multiplication is required as one of the operands of the addition. But
54 the order of operations is not fully determined by this: in C<2 * 2 + 4 * 5>
55 both multiplications must be performed before the addition, but the grouping
56 does not say anything about the order in which the two multiplications are
57 performed. In fact Perl has a general rule that the operands of an operator
58 are evaluated in left-to-right order. A few operators such as C<&&=> have
59 special evaluation rules that can result in an operand not being evaluated at
60 all; in general, the top-level operator in an expression has control of
61 operand evaluation.
62
63 Some comparison operators, as their associativity, I<chain> with some
64 operators of the same precedence (but never with operators of different
65 precedence).  This chaining means that each comparison is performed
66 on the two arguments surrounding it, with each interior argument taking
67 part in two comparisons, and the comparison results are implicitly ANDed.
68 Thus S<C<"$x E<lt> $y E<lt>= $z">> behaves exactly like S<C<"$x E<lt>
69 $y && $y E<lt>= $z">>, assuming that C<"$y"> is as simple a scalar as
70 it looks.  The ANDing short-circuits just like C<"&&"> does, stopping
71 the sequence of comparisons as soon as one yields false.
72
73 In a chained comparison, each argument expression is evaluated at most
74 once, even if it takes part in two comparisons, but the result of the
75 evaluation is fetched for each comparison.  (It is not evaluated
76 at all if the short-circuiting means that it's not required for any
77 comparisons.)  This matters if the computation of an interior argument
78 is expensive or non-deterministic.  For example,
79
80     if($x < expensive_sub() <= $z) { ...
81
82 is not entirely like
83
84     if($x < expensive_sub() && expensive_sub() <= $z) { ...
85
86 but instead closer to
87
88     my $tmp = expensive_sub();
89     if($x < $tmp && $tmp <= $z) { ...
90
91 in that the subroutine is only called once.  However, it's not exactly
92 like this latter code either, because the chained comparison doesn't
93 actually involve any temporary variable (named or otherwise): there is
94 no assignment.  This doesn't make much difference where the expression
95 is a call to an ordinary subroutine, but matters more with an lvalue
96 subroutine, or if the argument expression yields some unusual kind of
97 scalar by other means.  For example, if the argument expression yields
98 a tied scalar, then the expression is evaluated to produce that scalar
99 at most once, but the value of that scalar may be fetched up to twice,
100 once for each comparison in which it is actually used.
101
102 In this example, the expression is evaluated only once, and the tied
103 scalar (the result of the expression) is fetched for each comparison that
104 uses it.
105
106     if ($x < $tied_scalar < $z) { ...
107
108 In the next example, the expression is evaluated only once, and the tied
109 scalar is fetched once as part of the operation within the expression.
110 The result of that operation is fetched for each comparison, which
111 normally doesn't matter unless that expression result is also magical due
112 to operator overloading.
113
114     if ($x < $tied_scalar + 42 < $z) { ...
115
116 Some operators are instead non-associative, meaning that it is a syntax
117 error to use a sequence of those operators of the same precedence.
118 For example, S<C<"$x .. $y .. $z">> is an error.
119
120 Perl operators have the following associativity and precedence,
121 listed from highest precedence to lowest.  Operators borrowed from
122 C keep the same precedence relationship with each other, even where
123 C's precedence is slightly screwy.  (This makes learning Perl easier
124 for C folks.)  With very few exceptions, these all operate on scalar
125 values only, not array values.
126
127     left        terms and list operators (leftward)
128     left        ->
129     nonassoc    ++ --
130     right       **
131     right       ! ~ ~. \ and unary + and -
132     left        =~ !~
133     left        * / % x
134     left        + - .
135     left        << >>
136     nonassoc    named unary operators
137     nonassoc    isa
138     chained     < > <= >= lt gt le ge
139     chain/na    == != eq ne <=> cmp ~~
140     left        & &.
141     left        | |. ^ ^.
142     left        &&
143     left        || //
144     nonassoc    ..  ...
145     right       ?:
146     right       = += -= *= etc. goto last next redo dump
147     left        , =>
148     nonassoc    list operators (rightward)
149     right       not
150     left        and
151     left        or xor
152
153 In the following sections, these operators are covered in detail, in the
154 same order in which they appear in the table above.
155
156 Many operators can be overloaded for objects.  See L<overload>.
157
158 =head2 Terms and List Operators (Leftward)
159 X<list operator> X<operator, list> X<term>
160
161 A TERM has the highest precedence in Perl.  They include variables,
162 quote and quote-like operators, any expression in parentheses,
163 and any function whose arguments are parenthesized.  Actually, there
164 aren't really functions in this sense, just list operators and unary
165 operators behaving as functions because you put parentheses around
166 the arguments.  These are all documented in L<perlfunc>.
167
168 If any list operator (C<print()>, etc.) or any unary operator (C<chdir()>, etc.)
169 is followed by a left parenthesis as the next token, the operator and
170 arguments within parentheses are taken to be of highest precedence,
171 just like a normal function call.
172
173 In the absence of parentheses, the precedence of list operators such as
174 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
175 whether you are looking at the left side or the right side of the operator.
176 For example, in
177
178     @ary = (1, 3, sort 4, 2);
179     print @ary;         # prints 1324
180
181 the commas on the right of the C<sort> are evaluated before the C<sort>,
182 but the commas on the left are evaluated after.  In other words,
183 list operators tend to gobble up all arguments that follow, and
184 then act like a simple TERM with regard to the preceding expression.
185 Be careful with parentheses:
186
187     # These evaluate exit before doing the print:
188     print($foo, exit);  # Obviously not what you want.
189     print $foo, exit;   # Nor is this.
190
191     # These do the print before evaluating exit:
192     (print $foo), exit; # This is what you want.
193     print($foo), exit;  # Or this.
194     print ($foo), exit; # Or even this.
195
196 Also note that
197
198     print ($foo & 255) + 1, "\n";
199
200 probably doesn't do what you expect at first glance.  The parentheses
201 enclose the argument list for C<print> which is evaluated (printing
202 the result of S<C<$foo & 255>>).  Then one is added to the return value
203 of C<print> (usually 1).  The result is something like this:
204
205     1 + 1, "\n";    # Obviously not what you meant.
206
207 To do what you meant properly, you must write:
208
209     print(($foo & 255) + 1, "\n");
210
211 See L</Named Unary Operators> for more discussion of this.
212
213 Also parsed as terms are the S<C<do {}>> and S<C<eval {}>> constructs, as
214 well as subroutine and method calls, and the anonymous
215 constructors C<[]> and C<{}>.
216
217 See also L</Quote and Quote-like Operators> toward the end of this section,
218 as well as L</"I/O Operators">.
219
220 =head2 The Arrow Operator
221 X<arrow> X<dereference> X<< -> >>
222
223 "C<< -> >>" is an infix dereference operator, just as it is in C
224 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
225 C<(...)> subscript, then the left side must be either a hard or
226 symbolic reference to an array, a hash, or a subroutine respectively.
227 (Or technically speaking, a location capable of holding a hard
228 reference, if it's an array or hash reference being used for
229 assignment.)  See L<perlreftut> and L<perlref>.
230
231 Otherwise, the right side is a method name or a simple scalar
232 variable containing either the method name or a subroutine reference,
233 and the left side must be either an object (a blessed reference)
234 or a class name (that is, a package name).  See L<perlobj>.
235
236 The dereferencing cases (as opposed to method-calling cases) are
237 somewhat extended by the C<postderef> feature.  For the
238 details of that feature, consult L<perlref/Postfix Dereference Syntax>.
239
240 =head2 Auto-increment and Auto-decrement
241 X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<-->
242
243 C<"++"> and C<"--"> work as in C.  That is, if placed before a variable,
244 they increment or decrement the variable by one before returning the
245 value, and if placed after, increment or decrement after returning the
246 value.
247
248     $i = 0;  $j = 0;
249     print $i++;  # prints 0
250     print ++$j;  # prints 1
251
252 Note that just as in C, Perl doesn't define B<when> the variable is
253 incremented or decremented.  You just know it will be done sometime
254 before or after the value is returned.  This also means that modifying
255 a variable twice in the same statement will lead to undefined behavior.
256 Avoid statements like:
257
258     $i = $i ++;
259     print ++ $i + $i ++;
260
261 Perl will not guarantee what the result of the above statements is.
262
263 The auto-increment operator has a little extra builtin magic to it.  If
264 you increment a variable that is numeric, or that has ever been used in
265 a numeric context, you get a normal increment.  If, however, the
266 variable has been used in only string contexts since it was set, and
267 has a value that is not the empty string and matches the pattern
268 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
269 character within its range, with carry:
270
271     print ++($foo = "99");      # prints "100"
272     print ++($foo = "a0");      # prints "a1"
273     print ++($foo = "Az");      # prints "Ba"
274     print ++($foo = "zz");      # prints "aaa"
275
276 C<undef> is always treated as numeric, and in particular is changed
277 to C<0> before incrementing (so that a post-increment of an undef value
278 will return C<0> rather than C<undef>).
279
280 The auto-decrement operator is not magical.
281
282 =head2 Exponentiation
283 X<**> X<exponentiation> X<power>
284
285 Binary C<"**"> is the exponentiation operator.  It binds even more
286 tightly than unary minus, so C<-2**4> is C<-(2**4)>, not C<(-2)**4>.
287 (This is
288 implemented using C's C<pow(3)> function, which actually works on doubles
289 internally.)
290
291 Note that certain exponentiation expressions are ill-defined:
292 these include C<0**0>, C<1**Inf>, and C<Inf**0>.  Do not expect
293 any particular results from these special cases, the results
294 are platform-dependent.
295
296 =head2 Symbolic Unary Operators
297 X<unary operator> X<operator, unary>
298
299 Unary C<"!"> performs logical negation, that is, "not".  See also
300 L<C<not>|/Logical Not> for a lower precedence version of this.
301 X<!>
302
303 Unary C<"-"> performs arithmetic negation if the operand is numeric,
304 including any string that looks like a number.  If the operand is
305 an identifier, a string consisting of a minus sign concatenated
306 with the identifier is returned.  Otherwise, if the string starts
307 with a plus or minus, a string starting with the opposite sign is
308 returned.  One effect of these rules is that C<-bareword> is equivalent
309 to the string C<"-bareword">.  If, however, the string begins with a
310 non-alphabetic character (excluding C<"+"> or C<"-">), Perl will attempt
311 to convert
312 the string to a numeric, and the arithmetic negation is performed.  If the
313 string cannot be cleanly converted to a numeric, Perl will give the warning
314 B<Argument "the string" isn't numeric in negation (-) at ...>.
315 X<-> X<negation, arithmetic>
316
317 Unary C<"~"> performs bitwise negation, that is, 1's complement.  For
318 example, S<C<0666 & ~027>> is 0640.  (See also L</Integer Arithmetic> and
319 L</Bitwise String Operators>.)  Note that the width of the result is
320 platform-dependent: C<~0> is 32 bits wide on a 32-bit platform, but 64
321 bits wide on a 64-bit platform, so if you are expecting a certain bit
322 width, remember to use the C<"&"> operator to mask off the excess bits.
323 X<~> X<negation, binary>
324
325 Starting in Perl 5.28, it is a fatal error to try to complement a string
326 containing a character with an ordinal value above 255.
327
328 If the "bitwise" feature is enabled via S<C<use
329 feature 'bitwise'>> or C<use v5.28>, then unary
330 C<"~"> always treats its argument as a number, and an
331 alternate form of the operator, C<"~.">, always treats its argument as a
332 string.  So C<~0> and C<~"0"> will both give 2**32-1 on 32-bit platforms,
333 whereas C<~.0> and C<~."0"> will both yield C<"\xff">.  Until Perl 5.28,
334 this feature produced a warning in the C<"experimental::bitwise"> category.
335
336 Unary C<"+"> has no effect whatsoever, even on strings.  It is useful
337 syntactically for separating a function name from a parenthesized expression
338 that would otherwise be interpreted as the complete list of function
339 arguments.  (See examples above under L</Terms and List Operators (Leftward)>.)
340 X<+>
341
342 Unary C<"\"> creates references.  If its operand is a single sigilled
343 thing, it creates a reference to that object.  If its operand is a
344 parenthesised list, then it creates references to the things mentioned
345 in the list.  Otherwise it puts its operand in list context, and creates
346 a list of references to the scalars in the list provided by the operand.
347 See L<perlreftut>
348 and L<perlref>.  Do not confuse this behavior with the behavior of
349 backslash within a string, although both forms do convey the notion
350 of protecting the next thing from interpolation.
351 X<\> X<reference> X<backslash>
352
353 =head2 Binding Operators
354 X<binding> X<operator, binding> X<=~> X<!~>
355
356 Binary C<"=~"> binds a scalar expression to a pattern match.  Certain operations
357 search or modify the string C<$_> by default.  This operator makes that kind
358 of operation work on some other string.  The right argument is a search
359 pattern, substitution, or transliteration.  The left argument is what is
360 supposed to be searched, substituted, or transliterated instead of the default
361 C<$_>.  When used in scalar context, the return value generally indicates the
362 success of the operation.  The exceptions are substitution (C<s///>)
363 and transliteration (C<y///>) with the C</r> (non-destructive) option,
364 which cause the B<r>eturn value to be the result of the substitution.
365 Behavior in list context depends on the particular operator.
366 See L</"Regexp Quote-Like Operators"> for details and L<perlretut> for
367 examples using these operators.
368
369 If the right argument is an expression rather than a search pattern,
370 substitution, or transliteration, it is interpreted as a search pattern at run
371 time.  Note that this means that its
372 contents will be interpolated twice, so
373
374     '\\' =~ q'\\';
375
376 is not ok, as the regex engine will end up trying to compile the
377 pattern C<\>, which it will consider a syntax error.
378
379 Binary C<"!~"> is just like C<"=~"> except the return value is negated in
380 the logical sense.
381
382 Binary C<"!~"> with a non-destructive substitution (C<s///r>) or transliteration
383 (C<y///r>) is a syntax error.
384
385 =head2 Multiplicative Operators
386 X<operator, multiplicative>
387
388 Binary C<"*"> multiplies two numbers.
389 X<*>
390
391 Binary C<"/"> divides two numbers.
392 X</> X<slash>
393
394 Binary C<"%"> is the modulo operator, which computes the division
395 remainder of its first argument with respect to its second argument.
396 Given integer
397 operands C<$m> and C<$n>: If C<$n> is positive, then S<C<$m % $n>> is
398 C<$m> minus the largest multiple of C<$n> less than or equal to
399 C<$m>.  If C<$n> is negative, then S<C<$m % $n>> is C<$m> minus the
400 smallest multiple of C<$n> that is not less than C<$m> (that is, the
401 result will be less than or equal to zero).  If the operands
402 C<$m> and C<$n> are floating point values and the absolute value of
403 C<$n> (that is C<abs($n)>) is less than S<C<(UV_MAX + 1)>>, only
404 the integer portion of C<$m> and C<$n> will be used in the operation
405 (Note: here C<UV_MAX> means the maximum of the unsigned integer type).
406 If the absolute value of the right operand (C<abs($n)>) is greater than
407 or equal to S<C<(UV_MAX + 1)>>, C<"%"> computes the floating-point remainder
408 C<$r> in the equation S<C<($r = $m - $i*$n)>> where C<$i> is a certain
409 integer that makes C<$r> have the same sign as the right operand
410 C<$n> (B<not> as the left operand C<$m> like C function C<fmod()>)
411 and the absolute value less than that of C<$n>.
412 Note that when S<C<use integer>> is in scope, C<"%"> gives you direct access
413 to the modulo operator as implemented by your C compiler.  This
414 operator is not as well defined for negative operands, but it will
415 execute faster.
416 X<%> X<remainder> X<modulo> X<mod>
417
418 Binary C<x> is the repetition operator.  In scalar context, or if the
419 left operand is neither enclosed in parentheses nor a C<qw//> list,
420 it performs a string repetition.  In that case it supplies scalar
421 context to the left operand, and returns a string consisting of the
422 left operand string repeated the number of times specified by the right
423 operand.  If the C<x> is in list context, and the left operand is either
424 enclosed in parentheses or a C<qw//> list, it performs a list repetition.
425 In that case it supplies list context to the left operand, and returns
426 a list consisting of the left operand list repeated the number of times
427 specified by the right operand.
428 If the right operand is zero or negative (raising a warning on
429 negative), it returns an empty string
430 or an empty list, depending on the context.
431 X<x>
432
433     print '-' x 80;             # print row of dashes
434
435     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
436
437     @ones = (1) x 80;           # a list of 80 1's
438     @ones = (5) x @ones;        # set all elements to 5
439
440
441 =head2 Additive Operators
442 X<operator, additive>
443
444 Binary C<"+"> returns the sum of two numbers.
445 X<+>
446
447 Binary C<"-"> returns the difference of two numbers.
448 X<->
449
450 Binary C<"."> concatenates two strings.
451 X<string, concatenation> X<concatenation>
452 X<cat> X<concat> X<concatenate> X<.>
453
454 =head2 Shift Operators
455 X<shift operator> X<operator, shift> X<<< << >>>
456 X<<< >> >>> X<right shift> X<left shift> X<bitwise shift>
457 X<shl> X<shr> X<shift, right> X<shift, left>
458
459 Binary C<<< "<<" >>> returns the value of its left argument shifted left by the
460 number of bits specified by the right argument.  Arguments should be
461 integers.  (See also L</Integer Arithmetic>.)
462
463 Binary C<<< ">>" >>> returns the value of its left argument shifted right by
464 the number of bits specified by the right argument.  Arguments should
465 be integers.  (See also L</Integer Arithmetic>.)
466
467 If S<C<use integer>> (see L</Integer Arithmetic>) is in force then
468 signed C integers are used (I<arithmetic shift>), otherwise unsigned C
469 integers are used (I<logical shift>), even for negative shiftees.
470 In arithmetic right shift the sign bit is replicated on the left,
471 in logical shift zero bits come in from the left.
472
473 Either way, the implementation isn't going to generate results larger
474 than the size of the integer type Perl was built with (32 bits or 64 bits).
475
476 Shifting by negative number of bits means the reverse shift: left
477 shift becomes right shift, right shift becomes left shift.  This is
478 unlike in C, where negative shift is undefined.
479
480 Shifting by more bits than the size of the integers means most of the
481 time zero (all bits fall off), except that under S<C<use integer>>
482 right overshifting a negative shiftee results in -1.  This is unlike
483 in C, where shifting by too many bits is undefined.  A common C
484 behavior is "shift by modulo wordbits", so that for example
485
486     1 >> 64 == 1 >> (64 % 64) == 1 >> 0 == 1  # Common C behavior.
487
488 but that is completely accidental.
489
490 If you get tired of being subject to your platform's native integers,
491 the S<C<use bigint>> pragma neatly sidesteps the issue altogether:
492
493     print 20 << 20;  # 20971520
494     print 20 << 40;  # 5120 on 32-bit machines,
495                      # 21990232555520 on 64-bit machines
496     use bigint;
497     print 20 << 100; # 25353012004564588029934064107520
498
499 =head2 Named Unary Operators
500 X<operator, named unary>
501
502 The various named unary operators are treated as functions with one
503 argument, with optional parentheses.
504
505 If any list operator (C<print()>, etc.) or any unary operator (C<chdir()>, etc.)
506 is followed by a left parenthesis as the next token, the operator and
507 arguments within parentheses are taken to be of highest precedence,
508 just like a normal function call.  For example,
509 because named unary operators are higher precedence than C<||>:
510
511     chdir $foo    || die;       # (chdir $foo) || die
512     chdir($foo)   || die;       # (chdir $foo) || die
513     chdir ($foo)  || die;       # (chdir $foo) || die
514     chdir +($foo) || die;       # (chdir $foo) || die
515
516 but, because C<"*"> is higher precedence than named operators:
517
518     chdir $foo * 20;    # chdir ($foo * 20)
519     chdir($foo) * 20;   # (chdir $foo) * 20
520     chdir ($foo) * 20;  # (chdir $foo) * 20
521     chdir +($foo) * 20; # chdir ($foo * 20)
522
523     rand 10 * 20;       # rand (10 * 20)
524     rand(10) * 20;      # (rand 10) * 20
525     rand (10) * 20;     # (rand 10) * 20
526     rand +(10) * 20;    # rand (10 * 20)
527
528 Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are
529 treated like named unary operators, but they don't follow this functional
530 parenthesis rule.  That means, for example, that C<-f($file).".bak"> is
531 equivalent to S<C<-f "$file.bak">>.
532 X<-X> X<filetest> X<operator, filetest>
533
534 See also L</"Terms and List Operators (Leftward)">.
535
536 =head2 Relational Operators
537 X<relational operator> X<operator, relational>
538
539 Perl operators that return true or false generally return values
540 that can be safely used as numbers.  For example, the relational
541 operators in this section and the equality operators in the next
542 one return C<1> for true and a special version of the defined empty
543 string, C<"">, which counts as a zero but is exempt from warnings
544 about improper numeric conversions, just as S<C<"0 but true">> is.
545
546 Binary C<< "<" >> returns true if the left argument is numerically less than
547 the right argument.
548 X<< < >>
549
550 Binary C<< ">" >> returns true if the left argument is numerically greater
551 than the right argument.
552 X<< > >>
553
554 Binary C<< "<=" >> returns true if the left argument is numerically less than
555 or equal to the right argument.
556 X<< <= >>
557
558 Binary C<< ">=" >> returns true if the left argument is numerically greater
559 than or equal to the right argument.
560 X<< >= >>
561
562 Binary C<"lt"> returns true if the left argument is stringwise less than
563 the right argument.
564 X<< lt >>
565
566 Binary C<"gt"> returns true if the left argument is stringwise greater
567 than the right argument.
568 X<< gt >>
569
570 Binary C<"le"> returns true if the left argument is stringwise less than
571 or equal to the right argument.
572 X<< le >>
573
574 Binary C<"ge"> returns true if the left argument is stringwise greater
575 than or equal to the right argument.
576 X<< ge >>
577
578 A sequence of relational operators, such as S<C<"$x E<lt> $y E<lt>=
579 $z">>, performs chained comparisons, in the manner described above in
580 the section L</"Operator Precedence and Associativity">.
581 Beware that they do not chain with equality operators, which have lower
582 precedence.
583
584 =head2 Equality Operators
585 X<equality> X<equal> X<equals> X<operator, equality>
586
587 Binary C<< "==" >> returns true if the left argument is numerically equal to
588 the right argument.
589 X<==>
590
591 Binary C<< "!=" >> returns true if the left argument is numerically not equal
592 to the right argument.
593 X<!=>
594
595 Binary C<"eq"> returns true if the left argument is stringwise equal to
596 the right argument.
597 X<eq>
598
599 Binary C<"ne"> returns true if the left argument is stringwise not equal
600 to the right argument.
601 X<ne>
602
603 A sequence of the above equality operators, such as S<C<"$x == $y ==
604 $z">>, performs chained comparisons, in the manner described above in
605 the section L</"Operator Precedence and Associativity">.
606 Beware that they do not chain with relational operators, which have
607 higher precedence.
608
609 Binary C<< "<=>" >> returns -1, 0, or 1 depending on whether the left
610 argument is numerically less than, equal to, or greater than the right
611 argument.  If your platform supports C<NaN>'s (not-a-numbers) as numeric
612 values, using them with C<< "<=>" >> returns undef.  C<NaN> is not
613 C<< "<" >>, C<< "==" >>, C<< ">" >>, C<< "<=" >> or C<< ">=" >> anything
614 (even C<NaN>), so those 5 return false.  S<C<< NaN != NaN >>> returns
615 true, as does S<C<NaN !=> I<anything else>>.  If your platform doesn't
616 support C<NaN>'s then C<NaN> is just a string with numeric value 0.
617 X<< <=> >>
618 X<spaceship>
619
620     $ perl -le '$x = "NaN"; print "No NaN support here" if $x == $x'
621     $ perl -le '$x = "NaN"; print "NaN support here" if $x != $x'
622
623 (Note that the L<bigint>, L<bigrat>, and L<bignum> pragmas all
624 support C<"NaN">.)
625
626 Binary C<"cmp"> returns -1, 0, or 1 depending on whether the left
627 argument is stringwise less than, equal to, or greater than the right
628 argument.
629
630 Here we can see the difference between <=> and cmp,
631
632     print 10 <=> 2 #prints 1
633     print 10 cmp 2 #prints -1
634
635 (likewise between gt and >, lt and <, etc.)
636 X<cmp>
637
638 Binary C<"~~"> does a smartmatch between its arguments.  Smart matching
639 is described in the next section.
640 X<~~>
641
642 The two-sided ordering operators C<"E<lt>=E<gt>"> and C<"cmp">, and the
643 smartmatch operator C<"~~">, are non-associative with respect to each
644 other and with respect to the equality operators of the same precedence.
645
646 C<"lt">, C<"le">, C<"ge">, C<"gt"> and C<"cmp"> use the collation (sort)
647 order specified by the current C<LC_COLLATE> locale if a S<C<use
648 locale>> form that includes collation is in effect.  See L<perllocale>.
649 Do not mix these with Unicode,
650 only use them with legacy 8-bit locale encodings.
651 The standard C<L<Unicode::Collate>> and
652 C<L<Unicode::Collate::Locale>> modules offer much more powerful
653 solutions to collation issues.
654
655 For case-insensitive comparisons, look at the L<perlfunc/fc> case-folding
656 function, available in Perl v5.16 or later:
657
658     if ( fc($x) eq fc($y) ) { ... }
659
660 =head2 Class Instance Operator
661 X<isa operator>
662
663 Binary C<isa> evaluates to true when the left argument is an object instance of
664 the class (or a subclass derived from that class) given by the right argument.
665 If the left argument is not defined, not a blessed object instance, nor does
666 not derive from the class given by the right argument, the operator evaluates
667 as false. The right argument may give the class either as a bareword or a
668 scalar expression that yields a string class name:
669
670     if( $obj isa Some::Class ) { ... }
671
672     if( $obj isa "Different::Class" ) { ... }
673     if( $obj isa $name_of_class ) { ... }
674
675 This is an experimental feature and is available from Perl 5.31.6 when enabled
676 by C<use feature 'isa'>. It emits a warning in the C<experimental::isa>
677 category.
678
679 =head2 Smartmatch Operator
680
681 First available in Perl 5.10.1 (the 5.10.0 version behaved differently),
682 binary C<~~> does a "smartmatch" between its arguments.  This is mostly
683 used implicitly in the C<when> construct described in L<perlsyn>, although
684 not all C<when> clauses call the smartmatch operator.  Unique among all of
685 Perl's operators, the smartmatch operator can recurse.  The smartmatch
686 operator is L<experimental|perlpolicy/experimental> and its behavior is
687 subject to change.
688
689 It is also unique in that all other Perl operators impose a context
690 (usually string or numeric context) on their operands, autoconverting
691 those operands to those imposed contexts.  In contrast, smartmatch
692 I<infers> contexts from the actual types of its operands and uses that
693 type information to select a suitable comparison mechanism.
694
695 The C<~~> operator compares its operands "polymorphically", determining how
696 to compare them according to their actual types (numeric, string, array,
697 hash, etc.).  Like the equality operators with which it shares the same
698 precedence, C<~~> returns 1 for true and C<""> for false.  It is often best
699 read aloud as "in", "inside of", or "is contained in", because the left
700 operand is often looked for I<inside> the right operand.  That makes the
701 order of the operands to the smartmatch operand often opposite that of
702 the regular match operator.  In other words, the "smaller" thing is usually
703 placed in the left operand and the larger one in the right.
704
705 The behavior of a smartmatch depends on what type of things its arguments
706 are, as determined by the following table.  The first row of the table
707 whose types apply determines the smartmatch behavior.  Because what
708 actually happens is mostly determined by the type of the second operand,
709 the table is sorted on the right operand instead of on the left.
710
711  Left      Right      Description and pseudocode
712  ===============================================================
713  Any       undef      check whether Any is undefined
714                 like: !defined Any
715
716  Any       Object     invoke ~~ overloading on Object, or die
717
718  Right operand is an ARRAY:
719
720  Left      Right      Description and pseudocode
721  ===============================================================
722  ARRAY1    ARRAY2     recurse on paired elements of ARRAY1 and ARRAY2[2]
723                 like: (ARRAY1[0] ~~ ARRAY2[0])
724                         && (ARRAY1[1] ~~ ARRAY2[1]) && ...
725  HASH      ARRAY      any ARRAY elements exist as HASH keys
726                 like: grep { exists HASH->{$_} } ARRAY
727  Regexp    ARRAY      any ARRAY elements pattern match Regexp
728                 like: grep { /Regexp/ } ARRAY
729  undef     ARRAY      undef in ARRAY
730                 like: grep { !defined } ARRAY
731  Any       ARRAY      smartmatch each ARRAY element[3]
732                 like: grep { Any ~~ $_ } ARRAY
733
734  Right operand is a HASH:
735
736  Left      Right      Description and pseudocode
737  ===============================================================
738  HASH1     HASH2      all same keys in both HASHes
739                 like: keys HASH1 ==
740                          grep { exists HASH2->{$_} } keys HASH1
741  ARRAY     HASH       any ARRAY elements exist as HASH keys
742                 like: grep { exists HASH->{$_} } ARRAY
743  Regexp    HASH       any HASH keys pattern match Regexp
744                 like: grep { /Regexp/ } keys HASH
745  undef     HASH       always false (undef can't be a key)
746                 like: 0 == 1
747  Any       HASH       HASH key existence
748                 like: exists HASH->{Any}
749
750  Right operand is CODE:
751
752  Left      Right      Description and pseudocode
753  ===============================================================
754  ARRAY     CODE       sub returns true on all ARRAY elements[1]
755                 like: !grep { !CODE->($_) } ARRAY
756  HASH      CODE       sub returns true on all HASH keys[1]
757                 like: !grep { !CODE->($_) } keys HASH
758  Any       CODE       sub passed Any returns true
759                 like: CODE->(Any)
760
761 Right operand is a Regexp:
762
763  Left      Right      Description and pseudocode
764  ===============================================================
765  ARRAY     Regexp     any ARRAY elements match Regexp
766                 like: grep { /Regexp/ } ARRAY
767  HASH      Regexp     any HASH keys match Regexp
768                 like: grep { /Regexp/ } keys HASH
769  Any       Regexp     pattern match
770                 like: Any =~ /Regexp/
771
772  Other:
773
774  Left      Right      Description and pseudocode
775  ===============================================================
776  Object    Any        invoke ~~ overloading on Object,
777                       or fall back to...
778
779  Any       Num        numeric equality
780                  like: Any == Num
781  Num       nummy[4]    numeric equality
782                  like: Num == nummy
783  undef     Any        check whether undefined
784                  like: !defined(Any)
785  Any       Any        string equality
786                  like: Any eq Any
787
788
789 Notes:
790
791 =over
792
793 =item 1.
794 Empty hashes or arrays match.
795
796 =item 2.
797 That is, each element smartmatches the element of the same index in the other array.[3]
798
799 =item 3.
800 If a circular reference is found, fall back to referential equality.
801
802 =item 4.
803 Either an actual number, or a string that looks like one.
804
805 =back
806
807 The smartmatch implicitly dereferences any non-blessed hash or array
808 reference, so the C<I<HASH>> and C<I<ARRAY>> entries apply in those cases.
809 For blessed references, the C<I<Object>> entries apply.  Smartmatches
810 involving hashes only consider hash keys, never hash values.
811
812 The "like" code entry is not always an exact rendition.  For example, the
813 smartmatch operator short-circuits whenever possible, but C<grep> does
814 not.  Also, C<grep> in scalar context returns the number of matches, but
815 C<~~> returns only true or false.
816
817 Unlike most operators, the smartmatch operator knows to treat C<undef>
818 specially:
819
820     use v5.10.1;
821     @array = (1, 2, 3, undef, 4, 5);
822     say "some elements undefined" if undef ~~ @array;
823
824 Each operand is considered in a modified scalar context, the modification
825 being that array and hash variables are passed by reference to the
826 operator, which implicitly dereferences them.  Both elements
827 of each pair are the same:
828
829     use v5.10.1;
830
831     my %hash = (red    => 1, blue   => 2, green  => 3,
832                 orange => 4, yellow => 5, purple => 6,
833                 black  => 7, grey   => 8, white  => 9);
834
835     my @array = qw(red blue green);
836
837     say "some array elements in hash keys" if  @array ~~  %hash;
838     say "some array elements in hash keys" if \@array ~~ \%hash;
839
840     say "red in array" if "red" ~~  @array;
841     say "red in array" if "red" ~~ \@array;
842
843     say "some keys end in e" if /e$/ ~~  %hash;
844     say "some keys end in e" if /e$/ ~~ \%hash;
845
846 Two arrays smartmatch if each element in the first array smartmatches
847 (that is, is "in") the corresponding element in the second array,
848 recursively.
849
850     use v5.10.1;
851     my @little = qw(red blue green);
852     my @bigger = ("red", "blue", [ "orange", "green" ] );
853     if (@little ~~ @bigger) {  # true!
854         say "little is contained in bigger";
855     }
856
857 Because the smartmatch operator recurses on nested arrays, this
858 will still report that "red" is in the array.
859
860     use v5.10.1;
861     my @array = qw(red blue green);
862     my $nested_array = [[[[[[[ @array ]]]]]]];
863     say "red in array" if "red" ~~ $nested_array;
864
865 If two arrays smartmatch each other, then they are deep
866 copies of each others' values, as this example reports:
867
868     use v5.12.0;
869     my @a = (0, 1, 2, [3, [4, 5], 6], 7);
870     my @b = (0, 1, 2, [3, [4, 5], 6], 7);
871
872     if (@a ~~ @b && @b ~~ @a) {
873         say "a and b are deep copies of each other";
874     }
875     elsif (@a ~~ @b) {
876         say "a smartmatches in b";
877     }
878     elsif (@b ~~ @a) {
879         say "b smartmatches in a";
880     }
881     else {
882         say "a and b don't smartmatch each other at all";
883     }
884
885
886 If you were to set S<C<$b[3] = 4>>, then instead of reporting that "a and b
887 are deep copies of each other", it now reports that C<"b smartmatches in a">.
888 That's because the corresponding position in C<@a> contains an array that
889 (eventually) has a 4 in it.
890
891 Smartmatching one hash against another reports whether both contain the
892 same keys, no more and no less.  This could be used to see whether two
893 records have the same field names, without caring what values those fields
894 might have.  For example:
895
896     use v5.10.1;
897     sub make_dogtag {
898         state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 };
899
900         my ($class, $init_fields) = @_;
901
902         die "Must supply (only) name, rank, and serial number"
903             unless $init_fields ~~ $REQUIRED_FIELDS;
904
905         ...
906     }
907
908 However, this only does what you mean if C<$init_fields> is indeed a hash
909 reference. The condition C<$init_fields ~~ $REQUIRED_FIELDS> also allows the
910 strings C<"name">, C<"rank">, C<"serial_num"> as well as any array reference
911 that contains C<"name"> or C<"rank"> or C<"serial_num"> anywhere to pass
912 through.
913
914 The smartmatch operator is most often used as the implicit operator of a
915 C<when> clause.  See the section on "Switch Statements" in L<perlsyn>.
916
917 =head3 Smartmatching of Objects
918
919 To avoid relying on an object's underlying representation, if the
920 smartmatch's right operand is an object that doesn't overload C<~~>,
921 it raises the exception "C<Smartmatching a non-overloaded object
922 breaks encapsulation>".  That's because one has no business digging
923 around to see whether something is "in" an object.  These are all
924 illegal on objects without a C<~~> overload:
925
926     %hash ~~ $object
927        42 ~~ $object
928    "fred" ~~ $object
929
930 However, you can change the way an object is smartmatched by overloading
931 the C<~~> operator.  This is allowed to
932 extend the usual smartmatch semantics.
933 For objects that do have an C<~~> overload, see L<overload>.
934
935 Using an object as the left operand is allowed, although not very useful.
936 Smartmatching rules take precedence over overloading, so even if the
937 object in the left operand has smartmatch overloading, this will be
938 ignored.  A left operand that is a non-overloaded object falls back on a
939 string or numeric comparison of whatever the C<ref> operator returns.  That
940 means that
941
942     $object ~~ X
943
944 does I<not> invoke the overload method with C<I<X>> as an argument.
945 Instead the above table is consulted as normal, and based on the type of
946 C<I<X>>, overloading may or may not be invoked.  For simple strings or
947 numbers, "in" becomes equivalent to this:
948
949     $object ~~ $number          ref($object) == $number
950     $object ~~ $string          ref($object) eq $string
951
952 For example, this reports that the handle smells IOish
953 (but please don't really do this!):
954
955     use IO::Handle;
956     my $fh = IO::Handle->new();
957     if ($fh ~~ /\bIO\b/) {
958         say "handle smells IOish";
959     }
960
961 That's because it treats C<$fh> as a string like
962 C<"IO::Handle=GLOB(0x8039e0)">, then pattern matches against that.
963
964 =head2 Bitwise And
965 X<operator, bitwise, and> X<bitwise and> X<&>
966
967 Binary C<"&"> returns its operands ANDed together bit by bit.  Although no
968 warning is currently raised, the result is not well defined when this operation
969 is performed on operands that aren't either numbers (see
970 L</Integer Arithmetic>) nor bitstrings (see L</Bitwise String Operators>).
971
972 Note that C<"&"> has lower priority than relational operators, so for example
973 the parentheses are essential in a test like
974
975     print "Even\n" if ($x & 1) == 0;
976
977 If the "bitwise" feature is enabled via S<C<use feature 'bitwise'>> or
978 C<use v5.28>, then this operator always treats its operands as numbers.
979 Before Perl 5.28 this feature produced a warning in the
980 C<"experimental::bitwise"> category.
981
982 =head2 Bitwise Or and Exclusive Or
983 X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor>
984 X<bitwise xor> X<^>
985
986 Binary C<"|"> returns its operands ORed together bit by bit.
987
988 Binary C<"^"> returns its operands XORed together bit by bit.
989
990 Although no warning is currently raised, the results are not well
991 defined when these operations are performed on operands that aren't either
992 numbers (see L</Integer Arithmetic>) nor bitstrings (see L</Bitwise String
993 Operators>).
994
995 Note that C<"|"> and C<"^"> have lower priority than relational operators, so
996 for example the parentheses are essential in a test like
997
998     print "false\n" if (8 | 2) != 10;
999
1000 If the "bitwise" feature is enabled via S<C<use feature 'bitwise'>> or
1001 C<use v5.28>, then this operator always treats its operands as numbers.
1002 Before Perl 5.28. this feature produced a warning in the
1003 C<"experimental::bitwise"> category.
1004
1005 =head2 C-style Logical And
1006 X<&&> X<logical and> X<operator, logical, and>
1007
1008 Binary C<"&&"> performs a short-circuit logical AND operation.  That is,
1009 if the left operand is false, the right operand is not even evaluated.
1010 Scalar or list context propagates down to the right operand if it
1011 is evaluated.
1012
1013 =head2 C-style Logical Or
1014 X<||> X<operator, logical, or>
1015
1016 Binary C<"||"> performs a short-circuit logical OR operation.  That is,
1017 if the left operand is true, the right operand is not even evaluated.
1018 Scalar or list context propagates down to the right operand if it
1019 is evaluated.
1020
1021 =head2 Logical Defined-Or
1022 X<//> X<operator, logical, defined-or>
1023
1024 Although it has no direct equivalent in C, Perl's C<//> operator is related
1025 to its C-style "or".  In fact, it's exactly the same as C<||>, except that it
1026 tests the left hand side's definedness instead of its truth.  Thus,
1027 S<C<< EXPR1 // EXPR2 >>> returns the value of C<< EXPR1 >> if it's defined,
1028 otherwise, the value of C<< EXPR2 >> is returned.
1029 (C<< EXPR1 >> is evaluated in scalar context, C<< EXPR2 >>
1030 in the context of C<< // >> itself).  Usually,
1031 this is the same result as S<C<< defined(EXPR1) ? EXPR1 : EXPR2 >>> (except that
1032 the ternary-operator form can be used as a lvalue, while S<C<< EXPR1 // EXPR2 >>>
1033 cannot).  This is very useful for
1034 providing default values for variables.  If you actually want to test if
1035 at least one of C<$x> and C<$y> is defined, use S<C<defined($x // $y)>>.
1036
1037 The C<||>, C<//> and C<&&> operators return the last value evaluated
1038 (unlike C's C<||> and C<&&>, which return 0 or 1).  Thus, a reasonably
1039 portable way to find out the home directory might be:
1040
1041     $home =  $ENV{HOME}
1042           // $ENV{LOGDIR}
1043           // (getpwuid($<))[7]
1044           // die "You're homeless!\n";
1045
1046 In particular, this means that you shouldn't use this
1047 for selecting between two aggregates for assignment:
1048
1049     @a = @b || @c;            # This doesn't do the right thing
1050     @a = scalar(@b) || @c;    # because it really means this.
1051     @a = @b ? @b : @c;        # This works fine, though.
1052
1053 As alternatives to C<&&> and C<||> when used for
1054 control flow, Perl provides the C<and> and C<or> operators (see below).
1055 The short-circuit behavior is identical.  The precedence of C<"and">
1056 and C<"or"> is much lower, however, so that you can safely use them after a
1057 list operator without the need for parentheses:
1058
1059     unlink "alpha", "beta", "gamma"
1060             or gripe(), next LINE;
1061
1062 With the C-style operators that would have been written like this:
1063
1064     unlink("alpha", "beta", "gamma")
1065             || (gripe(), next LINE);
1066
1067 It would be even more readable to write that this way:
1068
1069     unless(unlink("alpha", "beta", "gamma")) {
1070         gripe();
1071         next LINE;
1072     }
1073
1074 Using C<"or"> for assignment is unlikely to do what you want; see below.
1075
1076 =head2 Range Operators
1077 X<operator, range> X<range> X<..> X<...>
1078
1079 Binary C<".."> is the range operator, which is really two different
1080 operators depending on the context.  In list context, it returns a
1081 list of values counting (up by ones) from the left value to the right
1082 value.  If the left value is greater than the right value then it
1083 returns the empty list.  The range operator is useful for writing
1084 S<C<foreach (1..10)>> loops and for doing slice operations on arrays.  In
1085 the current implementation, no temporary array is created when the
1086 range operator is used as the expression in C<foreach> loops, but older
1087 versions of Perl might burn a lot of memory when you write something
1088 like this:
1089
1090     for (1 .. 1_000_000) {
1091         # code
1092     }
1093
1094 The range operator also works on strings, using the magical
1095 auto-increment, see below.
1096
1097 In scalar context, C<".."> returns a boolean value.  The operator is
1098 bistable, like a flip-flop, and emulates the line-range (comma)
1099 operator of B<sed>, B<awk>, and various editors.  Each C<".."> operator
1100 maintains its own boolean state, even across calls to a subroutine
1101 that contains it.  It is false as long as its left operand is false.
1102 Once the left operand is true, the range operator stays true until the
1103 right operand is true, I<AFTER> which the range operator becomes false
1104 again.  It doesn't become false till the next time the range operator
1105 is evaluated.  It can test the right operand and become false on the
1106 same evaluation it became true (as in B<awk>), but it still returns
1107 true once.  If you don't want it to test the right operand until the
1108 next evaluation, as in B<sed>, just use three dots (C<"...">) instead of
1109 two.  In all other regards, C<"..."> behaves just like C<".."> does.
1110
1111 The right operand is not evaluated while the operator is in the
1112 "false" state, and the left operand is not evaluated while the
1113 operator is in the "true" state.  The precedence is a little lower
1114 than || and &&.  The value returned is either the empty string for
1115 false, or a sequence number (beginning with 1) for true.  The sequence
1116 number is reset for each range encountered.  The final sequence number
1117 in a range has the string C<"E0"> appended to it, which doesn't affect
1118 its numeric value, but gives you something to search for if you want
1119 to exclude the endpoint.  You can exclude the beginning point by
1120 waiting for the sequence number to be greater than 1.
1121
1122 If either operand of scalar C<".."> is a constant expression,
1123 that operand is considered true if it is equal (C<==>) to the current
1124 input line number (the C<$.> variable).
1125
1126 To be pedantic, the comparison is actually S<C<int(EXPR) == int(EXPR)>>,
1127 but that is only an issue if you use a floating point expression; when
1128 implicitly using C<$.> as described in the previous paragraph, the
1129 comparison is S<C<int(EXPR) == int($.)>> which is only an issue when C<$.>
1130 is set to a floating point value and you are not reading from a file.
1131 Furthermore, S<C<"span" .. "spat">> or S<C<2.18 .. 3.14>> will not do what
1132 you want in scalar context because each of the operands are evaluated
1133 using their integer representation.
1134
1135 Examples:
1136
1137 As a scalar operator:
1138
1139     if (101 .. 200) { print; } # print 2nd hundred lines, short for
1140                                #  if ($. == 101 .. $. == 200) { print; }
1141
1142     next LINE if (1 .. /^$/);  # skip header lines, short for
1143                                #   next LINE if ($. == 1 .. /^$/);
1144                                # (typically in a loop labeled LINE)
1145
1146     s/^/> / if (/^$/ .. eof());  # quote body
1147
1148     # parse mail messages
1149     while (<>) {
1150         $in_header =   1  .. /^$/;
1151         $in_body   = /^$/ .. eof;
1152         if ($in_header) {
1153             # do something
1154         } else { # in body
1155             # do something else
1156         }
1157     } continue {
1158         close ARGV if eof;             # reset $. each file
1159     }
1160
1161 Here's a simple example to illustrate the difference between
1162 the two range operators:
1163
1164     @lines = ("   - Foo",
1165               "01 - Bar",
1166               "1  - Baz",
1167               "   - Quux");
1168
1169     foreach (@lines) {
1170         if (/0/ .. /1/) {
1171             print "$_\n";
1172         }
1173     }
1174
1175 This program will print only the line containing "Bar".  If
1176 the range operator is changed to C<...>, it will also print the
1177 "Baz" line.
1178
1179 And now some examples as a list operator:
1180
1181     for (101 .. 200) { print }      # print $_ 100 times
1182     @foo = @foo[0 .. $#foo];        # an expensive no-op
1183     @foo = @foo[$#foo-4 .. $#foo];  # slice last 5 items
1184
1185 Because each operand is evaluated in integer form, S<C<2.18 .. 3.14>> will
1186 return two elements in list context.
1187
1188     @list = (2.18 .. 3.14); # same as @list = (2 .. 3);
1189
1190 The range operator in list context can make use of the magical
1191 auto-increment algorithm if both operands are strings, subject to the
1192 following rules:
1193
1194 =over
1195
1196 =item *
1197
1198 With one exception (below), if both strings look like numbers to Perl,
1199 the magic increment will not be applied, and the strings will be treated
1200 as numbers (more specifically, integers) instead.
1201
1202 For example, C<"-2".."2"> is the same as C<-2..2>, and
1203 C<"2.18".."3.14"> produces C<2, 3>.
1204
1205 =item *
1206
1207 The exception to the above rule is when the left-hand string begins with
1208 C<0> and is longer than one character, in this case the magic increment
1209 I<will> be applied, even though strings like C<"01"> would normally look
1210 like a number to Perl.
1211
1212 For example, C<"01".."04"> produces C<"01", "02", "03", "04">, and
1213 C<"00".."-1"> produces C<"00"> through C<"99"> - this may seem
1214 surprising, but see the following rules for why it works this way.
1215 To get dates with leading zeros, you can say:
1216
1217     @z2 = ("01" .. "31");
1218     print $z2[$mday];
1219
1220 If you want to force strings to be interpreted as numbers, you could say
1221
1222     @numbers = ( 0+$first .. 0+$last );
1223
1224 B<Note:> In Perl versions 5.30 and below, I<any> string on the left-hand
1225 side beginning with C<"0">, including the string C<"0"> itself, would
1226 cause the magic string increment behavior. This means that on these Perl
1227 versions, C<"0".."-1"> would produce C<"0"> through C<"99">, which was
1228 inconsistent with C<0..-1>, which produces the empty list. This also means
1229 that C<"0".."9"> now produces a list of integers instead of a list of
1230 strings.
1231
1232 =item *
1233
1234 If the initial value specified isn't part of a magical increment
1235 sequence (that is, a non-empty string matching C</^[a-zA-Z]*[0-9]*\z/>),
1236 only the initial value will be returned.
1237
1238 For example, C<"ax".."az"> produces C<"ax", "ay", "az">, but
1239 C<"*x".."az"> produces only C<"*x">.
1240
1241 =item *
1242
1243 For other initial values that are strings that do follow the rules of the
1244 magical increment, the corresponding sequence will be returned.
1245
1246 For example, you can say
1247
1248     @alphabet = ("A" .. "Z");
1249
1250 to get all normal letters of the English alphabet, or
1251
1252     $hexdigit = (0 .. 9, "a" .. "f")[$num & 15];
1253
1254 to get a hexadecimal digit.
1255
1256 =item *
1257
1258 If the final value specified is not in the sequence that the magical
1259 increment would produce, the sequence goes until the next value would
1260 be longer than the final value specified. If the length of the final
1261 string is shorter than the first, the empty list is returned.
1262
1263 For example, C<"a".."--"> is the same as C<"a".."zz">, C<"0".."xx">
1264 produces C<"0"> through C<"99">, and C<"aaa".."--"> returns the empty
1265 list.
1266
1267 =back
1268
1269 As of Perl 5.26, the list-context range operator on strings works as expected
1270 in the scope of L<< S<C<"use feature 'unicode_strings">>|feature/The
1271 'unicode_strings' feature >>. In previous versions, and outside the scope of
1272 that feature, it exhibits L<perlunicode/The "Unicode Bug">: its behavior
1273 depends on the internal encoding of the range endpoint.
1274
1275 Because the magical increment only works on non-empty strings matching
1276 C</^[a-zA-Z]*[0-9]*\z/>, the following will only return an alpha:
1277
1278     use charnames "greek";
1279     my @greek_small =  ("\N{alpha}" .. "\N{omega}");
1280
1281 To get the 25 traditional lowercase Greek letters, including both sigmas,
1282 you could use this instead:
1283
1284     use charnames "greek";
1285     my @greek_small =  map { chr } ( ord("\N{alpha}")
1286                                         ..
1287                                      ord("\N{omega}")
1288                                    );
1289
1290 However, because there are I<many> other lowercase Greek characters than
1291 just those, to match lowercase Greek characters in a regular expression,
1292 you could use the pattern C</(?:(?=\p{Greek})\p{Lower})+/> (or the
1293 L<experimental feature|perlrecharclass/Extended Bracketed Character
1294 Classes> C<S</(?[ \p{Greek} & \p{Lower} ])+/>>).
1295
1296 =head2 Conditional Operator
1297 X<operator, conditional> X<operator, ternary> X<ternary> X<?:>
1298
1299 Ternary C<"?:"> is the conditional operator, just as in C.  It works much
1300 like an if-then-else.  If the argument before the C<?> is true, the
1301 argument before the C<:> is returned, otherwise the argument after the
1302 C<:> is returned.  For example:
1303
1304     printf "I have %d dog%s.\n", $n,
1305             ($n == 1) ? "" : "s";
1306
1307 Scalar or list context propagates downward into the 2nd
1308 or 3rd argument, whichever is selected.
1309
1310     $x = $ok ? $y : $z;  # get a scalar
1311     @x = $ok ? @y : @z;  # get an array
1312     $x = $ok ? @y : @z;  # oops, that's just a count!
1313
1314 The operator may be assigned to if both the 2nd and 3rd arguments are
1315 legal lvalues (meaning that you can assign to them):
1316
1317     ($x_or_y ? $x : $y) = $z;
1318
1319 Because this operator produces an assignable result, using assignments
1320 without parentheses will get you in trouble.  For example, this:
1321
1322     $x % 2 ? $x += 10 : $x += 2
1323
1324 Really means this:
1325
1326     (($x % 2) ? ($x += 10) : $x) += 2
1327
1328 Rather than this:
1329
1330     ($x % 2) ? ($x += 10) : ($x += 2)
1331
1332 That should probably be written more simply as:
1333
1334     $x += ($x % 2) ? 10 : 2;
1335
1336 =head2 Assignment Operators
1337 X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=>
1338 X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=>
1339 X<%=> X<^=> X<x=> X<&.=> X<|.=> X<^.=>
1340
1341 C<"="> is the ordinary assignment operator.
1342
1343 Assignment operators work as in C.  That is,
1344
1345     $x += 2;
1346
1347 is equivalent to
1348
1349     $x = $x + 2;
1350
1351 although without duplicating any side effects that dereferencing the lvalue
1352 might trigger, such as from C<tie()>.  Other assignment operators work similarly.
1353 The following are recognized:
1354
1355     **=    +=    *=    &=    &.=    <<=    &&=
1356            -=    /=    |=    |.=    >>=    ||=
1357            .=    %=    ^=    ^.=           //=
1358                  x=
1359
1360 Although these are grouped by family, they all have the precedence
1361 of assignment.  These combined assignment operators can only operate on
1362 scalars, whereas the ordinary assignment operator can assign to arrays,
1363 hashes, lists and even references.  (See L<"Context"|perldata/Context>
1364 and L<perldata/List value constructors>, and L<perlref/Assigning to
1365 References>.)
1366
1367 Unlike in C, the scalar assignment operator produces a valid lvalue.
1368 Modifying an assignment is equivalent to doing the assignment and
1369 then modifying the variable that was assigned to.  This is useful
1370 for modifying a copy of something, like this:
1371
1372     ($tmp = $global) =~ tr/13579/24680/;
1373
1374 Although as of 5.14, that can be also be accomplished this way:
1375
1376     use v5.14;
1377     $tmp = ($global =~  tr/13579/24680/r);
1378
1379 Likewise,
1380
1381     ($x += 2) *= 3;
1382
1383 is equivalent to
1384
1385     $x += 2;
1386     $x *= 3;
1387
1388 Similarly, a list assignment in list context produces the list of
1389 lvalues assigned to, and a list assignment in scalar context returns
1390 the number of elements produced by the expression on the right hand
1391 side of the assignment.
1392
1393 The three dotted bitwise assignment operators (C<&.=> C<|.=> C<^.=>) are new in
1394 Perl 5.22.  See L</Bitwise String Operators>.
1395
1396 =head2 Comma Operator
1397 X<comma> X<operator, comma> X<,>
1398
1399 Binary C<","> is the comma operator.  In scalar context it evaluates
1400 its left argument, throws that value away, then evaluates its right
1401 argument and returns that value.  This is just like C's comma operator.
1402
1403 In list context, it's just the list argument separator, and inserts
1404 both its arguments into the list.  These arguments are also evaluated
1405 from left to right.
1406
1407 The C<< => >> operator (sometimes pronounced "fat comma") is a synonym
1408 for the comma except that it causes a
1409 word on its left to be interpreted as a string if it begins with a letter
1410 or underscore and is composed only of letters, digits and underscores.
1411 This includes operands that might otherwise be interpreted as operators,
1412 constants, single number v-strings or function calls.  If in doubt about
1413 this behavior, the left operand can be quoted explicitly.
1414
1415 Otherwise, the C<< => >> operator behaves exactly as the comma operator
1416 or list argument separator, according to context.
1417
1418 For example:
1419
1420     use constant FOO => "something";
1421
1422     my %h = ( FOO => 23 );
1423
1424 is equivalent to:
1425
1426     my %h = ("FOO", 23);
1427
1428 It is I<NOT>:
1429
1430     my %h = ("something", 23);
1431
1432 The C<< => >> operator is helpful in documenting the correspondence
1433 between keys and values in hashes, and other paired elements in lists.
1434
1435     %hash = ( $key => $value );
1436     login( $username => $password );
1437
1438 The special quoting behavior ignores precedence, and hence may apply to
1439 I<part> of the left operand:
1440
1441     print time.shift => "bbb";
1442
1443 That example prints something like C<"1314363215shiftbbb">, because the
1444 C<< => >> implicitly quotes the C<shift> immediately on its left, ignoring
1445 the fact that C<time.shift> is the entire left operand.
1446
1447 =head2 List Operators (Rightward)
1448 X<operator, list, rightward> X<list operator>
1449
1450 On the right side of a list operator, the comma has very low precedence,
1451 such that it controls all comma-separated expressions found there.
1452 The only operators with lower precedence are the logical operators
1453 C<"and">, C<"or">, and C<"not">, which may be used to evaluate calls to list
1454 operators without the need for parentheses:
1455
1456     open HANDLE, "< :encoding(UTF-8)", "filename"
1457         or die "Can't open: $!\n";
1458
1459 However, some people find that code harder to read than writing
1460 it with parentheses:
1461
1462     open(HANDLE, "< :encoding(UTF-8)", "filename")
1463         or die "Can't open: $!\n";
1464
1465 in which case you might as well just use the more customary C<"||"> operator:
1466
1467     open(HANDLE, "< :encoding(UTF-8)", "filename")
1468         || die "Can't open: $!\n";
1469
1470 See also discussion of list operators in L</Terms and List Operators (Leftward)>.
1471
1472 =head2 Logical Not
1473 X<operator, logical, not> X<not>
1474
1475 Unary C<"not"> returns the logical negation of the expression to its right.
1476 It's the equivalent of C<"!"> except for the very low precedence.
1477
1478 =head2 Logical And
1479 X<operator, logical, and> X<and>
1480
1481 Binary C<"and"> returns the logical conjunction of the two surrounding
1482 expressions.  It's equivalent to C<&&> except for the very low
1483 precedence.  This means that it short-circuits: the right
1484 expression is evaluated only if the left expression is true.
1485
1486 =head2 Logical or and Exclusive Or
1487 X<operator, logical, or> X<operator, logical, xor>
1488 X<operator, logical, exclusive or>
1489 X<or> X<xor>
1490
1491 Binary C<"or"> returns the logical disjunction of the two surrounding
1492 expressions.  It's equivalent to C<||> except for the very low precedence.
1493 This makes it useful for control flow:
1494
1495     print FH $data              or die "Can't write to FH: $!";
1496
1497 This means that it short-circuits: the right expression is evaluated
1498 only if the left expression is false.  Due to its precedence, you must
1499 be careful to avoid using it as replacement for the C<||> operator.
1500 It usually works out better for flow control than in assignments:
1501
1502     $x = $y or $z;              # bug: this is wrong
1503     ($x = $y) or $z;            # really means this
1504     $x = $y || $z;              # better written this way
1505
1506 However, when it's a list-context assignment and you're trying to use
1507 C<||> for control flow, you probably need C<"or"> so that the assignment
1508 takes higher precedence.
1509
1510     @info = stat($file) || die;     # oops, scalar sense of stat!
1511     @info = stat($file) or die;     # better, now @info gets its due
1512
1513 Then again, you could always use parentheses.
1514
1515 Binary C<"xor"> returns the exclusive-OR of the two surrounding expressions.
1516 It cannot short-circuit (of course).
1517
1518 There is no low precedence operator for defined-OR.
1519
1520 =head2 C Operators Missing From Perl
1521 X<operator, missing from perl> X<&> X<*>
1522 X<typecasting> X<(TYPE)>
1523
1524 Here is what C has that Perl doesn't:
1525
1526 =over 8
1527
1528 =item unary &
1529
1530 Address-of operator.  (But see the C<"\"> operator for taking a reference.)
1531
1532 =item unary *
1533
1534 Dereference-address operator.  (Perl's prefix dereferencing
1535 operators are typed: C<$>, C<@>, C<%>, and C<&>.)
1536
1537 =item (TYPE)
1538
1539 Type-casting operator.
1540
1541 =back
1542
1543 =head2 Quote and Quote-like Operators
1544 X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m>
1545 X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>>
1546 X<escape sequence> X<escape>
1547
1548 While we usually think of quotes as literal values, in Perl they
1549 function as operators, providing various kinds of interpolating and
1550 pattern matching capabilities.  Perl provides customary quote characters
1551 for these behaviors, but also provides a way for you to choose your
1552 quote character for any of them.  In the following table, a C<{}> represents
1553 any pair of delimiters you choose.
1554
1555     Customary  Generic        Meaning        Interpolates
1556         ''       q{}          Literal             no
1557         ""      qq{}          Literal             yes
1558         ``      qx{}          Command             yes*
1559                 qw{}         Word list            no
1560         //       m{}       Pattern match          yes*
1561                 qr{}          Pattern             yes*
1562                  s{}{}      Substitution          yes*
1563                 tr{}{}    Transliteration         no (but see below)
1564                  y{}{}    Transliteration         no (but see below)
1565         <<EOF                 here-doc            yes*
1566
1567         * unless the delimiter is ''.
1568
1569 Non-bracketing delimiters use the same character fore and aft, but the four
1570 sorts of ASCII brackets (round, angle, square, curly) all nest, which means
1571 that
1572
1573     q{foo{bar}baz}
1574
1575 is the same as
1576
1577     'foo{bar}baz'
1578
1579 Note, however, that this does not always work for quoting Perl code:
1580
1581     $s = q{ if($x eq "}") ... }; # WRONG
1582
1583 is a syntax error.  The C<L<Text::Balanced>> module (standard as of v5.8,
1584 and from CPAN before then) is able to do this properly.
1585
1586 There can (and in some cases, must) be whitespace between the operator
1587 and the quoting
1588 characters, except when C<#> is being used as the quoting character.
1589 C<q#foo#> is parsed as the string C<foo>, while S<C<q #foo#>> is the
1590 operator C<q> followed by a comment.  Its argument will be taken
1591 from the next line.  This allows you to write:
1592
1593     s {foo}  # Replace foo
1594       {bar}  # with bar.
1595
1596 The cases where whitespace must be used are when the quoting character
1597 is a word character (meaning it matches C</\w/>):
1598
1599     q XfooX # Works: means the string 'foo'
1600     qXfooX  # WRONG!
1601
1602 The following escape sequences are available in constructs that interpolate,
1603 and in transliterations whose delimiters aren't single quotes (C<"'">).
1604 In all the ones with braces, any number of blanks and/or tabs adjoining
1605 and within the braces are allowed (and ignored).
1606 X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N> X<\N{}>
1607 X<\o{}>
1608
1609     Sequence     Note  Description
1610     \t                  tab               (HT, TAB)
1611     \n                  newline           (NL)
1612     \r                  return            (CR)
1613     \f                  form feed         (FF)
1614     \b                  backspace         (BS)
1615     \a                  alarm (bell)      (BEL)
1616     \e                  escape            (ESC)
1617     \x{263A}     [1,8]  hex char          (example shown: SMILEY)
1618     \x{ 263A }          Same, but shows optional blanks inside and
1619                         adjoining the braces
1620     \x1b         [2,8]  restricted range hex char (example: ESC)
1621     \N{name}     [3]    named Unicode character or character sequence
1622     \N{U+263D}   [4,8]  Unicode character (example: FIRST QUARTER MOON)
1623     \c[          [5]    control char      (example: chr(27))
1624     \o{23072}    [6,8]  octal char        (example: SMILEY)
1625     \033         [7,8]  restricted range octal char  (example: ESC)
1626
1627 Note that any escape sequence using braces inside interpolated
1628 constructs may have optional blanks (tab or space characters) adjoining
1629 with and inside of the braces, as illustrated above by the second
1630 S<C<\x{ }>> example.
1631
1632 =over 4
1633
1634 =item [1]
1635
1636 The result is the character specified by the hexadecimal number between
1637 the braces.  See L</[8]> below for details on which character.
1638
1639 Blanks (tab or space characters) may separate the number from either or
1640 both of the braces.
1641
1642 Otherwise, only hexadecimal digits are valid between the braces.  If an
1643 invalid character is encountered, a warning will be issued and the
1644 invalid character and all subsequent characters (valid or invalid)
1645 within the braces will be discarded.
1646
1647 If there are no valid digits between the braces, the generated character is
1648 the NULL character (C<\x{00}>).  However, an explicit empty brace (C<\x{}>)
1649 will not cause a warning (currently).
1650
1651 =item [2]
1652
1653 The result is the character specified by the hexadecimal number in the range
1654 0x00 to 0xFF.  See L</[8]> below for details on which character.
1655
1656 Only hexadecimal digits are valid following C<\x>.  When C<\x> is followed
1657 by fewer than two valid digits, any valid digits will be zero-padded.  This
1658 means that C<\x7> will be interpreted as C<\x07>, and a lone C<"\x"> will be
1659 interpreted as C<\x00>.  Except at the end of a string, having fewer than
1660 two valid digits will result in a warning.  Note that although the warning
1661 says the illegal character is ignored, it is only ignored as part of the
1662 escape and will still be used as the subsequent character in the string.
1663 For example:
1664
1665   Original    Result    Warns?
1666   "\x7"       "\x07"    no
1667   "\x"        "\x00"    no
1668   "\x7q"      "\x07q"   yes
1669   "\xq"       "\x00q"   yes
1670
1671 =item [3]
1672
1673 The result is the Unicode character or character sequence given by I<name>.
1674 See L<charnames>.
1675
1676 =item [4]
1677
1678 S<C<\N{U+I<hexadecimal number>}>> means the Unicode character whose Unicode code
1679 point is I<hexadecimal number>.
1680
1681 =item [5]
1682
1683 The character following C<\c> is mapped to some other character as shown in the
1684 table:
1685
1686  Sequence   Value
1687    \c@      chr(0)
1688    \cA      chr(1)
1689    \ca      chr(1)
1690    \cB      chr(2)
1691    \cb      chr(2)
1692    ...
1693    \cZ      chr(26)
1694    \cz      chr(26)
1695    \c[      chr(27)
1696                      # See below for chr(28)
1697    \c]      chr(29)
1698    \c^      chr(30)
1699    \c_      chr(31)
1700    \c?      chr(127) # (on ASCII platforms; see below for link to
1701                      #  EBCDIC discussion)
1702
1703 In other words, it's the character whose code point has had 64 xor'd with
1704 its uppercase.  C<\c?> is DELETE on ASCII platforms because
1705 S<C<ord("?") ^ 64>> is 127, and
1706 C<\c@> is NULL because the ord of C<"@"> is 64, so xor'ing 64 itself produces 0.
1707
1708 Also, C<\c\I<X>> yields S<C< chr(28) . "I<X>">> for any I<X>, but cannot come at the
1709 end of a string, because the backslash would be parsed as escaping the end
1710 quote.
1711
1712 On ASCII platforms, the resulting characters from the list above are the
1713 complete set of ASCII controls.  This isn't the case on EBCDIC platforms; see
1714 L<perlebcdic/OPERATOR DIFFERENCES> for a full discussion of the
1715 differences between these for ASCII versus EBCDIC platforms.
1716
1717 Use of any other character following the C<"c"> besides those listed above is
1718 discouraged, and as of Perl v5.20, the only characters actually allowed
1719 are the printable ASCII ones, minus the left brace C<"{">.  What happens
1720 for any of the allowed other characters is that the value is derived by
1721 xor'ing with the seventh bit, which is 64, and a warning raised if
1722 enabled.  Using the non-allowed characters generates a fatal error.
1723
1724 To get platform independent controls, you can use C<\N{...}>.
1725
1726 =item [6]
1727
1728 The result is the character specified by the octal number between the braces.
1729 See L</[8]> below for details on which character.
1730
1731 Blanks (tab or space characters) may separate the number from either or
1732 both of the braces.
1733
1734 Otherwise, if a character that isn't an octal digit is encountered, a
1735 warning is raised, and the value is based on the octal digits before it,
1736 discarding it and all following characters up to the closing brace.  It
1737 is a fatal error if there are no octal digits at all.
1738
1739 =item [7]
1740
1741 The result is the character specified by the three-digit octal number in the
1742 range 000 to 777 (but best to not use above 077, see next paragraph).  See
1743 L</[8]> below for details on which character.
1744
1745 Some contexts allow 2 or even 1 digit, but any usage without exactly
1746 three digits, the first being a zero, may give unintended results.  (For
1747 example, in a regular expression it may be confused with a backreference;
1748 see L<perlrebackslash/Octal escapes>.)  Starting in Perl 5.14, you may
1749 use C<\o{}> instead, which avoids all these problems.  Otherwise, it is best to
1750 use this construct only for ordinals C<\077> and below, remembering to pad to
1751 the left with zeros to make three digits.  For larger ordinals, either use
1752 C<\o{}>, or convert to something else, such as to hex and use C<\N{U+}>
1753 (which is portable between platforms with different character sets) or
1754 C<\x{}> instead.
1755
1756 =item [8]
1757
1758 Several constructs above specify a character by a number.  That number
1759 gives the character's position in the character set encoding (indexed from 0).
1760 This is called synonymously its ordinal, code position, or code point.  Perl
1761 works on platforms that have a native encoding currently of either ASCII/Latin1
1762 or EBCDIC, each of which allow specification of 256 characters.  In general, if
1763 the number is 255 (0xFF, 0377) or below, Perl interprets this in the platform's
1764 native encoding.  If the number is 256 (0x100, 0400) or above, Perl interprets
1765 it as a Unicode code point and the result is the corresponding Unicode
1766 character.  For example C<\x{50}> and C<\o{120}> both are the number 80 in
1767 decimal, which is less than 256, so the number is interpreted in the native
1768 character set encoding.  In ASCII the character in the 80th position (indexed
1769 from 0) is the letter C<"P">, and in EBCDIC it is the ampersand symbol C<"&">.
1770 C<\x{100}> and C<\o{400}> are both 256 in decimal, so the number is interpreted
1771 as a Unicode code point no matter what the native encoding is.  The name of the
1772 character in the 256th position (indexed by 0) in Unicode is
1773 C<LATIN CAPITAL LETTER A WITH MACRON>.
1774
1775 An exception to the above rule is that S<C<\N{U+I<hex number>}>> is
1776 always interpreted as a Unicode code point, so that C<\N{U+0050}> is C<"P"> even
1777 on EBCDIC platforms.
1778
1779 =back
1780
1781 B<NOTE>: Unlike C and other languages, Perl has no C<\v> escape sequence for
1782 the vertical tab (VT, which is 11 in both ASCII and EBCDIC), but you may
1783 use C<\N{VT}>, C<\ck>, C<\N{U+0b}>, or C<\x0b>.  (C<\v>
1784 does have meaning in regular expression patterns in Perl, see L<perlre>.)
1785
1786 The following escape sequences are available in constructs that interpolate,
1787 but not in transliterations.
1788 X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q> X<\F>
1789
1790     \l          lowercase next character only
1791     \u          titlecase (not uppercase!) next character only
1792     \L          lowercase all characters till \E or end of string
1793     \U          uppercase all characters till \E or end of string
1794     \F          foldcase all characters till \E or end of string
1795     \Q          quote (disable) pattern metacharacters till \E or
1796                 end of string
1797     \E          end either case modification or quoted section
1798                 (whichever was last seen)
1799
1800 See L<perlfunc/quotemeta> for the exact definition of characters that
1801 are quoted by C<\Q>.
1802
1803 C<\L>, C<\U>, C<\F>, and C<\Q> can stack, in which case you need one
1804 C<\E> for each.  For example:
1805
1806  say"This \Qquoting \ubusiness \Uhere isn't quite\E done yet,\E is it?";
1807  This quoting\ Business\ HERE\ ISN\'T\ QUITE\ done\ yet\, is it?
1808
1809 If a S<C<use locale>> form that includes C<LC_CTYPE> is in effect (see
1810 L<perllocale>), the case map used by C<\l>, C<\L>, C<\u>, and C<\U> is
1811 taken from the current locale.  If Unicode (for example, C<\N{}> or code
1812 points of 0x100 or beyond) is being used, the case map used by C<\l>,
1813 C<\L>, C<\u>, and C<\U> is as defined by Unicode.  That means that
1814 case-mapping a single character can sometimes produce a sequence of
1815 several characters.
1816 Under S<C<use locale>>, C<\F> produces the same results as C<\L>
1817 for all locales but a UTF-8 one, where it instead uses the Unicode
1818 definition.
1819
1820 All systems use the virtual C<"\n"> to represent a line terminator,
1821 called a "newline".  There is no such thing as an unvarying, physical
1822 newline character.  It is only an illusion that the operating system,
1823 device drivers, C libraries, and Perl all conspire to preserve.  Not all
1824 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
1825 on the ancient Macs (pre-MacOS X) of yesteryear, these used to be reversed,
1826 and on systems without a line terminator,
1827 printing C<"\n"> might emit no actual data.  In general, use C<"\n"> when
1828 you mean a "newline" for your system, but use the literal ASCII when you
1829 need an exact character.  For example, most networking protocols expect
1830 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
1831 and although they often accept just C<"\012">, they seldom tolerate just
1832 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
1833 you may be burned some day.
1834 X<newline> X<line terminator> X<eol> X<end of line>
1835 X<\n> X<\r> X<\r\n>
1836
1837 For constructs that do interpolate, variables beginning with "C<$>"
1838 or "C<@>" are interpolated.  Subscripted variables such as C<$a[3]> or
1839 C<< $href->{key}[0] >> are also interpolated, as are array and hash slices.
1840 But method calls such as C<< $obj->meth >> are not.
1841
1842 Interpolating an array or slice interpolates the elements in order,
1843 separated by the value of C<$">, so is equivalent to interpolating
1844 S<C<join $", @array>>.  "Punctuation" arrays such as C<@*> are usually
1845 interpolated only if the name is enclosed in braces C<@{*}>, but the
1846 arrays C<@_>, C<@+>, and C<@-> are interpolated even without braces.
1847
1848 For double-quoted strings, the quoting from C<\Q> is applied after
1849 interpolation and escapes are processed.
1850
1851     "abc\Qfoo\tbar$s\Exyz"
1852
1853 is equivalent to
1854
1855     "abc" . quotemeta("foo\tbar$s") . "xyz"
1856
1857 For the pattern of regex operators (C<qr//>, C<m//> and C<s///>),
1858 the quoting from C<\Q> is applied after interpolation is processed,
1859 but before escapes are processed.  This allows the pattern to match
1860 literally (except for C<$> and C<@>).  For example, the following matches:
1861
1862     '\s\t' =~ /\Q\s\t/
1863
1864 Because C<$> or C<@> trigger interpolation, you'll need to use something
1865 like C</\Quser\E\@\Qhost/> to match them literally.
1866
1867 Patterns are subject to an additional level of interpretation as a
1868 regular expression.  This is done as a second pass, after variables are
1869 interpolated, so that regular expressions may be incorporated into the
1870 pattern from the variables.  If this is not what you want, use C<\Q> to
1871 interpolate a variable literally.
1872
1873 Apart from the behavior described above, Perl does not expand
1874 multiple levels of interpolation.  In particular, contrary to the
1875 expectations of shell programmers, back-quotes do I<NOT> interpolate
1876 within double quotes, nor do single quotes impede evaluation of
1877 variables when used within double quotes.
1878
1879 =head2 Regexp Quote-Like Operators
1880 X<operator, regexp>
1881
1882 Here are the quote-like operators that apply to pattern
1883 matching and related activities.
1884
1885 =over 8
1886
1887 =item C<qr/I<STRING>/msixpodualn>
1888 X<qr> X</i> X</m> X</o> X</s> X</x> X</p>
1889
1890 This operator quotes (and possibly compiles) its I<STRING> as a regular
1891 expression.  I<STRING> is interpolated the same way as I<PATTERN>
1892 in C<m/I<PATTERN>/>.  If C<"'"> is used as the delimiter, no variable
1893 interpolation is done.  Returns a Perl value which may be used instead of the
1894 corresponding C</I<STRING>/msixpodualn> expression.  The returned value is a
1895 normalized version of the original pattern.  It magically differs from
1896 a string containing the same characters: C<ref(qr/x/)> returns "Regexp";
1897 however, dereferencing it is not well defined (you currently get the
1898 normalized version of the original pattern, but this may change).
1899
1900
1901 For example,
1902
1903     $rex = qr/my.STRING/is;
1904     print $rex;                 # prints (?si-xm:my.STRING)
1905     s/$rex/foo/;
1906
1907 is equivalent to
1908
1909     s/my.STRING/foo/is;
1910
1911 The result may be used as a subpattern in a match:
1912
1913     $re = qr/$pattern/;
1914     $string =~ /foo${re}bar/;   # can be interpolated in other
1915                                 # patterns
1916     $string =~ $re;             # or used standalone
1917     $string =~ /$re/;           # or this way
1918
1919 Since Perl may compile the pattern at the moment of execution of the C<qr()>
1920 operator, using C<qr()> may have speed advantages in some situations,
1921 notably if the result of C<qr()> is used standalone:
1922
1923     sub match {
1924         my $patterns = shift;
1925         my @compiled = map qr/$_/i, @$patterns;
1926         grep {
1927             my $success = 0;
1928             foreach my $pat (@compiled) {
1929                 $success = 1, last if /$pat/;
1930             }
1931             $success;
1932         } @_;
1933     }
1934
1935 Precompilation of the pattern into an internal representation at
1936 the moment of C<qr()> avoids the need to recompile the pattern every
1937 time a match C</$pat/> is attempted.  (Perl has many other internal
1938 optimizations, but none would be triggered in the above example if
1939 we did not use C<qr()> operator.)
1940
1941 Options (specified by the following modifiers) are:
1942
1943     m   Treat string as multiple lines.
1944     s   Treat string as single line. (Make . match a newline)
1945     i   Do case-insensitive pattern matching.
1946     x   Use extended regular expressions; specifying two
1947         x's means \t and the SPACE character are ignored within
1948         square-bracketed character classes
1949     p   When matching preserve a copy of the matched string so
1950         that ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} will be
1951         defined (ignored starting in v5.20) as these are always
1952         defined starting in that release
1953     o   Compile pattern only once.
1954     a   ASCII-restrict: Use ASCII for \d, \s, \w and [[:posix:]]
1955         character classes; specifying two a's adds the further
1956         restriction that no ASCII character will match a
1957         non-ASCII one under /i.
1958     l   Use the current run-time locale's rules.
1959     u   Use Unicode rules.
1960     d   Use Unicode or native charset, as in 5.12 and earlier.
1961     n   Non-capture mode. Don't let () fill in $1, $2, etc...
1962
1963 If a precompiled pattern is embedded in a larger pattern then the effect
1964 of C<"msixpluadn"> will be propagated appropriately.  The effect that the
1965 C</o> modifier has is not propagated, being restricted to those patterns
1966 explicitly using it.
1967
1968 The C</a>, C</d>, C</l>, and C</u> modifiers (added in Perl 5.14)
1969 control the character set rules, but C</a> is the only one you are likely
1970 to want to specify explicitly; the other three are selected
1971 automatically by various pragmas.
1972
1973 See L<perlre> for additional information on valid syntax for I<STRING>, and
1974 for a detailed look at the semantics of regular expressions.  In
1975 particular, all modifiers except the largely obsolete C</o> are further
1976 explained in L<perlre/Modifiers>.  C</o> is described in the next section.
1977
1978 =item C<m/I<PATTERN>/msixpodualngc>
1979 X<m> X<operator, match>
1980 X<regexp, options> X<regexp> X<regex, options> X<regex>
1981 X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c>
1982
1983 =item C</I<PATTERN>/msixpodualngc>
1984
1985 Searches a string for a pattern match, and in scalar context returns
1986 true if it succeeds, false if it fails.  If no string is specified
1987 via the C<=~> or C<!~> operator, the C<$_> string is searched.  (The
1988 string specified with C<=~> need not be an lvalue--it may be the
1989 result of an expression evaluation, but remember the C<=~> binds
1990 rather tightly.)  See also L<perlre>.
1991
1992 Options are as described in C<qr//> above; in addition, the following match
1993 process modifiers are available:
1994
1995  g  Match globally, i.e., find all occurrences.
1996  c  Do not reset search position on a failed match when /g is
1997     in effect.
1998
1999 If C<"/"> is the delimiter then the initial C<m> is optional.  With the C<m>
2000 you can use any pair of non-whitespace (ASCII) characters
2001 as delimiters.  This is particularly useful for matching path names
2002 that contain C<"/">, to avoid LTS (leaning toothpick syndrome).  If C<"?"> is
2003 the delimiter, then a match-only-once rule applies,
2004 described in C<m?I<PATTERN>?> below.  If C<"'"> (single quote) is the delimiter,
2005 no variable interpolation is performed on the I<PATTERN>.
2006 When using a delimiter character valid in an identifier, whitespace is required
2007 after the C<m>.
2008
2009 I<PATTERN> may contain variables, which will be interpolated
2010 every time the pattern search is evaluated, except
2011 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
2012 C<$|> are not interpolated because they look like end-of-string tests.)
2013 Perl will not recompile the pattern unless an interpolated
2014 variable that it contains changes.  You can force Perl to skip the
2015 test and never recompile by adding a C</o> (which stands for "once")
2016 after the trailing delimiter.
2017 Once upon a time, Perl would recompile regular expressions
2018 unnecessarily, and this modifier was useful to tell it not to do so, in the
2019 interests of speed.  But now, the only reasons to use C</o> are one of:
2020
2021 =over
2022
2023 =item 1
2024
2025 The variables are thousands of characters long and you know that they
2026 don't change, and you need to wring out the last little bit of speed by
2027 having Perl skip testing for that.  (There is a maintenance penalty for
2028 doing this, as mentioning C</o> constitutes a promise that you won't
2029 change the variables in the pattern.  If you do change them, Perl won't
2030 even notice.)
2031
2032 =item 2
2033
2034 you want the pattern to use the initial values of the variables
2035 regardless of whether they change or not.  (But there are saner ways
2036 of accomplishing this than using C</o>.)
2037
2038 =item 3
2039
2040 If the pattern contains embedded code, such as
2041
2042     use re 'eval';
2043     $code = 'foo(?{ $x })';
2044     /$code/
2045
2046 then perl will recompile each time, even though the pattern string hasn't
2047 changed, to ensure that the current value of C<$x> is seen each time.
2048 Use C</o> if you want to avoid this.
2049
2050 =back
2051
2052 The bottom line is that using C</o> is almost never a good idea.
2053
2054 =item The empty pattern C<//>
2055
2056 If the I<PATTERN> evaluates to the empty string, the last
2057 I<successfully> matched regular expression is used instead.  In this
2058 case, only the C<g> and C<c> flags on the empty pattern are honored;
2059 the other flags are taken from the original pattern.  If no match has
2060 previously succeeded, this will (silently) act instead as a genuine
2061 empty pattern (which will always match).
2062
2063 Note that it's possible to confuse Perl into thinking C<//> (the empty
2064 regex) is really C<//> (the defined-or operator).  Perl is usually pretty
2065 good about this, but some pathological cases might trigger this, such as
2066 C<$x///> (is that S<C<($x) / (//)>> or S<C<$x // />>?) and S<C<print $fh //>>
2067 (S<C<print $fh(//>> or S<C<print($fh //>>?).  In all of these examples, Perl
2068 will assume you meant defined-or.  If you meant the empty regex, just
2069 use parentheses or spaces to disambiguate, or even prefix the empty
2070 regex with an C<m> (so C<//> becomes C<m//>).
2071
2072 =item Matching in list context
2073
2074 If the C</g> option is not used, C<m//> in list context returns a
2075 list consisting of the subexpressions matched by the parentheses in the
2076 pattern, that is, (C<$1>, C<$2>, C<$3>...)  (Note that here C<$1> etc. are
2077 also set).  When there are no parentheses in the pattern, the return
2078 value is the list C<(1)> for success.
2079 With or without parentheses, an empty list is returned upon failure.
2080
2081 Examples:
2082
2083  open(TTY, "+</dev/tty")
2084     || die "can't access /dev/tty: $!";
2085
2086  <TTY> =~ /^y/i && foo();       # do foo if desired
2087
2088  if (/Version: *([0-9.]*)/) { $version = $1; }
2089
2090  next if m#^/usr/spool/uucp#;
2091
2092  # poor man's grep
2093  $arg = shift;
2094  while (<>) {
2095     print if /$arg/o; # compile only once (no longer needed!)
2096  }
2097
2098  if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
2099
2100 This last example splits C<$foo> into the first two words and the
2101 remainder of the line, and assigns those three fields to C<$F1>, C<$F2>, and
2102 C<$Etc>.  The conditional is true if any variables were assigned; that is,
2103 if the pattern matched.
2104
2105 The C</g> modifier specifies global pattern matching--that is,
2106 matching as many times as possible within the string.  How it behaves
2107 depends on the context.  In list context, it returns a list of the
2108 substrings matched by any capturing parentheses in the regular
2109 expression.  If there are no parentheses, it returns a list of all
2110 the matched strings, as if there were parentheses around the whole
2111 pattern.
2112
2113 In scalar context, each execution of C<m//g> finds the next match,
2114 returning true if it matches, and false if there is no further match.
2115 The position after the last match can be read or set using the C<pos()>
2116 function; see L<perlfunc/pos>.  A failed match normally resets the
2117 search position to the beginning of the string, but you can avoid that
2118 by adding the C</c> modifier (for example, C<m//gc>).  Modifying the target
2119 string also resets the search position.
2120
2121 =item C<\G I<assertion>>
2122
2123 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
2124 zero-width assertion that matches the exact position where the
2125 previous C<m//g>, if any, left off.  Without the C</g> modifier, the
2126 C<\G> assertion still anchors at C<pos()> as it was at the start of
2127 the operation (see L<perlfunc/pos>), but the match is of course only
2128 attempted once.  Using C<\G> without C</g> on a target string that has
2129 not previously had a C</g> match applied to it is the same as using
2130 the C<\A> assertion to match the beginning of the string.  Note also
2131 that, currently, C<\G> is only properly supported when anchored at the
2132 very beginning of the pattern.
2133
2134 Examples:
2135
2136     # list context
2137     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
2138
2139     # scalar context
2140     local $/ = "";
2141     while ($paragraph = <>) {
2142         while ($paragraph =~ /\p{Ll}['")]*[.!?]+['")]*\s/g) {
2143             $sentences++;
2144         }
2145     }
2146     say $sentences;
2147
2148 Here's another way to check for sentences in a paragraph:
2149
2150  my $sentence_rx = qr{
2151     (?: (?<= ^ ) | (?<= \s ) )  # after start-of-string or
2152                                 # whitespace
2153     \p{Lu}                      # capital letter
2154     .*?                         # a bunch of anything
2155     (?<= \S )                   # that ends in non-
2156                                 # whitespace
2157     (?<! \b [DMS]r  )           # but isn't a common abbr.
2158     (?<! \b Mrs )
2159     (?<! \b Sra )
2160     (?<! \b St  )
2161     [.?!]                       # followed by a sentence
2162                                 # ender
2163     (?= $ | \s )                # in front of end-of-string
2164                                 # or whitespace
2165  }sx;
2166  local $/ = "";
2167  while (my $paragraph = <>) {
2168     say "NEW PARAGRAPH";
2169     my $count = 0;
2170     while ($paragraph =~ /($sentence_rx)/g) {
2171         printf "\tgot sentence %d: <%s>\n", ++$count, $1;
2172     }
2173  }
2174
2175 Here's how to use C<m//gc> with C<\G>:
2176
2177     $_ = "ppooqppqq";
2178     while ($i++ < 2) {
2179         print "1: '";
2180         print $1 while /(o)/gc; print "', pos=", pos, "\n";
2181         print "2: '";
2182         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
2183         print "3: '";
2184         print $1 while /(p)/gc; print "', pos=", pos, "\n";
2185     }
2186     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
2187
2188 The last example should print:
2189
2190     1: 'oo', pos=4
2191     2: 'q', pos=5
2192     3: 'pp', pos=7
2193     1: '', pos=7
2194     2: 'q', pos=8
2195     3: '', pos=8
2196     Final: 'q', pos=8
2197
2198 Notice that the final match matched C<q> instead of C<p>, which a match
2199 without the C<\G> anchor would have done.  Also note that the final match
2200 did not update C<pos>.  C<pos> is only updated on a C</g> match.  If the
2201 final match did indeed match C<p>, it's a good bet that you're running an
2202 ancient (pre-5.6.0) version of Perl.
2203
2204 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
2205 combine several regexps like this to process a string part-by-part,
2206 doing different actions depending on which regexp matched.  Each
2207 regexp tries to match where the previous one leaves off.
2208
2209  $_ = <<'EOL';
2210     $url = URI::URL->new( "http://example.com/" );
2211     die if $url eq "xXx";
2212  EOL
2213
2214  LOOP: {
2215      print(" digits"),       redo LOOP if /\G\d+\b[,.;]?\s*/gc;
2216      print(" lowercase"),    redo LOOP
2217                                     if /\G\p{Ll}+\b[,.;]?\s*/gc;
2218      print(" UPPERCASE"),    redo LOOP
2219                                     if /\G\p{Lu}+\b[,.;]?\s*/gc;
2220      print(" Capitalized"),  redo LOOP
2221                               if /\G\p{Lu}\p{Ll}+\b[,.;]?\s*/gc;
2222      print(" MiXeD"),        redo LOOP if /\G\pL+\b[,.;]?\s*/gc;
2223      print(" alphanumeric"), redo LOOP
2224                             if /\G[\p{Alpha}\pN]+\b[,.;]?\s*/gc;
2225      print(" line-noise"),   redo LOOP if /\G\W+/gc;
2226      print ". That's all!\n";
2227  }
2228
2229 Here is the output (split into several lines):
2230
2231  line-noise lowercase line-noise UPPERCASE line-noise UPPERCASE
2232  line-noise lowercase line-noise lowercase line-noise lowercase
2233  lowercase line-noise lowercase lowercase line-noise lowercase
2234  lowercase line-noise MiXeD line-noise. That's all!
2235
2236 =item C<m?I<PATTERN>?msixpodualngc>
2237 X<?> X<operator, match-once>
2238
2239 This is just like the C<m/I<PATTERN>/> search, except that it matches
2240 only once between calls to the C<reset()> operator.  This is a useful
2241 optimization when you want to see only the first occurrence of
2242 something in each file of a set of files, for instance.  Only C<m??>
2243 patterns local to the current package are reset.
2244
2245     while (<>) {
2246         if (m?^$?) {
2247                             # blank line between header and body
2248         }
2249     } continue {
2250         reset if eof;       # clear m?? status for next file
2251     }
2252
2253 Another example switched the first "latin1" encoding it finds
2254 to "utf8" in a pod file:
2255
2256     s//utf8/ if m? ^ =encoding \h+ \K latin1 ?x;
2257
2258 The match-once behavior is controlled by the match delimiter being
2259 C<?>; with any other delimiter this is the normal C<m//> operator.
2260
2261 In the past, the leading C<m> in C<m?I<PATTERN>?> was optional, but omitting it
2262 would produce a deprecation warning.  As of v5.22.0, omitting it produces a
2263 syntax error.  If you encounter this construct in older code, you can just add
2264 C<m>.
2265
2266 =item C<s/I<PATTERN>/I<REPLACEMENT>/msixpodualngcer>
2267 X<s> X<substitute> X<substitution> X<replace> X<regexp, replace>
2268 X<regexp, substitute> X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c> X</e> X</r>
2269
2270 Searches a string for a pattern, and if found, replaces that pattern
2271 with the replacement text and returns the number of substitutions
2272 made.  Otherwise it returns false (a value that is both an empty string (C<"">)
2273 and numeric zero (C<0>) as described in L</Relational Operators>).
2274
2275 If the C</r> (non-destructive) option is used then it runs the
2276 substitution on a copy of the string and instead of returning the
2277 number of substitutions, it returns the copy whether or not a
2278 substitution occurred.  The original string is never changed when
2279 C</r> is used.  The copy will always be a plain string, even if the
2280 input is an object or a tied variable.
2281
2282 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
2283 variable is searched and modified.  Unless the C</r> option is used,
2284 the string specified must be a scalar variable, an array element, a
2285 hash element, or an assignment to one of those; that is, some sort of
2286 scalar lvalue.
2287
2288 If the delimiter chosen is a single quote, no variable interpolation is
2289 done on either the I<PATTERN> or the I<REPLACEMENT>.  Otherwise, if the
2290 I<PATTERN> contains a C<$> that looks like a variable rather than an
2291 end-of-string test, the variable will be interpolated into the pattern
2292 at run-time.  If you want the pattern compiled only once the first time
2293 the variable is interpolated, use the C</o> option.  If the pattern
2294 evaluates to the empty string, the last successfully executed regular
2295 expression is used instead.  See L<perlre> for further explanation on these.
2296
2297 Options are as with C<m//> with the addition of the following replacement
2298 specific options:
2299
2300     e   Evaluate the right side as an expression.
2301     ee  Evaluate the right side as a string then eval the
2302         result.
2303     r   Return substitution and leave the original string
2304         untouched.
2305
2306 Any non-whitespace delimiter may replace the slashes.  Add space after
2307 the C<s> when using a character allowed in identifiers.  If single quotes
2308 are used, no interpretation is done on the replacement string (the C</e>
2309 modifier overrides this, however).  Note that Perl treats backticks
2310 as normal delimiters; the replacement text is not evaluated as a command.
2311 If the I<PATTERN> is delimited by bracketing quotes, the I<REPLACEMENT> has
2312 its own pair of quotes, which may or may not be bracketing quotes, for example,
2313 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
2314 replacement portion to be treated as a full-fledged Perl expression
2315 and evaluated right then and there.  It is, however, syntax checked at
2316 compile-time.  A second C<e> modifier will cause the replacement portion
2317 to be C<eval>ed before being run as a Perl expression.
2318
2319 Examples:
2320
2321     s/\bgreen\b/mauve/g;              # don't change wintergreen
2322
2323     $path =~ s|/usr/bin|/usr/local/bin|;
2324
2325     s/Login: $foo/Login: $bar/; # run-time pattern
2326
2327     ($foo = $bar) =~ s/this/that/;      # copy first, then
2328                                         # change
2329     ($foo = "$bar") =~ s/this/that/;    # convert to string,
2330                                         # copy, then change
2331     $foo = $bar =~ s/this/that/r;       # Same as above using /r
2332     $foo = $bar =~ s/this/that/r
2333                 =~ s/that/the other/r;  # Chained substitutes
2334                                         # using /r
2335     @foo = map { s/this/that/r } @bar   # /r is very useful in
2336                                         # maps
2337
2338     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-cnt
2339
2340     $_ = 'abc123xyz';
2341     s/\d+/$&*2/e;               # yields 'abc246xyz'
2342     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
2343     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
2344
2345     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
2346     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
2347     s/^=(\w+)/pod($1)/ge;       # use function call
2348
2349     $_ = 'abc123xyz';
2350     $x = s/abc/def/r;           # $x is 'def123xyz' and
2351                                 # $_ remains 'abc123xyz'.
2352
2353     # expand variables in $_, but dynamics only, using
2354     # symbolic dereferencing
2355     s/\$(\w+)/${$1}/g;
2356
2357     # Add one to the value of any numbers in the string
2358     s/(\d+)/1 + $1/eg;
2359
2360     # Titlecase words in the last 30 characters only
2361     substr($str, -30) =~ s/\b(\p{Alpha}+)\b/\u\L$1/g;
2362
2363     # This will expand any embedded scalar variable
2364     # (including lexicals) in $_ : First $1 is interpolated
2365     # to the variable name, and then evaluated
2366     s/(\$\w+)/$1/eeg;
2367
2368     # Delete (most) C comments.
2369     $program =~ s {
2370         /\*     # Match the opening delimiter.
2371         .*?     # Match a minimal number of characters.
2372         \*/     # Match the closing delimiter.
2373     } []gsx;
2374
2375     s/^\s*(.*?)\s*$/$1/;        # trim whitespace in $_,
2376                                 # expensively
2377
2378     for ($variable) {           # trim whitespace in $variable,
2379                                 # cheap
2380         s/^\s+//;
2381         s/\s+$//;
2382     }
2383
2384     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
2385
2386     $foo !~ s/A/a/g;    # Lowercase all A's in $foo; return
2387                         # 0 if any were found and changed;
2388                         # otherwise return 1
2389
2390 Note the use of C<$> instead of C<\> in the last example.  Unlike
2391 B<sed>, we use the \<I<digit>> form only in the left hand side.
2392 Anywhere else it's $<I<digit>>.
2393
2394 Occasionally, you can't use just a C</g> to get all the changes
2395 to occur that you might want.  Here are two common cases:
2396
2397     # put commas in the right places in an integer
2398     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;
2399
2400     # expand tabs to 8-column spacing
2401     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
2402
2403 X</c>While C<s///> accepts the C</c> flag, it has no effect beyond
2404 producing a warning if warnings are enabled.
2405
2406 =back
2407
2408 =head2 Quote-Like Operators
2409 X<operator, quote-like>
2410
2411 =over 4
2412
2413 =item C<q/I<STRING>/>
2414 X<q> X<quote, single> X<'> X<''>
2415
2416 =item C<'I<STRING>'>
2417
2418 A single-quoted, literal string.  A backslash represents a backslash
2419 unless followed by the delimiter or another backslash, in which case
2420 the delimiter or backslash is interpolated.
2421
2422     $foo = q!I said, "You said, 'She said it.'"!;
2423     $bar = q('This is it.');
2424     $baz = '\n';                # a two-character string
2425
2426 =item C<qq/I<STRING>/>
2427 X<qq> X<quote, double> X<"> X<"">
2428
2429 =item C<"I<STRING>">
2430
2431 A double-quoted, interpolated string.
2432
2433     $_ .= qq
2434      (*** The previous line contains the naughty word "$1".\n)
2435                 if /\b(tcl|java|python)\b/i;      # :-)
2436     $baz = "\n";                # a one-character string
2437
2438 =item C<qx/I<STRING>/>
2439 X<qx> X<`> X<``> X<backtick>
2440
2441 =item C<`I<STRING>`>
2442
2443 A string which is (possibly) interpolated and then executed as a
2444 system command, via F</bin/sh> or its equivalent if required.  Shell
2445 wildcards, pipes, and redirections will be honored.  Similarly to
2446 C<system>, if the string contains no shell metacharacters then it will
2447 executed directly.  The collected standard output of the command is
2448 returned; standard error is unaffected.  In scalar context, it comes
2449 back as a single (potentially multi-line) string, or C<undef> if the
2450 shell (or command) could not be started.  In list context, returns a
2451 list of lines (however you've defined lines with C<$/> or
2452 C<$INPUT_RECORD_SEPARATOR>), or an empty list if the shell (or command)
2453 could not be started.
2454
2455 Because backticks do not affect standard error, use shell file descriptor
2456 syntax (assuming the shell supports this) if you care to address this.
2457 To capture a command's STDERR and STDOUT together:
2458
2459     $output = `cmd 2>&1`;
2460
2461 To capture a command's STDOUT but discard its STDERR:
2462
2463     $output = `cmd 2>/dev/null`;
2464
2465 To capture a command's STDERR but discard its STDOUT (ordering is
2466 important here):
2467
2468     $output = `cmd 2>&1 1>/dev/null`;
2469
2470 To exchange a command's STDOUT and STDERR in order to capture the STDERR
2471 but leave its STDOUT to come out the old STDERR:
2472
2473     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
2474
2475 To read both a command's STDOUT and its STDERR separately, it's easiest
2476 to redirect them separately to files, and then read from those files
2477 when the program is done:
2478
2479     system("program args 1>program.stdout 2>program.stderr");
2480
2481 The STDIN filehandle used by the command is inherited from Perl's STDIN.
2482 For example:
2483
2484     open(SPLAT, "stuff")   || die "can't open stuff: $!";
2485     open(STDIN, "<&SPLAT") || die "can't dupe SPLAT: $!";
2486     print STDOUT `sort`;
2487
2488 will print the sorted contents of the file named F<"stuff">.
2489
2490 Using single-quote as a delimiter protects the command from Perl's
2491 double-quote interpolation, passing it on to the shell instead:
2492
2493     $perl_info  = qx(ps $$);            # that's Perl's $$
2494     $shell_info = qx'ps $$';            # that's the new shell's $$
2495
2496 How that string gets evaluated is entirely subject to the command
2497 interpreter on your system.  On most platforms, you will have to protect
2498 shell metacharacters if you want them treated literally.  This is in
2499 practice difficult to do, as it's unclear how to escape which characters.
2500 See L<perlsec> for a clean and safe example of a manual C<fork()> and C<exec()>
2501 to emulate backticks safely.
2502
2503 On some platforms (notably DOS-like ones), the shell may not be
2504 capable of dealing with multiline commands, so putting newlines in
2505 the string may not get you what you want.  You may be able to evaluate
2506 multiple commands in a single line by separating them with the command
2507 separator character, if your shell supports that (for example, C<;> on
2508 many Unix shells and C<&> on the Windows NT C<cmd> shell).
2509
2510 Perl will attempt to flush all files opened for
2511 output before starting the child process, but this may not be supported
2512 on some platforms (see L<perlport>).  To be safe, you may need to set
2513 C<$|> (C<$AUTOFLUSH> in C<L<English>>) or call the C<autoflush()> method of
2514 C<L<IO::Handle>> on any open handles.
2515
2516 Beware that some command shells may place restrictions on the length
2517 of the command line.  You must ensure your strings don't exceed this
2518 limit after any necessary interpolations.  See the platform-specific
2519 release notes for more details about your particular environment.
2520
2521 Using this operator can lead to programs that are difficult to port,
2522 because the shell commands called vary between systems, and may in
2523 fact not be present at all.  As one example, the C<type> command under
2524 the POSIX shell is very different from the C<type> command under DOS.
2525 That doesn't mean you should go out of your way to avoid backticks
2526 when they're the right way to get something done.  Perl was made to be
2527 a glue language, and one of the things it glues together is commands.
2528 Just understand what you're getting yourself into.
2529
2530 Like C<system>, backticks put the child process exit code in C<$?>.
2531 If you'd like to manually inspect failure, you can check all possible
2532 failure modes by inspecting C<$?> like this:
2533
2534     if ($? == -1) {
2535         print "failed to execute: $!\n";
2536     }
2537     elsif ($? & 127) {
2538         printf "child died with signal %d, %s coredump\n",
2539             ($? & 127),  ($? & 128) ? 'with' : 'without';
2540     }
2541     else {
2542         printf "child exited with value %d\n", $? >> 8;
2543     }
2544
2545 Use the L<open> pragma to control the I/O layers used when reading the
2546 output of the command, for example:
2547
2548   use open IN => ":encoding(UTF-8)";
2549   my $x = `cmd-producing-utf-8`;
2550
2551 C<qx//> can also be called like a function with L<perlfunc/readpipe>.
2552
2553 See L</"I/O Operators"> for more discussion.
2554
2555 =item C<qw/I<STRING>/>
2556 X<qw> X<quote, list> X<quote, words>
2557
2558 Evaluates to a list of the words extracted out of I<STRING>, using embedded
2559 whitespace as the word delimiters.  It can be understood as being roughly
2560 equivalent to:
2561
2562     split(" ", q/STRING/);
2563
2564 the differences being that it only splits on ASCII whitespace,
2565 generates a real list at compile time, and
2566 in scalar context it returns the last element in the list.  So
2567 this expression:
2568
2569     qw(foo bar baz)
2570
2571 is semantically equivalent to the list:
2572
2573     "foo", "bar", "baz"
2574
2575 Some frequently seen examples:
2576
2577     use POSIX qw( setlocale localeconv )
2578     @EXPORT = qw( foo bar baz );
2579
2580 A common mistake is to try to separate the words with commas or to
2581 put comments into a multi-line C<qw>-string.  For this reason, the
2582 S<C<use warnings>> pragma and the B<-w> switch (that is, the C<$^W> variable)
2583 produces warnings if the I<STRING> contains the C<","> or the C<"#"> character.
2584
2585 =item C<tr/I<SEARCHLIST>/I<REPLACEMENTLIST>/cdsr>
2586 X<tr> X<y> X<transliterate> X</c> X</d> X</s>
2587
2588 =item C<y/I<SEARCHLIST>/I<REPLACEMENTLIST>/cdsr>
2589
2590 Transliterates all occurrences of the characters found (or not found
2591 if the C</c> modifier is specified) in the search list with the
2592 positionally corresponding character in the replacement list, possibly
2593 deleting some, depending on the modifiers specified.  It returns the
2594 number of characters replaced or deleted.  If no string is specified via
2595 the C<=~> or C<!~> operator, the C<$_> string is transliterated.
2596
2597 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.
2598
2599 If the C</r> (non-destructive) option is present, a new copy of the string
2600 is made and its characters transliterated, and this copy is returned no
2601 matter whether it was modified or not: the original string is always
2602 left unchanged.  The new copy is always a plain string, even if the input
2603 string is an object or a tied variable.
2604
2605 Unless the C</r> option is used, the string specified with C<=~> must be a
2606 scalar variable, an array element, a hash element, or an assignment to one
2607 of those; in other words, an lvalue.
2608
2609 The characters delimitting I<SEARCHLIST> and I<REPLACEMENTLIST>
2610 can be any printable character, not just forward slashes.  If they
2611 are single quotes (C<tr'I<SEARCHLIST>'I<REPLACEMENTLIST>'>), the only
2612 interpolation is removal of C<\> from pairs of C<\\>.
2613
2614 Otherwise, a character range may be specified with a hyphen, so
2615 C<tr/A-J/0-9/> does the same replacement as
2616 C<tr/ACEGIBDFHJ/0246813579/>.
2617
2618 If the I<SEARCHLIST> is delimited by bracketing quotes, the
2619 I<REPLACEMENTLIST> must have its own pair of quotes, which may or may
2620 not be bracketing quotes; for example, C<tr[aeiouy][yuoiea]> or
2621 C<tr(+\-*/)/ABCD/>.
2622
2623 Characters may be literals, or (if the delimiters aren't single quotes)
2624 any of the escape sequences accepted in double-quoted strings.  But
2625 there is never any variable interpolation, so C<"$"> and C<"@"> are
2626 always treated as literals.  A hyphen at the beginning or end, or
2627 preceded by a backslash is also always considered a literal.  Escape
2628 sequence details are in L<the table near the beginning of this
2629 section|/Quote and Quote-like Operators>.
2630
2631 Note that C<tr> does B<not> do regular expression character classes such as
2632 C<\d> or C<\pL>.  The C<tr> operator is not equivalent to the C<L<tr(1)>>
2633 utility.  C<tr[a-z][A-Z]> will uppercase the 26 letters "a" through "z",
2634 but for case changing not confined to ASCII, use
2635 L<C<lc>|perlfunc/lc>, L<C<uc>|perlfunc/uc>,
2636 L<C<lcfirst>|perlfunc/lcfirst>, L<C<ucfirst>|perlfunc/ucfirst>
2637 (all documented in L<perlfunc>), or the
2638 L<substitution operator C<sE<sol>I<PATTERN>E<sol>I<REPLACEMENT>E<sol>>|/sE<sol>PATTERNE<sol>REPLACEMENTE<sol>msixpodualngcer>
2639 (with C<\U>, C<\u>, C<\L>, and C<\l> string-interpolation escapes in the
2640 I<REPLACEMENT> portion).
2641
2642 Most ranges are unportable between character sets, but certain ones
2643 signal Perl to do special handling to make them portable.  There are two
2644 classes of portable ranges.  The first are any subsets of the ranges
2645 C<A-Z>, C<a-z>, and C<0-9>, when expressed as literal characters.
2646
2647   tr/h-k/H-K/
2648
2649 capitalizes the letters C<"h">, C<"i">, C<"j">, and C<"k"> and nothing
2650 else, no matter what the platform's character set is.  In contrast, all
2651 of
2652
2653   tr/\x68-\x6B/\x48-\x4B/
2654   tr/h-\x6B/H-\x4B/
2655   tr/\x68-k/\x48-K/
2656
2657 do the same capitalizations as the previous example when run on ASCII
2658 platforms, but something completely different on EBCDIC ones.
2659
2660 The second class of portable ranges is invoked when one or both of the
2661 range's end points are expressed as C<\N{...}>
2662
2663  $string =~ tr/\N{U+20}-\N{U+7E}//d;
2664
2665 removes from C<$string> all the platform's characters which are
2666 equivalent to any of Unicode U+0020, U+0021, ... U+007D, U+007E.  This
2667 is a portable range, and has the same effect on every platform it is
2668 run on.  In this example, these are the ASCII
2669 printable characters.  So after this is run, C<$string> has only
2670 controls and characters which have no ASCII equivalents.
2671
2672 But, even for portable ranges, it is not generally obvious what is
2673 included without having to look things up in the manual.  A sound
2674 principle is to use only ranges that both begin from, and end at, either
2675 ASCII alphabetics of equal case (C<b-e>, C<B-E>), or digits (C<1-4>).
2676 Anything else is unclear (and unportable unless C<\N{...}> is used).  If
2677 in doubt, spell out the character sets in full.
2678
2679 Options:
2680
2681     c   Complement the SEARCHLIST.
2682     d   Delete found but unreplaced characters.
2683     r   Return the modified string and leave the original string
2684         untouched.
2685     s   Squash duplicate replaced characters.
2686
2687 If the C</d> modifier is specified, any characters specified by
2688 I<SEARCHLIST>  not found in I<REPLACEMENTLIST> are deleted.  (Note that
2689 this is slightly more flexible than the behavior of some B<tr> programs,
2690 which delete anything they find in the I<SEARCHLIST>, period.)
2691
2692 If the C</s> modifier is specified, sequences of characters, all in a
2693 row, that were transliterated to the same character are squashed down to
2694 a single instance of that character.
2695
2696  my $a = "aaabbbca";
2697  $a =~ tr/ab/dd/s;     # $a now is "dcd"
2698
2699 If the C</d> modifier is used, the I<REPLACEMENTLIST> is always interpreted
2700 exactly as specified.  Otherwise, if the I<REPLACEMENTLIST> is shorter
2701 than the I<SEARCHLIST>, the final character, if any, is replicated until
2702 it is long enough.  There won't be a final character if and only if the
2703 I<REPLACEMENTLIST> is empty, in which case I<REPLACEMENTLIST> is
2704 copied from I<SEARCHLIST>.    An empty I<REPLACEMENTLIST> is useful
2705 for counting characters in a class, or for squashing character sequences
2706 in a class.
2707
2708     tr/abcd//            tr/abcd/abcd/
2709     tr/abcd/AB/          tr/abcd/ABBB/
2710     tr/abcd//d           s/[abcd]//g
2711     tr/abcd/AB/d         (tr/ab/AB/ + s/[cd]//g)  - but run together
2712
2713 If the C</c> modifier is specified, the characters to be transliterated
2714 are the ones NOT in I<SEARCHLIST>, that is, it is complemented.  If
2715 C</d> and/or C</s> are also specified, they apply to the complemented
2716 I<SEARCHLIST>.  Recall, that if I<REPLACEMENTLIST> is empty (except
2717 under C</d>) a copy of I<SEARCHLIST> is used instead.  That copy is made
2718 after complementing under C</c>.  I<SEARCHLIST> is sorted by code point
2719 order after complementing, and any I<REPLACEMENTLIST>  is applied to
2720 that sorted result.  This means that under C</c>, the order of the
2721 characters specified in I<SEARCHLIST> is irrelevant.  This can
2722 lead to different results on EBCDIC systems if I<REPLACEMENTLIST>
2723 contains more than one character, hence it is generally non-portable to
2724 use C</c> with such a I<REPLACEMENTLIST>.
2725
2726 Another way of describing the operation is this:
2727 If C</c> is specified, the I<SEARCHLIST> is sorted by code point order,
2728 then complemented.  If I<REPLACEMENTLIST> is empty and C</d> is not
2729 specified, I<REPLACEMENTLIST> is replaced by a copy of I<SEARCHLIST> (as
2730 modified under C</c>), and these potentially modified lists are used as
2731 the basis for what follows.  Any character in the target string that
2732 isn't in I<SEARCHLIST> is passed through unchanged.  Every other
2733 character in the target string is replaced by the character in
2734 I<REPLACEMENTLIST> that positionally corresponds to its mate in
2735 I<SEARCHLIST>, except that under C</s>, the 2nd and following characters
2736 are squeezed out in a sequence of characters in a row that all translate
2737 to the same character.  If I<SEARCHLIST> is longer than
2738 I<REPLACEMENTLIST>, characters in the target string that match a
2739 character in I<SEARCHLIST> that doesn't have a correspondence in
2740 I<REPLACEMENTLIST> are either deleted from the target string if C</d> is
2741 specified; or replaced by the final character in I<REPLACEMENTLIST> if
2742 C</d> isn't specified.
2743
2744 Some examples:
2745
2746  $ARGV[1] =~ tr/A-Z/a-z/;   # canonicalize to lower case ASCII
2747
2748  $cnt = tr/*/*/;            # count the stars in $_
2749  $cnt = tr/*//;             # same thing
2750
2751  $cnt = $sky =~ tr/*/*/;    # count the stars in $sky
2752  $cnt = $sky =~ tr/*//;     # same thing
2753
2754  $cnt = $sky =~ tr/*//c;    # count all the non-stars in $sky
2755  $cnt = $sky =~ tr/*/*/c;   # same, but transliterate each non-star
2756                             # into a star, leaving the already-stars
2757                             # alone.  Afterwards, everything in $sky
2758                             # is a star.
2759
2760  $cnt = tr/0-9//;           # count the ASCII digits in $_
2761
2762  tr/a-zA-Z//s;              # bookkeeper -> bokeper
2763  tr/o/o/s;                  # bookkeeper -> bokkeeper
2764  tr/oe/oe/s;                # bookkeeper -> bokkeper
2765  tr/oe//s;                  # bookkeeper -> bokkeper
2766  tr/oe/o/s;                 # bookkeeper -> bokkopor
2767
2768  ($HOST = $host) =~ tr/a-z/A-Z/;
2769   $HOST = $host  =~ tr/a-z/A-Z/r; # same thing
2770
2771  $HOST = $host =~ tr/a-z/A-Z/r   # chained with s///r
2772                =~ s/:/ -p/r;
2773
2774  tr/a-zA-Z/ /cs;                 # change non-alphas to single space
2775
2776  @stripped = map tr/a-zA-Z/ /csr, @original;
2777                                  # /r with map
2778
2779  tr [\200-\377]
2780     [\000-\177];                 # wickedly delete 8th bit
2781
2782  $foo !~ tr/A/a/    # transliterate all the A's in $foo to 'a',
2783                     # return 0 if any were found and changed.
2784                     # Otherwise return 1
2785
2786 If multiple transliterations are given for a character, only the
2787 first one is used:
2788
2789  tr/AAA/XYZ/
2790
2791 will transliterate any A to X.
2792
2793 Because the transliteration table is built at compile time, neither
2794 the I<SEARCHLIST> nor the I<REPLACEMENTLIST> are subjected to double quote
2795 interpolation.  That means that if you want to use variables, you
2796 must use an C<eval()>:
2797
2798  eval "tr/$oldlist/$newlist/";
2799  die $@ if $@;
2800
2801  eval "tr/$oldlist/$newlist/, 1" or die $@;
2802
2803 =item C<< <<I<EOF> >>
2804 X<here-doc> X<heredoc> X<here-document> X<<< << >>>
2805
2806 A line-oriented form of quoting is based on the shell "here-document"
2807 syntax.  Following a C<< << >> you specify a string to terminate
2808 the quoted material, and all lines following the current line down to
2809 the terminating string are the value of the item.
2810
2811 Prefixing the terminating string with a C<~> specifies that you
2812 want to use L</Indented Here-docs> (see below).
2813
2814 The terminating string may be either an identifier (a word), or some
2815 quoted text.  An unquoted identifier works like double quotes.
2816 There may not be a space between the C<< << >> and the identifier,
2817 unless the identifier is explicitly quoted.  The terminating string
2818 must appear by itself (unquoted and with no surrounding whitespace)
2819 on the terminating line.
2820
2821 If the terminating string is quoted, the type of quotes used determine
2822 the treatment of the text.
2823
2824 =over 4
2825
2826 =item Double Quotes
2827
2828 Double quotes indicate that the text will be interpolated using exactly
2829 the same rules as normal double quoted strings.
2830
2831        print <<EOF;
2832     The price is $Price.
2833     EOF
2834
2835        print << "EOF"; # same as above
2836     The price is $Price.
2837     EOF
2838
2839
2840 =item Single Quotes
2841
2842 Single quotes indicate the text is to be treated literally with no
2843 interpolation of its content.  This is similar to single quoted
2844 strings except that backslashes have no special meaning, with C<\\>
2845 being treated as two backslashes and not one as they would in every
2846 other quoting construct.
2847
2848 Just as in the shell, a backslashed bareword following the C<<< << >>>
2849 means the same thing as a single-quoted string does:
2850
2851         $cost = <<'VISTA';  # hasta la ...
2852     That'll be $10 please, ma'am.
2853     VISTA
2854
2855         $cost = <<\VISTA;   # Same thing!
2856     That'll be $10 please, ma'am.
2857     VISTA
2858
2859 This is the only form of quoting in perl where there is no need
2860 to worry about escaping content, something that code generators
2861 can and do make good use of.
2862
2863 =item Backticks
2864
2865 The content of the here doc is treated just as it would be if the
2866 string were embedded in backticks.  Thus the content is interpolated
2867 as though it were double quoted and then executed via the shell, with
2868 the results of the execution returned.
2869
2870        print << `EOC`; # execute command and get results
2871     echo hi there
2872     EOC
2873
2874 =back
2875
2876 =over 4
2877
2878 =item Indented Here-docs
2879
2880 The here-doc modifier C<~> allows you to indent your here-docs to make
2881 the code more readable:
2882
2883     if ($some_var) {
2884       print <<~EOF;
2885         This is a here-doc
2886         EOF
2887     }
2888
2889 This will print...
2890
2891     This is a here-doc
2892
2893 ...with no leading whitespace.
2894
2895 The delimiter is used to determine the B<exact> whitespace to
2896 remove from the beginning of each line.  All lines B<must> have
2897 at least the same starting whitespace (except lines only
2898 containing a newline) or perl will croak.  Tabs and spaces can
2899 be mixed, but are matched exactly.  One tab will not be equal to
2900 8 spaces!
2901
2902 Additional beginning whitespace (beyond what preceded the
2903 delimiter) will be preserved:
2904
2905     print <<~EOF;
2906       This text is not indented
2907         This text is indented with two spaces
2908                 This text is indented with two tabs
2909       EOF
2910
2911 Finally, the modifier may be used with all of the forms
2912 mentioned above:
2913
2914     <<~\EOF;
2915     <<~'EOF'
2916     <<~"EOF"
2917     <<~`EOF`
2918
2919 And whitespace may be used between the C<~> and quoted delimiters:
2920
2921     <<~ 'EOF'; # ... "EOF", `EOF`
2922
2923 =back
2924
2925 It is possible to stack multiple here-docs in a row:
2926
2927        print <<"foo", <<"bar"; # you can stack them
2928     I said foo.
2929     foo
2930     I said bar.
2931     bar
2932
2933        myfunc(<< "THIS", 23, <<'THAT');
2934     Here's a line
2935     or two.
2936     THIS
2937     and here's another.
2938     THAT
2939
2940 Just don't forget that you have to put a semicolon on the end
2941 to finish the statement, as Perl doesn't know you're not going to
2942 try to do this:
2943
2944        print <<ABC
2945     179231
2946     ABC
2947        + 20;
2948
2949 If you want to remove the line terminator from your here-docs,
2950 use C<chomp()>.
2951
2952     chomp($string = <<'END');
2953     This is a string.
2954     END
2955
2956 If you want your here-docs to be indented with the rest of the code,
2957 use the C<<< <<~FOO >>> construct described under L</Indented Here-docs>:
2958
2959     $quote = <<~'FINIS';
2960        The Road goes ever on and on,
2961        down from the door where it began.
2962        FINIS
2963
2964 If you use a here-doc within a delimited construct, such as in C<s///eg>,
2965 the quoted material must still come on the line following the
2966 C<<< <<FOO >>> marker, which means it may be inside the delimited
2967 construct:
2968
2969     s/this/<<E . 'that'
2970     the other
2971     E
2972      . 'more '/eg;
2973
2974 It works this way as of Perl 5.18.  Historically, it was inconsistent, and
2975 you would have to write
2976
2977     s/this/<<E . 'that'
2978      . 'more '/eg;
2979     the other
2980     E
2981
2982 outside of string evals.
2983
2984 Additionally, quoting rules for the end-of-string identifier are
2985 unrelated to Perl's quoting rules.  C<q()>, C<qq()>, and the like are not
2986 supported in place of C<''> and C<"">, and the only interpolation is for
2987 backslashing the quoting character:
2988
2989     print << "abc\"def";
2990     testing...
2991     abc"def
2992
2993 Finally, quoted strings cannot span multiple lines.  The general rule is
2994 that the identifier must be a string literal.  Stick with that, and you
2995 should be safe.
2996
2997 =back
2998
2999 =head2 Gory details of parsing quoted constructs
3000 X<quote, gory details>
3001
3002 When presented with something that might have several different
3003 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
3004 principle to pick the most probable interpretation.  This strategy
3005 is so successful that Perl programmers often do not suspect the
3006 ambivalence of what they write.  But from time to time, Perl's
3007 notions differ substantially from what the author honestly meant.
3008
3009 This section hopes to clarify how Perl handles quoted constructs.
3010 Although the most common reason to learn this is to unravel labyrinthine
3011 regular expressions, because the initial steps of parsing are the
3012 same for all quoting operators, they are all discussed together.
3013
3014 The most important Perl parsing rule is the first one discussed
3015 below: when processing a quoted construct, Perl first finds the end
3016 of that construct, then interprets its contents.  If you understand
3017 this rule, you may skip the rest of this section on the first
3018 reading.  The other rules are likely to contradict the user's
3019 expectations much less frequently than this first one.
3020
3021 Some passes discussed below are performed concurrently, but because
3022 their results are the same, we consider them individually.  For different
3023 quoting constructs, Perl performs different numbers of passes, from
3024 one to four, but these passes are always performed in the same order.
3025
3026 =over 4
3027
3028 =item Finding the end
3029
3030 The first pass is finding the end of the quoted construct.  This results
3031 in saving to a safe location a copy of the text (between the starting
3032 and ending delimiters), normalized as necessary to avoid needing to know
3033 what the original delimiters were.
3034
3035 If the construct is a here-doc, the ending delimiter is a line
3036 that has a terminating string as the content.  Therefore C<<<EOF> is
3037 terminated by C<EOF> immediately followed by C<"\n"> and starting
3038 from the first column of the terminating line.
3039 When searching for the terminating line of a here-doc, nothing
3040 is skipped.  In other words, lines after the here-doc syntax
3041 are compared with the terminating string line by line.
3042
3043 For the constructs except here-docs, single characters are used as starting
3044 and ending delimiters.  If the starting delimiter is an opening punctuation
3045 (that is C<(>, C<[>, C<{>, or C<< < >>), the ending delimiter is the
3046 corresponding closing punctuation (that is C<)>, C<]>, C<}>, or C<< > >>).
3047 If the starting delimiter is an unpaired character like C</> or a closing
3048 punctuation, the ending delimiter is the same as the starting delimiter.
3049 Therefore a C</> terminates a C<qq//> construct, while a C<]> terminates
3050 both C<qq[]> and C<qq]]> constructs.
3051
3052 When searching for single-character delimiters, escaped delimiters
3053 and C<\\> are skipped.  For example, while searching for terminating C</>,
3054 combinations of C<\\> and C<\/> are skipped.  If the delimiters are
3055 bracketing, nested pairs are also skipped.  For example, while searching
3056 for a closing C<]> paired with the opening C<[>, combinations of C<\\>, C<\]>,
3057 and C<\[> are all skipped, and nested C<[> and C<]> are skipped as well.
3058 However, when backslashes are used as the delimiters (like C<qq\\> and
3059 C<tr\\\>), nothing is skipped.
3060 During the search for the end, backslashes that escape delimiters or
3061 other backslashes are removed (exactly speaking, they are not copied to the
3062 safe location).
3063
3064 For constructs with three-part delimiters (C<s///>, C<y///>, and
3065 C<tr///>), the search is repeated once more.
3066 If the first delimiter is not an opening punctuation, the three delimiters must
3067 be the same, such as C<s!!!> and C<tr)))>,
3068 in which case the second delimiter
3069 terminates the left part and starts the right part at once.
3070 If the left part is delimited by bracketing punctuation (that is C<()>,
3071 C<[]>, C<{}>, or C<< <> >>), the right part needs another pair of
3072 delimiters such as C<s(){}> and C<tr[]//>.  In these cases, whitespace
3073 and comments are allowed between the two parts, although the comment must follow
3074 at least one whitespace character; otherwise a character expected as the
3075 start of the comment may be regarded as the starting delimiter of the right part.
3076
3077 During this search no attention is paid to the semantics of the construct.
3078 Thus:
3079
3080     "$hash{"$foo/$bar"}"
3081
3082 or:
3083
3084     m/
3085       bar       # NOT a comment, this slash / terminated m//!
3086      /x
3087
3088 do not form legal quoted expressions.   The quoted part ends on the
3089 first C<"> and C</>, and the rest happens to be a syntax error.
3090 Because the slash that terminated C<m//> was followed by a C<SPACE>,
3091 the example above is not C<m//x>, but rather C<m//> with no C</x>
3092 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
3093
3094 Also no attention is paid to C<\c\> (multichar control char syntax) during
3095 this search.  Thus the second C<\> in C<qq/\c\/> is interpreted as a part
3096 of C<\/>, and the following C</> is not recognized as a delimiter.
3097 Instead, use C<\034> or C<\x1c> at the end of quoted constructs.
3098
3099 =item Interpolation
3100 X<interpolation>
3101
3102 The next step is interpolation in the text obtained, which is now
3103 delimiter-independent.  There are multiple cases.
3104
3105 =over 4
3106
3107 =item C<<<'EOF'>
3108
3109 No interpolation is performed.
3110 Note that the combination C<\\> is left intact, since escaped delimiters
3111 are not available for here-docs.
3112
3113 =item  C<m''>, the pattern of C<s'''>
3114
3115 No interpolation is performed at this stage.
3116 Any backslashed sequences including C<\\> are treated at the stage
3117 to L</"parsing regular expressions">.
3118
3119 =item C<''>, C<q//>, C<tr'''>, C<y'''>, the replacement of C<s'''>
3120
3121 The only interpolation is removal of C<\> from pairs of C<\\>.
3122 Therefore C<"-"> in C<tr'''> and C<y'''> is treated literally
3123 as a hyphen and no character range is available.
3124 C<\1> in the replacement of C<s'''> does not work as C<$1>.
3125
3126 =item C<tr///>, C<y///>
3127
3128 No variable interpolation occurs.  String modifying combinations for
3129 case and quoting such as C<\Q>, C<\U>, and C<\E> are not recognized.
3130 The other escape sequences such as C<\200> and C<\t> and backslashed
3131 characters such as C<\\> and C<\-> are converted to appropriate literals.
3132 The character C<"-"> is treated specially and therefore C<\-> is treated
3133 as a literal C<"-">.
3134
3135 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>, C<<<"EOF">
3136
3137 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> (possibly paired with C<\E>) are
3138 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
3139 is converted to S<C<$foo . (quotemeta("baz" . $bar))>> internally.
3140 The other escape sequences such as C<\200> and C<\t> and backslashed
3141 characters such as C<\\> and C<\-> are replaced with appropriate
3142 expansions.
3143
3144 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
3145 is interpolated in the usual way.  Something like C<"\Q\\E"> has
3146 no C<\E> inside.  Instead, it has C<\Q>, C<\\>, and C<E>, so the
3147 result is the same as for C<"\\\\E">.  As a general rule, backslashes
3148 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
3149 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
3150 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
3151
3152   $str = '\t';
3153   return "\Q$str";
3154
3155 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
3156
3157 Interpolated scalars and arrays are converted internally to the C<join> and
3158 C<"."> catenation operations.  Thus, S<C<"$foo XXX '@arr'">> becomes:
3159
3160   $foo . " XXX '" . (join $", @arr) . "'";
3161
3162 All operations above are performed simultaneously, left to right.
3163
3164 Because the result of S<C<"\Q I<STRING> \E">> has all metacharacters
3165 quoted, there is no way to insert a literal C<$> or C<@> inside a
3166 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to become
3167 C<"\\\$">; if not, it is interpreted as the start of an interpolated
3168 scalar.
3169
3170 Note also that the interpolation code needs to make a decision on
3171 where the interpolated scalar ends.  For instance, whether
3172 S<C<< "a $x -> {c}" >>> really means:
3173
3174   "a " . $x . " -> {c}";
3175
3176 or:
3177
3178   "a " . $x -> {c};
3179
3180 Most of the time, the longest possible text that does not include
3181 spaces between components and which contains matching braces or
3182 brackets.  because the outcome may be determined by voting based
3183 on heuristic estimators, the result is not strictly predictable.
3184 Fortunately, it's usually correct for ambiguous cases.
3185
3186 =item the replacement of C<s///>
3187
3188 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> and interpolation
3189 happens as with C<qq//> constructs.
3190
3191 It is at this step that C<\1> is begrudgingly converted to C<$1> in
3192 the replacement text of C<s///>, in order to correct the incorrigible
3193 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
3194 is emitted if the S<C<use warnings>> pragma or the B<-w> command-line flag
3195 (that is, the C<$^W> variable) was set.
3196
3197 =item C<RE> in C<m?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>,
3198
3199 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F>, C<\E>,
3200 and interpolation happens (almost) as with C<qq//> constructs.
3201
3202 Processing of C<\N{...}> is also done here, and compiled into an intermediate
3203 form for the regex compiler.  (This is because, as mentioned below, the regex
3204 compilation may be done at execution time, and C<\N{...}> is a compile-time
3205 construct.)
3206
3207 However any other combinations of C<\> followed by a character
3208 are not substituted but only skipped, in order to parse them
3209 as regular expressions at the following step.
3210 As C<\c> is skipped at this step, C<@> of C<\c@> in RE is possibly
3211 treated as an array symbol (for example C<@foo>),
3212 even though the same text in C<qq//> gives interpolation of C<\c@>.
3213
3214 Code blocks such as C<(?{BLOCK})> are handled by temporarily passing control
3215 back to the perl parser, in a similar way that an interpolated array
3216 subscript expression such as C<"foo$array[1+f("[xyz")]bar"> would be.
3217
3218 Moreover, inside C<(?{BLOCK})>, S<C<(?# comment )>>, and
3219 a C<#>-comment in a C</x>-regular expression, no processing is
3220 performed whatsoever.  This is the first step at which the presence
3221 of the C</x> modifier is relevant.
3222
3223 Interpolation in patterns has several quirks: C<$|>, C<$(>, C<$)>, C<@+>
3224 and C<@-> are not interpolated, and constructs C<$var[SOMETHING]> are
3225 voted (by several different estimators) to be either an array element
3226 or C<$var> followed by an RE alternative.  This is where the notation
3227 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
3228 array element C<-9>, not as a regular expression from the variable
3229 C<$arr> followed by a digit, which would be the interpretation of
3230 C</$arr[0-9]/>.  Since voting among different estimators may occur,
3231 the result is not predictable.
3232
3233 The lack of processing of C<\\> creates specific restrictions on
3234 the post-processed text.  If the delimiter is C</>, one cannot get
3235 the combination C<\/> into the result of this step.  C</> will
3236 finish the regular expression, C<\/> will be stripped to C</> on
3237 the previous step, and C<\\/> will be left as is.  Because C</> is
3238 equivalent to C<\/> inside a regular expression, this does not
3239 matter unless the delimiter happens to be character special to the
3240 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<m?foo?>; or an
3241 alphanumeric char, as in:
3242
3243   m m ^ a \s* b mmx;
3244
3245 In the RE above, which is intentionally obfuscated for illustration, the
3246 delimiter is C<m>, the modifier is C<mx>, and after delimiter-removal the
3247 RE is the same as for S<C<m/ ^ a \s* b /mx>>.  There's more than one
3248 reason you're encouraged to restrict your delimiters to non-alphanumeric,
3249 non-whitespace choices.
3250
3251 =back
3252
3253 This step is the last one for all constructs except regular expressions,
3254 which are processed further.
3255
3256 =item parsing regular expressions
3257 X<regexp, parse>
3258
3259 Previous steps were performed during the compilation of Perl code,
3260 but this one happens at run time, although it may be optimized to
3261 be calculated at compile time if appropriate.  After preprocessing
3262 described above, and possibly after evaluation if concatenation,
3263 joining, casing translation, or metaquoting are involved, the
3264 resulting I<string> is passed to the RE engine for compilation.
3265
3266 Whatever happens in the RE engine might be better discussed in L<perlre>,
3267 but for the sake of continuity, we shall do so here.
3268
3269 This is another step where the presence of the C</x> modifier is
3270 relevant.  The RE engine scans the string from left to right and
3271 converts it into a finite automaton.
3272
3273 Backslashed characters are either replaced with corresponding
3274 literal strings (as with C<\{>), or else they generate special nodes
3275 in the finite automaton (as with C<\b>).  Characters special to the
3276 RE engine (such as C<|>) generate corresponding nodes or groups of
3277 nodes.  C<(?#...)> comments are ignored.  All the rest is either
3278 converted to literal strings to match, or else is ignored (as is
3279 whitespace and C<#>-style comments if C</x> is present).
3280
3281 Parsing of the bracketed character class construct, C<[...]>, is
3282 rather different than the rule used for the rest of the pattern.
3283 The terminator of this construct is found using the same rules as
3284 for finding the terminator of a C<{}>-delimited construct, the only
3285 exception being that C<]> immediately following C<[> is treated as
3286 though preceded by a backslash.
3287
3288 The terminator of runtime C<(?{...})> is found by temporarily switching
3289 control to the perl parser, which should stop at the point where the
3290 logically balancing terminating C<}> is found.
3291
3292 It is possible to inspect both the string given to RE engine and the
3293 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
3294 in the S<C<use L<re>>> pragma, as well as Perl's B<-Dr> command-line
3295 switch documented in L<perlrun/"Command Switches">.
3296
3297 =item Optimization of regular expressions
3298 X<regexp, optimization>
3299
3300 This step is listed for completeness only.  Since it does not change
3301 semantics, details of this step are not documented and are subject
3302 to change without notice.  This step is performed over the finite
3303 automaton that was generated during the previous pass.
3304
3305 It is at this stage that C<split()> silently optimizes C</^/> to
3306 mean C</^/m>.
3307
3308 =back
3309
3310 =head2 I/O Operators
3311 X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle>
3312 X<< <> >> X<< <<>> >> X<@ARGV>
3313
3314 There are several I/O operators you should know about.
3315
3316 A string enclosed by backticks (grave accents) first undergoes
3317 double-quote interpolation.  It is then interpreted as an external
3318 command, and the output of that command is the value of the
3319 backtick string, like in a shell.  In scalar context, a single string
3320 consisting of all output is returned.  In list context, a list of
3321 values is returned, one per line of output.  (You can set C<$/> to use
3322 a different line terminator.)  The command is executed each time the
3323 pseudo-literal is evaluated.  The status value of the command is
3324 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
3325 Unlike in B<csh>, no translation is done on the return data--newlines
3326 remain newlines.  Unlike in any of the shells, single quotes do not
3327 hide variable names in the command from interpretation.  To pass a
3328 literal dollar-sign through to the shell you need to hide it with a
3329 backslash.  The generalized form of backticks is C<qx//>, or you can
3330 call the L<perlfunc/readpipe> function.  (Because
3331 backticks always undergo shell expansion as well, see L<perlsec> for
3332 security concerns.)
3333 X<qx> X<`> X<``> X<backtick> X<glob>
3334
3335 In scalar context, evaluating a filehandle in angle brackets yields
3336 the next line from that file (the newline, if any, included), or
3337 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
3338 (sometimes known as file-slurp mode) and the file is empty, it
3339 returns C<''> the first time, followed by C<undef> subsequently.
3340
3341 Ordinarily you must assign the returned value to a variable, but
3342 there is one situation where an automatic assignment happens.  If
3343 and only if the input symbol is the only thing inside the conditional
3344 of a C<while> statement (even if disguised as a C<for(;;)> loop),
3345 the value is automatically assigned to the global variable C<$_>,
3346 destroying whatever was there previously.  (This may seem like an
3347 odd thing to you, but you'll use the construct in almost every Perl
3348 script you write.)  The C<$_> variable is not implicitly localized.
3349 You'll have to put a S<C<local $_;>> before the loop if you want that
3350 to happen.  Furthermore, if the input symbol or an explicit assignment
3351 of the input symbol to a scalar is used as a C<while>/C<for> condition,
3352 then the condition actually tests for definedness of the expression's
3353 value, not for its regular truth value.
3354
3355 Thus the following lines are equivalent:
3356
3357     while (defined($_ = <STDIN>)) { print; }
3358     while ($_ = <STDIN>) { print; }
3359     while (<STDIN>) { print; }
3360     for (;<STDIN>;) { print; }
3361     print while defined($_ = <STDIN>);
3362     print while ($_ = <STDIN>);
3363     print while <STDIN>;
3364
3365 This also behaves similarly, but assigns to a lexical variable
3366 instead of to C<$_>:
3367
3368     while (my $line = <STDIN>) { print $line }
3369
3370 In these loop constructs, the assigned value (whether assignment
3371 is automatic or explicit) is then tested to see whether it is
3372 defined.  The defined test avoids problems where the line has a string
3373 value that would be treated as false by Perl; for example a "" or
3374 a C<"0"> with no trailing newline.  If you really mean for such values
3375 to terminate the loop, they should be tested for explicitly:
3376
3377     while (($_ = <STDIN>) ne '0') { ... }
3378     while (<STDIN>) { last unless $_; ... }
3379
3380 In other boolean contexts, C<< <I<FILEHANDLE>> >> without an
3381 explicit C<defined> test or comparison elicits a warning if the
3382 S<C<use warnings>> pragma or the B<-w>
3383 command-line switch (the C<$^W> variable) is in effect.
3384
3385 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
3386 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
3387 in packages, where they would be interpreted as local identifiers
3388 rather than global.)  Additional filehandles may be created with
3389 the C<open()> function, amongst others.  See L<perlopentut> and
3390 L<perlfunc/open> for details on this.
3391 X<stdin> X<stdout> X<sterr>
3392
3393 If a C<< <I<FILEHANDLE>> >> is used in a context that is looking for
3394 a list, a list comprising all input lines is returned, one line per
3395 list element.  It's easy to grow to a rather large data space this
3396 way, so use with care.
3397
3398 C<< <I<FILEHANDLE>> >>  may also be spelled C<readline(*I<FILEHANDLE>)>.
3399 See L<perlfunc/readline>.
3400
3401 The null filehandle C<< <> >> (sometimes called the diamond operator) is
3402 special: it can be used to emulate the
3403 behavior of B<sed> and B<awk>, and any other Unix filter program
3404 that takes a list of filenames, doing the same to each line
3405 of input from all of them.  Input from C<< <> >> comes either from
3406 standard input, or from each file listed on the command line.  Here's
3407 how it works: the first time C<< <> >> is evaluated, the C<@ARGV> array is
3408 checked, and if it is empty, C<$ARGV[0]> is set to C<"-">, which when opened
3409 gives you standard input.  The C<@ARGV> array is then processed as a list
3410 of filenames.  The loop
3411
3412     while (<>) {
3413         ...                     # code for each line
3414     }
3415
3416 is equivalent to the following Perl-like pseudo code:
3417
3418     unshift(@ARGV, '-') unless @ARGV;
3419     while ($ARGV = shift) {
3420         open(ARGV, $ARGV);
3421         while (<ARGV>) {
3422             ...         # code for each line
3423         }
3424     }
3425
3426 except that it isn't so cumbersome to say, and will actually work.
3427 It really does shift the C<@ARGV> array and put the current filename
3428 into the C<$ARGV> variable.  It also uses filehandle I<ARGV>
3429 internally.  C<< <> >> is just a synonym for C<< <ARGV> >>, which
3430 is magical.  (The pseudo code above doesn't work because it treats
3431 C<< <ARGV> >> as non-magical.)
3432
3433 Since the null filehandle uses the two argument form of L<perlfunc/open>
3434 it interprets special characters, so if you have a script like this:
3435
3436     while (<>) {
3437         print;
3438     }
3439
3440 and call it with S<C<perl dangerous.pl 'rm -rfv *|'>>, it actually opens a
3441 pipe, executes the C<rm> command and reads C<rm>'s output from that pipe.
3442 If you want all items in C<@ARGV> to be interpreted as file names, you
3443 can use the module C<ARGV::readonly> from CPAN, or use the double
3444 diamond bracket:
3445
3446     while (<<>>) {
3447         print;
3448     }
3449
3450 Using double angle brackets inside of a while causes the open to use the
3451 three argument form (with the second argument being C<< < >>), so all
3452 arguments in C<ARGV> are treated as literal filenames (including C<"-">).
3453 (Note that for convenience, if you use C<< <<>> >> and if C<@ARGV> is
3454 empty, it will still read from the standard input.)
3455
3456 You can modify C<@ARGV> before the first C<< <> >> as long as the array ends up
3457 containing the list of filenames you really want.  Line numbers (C<$.>)
3458 continue as though the input were one big happy file.  See the example
3459 in L<perlfunc/eof> for how to reset line numbers on each file.
3460
3461 If you want to set C<@ARGV> to your own list of files, go right ahead.
3462 This sets C<@ARGV> to all plain text files if no C<@ARGV> was given:
3463
3464     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
3465
3466 You can even set them to pipe commands.  For example, this automatically
3467 filters compressed arguments through B<gzip>:
3468
3469     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
3470
3471 If you want to pass switches into your script, you can use one of the
3472 C<Getopts> modules or put a loop on the front like this:
3473
3474     while ($_ = $ARGV[0], /^-/) {
3475         shift;
3476         last if /^--$/;
3477         if (/^-D(.*)/) { $debug = $1 }
3478         if (/^-v/)     { $verbose++  }
3479         # ...           # other switches
3480     }
3481
3482     while (<>) {
3483         # ...           # code for each line
3484     }
3485
3486 The C<< <> >> symbol will return C<undef> for end-of-file only once.
3487 If you call it again after this, it will assume you are processing another
3488 C<@ARGV> list, and if you haven't set C<@ARGV>, will read input from STDIN.
3489
3490 If what the angle brackets contain is a simple scalar variable (for example,
3491 C<$foo>), then that variable contains the name of the
3492 filehandle to input from, or its typeglob, or a reference to the
3493 same.  For example:
3494
3495     $fh = \*STDIN;
3496     $line = <$fh>;
3497
3498 If what's within the angle brackets is neither a filehandle nor a simple
3499 scalar variable containing a filehandle name, typeglob, or typeglob
3500 reference, it is interpreted as a filename pattern to be globbed, and
3501 either a list of filenames or the next filename in the list is returned,
3502 depending on context.  This distinction is determined on syntactic
3503 grounds alone.  That means C<< <$x> >> is always a C<readline()> from
3504 an indirect handle, but C<< <$hash{key}> >> is always a C<glob()>.
3505 That's because C<$x> is a simple scalar variable, but C<$hash{key}> is
3506 not--it's a hash element.  Even C<< <$x > >> (note the extra space)
3507 is treated as C<glob("$x ")>, not C<readline($x)>.
3508
3509 One level of double-quote interpretation is done first, but you can't
3510 say C<< <$foo> >> because that's an indirect filehandle as explained
3511 in the previous paragraph.  (In older versions of Perl, programmers
3512 would insert curly brackets to force interpretation as a filename glob:
3513 C<< <${foo}> >>.  These days, it's considered cleaner to call the
3514 internal function directly as C<glob($foo)>, which is probably the right
3515 way to have done it in the first place.)  For example:
3516
3517     while (<*.c>) {
3518         chmod 0644, $_;
3519     }
3520
3521 is roughly equivalent to:
3522
3523     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
3524     while (<FOO>) {
3525         chomp;
3526         chmod 0644, $_;
3527     }
3528
3529 except that the globbing is actually done internally using the standard
3530 C<L<File::Glob>> extension.  Of course, the shortest way to do the above is:
3531
3532     chmod 0644, <*.c>;
3533
3534 A (file)glob evaluates its (embedded) argument only when it is
3535 starting a new list.  All values must be read before it will start
3536 over.  In list context, this isn't important because you automatically
3537 get them all anyway.  However, in scalar context the operator returns
3538 the next value each time it's called, or C<undef> when the list has
3539 run out.  As with filehandle reads, an automatic C<defined> is
3540 generated when the glob occurs in the test part of a C<while>,
3541 because legal glob returns (for example,
3542 a file called F<0>) would otherwise
3543 terminate the loop.  Again, C<undef> is returned only once.  So if
3544 you're expecting a single value from a glob, it is much better to
3545 say
3546
3547     ($file) = <blurch*>;
3548
3549 than
3550
3551     $file = <blurch*>;
3552
3553 because the latter will alternate between returning a filename and
3554 returning false.
3555
3556 If you're trying to do variable interpolation, it's definitely better
3557 to use the C<glob()> function, because the older notation can cause people
3558 to become confused with the indirect filehandle notation.
3559
3560     @files = glob("$dir/*.[ch]");
3561     @files = glob($files[$i]);
3562
3563 If an angle-bracket-based globbing expression is used as the condition of
3564 a C<while> or C<for> loop, then it will be implicitly assigned to C<$_>.
3565 If either a globbing expression or an explicit assignment of a globbing
3566 expression to a scalar is used as a C<while>/C<for> condition, then
3567 the condition actually tests for definedness of the expression's value,
3568 not for its regular truth value.
3569
3570 =head2 Constant Folding
3571 X<constant folding> X<folding>
3572
3573 Like C, Perl does a certain amount of expression evaluation at
3574 compile time whenever it determines that all arguments to an
3575 operator are static and have no side effects.  In particular, string
3576 concatenation happens at compile time between literals that don't do
3577 variable substitution.  Backslash interpolation also happens at
3578 compile time.  You can say
3579
3580       'Now is the time for all'
3581     . "\n"
3582     .  'good men to come to.'
3583
3584 and this all reduces to one string internally.  Likewise, if
3585 you say
3586
3587     foreach $file (@filenames) {
3588         if (-s $file > 5 + 100 * 2**16) {  }
3589     }
3590
3591 the compiler precomputes the number which that expression
3592 represents so that the interpreter won't have to.
3593
3594 =head2 No-ops
3595 X<no-op> X<nop>
3596
3597 Perl doesn't officially have a no-op operator, but the bare constants
3598 C<0> and C<1> are special-cased not to produce a warning in void
3599 context, so you can for example safely do
3600
3601     1 while foo();
3602
3603 =head2 Bitwise String Operators
3604 X<operator, bitwise, string> X<&.> X<|.> X<^.> X<~.>
3605
3606 Bitstrings of any size may be manipulated by the bitwise operators
3607 (C<~ | & ^>).
3608
3609 If the operands to a binary bitwise op are strings of different
3610 sizes, B<|> and B<^> ops act as though the shorter operand had
3611 additional zero bits on the right, while the B<&> op acts as though
3612 the longer operand were truncated to the length of the shorter.
3613 The granularity for such extension or truncation is one or more
3614 bytes.
3615
3616     # ASCII-based examples
3617     print "j p \n" ^ " a h";            # prints "JAPH\n"
3618     print "JA" | "  ph\n";              # prints "japh\n"
3619     print "japh\nJunk" & '_____';       # prints "JAPH\n";
3620     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
3621
3622 If you are intending to manipulate bitstrings, be certain that
3623 you're supplying bitstrings: If an operand is a number, that will imply
3624 a B<numeric> bitwise operation.  You may explicitly show which type of
3625 operation you intend by using C<""> or C<0+>, as in the examples below.
3626
3627     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
3628     $foo = '150' |  105;        # yields 255
3629     $foo =  150  | '105';       # yields 255
3630     $foo = '150' | '105';       # yields string '155' (under ASCII)
3631
3632     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
3633     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
3634
3635 This somewhat unpredictable behavior can be avoided with the "bitwise"
3636 feature, new in Perl 5.22.  You can enable it via S<C<use feature
3637 'bitwise'>> or C<use v5.28>.  Before Perl 5.28, it used to emit a warning
3638 in the C<"experimental::bitwise"> category.  Under this feature, the four
3639 standard bitwise operators (C<~ | & ^>) are always numeric.  Adding a dot
3640 after each operator (C<~. |. &. ^.>) forces it to treat its operands as
3641 strings:
3642
3643     use feature "bitwise";
3644     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
3645     $foo = '150' |  105;        # yields 255
3646     $foo =  150  | '105';       # yields 255
3647     $foo = '150' | '105';       # yields 255
3648     $foo =  150  |. 105;        # yields string '155'
3649     $foo = '150' |. 105;        # yields string '155'
3650     $foo =  150  |.'105';       # yields string '155'
3651     $foo = '150' |.'105';       # yields string '155'
3652
3653     $baz = $foo &  $bar;        # both operands numeric
3654     $biz = $foo ^. $bar;        # both operands stringy
3655
3656 The assignment variants of these operators (C<&= |= ^= &.= |.= ^.=>)
3657 behave likewise under the feature.
3658
3659 It is a fatal error if an operand contains a character whose ordinal
3660 value is above 0xFF, and hence not expressible except in UTF-8.  The
3661 operation is performed on a non-UTF-8 copy for other operands encoded in
3662 UTF-8.  See L<perlunicode/Byte and Character Semantics>.
3663
3664 See L<perlfunc/vec> for information on how to manipulate individual bits
3665 in a bit vector.
3666
3667 =head2 Integer Arithmetic
3668 X<integer>
3669
3670 By default, Perl assumes that it must do most of its arithmetic in
3671 floating point.  But by saying
3672
3673     use integer;
3674
3675 you may tell the compiler to use integer operations
3676 (see L<integer> for a detailed explanation) from here to the end of
3677 the enclosing BLOCK.  An inner BLOCK may countermand this by saying
3678
3679     no integer;
3680
3681 which lasts until the end of that BLOCK.  Note that this doesn't
3682 mean everything is an integer, merely that Perl will use integer
3683 operations for arithmetic, comparison, and bitwise operators.  For
3684 example, even under S<C<use integer>>, if you take the C<sqrt(2)>, you'll
3685 still get C<1.4142135623731> or so.
3686
3687 Used on numbers, the bitwise operators (C<&> C<|> C<^> C<~> C<< << >>
3688 C<< >> >>) always produce integral results.  (But see also
3689 L</Bitwise String Operators>.)  However, S<C<use integer>> still has meaning for
3690 them.  By default, their results are interpreted as unsigned integers, but
3691 if S<C<use integer>> is in effect, their results are interpreted
3692 as signed integers.  For example, C<~0> usually evaluates to a large
3693 integral value.  However, S<C<use integer; ~0>> is C<-1> on two's-complement
3694 machines.
3695
3696 =head2 Floating-point Arithmetic
3697
3698 X<floating-point> X<floating point> X<float> X<real>
3699
3700 While S<C<use integer>> provides integer-only arithmetic, there is no
3701 analogous mechanism to provide automatic rounding or truncation to a
3702 certain number of decimal places.  For rounding to a certain number
3703 of digits, C<sprintf()> or C<printf()> is usually the easiest route.
3704 See L<perlfaq4>.
3705
3706 Floating-point numbers are only approximations to what a mathematician
3707 would call real numbers.  There are infinitely more reals than floats,
3708 so some corners must be cut.  For example:
3709
3710     printf "%.20g\n", 123456789123456789;
3711     #        produces 123456789123456784
3712
3713 Testing for exact floating-point equality or inequality is not a
3714 good idea.  Here's a (relatively expensive) work-around to compare
3715 whether two floating-point numbers are equal to a particular number of
3716 decimal places.  See Knuth, volume II, for a more robust treatment of
3717 this topic.
3718
3719     sub fp_equal {
3720         my ($X, $Y, $POINTS) = @_;
3721         my ($tX, $tY);
3722         $tX = sprintf("%.${POINTS}g", $X);
3723         $tY = sprintf("%.${POINTS}g", $Y);
3724         return $tX eq $tY;
3725     }
3726
3727 The POSIX module (part of the standard perl distribution) implements
3728 C<ceil()>, C<floor()>, and other mathematical and trigonometric functions.
3729 The C<L<Math::Complex>> module (part of the standard perl distribution)
3730 defines mathematical functions that work on both the reals and the
3731 imaginary numbers.  C<Math::Complex> is not as efficient as POSIX, but
3732 POSIX can't work with complex numbers.
3733
3734 Rounding in financial applications can have serious implications, and
3735 the rounding method used should be specified precisely.  In these
3736 cases, it probably pays not to trust whichever system rounding is
3737 being used by Perl, but to instead implement the rounding function you
3738 need yourself.
3739
3740 =head2 Bigger Numbers
3741 X<number, arbitrary precision>
3742
3743 The standard C<L<Math::BigInt>>, C<L<Math::BigRat>>, and
3744 C<L<Math::BigFloat>> modules,
3745 along with the C<bignum>, C<bigint>, and C<bigrat> pragmas, provide
3746 variable-precision arithmetic and overloaded operators, although
3747 they're currently pretty slow.  At the cost of some space and
3748 considerable speed, they avoid the normal pitfalls associated with
3749 limited-precision representations.
3750
3751         use 5.010;
3752         use bigint;  # easy interface to Math::BigInt
3753         $x = 123456789123456789;
3754         say $x * $x;
3755     +15241578780673678515622620750190521
3756
3757 Or with rationals:
3758
3759         use 5.010;
3760         use bigrat;
3761         $x = 3/22;
3762         $y = 4/6;
3763         say "x/y is ", $x/$y;
3764         say "x*y is ", $x*$y;
3765         x/y is 9/44
3766         x*y is 1/11
3767
3768 Several modules let you calculate with unlimited or fixed precision
3769 (bound only by memory and CPU time).  There
3770 are also some non-standard modules that
3771 provide faster implementations via external C libraries.
3772
3773 Here is a short, but incomplete summary:
3774
3775   Math::String           treat string sequences like numbers
3776   Math::FixedPrecision   calculate with a fixed precision
3777   Math::Currency         for currency calculations
3778   Bit::Vector            manipulate bit vectors fast (uses C)
3779   Math::BigIntFast       Bit::Vector wrapper for big numbers
3780   Math::Pari             provides access to the Pari C library
3781   Math::Cephes           uses the external Cephes C library (no
3782                          big numbers)
3783   Math::Cephes::Fraction fractions via the Cephes library
3784   Math::GMP              another one using an external C library
3785   Math::GMPz             an alternative interface to libgmp's big ints
3786   Math::GMPq             an interface to libgmp's fraction numbers
3787   Math::GMPf             an interface to libgmp's floating point numbers
3788
3789 Choose wisely.
3790
3791 =cut