This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
t/loc_tools.pl: Add optional parameter to find_locales()
[perl5.git] / t / loc_tools.pl
1 # Common tools for test files files to find the locales which exist on the
2 # system.  Caller should have defined ok() for the unlikely event that setup
3 # here fails, and should have verified that this isn't miniperl before calling
4 # the functions.
5
6 # Note that it's okay that some languages have their native names
7 # capitalized here even though that's not "right".  They are lowercased
8 # anyway later during the scanning process (and besides, some clueless
9 # vendor might have them capitalized erroneously anyway).
10
11 sub _trylocale ($$$$) { # Adds the locale given by the first parameter to the
12                         # list given by the 3rd iff the platform supports the
13                         # locale in each of the categories given by the 2nd
14                         # parameter, which is either a single category or a
15                         # reference to a list of categories
16                         # The 4th parameter is true if to reject locales that
17                         # aren't apparently fully compatible with Perl.
18     my $locale = shift;
19     my $categories = shift;
20     my $list = shift;
21     my $only_plays_well = shift;
22
23     return if ! $locale || grep { $locale eq $_ } @$list;
24
25     $categories = [ $categories ] unless ref $categories;
26
27     my $badutf8 = 0;
28     my $plays_well = 1;
29
30     use warnings 'locale';
31
32     local $SIG{__WARN__} = sub {
33         $badutf8 = 1 if $_[0] =~ /Malformed UTF-8/;
34         $plays_well = 0 if $_[0] =~ /Locale .* may not work well/i
35     };
36
37     foreach my $category (@$categories) {
38         return unless setlocale($category, $locale);
39         return if $only_plays_well && ! $plays_well;
40     }
41
42     if ($badutf8) {
43         ok(0, "Verify locale name doesn't contain malformed utf8");
44         return;
45     }
46     push @$list, $locale;
47 }
48
49 sub _decode_encodings {
50     my @enc;
51
52     foreach (split(/ /, shift)) {
53         if (/^(\d+)$/) {
54             push @enc, "ISO8859-$1";
55             push @enc, "iso8859$1";     # HP
56             if ($1 eq '1') {
57                  push @enc, "roman8";   # HP
58             }
59             push @enc, $_;
60             push @enc, "$_.UTF-8";
61             push @enc, "$_.65001"; # Windows UTF-8
62             push @enc, "$_.ACP"; # Windows ANSI code page
63             push @enc, "$_.OCP"; # Windows OEM code page
64             push @enc, "$_.1252"; # Windows
65         }
66     }
67     if ($^O eq 'os390') {
68         push @enc, qw(IBM-037 IBM-819 IBM-1047);
69     }
70     push @enc, "UTF-8";
71     push @enc, "65001"; # Windows UTF-8
72
73     return @enc;
74 }
75
76 sub find_locales ($;$) {  # Returns an array of all the locales we found on the
77                           # system.  If the optional 2nd parameter is
78                           # non-zero, the list is restricted to those locales
79                           # that play well with Perl.
80                           # The first parameter is either a single locale
81                           # category or a reference to a list of categories to
82                           # find valid locales for it (or in the case of
83                           # multiple) for all of them.
84     my $categories = shift;
85     my $only_plays_well = shift // 0;
86
87     use Config;;
88     my $have_setlocale = $Config{d_setlocale};
89
90     # Visual C's CRT goes silly on strings of the form "en_US.ISO8859-1"
91     # and mingw32 uses said silly CRT
92     # This doesn't seem to be an issue any more, at least on Windows XP,
93     # so re-enable the tests for Windows XP onwards.
94     my $winxp = ($^O eq 'MSWin32' && defined &Win32::GetOSVersion &&
95                     join('.', (Win32::GetOSVersion())[1..2]) >= 5.1);
96     $have_setlocale = 0 if ((($^O eq 'MSWin32' && !$winxp) || $^O eq 'NetWare') &&
97                     $Config{cc} =~ /^(cl|gcc|g\+\+|ici)/i);
98
99     # UWIN seems to loop after taint tests, just skip for now
100     $have_setlocale = 0 if ($^O =~ /^uwin/);
101
102     return unless $have_setlocale;
103
104     # Done this way in case this is 'required' in the caller before seeing if
105     # this is miniperl.
106     eval { require POSIX; import POSIX 'locale_h'; };
107     unless (defined &POSIX::LC_CTYPE) {
108       return;
109     }
110
111     _trylocale("C", $categories, \@Locale, $only_plays_well);
112     _trylocale("POSIX", $categories, \@Locale, $only_plays_well);
113     foreach (0..15) {
114         _trylocale("ISO8859-$_", $categories, \@Locale, $only_plays_well);
115         _trylocale("iso8859$_", $categories, \@Locale, $only_plays_well);
116         _trylocale("iso8859-$_", $categories, \@Locale, $only_plays_well);
117         _trylocale("iso_8859_$_", $categories, \@Locale, $only_plays_well);
118         _trylocale("isolatin$_", $categories, \@Locale, $only_plays_well);
119         _trylocale("isolatin-$_", $categories, \@Locale, $only_plays_well);
120         _trylocale("iso_latin_$_", $categories, \@Locale, $only_plays_well);
121     }
122
123     # Sanitize the environment so that we can run the external 'locale'
124     # program without the taint mode getting grumpy.
125
126     # $ENV{PATH} is special in VMS.
127     delete local $ENV{PATH} if $^O ne 'VMS' or $Config{d_setenv};
128
129     # Other subversive stuff.
130     delete local @ENV{qw(IFS CDPATH ENV BASH_ENV)};
131
132     if (-x "/usr/bin/locale"
133         && open(LOCALES, "/usr/bin/locale -a 2>/dev/null|"))
134     {
135         while (<LOCALES>) {
136             # It seems that /usr/bin/locale steadfastly outputs 8 bit data, which
137             # ain't great when we're running this testPERL_UNICODE= so that utf8
138             # locales will cause all IO hadles to default to (assume) utf8
139             next unless utf8::valid($_);
140             chomp;
141             _trylocale($_, $categories, \@Locale, $only_plays_well);
142         }
143         close(LOCALES);
144     } elsif ($^O eq 'VMS'
145              && defined($ENV{'SYS$I18N_LOCALE'})
146              && -d 'SYS$I18N_LOCALE')
147     {
148     # The SYS$I18N_LOCALE logical name search list was not present on
149     # VAX VMS V5.5-12, but was on AXP && VAX VMS V6.2 as well as later versions.
150         opendir(LOCALES, "SYS\$I18N_LOCALE:");
151         while ($_ = readdir(LOCALES)) {
152             chomp;
153             _trylocale($_, $categories, \@Locale, $only_plays_well);
154         }
155         close(LOCALES);
156     } elsif (($^O eq 'openbsd' || $^O eq 'bitrig' ) && -e '/usr/share/locale') {
157
158     # OpenBSD doesn't have a locale executable, so reading /usr/share/locale
159     # is much easier and faster than the last resort method.
160
161         opendir(LOCALES, '/usr/share/locale');
162         while ($_ = readdir(LOCALES)) {
163             chomp;
164             _trylocale($_, $categories, \@Locale, $only_plays_well);
165         }
166         close(LOCALES);
167     } else { # Final fallback.  Try our list of locales hard-coded here
168
169         # This is going to be slow.
170         my @Data;
171
172         # Locales whose name differs if the utf8 bit is on are stored in these two
173         # files with appropriate encodings.
174         if ($^H & 0x08 || (${^OPEN} || "") =~ /:utf8/) {
175             @Data = do "lib/locale/utf8";
176         } else {
177             @Data = do "lib/locale/latin1";
178         }
179
180         # The rest of the locales are in this file.
181         push @Data, <DATA>;
182
183         foreach my $line (@Data) {
184             my ($locale_name, $language_codes, $country_codes, $encodings) =
185                 split /:/, $line;
186             my @enc = _decode_encodings($encodings);
187             foreach my $loc (split(/ /, $locale_name)) {
188                 _trylocale($loc, $categories, \@Locale, $only_plays_well);
189                 foreach my $enc (@enc) {
190                     _trylocale("$loc.$enc", $categories, \@Locale,
191                                                             $only_plays_well);
192                 }
193                 $loc = lc $loc;
194                 foreach my $enc (@enc) {
195                     _trylocale("$loc.$enc", $categories, \@Locale,
196                                                             $only_plays_well);
197                 }
198             }
199             foreach my $lang (split(/ /, $language_codes)) {
200                 _trylocale($lang, $categories, \@Locale, $only_plays_well);
201                 foreach my $country (split(/ /, $country_codes)) {
202                     my $lc = "${lang}_${country}";
203                     _trylocale($lc, $categories, \@Locale, $only_plays_well);
204                     foreach my $enc (@enc) {
205                         _trylocale("$lc.$enc", $categories, \@Locale,
206                                                             $only_plays_well);
207                     }
208                     my $lC = "${lang}_\U${country}";
209                     _trylocale($lC, $categories, \@Locale, $only_plays_well);
210                     foreach my $enc (@enc) {
211                         _trylocale("$lC.$enc", $categories, \@Locale,
212                                                             $only_plays_well);
213                     }
214                 }
215             }
216         }
217     }
218
219     @Locale = sort @Locale;
220
221     return @Locale;
222 }
223
224 sub is_locale_utf8 ($) { # Return a boolean as to if core Perl thinks the input
225                          # is a UTF-8 locale
226
227     # On z/OS, even locales marked as UTF-8 aren't.
228     return 0 if ord "A" != 65;
229
230     my $locale = shift;
231
232     use locale;
233     no warnings 'locale'; # We may be trying out a weird locale
234
235     my $save_locale = setlocale(&POSIX::LC_CTYPE());
236     if (! $save_locale) {
237         ok(0, "Verify could save previous locale");
238         return 0;
239     }
240
241     if (! setlocale(&POSIX::LC_CTYPE(), $locale)) {
242         ok(0, "Verify could setlocale to $locale");
243         return 0;
244     }
245
246     my $ret = 0;
247
248     # Use an op that gives different results for UTF-8 than any other locale.
249     # If a platform has UTF-8 locales, there should be at least one locale on
250     # most platforms with UTF-8 in its name, so if there is a bug in the op
251     # giving a false negative, we should get a failure for those locales as we
252     # go through testing all the locales on the platform.
253     if (CORE::fc(chr utf8::unicode_to_native(0xdf)) ne "ss") {
254         if ($locale =~ /UTF-?8/i) {
255             ok (0, "Verify $locale with UTF-8 in name is a UTF-8 locale");
256         }
257     }
258     else {
259         $ret = 1;
260     }
261
262     die "Couldn't restore locale '$save_locale'"
263         unless setlocale(&POSIX::LC_CTYPE(), $save_locale);
264
265     return $ret;
266 }
267
268 sub find_utf8_ctype_locale (;$) { # Return the name of a locale that core Perl
269                                   # thinks is a UTF-8 LC_CTYPE locale.
270                                   # Optional parameter is a reference to a
271                                   # list of locales to try; if omitted, this
272                                   # tries all locales it can find on the
273                                   # platform
274     my $locales_ref = shift;
275     return if !defined &POSIX::LC_CTYPE;
276     if (! defined $locales_ref) {
277         my @locales = find_locales(&POSIX::LC_CTYPE(),
278                                    1 # Reject iffy locales.
279                                   );
280         $locales_ref = \@locales;
281     }
282
283     foreach my $locale (@$locales_ref) {
284         return $locale if is_locale_utf8($locale);
285     }
286
287     return;
288 }
289
290 1
291
292 # Format of data is: locale_name, language_codes, country_codes, encodings
293 __DATA__
294 Afrikaans:af:za:1 15
295 Arabic:ar:dz eg sa:6 arabic8
296 Brezhoneg Breton:br:fr:1 15
297 Bulgarski Bulgarian:bg:bg:5
298 Chinese:zh:cn tw:cn.EUC eucCN eucTW euc.CN euc.TW Big5 GB2312 tw.EUC
299 Hrvatski Croatian:hr:hr:2
300 Cymraeg Welsh:cy:cy:1 14 15
301 Czech:cs:cz:2
302 Dansk Danish:da:dk:1 15
303 Nederlands Dutch:nl:be nl:1 15
304 English American British:en:au ca gb ie nz us uk zw:1 15 cp850
305 Esperanto:eo:eo:3
306 Eesti Estonian:et:ee:4 6 13
307 Suomi Finnish:fi:fi:1 15
308 Flamish::fl:1 15
309 Deutsch German:de:at be ch de lu:1 15
310 Euskaraz Basque:eu:es fr:1 15
311 Galego Galician:gl:es:1 15
312 Ellada Greek:el:gr:7 g8
313 Frysk:fy:nl:1 15
314 Greenlandic:kl:gl:4 6
315 Hebrew:iw:il:8 hebrew8
316 Hungarian:hu:hu:2
317 Indonesian:id:id:1 15
318 Gaeilge Irish:ga:IE:1 14 15
319 Italiano Italian:it:ch it:1 15
320 Nihongo Japanese:ja:jp:euc eucJP jp.EUC sjis
321 Korean:ko:kr:
322 Latine Latin:la:va:1 15
323 Latvian:lv:lv:4 6 13
324 Lithuanian:lt:lt:4 6 13
325 Macedonian:mk:mk:1 15
326 Maltese:mt:mt:3
327 Moldovan:mo:mo:2
328 Norsk Norwegian:no no\@nynorsk nb nn:no:1 15
329 Occitan:oc:es:1 15
330 Polski Polish:pl:pl:2
331 Rumanian:ro:ro:2
332 Russki Russian:ru:ru su ua:5 koi8 koi8r KOI8-R koi8u cp1251 cp866
333 Serbski Serbian:sr:yu:5
334 Slovak:sk:sk:2
335 Slovene Slovenian:sl:si:2
336 Sqhip Albanian:sq:sq:1 15
337 Svenska Swedish:sv:fi se:1 15
338 Thai:th:th:11 tis620
339 Turkish:tr:tr:9 turkish8
340 Yiddish:yi::1 15