This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Bump $Carp::Heavy::VERSION too to avoid test failure from 858e29b93a
[perl5.git] / ext / attributes / attributes.pm
1 package attributes;
2
3 our $VERSION = 0.20;
4
5 @EXPORT_OK = qw(get reftype);
6 @EXPORT = ();
7 %EXPORT_TAGS = (ALL => [@EXPORT, @EXPORT_OK]);
8
9 use strict;
10
11 sub croak {
12     require Carp;
13     goto &Carp::croak;
14 }
15
16 sub carp {
17     require Carp;
18     goto &Carp::carp;
19 }
20
21 my %deprecated;
22 $deprecated{CODE} = qr/\A-?(locked)\z/;
23 $deprecated{ARRAY} = $deprecated{HASH} = $deprecated{SCALAR}
24     = qr/\A-?(unique)\z/;
25
26 sub _modify_attrs_and_deprecate {
27     my $svtype = shift;
28     # Now that we've removed handling of locked from the XS code, we need to
29     # remove it here, else it ends up in @badattrs. (If we do the deprecation in
30     # XS, we can't control the warning based on *our* caller's lexical settings,
31     # and the warned line is in this package)
32     grep {
33         $deprecated{$svtype} && /$deprecated{$svtype}/ ? do {
34             require warnings;
35             warnings::warnif('deprecated', "Attribute \"$1\" is deprecated");
36             0;
37         } : $svtype eq 'CODE' && /^-?lvalue\z/ ? do {
38             require warnings;
39             warnings::warnif(
40                 'misc',
41                 "lvalue attribute "
42                    . (/^-/ ? "removed from" : "applied to")
43                    . " already-defined subroutine"
44             );
45             0;
46         } : 1
47     } _modify_attrs(@_);
48 }
49
50 sub import {
51     @_ > 2 && ref $_[2] or do {
52         require Exporter;
53         goto &Exporter::import;
54     };
55     my (undef,$home_stash,$svref,@attrs) = @_;
56
57     my $svtype = uc reftype($svref);
58     my $pkgmeth;
59     $pkgmeth = UNIVERSAL::can($home_stash, "MODIFY_${svtype}_ATTRIBUTES")
60         if defined $home_stash && $home_stash ne '';
61     my @badattrs;
62     if ($pkgmeth) {
63         my @pkgattrs = _modify_attrs_and_deprecate($svtype, $svref, @attrs);
64         @badattrs = $pkgmeth->($home_stash, $svref, @pkgattrs);
65         if (!@badattrs && @pkgattrs) {
66             require warnings;
67             return unless warnings::enabled('reserved');
68             @pkgattrs = grep { m/\A[[:lower:]]+(?:\z|\()/ } @pkgattrs;
69             if (@pkgattrs) {
70                 for my $attr (@pkgattrs) {
71                     $attr =~ s/\(.+\z//s;
72                 }
73                 my $s = ((@pkgattrs == 1) ? '' : 's');
74                 carp "$svtype package attribute$s " .
75                     "may clash with future reserved word$s: " .
76                     join(' : ' , @pkgattrs);
77             }
78         }
79     }
80     else {
81         @badattrs = _modify_attrs_and_deprecate($svtype, $svref, @attrs);
82     }
83     if (@badattrs) {
84         croak "Invalid $svtype attribute" .
85             (( @badattrs == 1 ) ? '' : 's') .
86             ": " .
87             join(' : ', @badattrs);
88     }
89 }
90
91 sub get ($) {
92     @_ == 1  && ref $_[0] or
93         croak 'Usage: '.__PACKAGE__.'::get $ref';
94     my $svref = shift;
95     my $svtype = uc reftype($svref);
96     my $stash = _guess_stash($svref);
97     $stash = caller unless defined $stash;
98     my $pkgmeth;
99     $pkgmeth = UNIVERSAL::can($stash, "FETCH_${svtype}_ATTRIBUTES")
100         if defined $stash && $stash ne '';
101     return $pkgmeth ?
102                 (_fetch_attrs($svref), $pkgmeth->($stash, $svref)) :
103                 (_fetch_attrs($svref))
104         ;
105 }
106
107 sub require_version { goto &UNIVERSAL::VERSION }
108
109 require XSLoader;
110 XSLoader::load();
111
112 1;
113 __END__
114 #The POD goes here
115
116 =head1 NAME
117
118 attributes - get/set subroutine or variable attributes
119
120 =head1 SYNOPSIS
121
122   sub foo : method ;
123   my ($x,@y,%z) : Bent = 1;
124   my $s = sub : method { ... };
125
126   use attributes ();    # optional, to get subroutine declarations
127   my @attrlist = attributes::get(\&foo);
128
129   use attributes 'get'; # import the attributes::get subroutine
130   my @attrlist = get \&foo;
131
132 =head1 DESCRIPTION
133
134 Subroutine declarations and definitions may optionally have attribute lists
135 associated with them.  (Variable C<my> declarations also may, but see the
136 warning below.)  Perl handles these declarations by passing some information
137 about the call site and the thing being declared along with the attribute
138 list to this module.  In particular, the first example above is equivalent to
139 the following:
140
141     use attributes __PACKAGE__, \&foo, 'method';
142
143 The second example in the synopsis does something equivalent to this:
144
145     use attributes ();
146     my ($x,@y,%z);
147     attributes::->import(__PACKAGE__, \$x, 'Bent');
148     attributes::->import(__PACKAGE__, \@y, 'Bent');
149     attributes::->import(__PACKAGE__, \%z, 'Bent');
150     ($x,@y,%z) = 1;
151
152 Yes, that's a lot of expansion.
153
154 B<WARNING>: attribute declarations for variables are still evolving.
155 The semantics and interfaces of such declarations could change in
156 future versions.  They are present for purposes of experimentation
157 with what the semantics ought to be.  Do not rely on the current
158 implementation of this feature.
159
160 There are only a few attributes currently handled by Perl itself (or
161 directly by this module, depending on how you look at it.)  However,
162 package-specific attributes are allowed by an extension mechanism.
163 (See L<"Package-specific Attribute Handling"> below.)
164
165 The setting of subroutine attributes happens at compile time.
166 Variable attributes in C<our> declarations are also applied at compile time.
167 However, C<my> variables get their attributes applied at run-time.
168 This means that you have to I<reach> the run-time component of the C<my>
169 before those attributes will get applied.  For example:
170
171     my $x : Bent = 42 if 0;
172
173 will neither assign 42 to $x I<nor> will it apply the C<Bent> attribute
174 to the variable.
175
176 An attempt to set an unrecognized attribute is a fatal error.  (The
177 error is trappable, but it still stops the compilation within that
178 C<eval>.)  Setting an attribute with a name that's all lowercase
179 letters that's not a built-in attribute (such as "foo") will result in
180 a warning with B<-w> or C<use warnings 'reserved'>.
181
182 =head2 What C<import> does
183
184 In the description it is mentioned that
185
186   sub foo : method;
187
188 is equivalent to
189
190   use attributes __PACKAGE__, \&foo, 'method';
191
192 As you might know this calls the C<import> function of C<attributes> at compile 
193 time with these parameters: 'attributes', the caller's package name, the reference 
194 to the code and 'method'.
195
196   attributes->import( __PACKAGE__, \&foo, 'method' );
197
198 So you want to know what C<import> actually does?
199
200 First of all C<import> gets the type of the third parameter ('CODE' in this case).
201 C<attributes.pm> checks if there is a subroutine called C<< MODIFY_<reftype>_ATTRIBUTES >>
202 in the caller's namespace (here: 'main').  In this case a
203 subroutine C<MODIFY_CODE_ATTRIBUTES> is required.  Then this
204 method is called to check if you have used a "bad attribute".
205 The subroutine call in this example would look like
206
207   MODIFY_CODE_ATTRIBUTES( 'main', \&foo, 'method' );
208
209 C<< MODIFY_<reftype>_ATTRIBUTES >> has to return a list of all "bad attributes".
210 If there are any bad attributes C<import> croaks.
211
212 (See L<"Package-specific Attribute Handling"> below.)
213
214 =head2 Built-in Attributes
215
216 The following are the built-in attributes for subroutines:
217
218 =over 4
219
220 =item lvalue
221
222 Indicates that the referenced subroutine is a valid lvalue and can
223 be assigned to.  The subroutine must return a modifiable value such
224 as a scalar variable, as described in L<perlsub>.
225
226 This module allows one to set this attribute on a subroutine that is
227 already defined.  For Perl subroutines (XSUBs are fine), it may or may not
228 do what you want, depending on the code inside the subroutine, with details
229 subject to change in future Perl versions.  You may run into problems with
230 lvalue context not being propagated properly into the subroutine, or maybe
231 even assertion failures.  For this reason, a warning is emitted if warnings
232 are enabled.  In other words, you should only do this if you really know
233 what you are doing.  You have been warned.
234
235 =item method
236
237 Indicates that the referenced subroutine
238 is a method.  A subroutine so marked
239 will not trigger the "Ambiguous call resolved as CORE::%s" warning.
240
241 =item locked
242
243 The "locked" attribute has no effect in
244 5.10.0 and later.  It was used as part
245 of the now-removed "Perl 5.005 threads".
246
247 =back
248
249 =head2 Available Subroutines
250
251 The following subroutines are available for general use once this module
252 has been loaded:
253
254 =over 4
255
256 =item get
257
258 This routine expects a single parameter--a reference to a
259 subroutine or variable.  It returns a list of attributes, which may be
260 empty.  If passed invalid arguments, it uses die() (via L<Carp::croak|Carp>)
261 to raise a fatal exception.  If it can find an appropriate package name
262 for a class method lookup, it will include the results from a
263 C<FETCH_I<type>_ATTRIBUTES> call in its return list, as described in
264 L<"Package-specific Attribute Handling"> below.
265 Otherwise, only L<built-in attributes|"Built-in Attributes"> will be returned.
266
267 =item reftype
268
269 This routine expects a single parameter--a reference to a subroutine or
270 variable.  It returns the built-in type of the referenced variable,
271 ignoring any package into which it might have been blessed.
272 This can be useful for determining the I<type> value which forms part of
273 the method names described in L<"Package-specific Attribute Handling"> below.
274
275 =back
276
277 Note that these routines are I<not> exported by default.
278
279 =head2 Package-specific Attribute Handling
280
281 B<WARNING>: the mechanisms described here are still experimental.  Do not
282 rely on the current implementation.  In particular, there is no provision
283 for applying package attributes to 'cloned' copies of subroutines used as
284 closures.  (See L<perlref/"Making References"> for information on closures.)
285 Package-specific attribute handling may change incompatibly in a future
286 release.
287
288 When an attribute list is present in a declaration, a check is made to see
289 whether an attribute 'modify' handler is present in the appropriate package
290 (or its @ISA inheritance tree).  Similarly, when C<attributes::get> is
291 called on a valid reference, a check is made for an appropriate attribute
292 'fetch' handler.  See L<"EXAMPLES"> to see how the "appropriate package"
293 determination works.
294
295 The handler names are based on the underlying type of the variable being
296 declared or of the reference passed.  Because these attributes are
297 associated with subroutine or variable declarations, this deliberately
298 ignores any possibility of being blessed into some package.  Thus, a
299 subroutine declaration uses "CODE" as its I<type>, and even a blessed
300 hash reference uses "HASH" as its I<type>.
301
302 The class methods invoked for modifying and fetching are these:
303
304 =over 4
305
306 =item FETCH_I<type>_ATTRIBUTES
307
308 This method is called with two arguments:  the relevant package name,
309 and a reference to a variable or subroutine for which package-defined
310 attributes are desired.  The expected return value is a list of
311 associated attributes.  This list may be empty.
312
313 =item MODIFY_I<type>_ATTRIBUTES
314
315 This method is called with two fixed arguments, followed by the list of
316 attributes from the relevant declaration.  The two fixed arguments are
317 the relevant package name and a reference to the declared subroutine or
318 variable.  The expected return value is a list of attributes which were
319 not recognized by this handler.  Note that this allows for a derived class
320 to delegate a call to its base class, and then only examine the attributes
321 which the base class didn't already handle for it.
322
323 The call to this method is currently made I<during> the processing of the
324 declaration.  In particular, this means that a subroutine reference will
325 probably be for an undefined subroutine, even if this declaration is
326 actually part of the definition.
327
328 =back
329
330 Calling C<attributes::get()> from within the scope of a null package
331 declaration C<package ;> for an unblessed variable reference will
332 not provide any starting package name for the 'fetch' method lookup.
333 Thus, this circumstance will not result in a method call for package-defined
334 attributes.  A named subroutine knows to which symbol table entry it belongs
335 (or originally belonged), and it will use the corresponding package.
336 An anonymous subroutine knows the package name into which it was compiled
337 (unless it was also compiled with a null package declaration), and so it
338 will use that package name.
339
340 =head2 Syntax of Attribute Lists
341
342 An attribute list is a sequence of attribute specifications, separated by
343 whitespace or a colon (with optional whitespace).
344 Each attribute specification is a simple
345 name, optionally followed by a parenthesised parameter list.
346 If such a parameter list is present, it is scanned past as for the rules
347 for the C<q()> operator.  (See L<perlop/"Quote and Quote-like Operators">.)
348 The parameter list is passed as it was found, however, and not as per C<q()>.
349
350 Some examples of syntactically valid attribute lists:
351
352     switch(10,foo(7,3))  :  expensive
353     Ugly('\(") :Bad
354     _5x5
355     lvalue method
356
357 Some examples of syntactically invalid attribute lists (with annotation):
358
359     switch(10,foo()             # ()-string not balanced
360     Ugly('(')                   # ()-string not balanced
361     5x5                         # "5x5" not a valid identifier
362     Y2::north                   # "Y2::north" not a simple identifier
363     foo + bar                   # "+" neither a colon nor whitespace
364
365 =head1 EXPORTS
366
367 =head2 Default exports
368
369 None.
370
371 =head2 Available exports
372
373 The routines C<get> and C<reftype> are exportable.
374
375 =head2 Export tags defined
376
377 The C<:ALL> tag will get all of the above exports.
378
379 =head1 EXAMPLES
380
381 Here are some samples of syntactically valid declarations, with annotation
382 as to how they resolve internally into C<use attributes> invocations by
383 perl.  These examples are primarily useful to see how the "appropriate
384 package" is found for the possible method lookups for package-defined
385 attributes.
386
387 =over 4
388
389 =item 1.
390
391 Code:
392
393     package Canine;
394     package Dog;
395     my Canine $spot : Watchful ;
396
397 Effect:
398
399     use attributes ();
400     attributes::->import(Canine => \$spot, "Watchful");
401
402 =item 2.
403
404 Code:
405
406     package Felis;
407     my $cat : Nervous;
408
409 Effect:
410
411     use attributes ();
412     attributes::->import(Felis => \$cat, "Nervous");
413
414 =item 3.
415
416 Code:
417
418     package X;
419     sub foo : lvalue ;
420
421 Effect:
422
423     use attributes X => \&foo, "lvalue";
424
425 =item 4.
426
427 Code:
428
429     package X;
430     sub Y::x : lvalue { 1 }
431
432 Effect:
433
434     use attributes Y => \&Y::x, "lvalue";
435
436 =item 5.
437
438 Code:
439
440     package X;
441     sub foo { 1 }
442
443     package Y;
444     BEGIN { *bar = \&X::foo; }
445
446     package Z;
447     sub Y::bar : lvalue ;
448
449 Effect:
450
451     use attributes X => \&X::foo, "lvalue";
452
453 =back
454
455 This last example is purely for purposes of completeness.  You should not
456 be trying to mess with the attributes of something in a package that's
457 not your own.
458
459 =head1 MORE EXAMPLES
460
461 =over 4
462
463 =item 1.
464
465     sub MODIFY_CODE_ATTRIBUTES {
466        my ($class,$code,@attrs) = @_;
467
468        my $allowed = 'MyAttribute';
469        my @bad = grep { $_ ne $allowed } @attrs;
470
471        return @bad;
472     }
473
474     sub foo : MyAttribute {
475        print "foo\n";
476     }
477
478 This example runs.  At compile time
479 C<MODIFY_CODE_ATTRIBUTES> is called.  In that
480 subroutine, we check if any attribute is disallowed and we return a list of
481 these "bad attributes".
482
483 As we return an empty list, everything is fine.
484
485 =item 2.
486
487   sub MODIFY_CODE_ATTRIBUTES {
488      my ($class,$code,@attrs) = @_;
489
490      my $allowed = 'MyAttribute';
491      my @bad = grep{ $_ ne $allowed }@attrs;
492
493      return @bad;
494   }
495
496   sub foo : MyAttribute Test {
497      print "foo\n";
498   }
499
500 This example is aborted at compile time as we use the attribute "Test" which
501 isn't allowed.  C<MODIFY_CODE_ATTRIBUTES>
502 returns a list that contains a single
503 element ('Test').
504
505 =back
506
507 =head1 SEE ALSO
508
509 L<perlsub/"Private Variables via my()"> and
510 L<perlsub/"Subroutine Attributes"> for details on the basic declarations;
511 L<perlfunc/use> for details on the normal invocation mechanism.
512
513 =cut