This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
ef2a66e3f61299c719eb6f8a2ac0ae4be2a73384
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start or end of the string to matching the start or end of any
35 line anywhere within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as /ms, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If C<use locale> is in effect, the case map is taken from the current
55 locale.  See L<perllocale>.
56
57 =item x
58 X</x>
59
60 Extend your pattern's legibility by permitting whitespace and comments.
61
62 =item p
63 X</p> X<regex, preserve> X<regexp, preserve>
64
65 Preserve the string matched such that ${^PREMATCH}, {$^MATCH}, and
66 ${^POSTMATCH} are available for use after matching.
67
68 =item g and c
69 X</g> X</c>
70
71 Global matching, and keep the Current position after failed matching.
72 Unlike i, m, s and x, these two flags affect the way the regex is used
73 rather than the regex itself. See
74 L<perlretut/"Using regular expressions in Perl"> for further explanation
75 of the g and c modifiers.
76
77 =back
78
79 These are usually written as "the C</x> modifier", even though the delimiter
80 in question might not really be a slash.  Any of these
81 modifiers may also be embedded within the regular expression itself using
82 the C<(?...)> construct.  See below.
83
84 The C</x> modifier itself needs a little more explanation.  It tells
85 the regular expression parser to ignore whitespace that is neither
86 backslashed nor within a character class.  You can use this to break up
87 your regular expression into (slightly) more readable parts.  The C<#>
88 character is also treated as a metacharacter introducing a comment,
89 just as in ordinary Perl code.  This also means that if you want real
90 whitespace or C<#> characters in the pattern (outside a character
91 class, where they are unaffected by C</x>), then you'll either have to
92 escape them (using backslashes or C<\Q...\E>) or encode them using octal
93 or hex escapes.  Taken together, these features go a long way towards
94 making Perl's regular expressions more readable.  Note that you have to
95 be careful not to include the pattern delimiter in the comment--perl has
96 no way of knowing you did not intend to close the pattern early.  See
97 the C-comment deletion code in L<perlop>.  Also note that anything inside
98 a C<\Q...\E> stays unaffected by C</x>.
99 X</x>
100
101 =head2 Regular Expressions
102
103 =head3 Metacharacters
104
105 The patterns used in Perl pattern matching evolved from the ones supplied in
106 the Version 8 regex routines.  (The routines are derived
107 (distantly) from Henry Spencer's freely redistributable reimplementation
108 of the V8 routines.)  See L<Version 8 Regular Expressions> for
109 details.
110
111 In particular the following metacharacters have their standard I<egrep>-ish
112 meanings:
113 X<metacharacter>
114 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
115
116
117     \   Quote the next metacharacter
118     ^   Match the beginning of the line
119     .   Match any character (except newline)
120     $   Match the end of the line (or before newline at the end)
121     |   Alternation
122     ()  Grouping
123     []  Character class
124
125 By default, the "^" character is guaranteed to match only the
126 beginning of the string, the "$" character only the end (or before the
127 newline at the end), and Perl does certain optimizations with the
128 assumption that the string contains only one line.  Embedded newlines
129 will not be matched by "^" or "$".  You may, however, wish to treat a
130 string as a multi-line buffer, such that the "^" will match after any
131 newline within the string (except if the newline is the last character in
132 the string), and "$" will match before any newline.  At the
133 cost of a little more overhead, you can do this by using the /m modifier
134 on the pattern match operator.  (Older programs did this by setting C<$*>,
135 but this practice has been removed in perl 5.9.)
136 X<^> X<$> X</m>
137
138 To simplify multi-line substitutions, the "." character never matches a
139 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
140 the string is a single line--even if it isn't.
141 X<.> X</s>
142
143 =head3 Quantifiers
144
145 The following standard quantifiers are recognized:
146 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
147
148     *      Match 0 or more times
149     +      Match 1 or more times
150     ?      Match 1 or 0 times
151     {n}    Match exactly n times
152     {n,}   Match at least n times
153     {n,m}  Match at least n but not more than m times
154
155 (If a curly bracket occurs in any other context, it is treated
156 as a regular character.  In particular, the lower bound
157 is not optional.)  The "*" quantifier is equivalent to C<{0,}>, the "+"
158 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
159 to integral values less than a preset limit defined when perl is built.
160 This is usually 32766 on the most common platforms.  The actual limit can
161 be seen in the error message generated by code such as this:
162
163     $_ **= $_ , / {$_} / for 2 .. 42;
164
165 By default, a quantified subpattern is "greedy", that is, it will match as
166 many times as possible (given a particular starting location) while still
167 allowing the rest of the pattern to match.  If you want it to match the
168 minimum number of times possible, follow the quantifier with a "?".  Note
169 that the meanings don't change, just the "greediness":
170 X<metacharacter> X<greedy> X<greediness>
171 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
172
173     *?     Match 0 or more times, not greedily
174     +?     Match 1 or more times, not greedily
175     ??     Match 0 or 1 time, not greedily
176     {n}?   Match exactly n times, not greedily
177     {n,}?  Match at least n times, not greedily
178     {n,m}? Match at least n but not more than m times, not greedily
179
180 By default, when a quantified subpattern does not allow the rest of the
181 overall pattern to match, Perl will backtrack. However, this behaviour is
182 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
183 as well.
184
185     *+     Match 0 or more times and give nothing back
186     ++     Match 1 or more times and give nothing back
187     ?+     Match 0 or 1 time and give nothing back
188     {n}+   Match exactly n times and give nothing back (redundant)
189     {n,}+  Match at least n times and give nothing back
190     {n,m}+ Match at least n but not more than m times and give nothing back
191
192 For instance,
193
194    'aaaa' =~ /a++a/
195
196 will never match, as the C<a++> will gobble up all the C<a>'s in the
197 string and won't leave any for the remaining part of the pattern. This
198 feature can be extremely useful to give perl hints about where it
199 shouldn't backtrack. For instance, the typical "match a double-quoted
200 string" problem can be most efficiently performed when written as:
201
202    /"(?:[^"\\]++|\\.)*+"/
203
204 as we know that if the final quote does not match, backtracking will not
205 help. See the independent subexpression C<< (?>...) >> for more details;
206 possessive quantifiers are just syntactic sugar for that construct. For
207 instance the above example could also be written as follows:
208
209    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
210
211 =head3 Escape sequences
212
213 Because patterns are processed as double quoted strings, the following
214 also work:
215 X<\t> X<\n> X<\r> X<\f> X<\e> X<\a> X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q>
216 X<\0> X<\c> X<\N> X<\x>
217
218     \t          tab                   (HT, TAB)
219     \n          newline               (LF, NL)
220     \r          return                (CR)
221     \f          form feed             (FF)
222     \a          alarm (bell)          (BEL)
223     \e          escape (think troff)  (ESC)
224     \033        octal char            (example: ESC)
225     \x1B        hex char              (example: ESC)
226     \x{263a}    wide hex char         (example: Unicode SMILEY)
227     \cK         control char          (example: VT)
228     \N{name}    named char
229     \l          lowercase next char (think vi)
230     \u          uppercase next char (think vi)
231     \L          lowercase till \E (think vi)
232     \U          uppercase till \E (think vi)
233     \E          end case modification (think vi)
234     \Q          quote (disable) pattern metacharacters till \E
235
236 If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
237 and C<\U> is taken from the current locale.  See L<perllocale>.  For
238 documentation of C<\N{name}>, see L<charnames>.
239
240 You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
241 An unescaped C<$> or C<@> interpolates the corresponding variable,
242 while escaping will cause the literal string C<\$> to be matched.
243 You'll need to write something like C<m/\Quser\E\@\Qhost/>.
244
245 =head3 Character Classes and other Special Escapes
246
247 In addition, Perl defines the following:
248 X<\w> X<\W> X<\s> X<\S> X<\d> X<\D> X<\X> X<\p> X<\P> X<\C>
249 X<\g> X<\k> X<\N> X<\K> X<\v> X<\V> X<\h> X<\H>
250 X<word> X<whitespace> X<character class> X<backreference>
251
252     \w       Match a "word" character (alphanumeric plus "_")
253     \W       Match a non-"word" character
254     \s       Match a whitespace character
255     \S       Match a non-whitespace character
256     \d       Match a digit character
257     \D       Match a non-digit character
258     \pP      Match P, named property.  Use \p{Prop} for longer names.
259     \PP      Match non-P
260     \X       Match eXtended Unicode "combining character sequence",
261              equivalent to (?:\PM\pM*)
262     \C       Match a single C char (octet) even under Unicode.
263              NOTE: breaks up characters into their UTF-8 bytes,
264              so you may end up with malformed pieces of UTF-8.
265              Unsupported in lookbehind.
266     \1       Backreference to a specific group.
267              '1' may actually be any positive integer.
268     \g1      Backreference to a specific or previous group,
269     \g{-1}   number may be negative indicating a previous buffer and may
270              optionally be wrapped in curly brackets for safer parsing.
271     \g{name} Named backreference
272     \k<name> Named backreference
273     \N{name} Named Unicode character, or Unicode escape
274     \x12     Hexadecimal escape sequence
275     \x{1234} Long hexadecimal escape sequence
276     \K       Keep the stuff left of the \K, don't include it in $&
277     \v       Vertical whitespace
278     \V       Not vertical whitespace
279     \h       Horizontal whitespace
280     \H       Not horizontal whitespace
281     \R       Linebreak
282
283 A C<\w> matches a single alphanumeric character (an alphabetic
284 character, or a decimal digit) or C<_>, not a whole word.  Use C<\w+>
285 to match a string of Perl-identifier characters (which isn't the same
286 as matching an English word).  If C<use locale> is in effect, the list
287 of alphabetic characters generated by C<\w> is taken from the current
288 locale.  See L<perllocale>.  You may use C<\w>, C<\W>, C<\s>, C<\S>,
289 C<\d>, and C<\D> within character classes, but they aren't usable
290 as either end of a range. If any of them precedes or follows a "-",
291 the "-" is understood literally. If Unicode is in effect, C<\s> matches
292 also "\x{85}", "\x{2028}", and "\x{2029}". See L<perlunicode> for more
293 details about C<\pP>, C<\PP>, C<\X> and the possibility of defining
294 your own C<\p> and C<\P> properties, and L<perluniintro> about Unicode
295 in general.
296 X<\w> X<\W> X<word>
297
298 C<\R> will atomically match a linebreak, including the network line-ending
299 "\x0D\x0A".  Specifically, X<\R> is exactly equivalent to
300
301   (?>\x0D\x0A?|[\x0A-\x0C\x85\x{2028}\x{2029}])
302
303 B<Note:> C<\R> has no special meaning inside of a character class;
304 use C<\v> instead (vertical whitespace).
305 X<\R>
306
307 The POSIX character class syntax
308 X<character class>
309
310     [:class:]
311
312 is also available.  Note that the C<[> and C<]> brackets are I<literal>;
313 they must always be used within a character class expression.
314
315     # this is correct:
316     $string =~ /[[:alpha:]]/;
317
318     # this is not, and will generate a warning:
319     $string =~ /[:alpha:]/;
320
321 The available classes and their backslash equivalents (if available) are
322 as follows:
323 X<character class>
324 X<alpha> X<alnum> X<ascii> X<blank> X<cntrl> X<digit> X<graph>
325 X<lower> X<print> X<punct> X<space> X<upper> X<word> X<xdigit>
326
327     alpha
328     alnum
329     ascii
330     blank               [1]
331     cntrl
332     digit       \d
333     graph
334     lower
335     print
336     punct
337     space       \s      [2]
338     upper
339     word        \w      [3]
340     xdigit
341
342 =over
343
344 =item [1]
345
346 A GNU extension equivalent to C<[ \t]>, "all horizontal whitespace".
347
348 =item [2]
349
350 Not exactly equivalent to C<\s> since the C<[[:space:]]> includes
351 also the (very rare) "vertical tabulator", "\cK" or chr(11) in ASCII.
352
353 =item [3]
354
355 A Perl extension, see above.
356
357 =back
358
359 For example use C<[:upper:]> to match all the uppercase characters.
360 Note that the C<[]> are part of the C<[::]> construct, not part of the
361 whole character class.  For example:
362
363     [01[:alpha:]%]
364
365 matches zero, one, any alphabetic character, and the percent sign.
366
367 The following equivalences to Unicode \p{} constructs and equivalent
368 backslash character classes (if available), will hold:
369 X<character class> X<\p> X<\p{}>
370
371     [[:...:]]   \p{...}         backslash
372
373     alpha       IsAlpha
374     alnum       IsAlnum
375     ascii       IsASCII
376     blank
377     cntrl       IsCntrl
378     digit       IsDigit        \d
379     graph       IsGraph
380     lower       IsLower
381     print       IsPrint
382     punct       IsPunct
383     space       IsSpace
384                 IsSpacePerl    \s
385     upper       IsUpper
386     word        IsWord
387     xdigit      IsXDigit
388
389 For example C<[[:lower:]]> and C<\p{IsLower}> are equivalent.
390
391 If the C<utf8> pragma is not used but the C<locale> pragma is, the
392 classes correlate with the usual isalpha(3) interface (except for
393 "word" and "blank").
394
395 The assumedly non-obviously named classes are:
396
397 =over 4
398
399 =item cntrl
400 X<cntrl>
401
402 Any control character.  Usually characters that don't produce output as
403 such but instead control the terminal somehow: for example newline and
404 backspace are control characters.  All characters with ord() less than
405 32 are usually classified as control characters (assuming ASCII,
406 the ISO Latin character sets, and Unicode), as is the character with
407 the ord() value of 127 (C<DEL>).
408
409 =item graph
410 X<graph>
411
412 Any alphanumeric or punctuation (special) character.
413
414 =item print
415 X<print>
416
417 Any alphanumeric or punctuation (special) character or the space character.
418
419 =item punct
420 X<punct>
421
422 Any punctuation (special) character.
423
424 =item xdigit
425 X<xdigit>
426
427 Any hexadecimal digit.  Though this may feel silly ([0-9A-Fa-f] would
428 work just fine) it is included for completeness.
429
430 =back
431
432 You can negate the [::] character classes by prefixing the class name
433 with a '^'. This is a Perl extension.  For example:
434 X<character class, negation>
435
436     POSIX         traditional  Unicode
437
438     [[:^digit:]]    \D         \P{IsDigit}
439     [[:^space:]]    \S         \P{IsSpace}
440     [[:^word:]]     \W         \P{IsWord}
441
442 Perl respects the POSIX standard in that POSIX character classes are
443 only supported within a character class.  The POSIX character classes
444 [.cc.] and [=cc=] are recognized but B<not> supported and trying to
445 use them will cause an error.
446
447 =head3 Assertions
448
449 Perl defines the following zero-width assertions:
450 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
451 X<regexp, zero-width assertion>
452 X<regular expression, zero-width assertion>
453 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
454
455     \b  Match a word boundary
456     \B  Match except at a word boundary
457     \A  Match only at beginning of string
458     \Z  Match only at end of string, or before newline at the end
459     \z  Match only at end of string
460     \G  Match only at pos() (e.g. at the end-of-match position
461         of prior m//g)
462
463 A word boundary (C<\b>) is a spot between two characters
464 that has a C<\w> on one side of it and a C<\W> on the other side
465 of it (in either order), counting the imaginary characters off the
466 beginning and end of the string as matching a C<\W>.  (Within
467 character classes C<\b> represents backspace rather than a word
468 boundary, just as it normally does in any double-quoted string.)
469 The C<\A> and C<\Z> are just like "^" and "$", except that they
470 won't match multiple times when the C</m> modifier is used, while
471 "^" and "$" will match at every internal line boundary.  To match
472 the actual end of the string and not ignore an optional trailing
473 newline, use C<\z>.
474 X<\b> X<\A> X<\Z> X<\z> X</m>
475
476 The C<\G> assertion can be used to chain global matches (using
477 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
478 It is also useful when writing C<lex>-like scanners, when you have
479 several patterns that you want to match against consequent substrings
480 of your string, see the previous reference.  The actual location
481 where C<\G> will match can also be influenced by using C<pos()> as
482 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
483 matches is modified somewhat, in that contents to the left of C<\G> is
484 not counted when determining the length of the match. Thus the following
485 will not match forever:
486 X<\G>
487
488     $str = 'ABC';
489     pos($str) = 1;
490     while (/.\G/g) {
491         print $&;
492     }
493
494 It will print 'A' and then terminate, as it considers the match to
495 be zero-width, and thus will not match at the same position twice in a
496 row.
497
498 It is worth noting that C<\G> improperly used can result in an infinite
499 loop. Take care when using patterns that include C<\G> in an alternation.
500
501 =head3 Capture buffers
502
503 The bracketing construct C<( ... )> creates capture buffers. To refer
504 to the current contents of a buffer later on, within the same pattern,
505 use \1 for the first, \2 for the second, and so on.
506 Outside the match use "$" instead of "\".  (The
507 \<digit> notation works in certain circumstances outside
508 the match.  See the warning below about \1 vs $1 for details.)
509 Referring back to another part of the match is called a
510 I<backreference>.
511 X<regex, capture buffer> X<regexp, capture buffer>
512 X<regular expression, capture buffer> X<backreference>
513
514 There is no limit to the number of captured substrings that you may
515 use.  However Perl also uses \10, \11, etc. as aliases for \010,
516 \011, etc.  (Recall that 0 means octal, so \011 is the character at
517 number 9 in your coded character set; which would be the 10th character,
518 a horizontal tab under ASCII.)  Perl resolves this
519 ambiguity by interpreting \10 as a backreference only if at least 10
520 left parentheses have opened before it.  Likewise \11 is a
521 backreference only if at least 11 left parentheses have opened
522 before it.  And so on.  \1 through \9 are always interpreted as
523 backreferences.
524
525 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
526 In order to provide a safer and easier way to construct patterns using
527 backreferences, Perl 5.10 provides the C<\g{N}> notation. The curly
528 brackets are optional, however omitting them is less safe as the meaning
529 of the pattern can be changed by text (such as digits) following it.
530 When N is a positive integer the C<\g{N}> notation is exactly equivalent
531 to using normal backreferences. When N is a negative integer then it is
532 a relative backreference referring to the previous N'th capturing group.
533 When the bracket form is used and N is not an integer, it is treated as a
534 reference to a named buffer.
535
536 Thus C<\g{-1}> refers to the last buffer, C<\g{-2}> refers to the
537 buffer before that. For example:
538
539         /
540          (Y)            # buffer 1
541          (              # buffer 2
542             (X)         # buffer 3
543             \g{-1}      # backref to buffer 3
544             \g{-3}      # backref to buffer 1
545          )
546         /x
547
548 and would match the same as C</(Y) ( (X) \3 \1 )/x>.
549
550 Additionally, as of Perl 5.10 you may use named capture buffers and named
551 backreferences. The notation is C<< (?<name>...) >> to declare and C<< \k<name> >>
552 to reference. You may also use apostrophes instead of angle brackets to delimit the
553 name; and you may use the bracketed C<< \g{name} >> backreference syntax.
554 It's possible to refer to a named capture buffer by absolute and relative number as well.
555 Outside the pattern, a named capture buffer is available via the C<%+> hash.
556 When different buffers within the same pattern have the same name, C<$+{name}>
557 and C<< \k<name> >> refer to the leftmost defined group. (Thus it's possible
558 to do things with named capture buffers that would otherwise require C<(??{})>
559 code to accomplish.)
560 X<named capture buffer> X<regular expression, named capture buffer>
561 X<%+> X<$+{name}> X<\k{name}>
562
563 Examples:
564
565     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
566
567     /(.)\1/                         # find first doubled char
568          and print "'$1' is the first doubled character\n";
569
570     /(?<char>.)\k<char>/            # ... a different way
571          and print "'$+{char}' is the first doubled character\n";
572
573     /(?'char'.)\1/                  # ... mix and match
574          and print "'$1' is the first doubled character\n";
575
576     if (/Time: (..):(..):(..)/) {   # parse out values
577         $hours = $1;
578         $minutes = $2;
579         $seconds = $3;
580     }
581
582 Several special variables also refer back to portions of the previous
583 match.  C<$+> returns whatever the last bracket match matched.
584 C<$&> returns the entire matched string.  (At one point C<$0> did
585 also, but now it returns the name of the program.)  C<$`> returns
586 everything before the matched string.  C<$'> returns everything
587 after the matched string. And C<$^N> contains whatever was matched by
588 the most-recently closed group (submatch). C<$^N> can be used in
589 extended patterns (see below), for example to assign a submatch to a
590 variable.
591 X<$+> X<$^N> X<$&> X<$`> X<$'>
592
593 The numbered match variables ($1, $2, $3, etc.) and the related punctuation
594 set (C<$+>, C<$&>, C<$`>, C<$'>, and C<$^N>) are all dynamically scoped
595 until the end of the enclosing block or until the next successful
596 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
597 X<$+> X<$^N> X<$&> X<$`> X<$'>
598 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
599
600
601 B<NOTE>: Failed matches in Perl do not reset the match variables,
602 which makes it easier to write code that tests for a series of more
603 specific cases and remembers the best match.
604
605 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
606 C<$'> anywhere in the program, it has to provide them for every
607 pattern match.  This may substantially slow your program.  Perl
608 uses the same mechanism to produce $1, $2, etc, so you also pay a
609 price for each pattern that contains capturing parentheses.  (To
610 avoid this cost while retaining the grouping behaviour, use the
611 extended regular expression C<(?: ... )> instead.)  But if you never
612 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
613 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
614 if you can, but if you can't (and some algorithms really appreciate
615 them), once you've used them once, use them at will, because you've
616 already paid the price.  As of 5.005, C<$&> is not so costly as the
617 other two.
618 X<$&> X<$`> X<$'>
619
620 As a workaround for this problem, Perl 5.10 introduces C<${^PREMATCH}>,
621 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
622 and C<$'>, B<except> that they are only guaranteed to be defined after a
623 successful match that was executed with the C</p> (preserve) modifier.
624 The use of these variables incurs no global performance penalty, unlike
625 their punctuation char equivalents, however at the trade-off that you
626 have to tell perl when you want to use them.
627 X</p> X<p modifier>
628
629 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
630 C<\w>, C<\n>.  Unlike some other regular expression languages, there
631 are no backslashed symbols that aren't alphanumeric.  So anything
632 that looks like \\, \(, \), \<, \>, \{, or \} is always
633 interpreted as a literal character, not a metacharacter.  This was
634 once used in a common idiom to disable or quote the special meanings
635 of regular expression metacharacters in a string that you want to
636 use for a pattern. Simply quote all non-"word" characters:
637
638     $pattern =~ s/(\W)/\\$1/g;
639
640 (If C<use locale> is set, then this depends on the current locale.)
641 Today it is more common to use the quotemeta() function or the C<\Q>
642 metaquoting escape sequence to disable all metacharacters' special
643 meanings like this:
644
645     /$unquoted\Q$quoted\E$unquoted/
646
647 Beware that if you put literal backslashes (those not inside
648 interpolated variables) between C<\Q> and C<\E>, double-quotish
649 backslash interpolation may lead to confusing results.  If you
650 I<need> to use literal backslashes within C<\Q...\E>,
651 consult L<perlop/"Gory details of parsing quoted constructs">.
652
653 =head2 Extended Patterns
654
655 Perl also defines a consistent extension syntax for features not
656 found in standard tools like B<awk> and B<lex>.  The syntax is a
657 pair of parentheses with a question mark as the first thing within
658 the parentheses.  The character after the question mark indicates
659 the extension.
660
661 The stability of these extensions varies widely.  Some have been
662 part of the core language for many years.  Others are experimental
663 and may change without warning or be completely removed.  Check
664 the documentation on an individual feature to verify its current
665 status.
666
667 A question mark was chosen for this and for the minimal-matching
668 construct because 1) question marks are rare in older regular
669 expressions, and 2) whenever you see one, you should stop and
670 "question" exactly what is going on.  That's psychology...
671
672 =over 10
673
674 =item C<(?#text)>
675 X<(?#)>
676
677 A comment.  The text is ignored.  If the C</x> modifier enables
678 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
679 the comment as soon as it sees a C<)>, so there is no way to put a literal
680 C<)> in the comment.
681
682 =item C<(?pimsx-imsx)>
683 X<(?)>
684
685 One or more embedded pattern-match modifiers, to be turned on (or
686 turned off, if preceded by C<->) for the remainder of the pattern or
687 the remainder of the enclosing pattern group (if any). This is
688 particularly useful for dynamic patterns, such as those read in from a
689 configuration file, taken from an argument, or specified in a table
690 somewhere.  Consider the case where some patterns want to be case
691 sensitive and some do not:  The case insensitive ones merely need to
692 include C<(?i)> at the front of the pattern.  For example:
693
694     $pattern = "foobar";
695     if ( /$pattern/i ) { }
696
697     # more flexible:
698
699     $pattern = "(?i)foobar";
700     if ( /$pattern/ ) { }
701
702 These modifiers are restored at the end of the enclosing group. For example,
703
704     ( (?i) blah ) \s+ \1
705
706 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
707 repetition of the previous word, assuming the C</x> modifier, and no C</i>
708 modifier outside this group.
709
710 Note that the C<p> modifier is special in that it can only be enabled,
711 not disabled, and that its presence anywhere in a pattern has a global
712 effect. Thus C<(?-p)> and C<(?-p:...)> are meaningless and will warn
713 when executed under C<use warnings>.
714
715 =item C<(?:pattern)>
716 X<(?:)>
717
718 =item C<(?imsx-imsx:pattern)>
719
720 This is for clustering, not capturing; it groups subexpressions like
721 "()", but doesn't make backreferences as "()" does.  So
722
723     @fields = split(/\b(?:a|b|c)\b/)
724
725 is like
726
727     @fields = split(/\b(a|b|c)\b/)
728
729 but doesn't spit out extra fields.  It's also cheaper not to capture
730 characters if you don't need to.
731
732 Any letters between C<?> and C<:> act as flags modifiers as with
733 C<(?imsx-imsx)>.  For example,
734
735     /(?s-i:more.*than).*million/i
736
737 is equivalent to the more verbose
738
739     /(?:(?s-i)more.*than).*million/i
740
741 =item C<(?|pattern)>
742 X<(?|)> X<Branch reset>
743
744 This is the "branch reset" pattern, which has the special property
745 that the capture buffers are numbered from the same starting point
746 in each alternation branch. It is available starting from perl 5.10.
747
748 Capture buffers are numbered from left to right, but inside this
749 construct the numbering is restarted for each branch.
750
751 The numbering within each branch will be as normal, and any buffers
752 following this construct will be numbered as though the construct
753 contained only one branch, that being the one with the most capture
754 buffers in it.
755
756 This construct will be useful when you want to capture one of a
757 number of alternative matches.
758
759 Consider the following pattern.  The numbers underneath show in
760 which buffer the captured content will be stored.
761
762
763     # before  ---------------branch-reset----------- after        
764     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
765     # 1            2         2  3        2     3     4  
766
767 =item Look-Around Assertions
768 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
769
770 Look-around assertions are zero width patterns which match a specific
771 pattern without including it in C<$&>. Positive assertions match when
772 their subpattern matches, negative assertions match when their subpattern
773 fails. Look-behind matches text up to the current match position,
774 look-ahead matches text following the current match position.
775
776 =over 4
777
778 =item C<(?=pattern)>
779 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
780
781 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
782 matches a word followed by a tab, without including the tab in C<$&>.
783
784 =item C<(?!pattern)>
785 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
786
787 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
788 matches any occurrence of "foo" that isn't followed by "bar".  Note
789 however that look-ahead and look-behind are NOT the same thing.  You cannot
790 use this for look-behind.
791
792 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
793 will not do what you want.  That's because the C<(?!foo)> is just saying that
794 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
795 match.  You would have to do something like C</(?!foo)...bar/> for that.   We
796 say "like" because there's the case of your "bar" not having three characters
797 before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
798 Sometimes it's still easier just to say:
799
800     if (/bar/ && $` !~ /foo$/)
801
802 For look-behind see below.
803
804 =item C<(?<=pattern)> C<\K>
805 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
806
807 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
808 matches a word that follows a tab, without including the tab in C<$&>.
809 Works only for fixed-width look-behind.
810
811 There is a special form of this construct, called C<\K>, which causes the
812 regex engine to "keep" everything it had matched prior to the C<\K> and
813 not include it in C<$&>. This effectively provides variable length
814 look-behind. The use of C<\K> inside of another look-around assertion
815 is allowed, but the behaviour is currently not well defined.
816
817 For various reasons C<\K> may be significantly more efficient than the
818 equivalent C<< (?<=...) >> construct, and it is especially useful in
819 situations where you want to efficiently remove something following
820 something else in a string. For instance
821
822   s/(foo)bar/$1/g;
823
824 can be rewritten as the much more efficient
825
826   s/foo\Kbar//g;
827
828 =item C<(?<!pattern)>
829 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
830
831 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
832 matches any occurrence of "foo" that does not follow "bar".  Works
833 only for fixed-width look-behind.
834
835 =back
836
837 =item C<(?'NAME'pattern)>
838
839 =item C<< (?<NAME>pattern) >>
840 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
841
842 A named capture buffer. Identical in every respect to normal capturing
843 parentheses C<()> but for the additional fact that C<%+> may be used after
844 a successful match to refer to a named buffer. See C<perlvar> for more
845 details on the C<%+> hash.
846
847 If multiple distinct capture buffers have the same name then the
848 $+{NAME} will refer to the leftmost defined buffer in the match.
849
850 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
851
852 B<NOTE:> While the notation of this construct is the same as the similar
853 function in .NET regexes, the behavior is not. In Perl the buffers are
854 numbered sequentially regardless of being named or not. Thus in the
855 pattern
856
857   /(x)(?<foo>y)(z)/
858
859 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
860 the opposite which is what a .NET regex hacker might expect.
861
862 Currently NAME is restricted to simple identifiers only.
863 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
864 its Unicode extension (see L<utf8>),
865 though it isn't extended by the locale (see L<perllocale>).
866
867 B<NOTE:> In order to make things easier for programmers with experience
868 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
869 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
870 support the use of single quotes as a delimiter for the name. This is
871 only available in Perl 5.10 or later.
872
873 =item C<< \k<NAME> >>
874
875 =item C<< \k'NAME' >>
876
877 Named backreference. Similar to numeric backreferences, except that
878 the group is designated by name and not number. If multiple groups
879 have the same name then it refers to the leftmost defined group in
880 the current match.
881
882 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
883 earlier in the pattern.
884
885 Both forms are equivalent.
886
887 B<NOTE:> In order to make things easier for programmers with experience
888 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
889 may be used instead of C<< \k<NAME> >> in Perl 5.10 or later.
890
891 =item C<(?{ code })>
892 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
893
894 B<WARNING>: This extended regular expression feature is considered
895 experimental, and may be changed without notice. Code executed that
896 has side effects may not perform identically from version to version
897 due to the effect of future optimisations in the regex engine.
898
899 This zero-width assertion evaluates any embedded Perl code.  It
900 always succeeds, and its C<code> is not interpolated.  Currently,
901 the rules to determine where the C<code> ends are somewhat convoluted.
902
903 This feature can be used together with the special variable C<$^N> to
904 capture the results of submatches in variables without having to keep
905 track of the number of nested parentheses. For example:
906
907   $_ = "The brown fox jumps over the lazy dog";
908   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
909   print "color = $color, animal = $animal\n";
910
911 Inside the C<(?{...})> block, C<$_> refers to the string the regular
912 expression is matching against. You can also use C<pos()> to know what is
913 the current position of matching within this string.
914
915 The C<code> is properly scoped in the following sense: If the assertion
916 is backtracked (compare L<"Backtracking">), all changes introduced after
917 C<local>ization are undone, so that
918
919   $_ = 'a' x 8;
920   m<
921      (?{ $cnt = 0 })                    # Initialize $cnt.
922      (
923        a
924        (?{
925            local $cnt = $cnt + 1;       # Update $cnt, backtracking-safe.
926        })
927      )*
928      aaaa
929      (?{ $res = $cnt })                 # On success copy to non-localized
930                                         # location.
931    >x;
932
933 will set C<$res = 4>.  Note that after the match, C<$cnt> returns to the globally
934 introduced value, because the scopes that restrict C<local> operators
935 are unwound.
936
937 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
938 switch.  If I<not> used in this way, the result of evaluation of
939 C<code> is put into the special variable C<$^R>.  This happens
940 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
941 inside the same regular expression.
942
943 The assignment to C<$^R> above is properly localized, so the old
944 value of C<$^R> is restored if the assertion is backtracked; compare
945 L<"Backtracking">.
946
947 Due to an unfortunate implementation issue, the Perl code contained in these
948 blocks is treated as a compile time closure that can have seemingly bizarre
949 consequences when used with lexically scoped variables inside of subroutines
950 or loops.  There are various workarounds for this, including simply using
951 global variables instead.  If you are using this construct and strange results
952 occur then check for the use of lexically scoped variables.
953
954 For reasons of security, this construct is forbidden if the regular
955 expression involves run-time interpolation of variables, unless the
956 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
957 variables contain results of C<qr//> operator (see
958 L<perlop/"qr/STRING/imosx">).
959
960 This restriction is due to the wide-spread and remarkably convenient
961 custom of using run-time determined strings as patterns.  For example:
962
963     $re = <>;
964     chomp $re;
965     $string =~ /$re/;
966
967 Before Perl knew how to execute interpolated code within a pattern,
968 this operation was completely safe from a security point of view,
969 although it could raise an exception from an illegal pattern.  If
970 you turn on the C<use re 'eval'>, though, it is no longer secure,
971 so you should only do so if you are also using taint checking.
972 Better yet, use the carefully constrained evaluation within a Safe
973 compartment.  See L<perlsec> for details about both these mechanisms.
974
975 Because Perl's regex engine is currently not re-entrant, interpolated
976 code may not invoke the regex engine either directly with C<m//> or C<s///>),
977 or indirectly with functions such as C<split>.
978
979 =item C<(??{ code })>
980 X<(??{})>
981 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
982
983 B<WARNING>: This extended regular expression feature is considered
984 experimental, and may be changed without notice. Code executed that
985 has side effects may not perform identically from version to version
986 due to the effect of future optimisations in the regex engine.
987
988 This is a "postponed" regular subexpression.  The C<code> is evaluated
989 at run time, at the moment this subexpression may match.  The result
990 of evaluation is considered as a regular expression and matched as
991 if it were inserted instead of this construct.  Note that this means
992 that the contents of capture buffers defined inside an eval'ed pattern
993 are not available outside of the pattern, and vice versa, there is no
994 way for the inner pattern to refer to a capture buffer defined outside.
995 Thus,
996
997     ('a' x 100)=~/(??{'(.)' x 100})/
998
999 B<will> match, it will B<not> set $1.
1000
1001 The C<code> is not interpolated.  As before, the rules to determine
1002 where the C<code> ends are currently somewhat convoluted.
1003
1004 The following pattern matches a parenthesized group:
1005
1006   $re = qr{
1007              \(
1008              (?:
1009                 (?> [^()]+ )    # Non-parens without backtracking
1010               |
1011                 (??{ $re })     # Group with matching parens
1012              )*
1013              \)
1014           }x;
1015
1016 See also C<(?PARNO)> for a different, more efficient way to accomplish
1017 the same task.
1018
1019 Because perl's regex engine is not currently re-entrant, delayed
1020 code may not invoke the regex engine either directly with C<m//> or C<s///>),
1021 or indirectly with functions such as C<split>.
1022
1023 Recursing deeper than 50 times without consuming any input string will
1024 result in a fatal error.  The maximum depth is compiled into perl, so
1025 changing it requires a custom build.
1026
1027 =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
1028 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1029 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1030 X<regex, relative recursion>
1031
1032 Similar to C<(??{ code })> except it does not involve compiling any code,
1033 instead it treats the contents of a capture buffer as an independent
1034 pattern that must match at the current position.  Capture buffers
1035 contained by the pattern will have the value as determined by the
1036 outermost recursion.
1037
1038 PARNO is a sequence of digits (not starting with 0) whose value reflects
1039 the paren-number of the capture buffer to recurse to. C<(?R)> recurses to
1040 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1041 C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
1042 to be relative, with negative numbers indicating preceding capture buffers
1043 and positive ones following. Thus C<(?-1)> refers to the most recently
1044 declared buffer, and C<(?+1)> indicates the next buffer to be declared.
1045 Note that the counting for relative recursion differs from that of
1046 relative backreferences, in that with recursion unclosed buffers B<are>
1047 included.
1048
1049 The following pattern matches a function foo() which may contain
1050 balanced parentheses as the argument.
1051
1052   $re = qr{ (                    # paren group 1 (full function)
1053               foo
1054               (                  # paren group 2 (parens)
1055                 \(
1056                   (              # paren group 3 (contents of parens)
1057                   (?:
1058                    (?> [^()]+ )  # Non-parens without backtracking
1059                   |
1060                    (?2)          # Recurse to start of paren group 2
1061                   )*
1062                   )
1063                 \)
1064               )
1065             )
1066           }x;
1067
1068 If the pattern was used as follows
1069
1070     'foo(bar(baz)+baz(bop))'=~/$re/
1071         and print "\$1 = $1\n",
1072                   "\$2 = $2\n",
1073                   "\$3 = $3\n";
1074
1075 the output produced should be the following:
1076
1077     $1 = foo(bar(baz)+baz(bop))
1078     $2 = (bar(baz)+baz(bop))
1079     $3 = bar(baz)+baz(bop)
1080
1081 If there is no corresponding capture buffer defined, then it is a
1082 fatal error.  Recursing deeper than 50 times without consuming any input
1083 string will also result in a fatal error.  The maximum depth is compiled
1084 into perl, so changing it requires a custom build.
1085
1086 The following shows how using negative indexing can make it
1087 easier to embed recursive patterns inside of a C<qr//> construct
1088 for later use:
1089
1090     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1091     if (/foo $parens \s+ + \s+ bar $parens/x) {
1092        # do something here...
1093     }
1094
1095 B<Note> that this pattern does not behave the same way as the equivalent
1096 PCRE or Python construct of the same form. In Perl you can backtrack into
1097 a recursed group, in PCRE and Python the recursed into group is treated
1098 as atomic. Also, modifiers are resolved at compile time, so constructs
1099 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1100 be processed.
1101
1102 =item C<(?&NAME)>
1103 X<(?&NAME)>
1104
1105 Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1106 parenthesis to recurse to is determined by name. If multiple parentheses have
1107 the same name, then it recurses to the leftmost.
1108
1109 It is an error to refer to a name that is not declared somewhere in the
1110 pattern.
1111
1112 B<NOTE:> In order to make things easier for programmers with experience
1113 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1114 may be used instead of C<< (?&NAME) >> in Perl 5.10 or later.
1115
1116 =item C<(?(condition)yes-pattern|no-pattern)>
1117 X<(?()>
1118
1119 =item C<(?(condition)yes-pattern)>
1120
1121 Conditional expression.  C<(condition)> should be either an integer in
1122 parentheses (which is valid if the corresponding pair of parentheses
1123 matched), a look-ahead/look-behind/evaluate zero-width assertion, a
1124 name in angle brackets or single quotes (which is valid if a buffer
1125 with the given name matched), or the special symbol (R) (true when
1126 evaluated inside of recursion or eval). Additionally the R may be
1127 followed by a number, (which will be true when evaluated when recursing
1128 inside of the appropriate group), or by C<&NAME>, in which case it will
1129 be true only when evaluated during recursion in the named group.
1130
1131 Here's a summary of the possible predicates:
1132
1133 =over 4
1134
1135 =item (1) (2) ...
1136
1137 Checks if the numbered capturing buffer has matched something.
1138
1139 =item (<NAME>) ('NAME')
1140
1141 Checks if a buffer with the given name has matched something.
1142
1143 =item (?{ CODE })
1144
1145 Treats the code block as the condition.
1146
1147 =item (R)
1148
1149 Checks if the expression has been evaluated inside of recursion.
1150
1151 =item (R1) (R2) ...
1152
1153 Checks if the expression has been evaluated while executing directly
1154 inside of the n-th capture group. This check is the regex equivalent of
1155
1156   if ((caller(0))[3] eq 'subname') { ... }
1157
1158 In other words, it does not check the full recursion stack.
1159
1160 =item (R&NAME)
1161
1162 Similar to C<(R1)>, this predicate checks to see if we're executing
1163 directly inside of the leftmost group with a given name (this is the same
1164 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1165 stack, but only the name of the innermost active recursion.
1166
1167 =item (DEFINE)
1168
1169 In this case, the yes-pattern is never directly executed, and no
1170 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1171 See below for details.
1172
1173 =back
1174
1175 For example:
1176
1177     m{ ( \( )?
1178        [^()]+
1179        (?(1) \) )
1180      }x
1181
1182 matches a chunk of non-parentheses, possibly included in parentheses
1183 themselves.
1184
1185 A special form is the C<(DEFINE)> predicate, which never executes directly
1186 its yes-pattern, and does not allow a no-pattern. This allows to define
1187 subpatterns which will be executed only by using the recursion mechanism.
1188 This way, you can define a set of regular expression rules that can be
1189 bundled into any pattern you choose.
1190
1191 It is recommended that for this usage you put the DEFINE block at the
1192 end of the pattern, and that you name any subpatterns defined within it.
1193
1194 Also, it's worth noting that patterns defined this way probably will
1195 not be as efficient, as the optimiser is not very clever about
1196 handling them.
1197
1198 An example of how this might be used is as follows:
1199
1200   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1201    (?(DEFINE)
1202      (?<NAME_PAT>....)
1203      (?<ADRESS_PAT>....)
1204    )/x
1205
1206 Note that capture buffers matched inside of recursion are not accessible
1207 after the recursion returns, so the extra layer of capturing buffers is
1208 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1209 C<$+{NAME}> would be.
1210
1211 =item C<< (?>pattern) >>
1212 X<backtrack> X<backtracking> X<atomic> X<possessive>
1213
1214 An "independent" subexpression, one which matches the substring
1215 that a I<standalone> C<pattern> would match if anchored at the given
1216 position, and it matches I<nothing other than this substring>.  This
1217 construct is useful for optimizations of what would otherwise be
1218 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1219 It may also be useful in places where the "grab all you can, and do not
1220 give anything back" semantic is desirable.
1221
1222 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1223 (anchored at the beginning of string, as above) will match I<all>
1224 characters C<a> at the beginning of string, leaving no C<a> for
1225 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1226 since the match of the subgroup C<a*> is influenced by the following
1227 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1228 C<a*ab> will match fewer characters than a standalone C<a*>, since
1229 this makes the tail match.
1230
1231 An effect similar to C<< (?>pattern) >> may be achieved by writing
1232 C<(?=(pattern))\1>.  This matches the same substring as a standalone
1233 C<a+>, and the following C<\1> eats the matched string; it therefore
1234 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1235 (The difference between these two constructs is that the second one
1236 uses a capturing group, thus shifting ordinals of backreferences
1237 in the rest of a regular expression.)
1238
1239 Consider this pattern:
1240
1241     m{ \(
1242           (
1243             [^()]+              # x+
1244           |
1245             \( [^()]* \)
1246           )+
1247        \)
1248      }x
1249
1250 That will efficiently match a nonempty group with matching parentheses
1251 two levels deep or less.  However, if there is no such group, it
1252 will take virtually forever on a long string.  That's because there
1253 are so many different ways to split a long string into several
1254 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1255 to a subpattern of the above pattern.  Consider how the pattern
1256 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1257 seconds, but that each extra letter doubles this time.  This
1258 exponential performance will make it appear that your program has
1259 hung.  However, a tiny change to this pattern
1260
1261     m{ \(
1262           (
1263             (?> [^()]+ )        # change x+ above to (?> x+ )
1264           |
1265             \( [^()]* \)
1266           )+
1267        \)
1268      }x
1269
1270 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1271 this yourself would be a productive exercise), but finishes in a fourth
1272 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1273 however, that this pattern currently triggers a warning message under
1274 the C<use warnings> pragma or B<-w> switch saying it
1275 C<"matches null string many times in regex">.
1276
1277 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1278 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1279 This was only 4 times slower on a string with 1000000 C<a>s.
1280
1281 The "grab all you can, and do not give anything back" semantic is desirable
1282 in many situations where on the first sight a simple C<()*> looks like
1283 the correct solution.  Suppose we parse text with comments being delimited
1284 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1285 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1286 the comment delimiter, because it may "give up" some whitespace if
1287 the remainder of the pattern can be made to match that way.  The correct
1288 answer is either one of these:
1289
1290     (?>#[ \t]*)
1291     #[ \t]*(?![ \t])
1292
1293 For example, to grab non-empty comments into $1, one should use either
1294 one of these:
1295
1296     / (?> \# [ \t]* ) (        .+ ) /x;
1297     /     \# [ \t]*   ( [^ \t] .* ) /x;
1298
1299 Which one you pick depends on which of these expressions better reflects
1300 the above specification of comments.
1301
1302 In some literature this construct is called "atomic matching" or
1303 "possessive matching".
1304
1305 Possessive quantifiers are equivalent to putting the item they are applied
1306 to inside of one of these constructs. The following equivalences apply:
1307
1308     Quantifier Form     Bracketing Form
1309     ---------------     ---------------
1310     PAT*+               (?>PAT*)
1311     PAT++               (?>PAT+)
1312     PAT?+               (?>PAT?)
1313     PAT{min,max}+       (?>PAT{min,max})
1314
1315 =back
1316
1317 =head2 Special Backtracking Control Verbs
1318
1319 B<WARNING:> These patterns are experimental and subject to change or
1320 removal in a future version of Perl. Their usage in production code should
1321 be noted to avoid problems during upgrades.
1322
1323 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1324 otherwise stated the ARG argument is optional; in some cases, it is
1325 forbidden.
1326
1327 Any pattern containing a special backtracking verb that allows an argument
1328 has the special behaviour that when executed it sets the current packages'
1329 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1330 rules apply:
1331
1332 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1333 verb pattern, if the verb was involved in the failure of the match. If the
1334 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1335 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1336 none. Also, the C<$REGMARK> variable will be set to FALSE.
1337
1338 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1339 the C<$REGMARK> variable will be set to the name of the last
1340 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1341 C<(*MARK:NAME)> verb below for more details.
1342
1343 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1344 and most other regex related variables. They are not local to a scope, nor
1345 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1346 Use C<local> to localize changes to them to a specific scope if necessary.
1347
1348 If a pattern does not contain a special backtracking verb that allows an
1349 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1350
1351 =over 4
1352
1353 =item Verbs that take an argument
1354
1355 =over 4
1356
1357 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1358 X<(*PRUNE)> X<(*PRUNE:NAME)>
1359
1360 This zero-width pattern prunes the backtracking tree at the current point
1361 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1362 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1363 A may backtrack as necessary to match. Once it is reached, matching
1364 continues in B, which may also backtrack as necessary; however, should B
1365 not match, then no further backtracking will take place, and the pattern
1366 will fail outright at the current starting position.
1367
1368 The following example counts all the possible matching strings in a
1369 pattern (without actually matching any of them).
1370
1371     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1372     print "Count=$count\n";
1373
1374 which produces:
1375
1376     aaab
1377     aaa
1378     aa
1379     a
1380     aab
1381     aa
1382     a
1383     ab
1384     a
1385     Count=9
1386
1387 If we add a C<(*PRUNE)> before the count like the following
1388
1389     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1390     print "Count=$count\n";
1391
1392 we prevent backtracking and find the count of the longest matching
1393 at each matching startpoint like so:
1394
1395     aaab
1396     aab
1397     ab
1398     Count=3
1399
1400 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1401
1402 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1403 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1404 replaced with a C<< (?>pattern) >> with no functional difference; however,
1405 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1406 C<< (?>pattern) >> alone.
1407
1408
1409 =item C<(*SKIP)> C<(*SKIP:NAME)>
1410 X<(*SKIP)>
1411
1412 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1413 failure it also signifies that whatever text that was matched leading up
1414 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1415 of this pattern. This effectively means that the regex engine "skips" forward
1416 to this position on failure and tries to match again, (assuming that
1417 there is sufficient room to match).
1418
1419 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1420 C<(*MARK:NAME)> was encountered while matching, then it is that position
1421 which is used as the "skip point". If no C<(*MARK)> of that name was
1422 encountered, then the C<(*SKIP)> operator has no effect. When used
1423 without a name the "skip point" is where the match point was when
1424 executing the (*SKIP) pattern.
1425
1426 Compare the following to the examples in C<(*PRUNE)>, note the string
1427 is twice as long:
1428
1429     'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1430     print "Count=$count\n";
1431
1432 outputs
1433
1434     aaab
1435     aaab
1436     Count=2
1437
1438 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1439 executed, the next startpoint will be where the cursor was when the
1440 C<(*SKIP)> was executed.
1441
1442 =item C<(*MARK:NAME)> C<(*:NAME)>
1443 X<(*MARK)> C<(*MARK:NAME)> C<(*:NAME)>
1444
1445 This zero-width pattern can be used to mark the point reached in a string
1446 when a certain part of the pattern has been successfully matched. This
1447 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1448 forward to that point if backtracked into on failure. Any number of
1449 C<(*MARK)> patterns are allowed, and the NAME portion is optional and may
1450 be duplicated.
1451
1452 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1453 can be used to "label" a pattern branch, so that after matching, the
1454 program can determine which branches of the pattern were involved in the
1455 match.
1456
1457 When a match is successful, the C<$REGMARK> variable will be set to the
1458 name of the most recently executed C<(*MARK:NAME)> that was involved
1459 in the match.
1460
1461 This can be used to determine which branch of a pattern was matched
1462 without using a separate capture buffer for each branch, which in turn
1463 can result in a performance improvement, as perl cannot optimize
1464 C</(?:(x)|(y)|(z))/> as efficiently as something like
1465 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1466
1467 When a match has failed, and unless another verb has been involved in
1468 failing the match and has provided its own name to use, the C<$REGERROR>
1469 variable will be set to the name of the most recently executed
1470 C<(*MARK:NAME)>.
1471
1472 See C<(*SKIP)> for more details.
1473
1474 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1475
1476 =item C<(*THEN)> C<(*THEN:NAME)>
1477
1478 This is similar to the "cut group" operator C<::> from Perl6. Like
1479 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1480 failure, it causes the regex engine to try the next alternation in the
1481 innermost enclosing group (capturing or otherwise).
1482
1483 Its name comes from the observation that this operation combined with the
1484 alternation operator (C<|>) can be used to create what is essentially a
1485 pattern-based if/then/else block:
1486
1487   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1488
1489 Note that if this operator is used and NOT inside of an alternation then
1490 it acts exactly like the C<(*PRUNE)> operator.
1491
1492   / A (*PRUNE) B /
1493
1494 is the same as
1495
1496   / A (*THEN) B /
1497
1498 but
1499
1500   / ( A (*THEN) B | C (*THEN) D ) /
1501
1502 is not the same as
1503
1504   / ( A (*PRUNE) B | C (*PRUNE) D ) /
1505
1506 as after matching the A but failing on the B the C<(*THEN)> verb will
1507 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1508
1509 =item C<(*COMMIT)>
1510 X<(*COMMIT)>
1511
1512 This is the Perl6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1513 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1514 into on failure it causes the match to fail outright. No further attempts
1515 to find a valid match by advancing the start pointer will occur again.
1516 For example,
1517
1518     'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1519     print "Count=$count\n";
1520
1521 outputs
1522
1523     aaab
1524     Count=1
1525
1526 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1527 does not match, the regex engine will not try any further matching on the
1528 rest of the string.
1529
1530 =back
1531
1532 =item Verbs without an argument
1533
1534 =over 4
1535
1536 =item C<(*FAIL)> C<(*F)>
1537 X<(*FAIL)> X<(*F)>
1538
1539 This pattern matches nothing and always fails. It can be used to force the
1540 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1541 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1542
1543 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1544
1545 =item C<(*ACCEPT)>
1546 X<(*ACCEPT)>
1547
1548 B<WARNING:> This feature is highly experimental. It is not recommended
1549 for production code.
1550
1551 This pattern matches nothing and causes the end of successful matching at
1552 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1553 whether there is actually more to match in the string. When inside of a
1554 nested pattern, such as recursion, or in a subpattern dynamically generated
1555 via C<(??{})>, only the innermost pattern is ended immediately.
1556
1557 If the C<(*ACCEPT)> is inside of capturing buffers then the buffers are
1558 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1559 For instance:
1560
1561   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1562
1563 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1564 be set. If another branch in the inner parentheses were matched, such as in the
1565 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1566
1567 =back
1568
1569 =back
1570
1571 =head2 Backtracking
1572 X<backtrack> X<backtracking>
1573
1574 NOTE: This section presents an abstract approximation of regular
1575 expression behavior.  For a more rigorous (and complicated) view of
1576 the rules involved in selecting a match among possible alternatives,
1577 see L<Combining RE Pieces>.
1578
1579 A fundamental feature of regular expression matching involves the
1580 notion called I<backtracking>, which is currently used (when needed)
1581 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
1582 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
1583 internally, but the general principle outlined here is valid.
1584
1585 For a regular expression to match, the I<entire> regular expression must
1586 match, not just part of it.  So if the beginning of a pattern containing a
1587 quantifier succeeds in a way that causes later parts in the pattern to
1588 fail, the matching engine backs up and recalculates the beginning
1589 part--that's why it's called backtracking.
1590
1591 Here is an example of backtracking:  Let's say you want to find the
1592 word following "foo" in the string "Food is on the foo table.":
1593
1594     $_ = "Food is on the foo table.";
1595     if ( /\b(foo)\s+(\w+)/i ) {
1596         print "$2 follows $1.\n";
1597     }
1598
1599 When the match runs, the first part of the regular expression (C<\b(foo)>)
1600 finds a possible match right at the beginning of the string, and loads up
1601 $1 with "Foo".  However, as soon as the matching engine sees that there's
1602 no whitespace following the "Foo" that it had saved in $1, it realizes its
1603 mistake and starts over again one character after where it had the
1604 tentative match.  This time it goes all the way until the next occurrence
1605 of "foo". The complete regular expression matches this time, and you get
1606 the expected output of "table follows foo."
1607
1608 Sometimes minimal matching can help a lot.  Imagine you'd like to match
1609 everything between "foo" and "bar".  Initially, you write something
1610 like this:
1611
1612     $_ =  "The food is under the bar in the barn.";
1613     if ( /foo(.*)bar/ ) {
1614         print "got <$1>\n";
1615     }
1616
1617 Which perhaps unexpectedly yields:
1618
1619   got <d is under the bar in the >
1620
1621 That's because C<.*> was greedy, so you get everything between the
1622 I<first> "foo" and the I<last> "bar".  Here it's more effective
1623 to use minimal matching to make sure you get the text between a "foo"
1624 and the first "bar" thereafter.
1625
1626     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
1627   got <d is under the >
1628
1629 Here's another example. Let's say you'd like to match a number at the end
1630 of a string, and you also want to keep the preceding part of the match.
1631 So you write this:
1632
1633     $_ = "I have 2 numbers: 53147";
1634     if ( /(.*)(\d*)/ ) {                                # Wrong!
1635         print "Beginning is <$1>, number is <$2>.\n";
1636     }
1637
1638 That won't work at all, because C<.*> was greedy and gobbled up the
1639 whole string. As C<\d*> can match on an empty string the complete
1640 regular expression matched successfully.
1641
1642     Beginning is <I have 2 numbers: 53147>, number is <>.
1643
1644 Here are some variants, most of which don't work:
1645
1646     $_ = "I have 2 numbers: 53147";
1647     @pats = qw{
1648         (.*)(\d*)
1649         (.*)(\d+)
1650         (.*?)(\d*)
1651         (.*?)(\d+)
1652         (.*)(\d+)$
1653         (.*?)(\d+)$
1654         (.*)\b(\d+)$
1655         (.*\D)(\d+)$
1656     };
1657
1658     for $pat (@pats) {
1659         printf "%-12s ", $pat;
1660         if ( /$pat/ ) {
1661             print "<$1> <$2>\n";
1662         } else {
1663             print "FAIL\n";
1664         }
1665     }
1666
1667 That will print out:
1668
1669     (.*)(\d*)    <I have 2 numbers: 53147> <>
1670     (.*)(\d+)    <I have 2 numbers: 5314> <7>
1671     (.*?)(\d*)   <> <>
1672     (.*?)(\d+)   <I have > <2>
1673     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
1674     (.*?)(\d+)$  <I have 2 numbers: > <53147>
1675     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
1676     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
1677
1678 As you see, this can be a bit tricky.  It's important to realize that a
1679 regular expression is merely a set of assertions that gives a definition
1680 of success.  There may be 0, 1, or several different ways that the
1681 definition might succeed against a particular string.  And if there are
1682 multiple ways it might succeed, you need to understand backtracking to
1683 know which variety of success you will achieve.
1684
1685 When using look-ahead assertions and negations, this can all get even
1686 trickier.  Imagine you'd like to find a sequence of non-digits not
1687 followed by "123".  You might try to write that as
1688
1689     $_ = "ABC123";
1690     if ( /^\D*(?!123)/ ) {              # Wrong!
1691         print "Yup, no 123 in $_\n";
1692     }
1693
1694 But that isn't going to match; at least, not the way you're hoping.  It
1695 claims that there is no 123 in the string.  Here's a clearer picture of
1696 why that pattern matches, contrary to popular expectations:
1697
1698     $x = 'ABC123';
1699     $y = 'ABC445';
1700
1701     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
1702     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
1703
1704     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
1705     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
1706
1707 This prints
1708
1709     2: got ABC
1710     3: got AB
1711     4: got ABC
1712
1713 You might have expected test 3 to fail because it seems to a more
1714 general purpose version of test 1.  The important difference between
1715 them is that test 3 contains a quantifier (C<\D*>) and so can use
1716 backtracking, whereas test 1 will not.  What's happening is
1717 that you've asked "Is it true that at the start of $x, following 0 or more
1718 non-digits, you have something that's not 123?"  If the pattern matcher had
1719 let C<\D*> expand to "ABC", this would have caused the whole pattern to
1720 fail.
1721
1722 The search engine will initially match C<\D*> with "ABC".  Then it will
1723 try to match C<(?!123> with "123", which fails.  But because
1724 a quantifier (C<\D*>) has been used in the regular expression, the
1725 search engine can backtrack and retry the match differently
1726 in the hope of matching the complete regular expression.
1727
1728 The pattern really, I<really> wants to succeed, so it uses the
1729 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
1730 time.  Now there's indeed something following "AB" that is not
1731 "123".  It's "C123", which suffices.
1732
1733 We can deal with this by using both an assertion and a negation.
1734 We'll say that the first part in $1 must be followed both by a digit
1735 and by something that's not "123".  Remember that the look-aheads
1736 are zero-width expressions--they only look, but don't consume any
1737 of the string in their match.  So rewriting this way produces what
1738 you'd expect; that is, case 5 will fail, but case 6 succeeds:
1739
1740     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
1741     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
1742
1743     6: got ABC
1744
1745 In other words, the two zero-width assertions next to each other work as though
1746 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
1747 matches only if you're at the beginning of the line AND the end of the
1748 line simultaneously.  The deeper underlying truth is that juxtaposition in
1749 regular expressions always means AND, except when you write an explicit OR
1750 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
1751 although the attempted matches are made at different positions because "a"
1752 is not a zero-width assertion, but a one-width assertion.
1753
1754 B<WARNING>: Particularly complicated regular expressions can take
1755 exponential time to solve because of the immense number of possible
1756 ways they can use backtracking to try for a match.  For example, without
1757 internal optimizations done by the regular expression engine, this will
1758 take a painfully long time to run:
1759
1760     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
1761
1762 And if you used C<*>'s in the internal groups instead of limiting them
1763 to 0 through 5 matches, then it would take forever--or until you ran
1764 out of stack space.  Moreover, these internal optimizations are not
1765 always applicable.  For example, if you put C<{0,5}> instead of C<*>
1766 on the external group, no current optimization is applicable, and the
1767 match takes a long time to finish.
1768
1769 A powerful tool for optimizing such beasts is what is known as an
1770 "independent group",
1771 which does not backtrack (see L<C<< (?>pattern) >>>).  Note also that
1772 zero-length look-ahead/look-behind assertions will not backtrack to make
1773 the tail match, since they are in "logical" context: only
1774 whether they match is considered relevant.  For an example
1775 where side-effects of look-ahead I<might> have influenced the
1776 following match, see L<C<< (?>pattern) >>>.
1777
1778 =head2 Version 8 Regular Expressions
1779 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
1780
1781 In case you're not familiar with the "regular" Version 8 regex
1782 routines, here are the pattern-matching rules not described above.
1783
1784 Any single character matches itself, unless it is a I<metacharacter>
1785 with a special meaning described here or above.  You can cause
1786 characters that normally function as metacharacters to be interpreted
1787 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
1788 character; "\\" matches a "\"). This escape mechanism is also required
1789 for the character used as the pattern delimiter.
1790
1791 A series of characters matches that series of characters in the target
1792 string, so the pattern  C<blurfl> would match "blurfl" in the target
1793 string.
1794
1795 You can specify a character class, by enclosing a list of characters
1796 in C<[]>, which will match any character from the list.  If the
1797 first character after the "[" is "^", the class matches any character not
1798 in the list.  Within a list, the "-" character specifies a
1799 range, so that C<a-z> represents all characters between "a" and "z",
1800 inclusive.  If you want either "-" or "]" itself to be a member of a
1801 class, put it at the start of the list (possibly after a "^"), or
1802 escape it with a backslash.  "-" is also taken literally when it is
1803 at the end of the list, just before the closing "]".  (The
1804 following all specify the same class of three characters: C<[-az]>,
1805 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
1806 specifies a class containing twenty-six characters, even on EBCDIC-based
1807 character sets.)  Also, if you try to use the character
1808 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
1809 a range, the "-" is understood literally.
1810
1811 Note also that the whole range idea is rather unportable between
1812 character sets--and even within character sets they may cause results
1813 you probably didn't expect.  A sound principle is to use only ranges
1814 that begin from and end at either alphabetics of equal case ([a-e],
1815 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
1816 spell out the character sets in full.
1817
1818 Characters may be specified using a metacharacter syntax much like that
1819 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
1820 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
1821 of octal digits, matches the character whose coded character set value
1822 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
1823 matches the character whose numeric value is I<nn>. The expression \cI<x>
1824 matches the character control-I<x>.  Finally, the "." metacharacter
1825 matches any character except "\n" (unless you use C</s>).
1826
1827 You can specify a series of alternatives for a pattern using "|" to
1828 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
1829 or "foe" in the target string (as would C<f(e|i|o)e>).  The
1830 first alternative includes everything from the last pattern delimiter
1831 ("(", "[", or the beginning of the pattern) up to the first "|", and
1832 the last alternative contains everything from the last "|" to the next
1833 pattern delimiter.  That's why it's common practice to include
1834 alternatives in parentheses: to minimize confusion about where they
1835 start and end.
1836
1837 Alternatives are tried from left to right, so the first
1838 alternative found for which the entire expression matches, is the one that
1839 is chosen. This means that alternatives are not necessarily greedy. For
1840 example: when matching C<foo|foot> against "barefoot", only the "foo"
1841 part will match, as that is the first alternative tried, and it successfully
1842 matches the target string. (This might not seem important, but it is
1843 important when you are capturing matched text using parentheses.)
1844
1845 Also remember that "|" is interpreted as a literal within square brackets,
1846 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
1847
1848 Within a pattern, you may designate subpatterns for later reference
1849 by enclosing them in parentheses, and you may refer back to the
1850 I<n>th subpattern later in the pattern using the metacharacter
1851 \I<n>.  Subpatterns are numbered based on the left to right order
1852 of their opening parenthesis.  A backreference matches whatever
1853 actually matched the subpattern in the string being examined, not
1854 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\1\d*> will
1855 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
1856 1 matched "0x", even though the rule C<0|0x> could potentially match
1857 the leading 0 in the second number.
1858
1859 =head2 Warning on \1 Instead of $1
1860
1861 Some people get too used to writing things like:
1862
1863     $pattern =~ s/(\W)/\\\1/g;
1864
1865 This is grandfathered for the RHS of a substitute to avoid shocking the
1866 B<sed> addicts, but it's a dirty habit to get into.  That's because in
1867 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
1868 the usual double-quoted string means a control-A.  The customary Unix
1869 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
1870 of doing that, you get yourself into trouble if you then add an C</e>
1871 modifier.
1872
1873     s/(\d+)/ \1 + 1 /eg;        # causes warning under -w
1874
1875 Or if you try to do
1876
1877     s/(\d+)/\1000/;
1878
1879 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
1880 C<${1}000>.  The operation of interpolation should not be confused
1881 with the operation of matching a backreference.  Certainly they mean two
1882 different things on the I<left> side of the C<s///>.
1883
1884 =head2 Repeated Patterns Matching a Zero-length Substring
1885
1886 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
1887
1888 Regular expressions provide a terse and powerful programming language.  As
1889 with most other power tools, power comes together with the ability
1890 to wreak havoc.
1891
1892 A common abuse of this power stems from the ability to make infinite
1893 loops using regular expressions, with something as innocuous as:
1894
1895     'foo' =~ m{ ( o? )* }x;
1896
1897 The C<o?> matches at the beginning of C<'foo'>, and since the position
1898 in the string is not moved by the match, C<o?> would match again and again
1899 because of the C<*> quantifier.  Another common way to create a similar cycle
1900 is with the looping modifier C<//g>:
1901
1902     @matches = ( 'foo' =~ m{ o? }xg );
1903
1904 or
1905
1906     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1907
1908 or the loop implied by split().
1909
1910 However, long experience has shown that many programming tasks may
1911 be significantly simplified by using repeated subexpressions that
1912 may match zero-length substrings.  Here's a simple example being:
1913
1914     @chars = split //, $string;           # // is not magic in split
1915     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1916
1917 Thus Perl allows such constructs, by I<forcefully breaking
1918 the infinite loop>.  The rules for this are different for lower-level
1919 loops given by the greedy quantifiers C<*+{}>, and for higher-level
1920 ones like the C</g> modifier or split() operator.
1921
1922 The lower-level loops are I<interrupted> (that is, the loop is
1923 broken) when Perl detects that a repeated expression matched a
1924 zero-length substring.   Thus
1925
1926    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1927
1928 is made equivalent to
1929
1930    m{   (?: NON_ZERO_LENGTH )*
1931       |
1932         (?: ZERO_LENGTH )?
1933     }x;
1934
1935 The higher level-loops preserve an additional state between iterations:
1936 whether the last match was zero-length.  To break the loop, the following
1937 match after a zero-length match is prohibited to have a length of zero.
1938 This prohibition interacts with backtracking (see L<"Backtracking">),
1939 and so the I<second best> match is chosen if the I<best> match is of
1940 zero length.
1941
1942 For example:
1943
1944     $_ = 'bar';
1945     s/\w??/<$&>/g;
1946
1947 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
1948 match given by non-greedy C<??> is the zero-length match, and the I<second
1949 best> match is what is matched by C<\w>.  Thus zero-length matches
1950 alternate with one-character-long matches.
1951
1952 Similarly, for repeated C<m/()/g> the second-best match is the match at the
1953 position one notch further in the string.
1954
1955 The additional state of being I<matched with zero-length> is associated with
1956 the matched string, and is reset by each assignment to pos().
1957 Zero-length matches at the end of the previous match are ignored
1958 during C<split>.
1959
1960 =head2 Combining RE Pieces
1961
1962 Each of the elementary pieces of regular expressions which were described
1963 before (such as C<ab> or C<\Z>) could match at most one substring
1964 at the given position of the input string.  However, in a typical regular
1965 expression these elementary pieces are combined into more complicated
1966 patterns using combining operators C<ST>, C<S|T>, C<S*> etc
1967 (in these examples C<S> and C<T> are regular subexpressions).
1968
1969 Such combinations can include alternatives, leading to a problem of choice:
1970 if we match a regular expression C<a|ab> against C<"abc">, will it match
1971 substring C<"a"> or C<"ab">?  One way to describe which substring is
1972 actually matched is the concept of backtracking (see L<"Backtracking">).
1973 However, this description is too low-level and makes you think
1974 in terms of a particular implementation.
1975
1976 Another description starts with notions of "better"/"worse".  All the
1977 substrings which may be matched by the given regular expression can be
1978 sorted from the "best" match to the "worst" match, and it is the "best"
1979 match which is chosen.  This substitutes the question of "what is chosen?"
1980 by the question of "which matches are better, and which are worse?".
1981
1982 Again, for elementary pieces there is no such question, since at most
1983 one match at a given position is possible.  This section describes the
1984 notion of better/worse for combining operators.  In the description
1985 below C<S> and C<T> are regular subexpressions.
1986
1987 =over 4
1988
1989 =item C<ST>
1990
1991 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
1992 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
1993 which can be matched by C<T>.
1994
1995 If C<A> is better match for C<S> than C<A'>, C<AB> is a better
1996 match than C<A'B'>.
1997
1998 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
1999 C<B> is better match for C<T> than C<B'>.
2000
2001 =item C<S|T>
2002
2003 When C<S> can match, it is a better match than when only C<T> can match.
2004
2005 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2006 two matches for C<T>.
2007
2008 =item C<S{REPEAT_COUNT}>
2009
2010 Matches as C<SSS...S> (repeated as many times as necessary).
2011
2012 =item C<S{min,max}>
2013
2014 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2015
2016 =item C<S{min,max}?>
2017
2018 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2019
2020 =item C<S?>, C<S*>, C<S+>
2021
2022 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2023
2024 =item C<S??>, C<S*?>, C<S+?>
2025
2026 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2027
2028 =item C<< (?>S) >>
2029
2030 Matches the best match for C<S> and only that.
2031
2032 =item C<(?=S)>, C<(?<=S)>
2033
2034 Only the best match for C<S> is considered.  (This is important only if
2035 C<S> has capturing parentheses, and backreferences are used somewhere
2036 else in the whole regular expression.)
2037
2038 =item C<(?!S)>, C<(?<!S)>
2039
2040 For this grouping operator there is no need to describe the ordering, since
2041 only whether or not C<S> can match is important.
2042
2043 =item C<(??{ EXPR })>, C<(?PARNO)>
2044
2045 The ordering is the same as for the regular expression which is
2046 the result of EXPR, or the pattern contained by capture buffer PARNO.
2047
2048 =item C<(?(condition)yes-pattern|no-pattern)>
2049
2050 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2051 already determined.  The ordering of the matches is the same as for the
2052 chosen subexpression.
2053
2054 =back
2055
2056 The above recipes describe the ordering of matches I<at a given position>.
2057 One more rule is needed to understand how a match is determined for the
2058 whole regular expression: a match at an earlier position is always better
2059 than a match at a later position.
2060
2061 =head2 Creating Custom RE Engines
2062
2063 Overloaded constants (see L<overload>) provide a simple way to extend
2064 the functionality of the RE engine.
2065
2066 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2067 matches at a boundary between whitespace characters and non-whitespace
2068 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2069 at these positions, so we want to have each C<\Y|> in the place of the
2070 more complicated version.  We can create a module C<customre> to do
2071 this:
2072
2073     package customre;
2074     use overload;
2075
2076     sub import {
2077       shift;
2078       die "No argument to customre::import allowed" if @_;
2079       overload::constant 'qr' => \&convert;
2080     }
2081
2082     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2083
2084     # We must also take care of not escaping the legitimate \\Y|
2085     # sequence, hence the presence of '\\' in the conversion rules.
2086     my %rules = ( '\\' => '\\\\',
2087                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2088     sub convert {
2089       my $re = shift;
2090       $re =~ s{
2091                 \\ ( \\ | Y . )
2092               }
2093               { $rules{$1} or invalid($re,$1) }sgex;
2094       return $re;
2095     }
2096
2097 Now C<use customre> enables the new escape in constant regular
2098 expressions, i.e., those without any runtime variable interpolations.
2099 As documented in L<overload>, this conversion will work only over
2100 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2101 part of this regular expression needs to be converted explicitly
2102 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2103
2104     use customre;
2105     $re = <>;
2106     chomp $re;
2107     $re = customre::convert $re;
2108     /\Y|$re\Y|/;
2109
2110 =head1 PCRE/Python Support
2111
2112 As of Perl 5.10 Perl supports several Python/PCRE specific extensions
2113 to the regex syntax. While Perl programmers are encouraged to use the
2114 Perl specific syntax, the following are legal in Perl 5.10:
2115
2116 =over 4
2117
2118 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2119
2120 Define a named capture buffer. Equivalent to C<< (?<NAME>pattern) >>.
2121
2122 =item C<< (?P=NAME) >>
2123
2124 Backreference to a named capture buffer. Equivalent to C<< \g{NAME} >>.
2125
2126 =item C<< (?P>NAME) >>
2127
2128 Subroutine call to a named capture buffer. Equivalent to C<< (?&NAME) >>.
2129
2130 =back
2131
2132 =head1 BUGS
2133
2134 This document varies from difficult to understand to completely
2135 and utterly opaque.  The wandering prose riddled with jargon is
2136 hard to fathom in several places.
2137
2138 This document needs a rewrite that separates the tutorial content
2139 from the reference content.
2140
2141 =head1 SEE ALSO
2142
2143 L<perlrequick>.
2144
2145 L<perlretut>.
2146
2147 L<perlop/"Regexp Quote-Like Operators">.
2148
2149 L<perlop/"Gory details of parsing quoted constructs">.
2150
2151 L<perlfaq6>.
2152
2153 L<perlfunc/pos>.
2154
2155 L<perllocale>.
2156
2157 L<perlebcdic>.
2158
2159 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2160 by O'Reilly and Associates.