This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Add Regexp::Keep \K functionality to regex engine as well as add \v and \V, cleanup...
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19 Matching operations can have various modifiers.  Modifiers
20 that relate to the interpretation of the regular expression inside
21 are listed below.  Modifiers that alter the way a regular expression
22 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
23 L<perlop/"Gory details of parsing quoted constructs">.
24
25 =over 4
26
27 =item i
28 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
29 X<regular expression, case-insensitive>
30
31 Do case-insensitive pattern matching.
32
33 If C<use locale> is in effect, the case map is taken from the current
34 locale.  See L<perllocale>.
35
36 =item m
37 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
38
39 Treat string as multiple lines.  That is, change "^" and "$" from matching
40 the start or end of the string to matching the start or end of any
41 line anywhere within the string.
42
43 =item s
44 X</s> X<regex, single-line> X<regexp, single-line>
45 X<regular expression, single-line>
46
47 Treat string as single line.  That is, change "." to match any character
48 whatsoever, even a newline, which normally it would not match.
49
50 Used together, as /ms, they let the "." match any character whatsoever,
51 while still allowing "^" and "$" to match, respectively, just after
52 and just before newlines within the string.
53
54 =item x
55 X</x>
56
57 Extend your pattern's legibility by permitting whitespace and comments.
58
59 =back
60
61 These are usually written as "the C</x> modifier", even though the delimiter
62 in question might not really be a slash.  Any of these
63 modifiers may also be embedded within the regular expression itself using
64 the C<(?...)> construct.  See below.
65
66 The C</x> modifier itself needs a little more explanation.  It tells
67 the regular expression parser to ignore whitespace that is neither
68 backslashed nor within a character class.  You can use this to break up
69 your regular expression into (slightly) more readable parts.  The C<#>
70 character is also treated as a metacharacter introducing a comment,
71 just as in ordinary Perl code.  This also means that if you want real
72 whitespace or C<#> characters in the pattern (outside a character
73 class, where they are unaffected by C</x>), then you'll either have to
74 escape them (using backslashes or C<\Q...\E>) or encode them using octal
75 or hex escapes.  Taken together, these features go a long way towards
76 making Perl's regular expressions more readable.  Note that you have to
77 be careful not to include the pattern delimiter in the comment--perl has
78 no way of knowing you did not intend to close the pattern early.  See
79 the C-comment deletion code in L<perlop>.  Also note that anything inside
80 a C<\Q...\E> stays unaffected by C</x>.
81 X</x>
82
83 =head2 Regular Expressions
84
85 =head3 Metacharacters
86
87 The patterns used in Perl pattern matching derive from supplied in
88 the Version 8 regex routines.  (The routines are derived
89 (distantly) from Henry Spencer's freely redistributable reimplementation
90 of the V8 routines.)  See L<Version 8 Regular Expressions> for
91 details.
92
93 In particular the following metacharacters have their standard I<egrep>-ish
94 meanings:
95 X<metacharacter>
96 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
97
98
99     \   Quote the next metacharacter
100     ^   Match the beginning of the line
101     .   Match any character (except newline)
102     $   Match the end of the line (or before newline at the end)
103     |   Alternation
104     ()  Grouping
105     []  Character class
106
107 By default, the "^" character is guaranteed to match only the
108 beginning of the string, the "$" character only the end (or before the
109 newline at the end), and Perl does certain optimizations with the
110 assumption that the string contains only one line.  Embedded newlines
111 will not be matched by "^" or "$".  You may, however, wish to treat a
112 string as a multi-line buffer, such that the "^" will match after any
113 newline within the string (except if the newline is the last character in
114 the string), and "$" will match before any newline.  At the
115 cost of a little more overhead, you can do this by using the /m modifier
116 on the pattern match operator.  (Older programs did this by setting C<$*>,
117 but this practice has been removed in perl 5.9.)
118 X<^> X<$> X</m>
119
120 To simplify multi-line substitutions, the "." character never matches a
121 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
122 the string is a single line--even if it isn't.
123 X<.> X</s>
124
125 =head3 Quantifiers
126
127 The following standard quantifiers are recognized:
128 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
129
130     *      Match 0 or more times
131     +      Match 1 or more times
132     ?      Match 1 or 0 times
133     {n}    Match exactly n times
134     {n,}   Match at least n times
135     {n,m}  Match at least n but not more than m times
136
137 (If a curly bracket occurs in any other context, it is treated
138 as a regular character.  In particular, the lower bound
139 is not optional.)  The "*" modifier is equivalent to C<{0,}>, the "+"
140 modifier to C<{1,}>, and the "?" modifier to C<{0,1}>.  n and m are limited
141 to integral values less than a preset limit defined when perl is built.
142 This is usually 32766 on the most common platforms.  The actual limit can
143 be seen in the error message generated by code such as this:
144
145     $_ **= $_ , / {$_} / for 2 .. 42;
146
147 By default, a quantified subpattern is "greedy", that is, it will match as
148 many times as possible (given a particular starting location) while still
149 allowing the rest of the pattern to match.  If you want it to match the
150 minimum number of times possible, follow the quantifier with a "?".  Note
151 that the meanings don't change, just the "greediness":
152 X<metacharacter> X<greedy> X<greedyness>
153 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
154
155     *?     Match 0 or more times
156     +?     Match 1 or more times
157     ??     Match 0 or 1 time
158     {n}?   Match exactly n times
159     {n,}?  Match at least n times
160     {n,m}? Match at least n but not more than m times
161
162 By default, when a quantified subpattern does not allow the rest of the
163 overall pattern to match, Perl will backtrack. However, this behaviour is
164 sometimes undesirable. Thus Perl provides the "possesive" quantifier form
165 as well.
166
167     *+     Match 0 or more times and give nothing back
168     ++     Match 1 or more times and give nothing back
169     ?+     Match 0 or 1 time and give nothing back
170     {n}+   Match exactly n times and give nothing back (redundant)
171     {n,}+  Match at least n times and give nothing back
172     {n,m}+ Match at least n but not more than m times and give nothing back
173
174 For instance,
175
176    'aaaa' =~ /a++a/
177
178 will never match, as the C<a++> will gobble up all the C<a>'s in the
179 string and won't leave any for the remaining part of the pattern. This
180 feature can be extremely useful to give perl hints about where it
181 shouldn't backtrack. For instance, the typical "match a double-quoted
182 string" problem can be most efficiently performed when written as:
183
184    /"(?:[^"\\]++|\\.)*+"/
185
186 as we know that if the final quote does not match, bactracking will not
187 help. See the independent subexpression C<< (?>...) >> for more details;
188 possessive quantifiers are just syntactic sugar for that construct. For
189 instance the above example could also be written as follows:
190
191    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
192
193 =head3 Escape sequences
194
195 Because patterns are processed as double quoted strings, the following
196 also work:
197 X<\t> X<\n> X<\r> X<\f> X<\a> X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q>
198 X<\0> X<\c> X<\N> X<\x>
199
200     \t          tab                   (HT, TAB)
201     \n          newline               (LF, NL)
202     \r          return                (CR)
203     \f          form feed             (FF)
204     \a          alarm (bell)          (BEL)
205     \e          escape (think troff)  (ESC)
206     \033        octal char (think of a PDP-11)
207     \x1B        hex char
208     \x{263a}    wide hex char         (Unicode SMILEY)
209     \c[         control char
210     \N{name}    named char
211     \l          lowercase next char (think vi)
212     \u          uppercase next char (think vi)
213     \L          lowercase till \E (think vi)
214     \U          uppercase till \E (think vi)
215     \E          end case modification (think vi)
216     \Q          quote (disable) pattern metacharacters till \E
217
218 If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
219 and C<\U> is taken from the current locale.  See L<perllocale>.  For
220 documentation of C<\N{name}>, see L<charnames>.
221
222 You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
223 An unescaped C<$> or C<@> interpolates the corresponding variable,
224 while escaping will cause the literal string C<\$> to be matched.
225 You'll need to write something like C<m/\Quser\E\@\Qhost/>.
226
227 =head3 Character classes
228
229 In addition, Perl defines the following:
230 X<metacharacter>
231 X<\w> X<\W> X<\s> X<\S> X<\d> X<\D> X<\X> X<\p> X<\P> X<\C>
232 X<word> X<whitespace>
233
234     \w       Match a "word" character (alphanumeric plus "_")
235     \W       Match a non-"word" character
236     \s       Match a whitespace character
237     \S       Match a non-whitespace character
238     \d       Match a digit character
239     \D       Match a non-digit character
240     \pP      Match P, named property.  Use \p{Prop} for longer names.
241     \PP      Match non-P
242     \X       Match eXtended Unicode "combining character sequence",
243              equivalent to (?:\PM\pM*)
244     \C       Match a single C char (octet) even under Unicode.
245              NOTE: breaks up characters into their UTF-8 bytes,
246              so you may end up with malformed pieces of UTF-8.
247              Unsupported in lookbehind.
248     \1       Backreference to a specific group.
249              '1' may actually be any positive integer.
250     \g1      Backreference to a specific or previous group,
251     \g{-1}   number may be negative indicating a previous buffer and may
252              optionally be wrapped in curly brackets for safer parsing.
253     \g{name} Named backreference
254     \k<name> Named backreference
255     \N{name} Named unicode character, or unicode escape
256     \x12     Hexadecimal escape sequence
257     \x{1234} Long hexadecimal escape sequence
258     \K       Keep the stuff left of the \K, don't include it in $&
259     \v       Shortcut for (*PRUNE)
260     \V       Shortcut for (*SKIP)
261
262 A C<\w> matches a single alphanumeric character (an alphabetic
263 character, or a decimal digit) or C<_>, not a whole word.  Use C<\w+>
264 to match a string of Perl-identifier characters (which isn't the same
265 as matching an English word).  If C<use locale> is in effect, the list
266 of alphabetic characters generated by C<\w> is taken from the current
267 locale.  See L<perllocale>.  You may use C<\w>, C<\W>, C<\s>, C<\S>,
268 C<\d>, and C<\D> within character classes, but if you try to use them
269 as endpoints of a range, that's not a range, the "-" is understood
270 literally.  If Unicode is in effect, C<\s> matches also "\x{85}",
271 "\x{2028}, and "\x{2029}", see L<perlunicode> for more details about
272 C<\pP>, C<\PP>, and C<\X>, and L<perluniintro> about Unicode in general.
273 You can define your own C<\p> and C<\P> properties, see L<perlunicode>.
274 X<\w> X<\W> X<word>
275
276 The POSIX character class syntax
277 X<character class>
278
279     [:class:]
280
281 is also available.  Note that the C<[> and C<]> braces are I<literal>;
282 they must always be used within a character class expression.
283
284     # this is correct:
285     $string =~ /[[:alpha:]]/;
286
287     # this is not, and will generate a warning:
288     $string =~ /[:alpha:]/;
289
290 The available classes and their backslash equivalents (if available) are
291 as follows:
292 X<character class>
293 X<alpha> X<alnum> X<ascii> X<blank> X<cntrl> X<digit> X<graph>
294 X<lower> X<print> X<punct> X<space> X<upper> X<word> X<xdigit>
295
296     alpha
297     alnum
298     ascii
299     blank               [1]
300     cntrl
301     digit       \d
302     graph
303     lower
304     print
305     punct
306     space       \s      [2]
307     upper
308     word        \w      [3]
309     xdigit
310
311 =over
312
313 =item [1]
314
315 A GNU extension equivalent to C<[ \t]>, "all horizontal whitespace".
316
317 =item [2]
318
319 Not exactly equivalent to C<\s> since the C<[[:space:]]> includes
320 also the (very rare) "vertical tabulator", "\ck", chr(11).
321
322 =item [3]
323
324 A Perl extension, see above.
325
326 =back
327
328 For example use C<[:upper:]> to match all the uppercase characters.
329 Note that the C<[]> are part of the C<[::]> construct, not part of the
330 whole character class.  For example:
331
332     [01[:alpha:]%]
333
334 matches zero, one, any alphabetic character, and the percentage sign.
335
336 The following equivalences to Unicode \p{} constructs and equivalent
337 backslash character classes (if available), will hold:
338 X<character class> X<\p> X<\p{}>
339
340     [[:...:]]   \p{...}         backslash
341
342     alpha       IsAlpha
343     alnum       IsAlnum
344     ascii       IsASCII
345     blank       IsSpace
346     cntrl       IsCntrl
347     digit       IsDigit        \d
348     graph       IsGraph
349     lower       IsLower
350     print       IsPrint
351     punct       IsPunct
352     space       IsSpace
353                 IsSpacePerl    \s
354     upper       IsUpper
355     word        IsWord
356     xdigit      IsXDigit
357
358 For example C<[[:lower:]]> and C<\p{IsLower}> are equivalent.
359
360 If the C<utf8> pragma is not used but the C<locale> pragma is, the
361 classes correlate with the usual isalpha(3) interface (except for
362 "word" and "blank").
363
364 The assumedly non-obviously named classes are:
365
366 =over 4
367
368 =item cntrl
369 X<cntrl>
370
371 Any control character.  Usually characters that don't produce output as
372 such but instead control the terminal somehow: for example newline and
373 backspace are control characters.  All characters with ord() less than
374 32 are most often classified as control characters (assuming ASCII,
375 the ISO Latin character sets, and Unicode), as is the character with
376 the ord() value of 127 (C<DEL>).
377
378 =item graph
379 X<graph>
380
381 Any alphanumeric or punctuation (special) character.
382
383 =item print
384 X<print>
385
386 Any alphanumeric or punctuation (special) character or the space character.
387
388 =item punct
389 X<punct>
390
391 Any punctuation (special) character.
392
393 =item xdigit
394 X<xdigit>
395
396 Any hexadecimal digit.  Though this may feel silly ([0-9A-Fa-f] would
397 work just fine) it is included for completeness.
398
399 =back
400
401 You can negate the [::] character classes by prefixing the class name
402 with a '^'. This is a Perl extension.  For example:
403 X<character class, negation>
404
405     POSIX         traditional  Unicode
406
407     [[:^digit:]]    \D         \P{IsDigit}
408     [[:^space:]]    \S         \P{IsSpace}
409     [[:^word:]]     \W         \P{IsWord}
410
411 Perl respects the POSIX standard in that POSIX character classes are
412 only supported within a character class.  The POSIX character classes
413 [.cc.] and [=cc=] are recognized but B<not> supported and trying to
414 use them will cause an error.
415
416 =head3 Assertions
417
418 Perl defines the following zero-width assertions:
419 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
420 X<regexp, zero-width assertion>
421 X<regular expression, zero-width assertion>
422 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
423
424     \b  Match a word boundary
425     \B  Match a non-(word boundary)
426     \A  Match only at beginning of string
427     \Z  Match only at end of string, or before newline at the end
428     \z  Match only at end of string
429     \G  Match only at pos() (e.g. at the end-of-match position
430         of prior m//g)
431
432 A word boundary (C<\b>) is a spot between two characters
433 that has a C<\w> on one side of it and a C<\W> on the other side
434 of it (in either order), counting the imaginary characters off the
435 beginning and end of the string as matching a C<\W>.  (Within
436 character classes C<\b> represents backspace rather than a word
437 boundary, just as it normally does in any double-quoted string.)
438 The C<\A> and C<\Z> are just like "^" and "$", except that they
439 won't match multiple times when the C</m> modifier is used, while
440 "^" and "$" will match at every internal line boundary.  To match
441 the actual end of the string and not ignore an optional trailing
442 newline, use C<\z>.
443 X<\b> X<\A> X<\Z> X<\z> X</m>
444
445 The C<\G> assertion can be used to chain global matches (using
446 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
447 It is also useful when writing C<lex>-like scanners, when you have
448 several patterns that you want to match against consequent substrings
449 of your string, see the previous reference.  The actual location
450 where C<\G> will match can also be influenced by using C<pos()> as
451 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
452 matches is modified somewhat, in that contents to the left of C<\G> is
453 not counted when determining the length of the match. Thus the following
454 will not match forever:
455 X<\G>
456
457     $str = 'ABC';
458     pos($str) = 1;
459     while (/.\G/g) {
460         print $&;
461     }
462
463 It will print 'A' and then terminate, as it considers the match to
464 be zero-width, and thus will not match at the same position twice in a
465 row.
466
467 It is worth noting that C<\G> improperly used can result in an infinite
468 loop. Take care when using patterns that include C<\G> in an alternation.
469
470 =head3 Capture buffers
471
472 The bracketing construct C<( ... )> creates capture buffers.  To
473 refer to the digit'th buffer use \<digit> within the
474 match.  Outside the match use "$" instead of "\".  (The
475 \<digit> notation works in certain circumstances outside
476 the match.  See the warning below about \1 vs $1 for details.)
477 Referring back to another part of the match is called a
478 I<backreference>.
479 X<regex, capture buffer> X<regexp, capture buffer>
480 X<regular expression, capture buffer> X<backreference>
481
482 There is no limit to the number of captured substrings that you may
483 use.  However Perl also uses \10, \11, etc. as aliases for \010,
484 \011, etc.  (Recall that 0 means octal, so \011 is the character at
485 number 9 in your coded character set; which would be the 10th character,
486 a horizontal tab under ASCII.)  Perl resolves this
487 ambiguity by interpreting \10 as a backreference only if at least 10
488 left parentheses have opened before it.  Likewise \11 is a
489 backreference only if at least 11 left parentheses have opened
490 before it.  And so on.  \1 through \9 are always interpreted as
491 backreferences.
492
493 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
494 In order to provide a safer and easier way to construct patterns using
495 backrefs, in Perl 5.10 the C<\g{N}> notation is provided. The curly
496 brackets are optional, however omitting them is less safe as the meaning
497 of the pattern can be changed by text (such as digits) following it.
498 When N is a positive integer the C<\g{N}> notation is exactly equivalent
499 to using normal backreferences. When N is a negative integer then it is
500 a relative backreference referring to the previous N'th capturing group.
501 When the bracket form is used and N is not an integer, it is treated as a
502 reference to a named buffer.
503
504 Thus C<\g{-1}> refers to the last buffer, C<\g{-2}> refers to the
505 buffer before that. For example:
506
507         /
508          (Y)            # buffer 1
509          (              # buffer 2
510             (X)         # buffer 3
511             \g{-1}      # backref to buffer 3
512             \g{-3}      # backref to buffer 1
513          )
514         /x
515
516 and would match the same as C</(Y) ( (X) \3 \1 )/x>.
517
518 Additionally, as of Perl 5.10 you may use named capture buffers and named
519 backreferences. The notation is C<< (?<name>...) >> to declare and C<< \k<name> >>
520 to reference. You may also use single quotes instead of angle brackets to quote the
521 name; and you may use the bracketed C<< \g{name} >> back reference syntax.
522 The only difference between named capture buffers and unnamed ones is
523 that multiple buffers may have the same name and that the contents of
524 named capture buffers are available via the C<%+> hash. When multiple
525 groups share the same name C<$+{name}> and C<< \k<name> >> refer to the
526 leftmost defined group, thus it's possible to do things with named capture
527 buffers that would otherwise require C<(??{})> code to accomplish. Named
528 capture buffers are numbered just as normal capture buffers are and may be
529 referenced via the magic numeric variables or via numeric backreferences
530 as well as by name.
531
532 Examples:
533
534     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
535
536     /(.)\1/                         # find first doubled char
537          and print "'$1' is the first doubled character\n";
538
539     /(?<char>.)\k<char>/            # ... a different way
540          and print "'$+{char}' is the first doubled character\n";
541
542     /(?<char>.)\1/                  # ... mix and match
543          and print "'$1' is the first doubled character\n";
544
545     if (/Time: (..):(..):(..)/) {   # parse out values
546         $hours = $1;
547         $minutes = $2;
548         $seconds = $3;
549     }
550
551 Several special variables also refer back to portions of the previous
552 match.  C<$+> returns whatever the last bracket match matched.
553 C<$&> returns the entire matched string.  (At one point C<$0> did
554 also, but now it returns the name of the program.)  C<$`> returns
555 everything before the matched string.  C<$'> returns everything
556 after the matched string. And C<$^N> contains whatever was matched by
557 the most-recently closed group (submatch). C<$^N> can be used in
558 extended patterns (see below), for example to assign a submatch to a
559 variable.
560 X<$+> X<$^N> X<$&> X<$`> X<$'>
561
562 The numbered match variables ($1, $2, $3, etc.) and the related punctuation
563 set (C<$+>, C<$&>, C<$`>, C<$'>, and C<$^N>) are all dynamically scoped
564 until the end of the enclosing block or until the next successful
565 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
566 X<$+> X<$^N> X<$&> X<$`> X<$'>
567 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
568
569
570 B<NOTE>: failed matches in Perl do not reset the match variables,
571 which makes it easier to write code that tests for a series of more
572 specific cases and remembers the best match.
573
574 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
575 C<$'> anywhere in the program, it has to provide them for every
576 pattern match.  This may substantially slow your program.  Perl
577 uses the same mechanism to produce $1, $2, etc, so you also pay a
578 price for each pattern that contains capturing parentheses.  (To
579 avoid this cost while retaining the grouping behaviour, use the
580 extended regular expression C<(?: ... )> instead.)  But if you never
581 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
582 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
583 if you can, but if you can't (and some algorithms really appreciate
584 them), once you've used them once, use them at will, because you've
585 already paid the price.  As of 5.005, C<$&> is not so costly as the
586 other two.
587 X<$&> X<$`> X<$'>
588
589 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
590 C<\w>, C<\n>.  Unlike some other regular expression languages, there
591 are no backslashed symbols that aren't alphanumeric.  So anything
592 that looks like \\, \(, \), \<, \>, \{, or \} is always
593 interpreted as a literal character, not a metacharacter.  This was
594 once used in a common idiom to disable or quote the special meanings
595 of regular expression metacharacters in a string that you want to
596 use for a pattern. Simply quote all non-"word" characters:
597
598     $pattern =~ s/(\W)/\\$1/g;
599
600 (If C<use locale> is set, then this depends on the current locale.)
601 Today it is more common to use the quotemeta() function or the C<\Q>
602 metaquoting escape sequence to disable all metacharacters' special
603 meanings like this:
604
605     /$unquoted\Q$quoted\E$unquoted/
606
607 Beware that if you put literal backslashes (those not inside
608 interpolated variables) between C<\Q> and C<\E>, double-quotish
609 backslash interpolation may lead to confusing results.  If you
610 I<need> to use literal backslashes within C<\Q...\E>,
611 consult L<perlop/"Gory details of parsing quoted constructs">.
612
613 =head2 Extended Patterns
614
615 Perl also defines a consistent extension syntax for features not
616 found in standard tools like B<awk> and B<lex>.  The syntax is a
617 pair of parentheses with a question mark as the first thing within
618 the parentheses.  The character after the question mark indicates
619 the extension.
620
621 The stability of these extensions varies widely.  Some have been
622 part of the core language for many years.  Others are experimental
623 and may change without warning or be completely removed.  Check
624 the documentation on an individual feature to verify its current
625 status.
626
627 A question mark was chosen for this and for the minimal-matching
628 construct because 1) question marks are rare in older regular
629 expressions, and 2) whenever you see one, you should stop and
630 "question" exactly what is going on.  That's psychology...
631
632 =over 10
633
634 =item C<(?#text)>
635 X<(?#)>
636
637 A comment.  The text is ignored.  If the C</x> modifier enables
638 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
639 the comment as soon as it sees a C<)>, so there is no way to put a literal
640 C<)> in the comment.
641
642 =item C<(?imsx-imsx)>
643 X<(?)>
644
645 One or more embedded pattern-match modifiers, to be turned on (or
646 turned off, if preceded by C<->) for the remainder of the pattern or
647 the remainder of the enclosing pattern group (if any). This is
648 particularly useful for dynamic patterns, such as those read in from a
649 configuration file, read in as an argument, are specified in a table
650 somewhere, etc.  Consider the case that some of which want to be case
651 sensitive and some do not.  The case insensitive ones need to include
652 merely C<(?i)> at the front of the pattern.  For example:
653
654     $pattern = "foobar";
655     if ( /$pattern/i ) { }
656
657     # more flexible:
658
659     $pattern = "(?i)foobar";
660     if ( /$pattern/ ) { }
661
662 These modifiers are restored at the end of the enclosing group. For example,
663
664     ( (?i) blah ) \s+ \1
665
666 will match a repeated (I<including the case>!) word C<blah> in any
667 case, assuming C<x> modifier, and no C<i> modifier outside this
668 group.
669
670 =item C<(?:pattern)>
671 X<(?:)>
672
673 =item C<(?imsx-imsx:pattern)>
674
675 This is for clustering, not capturing; it groups subexpressions like
676 "()", but doesn't make backreferences as "()" does.  So
677
678     @fields = split(/\b(?:a|b|c)\b/)
679
680 is like
681
682     @fields = split(/\b(a|b|c)\b/)
683
684 but doesn't spit out extra fields.  It's also cheaper not to capture
685 characters if you don't need to.
686
687 Any letters between C<?> and C<:> act as flags modifiers as with
688 C<(?imsx-imsx)>.  For example,
689
690     /(?s-i:more.*than).*million/i
691
692 is equivalent to the more verbose
693
694     /(?:(?s-i)more.*than).*million/i
695
696 =item Look-Around Assertions
697 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
698
699 Look-around assertions are zero width patterns which match a specific
700 pattern without including it in C<$&>. Positive assertions match when
701 their subpattern matches, negative assertions match when their subpattern
702 fails. Look-behind matches text up to the current match position,
703 look-ahead matches text following the current match position.
704
705 =over 4
706
707 =item C<(?=pattern)>
708 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
709
710 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
711 matches a word followed by a tab, without including the tab in C<$&>.
712
713 =item C<(?!pattern)>
714 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
715
716 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
717 matches any occurrence of "foo" that isn't followed by "bar".  Note
718 however that look-ahead and look-behind are NOT the same thing.  You cannot
719 use this for look-behind.
720
721 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
722 will not do what you want.  That's because the C<(?!foo)> is just saying that
723 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
724 match.  You would have to do something like C</(?!foo)...bar/> for that.   We
725 say "like" because there's the case of your "bar" not having three characters
726 before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
727 Sometimes it's still easier just to say:
728
729     if (/bar/ && $` !~ /foo$/)
730
731 For look-behind see below.
732
733 =item C<(?<=pattern)> C<\K>
734 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
735
736 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
737 matches a word that follows a tab, without including the tab in C<$&>.
738 Works only for fixed-width look-behind.
739
740 There is a special form of this construct, called C<\K>, which causes the
741 regex engine to "keep" everything it had matched prior to the C<\K> and
742 not include it in C<$&>. This effectively provides variable length
743 look-behind. The use of C<\K> inside of another look-around assertion
744 is allowed, but the behaviour is currently not well defined.
745
746 For various reasons C<\K> may be signifigantly more efficient than the
747 equivalent C<< (?<=...) >> construct, and it is especially useful in
748 situations where you want to efficiently remove something following
749 something else in a string. For instance
750
751   s/(foo)bar/$1/g;
752
753 can be rewritten as the much more efficient
754
755   s/foo\Kbar//g;
756
757 =item C<(?<!pattern)>
758 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
759
760 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
761 matches any occurrence of "foo" that does not follow "bar".  Works
762 only for fixed-width look-behind.
763
764 =back
765
766 =item C<(?'NAME'pattern)>
767
768 =item C<< (?<NAME>pattern) >>
769 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
770
771 A named capture buffer. Identical in every respect to normal capturing
772 parens C<()> but for the additional fact that C<%+> may be used after
773 a succesful match to refer to a named buffer. See C<perlvar> for more
774 details on the C<%+> hash.
775
776 If multiple distinct capture buffers have the same name then the
777 $+{NAME} will refer to the leftmost defined buffer in the match.
778
779 The forms C<(?'NAME'pattern)> and C<(?<NAME>pattern)> are equivalent.
780
781 B<NOTE:> While the notation of this construct is the same as the similar
782 function in .NET regexes, the behavior is not, in Perl the buffers are
783 numbered sequentially regardless of being named or not. Thus in the
784 pattern
785
786   /(x)(?<foo>y)(z)/
787
788 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
789 the opposite which is what a .NET regex hacker might expect.
790
791 Currently NAME is restricted to simple identifiers only.
792 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
793 its Unicode extension (see L<utf8>),
794 though it isn't extended by the locale (see L<perllocale>).
795
796 B<NOTE:> In order to make things easier for programmers with experience
797 with the Python or PCRE regex engines the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
798 maybe be used instead of C<< (?<NAME>pattern) >>; however this form does not
799 support the use of single quotes as a delimiter for the name. This is
800 only available in Perl 5.10 or later.
801
802 =item C<< \k<NAME> >>
803
804 =item C<< \k'NAME' >>
805
806 Named backreference. Similar to numeric backreferences, except that
807 the group is designated by name and not number. If multiple groups
808 have the same name then it refers to the leftmost defined group in
809 the current match.
810
811 It is an error to refer to a name not defined by a C<(?<NAME>)>
812 earlier in the pattern.
813
814 Both forms are equivalent.
815
816 B<NOTE:> In order to make things easier for programmers with experience
817 with the Python or PCRE regex engines the pattern C<< (?P=NAME) >>
818 maybe be used instead of C<< \k<NAME> >> in Perl 5.10 or later.
819
820 =item C<(?{ code })>
821 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
822
823 B<WARNING>: This extended regular expression feature is considered
824 experimental, and may be changed without notice. Code executed that
825 has side effects may not perform identically from version to version
826 due to the effect of future optimisations in the regex engine.
827
828 This zero-width assertion evaluates any embedded Perl code.  It
829 always succeeds, and its C<code> is not interpolated.  Currently,
830 the rules to determine where the C<code> ends are somewhat convoluted.
831
832 This feature can be used together with the special variable C<$^N> to
833 capture the results of submatches in variables without having to keep
834 track of the number of nested parentheses. For example:
835
836   $_ = "The brown fox jumps over the lazy dog";
837   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
838   print "color = $color, animal = $animal\n";
839
840 Inside the C<(?{...})> block, C<$_> refers to the string the regular
841 expression is matching against. You can also use C<pos()> to know what is
842 the current position of matching within this string.
843
844 The C<code> is properly scoped in the following sense: If the assertion
845 is backtracked (compare L<"Backtracking">), all changes introduced after
846 C<local>ization are undone, so that
847
848   $_ = 'a' x 8;
849   m<
850      (?{ $cnt = 0 })                    # Initialize $cnt.
851      (
852        a
853        (?{
854            local $cnt = $cnt + 1;       # Update $cnt, backtracking-safe.
855        })
856      )*
857      aaaa
858      (?{ $res = $cnt })                 # On success copy to non-localized
859                                         # location.
860    >x;
861
862 will set C<$res = 4>.  Note that after the match, $cnt returns to the globally
863 introduced value, because the scopes that restrict C<local> operators
864 are unwound.
865
866 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
867 switch.  If I<not> used in this way, the result of evaluation of
868 C<code> is put into the special variable C<$^R>.  This happens
869 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
870 inside the same regular expression.
871
872 The assignment to C<$^R> above is properly localized, so the old
873 value of C<$^R> is restored if the assertion is backtracked; compare
874 L<"Backtracking">.
875
876 Due to an unfortunate implementation issue, the Perl code contained in these
877 blocks is treated as a compile time closure that can have seemingly bizarre
878 consequences when used with lexically scoped variables inside of subroutines
879 or loops.  There are various workarounds for this, including simply using
880 global variables instead.  If you are using this construct and strange results
881 occur then check for the use of lexically scoped variables.
882
883 For reasons of security, this construct is forbidden if the regular
884 expression involves run-time interpolation of variables, unless the
885 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
886 variables contain results of C<qr//> operator (see
887 L<perlop/"qr/STRING/imosx">).
888
889 This restriction is because of the wide-spread and remarkably convenient
890 custom of using run-time determined strings as patterns.  For example:
891
892     $re = <>;
893     chomp $re;
894     $string =~ /$re/;
895
896 Before Perl knew how to execute interpolated code within a pattern,
897 this operation was completely safe from a security point of view,
898 although it could raise an exception from an illegal pattern.  If
899 you turn on the C<use re 'eval'>, though, it is no longer secure,
900 so you should only do so if you are also using taint checking.
901 Better yet, use the carefully constrained evaluation within a Safe
902 compartment.  See L<perlsec> for details about both these mechanisms.
903
904 Because perl's regex engine is not currently re-entrant, interpolated
905 code may not invoke the regex engine either directly with C<m//> or C<s///>),
906 or indirectly with functions such as C<split>.
907
908 =item C<(??{ code })>
909 X<(??{})>
910 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
911
912 B<WARNING>: This extended regular expression feature is considered
913 experimental, and may be changed without notice. Code executed that
914 has side effects may not perform identically from version to version
915 due to the effect of future optimisations in the regex engine.
916
917 This is a "postponed" regular subexpression.  The C<code> is evaluated
918 at run time, at the moment this subexpression may match.  The result
919 of evaluation is considered as a regular expression and matched as
920 if it were inserted instead of this construct.  Note that this means
921 that the contents of capture buffers defined inside an eval'ed pattern
922 are not available outside of the pattern, and vice versa, there is no
923 way for the inner pattern to refer to a capture buffer defined outside.
924 Thus,
925
926     ('a' x 100)=~/(??{'(.)' x 100})/
927
928 B<will> match, it will B<not> set $1.
929
930 The C<code> is not interpolated.  As before, the rules to determine
931 where the C<code> ends are currently somewhat convoluted.
932
933 The following pattern matches a parenthesized group:
934
935   $re = qr{
936              \(
937              (?:
938                 (?> [^()]+ )    # Non-parens without backtracking
939               |
940                 (??{ $re })     # Group with matching parens
941              )*
942              \)
943           }x;
944
945 See also C<(?PARNO)> for a different, more efficient way to accomplish
946 the same task.
947
948 Because perl's regex engine is not currently re-entrant, delayed
949 code may not invoke the regex engine either directly with C<m//> or C<s///>),
950 or indirectly with functions such as C<split>.
951
952 Recursing deeper than 50 times without consuming any input string will
953 result in a fatal error.  The maximum depth is compiled into perl, so
954 changing it requires a custom build.
955
956 =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
957 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
958 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
959 X<regex, relative recursion>
960
961 Similar to C<(??{ code })> except it does not involve compiling any code,
962 instead it treats the contents of a capture buffer as an independent
963 pattern that must match at the current position.  Capture buffers
964 contained by the pattern will have the value as determined by the
965 outermost recursion.
966
967 PARNO is a sequence of digits (not starting with 0) whose value reflects
968 the paren-number of the capture buffer to recurse to. C<(?R)> recurses to
969 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
970 C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
971 to be relative, with negative numbers indicating preceding capture buffers
972 and positive ones following. Thus C<(?-1)> refers to the most recently
973 declared buffer, and C<(?+1)> indicates the next buffer to be declared.
974 Note that the counting for relative recursion differs from that of
975 relative backreferences, in that with recursion unclosed buffers B<are>
976 included.
977
978 The following pattern matches a function foo() which may contain
979 balanced parentheses as the argument.
980
981   $re = qr{ (                    # paren group 1 (full function)
982               foo
983               (                  # paren group 2 (parens)
984                 \(
985                   (              # paren group 3 (contents of parens)
986                   (?:
987                    (?> [^()]+ )  # Non-parens without backtracking
988                   |
989                    (?2)          # Recurse to start of paren group 2
990                   )*
991                   )
992                 \)
993               )
994             )
995           }x;
996
997 If the pattern was used as follows
998
999     'foo(bar(baz)+baz(bop))'=~/$re/
1000         and print "\$1 = $1\n",
1001                   "\$2 = $2\n",
1002                   "\$3 = $3\n";
1003
1004 the output produced should be the following:
1005
1006     $1 = foo(bar(baz)+baz(bop))
1007     $2 = (bar(baz)+baz(bop))
1008     $3 = bar(baz)+baz(bop)
1009
1010 If there is no corresponding capture buffer defined, then it is a
1011 fatal error.  Recursing deeper than 50 times without consuming any input
1012 string will also result in a fatal error.  The maximum depth is compiled
1013 into perl, so changing it requires a custom build.
1014
1015 The following shows how using negative indexing can make it
1016 easier to embed recursive patterns inside of a C<qr//> construct
1017 for later use:
1018
1019     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1020     if (/foo $parens \s+ + \s+ bar $parens/x) {
1021        # do something here...
1022     }
1023
1024 B<Note> that this pattern does not behave the same way as the equivalent
1025 PCRE or Python construct of the same form. In perl you can backtrack into
1026 a recursed group, in PCRE and Python the recursed into group is treated
1027 as atomic. Also, modifiers are resolved at compile time, so constructs
1028 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1029 be processed.
1030
1031 =item C<(?&NAME)>
1032 X<(?&NAME)>
1033
1034 Recurse to a named subpattern. Identical to (?PARNO) except that the
1035 parenthesis to recurse to is determined by name. If multiple parens have
1036 the same name, then it recurses to the leftmost.
1037
1038 It is an error to refer to a name that is not declared somewhere in the
1039 pattern.
1040
1041 B<NOTE:> In order to make things easier for programmers with experience
1042 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1043 maybe be used instead of C<< (?&NAME) >> as of Perl 5.10.
1044
1045 =item C<(?(condition)yes-pattern|no-pattern)>
1046 X<(?()>
1047
1048 =item C<(?(condition)yes-pattern)>
1049
1050 Conditional expression.  C<(condition)> should be either an integer in
1051 parentheses (which is valid if the corresponding pair of parentheses
1052 matched), a look-ahead/look-behind/evaluate zero-width assertion, a
1053 name in angle brackets or single quotes (which is valid if a buffer
1054 with the given name matched), or the special symbol (R) (true when
1055 evaluated inside of recursion or eval). Additionally the R may be
1056 followed by a number, (which will be true when evaluated when recursing
1057 inside of the appropriate group), or by C<&NAME>, in which case it will
1058 be true only when evaluated during recursion in the named group.
1059
1060 Here's a summary of the possible predicates:
1061
1062 =over 4
1063
1064 =item (1) (2) ...
1065
1066 Checks if the numbered capturing buffer has matched something.
1067
1068 =item (<NAME>) ('NAME')
1069
1070 Checks if a buffer with the given name has matched something.
1071
1072 =item (?{ CODE })
1073
1074 Treats the code block as the condition.
1075
1076 =item (R)
1077
1078 Checks if the expression has been evaluated inside of recursion.
1079
1080 =item (R1) (R2) ...
1081
1082 Checks if the expression has been evaluated while executing directly
1083 inside of the n-th capture group. This check is the regex equivalent of
1084
1085   if ((caller(0))[3] eq 'subname') { ... }
1086
1087 In other words, it does not check the full recursion stack.
1088
1089 =item (R&NAME)
1090
1091 Similar to C<(R1)>, this predicate checks to see if we're executing
1092 directly inside of the leftmost group with a given name (this is the same
1093 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1094 stack, but only the name of the innermost active recursion.
1095
1096 =item (DEFINE)
1097
1098 In this case, the yes-pattern is never directly executed, and no
1099 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1100 See below for details.
1101
1102 =back
1103
1104 For example:
1105
1106     m{ ( \( )?
1107        [^()]+
1108        (?(1) \) )
1109      }x
1110
1111 matches a chunk of non-parentheses, possibly included in parentheses
1112 themselves.
1113
1114 A special form is the C<(DEFINE)> predicate, which never executes directly
1115 its yes-pattern, and does not allow a no-pattern. This allows to define
1116 subpatterns which will be executed only by using the recursion mechanism.
1117 This way, you can define a set of regular expression rules that can be
1118 bundled into any pattern you choose.
1119
1120 It is recommended that for this usage you put the DEFINE block at the
1121 end of the pattern, and that you name any subpatterns defined within it.
1122
1123 Also, it's worth noting that patterns defined this way probably will
1124 not be as efficient, as the optimiser is not very clever about
1125 handling them.
1126
1127 An example of how this might be used is as follows:
1128
1129   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1130    (?(DEFINE)
1131      (?<NAME_PAT>....)
1132      (?<ADRESS_PAT>....)
1133    )/x
1134
1135 Note that capture buffers matched inside of recursion are not accessible
1136 after the recursion returns, so the extra layer of capturing buffers are
1137 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1138 C<$+{NAME}> would be.
1139
1140 =item C<< (?>pattern) >>
1141 X<backtrack> X<backtracking> X<atomic> X<possessive>
1142
1143 An "independent" subexpression, one which matches the substring
1144 that a I<standalone> C<pattern> would match if anchored at the given
1145 position, and it matches I<nothing other than this substring>.  This
1146 construct is useful for optimizations of what would otherwise be
1147 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1148 It may also be useful in places where the "grab all you can, and do not
1149 give anything back" semantic is desirable.
1150
1151 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1152 (anchored at the beginning of string, as above) will match I<all>
1153 characters C<a> at the beginning of string, leaving no C<a> for
1154 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1155 since the match of the subgroup C<a*> is influenced by the following
1156 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1157 C<a*ab> will match fewer characters than a standalone C<a*>, since
1158 this makes the tail match.
1159
1160 An effect similar to C<< (?>pattern) >> may be achieved by writing
1161 C<(?=(pattern))\1>.  This matches the same substring as a standalone
1162 C<a+>, and the following C<\1> eats the matched string; it therefore
1163 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1164 (The difference between these two constructs is that the second one
1165 uses a capturing group, thus shifting ordinals of backreferences
1166 in the rest of a regular expression.)
1167
1168 Consider this pattern:
1169
1170     m{ \(
1171           (
1172             [^()]+              # x+
1173           |
1174             \( [^()]* \)
1175           )+
1176        \)
1177      }x
1178
1179 That will efficiently match a nonempty group with matching parentheses
1180 two levels deep or less.  However, if there is no such group, it
1181 will take virtually forever on a long string.  That's because there
1182 are so many different ways to split a long string into several
1183 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1184 to a subpattern of the above pattern.  Consider how the pattern
1185 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1186 seconds, but that each extra letter doubles this time.  This
1187 exponential performance will make it appear that your program has
1188 hung.  However, a tiny change to this pattern
1189
1190     m{ \(
1191           (
1192             (?> [^()]+ )        # change x+ above to (?> x+ )
1193           |
1194             \( [^()]* \)
1195           )+
1196        \)
1197      }x
1198
1199 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1200 this yourself would be a productive exercise), but finishes in a fourth
1201 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1202 however, that this pattern currently triggers a warning message under
1203 the C<use warnings> pragma or B<-w> switch saying it
1204 C<"matches null string many times in regex">.
1205
1206 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1207 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1208 This was only 4 times slower on a string with 1000000 C<a>s.
1209
1210 The "grab all you can, and do not give anything back" semantic is desirable
1211 in many situations where on the first sight a simple C<()*> looks like
1212 the correct solution.  Suppose we parse text with comments being delimited
1213 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1214 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1215 the comment delimiter, because it may "give up" some whitespace if
1216 the remainder of the pattern can be made to match that way.  The correct
1217 answer is either one of these:
1218
1219     (?>#[ \t]*)
1220     #[ \t]*(?![ \t])
1221
1222 For example, to grab non-empty comments into $1, one should use either
1223 one of these:
1224
1225     / (?> \# [ \t]* ) (        .+ ) /x;
1226     /     \# [ \t]*   ( [^ \t] .* ) /x;
1227
1228 Which one you pick depends on which of these expressions better reflects
1229 the above specification of comments.
1230
1231 In some literature this construct is called "atomic matching" or
1232 "possessive matching".
1233
1234 Possessive quantifiers are equivalent to putting the item they are applied
1235 to inside of one of these constructs. The following equivalences apply:
1236
1237     Quantifier Form     Bracketing Form
1238     ---------------     ---------------
1239     PAT*+               (?>PAT*)
1240     PAT++               (?>PAT+)
1241     PAT?+               (?>PAT?)
1242     PAT{min,max}+       (?>PAT{min,max})
1243
1244 =back
1245
1246 =head2 Special Backtracking Control Verbs
1247
1248 B<WARNING:> These patterns are experimental and subject to change or
1249 removal in a future version of perl. Their usage in production code should
1250 be noted to avoid problems during upgrades.
1251
1252 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1253 otherwise stated the ARG argument is optional; in some cases, it is
1254 forbidden.
1255
1256 Any pattern containing a special backtracking verb that allows an argument
1257 has the special behaviour that when executed it sets the current packages'
1258 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1259 rules apply:
1260
1261 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1262 verb pattern, if the verb was involved in the failure of the match. If the
1263 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1264 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1265 none. Also, the C<$REGMARK> variable will be set to FALSE.
1266
1267 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1268 the C<$REGMARK> variable will be set to the name of the last
1269 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1270 C<(*MARK:NAME)> verb below for more details.
1271
1272 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1273 and most other regex related variables. They are not local to a scope, nor
1274 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1275 Use C<local> to localize changes to them to a specific scope if necessary.
1276
1277 If a pattern does not contain a special backtracking verb that allows an
1278 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1279
1280 =over 4
1281
1282 =item Verbs that take an argument
1283
1284 =over 4
1285
1286 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1287 X<(*PRUNE)> X<(*PRUNE:NAME)> X<\v>
1288
1289 This zero-width pattern prunes the backtracking tree at the current point
1290 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1291 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1292 A may backtrack as necessary to match. Once it is reached, matching
1293 continues in B, which may also backtrack as necessary; however, should B
1294 not match, then no further backtracking will take place, and the pattern
1295 will fail outright at the current starting position.
1296
1297 As a shortcut, X<\v> is exactly equivalent to C<(*PRUNE)>.
1298
1299 The following example counts all the possible matching strings in a
1300 pattern (without actually matching any of them).
1301
1302     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1303     print "Count=$count\n";
1304
1305 which produces:
1306
1307     aaab
1308     aaa
1309     aa
1310     a
1311     aab
1312     aa
1313     a
1314     ab
1315     a
1316     Count=9
1317
1318 If we add a C<(*PRUNE)> before the count like the following
1319
1320     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1321     print "Count=$count\n";
1322
1323 we prevent backtracking and find the count of the longest matching
1324 at each matching startpoint like so:
1325
1326     aaab
1327     aab
1328     ab
1329     Count=3
1330
1331 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1332
1333 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1334 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1335 replaced with a C<< (?>pattern) >> with no functional difference; however,
1336 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1337 C<< (?>pattern) >> alone.
1338
1339
1340 =item C<(*SKIP)> C<(*SKIP:NAME)>
1341 X<(*SKIP)>
1342
1343 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1344 failure it also signifies that whatever text that was matched leading up
1345 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1346 of this pattern. This effectively means that the regex engine "skips" forward
1347 to this position on failure and tries to match again, (assuming that
1348 there is sufficient room to match).
1349
1350 As a shortcut X<\V> is exactly equivalent to C<(*SKIP)>.
1351
1352 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1353 C<(*MARK:NAME)> was encountered while matching, then it is that position
1354 which is used as the "skip point". If no C<(*MARK)> of that name was
1355 encountered, then the C<(*SKIP)> operator has no effect. When used
1356 without a name the "skip point" is where the match point was when
1357 executing the (*SKIP) pattern.
1358
1359 Compare the following to the examples in C<(*PRUNE)>, note the string
1360 is twice as long:
1361
1362     'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1363     print "Count=$count\n";
1364
1365 outputs
1366
1367     aaab
1368     aaab
1369     Count=2
1370
1371 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1372 executed, the next startpoint will be where the cursor was when the
1373 C<(*SKIP)> was executed.
1374
1375 =item C<(*MARK:NAME)> C<(*:NAME)>
1376 X<(*MARK)> C<(*MARK:NAME)> C<(*:NAME)>
1377
1378 This zero-width pattern can be used to mark the point reached in a string
1379 when a certain part of the pattern has been successfully matched. This
1380 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1381 forward to that point if backtracked into on failure. Any number of
1382 C<(*MARK)> patterns are allowed, and the NAME portion is optional and may
1383 be duplicated.
1384
1385 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1386 can be used to "label" a pattern branch, so that after matching, the
1387 program can determine which branches of the pattern were involved in the
1388 match.
1389
1390 When a match is successful, the C<$REGMARK> variable will be set to the
1391 name of the most recently executed C<(*MARK:NAME)> that was involved
1392 in the match.
1393
1394 This can be used to determine which branch of a pattern was matched
1395 without using a seperate capture buffer for each branch, which in turn
1396 can result in a performance improvement, as perl cannot optimize
1397 C</(?:(x)|(y)|(z))/> as efficiently as something like
1398 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1399
1400 When a match has failed, and unless another verb has been involved in
1401 failing the match and has provided its own name to use, the C<$REGERROR>
1402 variable will be set to the name of the most recently executed
1403 C<(*MARK:NAME)>.
1404
1405 See C<(*SKIP)> for more details.
1406
1407 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1408
1409 =item C<(*THEN)> C<(*THEN:NAME)>
1410
1411 This is similar to the "cut group" operator C<::> from Perl6. Like
1412 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1413 failure, it causes the regex engine to try the next alternation in the
1414 innermost enclosing group (capturing or otherwise).
1415
1416 Its name comes from the observation that this operation combined with the
1417 alternation operator (C<|>) can be used to create what is essentially a
1418 pattern-based if/then/else block:
1419
1420   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1421
1422 Note that if this operator is used and NOT inside of an alternation then
1423 it acts exactly like the C<(*PRUNE)> operator.
1424
1425   / A (*PRUNE) B /
1426
1427 is the same as
1428
1429   / A (*THEN) B /
1430
1431 but
1432
1433   / ( A (*THEN) B | C (*THEN) D ) /
1434
1435 is not the same as
1436
1437   / ( A (*PRUNE) B | C (*PRUNE) D ) /
1438
1439 as after matching the A but failing on the B the C<(*THEN)> verb will
1440 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1441
1442 =item C<(*COMMIT)>
1443 X<(*COMMIT)>
1444
1445 This is the Perl6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1446 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1447 into on failure it causes the match to fail outright. No further attempts
1448 to find a valid match by advancing the start pointer will occur again.
1449 For example,
1450
1451     'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1452     print "Count=$count\n";
1453
1454 outputs
1455
1456     aaab
1457     Count=1
1458
1459 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1460 does not match, the regex engine will not try any further matching on the
1461 rest of the string.
1462
1463 =back
1464
1465 =item Verbs without an argument
1466
1467 =over 4
1468
1469 =item C<(*FAIL)> C<(*F)>
1470 X<(*FAIL)> X<(*F)>
1471
1472 This pattern matches nothing and always fails. It can be used to force the
1473 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1474 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1475
1476 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1477
1478 =item C<(*ACCEPT)>
1479 X<(*ACCEPT)>
1480
1481 B<WARNING:> This feature is highly experimental. It is not recommended
1482 for production code.
1483
1484 This pattern matches nothing and causes the end of successful matching at
1485 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1486 whether there is actually more to match in the string. When inside of a
1487 nested pattern, such as recursion or a dynamically generated subbpattern
1488 via C<(??{})>, only the innermost pattern is ended immediately.
1489
1490 If the C<(*ACCEPT)> is inside of capturing buffers then the buffers are
1491 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1492 For instance:
1493
1494   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1495
1496 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1497 be set. If another branch in the inner parens were matched, such as in the
1498 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1499
1500 =back
1501
1502 =back
1503
1504 =head2 Backtracking
1505 X<backtrack> X<backtracking>
1506
1507 NOTE: This section presents an abstract approximation of regular
1508 expression behavior.  For a more rigorous (and complicated) view of
1509 the rules involved in selecting a match among possible alternatives,
1510 see L<Combining pieces together>.
1511
1512 A fundamental feature of regular expression matching involves the
1513 notion called I<backtracking>, which is currently used (when needed)
1514 by all regular expression quantifiers, namely C<*>, C<*?>, C<+>,
1515 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
1516 internally, but the general principle outlined here is valid.
1517
1518 For a regular expression to match, the I<entire> regular expression must
1519 match, not just part of it.  So if the beginning of a pattern containing a
1520 quantifier succeeds in a way that causes later parts in the pattern to
1521 fail, the matching engine backs up and recalculates the beginning
1522 part--that's why it's called backtracking.
1523
1524 Here is an example of backtracking:  Let's say you want to find the
1525 word following "foo" in the string "Food is on the foo table.":
1526
1527     $_ = "Food is on the foo table.";
1528     if ( /\b(foo)\s+(\w+)/i ) {
1529         print "$2 follows $1.\n";
1530     }
1531
1532 When the match runs, the first part of the regular expression (C<\b(foo)>)
1533 finds a possible match right at the beginning of the string, and loads up
1534 $1 with "Foo".  However, as soon as the matching engine sees that there's
1535 no whitespace following the "Foo" that it had saved in $1, it realizes its
1536 mistake and starts over again one character after where it had the
1537 tentative match.  This time it goes all the way until the next occurrence
1538 of "foo". The complete regular expression matches this time, and you get
1539 the expected output of "table follows foo."
1540
1541 Sometimes minimal matching can help a lot.  Imagine you'd like to match
1542 everything between "foo" and "bar".  Initially, you write something
1543 like this:
1544
1545     $_ =  "The food is under the bar in the barn.";
1546     if ( /foo(.*)bar/ ) {
1547         print "got <$1>\n";
1548     }
1549
1550 Which perhaps unexpectedly yields:
1551
1552   got <d is under the bar in the >
1553
1554 That's because C<.*> was greedy, so you get everything between the
1555 I<first> "foo" and the I<last> "bar".  Here it's more effective
1556 to use minimal matching to make sure you get the text between a "foo"
1557 and the first "bar" thereafter.
1558
1559     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
1560   got <d is under the >
1561
1562 Here's another example: let's say you'd like to match a number at the end
1563 of a string, and you also want to keep the preceding part of the match.
1564 So you write this:
1565
1566     $_ = "I have 2 numbers: 53147";
1567     if ( /(.*)(\d*)/ ) {                                # Wrong!
1568         print "Beginning is <$1>, number is <$2>.\n";
1569     }
1570
1571 That won't work at all, because C<.*> was greedy and gobbled up the
1572 whole string. As C<\d*> can match on an empty string the complete
1573 regular expression matched successfully.
1574
1575     Beginning is <I have 2 numbers: 53147>, number is <>.
1576
1577 Here are some variants, most of which don't work:
1578
1579     $_ = "I have 2 numbers: 53147";
1580     @pats = qw{
1581         (.*)(\d*)
1582         (.*)(\d+)
1583         (.*?)(\d*)
1584         (.*?)(\d+)
1585         (.*)(\d+)$
1586         (.*?)(\d+)$
1587         (.*)\b(\d+)$
1588         (.*\D)(\d+)$
1589     };
1590
1591     for $pat (@pats) {
1592         printf "%-12s ", $pat;
1593         if ( /$pat/ ) {
1594             print "<$1> <$2>\n";
1595         } else {
1596             print "FAIL\n";
1597         }
1598     }
1599
1600 That will print out:
1601
1602     (.*)(\d*)    <I have 2 numbers: 53147> <>
1603     (.*)(\d+)    <I have 2 numbers: 5314> <7>
1604     (.*?)(\d*)   <> <>
1605     (.*?)(\d+)   <I have > <2>
1606     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
1607     (.*?)(\d+)$  <I have 2 numbers: > <53147>
1608     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
1609     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
1610
1611 As you see, this can be a bit tricky.  It's important to realize that a
1612 regular expression is merely a set of assertions that gives a definition
1613 of success.  There may be 0, 1, or several different ways that the
1614 definition might succeed against a particular string.  And if there are
1615 multiple ways it might succeed, you need to understand backtracking to
1616 know which variety of success you will achieve.
1617
1618 When using look-ahead assertions and negations, this can all get even
1619 trickier.  Imagine you'd like to find a sequence of non-digits not
1620 followed by "123".  You might try to write that as
1621
1622     $_ = "ABC123";
1623     if ( /^\D*(?!123)/ ) {              # Wrong!
1624         print "Yup, no 123 in $_\n";
1625     }
1626
1627 But that isn't going to match; at least, not the way you're hoping.  It
1628 claims that there is no 123 in the string.  Here's a clearer picture of
1629 why that pattern matches, contrary to popular expectations:
1630
1631     $x = 'ABC123';
1632     $y = 'ABC445';
1633
1634     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
1635     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
1636
1637     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
1638     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
1639
1640 This prints
1641
1642     2: got ABC
1643     3: got AB
1644     4: got ABC
1645
1646 You might have expected test 3 to fail because it seems to a more
1647 general purpose version of test 1.  The important difference between
1648 them is that test 3 contains a quantifier (C<\D*>) and so can use
1649 backtracking, whereas test 1 will not.  What's happening is
1650 that you've asked "Is it true that at the start of $x, following 0 or more
1651 non-digits, you have something that's not 123?"  If the pattern matcher had
1652 let C<\D*> expand to "ABC", this would have caused the whole pattern to
1653 fail.
1654
1655 The search engine will initially match C<\D*> with "ABC".  Then it will
1656 try to match C<(?!123> with "123", which fails.  But because
1657 a quantifier (C<\D*>) has been used in the regular expression, the
1658 search engine can backtrack and retry the match differently
1659 in the hope of matching the complete regular expression.
1660
1661 The pattern really, I<really> wants to succeed, so it uses the
1662 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
1663 time.  Now there's indeed something following "AB" that is not
1664 "123".  It's "C123", which suffices.
1665
1666 We can deal with this by using both an assertion and a negation.
1667 We'll say that the first part in $1 must be followed both by a digit
1668 and by something that's not "123".  Remember that the look-aheads
1669 are zero-width expressions--they only look, but don't consume any
1670 of the string in their match.  So rewriting this way produces what
1671 you'd expect; that is, case 5 will fail, but case 6 succeeds:
1672
1673     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
1674     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
1675
1676     6: got ABC
1677
1678 In other words, the two zero-width assertions next to each other work as though
1679 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
1680 matches only if you're at the beginning of the line AND the end of the
1681 line simultaneously.  The deeper underlying truth is that juxtaposition in
1682 regular expressions always means AND, except when you write an explicit OR
1683 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
1684 although the attempted matches are made at different positions because "a"
1685 is not a zero-width assertion, but a one-width assertion.
1686
1687 B<WARNING>: particularly complicated regular expressions can take
1688 exponential time to solve because of the immense number of possible
1689 ways they can use backtracking to try match.  For example, without
1690 internal optimizations done by the regular expression engine, this will
1691 take a painfully long time to run:
1692
1693     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
1694
1695 And if you used C<*>'s in the internal groups instead of limiting them
1696 to 0 through 5 matches, then it would take forever--or until you ran
1697 out of stack space.  Moreover, these internal optimizations are not
1698 always applicable.  For example, if you put C<{0,5}> instead of C<*>
1699 on the external group, no current optimization is applicable, and the
1700 match takes a long time to finish.
1701
1702 A powerful tool for optimizing such beasts is what is known as an
1703 "independent group",
1704 which does not backtrack (see L<C<< (?>pattern) >>>).  Note also that
1705 zero-length look-ahead/look-behind assertions will not backtrack to make
1706 the tail match, since they are in "logical" context: only
1707 whether they match is considered relevant.  For an example
1708 where side-effects of look-ahead I<might> have influenced the
1709 following match, see L<C<< (?>pattern) >>>.
1710
1711 =head2 Version 8 Regular Expressions
1712 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
1713
1714 In case you're not familiar with the "regular" Version 8 regex
1715 routines, here are the pattern-matching rules not described above.
1716
1717 Any single character matches itself, unless it is a I<metacharacter>
1718 with a special meaning described here or above.  You can cause
1719 characters that normally function as metacharacters to be interpreted
1720 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
1721 character; "\\" matches a "\").  A series of characters matches that
1722 series of characters in the target string, so the pattern C<blurfl>
1723 would match "blurfl" in the target string.
1724
1725 You can specify a character class, by enclosing a list of characters
1726 in C<[]>, which will match any character from the list.  If the
1727 first character after the "[" is "^", the class matches any character not
1728 in the list.  Within a list, the "-" character specifies a
1729 range, so that C<a-z> represents all characters between "a" and "z",
1730 inclusive.  If you want either "-" or "]" itself to be a member of a
1731 class, put it at the start of the list (possibly after a "^"), or
1732 escape it with a backslash.  "-" is also taken literally when it is
1733 at the end of the list, just before the closing "]".  (The
1734 following all specify the same class of three characters: C<[-az]>,
1735 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
1736 specifies a class containing twenty-six characters, even on EBCDIC-based
1737 character sets.)  Also, if you try to use the character
1738 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
1739 a range, the "-" is understood literally.
1740
1741 Note also that the whole range idea is rather unportable between
1742 character sets--and even within character sets they may cause results
1743 you probably didn't expect.  A sound principle is to use only ranges
1744 that begin from and end at either alphabets of equal case ([a-e],
1745 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
1746 spell out the character sets in full.
1747
1748 Characters may be specified using a metacharacter syntax much like that
1749 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
1750 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
1751 of octal digits, matches the character whose coded character set value
1752 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
1753 matches the character whose numeric value is I<nn>. The expression \cI<x>
1754 matches the character control-I<x>.  Finally, the "." metacharacter
1755 matches any character except "\n" (unless you use C</s>).
1756
1757 You can specify a series of alternatives for a pattern using "|" to
1758 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
1759 or "foe" in the target string (as would C<f(e|i|o)e>).  The
1760 first alternative includes everything from the last pattern delimiter
1761 ("(", "[", or the beginning of the pattern) up to the first "|", and
1762 the last alternative contains everything from the last "|" to the next
1763 pattern delimiter.  That's why it's common practice to include
1764 alternatives in parentheses: to minimize confusion about where they
1765 start and end.
1766
1767 Alternatives are tried from left to right, so the first
1768 alternative found for which the entire expression matches, is the one that
1769 is chosen. This means that alternatives are not necessarily greedy. For
1770 example: when matching C<foo|foot> against "barefoot", only the "foo"
1771 part will match, as that is the first alternative tried, and it successfully
1772 matches the target string. (This might not seem important, but it is
1773 important when you are capturing matched text using parentheses.)
1774
1775 Also remember that "|" is interpreted as a literal within square brackets,
1776 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
1777
1778 Within a pattern, you may designate subpatterns for later reference
1779 by enclosing them in parentheses, and you may refer back to the
1780 I<n>th subpattern later in the pattern using the metacharacter
1781 \I<n>.  Subpatterns are numbered based on the left to right order
1782 of their opening parenthesis.  A backreference matches whatever
1783 actually matched the subpattern in the string being examined, not
1784 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\1\d*> will
1785 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
1786 1 matched "0x", even though the rule C<0|0x> could potentially match
1787 the leading 0 in the second number.
1788
1789 =head2 Warning on \1 vs $1
1790
1791 Some people get too used to writing things like:
1792
1793     $pattern =~ s/(\W)/\\\1/g;
1794
1795 This is grandfathered for the RHS of a substitute to avoid shocking the
1796 B<sed> addicts, but it's a dirty habit to get into.  That's because in
1797 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
1798 the usual double-quoted string means a control-A.  The customary Unix
1799 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
1800 of doing that, you get yourself into trouble if you then add an C</e>
1801 modifier.
1802
1803     s/(\d+)/ \1 + 1 /eg;        # causes warning under -w
1804
1805 Or if you try to do
1806
1807     s/(\d+)/\1000/;
1808
1809 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
1810 C<${1}000>.  The operation of interpolation should not be confused
1811 with the operation of matching a backreference.  Certainly they mean two
1812 different things on the I<left> side of the C<s///>.
1813
1814 =head2 Repeated patterns matching zero-length substring
1815
1816 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
1817
1818 Regular expressions provide a terse and powerful programming language.  As
1819 with most other power tools, power comes together with the ability
1820 to wreak havoc.
1821
1822 A common abuse of this power stems from the ability to make infinite
1823 loops using regular expressions, with something as innocuous as:
1824
1825     'foo' =~ m{ ( o? )* }x;
1826
1827 The C<o?> can match at the beginning of C<'foo'>, and since the position
1828 in the string is not moved by the match, C<o?> would match again and again
1829 because of the C<*> modifier.  Another common way to create a similar cycle
1830 is with the looping modifier C<//g>:
1831
1832     @matches = ( 'foo' =~ m{ o? }xg );
1833
1834 or
1835
1836     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1837
1838 or the loop implied by split().
1839
1840 However, long experience has shown that many programming tasks may
1841 be significantly simplified by using repeated subexpressions that
1842 may match zero-length substrings.  Here's a simple example being:
1843
1844     @chars = split //, $string;           # // is not magic in split
1845     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1846
1847 Thus Perl allows such constructs, by I<forcefully breaking
1848 the infinite loop>.  The rules for this are different for lower-level
1849 loops given by the greedy modifiers C<*+{}>, and for higher-level
1850 ones like the C</g> modifier or split() operator.
1851
1852 The lower-level loops are I<interrupted> (that is, the loop is
1853 broken) when Perl detects that a repeated expression matched a
1854 zero-length substring.   Thus
1855
1856    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1857
1858 is made equivalent to
1859
1860    m{   (?: NON_ZERO_LENGTH )*
1861       |
1862         (?: ZERO_LENGTH )?
1863     }x;
1864
1865 The higher level-loops preserve an additional state between iterations:
1866 whether the last match was zero-length.  To break the loop, the following
1867 match after a zero-length match is prohibited to have a length of zero.
1868 This prohibition interacts with backtracking (see L<"Backtracking">),
1869 and so the I<second best> match is chosen if the I<best> match is of
1870 zero length.
1871
1872 For example:
1873
1874     $_ = 'bar';
1875     s/\w??/<$&>/g;
1876
1877 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
1878 match given by non-greedy C<??> is the zero-length match, and the I<second
1879 best> match is what is matched by C<\w>.  Thus zero-length matches
1880 alternate with one-character-long matches.
1881
1882 Similarly, for repeated C<m/()/g> the second-best match is the match at the
1883 position one notch further in the string.
1884
1885 The additional state of being I<matched with zero-length> is associated with
1886 the matched string, and is reset by each assignment to pos().
1887 Zero-length matches at the end of the previous match are ignored
1888 during C<split>.
1889
1890 =head2 Combining pieces together
1891
1892 Each of the elementary pieces of regular expressions which were described
1893 before (such as C<ab> or C<\Z>) could match at most one substring
1894 at the given position of the input string.  However, in a typical regular
1895 expression these elementary pieces are combined into more complicated
1896 patterns using combining operators C<ST>, C<S|T>, C<S*> etc
1897 (in these examples C<S> and C<T> are regular subexpressions).
1898
1899 Such combinations can include alternatives, leading to a problem of choice:
1900 if we match a regular expression C<a|ab> against C<"abc">, will it match
1901 substring C<"a"> or C<"ab">?  One way to describe which substring is
1902 actually matched is the concept of backtracking (see L<"Backtracking">).
1903 However, this description is too low-level and makes you think
1904 in terms of a particular implementation.
1905
1906 Another description starts with notions of "better"/"worse".  All the
1907 substrings which may be matched by the given regular expression can be
1908 sorted from the "best" match to the "worst" match, and it is the "best"
1909 match which is chosen.  This substitutes the question of "what is chosen?"
1910 by the question of "which matches are better, and which are worse?".
1911
1912 Again, for elementary pieces there is no such question, since at most
1913 one match at a given position is possible.  This section describes the
1914 notion of better/worse for combining operators.  In the description
1915 below C<S> and C<T> are regular subexpressions.
1916
1917 =over 4
1918
1919 =item C<ST>
1920
1921 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
1922 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
1923 which can be matched by C<T>.
1924
1925 If C<A> is better match for C<S> than C<A'>, C<AB> is a better
1926 match than C<A'B'>.
1927
1928 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
1929 C<B> is better match for C<T> than C<B'>.
1930
1931 =item C<S|T>
1932
1933 When C<S> can match, it is a better match than when only C<T> can match.
1934
1935 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
1936 two matches for C<T>.
1937
1938 =item C<S{REPEAT_COUNT}>
1939
1940 Matches as C<SSS...S> (repeated as many times as necessary).
1941
1942 =item C<S{min,max}>
1943
1944 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
1945
1946 =item C<S{min,max}?>
1947
1948 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
1949
1950 =item C<S?>, C<S*>, C<S+>
1951
1952 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
1953
1954 =item C<S??>, C<S*?>, C<S+?>
1955
1956 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
1957
1958 =item C<< (?>S) >>
1959
1960 Matches the best match for C<S> and only that.
1961
1962 =item C<(?=S)>, C<(?<=S)>
1963
1964 Only the best match for C<S> is considered.  (This is important only if
1965 C<S> has capturing parentheses, and backreferences are used somewhere
1966 else in the whole regular expression.)
1967
1968 =item C<(?!S)>, C<(?<!S)>
1969
1970 For this grouping operator there is no need to describe the ordering, since
1971 only whether or not C<S> can match is important.
1972
1973 =item C<(??{ EXPR })>, C<(?PARNO)>
1974
1975 The ordering is the same as for the regular expression which is
1976 the result of EXPR, or the pattern contained by capture buffer PARNO.
1977
1978 =item C<(?(condition)yes-pattern|no-pattern)>
1979
1980 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
1981 already determined.  The ordering of the matches is the same as for the
1982 chosen subexpression.
1983
1984 =back
1985
1986 The above recipes describe the ordering of matches I<at a given position>.
1987 One more rule is needed to understand how a match is determined for the
1988 whole regular expression: a match at an earlier position is always better
1989 than a match at a later position.
1990
1991 =head2 Creating custom RE engines
1992
1993 Overloaded constants (see L<overload>) provide a simple way to extend
1994 the functionality of the RE engine.
1995
1996 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
1997 matches at boundary between whitespace characters and non-whitespace
1998 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
1999 at these positions, so we want to have each C<\Y|> in the place of the
2000 more complicated version.  We can create a module C<customre> to do
2001 this:
2002
2003     package customre;
2004     use overload;
2005
2006     sub import {
2007       shift;
2008       die "No argument to customre::import allowed" if @_;
2009       overload::constant 'qr' => \&convert;
2010     }
2011
2012     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2013
2014     # We must also take care of not escaping the legitimate \\Y|
2015     # sequence, hence the presence of '\\' in the conversion rules.
2016     my %rules = ( '\\' => '\\\\',
2017                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2018     sub convert {
2019       my $re = shift;
2020       $re =~ s{
2021                 \\ ( \\ | Y . )
2022               }
2023               { $rules{$1} or invalid($re,$1) }sgex;
2024       return $re;
2025     }
2026
2027 Now C<use customre> enables the new escape in constant regular
2028 expressions, i.e., those without any runtime variable interpolations.
2029 As documented in L<overload>, this conversion will work only over
2030 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2031 part of this regular expression needs to be converted explicitly
2032 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2033
2034     use customre;
2035     $re = <>;
2036     chomp $re;
2037     $re = customre::convert $re;
2038     /\Y|$re\Y|/;
2039
2040 =head1 PCRE/Python Support
2041
2042 As of Perl 5.10 Perl supports several Python/PCRE specific extensions
2043 to the regex syntax. While Perl programmers are encouraged to use the
2044 Perl specific syntax, the following are legal in Perl 5.10:
2045
2046 =over 4
2047
2048 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2049
2050 Define a named capture buffer. Equivalent to C<< (?<NAME>pattern) >>.
2051
2052 =item C<< (?P=NAME) >>
2053
2054 Backreference to a named capture buffer. Equivalent to C<< \g{NAME} >>.
2055
2056 =item C<< (?P>NAME) >>
2057
2058 Subroutine call to a named capture buffer. Equivalent to C<< (?&NAME) >>.
2059
2060 =back
2061
2062 =head1 BUGS
2063
2064 This document varies from difficult to understand to completely
2065 and utterly opaque.  The wandering prose riddled with jargon is
2066 hard to fathom in several places.
2067
2068 This document needs a rewrite that separates the tutorial content
2069 from the reference content.
2070
2071 =head1 SEE ALSO
2072
2073 L<perlrequick>.
2074
2075 L<perlretut>.
2076
2077 L<perlop/"Regexp Quote-Like Operators">.
2078
2079 L<perlop/"Gory details of parsing quoted constructs">.
2080
2081 L<perlfaq6>.
2082
2083 L<perlfunc/pos>.
2084
2085 L<perllocale>.
2086
2087 L<perlebcdic>.
2088
2089 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2090 by O'Reilly and Associates.