This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
ee3625addbce22ac039916d5af852f009405bec9
[perl5.git] / t / re / charset.t
1 # Test the /a, /d, etc regex modifiers
2
3 BEGIN {
4     chdir 't' if -d 't';
5     @INC = '../lib';
6     require Config; import Config;
7     require './test.pl';
8 }
9
10 use strict;
11 use warnings;
12
13 plan('no_plan');
14
15 # Each case is a valid element of its hash key.  Choose, where available, an
16 # ASCII-range, Latin-1 non-ASCII range, and above Latin1 range code point.
17 my %testcases = (
18     '\w' => [ ord("A"), 0xE2, 0x16B ],   # Below expects these to all be alpha
19     '\d' => [ ord("0"), 0x0662 ],
20     '\s' => [ ord("\t"), 0xA0, 0x1680 ],  # Below expects these to be [:blank:]
21     '[:cntrl:]' => [ 0x00, 0x88 ],
22     '[:graph:]' => [ ord("&"), 0xF7, 0x02C7 ], # Below expects these to be
23                                                # [:print:]
24     '[:lower:]' => [ ord("g"), 0xE3, 0x0127 ],
25     '[:punct:]' => [ ord("!"), 0xBF, 0x055C ],
26     '[:upper:]' => [ ord("G"), 0xC3, 0x0126 ],
27     '[:xdigit:]' => [ ord("4"), 0xFF15 ],
28 );
29
30 $testcases{'[:digit:]'} = $testcases{'\d'};
31 $testcases{'[:alnum:]'} = $testcases{'\w'};
32 $testcases{'[:alpha:]'} = $testcases{'\w'};
33 $testcases{'[:blank:]'} = $testcases{'\s'};
34 $testcases{'[:print:]'} = $testcases{'[:graph:]'};
35 $testcases{'[:space:]'} = $testcases{'\s'};
36 $testcases{'[:word:]'} = $testcases{'\w'};
37
38 my @charsets = qw(a d u aa);
39 if (! is_miniperl() && $Config{d_setlocale}) {
40     require POSIX;
41     my $current_locale = POSIX::setlocale( &POSIX::LC_ALL, "C") // "";
42     if ($current_locale eq 'C') {
43         require locale; import locale;
44
45         # Some locale implementations don't have the 128-255 characters all
46         # mean nothing.  Skip the locale tests in that situation
47         for my $i (128 .. 255) {
48             goto bad_locale if chr($i) =~ /[[:print:]]/;
49         }
50         push @charsets, 'l';
51     bad_locale:
52     }
53 }
54
55 # For each possible character set...
56 foreach my $charset (@charsets) {
57
58     # And in utf8 or not
59     foreach my $upgrade ("", 'utf8::upgrade($a); ') {
60
61         # reverse gets the, \w, \s, \d first.
62         for my $class (reverse sort keys %testcases) {
63
64             # The complement of \w is \W; of [:posix:] is [:^posix:]
65             my $complement = $class;
66             if ($complement !~ s/ ( \[: ) /$1^/x) {
67                 $complement = uc($class);
68             }
69
70             # For each test case
71             foreach my $ord (@{$testcases{$class}}) {
72                 my $char = display(chr($ord));
73
74                 # > 255 already implies upgraded.  Skip the ones that don't
75                 # have an explicit upgrade.  This shows more clearly in the
76                 # output which tests are in utf8, or not.
77                 next if $ord > 255 && ! $upgrade;
78
79                 my $reason = "";    # Explanation output with each test
80                 my $neg_reason = "";
81                 my $match = 1;      # Calculated whether test regex should
82                                     # match or not
83
84                 # Everything always matches in ASCII, or under /u
85                 if ($ord < 128 || $charset eq 'u') {
86                     $reason = "\"$char\" is a $class under /$charset";
87                     $neg_reason = "\"$char\" is not a $complement under /$charset";
88                 }
89                 elsif ($charset eq "a" || $charset eq "aa") {
90                     $match = 0;
91                     $reason = "\"$char\" is non-ASCII, which can't be a $class under /a";
92                     $neg_reason = "\"$char\" is non-ASCII, which is a $complement under /a";
93                 }
94                 elsif ($ord > 255) {
95                     $reason = "\"$char\" is a $class under /$charset";
96                     $neg_reason = "\"$char\" is not a $complement under /$charset";
97                 }
98                 elsif ($charset eq 'l') {
99
100                     # We are using the C locale, which is essentially ASCII,
101                     # but under utf8, the above-latin1 chars are treated as
102                     # Unicode)
103                     $reason = "\"$char\" is not a $class in this locale under /l";
104                     $neg_reason = "\"$char\" is a $complement in this locale under /l";
105                     $match = 0;
106                 }
107                 elsif ($upgrade) {
108                     $reason = "\"$char\" is a $class in utf8 under /d";
109                     $neg_reason = "\"$char\" is not a $complement in utf8 under /d";
110                 }
111                 else {
112                     $reason = "\"$char\" is above-ASCII latin1, which requires utf8 to be a $class under /d";
113                     $neg_reason = "\"$char\" is above-ASCII latin1, which is a $complement under /d (unless in utf8)";
114                     $match = 0;
115                 }
116                 $reason = "; $reason" if $reason;
117                 $neg_reason = "; $neg_reason" if $neg_reason;
118
119                 my $op;
120                 my $neg_op;
121                 if ($match) {
122                     $op = '=~';
123                     $neg_op = '!~';
124                 }
125                 else {
126                     $op = '!~';
127                     $neg_op = '=~';
128                 }
129
130                 # In [...] or not
131                 foreach my $bracketed (0, 1) {
132                     my $lb = "";
133                     my $rb = "";
134                     if ($bracketed) {
135
136                         # Adds an extra char to the character class to make sure
137                         # that the class doesn't get optimized away.
138                         $lb = ($bracketed) ? '[_' : "";
139                         $rb = ($bracketed) ? ']' : "";
140                     }
141                     else {  # [:posix:] must be inside outer [ ]
142                         next if $class =~ /\[/;
143                     }
144
145                     my $length = 10;    # For regexec.c regrepeat() cases by
146                                         # matching more than one item
147                     # Test both class and its complement, and with one or more
148                     # than one item to match.
149                     foreach my $eval (
150                         qq[my \$a = "$char"; $upgrade\$a $op qr/ (?$charset: $lb$class$rb ) /x],
151                         qq[my \$a = "$char" x $length; $upgrade\$a $op qr/ (?$charset: $lb$class$rb\{$length} ) /x],
152                     ) {
153                         ok (eval $eval, $eval . $reason);
154                     }
155                     foreach my $eval (
156                         qq[my \$a = "$char"; $upgrade\$a $neg_op qr/ (?$charset: $lb$complement$rb ) /x],
157                         qq[my \$a = "$char" x $length; $upgrade\$a $neg_op qr/ (?$charset: $lb$complement$rb\{$length} ) /x],
158                     ) {
159                         ok (eval $eval, $eval . $neg_reason);
160                     }
161                 }
162
163                 next if $class ne '\w';
164
165                 # Test \b, \B at beginning and end of string
166                 foreach my $eval (
167                     qq[my \$a = "$char"; $upgrade\$a $op qr/ (?$charset: ^ \\b . ) /x],
168                     qq[my \$a = "$char"; $upgrade\$a $op qr/ (?$charset: . \\b \$) /x],
169                 ) {
170                     ok (eval $eval, $eval . $reason);
171                 }
172                 foreach my $eval (
173                     qq[my \$a = "$char"; $upgrade\$a $neg_op qr/(?$charset: ^ \\B . ) /x],
174                     qq[my \$a = "$char"; $upgrade\$a $neg_op qr/(?$charset: . \\B \$ ) /x],
175                 ) {
176                     ok (eval $eval, $eval . $neg_reason);
177                 }
178
179                 # Test \b, \B adjacent to a non-word char, both before it and
180                 # after.  We test with ASCII, Latin1 and Unicode non-word chars
181                 foreach my $space_ord (@{$testcases{'\s'}}) {
182
183                     # Useless to try to test non-utf8 when the ord itself
184                     # forces utf8
185                     next if $space_ord > 255 && ! $upgrade;
186
187                     my $space = display(chr $space_ord);
188
189                     foreach my $eval (
190                         qq[my \$a = "$space$char"; $upgrade\$a $op qr/ (?$charset: . \\b . ) /x],
191                         qq[my \$a = "$char$space"; $upgrade\$a $op qr/ (?$charset: . \\b . ) /x],
192                     ) {
193                         ok (eval $eval, $eval . $reason . "; \"$space\" is not a \\w");
194                     }
195                     foreach my $eval (
196                         qq[my \$a = "$space$char"; $upgrade\$a $neg_op qr/ (?$charset: . \\B . ) /x],
197                         qq[my \$a = "$char$space"; $upgrade\$a $neg_op qr/ (?$charset: . \\B . ) /x],
198                     ) {
199                         ok (eval $eval, $eval . $neg_reason . "; \"$space\" is not a \\w");
200                     }
201                 }
202
203                 # Test \b, \B in the middle of two nominally word chars, but
204                 # one or both may be considered non-word depending on range
205                 # and charset.
206                 foreach my $other_ord (@{$testcases{'\w'}}) {
207                     next if $other_ord > 255 && ! $upgrade;
208                     my $other = display(chr $other_ord);
209
210                     # Determine if the other char is a word char in current
211                     # circumstances
212                     my $other_is_word = 1;
213                     my $other_reason = "\"$other\" is a $class under /$charset";
214                     my $other_neg_reason = "\"$other\" is not a $complement under /$charset";
215                     if ($other_ord > 127
216                         && $charset ne 'u'
217                         && (($charset eq "a" || $charset eq "aa")
218                             || ($other_ord < 256 && ($charset eq 'l' || ! $upgrade))))
219                     {
220                         $other_is_word = 0;
221                         $other_reason = "\"$other\" is not a $class under /$charset";
222                         $other_neg_reason = "\"$other\" is a $complement under /$charset";
223                     }
224                     my $both_reason = $reason;
225                     $both_reason .= "; $other_reason" if $other_ord != $ord;
226                     my $both_neg_reason = $neg_reason;
227                     $both_neg_reason .= "; $other_neg_reason" if $other_ord != $ord;
228
229                     # If both are the same wordness, then \b will fail; \B
230                     # succeed
231                     if ($match == $other_is_word) {
232                         $op = '!~';
233                         $neg_op = '=~';
234                     }
235                     else {
236                         $op = '=~';
237                         $neg_op = '!~';
238                     }
239
240                     foreach my $eval (
241                         qq[my \$a = "$other$char"; $upgrade\$a $op qr/ (?$charset: $other \\b $char ) /x],
242                         qq[my \$a = "$char$other"; $upgrade\$a $op qr/ (?$charset: $char \\b $other ) /x],
243                     ) {
244                         ok (eval $eval, $eval . $both_reason);
245                     }
246                     foreach my $eval (
247                         qq[my \$a = "$other$char"; $upgrade\$a $neg_op qr/ (?$charset: $other \\B $char ) /x],
248                         qq[my \$a = "$char$other"; $upgrade\$a $neg_op qr/ (?$charset: $char \\B $other ) /x],
249                     ) {
250                         ok (eval $eval, $eval . $both_neg_reason);
251                     }
252
253                     next if $other_ord == $ord;
254
255                     # These start with the \b or \B.  They are included, based
256                     # on source code analysis, to force the testing of the FBC
257                     # (find_by_class) portions of regexec.c.
258                     foreach my $eval (
259                         qq[my \$a = "$other$char"; $upgrade\$a $op qr/ (?$charset: \\b $char ) /x],
260                         qq[my \$a = "$char$other"; $upgrade\$a $op qr/ (?$charset: \\b $other ) /x],
261                     ) {
262                         ok (eval $eval, $eval . $both_reason);
263                     }
264                     foreach my $eval (
265                         qq[my \$a = "$other$char"; $upgrade\$a $neg_op qr/ (?$charset: \\B $char ) /x],
266                         qq[my \$a = "$char$other"; $upgrade\$a $neg_op qr/ (?$charset: \\B $other ) /x],
267                     ) {
268                         ok (eval $eval, $eval . $both_neg_reason);
269                     }
270                 }
271             } # End of each test case in a class
272         } # End of \w, \s, ...
273     } # End of utf8 upgraded or not
274 }
275
276 plan(curr_test() - 1);