This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
ed4b3708f4c6aaf75ec318ce7bfa3e27668d59af
[perl5.git] / pod / perlvar.pod
1 =head1 NAME
2
3 perlvar - Perl predefined variables
4
5 =head1 DESCRIPTION
6
7 =head2 The Syntax of Variable Names
8
9 Variable names in Perl can have several formats.  Usually, they
10 must begin with a letter or underscore, in which case they can be
11 arbitrarily long (up to an internal limit of 251 characters) and
12 may contain letters, digits, underscores, or the special sequence
13 C<::> or C<'>.  In this case, the part before the last C<::> or
14 C<'> is taken to be a I<package qualifier>; see L<perlmod>.
15
16 Perl variable names may also be a sequence of digits or a single
17 punctuation or control character.  These names are all reserved for
18 special uses by Perl; for example, the all-digits names are used
19 to hold data captured by backreferences after a regular expression
20 match.  Perl has a special syntax for the single-control-character
21 names: It understands C<^X> (caret C<X>) to mean the control-C<X>
22 character.  For example, the notation C<$^W> (dollar-sign caret
23 C<W>) is the scalar variable whose name is the single character
24 control-C<W>.  This is better than typing a literal control-C<W>
25 into your program.
26
27 Since Perl 5.6, Perl variable names may be alphanumeric
28 strings that begin with control characters (or better yet, a caret).
29 These variables must be written in the form C<${^Foo}>; the braces
30 are not optional.  C<${^Foo}> denotes the scalar variable whose
31 name is a control-C<F> followed by two C<o>'s.  These variables are
32 reserved for future special uses by Perl, except for the ones that
33 begin with C<^_> (control-underscore or caret-underscore).  No
34 control-character name that begins with C<^_> will acquire a special
35 meaning in any future version of Perl; such names may therefore be
36 used safely in programs.  C<$^_> itself, however, I<is> reserved.
37
38 Perl identifiers that begin with digits, control characters, or
39 punctuation characters are exempt from the effects of the C<package>
40 declaration and are always forced to be in package C<main>; they are
41 also exempt from C<strict 'vars'> errors.  A few other names are also
42 exempt in these ways:
43
44         ENV      STDIN
45         INC      STDOUT
46         ARGV     STDERR
47         ARGVOUT
48         SIG
49
50 In particular, the special C<${^_XYZ}> variables are always taken
51 to be in package C<main>, regardless of any C<package> declarations
52 presently in scope.
53
54 =head1 SPECIAL VARIABLES
55
56 The following names have special meaning to Perl.  Most punctuation
57 names have reasonable mnemonics, or analogs in the shells.
58 Nevertheless, if you wish to use long variable names, you need only say:
59
60         use English;
61
62 at the top of your program.  This aliases all the short names to the long
63 names in the current package.  Some even have medium names, generally
64 borrowed from B<awk>.  To avoid a performance hit, if you don't need the
65 C<$PREMATCH>, C<$MATCH>, or C<$POSTMATCH> it's best to use the C<English>
66 module without them:
67
68         use English '-no_match_vars';
69
70 Before you continue, note the sort order for variables.  In general, we
71 first list the variables in case-insensitive, almost-lexigraphical
72 order (ignoring the C<{> or C<^> preceding words, as in C<${^UNICODE}>
73 or C<$^T>), although C<$_> and C<@_> move up to the top of the pile.
74 For variables with the same identifier, we list it in order of scalar,
75 array, hash, and bareword.
76
77 =head2 General Variables
78
79 =over 8
80
81 =item $ARG
82
83 =item $_
84 X<$_> X<$ARG>
85
86 The default input and pattern-searching space.  The following pairs are
87 equivalent:
88
89         while (<>) {...}    # equivalent only in while!
90         while (defined($_ = <>)) {...}
91
92         /^Subject:/
93         $_ =~ /^Subject:/
94
95         tr/a-z/A-Z/
96         $_ =~ tr/a-z/A-Z/
97
98         chomp
99         chomp($_)
100
101 Here are the places where Perl will assume C<$_> even if you don't use it:
102
103 =over 3
104
105 =item *
106
107 The following functions use C<$_> as a default argument:
108
109 abs, alarm, chomp, chop, chr, chroot,
110 cos, defined, eval, evalbytes, exp, glob,
111 hex, int, lc, lcfirst, length, log, lstat, mkdir, oct, ord, pos, print,
112 quotemeta, readlink, readpipe, ref, require, reverse (in scalar context only),
113 rmdir, sin, split (on its second argument), sqrt, stat, study, uc, ucfirst,
114 unlink, unpack.
115
116 =item *
117
118 All file tests (C<-f>, C<-d>) except for C<-t>, which defaults to STDIN.
119 See L<perlfunc/-X>
120
121 =item *
122
123 The pattern matching operations C<m//>, C<s///> and C<tr///> (aka C<y///>)
124 when used without an C<=~> operator.
125
126 =item *
127
128 The default iterator variable in a C<foreach> loop if no other
129 variable is supplied.
130
131 =item *
132
133 The implicit iterator variable in the C<grep()> and C<map()> functions.
134
135 =item *
136
137 The implicit variable of C<given()>.
138
139 =item *
140
141 The default place to put an input record when a C<< <FH> >>
142 operation's result is tested by itself as the sole criterion of a C<while>
143 test.  Outside a C<while> test, this will not happen.
144
145 =back
146
147 As C<$_> is a global variable, this may lead in some cases to unwanted
148 side-effects.  As of perl 5.10, you can now use a lexical version of
149 C<$_> by declaring it in a file or in a block with C<my>.  Moreover,
150 declaring C<our $_> restores the global C<$_> in the current scope.
151
152 Mnemonic: underline is understood in certain operations.
153
154 =item @ARG
155
156 =item @_
157 X<@_> X<@ARG>
158
159 Within a subroutine the array C<@_> contains the parameters passed to
160 that subroutine.  Inside a subroutine, C<@_> is the default array for
161 the array operators C<push>, C<pop>, C<shift>, and C<unshift>.
162
163 See L<perlsub>.
164
165 =item $LIST_SEPARATOR
166
167 =item $"
168 X<$"> X<$LIST_SEPARATOR>
169
170 When an array or an array slice is interpolated into a double-quoted
171 string or a similar context such as C</.../>, its elements are
172 separated by this value.  Default is a space.  For example, this:
173
174         print "The array is: @array\n";
175
176 is equivalent to this:
177
178         print "The array is: " . join($", @array) . "\n";
179
180 Mnemonic: works in double-quoted context.
181
182 =item $PROCESS_ID
183
184 =item $PID
185
186 =item $$
187 X<$$> X<$PID> X<$PROCESS_ID>
188
189 The process number of the Perl running this script.  Though you I<can> set
190 this variable, doing so is generally discouraged, although it can be
191 invaluable for some testing purposes.  It will be reset automatically
192 across C<fork()> calls.
193
194 Note for Linux and Debian GNU/kFreeBSD users: Before Perl v5.16.0 perl
195 would emulate POSIX semantics on Linux systems using LinuxThreads, a
196 partial implementation of POSIX Threads that has since been superseded
197 by the Native POSIX Thread Library (NPTL).
198
199 LinuxThreads is now obsolete on Linux, and and caching C<getpid()>
200 like this made embedding perl unnecessarily complex (since you'd have
201 to manually update the value of $$), so now C<$$> and C<getppid()>
202 will always return the same values as the underlying C library.
203
204 Debian GNU/kFreeBSD systems also used LinuxThreads up until and
205 including the 6.0 release, but after that moved to FreeBSD thread
206 semantics, which are POSIX-like.
207
208 To see if your system is affected by this discrepancy check if
209 C<getconf GNU_LIBPTHREAD_VERSION | grep -q NPTL> returns a false
210 value. NTPL threads preserve the POSIX semantics.
211
212 Mnemonic: same as shells.
213
214 =item $PROGRAM_NAME
215
216 =item $0
217 X<$0> X<$PROGRAM_NAME>
218
219 Contains the name of the program being executed.
220
221 On some (but not all) operating systems assigning to C<$0> modifies
222 the argument area that the C<ps> program sees.  On some platforms you
223 may have to use special C<ps> options or a different C<ps> to see the
224 changes.  Modifying the C<$0> is more useful as a way of indicating the
225 current program state than it is for hiding the program you're
226 running.
227
228 Note that there are platform-specific limitations on the maximum
229 length of C<$0>.  In the most extreme case it may be limited to the
230 space occupied by the original C<$0>.
231
232 In some platforms there may be arbitrary amount of padding, for
233 example space characters, after the modified name as shown by C<ps>.
234 In some platforms this padding may extend all the way to the original
235 length of the argument area, no matter what you do (this is the case
236 for example with Linux 2.2).
237
238 Note for BSD users: setting C<$0> does not completely remove "perl"
239 from the ps(1) output.  For example, setting C<$0> to C<"foobar"> may
240 result in C<"perl: foobar (perl)"> (whether both the C<"perl: "> prefix
241 and the " (perl)" suffix are shown depends on your exact BSD variant
242 and version).  This is an operating system feature, Perl cannot help it.
243
244 In multithreaded scripts Perl coordinates the threads so that any
245 thread may modify its copy of the C<$0> and the change becomes visible
246 to ps(1) (assuming the operating system plays along).  Note that
247 the view of C<$0> the other threads have will not change since they
248 have their own copies of it.
249
250 If the program has been given to perl via the switches C<-e> or C<-E>,
251 C<$0> will contain the string C<"-e">.
252
253 On Linux as of perl 5.14 the legacy process name will be set with
254 C<prctl(2)>, in addition to altering the POSIX name via C<argv[0]> as
255 perl has done since version 4.000.  Now system utilities that read the
256 legacy process name such as ps, top and killall will recognize the
257 name you set when assigning to C<$0>.  The string you supply will be
258 cut off at 16 bytes, this is a limitation imposed by Linux.
259
260 Mnemonic: same as B<sh> and B<ksh>.
261
262 =item $REAL_GROUP_ID
263
264 =item $GID
265
266 =item $(
267 X<$(> X<$GID> X<$REAL_GROUP_ID>
268
269 The real gid of this process.  If you are on a machine that supports
270 membership in multiple groups simultaneously, gives a space separated
271 list of groups you are in.  The first number is the one returned by
272 C<getgid()>, and the subsequent ones by C<getgroups()>, one of which may be
273 the same as the first number.
274
275 However, a value assigned to C<$(> must be a single number used to
276 set the real gid.  So the value given by C<$(> should I<not> be assigned
277 back to C<$(> without being forced numeric, such as by adding zero.  Note
278 that this is different to the effective gid (C<$)>) which does take a
279 list.
280
281 You can change both the real gid and the effective gid at the same
282 time by using C<POSIX::setgid()>.  Changes
283 to C<$(> require a check to C<$!>
284 to detect any possible errors after an attempted change.
285
286 Mnemonic: parentheses are used to I<group> things.  The real gid is the
287 group you I<left>, if you're running setgid.
288
289 =item $EFFECTIVE_GROUP_ID
290
291 =item $EGID
292
293 =item $)
294 X<$)> X<$EGID> X<$EFFECTIVE_GROUP_ID>
295
296 The effective gid of this process.  If you are on a machine that
297 supports membership in multiple groups simultaneously, gives a space
298 separated list of groups you are in.  The first number is the one
299 returned by C<getegid()>, and the subsequent ones by C<getgroups()>,
300 one of which may be the same as the first number.
301
302 Similarly, a value assigned to C<$)> must also be a space-separated
303 list of numbers.  The first number sets the effective gid, and
304 the rest (if any) are passed to C<setgroups()>.  To get the effect of an
305 empty list for C<setgroups()>, just repeat the new effective gid; that is,
306 to force an effective gid of 5 and an effectively empty C<setgroups()>
307 list, say C< $) = "5 5" >.
308
309 You can change both the effective gid and the real gid at the same
310 time by using C<POSIX::setgid()> (use only a single numeric argument).
311 Changes to C<$)> require a check to C<$!> to detect any possible errors
312 after an attempted change.
313
314 C<< $< >>, C<< $> >>, C<$(> and C<$)> can be set only on
315 machines that support the corresponding I<set[re][ug]id()> routine.  C<$(>
316 and C<$)> can be swapped only on machines supporting C<setregid()>.
317
318 Mnemonic: parentheses are used to I<group> things.  The effective gid
319 is the group that's I<right> for you, if you're running setgid.
320
321 =item $REAL_USER_ID
322
323 =item $UID
324
325 =item $<
326 X<< $< >> X<$UID> X<$REAL_USER_ID>
327
328 The real uid of this process.  You can change both the real uid and the
329 effective uid at the same time by using C<POSIX::setuid()>.  Since
330 changes to C<< $< >> require a system call, check C<$!> after a change
331 attempt to detect any possible errors.
332
333 Mnemonic: it's the uid you came I<from>, if you're running setuid.
334
335 =item $EFFECTIVE_USER_ID
336
337 =item $EUID
338
339 =item $>
340 X<< $> >> X<$EUID> X<$EFFECTIVE_USER_ID>
341
342 The effective uid of this process.  For example:
343
344         $< = $>;            # set real to effective uid
345         ($<,$>) = ($>,$<);  # swap real and effective uids
346
347 You can change both the effective uid and the real uid at the same
348 time by using C<POSIX::setuid()>.  Changes to C<< $> >> require a check
349 to C<$!> to detect any possible errors after an attempted change.
350
351 C<< $< >> and C<< $> >> can be swapped only on machines
352 supporting C<setreuid()>.
353
354 Mnemonic: it's the uid you went I<to>, if you're running setuid.
355
356 =item $SUBSCRIPT_SEPARATOR
357
358 =item $SUBSEP
359
360 =item $;
361 X<$;> X<$SUBSEP> X<SUBSCRIPT_SEPARATOR>
362
363 The subscript separator for multidimensional array emulation.  If you
364 refer to a hash element as
365
366         $foo{$a,$b,$c}
367
368 it really means
369
370         $foo{join($;, $a, $b, $c)}
371
372 But don't put
373
374         @foo{$a,$b,$c}  # a slice--note the @
375
376 which means
377
378         ($foo{$a},$foo{$b},$foo{$c})
379
380 Default is "\034", the same as SUBSEP in B<awk>.  If your keys contain
381 binary data there might not be any safe value for C<$;>.
382
383 Consider using "real" multidimensional arrays as described
384 in L<perllol>.
385
386 Mnemonic: comma (the syntactic subscript separator) is a semi-semicolon.
387
388 =item $a
389
390 =item $b
391 X<$a> X<$b>
392
393 Special package variables when using C<sort()>, see L<perlfunc/sort>.
394 Because of this specialness C<$a> and C<$b> don't need to be declared
395 (using C<use vars>, or C<our()>) even when using the C<strict 'vars'>
396 pragma.  Don't lexicalize them with C<my $a> or C<my $b> if you want to
397 be able to use them in the C<sort()> comparison block or function.
398
399 =item %ENV
400 X<%ENV>
401
402 The hash C<%ENV> contains your current environment.  Setting a
403 value in C<ENV> changes the environment for any child processes
404 you subsequently C<fork()> off.
405
406 =item $SYSTEM_FD_MAX
407
408 =item $^F
409 X<$^F> X<$SYSTEM_FD_MAX>
410
411 The maximum system file descriptor, ordinarily 2.  System file
412 descriptors are passed to C<exec()>ed processes, while higher file
413 descriptors are not.  Also, during an
414 C<open()>, system file descriptors are
415 preserved even if the C<open()> fails (ordinary file descriptors are
416 closed before the C<open()> is attempted).  The close-on-exec
417 status of a file descriptor will be decided according to the value of
418 C<$^F> when the corresponding file, pipe, or socket was opened, not the
419 time of the C<exec()>.
420
421 =item @F
422 X<@F>
423
424 The array C<@F> contains the fields of each line read in when autosplit
425 mode is turned on.  See L<perlrun> for the B<-a> switch.  This array
426 is package-specific, and must be declared or given a full package name
427 if not in package main when running under C<strict 'vars'>.
428
429 =item @INC
430 X<@INC>
431
432 The array C<@INC> contains the list of places that the C<do EXPR>,
433 C<require>, or C<use> constructs look for their library files.  It
434 initially consists of the arguments to any B<-I> command-line
435 switches, followed by the default Perl library, probably
436 F</usr/local/lib/perl>, followed by ".", to represent the current
437 directory.  ("." will not be appended if taint checks are enabled,
438 either by C<-T> or by C<-t>.)  If you need to modify this at runtime,
439 you should use the C<use lib> pragma to get the machine-dependent
440 library properly loaded also:
441
442         use lib '/mypath/libdir/';
443         use SomeMod;
444
445 You can also insert hooks into the file inclusion system by putting Perl
446 code directly into C<@INC>.  Those hooks may be subroutine references,
447 array references or blessed objects.  See L<perlfunc/require> for details.
448
449 =item %INC
450 X<%INC>
451
452 The hash C<%INC> contains entries for each filename included via the
453 C<do>, C<require>, or C<use> operators.  The key is the filename
454 you specified (with module names converted to pathnames), and the
455 value is the location of the file found.  The C<require>
456 operator uses this hash to determine whether a particular file has
457 already been included.
458
459 If the file was loaded via a hook (e.g. a subroutine reference, see
460 L<perlfunc/require> for a description of these hooks), this hook is
461 by default inserted into C<%INC> in place of a filename.  Note, however,
462 that the hook may have set the C<%INC> entry by itself to provide some more
463 specific info.
464
465 =item $INPLACE_EDIT
466
467 =item $^I
468 X<$^I> X<$INPLACE_EDIT>
469
470 The current value of the inplace-edit extension.  Use C<undef> to disable
471 inplace editing.
472
473 Mnemonic: value of B<-i> switch.
474
475 =item $^M
476 X<$^M>
477
478 By default, running out of memory is an untrappable, fatal error.
479 However, if suitably built, Perl can use the contents of C<$^M>
480 as an emergency memory pool after C<die()>ing.  Suppose that your Perl
481 were compiled with C<-DPERL_EMERGENCY_SBRK> and used Perl's malloc.
482 Then
483
484         $^M = 'a' x (1 << 16);
485
486 would allocate a 64K buffer for use in an emergency.  See the
487 F<INSTALL> file in the Perl distribution for information on how to
488 add custom C compilation flags when compiling perl.  To discourage casual
489 use of this advanced feature, there is no L<English|English> long name for
490 this variable.
491
492 This variable was added in Perl 5.004.
493
494 =item $OSNAME
495
496 =item $^O
497 X<$^O> X<$OSNAME>
498
499 The name of the operating system under which this copy of Perl was
500 built, as determined during the configuration process.  For examples
501 see L<perlport/PLATFORMS>.
502
503 The value is identical to C<$Config{'osname'}>.  See also L<Config>
504 and the B<-V> command-line switch documented in L<perlrun>.
505
506 In Windows platforms, C<$^O> is not very helpful: since it is always
507 C<MSWin32>, it doesn't tell the difference between
508 95/98/ME/NT/2000/XP/CE/.NET.  Use C<Win32::GetOSName()> or
509 Win32::GetOSVersion() (see L<Win32> and L<perlport>) to distinguish
510 between the variants.
511
512 This variable was added in Perl 5.003.
513
514 =item %SIG
515 X<%SIG>
516
517 The hash C<%SIG> contains signal handlers for signals.  For example:
518
519         sub handler {   # 1st argument is signal name
520                 my($sig) = @_;
521                 print "Caught a SIG$sig--shutting down\n";
522                 close(LOG);
523                 exit(0);
524                 }
525
526         $SIG{'INT'}  = \&handler;
527         $SIG{'QUIT'} = \&handler;
528         ...
529         $SIG{'INT'}  = 'DEFAULT';   # restore default action
530         $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
531
532 Using a value of C<'IGNORE'> usually has the effect of ignoring the
533 signal, except for the C<CHLD> signal.  See L<perlipc> for more about
534 this special case.
535
536 Here are some other examples:
537
538         $SIG{"PIPE"} = "Plumber";   # assumes main::Plumber (not recommended)
539         $SIG{"PIPE"} = \&Plumber;   # just fine; assume current Plumber
540         $SIG{"PIPE"} = *Plumber;    # somewhat esoteric
541         $SIG{"PIPE"} = Plumber();   # oops, what did Plumber() return??
542
543 Be sure not to use a bareword as the name of a signal handler,
544 lest you inadvertently call it.
545
546 If your system has the C<sigaction()> function then signal handlers
547 are installed using it.  This means you get reliable signal handling.
548
549 The default delivery policy of signals changed in Perl 5.8.0 from
550 immediate (also known as "unsafe") to deferred, also known as "safe
551 signals".  See L<perlipc> for more information.
552
553 Certain internal hooks can be also set using the C<%SIG> hash.  The
554 routine indicated by C<$SIG{__WARN__}> is called when a warning
555 message is about to be printed.  The warning message is passed as the
556 first argument.  The presence of a C<__WARN__> hook causes the
557 ordinary printing of warnings to C<STDERR> to be suppressed.  You can
558 use this to save warnings in a variable, or turn warnings into fatal
559 errors, like this:
560
561         local $SIG{__WARN__} = sub { die $_[0] };
562         eval $proggie;
563
564 As the C<'IGNORE'> hook is not supported by C<__WARN__>, you can
565 disable warnings using the empty subroutine:
566
567         local $SIG{__WARN__} = sub {};
568
569 The routine indicated by C<$SIG{__DIE__}> is called when a fatal
570 exception is about to be thrown.  The error message is passed as the
571 first argument.  When a C<__DIE__> hook routine returns, the exception
572 processing continues as it would have in the absence of the hook,
573 unless the hook routine itself exits via a C<goto &sub>, a loop exit,
574 or a C<die()>.  The C<__DIE__> handler is explicitly disabled during
575 the call, so that you can die from a C<__DIE__> handler.  Similarly
576 for C<__WARN__>.
577
578 Due to an implementation glitch, the C<$SIG{__DIE__}> hook is called
579 even inside an C<eval()>.  Do not use this to rewrite a pending
580 exception in C<$@>, or as a bizarre substitute for overriding
581 C<CORE::GLOBAL::die()>.  This strange action at a distance may be fixed
582 in a future release so that C<$SIG{__DIE__}> is only called if your
583 program is about to exit, as was the original intent.  Any other use is
584 deprecated.
585
586 C<__DIE__>/C<__WARN__> handlers are very special in one respect: they
587 may be called to report (probable) errors found by the parser.  In such
588 a case the parser may be in inconsistent state, so any attempt to
589 evaluate Perl code from such a handler will probably result in a
590 segfault.  This means that warnings or errors that result from parsing
591 Perl should be used with extreme caution, like this:
592
593         require Carp if defined $^S;
594         Carp::confess("Something wrong") if defined &Carp::confess;
595         die "Something wrong, but could not load Carp to give backtrace...
596            To see backtrace try starting Perl with -MCarp switch";
597
598 Here the first line will load C<Carp> I<unless> it is the parser who
599 called the handler.  The second line will print backtrace and die if
600 C<Carp> was available.  The third line will be executed only if C<Carp> was
601 not available.
602
603 Having to even think about the C<$^S> variable in your exception
604 handlers is simply wrong.  C<$SIG{__DIE__}> as currently implemented
605 invites grievous and difficult to track down errors.  Avoid it
606 and use an C<END{}> or CORE::GLOBAL::die override instead.
607
608 See L<perlfunc/die>, L<perlfunc/warn>, L<perlfunc/eval>, and
609 L<warnings> for additional information.
610
611 =item $BASETIME
612
613 =item $^T
614 X<$^T> X<$BASETIME>
615
616 The time at which the program began running, in seconds since the
617 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>,
618 and B<-C> filetests are based on this value.
619
620 =item $PERL_VERSION
621
622 =item $^V
623 X<$^V> X<$PERL_VERSION>
624
625 The revision, version, and subversion of the Perl interpreter,
626 represented as a C<version> object.
627
628 This variable first appeared in perl 5.6.0; earlier versions of perl
629 will see an undefined value.  Before perl 5.10.0 C<$^V> was represented
630 as a v-string.
631
632 C<$^V> can be used to determine whether the Perl interpreter executing
633 a script is in the right range of versions.  For example:
634
635         warn "Hashes not randomized!\n" if !$^V or $^V lt v5.8.1
636
637 To convert C<$^V> into its string representation use C<sprintf()>'s
638 C<"%vd"> conversion:
639
640         printf "version is v%vd\n", $^V;  # Perl's version
641
642 See the documentation of C<use VERSION> and C<require VERSION>
643 for a convenient way to fail if the running Perl interpreter is too old.
644
645 See also C<$]> for an older representation of the Perl version.
646
647 This variable was added in Perl 5.6.
648
649 Mnemonic: use ^V for Version Control.
650
651 =item ${^WIN32_SLOPPY_STAT}
652 X<${^WIN32_SLOPPY_STAT}> X<sitecustomize> X<sitecustomize.pl>
653
654 If this variable is set to a true value, then C<stat()> on Windows will
655 not try to open the file.  This means that the link count cannot be
656 determined and file attributes may be out of date if additional
657 hardlinks to the file exist.  On the other hand, not opening the file
658 is considerably faster, especially for files on network drives.
659
660 This variable could be set in the F<sitecustomize.pl> file to
661 configure the local Perl installation to use "sloppy" C<stat()> by
662 default.  See the documentation for B<-f> in
663 L<perlrun|perlrun/"Command Switches"> for more information about site
664 customization.
665
666 This variable was added in Perl 5.10.
667
668 =item $EXECUTABLE_NAME
669
670 =item $^X
671 X<$^X> X<$EXECUTABLE_NAME>
672
673 The name used to execute the current copy of Perl, from C's
674 C<argv[0]> or (where supported) F</proc/self/exe>.
675
676 Depending on the host operating system, the value of C<$^X> may be
677 a relative or absolute pathname of the perl program file, or may
678 be the string used to invoke perl but not the pathname of the
679 perl program file.  Also, most operating systems permit invoking
680 programs that are not in the PATH environment variable, so there
681 is no guarantee that the value of C<$^X> is in PATH.  For VMS, the
682 value may or may not include a version number.
683
684 You usually can use the value of C<$^X> to re-invoke an independent
685 copy of the same perl that is currently running, e.g.,
686
687         @first_run = `$^X -le "print int rand 100 for 1..100"`;
688
689 But recall that not all operating systems support forking or
690 capturing of the output of commands, so this complex statement
691 may not be portable.
692
693 It is not safe to use the value of C<$^X> as a path name of a file,
694 as some operating systems that have a mandatory suffix on
695 executable files do not require use of the suffix when invoking
696 a command.  To convert the value of C<$^X> to a path name, use the
697 following statements:
698
699         # Build up a set of file names (not command names).
700         use Config;
701         my $this_perl = $^X;
702         if ($^O ne 'VMS') {
703                 $this_perl .= $Config{_exe}
704                   unless $this_perl =~ m/$Config{_exe}$/i;
705                 }
706
707 Because many operating systems permit anyone with read access to
708 the Perl program file to make a copy of it, patch the copy, and
709 then execute the copy, the security-conscious Perl programmer
710 should take care to invoke the installed copy of perl, not the
711 copy referenced by C<$^X>.  The following statements accomplish
712 this goal, and produce a pathname that can be invoked as a
713 command or referenced as a file.
714
715         use Config;
716         my $secure_perl_path = $Config{perlpath};
717         if ($^O ne 'VMS') {
718                 $secure_perl_path .= $Config{_exe}
719                         unless $secure_perl_path =~ m/$Config{_exe}$/i;
720                 }
721
722 =back
723
724 =head2 Variables related to regular expressions
725
726 Most of the special variables related to regular expressions are side
727 effects.  Perl sets these variables when it has a successful match, so
728 you should check the match result before using them.  For instance:
729
730         if( /P(A)TT(ER)N/ ) {
731                 print "I found $1 and $2\n";
732                 }
733
734 These variables are read-only and dynamically-scoped, unless we note
735 otherwise.
736
737 The dynamic nature of the regular expression variables means that
738 their value is limited to the block that they are in, as demonstrated
739 by this bit of code:
740
741         my $outer = 'Wallace and Grommit';
742         my $inner = 'Mutt and Jeff';
743
744         my $pattern = qr/(\S+) and (\S+)/;
745
746         sub show_n { print "\$1 is $1; \$2 is $2\n" }
747
748         {
749         OUTER:
750                 show_n() if $outer =~ m/$pattern/;
751
752                 INNER: {
753                         show_n() if $inner =~ m/$pattern/;
754                         }
755
756                 show_n();
757         }
758
759 The output shows that while in the C<OUTER> block, the values of C<$1>
760 and C<$2> are from the match against C<$outer>.  Inside the C<INNER>
761 block, the values of C<$1> and C<$2> are from the match against
762 C<$inner>, but only until the end of the block (i.e. the dynamic
763 scope).  After the C<INNER> block completes, the values of C<$1> and
764 C<$2> return to the values for the match against C<$outer> even though
765 we have not made another match:
766
767         $1 is Wallace; $2 is Grommit
768         $1 is Mutt; $2 is Jeff
769         $1 is Wallace; $2 is Grommit
770
771 Due to an unfortunate accident of Perl's implementation, C<use
772 English> imposes a considerable performance penalty on all regular
773 expression matches in a program because it uses the C<$`>, C<$&>, and
774 C<$'>, regardless of whether they occur in the scope of C<use
775 English>.  For that reason, saying C<use English> in libraries is
776 strongly discouraged unless you import it without the match variables:
777
778         use English '-no_match_vars'
779
780 The C<Devel::NYTProf> and C<Devel::FindAmpersand>
781 modules can help you find uses of these
782 problematic match variables in your code.
783
784 Since Perl 5.10, you can use the C</p> match operator flag and the
785 C<${^PREMATCH}>, C<${^MATCH}>, and C<${^POSTMATCH}> variables instead
786 so you only suffer the performance penalties.
787
788 =over 8
789
790 =item $<I<digits>> ($1, $2, ...)
791 X<$1> X<$2> X<$3>
792
793 Contains the subpattern from the corresponding set of capturing
794 parentheses from the last successful pattern match, not counting patterns
795 matched in nested blocks that have been exited already.
796
797 These variables are read-only and dynamically-scoped.
798
799 Mnemonic: like \digits.
800
801 =item $MATCH
802
803 =item $&
804 X<$&> X<$MATCH>
805
806 The string matched by the last successful pattern match (not counting
807 any matches hidden within a BLOCK or C<eval()> enclosed by the current
808 BLOCK).
809
810 The use of this variable anywhere in a program imposes a considerable
811 performance penalty on all regular expression matches.  To avoid this
812 penalty, you can extract the same substring by using L</@->.  Starting
813 with Perl 5.10, you can use the C</p> match flag and the C<${^MATCH}>
814 variable to do the same thing for particular match operations.
815
816 This variable is read-only and dynamically-scoped.
817
818 Mnemonic: like C<&> in some editors.
819
820 =item ${^MATCH}
821 X<${^MATCH}>
822
823 This is similar to C<$&> (C<$MATCH>) except that it does not incur the
824 performance penalty associated with that variable, and is only guaranteed
825 to return a defined value when the pattern was compiled or executed with
826 the C</p> modifier.
827
828 This variable was added in Perl 5.10.
829
830 This variable is read-only and dynamically-scoped.
831
832 =item $PREMATCH
833
834 =item $`
835 X<$`> X<$PREMATCH> X<${^PREMATCH}>
836
837 The string preceding whatever was matched by the last successful
838 pattern match, not counting any matches hidden within a BLOCK or C<eval>
839 enclosed by the current BLOCK.
840
841 The use of this variable anywhere in a program imposes a considerable
842 performance penalty on all regular expression matches.  To avoid this
843 penalty, you can extract the same substring by using L</@->.  Starting
844 with Perl 5.10, you can use the C</p> match flag and the
845 C<${^PREMATCH}> variable to do the same thing for particular match
846 operations.
847
848 This variable is read-only and dynamically-scoped.
849
850 Mnemonic: C<`> often precedes a quoted string.
851
852 =item ${^PREMATCH}
853 X<$`> X<${^PREMATCH}>
854
855 This is similar to C<$`> ($PREMATCH) except that it does not incur the
856 performance penalty associated with that variable, and is only guaranteed
857 to return a defined value when the pattern was compiled or executed with
858 the C</p> modifier.
859
860 This variable was added in Perl 5.10
861
862 This variable is read-only and dynamically-scoped.
863
864 =item $POSTMATCH
865
866 =item $'
867 X<$'> X<$POSTMATCH> X<${^POSTMATCH}> X<@->
868
869 The string following whatever was matched by the last successful
870 pattern match (not counting any matches hidden within a BLOCK or C<eval()>
871 enclosed by the current BLOCK).  Example:
872
873         local $_ = 'abcdefghi';
874         /def/;
875         print "$`:$&:$'\n";     # prints abc:def:ghi
876
877 The use of this variable anywhere in a program imposes a considerable
878 performance penalty on all regular expression matches.
879 To avoid this penalty, you can extract the same substring by
880 using L</@->.  Starting with Perl 5.10, you can use the C</p> match flag
881 and the C<${^POSTMATCH}> variable to do the same thing for particular
882 match operations.
883
884 This variable is read-only and dynamically-scoped.
885
886 Mnemonic: C<'> often follows a quoted string.
887
888 =item ${^POSTMATCH}
889 X<${^POSTMATCH}> X<$'> X<$POSTMATCH>
890
891 This is similar to C<$'> (C<$POSTMATCH>) except that it does not incur the
892 performance penalty associated with that variable, and is only guaranteed
893 to return a defined value when the pattern was compiled or executed with
894 the C</p> modifier.
895
896 This variable was added in Perl 5.10.
897
898 This variable is read-only and dynamically-scoped.
899
900 =item $LAST_PAREN_MATCH
901
902 =item $+
903 X<$+> X<$LAST_PAREN_MATCH>
904
905 The text matched by the last bracket of the last successful search pattern.
906 This is useful if you don't know which one of a set of alternative patterns
907 matched.  For example:
908
909         /Version: (.*)|Revision: (.*)/ && ($rev = $+);
910
911 This variable is read-only and dynamically-scoped.
912
913 Mnemonic: be positive and forward looking.
914
915 =item $LAST_SUBMATCH_RESULT
916
917 =item $^N
918 X<$^N> X<$LAST_SUBMATCH_RESULT>
919
920 The text matched by the used group most-recently closed (i.e. the group
921 with the rightmost closing parenthesis) of the last successful search
922 pattern.
923
924 This is primarily used inside C<(?{...})> blocks for examining text
925 recently matched.  For example, to effectively capture text to a variable
926 (in addition to C<$1>, C<$2>, etc.), replace C<(...)> with
927
928         (?:(...)(?{ $var = $^N }))
929
930 By setting and then using C<$var> in this way relieves you from having to
931 worry about exactly which numbered set of parentheses they are.
932
933 This variable was added in Perl 5.8.
934
935 Mnemonic: the (possibly) Nested parenthesis that most recently closed.
936
937 =item @LAST_MATCH_END
938
939 =item @+
940 X<@+> X<@LAST_MATCH_END>
941
942 This array holds the offsets of the ends of the last successful
943 submatches in the currently active dynamic scope.  C<$+[0]> is
944 the offset into the string of the end of the entire match.  This
945 is the same value as what the C<pos> function returns when called
946 on the variable that was matched against.  The I<n>th element
947 of this array holds the offset of the I<n>th submatch, so
948 C<$+[1]> is the offset past where C<$1> ends, C<$+[2]> the offset
949 past where C<$2> ends, and so on.  You can use C<$#+> to determine
950 how many subgroups were in the last successful match.  See the
951 examples given for the C<@-> variable.
952
953 This variable was added in Perl 5.6.
954
955 =item %LAST_PAREN_MATCH
956
957 =item %+
958 X<%+> X<%LAST_PAREN_MATCH>
959
960 Similar to C<@+>, the C<%+> hash allows access to the named capture
961 buffers, should they exist, in the last successful match in the
962 currently active dynamic scope.
963
964 For example, C<$+{foo}> is equivalent to C<$1> after the following match:
965
966         'foo' =~ /(?<foo>foo)/;
967
968 The keys of the C<%+> hash list only the names of buffers that have
969 captured (and that are thus associated to defined values).
970
971 The underlying behaviour of C<%+> is provided by the
972 L<Tie::Hash::NamedCapture> module.
973
974 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
975 associated with the last successful regular expression.  Therefore mixing
976 iterative access to them via C<each> may have unpredictable results.
977 Likewise, if the last successful match changes, then the results may be
978 surprising.
979
980 This variable was added in Perl 5.10.
981
982 This variable is read-only and dynamically-scoped.
983
984 =item @LAST_MATCH_START
985
986 =item @-
987 X<@-> X<@LAST_MATCH_START>
988
989 C<$-[0]> is the offset of the start of the last successful match.
990 C<$-[>I<n>C<]> is the offset of the start of the substring matched by
991 I<n>-th subpattern, or undef if the subpattern did not match.
992
993 Thus, after a match against C<$_>, C<$&> coincides with C<substr $_, $-[0],
994 $+[0] - $-[0]>.  Similarly, $I<n> coincides with C<substr $_, $-[n],
995 $+[n] - $-[n]> if C<$-[n]> is defined, and $+ coincides with
996 C<substr $_, $-[$#-], $+[$#-] - $-[$#-]>.  One can use C<$#-> to find the
997 last matched subgroup in the last successful match.  Contrast with
998 C<$#+>, the number of subgroups in the regular expression.  Compare
999 with C<@+>.
1000
1001 This array holds the offsets of the beginnings of the last
1002 successful submatches in the currently active dynamic scope.
1003 C<$-[0]> is the offset into the string of the beginning of the
1004 entire match.  The I<n>th element of this array holds the offset
1005 of the I<n>th submatch, so C<$-[1]> is the offset where C<$1>
1006 begins, C<$-[2]> the offset where C<$2> begins, and so on.
1007
1008 After a match against some variable C<$var>:
1009
1010 =over 5
1011
1012 =item C<$`> is the same as C<substr($var, 0, $-[0])>
1013
1014 =item C<$&> is the same as C<substr($var, $-[0], $+[0] - $-[0])>
1015
1016 =item C<$'> is the same as C<substr($var, $+[0])>
1017
1018 =item C<$1> is the same as C<substr($var, $-[1], $+[1] - $-[1])>
1019
1020 =item C<$2> is the same as C<substr($var, $-[2], $+[2] - $-[2])>
1021
1022 =item C<$3> is the same as C<substr($var, $-[3], $+[3] - $-[3])>
1023
1024 =back
1025
1026 This variable was added in Perl 5.6.
1027
1028 =item %LAST_MATCH_START
1029
1030 =item %-
1031 X<%-> X<%LAST_MATCH_START>
1032
1033 Similar to C<%+>, this variable allows access to the named capture groups
1034 in the last successful match in the currently active dynamic scope.  To
1035 each capture group name found in the regular expression, it associates a
1036 reference to an array containing the list of values captured by all
1037 buffers with that name (should there be several of them), in the order
1038 where they appear.
1039
1040 Here's an example:
1041
1042     if ('1234' =~ /(?<A>1)(?<B>2)(?<A>3)(?<B>4)/) {
1043         foreach my $bufname (sort keys %-) {
1044             my $ary = $-{$bufname};
1045             foreach my $idx (0..$#$ary) {
1046                 print "\$-{$bufname}[$idx] : ",
1047                       (defined($ary->[$idx]) ? "'$ary->[$idx]'" : "undef"),
1048                       "\n";
1049             }
1050         }
1051     }
1052
1053 would print out:
1054
1055         $-{A}[0] : '1'
1056         $-{A}[1] : '3'
1057         $-{B}[0] : '2'
1058         $-{B}[1] : '4'
1059
1060 The keys of the C<%-> hash correspond to all buffer names found in
1061 the regular expression.
1062
1063 The behaviour of C<%-> is implemented via the
1064 L<Tie::Hash::NamedCapture> module.
1065
1066 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
1067 associated with the last successful regular expression.  Therefore mixing
1068 iterative access to them via C<each> may have unpredictable results.
1069 Likewise, if the last successful match changes, then the results may be
1070 surprising.
1071
1072 This variable was added in Perl 5.10
1073
1074 This variable is read-only and dynamically-scoped.
1075
1076 =item $LAST_REGEXP_CODE_RESULT
1077
1078 =item $^R
1079 X<$^R> X<$LAST_REGEXP_CODE_RESULT>
1080
1081 The result of evaluation of the last successful C<(?{ code })>
1082 regular expression assertion (see L<perlre>).  May be written to.
1083
1084 This variable was added in Perl 5.005.
1085
1086 =item ${^RE_DEBUG_FLAGS}
1087 X<${^RE_DEBUG_FLAGS}>
1088
1089 The current value of the regex debugging flags.  Set to 0 for no debug output
1090 even when the C<re 'debug'> module is loaded.  See L<re> for details.
1091
1092 This variable was added in Perl 5.10.
1093
1094 =item ${^RE_TRIE_MAXBUF}
1095 X<${^RE_TRIE_MAXBUF}>
1096
1097 Controls how certain regex optimisations are applied and how much memory they
1098 utilize.  This value by default is 65536 which corresponds to a 512kB
1099 temporary cache.  Set this to a higher value to trade
1100 memory for speed when matching large alternations.  Set
1101 it to a lower value if you want the optimisations to
1102 be as conservative of memory as possible but still occur, and set it to a
1103 negative value to prevent the optimisation and conserve the most memory.
1104 Under normal situations this variable should be of no interest to you.
1105
1106 This variable was added in Perl 5.10.
1107
1108 =back
1109
1110 =head2 Variables related to filehandles
1111
1112 Variables that depend on the currently selected filehandle may be set
1113 by calling an appropriate object method on the C<IO::Handle> object,
1114 although this is less efficient than using the regular built-in
1115 variables.  (Summary lines below for this contain the word HANDLE.)
1116 First you must say
1117
1118         use IO::Handle;
1119
1120 after which you may use either
1121
1122         method HANDLE EXPR
1123
1124 or more safely,
1125
1126         HANDLE->method(EXPR)
1127
1128 Each method returns the old value of the C<IO::Handle> attribute.  The
1129 methods each take an optional EXPR, which, if supplied, specifies the
1130 new value for the C<IO::Handle> attribute in question.  If not
1131 supplied, most methods do nothing to the current value--except for
1132 C<autoflush()>, which will assume a 1 for you, just to be different.
1133
1134 Because loading in the C<IO::Handle> class is an expensive operation,
1135 you should learn how to use the regular built-in variables.
1136
1137 A few of these variables are considered "read-only".  This means that
1138 if you try to assign to this variable, either directly or indirectly
1139 through a reference, you'll raise a run-time exception.
1140
1141 You should be very careful when modifying the default values of most
1142 special variables described in this document.  In most cases you want
1143 to localize these variables before changing them, since if you don't,
1144 the change may affect other modules which rely on the default values
1145 of the special variables that you have changed.  This is one of the
1146 correct ways to read the whole file at once:
1147
1148         open my $fh, "<", "foo" or die $!;
1149         local $/; # enable localized slurp mode
1150         my $content = <$fh>;
1151         close $fh;
1152
1153 But the following code is quite bad:
1154
1155         open my $fh, "<", "foo" or die $!;
1156         undef $/; # enable slurp mode
1157         my $content = <$fh>;
1158         close $fh;
1159
1160 since some other module, may want to read data from some file in the
1161 default "line mode", so if the code we have just presented has been
1162 executed, the global value of C<$/> is now changed for any other code
1163 running inside the same Perl interpreter.
1164
1165 Usually when a variable is localized you want to make sure that this
1166 change affects the shortest scope possible.  So unless you are already
1167 inside some short C<{}> block, you should create one yourself.  For
1168 example:
1169
1170         my $content = '';
1171         open my $fh, "<", "foo" or die $!;
1172         {
1173                 local $/;
1174                 $content = <$fh>;
1175         }
1176         close $fh;
1177
1178 Here is an example of how your own code can go broken:
1179
1180         for ( 1..3 ){
1181                 $\ = "\r\n";
1182                 nasty_break();
1183                 print "$_";
1184         }
1185
1186         sub nasty_break {
1187         $\ = "\f";
1188         # do something with $_
1189         }
1190
1191 You probably expect this code to print the equivalent of
1192
1193     "1\r\n2\r\n3\r\n"
1194
1195 but instead you get:
1196
1197     "1\f2\f3\f"
1198
1199 Why? Because C<nasty_break()> modifies C<$\> without localizing it
1200 first.  The value you set in  C<nasty_break()> is still there when you
1201 return.  The fix is to add C<local()> so the value doesn't leak out of
1202 C<nasty_break()>:
1203
1204         local $\ = "\f";
1205
1206 It's easy to notice the problem in such a short example, but in more
1207 complicated code you are looking for trouble if you don't localize
1208 changes to the special variables.
1209
1210 =over 8
1211
1212 =item $ARGV
1213 X<$ARGV>
1214
1215 Contains the name of the current file when reading from C<< <> >>.
1216
1217 =item @ARGV
1218 X<@ARGV>
1219
1220 The array C<@ARGV> contains the command-line arguments intended for
1221 the script.  C<$#ARGV> is generally the number of arguments minus
1222 one, because C<$ARGV[0]> is the first argument, I<not> the program's
1223 command name itself.  See L</$0> for the command name.
1224
1225 =item ARGV
1226 X<ARGV>
1227
1228 The special filehandle that iterates over command-line filenames in
1229 C<@ARGV>.  Usually written as the null filehandle in the angle operator
1230 C<< <> >>.  Note that currently C<ARGV> only has its magical effect
1231 within the C<< <> >> operator; elsewhere it is just a plain filehandle
1232 corresponding to the last file opened by C<< <> >>.  In particular,
1233 passing C<\*ARGV> as a parameter to a function that expects a filehandle
1234 may not cause your function to automatically read the contents of all the
1235 files in C<@ARGV>.
1236
1237 =item ARGVOUT
1238 X<ARGVOUT>
1239
1240 The special filehandle that points to the currently open output file
1241 when doing edit-in-place processing with B<-i>.  Useful when you have
1242 to do a lot of inserting and don't want to keep modifying C<$_>.  See
1243 L<perlrun> for the B<-i> switch.
1244
1245 =item Handle->output_field_separator( EXPR )
1246
1247 =item $OUTPUT_FIELD_SEPARATOR
1248
1249 =item $OFS
1250
1251 =item $,
1252 X<$,> X<$OFS> X<$OUTPUT_FIELD_SEPARATOR>
1253
1254 The output field separator for the print operator.  If defined, this
1255 value is printed between each of print's arguments.  Default is C<undef>.
1256
1257 Mnemonic: what is printed when there is a "," in your print statement.
1258
1259 =item HANDLE->input_line_number( EXPR )
1260
1261 =item $INPUT_LINE_NUMBER
1262
1263 =item $NR
1264
1265 =item $.
1266 X<$.> X<$NR> X<$INPUT_LINE_NUMBER> X<line number>
1267
1268 Current line number for the last filehandle accessed.
1269
1270 Each filehandle in Perl counts the number of lines that have been read
1271 from it.  (Depending on the value of C<$/>, Perl's idea of what
1272 constitutes a line may not match yours.)  When a line is read from a
1273 filehandle (via C<readline()> or C<< <> >>), or when C<tell()> or
1274 C<seek()> is called on it, C<$.> becomes an alias to the line counter
1275 for that filehandle.
1276
1277 You can adjust the counter by assigning to C<$.>, but this will not
1278 actually move the seek pointer.  I<Localizing C<$.> will not localize
1279 the filehandle's line count>.  Instead, it will localize perl's notion
1280 of which filehandle C<$.> is currently aliased to.
1281
1282 C<$.> is reset when the filehandle is closed, but B<not> when an open
1283 filehandle is reopened without an intervening C<close()>.  For more
1284 details, see L<perlop/"IE<sol>O Operators">.  Because C<< <> >> never does
1285 an explicit close, line numbers increase across C<ARGV> files (but see
1286 examples in L<perlfunc/eof>).
1287
1288 You can also use C<< HANDLE->input_line_number(EXPR) >> to access the
1289 line counter for a given filehandle without having to worry about
1290 which handle you last accessed.
1291
1292 Mnemonic: many programs use "." to mean the current line number.
1293
1294 =item HANDLE->input_record_separator( EXPR )
1295
1296 =item $INPUT_RECORD_SEPARATOR
1297
1298 =item $RS
1299
1300 =item $/
1301 X<$/> X<$RS> X<$INPUT_RECORD_SEPARATOR>
1302
1303 The input record separator, newline by default.  This influences Perl's
1304 idea of what a "line" is.  Works like B<awk>'s RS variable, including
1305 treating empty lines as a terminator if set to the null string (an
1306 empty line cannot contain any spaces or tabs).  You may set it to a
1307 multi-character string to match a multi-character terminator, or to
1308 C<undef> to read through the end of file.  Setting it to C<"\n\n">
1309 means something slightly different than setting to C<"">, if the file
1310 contains consecutive empty lines.  Setting to C<""> will treat two or
1311 more consecutive empty lines as a single empty line.  Setting to
1312 C<"\n\n"> will blindly assume that the next input character belongs to
1313 the next paragraph, even if it's a newline.
1314
1315     local $/;           # enable "slurp" mode
1316     local $_ = <FH>;    # whole file now here
1317     s/\n[ \t]+/ /g;
1318
1319 Remember: the value of C<$/> is a string, not a regex.  B<awk> has to
1320 be better for something. :-)
1321
1322 Setting C<$/> to a reference to an integer, scalar containing an
1323 integer, or scalar that's convertible to an integer will attempt to
1324 read records instead of lines, with the maximum record size being the
1325 referenced integer.  So this:
1326
1327     local $/ = \32768; # or \"32768", or \$var_containing_32768
1328     open my $fh, "<", $myfile or die $!;
1329     local $_ = <$fh>;
1330
1331 will read a record of no more than 32768 bytes from FILE.  If you're
1332 not reading from a record-oriented file (or your OS doesn't have
1333 record-oriented files), then you'll likely get a full chunk of data
1334 with every read.  If a record is larger than the record size you've
1335 set, you'll get the record back in pieces.  Trying to set the record
1336 size to zero or less will cause reading in the (rest of the) whole file.
1337
1338 On VMS, record reads are done with the equivalent of C<sysread>,
1339 so it's best not to mix record and non-record reads on the same
1340 file.  (This is unlikely to be a problem, because any file you'd
1341 want to read in record mode is probably unusable in line mode.)
1342 Non-VMS systems do normal I/O, so it's safe to mix record and
1343 non-record reads of a file.
1344
1345 See also L<perlport/"Newlines">. Also see L</$.>.
1346
1347 Mnemonic: / delimits line boundaries when quoting poetry.
1348
1349 =item Handle->output_record_separator( EXPR )
1350
1351 =item $OUTPUT_RECORD_SEPARATOR
1352
1353 =item $ORS
1354
1355 =item $\
1356 X<$\> X<$ORS> X<$OUTPUT_RECORD_SEPARATOR>
1357
1358 The output record separator for the print operator.  If defined, this
1359 value is printed after the last of print's arguments.  Default is C<undef>.
1360
1361 Mnemonic: you set C<$\> instead of adding "\n" at the end of the print.
1362 Also, it's just like C<$/>, but it's what you get "back" from Perl.
1363
1364 =item HANDLE->autoflush( EXPR )
1365
1366 =item $OUTPUT_AUTOFLUSH
1367
1368 =item $|
1369 X<$|> X<autoflush> X<flush> X<$OUTPUT_AUTOFLUSH>
1370
1371 If set to nonzero, forces a flush right away and after every write or
1372 print on the currently selected output channel.  Default is 0
1373 (regardless of whether the channel is really buffered by the system or
1374 not; C<$|> tells you only whether you've asked Perl explicitly to
1375 flush after each write).  STDOUT will typically be line buffered if
1376 output is to the terminal and block buffered otherwise.  Setting this
1377 variable is useful primarily when you are outputting to a pipe or
1378 socket, such as when you are running a Perl program under B<rsh> and
1379 want to see the output as it's happening.  This has no effect on input
1380 buffering.  See L<perlfunc/getc> for that.  See L<perlfunc/select> on
1381 how to select the output channel.  See also L<IO::Handle>.
1382
1383 Mnemonic: when you want your pipes to be piping hot.
1384
1385 =back
1386
1387 =head3 Variables related to formats
1388
1389 The special variables for formats are a subset of those for
1390 filehandles.  See L<perlform> for more information about Perl's
1391 formats.
1392
1393 =over 8
1394
1395 =item $ACCUMULATOR
1396
1397 =item $^A
1398 X<$^A> X<$ACCUMULATOR>
1399
1400 The current value of the C<write()> accumulator for C<format()> lines.
1401 A format contains C<formline()> calls that put their result into
1402 C<$^A>.  After calling its format, C<write()> prints out the contents
1403 of C<$^A> and empties.  So you never really see the contents of C<$^A>
1404 unless you call C<formline()> yourself and then look at it.  See
1405 L<perlform> and L<perlfunc/"formline PICTURE,LIST">.
1406
1407 =item HANDLE->format_formfeed(EXPR)
1408
1409 =item $FORMAT_FORMFEED
1410
1411 =item $^L
1412 X<$^L> X<$FORMAT_FORMFEED>
1413
1414 What formats output as a form feed.  The default is C<\f>.
1415
1416 =item HANDLE->format_page_number(EXPR)
1417
1418 =item $FORMAT_PAGE_NUMBER
1419
1420 =item $%
1421 X<$%> X<$FORMAT_PAGE_NUMBER>
1422
1423 The current page number of the currently selected output channel.
1424
1425 Mnemonic: C<%> is page number in B<nroff>.
1426
1427 =item HANDLE->format_lines_left(EXPR)
1428
1429 =item $FORMAT_LINES_LEFT
1430
1431 =item $-
1432 X<$-> X<$FORMAT_LINES_LEFT>
1433
1434 The number of lines left on the page of the currently selected output
1435 channel.
1436
1437 Mnemonic: lines_on_page - lines_printed.
1438
1439 =item Handle->format_line_break_characters EXPR
1440
1441 =item $FORMAT_LINE_BREAK_CHARACTERS
1442
1443 =item $:
1444 X<$:> X<FORMAT_LINE_BREAK_CHARACTERS>
1445
1446 The current set of characters after which a string may be broken to
1447 fill continuation fields (starting with C<^>) in a format.  The default is
1448 S<" \n-">, to break on a space, newline, or a hyphen.
1449
1450 Mnemonic: a "colon" in poetry is a part of a line.
1451
1452 =item HANDLE->format_lines_per_page(EXPR)
1453
1454 =item $FORMAT_LINES_PER_PAGE
1455
1456 =item $=
1457 X<$=> X<$FORMAT_LINES_PER_PAGE>
1458
1459 The current page length (printable lines) of the currently selected
1460 output channel.  The default is 60.
1461
1462 Mnemonic: = has horizontal lines.
1463
1464 =item HANDLE->format_top_name(EXPR)
1465
1466 =item $FORMAT_TOP_NAME
1467
1468 =item $^
1469 X<$^> X<$FORMAT_TOP_NAME>
1470
1471 The name of the current top-of-page format for the currently selected
1472 output channel.  The default is the name of the filehandle with C<_TOP>
1473 appended.  For example, the default format top name for the C<STDOUT>
1474 filehandle is C<STDOUT_TOP>.
1475
1476 Mnemonic: points to top of page.
1477
1478 =item HANDLE->format_name(EXPR)
1479
1480 =item $FORMAT_NAME
1481
1482 =item $~
1483 X<$~> X<$FORMAT_NAME>
1484
1485 The name of the current report format for the currently selected
1486 output channel.  The default format name is the same as the filehandle
1487 name.  For example, the default format name for the C<STDOUT>
1488 filehandle is just C<STDOUT>.
1489
1490 Mnemonic: brother to C<$^>.
1491
1492 =back
1493
1494 =head2 Error Variables
1495 X<error> X<exception>
1496
1497 The variables C<$@>, C<$!>, C<$^E>, and C<$?> contain information
1498 about different types of error conditions that may appear during
1499 execution of a Perl program.  The variables are shown ordered by
1500 the "distance" between the subsystem which reported the error and
1501 the Perl process.  They correspond to errors detected by the Perl
1502 interpreter, C library, operating system, or an external program,
1503 respectively.
1504
1505 To illustrate the differences between these variables, consider the
1506 following Perl expression, which uses a single-quoted string.  After
1507 execution of this statement, perl may have set all four special error
1508 variables:
1509
1510         eval q{
1511                 open my $pipe, "/cdrom/install |" or die $!;
1512                 my @res = <$pipe>;
1513                 close $pipe or die "bad pipe: $?, $!";
1514             };
1515
1516 When perl executes the C<eval()> expression, it translates the
1517 C<open()>, C<< <PIPE> >>, and C<close> calls in the C run-time library
1518 and thence to the operating system kernel.  perl sets C<$!> to
1519 the C library's C<errno> if one of these calls fails.
1520
1521 C<$@> is set if the string to be C<eval>-ed did not compile (this may
1522 happen if C<open> or C<close> were imported with bad prototypes), or
1523 if Perl code executed during evaluation C<die()>d.  In these cases the
1524 value of C<$@> is the compile error, or the argument to C<die> (which
1525 will interpolate C<$!> and C<$?>).  (See also L<Fatal>, though.)
1526
1527 Under a few operating systems, C<$^E> may contain a more verbose error
1528 indicator, such as in this case, "CDROM tray not closed."  Systems that
1529 do not support extended error messages leave C<$^E> the same as C<$!>.
1530
1531 Finally, C<$?> may be set to non-0 value if the external program
1532 F</cdrom/install> fails.  The upper eight bits reflect specific error
1533 conditions encountered by the program (the program's C<exit()> value).
1534 The lower eight bits reflect mode of failure, like signal death and
1535 core dump information.  See L<wait(2)> for details.  In contrast to
1536 C<$!> and C<$^E>, which are set only if error condition is detected,
1537 the variable C<$?> is set on each C<wait> or pipe C<close>,
1538 overwriting the old value.  This is more like C<$@>, which on every
1539 C<eval()> is always set on failure and cleared on success.
1540
1541 For more details, see the individual descriptions at C<$@>, C<$!>,
1542 C<$^E>, and C<$?>.
1543
1544 =over 8
1545
1546 =item ${^CHILD_ERROR_NATIVE}
1547 X<$^CHILD_ERROR_NATIVE>
1548
1549 The native status returned by the last pipe close, backtick (C<``>)
1550 command, successful call to C<wait()> or C<waitpid()>, or from the
1551 C<system()> operator.  On POSIX-like systems this value can be decoded
1552 with the WIFEXITED, WEXITSTATUS, WIFSIGNALED, WTERMSIG, WIFSTOPPED,
1553 WSTOPSIG and WIFCONTINUED functions provided by the L<POSIX> module.
1554
1555 Under VMS this reflects the actual VMS exit status; i.e. it is the
1556 same as C<$?> when the pragma C<use vmsish 'status'> is in effect.
1557
1558 This variable was added in Perl 5.8.9.
1559
1560 =item $EXTENDED_OS_ERROR
1561
1562 =item $^E
1563 X<$^E> X<$EXTENDED_OS_ERROR>
1564
1565 Error information specific to the current operating system.  At the
1566 moment, this differs from C<$!> under only VMS, OS/2, and Win32 (and
1567 for MacPerl).  On all other platforms, C<$^E> is always just the same
1568 as C<$!>.
1569
1570 Under VMS, C<$^E> provides the VMS status value from the last system
1571 error.  This is more specific information about the last system error
1572 than that provided by C<$!>.  This is particularly important when C<$!>
1573 is set to B<EVMSERR>.
1574
1575 Under OS/2, C<$^E> is set to the error code of the last call to OS/2
1576 API either via CRT, or directly from perl.
1577
1578 Under Win32, C<$^E> always returns the last error information reported
1579 by the Win32 call C<GetLastError()> which describes the last error
1580 from within the Win32 API.  Most Win32-specific code will report errors
1581 via C<$^E>.  ANSI C and Unix-like calls set C<errno> and so most
1582 portable Perl code will report errors via C<$!>.
1583
1584 Caveats mentioned in the description of C<$!> generally apply to
1585 C<$^E>, also.
1586
1587 This variable was added in Perl 5.003.
1588
1589 Mnemonic: Extra error explanation.
1590
1591 =item $EXCEPTIONS_BEING_CAUGHT
1592
1593 =item $^S
1594 X<$^S> X<$EXCEPTIONS_BEING_CAUGHT>
1595
1596 Current state of the interpreter.
1597
1598         $^S         State
1599         ---------   -------------------
1600         undef       Parsing module/eval
1601         true (1)    Executing an eval
1602         false (0)   Otherwise
1603
1604 The first state may happen in C<$SIG{__DIE__}> and C<$SIG{__WARN__}>
1605 handlers.
1606
1607 This variable was added in Perl 5.004.
1608
1609 =item $WARNING
1610
1611 =item $^W
1612 X<$^W> X<$WARNING>
1613
1614 The current value of the warning switch, initially true if B<-w> was
1615 used, false otherwise, but directly modifiable.
1616
1617 See also L<warnings>.
1618
1619 Mnemonic: related to the B<-w> switch.
1620
1621 =item ${^WARNING_BITS}
1622 X<${^WARNING_BITS}>
1623
1624 The current set of warning checks enabled by the C<use warnings> pragma.
1625 It has the same scoping as the C<$^H> and C<%^H> variables.  The exact
1626 values are considered internal to the L<warnings> pragma and may change
1627 between versions of Perl.
1628
1629 This variable was added in Perl 5.6.
1630
1631 =item $OS_ERROR
1632
1633 =item $ERRNO
1634
1635 =item $!
1636 X<$!> X<$ERRNO> X<$OS_ERROR>
1637
1638 When referenced, C<$!> retrieves the current value
1639 of the C C<errno> integer variable.
1640 If C<$!> is assigned a numerical value, that value is stored in C<errno>.
1641 When referenced as a string, C<$!> yields the system error string
1642 corresponding to C<errno>.
1643
1644 Many system or library calls set C<errno> if they fail,
1645 to indicate the cause of failure.  They usually do B<not>
1646 set C<errno> to zero if they succeed.  This means C<errno>,
1647 hence C<$!>, is meaningful only I<immediately> after a B<failure>:
1648
1649     if (open my $fh, "<", $filename) {
1650                 # Here $! is meaningless.
1651                 ...
1652     }
1653     else {
1654                 # ONLY here is $! meaningful.
1655                 ...
1656                 # Already here $! might be meaningless.
1657     }
1658     # Since here we might have either success or failure,
1659     # $! is meaningless.
1660
1661 Here, I<meaningless> means that C<$!> may be unrelated to the outcome
1662 of the C<open()> operator.  Assignment to C<$!> is similarly ephemeral.
1663 It can be used immediately before invoking the C<die()> operator,
1664 to set the exit value, or to inspect the system error string
1665 corresponding to error I<n>, or to restore C<$!> to a meaningful state.
1666
1667 Mnemonic: What just went bang?
1668
1669 =item %OS_ERROR
1670
1671 =item %ERRNO
1672
1673 =item %!
1674 X<%!> X<%OS_ERROR> X<%ERRNO>
1675
1676 Each element of C<%!> has a true value only if C<$!> is set to that
1677 value.  For example, C<$!{ENOENT}> is true if and only if the current
1678 value of C<$!> is C<ENOENT>; that is, if the most recent error was "No
1679 such file or directory" (or its moral equivalent: not all operating
1680 systems give that exact error, and certainly not all languages).  To
1681 check if a particular key is meaningful on your system, use C<exists
1682 $!{the_key}>; for a list of legal keys, use C<keys %!>.  See L<Errno>
1683 for more information, and also see L</$!>.
1684
1685 This variable was added in Perl 5.005.
1686
1687 =item $CHILD_ERROR
1688
1689 =item $?
1690 X<$?> X<$CHILD_ERROR>
1691
1692 The status returned by the last pipe close, backtick (C<``>) command,
1693 successful call to C<wait()> or C<waitpid()>, or from the C<system()>
1694 operator.  This is just the 16-bit status word returned by the
1695 traditional Unix C<wait()> system call (or else is made up to look
1696 like it).  Thus, the exit value of the subprocess is really (C<<< $? >>
1697 8 >>>), and C<$? & 127> gives which signal, if any, the process died
1698 from, and C<$? & 128> reports whether there was a core dump.
1699
1700 Additionally, if the C<h_errno> variable is supported in C, its value
1701 is returned via C<$?> if any C<gethost*()> function fails.
1702
1703 If you have installed a signal handler for C<SIGCHLD>, the
1704 value of C<$?> will usually be wrong outside that handler.
1705
1706 Inside an C<END> subroutine C<$?> contains the value that is going to be
1707 given to C<exit()>.  You can modify C<$?> in an C<END> subroutine to
1708 change the exit status of your program.  For example:
1709
1710     END {
1711         $? = 1 if $? == 255;  # die would make it 255
1712     }
1713
1714 Under VMS, the pragma C<use vmsish 'status'> makes C<$?> reflect the
1715 actual VMS exit status, instead of the default emulation of POSIX
1716 status; see L<perlvms/$?> for details.
1717
1718 Mnemonic: similar to B<sh> and B<ksh>.
1719
1720 =item $EVAL_ERROR
1721
1722 =item $@
1723 X<$@> X<$EVAL_ERROR>
1724
1725 The Perl syntax error message from the
1726 last C<eval()> operator.  If C<$@> is
1727 the null string, the last C<eval()> parsed and executed correctly
1728 (although the operations you invoked may have failed in the normal
1729 fashion).
1730
1731 Warning messages are not collected in this variable.  You can, however,
1732 set up a routine to process warnings by setting C<$SIG{__WARN__}> as
1733 described in L</%SIG>.
1734
1735 Mnemonic: Where was the syntax error "at"?
1736
1737 =back
1738
1739 =head2 Variables related to the interpreter state
1740
1741 These variables provide information about the current interpreter state.
1742
1743 =over 8
1744
1745 =item $COMPILING
1746
1747 =item $^C
1748 X<$^C> X<$COMPILING>
1749
1750 The current value of the flag associated with the B<-c> switch.
1751 Mainly of use with B<-MO=...> to allow code to alter its behavior
1752 when being compiled, such as for example to C<AUTOLOAD> at compile
1753 time rather than normal, deferred loading.  Setting
1754 C<$^C = 1> is similar to calling C<B::minus_c>.
1755
1756 This variable was added in Perl 5.6.
1757
1758 =item $DEBUGGING
1759
1760 =item $^D
1761 X<$^D> X<$DEBUGGING>
1762
1763 The current value of the debugging flags.  May be read or set.  Like its
1764 command-line equivalent, you can use numeric or symbolic values, eg
1765 C<$^D = 10> or C<$^D = "st">.
1766
1767 Mnemonic: value of B<-D> switch.
1768
1769 =item ${^ENCODING}
1770 X<${^ENCODING}>
1771
1772 The I<object reference> to the C<Encode> object that is used to convert
1773 the source code to Unicode.  Thanks to this variable your Perl script
1774 does not have to be written in UTF-8.  Default is I<undef>.  The direct
1775 manipulation of this variable is highly discouraged.
1776
1777 This variable was added in Perl 5.8.2.
1778
1779 =item ${^GLOBAL_PHASE}
1780 X<${^GLOBAL_PHASE}>
1781
1782 The current phase of the perl interpreter.
1783
1784 Possible values are:
1785
1786 =over 8
1787
1788 =item CONSTRUCT
1789
1790 The C<PerlInterpreter*> is being constructed via C<perl_construct>.  This
1791 value is mostly there for completeness and for use via the
1792 underlying C variable C<PL_phase>.  It's not really possible for Perl
1793 code to be executed unless construction of the interpreter is
1794 finished.
1795
1796 =item START
1797
1798 This is the global compile-time.  That includes, basically, every
1799 C<BEGIN> block executed directly or indirectly from during the
1800 compile-time of the top-level program.
1801
1802 This phase is not called "BEGIN" to avoid confusion with
1803 C<BEGIN>-blocks, as those are executed during compile-time of any
1804 compilation unit, not just the top-level program.  A new, localised
1805 compile-time entered at run-time, for example by constructs as
1806 C<eval "use SomeModule"> are not global interpreter phases, and
1807 therefore aren't reflected by C<${^GLOBAL_PHASE}>.
1808
1809 =item CHECK
1810
1811 Execution of any C<CHECK> blocks.
1812
1813 =item INIT
1814
1815 Similar to "CHECK", but for C<INIT>-blocks, not C<CHECK> blocks.
1816
1817 =item RUN
1818
1819 The main run-time, i.e. the execution of C<PL_main_root>.
1820
1821 =item END
1822
1823 Execution of any C<END> blocks.
1824
1825 =item DESTRUCT
1826
1827 Global destruction.
1828
1829 =back
1830
1831 Also note that there's no value for UNITCHECK-blocks.  That's because
1832 those are run for each compilation unit individually, and therefore is
1833 not a global interpreter phase.
1834
1835 Not every program has to go through each of the possible phases, but
1836 transition from one phase to another can only happen in the order
1837 described in the above list.
1838
1839 An example of all of the phases Perl code can see:
1840
1841     BEGIN { print "compile-time: ${^GLOBAL_PHASE}\n" }
1842
1843     INIT  { print "init-time: ${^GLOBAL_PHASE}\n" }
1844
1845     CHECK { print "check-time: ${^GLOBAL_PHASE}\n" }
1846
1847     {
1848         package Print::Phase;
1849
1850         sub new {
1851             my ($class, $time) = @_;
1852             return bless \$time, $class;
1853         }
1854
1855         sub DESTROY {
1856             my $self = shift;
1857             print "$$self: ${^GLOBAL_PHASE}\n";
1858         }
1859     }
1860
1861     print "run-time: ${^GLOBAL_PHASE}\n";
1862
1863     my $runtime = Print::Phase->new(
1864         "lexical variables are garbage collected before END"
1865     );
1866
1867     END   { print "end-time: ${^GLOBAL_PHASE}\n" }
1868
1869     our $destruct = Print::Phase->new(
1870         "package variables are garbage collected after END"
1871     );
1872
1873 This will print out
1874
1875     compile-time: START
1876     check-time: CHECK
1877     init-time: INIT
1878     run-time: RUN
1879     lexical variables are garbage collected before END: RUN
1880     end-time: END
1881     package variables are garbage collected after END: DESTRUCT
1882
1883 This variable was added in Perl 5.14.0.
1884
1885 =item $^H
1886 X<$^H>
1887
1888 WARNING: This variable is strictly for
1889 internal use only.  Its availability,
1890 behavior, and contents are subject to change without notice.
1891
1892 This variable contains compile-time hints for the Perl interpreter.  At the
1893 end of compilation of a BLOCK the value of this variable is restored to the
1894 value when the interpreter started to compile the BLOCK.
1895
1896 When perl begins to parse any block construct that provides a lexical scope
1897 (e.g., eval body, required file, subroutine body, loop body, or conditional
1898 block), the existing value of C<$^H> is saved, but its value is left unchanged.
1899 When the compilation of the block is completed, it regains the saved value.
1900 Between the points where its value is saved and restored, code that
1901 executes within BEGIN blocks is free to change the value of C<$^H>.
1902
1903 This behavior provides the semantic of lexical scoping, and is used in,
1904 for instance, the C<use strict> pragma.
1905
1906 The contents should be an integer; different bits of it are used for
1907 different pragmatic flags.  Here's an example:
1908
1909         sub add_100 { $^H |= 0x100 }
1910
1911         sub foo {
1912                 BEGIN { add_100() }
1913                 bar->baz($boon);
1914         }
1915
1916 Consider what happens during execution of the BEGIN block.  At this point
1917 the BEGIN block has already been compiled, but the body of C<foo()> is still
1918 being compiled.  The new value of C<$^H>
1919 will therefore be visible only while
1920 the body of C<foo()> is being compiled.
1921
1922 Substitution of C<BEGIN { add_100() }> block with:
1923
1924         BEGIN { require strict; strict->import('vars') }
1925
1926 demonstrates how C<use strict 'vars'> is implemented.  Here's a conditional
1927 version of the same lexical pragma:
1928
1929         BEGIN { require strict; strict->import('vars') if $condition }
1930
1931 This variable was added in Perl 5.003.
1932
1933 =item %^H
1934 X<%^H>
1935
1936 The C<%^H> hash provides the same scoping semantic as C<$^H>.  This makes
1937 it useful for implementation of lexically scoped pragmas.  See
1938 L<perlpragma>.
1939
1940 When putting items into C<%^H>, in order to avoid conflicting with other
1941 users of the hash there is a convention regarding which keys to use.
1942 A module should use only keys that begin with the module's name (the
1943 name of its main package) and a "/" character.  For example, a module
1944 C<Foo::Bar> should use keys such as C<Foo::Bar/baz>.
1945
1946 This variable was added in Perl 5.6.
1947
1948 =item ${^OPEN}
1949 X<${^OPEN}>
1950
1951 An internal variable used by PerlIO.  A string in two parts, separated
1952 by a C<\0> byte, the first part describes the input layers, the second
1953 part describes the output layers.
1954
1955 This variable was added in Perl 5.8.0.
1956
1957 =item $PERLDB
1958
1959 =item $^P
1960 X<$^P> X<$PERLDB>
1961
1962 The internal variable for debugging support.  The meanings of the
1963 various bits are subject to change, but currently indicate:
1964
1965 =over 6
1966
1967 =item 0x01
1968
1969 Debug subroutine enter/exit.
1970
1971 =item 0x02
1972
1973 Line-by-line debugging.  Causes C<DB::DB()> subroutine to be called for
1974 each statement executed.  Also causes saving source code lines (like
1975 0x400).
1976
1977 =item 0x04
1978
1979 Switch off optimizations.
1980
1981 =item 0x08
1982
1983 Preserve more data for future interactive inspections.
1984
1985 =item 0x10
1986
1987 Keep info about source lines on which a subroutine is defined.
1988
1989 =item 0x20
1990
1991 Start with single-step on.
1992
1993 =item 0x40
1994
1995 Use subroutine address instead of name when reporting.
1996
1997 =item 0x80
1998
1999 Report C<goto &subroutine> as well.
2000
2001 =item 0x100
2002
2003 Provide informative "file" names for evals based on the place they were compiled.
2004
2005 =item 0x200
2006
2007 Provide informative names to anonymous subroutines based on the place they
2008 were compiled.
2009
2010 =item 0x400
2011
2012 Save source code lines into C<@{"_<$filename"}>.
2013
2014 =back
2015
2016 Some bits may be relevant at compile-time only, some at
2017 run-time only.  This is a new mechanism and the details may change.
2018 See also L<perldebguts>.
2019
2020 =item ${^TAINT}
2021 X<${^TAINT}>
2022
2023 Reflects if taint mode is on or off.  1 for on (the program was run with
2024 B<-T>), 0 for off, -1 when only taint warnings are enabled (i.e. with
2025 B<-t> or B<-TU>).
2026
2027 This variable is read-only.
2028
2029 This variable was added in Perl 5.8.
2030
2031 =item ${^UNICODE}
2032 X<${^UNICODE}>
2033
2034 Reflects certain Unicode settings of Perl.  See L<perlrun>
2035 documentation for the C<-C> switch for more information about
2036 the possible values.
2037
2038 This variable is set during Perl startup and is thereafter read-only.
2039
2040 This variable was added in Perl 5.8.2.
2041
2042 =item ${^UTF8CACHE}
2043 X<${^UTF8CACHE}>
2044
2045 This variable controls the state of the internal UTF-8 offset caching code.
2046 1 for on (the default), 0 for off, -1 to debug the caching code by checking
2047 all its results against linear scans, and panicking on any discrepancy.
2048
2049 This variable was added in Perl 5.8.9.
2050
2051 =item ${^UTF8LOCALE}
2052 X<${^UTF8LOCALE}>
2053
2054 This variable indicates whether a UTF-8 locale was detected by perl at
2055 startup.  This information is used by perl when it's in
2056 adjust-utf8ness-to-locale mode (as when run with the C<-CL> command-line
2057 switch); see L<perlrun> for more info on this.
2058
2059 This variable was added in Perl 5.8.8.
2060
2061 =back
2062
2063 =head2 Deprecated and removed variables
2064
2065 Deprecating a variable announces the intent of the perl maintainers to
2066 eventually remove the variable from the language.  It may still be
2067 available despite its status.  Using a deprecated variable triggers
2068 a warning.
2069
2070 Once a variable is removed, its use triggers an error telling you
2071 the variable is unsupported.
2072
2073 See L<perldiag> for details about error messages.
2074
2075 =over 8
2076
2077 =item $OFMT
2078
2079 =item $#
2080 X<$#> X<$OFMT>
2081
2082 C<$#> was a variable that could be used to format printed numbers.
2083 After a deprecation cycle, its magic was removed in Perl 5.10 and
2084 using it now triggers a warning: C<$# is no longer supported>.
2085
2086 This is not the sigil you use in front of an array name to get the
2087 last index, like C<$#array>.  That's still how you get the last index
2088 of an array in Perl.  The two have nothing to do with each other.
2089
2090 Deprecated in Perl 5.
2091
2092 Removed in Perl 5.10.
2093
2094 =item $*
2095 X<$*>
2096
2097 C<$*> was a variable that you could use to enable multiline matching.
2098 After a deprecation cycle, its magic was removed in Perl 5.10.
2099 Using it now triggers a warning: C<$* is no longer supported>.
2100 You should use the C</s> and C</m> regexp modifiers instead.
2101
2102 Deprecated in Perl 5.
2103
2104 Removed in Perl 5.10.
2105
2106 =item $ARRAY_BASE
2107
2108 =item $[
2109 X<$[> X<$ARRAY_BASE>
2110
2111 This variable stores the index of the first element in an array, and
2112 of the first character in a substring.  The default is 0, but you could
2113 theoretically set it to 1 to make Perl behave more like B<awk> (or Fortran)
2114 when subscripting and when evaluating the index() and substr() functions.
2115
2116 As of release 5 of Perl, assignment to C<$[> is treated as a compiler
2117 directive, and cannot influence the behavior of any other file.
2118 (That's why you can only assign compile-time constants to it.)
2119 Its use is highly discouraged.
2120
2121 Prior to Perl 5.10, assignment to C<$[> could be seen from outer lexical
2122 scopes in the same file, unlike other compile-time directives (such as
2123 L<strict>).  Using local() on it would bind its value strictly to a lexical
2124 block.  Now it is always lexically scoped.
2125
2126 As of Perl 5.16, it is implemented by the L<arybase> module.  See
2127 L<arybase> for more details on its behaviour.
2128
2129 Under C<use v5.16>, or C<no feature "array_base">, C<$[> no longer has any
2130 effect, and always contains 0.  Assigning 0 to it is permitted, but any
2131 other value will produce an error.
2132
2133 Mnemonic: [ begins subscripts.
2134
2135 Deprecated in Perl 5.12.
2136
2137 =item $OLD_PERL_VERSION
2138
2139 =item $]
2140 X<$]> X<$OLD_PERL_VERSION>
2141
2142 See L</$^V> for a more modern representation of the Perl version that allows
2143 accurate string comparisons.
2144
2145 The version + patchlevel / 1000 of the Perl interpreter.  This variable
2146 can be used to determine whether the Perl interpreter executing a
2147 script is in the right range of versions:
2148
2149     warn "No checksumming!\n" if $] < 3.019;
2150
2151 The floating point representation can sometimes lead to inaccurate
2152 numeric comparisons.
2153
2154 See also the documentation of C<use VERSION> and C<require VERSION>
2155 for a convenient way to fail if the running Perl interpreter is too old.
2156
2157 Mnemonic: Is this version of perl in the right bracket?
2158
2159 =back
2160
2161 =cut