This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
undo changes to Exporter.pm from #2312
[perl5.git] / lib / Exporter.pm
1 package Exporter;
2
3 require 5.001;
4
5 #
6 # We go to a lot of trouble not to 'require Carp' at file scope,
7 #  because Carp requires Exporter, and something has to give.
8 #
9
10 $ExportLevel = 0;
11 $Verbose = 0 unless $Verbose;
12
13 sub export {
14
15     # First make import warnings look like they're coming from the "use".
16     local $SIG{__WARN__} = sub {
17         my $text = shift;
18         if ($text =~ s/ at \S*Exporter.pm line \d+.*\n//) {
19             require Carp;
20             local $Carp::CarpLevel = 1; # ignore package calling us too.
21             Carp::carp($text);
22         }
23         else {
24             warn $text;
25         }
26     };
27     local $SIG{__DIE__} = sub {
28         require Carp;
29         local $Carp::CarpLevel = 1;     # ignore package calling us too.
30         Carp::croak("$_[0]Illegal null symbol in \@${1}::EXPORT")
31             if $_[0] =~ /^Unable to create sub named "(.*?)::"/;
32     };
33
34     my($pkg, $callpkg, @imports) = @_;
35     my($type, $sym, $oops);
36     *exports = *{"${pkg}::EXPORT"};
37
38     if (@imports) {
39         if (!%exports) {
40             grep(s/^&//, @exports);
41             @exports{@exports} = (1) x @exports;
42             my $ok = \@{"${pkg}::EXPORT_OK"};
43             if (@$ok) {
44                 grep(s/^&//, @$ok);
45                 @exports{@$ok} = (1) x @$ok;
46             }
47         }
48
49         if ($imports[0] =~ m#^[/!:]#){
50             my $tagsref = \%{"${pkg}::EXPORT_TAGS"};
51             my $tagdata;
52             my %imports;
53             my($remove, $spec, @names, @allexports);
54             # negated first item implies starting with default set:
55             unshift @imports, ':DEFAULT' if $imports[0] =~ m/^!/;
56             foreach $spec (@imports){
57                 $remove = $spec =~ s/^!//;
58
59                 if ($spec =~ s/^://){
60                     if ($spec eq 'DEFAULT'){
61                         @names = @exports;
62                     }
63                     elsif ($tagdata = $tagsref->{$spec}) {
64                         @names = @$tagdata;
65                     }
66                     else {
67                         warn qq["$spec" is not defined in %${pkg}::EXPORT_TAGS];
68                         ++$oops;
69                         next;
70                     }
71                 }
72                 elsif ($spec =~ m:^/(.*)/$:){
73                     my $patn = $1;
74                     @allexports = keys %exports unless @allexports; # only do keys once
75                     @names = grep(/$patn/, @allexports); # not anchored by default
76                 }
77                 else {
78                     @names = ($spec); # is a normal symbol name
79                 }
80
81                 warn "Import ".($remove ? "del":"add").": @names "
82                     if $Verbose;
83
84                 if ($remove) {
85                    foreach $sym (@names) { delete $imports{$sym} } 
86                 }
87                 else {
88                     @imports{@names} = (1) x @names;
89                 }
90             }
91             @imports = keys %imports;
92         }
93
94         foreach $sym (@imports) {
95             if (!$exports{$sym}) {
96                 if ($sym =~ m/^\d/) {
97                     $pkg->require_version($sym);
98                     # If the version number was the only thing specified
99                     # then we should act as if nothing was specified:
100                     if (@imports == 1) {
101                         @imports = @exports;
102                         last;
103                     }
104                     # We need a way to emulate 'use Foo ()' but still
105                     # allow an easy version check: "use Foo 1.23, ''";
106                     if (@imports == 2 and !$imports[1]) {
107                         @imports = ();
108                         last;
109                     }
110                 } elsif ($sym !~ s/^&// || !$exports{$sym}) {
111                     require Carp;
112                     Carp::carp(qq["$sym" is not exported by the $pkg module]);
113                     $oops++;
114                 }
115             }
116         }
117         if ($oops) {
118             require Carp;
119             Carp::croak("Can't continue after import errors");
120         }
121     }
122     else {
123         @imports = @exports;
124     }
125
126     *fail = *{"${pkg}::EXPORT_FAIL"};
127     if (@fail) {
128         if (!%fail) {
129             # Build cache of symbols. Optimise the lookup by adding
130             # barewords twice... both with and without a leading &.
131             # (Technique could be applied to %exports cache at cost of memory)
132             my @expanded = map { /^\w/ ? ($_, '&'.$_) : $_ } @fail;
133             warn "${pkg}::EXPORT_FAIL cached: @expanded" if $Verbose;
134             @fail{@expanded} = (1) x @expanded;
135         }
136         my @failed;
137         foreach $sym (@imports) { push(@failed, $sym) if $fail{$sym} }
138         if (@failed) {
139             @failed = $pkg->export_fail(@failed);
140             foreach $sym (@failed) {
141                 require Carp;
142                 Carp::carp(qq["$sym" is not implemented by the $pkg module ],
143                         "on this architecture");
144             }
145             if (@failed) {
146                 require Carp;
147                 Carp::croak("Can't continue after import errors");
148             }
149         }
150     }
151
152     warn "Importing into $callpkg from $pkg: ",
153                 join(", ",sort @imports) if $Verbose;
154
155     foreach $sym (@imports) {
156         # shortcut for the common case of no type character
157         (*{"${callpkg}::$sym"} = \&{"${pkg}::$sym"}, next)
158             unless $sym =~ s/^(\W)//;
159         $type = $1;
160         *{"${callpkg}::$sym"} =
161             $type eq '&' ? \&{"${pkg}::$sym"} :
162             $type eq '$' ? \${"${pkg}::$sym"} :
163             $type eq '@' ? \@{"${pkg}::$sym"} :
164             $type eq '%' ? \%{"${pkg}::$sym"} :
165             $type eq '*' ?  *{"${pkg}::$sym"} :
166             do { require Carp; Carp::croak("Can't export symbol: $type$sym") };
167     }
168 }
169
170 sub export_to_level
171 {
172       my $pkg = shift;
173       my ($level, $junk) = (shift, shift);  # need to get rid of first arg
174                                             # we know it already.
175       my $callpkg = caller($level);
176       $pkg->export($callpkg, @_);
177 }
178
179 sub import {
180     my $pkg = shift;
181     my $callpkg = caller($ExportLevel);
182     export $pkg, $callpkg, @_;
183 }
184
185
186
187 # Utility functions
188
189 sub _push_tags {
190     my($pkg, $var, $syms) = @_;
191     my $nontag;
192     *export_tags = \%{"${pkg}::EXPORT_TAGS"};
193     push(@{"${pkg}::$var"},
194         map { $export_tags{$_} ? @{$export_tags{$_}} : scalar(++$nontag,$_) }
195                 (@$syms) ? @$syms : keys %export_tags);
196     if ($nontag and $^W) {
197         # This may change to a die one day
198         require Carp;
199         Carp::carp("Some names are not tags");
200     }
201 }
202
203 sub export_tags    { _push_tags((caller)[0], "EXPORT",    \@_) }
204 sub export_ok_tags { _push_tags((caller)[0], "EXPORT_OK", \@_) }
205
206
207 # Default methods
208
209 sub export_fail {
210     my $self = shift;
211     @_;
212 }
213
214 sub require_version {
215     my($self, $wanted) = @_;
216     my $pkg = ref $self || $self;
217     my $version = ${"${pkg}::VERSION"};
218     if (!$version or $version < $wanted) {
219         $version ||= "(undef)";
220         my $file = $INC{"$pkg.pm"};
221         $file &&= " ($file)";
222         require Carp;
223         Carp::croak("$pkg $wanted required--this is only version $version$file")
224     }
225     $version;
226 }
227
228 1;
229
230 # A simple self test harness. Change 'require Carp' to 'use Carp ()' for testing.
231 # package main; eval(join('',<DATA>)) or die $@ unless caller;
232 __END__
233 package Test;
234 $INC{'Exporter.pm'} = 1;
235 @ISA = qw(Exporter);
236 @EXPORT      = qw(A1 A2 A3 A4 A5);
237 @EXPORT_OK   = qw(B1 B2 B3 B4 B5);
238 %EXPORT_TAGS = (T1=>[qw(A1 A2 B1 B2)], T2=>[qw(A1 A2 B3 B4)], T3=>[qw(X3)]);
239 @EXPORT_FAIL = qw(B4);
240 Exporter::export_ok_tags('T3', 'unknown_tag');
241 sub export_fail {
242     map { "Test::$_" } @_       # edit symbols just as an example
243 }
244
245 package main;
246 $Exporter::Verbose = 1;
247 #import Test;
248 #import Test qw(X3);            # export ok via export_ok_tags()
249 #import Test qw(:T1 !A2 /5/ !/3/ B5);
250 import Test qw(:T2 !B4);
251 import Test qw(:T2);            # should fail
252 1;
253
254 =head1 NAME
255
256 Exporter - Implements default import method for modules
257
258 =head1 SYNOPSIS
259
260 In module ModuleName.pm:
261
262   package ModuleName;
263   require Exporter;
264   @ISA = qw(Exporter);
265
266   @EXPORT = qw(...);            # symbols to export by default
267   @EXPORT_OK = qw(...);         # symbols to export on request
268   %EXPORT_TAGS = tag => [...];  # define names for sets of symbols
269
270 In other files which wish to use ModuleName:
271
272   use ModuleName;               # import default symbols into my package
273
274   use ModuleName qw(...);       # import listed symbols into my package
275
276   use ModuleName ();            # do not import any symbols
277
278 =head1 DESCRIPTION
279
280 The Exporter module implements a default C<import> method which
281 many modules choose to inherit rather than implement their own.
282
283 Perl automatically calls the C<import> method when processing a
284 C<use> statement for a module. Modules and C<use> are documented
285 in L<perlfunc> and L<perlmod>. Understanding the concept of
286 modules and how the C<use> statement operates is important to
287 understanding the Exporter.
288
289 =head2 Selecting What To Export
290
291 Do B<not> export method names!
292
293 Do B<not> export anything else by default without a good reason!
294
295 Exports pollute the namespace of the module user.  If you must export
296 try to use @EXPORT_OK in preference to @EXPORT and avoid short or
297 common symbol names to reduce the risk of name clashes.
298
299 Generally anything not exported is still accessible from outside the
300 module using the ModuleName::item_name (or $blessed_ref-E<gt>method)
301 syntax.  By convention you can use a leading underscore on names to
302 informally indicate that they are 'internal' and not for public use.
303
304 (It is actually possible to get private functions by saying:
305
306   my $subref = sub { ... };
307   &$subref;
308
309 But there's no way to call that directly as a method, since a method
310 must have a name in the symbol table.)
311
312 As a general rule, if the module is trying to be object oriented
313 then export nothing. If it's just a collection of functions then
314 @EXPORT_OK anything but use @EXPORT with caution.
315
316 Other module design guidelines can be found in L<perlmod>.
317
318 =head2 Specialised Import Lists
319
320 If the first entry in an import list begins with !, : or / then the
321 list is treated as a series of specifications which either add to or
322 delete from the list of names to import. They are processed left to
323 right. Specifications are in the form:
324
325     [!]name         This name only
326     [!]:DEFAULT     All names in @EXPORT
327     [!]:tag         All names in $EXPORT_TAGS{tag} anonymous list
328     [!]/pattern/    All names in @EXPORT and @EXPORT_OK which match
329
330 A leading ! indicates that matching names should be deleted from the
331 list of names to import.  If the first specification is a deletion it
332 is treated as though preceded by :DEFAULT. If you just want to import
333 extra names in addition to the default set you will still need to
334 include :DEFAULT explicitly.
335
336 e.g., Module.pm defines:
337
338     @EXPORT      = qw(A1 A2 A3 A4 A5);
339     @EXPORT_OK   = qw(B1 B2 B3 B4 B5);
340     %EXPORT_TAGS = (T1 => [qw(A1 A2 B1 B2)], T2 => [qw(A1 A2 B3 B4)]);
341
342     Note that you cannot use tags in @EXPORT or @EXPORT_OK.
343     Names in EXPORT_TAGS must also appear in @EXPORT or @EXPORT_OK.
344
345 An application using Module can say something like:
346
347     use Module qw(:DEFAULT :T2 !B3 A3);
348
349 Other examples include:
350
351     use Socket qw(!/^[AP]F_/ !SOMAXCONN !SOL_SOCKET);
352     use POSIX  qw(:errno_h :termios_h !TCSADRAIN !/^EXIT/);
353
354 Remember that most patterns (using //) will need to be anchored
355 with a leading ^, e.g., C</^EXIT/> rather than C</EXIT/>.
356
357 You can say C<BEGIN { $Exporter::Verbose=1 }> to see how the
358 specifications are being processed and what is actually being imported
359 into modules.
360
361 =head2 Exporting without using Export's import method
362
363 Exporter has a special method, 'export_to_level' which is used in situations
364 where you can't directly call Export's import method. The export_to_level
365 method looks like:
366
367 MyPackage->export_to_level($where_to_export, @what_to_export);
368
369 where $where_to_export is an integer telling how far up the calling stack
370 to export your symbols, and @what_to_export is an array telling what
371 symbols *to* export (usually this is @_).
372
373 For example, suppose that you have a module, A, which already has an
374 import function:
375
376 package A;
377
378 @ISA = qw(Exporter);
379 @EXPORT_OK = qw ($b);
380
381 sub import
382 {
383     $A::b = 1;     # not a very useful import method
384 }
385
386 and you want to Export symbol $A::b back to the module that called 
387 package A. Since Exporter relies on the import method to work, via 
388 inheritance, as it stands Exporter::import() will never get called. 
389 Instead, say the following:
390
391 package A;
392 @ISA = qw(Exporter);
393 @EXPORT_OK = qw ($b);
394
395 sub import
396 {
397     $A::b = 1;
398     A->export_to_level(1, @_);
399 }
400
401 This will export the symbols one level 'above' the current package - ie: to 
402 the program or module that used package A. 
403
404 Note: Be careful not to modify '@_' at all before you call export_to_level
405 - or people using your package will get very unexplained results!
406
407
408 =head2 Module Version Checking
409
410 The Exporter module will convert an attempt to import a number from a
411 module into a call to $module_name-E<gt>require_version($value). This can
412 be used to validate that the version of the module being used is
413 greater than or equal to the required version.
414
415 The Exporter module supplies a default require_version method which
416 checks the value of $VERSION in the exporting module.
417
418 Since the default require_version method treats the $VERSION number as
419 a simple numeric value it will regard version 1.10 as lower than
420 1.9. For this reason it is strongly recommended that you use numbers
421 with at least two decimal places, e.g., 1.09.
422
423 =head2 Managing Unknown Symbols
424
425 In some situations you may want to prevent certain symbols from being
426 exported. Typically this applies to extensions which have functions
427 or constants that may not exist on some systems.
428
429 The names of any symbols that cannot be exported should be listed
430 in the C<@EXPORT_FAIL> array.
431
432 If a module attempts to import any of these symbols the Exporter
433 will give the module an opportunity to handle the situation before
434 generating an error. The Exporter will call an export_fail method
435 with a list of the failed symbols:
436
437   @failed_symbols = $module_name->export_fail(@failed_symbols);
438
439 If the export_fail method returns an empty list then no error is
440 recorded and all the requested symbols are exported. If the returned
441 list is not empty then an error is generated for each symbol and the
442 export fails. The Exporter provides a default export_fail method which
443 simply returns the list unchanged.
444
445 Uses for the export_fail method include giving better error messages
446 for some symbols and performing lazy architectural checks (put more
447 symbols into @EXPORT_FAIL by default and then take them out if someone
448 actually tries to use them and an expensive check shows that they are
449 usable on that platform).
450
451 =head2 Tag Handling Utility Functions
452
453 Since the symbols listed within %EXPORT_TAGS must also appear in either
454 @EXPORT or @EXPORT_OK, two utility functions are provided which allow
455 you to easily add tagged sets of symbols to @EXPORT or @EXPORT_OK:
456
457   %EXPORT_TAGS = (foo => [qw(aa bb cc)], bar => [qw(aa cc dd)]);
458
459   Exporter::export_tags('foo');     # add aa, bb and cc to @EXPORT
460   Exporter::export_ok_tags('bar');  # add aa, cc and dd to @EXPORT_OK
461
462 Any names which are not tags are added to @EXPORT or @EXPORT_OK
463 unchanged but will trigger a warning (with C<-w>) to avoid misspelt tags
464 names being silently added to @EXPORT or @EXPORT_OK. Future versions
465 may make this a fatal error.
466
467 =cut