This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Storable: throw exception on huge values
[perl5.git] / dist / Storable / t / huge.t
1 #!./perl
2
3 use strict;
4 use warnings;
5
6 use Config;
7 use Storable qw(dclone);
8 use Test::More;
9
10 BEGIN {
11     plan skip_all => 'Storable was not built'
12         if $ENV{PERL_CORE} && $Config{'extensions'} !~ /\b Storable \b/x;
13     plan skip_all => 'Need 64-bit pointers for this test'
14         if $Config{ptrsize} < 8;
15     plan skip_all => 'Need ~4 GiB of core for this test'
16         if !$ENV{PERL_TEST_MEMORY} || $ENV{PERL_TEST_MEMORY} < 4;
17 }
18
19 # Just too big to fit in an I32.
20 my $huge = int(2 ** 31);
21
22 # For now, all of these should throw an exception. Actually storing and
23 # retrieving them would require changing the serialisation format, and
24 # that's a larger task than I'm looking to undertake right now.
25 my @cases = (
26     ['huge string',
27      sub { my $s = 'x' x $huge; \$s }],
28
29     ['huge array',
30      sub { my @x; $x[$huge] = undef; \@x }],
31
32     ['array with huge element',
33      sub { my $s = 'x' x $huge; [$s] }],
34
35     # A hash with a huge number of keys would require tens of gigabytes of
36     # memory, which doesn't seem like a good idea even for this test file.
37
38     ['hash with huge value',
39      sub { my $s = 'x' x $huge; +{ foo => $s } }],
40
41     # Can't test hash with a huge key, because Perl internals currently
42     # limit hash keys to <2**31 anyway
43 );
44
45 plan tests => scalar @cases;
46
47 for (@cases) {
48     my ($desc, $build) = @$_;
49     note "building test input: $desc";
50     my $input = $build->();
51     note "running test: $desc";
52     my ($exn, $clone);
53     $exn = $@ if !eval { $clone = dclone($input); 1 };
54     like($exn, qr/^Storable cannot yet handle data that needs a 64-bit machine\b/,
55          "$desc: throw an exception, not a segfault or panic");
56
57     # Ensure the huge objects are freed right now:
58     undef $input;
59     undef $clone;
60 }