This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
[perl5db] Convert variables to our.
[perl5.git] / lib / perl5db.pl
1
2 =head1 NAME
3
4 perl5db.pl - the perl debugger
5
6 =head1 SYNOPSIS
7
8     perl -d  your_Perl_script
9
10 =head1 DESCRIPTION
11
12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
13 you invoke a script with C<perl -d>. This documentation tries to outline the
14 structure and services provided by C<perl5db.pl>, and to describe how you
15 can use them.
16
17 =head1 GENERAL NOTES
18
19 The debugger can look pretty forbidding to many Perl programmers. There are
20 a number of reasons for this, many stemming out of the debugger's history.
21
22 When the debugger was first written, Perl didn't have a lot of its nicer
23 features - no references, no lexical variables, no closures, no object-oriented
24 programming. So a lot of the things one would normally have done using such
25 features was done using global variables, globs and the C<local()> operator
26 in creative ways.
27
28 Some of these have survived into the current debugger; a few of the more
29 interesting and still-useful idioms are noted in this section, along with notes
30 on the comments themselves.
31
32 =head2 Why not use more lexicals?
33
34 Experienced Perl programmers will note that the debugger code tends to use
35 mostly package globals rather than lexically-scoped variables. This is done
36 to allow a significant amount of control of the debugger from outside the
37 debugger itself.
38
39 Unfortunately, though the variables are accessible, they're not well
40 documented, so it's generally been a decision that hasn't made a lot of
41 difference to most users. Where appropriate, comments have been added to
42 make variables more accessible and usable, with the understanding that these
43 I<are> debugger internals, and are therefore subject to change. Future
44 development should probably attempt to replace the globals with a well-defined
45 API, but for now, the variables are what we've got.
46
47 =head2 Automated variable stacking via C<local()>
48
49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
50 temporary copy of a variable in the current scope. When the scope ends, the
51 old copy is restored. This is often used in the debugger to handle the
52 automatic stacking of variables during recursive calls:
53
54      sub foo {
55         local $some_global++;
56
57         # Do some stuff, then ...
58         return;
59      }
60
61 What happens is that on entry to the subroutine, C<$some_global> is localized,
62 then altered. When the subroutine returns, Perl automatically undoes the
63 localization, restoring the previous value. Voila, automatic stack management.
64
65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
66 which lets the debugger get control inside of C<eval>'ed code. The debugger
67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
71
72 In any case, watch for this pattern. It occurs fairly often.
73
74 =head2 The C<^> trick
75
76 This is used to cleverly reverse the sense of a logical test depending on
77 the value of an auxiliary variable. For instance, the debugger's C<S>
78 (search for subroutines by pattern) allows you to negate the pattern
79 like this:
80
81    # Find all non-'foo' subs:
82    S !/foo/
83
84 Boolean algebra states that the truth table for XOR looks like this:
85
86 =over 4
87
88 =item * 0 ^ 0 = 0
89
90 (! not present and no match) --> false, don't print
91
92 =item * 0 ^ 1 = 1
93
94 (! not present and matches) --> true, print
95
96 =item * 1 ^ 0 = 1
97
98 (! present and no match) --> true, print
99
100 =item * 1 ^ 1 = 0
101
102 (! present and matches) --> false, don't print
103
104 =back
105
106 As you can see, the first pair applies when C<!> isn't supplied, and
107 the second pair applies when it is. The XOR simply allows us to
108 compact a more complicated if-then-elseif-else into a more elegant
109 (but perhaps overly clever) single test. After all, it needed this
110 explanation...
111
112 =head2 FLAGS, FLAGS, FLAGS
113
114 There is a certain C programming legacy in the debugger. Some variables,
115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
117 of state to be stored independently in a single scalar.
118
119 A test like
120
121     if ($scalar & 4) ...
122
123 is checking to see if the appropriate bit is on. Since each bit can be
124 "addressed" independently in this way, C<$scalar> is acting sort of like
125 an array of bits. Obviously, since the contents of C<$scalar> are just a
126 bit-pattern, we can save and restore it easily (it will just look like
127 a number).
128
129 The problem, is of course, that this tends to leave magic numbers scattered
130 all over your program whenever a bit is set, cleared, or checked. So why do
131 it?
132
133 =over 4
134
135 =item *
136
137 First, doing an arithmetical or bitwise operation on a scalar is
138 just about the fastest thing you can do in Perl: C<use constant> actually
139 creates a subroutine call, and array and hash lookups are much slower. Is
140 this over-optimization at the expense of readability? Possibly, but the
141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
142 probably have to benchmark alternate implementations and see which is the
143 best balance of readability and speed, and then document how it actually
144 works.
145
146 =item *
147
148 Second, it's very easy to serialize a scalar number. This is done in
149 the restart code; the debugger state variables are saved in C<%ENV> and then
150 restored when the debugger is restarted. Having them be just numbers makes
151 this trivial.
152
153 =item *
154
155 Third, some of these variables are being shared with the Perl core
156 smack in the middle of the interpreter's execution loop. It's much faster for
157 a C program (like the interpreter) to check a bit in a scalar than to access
158 several different variables (or a Perl array).
159
160 =back
161
162 =head2 What are those C<XXX> comments for?
163
164 Any comment containing C<XXX> means that the comment is either somewhat
165 speculative - it's not exactly clear what a given variable or chunk of
166 code is doing, or that it is incomplete - the basics may be clear, but the
167 subtleties are not completely documented.
168
169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
170
171 =head1 DATA STRUCTURES MAINTAINED BY CORE
172
173 There are a number of special data structures provided to the debugger by
174 the Perl interpreter.
175
176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
177 via glob assignment) contains the text from C<$filename>, with each
178 element corresponding to a single line of C<$filename>. Additionally,
179 breakable lines will be dualvars with the numeric component being the
180 memory address of a COP node. Non-breakable lines are dualvar to 0.
181
182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
183 assignment) contains breakpoints and actions.  The keys are line numbers;
184 you can set individual values, but not the whole hash. The Perl interpreter
185 uses this hash to determine where breakpoints have been set. Any true value is
186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
188
189 The scalar C<${"_<$filename"}> simply contains the string C<<< _<$filename> >>>.
190 This is also the case for evaluated strings that contain subroutines, or
191 which are currently being executed.  The $filename for C<eval>ed strings looks
192 like C<(eval 34).
193
194 =head1 DEBUGGER STARTUP
195
196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
198 of options. In addition, this file may define a subroutine C<&afterinit>
199 that will be executed (in the debugger's context) after the debugger has
200 initialized itself.
201
202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
203 contents as the argument of a C<o> command in the debugger.
204
205 =head2 STARTUP-ONLY OPTIONS
206
207 The following options can only be specified at startup.
208 To set them in your rcfile, add a call to
209 C<&parse_options("optionName=new_value")>.
210
211 =over 4
212
213 =item * TTY
214
215 the TTY to use for debugging i/o.
216
217 =item * noTTY
218
219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
221 Term::Rendezvous.  Current variant is to have the name of TTY in this
222 file.
223
224 =item * ReadLine
225
226 if false, a dummy ReadLine is used, so you can debug
227 ReadLine applications.
228
229 =item * NonStop
230
231 if true, no i/o is performed until interrupt.
232
233 =item * LineInfo
234
235 file or pipe to print line number info to.  If it is a
236 pipe, a short "emacs like" message is used.
237
238 =item * RemotePort
239
240 host:port to connect to on remote host for remote debugging.
241
242 =item * HistFile
243
244 file to store session history to. There is no default and so no
245 history file is written unless this variable is explicitly set.
246
247 =item * HistSize
248
249 number of commands to store to the file specified in C<HistFile>.
250 Default is 100.
251
252 =back
253
254 =head3 SAMPLE RCFILE
255
256  &parse_options("NonStop=1 LineInfo=db.out");
257   sub afterinit { $trace = 1; }
258
259 The script will run without human intervention, putting trace
260 information into C<db.out>.  (If you interrupt it, you had better
261 reset C<LineInfo> to something I<interactive>!)
262
263 =head1 INTERNALS DESCRIPTION
264
265 =head2 DEBUGGER INTERFACE VARIABLES
266
267 Perl supplies the values for C<%sub>.  It effectively inserts
268 a C<&DB::DB();> in front of each place that can have a
269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
271 {require 'perl5db.pl'}> before the first line.
272
273 After each C<require>d file is compiled, but before it is executed, a
274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
275 is the expanded name of the C<require>d file (as found via C<%INC>).
276
277 =head3 IMPORTANT INTERNAL VARIABLES
278
279 =head4 C<$CreateTTY>
280
281 Used to control when the debugger will attempt to acquire another TTY to be
282 used for input.
283
284 =over
285
286 =item * 1 -  on C<fork()>
287
288 =item * 2 - debugger is started inside debugger
289
290 =item * 4 -  on startup
291
292 =back
293
294 =head4 C<$doret>
295
296 The value -2 indicates that no return value should be printed.
297 Any other positive value causes C<DB::sub> to print return values.
298
299 =head4 C<$evalarg>
300
301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
302 contents of C<@_> when C<DB::eval> is called.
303
304 =head4 C<$frame>
305
306 Determines what messages (if any) will get printed when a subroutine (or eval)
307 is entered or exited.
308
309 =over 4
310
311 =item * 0 -  No enter/exit messages
312
313 =item * 1 - Print I<entering> messages on subroutine entry
314
315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
316
317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
318
319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
320
321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
322
323 =back
324
325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
326 The debugger internally juggles the value of C<$frame> during execution to
327 protect external modules that the debugger uses from getting traced.
328
329 =head4 C<$level>
330
331 Tracks current debugger nesting level. Used to figure out how many
332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
333 outputs a prompt. Also used to help determine if the program has finished
334 during command parsing.
335
336 =head4 C<$onetimeDump>
337
338 Controls what (if anything) C<DB::eval()> will print after evaluating an
339 expression.
340
341 =over 4
342
343 =item * C<undef> - don't print anything
344
345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
346
347 =item * C<methods> - print the methods callable on the first item returned
348
349 =back
350
351 =head4 C<$onetimeDumpDepth>
352
353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
354 dumping a structure. Numeric. If C<undef>, print all levels.
355
356 =head4 C<$signal>
357
358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
359 which is called before every statement, checks this and puts the user into
360 command mode if it finds C<$signal> set to a true value.
361
362 =head4 C<$single>
363
364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
365 each subroutine; popped again at the end of each subroutine.
366
367 =over 4
368
369 =item * 0 - run continuously.
370
371 =item * 1 - single-step, go into subs. The C<s> command.
372
373 =item * 2 - single-step, don't go into subs. The C<n> command.
374
375 =item * 4 - print current sub depth (turned on to force this when C<too much
376 recursion> occurs.
377
378 =back
379
380 =head4 C<$trace>
381
382 Controls the output of trace information.
383
384 =over 4
385
386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
387
388 =item * 2 - watch expressions are active
389
390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
391
392 =back
393
394 =head4 C<$slave_editor>
395
396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
397
398 =head4 C<@cmdfhs>
399
400 Stack of filehandles that C<DB::readline()> will read commands from.
401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
402
403 =head4 C<@dbline>
404
405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
406 supplied by the Perl interpreter to the debugger. Contains the source.
407
408 =head4 C<@old_watch>
409
410 Previous values of watch expressions. First set when the expression is
411 entered; reset whenever the watch expression changes.
412
413 =head4 C<@saved>
414
415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
416 so that the debugger can substitute safe values while it's running, and
417 restore them when it returns control.
418
419 =head4 C<@stack>
420
421 Saves the current value of C<$single> on entry to a subroutine.
422 Manipulated by the C<c> command to turn off tracing in all subs above the
423 current one.
424
425 =head4 C<@to_watch>
426
427 The 'watch' expressions: to be evaluated before each line is executed.
428
429 =head4 C<@typeahead>
430
431 The typeahead buffer, used by C<DB::readline>.
432
433 =head4 C<%alias>
434
435 Command aliases. Stored as character strings to be substituted for a command
436 entered.
437
438 =head4 C<%break_on_load>
439
440 Keys are file names, values are 1 (break when this file is loaded) or undef
441 (don't break when it is loaded).
442
443 =head4 C<%dbline>
444
445 Keys are line numbers, values are C<condition\0action>. If used in numeric
446 context, values are 0 if not breakable, 1 if breakable, no matter what is
447 in the actual hash entry.
448
449 =head4 C<%had_breakpoints>
450
451 Keys are file names; values are bitfields:
452
453 =over 4
454
455 =item * 1 - file has a breakpoint in it.
456
457 =item * 2 - file has an action in it.
458
459 =back
460
461 A zero or undefined value means this file has neither.
462
463 =head4 C<%option>
464
465 Stores the debugger options. These are character string values.
466
467 =head4 C<%postponed>
468
469 Saves breakpoints for code that hasn't been compiled yet.
470 Keys are subroutine names, values are:
471
472 =over 4
473
474 =item * C<compile> - break when this sub is compiled
475
476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
477
478 =back
479
480 =head4 C<%postponed_file>
481
482 This hash keeps track of breakpoints that need to be set for files that have
483 not yet been compiled. Keys are filenames; values are references to hashes.
484 Each of these hashes is keyed by line number, and its values are breakpoint
485 definitions (C<condition\0action>).
486
487 =head1 DEBUGGER INITIALIZATION
488
489 The debugger's initialization actually jumps all over the place inside this
490 package. This is because there are several BEGIN blocks (which of course
491 execute immediately) spread through the code. Why is that?
492
493 The debugger needs to be able to change some things and set some things up
494 before the debugger code is compiled; most notably, the C<$deep> variable that
495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
496 debugger has to turn off warnings while the debugger code is compiled, but then
497 restore them to their original setting before the program being debugged begins
498 executing.
499
500 The first C<BEGIN> block simply turns off warnings by saving the current
501 setting of C<$^W> and then setting it to zero. The second one initializes
502 the debugger variables that are needed before the debugger begins executing.
503 The third one puts C<$^X> back to its former value.
504
505 We'll detail the second C<BEGIN> block later; just remember that if you need
506 to initialize something before the debugger starts really executing, that's
507 where it has to go.
508
509 =cut
510
511 package DB;
512
513 use strict;
514
515 BEGIN {eval 'use IO::Handle'}; # Needed for flush only? breaks under miniperl
516
517 BEGIN {
518     require feature;
519     $^V =~ /^v(\d+\.\d+)/;
520     feature->import(":$1");
521 }
522
523 # Debugger for Perl 5.00x; perl5db.pl patch level:
524 use vars qw($VERSION $header);
525
526 $VERSION = '1.39_05';
527
528 $header = "perl5db.pl version $VERSION";
529
530 =head1 DEBUGGER ROUTINES
531
532 =head2 C<DB::eval()>
533
534 This function replaces straight C<eval()> inside the debugger; it simplifies
535 the process of evaluating code in the user's context.
536
537 The code to be evaluated is passed via the package global variable
538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
539
540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
543 user's current package, grabbed when C<DB::DB> got control.  This causes the
544 proper context to be used when the eval is actually done.  Afterward, we
545 restore C<$trace>, C<$single>, and C<$^D>.
546
547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
551 considered sane by the debugger. If there was an C<eval()> error, we print
552 it on the debugger's output. If C<$onetimedump> is defined, we call
553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
554 'methods'. Setting it to something else causes the debugger to do the eval
555 but not print the result - handy if you want to do something else with it
556 (the "watch expressions" code does this to get the value of the watch
557 expression but not show it unless it matters).
558
559 In any case, we then return the list of output from C<eval> to the caller,
560 and unwinding restores the former version of C<$@> in C<@saved> as well
561 (the localization of C<$saved[0]> goes away at the end of this scope).
562
563 =head3 Parameters and variables influencing execution of DB::eval()
564
565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
567 The variables listed below influence C<DB::eval()>'s execution directly.
568
569 =over 4
570
571 =item C<$evalarg> - the thing to actually be eval'ed
572
573 =item C<$trace> - Current state of execution tracing
574
575 =item C<$single> - Current state of single-stepping
576
577 =item C<$onetimeDump> - what is to be displayed after the evaluation
578
579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
580
581 =back
582
583 The following variables are altered by C<DB::eval()> during its execution. They
584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
585
586 =over 4
587
588 =item C<@res> - used to capture output from actual C<eval>.
589
590 =item C<$otrace> - saved value of C<$trace>.
591
592 =item C<$osingle> - saved value of C<$single>.
593
594 =item C<$od> - saved value of C<$^D>.
595
596 =item C<$saved[0]> - saved value of C<$@>.
597
598 =item $\ - for output of C<$@> if there is an evaluation error.
599
600 =back
601
602 =head3 The problem of lexicals
603
604 The context of C<DB::eval()> presents us with some problems. Obviously,
605 we want to be 'sandboxed' away from the debugger's internals when we do
606 the eval, but we need some way to control how punctuation variables and
607 debugger globals are used.
608
609 We can't use local, because the code inside C<DB::eval> can see localized
610 variables; and we can't use C<my> either for the same reason. The code
611 in this routine compromises and uses C<my>.
612
613 After this routine is over, we don't have user code executing in the debugger's
614 context, so we can use C<my> freely.
615
616 =cut
617
618 ############################################## Begin lexical danger zone
619
620 # 'my' variables used here could leak into (that is, be visible in)
621 # the context that the code being evaluated is executing in. This means that
622 # the code could modify the debugger's variables.
623 #
624 # Fiddling with the debugger's context could be Bad. We insulate things as
625 # much as we can.
626
627 use vars qw(
628     @args
629     %break_on_load
630     @cmdfhs
631     $CommandSet
632     $CreateTTY
633     $DBGR
634     @dbline
635     $dbline
636     %dbline
637     $dieLevel
638     $evalarg
639     $filename
640     $frame
641     $hist
642     $histfile
643     $histsize
644     $ImmediateStop
645     $IN
646     $inhibit_exit
647     @ini_INC
648     $ini_warn
649     $line
650     $maxtrace
651     $od
652     $onetimeDump
653     $onetimedumpDepth
654     %option
655     @options
656     $osingle
657     $otrace
658     $OUT
659     $packname
660     $pager
661     $post
662     %postponed
663     $prc
664     $pre
665     $pretype
666     $psh
667     @RememberOnROptions
668     $remoteport
669     @res
670     $rl
671     @saved
672     $signalLevel
673     $start
674     $sub
675     %sub
676     $subname
677     $term
678     $usercontext
679     $warnLevel
680     $window
681 );
682
683 our ($trace, $single, $signal);
684
685 # Used to save @ARGV and extract any debugger-related flags.
686 use vars qw(@ARGS);
687
688 # Used to prevent multiple entries to diesignal()
689 # (if for instance diesignal() itself dies)
690 use vars qw($panic);
691
692 # Used to prevent the debugger from running nonstop
693 # after a restart
694 our ($second_time);
695
696 sub _calc_usercontext {
697     my ($package) = @_;
698
699     # Cancel strict completely for the evaluated code, so the code
700     # the user evaluates won't be affected by it. (Shlomi Fish)
701     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
702     . "package $package;";    # this won't let them modify, alas
703 }
704
705 sub eval {
706
707     # 'my' would make it visible from user code
708     #    but so does local! --tchrist
709     # Remember: this localizes @DB::res, not @main::res.
710     local @res;
711     {
712
713         # Try to keep the user code from messing  with us. Save these so that
714         # even if the eval'ed code changes them, we can put them back again.
715         # Needed because the user could refer directly to the debugger's
716         # package globals (and any 'my' variables in this containing scope)
717         # inside the eval(), and we want to try to stay safe.
718         local $otrace  = $trace;
719         local $osingle = $single;
720         local $od      = $^D;
721
722         # Untaint the incoming eval() argument.
723         { ($evalarg) = $evalarg =~ /(.*)/s; }
724
725         # $usercontext built in DB::DB near the comment
726         # "set up the context for DB::eval ..."
727         # Evaluate and save any results.
728         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
729
730         # Restore those old values.
731         $trace  = $otrace;
732         $single = $osingle;
733         $^D     = $od;
734     }
735
736     # Save the current value of $@, and preserve it in the debugger's copy
737     # of the saved precious globals.
738     my $at = $@;
739
740     # Since we're only saving $@, we only have to localize the array element
741     # that it will be stored in.
742     local $saved[0];    # Preserve the old value of $@
743     eval { DB::save() };
744
745     # Now see whether we need to report an error back to the user.
746     if ($at) {
747         local $\ = '';
748         print $OUT $at;
749     }
750
751     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
752     # are package globals.
753     elsif ($onetimeDump) {
754         if ( $onetimeDump eq 'dump' ) {
755             local $option{dumpDepth} = $onetimedumpDepth
756               if defined $onetimedumpDepth;
757             dumpit( $OUT, \@res );
758         }
759         elsif ( $onetimeDump eq 'methods' ) {
760             methods( $res[0] );
761         }
762     } ## end elsif ($onetimeDump)
763     @res;
764 } ## end sub eval
765
766 ############################################## End lexical danger zone
767
768 # After this point it is safe to introduce lexicals.
769 # The code being debugged will be executing in its own context, and
770 # can't see the inside of the debugger.
771 #
772 # However, one should not overdo it: leave as much control from outside as
773 # possible. If you make something a lexical, it's not going to be addressable
774 # from outside the debugger even if you know its name.
775
776 # This file is automatically included if you do perl -d.
777 # It's probably not useful to include this yourself.
778 #
779 # Before venturing further into these twisty passages, it is
780 # wise to read the perldebguts man page or risk the ire of dragons.
781 #
782 # (It should be noted that perldebguts will tell you a lot about
783 # the underlying mechanics of how the debugger interfaces into the
784 # Perl interpreter, but not a lot about the debugger itself. The new
785 # comments in this code try to address this problem.)
786
787 # Note that no subroutine call is possible until &DB::sub is defined
788 # (for subroutines defined outside of the package DB). In fact the same is
789 # true if $deep is not defined.
790
791 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
792
793 # modified Perl debugger, to be run from Emacs in perldb-mode
794 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
795 # Johan Vromans -- upgrade to 4.0 pl 10
796 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
797 ########################################################################
798
799 =head1 DEBUGGER INITIALIZATION
800
801 The debugger starts up in phases.
802
803 =head2 BASIC SETUP
804
805 First, it initializes the environment it wants to run in: turning off
806 warnings during its own compilation, defining variables which it will need
807 to avoid warnings later, setting itself up to not exit when the program
808 terminates, and defaulting to printing return values for the C<r> command.
809
810 =cut
811
812 # Needed for the statement after exec():
813 #
814 # This BEGIN block is simply used to switch off warnings during debugger
815 # compilation. Probably it would be better practice to fix the warnings,
816 # but this is how it's done at the moment.
817
818 BEGIN {
819     $ini_warn = $^W;
820     $^W       = 0;
821 }    # Switch compilation warnings off until another BEGIN.
822
823 local ($^W) = 0;    # Switch run-time warnings off during init.
824
825 =head2 THREADS SUPPORT
826
827 If we are running under a threaded Perl, we require threads and threads::shared
828 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
829 threaded debugger control.  C<-dt> can also be used to set this.
830
831 Each new thread will be announced and the debugger prompt will always inform
832 you of each new thread created.  It will also indicate the thread id in which
833 we are currently running within the prompt like this:
834
835     [tid] DB<$i>
836
837 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
838 command prompt.  The prompt will show: C<[0]> when running under threads, but
839 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
840
841 While running under threads, when you set or delete a breakpoint (etc.), this
842 will apply to all threads, not just the currently running one.  When you are
843 in a currently executing thread, you will stay there until it completes.  With
844 the current implementation it is not currently possible to hop from one thread
845 to another.
846
847 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
848
849 Note that threading support was built into the debugger as of Perl version
850 C<5.8.6> and debugger version C<1.2.8>.
851
852 =cut
853
854 BEGIN {
855     # ensure we can share our non-threaded variables or no-op
856     if ($ENV{PERL5DB_THREADED}) {
857         require threads;
858         require threads::shared;
859         import threads::shared qw(share);
860         $DBGR;
861         share(\$DBGR);
862         lock($DBGR);
863         print "Threads support enabled\n";
864     } else {
865         *lock  = sub(*) {};
866         *share = sub(*) {};
867     }
868 }
869
870 # These variables control the execution of 'dumpvar.pl'.
871 {
872     package dumpvar;
873     use vars qw(
874     $hashDepth
875     $arrayDepth
876     $dumpDBFiles
877     $dumpPackages
878     $quoteHighBit
879     $printUndef
880     $globPrint
881     $usageOnly
882     );
883 }
884
885 # used to control die() reporting in diesignal()
886 {
887     package Carp;
888     use vars qw($CarpLevel);
889 }
890
891 # without threads, $filename is not defined until DB::DB is called
892 foreach my $k (keys (%INC)) {
893     share(\$main::{'_<'.$filename}) if defined $filename;
894 };
895
896 # Command-line + PERLLIB:
897 # Save the contents of @INC before they are modified elsewhere.
898 @ini_INC = @INC;
899
900 # This was an attempt to clear out the previous values of various
901 # trapped errors. Apparently it didn't help. XXX More info needed!
902 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
903
904 # We set these variables to safe values. We don't want to blindly turn
905 # off warnings, because other packages may still want them.
906 $trace = $signal = $single = 0;    # Uninitialized warning suppression
907                                    # (local $^W cannot help - other packages!).
908
909 # Default to not exiting when program finishes; print the return
910 # value when the 'r' command is used to return from a subroutine.
911 $inhibit_exit = $option{PrintRet} = 1;
912
913 use vars qw($trace_to_depth);
914
915 # Default to 1E9 so it won't be limited to a certain recursion depth.
916 $trace_to_depth = 1E9;
917
918 =head1 OPTION PROCESSING
919
920 The debugger's options are actually spread out over the debugger itself and
921 C<dumpvar.pl>; some of these are variables to be set, while others are
922 subs to be called with a value. To try to make this a little easier to
923 manage, the debugger uses a few data structures to define what options
924 are legal and how they are to be processed.
925
926 First, the C<@options> array defines the I<names> of all the options that
927 are to be accepted.
928
929 =cut
930
931 @options = qw(
932   CommandSet   HistFile      HistSize
933   hashDepth    arrayDepth    dumpDepth
934   DumpDBFiles  DumpPackages  DumpReused
935   compactDump  veryCompact   quote
936   HighBit      undefPrint    globPrint
937   PrintRet     UsageOnly     frame
938   AutoTrace    TTY           noTTY
939   ReadLine     NonStop       LineInfo
940   maxTraceLen  recallCommand ShellBang
941   pager        tkRunning     ornaments
942   signalLevel  warnLevel     dieLevel
943   inhibit_exit ImmediateStop bareStringify
944   CreateTTY    RemotePort    windowSize
945   DollarCaretP
946 );
947
948 @RememberOnROptions = qw(DollarCaretP);
949
950 =pod
951
952 Second, C<optionVars> lists the variables that each option uses to save its
953 state.
954
955 =cut
956
957 use vars qw(%optionVars);
958
959 %optionVars = (
960     hashDepth     => \$dumpvar::hashDepth,
961     arrayDepth    => \$dumpvar::arrayDepth,
962     CommandSet    => \$CommandSet,
963     DumpDBFiles   => \$dumpvar::dumpDBFiles,
964     DumpPackages  => \$dumpvar::dumpPackages,
965     DumpReused    => \$dumpvar::dumpReused,
966     HighBit       => \$dumpvar::quoteHighBit,
967     undefPrint    => \$dumpvar::printUndef,
968     globPrint     => \$dumpvar::globPrint,
969     UsageOnly     => \$dumpvar::usageOnly,
970     CreateTTY     => \$CreateTTY,
971     bareStringify => \$dumpvar::bareStringify,
972     frame         => \$frame,
973     AutoTrace     => \$trace,
974     inhibit_exit  => \$inhibit_exit,
975     maxTraceLen   => \$maxtrace,
976     ImmediateStop => \$ImmediateStop,
977     RemotePort    => \$remoteport,
978     windowSize    => \$window,
979     HistFile      => \$histfile,
980     HistSize      => \$histsize,
981 );
982
983 =pod
984
985 Third, C<%optionAction> defines the subroutine to be called to process each
986 option.
987
988 =cut
989
990 use vars qw(%optionAction);
991
992 %optionAction = (
993     compactDump   => \&dumpvar::compactDump,
994     veryCompact   => \&dumpvar::veryCompact,
995     quote         => \&dumpvar::quote,
996     TTY           => \&TTY,
997     noTTY         => \&noTTY,
998     ReadLine      => \&ReadLine,
999     NonStop       => \&NonStop,
1000     LineInfo      => \&LineInfo,
1001     recallCommand => \&recallCommand,
1002     ShellBang     => \&shellBang,
1003     pager         => \&pager,
1004     signalLevel   => \&signalLevel,
1005     warnLevel     => \&warnLevel,
1006     dieLevel      => \&dieLevel,
1007     tkRunning     => \&tkRunning,
1008     ornaments     => \&ornaments,
1009     RemotePort    => \&RemotePort,
1010     DollarCaretP  => \&DollarCaretP,
1011 );
1012
1013 =pod
1014
1015 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1016 option is used.
1017
1018 =cut
1019
1020 # Note that this list is not complete: several options not listed here
1021 # actually require that dumpvar.pl be loaded for them to work, but are
1022 # not in the table. A subsequent patch will correct this problem; for
1023 # the moment, we're just recommenting, and we are NOT going to change
1024 # function.
1025 use vars qw(%optionRequire);
1026
1027 %optionRequire = (
1028     compactDump => 'dumpvar.pl',
1029     veryCompact => 'dumpvar.pl',
1030     quote       => 'dumpvar.pl',
1031 );
1032
1033 =pod
1034
1035 There are a number of initialization-related variables which can be set
1036 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1037 variable. These are:
1038
1039 =over 4
1040
1041 =item C<$rl> - readline control XXX needs more explanation
1042
1043 =item C<$warnLevel> - whether or not debugger takes over warning handling
1044
1045 =item C<$dieLevel> - whether or not debugger takes over die handling
1046
1047 =item C<$signalLevel> - whether or not debugger takes over signal handling
1048
1049 =item C<$pre> - preprompt actions (array reference)
1050
1051 =item C<$post> - postprompt actions (array reference)
1052
1053 =item C<$pretype>
1054
1055 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1056
1057 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1058
1059 =back
1060
1061 =cut
1062
1063 # These guys may be defined in $ENV{PERL5DB} :
1064 $rl          = 1     unless defined $rl;
1065 $warnLevel   = 1     unless defined $warnLevel;
1066 $dieLevel    = 1     unless defined $dieLevel;
1067 $signalLevel = 1     unless defined $signalLevel;
1068 $pre         = []    unless defined $pre;
1069 $post        = []    unless defined $post;
1070 $pretype     = []    unless defined $pretype;
1071 $CreateTTY   = 3     unless defined $CreateTTY;
1072 $CommandSet  = '580' unless defined $CommandSet;
1073
1074 share($rl);
1075 share($warnLevel);
1076 share($dieLevel);
1077 share($signalLevel);
1078 share($pre);
1079 share($post);
1080 share($pretype);
1081 share($rl);
1082 share($CreateTTY);
1083 share($CommandSet);
1084
1085 =pod
1086
1087 The default C<die>, C<warn>, and C<signal> handlers are set up.
1088
1089 =cut
1090
1091 warnLevel($warnLevel);
1092 dieLevel($dieLevel);
1093 signalLevel($signalLevel);
1094
1095 =pod
1096
1097 The pager to be used is needed next. We try to get it from the
1098 environment first.  If it's not defined there, we try to find it in
1099 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1100 then call the C<pager()> function to save the pager name.
1101
1102 =cut
1103
1104 # This routine makes sure $pager is set up so that '|' can use it.
1105 pager(
1106
1107     # If PAGER is defined in the environment, use it.
1108     defined $ENV{PAGER}
1109     ? $ENV{PAGER}
1110
1111       # If not, see if Config.pm defines it.
1112     : eval { require Config }
1113       && defined $Config::Config{pager}
1114     ? $Config::Config{pager}
1115
1116       # If not, fall back to 'more'.
1117     : 'more'
1118   )
1119   unless defined $pager;
1120
1121 =pod
1122
1123 We set up the command to be used to access the man pages, the command
1124 recall character (C<!> unless otherwise defined) and the shell escape
1125 character (C<!> unless otherwise defined). Yes, these do conflict, and
1126 neither works in the debugger at the moment.
1127
1128 =cut
1129
1130 setman();
1131
1132 # Set up defaults for command recall and shell escape (note:
1133 # these currently don't work in linemode debugging).
1134 recallCommand("!") unless defined $prc;
1135 shellBang("!")     unless defined $psh;
1136
1137 =pod
1138
1139 We then set up the gigantic string containing the debugger help.
1140 We also set the limit on the number of arguments we'll display during a
1141 trace.
1142
1143 =cut
1144
1145 sethelp();
1146
1147 # If we didn't get a default for the length of eval/stack trace args,
1148 # set it here.
1149 $maxtrace = 400 unless defined $maxtrace;
1150
1151 =head2 SETTING UP THE DEBUGGER GREETING
1152
1153 The debugger I<greeting> helps to inform the user how many debuggers are
1154 running, and whether the current debugger is the primary or a child.
1155
1156 If we are the primary, we just hang onto our pid so we'll have it when
1157 or if we start a child debugger. If we are a child, we'll set things up
1158 so we'll have a unique greeting and so the parent will give us our own
1159 TTY later.
1160
1161 We save the current contents of the C<PERLDB_PIDS> environment variable
1162 because we mess around with it. We'll also need to hang onto it because
1163 we'll need it if we restart.
1164
1165 Child debuggers make a label out of the current PID structure recorded in
1166 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1167 yet so the parent will give them one later via C<resetterm()>.
1168
1169 =cut
1170
1171 # Save the current contents of the environment; we're about to
1172 # much with it. We'll need this if we have to restart.
1173 use vars qw($ini_pids);
1174 $ini_pids = $ENV{PERLDB_PIDS};
1175
1176 use vars qw ($pids $term_pid);
1177
1178 if ( defined $ENV{PERLDB_PIDS} ) {
1179
1180     # We're a child. Make us a label out of the current PID structure
1181     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1182     # a term yet so the parent will give us one later via resetterm().
1183
1184     my $env_pids = $ENV{PERLDB_PIDS};
1185     $pids = "[$env_pids]";
1186
1187     # Unless we are on OpenVMS, all programs under the DCL shell run under
1188     # the same PID.
1189
1190     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1191         $term_pid         = $$;
1192     }
1193     else {
1194         $ENV{PERLDB_PIDS} .= "->$$";
1195         $term_pid = -1;
1196     }
1197
1198 } ## end if (defined $ENV{PERLDB_PIDS...
1199 else {
1200
1201     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1202     # child debugger, and mark us as the parent, so we'll know to set up
1203     # more TTY's is we have to.
1204     $ENV{PERLDB_PIDS} = "$$";
1205     $pids             = "[pid=$$]";
1206     $term_pid         = $$;
1207 }
1208
1209 use vars qw($pidprompt);
1210 $pidprompt = '';
1211
1212 # Sets up $emacs as a synonym for $slave_editor.
1213 use vars qw($slave_editor);
1214 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1215
1216 =head2 READING THE RC FILE
1217
1218 The debugger will read a file of initialization options if supplied. If
1219 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1220
1221 =cut
1222
1223 # As noted, this test really doesn't check accurately that the debugger
1224 # is running at a terminal or not.
1225
1226 use vars qw($rcfile);
1227 {
1228     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1229     # this is the wrong metric!
1230     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1231 }
1232
1233 =pod
1234
1235 The debugger does a safety test of the file to be read. It must be owned
1236 either by the current user or root, and must only be writable by the owner.
1237
1238 =cut
1239
1240 # This wraps a safety test around "do" to read and evaluate the init file.
1241 #
1242 # This isn't really safe, because there's a race
1243 # between checking and opening.  The solution is to
1244 # open and fstat the handle, but then you have to read and
1245 # eval the contents.  But then the silly thing gets
1246 # your lexical scope, which is unfortunate at best.
1247 sub safe_do {
1248     my $file = shift;
1249
1250     # Just exactly what part of the word "CORE::" don't you understand?
1251     local $SIG{__WARN__};
1252     local $SIG{__DIE__};
1253
1254     unless ( is_safe_file($file) ) {
1255         CORE::warn <<EO_GRIPE;
1256 perldb: Must not source insecure rcfile $file.
1257         You or the superuser must be the owner, and it must not
1258         be writable by anyone but its owner.
1259 EO_GRIPE
1260         return;
1261     } ## end unless (is_safe_file($file...
1262
1263     do $file;
1264     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1265 } ## end sub safe_do
1266
1267 # This is the safety test itself.
1268 #
1269 # Verifies that owner is either real user or superuser and that no
1270 # one but owner may write to it.  This function is of limited use
1271 # when called on a path instead of upon a handle, because there are
1272 # no guarantees that filename (by dirent) whose file (by ino) is
1273 # eventually accessed is the same as the one tested.
1274 # Assumes that the file's existence is not in doubt.
1275 sub is_safe_file {
1276     my $path = shift;
1277     stat($path) || return;    # mysteriously vaporized
1278     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1279
1280     return 0 if $uid != 0 && $uid != $<;
1281     return 0 if $mode & 022;
1282     return 1;
1283 } ## end sub is_safe_file
1284
1285 # If the rcfile (whichever one we decided was the right one to read)
1286 # exists, we safely do it.
1287 if ( -f $rcfile ) {
1288     safe_do("./$rcfile");
1289 }
1290
1291 # If there isn't one here, try the user's home directory.
1292 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1293     safe_do("$ENV{HOME}/$rcfile");
1294 }
1295
1296 # Else try the login directory.
1297 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1298     safe_do("$ENV{LOGDIR}/$rcfile");
1299 }
1300
1301 # If the PERLDB_OPTS variable has options in it, parse those out next.
1302 if ( defined $ENV{PERLDB_OPTS} ) {
1303     parse_options( $ENV{PERLDB_OPTS} );
1304 }
1305
1306 =pod
1307
1308 The last thing we do during initialization is determine which subroutine is
1309 to be used to obtain a new terminal when a new debugger is started. Right now,
1310 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1311 (darwin).
1312
1313 =cut
1314
1315 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1316 # Works if you're running an xterm or xterm-like window, or you're on
1317 # OS/2, or on Mac OS X. This may need some expansion.
1318
1319 if (not defined &get_fork_TTY)       # only if no routine exists
1320 {
1321     if ( defined $remoteport ) {
1322                                                  # Expect an inetd-like server
1323         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1324     }
1325     elsif (defined $ENV{TERM}                    # If we know what kind
1326                                                  # of terminal this is,
1327         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1328         and defined $ENV{DISPLAY}                # and what display it's on,
1329       )
1330     {
1331         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1332     }
1333     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1334         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1335     }
1336     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1337             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1338             and $ENV{TERM_PROGRAM}
1339                 eq 'Apple_Terminal'              # Terminal.app
1340             )
1341     {
1342         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1343     }
1344 } ## end if (not defined &get_fork_TTY...
1345
1346 # untaint $^O, which may have been tainted by the last statement.
1347 # see bug [perl #24674]
1348 $^O =~ m/^(.*)\z/;
1349 $^O = $1;
1350
1351 # Here begin the unreadable code.  It needs fixing.
1352
1353 =head2 RESTART PROCESSING
1354
1355 This section handles the restart command. When the C<R> command is invoked, it
1356 tries to capture all of the state it can into environment variables, and
1357 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1358 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1359 the R command stuffed into the environment variables.
1360
1361   PERLDB_RESTART   - flag only, contains no restart data itself.
1362   PERLDB_HIST      - command history, if it's available
1363   PERLDB_ON_LOAD   - breakpoints set by the rc file
1364   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1365   PERLDB_VISITED   - files that had breakpoints
1366   PERLDB_FILE_...  - breakpoints for a file
1367   PERLDB_OPT       - active options
1368   PERLDB_INC       - the original @INC
1369   PERLDB_PRETYPE   - preprompt debugger actions
1370   PERLDB_PRE       - preprompt Perl code
1371   PERLDB_POST      - post-prompt Perl code
1372   PERLDB_TYPEAHEAD - typeahead captured by readline()
1373
1374 We chug through all these variables and plug the values saved in them
1375 back into the appropriate spots in the debugger.
1376
1377 =cut
1378
1379 use vars qw(@hist @truehist %postponed_file @typeahead);
1380
1381 sub _restore_shared_globals_after_restart
1382 {
1383     @hist          = get_list('PERLDB_HIST');
1384     %break_on_load = get_list("PERLDB_ON_LOAD");
1385     %postponed     = get_list("PERLDB_POSTPONE");
1386
1387     share(@hist);
1388     share(@truehist);
1389     share(%break_on_load);
1390     share(%postponed);
1391 }
1392
1393 sub _restore_breakpoints_and_actions {
1394
1395     my @had_breakpoints = get_list("PERLDB_VISITED");
1396
1397     for my $file_idx ( 0 .. $#had_breakpoints ) {
1398         my $filename = $had_breakpoints[$file_idx];
1399         my %pf = get_list("PERLDB_FILE_$file_idx");
1400         $postponed_file{ $filename } = \%pf if %pf;
1401         my @lines = sort {$a <=> $b} keys(%pf);
1402         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1403         for my $line_idx (0 .. $#lines) {
1404             _set_breakpoint_enabled_status(
1405                 $filename,
1406                 $lines[$line_idx],
1407                 ($enabled_statuses[$line_idx] ? 1 : ''),
1408             );
1409         }
1410     }
1411
1412     return;
1413 }
1414
1415 sub _restore_options_after_restart
1416 {
1417     my %options_map = get_list("PERLDB_OPT");
1418
1419     while ( my ( $opt, $val ) = each %options_map ) {
1420         $val =~ s/[\\\']/\\$1/g;
1421         parse_options("$opt'$val'");
1422     }
1423
1424     return;
1425 }
1426
1427 sub _restore_globals_after_restart
1428 {
1429     # restore original @INC
1430     @INC     = get_list("PERLDB_INC");
1431     @ini_INC = @INC;
1432
1433     # return pre/postprompt actions and typeahead buffer
1434     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1435     $pre       = [ get_list("PERLDB_PRE") ];
1436     $post      = [ get_list("PERLDB_POST") ];
1437     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1438
1439     return;
1440 }
1441
1442
1443 if ( exists $ENV{PERLDB_RESTART} ) {
1444
1445     # We're restarting, so we don't need the flag that says to restart anymore.
1446     delete $ENV{PERLDB_RESTART};
1447
1448     # $restart = 1;
1449     _restore_shared_globals_after_restart();
1450
1451     _restore_breakpoints_and_actions();
1452
1453     # restore options
1454     _restore_options_after_restart();
1455
1456     _restore_globals_after_restart();
1457 } ## end if (exists $ENV{PERLDB_RESTART...
1458
1459 =head2 SETTING UP THE TERMINAL
1460
1461 Now, we'll decide how the debugger is going to interact with the user.
1462 If there's no TTY, we set the debugger to run non-stop; there's not going
1463 to be anyone there to enter commands.
1464
1465 =cut
1466
1467 use vars qw($notty $console $tty $LINEINFO);
1468 use vars qw($lineinfo $doccmd);
1469
1470 our ($runnonstop);
1471
1472 if ($notty) {
1473     $runnonstop = 1;
1474     share($runnonstop);
1475 }
1476
1477 =pod
1478
1479 If there is a TTY, we have to determine who it belongs to before we can
1480 proceed. If this is a slave editor or graphical debugger (denoted by
1481 the first command-line switch being '-emacs'), we shift this off and
1482 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1483
1484 =cut
1485
1486 else {
1487
1488     # Is Perl being run from a slave editor or graphical debugger?
1489     # If so, don't use readline, and set $slave_editor = 1.
1490     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1491         $rl = 0;
1492         shift(@main::ARGV);
1493     }
1494
1495     #require Term::ReadLine;
1496
1497 =pod
1498
1499 We then determine what the console should be on various systems:
1500
1501 =over 4
1502
1503 =item * Cygwin - We use C<stdin> instead of a separate device.
1504
1505 =cut
1506
1507     if ( $^O eq 'cygwin' ) {
1508
1509         # /dev/tty is binary. use stdin for textmode
1510         undef $console;
1511     }
1512
1513 =item * Unix - use C</dev/tty>.
1514
1515 =cut
1516
1517     elsif ( -e "/dev/tty" ) {
1518         $console = "/dev/tty";
1519     }
1520
1521 =item * Windows or MSDOS - use C<con>.
1522
1523 =cut
1524
1525     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1526         $console = "con";
1527     }
1528
1529 =item * VMS - use C<sys$command>.
1530
1531 =cut
1532
1533     else {
1534
1535         # everything else is ...
1536         $console = "sys\$command";
1537     }
1538
1539 =pod
1540
1541 =back
1542
1543 Several other systems don't use a specific console. We C<undef $console>
1544 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1545 with a slave editor, Epoc).
1546
1547 =cut
1548
1549     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1550
1551         # /dev/tty is binary. use stdin for textmode
1552         $console = undef;
1553     }
1554
1555     if ( $^O eq 'NetWare' ) {
1556
1557         # /dev/tty is binary. use stdin for textmode
1558         $console = undef;
1559     }
1560
1561     # In OS/2, we need to use STDIN to get textmode too, even though
1562     # it pretty much looks like Unix otherwise.
1563     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1564     {    # In OS/2
1565         $console = undef;
1566     }
1567
1568     # EPOC also falls into the 'got to use STDIN' camp.
1569     if ( $^O eq 'epoc' ) {
1570         $console = undef;
1571     }
1572
1573 =pod
1574
1575 If there is a TTY hanging around from a parent, we use that as the console.
1576
1577 =cut
1578
1579     $console = $tty if defined $tty;
1580
1581 =head2 SOCKET HANDLING
1582
1583 The debugger is capable of opening a socket and carrying out a debugging
1584 session over the socket.
1585
1586 If C<RemotePort> was defined in the options, the debugger assumes that it
1587 should try to start a debugging session on that port. It builds the socket
1588 and then tries to connect the input and output filehandles to it.
1589
1590 =cut
1591
1592     # Handle socket stuff.
1593
1594     if ( defined $remoteport ) {
1595
1596         # If RemotePort was defined in the options, connect input and output
1597         # to the socket.
1598         $IN = $OUT = connect_remoteport();
1599     } ## end if (defined $remoteport)
1600
1601 =pod
1602
1603 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1604 this is probably a situation where multiple debuggers are running (for example,
1605 a backticked command that starts up another debugger). We create a new IN and
1606 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1607 and if we can.
1608
1609 =cut
1610
1611     # Non-socket.
1612     else {
1613
1614         # Two debuggers running (probably a system or a backtick that invokes
1615         # the debugger itself under the running one). create a new IN and OUT
1616         # filehandle, and do the necessary mojo to create a new tty if we
1617         # know how, and we can.
1618         create_IN_OUT(4) if $CreateTTY & 4;
1619         if ($console) {
1620
1621             # If we have a console, check to see if there are separate ins and
1622             # outs to open. (They are assumed identical if not.)
1623
1624             my ( $i, $o ) = split /,/, $console;
1625             $o = $i unless defined $o;
1626
1627             # read/write on in, or just read, or read on STDIN.
1628             open( IN,      "+<$i" )
1629               || open( IN, "<$i" )
1630               || open( IN, "<&STDIN" );
1631
1632             # read/write/create/clobber out, or write/create/clobber out,
1633             # or merge with STDERR, or merge with STDOUT.
1634                  open( OUT, "+>$o" )
1635               || open( OUT, ">$o" )
1636               || open( OUT, ">&STDERR" )
1637               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1638
1639         } ## end if ($console)
1640         elsif ( not defined $console ) {
1641
1642             # No console. Open STDIN.
1643             open( IN, "<&STDIN" );
1644
1645             # merge with STDERR, or with STDOUT.
1646             open( OUT,      ">&STDERR" )
1647               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1648             $console = 'STDIN/OUT';
1649         } ## end elsif (not defined $console)
1650
1651         # Keep copies of the filehandles so that when the pager runs, it
1652         # can close standard input without clobbering ours.
1653         if ($console or (not defined($console))) {
1654             $IN = \*IN;
1655             $OUT = \*OUT;
1656         }
1657     } ## end elsif (from if(defined $remoteport))
1658
1659     # Unbuffer DB::OUT. We need to see responses right away.
1660     $OUT->autoflush(1);
1661
1662     # Line info goes to debugger output unless pointed elsewhere.
1663     # Pointing elsewhere makes it possible for slave editors to
1664     # keep track of file and position. We have both a filehandle
1665     # and a I/O description to keep track of.
1666     $LINEINFO = $OUT     unless defined $LINEINFO;
1667     $lineinfo = $console unless defined $lineinfo;
1668     # share($LINEINFO); # <- unable to share globs
1669     share($lineinfo);   #
1670
1671 =pod
1672
1673 To finish initialization, we show the debugger greeting,
1674 and then call the C<afterinit()> subroutine if there is one.
1675
1676 =cut
1677
1678     # Show the debugger greeting.
1679     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1680     unless ($runnonstop) {
1681         local $\ = '';
1682         local $, = '';
1683         if ( $term_pid eq '-1' ) {
1684             print $OUT "\nDaughter DB session started...\n";
1685         }
1686         else {
1687             print $OUT "\nLoading DB routines from $header\n";
1688             print $OUT (
1689                 "Editor support ",
1690                 $slave_editor ? "enabled" : "available", ".\n"
1691             );
1692             print $OUT
1693 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1694         } ## end else [ if ($term_pid eq '-1')
1695     } ## end unless ($runnonstop)
1696 } ## end else [ if ($notty)
1697
1698 # XXX This looks like a bug to me.
1699 # Why copy to @ARGS and then futz with @args?
1700 @ARGS = @ARGV;
1701 # for (@args) {
1702     # Make sure backslashes before single quotes are stripped out, and
1703     # keep args unless they are numeric (XXX why?)
1704     # s/\'/\\\'/g;                      # removed while not justified understandably
1705     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1706 # }
1707
1708 # If there was an afterinit() sub defined, call it. It will get
1709 # executed in our scope, so it can fiddle with debugger globals.
1710 if ( defined &afterinit ) {    # May be defined in $rcfile
1711     afterinit();
1712 }
1713
1714 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1715 use vars qw($I_m_init);
1716
1717 $I_m_init = 1;
1718
1719 ############################################################ Subroutines
1720
1721 =head1 SUBROUTINES
1722
1723 =head2 DB
1724
1725 This gigantic subroutine is the heart of the debugger. Called before every
1726 statement, its job is to determine if a breakpoint has been reached, and
1727 stop if so; read commands from the user, parse them, and execute
1728 them, and then send execution off to the next statement.
1729
1730 Note that the order in which the commands are processed is very important;
1731 some commands earlier in the loop will actually alter the C<$cmd> variable
1732 to create other commands to be executed later. This is all highly I<optimized>
1733 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1734 see what's happening in any given command.
1735
1736 =cut
1737
1738 use vars qw(
1739     $action
1740     %alias
1741     $cmd
1742     $doret
1743     $fall_off_end
1744     $file
1745     $filename_ini
1746     $finished
1747     %had_breakpoints
1748     $incr
1749     $laststep
1750     $level
1751     $max
1752     @old_watch
1753     $package
1754     $rc
1755     $sh
1756     @stack
1757     $stack_depth
1758     @to_watch
1759     $try
1760     $end
1761 );
1762
1763 sub _DB__determine_if_we_should_break
1764 {
1765     # if we have something here, see if we should break.
1766     # $stop is lexical and local to this block - $action on the other hand
1767     # is global.
1768     my $stop;
1769
1770     if ( $dbline{$line}
1771         && _is_breakpoint_enabled($filename, $line)
1772         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1773     {
1774
1775         # Stop if the stop criterion says to just stop.
1776         if ( $stop eq '1' ) {
1777             $signal |= 1;
1778         }
1779
1780         # It's a conditional stop; eval it in the user's context and
1781         # see if we should stop. If so, remove the one-time sigil.
1782         elsif ($stop) {
1783             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1784             &eval;
1785             # If the breakpoint is temporary, then delete its enabled status.
1786             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1787                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1788             }
1789         }
1790     } ## end if ($dbline{$line} && ...
1791 }
1792
1793 sub _DB__is_finished {
1794     if ($finished and $level <= 1) {
1795         end_report();
1796         return 1;
1797     }
1798     else {
1799         return;
1800     }
1801 }
1802
1803 sub _DB__read_next_cmd
1804 {
1805     my ($tid) = @_;
1806
1807     # We have a terminal, or can get one ...
1808     if (!$term) {
1809         setterm();
1810     }
1811
1812     # ... and it belogs to this PID or we get one for this PID ...
1813     if ($term_pid != $$) {
1814         resetterm(1);
1815     }
1816
1817     # ... and we got a line of command input ...
1818     $cmd = DB::readline(
1819         "$pidprompt $tid DB"
1820         . ( '<' x $level )
1821         . ( $#hist + 1 )
1822         . ( '>' x $level ) . " "
1823     );
1824
1825     return defined($cmd);
1826 }
1827
1828 sub _DB__trim_command_and_return_first_component {
1829     $cmd =~ s/\A\s+//s;    # trim annoying leading whitespace
1830     $cmd =~ s/\s+\z//s;    # trim annoying trailing whitespace
1831
1832     $cmd =~ m{\A(\S*)};
1833     return $1;
1834 }
1835
1836 sub DB {
1837
1838     # lock the debugger and get the thread id for the prompt
1839     lock($DBGR);
1840     my $tid;
1841     my $position;
1842     my ($prefix, $after, $infix);
1843     my $pat;
1844     my $explicit_stop;
1845
1846     if ($ENV{PERL5DB_THREADED}) {
1847         $tid = eval { "[".threads->tid."]" };
1848     }
1849
1850     my $obj = DB::Obj->new(
1851         {
1852             position => \$position,
1853             prefix => \$prefix,
1854             after => \$after,
1855             explicit_stop => \$explicit_stop,
1856             infix => \$infix,
1857         },
1858     );
1859
1860     $obj->_DB_on_init__initialize_globals(@_);
1861
1862     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1863     # The code being debugged may have altered them.
1864     &save;
1865
1866     # Since DB::DB gets called after every line, we can use caller() to
1867     # figure out where we last were executing. Sneaky, eh? This works because
1868     # caller is returning all the extra information when called from the
1869     # debugger.
1870     local ( $package, $filename, $line ) = caller;
1871     $filename_ini = $filename;
1872
1873     # set up the context for DB::eval, so it can properly execute
1874     # code on behalf of the user. We add the package in so that the
1875     # code is eval'ed in the proper package (not in the debugger!).
1876     local $usercontext = _calc_usercontext($package);
1877
1878     # Create an alias to the active file magical array to simplify
1879     # the code here.
1880     local (*dbline) = $main::{ '_<' . $filename };
1881
1882     # Last line in the program.
1883     $max = $#dbline;
1884
1885     _DB__determine_if_we_should_break(@_);
1886
1887     # Preserve the current stop-or-not, and see if any of the W
1888     # (watch expressions) has changed.
1889     my $was_signal = $signal;
1890
1891     # If we have any watch expressions ...
1892     $obj->_DB__handle_watch_expressions(@_);
1893
1894 =head2 C<watchfunction()>
1895
1896 C<watchfunction()> is a function that can be defined by the user; it is a
1897 function which will be run on each entry to C<DB::DB>; it gets the
1898 current package, filename, and line as its parameters.
1899
1900 The watchfunction can do anything it likes; it is executing in the
1901 debugger's context, so it has access to all of the debugger's internal
1902 data structures and functions.
1903
1904 C<watchfunction()> can control the debugger's actions. Any of the following
1905 will cause the debugger to return control to the user's program after
1906 C<watchfunction()> executes:
1907
1908 =over 4
1909
1910 =item *
1911
1912 Returning a false value from the C<watchfunction()> itself.
1913
1914 =item *
1915
1916 Altering C<$single> to a false value.
1917
1918 =item *
1919
1920 Altering C<$signal> to a false value.
1921
1922 =item *
1923
1924 Turning off the C<4> bit in C<$trace> (this also disables the
1925 check for C<watchfunction()>. This can be done with
1926
1927     $trace &= ~4;
1928
1929 =back
1930
1931 =cut
1932
1933     # If there's a user-defined DB::watchfunction, call it with the
1934     # current package, filename, and line. The function executes in
1935     # the DB:: package.
1936     if ( $trace & 4 ) {    # User-installed watch
1937         return
1938           if watchfunction( $package, $filename, $line )
1939           and not $single
1940           and not $was_signal
1941           and not( $trace & ~4 );
1942     } ## end if ($trace & 4)
1943
1944     # Pick up any alteration to $signal in the watchfunction, and
1945     # turn off the signal now.
1946     $was_signal = $signal;
1947     $signal     = 0;
1948
1949 =head2 GETTING READY TO EXECUTE COMMANDS
1950
1951 The debugger decides to take control if single-step mode is on, the
1952 C<t> command was entered, or the user generated a signal. If the program
1953 has fallen off the end, we set things up so that entering further commands
1954 won't cause trouble, and we say that the program is over.
1955
1956 =cut
1957
1958     # Make sure that we always print if asked for explicitly regardless
1959     # of $trace_to_depth .
1960     $explicit_stop = ($single || $was_signal);
1961
1962     # Check to see if we should grab control ($single true,
1963     # trace set appropriately, or we got a signal).
1964     if ( $explicit_stop || ( $trace & 1 ) ) {
1965         $obj->_DB__grab_control(@_);
1966     } ## end if ($single || ($trace...
1967
1968 =pod
1969
1970 If there's an action to be executed for the line we stopped at, execute it.
1971 If there are any preprompt actions, execute those as well.
1972
1973 =cut
1974
1975     # If there's an action, do it now.
1976     if ($action) {
1977         $evalarg = $action;
1978         DB::eval();
1979     }
1980
1981     # Are we nested another level (e.g., did we evaluate a function
1982     # that had a breakpoint in it at the debugger prompt)?
1983     if ( $single || $was_signal ) {
1984
1985         # Yes, go down a level.
1986         local $level = $level + 1;
1987
1988         # Do any pre-prompt actions.
1989         foreach $evalarg (@$pre) {
1990             DB::eval();
1991         }
1992
1993         # Complain about too much recursion if we passed the limit.
1994         if ($single & 4) {
1995             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
1996         }
1997
1998         # The line we're currently on. Set $incr to -1 to stay here
1999         # until we get a command that tells us to advance.
2000         $start = $line;
2001         $incr  = -1;      # for backward motion.
2002
2003         # Tack preprompt debugger actions ahead of any actual input.
2004         @typeahead = ( @$pretype, @typeahead );
2005
2006 =head2 WHERE ARE WE?
2007
2008 XXX Relocate this section?
2009
2010 The debugger normally shows the line corresponding to the current line of
2011 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2012 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2013
2014 C<$incr> controls by how many lines the I<current> line should move forward
2015 after a command is executed. If set to -1, this indicates that the I<current>
2016 line shouldn't change.
2017
2018 C<$start> is the I<current> line. It is used for things like knowing where to
2019 move forwards or backwards from when doing an C<L> or C<-> command.
2020
2021 C<$max> tells the debugger where the last line of the current file is. It's
2022 used to terminate loops most often.
2023
2024 =head2 THE COMMAND LOOP
2025
2026 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2027 in two parts:
2028
2029 =over 4
2030
2031 =item *
2032
2033 The outer part of the loop, starting at the C<CMD> label. This loop
2034 reads a command and then executes it.
2035
2036 =item *
2037
2038 The inner part of the loop, starting at the C<PIPE> label. This part
2039 is wholly contained inside the C<CMD> block and only executes a command.
2040 Used to handle commands running inside a pager.
2041
2042 =back
2043
2044 So why have two labels to restart the loop? Because sometimes, it's easier to
2045 have a command I<generate> another command and then re-execute the loop to do
2046 the new command. This is faster, but perhaps a bit more convoluted.
2047
2048 =cut
2049
2050         # The big command dispatch loop. It keeps running until the
2051         # user yields up control again.
2052         #
2053         # If we have a terminal for input, and we get something back
2054         # from readline(), keep on processing.
2055         my $piped;
2056         my $selected;
2057
2058       CMD:
2059         while (_DB__read_next_cmd($tid))
2060         {
2061
2062             share($cmd);
2063             # ... try to execute the input as debugger commands.
2064
2065             # Don't stop running.
2066             $single = 0;
2067
2068             # No signal is active.
2069             $signal = 0;
2070
2071             # Handle continued commands (ending with \):
2072             if ($cmd =~ s/\\\z/\n/) {
2073                 $cmd .= DB::readline("  cont: ");
2074                 redo CMD;
2075             }
2076
2077 =head4 The null command
2078
2079 A newline entered by itself means I<re-execute the last command>. We grab the
2080 command out of C<$laststep> (where it was recorded previously), and copy it
2081 back into C<$cmd> to be executed below. If there wasn't any previous command,
2082 we'll do nothing below (no command will match). If there was, we also save it
2083 in the command history and fall through to allow the command parsing to pick
2084 it up.
2085
2086 =cut
2087
2088             # Empty input means repeat the last command.
2089             if ($cmd eq '') {
2090                 $cmd = $laststep;
2091             }
2092             chomp($cmd);    # get rid of the annoying extra newline
2093             if (length($cmd) >= 2) {
2094                 push( @hist, $cmd );
2095             }
2096             push( @truehist, $cmd );
2097             share(@hist);
2098             share(@truehist);
2099
2100             # This is a restart point for commands that didn't arrive
2101             # via direct user input. It allows us to 'redo PIPE' to
2102             # re-execute command processing without reading a new command.
2103           PIPE: {
2104                 my $i = _DB__trim_command_and_return_first_component();
2105
2106 =head3 COMMAND ALIASES
2107
2108 The debugger can create aliases for commands (these are stored in the
2109 C<%alias> hash). Before a command is executed, the command loop looks it up
2110 in the alias hash and substitutes the contents of the alias for the command,
2111 completely replacing it.
2112
2113 =cut
2114
2115                 # See if there's an alias for the command, and set it up if so.
2116                 if ( $alias{$i} ) {
2117
2118                     # Squelch signal handling; we want to keep control here
2119                     # if something goes loco during the alias eval.
2120                     local $SIG{__DIE__};
2121                     local $SIG{__WARN__};
2122
2123                     # This is a command, so we eval it in the DEBUGGER's
2124                     # scope! Otherwise, we can't see the special debugger
2125                     # variables, or get to the debugger's subs. (Well, we
2126                     # _could_, but why make it even more complicated?)
2127                     eval "\$cmd =~ $alias{$i}";
2128                     if ($@) {
2129                         local $\ = '';
2130                         print $OUT "Couldn't evaluate '$i' alias: $@";
2131                         next CMD;
2132                     }
2133                 } ## end if ($alias{$i})
2134
2135 =head3 MAIN-LINE COMMANDS
2136
2137 All of these commands work up to and after the program being debugged has
2138 terminated.
2139
2140 =head4 C<q> - quit
2141
2142 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2143 try to execute further, cleaning any restart-related stuff out of the
2144 environment, and executing with the last value of C<$?>.
2145
2146 =cut
2147
2148                 if ($cmd eq 'q') {
2149                     $fall_off_end = 1;
2150                     clean_ENV();
2151                     exit $?;
2152                 }
2153
2154 =head4 C<t> - trace [n]
2155
2156 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2157 If level is specified, set C<$trace_to_depth>.
2158
2159 =cut
2160
2161                 $obj->_handle_t_command();
2162
2163 =head4 C<S> - list subroutines matching/not matching a pattern
2164
2165 Walks through C<%sub>, checking to see whether or not to print the name.
2166
2167 =cut
2168
2169                 if (my ($print_all_subs, $should_reverse, $Spatt)
2170                     = $cmd =~ /\AS(\s+(!)?(.+))?\z/) {
2171                     # $Spatt is the pattern (if any) to use.
2172                     # Reverse scan?
2173                     my $Srev     = defined $should_reverse;
2174                     # No args - print all subs.
2175                     my $Snocheck = !defined $print_all_subs;
2176
2177                     # Need to make these sane here.
2178                     local $\ = '';
2179                     local $, = '';
2180
2181                     # Search through the debugger's magical hash of subs.
2182                     # If $nocheck is true, just print the sub name.
2183                     # Otherwise, check it against the pattern. We then use
2184                     # the XOR trick to reverse the condition as required.
2185                     foreach $subname ( sort( keys %sub ) ) {
2186                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2187                             print $OUT $subname, "\n";
2188                         }
2189                     }
2190                     next CMD;
2191                 }
2192
2193 =head4 C<X> - list variables in current package
2194
2195 Since the C<V> command actually processes this, just change this to the
2196 appropriate C<V> command and fall through.
2197
2198 =cut
2199
2200                 $cmd =~ s/^X\b/V $package/;
2201
2202 =head4 C<V> - list variables
2203
2204 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2205
2206 =cut
2207
2208                 # Bare V commands get the currently-being-debugged package
2209                 # added.
2210                 if ($cmd eq "V") {
2211                     $cmd = "V $package";
2212                 }
2213
2214                 # V - show variables in package.
2215                 if (my ($new_packname, $new_vars_str) =
2216                     $cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
2217
2218                     # Save the currently selected filehandle and
2219                     # force output to debugger's filehandle (dumpvar
2220                     # just does "print" for output).
2221                     my $savout = select($OUT);
2222
2223                     # Grab package name and variables to dump.
2224                     $packname = $new_packname;
2225                     my @vars     = split( ' ', $new_vars_str );
2226
2227                     # If main::dumpvar isn't here, get it.
2228                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2229                     if ( defined &main::dumpvar ) {
2230
2231                         # We got it. Turn off subroutine entry/exit messages
2232                         # for the moment, along with return values.
2233                         local $frame = 0;
2234                         local $doret = -2;
2235
2236                         # must detect sigpipe failures  - not catching
2237                         # then will cause the debugger to die.
2238                         eval {
2239                             &main::dumpvar(
2240                                 $packname,
2241                                 defined $option{dumpDepth}
2242                                 ? $option{dumpDepth}
2243                                 : -1,    # assume -1 unless specified
2244                                 @vars
2245                             );
2246                         };
2247
2248                         # The die doesn't need to include the $@, because
2249                         # it will automatically get propagated for us.
2250                         if ($@) {
2251                             die unless $@ =~ /dumpvar print failed/;
2252                         }
2253                     } ## end if (defined &main::dumpvar)
2254                     else {
2255
2256                         # Couldn't load dumpvar.
2257                         print $OUT "dumpvar.pl not available.\n";
2258                     }
2259
2260                     # Restore the output filehandle, and go round again.
2261                     select($savout);
2262                     next CMD;
2263                 }
2264
2265 =head4 C<x> - evaluate and print an expression
2266
2267 Hands the expression off to C<DB::eval>, setting it up to print the value
2268 via C<dumpvar.pl> instead of just printing it directly.
2269
2270 =cut
2271
2272                 if ($cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
2273                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2274
2275                     # handle special  "x 3 blah" syntax XXX propagate
2276                     # doc back to special variables.
2277                     if ( $cmd =~ s#\A\s*(\d+)(?=\s)# #) {
2278                         $onetimedumpDepth = $1;
2279                     }
2280                 }
2281
2282 =head4 C<m> - print methods
2283
2284 Just uses C<DB::methods> to determine what methods are available.
2285
2286 =cut
2287
2288                 if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2289                     methods($1);
2290                     next CMD;
2291                 }
2292
2293                 # m expr - set up DB::eval to do the work
2294                 if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2295                     $onetimeDump = 'methods';   #  method output gets used there
2296                 }
2297
2298 =head4 C<f> - switch files
2299
2300 =cut
2301
2302                 if (($file) = $cmd =~ /\Af\b\s*(.*)/) {
2303                     $file =~ s/\s+$//;
2304
2305                     # help for no arguments (old-style was return from sub).
2306                     if ( !$file ) {
2307                         print $OUT
2308                           "The old f command is now the r command.\n";    # hint
2309                         print $OUT "The new f command switches filenames.\n";
2310                         next CMD;
2311                     } ## end if (!$file)
2312
2313                     # if not in magic file list, try a close match.
2314                     if ( !defined $main::{ '_<' . $file } ) {
2315                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2316                             {
2317                                 $try = substr( $try, 2 );
2318                                 print $OUT "Choosing $try matching '$file':\n";
2319                                 $file = $try;
2320                             }
2321                         } ## end if (($try) = grep(m#^_<.*$file#...
2322                     } ## end if (!defined $main::{ ...
2323
2324                     # If not successfully switched now, we failed.
2325                     if ( !defined $main::{ '_<' . $file } ) {
2326                         print $OUT "No file matching '$file' is loaded.\n";
2327                         next CMD;
2328                     }
2329
2330                     # We switched, so switch the debugger internals around.
2331                     elsif ( $file ne $filename ) {
2332                         *dbline   = $main::{ '_<' . $file };
2333                         $max      = $#dbline;
2334                         $filename = $file;
2335                         $start    = 1;
2336                         $cmd      = "l";
2337                     } ## end elsif ($file ne $filename)
2338
2339                     # We didn't switch; say we didn't.
2340                     else {
2341                         print $OUT "Already in $file.\n";
2342                         next CMD;
2343                     }
2344                 }
2345
2346 =head4 C<.> - return to last-executed line.
2347
2348 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2349 and then we look up the line in the magical C<%dbline> hash.
2350
2351 =cut
2352
2353                 # . command.
2354                 if ($cmd eq '.') {
2355                     $incr = -1;    # stay at current line
2356
2357                     # Reset everything to the old location.
2358                     $start    = $line;
2359                     $filename = $filename_ini;
2360                     *dbline   = $main::{ '_<' . $filename };
2361                     $max      = $#dbline;
2362
2363                     # Now where are we?
2364                     print_lineinfo($position);
2365                     next CMD;
2366                 }
2367
2368 =head4 C<-> - back one window
2369
2370 We change C<$start> to be one window back; if we go back past the first line,
2371 we set it to be the first line. We ser C<$incr> to put us back at the
2372 currently-executing line, and then put a C<l $start +> (list one window from
2373 C<$start>) in C<$cmd> to be executed later.
2374
2375 =cut
2376
2377                 # - - back a window.
2378                 if ($cmd eq '-') {
2379
2380                     # back up by a window; go to 1 if back too far.
2381                     $start -= $incr + $window + 1;
2382                     $start = 1 if $start <= 0;
2383                     $incr  = $window - 1;
2384
2385                     # Generate and execute a "l +" command (handled below).
2386                     $cmd = 'l ' . ($start) . '+';
2387                 }
2388
2389 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2390
2391 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2392 problems, most notably that the default case of several commands destroying
2393 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2394 retain the old commands for those who were used to using them or who preferred
2395 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2396 deal with them instead of processing them in-line.
2397
2398 =cut
2399
2400                 # All of these commands were remapped in perl 5.8.0;
2401                 # we send them off to the secondary dispatcher (see below).
2402                 if (my ($cmd_letter, $my_arg) = $cmd =~ /\A([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so) {
2403                     &cmd_wrapper( $cmd_letter, $my_arg, $line );
2404                     next CMD;
2405                 }
2406
2407 =head4 C<y> - List lexicals in higher scope
2408
2409 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2410 above the current one and then displays then using C<dumpvar.pl>.
2411
2412 =cut
2413
2414                 if (my ($match_level, $match_vars)
2415                     = $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/) {
2416
2417                     # See if we've got the necessary support.
2418                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2419                       or &warn(
2420                         $@ =~ /locate/
2421                         ? "PadWalker module not found - please install\n"
2422                         : $@
2423                       )
2424                       and next CMD;
2425
2426                     # Load up dumpvar if we don't have it. If we can, that is.
2427                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2428                     defined &main::dumpvar
2429                       or print $OUT "dumpvar.pl not available.\n"
2430                       and next CMD;
2431
2432                     # Got all the modules we need. Find them and print them.
2433                     my @vars = split( ' ', $match_vars || '' );
2434
2435                     # Find the pad.
2436                     my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
2437
2438                     # Oops. Can't find it.
2439                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2440
2441                     # Show the desired vars with dumplex().
2442                     my $savout = select($OUT);
2443
2444                     # Have dumplex dump the lexicals.
2445                     dumpvar::dumplex( $_, $h->{$_},
2446                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2447                         @vars )
2448                       for sort keys %$h;
2449                     select($savout);
2450                     next CMD;
2451                 }
2452
2453 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2454
2455 All of the commands below this point don't work after the program being
2456 debugged has ended. All of them check to see if the program has ended; this
2457 allows the commands to be relocated without worrying about a 'line of
2458 demarcation' above which commands can be entered anytime, and below which
2459 they can't.
2460
2461 =head4 C<n> - single step, but don't trace down into subs
2462
2463 Done by setting C<$single> to 2, which forces subs to execute straight through
2464 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2465 so a null command knows what to re-execute.
2466
2467 =cut
2468
2469                 # n - next
2470                 if ($cmd eq 'n') {
2471                     next CMD if _DB__is_finished();
2472
2473                     # Single step, but don't enter subs.
2474                     $single = 2;
2475
2476                     # Save for empty command (repeat last).
2477                     $laststep = $cmd;
2478                     last CMD;
2479                 }
2480
2481 =head4 C<s> - single-step, entering subs
2482
2483 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2484 subs. Also saves C<s> as C<$lastcmd>.
2485
2486 =cut
2487
2488                 # s - single step.
2489                 if ($cmd eq 's') {
2490
2491                     # Get out and restart the command loop if program
2492                     # has finished.
2493                     next CMD if _DB__is_finished();
2494
2495                     # Single step should enter subs.
2496                     $single = 1;
2497
2498                     # Save for empty command (repeat last).
2499                     $laststep = $cmd;
2500                     last CMD;
2501                 }
2502
2503 =head4 C<c> - run continuously, setting an optional breakpoint
2504
2505 Most of the code for this command is taken up with locating the optional
2506 breakpoint, which is either a subroutine name or a line number. We set
2507 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2508 in this and all call levels above this one.
2509
2510 =cut
2511
2512                 # c - start continuous execution.
2513                 if (($i) = $cmd =~ m#\Ac\b\s*([\w:]*)\s*\z#) {
2514
2515                     # Hey, show's over. The debugged program finished
2516                     # executing already.
2517                     next CMD if _DB__is_finished();
2518
2519                     # Capture the place to put a one-time break.
2520                     $subname = $i;
2521
2522                     #  Probably not needed, since we finish an interactive
2523                     #  sub-session anyway...
2524                     # local $filename = $filename;
2525                     # local *dbline = *dbline; # XXX Would this work?!
2526                     #
2527                     # The above question wonders if localizing the alias
2528                     # to the magic array works or not. Since it's commented
2529                     # out, we'll just leave that to speculation for now.
2530
2531                     # If the "subname" isn't all digits, we'll assume it
2532                     # is a subroutine name, and try to find it.
2533                     if ( $subname =~ /\D/ ) {    # subroutine name
2534                             # Qualify it to the current package unless it's
2535                             # already qualified.
2536                         $subname = $package . "::" . $subname
2537                           unless $subname =~ /::/;
2538
2539                         # find_sub will return "file:line_number" corresponding
2540                         # to where the subroutine is defined; we call find_sub,
2541                         # break up the return value, and assign it in one
2542                         # operation.
2543                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2544
2545                         # Force the line number to be numeric.
2546                         $i += 0;
2547
2548                         # If we got a line number, we found the sub.
2549                         if ($i) {
2550
2551                             # Switch all the debugger's internals around so
2552                             # we're actually working with that file.
2553                             $filename = $file;
2554                             *dbline   = $main::{ '_<' . $filename };
2555
2556                             # Mark that there's a breakpoint in this file.
2557                             $had_breakpoints{$filename} |= 1;
2558
2559                             # Scan forward to the first executable line
2560                             # after the 'sub whatever' line.
2561                             $max = $#dbline;
2562                             ++$i while $dbline[$i] == 0 && $i < $max;
2563                         } ## end if ($i)
2564
2565                         # We didn't find a sub by that name.
2566                         else {
2567                             print $OUT "Subroutine $subname not found.\n";
2568                             next CMD;
2569                         }
2570                     } ## end if ($subname =~ /\D/)
2571
2572                     # At this point, either the subname was all digits (an
2573                     # absolute line-break request) or we've scanned through
2574                     # the code following the definition of the sub, looking
2575                     # for an executable, which we may or may not have found.
2576                     #
2577                     # If $i (which we set $subname from) is non-zero, we
2578                     # got a request to break at some line somewhere. On
2579                     # one hand, if there wasn't any real subroutine name
2580                     # involved, this will be a request to break in the current
2581                     # file at the specified line, so we have to check to make
2582                     # sure that the line specified really is breakable.
2583                     #
2584                     # On the other hand, if there was a subname supplied, the
2585                     # preceding block has moved us to the proper file and
2586                     # location within that file, and then scanned forward
2587                     # looking for the next executable line. We have to make
2588                     # sure that one was found.
2589                     #
2590                     # On the gripping hand, we can't do anything unless the
2591                     # current value of $i points to a valid breakable line.
2592                     # Check that.
2593                     if ($i) {
2594
2595                         # Breakable?
2596                         if ( $dbline[$i] == 0 ) {
2597                             print $OUT "Line $i not breakable.\n";
2598                             next CMD;
2599                         }
2600
2601                         # Yes. Set up the one-time-break sigil.
2602                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2603                         _enable_breakpoint_temp_enabled_status($filename, $i);
2604                     } ## end if ($i)
2605
2606                     # Turn off stack tracing from here up.
2607                     for my $i (0 .. $stack_depth) {
2608                         $stack[ $i ] &= ~1;
2609                     }
2610                     last CMD;
2611                 }
2612
2613 =head4 C<r> - return from a subroutine
2614
2615 For C<r> to work properly, the debugger has to stop execution again
2616 immediately after the return is executed. This is done by forcing
2617 single-stepping to be on in the call level above the current one. If
2618 we are printing return values when a C<r> is executed, set C<$doret>
2619 appropriately, and force us out of the command loop.
2620
2621 =cut
2622
2623                 # r - return from the current subroutine.
2624                 if ($cmd eq 'r') {
2625
2626                     # Can't do anything if the program's over.
2627                     next CMD if _DB__is_finished();
2628
2629                     # Turn on stack trace.
2630                     $stack[$stack_depth] |= 1;
2631
2632                     # Print return value unless the stack is empty.
2633                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2634                     last CMD;
2635                 }
2636
2637 =head4 C<T> - stack trace
2638
2639 Just calls C<DB::print_trace>.
2640
2641 =cut
2642
2643                 if ($cmd eq 'T') {
2644                     print_trace( $OUT, 1 );    # skip DB
2645                     next CMD;
2646                 }
2647
2648 =head4 C<w> - List window around current line.
2649
2650 Just calls C<DB::cmd_w>.
2651
2652 =cut
2653
2654                 if (my ($arg) = $cmd =~ /\Aw\b\s*(.*)/s) {
2655                     &cmd_w( 'w', $arg );
2656                     next CMD;
2657                 }
2658
2659 =head4 C<W> - watch-expression processing.
2660
2661 Just calls C<DB::cmd_W>.
2662
2663 =cut
2664
2665                 if (my ($arg) = $cmd =~ /\AW\b\s*(.*)/s) {
2666                     &cmd_W( 'W', $arg );
2667                     next CMD;
2668                 }
2669
2670 =head4 C</> - search forward for a string in the source
2671
2672 We take the argument and treat it as a pattern. If it turns out to be a
2673 bad one, we return the error we got from trying to C<eval> it and exit.
2674 If not, we create some code to do the search and C<eval> it so it can't
2675 mess us up.
2676
2677 =cut
2678
2679                 # The pattern as a string.
2680                 use vars qw($inpat);
2681
2682                 if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2683
2684                     # Remove the final slash.
2685                     $inpat =~ s:([^\\])/$:$1:;
2686
2687                     # If the pattern isn't null ...
2688                     if ( $inpat ne "" ) {
2689
2690                         # Turn of warn and die procesing for a bit.
2691                         local $SIG{__DIE__};
2692                         local $SIG{__WARN__};
2693
2694                         # Create the pattern.
2695                         eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2696                         if ( $@ ne "" ) {
2697
2698                             # Oops. Bad pattern. No biscuit.
2699                             # Print the eval error and go back for more
2700                             # commands.
2701                             print $OUT "$@";
2702                             next CMD;
2703                         }
2704                         $pat = $inpat;
2705                     } ## end if ($inpat ne "")
2706
2707                     # Set up to stop on wrap-around.
2708                     $end = $start;
2709
2710                     # Don't move off the current line.
2711                     $incr = -1;
2712
2713                     # Done in eval so nothing breaks if the pattern
2714                     # does something weird.
2715                     eval '
2716                         no strict q/vars/;
2717                         for (;;) {
2718                             # Move ahead one line.
2719                             ++$start;
2720
2721                             # Wrap if we pass the last line.
2722                             $start = 1 if ($start > $max);
2723
2724                             # Stop if we have gotten back to this line again,
2725                             last if ($start == $end);
2726
2727                             # A hit! (Note, though, that we are doing
2728                             # case-insensitive matching. Maybe a qr//
2729                             # expression would be better, so the user could
2730                             # do case-sensitive matching if desired.
2731                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2732                                 if ($slave_editor) {
2733                                     # Handle proper escaping in the slave.
2734                                     print $OUT "\032\032$filename:$start:0\n";
2735                                 }
2736                                 else {
2737                                     # Just print the line normally.
2738                                     print $OUT "$start:\t",$dbline[$start],"\n";
2739                                 }
2740                                 # And quit since we found something.
2741                                 last;
2742                             }
2743                          } ';
2744
2745                     # If we wrapped, there never was a match.
2746                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2747                     next CMD;
2748                 }
2749
2750 =head4 C<?> - search backward for a string in the source
2751
2752 Same as for C</>, except the loop runs backwards.
2753
2754 =cut
2755
2756                 # ? - backward pattern search.
2757                 if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2758
2759                     # Get the pattern, remove trailing question mark.
2760                     $inpat =~ s:([^\\])\?$:$1:;
2761
2762                     # If we've got one ...
2763                     if ( $inpat ne "" ) {
2764
2765                         # Turn off die & warn handlers.
2766                         local $SIG{__DIE__};
2767                         local $SIG{__WARN__};
2768                         eval '$inpat =~ m' . "\a$inpat\a";
2769
2770                         if ( $@ ne "" ) {
2771
2772                             # Ouch. Not good. Print the error.
2773                             print $OUT $@;
2774                             next CMD;
2775                         }
2776                         $pat = $inpat;
2777                     } ## end if ($inpat ne "")
2778
2779                     # Where we are now is where to stop after wraparound.
2780                     $end = $start;
2781
2782                     # Don't move away from this line.
2783                     $incr = -1;
2784
2785                     # Search inside the eval to prevent pattern badness
2786                     # from killing us.
2787                     eval '
2788                         no strict q/vars/;
2789                         for (;;) {
2790                             # Back up a line.
2791                             --$start;
2792
2793                             # Wrap if we pass the first line.
2794
2795                             $start = $max if ($start <= 0);
2796
2797                             # Quit if we get back where we started,
2798                             last if ($start == $end);
2799
2800                             # Match?
2801                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2802                                 if ($slave_editor) {
2803                                     # Yep, follow slave editor requirements.
2804                                     print $OUT "\032\032$filename:$start:0\n";
2805                                 }
2806                                 else {
2807                                     # Yep, just print normally.
2808                                     print $OUT "$start:\t",$dbline[$start],"\n";
2809                                 }
2810
2811                                 # Found, so done.
2812                                 last;
2813                             }
2814                         } ';
2815
2816                     # Say we failed if the loop never found anything,
2817                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2818                     next CMD;
2819                 }
2820
2821 =head4 C<$rc> - Recall command
2822
2823 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2824 that the terminal supports history). It find the the command required, puts it
2825 into C<$cmd>, and redoes the loop to execute it.
2826
2827 =cut
2828
2829                 # $rc - recall command.
2830                 if (my ($minus, $arg) = $cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
2831
2832                     # No arguments, take one thing off history.
2833                     pop(@hist) if length($cmd) > 1;
2834
2835                     # Relative (- found)?
2836                     #  Y - index back from most recent (by 1 if bare minus)
2837                     #  N - go to that particular command slot or the last
2838                     #      thing if nothing following.
2839                     $i = $minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist );
2840
2841                     # Pick out the command desired.
2842                     $cmd = $hist[$i];
2843
2844                     # Print the command to be executed and restart the loop
2845                     # with that command in the buffer.
2846                     print $OUT $cmd, "\n";
2847                     redo CMD;
2848                 }
2849
2850 =head4 C<$sh$sh> - C<system()> command
2851
2852 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2853 C<STDOUT> from getting messed up.
2854
2855 =cut
2856
2857                 # $sh$sh - run a shell command (if it's all ASCII).
2858                 # Can't run shell commands with Unicode in the debugger, hmm.
2859                 if (my ($arg) = $cmd =~ m#\A$sh$sh\s*(.*)#ms) {
2860
2861                     # System it.
2862                     &system($arg);
2863                     next CMD;
2864                 }
2865
2866 =head4 C<$rc I<pattern> $rc> - Search command history
2867
2868 Another command to manipulate C<@hist>: this one searches it with a pattern.
2869 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2870
2871 =cut
2872
2873                 # $rc pattern $rc - find a command in the history.
2874                 if (my ($arg) = $cmd =~ /\A$rc([^$rc].*)\z/) {
2875
2876                     # Create the pattern to use.
2877                     $pat = "^$arg";
2878
2879                     # Toss off last entry if length is >1 (and it always is).
2880                     pop(@hist) if length($cmd) > 1;
2881
2882                     # Look backward through the history.
2883                     for ( $i = $#hist ; $i ; --$i ) {
2884                         # Stop if we find it.
2885                         last if $hist[$i] =~ /$pat/;
2886                     }
2887
2888                     if ( !$i ) {
2889
2890                         # Never found it.
2891                         print $OUT "No such command!\n\n";
2892                         next CMD;
2893                     }
2894
2895                     # Found it. Put it in the buffer, print it, and process it.
2896                     $cmd = $hist[$i];
2897                     print $OUT $cmd, "\n";
2898                     redo CMD;
2899                 }
2900
2901 =head4 C<$sh> - Invoke a shell
2902
2903 Uses C<DB::system> to invoke a shell.
2904
2905 =cut
2906
2907                 # $sh - start a shell.
2908                 if ($cmd =~ /\A$sh\z/) {
2909
2910                     # Run the user's shell. If none defined, run Bourne.
2911                     # We resume execution when the shell terminates.
2912                     &system( $ENV{SHELL} || "/bin/sh" );
2913                     next CMD;
2914                 }
2915
2916 =head4 C<$sh I<command>> - Force execution of a command in a shell
2917
2918 Like the above, but the command is passed to the shell. Again, we use
2919 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
2920
2921 =cut
2922
2923                 # $sh command - start a shell and run a command in it.
2924                 if (my ($arg) = $cmd =~ m#\A$sh\s*(.*)#ms) {
2925
2926                     # XXX: using csh or tcsh destroys sigint retvals!
2927                     #&system($1);  # use this instead
2928
2929                     # use the user's shell, or Bourne if none defined.
2930                     &system( $ENV{SHELL} || "/bin/sh", "-c", $arg );
2931                     next CMD;
2932                 }
2933
2934 =head4 C<H> - display commands in history
2935
2936 Prints the contents of C<@hist> (if any).
2937
2938 =cut
2939
2940                 if ($cmd =~ /\AH\b\s*\*/) {
2941                     @hist = @truehist = ();
2942                     print $OUT "History cleansed\n";
2943                     next CMD;
2944                 }
2945
2946                 if (my ($num)
2947                     = $cmd =~ /\AH\b\s*(?:-(\d+))?/) {
2948
2949                     # Anything other than negative numbers is ignored by
2950                     # the (incorrect) pattern, so this test does nothing.
2951                     $end = $num ? ( $#hist - $num ) : 0;
2952
2953                     # Set to the minimum if less than zero.
2954                     $hist = 0 if $hist < 0;
2955
2956                     # Start at the end of the array.
2957                     # Stay in while we're still above the ending value.
2958                     # Tick back by one each time around the loop.
2959                     for ( $i = $#hist ; $i > $end ; $i-- ) {
2960
2961                         # Print the command  unless it has no arguments.
2962                         print $OUT "$i: ", $hist[$i], "\n"
2963                           unless $hist[$i] =~ /^.?$/;
2964                     }
2965                     next CMD;
2966                 }
2967
2968 =head4 C<man, doc, perldoc> - look up documentation
2969
2970 Just calls C<runman()> to print the appropriate document.
2971
2972 =cut
2973
2974                 # man, perldoc, doc - show manual pages.
2975                 if (my ($man_page)
2976                     = $cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
2977                     runman($man_page);
2978                     next CMD;
2979                 }
2980
2981 =head4 C<p> - print
2982
2983 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
2984 the bottom of the loop.
2985
2986 =cut
2987
2988                 my $print_cmd = 'print {$DB::OUT} ';
2989                 # p - print (no args): print $_.
2990                 if ($cmd eq 'p') {
2991                     $cmd = $print_cmd . '$_';
2992                 }
2993
2994                 # p - print the given expression.
2995                 $cmd =~ s/\Ap\b/$print_cmd /;
2996
2997 =head4 C<=> - define command alias
2998
2999 Manipulates C<%alias> to add or list command aliases.
3000
3001 =cut
3002
3003                 # = - set up a command alias.
3004                 if ($cmd =~ s/\A=\s*//) {
3005                     my @keys;
3006                     if ( length $cmd == 0 ) {
3007
3008                         # No args, get current aliases.
3009                         @keys = sort keys %alias;
3010                     }
3011                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3012
3013                         # Creating a new alias. $k is alias name, $v is
3014                         # alias value.
3015
3016                         # can't use $_ or kill //g state
3017                         for my $x ( $k, $v ) {
3018
3019                             # Escape "alarm" characters.
3020                             $x =~ s/\a/\\a/g;
3021                         }
3022
3023                         # Substitute key for value, using alarm chars
3024                         # as separators (which is why we escaped them in
3025                         # the command).
3026                         $alias{$k} = "s\a$k\a$v\a";
3027
3028                         # Turn off standard warn and die behavior.
3029                         local $SIG{__DIE__};
3030                         local $SIG{__WARN__};
3031
3032                         # Is it valid Perl?
3033                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3034
3035                             # Nope. Bad alias. Say so and get out.
3036                             print $OUT "Can't alias $k to $v: $@\n";
3037                             delete $alias{$k};
3038                             next CMD;
3039                         }
3040
3041                         # We'll only list the new one.
3042                         @keys = ($k);
3043                     } ## end elsif (my ($k, $v) = ($cmd...
3044
3045                     # The argument is the alias to list.
3046                     else {
3047                         @keys = ($cmd);
3048                     }
3049
3050                     # List aliases.
3051                     for my $k (@keys) {
3052
3053                         # Messy metaquoting: Trim the substitution code off.
3054                         # We use control-G as the delimiter because it's not
3055                         # likely to appear in the alias.
3056                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3057
3058                             # Print the alias.
3059                             print $OUT "$k\t= $1\n";
3060                         }
3061                         elsif ( defined $alias{$k} ) {
3062
3063                             # Couldn't trim it off; just print the alias code.
3064                             print $OUT "$k\t$alias{$k}\n";
3065                         }
3066                         else {
3067
3068                             # No such, dude.
3069                             print "No alias for $k\n";
3070                         }
3071                     } ## end for my $k (@keys)
3072                     next CMD;
3073                 }
3074
3075 =head4 C<source> - read commands from a file.
3076
3077 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3078 pick it up.
3079
3080 =cut
3081
3082                 # source - read commands from a file (or pipe!) and execute.
3083                 if (my ($sourced_fn) = $cmd =~ /\Asource\s+(.*\S)/) {
3084                     if ( open my $fh, $sourced_fn ) {
3085
3086                         # Opened OK; stick it in the list of file handles.
3087                         push @cmdfhs, $fh;
3088                     }
3089                     else {
3090
3091                         # Couldn't open it.
3092                         &warn("Can't execute '$sourced_fn': $!\n");
3093                     }
3094                     next CMD;
3095                 }
3096
3097                 if (my ($which_cmd, $position)
3098                     = $cmd =~ /^(enable|disable)\s+(\S+)\s*$/) {
3099
3100                     my ($fn, $line_num);
3101                     if ($position =~ m{\A\d+\z})
3102                     {
3103                         $fn = $filename;
3104                         $line_num = $position;
3105                     }
3106                     elsif (my ($new_fn, $new_line_num)
3107                         = $position =~ m{\A(.*):(\d+)\z}) {
3108                         ($fn, $line_num) = ($new_fn, $new_line_num);
3109                     }
3110                     else
3111                     {
3112                         &warn("Wrong spec for enable/disable argument.\n");
3113                     }
3114
3115                     if (defined($fn)) {
3116                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3117                             _set_breakpoint_enabled_status($fn, $line_num,
3118                                 ($which_cmd eq 'enable' ? 1 : '')
3119                             );
3120                         }
3121                         else {
3122                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3123                         }
3124                     }
3125
3126                     next CMD;
3127                 }
3128
3129 =head4 C<save> - send current history to a file
3130
3131 Takes the complete history, (not the shrunken version you see with C<H>),
3132 and saves it to the given filename, so it can be replayed using C<source>.
3133
3134 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3135
3136 =cut
3137
3138                 # save source - write commands to a file for later use
3139                 if (my ($new_fn) = $cmd =~ /\Asave\s*(.*)\z/) {
3140                     my $filename = $new_fn || '.perl5dbrc';    # default?
3141                     if ( open my $fh, '>', $filename ) {
3142
3143                        # chomp to remove extraneous newlines from source'd files
3144                         chomp( my @truelist =
3145                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3146                               @truehist );
3147                         print $fh join( "\n", @truelist );
3148                         print "commands saved in $file\n";
3149                     }
3150                     else {
3151                         &warn("Can't save debugger commands in '$new_fn': $!\n");
3152                     }
3153                     next CMD;
3154                 }
3155
3156 =head4 C<R> - restart
3157
3158 Restart the debugger session.
3159
3160 =head4 C<rerun> - rerun the current session
3161
3162 Return to any given position in the B<true>-history list
3163
3164 =cut
3165
3166                 # R - restart execution.
3167                 # rerun - controlled restart execution.
3168                 if (my ($cmd_cmd, $cmd_params) =
3169                     $cmd =~ /\A((?:R)|(?:rerun\s*(.*)))\z/) {
3170                     my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
3171
3172                     # Close all non-system fds for a clean restart.  A more
3173                     # correct method would be to close all fds that were not
3174                     # open when the process started, but this seems to be
3175                     # hard.  See "debugger 'R'estart and open database
3176                     # connections" on p5p.
3177
3178                     my $max_fd = 1024; # default if POSIX can't be loaded
3179                     if (eval { require POSIX }) {
3180                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3181                     }
3182
3183                     if (defined $max_fd) {
3184                         foreach ($^F+1 .. $max_fd-1) {
3185                             next unless open FD_TO_CLOSE, "<&=$_";
3186                             close(FD_TO_CLOSE);
3187                         }
3188                     }
3189
3190                     # And run Perl again.  We use exec() to keep the
3191                     # PID stable (and that way $ini_pids is still valid).
3192                     exec(@args) || print $OUT "exec failed: $!\n";
3193
3194                     last CMD;
3195                 }
3196
3197 =head4 C<|, ||> - pipe output through the pager.
3198
3199 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3200 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3201 pipe to the pager (restoring the output filehandles if this fails). If this
3202 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3203 set C<$signal>, sending us back into the debugger.
3204
3205 We then trim off the pipe symbols and C<redo> the command loop at the
3206 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3207 reading another.
3208
3209 =cut
3210
3211                 # || - run command in the pager, with output to DB::OUT.
3212                 if ($cmd =~ m#\A\|\|?\s*[^|]#) {
3213                     if ( $pager =~ /^\|/ ) {
3214
3215                         # Default pager is into a pipe. Redirect I/O.
3216                         open( SAVEOUT, ">&STDOUT" )
3217                           || &warn("Can't save STDOUT");
3218                         open( STDOUT, ">&OUT" )
3219                           || &warn("Can't redirect STDOUT");
3220                     } ## end if ($pager =~ /^\|/)
3221                     else {
3222
3223                         # Not into a pipe. STDOUT is safe.
3224                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3225                     }
3226
3227                     # Fix up environment to record we have less if so.
3228                     fix_less();
3229
3230                     unless ( $piped = open( OUT, $pager ) ) {
3231
3232                         # Couldn't open pipe to pager.
3233                         &warn("Can't pipe output to '$pager'");
3234                         if ( $pager =~ /^\|/ ) {
3235
3236                             # Redirect I/O back again.
3237                             open( OUT, ">&STDOUT" )    # XXX: lost message
3238                               || &warn("Can't restore DB::OUT");
3239                             open( STDOUT, ">&SAVEOUT" )
3240                               || &warn("Can't restore STDOUT");
3241                             close(SAVEOUT);
3242                         } ## end if ($pager =~ /^\|/)
3243                         else {
3244
3245                             # Redirect I/O. STDOUT already safe.
3246                             open( OUT, ">&STDOUT" )    # XXX: lost message
3247                               || &warn("Can't restore DB::OUT");
3248                         }
3249                         next CMD;
3250                     } ## end unless ($piped = open(OUT,...
3251
3252                     # Set up broken-pipe handler if necessary.
3253                     $SIG{PIPE} = \&DB::catch
3254                       if $pager =~ /^\|/
3255                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3256
3257                     OUT->autoflush(1);
3258                     # Save current filehandle, and put it back.
3259                     $selected = select(OUT);
3260                     # Don't put it back if pager was a pipe.
3261                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3262
3263                     # Trim off the pipe symbols and run the command now.
3264                     $cmd =~ s#\A\|+\s*##;
3265                     redo PIPE;
3266                 }
3267
3268 =head3 END OF COMMAND PARSING
3269
3270 Anything left in C<$cmd> at this point is a Perl expression that we want to
3271 evaluate. We'll always evaluate in the user's context, and fully qualify
3272 any variables we might want to address in the C<DB> package.
3273
3274 =cut
3275
3276                 # t - turn trace on.
3277                 if ($cmd =~ s#\At\s+(\d+)?#\$DB::trace |= 1;\n#) {
3278                     my $trace_arg = $1;
3279                     $trace_to_depth = $trace_arg ? $stack_depth||0 + $1 : 1E9;
3280                 }
3281
3282                 # s - single-step. Remember the last command was 's'.
3283                 if ($cmd =~ s/\As\s/\$DB::single = 1;\n/) {
3284                     $laststep = 's';
3285                 }
3286
3287                 # n - single-step, but not into subs. Remember last command
3288                 # was 'n'.
3289                 if ($cmd =~ s#\An\s#\$DB::single = 2;\n#) {
3290                     $laststep = 'n';
3291                 }
3292
3293             }    # PIPE:
3294
3295             # Make sure the flag that says "the debugger's running" is
3296             # still on, to make sure we get control again.
3297             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3298
3299             # Run *our* eval that executes in the caller's context.
3300             DB::eval();
3301
3302             # Turn off the one-time-dump stuff now.
3303             if ($onetimeDump) {
3304                 $onetimeDump      = undef;
3305                 $onetimedumpDepth = undef;
3306             }
3307             elsif ( $term_pid == $$ ) {
3308                 eval { # May run under miniperl, when not available...
3309                     STDOUT->flush();
3310                     STDERR->flush();
3311                 };
3312
3313                 # XXX If this is the master pid, print a newline.
3314                 print {$OUT} "\n";
3315             }
3316         } ## end while (($term || &setterm...
3317
3318 =head3 POST-COMMAND PROCESSING
3319
3320 After each command, we check to see if the command output was piped anywhere.
3321 If so, we go through the necessary code to unhook the pipe and go back to
3322 our standard filehandles for input and output.
3323
3324 =cut
3325
3326         continue {    # CMD:
3327
3328             # At the end of every command:
3329             if ($piped) {
3330
3331                 # Unhook the pipe mechanism now.
3332                 if ( $pager =~ /^\|/ ) {
3333
3334                     # No error from the child.
3335                     $? = 0;
3336
3337                     # we cannot warn here: the handle is missing --tchrist
3338                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3339
3340                     # most of the $? crud was coping with broken cshisms
3341                     # $? is explicitly set to 0, so this never runs.
3342                     if ($?) {
3343                         print SAVEOUT "Pager '$pager' failed: ";
3344                         if ( $? == -1 ) {
3345                             print SAVEOUT "shell returned -1\n";
3346                         }
3347                         elsif ( $? >> 8 ) {
3348                             print SAVEOUT ( $? & 127 )
3349                               ? " (SIG#" . ( $? & 127 ) . ")"
3350                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3351                         }
3352                         else {
3353                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3354                         }
3355                     } ## end if ($?)
3356
3357                     # Reopen filehandle for our output (if we can) and
3358                     # restore STDOUT (if we can).
3359                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3360                     open( STDOUT, ">&SAVEOUT" )
3361                       || &warn("Can't restore STDOUT");
3362
3363                     # Turn off pipe exception handler if necessary.
3364                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3365
3366                     # Will stop ignoring SIGPIPE if done like nohup(1)
3367                     # does SIGINT but Perl doesn't give us a choice.
3368                 } ## end if ($pager =~ /^\|/)
3369                 else {
3370
3371                     # Non-piped "pager". Just restore STDOUT.
3372                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3373                 }
3374
3375                 # Close filehandle pager was using, restore the normal one
3376                 # if necessary,
3377                 close(SAVEOUT);
3378                 select($selected), $selected = "" unless $selected eq "";
3379
3380                 # No pipes now.
3381                 $piped = "";
3382             } ## end if ($piped)
3383         }    # CMD:
3384
3385 =head3 COMMAND LOOP TERMINATION
3386
3387 When commands have finished executing, we come here. If the user closed the
3388 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3389 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3390 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3391 The interpreter will then execute the next line and then return control to us
3392 again.
3393
3394 =cut
3395
3396         # No more commands? Quit.
3397         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3398
3399         # Evaluate post-prompt commands.
3400         foreach $evalarg (@$post) {
3401             DB::eval();
3402         }
3403     }    # if ($single || $signal)
3404
3405     # Put the user's globals back where you found them.
3406     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3407     ();
3408 } ## end sub DB
3409
3410 package DB::Obj;
3411
3412 sub new {
3413     my $class = shift;
3414
3415     my $self = bless {}, $class;
3416
3417     $self->_init(@_);
3418
3419     return $self;
3420 }
3421
3422 sub _init {
3423     my ($self, $args) = @_;
3424
3425     %{$self} = (%$self, %$args);
3426
3427     return;
3428 }
3429
3430 {
3431     no strict 'refs';
3432     foreach my $slot_name (qw(after explicit_stop infix position prefix)) {
3433         my $slot = $slot_name;
3434         *{$slot} = sub {
3435             my $self = shift;
3436
3437             if (@_) {
3438                 ${ $self->{$slot} } = shift;
3439             }
3440
3441             return ${ $self->{$slot} };
3442         };
3443
3444         *{"append_to_$slot"} = sub {
3445             my $self = shift;
3446             my $s = shift;
3447
3448             return $self->$slot($self->$slot . $s);
3449         };
3450     }
3451 }
3452
3453 sub _DB_on_init__initialize_globals
3454 {
3455     my $self = shift;
3456
3457     # Check for whether we should be running continuously or not.
3458     # _After_ the perl program is compiled, $single is set to 1:
3459     if ( $single and not $second_time++ ) {
3460
3461         # Options say run non-stop. Run until we get an interrupt.
3462         if ($runnonstop) {    # Disable until signal
3463                 # If there's any call stack in place, turn off single
3464                 # stepping into subs throughout the stack.
3465             for my $i (0 .. $DB::stack_depth) {
3466                 $DB::stack[ $i ] &= ~1;
3467             }
3468
3469             # And we are now no longer in single-step mode.
3470             $single = 0;
3471
3472             # If we simply returned at this point, we wouldn't get
3473             # the trace info. Fall on through.
3474             # return;
3475         } ## end if ($runnonstop)
3476
3477         elsif ($DB::ImmediateStop) {
3478
3479             # We are supposed to stop here; XXX probably a break.
3480             $DB::ImmediateStop = 0;    # We've processed it; turn it off
3481             $signal        = 1;    # Simulate an interrupt to force
3482                                    # us into the command loop
3483         }
3484     } ## end if ($single and not $second_time...
3485
3486     # If we're in single-step mode, or an interrupt (real or fake)
3487     # has occurred, turn off non-stop mode.
3488     $runnonstop = 0 if $single or $signal;
3489
3490     return;
3491 }
3492
3493 sub _DB__handle_watch_expressions
3494 {
3495     my $self = shift;
3496
3497     if ( $trace & 2 ) {
3498         for my $n (0 .. $#DB::to_watch) {
3499             $DB::evalarg = $DB::to_watch[$n];
3500             local $DB::onetimeDump;    # Tell DB::eval() to not output results
3501
3502             # Fix context DB::eval() wants to return an array, but
3503             # we need a scalar here.
3504             my ($val) = join( "', '", DB::eval() );
3505             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
3506
3507             # Did it change?
3508             if ( $val ne $DB::old_watch[$n] ) {
3509
3510                 # Yep! Show the difference, and fake an interrupt.
3511                 $signal = 1;
3512                 print {$DB::OUT} <<EOP;
3513 Watchpoint $n:\t$DB::to_watch[$n] changed:
3514     old value:\t$DB::old_watch[$n]
3515     new value:\t$val
3516 EOP
3517                 $DB::old_watch[$n] = $val;
3518             } ## end if ($val ne $old_watch...
3519         } ## end for my $n (0 ..
3520     } ## end if ($trace & 2)
3521
3522     return;
3523 }
3524
3525 sub _my_print_lineinfo
3526 {
3527     my ($self, $i, $incr_pos) = @_;
3528
3529     if ($DB::frame) {
3530         # Print it indented if tracing is on.
3531         DB::print_lineinfo( ' ' x $DB::stack_depth,
3532             "$i:\t$DB::dbline[$i]" . $self->after );
3533     }
3534     else {
3535         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3536     }
3537 }
3538
3539 sub _curr_line {
3540     return $DB::dbline[$DB::line];
3541 }
3542
3543 sub _DB__grab_control
3544 {
3545     my $self = shift;
3546
3547     # Yes, grab control.
3548     if ($DB::slave_editor) {
3549
3550         # Tell the editor to update its position.
3551         $self->position("\032\032${DB::filename}:${DB::line}:0\n");
3552         DB::print_lineinfo($self->position());
3553     }
3554
3555 =pod
3556
3557 Special check: if we're in package C<DB::fake>, we've gone through the
3558 C<END> block at least once. We set up everything so that we can continue
3559 to enter commands and have a valid context to be in.
3560
3561 =cut
3562
3563     elsif ( $DB::package eq 'DB::fake' ) {
3564
3565         # Fallen off the end already.
3566         if (!$DB::term) {
3567             DB::setterm();
3568         }
3569
3570         DB::print_help(<<EOP);
3571 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3572 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3573 B<h q>, B<h R> or B<h o> to get additional info.
3574 EOP
3575
3576         # Set the DB::eval context appropriately.
3577         $DB::package     = 'main';
3578         $DB::usercontext = DB::_calc_usercontext($DB::package);
3579     } ## end elsif ($package eq 'DB::fake')
3580
3581 =pod
3582
3583 If the program hasn't finished executing, we scan forward to the
3584 next executable line, print that out, build the prompt from the file and line
3585 number information, and print that.
3586
3587 =cut
3588
3589     else {
3590
3591
3592         # Still somewhere in the midst of execution. Set up the
3593         #  debugger prompt.
3594         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3595                              # Perl 5 ones (sorry, we don't print Klingon
3596                              #module names)
3597
3598         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3599         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3600         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3601
3602         # Break up the prompt if it's really long.
3603         if ( length($self->prefix()) > 30 ) {
3604             $self->position($self->prefix . "$DB::line):\n$DB::line:\t" . $self->_curr_line . $self->after);
3605             $self->prefix("");
3606             $self->infix(":\t");
3607         }
3608         else {
3609             $self->infix("):\t");
3610             $self->position(
3611                 $self->prefix . $DB::line. $self->infix
3612                 . $self->_curr_line . $self->after
3613             );
3614         }
3615
3616         # Print current line info, indenting if necessary.
3617         $self->_my_print_lineinfo($DB::line, $self->position);
3618
3619         my $i;
3620         my $line_i = sub { return $DB::dbline[$i]; };
3621
3622         # Scan forward, stopping at either the end or the next
3623         # unbreakable line.
3624         for ( $i = $DB::line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3625         {    #{ vi
3626
3627             # Drop out on null statements, block closers, and comments.
3628             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3629
3630             # Drop out if the user interrupted us.
3631             last if $signal;
3632
3633             # Append a newline if the line doesn't have one. Can happen
3634             # in eval'ed text, for instance.
3635             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3636
3637             # Next executable line.
3638             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3639                 . $self->after;
3640             $self->append_to_position($incr_pos);
3641             $self->_my_print_lineinfo($i, $incr_pos);
3642         } ## end for ($i = $line + 1 ; $i...
3643     } ## end else [ if ($slave_editor)
3644
3645     return;
3646 }
3647
3648 sub _handle_t_command {
3649     if (my ($levels) = $DB::cmd =~ /\At(?:\s+(\d+))?\z/) {
3650         $trace ^= 1;
3651         local $\ = '';
3652         $DB::trace_to_depth = $levels ? $DB::stack_depth + $levels : 1E9;
3653         print {$DB::OUT} "Trace = "
3654         . ( ( $trace & 1 )
3655             ? ( $levels ? "on (to level $DB::trace_to_depth)" : "on" )
3656             : "off" ) . "\n";
3657         next CMD;
3658     }
3659
3660     return;
3661 }
3662
3663 package DB;
3664
3665 # The following code may be executed now:
3666 # BEGIN {warn 4}
3667
3668 =head2 sub
3669
3670 C<sub> is called whenever a subroutine call happens in the program being
3671 debugged. The variable C<$DB::sub> contains the name of the subroutine
3672 being called.
3673
3674 The core function of this subroutine is to actually call the sub in the proper
3675 context, capturing its output. This of course causes C<DB::DB> to get called
3676 again, repeating until the subroutine ends and returns control to C<DB::sub>
3677 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3678 return value, and returns its captured copy of the return value as its own
3679 return value. The value then feeds back into the program being debugged as if
3680 C<DB::sub> hadn't been there at all.
3681
3682 C<sub> does all the work of printing the subroutine entry and exit messages
3683 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3684 and also prints the return value if needed (for the C<r> command and if
3685 the 16 bit is set in C<$frame>).
3686
3687 It also tracks the subroutine call depth by saving the current setting of
3688 C<$single> in the C<@stack> package global; if this exceeds the value in
3689 C<$deep>, C<sub> automatically turns on printing of the current depth by
3690 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3691 of stop/don't stop on entry to subs set as it currently is set.
3692
3693 =head3 C<caller()> support
3694
3695 If C<caller()> is called from the package C<DB>, it provides some
3696 additional data, in the following order:
3697
3698 =over 4
3699
3700 =item * C<$package>
3701
3702 The package name the sub was in
3703
3704 =item * C<$filename>
3705
3706 The filename it was defined in
3707
3708 =item * C<$line>
3709
3710 The line number it was defined on
3711
3712 =item * C<$subroutine>
3713
3714 The subroutine name; C<(eval)> if an C<eval>().
3715
3716 =item * C<$hasargs>
3717
3718 1 if it has arguments, 0 if not
3719
3720 =item * C<$wantarray>
3721
3722 1 if array context, 0 if scalar context
3723
3724 =item * C<$evaltext>
3725
3726 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3727
3728 =item * C<$is_require>
3729
3730 frame was created by a C<use> or C<require> statement
3731
3732 =item * C<$hints>
3733
3734 pragma information; subject to change between versions
3735
3736 =item * C<$bitmask>
3737
3738 pragma information; subject to change between versions
3739
3740 =item * C<@DB::args>
3741
3742 arguments with which the subroutine was invoked
3743
3744 =back
3745
3746 =cut
3747
3748 use vars qw($deep);
3749
3750 # We need to fully qualify the name ("DB::sub") to make "use strict;"
3751 # happy. -- Shlomi Fish
3752 sub DB::sub {
3753     # Do not use a regex in this subroutine -> results in corrupted memory
3754     # See: [perl #66110]
3755
3756     # lock ourselves under threads
3757     lock($DBGR);
3758
3759     # Whether or not the autoloader was running, a scalar to put the
3760     # sub's return value in (if needed), and an array to put the sub's
3761     # return value in (if needed).
3762     my ( $al, $ret, @ret ) = "";
3763     if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3764         print "creating new thread\n";
3765     }
3766
3767     # If the last ten characters are '::AUTOLOAD', note we've traced
3768     # into AUTOLOAD for $sub.
3769     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3770         no strict 'refs';
3771         $al = " for $$sub" if defined $$sub;
3772     }
3773
3774     # We stack the stack pointer and then increment it to protect us
3775     # from a situation that might unwind a whole bunch of call frames
3776     # at once. Localizing the stack pointer means that it will automatically
3777     # unwind the same amount when multiple stack frames are unwound.
3778     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3779
3780     # Expand @stack.
3781     $#stack = $stack_depth;
3782
3783     # Save current single-step setting.
3784     $stack[-1] = $single;
3785
3786     # Turn off all flags except single-stepping.
3787     $single &= 1;
3788
3789     # If we've gotten really deeply recursed, turn on the flag that will
3790     # make us stop with the 'deep recursion' message.
3791     $single |= 4 if $stack_depth == $deep;
3792
3793     # If frame messages are on ...
3794     (
3795         $frame & 4    # Extended frame entry message
3796         ? (
3797             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3798
3799             # Why -1? But it works! :-(
3800             # Because print_trace will call add 1 to it and then call
3801             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3802             # in dump_trace.
3803             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3804           )
3805         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3806
3807           # standard frame entry message
3808       )
3809       if $frame;
3810
3811     # Determine the sub's return type, and capture appropriately.
3812     if (wantarray) {
3813
3814         # Called in array context. call sub and capture output.
3815         # DB::DB will recursively get control again if appropriate; we'll come
3816         # back here when the sub is finished.
3817         {
3818             no strict 'refs';
3819             @ret = &$sub;
3820         }
3821
3822         # Pop the single-step value back off the stack.
3823         $single |= $stack[ $stack_depth-- ];
3824
3825         # Check for exit trace messages...
3826         (
3827             $frame & 4    # Extended exit message
3828             ? (
3829                 print_lineinfo( ' ' x $stack_depth, "out " ),
3830                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3831               )
3832             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3833
3834               # Standard exit message
3835           )
3836           if $frame & 2;
3837
3838         # Print the return info if we need to.
3839         if ( $doret eq $stack_depth or $frame & 16 ) {
3840
3841             # Turn off output record separator.
3842             local $\ = '';
3843             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3844
3845             # Indent if we're printing because of $frame tracing.
3846             print $fh ' ' x $stack_depth if $frame & 16;
3847
3848             # Print the return value.
3849             print $fh "list context return from $sub:\n";
3850             dumpit( $fh, \@ret );
3851
3852             # And don't print it again.
3853             $doret = -2;
3854         } ## end if ($doret eq $stack_depth...
3855             # And we have to return the return value now.
3856         @ret;
3857     } ## end if (wantarray)
3858
3859     # Scalar context.
3860     else {
3861         if ( defined wantarray ) {
3862             no strict 'refs';
3863             # Save the value if it's wanted at all.
3864             $ret = &$sub;
3865         }
3866         else {
3867             no strict 'refs';
3868             # Void return, explicitly.
3869             &$sub;
3870             undef $ret;
3871         }
3872
3873         # Pop the single-step value off the stack.
3874         $single |= $stack[ $stack_depth-- ];
3875
3876         # If we're doing exit messages...
3877         (
3878             $frame & 4    # Extended messages
3879             ? (
3880                 print_lineinfo( ' ' x $stack_depth, "out " ),
3881                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3882               )
3883             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3884
3885               # Standard messages
3886           )
3887           if $frame & 2;
3888
3889         # If we are supposed to show the return value... same as before.
3890         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3891             local $\ = '';
3892             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3893             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3894             print $fh (
3895                 defined wantarray
3896                 ? "scalar context return from $sub: "
3897                 : "void context return from $sub\n"
3898             );
3899             dumpit( $fh, $ret ) if defined wantarray;
3900             $doret = -2;
3901         } ## end if ($doret eq $stack_depth...
3902
3903         # Return the appropriate scalar value.
3904         $ret;
3905     } ## end else [ if (wantarray)
3906 } ## end sub _sub
3907
3908 sub lsub : lvalue {
3909
3910     no strict 'refs';
3911
3912     # lock ourselves under threads
3913     lock($DBGR);
3914
3915     # Whether or not the autoloader was running, a scalar to put the
3916     # sub's return value in (if needed), and an array to put the sub's
3917     # return value in (if needed).
3918     my ( $al, $ret, @ret ) = "";
3919     if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3920         print "creating new thread\n";
3921     }
3922
3923     # If the last ten characters are C'::AUTOLOAD', note we've traced
3924     # into AUTOLOAD for $sub.
3925     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3926         $al = " for $$sub";
3927     }
3928
3929     # We stack the stack pointer and then increment it to protect us
3930     # from a situation that might unwind a whole bunch of call frames
3931     # at once. Localizing the stack pointer means that it will automatically
3932     # unwind the same amount when multiple stack frames are unwound.
3933     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3934
3935     # Expand @stack.
3936     $#stack = $stack_depth;
3937
3938     # Save current single-step setting.
3939     $stack[-1] = $single;
3940
3941     # Turn off all flags except single-stepping.
3942     $single &= 1;
3943
3944     # If we've gotten really deeply recursed, turn on the flag that will
3945     # make us stop with the 'deep recursion' message.
3946     $single |= 4 if $stack_depth == $deep;
3947
3948     # If frame messages are on ...
3949     (
3950         $frame & 4    # Extended frame entry message
3951         ? (
3952             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3953
3954             # Why -1? But it works! :-(
3955             # Because print_trace will call add 1 to it and then call
3956             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3957             # in dump_trace.
3958             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3959           )
3960         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3961
3962           # standard frame entry message
3963       )
3964       if $frame;
3965
3966     # Pop the single-step value back off the stack.
3967     $single |= $stack[ $stack_depth-- ];
3968
3969     # call the original lvalue sub.
3970     &$sub;
3971 }
3972
3973 # Abstracting common code from multiple places elsewhere:
3974 sub depth_print_lineinfo {
3975     my $always_print = shift;
3976
3977     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
3978 }
3979
3980 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3981
3982 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3983 Most of the changes were to systematize the command structure and to eliminate
3984 commands that threw away user input without checking.
3985
3986 The following sections describe the code added to make it easy to support
3987 multiple command sets with conflicting command names. This section is a start
3988 at unifying all command processing to make it simpler to develop commands.
3989
3990 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3991 number, and C<$dbline> (the current line) as arguments.
3992
3993 Support functions in this section which have multiple modes of failure C<die>
3994 on error; the rest simply return a false value.
3995
3996 The user-interface functions (all of the C<cmd_*> functions) just output
3997 error messages.
3998
3999 =head2 C<%set>
4000
4001 The C<%set> hash defines the mapping from command letter to subroutine
4002 name suffix.
4003
4004 C<%set> is a two-level hash, indexed by set name and then by command name.
4005 Note that trying to set the CommandSet to C<foobar> simply results in the
4006 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
4007
4008 =cut
4009
4010 ### The API section
4011
4012 my %set = (    #
4013     'pre580' => {
4014         'a' => 'pre580_a',
4015         'A' => 'pre580_null',
4016         'b' => 'pre580_b',
4017         'B' => 'pre580_null',
4018         'd' => 'pre580_null',
4019         'D' => 'pre580_D',
4020         'h' => 'pre580_h',
4021         'M' => 'pre580_null',
4022         'O' => 'o',
4023         'o' => 'pre580_null',
4024         'v' => 'M',
4025         'w' => 'v',
4026         'W' => 'pre580_W',
4027     },
4028     'pre590' => {
4029         '<'  => 'pre590_prepost',
4030         '<<' => 'pre590_prepost',
4031         '>'  => 'pre590_prepost',
4032         '>>' => 'pre590_prepost',
4033         '{'  => 'pre590_prepost',
4034         '{{' => 'pre590_prepost',
4035     },
4036 );
4037
4038 my %breakpoints_data;
4039
4040 sub _has_breakpoint_data_ref {
4041     my ($filename, $line) = @_;
4042
4043     return (
4044         exists( $breakpoints_data{$filename} )
4045             and
4046         exists( $breakpoints_data{$filename}{$line} )
4047     );
4048 }
4049
4050 sub _get_breakpoint_data_ref {
4051     my ($filename, $line) = @_;
4052
4053     return ($breakpoints_data{$filename}{$line} ||= +{});
4054 }
4055
4056 sub _delete_breakpoint_data_ref {
4057     my ($filename, $line) = @_;
4058
4059     delete($breakpoints_data{$filename}{$line});
4060     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4061         delete($breakpoints_data{$filename});
4062     }
4063
4064     return;
4065 }
4066
4067 sub _set_breakpoint_enabled_status {
4068     my ($filename, $line, $status) = @_;
4069
4070     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4071         ($status ? 1 : '')
4072         ;
4073
4074     return;
4075 }
4076
4077 sub _enable_breakpoint_temp_enabled_status {
4078     my ($filename, $line) = @_;
4079
4080     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4081
4082     return;
4083 }
4084
4085 sub _cancel_breakpoint_temp_enabled_status {
4086     my ($filename, $line) = @_;
4087
4088     my $ref = _get_breakpoint_data_ref($filename, $line);
4089
4090     delete ($ref->{'temp_enabled'});
4091
4092     if (! %$ref) {
4093         _delete_breakpoint_data_ref($filename, $line);
4094     }
4095
4096     return;
4097 }
4098
4099 sub _is_breakpoint_enabled {
4100     my ($filename, $line) = @_;
4101
4102     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4103     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4104 }
4105
4106 =head2 C<cmd_wrapper()> (API)
4107
4108 C<cmd_wrapper()> allows the debugger to switch command sets
4109 depending on the value of the C<CommandSet> option.
4110
4111 It tries to look up the command in the C<%set> package-level I<lexical>
4112 (which means external entities can't fiddle with it) and create the name of
4113 the sub to call based on the value found in the hash (if it's there). I<All>
4114 of the commands to be handled in a set have to be added to C<%set>; if they
4115 aren't found, the 5.8.0 equivalent is called (if there is one).
4116
4117 This code uses symbolic references.
4118
4119 =cut
4120
4121 sub cmd_wrapper {
4122     my $cmd      = shift;
4123     my $line     = shift;
4124     my $dblineno = shift;
4125
4126     # Assemble the command subroutine's name by looking up the
4127     # command set and command name in %set. If we can't find it,
4128     # default to the older version of the command.
4129     my $call = 'cmd_'
4130       . ( $set{$CommandSet}{$cmd}
4131           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
4132
4133     # Call the command subroutine, call it by name.
4134     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4135 } ## end sub cmd_wrapper
4136
4137 =head3 C<cmd_a> (command)
4138
4139 The C<a> command handles pre-execution actions. These are associated with a
4140 particular line, so they're stored in C<%dbline>. We default to the current
4141 line if none is specified.
4142
4143 =cut
4144
4145 sub cmd_a {
4146     my $cmd    = shift;
4147     my $line   = shift || '';    # [.|line] expr
4148     my $dbline = shift;
4149
4150     # If it's dot (here), or not all digits,  use the current line.
4151     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
4152
4153     # Should be a line number followed by an expression.
4154     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4155         my ( $lineno, $expr ) = ( $1, $2 );
4156
4157         # If we have an expression ...
4158         if ( length $expr ) {
4159
4160             # ... but the line isn't breakable, complain.
4161             if ( $dbline[$lineno] == 0 ) {
4162                 print $OUT
4163                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4164             }
4165             else {
4166
4167                 # It's executable. Record that the line has an action.
4168                 $had_breakpoints{$filename} |= 2;
4169
4170                 # Remove any action, temp breakpoint, etc.
4171                 $dbline{$lineno} =~ s/\0[^\0]*//;
4172
4173                 # Add the action to the line.
4174                 $dbline{$lineno} .= "\0" . action($expr);
4175
4176                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4177             }
4178         } ## end if (length $expr)
4179     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4180     else {
4181
4182         # Syntax wrong.
4183         print $OUT
4184           "Adding an action requires an optional lineno and an expression\n"
4185           ;    # hint
4186     }
4187 } ## end sub cmd_a
4188
4189 =head3 C<cmd_A> (command)
4190
4191 Delete actions. Similar to above, except the delete code is in a separate
4192 subroutine, C<delete_action>.
4193
4194 =cut
4195
4196 sub cmd_A {
4197     my $cmd    = shift;
4198     my $line   = shift || '';
4199     my $dbline = shift;
4200
4201     # Dot is this line.
4202     $line =~ s/^\./$dbline/;
4203
4204     # Call delete_action with a null param to delete them all.
4205     # The '1' forces the eval to be true. It'll be false only
4206     # if delete_action blows up for some reason, in which case
4207     # we print $@ and get out.
4208     if ( $line eq '*' ) {
4209         if (! eval { _delete_all_actions(); 1 }) {
4210             print {$OUT} $@;
4211             return;
4212         }
4213     }
4214
4215     # There's a real line  number. Pass it to delete_action.
4216     # Error trapping is as above.
4217     elsif ( $line =~ /^(\S.*)/ ) {
4218         if (! eval { delete_action($1); 1 }) {
4219             print {$OUT} $@;
4220             return;
4221         }
4222     }
4223
4224     # Swing and a miss. Bad syntax.
4225     else {
4226         print $OUT
4227           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4228     }
4229 } ## end sub cmd_A
4230
4231 =head3 C<delete_action> (API)
4232
4233 C<delete_action> accepts either a line number or C<undef>. If a line number
4234 is specified, we check for the line being executable (if it's not, it
4235 couldn't have had an  action). If it is, we just take the action off (this
4236 will get any kind of an action, including breakpoints).
4237
4238 =cut
4239
4240 sub _remove_action_from_dbline {
4241     my $i = shift;
4242
4243     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4244     delete $dbline{$i} if $dbline{$i} eq '';
4245
4246     return;
4247 }
4248
4249 sub _delete_all_actions {
4250     print {$OUT} "Deleting all actions...\n";
4251
4252     for my $file ( keys %had_breakpoints ) {
4253         local *dbline = $main::{ '_<' . $file };
4254         $max = $#dbline;
4255         my $was;
4256         for my $i (1 .. $max) {
4257             if ( defined $dbline{$i} ) {
4258                 _remove_action_from_dbline($i);
4259             }
4260         }
4261
4262         unless ( $had_breakpoints{$file} &= ~2 ) {
4263             delete $had_breakpoints{$file};
4264         }
4265     }
4266
4267     return;
4268 }
4269
4270 sub delete_action {
4271     my $i = shift;
4272
4273     if ( defined($i) ) {
4274         # Can there be one?
4275         die "Line $i has no action .\n" if $dbline[$i] == 0;
4276
4277         # Nuke whatever's there.
4278         _remove_action_from_dbline($i);
4279     }
4280     else {
4281         _delete_all_actions();
4282     }
4283 }
4284
4285 =head3 C<cmd_b> (command)
4286
4287 Set breakpoints. Since breakpoints can be set in so many places, in so many
4288 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4289 we try to parse the command type, and then shuttle it off to an appropriate
4290 subroutine to actually do the work of setting the breakpoint in the right
4291 place.
4292
4293 =cut
4294
4295 sub cmd_b {
4296     my $cmd    = shift;
4297     my $line   = shift;    # [.|line] [cond]
4298     my $dbline = shift;
4299
4300     my $default_cond = sub {
4301         my $cond = shift;
4302         return length($cond) ? $cond : '1';
4303     };
4304
4305     # Make . the current line number if it's there..
4306     $line =~ s/^\.(\s|\z)/$dbline$1/;
4307
4308     # No line number, no condition. Simple break on current line.
4309     if ( $line =~ /^\s*$/ ) {
4310         cmd_b_line( $dbline, 1 );
4311     }
4312
4313     # Break on load for a file.
4314     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4315         $file =~ s/\s+\z//;
4316         cmd_b_load($file);
4317     }
4318
4319     # b compile|postpone <some sub> [<condition>]
4320     # The interpreter actually traps this one for us; we just put the
4321     # necessary condition in the %postponed hash.
4322     elsif ( my ($action, $subname, $cond)
4323         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4324
4325         # De-Perl4-ify the name - ' separators to ::.
4326         $subname =~ s/'/::/g;
4327
4328         # Qualify it into the current package unless it's already qualified.
4329         $subname = "${package}::" . $subname unless $subname =~ /::/;
4330
4331         # Add main if it starts with ::.
4332         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4333
4334         # Save the break type for this sub.
4335         $postponed{$subname} = (($action eq 'postpone')
4336             ? ( "break +0 if " . $default_cond->($cond) )
4337             : "compile");
4338     } ## end elsif ($line =~ ...
4339     # b <filename>:<line> [<condition>]
4340     elsif (my ($filename, $line_num, $cond)
4341         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4342         cmd_b_filename_line(
4343             $filename,
4344             $line_num,
4345             (length($cond) ? $cond : '1'),
4346         );
4347     }
4348     # b <sub name> [<condition>]
4349     elsif ( my ($new_subname, $new_cond) =
4350         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4351
4352         #
4353         $subname = $new_subname;
4354         cmd_b_sub( $subname, $default_cond->($new_cond) );
4355     }
4356
4357     # b <line> [<condition>].
4358     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4359
4360         # Capture the line. If none, it's the current line.
4361         $line = $line_n || $dbline;
4362
4363         # Break on line.
4364         cmd_b_line( $line, $default_cond->($cond) );
4365     }
4366
4367     # Line didn't make sense.
4368     else {
4369         print "confused by line($line)?\n";
4370     }
4371
4372     return;
4373 } ## end sub cmd_b
4374
4375 =head3 C<break_on_load> (API)
4376
4377 We want to break when this file is loaded. Mark this file in the
4378 C<%break_on_load> hash, and note that it has a breakpoint in
4379 C<%had_breakpoints>.
4380
4381 =cut
4382
4383 sub break_on_load {
4384     my $file = shift;
4385     $break_on_load{$file} = 1;
4386     $had_breakpoints{$file} |= 1;
4387 }
4388
4389 =head3 C<report_break_on_load> (API)
4390
4391 Gives us an array of filenames that are set to break on load. Note that
4392 only files with break-on-load are in here, so simply showing the keys
4393 suffices.
4394
4395 =cut
4396
4397 sub report_break_on_load {
4398     sort keys %break_on_load;
4399 }
4400
4401 =head3 C<cmd_b_load> (command)
4402
4403 We take the file passed in and try to find it in C<%INC> (which maps modules
4404 to files they came from). We mark those files for break-on-load via
4405 C<break_on_load> and then report that it was done.
4406
4407 =cut
4408
4409 sub cmd_b_load {
4410     my $file = shift;
4411     my @files;
4412
4413     # This is a block because that way we can use a redo inside it
4414     # even without there being any looping structure at all outside it.
4415     {
4416
4417         # Save short name and full path if found.
4418         push @files, $file;
4419         push @files, $::INC{$file} if $::INC{$file};
4420
4421         # Tack on .pm and do it again unless there was a '.' in the name
4422         # already.
4423         $file .= '.pm', redo unless $file =~ /\./;
4424     }
4425
4426     # Do the real work here.
4427     break_on_load($_) for @files;
4428
4429     # All the files that have break-on-load breakpoints.
4430     @files = report_break_on_load;
4431
4432     # Normalize for the purposes of our printing this.
4433     local $\ = '';
4434     local $" = ' ';
4435     print $OUT "Will stop on load of '@files'.\n";
4436 } ## end sub cmd_b_load
4437
4438 =head3 C<$filename_error> (API package global)
4439
4440 Several of the functions we need to implement in the API need to work both
4441 on the current file and on other files. We don't want to duplicate code, so
4442 C<$filename_error> is used to contain the name of the file that's being
4443 worked on (if it's not the current one).
4444
4445 We can now build functions in pairs: the basic function works on the current
4446 file, and uses C<$filename_error> as part of its error message. Since this is
4447 initialized to C<"">, no filename will appear when we are working on the
4448 current file.
4449
4450 The second function is a wrapper which does the following:
4451
4452 =over 4
4453
4454 =item *
4455
4456 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4457
4458 =item *
4459
4460 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4461
4462 =item *
4463
4464 Calls the first function.
4465
4466 The first function works on the I<current> file (i.e., the one we changed to),
4467 and prints C<$filename_error> in the error message (the name of the other file)
4468 if it needs to. When the functions return, C<*dbline> is restored to point
4469 to the actual current file (the one we're executing in) and
4470 C<$filename_error> is restored to C<"">. This restores everything to
4471 the way it was before the second function was called at all.
4472
4473 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4474 details.
4475
4476 =back
4477
4478 =cut
4479
4480 use vars qw($filename_error);
4481 $filename_error = '';
4482
4483 =head3 breakable_line(from, to) (API)
4484
4485 The subroutine decides whether or not a line in the current file is breakable.
4486 It walks through C<@dbline> within the range of lines specified, looking for
4487 the first line that is breakable.
4488
4489 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4490 first line I<after> C<$to> that's breakable, if there is one.
4491
4492 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4493 first line I<before> C<$to> that's breakable, if there is one.
4494
4495 =cut
4496
4497 sub breakable_line {
4498
4499     my ( $from, $to ) = @_;
4500
4501     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4502     my $i = $from;
4503
4504     # If there are at least 2 arguments, we're trying to search a range.
4505     if ( @_ >= 2 ) {
4506
4507         # $delta is positive for a forward search, negative for a backward one.
4508         my $delta = $from < $to ? +1 : -1;
4509
4510         # Keep us from running off the ends of the file.
4511         my $limit = $delta > 0 ? $#dbline : 1;
4512
4513         # Clever test. If you're a mathematician, it's obvious why this
4514         # test works. If not:
4515         # If $delta is positive (going forward), $limit will be $#dbline.
4516         #    If $to is less than $limit, ($limit - $to) will be positive, times
4517         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4518         #    as the stopping point.
4519         #
4520         #    If $to is greater than $limit, ($limit - $to) is negative,
4521         #    times $delta of 1 (positive), so the result is < 0 and we should
4522         #    use $limit ($#dbline) as the stopping point.
4523         #
4524         # If $delta is negative (going backward), $limit will be 1.
4525         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4526         #    (negative) so the result is > 0, and we use $to as the stopping
4527         #    point.
4528         #
4529         #    If $to is less than zero, ($limit - $to) will be positive,
4530         #    times $delta of -1 (negative), so the result is not > 0, and
4531         #    we use $limit (1) as the stopping point.
4532         #
4533         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4534         #    (negative), still giving zero; the result is not > 0, and
4535         #    we use $limit (1) as the stopping point.
4536         #
4537         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4538         #    (negative), giving a positive (>0) value, so we'll set $limit to
4539         #    $to.
4540
4541         $limit = $to if ( $limit - $to ) * $delta > 0;
4542
4543         # The real search loop.
4544         # $i starts at $from (the point we want to start searching from).
4545         # We move through @dbline in the appropriate direction (determined
4546         # by $delta: either -1 (back) or +1 (ahead).
4547         # We stay in as long as we haven't hit an executable line
4548         # ($dbline[$i] == 0 means not executable) and we haven't reached
4549         # the limit yet (test similar to the above).
4550         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4551
4552     } ## end if (@_ >= 2)
4553
4554     # If $i points to a line that is executable, return that.
4555     return $i unless $dbline[$i] == 0;
4556
4557     # Format the message and print it: no breakable lines in range.
4558     my ( $pl, $upto ) = ( '', '' );
4559     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4560
4561     # If there's a filename in filename_error, we'll see it.
4562     # If not, not.
4563     die "Line$pl $from$upto$filename_error not breakable\n";
4564 } ## end sub breakable_line
4565
4566 =head3 breakable_line_in_filename(file, from, to) (API)
4567
4568 Like C<breakable_line>, but look in another file.
4569
4570 =cut
4571
4572 sub breakable_line_in_filename {
4573
4574     # Capture the file name.
4575     my ($f) = shift;
4576
4577     # Swap the magic line array over there temporarily.
4578     local *dbline = $main::{ '_<' . $f };
4579
4580     # If there's an error, it's in this other file.