This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
[DOCPATCH] perlfunc delete
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 A named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over 4
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
140 C<umask>, C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<our>, C<prototype>,
204 C<qx>, C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
228 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<socket>, C<socketpair>,
238 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
239 C<times>, C<truncate>, C<umask>, C<unlink>,
240 C<utime>, C<wait>, C<waitpid>
241
242 For more information about the portability of these functions, see
243 L<perlport> and other available platform-specific documentation.
244
245 =head2 Alphabetical Listing of Perl Functions
246
247 =over 8
248
249 =item -X FILEHANDLE
250
251 =item -X EXPR
252
253 =item -X
254
255 A file test, where X is one of the letters listed below.  This unary
256 operator takes one argument, either a filename or a filehandle, and
257 tests the associated file to see if something is true about it.  If the
258 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
259 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
260 the undefined value if the file doesn't exist.  Despite the funny
261 names, precedence is the same as any other named unary operator, and
262 the argument may be parenthesized like any other unary operator.  The
263 operator may be any of:
264 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
265 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
266
267     -r  File is readable by effective uid/gid.
268     -w  File is writable by effective uid/gid.
269     -x  File is executable by effective uid/gid.
270     -o  File is owned by effective uid.
271
272     -R  File is readable by real uid/gid.
273     -W  File is writable by real uid/gid.
274     -X  File is executable by real uid/gid.
275     -O  File is owned by real uid.
276
277     -e  File exists.
278     -z  File has zero size (is empty).
279     -s  File has nonzero size (returns size in bytes).
280
281     -f  File is a plain file.
282     -d  File is a directory.
283     -l  File is a symbolic link.
284     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
285     -S  File is a socket.
286     -b  File is a block special file.
287     -c  File is a character special file.
288     -t  Filehandle is opened to a tty.
289
290     -u  File has setuid bit set.
291     -g  File has setgid bit set.
292     -k  File has sticky bit set.
293
294     -T  File is an ASCII text file (heuristic guess).
295     -B  File is a "binary" file (opposite of -T).
296
297     -M  Script start time minus file modification time, in days.
298     -A  Same for access time.
299     -C  Same for inode change time (Unix, may differ for other platforms)
300
301 Example:
302
303     while (<>) {
304         chomp;
305         next unless -f $_;      # ignore specials
306         #...
307     }
308
309 The interpretation of the file permission operators C<-r>, C<-R>,
310 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
311 of the file and the uids and gids of the user.  There may be other
312 reasons you can't actually read, write, or execute the file.  Such
313 reasons may be for example network filesystem access controls, ACLs
314 (access control lists), read-only filesystems, and unrecognized
315 executable formats.
316
317 Also note that, for the superuser on the local filesystems, the C<-r>,
318 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
319 if any execute bit is set in the mode.  Scripts run by the superuser
320 may thus need to do a stat() to determine the actual mode of the file,
321 or temporarily set their effective uid to something else.
322
323 If you are using ACLs, there is a pragma called C<filetest> that may
324 produce more accurate results than the bare stat() mode bits.
325 When under the C<use filetest 'access'> the above-mentioned filetests
326 will test whether the permission can (not) be granted using the
327 access() family of system calls.  Also note that the C<-x> and C<-X> may
328 under this pragma return true even if there are no execute permission
329 bits set (nor any extra execute permission ACLs).  This strangeness is
330 due to the underlying system calls' definitions.  Read the
331 documentation for the C<filetest> pragma for more information.
332
333 Note that C<-s/a/b/> does not do a negated substitution.  Saying
334 C<-exp($foo)> still works as expected, however--only single letters
335 following a minus are interpreted as file tests.
336
337 The C<-T> and C<-B> switches work as follows.  The first block or so of the
338 file is examined for odd characters such as strange control codes or
339 characters with the high bit set.  If too many strange characters (>30%)
340 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
341 containing null in the first block is considered a binary file.  If C<-T>
342 or C<-B> is used on a filehandle, the current IO buffer is examined
343 rather than the first block.  Both C<-T> and C<-B> return true on a null
344 file, or a file at EOF when testing a filehandle.  Because you have to
345 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
346 against the file first, as in C<next unless -f $file && -T $file>.
347
348 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
349 the special filehandle consisting of a solitary underline, then the stat
350 structure of the previous file test (or stat operator) is used, saving
351 a system call.  (This doesn't work with C<-t>, and you need to remember
352 that lstat() and C<-l> will leave values in the stat structure for the
353 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
354 a C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
355 Example:
356
357     print "Can do.\n" if -r $a || -w _ || -x _;
358
359     stat($filename);
360     print "Readable\n" if -r _;
361     print "Writable\n" if -w _;
362     print "Executable\n" if -x _;
363     print "Setuid\n" if -u _;
364     print "Setgid\n" if -g _;
365     print "Sticky\n" if -k _;
366     print "Text\n" if -T _;
367     print "Binary\n" if -B _;
368
369 =item abs VALUE
370
371 =item abs
372
373 Returns the absolute value of its argument.
374 If VALUE is omitted, uses C<$_>.
375
376 =item accept NEWSOCKET,GENERICSOCKET
377
378 Accepts an incoming socket connect, just as the accept(2) system call
379 does.  Returns the packed address if it succeeded, false otherwise.
380 See the example in L<perlipc/"Sockets: Client/Server Communication">.
381
382 On systems that support a close-on-exec flag on files, the flag will
383 be set for the newly opened file descriptor, as determined by the
384 value of $^F.  See L<perlvar/$^F>.
385
386 =item alarm SECONDS
387
388 =item alarm
389
390 Arranges to have a SIGALRM delivered to this process after the
391 specified number of wallclock seconds have elapsed.  If SECONDS is not
392 specified, the value stored in C<$_> is used. (On some machines,
393 unfortunately, the elapsed time may be up to one second less or more
394 than you specified because of how seconds are counted, and process
395 scheduling may delay the delivery of the signal even further.)
396
397 Only one timer may be counting at once.  Each call disables the
398 previous timer, and an argument of C<0> may be supplied to cancel the
399 previous timer without starting a new one.  The returned value is the
400 amount of time remaining on the previous timer.
401
402 For delays of finer granularity than one second, you may use Perl's
403 four-argument version of select() leaving the first three arguments
404 undefined, or you might be able to use the C<syscall> interface to
405 access setitimer(2) if your system supports it.  The Time::HiRes
406 module (from CPAN, and starting from Perl 5.8 part of the standard
407 distribution) may also prove useful.
408
409 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
410 (C<sleep> may be internally implemented in your system with C<alarm>)
411
412 If you want to use C<alarm> to time out a system call you need to use an
413 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
414 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
415 restart system calls on some systems.  Using C<eval>/C<die> always works,
416 modulo the caveats given in L<perlipc/"Signals">.
417
418     eval {
419         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
420         alarm $timeout;
421         $nread = sysread SOCKET, $buffer, $size;
422         alarm 0;
423     };
424     if ($@) {
425         die unless $@ eq "alarm\n";   # propagate unexpected errors
426         # timed out
427     }
428     else {
429         # didn't
430     }
431
432 For more information see L<perlipc>.
433
434 =item atan2 Y,X
435
436 Returns the arctangent of Y/X in the range -PI to PI.
437
438 For the tangent operation, you may use the C<Math::Trig::tan>
439 function, or use the familiar relation:
440
441     sub tan { sin($_[0]) / cos($_[0])  }
442
443 =item bind SOCKET,NAME
444
445 Binds a network address to a socket, just as the bind system call
446 does.  Returns true if it succeeded, false otherwise.  NAME should be a
447 packed address of the appropriate type for the socket.  See the examples in
448 L<perlipc/"Sockets: Client/Server Communication">.
449
450 =item binmode FILEHANDLE, LAYER
451
452 =item binmode FILEHANDLE
453
454 Arranges for FILEHANDLE to be read or written in "binary" or "text"
455 mode on systems where the run-time libraries distinguish between
456 binary and text files.  If FILEHANDLE is an expression, the value is
457 taken as the name of the filehandle.  Returns true on success,
458 otherwise it returns C<undef> and sets C<$!> (errno).
459
460 On some systems (in general, DOS and Windows-based systems) binmode()
461 is necessary when you're not working with a text file.  For the sake
462 of portability it is a good idea to always use it when appropriate,
463 and to never use it when it isn't appropriate.  Also, people can
464 set their I/O to be by default UTF-8 encoded Unicode, not bytes.
465
466 In other words: regardless of platform, use binmode() on binary data,
467 like for example images.
468
469 If LAYER is present it is a single string, but may contain multiple
470 directives. The directives alter the behaviour of the file handle.
471 When LAYER is present using binmode on text file makes sense.
472
473 If LAYER is omitted or specified as C<:raw> the filehandle is made
474 suitable for passing binary data. This includes turning off possible CRLF
475 translation and marking it as bytes (as opposed to Unicode characters).
476 Note that, despite what may be implied in I<"Programming Perl"> (the
477 Camel) or elsewhere, C<:raw> is I<not> the simply inverse of C<:crlf>
478 -- other layers which would affect binary nature of the stream are
479 I<also> disabled. See L<PerlIO>, L<perlrun> and the discussion about the
480 PERLIO environment variable.
481
482 The C<:bytes>, C<:crlf>, and C<:utf8>, and any other directives of the
483 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
484 establish default I/O layers.  See L<open>.
485
486 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
487 in "Programming Perl, 3rd Edition".  However, since the publishing of this
488 book, by many known as "Camel III", the consensus of the naming of this
489 functionality has moved from "discipline" to "layer".  All documentation
490 of this version of Perl therefore refers to "layers" rather than to
491 "disciplines".  Now back to the regularly scheduled documentation...>
492
493 To mark FILEHANDLE as UTF-8, use C<:utf8>.
494
495 In general, binmode() should be called after open() but before any I/O
496 is done on the filehandle.  Calling binmode() will normally flush any
497 pending buffered output data (and perhaps pending input data) on the
498 handle.  An exception to this is the C<:encoding> layer that
499 changes the default character encoding of the handle, see L<open>.
500 The C<:encoding> layer sometimes needs to be called in
501 mid-stream, and it doesn't flush the stream.  The C<:encoding>
502 also implicitly pushes on top of itself the C<:utf8> layer because
503 internally Perl will operate on UTF-8 encoded Unicode characters.
504
505 The operating system, device drivers, C libraries, and Perl run-time
506 system all work together to let the programmer treat a single
507 character (C<\n>) as the line terminator, irrespective of the external
508 representation.  On many operating systems, the native text file
509 representation matches the internal representation, but on some
510 platforms the external representation of C<\n> is made up of more than
511 one character.
512
513 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
514 character to end each line in the external representation of text (even
515 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
516 on Unix and most VMS files). In other systems like OS/2, DOS and the
517 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
518 but what's stored in text files are the two characters C<\cM\cJ>.  That
519 means that, if you don't use binmode() on these systems, C<\cM\cJ>
520 sequences on disk will be converted to C<\n> on input, and any C<\n> in
521 your program will be converted back to C<\cM\cJ> on output.  This is what
522 you want for text files, but it can be disastrous for binary files.
523
524 Another consequence of using binmode() (on some systems) is that
525 special end-of-file markers will be seen as part of the data stream.
526 For systems from the Microsoft family this means that if your binary
527 data contains C<\cZ>, the I/O subsystem will regard it as the end of
528 the file, unless you use binmode().
529
530 binmode() is not only important for readline() and print() operations,
531 but also when using read(), seek(), sysread(), syswrite() and tell()
532 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
533 in L<perlvar> for how to manually set your input and output
534 line-termination sequences.
535
536 =item bless REF,CLASSNAME
537
538 =item bless REF
539
540 This function tells the thingy referenced by REF that it is now an object
541 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
542 is used.  Because a C<bless> is often the last thing in a constructor,
543 it returns the reference for convenience.  Always use the two-argument
544 version if the function doing the blessing might be inherited by a
545 derived class.  See L<perltoot> and L<perlobj> for more about the blessing
546 (and blessings) of objects.
547
548 Consider always blessing objects in CLASSNAMEs that are mixed case.
549 Namespaces with all lowercase names are considered reserved for
550 Perl pragmata.  Builtin types have all uppercase names, so to prevent
551 confusion, you may wish to avoid such package names as well.  Make sure
552 that CLASSNAME is a true value.
553
554 See L<perlmod/"Perl Modules">.
555
556 =item caller EXPR
557
558 =item caller
559
560 Returns the context of the current subroutine call.  In scalar context,
561 returns the caller's package name if there is a caller, that is, if
562 we're in a subroutine or C<eval> or C<require>, and the undefined value
563 otherwise.  In list context, returns
564
565     ($package, $filename, $line) = caller;
566
567 With EXPR, it returns some extra information that the debugger uses to
568 print a stack trace.  The value of EXPR indicates how many call frames
569 to go back before the current one.
570
571     ($package, $filename, $line, $subroutine, $hasargs,
572     $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);
573
574 Here $subroutine may be C<(eval)> if the frame is not a subroutine
575 call, but an C<eval>.  In such a case additional elements $evaltext and
576 C<$is_require> are set: C<$is_require> is true if the frame is created by a
577 C<require> or C<use> statement, $evaltext contains the text of the
578 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
579 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
580 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
581 frame.)  $subroutine may also be C<(unknown)> if this particular
582 subroutine happens to have been deleted from the symbol table.
583 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
584 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
585 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
586 between versions of Perl, and are not meant for external use.
587
588 Furthermore, when called from within the DB package, caller returns more
589 detailed information: it sets the list variable C<@DB::args> to be the
590 arguments with which the subroutine was invoked.
591
592 Be aware that the optimizer might have optimized call frames away before
593 C<caller> had a chance to get the information.  That means that C<caller(N)>
594 might not return information about the call frame you expect it do, for
595 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
596 previous time C<caller> was called.
597
598 =item chdir EXPR
599
600 Changes the working directory to EXPR, if possible. If EXPR is omitted,
601 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
602 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
603 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
604 neither is set, C<chdir> does nothing. It returns true upon success,
605 false otherwise. See the example under C<die>.
606
607 =item chmod LIST
608
609 Changes the permissions of a list of files.  The first element of the
610 list must be the numerical mode, which should probably be an octal
611 number, and which definitely should I<not> a string of octal digits:
612 C<0644> is okay, C<'0644'> is not.  Returns the number of files
613 successfully changed.  See also L</oct>, if all you have is a string.
614
615     $cnt = chmod 0755, 'foo', 'bar';
616     chmod 0755, @executables;
617     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
618                                              # --w----r-T
619     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
620     $mode = 0644;   chmod $mode, 'foo';      # this is best
621
622 You can also import the symbolic C<S_I*> constants from the Fcntl
623 module:
624
625     use Fcntl ':mode';
626
627     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
628     # This is identical to the chmod 0755 of the above example.
629
630 =item chomp VARIABLE
631
632 =item chomp( LIST )
633
634 =item chomp
635
636 This safer version of L</chop> removes any trailing string
637 that corresponds to the current value of C<$/> (also known as
638 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
639 number of characters removed from all its arguments.  It's often used to
640 remove the newline from the end of an input record when you're worried
641 that the final record may be missing its newline.  When in paragraph
642 mode (C<$/ = "">), it removes all trailing newlines from the string.
643 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
644 a reference to an integer or the like, see L<perlvar>) chomp() won't
645 remove anything.
646 If VARIABLE is omitted, it chomps C<$_>.  Example:
647
648     while (<>) {
649         chomp;  # avoid \n on last field
650         @array = split(/:/);
651         # ...
652     }
653
654 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
655
656 You can actually chomp anything that's an lvalue, including an assignment:
657
658     chomp($cwd = `pwd`);
659     chomp($answer = <STDIN>);
660
661 If you chomp a list, each element is chomped, and the total number of
662 characters removed is returned.
663
664 Note that parentheses are necessary when you're chomping anything
665 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
666 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
667 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
668 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
669 as C<chomp($a, $b)>.
670
671 =item chop VARIABLE
672
673 =item chop( LIST )
674
675 =item chop
676
677 Chops off the last character of a string and returns the character
678 chopped.  It is much more efficient than C<s/.$//s> because it neither
679 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
680 If VARIABLE is a hash, it chops the hash's values, but not its keys.
681
682 You can actually chop anything that's an lvalue, including an assignment.
683
684 If you chop a list, each element is chopped.  Only the value of the
685 last C<chop> is returned.
686
687 Note that C<chop> returns the last character.  To return all but the last
688 character, use C<substr($string, 0, -1)>.
689
690 See also L</chomp>.
691
692 =item chown LIST
693
694 Changes the owner (and group) of a list of files.  The first two
695 elements of the list must be the I<numeric> uid and gid, in that
696 order.  A value of -1 in either position is interpreted by most
697 systems to leave that value unchanged.  Returns the number of files
698 successfully changed.
699
700     $cnt = chown $uid, $gid, 'foo', 'bar';
701     chown $uid, $gid, @filenames;
702
703 Here's an example that looks up nonnumeric uids in the passwd file:
704
705     print "User: ";
706     chomp($user = <STDIN>);
707     print "Files: ";
708     chomp($pattern = <STDIN>);
709
710     ($login,$pass,$uid,$gid) = getpwnam($user)
711         or die "$user not in passwd file";
712
713     @ary = glob($pattern);      # expand filenames
714     chown $uid, $gid, @ary;
715
716 On most systems, you are not allowed to change the ownership of the
717 file unless you're the superuser, although you should be able to change
718 the group to any of your secondary groups.  On insecure systems, these
719 restrictions may be relaxed, but this is not a portable assumption.
720 On POSIX systems, you can detect this condition this way:
721
722     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
723     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
724
725 =item chr NUMBER
726
727 =item chr
728
729 Returns the character represented by that NUMBER in the character set.
730 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
731 chr(0x263a) is a Unicode smiley face.  Note that characters from 128
732 to 255 (inclusive) are by default not encoded in UTF-8 Unicode for
733 backward compatibility reasons (but see L<encoding>).
734
735 If NUMBER is omitted, uses C<$_>.
736
737 For the reverse, use L</ord>.
738
739 Note that under the C<bytes> pragma the NUMBER is masked to
740 the low eight bits.
741
742 See L<perlunicode> and L<encoding> for more about Unicode.
743
744 =item chroot FILENAME
745
746 =item chroot
747
748 This function works like the system call by the same name: it makes the
749 named directory the new root directory for all further pathnames that
750 begin with a C</> by your process and all its children.  (It doesn't
751 change your current working directory, which is unaffected.)  For security
752 reasons, this call is restricted to the superuser.  If FILENAME is
753 omitted, does a C<chroot> to C<$_>.
754
755 =item close FILEHANDLE
756
757 =item close
758
759 Closes the file or pipe associated with the file handle, returning
760 true only if IO buffers are successfully flushed and closes the system
761 file descriptor.  Closes the currently selected filehandle if the
762 argument is omitted.
763
764 You don't have to close FILEHANDLE if you are immediately going to do
765 another C<open> on it, because C<open> will close it for you.  (See
766 C<open>.)  However, an explicit C<close> on an input file resets the line
767 counter (C<$.>), while the implicit close done by C<open> does not.
768
769 If the file handle came from a piped open C<close> will additionally
770 return false if one of the other system calls involved fails or if the
771 program exits with non-zero status.  (If the only problem was that the
772 program exited non-zero C<$!> will be set to C<0>.)  Closing a pipe
773 also waits for the process executing on the pipe to complete, in case you
774 want to look at the output of the pipe afterwards, and
775 implicitly puts the exit status value of that command into C<$?>.
776
777 Prematurely closing the read end of a pipe (i.e. before the process
778 writing to it at the other end has closed it) will result in a
779 SIGPIPE being delivered to the writer.  If the other end can't
780 handle that, be sure to read all the data before closing the pipe.
781
782 Example:
783
784     open(OUTPUT, '|sort >foo')  # pipe to sort
785         or die "Can't start sort: $!";
786     #...                        # print stuff to output
787     close OUTPUT                # wait for sort to finish
788         or warn $! ? "Error closing sort pipe: $!"
789                    : "Exit status $? from sort";
790     open(INPUT, 'foo')          # get sort's results
791         or die "Can't open 'foo' for input: $!";
792
793 FILEHANDLE may be an expression whose value can be used as an indirect
794 filehandle, usually the real filehandle name.
795
796 =item closedir DIRHANDLE
797
798 Closes a directory opened by C<opendir> and returns the success of that
799 system call.
800
801 =item connect SOCKET,NAME
802
803 Attempts to connect to a remote socket, just as the connect system call
804 does.  Returns true if it succeeded, false otherwise.  NAME should be a
805 packed address of the appropriate type for the socket.  See the examples in
806 L<perlipc/"Sockets: Client/Server Communication">.
807
808 =item continue BLOCK
809
810 Actually a flow control statement rather than a function.  If there is a
811 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
812 C<foreach>), it is always executed just before the conditional is about to
813 be evaluated again, just like the third part of a C<for> loop in C.  Thus
814 it can be used to increment a loop variable, even when the loop has been
815 continued via the C<next> statement (which is similar to the C C<continue>
816 statement).
817
818 C<last>, C<next>, or C<redo> may appear within a C<continue>
819 block.  C<last> and C<redo> will behave as if they had been executed within
820 the main block.  So will C<next>, but since it will execute a C<continue>
821 block, it may be more entertaining.
822
823     while (EXPR) {
824         ### redo always comes here
825         do_something;
826     } continue {
827         ### next always comes here
828         do_something_else;
829         # then back the top to re-check EXPR
830     }
831     ### last always comes here
832
833 Omitting the C<continue> section is semantically equivalent to using an
834 empty one, logically enough.  In that case, C<next> goes directly back
835 to check the condition at the top of the loop.
836
837 =item cos EXPR
838
839 =item cos
840
841 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
842 takes cosine of C<$_>.
843
844 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
845 function, or use this relation:
846
847     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
848
849 =item crypt PLAINTEXT,SALT
850
851 Encrypts a string exactly like the crypt(3) function in the C library
852 (assuming that you actually have a version there that has not been
853 extirpated as a potential munition).  This can prove useful for checking
854 the password file for lousy passwords, amongst other things.  Only the
855 guys wearing white hats should do this.
856
857 Note that L<crypt|/crypt> is intended to be a one-way function, much like
858 breaking eggs to make an omelette.  There is no (known) corresponding
859 decrypt function (in other words, the crypt() is a one-way hash
860 function).  As a result, this function isn't all that useful for
861 cryptography.  (For that, see your nearby CPAN mirror.)
862
863 When verifying an existing encrypted string you should use the
864 encrypted text as the salt (like C<crypt($plain, $crypted) eq
865 $crypted>).  This allows your code to work with the standard L<crypt|/crypt>
866 and with more exotic implementations.  In other words, do not assume
867 anything about the returned string itself, or how many bytes in
868 the encrypted string matter.
869
870 Traditionally the result is a string of 13 bytes: two first bytes of
871 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
872 the first eight bytes of the encrypted string mattered, but
873 alternative hashing schemes (like MD5), higher level security schemes
874 (like C2), and implementations on non-UNIX platforms may produce
875 different strings.
876
877 When choosing a new salt create a random two character string whose
878 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
879 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
880 characters is just a recommendation; the characters allowed in
881 the salt depend solely on your system's crypt library, and Perl can't
882 restrict what salts C<crypt()> accepts.
883
884 Here's an example that makes sure that whoever runs this program knows
885 their own password:
886
887     $pwd = (getpwuid($<))[1];
888
889     system "stty -echo";
890     print "Password: ";
891     chomp($word = <STDIN>);
892     print "\n";
893     system "stty echo";
894
895     if (crypt($word, $pwd) ne $pwd) {
896         die "Sorry...\n";
897     } else {
898         print "ok\n";
899     }
900
901 Of course, typing in your own password to whoever asks you
902 for it is unwise.
903
904 The L<crypt|/crypt> function is unsuitable for encrypting large quantities
905 of data, not least of all because you can't get the information
906 back.  Look at the F<by-module/Crypt> and F<by-module/PGP> directories
907 on your favorite CPAN mirror for a slew of potentially useful
908 modules.
909
910 If using crypt() on a Unicode string (which I<potentially> has
911 characters with codepoints above 255), Perl tries to make sense
912 of the situation by trying to downgrade (a copy of the string)
913 the string back to an eight-bit byte string before calling crypt()
914 (on that copy).  If that works, good.  If not, crypt() dies with
915 C<Wide character in crypt>.
916
917 =item dbmclose HASH
918
919 [This function has been largely superseded by the C<untie> function.]
920
921 Breaks the binding between a DBM file and a hash.
922
923 =item dbmopen HASH,DBNAME,MASK
924
925 [This function has been largely superseded by the C<tie> function.]
926
927 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
928 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
929 argument is I<not> a filehandle, even though it looks like one).  DBNAME
930 is the name of the database (without the F<.dir> or F<.pag> extension if
931 any).  If the database does not exist, it is created with protection
932 specified by MASK (as modified by the C<umask>).  If your system supports
933 only the older DBM functions, you may perform only one C<dbmopen> in your
934 program.  In older versions of Perl, if your system had neither DBM nor
935 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
936 sdbm(3).
937
938 If you don't have write access to the DBM file, you can only read hash
939 variables, not set them.  If you want to test whether you can write,
940 either use file tests or try setting a dummy hash entry inside an C<eval>,
941 which will trap the error.
942
943 Note that functions such as C<keys> and C<values> may return huge lists
944 when used on large DBM files.  You may prefer to use the C<each>
945 function to iterate over large DBM files.  Example:
946
947     # print out history file offsets
948     dbmopen(%HIST,'/usr/lib/news/history',0666);
949     while (($key,$val) = each %HIST) {
950         print $key, ' = ', unpack('L',$val), "\n";
951     }
952     dbmclose(%HIST);
953
954 See also L<AnyDBM_File> for a more general description of the pros and
955 cons of the various dbm approaches, as well as L<DB_File> for a particularly
956 rich implementation.
957
958 You can control which DBM library you use by loading that library
959 before you call dbmopen():
960
961     use DB_File;
962     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
963         or die "Can't open netscape history file: $!";
964
965 =item defined EXPR
966
967 =item defined
968
969 Returns a Boolean value telling whether EXPR has a value other than
970 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
971 checked.
972
973 Many operations return C<undef> to indicate failure, end of file,
974 system error, uninitialized variable, and other exceptional
975 conditions.  This function allows you to distinguish C<undef> from
976 other values.  (A simple Boolean test will not distinguish among
977 C<undef>, zero, the empty string, and C<"0">, which are all equally
978 false.)  Note that since C<undef> is a valid scalar, its presence
979 doesn't I<necessarily> indicate an exceptional condition: C<pop>
980 returns C<undef> when its argument is an empty array, I<or> when the
981 element to return happens to be C<undef>.
982
983 You may also use C<defined(&func)> to check whether subroutine C<&func>
984 has ever been defined.  The return value is unaffected by any forward
985 declarations of C<&func>.  Note that a subroutine which is not defined
986 may still be callable: its package may have an C<AUTOLOAD> method that
987 makes it spring into existence the first time that it is called -- see
988 L<perlsub>.
989
990 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
991 used to report whether memory for that aggregate has ever been
992 allocated.  This behavior may disappear in future versions of Perl.
993 You should instead use a simple test for size:
994
995     if (@an_array) { print "has array elements\n" }
996     if (%a_hash)   { print "has hash members\n"   }
997
998 When used on a hash element, it tells you whether the value is defined,
999 not whether the key exists in the hash.  Use L</exists> for the latter
1000 purpose.
1001
1002 Examples:
1003
1004     print if defined $switch{'D'};
1005     print "$val\n" while defined($val = pop(@ary));
1006     die "Can't readlink $sym: $!"
1007         unless defined($value = readlink $sym);
1008     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1009     $debugging = 0 unless defined $debugging;
1010
1011 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1012 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1013 defined values.  For example, if you say
1014
1015     "ab" =~ /a(.*)b/;
1016
1017 The pattern match succeeds, and C<$1> is defined, despite the fact that it
1018 matched "nothing".  But it didn't really match nothing--rather, it
1019 matched something that happened to be zero characters long.  This is all
1020 very above-board and honest.  When a function returns an undefined value,
1021 it's an admission that it couldn't give you an honest answer.  So you
1022 should use C<defined> only when you're questioning the integrity of what
1023 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1024 what you want.
1025
1026 See also L</undef>, L</exists>, L</ref>.
1027
1028 =item delete EXPR
1029
1030 Given an expression that specifies a hash element, array element, hash slice,
1031 or array slice, deletes the specified element(s) from the hash or array.
1032 In the case of an array, if the array elements happen to be at the end,
1033 the size of the array will shrink to the highest element that tests
1034 true for exists() (or 0 if no such element exists).
1035
1036 Returns a list with the same number of elements as the number of elements
1037 for which deletion was attempted.  Each element of that list consists of
1038 either the value of the element deleted, or the undefined value.  In scalar
1039 context, this means that you get the value of the last element deleted (or
1040 the undefined value if that element did not exist).
1041
1042     %hash = (foo => 11, bar => 22, baz => 33);
1043     $scalar = delete $hash{foo};             # $scalar is 11
1044     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1045     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1046
1047 Deleting from C<%ENV> modifies the environment.  Deleting from
1048 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
1049 from a C<tie>d hash or array may not necessarily return anything.
1050
1051 Deleting an array element effectively returns that position of the array
1052 to its initial, uninitialized state.  Subsequently testing for the same
1053 element with exists() will return false.  Note that deleting array
1054 elements in the middle of an array will not shift the index of the ones
1055 after them down--use splice() for that.  See L</exists>.
1056
1057 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1058
1059     foreach $key (keys %HASH) {
1060         delete $HASH{$key};
1061     }
1062
1063     foreach $index (0 .. $#ARRAY) {
1064         delete $ARRAY[$index];
1065     }
1066
1067 And so do these:
1068
1069     delete @HASH{keys %HASH};
1070
1071     delete @ARRAY[0 .. $#ARRAY];
1072
1073 But both of these are slower than just assigning the empty list
1074 or undefining %HASH or @ARRAY:
1075
1076     %HASH = ();         # completely empty %HASH
1077     undef %HASH;        # forget %HASH ever existed
1078
1079     @ARRAY = ();        # completely empty @ARRAY
1080     undef @ARRAY;       # forget @ARRAY ever existed
1081
1082 Note that the EXPR can be arbitrarily complicated as long as the final
1083 operation is a hash element, array element,  hash slice, or array slice
1084 lookup:
1085
1086     delete $ref->[$x][$y]{$key};
1087     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1088
1089     delete $ref->[$x][$y][$index];
1090     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1091
1092 =item die LIST
1093
1094 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1095 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1096 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1097 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1098 an C<eval(),> the error message is stuffed into C<$@> and the
1099 C<eval> is terminated with the undefined value.  This makes
1100 C<die> the way to raise an exception.
1101
1102 Equivalent examples:
1103
1104     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1105     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1106
1107 If the last element of LIST does not end in a newline, the current
1108 script line number and input line number (if any) are also printed,
1109 and a newline is supplied.  Note that the "input line number" (also
1110 known as "chunk") is subject to whatever notion of "line" happens to
1111 be currently in effect, and is also available as the special variable
1112 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1113
1114 Hint: sometimes appending C<", stopped"> to your message will cause it
1115 to make better sense when the string C<"at foo line 123"> is appended.
1116 Suppose you are running script "canasta".
1117
1118     die "/etc/games is no good";
1119     die "/etc/games is no good, stopped";
1120
1121 produce, respectively
1122
1123     /etc/games is no good at canasta line 123.
1124     /etc/games is no good, stopped at canasta line 123.
1125
1126 See also exit(), warn(), and the Carp module.
1127
1128 If LIST is empty and C<$@> already contains a value (typically from a
1129 previous eval) that value is reused after appending C<"\t...propagated">.
1130 This is useful for propagating exceptions:
1131
1132     eval { ... };
1133     die unless $@ =~ /Expected exception/;
1134
1135 If LIST is empty and C<$@> contains an object reference that has a
1136 C<PROPAGATE> method, that method will be called with additional file
1137 and line number parameters.  The return value replaces the value in
1138 C<$@>.  ie. as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1139 were called.
1140
1141 If C<$@> is empty then the string C<"Died"> is used.
1142
1143 die() can also be called with a reference argument.  If this happens to be
1144 trapped within an eval(), $@ contains the reference.  This behavior permits
1145 a more elaborate exception handling implementation using objects that
1146 maintain arbitrary state about the nature of the exception.  Such a scheme
1147 is sometimes preferable to matching particular string values of $@ using
1148 regular expressions.  Here's an example:
1149
1150     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1151     if ($@) {
1152         if (ref($@) && UNIVERSAL::isa($@,"Some::Module::Exception")) {
1153             # handle Some::Module::Exception
1154         }
1155         else {
1156             # handle all other possible exceptions
1157         }
1158     }
1159
1160 Because perl will stringify uncaught exception messages before displaying
1161 them, you may want to overload stringification operations on such custom
1162 exception objects.  See L<overload> for details about that.
1163
1164 You can arrange for a callback to be run just before the C<die>
1165 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1166 handler will be called with the error text and can change the error
1167 message, if it sees fit, by calling C<die> again.  See
1168 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1169 L<"eval BLOCK"> for some examples.  Although this feature was meant
1170 to be run only right before your program was to exit, this is not
1171 currently the case--the C<$SIG{__DIE__}> hook is currently called
1172 even inside eval()ed blocks/strings!  If one wants the hook to do
1173 nothing in such situations, put
1174
1175         die @_ if $^S;
1176
1177 as the first line of the handler (see L<perlvar/$^S>).  Because
1178 this promotes strange action at a distance, this counterintuitive
1179 behavior may be fixed in a future release.
1180
1181 =item do BLOCK
1182
1183 Not really a function.  Returns the value of the last command in the
1184 sequence of commands indicated by BLOCK.  When modified by a loop
1185 modifier, executes the BLOCK once before testing the loop condition.
1186 (On other statements the loop modifiers test the conditional first.)
1187
1188 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1189 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1190 See L<perlsyn> for alternative strategies.
1191
1192 =item do SUBROUTINE(LIST)
1193
1194 A deprecated form of subroutine call.  See L<perlsub>.
1195
1196 =item do EXPR
1197
1198 Uses the value of EXPR as a filename and executes the contents of the
1199 file as a Perl script.  Its primary use is to include subroutines
1200 from a Perl subroutine library.
1201
1202     do 'stat.pl';
1203
1204 is just like
1205
1206     eval `cat stat.pl`;
1207
1208 except that it's more efficient and concise, keeps track of the current
1209 filename for error messages, searches the @INC libraries, and updates
1210 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1211 variables.  It also differs in that code evaluated with C<do FILENAME>
1212 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1213 same, however, in that it does reparse the file every time you call it,
1214 so you probably don't want to do this inside a loop.
1215
1216 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1217 error.  If C<do> can read the file but cannot compile it, it
1218 returns undef and sets an error message in C<$@>.   If the file is
1219 successfully compiled, C<do> returns the value of the last expression
1220 evaluated.
1221
1222 Note that inclusion of library modules is better done with the
1223 C<use> and C<require> operators, which also do automatic error checking
1224 and raise an exception if there's a problem.
1225
1226 You might like to use C<do> to read in a program configuration
1227 file.  Manual error checking can be done this way:
1228
1229     # read in config files: system first, then user
1230     for $file ("/share/prog/defaults.rc",
1231                "$ENV{HOME}/.someprogrc")
1232    {
1233         unless ($return = do $file) {
1234             warn "couldn't parse $file: $@" if $@;
1235             warn "couldn't do $file: $!"    unless defined $return;
1236             warn "couldn't run $file"       unless $return;
1237         }
1238     }
1239
1240 =item dump LABEL
1241
1242 =item dump
1243
1244 This function causes an immediate core dump.  See also the B<-u>
1245 command-line switch in L<perlrun>, which does the same thing.
1246 Primarily this is so that you can use the B<undump> program (not
1247 supplied) to turn your core dump into an executable binary after
1248 having initialized all your variables at the beginning of the
1249 program.  When the new binary is executed it will begin by executing
1250 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1251 Think of it as a goto with an intervening core dump and reincarnation.
1252 If C<LABEL> is omitted, restarts the program from the top.
1253
1254 B<WARNING>: Any files opened at the time of the dump will I<not>
1255 be open any more when the program is reincarnated, with possible
1256 resulting confusion on the part of Perl.
1257
1258 This function is now largely obsolete, partly because it's very
1259 hard to convert a core file into an executable, and because the
1260 real compiler backends for generating portable bytecode and compilable
1261 C code have superseded it.  That's why you should now invoke it as
1262 C<CORE::dump()>, if you don't want to be warned against a possible
1263 typo.
1264
1265 If you're looking to use L<dump> to speed up your program, consider
1266 generating bytecode or native C code as described in L<perlcc>.  If
1267 you're just trying to accelerate a CGI script, consider using the
1268 C<mod_perl> extension to B<Apache>, or the CPAN module, CGI::Fast.
1269 You might also consider autoloading or selfloading, which at least
1270 make your program I<appear> to run faster.
1271
1272 =item each HASH
1273
1274 When called in list context, returns a 2-element list consisting of the
1275 key and value for the next element of a hash, so that you can iterate over
1276 it.  When called in scalar context, returns only the key for the next
1277 element in the hash.
1278
1279 Entries are returned in an apparently random order.  The actual random
1280 order is subject to change in future versions of perl, but it is
1281 guaranteed to be in the same order as either the C<keys> or C<values>
1282 function would produce on the same (unmodified) hash.  Since Perl
1283 5.8.1 the ordering is different even between different runs of Perl
1284 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1285
1286 When the hash is entirely read, a null array is returned in list context
1287 (which when assigned produces a false (C<0>) value), and C<undef> in
1288 scalar context.  The next call to C<each> after that will start iterating
1289 again.  There is a single iterator for each hash, shared by all C<each>,
1290 C<keys>, and C<values> function calls in the program; it can be reset by
1291 reading all the elements from the hash, or by evaluating C<keys HASH> or
1292 C<values HASH>.  If you add or delete elements of a hash while you're
1293 iterating over it, you may get entries skipped or duplicated, so
1294 don't.  Exception: It is always safe to delete the item most recently
1295 returned by C<each()>, which means that the following code will work:
1296
1297         while (($key, $value) = each %hash) {
1298           print $key, "\n";
1299           delete $hash{$key};   # This is safe
1300         }
1301
1302 The following prints out your environment like the printenv(1) program,
1303 only in a different order:
1304
1305     while (($key,$value) = each %ENV) {
1306         print "$key=$value\n";
1307     }
1308
1309 See also C<keys>, C<values> and C<sort>.
1310
1311 =item eof FILEHANDLE
1312
1313 =item eof ()
1314
1315 =item eof
1316
1317 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1318 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1319 gives the real filehandle.  (Note that this function actually
1320 reads a character and then C<ungetc>s it, so isn't very useful in an
1321 interactive context.)  Do not read from a terminal file (or call
1322 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1323 as terminals may lose the end-of-file condition if you do.
1324
1325 An C<eof> without an argument uses the last file read.  Using C<eof()>
1326 with empty parentheses is very different.  It refers to the pseudo file
1327 formed from the files listed on the command line and accessed via the
1328 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1329 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1330 used will cause C<@ARGV> to be examined to determine if input is
1331 available.   Similarly, an C<eof()> after C<< <> >> has returned
1332 end-of-file will assume you are processing another C<@ARGV> list,
1333 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1334 see L<perlop/"I/O Operators">.
1335
1336 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1337 detect the end of each file, C<eof()> will only detect the end of the
1338 last file.  Examples:
1339
1340     # reset line numbering on each input file
1341     while (<>) {
1342         next if /^\s*#/;        # skip comments
1343         print "$.\t$_";
1344     } continue {
1345         close ARGV  if eof;     # Not eof()!
1346     }
1347
1348     # insert dashes just before last line of last file
1349     while (<>) {
1350         if (eof()) {            # check for end of last file
1351             print "--------------\n";
1352         }
1353         print;
1354         last if eof();          # needed if we're reading from a terminal
1355     }
1356
1357 Practical hint: you almost never need to use C<eof> in Perl, because the
1358 input operators typically return C<undef> when they run out of data, or if
1359 there was an error.
1360
1361 =item eval EXPR
1362
1363 =item eval BLOCK
1364
1365 In the first form, the return value of EXPR is parsed and executed as if it
1366 were a little Perl program.  The value of the expression (which is itself
1367 determined within scalar context) is first parsed, and if there weren't any
1368 errors, executed in the lexical context of the current Perl program, so
1369 that any variable settings or subroutine and format definitions remain
1370 afterwards.  Note that the value is parsed every time the eval executes.
1371 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1372 delay parsing and subsequent execution of the text of EXPR until run time.
1373
1374 In the second form, the code within the BLOCK is parsed only once--at the
1375 same time the code surrounding the eval itself was parsed--and executed
1376 within the context of the current Perl program.  This form is typically
1377 used to trap exceptions more efficiently than the first (see below), while
1378 also providing the benefit of checking the code within BLOCK at compile
1379 time.
1380
1381 The final semicolon, if any, may be omitted from the value of EXPR or within
1382 the BLOCK.
1383
1384 In both forms, the value returned is the value of the last expression
1385 evaluated inside the mini-program; a return statement may be also used, just
1386 as with subroutines.  The expression providing the return value is evaluated
1387 in void, scalar, or list context, depending on the context of the eval itself.
1388 See L</wantarray> for more on how the evaluation context can be determined.
1389
1390 If there is a syntax error or runtime error, or a C<die> statement is
1391 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1392 error message.  If there was no error, C<$@> is guaranteed to be a null
1393 string.  Beware that using C<eval> neither silences perl from printing
1394 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1395 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1396 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1397 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1398
1399 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1400 determining whether a particular feature (such as C<socket> or C<symlink>)
1401 is implemented.  It is also Perl's exception trapping mechanism, where
1402 the die operator is used to raise exceptions.
1403
1404 If the code to be executed doesn't vary, you may use the eval-BLOCK
1405 form to trap run-time errors without incurring the penalty of
1406 recompiling each time.  The error, if any, is still returned in C<$@>.
1407 Examples:
1408
1409     # make divide-by-zero nonfatal
1410     eval { $answer = $a / $b; }; warn $@ if $@;
1411
1412     # same thing, but less efficient
1413     eval '$answer = $a / $b'; warn $@ if $@;
1414
1415     # a compile-time error
1416     eval { $answer = };                 # WRONG
1417
1418     # a run-time error
1419     eval '$answer =';   # sets $@
1420
1421 Due to the current arguably broken state of C<__DIE__> hooks, when using
1422 the C<eval{}> form as an exception trap in libraries, you may wish not
1423 to trigger any C<__DIE__> hooks that user code may have installed.
1424 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1425 as shown in this example:
1426
1427     # a very private exception trap for divide-by-zero
1428     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1429     warn $@ if $@;
1430
1431 This is especially significant, given that C<__DIE__> hooks can call
1432 C<die> again, which has the effect of changing their error messages:
1433
1434     # __DIE__ hooks may modify error messages
1435     {
1436        local $SIG{'__DIE__'} =
1437               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1438        eval { die "foo lives here" };
1439        print $@ if $@;                # prints "bar lives here"
1440     }
1441
1442 Because this promotes action at a distance, this counterintuitive behavior
1443 may be fixed in a future release.
1444
1445 With an C<eval>, you should be especially careful to remember what's
1446 being looked at when:
1447
1448     eval $x;            # CASE 1
1449     eval "$x";          # CASE 2
1450
1451     eval '$x';          # CASE 3
1452     eval { $x };        # CASE 4
1453
1454     eval "\$$x++";      # CASE 5
1455     $$x++;              # CASE 6
1456
1457 Cases 1 and 2 above behave identically: they run the code contained in
1458 the variable $x.  (Although case 2 has misleading double quotes making
1459 the reader wonder what else might be happening (nothing is).)  Cases 3
1460 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1461 does nothing but return the value of $x.  (Case 4 is preferred for
1462 purely visual reasons, but it also has the advantage of compiling at
1463 compile-time instead of at run-time.)  Case 5 is a place where
1464 normally you I<would> like to use double quotes, except that in this
1465 particular situation, you can just use symbolic references instead, as
1466 in case 6.
1467
1468 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1469 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1470
1471 Note that as a very special case, an C<eval ''> executed within the C<DB>
1472 package doesn't see the usual surrounding lexical scope, but rather the
1473 scope of the first non-DB piece of code that called it. You don't normally
1474 need to worry about this unless you are writing a Perl debugger.
1475
1476 =item exec LIST
1477
1478 =item exec PROGRAM LIST
1479
1480 The C<exec> function executes a system command I<and never returns>--
1481 use C<system> instead of C<exec> if you want it to return.  It fails and
1482 returns false only if the command does not exist I<and> it is executed
1483 directly instead of via your system's command shell (see below).
1484
1485 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1486 warns you if there is a following statement which isn't C<die>, C<warn>,
1487 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1488 I<really> want to follow an C<exec> with some other statement, you
1489 can use one of these styles to avoid the warning:
1490
1491     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1492     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1493
1494 If there is more than one argument in LIST, or if LIST is an array
1495 with more than one value, calls execvp(3) with the arguments in LIST.
1496 If there is only one scalar argument or an array with one element in it,
1497 the argument is checked for shell metacharacters, and if there are any,
1498 the entire argument is passed to the system's command shell for parsing
1499 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1500 If there are no shell metacharacters in the argument, it is split into
1501 words and passed directly to C<execvp>, which is more efficient.
1502 Examples:
1503
1504     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1505     exec "sort $outfile | uniq";
1506
1507 If you don't really want to execute the first argument, but want to lie
1508 to the program you are executing about its own name, you can specify
1509 the program you actually want to run as an "indirect object" (without a
1510 comma) in front of the LIST.  (This always forces interpretation of the
1511 LIST as a multivalued list, even if there is only a single scalar in
1512 the list.)  Example:
1513
1514     $shell = '/bin/csh';
1515     exec $shell '-sh';          # pretend it's a login shell
1516
1517 or, more directly,
1518
1519     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1520
1521 When the arguments get executed via the system shell, results will
1522 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1523 for details.
1524
1525 Using an indirect object with C<exec> or C<system> is also more
1526 secure.  This usage (which also works fine with system()) forces
1527 interpretation of the arguments as a multivalued list, even if the
1528 list had just one argument.  That way you're safe from the shell
1529 expanding wildcards or splitting up words with whitespace in them.
1530
1531     @args = ( "echo surprise" );
1532
1533     exec @args;               # subject to shell escapes
1534                                 # if @args == 1
1535     exec { $args[0] } @args;  # safe even with one-arg list
1536
1537 The first version, the one without the indirect object, ran the I<echo>
1538 program, passing it C<"surprise"> an argument.  The second version
1539 didn't--it tried to run a program literally called I<"echo surprise">,
1540 didn't find it, and set C<$?> to a non-zero value indicating failure.
1541
1542 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1543 output before the exec, but this may not be supported on some platforms
1544 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1545 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1546 open handles in order to avoid lost output.
1547
1548 Note that C<exec> will not call your C<END> blocks, nor will it call
1549 any C<DESTROY> methods in your objects.
1550
1551 =item exists EXPR
1552
1553 Given an expression that specifies a hash element or array element,
1554 returns true if the specified element in the hash or array has ever
1555 been initialized, even if the corresponding value is undefined.  The
1556 element is not autovivified if it doesn't exist.
1557
1558     print "Exists\n"    if exists $hash{$key};
1559     print "Defined\n"   if defined $hash{$key};
1560     print "True\n"      if $hash{$key};
1561
1562     print "Exists\n"    if exists $array[$index];
1563     print "Defined\n"   if defined $array[$index];
1564     print "True\n"      if $array[$index];
1565
1566 A hash or array element can be true only if it's defined, and defined if
1567 it exists, but the reverse doesn't necessarily hold true.
1568
1569 Given an expression that specifies the name of a subroutine,
1570 returns true if the specified subroutine has ever been declared, even
1571 if it is undefined.  Mentioning a subroutine name for exists or defined
1572 does not count as declaring it.  Note that a subroutine which does not
1573 exist may still be callable: its package may have an C<AUTOLOAD>
1574 method that makes it spring into existence the first time that it is
1575 called -- see L<perlsub>.
1576
1577     print "Exists\n"    if exists &subroutine;
1578     print "Defined\n"   if defined &subroutine;
1579
1580 Note that the EXPR can be arbitrarily complicated as long as the final
1581 operation is a hash or array key lookup or subroutine name:
1582
1583     if (exists $ref->{A}->{B}->{$key})  { }
1584     if (exists $hash{A}{B}{$key})       { }
1585
1586     if (exists $ref->{A}->{B}->[$ix])   { }
1587     if (exists $hash{A}{B}[$ix])        { }
1588
1589     if (exists &{$ref->{A}{B}{$key}})   { }
1590
1591 Although the deepest nested array or hash will not spring into existence
1592 just because its existence was tested, any intervening ones will.
1593 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1594 into existence due to the existence test for the $key element above.
1595 This happens anywhere the arrow operator is used, including even:
1596
1597     undef $ref;
1598     if (exists $ref->{"Some key"})      { }
1599     print $ref;             # prints HASH(0x80d3d5c)
1600
1601 This surprising autovivification in what does not at first--or even
1602 second--glance appear to be an lvalue context may be fixed in a future
1603 release.
1604
1605 Use of a subroutine call, rather than a subroutine name, as an argument
1606 to exists() is an error.
1607
1608     exists &sub;        # OK
1609     exists &sub();      # Error
1610
1611 =item exit EXPR
1612
1613 Evaluates EXPR and exits immediately with that value.    Example:
1614
1615     $ans = <STDIN>;
1616     exit 0 if $ans =~ /^[Xx]/;
1617
1618 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1619 universally recognized values for EXPR are C<0> for success and C<1>
1620 for error; other values are subject to interpretation depending on the
1621 environment in which the Perl program is running.  For example, exiting
1622 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1623 the mailer to return the item undelivered, but that's not true everywhere.
1624
1625 Don't use C<exit> to abort a subroutine if there's any chance that
1626 someone might want to trap whatever error happened.  Use C<die> instead,
1627 which can be trapped by an C<eval>.
1628
1629 The exit() function does not always exit immediately.  It calls any
1630 defined C<END> routines first, but these C<END> routines may not
1631 themselves abort the exit.  Likewise any object destructors that need to
1632 be called are called before the real exit.  If this is a problem, you
1633 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1634 See L<perlmod> for details.
1635
1636 =item exp EXPR
1637
1638 =item exp
1639
1640 Returns I<e> (the natural logarithm base) to the power of EXPR.
1641 If EXPR is omitted, gives C<exp($_)>.
1642
1643 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1644
1645 Implements the fcntl(2) function.  You'll probably have to say
1646
1647     use Fcntl;
1648
1649 first to get the correct constant definitions.  Argument processing and
1650 value return works just like C<ioctl> below.
1651 For example:
1652
1653     use Fcntl;
1654     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1655         or die "can't fcntl F_GETFL: $!";
1656
1657 You don't have to check for C<defined> on the return from C<fcntl>.
1658 Like C<ioctl>, it maps a C<0> return from the system call into
1659 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1660 in numeric context.  It is also exempt from the normal B<-w> warnings
1661 on improper numeric conversions.
1662
1663 Note that C<fcntl> will produce a fatal error if used on a machine that
1664 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1665 manpage to learn what functions are available on your system.
1666
1667 Here's an example of setting a filehandle named C<REMOTE> to be
1668 non-blocking at the system level.  You'll have to negotiate C<$|>
1669 on your own, though.
1670
1671     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1672
1673     $flags = fcntl(REMOTE, F_GETFL, 0)
1674                 or die "Can't get flags for the socket: $!\n";
1675
1676     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1677                 or die "Can't set flags for the socket: $!\n";
1678
1679 =item fileno FILEHANDLE
1680
1681 Returns the file descriptor for a filehandle, or undefined if the
1682 filehandle is not open.  This is mainly useful for constructing
1683 bitmaps for C<select> and low-level POSIX tty-handling operations.
1684 If FILEHANDLE is an expression, the value is taken as an indirect
1685 filehandle, generally its name.
1686
1687 You can use this to find out whether two handles refer to the
1688 same underlying descriptor:
1689
1690     if (fileno(THIS) == fileno(THAT)) {
1691         print "THIS and THAT are dups\n";
1692     }
1693
1694 (Filehandles connected to memory objects via new features of C<open> may
1695 return undefined even though they are open.)
1696
1697
1698 =item flock FILEHANDLE,OPERATION
1699
1700 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1701 for success, false on failure.  Produces a fatal error if used on a
1702 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1703 C<flock> is Perl's portable file locking interface, although it locks
1704 only entire files, not records.
1705
1706 Two potentially non-obvious but traditional C<flock> semantics are
1707 that it waits indefinitely until the lock is granted, and that its locks
1708 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1709 fewer guarantees.  This means that files locked with C<flock> may be
1710 modified by programs that do not also use C<flock>.  See L<perlport>,
1711 your port's specific documentation, or your system-specific local manpages
1712 for details.  It's best to assume traditional behavior if you're writing
1713 portable programs.  (But if you're not, you should as always feel perfectly
1714 free to write for your own system's idiosyncrasies (sometimes called
1715 "features").  Slavish adherence to portability concerns shouldn't get
1716 in the way of your getting your job done.)
1717
1718 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1719 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1720 you can use the symbolic names if you import them from the Fcntl module,
1721 either individually, or as a group using the ':flock' tag.  LOCK_SH
1722 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1723 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1724 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1725 waiting for the lock (check the return status to see if you got it).
1726
1727 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1728 before locking or unlocking it.
1729
1730 Note that the emulation built with lockf(3) doesn't provide shared
1731 locks, and it requires that FILEHANDLE be open with write intent.  These
1732 are the semantics that lockf(3) implements.  Most if not all systems
1733 implement lockf(3) in terms of fcntl(2) locking, though, so the
1734 differing semantics shouldn't bite too many people.
1735
1736 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1737 be open with read intent to use LOCK_SH and requires that it be open
1738 with write intent to use LOCK_EX.
1739
1740 Note also that some versions of C<flock> cannot lock things over the
1741 network; you would need to use the more system-specific C<fcntl> for
1742 that.  If you like you can force Perl to ignore your system's flock(2)
1743 function, and so provide its own fcntl(2)-based emulation, by passing
1744 the switch C<-Ud_flock> to the F<Configure> program when you configure
1745 perl.
1746
1747 Here's a mailbox appender for BSD systems.
1748
1749     use Fcntl ':flock'; # import LOCK_* constants
1750
1751     sub lock {
1752         flock(MBOX,LOCK_EX);
1753         # and, in case someone appended
1754         # while we were waiting...
1755         seek(MBOX, 0, 2);
1756     }
1757
1758     sub unlock {
1759         flock(MBOX,LOCK_UN);
1760     }
1761
1762     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1763             or die "Can't open mailbox: $!";
1764
1765     lock();
1766     print MBOX $msg,"\n\n";
1767     unlock();
1768
1769 On systems that support a real flock(), locks are inherited across fork()
1770 calls, whereas those that must resort to the more capricious fcntl()
1771 function lose the locks, making it harder to write servers.
1772
1773 See also L<DB_File> for other flock() examples.
1774
1775 =item fork
1776
1777 Does a fork(2) system call to create a new process running the
1778 same program at the same point.  It returns the child pid to the
1779 parent process, C<0> to the child process, or C<undef> if the fork is
1780 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1781 are shared, while everything else is copied.  On most systems supporting
1782 fork(), great care has gone into making it extremely efficient (for
1783 example, using copy-on-write technology on data pages), making it the
1784 dominant paradigm for multitasking over the last few decades.
1785
1786 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1787 output before forking the child process, but this may not be supported
1788 on some platforms (see L<perlport>).  To be safe, you may need to set
1789 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1790 C<IO::Handle> on any open handles in order to avoid duplicate output.
1791
1792 If you C<fork> without ever waiting on your children, you will
1793 accumulate zombies.  On some systems, you can avoid this by setting
1794 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1795 forking and reaping moribund children.
1796
1797 Note that if your forked child inherits system file descriptors like
1798 STDIN and STDOUT that are actually connected by a pipe or socket, even
1799 if you exit, then the remote server (such as, say, a CGI script or a
1800 backgrounded job launched from a remote shell) won't think you're done.
1801 You should reopen those to F</dev/null> if it's any issue.
1802
1803 =item format
1804
1805 Declare a picture format for use by the C<write> function.  For
1806 example:
1807
1808     format Something =
1809         Test: @<<<<<<<< @||||| @>>>>>
1810               $str,     $%,    '$' . int($num)
1811     .
1812
1813     $str = "widget";
1814     $num = $cost/$quantity;
1815     $~ = 'Something';
1816     write;
1817
1818 See L<perlform> for many details and examples.
1819
1820 =item formline PICTURE,LIST
1821
1822 This is an internal function used by C<format>s, though you may call it,
1823 too.  It formats (see L<perlform>) a list of values according to the
1824 contents of PICTURE, placing the output into the format output
1825 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1826 Eventually, when a C<write> is done, the contents of
1827 C<$^A> are written to some filehandle, but you could also read C<$^A>
1828 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1829 does one C<formline> per line of form, but the C<formline> function itself
1830 doesn't care how many newlines are embedded in the PICTURE.  This means
1831 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1832 You may therefore need to use multiple formlines to implement a single
1833 record format, just like the format compiler.
1834
1835 Be careful if you put double quotes around the picture, because an C<@>
1836 character may be taken to mean the beginning of an array name.
1837 C<formline> always returns true.  See L<perlform> for other examples.
1838
1839 =item getc FILEHANDLE
1840
1841 =item getc
1842
1843 Returns the next character from the input file attached to FILEHANDLE,
1844 or the undefined value at end of file, or if there was an error (in
1845 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
1846 STDIN.  This is not particularly efficient.  However, it cannot be
1847 used by itself to fetch single characters without waiting for the user
1848 to hit enter.  For that, try something more like:
1849
1850     if ($BSD_STYLE) {
1851         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1852     }
1853     else {
1854         system "stty", '-icanon', 'eol', "\001";
1855     }
1856
1857     $key = getc(STDIN);
1858
1859     if ($BSD_STYLE) {
1860         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1861     }
1862     else {
1863         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1864     }
1865     print "\n";
1866
1867 Determination of whether $BSD_STYLE should be set
1868 is left as an exercise to the reader.
1869
1870 The C<POSIX::getattr> function can do this more portably on
1871 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1872 module from your nearest CPAN site; details on CPAN can be found on
1873 L<perlmodlib/CPAN>.
1874
1875 =item getlogin
1876
1877 Implements the C library function of the same name, which on most
1878 systems returns the current login from F</etc/utmp>, if any.  If null,
1879 use C<getpwuid>.
1880
1881     $login = getlogin || getpwuid($<) || "Kilroy";
1882
1883 Do not consider C<getlogin> for authentication: it is not as
1884 secure as C<getpwuid>.
1885
1886 =item getpeername SOCKET
1887
1888 Returns the packed sockaddr address of other end of the SOCKET connection.
1889
1890     use Socket;
1891     $hersockaddr    = getpeername(SOCK);
1892     ($port, $iaddr) = sockaddr_in($hersockaddr);
1893     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1894     $herstraddr     = inet_ntoa($iaddr);
1895
1896 =item getpgrp PID
1897
1898 Returns the current process group for the specified PID.  Use
1899 a PID of C<0> to get the current process group for the
1900 current process.  Will raise an exception if used on a machine that
1901 doesn't implement getpgrp(2).  If PID is omitted, returns process
1902 group of current process.  Note that the POSIX version of C<getpgrp>
1903 does not accept a PID argument, so only C<PID==0> is truly portable.
1904
1905 =item getppid
1906
1907 Returns the process id of the parent process.
1908
1909 Note for Linux users: on Linux, the C functions C<getpid()> and
1910 C<getppid()> return different values from different threads. In order to
1911 be portable, this behavior is not reflected by the perl-level function
1912 C<getppid()>, that returns a consistent value across threads. If you want
1913 to call the underlying C<getppid()>, you may use the CPAN module
1914 C<Linux::Pid>.
1915
1916 =item getpriority WHICH,WHO
1917
1918 Returns the current priority for a process, a process group, or a user.
1919 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1920 machine that doesn't implement getpriority(2).
1921
1922 =item getpwnam NAME
1923
1924 =item getgrnam NAME
1925
1926 =item gethostbyname NAME
1927
1928 =item getnetbyname NAME
1929
1930 =item getprotobyname NAME
1931
1932 =item getpwuid UID
1933
1934 =item getgrgid GID
1935
1936 =item getservbyname NAME,PROTO
1937
1938 =item gethostbyaddr ADDR,ADDRTYPE
1939
1940 =item getnetbyaddr ADDR,ADDRTYPE
1941
1942 =item getprotobynumber NUMBER
1943
1944 =item getservbyport PORT,PROTO
1945
1946 =item getpwent
1947
1948 =item getgrent
1949
1950 =item gethostent
1951
1952 =item getnetent
1953
1954 =item getprotoent
1955
1956 =item getservent
1957
1958 =item setpwent
1959
1960 =item setgrent
1961
1962 =item sethostent STAYOPEN
1963
1964 =item setnetent STAYOPEN
1965
1966 =item setprotoent STAYOPEN
1967
1968 =item setservent STAYOPEN
1969
1970 =item endpwent
1971
1972 =item endgrent
1973
1974 =item endhostent
1975
1976 =item endnetent
1977
1978 =item endprotoent
1979
1980 =item endservent
1981
1982 These routines perform the same functions as their counterparts in the
1983 system library.  In list context, the return values from the
1984 various get routines are as follows:
1985
1986     ($name,$passwd,$uid,$gid,
1987        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1988     ($name,$passwd,$gid,$members) = getgr*
1989     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1990     ($name,$aliases,$addrtype,$net) = getnet*
1991     ($name,$aliases,$proto) = getproto*
1992     ($name,$aliases,$port,$proto) = getserv*
1993
1994 (If the entry doesn't exist you get a null list.)
1995
1996 The exact meaning of the $gcos field varies but it usually contains
1997 the real name of the user (as opposed to the login name) and other
1998 information pertaining to the user.  Beware, however, that in many
1999 system users are able to change this information and therefore it
2000 cannot be trusted and therefore the $gcos is tainted (see
2001 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2002 login shell, are also tainted, because of the same reason.
2003
2004 In scalar context, you get the name, unless the function was a
2005 lookup by name, in which case you get the other thing, whatever it is.
2006 (If the entry doesn't exist you get the undefined value.)  For example:
2007
2008     $uid   = getpwnam($name);
2009     $name  = getpwuid($num);
2010     $name  = getpwent();
2011     $gid   = getgrnam($name);
2012     $name  = getgrgid($num);
2013     $name  = getgrent();
2014     #etc.
2015
2016 In I<getpw*()> the fields $quota, $comment, and $expire are special
2017 cases in the sense that in many systems they are unsupported.  If the
2018 $quota is unsupported, it is an empty scalar.  If it is supported, it
2019 usually encodes the disk quota.  If the $comment field is unsupported,
2020 it is an empty scalar.  If it is supported it usually encodes some
2021 administrative comment about the user.  In some systems the $quota
2022 field may be $change or $age, fields that have to do with password
2023 aging.  In some systems the $comment field may be $class.  The $expire
2024 field, if present, encodes the expiration period of the account or the
2025 password.  For the availability and the exact meaning of these fields
2026 in your system, please consult your getpwnam(3) documentation and your
2027 F<pwd.h> file.  You can also find out from within Perl what your
2028 $quota and $comment fields mean and whether you have the $expire field
2029 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2030 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2031 files are only supported if your vendor has implemented them in the
2032 intuitive fashion that calling the regular C library routines gets the
2033 shadow versions if you're running under privilege or if there exists
2034 the shadow(3) functions as found in System V ( this includes Solaris
2035 and Linux.)  Those systems which implement a proprietary shadow password
2036 facility are unlikely to be supported.
2037
2038 The $members value returned by I<getgr*()> is a space separated list of
2039 the login names of the members of the group.
2040
2041 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2042 C, it will be returned to you via C<$?> if the function call fails.  The
2043 C<@addrs> value returned by a successful call is a list of the raw
2044 addresses returned by the corresponding system library call.  In the
2045 Internet domain, each address is four bytes long and you can unpack it
2046 by saying something like:
2047
2048     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
2049
2050 The Socket library makes this slightly easier:
2051
2052     use Socket;
2053     $iaddr = inet_aton("127.1"); # or whatever address
2054     $name  = gethostbyaddr($iaddr, AF_INET);
2055
2056     # or going the other way
2057     $straddr = inet_ntoa($iaddr);
2058
2059 If you get tired of remembering which element of the return list
2060 contains which return value, by-name interfaces are provided
2061 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2062 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2063 and C<User::grent>.  These override the normal built-ins, supplying
2064 versions that return objects with the appropriate names
2065 for each field.  For example:
2066
2067    use File::stat;
2068    use User::pwent;
2069    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2070
2071 Even though it looks like they're the same method calls (uid),
2072 they aren't, because a C<File::stat> object is different from
2073 a C<User::pwent> object.
2074
2075 =item getsockname SOCKET
2076
2077 Returns the packed sockaddr address of this end of the SOCKET connection,
2078 in case you don't know the address because you have several different
2079 IPs that the connection might have come in on.
2080
2081     use Socket;
2082     $mysockaddr = getsockname(SOCK);
2083     ($port, $myaddr) = sockaddr_in($mysockaddr);
2084     printf "Connect to %s [%s]\n",
2085        scalar gethostbyaddr($myaddr, AF_INET),
2086        inet_ntoa($myaddr);
2087
2088 =item getsockopt SOCKET,LEVEL,OPTNAME
2089
2090 Returns the socket option requested, or undef if there is an error.
2091
2092 =item glob EXPR
2093
2094 =item glob
2095
2096 In list context, returns a (possibly empty) list of filename expansions on
2097 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2098 scalar context, glob iterates through such filename expansions, returning
2099 undef when the list is exhausted. This is the internal function
2100 implementing the C<< <*.c> >> operator, but you can use it directly. If
2101 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2102 more detail in L<perlop/"I/O Operators">.
2103
2104 Beginning with v5.6.0, this operator is implemented using the standard
2105 C<File::Glob> extension.  See L<File::Glob> for details.
2106
2107 =item gmtime EXPR
2108
2109 Converts a time as returned by the time function to an 8-element list
2110 with the time localized for the standard Greenwich time zone.
2111 Typically used as follows:
2112
2113     #  0    1    2     3     4    5     6     7
2114     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) =
2115                                             gmtime(time);
2116
2117 All list elements are numeric, and come straight out of the C `struct
2118 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2119 specified time.  $mday is the day of the month, and $mon is the month
2120 itself, in the range C<0..11> with 0 indicating January and 11
2121 indicating December.  $year is the number of years since 1900.  That
2122 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2123 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2124 the year, in the range C<0..364> (or C<0..365> in leap years.)
2125
2126 Note that the $year element is I<not> simply the last two digits of
2127 the year.  If you assume it is, then you create non-Y2K-compliant
2128 programs--and you wouldn't want to do that, would you?
2129
2130 The proper way to get a complete 4-digit year is simply:
2131
2132         $year += 1900;
2133
2134 And to get the last two digits of the year (e.g., '01' in 2001) do:
2135
2136         $year = sprintf("%02d", $year % 100);
2137
2138 If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>).
2139
2140 In scalar context, C<gmtime()> returns the ctime(3) value:
2141
2142     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2143
2144 Also see the C<timegm> function provided by the C<Time::Local> module,
2145 and the strftime(3) function available via the POSIX module.
2146
2147 This scalar value is B<not> locale dependent (see L<perllocale>), but
2148 is instead a Perl builtin.  Also see the C<Time::Local> module, and the
2149 strftime(3) and mktime(3) functions available via the POSIX module.  To
2150 get somewhat similar but locale dependent date strings, set up your
2151 locale environment variables appropriately (please see L<perllocale>)
2152 and try for example:
2153
2154     use POSIX qw(strftime);
2155     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2156
2157 Note that the C<%a> and C<%b> escapes, which represent the short forms
2158 of the day of the week and the month of the year, may not necessarily
2159 be three characters wide in all locales.
2160
2161 =item goto LABEL
2162
2163 =item goto EXPR
2164
2165 =item goto &NAME
2166
2167 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2168 execution there.  It may not be used to go into any construct that
2169 requires initialization, such as a subroutine or a C<foreach> loop.  It
2170 also can't be used to go into a construct that is optimized away,
2171 or to get out of a block or subroutine given to C<sort>.
2172 It can be used to go almost anywhere else within the dynamic scope,
2173 including out of subroutines, but it's usually better to use some other
2174 construct such as C<last> or C<die>.  The author of Perl has never felt the
2175 need to use this form of C<goto> (in Perl, that is--C is another matter).
2176 (The difference being that C does not offer named loops combined with
2177 loop control.  Perl does, and this replaces most structured uses of C<goto>
2178 in other languages.)
2179
2180 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2181 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2182 necessarily recommended if you're optimizing for maintainability:
2183
2184     goto ("FOO", "BAR", "GLARCH")[$i];
2185
2186 The C<goto-&NAME> form is quite different from the other forms of
2187 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2188 doesn't have the stigma associated with other gotos.  Instead, it
2189 exits the current subroutine (losing any changes set by local()) and
2190 immediately calls in its place the named subroutine using the current
2191 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2192 load another subroutine and then pretend that the other subroutine had
2193 been called in the first place (except that any modifications to C<@_>
2194 in the current subroutine are propagated to the other subroutine.)
2195 After the C<goto>, not even C<caller> will be able to tell that this
2196 routine was called first.
2197
2198 NAME needn't be the name of a subroutine; it can be a scalar variable
2199 containing a code reference, or a block which evaluates to a code
2200 reference.
2201
2202 =item grep BLOCK LIST
2203
2204 =item grep EXPR,LIST
2205
2206 This is similar in spirit to, but not the same as, grep(1) and its
2207 relatives.  In particular, it is not limited to using regular expressions.
2208
2209 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2210 C<$_> to each element) and returns the list value consisting of those
2211 elements for which the expression evaluated to true.  In scalar
2212 context, returns the number of times the expression was true.
2213
2214     @foo = grep(!/^#/, @bar);    # weed out comments
2215
2216 or equivalently,
2217
2218     @foo = grep {!/^#/} @bar;    # weed out comments
2219
2220 Note that C<$_> is an alias to the list value, so it can be used to
2221 modify the elements of the LIST.  While this is useful and supported,
2222 it can cause bizarre results if the elements of LIST are not variables.
2223 Similarly, grep returns aliases into the original list, much as a for
2224 loop's index variable aliases the list elements.  That is, modifying an
2225 element of a list returned by grep (for example, in a C<foreach>, C<map>
2226 or another C<grep>) actually modifies the element in the original list.
2227 This is usually something to be avoided when writing clear code.
2228
2229 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2230
2231 =item hex EXPR
2232
2233 =item hex
2234
2235 Interprets EXPR as a hex string and returns the corresponding value.
2236 (To convert strings that might start with either 0, 0x, or 0b, see
2237 L</oct>.)  If EXPR is omitted, uses C<$_>.
2238
2239     print hex '0xAf'; # prints '175'
2240     print hex 'aF';   # same
2241
2242 Hex strings may only represent integers.  Strings that would cause
2243 integer overflow trigger a warning.  Leading whitespace is not stripped,
2244 unlike oct().
2245
2246 =item import
2247
2248 There is no builtin C<import> function.  It is just an ordinary
2249 method (subroutine) defined (or inherited) by modules that wish to export
2250 names to another module.  The C<use> function calls the C<import> method
2251 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2252
2253 =item index STR,SUBSTR,POSITION
2254
2255 =item index STR,SUBSTR
2256
2257 The index function searches for one string within another, but without
2258 the wildcard-like behavior of a full regular-expression pattern match.
2259 It returns the position of the first occurrence of SUBSTR in STR at
2260 or after POSITION.  If POSITION is omitted, starts searching from the
2261 beginning of the string.  The return value is based at C<0> (or whatever
2262 you've set the C<$[> variable to--but don't do that).  If the substring
2263 is not found, returns one less than the base, ordinarily C<-1>.
2264
2265 =item int EXPR
2266
2267 =item int
2268
2269 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2270 You should not use this function for rounding: one because it truncates
2271 towards C<0>, and two because machine representations of floating point
2272 numbers can sometimes produce counterintuitive results.  For example,
2273 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2274 because it's really more like -268.99999999999994315658 instead.  Usually,
2275 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2276 functions will serve you better than will int().
2277
2278 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2279
2280 Implements the ioctl(2) function.  You'll probably first have to say
2281
2282     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
2283
2284 to get the correct function definitions.  If F<ioctl.ph> doesn't
2285 exist or doesn't have the correct definitions you'll have to roll your
2286 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2287 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2288 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2289 written depending on the FUNCTION--a pointer to the string value of SCALAR
2290 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2291 has no string value but does have a numeric value, that value will be
2292 passed rather than a pointer to the string value.  To guarantee this to be
2293 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2294 functions may be needed to manipulate the values of structures used by
2295 C<ioctl>.
2296
2297 The return value of C<ioctl> (and C<fcntl>) is as follows:
2298
2299         if OS returns:          then Perl returns:
2300             -1                    undefined value
2301              0                  string "0 but true"
2302         anything else               that number
2303
2304 Thus Perl returns true on success and false on failure, yet you can
2305 still easily determine the actual value returned by the operating
2306 system:
2307
2308     $retval = ioctl(...) || -1;
2309     printf "System returned %d\n", $retval;
2310
2311 The special string C<"0 but true"> is exempt from B<-w> complaints
2312 about improper numeric conversions.
2313
2314 =item join EXPR,LIST
2315
2316 Joins the separate strings of LIST into a single string with fields
2317 separated by the value of EXPR, and returns that new string.  Example:
2318
2319     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2320
2321 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2322 first argument.  Compare L</split>.
2323
2324 =item keys HASH
2325
2326 Returns a list consisting of all the keys of the named hash.
2327 (In scalar context, returns the number of keys.)
2328
2329 The keys are returned in an apparently random order.  The actual
2330 random order is subject to change in future versions of perl, but it
2331 is guaranteed to be the same order as either the C<values> or C<each>
2332 function produces (given that the hash has not been modified).  Since
2333 Perl 5.8.1 the ordering is different even between different runs of
2334 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2335 Attacks">).
2336
2337 As a side effect, calling keys() resets the HASH's internal iterator,
2338 see L</each>. (In particular, calling keys() in void context resets
2339 the iterator with no other overhead.)
2340
2341 Here is yet another way to print your environment:
2342
2343     @keys = keys %ENV;
2344     @values = values %ENV;
2345     while (@keys) {
2346         print pop(@keys), '=', pop(@values), "\n";
2347     }
2348
2349 or how about sorted by key:
2350
2351     foreach $key (sort(keys %ENV)) {
2352         print $key, '=', $ENV{$key}, "\n";
2353     }
2354
2355 The returned values are copies of the original keys in the hash, so
2356 modifying them will not affect the original hash.  Compare L</values>.
2357
2358 To sort a hash by value, you'll need to use a C<sort> function.
2359 Here's a descending numeric sort of a hash by its values:
2360
2361     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2362         printf "%4d %s\n", $hash{$key}, $key;
2363     }
2364
2365 As an lvalue C<keys> allows you to increase the number of hash buckets
2366 allocated for the given hash.  This can gain you a measure of efficiency if
2367 you know the hash is going to get big.  (This is similar to pre-extending
2368 an array by assigning a larger number to $#array.)  If you say
2369
2370     keys %hash = 200;
2371
2372 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2373 in fact, since it rounds up to the next power of two.  These
2374 buckets will be retained even if you do C<%hash = ()>, use C<undef
2375 %hash> if you want to free the storage while C<%hash> is still in scope.
2376 You can't shrink the number of buckets allocated for the hash using
2377 C<keys> in this way (but you needn't worry about doing this by accident,
2378 as trying has no effect).
2379
2380 See also C<each>, C<values> and C<sort>.
2381
2382 =item kill SIGNAL, LIST
2383
2384 Sends a signal to a list of processes.  Returns the number of
2385 processes successfully signaled (which is not necessarily the
2386 same as the number actually killed).
2387
2388     $cnt = kill 1, $child1, $child2;
2389     kill 9, @goners;
2390
2391 If SIGNAL is zero, no signal is sent to the process.  This is a
2392 useful way to check that a child process is alive and hasn't changed
2393 its UID.  See L<perlport> for notes on the portability of this
2394 construct.
2395
2396 Unlike in the shell, if SIGNAL is negative, it kills
2397 process groups instead of processes.  (On System V, a negative I<PROCESS>
2398 number will also kill process groups, but that's not portable.)  That
2399 means you usually want to use positive not negative signals.  You may also
2400 use a signal name in quotes.
2401
2402 See L<perlipc/"Signals"> for more details.
2403
2404 =item last LABEL
2405
2406 =item last
2407
2408 The C<last> command is like the C<break> statement in C (as used in
2409 loops); it immediately exits the loop in question.  If the LABEL is
2410 omitted, the command refers to the innermost enclosing loop.  The
2411 C<continue> block, if any, is not executed:
2412
2413     LINE: while (<STDIN>) {
2414         last LINE if /^$/;      # exit when done with header
2415         #...
2416     }
2417
2418 C<last> cannot be used to exit a block which returns a value such as
2419 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2420 a grep() or map() operation.
2421
2422 Note that a block by itself is semantically identical to a loop
2423 that executes once.  Thus C<last> can be used to effect an early
2424 exit out of such a block.
2425
2426 See also L</continue> for an illustration of how C<last>, C<next>, and
2427 C<redo> work.
2428
2429 =item lc EXPR
2430
2431 =item lc
2432
2433 Returns a lowercased version of EXPR.  This is the internal function
2434 implementing the C<\L> escape in double-quoted strings.  Respects
2435 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2436 and L<perlunicode> for more details about locale and Unicode support.
2437
2438 If EXPR is omitted, uses C<$_>.
2439
2440 =item lcfirst EXPR
2441
2442 =item lcfirst
2443
2444 Returns the value of EXPR with the first character lowercased.  This
2445 is the internal function implementing the C<\l> escape in
2446 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2447 locale> in force.  See L<perllocale> and L<perlunicode> for more
2448 details about locale and Unicode support.
2449
2450 If EXPR is omitted, uses C<$_>.
2451
2452 =item length EXPR
2453
2454 =item length
2455
2456 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2457 omitted, returns length of C<$_>.  Note that this cannot be used on
2458 an entire array or hash to find out how many elements these have.
2459 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2460
2461 Note the I<characters>: if the EXPR is in Unicode, you will get the
2462 number of characters, not the number of bytes.  To get the length
2463 in bytes, use C<do { use bytes; length(EXPR) }>, see L<bytes>.
2464
2465 =item link OLDFILE,NEWFILE
2466
2467 Creates a new filename linked to the old filename.  Returns true for
2468 success, false otherwise.
2469
2470 =item listen SOCKET,QUEUESIZE
2471
2472 Does the same thing that the listen system call does.  Returns true if
2473 it succeeded, false otherwise.  See the example in
2474 L<perlipc/"Sockets: Client/Server Communication">.
2475
2476 =item local EXPR
2477
2478 You really probably want to be using C<my> instead, because C<local> isn't
2479 what most people think of as "local".  See
2480 L<perlsub/"Private Variables via my()"> for details.
2481
2482 A local modifies the listed variables to be local to the enclosing
2483 block, file, or eval.  If more than one value is listed, the list must
2484 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2485 for details, including issues with tied arrays and hashes.
2486
2487 =item localtime EXPR
2488
2489 Converts a time as returned by the time function to a 9-element list
2490 with the time analyzed for the local time zone.  Typically used as
2491 follows:
2492
2493     #  0    1    2     3     4    5     6     7     8
2494     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2495                                                 localtime(time);
2496
2497 All list elements are numeric, and come straight out of the C `struct
2498 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2499 specified time.  $mday is the day of the month, and $mon is the month
2500 itself, in the range C<0..11> with 0 indicating January and 11
2501 indicating December.  $year is the number of years since 1900.  That
2502 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2503 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2504 the year, in the range C<0..364> (or C<0..365> in leap years.)  $isdst
2505 is true if the specified time occurs during daylight savings time,
2506 false otherwise.
2507
2508 Note that the $year element is I<not> simply the last two digits of
2509 the year.  If you assume it is, then you create non-Y2K-compliant
2510 programs--and you wouldn't want to do that, would you?
2511
2512 The proper way to get a complete 4-digit year is simply:
2513
2514         $year += 1900;
2515
2516 And to get the last two digits of the year (e.g., '01' in 2001) do:
2517
2518         $year = sprintf("%02d", $year % 100);
2519
2520 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2521
2522 In scalar context, C<localtime()> returns the ctime(3) value:
2523
2524     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2525
2526 This scalar value is B<not> locale dependent, see L<perllocale>, but
2527 instead a Perl builtin.  Also see the C<Time::Local> module
2528 (to convert the second, minutes, hours, ... back to seconds since the
2529 stroke of midnight the 1st of January 1970, the value returned by
2530 time()), and the strftime(3) and mktime(3) functions available via the
2531 POSIX module.  To get somewhat similar but locale dependent date
2532 strings, set up your locale environment variables appropriately
2533 (please see L<perllocale>) and try for example:
2534
2535     use POSIX qw(strftime);
2536     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2537
2538 Note that the C<%a> and C<%b>, the short forms of the day of the week
2539 and the month of the year, may not necessarily be three characters wide.
2540
2541 =item lock THING
2542
2543 This function places an advisory lock on a shared variable, or referenced
2544 object contained in I<THING> until the lock goes out of scope.
2545
2546 lock() is a "weak keyword" : this means that if you've defined a function
2547 by this name (before any calls to it), that function will be called
2548 instead. (However, if you've said C<use threads>, lock() is always a
2549 keyword.) See L<threads>.
2550
2551 =item log EXPR
2552
2553 =item log
2554
2555 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2556 returns log of C<$_>.  To get the log of another base, use basic algebra:
2557 The base-N log of a number is equal to the natural log of that number
2558 divided by the natural log of N.  For example:
2559
2560     sub log10 {
2561         my $n = shift;
2562         return log($n)/log(10);
2563     }
2564
2565 See also L</exp> for the inverse operation.
2566
2567 =item lstat EXPR
2568
2569 =item lstat
2570
2571 Does the same thing as the C<stat> function (including setting the
2572 special C<_> filehandle) but stats a symbolic link instead of the file
2573 the symbolic link points to.  If symbolic links are unimplemented on
2574 your system, a normal C<stat> is done.  For much more detailed
2575 information, please see the documentation for C<stat>.
2576
2577 If EXPR is omitted, stats C<$_>.
2578
2579 =item m//
2580
2581 The match operator.  See L<perlop>.
2582
2583 =item map BLOCK LIST
2584
2585 =item map EXPR,LIST
2586
2587 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2588 C<$_> to each element) and returns the list value composed of the
2589 results of each such evaluation.  In scalar context, returns the
2590 total number of elements so generated.  Evaluates BLOCK or EXPR in
2591 list context, so each element of LIST may produce zero, one, or
2592 more elements in the returned value.
2593
2594     @chars = map(chr, @nums);
2595
2596 translates a list of numbers to the corresponding characters.  And
2597
2598     %hash = map { getkey($_) => $_ } @array;
2599
2600 is just a funny way to write
2601
2602     %hash = ();
2603     foreach $_ (@array) {
2604         $hash{getkey($_)} = $_;
2605     }
2606
2607 Note that C<$_> is an alias to the list value, so it can be used to
2608 modify the elements of the LIST.  While this is useful and supported,
2609 it can cause bizarre results if the elements of LIST are not variables.
2610 Using a regular C<foreach> loop for this purpose would be clearer in
2611 most cases.  See also L</grep> for an array composed of those items of
2612 the original list for which the BLOCK or EXPR evaluates to true.
2613
2614 C<{> starts both hash references and blocks, so C<map { ...> could be either
2615 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2616 ahead for the closing C<}> it has to take a guess at which its dealing with
2617 based what it finds just after the C<{>. Usually it gets it right, but if it
2618 doesn't it won't realize something is wrong until it gets to the C<}> and
2619 encounters the missing (or unexpected) comma. The syntax error will be
2620 reported close to the C<}> but you'll need to change something near the C<{>
2621 such as using a unary C<+> to give perl some help:
2622
2623     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2624     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2625     %hash = map { ("\L$_", 1) } @array  # this also works
2626     %hash = map {  lc($_), 1  } @array  # as does this.
2627     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2628
2629     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2630
2631 or to force an anon hash constructor use C<+{>
2632
2633    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2634
2635 and you get list of anonymous hashes each with only 1 entry.
2636
2637 =item mkdir FILENAME,MASK
2638
2639 =item mkdir FILENAME
2640
2641 Creates the directory specified by FILENAME, with permissions
2642 specified by MASK (as modified by C<umask>).  If it succeeds it
2643 returns true, otherwise it returns false and sets C<$!> (errno).
2644 If omitted, MASK defaults to 0777.
2645
2646 In general, it is better to create directories with permissive MASK,
2647 and let the user modify that with their C<umask>, than it is to supply
2648 a restrictive MASK and give the user no way to be more permissive.
2649 The exceptions to this rule are when the file or directory should be
2650 kept private (mail files, for instance).  The perlfunc(1) entry on
2651 C<umask> discusses the choice of MASK in more detail.
2652
2653 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2654 number of trailing slashes.  Some operating and filesystems do not get
2655 this right, so Perl automatically removes all trailing slashes to keep
2656 everyone happy.
2657
2658 =item msgctl ID,CMD,ARG
2659
2660 Calls the System V IPC function msgctl(2).  You'll probably have to say
2661
2662     use IPC::SysV;
2663
2664 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2665 then ARG must be a variable which will hold the returned C<msqid_ds>
2666 structure.  Returns like C<ioctl>: the undefined value for error,
2667 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2668 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2669
2670 =item msgget KEY,FLAGS
2671
2672 Calls the System V IPC function msgget(2).  Returns the message queue
2673 id, or the undefined value if there is an error.  See also
2674 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2675
2676 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2677
2678 Calls the System V IPC function msgrcv to receive a message from
2679 message queue ID into variable VAR with a maximum message size of
2680 SIZE.  Note that when a message is received, the message type as a
2681 native long integer will be the first thing in VAR, followed by the
2682 actual message.  This packing may be opened with C<unpack("l! a*")>.
2683 Taints the variable.  Returns true if successful, or false if there is
2684 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2685 C<IPC::SysV::Msg> documentation.
2686
2687 =item msgsnd ID,MSG,FLAGS
2688
2689 Calls the System V IPC function msgsnd to send the message MSG to the
2690 message queue ID.  MSG must begin with the native long integer message
2691 type, and be followed by the length of the actual message, and finally
2692 the message itself.  This kind of packing can be achieved with
2693 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2694 or false if there is an error.  See also C<IPC::SysV>
2695 and C<IPC::SysV::Msg> documentation.
2696
2697 =item my EXPR
2698
2699 =item my TYPE EXPR
2700
2701 =item my EXPR : ATTRS
2702
2703 =item my TYPE EXPR : ATTRS
2704
2705 A C<my> declares the listed variables to be local (lexically) to the
2706 enclosing block, file, or C<eval>.  If more than one value is listed,
2707 the list must be placed in parentheses.
2708
2709 The exact semantics and interface of TYPE and ATTRS are still
2710 evolving.  TYPE is currently bound to the use of C<fields> pragma,
2711 and attributes are handled using the C<attributes> pragma, or starting
2712 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
2713 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
2714 L<attributes>, and L<Attribute::Handlers>.
2715
2716 =item next LABEL
2717
2718 =item next
2719
2720 The C<next> command is like the C<continue> statement in C; it starts
2721 the next iteration of the loop:
2722
2723     LINE: while (<STDIN>) {
2724         next LINE if /^#/;      # discard comments
2725         #...
2726     }
2727
2728 Note that if there were a C<continue> block on the above, it would get
2729 executed even on discarded lines.  If the LABEL is omitted, the command
2730 refers to the innermost enclosing loop.
2731
2732 C<next> cannot be used to exit a block which returns a value such as
2733 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2734 a grep() or map() operation.
2735
2736 Note that a block by itself is semantically identical to a loop
2737 that executes once.  Thus C<next> will exit such a block early.
2738
2739 See also L</continue> for an illustration of how C<last>, C<next>, and
2740 C<redo> work.
2741
2742 =item no Module VERSION LIST
2743
2744 =item no Module VERSION
2745
2746 =item no Module LIST
2747
2748 =item no Module
2749
2750 See the C<use> function, of which C<no> is the opposite.
2751
2752 =item oct EXPR
2753
2754 =item oct
2755
2756 Interprets EXPR as an octal string and returns the corresponding
2757 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2758 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2759 binary string.  Leading whitespace is ignored in all three cases.)
2760 The following will handle decimal, binary, octal, and hex in the standard
2761 Perl or C notation:
2762
2763     $val = oct($val) if $val =~ /^0/;
2764
2765 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2766 in octal), use sprintf() or printf():
2767
2768     $perms = (stat("filename"))[2] & 07777;
2769     $oct_perms = sprintf "%lo", $perms;
2770
2771 The oct() function is commonly used when a string such as C<644> needs
2772 to be converted into a file mode, for example. (Although perl will
2773 automatically convert strings into numbers as needed, this automatic
2774 conversion assumes base 10.)
2775
2776 =item open FILEHANDLE,EXPR
2777
2778 =item open FILEHANDLE,MODE,EXPR
2779
2780 =item open FILEHANDLE,MODE,EXPR,LIST
2781
2782 =item open FILEHANDLE,MODE,REFERENCE
2783
2784 =item open FILEHANDLE
2785
2786 Opens the file whose filename is given by EXPR, and associates it with
2787 FILEHANDLE.
2788
2789 (The following is a comprehensive reference to open(): for a gentler
2790 introduction you may consider L<perlopentut>.)
2791
2792 If FILEHANDLE is an undefined scalar variable (or array or hash element)
2793 the variable is assigned a reference to a new anonymous filehandle,
2794 otherwise if FILEHANDLE is an expression, its value is used as the name of
2795 the real filehandle wanted.  (This is considered a symbolic reference, so
2796 C<use strict 'refs'> should I<not> be in effect.)
2797
2798 If EXPR is omitted, the scalar variable of the same name as the
2799 FILEHANDLE contains the filename.  (Note that lexical variables--those
2800 declared with C<my>--will not work for this purpose; so if you're
2801 using C<my>, specify EXPR in your call to open.)
2802
2803 If three or more arguments are specified then the mode of opening and
2804 the file name are separate. If MODE is C<< '<' >> or nothing, the file
2805 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
2806 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
2807 the file is opened for appending, again being created if necessary.
2808
2809 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
2810 indicate that you want both read and write access to the file; thus
2811 C<< '+<' >> is almost always preferred for read/write updates--the C<<
2812 '+>' >> mode would clobber the file first.  You can't usually use
2813 either read-write mode for updating textfiles, since they have
2814 variable length records.  See the B<-i> switch in L<perlrun> for a
2815 better approach.  The file is created with permissions of C<0666>
2816 modified by the process' C<umask> value.
2817
2818 These various prefixes correspond to the fopen(3) modes of C<'r'>,
2819 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
2820
2821 In the 2-arguments (and 1-argument) form of the call the mode and
2822 filename should be concatenated (in this order), possibly separated by
2823 spaces.  It is possible to omit the mode in these forms if the mode is
2824 C<< '<' >>.
2825
2826 If the filename begins with C<'|'>, the filename is interpreted as a
2827 command to which output is to be piped, and if the filename ends with a
2828 C<'|'>, the filename is interpreted as a command which pipes output to
2829 us.  See L<perlipc/"Using open() for IPC">
2830 for more examples of this.  (You are not allowed to C<open> to a command
2831 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2832 and L<perlipc/"Bidirectional Communication with Another Process">
2833 for alternatives.)
2834
2835 For three or more arguments if MODE is C<'|-'>, the filename is
2836 interpreted as a command to which output is to be piped, and if MODE
2837 is C<'-|'>, the filename is interpreted as a command which pipes
2838 output to us.  In the 2-arguments (and 1-argument) form one should
2839 replace dash (C<'-'>) with the command.
2840 See L<perlipc/"Using open() for IPC"> for more examples of this.
2841 (You are not allowed to C<open> to a command that pipes both in I<and>
2842 out, but see L<IPC::Open2>, L<IPC::Open3>, and
2843 L<perlipc/"Bidirectional Communication"> for alternatives.)
2844
2845 In the three-or-more argument form of pipe opens, if LIST is specified
2846 (extra arguments after the command name) then LIST becomes arguments
2847 to the command invoked if the platform supports it.  The meaning of
2848 C<open> with more than three arguments for non-pipe modes is not yet
2849 specified. Experimental "layers" may give extra LIST arguments
2850 meaning.
2851
2852 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2853 and opening C<< '>-' >> opens STDOUT.
2854
2855 You may use the three-argument form of open to specify IO "layers"
2856 (sometimes also referred to as "disciplines") to be applied to the handle
2857 that affect how the input and output are processed (see L<open> and
2858 L<PerlIO> for more details). For example
2859
2860   open(FH, "<:utf8", "file")
2861
2862 will open the UTF-8 encoded file containing Unicode characters,
2863 see L<perluniintro>. (Note that if layers are specified in the
2864 three-arg form then default layers set by the C<open> pragma are
2865 ignored.)
2866
2867 Open returns nonzero upon success, the undefined value otherwise.  If
2868 the C<open> involved a pipe, the return value happens to be the pid of
2869 the subprocess.
2870
2871 If you're running Perl on a system that distinguishes between text
2872 files and binary files, then you should check out L</binmode> for tips
2873 for dealing with this.  The key distinction between systems that need
2874 C<binmode> and those that don't is their text file formats.  Systems
2875 like Unix, Mac OS, and Plan 9, which delimit lines with a single
2876 character, and which encode that character in C as C<"\n">, do not
2877 need C<binmode>.  The rest need it.
2878
2879 When opening a file, it's usually a bad idea to continue normal execution
2880 if the request failed, so C<open> is frequently used in connection with
2881 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2882 where you want to make a nicely formatted error message (but there are
2883 modules that can help with that problem)) you should always check
2884 the return value from opening a file.  The infrequent exception is when
2885 working with an unopened filehandle is actually what you want to do.
2886
2887 As a special case the 3 arg form with a read/write mode and the third
2888 argument being C<undef>:
2889
2890     open(TMP, "+>", undef) or die ...
2891
2892 opens a filehandle to an anonymous temporary file.  Also using "+<"
2893 works for symmetry, but you really should consider writing something
2894 to the temporary file first.  You will need to seek() to do the
2895 reading.
2896
2897 File handles can be opened to "in memory" files held in Perl scalars via:
2898
2899     open($fh, '>', \$variable) || ..
2900
2901 Though if you try to re-open C<STDOUT> or C<STDERR> as an "in memory"
2902 file, you have to close it first:
2903
2904     close STDOUT;
2905     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
2906
2907 Examples:
2908
2909     $ARTICLE = 100;
2910     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2911     while (<ARTICLE>) {...
2912
2913     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
2914     # if the open fails, output is discarded
2915
2916     open(DBASE, '+<', 'dbase.mine')             # open for update
2917         or die "Can't open 'dbase.mine' for update: $!";
2918
2919     open(DBASE, '+<dbase.mine')                 # ditto
2920         or die "Can't open 'dbase.mine' for update: $!";
2921
2922     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
2923         or die "Can't start caesar: $!";
2924
2925     open(ARTICLE, "caesar <$article |")         # ditto
2926         or die "Can't start caesar: $!";
2927
2928     open(EXTRACT, "|sort >/tmp/Tmp$$")          # $$ is our process id
2929         or die "Can't start sort: $!";
2930
2931     # in memory files
2932     open(MEMORY,'>', \$var)
2933         or die "Can't open memory file: $!";
2934     print MEMORY "foo!\n";                      # output will end up in $var
2935
2936     # process argument list of files along with any includes
2937
2938     foreach $file (@ARGV) {
2939         process($file, 'fh00');
2940     }
2941
2942     sub process {
2943         my($filename, $input) = @_;
2944         $input++;               # this is a string increment
2945         unless (open($input, $filename)) {
2946             print STDERR "Can't open $filename: $!\n";
2947             return;
2948         }
2949
2950         local $_;
2951         while (<$input>) {              # note use of indirection
2952             if (/^#include "(.*)"/) {
2953                 process($1, $input);
2954                 next;
2955             }
2956             #...                # whatever
2957         }
2958     }
2959
2960 You may also, in the Bourne shell tradition, specify an EXPR beginning
2961 with C<< '>&' >>, in which case the rest of the string is interpreted
2962 as the name of a filehandle (or file descriptor, if numeric) to be
2963 duped (as L<dup(2)>) and opened.  You may use C<&> after C<< > >>,
2964 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
2965 The mode you specify should match the mode of the original filehandle.
2966 (Duping a filehandle does not take into account any existing contents
2967 of IO buffers.) If you use the 3 arg form then you can pass either a
2968 number, the name of a filehandle or the normal "reference to a glob".
2969
2970 Here is a script that saves, redirects, and restores C<STDOUT> and
2971 C<STDERR> using various methods:
2972
2973     #!/usr/bin/perl
2974     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
2975     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
2976
2977     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
2978     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
2979
2980     select STDERR; $| = 1;      # make unbuffered
2981     select STDOUT; $| = 1;      # make unbuffered
2982
2983     print STDOUT "stdout 1\n";  # this works for
2984     print STDERR "stderr 1\n";  # subprocesses too
2985
2986     close STDOUT;
2987     close STDERR;
2988
2989     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
2990     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
2991
2992     print STDOUT "stdout 2\n";
2993     print STDERR "stderr 2\n";
2994
2995 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
2996 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
2997 that file descriptor (and not call L<dup(2)>); this is more
2998 parsimonious of file descriptors.  For example:
2999
3000     # open for input, reusing the fileno of $fd
3001     open(FILEHANDLE, "<&=$fd")
3002
3003 or
3004
3005     open(FILEHANDLE, "<&=", $fd)
3006
3007 or
3008
3009     # open for append, using the fileno of OLDFH
3010     open(FH, ">>&=", OLDFH)
3011
3012 or
3013
3014     open(FH, ">>&=OLDFH")
3015
3016 Being parsimonious on filehandles is also useful (besides being
3017 parsimonious) for example when something is dependent on file
3018 descriptors, like for example locking using flock().  If you do just
3019 C<< open(A, '>>&B') >>, the filehandle A will not have the same file
3020 descriptor as B, and therefore flock(A) will not flock(B), and vice
3021 versa.  But with C<< open(A, '>>&=B') >> the filehandles will share
3022 the same file descriptor.
3023
3024 Note that if you are using Perls older than 5.8.0, Perl will be using
3025 the standard C libraries' fdopen() to implement the "=" functionality.
3026 On many UNIX systems fdopen() fails when file descriptors exceed a
3027 certain value, typically 255.  For Perls 5.8.0 and later, PerlIO is
3028 most often the default.
3029
3030 You can see whether Perl has been compiled with PerlIO or not by
3031 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
3032 is C<define>, you have PerlIO, otherwise you don't.
3033
3034 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
3035 with 2-arguments (or 1-argument) form of open(), then
3036 there is an implicit fork done, and the return value of open is the pid
3037 of the child within the parent process, and C<0> within the child
3038 process.  (Use C<defined($pid)> to determine whether the open was successful.)
3039 The filehandle behaves normally for the parent, but i/o to that
3040 filehandle is piped from/to the STDOUT/STDIN of the child process.
3041 In the child process the filehandle isn't opened--i/o happens from/to
3042 the new STDOUT or STDIN.  Typically this is used like the normal
3043 piped open when you want to exercise more control over just how the
3044 pipe command gets executed, such as when you are running setuid, and
3045 don't want to have to scan shell commands for metacharacters.
3046 The following triples are more or less equivalent:
3047
3048     open(FOO, "|tr '[a-z]' '[A-Z]'");
3049     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
3050     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
3051     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
3052
3053     open(FOO, "cat -n '$file'|");
3054     open(FOO, '-|', "cat -n '$file'");
3055     open(FOO, '-|') || exec 'cat', '-n', $file;
3056     open(FOO, '-|', "cat", '-n', $file);
3057
3058 The last example in each block shows the pipe as "list form", which is
3059 not yet supported on all platforms.  A good rule of thumb is that if
3060 your platform has true C<fork()> (in other words, if your platform is
3061 UNIX) you can use the list form.
3062
3063 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3064
3065 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3066 output before any operation that may do a fork, but this may not be
3067 supported on some platforms (see L<perlport>).  To be safe, you may need
3068 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3069 of C<IO::Handle> on any open handles.
3070
3071 On systems that support a close-on-exec flag on files, the flag will
3072 be set for the newly opened file descriptor as determined by the value
3073 of $^F.  See L<perlvar/$^F>.
3074
3075 Closing any piped filehandle causes the parent process to wait for the
3076 child to finish, and returns the status value in C<$?>.
3077
3078 The filename passed to 2-argument (or 1-argument) form of open() will
3079 have leading and trailing whitespace deleted, and the normal
3080 redirection characters honored.  This property, known as "magic open",
3081 can often be used to good effect.  A user could specify a filename of
3082 F<"rsh cat file |">, or you could change certain filenames as needed:
3083
3084     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3085     open(FH, $filename) or die "Can't open $filename: $!";
3086
3087 Use 3-argument form to open a file with arbitrary weird characters in it,
3088
3089     open(FOO, '<', $file);
3090
3091 otherwise it's necessary to protect any leading and trailing whitespace:
3092
3093     $file =~ s#^(\s)#./$1#;
3094     open(FOO, "< $file\0");
3095
3096 (this may not work on some bizarre filesystems).  One should
3097 conscientiously choose between the I<magic> and 3-arguments form
3098 of open():
3099
3100     open IN, $ARGV[0];
3101
3102 will allow the user to specify an argument of the form C<"rsh cat file |">,
3103 but will not work on a filename which happens to have a trailing space, while
3104
3105     open IN, '<', $ARGV[0];
3106
3107 will have exactly the opposite restrictions.
3108
3109 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3110 should use the C<sysopen> function, which involves no such magic (but
3111 may use subtly different filemodes than Perl open(), which is mapped
3112 to C fopen()).  This is
3113 another way to protect your filenames from interpretation.  For example:
3114
3115     use IO::Handle;
3116     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3117         or die "sysopen $path: $!";
3118     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3119     print HANDLE "stuff $$\n";
3120     seek(HANDLE, 0, 0);
3121     print "File contains: ", <HANDLE>;
3122
3123 Using the constructor from the C<IO::Handle> package (or one of its
3124 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3125 filehandles that have the scope of whatever variables hold references to
3126 them, and automatically close whenever and however you leave that scope:
3127
3128     use IO::File;
3129     #...
3130     sub read_myfile_munged {
3131         my $ALL = shift;
3132         my $handle = new IO::File;
3133         open($handle, "myfile") or die "myfile: $!";
3134         $first = <$handle>
3135             or return ();     # Automatically closed here.
3136         mung $first or die "mung failed";       # Or here.
3137         return $first, <$handle> if $ALL;       # Or here.
3138         $first;                                 # Or here.
3139     }
3140
3141 See L</seek> for some details about mixing reading and writing.
3142
3143 =item opendir DIRHANDLE,EXPR
3144
3145 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3146 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3147 DIRHANDLE may be an expression whose value can be used as an indirect
3148 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3149 scalar variable (or array or hash element), the variable is assigned a
3150 reference to a new anonymous dirhandle.
3151 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3152
3153 =item ord EXPR
3154
3155 =item ord
3156
3157 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3158 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3159 uses C<$_>.
3160
3161 For the reverse, see L</chr>.
3162 See L<perlunicode> and L<encoding> for more about Unicode.
3163
3164 =item our EXPR
3165
3166 =item our EXPR TYPE
3167
3168 =item our EXPR : ATTRS
3169
3170 =item our TYPE EXPR : ATTRS
3171
3172 An C<our> declares the listed variables to be valid globals within
3173 the enclosing block, file, or C<eval>.  That is, it has the same
3174 scoping rules as a "my" declaration, but does not create a local
3175 variable.  If more than one value is listed, the list must be placed
3176 in parentheses.  The C<our> declaration has no semantic effect unless
3177 "use strict vars" is in effect, in which case it lets you use the
3178 declared global variable without qualifying it with a package name.
3179 (But only within the lexical scope of the C<our> declaration.  In this
3180 it differs from "use vars", which is package scoped.)
3181
3182 An C<our> declaration declares a global variable that will be visible
3183 across its entire lexical scope, even across package boundaries.  The
3184 package in which the variable is entered is determined at the point
3185 of the declaration, not at the point of use.  This means the following
3186 behavior holds:
3187
3188     package Foo;
3189     our $bar;           # declares $Foo::bar for rest of lexical scope
3190     $bar = 20;
3191
3192     package Bar;
3193     print $bar;         # prints 20
3194
3195 Multiple C<our> declarations in the same lexical scope are allowed
3196 if they are in different packages.  If they happened to be in the same
3197 package, Perl will emit warnings if you have asked for them.
3198
3199     use warnings;
3200     package Foo;
3201     our $bar;           # declares $Foo::bar for rest of lexical scope
3202     $bar = 20;
3203
3204     package Bar;
3205     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3206     print $bar;         # prints 30
3207
3208     our $bar;           # emits warning
3209
3210 An C<our> declaration may also have a list of attributes associated
3211 with it.
3212
3213 The exact semantics and interface of TYPE and ATTRS are still
3214 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3215 and attributes are handled using the C<attributes> pragma, or starting
3216 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3217 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3218 L<attributes>, and L<Attribute::Handlers>.
3219
3220 The only currently recognized C<our()> attribute is C<unique> which
3221 indicates that a single copy of the global is to be used by all
3222 interpreters should the program happen to be running in a
3223 multi-interpreter environment. (The default behaviour would be for
3224 each interpreter to have its own copy of the global.)  Examples:
3225
3226     our @EXPORT : unique = qw(foo);
3227     our %EXPORT_TAGS : unique = (bar => [qw(aa bb cc)]);
3228     our $VERSION : unique = "1.00";
3229
3230 Note that this attribute also has the effect of making the global
3231 readonly when the first new interpreter is cloned (for example,
3232 when the first new thread is created).
3233
3234 Multi-interpreter environments can come to being either through the
3235 fork() emulation on Windows platforms, or by embedding perl in a
3236 multi-threaded application.  The C<unique> attribute does nothing in
3237 all other environments.
3238
3239 =item pack TEMPLATE,LIST
3240
3241 Takes a LIST of values and converts it into a string using the rules
3242 given by the TEMPLATE.  The resulting string is the concatenation of
3243 the converted values.  Typically, each converted value looks
3244 like its machine-level representation.  For example, on 32-bit machines
3245 a converted integer may be represented by a sequence of 4 bytes.
3246
3247 The TEMPLATE is a sequence of characters that give the order and type
3248 of values, as follows:
3249
3250     a   A string with arbitrary binary data, will be null padded.
3251     A   A text (ASCII) string, will be space padded.
3252     Z   A null terminated (ASCIZ) string, will be null padded.
3253
3254     b   A bit string (ascending bit order inside each byte, like vec()).
3255     B   A bit string (descending bit order inside each byte).
3256     h   A hex string (low nybble first).
3257     H   A hex string (high nybble first).
3258
3259     c   A signed char value.
3260     C   An unsigned char value.  Only does bytes.  See U for Unicode.
3261
3262     s   A signed short value.
3263     S   An unsigned short value.
3264           (This 'short' is _exactly_ 16 bits, which may differ from
3265            what a local C compiler calls 'short'.  If you want
3266            native-length shorts, use the '!' suffix.)
3267
3268     i   A signed integer value.
3269     I   An unsigned integer value.
3270           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3271            size depends on what a local C compiler calls 'int',
3272            and may even be larger than the 'long' described in
3273            the next item.)
3274
3275     l   A signed long value.
3276     L   An unsigned long value.
3277           (This 'long' is _exactly_ 32 bits, which may differ from
3278            what a local C compiler calls 'long'.  If you want
3279            native-length longs, use the '!' suffix.)
3280
3281     n   An unsigned short in "network" (big-endian) order.
3282     N   An unsigned long in "network" (big-endian) order.
3283     v   An unsigned short in "VAX" (little-endian) order.
3284     V   An unsigned long in "VAX" (little-endian) order.
3285           (These 'shorts' and 'longs' are _exactly_ 16 bits and
3286            _exactly_ 32 bits, respectively.)
3287
3288     q   A signed quad (64-bit) value.
3289     Q   An unsigned quad value.
3290           (Quads are available only if your system supports 64-bit
3291            integer values _and_ if Perl has been compiled to support those.
3292            Causes a fatal error otherwise.)
3293
3294     j   A signed integer value (a Perl internal integer, IV).
3295     J   An unsigned integer value (a Perl internal unsigned integer, UV).
3296
3297     f   A single-precision float in the native format.
3298     d   A double-precision float in the native format.
3299
3300     F   A floating point value in the native native format
3301            (a Perl internal floating point value, NV).
3302     D   A long double-precision float in the native format.
3303           (Long doubles are available only if your system supports long
3304            double values _and_ if Perl has been compiled to support those.
3305            Causes a fatal error otherwise.)
3306
3307     p   A pointer to a null-terminated string.
3308     P   A pointer to a structure (fixed-length string).
3309
3310     u   A uuencoded string.
3311     U   A Unicode character number.  Encodes to UTF-8 internally
3312         (or UTF-EBCDIC in EBCDIC platforms).
3313
3314     w   A BER compressed integer.  Its bytes represent an unsigned
3315         integer in base 128, most significant digit first, with as
3316         few digits as possible.  Bit eight (the high bit) is set
3317         on each byte except the last.
3318
3319     x   A null byte.
3320     X   Back up a byte.
3321     @   Null fill to absolute position, counted from the start of
3322         the innermost ()-group.
3323     (   Start of a ()-group.
3324
3325 The following rules apply:
3326
3327 =over 8
3328
3329 =item *
3330
3331 Each letter may optionally be followed by a number giving a repeat
3332 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3333 C<H>, C<@>, C<x>, C<X> and C<P> the pack function will gobble up that
3334 many values from the LIST.  A C<*> for the repeat count means to use
3335 however many items are left, except for C<@>, C<x>, C<X>, where it is
3336 equivalent to C<0>, and C<u>, where it is equivalent to 1 (or 45, what
3337 is the same).  A numeric repeat count may optionally be enclosed in
3338 brackets, as in C<pack 'C[80]', @arr>.
3339
3340 One can replace the numeric repeat count by a template enclosed in brackets;
3341 then the packed length of this template in bytes is used as a count.
3342 For example, C<x[L]> skips a long (it skips the number of bytes in a long);
3343 the template C<$t X[$t] $t> unpack()s twice what $t unpacks.
3344 If the template in brackets contains alignment commands (such as C<x![d]>),
3345 its packed length is calculated as if the start of the template has the maximal
3346 possible alignment.
3347
3348 When used with C<Z>, C<*> results in the addition of a trailing null
3349 byte (so the packed result will be one longer than the byte C<length>
3350 of the item).
3351
3352 The repeat count for C<u> is interpreted as the maximal number of bytes
3353 to encode per line of output, with 0 and 1 replaced by 45.
3354
3355 =item *
3356
3357 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3358 string of length count, padding with nulls or spaces as necessary.  When
3359 unpacking, C<A> strips trailing spaces and nulls, C<Z> strips everything
3360 after the first null, and C<a> returns data verbatim.  When packing,
3361 C<a>, and C<Z> are equivalent.
3362
3363 If the value-to-pack is too long, it is truncated.  If too long and an
3364 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3365 by a null byte.  Thus C<Z> always packs a trailing null byte under
3366 all circumstances.
3367
3368 =item *
3369
3370 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3371 Each byte of the input field of pack() generates 1 bit of the result.
3372 Each result bit is based on the least-significant bit of the corresponding
3373 input byte, i.e., on C<ord($byte)%2>.  In particular, bytes C<"0"> and
3374 C<"1"> generate bits 0 and 1, as do bytes C<"\0"> and C<"\1">.
3375
3376 Starting from the beginning of the input string of pack(), each 8-tuple
3377 of bytes is converted to 1 byte of output.  With format C<b>
3378 the first byte of the 8-tuple determines the least-significant bit of a
3379 byte, and with format C<B> it determines the most-significant bit of
3380 a byte.
3381
3382 If the length of the input string is not exactly divisible by 8, the
3383 remainder is packed as if the input string were padded by null bytes
3384 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3385
3386 If the input string of pack() is longer than needed, extra bytes are ignored.
3387 A C<*> for the repeat count of pack() means to use all the bytes of
3388 the input field.  On unpack()ing the bits are converted to a string
3389 of C<"0">s and C<"1">s.
3390
3391 =item *
3392
3393 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3394 representable as hexadecimal digits, 0-9a-f) long.
3395
3396 Each byte of the input field of pack() generates 4 bits of the result.
3397 For non-alphabetical bytes the result is based on the 4 least-significant
3398 bits of the input byte, i.e., on C<ord($byte)%16>.  In particular,
3399 bytes C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3400 C<"\0"> and C<"\1">.  For bytes C<"a".."f"> and C<"A".."F"> the result
3401 is compatible with the usual hexadecimal digits, so that C<"a"> and
3402 C<"A"> both generate the nybble C<0xa==10>.  The result for bytes
3403 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3404
3405 Starting from the beginning of the input string of pack(), each pair
3406 of bytes is converted to 1 byte of output.  With format C<h> the
3407 first byte of the pair determines the least-significant nybble of the
3408 output byte, and with format C<H> it determines the most-significant
3409 nybble.
3410
3411 If the length of the input string is not even, it behaves as if padded
3412 by a null byte at the end.  Similarly, during unpack()ing the "extra"
3413 nybbles are ignored.
3414
3415 If the input string of pack() is longer than needed, extra bytes are ignored.
3416 A C<*> for the repeat count of pack() means to use all the bytes of
3417 the input field.  On unpack()ing the bits are converted to a string
3418 of hexadecimal digits.
3419
3420 =item *
3421
3422 The C<p> type packs a pointer to a null-terminated string.  You are
3423 responsible for ensuring the string is not a temporary value (which can
3424 potentially get deallocated before you get around to using the packed result).
3425 The C<P> type packs a pointer to a structure of the size indicated by the
3426 length.  A NULL pointer is created if the corresponding value for C<p> or
3427 C<P> is C<undef>, similarly for unpack().
3428
3429 =item *
3430
3431 The C</> template character allows packing and unpacking of strings where
3432 the packed structure contains a byte count followed by the string itself.
3433 You write I<length-item>C</>I<string-item>.
3434
3435 The I<length-item> can be any C<pack> template letter, and describes
3436 how the length value is packed.  The ones likely to be of most use are
3437 integer-packing ones like C<n> (for Java strings), C<w> (for ASN.1 or
3438 SNMP) and C<N> (for Sun XDR).
3439
3440 For C<pack>, the I<string-item> must, at present, be C<"A*">, C<"a*"> or
3441 C<"Z*">. For C<unpack> the length of the string is obtained from the
3442 I<length-item>, but if you put in the '*' it will be ignored. For all other
3443 codes, C<unpack> applies the length value to the next item, which must not
3444 have a repeat count.
3445
3446     unpack 'C/a', "\04Gurusamy";        gives 'Guru'
3447     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond','J')
3448     pack 'n/a* w/a*','hello,','world';  gives "\000\006hello,\005world"
3449
3450 The I<length-item> is not returned explicitly from C<unpack>.
3451
3452 Adding a count to the I<length-item> letter is unlikely to do anything
3453 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3454 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3455 which Perl does not regard as legal in numeric strings.
3456
3457 =item *
3458
3459 The integer types C<s>, C<S>, C<l>, and C<L> may be
3460 immediately followed by a C<!> suffix to signify native shorts or
3461 longs--as you can see from above for example a bare C<l> does mean
3462 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3463 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3464 see whether using C<!> makes any difference by
3465
3466         print length(pack("s")), " ", length(pack("s!")), "\n";
3467         print length(pack("l")), " ", length(pack("l!")), "\n";
3468
3469 C<i!> and C<I!> also work but only because of completeness;
3470 they are identical to C<i> and C<I>.
3471
3472 The actual sizes (in bytes) of native shorts, ints, longs, and long
3473 longs on the platform where Perl was built are also available via
3474 L<Config>:
3475
3476        use Config;
3477        print $Config{shortsize},    "\n";
3478        print $Config{intsize},      "\n";
3479        print $Config{longsize},     "\n";
3480        print $Config{longlongsize}, "\n";
3481
3482 (The C<$Config{longlongsize}> will be undefined if your system does
3483 not support long longs.)
3484
3485 =item *
3486
3487 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J>
3488 are inherently non-portable between processors and operating systems
3489 because they obey the native byteorder and endianness.  For example a
3490 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3491 (arranged in and handled by the CPU registers) into bytes as
3492
3493         0x12 0x34 0x56 0x78     # big-endian
3494         0x78 0x56 0x34 0x12     # little-endian
3495
3496 Basically, the Intel and VAX CPUs are little-endian, while everybody
3497 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3498 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3499 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3500 mode.
3501
3502 The names `big-endian' and `little-endian' are comic references to
3503 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3504 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3505 the egg-eating habits of the Lilliputians.
3506
3507 Some systems may have even weirder byte orders such as
3508
3509         0x56 0x78 0x12 0x34
3510         0x34 0x12 0x78 0x56
3511
3512 You can see your system's preference with
3513
3514         print join(" ", map { sprintf "%#02x", $_ }
3515                             unpack("C*",pack("L",0x12345678))), "\n";
3516
3517 The byteorder on the platform where Perl was built is also available
3518 via L<Config>:
3519
3520         use Config;
3521         print $Config{byteorder}, "\n";
3522
3523 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3524 and C<'87654321'> are big-endian.
3525
3526 If you want portable packed integers use the formats C<n>, C<N>,
3527 C<v>, and C<V>, their byte endianness and size are known.
3528 See also L<perlport>.
3529
3530 =item *
3531
3532 Real numbers (floats and doubles) are in the native machine format only;
3533 due to the multiplicity of floating formats around, and the lack of a
3534 standard "network" representation, no facility for interchange has been
3535 made.  This means that packed floating point data written on one machine
3536 may not be readable on another - even if both use IEEE floating point
3537 arithmetic (as the endian-ness of the memory representation is not part
3538 of the IEEE spec).  See also L<perlport>.
3539
3540 Note that Perl uses doubles internally for all numeric calculation, and
3541 converting from double into float and thence back to double again will
3542 lose precision (i.e., C<unpack("f", pack("f", $foo)>) will not in general
3543 equal $foo).
3544
3545 =item *
3546
3547 If the pattern begins with a C<U>, the resulting string will be
3548 treated as UTF-8-encoded Unicode. You can force UTF-8 encoding on in a
3549 string with an initial C<U0>, and the bytes that follow will be
3550 interpreted as Unicode characters. If you don't want this to happen,
3551 you can begin your pattern with C<C0> (or anything else) to force Perl
3552 not to UTF-8 encode your string, and then follow this with a C<U*>
3553 somewhere in your pattern.
3554
3555 =item *
3556
3557 You must yourself do any alignment or padding by inserting for example
3558 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3559 could know where the bytes are going to or coming from.  Therefore
3560 C<pack> (and C<unpack>) handle their output and input as flat
3561 sequences of bytes.
3562
3563 =item *
3564
3565 A ()-group is a sub-TEMPLATE enclosed in parentheses.  A group may
3566 take a repeat count, both as postfix, and for unpack() also via the C</>
3567 template character. Within each repetition of a group, positioning with
3568 C<@> starts again at 0. Therefore, the result of
3569
3570     pack( '@1A((@2A)@3A)', 'a', 'b', 'c' )
3571
3572 is the string "\0a\0\0bc".
3573
3574
3575 =item *
3576
3577 C<x> and C<X> accept C<!> modifier.  In this case they act as
3578 alignment commands: they jump forward/back to the closest position
3579 aligned at a multiple of C<count> bytes.  For example, to pack() or
3580 unpack() C's C<struct {char c; double d; char cc[2]}> one may need to
3581 use the template C<C x![d] d C[2]>; this assumes that doubles must be
3582 aligned on the double's size.
3583
3584 For alignment commands C<count> of 0 is equivalent to C<count> of 1;
3585 both result in no-ops.
3586
3587 =item *
3588
3589 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3590 White space may be used to separate pack codes from each other, but
3591 a C<!> modifier and a repeat count must follow immediately.
3592
3593 =item *
3594
3595 If TEMPLATE requires more arguments to pack() than actually given, pack()
3596 assumes additional C<""> arguments.  If TEMPLATE requires less arguments
3597 to pack() than actually given, extra arguments are ignored.
3598
3599 =back
3600
3601 Examples:
3602
3603     $foo = pack("CCCC",65,66,67,68);
3604     # foo eq "ABCD"
3605     $foo = pack("C4",65,66,67,68);
3606     # same thing
3607     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3608     # same thing with Unicode circled letters
3609
3610     $foo = pack("ccxxcc",65,66,67,68);
3611     # foo eq "AB\0\0CD"
3612
3613     # note: the above examples featuring "C" and "c" are true
3614     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3615     # and UTF-8.  In EBCDIC the first example would be
3616     # $foo = pack("CCCC",193,194,195,196);
3617
3618     $foo = pack("s2",1,2);
3619     # "\1\0\2\0" on little-endian
3620     # "\0\1\0\2" on big-endian
3621
3622     $foo = pack("a4","abcd","x","y","z");
3623     # "abcd"
3624
3625     $foo = pack("aaaa","abcd","x","y","z");
3626     # "axyz"
3627
3628     $foo = pack("a14","abcdefg");
3629     # "abcdefg\0\0\0\0\0\0\0"
3630
3631     $foo = pack("i9pl", gmtime);
3632     # a real struct tm (on my system anyway)
3633
3634     $utmp_template = "Z8 Z8 Z16 L";
3635     $utmp = pack($utmp_template, @utmp1);
3636     # a struct utmp (BSDish)
3637
3638     @utmp2 = unpack($utmp_template, $utmp);
3639     # "@utmp1" eq "@utmp2"
3640
3641     sub bintodec {
3642         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3643     }
3644
3645     $foo = pack('sx2l', 12, 34);
3646     # short 12, two zero bytes padding, long 34
3647     $bar = pack('s@4l', 12, 34);
3648     # short 12, zero fill to position 4, long 34
3649     # $foo eq $bar
3650
3651 The same template may generally also be used in unpack().
3652
3653 =item package NAMESPACE
3654
3655 =item package
3656
3657 Declares the compilation unit as being in the given namespace.  The scope
3658 of the package declaration is from the declaration itself through the end
3659 of the enclosing block, file, or eval (the same as the C<my> operator).
3660 All further unqualified dynamic identifiers will be in this namespace.
3661 A package statement affects only dynamic variables--including those
3662 you've used C<local> on--but I<not> lexical variables, which are created
3663 with C<my>.  Typically it would be the first declaration in a file to
3664 be included by the C<require> or C<use> operator.  You can switch into a
3665 package in more than one place; it merely influences which symbol table
3666 is used by the compiler for the rest of that block.  You can refer to
3667 variables and filehandles in other packages by prefixing the identifier
3668 with the package name and a double colon:  C<$Package::Variable>.
3669 If the package name is null, the C<main> package as assumed.  That is,
3670 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3671 still seen in older code).
3672
3673 If NAMESPACE is omitted, then there is no current package, and all
3674 identifiers must be fully qualified or lexicals.  However, you are
3675 strongly advised not to make use of this feature. Its use can cause
3676 unexpected behaviour, even crashing some versions of Perl. It is
3677 deprecated, and will be removed from a future release.
3678
3679 See L<perlmod/"Packages"> for more information about packages, modules,
3680 and classes.  See L<perlsub> for other scoping issues.
3681
3682 =item pipe READHANDLE,WRITEHANDLE
3683
3684 Opens a pair of connected pipes like the corresponding system call.
3685 Note that if you set up a loop of piped processes, deadlock can occur
3686 unless you are very careful.  In addition, note that Perl's pipes use
3687 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3688 after each command, depending on the application.
3689
3690 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3691 for examples of such things.
3692
3693 On systems that support a close-on-exec flag on files, the flag will be set
3694 for the newly opened file descriptors as determined by the value of $^F.
3695 See L<perlvar/$^F>.
3696
3697 =item pop ARRAY
3698
3699 =item pop
3700
3701 Pops and returns the last value of the array, shortening the array by
3702 one element.  Has an effect similar to
3703
3704     $ARRAY[$#ARRAY--]
3705
3706 If there are no elements in the array, returns the undefined value
3707 (although this may happen at other times as well).  If ARRAY is
3708 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3709 array in subroutines, just like C<shift>.
3710
3711 =item pos SCALAR
3712
3713 =item pos
3714
3715 Returns the offset of where the last C<m//g> search left off for the variable
3716 in question (C<$_> is used when the variable is not specified).  May be
3717 modified to change that offset.  Such modification will also influence
3718 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
3719 L<perlop>.
3720
3721 =item print FILEHANDLE LIST
3722
3723 =item print LIST
3724
3725 =item print
3726
3727 Prints a string or a list of strings.  Returns true if successful.
3728 FILEHANDLE may be a scalar variable name, in which case the variable
3729 contains the name of or a reference to the filehandle, thus introducing
3730 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3731 the next token is a term, it may be misinterpreted as an operator
3732 unless you interpose a C<+> or put parentheses around the arguments.)
3733 If FILEHANDLE is omitted, prints by default to standard output (or
3734 to the last selected output channel--see L</select>).  If LIST is
3735 also omitted, prints C<$_> to the currently selected output channel.
3736 To set the default output channel to something other than STDOUT
3737 use the select operation.  The current value of C<$,> (if any) is
3738 printed between each LIST item.  The current value of C<$\> (if
3739 any) is printed after the entire LIST has been printed.  Because
3740 print takes a LIST, anything in the LIST is evaluated in list
3741 context, and any subroutine that you call will have one or more of
3742 its expressions evaluated in list context.  Also be careful not to
3743 follow the print keyword with a left parenthesis unless you want
3744 the corresponding right parenthesis to terminate the arguments to
3745 the print--interpose a C<+> or put parentheses around all the
3746 arguments.
3747
3748 Note that if you're storing FILEHANDLES in an array or other expression,
3749 you will have to use a block returning its value instead:
3750
3751     print { $files[$i] } "stuff\n";
3752     print { $OK ? STDOUT : STDERR } "stuff\n";
3753
3754 =item printf FILEHANDLE FORMAT, LIST
3755
3756 =item printf FORMAT, LIST
3757
3758 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3759 (the output record separator) is not appended.  The first argument
3760 of the list will be interpreted as the C<printf> format. See C<sprintf>
3761 for an explanation of the format argument. If C<use locale> is in effect,
3762 the character used for the decimal point in formatted real numbers is
3763 affected by the LC_NUMERIC locale.  See L<perllocale>.
3764
3765 Don't fall into the trap of using a C<printf> when a simple
3766 C<print> would do.  The C<print> is more efficient and less
3767 error prone.
3768
3769 =item prototype FUNCTION
3770
3771 Returns the prototype of a function as a string (or C<undef> if the
3772 function has no prototype).  FUNCTION is a reference to, or the name of,
3773 the function whose prototype you want to retrieve.
3774
3775 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
3776 name for Perl builtin.  If the builtin is not I<overridable> (such as
3777 C<qw//>) or its arguments cannot be expressed by a prototype (such as
3778 C<system>) returns C<undef> because the builtin does not really behave
3779 like a Perl function.  Otherwise, the string describing the equivalent
3780 prototype is returned.
3781
3782 =item push ARRAY,LIST
3783
3784 Treats ARRAY as a stack, and pushes the values of LIST
3785 onto the end of ARRAY.  The length of ARRAY increases by the length of
3786 LIST.  Has the same effect as
3787
3788     for $value (LIST) {
3789         $ARRAY[++$#ARRAY] = $value;
3790     }
3791
3792 but is more efficient.  Returns the new number of elements in the array.
3793
3794 =item q/STRING/
3795
3796 =item qq/STRING/
3797
3798 =item qr/STRING/
3799
3800 =item qx/STRING/
3801
3802 =item qw/STRING/
3803
3804 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
3805
3806 =item quotemeta EXPR
3807
3808 =item quotemeta
3809
3810 Returns the value of EXPR with all non-"word"
3811 characters backslashed.  (That is, all characters not matching
3812 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
3813 returned string, regardless of any locale settings.)
3814 This is the internal function implementing
3815 the C<\Q> escape in double-quoted strings.
3816
3817 If EXPR is omitted, uses C<$_>.
3818
3819 =item rand EXPR
3820
3821 =item rand
3822
3823 Returns a random fractional number greater than or equal to C<0> and less
3824 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
3825 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
3826 also special-cased as C<1> - this has not been documented before perl 5.8.0
3827 and is subject to change in future versions of perl.  Automatically calls
3828 C<srand> unless C<srand> has already been called.  See also C<srand>.
3829
3830 Apply C<int()> to the value returned by C<rand()> if you want random
3831 integers instead of random fractional numbers.  For example,
3832
3833     int(rand(10))
3834
3835 returns a random integer between C<0> and C<9>, inclusive.
3836
3837 (Note: If your rand function consistently returns numbers that are too
3838 large or too small, then your version of Perl was probably compiled
3839 with the wrong number of RANDBITS.)
3840
3841 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
3842
3843 =item read FILEHANDLE,SCALAR,LENGTH
3844
3845 Attempts to read LENGTH I<characters> of data into variable SCALAR
3846 from the specified FILEHANDLE.  Returns the number of characters
3847 actually read, C<0> at end of file, or undef if there was an error (in
3848 the latter case C<$!> is also set).  SCALAR will be grown or shrunk 
3849 so that the last character actually read is the last character of the
3850 scalar after the read.
3851
3852 An OFFSET may be specified to place the read data at some place in the
3853 string other than the beginning.  A negative OFFSET specifies
3854 placement at that many characters counting backwards from the end of
3855 the string.  A positive OFFSET greater than the length of SCALAR
3856 results in the string being padded to the required size with C<"\0">
3857 bytes before the result of the read is appended.
3858
3859 The call is actually implemented in terms of either Perl's or system's
3860 fread() call.  To get a true read(2) system call, see C<sysread>.
3861
3862 Note the I<characters>: depending on the status of the filehandle,
3863 either (8-bit) bytes or characters are read.  By default all
3864 filehandles operate on bytes, but for example if the filehandle has
3865 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
3866 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
3867 characters, not bytes.  Similarly for the C<:encoding> pragma:
3868 in that case pretty much any characters can be read.
3869
3870 =item readdir DIRHANDLE
3871
3872 Returns the next directory entry for a directory opened by C<opendir>.
3873 If used in list context, returns all the rest of the entries in the
3874 directory.  If there are no more entries, returns an undefined value in
3875 scalar context or a null list in list context.
3876
3877 If you're planning to filetest the return values out of a C<readdir>, you'd
3878 better prepend the directory in question.  Otherwise, because we didn't
3879 C<chdir> there, it would have been testing the wrong file.
3880
3881     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
3882     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
3883     closedir DIR;
3884
3885 =item readline EXPR
3886
3887 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
3888 context, each call reads and returns the next line, until end-of-file is
3889 reached, whereupon the subsequent call returns undef.  In list context,
3890 reads until end-of-file is reached and returns a list of lines.  Note that
3891 the notion of "line" used here is however you may have defined it
3892 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
3893
3894 When C<$/> is set to C<undef>, when readline() is in scalar
3895 context (i.e. file slurp mode), and when an empty file is read, it
3896 returns C<''> the first time, followed by C<undef> subsequently.
3897
3898 This is the internal function implementing the C<< <EXPR> >>
3899 operator, but you can use it directly.  The C<< <EXPR> >>
3900 operator is discussed in more detail in L<perlop/"I/O Operators">.
3901
3902     $line = <STDIN>;
3903     $line = readline(*STDIN);           # same thing
3904
3905 If readline encounters an operating system error, C<$!> will be set with the
3906 corresponding error message.  It can be helpful to check C<$!> when you are
3907 reading from filehandles you don't trust, such as a tty or a socket.  The
3908 following example uses the operator form of C<readline>, and takes the necessary
3909 steps to ensure that C<readline> was successful.
3910
3911     for (;;) {
3912         undef $!;
3913         unless (defined( $line = <> )) {
3914             die $! if $!;
3915             last; # reached EOF
3916         }
3917         # ...
3918     }
3919
3920 =item readlink EXPR
3921
3922 =item readlink
3923
3924 Returns the value of a symbolic link, if symbolic links are
3925 implemented.  If not, gives a fatal error.  If there is some system
3926 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
3927 omitted, uses C<$_>.
3928
3929 =item readpipe EXPR
3930
3931 EXPR is executed as a system command.
3932 The collected standard output of the command is returned.
3933 In scalar context, it comes back as a single (potentially
3934 multi-line) string.  In list context, returns a list of lines
3935 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
3936 This is the internal function implementing the C<qx/EXPR/>
3937 operator, but you can use it directly.  The C<qx/EXPR/>
3938 operator is discussed in more detail in L<perlop/"I/O Operators">.
3939
3940 =item recv SOCKET,SCALAR,LENGTH,FLAGS
3941
3942 Receives a message on a socket.  Attempts to receive LENGTH characters
3943 of data into variable SCALAR from the specified SOCKET filehandle.
3944 SCALAR will be grown or shrunk to the length actually read.  Takes the
3945 same flags as the system call of the same name.  Returns the address
3946 of the sender if SOCKET's protocol supports this; returns an empty
3947 string otherwise.  If there's an error, returns the undefined value.
3948 This call is actually implemented in terms of recvfrom(2) system call.
3949 See L<perlipc/"UDP: Message Passing"> for examples.
3950
3951 Note the I<characters>: depending on the status of the socket, either
3952 (8-bit) bytes or characters are received.  By default all sockets
3953 operate on bytes, but for example if the socket has been changed using
3954 binmode() to operate with the C<:utf8> I/O layer (see the C<open>
3955 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
3956 characters, not bytes.  Similarly for the C<:encoding> pragma:
3957 in that case pretty much any characters can be read.
3958
3959 =item redo LABEL
3960
3961 =item redo
3962
3963 The C<redo> command restarts the loop block without evaluating the
3964 conditional again.  The C<continue> block, if any, is not executed.  If
3965 the LABEL is omitted, the command refers to the innermost enclosing
3966 loop.  This command is normally used by programs that want to lie to
3967 themselves about what was just input:
3968
3969     # a simpleminded Pascal comment stripper
3970     # (warning: assumes no { or } in strings)
3971     LINE: while (<STDIN>) {
3972         while (s|({.*}.*){.*}|$1 |) {}
3973         s|{.*}| |;
3974         if (s|{.*| |) {
3975             $front = $_;
3976             while (<STDIN>) {
3977                 if (/}/) {      # end of comment?
3978                     s|^|$front\{|;
3979                     redo LINE;
3980                 }
3981             }
3982         }
3983         print;
3984     }
3985
3986 C<redo> cannot be used to retry a block which returns a value such as
3987 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
3988 a grep() or map() operation.
3989
3990 Note that a block by itself is semantically identical to a loop
3991 that executes once.  Thus C<redo> inside such a block will effectively
3992 turn it into a looping construct.
3993
3994 See also L</continue> for an illustration of how C<last>, C<next>, and
3995 C<redo> work.
3996
3997 =item ref EXPR
3998
3999 =item ref
4000
4001 Returns a non-empty string if EXPR is a reference, the empty
4002 string otherwise. If EXPR
4003 is not specified, C<$_> will be used.  The value returned depends on the
4004 type of thing the reference is a reference to.
4005 Builtin types include:
4006
4007     SCALAR
4008     ARRAY
4009     HASH
4010     CODE
4011     REF
4012     GLOB
4013     LVALUE
4014
4015 If the referenced object has been blessed into a package, then that package
4016 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
4017
4018     if (ref($r) eq "HASH") {
4019         print "r is a reference to a hash.\n";
4020     }
4021     unless (ref($r)) {
4022         print "r is not a reference at all.\n";
4023     }
4024     if (UNIVERSAL::isa($r, "HASH")) {  # for subclassing
4025         print "r is a reference to something that isa hash.\n";
4026     }
4027
4028 See also L<perlref>.
4029
4030 =item rename OLDNAME,NEWNAME
4031
4032 Changes the name of a file; an existing file NEWNAME will be
4033 clobbered.  Returns true for success, false otherwise.
4034
4035 Behavior of this function varies wildly depending on your system
4036 implementation.  For example, it will usually not work across file system
4037 boundaries, even though the system I<mv> command sometimes compensates
4038 for this.  Other restrictions include whether it works on directories,
4039 open files, or pre-existing files.  Check L<perlport> and either the
4040 rename(2) manpage or equivalent system documentation for details.
4041
4042 =item require VERSION
4043
4044 =item require EXPR
4045
4046 =item require
4047
4048 Demands a version of Perl specified by VERSION, or demands some semantics
4049 specified by EXPR or by C<$_> if EXPR is not supplied.
4050
4051 VERSION may be either a numeric argument such as 5.006, which will be
4052 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
4053 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
4054 VERSION is greater than the version of the current Perl interpreter.
4055 Compare with L</use>, which can do a similar check at compile time.
4056
4057 Specifying VERSION as a literal of the form v5.6.1 should generally be
4058 avoided, because it leads to misleading error messages under earlier
4059 versions of Perl which do not support this syntax.  The equivalent numeric
4060 version should be used instead.
4061
4062     require v5.6.1;     # run time version check
4063     require 5.6.1;      # ditto
4064     require 5.006_001;  # ditto; preferred for backwards compatibility
4065
4066 Otherwise, demands that a library file be included if it hasn't already
4067 been included.  The file is included via the do-FILE mechanism, which is
4068 essentially just a variety of C<eval>.  Has semantics similar to the
4069 following subroutine:
4070
4071     sub require {
4072        my ($filename) = @_;
4073        if (exists $INC{$filename}) {
4074            return 1 if $INC{$filename};
4075            die "Compilation failed in require";
4076        }
4077        my ($realfilename,$result);
4078        ITER: {
4079            foreach $prefix (@INC) {
4080                $realfilename = "$prefix/$filename";
4081                if (-f $realfilename) {
4082                    $INC{$filename} = $realfilename;
4083                    $result = do $realfilename;
4084                    last ITER;
4085                }
4086            }
4087            die "Can't find $filename in \@INC";
4088        }
4089        if ($@) {
4090            $INC{$filename} = undef;
4091            die $@;
4092        } elsif (!$result) {
4093            delete $INC{$filename};
4094            die "$filename did not return true value";
4095        } else {
4096            return $result;
4097        }
4098     }
4099
4100 Note that the file will not be included twice under the same specified
4101 name.
4102
4103 The file must return true as the last statement to indicate
4104 successful execution of any initialization code, so it's customary to
4105 end such a file with C<1;> unless you're sure it'll return true
4106 otherwise.  But it's better just to put the C<1;>, in case you add more
4107 statements.
4108
4109 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
4110 replaces "F<::>" with "F</>" in the filename for you,
4111 to make it easy to load standard modules.  This form of loading of
4112 modules does not risk altering your namespace.
4113
4114 In other words, if you try this:
4115
4116         require Foo::Bar;    # a splendid bareword
4117
4118 The require function will actually look for the "F<Foo/Bar.pm>" file in the
4119 directories specified in the C<@INC> array.
4120
4121 But if you try this:
4122
4123         $class = 'Foo::Bar';
4124         require $class;      # $class is not a bareword
4125     #or
4126         require "Foo::Bar";  # not a bareword because of the ""
4127
4128 The require function will look for the "F<Foo::Bar>" file in the @INC array and
4129 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
4130
4131         eval "require $class";
4132
4133 Now that you understand how C<require> looks for files in the case of
4134 a bareword argument, there is a little extra functionality going on
4135 behind the scenes.  Before C<require> looks for a "F<.pm>" extension,
4136 it will first look for a filename with a "F<.pmc>" extension.  A file
4137 with this extension is assumed to be Perl bytecode generated by
4138 L<B::Bytecode|B::Bytecode>.  If this file is found, and it's modification
4139 time is newer than a coinciding "F<.pm>" non-compiled file, it will be
4140 loaded in place of that non-compiled file ending in a "F<.pm>" extension.
4141
4142 You can also insert hooks into the import facility, by putting directly
4143 Perl code into the @INC array.  There are three forms of hooks: subroutine
4144 references, array references and blessed objects.
4145
4146 Subroutine references are the simplest case.  When the inclusion system
4147 walks through @INC and encounters a subroutine, this subroutine gets
4148 called with two parameters, the first being a reference to itself, and the
4149 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
4150 subroutine should return C<undef> or a filehandle, from which the file to
4151 include will be read.  If C<undef> is returned, C<require> will look at
4152 the remaining elements of @INC.
4153
4154 If the hook is an array reference, its first element must be a subroutine
4155 reference.  This subroutine is called as above, but the first parameter is
4156 the array reference.  This enables to pass indirectly some arguments to
4157 the subroutine.
4158
4159 In other words, you can write:
4160
4161     push @INC, \&my_sub;
4162     sub my_sub {
4163         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
4164         ...
4165     }
4166
4167 or:
4168
4169     push @INC, [ \&my_sub, $x, $y, ... ];
4170     sub my_sub {
4171         my ($arrayref, $filename) = @_;
4172         # Retrieve $x, $y, ...
4173         my @parameters = @$arrayref[1..$#$arrayref];
4174         ...
4175     }
4176
4177 If the hook is an object, it must provide an INC method, that will be
4178 called as above, the first parameter being the object itself.  (Note that
4179 you must fully qualify the sub's name, as it is always forced into package
4180 C<main>.)  Here is a typical code layout:
4181
4182     # In Foo.pm
4183     package Foo;
4184     sub new { ... }
4185     sub Foo::INC {
4186         my ($self, $filename) = @_;
4187         ...
4188     }
4189
4190     # In the main program
4191     push @INC, new Foo(...);
4192
4193 Note that these hooks are also permitted to set the %INC entry
4194 corresponding to the files they have loaded. See L<perlvar/%INC>.
4195
4196 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
4197
4198 =item reset EXPR
4199
4200 =item reset
4201
4202 Generally used in a C<continue> block at the end of a loop to clear
4203 variables and reset C<??> searches so that they work again.  The
4204 expression is interpreted as a list of single characters (hyphens
4205 allowed for ranges).  All variables and arrays beginning with one of
4206 those letters are reset to their pristine state.  If the expression is
4207 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
4208 only variables or searches in the current package.  Always returns
4209 1.  Examples:
4210
4211     reset 'X';          # reset all X variables
4212     reset 'a-z';        # reset lower case variables
4213     reset;              # just reset ?one-time? searches
4214
4215 Resetting C<"A-Z"> is not recommended because you'll wipe out your
4216 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
4217 variables--lexical variables are unaffected, but they clean themselves
4218 up on scope exit anyway, so you'll probably want to use them instead.
4219 See L</my>.
4220
4221 =item return EXPR
4222
4223 =item return
4224
4225 Returns from a subroutine, C<eval>, or C<do FILE> with the value
4226 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
4227 context, depending on how the return value will be used, and the context
4228 may vary from one execution to the next (see C<wantarray>).  If no EXPR
4229 is given, returns an empty list in list context, the undefined value in
4230 scalar context, and (of course) nothing at all in a void context.
4231
4232 (Note that in the absence of an explicit C<return>, a subroutine, eval,
4233 or do FILE will automatically return the value of the last expression
4234 evaluated.)
4235
4236 =item reverse LIST
4237
4238 In list context, returns a list value consisting of the elements
4239 of LIST in the opposite order.  In scalar context, concatenates the
4240 elements of LIST and returns a string value with all characters
4241 in the opposite order.
4242
4243     print reverse <>;           # line tac, last line first
4244
4245     undef $/;                   # for efficiency of <>
4246     print scalar reverse <>;    # character tac, last line tsrif
4247
4248 This operator is also handy for inverting a hash, although there are some
4249 caveats.  If a value is duplicated in the original hash, only one of those
4250 can be represented as a key in the inverted hash.  Also, this has to
4251 unwind one hash and build a whole new one, which may take some time
4252 on a large hash, such as from a DBM file.
4253
4254     %by_name = reverse %by_address;     # Invert the hash
4255
4256 =item rewinddir DIRHANDLE
4257
4258 Sets the current position to the beginning of the directory for the
4259 C<readdir> routine on DIRHANDLE.
4260
4261 =item rindex STR,SUBSTR,POSITION
4262
4263 =item rindex STR,SUBSTR
4264
4265 Works just like index() except that it returns the position of the LAST
4266 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
4267 last occurrence at or before that position.
4268
4269 =item rmdir FILENAME
4270
4271 =item rmdir
4272
4273 Deletes the directory specified by FILENAME if that directory is
4274 empty.  If it succeeds it returns true, otherwise it returns false and
4275 sets C<$!> (errno).  If FILENAME is omitted, uses C<$_>.
4276
4277 =item s///
4278
4279 The substitution operator.  See L<perlop>.
4280
4281 =item scalar EXPR
4282
4283 Forces EXPR to be interpreted in scalar context and returns the value
4284 of EXPR.
4285
4286     @counts = ( scalar @a, scalar @b, scalar @c );
4287
4288 There is no equivalent operator to force an expression to
4289 be interpolated in list context because in practice, this is never
4290 needed.  If you really wanted to do so, however, you could use
4291 the construction C<@{[ (some expression) ]}>, but usually a simple
4292 C<(some expression)> suffices.
4293
4294 Because C<scalar> is unary operator, if you accidentally use for EXPR a
4295 parenthesized list, this behaves as a scalar comma expression, evaluating
4296 all but the last element in void context and returning the final element
4297 evaluated in scalar context.  This is seldom what you want.
4298
4299 The following single statement:
4300
4301         print uc(scalar(&foo,$bar)),$baz;
4302
4303 is the moral equivalent of these two:
4304
4305         &foo;
4306         print(uc($bar),$baz);
4307
4308 See L<perlop> for more details on unary operators and the comma operator.
4309
4310 =item seek FILEHANDLE,POSITION,WHENCE
4311
4312 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
4313 FILEHANDLE may be an expression whose value gives the name of the
4314 filehandle.  The values for WHENCE are C<0> to set the new position
4315 I<in bytes> to POSITION, C<1> to set it to the current position plus
4316 POSITION, and C<2> to set it to EOF plus POSITION (typically
4317 negative).  For WHENCE you may use the constants C<SEEK_SET>,
4318 C<SEEK_CUR>, and C<SEEK_END> (start of the file, current position, end
4319 of the file) from the Fcntl module.  Returns C<1> upon success, C<0>
4320 otherwise.
4321
4322 Note the I<in bytes>: even if the filehandle has been set to
4323 operate on characters (for example by using the C<:utf8> open
4324 layer), tell() will return byte offsets, not character offsets
4325 (because implementing that would render seek() and tell() rather slow).
4326
4327 If you want to position file for C<sysread> or C<syswrite>, don't use
4328 C<seek>--buffering makes its effect on the file's system position
4329 unpredictable and non-portable.  Use C<sysseek> instead.
4330
4331 Due to the rules and rigors of ANSI C, on some systems you have to do a
4332 seek whenever you switch between reading and writing.  Amongst other
4333 things, this may have the effect of calling stdio's clearerr(3).
4334 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
4335
4336     seek(TEST,0,1);
4337
4338 This is also useful for applications emulating C<tail -f>.  Once you hit
4339 EOF on your read, and then sleep for a while, you might have to stick in a
4340 seek() to reset things.  The C<seek> doesn't change the current position,
4341 but it I<does> clear the end-of-file condition on the handle, so that the
4342 next C<< <FILE> >> makes Perl try again to read something.  We hope.
4343
4344 If that doesn't work (some IO implementations are particularly
4345 cantankerous), then you may need something more like this:
4346
4347     for (;;) {
4348         for ($curpos = tell(FILE); $_ = <FILE>;
4349              $curpos = tell(FILE)) {
4350             # search for some stuff and put it into files
4351         }
4352         sleep($for_a_while);
4353         seek(FILE, $curpos, 0);
4354     }
4355
4356 =item seekdir DIRHANDLE,POS
4357
4358 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
4359 must be a value returned by C<telldir>.  Has the same caveats about
4360 possible directory compaction as the corresponding system library
4361 routine.
4362
4363 =item select FILEHANDLE
4364
4365 =item select
4366
4367 Returns the currently selected filehandle.  Sets the current default
4368 filehandle for output, if FILEHANDLE is supplied.  This has two
4369 effects: first, a C<write> or a C<print> without a filehandle will
4370 default to this FILEHANDLE.  Second, references to variables related to
4371 output will refer to this output channel.  For example, if you have to
4372 set the top of form format for more than one output channel, you might
4373 do the following:
4374
4375     select(REPORT1);
4376     $^ = 'report1_top';
4377     select(REPORT2);
4378     $^ = 'report2_top';
4379
4380 FILEHANDLE may be an expression whose value gives the name of the
4381 actual filehandle.  Thus:
4382
4383     $oldfh = select(STDERR); $| = 1; select($oldfh);
4384
4385 Some programmers may prefer to think of filehandles as objects with
4386 methods, preferring to write the last example as:
4387
4388     use IO::Handle;
4389     STDERR->autoflush(1);
4390
4391 =item select RBITS,WBITS,EBITS,TIMEOUT
4392
4393 This calls the select(2) system call with the bit masks specified, which
4394 can be constructed using C<fileno> and C<vec>, along these lines:
4395
4396     $rin = $win = $ein = '';
4397     vec($rin,fileno(STDIN),1) = 1;
4398     vec($win,fileno(STDOUT),1) = 1;
4399     $ein = $rin | $win;
4400
4401 If you want to select on many filehandles you might wish to write a
4402 subroutine:
4403
4404     sub fhbits {
4405         my(@fhlist) = split(' ',$_[0]);
4406         my($bits);
4407         for (@fhlist) {
4408             vec($bits,fileno($_),1) = 1;
4409         }
4410         $bits;
4411     }
4412     $rin = fhbits('STDIN TTY SOCK');
4413
4414 The usual idiom is:
4415
4416     ($nfound,$timeleft) =
4417       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
4418
4419 or to block until something becomes ready just do this
4420
4421     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
4422
4423 Most systems do not bother to return anything useful in $timeleft, so
4424 calling select() in scalar context just returns $nfound.
4425
4426 Any of the bit masks can also be undef.  The timeout, if specified, is
4427 in seconds, which may be fractional.  Note: not all implementations are
4428 capable of returning the $timeleft.  If not, they always return
4429 $timeleft equal to the supplied $timeout.
4430
4431 You can effect a sleep of 250 milliseconds this way:
4432
4433     select(undef, undef, undef, 0.25);
4434
4435 Note that whether C<select> gets restarted after signals (say, SIGALRM)
4436 is implementation-dependent.
4437
4438 B<WARNING>: One should not attempt to mix buffered I/O (like C<read>
4439 or <FH>) with C<select>, except as permitted by POSIX, and even
4440 then only on POSIX systems.  You have to use C<sysread> instead.
4441
4442 =item semctl ID,SEMNUM,CMD,ARG
4443
4444 Calls the System V IPC function C<semctl>.  You'll probably have to say
4445
4446     use IPC::SysV;
4447
4448 first to get the correct constant definitions.  If CMD is IPC_STAT or
4449 GETALL, then ARG must be a variable which will hold the returned
4450 semid_ds structure or semaphore value array.  Returns like C<ioctl>:
4451 the undefined value for error, "C<0 but true>" for zero, or the actual
4452 return value otherwise.  The ARG must consist of a vector of native
4453 short integers, which may be created with C<pack("s!",(0)x$nsem)>.
4454 See also L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::Semaphore>
4455 documentation.
4456
4457 =item semget KEY,NSEMS,FLAGS
4458
4459 Calls the System V IPC function semget.  Returns the semaphore id, or
4460 the undefined value if there is an error.  See also
4461 L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::SysV::Semaphore>
4462 documentation.
4463
4464 =item semop KEY,OPSTRING
4465
4466 Calls the System V IPC function semop to perform semaphore operations
4467 such as signalling and waiting.  OPSTRING must be a packed array of
4468 semop structures.  Each semop structure can be generated with
4469 C<pack("s!3", $semnum, $semop, $semflag)>.  The number of semaphore
4470 operations is implied by the length of OPSTRING.  Returns true if
4471 successful, or false if there is an error.  As an example, the
4472 following code waits on semaphore $semnum of semaphore id $semid:
4473
4474     $semop = pack("s!3", $semnum, -1, 0);
4475     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
4476
4477 To signal the semaphore, replace C<-1> with C<1>.  See also
4478 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::SysV::Semaphore>
4479 documentation.
4480
4481 =item send SOCKET,MSG,FLAGS,TO
4482
4483 =item send SOCKET,MSG,FLAGS
4484
4485 Sends a message on a socket.  Attempts to send the scalar MSG to the
4486 SOCKET filehandle.  Takes the same flags as the system call of the
4487 same name.  On unconnected sockets you must specify a destination to
4488 send TO, in which case it does a C C<sendto>.  Returns the number of
4489 characters sent, or the undefined value if there is an error.  The C
4490 system call sendmsg(2) is currently unimplemented.  See
4491 L<perlipc/"UDP: Message Passing"> for examples.
4492
4493 Note the I<characters>: depending on the status of the socket, either
4494 (8-bit) bytes or characters are sent.  By default all sockets operate
4495 on bytes, but for example if the socket has been changed using
4496 binmode() to operate with the C<:utf8> I/O layer (see L</open>, or the
4497 C<open> pragma, L<open>), the I/O will operate on UTF-8 encoded
4498 Unicode characters, not bytes.  Similarly for the C<:encoding> pragma:
4499 in that case pretty much any characters can be sent.
4500
4501 =item setpgrp PID,PGRP
4502
4503 Sets the current process group for the specified PID, C<0> for the current
4504 process.  Will produce a fatal error if used on a machine that doesn't
4505 implement POSIX setpgid(2) or BSD setpgrp(2).  If the arguments are omitted,
4506 it defaults to C<0,0>.  Note that the BSD 4.2 version of C<setpgrp> does not
4507 accept any arguments, so only C<setpgrp(0,0)> is portable.  See also
4508 C<POSIX::setsid()>.
4509
4510 =item setpriority WHICH,WHO,PRIORITY
4511
4512 Sets the current priority for a process, a process group, or a user.
4513 (See setpriority(2).)  Will produce a fatal error if used on a machine
4514 that doesn't implement setpriority(2).
4515
4516 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
4517
4518 Sets the socket option requested.  Returns undefined if there is an
4519 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
4520 argument.
4521
4522 =item shift ARRAY
4523
4524 =item shift
4525
4526 Shifts the first value of the array off and returns it, shortening the
4527 array by 1 and moving everything down.  If there are no elements in the
4528 array, returns the undefined value.  If ARRAY is omitted, shifts the
4529 C<@_> array within the lexical scope of subroutines and formats, and the
4530 C<@ARGV> array at file scopes or within the lexical scopes established by
4531 the C<eval ''>, C<BEGIN {}>, C<INIT {}>, C<CHECK {}>, and C<END {}>
4532 constructs.
4533
4534 See also C<unshift>, C<push>, and C<pop>.  C<shift> and C<unshift> do the
4535 same thing to the left end of an array that C<pop> and C<push> do to the
4536 right end.
4537
4538 =item shmctl ID,CMD,ARG
4539
4540 Calls the System V IPC function shmctl.  You'll probably have to say
4541
4542     use IPC::SysV;
4543
4544 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
4545 then ARG must be a variable which will hold the returned C<shmid_ds>
4546 structure.  Returns like ioctl: the undefined value for error, "C<0> but
4547 true" for zero, or the actual return value otherwise.
4548 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4549
4550 =item shmget KEY,SIZE,FLAGS
4551
4552 Calls the System V IPC function shmget.  Returns the shared memory
4553 segment id, or the undefined value if there is an error.
4554 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4555
4556 =item shmread ID,VAR,POS,SIZE
4557
4558 =item shmwrite ID,STRING,POS,SIZE
4559
4560 Reads or writes the System V shared memory segment ID starting at
4561 position POS for size SIZE by attaching to it, copying in/out, and
4562 detaching from it.  When reading, VAR must be a variable that will
4563 hold the data read.  When writing, if STRING is too long, only SIZE
4564 bytes are used; if STRING is too short, nulls are written to fill out
4565 SIZE bytes.  Return true if successful, or false if there is an error.
4566 shmread() taints the variable. See also L<perlipc/"SysV IPC">,
4567 C<IPC::SysV> documentation, and the C<IPC::Shareable> module from CPAN.
4568
4569 =item shutdown SOCKET,HOW
4570
4571 Shuts down a socket connection in the manner indicated by HOW, which
4572 has the same interpretation as in the system call of the same name.
4573
4574     shutdown(SOCKET, 0);    # I/we have stopped reading data
4575     shutdown(SOCKET, 1);    # I/we have stopped writing data
4576     shutdown(SOCKET, 2);    # I/we have stopped using this socket
4577
4578 This is useful with sockets when you want to tell the other
4579 side you're done writing but not done reading, or vice versa.
4580 It's also a more insistent form of close because it also
4581 disables the file descriptor in any forked copies in other
4582 processes.
4583
4584 =item sin EXPR
4585
4586 =item sin
4587
4588 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
4589 returns sine of C<$_>.
4590
4591 For the inverse sine operation, you may use the C<Math::Trig::asin>
4592 function, or use this relation:
4593
4594     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
4595
4596 =item sleep EXPR
4597
4598 =item sleep
4599
4600 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
4601 May be interrupted if the process receives a signal such as C<SIGALRM>.
4602 Returns the number of seconds actually slept.  You probably cannot
4603 mix C<alarm> and C<sleep> calls, because C<sleep> is often implemented
4604 using C<alarm>.
4605
4606 On some older systems, it may sleep up to a full second less than what
4607 you requested, depending on how it counts seconds.  Most modern systems
4608 always sleep the full amount.  They may appear to sleep longer than that,
4609 however, because your process might not be scheduled right away in a
4610 busy multitasking system.
4611
4612 For delays of finer granularity than one second, you may use Perl's
4613 C<syscall> interface to access setitimer(2) if your system supports
4614 it, or else see L</select> above.  The Time::HiRes module (from CPAN,
4615 and starting from Perl 5.8 part of the standard distribution) may also
4616 help.
4617
4618 See also the POSIX module's C<pause> function.
4619
4620 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
4621
4622 Opens a socket of the specified kind and attaches it to filehandle
4623 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for
4624 the system call of the same name.  You should C<use Socket> first
4625 to get the proper definitions imported.  See the examples in
4626 L<perlipc/"Sockets: Client/Server Communication">.
4627
4628 On systems that support a close-on-exec flag on files, the flag will
4629 be set for the newly opened file descriptor, as determined by the
4630 value of $^F.  See L<perlvar/$^F>.
4631
4632 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
4633
4634 Creates an unnamed pair of sockets in the specified domain, of the
4635 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the