This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
eb71b89a834bcb06e3c02e5272cf21e69d8ad543
[perl5.git] / pod / perlop.pod
1 =head1 NAME
2 X<operator>
3
4 perlop - Perl operators and precedence
5
6 =head1 DESCRIPTION
7
8 =head2 Operator Precedence and Associativity
9 X<operator, precedence> X<precedence> X<associativity>
10
11 Operator precedence and associativity work in Perl more or less like
12 they do in mathematics.
13
14 I<Operator precedence> means some operators are evaluated before
15 others.  For example, in C<2 + 4 * 5>, the multiplication has higher
16 precedence so C<4 * 5> is evaluated first yielding C<2 + 20 ==
17 22> and not C<6 * 5 == 30>.
18
19 I<Operator associativity> defines what happens if a sequence of the
20 same operators is used one after another: whether the evaluator will
21 evaluate the left operations first or the right.  For example, in C<8
22 - 4 - 2>, subtraction is left associative so Perl evaluates the
23 expression left to right.  C<8 - 4> is evaluated first making the
24 expression C<4 - 2 == 2> and not C<8 - 2 == 6>.
25
26 Perl operators have the following associativity and precedence,
27 listed from highest precedence to lowest.  Operators borrowed from
28 C keep the same precedence relationship with each other, even where
29 C's precedence is slightly screwy.  (This makes learning Perl easier
30 for C folks.)  With very few exceptions, these all operate on scalar
31 values only, not array values.
32
33     left        terms and list operators (leftward)
34     left        ->
35     nonassoc    ++ --
36     right       **
37     right       ! ~ \ and unary + and -
38     left        =~ !~
39     left        * / % x
40     left        + - .
41     left        << >>
42     nonassoc    named unary operators
43     nonassoc    < > <= >= lt gt le ge
44     nonassoc    == != <=> eq ne cmp ~~
45     left        &
46     left        | ^
47     left        &&
48     left        || //
49     nonassoc    ..  ...
50     right       ?:
51     right       = += -= *= etc.
52     left        , =>
53     nonassoc    list operators (rightward)
54     right       not
55     left        and
56     left        or xor
57
58 In the following sections, these operators are covered in precedence order.
59
60 Many operators can be overloaded for objects.  See L<overload>.
61
62 =head2 Terms and List Operators (Leftward)
63 X<list operator> X<operator, list> X<term>
64
65 A TERM has the highest precedence in Perl.  They include variables,
66 quote and quote-like operators, any expression in parentheses,
67 and any function whose arguments are parenthesized.  Actually, there
68 aren't really functions in this sense, just list operators and unary
69 operators behaving as functions because you put parentheses around
70 the arguments.  These are all documented in L<perlfunc>.
71
72 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
73 is followed by a left parenthesis as the next token, the operator and
74 arguments within parentheses are taken to be of highest precedence,
75 just like a normal function call.
76
77 In the absence of parentheses, the precedence of list operators such as
78 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
79 whether you are looking at the left side or the right side of the operator.
80 For example, in
81
82     @ary = (1, 3, sort 4, 2);
83     print @ary;         # prints 1324
84
85 the commas on the right of the sort are evaluated before the sort,
86 but the commas on the left are evaluated after.  In other words,
87 list operators tend to gobble up all arguments that follow, and
88 then act like a simple TERM with regard to the preceding expression.
89 Be careful with parentheses:
90
91     # These evaluate exit before doing the print:
92     print($foo, exit);  # Obviously not what you want.
93     print $foo, exit;   # Nor is this.
94
95     # These do the print before evaluating exit:
96     (print $foo), exit; # This is what you want.
97     print($foo), exit;  # Or this.
98     print ($foo), exit; # Or even this.
99
100 Also note that
101
102     print ($foo & 255) + 1, "\n";
103
104 probably doesn't do what you expect at first glance.  The parentheses
105 enclose the argument list for C<print> which is evaluated (printing
106 the result of C<$foo & 255>).  Then one is added to the return value
107 of C<print> (usually 1).  The result is something like this:
108
109     1 + 1, "\n";    # Obviously not what you meant.
110
111 To do what you meant properly, you must write:
112
113     print(($foo & 255) + 1, "\n");
114
115 See L<Named Unary Operators> for more discussion of this.
116
117 Also parsed as terms are the C<do {}> and C<eval {}> constructs, as
118 well as subroutine and method calls, and the anonymous
119 constructors C<[]> and C<{}>.
120
121 See also L<Quote and Quote-like Operators> toward the end of this section,
122 as well as L</"I/O Operators">.
123
124 =head2 The Arrow Operator
125 X<arrow> X<dereference> X<< -> >>
126
127 "C<< -> >>" is an infix dereference operator, just as it is in C
128 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
129 C<(...)> subscript, then the left side must be either a hard or
130 symbolic reference to an array, a hash, or a subroutine respectively.
131 (Or technically speaking, a location capable of holding a hard
132 reference, if it's an array or hash reference being used for
133 assignment.)  See L<perlreftut> and L<perlref>.
134
135 Otherwise, the right side is a method name or a simple scalar
136 variable containing either the method name or a subroutine reference,
137 and the left side must be either an object (a blessed reference)
138 or a class name (that is, a package name).  See L<perlobj>.
139
140 =head2 Auto-increment and Auto-decrement
141 X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<-->
142
143 "++" and "--" work as in C.  That is, if placed before a variable,
144 they increment or decrement the variable by one before returning the
145 value, and if placed after, increment or decrement after returning the
146 value.
147
148     $i = 0;  $j = 0;
149     print $i++;  # prints 0
150     print ++$j;  # prints 1
151
152 Note that just as in C, Perl doesn't define B<when> the variable is
153 incremented or decremented. You just know it will be done sometime
154 before or after the value is returned. This also means that modifying
155 a variable twice in the same statement will lead to undefined behaviour.
156 Avoid statements like:
157
158     $i = $i ++;
159     print ++ $i + $i ++;
160
161 Perl will not guarantee what the result of the above statements is.
162
163 The auto-increment operator has a little extra builtin magic to it.  If
164 you increment a variable that is numeric, or that has ever been used in
165 a numeric context, you get a normal increment.  If, however, the
166 variable has been used in only string contexts since it was set, and
167 has a value that is not the empty string and matches the pattern
168 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
169 character within its range, with carry:
170
171     print ++($foo = '99');      # prints '100'
172     print ++($foo = 'a0');      # prints 'a1'
173     print ++($foo = 'Az');      # prints 'Ba'
174     print ++($foo = 'zz');      # prints 'aaa'
175
176 C<undef> is always treated as numeric, and in particular is changed
177 to C<0> before incrementing (so that a post-increment of an undef value
178 will return C<0> rather than C<undef>).
179
180 The auto-decrement operator is not magical.
181
182 =head2 Exponentiation
183 X<**> X<exponentiation> X<power>
184
185 Binary "**" is the exponentiation operator.  It binds even more
186 tightly than unary minus, so -2**4 is -(2**4), not (-2)**4. (This is
187 implemented using C's pow(3) function, which actually works on doubles
188 internally.)
189
190 =head2 Symbolic Unary Operators
191 X<unary operator> X<operator, unary>
192
193 Unary "!" performs logical negation, i.e., "not".  See also C<not> for a lower
194 precedence version of this.
195 X<!>
196
197 Unary "-" performs arithmetic negation if the operand is numeric,
198 including any string that looks like a number.  If the operand is
199 an identifier, a string consisting of a minus sign concatenated
200 with the identifier is returned.  Otherwise, if the string starts
201 with a plus or minus, a string starting with the opposite sign is
202 returned.  One effect of these rules is that -bareword is equivalent
203 to the string "-bareword".  If, however, the string begins with a
204 non-alphabetic character (excluding "+" or "-"), Perl will attempt to convert
205 the string to a numeric and the arithmetic negation is performed. If the
206 string cannot be cleanly converted to a numeric, Perl will give the warning
207 B<Argument "the string" isn't numeric in negation (-) at ...>.
208 X<-> X<negation, arithmetic>
209
210 Unary "~" performs bitwise negation, i.e., 1's complement.  For
211 example, C<0666 & ~027> is 0640.  (See also L<Integer Arithmetic> and
212 L<Bitwise String Operators>.)  Note that the width of the result is
213 platform-dependent: ~0 is 32 bits wide on a 32-bit platform, but 64
214 bits wide on a 64-bit platform, so if you are expecting a certain bit
215 width, remember to use the & operator to mask off the excess bits.
216 X<~> X<negation, binary>
217
218 Unary "+" has no effect whatsoever, even on strings.  It is useful
219 syntactically for separating a function name from a parenthesized expression
220 that would otherwise be interpreted as the complete list of function
221 arguments.  (See examples above under L<Terms and List Operators (Leftward)>.)
222 X<+>
223
224 Unary "\" creates a reference to whatever follows it.  See L<perlreftut>
225 and L<perlref>.  Do not confuse this behavior with the behavior of
226 backslash within a string, although both forms do convey the notion
227 of protecting the next thing from interpolation.
228 X<\> X<reference> X<backslash>
229
230 =head2 Binding Operators
231 X<binding> X<operator, binding> X<=~> X<!~>
232
233 Binary "=~" binds a scalar expression to a pattern match.  Certain operations
234 search or modify the string $_ by default.  This operator makes that kind
235 of operation work on some other string.  The right argument is a search
236 pattern, substitution, or transliteration.  The left argument is what is
237 supposed to be searched, substituted, or transliterated instead of the default
238 $_.  When used in scalar context, the return value generally indicates the
239 success of the operation.  The exceptions are substitution (s///)
240 and transliteration (y///) with the C</r> (non-destructive) option,
241 which cause the B<r>eturn value to be the result of the substitution.
242 Behavior in list context depends on the particular operator.
243 See L</"Regexp Quote-Like Operators"> for details and L<perlretut> for
244 examples using these operators.
245
246 If the right argument is an expression rather than a search pattern,
247 substitution, or transliteration, it is interpreted as a search pattern at run
248 time. Note that this means that its contents will be interpolated twice, so
249
250   '\\' =~ q'\\';
251
252 is not ok, as the regex engine will end up trying to compile the
253 pattern C<\>, which it will consider a syntax error.
254
255 Binary "!~" is just like "=~" except the return value is negated in
256 the logical sense.
257
258 Binary "!~" with a non-destructive substitution (s///r) or transliteration
259 (y///r) is a syntax error.
260
261 =head2 Multiplicative Operators
262 X<operator, multiplicative>
263
264 Binary "*" multiplies two numbers.
265 X<*>
266
267 Binary "/" divides two numbers.
268 X</> X<slash>
269
270 Binary "%" is the modulo operator, which computes the division
271 remainder of its first argument with respect to its second argument.
272 Given integer
273 operands C<$a> and C<$b>: If C<$b> is positive, then C<$a % $b> is
274 C<$a> minus the largest multiple of C<$b> less than or equal to
275 C<$a>.  If C<$b> is negative, then C<$a % $b> is C<$a> minus the
276 smallest multiple of C<$b> that is not less than C<$a> (i.e. the
277 result will be less than or equal to zero).  If the operands
278 C<$a> and C<$b> are floating point values and the absolute value of
279 C<$b> (that is C<abs($b)>) is less than C<(UV_MAX + 1)>, only
280 the integer portion of C<$a> and C<$b> will be used in the operation
281 (Note: here C<UV_MAX> means the maximum of the unsigned integer type).
282 If the absolute value of the right operand (C<abs($b)>) is greater than
283 or equal to C<(UV_MAX + 1)>, "%" computes the floating-point remainder
284 C<$r> in the equation C<($r = $a - $i*$b)> where C<$i> is a certain
285 integer that makes C<$r> have the same sign as the right operand
286 C<$b> (B<not> as the left operand C<$a> like C function C<fmod()>)
287 and the absolute value less than that of C<$b>.
288 Note that when C<use integer> is in scope, "%" gives you direct access
289 to the modulo operator as implemented by your C compiler.  This
290 operator is not as well defined for negative operands, but it will
291 execute faster.
292 X<%> X<remainder> X<modulo> X<mod>
293
294 Binary "x" is the repetition operator.  In scalar context or if the left
295 operand is not enclosed in parentheses, it returns a string consisting
296 of the left operand repeated the number of times specified by the right
297 operand.  In list context, if the left operand is enclosed in
298 parentheses or is a list formed by C<qw/STRING/>, it repeats the list.
299 If the right operand is zero or negative, it returns an empty string
300 or an empty list, depending on the context.
301 X<x>
302
303     print '-' x 80;             # print row of dashes
304
305     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
306
307     @ones = (1) x 80;           # a list of 80 1's
308     @ones = (5) x @ones;        # set all elements to 5
309
310
311 =head2 Additive Operators
312 X<operator, additive>
313
314 Binary "+" returns the sum of two numbers.
315 X<+>
316
317 Binary "-" returns the difference of two numbers.
318 X<->
319
320 Binary "." concatenates two strings.
321 X<string, concatenation> X<concatenation>
322 X<cat> X<concat> X<concatenate> X<.>
323
324 =head2 Shift Operators
325 X<shift operator> X<operator, shift> X<<< << >>>
326 X<<< >> >>> X<right shift> X<left shift> X<bitwise shift>
327 X<shl> X<shr> X<shift, right> X<shift, left>
328
329 Binary "<<" returns the value of its left argument shifted left by the
330 number of bits specified by the right argument.  Arguments should be
331 integers.  (See also L<Integer Arithmetic>.)
332
333 Binary ">>" returns the value of its left argument shifted right by
334 the number of bits specified by the right argument.  Arguments should
335 be integers.  (See also L<Integer Arithmetic>.)
336
337 Note that both "<<" and ">>" in Perl are implemented directly using
338 "<<" and ">>" in C.  If C<use integer> (see L<Integer Arithmetic>) is
339 in force then signed C integers are used, else unsigned C integers are
340 used.  Either way, the implementation isn't going to generate results
341 larger than the size of the integer type Perl was built with (32 bits
342 or 64 bits).
343
344 The result of overflowing the range of the integers is undefined
345 because it is undefined also in C.  In other words, using 32-bit
346 integers, C<< 1 << 32 >> is undefined.  Shifting by a negative number
347 of bits is also undefined.
348
349 =head2 Named Unary Operators
350 X<operator, named unary>
351
352 The various named unary operators are treated as functions with one
353 argument, with optional parentheses.
354
355 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
356 is followed by a left parenthesis as the next token, the operator and
357 arguments within parentheses are taken to be of highest precedence,
358 just like a normal function call.  For example,
359 because named unary operators are higher precedence than ||:
360
361     chdir $foo    || die;       # (chdir $foo) || die
362     chdir($foo)   || die;       # (chdir $foo) || die
363     chdir ($foo)  || die;       # (chdir $foo) || die
364     chdir +($foo) || die;       # (chdir $foo) || die
365
366 but, because * is higher precedence than named operators:
367
368     chdir $foo * 20;    # chdir ($foo * 20)
369     chdir($foo) * 20;   # (chdir $foo) * 20
370     chdir ($foo) * 20;  # (chdir $foo) * 20
371     chdir +($foo) * 20; # chdir ($foo * 20)
372
373     rand 10 * 20;       # rand (10 * 20)
374     rand(10) * 20;      # (rand 10) * 20
375     rand (10) * 20;     # (rand 10) * 20
376     rand +(10) * 20;    # rand (10 * 20)
377
378 Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are
379 treated like named unary operators, but they don't follow this functional
380 parenthesis rule.  That means, for example, that C<-f($file).".bak"> is
381 equivalent to C<-f "$file.bak">.
382 X<-X> X<filetest> X<operator, filetest>
383
384 See also L<"Terms and List Operators (Leftward)">.
385
386 =head2 Relational Operators
387 X<relational operator> X<operator, relational>
388
389 Binary "<" returns true if the left argument is numerically less than
390 the right argument.
391 X<< < >>
392
393 Binary ">" returns true if the left argument is numerically greater
394 than the right argument.
395 X<< > >>
396
397 Binary "<=" returns true if the left argument is numerically less than
398 or equal to the right argument.
399 X<< <= >>
400
401 Binary ">=" returns true if the left argument is numerically greater
402 than or equal to the right argument.
403 X<< >= >>
404
405 Binary "lt" returns true if the left argument is stringwise less than
406 the right argument.
407 X<< lt >>
408
409 Binary "gt" returns true if the left argument is stringwise greater
410 than the right argument.
411 X<< gt >>
412
413 Binary "le" returns true if the left argument is stringwise less than
414 or equal to the right argument.
415 X<< le >>
416
417 Binary "ge" returns true if the left argument is stringwise greater
418 than or equal to the right argument.
419 X<< ge >>
420
421 =head2 Equality Operators
422 X<equality> X<equal> X<equals> X<operator, equality>
423
424 Binary "==" returns true if the left argument is numerically equal to
425 the right argument.
426 X<==>
427
428 Binary "!=" returns true if the left argument is numerically not equal
429 to the right argument.
430 X<!=>
431
432 Binary "<=>" returns -1, 0, or 1 depending on whether the left
433 argument is numerically less than, equal to, or greater than the right
434 argument.  If your platform supports NaNs (not-a-numbers) as numeric
435 values, using them with "<=>" returns undef.  NaN is not "<", "==", ">",
436 "<=" or ">=" anything (even NaN), so those 5 return false. NaN != NaN
437 returns true, as does NaN != anything else. If your platform doesn't
438 support NaNs then NaN is just a string with numeric value 0.
439 X<< <=> >> X<spaceship>
440
441     perl -le '$a = "NaN"; print "No NaN support here" if $a == $a'
442     perl -le '$a = "NaN"; print "NaN support here" if $a != $a'
443
444 Binary "eq" returns true if the left argument is stringwise equal to
445 the right argument.
446 X<eq>
447
448 Binary "ne" returns true if the left argument is stringwise not equal
449 to the right argument.
450 X<ne>
451
452 Binary "cmp" returns -1, 0, or 1 depending on whether the left
453 argument is stringwise less than, equal to, or greater than the right
454 argument.
455 X<cmp>
456
457 Binary "~~" does a smart match between its arguments. Smart matching
458 is described in L<perlsyn/"Smart matching in detail">.
459 X<~~>
460
461 "lt", "le", "ge", "gt" and "cmp" use the collation (sort) order specified
462 by the current locale if C<use locale> is in effect.  See L<perllocale>.
463
464 =head2 Bitwise And
465 X<operator, bitwise, and> X<bitwise and> X<&>
466
467 Binary "&" returns its operands ANDed together bit by bit.
468 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
469
470 Note that "&" has lower priority than relational operators, so for example
471 the brackets are essential in a test like
472
473         print "Even\n" if ($x & 1) == 0;
474
475 =head2 Bitwise Or and Exclusive Or
476 X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor>
477 X<bitwise xor> X<^>
478
479 Binary "|" returns its operands ORed together bit by bit.
480 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
481
482 Binary "^" returns its operands XORed together bit by bit.
483 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
484
485 Note that "|" and "^" have lower priority than relational operators, so
486 for example the brackets are essential in a test like
487
488         print "false\n" if (8 | 2) != 10;
489
490 =head2 C-style Logical And
491 X<&&> X<logical and> X<operator, logical, and>
492
493 Binary "&&" performs a short-circuit logical AND operation.  That is,
494 if the left operand is false, the right operand is not even evaluated.
495 Scalar or list context propagates down to the right operand if it
496 is evaluated.
497
498 =head2 C-style Logical Or
499 X<||> X<operator, logical, or>
500
501 Binary "||" performs a short-circuit logical OR operation.  That is,
502 if the left operand is true, the right operand is not even evaluated.
503 Scalar or list context propagates down to the right operand if it
504 is evaluated.
505
506 =head2 C-style Logical Defined-Or
507 X<//> X<operator, logical, defined-or>
508
509 Although it has no direct equivalent in C, Perl's C<//> operator is related
510 to its C-style or.  In fact, it's exactly the same as C<||>, except that it
511 tests the left hand side's definedness instead of its truth.  Thus, C<$a // $b>
512 is similar to C<defined($a) || $b> (except that it returns the value of C<$a>
513 rather than the value of C<defined($a)>) and yields the same result as
514 C<defined($a) ? $a : $b> (except that the ternary-operator form can be
515 used as a lvalue, while C<$a // $b> cannot).  This is very useful for
516 providing default values for variables.  If you actually want to test if
517 at least one of C<$a> and C<$b> is defined, use C<defined($a // $b)>.
518
519 The C<||>, C<//> and C<&&> operators return the last value evaluated
520 (unlike C's C<||> and C<&&>, which return 0 or 1). Thus, a reasonably
521 portable way to find out the home directory might be:
522
523     $home = $ENV{'HOME'} // $ENV{'LOGDIR'} //
524         (getpwuid($<))[7] // die "You're homeless!\n";
525
526 In particular, this means that you shouldn't use this
527 for selecting between two aggregates for assignment:
528
529     @a = @b || @c;              # this is wrong
530     @a = scalar(@b) || @c;      # really meant this
531     @a = @b ? @b : @c;          # this works fine, though
532
533 As more readable alternatives to C<&&> and C<||> when used for
534 control flow, Perl provides the C<and> and C<or> operators (see below).
535 The short-circuit behavior is identical.  The precedence of "and"
536 and "or" is much lower, however, so that you can safely use them after a
537 list operator without the need for parentheses:
538
539     unlink "alpha", "beta", "gamma"
540             or gripe(), next LINE;
541
542 With the C-style operators that would have been written like this:
543
544     unlink("alpha", "beta", "gamma")
545             || (gripe(), next LINE);
546
547 Using "or" for assignment is unlikely to do what you want; see below.
548
549 =head2 Range Operators
550 X<operator, range> X<range> X<..> X<...>
551
552 Binary ".." is the range operator, which is really two different
553 operators depending on the context.  In list context, it returns a
554 list of values counting (up by ones) from the left value to the right
555 value.  If the left value is greater than the right value then it
556 returns the empty list.  The range operator is useful for writing
557 C<foreach (1..10)> loops and for doing slice operations on arrays. In
558 the current implementation, no temporary array is created when the
559 range operator is used as the expression in C<foreach> loops, but older
560 versions of Perl might burn a lot of memory when you write something
561 like this:
562
563     for (1 .. 1_000_000) {
564         # code
565     }
566
567 The range operator also works on strings, using the magical
568 auto-increment, see below.
569
570 In scalar context, ".." returns a boolean value.  The operator is
571 bistable, like a flip-flop, and emulates the line-range (comma)
572 operator of B<sed>, B<awk>, and various editors. Each ".." operator
573 maintains its own boolean state, even across calls to a subroutine
574 that contains it. It is false as long as its left operand is false.
575 Once the left operand is true, the range operator stays true until the
576 right operand is true, I<AFTER> which the range operator becomes false
577 again.  It doesn't become false till the next time the range operator
578 is evaluated.  It can test the right operand and become false on the
579 same evaluation it became true (as in B<awk>), but it still returns
580 true once. If you don't want it to test the right operand until the
581 next evaluation, as in B<sed>, just use three dots ("...") instead of
582 two.  In all other regards, "..." behaves just like ".." does.
583
584 The right operand is not evaluated while the operator is in the
585 "false" state, and the left operand is not evaluated while the
586 operator is in the "true" state.  The precedence is a little lower
587 than || and &&.  The value returned is either the empty string for
588 false, or a sequence number (beginning with 1) for true.  The sequence
589 number is reset for each range encountered.  The final sequence number
590 in a range has the string "E0" appended to it, which doesn't affect
591 its numeric value, but gives you something to search for if you want
592 to exclude the endpoint.  You can exclude the beginning point by
593 waiting for the sequence number to be greater than 1.
594
595 If either operand of scalar ".." is a constant expression,
596 that operand is considered true if it is equal (C<==>) to the current
597 input line number (the C<$.> variable).
598
599 To be pedantic, the comparison is actually C<int(EXPR) == int(EXPR)>,
600 but that is only an issue if you use a floating point expression; when
601 implicitly using C<$.> as described in the previous paragraph, the
602 comparison is C<int(EXPR) == int($.)> which is only an issue when C<$.>
603 is set to a floating point value and you are not reading from a file.
604 Furthermore, C<"span" .. "spat"> or C<2.18 .. 3.14> will not do what
605 you want in scalar context because each of the operands are evaluated
606 using their integer representation.
607
608 Examples:
609
610 As a scalar operator:
611
612     if (101 .. 200) { print; } # print 2nd hundred lines, short for
613                                #  if ($. == 101 .. $. == 200) { print; }
614
615     next LINE if (1 .. /^$/);  # skip header lines, short for
616                                #   next LINE if ($. == 1 .. /^$/);
617                                # (typically in a loop labeled LINE)
618
619     s/^/> / if (/^$/ .. eof());  # quote body
620
621     # parse mail messages
622     while (<>) {
623         $in_header =   1  .. /^$/;
624         $in_body   = /^$/ .. eof;
625         if ($in_header) {
626             # do something
627         } else { # in body
628             # do something else
629         }
630     } continue {
631         close ARGV if eof;             # reset $. each file
632     }
633
634 Here's a simple example to illustrate the difference between
635 the two range operators:
636
637     @lines = ("   - Foo",
638               "01 - Bar",
639               "1  - Baz",
640               "   - Quux");
641
642     foreach (@lines) {
643         if (/0/ .. /1/) {
644             print "$_\n";
645         }
646     }
647
648 This program will print only the line containing "Bar". If
649 the range operator is changed to C<...>, it will also print the
650 "Baz" line.
651
652 And now some examples as a list operator:
653
654     for (101 .. 200) { print; } # print $_ 100 times
655     @foo = @foo[0 .. $#foo];    # an expensive no-op
656     @foo = @foo[$#foo-4 .. $#foo];      # slice last 5 items
657
658 The range operator (in list context) makes use of the magical
659 auto-increment algorithm if the operands are strings.  You
660 can say
661
662     @alphabet = ('A' .. 'Z');
663
664 to get all normal letters of the English alphabet, or
665
666     $hexdigit = (0 .. 9, 'a' .. 'f')[$num & 15];
667
668 to get a hexadecimal digit, or
669
670     @z2 = ('01' .. '31');  print $z2[$mday];
671
672 to get dates with leading zeros.
673
674 If the final value specified is not in the sequence that the magical
675 increment would produce, the sequence goes until the next value would
676 be longer than the final value specified.
677
678 If the initial value specified isn't part of a magical increment
679 sequence (that is, a non-empty string matching "/^[a-zA-Z]*[0-9]*\z/"),
680 only the initial value will be returned.  So the following will only
681 return an alpha:
682
683     use charnames 'greek';
684     my @greek_small =  ("\N{alpha}" .. "\N{omega}");
685
686 To get lower-case greek letters, use this instead:
687
688     my @greek_small =  map { chr } ( ord("\N{alpha}") ..
689                                                      ord("\N{omega}") );
690
691 Because each operand is evaluated in integer form, C<2.18 .. 3.14> will
692 return two elements in list context.
693
694     @list = (2.18 .. 3.14); # same as @list = (2 .. 3);
695
696 =head2 Conditional Operator
697 X<operator, conditional> X<operator, ternary> X<ternary> X<?:>
698
699 Ternary "?:" is the conditional operator, just as in C.  It works much
700 like an if-then-else.  If the argument before the ? is true, the
701 argument before the : is returned, otherwise the argument after the :
702 is returned.  For example:
703
704     printf "I have %d dog%s.\n", $n,
705             ($n == 1) ? '' : "s";
706
707 Scalar or list context propagates downward into the 2nd
708 or 3rd argument, whichever is selected.
709
710     $a = $ok ? $b : $c;  # get a scalar
711     @a = $ok ? @b : @c;  # get an array
712     $a = $ok ? @b : @c;  # oops, that's just a count!
713
714 The operator may be assigned to if both the 2nd and 3rd arguments are
715 legal lvalues (meaning that you can assign to them):
716
717     ($a_or_b ? $a : $b) = $c;
718
719 Because this operator produces an assignable result, using assignments
720 without parentheses will get you in trouble.  For example, this:
721
722     $a % 2 ? $a += 10 : $a += 2
723
724 Really means this:
725
726     (($a % 2) ? ($a += 10) : $a) += 2
727
728 Rather than this:
729
730     ($a % 2) ? ($a += 10) : ($a += 2)
731
732 That should probably be written more simply as:
733
734     $a += ($a % 2) ? 10 : 2;
735
736 =head2 Assignment Operators
737 X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=>
738 X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=>
739 X<%=> X<^=> X<x=>
740
741 "=" is the ordinary assignment operator.
742
743 Assignment operators work as in C.  That is,
744
745     $a += 2;
746
747 is equivalent to
748
749     $a = $a + 2;
750
751 although without duplicating any side effects that dereferencing the lvalue
752 might trigger, such as from tie().  Other assignment operators work similarly.
753 The following are recognized:
754
755     **=    +=    *=    &=    <<=    &&=
756            -=    /=    |=    >>=    ||=
757            .=    %=    ^=           //=
758                  x=
759
760 Although these are grouped by family, they all have the precedence
761 of assignment.
762
763 Unlike in C, the scalar assignment operator produces a valid lvalue.
764 Modifying an assignment is equivalent to doing the assignment and
765 then modifying the variable that was assigned to.  This is useful
766 for modifying a copy of something, like this:
767
768     ($tmp = $global) =~ tr [A-Z] [a-z];
769
770 Likewise,
771
772     ($a += 2) *= 3;
773
774 is equivalent to
775
776     $a += 2;
777     $a *= 3;
778
779 Similarly, a list assignment in list context produces the list of
780 lvalues assigned to, and a list assignment in scalar context returns
781 the number of elements produced by the expression on the right hand
782 side of the assignment.
783
784 =head2 Comma Operator
785 X<comma> X<operator, comma> X<,>
786
787 Binary "," is the comma operator.  In scalar context it evaluates
788 its left argument, throws that value away, then evaluates its right
789 argument and returns that value.  This is just like C's comma operator.
790
791 In list context, it's just the list argument separator, and inserts
792 both its arguments into the list.  These arguments are also evaluated
793 from left to right.
794
795 The C<< => >> operator is a synonym for the comma except that it causes
796 its left operand to be interpreted as a string if it begins with a letter
797 or underscore and is composed only of letters, digits and underscores.
798 This includes operands that might otherwise be interpreted as operators,
799 constants, single number v-strings or function calls. If in doubt about
800 this behaviour, the left operand can be quoted explicitly.
801
802 Otherwise, the C<< => >> operator behaves exactly as the comma operator
803 or list argument separator, according to context.
804
805 For example:
806
807     use constant FOO => "something";
808
809     my %h = ( FOO => 23 );
810
811 is equivalent to:
812
813     my %h = ("FOO", 23);
814
815 It is I<NOT>:
816
817     my %h = ("something", 23);
818
819 The C<< => >> operator is helpful in documenting the correspondence
820 between keys and values in hashes, and other paired elements in lists.
821
822         %hash = ( $key => $value );
823         login( $username => $password );
824
825 =head2 Yada Yada Operator
826 X<...> X<... operator> X<yada yada operator>
827
828 The yada yada operator (noted C<...>) is a placeholder for code. Perl
829 parses it without error, but when you try to execute a yada yada, it
830 throws an exception with the text C<Unimplemented>:
831
832         sub unimplemented { ... }
833         
834         eval { unimplemented() };
835         if( $@ eq 'Unimplemented' ) {
836           print "I found the yada yada!\n";
837           }
838
839 You can only use the yada yada to stand in for a complete statement.
840 These examples of the yada yada work:
841
842         { ... }
843         
844         sub foo { ... }
845         
846         ...;
847         
848         eval { ... };
849         
850         sub foo {
851                         my( $self ) = shift;
852                         
853                         ...;
854                         }
855                         
856         do { my $n; ...; print 'Hurrah!' };
857
858 The yada yada cannot stand in for an expression that is part of a
859 larger statement since the C<...> is also the three-dot version of the
860 range operator (see L<Range Operators>). These examples of the yada
861 yada are still syntax errors:
862
863         print ...;
864         
865         open my($fh), '>', '/dev/passwd' or ...;
866         
867         if( $condition && ... ) { print "Hello\n" };
868
869 There are some cases where Perl can't immediately tell the difference
870 between an expression and a statement. For instance, the syntax for a
871 block and an anonymous hash reference constructor look the same unless
872 there's something in the braces that give Perl a hint. The yada yada
873 is a syntax error if Perl doesn't guess that the C<{ ... }> is a
874 block. In that case, it doesn't think the C<...> is the yada yada
875 because it's expecting an expression instead of a statement:
876
877         my @transformed = map { ... } @input;  # syntax error
878
879 You can use a C<;> inside your block to denote that the C<{ ... }> is
880 a block and not a hash reference constructor. Now the yada yada works:
881
882         my @transformed = map {; ... } @input; # ; disambiguates
883
884         my @transformed = map { ...; } @input; # ; disambiguates
885
886 =head2 List Operators (Rightward)
887 X<operator, list, rightward> X<list operator>
888
889 On the right side of a list operator, it has very low precedence,
890 such that it controls all comma-separated expressions found there.
891 The only operators with lower precedence are the logical operators
892 "and", "or", and "not", which may be used to evaluate calls to list
893 operators without the need for extra parentheses:
894
895     open HANDLE, "filename"
896         or die "Can't open: $!\n";
897
898 See also discussion of list operators in L<Terms and List Operators (Leftward)>.
899
900 =head2 Logical Not
901 X<operator, logical, not> X<not>
902
903 Unary "not" returns the logical negation of the expression to its right.
904 It's the equivalent of "!" except for the very low precedence.
905
906 =head2 Logical And
907 X<operator, logical, and> X<and>
908
909 Binary "and" returns the logical conjunction of the two surrounding
910 expressions.  It's equivalent to && except for the very low
911 precedence.  This means that it short-circuits: i.e., the right
912 expression is evaluated only if the left expression is true.
913
914 =head2 Logical or, Defined or, and Exclusive Or
915 X<operator, logical, or> X<operator, logical, xor>
916 X<operator, logical, defined or> X<operator, logical, exclusive or>
917 X<or> X<xor>
918
919 Binary "or" returns the logical disjunction of the two surrounding
920 expressions.  It's equivalent to || except for the very low precedence.
921 This makes it useful for control flow
922
923     print FH $data              or die "Can't write to FH: $!";
924
925 This means that it short-circuits: i.e., the right expression is evaluated
926 only if the left expression is false.  Due to its precedence, you should
927 probably avoid using this for assignment, only for control flow.
928
929     $a = $b or $c;              # bug: this is wrong
930     ($a = $b) or $c;            # really means this
931     $a = $b || $c;              # better written this way
932
933 However, when it's a list-context assignment and you're trying to use
934 "||" for control flow, you probably need "or" so that the assignment
935 takes higher precedence.
936
937     @info = stat($file) || die;     # oops, scalar sense of stat!
938     @info = stat($file) or die;     # better, now @info gets its due
939
940 Then again, you could always use parentheses.
941
942 Binary "xor" returns the exclusive-OR of the two surrounding expressions.
943 It cannot short circuit, of course.
944
945 =head2 C Operators Missing From Perl
946 X<operator, missing from perl> X<&> X<*>
947 X<typecasting> X<(TYPE)>
948
949 Here is what C has that Perl doesn't:
950
951 =over 8
952
953 =item unary &
954
955 Address-of operator.  (But see the "\" operator for taking a reference.)
956
957 =item unary *
958
959 Dereference-address operator. (Perl's prefix dereferencing
960 operators are typed: $, @, %, and &.)
961
962 =item (TYPE)
963
964 Type-casting operator.
965
966 =back
967
968 =head2 Quote and Quote-like Operators
969 X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m>
970 X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>>
971 X<escape sequence> X<escape>
972
973
974 While we usually think of quotes as literal values, in Perl they
975 function as operators, providing various kinds of interpolating and
976 pattern matching capabilities.  Perl provides customary quote characters
977 for these behaviors, but also provides a way for you to choose your
978 quote character for any of them.  In the following table, a C<{}> represents
979 any pair of delimiters you choose.
980
981     Customary  Generic        Meaning        Interpolates
982         ''       q{}          Literal             no
983         ""      qq{}          Literal             yes
984         ``      qx{}          Command             yes*
985                 qw{}         Word list            no
986         //       m{}       Pattern match          yes*
987                 qr{}          Pattern             yes*
988                  s{}{}      Substitution          yes*
989                 tr{}{}    Transliteration         no (but see below)
990         <<EOF                 here-doc            yes*
991
992         * unless the delimiter is ''.
993
994 Non-bracketing delimiters use the same character fore and aft, but the four
995 sorts of brackets (round, angle, square, curly) will all nest, which means
996 that
997
998         q{foo{bar}baz}
999
1000 is the same as
1001
1002         'foo{bar}baz'
1003
1004 Note, however, that this does not always work for quoting Perl code:
1005
1006         $s = q{ if($a eq "}") ... }; # WRONG
1007
1008 is a syntax error. The C<Text::Balanced> module (from CPAN, and
1009 starting from Perl 5.8 part of the standard distribution) is able
1010 to do this properly.
1011
1012 There can be whitespace between the operator and the quoting
1013 characters, except when C<#> is being used as the quoting character.
1014 C<q#foo#> is parsed as the string C<foo>, while C<q #foo#> is the
1015 operator C<q> followed by a comment.  Its argument will be taken
1016 from the next line.  This allows you to write:
1017
1018     s {foo}  # Replace foo
1019       {bar}  # with bar.
1020
1021 The following escape sequences are available in constructs that interpolate
1022 and in transliterations.
1023 X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N> X<\N{}>
1024 X<\o{}>
1025
1026     Sequence     Note  Description
1027     \t                  tab               (HT, TAB)
1028     \n                  newline           (NL)
1029     \r                  return            (CR)
1030     \f                  form feed         (FF)
1031     \b                  backspace         (BS)
1032     \a                  alarm (bell)      (BEL)
1033     \e                  escape            (ESC)
1034     \x{263a}     [1,8]  hex char          (example: SMILEY)
1035     \x1b         [2,8]  restricted range hex char (example: ESC)
1036     \N{name}     [3]    named Unicode character or character sequence
1037     \N{U+263D}   [4,8]  Unicode character (example: FIRST QUARTER MOON)
1038     \c[          [5]    control char      (example: chr(27))
1039     \o{23072}    [6,8]  octal char        (example: SMILEY)
1040     \033         [7,8]  restricted range octal char  (example: ESC)
1041
1042 =over 4
1043
1044 =item [1]
1045
1046 The result is the character specified by the hexadecimal number between
1047 the braces.  See L</[8]> below for details on which character.
1048
1049 Only hexadecimal digits are valid between the braces. If an invalid
1050 character is encountered, a warning will be issued and the invalid
1051 character and all subsequent characters (valid or invalid) within the
1052 braces will be discarded.
1053
1054 If there are no valid digits between the braces, the generated character is
1055 the NULL character (C<\x{00}>).  However, an explicit empty brace (C<\x{}>)
1056 will not cause a warning.
1057
1058 =item [2]
1059
1060 The result is the character specified by the hexadecimal number in the range
1061 0x00 to 0xFF.  See L</[8]> below for details on which character.
1062
1063 Only hexadecimal digits are valid following C<\x>.  When C<\x> is followed
1064 by fewer than two valid digits, any valid digits will be zero-padded.  This
1065 means that C<\x7> will be interpreted as C<\x07> and C<\x> alone will be
1066 interpreted as C<\x00>.  Except at the end of a string, having fewer than
1067 two valid digits will result in a warning.  Note that while the warning
1068 says the illegal character is ignored, it is only ignored as part of the
1069 escape and will still be used as the subsequent character in the string.
1070 For example:
1071
1072   Original    Result    Warns?
1073   "\x7"       "\x07"    no
1074   "\x"        "\x00"    no
1075   "\x7q"      "\x07q"   yes
1076   "\xq"       "\x00q"   yes
1077
1078 =item [3]
1079
1080 The result is the Unicode character or character sequence given by I<name>.
1081 See L<charnames>.
1082
1083 =item [4]
1084
1085 C<\N{U+I<hexadecimal number>}> means the Unicode character whose Unicode code
1086 point is I<hexadecimal number>.
1087
1088 =item [5]
1089
1090 The character following C<\c> is mapped to some other character as shown in the
1091 table:
1092
1093  Sequence   Value
1094    \c@      chr(0)
1095    \cA      chr(1)
1096    \ca      chr(1)
1097    \cB      chr(2)
1098    \cb      chr(2)
1099    ...
1100    \cZ      chr(26)
1101    \cz      chr(26)
1102    \c[      chr(27)
1103    \c]      chr(29)
1104    \c^      chr(30)
1105    \c?      chr(127)
1106
1107 Also, C<\c\I<X>> yields C< chr(28) . "I<X>"> for any I<X>, but cannot come at the
1108 end of a string, because the backslash would be parsed as escaping the end
1109 quote.
1110
1111 On ASCII platforms, the resulting characters from the list above are the
1112 complete set of ASCII controls.  This isn't the case on EBCDIC platforms; see
1113 L<perlebcdic/OPERATOR DIFFERENCES> for the complete list of what these
1114 sequences mean on both ASCII and EBCDIC platforms.
1115
1116 Use of any other character following the "c" besides those listed above is
1117 discouraged, and may become deprecated or forbidden.  What happens for those
1118 other characters currently though, is that the value is derived by inverting
1119 the 7th bit (0x40).
1120
1121 To get platform independent controls, you can use C<\N{...}>.
1122
1123 =item [6]
1124
1125 The result is the character specified by the octal number between the braces.
1126 See L</[8]> below for details on which character.
1127
1128 If a character that isn't an octal digit is encountered, a warning is raised,
1129 and the value is based on the octal digits before it, discarding it and all
1130 following characters up to the closing brace.  It is a fatal error if there are
1131 no octal digits at all.
1132
1133 =item [7]
1134
1135 The result is the character specified by the three digit octal number in the
1136 range 000 to 777 (but best to not use above 077, see next paragraph).  See
1137 L</[8]> below for details on which character.
1138
1139 Some contexts allow 2 or even 1 digit, but any usage without exactly
1140 three digits, the first being a zero, may give unintended results.  (For
1141 example, see L<perlrebackslash/Octal escapes>.)  Starting in Perl 5.14, you may
1142 use C<\o{}> instead which avoids all these problems.  Otherwise, it is best to
1143 use this construct only for ordinals C<\077> and below, remembering to pad to
1144 the left with zeros to make three digits.  For larger ordinals, either use
1145 C<\o{}> , or convert to something else, such as to hex and use C<\x{}>
1146 instead.
1147
1148 Having fewer than 3 digits may lead to a misleading warning message that says
1149 that what follows is ignored.  For example, C<"\128"> in the ASCII character set
1150 is equivalent to the two characters C<"\n8">, but the warning C<Illegal octal
1151 digit '8' ignored> will be thrown.  To avoid this warning, make sure to pad
1152 your octal number with C<0>s: C<"\0128">.
1153
1154 =item [8]
1155
1156 Several of the constructs above specify a character by a number.  That number
1157 gives the character's position in the character set encoding (indexed from 0).
1158 This is called synonymously its ordinal, code position, or code point).  Perl
1159 works on platforms that have a native encoding currently of either ASCII/Latin1
1160 or EBCDIC, each of which allow specification of 256 characters.  In general, if
1161 the number is 255 (0xFF, 0377) or below, Perl interprets this in the platform's
1162 native encoding.  If the number is 256 (0x100, 0400) or above, Perl interprets
1163 it as as a Unicode code point and the result is the corresponding Unicode
1164 character.  For example C<\x{50}> and C<\o{120}> both are the number 80 in
1165 decimal, which is less than 256, so the number is interpreted in the native
1166 character set encoding.  In ASCII the character in the 80th position (indexed
1167 from 0) is the letter "P", and in EBCDIC it is the ampersand symbol "&".
1168 C<\x{100}> and C<\o{400}> are both 256 in decimal, so the number is interpreted
1169 as a Unicode code point no matter what the native encoding is.  The name of the
1170 character in the 100th position (indexed by 0) in Unicode is
1171 C<LATIN CAPITAL LETTER A WITH MACRON>.
1172
1173 There are a couple of exceptions to the above rule.  C<\N{U+I<hex number>}> is
1174 always interpreted as a Unicode code point, so that C<\N{U+0050}> is "P" even
1175 on EBCDIC platforms.  And if L<C<S<use encoding>>|encoding> is in effect, the
1176 number is considered to be in that encoding, and is translated from that into
1177 the platform's native encoding if there is a corresponding native character;
1178 otherwise to Unicode.
1179
1180 =back
1181
1182 B<NOTE>: Unlike C and other languages, Perl has no C<\v> escape sequence for
1183 the vertical tab (VT - ASCII 11), but you may use C<\ck> or C<\x0b>.  (C<\v>
1184 does have meaning in regular expression patterns in Perl, see L<perlre>.)
1185
1186 The following escape sequences are available in constructs that interpolate,
1187 but not in transliterations.
1188 X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q>
1189
1190     \l          lowercase next char
1191     \u          uppercase next char
1192     \L          lowercase till \E
1193     \U          uppercase till \E
1194     \Q          quote non-word characters till \E
1195     \E          end either case modification or quoted section
1196
1197 If C<use locale> is in effect, the case map used by C<\l>, C<\L>,
1198 C<\u> and C<\U> is taken from the current locale.  See L<perllocale>.
1199 If Unicode (for example, C<\N{}> or wide hex characters of 0x100 or
1200 beyond) is being used, the case map used by C<\l>, C<\L>, C<\u> and
1201 C<\U> is as defined by Unicode.
1202
1203 All systems use the virtual C<"\n"> to represent a line terminator,
1204 called a "newline".  There is no such thing as an unvarying, physical
1205 newline character.  It is only an illusion that the operating system,
1206 device drivers, C libraries, and Perl all conspire to preserve.  Not all
1207 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
1208 on a Mac, these are reversed, and on systems without line terminator,
1209 printing C<"\n"> may emit no actual data.  In general, use C<"\n"> when
1210 you mean a "newline" for your system, but use the literal ASCII when you
1211 need an exact character.  For example, most networking protocols expect
1212 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
1213 and although they often accept just C<"\012">, they seldom tolerate just
1214 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
1215 you may be burned some day.
1216 X<newline> X<line terminator> X<eol> X<end of line>
1217 X<\n> X<\r> X<\r\n>
1218
1219 For constructs that do interpolate, variables beginning with "C<$>"
1220 or "C<@>" are interpolated.  Subscripted variables such as C<$a[3]> or
1221 C<< $href->{key}[0] >> are also interpolated, as are array and hash slices.
1222 But method calls such as C<< $obj->meth >> are not.
1223
1224 Interpolating an array or slice interpolates the elements in order,
1225 separated by the value of C<$">, so is equivalent to interpolating
1226 C<join $", @array>.    "Punctuation" arrays such as C<@*> are only
1227 interpolated if the name is enclosed in braces C<@{*}>, but special
1228 arrays C<@_>, C<@+>, and C<@-> are interpolated, even without braces.
1229
1230 For double-quoted strings, the quoting from C<\Q> is applied after
1231 interpolation and escapes are processed.
1232
1233     "abc\Qfoo\tbar$s\Exyz"
1234
1235 is equivalent to
1236
1237     "abc" . quotemeta("foo\tbar$s") . "xyz"
1238
1239 For the pattern of regex operators (C<qr//>, C<m//> and C<s///>),
1240 the quoting from C<\Q> is applied after interpolation is processed,
1241 but before escapes are processed. This allows the pattern to match
1242 literally (except for C<$> and C<@>). For example, the following matches:
1243
1244     '\s\t' =~ /\Q\s\t/
1245
1246 Because C<$> or C<@> trigger interpolation, you'll need to use something
1247 like C</\Quser\E\@\Qhost/> to match them literally.
1248
1249 Patterns are subject to an additional level of interpretation as a
1250 regular expression.  This is done as a second pass, after variables are
1251 interpolated, so that regular expressions may be incorporated into the
1252 pattern from the variables.  If this is not what you want, use C<\Q> to
1253 interpolate a variable literally.
1254
1255 Apart from the behavior described above, Perl does not expand
1256 multiple levels of interpolation.  In particular, contrary to the
1257 expectations of shell programmers, back-quotes do I<NOT> interpolate
1258 within double quotes, nor do single quotes impede evaluation of
1259 variables when used within double quotes.
1260
1261 =head2 Regexp Quote-Like Operators
1262 X<operator, regexp>
1263
1264 Here are the quote-like operators that apply to pattern
1265 matching and related activities.
1266
1267 =over 8
1268
1269 =item qr/STRING/msixpo
1270 X<qr> X</i> X</m> X</o> X</s> X</x> X</p>
1271
1272 This operator quotes (and possibly compiles) its I<STRING> as a regular
1273 expression.  I<STRING> is interpolated the same way as I<PATTERN>
1274 in C<m/PATTERN/>.  If "'" is used as the delimiter, no interpolation
1275 is done.  Returns a Perl value which may be used instead of the
1276 corresponding C</STRING/msixpo> expression. The returned value is a
1277 normalized version of the original pattern. It magically differs from
1278 a string containing the same characters: C<ref(qr/x/)> returns "Regexp",
1279 even though dereferencing the result returns undef.
1280
1281 For example,
1282
1283     $rex = qr/my.STRING/is;
1284     print $rex;                 # prints (?si-xm:my.STRING)
1285     s/$rex/foo/;
1286
1287 is equivalent to
1288
1289     s/my.STRING/foo/is;
1290
1291 The result may be used as a subpattern in a match:
1292
1293     $re = qr/$pattern/;
1294     $string =~ /foo${re}bar/;   # can be interpolated in other patterns
1295     $string =~ $re;             # or used standalone
1296     $string =~ /$re/;           # or this way
1297
1298 Since Perl may compile the pattern at the moment of execution of qr()
1299 operator, using qr() may have speed advantages in some situations,
1300 notably if the result of qr() is used standalone:
1301
1302     sub match {
1303         my $patterns = shift;
1304         my @compiled = map qr/$_/i, @$patterns;
1305         grep {
1306             my $success = 0;
1307             foreach my $pat (@compiled) {
1308                 $success = 1, last if /$pat/;
1309             }
1310             $success;
1311         } @_;
1312     }
1313
1314 Precompilation of the pattern into an internal representation at
1315 the moment of qr() avoids a need to recompile the pattern every
1316 time a match C</$pat/> is attempted.  (Perl has many other internal
1317 optimizations, but none would be triggered in the above example if
1318 we did not use qr() operator.)
1319
1320 Options (specified by the following modifiers) are:
1321
1322     m   Treat string as multiple lines.
1323     s   Treat string as single line. (Make . match a newline)
1324     i   Do case-insensitive pattern matching.
1325     x   Use extended regular expressions.
1326     p   When matching preserve a copy of the matched string so
1327         that ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} will be defined.
1328     o   Compile pattern only once.
1329
1330 If a precompiled pattern is embedded in a larger pattern then the effect
1331 of 'msixp' will be propagated appropriately.  The effect of the 'o'
1332 modifier has is not propagated, being restricted to those patterns
1333 explicitly using it.
1334
1335 Several other modifiers to control the character set semantics were
1336 added for 5.14 that, unlike the ones listed above,  may not be used
1337 after the final pattern delimiter, but only following a C<"(?"> inside
1338 the regular expression.  (It is planned in 5.16 to make them usable in
1339 the suffix position.)  These are B<C<"a">>, B<C<"d">>, B<C<"l">>, and
1340 B<C<"u">>.  They are documented in L<perlre/Extended Patterns>.
1341
1342 See L<perlre> for additional information on valid syntax for STRING, and
1343 for a detailed look at the semantics of regular expressions.
1344
1345 =item m/PATTERN/msixpogc
1346 X<m> X<operator, match>
1347 X<regexp, options> X<regexp> X<regex, options> X<regex>
1348 X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c>
1349
1350 =item /PATTERN/msixpogc
1351
1352 Searches a string for a pattern match, and in scalar context returns
1353 true if it succeeds, false if it fails.  If no string is specified
1354 via the C<=~> or C<!~> operator, the $_ string is searched.  (The
1355 string specified with C<=~> need not be an lvalue--it may be the
1356 result of an expression evaluation, but remember the C<=~> binds
1357 rather tightly.)  See also L<perlre>.  See L<perllocale> for
1358 discussion of additional considerations that apply when C<use locale>
1359 is in effect.
1360
1361 Options are as described in C<qr//>; in addition, the following match
1362 process modifiers are available:
1363
1364  g  Match globally, i.e., find all occurrences.
1365  c  Do not reset search position on a failed match when /g is in effect.
1366
1367 If "/" is the delimiter then the initial C<m> is optional.  With the C<m>
1368 you can use any pair of non-whitespace characters
1369 as delimiters.  This is particularly useful for matching path names
1370 that contain "/", to avoid LTS (leaning toothpick syndrome).  If "?" is
1371 the delimiter, then a match-only-once rule applies,
1372 described in C<m?PATTERN?> below.
1373 If "'" is the delimiter, no interpolation is performed on the PATTERN.
1374 When using a character valid in an identifier, whitespace is required
1375 after the C<m>.
1376
1377 PATTERN may contain variables, which will be interpolated (and the
1378 pattern recompiled) every time the pattern search is evaluated, except
1379 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
1380 C<$|> are not interpolated because they look like end-of-string tests.)
1381 If you want such a pattern to be compiled only once, add a C</o> after
1382 the trailing delimiter.  This avoids expensive run-time recompilations,
1383 and is useful when the value you are interpolating won't change over
1384 the life of the script.  However, mentioning C</o> constitutes a promise
1385 that you won't change the variables in the pattern.  If you change them,
1386 Perl won't even notice.  See also L<"qr/STRING/msixpo">.
1387
1388 =item The empty pattern //
1389
1390 If the PATTERN evaluates to the empty string, the last
1391 I<successfully> matched regular expression is used instead. In this
1392 case, only the C<g> and C<c> flags on the empty pattern is honoured -
1393 the other flags are taken from the original pattern. If no match has
1394 previously succeeded, this will (silently) act instead as a genuine
1395 empty pattern (which will always match).
1396
1397 Note that it's possible to confuse Perl into thinking C<//> (the empty
1398 regex) is really C<//> (the defined-or operator).  Perl is usually pretty
1399 good about this, but some pathological cases might trigger this, such as
1400 C<$a///> (is that C<($a) / (//)> or C<$a // />?) and C<print $fh //>
1401 (C<print $fh(//> or C<print($fh //>?).  In all of these examples, Perl
1402 will assume you meant defined-or.  If you meant the empty regex, just
1403 use parentheses or spaces to disambiguate, or even prefix the empty
1404 regex with an C<m> (so C<//> becomes C<m//>).
1405
1406 =item Matching in list context
1407
1408 If the C</g> option is not used, C<m//> in list context returns a
1409 list consisting of the subexpressions matched by the parentheses in the
1410 pattern, i.e., (C<$1>, C<$2>, C<$3>...).  (Note that here C<$1> etc. are
1411 also set, and that this differs from Perl 4's behavior.)  When there are
1412 no parentheses in the pattern, the return value is the list C<(1)> for
1413 success.  With or without parentheses, an empty list is returned upon
1414 failure.
1415
1416 Examples:
1417
1418     open(TTY, '/dev/tty');
1419     <TTY> =~ /^y/i && foo();    # do foo if desired
1420
1421     if (/Version: *([0-9.]*)/) { $version = $1; }
1422
1423     next if m#^/usr/spool/uucp#;
1424
1425     # poor man's grep
1426     $arg = shift;
1427     while (<>) {
1428         print if /$arg/o;       # compile only once
1429     }
1430
1431     if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
1432
1433 This last example splits $foo into the first two words and the
1434 remainder of the line, and assigns those three fields to $F1, $F2, and
1435 $Etc.  The conditional is true if any variables were assigned, i.e., if
1436 the pattern matched.
1437
1438 The C</g> modifier specifies global pattern matching--that is,
1439 matching as many times as possible within the string. How it behaves
1440 depends on the context. In list context, it returns a list of the
1441 substrings matched by any capturing parentheses in the regular
1442 expression. If there are no parentheses, it returns a list of all
1443 the matched strings, as if there were parentheses around the whole
1444 pattern.
1445
1446 In scalar context, each execution of C<m//g> finds the next match,
1447 returning true if it matches, and false if there is no further match.
1448 The position after the last match can be read or set using the C<pos()>
1449 function; see L<perlfunc/pos>. A failed match normally resets the
1450 search position to the beginning of the string, but you can avoid that
1451 by adding the C</c> modifier (e.g. C<m//gc>). Modifying the target
1452 string also resets the search position.
1453
1454 =item \G assertion
1455
1456 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
1457 zero-width assertion that matches the exact position where the
1458 previous C<m//g>, if any, left off. Without the C</g> modifier, the
1459 C<\G> assertion still anchors at C<pos()> as it was at the start of
1460 the operation (see L<perlfunc/pos>), but the match is of course only
1461 attempted once. Using C<\G> without C</g> on a target string that has
1462 not previously had a C</g> match applied to it is the same as using
1463 the C<\A> assertion to match the beginning of the string.  Note also
1464 that, currently, C<\G> is only properly supported when anchored at the
1465 very beginning of the pattern.
1466
1467 Examples:
1468
1469     # list context
1470     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
1471
1472     # scalar context
1473     $/ = "";
1474     while (defined($paragraph = <>)) {
1475         while ($paragraph =~ /[a-z]['")]*[.!?]+['")]*\s/g) {
1476             $sentences++;
1477         }
1478     }
1479     print "$sentences\n";
1480
1481     # using m//gc with \G
1482     $_ = "ppooqppqq";
1483     while ($i++ < 2) {
1484         print "1: '";
1485         print $1 while /(o)/gc; print "', pos=", pos, "\n";
1486         print "2: '";
1487         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
1488         print "3: '";
1489         print $1 while /(p)/gc; print "', pos=", pos, "\n";
1490     }
1491     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
1492
1493 The last example should print:
1494
1495     1: 'oo', pos=4
1496     2: 'q', pos=5
1497     3: 'pp', pos=7
1498     1: '', pos=7
1499     2: 'q', pos=8
1500     3: '', pos=8
1501     Final: 'q', pos=8
1502
1503 Notice that the final match matched C<q> instead of C<p>, which a match
1504 without the C<\G> anchor would have done. Also note that the final match
1505 did not update C<pos>. C<pos> is only updated on a C</g> match. If the
1506 final match did indeed match C<p>, it's a good bet that you're running an
1507 older (pre-5.6.0) Perl.
1508
1509 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
1510 combine several regexps like this to process a string part-by-part,
1511 doing different actions depending on which regexp matched.  Each
1512 regexp tries to match where the previous one leaves off.
1513
1514  $_ = <<'EOL';
1515     $url = URI::URL->new( "http://example.com/" ); die if $url eq "xXx";
1516  EOL
1517  LOOP:
1518     {
1519      print(" digits"),       redo LOOP if /\G\d+\b[,.;]?\s*/gc;
1520      print(" lowercase"),    redo LOOP if /\G[a-z]+\b[,.;]?\s*/gc;
1521      print(" UPPERCASE"),    redo LOOP if /\G[A-Z]+\b[,.;]?\s*/gc;
1522      print(" Capitalized"),  redo LOOP if /\G[A-Z][a-z]+\b[,.;]?\s*/gc;
1523      print(" MiXeD"),        redo LOOP if /\G[A-Za-z]+\b[,.;]?\s*/gc;
1524      print(" alphanumeric"), redo LOOP if /\G[A-Za-z0-9]+\b[,.;]?\s*/gc;
1525      print(" line-noise"),   redo LOOP if /\G[^A-Za-z0-9]+/gc;
1526      print ". That's all!\n";
1527     }
1528
1529 Here is the output (split into several lines):
1530
1531         line-noise lowercase line-noise UPPERCASE line-noise UPPERCASE
1532         line-noise lowercase line-noise lowercase line-noise lowercase
1533         lowercase line-noise lowercase lowercase line-noise lowercase
1534         lowercase line-noise MiXeD line-noise. That's all!
1535
1536 =item m?PATTERN?
1537 X<?> X<operator, match-once>
1538
1539 =item ?PATTERN?
1540
1541 This is just like the C<m/PATTERN/> search, except that it matches
1542 only once between calls to the reset() operator.  This is a useful
1543 optimization when you want to see only the first occurrence of
1544 something in each file of a set of files, for instance.  Only C<m??>
1545 patterns local to the current package are reset.
1546
1547     while (<>) {
1548         if (m?^$?) {
1549                             # blank line between header and body
1550         }
1551     } continue {
1552         reset if eof;       # clear m?? status for next file
1553     }
1554
1555 The match-once behaviour is controlled by the match delimiter being
1556 C<?>; with any other delimiter this is the normal C<m//> operator.  
1557
1558 For historical reasons, the leading C<m> in C<m?PATTERN?> is optional,
1559 but the resulting C<?PATTERN?> syntax is deprecated, will warn on
1560 usage and may be removed from a future stable release of Perl without
1561 further notice.
1562
1563 =item s/PATTERN/REPLACEMENT/msixpogcer
1564 X<substitute> X<substitution> X<replace> X<regexp, replace>
1565 X<regexp, substitute> X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c> X</e> X</r>
1566
1567 Searches a string for a pattern, and if found, replaces that pattern
1568 with the replacement text and returns the number of substitutions
1569 made.  Otherwise it returns false (specifically, the empty string).
1570
1571 If the C</r> (non-destructive) option is used then it will perform the
1572 substitution on a copy of the string and return the copy whether or not a
1573 substitution occurred. The original string will always remain unchanged in
1574 this case. The copy will always be a plain string, even if the input is an
1575 object or a tied variable.
1576
1577 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
1578 variable is searched and modified.  (The string specified with C<=~> must
1579 be scalar variable, an array element, a hash element, or an assignment
1580 to one of those, i.e., an lvalue.)
1581
1582 If the delimiter chosen is a single quote, no interpolation is
1583 done on either the PATTERN or the REPLACEMENT.  Otherwise, if the
1584 PATTERN contains a $ that looks like a variable rather than an
1585 end-of-string test, the variable will be interpolated into the pattern
1586 at run-time.  If you want the pattern compiled only once the first time
1587 the variable is interpolated, use the C</o> option.  If the pattern
1588 evaluates to the empty string, the last successfully executed regular
1589 expression is used instead.  See L<perlre> for further explanation on these.
1590 See L<perllocale> for discussion of additional considerations that apply
1591 when C<use locale> is in effect.
1592
1593 Options are as with m// with the addition of the following replacement
1594 specific options:
1595
1596     e   Evaluate the right side as an expression.
1597     ee  Evaluate the right side as a string then eval the result.
1598     r   Return substitution and leave the original string untouched.
1599
1600 Any non-whitespace delimiter may replace the slashes.  Add space after
1601 the C<s> when using a character allowed in identifiers.  If single quotes
1602 are used, no interpretation is done on the replacement string (the C</e>
1603 modifier overrides this, however).  Unlike Perl 4, Perl 5 treats backticks
1604 as normal delimiters; the replacement text is not evaluated as a command.
1605 If the PATTERN is delimited by bracketing quotes, the REPLACEMENT has
1606 its own pair of quotes, which may or may not be bracketing quotes, e.g.,
1607 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
1608 replacement portion to be treated as a full-fledged Perl expression
1609 and evaluated right then and there.  It is, however, syntax checked at
1610 compile-time. A second C<e> modifier will cause the replacement portion
1611 to be C<eval>ed before being run as a Perl expression.
1612
1613 Examples:
1614
1615     s/\bgreen\b/mauve/g;                # don't change wintergreen
1616
1617     $path =~ s|/usr/bin|/usr/local/bin|;
1618
1619     s/Login: $foo/Login: $bar/; # run-time pattern
1620
1621     ($foo = $bar) =~ s/this/that/;      # copy first, then change
1622     ($foo = "$bar") =~ s/this/that/;    # convert to string, copy, then change
1623     $foo = $bar =~ s/this/that/r;       # Same as above using /r
1624     $foo = $bar =~ s/this/that/r
1625                 =~ s/that/the other/r;  # Chained substitutes using /r
1626     @foo = map { s/this/that/r } @bar   # /r is very useful in maps
1627
1628     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-count
1629
1630     $_ = 'abc123xyz';
1631     s/\d+/$&*2/e;               # yields 'abc246xyz'
1632     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
1633     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
1634
1635     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
1636     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
1637     s/^=(\w+)/pod($1)/ge;       # use function call
1638
1639     $_ = 'abc123xyz';
1640     $a = s/abc/def/r;           # $a is 'def123xyz' and
1641                                 # $_ remains 'abc123xyz'.
1642
1643     # expand variables in $_, but dynamics only, using
1644     # symbolic dereferencing
1645     s/\$(\w+)/${$1}/g;
1646
1647     # Add one to the value of any numbers in the string
1648     s/(\d+)/1 + $1/eg;
1649
1650     # This will expand any embedded scalar variable
1651     # (including lexicals) in $_ : First $1 is interpolated
1652     # to the variable name, and then evaluated
1653     s/(\$\w+)/$1/eeg;
1654
1655     # Delete (most) C comments.
1656     $program =~ s {
1657         /\*     # Match the opening delimiter.
1658         .*?     # Match a minimal number of characters.
1659         \*/     # Match the closing delimiter.
1660     } []gsx;
1661
1662     s/^\s*(.*?)\s*$/$1/;        # trim whitespace in $_, expensively
1663
1664     for ($variable) {           # trim whitespace in $variable, cheap
1665         s/^\s+//;
1666         s/\s+$//;
1667     }
1668
1669     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
1670
1671 Note the use of $ instead of \ in the last example.  Unlike
1672 B<sed>, we use the \<I<digit>> form in only the left hand side.
1673 Anywhere else it's $<I<digit>>.
1674
1675 Occasionally, you can't use just a C</g> to get all the changes
1676 to occur that you might want.  Here are two common cases:
1677
1678     # put commas in the right places in an integer
1679     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;
1680
1681     # expand tabs to 8-column spacing
1682     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
1683
1684 =back
1685
1686 =head2 Quote-Like Operators
1687 X<operator, quote-like>
1688
1689 =over 4
1690
1691 =item q/STRING/
1692 X<q> X<quote, single> X<'> X<''>
1693
1694 =item 'STRING'
1695
1696 A single-quoted, literal string.  A backslash represents a backslash
1697 unless followed by the delimiter or another backslash, in which case
1698 the delimiter or backslash is interpolated.
1699
1700     $foo = q!I said, "You said, 'She said it.'"!;
1701     $bar = q('This is it.');
1702     $baz = '\n';                # a two-character string
1703
1704 =item qq/STRING/
1705 X<qq> X<quote, double> X<"> X<"">
1706
1707 =item "STRING"
1708
1709 A double-quoted, interpolated string.
1710
1711     $_ .= qq
1712      (*** The previous line contains the naughty word "$1".\n)
1713                 if /\b(tcl|java|python)\b/i;      # :-)
1714     $baz = "\n";                # a one-character string
1715
1716 =item qx/STRING/
1717 X<qx> X<`> X<``> X<backtick>
1718
1719 =item `STRING`
1720
1721 A string which is (possibly) interpolated and then executed as a
1722 system command with C</bin/sh> or its equivalent.  Shell wildcards,
1723 pipes, and redirections will be honored.  The collected standard
1724 output of the command is returned; standard error is unaffected.  In
1725 scalar context, it comes back as a single (potentially multi-line)
1726 string, or undef if the command failed.  In list context, returns a
1727 list of lines (however you've defined lines with $/ or
1728 $INPUT_RECORD_SEPARATOR), or an empty list if the command failed.
1729
1730 Because backticks do not affect standard error, use shell file descriptor
1731 syntax (assuming the shell supports this) if you care to address this.
1732 To capture a command's STDERR and STDOUT together:
1733
1734     $output = `cmd 2>&1`;
1735
1736 To capture a command's STDOUT but discard its STDERR:
1737
1738     $output = `cmd 2>/dev/null`;
1739
1740 To capture a command's STDERR but discard its STDOUT (ordering is
1741 important here):
1742
1743     $output = `cmd 2>&1 1>/dev/null`;
1744
1745 To exchange a command's STDOUT and STDERR in order to capture the STDERR
1746 but leave its STDOUT to come out the old STDERR:
1747
1748     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
1749
1750 To read both a command's STDOUT and its STDERR separately, it's easiest
1751 to redirect them separately to files, and then read from those files
1752 when the program is done:
1753
1754     system("program args 1>program.stdout 2>program.stderr");
1755
1756 The STDIN filehandle used by the command is inherited from Perl's STDIN.
1757 For example:
1758
1759     open BLAM, "blam" || die "Can't open: $!";
1760     open STDIN, "<&BLAM";
1761     print `sort`;
1762
1763 will print the sorted contents of the file "blam".
1764
1765 Using single-quote as a delimiter protects the command from Perl's
1766 double-quote interpolation, passing it on to the shell instead:
1767
1768     $perl_info  = qx(ps $$);            # that's Perl's $$
1769     $shell_info = qx'ps $$';            # that's the new shell's $$
1770
1771 How that string gets evaluated is entirely subject to the command
1772 interpreter on your system.  On most platforms, you will have to protect
1773 shell metacharacters if you want them treated literally.  This is in
1774 practice difficult to do, as it's unclear how to escape which characters.
1775 See L<perlsec> for a clean and safe example of a manual fork() and exec()
1776 to emulate backticks safely.
1777
1778 On some platforms (notably DOS-like ones), the shell may not be
1779 capable of dealing with multiline commands, so putting newlines in
1780 the string may not get you what you want.  You may be able to evaluate
1781 multiple commands in a single line by separating them with the command
1782 separator character, if your shell supports that (e.g. C<;> on many Unix
1783 shells; C<&> on the Windows NT C<cmd> shell).
1784
1785 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1786 output before starting the child process, but this may not be supported
1787 on some platforms (see L<perlport>).  To be safe, you may need to set
1788 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1789 C<IO::Handle> on any open handles.
1790
1791 Beware that some command shells may place restrictions on the length
1792 of the command line.  You must ensure your strings don't exceed this
1793 limit after any necessary interpolations.  See the platform-specific
1794 release notes for more details about your particular environment.
1795
1796 Using this operator can lead to programs that are difficult to port,
1797 because the shell commands called vary between systems, and may in
1798 fact not be present at all.  As one example, the C<type> command under
1799 the POSIX shell is very different from the C<type> command under DOS.
1800 That doesn't mean you should go out of your way to avoid backticks
1801 when they're the right way to get something done.  Perl was made to be
1802 a glue language, and one of the things it glues together is commands.
1803 Just understand what you're getting yourself into.
1804
1805 See L</"I/O Operators"> for more discussion.
1806
1807 =item qw/STRING/
1808 X<qw> X<quote, list> X<quote, words>
1809
1810 Evaluates to a list of the words extracted out of STRING, using embedded
1811 whitespace as the word delimiters.  It can be understood as being roughly
1812 equivalent to:
1813
1814     split(' ', q/STRING/);
1815
1816 the differences being that it generates a real list at compile time, and
1817 in scalar context it returns the last element in the list.  So
1818 this expression:
1819
1820     qw(foo bar baz)
1821
1822 is semantically equivalent to the list:
1823
1824     'foo', 'bar', 'baz'
1825
1826 Some frequently seen examples:
1827
1828     use POSIX qw( setlocale localeconv )
1829     @EXPORT = qw( foo bar baz );
1830
1831 A common mistake is to try to separate the words with comma or to
1832 put comments into a multi-line C<qw>-string.  For this reason, the
1833 C<use warnings> pragma and the B<-w> switch (that is, the C<$^W> variable)
1834 produces warnings if the STRING contains the "," or the "#" character.
1835
1836
1837 =item tr/SEARCHLIST/REPLACEMENTLIST/cdsr
1838 X<tr> X<y> X<transliterate> X</c> X</d> X</s>
1839
1840 =item y/SEARCHLIST/REPLACEMENTLIST/cdsr
1841
1842 Transliterates all occurrences of the characters found in the search list
1843 with the corresponding character in the replacement list.  It returns
1844 the number of characters replaced or deleted.  If no string is
1845 specified via the =~ or !~ operator, the $_ string is transliterated.  (The
1846 string specified with =~ must be a scalar variable, an array element, a
1847 hash element, or an assignment to one of those, i.e., an lvalue.)
1848
1849 If the C</r> (non-destructive) option is used then it will perform the
1850 replacement on a copy of the string and return the copy whether or not it
1851 was modified. The original string will always remain unchanged in
1852 this case. The copy will always be a plain string, even if the input is an
1853 object or a tied variable.
1854
1855 A character range may be specified with a hyphen, so C<tr/A-J/0-9/>
1856 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
1857 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
1858 SEARCHLIST is delimited by bracketing quotes, the REPLACEMENTLIST has
1859 its own pair of quotes, which may or may not be bracketing quotes,
1860 e.g., C<tr[A-Z][a-z]> or C<tr(+\-*/)/ABCD/>.
1861
1862 Note that C<tr> does B<not> do regular expression character classes
1863 such as C<\d> or C<[:lower:]>.  The C<tr> operator is not equivalent to
1864 the tr(1) utility.  If you want to map strings between lower/upper
1865 cases, see L<perlfunc/lc> and L<perlfunc/uc>, and in general consider
1866 using the C<s> operator if you need regular expressions.
1867
1868 Note also that the whole range idea is rather unportable between
1869 character sets--and even within character sets they may cause results
1870 you probably didn't expect.  A sound principle is to use only ranges
1871 that begin from and end at either alphabets of equal case (a-e, A-E),
1872 or digits (0-4).  Anything else is unsafe.  If in doubt, spell out the
1873 character sets in full.
1874
1875 Options:
1876
1877     c   Complement the SEARCHLIST.
1878     d   Delete found but unreplaced characters.
1879     s   Squash duplicate replaced characters.
1880     r   Return the modified string and leave the original string
1881         untouched.
1882
1883 If the C</c> modifier is specified, the SEARCHLIST character set
1884 is complemented.  If the C</d> modifier is specified, any characters
1885 specified by SEARCHLIST not found in REPLACEMENTLIST are deleted.
1886 (Note that this is slightly more flexible than the behavior of some
1887 B<tr> programs, which delete anything they find in the SEARCHLIST,
1888 period.) If the C</s> modifier is specified, sequences of characters
1889 that were transliterated to the same character are squashed down
1890 to a single instance of the character.
1891
1892 If the C</d> modifier is used, the REPLACEMENTLIST is always interpreted
1893 exactly as specified.  Otherwise, if the REPLACEMENTLIST is shorter
1894 than the SEARCHLIST, the final character is replicated till it is long
1895 enough.  If the REPLACEMENTLIST is empty, the SEARCHLIST is replicated.
1896 This latter is useful for counting characters in a class or for
1897 squashing character sequences in a class.
1898
1899 Examples:
1900
1901     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case
1902
1903     $cnt = tr/*/*/;             # count the stars in $_
1904
1905     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
1906
1907     $cnt = tr/0-9//;            # count the digits in $_
1908
1909     tr/a-zA-Z//s;               # bookkeeper -> bokeper
1910
1911     ($HOST = $host) =~ tr/a-z/A-Z/;
1912     $HOST = $host =~ tr/a-z/A-Z/r;   # same thing
1913
1914     $HOST = $host =~ tr/a-z/A-Z/r    # chained with s///
1915                   =~ s/:/ -p/r;
1916
1917     tr/a-zA-Z/ /cs;             # change non-alphas to single space
1918
1919     @stripped = map tr/a-zA-Z/ /csr, @original;
1920                                 # /r with map
1921
1922     tr [\200-\377]
1923        [\000-\177];             # delete 8th bit
1924
1925 If multiple transliterations are given for a character, only the
1926 first one is used:
1927
1928     tr/AAA/XYZ/
1929
1930 will transliterate any A to X.
1931
1932 Because the transliteration table is built at compile time, neither
1933 the SEARCHLIST nor the REPLACEMENTLIST are subjected to double quote
1934 interpolation.  That means that if you want to use variables, you
1935 must use an eval():
1936
1937     eval "tr/$oldlist/$newlist/";
1938     die $@ if $@;
1939
1940     eval "tr/$oldlist/$newlist/, 1" or die $@;
1941
1942 =item <<EOF
1943 X<here-doc> X<heredoc> X<here-document> X<<< << >>>
1944
1945 A line-oriented form of quoting is based on the shell "here-document"
1946 syntax.  Following a C<< << >> you specify a string to terminate
1947 the quoted material, and all lines following the current line down to
1948 the terminating string are the value of the item.
1949
1950 The terminating string may be either an identifier (a word), or some
1951 quoted text.  An unquoted identifier works like double quotes.
1952 There may not be a space between the C<< << >> and the identifier,
1953 unless the identifier is explicitly quoted.  (If you put a space it
1954 will be treated as a null identifier, which is valid, and matches the
1955 first empty line.)  The terminating string must appear by itself
1956 (unquoted and with no surrounding whitespace) on the terminating line.
1957
1958 If the terminating string is quoted, the type of quotes used determine
1959 the treatment of the text.
1960
1961 =over 4
1962
1963 =item Double Quotes
1964
1965 Double quotes indicate that the text will be interpolated using exactly
1966 the same rules as normal double quoted strings.
1967
1968        print <<EOF;
1969     The price is $Price.
1970     EOF
1971
1972        print << "EOF"; # same as above
1973     The price is $Price.
1974     EOF
1975
1976
1977 =item Single Quotes
1978
1979 Single quotes indicate the text is to be treated literally with no
1980 interpolation of its content. This is similar to single quoted
1981 strings except that backslashes have no special meaning, with C<\\>
1982 being treated as two backslashes and not one as they would in every
1983 other quoting construct.
1984
1985 This is the only form of quoting in perl where there is no need
1986 to worry about escaping content, something that code generators
1987 can and do make good use of.
1988
1989 =item Backticks
1990
1991 The content of the here doc is treated just as it would be if the
1992 string were embedded in backticks. Thus the content is interpolated
1993 as though it were double quoted and then executed via the shell, with
1994 the results of the execution returned.
1995
1996        print << `EOC`; # execute command and get results
1997     echo hi there
1998     EOC
1999
2000 =back
2001
2002 It is possible to stack multiple here-docs in a row:
2003
2004        print <<"foo", <<"bar"; # you can stack them
2005     I said foo.
2006     foo
2007     I said bar.
2008     bar
2009
2010        myfunc(<< "THIS", 23, <<'THAT');
2011     Here's a line
2012     or two.
2013     THIS
2014     and here's another.
2015     THAT
2016
2017 Just don't forget that you have to put a semicolon on the end
2018 to finish the statement, as Perl doesn't know you're not going to
2019 try to do this:
2020
2021        print <<ABC
2022     179231
2023     ABC
2024        + 20;
2025
2026 If you want to remove the line terminator from your here-docs,
2027 use C<chomp()>.
2028
2029     chomp($string = <<'END');
2030     This is a string.
2031     END
2032
2033 If you want your here-docs to be indented with the rest of the code,
2034 you'll need to remove leading whitespace from each line manually:
2035
2036     ($quote = <<'FINIS') =~ s/^\s+//gm;
2037        The Road goes ever on and on,
2038        down from the door where it began.
2039     FINIS
2040
2041 If you use a here-doc within a delimited construct, such as in C<s///eg>,
2042 the quoted material must come on the lines following the final delimiter.
2043 So instead of
2044
2045     s/this/<<E . 'that'
2046     the other
2047     E
2048      . 'more '/eg;
2049
2050 you have to write
2051
2052     s/this/<<E . 'that'
2053      . 'more '/eg;
2054     the other
2055     E
2056
2057 If the terminating identifier is on the last line of the program, you
2058 must be sure there is a newline after it; otherwise, Perl will give the
2059 warning B<Can't find string terminator "END" anywhere before EOF...>.
2060
2061 Additionally, the quoting rules for the end of string identifier are not
2062 related to Perl's quoting rules. C<q()>, C<qq()>, and the like are not
2063 supported in place of C<''> and C<"">, and the only interpolation is for
2064 backslashing the quoting character:
2065
2066     print << "abc\"def";
2067     testing...
2068     abc"def
2069
2070 Finally, quoted strings cannot span multiple lines.  The general rule is
2071 that the identifier must be a string literal.  Stick with that, and you
2072 should be safe.
2073
2074 =back
2075
2076 =head2 Gory details of parsing quoted constructs
2077 X<quote, gory details>
2078
2079 When presented with something that might have several different
2080 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
2081 principle to pick the most probable interpretation.  This strategy
2082 is so successful that Perl programmers often do not suspect the
2083 ambivalence of what they write.  But from time to time, Perl's
2084 notions differ substantially from what the author honestly meant.
2085
2086 This section hopes to clarify how Perl handles quoted constructs.
2087 Although the most common reason to learn this is to unravel labyrinthine
2088 regular expressions, because the initial steps of parsing are the
2089 same for all quoting operators, they are all discussed together.
2090
2091 The most important Perl parsing rule is the first one discussed
2092 below: when processing a quoted construct, Perl first finds the end
2093 of that construct, then interprets its contents.  If you understand
2094 this rule, you may skip the rest of this section on the first
2095 reading.  The other rules are likely to contradict the user's
2096 expectations much less frequently than this first one.
2097
2098 Some passes discussed below are performed concurrently, but because
2099 their results are the same, we consider them individually.  For different
2100 quoting constructs, Perl performs different numbers of passes, from
2101 one to four, but these passes are always performed in the same order.
2102
2103 =over 4
2104
2105 =item Finding the end
2106
2107 The first pass is finding the end of the quoted construct, where
2108 the information about the delimiters is used in parsing.
2109 During this search, text between the starting and ending delimiters
2110 is copied to a safe location. The text copied gets delimiter-independent.
2111
2112 If the construct is a here-doc, the ending delimiter is a line
2113 that has a terminating string as the content. Therefore C<<<EOF> is
2114 terminated by C<EOF> immediately followed by C<"\n"> and starting
2115 from the first column of the terminating line.
2116 When searching for the terminating line of a here-doc, nothing
2117 is skipped. In other words, lines after the here-doc syntax
2118 are compared with the terminating string line by line.
2119
2120 For the constructs except here-docs, single characters are used as starting
2121 and ending delimiters. If the starting delimiter is an opening punctuation
2122 (that is C<(>, C<[>, C<{>, or C<< < >>), the ending delimiter is the
2123 corresponding closing punctuation (that is C<)>, C<]>, C<}>, or C<< > >>).
2124 If the starting delimiter is an unpaired character like C</> or a closing
2125 punctuation, the ending delimiter is same as the starting delimiter.
2126 Therefore a C</> terminates a C<qq//> construct, while a C<]> terminates
2127 C<qq[]> and C<qq]]> constructs.
2128
2129 When searching for single-character delimiters, escaped delimiters
2130 and C<\\> are skipped. For example, while searching for terminating C</>,
2131 combinations of C<\\> and C<\/> are skipped.  If the delimiters are
2132 bracketing, nested pairs are also skipped.  For example, while searching
2133 for closing C<]> paired with the opening C<[>, combinations of C<\\>, C<\]>,
2134 and C<\[> are all skipped, and nested C<[> and C<]> are skipped as well.
2135 However, when backslashes are used as the delimiters (like C<qq\\> and
2136 C<tr\\\>), nothing is skipped.
2137 During the search for the end, backslashes that escape delimiters
2138 are removed (exactly speaking, they are not copied to the safe location).
2139
2140 For constructs with three-part delimiters (C<s///>, C<y///>, and
2141 C<tr///>), the search is repeated once more.
2142 If the first delimiter is not an opening punctuation, three delimiters must
2143 be same such as C<s!!!> and C<tr)))>, in which case the second delimiter
2144 terminates the left part and starts the right part at once.
2145 If the left part is delimited by bracketing punctuations (that is C<()>,
2146 C<[]>, C<{}>, or C<< <> >>), the right part needs another pair of
2147 delimiters such as C<s(){}> and C<tr[]//>.  In these cases, whitespaces
2148 and comments are allowed between both parts, though the comment must follow
2149 at least one whitespace; otherwise a character expected as the start of
2150 the comment may be regarded as the starting delimiter of the right part.
2151
2152 During this search no attention is paid to the semantics of the construct.
2153 Thus:
2154
2155     "$hash{"$foo/$bar"}"
2156
2157 or:
2158
2159     m/
2160       bar       # NOT a comment, this slash / terminated m//!
2161      /x
2162
2163 do not form legal quoted expressions.   The quoted part ends on the
2164 first C<"> and C</>, and the rest happens to be a syntax error.
2165 Because the slash that terminated C<m//> was followed by a C<SPACE>,
2166 the example above is not C<m//x>, but rather C<m//> with no C</x>
2167 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
2168
2169 Also no attention is paid to C<\c\> (multichar control char syntax) during
2170 this search. Thus the second C<\> in C<qq/\c\/> is interpreted as a part
2171 of C<\/>, and the following C</> is not recognized as a delimiter.
2172 Instead, use C<\034> or C<\x1c> at the end of quoted constructs.
2173
2174 =item Interpolation
2175 X<interpolation>
2176
2177 The next step is interpolation in the text obtained, which is now
2178 delimiter-independent.  There are multiple cases.
2179
2180 =over 4
2181
2182 =item C<<<'EOF'>
2183
2184 No interpolation is performed.
2185 Note that the combination C<\\> is left intact, since escaped delimiters
2186 are not available for here-docs.
2187
2188 =item  C<m''>, the pattern of C<s'''>
2189
2190 No interpolation is performed at this stage.
2191 Any backslashed sequences including C<\\> are treated at the stage
2192 to L</"parsing regular expressions">.
2193
2194 =item C<''>, C<q//>, C<tr'''>, C<y'''>, the replacement of C<s'''>
2195
2196 The only interpolation is removal of C<\> from pairs of C<\\>.
2197 Therefore C<-> in C<tr'''> and C<y'''> is treated literally
2198 as a hyphen and no character range is available.
2199 C<\1> in the replacement of C<s'''> does not work as C<$1>.
2200
2201 =item C<tr///>, C<y///>
2202
2203 No variable interpolation occurs.  String modifying combinations for
2204 case and quoting such as C<\Q>, C<\U>, and C<\E> are not recognized.
2205 The other escape sequences such as C<\200> and C<\t> and backslashed
2206 characters such as C<\\> and C<\-> are converted to appropriate literals.
2207 The character C<-> is treated specially and therefore C<\-> is treated
2208 as a literal C<->.
2209
2210 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>, C<<<"EOF">
2211
2212 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l> (possibly paired with C<\E>) are
2213 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
2214 is converted to C<$foo . (quotemeta("baz" . $bar))> internally.
2215 The other escape sequences such as C<\200> and C<\t> and backslashed
2216 characters such as C<\\> and C<\-> are replaced with appropriate
2217 expansions.
2218
2219 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
2220 is interpolated in the usual way.  Something like C<"\Q\\E"> has
2221 no C<\E> inside.  instead, it has C<\Q>, C<\\>, and C<E>, so the
2222 result is the same as for C<"\\\\E">.  As a general rule, backslashes
2223 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
2224 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
2225 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
2226
2227   $str = '\t';
2228   return "\Q$str";
2229
2230 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
2231
2232 Interpolated scalars and arrays are converted internally to the C<join> and
2233 C<.> catenation operations.  Thus, C<"$foo XXX '@arr'"> becomes:
2234
2235   $foo . " XXX '" . (join $", @arr) . "'";
2236
2237 All operations above are performed simultaneously, left to right.
2238
2239 Because the result of C<"\Q STRING \E"> has all metacharacters
2240 quoted, there is no way to insert a literal C<$> or C<@> inside a
2241 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to became
2242 C<"\\\$">; if not, it is interpreted as the start of an interpolated
2243 scalar.
2244
2245 Note also that the interpolation code needs to make a decision on
2246 where the interpolated scalar ends.  For instance, whether
2247 C<< "a $b -> {c}" >> really means:
2248
2249   "a " . $b . " -> {c}";
2250
2251 or:
2252
2253   "a " . $b -> {c};
2254
2255 Most of the time, the longest possible text that does not include
2256 spaces between components and which contains matching braces or
2257 brackets.  because the outcome may be determined by voting based
2258 on heuristic estimators, the result is not strictly predictable.
2259 Fortunately, it's usually correct for ambiguous cases.
2260
2261 =item the replacement of C<s///>
2262
2263 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, and interpolation
2264 happens as with C<qq//> constructs.
2265
2266 It is at this step that C<\1> is begrudgingly converted to C<$1> in
2267 the replacement text of C<s///>, in order to correct the incorrigible
2268 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
2269 is emitted if the C<use warnings> pragma or the B<-w> command-line flag
2270 (that is, the C<$^W> variable) was set.
2271
2272 =item C<RE> in C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>,
2273
2274 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\E>,
2275 and interpolation happens (almost) as with C<qq//> constructs.
2276
2277 Processing of C<\N{...}> is also done here, and compiled into an intermediate
2278 form for the regex compiler.  (This is because, as mentioned below, the regex
2279 compilation may be done at execution time, and C<\N{...}> is a compile-time
2280 construct.)
2281
2282 However any other combinations of C<\> followed by a character
2283 are not substituted but only skipped, in order to parse them
2284 as regular expressions at the following step.
2285 As C<\c> is skipped at this step, C<@> of C<\c@> in RE is possibly
2286 treated as an array symbol (for example C<@foo>),
2287 even though the same text in C<qq//> gives interpolation of C<\c@>.
2288
2289 Moreover, inside C<(?{BLOCK})>, C<(?# comment )>, and
2290 a C<#>-comment in a C<//x>-regular expression, no processing is
2291 performed whatsoever.  This is the first step at which the presence
2292 of the C<//x> modifier is relevant.
2293
2294 Interpolation in patterns has several quirks: C<$|>, C<$(>, C<$)>, C<@+>
2295 and C<@-> are not interpolated, and constructs C<$var[SOMETHING]> are
2296 voted (by several different estimators) to be either an array element
2297 or C<$var> followed by an RE alternative.  This is where the notation
2298 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
2299 array element C<-9>, not as a regular expression from the variable
2300 C<$arr> followed by a digit, which would be the interpretation of
2301 C</$arr[0-9]/>.  Since voting among different estimators may occur,
2302 the result is not predictable.
2303
2304 The lack of processing of C<\\> creates specific restrictions on
2305 the post-processed text.  If the delimiter is C</>, one cannot get
2306 the combination C<\/> into the result of this step.  C</> will
2307 finish the regular expression, C<\/> will be stripped to C</> on
2308 the previous step, and C<\\/> will be left as is.  Because C</> is
2309 equivalent to C<\/> inside a regular expression, this does not
2310 matter unless the delimiter happens to be character special to the
2311 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an
2312 alphanumeric char, as in:
2313
2314   m m ^ a \s* b mmx;
2315
2316 In the RE above, which is intentionally obfuscated for illustration, the
2317 delimiter is C<m>, the modifier is C<mx>, and after delimiter-removal the
2318 RE is the same as for C<m/ ^ a \s* b /mx>.  There's more than one
2319 reason you're encouraged to restrict your delimiters to non-alphanumeric,
2320 non-whitespace choices.
2321
2322 =back
2323
2324 This step is the last one for all constructs except regular expressions,
2325 which are processed further.
2326
2327 =item parsing regular expressions
2328 X<regexp, parse>
2329
2330 Previous steps were performed during the compilation of Perl code,
2331 but this one happens at run time, although it may be optimized to
2332 be calculated at compile time if appropriate.  After preprocessing
2333 described above, and possibly after evaluation if concatenation,
2334 joining, casing translation, or metaquoting are involved, the
2335 resulting I<string> is passed to the RE engine for compilation.
2336
2337 Whatever happens in the RE engine might be better discussed in L<perlre>,
2338 but for the sake of continuity, we shall do so here.
2339
2340 This is another step where the presence of the C<//x> modifier is
2341 relevant.  The RE engine scans the string from left to right and
2342 converts it to a finite automaton.
2343
2344 Backslashed characters are either replaced with corresponding
2345 literal strings (as with C<\{>), or else they generate special nodes
2346 in the finite automaton (as with C<\b>).  Characters special to the
2347 RE engine (such as C<|>) generate corresponding nodes or groups of
2348 nodes.  C<(?#...)> comments are ignored.  All the rest is either
2349 converted to literal strings to match, or else is ignored (as is
2350 whitespace and C<#>-style comments if C<//x> is present).
2351
2352 Parsing of the bracketed character class construct, C<[...]>, is
2353 rather different than the rule used for the rest of the pattern.
2354 The terminator of this construct is found using the same rules as
2355 for finding the terminator of a C<{}>-delimited construct, the only
2356 exception being that C<]> immediately following C<[> is treated as
2357 though preceded by a backslash.  Similarly, the terminator of
2358 C<(?{...})> is found using the same rules as for finding the
2359 terminator of a C<{}>-delimited construct.
2360
2361 It is possible to inspect both the string given to RE engine and the
2362 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
2363 in the C<use L<re>> pragma, as well as Perl's B<-Dr> command-line
2364 switch documented in L<perlrun/"Command Switches">.
2365
2366 =item Optimization of regular expressions
2367 X<regexp, optimization>
2368
2369 This step is listed for completeness only.  Since it does not change
2370 semantics, details of this step are not documented and are subject
2371 to change without notice.  This step is performed over the finite
2372 automaton that was generated during the previous pass.
2373
2374 It is at this stage that C<split()> silently optimizes C</^/> to
2375 mean C</^/m>.
2376
2377 =back
2378
2379 =head2 I/O Operators
2380 X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle>
2381 X<< <> >> X<@ARGV>
2382
2383 There are several I/O operators you should know about.
2384
2385 A string enclosed by backticks (grave accents) first undergoes
2386 double-quote interpolation.  It is then interpreted as an external
2387 command, and the output of that command is the value of the
2388 backtick string, like in a shell.  In scalar context, a single string
2389 consisting of all output is returned.  In list context, a list of
2390 values is returned, one per line of output.  (You can set C<$/> to use
2391 a different line terminator.)  The command is executed each time the
2392 pseudo-literal is evaluated.  The status value of the command is
2393 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
2394 Unlike in B<csh>, no translation is done on the return data--newlines
2395 remain newlines.  Unlike in any of the shells, single quotes do not
2396 hide variable names in the command from interpretation.  To pass a
2397 literal dollar-sign through to the shell you need to hide it with a
2398 backslash.  The generalized form of backticks is C<qx//>.  (Because
2399 backticks always undergo shell expansion as well, see L<perlsec> for
2400 security concerns.)
2401 X<qx> X<`> X<``> X<backtick> X<glob>
2402
2403 In scalar context, evaluating a filehandle in angle brackets yields
2404 the next line from that file (the newline, if any, included), or
2405 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
2406 (sometimes known as file-slurp mode) and the file is empty, it
2407 returns C<''> the first time, followed by C<undef> subsequently.
2408
2409 Ordinarily you must assign the returned value to a variable, but
2410 there is one situation where an automatic assignment happens.  If
2411 and only if the input symbol is the only thing inside the conditional
2412 of a C<while> statement (even if disguised as a C<for(;;)> loop),
2413 the value is automatically assigned to the global variable $_,
2414 destroying whatever was there previously.  (This may seem like an
2415 odd thing to you, but you'll use the construct in almost every Perl
2416 script you write.)  The $_ variable is not implicitly localized.
2417 You'll have to put a C<local $_;> before the loop if you want that
2418 to happen.
2419
2420 The following lines are equivalent:
2421
2422     while (defined($_ = <STDIN>)) { print; }
2423     while ($_ = <STDIN>) { print; }
2424     while (<STDIN>) { print; }
2425     for (;<STDIN>;) { print; }
2426     print while defined($_ = <STDIN>);
2427     print while ($_ = <STDIN>);
2428     print while <STDIN>;
2429
2430 This also behaves similarly, but avoids $_ :
2431
2432     while (my $line = <STDIN>) { print $line }
2433
2434 In these loop constructs, the assigned value (whether assignment
2435 is automatic or explicit) is then tested to see whether it is
2436 defined.  The defined test avoids problems where line has a string
2437 value that would be treated as false by Perl, for example a "" or
2438 a "0" with no trailing newline.  If you really mean for such values
2439 to terminate the loop, they should be tested for explicitly:
2440
2441     while (($_ = <STDIN>) ne '0') { ... }
2442     while (<STDIN>) { last unless $_; ... }
2443
2444 In other boolean contexts, C<< <filehandle> >> without an
2445 explicit C<defined> test or comparison elicits a warning if the
2446 C<use warnings> pragma or the B<-w>
2447 command-line switch (the C<$^W> variable) is in effect.
2448
2449 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
2450 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
2451 in packages, where they would be interpreted as local identifiers
2452 rather than global.)  Additional filehandles may be created with
2453 the open() function, amongst others.  See L<perlopentut> and
2454 L<perlfunc/open> for details on this.
2455 X<stdin> X<stdout> X<sterr>
2456
2457 If a <FILEHANDLE> is used in a context that is looking for
2458 a list, a list comprising all input lines is returned, one line per
2459 list element.  It's easy to grow to a rather large data space this
2460 way, so use with care.
2461
2462 <FILEHANDLE> may also be spelled C<readline(*FILEHANDLE)>.
2463 See L<perlfunc/readline>.
2464
2465 The null filehandle <> is special: it can be used to emulate the
2466 behavior of B<sed> and B<awk>.  Input from <> comes either from
2467 standard input, or from each file listed on the command line.  Here's
2468 how it works: the first time <> is evaluated, the @ARGV array is
2469 checked, and if it is empty, C<$ARGV[0]> is set to "-", which when opened
2470 gives you standard input.  The @ARGV array is then processed as a list
2471 of filenames.  The loop
2472
2473     while (<>) {
2474         ...                     # code for each line
2475     }
2476
2477 is equivalent to the following Perl-like pseudo code:
2478
2479     unshift(@ARGV, '-') unless @ARGV;
2480     while ($ARGV = shift) {
2481         open(ARGV, $ARGV);
2482         while (<ARGV>) {
2483             ...         # code for each line
2484         }
2485     }
2486
2487 except that it isn't so cumbersome to say, and will actually work.
2488 It really does shift the @ARGV array and put the current filename
2489 into the $ARGV variable.  It also uses filehandle I<ARGV>
2490 internally. <> is just a synonym for <ARGV>, which
2491 is magical.  (The pseudo code above doesn't work because it treats
2492 <ARGV> as non-magical.)
2493
2494 Since the null filehandle uses the two argument form of L<perlfunc/open>
2495 it interprets special characters, so if you have a script like this:
2496
2497     while (<>) {
2498         print;
2499     }
2500
2501 and call it with C<perl dangerous.pl 'rm -rfv *|'>, it actually opens a
2502 pipe, executes the C<rm> command and reads C<rm>'s output from that pipe.
2503 If you want all items in C<@ARGV> to be interpreted as file names, you
2504 can use the module C<ARGV::readonly> from CPAN.
2505
2506 You can modify @ARGV before the first <> as long as the array ends up
2507 containing the list of filenames you really want.  Line numbers (C<$.>)
2508 continue as though the input were one big happy file.  See the example
2509 in L<perlfunc/eof> for how to reset line numbers on each file.
2510
2511 If you want to set @ARGV to your own list of files, go right ahead.
2512 This sets @ARGV to all plain text files if no @ARGV was given:
2513
2514     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
2515
2516 You can even set them to pipe commands.  For example, this automatically
2517 filters compressed arguments through B<gzip>:
2518
2519     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
2520
2521 If you want to pass switches into your script, you can use one of the
2522 Getopts modules or put a loop on the front like this:
2523
2524     while ($_ = $ARGV[0], /^-/) {
2525         shift;
2526         last if /^--$/;
2527         if (/^-D(.*)/) { $debug = $1 }
2528         if (/^-v/)     { $verbose++  }
2529         # ...           # other switches
2530     }
2531
2532     while (<>) {
2533         # ...           # code for each line
2534     }
2535
2536 The <> symbol will return C<undef> for end-of-file only once.
2537 If you call it again after this, it will assume you are processing another
2538 @ARGV list, and if you haven't set @ARGV, will read input from STDIN.
2539
2540 If what the angle brackets contain is a simple scalar variable (e.g.,
2541 <$foo>), then that variable contains the name of the
2542 filehandle to input from, or its typeglob, or a reference to the
2543 same.  For example:
2544
2545     $fh = \*STDIN;
2546     $line = <$fh>;
2547
2548 If what's within the angle brackets is neither a filehandle nor a simple
2549 scalar variable containing a filehandle name, typeglob, or typeglob
2550 reference, it is interpreted as a filename pattern to be globbed, and
2551 either a list of filenames or the next filename in the list is returned,
2552 depending on context.  This distinction is determined on syntactic
2553 grounds alone.  That means C<< <$x> >> is always a readline() from
2554 an indirect handle, but C<< <$hash{key}> >> is always a glob().
2555 That's because $x is a simple scalar variable, but C<$hash{key}> is
2556 not--it's a hash element.  Even C<< <$x > >> (note the extra space)
2557 is treated as C<glob("$x ")>, not C<readline($x)>.
2558
2559 One level of double-quote interpretation is done first, but you can't
2560 say C<< <$foo> >> because that's an indirect filehandle as explained
2561 in the previous paragraph.  (In older versions of Perl, programmers
2562 would insert curly brackets to force interpretation as a filename glob:
2563 C<< <${foo}> >>.  These days, it's considered cleaner to call the
2564 internal function directly as C<glob($foo)>, which is probably the right
2565 way to have done it in the first place.)  For example:
2566
2567     while (<*.c>) {
2568         chmod 0644, $_;
2569     }
2570
2571 is roughly equivalent to:
2572
2573     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
2574     while (<FOO>) {
2575         chomp;
2576         chmod 0644, $_;
2577     }
2578
2579 except that the globbing is actually done internally using the standard
2580 C<File::Glob> extension.  Of course, the shortest way to do the above is:
2581
2582     chmod 0644, <*.c>;
2583
2584 A (file)glob evaluates its (embedded) argument only when it is
2585 starting a new list.  All values must be read before it will start
2586 over.  In list context, this isn't important because you automatically
2587 get them all anyway.  However, in scalar context the operator returns
2588 the next value each time it's called, or C<undef> when the list has
2589 run out.  As with filehandle reads, an automatic C<defined> is
2590 generated when the glob occurs in the test part of a C<while>,
2591 because legal glob returns (e.g. a file called F<0>) would otherwise
2592 terminate the loop.  Again, C<undef> is returned only once.  So if
2593 you're expecting a single value from a glob, it is much better to
2594 say
2595
2596     ($file) = <blurch*>;
2597
2598 than
2599
2600     $file = <blurch*>;
2601
2602 because the latter will alternate between returning a filename and
2603 returning false.
2604
2605 If you're trying to do variable interpolation, it's definitely better
2606 to use the glob() function, because the older notation can cause people
2607 to become confused with the indirect filehandle notation.
2608
2609     @files = glob("$dir/*.[ch]");
2610     @files = glob($files[$i]);
2611
2612 =head2 Constant Folding
2613 X<constant folding> X<folding>
2614
2615 Like C, Perl does a certain amount of expression evaluation at
2616 compile time whenever it determines that all arguments to an
2617 operator are static and have no side effects.  In particular, string
2618 concatenation happens at compile time between literals that don't do
2619 variable substitution.  Backslash interpolation also happens at
2620 compile time.  You can say
2621
2622     'Now is the time for all' . "\n" .
2623         'good men to come to.'
2624
2625 and this all reduces to one string internally.  Likewise, if
2626 you say
2627
2628     foreach $file (@filenames) {
2629         if (-s $file > 5 + 100 * 2**16) {  }
2630     }
2631
2632 the compiler will precompute the number which that expression
2633 represents so that the interpreter won't have to.
2634
2635 =head2 No-ops
2636 X<no-op> X<nop>
2637
2638 Perl doesn't officially have a no-op operator, but the bare constants
2639 C<0> and C<1> are special-cased to not produce a warning in a void
2640 context, so you can for example safely do
2641
2642     1 while foo();
2643
2644 =head2 Bitwise String Operators
2645 X<operator, bitwise, string>
2646
2647 Bitstrings of any size may be manipulated by the bitwise operators
2648 (C<~ | & ^>).
2649
2650 If the operands to a binary bitwise op are strings of different
2651 sizes, B<|> and B<^> ops act as though the shorter operand had
2652 additional zero bits on the right, while the B<&> op acts as though
2653 the longer operand were truncated to the length of the shorter.
2654 The granularity for such extension or truncation is one or more
2655 bytes.
2656
2657     # ASCII-based examples
2658     print "j p \n" ^ " a h";            # prints "JAPH\n"
2659     print "JA" | "  ph\n";              # prints "japh\n"
2660     print "japh\nJunk" & '_____';       # prints "JAPH\n";
2661     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
2662
2663 If you are intending to manipulate bitstrings, be certain that
2664 you're supplying bitstrings: If an operand is a number, that will imply
2665 a B<numeric> bitwise operation.  You may explicitly show which type of
2666 operation you intend by using C<""> or C<0+>, as in the examples below.
2667
2668     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
2669     $foo = '150' |  105;        # yields 255
2670     $foo =  150  | '105';       # yields 255
2671     $foo = '150' | '105';       # yields string '155' (under ASCII)
2672
2673     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
2674     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
2675
2676 See L<perlfunc/vec> for information on how to manipulate individual bits
2677 in a bit vector.
2678
2679 =head2 Integer Arithmetic
2680 X<integer>
2681
2682 By default, Perl assumes that it must do most of its arithmetic in
2683 floating point.  But by saying
2684
2685     use integer;
2686
2687 you may tell the compiler to use integer operations
2688 (see L<integer> for a detailed explanation) from here to the end of
2689 the enclosing BLOCK.  An inner BLOCK may countermand this by saying
2690
2691     no integer;
2692
2693 which lasts until the end of that BLOCK.  Note that this doesn't
2694 mean everything is an integer, merely that Perl will use integer
2695 operations for arithmetic, comparison, and bitwise operators.  For
2696 example, even under C<use integer>, if you take the C<sqrt(2)>, you'll
2697 still get C<1.4142135623731> or so.
2698
2699 Used on numbers, the bitwise operators ("&", "|", "^", "~", "<<",
2700 and ">>") always produce integral results.  (But see also
2701 L<Bitwise String Operators>.)  However, C<use integer> still has meaning for
2702 them.  By default, their results are interpreted as unsigned integers, but
2703 if C<use integer> is in effect, their results are interpreted
2704 as signed integers.  For example, C<~0> usually evaluates to a large
2705 integral value.  However, C<use integer; ~0> is C<-1> on two's-complement
2706 machines.
2707
2708 =head2 Floating-point Arithmetic
2709 X<floating-point> X<floating point> X<float> X<real>
2710
2711 While C<use integer> provides integer-only arithmetic, there is no
2712 analogous mechanism to provide automatic rounding or truncation to a
2713 certain number of decimal places.  For rounding to a certain number
2714 of digits, sprintf() or printf() is usually the easiest route.
2715 See L<perlfaq4>.
2716
2717 Floating-point numbers are only approximations to what a mathematician
2718 would call real numbers.  There are infinitely more reals than floats,
2719 so some corners must be cut.  For example:
2720
2721     printf "%.20g\n", 123456789123456789;
2722     #        produces 123456789123456784
2723
2724 Testing for exact floating-point equality or inequality is not a
2725 good idea.  Here's a (relatively expensive) work-around to compare
2726 whether two floating-point numbers are equal to a particular number of
2727 decimal places.  See Knuth, volume II, for a more robust treatment of
2728 this topic.
2729
2730     sub fp_equal {
2731         my ($X, $Y, $POINTS) = @_;
2732         my ($tX, $tY);
2733         $tX = sprintf("%.${POINTS}g", $X);
2734         $tY = sprintf("%.${POINTS}g", $Y);
2735         return $tX eq $tY;
2736     }
2737
2738 The POSIX module (part of the standard perl distribution) implements
2739 ceil(), floor(), and other mathematical and trigonometric functions.
2740 The Math::Complex module (part of the standard perl distribution)
2741 defines mathematical functions that work on both the reals and the
2742 imaginary numbers.  Math::Complex not as efficient as POSIX, but
2743 POSIX can't work with complex numbers.
2744
2745 Rounding in financial applications can have serious implications, and
2746 the rounding method used should be specified precisely.  In these
2747 cases, it probably pays not to trust whichever system rounding is
2748 being used by Perl, but to instead implement the rounding function you
2749 need yourself.
2750
2751 =head2 Bigger Numbers
2752 X<number, arbitrary precision>
2753
2754 The standard Math::BigInt and Math::BigFloat modules provide
2755 variable-precision arithmetic and overloaded operators, although
2756 they're currently pretty slow. At the cost of some space and
2757 considerable speed, they avoid the normal pitfalls associated with
2758 limited-precision representations.
2759
2760     use Math::BigInt;
2761     $x = Math::BigInt->new('123456789123456789');
2762     print $x * $x;
2763
2764     # prints +15241578780673678515622620750190521
2765
2766 There are several modules that let you calculate with (bound only by
2767 memory and cpu-time) unlimited or fixed precision. There are also
2768 some non-standard modules that provide faster implementations via
2769 external C libraries.
2770
2771 Here is a short, but incomplete summary:
2772
2773   Math::Fraction         big, unlimited fractions like 9973 / 12967
2774   Math::String           treat string sequences like numbers
2775   Math::FixedPrecision   calculate with a fixed precision
2776   Math::Currency         for currency calculations
2777   Bit::Vector            manipulate bit vectors fast (uses C)
2778   Math::BigIntFast       Bit::Vector wrapper for big numbers
2779   Math::Pari             provides access to the Pari C library
2780   Math::BigInteger       uses an external C library
2781   Math::Cephes           uses external Cephes C library (no big numbers)
2782   Math::Cephes::Fraction fractions via the Cephes library
2783   Math::GMP              another one using an external C library
2784
2785 Choose wisely.
2786
2787 =cut