This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
flock() pod talks about "adding" in the sense of "or-ing"
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 An named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<umask>,
140 C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<prototype>, C<qx>,
204 C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostent>,
228 C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<socket>, C<socketpair>, C<stat>, C<symlink>, C<syscall>,
238 C<sysopen>, C<system>, C<times>, C<truncate>, C<umask>, C<unlink>,
239 C<utime>, C<wait>, C<waitpid>
240
241 For more information about the portability of these functions, see
242 L<perlport> and other available platform-specific documentation.
243
244 =head2 Alphabetical Listing of Perl Functions
245
246 =over 8
247
248 =item I<-X> FILEHANDLE
249
250 =item I<-X> EXPR
251
252 =item I<-X>
253
254 A file test, where X is one of the letters listed below.  This unary
255 operator takes one argument, either a filename or a filehandle, and
256 tests the associated file to see if something is true about it.  If the
257 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
258 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
259 the undefined value if the file doesn't exist.  Despite the funny
260 names, precedence is the same as any other named unary operator, and
261 the argument may be parenthesized like any other unary operator.  The
262 operator may be any of:
263 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
264 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
265
266     -r  File is readable by effective uid/gid.
267     -w  File is writable by effective uid/gid.
268     -x  File is executable by effective uid/gid.
269     -o  File is owned by effective uid.
270
271     -R  File is readable by real uid/gid.
272     -W  File is writable by real uid/gid.
273     -X  File is executable by real uid/gid.
274     -O  File is owned by real uid.
275
276     -e  File exists.
277     -z  File has zero size.
278     -s  File has nonzero size (returns size).
279
280     -f  File is a plain file.
281     -d  File is a directory.
282     -l  File is a symbolic link.
283     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
284     -S  File is a socket.
285     -b  File is a block special file.
286     -c  File is a character special file.
287     -t  Filehandle is opened to a tty.
288
289     -u  File has setuid bit set.
290     -g  File has setgid bit set.
291     -k  File has sticky bit set.
292
293     -T  File is an ASCII text file.
294     -B  File is a "binary" file (opposite of -T).
295
296     -M  Age of file in days when script started.
297     -A  Same for access time.
298     -C  Same for inode change time.
299
300 Example:
301
302     while (<>) {
303         chop;
304         next unless -f $_;      # ignore specials
305         #...
306     }
307
308 The interpretation of the file permission operators C<-r>, C<-R>,
309 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
310 of the file and the uids and gids of the user.  There may be other
311 reasons you can't actually read, write, or execute the file.  Such
312 reasons may be for example network filesystem access controls, ACLs
313 (access control lists), read-only filesystems, and unrecognized
314 executable formats.
315
316 Also note that, for the superuser on the local filesystems, the C<-r>,
317 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
318 if any execute bit is set in the mode.  Scripts run by the superuser
319 may thus need to do a stat() to determine the actual mode of the file,
320 or temporarily set their effective uid to something else.
321
322 If you are using ACLs, there is a pragma called C<filetest> that may
323 produce more accurate results than the bare stat() mode bits.
324 When under the C<use filetest 'access'> the above-mentioned filetests
325 will test whether the permission can (not) be granted using the
326 access() family of system calls.  Also note that the C<-x> and C<-X> may
327 under this pragma return true even if there are no execute permission
328 bits set (nor any extra execute permission ACLs).  This strangeness is
329 due to the underlying system calls' definitions.  Read the
330 documentation for the C<filetest> pragma for more information.
331
332 Note that C<-s/a/b/> does not do a negated substitution.  Saying
333 C<-exp($foo)> still works as expected, however--only single letters
334 following a minus are interpreted as file tests.
335
336 The C<-T> and C<-B> switches work as follows.  The first block or so of the
337 file is examined for odd characters such as strange control codes or
338 characters with the high bit set.  If too many strange characters (E<gt>30%)
339 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
340 containing null in the first block is considered a binary file.  If C<-T>
341 or C<-B> is used on a filehandle, the current stdio buffer is examined
342 rather than the first block.  Both C<-T> and C<-B> return true on a null
343 file, or a file at EOF when testing a filehandle.  Because you have to
344 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
345 against the file first, as in C<next unless -f $file && -T $file>.
346
347 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
348 the special filehandle consisting of a solitary underline, then the stat
349 structure of the previous file test (or stat operator) is used, saving
350 a system call.  (This doesn't work with C<-t>, and you need to remember
351 that lstat() and C<-l> will leave values in the stat structure for the
352 symbolic link, not the real file.)  Example:
353
354     print "Can do.\n" if -r $a || -w _ || -x _;
355
356     stat($filename);
357     print "Readable\n" if -r _;
358     print "Writable\n" if -w _;
359     print "Executable\n" if -x _;
360     print "Setuid\n" if -u _;
361     print "Setgid\n" if -g _;
362     print "Sticky\n" if -k _;
363     print "Text\n" if -T _;
364     print "Binary\n" if -B _;
365
366 =item abs VALUE
367
368 =item abs
369
370 Returns the absolute value of its argument.
371 If VALUE is omitted, uses C<$_>.
372
373 =item accept NEWSOCKET,GENERICSOCKET
374
375 Accepts an incoming socket connect, just as the accept(2) system call
376 does.  Returns the packed address if it succeeded, false otherwise.
377 See the example in L<perlipc/"Sockets: Client/Server Communication">.
378
379 =item alarm SECONDS
380
381 =item alarm
382
383 Arranges to have a SIGALRM delivered to this process after the
384 specified number of seconds have elapsed.  If SECONDS is not specified,
385 the value stored in C<$_> is used. (On some machines,
386 unfortunately, the elapsed time may be up to one second less than you
387 specified because of how seconds are counted.)  Only one timer may be
388 counting at once.  Each call disables the previous timer, and an
389 argument of C<0> may be supplied to cancel the previous timer without
390 starting a new one.  The returned value is the amount of time remaining
391 on the previous timer.
392
393 For delays of finer granularity than one second, you may use Perl's
394 four-argument version of select() leaving the first three arguments
395 undefined, or you might be able to use the C<syscall> interface to
396 access setitimer(2) if your system supports it.  The Time::HiRes module
397 from CPAN may also prove useful.
398
399 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
400 (C<sleep> may be internally implemented in your system with C<alarm>)
401
402 If you want to use C<alarm> to time out a system call you need to use an
403 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
404 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
405 restart system calls on some systems.  Using C<eval>/C<die> always works,
406 modulo the caveats given in L<perlipc/"Signals">.
407
408     eval {
409         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
410         alarm $timeout;
411         $nread = sysread SOCKET, $buffer, $size;
412         alarm 0;
413     };
414     if ($@) {
415         die unless $@ eq "alarm\n";   # propagate unexpected errors
416         # timed out
417     }
418     else {
419         # didn't
420     }
421
422 =item atan2 Y,X
423
424 Returns the arctangent of Y/X in the range -PI to PI.
425
426 For the tangent operation, you may use the C<POSIX::tan()>
427 function, or use the familiar relation:
428
429     sub tan { sin($_[0]) / cos($_[0])  }
430
431 =item bind SOCKET,NAME
432
433 Binds a network address to a socket, just as the bind system call
434 does.  Returns true if it succeeded, false otherwise.  NAME should be a
435 packed address of the appropriate type for the socket.  See the examples in
436 L<perlipc/"Sockets: Client/Server Communication">.
437
438 =item binmode FILEHANDLE
439
440 Arranges for FILEHANDLE to be read or written in "binary" mode on
441 systems whose run-time libraries force the programmer to guess
442 between binary and text files.  If FILEHANDLE is an expression, the
443 value is taken as the name of the filehandle.  binmode() should be
444 called after the C<open> but before any I/O is done on the filehandle.
445 The only way to reset binary mode on a filehandle is to reopen the
446 file.
447
448 The operating system, device drivers, C libraries, and Perl run-time
449 system all conspire to let the programmer conveniently treat a
450 simple, one-byte C<\n> as the line terminator, irrespective of its
451 external representation.  On Unix and its brethren, the native file
452 representation exactly matches the internal representation, making
453 everyone's lives unbelievably simpler.  Consequently, L<binmode>
454 has no effect under Unix, Plan9, or Mac OS, all of which use C<\n>
455 to end each line.  (Unix and Plan9 think C<\n> means C<\cJ> and
456 C<\r> means C<\cM>, whereas the Mac goes the other way--it uses
457 C<\cM> for c<\n> and C<\cJ> to mean C<\r>.  But that's ok, because
458 it's only one byte, and the internal and external representations
459 match.)
460
461 In legacy systems like MS-DOS and its embellishments, your program
462 sees a C<\n> as a simple C<\cJ> (just as in Unix), but oddly enough,
463 that's not what's physically stored on disk.  What's worse, these
464 systems refuse to help you with this; it's up to you to remember
465 what to do.  And you mustn't go applying binmode() with wild abandon,
466 either, because if your system does care about binmode(), then using
467 it when you shouldn't is just as perilous as failing to use it when
468 you should.
469
470 That means that on any version of Microsoft WinXX that you might
471 care to name (or not), binmode() causes C<\cM\cJ> sequences on disk
472 to be converted to C<\n> when read into your program, and causes
473 any C<\n> in your program to be converted back to C<\cM\cJ> on
474 output to disk.  This sad discrepancy leads to no end of
475 problems in not just the readline operator, but also when using
476 seek(), tell(), and read() calls.  See L<perlport> for other painful
477 details.  See the C<$/> and C<$\> variables in L<perlvar> for how
478 to manually set your input and output line-termination sequences.
479
480 =item bless REF,CLASSNAME
481
482 =item bless REF
483
484 This function tells the thingy referenced by REF that it is now an object
485 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
486 is used.  Because a C<bless> is often the last thing in a constructor,
487 it returns the reference for convenience.  Always use the two-argument
488 version if the function doing the blessing might be inherited by a
489 derived class.  See L<perltoot> and L<perlobj> for more about the blessing
490 (and blessings) of objects.
491
492 Consider always blessing objects in CLASSNAMEs that are mixed case.
493 Namespaces with all lowercase names are considered reserved for
494 Perl pragmata.  Builtin types have all uppercase names, so to prevent
495 confusion, you may wish to avoid such package names as well.  Make sure
496 that CLASSNAME is a true value.
497
498 See L<perlmod/"Perl Modules">.
499
500 =item caller EXPR
501
502 =item caller
503
504 Returns the context of the current subroutine call.  In scalar context,
505 returns the caller's package name if there is a caller, that is, if
506 we're in a subroutine or C<eval> or C<require>, and the undefined value
507 otherwise.  In list context, returns
508
509     ($package, $filename, $line) = caller;
510
511 With EXPR, it returns some extra information that the debugger uses to
512 print a stack trace.  The value of EXPR indicates how many call frames
513 to go back before the current one.
514
515     ($package, $filename, $line, $subroutine, $hasargs,
516     $wantarray, $evaltext, $is_require, $hints) = caller($i);
517
518 Here $subroutine may be C<(eval)> if the frame is not a subroutine
519 call, but an C<eval>.  In such a case additional elements $evaltext and
520 C<$is_require> are set: C<$is_require> is true if the frame is created by a
521 C<require> or C<use> statement, $evaltext contains the text of the
522 C<eval EXPR> statement.  In particular, for a C<eval BLOCK> statement,
523 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
524 each C<use> statement creates a C<require> frame inside an C<eval EXPR>)
525 frame.  C<$hints> contains pragmatic hints that the caller was
526 compiled with.  The C<$hints> value is subject to change between versions
527 of Perl, and is not meant for external use.
528
529 Furthermore, when called from within the DB package, caller returns more
530 detailed information: it sets the list variable C<@DB::args> to be the
531 arguments with which the subroutine was invoked.
532
533 Be aware that the optimizer might have optimized call frames away before
534 C<caller> had a chance to get the information.  That means that C<caller(N)>
535 might not return information about the call frame you expect it do, for
536 C<N E<gt> 1>.  In particular, C<@DB::args> might have information from the 
537 previous time C<caller> was called.
538
539 =item chdir EXPR
540
541 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
542 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
543 changes to the directory specified by C<$ENV{LOGDIR}>.  If neither is
544 set, C<chdir> does nothing.  It returns true upon success, false
545 otherwise.  See the example under C<die>.
546
547 =item chmod LIST
548
549 Changes the permissions of a list of files.  The first element of the
550 list must be the numerical mode, which should probably be an octal
551 number, and which definitely should I<not> a string of octal digits:
552 C<0644> is okay, C<'0644'> is not.  Returns the number of files
553 successfully changed.  See also L</oct>, if all you have is a string.
554
555     $cnt = chmod 0755, 'foo', 'bar';
556     chmod 0755, @executables;
557     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
558                                              # --w----r-T
559     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
560     $mode = 0644;   chmod $mode, 'foo';      # this is best
561
562 =item chomp VARIABLE
563
564 =item chomp LIST
565
566 =item chomp
567
568 This safer version of L</chop> removes any trailing string
569 that corresponds to the current value of C<$/> (also known as
570 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
571 number of characters removed from all its arguments.  It's often used to
572 remove the newline from the end of an input record when you're worried
573 that the final record may be missing its newline.  When in paragraph
574 mode (C<$/ = "">), it removes all trailing newlines from the string.
575 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
576 a reference to an integer or the like, see L<perlvar>) chomp() won't
577 remove anything.  
578 If VARIABLE is omitted, it chomps C<$_>.  Example:
579
580     while (<>) {
581         chomp;  # avoid \n on last field
582         @array = split(/:/);
583         # ...
584     }
585
586 You can actually chomp anything that's an lvalue, including an assignment:
587
588     chomp($cwd = `pwd`);
589     chomp($answer = <STDIN>);
590
591 If you chomp a list, each element is chomped, and the total number of
592 characters removed is returned.
593
594 =item chop VARIABLE
595
596 =item chop LIST
597
598 =item chop
599
600 Chops off the last character of a string and returns the character
601 chopped.  It's used primarily to remove the newline from the end of an
602 input record, but is much more efficient than C<s/\n//> because it neither
603 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
604 Example:
605
606     while (<>) {
607         chop;   # avoid \n on last field
608         @array = split(/:/);
609         #...
610     }
611
612 You can actually chop anything that's an lvalue, including an assignment:
613
614     chop($cwd = `pwd`);
615     chop($answer = <STDIN>);
616
617 If you chop a list, each element is chopped.  Only the value of the
618 last C<chop> is returned.
619
620 Note that C<chop> returns the last character.  To return all but the last
621 character, use C<substr($string, 0, -1)>.
622
623 =item chown LIST
624
625 Changes the owner (and group) of a list of files.  The first two
626 elements of the list must be the I<numeric> uid and gid, in that
627 order.  A value of -1 in either position is interpreted by most
628 systems to leave that value unchanged.  Returns the number of files
629 successfully changed.
630
631     $cnt = chown $uid, $gid, 'foo', 'bar';
632     chown $uid, $gid, @filenames;
633
634 Here's an example that looks up nonnumeric uids in the passwd file:
635
636     print "User: ";
637     chomp($user = <STDIN>);
638     print "Files: ";
639     chomp($pattern = <STDIN>);
640
641     ($login,$pass,$uid,$gid) = getpwnam($user)
642         or die "$user not in passwd file";
643
644     @ary = glob($pattern);      # expand filenames
645     chown $uid, $gid, @ary;
646
647 On most systems, you are not allowed to change the ownership of the
648 file unless you're the superuser, although you should be able to change
649 the group to any of your secondary groups.  On insecure systems, these
650 restrictions may be relaxed, but this is not a portable assumption.
651 On POSIX systems, you can detect this condition this way:
652
653     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
654     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
655
656 =item chr NUMBER
657
658 =item chr
659
660 Returns the character represented by that NUMBER in the character set.
661 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
662 chr(0x263a) is a Unicode smiley face (but only within the scope of
663 a C<use utf8>).  For the reverse, use L</ord>.  
664 See L<utf8> for more about Unicode.
665
666 If NUMBER is omitted, uses C<$_>.
667
668 =item chroot FILENAME
669
670 =item chroot
671
672 This function works like the system call by the same name: it makes the
673 named directory the new root directory for all further pathnames that
674 begin with a C</> by your process and all its children.  (It doesn't
675 change your current working directory, which is unaffected.)  For security
676 reasons, this call is restricted to the superuser.  If FILENAME is
677 omitted, does a C<chroot> to C<$_>.
678
679 =item close FILEHANDLE
680
681 =item close
682
683 Closes the file or pipe associated with the file handle, returning true
684 only if stdio successfully flushes buffers and closes the system file
685 descriptor.  Closes the currently selected filehandle if the argument
686 is omitted.
687
688 You don't have to close FILEHANDLE if you are immediately going to do
689 another C<open> on it, because C<open> will close it for you.  (See
690 C<open>.)  However, an explicit C<close> on an input file resets the line
691 counter (C<$.>), while the implicit close done by C<open> does not.
692
693 If the file handle came from a piped open C<close> will additionally
694 return false if one of the other system calls involved fails or if the
695 program exits with non-zero status.  (If the only problem was that the
696 program exited non-zero C<$!> will be set to C<0>.)  Closing a pipe 
697 also waits for the process executing on the pipe to complete, in case you
698 want to look at the output of the pipe afterwards, and 
699 implicitly puts the exit status value of that command into C<$?>.
700
701 Prematurely closing the read end of a pipe (i.e. before the process
702 writing to it at the other end has closed it) will result in a
703 SIGPIPE being delivered to the writer.  If the other end can't
704 handle that, be sure to read all the data before closing the pipe.
705
706 Example:
707
708     open(OUTPUT, '|sort >foo')  # pipe to sort
709         or die "Can't start sort: $!";
710     #...                        # print stuff to output
711     close OUTPUT                # wait for sort to finish
712         or warn $! ? "Error closing sort pipe: $!"
713                    : "Exit status $? from sort";
714     open(INPUT, 'foo')          # get sort's results
715         or die "Can't open 'foo' for input: $!";
716
717 FILEHANDLE may be an expression whose value can be used as an indirect
718 filehandle, usually the real filehandle name.
719
720 =item closedir DIRHANDLE
721
722 Closes a directory opened by C<opendir> and returns the success of that
723 system call.
724
725 DIRHANDLE may be an expression whose value can be used as an indirect
726 dirhandle, usually the real dirhandle name.
727
728 =item connect SOCKET,NAME
729
730 Attempts to connect to a remote socket, just as the connect system call
731 does.  Returns true if it succeeded, false otherwise.  NAME should be a
732 packed address of the appropriate type for the socket.  See the examples in
733 L<perlipc/"Sockets: Client/Server Communication">.
734
735 =item continue BLOCK
736
737 Actually a flow control statement rather than a function.  If there is a
738 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
739 C<foreach>), it is always executed just before the conditional is about to
740 be evaluated again, just like the third part of a C<for> loop in C.  Thus
741 it can be used to increment a loop variable, even when the loop has been
742 continued via the C<next> statement (which is similar to the C C<continue>
743 statement).
744
745 C<last>, C<next>, or C<redo> may appear within a C<continue>
746 block.  C<last> and C<redo> will behave as if they had been executed within
747 the main block.  So will C<next>, but since it will execute a C<continue>
748 block, it may be more entertaining.
749
750     while (EXPR) {
751         ### redo always comes here
752         do_something;
753     } continue {
754         ### next always comes here
755         do_something_else;
756         # then back the top to re-check EXPR
757     }
758     ### last always comes here
759
760 Omitting the C<continue> section is semantically equivalent to using an
761 empty one, logically enough.  In that case, C<next> goes directly back
762 to check the condition at the top of the loop.
763
764 =item cos EXPR
765
766 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
767 takes cosine of C<$_>.
768
769 For the inverse cosine operation, you may use the C<POSIX::acos()>
770 function, or use this relation:
771
772     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
773
774 =item crypt PLAINTEXT,SALT
775
776 Encrypts a string exactly like the crypt(3) function in the C library
777 (assuming that you actually have a version there that has not been
778 extirpated as a potential munition).  This can prove useful for checking
779 the password file for lousy passwords, amongst other things.  Only the
780 guys wearing white hats should do this.
781
782 Note that C<crypt> is intended to be a one-way function, much like breaking
783 eggs to make an omelette.  There is no (known) corresponding decrypt
784 function.  As a result, this function isn't all that useful for
785 cryptography.  (For that, see your nearby CPAN mirror.)
786
787 When verifying an existing encrypted string you should use the encrypted
788 text as the salt (like C<crypt($plain, $crypted) eq $crypted>).  This
789 allows your code to work with the standard C<crypt> and with more
790 exotic implementations.  When choosing a new salt create a random two
791 character string whose characters come from the set C<[./0-9A-Za-z]>
792 (like C<join '', ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).
793
794 Here's an example that makes sure that whoever runs this program knows
795 their own password:
796
797     $pwd = (getpwuid($<))[1];
798
799     system "stty -echo";
800     print "Password: ";
801     chomp($word = <STDIN>);
802     print "\n";
803     system "stty echo";
804
805     if (crypt($word, $pwd) ne $pwd) {
806         die "Sorry...\n";
807     } else {
808         print "ok\n";
809     }
810
811 Of course, typing in your own password to whoever asks you
812 for it is unwise.
813
814 The L<crypt> function is unsuitable for encrypting large quantities
815 of data, not least of all because you can't get the information
816 back.  Look at the F<by-module/Crypt> and F<by-module/PGP> directories
817 on your favorite CPAN mirror for a slew of potentially useful
818 modules.
819
820 =item dbmclose HASH
821
822 [This function has been largely superseded by the C<untie> function.]
823
824 Breaks the binding between a DBM file and a hash.
825
826 =item dbmopen HASH,DBNAME,MASK
827
828 [This function has been largely superseded by the C<tie> function.]
829
830 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
831 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
832 argument is I<not> a filehandle, even though it looks like one).  DBNAME
833 is the name of the database (without the F<.dir> or F<.pag> extension if
834 any).  If the database does not exist, it is created with protection
835 specified by MASK (as modified by the C<umask>).  If your system supports
836 only the older DBM functions, you may perform only one C<dbmopen> in your
837 program.  In older versions of Perl, if your system had neither DBM nor
838 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
839 sdbm(3).
840
841 If you don't have write access to the DBM file, you can only read hash
842 variables, not set them.  If you want to test whether you can write,
843 either use file tests or try setting a dummy hash entry inside an C<eval>,
844 which will trap the error.
845
846 Note that functions such as C<keys> and C<values> may return huge lists
847 when used on large DBM files.  You may prefer to use the C<each>
848 function to iterate over large DBM files.  Example:
849
850     # print out history file offsets
851     dbmopen(%HIST,'/usr/lib/news/history',0666);
852     while (($key,$val) = each %HIST) {
853         print $key, ' = ', unpack('L',$val), "\n";
854     }
855     dbmclose(%HIST);
856
857 See also L<AnyDBM_File> for a more general description of the pros and
858 cons of the various dbm approaches, as well as L<DB_File> for a particularly
859 rich implementation.
860
861 You can control which DBM library you use by loading that library
862 before you call dbmopen():
863
864     use DB_File;
865     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
866         or die "Can't open netscape history file: $!";
867
868 =item defined EXPR
869
870 =item defined
871
872 Returns a Boolean value telling whether EXPR has a value other than
873 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
874 checked.
875
876 Many operations return C<undef> to indicate failure, end of file,
877 system error, uninitialized variable, and other exceptional
878 conditions.  This function allows you to distinguish C<undef> from
879 other values.  (A simple Boolean test will not distinguish among
880 C<undef>, zero, the empty string, and C<"0">, which are all equally
881 false.)  Note that since C<undef> is a valid scalar, its presence
882 doesn't I<necessarily> indicate an exceptional condition: C<pop>
883 returns C<undef> when its argument is an empty array, I<or> when the
884 element to return happens to be C<undef>.
885
886 You may also use C<defined(&func)> to check whether subroutine C<&func>
887 has ever been defined.  The return value is unaffected by any forward
888 declarations of C<&foo>.
889
890 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
891 used to report whether memory for that aggregate has ever been
892 allocated.  This behavior may disappear in future versions of Perl.
893 You should instead use a simple test for size:
894
895     if (@an_array) { print "has array elements\n" }
896     if (%a_hash)   { print "has hash members\n"   }
897
898 When used on a hash element, it tells you whether the value is defined,
899 not whether the key exists in the hash.  Use L</exists> for the latter
900 purpose.
901
902 Examples:
903
904     print if defined $switch{'D'};
905     print "$val\n" while defined($val = pop(@ary));
906     die "Can't readlink $sym: $!"
907         unless defined($value = readlink $sym);
908     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
909     $debugging = 0 unless defined $debugging;
910
911 Note:  Many folks tend to overuse C<defined>, and then are surprised to
912 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
913 defined values.  For example, if you say
914
915     "ab" =~ /a(.*)b/;
916
917 The pattern match succeeds, and C<$1> is defined, despite the fact that it
918 matched "nothing".  But it didn't really match nothing--rather, it
919 matched something that happened to be zero characters long.  This is all
920 very above-board and honest.  When a function returns an undefined value,
921 it's an admission that it couldn't give you an honest answer.  So you
922 should use C<defined> only when you're questioning the integrity of what
923 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
924 what you want.
925
926 See also L</undef>, L</exists>, L</ref>.
927
928 =item delete EXPR
929
930 Given an expression that specifies a hash element, array element, hash slice,
931 or array slice, deletes the specified element(s) from the hash or array.
932 If the array elements happen to be at the end of the array, the size
933 of the array will shrink by that number of elements.
934
935 Returns each element so deleted or the undefined value if there was no such
936 element.  Deleting from C<$ENV{}> modifies the environment.  Deleting from
937 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
938 from a C<tie>d hash or array may not necessarily return anything.
939
940 Deleting an array element effectively returns that position of the array
941 to its initial, uninitialized state.  Subsequently testing for the same
942 element with exists() will return false.  See L</exists>.
943
944 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
945
946     foreach $key (keys %HASH) {
947         delete $HASH{$key};
948     }
949
950     foreach $index (0 .. $#ARRAY) {
951         delete $ARRAY[$index];
952     }
953
954 And so do these:
955
956     delete @HASH{keys %HASH};
957
958     delete @ARRAY[0 .. $#ARRAY];
959
960 But both of these are slower than just assigning the empty list
961 or undefining %HASH or @ARRAY:
962
963     %HASH = ();         # completely empty %HASH
964     undef %HASH;        # forget %HASH ever existed
965
966     @ARRAY = ();        # completely empty @ARRAY
967     undef @ARRAY;       # forget @ARRAY ever existed
968
969 Note that the EXPR can be arbitrarily complicated as long as the final
970 operation is a hash element, array element,  hash slice, or array slice
971 lookup:
972
973     delete $ref->[$x][$y]{$key};
974     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
975
976     delete $ref->[$x][$y][$index];
977     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
978
979 =item die LIST
980
981 Outside an C<eval>, prints the value of LIST to C<STDERR> and
982 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
983 exits with the value of C<($? E<gt>E<gt> 8)> (backtick `command`
984 status).  If C<($? E<gt>E<gt> 8)> is C<0>, exits with C<255>.  Inside
985 an C<eval(),> the error message is stuffed into C<$@> and the
986 C<eval> is terminated with the undefined value.  This makes
987 C<die> the way to raise an exception.
988
989 Equivalent examples:
990
991     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
992     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
993
994 If the value of EXPR does not end in a newline, the current script line
995 number and input line number (if any) are also printed, and a newline
996 is supplied.  Note that the "input line number" (also known as "chunk")
997 is subject to whatever notion of "line" happens to be currently in
998 effect, and is also available as the special variable C<$.>.
999 See L<perlvar/"$/"> and L<perlvar/"$.">.
1000
1001 Hint: sometimes appending C<", stopped"> to your message
1002 will cause it to make better sense when the string C<"at foo line 123"> is
1003 appended.  Suppose you are running script "canasta".
1004
1005     die "/etc/games is no good";
1006     die "/etc/games is no good, stopped";
1007
1008 produce, respectively
1009
1010     /etc/games is no good at canasta line 123.
1011     /etc/games is no good, stopped at canasta line 123.
1012
1013 See also exit(), warn(), and the Carp module.
1014
1015 If LIST is empty and C<$@> already contains a value (typically from a
1016 previous eval) that value is reused after appending C<"\t...propagated">.
1017 This is useful for propagating exceptions:
1018
1019     eval { ... };
1020     die unless $@ =~ /Expected exception/;
1021
1022 If C<$@> is empty then the string C<"Died"> is used.
1023
1024 die() can also be called with a reference argument.  If this happens to be
1025 trapped within an eval(), $@ contains the reference.  This behavior permits
1026 a more elaborate exception handling implementation using objects that
1027 maintain arbitary state about the nature of the exception.  Such a scheme
1028 is sometimes preferable to matching particular string values of $@ using
1029 regular expressions.  Here's an example:
1030
1031     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1032     if ($@) {
1033         if (ref($@) && UNIVERSAL::isa($@,"Some::Module::Exception")) {
1034             # handle Some::Module::Exception
1035         }
1036         else {
1037             # handle all other possible exceptions
1038         }
1039     }
1040
1041 Because perl will stringify uncaught exception messages before displaying
1042 them, you may want to overload stringification operations on such custom
1043 exception objects.  See L<overload> for details about that.
1044
1045 You can arrange for a callback to be run just before the C<die>
1046 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1047 handler will be called with the error text and can change the error
1048 message, if it sees fit, by calling C<die> again.  See
1049 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1050 L<"eval BLOCK"> for some examples.  Although this feature was meant
1051 to be run only right before your program was to exit, this is not
1052 currently the case--the C<$SIG{__DIE__}> hook is currently called
1053 even inside eval()ed blocks/strings!  If one wants the hook to do
1054 nothing in such situations, put
1055
1056         die @_ if $^S;
1057
1058 as the first line of the handler (see L<perlvar/$^S>).  Because
1059 this promotes strange action at a distance, this counterintuitive
1060 behavior may be fixed in a future release.  
1061
1062 =item do BLOCK
1063
1064 Not really a function.  Returns the value of the last command in the
1065 sequence of commands indicated by BLOCK.  When modified by a loop
1066 modifier, executes the BLOCK once before testing the loop condition.
1067 (On other statements the loop modifiers test the conditional first.)
1068
1069 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1070 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1071 See L<perlsyn> for alternative strategies.
1072
1073 =item do SUBROUTINE(LIST)
1074
1075 A deprecated form of subroutine call.  See L<perlsub>.
1076
1077 =item do EXPR
1078
1079 Uses the value of EXPR as a filename and executes the contents of the
1080 file as a Perl script.  Its primary use is to include subroutines
1081 from a Perl subroutine library.
1082
1083     do 'stat.pl';
1084
1085 is just like
1086
1087     scalar eval `cat stat.pl`;
1088
1089 except that it's more efficient and concise, keeps track of the current
1090 filename for error messages, searches the @INC libraries, and updates
1091 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1092 variables.  It also differs in that code evaluated with C<do FILENAME>
1093 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1094 same, however, in that it does reparse the file every time you call it,
1095 so you probably don't want to do this inside a loop.
1096
1097 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1098 error.  If C<do> can read the file but cannot compile it, it
1099 returns undef and sets an error message in C<$@>.   If the file is
1100 successfully compiled, C<do> returns the value of the last expression
1101 evaluated.
1102
1103 Note that inclusion of library modules is better done with the
1104 C<use> and C<require> operators, which also do automatic error checking
1105 and raise an exception if there's a problem.
1106
1107 You might like to use C<do> to read in a program configuration
1108 file.  Manual error checking can be done this way:
1109
1110     # read in config files: system first, then user 
1111     for $file ("/share/prog/defaults.rc",
1112                "$ENV{HOME}/.someprogrc") 
1113    {
1114         unless ($return = do $file) {
1115             warn "couldn't parse $file: $@" if $@;
1116             warn "couldn't do $file: $!"    unless defined $return;
1117             warn "couldn't run $file"       unless $return;
1118         }
1119     }
1120
1121 =item dump LABEL
1122
1123 =item dump
1124
1125 This function causes an immediate core dump.  See also the B<-u>
1126 command-line switch in L<perlrun>, which does the same thing.
1127 Primarily this is so that you can use the B<undump> program (not
1128 supplied) to turn your core dump into an executable binary after
1129 having initialized all your variables at the beginning of the
1130 program.  When the new binary is executed it will begin by executing
1131 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1132 Think of it as a goto with an intervening core dump and reincarnation.
1133 If C<LABEL> is omitted, restarts the program from the top.
1134
1135 B<WARNING>: Any files opened at the time of the dump will I<not>
1136 be open any more when the program is reincarnated, with possible
1137 resulting confusion on the part of Perl.  
1138
1139 This function is now largely obsolete, partly because it's very
1140 hard to convert a core file into an executable, and because the
1141 real compiler backends for generating portable bytecode and compilable
1142 C code have superseded it.
1143
1144 If you're looking to use L<dump> to speed up your program, consider
1145 generating bytecode or native C code as described in L<perlcc>.  If
1146 you're just trying to accelerate a CGI script, consider using the
1147 C<mod_perl> extension to B<Apache>, or the CPAN module, Fast::CGI.
1148 You might also consider autoloading or selfloading, which at least
1149 make your program I<appear> to run faster.  
1150
1151 =item each HASH
1152
1153 When called in list context, returns a 2-element list consisting of the
1154 key and value for the next element of a hash, so that you can iterate over
1155 it.  When called in scalar context, returns the key for only the "next"
1156 element in the hash.  (Note: Keys may be C<"0"> or C<"">, which are logically
1157 false; you may wish to avoid constructs like C<while ($k = each %foo) {}>
1158 for this reason.)
1159
1160 Entries are returned in an apparently random order.  The actual random
1161 order is subject to change in future versions of perl, but it is guaranteed
1162 to be in the same order as either the C<keys> or C<values> function
1163 would produce on the same (unmodified) hash.
1164
1165 When the hash is entirely read, a null array is returned in list context
1166 (which when assigned produces a false (C<0>) value), and C<undef> in
1167 scalar context.  The next call to C<each> after that will start iterating
1168 again.  There is a single iterator for each hash, shared by all C<each>,
1169 C<keys>, and C<values> function calls in the program; it can be reset by
1170 reading all the elements from the hash, or by evaluating C<keys HASH> or
1171 C<values HASH>.  If you add or delete elements of a hash while you're
1172 iterating over it, you may get entries skipped or duplicated, so don't.
1173
1174 The following prints out your environment like the printenv(1) program,
1175 only in a different order:
1176
1177     while (($key,$value) = each %ENV) {
1178         print "$key=$value\n";
1179     }
1180
1181 See also C<keys>, C<values> and C<sort>.
1182
1183 =item eof FILEHANDLE
1184
1185 =item eof ()
1186
1187 =item eof
1188
1189 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1190 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1191 gives the real filehandle.  (Note that this function actually
1192 reads a character and then C<ungetc>s it, so isn't very useful in an
1193 interactive context.)  Do not read from a terminal file (or call
1194 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1195 as terminals may lose the end-of-file condition if you do.
1196
1197 An C<eof> without an argument uses the last file read.  Using C<eof()>
1198 with empty parentheses is very different.  It refers to the pseudo file
1199 formed from the files listed on the command line and accessed via the
1200 C<E<lt>E<gt>> operator.  Since C<E<lt>E<gt>> isn't explicitly opened,
1201 as a normal filehandle is, an C<eof()> before C<E<lt>E<gt>> has been
1202 used will cause C<@ARGV> to be examined to determine if input is
1203 available.
1204
1205 In a C<while (E<lt>E<gt>)> loop, C<eof> or C<eof(ARGV)> can be used to
1206 detect the end of each file, C<eof()> will only detect the end of the
1207 last file.  Examples:
1208
1209     # reset line numbering on each input file
1210     while (<>) {
1211         next if /^\s*#/;        # skip comments 
1212         print "$.\t$_";
1213     } continue {
1214         close ARGV  if eof;     # Not eof()!
1215     }
1216
1217     # insert dashes just before last line of last file
1218     while (<>) {
1219         if (eof()) {            # check for end of current file
1220             print "--------------\n";
1221             close(ARGV);        # close or last; is needed if we
1222                                 # are reading from the terminal
1223         }
1224         print;
1225     }
1226
1227 Practical hint: you almost never need to use C<eof> in Perl, because the
1228 input operators typically return C<undef> when they run out of data, or if
1229 there was an error.
1230
1231 =item eval EXPR
1232
1233 =item eval BLOCK
1234
1235 In the first form, the return value of EXPR is parsed and executed as if it
1236 were a little Perl program.  The value of the expression (which is itself
1237 determined within scalar context) is first parsed, and if there weren't any
1238 errors, executed in the context of the current Perl program, so that any
1239 variable settings or subroutine and format definitions remain afterwards.
1240 Note that the value is parsed every time the eval executes.  If EXPR is
1241 omitted, evaluates C<$_>.  This form is typically used to delay parsing
1242 and subsequent execution of the text of EXPR until run time.
1243
1244 In the second form, the code within the BLOCK is parsed only once--at the
1245 same time the code surrounding the eval itself was parsed--and executed
1246 within the context of the current Perl program.  This form is typically
1247 used to trap exceptions more efficiently than the first (see below), while
1248 also providing the benefit of checking the code within BLOCK at compile
1249 time.
1250
1251 The final semicolon, if any, may be omitted from the value of EXPR or within
1252 the BLOCK.
1253
1254 In both forms, the value returned is the value of the last expression
1255 evaluated inside the mini-program; a return statement may be also used, just
1256 as with subroutines.  The expression providing the return value is evaluated
1257 in void, scalar, or list context, depending on the context of the eval itself.
1258 See L</wantarray> for more on how the evaluation context can be determined.
1259
1260 If there is a syntax error or runtime error, or a C<die> statement is
1261 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1262 error message.  If there was no error, C<$@> is guaranteed to be a null
1263 string.  Beware that using C<eval> neither silences perl from printing
1264 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1265 To do either of those, you have to use the C<$SIG{__WARN__}> facility.  See
1266 L</warn> and L<perlvar>.
1267
1268 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1269 determining whether a particular feature (such as C<socket> or C<symlink>)
1270 is implemented.  It is also Perl's exception trapping mechanism, where
1271 the die operator is used to raise exceptions.
1272
1273 If the code to be executed doesn't vary, you may use the eval-BLOCK
1274 form to trap run-time errors without incurring the penalty of
1275 recompiling each time.  The error, if any, is still returned in C<$@>.
1276 Examples:
1277
1278     # make divide-by-zero nonfatal
1279     eval { $answer = $a / $b; }; warn $@ if $@;
1280
1281     # same thing, but less efficient
1282     eval '$answer = $a / $b'; warn $@ if $@;
1283
1284     # a compile-time error
1285     eval { $answer = };                 # WRONG
1286
1287     # a run-time error
1288     eval '$answer =';   # sets $@
1289
1290 Due to the current arguably broken state of C<__DIE__> hooks, when using
1291 the C<eval{}> form as an exception trap in libraries, you may wish not
1292 to trigger any C<__DIE__> hooks that user code may have installed.
1293 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1294 as shown in this example:
1295
1296     # a very private exception trap for divide-by-zero
1297     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1298     warn $@ if $@;
1299
1300 This is especially significant, given that C<__DIE__> hooks can call
1301 C<die> again, which has the effect of changing their error messages:
1302
1303     # __DIE__ hooks may modify error messages
1304     {
1305        local $SIG{'__DIE__'} =
1306               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1307        eval { die "foo lives here" };
1308        print $@ if $@;                # prints "bar lives here"
1309     }
1310
1311 Because this promotes action at a distance, this counterintuitive behavior
1312 may be fixed in a future release.
1313
1314 With an C<eval>, you should be especially careful to remember what's
1315 being looked at when:
1316
1317     eval $x;            # CASE 1
1318     eval "$x";          # CASE 2
1319
1320     eval '$x';          # CASE 3
1321     eval { $x };        # CASE 4
1322
1323     eval "\$$x++";      # CASE 5
1324     $$x++;              # CASE 6
1325
1326 Cases 1 and 2 above behave identically: they run the code contained in
1327 the variable $x.  (Although case 2 has misleading double quotes making
1328 the reader wonder what else might be happening (nothing is).)  Cases 3
1329 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1330 does nothing but return the value of $x.  (Case 4 is preferred for
1331 purely visual reasons, but it also has the advantage of compiling at
1332 compile-time instead of at run-time.)  Case 5 is a place where
1333 normally you I<would> like to use double quotes, except that in this
1334 particular situation, you can just use symbolic references instead, as
1335 in case 6.
1336
1337 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1338 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1339
1340 =item exec LIST
1341
1342 =item exec PROGRAM LIST
1343
1344 The C<exec> function executes a system command I<and never returns>--
1345 use C<system> instead of C<exec> if you want it to return.  It fails and
1346 returns false only if the command does not exist I<and> it is executed
1347 directly instead of via your system's command shell (see below).
1348
1349 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1350 warns you if there is a following statement which isn't C<die>, C<warn>,
1351 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1352 I<really> want to follow an C<exec> with some other statement, you
1353 can use one of these styles to avoid the warning:
1354
1355     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1356     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1357
1358 If there is more than one argument in LIST, or if LIST is an array
1359 with more than one value, calls execvp(3) with the arguments in LIST.
1360 If there is only one scalar argument or an array with one element in it,
1361 the argument is checked for shell metacharacters, and if there are any,
1362 the entire argument is passed to the system's command shell for parsing
1363 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1364 If there are no shell metacharacters in the argument, it is split into
1365 words and passed directly to C<execvp>, which is more efficient.  
1366 Examples:
1367
1368     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1369     exec "sort $outfile | uniq";
1370
1371 If you don't really want to execute the first argument, but want to lie
1372 to the program you are executing about its own name, you can specify
1373 the program you actually want to run as an "indirect object" (without a
1374 comma) in front of the LIST.  (This always forces interpretation of the
1375 LIST as a multivalued list, even if there is only a single scalar in
1376 the list.)  Example:
1377
1378     $shell = '/bin/csh';
1379     exec $shell '-sh';          # pretend it's a login shell
1380
1381 or, more directly,
1382
1383     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1384
1385 When the arguments get executed via the system shell, results will
1386 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1387 for details.
1388
1389 Using an indirect object with C<exec> or C<system> is also more
1390 secure.  This usage (which also works fine with system()) forces
1391 interpretation of the arguments as a multivalued list, even if the
1392 list had just one argument.  That way you're safe from the shell
1393 expanding wildcards or splitting up words with whitespace in them.
1394
1395     @args = ( "echo surprise" );
1396
1397     exec @args;               # subject to shell escapes
1398                                 # if @args == 1
1399     exec { $args[0] } @args;  # safe even with one-arg list
1400
1401 The first version, the one without the indirect object, ran the I<echo>
1402 program, passing it C<"surprise"> an argument.  The second version
1403 didn't--it tried to run a program literally called I<"echo surprise">,
1404 didn't find it, and set C<$?> to a non-zero value indicating failure.
1405
1406 Note that C<exec> will not call your C<END> blocks, nor will it call
1407 any C<DESTROY> methods in your objects.
1408
1409 =item exists EXPR
1410
1411 Given an expression that specifies a hash element or array element,
1412 returns true if the specified element in the hash or array has ever
1413 been initialized, even if the corresponding value is undefined.  The
1414 element is not autovivified if it doesn't exist.
1415
1416     print "Exists\n"    if exists $hash{$key};
1417     print "Defined\n"   if defined $hash{$key};
1418     print "True\n"      if $hash{$key};
1419
1420     print "Exists\n"    if exists $array[$index];
1421     print "Defined\n"   if defined $array[$index];
1422     print "True\n"      if $array[$index];
1423
1424 A hash or array element can be true only if it's defined, and defined if
1425 it exists, but the reverse doesn't necessarily hold true.
1426
1427 Given an expression that specifies the name of a subroutine,
1428 returns true if the specified subroutine has ever been declared, even
1429 if it is undefined.  Mentioning a subroutine name for exists or defined
1430 does not count as declaring it.
1431
1432     print "Exists\n"    if exists &subroutine;
1433     print "Defined\n"   if defined &subroutine;
1434
1435 Note that the EXPR can be arbitrarily complicated as long as the final
1436 operation is a hash or array key lookup or subroutine name:
1437
1438     if (exists $ref->{A}->{B}->{$key})  { }
1439     if (exists $hash{A}{B}{$key})       { }
1440
1441     if (exists $ref->{A}->{B}->[$ix])   { }
1442     if (exists $hash{A}{B}[$ix])        { }
1443
1444     if (exists &{$ref->{A}{B}{$key}})   { }
1445
1446 Although the deepest nested array or hash will not spring into existence
1447 just because its existence was tested, any intervening ones will.
1448 Thus C<$ref-E<gt>{"A"}> and C<$ref-E<gt>{"A"}-E<gt>{"B"}> will spring
1449 into existence due to the existence test for the $key element above.
1450 This happens anywhere the arrow operator is used, including even:
1451
1452     undef $ref;
1453     if (exists $ref->{"Some key"})      { }
1454     print $ref;             # prints HASH(0x80d3d5c)
1455
1456 This surprising autovivification in what does not at first--or even
1457 second--glance appear to be an lvalue context may be fixed in a future
1458 release.
1459
1460 See L<perlref/"Pseudo-hashes"> for specifics on how exists() acts when
1461 used on a pseudo-hash.
1462
1463 Use of a subroutine call, rather than a subroutine name, as an argument
1464 to exists() is an error.
1465
1466     exists &sub;        # OK
1467     exists &sub();      # Error
1468
1469 =item exit EXPR
1470
1471 Evaluates EXPR and exits immediately with that value.    Example:
1472
1473     $ans = <STDIN>;
1474     exit 0 if $ans =~ /^[Xx]/;
1475
1476 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1477 universally recognized values for EXPR are C<0> for success and C<1>
1478 for error; other values are subject to interpretation depending on the
1479 environment in which the Perl program is running.  For example, exiting
1480 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1481 the mailer to return the item undelivered, but that's not true everywhere.
1482
1483 Don't use C<exit> to abort a subroutine if there's any chance that
1484 someone might want to trap whatever error happened.  Use C<die> instead,
1485 which can be trapped by an C<eval>.
1486
1487 The exit() function does not always exit immediately.  It calls any
1488 defined C<END> routines first, but these C<END> routines may not
1489 themselves abort the exit.  Likewise any object destructors that need to
1490 be called are called before the real exit.  If this is a problem, you
1491 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1492 See L<perlmod> for details.
1493
1494 =item exp EXPR
1495
1496 =item exp
1497
1498 Returns I<e> (the natural logarithm base) to the power of EXPR.  
1499 If EXPR is omitted, gives C<exp($_)>.
1500
1501 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1502
1503 Implements the fcntl(2) function.  You'll probably have to say
1504
1505     use Fcntl;
1506
1507 first to get the correct constant definitions.  Argument processing and
1508 value return works just like C<ioctl> below.  
1509 For example:
1510
1511     use Fcntl;
1512     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1513         or die "can't fcntl F_GETFL: $!";
1514
1515 You don't have to check for C<defined> on the return from C<fnctl>.
1516 Like C<ioctl>, it maps a C<0> return from the system call into
1517 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1518 in numeric context.  It is also exempt from the normal B<-w> warnings
1519 on improper numeric conversions.
1520
1521 Note that C<fcntl> will produce a fatal error if used on a machine that
1522 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1523 manpage to learn what functions are available on your system.
1524
1525 =item fileno FILEHANDLE
1526
1527 Returns the file descriptor for a filehandle, or undefined if the
1528 filehandle is not open.  This is mainly useful for constructing
1529 bitmaps for C<select> and low-level POSIX tty-handling operations.
1530 If FILEHANDLE is an expression, the value is taken as an indirect
1531 filehandle, generally its name.
1532
1533 You can use this to find out whether two handles refer to the 
1534 same underlying descriptor:
1535
1536     if (fileno(THIS) == fileno(THAT)) {
1537         print "THIS and THAT are dups\n";
1538     } 
1539
1540 =item flock FILEHANDLE,OPERATION
1541
1542 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1543 for success, false on failure.  Produces a fatal error if used on a
1544 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1545 C<flock> is Perl's portable file locking interface, although it locks
1546 only entire files, not records.
1547
1548 Two potentially non-obvious but traditional C<flock> semantics are
1549 that it waits indefinitely until the lock is granted, and that its locks
1550 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1551 fewer guarantees.  This means that files locked with C<flock> may be
1552 modified by programs that do not also use C<flock>.  See L<perlport>,
1553 your port's specific documentation, or your system-specific local manpages
1554 for details.  It's best to assume traditional behavior if you're writing
1555 portable programs.  (But if you're not, you should as always feel perfectly
1556 free to write for your own system's idiosyncrasies (sometimes called
1557 "features").  Slavish adherence to portability concerns shouldn't get
1558 in the way of your getting your job done.)
1559
1560 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1561 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1562 you can use the symbolic names if you import them from the Fcntl module,
1563 either individually, or as a group using the ':flock' tag.  LOCK_SH
1564 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1565 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1566 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1567 waiting for the lock (check the return status to see if you got it).
1568
1569 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1570 before locking or unlocking it.
1571
1572 Note that the emulation built with lockf(3) doesn't provide shared
1573 locks, and it requires that FILEHANDLE be open with write intent.  These
1574 are the semantics that lockf(3) implements.  Most if not all systems
1575 implement lockf(3) in terms of fcntl(2) locking, though, so the
1576 differing semantics shouldn't bite too many people.
1577
1578 Note also that some versions of C<flock> cannot lock things over the
1579 network; you would need to use the more system-specific C<fcntl> for
1580 that.  If you like you can force Perl to ignore your system's flock(2)
1581 function, and so provide its own fcntl(2)-based emulation, by passing
1582 the switch C<-Ud_flock> to the F<Configure> program when you configure
1583 perl.
1584
1585 Here's a mailbox appender for BSD systems.
1586
1587     use Fcntl ':flock'; # import LOCK_* constants
1588
1589     sub lock {
1590         flock(MBOX,LOCK_EX);
1591         # and, in case someone appended
1592         # while we were waiting...
1593         seek(MBOX, 0, 2);
1594     }
1595
1596     sub unlock {
1597         flock(MBOX,LOCK_UN);
1598     }
1599
1600     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1601             or die "Can't open mailbox: $!";
1602
1603     lock();
1604     print MBOX $msg,"\n\n";
1605     unlock();
1606
1607 On systems that support a real flock(), locks are inherited across fork()
1608 calls, whereas those that must resort to the more capricious fcntl()
1609 function lose the locks, making it harder to write servers.
1610
1611 See also L<DB_File> for other flock() examples.
1612
1613 =item fork
1614
1615 Does a fork(2) system call to create a new process running the
1616 same program at the same point.  It returns the child pid to the
1617 parent process, C<0> to the child process, or C<undef> if the fork is
1618 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1619 are shared, while everything else is copied.  On most systems supporting
1620 fork(), great care has gone into making it extremely efficient (for
1621 example, using copy-on-write technology on data pages), making it the
1622 dominant paradigm for multitasking over the last few decades.
1623
1624 All files opened for output are flushed before forking the child process.
1625
1626 If you C<fork> without ever waiting on your children, you will
1627 accumulate zombies.  On some systems, you can avoid this by setting
1628 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1629 forking and reaping moribund children.
1630
1631 Note that if your forked child inherits system file descriptors like
1632 STDIN and STDOUT that are actually connected by a pipe or socket, even
1633 if you exit, then the remote server (such as, say, a CGI script or a
1634 backgrounded job launched from a remote shell) won't think you're done.
1635 You should reopen those to F</dev/null> if it's any issue.
1636
1637 =item format
1638
1639 Declare a picture format for use by the C<write> function.  For
1640 example:
1641
1642     format Something =
1643         Test: @<<<<<<<< @||||| @>>>>>
1644               $str,     $%,    '$' . int($num)
1645     .
1646
1647     $str = "widget";
1648     $num = $cost/$quantity;
1649     $~ = 'Something';
1650     write;
1651
1652 See L<perlform> for many details and examples.
1653
1654 =item formline PICTURE,LIST
1655
1656 This is an internal function used by C<format>s, though you may call it,
1657 too.  It formats (see L<perlform>) a list of values according to the
1658 contents of PICTURE, placing the output into the format output
1659 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1660 Eventually, when a C<write> is done, the contents of
1661 C<$^A> are written to some filehandle, but you could also read C<$^A>
1662 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1663 does one C<formline> per line of form, but the C<formline> function itself
1664 doesn't care how many newlines are embedded in the PICTURE.  This means
1665 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1666 You may therefore need to use multiple formlines to implement a single
1667 record format, just like the format compiler.
1668
1669 Be careful if you put double quotes around the picture, because an C<@>
1670 character may be taken to mean the beginning of an array name.
1671 C<formline> always returns true.  See L<perlform> for other examples.
1672
1673 =item getc FILEHANDLE
1674
1675 =item getc
1676
1677 Returns the next character from the input file attached to FILEHANDLE,
1678 or the undefined value at end of file, or if there was an error.
1679 If FILEHANDLE is omitted, reads from STDIN.  This is not particularly
1680 efficient.  However, it cannot be used by itself to fetch single
1681 characters without waiting for the user to hit enter.  For that, try
1682 something more like:
1683
1684     if ($BSD_STYLE) {
1685         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1686     }
1687     else {
1688         system "stty", '-icanon', 'eol', "\001";
1689     }
1690
1691     $key = getc(STDIN);
1692
1693     if ($BSD_STYLE) {
1694         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1695     }
1696     else {
1697         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1698     }
1699     print "\n";
1700
1701 Determination of whether $BSD_STYLE should be set
1702 is left as an exercise to the reader.
1703
1704 The C<POSIX::getattr> function can do this more portably on
1705 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1706 module from your nearest CPAN site; details on CPAN can be found on
1707 L<perlmodlib/CPAN>.
1708
1709 =item getlogin
1710
1711 Implements the C library function of the same name, which on most
1712 systems returns the current login from F</etc/utmp>, if any.  If null,
1713 use C<getpwuid>.
1714
1715     $login = getlogin || getpwuid($<) || "Kilroy";
1716
1717 Do not consider C<getlogin> for authentication: it is not as
1718 secure as C<getpwuid>.
1719
1720 =item getpeername SOCKET
1721
1722 Returns the packed sockaddr address of other end of the SOCKET connection.
1723
1724     use Socket;
1725     $hersockaddr    = getpeername(SOCK);
1726     ($port, $iaddr) = sockaddr_in($hersockaddr);
1727     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1728     $herstraddr     = inet_ntoa($iaddr);
1729
1730 =item getpgrp PID
1731
1732 Returns the current process group for the specified PID.  Use
1733 a PID of C<0> to get the current process group for the
1734 current process.  Will raise an exception if used on a machine that
1735 doesn't implement getpgrp(2).  If PID is omitted, returns process
1736 group of current process.  Note that the POSIX version of C<getpgrp>
1737 does not accept a PID argument, so only C<PID==0> is truly portable.
1738
1739 =item getppid
1740
1741 Returns the process id of the parent process.
1742
1743 =item getpriority WHICH,WHO
1744
1745 Returns the current priority for a process, a process group, or a user.
1746 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1747 machine that doesn't implement getpriority(2).
1748
1749 =item getpwnam NAME
1750
1751 =item getgrnam NAME
1752
1753 =item gethostbyname NAME
1754
1755 =item getnetbyname NAME
1756
1757 =item getprotobyname NAME
1758
1759 =item getpwuid UID
1760
1761 =item getgrgid GID
1762
1763 =item getservbyname NAME,PROTO
1764
1765 =item gethostbyaddr ADDR,ADDRTYPE
1766
1767 =item getnetbyaddr ADDR,ADDRTYPE
1768
1769 =item getprotobynumber NUMBER
1770
1771 =item getservbyport PORT,PROTO
1772
1773 =item getpwent
1774
1775 =item getgrent
1776
1777 =item gethostent
1778
1779 =item getnetent
1780
1781 =item getprotoent
1782
1783 =item getservent
1784
1785 =item setpwent
1786
1787 =item setgrent
1788
1789 =item sethostent STAYOPEN
1790
1791 =item setnetent STAYOPEN
1792
1793 =item setprotoent STAYOPEN
1794
1795 =item setservent STAYOPEN
1796
1797 =item endpwent
1798
1799 =item endgrent
1800
1801 =item endhostent
1802
1803 =item endnetent
1804
1805 =item endprotoent
1806
1807 =item endservent
1808
1809 These routines perform the same functions as their counterparts in the
1810 system library.  In list context, the return values from the
1811 various get routines are as follows:
1812
1813     ($name,$passwd,$uid,$gid,
1814        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1815     ($name,$passwd,$gid,$members) = getgr*
1816     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1817     ($name,$aliases,$addrtype,$net) = getnet*
1818     ($name,$aliases,$proto) = getproto*
1819     ($name,$aliases,$port,$proto) = getserv*
1820
1821 (If the entry doesn't exist you get a null list.)
1822
1823 In scalar context, you get the name, unless the function was a
1824 lookup by name, in which case you get the other thing, whatever it is.
1825 (If the entry doesn't exist you get the undefined value.)  For example:
1826
1827     $uid   = getpwnam($name);
1828     $name  = getpwuid($num);
1829     $name  = getpwent();
1830     $gid   = getgrnam($name);
1831     $name  = getgrgid($num;
1832     $name  = getgrent();
1833     #etc.
1834
1835 In I<getpw*()> the fields $quota, $comment, and $expire are
1836 special cases in the sense that in many systems they are unsupported.
1837 If the $quota is unsupported, it is an empty scalar.  If it is
1838 supported, it usually encodes the disk quota.  If the $comment
1839 field is unsupported, it is an empty scalar.  If it is supported it
1840 usually encodes some administrative comment about the user.  In some
1841 systems the $quota field may be $change or $age, fields that have
1842 to do with password aging.  In some systems the $comment field may
1843 be $class.  The $expire field, if present, encodes the expiration
1844 period of the account or the password.  For the availability and the
1845 exact meaning of these fields in your system, please consult your
1846 getpwnam(3) documentation and your F<pwd.h> file.  You can also find
1847 out from within Perl what your $quota and $comment fields mean
1848 and whether you have the $expire field by using the C<Config> module
1849 and the values C<d_pwquota>, C<d_pwage>, C<d_pwchange>, C<d_pwcomment>,
1850 and C<d_pwexpire>.  Shadow password files are only supported if your
1851 vendor has implemented them in the intuitive fashion that calling the
1852 regular C library routines gets the shadow versions if you're running
1853 under privilege.  Those that incorrectly implement a separate library
1854 call are not supported.
1855
1856 The $members value returned by I<getgr*()> is a space separated list of
1857 the login names of the members of the group.
1858
1859 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1860 C, it will be returned to you via C<$?> if the function call fails.  The
1861 C<@addrs> value returned by a successful call is a list of the raw
1862 addresses returned by the corresponding system library call.  In the
1863 Internet domain, each address is four bytes long and you can unpack it
1864 by saying something like:
1865
1866     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1867
1868 The Socket library makes this slightly easier:
1869
1870     use Socket;
1871     $iaddr = inet_aton("127.1"); # or whatever address
1872     $name  = gethostbyaddr($iaddr, AF_INET);
1873
1874     # or going the other way
1875     $straddr = inet_ntoa($iaddr);
1876
1877 If you get tired of remembering which element of the return list
1878 contains which return value, by-name interfaces are provided
1879 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
1880 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
1881 and C<User::grent>.  These override the normal built-ins, supplying
1882 versions that return objects with the appropriate names
1883 for each field.  For example:
1884
1885    use File::stat;
1886    use User::pwent;
1887    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
1888
1889 Even though it looks like they're the same method calls (uid), 
1890 they aren't, because a C<File::stat> object is different from 
1891 a C<User::pwent> object.
1892
1893 =item getsockname SOCKET
1894
1895 Returns the packed sockaddr address of this end of the SOCKET connection,
1896 in case you don't know the address because you have several different
1897 IPs that the connection might have come in on.
1898
1899     use Socket;
1900     $mysockaddr = getsockname(SOCK);
1901     ($port, $myaddr) = sockaddr_in($mysockaddr);
1902     printf "Connect to %s [%s]\n", 
1903        scalar gethostbyaddr($myaddr, AF_INET),
1904        inet_ntoa($myaddr);
1905
1906 =item getsockopt SOCKET,LEVEL,OPTNAME
1907
1908 Returns the socket option requested, or undef if there is an error.
1909
1910 =item glob EXPR
1911
1912 =item glob
1913
1914 Returns the value of EXPR with filename expansions such as the
1915 standard Unix shell F</bin/csh> would do.  This is the internal function
1916 implementing the C<E<lt>*.cE<gt>> operator, but you can use it directly.
1917 If EXPR is omitted, C<$_> is used.  The C<E<lt>*.cE<gt>> operator is
1918 discussed in more detail in L<perlop/"I/O Operators">.
1919
1920 =item gmtime EXPR
1921
1922 Converts a time as returned by the time function to a 9-element list
1923 with the time localized for the standard Greenwich time zone.
1924 Typically used as follows:
1925
1926     #  0    1    2     3     4    5     6     7     8
1927     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
1928                                             gmtime(time);
1929
1930 All list elements are numeric, and come straight out of a struct tm.
1931 In particular this means that $mon has the range C<0..11> and $wday
1932 has the range C<0..6> with sunday as day C<0>.  Also, $year is the
1933 number of years since 1900, that is, $year is C<123> in year 2023,
1934 I<not> simply the last two digits of the year.  If you assume it is,
1935 then you create non-Y2K-compliant programs--and you wouldn't want to do
1936 that, would you?
1937
1938 The proper way to get a complete 4-digit year is simply:
1939
1940         $year += 1900;
1941
1942 And to get the last two digits of the year (e.g., '01' in 2001) do:
1943
1944         $year = sprintf("%02d", $year % 100);
1945
1946 If EXPR is omitted, does C<gmtime(time())>.
1947
1948 In scalar context, returns the ctime(3) value:
1949
1950     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
1951
1952 Also see the C<timegm> function provided by the C<Time::Local> module,
1953 and the strftime(3) function available via the POSIX module.
1954
1955 This scalar value is B<not> locale dependent (see L<perllocale>), but
1956 is instead a Perl builtin.  Also see the C<Time::Local> module, and the
1957 strftime(3) and mktime(3) functions available via the POSIX module.  To
1958 get somewhat similar but locale dependent date strings, set up your
1959 locale environment variables appropriately (please see L<perllocale>)
1960 and try for example:
1961
1962     use POSIX qw(strftime);
1963     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
1964
1965 Note that the C<%a> and C<%b> escapes, which represent the short forms
1966 of the day of the week and the month of the year, may not necessarily
1967 be three characters wide in all locales.
1968
1969 =item goto LABEL
1970
1971 =item goto EXPR
1972
1973 =item goto &NAME
1974
1975 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
1976 execution there.  It may not be used to go into any construct that
1977 requires initialization, such as a subroutine or a C<foreach> loop.  It
1978 also can't be used to go into a construct that is optimized away,
1979 or to get out of a block or subroutine given to C<sort>.
1980 It can be used to go almost anywhere else within the dynamic scope,
1981 including out of subroutines, but it's usually better to use some other
1982 construct such as C<last> or C<die>.  The author of Perl has never felt the
1983 need to use this form of C<goto> (in Perl, that is--C is another matter).
1984
1985 The C<goto-EXPR> form expects a label name, whose scope will be resolved
1986 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
1987 necessarily recommended if you're optimizing for maintainability:
1988
1989     goto ("FOO", "BAR", "GLARCH")[$i];
1990
1991 The C<goto-&NAME> form is quite different from the other forms of C<goto>.
1992 In fact, it isn't a goto in the normal sense at all, and doesn't have
1993 the stigma associated with other gotos.  Instead, it
1994 substitutes a call to the named subroutine for the currently running
1995 subroutine.  This is used by C<AUTOLOAD> subroutines that wish to load
1996 another subroutine and then pretend that the other subroutine had been
1997 called in the first place (except that any modifications to C<@_>
1998 in the current subroutine are propagated to the other subroutine.)
1999 After the C<goto>, not even C<caller> will be able to tell that this
2000 routine was called first.
2001
2002 NAME needn't be the name of a subroutine; it can be a scalar variable
2003 containing a code reference, or a block which evaluates to a code
2004 reference.
2005
2006 =item grep BLOCK LIST
2007
2008 =item grep EXPR,LIST
2009
2010 This is similar in spirit to, but not the same as, grep(1) and its
2011 relatives.  In particular, it is not limited to using regular expressions.
2012
2013 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2014 C<$_> to each element) and returns the list value consisting of those
2015 elements for which the expression evaluated to true.  In scalar
2016 context, returns the number of times the expression was true.
2017
2018     @foo = grep(!/^#/, @bar);    # weed out comments
2019
2020 or equivalently,
2021
2022     @foo = grep {!/^#/} @bar;    # weed out comments
2023
2024 Note that, because C<$_> is a reference into the list value, it can
2025 be used to modify the elements of the array.  While this is useful and
2026 supported, it can cause bizarre results if the LIST is not a named array.
2027 Similarly, grep returns aliases into the original list, much as a for
2028 loop's index variable aliases the list elements.  That is, modifying an
2029 element of a list returned by grep (for example, in a C<foreach>, C<map>
2030 or another C<grep>) actually modifies the element in the original list.
2031 This is usually something to be avoided when writing clear code.
2032
2033 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2034
2035 =item hex EXPR
2036
2037 =item hex
2038
2039 Interprets EXPR as a hex string and returns the corresponding value.
2040 (To convert strings that might start with either 0, 0x, or 0b, see
2041 L</oct>.)  If EXPR is omitted, uses C<$_>.
2042
2043     print hex '0xAf'; # prints '175'
2044     print hex 'aF';   # same
2045
2046 Hex strings may only represent integers.  Strings that would cause
2047 integer overflow trigger a warning.
2048
2049 =item import
2050
2051 There is no builtin C<import> function.  It is just an ordinary
2052 method (subroutine) defined (or inherited) by modules that wish to export
2053 names to another module.  The C<use> function calls the C<import> method
2054 for the package used.  See also L</use()>, L<perlmod>, and L<Exporter>.
2055
2056 =item index STR,SUBSTR,POSITION
2057
2058 =item index STR,SUBSTR
2059
2060 The index function searches for one string within another, but without
2061 the wildcard-like behavior of a full regular-expression pattern match.
2062 It returns the position of the first occurrence of SUBSTR in STR at
2063 or after POSITION.  If POSITION is omitted, starts searching from the
2064 beginning of the string.  The return value is based at C<0> (or whatever
2065 you've set the C<$[> variable to--but don't do that).  If the substring
2066 is not found, returns one less than the base, ordinarily C<-1>.
2067
2068 =item int EXPR
2069
2070 =item int
2071
2072 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2073 You should not use this function for rounding: one because it truncates
2074 towards C<0>, and two because machine representations of floating point
2075 numbers can sometimes produce counterintuitive results.  For example,
2076 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2077 because it's really more like -268.99999999999994315658 instead.  Usually,
2078 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2079 functions will serve you better than will int().
2080
2081 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2082
2083 Implements the ioctl(2) function.  You'll probably first have to say
2084
2085     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
2086
2087 to get the correct function definitions.  If F<ioctl.ph> doesn't
2088 exist or doesn't have the correct definitions you'll have to roll your
2089 own, based on your C header files such as F<E<lt>sys/ioctl.hE<gt>>.
2090 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2091 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2092 written depending on the FUNCTION--a pointer to the string value of SCALAR
2093 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2094 has no string value but does have a numeric value, that value will be
2095 passed rather than a pointer to the string value.  To guarantee this to be
2096 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2097 functions may be needed to manipulate the values of structures used by
2098 C<ioctl>.  
2099
2100 The return value of C<ioctl> (and C<fcntl>) is as follows:
2101
2102         if OS returns:          then Perl returns:
2103             -1                    undefined value
2104              0                  string "0 but true"
2105         anything else               that number
2106
2107 Thus Perl returns true on success and false on failure, yet you can
2108 still easily determine the actual value returned by the operating
2109 system:
2110
2111     $retval = ioctl(...) || -1;
2112     printf "System returned %d\n", $retval;
2113
2114 The special string "C<0> but true" is exempt from B<-w> complaints
2115 about improper numeric conversions.
2116
2117 Here's an example of setting a filehandle named C<REMOTE> to be
2118 non-blocking at the system level.  You'll have to negotiate C<$|>
2119 on your own, though.
2120
2121     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2122
2123     $flags = fcntl(REMOTE, F_GETFL, 0)
2124                 or die "Can't get flags for the socket: $!\n";
2125
2126     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2127                 or die "Can't set flags for the socket: $!\n";
2128
2129 =item join EXPR,LIST
2130
2131 Joins the separate strings of LIST into a single string with fields
2132 separated by the value of EXPR, and returns that new string.  Example:
2133
2134     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2135
2136 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2137 first argument.  Compare L</split>.
2138
2139 =item keys HASH
2140
2141 Returns a list consisting of all the keys of the named hash.  (In
2142 scalar context, returns the number of keys.)  The keys are returned in
2143 an apparently random order.  The actual random order is subject to
2144 change in future versions of perl, but it is guaranteed to be the same
2145 order as either the C<values> or C<each> function produces (given
2146 that the hash has not been modified).  As a side effect, it resets
2147 HASH's iterator.
2148
2149 Here is yet another way to print your environment:
2150
2151     @keys = keys %ENV;
2152     @values = values %ENV;
2153     while (@keys) { 
2154         print pop(@keys), '=', pop(@values), "\n";
2155     }
2156
2157 or how about sorted by key:
2158
2159     foreach $key (sort(keys %ENV)) {
2160         print $key, '=', $ENV{$key}, "\n";
2161     }
2162
2163 To sort a hash by value, you'll need to use a C<sort> function.
2164 Here's a descending numeric sort of a hash by its values:
2165
2166     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2167         printf "%4d %s\n", $hash{$key}, $key;
2168     }
2169
2170 As an lvalue C<keys> allows you to increase the number of hash buckets
2171 allocated for the given hash.  This can gain you a measure of efficiency if
2172 you know the hash is going to get big.  (This is similar to pre-extending
2173 an array by assigning a larger number to $#array.)  If you say
2174
2175     keys %hash = 200;
2176
2177 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2178 in fact, since it rounds up to the next power of two.  These
2179 buckets will be retained even if you do C<%hash = ()>, use C<undef
2180 %hash> if you want to free the storage while C<%hash> is still in scope.
2181 You can't shrink the number of buckets allocated for the hash using
2182 C<keys> in this way (but you needn't worry about doing this by accident,
2183 as trying has no effect).
2184
2185 See also C<each>, C<values> and C<sort>.
2186
2187 =item kill SIGNAL, LIST
2188
2189 Sends a signal to a list of processes.  Returns the number of
2190 processes successfully signaled (which is not necessarily the
2191 same as the number actually killed).
2192
2193     $cnt = kill 1, $child1, $child2;
2194     kill 9, @goners;
2195
2196 If SIGNAL is zero, no signal is sent to the process.  This is a
2197 useful way to check that the process is alive and hasn't changed
2198 its UID.  See L<perlport> for notes on the portability of this
2199 construct.
2200
2201 Unlike in the shell, if SIGNAL is negative, it kills
2202 process groups instead of processes.  (On System V, a negative I<PROCESS>
2203 number will also kill process groups, but that's not portable.)  That
2204 means you usually want to use positive not negative signals.  You may also
2205 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
2206
2207 =item last LABEL
2208
2209 =item last
2210
2211 The C<last> command is like the C<break> statement in C (as used in
2212 loops); it immediately exits the loop in question.  If the LABEL is
2213 omitted, the command refers to the innermost enclosing loop.  The
2214 C<continue> block, if any, is not executed:
2215
2216     LINE: while (<STDIN>) {
2217         last LINE if /^$/;      # exit when done with header
2218         #...
2219     }
2220
2221 C<last> cannot be used to exit a block which returns a value such as
2222 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2223 a grep() or map() operation.
2224
2225 Note that a block by itself is semantically identical to a loop
2226 that executes once.  Thus C<last> can be used to effect an early
2227 exit out of such a block.
2228
2229 See also L</continue> for an illustration of how C<last>, C<next>, and
2230 C<redo> work.
2231
2232 =item lc EXPR
2233
2234 =item lc
2235
2236 Returns an lowercased version of EXPR.  This is the internal function
2237 implementing the C<\L> escape in double-quoted strings.
2238 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2239 and L<utf8>.
2240
2241 If EXPR is omitted, uses C<$_>.
2242
2243 =item lcfirst EXPR
2244
2245 =item lcfirst
2246
2247 Returns the value of EXPR with the first character lowercased.  This is
2248 the internal function implementing the C<\l> escape in double-quoted strings.
2249 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
2250
2251 If EXPR is omitted, uses C<$_>.
2252
2253 =item length EXPR
2254
2255 =item length
2256
2257 Returns the length in characters of the value of EXPR.  If EXPR is
2258 omitted, returns length of C<$_>.  Note that this cannot be used on 
2259 an entire array or hash to find out how many elements these have.
2260 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2261
2262 =item link OLDFILE,NEWFILE
2263
2264 Creates a new filename linked to the old filename.  Returns true for
2265 success, false otherwise. 
2266
2267 =item listen SOCKET,QUEUESIZE
2268
2269 Does the same thing that the listen system call does.  Returns true if
2270 it succeeded, false otherwise.  See the example in L<perlipc/"Sockets: Client/Server Communication">.
2271
2272 =item local EXPR
2273
2274 You really probably want to be using C<my> instead, because C<local> isn't
2275 what most people think of as "local".  See L<perlsub/"Private Variables
2276 via my()"> for details.
2277
2278 A local modifies the listed variables to be local to the enclosing
2279 block, file, or eval.  If more than one value is listed, the list must
2280 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2281 for details, including issues with tied arrays and hashes.
2282
2283 =item localtime EXPR
2284
2285 Converts a time as returned by the time function to a 9-element list
2286 with the time analyzed for the local time zone.  Typically used as
2287 follows:
2288
2289     #  0    1    2     3     4    5     6     7     8
2290     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2291                                                 localtime(time);
2292
2293 All list elements are numeric, and come straight out of a struct tm.
2294 In particular this means that $mon has the range C<0..11> and $wday
2295 has the range C<0..6> with sunday as day C<0>.  Also, $year is the
2296 number of years since 1900, that is, $year is C<123> in year 2023,
2297 and I<not> simply the last two digits of the year.  If you assume it is,
2298 then you create non-Y2K-compliant programs--and you wouldn't want to do
2299 that, would you?
2300
2301 The proper way to get a complete 4-digit year is simply:
2302
2303         $year += 1900;
2304
2305 And to get the last two digits of the year (e.g., '01' in 2001) do:
2306
2307         $year = sprintf("%02d", $year % 100);
2308
2309 If EXPR is omitted, uses the current time (C<localtime(time)>).
2310
2311 In scalar context, returns the ctime(3) value:
2312
2313     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2314
2315 This scalar value is B<not> locale dependent, see L<perllocale>, but
2316 instead a Perl builtin.  Also see the C<Time::Local> module
2317 (to convert the second, minutes, hours, ... back to seconds since the
2318 stroke of midnight the 1st of January 1970, the value returned by
2319 time()), and the strftime(3) and mktime(3) function available via the
2320 POSIX module.  To get somewhat similar but locale dependent date
2321 strings, set up your locale environment variables appropriately
2322 (please see L<perllocale>) and try for example:
2323
2324     use POSIX qw(strftime);
2325     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2326
2327 Note that the C<%a> and C<%b>, the short forms of the day of the week
2328 and the month of the year, may not necessarily be three characters wide.
2329
2330 =item lock
2331
2332     lock I<THING>
2333
2334 This function places an advisory lock on a variable, subroutine,
2335 or referenced object contained in I<THING> until the lock goes out
2336 of scope.  This is a built-in function only if your version of Perl
2337 was built with threading enabled, and if you've said C<use Threads>.
2338 Otherwise a user-defined function by this name will be called.  See
2339 L<Thread>.
2340
2341 =item log EXPR
2342
2343 =item log
2344
2345 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2346 returns log of C<$_>.  To get the log of another base, use basic algebra:
2347 The base-N log of a number is equal to the natural log of that number
2348 divided by the natural log of N.  For example:
2349
2350     sub log10 {
2351         my $n = shift;
2352         return log($n)/log(10);
2353     } 
2354
2355 See also L</exp> for the inverse operation.
2356
2357 =item lstat FILEHANDLE
2358
2359 =item lstat EXPR
2360
2361 =item lstat
2362
2363 Does the same thing as the C<stat> function (including setting the
2364 special C<_> filehandle) but stats a symbolic link instead of the file
2365 the symbolic link points to.  If symbolic links are unimplemented on
2366 your system, a normal C<stat> is done.
2367
2368 If EXPR is omitted, stats C<$_>.
2369
2370 =item m//
2371
2372 The match operator.  See L<perlop>.
2373
2374 =item map BLOCK LIST
2375
2376 =item map EXPR,LIST
2377
2378 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2379 C<$_> to each element) and returns the list value composed of the
2380 results of each such evaluation.  In scalar context, returns the
2381 total number of elements so generated.  Evaluates BLOCK or EXPR in
2382 list context, so each element of LIST may produce zero, one, or
2383 more elements in the returned value.
2384
2385     @chars = map(chr, @nums);
2386
2387 translates a list of numbers to the corresponding characters.  And
2388
2389     %hash = map { getkey($_) => $_ } @array;
2390
2391 is just a funny way to write
2392
2393     %hash = ();
2394     foreach $_ (@array) {
2395         $hash{getkey($_)} = $_;
2396     }
2397
2398 Note that, because C<$_> is a reference into the list value, it can
2399 be used to modify the elements of the array.  While this is useful and
2400 supported, it can cause bizarre results if the LIST is not a named array.
2401 Using a regular C<foreach> loop for this purpose would be clearer in
2402 most cases.  See also L</grep> for an array composed of those items of
2403 the original list for which the BLOCK or EXPR evaluates to true.
2404
2405 =item mkdir FILENAME,MASK
2406
2407 Creates the directory specified by FILENAME, with permissions
2408 specified by MASK (as modified by C<umask>).  If it succeeds it
2409 returns true, otherwise it returns false and sets C<$!> (errno).
2410
2411 In general, it is better to create directories with permissive MASK,
2412 and let the user modify that with their C<umask>, than it is to supply
2413 a restrictive MASK and give the user no way to be more permissive.
2414 The exceptions to this rule are when the file or directory should be
2415 kept private (mail files, for instance).  The perlfunc(1) entry on
2416 C<umask> discusses the choice of MASK in more detail.
2417
2418 =item msgctl ID,CMD,ARG
2419
2420 Calls the System V IPC function msgctl(2).  You'll probably have to say
2421
2422     use IPC::SysV;
2423
2424 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2425 then ARG must be a variable which will hold the returned C<msqid_ds>
2426 structure.  Returns like C<ioctl>: the undefined value for error,
2427 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2428 C<IPC::SysV> and C<IPC::Semaphore> documentation.
2429
2430 =item msgget KEY,FLAGS
2431
2432 Calls the System V IPC function msgget(2).  Returns the message queue
2433 id, or the undefined value if there is an error.  See also C<IPC::SysV>
2434 and C<IPC::Msg> documentation.
2435
2436 =item msgsnd ID,MSG,FLAGS
2437
2438 Calls the System V IPC function msgsnd to send the message MSG to the
2439 message queue ID.  MSG must begin with the long integer message type,
2440 which may be created with C<pack("l", $type)>.  Returns true if
2441 successful, or false if there is an error.  See also C<IPC::SysV>
2442 and C<IPC::SysV::Msg> documentation.
2443
2444 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2445
2446 Calls the System V IPC function msgrcv to receive a message from
2447 message queue ID into variable VAR with a maximum message size of
2448 SIZE.  Note that if a message is received, the message type will be
2449 the first thing in VAR, and the maximum length of VAR is SIZE plus the
2450 size of the message type.  Returns true if successful, or false if
2451 there is an error.  See also C<IPC::SysV> and C<IPC::SysV::Msg> documentation.
2452
2453 =item my EXPR
2454
2455 =item my EXPR : ATTRIBUTES
2456
2457 A C<my> declares the listed variables to be local (lexically) to the
2458 enclosing block, file, or C<eval>.  If
2459 more than one value is listed, the list must be placed in parentheses.  See
2460 L<perlsub/"Private Variables via my()"> for details.
2461
2462 =item next LABEL
2463
2464 =item next
2465
2466 The C<next> command is like the C<continue> statement in C; it starts
2467 the next iteration of the loop:
2468
2469     LINE: while (<STDIN>) {
2470         next LINE if /^#/;      # discard comments
2471         #...
2472     }
2473
2474 Note that if there were a C<continue> block on the above, it would get
2475 executed even on discarded lines.  If the LABEL is omitted, the command
2476 refers to the innermost enclosing loop.
2477
2478 C<next> cannot be used to exit a block which returns a value such as
2479 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2480 a grep() or map() operation.
2481
2482 Note that a block by itself is semantically identical to a loop
2483 that executes once.  Thus C<next> will exit such a block early.
2484
2485 See also L</continue> for an illustration of how C<last>, C<next>, and
2486 C<redo> work.
2487
2488 =item no Module LIST
2489
2490 See the L</use> function, which C<no> is the opposite of.
2491
2492 =item oct EXPR
2493
2494 =item oct
2495
2496 Interprets EXPR as an octal string and returns the corresponding
2497 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2498 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2499 binary string.)  The following will handle decimal, binary, octal, and
2500 hex in the standard Perl or C notation:
2501
2502     $val = oct($val) if $val =~ /^0/;
2503
2504 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2505 in octal), use sprintf() or printf():
2506
2507     $perms = (stat("filename"))[2] & 07777;
2508     $oct_perms = sprintf "%lo", $perms;
2509
2510 The oct() function is commonly used when a string such as C<644> needs
2511 to be converted into a file mode, for example. (Although perl will
2512 automatically convert strings into numbers as needed, this automatic
2513 conversion assumes base 10.)
2514
2515 =item open FILEHANDLE,MODE,EXPR
2516
2517 =item open FILEHANDLE,EXPR
2518
2519 =item open FILEHANDLE
2520
2521 Opens the file whose filename is given by EXPR, and associates it with
2522 FILEHANDLE.  If FILEHANDLE is an expression, its value is used as the
2523 name of the real filehandle wanted.  If EXPR is omitted, the scalar
2524 variable of the same name as the FILEHANDLE contains the filename.
2525 (Note that lexical variables--those declared with C<my>--will not work
2526 for this purpose; so if you're using C<my>, specify EXPR in your call
2527 to open.)  See L<perlopentut> for a kinder, gentler explanation of opening
2528 files.
2529
2530 If MODE is C<'E<lt>'> or nothing, the file is opened for input.
2531 If MODE is C<'E<gt>'>, the file is truncated and opened for
2532 output, being created if necessary.  If MODE is C<'E<gt>E<gt>'>,
2533 the file is opened for appending, again being created if necessary. 
2534 You can put a C<'+'> in front of the C<'E<gt>'> or C<'E<lt>'> to indicate that
2535 you want both read and write access to the file; thus C<'+E<lt>'> is almost
2536 always preferred for read/write updates--the C<'+E<gt>'> mode would clobber the
2537 file first.  You can't usually use either read-write mode for updating
2538 textfiles, since they have variable length records.  See the B<-i>
2539 switch in L<perlrun> for a better approach.  The file is created with
2540 permissions of C<0666> modified by the process' C<umask> value.
2541
2542 These various prefixes correspond to the fopen(3) modes of C<'r'>, C<'r+'>, C<'w'>,
2543 C<'w+'>, C<'a'>, and C<'a+'>.
2544
2545 In the 2-arguments (and 1-argument) form of the call the mode and
2546 filename should be concatenated (in this order), possibly separated by
2547 spaces.  It is possible to omit the mode if the mode is C<'E<lt>'>.
2548
2549 If the filename begins with C<'|'>, the filename is interpreted as a
2550 command to which output is to be piped, and if the filename ends with a
2551 C<'|'>, the filename is interpreted as a command which pipes output to
2552 us.  See L<perlipc/"Using open() for IPC">
2553 for more examples of this.  (You are not allowed to C<open> to a command
2554 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2555 and L<perlipc/"Bidirectional Communication"> for alternatives.)
2556
2557 If MODE is C<'|-'>, the filename is interpreted as a
2558 command to which output is to be piped, and if MODE is
2559 C<'-|'>, the filename is interpreted as a command which pipes output to
2560 us.  In the 2-arguments (and 1-argument) form one should replace dash
2561 (C<'-'>) with the command.  See L<perlipc/"Using open() for IPC">
2562 for more examples of this.  (You are not allowed to C<open> to a command
2563 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2564 and L<perlipc/"Bidirectional Communication"> for alternatives.)
2565
2566 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2567 and opening C<'E<gt>-'> opens STDOUT.  
2568
2569 Open returns
2570 nonzero upon success, the undefined value otherwise.  If the C<open>
2571 involved a pipe, the return value happens to be the pid of the
2572 subprocess.
2573
2574 If you're unfortunate enough to be running Perl on a system that
2575 distinguishes between text files and binary files (modern operating
2576 systems don't care), then you should check out L</binmode> for tips for
2577 dealing with this.  The key distinction between systems that need C<binmode>
2578 and those that don't is their text file formats.  Systems like Unix, MacOS, and
2579 Plan9, which delimit lines with a single character, and which encode that
2580 character in C as C<"\n">, do not need C<binmode>.  The rest need it.
2581
2582 When opening a file, it's usually a bad idea to continue normal execution
2583 if the request failed, so C<open> is frequently used in connection with
2584 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2585 where you want to make a nicely formatted error message (but there are
2586 modules that can help with that problem)) you should always check
2587 the return value from opening a file.  The infrequent exception is when
2588 working with an unopened filehandle is actually what you want to do.
2589
2590 Examples:
2591
2592     $ARTICLE = 100;
2593     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2594     while (<ARTICLE>) {...
2595
2596     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
2597     # if the open fails, output is discarded
2598
2599     open(DBASE, '+<', 'dbase.mine')             # open for update
2600         or die "Can't open 'dbase.mine' for update: $!";
2601
2602     open(DBASE, '+<dbase.mine')                 # ditto
2603         or die "Can't open 'dbase.mine' for update: $!";
2604
2605     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
2606         or die "Can't start caesar: $!";
2607
2608     open(ARTICLE, "caesar <$article |")         # ditto
2609         or die "Can't start caesar: $!";
2610
2611     open(EXTRACT, "|sort >/tmp/Tmp$$")          # $$ is our process id
2612         or die "Can't start sort: $!";
2613
2614     # process argument list of files along with any includes
2615
2616     foreach $file (@ARGV) {
2617         process($file, 'fh00');
2618     }
2619
2620     sub process {
2621         my($filename, $input) = @_;
2622         $input++;               # this is a string increment
2623         unless (open($input, $filename)) {
2624             print STDERR "Can't open $filename: $!\n";
2625             return;
2626         }
2627
2628         local $_;
2629         while (<$input>) {              # note use of indirection
2630             if (/^#include "(.*)"/) {
2631                 process($1, $input);
2632                 next;
2633             }
2634             #...                # whatever
2635         }
2636     }
2637
2638 You may also, in the Bourne shell tradition, specify an EXPR beginning
2639 with C<'E<gt>&'>, in which case the rest of the string is interpreted as the
2640 name of a filehandle (or file descriptor, if numeric) to be
2641 duped and opened.  You may use C<&> after C<E<gt>>, C<E<gt>E<gt>>,
2642 C<E<lt>>, C<+E<gt>>, C<+E<gt>E<gt>>, and C<+E<lt>>.  The
2643 mode you specify should match the mode of the original filehandle.
2644 (Duping a filehandle does not take into account any existing contents of
2645 stdio buffers.)  Duping file handles is not yet supported for 3-argument
2646 open().
2647
2648 Here is a script that saves, redirects, and restores STDOUT and
2649 STDERR:
2650
2651     #!/usr/bin/perl
2652     open(OLDOUT, ">&STDOUT");
2653     open(OLDERR, ">&STDERR");
2654
2655     open(STDOUT, '>', "foo.out") || die "Can't redirect stdout";
2656     open(STDERR, ">&STDOUT")     || die "Can't dup stdout";
2657
2658     select(STDERR); $| = 1;     # make unbuffered
2659     select(STDOUT); $| = 1;     # make unbuffered
2660
2661     print STDOUT "stdout 1\n";  # this works for
2662     print STDERR "stderr 1\n";  # subprocesses too
2663
2664     close(STDOUT);
2665     close(STDERR);
2666
2667     open(STDOUT, ">&OLDOUT");
2668     open(STDERR, ">&OLDERR");
2669
2670     print STDOUT "stdout 2\n";
2671     print STDERR "stderr 2\n";
2672
2673 If you specify C<'E<lt>&=N'>, where C<N> is a number, then Perl will do an
2674 equivalent of C's C<fdopen> of that file descriptor; this is more
2675 parsimonious of file descriptors.  For example:
2676
2677     open(FILEHANDLE, "<&=$fd")
2678
2679 Note that this feature depends on the fdopen() C library function.
2680 On many UNIX systems, fdopen() is known to fail when file descriptors
2681 exceed a certain value, typically 255. If you need more file
2682 descriptors than that, consider rebuilding Perl to use the C<sfio>
2683 library.
2684
2685 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
2686 with 2-arguments (or 1-argument) form of open(), then
2687 there is an implicit fork done, and the return value of open is the pid
2688 of the child within the parent process, and C<0> within the child
2689 process.  (Use C<defined($pid)> to determine whether the open was successful.)
2690 The filehandle behaves normally for the parent, but i/o to that
2691 filehandle is piped from/to the STDOUT/STDIN of the child process.
2692 In the child process the filehandle isn't opened--i/o happens from/to
2693 the new STDOUT or STDIN.  Typically this is used like the normal
2694 piped open when you want to exercise more control over just how the
2695 pipe command gets executed, such as when you are running setuid, and
2696 don't want to have to scan shell commands for metacharacters.
2697 The following triples are more or less equivalent:
2698
2699     open(FOO, "|tr '[a-z]' '[A-Z]'");
2700     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
2701     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
2702
2703     open(FOO, "cat -n '$file'|");
2704     open(FOO, '-|', "cat -n '$file'");
2705     open(FOO, '-|') || exec 'cat', '-n', $file;
2706
2707 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
2708
2709 NOTE: On any operation that may do a fork, all files opened for output
2710 are flushed before the fork is attempted.  On systems that support a
2711 close-on-exec flag on files, the flag will be set for the newly opened
2712 file descriptor as determined by the value of $^F.  See L<perlvar/$^F>.
2713
2714 Closing any piped filehandle causes the parent process to wait for the
2715 child to finish, and returns the status value in C<$?>.
2716
2717 The filename passed to 2-argument (or 1-argument) form of open()
2718 will have leading and trailing
2719 whitespace deleted, and the normal redirection characters
2720 honored.  This property, known as "magic open", 
2721 can often be used to good effect.  A user could specify a filename of
2722 F<"rsh cat file |">, or you could change certain filenames as needed:
2723
2724     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
2725     open(FH, $filename) or die "Can't open $filename: $!";
2726
2727 Use 3-argument form to open a file with arbitrary weird characters in it,
2728
2729     open(FOO, '<', $file);
2730
2731 otherwise it's necessary to protect any leading and trailing whitespace:
2732
2733     $file =~ s#^(\s)#./$1#;
2734     open(FOO, "< $file\0");
2735
2736 (this may not work on some bizzare filesystems).  One should
2737 conscientiously choose between the the I<magic> and 3-arguments form
2738 of open():
2739
2740     open IN, $ARGV[0];
2741
2742 will allow the user to specify an argument of the form C<"rsh cat file |">,
2743 but will not work on a filename which happens to have a trailing space, while
2744
2745     open IN, '<', $ARGV[0];
2746
2747 will have exactly the opposite restrictions.
2748
2749 If you want a "real" C C<open> (see L<open(2)> on your system), then you
2750 should use the C<sysopen> function, which involves no such magic (but
2751 may use subtly different filemodes than Perl open(), which is mapped
2752 to C fopen()).  This is
2753 another way to protect your filenames from interpretation.  For example:
2754
2755     use IO::Handle;
2756     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
2757         or die "sysopen $path: $!";
2758     $oldfh = select(HANDLE); $| = 1; select($oldfh);
2759     print HANDLE "stuff $$\n");
2760     seek(HANDLE, 0, 0);
2761     print "File contains: ", <HANDLE>;
2762
2763 Using the constructor from the C<IO::Handle> package (or one of its
2764 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
2765 filehandles that have the scope of whatever variables hold references to
2766 them, and automatically close whenever and however you leave that scope:
2767
2768     use IO::File;
2769     #...
2770     sub read_myfile_munged {
2771         my $ALL = shift;
2772         my $handle = new IO::File;
2773         open($handle, "myfile") or die "myfile: $!";
2774         $first = <$handle>
2775             or return ();     # Automatically closed here.
2776         mung $first or die "mung failed";       # Or here.
2777         return $first, <$handle> if $ALL;       # Or here.
2778         $first;                                 # Or here.
2779     }
2780
2781 See L</seek> for some details about mixing reading and writing.
2782
2783 =item opendir DIRHANDLE,EXPR
2784
2785 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
2786 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
2787 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
2788
2789 =item ord EXPR
2790
2791 =item ord
2792
2793 Returns the numeric (ASCII or Unicode) value of the first character of EXPR.  If
2794 EXPR is omitted, uses C<$_>.  For the reverse, see L</chr>.
2795 See L<utf8> for more about Unicode.
2796
2797 =item our EXPR
2798
2799 An C<our> declares the listed variables to be valid globals within
2800 the enclosing block, file, or C<eval>.  That is, it has the same
2801 scoping rules as a "my" declaration, but does not create a local
2802 variable.  If more than one value is listed, the list must be placed
2803 in parentheses.  The C<our> declaration has no semantic effect unless
2804 "use strict vars" is in effect, in which case it lets you use the
2805 declared global variable without qualifying it with a package name.
2806 (But only within the lexical scope of the C<our> declaration.  In this
2807 it differs from "use vars", which is package scoped.)
2808
2809 An C<our> declaration declares a global variable that will be visible
2810 across its entire lexical scope, even across package boundaries.  The
2811 package in which the variable is entered is determined at the point
2812 of the declaration, not at the point of use.  This means the following
2813 behavior holds:
2814
2815     package Foo;
2816     our $bar;           # declares $Foo::bar for rest of lexical scope
2817     $bar = 20;
2818
2819     package Bar;
2820     print $bar;         # prints 20
2821
2822 Multiple C<our> declarations in the same lexical scope are allowed
2823 if they are in different packages.  If they happened to be in the same
2824 package, Perl will emit warnings if you have asked for them.
2825
2826     use warnings;
2827     package Foo;
2828     our $bar;           # declares $Foo::bar for rest of lexical scope
2829     $bar = 20;
2830
2831     package Bar;
2832     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
2833     print $bar;         # prints 30
2834
2835     our $bar;           # emits warning
2836
2837 =item pack TEMPLATE,LIST
2838
2839 Takes a LIST of values and converts it into a string using the rules
2840 given by the TEMPLATE.  The resulting string is the concatenation of
2841 the converted values.  Typically, each converted value looks
2842 like its machine-level representation.  For example, on 32-bit machines
2843 a converted integer may be represented by a sequence of 4 bytes.
2844
2845 The TEMPLATE is a
2846 sequence of characters that give the order and type of values, as
2847 follows:
2848
2849     a   A string with arbitrary binary data, will be null padded.
2850     A   An ascii string, will be space padded.
2851     Z   A null terminated (asciz) string, will be null padded.
2852
2853     b   A bit string (ascending bit order inside each byte, like vec()).
2854     B   A bit string (descending bit order inside each byte).
2855     h   A hex string (low nybble first).
2856     H   A hex string (high nybble first).
2857
2858     c   A signed char value.
2859     C   An unsigned char value.  Only does bytes.  See U for Unicode.
2860
2861     s   A signed short value.
2862     S   An unsigned short value.
2863           (This 'short' is _exactly_ 16 bits, which may differ from
2864            what a local C compiler calls 'short'.  If you want
2865            native-length shorts, use the '!' suffix.)
2866
2867     i   A signed integer value.
2868     I   An unsigned integer value.
2869           (This 'integer' is _at_least_ 32 bits wide.  Its exact
2870            size depends on what a local C compiler calls 'int',
2871            and may even be larger than the 'long' described in
2872            the next item.)
2873
2874     l   A signed long value.
2875     L   An unsigned long value.
2876           (This 'long' is _exactly_ 32 bits, which may differ from
2877            what a local C compiler calls 'long'.  If you want
2878            native-length longs, use the '!' suffix.)
2879
2880     n   An unsigned short in "network" (big-endian) order.
2881     N   An unsigned long in "network" (big-endian) order.
2882     v   An unsigned short in "VAX" (little-endian) order.
2883     V   An unsigned long in "VAX" (little-endian) order.
2884           (These 'shorts' and 'longs' are _exactly_ 16 bits and
2885            _exactly_ 32 bits, respectively.)
2886
2887     q   A signed quad (64-bit) value.
2888     Q   An unsigned quad value.
2889           (Quads are available only if your system supports 64-bit
2890            integer values _and_ if Perl has been compiled to support those.
2891            Causes a fatal error otherwise.)
2892
2893     f   A single-precision float in the native format.
2894     d   A double-precision float in the native format.
2895
2896     p   A pointer to a null-terminated string.
2897     P   A pointer to a structure (fixed-length string).
2898
2899     u   A uuencoded string.
2900     U   A Unicode character number.  Encodes to UTF-8 internally.
2901         Works even if C<use utf8> is not in effect.
2902
2903     w   A BER compressed integer.  Its bytes represent an unsigned
2904         integer in base 128, most significant digit first, with as
2905         few digits as possible.  Bit eight (the high bit) is set
2906         on each byte except the last.
2907
2908     x   A null byte.
2909     X   Back up a byte.
2910     @   Null fill to absolute position.
2911
2912 The following rules apply:
2913
2914 =over 8
2915
2916 =item *
2917
2918 Each letter may optionally be followed by a number giving a repeat
2919 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
2920 C<H>, and C<P> the pack function will gobble up that many values from
2921 the LIST.  A C<*> for the repeat count means to use however many items are
2922 left, except for C<@>, C<x>, C<X>, where it is equivalent
2923 to C<0>, and C<u>, where it is equivalent to 1 (or 45, what is the
2924 same).
2925
2926 When used with C<Z>, C<*> results in the addition of a trailing null
2927 byte (so the packed result will be one longer than the byte C<length>
2928 of the item).
2929
2930 The repeat count for C<u> is interpreted as the maximal number of bytes
2931 to encode per line of output, with 0 and 1 replaced by 45.
2932
2933 =item *
2934
2935 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
2936 string of length count, padding with nulls or spaces as necessary.  When
2937 unpacking, C<A> strips trailing spaces and nulls, C<Z> strips everything
2938 after the first null, and C<a> returns data verbatim.  When packing,
2939 C<a>, and C<Z> are equivalent.
2940
2941 If the value-to-pack is too long, it is truncated.  If too long and an
2942 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
2943 by a null byte.  Thus C<Z> always packs a trailing null byte under
2944 all circumstances.
2945
2946 =item *
2947
2948 Likewise, the C<b> and C<B> fields pack a string that many bits long.
2949 Each byte of the input field of pack() generates 1 bit of the result.
2950 Each result bit is based on the least-significant bit of the corresponding
2951 input byte, i.e., on C<ord($byte)%2>.  In particular, bytes C<"0"> and
2952 C<"1"> generate bits 0 and 1, as do bytes C<"\0"> and C<"\1">.
2953
2954 Starting from the beginning of the input string of pack(), each 8-tuple
2955 of bytes is converted to 1 byte of output.  With format C<b>
2956 the first byte of the 8-tuple determines the least-significant bit of a
2957 byte, and with format C<B> it determines the most-significant bit of
2958 a byte.
2959
2960 If the length of the input string is not exactly divisible by 8, the
2961 remainder is packed as if the input string were padded by null bytes
2962 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
2963
2964 If the input string of pack() is longer than needed, extra bytes are ignored.
2965 A C<*> for the repeat count of pack() means to use all the bytes of
2966 the input field.  On unpack()ing the bits are converted to a string
2967 of C<"0">s and C<"1">s.
2968
2969 =item *
2970
2971 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
2972 representable as hexadecimal digits, 0-9a-f) long.
2973
2974 Each byte of the input field of pack() generates 4 bits of the result.
2975 For non-alphabetical bytes the result is based on the 4 least-significant
2976 bits of the input byte, i.e., on C<ord($byte)%16>.  In particular,
2977 bytes C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
2978 C<"\0"> and C<"\1">.  For bytes C<"a".."f"> and C<"A".."F"> the result
2979 is compatible with the usual hexadecimal digits, so that C<"a"> and
2980 C<"A"> both generate the nybble C<0xa==10>.  The result for bytes
2981 C<"g".."z"> and C<"G".."Z"> is not well-defined.
2982
2983 Starting from the beginning of the input string of pack(), each pair
2984 of bytes is converted to 1 byte of output.  With format C<h> the
2985 first byte of the pair determines the least-significant nybble of the
2986 output byte, and with format C<H> it determines the most-significant
2987 nybble.
2988
2989 If the length of the input string is not even, it behaves as if padded
2990 by a null byte at the end.  Similarly, during unpack()ing the "extra"
2991 nybbles are ignored.
2992
2993 If the input string of pack() is longer than needed, extra bytes are ignored.
2994 A C<*> for the repeat count of pack() means to use all the bytes of
2995 the input field.  On unpack()ing the bits are converted to a string
2996 of hexadecimal digits.
2997
2998 =item *
2999
3000 The C<p> type packs a pointer to a null-terminated string.  You are
3001 responsible for ensuring the string is not a temporary value (which can
3002 potentially get deallocated before you get around to using the packed result).
3003 The C<P> type packs a pointer to a structure of the size indicated by the
3004 length.  A NULL pointer is created if the corresponding value for C<p> or
3005 C<P> is C<undef>, similarly for unpack().
3006
3007 =item *
3008
3009 The C</> template character allows packing and unpacking of strings where
3010 the packed structure contains a byte count followed by the string itself.
3011 You write I<length-item>C</>I<string-item>.
3012
3013 The I<length-item> can be any C<pack> template letter,
3014 and describes how the length value is packed.
3015 The ones likely to be of most use are integer-packing ones like
3016 C<n> (for Java strings), C<w> (for ASN.1 or SNMP)
3017 and C<N> (for Sun XDR).
3018
3019 The I<string-item> must, at present, be C<"A*">, C<"a*"> or C<"Z*">.
3020 For C<unpack> the length of the string is obtained from the I<length-item>,
3021 but if you put in the '*' it will be ignored.
3022
3023     unpack 'C/a', "\04Gurusamy";        gives 'Guru'
3024     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond','J')
3025     pack 'n/a* w/a*','hello,','world';  gives "\000\006hello,\005world"
3026
3027 The I<length-item> is not returned explicitly from C<unpack>.
3028
3029 Adding a count to the I<length-item> letter is unlikely to do anything
3030 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3031 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3032 which Perl does not regard as legal in numeric strings.
3033
3034 =item *
3035
3036 The integer types C<s>, C<S>, C<l>, and C<L> may be
3037 immediately followed by a C<!> suffix to signify native shorts or
3038 longs--as you can see from above for example a bare C<l> does mean
3039 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3040 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3041 see whether using C<!> makes any difference by
3042
3043         print length(pack("s")), " ", length(pack("s!")), "\n";
3044         print length(pack("l")), " ", length(pack("l!")), "\n";
3045
3046 C<i!> and C<I!> also work but only because of completeness;
3047 they are identical to C<i> and C<I>.
3048
3049 The actual sizes (in bytes) of native shorts, ints, longs, and long
3050 longs on the platform where Perl was built are also available via
3051 L<Config>:
3052
3053        use Config;
3054        print $Config{shortsize},    "\n";
3055        print $Config{intsize},      "\n";
3056        print $Config{longsize},     "\n";
3057        print $Config{longlongsize}, "\n";
3058
3059 (The C<$Config{longlongsize}> will be undefine if your system does
3060 not support long longs.) 
3061
3062 =item *
3063
3064 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, and C<L>
3065 are inherently non-portable between processors and operating systems
3066 because they obey the native byteorder and endianness.  For example a
3067 4-byte integer 0x12345678 (305419896 decimal) be ordered natively
3068 (arranged in and handled by the CPU registers) into bytes as
3069  
3070         0x12 0x34 0x56 0x78     # little-endian
3071         0x78 0x56 0x34 0x12     # big-endian
3072  
3073 Basically, the Intel, Alpha, and VAX CPUs are little-endian, while
3074 everybody else, for example Motorola m68k/88k, PPC, Sparc, HP PA,
3075 Power, and Cray are big-endian.  MIPS can be either: Digital used it
3076 in little-endian mode; SGI uses it in big-endian mode.
3077
3078 The names `big-endian' and `little-endian' are comic references to
3079 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3080 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3081 the egg-eating habits of the Lilliputians.
3082  
3083 Some systems may have even weirder byte orders such as
3084  
3085         0x56 0x78 0x12 0x34
3086         0x34 0x12 0x78 0x56
3087  
3088 You can see your system's preference with
3089
3090         print join(" ", map { sprintf "%#02x", $_ }
3091                             unpack("C*",pack("L",0x12345678))), "\n";
3092
3093 The byteorder on the platform where Perl was built is also available
3094 via L<Config>:
3095
3096         use Config;
3097         print $Config{byteorder}, "\n";
3098
3099 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3100 and C<'87654321'> are big-endian.
3101
3102 If you want portable packed integers use the formats C<n>, C<N>,
3103 C<v>, and C<V>, their byte endianness and size is known.
3104 See also L<perlport>.
3105
3106 =item *
3107
3108 Real numbers (floats and doubles) are in the native machine format only;
3109 due to the multiplicity of floating formats around, and the lack of a
3110 standard "network" representation, no facility for interchange has been
3111 made.  This means that packed floating point data written on one machine
3112 may not be readable on another - even if both use IEEE floating point
3113 arithmetic (as the endian-ness of the memory representation is not part
3114 of the IEEE spec).  See also L<perlport>.
3115
3116 Note that Perl uses doubles internally for all numeric calculation, and
3117 converting from double into float and thence back to double again will
3118 lose precision (i.e., C<unpack("f", pack("f", $foo)>) will not in general
3119 equal $foo).
3120
3121 =item *
3122
3123 You must yourself do any alignment or padding by inserting for example
3124 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3125 could know where the bytes are going to or coming from.  Therefore
3126 C<pack> (and C<unpack>) handle their output and input as flat
3127 sequences of bytes.
3128
3129 =item *
3130
3131 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3132
3133 =item *
3134
3135 If TEMPLATE requires more arguments to pack() than actually given, pack()
3136 assumes additional C<""> arguments.  If TEMPLATE requires less arguments
3137 to pack() than actually given, extra arguments are ignored.
3138
3139 =back
3140
3141 Examples:
3142
3143     $foo = pack("CCCC",65,66,67,68);
3144     # foo eq "ABCD"
3145     $foo = pack("C4",65,66,67,68);
3146     # same thing
3147     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3148     # same thing with Unicode circled letters
3149
3150     $foo = pack("ccxxcc",65,66,67,68);
3151     # foo eq "AB\0\0CD"
3152
3153     # note: the above examples featuring "C" and "c" are true
3154     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3155     # and UTF-8.  In EBCDIC the first example would be
3156     # $foo = pack("CCCC",193,194,195,196);
3157
3158     $foo = pack("s2",1,2);
3159     # "\1\0\2\0" on little-endian
3160     # "\0\1\0\2" on big-endian
3161
3162     $foo = pack("a4","abcd","x","y","z");
3163     # "abcd"
3164
3165     $foo = pack("aaaa","abcd","x","y","z");
3166     # "axyz"
3167
3168     $foo = pack("a14","abcdefg");
3169     # "abcdefg\0\0\0\0\0\0\0"
3170
3171     $foo = pack("i9pl", gmtime);
3172     # a real struct tm (on my system anyway)
3173
3174     $utmp_template = "Z8 Z8 Z16 L";
3175     $utmp = pack($utmp_template, @utmp1);
3176     # a struct utmp (BSDish)
3177
3178     @utmp2 = unpack($utmp_template, $utmp);
3179     # "@utmp1" eq "@utmp2"
3180
3181     sub bintodec {
3182         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3183     }
3184
3185     $foo = pack('sx2l', 12, 34);
3186     # short 12, two zero bytes padding, long 34
3187     $bar = pack('s@4l', 12, 34);
3188     # short 12, zero fill to position 4, long 34
3189     # $foo eq $bar
3190
3191 The same template may generally also be used in unpack().
3192
3193 =item package 
3194
3195 =item package NAMESPACE
3196
3197 Declares the compilation unit as being in the given namespace.  The scope
3198 of the package declaration is from the declaration itself through the end
3199 of the enclosing block, file, or eval (the same as the C<my> operator).
3200 All further unqualified dynamic identifiers will be in this namespace.
3201 A package statement affects only dynamic variables--including those
3202 you've used C<local> on--but I<not> lexical variables, which are created
3203 with C<my>.  Typically it would be the first declaration in a file to
3204 be included by the C<require> or C<use> operator.  You can switch into a
3205 package in more than one place; it merely influences which symbol table
3206 is used by the compiler for the rest of that block.  You can refer to
3207 variables and filehandles in other packages by prefixing the identifier
3208 with the package name and a double colon:  C<$Package::Variable>.
3209 If the package name is null, the C<main> package as assumed.  That is,
3210 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3211 still seen in older code).
3212
3213 If NAMESPACE is omitted, then there is no current package, and all
3214 identifiers must be fully qualified or lexicals.  This is stricter
3215 than C<use strict>, since it also extends to function names.
3216
3217 See L<perlmod/"Packages"> for more information about packages, modules,
3218 and classes.  See L<perlsub> for other scoping issues.
3219
3220 =item pipe READHANDLE,WRITEHANDLE
3221
3222 Opens a pair of connected pipes like the corresponding system call.
3223 Note that if you set up a loop of piped processes, deadlock can occur
3224 unless you are very careful.  In addition, note that Perl's pipes use
3225 stdio buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3226 after each command, depending on the application.
3227
3228 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3229 for examples of such things.
3230
3231 On systems that support a close-on-exec flag on files, the flag will be set
3232 for the newly opened file descriptors as determined by the value of $^F.
3233 See L<perlvar/$^F>.
3234
3235 =item pop ARRAY
3236
3237 =item pop
3238
3239 Pops and returns the last value of the array, shortening the array by
3240 one element.  Has an effect similar to
3241
3242     $ARRAY[$#ARRAY--]
3243
3244 If there are no elements in the array, returns the undefined value
3245 (although this may happen at other times as well).  If ARRAY is
3246 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3247 array in subroutines, just like C<shift>.
3248
3249 =item pos SCALAR
3250
3251 =item pos
3252
3253 Returns the offset of where the last C<m//g> search left off for the variable
3254 is in question (C<$_> is used when the variable is not specified).  May be
3255 modified to change that offset.  Such modification will also influence
3256 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
3257 L<perlop>.
3258
3259 =item print FILEHANDLE LIST
3260
3261 =item print LIST
3262
3263 =item print
3264
3265 Prints a string or a list of strings.  Returns true if successful.
3266 FILEHANDLE may be a scalar variable name, in which case the variable
3267 contains the name of or a reference to the filehandle, thus introducing
3268 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3269 the next token is a term, it may be misinterpreted as an operator
3270 unless you interpose a C<+> or put parentheses around the arguments.)
3271 If FILEHANDLE is omitted, prints by default to standard output (or
3272 to the last selected output channel--see L</select>).  If LIST is
3273 also omitted, prints C<$_> to the currently selected output channel.
3274 To set the default output channel to something other than STDOUT
3275 use the select operation.  The current value of C<$,> (if any) is
3276 printed between each LIST item.  The current value of C<$\> (if
3277 any) is printed after the entire LIST has been printed.  Because
3278 print takes a LIST, anything in the LIST is evaluated in list
3279 context, and any subroutine that you call will have one or more of
3280 its expressions evaluated in list context.  Also be careful not to
3281 follow the print keyword with a left parenthesis unless you want
3282 the corresponding right parenthesis to terminate the arguments to
3283 the print--interpose a C<+> or put parentheses around all the
3284 arguments.
3285
3286 Note that if you're storing FILEHANDLES in an array or other expression,
3287 you will have to use a block returning its value instead:
3288
3289     print { $files[$i] } "stuff\n";
3290     print { $OK ? STDOUT : STDERR } "stuff\n";
3291
3292 =item printf FILEHANDLE FORMAT, LIST
3293
3294 =item printf FORMAT, LIST
3295
3296 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3297 (the output record separator) is not appended.  The first argument
3298 of the list will be interpreted as the C<printf> format.  If C<use locale> is
3299 in effect, the character used for the decimal point in formatted real numbers
3300 is affected by the LC_NUMERIC locale.  See L<perllocale>.
3301
3302 Don't fall into the trap of using a C<printf> when a simple
3303 C<print> would do.  The C<print> is more efficient and less
3304 error prone.
3305
3306 =item prototype FUNCTION
3307
3308 Returns the prototype of a function as a string (or C<undef> if the
3309 function has no prototype).  FUNCTION is a reference to, or the name of,
3310 the function whose prototype you want to retrieve.
3311
3312 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
3313 name for Perl builtin.  If the builtin is not I<overridable> (such as
3314 C<qw//>) or its arguments cannot be expressed by a prototype (such as
3315 C<system>) returns C<undef> because the builtin does not really behave
3316 like a Perl function.  Otherwise, the string describing the equivalent
3317 prototype is returned.
3318
3319 =item push ARRAY,LIST
3320
3321 Treats ARRAY as a stack, and pushes the values of LIST
3322 onto the end of ARRAY.  The length of ARRAY increases by the length of
3323 LIST.  Has the same effect as
3324
3325     for $value (LIST) {
3326         $ARRAY[++$#ARRAY] = $value;
3327     }
3328
3329 but is more efficient.  Returns the new number of elements in the array.
3330
3331 =item q/STRING/
3332
3333 =item qq/STRING/
3334
3335 =item qr/STRING/
3336
3337 =item qx/STRING/
3338
3339 =item qw/STRING/
3340
3341 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
3342
3343 =item quotemeta EXPR
3344
3345 =item quotemeta
3346
3347 Returns the value of EXPR with all non-alphanumeric
3348 characters backslashed.  (That is, all characters not matching
3349 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
3350 returned string, regardless of any locale settings.)
3351 This is the internal function implementing
3352 the C<\Q> escape in double-quoted strings.
3353
3354 If EXPR is omitted, uses C<$_>.
3355
3356 =item rand EXPR
3357
3358 =item rand
3359
3360 Returns a random fractional number greater than or equal to C<0> and less
3361 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
3362 omitted, the value C<1> is used.  Automatically calls C<srand> unless
3363 C<srand> has already been called.  See also C<srand>.
3364
3365 (Note: If your rand function consistently returns numbers that are too
3366 large or too small, then your version of Perl was probably compiled
3367 with the wrong number of RANDBITS.)
3368
3369 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
3370
3371 =item read FILEHANDLE,SCALAR,LENGTH
3372
3373 Attempts to read LENGTH bytes of data into variable SCALAR from the
3374 specified FILEHANDLE.  Returns the number of bytes actually read,
3375 C<0> at end of file, or undef if there was an error.  SCALAR will be grown
3376 or shrunk to the length actually read.  An OFFSET may be specified to
3377 place the read data at some other place than the beginning of the
3378 string.  This call is actually implemented in terms of stdio's fread(3)
3379 call.  To get a true read(2) system call, see C<sysread>.
3380
3381 =item readdir DIRHANDLE
3382
3383 Returns the next directory entry for a directory opened by C<opendir>.
3384 If used in list context, returns all the rest of the entries in the
3385 directory.  If there are no more entries, returns an undefined value in
3386 scalar context or a null list in list context.
3387
3388 If you're planning to filetest the return values out of a C<readdir>, you'd
3389 better prepend the directory in question.  Otherwise, because we didn't
3390 C<chdir> there, it would have been testing the wrong file.
3391
3392     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
3393     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
3394     closedir DIR;
3395
3396 =item readline EXPR
3397
3398 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
3399 context, each call reads and returns the next line, until end-of-file is
3400 reached, whereupon the subsequent call returns undef.  In list context,
3401 reads until end-of-file is reached and returns a list of lines.  Note that
3402 the notion of "line" used here is however you may have defined it
3403 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
3404
3405 When C<$/> is set to C<undef>, when readline() is in scalar
3406 context (i.e. file slurp mode), and when an empty file is read, it
3407 returns C<''> the first time, followed by C<undef> subsequently.
3408
3409 This is the internal function implementing the C<E<lt>EXPRE<gt>>
3410 operator, but you can use it directly.  The C<E<lt>EXPRE<gt>>
3411 operator is discussed in more detail in L<perlop/"I/O Operators">.
3412
3413     $line = <STDIN>;
3414     $line = readline(*STDIN);           # same thing
3415
3416 =item readlink EXPR
3417
3418 =item readlink
3419
3420 Returns the value of a symbolic link, if symbolic links are
3421 implemented.  If not, gives a fatal error.  If there is some system
3422 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
3423 omitted, uses C<$_>.
3424
3425 =item readpipe EXPR
3426
3427 EXPR is executed as a system command.
3428 The collected standard output of the command is returned.
3429 In scalar context, it comes back as a single (potentially
3430 multi-line) string.  In list context, returns a list of lines
3431 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
3432 This is the internal function implementing the C<qx/EXPR/>
3433 operator, but you can use it directly.  The C<qx/EXPR/>
3434 operator is discussed in more detail in L<perlop/"I/O Operators">.
3435
3436 =item recv SOCKET,SCALAR,LENGTH,FLAGS
3437
3438 Receives a message on a socket.  Attempts to receive LENGTH bytes of
3439 data into variable SCALAR from the specified SOCKET filehandle.  SCALAR
3440 will be grown or shrunk to the length actually read.  Takes the same
3441 flags as the system call of the same name.  Returns the address of the
3442 sender if SOCKET's protocol supports this; returns an empty string
3443 otherwise.  If there's an error, returns the undefined value.  This call
3444 is actually implemented in terms of recvfrom(2) system call.  See
3445 L<perlipc/"UDP: Message Passing"> for examples.
3446
3447 =item redo LABEL
3448
3449 =item redo
3450
3451 The C<redo> command restarts the loop block without evaluating the
3452 conditional again.  The C<continue> block, if any, is not executed.  If
3453 the LABEL is omitted, the command refers to the innermost enclosing
3454 loop.  This command is normally used by programs that want to lie to
3455 themselves about what was just input:
3456
3457     # a simpleminded Pascal comment stripper
3458     # (warning: assumes no { or } in strings)
3459     LINE: while (<STDIN>) {
3460         while (s|({.*}.*){.*}|$1 |) {}
3461         s|{.*}| |;
3462         if (s|{.*| |) {
3463             $front = $_;
3464             while (<STDIN>) {
3465                 if (/}/) {      # end of comment?
3466                     s|^|$front\{|;
3467                     redo LINE;
3468                 }
3469             }
3470         }
3471         print;
3472     }
3473
3474 C<redo> cannot be used to retry a block which returns a value such as
3475 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
3476 a grep() or map() operation.
3477
3478 Note that a block by itself is semantically identical to a loop
3479 that executes once.  Thus C<redo> inside such a block will effectively
3480 turn it into a looping construct.
3481
3482 See also L</continue> for an illustration of how C<last>, C<next>, and
3483 C<redo> work.
3484
3485 =item ref EXPR
3486
3487 =item ref
3488
3489 Returns a true value if EXPR is a reference, false otherwise.  If EXPR
3490 is not specified, C<$_> will be used.  The value returned depends on the
3491 type of thing the reference is a reference to.
3492 Builtin types include:
3493
3494     SCALAR
3495     ARRAY
3496     HASH
3497     CODE
3498     REF
3499     GLOB
3500     LVALUE
3501
3502 If the referenced object has been blessed into a package, then that package
3503 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
3504
3505     if (ref($r) eq "HASH") {
3506         print "r is a reference to a hash.\n";
3507     }
3508     unless (ref($r)) {
3509         print "r is not a reference at all.\n";
3510     }
3511     if (UNIVERSAL::isa($r, "HASH")) {  # for subclassing
3512         print "r is a reference to something that isa hash.\n";
3513     } 
3514
3515 See also L<perlref>.
3516
3517 =item rename OLDNAME,NEWNAME
3518
3519 Changes the name of a file; an existing file NEWNAME will be
3520 clobbered.  Returns true for success, false otherwise.
3521
3522 Behavior of this function varies wildly depending on your system
3523 implementation.  For example, it will usually not work across file system
3524 boundaries, even though the system I<mv> command sometimes compensates
3525 for this.  Other restrictions include whether it works on directories,
3526 open files, or pre-existing files.  Check L<perlport> and either the
3527 rename(2) manpage or equivalent system documentation for details.
3528
3529 =item require VERSION
3530
3531 =item require EXPR
3532
3533 =item require
3534
3535 Demands some semantics specified by EXPR, or by C<$_> if EXPR is not
3536 supplied.  If a version number or tuple is specified, or if EXPR is
3537 numeric, demands that the current version of Perl
3538 (C<$^V> or C<$]> or $PERL_VERSION) be equal or greater than EXPR.
3539
3540 Otherwise, demands that a library file be included if it hasn't already
3541 been included.  The file is included via the do-FILE mechanism, which is
3542 essentially just a variety of C<eval>.  Has semantics similar to the following
3543 subroutine:
3544
3545     sub require {
3546         my($filename) = @_;
3547         return 1 if $INC{$filename};
3548         my($realfilename,$result);
3549         ITER: {
3550             foreach $prefix (@INC) {
3551                 $realfilename = "$prefix/$filename";
3552                 if (-f $realfilename) {
3553                     $INC{$filename} = $realfilename;
3554                     $result = do $realfilename;
3555                     last ITER;
3556                 }
3557             }
3558             die "Can't find $filename in \@INC";
3559         }
3560         delete $INC{$filename} if $@ || !$result;
3561         die $@ if $@;
3562         die "$filename did not return true value" unless $result;
3563         return $result;
3564     }
3565
3566 Note that the file will not be included twice under the same specified
3567 name.  The file must return true as the last statement to indicate
3568 successful execution of any initialization code, so it's customary to
3569 end such a file with C<1;> unless you're sure it'll return true
3570 otherwise.  But it's better just to put the C<1;>, in case you add more
3571 statements.
3572
3573 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
3574 replaces "F<::>" with "F</>" in the filename for you,
3575 to make it easy to load standard modules.  This form of loading of
3576 modules does not risk altering your namespace.
3577
3578 In other words, if you try this:
3579
3580         require Foo::Bar;    # a splendid bareword 
3581
3582 The require function will actually look for the "F<Foo/Bar.pm>" file in the 
3583 directories specified in the C<@INC> array.
3584
3585 But if you try this:
3586
3587         $class = 'Foo::Bar';
3588         require $class;      # $class is not a bareword
3589     #or
3590         require "Foo::Bar";  # not a bareword because of the ""
3591
3592 The require function will look for the "F<Foo::Bar>" file in the @INC array and 
3593 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
3594
3595         eval "require $class";
3596
3597 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
3598
3599 =item reset EXPR
3600
3601 =item reset
3602
3603 Generally used in a C<continue> block at the end of a loop to clear
3604 variables and reset C<??> searches so that they work again.  The
3605 expression is interpreted as a list of single characters (hyphens
3606 allowed for ranges).  All variables and arrays beginning with one of
3607 those letters are reset to their pristine state.  If the expression is
3608 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
3609 only variables or searches in the current package.  Always returns
3610 1.  Examples:
3611
3612     reset 'X';          # reset all X variables
3613     reset 'a-z';        # reset lower case variables
3614     reset;              # just reset ?one-time? searches
3615
3616 Resetting C<"A-Z"> is not recommended because you'll wipe out your
3617 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
3618 variables--lexical variables are unaffected, but they clean themselves
3619 up on scope exit anyway, so you'll probably want to use them instead.
3620 See L</my>.
3621
3622 =item return EXPR
3623
3624 =item return
3625
3626 Returns from a subroutine, C<eval>, or C<do FILE> with the value 
3627 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
3628 context, depending on how the return value will be used, and the context
3629 may vary from one execution to the next (see C<wantarray>).  If no EXPR
3630 is given, returns an empty list in list context, the undefined value in
3631 scalar context, and (of course) nothing at all in a void context.
3632
3633 (Note that in the absence of a explicit C<return>, a subroutine, eval,
3634 or do FILE will automatically return the value of the last expression
3635 evaluated.)
3636
3637 =item reverse LIST
3638
3639 In list context, returns a list value consisting of the elements
3640 of LIST in the opposite order.  In scalar context, concatenates the
3641 elements of LIST and returns a string value with all characters
3642 in the opposite order.
3643
3644     print reverse <>;           # line tac, last line first
3645
3646     undef $/;                   # for efficiency of <>
3647     print scalar reverse <>;    # character tac, last line tsrif
3648
3649 This operator is also handy for inverting a hash, although there are some
3650 caveats.  If a value is duplicated in the original hash, only one of those
3651 can be represented as a key in the inverted hash.  Also, this has to
3652 unwind one hash and build a whole new one, which may take some time
3653 on a large hash, such as from a DBM file.
3654
3655     %by_name = reverse %by_address;     # Invert the hash
3656
3657 =item rewinddir DIRHANDLE
3658
3659 Sets the current position to the beginning of the directory for the
3660 C<readdir> routine on DIRHANDLE.
3661
3662 =item rindex STR,SUBSTR,POSITION
3663
3664 =item rindex STR,SUBSTR
3665
3666 Works just like index() except that it returns the position of the LAST
3667 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
3668 last occurrence at or before that position.
3669
3670 =item rmdir FILENAME
3671
3672 =item rmdir
3673
3674 Deletes the directory specified by FILENAME if that directory is empty.  If it
3675 succeeds it returns true, otherwise it returns false and sets C<$!> (errno).  If
3676 FILENAME is omitted, uses C<$_>.
3677
3678 =item s///
3679
3680 The substitution operator.  See L<perlop>.
3681
3682 =item scalar EXPR
3683
3684 Forces EXPR to be interpreted in scalar context and returns the value
3685 of EXPR.
3686
3687     @counts = ( scalar @a, scalar @b, scalar @c );
3688
3689 There is no equivalent operator to force an expression to
3690 be interpolated in list context because in practice, this is never
3691 needed.  If you really wanted to do so, however, you could use
3692 the construction C<@{[ (some expression) ]}>, but usually a simple
3693 C<(some expression)> suffices.
3694
3695 Because C<scalar> is unary operator, if you accidentally use for EXPR a
3696 parenthesized list, this behaves as a scalar comma expression, evaluating
3697 all but the last element in void context and returning the final element
3698 evaluated in scalar context.  This is seldom what you want.
3699
3700 The following single statement:
3701
3702         print uc(scalar(&foo,$bar)),$baz;
3703
3704 is the moral equivalent of these two:
3705
3706         &foo;
3707         print(uc($bar),$baz);
3708
3709 See L<perlop> for more details on unary operators and the comma operator.
3710
3711 =item seek FILEHANDLE,POSITION,WHENCE
3712
3713 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
3714 FILEHANDLE may be an expression whose value gives the name of the
3715 filehandle.  The values for WHENCE are C<0> to set the new position to
3716 POSITION, C<1> to set it to the current position plus POSITION, and
3717 C<2> to set it to EOF plus POSITION (typically negative).  For WHENCE
3718 you may use the constants C<SEEK_SET>, C<SEEK_CUR>, and C<SEEK_END>
3719 (start of the file, current position, end of the file) from any of the
3720 modules Fcntl, C<IO::Seekable>, or POSIX.  Returns C<1> upon success,
3721 C<0> otherwise.
3722
3723 If you want to position file for C<sysread> or C<syswrite>, don't use
3724 C<seek>--buffering makes its effect on the file's system position
3725 unpredictable and non-portable.  Use C<sysseek> instead.
3726
3727 Due to the rules and rigors of ANSI C, on some systems you have to do a
3728 seek whenever you switch between reading and writing.  Amongst other
3729 things, this may have the effect of calling stdio's clearerr(3).
3730 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
3731
3732     seek(TEST,0,1);
3733
3734 This is also useful for applications emulating C<tail -f>.  Once you hit
3735 EOF on your read, and then sleep for a while, you might have to stick in a
3736 seek() to reset things.  The C<seek> doesn't change the current position,
3737 but it I<does> clear the end-of-file condition on the handle, so that the
3738 next C<E<lt>FILEE<gt>> makes Perl try again to read something.  We hope.
3739
3740 If that doesn't work (some stdios are particularly cantankerous), then
3741 you may need something more like this:
3742
3743     for (;;) {
3744         for ($curpos = tell(FILE); $_ = <FILE>;
3745              $curpos = tell(FILE)) {
3746             # search for some stuff and put it into files
3747         }
3748         sleep($for_a_while);
3749         seek(FILE, $curpos, 0);
3750     }
3751
3752 =item seekdir DIRHANDLE,POS
3753
3754 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
3755 must be a value returned by C<telldir>.  Has the same caveats about
3756 possible directory compaction as the corresponding system library
3757 routine.
3758
3759 =item select FILEHANDLE
3760
3761 =item select
3762
3763 Returns the currently selected filehandle.  Sets the current default
3764 filehandle for output, if FILEHANDLE is supplied.  This has two
3765 effects: first, a C<write> or a C<print> without a filehandle will
3766 default to this FILEHANDLE.  Second, references to variables related to
3767 output will refer to this output channel.  For example, if you have to
3768 set the top of form format for more than one output channel, you might
3769 do the following:
3770
3771     select(REPORT1);
3772     $^ = 'report1_top';
3773     select(REPORT2);
3774     $^ = 'report2_top';
3775
3776 FILEHANDLE may be an expression whose value gives the name of the
3777 actual filehandle.  Thus:
3778
3779     $oldfh = select(STDERR); $| = 1; select($oldfh);
3780
3781 Some programmers may prefer to think of filehandles as objects with
3782 methods, preferring to write the last example as:
3783
3784     use IO::Handle;
3785     STDERR->autoflush(1);
3786
3787 =item select RBITS,WBITS,EBITS,TIMEOUT
3788
3789 This calls the select(2) system call with the bit masks specified, which
3790 can be constructed using C<fileno> and C<vec>, along these lines:
3791
3792     $rin = $win = $ein = '';
3793     vec($rin,fileno(STDIN),1) = 1;
3794     vec($win,fileno(STDOUT),1) = 1;
3795     $ein = $rin | $win;
3796
3797 If you want to select on many filehandles you might wish to write a
3798 subroutine:
3799
3800     sub fhbits {
3801         my(@fhlist) = split(' ',$_[0]);
3802         my($bits);
3803         for (@fhlist) {
3804             vec($bits,fileno($_),1) = 1;
3805         }
3806         $bits;
3807     }
3808     $rin = fhbits('STDIN TTY SOCK');
3809
3810 The usual idiom is:
3811
3812     ($nfound,$timeleft) =
3813       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
3814
3815 or to block until something becomes ready just do this
3816
3817     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
3818
3819 Most systems do not bother to return anything useful in $timeleft, so
3820 calling select() in scalar context just returns $nfound.
3821
3822 Any of the bit masks can also be undef.  The timeout, if specified, is
3823 in seconds, which may be fractional.  Note: not all implementations are
3824 capable of returning the$timeleft.  If not, they always return
3825 $timeleft equal to the supplied $timeout.
3826
3827 You can effect a sleep of 250 milliseconds this way:
3828
3829     select(undef, undef, undef, 0.25);
3830
3831 B<WARNING>: One should not attempt to mix buffered I/O (like C<read>
3832 or E<lt>FHE<gt>) with C<select>, except as permitted by POSIX, and even
3833 then only on POSIX systems.  You have to use C<sysread> instead.
3834
3835 =item semctl ID,SEMNUM,CMD,ARG
3836
3837 Calls the System V IPC function C<semctl>.  You'll probably have to say
3838
3839     use IPC::SysV;
3840
3841 first to get the correct constant definitions.  If CMD is IPC_STAT or
3842 GETALL, then ARG must be a variable which will hold the returned
3843 semid_ds structure or semaphore value array.  Returns like C<ioctl>: the
3844 undefined value for error, "C<0 but true>" for zero, or the actual return
3845 value otherwise.  See also C<IPC::SysV> and C<IPC::Semaphore> documentation.
3846
3847 =item semget KEY,NSEMS,FLAGS
3848
3849 Calls the System V IPC function semget.  Returns the semaphore id, or
3850 the undefined value if there is an error.  See also C<IPC::SysV> and
3851 C<IPC::SysV::Semaphore> documentation.
3852
3853 =item semop KEY,OPSTRING
3854
3855 Calls the System V IPC function semop to perform semaphore operations
3856 such as signaling and waiting.  OPSTRING must be a packed array of
3857 semop structures.  Each semop structure can be generated with
3858 C<pack("sss", $semnum, $semop, $semflag)>.  The number of semaphore
3859 operations is implied by the length of OPSTRING.  Returns true if
3860 successful, or false if there is an error.  As an example, the
3861 following code waits on semaphore $semnum of semaphore id $semid:
3862
3863     $semop = pack("sss", $semnum, -1, 0);
3864     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
3865
3866 To signal the semaphore, replace C<-1> with C<1>.  See also C<IPC::SysV>
3867 and C<IPC::SysV::Semaphore> documentation.
3868
3869 =item send SOCKET,MSG,FLAGS,TO
3870
3871 =item send SOCKET,MSG,FLAGS
3872
3873 Sends a message on a socket.  Takes the same flags as the system call
3874 of the same name.  On unconnected sockets you must specify a
3875 destination to send TO, in which case it does a C C<sendto>.  Returns
3876 the number of characters sent, or the undefined value if there is an
3877 error.  The C system call sendmsg(2) is currently unimplemented.
3878 See L<perlipc/"UDP: Message Passing"> for examples.
3879
3880 =item setpgrp PID,PGRP
3881
3882 Sets the current process group for the specified PID, C<0> for the current
3883 process.  Will produce a fatal error if used on a machine that doesn't
3884 implement POSIX setpgid(2) or BSD setpgrp(2).  If the arguments are omitted,
3885 it defaults to C<0,0>.  Note that the BSD 4.2 version of C<setpgrp> does not
3886 accept any arguments, so only C<setpgrp(0,0)> is portable.  See also
3887 C<POSIX::setsid()>.
3888
3889 =item setpriority WHICH,WHO,PRIORITY
3890
3891 Sets the current priority for a process, a process group, or a user.
3892 (See setpriority(2).)  Will produce a fatal error if used on a machine
3893 that doesn't implement setpriority(2).
3894
3895 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
3896
3897 Sets the socket option requested.  Returns undefined if there is an
3898 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
3899 argument.
3900
3901 =item shift ARRAY
3902
3903 =item shift
3904
3905 Shifts the first value of the array off and returns it, shortening the
3906 array by 1 and moving everything down.  If there are no elements in the
3907 array, returns the undefined value.  If ARRAY is omitted, shifts the
3908 C<@_> array within the lexical scope of subroutines and formats, and the
3909 C<@ARGV> array at file scopes or within the lexical scopes established by
3910 the C<eval ''>, C<BEGIN {}>, C<INIT {}>, C<CHECK {}>, and C<END {}>
3911 constructs.
3912
3913 See also C<unshift>, C<push>, and C<pop>.  C<Shift()> and C<unshift> do the
3914 same thing to the left end of an array that C<pop> and C<push> do to the
3915 right end.
3916
3917 =item shmctl ID,CMD,ARG
3918
3919 Calls the System V IPC function shmctl.  You'll probably have to say
3920
3921     use IPC::SysV;
3922
3923 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3924 then ARG must be a variable which will hold the returned C<shmid_ds>
3925 structure.  Returns like ioctl: the undefined value for error, "C<0> but
3926 true" for zero, or the actual return value otherwise.
3927 See also C<IPC::SysV> documentation.
3928
3929 =item shmget KEY,SIZE,FLAGS
3930
3931 Calls the System V IPC function shmget.  Returns the shared memory
3932 segment id, or the undefined value if there is an error.
3933 See also C<IPC::SysV> documentation.
3934
3935 =item shmread ID,VAR,POS,SIZE
3936
3937 =item shmwrite ID,STRING,POS,SIZE
3938
3939 Reads or writes the System V shared memory segment ID starting at
3940 position POS for size SIZE by attaching to it, copying in/out, and
3941 detaching from it.  When reading, VAR must be a variable that will
3942 hold the data read.  When writing, if STRING is too long, only SIZE
3943 bytes are used; if STRING is too short, nulls are written to fill out
3944 SIZE bytes.  Return true if successful, or false if there is an error.
3945 See also C<IPC::SysV> documentation and the C<IPC::Shareable> module
3946 from CPAN.
3947
3948 =item shutdown SOCKET,HOW
3949
3950 Shuts down a socket connection in the manner indicated by HOW, which
3951 has the same interpretation as in the system call of the same name.
3952
3953     shutdown(SOCKET, 0);    # I/we have stopped reading data
3954     shutdown(SOCKET, 1);    # I/we have stopped writing data
3955     shutdown(SOCKET, 2);    # I/we have stopped using this socket
3956
3957 This is useful with sockets when you want to tell the other
3958 side you're done writing but not done reading, or vice versa.
3959 It's also a more insistent form of close because it also 
3960 disables the file descriptor in any forked copies in other
3961 processes.
3962
3963 =item sin EXPR
3964
3965 =item sin
3966
3967 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
3968 returns sine of C<$_>.
3969
3970 For the inverse sine operation, you may use the C<POSIX::asin>
3971 function, or use this relation:
3972
3973     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
3974
3975 =item sleep EXPR
3976
3977 =item sleep
3978
3979 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
3980 May be interrupted if the process receives a signal such as C<SIGALRM>.
3981 Returns the number of seconds actually slept.  You probably cannot
3982 mix C<alarm> and C<sleep> calls, because C<sleep> is often implemented
3983 using C<alarm>.
3984
3985 On some older systems, it may sleep up to a full second less than what
3986 you requested, depending on how it counts seconds.  Most modern systems
3987 always sleep the full amount.  They may appear to sleep longer than that,
3988 however, because your process might not be scheduled right away in a
3989 busy multitasking system.
3990
3991 For delays of finer granularity than one second, you may use Perl's
3992 C<syscall> interface to access setitimer(2) if your system supports
3993 it, or else see L</select> above.  The Time::HiRes module from CPAN
3994 may also help.
3995
3996 See also the POSIX module's C<sigpause> function.
3997
3998 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
3999
4000 Opens a socket of the specified kind and attaches it to filehandle
4001 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for
4002 the system call of the same name.  You should C<use Socket> first
4003 to get the proper definitions imported.  See the examples in
4004 L<perlipc/"Sockets: Client/Server Communication">.
4005
4006 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
4007
4008 Creates an unnamed pair of sockets in the specified domain, of the
4009 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
4010 for the system call of the same name.  If unimplemented, yields a fatal
4011 error.  Returns true if successful.
4012
4013 Some systems defined C<pipe> in terms of C<socketpair>, in which a call
4014 to C<pipe(Rdr, Wtr)> is essentially:
4015
4016     use Socket;
4017     socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
4018     shutdown(Rdr, 1);        # no more writing for reader
4019     shutdown(Wtr, 0);        # no more reading for writer
4020
4021 See L<perlipc> for an example of socketpair use.
4022
4023 =item sort SUBNAME LIST
4024
4025 =item sort BLOCK LIST
4026
4027 =item sort LIST
4028
4029 Sorts the LIST and returns the sorted list value.  If SUBNAME or BLOCK
4030 is omitted, C<sort>s in standard string comparison order.  If SUBNAME is
4031 specified, it gives the name of a subroutine that returns an integer
4032 less than, equal to, or greater than C<0>, depending on how the elements
4033 of the list are to be ordered.  (The C<E<lt>=E<gt>> and C<cmp>
4034 operators are extremely useful in such routines.)  SUBNAME may be a
4035 scalar variable name (unsubscripted), in which case the value provides
4036 the name of (or a reference to) the actual subroutine to use.  In place
4037 of a SUBNAME, you can provide a BLOCK as an anonymous, in-line sort
4038 subroutine.
4039
4040 If the subroutine's prototype is C<($$)>, the elements to be compared
4041 are passed by reference in C<@_>, as for a normal subroutine.  If not,
4042 the normal calling code for subroutines is bypassed in the interests of
4043 efficiency, and the elements to be compared are passed into the subroutine
4044 as the package global variables $a and $b (see example below).  Note that
4045 in the latter case, it is usually counter-productive to declare $a and
4046 $b as lexicals.
4047
4048 In either case, the subroutine may not be recursive.  The values to be
4049 compared are always passed by reference, so don't modify them.
4050
4051 You also cannot exit out of the sort block or subroutine using any of the
4052 loop control operators described in L<perlsyn> or with C<goto>.
4053
4054 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
4055 current collation locale.  See L<perllocale>.
4056
4057 Examples:
4058
4059     # sort lexically
4060     @articles = sort @files;
4061
4062     # same thing, but with explicit sort routine
4063     @articles = sort {$a cmp $b} @files;
4064
4065     # now case-insensitively
4066     @articles = sort {uc($a) cmp uc($b)} @files;
4067
4068     # same thing in reversed order
4069     @articles = sort {$b cmp $a} @files;
4070
4071     # sort numerically ascending
4072     @articles = sort {$a <=> $b} @files;
4073
4074     # sort numerically descending
4075     @articles = sort {$b <=> $a} @files;
4076
4077     # this sorts the %age hash by value instead of key
4078     # using an in-line function
4079     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
4080
4081     # sort using explicit subroutine name
4082     sub byage {
4083         $age{$a} <=> $age{$b};  # presuming numeric
4084     }
4085     @sortedclass = sort byage @class;
4086
4087     sub backwards { $b cmp $a }
4088     @harry  = qw(dog cat x Cain Abel);
4089     @george = qw(gone chased yz Punished Axed);
4090     print sort @harry;
4091             # prints AbelCaincatdogx
4092     print sort backwards @harry;
4093             # prints xdogcatCainAbel
4094     print sort @george, 'to', @harry;
4095             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
4096
4097     # inefficiently sort by descending numeric compare using
4098     # the first integer after the first = sign, or the
4099     # whole record case-insensitively otherwise
4100
4101     @new = sort {
4102         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
4103                             ||
4104                     uc($a)  cmp  uc($b)
4105     } @old;
4106
4107     # same thing, but much more efficiently;
4108     # we'll build auxiliary indices instead
4109     # for speed
4110     @nums = @caps = ();
4111     for (@old) {
4112         push @nums, /=(\d+)/;
4113         push @caps, uc($_);
4114     }
4115
4116     @new = @old[ sort {
4117                         $nums[$b] <=> $nums[$a]
4118                                  ||
4119                         $caps[$a] cmp $caps[$b]
4120                        } 0..$#old
4121                ];
4122
4123     # same thing, but without any temps
4124     @new = map { $_->[0] }
4125            sort { $b->[1] <=> $a->[1]
4126                            ||
4127                   $a->[2] cmp $b->[2]
4128            } map { [$_, /=(\d+)/, uc($_)] } @old;
4129     
4130     # using a prototype allows you to use any comparison subroutine
4131     # as a sort subroutine (including other package's subroutines)
4132     package other;
4133     sub backwards ($$) { $_[1] cmp $_[0]; }     # $a and $b are not set here
4134
4135     package main;
4136     @new = sort other::backwards @old;
4137
4138 If you're using strict, you I<must not> declare $a
4139 and $b as lexicals.  They are package globals.  That means
4140 if you're in the C<main> package, it's
4141
4142     @articles = sort {$main::b <=> $main::a} @files;
4143
4144 or just
4145
4146     @articles = sort {$::b <=> $::a} @files;
4147
4148 but if you're in the C<FooPack> package, it's
4149
4150     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
4151
4152 The comparison function is required to behave.  If it returns
4153 inconsistent results (sometimes saying C<$x[1]> is less than C<$x[2]> and
4154 sometimes saying the opposite, for example) the results are not
4155 well-defined.
4156
4157 =item splice ARRAY,OFFSET,LENGTH,LIST
4158
4159 =item splice ARRAY,OFFSET,LENGTH
4160
4161 =item splice ARRAY,OFFSET
4162
4163 Removes the elements designated by OFFSET and LENGTH from an array, and
4164 replaces them with the elements of LIST, if any.  In list context,
4165 returns the elements removed from the array.  In scalar context,
4166 returns the last element removed, or C<undef> if no elements are
4167 removed.  The array grows or shrinks as necessary.
4168 If OFFSET is negative then it starts that far from the end of the array.
4169 If LENGTH is omitted, removes everything from OFFSET onward.
4170 If LENGTH is negative, leave that many elements off the end of the array.
4171 The following equivalences hold (assuming C<$[ == 0>):
4172
4173     push(@a,$x,$y)      splice(@a,@a,0,$x,$y)
4174     pop(@a)             splice(@a,-1)
4175     shift(@a)           splice(@a,0,1)
4176     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
4177     $a[$x] = $y         splice(@a,$x,1,$y)
4178
4179 Example, assuming array lengths are passed before arrays:
4180
4181     sub aeq {   # compare two list values
4182         my(@a) = splice(@_,0,shift);
4183         my(@b) = splice(@_,0,shift);
4184         return 0 unless @a == @b;       # same len?
4185         while (@a) {
4186             return 0 if pop(@a) ne pop(@b);
4187         }
4188         return 1;
4189     }
4190     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
4191
4192 =item split /PATTERN/,EXPR,LIMIT
4193
4194 =item split /PATTERN/,EXPR
4195
4196 =item split /PATTERN/
4197
4198 =item split
4199
4200 Splits a string into a list of strings and returns that list.  By default,
4201 empty leading fields are preserved, and empty trailing ones are deleted.
4202
4203 If not in list context, returns the number of fields found and splits into
4204 the C<@_> array.  (In list context, you can force the split into C<@_> by
4205 using C<??> as the pattern delimiters, but it still returns the list
4206 value.)  The use of implicit split to C<@_> is deprecated, however, because
4207 it clobbers your subroutine arguments.
4208
4209 If EXPR is omitted, splits the C<$_> string.  If PATTERN is also omitted,
4210 splits on whitespace (after skipping any leading whitespace).  Anything
4211 matching PATTERN is taken to be a delimiter separating the fields.  (Note
4212 that the delimiter may be longer than one character.)
4213
4214 If LIMIT is specified and positive, splits into no more than that
4215 many fields (though it may split into fewer).  If LIMIT is unspecified
4216 or zero, trailing null fields are stripped (which potential users
4217 of C<pop> would do well to remember).  If LIMIT is negative, it is
4218 treated as if an arbitrarily large LIMIT had been specified.
4219
4220 A pattern matching the null string (not to be confused with
4221 a null pattern C<//>, which is just one member of the set of patterns
4222 matching a null string) will split the value of EXPR into separate
4223 characters at each point it matches that way.  For example:
4224
4225     print join(':', split(/ */, 'hi there'));
4226
4227 produces the output 'h:i:t:h:e:r:e'.
4228
4229 The LIMIT parameter can be used to split a line partially
4230
4231     ($login, $passwd, $remainder) = split(/:/, $_, 3);
4232
4233 When assigning to a list, if LIMIT is omitted, Perl supplies a LIMIT
4234 one larger than the number of variables in the list, to avoid
4235 unnecessary work.  For the list above LIMIT would have been 4 by
4236 default.  In time critical applications it behooves you not to split
4237 into more fields than you really need.
4238
4239 If the PATTERN contains parentheses, additional list elements are
4240 created from each matching substring in the delimiter.
4241
4242     split(/([,-])/, "1-10,20", 3);
4243
4244 produces the list value
4245
4246     (1, '-', 10, ',', 20)
4247
4248 If you had the entire header of a normal Unix email message in $header,
4249 you could split it up into fields and their values this way:
4250
4251     $header =~ s/\n\s+/ /g;  # fix continuation lines
4252     %hdrs   =  (UNIX_FROM => split /^(\S*?):\s*/m, $header);
4253
4254 The pattern C</PATTERN/> may be replaced with an expression to specify
4255 patterns that vary at runtime.  (To do runtime compilation only once,
4256 use C</$variable/o>.)
4257
4258 As a special case, specifying a PATTERN of space (C<' '>) will split on
4259 white space just as C<split> with no arguments does.  Thus, C<split(' ')> can
4260 be used to emulate B<awk>'s default behavior, whereas C<split(/ /)>
4261 will give you as many null initial fields as there are leading spaces.
4262 A C<split> on C</\s+/> is like a C<split(' ')> except that any leading
4263 whitespace produces a null first field.  A C<split> with no arguments
4264 really does a C<split(' ', $_)> internally.
4265
4266 Example:
4267
4268     open(PASSWD, '/etc/passwd');
4269     while (<PASSWD>) {
4270         ($login, $passwd, $uid, $gid,
4271          $gcos, $home, $shell) = split(/:/);
4272         #...
4273     }
4274
4275 (Note that $shell above will still have a newline on it.  See L</chop>,
4276 L</chomp>, and L</join>.)
4277
4278 =item sprintf FORMAT, LIST
4279
4280 Returns a string formatted by the usual C<printf> conventions of the
4281 C library function C<sprintf>.  See L<sprintf(3)> or L<printf(3)>
4282 on your system for an explanation of the general principles.
4283
4284 Perl does its own C<sprintf> formatting--it emulates the C
4285 function C<sprintf>, but it doesn't use it (except for floating-point
4286 numbers, and even then only the standard modifiers are allowed).  As a
4287 result, any non-standard extensions in your local C<sprintf> are not
4288 available from Perl.
4289
4290 Perl's C<sprintf> permits the following universally-known conversions:
4291
4292    %%   a percent sign
4293    %c   a character with the given number
4294    %s   a string
4295    %d   a signed integer, in decimal
4296    %u   an unsigned integer, in decimal
4297    %o   an unsigned integer, in octal
4298    %x   an unsigned integer, in hexadecimal
4299    %e   a floating-point number, in scientific notation
4300    %f   a floating-point number, in fixed decimal notation
4301    %g   a floating-point number, in %e or %f notation
4302
4303 In addition, Perl permits the following widely-supported conversions:
4304
4305    %X   like %x, but using upper-case letters
4306    %E   like %e, but using an upper-case "E"
4307    %G   like %g, but with an upper-case "E" (if applicable)
4308    %b   an unsigned integer, in binary
4309    %p   a pointer (outputs the Perl value's address in hexadecimal)
4310    %n   special: *stores* the number of characters output so far
4311         into the next variable in the parameter list 
4312
4313 Finally, for backward (and we do mean "backward") compatibility, Perl
4314 permits these unnecessary but widely-supported conversions:
4315
4316    %i   a synonym for %d
4317    %D   a synonym for %ld
4318    %U   a synonym for %lu
4319    %O   a synonym for %lo
4320    %F   a synonym for %f
4321
4322 Perl permits the following universally-known flags between the C<%>
4323 and the conversion letter:
4324
4325    space   prefix positive number with a space
4326    +       prefix positive number with a plus sign
4327    -       left-justify within the field
4328    0       use zeros, not spaces, to right-justify
4329    #       prefix non-zero octal with "0", non-zero hex with "0x"
4330    number  minimum field width
4331    .number "precision": digits after decimal point for
4332            floating-point, max length for string, minimum length
4333            for integer
4334    l       interpret integer as C type "long" or "unsigned long"
4335    h       interpret integer as C type "short" or "unsigned short"
4336            If no flags, interpret integer as C type "int" or "unsigned"
4337
4338 There is also one Perl-specific flag:
4339
4340    V       interpret integer as Perl's standard integer type
4341
4342 Where a number would appear in the flags, an asterisk (C<*>) may be
4343 used instead, in which case Perl uses the next item in the parameter
4344 list as the given number (that is, as the field width or precision).
4345 If a field width obtained through C<*> is negative, it has the same
4346 effect as the C<-> flag: left-justification.
4347
4348 If C<use locale> is in effect, the character used for the decimal
4349 point in formatted real numbers is affected by the LC_NUMERIC locale.
4350 See L<perllocale>.
4351
4352 If Perl understands "quads" (64-bit integers) (this requires
4353 either that the platform natively supports quads or that Perl
4354 has been specifically compiled to support quads), the characters
4355
4356         d u o x X b i D U O
4357
4358 print quads, and they may optionally be preceded by
4359
4360         ll L q
4361
4362 For example
4363
4364         %lld %16LX %qo
4365
4366 You can find out whether your Perl supports quads via L<Config>:
4367
4368         use Config;
4369         ($Config{use64bits} eq 'define' || $Config{longsize} == 8) &&
4370                 print "quads\n";
4371
4372 If Perl understands "long doubles" (this requires that the platform
4373 supports long doubles), the flags
4374
4375         e f g E F G
4376
4377 may optionally be preceded by
4378
4379         ll L
4380
4381 For example
4382
4383         %llf %Lg
4384
4385 You can find out whether your Perl supports long doubles via L<Config>:
4386
4387         use Config;
4388         $Config{d_longdbl} eq 'define' && print "long doubles\n";
4389
4390 =item sqrt EXPR
4391
4392 =item sqrt
4393
4394 Return the square root of EXPR.  If EXPR is omitted, returns square
4395 root of C<$_>.  Only works on non-negative operands, unless you've
4396 loaded the standard Math::Complex module.
4397
4398     use Math::Complex;
4399     print sqrt(-2);    # prints 1.4142135623731i
4400
4401 =item srand EXPR
4402
4403 =item srand
4404
4405 Sets the random number seed for the C<rand> operator.  If EXPR is
4406 omitted, uses a semi-random value supplied by the kernel (if it supports
4407 the F</dev/urandom> device) or based on the current time and process
4408 ID, among other things.  In versions of Perl prior to 5.004 the default
4409 seed was just the current C<time>.  This isn't a particularly good seed,
4410 so many old programs supply their own seed value (often C<time ^ $$> or
4411 C<time ^ ($$ + ($$ E<lt>E<lt> 15))>), but that isn't necessary any more.
4412
4413 In fact, it's usually not necessary to call C<srand> at all, because if
4414 it is not called explicitly, it is called implicitly at the first use of
4415 the C<rand> operator.  However, this was not the case in version of Perl
4416 before 5.004, so if your script will run under older Perl versions, it
4417 should call C<srand>.
4418
4419 Note that you need something much more random than the default seed for
4420 cryptographic purposes.  Checksumming the compressed output of one or more
4421 rapidly changing operating system status programs is the usual method.  For
4422 example:
4423
4424     srand (time ^ $$ ^ unpack "%L*", `ps axww | gzip`);
4425
4426 If you're particularly concerned with this, see the C<Math::TrulyRandom>
4427 module in CPAN.
4428
4429 Do I<not> call C<srand> multiple times in your program unless you know
4430 exactly what you're doing and why you're doing it.  The point of the
4431 function is to "seed" the C<rand> function so that C<rand> can produce
4432 a different sequence each time you run your program.  Just do it once at the
4433 top of your program, or you I<won't> get random numbers out of C<rand>!
4434
4435 Frequently called programs (like CGI scripts) that simply use
4436
4437     time ^ $$
4438
4439 for a seed can fall prey to the mathematical property that
4440
4441     a^b == (a+1)^(b+1)
4442
4443 one-third of the time.  So don't do that.
4444
4445 =item stat FILEHANDLE
4446
4447 =item stat EXPR
4448
4449 =item stat
4450
4451 Returns a 13-element list giving the status info for a file, either
4452 the file opened via FILEHANDLE, or named by EXPR.  If EXPR is omitted,
4453 it stats C<$_>.  Returns a null list if the stat fails.  Typically used
4454 as follows:
4455
4456     ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
4457        $atime,$mtime,$ctime,$blksize,$blocks)
4458            = stat($filename);
4459
4460 Not all fields are supported on all filesystem types.  Here are the
4461 meaning of the fields:
4462
4463   0 dev      device number of filesystem
4464   1 ino      inode number
4465   2 mode     file mode  (type and permissions)
4466   3 nlink    number of (hard) links to the file
4467   4 uid      numeric user ID of file's owner
4468   5 gid      numeric group ID of file's owner
4469   6 rdev     the device identifier (special files only)
4470   7 size     total size of file, in bytes
4471   8 atime    last access time in seconds since the epoch
4472   9 mtime    last modify time in seconds since the epoch
4473  10 ctime    inode change time (NOT creation time!) in seconds since the epoch
4474  11 blksize  preferred block size for file system I/O
4475  12 blocks   actual number of blocks allocated
4476
4477 (The epoch was at 00:00 January 1, 1970 GMT.)
4478
4479 If stat is passed the special filehandle consisting of an underline, no
4480 stat is done, but the current contents of the stat structure from the
4481 last stat or filetest are returned.  Example:
4482
4483     if (-x $file && (($d) = stat(_)) && $d < 0) {
4484         print "$file is executable NFS file\n";
4485     }
4486
4487 (This works on machines only for which the device number is negative under NFS.)
4488
4489 Because the mode contains both the file type and its permissions, you
4490 should mask off the file type portion and (s)printf using a C<"%o"> 
4491 if you want to see the real permissions.
4492
4493     $mode = (stat($filename))[2];
4494     printf "Permissions are %04o\n", $mode & 07777;
4495
4496 In scalar context, C<stat> returns a boolean value indicating success
4497 or failure, and, if successful, sets the information associated with
4498 the special filehandle C<_>.
4499
4500 The File::stat module provides a convenient, by-name access mechanism:
4501
4502     use File::stat;
4503     $sb = stat($filename);
4504     printf "File is %s, size is %s, perm %04o, mtime %s\n", 
4505         $filename, $sb->size, $sb->mode & 07777,
4506         scalar localtime $sb->mtime;
4507
4508 =item study SCALAR
4509
4510 =item study
4511
4512 Takes extra time to study SCALAR (C<$_> if unspecified) in anticipation of
4513 doing many pattern matches on the string before it is next modified.
4514 This may or may not save time, depending on the nature and number of
4515 patterns you are searching on, and on the distribution of character
4516 frequencies in the string to be searched--you probably want to compare
4517 run times with and without it to see which runs faster.  Those loops
4518 which scan for many short constant strings (including the constant
4519 parts of more complex patterns) will benefit most.  You may have only
4520 one C<study> active at a time--if you study a different scalar the first
4521 is "unstudied".  (The way C<study> works is this: a linked list of every
4522 character in the string to be searched is made, so we know, for
4523 example, where all the C<'k'> characters are.  From each search string,
4524 the rarest character is selected, based on some static frequency tables
4525 constructed from some C programs and English text.  Only those places
4526 that contain this "rarest" character are examined.)
4527
4528 For example, here is a loop that inserts index producing entries
4529 before any line containing a certain pattern:
4530
4531     while (<>) {
4532         study;
4533         print ".IX foo\n"       if /\bfoo\b/;
4534         print ".IX bar\n"       if /\bbar\b/;
4535         print ".IX blurfl\n"    if /\bblurfl\b/;
4536         # ...
4537         print;
4538     }
4539
4540 In searching for C</\bfoo\b/>, only those locations in C<$_> that contain C<f>
4541 will be looked at, because C<f> is rarer than C<o>.  In general, this is
4542 a big win except in pathological cases.  The only question is whether
4543 it saves you more time than it took to build the linked list in the
4544 first place.
4545
4546 Note that if you have to look for strings that you don't know till
4547 runtime, you can build an entire loop as a string and C<eval> that to
4548 avoid recompiling all your patterns all the time.  Together with
4549 undefining C<$/> to input entire files as one record, this can be very
4550 fast, often faster than specialized programs like fgrep(1).  The following
4551 scans a list of files (C<@files>) for a list of words (C<@words>), and prints
4552 out the names of those files that contain a match:
4553
4554     $search = 'while (<>) { study;';
4555     foreach $word (@words) {
4556         $search .= "++\$seen{\$ARGV} if /\\b$word\\b/;\n";
4557     }
4558     $search .= "}";
4559     @ARGV = @files;
4560     undef $/;
4561     eval $search;               # this screams
4562     $/ = "\n";          # put back to normal input delimiter
4563     foreach $file (sort keys(%seen)) {
4564         print $file, "\n";
4565     }
4566
4567 =item sub BLOCK
4568
4569 =item sub NAME
4570
4571 =item sub NAME BLOCK
4572
4573 This is subroutine definition, not a real function I<per se>.  With just a
4574 NAME (and possibly prototypes or attributes), it's just a forward declaration.
4575 Without a NAME, it's an anonymous function declaration, and does actually
4576 return a value: the CODE ref of the closure you just created.  See L<perlsub>
4577 and L<perlref> for details.
4578
4579 =item substr EXPR,OFFSET,LENGTH,REPLACEMENT
4580
4581 =item substr EXPR,OFFSET,LENGTH
4582
4583 =item substr EXPR,OFFSET
4584
4585 Extracts a substring out of EXPR and returns it.  First character is at
4586 offset C<0>, or whatever you've set C<$[> to (but don't do that).
4587 If OFFSET is negative (or more precisely, less than C<$[>), starts
4588 that far from the end of the string.  If LENGTH is omitted, returns
4589 everything to the end of the string.  If LENGTH is negative, leaves that
4590 many characters off the end of the string.
4591
4592 You can use the substr() function as an lvalue, in which case EXPR
4593 must itself be an lvalue.  If you assign something shorter than LENGTH,
4594 the string will shrink, and if you assign something longer than LENGTH,
4595 the string will grow to accommodate it.  To keep the string the same
4596 length you may need to pad or chop your value using C<sprintf>.
4597
4598 If OFFSET and LENGTH specify a substring that is partly outside the
4599 string, only the part within the string is returned.  If the substring
4600 is beyond either end of the string, substr() returns the undefined
4601 value and produces a warning.  When used as an lvalue, specifying a
4602 substring that is entirely outside the string is a fatal error.
4603 Here's an example showing the behavior for boundary cases:
4604
4605     my $name = 'fred';
4606     substr($name, 4) = 'dy';            # $name is now 'freddy'
4607     my $null = substr $name, 6, 2;      # returns '' (no warning)
4608     my $oops = substr $name, 7;         # returns undef, with warning
4609     substr($name, 7) = 'gap';           # fatal error
4610
4611 An alternative to using substr() as an lvalue is to specify the
4612 replacement string as the 4th argument.  This allows you to replace
4613 parts of the EXPR and return what was there before in one operation,
4614 just as you can with splice().
4615
4616 =item symlink OLDFILE,NEWFILE
4617
4618 Creates a new filename symbolically linked to the old filename.
4619 Returns C<1> for success, C<0> otherwise.  On systems that don't support
4620 symbolic links, produces a fatal error at run time.  To check for that,
4621 use eval:
4622
4623     $symlink_exists = eval { symlink("",""); 1 };
4624
4625 =item syscall LIST
4626
4627 Calls the system call specified as the first element of the list,
4628 passing the remaining elements as arguments to the system call.  If
4629 unimplemented, produces a fatal error.  The arguments are interpreted
4630 as follows: if a given argument is numeric, the argument is passed as
4631 an int.  If not, the pointer to the string value is passed.  You are
4632 responsible to make sure a string is pre-extended long enough to
4633 receive any result that might be written into a string.  You can't use a
4634 string literal (or other read-only string) as an argument to C<syscall>
4635 because Perl has to assume that any string pointer might be written
4636 through.  If your
4637 integer arguments are not literals and have never been interpreted in a
4638 numeric context, you may need to add C<0> to them to force them to look
4639 like numbers.  This emulates the C<syswrite> function (or vice versa):
4640
4641     require 'syscall.ph';               # may need to run h2ph
4642     $s = "hi there\n";
4643     syscall(&SYS_write, fileno(STDOUT), $s, length $s);
4644
4645 Note that Perl supports passing of up to only 14 arguments to your system call,
4646 which in practice should usually suffice.
4647
4648 Syscall returns whatever value returned by the system call it calls.
4649 If the system call fails, C<syscall> returns C<-1> and sets C<$!> (errno).
4650 Note that some system calls can legitimately return C<-1>.  The proper
4651 way to handle such calls is to assign C<$!=0;> before the call and
4652 check the value of C<$!> if syscall returns C<-1>.
4653
4654 There's a problem with C<syscall(&SYS_pipe)>: it returns the file
4655 number of the read end of the pipe it creates.  There is no way
4656 to retrieve the file number of the other end.  You can avoid this 
4657 problem by using C<pipe> instead.
4658
4659 =item sysopen FILEHANDLE,FILENAME,MODE
4660
4661 =item sysopen FILEHANDLE,FILENAME,MODE,PERMS
4662