This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
regen/unicode_constants.pl: Convert '-' in names to '_'
[perl5.git] / regen / unicode_constants.pl
1 use v5.16.0;
2 use strict;
3 use warnings;
4 require 'regen/regen_lib.pl';
5 use charnames qw(:loose);
6
7 my $out_fh = open_new('unicode_constants.h', '>',
8                       {style => '*', by => $0,
9                       from => "Unicode data"});
10
11 print $out_fh <<END;
12
13 #ifndef H_UNICODE_CONSTANTS   /* Guard against nested #includes */
14 #define H_UNICODE_CONSTANTS   1
15
16 /* This file contains #defines for various Unicode code points.  The values
17  * the macros expand to are the native Unicode code point, or all or portions
18  * of the UTF-8 encoding for the code point.  In the former case, the macro
19  * name has the suffix "_NATIVE"; otherwise, the suffix "_UTF8".
20  *
21  * The macros that have the suffix "_UTF8" may have further suffixes, as
22  * follows:
23  *  "_FIRST_BYTE" if the value is just the first byte of the UTF-8
24  *                representation; the value will be a numeric constant.
25  *  "_TAIL"       if instead it represents all but the first byte.  This, and
26  *                with no additional suffix are both string constants */
27
28 END
29
30 # The data are at the end of this file.  A blank line is output as-is.
31 # Otherwise, each line represents one #define, and begins with either a
32 # Unicode character name with the blanks and dashes in it squeezed out or replaced by
33 # underscores; or it may be a hexadecimal Unicode code point.  In the latter
34 # case, the name will be looked-up to use as the name of the macro.  In either
35 # case, the macro name will have suffixes as listed above, and all blanks and
36 # dashes will be replaced by underscores.
37 #
38 # Each line may optionally have one of the following flags on it, separated by
39 # white space from the initial token.
40 #   string  indicates that the output is to be of the string form
41 #           described in the comments above that are placed in the file.
42 #   string_skip_ifundef  is the same as 'string', but instead of dying if the
43 #           code point doesn't exist, the line is just skipped: no output is
44 #           generated for it
45 #   first   indicates that the output is to be of the FIRST_BYTE form.
46 #   tail    indicates that the output is of the _TAIL form.
47 #   native  indicates that the output is the code point, converted to the
48 #           platform's native character set if applicable
49 #
50 # If the code point has no official name, the desired name may be appended
51 # after the flag, which will be ignored if there is an official name.
52 #
53 # This program is used to make it convenient to create compile time constants
54 # of UTF-8, and to generate proper EBCDIC as well as ASCII without manually
55 # having to figure things out.
56
57 while ( <DATA> ) {
58     if ($_ !~ /\S/) {
59         print $out_fh "\n";
60         next;
61     }
62
63     chomp;
64     unless ($_ =~ m/ ^ ( [^\ ]* )           # Name or code point token
65                        (?: [\ ]+ ( [^ ]* ) )?  # optional flag
66                        (?: [\ ]+ ( .* ) )?  # name if unnamed; flag is required
67                    /x)
68     {
69         die "Unexpected syntax at line $.: $_\n";
70     }
71
72     my $name_or_cp = $1;
73     my $flag = $2;
74     my $desired_name = $3;
75
76     my $name;
77     my $cp;
78     my $undef_ok = $desired_name || $flag =~ /skip_if_undef/;
79
80     if ($name_or_cp =~ /[^[:xdigit:]]/) {
81
82         # Anything that isn't a hex value must be a name.
83         $name = $name_or_cp;
84         $cp = charnames::vianame($name =~ s/_/ /gr);
85         die "Unknown name '$name' at line $.: $_\n" unless defined $name;
86     }
87     else {
88         $cp = $name_or_cp;
89         $name = charnames::viacode("0$cp"); # viacode requires a leading zero
90                                             # to be sure that the argument is
91                                             # hex
92         if (! defined $name) {
93             die "Unknown code point '$cp' at line $.: $_\n" unless $undef_ok;
94             $name = "";
95         }
96     }
97
98     $name = $desired_name if $name eq "" && $desired_name;
99     $name =~ s/[- ]/_/g;   # The macro name can have no blanks nor dashes
100
101     my $str = join "", map { sprintf "\\x%02X", $_ }
102                        unpack("U0C*", pack("U", hex $cp));
103
104     my $suffix = '_UTF8';
105     if (! defined $flag  || $flag =~ /^ string (_skip_if_undef)? $/x) {
106         $str = "\"$str\"";  # Will be a string constant
107     } elsif ($flag eq 'tail') {
108             $str =~ s/\\x..//;  # Remove the first byte
109             $suffix .= '_TAIL';
110             $str = "\"$str\"";  # Will be a string constant
111     }
112     elsif ($flag eq 'first') {
113         $str =~ s/ \\x ( .. ) .* /$1/x; # Get the two nibbles of the 1st byte
114         $suffix .= '_FIRST_BYTE';
115         $str = "0x$str";        # Is a numeric constant
116     }
117     elsif ($flag eq 'native') {
118         die "Are you sure you want to run this on an above-Latin1 code point?" if hex $cp > 0xff;
119         $suffix = '_NATIVE';
120         $str = utf8::unicode_to_native(hex $cp);
121         $str = "0x$cp";        # Is a numeric constant
122     }
123     else {
124         die "Unknown flag at line $.: $_\n";
125     }
126     print $out_fh "#define ${name}$suffix $str    /* U+$cp */\n";
127 }
128
129 print $out_fh "\n#endif /* H_UNICODE_CONSTANTS */\n";
130
131 read_only_bottom_close_and_rename($out_fh);
132
133 __DATA__
134 0300 string
135 0301 string
136 0308 string
137
138 03B9 string
139
140 03C5 string
141
142 2010 string
143 D800 first FIRST_SURROGATE
144
145 007F native
146 00DF native
147 00E5 native
148 00C5 native
149 00FF native
150 00B5 native
151 0085 native