This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
This patch with tests resolves CPAN RT #40727. The issue is an infi-
[perl5.git] / dist / Locale-Maketext / lib / Locale / Maketext.pm
1
2 package Locale::Maketext;
3 use strict;
4 use vars qw( @ISA $VERSION $MATCH_SUPERS $USING_LANGUAGE_TAGS
5 $USE_LITERALS $MATCH_SUPERS_TIGHTLY);
6 use Carp ();
7 use I18N::LangTags 0.30 ();
8
9 #--------------------------------------------------------------------------
10
11 BEGIN { unless(defined &DEBUG) { *DEBUG = sub () {0} } }
12 # define the constant 'DEBUG' at compile-time
13
14 # turn on utf8 if we have it (this is what GutsLoader.pm used to do essentially )
15 #    use if (exists $INC{'utf8.pm'} || eval 'use utf8'), 'utf8';
16 BEGIN {
17
18     # if we have it || we can load it
19     if ( exists $INC{'utf8.pm'} || eval { local $SIG{'__DIE__'};require utf8; } ) {
20         utf8->import();
21         DEBUG and warn " utf8 on for _compile()\n";
22     }
23     else {
24         DEBUG and warn " utf8 not available for _compile() ($INC{'utf8.pm'})\n$@\n";
25     }
26 }
27
28
29 $VERSION = '1.15';
30 @ISA = ();
31
32 $MATCH_SUPERS = 1;
33 $MATCH_SUPERS_TIGHTLY = 1;
34 $USING_LANGUAGE_TAGS  = 1;
35 # Turning this off is somewhat of a security risk in that little or no
36 # checking will be done on the legality of tokens passed to the
37 # eval("use $module_name") in _try_use.  If you turn this off, you have
38 # to do your own taint checking.
39
40 $USE_LITERALS = 1 unless defined $USE_LITERALS;
41 # a hint for compiling bracket-notation things.
42
43 my %isa_scan = ();
44
45 ###########################################################################
46
47 sub quant {
48     my($handle, $num, @forms) = @_;
49
50     return $num if @forms == 0; # what should this mean?
51     return $forms[2] if @forms > 2 and $num == 0; # special zeroth case
52
53     # Normal case:
54     # Note that the formatting of $num is preserved.
55     return( $handle->numf($num) . ' ' . $handle->numerate($num, @forms) );
56     # Most human languages put the number phrase before the qualified phrase.
57 }
58
59
60 sub numerate {
61     # return this lexical item in a form appropriate to this number
62     my($handle, $num, @forms) = @_;
63     my $s = ($num == 1);
64
65     return '' unless @forms;
66     if(@forms == 1) { # only the headword form specified
67         return $s ? $forms[0] : ($forms[0] . 's'); # very cheap hack.
68     }
69     else { # sing and plural were specified
70         return $s ? $forms[0] : $forms[1];
71     }
72 }
73
74 #--------------------------------------------------------------------------
75
76 sub numf {
77     my($handle, $num) = @_[0,1];
78     if($num < 10_000_000_000 and $num > -10_000_000_000 and $num == int($num)) {
79         $num += 0;  # Just use normal integer stringification.
80         # Specifically, don't let %G turn ten million into 1E+007
81     }
82     else {
83         $num = CORE::sprintf('%G', $num);
84         # "CORE::" is there to avoid confusion with the above sub sprintf.
85     }
86     while( $num =~ s/^([-+]?\d+)(\d{3})/$1,$2/s ) {1}  # right from perlfaq5
87     # The initial \d+ gobbles as many digits as it can, and then we
88     #  backtrack so it un-eats the rightmost three, and then we
89     #  insert the comma there.
90
91     $num =~ tr<.,><,.> if ref($handle) and $handle->{'numf_comma'};
92     # This is just a lame hack instead of using Number::Format
93     return $num;
94 }
95
96 sub sprintf {
97     no integer;
98     my($handle, $format, @params) = @_;
99     return CORE::sprintf($format, @params);
100     # "CORE::" is there to avoid confusion with myself!
101 }
102
103 #=#=#=#=#=#=#=#=#=#=#=#=#=#=#=#=#=#=#=#=#=#=#=#=#=#=#=#=#=#=#=#=#=#=#=#=#=#
104
105 use integer; # vroom vroom... applies to the whole rest of the module
106
107 sub language_tag {
108     my $it = ref($_[0]) || $_[0];
109     return undef unless $it =~ m/([^':]+)(?:::)?$/s;
110     $it = lc($1);
111     $it =~ tr<_><->;
112     return $it;
113 }
114
115 sub encoding {
116     my $it = $_[0];
117     return(
118         (ref($it) && $it->{'encoding'})
119         || 'iso-8859-1'   # Latin-1
120     );
121 }
122
123 #--------------------------------------------------------------------------
124
125 sub fallback_languages { return('i-default', 'en', 'en-US') }
126
127 sub fallback_language_classes { return () }
128
129 #--------------------------------------------------------------------------
130
131 sub fail_with { # an actual attribute method!
132     my($handle, @params) = @_;
133     return unless ref($handle);
134     $handle->{'fail'} = $params[0] if @params;
135     return $handle->{'fail'};
136 }
137
138 #--------------------------------------------------------------------------
139
140 sub failure_handler_auto {
141     # Meant to be used like:
142     #  $handle->fail_with('failure_handler_auto')
143
144     my $handle = shift;
145     my $phrase = shift;
146
147     $handle->{'failure_lex'} ||= {};
148     my $lex = $handle->{'failure_lex'};
149
150     my $value;
151     $lex->{$phrase} ||= ($value = $handle->_compile($phrase));
152
153     # Dumbly copied from sub maketext:
154     return ${$value} if ref($value) eq 'SCALAR';
155     return $value    if ref($value) ne 'CODE';
156     {
157         local $SIG{'__DIE__'};
158         eval { $value = &$value($handle, @_) };
159     }
160     # If we make it here, there was an exception thrown in the
161     #  call to $value, and so scream:
162     if($@) {
163         my $err = $@;
164         # pretty up the error message
165         $err =~ s{\s+at\s+\(eval\s+\d+\)\s+line\s+(\d+)\.?\n?}
166                  {\n in bracket code [compiled line $1],}s;
167         #$err =~ s/\n?$/\n/s;
168         Carp::croak "Error in maketexting \"$phrase\":\n$err as used";
169         # Rather unexpected, but suppose that the sub tried calling
170         # a method that didn't exist.
171     }
172     else {
173         return $value;
174     }
175 }
176
177 #==========================================================================
178
179 sub new {
180     # Nothing fancy!
181     my $class = ref($_[0]) || $_[0];
182     my $handle = bless {}, $class;
183     $handle->init;
184     return $handle;
185 }
186
187 sub init { return } # no-op
188
189 ###########################################################################
190
191 sub maketext {
192     # Remember, this can fail.  Failure is controllable many ways.
193     Carp::croak 'maketext requires at least one parameter' unless @_ > 1;
194
195     my($handle, $phrase) = splice(@_,0,2);
196     Carp::confess('No handle/phrase') unless (defined($handle) && defined($phrase));
197
198
199     # Don't interefere with $@ in case that's being interpolated into the msg.
200     local $@;
201
202     # Look up the value:
203
204     my $value;
205     if (exists $handle->{'_external_lex_cache'}{$phrase}) {
206         DEBUG and warn "* Using external lex cache version of \"$phrase\"\n";
207         $value = $handle->{'_external_lex_cache'}{$phrase};
208     }
209     else {
210         foreach my $h_r (
211             @{  $isa_scan{ref($handle) || $handle} || $handle->_lex_refs  }
212         ) {
213             DEBUG and warn "* Looking up \"$phrase\" in $h_r\n";
214             if(exists $h_r->{$phrase}) {
215                 DEBUG and warn "  Found \"$phrase\" in $h_r\n";
216                 unless(ref($value = $h_r->{$phrase})) {
217                     # Nonref means it's not yet compiled.  Compile and replace.
218                     if ($handle->{'use_external_lex_cache'}) {
219                         $value = $handle->{'_external_lex_cache'}{$phrase} = $handle->_compile($value);
220                     }
221                     else {
222                         $value = $h_r->{$phrase} = $handle->_compile($value);
223                     }
224                 }
225                 last;
226             }
227             # extending packages need to be able to localize _AUTO and if readonly can't "local $h_r->{'_AUTO'} = 1;"
228             # but they can "local $handle->{'_external_lex_cache'}{'_AUTO'} = 1;"
229             elsif($phrase !~ m/^_/s and ($handle->{'use_external_lex_cache'} ? ( exists $handle->{'_external_lex_cache'}{'_AUTO'} ? $handle->{'_external_lex_cache'}{'_AUTO'} : $h_r->{'_AUTO'} ) : $h_r->{'_AUTO'})) {
230                 # it's an auto lex, and this is an autoable key!
231                 DEBUG and warn "  Automaking \"$phrase\" into $h_r\n";
232                 if ($handle->{'use_external_lex_cache'}) {
233                     $value = $handle->{'_external_lex_cache'}{$phrase} = $handle->_compile($phrase);
234                 }
235                 else {
236                     $value = $h_r->{$phrase} = $handle->_compile($phrase);
237                 }
238                 last;
239             }
240             DEBUG>1 and print "  Not found in $h_r, nor automakable\n";
241             # else keep looking
242         }
243     }
244
245     unless(defined($value)) {
246         DEBUG and warn "! Lookup of \"$phrase\" in/under ", ref($handle) || $handle, " fails.\n";
247         if(ref($handle) and $handle->{'fail'}) {
248             DEBUG and warn "WARNING0: maketext fails looking for <$phrase>\n";
249             my $fail;
250             if(ref($fail = $handle->{'fail'}) eq 'CODE') { # it's a sub reference
251                 return &{$fail}($handle, $phrase, @_);
252                 # If it ever returns, it should return a good value.
253             }
254             else { # It's a method name
255                 return $handle->$fail($phrase, @_);
256                 # If it ever returns, it should return a good value.
257             }
258         }
259         else {
260             # All we know how to do is this;
261             Carp::croak("maketext doesn't know how to say:\n$phrase\nas needed");
262         }
263     }
264
265     return $$value if ref($value) eq 'SCALAR';
266     return $value unless ref($value) eq 'CODE';
267
268     {
269         local $SIG{'__DIE__'};
270         eval { $value = &$value($handle, @_) };
271     }
272     # If we make it here, there was an exception thrown in the
273     #  call to $value, and so scream:
274     if ($@) {
275         my $err = $@;
276         # pretty up the error message
277         $err =~ s{\s+at\s+\(eval\s+\d+\)\s+line\s+(\d+)\.?\n?}
278                  {\n in bracket code [compiled line $1],}s;
279         #$err =~ s/\n?$/\n/s;
280         Carp::croak "Error in maketexting \"$phrase\":\n$err as used";
281         # Rather unexpected, but suppose that the sub tried calling
282         # a method that didn't exist.
283     }
284     else {
285         return $value;
286     }
287 }
288
289 ###########################################################################
290
291 sub get_handle {  # This is a constructor and, yes, it CAN FAIL.
292     # Its class argument has to be the base class for the current
293     # application's l10n files.
294
295     my($base_class, @languages) = @_;
296     $base_class = ref($base_class) || $base_class;
297     # Complain if they use __PACKAGE__ as a project base class?
298
299     if( @languages ) {
300         DEBUG and warn 'Lgs@', __LINE__, ': ', map("<$_>", @languages), "\n";
301         if($USING_LANGUAGE_TAGS) {   # An explicit language-list was given!
302             @languages =
303             map {; $_, I18N::LangTags::alternate_language_tags($_) }
304             # Catch alternation
305             map I18N::LangTags::locale2language_tag($_),
306             # If it's a lg tag, fine, pass thru (untainted)
307             # If it's a locale ID, try converting to a lg tag (untainted),
308             # otherwise nix it.
309             @languages;
310             DEBUG and warn 'Lgs@', __LINE__, ': ', map("<$_>", @languages), "\n";
311         }
312     }
313     else {
314         @languages = $base_class->_ambient_langprefs;
315     }
316
317     @languages = $base_class->_langtag_munging(@languages);
318
319     my %seen;
320     foreach my $module_name ( map { $base_class . '::' . $_ }  @languages ) {
321         next unless length $module_name; # sanity
322         next if $seen{$module_name}++        # Already been here, and it was no-go
323         || !&_try_use($module_name); # Try to use() it, but can't it.
324         return($module_name->new); # Make it!
325     }
326
327     return undef; # Fail!
328 }
329
330 ###########################################################################
331
332 sub _langtag_munging {
333     my($base_class, @languages) = @_;
334
335     # We have all these DEBUG statements because otherwise it's hard as hell
336     # to diagnose ifwhen something goes wrong.
337
338     DEBUG and warn 'Lgs1: ', map("<$_>", @languages), "\n";
339
340     if($USING_LANGUAGE_TAGS) {
341         DEBUG and warn 'Lgs@', __LINE__, ': ', map("<$_>", @languages), "\n";
342         @languages     = $base_class->_add_supers( @languages );
343
344         push @languages, I18N::LangTags::panic_languages(@languages);
345         DEBUG and warn "After adding panic languages:\n",
346         ' Lgs@', __LINE__, ': ', map("<$_>", @languages), "\n";
347
348         push @languages, $base_class->fallback_languages;
349         # You are free to override fallback_languages to return empty-list!
350         DEBUG and warn 'Lgs@', __LINE__, ': ', map("<$_>", @languages), "\n";
351
352         @languages =  # final bit of processing to turn them into classname things
353         map {
354             my $it = $_;  # copy
355             $it =~ tr<-A-Z><_a-z>; # lc, and turn - to _
356             $it =~ tr<_a-z0-9><>cd;  # remove all but a-z0-9_
357             $it;
358         } @languages
359         ;
360         DEBUG and warn "Nearing end of munging:\n",
361         ' Lgs@', __LINE__, ': ', map("<$_>", @languages), "\n";
362     }
363     else {
364         DEBUG and warn "Bypassing language-tags.\n",
365         ' Lgs@', __LINE__, ': ', map("<$_>", @languages), "\n";
366     }
367
368     DEBUG and warn "Before adding fallback classes:\n",
369     ' Lgs@', __LINE__, ': ', map("<$_>", @languages), "\n";
370
371     push @languages, $base_class->fallback_language_classes;
372     # You are free to override that to return whatever.
373
374     DEBUG and warn "Finally:\n",
375     ' Lgs@', __LINE__, ': ', map("<$_>", @languages), "\n";
376
377     return @languages;
378 }
379
380 ###########################################################################
381
382 sub _ambient_langprefs {
383     require I18N::LangTags::Detect;
384     return  I18N::LangTags::Detect::detect();
385 }
386
387 ###########################################################################
388
389 sub _add_supers {
390     my($base_class, @languages) = @_;
391
392     if (!$MATCH_SUPERS) {
393         # Nothing
394         DEBUG and warn "Bypassing any super-matching.\n",
395         ' Lgs@', __LINE__, ': ', map("<$_>", @languages), "\n";
396
397     }
398     elsif( $MATCH_SUPERS_TIGHTLY ) {
399         DEBUG and warn "Before adding new supers tightly:\n",
400         ' Lgs@', __LINE__, ': ', map("<$_>", @languages), "\n";
401         @languages = I18N::LangTags::implicate_supers( @languages );
402         DEBUG and warn "After adding new supers tightly:\n",
403         ' Lgs@', __LINE__, ': ', map("<$_>", @languages), "\n";
404
405     }
406     else {
407         DEBUG and warn "Before adding supers to end:\n",
408         ' Lgs@', __LINE__, ': ', map("<$_>", @languages), "\n";
409         @languages = I18N::LangTags::implicate_supers_strictly( @languages );
410         DEBUG and warn "After adding supers to end:\n",
411         ' Lgs@', __LINE__, ': ', map("<$_>", @languages), "\n";
412     }
413
414     return @languages;
415 }
416
417 ###########################################################################
418 #
419 # This is where most people should stop reading.
420 #
421 ###########################################################################
422
423 my %tried = ();
424 # memoization of whether we've used this module, or found it unusable.
425
426 sub _try_use {   # Basically a wrapper around "require Modulename"
427     # "Many men have tried..."  "They tried and failed?"  "They tried and died."
428     return $tried{$_[0]} if exists $tried{$_[0]};  # memoization
429
430     my $module = $_[0];   # ASSUME sane module name!
431     { no strict 'refs';
432         return($tried{$module} = 1)
433         if %{$module . '::Lexicon'} or @{$module . '::ISA'};
434         # weird case: we never use'd it, but there it is!
435     }
436
437     DEBUG and warn " About to use $module ...\n";
438     {
439         local $SIG{'__DIE__'};
440         eval "require $module"; # used to be "use $module", but no point in that.
441     }
442     if($@) {
443         DEBUG and warn "Error using $module \: $@\n";
444         return $tried{$module} = 0;
445     }
446     else {
447         DEBUG and warn " OK, $module is used\n";
448         return $tried{$module} = 1;
449     }
450 }
451
452 #--------------------------------------------------------------------------
453
454 sub _lex_refs {  # report the lexicon references for this handle's class
455     # returns an arrayREF!
456     no strict 'refs';
457     no warnings 'once';
458     my $class = ref($_[0]) || $_[0];
459     DEBUG and warn "Lex refs lookup on $class\n";
460     return $isa_scan{$class} if exists $isa_scan{$class};  # memoization!
461
462     my @lex_refs;
463     my $seen_r = ref($_[1]) ? $_[1] : {};
464
465     if( defined( *{$class . '::Lexicon'}{'HASH'} )) {
466         push @lex_refs, *{$class . '::Lexicon'}{'HASH'};
467         DEBUG and warn '%' . $class . '::Lexicon contains ',
468             scalar(keys %{$class . '::Lexicon'}), " entries\n";
469     }
470
471     # Implements depth(height?)-first recursive searching of superclasses.
472     # In hindsight, I suppose I could have just used Class::ISA!
473     foreach my $superclass (@{$class . '::ISA'}) {
474         DEBUG and warn " Super-class search into $superclass\n";
475         next if $seen_r->{$superclass}++;
476         push @lex_refs, @{&_lex_refs($superclass, $seen_r)};  # call myself
477     }
478
479     $isa_scan{$class} = \@lex_refs; # save for next time
480     return \@lex_refs;
481 }
482
483 sub clear_isa_scan { %isa_scan = (); return; } # end on a note of simplicity!
484
485 #--------------------------------------------------------------------------
486
487 sub _compile {
488     # This big scary routine compiles an entry.
489     # It returns either a coderef if there's brackety bits in this, or
490     #  otherwise a ref to a scalar.
491
492     my $target = ref($_[0]) || $_[0];
493
494     my(@code);
495     my(@c) = (''); # "chunks" -- scratch.
496     my $call_count = 0;
497     my $big_pile = '';
498     {
499         my $in_group = 0; # start out outside a group
500         my($m, @params); # scratch
501
502         my $string_to_compile = $_[1]; # There are taint issues using regex on @_ - perlbug 60378,27344
503         while($string_to_compile =~  # Iterate over chunks.
504             m/\G(
505                 [^\~\[\]]+  # non-~[] stuff
506                 |
507                 ~.       # ~[, ~], ~~, ~other
508                 |
509                 \[          # [ presumably opening a group
510                 |
511                 \]          # ] presumably closing a group
512                 |
513                 ~           # terminal ~ ?
514                 |
515                 $
516             )/xgs
517         ) {
518             DEBUG>2 and warn qq{  "$1"\n};
519
520             if($1 eq '[' or $1 eq '') {       # "[" or end
521                 # Whether this is "[" or end, force processing of any
522                 #  preceding literal.
523                 if($in_group) {
524                     if($1 eq '') {
525                         $target->_die_pointing($string_to_compile, 'Unterminated bracket group');
526                     }
527                     else {
528                         $target->_die_pointing($string_to_compile, 'You can\'t nest bracket groups');
529                     }
530                 }
531                 else {
532                     if ($1 eq '') {
533                         DEBUG>2 and warn "   [end-string]\n";
534                     }
535                     else {
536                         $in_group = 1;
537                     }
538                     die "How come \@c is empty?? in <$string_to_compile>" unless @c; # sanity
539                     if(length $c[-1]) {
540                         # Now actually processing the preceding literal
541                         $big_pile .= $c[-1];
542                         if($USE_LITERALS and (
543                                 (ord('A') == 65)
544                                 ? $c[-1] !~ m/[^\x20-\x7E]/s
545                                 # ASCII very safe chars
546                                 : $c[-1] !~ m/[^ !"\#\$%&'()*+,\-.\/0-9:;<=>?\@A-Z[\\\]^_`a-z{|}~\x07]/s
547                                 # EBCDIC very safe chars
548                             )) {
549                             # normal case -- all very safe chars
550                             $c[-1] =~ s/'/\\'/g;
551                             push @code, q{ '} . $c[-1] . "',\n";
552                             $c[-1] = ''; # reuse this slot
553                         }
554                         else {
555                             push @code, ' $c[' . $#c . "],\n";
556                             push @c, ''; # new chunk
557                         }
558                     }
559                     # else just ignore the empty string.
560                 }
561
562             }
563             elsif($1 eq ']') {  # "]"
564                 # close group -- go back in-band
565                 if($in_group) {
566                     $in_group = 0;
567
568                     DEBUG>2 and warn "   --Closing group [$c[-1]]\n";
569
570                     # And now process the group...
571
572                     if(!length($c[-1]) or $c[-1] =~ m/^\s+$/s) {
573                         DEBUG>2 and warn "   -- (Ignoring)\n";
574                         $c[-1] = ''; # reset out chink
575                         next;
576                     }
577
578                     #$c[-1] =~ s/^\s+//s;
579                     #$c[-1] =~ s/\s+$//s;
580                     ($m,@params) = split(/,/, $c[-1], -1);  # was /\s*,\s*/
581
582                     # A bit of a hack -- we've turned "~,"'s into DELs, so turn
583                     #  'em into real commas here.
584                     if (ord('A') == 65) { # ASCII, etc
585                         foreach($m, @params) { tr/\x7F/,/ }
586                     }
587                     else {              # EBCDIC (1047, 0037, POSIX-BC)
588                         # Thanks to Peter Prymmer for the EBCDIC handling
589                         foreach($m, @params) { tr/\x07/,/ }
590                     }
591
592                     # Special-case handling of some method names:
593                     if($m eq '_*' or $m =~ m/^_(-?\d+)$/s) {
594                         # Treat [_1,...] as [,_1,...], etc.
595                         unshift @params, $m;
596                         $m = '';
597                     }
598                     elsif($m eq '*') {
599                         $m = 'quant'; # "*" for "times": "4 cars" is 4 times "cars"
600                     }
601                     elsif($m eq '#') {
602                         $m = 'numf';  # "#" for "number": [#,_1] for "the number _1"
603                     }
604
605                     # Most common case: a simple, legal-looking method name
606                     if($m eq '') {
607                         # 0-length method name means to just interpolate:
608                         push @code, ' (';
609                     }
610                     elsif($m =~ /^\w+(?:\:\:\w+)*$/s
611                             and $m !~ m/(?:^|\:)\d/s
612                         # exclude starting a (sub)package or symbol with a digit
613                     ) {
614                         # Yes, it even supports the demented (and undocumented?)
615                         #  $obj->Foo::bar(...) syntax.
616                         $target->_die_pointing(
617                             $string_to_compile, q{Can't use "SUPER::" in a bracket-group method},
618                             2 + length($c[-1])
619                         )
620                         if $m =~ m/^SUPER::/s;
621                         # Because for SUPER:: to work, we'd have to compile this into
622                         #  the right package, and that seems just not worth the bother,
623                         #  unless someone convinces me otherwise.
624
625                         push @code, ' $_[0]->' . $m . '(';
626                     }
627                     else {
628                         # TODO: implement something?  or just too icky to consider?
629                         $target->_die_pointing(
630                             $string_to_compile,
631                             "Can't use \"$m\" as a method name in bracket group",
632                             2 + length($c[-1])
633                         );
634                     }
635
636                     pop @c; # we don't need that chunk anymore
637                     ++$call_count;
638
639                     foreach my $p (@params) {
640                         if($p eq '_*') {
641                             # Meaning: all parameters except $_[0]
642                             $code[-1] .= ' @_[1 .. $#_], ';
643                             # and yes, that does the right thing for all @_ < 3
644                         }
645                         elsif($p =~ m/^_(-?\d+)$/s) {
646                             # _3 meaning $_[3]
647                             $code[-1] .= '$_[' . (0 + $1) . '], ';
648                         }
649                         elsif($USE_LITERALS and (
650                                 (ord('A') == 65)
651                                 ? $p !~ m/[^\x20-\x7E]/s
652                                 # ASCII very safe chars
653                                 : $p !~ m/[^ !"\#\$%&'()*+,\-.\/0-9:;<=>?\@A-Z[\\\]^_`a-z{|}~\x07]/s
654                                 # EBCDIC very safe chars
655                             )) {
656                             # Normal case: a literal containing only safe characters
657                             $p =~ s/'/\\'/g;
658                             $code[-1] .= q{'} . $p . q{', };
659                         }
660                         else {
661                             # Stow it on the chunk-stack, and just refer to that.
662                             push @c, $p;
663                             push @code, ' $c[' . $#c . '], ';
664                         }
665                     }
666                     $code[-1] .= "),\n";
667
668                     push @c, '';
669                 }
670                 else {
671                     $target->_die_pointing($string_to_compile, q{Unbalanced ']'});
672                 }
673
674             }
675             elsif(substr($1,0,1) ne '~') {
676                 # it's stuff not containing "~" or "[" or "]"
677                 # i.e., a literal blob
678                 $c[-1] .= $1;
679
680             }
681             elsif($1 eq '~~') { # "~~"
682                 $c[-1] .= '~';
683
684             }
685             elsif($1 eq '~[') { # "~["
686                 $c[-1] .= '[';
687
688             }
689             elsif($1 eq '~]') { # "~]"
690                 $c[-1] .= ']';
691
692             }
693             elsif($1 eq '~,') { # "~,"
694                 if($in_group) {
695                     # This is a hack, based on the assumption that no-one will actually
696                     # want a DEL inside a bracket group.  Let's hope that's it's true.
697                     if (ord('A') == 65) { # ASCII etc
698                         $c[-1] .= "\x7F";
699                     }
700                     else {              # EBCDIC (cp 1047, 0037, POSIX-BC)
701                         $c[-1] .= "\x07";
702                     }
703                 }
704                 else {
705                     $c[-1] .= '~,';
706                 }
707
708             }
709             elsif($1 eq '~') { # possible only at string-end, it seems.
710                 $c[-1] .= '~';
711
712             }
713             else {
714                 # It's a "~X" where X is not a special character.
715                 # Consider it a literal ~ and X.
716                 $c[-1] .= $1;
717             }
718         }
719     }
720
721     if($call_count) {
722         undef $big_pile; # Well, nevermind that.
723     }
724     else {
725         # It's all literals!  Ahwell, that can happen.
726         # So don't bother with the eval.  Return a SCALAR reference.
727         return \$big_pile;
728     }
729
730     die q{Last chunk isn't null??} if @c and length $c[-1]; # sanity
731     DEBUG and warn scalar(@c), " chunks under closure\n";
732     if(@code == 0) { # not possible?
733         DEBUG and warn "Empty code\n";
734         return \'';
735     }
736     elsif(@code > 1) { # most cases, presumably!
737         unshift @code, "join '',\n";
738     }
739     unshift @code, "use strict; sub {\n";
740     push @code, "}\n";
741
742     DEBUG and warn @code;
743     my $sub = eval(join '', @code);
744     die "$@ while evalling" . join('', @code) if $@; # Should be impossible.
745     return $sub;
746 }
747
748 #--------------------------------------------------------------------------
749
750 sub _die_pointing {
751     # This is used by _compile to throw a fatal error
752     my $target = shift; # class name
753     # ...leaving $_[0] the error-causing text, and $_[1] the error message
754
755     my $i = index($_[0], "\n");
756
757     my $pointy;
758     my $pos = pos($_[0]) - (defined($_[2]) ? $_[2] : 0) - 1;
759     if($pos < 1) {
760         $pointy = "^=== near there\n";
761     }
762     else { # we need to space over
763         my $first_tab = index($_[0], "\t");
764         if($pos > 2 and ( -1 == $first_tab  or  $first_tab > pos($_[0]))) {
765             # No tabs, or the first tab is harmlessly after where we will point to,
766             # AND we're far enough from the margin that we can draw a proper arrow.
767             $pointy = ('=' x $pos) . "^ near there\n";
768         }
769         else {
770             # tabs screw everything up!
771             $pointy = substr($_[0],0,$pos);
772             $pointy =~ tr/\t //cd;
773             # make everything into whitespace, but preseving tabs
774             $pointy .= "^=== near there\n";
775         }
776     }
777
778     my $errmsg = "$_[1], in\:\n$_[0]";
779
780     if($i == -1) {
781         # No newline.
782         $errmsg .= "\n" . $pointy;
783     }
784     elsif($i == (length($_[0]) - 1)  ) {
785         # Already has a newline at end.
786         $errmsg .= $pointy;
787     }
788     else {
789         # don't bother with the pointy bit, I guess.
790     }
791     Carp::croak( "$errmsg via $target, as used" );
792 }
793
794 1;