This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Add thread-safe locale handling
[perl5.git] / pod / perlvar.pod
1 =head1 NAME
2
3 perlvar - Perl predefined variables
4
5 =head1 DESCRIPTION
6
7 =head2 The Syntax of Variable Names
8
9 Variable names in Perl can have several formats.  Usually, they
10 must begin with a letter or underscore, in which case they can be
11 arbitrarily long (up to an internal limit of 251 characters) and
12 may contain letters, digits, underscores, or the special sequence
13 C<::> or C<'>.  In this case, the part before the last C<::> or
14 C<'> is taken to be a I<package qualifier>; see L<perlmod>.
15 A Unicode letter that is not ASCII is not considered to be a letter
16 unless S<C<"use utf8">> is in effect, and somewhat more complicated
17 rules apply; see L<perldata/Identifier parsing> for details.
18
19 Perl variable names may also be a sequence of digits, a single
20 punctuation character, or the two-character sequence: C<^> (caret or
21 CIRCUMFLEX ACCENT) followed by any one of the characters C<[][A-Z^_?\]>.
22 These names are all reserved for
23 special uses by Perl; for example, the all-digits names are used
24 to hold data captured by backreferences after a regular expression
25 match.
26
27 Since Perl v5.6.0, Perl variable names may also be alphanumeric strings
28 preceded by a caret.  These must all be written in the form C<${^Foo}>;
29 the braces are not optional.  C<${^Foo}> denotes the scalar variable
30 whose name is considered to be a control-C<F> followed by two C<o>'s.
31 These variables are
32 reserved for future special uses by Perl, except for the ones that
33 begin with C<^_> (caret-underscore).  No
34 name that begins with C<^_> will acquire a special
35 meaning in any future version of Perl; such names may therefore be
36 used safely in programs.  C<$^_> itself, however, I<is> reserved.
37
38 Perl identifiers that begin with digits or
39 punctuation characters are exempt from the effects of the C<package>
40 declaration and are always forced to be in package C<main>; they are
41 also exempt from C<strict 'vars'> errors.  A few other names are also
42 exempt in these ways:
43
44     ENV      STDIN
45     INC      STDOUT
46     ARGV     STDERR
47     ARGVOUT
48     SIG
49
50 In particular, the special C<${^_XYZ}> variables are always taken
51 to be in package C<main>, regardless of any C<package> declarations
52 presently in scope.
53
54 =head1 SPECIAL VARIABLES
55
56 The following names have special meaning to Perl.  Most punctuation
57 names have reasonable mnemonics, or analogs in the shells.
58 Nevertheless, if you wish to use long variable names, you need only say:
59
60     use English;
61
62 at the top of your program.  This aliases all the short names to the long
63 names in the current package.  Some even have medium names, generally
64 borrowed from B<awk>.  For more info, please see L<English>.
65
66 Before you continue, note the sort order for variables.  In general, we
67 first list the variables in case-insensitive, almost-lexigraphical
68 order (ignoring the C<{> or C<^> preceding words, as in C<${^UNICODE}>
69 or C<$^T>), although C<$_> and C<@_> move up to the top of the pile.
70 For variables with the same identifier, we list it in order of scalar,
71 array, hash, and bareword.
72
73 =head2 General Variables
74
75 =over 8
76
77 =item $ARG
78
79 =item $_
80 X<$_> X<$ARG>
81
82 The default input and pattern-searching space.  The following pairs are
83 equivalent:
84
85     while (<>) {...}    # equivalent only in while!
86     while (defined($_ = <>)) {...}
87
88     /^Subject:/
89     $_ =~ /^Subject:/
90
91     tr/a-z/A-Z/
92     $_ =~ tr/a-z/A-Z/
93
94     chomp
95     chomp($_)
96
97 Here are the places where Perl will assume C<$_> even if you don't use it:
98
99 =over 3
100
101 =item *
102
103 The following functions use C<$_> as a default argument:
104
105 abs, alarm, chomp, chop, chr, chroot,
106 cos, defined, eval, evalbytes, exp, fc, glob, hex, int, lc,
107 lcfirst, length, log, lstat, mkdir, oct, ord, pos, print, printf,
108 quotemeta, readlink, readpipe, ref, require, reverse (in scalar context only),
109 rmdir, say, sin, split (for its second
110 argument), sqrt, stat, study, uc, ucfirst,
111 unlink, unpack.
112
113 =item *
114
115 All file tests (C<-f>, C<-d>) except for C<-t>, which defaults to STDIN.
116 See L<perlfunc/-X>
117
118 =item *
119
120 The pattern matching operations C<m//>, C<s///> and C<tr///> (aka C<y///>)
121 when used without an C<=~> operator.
122
123 =item *
124
125 The default iterator variable in a C<foreach> loop if no other
126 variable is supplied.
127
128 =item *
129
130 The implicit iterator variable in the C<grep()> and C<map()> functions.
131
132 =item *
133
134 The implicit variable of C<given()>.
135
136 =item *
137
138 The default place to put the next value or input record
139 when a C<< <FH> >>, C<readline>, C<readdir> or C<each>
140 operation's result is tested by itself as the sole criterion of a C<while>
141 test.  Outside a C<while> test, this will not happen.
142
143 =back
144
145 C<$_> is by default a global variable.  However, as
146 of perl v5.10.0, you can use a lexical version of
147 C<$_> by declaring it in a file or in a block with C<my>.  Moreover,
148 declaring C<our $_> restores the global C<$_> in the current scope.  Though
149 this seemed like a good idea at the time it was introduced, lexical C<$_>
150 actually causes more problems than it solves.  If you call a function that
151 expects to be passed information via C<$_>, it may or may not work,
152 depending on how the function is written, there not being any easy way to
153 solve this.  Just avoid lexical C<$_>, unless you are feeling particularly
154 masochistic.  For this reason lexical C<$_> is still experimental and will
155 produce a warning unless warnings have been disabled.  As with other
156 experimental features, the behavior of lexical C<$_> is subject to change
157 without notice, including change into a fatal error.
158
159 Mnemonic: underline is understood in certain operations.
160
161 =item @ARG
162
163 =item @_
164 X<@_> X<@ARG>
165
166 Within a subroutine the array C<@_> contains the parameters passed to
167 that subroutine.  Inside a subroutine, C<@_> is the default array for
168 the array operators C<pop> and C<shift>.
169
170 See L<perlsub>.
171
172 =item $LIST_SEPARATOR
173
174 =item $"
175 X<$"> X<$LIST_SEPARATOR>
176
177 When an array or an array slice is interpolated into a double-quoted
178 string or a similar context such as C</.../>, its elements are
179 separated by this value.  Default is a space.  For example, this:
180
181     print "The array is: @array\n";
182
183 is equivalent to this:
184
185     print "The array is: " . join($", @array) . "\n";
186
187 Mnemonic: works in double-quoted context.
188
189 =item $PROCESS_ID
190
191 =item $PID
192
193 =item $$
194 X<$$> X<$PID> X<$PROCESS_ID>
195
196 The process number of the Perl running this script.  Though you I<can> set
197 this variable, doing so is generally discouraged, although it can be
198 invaluable for some testing purposes.  It will be reset automatically
199 across C<fork()> calls.
200
201 Note for Linux and Debian GNU/kFreeBSD users: Before Perl v5.16.0 perl
202 would emulate POSIX semantics on Linux systems using LinuxThreads, a
203 partial implementation of POSIX Threads that has since been superseded
204 by the Native POSIX Thread Library (NPTL).
205
206 LinuxThreads is now obsolete on Linux, and caching C<getpid()>
207 like this made embedding perl unnecessarily complex (since you'd have
208 to manually update the value of $$), so now C<$$> and C<getppid()>
209 will always return the same values as the underlying C library.
210
211 Debian GNU/kFreeBSD systems also used LinuxThreads up until and
212 including the 6.0 release, but after that moved to FreeBSD thread
213 semantics, which are POSIX-like.
214
215 To see if your system is affected by this discrepancy check if
216 C<getconf GNU_LIBPTHREAD_VERSION | grep -q NPTL> returns a false
217 value.  NTPL threads preserve the POSIX semantics.
218
219 Mnemonic: same as shells.
220
221 =item $PROGRAM_NAME
222
223 =item $0
224 X<$0> X<$PROGRAM_NAME>
225
226 Contains the name of the program being executed.
227
228 On some (but not all) operating systems assigning to C<$0> modifies
229 the argument area that the C<ps> program sees.  On some platforms you
230 may have to use special C<ps> options or a different C<ps> to see the
231 changes.  Modifying the C<$0> is more useful as a way of indicating the
232 current program state than it is for hiding the program you're
233 running.
234
235 Note that there are platform-specific limitations on the maximum
236 length of C<$0>.  In the most extreme case it may be limited to the
237 space occupied by the original C<$0>.
238
239 In some platforms there may be arbitrary amount of padding, for
240 example space characters, after the modified name as shown by C<ps>.
241 In some platforms this padding may extend all the way to the original
242 length of the argument area, no matter what you do (this is the case
243 for example with Linux 2.2).
244
245 Note for BSD users: setting C<$0> does not completely remove "perl"
246 from the ps(1) output.  For example, setting C<$0> to C<"foobar"> may
247 result in C<"perl: foobar (perl)"> (whether both the C<"perl: "> prefix
248 and the " (perl)" suffix are shown depends on your exact BSD variant
249 and version).  This is an operating system feature, Perl cannot help it.
250
251 In multithreaded scripts Perl coordinates the threads so that any
252 thread may modify its copy of the C<$0> and the change becomes visible
253 to ps(1) (assuming the operating system plays along).  Note that
254 the view of C<$0> the other threads have will not change since they
255 have their own copies of it.
256
257 If the program has been given to perl via the switches C<-e> or C<-E>,
258 C<$0> will contain the string C<"-e">.
259
260 On Linux as of perl v5.14.0 the legacy process name will be set with
261 C<prctl(2)>, in addition to altering the POSIX name via C<argv[0]> as
262 perl has done since version 4.000.  Now system utilities that read the
263 legacy process name such as ps, top and killall will recognize the
264 name you set when assigning to C<$0>.  The string you supply will be
265 cut off at 16 bytes, this is a limitation imposed by Linux.
266
267 Mnemonic: same as B<sh> and B<ksh>.
268
269 =item $REAL_GROUP_ID
270
271 =item $GID
272
273 =item $(
274 X<$(> X<$GID> X<$REAL_GROUP_ID>
275
276 The real gid of this process.  If you are on a machine that supports
277 membership in multiple groups simultaneously, gives a space separated
278 list of groups you are in.  The first number is the one returned by
279 C<getgid()>, and the subsequent ones by C<getgroups()>, one of which may be
280 the same as the first number.
281
282 However, a value assigned to C<$(> must be a single number used to
283 set the real gid.  So the value given by C<$(> should I<not> be assigned
284 back to C<$(> without being forced numeric, such as by adding zero.  Note
285 that this is different to the effective gid (C<$)>) which does take a
286 list.
287
288 You can change both the real gid and the effective gid at the same
289 time by using C<POSIX::setgid()>.  Changes
290 to C<$(> require a check to C<$!>
291 to detect any possible errors after an attempted change.
292
293 Mnemonic: parentheses are used to I<group> things.  The real gid is the
294 group you I<left>, if you're running setgid.
295
296 =item $EFFECTIVE_GROUP_ID
297
298 =item $EGID
299
300 =item $)
301 X<$)> X<$EGID> X<$EFFECTIVE_GROUP_ID>
302
303 The effective gid of this process.  If you are on a machine that
304 supports membership in multiple groups simultaneously, gives a space
305 separated list of groups you are in.  The first number is the one
306 returned by C<getegid()>, and the subsequent ones by C<getgroups()>,
307 one of which may be the same as the first number.
308
309 Similarly, a value assigned to C<$)> must also be a space-separated
310 list of numbers.  The first number sets the effective gid, and
311 the rest (if any) are passed to C<setgroups()>.  To get the effect of an
312 empty list for C<setgroups()>, just repeat the new effective gid; that is,
313 to force an effective gid of 5 and an effectively empty C<setgroups()>
314 list, say C< $) = "5 5" >.
315
316 You can change both the effective gid and the real gid at the same
317 time by using C<POSIX::setgid()> (use only a single numeric argument).
318 Changes to C<$)> require a check to C<$!> to detect any possible errors
319 after an attempted change.
320
321 C<< $< >>, C<< $> >>, C<$(> and C<$)> can be set only on
322 machines that support the corresponding I<set[re][ug]id()> routine.  C<$(>
323 and C<$)> can be swapped only on machines supporting C<setregid()>.
324
325 Mnemonic: parentheses are used to I<group> things.  The effective gid
326 is the group that's I<right> for you, if you're running setgid.
327
328 =item $REAL_USER_ID
329
330 =item $UID
331
332 =item $<
333 X<< $< >> X<$UID> X<$REAL_USER_ID>
334
335 The real uid of this process.  You can change both the real uid and the
336 effective uid at the same time by using C<POSIX::setuid()>.  Since
337 changes to C<< $< >> require a system call, check C<$!> after a change
338 attempt to detect any possible errors.
339
340 Mnemonic: it's the uid you came I<from>, if you're running setuid.
341
342 =item $EFFECTIVE_USER_ID
343
344 =item $EUID
345
346 =item $>
347 X<< $> >> X<$EUID> X<$EFFECTIVE_USER_ID>
348
349 The effective uid of this process.  For example:
350
351     $< = $>;            # set real to effective uid
352     ($<,$>) = ($>,$<);  # swap real and effective uids
353
354 You can change both the effective uid and the real uid at the same
355 time by using C<POSIX::setuid()>.  Changes to C<< $> >> require a check
356 to C<$!> to detect any possible errors after an attempted change.
357
358 C<< $< >> and C<< $> >> can be swapped only on machines
359 supporting C<setreuid()>.
360
361 Mnemonic: it's the uid you went I<to>, if you're running setuid.
362
363 =item $SUBSCRIPT_SEPARATOR
364
365 =item $SUBSEP
366
367 =item $;
368 X<$;> X<$SUBSEP> X<SUBSCRIPT_SEPARATOR>
369
370 The subscript separator for multidimensional array emulation.  If you
371 refer to a hash element as
372
373     $foo{$x,$y,$z}
374
375 it really means
376
377     $foo{join($;, $x, $y, $z)}
378
379 But don't put
380
381     @foo{$x,$y,$z}      # a slice--note the @
382
383 which means
384
385     ($foo{$x},$foo{$y},$foo{$z})
386
387 Default is "\034", the same as SUBSEP in B<awk>.  If your keys contain
388 binary data there might not be any safe value for C<$;>.
389
390 Consider using "real" multidimensional arrays as described
391 in L<perllol>.
392
393 Mnemonic: comma (the syntactic subscript separator) is a semi-semicolon.
394
395 =item $a
396
397 =item $b
398 X<$a> X<$b>
399
400 Special package variables when using C<sort()>, see L<perlfunc/sort>.
401 Because of this specialness C<$a> and C<$b> don't need to be declared
402 (using C<use vars>, or C<our()>) even when using the C<strict 'vars'>
403 pragma.  Don't lexicalize them with C<my $a> or C<my $b> if you want to
404 be able to use them in the C<sort()> comparison block or function.
405
406 =item %ENV
407 X<%ENV>
408
409 The hash C<%ENV> contains your current environment.  Setting a
410 value in C<ENV> changes the environment for any child processes
411 you subsequently C<fork()> off.
412
413 As of v5.18.0, both keys and values stored in C<%ENV> are stringified.
414
415     my $foo = 1;
416     $ENV{'bar'} = \$foo;
417     if( ref $ENV{'bar'} ) {
418         say "Pre 5.18.0 Behaviour";
419     } else {
420         say "Post 5.18.0 Behaviour";
421     }
422
423 Previously, only child processes received stringified values:
424
425     my $foo = 1;
426     $ENV{'bar'} = \$foo;
427
428     # Always printed 'non ref'
429     system($^X, '-e',
430            q/print ( ref $ENV{'bar'}  ? 'ref' : 'non ref' ) /);
431
432 This happens because you can't really share arbitrary data structures with
433 foreign processes.
434
435 =item $OLD_PERL_VERSION
436
437 =item $]
438 X<$]> X<$OLD_PERL_VERSION>
439
440 The revision, version, and subversion of the Perl interpreter, represented
441 as a decimal of the form 5.XXXYYY, where XXX is the version / 1e3 and YYY
442 is the subversion / 1e6.  For example, Perl v5.10.1 would be "5.010001".
443
444 This variable can be used to determine whether the Perl interpreter
445 executing a script is in the right range of versions:
446
447     warn "No PerlIO!\n" if $] lt '5.008';
448
449 When comparing C<$]>, string comparison operators are B<highly
450 recommended>.  The inherent limitations of binary floating point
451 representation can sometimes lead to incorrect comparisons for some
452 numbers on some architectures.
453
454 See also the documentation of C<use VERSION> and C<require VERSION>
455 for a convenient way to fail if the running Perl interpreter is too old.
456
457 See L</$^V> for a representation of the Perl version as a L<version>
458 object, which allows more flexible string comparisons.
459
460 The main advantage of C<$]> over C<$^V> is that it works the same on any
461 version of Perl.  The disadvantages are that it can't easily be compared
462 to versions in other formats (e.g. literal v-strings, "v1.2.3" or
463 version objects) and numeric comparisons can occasionally fail; it's good
464 for string literal version checks and bad for comparing to a variable
465 that hasn't been sanity-checked.
466
467 The C<$OLD_PERL_VERSION> form was added in Perl v5.20.0 for historical
468 reasons but its use is discouraged. (If your reason to use C<$]> is to
469 run code on old perls then referring to it as C<$OLD_PERL_VERSION> would
470 be self-defeating.)
471
472 Mnemonic: Is this version of perl in the right bracket?
473
474 =item $SYSTEM_FD_MAX
475
476 =item $^F
477 X<$^F> X<$SYSTEM_FD_MAX>
478
479 The maximum system file descriptor, ordinarily 2.  System file
480 descriptors are passed to C<exec()>ed processes, while higher file
481 descriptors are not.  Also, during an
482 C<open()>, system file descriptors are
483 preserved even if the C<open()> fails (ordinary file descriptors are
484 closed before the C<open()> is attempted).  The close-on-exec
485 status of a file descriptor will be decided according to the value of
486 C<$^F> when the corresponding file, pipe, or socket was opened, not the
487 time of the C<exec()>.
488
489 =item @F
490 X<@F>
491
492 The array C<@F> contains the fields of each line read in when autosplit
493 mode is turned on.  See L<perlrun> for the B<-a> switch.  This array
494 is package-specific, and must be declared or given a full package name
495 if not in package main when running under C<strict 'vars'>.
496
497 =item @INC
498 X<@INC>
499
500 The array C<@INC> contains the list of places that the C<do EXPR>,
501 C<require>, or C<use> constructs look for their library files.  It
502 initially consists of the arguments to any B<-I> command-line
503 switches, followed by the default Perl library, probably
504 F</usr/local/lib/perl>, followed by ".", to represent the current
505 directory.  ("." will not be appended if taint checks are enabled,
506 either by C<-T> or by C<-t>, or if configured not to do so by the
507 C<-Ddefault_inc_excludes_dot> compile time option.)  If you need to
508 modify this at runtime, you should use the C<use lib> pragma to get
509 the machine-dependent library properly loaded also:
510
511     use lib '/mypath/libdir/';
512     use SomeMod;
513
514 You can also insert hooks into the file inclusion system by putting Perl
515 code directly into C<@INC>.  Those hooks may be subroutine references,
516 array references or blessed objects.  See L<perlfunc/require> for details.
517
518 =item %INC
519 X<%INC>
520
521 The hash C<%INC> contains entries for each filename included via the
522 C<do>, C<require>, or C<use> operators.  The key is the filename
523 you specified (with module names converted to pathnames), and the
524 value is the location of the file found.  The C<require>
525 operator uses this hash to determine whether a particular file has
526 already been included.
527
528 If the file was loaded via a hook (e.g. a subroutine reference, see
529 L<perlfunc/require> for a description of these hooks), this hook is
530 by default inserted into C<%INC> in place of a filename.  Note, however,
531 that the hook may have set the C<%INC> entry by itself to provide some more
532 specific info.
533
534 =item $INPLACE_EDIT
535
536 =item $^I
537 X<$^I> X<$INPLACE_EDIT>
538
539 The current value of the inplace-edit extension.  Use C<undef> to disable
540 inplace editing.
541
542 Mnemonic: value of B<-i> switch.
543
544 =item @ISA
545 X<@ISA>
546
547 Each package contains a special array called C<@ISA> which contains a list
548 of that class's parent classes, if any. This array is simply a list of
549 scalars, each of which is a string that corresponds to a package name. The
550 array is examined when Perl does method resolution, which is covered in
551 L<perlobj>.
552
553 To load packages while adding them to C<@ISA>, see the L<parent> pragma. The
554 discouraged L<base> pragma does this as well, but should not be used except
555 when compatibility with the discouraged L<fields> pragma is required.
556
557 =item $^M
558 X<$^M>
559
560 By default, running out of memory is an untrappable, fatal error.
561 However, if suitably built, Perl can use the contents of C<$^M>
562 as an emergency memory pool after C<die()>ing.  Suppose that your Perl
563 were compiled with C<-DPERL_EMERGENCY_SBRK> and used Perl's malloc.
564 Then
565
566     $^M = 'a' x (1 << 16);
567
568 would allocate a 64K buffer for use in an emergency.  See the
569 F<INSTALL> file in the Perl distribution for information on how to
570 add custom C compilation flags when compiling perl.  To discourage casual
571 use of this advanced feature, there is no L<English|English> long name for
572 this variable.
573
574 This variable was added in Perl 5.004.
575
576 =item $OSNAME
577
578 =item $^O
579 X<$^O> X<$OSNAME>
580
581 The name of the operating system under which this copy of Perl was
582 built, as determined during the configuration process.  For examples
583 see L<perlport/PLATFORMS>.
584
585 The value is identical to C<$Config{'osname'}>.  See also L<Config>
586 and the B<-V> command-line switch documented in L<perlrun>.
587
588 In Windows platforms, C<$^O> is not very helpful: since it is always
589 C<MSWin32>, it doesn't tell the difference between
590 95/98/ME/NT/2000/XP/CE/.NET.  Use C<Win32::GetOSName()> or
591 Win32::GetOSVersion() (see L<Win32> and L<perlport>) to distinguish
592 between the variants.
593
594 This variable was added in Perl 5.003.
595
596 =item %SIG
597 X<%SIG>
598
599 The hash C<%SIG> contains signal handlers for signals.  For example:
600
601     sub handler {   # 1st argument is signal name
602         my($sig) = @_;
603         print "Caught a SIG$sig--shutting down\n";
604         close(LOG);
605         exit(0);
606         }
607
608     $SIG{'INT'}  = \&handler;
609     $SIG{'QUIT'} = \&handler;
610     ...
611     $SIG{'INT'}  = 'DEFAULT';   # restore default action
612     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
613
614 Using a value of C<'IGNORE'> usually has the effect of ignoring the
615 signal, except for the C<CHLD> signal.  See L<perlipc> for more about
616 this special case.
617
618 Here are some other examples:
619
620     $SIG{"PIPE"} = "Plumber";   # assumes main::Plumber (not
621                                 # recommended)
622     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current
623                                 # Plumber
624     $SIG{"PIPE"} = *Plumber;    # somewhat esoteric
625     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber()
626                                 # return??
627
628 Be sure not to use a bareword as the name of a signal handler,
629 lest you inadvertently call it.
630
631 If your system has the C<sigaction()> function then signal handlers
632 are installed using it.  This means you get reliable signal handling.
633
634 The default delivery policy of signals changed in Perl v5.8.0 from
635 immediate (also known as "unsafe") to deferred, also known as "safe
636 signals".  See L<perlipc> for more information.
637
638 Certain internal hooks can be also set using the C<%SIG> hash.  The
639 routine indicated by C<$SIG{__WARN__}> is called when a warning
640 message is about to be printed.  The warning message is passed as the
641 first argument.  The presence of a C<__WARN__> hook causes the
642 ordinary printing of warnings to C<STDERR> to be suppressed.  You can
643 use this to save warnings in a variable, or turn warnings into fatal
644 errors, like this:
645
646     local $SIG{__WARN__} = sub { die $_[0] };
647     eval $proggie;
648
649 As the C<'IGNORE'> hook is not supported by C<__WARN__>, you can
650 disable warnings using the empty subroutine:
651
652     local $SIG{__WARN__} = sub {};
653
654 The routine indicated by C<$SIG{__DIE__}> is called when a fatal
655 exception is about to be thrown.  The error message is passed as the
656 first argument.  When a C<__DIE__> hook routine returns, the exception
657 processing continues as it would have in the absence of the hook,
658 unless the hook routine itself exits via a C<goto &sub>, a loop exit,
659 or a C<die()>.  The C<__DIE__> handler is explicitly disabled during
660 the call, so that you can die from a C<__DIE__> handler.  Similarly
661 for C<__WARN__>.
662
663 The C<$SIG{__DIE__}> hook is called even inside an C<eval()>. It was
664 never intended to happen this way, but an implementation glitch made
665 this possible. This used to be deprecated, as it allowed strange action
666 at a distance like rewriting a pending exception in C<$@>. Plans to
667 rectify this have been scrapped, as users found that rewriting a 
668 pending exception is actually a useful feature, and not a bug.
669
670 C<__DIE__>/C<__WARN__> handlers are very special in one respect: they
671 may be called to report (probable) errors found by the parser.  In such
672 a case the parser may be in inconsistent state, so any attempt to
673 evaluate Perl code from such a handler will probably result in a
674 segfault.  This means that warnings or errors that result from parsing
675 Perl should be used with extreme caution, like this:
676
677     require Carp if defined $^S;
678     Carp::confess("Something wrong") if defined &Carp::confess;
679     die "Something wrong, but could not load Carp to give "
680       . "backtrace...\n\t"
681       . "To see backtrace try starting Perl with -MCarp switch";
682
683 Here the first line will load C<Carp> I<unless> it is the parser who
684 called the handler.  The second line will print backtrace and die if
685 C<Carp> was available.  The third line will be executed only if C<Carp> was
686 not available.
687
688 Having to even think about the C<$^S> variable in your exception
689 handlers is simply wrong.  C<$SIG{__DIE__}> as currently implemented
690 invites grievous and difficult to track down errors.  Avoid it
691 and use an C<END{}> or CORE::GLOBAL::die override instead.
692
693 See L<perlfunc/die>, L<perlfunc/warn>, L<perlfunc/eval>, and
694 L<warnings> for additional information.
695
696 =item $BASETIME
697
698 =item $^T
699 X<$^T> X<$BASETIME>
700
701 The time at which the program began running, in seconds since the
702 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>,
703 and B<-C> filetests are based on this value.
704
705 =item $PERL_VERSION
706
707 =item $^V
708 X<$^V> X<$PERL_VERSION>
709
710 The revision, version, and subversion of the Perl interpreter,
711 represented as a L<version> object.
712
713 This variable first appeared in perl v5.6.0; earlier versions of perl
714 will see an undefined value.  Before perl v5.10.0 C<$^V> was represented
715 as a v-string rather than a L<version> object.
716
717 C<$^V> can be used to determine whether the Perl interpreter executing
718 a script is in the right range of versions.  For example:
719
720     warn "Hashes not randomized!\n" if !$^V or $^V lt v5.8.1
721
722 While version objects overload stringification, to portably convert
723 C<$^V> into its string representation, use C<sprintf()>'s C<"%vd">
724 conversion, which works for both v-strings or version objects:
725
726     printf "version is v%vd\n", $^V;  # Perl's version
727
728 See the documentation of C<use VERSION> and C<require VERSION>
729 for a convenient way to fail if the running Perl interpreter is too old.
730
731 See also C<L</$]>> for a decimal representation of the Perl version.
732
733 The main advantage of C<$^V> over C<$]> is that, for Perl v5.10.0 or
734 later, it overloads operators, allowing easy comparison against other
735 version representations (e.g. decimal, literal v-string, "v1.2.3", or
736 objects).  The disadvantage is that prior to v5.10.0, it was only a
737 literal v-string, which can't be easily printed or compared, whereas
738 the behavior of C<$]> is unchanged on all versions of Perl.
739
740 Mnemonic: use ^V for a version object.
741
742 =item ${^WIN32_SLOPPY_STAT}
743 X<${^WIN32_SLOPPY_STAT}> X<sitecustomize> X<sitecustomize.pl>
744
745 If this variable is set to a true value, then C<stat()> on Windows will
746 not try to open the file.  This means that the link count cannot be
747 determined and file attributes may be out of date if additional
748 hardlinks to the file exist.  On the other hand, not opening the file
749 is considerably faster, especially for files on network drives.
750
751 This variable could be set in the F<sitecustomize.pl> file to
752 configure the local Perl installation to use "sloppy" C<stat()> by
753 default.  See the documentation for B<-f> in
754 L<perlrun|perlrun/"Command Switches"> for more information about site
755 customization.
756
757 This variable was added in Perl v5.10.0.
758
759 =item $EXECUTABLE_NAME
760
761 =item $^X
762 X<$^X> X<$EXECUTABLE_NAME>
763
764 The name used to execute the current copy of Perl, from C's
765 C<argv[0]> or (where supported) F</proc/self/exe>.
766
767 Depending on the host operating system, the value of C<$^X> may be
768 a relative or absolute pathname of the perl program file, or may
769 be the string used to invoke perl but not the pathname of the
770 perl program file.  Also, most operating systems permit invoking
771 programs that are not in the PATH environment variable, so there
772 is no guarantee that the value of C<$^X> is in PATH.  For VMS, the
773 value may or may not include a version number.
774
775 You usually can use the value of C<$^X> to re-invoke an independent
776 copy of the same perl that is currently running, e.g.,
777
778     @first_run = `$^X -le "print int rand 100 for 1..100"`;
779
780 But recall that not all operating systems support forking or
781 capturing of the output of commands, so this complex statement
782 may not be portable.
783
784 It is not safe to use the value of C<$^X> as a path name of a file,
785 as some operating systems that have a mandatory suffix on
786 executable files do not require use of the suffix when invoking
787 a command.  To convert the value of C<$^X> to a path name, use the
788 following statements:
789
790     # Build up a set of file names (not command names).
791     use Config;
792     my $this_perl = $^X;
793     if ($^O ne 'VMS') {
794         $this_perl .= $Config{_exe}
795           unless $this_perl =~ m/$Config{_exe}$/i;
796         }
797
798 Because many operating systems permit anyone with read access to
799 the Perl program file to make a copy of it, patch the copy, and
800 then execute the copy, the security-conscious Perl programmer
801 should take care to invoke the installed copy of perl, not the
802 copy referenced by C<$^X>.  The following statements accomplish
803 this goal, and produce a pathname that can be invoked as a
804 command or referenced as a file.
805
806     use Config;
807     my $secure_perl_path = $Config{perlpath};
808     if ($^O ne 'VMS') {
809         $secure_perl_path .= $Config{_exe}
810             unless $secure_perl_path =~ m/$Config{_exe}$/i;
811         }
812
813 =back
814
815 =head2 Variables related to regular expressions
816
817 Most of the special variables related to regular expressions are side
818 effects.  Perl sets these variables when it has a successful match, so
819 you should check the match result before using them.  For instance:
820
821     if( /P(A)TT(ER)N/ ) {
822         print "I found $1 and $2\n";
823         }
824
825 These variables are read-only and dynamically-scoped, unless we note
826 otherwise.
827
828 The dynamic nature of the regular expression variables means that
829 their value is limited to the block that they are in, as demonstrated
830 by this bit of code:
831
832     my $outer = 'Wallace and Grommit';
833     my $inner = 'Mutt and Jeff';
834
835     my $pattern = qr/(\S+) and (\S+)/;
836
837     sub show_n { print "\$1 is $1; \$2 is $2\n" }
838
839     {
840     OUTER:
841         show_n() if $outer =~ m/$pattern/;
842
843         INNER: {
844             show_n() if $inner =~ m/$pattern/;
845             }
846
847         show_n();
848     }
849
850 The output shows that while in the C<OUTER> block, the values of C<$1>
851 and C<$2> are from the match against C<$outer>.  Inside the C<INNER>
852 block, the values of C<$1> and C<$2> are from the match against
853 C<$inner>, but only until the end of the block (i.e. the dynamic
854 scope).  After the C<INNER> block completes, the values of C<$1> and
855 C<$2> return to the values for the match against C<$outer> even though
856 we have not made another match:
857
858     $1 is Wallace; $2 is Grommit
859     $1 is Mutt; $2 is Jeff
860     $1 is Wallace; $2 is Grommit
861
862 =head3 Performance issues
863
864 Traditionally in Perl, any use of any of the three variables  C<$`>, C<$&>
865 or C<$'> (or their C<use English> equivalents) anywhere in the code, caused
866 all subsequent successful pattern matches to make a copy of the matched
867 string, in case the code might subsequently access one of those variables.
868 This imposed a considerable performance penalty across the whole program,
869 so generally the use of these variables has been discouraged.
870
871 In Perl 5.6.0 the C<@-> and C<@+> dynamic arrays were introduced that
872 supply the indices of successful matches. So you could for example do
873 this:
874
875     $str =~ /pattern/;
876
877     print $`, $&, $'; # bad: perfomance hit
878
879     print             # good: no perfomance hit
880         substr($str, 0,     $-[0]),
881         substr($str, $-[0], $+[0]-$-[0]),
882         substr($str, $+[0]);
883
884 In Perl 5.10.0 the C</p> match operator flag and the C<${^PREMATCH}>,
885 C<${^MATCH}>, and C<${^POSTMATCH}> variables were introduced, that allowed
886 you to suffer the penalties only on patterns marked with C</p>.
887
888 In Perl 5.18.0 onwards, perl started noting the presence of each of the
889 three variables separately, and only copied that part of the string
890 required; so in
891
892     $`; $&; "abcdefgh" =~ /d/
893
894 perl would only copy the "abcd" part of the string. That could make a big
895 difference in something like
896
897     $str = 'x' x 1_000_000;
898     $&; # whoops
899     $str =~ /x/g # one char copied a million times, not a million chars
900
901 In Perl 5.20.0 a new copy-on-write system was enabled by default, which
902 finally fixes all performance issues with these three variables, and makes
903 them safe to use anywhere.
904
905 The C<Devel::NYTProf> and C<Devel::FindAmpersand> modules can help you
906 find uses of these problematic match variables in your code.
907
908 =over 8
909
910 =item $<I<digits>> ($1, $2, ...)
911 X<$1> X<$2> X<$3> X<$I<digits>>
912
913 Contains the subpattern from the corresponding set of capturing
914 parentheses from the last successful pattern match, not counting patterns
915 matched in nested blocks that have been exited already.
916
917 Note there is a distinction between a capture buffer which matches
918 the empty string a capture buffer which is optional. Eg, C<(x?)> and
919 C<(x)?> The latter may be undef, the former not.
920
921 These variables are read-only and dynamically-scoped.
922
923 Mnemonic: like \digits.
924
925 =item @{^CAPTURE}
926 X<@{^CAPTURE}> X<@^CAPTURE>
927
928 An array which exposes the contents of the capture buffers, if any, of
929 the last successful pattern match, not counting patterns matched
930 in nested blocks that have been exited already.
931
932 Note that the 0 index of @{^CAPTURE} is equivalent to $1, the 1 index
933 is equivalent to $2, etc.
934
935     if ("foal"=~/(.)(.)(.)(.)/) {
936         print join "-", @{^CAPTURE};
937     }
938
939 should output "f-o-a-l".
940
941 See also L</$I<digits>>, L</%{^CAPTURE}> and L</%{^CAPTURE_ALL}>.
942
943 Note that unlike most other regex magic variables there is no single
944 letter equivalent to C<@{^CAPTURE}>.
945
946 This variable was added in 5.25.7
947
948 =item $MATCH
949
950 =item $&
951 X<$&> X<$MATCH>
952
953 The string matched by the last successful pattern match (not counting
954 any matches hidden within a BLOCK or C<eval()> enclosed by the current
955 BLOCK).
956
957 See L</Performance issues> above for the serious performance implications
958 of using this variable (even once) in your code.
959
960 This variable is read-only and dynamically-scoped.
961
962 Mnemonic: like C<&> in some editors.
963
964 =item ${^MATCH}
965 X<${^MATCH}>
966
967 This is similar to C<$&> (C<$MATCH>) except that it does not incur the
968 performance penalty associated with that variable.
969
970 See L</Performance issues> above.
971
972 In Perl v5.18 and earlier, it is only guaranteed
973 to return a defined value when the pattern was compiled or executed with
974 the C</p> modifier.  In Perl v5.20, the C</p> modifier does nothing, so
975 C<${^MATCH}> does the same thing as C<$MATCH>.
976
977 This variable was added in Perl v5.10.0.
978
979 This variable is read-only and dynamically-scoped.
980
981 =item $PREMATCH
982
983 =item $`
984 X<$`> X<$PREMATCH> X<${^PREMATCH}>
985
986 The string preceding whatever was matched by the last successful
987 pattern match, not counting any matches hidden within a BLOCK or C<eval>
988 enclosed by the current BLOCK.
989
990 See L</Performance issues> above for the serious performance implications
991 of using this variable (even once) in your code.
992
993 This variable is read-only and dynamically-scoped.
994
995 Mnemonic: C<`> often precedes a quoted string.
996
997 =item ${^PREMATCH}
998 X<$`> X<${^PREMATCH}>
999
1000 This is similar to C<$`> ($PREMATCH) except that it does not incur the
1001 performance penalty associated with that variable.
1002
1003 See L</Performance issues> above.
1004
1005 In Perl v5.18 and earlier, it is only guaranteed
1006 to return a defined value when the pattern was compiled or executed with
1007 the C</p> modifier.  In Perl v5.20, the C</p> modifier does nothing, so
1008 C<${^PREMATCH}> does the same thing as C<$PREMATCH>.
1009
1010 This variable was added in Perl v5.10.0.
1011
1012 This variable is read-only and dynamically-scoped.
1013
1014 =item $POSTMATCH
1015
1016 =item $'
1017 X<$'> X<$POSTMATCH> X<${^POSTMATCH}> X<@->
1018
1019 The string following whatever was matched by the last successful
1020 pattern match (not counting any matches hidden within a BLOCK or C<eval()>
1021 enclosed by the current BLOCK).  Example:
1022
1023     local $_ = 'abcdefghi';
1024     /def/;
1025     print "$`:$&:$'\n";         # prints abc:def:ghi
1026
1027 See L</Performance issues> above for the serious performance implications
1028 of using this variable (even once) in your code.
1029
1030 This variable is read-only and dynamically-scoped.
1031
1032 Mnemonic: C<'> often follows a quoted string.
1033
1034 =item ${^POSTMATCH}
1035 X<${^POSTMATCH}> X<$'> X<$POSTMATCH>
1036
1037 This is similar to C<$'> (C<$POSTMATCH>) except that it does not incur the
1038 performance penalty associated with that variable.
1039
1040 See L</Performance issues> above.
1041
1042 In Perl v5.18 and earlier, it is only guaranteed
1043 to return a defined value when the pattern was compiled or executed with
1044 the C</p> modifier.  In Perl v5.20, the C</p> modifier does nothing, so
1045 C<${^POSTMATCH}> does the same thing as C<$POSTMATCH>.
1046
1047 This variable was added in Perl v5.10.0.
1048
1049 This variable is read-only and dynamically-scoped.
1050
1051 =item $LAST_PAREN_MATCH
1052
1053 =item $+
1054 X<$+> X<$LAST_PAREN_MATCH>
1055
1056 The text matched by the last bracket of the last successful search pattern.
1057 This is useful if you don't know which one of a set of alternative patterns
1058 matched.  For example:
1059
1060     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
1061
1062 This variable is read-only and dynamically-scoped.
1063
1064 Mnemonic: be positive and forward looking.
1065
1066 =item $LAST_SUBMATCH_RESULT
1067
1068 =item $^N
1069 X<$^N> X<$LAST_SUBMATCH_RESULT>
1070
1071 The text matched by the used group most-recently closed (i.e. the group
1072 with the rightmost closing parenthesis) of the last successful search
1073 pattern.
1074
1075 This is primarily used inside C<(?{...})> blocks for examining text
1076 recently matched.  For example, to effectively capture text to a variable
1077 (in addition to C<$1>, C<$2>, etc.), replace C<(...)> with
1078
1079     (?:(...)(?{ $var = $^N }))
1080
1081 By setting and then using C<$var> in this way relieves you from having to
1082 worry about exactly which numbered set of parentheses they are.
1083
1084 This variable was added in Perl v5.8.0.
1085
1086 Mnemonic: the (possibly) Nested parenthesis that most recently closed.
1087
1088 =item @LAST_MATCH_END
1089
1090 =item @+
1091 X<@+> X<@LAST_MATCH_END>
1092
1093 This array holds the offsets of the ends of the last successful
1094 submatches in the currently active dynamic scope.  C<$+[0]> is
1095 the offset into the string of the end of the entire match.  This
1096 is the same value as what the C<pos> function returns when called
1097 on the variable that was matched against.  The I<n>th element
1098 of this array holds the offset of the I<n>th submatch, so
1099 C<$+[1]> is the offset past where C<$1> ends, C<$+[2]> the offset
1100 past where C<$2> ends, and so on.  You can use C<$#+> to determine
1101 how many subgroups were in the last successful match.  See the
1102 examples given for the C<@-> variable.
1103
1104 This variable was added in Perl v5.6.0.
1105
1106 =item %{^CAPTURE}
1107
1108 =item %LAST_PAREN_MATCH
1109
1110 =item %+
1111 X<%+> X<%LAST_PAREN_MATCH> X<%{^CAPTURE}>
1112
1113 Similar to C<@+>, the C<%+> hash allows access to the named capture
1114 buffers, should they exist, in the last successful match in the
1115 currently active dynamic scope.
1116
1117 For example, C<$+{foo}> is equivalent to C<$1> after the following match:
1118
1119     'foo' =~ /(?<foo>foo)/;
1120
1121 The keys of the C<%+> hash list only the names of buffers that have
1122 captured (and that are thus associated to defined values).
1123
1124 If multiple distinct capture groups have the same name, then
1125 C<$+{NAME}> will refer to the leftmost defined group in the match.
1126
1127 The underlying behaviour of C<%+> is provided by the
1128 L<Tie::Hash::NamedCapture> module.
1129
1130 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
1131 associated with the last successful regular expression.  Therefore mixing
1132 iterative access to them via C<each> may have unpredictable results.
1133 Likewise, if the last successful match changes, then the results may be
1134 surprising.
1135
1136 This variable was added in Perl v5.10.0. The C<%{^CAPTURE}> alias was
1137 added in 5.25.7.
1138
1139 This variable is read-only and dynamically-scoped.
1140
1141 =item @LAST_MATCH_START
1142
1143 =item @-
1144 X<@-> X<@LAST_MATCH_START>
1145
1146 C<$-[0]> is the offset of the start of the last successful match.
1147 C<$-[>I<n>C<]> is the offset of the start of the substring matched by
1148 I<n>-th subpattern, or undef if the subpattern did not match.
1149
1150 Thus, after a match against C<$_>, C<$&> coincides with C<substr $_, $-[0],
1151 $+[0] - $-[0]>.  Similarly, $I<n> coincides with C<substr $_, $-[n],
1152 $+[n] - $-[n]> if C<$-[n]> is defined, and $+ coincides with
1153 C<substr $_, $-[$#-], $+[$#-] - $-[$#-]>.  One can use C<$#-> to find the
1154 last matched subgroup in the last successful match.  Contrast with
1155 C<$#+>, the number of subgroups in the regular expression.  Compare
1156 with C<@+>.
1157
1158 This array holds the offsets of the beginnings of the last
1159 successful submatches in the currently active dynamic scope.
1160 C<$-[0]> is the offset into the string of the beginning of the
1161 entire match.  The I<n>th element of this array holds the offset
1162 of the I<n>th submatch, so C<$-[1]> is the offset where C<$1>
1163 begins, C<$-[2]> the offset where C<$2> begins, and so on.
1164
1165 After a match against some variable C<$var>:
1166
1167 =over 5
1168
1169 =item C<$`> is the same as C<substr($var, 0, $-[0])>
1170
1171 =item C<$&> is the same as C<substr($var, $-[0], $+[0] - $-[0])>
1172
1173 =item C<$'> is the same as C<substr($var, $+[0])>
1174
1175 =item C<$1> is the same as C<substr($var, $-[1], $+[1] - $-[1])>
1176
1177 =item C<$2> is the same as C<substr($var, $-[2], $+[2] - $-[2])>
1178
1179 =item C<$3> is the same as C<substr($var, $-[3], $+[3] - $-[3])>
1180
1181 =back
1182
1183 This variable was added in Perl v5.6.0.
1184
1185 =item %{^CAPTURE_ALL}
1186 X<%{^CAPTURE_ALL}>
1187
1188 =item %-
1189 X<%->
1190
1191 Similar to C<%+>, this variable allows access to the named capture groups
1192 in the last successful match in the currently active dynamic scope.  To
1193 each capture group name found in the regular expression, it associates a
1194 reference to an array containing the list of values captured by all
1195 buffers with that name (should there be several of them), in the order
1196 where they appear.
1197
1198 Here's an example:
1199
1200     if ('1234' =~ /(?<A>1)(?<B>2)(?<A>3)(?<B>4)/) {
1201         foreach my $bufname (sort keys %-) {
1202             my $ary = $-{$bufname};
1203             foreach my $idx (0..$#$ary) {
1204                 print "\$-{$bufname}[$idx] : ",
1205                       (defined($ary->[$idx])
1206                           ? "'$ary->[$idx]'"
1207                           : "undef"),
1208                       "\n";
1209             }
1210         }
1211     }
1212
1213 would print out:
1214
1215     $-{A}[0] : '1'
1216     $-{A}[1] : '3'
1217     $-{B}[0] : '2'
1218     $-{B}[1] : '4'
1219
1220 The keys of the C<%-> hash correspond to all buffer names found in
1221 the regular expression.
1222
1223 The behaviour of C<%-> is implemented via the
1224 L<Tie::Hash::NamedCapture> module.
1225
1226 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
1227 associated with the last successful regular expression.  Therefore mixing
1228 iterative access to them via C<each> may have unpredictable results.
1229 Likewise, if the last successful match changes, then the results may be
1230 surprising.
1231
1232 This variable was added in Perl v5.10.0. The C<%{^CAPTURE_ALL}> alias was
1233 added in 5.25.7.
1234
1235 This variable is read-only and dynamically-scoped.
1236
1237 =item $LAST_REGEXP_CODE_RESULT
1238
1239 =item $^R
1240 X<$^R> X<$LAST_REGEXP_CODE_RESULT>
1241
1242 The result of evaluation of the last successful C<(?{ code })>
1243 regular expression assertion (see L<perlre>).  May be written to.
1244
1245 This variable was added in Perl 5.005.
1246
1247 =item ${^RE_DEBUG_FLAGS}
1248 X<${^RE_DEBUG_FLAGS}>
1249
1250 The current value of the regex debugging flags.  Set to 0 for no debug output
1251 even when the C<re 'debug'> module is loaded.  See L<re> for details.
1252
1253 This variable was added in Perl v5.10.0.
1254
1255 =item ${^RE_TRIE_MAXBUF}
1256 X<${^RE_TRIE_MAXBUF}>
1257
1258 Controls how certain regex optimisations are applied and how much memory they
1259 utilize.  This value by default is 65536 which corresponds to a 512kB
1260 temporary cache.  Set this to a higher value to trade
1261 memory for speed when matching large alternations.  Set
1262 it to a lower value if you want the optimisations to
1263 be as conservative of memory as possible but still occur, and set it to a
1264 negative value to prevent the optimisation and conserve the most memory.
1265 Under normal situations this variable should be of no interest to you.
1266
1267 This variable was added in Perl v5.10.0.
1268
1269 =back
1270
1271 =head2 Variables related to filehandles
1272
1273 Variables that depend on the currently selected filehandle may be set
1274 by calling an appropriate object method on the C<IO::Handle> object,
1275 although this is less efficient than using the regular built-in
1276 variables.  (Summary lines below for this contain the word HANDLE.)
1277 First you must say
1278
1279     use IO::Handle;
1280
1281 after which you may use either
1282
1283     method HANDLE EXPR
1284
1285 or more safely,
1286
1287     HANDLE->method(EXPR)
1288
1289 Each method returns the old value of the C<IO::Handle> attribute.  The
1290 methods each take an optional EXPR, which, if supplied, specifies the
1291 new value for the C<IO::Handle> attribute in question.  If not
1292 supplied, most methods do nothing to the current value--except for
1293 C<autoflush()>, which will assume a 1 for you, just to be different.
1294
1295 Because loading in the C<IO::Handle> class is an expensive operation,
1296 you should learn how to use the regular built-in variables.
1297
1298 A few of these variables are considered "read-only".  This means that
1299 if you try to assign to this variable, either directly or indirectly
1300 through a reference, you'll raise a run-time exception.
1301
1302 You should be very careful when modifying the default values of most
1303 special variables described in this document.  In most cases you want
1304 to localize these variables before changing them, since if you don't,
1305 the change may affect other modules which rely on the default values
1306 of the special variables that you have changed.  This is one of the
1307 correct ways to read the whole file at once:
1308
1309     open my $fh, "<", "foo" or die $!;
1310     local $/; # enable localized slurp mode
1311     my $content = <$fh>;
1312     close $fh;
1313
1314 But the following code is quite bad:
1315
1316     open my $fh, "<", "foo" or die $!;
1317     undef $/; # enable slurp mode
1318     my $content = <$fh>;
1319     close $fh;
1320
1321 since some other module, may want to read data from some file in the
1322 default "line mode", so if the code we have just presented has been
1323 executed, the global value of C<$/> is now changed for any other code
1324 running inside the same Perl interpreter.
1325
1326 Usually when a variable is localized you want to make sure that this
1327 change affects the shortest scope possible.  So unless you are already
1328 inside some short C<{}> block, you should create one yourself.  For
1329 example:
1330
1331     my $content = '';
1332     open my $fh, "<", "foo" or die $!;
1333     {
1334         local $/;
1335         $content = <$fh>;
1336     }
1337     close $fh;
1338
1339 Here is an example of how your own code can go broken:
1340
1341     for ( 1..3 ){
1342         $\ = "\r\n";
1343         nasty_break();
1344         print "$_";
1345     }
1346
1347     sub nasty_break {
1348         $\ = "\f";
1349         # do something with $_
1350     }
1351
1352 You probably expect this code to print the equivalent of
1353
1354     "1\r\n2\r\n3\r\n"
1355
1356 but instead you get:
1357
1358     "1\f2\f3\f"
1359
1360 Why? Because C<nasty_break()> modifies C<$\> without localizing it
1361 first.  The value you set in  C<nasty_break()> is still there when you
1362 return.  The fix is to add C<local()> so the value doesn't leak out of
1363 C<nasty_break()>:
1364
1365     local $\ = "\f";
1366
1367 It's easy to notice the problem in such a short example, but in more
1368 complicated code you are looking for trouble if you don't localize
1369 changes to the special variables.
1370
1371 =over 8
1372
1373 =item $ARGV
1374 X<$ARGV>
1375
1376 Contains the name of the current file when reading from C<< <> >>.
1377
1378 =item @ARGV
1379 X<@ARGV>
1380
1381 The array C<@ARGV> contains the command-line arguments intended for
1382 the script.  C<$#ARGV> is generally the number of arguments minus
1383 one, because C<$ARGV[0]> is the first argument, I<not> the program's
1384 command name itself.  See L</$0> for the command name.
1385
1386 =item ARGV
1387 X<ARGV>
1388
1389 The special filehandle that iterates over command-line filenames in
1390 C<@ARGV>.  Usually written as the null filehandle in the angle operator
1391 C<< <> >>.  Note that currently C<ARGV> only has its magical effect
1392 within the C<< <> >> operator; elsewhere it is just a plain filehandle
1393 corresponding to the last file opened by C<< <> >>.  In particular,
1394 passing C<\*ARGV> as a parameter to a function that expects a filehandle
1395 may not cause your function to automatically read the contents of all the
1396 files in C<@ARGV>.
1397
1398 =item ARGVOUT
1399 X<ARGVOUT>
1400
1401 The special filehandle that points to the currently open output file
1402 when doing edit-in-place processing with B<-i>.  Useful when you have
1403 to do a lot of inserting and don't want to keep modifying C<$_>.  See
1404 L<perlrun> for the B<-i> switch.
1405
1406 =item IO::Handle->output_field_separator( EXPR )
1407
1408 =item $OUTPUT_FIELD_SEPARATOR
1409
1410 =item $OFS
1411
1412 =item $,
1413 X<$,> X<$OFS> X<$OUTPUT_FIELD_SEPARATOR>
1414
1415 The output field separator for the print operator.  If defined, this
1416 value is printed between each of print's arguments.  Default is C<undef>.
1417
1418 You cannot call C<output_field_separator()> on a handle, only as a
1419 static method.  See L<IO::Handle|IO::Handle>.
1420
1421 Mnemonic: what is printed when there is a "," in your print statement.
1422
1423 =item HANDLE->input_line_number( EXPR )
1424
1425 =item $INPUT_LINE_NUMBER
1426
1427 =item $NR
1428
1429 =item $.
1430 X<$.> X<$NR> X<$INPUT_LINE_NUMBER> X<line number>
1431
1432 Current line number for the last filehandle accessed.
1433
1434 Each filehandle in Perl counts the number of lines that have been read
1435 from it.  (Depending on the value of C<$/>, Perl's idea of what
1436 constitutes a line may not match yours.)  When a line is read from a
1437 filehandle (via C<readline()> or C<< <> >>), or when C<tell()> or
1438 C<seek()> is called on it, C<$.> becomes an alias to the line counter
1439 for that filehandle.
1440
1441 You can adjust the counter by assigning to C<$.>, but this will not
1442 actually move the seek pointer.  I<Localizing C<$.> will not localize
1443 the filehandle's line count>.  Instead, it will localize perl's notion
1444 of which filehandle C<$.> is currently aliased to.
1445
1446 C<$.> is reset when the filehandle is closed, but B<not> when an open
1447 filehandle is reopened without an intervening C<close()>.  For more
1448 details, see L<perlop/"IE<sol>O Operators">.  Because C<< <> >> never does
1449 an explicit close, line numbers increase across C<ARGV> files (but see
1450 examples in L<perlfunc/eof>).
1451
1452 You can also use C<< HANDLE->input_line_number(EXPR) >> to access the
1453 line counter for a given filehandle without having to worry about
1454 which handle you last accessed.
1455
1456 Mnemonic: many programs use "." to mean the current line number.
1457
1458 =item IO::Handle->input_record_separator( EXPR )
1459
1460 =item $INPUT_RECORD_SEPARATOR
1461
1462 =item $RS
1463
1464 =item $/
1465 X<$/> X<$RS> X<$INPUT_RECORD_SEPARATOR>
1466
1467 The input record separator, newline by default.  This influences Perl's
1468 idea of what a "line" is.  Works like B<awk>'s RS variable, including
1469 treating empty lines as a terminator if set to the null string (an
1470 empty line cannot contain any spaces or tabs).  You may set it to a
1471 multi-character string to match a multi-character terminator, or to
1472 C<undef> to read through the end of file.  Setting it to C<"\n\n">
1473 means something slightly different than setting to C<"">, if the file
1474 contains consecutive empty lines.  Setting to C<""> will treat two or
1475 more consecutive empty lines as a single empty line.  Setting to
1476 C<"\n\n"> will blindly assume that the next input character belongs to
1477 the next paragraph, even if it's a newline.
1478
1479     local $/;           # enable "slurp" mode
1480     local $_ = <FH>;    # whole file now here
1481     s/\n[ \t]+/ /g;
1482
1483 Remember: the value of C<$/> is a string, not a regex.  B<awk> has to
1484 be better for something. :-)
1485
1486 Setting C<$/> to a reference to an integer, scalar containing an
1487 integer, or scalar that's convertible to an integer will attempt to
1488 read records instead of lines, with the maximum record size being the
1489 referenced integer number of characters.  So this:
1490
1491     local $/ = \32768; # or \"32768", or \$var_containing_32768
1492     open my $fh, "<", $myfile or die $!;
1493     local $_ = <$fh>;
1494
1495 will read a record of no more than 32768 characters from $fh.  If you're
1496 not reading from a record-oriented file (or your OS doesn't have
1497 record-oriented files), then you'll likely get a full chunk of data
1498 with every read.  If a record is larger than the record size you've
1499 set, you'll get the record back in pieces.  Trying to set the record
1500 size to zero or less is deprecated and will cause $/ to have the value
1501 of "undef", which will cause reading in the (rest of the) whole file.
1502
1503 As of 5.19.9 setting C<$/> to any other form of reference will throw a
1504 fatal exception. This is in preparation for supporting new ways to set
1505 C<$/> in the future.
1506
1507 On VMS only, record reads bypass PerlIO layers and any associated
1508 buffering, so you must not mix record and non-record reads on the
1509 same filehandle.  Record mode mixes with line mode only when the
1510 same buffering layer is in use for both modes.
1511
1512 You cannot call C<input_record_separator()> on a handle, only as a
1513 static method.  See L<IO::Handle|IO::Handle>.
1514
1515 See also L<perlport/"Newlines">.  Also see L</$.>.
1516
1517 Mnemonic: / delimits line boundaries when quoting poetry.
1518
1519 =item IO::Handle->output_record_separator( EXPR )
1520
1521 =item $OUTPUT_RECORD_SEPARATOR
1522
1523 =item $ORS
1524
1525 =item $\
1526 X<$\> X<$ORS> X<$OUTPUT_RECORD_SEPARATOR>
1527
1528 The output record separator for the print operator.  If defined, this
1529 value is printed after the last of print's arguments.  Default is C<undef>.
1530
1531 You cannot call C<output_record_separator()> on a handle, only as a
1532 static method.  See L<IO::Handle|IO::Handle>.
1533
1534 Mnemonic: you set C<$\> instead of adding "\n" at the end of the print.
1535 Also, it's just like C<$/>, but it's what you get "back" from Perl.
1536
1537 =item HANDLE->autoflush( EXPR )
1538
1539 =item $OUTPUT_AUTOFLUSH
1540
1541 =item $|
1542 X<$|> X<autoflush> X<flush> X<$OUTPUT_AUTOFLUSH>
1543
1544 If set to nonzero, forces a flush right away and after every write or
1545 print on the currently selected output channel.  Default is 0
1546 (regardless of whether the channel is really buffered by the system or
1547 not; C<$|> tells you only whether you've asked Perl explicitly to
1548 flush after each write).  STDOUT will typically be line buffered if
1549 output is to the terminal and block buffered otherwise.  Setting this
1550 variable is useful primarily when you are outputting to a pipe or
1551 socket, such as when you are running a Perl program under B<rsh> and
1552 want to see the output as it's happening.  This has no effect on input
1553 buffering.  See L<perlfunc/getc> for that.  See L<perlfunc/select> on
1554 how to select the output channel.  See also L<IO::Handle>.
1555
1556 Mnemonic: when you want your pipes to be piping hot.
1557
1558 =item ${^LAST_FH}
1559 X<${^LAST_FH}>
1560
1561 This read-only variable contains a reference to the last-read filehandle.
1562 This is set by C<< <HANDLE> >>, C<readline>, C<tell>, C<eof> and C<seek>.
1563 This is the same handle that C<$.> and C<tell> and C<eof> without arguments
1564 use.  It is also the handle used when Perl appends ", <STDIN> line 1" to
1565 an error or warning message.
1566
1567 This variable was added in Perl v5.18.0.
1568
1569 =back
1570
1571 =head3 Variables related to formats
1572
1573 The special variables for formats are a subset of those for
1574 filehandles.  See L<perlform> for more information about Perl's
1575 formats.
1576
1577 =over 8
1578
1579 =item $ACCUMULATOR
1580
1581 =item $^A
1582 X<$^A> X<$ACCUMULATOR>
1583
1584 The current value of the C<write()> accumulator for C<format()> lines.
1585 A format contains C<formline()> calls that put their result into
1586 C<$^A>.  After calling its format, C<write()> prints out the contents
1587 of C<$^A> and empties.  So you never really see the contents of C<$^A>
1588 unless you call C<formline()> yourself and then look at it.  See
1589 L<perlform> and L<perlfunc/"formline PICTURE,LIST">.
1590
1591 =item IO::Handle->format_formfeed(EXPR)
1592
1593 =item $FORMAT_FORMFEED
1594
1595 =item $^L
1596 X<$^L> X<$FORMAT_FORMFEED>
1597
1598 What formats output as a form feed.  The default is C<\f>.
1599
1600 You cannot call C<format_formfeed()> on a handle, only as a static
1601 method.  See L<IO::Handle|IO::Handle>.
1602
1603 =item HANDLE->format_page_number(EXPR)
1604
1605 =item $FORMAT_PAGE_NUMBER
1606
1607 =item $%
1608 X<$%> X<$FORMAT_PAGE_NUMBER>
1609
1610 The current page number of the currently selected output channel.
1611
1612 Mnemonic: C<%> is page number in B<nroff>.
1613
1614 =item HANDLE->format_lines_left(EXPR)
1615
1616 =item $FORMAT_LINES_LEFT
1617
1618 =item $-
1619 X<$-> X<$FORMAT_LINES_LEFT>
1620
1621 The number of lines left on the page of the currently selected output
1622 channel.
1623
1624 Mnemonic: lines_on_page - lines_printed.
1625
1626 =item IO::Handle->format_line_break_characters EXPR
1627
1628 =item $FORMAT_LINE_BREAK_CHARACTERS
1629
1630 =item $:
1631 X<$:> X<FORMAT_LINE_BREAK_CHARACTERS>
1632
1633 The current set of characters after which a string may be broken to
1634 fill continuation fields (starting with C<^>) in a format.  The default is
1635 S<" \n-">, to break on a space, newline, or a hyphen.
1636
1637 You cannot call C<format_line_break_characters()> on a handle, only as
1638 a static method.  See L<IO::Handle|IO::Handle>.
1639
1640 Mnemonic: a "colon" in poetry is a part of a line.
1641
1642 =item HANDLE->format_lines_per_page(EXPR)
1643
1644 =item $FORMAT_LINES_PER_PAGE
1645
1646 =item $=
1647 X<$=> X<$FORMAT_LINES_PER_PAGE>
1648
1649 The current page length (printable lines) of the currently selected
1650 output channel.  The default is 60.
1651
1652 Mnemonic: = has horizontal lines.
1653
1654 =item HANDLE->format_top_name(EXPR)
1655
1656 =item $FORMAT_TOP_NAME
1657
1658 =item $^
1659 X<$^> X<$FORMAT_TOP_NAME>
1660
1661 The name of the current top-of-page format for the currently selected
1662 output channel.  The default is the name of the filehandle with C<_TOP>
1663 appended.  For example, the default format top name for the C<STDOUT>
1664 filehandle is C<STDOUT_TOP>.
1665
1666 Mnemonic: points to top of page.
1667
1668 =item HANDLE->format_name(EXPR)
1669
1670 =item $FORMAT_NAME
1671
1672 =item $~
1673 X<$~> X<$FORMAT_NAME>
1674
1675 The name of the current report format for the currently selected
1676 output channel.  The default format name is the same as the filehandle
1677 name.  For example, the default format name for the C<STDOUT>
1678 filehandle is just C<STDOUT>.
1679
1680 Mnemonic: brother to C<$^>.
1681
1682 =back
1683
1684 =head2 Error Variables
1685 X<error> X<exception>
1686
1687 The variables C<$@>, C<$!>, C<$^E>, and C<$?> contain information
1688 about different types of error conditions that may appear during
1689 execution of a Perl program.  The variables are shown ordered by
1690 the "distance" between the subsystem which reported the error and
1691 the Perl process.  They correspond to errors detected by the Perl
1692 interpreter, C library, operating system, or an external program,
1693 respectively.
1694
1695 To illustrate the differences between these variables, consider the
1696 following Perl expression, which uses a single-quoted string.  After
1697 execution of this statement, perl may have set all four special error
1698 variables:
1699
1700     eval q{
1701         open my $pipe, "/cdrom/install |" or die $!;
1702         my @res = <$pipe>;
1703         close $pipe or die "bad pipe: $?, $!";
1704     };
1705
1706 When perl executes the C<eval()> expression, it translates the
1707 C<open()>, C<< <PIPE> >>, and C<close> calls in the C run-time library
1708 and thence to the operating system kernel.  perl sets C<$!> to
1709 the C library's C<errno> if one of these calls fails.
1710
1711 C<$@> is set if the string to be C<eval>-ed did not compile (this may
1712 happen if C<open> or C<close> were imported with bad prototypes), or
1713 if Perl code executed during evaluation C<die()>d.  In these cases the
1714 value of C<$@> is the compile error, or the argument to C<die> (which
1715 will interpolate C<$!> and C<$?>).  (See also L<Fatal>, though.)
1716
1717 Under a few operating systems, C<$^E> may contain a more verbose error
1718 indicator, such as in this case, "CDROM tray not closed."  Systems that
1719 do not support extended error messages leave C<$^E> the same as C<$!>.
1720
1721 Finally, C<$?> may be set to a non-0 value if the external program
1722 F</cdrom/install> fails.  The upper eight bits reflect specific error
1723 conditions encountered by the program (the program's C<exit()> value).
1724 The lower eight bits reflect mode of failure, like signal death and
1725 core dump information.  See L<wait(2)> for details.  In contrast to
1726 C<$!> and C<$^E>, which are set only if an error condition is detected,
1727 the variable C<$?> is set on each C<wait> or pipe C<close>,
1728 overwriting the old value.  This is more like C<$@>, which on every
1729 C<eval()> is always set on failure and cleared on success.
1730
1731 For more details, see the individual descriptions at C<$@>, C<$!>,
1732 C<$^E>, and C<$?>.
1733
1734 =over 8
1735
1736 =item ${^CHILD_ERROR_NATIVE}
1737 X<$^CHILD_ERROR_NATIVE>
1738
1739 The native status returned by the last pipe close, backtick (C<``>)
1740 command, successful call to C<wait()> or C<waitpid()>, or from the
1741 C<system()> operator.  On POSIX-like systems this value can be decoded
1742 with the WIFEXITED, WEXITSTATUS, WIFSIGNALED, WTERMSIG, WIFSTOPPED,
1743 WSTOPSIG and WIFCONTINUED functions provided by the L<POSIX> module.
1744
1745 Under VMS this reflects the actual VMS exit status; i.e. it is the
1746 same as C<$?> when the pragma C<use vmsish 'status'> is in effect.
1747
1748 This variable was added in Perl v5.10.0.
1749
1750 =item $EXTENDED_OS_ERROR
1751
1752 =item $^E
1753 X<$^E> X<$EXTENDED_OS_ERROR>
1754
1755 Error information specific to the current operating system.  At the
1756 moment, this differs from C<L</$!>> under only VMS, OS/2, and Win32 (and
1757 for MacPerl).  On all other platforms, C<$^E> is always just the same
1758 as C<$!>.
1759
1760 Under VMS, C<$^E> provides the VMS status value from the last system
1761 error.  This is more specific information about the last system error
1762 than that provided by C<$!>.  This is particularly important when C<$!>
1763 is set to B<EVMSERR>.
1764
1765 Under OS/2, C<$^E> is set to the error code of the last call to OS/2
1766 API either via CRT, or directly from perl.
1767
1768 Under Win32, C<$^E> always returns the last error information reported
1769 by the Win32 call C<GetLastError()> which describes the last error
1770 from within the Win32 API.  Most Win32-specific code will report errors
1771 via C<$^E>.  ANSI C and Unix-like calls set C<errno> and so most
1772 portable Perl code will report errors via C<$!>.
1773
1774 Caveats mentioned in the description of C<L</$!>> generally apply to
1775 C<$^E>, also.
1776
1777 This variable was added in Perl 5.003.
1778
1779 Mnemonic: Extra error explanation.
1780
1781 =item $EXCEPTIONS_BEING_CAUGHT
1782
1783 =item $^S
1784 X<$^S> X<$EXCEPTIONS_BEING_CAUGHT>
1785
1786 Current state of the interpreter.
1787
1788         $^S         State
1789         ---------   -------------------------------------
1790         undef       Parsing module, eval, or main program
1791         true (1)    Executing an eval
1792         false (0)   Otherwise
1793
1794 The first state may happen in C<$SIG{__DIE__}> and C<$SIG{__WARN__}>
1795 handlers.
1796
1797 The English name $EXCEPTIONS_BEING_CAUGHT is slightly misleading, because
1798 the C<undef> value does not indicate whether exceptions are being caught,
1799 since compilation of the main program does not catch exceptions.
1800
1801 This variable was added in Perl 5.004.
1802
1803 =item $WARNING
1804
1805 =item $^W
1806 X<$^W> X<$WARNING>
1807
1808 The current value of the warning switch, initially true if B<-w> was
1809 used, false otherwise, but directly modifiable.
1810
1811 See also L<warnings>.
1812
1813 Mnemonic: related to the B<-w> switch.
1814
1815 =item ${^WARNING_BITS}
1816 X<${^WARNING_BITS}>
1817
1818 The current set of warning checks enabled by the C<use warnings> pragma.
1819 It has the same scoping as the C<$^H> and C<%^H> variables.  The exact
1820 values are considered internal to the L<warnings> pragma and may change
1821 between versions of Perl.
1822
1823 This variable was added in Perl v5.6.0.
1824
1825 =item $OS_ERROR
1826
1827 =item $ERRNO
1828
1829 =item $!
1830 X<$!> X<$ERRNO> X<$OS_ERROR>
1831
1832 When referenced, C<$!> retrieves the current value
1833 of the C C<errno> integer variable.
1834 If C<$!> is assigned a numerical value, that value is stored in C<errno>.
1835 When referenced as a string, C<$!> yields the system error string
1836 corresponding to C<errno>.
1837
1838 Many system or library calls set C<errno> if they fail,
1839 to indicate the cause of failure.  They usually do B<not>
1840 set C<errno> to zero if they succeed.  This means C<errno>,
1841 hence C<$!>, is meaningful only I<immediately> after a B<failure>:
1842
1843     if (open my $fh, "<", $filename) {
1844                 # Here $! is meaningless.
1845                 ...
1846     }
1847     else {
1848                 # ONLY here is $! meaningful.
1849                 ...
1850                 # Already here $! might be meaningless.
1851     }
1852     # Since here we might have either success or failure,
1853     # $! is meaningless.
1854
1855 Here, I<meaningless> means that C<$!> may be unrelated to the outcome
1856 of the C<open()> operator.  Assignment to C<$!> is similarly ephemeral.
1857 It can be used immediately before invoking the C<die()> operator,
1858 to set the exit value, or to inspect the system error string
1859 corresponding to error I<n>, or to restore C<$!> to a meaningful state.
1860
1861 Mnemonic: What just went bang?
1862
1863 =item %OS_ERROR
1864
1865 =item %ERRNO
1866
1867 =item %!
1868 X<%!> X<%OS_ERROR> X<%ERRNO>
1869
1870 Each element of C<%!> has a true value only if C<$!> is set to that
1871 value.  For example, C<$!{ENOENT}> is true if and only if the current
1872 value of C<$!> is C<ENOENT>; that is, if the most recent error was "No
1873 such file or directory" (or its moral equivalent: not all operating
1874 systems give that exact error, and certainly not all languages).  The
1875 specific true value is not guaranteed, but in the past has generally
1876 been the numeric value of C<$!>.  To check if a particular key is
1877 meaningful on your system, use C<exists $!{the_key}>; for a list of legal
1878 keys, use C<keys %!>.  See L<Errno> for more information, and also see
1879 L</$!>.
1880
1881 This variable was added in Perl 5.005.
1882
1883 =item $CHILD_ERROR
1884
1885 =item $?
1886 X<$?> X<$CHILD_ERROR>
1887
1888 The status returned by the last pipe close, backtick (C<``>) command,
1889 successful call to C<wait()> or C<waitpid()>, or from the C<system()>
1890 operator.  This is just the 16-bit status word returned by the
1891 traditional Unix C<wait()> system call (or else is made up to look
1892 like it).  Thus, the exit value of the subprocess is really (C<<< $? >>
1893 8 >>>), and C<$? & 127> gives which signal, if any, the process died
1894 from, and C<$? & 128> reports whether there was a core dump.
1895
1896 Additionally, if the C<h_errno> variable is supported in C, its value
1897 is returned via C<$?> if any C<gethost*()> function fails.
1898
1899 If you have installed a signal handler for C<SIGCHLD>, the
1900 value of C<$?> will usually be wrong outside that handler.
1901
1902 Inside an C<END> subroutine C<$?> contains the value that is going to be
1903 given to C<exit()>.  You can modify C<$?> in an C<END> subroutine to
1904 change the exit status of your program.  For example:
1905
1906     END {
1907         $? = 1 if $? == 255;  # die would make it 255
1908     }
1909
1910 Under VMS, the pragma C<use vmsish 'status'> makes C<$?> reflect the
1911 actual VMS exit status, instead of the default emulation of POSIX
1912 status; see L<perlvms/$?> for details.
1913
1914 Mnemonic: similar to B<sh> and B<ksh>.
1915
1916 =item $EVAL_ERROR
1917
1918 =item $@
1919 X<$@> X<$EVAL_ERROR>
1920
1921 The Perl error from the last C<eval> operator, i.e. the last exception that
1922 was caught.  For C<eval BLOCK>, this is either a runtime error message or the
1923 string or reference C<die> was called with.  The C<eval STRING> form also
1924 catches syntax errors and other compile time exceptions.
1925
1926 If no error occurs, C<eval> sets C<$@> to the empty string.
1927
1928 Warning messages are not collected in this variable.  You can, however,
1929 set up a routine to process warnings by setting C<$SIG{__WARN__}> as
1930 described in L</%SIG>.
1931
1932 Mnemonic: Where was the error "at"?
1933
1934 =back
1935
1936 =head2 Variables related to the interpreter state
1937
1938 These variables provide information about the current interpreter state.
1939
1940 =over 8
1941
1942 =item $COMPILING
1943
1944 =item $^C
1945 X<$^C> X<$COMPILING>
1946
1947 The current value of the flag associated with the B<-c> switch.
1948 Mainly of use with B<-MO=...> to allow code to alter its behavior
1949 when being compiled, such as for example to C<AUTOLOAD> at compile
1950 time rather than normal, deferred loading.  Setting
1951 C<$^C = 1> is similar to calling C<B::minus_c>.
1952
1953 This variable was added in Perl v5.6.0.
1954
1955 =item $DEBUGGING
1956
1957 =item $^D
1958 X<$^D> X<$DEBUGGING>
1959
1960 The current value of the debugging flags.  May be read or set.  Like its
1961 L<command-line equivalent|perlrun/B<-D>I<letters>>, you can use numeric
1962 or symbolic values, e.g. C<$^D = 10> or C<$^D = "st">.  See
1963 L<perlrun/B<-D>I<number>>.  The contents of this variable also affects the
1964 debugger operation.  See L<perldebguts/Debugger Internals>.
1965
1966 Mnemonic: value of B<-D> switch.
1967
1968 =item ${^ENCODING}
1969 X<${^ENCODING}>
1970
1971 This variable is no longer supported.
1972
1973 It used to hold the I<object reference> to the C<Encode> object that was
1974 used to convert the source code to Unicode.
1975
1976 Its purpose was to allow your non-ASCII Perl
1977 scripts not to have to be written in UTF-8; this was
1978 useful before editors that worked on UTF-8 encoded text were common, but
1979 that was long ago.  It caused problems, such as affecting the operation
1980 of other modules that weren't expecting it, causing general mayhem.
1981
1982 If you need something like this functionality, it is recommended that use
1983 you a simple source filter, such as L<Filter::Encoding>.
1984
1985 If you are coming here because code of yours is being adversely affected
1986 by someone's use of this variable, you can usually work around it by
1987 doing this:
1988
1989  local ${^ENCODING};
1990
1991 near the beginning of the functions that are getting broken.  This
1992 undefines the variable during the scope of execution of the including
1993 function.
1994
1995 This variable was added in Perl 5.8.2 and removed in 5.26.0.
1996 Setting it to anything other than C<undef> was made fatal in Perl 5.28.0.
1997
1998 =item ${^GLOBAL_PHASE}
1999 X<${^GLOBAL_PHASE}>
2000
2001 The current phase of the perl interpreter.
2002
2003 Possible values are:
2004
2005 =over 8
2006
2007 =item CONSTRUCT
2008
2009 The C<PerlInterpreter*> is being constructed via C<perl_construct>.  This
2010 value is mostly there for completeness and for use via the
2011 underlying C variable C<PL_phase>.  It's not really possible for Perl
2012 code to be executed unless construction of the interpreter is
2013 finished.
2014
2015 =item START
2016
2017 This is the global compile-time.  That includes, basically, every
2018 C<BEGIN> block executed directly or indirectly from during the
2019 compile-time of the top-level program.
2020
2021 This phase is not called "BEGIN" to avoid confusion with
2022 C<BEGIN>-blocks, as those are executed during compile-time of any
2023 compilation unit, not just the top-level program.  A new, localised
2024 compile-time entered at run-time, for example by constructs as
2025 C<eval "use SomeModule"> are not global interpreter phases, and
2026 therefore aren't reflected by C<${^GLOBAL_PHASE}>.
2027
2028 =item CHECK
2029
2030 Execution of any C<CHECK> blocks.
2031
2032 =item INIT
2033
2034 Similar to "CHECK", but for C<INIT>-blocks, not C<CHECK> blocks.
2035
2036 =item RUN
2037
2038 The main run-time, i.e. the execution of C<PL_main_root>.
2039
2040 =item END
2041
2042 Execution of any C<END> blocks.
2043
2044 =item DESTRUCT
2045
2046 Global destruction.
2047
2048 =back
2049
2050 Also note that there's no value for UNITCHECK-blocks.  That's because
2051 those are run for each compilation unit individually, and therefore is
2052 not a global interpreter phase.
2053
2054 Not every program has to go through each of the possible phases, but
2055 transition from one phase to another can only happen in the order
2056 described in the above list.
2057
2058 An example of all of the phases Perl code can see:
2059
2060     BEGIN { print "compile-time: ${^GLOBAL_PHASE}\n" }
2061
2062     INIT  { print "init-time: ${^GLOBAL_PHASE}\n" }
2063
2064     CHECK { print "check-time: ${^GLOBAL_PHASE}\n" }
2065
2066     {
2067         package Print::Phase;
2068
2069         sub new {
2070             my ($class, $time) = @_;
2071             return bless \$time, $class;
2072         }
2073
2074         sub DESTROY {
2075             my $self = shift;
2076             print "$$self: ${^GLOBAL_PHASE}\n";
2077         }
2078     }
2079
2080     print "run-time: ${^GLOBAL_PHASE}\n";
2081
2082     my $runtime = Print::Phase->new(
2083         "lexical variables are garbage collected before END"
2084     );
2085
2086     END   { print "end-time: ${^GLOBAL_PHASE}\n" }
2087
2088     our $destruct = Print::Phase->new(
2089         "package variables are garbage collected after END"
2090     );
2091
2092 This will print out
2093
2094     compile-time: START
2095     check-time: CHECK
2096     init-time: INIT
2097     run-time: RUN
2098     lexical variables are garbage collected before END: RUN
2099     end-time: END
2100     package variables are garbage collected after END: DESTRUCT
2101
2102 This variable was added in Perl 5.14.0.
2103
2104 =item $^H
2105 X<$^H>
2106
2107 WARNING: This variable is strictly for
2108 internal use only.  Its availability,
2109 behavior, and contents are subject to change without notice.
2110
2111 This variable contains compile-time hints for the Perl interpreter.  At the
2112 end of compilation of a BLOCK the value of this variable is restored to the
2113 value when the interpreter started to compile the BLOCK.
2114
2115 When perl begins to parse any block construct that provides a lexical scope
2116 (e.g., eval body, required file, subroutine body, loop body, or conditional
2117 block), the existing value of C<$^H> is saved, but its value is left unchanged.
2118 When the compilation of the block is completed, it regains the saved value.
2119 Between the points where its value is saved and restored, code that
2120 executes within BEGIN blocks is free to change the value of C<$^H>.
2121
2122 This behavior provides the semantic of lexical scoping, and is used in,
2123 for instance, the C<use strict> pragma.
2124
2125 The contents should be an integer; different bits of it are used for
2126 different pragmatic flags.  Here's an example:
2127
2128     sub add_100 { $^H |= 0x100 }
2129
2130     sub foo {
2131         BEGIN { add_100() }
2132         bar->baz($boon);
2133     }
2134
2135 Consider what happens during execution of the BEGIN block.  At this point
2136 the BEGIN block has already been compiled, but the body of C<foo()> is still
2137 being compiled.  The new value of C<$^H>
2138 will therefore be visible only while
2139 the body of C<foo()> is being compiled.
2140
2141 Substitution of C<BEGIN { add_100() }> block with:
2142
2143     BEGIN { require strict; strict->import('vars') }
2144
2145 demonstrates how C<use strict 'vars'> is implemented.  Here's a conditional
2146 version of the same lexical pragma:
2147
2148     BEGIN {
2149         require strict; strict->import('vars') if $condition
2150     }
2151
2152 This variable was added in Perl 5.003.
2153
2154 =item %^H
2155 X<%^H>
2156
2157 The C<%^H> hash provides the same scoping semantic as C<$^H>.  This makes
2158 it useful for implementation of lexically scoped pragmas.  See
2159 L<perlpragma>.   All the entries are stringified when accessed at
2160 runtime, so only simple values can be accommodated.  This means no
2161 pointers to objects, for example.
2162
2163 When putting items into C<%^H>, in order to avoid conflicting with other
2164 users of the hash there is a convention regarding which keys to use.
2165 A module should use only keys that begin with the module's name (the
2166 name of its main package) and a "/" character.  For example, a module
2167 C<Foo::Bar> should use keys such as C<Foo::Bar/baz>.
2168
2169 This variable was added in Perl v5.6.0.
2170
2171 =item ${^OPEN}
2172 X<${^OPEN}>
2173
2174 An internal variable used by PerlIO.  A string in two parts, separated
2175 by a C<\0> byte, the first part describes the input layers, the second
2176 part describes the output layers.
2177
2178 This variable was added in Perl v5.8.0.
2179
2180 =item $PERLDB
2181
2182 =item $^P
2183 X<$^P> X<$PERLDB>
2184
2185 The internal variable for debugging support.  The meanings of the
2186 various bits are subject to change, but currently indicate:
2187
2188 =over 6
2189
2190 =item 0x01
2191
2192 Debug subroutine enter/exit.
2193
2194 =item 0x02
2195
2196 Line-by-line debugging.  Causes C<DB::DB()> subroutine to be called for
2197 each statement executed.  Also causes saving source code lines (like
2198 0x400).
2199
2200 =item 0x04
2201
2202 Switch off optimizations.
2203
2204 =item 0x08
2205
2206 Preserve more data for future interactive inspections.
2207
2208 =item 0x10
2209
2210 Keep info about source lines on which a subroutine is defined.
2211
2212 =item 0x20
2213
2214 Start with single-step on.
2215
2216 =item 0x40
2217
2218 Use subroutine address instead of name when reporting.
2219
2220 =item 0x80
2221
2222 Report C<goto &subroutine> as well.
2223
2224 =item 0x100
2225
2226 Provide informative "file" names for evals based on the place they were compiled.
2227
2228 =item 0x200
2229
2230 Provide informative names to anonymous subroutines based on the place they
2231 were compiled.
2232
2233 =item 0x400
2234
2235 Save source code lines into C<@{"_<$filename"}>.
2236
2237 =item 0x800
2238
2239 When saving source, include evals that generate no subroutines.
2240
2241 =item 0x1000
2242
2243 When saving source, include source that did not compile.
2244
2245 =back
2246
2247 Some bits may be relevant at compile-time only, some at
2248 run-time only.  This is a new mechanism and the details may change.
2249 See also L<perldebguts>.
2250
2251 =item ${^TAINT}
2252 X<${^TAINT}>
2253
2254 Reflects if taint mode is on or off.  1 for on (the program was run with
2255 B<-T>), 0 for off, -1 when only taint warnings are enabled (i.e. with
2256 B<-t> or B<-TU>).
2257
2258 This variable is read-only.
2259
2260 This variable was added in Perl v5.8.0.
2261
2262 =item ${^SAFE_LOCALES}
2263 X<${^SAFE_LOCALES}>
2264
2265 Reflects if safe locale operations are available to this perl (when the
2266 value is 1) or not (the value is 0).  This variable is always 1 if the
2267 perl has been compiled without threads.  It is also 1 if this perl is
2268 using thread-safe locale operations.  Note that an individual thread may
2269 choose to use the global locale (generally unsafe) by calling
2270 C<switch_to_global_locale>.  This variable currently is still
2271 set to 1 in such threads.
2272
2273 This variable is read-only.
2274
2275 This variable was added in Perl v5.28.0.
2276
2277 =item ${^UNICODE}
2278 X<${^UNICODE}>
2279
2280 Reflects certain Unicode settings of Perl.  See L<perlrun>
2281 documentation for the C<-C> switch for more information about
2282 the possible values.
2283
2284 This variable is set during Perl startup and is thereafter read-only.
2285
2286 This variable was added in Perl v5.8.2.
2287
2288 =item ${^UTF8CACHE}
2289 X<${^UTF8CACHE}>
2290
2291 This variable controls the state of the internal UTF-8 offset caching code.
2292 1 for on (the default), 0 for off, -1 to debug the caching code by checking
2293 all its results against linear scans, and panicking on any discrepancy.
2294
2295 This variable was added in Perl v5.8.9.  It is subject to change or
2296 removal without notice, but is currently used to avoid recalculating the
2297 boundaries of multi-byte UTF-8-encoded characters.
2298
2299 =item ${^UTF8LOCALE}
2300 X<${^UTF8LOCALE}>
2301
2302 This variable indicates whether a UTF-8 locale was detected by perl at
2303 startup.  This information is used by perl when it's in
2304 adjust-utf8ness-to-locale mode (as when run with the C<-CL> command-line
2305 switch); see L<perlrun> for more info on this.
2306
2307 This variable was added in Perl v5.8.8.
2308
2309 =back
2310
2311 =head2 Deprecated and removed variables
2312
2313 Deprecating a variable announces the intent of the perl maintainers to
2314 eventually remove the variable from the language.  It may still be
2315 available despite its status.  Using a deprecated variable triggers
2316 a warning.
2317
2318 Once a variable is removed, its use triggers an error telling you
2319 the variable is unsupported.
2320
2321 See L<perldiag> for details about error messages.
2322
2323 =over 8
2324
2325 =item $#
2326 X<$#>
2327
2328 C<$#> was a variable that could be used to format printed numbers.
2329 After a deprecation cycle, its magic was removed in Perl v5.10.0 and
2330 using it now triggers a warning: C<$# is no longer supported>.
2331
2332 This is not the sigil you use in front of an array name to get the
2333 last index, like C<$#array>.  That's still how you get the last index
2334 of an array in Perl.  The two have nothing to do with each other.
2335
2336 Deprecated in Perl 5.
2337
2338 Removed in Perl v5.10.0.
2339
2340 =item $*
2341 X<$*>
2342
2343 C<$*> was a variable that you could use to enable multiline matching.
2344 After a deprecation cycle, its magic was removed in Perl v5.10.0.
2345 Using it now triggers a warning: C<$* is no longer supported>.
2346 You should use the C</s> and C</m> regexp modifiers instead.
2347
2348 Deprecated in Perl 5.
2349
2350 Removed in Perl v5.10.0.
2351
2352 =item $[
2353 X<$[>
2354
2355 This variable stores the index of the first element in an array, and
2356 of the first character in a substring.  The default is 0, but you could
2357 theoretically set it to 1 to make Perl behave more like B<awk> (or Fortran)
2358 when subscripting and when evaluating the index() and substr() functions.
2359
2360 As of release 5 of Perl, assignment to C<$[> is treated as a compiler
2361 directive, and cannot influence the behavior of any other file.
2362 (That's why you can only assign compile-time constants to it.)
2363 Its use is highly discouraged.
2364
2365 Prior to Perl v5.10.0, assignment to C<$[> could be seen from outer lexical
2366 scopes in the same file, unlike other compile-time directives (such as
2367 L<strict>).  Using local() on it would bind its value strictly to a lexical
2368 block.  Now it is always lexically scoped.
2369
2370 As of Perl v5.16.0, it is implemented by the L<arybase> module.  See
2371 L<arybase> for more details on its behaviour.
2372
2373 Under C<use v5.16>, or C<no feature "array_base">, C<$[> no longer has any
2374 effect, and always contains 0.  Assigning 0 to it is permitted, but any
2375 other value will produce an error.
2376
2377 Mnemonic: [ begins subscripts.
2378
2379 Deprecated in Perl v5.12.0.
2380
2381 Assigning a non-zero value be fatal in Perl v5.30.0.
2382
2383 =back
2384
2385 =cut