This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Add thread-safe locale handling
[perl5.git] / dist / threads / lib / threads.pm
1 package threads;
2
3 use 5.008;
4
5 use strict;
6 use warnings;
7
8 our $VERSION = '2.22';      # remember to update version in POD!
9 my $XS_VERSION = $VERSION;
10 $VERSION = eval $VERSION;
11
12 # Verify this Perl supports threads
13 require Config;
14 if (! $Config::Config{useithreads}) {
15     die("This Perl not built to support threads\n");
16 }
17
18 # Complain if 'threads' is loaded after 'threads::shared'
19 if ($threads::shared::threads_shared) {
20     warn <<'_MSG_';
21 Warning, threads::shared has already been loaded.  To
22 enable shared variables, 'use threads' must be called
23 before threads::shared or any module that uses it.
24 _MSG_
25 }
26
27 # Declare that we have been loaded
28 $threads::threads = 1;
29
30 # Load the XS code
31 require XSLoader;
32 XSLoader::load('threads', $XS_VERSION);
33
34
35 ### Export ###
36
37 sub import
38 {
39     my $class = shift;   # Not used
40
41     # Exported subroutines
42     my @EXPORT = qw(async);
43
44     # Handle args
45     while (my $sym = shift) {
46         if ($sym =~ /^(?:stack|exit)/i) {
47             if (defined(my $arg = shift)) {
48                 if ($sym =~ /^stack/i) {
49                     threads->set_stack_size($arg);
50                 } else {
51                     $threads::thread_exit_only = $arg =~ /^thread/i;
52                 }
53             } else {
54                 require Carp;
55                 Carp::croak("threads: Missing argument for option: $sym");
56             }
57
58         } elsif ($sym =~ /^str/i) {
59             import overload ('""' => \&tid);
60
61         } elsif ($sym =~ /^(?::all|yield)$/) {
62             push(@EXPORT, qw(yield));
63
64         } else {
65             require Carp;
66             Carp::croak("threads: Unknown import option: $sym");
67         }
68     }
69
70     # Export subroutine names
71     my $caller = caller();
72     foreach my $sym (@EXPORT) {
73         no strict 'refs';
74         *{$caller.'::'.$sym} = \&{$sym};
75     }
76
77     # Set stack size via environment variable
78     if (exists($ENV{'PERL5_ITHREADS_STACK_SIZE'})) {
79         threads->set_stack_size($ENV{'PERL5_ITHREADS_STACK_SIZE'});
80     }
81 }
82
83
84 ### Methods, etc. ###
85
86 # Exit from a thread (only)
87 sub exit
88 {
89     my ($class, $status) = @_;
90     if (! defined($status)) {
91         $status = 0;
92     }
93
94     # Class method only
95     if (ref($class)) {
96         require Carp;
97         Carp::croak('Usage: threads->exit(status)');
98     }
99
100     $class->set_thread_exit_only(1);
101     CORE::exit($status);
102 }
103
104 # 'Constant' args for threads->list()
105 sub threads::all      { }
106 sub threads::running  { 1 }
107 sub threads::joinable { 0 }
108
109 # 'new' is an alias for 'create'
110 *new = \&create;
111
112 # 'async' is a function alias for the 'threads->create()' method
113 sub async (&;@)
114 {
115     unshift(@_, 'threads');
116     # Use "goto" trick to avoid pad problems from 5.8.1 (fixed in 5.8.2)
117     goto &create;
118 }
119
120 # Thread object equality checking
121 use overload (
122     '==' => \&equal,
123     '!=' => sub { ! equal(@_) },
124     'fallback' => 1
125 );
126
127 1;
128
129 __END__
130
131 =head1 NAME
132
133 threads - Perl interpreter-based threads
134
135 =head1 VERSION
136
137 This document describes threads version 2.21
138
139 =head1 WARNING
140
141 The "interpreter-based threads" provided by Perl are not the fast, lightweight
142 system for multitasking that one might expect or hope for.  Threads are
143 implemented in a way that make them easy to misuse.  Few people know how to
144 use them correctly or will be able to provide help.
145
146 The use of interpreter-based threads in perl is officially
147 L<discouraged|perlpolicy/discouraged>.
148
149 =head1 SYNOPSIS
150
151     use threads ('yield',
152                  'stack_size' => 64*4096,
153                  'exit' => 'threads_only',
154                  'stringify');
155
156     sub start_thread {
157         my @args = @_;
158         print('Thread started: ', join(' ', @args), "\n");
159     }
160     my $thr = threads->create('start_thread', 'argument');
161     $thr->join();
162
163     threads->create(sub { print("I am a thread\n"); })->join();
164
165     my $thr2 = async { foreach (@files) { ... } };
166     $thr2->join();
167     if (my $err = $thr2->error()) {
168         warn("Thread error: $err\n");
169     }
170
171     # Invoke thread in list context (implicit) so it can return a list
172     my ($thr) = threads->create(sub { return (qw/a b c/); });
173     # or specify list context explicitly
174     my $thr = threads->create({'context' => 'list'},
175                               sub { return (qw/a b c/); });
176     my @results = $thr->join();
177
178     $thr->detach();
179
180     # Get a thread's object
181     $thr = threads->self();
182     $thr = threads->object($tid);
183
184     # Get a thread's ID
185     $tid = threads->tid();
186     $tid = $thr->tid();
187     $tid = "$thr";
188
189     # Give other threads a chance to run
190     threads->yield();
191     yield();
192
193     # Lists of non-detached threads
194     my @threads = threads->list();
195     my $thread_count = threads->list();
196
197     my @running = threads->list(threads::running);
198     my @joinable = threads->list(threads::joinable);
199
200     # Test thread objects
201     if ($thr1 == $thr2) {
202         ...
203     }
204
205     # Manage thread stack size
206     $stack_size = threads->get_stack_size();
207     $old_size = threads->set_stack_size(32*4096);
208
209     # Create a thread with a specific context and stack size
210     my $thr = threads->create({ 'context'    => 'list',
211                                 'stack_size' => 32*4096,
212                                 'exit'       => 'thread_only' },
213                               \&foo);
214
215     # Get thread's context
216     my $wantarray = $thr->wantarray();
217
218     # Check thread's state
219     if ($thr->is_running()) {
220         sleep(1);
221     }
222     if ($thr->is_joinable()) {
223         $thr->join();
224     }
225
226     # Send a signal to a thread
227     $thr->kill('SIGUSR1');
228
229     # Exit a thread
230     threads->exit();
231
232 =head1 DESCRIPTION
233
234 Since Perl 5.8, thread programming has been available using a model called
235 I<interpreter threads> which provides a new Perl interpreter for each
236 thread, and, by default, results in no data or state information being shared
237 between threads.
238
239 (Prior to Perl 5.8, I<5005threads> was available through the C<Thread.pm> API.
240 This threading model has been deprecated, and was removed as of Perl 5.10.0.)
241
242 As just mentioned, all variables are, by default, thread local.  To use shared
243 variables, you need to also load L<threads::shared>:
244
245     use threads;
246     use threads::shared;
247
248 When loading L<threads::shared>, you must C<use threads> before you
249 C<use threads::shared>.  (C<threads> will emit a warning if you do it the
250 other way around.)
251
252 It is strongly recommended that you enable threads via C<use threads> as early
253 as possible in your script.
254
255 If needed, scripts can be written so as to run on both threaded and
256 non-threaded Perls:
257
258     my $can_use_threads = eval 'use threads; 1';
259     if ($can_use_threads) {
260         # Do processing using threads
261         ...
262     } else {
263         # Do it without using threads
264         ...
265     }
266
267 =over
268
269 =item $thr = threads->create(FUNCTION, ARGS)
270
271 This will create a new thread that will begin execution with the specified
272 entry point function, and give it the I<ARGS> list as parameters.  It will
273 return the corresponding threads object, or C<undef> if thread creation failed.
274
275 I<FUNCTION> may either be the name of a function, an anonymous subroutine, or
276 a code ref.
277
278     my $thr = threads->create('func_name', ...);
279         # or
280     my $thr = threads->create(sub { ... }, ...);
281         # or
282     my $thr = threads->create(\&func, ...);
283
284 The C<-E<gt>new()> method is an alias for C<-E<gt>create()>.
285
286 =item $thr->join()
287
288 This will wait for the corresponding thread to complete its execution.  When
289 the thread finishes, C<-E<gt>join()> will return the return value(s) of the
290 entry point function.
291
292 The context (void, scalar or list) for the return value(s) for C<-E<gt>join()>
293 is determined at the time of thread creation.
294
295     # Create thread in list context (implicit)
296     my ($thr1) = threads->create(sub {
297                                     my @results = qw(a b c);
298                                     return (@results);
299                                  });
300     #   or (explicit)
301     my $thr1 = threads->create({'context' => 'list'},
302                                sub {
303                                     my @results = qw(a b c);
304                                     return (@results);
305                                });
306     # Retrieve list results from thread
307     my @res1 = $thr1->join();
308
309     # Create thread in scalar context (implicit)
310     my $thr2 = threads->create(sub {
311                                     my $result = 42;
312                                     return ($result);
313                                  });
314     # Retrieve scalar result from thread
315     my $res2 = $thr2->join();
316
317     # Create a thread in void context (explicit)
318     my $thr3 = threads->create({'void' => 1},
319                                sub { print("Hello, world\n"); });
320     # Join the thread in void context (i.e., no return value)
321     $thr3->join();
322
323 See L</"THREAD CONTEXT"> for more details.
324
325 If the program exits without all threads having either been joined or
326 detached, then a warning will be issued.
327
328 Calling C<-E<gt>join()> or C<-E<gt>detach()> on an already joined thread will
329 cause an error to be thrown.
330
331 =item $thr->detach()
332
333 Makes the thread unjoinable, and causes any eventual return value to be
334 discarded.  When the program exits, any detached threads that are still
335 running are silently terminated.
336
337 If the program exits without all threads having either been joined or
338 detached, then a warning will be issued.
339
340 Calling C<-E<gt>join()> or C<-E<gt>detach()> on an already detached thread
341 will cause an error to be thrown.
342
343 =item threads->detach()
344
345 Class method that allows a thread to detach itself.
346
347 =item threads->self()
348
349 Class method that allows a thread to obtain its own I<threads> object.
350
351 =item $thr->tid()
352
353 Returns the ID of the thread.  Thread IDs are unique integers with the main
354 thread in a program being 0, and incrementing by 1 for every thread created.
355
356 =item threads->tid()
357
358 Class method that allows a thread to obtain its own ID.
359
360 =item "$thr"
361
362 If you add the C<stringify> import option to your C<use threads> declaration,
363 then using a threads object in a string or a string context (e.g., as a hash
364 key) will cause its ID to be used as the value:
365
366     use threads qw(stringify);
367
368     my $thr = threads->create(...);
369     print("Thread $thr started\n");  # Prints: Thread 1 started
370
371 =item threads->object($tid)
372
373 This will return the I<threads> object for the I<active> thread associated
374 with the specified thread ID.  If C<$tid> is the value for the current thread,
375 then this call works the same as C<-E<gt>self()>.  Otherwise, returns C<undef>
376 if there is no thread associated with the TID, if the thread is joined or
377 detached, if no TID is specified or if the specified TID is undef.
378
379 =item threads->yield()
380
381 This is a suggestion to the OS to let this thread yield CPU time to other
382 threads.  What actually happens is highly dependent upon the underlying
383 thread implementation.
384
385 You may do C<use threads qw(yield)>, and then just use C<yield()> in your
386 code.
387
388 =item threads->list()
389
390 =item threads->list(threads::all)
391
392 =item threads->list(threads::running)
393
394 =item threads->list(threads::joinable)
395
396 With no arguments (or using C<threads::all>) and in a list context, returns a
397 list of all non-joined, non-detached I<threads> objects.  In a scalar context,
398 returns a count of the same.
399
400 With a I<true> argument (using C<threads::running>), returns a list of all
401 non-joined, non-detached I<threads> objects that are still running.
402
403 With a I<false> argument (using C<threads::joinable>), returns a list of all
404 non-joined, non-detached I<threads> objects that have finished running (i.e.,
405 for which C<-E<gt>join()> will not I<block>).
406
407 =item $thr1->equal($thr2)
408
409 Tests if two threads objects are the same thread or not.  This is overloaded
410 to the more natural forms:
411
412     if ($thr1 == $thr2) {
413         print("Threads are the same\n");
414     }
415     # or
416     if ($thr1 != $thr2) {
417         print("Threads differ\n");
418     }
419
420 (Thread comparison is based on thread IDs.)
421
422 =item async BLOCK;
423
424 C<async> creates a thread to execute the block immediately following
425 it.  This block is treated as an anonymous subroutine, and so must have a
426 semicolon after the closing brace.  Like C<threads-E<gt>create()>, C<async>
427 returns a I<threads> object.
428
429 =item $thr->error()
430
431 Threads are executed in an C<eval> context.  This method will return C<undef>
432 if the thread terminates I<normally>.  Otherwise, it returns the value of
433 C<$@> associated with the thread's execution status in its C<eval> context.
434
435 =item $thr->_handle()
436
437 This I<private> method returns a pointer (i.e., the memory location expressed
438 as an unsigned integer) to the internal thread structure associated with a
439 threads object.  For Win32, this is a pointer to the C<HANDLE> value returned
440 by C<CreateThread> (i.e., C<HANDLE *>); for other platforms, it is a pointer
441 to the C<pthread_t> structure used in the C<pthread_create> call (i.e.,
442 C<pthread_t *>).
443
444 This method is of no use for general Perl threads programming.  Its intent is
445 to provide other (XS-based) thread modules with the capability to access, and
446 possibly manipulate, the underlying thread structure associated with a Perl
447 thread.
448
449 =item threads->_handle()
450
451 Class method that allows a thread to obtain its own I<handle>.
452
453 =back
454
455 =head1 EXITING A THREAD
456
457 The usual method for terminating a thread is to
458 L<return()|perlfunc/"return EXPR"> from the entry point function with the
459 appropriate return value(s).
460
461 =over
462
463 =item threads->exit()
464
465 If needed, a thread can be exited at any time by calling
466 C<threads-E<gt>exit()>.  This will cause the thread to return C<undef> in a
467 scalar context, or the empty list in a list context.
468
469 When called from the I<main> thread, this behaves the same as C<exit(0)>.
470
471 =item threads->exit(status)
472
473 When called from a thread, this behaves like C<threads-E<gt>exit()> (i.e., the
474 exit status code is ignored).
475
476 When called from the I<main> thread, this behaves the same as C<exit(status)>.
477
478 =item die()
479
480 Calling C<die()> in a thread indicates an abnormal exit for the thread.  Any
481 C<$SIG{__DIE__}> handler in the thread will be called first, and then the
482 thread will exit with a warning message that will contain any arguments passed
483 in the C<die()> call.
484
485 =item exit(status)
486
487 Calling L<exit()|perlfunc/"exit EXPR"> inside a thread causes the whole
488 application to terminate.  Because of this, the use of C<exit()> inside
489 threaded code, or in modules that might be used in threaded applications, is
490 strongly discouraged.
491
492 If C<exit()> really is needed, then consider using the following:
493
494     threads->exit() if threads->can('exit');   # Thread friendly
495     exit(status);
496
497 =item use threads 'exit' => 'threads_only'
498
499 This globally overrides the default behavior of calling C<exit()> inside a
500 thread, and effectively causes such calls to behave the same as
501 C<threads-E<gt>exit()>.  In other words, with this setting, calling C<exit()>
502 causes only the thread to terminate.
503
504 Because of its global effect, this setting should not be used inside modules
505 or the like.
506
507 The I<main> thread is unaffected by this setting.
508
509 =item threads->create({'exit' => 'thread_only'}, ...)
510
511 This overrides the default behavior of C<exit()> inside the newly created
512 thread only.
513
514 =item $thr->set_thread_exit_only(boolean)
515
516 This can be used to change the I<exit thread only> behavior for a thread after
517 it has been created.  With a I<true> argument, C<exit()> will cause only the
518 thread to exit.  With a I<false> argument, C<exit()> will terminate the
519 application.
520
521 The I<main> thread is unaffected by this call.
522
523 =item threads->set_thread_exit_only(boolean)
524
525 Class method for use inside a thread to change its own behavior for C<exit()>.
526
527 The I<main> thread is unaffected by this call.
528
529 =back
530
531 =head1 THREAD STATE
532
533 The following boolean methods are useful in determining the I<state> of a
534 thread.
535
536 =over
537
538 =item $thr->is_running()
539
540 Returns true if a thread is still running (i.e., if its entry point function
541 has not yet finished or exited).
542
543 =item $thr->is_joinable()
544
545 Returns true if the thread has finished running, is not detached and has not
546 yet been joined.  In other words, the thread is ready to be joined, and a call
547 to C<$thr-E<gt>join()> will not I<block>.
548
549 =item $thr->is_detached()
550
551 Returns true if the thread has been detached.
552
553 =item threads->is_detached()
554
555 Class method that allows a thread to determine whether or not it is detached.
556
557 =back
558
559 =head1 THREAD CONTEXT
560
561 As with subroutines, the type of value returned from a thread's entry point
562 function may be determined by the thread's I<context>:  list, scalar or void.
563 The thread's context is determined at thread creation.  This is necessary so
564 that the context is available to the entry point function via
565 L<wantarray()|perlfunc/"wantarray">.  The thread may then specify a value of
566 the appropriate type to be returned from C<-E<gt>join()>.
567
568 =head2 Explicit context
569
570 Because thread creation and thread joining may occur in different contexts, it
571 may be desirable to state the context explicitly to the thread's entry point
572 function.  This may be done by calling C<-E<gt>create()> with a hash reference
573 as the first argument:
574
575     my $thr = threads->create({'context' => 'list'}, \&foo);
576     ...
577     my @results = $thr->join();
578
579 In the above, the threads object is returned to the parent thread in scalar
580 context, and the thread's entry point function C<foo> will be called in list
581 (array) context such that the parent thread can receive a list (array) from
582 the C<-E<gt>join()> call.  (C<'array'> is synonymous with C<'list'>.)
583
584 Similarly, if you need the threads object, but your thread will not be
585 returning a value (i.e., I<void> context), you would do the following:
586
587     my $thr = threads->create({'context' => 'void'}, \&foo);
588     ...
589     $thr->join();
590
591 The context type may also be used as the I<key> in the hash reference followed
592 by a I<true> value:
593
594     threads->create({'scalar' => 1}, \&foo);
595     ...
596     my ($thr) = threads->list();
597     my $result = $thr->join();
598
599 =head2 Implicit context
600
601 If not explicitly stated, the thread's context is implied from the context
602 of the C<-E<gt>create()> call:
603
604     # Create thread in list context
605     my ($thr) = threads->create(...);
606
607     # Create thread in scalar context
608     my $thr = threads->create(...);
609
610     # Create thread in void context
611     threads->create(...);
612
613 =head2 $thr->wantarray()
614
615 This returns the thread's context in the same manner as
616 L<wantarray()|perlfunc/"wantarray">.
617
618 =head2 threads->wantarray()
619
620 Class method to return the current thread's context.  This returns the same
621 value as running L<wantarray()|perlfunc/"wantarray"> inside the current
622 thread's entry point function.
623
624 =head1 THREAD STACK SIZE
625
626 The default per-thread stack size for different platforms varies
627 significantly, and is almost always far more than is needed for most
628 applications.  On Win32, Perl's makefile explicitly sets the default stack to
629 16 MB; on most other platforms, the system default is used, which again may be
630 much larger than is needed.
631
632 By tuning the stack size to more accurately reflect your application's needs,
633 you may significantly reduce your application's memory usage, and increase the
634 number of simultaneously running threads.
635
636 Note that on Windows, address space allocation granularity is 64 KB,
637 therefore, setting the stack smaller than that on Win32 Perl will not save any
638 more memory.
639
640 =over
641
642 =item threads->get_stack_size();
643
644 Returns the current default per-thread stack size.  The default is zero, which
645 means the system default stack size is currently in use.
646
647 =item $size = $thr->get_stack_size();
648
649 Returns the stack size for a particular thread.  A return value of zero
650 indicates the system default stack size was used for the thread.
651
652 =item $old_size = threads->set_stack_size($new_size);
653
654 Sets a new default per-thread stack size, and returns the previous setting.
655
656 Some platforms have a minimum thread stack size.  Trying to set the stack size
657 below this value will result in a warning, and the minimum stack size will be
658 used.
659
660 Some Linux platforms have a maximum stack size.  Setting too large of a stack
661 size will cause thread creation to fail.
662
663 If needed, C<$new_size> will be rounded up to the next multiple of the memory
664 page size (usually 4096 or 8192).
665
666 Threads created after the stack size is set will then either call
667 C<pthread_attr_setstacksize()> I<(for pthreads platforms)>, or supply the
668 stack size to C<CreateThread()> I<(for Win32 Perl)>.
669
670 (Obviously, this call does not affect any currently extant threads.)
671
672 =item use threads ('stack_size' => VALUE);
673
674 This sets the default per-thread stack size at the start of the application.
675
676 =item $ENV{'PERL5_ITHREADS_STACK_SIZE'}
677
678 The default per-thread stack size may be set at the start of the application
679 through the use of the environment variable C<PERL5_ITHREADS_STACK_SIZE>:
680
681     PERL5_ITHREADS_STACK_SIZE=1048576
682     export PERL5_ITHREADS_STACK_SIZE
683     perl -e'use threads; print(threads->get_stack_size(), "\n")'
684
685 This value overrides any C<stack_size> parameter given to C<use threads>.  Its
686 primary purpose is to permit setting the per-thread stack size for legacy
687 threaded applications.
688
689 =item threads->create({'stack_size' => VALUE}, FUNCTION, ARGS)
690
691 To specify a particular stack size for any individual thread, call
692 C<-E<gt>create()> with a hash reference as the first argument:
693
694     my $thr = threads->create({'stack_size' => 32*4096},
695                               \&foo, @args);
696
697 =item $thr2 = $thr1->create(FUNCTION, ARGS)
698
699 This creates a new thread (C<$thr2>) that inherits the stack size from an
700 existing thread (C<$thr1>).  This is shorthand for the following:
701
702     my $stack_size = $thr1->get_stack_size();
703     my $thr2 = threads->create({'stack_size' => $stack_size},
704                                FUNCTION, ARGS);
705
706 =back
707
708 =head1 THREAD SIGNALLING
709
710 When safe signals is in effect (the default behavior - see L</"Unsafe signals">
711 for more details), then signals may be sent and acted upon by individual
712 threads.
713
714 =over 4
715
716 =item $thr->kill('SIG...');
717
718 Sends the specified signal to the thread.  Signal names and (positive) signal
719 numbers are the same as those supported by
720 L<kill()|perlfunc/"kill SIGNAL, LIST">.  For example, 'SIGTERM', 'TERM' and
721 (depending on the OS) 15 are all valid arguments to C<-E<gt>kill()>.
722
723 Returns the thread object to allow for method chaining:
724
725     $thr->kill('SIG...')->join();
726
727 =back
728
729 Signal handlers need to be set up in the threads for the signals they are
730 expected to act upon.  Here's an example for I<cancelling> a thread:
731
732     use threads;
733
734     sub thr_func
735     {
736         # Thread 'cancellation' signal handler
737         $SIG{'KILL'} = sub { threads->exit(); };
738
739         ...
740     }
741
742     # Create a thread
743     my $thr = threads->create('thr_func');
744
745     ...
746
747     # Signal the thread to terminate, and then detach
748     # it so that it will get cleaned up automatically
749     $thr->kill('KILL')->detach();
750
751 Here's another simplistic example that illustrates the use of thread
752 signalling in conjunction with a semaphore to provide rudimentary I<suspend>
753 and I<resume> capabilities:
754
755     use threads;
756     use Thread::Semaphore;
757
758     sub thr_func
759     {
760         my $sema = shift;
761
762         # Thread 'suspend/resume' signal handler
763         $SIG{'STOP'} = sub {
764             $sema->down();      # Thread suspended
765             $sema->up();        # Thread resumes
766         };
767
768         ...
769     }
770
771     # Create a semaphore and pass it to a thread
772     my $sema = Thread::Semaphore->new();
773     my $thr = threads->create('thr_func', $sema);
774
775     # Suspend the thread
776     $sema->down();
777     $thr->kill('STOP');
778
779     ...
780
781     # Allow the thread to continue
782     $sema->up();
783
784 CAVEAT:  The thread signalling capability provided by this module does not
785 actually send signals via the OS.  It I<emulates> signals at the Perl-level
786 such that signal handlers are called in the appropriate thread.  For example,
787 sending C<$thr-E<gt>kill('STOP')> does not actually suspend a thread (or the
788 whole process), but does cause a C<$SIG{'STOP'}> handler to be called in that
789 thread (as illustrated above).
790
791 As such, signals that would normally not be appropriate to use in the
792 C<kill()> command (e.g., C<kill('KILL', $$)>) are okay to use with the
793 C<-E<gt>kill()> method (again, as illustrated above).
794
795 Correspondingly, sending a signal to a thread does not disrupt the operation
796 the thread is currently working on:  The signal will be acted upon after the
797 current operation has completed.  For instance, if the thread is I<stuck> on
798 an I/O call, sending it a signal will not cause the I/O call to be interrupted
799 such that the signal is acted up immediately.
800
801 Sending a signal to a terminated/finished thread is ignored.
802
803 =head1 WARNINGS
804
805 =over 4
806
807 =item Perl exited with active threads:
808
809 If the program exits without all threads having either been joined or
810 detached, then this warning will be issued.
811
812 NOTE:  If the I<main> thread exits, then this warning cannot be suppressed
813 using C<no warnings 'threads';> as suggested below.
814
815 =item Thread creation failed: pthread_create returned #
816
817 See the appropriate I<man> page for C<pthread_create> to determine the actual
818 cause for the failure.
819
820 =item Thread # terminated abnormally: ...
821
822 A thread terminated in some manner other than just returning from its entry
823 point function, or by using C<threads-E<gt>exit()>.  For example, the thread
824 may have terminated because of an error, or by using C<die>.
825
826 =item Using minimum thread stack size of #
827
828 Some platforms have a minimum thread stack size.  Trying to set the stack size
829 below this value will result in the above warning, and the stack size will be
830 set to the minimum.
831
832 =item Thread creation failed: pthread_attr_setstacksize(I<SIZE>) returned 22
833
834 The specified I<SIZE> exceeds the system's maximum stack size.  Use a smaller
835 value for the stack size.
836
837 =back
838
839 If needed, thread warnings can be suppressed by using:
840
841     no warnings 'threads';
842
843 in the appropriate scope.
844
845 =head1 ERRORS
846
847 =over 4
848
849 =item This Perl not built to support threads
850
851 The particular copy of Perl that you're trying to use was not built using the
852 C<useithreads> configuration option.
853
854 Having threads support requires all of Perl and all of the XS modules in the
855 Perl installation to be rebuilt; it is not just a question of adding the
856 L<threads> module (i.e., threaded and non-threaded Perls are binary
857 incompatible).
858
859 =item Cannot change stack size of an existing thread
860
861 The stack size of currently extant threads cannot be changed, therefore, the
862 following results in the above error:
863
864     $thr->set_stack_size($size);
865
866 =item Cannot signal threads without safe signals
867
868 Safe signals must be in effect to use the C<-E<gt>kill()> signalling method.
869 See L</"Unsafe signals"> for more details.
870
871 =item Unrecognized signal name: ...
872
873 The particular copy of Perl that you're trying to use does not support the
874 specified signal being used in a C<-E<gt>kill()> call.
875
876 =back
877
878 =head1 BUGS AND LIMITATIONS
879
880 Before you consider posting a bug report, please consult, and possibly post a
881 message to the discussion forum to see if what you've encountered is a known
882 problem.
883
884 =over
885
886 =item Thread-safe modules
887
888 See L<perlmod/"Making your module threadsafe"> when creating modules that may
889 be used in threaded applications, especially if those modules use non-Perl
890 data, or XS code.
891
892 =item Using non-thread-safe modules
893
894 Unfortunately, you may encounter Perl modules that are not I<thread-safe>.
895 For example, they may crash the Perl interpreter during execution, or may dump
896 core on termination.  Depending on the module and the requirements of your
897 application, it may be possible to work around such difficulties.
898
899 If the module will only be used inside a thread, you can try loading the
900 module from inside the thread entry point function using C<require> (and
901 C<import> if needed):
902
903     sub thr_func
904     {
905         require Unsafe::Module
906         # Unsafe::Module->import(...);
907
908         ....
909     }
910
911 If the module is needed inside the I<main> thread, try modifying your
912 application so that the module is loaded (again using C<require> and
913 C<-E<gt>import()>) after any threads are started, and in such a way that no
914 other threads are started afterwards.
915
916 If the above does not work, or is not adequate for your application, then file
917 a bug report on L<http://rt.cpan.org/Public/> against the problematic module.
918
919 =item Memory consumption
920
921 On most systems, frequent and continual creation and destruction of threads
922 can lead to ever-increasing growth in the memory footprint of the Perl
923 interpreter.  While it is simple to just launch threads and then
924 C<-E<gt>join()> or C<-E<gt>detach()> them, for long-lived applications, it is
925 better to maintain a pool of threads, and to reuse them for the work needed,
926 using L<queues|Thread::Queue> to notify threads of pending work.  The CPAN
927 distribution of this module contains a simple example
928 (F<examples/pool_reuse.pl>) illustrating the creation, use and monitoring of a
929 pool of I<reusable> threads.
930
931 =item Current working directory
932
933 On all platforms except MSWin32, the setting for the current working directory
934 is shared among all threads such that changing it in one thread (e.g., using
935 C<chdir()>) will affect all the threads in the application.
936
937 On MSWin32, each thread maintains its own the current working directory
938 setting.
939
940 =item Locales
941
942 Prior to Perl 5.28, locales could not be used with threads, due to various
943 race conditions.  Starting in that release, on systems that implement
944 thread-safe locale functions, threads can be used, with some caveats.
945 This includes Windows starting with Visual Studio 2005, and systems compatible
946 with POSIX 2008.  See L<perllocale/Multi-threaded operation>.
947
948 Each thread (except the main thread) is started using the C locale.  The main
949 thread is started like all other Perl programs; see L<perllocale/ENVIRONMENT>.
950 You can switch locales in any thread as often as you like.
951
952 If you want to inherit the parent thread's locale, you can, in the parent, set
953 a variable like so:
954
955     $foo = POSIX::setlocale(LC_ALL, NULL);
956
957 and then pass to threads->create() a sub that closes over C<$foo>.  Then, in
958 the child, you say
959
960     POSIX::setlocale(LC_ALL, $foo);
961
962 Or you can use the facilities in L<threads::shared> to pass C<$foo>;
963 or if the environment hasn't changed, in the child, do
964
965     POSIX::setlocale(LC_ALL, "");
966
967 =item Environment variables
968
969 Currently, on all platforms except MSWin32, all I<system> calls (e.g., using
970 C<system()> or back-ticks) made from threads use the environment variable
971 settings from the I<main> thread.  In other words, changes made to C<%ENV> in
972 a thread will not be visible in I<system> calls made by that thread.
973
974 To work around this, set environment variables as part of the I<system> call.
975 For example:
976
977     my $msg = 'hello';
978     system("FOO=$msg; echo \$FOO");   # Outputs 'hello' to STDOUT
979
980 On MSWin32, each thread maintains its own set of environment variables.
981
982 =item Catching signals
983
984 Signals are I<caught> by the main thread (thread ID = 0) of a script.
985 Therefore, setting up signal handlers in threads for purposes other than
986 L</"THREAD SIGNALLING"> as documented above will not accomplish what is
987 intended.
988
989 This is especially true if trying to catch C<SIGALRM> in a thread.  To handle
990 alarms in threads, set up a signal handler in the main thread, and then use
991 L</"THREAD SIGNALLING"> to relay the signal to the thread:
992
993   # Create thread with a task that may time out
994   my $thr = threads->create(sub {
995       threads->yield();
996       eval {
997           $SIG{ALRM} = sub { die("Timeout\n"); };
998           alarm(10);
999           ...  # Do work here
1000           alarm(0);
1001       };
1002       if ($@ =~ /Timeout/) {
1003           warn("Task in thread timed out\n");
1004       }
1005   };
1006
1007   # Set signal handler to relay SIGALRM to thread
1008   $SIG{ALRM} = sub { $thr->kill('ALRM') };
1009
1010   ... # Main thread continues working
1011
1012 =item Parent-child threads
1013
1014 On some platforms, it might not be possible to destroy I<parent> threads while
1015 there are still existing I<child> threads.
1016
1017 =item Unsafe signals
1018
1019 Since Perl 5.8.0, signals have been made safer in Perl by postponing their
1020 handling until the interpreter is in a I<safe> state.  See
1021 L<perl58delta/"Safe Signals"> and L<perlipc/"Deferred Signals (Safe Signals)">
1022 for more details.
1023
1024 Safe signals is the default behavior, and the old, immediate, unsafe
1025 signalling behavior is only in effect in the following situations:
1026
1027 =over 4
1028
1029 =item * Perl has been built with C<PERL_OLD_SIGNALS> (see C<perl -V>).
1030
1031 =item * The environment variable C<PERL_SIGNALS> is set to C<unsafe>
1032 (see L<perlrun/"PERL_SIGNALS">).
1033
1034 =item * The module L<Perl::Unsafe::Signals> is used.
1035
1036 =back
1037
1038 If unsafe signals is in effect, then signal handling is not thread-safe, and
1039 the C<-E<gt>kill()> signalling method cannot be used.
1040
1041 =item Identity of objects returned from threads
1042
1043 When a value is returned from a thread through a C<join> operation,
1044 the value and everything that it references is copied across to the
1045 joining thread, in much the same way that values are copied upon thread
1046 creation.  This works fine for most kinds of value, including arrays,
1047 hashes, and subroutines.  The copying recurses through array elements,
1048 reference scalars, variables closed over by subroutines, and other kinds
1049 of reference.
1050
1051 However, everything referenced by the returned value is a fresh copy in
1052 the joining thread, even if a returned object had in the child thread
1053 been a copy of something that previously existed in the parent thread.
1054 After joining, the parent will therefore have a duplicate of each such
1055 object.  This sometimes matters, especially if the object gets mutated;
1056 this can especially matter for private data to which a returned subroutine
1057 provides access.
1058
1059 =item Returning blessed objects from threads
1060
1061 Returning blessed objects from threads does not work.  Depending on the classes
1062 involved, you may be able to work around this by returning a serialized
1063 version of the object (e.g., using L<Data::Dumper> or L<Storable>), and then
1064 reconstituting it in the joining thread.  If you're using Perl 5.10.0 or
1065 later, and if the class supports L<shared objects|threads::shared/"OBJECTS">,
1066 you can pass them via L<shared queues|Thread::Queue>.
1067
1068 =item END blocks in threads
1069
1070 It is possible to add L<END blocks|perlmod/"BEGIN, UNITCHECK, CHECK, INIT and
1071 END"> to threads by using L<require|perlfunc/"require VERSION"> or
1072 L<eval|perlfunc/"eval EXPR"> with the appropriate code.  These C<END> blocks
1073 will then be executed when the thread's interpreter is destroyed (i.e., either
1074 during a C<-E<gt>join()> call, or at program termination).
1075
1076 However, calling any L<threads> methods in such an C<END> block will most
1077 likely I<fail> (e.g., the application may hang, or generate an error) due to
1078 mutexes that are needed to control functionality within the L<threads> module.
1079
1080 For this reason, the use of C<END> blocks in threads is B<strongly>
1081 discouraged.
1082
1083 =item Open directory handles
1084
1085 In perl 5.14 and higher, on systems other than Windows that do
1086 not support the C<fchdir> C function, directory handles (see
1087 L<opendir|perlfunc/"opendir DIRHANDLE,EXPR">) will not be copied to new
1088 threads. You can use the C<d_fchdir> variable in L<Config.pm|Config> to
1089 determine whether your system supports it.
1090
1091 In prior perl versions, spawning threads with open directory handles would
1092 crash the interpreter.
1093 L<[perl #75154]|http://rt.perl.org/rt3/Public/Bug/Display.html?id=75154>
1094
1095 =item Detached threads and global destruction
1096
1097 If the main thread exits while there are detached threads which are still
1098 running, then Perl's global destruction phase is not executed because
1099 otherwise certain global structures that control the operation of threads and
1100 that are allocated in the main thread's memory may get destroyed before the
1101 detached thread is destroyed.
1102
1103 If you are using any code that requires the execution of the global
1104 destruction phase for clean up (e.g., removing temp files), then do not use
1105 detached threads, but rather join all threads before exiting the program.
1106
1107 =item Perl Bugs and the CPAN Version of L<threads>
1108
1109 Support for threads extends beyond the code in this module (i.e.,
1110 F<threads.pm> and F<threads.xs>), and into the Perl interpreter itself.  Older
1111 versions of Perl contain bugs that may manifest themselves despite using the
1112 latest version of L<threads> from CPAN.  There is no workaround for this other
1113 than upgrading to the latest version of Perl.
1114
1115 Even with the latest version of Perl, it is known that certain constructs
1116 with threads may result in warning messages concerning leaked scalars or
1117 unreferenced scalars.  However, such warnings are harmless, and may safely be
1118 ignored.
1119
1120 You can search for L<threads> related bug reports at
1121 L<http://rt.cpan.org/Public/>.  If needed submit any new bugs, problems,
1122 patches, etc. to: L<http://rt.cpan.org/Public/Dist/Display.html?Name=threads>
1123
1124 =back
1125
1126 =head1 REQUIREMENTS
1127
1128 Perl 5.8.0 or later
1129
1130 =head1 SEE ALSO
1131
1132 threads on MetaCPAN:
1133 L<https://metacpan.org/release/threads>
1134
1135 Code repository for CPAN distribution:
1136 L<https://github.com/Dual-Life/threads>
1137
1138 L<threads::shared>, L<perlthrtut>
1139
1140 L<http://www.perl.com/pub/a/2002/06/11/threads.html> and
1141 L<http://www.perl.com/pub/a/2002/09/04/threads.html>
1142
1143 Perl threads mailing list:
1144 L<http://lists.perl.org/list/ithreads.html>
1145
1146 Stack size discussion:
1147 L<http://www.perlmonks.org/?node_id=532956>
1148
1149 Sample code in the I<examples> directory of this distribution on CPAN.
1150
1151 =head1 AUTHOR
1152
1153 Artur Bergman E<lt>sky AT crucially DOT netE<gt>
1154
1155 CPAN version produced by Jerry D. Hedden <jdhedden AT cpan DOT org>
1156
1157 =head1 LICENSE
1158
1159 threads is released under the same license as Perl.
1160
1161 =head1 ACKNOWLEDGEMENTS
1162
1163 Richard Soderberg E<lt>perl AT crystalflame DOT netE<gt> -
1164 Helping me out tons, trying to find reasons for races and other weird bugs!
1165
1166 Simon Cozens E<lt>simon AT brecon DOT co DOT ukE<gt> -
1167 Being there to answer zillions of annoying questions
1168
1169 Rocco Caputo E<lt>troc AT netrus DOT netE<gt>
1170
1171 Vipul Ved Prakash E<lt>mail AT vipul DOT netE<gt> -
1172 Helping with debugging
1173
1174 Dean Arnold E<lt>darnold AT presicient DOT comE<gt> -
1175 Stack size API
1176
1177 =cut