This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Improve warnings about known issues in (?{...}) blocks in the regex engine
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start or end of the string to matching the start or end of any
35 line anywhere within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as /ms, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If C<use locale> is in effect, the case map is taken from the current
55 locale.  See L<perllocale>.
56
57 =item x
58 X</x>
59
60 Extend your pattern's legibility by permitting whitespace and comments.
61
62 =item p
63 X</p> X<regex, preserve> X<regexp, preserve>
64
65 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
66 ${^POSTMATCH} are available for use after matching.
67
68 =item g and c
69 X</g> X</c>
70
71 Global matching, and keep the Current position after failed matching.
72 Unlike i, m, s and x, these two flags affect the way the regex is used
73 rather than the regex itself. See
74 L<perlretut/"Using regular expressions in Perl"> for further explanation
75 of the g and c modifiers.
76
77 =back
78
79 These are usually written as "the C</x> modifier", even though the delimiter
80 in question might not really be a slash.  Any of these
81 modifiers may also be embedded within the regular expression itself using
82 the C<(?...)> construct.  See below.
83
84 The C</x> modifier itself needs a little more explanation.  It tells
85 the regular expression parser to ignore whitespace that is neither
86 backslashed nor within a character class.  You can use this to break up
87 your regular expression into (slightly) more readable parts.  The C<#>
88 character is also treated as a metacharacter introducing a comment,
89 just as in ordinary Perl code.  This also means that if you want real
90 whitespace or C<#> characters in the pattern (outside a character
91 class, where they are unaffected by C</x>), then you'll either have to
92 escape them (using backslashes or C<\Q...\E>) or encode them using octal
93 or hex escapes.  Taken together, these features go a long way towards
94 making Perl's regular expressions more readable.  Note that you have to
95 be careful not to include the pattern delimiter in the comment--perl has
96 no way of knowing you did not intend to close the pattern early.  See
97 the C-comment deletion code in L<perlop>.  Also note that anything inside
98 a C<\Q...\E> stays unaffected by C</x>.
99 X</x>
100
101 =head2 Regular Expressions
102
103 =head3 Metacharacters
104
105 The patterns used in Perl pattern matching evolved from those supplied in
106 the Version 8 regex routines.  (The routines are derived
107 (distantly) from Henry Spencer's freely redistributable reimplementation
108 of the V8 routines.)  See L<Version 8 Regular Expressions> for
109 details.
110
111 In particular the following metacharacters have their standard I<egrep>-ish
112 meanings:
113 X<metacharacter>
114 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
115
116
117     \   Quote the next metacharacter
118     ^   Match the beginning of the line
119     .   Match any character (except newline)
120     $   Match the end of the line (or before newline at the end)
121     |   Alternation
122     ()  Grouping
123     []  Character class
124
125 By default, the "^" character is guaranteed to match only the
126 beginning of the string, the "$" character only the end (or before the
127 newline at the end), and Perl does certain optimizations with the
128 assumption that the string contains only one line.  Embedded newlines
129 will not be matched by "^" or "$".  You may, however, wish to treat a
130 string as a multi-line buffer, such that the "^" will match after any
131 newline within the string (except if the newline is the last character in
132 the string), and "$" will match before any newline.  At the
133 cost of a little more overhead, you can do this by using the /m modifier
134 on the pattern match operator.  (Older programs did this by setting C<$*>,
135 but this practice has been removed in perl 5.9.)
136 X<^> X<$> X</m>
137
138 To simplify multi-line substitutions, the "." character never matches a
139 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
140 the string is a single line--even if it isn't.
141 X<.> X</s>
142
143 =head3 Quantifiers
144
145 The following standard quantifiers are recognized:
146 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
147
148     *      Match 0 or more times
149     +      Match 1 or more times
150     ?      Match 1 or 0 times
151     {n}    Match exactly n times
152     {n,}   Match at least n times
153     {n,m}  Match at least n but not more than m times
154
155 (If a curly bracket occurs in any other context, it is treated
156 as a regular character.  In particular, the lower bound
157 is not optional.)  The "*" quantifier is equivalent to C<{0,}>, the "+"
158 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
159 to integral values less than a preset limit defined when perl is built.
160 This is usually 32766 on the most common platforms.  The actual limit can
161 be seen in the error message generated by code such as this:
162
163     $_ **= $_ , / {$_} / for 2 .. 42;
164
165 By default, a quantified subpattern is "greedy", that is, it will match as
166 many times as possible (given a particular starting location) while still
167 allowing the rest of the pattern to match.  If you want it to match the
168 minimum number of times possible, follow the quantifier with a "?".  Note
169 that the meanings don't change, just the "greediness":
170 X<metacharacter> X<greedy> X<greediness>
171 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
172
173     *?     Match 0 or more times, not greedily
174     +?     Match 1 or more times, not greedily
175     ??     Match 0 or 1 time, not greedily
176     {n}?   Match exactly n times, not greedily
177     {n,}?  Match at least n times, not greedily
178     {n,m}? Match at least n but not more than m times, not greedily
179
180 By default, when a quantified subpattern does not allow the rest of the
181 overall pattern to match, Perl will backtrack. However, this behaviour is
182 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
183 as well.
184
185     *+     Match 0 or more times and give nothing back
186     ++     Match 1 or more times and give nothing back
187     ?+     Match 0 or 1 time and give nothing back
188     {n}+   Match exactly n times and give nothing back (redundant)
189     {n,}+  Match at least n times and give nothing back
190     {n,m}+ Match at least n but not more than m times and give nothing back
191
192 For instance,
193
194    'aaaa' =~ /a++a/
195
196 will never match, as the C<a++> will gobble up all the C<a>'s in the
197 string and won't leave any for the remaining part of the pattern. This
198 feature can be extremely useful to give perl hints about where it
199 shouldn't backtrack. For instance, the typical "match a double-quoted
200 string" problem can be most efficiently performed when written as:
201
202    /"(?:[^"\\]++|\\.)*+"/
203
204 as we know that if the final quote does not match, backtracking will not
205 help. See the independent subexpression C<< (?>...) >> for more details;
206 possessive quantifiers are just syntactic sugar for that construct. For
207 instance the above example could also be written as follows:
208
209    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
210
211 =head3 Escape sequences
212
213 Because patterns are processed as double quoted strings, the following
214 also work:
215 X<\t> X<\n> X<\r> X<\f> X<\e> X<\a> X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q>
216 X<\0> X<\c> X<\N> X<\x>
217
218     \t          tab                   (HT, TAB)
219     \n          newline               (LF, NL)
220     \r          return                (CR)
221     \f          form feed             (FF)
222     \a          alarm (bell)          (BEL)
223     \e          escape (think troff)  (ESC)
224     \033        octal char            (example: ESC)
225     \x1B        hex char              (example: ESC)
226     \x{263a}    long hex char         (example: Unicode SMILEY)
227     \cK         control char          (example: VT)
228     \N{name}    named Unicode character
229     \l          lowercase next char (think vi)
230     \u          uppercase next char (think vi)
231     \L          lowercase till \E (think vi)
232     \U          uppercase till \E (think vi)
233     \E          end case modification (think vi)
234     \Q          quote (disable) pattern metacharacters till \E
235
236 If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
237 and C<\U> is taken from the current locale.  See L<perllocale>.  For
238 documentation of C<\N{name}>, see L<charnames>.
239
240 You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
241 An unescaped C<$> or C<@> interpolates the corresponding variable,
242 while escaping will cause the literal string C<\$> to be matched.
243 You'll need to write something like C<m/\Quser\E\@\Qhost/>.
244
245 =head3 Character Classes and other Special Escapes
246
247 In addition, Perl defines the following:
248 X<\w> X<\W> X<\s> X<\S> X<\d> X<\D> X<\X> X<\p> X<\P> X<\C>
249 X<\g> X<\k> X<\N> X<\K> X<\v> X<\V> X<\h> X<\H>
250 X<word> X<whitespace> X<character class> X<backreference>
251
252     \w       Match a "word" character (alphanumeric plus "_")
253     \W       Match a non-"word" character
254     \s       Match a whitespace character
255     \S       Match a non-whitespace character
256     \d       Match a digit character
257     \D       Match a non-digit character
258     \pP      Match P, named property.  Use \p{Prop} for longer names.
259     \PP      Match non-P
260     \X       Match eXtended Unicode "combining character sequence",
261              equivalent to (?>\PM\pM*)
262     \C       Match a single C char (octet) even under Unicode.
263              NOTE: breaks up characters into their UTF-8 bytes,
264              so you may end up with malformed pieces of UTF-8.
265              Unsupported in lookbehind.
266     \1       Backreference to a specific group.
267              '1' may actually be any positive integer.
268     \g1      Backreference to a specific or previous group,
269     \g{-1}   number may be negative indicating a previous buffer and may
270              optionally be wrapped in curly brackets for safer parsing.
271     \g{name} Named backreference
272     \k<name> Named backreference
273     \K       Keep the stuff left of the \K, don't include it in $&
274     \N       Any character but \n
275     \v       Vertical whitespace
276     \V       Not vertical whitespace
277     \h       Horizontal whitespace
278     \H       Not horizontal whitespace
279     \R       Linebreak
280
281 A C<\w> matches a single alphanumeric character (an alphabetic
282 character, or a decimal digit) or C<_>, not a whole word.  Use C<\w+>
283 to match a string of Perl-identifier characters (which isn't the same
284 as matching an English word).  If C<use locale> is in effect, the list
285 of alphabetic characters generated by C<\w> is taken from the current
286 locale.  See L<perllocale>.  You may use C<\w>, C<\W>, C<\s>, C<\S>,
287 C<\d>, and C<\D> within character classes, but they aren't usable
288 as either end of a range. If any of them precedes or follows a "-",
289 the "-" is understood literally. If Unicode is in effect, C<\s> matches
290 also "\x{85}", "\x{2028}", and "\x{2029}". See L<perlunicode> for more
291 details about C<\pP>, C<\PP>, C<\X> and the possibility of defining
292 your own C<\p> and C<\P> properties, and L<perluniintro> about Unicode
293 in general.
294 X<\w> X<\W> X<word>
295
296 C<\R> will atomically match a linebreak, including the network line-ending
297 "\x0D\x0A".  Specifically, X<\R> is exactly equivalent to
298
299   (?>\x0D\x0A?|[\x0A-\x0C\x85\x{2028}\x{2029}])
300
301 B<Note:> C<\R> has no special meaning inside of a character class;
302 use C<\v> instead (vertical whitespace).
303 X<\R>
304
305 The POSIX character class syntax
306 X<character class>
307
308     [:class:]
309
310 is also available.  Note that the C<[> and C<]> brackets are I<literal>;
311 they must always be used within a character class expression.
312
313     # this is correct:
314     $string =~ /[[:alpha:]]/;
315
316     # this is not, and will generate a warning:
317     $string =~ /[:alpha:]/;
318
319 The following table shows the mapping of POSIX character class
320 names, common escapes, literal escape sequences and their equivalent
321 Unicode style property names.
322 X<character class> X<\p> X<\p{}>
323 X<alpha> X<alnum> X<ascii> X<blank> X<cntrl> X<digit> X<graph>
324 X<lower> X<print> X<punct> X<space> X<upper> X<word> X<xdigit>
325
326 B<Note:> up to Perl 5.10 the property names used were shared with
327 standard Unicode properties, this was changed in Perl 5.11, see
328 L<perl5110delta> for details.
329
330     POSIX  Esc  Class               Property            Note
331     --------------------------------------------------------
332     alnum       [0-9A-Za-z]         IsPosixAlnum
333     alpha       [A-Za-z]            IsPosixAlpha
334     ascii       [\000-\177]         IsASCII
335     blank       [\011 ]             IsPosixBlank        [1]
336     cntrl       [\0-\37\177]        IsPosixCntrl
337     digit   \d  [0-9]               IsPosixDigit
338     graph       [!-~]               IsPosixGraph
339     lower       [a-z]               IsPosixLower
340     print       [ -~]               IsPosixPrint
341     punct       [!-/:-@[-`{-~]      IsPosixPunct
342     space       [\11-\15 ]          IsPosixSpace        [2]
343             \s  [\11\12\14\15 ]     IsPerlSpace         [2]
344     upper       [A-Z]               IsPosixUpper
345     word    \w  [0-9A-Z_a-z]        IsPerlWord          [3]
346     xdigit      [0-9A-Fa-f]         IsXDigit
347
348 =over
349
350 =item [1]
351
352 A GNU extension equivalent to C<[ \t]>, "all horizontal whitespace".
353
354 =item [2]
355
356 Note that C<\s> and C<[[:space:]]> are B<not> equivalent as C<[[:space:]]>
357 includes also the (very rare) "vertical tabulator", "\cK" or chr(11) in
358 ASCII.
359
360 =item [3]
361
362 A Perl extension, see above.
363
364 =back
365
366 For example use C<[:upper:]> to match all the uppercase characters.
367 Note that the C<[]> are part of the C<[::]> construct, not part of the
368 whole character class.  For example:
369
370     [01[:alpha:]%]
371
372 matches zero, one, any alphabetic character, and the percent sign.
373
374 =over 4
375
376 =item C<$>
377
378 Currency symbol
379
380 =item C<+> C<< < >> C<=> C<< > >> C<|> C<~>
381
382 Mathematical symbols
383
384 =item C<^> C<`>
385
386 Modifier symbols (accents)
387
388
389 =back
390
391 The other named classes are:
392
393 =over 4
394
395 =item cntrl
396 X<cntrl>
397
398 Any control character.  Usually characters that don't produce output as
399 such but instead control the terminal somehow: for example newline and
400 backspace are control characters.  All characters with ord() less than
401 32 are usually classified as control characters (assuming ASCII,
402 the ISO Latin character sets, and Unicode), as is the character with
403 the ord() value of 127 (C<DEL>).
404
405 =item graph
406 X<graph>
407
408 Any alphanumeric or punctuation (special) character.
409
410 =item print
411 X<print>
412
413 Any alphanumeric or punctuation (special) character or the space character.
414
415 =item punct
416 X<punct>
417
418 Any punctuation (special) character.
419
420 =item xdigit
421 X<xdigit>
422
423 Any hexadecimal digit.  Though this may feel silly ([0-9A-Fa-f] would
424 work just fine) it is included for completeness.
425
426 =back
427
428 You can negate the [::] character classes by prefixing the class name
429 with a '^'. This is a Perl extension.  For example:
430 X<character class, negation>
431
432     POSIX         traditional  Unicode
433
434     [[:^digit:]]    \D         \P{IsPosixDigit}
435     [[:^space:]]    \S         \P{IsPosixSpace}
436     [[:^word:]]     \W         \P{IsPerlWord}
437
438 Perl respects the POSIX standard in that POSIX character classes are
439 only supported within a character class.  The POSIX character classes
440 [.cc.] and [=cc=] are recognized but B<not> supported and trying to
441 use them will cause an error.
442
443 =head3 Assertions
444
445 Perl defines the following zero-width assertions:
446 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
447 X<regexp, zero-width assertion>
448 X<regular expression, zero-width assertion>
449 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
450
451     \b  Match a word boundary
452     \B  Match except at a word boundary
453     \A  Match only at beginning of string
454     \Z  Match only at end of string, or before newline at the end
455     \z  Match only at end of string
456     \G  Match only at pos() (e.g. at the end-of-match position
457         of prior m//g)
458
459 A word boundary (C<\b>) is a spot between two characters
460 that has a C<\w> on one side of it and a C<\W> on the other side
461 of it (in either order), counting the imaginary characters off the
462 beginning and end of the string as matching a C<\W>.  (Within
463 character classes C<\b> represents backspace rather than a word
464 boundary, just as it normally does in any double-quoted string.)
465 The C<\A> and C<\Z> are just like "^" and "$", except that they
466 won't match multiple times when the C</m> modifier is used, while
467 "^" and "$" will match at every internal line boundary.  To match
468 the actual end of the string and not ignore an optional trailing
469 newline, use C<\z>.
470 X<\b> X<\A> X<\Z> X<\z> X</m>
471
472 The C<\G> assertion can be used to chain global matches (using
473 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
474 It is also useful when writing C<lex>-like scanners, when you have
475 several patterns that you want to match against consequent substrings
476 of your string, see the previous reference.  The actual location
477 where C<\G> will match can also be influenced by using C<pos()> as
478 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
479 matches is modified somewhat, in that contents to the left of C<\G> is
480 not counted when determining the length of the match. Thus the following
481 will not match forever:
482 X<\G>
483
484     $str = 'ABC';
485     pos($str) = 1;
486     while (/.\G/g) {
487         print $&;
488     }
489
490 It will print 'A' and then terminate, as it considers the match to
491 be zero-width, and thus will not match at the same position twice in a
492 row.
493
494 It is worth noting that C<\G> improperly used can result in an infinite
495 loop. Take care when using patterns that include C<\G> in an alternation.
496
497 =head3 Capture buffers
498
499 The bracketing construct C<( ... )> creates capture buffers. To refer
500 to the current contents of a buffer later on, within the same pattern,
501 use \1 for the first, \2 for the second, and so on.
502 Outside the match use "$" instead of "\".  (The
503 \<digit> notation works in certain circumstances outside
504 the match.  See the warning below about \1 vs $1 for details.)
505 Referring back to another part of the match is called a
506 I<backreference>.
507 X<regex, capture buffer> X<regexp, capture buffer>
508 X<regular expression, capture buffer> X<backreference>
509
510 There is no limit to the number of captured substrings that you may
511 use.  However Perl also uses \10, \11, etc. as aliases for \010,
512 \011, etc.  (Recall that 0 means octal, so \011 is the character at
513 number 9 in your coded character set; which would be the 10th character,
514 a horizontal tab under ASCII.)  Perl resolves this
515 ambiguity by interpreting \10 as a backreference only if at least 10
516 left parentheses have opened before it.  Likewise \11 is a
517 backreference only if at least 11 left parentheses have opened
518 before it.  And so on.  \1 through \9 are always interpreted as
519 backreferences.
520
521 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
522 In order to provide a safer and easier way to construct patterns using
523 backreferences, Perl provides the C<\g{N}> notation (starting with perl
524 5.10.0). The curly brackets are optional, however omitting them is less
525 safe as the meaning of the pattern can be changed by text (such as digits)
526 following it. When N is a positive integer the C<\g{N}> notation is
527 exactly equivalent to using normal backreferences. When N is a negative
528 integer then it is a relative backreference referring to the previous N'th
529 capturing group. When the bracket form is used and N is not an integer, it
530 is treated as a reference to a named buffer.
531
532 Thus C<\g{-1}> refers to the last buffer, C<\g{-2}> refers to the
533 buffer before that. For example:
534
535         /
536          (Y)            # buffer 1
537          (              # buffer 2
538             (X)         # buffer 3
539             \g{-1}      # backref to buffer 3
540             \g{-3}      # backref to buffer 1
541          )
542         /x
543
544 and would match the same as C</(Y) ( (X) \3 \1 )/x>.
545
546 Additionally, as of Perl 5.10.0 you may use named capture buffers and named
547 backreferences. The notation is C<< (?<name>...) >> to declare and C<< \k<name> >>
548 to reference. You may also use apostrophes instead of angle brackets to delimit the
549 name; and you may use the bracketed C<< \g{name} >> backreference syntax.
550 It's possible to refer to a named capture buffer by absolute and relative number as well.
551 Outside the pattern, a named capture buffer is available via the C<%+> hash.
552 When different buffers within the same pattern have the same name, C<$+{name}>
553 and C<< \k<name> >> refer to the leftmost defined group. (Thus it's possible
554 to do things with named capture buffers that would otherwise require C<(??{})>
555 code to accomplish.)
556 X<named capture buffer> X<regular expression, named capture buffer>
557 X<%+> X<$+{name}> X<< \k<name> >>
558
559 Examples:
560
561     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
562
563     /(.)\1/                         # find first doubled char
564          and print "'$1' is the first doubled character\n";
565
566     /(?<char>.)\k<char>/            # ... a different way
567          and print "'$+{char}' is the first doubled character\n";
568
569     /(?'char'.)\1/                  # ... mix and match
570          and print "'$1' is the first doubled character\n";
571
572     if (/Time: (..):(..):(..)/) {   # parse out values
573         $hours = $1;
574         $minutes = $2;
575         $seconds = $3;
576     }
577
578 Several special variables also refer back to portions of the previous
579 match.  C<$+> returns whatever the last bracket match matched.
580 C<$&> returns the entire matched string.  (At one point C<$0> did
581 also, but now it returns the name of the program.)  C<$`> returns
582 everything before the matched string.  C<$'> returns everything
583 after the matched string. And C<$^N> contains whatever was matched by
584 the most-recently closed group (submatch). C<$^N> can be used in
585 extended patterns (see below), for example to assign a submatch to a
586 variable.
587 X<$+> X<$^N> X<$&> X<$`> X<$'>
588
589 The numbered match variables ($1, $2, $3, etc.) and the related punctuation
590 set (C<$+>, C<$&>, C<$`>, C<$'>, and C<$^N>) are all dynamically scoped
591 until the end of the enclosing block or until the next successful
592 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
593 X<$+> X<$^N> X<$&> X<$`> X<$'>
594 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
595
596
597 B<NOTE>: Failed matches in Perl do not reset the match variables,
598 which makes it easier to write code that tests for a series of more
599 specific cases and remembers the best match.
600
601 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
602 C<$'> anywhere in the program, it has to provide them for every
603 pattern match.  This may substantially slow your program.  Perl
604 uses the same mechanism to produce $1, $2, etc, so you also pay a
605 price for each pattern that contains capturing parentheses.  (To
606 avoid this cost while retaining the grouping behaviour, use the
607 extended regular expression C<(?: ... )> instead.)  But if you never
608 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
609 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
610 if you can, but if you can't (and some algorithms really appreciate
611 them), once you've used them once, use them at will, because you've
612 already paid the price.  As of 5.005, C<$&> is not so costly as the
613 other two.
614 X<$&> X<$`> X<$'>
615
616 As a workaround for this problem, Perl 5.10.0 introduces C<${^PREMATCH}>,
617 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
618 and C<$'>, B<except> that they are only guaranteed to be defined after a
619 successful match that was executed with the C</p> (preserve) modifier.
620 The use of these variables incurs no global performance penalty, unlike
621 their punctuation char equivalents, however at the trade-off that you
622 have to tell perl when you want to use them.
623 X</p> X<p modifier>
624
625 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
626 C<\w>, C<\n>.  Unlike some other regular expression languages, there
627 are no backslashed symbols that aren't alphanumeric.  So anything
628 that looks like \\, \(, \), \<, \>, \{, or \} is always
629 interpreted as a literal character, not a metacharacter.  This was
630 once used in a common idiom to disable or quote the special meanings
631 of regular expression metacharacters in a string that you want to
632 use for a pattern. Simply quote all non-"word" characters:
633
634     $pattern =~ s/(\W)/\\$1/g;
635
636 (If C<use locale> is set, then this depends on the current locale.)
637 Today it is more common to use the quotemeta() function or the C<\Q>
638 metaquoting escape sequence to disable all metacharacters' special
639 meanings like this:
640
641     /$unquoted\Q$quoted\E$unquoted/
642
643 Beware that if you put literal backslashes (those not inside
644 interpolated variables) between C<\Q> and C<\E>, double-quotish
645 backslash interpolation may lead to confusing results.  If you
646 I<need> to use literal backslashes within C<\Q...\E>,
647 consult L<perlop/"Gory details of parsing quoted constructs">.
648
649 =head2 Extended Patterns
650
651 Perl also defines a consistent extension syntax for features not
652 found in standard tools like B<awk> and B<lex>.  The syntax is a
653 pair of parentheses with a question mark as the first thing within
654 the parentheses.  The character after the question mark indicates
655 the extension.
656
657 The stability of these extensions varies widely.  Some have been
658 part of the core language for many years.  Others are experimental
659 and may change without warning or be completely removed.  Check
660 the documentation on an individual feature to verify its current
661 status.
662
663 A question mark was chosen for this and for the minimal-matching
664 construct because 1) question marks are rare in older regular
665 expressions, and 2) whenever you see one, you should stop and
666 "question" exactly what is going on.  That's psychology...
667
668 =over 10
669
670 =item C<(?#text)>
671 X<(?#)>
672
673 A comment.  The text is ignored.  If the C</x> modifier enables
674 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
675 the comment as soon as it sees a C<)>, so there is no way to put a literal
676 C<)> in the comment.
677
678 =item C<(?pimsx-imsx)>
679 X<(?)>
680
681 One or more embedded pattern-match modifiers, to be turned on (or
682 turned off, if preceded by C<->) for the remainder of the pattern or
683 the remainder of the enclosing pattern group (if any). This is
684 particularly useful for dynamic patterns, such as those read in from a
685 configuration file, taken from an argument, or specified in a table
686 somewhere.  Consider the case where some patterns want to be case
687 sensitive and some do not:  The case insensitive ones merely need to
688 include C<(?i)> at the front of the pattern.  For example:
689
690     $pattern = "foobar";
691     if ( /$pattern/i ) { }
692
693     # more flexible:
694
695     $pattern = "(?i)foobar";
696     if ( /$pattern/ ) { }
697
698 These modifiers are restored at the end of the enclosing group. For example,
699
700     ( (?i) blah ) \s+ \1
701
702 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
703 repetition of the previous word, assuming the C</x> modifier, and no C</i>
704 modifier outside this group.
705
706 These modifiers do not carry over into named subpatterns called in the
707 enclosing group. In other words, a pattern such as C<((?i)(&NAME))> does not
708 change the case-sensitivity of the "NAME" pattern.
709
710 Note that the C<p> modifier is special in that it can only be enabled,
711 not disabled, and that its presence anywhere in a pattern has a global
712 effect. Thus C<(?-p)> and C<(?-p:...)> are meaningless and will warn
713 when executed under C<use warnings>.
714
715 =item C<(?:pattern)>
716 X<(?:)>
717
718 =item C<(?imsx-imsx:pattern)>
719
720 This is for clustering, not capturing; it groups subexpressions like
721 "()", but doesn't make backreferences as "()" does.  So
722
723     @fields = split(/\b(?:a|b|c)\b/)
724
725 is like
726
727     @fields = split(/\b(a|b|c)\b/)
728
729 but doesn't spit out extra fields.  It's also cheaper not to capture
730 characters if you don't need to.
731
732 Any letters between C<?> and C<:> act as flags modifiers as with
733 C<(?imsx-imsx)>.  For example,
734
735     /(?s-i:more.*than).*million/i
736
737 is equivalent to the more verbose
738
739     /(?:(?s-i)more.*than).*million/i
740
741 =item C<(?|pattern)>
742 X<(?|)> X<Branch reset>
743
744 This is the "branch reset" pattern, which has the special property
745 that the capture buffers are numbered from the same starting point
746 in each alternation branch. It is available starting from perl 5.10.0.
747
748 Capture buffers are numbered from left to right, but inside this
749 construct the numbering is restarted for each branch.
750
751 The numbering within each branch will be as normal, and any buffers
752 following this construct will be numbered as though the construct
753 contained only one branch, that being the one with the most capture
754 buffers in it.
755
756 This construct will be useful when you want to capture one of a
757 number of alternative matches.
758
759 Consider the following pattern.  The numbers underneath show in
760 which buffer the captured content will be stored.
761
762
763     # before  ---------------branch-reset----------- after        
764     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
765     # 1            2         2  3        2     3     4  
766
767 Note: as of Perl 5.10.0, branch resets interfere with the contents of
768 the C<%+> hash, that holds named captures. Consider using C<%-> instead.
769
770 =item Look-Around Assertions
771 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
772
773 Look-around assertions are zero width patterns which match a specific
774 pattern without including it in C<$&>. Positive assertions match when
775 their subpattern matches, negative assertions match when their subpattern
776 fails. Look-behind matches text up to the current match position,
777 look-ahead matches text following the current match position.
778
779 =over 4
780
781 =item C<(?=pattern)>
782 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
783
784 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
785 matches a word followed by a tab, without including the tab in C<$&>.
786
787 =item C<(?!pattern)>
788 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
789
790 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
791 matches any occurrence of "foo" that isn't followed by "bar".  Note
792 however that look-ahead and look-behind are NOT the same thing.  You cannot
793 use this for look-behind.
794
795 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
796 will not do what you want.  That's because the C<(?!foo)> is just saying that
797 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
798 match.  You would have to do something like C</(?!foo)...bar/> for that.   We
799 say "like" because there's the case of your "bar" not having three characters
800 before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
801 Sometimes it's still easier just to say:
802
803     if (/bar/ && $` !~ /foo$/)
804
805 For look-behind see below.
806
807 =item C<(?<=pattern)> C<\K>
808 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
809
810 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
811 matches a word that follows a tab, without including the tab in C<$&>.
812 Works only for fixed-width look-behind.
813
814 There is a special form of this construct, called C<\K>, which causes the
815 regex engine to "keep" everything it had matched prior to the C<\K> and
816 not include it in C<$&>. This effectively provides variable length
817 look-behind. The use of C<\K> inside of another look-around assertion
818 is allowed, but the behaviour is currently not well defined.
819
820 For various reasons C<\K> may be significantly more efficient than the
821 equivalent C<< (?<=...) >> construct, and it is especially useful in
822 situations where you want to efficiently remove something following
823 something else in a string. For instance
824
825   s/(foo)bar/$1/g;
826
827 can be rewritten as the much more efficient
828
829   s/foo\Kbar//g;
830
831 =item C<(?<!pattern)>
832 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
833
834 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
835 matches any occurrence of "foo" that does not follow "bar".  Works
836 only for fixed-width look-behind.
837
838 =back
839
840 =item C<(?'NAME'pattern)>
841
842 =item C<< (?<NAME>pattern) >>
843 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
844
845 A named capture buffer. Identical in every respect to normal capturing
846 parentheses C<()> but for the additional fact that C<%+> or C<%-> may be
847 used after a successful match to refer to a named buffer. See C<perlvar>
848 for more details on the C<%+> and C<%-> hashes.
849
850 If multiple distinct capture buffers have the same name then the
851 $+{NAME} will refer to the leftmost defined buffer in the match.
852
853 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
854
855 B<NOTE:> While the notation of this construct is the same as the similar
856 function in .NET regexes, the behavior is not. In Perl the buffers are
857 numbered sequentially regardless of being named or not. Thus in the
858 pattern
859
860   /(x)(?<foo>y)(z)/
861
862 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
863 the opposite which is what a .NET regex hacker might expect.
864
865 Currently NAME is restricted to simple identifiers only.
866 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
867 its Unicode extension (see L<utf8>),
868 though it isn't extended by the locale (see L<perllocale>).
869
870 B<NOTE:> In order to make things easier for programmers with experience
871 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
872 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
873 support the use of single quotes as a delimiter for the name.
874
875 =item C<< \k<NAME> >>
876
877 =item C<< \k'NAME' >>
878
879 Named backreference. Similar to numeric backreferences, except that
880 the group is designated by name and not number. If multiple groups
881 have the same name then it refers to the leftmost defined group in
882 the current match.
883
884 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
885 earlier in the pattern.
886
887 Both forms are equivalent.
888
889 B<NOTE:> In order to make things easier for programmers with experience
890 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
891 may be used instead of C<< \k<NAME> >>.
892
893 =item C<(?{ code })>
894 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
895
896 B<WARNING>: This extended regular expression feature is considered
897 experimental, and may be changed without notice. Code executed that
898 has side effects may not perform identically from version to version
899 due to the effect of future optimisations in the regex engine.
900
901 This zero-width assertion evaluates any embedded Perl code.  It
902 always succeeds, and its C<code> is not interpolated.  Currently,
903 the rules to determine where the C<code> ends are somewhat convoluted.
904
905 This feature can be used together with the special variable C<$^N> to
906 capture the results of submatches in variables without having to keep
907 track of the number of nested parentheses. For example:
908
909   $_ = "The brown fox jumps over the lazy dog";
910   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
911   print "color = $color, animal = $animal\n";
912
913 Inside the C<(?{...})> block, C<$_> refers to the string the regular
914 expression is matching against. You can also use C<pos()> to know what is
915 the current position of matching within this string.
916
917 The C<code> is properly scoped in the following sense: If the assertion
918 is backtracked (compare L<"Backtracking">), all changes introduced after
919 C<local>ization are undone, so that
920
921   $_ = 'a' x 8;
922   m<
923      (?{ $cnt = 0 })                    # Initialize $cnt.
924      (
925        a
926        (?{
927            local $cnt = $cnt + 1;       # Update $cnt, backtracking-safe.
928        })
929      )*
930      aaaa
931      (?{ $res = $cnt })                 # On success copy to non-localized
932                                         # location.
933    >x;
934
935 will set C<$res = 4>.  Note that after the match, C<$cnt> returns to the globally
936 introduced value, because the scopes that restrict C<local> operators
937 are unwound.
938
939 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
940 switch.  If I<not> used in this way, the result of evaluation of
941 C<code> is put into the special variable C<$^R>.  This happens
942 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
943 inside the same regular expression.
944
945 The assignment to C<$^R> above is properly localized, so the old
946 value of C<$^R> is restored if the assertion is backtracked; compare
947 L<"Backtracking">.
948
949 For reasons of security, this construct is forbidden if the regular
950 expression involves run-time interpolation of variables, unless the
951 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
952 variables contain results of C<qr//> operator (see
953 L<perlop/"qr/STRING/imosx">).
954
955 This restriction is due to the wide-spread and remarkably convenient
956 custom of using run-time determined strings as patterns.  For example:
957
958     $re = <>;
959     chomp $re;
960     $string =~ /$re/;
961
962 Before Perl knew how to execute interpolated code within a pattern,
963 this operation was completely safe from a security point of view,
964 although it could raise an exception from an illegal pattern.  If
965 you turn on the C<use re 'eval'>, though, it is no longer secure,
966 so you should only do so if you are also using taint checking.
967 Better yet, use the carefully constrained evaluation within a Safe
968 compartment.  See L<perlsec> for details about both these mechanisms.
969
970 B<WARNING>: Use of lexical (C<my>) variables in these blocks is
971 broken. The result is unpredictable and will make perl unstable. The
972 workaround is to use global (C<our>) variables.
973
974 B<WARNING>: Because Perl's regex engine is currently not re-entrant,
975 interpolated code may not invoke the regex engine either directly with
976 C<m//> or C<s///>), or indirectly with functions such as
977 C<split>. Invoking the regex engine in these blocks will make perl
978 unstable.
979
980 =item C<(??{ code })>
981 X<(??{})>
982 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
983
984 B<WARNING>: This extended regular expression feature is considered
985 experimental, and may be changed without notice. Code executed that
986 has side effects may not perform identically from version to version
987 due to the effect of future optimisations in the regex engine.
988
989 This is a "postponed" regular subexpression.  The C<code> is evaluated
990 at run time, at the moment this subexpression may match.  The result
991 of evaluation is considered as a regular expression and matched as
992 if it were inserted instead of this construct.  Note that this means
993 that the contents of capture buffers defined inside an eval'ed pattern
994 are not available outside of the pattern, and vice versa, there is no
995 way for the inner pattern to refer to a capture buffer defined outside.
996 Thus,
997
998     ('a' x 100)=~/(??{'(.)' x 100})/
999
1000 B<will> match, it will B<not> set $1.
1001
1002 The C<code> is not interpolated.  As before, the rules to determine
1003 where the C<code> ends are currently somewhat convoluted.
1004
1005 The following pattern matches a parenthesized group:
1006
1007   $re = qr{
1008              \(
1009              (?:
1010                 (?> [^()]+ )    # Non-parens without backtracking
1011               |
1012                 (??{ $re })     # Group with matching parens
1013              )*
1014              \)
1015           }x;
1016
1017 See also C<(?PARNO)> for a different, more efficient way to accomplish
1018 the same task.
1019
1020 Because perl's regex engine is not currently re-entrant, delayed
1021 code may not invoke the regex engine either directly with C<m//> or C<s///>),
1022 or indirectly with functions such as C<split>.
1023
1024 Recursing deeper than 50 times without consuming any input string will
1025 result in a fatal error.  The maximum depth is compiled into perl, so
1026 changing it requires a custom build.
1027
1028 =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
1029 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1030 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1031 X<regex, relative recursion>
1032
1033 Similar to C<(??{ code })> except it does not involve compiling any code,
1034 instead it treats the contents of a capture buffer as an independent
1035 pattern that must match at the current position.  Capture buffers
1036 contained by the pattern will have the value as determined by the
1037 outermost recursion.
1038
1039 PARNO is a sequence of digits (not starting with 0) whose value reflects
1040 the paren-number of the capture buffer to recurse to. C<(?R)> recurses to
1041 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1042 C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
1043 to be relative, with negative numbers indicating preceding capture buffers
1044 and positive ones following. Thus C<(?-1)> refers to the most recently
1045 declared buffer, and C<(?+1)> indicates the next buffer to be declared.
1046 Note that the counting for relative recursion differs from that of
1047 relative backreferences, in that with recursion unclosed buffers B<are>
1048 included.
1049
1050 The following pattern matches a function foo() which may contain
1051 balanced parentheses as the argument.
1052
1053   $re = qr{ (                    # paren group 1 (full function)
1054               foo
1055               (                  # paren group 2 (parens)
1056                 \(
1057                   (              # paren group 3 (contents of parens)
1058                   (?:
1059                    (?> [^()]+ )  # Non-parens without backtracking
1060                   |
1061                    (?2)          # Recurse to start of paren group 2
1062                   )*
1063                   )
1064                 \)
1065               )
1066             )
1067           }x;
1068
1069 If the pattern was used as follows
1070
1071     'foo(bar(baz)+baz(bop))'=~/$re/
1072         and print "\$1 = $1\n",
1073                   "\$2 = $2\n",
1074                   "\$3 = $3\n";
1075
1076 the output produced should be the following:
1077
1078     $1 = foo(bar(baz)+baz(bop))
1079     $2 = (bar(baz)+baz(bop))
1080     $3 = bar(baz)+baz(bop)
1081
1082 If there is no corresponding capture buffer defined, then it is a
1083 fatal error.  Recursing deeper than 50 times without consuming any input
1084 string will also result in a fatal error.  The maximum depth is compiled
1085 into perl, so changing it requires a custom build.
1086
1087 The following shows how using negative indexing can make it
1088 easier to embed recursive patterns inside of a C<qr//> construct
1089 for later use:
1090
1091     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1092     if (/foo $parens \s+ + \s+ bar $parens/x) {
1093        # do something here...
1094     }
1095
1096 B<Note> that this pattern does not behave the same way as the equivalent
1097 PCRE or Python construct of the same form. In Perl you can backtrack into
1098 a recursed group, in PCRE and Python the recursed into group is treated
1099 as atomic. Also, modifiers are resolved at compile time, so constructs
1100 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1101 be processed.
1102
1103 =item C<(?&NAME)>
1104 X<(?&NAME)>
1105
1106 Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1107 parenthesis to recurse to is determined by name. If multiple parentheses have
1108 the same name, then it recurses to the leftmost.
1109
1110 It is an error to refer to a name that is not declared somewhere in the
1111 pattern.
1112
1113 B<NOTE:> In order to make things easier for programmers with experience
1114 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1115 may be used instead of C<< (?&NAME) >>.
1116
1117 =item C<(?(condition)yes-pattern|no-pattern)>
1118 X<(?()>
1119
1120 =item C<(?(condition)yes-pattern)>
1121
1122 Conditional expression.  C<(condition)> should be either an integer in
1123 parentheses (which is valid if the corresponding pair of parentheses
1124 matched), a look-ahead/look-behind/evaluate zero-width assertion, a
1125 name in angle brackets or single quotes (which is valid if a buffer
1126 with the given name matched), or the special symbol (R) (true when
1127 evaluated inside of recursion or eval). Additionally the R may be
1128 followed by a number, (which will be true when evaluated when recursing
1129 inside of the appropriate group), or by C<&NAME>, in which case it will
1130 be true only when evaluated during recursion in the named group.
1131
1132 Here's a summary of the possible predicates:
1133
1134 =over 4
1135
1136 =item (1) (2) ...
1137
1138 Checks if the numbered capturing buffer has matched something.
1139
1140 =item (<NAME>) ('NAME')
1141
1142 Checks if a buffer with the given name has matched something.
1143
1144 =item (?{ CODE })
1145
1146 Treats the code block as the condition.
1147
1148 =item (R)
1149
1150 Checks if the expression has been evaluated inside of recursion.
1151
1152 =item (R1) (R2) ...
1153
1154 Checks if the expression has been evaluated while executing directly
1155 inside of the n-th capture group. This check is the regex equivalent of
1156
1157   if ((caller(0))[3] eq 'subname') { ... }
1158
1159 In other words, it does not check the full recursion stack.
1160
1161 =item (R&NAME)
1162
1163 Similar to C<(R1)>, this predicate checks to see if we're executing
1164 directly inside of the leftmost group with a given name (this is the same
1165 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1166 stack, but only the name of the innermost active recursion.
1167
1168 =item (DEFINE)
1169
1170 In this case, the yes-pattern is never directly executed, and no
1171 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1172 See below for details.
1173
1174 =back
1175
1176 For example:
1177
1178     m{ ( \( )?
1179        [^()]+
1180        (?(1) \) )
1181      }x
1182
1183 matches a chunk of non-parentheses, possibly included in parentheses
1184 themselves.
1185
1186 A special form is the C<(DEFINE)> predicate, which never executes directly
1187 its yes-pattern, and does not allow a no-pattern. This allows to define
1188 subpatterns which will be executed only by using the recursion mechanism.
1189 This way, you can define a set of regular expression rules that can be
1190 bundled into any pattern you choose.
1191
1192 It is recommended that for this usage you put the DEFINE block at the
1193 end of the pattern, and that you name any subpatterns defined within it.
1194
1195 Also, it's worth noting that patterns defined this way probably will
1196 not be as efficient, as the optimiser is not very clever about
1197 handling them.
1198
1199 An example of how this might be used is as follows:
1200
1201   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1202    (?(DEFINE)
1203      (?<NAME_PAT>....)
1204      (?<ADRESS_PAT>....)
1205    )/x
1206
1207 Note that capture buffers matched inside of recursion are not accessible
1208 after the recursion returns, so the extra layer of capturing buffers is
1209 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1210 C<$+{NAME}> would be.
1211
1212 =item C<< (?>pattern) >>
1213 X<backtrack> X<backtracking> X<atomic> X<possessive>
1214
1215 An "independent" subexpression, one which matches the substring
1216 that a I<standalone> C<pattern> would match if anchored at the given
1217 position, and it matches I<nothing other than this substring>.  This
1218 construct is useful for optimizations of what would otherwise be
1219 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1220 It may also be useful in places where the "grab all you can, and do not
1221 give anything back" semantic is desirable.
1222
1223 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1224 (anchored at the beginning of string, as above) will match I<all>
1225 characters C<a> at the beginning of string, leaving no C<a> for
1226 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1227 since the match of the subgroup C<a*> is influenced by the following
1228 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1229 C<a*ab> will match fewer characters than a standalone C<a*>, since
1230 this makes the tail match.
1231
1232 An effect similar to C<< (?>pattern) >> may be achieved by writing
1233 C<(?=(pattern))\1>.  This matches the same substring as a standalone
1234 C<a+>, and the following C<\1> eats the matched string; it therefore
1235 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1236 (The difference between these two constructs is that the second one
1237 uses a capturing group, thus shifting ordinals of backreferences
1238 in the rest of a regular expression.)
1239
1240 Consider this pattern:
1241
1242     m{ \(
1243           (
1244             [^()]+              # x+
1245           |
1246             \( [^()]* \)
1247           )+
1248        \)
1249      }x
1250
1251 That will efficiently match a nonempty group with matching parentheses
1252 two levels deep or less.  However, if there is no such group, it
1253 will take virtually forever on a long string.  That's because there
1254 are so many different ways to split a long string into several
1255 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1256 to a subpattern of the above pattern.  Consider how the pattern
1257 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1258 seconds, but that each extra letter doubles this time.  This
1259 exponential performance will make it appear that your program has
1260 hung.  However, a tiny change to this pattern
1261
1262     m{ \(
1263           (
1264             (?> [^()]+ )        # change x+ above to (?> x+ )
1265           |
1266             \( [^()]* \)
1267           )+
1268        \)
1269      }x
1270
1271 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1272 this yourself would be a productive exercise), but finishes in a fourth
1273 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1274 however, that this pattern currently triggers a warning message under
1275 the C<use warnings> pragma or B<-w> switch saying it
1276 C<"matches null string many times in regex">.
1277
1278 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1279 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1280 This was only 4 times slower on a string with 1000000 C<a>s.
1281
1282 The "grab all you can, and do not give anything back" semantic is desirable
1283 in many situations where on the first sight a simple C<()*> looks like
1284 the correct solution.  Suppose we parse text with comments being delimited
1285 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1286 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1287 the comment delimiter, because it may "give up" some whitespace if
1288 the remainder of the pattern can be made to match that way.  The correct
1289 answer is either one of these:
1290
1291     (?>#[ \t]*)
1292     #[ \t]*(?![ \t])
1293
1294 For example, to grab non-empty comments into $1, one should use either
1295 one of these:
1296
1297     / (?> \# [ \t]* ) (        .+ ) /x;
1298     /     \# [ \t]*   ( [^ \t] .* ) /x;
1299
1300 Which one you pick depends on which of these expressions better reflects
1301 the above specification of comments.
1302
1303 In some literature this construct is called "atomic matching" or
1304 "possessive matching".
1305
1306 Possessive quantifiers are equivalent to putting the item they are applied
1307 to inside of one of these constructs. The following equivalences apply:
1308
1309     Quantifier Form     Bracketing Form
1310     ---------------     ---------------
1311     PAT*+               (?>PAT*)
1312     PAT++               (?>PAT+)
1313     PAT?+               (?>PAT?)
1314     PAT{min,max}+       (?>PAT{min,max})
1315
1316 =back
1317
1318 =head2 Special Backtracking Control Verbs
1319
1320 B<WARNING:> These patterns are experimental and subject to change or
1321 removal in a future version of Perl. Their usage in production code should
1322 be noted to avoid problems during upgrades.
1323
1324 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1325 otherwise stated the ARG argument is optional; in some cases, it is
1326 forbidden.
1327
1328 Any pattern containing a special backtracking verb that allows an argument
1329 has the special behaviour that when executed it sets the current packages'
1330 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1331 rules apply:
1332
1333 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1334 verb pattern, if the verb was involved in the failure of the match. If the
1335 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1336 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1337 none. Also, the C<$REGMARK> variable will be set to FALSE.
1338
1339 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1340 the C<$REGMARK> variable will be set to the name of the last
1341 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1342 C<(*MARK:NAME)> verb below for more details.
1343
1344 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1345 and most other regex related variables. They are not local to a scope, nor
1346 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1347 Use C<local> to localize changes to them to a specific scope if necessary.
1348
1349 If a pattern does not contain a special backtracking verb that allows an
1350 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1351
1352 =over 4
1353
1354 =item Verbs that take an argument
1355
1356 =over 4
1357
1358 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1359 X<(*PRUNE)> X<(*PRUNE:NAME)>
1360
1361 This zero-width pattern prunes the backtracking tree at the current point
1362 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1363 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1364 A may backtrack as necessary to match. Once it is reached, matching
1365 continues in B, which may also backtrack as necessary; however, should B
1366 not match, then no further backtracking will take place, and the pattern
1367 will fail outright at the current starting position.
1368
1369 The following example counts all the possible matching strings in a
1370 pattern (without actually matching any of them).
1371
1372     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1373     print "Count=$count\n";
1374
1375 which produces:
1376
1377     aaab
1378     aaa
1379     aa
1380     a
1381     aab
1382     aa
1383     a
1384     ab
1385     a
1386     Count=9
1387
1388 If we add a C<(*PRUNE)> before the count like the following
1389
1390     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1391     print "Count=$count\n";
1392
1393 we prevent backtracking and find the count of the longest matching
1394 at each matching starting point like so:
1395
1396     aaab
1397     aab
1398     ab
1399     Count=3
1400
1401 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1402
1403 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1404 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1405 replaced with a C<< (?>pattern) >> with no functional difference; however,
1406 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1407 C<< (?>pattern) >> alone.
1408
1409
1410 =item C<(*SKIP)> C<(*SKIP:NAME)>
1411 X<(*SKIP)>
1412
1413 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1414 failure it also signifies that whatever text that was matched leading up
1415 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1416 of this pattern. This effectively means that the regex engine "skips" forward
1417 to this position on failure and tries to match again, (assuming that
1418 there is sufficient room to match).
1419
1420 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1421 C<(*MARK:NAME)> was encountered while matching, then it is that position
1422 which is used as the "skip point". If no C<(*MARK)> of that name was
1423 encountered, then the C<(*SKIP)> operator has no effect. When used
1424 without a name the "skip point" is where the match point was when
1425 executing the (*SKIP) pattern.
1426
1427 Compare the following to the examples in C<(*PRUNE)>, note the string
1428 is twice as long:
1429
1430     'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1431     print "Count=$count\n";
1432
1433 outputs
1434
1435     aaab
1436     aaab
1437     Count=2
1438
1439 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1440 executed, the next starting point will be where the cursor was when the
1441 C<(*SKIP)> was executed.
1442
1443 =item C<(*MARK:NAME)> C<(*:NAME)>
1444 X<(*MARK)> C<(*MARK:NAME)> C<(*:NAME)>
1445
1446 This zero-width pattern can be used to mark the point reached in a string
1447 when a certain part of the pattern has been successfully matched. This
1448 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1449 forward to that point if backtracked into on failure. Any number of
1450 C<(*MARK)> patterns are allowed, and the NAME portion is optional and may
1451 be duplicated.
1452
1453 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1454 can be used to "label" a pattern branch, so that after matching, the
1455 program can determine which branches of the pattern were involved in the
1456 match.
1457
1458 When a match is successful, the C<$REGMARK> variable will be set to the
1459 name of the most recently executed C<(*MARK:NAME)> that was involved
1460 in the match.
1461
1462 This can be used to determine which branch of a pattern was matched
1463 without using a separate capture buffer for each branch, which in turn
1464 can result in a performance improvement, as perl cannot optimize
1465 C</(?:(x)|(y)|(z))/> as efficiently as something like
1466 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1467
1468 When a match has failed, and unless another verb has been involved in
1469 failing the match and has provided its own name to use, the C<$REGERROR>
1470 variable will be set to the name of the most recently executed
1471 C<(*MARK:NAME)>.
1472
1473 See C<(*SKIP)> for more details.
1474
1475 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1476
1477 =item C<(*THEN)> C<(*THEN:NAME)>
1478
1479 This is similar to the "cut group" operator C<::> from Perl 6. Like
1480 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1481 failure, it causes the regex engine to try the next alternation in the
1482 innermost enclosing group (capturing or otherwise).
1483
1484 Its name comes from the observation that this operation combined with the
1485 alternation operator (C<|>) can be used to create what is essentially a
1486 pattern-based if/then/else block:
1487
1488   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1489
1490 Note that if this operator is used and NOT inside of an alternation then
1491 it acts exactly like the C<(*PRUNE)> operator.
1492
1493   / A (*PRUNE) B /
1494
1495 is the same as
1496
1497   / A (*THEN) B /
1498
1499 but
1500
1501   / ( A (*THEN) B | C (*THEN) D ) /
1502
1503 is not the same as
1504
1505   / ( A (*PRUNE) B | C (*PRUNE) D ) /
1506
1507 as after matching the A but failing on the B the C<(*THEN)> verb will
1508 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1509
1510 =item C<(*COMMIT)>
1511 X<(*COMMIT)>
1512
1513 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1514 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1515 into on failure it causes the match to fail outright. No further attempts
1516 to find a valid match by advancing the start pointer will occur again.
1517 For example,
1518
1519     'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1520     print "Count=$count\n";
1521
1522 outputs
1523
1524     aaab
1525     Count=1
1526
1527 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1528 does not match, the regex engine will not try any further matching on the
1529 rest of the string.
1530
1531 =back
1532
1533 =item Verbs without an argument
1534
1535 =over 4
1536
1537 =item C<(*FAIL)> C<(*F)>
1538 X<(*FAIL)> X<(*F)>
1539
1540 This pattern matches nothing and always fails. It can be used to force the
1541 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1542 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1543
1544 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1545
1546 =item C<(*ACCEPT)>
1547 X<(*ACCEPT)>
1548
1549 B<WARNING:> This feature is highly experimental. It is not recommended
1550 for production code.
1551
1552 This pattern matches nothing and causes the end of successful matching at
1553 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1554 whether there is actually more to match in the string. When inside of a
1555 nested pattern, such as recursion, or in a subpattern dynamically generated
1556 via C<(??{})>, only the innermost pattern is ended immediately.
1557
1558 If the C<(*ACCEPT)> is inside of capturing buffers then the buffers are
1559 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1560 For instance:
1561
1562   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1563
1564 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1565 be set. If another branch in the inner parentheses were matched, such as in the
1566 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1567
1568 =back
1569
1570 =back
1571
1572 =head2 Backtracking
1573 X<backtrack> X<backtracking>
1574
1575 NOTE: This section presents an abstract approximation of regular
1576 expression behavior.  For a more rigorous (and complicated) view of
1577 the rules involved in selecting a match among possible alternatives,
1578 see L<Combining RE Pieces>.
1579
1580 A fundamental feature of regular expression matching involves the
1581 notion called I<backtracking>, which is currently used (when needed)
1582 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
1583 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
1584 internally, but the general principle outlined here is valid.
1585
1586 For a regular expression to match, the I<entire> regular expression must
1587 match, not just part of it.  So if the beginning of a pattern containing a
1588 quantifier succeeds in a way that causes later parts in the pattern to
1589 fail, the matching engine backs up and recalculates the beginning
1590 part--that's why it's called backtracking.
1591
1592 Here is an example of backtracking:  Let's say you want to find the
1593 word following "foo" in the string "Food is on the foo table.":
1594
1595     $_ = "Food is on the foo table.";
1596     if ( /\b(foo)\s+(\w+)/i ) {
1597         print "$2 follows $1.\n";
1598     }
1599
1600 When the match runs, the first part of the regular expression (C<\b(foo)>)
1601 finds a possible match right at the beginning of the string, and loads up
1602 $1 with "Foo".  However, as soon as the matching engine sees that there's
1603 no whitespace following the "Foo" that it had saved in $1, it realizes its
1604 mistake and starts over again one character after where it had the
1605 tentative match.  This time it goes all the way until the next occurrence
1606 of "foo". The complete regular expression matches this time, and you get
1607 the expected output of "table follows foo."
1608
1609 Sometimes minimal matching can help a lot.  Imagine you'd like to match
1610 everything between "foo" and "bar".  Initially, you write something
1611 like this:
1612
1613     $_ =  "The food is under the bar in the barn.";
1614     if ( /foo(.*)bar/ ) {
1615         print "got <$1>\n";
1616     }
1617
1618 Which perhaps unexpectedly yields:
1619
1620   got <d is under the bar in the >
1621
1622 That's because C<.*> was greedy, so you get everything between the
1623 I<first> "foo" and the I<last> "bar".  Here it's more effective
1624 to use minimal matching to make sure you get the text between a "foo"
1625 and the first "bar" thereafter.
1626
1627     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
1628   got <d is under the >
1629
1630 Here's another example. Let's say you'd like to match a number at the end
1631 of a string, and you also want to keep the preceding part of the match.
1632 So you write this:
1633
1634     $_ = "I have 2 numbers: 53147";
1635     if ( /(.*)(\d*)/ ) {                                # Wrong!
1636         print "Beginning is <$1>, number is <$2>.\n";
1637     }
1638
1639 That won't work at all, because C<.*> was greedy and gobbled up the
1640 whole string. As C<\d*> can match on an empty string the complete
1641 regular expression matched successfully.
1642
1643     Beginning is <I have 2 numbers: 53147>, number is <>.
1644
1645 Here are some variants, most of which don't work:
1646
1647     $_ = "I have 2 numbers: 53147";
1648     @pats = qw{
1649         (.*)(\d*)
1650         (.*)(\d+)
1651         (.*?)(\d*)
1652         (.*?)(\d+)
1653         (.*)(\d+)$
1654         (.*?)(\d+)$
1655         (.*)\b(\d+)$
1656         (.*\D)(\d+)$
1657     };
1658
1659     for $pat (@pats) {
1660         printf "%-12s ", $pat;
1661         if ( /$pat/ ) {
1662             print "<$1> <$2>\n";
1663         } else {
1664             print "FAIL\n";
1665         }
1666     }
1667
1668 That will print out:
1669
1670     (.*)(\d*)    <I have 2 numbers: 53147> <>
1671     (.*)(\d+)    <I have 2 numbers: 5314> <7>
1672     (.*?)(\d*)   <> <>
1673     (.*?)(\d+)   <I have > <2>
1674     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
1675     (.*?)(\d+)$  <I have 2 numbers: > <53147>
1676     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
1677     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
1678
1679 As you see, this can be a bit tricky.  It's important to realize that a
1680 regular expression is merely a set of assertions that gives a definition
1681 of success.  There may be 0, 1, or several different ways that the
1682 definition might succeed against a particular string.  And if there are
1683 multiple ways it might succeed, you need to understand backtracking to
1684 know which variety of success you will achieve.
1685
1686 When using look-ahead assertions and negations, this can all get even
1687 trickier.  Imagine you'd like to find a sequence of non-digits not
1688 followed by "123".  You might try to write that as
1689
1690     $_ = "ABC123";
1691     if ( /^\D*(?!123)/ ) {              # Wrong!
1692         print "Yup, no 123 in $_\n";
1693     }
1694
1695 But that isn't going to match; at least, not the way you're hoping.  It
1696 claims that there is no 123 in the string.  Here's a clearer picture of
1697 why that pattern matches, contrary to popular expectations:
1698
1699     $x = 'ABC123';
1700     $y = 'ABC445';
1701
1702     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
1703     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
1704
1705     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
1706     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
1707
1708 This prints
1709
1710     2: got ABC
1711     3: got AB
1712     4: got ABC
1713
1714 You might have expected test 3 to fail because it seems to a more
1715 general purpose version of test 1.  The important difference between
1716 them is that test 3 contains a quantifier (C<\D*>) and so can use
1717 backtracking, whereas test 1 will not.  What's happening is
1718 that you've asked "Is it true that at the start of $x, following 0 or more
1719 non-digits, you have something that's not 123?"  If the pattern matcher had
1720 let C<\D*> expand to "ABC", this would have caused the whole pattern to
1721 fail.
1722
1723 The search engine will initially match C<\D*> with "ABC".  Then it will
1724 try to match C<(?!123> with "123", which fails.  But because
1725 a quantifier (C<\D*>) has been used in the regular expression, the
1726 search engine can backtrack and retry the match differently
1727 in the hope of matching the complete regular expression.
1728
1729 The pattern really, I<really> wants to succeed, so it uses the
1730 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
1731 time.  Now there's indeed something following "AB" that is not
1732 "123".  It's "C123", which suffices.
1733
1734 We can deal with this by using both an assertion and a negation.
1735 We'll say that the first part in $1 must be followed both by a digit
1736 and by something that's not "123".  Remember that the look-aheads
1737 are zero-width expressions--they only look, but don't consume any
1738 of the string in their match.  So rewriting this way produces what
1739 you'd expect; that is, case 5 will fail, but case 6 succeeds:
1740
1741     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
1742     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
1743
1744     6: got ABC
1745
1746 In other words, the two zero-width assertions next to each other work as though
1747 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
1748 matches only if you're at the beginning of the line AND the end of the
1749 line simultaneously.  The deeper underlying truth is that juxtaposition in
1750 regular expressions always means AND, except when you write an explicit OR
1751 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
1752 although the attempted matches are made at different positions because "a"
1753 is not a zero-width assertion, but a one-width assertion.
1754
1755 B<WARNING>: Particularly complicated regular expressions can take
1756 exponential time to solve because of the immense number of possible
1757 ways they can use backtracking to try for a match.  For example, without
1758 internal optimizations done by the regular expression engine, this will
1759 take a painfully long time to run:
1760
1761     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
1762
1763 And if you used C<*>'s in the internal groups instead of limiting them
1764 to 0 through 5 matches, then it would take forever--or until you ran
1765 out of stack space.  Moreover, these internal optimizations are not
1766 always applicable.  For example, if you put C<{0,5}> instead of C<*>
1767 on the external group, no current optimization is applicable, and the
1768 match takes a long time to finish.
1769
1770 A powerful tool for optimizing such beasts is what is known as an
1771 "independent group",
1772 which does not backtrack (see L<C<< (?>pattern) >>>).  Note also that
1773 zero-length look-ahead/look-behind assertions will not backtrack to make
1774 the tail match, since they are in "logical" context: only
1775 whether they match is considered relevant.  For an example
1776 where side-effects of look-ahead I<might> have influenced the
1777 following match, see L<C<< (?>pattern) >>>.
1778
1779 =head2 Version 8 Regular Expressions
1780 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
1781
1782 In case you're not familiar with the "regular" Version 8 regex
1783 routines, here are the pattern-matching rules not described above.
1784
1785 Any single character matches itself, unless it is a I<metacharacter>
1786 with a special meaning described here or above.  You can cause
1787 characters that normally function as metacharacters to be interpreted
1788 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
1789 character; "\\" matches a "\"). This escape mechanism is also required
1790 for the character used as the pattern delimiter.
1791
1792 A series of characters matches that series of characters in the target
1793 string, so the pattern  C<blurfl> would match "blurfl" in the target
1794 string.
1795
1796 You can specify a character class, by enclosing a list of characters
1797 in C<[]>, which will match any character from the list.  If the
1798 first character after the "[" is "^", the class matches any character not
1799 in the list.  Within a list, the "-" character specifies a
1800 range, so that C<a-z> represents all characters between "a" and "z",
1801 inclusive.  If you want either "-" or "]" itself to be a member of a
1802 class, put it at the start of the list (possibly after a "^"), or
1803 escape it with a backslash.  "-" is also taken literally when it is
1804 at the end of the list, just before the closing "]".  (The
1805 following all specify the same class of three characters: C<[-az]>,
1806 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
1807 specifies a class containing twenty-six characters, even on EBCDIC-based
1808 character sets.)  Also, if you try to use the character
1809 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
1810 a range, the "-" is understood literally.
1811
1812 Note also that the whole range idea is rather unportable between
1813 character sets--and even within character sets they may cause results
1814 you probably didn't expect.  A sound principle is to use only ranges
1815 that begin from and end at either alphabetics of equal case ([a-e],
1816 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
1817 spell out the character sets in full.
1818
1819 Characters may be specified using a metacharacter syntax much like that
1820 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
1821 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
1822 of octal digits, matches the character whose coded character set value
1823 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
1824 matches the character whose numeric value is I<nn>. The expression \cI<x>
1825 matches the character control-I<x>.  Finally, the "." metacharacter
1826 matches any character except "\n" (unless you use C</s>).
1827
1828 You can specify a series of alternatives for a pattern using "|" to
1829 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
1830 or "foe" in the target string (as would C<f(e|i|o)e>).  The
1831 first alternative includes everything from the last pattern delimiter
1832 ("(", "[", or the beginning of the pattern) up to the first "|", and
1833 the last alternative contains everything from the last "|" to the next
1834 pattern delimiter.  That's why it's common practice to include
1835 alternatives in parentheses: to minimize confusion about where they
1836 start and end.
1837
1838 Alternatives are tried from left to right, so the first
1839 alternative found for which the entire expression matches, is the one that
1840 is chosen. This means that alternatives are not necessarily greedy. For
1841 example: when matching C<foo|foot> against "barefoot", only the "foo"
1842 part will match, as that is the first alternative tried, and it successfully
1843 matches the target string. (This might not seem important, but it is
1844 important when you are capturing matched text using parentheses.)
1845
1846 Also remember that "|" is interpreted as a literal within square brackets,
1847 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
1848
1849 Within a pattern, you may designate subpatterns for later reference
1850 by enclosing them in parentheses, and you may refer back to the
1851 I<n>th subpattern later in the pattern using the metacharacter
1852 \I<n>.  Subpatterns are numbered based on the left to right order
1853 of their opening parenthesis.  A backreference matches whatever
1854 actually matched the subpattern in the string being examined, not
1855 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\1\d*> will
1856 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
1857 1 matched "0x", even though the rule C<0|0x> could potentially match
1858 the leading 0 in the second number.
1859
1860 =head2 Warning on \1 Instead of $1
1861
1862 Some people get too used to writing things like:
1863
1864     $pattern =~ s/(\W)/\\\1/g;
1865
1866 This is grandfathered for the RHS of a substitute to avoid shocking the
1867 B<sed> addicts, but it's a dirty habit to get into.  That's because in
1868 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
1869 the usual double-quoted string means a control-A.  The customary Unix
1870 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
1871 of doing that, you get yourself into trouble if you then add an C</e>
1872 modifier.
1873
1874     s/(\d+)/ \1 + 1 /eg;        # causes warning under -w
1875
1876 Or if you try to do
1877
1878     s/(\d+)/\1000/;
1879
1880 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
1881 C<${1}000>.  The operation of interpolation should not be confused
1882 with the operation of matching a backreference.  Certainly they mean two
1883 different things on the I<left> side of the C<s///>.
1884
1885 =head2 Repeated Patterns Matching a Zero-length Substring
1886
1887 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
1888
1889 Regular expressions provide a terse and powerful programming language.  As
1890 with most other power tools, power comes together with the ability
1891 to wreak havoc.
1892
1893 A common abuse of this power stems from the ability to make infinite
1894 loops using regular expressions, with something as innocuous as:
1895
1896     'foo' =~ m{ ( o? )* }x;
1897
1898 The C<o?> matches at the beginning of C<'foo'>, and since the position
1899 in the string is not moved by the match, C<o?> would match again and again
1900 because of the C<*> quantifier.  Another common way to create a similar cycle
1901 is with the looping modifier C<//g>:
1902
1903     @matches = ( 'foo' =~ m{ o? }xg );
1904
1905 or
1906
1907     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1908
1909 or the loop implied by split().
1910
1911 However, long experience has shown that many programming tasks may
1912 be significantly simplified by using repeated subexpressions that
1913 may match zero-length substrings.  Here's a simple example being:
1914
1915     @chars = split //, $string;           # // is not magic in split
1916     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1917
1918 Thus Perl allows such constructs, by I<forcefully breaking
1919 the infinite loop>.  The rules for this are different for lower-level
1920 loops given by the greedy quantifiers C<*+{}>, and for higher-level
1921 ones like the C</g> modifier or split() operator.
1922
1923 The lower-level loops are I<interrupted> (that is, the loop is
1924 broken) when Perl detects that a repeated expression matched a
1925 zero-length substring.   Thus
1926
1927    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1928
1929 is made equivalent to
1930
1931    m{   (?: NON_ZERO_LENGTH )*
1932       |
1933         (?: ZERO_LENGTH )?
1934     }x;
1935
1936 The higher level-loops preserve an additional state between iterations:
1937 whether the last match was zero-length.  To break the loop, the following
1938 match after a zero-length match is prohibited to have a length of zero.
1939 This prohibition interacts with backtracking (see L<"Backtracking">),
1940 and so the I<second best> match is chosen if the I<best> match is of
1941 zero length.
1942
1943 For example:
1944
1945     $_ = 'bar';
1946     s/\w??/<$&>/g;
1947
1948 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
1949 match given by non-greedy C<??> is the zero-length match, and the I<second
1950 best> match is what is matched by C<\w>.  Thus zero-length matches
1951 alternate with one-character-long matches.
1952
1953 Similarly, for repeated C<m/()/g> the second-best match is the match at the
1954 position one notch further in the string.
1955
1956 The additional state of being I<matched with zero-length> is associated with
1957 the matched string, and is reset by each assignment to pos().
1958 Zero-length matches at the end of the previous match are ignored
1959 during C<split>.
1960
1961 =head2 Combining RE Pieces
1962
1963 Each of the elementary pieces of regular expressions which were described
1964 before (such as C<ab> or C<\Z>) could match at most one substring
1965 at the given position of the input string.  However, in a typical regular
1966 expression these elementary pieces are combined into more complicated
1967 patterns using combining operators C<ST>, C<S|T>, C<S*> etc
1968 (in these examples C<S> and C<T> are regular subexpressions).
1969
1970 Such combinations can include alternatives, leading to a problem of choice:
1971 if we match a regular expression C<a|ab> against C<"abc">, will it match
1972 substring C<"a"> or C<"ab">?  One way to describe which substring is
1973 actually matched is the concept of backtracking (see L<"Backtracking">).
1974 However, this description is too low-level and makes you think
1975 in terms of a particular implementation.
1976
1977 Another description starts with notions of "better"/"worse".  All the
1978 substrings which may be matched by the given regular expression can be
1979 sorted from the "best" match to the "worst" match, and it is the "best"
1980 match which is chosen.  This substitutes the question of "what is chosen?"
1981 by the question of "which matches are better, and which are worse?".
1982
1983 Again, for elementary pieces there is no such question, since at most
1984 one match at a given position is possible.  This section describes the
1985 notion of better/worse for combining operators.  In the description
1986 below C<S> and C<T> are regular subexpressions.
1987
1988 =over 4
1989
1990 =item C<ST>
1991
1992 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
1993 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
1994 which can be matched by C<T>.
1995
1996 If C<A> is better match for C<S> than C<A'>, C<AB> is a better
1997 match than C<A'B'>.
1998
1999 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2000 C<B> is better match for C<T> than C<B'>.
2001
2002 =item C<S|T>
2003
2004 When C<S> can match, it is a better match than when only C<T> can match.
2005
2006 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2007 two matches for C<T>.
2008
2009 =item C<S{REPEAT_COUNT}>
2010
2011 Matches as C<SSS...S> (repeated as many times as necessary).
2012
2013 =item C<S{min,max}>
2014
2015 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2016
2017 =item C<S{min,max}?>
2018
2019 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2020
2021 =item C<S?>, C<S*>, C<S+>
2022
2023 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2024
2025 =item C<S??>, C<S*?>, C<S+?>
2026
2027 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2028
2029 =item C<< (?>S) >>
2030
2031 Matches the best match for C<S> and only that.
2032
2033 =item C<(?=S)>, C<(?<=S)>
2034
2035 Only the best match for C<S> is considered.  (This is important only if
2036 C<S> has capturing parentheses, and backreferences are used somewhere
2037 else in the whole regular expression.)
2038
2039 =item C<(?!S)>, C<(?<!S)>
2040
2041 For this grouping operator there is no need to describe the ordering, since
2042 only whether or not C<S> can match is important.
2043
2044 =item C<(??{ EXPR })>, C<(?PARNO)>
2045
2046 The ordering is the same as for the regular expression which is
2047 the result of EXPR, or the pattern contained by capture buffer PARNO.
2048
2049 =item C<(?(condition)yes-pattern|no-pattern)>
2050
2051 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2052 already determined.  The ordering of the matches is the same as for the
2053 chosen subexpression.
2054
2055 =back
2056
2057 The above recipes describe the ordering of matches I<at a given position>.
2058 One more rule is needed to understand how a match is determined for the
2059 whole regular expression: a match at an earlier position is always better
2060 than a match at a later position.
2061
2062 =head2 Creating Custom RE Engines
2063
2064 Overloaded constants (see L<overload>) provide a simple way to extend
2065 the functionality of the RE engine.
2066
2067 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2068 matches at a boundary between whitespace characters and non-whitespace
2069 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2070 at these positions, so we want to have each C<\Y|> in the place of the
2071 more complicated version.  We can create a module C<customre> to do
2072 this:
2073
2074     package customre;
2075     use overload;
2076
2077     sub import {
2078       shift;
2079       die "No argument to customre::import allowed" if @_;
2080       overload::constant 'qr' => \&convert;
2081     }
2082
2083     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2084
2085     # We must also take care of not escaping the legitimate \\Y|
2086     # sequence, hence the presence of '\\' in the conversion rules.
2087     my %rules = ( '\\' => '\\\\',
2088                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2089     sub convert {
2090       my $re = shift;
2091       $re =~ s{
2092                 \\ ( \\ | Y . )
2093               }
2094               { $rules{$1} or invalid($re,$1) }sgex;
2095       return $re;
2096     }
2097
2098 Now C<use customre> enables the new escape in constant regular
2099 expressions, i.e., those without any runtime variable interpolations.
2100 As documented in L<overload>, this conversion will work only over
2101 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2102 part of this regular expression needs to be converted explicitly
2103 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2104
2105     use customre;
2106     $re = <>;
2107     chomp $re;
2108     $re = customre::convert $re;
2109     /\Y|$re\Y|/;
2110
2111 =head1 PCRE/Python Support
2112
2113 As of Perl 5.10.0, Perl supports several Python/PCRE specific extensions
2114 to the regex syntax. While Perl programmers are encouraged to use the
2115 Perl specific syntax, the following are also accepted:
2116
2117 =over 4
2118
2119 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2120
2121 Define a named capture buffer. Equivalent to C<< (?<NAME>pattern) >>.
2122
2123 =item C<< (?P=NAME) >>
2124
2125 Backreference to a named capture buffer. Equivalent to C<< \g{NAME} >>.
2126
2127 =item C<< (?P>NAME) >>
2128
2129 Subroutine call to a named capture buffer. Equivalent to C<< (?&NAME) >>.
2130
2131 =back
2132
2133 =head1 BUGS
2134
2135 This document varies from difficult to understand to completely
2136 and utterly opaque.  The wandering prose riddled with jargon is
2137 hard to fathom in several places.
2138
2139 This document needs a rewrite that separates the tutorial content
2140 from the reference content.
2141
2142 =head1 SEE ALSO
2143
2144 L<perlrequick>.
2145
2146 L<perlretut>.
2147
2148 L<perlop/"Regexp Quote-Like Operators">.
2149
2150 L<perlop/"Gory details of parsing quoted constructs">.
2151
2152 L<perlfaq6>.
2153
2154 L<perlfunc/pos>.
2155
2156 L<perllocale>.
2157
2158 L<perlebcdic>.
2159
2160 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2161 by O'Reilly and Associates.