installperl

   1 #!./perl
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '..\lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8     $Is_VMS = $^O eq 'VMS';
   9     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  10 }
  11
  12 use File::Find;
  13 use File::Compare;
  14 use File::Copy ();
  15 use File::Path ();
  16 use ExtUtils::Packlist;
  17 use Config;
  18 use subs qw(unlink link chmod);
  19 use vars qw($packlist);
  20
  21 # override the ones in the rest of the script
  22 sub mkpath {
  23     File::Path::mkpath(@_) unless $nonono;
  24 }
  25
  26 $mainperldir = "/usr/bin";
  27 $exe_ext = $Config{exe_ext};
  28
  29 # Allow ``make install PERLNAME=something_besides_perl'':
  30 $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  31
  32 while (@ARGV) {
  33     $nonono = 1 if $ARGV[0] eq '-n';
  34     $versiononly = 1 if $ARGV[0] eq '-v';
  35     shift;
  36 }
  37
  38 umask 022 unless $Is_VMS;
  39
  40 @scripts = qw(  utils/c2ph utils/h2ph utils/h2xs
  41                 utils/perlbug utils/perldoc utils/pl2pm utils/splain utils/perlcc
  42                 x2p/s2p x2p/find2perl
  43                 pod/pod2man pod/pod2html pod/pod2latex pod/pod2text);
  44
  45 if ($Is_VMS) { @scripts = map { "$_.Com" } @scripts; }
  46
  47 @pods = (<pod/*.pod>);
  48
  49 %archpms = (
  50     Config => 1, FileHandle => 1, overload => 1,
  51     'File/Basename' => 1,       # uses m//t
  52 );
  53
  54 if ($^O eq 'dos') {
  55     push(@scripts,'djgpp/fixpmain');
  56     $archpms{config} = $archpms{filehand} = 1;
  57 }
  58
  59 if ((-e "testcompile") && (defined($ENV{'COMPILE'})))
  60 {
  61         push(@scripts, map("$_.exe", @scripts));
  62 }
  63
  64 find(sub {
  65         if ("$File::Find::dir/$_" =~ m{^ext/[^/]+/(.*)\.pm$}) {
  66             (my $pm = $1) =~ s{^lib/}{};
  67             $archpms{$pm} = 1;
  68         }
  69     }, 'ext');
  70
  71 $ver = $];
  72 $release = substr($ver,0,3);   # Not used presently.
  73 $patchlevel = substr($ver,3,2);
  74 die "Patchlevel of perl ($patchlevel)",
  75     "and patchlevel of config.sh ($Config{'PATCHLEVEL'}) don't match\n"
  76         if $patchlevel != $Config{'PATCHLEVEL'};
  77
  78 # Fetch some frequently-used items from %Config
  79 $installbin = $Config{installbin};
  80 $installscript = $Config{installscript};
  81 $installprivlib = $Config{installprivlib};
  82 $installarchlib = $Config{installarchlib};
  83 $installsitelib = $Config{installsitelib};
  84 $installsitearch = $Config{installsitearch};
  85 $installman1dir = $Config{installman1dir};
  86 $man1ext = $Config{man1ext};
  87 $libperl = $Config{libperl};
  88 # Shared library and dynamic loading suffixes.
  89 $so = $Config{so};
  90 $dlext = $Config{dlext};
  91
  92 $d_dosuid = $Config{d_dosuid};
  93 $binexp = $Config{binexp};
  94
  95 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
  96     foreach ( \$installbin,     \$installscript,  \$installprivlib,
  97               \$installarchlib, \$installsitelib, \$installsitearch,
  98               \$installman1dir ) {
  99       $$_ = unixify($$_);  $$_ =~ s:/$::;
 100     }
 101 }
 102
 103 # Do some quick sanity checks.
 104
 105 if ($d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
 106
 107    $installbin          || die "No installbin directory in config.sh\n";
 108 -d $installbin          || mkpath($installbin, 1, 0777);
 109 -d $installbin          || $nonono || die "$installbin is not a directory\n";
 110 -w $installbin          || $nonono || die "$installbin is not writable by you\n"
 111         unless $installbin =~ m#^/afs/# || $nonono;
 112
 113 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 114 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
 115
 116 -x 't/TEST'             || $^O eq 'MSWin32'
 117                         || warn "WARNING: You've never run 'make test'!!!",
 118                                 "  (Installing anyway.)\n";
 119
 120 if ($^O eq 'MSWin32') {
 121
 122 $perldll = 'perl.' . $dlext;
 123 $perldll = 'perlcore.' . $dlext if $Config{'ccflags'} =~ /PERL_OBJECT/i;
 124
 125 -f $perldll || die "No perl DLL built\n";
 126
 127 # Install the DLL
 128
 129 safe_unlink("$installbin/$perldll");
 130 copy("$perldll", "$installbin/$perldll");
 131 chmod(0755, "$installbin/$perldll");
 132 }
 133
 134 # This will be used to store the packlist
 135 $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 136
 137 # First we install the version-numbered executables.
 138
 139 if ($Is_VMS) {
 140     safe_unlink("$installbin/$perl$exe_ext");
 141     copy("perl$exe_ext", "$installbin/$perl$exe_ext");
 142     chmod(0755, "$installbin/$perl$exe_ext");
 143     safe_unlink("$installbin/${perl}shr$exe_ext");
 144     copy("perlshr$exe_ext", "$installbin/${perl}shr$exe_ext");
 145     chmod(0755, "$installbin/${perl}shr$exe_ext");
 146 }
 147 elsif ($^O ne 'dos') {
 148     safe_unlink("$installbin/$perl$ver$exe_ext");
 149     copy("perl$exe_ext", "$installbin/$perl$ver$exe_ext");
 150     chmod(0755, "$installbin/$perl$ver$exe_ext");
 151 } else {
 152     safe_unlink("$installbin/$perl.exe");
 153     copy("perl.exe", "$installbin/$perl.exe");
 154 }
 155
 156 safe_unlink("$installbin/s$perl$ver$exe_ext");
 157 if ($d_dosuid) {
 158     copy("suidperl$exe_ext", "$installbin/s$perl$ver$exe_ext");
 159     chmod(04711, "$installbin/s$perl$ver$exe_ext");
 160 }
 161
 162 # Install library files.
 163
 164 $do_installarchlib = $do_installprivlib = 0;
 165
 166 mkpath($installprivlib, 1, 0777);
 167 mkpath($installarchlib, 1, 0777);
 168 mkpath($installsitelib, 1, 0777) if ($installsitelib);
 169 mkpath($installsitearch, 1, 0777) if ($installsitearch);
 170
 171 if (chdir "lib") {
 172     $do_installarchlib = ! samepath($installarchlib, '.');
 173     $do_installprivlib = ! samepath($installprivlib, '.');
 174     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$]/);
 175
 176     if ($do_installarchlib || $do_installprivlib) {
 177         find(\&installlib, '.');
 178     }
 179     chdir ".." || die "Can't cd back to source directory: $!\n";
 180 }
 181 else {
 182     warn "Can't cd to lib to install lib files: $!\n";
 183 }
 184
 185 # Install header files and libraries.
 186 mkpath("$installarchlib/CORE", 1, 0777);
 187 if ($Is_VMS) {  # We did core file selection during build
 188     my $coredir = "lib/$Config{'arch'}/$]";
 189     $coredir =~ tr/./_/;
 190     @corefiles = <$coredir/*.*>;
 191 }
 192 else {
 193     @corefiles = <*.h libperl*.*>;
 194     # AIX needs perl.exp installed as well.
 195     push(@corefiles,'perl.exp') if $^O eq 'aix';
 196     # If they have built sperl.o...
 197     push(@corefiles,'sperl.o') if -f 'sperl.o';
 198 }
 199 foreach $file (@corefiles) {
 200     # HP-UX (at least) needs to maintain execute permissions
 201     # on dynamically-loadable libraries. So we do it for all.
 202     copy_if_diff($file,"$installarchlib/CORE/$file")
 203         and chmod($file =~ /\.(so|\Q$dlext\E)$/ ? 0555 : 0444,
 204                    "$installarchlib/CORE/$file");
 205 }
 206
 207 # Install main perl executables
 208 # Make links to ordinary names if installbin directory isn't current directory.
 209
 210 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 211     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 212     link("$installbin/$perl$ver$exe_ext", "$installbin/$perl$exe_ext");
 213     link("$installbin/s$perl$ver$exe_ext", "$installbin/suid$perl$exe_ext")
 214       if $d_dosuid;
 215 }
 216
 217 # Offer to install perl in a "standard" location
 218
 219 $mainperl_is_instperl = 0;
 220
 221 if (!$versiononly && !$nonono && $^O ne 'MSWin32' && !$Is_VMS && -t STDIN && -t STDERR
 222         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 223     local($usrbinperl)  = "$mainperldir/$perl$exe_ext";
 224     local($instperl)    = "$installbin/$perl$exe_ext";
 225     local($expinstperl) = "$binexp/$perl$exe_ext";
 226
 227     # First make sure $usrbinperl is not already the same as the perl we
 228     # just installed.
 229     if (-x $usrbinperl) {
 230         # Try to be clever about mainperl being a symbolic link
 231         # to binexp/perl if binexp and installbin are different.
 232         $mainperl_is_instperl =
 233             samepath($usrbinperl, $instperl) ||
 234             samepath($usrbinperl, $expinstperl) ||
 235              (($binexp ne $installbin) &&
 236               (-l $usrbinperl) &&
 237               ((readlink $usrbinperl) eq $expinstperl));
 238     }
 239     if ((! $mainperl_is_instperl) &&
 240         (yn("Many scripts expect perl to be installed as $usrbinperl.\n" .
 241              "Do you wish to have $usrbinperl be the same as\n" .
 242              "$expinstperl? [y] ")))
 243     {
 244         unlink($usrbinperl);
 245         eval { CORE::link $instperl, $usrbinperl } ||
 246             eval { symlink $expinstperl, $usrbinperl } ||
 247                 copy($instperl, $usrbinperl);
 248         $mainperl_is_instperl = 1;
 249     }
 250 }
 251
 252 # Make links to ordinary names if installbin directory isn't current directory.
 253
 254 if (!$versiononly && ! samepath($installbin, 'x2p')) {
 255     safe_unlink("$installbin/a2p$exe_ext");
 256     copy("x2p/a2p$exe_ext", "$installbin/a2p$exe_ext");
 257     chmod(0755, "$installbin/a2p$exe_ext");
 258 }
 259
 260 # cppstdin is just a script, but it is architecture-dependent, so
 261 # it can't safely be shared.  Place it in $installbin.
 262 # Note that Configure doesn't build cppstin if it isn't needed, so
 263 # we skip this if cppstdin doesn't exist.
 264 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 265     safe_unlink("$installbin/cppstdin");
 266     copy("cppstdin", "$installbin/cppstdin");
 267     chmod(0755, "$installbin/cppstdin");
 268 }
 269
 270 # Install scripts.
 271
 272 mkpath($installscript, 1, 0777);
 273
 274 if (! $versiononly) {
 275     for (@scripts) {
 276         (my $base = $_) =~ s#.*/##;
 277         copy($_, "$installscript/$base");
 278         chmod(0755, "$installscript/$base");
 279     }
 280 }
 281
 282 # pstruct should be a link to c2ph
 283
 284 if (! $versiononly) {
 285     safe_unlink("$installscript/pstruct" . ($Is_VMS ? '.Com' : ''));
 286     if ($^O eq 'dos' or $Is_VMS) {
 287         copy("$installscript/c2ph" . ($Is_VMS ? '.Com' : ''),
 288              "$installscript/pstruct" . ($Is_VMS ? '.Com' : ''));
 289     } else {
 290         link("$installscript/c2ph","$installscript/pstruct");
 291     }
 292 }
 293
 294 # Install pod pages.  Where? I guess in $installprivlib/pod.
 295
 296 if (! $versiononly || !($installprivlib =~ m/\Q$]/)) {
 297     mkpath("${installprivlib}/pod", 1, 0777);
 298
 299     # If Perl 5.003's perldiag.pod is there, rename it.
 300     if (open POD, "${installprivlib}/pod/perldiag.pod") {
 301         read POD, $_, 4000;
 302         close POD;
 303         # Some of Perl 5.003's diagnostic messages ended with periods.
 304         if (/^=.*\.$/m) {
 305             my ($from, $to) = ("${installprivlib}/pod/perldiag.pod",
 306                                "${installprivlib}/pod/perldiag-5.003.pod");
 307             print STDERR "  rename $from $to";
 308             rename($from, $to)
 309                 or warn "Couldn't rename $from to $to: $!\n"
 310                 unless $nonono;
 311         }
 312     }
 313
 314     foreach $file (@pods) {
 315         # $file is a name like  pod/perl.pod
 316         copy_if_diff($file, "${installprivlib}/${file}");
 317     }
 318
 319     # Link perldiag.pod into archlib
 320     my ($from, $to) = ("${installprivlib}/pod/perldiag.pod",
 321                        "${installarchlib}/pod/perldiag.pod");
 322     $packlist->{$to} = { from => $from, type => 'link' };
 323     if (compare($from, $to) || $nonono) {
 324         mkpath("${installarchlib}/pod", 1, 0777);
 325         unlink($to);
 326         link($from, $to) if ($^O ne 'dos');
 327     }
 328 }
 329
 330 # Check to make sure there aren't other perls around in installer's
 331 # path.  This is probably UNIX-specific.  Check all absolute directories
 332 # in the path except for where public executables are supposed to live.
 333 # Also skip $mainperl if the user opted to have it be a link to the
 334 # installed perl.
 335
 336 if (!$versiononly) {
 337
 338     $dirsep = ($^O eq 'os2' || $^O eq 'MSWin32') ? ';' : ':' ;
 339     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 340     @path = split(/$dirsep/, $path);
 341     if ($Is_VMS) {
 342         my $i = 0;
 343         while (exists $ENV{'DCL$PATH' . $i}) {
 344             $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 345             push(@path,$dir);
 346         }
 347     }
 348     @otherperls = ();
 349     for (@path) {
 350         next unless m,^/,;
 351         # Use &samepath here because some systems have other dirs linked
 352         # to $mainperldir (like SunOS)
 353         next if samepath($_, $binexp);
 354         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 355         push(@otherperls, "$_/$perl$exe_ext")
 356             if (-x "$_/$perl$exe_ext" && ! -d "$_/$perl$exe_ext");
 357     }
 358     if (@otherperls) {
 359         print STDERR "\nWarning: $perl appears in your path in the following " .
 360             "locations beyond where\nwe just installed it:\n";
 361         for (@otherperls) {
 362             print STDERR "    ", $_, "\n";
 363         }
 364         print STDERR "\n";
 365     }
 366
 367 }
 368
 369 $packlist->write() unless $nono;
 370 print STDERR "  Installation complete\n";
 371
 372 exit 0;
 373
 374 ###############################################################################
 375
 376 sub yn {
 377     local($prompt) = @_;
 378     local($answer);
 379     local($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 380     print STDERR $prompt;
 381     chop($answer = <STDIN>);
 382     $answer = $default if $answer =~ m/^\s*$/;
 383     ($answer =~ m/^[yY]/);
 384 }
 385
 386 sub unlink {
 387     local(@names) = @_;
 388     my($cnt) = 0;
 389
 390     return scalar(@names) if $Is_VMS;
 391
 392     foreach $name (@names) {
 393         next unless -e $name;
 394         chmod 0777, $name if ($^O eq 'os2' || $^O eq 'MSWin32');
 395         print STDERR "  unlink $name\n";
 396         ( CORE::unlink($name) and ++$cnt
 397           or warn "Couldn't unlink $name: $!\n" ) unless $nonono;
 398     }
 399     return $cnt;
 400 }
 401
 402 sub safe_unlink {
 403     return if $nonono or $Is_VMS;
 404     local @names = @_;
 405     foreach $name (@names) {
 406         next unless -e $name;
 407         chmod 0777, $name if ($^O eq 'os2' || $^O eq 'MSWin32');
 408         print STDERR "  unlink $name\n";
 409         next if CORE::unlink($name);
 410         warn "Couldn't unlink $name: $!\n";
 411         if ($! =~ /busy/i) {
 412             print STDERR "  mv $name $name.old\n";
 413             safe_rename($name, "$name.old")
 414                 or warn "Couldn't rename $name: $!\n";
 415         }
 416     }
 417 }
 418
 419 sub safe_rename {
 420     local($from,$to) = @_;
 421     if (-f $to and not unlink($to)) {
 422         my($i);
 423         for ($i = 1; $i < 50; $i++) {
 424             last if rename($to, "$to.$i");
 425         }
 426         warn("Cannot rename to `$to.$i': $!"), return 0
 427            if $i >= 50; # Give up!
 428     }
 429     link($from,$to) || return 0;
 430     unlink($from);
 431 }
 432
 433 sub link {
 434     my($from,$to) = @_;
 435     my($success) = 0;
 436
 437     print STDERR "  ln $from $to\n";
 438     eval {
 439         CORE::link($from, $to)
 440             ? $success++
 441             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
 442               ? die "AFS"  # okay inside eval {}
 443               : warn "Couldn't link $from to $to: $!\n"
 444           unless $nonono;
 445         $packlist->{$to} = { from => $from, type => 'link' };
 446     };
 447     if ($@) {
 448         print STDERR "  creating new version of $to\n" if $Is_VMS and -e $to;
 449         File::Copy::copy($from, $to)
 450             ? $success++
 451             : warn "Couldn't copy $from to $to: $!\n"
 452           unless $nonono;
 453         $packlist->{$to} = { type => 'file' };
 454     }
 455     $success;
 456 }
 457
 458 sub chmod {
 459     local($mode,$name) = @_;
 460
 461     return if ($^O eq 'dos');
 462     printf STDERR "  chmod %o %s\n", $mode, $name;
 463     CORE::chmod($mode,$name)
 464         || warn sprintf("Couldn't chmod %o %s: $!\n", $mode, $name)
 465       unless $nonono;
 466 }
 467
 468 sub copy {
 469     my($from,$to) = @_;
 470
 471     print STDERR "  cp $from $to\n";
 472     print STDERR "  creating new version of $to\n" if $Is_VMS and -e $to;
 473     File::Copy::copy($from, $to)
 474         || warn "Couldn't copy $from to $to: $!\n"
 475       unless $nonono;
 476     $packlist->{$to} = { type => 'file' };
 477 }
 478
 479 sub samepath {
 480     local($p1, $p2) = @_;
 481
 482     return (lc($p1) eq lc($p2)) if ($^O eq 'MSWin32');
 483
 484     if ($p1 ne $p2) {
 485         local($dev1, $ino1, $dev2, $ino2);
 486         ($dev1, $ino1) = stat($p1);
 487         ($dev2, $ino2) = stat($p2);
 488         ($dev1 == $dev2 && $ino1 == $ino2);
 489     }
 490     else {
 491         1;
 492     }
 493 }
 494
 495 sub installlib {
 496     my $dir = $File::Find::dir;
 497     $dir =~ s#^\.(?![^/])/?##;
 498     local($depth) = $dir ? "lib/$dir" : "lib";
 499
 500     my $name = $_;
 501
 502     if ($name eq 'CVS' && -d $name) {
 503         $File::Find::prune = 1;
 504         return;
 505     }
 506
 507     # ignore patch backups and the .exists files.
 508     return if $name =~ m{\.orig$|~$|^\.exists};
 509
 510     $name = "$dir/$name" if $dir ne '';
 511
 512     my $installlib = $installprivlib;
 513     if ($dir =~ /^auto/ ||
 514           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 515           ($name =~ /^(.*)\.(?:h|lib)$/i && $^O eq 'MSWin32')
 516        ) {
 517         $installlib = $installarchlib;
 518         return unless $do_installarchlib;
 519     } else {
 520         return unless $do_installprivlib;
 521     }
 522
 523     if (-f $_) {
 524         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$] && $archpms{$1})) {
 525             $installlib = $installprivlib;
 526             #We're installing *.al and *.ix files into $installprivlib,
 527             #but we have to delete old *.al and *.ix files from the 5.000
 528             #distribution:
 529             #This might not work because $archname might have changed.
 530             unlink("$installarchlib/$name");
 531         }
 532         $packlist->{"$installlib/$name"} = { type => 'file' };
 533         if (compare($_, "$installlib/$name") || $nonono) {
 534             unlink("$installlib/$name");
 535             mkpath("$installlib/$dir", 1, 0777);
 536             # HP-UX (at least) needs to maintain execute permissions
 537             # on dynamically-loaded libraries.
 538             copy_if_diff($_, "$installlib/$name")
 539                 and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
 540                            "$installlib/$name");
 541         }
 542     } elsif (-d $_) {
 543         mkpath("$installlib/$name", 1, 0777);
 544     }
 545 }
 546
 547 # Copy $from to $to, only if $from is different than $to.
 548 # Also preserve modification times for .a libraries.
 549 # On some systems, if you do
 550 #   ranlib libperl.a
 551 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 552 # and then try to link against the installed libperl.a, you might
 553 # get an error message to the effect that the symbol table is older
 554 # than the library.
 555 # Return true if copying occurred.
 556
 557 sub copy_if_diff {
 558     my($from,$to)=@_;
 559     -f $from || die "$0: $from not found";
 560     $packlist->{$to} = { type => 'file' };
 561     if (compare($from, $to) || $nonono) {
 562         safe_unlink($to);   # In case we don't have write permissions.
 563         if ($nonono) {
 564             $from = $depth . "/" . $from if $depth;
 565         }
 566         copy($from, $to);
 567         # Restore timestamps if it's a .a library or for OS/2.
 568         if (!$nonono && ($^O eq 'os2' || $to =~ /\.a$/)) {
 569             my ($atime, $mtime) = (stat $from)[8,9];
 570             utime $atime, $mtime, $to;
 571         }
 572         1;
 573     }
 574 }