This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
e7aa869ec6fec3d8d615df844294f377c48b744b
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # Needs 'no overloading' to run faster on miniperl.  Code commented out at the
8 # subroutine objaddr can be used instead to work as far back (untested) as
9 # 5.8: needs pack "U".  But almost all occurrences of objaddr have been
10 # removed in favor of using 'no overloading'.  You also would have to go
11 # through and replace occurrences like:
12 #       my $addr = do { no overloading; pack 'J', $self; }
13 # with
14 #       my $addr = main::objaddr $self;
15 # (or reverse commit 9b01bafde4b022706c3d6f947a0963f821b2e50b
16 # that instituted the change to main::objaddr, and subsequent commits that
17 # changed 0+$self to pack 'J', $self.)
18
19 my $start_time;
20 BEGIN { # Get the time the script started running; do it at compilation to
21         # get it as close as possible
22     $start_time= time;
23 }
24
25 require 5.010_001;
26 use strict;
27 use warnings;
28 use Carp;
29 use Config;
30 use File::Find;
31 use File::Path;
32 use File::Spec;
33 use Text::Tabs;
34 use re "/aa";
35
36 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
37 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
38
39 ##########################################################################
40 #
41 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
42 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
43 # a pod file and .t files, depending on option parameters.
44 #
45 # The structure of this file is:
46 #   First these introductory comments; then
47 #   code needed for everywhere, such as debugging stuff; then
48 #   code to handle input parameters; then
49 #   data structures likely to be of external interest (some of which depend on
50 #       the input parameters, so follows them; then
51 #   more data structures and subroutine and package (class) definitions; then
52 #   the small actual loop to process the input files and finish up; then
53 #   a __DATA__ section, for the .t tests
54 #
55 # This program works on all releases of Unicode so far.  The outputs have been
56 # scrutinized most intently for release 5.1.  The others have been checked for
57 # somewhat more than just sanity.  It can handle all non-provisional Unicode
58 # character properties in those releases.
59 #
60 # This program is mostly about Unicode character (or code point) properties.
61 # A property describes some attribute or quality of a code point, like if it
62 # is lowercase or not, its name, what version of Unicode it was first defined
63 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
64 # possibilities by making all properties into mappings from each code point
65 # into some corresponding value.  In the case of it being lowercase or not,
66 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
67 # property maps each Unicode code point to a single value, called a "property
68 # value".  (Some more recently defined properties, map a code point to a set
69 # of values.)
70 #
71 # When using a property in a regular expression, what is desired isn't the
72 # mapping of the code point to its property's value, but the reverse (or the
73 # mathematical "inverse relation"): starting with the property value, "Does a
74 # code point map to it?"  These are written in a "compound" form:
75 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
76 # files containing the lists of code points that map to each such regular
77 # expression property value, one file per list
78 #
79 # There is also a single form shortcut that Perl adds for many of the commonly
80 # used properties.  This happens for all binary properties, plus script,
81 # general_category, and block properties.
82 #
83 # Thus the outputs of this program are files.  There are map files, mostly in
84 # the 'To' directory; and there are list files for use in regular expression
85 # matching, all in subdirectories of the 'lib' directory, with each
86 # subdirectory being named for the property that the lists in it are for.
87 # Bookkeeping, test, and documentation files are also generated.
88
89 my $matches_directory = 'lib';   # Where match (\p{}) files go.
90 my $map_directory = 'To';        # Where map files go.
91
92 # DATA STRUCTURES
93 #
94 # The major data structures of this program are Property, of course, but also
95 # Table.  There are two kinds of tables, very similar to each other.
96 # "Match_Table" is the data structure giving the list of code points that have
97 # a particular property value, mentioned above.  There is also a "Map_Table"
98 # data structure which gives the property's mapping from code point to value.
99 # There are two structures because the match tables need to be combined in
100 # various ways, such as constructing unions, intersections, complements, etc.,
101 # and the map ones don't.  And there would be problems, perhaps subtle, if
102 # a map table were inadvertently operated on in some of those ways.
103 # The use of separate classes with operations defined on one but not the other
104 # prevents accidentally confusing the two.
105 #
106 # At the heart of each table's data structure is a "Range_List", which is just
107 # an ordered list of "Ranges", plus ancillary information, and methods to
108 # operate on them.  A Range is a compact way to store property information.
109 # Each range has a starting code point, an ending code point, and a value that
110 # is meant to apply to all the code points between the two end points,
111 # inclusive.  For a map table, this value is the property value for those
112 # code points.  Two such ranges could be written like this:
113 #   0x41 .. 0x5A, 'Upper',
114 #   0x61 .. 0x7A, 'Lower'
115 #
116 # Each range also has a type used as a convenience to classify the values.
117 # Most ranges in this program will be Type 0, or normal, but there are some
118 # ranges that have a non-zero type.  These are used only in map tables, and
119 # are for mappings that don't fit into the normal scheme of things.  Mappings
120 # that require a hash entry to communicate with utf8.c are one example;
121 # another example is mappings for charnames.pm to use which indicate a name
122 # that is algorithmically determinable from its code point (and the reverse).
123 # These are used to significantly compact these tables, instead of listing
124 # each one of the tens of thousands individually.
125 #
126 # In a match table, the value of a range is irrelevant (and hence the type as
127 # well, which will always be 0), and arbitrarily set to the null string.
128 # Using the example above, there would be two match tables for those two
129 # entries, one named Upper would contain the 0x41..0x5A range, and the other
130 # named Lower would contain 0x61..0x7A.
131 #
132 # Actually, there are two types of range lists, "Range_Map" is the one
133 # associated with map tables, and "Range_List" with match tables.
134 # Again, this is so that methods can be defined on one and not the others so
135 # as to prevent operating on them in incorrect ways.
136 #
137 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
138 # in the perl core.  All tables could in theory be written, but some are
139 # suppressed because there is no current practical use for them.  It is easy
140 # to change which get written by changing various lists that are near the top
141 # of the actual code in this file.  The table data structures contain enough
142 # ancillary information to allow them to be treated as separate entities for
143 # writing, such as the path to each one's file.  There is a heading in each
144 # map table that gives the format of its entries, and what the map is for all
145 # the code points missing from it.  (This allows tables to be more compact.)
146 #
147 # The Property data structure contains one or more tables.  All properties
148 # contain a map table (except the $perl property which is a
149 # pseudo-property containing only match tables), and any properties that
150 # are usable in regular expression matches also contain various matching
151 # tables, one for each value the property can have.  A binary property can
152 # have two values, True and False (or Y and N, which are preferred by Unicode
153 # terminology).  Thus each of these properties will have a map table that
154 # takes every code point and maps it to Y or N (but having ranges cuts the
155 # number of entries in that table way down), and two match tables, one
156 # which has a list of all the code points that map to Y, and one for all the
157 # code points that map to N.  (For each binary property, a third table is also
158 # generated for the pseudo Perl property.  It contains the identical code
159 # points as the Y table, but can be written in regular expressions, not in the
160 # compound form, but in a "single" form like \p{IsUppercase}.)  Many
161 # properties are binary, but some properties have several possible values,
162 # some have many, and properties like Name have a different value for every
163 # named code point.  Those will not, unless the controlling lists are changed,
164 # have their match tables written out.  But all the ones which can be used in
165 # regular expression \p{} and \P{} constructs will.  Prior to 5.14, generally
166 # a property would have either its map table or its match tables written but
167 # not both.  Again, what gets written is controlled by lists which can easily
168 # be changed.  Starting in 5.14, advantage was taken of this, and all the map
169 # tables needed to reconstruct the Unicode db are now written out, while
170 # suppressing the Unicode .txt files that contain the data.  Our tables are
171 # much more compact than the .txt files, so a significant space savings was
172 # achieved.  Also, tables are not written out that are trivially derivable
173 # from tables that do get written.  So, there typically is no file containing
174 # the code points not matched by a binary property (the table for \P{} versus
175 # lowercase \p{}), since you just need to invert the True table to get the
176 # False table.
177
178 # Properties have a 'Type', like 'binary', or 'string', or 'enum' depending on
179 # how many match tables there are and the content of the maps.  This 'Type' is
180 # different than a range 'Type', so don't get confused by the two concepts
181 # having the same name.
182 #
183 # For information about the Unicode properties, see Unicode's UAX44 document:
184
185 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
186
187 # As stated earlier, this program will work on any release of Unicode so far.
188 # Most obvious problems in earlier data have NOT been corrected except when
189 # necessary to make Perl or this program work reasonably, and to keep out
190 # potential security issues.  For example, no folding information was given in
191 # early releases, so this program substitutes lower case instead, just so that
192 # a regular expression with the /i option will do something that actually
193 # gives the right results in many cases.  There are also a couple other
194 # corrections for version 1.1.5, commented at the point they are made.  As an
195 # example of corrections that weren't made (but could be) is this statement
196 # from DerivedAge.txt: "The supplementary private use code points and the
197 # non-character code points were assigned in version 2.0, but not specifically
198 # listed in the UCD until versions 3.0 and 3.1 respectively."  (To be precise
199 # it was 3.0.1 not 3.0.0)  More information on Unicode version glitches is
200 # further down in these introductory comments.
201 #
202 # This program works on all non-provisional properties as of the current
203 # Unicode release, though the files for some are suppressed for various
204 # reasons.  You can change which are output by changing lists in this program.
205 #
206 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
207 # loose matchings rules (from Unicode TR18):
208 #
209 #    The recommended names for UCD properties and property values are in
210 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
211 #    [PropValue]. There are both abbreviated names and longer, more
212 #    descriptive names. It is strongly recommended that both names be
213 #    recognized, and that loose matching of property names be used,
214 #    whereby the case distinctions, whitespace, hyphens, and underbar
215 #    are ignored.
216 #
217 # The program still allows Fuzzy to override its determination of if loose
218 # matching should be used, but it isn't currently used, as it is no longer
219 # needed; the calculations it makes are good enough.
220 #
221 # SUMMARY OF HOW IT WORKS:
222 #
223 #   Process arguments
224 #
225 #   A list is constructed containing each input file that is to be processed
226 #
227 #   Each file on the list is processed in a loop, using the associated handler
228 #   code for each:
229 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
230 #            first.  These files name the properties and property values.
231 #            Objects are created of all the property and property value names
232 #            that the rest of the input should expect, including all synonyms.
233 #        The other input files give mappings from properties to property
234 #           values.  That is, they list code points and say what the mapping
235 #           is under the given property.  Some files give the mappings for
236 #           just one property; and some for many.  This program goes through
237 #           each file and populates the properties and their map tables from
238 #           them.  Some properties are listed in more than one file, and
239 #           Unicode has set up a precedence as to which has priority if there
240 #           is a conflict.  Thus the order of processing matters, and this
241 #           program handles the conflict possibility by processing the
242 #           overriding input files last, so that if necessary they replace
243 #           earlier values.
244 #        After this is all done, the program creates the property mappings not
245 #            furnished by Unicode, but derivable from what it does give.
246 #        The tables of code points that match each property value in each
247 #            property that is accessible by regular expressions are created.
248 #        The Perl-defined properties are created and populated.  Many of these
249 #            require data determined from the earlier steps
250 #        Any Perl-defined synonyms are created, and name clashes between Perl
251 #            and Unicode are reconciled and warned about.
252 #        All the properties are written to files
253 #        Any other files are written, and final warnings issued.
254 #
255 # For clarity, a number of operators have been overloaded to work on tables:
256 #   ~ means invert (take all characters not in the set).  The more
257 #       conventional '!' is not used because of the possibility of confusing
258 #       it with the actual boolean operation.
259 #   + means union
260 #   - means subtraction
261 #   & means intersection
262 # The precedence of these is the order listed.  Parentheses should be
263 # copiously used.  These are not a general scheme.  The operations aren't
264 # defined for a number of things, deliberately, to avoid getting into trouble.
265 # Operations are done on references and affect the underlying structures, so
266 # that the copy constructors for them have been overloaded to not return a new
267 # clone, but the input object itself.
268 #
269 # The bool operator is deliberately not overloaded to avoid confusion with
270 # "should it mean if the object merely exists, or also is non-empty?".
271 #
272 # WHY CERTAIN DESIGN DECISIONS WERE MADE
273 #
274 # This program needs to be able to run under miniperl.  Therefore, it uses a
275 # minimum of other modules, and hence implements some things itself that could
276 # be gotten from CPAN
277 #
278 # This program uses inputs published by the Unicode Consortium.  These can
279 # change incompatibly between releases without the Perl maintainers realizing
280 # it.  Therefore this program is now designed to try to flag these.  It looks
281 # at the directories where the inputs are, and flags any unrecognized files.
282 # It keeps track of all the properties in the files it handles, and flags any
283 # that it doesn't know how to handle.  It also flags any input lines that
284 # don't match the expected syntax, among other checks.
285 #
286 # It is also designed so if a new input file matches one of the known
287 # templates, one hopefully just needs to add it to a list to have it
288 # processed.
289 #
290 # As mentioned earlier, some properties are given in more than one file.  In
291 # particular, the files in the extracted directory are supposedly just
292 # reformattings of the others.  But they contain information not easily
293 # derivable from the other files, including results for Unihan, which this
294 # program doesn't ordinarily look at, and for unassigned code points.  They
295 # also have historically had errors or been incomplete.  In an attempt to
296 # create the best possible data, this program thus processes them first to
297 # glean information missing from the other files; then processes those other
298 # files to override any errors in the extracted ones.  Much of the design was
299 # driven by this need to store things and then possibly override them.
300 #
301 # It tries to keep fatal errors to a minimum, to generate something usable for
302 # testing purposes.  It always looks for files that could be inputs, and will
303 # warn about any that it doesn't know how to handle (the -q option suppresses
304 # the warning).
305 #
306 # Why is there more than one type of range?
307 #   This simplified things.  There are some very specialized code points that
308 #   have to be handled specially for output, such as Hangul syllable names.
309 #   By creating a range type (done late in the development process), it
310 #   allowed this to be stored with the range, and overridden by other input.
311 #   Originally these were stored in another data structure, and it became a
312 #   mess trying to decide if a second file that was for the same property was
313 #   overriding the earlier one or not.
314 #
315 # Why are there two kinds of tables, match and map?
316 #   (And there is a base class shared by the two as well.)  As stated above,
317 #   they actually are for different things.  Development proceeded much more
318 #   smoothly when I (khw) realized the distinction.  Map tables are used to
319 #   give the property value for every code point (actually every code point
320 #   that doesn't map to a default value).  Match tables are used for regular
321 #   expression matches, and are essentially the inverse mapping.  Separating
322 #   the two allows more specialized methods, and error checks so that one
323 #   can't just take the intersection of two map tables, for example, as that
324 #   is nonsensical.
325 #
326 # What about 'fate' and 'status'.  The concept of a table's fate was created
327 #   late when it became clear that something more was needed.  The difference
328 #   between this and 'status' is unclean, and could be improved if someone
329 #   wanted to spend the effort.
330 #
331 # DEBUGGING
332 #
333 # This program is written so it will run under miniperl.  Occasionally changes
334 # will cause an error where the backtrace doesn't work well under miniperl.
335 # To diagnose the problem, you can instead run it under regular perl, if you
336 # have one compiled.
337 #
338 # There is a good trace facility.  To enable it, first sub DEBUG must be set
339 # to return true.  Then a line like
340 #
341 # local $to_trace = 1 if main::DEBUG;
342 #
343 # can be added to enable tracing in its lexical scope (plus dynamic) or until
344 # you insert another line:
345 #
346 # local $to_trace = 0 if main::DEBUG;
347 #
348 # To actually trace, use a line like "trace $a, @b, %c, ...;
349 #
350 # Some of the more complex subroutines already have trace statements in them.
351 # Permanent trace statements should be like:
352 #
353 # trace ... if main::DEBUG && $to_trace;
354 #
355 # If there is just one or a few files that you're debugging, you can easily
356 # cause most everything else to be skipped.  Change the line
357 #
358 # my $debug_skip = 0;
359 #
360 # to 1, and every file whose object is in @input_file_objects and doesn't have
361 # a, 'non_skip => 1,' in its constructor will be skipped.  However, skipping
362 # Jamo.txt or UnicodeData.txt will likely cause fatal errors.
363 #
364 # To compare the output tables, it may be useful to specify the -annotate
365 # flag.  This causes the tables to expand so there is one entry for each
366 # non-algorithmically named code point giving, currently its name, and its
367 # graphic representation if printable (and you have a font that knows about
368 # it).  This makes it easier to see what the particular code points are in
369 # each output table.  The tables are usable, but because they don't have
370 # ranges (for the most part), a Perl using them will run slower.  Non-named
371 # code points are annotated with a description of their status, and contiguous
372 # ones with the same description will be output as a range rather than
373 # individually.  Algorithmically named characters are also output as ranges,
374 # except when there are just a few contiguous ones.
375 #
376 # FUTURE ISSUES
377 #
378 # The program would break if Unicode were to change its names so that
379 # interior white space, underscores, or dashes differences were significant
380 # within property and property value names.
381 #
382 # It might be easier to use the xml versions of the UCD if this program ever
383 # would need heavy revision, and the ability to handle old versions was not
384 # required.
385 #
386 # There is the potential for name collisions, in that Perl has chosen names
387 # that Unicode could decide it also likes.  There have been such collisions in
388 # the past, with mostly Perl deciding to adopt the Unicode definition of the
389 # name.  However in the 5.2 Unicode beta testing, there were a number of such
390 # collisions, which were withdrawn before the final release, because of Perl's
391 # and other's protests.  These all involved new properties which began with
392 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
393 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
394 # Unicode document, so they are unlikely to be used by Unicode for another
395 # purpose.  However, they might try something beginning with 'In', or use any
396 # of the other Perl-defined properties.  This program will warn you of name
397 # collisions, and refuse to generate tables with them, but manual intervention
398 # will be required in this event.  One scheme that could be implemented, if
399 # necessary, would be to have this program generate another file, or add a
400 # field to mktables.lst that gives the date of first definition of a property.
401 # Each new release of Unicode would use that file as a basis for the next
402 # iteration.  And the Perl synonym addition code could sort based on the age
403 # of the property, so older properties get priority, and newer ones that clash
404 # would be refused; hence existing code would not be impacted, and some other
405 # synonym would have to be used for the new property.  This is ugly, and
406 # manual intervention would certainly be easier to do in the short run; lets
407 # hope it never comes to this.
408 #
409 # A NOTE ON UNIHAN
410 #
411 # This program can generate tables from the Unihan database.  But it doesn't
412 # by default, letting the CPAN module Unicode::Unihan handle them.  Prior to
413 # version 5.2, this database was in a single file, Unihan.txt.  In 5.2 the
414 # database was split into 8 different files, all beginning with the letters
415 # 'Unihan'.  This program will read those file(s) if present, but it needs to
416 # know which of the many properties in the file(s) should have tables created
417 # for them.  It will create tables for any properties listed in
418 # PropertyAliases.txt and PropValueAliases.txt, plus any listed in the
419 # @cjk_properties array and the @cjk_property_values array.  Thus, if a
420 # property you want is not in those files of the release you are building
421 # against, you must add it to those two arrays.  Starting in 4.0, the
422 # Unicode_Radical_Stroke was listed in those files, so if the Unihan database
423 # is present in the directory, a table will be generated for that property.
424 # In 5.2, several more properties were added.  For your convenience, the two
425 # arrays are initialized with all the 6.0 listed properties that are also in
426 # earlier releases.  But these are commented out.  You can just uncomment the
427 # ones you want, or use them as a template for adding entries for other
428 # properties.
429 #
430 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
431 # and filter_unihan_line() are the functions where this is done.  This program
432 # already does some adjusting to make the lines look more like the rest of the
433 # Unicode DB;  You can see what that is in filter_unihan_line()
434 #
435 # There is a bug in the 3.2 data file in which some values for the
436 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
437 # could be added for these; or for a particular installation, the Unihan.txt
438 # file could be edited to fix them.
439 #
440 # HOW TO ADD A FILE TO BE PROCESSED
441 #
442 # A new file from Unicode needs to have an object constructed for it in
443 # @input_file_objects, probably at the end or at the end of the extracted
444 # ones.  The program should warn you if its name will clash with others on
445 # restrictive file systems, like DOS.  If so, figure out a better name, and
446 # add lines to the README.perl file giving that.  If the file is a character
447 # property, it should be in the format that Unicode has implicitly
448 # standardized for such files for the more recently introduced ones.
449 # If so, the Input_file constructor for @input_file_objects can just be the
450 # file name and release it first appeared in.  If not, then it should be
451 # possible to construct an each_line_handler() to massage the line into the
452 # standardized form.
453 #
454 # For non-character properties, more code will be needed.  You can look at
455 # the existing entries for clues.
456 #
457 # UNICODE VERSIONS NOTES
458 #
459 # The Unicode UCD has had a number of errors in it over the versions.  And
460 # these remain, by policy, in the standard for that version.  Therefore it is
461 # risky to correct them, because code may be expecting the error.  So this
462 # program doesn't generally make changes, unless the error breaks the Perl
463 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
464 # for U+1105, which causes real problems for the algorithms for Jamo
465 # calculations, so it is changed here.
466 #
467 # But it isn't so clear cut as to what to do about concepts that are
468 # introduced in a later release; should they extend back to earlier releases
469 # where the concept just didn't exist?  It was easier to do this than to not,
470 # so that's what was done.  For example, the default value for code points not
471 # in the files for various properties was probably undefined until changed by
472 # some version.  No_Block for blocks is such an example.  This program will
473 # assign No_Block even in Unicode versions that didn't have it.  This has the
474 # benefit that code being written doesn't have to special case earlier
475 # versions; and the detriment that it doesn't match the Standard precisely for
476 # the affected versions.
477 #
478 # Here are some observations about some of the issues in early versions:
479 #
480 # Prior to version 3.0, there were 3 character decompositions.  These are not
481 # handled by Unicode::Normalize, nor will it compile when presented a version
482 # that has them.  However, you can trivially get it to compile by simply
483 # ignoring those decompositions, by changing the croak to a carp.  At the time
484 # of this writing, the line (in cpan/Unicode-Normalize/mkheader) reads
485 #
486 #   croak("Weird Canonical Decomposition of U+$h");
487 #
488 # Simply change to a carp.  It will compile, but will not know about any three
489 # character decomposition.
490
491 # The number of code points in \p{alpha=True} halved in 2.1.9.  It turns out
492 # that the reason is that the CJK block starting at 4E00 was removed from
493 # PropList, and was not put back in until 3.1.0.  The Perl extension (the
494 # single property name \p{alpha}) has the correct values.  But the compound
495 # form is simply not generated until 3.1, as it can be argued that prior to
496 # this release, this was not an official property.  The comments for
497 # filter_old_style_proplist() give more details.
498 #
499 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
500 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
501 # reason is that 3.2 introduced U+205F=medium math space, which was not
502 # classed as white space, but Perl figured out that it should have been. 4.0
503 # reclassified it correctly.
504 #
505 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
506 # this was erroneously a synonym for 202 (it should be 200).  In 4.0, ATB
507 # became 202, and ATBL was left with no code points, as all the ones that
508 # mapped to 202 stayed mapped to 202.  Thus if your program used the numeric
509 # name for the class, it would not have been affected, but if it used the
510 # mnemonic, it would have been.
511 #
512 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that code
513 # points which eventually came to have this script property value, instead
514 # mapped to "Unknown".  But in the next release all these code points were
515 # moved to \p{sc=common} instead.
516 #
517 # The default for missing code points for BidiClass is complicated.  Starting
518 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
519 # tries to do the best it can for earlier releases.  It is done in
520 # process_PropertyAliases()
521 #
522 # In version 2.1.2, the entry in UnicodeData.txt:
523 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;;019F;
524 # should instead be
525 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;019F;;019F
526 # Without this change, there are casing problems for this character.
527 #
528 ##############################################################################
529
530 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
531                         # and errors
532 my $MAX_LINE_WIDTH = 78;
533
534 # Debugging aid to skip most files so as to not be distracted by them when
535 # concentrating on the ones being debugged.  Add
536 # non_skip => 1,
537 # to the constructor for those files you want processed when you set this.
538 # Files with a first version number of 0 are special: they are always
539 # processed regardless of the state of this flag.  Generally, Jamo.txt and
540 # UnicodeData.txt must not be skipped if you want this program to not die
541 # before normal completion.
542 my $debug_skip = 0;
543
544
545 # Normally these are suppressed.
546 my $write_Unicode_deprecated_tables = 0;
547
548 # Set to 1 to enable tracing.
549 our $to_trace = 0;
550
551 { # Closure for trace: debugging aid
552     my $print_caller = 1;        # ? Include calling subroutine name
553     my $main_with_colon = 'main::';
554     my $main_colon_length = length($main_with_colon);
555
556     sub trace {
557         return unless $to_trace;        # Do nothing if global flag not set
558
559         my @input = @_;
560
561         local $DB::trace = 0;
562         $DB::trace = 0;          # Quiet 'used only once' message
563
564         my $line_number;
565
566         # Loop looking up the stack to get the first non-trace caller
567         my $caller_line;
568         my $caller_name;
569         my $i = 0;
570         do {
571             $line_number = $caller_line;
572             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
573             $caller = $main_with_colon unless defined $caller;
574
575             $caller_name = $caller;
576
577             # get rid of pkg
578             $caller_name =~ s/.*:://;
579             if (substr($caller_name, 0, $main_colon_length)
580                 eq $main_with_colon)
581             {
582                 $caller_name = substr($caller_name, $main_colon_length);
583             }
584
585         } until ($caller_name ne 'trace');
586
587         # If the stack was empty, we were called from the top level
588         $caller_name = 'main' if ($caller_name eq ""
589                                     || $caller_name eq 'trace');
590
591         my $output = "";
592         foreach my $string (@input) {
593             #print STDERR __LINE__, ": ", join ", ", @input, "\n";
594             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
595                 $output .= simple_dumper($string);
596             }
597             else {
598                 $string = "$string" if ref $string;
599                 $string = $UNDEF unless defined $string;
600                 chomp $string;
601                 $string = '""' if $string eq "";
602                 $output .= " " if $output ne ""
603                                 && $string ne ""
604                                 && substr($output, -1, 1) ne " "
605                                 && substr($string, 0, 1) ne " ";
606                 $output .= $string;
607             }
608         }
609
610         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
611         print STDERR "$caller_name: " if $print_caller;
612         print STDERR $output, "\n";
613         return;
614     }
615 }
616
617 # This is for a rarely used development feature that allows you to compare two
618 # versions of the Unicode standard without having to deal with changes caused
619 # by the code points introduced in the later version.  Change the 0 to a
620 # string containing a SINGLE dotted Unicode release number (e.g. "2.1").  Only
621 # code points introduced in that release and earlier will be used; later ones
622 # are thrown away.  You use the version number of the earliest one you want to
623 # compare; then run this program on directory structures containing each
624 # release, and compare the outputs.  These outputs will therefore include only
625 # the code points common to both releases, and you can see the changes caused
626 # just by the underlying release semantic changes.  For versions earlier than
627 # 3.2, you must copy a version of DAge.txt into the directory.
628 my $string_compare_versions = DEBUG && 0; #  e.g., "2.1";
629 my $compare_versions = DEBUG
630                        && $string_compare_versions
631                        && pack "C*", split /\./, $string_compare_versions;
632
633 sub uniques {
634     # Returns non-duplicated input values.  From "Perl Best Practices:
635     # Encapsulated Cleverness".  p. 455 in first edition.
636
637     my %seen;
638     # Arguably this breaks encapsulation, if the goal is to permit multiple
639     # distinct objects to stringify to the same value, and be interchangeable.
640     # However, for this program, no two objects stringify identically, and all
641     # lists passed to this function are either objects or strings. So this
642     # doesn't affect correctness, but it does give a couple of percent speedup.
643     no overloading;
644     return grep { ! $seen{$_}++ } @_;
645 }
646
647 $0 = File::Spec->canonpath($0);
648
649 my $make_test_script = 0;      # ? Should we output a test script
650 my $make_norm_test_script = 0; # ? Should we output a normalization test script
651 my $write_unchanged_files = 0; # ? Should we update the output files even if
652                                #    we don't think they have changed
653 my $use_directory = "";        # ? Should we chdir somewhere.
654 my $pod_directory;             # input directory to store the pod file.
655 my $pod_file = 'perluniprops';
656 my $t_path;                     # Path to the .t test file
657 my $file_list = 'mktables.lst'; # File to store input and output file names.
658                                # This is used to speed up the build, by not
659                                # executing the main body of the program if
660                                # nothing on the list has changed since the
661                                # previous build
662 my $make_list = 1;             # ? Should we write $file_list.  Set to always
663                                # make a list so that when the pumpking is
664                                # preparing a release, s/he won't have to do
665                                # special things
666 my $glob_list = 0;             # ? Should we try to include unknown .txt files
667                                # in the input.
668 my $output_range_counts = $debugging_build;   # ? Should we include the number
669                                               # of code points in ranges in
670                                               # the output
671 my $annotate = 0;              # ? Should character names be in the output
672
673 # Verbosity levels; 0 is quiet
674 my $NORMAL_VERBOSITY = 1;
675 my $PROGRESS = 2;
676 my $VERBOSE = 3;
677
678 my $verbosity = $NORMAL_VERBOSITY;
679
680 # Process arguments
681 while (@ARGV) {
682     my $arg = shift @ARGV;
683     if ($arg eq '-v') {
684         $verbosity = $VERBOSE;
685     }
686     elsif ($arg eq '-p') {
687         $verbosity = $PROGRESS;
688         $| = 1;     # Flush buffers as we go.
689     }
690     elsif ($arg eq '-q') {
691         $verbosity = 0;
692     }
693     elsif ($arg eq '-w') {
694         $write_unchanged_files = 1; # update the files even if havent changed
695     }
696     elsif ($arg eq '-check') {
697         my $this = shift @ARGV;
698         my $ok = shift @ARGV;
699         if ($this ne $ok) {
700             print "Skipping as check params are not the same.\n";
701             exit(0);
702         }
703     }
704     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
705         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
706     }
707     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
708     {
709         $make_test_script = 1;
710     }
711     elsif ($arg eq '-makenormtest')
712     {
713         $make_norm_test_script = 1;
714     }
715     elsif ($arg eq '-makelist') {
716         $make_list = 1;
717     }
718     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
719         -d $use_directory or croak "Unknown directory '$use_directory'";
720     }
721     elsif ($arg eq '-L') {
722
723         # Existence not tested until have chdir'd
724         $file_list = shift;
725     }
726     elsif ($arg eq '-globlist') {
727         $glob_list = 1;
728     }
729     elsif ($arg eq '-c') {
730         $output_range_counts = ! $output_range_counts
731     }
732     elsif ($arg eq '-annotate') {
733         $annotate = 1;
734         $debugging_build = 1;
735         $output_range_counts = 1;
736     }
737     else {
738         my $with_c = 'with';
739         $with_c .= 'out' if $output_range_counts;   # Complements the state
740         croak <<END;
741 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
742           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
743           [-check A B ]
744   -c          : Output comments $with_c number of code points in ranges
745   -q          : Quiet Mode: Only output serious warnings.
746   -p          : Set verbosity level to normal plus show progress.
747   -v          : Set Verbosity level high:  Show progress and non-serious
748                 warnings
749   -w          : Write files regardless
750   -C dir      : Change to this directory before proceeding. All relative paths
751                 except those specified by the -P and -T options will be done
752                 with respect to this directory.
753   -P dir      : Output $pod_file file to directory 'dir'.
754   -T path     : Create a test script as 'path'; overrides -maketest
755   -L filelist : Use alternate 'filelist' instead of standard one
756   -globlist   : Take as input all non-Test *.txt files in current and sub
757                 directories
758   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
759                 overrides -T
760   -makelist   : Rewrite the file list $file_list based on current setup
761   -annotate   : Output an annotation for each character in the table files;
762                 useful for debugging mktables, looking at diffs; but is slow,
763                 memory intensive; resulting tables are usable but are slow and
764                 very large (and currently fail the Unicode::UCD.t tests).
765   -check A B  : Executes $0 only if A and B are the same
766 END
767     }
768 }
769
770 # Stores the most-recently changed file.  If none have changed, can skip the
771 # build
772 my $most_recent = (stat $0)[9];   # Do this before the chdir!
773
774 # Change directories now, because need to read 'version' early.
775 if ($use_directory) {
776     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
777         $pod_directory = File::Spec->rel2abs($pod_directory);
778     }
779     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
780         $t_path = File::Spec->rel2abs($t_path);
781     }
782     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
783     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
784         $pod_directory = File::Spec->abs2rel($pod_directory);
785     }
786     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
787         $t_path = File::Spec->abs2rel($t_path);
788     }
789 }
790
791 # Get Unicode version into regular and v-string.  This is done now because
792 # various tables below get populated based on it.  These tables are populated
793 # here to be near the top of the file, and so easily seeable by those needing
794 # to modify things.
795 open my $VERSION, "<", "version"
796                     or croak "$0: can't open required file 'version': $!\n";
797 my $string_version = <$VERSION>;
798 close $VERSION;
799 chomp $string_version;
800 my $v_version = pack "C*", split /\./, $string_version;        # v string
801
802 # The following are the complete names of properties with property values that
803 # are known to not match any code points in some versions of Unicode, but that
804 # may change in the future so they should be matchable, hence an empty file is
805 # generated for them.
806 my @tables_that_may_be_empty = (
807                                 'Joining_Type=Left_Joining',
808                                 );
809 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
810 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
811 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
812                                                     if $v_version ge v4.1.0;
813 push @tables_that_may_be_empty, 'Script_Extensions=Katakana_Or_Hiragana'
814                                                     if $v_version ge v6.0.0;
815 push @tables_that_may_be_empty, 'Grapheme_Cluster_Break=Prepend'
816                                                     if $v_version ge v6.1.0;
817
818 # The lists below are hashes, so the key is the item in the list, and the
819 # value is the reason why it is in the list.  This makes generation of
820 # documentation easier.
821
822 my %why_suppressed;  # No file generated for these.
823
824 # Files aren't generated for empty extraneous properties.  This is arguable.
825 # Extraneous properties generally come about because a property is no longer
826 # used in a newer version of Unicode.  If we generated a file without code
827 # points, programs that used to work on that property will still execute
828 # without errors.  It just won't ever match (or will always match, with \P{}).
829 # This means that the logic is now likely wrong.  I (khw) think its better to
830 # find this out by getting an error message.  Just move them to the table
831 # above to change this behavior
832 my %why_suppress_if_empty_warn_if_not = (
833
834    # It is the only property that has ever officially been removed from the
835    # Standard.  The database never contained any code points for it.
836    'Special_Case_Condition' => 'Obsolete',
837
838    # Apparently never official, but there were code points in some versions of
839    # old-style PropList.txt
840    'Non_Break' => 'Obsolete',
841 );
842
843 # These would normally go in the warn table just above, but they were changed
844 # a long time before this program was written, so warnings about them are
845 # moot.
846 if ($v_version gt v3.2.0) {
847     push @tables_that_may_be_empty,
848                                 'Canonical_Combining_Class=Attached_Below_Left'
849 }
850
851 # These are listed in the Property aliases file in 6.0, but Unihan is ignored
852 # unless explicitly added.
853 if ($v_version ge v5.2.0) {
854     my $unihan = 'Unihan; remove from list if using Unihan';
855     foreach my $table (qw (
856                            kAccountingNumeric
857                            kOtherNumeric
858                            kPrimaryNumeric
859                            kCompatibilityVariant
860                            kIICore
861                            kIRG_GSource
862                            kIRG_HSource
863                            kIRG_JSource
864                            kIRG_KPSource
865                            kIRG_MSource
866                            kIRG_KSource
867                            kIRG_TSource
868                            kIRG_USource
869                            kIRG_VSource
870                            kRSUnicode
871                         ))
872     {
873         $why_suppress_if_empty_warn_if_not{$table} = $unihan;
874     }
875 }
876
877 # Enum values for to_output_map() method in the Map_Table package.
878 my $EXTERNAL_MAP = 1;
879 my $INTERNAL_MAP = 2;
880 my $OUTPUT_ADJUSTED = 3;
881
882 # To override computed values for writing the map tables for these properties.
883 # The default for enum map tables is to write them out, so that the Unicode
884 # .txt files can be removed, but all the data to compute any property value
885 # for any code point is available in a more compact form.
886 my %global_to_output_map = (
887     # Needed by UCD.pm, but don't want to publicize that it exists, so won't
888     # get stuck supporting it if things change.  Since it is a STRING
889     # property, it normally would be listed in the pod, but INTERNAL_MAP
890     # suppresses that.
891     Unicode_1_Name => $INTERNAL_MAP,
892
893     Present_In => 0,                # Suppress, as easily computed from Age
894     Block => 0,                     # Suppress, as Blocks.txt is retained.
895
896     # Suppress, as mapping can be found instead from the
897     # Perl_Decomposition_Mapping file
898     Decomposition_Type => 0,
899 );
900
901 # Properties that this program ignores.
902 my @unimplemented_properties;
903
904 # With this release, it is automatically handled if the Unihan db is
905 # downloaded
906 push @unimplemented_properties, 'Unicode_Radical_Stroke' if $v_version le v5.2.0;
907
908 # There are several types of obsolete properties defined by Unicode.  These
909 # must be hand-edited for every new Unicode release.
910 my %why_deprecated;  # Generates a deprecated warning message if used.
911 my %why_stabilized;  # Documentation only
912 my %why_obsolete;    # Documentation only
913
914 {   # Closure
915     my $simple = 'Perl uses the more complete version of this property';
916     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
917
918     my $other_properties = 'other properties';
919     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
920     my $why_no_expand  = "Deprecated by Unicode.  These are characters that expand to more than one character in the specified normalization form, but whether they actually take up more bytes or not depends on the encoding being used.  For example, a UTF-8 encoded character may expand to a different number of bytes than a UTF-32 encoded character.";
921
922     %why_deprecated = (
923         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
924         'Jamo_Short_Name' => $contributory,
925         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
926         'Other_Alphabetic' => $contributory,
927         'Other_Default_Ignorable_Code_Point' => $contributory,
928         'Other_Grapheme_Extend' => $contributory,
929         'Other_ID_Continue' => $contributory,
930         'Other_ID_Start' => $contributory,
931         'Other_Lowercase' => $contributory,
932         'Other_Math' => $contributory,
933         'Other_Uppercase' => $contributory,
934         'Expands_On_NFC' => $why_no_expand,
935         'Expands_On_NFD' => $why_no_expand,
936         'Expands_On_NFKC' => $why_no_expand,
937         'Expands_On_NFKD' => $why_no_expand,
938     );
939
940     %why_suppressed = (
941         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
942         # contains the same information, but without the algorithmically
943         # determinable Hangul syllables'.  This file is not published, so it's
944         # existence is not noted in the comment.
945         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize or Unicode::UCD::prop_invmap()',
946
947         'Indic_Matra_Category' => "Provisional",
948         'Indic_Syllabic_Category' => "Provisional",
949
950         # Don't suppress ISO_Comment, as otherwise special handling is needed
951         # to differentiate between it and gc=c, which can be written as 'isc',
952         # which is the same characters as ISO_Comment's short name.
953
954         'Name' => "Accessible via \\N{...} or 'use charnames;' or Unicode::UCD::prop_invmap()",
955
956         'Simple_Case_Folding' => "$simple.  Can access this through Unicode::UCD::casefold or Unicode::UCD::prop_invmap()",
957         'Simple_Lowercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
958         'Simple_Titlecase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
959         'Simple_Uppercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
960
961         FC_NFKC_Closure => 'Supplanted in usage by NFKC_Casefold; otherwise not useful',
962     );
963
964     foreach my $property (
965
966             # The following are suppressed because they were made contributory
967             # or deprecated by Unicode before Perl ever thought about
968             # supporting them.
969             'Jamo_Short_Name',
970             'Grapheme_Link',
971             'Expands_On_NFC',
972             'Expands_On_NFD',
973             'Expands_On_NFKC',
974             'Expands_On_NFKD',
975
976             # The following are suppressed because they have been marked
977             # as deprecated for a sufficient amount of time
978             'Other_Alphabetic',
979             'Other_Default_Ignorable_Code_Point',
980             'Other_Grapheme_Extend',
981             'Other_ID_Continue',
982             'Other_ID_Start',
983             'Other_Lowercase',
984             'Other_Math',
985             'Other_Uppercase',
986     ) {
987         $why_suppressed{$property} = $why_deprecated{$property};
988     }
989
990     # Customize the message for all the 'Other_' properties
991     foreach my $property (keys %why_deprecated) {
992         next if (my $main_property = $property) !~ s/^Other_//;
993         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
994     }
995 }
996
997 if ($write_Unicode_deprecated_tables) {
998     foreach my $property (keys %why_suppressed) {
999         delete $why_suppressed{$property} if $property =~
1000                                                     / ^ Other | Grapheme /x;
1001     }
1002 }
1003
1004 if ($v_version ge 4.0.0) {
1005     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
1006     if ($v_version ge 6.0.0) {
1007         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
1008     }
1009 }
1010 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
1011     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
1012     if ($v_version ge 6.0.0) {
1013         $why_deprecated{'ISO_Comment'} = 'No longer needed for Unicode\'s internal chart generation; otherwise not useful, and code points for it have been removed';
1014     }
1015 }
1016
1017 # Probably obsolete forever
1018 if ($v_version ge v4.1.0) {
1019     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common".';
1020 }
1021 if ($v_version ge v6.0.0) {
1022     $why_suppressed{'Script=Katakana_Or_Hiragana'} .= '  Consider instead using "Script_Extensions=Katakana" or "Script_Extensions=Hiragana (or both)"';
1023     $why_suppressed{'Script_Extensions=Katakana_Or_Hiragana'} = 'All code points that would be matched by this are matched by either "Script_Extensions=Katakana" or "Script_Extensions=Hiragana"';
1024 }
1025
1026 # This program can create files for enumerated-like properties, such as
1027 # 'Numeric_Type'.  This file would be the same format as for a string
1028 # property, with a mapping from code point to its value, so you could look up,
1029 # for example, the script a code point is in.  But no one so far wants this
1030 # mapping, or they have found another way to get it since this is a new
1031 # feature.  So no file is generated except if it is in this list.
1032 my @output_mapped_properties = split "\n", <<END;
1033 END
1034
1035 # If you are using the Unihan database in a Unicode version before 5.2, you
1036 # need to add the properties that you want to extract from it to this table.
1037 # For your convenience, the properties in the 6.0 PropertyAliases.txt file are
1038 # listed, commented out
1039 my @cjk_properties = split "\n", <<'END';
1040 #cjkAccountingNumeric; kAccountingNumeric
1041 #cjkOtherNumeric; kOtherNumeric
1042 #cjkPrimaryNumeric; kPrimaryNumeric
1043 #cjkCompatibilityVariant; kCompatibilityVariant
1044 #cjkIICore ; kIICore
1045 #cjkIRG_GSource; kIRG_GSource
1046 #cjkIRG_HSource; kIRG_HSource
1047 #cjkIRG_JSource; kIRG_JSource
1048 #cjkIRG_KPSource; kIRG_KPSource
1049 #cjkIRG_KSource; kIRG_KSource
1050 #cjkIRG_TSource; kIRG_TSource
1051 #cjkIRG_USource; kIRG_USource
1052 #cjkIRG_VSource; kIRG_VSource
1053 #cjkRSUnicode; kRSUnicode                ; Unicode_Radical_Stroke; URS
1054 END
1055
1056 # Similarly for the property values.  For your convenience, the lines in the
1057 # 6.0 PropertyAliases.txt file are listed.  Just remove the first BUT NOT both
1058 # '#' marks (for Unicode versions before 5.2)
1059 my @cjk_property_values = split "\n", <<'END';
1060 ## @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
1061 ## @missing: 0000..10FFFF; cjkCompatibilityVariant; <code point>
1062 ## @missing: 0000..10FFFF; cjkIICore; <none>
1063 ## @missing: 0000..10FFFF; cjkIRG_GSource; <none>
1064 ## @missing: 0000..10FFFF; cjkIRG_HSource; <none>
1065 ## @missing: 0000..10FFFF; cjkIRG_JSource; <none>
1066 ## @missing: 0000..10FFFF; cjkIRG_KPSource; <none>
1067 ## @missing: 0000..10FFFF; cjkIRG_KSource; <none>
1068 ## @missing: 0000..10FFFF; cjkIRG_TSource; <none>
1069 ## @missing: 0000..10FFFF; cjkIRG_USource; <none>
1070 ## @missing: 0000..10FFFF; cjkIRG_VSource; <none>
1071 ## @missing: 0000..10FFFF; cjkOtherNumeric; NaN
1072 ## @missing: 0000..10FFFF; cjkPrimaryNumeric; NaN
1073 ## @missing: 0000..10FFFF; cjkRSUnicode; <none>
1074 END
1075
1076 # The input files don't list every code point.  Those not listed are to be
1077 # defaulted to some value.  Below are hard-coded what those values are for
1078 # non-binary properties as of 5.1.  Starting in 5.0, there are
1079 # machine-parsable comment lines in the files the give the defaults; so this
1080 # list shouldn't have to be extended.  The claim is that all missing entries
1081 # for binary properties will default to 'N'.  Unicode tried to change that in
1082 # 5.2, but the beta period produced enough protest that they backed off.
1083 #
1084 # The defaults for the fields that appear in UnicodeData.txt in this hash must
1085 # be in the form that it expects.  The others may be synonyms.
1086 my $CODE_POINT = '<code point>';
1087 my %default_mapping = (
1088     Age => "Unassigned",
1089     # Bidi_Class => Complicated; set in code
1090     Bidi_Mirroring_Glyph => "",
1091     Block => 'No_Block',
1092     Canonical_Combining_Class => 0,
1093     Case_Folding => $CODE_POINT,
1094     Decomposition_Mapping => $CODE_POINT,
1095     Decomposition_Type => 'None',
1096     East_Asian_Width => "Neutral",
1097     FC_NFKC_Closure => $CODE_POINT,
1098     General_Category => 'Cn',
1099     Grapheme_Cluster_Break => 'Other',
1100     Hangul_Syllable_Type => 'NA',
1101     ISO_Comment => "",
1102     Jamo_Short_Name => "",
1103     Joining_Group => "No_Joining_Group",
1104     # Joining_Type => Complicated; set in code
1105     kIICore => 'N',   #                       Is converted to binary
1106     #Line_Break => Complicated; set in code
1107     Lowercase_Mapping => $CODE_POINT,
1108     Name => "",
1109     Name_Alias => "",
1110     NFC_QC => 'Yes',
1111     NFD_QC => 'Yes',
1112     NFKC_QC => 'Yes',
1113     NFKD_QC => 'Yes',
1114     Numeric_Type => 'None',
1115     Numeric_Value => 'NaN',
1116     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1117     Sentence_Break => 'Other',
1118     Simple_Case_Folding => $CODE_POINT,
1119     Simple_Lowercase_Mapping => $CODE_POINT,
1120     Simple_Titlecase_Mapping => $CODE_POINT,
1121     Simple_Uppercase_Mapping => $CODE_POINT,
1122     Titlecase_Mapping => $CODE_POINT,
1123     Unicode_1_Name => "",
1124     Unicode_Radical_Stroke => "",
1125     Uppercase_Mapping => $CODE_POINT,
1126     Word_Break => 'Other',
1127 );
1128
1129 # Below are files that Unicode furnishes, but this program ignores, and why.
1130 # NormalizationCorrections.txt requires some more explanation.  It documents
1131 # the cumulative fixes to erroneous normalizations in earlier Unicode
1132 # versions.  Its main purpose is so that someone running on an earlier version
1133 # can use this file to override what got published in that earlier release.
1134 # It would be easy for mktables to read and handle this file.  But all the
1135 # corrections in it should already be in the other files for the release it
1136 # is.  To get it to actually mean something useful, someone would have to be
1137 # using an earlier Unicode release, and copy it to the files for that release
1138 # and recomplile.  So far there has been no demand to do that, so this hasn't
1139 # been implemented.
1140 my %ignored_files = (
1141     'CJKRadicals.txt' => 'Maps the kRSUnicode property values to corresponding code points',
1142     'Index.txt' => 'Alphabetical index of Unicode characters',
1143     'NamedSqProv.txt' => 'Named sequences proposed for inclusion in a later version of the Unicode Standard; if you need them now, you can append this file to F<NamedSequences.txt> and recompile perl',
1144     'NamesList.txt' => 'Annotated list of characters',
1145     'NormalizationCorrections.txt' => 'Documentation of corrections already incorporated into the Unicode data base',
1146     'Props.txt' => 'Only in very early releases; is a subset of F<PropList.txt> (which is used instead)',
1147     'ReadMe.txt' => 'Documentation',
1148     'StandardizedVariants.txt' => 'Certain glyph variations for character display are standardized.  This lists the non-Unihan ones; the Unihan ones are also not used by Perl, and are in a separate Unicode data base L<http://www.unicode.org/ivd>',
1149     'EmojiSources.txt' => 'Maps certain Unicode code points to their legacy Japanese cell-phone values',
1150     'auxiliary/WordBreakTest.html' => 'Documentation of validation tests',
1151     'auxiliary/SentenceBreakTest.html' => 'Documentation of validation tests',
1152     'auxiliary/GraphemeBreakTest.html' => 'Documentation of validation tests',
1153     'auxiliary/LineBreakTest.html' => 'Documentation of validation tests',
1154 );
1155
1156 my %skipped_files;  # List of files that we skip
1157
1158 ### End of externally interesting definitions, except for @input_file_objects
1159
1160 my $HEADER=<<"EOF";
1161 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1162 # This file is machine-generated by $0 from the Unicode
1163 # database, Version $string_version.  Any changes made here will be lost!
1164 EOF
1165
1166 my $INTERNAL_ONLY_HEADER = <<"EOF";
1167
1168 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1169 # This file is for internal use by core Perl only.  The format and even the
1170 # name or existence of this file are subject to change without notice.  Don't
1171 # use it directly.
1172 EOF
1173
1174 my $DEVELOPMENT_ONLY=<<"EOF";
1175 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1176 # This file contains information artificially constrained to code points
1177 # present in Unicode release $string_compare_versions.
1178 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1179 # not be used for production.
1180
1181 EOF
1182
1183 my $MAX_UNICODE_CODEPOINT_STRING = "10FFFF";
1184 my $MAX_UNICODE_CODEPOINT = hex $MAX_UNICODE_CODEPOINT_STRING;
1185 my $MAX_UNICODE_CODEPOINTS = $MAX_UNICODE_CODEPOINT + 1;
1186
1187 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1188 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1189 # to decrease backtracking.  The first regex allows the code point to be at
1190 # the end of a word, but to work properly, the word shouldn't end with a valid
1191 # hex character.  The second one won't match a code point at the end of a
1192 # word, and doesn't have the run-on issue
1193 my $run_on_code_point_re =
1194             qr/ (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1195 my $code_point_re = qr/\b$run_on_code_point_re/;
1196
1197 # This matches the beginning of the line in the Unicode db files that give the
1198 # defaults for code points not listed (i.e., missing) in the file.  The code
1199 # depends on this ending with a semi-colon, so it can assume it is a valid
1200 # field when the line is split() by semi-colons
1201 my $missing_defaults_prefix =
1202             qr/^#\s+\@missing:\s+0000\.\.$MAX_UNICODE_CODEPOINT_STRING\s*;/;
1203
1204 # Property types.  Unicode has more types, but these are sufficient for our
1205 # purposes.
1206 my $UNKNOWN = -1;   # initialized to illegal value
1207 my $NON_STRING = 1; # Either binary or enum
1208 my $BINARY = 2;
1209 my $FORCED_BINARY = 3; # Not a binary property, but, besides its normal
1210                        # tables, additional true and false tables are
1211                        # generated so that false is anything matching the
1212                        # default value, and true is everything else.
1213 my $ENUM = 4;       # Include catalog
1214 my $STRING = 5;     # Anything else: string or misc
1215
1216 # Some input files have lines that give default values for code points not
1217 # contained in the file.  Sometimes these should be ignored.
1218 my $NO_DEFAULTS = 0;        # Must evaluate to false
1219 my $NOT_IGNORED = 1;
1220 my $IGNORED = 2;
1221
1222 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1223 # and will appear in the main body of the tables in the output files, but
1224 # there are other types of ranges as well, listed below, that are specially
1225 # handled.   There are pseudo-types as well that will never be stored as a
1226 # type, but will affect the calculation of the type.
1227
1228 # 0 is for normal, non-specials
1229 my $MULTI_CP = 1;           # Sequence of more than code point
1230 my $HANGUL_SYLLABLE = 2;
1231 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1232 my $NULL = 4;               # The map is to the null string; utf8.c can't
1233                             # handle these, nor is there an accepted syntax
1234                             # for them in \p{} constructs
1235 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1236                              # otherwise be $MULTI_CP type are instead type 0
1237
1238 # process_generic_property_file() can accept certain overrides in its input.
1239 # Each of these must begin AND end with $CMD_DELIM.
1240 my $CMD_DELIM = "\a";
1241 my $REPLACE_CMD = 'replace';    # Override the Replace
1242 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1243
1244 my $NO = 0;
1245 my $YES = 1;
1246
1247 # Values for the Replace argument to add_range.
1248 # $NO                      # Don't replace; add only the code points not
1249                            # already present.
1250 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1251                            # the comments at the subroutine definition.
1252 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1253 my $MULTIPLE_BEFORE = 4;   # Don't replace, but add a duplicate record if
1254                            # already there
1255 my $MULTIPLE_AFTER = 5;    # Don't replace, but add a duplicate record if
1256                            # already there
1257 my $CROAK = 6;             # Die with an error if is already there
1258
1259 # Flags to give property statuses.  The phrases are to remind maintainers that
1260 # if the flag is changed, the indefinite article referring to it in the
1261 # documentation may need to be as well.
1262 my $NORMAL = "";
1263 my $DEPRECATED = 'D';
1264 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1265 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1266 my $DISCOURAGED = 'X';
1267 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1268 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1269 my $STRICTER = 'T';
1270 my $a_bold_stricter = "a 'B<$STRICTER>'";
1271 my $A_bold_stricter = "A 'B<$STRICTER>'";
1272 my $STABILIZED = 'S';
1273 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1274 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1275 my $OBSOLETE = 'O';
1276 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1277 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1278
1279 my %status_past_participles = (
1280     $DISCOURAGED => 'discouraged',
1281     $STABILIZED => 'stabilized',
1282     $OBSOLETE => 'obsolete',
1283     $DEPRECATED => 'deprecated',
1284 );
1285
1286 # Table fates.  These are somewhat ordered, so that fates < $MAP_PROXIED should be
1287 # externally documented.
1288 my $ORDINARY = 0;       # The normal fate.
1289 my $MAP_PROXIED = 1;    # The map table for the property isn't written out,
1290                         # but there is a file written that can be used to
1291                         # reconstruct this table
1292 my $INTERNAL_ONLY = 2;  # The file for this table is written out, but it is
1293                         # for Perl's internal use only
1294 my $SUPPRESSED = 3;     # The file for this table is not written out, and as a
1295                         # result, we don't bother to do many computations on
1296                         # it.
1297 my $PLACEHOLDER = 4;    # Like $SUPPRESSED, but we go through all the
1298                         # computations anyway, as the values are needed for
1299                         # things to work.  This happens when we have Perl
1300                         # extensions that depend on Unicode tables that
1301                         # wouldn't normally be in a given Unicode version.
1302
1303 # The format of the values of the tables:
1304 my $EMPTY_FORMAT = "";
1305 my $BINARY_FORMAT = 'b';
1306 my $DECIMAL_FORMAT = 'd';
1307 my $FLOAT_FORMAT = 'f';
1308 my $INTEGER_FORMAT = 'i';
1309 my $HEX_FORMAT = 'x';
1310 my $RATIONAL_FORMAT = 'r';
1311 my $STRING_FORMAT = 's';
1312 my $ADJUST_FORMAT = 'a';
1313 my $DECOMP_STRING_FORMAT = 'c';
1314 my $STRING_WHITE_SPACE_LIST = 'sw';
1315
1316 my %map_table_formats = (
1317     $BINARY_FORMAT => 'binary',
1318     $DECIMAL_FORMAT => 'single decimal digit',
1319     $FLOAT_FORMAT => 'floating point number',
1320     $INTEGER_FORMAT => 'integer',
1321     $HEX_FORMAT => 'non-negative hex whole number; a code point',
1322     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1323     $STRING_FORMAT => 'string',
1324     $ADJUST_FORMAT => 'some entries need adjustment',
1325     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1326     $STRING_WHITE_SPACE_LIST => 'string, but some elements are interpreted as a list; white space occurs only as list item separators'
1327 );
1328
1329 # Unicode didn't put such derived files in a separate directory at first.
1330 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1331 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1332 my $AUXILIARY = 'auxiliary';
1333
1334 # Hashes that will eventually go into Heavy.pl for the use of utf8_heavy.pl
1335 # and into UCD.pl for the use of UCD.pm
1336 my %loose_to_file_of;       # loosely maps table names to their respective
1337                             # files
1338 my %stricter_to_file_of;    # same; but for stricter mapping.
1339 my %loose_property_to_file_of; # Maps a loose property name to its map file
1340 my %file_to_swash_name;     # Maps the file name to its corresponding key name
1341                             # in the hash %utf8::SwashInfo
1342 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1343                              # their rational equivalent
1344 my %loose_property_name_of; # Loosely maps (non_string) property names to
1345                             # standard form
1346 my %string_property_loose_to_name; # Same, for string properties.
1347 my %loose_defaults;         # keys are of form "prop=value", where 'prop' is
1348                             # the property name in standard loose form, and
1349                             # 'value' is the default value for that property,
1350                             # also in standard loose form.
1351 my %loose_to_standard_value; # loosely maps table names to the canonical
1352                             # alias for them
1353 my %ambiguous_names;        # keys are alias names (in standard form) that
1354                             # have more than one possible meaning.
1355 my %prop_aliases;           # Keys are standard property name; values are each
1356                             # one's aliases
1357 my %prop_value_aliases;     # Keys of top level are standard property name;
1358                             # values are keys to another hash,  Each one is
1359                             # one of the property's values, in standard form.
1360                             # The values are that prop-val's aliases.
1361 my %ucd_pod;    # Holds entries that will go into the UCD section of the pod
1362
1363 # Most properties are immune to caseless matching, otherwise you would get
1364 # nonsensical results, as properties are a function of a code point, not
1365 # everything that is caselessly equivalent to that code point.  For example,
1366 # Changes_When_Case_Folded('s') should be false, whereas caselessly it would
1367 # be true because 's' and 'S' are equivalent caselessly.  However,
1368 # traditionally, [:upper:] and [:lower:] are equivalent caselessly, so we
1369 # extend that concept to those very few properties that are like this.  Each
1370 # such property will match the full range caselessly.  They are hard-coded in
1371 # the program; it's not worth trying to make it general as it's extremely
1372 # unlikely that they will ever change.
1373 my %caseless_equivalent_to;
1374
1375 # These constants names and values were taken from the Unicode standard,
1376 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1377 # syllables.  The '_string' versions are so generated tables can retain the
1378 # hex format, which is the more familiar value
1379 my $SBase_string = "0xAC00";
1380 my $SBase = CORE::hex $SBase_string;
1381 my $LBase_string = "0x1100";
1382 my $LBase = CORE::hex $LBase_string;
1383 my $VBase_string = "0x1161";
1384 my $VBase = CORE::hex $VBase_string;
1385 my $TBase_string = "0x11A7";
1386 my $TBase = CORE::hex $TBase_string;
1387 my $SCount = 11172;
1388 my $LCount = 19;
1389 my $VCount = 21;
1390 my $TCount = 28;
1391 my $NCount = $VCount * $TCount;
1392
1393 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1394 # with the above published constants.
1395 my %Jamo;
1396 my %Jamo_L;     # Leading consonants
1397 my %Jamo_V;     # Vowels
1398 my %Jamo_T;     # Trailing consonants
1399
1400 # For code points whose name contains its ordinal as a '-ABCD' suffix.
1401 # The key is the base name of the code point, and the value is an
1402 # array giving all the ranges that use this base name.  Each range
1403 # is actually a hash giving the 'low' and 'high' values of it.
1404 my %names_ending_in_code_point;
1405 my %loose_names_ending_in_code_point;   # Same as above, but has blanks, dashes
1406                                         # removed from the names
1407 # Inverse mapping.  The list of ranges that have these kinds of
1408 # names.  Each element contains the low, high, and base names in an
1409 # anonymous hash.
1410 my @code_points_ending_in_code_point;
1411
1412 # To hold Unicode's normalization test suite
1413 my @normalization_tests;
1414
1415 # Boolean: does this Unicode version have the hangul syllables, and are we
1416 # writing out a table for them?
1417 my $has_hangul_syllables = 0;
1418
1419 # Does this Unicode version have code points whose names end in their
1420 # respective code points, and are we writing out a table for them?  0 for no;
1421 # otherwise points to first property that a table is needed for them, so that
1422 # if multiple tables are needed, we don't create duplicates
1423 my $needing_code_points_ending_in_code_point = 0;
1424
1425 my @backslash_X_tests;     # List of tests read in for testing \X
1426 my @unhandled_properties;  # Will contain a list of properties found in
1427                            # the input that we didn't process.
1428 my @match_properties;      # Properties that have match tables, to be
1429                            # listed in the pod
1430 my @map_properties;        # Properties that get map files written
1431 my @named_sequences;       # NamedSequences.txt contents.
1432 my %potential_files;       # Generated list of all .txt files in the directory
1433                            # structure so we can warn if something is being
1434                            # ignored.
1435 my @files_actually_output; # List of files we generated.
1436 my @more_Names;            # Some code point names are compound; this is used
1437                            # to store the extra components of them.
1438 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1439                            # the minimum before we consider it equivalent to a
1440                            # candidate rational
1441 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1442
1443 # These store references to certain commonly used property objects
1444 my $gc;
1445 my $perl;
1446 my $block;
1447 my $perl_charname;
1448 my $print;
1449 my $Any;
1450 my $script;
1451
1452 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1453 my $has_In_conflicts = 0;
1454 my $has_Is_conflicts = 0;
1455
1456 sub internal_file_to_platform ($) {
1457     # Convert our file paths which have '/' separators to those of the
1458     # platform.
1459
1460     my $file = shift;
1461     return undef unless defined $file;
1462
1463     return File::Spec->join(split '/', $file);
1464 }
1465
1466 sub file_exists ($) {   # platform independent '-e'.  This program internally
1467                         # uses slash as a path separator.
1468     my $file = shift;
1469     return 0 if ! defined $file;
1470     return -e internal_file_to_platform($file);
1471 }
1472
1473 sub objaddr($) {
1474     # Returns the address of the blessed input object.
1475     # It doesn't check for blessedness because that would do a string eval
1476     # every call, and the program is structured so that this is never called
1477     # for a non-blessed object.
1478
1479     no overloading; # If overloaded, numifying below won't work.
1480
1481     # Numifying a ref gives its address.
1482     return pack 'J', $_[0];
1483 }
1484
1485 # These are used only if $annotate is true.
1486 # The entire range of Unicode characters is examined to populate these
1487 # after all the input has been processed.  But most can be skipped, as they
1488 # have the same descriptive phrases, such as being unassigned
1489 my @viacode;            # Contains the 1 million character names
1490 my @printable;          # boolean: And are those characters printable?
1491 my @annotate_char_type; # Contains a type of those characters, specifically
1492                         # for the purposes of annotation.
1493 my $annotate_ranges;    # A map of ranges of code points that have the same
1494                         # name for the purposes of annotation.  They map to the
1495                         # upper edge of the range, so that the end point can
1496                         # be immediately found.  This is used to skip ahead to
1497                         # the end of a range, and avoid processing each
1498                         # individual code point in it.
1499 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1500                                    # characters, but excluding those which are
1501                                    # also noncharacter code points
1502
1503 # The annotation types are an extension of the regular range types, though
1504 # some of the latter are folded into one.  Make the new types negative to
1505 # avoid conflicting with the regular types
1506 my $SURROGATE_TYPE = -1;
1507 my $UNASSIGNED_TYPE = -2;
1508 my $PRIVATE_USE_TYPE = -3;
1509 my $NONCHARACTER_TYPE = -4;
1510 my $CONTROL_TYPE = -5;
1511 my $UNKNOWN_TYPE = -6;  # Used only if there is a bug in this program
1512
1513 sub populate_char_info ($) {
1514     # Used only with the $annotate option.  Populates the arrays with the
1515     # input code point's info that are needed for outputting more detailed
1516     # comments.  If calling context wants a return, it is the end point of
1517     # any contiguous range of characters that share essentially the same info
1518
1519     my $i = shift;
1520     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1521
1522     $viacode[$i] = $perl_charname->value_of($i) || "";
1523
1524     # A character is generally printable if Unicode says it is,
1525     # but below we make sure that most Unicode general category 'C' types
1526     # aren't.
1527     $printable[$i] = $print->contains($i);
1528
1529     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1530
1531     # Only these two regular types are treated specially for annotations
1532     # purposes
1533     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1534                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1535
1536     # Give a generic name to all code points that don't have a real name.
1537     # We output ranges, if applicable, for these.  Also calculate the end
1538     # point of the range.
1539     my $end;
1540     if (! $viacode[$i]) {
1541         my $nonchar;
1542         if ($gc-> table('Private_use')->contains($i)) {
1543             $viacode[$i] = 'Private Use';
1544             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1545             $printable[$i] = 0;
1546             $end = $gc->table('Private_Use')->containing_range($i)->end;
1547         }
1548         elsif ((defined ($nonchar =
1549                             Property::property_ref('Noncharacter_Code_Point'))
1550                && $nonchar->table('Y')->contains($i)))
1551         {
1552             $viacode[$i] = 'Noncharacter';
1553             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1554             $printable[$i] = 0;
1555             $end = property_ref('Noncharacter_Code_Point')->table('Y')->
1556                                                     containing_range($i)->end;
1557         }
1558         elsif ($gc-> table('Control')->contains($i)) {
1559             $viacode[$i] = property_ref('Name_Alias')->value_of($i) || 'Control';
1560             $annotate_char_type[$i] = $CONTROL_TYPE;
1561             $printable[$i] = 0;
1562         }
1563         elsif ($gc-> table('Unassigned')->contains($i)) {
1564             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1565             $printable[$i] = 0;
1566             if ($v_version lt v2.0.0) { # No blocks in earliest releases
1567                 $viacode[$i] = 'Unassigned';
1568                 $end = $gc-> table('Unassigned')->containing_range($i)->end;
1569             }
1570             else {
1571                 $viacode[$i] = 'Unassigned, block=' . $block-> value_of($i);
1572
1573                 # Because we name the unassigned by the blocks they are in, it
1574                 # can't go past the end of that block, and it also can't go
1575                 # past the unassigned range it is in.  The special table makes
1576                 # sure that the non-characters, which are unassigned, are
1577                 # separated out.
1578                 $end = min($block->containing_range($i)->end,
1579                            $unassigned_sans_noncharacters->
1580                                                     containing_range($i)->end);
1581             }
1582         }
1583         elsif ($v_version lt v2.0.0) {  # No surrogates in earliest releases
1584             $viacode[$i] = $gc->value_of($i);
1585             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1586             $printable[$i] = 0;
1587         }
1588         elsif ($gc-> table('Surrogate')->contains($i)) {
1589             $viacode[$i] = 'Surrogate';
1590             $annotate_char_type[$i] = $SURROGATE_TYPE;
1591             $printable[$i] = 0;
1592             $end = $gc->table('Surrogate')->containing_range($i)->end;
1593         }
1594         else {
1595             Carp::my_carp_bug("Can't figure out how to annotate "
1596                               . sprintf("U+%04X", $i)
1597                               . ".  Proceeding anyway.");
1598             $viacode[$i] = 'UNKNOWN';
1599             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1600             $printable[$i] = 0;
1601         }
1602     }
1603
1604     # Here, has a name, but if it's one in which the code point number is
1605     # appended to the name, do that.
1606     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1607         $viacode[$i] .= sprintf("-%04X", $i);
1608         $end = $perl_charname->containing_range($i)->end;
1609     }
1610
1611     # And here, has a name, but if it's a hangul syllable one, replace it with
1612     # the correct name from the Unicode algorithm
1613     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1614         use integer;
1615         my $SIndex = $i - $SBase;
1616         my $L = $LBase + $SIndex / $NCount;
1617         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1618         my $T = $TBase + $SIndex % $TCount;
1619         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1620         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1621         $end = $perl_charname->containing_range($i)->end;
1622     }
1623
1624     return if ! defined wantarray;
1625     return $i if ! defined $end;    # If not a range, return the input
1626
1627     # Save this whole range so can find the end point quickly
1628     $annotate_ranges->add_map($i, $end, $end);
1629
1630     return $end;
1631 }
1632
1633 # Commented code below should work on Perl 5.8.
1634 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1635 ## the native perl version of it (which is what would operate under miniperl)
1636 ## is extremely slow, as it does a string eval every call.
1637 #my $has_fast_scalar_util = $\18 !~ /miniperl/
1638 #                            && defined eval "require Scalar::Util";
1639 #
1640 #sub objaddr($) {
1641 #    # Returns the address of the blessed input object.  Uses the XS version if
1642 #    # available.  It doesn't check for blessedness because that would do a
1643 #    # string eval every call, and the program is structured so that this is
1644 #    # never called for a non-blessed object.
1645 #
1646 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1647 #
1648 #    # Check at least that is a ref.
1649 #    my $pkg = ref($_[0]) or return undef;
1650 #
1651 #    # Change to a fake package to defeat any overloaded stringify
1652 #    bless $_[0], 'main::Fake';
1653 #
1654 #    # Numifying a ref gives its address.
1655 #    my $addr = pack 'J', $_[0];
1656 #
1657 #    # Return to original class
1658 #    bless $_[0], $pkg;
1659 #    return $addr;
1660 #}
1661
1662 sub max ($$) {
1663     my $a = shift;
1664     my $b = shift;
1665     return $a if $a >= $b;
1666     return $b;
1667 }
1668
1669 sub min ($$) {
1670     my $a = shift;
1671     my $b = shift;
1672     return $a if $a <= $b;
1673     return $b;
1674 }
1675
1676 sub clarify_number ($) {
1677     # This returns the input number with underscores inserted every 3 digits
1678     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1679     # checked.
1680
1681     my $number = shift;
1682     my $pos = length($number) - 3;
1683     return $number if $pos <= 1;
1684     while ($pos > 0) {
1685         substr($number, $pos, 0) = '_';
1686         $pos -= 3;
1687     }
1688     return $number;
1689 }
1690
1691
1692 package Carp;
1693
1694 # These routines give a uniform treatment of messages in this program.  They
1695 # are placed in the Carp package to cause the stack trace to not include them,
1696 # although an alternative would be to use another package and set @CARP_NOT
1697 # for it.
1698
1699 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1700
1701 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1702 # and overload trying to load Scalar:Util under miniperl.  See
1703 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1704 undef $overload::VERSION;
1705
1706 sub my_carp {
1707     my $message = shift || "";
1708     my $nofold = shift || 0;
1709
1710     if ($message) {
1711         $message = main::join_lines($message);
1712         $message =~ s/^$0: *//;     # Remove initial program name
1713         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1714         $message = "\n$0: $message;";
1715
1716         # Fold the message with program name, semi-colon end punctuation
1717         # (which looks good with the message that carp appends to it), and a
1718         # hanging indent for continuation lines.
1719         $message = main::simple_fold($message, "", 4) unless $nofold;
1720         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1721                                     # appends is to the same line
1722     }
1723
1724     return $message if defined wantarray;   # If a caller just wants the msg
1725
1726     carp $message;
1727     return;
1728 }
1729
1730 sub my_carp_bug {
1731     # This is called when it is clear that the problem is caused by a bug in
1732     # this program.
1733
1734     my $message = shift;
1735     $message =~ s/^$0: *//;
1736     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1737     carp $message;
1738     return;
1739 }
1740
1741 sub carp_too_few_args {
1742     if (@_ != 2) {
1743         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1744         return;
1745     }
1746
1747     my $args_ref = shift;
1748     my $count = shift;
1749
1750     my_carp_bug("Need at least $count arguments to "
1751         . (caller 1)[3]
1752         . ".  Instead got: '"
1753         . join ', ', @$args_ref
1754         . "'.  No action taken.");
1755     return;
1756 }
1757
1758 sub carp_extra_args {
1759     my $args_ref = shift;
1760     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1761
1762     unless (ref $args_ref) {
1763         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1764         return;
1765     }
1766     my ($package, $file, $line) = caller;
1767     my $subroutine = (caller 1)[3];
1768
1769     my $list;
1770     if (ref $args_ref eq 'HASH') {
1771         foreach my $key (keys %$args_ref) {
1772             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1773         }
1774         $list = join ', ', each %{$args_ref};
1775     }
1776     elsif (ref $args_ref eq 'ARRAY') {
1777         foreach my $arg (@$args_ref) {
1778             $arg = $UNDEF unless defined $arg;
1779         }
1780         $list = join ', ', @$args_ref;
1781     }
1782     else {
1783         my_carp_bug("Can't cope with ref "
1784                 . ref($args_ref)
1785                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1786         return;
1787     }
1788
1789     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1790     return;
1791 }
1792
1793 package main;
1794
1795 { # Closure
1796
1797     # This program uses the inside-out method for objects, as recommended in
1798     # "Perl Best Practices".  This closure aids in generating those.  There
1799     # are two routines.  setup_package() is called once per package to set
1800     # things up, and then set_access() is called for each hash representing a
1801     # field in the object.  These routines arrange for the object to be
1802     # properly destroyed when no longer used, and for standard accessor
1803     # functions to be generated.  If you need more complex accessors, just
1804     # write your own and leave those accesses out of the call to set_access().
1805     # More details below.
1806
1807     my %constructor_fields; # fields that are to be used in constructors; see
1808                             # below
1809
1810     # The values of this hash will be the package names as keys to other
1811     # hashes containing the name of each field in the package as keys, and
1812     # references to their respective hashes as values.
1813     my %package_fields;
1814
1815     sub setup_package {
1816         # Sets up the package, creating standard DESTROY and dump methods
1817         # (unless already defined).  The dump method is used in debugging by
1818         # simple_dumper().
1819         # The optional parameters are:
1820         #   a)  a reference to a hash, that gets populated by later
1821         #       set_access() calls with one of the accesses being
1822         #       'constructor'.  The caller can then refer to this, but it is
1823         #       not otherwise used by these two routines.
1824         #   b)  a reference to a callback routine to call during destruction
1825         #       of the object, before any fields are actually destroyed
1826
1827         my %args = @_;
1828         my $constructor_ref = delete $args{'Constructor_Fields'};
1829         my $destroy_callback = delete $args{'Destroy_Callback'};
1830         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1831
1832         my %fields;
1833         my $package = (caller)[0];
1834
1835         $package_fields{$package} = \%fields;
1836         $constructor_fields{$package} = $constructor_ref;
1837
1838         unless ($package->can('DESTROY')) {
1839             my $destroy_name = "${package}::DESTROY";
1840             no strict "refs";
1841
1842             # Use typeglob to give the anonymous subroutine the name we want
1843             *$destroy_name = sub {
1844                 my $self = shift;
1845                 my $addr = do { no overloading; pack 'J', $self; };
1846
1847                 $self->$destroy_callback if $destroy_callback;
1848                 foreach my $field (keys %{$package_fields{$package}}) {
1849                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1850                     delete $package_fields{$package}{$field}{$addr};
1851                 }
1852                 return;
1853             }
1854         }
1855
1856         unless ($package->can('dump')) {
1857             my $dump_name = "${package}::dump";
1858             no strict "refs";
1859             *$dump_name = sub {
1860                 my $self = shift;
1861                 return dump_inside_out($self, $package_fields{$package}, @_);
1862             }
1863         }
1864         return;
1865     }
1866
1867     sub set_access {
1868         # Arrange for the input field to be garbage collected when no longer
1869         # needed.  Also, creates standard accessor functions for the field
1870         # based on the optional parameters-- none if none of these parameters:
1871         #   'addable'    creates an 'add_NAME()' accessor function.
1872         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1873         #                function.
1874         #   'settable'   creates a 'set_NAME()' accessor function.
1875         #   'constructor' doesn't create an accessor function, but adds the
1876         #                field to the hash that was previously passed to
1877         #                setup_package();
1878         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1879         # 'add' etc. all mean 'addable'.
1880         # The read accessor function will work on both array and scalar
1881         # values.  If another accessor in the parameter list is 'a', the read
1882         # access assumes an array.  You can also force it to be array access
1883         # by specifying 'readable_array' instead of 'readable'
1884         #
1885         # A sort-of 'protected' access can be set-up by preceding the addable,
1886         # readable or settable with some initial portion of 'protected_' (but,
1887         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1888         # "protection" is only by convention.  All that happens is that the
1889         # accessor functions' names begin with an underscore.  So instead of
1890         # calling set_foo, the call is _set_foo.  (Real protection could be
1891         # accomplished by having a new subroutine, end_package, called at the
1892         # end of each package, and then storing the __LINE__ ranges and
1893         # checking them on every accessor.  But that is way overkill.)
1894
1895         # We create anonymous subroutines as the accessors and then use
1896         # typeglobs to assign them to the proper package and name
1897
1898         my $name = shift;   # Name of the field
1899         my $field = shift;  # Reference to the inside-out hash containing the
1900                             # field
1901
1902         my $package = (caller)[0];
1903
1904         if (! exists $package_fields{$package}) {
1905             croak "$0: Must call 'setup_package' before 'set_access'";
1906         }
1907
1908         # Stash the field so DESTROY can get it.
1909         $package_fields{$package}{$name} = $field;
1910
1911         # Remaining arguments are the accessors.  For each...
1912         foreach my $access (@_) {
1913             my $access = lc $access;
1914
1915             my $protected = "";
1916
1917             # Match the input as far as it goes.
1918             if ($access =~ /^(p[^_]*)_/) {
1919                 $protected = $1;
1920                 if (substr('protected_', 0, length $protected)
1921                     eq $protected)
1922                 {
1923
1924                     # Add 1 for the underscore not included in $protected
1925                     $access = substr($access, length($protected) + 1);
1926                     $protected = '_';
1927                 }
1928                 else {
1929                     $protected = "";
1930                 }
1931             }
1932
1933             if (substr('addable', 0, length $access) eq $access) {
1934                 my $subname = "${package}::${protected}add_$name";
1935                 no strict "refs";
1936
1937                 # add_ accessor.  Don't add if already there, which we
1938                 # determine using 'eq' for scalars and '==' otherwise.
1939                 *$subname = sub {
1940                     use strict "refs";
1941                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1942                     my $self = shift;
1943                     my $value = shift;
1944                     my $addr = do { no overloading; pack 'J', $self; };
1945                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1946                     if (ref $value) {
1947                         return if grep { $value == $_ } @{$field->{$addr}};
1948                     }
1949                     else {
1950                         return if grep { $value eq $_ } @{$field->{$addr}};
1951                     }
1952                     push @{$field->{$addr}}, $value;
1953                     return;
1954                 }
1955             }
1956             elsif (substr('constructor', 0, length $access) eq $access) {
1957                 if ($protected) {
1958                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
1959                 }
1960                 else {
1961                     $constructor_fields{$package}{$name} = $field;
1962                 }
1963             }
1964             elsif (substr('readable_array', 0, length $access) eq $access) {
1965
1966                 # Here has read access.  If one of the other parameters for
1967                 # access is array, or this one specifies array (by being more
1968                 # than just 'readable_'), then create a subroutine that
1969                 # assumes the data is an array.  Otherwise just a scalar
1970                 my $subname = "${package}::${protected}$name";
1971                 if (grep { /^a/i } @_
1972                     or length($access) > length('readable_'))
1973                 {
1974                     no strict "refs";
1975                     *$subname = sub {
1976                         use strict "refs";
1977                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1978                         my $addr = do { no overloading; pack 'J', $_[0]; };
1979                         if (ref $field->{$addr} ne 'ARRAY') {
1980                             my $type = ref $field->{$addr};
1981                             $type = 'scalar' unless $type;
1982                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
1983                             return;
1984                         }
1985                         return scalar @{$field->{$addr}} unless wantarray;
1986
1987                         # Make a copy; had problems with caller modifying the
1988                         # original otherwise
1989                         my @return = @{$field->{$addr}};
1990                         return @return;
1991                     }
1992                 }
1993                 else {
1994
1995                     # Here not an array value, a simpler function.
1996                     no strict "refs";
1997                     *$subname = sub {
1998                         use strict "refs";
1999                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
2000                         no overloading;
2001                         return $field->{pack 'J', $_[0]};
2002                     }
2003                 }
2004             }
2005             elsif (substr('settable', 0, length $access) eq $access) {
2006                 my $subname = "${package}::${protected}set_$name";
2007                 no strict "refs";
2008                 *$subname = sub {
2009                     use strict "refs";
2010                     if (main::DEBUG) {
2011                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
2012                         Carp::carp_extra_args(\@_) if @_ > 2;
2013                     }
2014                     # $self is $_[0]; $value is $_[1]
2015                     no overloading;
2016                     $field->{pack 'J', $_[0]} = $_[1];
2017                     return;
2018                 }
2019             }
2020             else {
2021                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
2022             }
2023         }
2024         return;
2025     }
2026 }
2027
2028 package Input_file;
2029
2030 # All input files use this object, which stores various attributes about them,
2031 # and provides for convenient, uniform handling.  The run method wraps the
2032 # processing.  It handles all the bookkeeping of opening, reading, and closing
2033 # the file, returning only significant input lines.
2034 #
2035 # Each object gets a handler which processes the body of the file, and is
2036 # called by run().  Most should use the generic, default handler, which has
2037 # code scrubbed to handle things you might not expect.  A handler should
2038 # basically be a while(next_line()) {...} loop.
2039 #
2040 # You can also set up handlers to
2041 #   1) call before the first line is read for pre processing
2042 #   2) call to adjust each line of the input before the main handler gets them
2043 #   3) call upon EOF before the main handler exits its loop
2044 #   4) call at the end for post processing
2045 #
2046 # $_ is used to store the input line, and is to be filtered by the
2047 # each_line_handler()s.  So, if the format of the line is not in the desired
2048 # format for the main handler, these are used to do that adjusting.  They can
2049 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
2050 # so the $_ output of one is used as the input to the next.  None of the other
2051 # handlers are stackable, but could easily be changed to be so.
2052 #
2053 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
2054 # which insert the parameters as lines to be processed before the next input
2055 # file line is read.  This allows the EOF handler to flush buffers, for
2056 # example.  The difference between the two routines is that the lines inserted
2057 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
2058 # called it from such a handler, you would get infinite recursion.)  Lines
2059 # inserted by insert_adjusted_lines() go directly to the main handler without
2060 # any adjustments.  If the  post-processing handler calls any of these, there
2061 # will be no effect.  Some error checking for these conditions could be added,
2062 # but it hasn't been done.
2063 #
2064 # carp_bad_line() should be called to warn of bad input lines, which clears $_
2065 # to prevent further processing of the line.  This routine will output the
2066 # message as a warning once, and then keep a count of the lines that have the
2067 # same message, and output that count at the end of the file's processing.
2068 # This keeps the number of messages down to a manageable amount.
2069 #
2070 # get_missings() should be called to retrieve any @missing input lines.
2071 # Messages will be raised if this isn't done if the options aren't to ignore
2072 # missings.
2073
2074 sub trace { return main::trace(@_); }
2075
2076 { # Closure
2077     # Keep track of fields that are to be put into the constructor.
2078     my %constructor_fields;
2079
2080     main::setup_package(Constructor_Fields => \%constructor_fields);
2081
2082     my %file; # Input file name, required
2083     main::set_access('file', \%file, qw{ c r });
2084
2085     my %first_released; # Unicode version file was first released in, required
2086     main::set_access('first_released', \%first_released, qw{ c r });
2087
2088     my %handler;    # Subroutine to process the input file, defaults to
2089                     # 'process_generic_property_file'
2090     main::set_access('handler', \%handler, qw{ c });
2091
2092     my %property;
2093     # name of property this file is for.  defaults to none, meaning not
2094     # applicable, or is otherwise determinable, for example, from each line.
2095     main::set_access('property', \%property, qw{ c r });
2096
2097     my %optional;
2098     # If this is true, the file is optional.  If not present, no warning is
2099     # output.  If it is present, the string given by this parameter is
2100     # evaluated, and if false the file is not processed.
2101     main::set_access('optional', \%optional, 'c', 'r');
2102
2103     my %non_skip;
2104     # This is used for debugging, to skip processing of all but a few input
2105     # files.  Add 'non_skip => 1' to the constructor for those files you want
2106     # processed when you set the $debug_skip global.
2107     main::set_access('non_skip', \%non_skip, 'c');
2108
2109     my %skip;
2110     # This is used to skip processing of this input file semi-permanently,
2111     # when it evaluates to true.  The value should be the reason the file is
2112     # being skipped.  It is used for files that we aren't planning to process
2113     # anytime soon, but want to allow to be in the directory and not raise a
2114     # message that we are not handling.  Mostly for test files.  This is in
2115     # contrast to the non_skip element, which is supposed to be used very
2116     # temporarily for debugging.  Sets 'optional' to 1.  Also, files that we
2117     # pretty much will never look at can be placed in the global
2118     # %ignored_files instead.  Ones used here will be added to %skipped files
2119     main::set_access('skip', \%skip, 'c');
2120
2121     my %each_line_handler;
2122     # list of subroutines to look at and filter each non-comment line in the
2123     # file.  defaults to none.  The subroutines are called in order, each is
2124     # to adjust $_ for the next one, and the final one adjusts it for
2125     # 'handler'
2126     main::set_access('each_line_handler', \%each_line_handler, 'c');
2127
2128     my %has_missings_defaults;
2129     # ? Are there lines in the file giving default values for code points
2130     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
2131     # the norm, but IGNORED means it has such lines, but the handler doesn't
2132     # use them.  Having these three states allows us to catch changes to the
2133     # UCD that this program should track
2134     main::set_access('has_missings_defaults',
2135                                         \%has_missings_defaults, qw{ c r });
2136
2137     my %pre_handler;
2138     # Subroutine to call before doing anything else in the file.  If undef, no
2139     # such handler is called.
2140     main::set_access('pre_handler', \%pre_handler, qw{ c });
2141
2142     my %eof_handler;
2143     # Subroutine to call upon getting an EOF on the input file, but before
2144     # that is returned to the main handler.  This is to allow buffers to be
2145     # flushed.  The handler is expected to call insert_lines() or
2146     # insert_adjusted() with the buffered material
2147     main::set_access('eof_handler', \%eof_handler, qw{ c r });
2148
2149     my %post_handler;
2150     # Subroutine to call after all the lines of the file are read in and
2151     # processed.  If undef, no such handler is called.
2152     main::set_access('post_handler', \%post_handler, qw{ c });
2153
2154     my %progress_message;
2155     # Message to print to display progress in lieu of the standard one
2156     main::set_access('progress_message', \%progress_message, qw{ c });
2157
2158     my %handle;
2159     # cache open file handle, internal.  Is undef if file hasn't been
2160     # processed at all, empty if has;
2161     main::set_access('handle', \%handle);
2162
2163     my %added_lines;
2164     # cache of lines added virtually to the file, internal
2165     main::set_access('added_lines', \%added_lines);
2166
2167     my %errors;
2168     # cache of errors found, internal
2169     main::set_access('errors', \%errors);
2170
2171     my %missings;
2172     # storage of '@missing' defaults lines
2173     main::set_access('missings', \%missings);
2174
2175     sub new {
2176         my $class = shift;
2177
2178         my $self = bless \do{ my $anonymous_scalar }, $class;
2179         my $addr = do { no overloading; pack 'J', $self; };
2180
2181         # Set defaults
2182         $handler{$addr} = \&main::process_generic_property_file;
2183         $non_skip{$addr} = 0;
2184         $skip{$addr} = 0;
2185         $has_missings_defaults{$addr} = $NO_DEFAULTS;
2186         $handle{$addr} = undef;
2187         $added_lines{$addr} = [ ];
2188         $each_line_handler{$addr} = [ ];
2189         $errors{$addr} = { };
2190         $missings{$addr} = [ ];
2191
2192         # Two positional parameters.
2193         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2194         $file{$addr} = main::internal_file_to_platform(shift);
2195         $first_released{$addr} = shift;
2196
2197         # The rest of the arguments are key => value pairs
2198         # %constructor_fields has been set up earlier to list all possible
2199         # ones.  Either set or push, depending on how the default has been set
2200         # up just above.
2201         my %args = @_;
2202         foreach my $key (keys %args) {
2203             my $argument = $args{$key};
2204
2205             # Note that the fields are the lower case of the constructor keys
2206             my $hash = $constructor_fields{lc $key};
2207             if (! defined $hash) {
2208                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
2209                 next;
2210             }
2211             if (ref $hash->{$addr} eq 'ARRAY') {
2212                 if (ref $argument eq 'ARRAY') {
2213                     foreach my $argument (@{$argument}) {
2214                         next if ! defined $argument;
2215                         push @{$hash->{$addr}}, $argument;
2216                     }
2217                 }
2218                 else {
2219                     push @{$hash->{$addr}}, $argument if defined $argument;
2220                 }
2221             }
2222             else {
2223                 $hash->{$addr} = $argument;
2224             }
2225             delete $args{$key};
2226         };
2227
2228         # If the file has a property for it, it means that the property is not
2229         # listed in the file's entries.  So add a handler to the list of line
2230         # handlers to insert the property name into the lines, to provide a
2231         # uniform interface to the final processing subroutine.
2232         # the final code doesn't have to worry about that.
2233         if ($property{$addr}) {
2234             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2235         }
2236
2237         if ($non_skip{$addr} && ! $debug_skip && $verbosity) {
2238             print "Warning: " . __PACKAGE__ . " constructor for $file{$addr} has useless 'non_skip' in it\n";
2239         }
2240
2241         # If skipping, set to optional, and add to list of ignored files,
2242         # including its reason
2243         if ($skip{$addr}) {
2244             $optional{$addr} = 1;
2245             $skipped_files{$file{$addr}} = $skip{$addr}
2246         }
2247
2248         return $self;
2249     }
2250
2251
2252     use overload
2253         fallback => 0,
2254         qw("") => "_operator_stringify",
2255         "." => \&main::_operator_dot,
2256         ".=" => \&main::_operator_dot_equal,
2257     ;
2258
2259     sub _operator_stringify {
2260         my $self = shift;
2261
2262         return __PACKAGE__ . " object for " . $self->file;
2263     }
2264
2265     # flag to make sure extracted files are processed early
2266     my $seen_non_extracted_non_age = 0;
2267
2268     sub run {
2269         # Process the input object $self.  This opens and closes the file and
2270         # calls all the handlers for it.  Currently,  this can only be called
2271         # once per file, as it destroy's the EOF handler
2272
2273         my $self = shift;
2274         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2275
2276         my $addr = do { no overloading; pack 'J', $self; };
2277
2278         my $file = $file{$addr};
2279
2280         # Don't process if not expecting this file (because released later
2281         # than this Unicode version), and isn't there.  This means if someone
2282         # copies it into an earlier version's directory, we will go ahead and
2283         # process it.
2284         return if $first_released{$addr} gt $v_version && ! -e $file;
2285
2286         # If in debugging mode and this file doesn't have the non-skip
2287         # flag set, and isn't one of the critical files, skip it.
2288         if ($debug_skip
2289             && $first_released{$addr} ne v0
2290             && ! $non_skip{$addr})
2291         {
2292             print "Skipping $file in debugging\n" if $verbosity;
2293             return;
2294         }
2295
2296         # File could be optional
2297         if ($optional{$addr}) {
2298             return unless -e $file;
2299             my $result = eval $optional{$addr};
2300             if (! defined $result) {
2301                 Carp::my_carp_bug("Got '$@' when tried to eval $optional{$addr}.  $file Skipped.");
2302                 return;
2303             }
2304             if (! $result) {
2305                 if ($verbosity) {
2306                     print STDERR "Skipping processing input file '$file' because '$optional{$addr}' is not true\n";
2307                 }
2308                 return;
2309             }
2310         }
2311
2312         if (! defined $file || ! -e $file) {
2313
2314             # If the file doesn't exist, see if have internal data for it
2315             # (based on first_released being 0).
2316             if ($first_released{$addr} eq v0) {
2317                 $handle{$addr} = 'pretend_is_open';
2318             }
2319             else {
2320                 if (! $optional{$addr}  # File could be optional
2321                     && $v_version ge $first_released{$addr})
2322                 {
2323                     print STDERR "Skipping processing input file '$file' because not found\n" if $v_version ge $first_released{$addr};
2324                 }
2325                 return;
2326             }
2327         }
2328         else {
2329
2330             # Here, the file exists.  Some platforms may change the case of
2331             # its name
2332             if ($seen_non_extracted_non_age) {
2333                 if ($file =~ /$EXTRACTED/i) {
2334                     Carp::my_carp_bug(main::join_lines(<<END
2335 $file should be processed just after the 'Prop...Alias' files, and before
2336 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2337 have subtle problems
2338 END
2339                     ));
2340                 }
2341             }
2342             elsif ($EXTRACTED_DIR
2343                     && $first_released{$addr} ne v0
2344                     && $file !~ /$EXTRACTED/i
2345                     && lc($file) ne 'dage.txt')
2346             {
2347                 # We don't set this (by the 'if' above) if we have no
2348                 # extracted directory, so if running on an early version,
2349                 # this test won't work.  Not worth worrying about.
2350                 $seen_non_extracted_non_age = 1;
2351             }
2352
2353             # And mark the file as having being processed, and warn if it
2354             # isn't a file we are expecting.  As we process the files,
2355             # they are deleted from the hash, so any that remain at the
2356             # end of the program are files that we didn't process.
2357             my $fkey = File::Spec->rel2abs($file);
2358             my $expecting = delete $potential_files{lc($fkey)};
2359
2360             Carp::my_carp("Was not expecting '$file'.") if
2361                     ! $expecting
2362                     && ! defined $handle{$addr};
2363
2364             # Having deleted from expected files, we can quit if not to do
2365             # anything.  Don't print progress unless really want verbosity
2366             if ($skip{$addr}) {
2367                 print "Skipping $file.\n" if $verbosity >= $VERBOSE;
2368                 return;
2369             }
2370
2371             # Open the file, converting the slashes used in this program
2372             # into the proper form for the OS
2373             my $file_handle;
2374             if (not open $file_handle, "<", $file) {
2375                 Carp::my_carp("Can't open $file.  Skipping: $!");
2376                 return 0;
2377             }
2378             $handle{$addr} = $file_handle; # Cache the open file handle
2379         }
2380
2381         if ($verbosity >= $PROGRESS) {
2382             if ($progress_message{$addr}) {
2383                 print "$progress_message{$addr}\n";
2384             }
2385             else {
2386                 # If using a virtual file, say so.
2387                 print "Processing ", (-e $file)
2388                                        ? $file
2389                                        : "substitute $file",
2390                                      "\n";
2391             }
2392         }
2393
2394
2395         # Call any special handler for before the file.
2396         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2397
2398         # Then the main handler
2399         &{$handler{$addr}}($self);
2400
2401         # Then any special post-file handler.
2402         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2403
2404         # If any errors have been accumulated, output the counts (as the first
2405         # error message in each class was output when it was encountered).
2406         if ($errors{$addr}) {
2407             my $total = 0;
2408             my $types = 0;
2409             foreach my $error (keys %{$errors{$addr}}) {
2410                 $total += $errors{$addr}->{$error};
2411                 delete $errors{$addr}->{$error};
2412                 $types++;
2413             }
2414             if ($total > 1) {
2415                 my $message
2416                         = "A total of $total lines had errors in $file.  ";
2417
2418                 $message .= ($types == 1)
2419                             ? '(Only the first one was displayed.)'
2420                             : '(Only the first of each type was displayed.)';
2421                 Carp::my_carp($message);
2422             }
2423         }
2424
2425         if (@{$missings{$addr}}) {
2426             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2427         }
2428
2429         # If a real file handle, close it.
2430         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2431                                                         ref $handle{$addr};
2432         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2433                                # the file, as opposed to undef
2434         return;
2435     }
2436
2437     sub next_line {
2438         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2439         # if such a line exists.  'logical' means that any lines that have
2440         # been added via insert_lines() will be returned in $_ before the file
2441         # is read again.
2442
2443         my $self = shift;
2444         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2445
2446         my $addr = do { no overloading; pack 'J', $self; };
2447
2448         # Here the file is open (or if the handle is not a ref, is an open
2449         # 'virtual' file).  Get the next line; any inserted lines get priority
2450         # over the file itself.
2451         my $adjusted;
2452
2453         LINE:
2454         while (1) { # Loop until find non-comment, non-empty line
2455             #local $to_trace = 1 if main::DEBUG;
2456             my $inserted_ref = shift @{$added_lines{$addr}};
2457             if (defined $inserted_ref) {
2458                 ($adjusted, $_) = @{$inserted_ref};
2459                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2460                 return 1 if $adjusted;
2461             }
2462             else {
2463                 last if ! ref $handle{$addr}; # Don't read unless is real file
2464                 last if ! defined ($_ = readline $handle{$addr});
2465             }
2466             chomp;
2467             trace $_ if main::DEBUG && $to_trace;
2468
2469             # See if this line is the comment line that defines what property
2470             # value that code points that are not listed in the file should
2471             # have.  The format or existence of these lines is not guaranteed
2472             # by Unicode since they are comments, but the documentation says
2473             # that this was added for machine-readability, so probably won't
2474             # change.  This works starting in Unicode Version 5.0.  They look
2475             # like:
2476             #
2477             # @missing: 0000..10FFFF; Not_Reordered
2478             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2479             # @missing: 0000..10FFFF; ; NaN
2480             #
2481             # Save the line for a later get_missings() call.
2482             if (/$missing_defaults_prefix/) {
2483                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2484                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2485                 }
2486                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2487                     my @defaults = split /\s* ; \s*/x, $_;
2488
2489                     # The first field is the @missing, which ends in a
2490                     # semi-colon, so can safely shift.
2491                     shift @defaults;
2492
2493                     # Some of these lines may have empty field placeholders
2494                     # which get in the way.  An example is:
2495                     # @missing: 0000..10FFFF; ; NaN
2496                     # Remove them.  Process starting from the top so the
2497                     # splice doesn't affect things still to be looked at.
2498                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2499                         next if $defaults[$i] ne "";
2500                         splice @defaults, $i, 1;
2501                     }
2502
2503                     # What's left should be just the property (maybe) and the
2504                     # default.  Having only one element means it doesn't have
2505                     # the property.
2506                     my $default;
2507                     my $property;
2508                     if (@defaults >= 1) {
2509                         if (@defaults == 1) {
2510                             $default = $defaults[0];
2511                         }
2512                         else {
2513                             $property = $defaults[0];
2514                             $default = $defaults[1];
2515                         }
2516                     }
2517
2518                     if (@defaults < 1
2519                         || @defaults > 2
2520                         || ($default =~ /^</
2521                             && $default !~ /^<code *point>$/i
2522                             && $default !~ /^<none>$/i
2523                             && $default !~ /^<script>$/i))
2524                     {
2525                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2526                     }
2527                     else {
2528
2529                         # If the property is missing from the line, it should
2530                         # be the one for the whole file
2531                         $property = $property{$addr} if ! defined $property;
2532
2533                         # Change <none> to the null string, which is what it
2534                         # really means.  If the default is the code point
2535                         # itself, set it to <code point>, which is what
2536                         # Unicode uses (but sometimes they've forgotten the
2537                         # space)
2538                         if ($default =~ /^<none>$/i) {
2539                             $default = "";
2540                         }
2541                         elsif ($default =~ /^<code *point>$/i) {
2542                             $default = $CODE_POINT;
2543                         }
2544                         elsif ($default =~ /^<script>$/i) {
2545
2546                             # Special case this one.  Currently is from
2547                             # ScriptExtensions.txt, and means for all unlisted
2548                             # code points, use their Script property values.
2549                             # For the code points not listed in that file, the
2550                             # default value is 'Unknown'.
2551                             $default = "Unknown";
2552                         }
2553
2554                         # Store them as a sub-arrays with both components.
2555                         push @{$missings{$addr}}, [ $default, $property ];
2556                     }
2557                 }
2558
2559                 # There is nothing for the caller to process on this comment
2560                 # line.
2561                 next;
2562             }
2563
2564             # Remove comments and trailing space, and skip this line if the
2565             # result is empty
2566             s/#.*//;
2567             s/\s+$//;
2568             next if /^$/;
2569
2570             # Call any handlers for this line, and skip further processing of
2571             # the line if the handler sets the line to null.
2572             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2573                 &{$sub_ref}($self);
2574                 next LINE if /^$/;
2575             }
2576
2577             # Here the line is ok.  return success.
2578             return 1;
2579         } # End of looping through lines.
2580
2581         # If there is an EOF handler, call it (only once) and if it generates
2582         # more lines to process go back in the loop to handle them.
2583         if ($eof_handler{$addr}) {
2584             &{$eof_handler{$addr}}($self);
2585             $eof_handler{$addr} = "";   # Currently only get one shot at it.
2586             goto LINE if $added_lines{$addr};
2587         }
2588
2589         # Return failure -- no more lines.
2590         return 0;
2591
2592     }
2593
2594 #   Not currently used, not fully tested.
2595 #    sub peek {
2596 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
2597 #        # record.  Not callable from an each_line_handler(), nor does it call
2598 #        # an each_line_handler() on the line.
2599 #
2600 #        my $self = shift;
2601 #        my $addr = do { no overloading; pack 'J', $self; };
2602 #
2603 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
2604 #            my ($adjusted, $line) = @{$inserted_ref};
2605 #            next if $adjusted;
2606 #
2607 #            # Remove comments and trailing space, and return a non-empty
2608 #            # resulting line
2609 #            $line =~ s/#.*//;
2610 #            $line =~ s/\s+$//;
2611 #            return $line if $line ne "";
2612 #        }
2613 #
2614 #        return if ! ref $handle{$addr}; # Don't read unless is real file
2615 #        while (1) { # Loop until find non-comment, non-empty line
2616 #            local $to_trace = 1 if main::DEBUG;
2617 #            trace $_ if main::DEBUG && $to_trace;
2618 #            return if ! defined (my $line = readline $handle{$addr});
2619 #            chomp $line;
2620 #            push @{$added_lines{$addr}}, [ 0, $line ];
2621 #
2622 #            $line =~ s/#.*//;
2623 #            $line =~ s/\s+$//;
2624 #            return $line if $line ne "";
2625 #        }
2626 #
2627 #        return;
2628 #    }
2629
2630
2631     sub insert_lines {
2632         # Lines can be inserted so that it looks like they were in the input
2633         # file at the place it was when this routine is called.  See also
2634         # insert_adjusted_lines().  Lines inserted via this routine go through
2635         # any each_line_handler()
2636
2637         my $self = shift;
2638
2639         # Each inserted line is an array, with the first element being 0 to
2640         # indicate that this line hasn't been adjusted, and needs to be
2641         # processed.
2642         no overloading;
2643         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
2644         return;
2645     }
2646
2647     sub insert_adjusted_lines {
2648         # Lines can be inserted so that it looks like they were in the input
2649         # file at the place it was when this routine is called.  See also
2650         # insert_lines().  Lines inserted via this routine are already fully
2651         # adjusted, ready to be processed; each_line_handler()s handlers will
2652         # not be called.  This means this is not a completely general
2653         # facility, as only the last each_line_handler on the stack should
2654         # call this.  It could be made more general, by passing to each of the
2655         # line_handlers their position on the stack, which they would pass on
2656         # to this routine, and that would replace the boolean first element in
2657         # the anonymous array pushed here, so that the next_line routine could
2658         # use that to call only those handlers whose index is after it on the
2659         # stack.  But this is overkill for what is needed now.
2660
2661         my $self = shift;
2662         trace $_[0] if main::DEBUG && $to_trace;
2663
2664         # Each inserted line is an array, with the first element being 1 to
2665         # indicate that this line has been adjusted
2666         no overloading;
2667         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
2668         return;
2669     }
2670
2671     sub get_missings {
2672         # Returns the stored up @missings lines' values, and clears the list.
2673         # The values are in an array, consisting of the default in the first
2674         # element, and the property in the 2nd.  However, since these lines
2675         # can be stacked up, the return is an array of all these arrays.
2676
2677         my $self = shift;
2678         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2679
2680         my $addr = do { no overloading; pack 'J', $self; };
2681
2682         # If not accepting a list return, just return the first one.
2683         return shift @{$missings{$addr}} unless wantarray;
2684
2685         my @return = @{$missings{$addr}};
2686         undef @{$missings{$addr}};
2687         return @return;
2688     }
2689
2690     sub _insert_property_into_line {
2691         # Add a property field to $_, if this file requires it.
2692
2693         my $self = shift;
2694         my $addr = do { no overloading; pack 'J', $self; };
2695         my $property = $property{$addr};
2696         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2697
2698         $_ =~ s/(;|$)/; $property$1/;
2699         return;
2700     }
2701
2702     sub carp_bad_line {
2703         # Output consistent error messages, using either a generic one, or the
2704         # one given by the optional parameter.  To avoid gazillions of the
2705         # same message in case the syntax of a  file is way off, this routine
2706         # only outputs the first instance of each message, incrementing a
2707         # count so the totals can be output at the end of the file.
2708
2709         my $self = shift;
2710         my $message = shift;
2711         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2712
2713         my $addr = do { no overloading; pack 'J', $self; };
2714
2715         $message = 'Unexpected line' unless $message;
2716
2717         # No trailing punctuation so as to fit with our addenda.
2718         $message =~ s/[.:;,]$//;
2719
2720         # If haven't seen this exact message before, output it now.  Otherwise
2721         # increment the count of how many times it has occurred
2722         unless ($errors{$addr}->{$message}) {
2723             Carp::my_carp("$message in '$_' in "
2724                             . $file{$addr}
2725                             . " at line $..  Skipping this line;");
2726             $errors{$addr}->{$message} = 1;
2727         }
2728         else {
2729             $errors{$addr}->{$message}++;
2730         }
2731
2732         # Clear the line to prevent any further (meaningful) processing of it.
2733         $_ = "";
2734
2735         return;
2736     }
2737 } # End closure
2738
2739 package Multi_Default;
2740
2741 # Certain properties in early versions of Unicode had more than one possible
2742 # default for code points missing from the files.  In these cases, one
2743 # default applies to everything left over after all the others are applied,
2744 # and for each of the others, there is a description of which class of code
2745 # points applies to it.  This object helps implement this by storing the
2746 # defaults, and for all but that final default, an eval string that generates
2747 # the class that it applies to.
2748
2749
2750 {   # Closure
2751
2752     main::setup_package();
2753
2754     my %class_defaults;
2755     # The defaults structure for the classes
2756     main::set_access('class_defaults', \%class_defaults);
2757
2758     my %other_default;
2759     # The default that applies to everything left over.
2760     main::set_access('other_default', \%other_default, 'r');
2761
2762
2763     sub new {
2764         # The constructor is called with default => eval pairs, terminated by
2765         # the left-over default. e.g.
2766         # Multi_Default->new(
2767         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
2768         #               -  0x200D',
2769         #        'R' => 'some other expression that evaluates to code points',
2770         #        .
2771         #        .
2772         #        .
2773         #        'U'));
2774
2775         my $class = shift;
2776
2777         my $self = bless \do{my $anonymous_scalar}, $class;
2778         my $addr = do { no overloading; pack 'J', $self; };
2779
2780         while (@_ > 1) {
2781             my $default = shift;
2782             my $eval = shift;
2783             $class_defaults{$addr}->{$default} = $eval;
2784         }
2785
2786         $other_default{$addr} = shift;
2787
2788         return $self;
2789     }
2790
2791     sub get_next_defaults {
2792         # Iterates and returns the next class of defaults.
2793         my $self = shift;
2794         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2795
2796         my $addr = do { no overloading; pack 'J', $self; };
2797
2798         return each %{$class_defaults{$addr}};
2799     }
2800 }
2801
2802 package Alias;
2803
2804 # An alias is one of the names that a table goes by.  This class defines them
2805 # including some attributes.  Everything is currently setup in the
2806 # constructor.
2807
2808
2809 {   # Closure
2810
2811     main::setup_package();
2812
2813     my %name;
2814     main::set_access('name', \%name, 'r');
2815
2816     my %loose_match;
2817     # Should this name match loosely or not.
2818     main::set_access('loose_match', \%loose_match, 'r');
2819
2820     my %make_re_pod_entry;
2821     # Some aliases should not get their own entries in the re section of the
2822     # pod, because they are covered by a wild-card, and some we want to
2823     # discourage use of.  Binary
2824     main::set_access('make_re_pod_entry', \%make_re_pod_entry, 'r', 's');
2825
2826     my %ucd;
2827     # Is this documented to be accessible via Unicode::UCD
2828     main::set_access('ucd', \%ucd, 'r', 's');
2829
2830     my %status;
2831     # Aliases have a status, like deprecated, or even suppressed (which means
2832     # they don't appear in documentation).  Enum
2833     main::set_access('status', \%status, 'r');
2834
2835     my %ok_as_filename;
2836     # Similarly, some aliases should not be considered as usable ones for
2837     # external use, such as file names, or we don't want documentation to
2838     # recommend them.  Boolean
2839     main::set_access('ok_as_filename', \%ok_as_filename, 'r');
2840
2841     sub new {
2842         my $class = shift;
2843
2844         my $self = bless \do { my $anonymous_scalar }, $class;
2845         my $addr = do { no overloading; pack 'J', $self; };
2846
2847         $name{$addr} = shift;
2848         $loose_match{$addr} = shift;
2849         $make_re_pod_entry{$addr} = shift;
2850         $ok_as_filename{$addr} = shift;
2851         $status{$addr} = shift;
2852         $ucd{$addr} = shift;
2853
2854         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2855
2856         # Null names are never ok externally
2857         $ok_as_filename{$addr} = 0 if $name{$addr} eq "";
2858
2859         return $self;
2860     }
2861 }
2862
2863 package Range;
2864
2865 # A range is the basic unit for storing code points, and is described in the
2866 # comments at the beginning of the program.  Each range has a starting code
2867 # point; an ending code point (not less than the starting one); a value
2868 # that applies to every code point in between the two end-points, inclusive;
2869 # and an enum type that applies to the value.  The type is for the user's
2870 # convenience, and has no meaning here, except that a non-zero type is
2871 # considered to not obey the normal Unicode rules for having standard forms.
2872 #
2873 # The same structure is used for both map and match tables, even though in the
2874 # latter, the value (and hence type) is irrelevant and could be used as a
2875 # comment.  In map tables, the value is what all the code points in the range
2876 # map to.  Type 0 values have the standardized version of the value stored as
2877 # well, so as to not have to recalculate it a lot.
2878
2879 sub trace { return main::trace(@_); }
2880
2881 {   # Closure
2882
2883     main::setup_package();
2884
2885     my %start;
2886     main::set_access('start', \%start, 'r', 's');
2887
2888     my %end;
2889     main::set_access('end', \%end, 'r', 's');
2890
2891     my %value;
2892     main::set_access('value', \%value, 'r');
2893
2894     my %type;
2895     main::set_access('type', \%type, 'r');
2896
2897     my %standard_form;
2898     # The value in internal standard form.  Defined only if the type is 0.
2899     main::set_access('standard_form', \%standard_form);
2900
2901     # Note that if these fields change, the dump() method should as well
2902
2903     sub new {
2904         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
2905         my $class = shift;
2906
2907         my $self = bless \do { my $anonymous_scalar }, $class;
2908         my $addr = do { no overloading; pack 'J', $self; };
2909
2910         $start{$addr} = shift;
2911         $end{$addr} = shift;
2912
2913         my %args = @_;
2914
2915         my $value = delete $args{'Value'};  # Can be 0
2916         $value = "" unless defined $value;
2917         $value{$addr} = $value;
2918
2919         $type{$addr} = delete $args{'Type'} || 0;
2920
2921         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2922
2923         return $self;
2924     }
2925
2926     use overload
2927         fallback => 0,
2928         qw("") => "_operator_stringify",
2929         "." => \&main::_operator_dot,
2930         ".=" => \&main::_operator_dot_equal,
2931     ;
2932
2933     sub _operator_stringify {
2934         my $self = shift;
2935         my $addr = do { no overloading; pack 'J', $self; };
2936
2937         # Output it like '0041..0065 (value)'
2938         my $return = sprintf("%04X", $start{$addr})
2939                         .  '..'
2940                         . sprintf("%04X", $end{$addr});
2941         my $value = $value{$addr};
2942         my $type = $type{$addr};
2943         $return .= ' (';
2944         $return .= "$value";
2945         $return .= ", Type=$type" if $type != 0;
2946         $return .= ')';
2947
2948         return $return;
2949     }
2950
2951     sub standard_form {
2952         # Calculate the standard form only if needed, and cache the result.
2953         # The standard form is the value itself if the type is special.
2954         # This represents a considerable CPU and memory saving - at the time
2955         # of writing there are 368676 non-special objects, but the standard
2956         # form is only requested for 22047 of them - ie about 6%.
2957
2958         my $self = shift;
2959         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2960
2961         my $addr = do { no overloading; pack 'J', $self; };
2962
2963         return $standard_form{$addr} if defined $standard_form{$addr};
2964
2965         my $value = $value{$addr};
2966         return $value if $type{$addr};
2967         return $standard_form{$addr} = main::standardize($value);
2968     }
2969
2970     sub dump {
2971         # Human, not machine readable.  For machine readable, comment out this
2972         # entire routine and let the standard one take effect.
2973         my $self = shift;
2974         my $indent = shift;
2975         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2976
2977         my $addr = do { no overloading; pack 'J', $self; };
2978
2979         my $return = $indent
2980                     . sprintf("%04X", $start{$addr})
2981                     . '..'
2982                     . sprintf("%04X", $end{$addr})
2983                     . " '$value{$addr}';";
2984         if (! defined $standard_form{$addr}) {
2985             $return .= "(type=$type{$addr})";
2986         }
2987         elsif ($standard_form{$addr} ne $value{$addr}) {
2988             $return .= "(standard '$standard_form{$addr}')";
2989         }
2990         return $return;
2991     }
2992 } # End closure
2993
2994 package _Range_List_Base;
2995
2996 # Base class for range lists.  A range list is simply an ordered list of
2997 # ranges, so that the ranges with the lowest starting numbers are first in it.
2998 #
2999 # When a new range is added that is adjacent to an existing range that has the
3000 # same value and type, it merges with it to form a larger range.
3001 #
3002 # Ranges generally do not overlap, except that there can be multiple entries
3003 # of single code point ranges.  This is because of NameAliases.txt.
3004 #
3005 # In this program, there is a standard value such that if two different
3006 # values, have the same standard value, they are considered equivalent.  This
3007 # value was chosen so that it gives correct results on Unicode data
3008
3009 # There are a number of methods to manipulate range lists, and some operators
3010 # are overloaded to handle them.
3011
3012 sub trace { return main::trace(@_); }
3013
3014 { # Closure
3015
3016     our $addr;
3017
3018     main::setup_package();
3019
3020     my %ranges;
3021     # The list of ranges
3022     main::set_access('ranges', \%ranges, 'readable_array');
3023
3024     my %max;
3025     # The highest code point in the list.  This was originally a method, but
3026     # actual measurements said it was used a lot.
3027     main::set_access('max', \%max, 'r');
3028
3029     my %each_range_iterator;
3030     # Iterator position for each_range()
3031     main::set_access('each_range_iterator', \%each_range_iterator);
3032
3033     my %owner_name_of;
3034     # Name of parent this is attached to, if any.  Solely for better error
3035     # messages.
3036     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
3037
3038     my %_search_ranges_cache;
3039     # A cache of the previous result from _search_ranges(), for better
3040     # performance
3041     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
3042
3043     sub new {
3044         my $class = shift;
3045         my %args = @_;
3046
3047         # Optional initialization data for the range list.
3048         my $initialize = delete $args{'Initialize'};
3049
3050         my $self;
3051
3052         # Use _union() to initialize.  _union() returns an object of this
3053         # class, which means that it will call this constructor recursively.
3054         # But it won't have this $initialize parameter so that it won't
3055         # infinitely loop on this.
3056         return _union($class, $initialize, %args) if defined $initialize;
3057
3058         $self = bless \do { my $anonymous_scalar }, $class;
3059         my $addr = do { no overloading; pack 'J', $self; };
3060
3061         # Optional parent object, only for debug info.
3062         $owner_name_of{$addr} = delete $args{'Owner'};
3063         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
3064
3065         # Stringify, in case it is an object.
3066         $owner_name_of{$addr} = "$owner_name_of{$addr}";
3067
3068         # This is used only for error messages, and so a colon is added
3069         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
3070
3071         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3072
3073         # Max is initialized to a negative value that isn't adjacent to 0,
3074         # for simpler tests
3075         $max{$addr} = -2;
3076
3077         $_search_ranges_cache{$addr} = 0;
3078         $ranges{$addr} = [];
3079
3080         return $self;
3081     }
3082
3083     use overload
3084         fallback => 0,
3085         qw("") => "_operator_stringify",
3086         "." => \&main::_operator_dot,
3087         ".=" => \&main::_operator_dot_equal,
3088     ;
3089
3090     sub _operator_stringify {
3091         my $self = shift;
3092         my $addr = do { no overloading; pack 'J', $self; };
3093
3094         return "Range_List attached to '$owner_name_of{$addr}'"
3095                                                 if $owner_name_of{$addr};
3096         return "anonymous Range_List " . \$self;
3097     }
3098
3099     sub _union {
3100         # Returns the union of the input code points.  It can be called as
3101         # either a constructor or a method.  If called as a method, the result
3102         # will be a new() instance of the calling object, containing the union
3103         # of that object with the other parameter's code points;  if called as
3104         # a constructor, the first parameter gives the class that the new object
3105         # should be, and the second parameter gives the code points to go into
3106         # it.
3107         # In either case, there are two parameters looked at by this routine;
3108         # any additional parameters are passed to the new() constructor.
3109         #
3110         # The code points can come in the form of some object that contains
3111         # ranges, and has a conventionally named method to access them; or
3112         # they can be an array of individual code points (as integers); or
3113         # just a single code point.
3114         #
3115         # If they are ranges, this routine doesn't make any effort to preserve
3116         # the range values and types of one input over the other.  Therefore
3117         # this base class should not allow _union to be called from other than
3118         # initialization code, so as to prevent two tables from being added
3119         # together where the range values matter.  The general form of this
3120         # routine therefore belongs in a derived class, but it was moved here
3121         # to avoid duplication of code.  The failure to overload this in this
3122         # class keeps it safe.
3123         #
3124         # It does make the effort during initialization to accept tables with
3125         # multiple values for the same code point, and to preserve the order
3126         # of these.  If there is only one input range or range set, it doesn't
3127         # sort (as it should already be sorted to the desired order), and will
3128         # accept multiple values per code point.  Otherwise it will merge
3129         # multiple values into a single one.
3130
3131         my $self;
3132         my @args;   # Arguments to pass to the constructor
3133
3134         my $class = shift;
3135
3136         # If a method call, will start the union with the object itself, and
3137         # the class of the new object will be the same as self.
3138         if (ref $class) {
3139             $self = $class;
3140             $class = ref $self;
3141             push @args, $self;
3142         }
3143
3144         # Add the other required parameter.
3145         push @args, shift;
3146         # Rest of parameters are passed on to the constructor
3147
3148         # Accumulate all records from both lists.
3149         my @records;
3150         my $input_count = 0;
3151         for my $arg (@args) {
3152             #local $to_trace = 0 if main::DEBUG;
3153             trace "argument = $arg" if main::DEBUG && $to_trace;
3154             if (! defined $arg) {
3155                 my $message = "";
3156                 if (defined $self) {
3157                     no overloading;
3158                     $message .= $owner_name_of{pack 'J', $self};
3159                 }
3160                 Carp::my_carp_bug($message . "Undefined argument to _union.  No union done.");
3161                 return;
3162             }
3163
3164             $arg = [ $arg ] if ! ref $arg;
3165             my $type = ref $arg;
3166             if ($type eq 'ARRAY') {
3167                 foreach my $element (@$arg) {
3168                     push @records, Range->new($element, $element);
3169                     $input_count++;
3170                 }
3171             }
3172             elsif ($arg->isa('Range')) {
3173                 push @records, $arg;
3174                 $input_count++;
3175             }
3176             elsif ($arg->can('ranges')) {
3177                 push @records, $arg->ranges;
3178                 $input_count++;
3179             }
3180             else {
3181                 my $message = "";
3182                 if (defined $self) {
3183                     no overloading;
3184                     $message .= $owner_name_of{pack 'J', $self};
3185                 }
3186                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
3187                 return;
3188             }
3189         }
3190
3191         # Sort with the range containing the lowest ordinal first, but if
3192         # two ranges start at the same code point, sort with the bigger range
3193         # of the two first, because it takes fewer cycles.
3194         if ($input_count > 1) {
3195             @records = sort { ($a->start <=> $b->start)
3196                                       or
3197                                     # if b is shorter than a, b->end will be
3198                                     # less than a->end, and we want to select
3199                                     # a, so want to return -1
3200                                     ($b->end <=> $a->end)
3201                                    } @records;
3202         }
3203
3204         my $new = $class->new(@_);
3205
3206         # Fold in records so long as they add new information.
3207         for my $set (@records) {
3208             my $start = $set->start;
3209             my $end   = $set->end;
3210             my $value = $set->value;
3211             my $type  = $set->type;
3212             if ($start > $new->max) {
3213                 $new->_add_delete('+', $start, $end, $value, Type => $type);
3214             }
3215             elsif ($end > $new->max) {
3216                 $new->_add_delete('+', $new->max +1, $end, $value,
3217                                                                 Type => $type);
3218             }
3219             elsif ($input_count == 1) {
3220                 # Here, overlaps existing range, but is from a single input,
3221                 # so preserve the multiple values from that input.
3222                 $new->_add_delete('+', $start, $end, $value, Type => $type,
3223                                                 Replace => $MULTIPLE_AFTER);
3224             }
3225         }
3226
3227         return $new;
3228     }
3229
3230     sub range_count {        # Return the number of ranges in the range list
3231         my $self = shift;
3232         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3233
3234         no overloading;
3235         return scalar @{$ranges{pack 'J', $self}};
3236     }
3237
3238     sub min {
3239         # Returns the minimum code point currently in the range list, or if
3240         # the range list is empty, 2 beyond the max possible.  This is a
3241         # method because used so rarely, that not worth saving between calls,
3242         # and having to worry about changing it as ranges are added and
3243         # deleted.
3244
3245         my $self = shift;
3246         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3247
3248         my $addr = do { no overloading; pack 'J', $self; };
3249
3250         # If the range list is empty, return a large value that isn't adjacent
3251         # to any that could be in the range list, for simpler tests
3252         return $MAX_UNICODE_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
3253         return $ranges{$addr}->[0]->start;
3254     }
3255
3256     sub contains {
3257         # Boolean: Is argument in the range list?  If so returns $i such that:
3258         #   range[$i]->end < $codepoint <= range[$i+1]->end
3259         # which is one beyond what you want; this is so that the 0th range
3260         # doesn't return false
3261         my $self = shift;
3262         my $codepoint = shift;
3263         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3264
3265         my $i = $self->_search_ranges($codepoint);
3266         return 0 unless defined $i;
3267
3268         # The search returns $i, such that
3269         #   range[$i-1]->end < $codepoint <= range[$i]->end
3270         # So is in the table if and only iff it is at least the start position
3271         # of range $i.
3272         no overloading;
3273         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3274         return $i + 1;
3275     }
3276
3277     sub containing_range {
3278         # Returns the range object that contains the code point, undef if none
3279
3280         my $self = shift;
3281         my $codepoint = shift;
3282         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3283
3284         my $i = $self->contains($codepoint);
3285         return unless $i;
3286
3287         # contains() returns 1 beyond where we should look
3288         no overloading;
3289         return $ranges{pack 'J', $self}->[$i-1];
3290     }
3291
3292     sub value_of {
3293         # Returns the value associated with the code point, undef if none
3294
3295         my $self = shift;
3296         my $codepoint = shift;
3297         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3298
3299         my $range = $self->containing_range($codepoint);
3300         return unless defined $range;
3301
3302         return $range->value;
3303     }
3304
3305     sub type_of {
3306         # Returns the type of the range containing the code point, undef if
3307         # the code point is not in the table
3308
3309         my $self = shift;
3310         my $codepoint = shift;
3311         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3312
3313         my $range = $self->containing_range($codepoint);
3314         return unless defined $range;
3315
3316         return $range->type;
3317     }
3318
3319     sub _search_ranges {
3320         # Find the range in the list which contains a code point, or where it
3321         # should go if were to add it.  That is, it returns $i, such that:
3322         #   range[$i-1]->end < $codepoint <= range[$i]->end
3323         # Returns undef if no such $i is possible (e.g. at end of table), or
3324         # if there is an error.
3325
3326         my $self = shift;
3327         my $code_point = shift;
3328         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3329
3330         my $addr = do { no overloading; pack 'J', $self; };
3331
3332         return if $code_point > $max{$addr};
3333         my $r = $ranges{$addr};                # The current list of ranges
3334         my $range_list_size = scalar @$r;
3335         my $i;
3336
3337         use integer;        # want integer division
3338
3339         # Use the cached result as the starting guess for this one, because,
3340         # an experiment on 5.1 showed that 90% of the time the cache was the
3341         # same as the result on the next call (and 7% it was one less).
3342         $i = $_search_ranges_cache{$addr};
3343         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
3344                                             # from an intervening deletion
3345         #local $to_trace = 1 if main::DEBUG;
3346         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
3347         return $i if $code_point <= $r->[$i]->end
3348                      && ($i == 0 || $r->[$i-1]->end < $code_point);
3349
3350         # Here the cache doesn't yield the correct $i.  Try adding 1.
3351         if ($i < $range_list_size - 1
3352             && $r->[$i]->end < $code_point &&
3353             $code_point <= $r->[$i+1]->end)
3354         {
3355             $i++;
3356             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
3357             $_search_ranges_cache{$addr} = $i;
3358             return $i;
3359         }
3360
3361         # Here, adding 1 also didn't work.  We do a binary search to
3362         # find the correct position, starting with current $i
3363         my $lower = 0;
3364         my $upper = $range_list_size - 1;
3365         while (1) {
3366             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
3367
3368             if ($code_point <= $r->[$i]->end) {
3369
3370                 # Here we have met the upper constraint.  We can quit if we
3371                 # also meet the lower one.
3372                 last if $i == 0 || $r->[$i-1]->end < $code_point;
3373
3374                 $upper = $i;        # Still too high.
3375
3376             }
3377             else {
3378
3379                 # Here, $r[$i]->end < $code_point, so look higher up.
3380                 $lower = $i;
3381             }
3382
3383             # Split search domain in half to try again.
3384             my $temp = ($upper + $lower) / 2;
3385
3386             # No point in continuing unless $i changes for next time
3387             # in the loop.
3388             if ($temp == $i) {
3389
3390                 # We can't reach the highest element because of the averaging.
3391                 # So if one below the upper edge, force it there and try one
3392                 # more time.
3393                 if ($i == $range_list_size - 2) {
3394
3395                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
3396                     $i = $range_list_size - 1;
3397
3398                     # Change $lower as well so if fails next time through,
3399                     # taking the average will yield the same $i, and we will
3400                     # quit with the error message just below.
3401                     $lower = $i;
3402                     next;
3403                 }
3404                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
3405                 return;
3406             }
3407             $i = $temp;
3408         } # End of while loop
3409
3410         if (main::DEBUG && $to_trace) {
3411             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
3412             trace "i=  [ $i ]", $r->[$i];
3413             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
3414         }
3415
3416         # Here we have found the offset.  Cache it as a starting point for the
3417         # next call.
3418         $_search_ranges_cache{$addr} = $i;
3419         return $i;
3420     }
3421
3422     sub _add_delete {
3423         # Add, replace or delete ranges to or from a list.  The $type
3424         # parameter gives which:
3425         #   '+' => insert or replace a range, returning a list of any changed
3426         #          ranges.
3427         #   '-' => delete a range, returning a list of any deleted ranges.
3428         #
3429         # The next three parameters give respectively the start, end, and
3430         # value associated with the range.  'value' should be null unless the
3431         # operation is '+';
3432         #
3433         # The range list is kept sorted so that the range with the lowest
3434         # starting position is first in the list, and generally, adjacent
3435         # ranges with the same values are merged into a single larger one (see
3436         # exceptions below).
3437         #
3438         # There are more parameters; all are key => value pairs:
3439         #   Type    gives the type of the value.  It is only valid for '+'.
3440         #           All ranges have types; if this parameter is omitted, 0 is
3441         #           assumed.  Ranges with type 0 are assumed to obey the
3442         #           Unicode rules for casing, etc; ranges with other types are
3443         #           not.  Otherwise, the type is arbitrary, for the caller's
3444         #           convenience, and looked at only by this routine to keep
3445         #           adjacent ranges of different types from being merged into
3446         #           a single larger range, and when Replace =>
3447         #           $IF_NOT_EQUIVALENT is specified (see just below).
3448         #   Replace  determines what to do if the range list already contains
3449         #            ranges which coincide with all or portions of the input
3450         #            range.  It is only valid for '+':
3451         #       => $NO            means that the new value is not to replace
3452         #                         any existing ones, but any empty gaps of the
3453         #                         range list coinciding with the input range
3454         #                         will be filled in with the new value.
3455         #       => $UNCONDITIONALLY  means to replace the existing values with
3456         #                         this one unconditionally.  However, if the
3457         #                         new and old values are identical, the
3458         #                         replacement is skipped to save cycles
3459         #       => $IF_NOT_EQUIVALENT means to replace the existing values
3460         #          (the default)  with this one if they are not equivalent.
3461         #                         Ranges are equivalent if their types are the
3462         #                         same, and they are the same string; or if
3463         #                         both are type 0 ranges, if their Unicode
3464         #                         standard forms are identical.  In this last
3465         #                         case, the routine chooses the more "modern"
3466         #                         one to use.  This is because some of the
3467         #                         older files are formatted with values that
3468         #                         are, for example, ALL CAPs, whereas the
3469         #                         derived files have a more modern style,
3470         #                         which looks better.  By looking for this
3471         #                         style when the pre-existing and replacement
3472         #                         standard forms are the same, we can move to
3473         #                         the modern style
3474         #       => $MULTIPLE_BEFORE means that if this range duplicates an
3475         #                         existing one, but has a different value,
3476         #                         don't replace the existing one, but insert
3477         #                         this, one so that the same range can occur
3478         #                         multiple times.  They are stored LIFO, so
3479         #                         that the final one inserted is the first one
3480         #                         returned in an ordered search of the table.
3481         #                         If this is an exact duplicate, including the
3482         #                         value, the original will be moved to be
3483         #                         first, before any other duplicate ranges
3484         #                         with different values.
3485         #       => $MULTIPLE_AFTER is like $MULTIPLE_BEFORE, but is stored
3486         #                         FIFO, so that this one is inserted after all
3487         #                         others that currently exist.  If this is an
3488         #                         exact duplicate, including value, of an
3489         #                         existing range, this one is discarded
3490         #                         (leaving the existing one in its original,
3491         #                         higher priority position
3492         #       => anything else  is the same as => $IF_NOT_EQUIVALENT
3493         #
3494         # "same value" means identical for non-type-0 ranges, and it means
3495         # having the same standard forms for type-0 ranges.
3496
3497         return Carp::carp_too_few_args(\@_, 5) if main::DEBUG && @_ < 5;
3498
3499         my $self = shift;
3500         my $operation = shift;   # '+' for add/replace; '-' for delete;
3501         my $start = shift;
3502         my $end   = shift;
3503         my $value = shift;
3504
3505         my %args = @_;
3506
3507         $value = "" if not defined $value;        # warning: $value can be "0"
3508
3509         my $replace = delete $args{'Replace'};
3510         $replace = $IF_NOT_EQUIVALENT unless defined $replace;
3511
3512         my $type = delete $args{'Type'};
3513         $type = 0 unless defined $type;
3514
3515         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3516
3517         my $addr = do { no overloading; pack 'J', $self; };
3518
3519         if ($operation ne '+' && $operation ne '-') {
3520             Carp::my_carp_bug("$owner_name_of{$addr}First parameter to _add_delete must be '+' or '-'.  No action taken.");
3521             return;
3522         }
3523         unless (defined $start && defined $end) {
3524             Carp::my_carp_bug("$owner_name_of{$addr}Undefined start and/or end to _add_delete.  No action taken.");
3525             return;
3526         }
3527         unless ($end >= $start) {
3528             Carp::my_carp_bug("$owner_name_of{$addr}End of range (" . sprintf("%04X", $end) . ") must not be before start (" . sprintf("%04X", $start) . ").  No action taken.");
3529             return;
3530         }
3531         if ($end > $MAX_UNICODE_CODEPOINT && $operation eq '+') {
3532             Carp::my_carp("$owner_name_of{$addr}Warning: Range '" . sprintf("%04X..%04X", $start, $end) . ") is above the Unicode maximum of " . sprintf("%04X", $MAX_UNICODE_CODEPOINT) . ".  Adding it anyway");
3533         }
3534         #local $to_trace = 1 if main::DEBUG;
3535
3536         if ($operation eq '-') {
3537             if ($replace != $IF_NOT_EQUIVALENT) {
3538                 Carp::my_carp_bug("$owner_name_of{$addr}Replace => \$IF_NOT_EQUIVALENT is required when deleting a range from a range list.  Assuming Replace => \$IF_NOT_EQUIVALENT.");
3539                 $replace = $IF_NOT_EQUIVALENT;
3540             }
3541             if ($type) {
3542                 Carp::my_carp_bug("$owner_name_of{$addr}Type => 0 is required when deleting a range from a range list.  Assuming Type => 0.");
3543                 $type = 0;
3544             }
3545             if ($value ne "") {
3546                 Carp::my_carp_bug("$owner_name_of{$addr}Value => \"\" is required when deleting a range from a range list.  Assuming Value => \"\".");
3547                 $value = "";
3548             }
3549         }
3550
3551         my $r = $ranges{$addr};               # The current list of ranges
3552         my $range_list_size = scalar @$r;     # And its size
3553         my $max = $max{$addr};                # The current high code point in
3554                                               # the list of ranges
3555
3556         # Do a special case requiring fewer machine cycles when the new range
3557         # starts after the current highest point.  The Unicode input data is
3558         # structured so this is common.
3559         if ($start > $max) {
3560
3561             trace "$owner_name_of{$addr} $operation", sprintf("%04X..%04X (%s) type=%d; prev max=%04X", $start, $end, $value, $type, $max) if main::DEBUG && $to_trace;
3562             return if $operation eq '-'; # Deleting a non-existing range is a
3563                                          # no-op
3564
3565             # If the new range doesn't logically extend the current final one
3566             # in the range list, create a new range at the end of the range
3567             # list.  (max cleverly is initialized to a negative number not
3568             # adjacent to 0 if the range list is empty, so even adding a range
3569             # to an empty range list starting at 0 will have this 'if'
3570             # succeed.)
3571             if ($start > $max + 1        # non-adjacent means can't extend.
3572                 || @{$r}[-1]->value ne $value # values differ, can't extend.
3573                 || @{$r}[-1]->type != $type # types differ, can't extend.
3574             ) {
3575                 push @$r, Range->new($start, $end,
3576                                      Value => $value,
3577                                      Type => $type);
3578             }
3579             else {
3580
3581                 # Here, the new range starts just after the current highest in
3582                 # the range list, and they have the same type and value.
3583                 # Extend the current range to incorporate the new one.
3584                 @{$r}[-1]->set_end($end);
3585             }
3586
3587             # This becomes the new maximum.
3588             $max{$addr} = $end;
3589
3590             return;
3591         }
3592         #local $to_trace = 0 if main::DEBUG;
3593
3594         trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) replace=$replace" if main::DEBUG && $to_trace;
3595
3596         # Here, the input range isn't after the whole rest of the range list.
3597         # Most likely 'splice' will be needed.  The rest of the routine finds
3598         # the needed splice parameters, and if necessary, does the splice.
3599         # First, find the offset parameter needed by the splice function for
3600         # the input range.  Note that the input range may span multiple
3601         # existing ones, but we'll worry about that later.  For now, just find
3602         # the beginning.  If the input range is to be inserted starting in a
3603         # position not currently in the range list, it must (obviously) come
3604         # just after the range below it, and just before the range above it.
3605         # Slightly less obviously, it will occupy the position currently
3606         # occupied by the range that is to come after it.  More formally, we
3607         # are looking for the position, $i, in the array of ranges, such that:
3608         #
3609         # r[$i-1]->start <= r[$i-1]->end < $start < r[$i]->start <= r[$i]->end
3610         #
3611         # (The ordered relationships within existing ranges are also shown in
3612         # the equation above).  However, if the start of the input range is
3613         # within an existing range, the splice offset should point to that
3614         # existing range's position in the list; that is $i satisfies a
3615         # somewhat different equation, namely:
3616         #
3617         #r[$i-1]->start <= r[$i-1]->end < r[$i]->start <= $start <= r[$i]->end
3618         #
3619         # More briefly, $start can come before or after r[$i]->start, and at
3620         # this point, we don't know which it will be.  However, these
3621         # two equations share these constraints:
3622         #
3623         #   r[$i-1]->end < $start <= r[$i]->end
3624         #
3625         # And that is good enough to find $i.
3626
3627         my $i = $self->_search_ranges($start);
3628         if (! defined $i) {
3629             Carp::my_carp_bug("Searching $self for range beginning with $start unexpectedly returned undefined.  Operation '$operation' not performed");
3630             return;
3631         }
3632
3633         # The search function returns $i such that:
3634         #
3635         # r[$i-1]->end < $start <= r[$i]->end
3636         #
3637         # That means that $i points to the first range in the range list
3638         # that could possibly be affected by this operation.  We still don't
3639         # know if the start of the input range is within r[$i], or if it
3640         # points to empty space between r[$i-1] and r[$i].
3641         trace "[$i] is the beginning splice point.  Existing range there is ", $r->[$i] if main::DEBUG && $to_trace;
3642
3643         # Special case the insertion of data that is not to replace any
3644         # existing data.
3645         if ($replace == $NO) {  # If $NO, has to be operation '+'
3646             #local $to_trace = 1 if main::DEBUG;
3647             trace "Doesn't replace" if main::DEBUG && $to_trace;
3648
3649             # Here, the new range is to take effect only on those code points
3650             # that aren't already in an existing range.  This can be done by
3651             # looking through the existing range list and finding the gaps in
3652             # the ranges that this new range affects, and then calling this
3653             # function recursively on each of those gaps, leaving untouched
3654             # anything already in the list.  Gather up a list of the changed
3655             # gaps first so that changes to the internal state as new ranges
3656             # are added won't be a problem.
3657             my @gap_list;
3658
3659             # First, if the starting point of the input range is outside an
3660             # existing one, there is a gap from there to the beginning of the
3661             # existing range -- add a span to fill the part that this new
3662             # range occupies
3663             if ($start < $r->[$i]->start) {
3664                 push @gap_list, Range->new($start,
3665                                            main::min($end,
3666                                                      $r->[$i]->start - 1),
3667                                            Type => $type);
3668                 trace "gap before $r->[$i] [$i], will add", $gap_list[-1] if main::DEBUG && $to_trace;
3669             }
3670
3671             # Then look through the range list for other gaps until we reach
3672             # the highest range affected by the input one.
3673             my $j;
3674             for ($j = $i+1; $j < $range_list_size; $j++) {
3675                 trace "j=[$j]", $r->[$j] if main::DEBUG && $to_trace;
3676                 last if $end < $r->[$j]->start;
3677
3678                 # If there is a gap between when this range starts and the
3679                 # previous one ends, add a span to fill it.  Note that just
3680                 # because there are two ranges doesn't mean there is a
3681                 # non-zero gap between them.  It could be that they have
3682                 # different values or types
3683                 if ($r->[$j-1]->end + 1 != $r->[$j]->start) {
3684                     push @gap_list,
3685                         Range->new($r->[$j-1]->end + 1,
3686                                    $r->[$j]->start - 1,
3687                                    Type => $type);
3688                     trace "gap between $r->[$j-1] and $r->[$j] [$j], will add: $gap_list[-1]" if main::DEBUG && $to_trace;
3689                 }
3690             }
3691
3692             # Here, we have either found an existing range in the range list,
3693             # beyond the area affected by the input one, or we fell off the
3694             # end of the loop because the input range affects the whole rest
3695             # of the range list.  In either case, $j is 1 higher than the
3696             # highest affected range.  If $j == $i, it means that there are no
3697             # affected ranges, that the entire insertion is in the gap between
3698             # r[$i-1], and r[$i], which we already have taken care of before
3699             # the loop.
3700             # On the other hand, if there are affected ranges, it might be
3701             # that there is a gap that needs filling after the final such
3702             # range to the end of the input range
3703             if ($r->[$j-1]->end < $end) {
3704                     push @gap_list, Range->new(main::max($start,
3705                                                          $r->[$j-1]->end + 1),
3706                                                $end,
3707                                                Type => $type);
3708                     trace "gap after $r->[$j-1], will add $gap_list[-1]" if main::DEBUG && $to_trace;
3709             }
3710
3711             # Call recursively to fill in all the gaps.
3712             foreach my $gap (@gap_list) {
3713                 $self->_add_delete($operation,
3714                                    $gap->start,
3715                                    $gap->end,
3716                                    $value,
3717                                    Type => $type);
3718             }
3719
3720             return;
3721         }
3722
3723         # Here, we have taken care of the case where $replace is $NO.
3724         # Remember that here, r[$i-1]->end < $start <= r[$i]->end
3725         # If inserting a multiple record, this is where it goes, before the
3726         # first (if any) existing one if inserting LIFO.  (If this is to go
3727         # afterwards, FIFO, we below move the pointer to there.)  These imply
3728         # an insertion, and no change to any existing ranges.  Note that $i
3729         # can be -1 if this new range doesn't actually duplicate any existing,
3730         # and comes at the beginning of the list.
3731         if ($replace == $MULTIPLE_BEFORE || $replace == $MULTIPLE_AFTER) {
3732
3733             if ($start != $end) {
3734                 Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the range ($start..$end) contains more than one code point.  No action taken.");
3735                 return;
3736             }
3737
3738             # If the new code point is within a current range ...
3739             if ($end >= $r->[$i]->start) {
3740
3741                 # Don't add an exact duplicate, as it isn't really a multiple
3742                 my $existing_value = $r->[$i]->value;
3743                 my $existing_type = $r->[$i]->type;
3744                 return if $value eq $existing_value && $type eq $existing_type;
3745
3746                 # If the multiple value is part of an existing range, we want
3747                 # to split up that range, so that only the single code point
3748                 # is affected.  To do this, we first call ourselves
3749                 # recursively to delete that code point from the table, having
3750                 # preserved its current data above.  Then we call ourselves
3751                 # recursively again to add the new multiple, which we know by
3752                 # the test just above is different than the current code
3753                 # point's value, so it will become a range containing a single
3754                 # code point: just itself.  Finally, we add back in the
3755                 # pre-existing code point, which will again be a single code
3756                 # point range.  Because 'i' likely will have changed as a
3757                 # result of these operations, we can't just continue on, but
3758                 # do this operation recursively as well.  If we are inserting
3759                 # LIFO, the pre-existing code point needs to go after the new
3760                 # one, so use MULTIPLE_AFTER; and vice versa.
3761                 if ($r->[$i]->start != $r->[$i]->end) {
3762                     $self->_add_delete('-', $start, $end, "");
3763                     $self->_add_delete('+', $start, $end, $value, Type => $type);
3764                     return $self->_add_delete('+',
3765                             $start, $end,
3766                             $existing_value,
3767                             Type => $existing_type,
3768                             Replace => ($replace == $MULTIPLE_BEFORE)
3769                                        ? $MULTIPLE_AFTER
3770                                        : $MULTIPLE_BEFORE);
3771                 }
3772             }
3773
3774             # If to place this new record after, move to beyond all existing
3775             # ones; but don't add this one if identical to any of them, as it
3776             # isn't really a multiple.  This leaves the original order, so
3777             # that the current request is ignored.  The reasoning is that the
3778             # previous request that wanted this record to have high priority
3779             # should have precedence.
3780             if ($replace == $MULTIPLE_AFTER) {
3781                 while ($i < @$r && $r->[$i]->start == $start) {
3782                     return if $value eq $r->[$i]->value
3783                               && $type eq $r->[$i]->type;
3784                     $i++;
3785                 }
3786             }
3787             else {
3788                 # If instead we are to place this new record before any
3789                 # existing ones, remove any identical ones that come after it.
3790                 # This changes the existing order so that the new one is
3791                 # first, as is being requested.
3792                 for (my $j = $i + 1;
3793                      $j < @$r && $r->[$j]->start == $start;
3794                      $j++)
3795                 {
3796                     if ($value eq $r->[$j]->value && $type eq $r->[$j]->type) {
3797                         splice @$r, $j, 1;
3798                         last;   # There should only be one instance, so no
3799                                 # need to keep looking
3800                     }
3801                 }
3802             }
3803
3804             trace "Adding multiple record at $i with $start..$end, $value" if main::DEBUG && $to_trace;
3805             my @return = splice @$r,
3806                                 $i,
3807                                 0,
3808                                 Range->new($start,
3809                                            $end,
3810                                            Value => $value,
3811                                            Type => $type);
3812             if (main::DEBUG && $to_trace) {
3813                 trace "After splice:";
3814                 trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3815                 trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3816                 trace "i  =[", $i, "]", $r->[$i] if $i >= 0;
3817                 trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3818                 trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3819                 trace 'i+3=[', $i+3, ']', $r->[$i+3] if $i < @$r - 3;
3820             }
3821             return @return;
3822         }
3823
3824         # Here, we have taken care of $NO and $MULTIPLE_foo replaces.  This
3825         # leaves delete, insert, and replace either unconditionally or if not
3826         # equivalent.  $i still points to the first potential affected range.
3827         # Now find the highest range affected, which will determine the length
3828         # parameter to splice.  (The input range can span multiple existing
3829         # ones.)  If this isn't a deletion, while we are looking through the
3830         # range list, see also if this is a replacement rather than a clean
3831         # insertion; that is if it will change the values of at least one
3832         # existing range.  Start off assuming it is an insert, until find it
3833         # isn't.
3834         my $clean_insert = $operation eq '+';
3835         my $j;        # This will point to the highest affected range
3836
3837         # For non-zero types, the standard form is the value itself;
3838         my $standard_form = ($type) ? $value : main::standardize($value);
3839
3840         for ($j = $i; $j < $range_list_size; $j++) {
3841             trace "Looking for highest affected range; the one at $j is ", $r->[$j] if main::DEBUG && $to_trace;
3842
3843             # If find a range that it doesn't overlap into, we can stop
3844             # searching
3845             last if $end < $r->[$j]->start;
3846
3847             # Here, overlaps the range at $j.  If the values don't match,
3848             # and so far we think this is a clean insertion, it becomes a
3849             # non-clean insertion, i.e., a 'change' or 'replace' instead.
3850             if ($clean_insert) {
3851                 if ($r->[$j]->standard_form ne $standard_form) {
3852                     $clean_insert = 0;
3853                     if ($replace == $CROAK) {
3854                         main::croak("The range to add "
3855                         . sprintf("%04X", $start)
3856                         . '-'
3857                         . sprintf("%04X", $end)
3858                         . " with value '$value' overlaps an existing range $r->[$j]");
3859                     }
3860                 }
3861                 else {
3862
3863                     # Here, the two values are essentially the same.  If the
3864                     # two are actually identical, replacing wouldn't change
3865                     # anything so skip it.
3866                     my $pre_existing = $r->[$j]->value;
3867                     if ($pre_existing ne $value) {
3868
3869                         # Here the new and old standardized values are the
3870                         # same, but the non-standardized values aren't.  If
3871                         # replacing unconditionally, then replace
3872                         if( $replace == $UNCONDITIONALLY) {
3873                             $clean_insert = 0;
3874                         }
3875                         else {
3876
3877                             # Here, are replacing conditionally.  Decide to
3878                             # replace or not based on which appears to look
3879                             # the "nicest".  If one is mixed case and the
3880                             # other isn't, choose the mixed case one.
3881                             my $new_mixed = $value =~ /[A-Z]/
3882                                             && $value =~ /[a-z]/;
3883                             my $old_mixed = $pre_existing =~ /[A-Z]/
3884                                             && $pre_existing =~ /[a-z]/;
3885
3886                             if ($old_mixed != $new_mixed) {
3887                                 $clean_insert = 0 if $new_mixed;
3888                                 if (main::DEBUG && $to_trace) {
3889                                     if ($clean_insert) {
3890                                         trace "Retaining $pre_existing over $value";
3891                                     }
3892                                     else {
3893                                         trace "Replacing $pre_existing with $value";
3894                                     }
3895                                 }
3896                             }
3897                             else {
3898
3899                                 # Here casing wasn't different between the two.
3900                                 # If one has hyphens or underscores and the
3901                                 # other doesn't, choose the one with the
3902                                 # punctuation.
3903                                 my $new_punct = $value =~ /[-_]/;
3904                                 my $old_punct = $pre_existing =~ /[-_]/;
3905
3906                                 if ($old_punct != $new_punct) {
3907                                     $clean_insert = 0 if $new_punct;
3908                                     if (main::DEBUG && $to_trace) {
3909                                         if ($clean_insert) {
3910                                             trace "Retaining $pre_existing over $value";
3911                                         }
3912                                         else {
3913                                             trace "Replacing $pre_existing with $value";
3914                                         }
3915                                     }
3916                                 }   # else existing one is just as "good";
3917                                     # retain it to save cycles.
3918                             }
3919                         }
3920                     }
3921                 }
3922             }
3923         } # End of loop looking for highest affected range.
3924
3925         # Here, $j points to one beyond the highest range that this insertion
3926         # affects (hence to beyond the range list if that range is the final
3927         # one in the range list).
3928
3929         # The splice length is all the affected ranges.  Get it before
3930         # subtracting, for efficiency, so we don't have to later add 1.
3931         my $length = $j - $i;
3932
3933         $j--;        # $j now points to the highest affected range.
3934         trace "Final affected range is $j: $r->[$j]" if main::DEBUG && $to_trace;
3935
3936         # Here, have taken care of $NO and $MULTIPLE_foo replaces.
3937         # $j points to the highest affected range.  But it can be < $i or even
3938         # -1.  These happen only if the insertion is entirely in the gap
3939         # between r[$i-1] and r[$i].  Here's why: j < i means that the j loop
3940         # above exited first time through with $end < $r->[$i]->start.  (And
3941         # then we subtracted one from j)  This implies also that $start <
3942         # $r->[$i]->start, but we know from above that $r->[$i-1]->end <
3943         # $start, so the entire input range is in the gap.
3944         if ($j < $i) {
3945
3946             # Here the entire input range is in the gap before $i.
3947
3948             if (main::DEBUG && $to_trace) {
3949                 if ($i) {
3950                     trace "Entire range is between $r->[$i-1] and $r->[$i]";
3951                 }
3952                 else {
3953                     trace "Entire range is before $r->[$i]";
3954                 }
3955             }
3956             return if $operation ne '+'; # Deletion of a non-existent range is
3957                                          # a no-op
3958         }
3959         else {
3960
3961             # Here part of the input range is not in the gap before $i.  Thus,
3962             # there is at least one affected one, and $j points to the highest
3963             # such one.
3964