This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
e5dac173743c7b0c9e72db72237731aaa890bf52
[perl5.git] / t / op / die_exit.t
1 #!./perl
2
3 #
4 # Verify that C<die> return the return code
5 #       -- Robin Barker 
6 #
7
8 BEGIN {
9     chdir 't' if -d 't';
10     @INC = '../lib';
11     require './test.pl';
12 }
13
14 use strict;
15
16 skip_all('broken on MPE/iX') if $^O eq 'mpeix';
17
18 $| = 1;
19
20
21 my %tests = (
22          1 => [   0,   0],
23          2 => [   0,   1], 
24          3 => [   0, 127], 
25          4 => [   0, 128], 
26          5 => [   0, 255], 
27          6 => [   0, 256], 
28          7 => [   0, 512], 
29          8 => [   1,   0],
30          9 => [   1,   1],
31         10 => [   1, 256],
32         11 => [ 128,   0],
33         12 => [ 128,   1],
34         13 => [ 128, 256],
35         14 => [ 255,   0],
36         15 => [ 255,   1],
37         16 => [ 255, 256],
38         # see if implicit close preserves $?
39         17 => [  0,  512, '{ local *F; open F, q[TEST]; close F; $!=0 } die;'],
40 );
41
42 my $max = keys %tests;
43
44 my $vms_exit_mode = 0;
45
46 if ($^O eq 'VMS') {
47     if (eval 'require VMS::Feature') {
48         $vms_exit_mode = !(VMS::Feature::current("posix_exit"));
49     } else {
50         my $env_unix_rpt = $ENV{'DECC$FILENAME_UNIX_REPORT'} || '';
51         my $env_posix_ex = $ENV{'PERL_VMS_POSIX_EXIT'} || '';
52         my $unix_rpt = $env_unix_rpt =~ /^[ET1]/i; 
53         my $posix_ex = $env_posix_ex =~ /^[ET1]/i;
54         if (($unix_rpt || $posix_ex) ) {
55             $vms_exit_mode = 0;
56         } else {
57             $vms_exit_mode = 1;
58         }
59     }
60 }
61
62 plan(tests => $max);
63
64 # Dump any error messages from the dying processes off to a temp file.
65 my $tempfile = tempfile();
66 open STDERR, '>', $tempfile or die "Can't open temp error file $tempfile:  $!";
67
68 foreach my $test (1 .. $max) {
69     my($bang, $query, $code) = @{$tests{$test}};
70     $code ||= 'die;';
71     if ($^O eq 'MSWin32' || $^O eq 'NetWare' || $^O eq 'VMS') {
72         system(qq{$^X -e "\$! = $bang; \$? = $query; $code"});
73     }
74     else {
75         system(qq{$^X -e '\$! = $bang; \$? = $query; $code'});
76     }
77     my $exit = $?;
78
79     # The legacy VMS exit code 44 (SS$_ABORT) is returned if a program dies.
80     # We only get the severity bits, which boils down to 4.  See L<perlvms/$?>.
81     $bang = 4 if $vms_exit_mode;
82
83     is($exit, (($bang || ($query >> 8) || 255) << 8),
84        sprintf "exit = 0x%04x bang = 0x%04x query = 0x%04x", $exit, $bang, $query);
85 }
86
87 close STDERR;
88