This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
POD typo in perlfunc
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments 
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate literal elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use parentheses, the simple but occasionally 
34 surprising rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  Whitespace
37 between the function and left parenthesis doesn't count, so sometimes
38 you need to be careful:
39
40     print 1+2+4;      # Prints 7.
41     print(1+2) + 4;   # Prints 3.
42     print (1+2)+4;    # Also prints 3!
43     print +(1+2)+4;   # Prints 7.
44     print ((1+2)+4);  # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in scalar context by
59 returning the undefined value, and in list context by returning the
60 empty list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls ("syscalls")
82 of the same name (like chown(2), fork(2), closedir(2), etc.) return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule include C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 Extension modules can also hook into the Perl parser to define new
90 kinds of keyword-headed expression.  These may look like functions, but
91 may also look completely different.  The syntax following the keyword
92 is defined entirely by the extension.  If you are an implementor, see
93 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
94 a module, see the module's documentation for details of the syntax that
95 it defines.
96
97 =head2 Perl Functions by Category
98 X<function>
99
100 Here are Perl's functions (including things that look like
101 functions, like some keywords and named operators)
102 arranged by category.  Some functions appear in more
103 than one place.
104
105 =over 4
106
107 =item Functions for SCALARs or strings
108 X<scalar> X<string> X<character>
109
110 =for Pod::Functions =String
111
112 C<chomp>, C<chop>, C<chr>, C<crypt>, C<fc>, C<hex>, C<index>, C<lc>,
113 C<lcfirst>, C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
114 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
115
116 C<fc> is available only if the C<"fc"> feature is enabled or if it is
117 prefixed with C<CORE::>.  The C<"fc"> feature is enabled automatically
118 with a C<use v5.16> (or higher) declaration in the current scope.
119
120
121 =item Regular expressions and pattern matching
122 X<regular expression> X<regex> X<regexp>
123
124 =for Pod::Functions =Regexp
125
126 C<m//>, C<pos>, C<qr//>, C<quotemeta>, C<s///>, C<split>, C<study>
127
128 =item Numeric functions
129 X<numeric> X<number> X<trigonometric> X<trigonometry>
130
131 =for Pod::Functions =Math
132
133 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
134 C<sin>, C<sqrt>, C<srand>
135
136 =item Functions for real @ARRAYs
137 X<array>
138
139 =for Pod::Functions =ARRAY
140
141 C<each>, C<keys>, C<pop>, C<push>, C<shift>, C<splice>, C<unshift>, C<values>
142
143 =item Functions for list data
144 X<list>
145
146 =for Pod::Functions =LIST
147
148 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
149
150 =item Functions for real %HASHes
151 X<hash>
152
153 =for Pod::Functions =HASH
154
155 C<delete>, C<each>, C<exists>, C<keys>, C<values>
156
157 =item Input and output functions
158 X<I/O> X<input> X<output> X<dbm>
159
160 =for Pod::Functions =I/O
161
162 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
163 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
164 C<readdir>, C<readline> C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>,
165 C<syscall>, C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>,
166 C<truncate>, C<warn>, C<write>
167
168 C<say> is available only if the C<"say"> feature is enabled or if it is
169 prefixed with C<CORE::>.  The C<"say"> feature is enabled automatically
170 with a C<use v5.10> (or higher) declaration in the current scope.
171
172 =item Functions for fixed-length data or records
173
174 =for Pod::Functions =Binary
175
176 C<pack>, C<read>, C<syscall>, C<sysread>, C<sysseek>, C<syswrite>, C<unpack>,
177 C<vec>
178
179 =item Functions for filehandles, files, or directories
180 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
181
182 =for Pod::Functions =File
183
184 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
185 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
186 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
187 C<umask>, C<unlink>, C<utime>
188
189 =item Keywords related to the control flow of your Perl program
190 X<control flow>
191
192 =for Pod::Functions =Flow
193
194 C<break>, C<caller>, C<continue>, C<die>, C<do>,
195 C<dump>, C<eval>, C<evalbytes> C<exit>,
196 C<__FILE__>, C<goto>, C<last>, C<__LINE__>, C<next>, C<__PACKAGE__>,
197 C<redo>, C<return>, C<sub>, C<__SUB__>, C<wantarray>
198
199 C<break> is available only if you enable the experimental C<"switch">
200 feature or use the C<CORE::> prefix. The C<"switch"> feature also enables
201 the C<default>, C<given> and C<when> statements, which are documented in
202 L<perlsyn/"Switch Statements">. The C<"switch"> feature is enabled
203 automatically with a C<use v5.10> (or higher) declaration in the current
204 scope. In Perl v5.14 and earlier, C<continue> required the C<"switch">
205 feature, like the other keywords.
206
207 C<evalbytes> is only available with the C<"evalbytes"> feature (see
208 L<feature>) or if prefixed with C<CORE::>.  C<__SUB__> is only available
209 with the C<"current_sub"> feature or if prefixed with C<CORE::>. Both
210 the C<"evalbytes"> and C<"current_sub"> features are enabled automatically
211 with a C<use v5.16> (or higher) declaration in the current scope.
212
213 =item Keywords related to scoping
214
215 =for Pod::Functions =Namespace
216
217 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<state>, C<use>
218
219 C<state> is available only if the C<"state"> feature is enabled or if it is
220 prefixed with C<CORE::>.  The C<"state"> feature is enabled automatically
221 with a C<use v5.10> (or higher) declaration in the current scope.
222
223 =item Miscellaneous functions
224
225 =for Pod::Functions =Misc
226
227 C<defined>, C<formline>, C<lock>, C<prototype>, C<reset>, C<scalar>, C<undef>
228
229 =item Functions for processes and process groups
230 X<process> X<pid> X<process id>
231
232 =for Pod::Functions =Process
233
234 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
235 C<pipe>, C<qx//>, C<readpipe>, C<setpgrp>,
236 C<setpriority>, C<sleep>, C<system>,
237 C<times>, C<wait>, C<waitpid>
238
239 =item Keywords related to Perl modules
240 X<module>
241
242 =for Pod::Functions =Modules
243
244 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
245
246 =item Keywords related to classes and object-orientation
247 X<object> X<class> X<package>
248
249 =for Pod::Functions =Objects
250
251 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
252 C<untie>, C<use>
253
254 =item Low-level socket functions
255 X<socket> X<sock>
256
257 =for Pod::Functions =Socket
258
259 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
260 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
261 C<socket>, C<socketpair>
262
263 =item System V interprocess communication functions
264 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
265
266 =for Pod::Functions =SysV
267
268 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
269 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
270
271 =item Fetching user and group info
272 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
273
274 =for Pod::Functions =User
275
276 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
277 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
278 C<getpwuid>, C<setgrent>, C<setpwent>
279
280 =item Fetching network info
281 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
282
283 =for Pod::Functions =Network
284
285 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
286 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
287 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
288 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
289 C<setnetent>, C<setprotoent>, C<setservent>
290
291 =item Time-related functions
292 X<time> X<date>
293
294 =for Pod::Functions =Time
295
296 C<gmtime>, C<localtime>, C<time>, C<times>
297
298 =item Non-function keywords
299
300 =for Pod::Functions =!Non-functions
301
302 C<and>, C<AUTOLOAD>, C<BEGIN>, C<CHECK>, C<cmp>, C<CORE>, C<__DATA__>,
303 C<default>, C<DESTROY>, C<else>, C<elseif>, C<elsif>, C<END>, C<__END__>,
304 C<eq>, C<for>, C<foreach>, C<ge>, C<given>, C<gt>, C<if>, C<INIT>, C<le>,
305 C<lt>, C<ne>, C<not>, C<or>, C<UNITCHECK>, C<unless>, C<until>, C<when>,
306 C<while>, C<x>, C<xor>
307
308 =back
309
310 =head2 Portability
311 X<portability> X<Unix> X<portable>
312
313 Perl was born in Unix and can therefore access all common Unix
314 system calls.  In non-Unix environments, the functionality of some
315 Unix system calls may not be available or details of the available
316 functionality may differ slightly.  The Perl functions affected
317 by this are:
318
319 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
320 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
321 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
322 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
323 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
324 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
325 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
326 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
327 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
328 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
329 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
330 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
331 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
332 C<shmwrite>, C<socket>, C<socketpair>,
333 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
334 C<times>, C<truncate>, C<umask>, C<unlink>,
335 C<utime>, C<wait>, C<waitpid>
336
337 For more information about the portability of these functions, see
338 L<perlport> and other available platform-specific documentation.
339
340 =head2 Alphabetical Listing of Perl Functions
341
342 =over 
343
344 =item -X FILEHANDLE
345 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
346 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
347
348 =item -X EXPR
349
350 =item -X DIRHANDLE
351
352 =item -X
353
354 =for Pod::Functions a file test (-r, -x, etc)
355
356 A file test, where X is one of the letters listed below.  This unary
357 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
358 and tests the associated file to see if something is true about it.  If the
359 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
360 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
361 the undefined value if the file doesn't exist.  Despite the funny
362 names, precedence is the same as any other named unary operator.  The
363 operator may be any of:
364
365     -r  File is readable by effective uid/gid.
366     -w  File is writable by effective uid/gid.
367     -x  File is executable by effective uid/gid.
368     -o  File is owned by effective uid.
369
370     -R  File is readable by real uid/gid.
371     -W  File is writable by real uid/gid.
372     -X  File is executable by real uid/gid.
373     -O  File is owned by real uid.
374
375     -e  File exists.
376     -z  File has zero size (is empty).
377     -s  File has nonzero size (returns size in bytes).
378
379     -f  File is a plain file.
380     -d  File is a directory.
381     -l  File is a symbolic link.
382     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
383     -S  File is a socket.
384     -b  File is a block special file.
385     -c  File is a character special file.
386     -t  Filehandle is opened to a tty.
387
388     -u  File has setuid bit set.
389     -g  File has setgid bit set.
390     -k  File has sticky bit set.
391
392     -T  File is an ASCII text file (heuristic guess).
393     -B  File is a "binary" file (opposite of -T).
394
395     -M  Script start time minus file modification time, in days.
396     -A  Same for access time.
397     -C  Same for inode change time (Unix, may differ for other
398         platforms)
399
400 Example:
401
402     while (<>) {
403         chomp;
404         next unless -f $_;  # ignore specials
405         #...
406     }
407
408 Note that C<-s/a/b/> does not do a negated substitution.  Saying
409 C<-exp($foo)> still works as expected, however: only single letters
410 following a minus are interpreted as file tests.
411
412 These operators are exempt from the "looks like a function rule" described
413 above.  That is, an opening parenthesis after the operator does not affect
414 how much of the following code constitutes the argument.  Put the opening
415 parentheses before the operator to separate it from code that follows (this
416 applies only to operators with higher precedence than unary operators, of
417 course):
418
419     -s($file) + 1024   # probably wrong; same as -s($file + 1024)
420     (-s $file) + 1024  # correct
421
422 The interpretation of the file permission operators C<-r>, C<-R>,
423 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
424 of the file and the uids and gids of the user.  There may be other
425 reasons you can't actually read, write, or execute the file: for
426 example network filesystem access controls, ACLs (access control lists),
427 read-only filesystems, and unrecognized executable formats.  Note
428 that the use of these six specific operators to verify if some operation
429 is possible is usually a mistake, because it may be open to race
430 conditions.
431
432 Also note that, for the superuser on the local filesystems, the C<-r>,
433 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
434 if any execute bit is set in the mode.  Scripts run by the superuser
435 may thus need to do a stat() to determine the actual mode of the file,
436 or temporarily set their effective uid to something else.
437
438 If you are using ACLs, there is a pragma called C<filetest> that may
439 produce more accurate results than the bare stat() mode bits.
440 When under C<use filetest 'access'> the above-mentioned filetests
441 test whether the permission can(not) be granted using the
442 access(2) family of system calls.  Also note that the C<-x> and C<-X> may
443 under this pragma return true even if there are no execute permission
444 bits set (nor any extra execute permission ACLs).  This strangeness is
445 due to the underlying system calls' definitions.  Note also that, due to
446 the implementation of C<use filetest 'access'>, the C<_> special
447 filehandle won't cache the results of the file tests when this pragma is
448 in effect.  Read the documentation for the C<filetest> pragma for more
449 information.
450
451 The C<-T> and C<-B> switches work as follows.  The first block or so of the
452 file is examined for odd characters such as strange control codes or
453 characters with the high bit set.  If too many strange characters (>30%)
454 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
455 containing a zero byte in the first block is considered a binary file.  If C<-T>
456 or C<-B> is used on a filehandle, the current IO buffer is examined
457 rather than the first block.  Both C<-T> and C<-B> return true on an empty
458 file, or a file at EOF when testing a filehandle.  Because you have to
459 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
460 against the file first, as in C<next unless -f $file && -T $file>.
461
462 If any of the file tests (or either the C<stat> or C<lstat> operator) is given
463 the special filehandle consisting of a solitary underline, then the stat
464 structure of the previous file test (or stat operator) is used, saving
465 a system call.  (This doesn't work with C<-t>, and you need to remember
466 that lstat() and C<-l> leave values in the stat structure for the
467 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
468 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
469 Example:
470
471     print "Can do.\n" if -r $a || -w _ || -x _;
472
473     stat($filename);
474     print "Readable\n" if -r _;
475     print "Writable\n" if -w _;
476     print "Executable\n" if -x _;
477     print "Setuid\n" if -u _;
478     print "Setgid\n" if -g _;
479     print "Sticky\n" if -k _;
480     print "Text\n" if -T _;
481     print "Binary\n" if -B _;
482
483 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
484 test operators, in a way that C<-f -w -x $file> is equivalent to
485 C<-x $file && -w _ && -f _>.  (This is only fancy fancy: if you use
486 the return value of C<-f $file> as an argument to another filetest
487 operator, no special magic will happen.)
488
489 Portability issues: L<perlport/-X>.
490
491 To avoid confusing would-be users of your code with mysterious
492 syntax errors, put something like this at the top of your script:
493
494     use 5.010;  # so filetest ops can stack
495
496 =item abs VALUE
497 X<abs> X<absolute>
498
499 =item abs
500
501 =for Pod::Functions absolute value function
502
503 Returns the absolute value of its argument.
504 If VALUE is omitted, uses C<$_>.
505
506 =item accept NEWSOCKET,GENERICSOCKET
507 X<accept>
508
509 =for Pod::Functions accept an incoming socket connect
510
511 Accepts an incoming socket connect, just as accept(2) 
512 does.  Returns the packed address if it succeeded, false otherwise.
513 See the example in L<perlipc/"Sockets: Client/Server Communication">.
514
515 On systems that support a close-on-exec flag on files, the flag will
516 be set for the newly opened file descriptor, as determined by the
517 value of $^F.  See L<perlvar/$^F>.
518
519 =item alarm SECONDS
520 X<alarm>
521 X<SIGALRM>
522 X<timer>
523
524 =item alarm
525
526 =for Pod::Functions schedule a SIGALRM
527
528 Arranges to have a SIGALRM delivered to this process after the
529 specified number of wallclock seconds has elapsed.  If SECONDS is not
530 specified, the value stored in C<$_> is used.  (On some machines,
531 unfortunately, the elapsed time may be up to one second less or more
532 than you specified because of how seconds are counted, and process
533 scheduling may delay the delivery of the signal even further.)
534
535 Only one timer may be counting at once.  Each call disables the
536 previous timer, and an argument of C<0> may be supplied to cancel the
537 previous timer without starting a new one.  The returned value is the
538 amount of time remaining on the previous timer.
539
540 For delays of finer granularity than one second, the Time::HiRes module
541 (from CPAN, and starting from Perl 5.8 part of the standard
542 distribution) provides ualarm().  You may also use Perl's four-argument
543 version of select() leaving the first three arguments undefined, or you
544 might be able to use the C<syscall> interface to access setitimer(2) if
545 your system supports it.  See L<perlfaq8> for details.
546
547 It is usually a mistake to intermix C<alarm> and C<sleep> calls, because
548 C<sleep> may be internally implemented on your system with C<alarm>.
549
550 If you want to use C<alarm> to time out a system call you need to use an
551 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
552 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
553 restart system calls on some systems.  Using C<eval>/C<die> always works,
554 modulo the caveats given in L<perlipc/"Signals">.
555
556     eval {
557         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
558         alarm $timeout;
559         $nread = sysread SOCKET, $buffer, $size;
560         alarm 0;
561     };
562     if ($@) {
563         die unless $@ eq "alarm\n";   # propagate unexpected errors
564         # timed out
565     }
566     else {
567         # didn't
568     }
569
570 For more information see L<perlipc>.
571
572 Portability issues: L<perlport/alarm>.
573
574 =item atan2 Y,X
575 X<atan2> X<arctangent> X<tan> X<tangent>
576
577 =for Pod::Functions arctangent of Y/X in the range -PI to PI
578
579 Returns the arctangent of Y/X in the range -PI to PI.
580
581 For the tangent operation, you may use the C<Math::Trig::tan>
582 function, or use the familiar relation:
583
584     sub tan { sin($_[0]) / cos($_[0])  }
585
586 The return value for C<atan2(0,0)> is implementation-defined; consult
587 your atan2(3) manpage for more information.
588
589 Portability issues: L<perlport/atan2>.
590
591 =item bind SOCKET,NAME
592 X<bind>
593
594 =for Pod::Functions binds an address to a socket
595
596 Binds a network address to a socket, just as bind(2)
597 does.  Returns true if it succeeded, false otherwise.  NAME should be a
598 packed address of the appropriate type for the socket.  See the examples in
599 L<perlipc/"Sockets: Client/Server Communication">.
600
601 =item binmode FILEHANDLE, LAYER
602 X<binmode> X<binary> X<text> X<DOS> X<Windows>
603
604 =item binmode FILEHANDLE
605
606 =for Pod::Functions prepare binary files for I/O
607
608 Arranges for FILEHANDLE to be read or written in "binary" or "text"
609 mode on systems where the run-time libraries distinguish between
610 binary and text files.  If FILEHANDLE is an expression, the value is
611 taken as the name of the filehandle.  Returns true on success,
612 otherwise it returns C<undef> and sets C<$!> (errno).
613
614 On some systems (in general, DOS- and Windows-based systems) binmode()
615 is necessary when you're not working with a text file.  For the sake
616 of portability it is a good idea always to use it when appropriate,
617 and never to use it when it isn't appropriate.  Also, people can
618 set their I/O to be by default UTF8-encoded Unicode, not bytes.
619
620 In other words: regardless of platform, use binmode() on binary data,
621 like images, for example.
622
623 If LAYER is present it is a single string, but may contain multiple
624 directives.  The directives alter the behaviour of the filehandle.
625 When LAYER is present, using binmode on a text file makes sense.
626
627 If LAYER is omitted or specified as C<:raw> the filehandle is made
628 suitable for passing binary data.  This includes turning off possible CRLF
629 translation and marking it as bytes (as opposed to Unicode characters).
630 Note that, despite what may be implied in I<"Programming Perl"> (the
631 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
632 Other layers that would affect the binary nature of the stream are
633 I<also> disabled.  See L<PerlIO>, L<perlrun>, and the discussion about the
634 PERLIO environment variable.
635
636 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
637 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
638 establish default I/O layers.  See L<open>.
639
640 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
641 in "Programming Perl, 3rd Edition".  However, since the publishing of this
642 book, by many known as "Camel III", the consensus of the naming of this
643 functionality has moved from "discipline" to "layer".  All documentation
644 of this version of Perl therefore refers to "layers" rather than to
645 "disciplines".  Now back to the regularly scheduled documentation...>
646
647 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(UTF-8)>.
648 C<:utf8> just marks the data as UTF-8 without further checking,
649 while C<:encoding(UTF-8)> checks the data for actually being valid
650 UTF-8.  More details can be found in L<PerlIO::encoding>.
651
652 In general, binmode() should be called after open() but before any I/O
653 is done on the filehandle.  Calling binmode() normally flushes any
654 pending buffered output data (and perhaps pending input data) on the
655 handle.  An exception to this is the C<:encoding> layer that
656 changes the default character encoding of the handle; see L</open>.
657 The C<:encoding> layer sometimes needs to be called in
658 mid-stream, and it doesn't flush the stream.  The C<:encoding>
659 also implicitly pushes on top of itself the C<:utf8> layer because
660 internally Perl operates on UTF8-encoded Unicode characters.
661
662 The operating system, device drivers, C libraries, and Perl run-time
663 system all conspire to let the programmer treat a single
664 character (C<\n>) as the line terminator, irrespective of external
665 representation.  On many operating systems, the native text file
666 representation matches the internal representation, but on some
667 platforms the external representation of C<\n> is made up of more than
668 one character.
669
670 All variants of Unix, Mac OS (old and new), and Stream_LF files on VMS use
671 a single character to end each line in the external representation of text
672 (even though that single character is CARRIAGE RETURN on old, pre-Darwin
673 flavors of Mac OS, and is LINE FEED on Unix and most VMS files).  In other
674 systems like OS/2, DOS, and the various flavors of MS-Windows, your program
675 sees a C<\n> as a simple C<\cJ>, but what's stored in text files are the
676 two characters C<\cM\cJ>.  That means that if you don't use binmode() on
677 these systems, C<\cM\cJ> sequences on disk will be converted to C<\n> on
678 input, and any C<\n> in your program will be converted back to C<\cM\cJ> on
679 output.  This is what you want for text files, but it can be disastrous for
680 binary files.
681
682 Another consequence of using binmode() (on some systems) is that
683 special end-of-file markers will be seen as part of the data stream.
684 For systems from the Microsoft family this means that, if your binary
685 data contain C<\cZ>, the I/O subsystem will regard it as the end of
686 the file, unless you use binmode().
687
688 binmode() is important not only for readline() and print() operations,
689 but also when using read(), seek(), sysread(), syswrite() and tell()
690 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
691 in L<perlvar> for how to manually set your input and output
692 line-termination sequences.
693
694 Portability issues: L<perlport/binmode>.
695
696 =item bless REF,CLASSNAME
697 X<bless>
698
699 =item bless REF
700
701 =for Pod::Functions create an object
702
703 This function tells the thingy referenced by REF that it is now an object
704 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
705 is used.  Because a C<bless> is often the last thing in a constructor,
706 it returns the reference for convenience.  Always use the two-argument
707 version if a derived class might inherit the function doing the blessing.
708 See L<perlobj> for more about the blessing (and blessings) of objects.
709
710 Consider always blessing objects in CLASSNAMEs that are mixed case.
711 Namespaces with all lowercase names are considered reserved for
712 Perl pragmata.  Builtin types have all uppercase names.  To prevent
713 confusion, you may wish to avoid such package names as well.  Make sure
714 that CLASSNAME is a true value.
715
716 See L<perlmod/"Perl Modules">.
717
718 =item break
719
720 =for Pod::Functions +switch break out of a C<given> block
721
722 Break out of a C<given()> block.
723
724 This keyword is enabled by the C<"switch"> feature: see
725 L<feature> for more information.  You can also access it by
726 prefixing it with C<CORE::>.  Alternately, include a C<use
727 v5.10> or later to the current scope.
728
729 =item caller EXPR
730 X<caller> X<call stack> X<stack> X<stack trace>
731
732 =item caller
733
734 =for Pod::Functions get context of the current subroutine call
735
736 Returns the context of the current subroutine call.  In scalar context,
737 returns the caller's package name if there I<is> a caller (that is, if
738 we're in a subroutine or C<eval> or C<require>) and the undefined value
739 otherwise.  In list context, returns
740
741     # 0         1          2
742     ($package, $filename, $line) = caller;
743
744 With EXPR, it returns some extra information that the debugger uses to
745 print a stack trace.  The value of EXPR indicates how many call frames
746 to go back before the current one.
747
748     #  0         1          2      3            4
749     ($package, $filename, $line, $subroutine, $hasargs,
750
751     #  5          6          7            8       9         10
752     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
753      = caller($i);
754
755 Here $subroutine may be C<(eval)> if the frame is not a subroutine
756 call, but an C<eval>.  In such a case additional elements $evaltext and
757 C<$is_require> are set: C<$is_require> is true if the frame is created by a
758 C<require> or C<use> statement, $evaltext contains the text of the
759 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
760 $subroutine is C<(eval)>, but $evaltext is undefined.  (Note also that
761 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
762 frame.)  $subroutine may also be C<(unknown)> if this particular
763 subroutine happens to have been deleted from the symbol table.
764 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
765 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
766 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
767 between versions of Perl, and are not meant for external use.
768
769 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
770 caller was compiled, or C<undef> if C<%^H> was empty.  Do not modify the values
771 of this hash, as they are the actual values stored in the optree.
772
773 Furthermore, when called from within the DB package in
774 list context, and with an argument, caller returns more
775 detailed information: it sets the list variable C<@DB::args> to be the
776 arguments with which the subroutine was invoked.
777
778 Be aware that the optimizer might have optimized call frames away before
779 C<caller> had a chance to get the information.  That means that C<caller(N)>
780 might not return information about the call frame you expect it to, for
781 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
782 previous time C<caller> was called.
783
784 Be aware that setting C<@DB::args> is I<best effort>, intended for
785 debugging or generating backtraces, and should not be relied upon.  In
786 particular, as C<@_> contains aliases to the caller's arguments, Perl does
787 not take a copy of C<@_>, so C<@DB::args> will contain modifications the
788 subroutine makes to C<@_> or its contents, not the original values at call
789 time.  C<@DB::args>, like C<@_>, does not hold explicit references to its
790 elements, so under certain cases its elements may have become freed and
791 reallocated for other variables or temporary values.  Finally, a side effect
792 of the current implementation is that the effects of C<shift @_> can
793 I<normally> be undone (but not C<pop @_> or other splicing, I<and> not if a
794 reference to C<@_> has been taken, I<and> subject to the caveat about reallocated
795 elements), so C<@DB::args> is actually a hybrid of the current state and
796 initial state of C<@_>.  Buyer beware.
797
798 =item chdir EXPR
799 X<chdir>
800 X<cd>
801 X<directory, change>
802
803 =item chdir FILEHANDLE
804
805 =item chdir DIRHANDLE
806
807 =item chdir
808
809 =for Pod::Functions change your current working directory
810
811 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
812 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
813 changes to the directory specified by C<$ENV{LOGDIR}>.  (Under VMS, the
814 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.)  If
815 neither is set, C<chdir> does nothing.  It returns true on success,
816 false otherwise.  See the example under C<die>.
817
818 On systems that support fchdir(2), you may pass a filehandle or
819 directory handle as the argument.  On systems that don't support fchdir(2),
820 passing handles raises an exception.
821
822 =item chmod LIST
823 X<chmod> X<permission> X<mode>
824
825 =for Pod::Functions changes the permissions on a list of files
826
827 Changes the permissions of a list of files.  The first element of the
828 list must be the numeric mode, which should probably be an octal
829 number, and which definitely should I<not> be a string of octal digits:
830 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
831 successfully changed.  See also L</oct> if all you have is a string.
832
833     $cnt = chmod 0755, "foo", "bar";
834     chmod 0755, @executables;
835     $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
836                                              # --w----r-T
837     $mode = "0644"; chmod oct($mode), "foo"; # this is better
838     $mode = 0644;   chmod $mode, "foo";      # this is best
839
840 On systems that support fchmod(2), you may pass filehandles among the
841 files.  On systems that don't support fchmod(2), passing filehandles raises
842 an exception.  Filehandles must be passed as globs or glob references to be
843 recognized; barewords are considered filenames.
844
845     open(my $fh, "<", "foo");
846     my $perm = (stat $fh)[2] & 07777;
847     chmod($perm | 0600, $fh);
848
849 You can also import the symbolic C<S_I*> constants from the C<Fcntl>
850 module:
851
852     use Fcntl qw( :mode );
853     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
854     # Identical to the chmod 0755 of the example above.
855
856 Portability issues: L<perlport/chmod>.
857
858 =item chomp VARIABLE
859 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
860
861 =item chomp( LIST )
862
863 =item chomp
864
865 =for Pod::Functions remove a trailing record separator from a string
866
867 This safer version of L</chop> removes any trailing string
868 that corresponds to the current value of C<$/> (also known as
869 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
870 number of characters removed from all its arguments.  It's often used to
871 remove the newline from the end of an input record when you're worried
872 that the final record may be missing its newline.  When in paragraph
873 mode (C<$/ = "">), it removes all trailing newlines from the string.
874 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
875 a reference to an integer or the like; see L<perlvar>) chomp() won't
876 remove anything.
877 If VARIABLE is omitted, it chomps C<$_>.  Example:
878
879     while (<>) {
880         chomp;  # avoid \n on last field
881         @array = split(/:/);
882         # ...
883     }
884
885 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
886
887 You can actually chomp anything that's an lvalue, including an assignment:
888
889     chomp($cwd = `pwd`);
890     chomp($answer = <STDIN>);
891
892 If you chomp a list, each element is chomped, and the total number of
893 characters removed is returned.
894
895 Note that parentheses are necessary when you're chomping anything
896 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
897 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
898 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
899 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
900 as C<chomp($a, $b)>.
901
902 =item chop VARIABLE
903 X<chop>
904
905 =item chop( LIST )
906
907 =item chop
908
909 =for Pod::Functions remove the last character from a string
910
911 Chops off the last character of a string and returns the character
912 chopped.  It is much more efficient than C<s/.$//s> because it neither
913 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
914 If VARIABLE is a hash, it chops the hash's values, but not its keys.
915
916 You can actually chop anything that's an lvalue, including an assignment.
917
918 If you chop a list, each element is chopped.  Only the value of the
919 last C<chop> is returned.
920
921 Note that C<chop> returns the last character.  To return all but the last
922 character, use C<substr($string, 0, -1)>.
923
924 See also L</chomp>.
925
926 =item chown LIST
927 X<chown> X<owner> X<user> X<group>
928
929 =for Pod::Functions change the ownership on a list of files
930
931 Changes the owner (and group) of a list of files.  The first two
932 elements of the list must be the I<numeric> uid and gid, in that
933 order.  A value of -1 in either position is interpreted by most
934 systems to leave that value unchanged.  Returns the number of files
935 successfully changed.
936
937     $cnt = chown $uid, $gid, 'foo', 'bar';
938     chown $uid, $gid, @filenames;
939
940 On systems that support fchown(2), you may pass filehandles among the
941 files.  On systems that don't support fchown(2), passing filehandles raises
942 an exception.  Filehandles must be passed as globs or glob references to be
943 recognized; barewords are considered filenames.
944
945 Here's an example that looks up nonnumeric uids in the passwd file:
946
947     print "User: ";
948     chomp($user = <STDIN>);
949     print "Files: ";
950     chomp($pattern = <STDIN>);
951
952     ($login,$pass,$uid,$gid) = getpwnam($user)
953         or die "$user not in passwd file";
954
955     @ary = glob($pattern);  # expand filenames
956     chown $uid, $gid, @ary;
957
958 On most systems, you are not allowed to change the ownership of the
959 file unless you're the superuser, although you should be able to change
960 the group to any of your secondary groups.  On insecure systems, these
961 restrictions may be relaxed, but this is not a portable assumption.
962 On POSIX systems, you can detect this condition this way:
963
964     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
965     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
966
967 Portability issues: L<perlport/chmod>.
968
969 =item chr NUMBER
970 X<chr> X<character> X<ASCII> X<Unicode>
971
972 =item chr
973
974 =for Pod::Functions get character this number represents
975
976 Returns the character represented by that NUMBER in the character set.
977 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
978 chr(0x263a) is a Unicode smiley face.  
979
980 Negative values give the Unicode replacement character (chr(0xfffd)),
981 except under the L<bytes> pragma, where the low eight bits of the value
982 (truncated to an integer) are used.
983
984 If NUMBER is omitted, uses C<$_>.
985
986 For the reverse, use L</ord>.
987
988 Note that characters from 128 to 255 (inclusive) are by default
989 internally not encoded as UTF-8 for backward compatibility reasons.
990
991 See L<perlunicode> for more about Unicode.
992
993 =item chroot FILENAME
994 X<chroot> X<root>
995
996 =item chroot
997
998 =for Pod::Functions make directory new root for path lookups
999
1000 This function works like the system call by the same name: it makes the
1001 named directory the new root directory for all further pathnames that
1002 begin with a C</> by your process and all its children.  (It doesn't
1003 change your current working directory, which is unaffected.)  For security
1004 reasons, this call is restricted to the superuser.  If FILENAME is
1005 omitted, does a C<chroot> to C<$_>.
1006
1007 Portability issues: L<perlport/chroot>.
1008
1009 =item close FILEHANDLE
1010 X<close>
1011
1012 =item close
1013
1014 =for Pod::Functions close file (or pipe or socket) handle
1015
1016 Closes the file or pipe associated with the filehandle, flushes the IO
1017 buffers, and closes the system file descriptor.  Returns true if those
1018 operations succeed and if no error was reported by any PerlIO
1019 layer.  Closes the currently selected filehandle if the argument is
1020 omitted.
1021
1022 You don't have to close FILEHANDLE if you are immediately going to do
1023 another C<open> on it, because C<open> closes it for you.  (See
1024 L<open|/open FILEHANDLE>.)  However, an explicit C<close> on an input file resets the line
1025 counter (C<$.>), while the implicit close done by C<open> does not.
1026
1027 If the filehandle came from a piped open, C<close> returns false if one of
1028 the other syscalls involved fails or if its program exits with non-zero
1029 status.  If the only problem was that the program exited non-zero, C<$!>
1030 will be set to C<0>.  Closing a pipe also waits for the process executing
1031 on the pipe to exit--in case you wish to look at the output of the pipe
1032 afterwards--and implicitly puts the exit status value of that command into
1033 C<$?> and C<${^CHILD_ERROR_NATIVE}>.
1034
1035 If there are multiple threads running, C<close> on a filehandle from a
1036 piped open returns true without waiting for the child process to terminate,
1037 if the filehandle is still open in another thread.
1038
1039 Closing the read end of a pipe before the process writing to it at the
1040 other end is done writing results in the writer receiving a SIGPIPE.  If
1041 the other end can't handle that, be sure to read all the data before
1042 closing the pipe.
1043
1044 Example:
1045
1046     open(OUTPUT, '|sort >foo')  # pipe to sort
1047         or die "Can't start sort: $!";
1048     #...                        # print stuff to output
1049     close OUTPUT                # wait for sort to finish
1050         or warn $! ? "Error closing sort pipe: $!"
1051                    : "Exit status $? from sort";
1052     open(INPUT, 'foo')          # get sort's results
1053         or die "Can't open 'foo' for input: $!";
1054
1055 FILEHANDLE may be an expression whose value can be used as an indirect
1056 filehandle, usually the real filehandle name or an autovivified handle.
1057
1058 =item closedir DIRHANDLE
1059 X<closedir>
1060
1061 =for Pod::Functions close directory handle
1062
1063 Closes a directory opened by C<opendir> and returns the success of that
1064 system call.
1065
1066 =item connect SOCKET,NAME
1067 X<connect>
1068
1069 =for Pod::Functions connect to a remote socket
1070
1071 Attempts to connect to a remote socket, just like connect(2).
1072 Returns true if it succeeded, false otherwise.  NAME should be a
1073 packed address of the appropriate type for the socket.  See the examples in
1074 L<perlipc/"Sockets: Client/Server Communication">.
1075
1076 =item continue BLOCK
1077 X<continue>
1078
1079 =item continue
1080
1081 =for Pod::Functions optional trailing block in a while or foreach
1082
1083 When followed by a BLOCK, C<continue> is actually a
1084 flow control statement rather than a function.  If
1085 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
1086 C<foreach>), it is always executed just before the conditional is about to
1087 be evaluated again, just like the third part of a C<for> loop in C.  Thus
1088 it can be used to increment a loop variable, even when the loop has been
1089 continued via the C<next> statement (which is similar to the C C<continue>
1090 statement).
1091
1092 C<last>, C<next>, or C<redo> may appear within a C<continue>
1093 block; C<last> and C<redo> behave as if they had been executed within
1094 the main block.  So will C<next>, but since it will execute a C<continue>
1095 block, it may be more entertaining.
1096
1097     while (EXPR) {
1098         ### redo always comes here
1099         do_something;
1100     } continue {
1101         ### next always comes here
1102         do_something_else;
1103         # then back the top to re-check EXPR
1104     }
1105     ### last always comes here
1106
1107 Omitting the C<continue> section is equivalent to using an
1108 empty one, logically enough, so C<next> goes directly back
1109 to check the condition at the top of the loop.
1110
1111 When there is no BLOCK, C<continue> is a function that
1112 falls through the current C<when> or C<default> block instead of iterating
1113 a dynamically enclosing C<foreach> or exiting a lexically enclosing C<given>.
1114 In Perl 5.14 and earlier, this form of C<continue> was
1115 only available when the C<"switch"> feature was enabled.
1116 See L<feature> and L<perlsyn/"Switch Statements"> for more
1117 information.
1118
1119 =item cos EXPR
1120 X<cos> X<cosine> X<acos> X<arccosine>
1121
1122 =item cos
1123
1124 =for Pod::Functions cosine function
1125
1126 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
1127 takes the cosine of C<$_>.
1128
1129 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
1130 function, or use this relation:
1131
1132     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
1133
1134 =item crypt PLAINTEXT,SALT
1135 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
1136 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1137
1138 =for Pod::Functions one-way passwd-style encryption
1139
1140 Creates a digest string exactly like the crypt(3) function in the C
1141 library (assuming that you actually have a version there that has not
1142 been extirpated as a potential munition).
1143
1144 crypt() is a one-way hash function.  The PLAINTEXT and SALT are turned
1145 into a short string, called a digest, which is returned.  The same
1146 PLAINTEXT and SALT will always return the same string, but there is no
1147 (known) way to get the original PLAINTEXT from the hash.  Small
1148 changes in the PLAINTEXT or SALT will result in large changes in the
1149 digest.
1150
1151 There is no decrypt function.  This function isn't all that useful for
1152 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1153 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1154 primarily used to check if two pieces of text are the same without
1155 having to transmit or store the text itself.  An example is checking
1156 if a correct password is given.  The digest of the password is stored,
1157 not the password itself.  The user types in a password that is
1158 crypt()'d with the same salt as the stored digest.  If the two digests
1159 match, the password is correct.
1160
1161 When verifying an existing digest string you should use the digest as
1162 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1163 to create the digest is visible as part of the digest.  This ensures
1164 crypt() will hash the new string with the same salt as the digest.
1165 This allows your code to work with the standard L<crypt|/crypt> and
1166 with more exotic implementations.  In other words, assume
1167 nothing about the returned string itself nor about how many bytes 
1168 of SALT may matter.
1169
1170 Traditionally the result is a string of 13 bytes: two first bytes of
1171 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1172 the first eight bytes of PLAINTEXT mattered.  But alternative
1173 hashing schemes (like MD5), higher level security schemes (like C2),
1174 and implementations on non-Unix platforms may produce different
1175 strings.
1176
1177 When choosing a new salt create a random two character string whose
1178 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1179 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1180 characters is just a recommendation; the characters allowed in
1181 the salt depend solely on your system's crypt library, and Perl can't
1182 restrict what salts C<crypt()> accepts.
1183
1184 Here's an example that makes sure that whoever runs this program knows
1185 their password:
1186
1187     $pwd = (getpwuid($<))[1];
1188
1189     system "stty -echo";
1190     print "Password: ";
1191     chomp($word = <STDIN>);
1192     print "\n";
1193     system "stty echo";
1194
1195     if (crypt($word, $pwd) ne $pwd) {
1196         die "Sorry...\n";
1197     } else {
1198         print "ok\n";
1199     }
1200
1201 Of course, typing in your own password to whoever asks you
1202 for it is unwise.
1203
1204 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1205 of data, not least of all because you can't get the information
1206 back.  Look at the L<Digest> module for more robust algorithms.
1207
1208 If using crypt() on a Unicode string (which I<potentially> has
1209 characters with codepoints above 255), Perl tries to make sense
1210 of the situation by trying to downgrade (a copy of)
1211 the string back to an eight-bit byte string before calling crypt()
1212 (on that copy).  If that works, good.  If not, crypt() dies with
1213 C<Wide character in crypt>.
1214
1215 Portability issues: L<perlport/crypt>.
1216
1217 =item dbmclose HASH
1218 X<dbmclose>
1219
1220 =for Pod::Functions breaks binding on a tied dbm file
1221
1222 [This function has been largely superseded by the C<untie> function.]
1223
1224 Breaks the binding between a DBM file and a hash.
1225
1226 Portability issues: L<perlport/dbmclose>.
1227
1228 =item dbmopen HASH,DBNAME,MASK
1229 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1230
1231 =for Pod::Functions create binding on a tied dbm file
1232
1233 [This function has been largely superseded by the
1234 L<tie|/tie VARIABLE,CLASSNAME,LIST> function.]
1235
1236 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1237 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1238 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1239 is the name of the database (without the F<.dir> or F<.pag> extension if
1240 any).  If the database does not exist, it is created with protection
1241 specified by MASK (as modified by the C<umask>).  To prevent creation of
1242 the database if it doesn't exist, you may specify a MODE
1243 of 0, and the function will return a false value if it
1244 can't find an existing database.  If your system supports
1245 only the older DBM functions, you may make only one C<dbmopen> call in your
1246 program.  In older versions of Perl, if your system had neither DBM nor
1247 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1248 sdbm(3).
1249
1250 If you don't have write access to the DBM file, you can only read hash
1251 variables, not set them.  If you want to test whether you can write,
1252 either use file tests or try setting a dummy hash entry inside an C<eval> 
1253 to trap the error.
1254
1255 Note that functions such as C<keys> and C<values> may return huge lists
1256 when used on large DBM files.  You may prefer to use the C<each>
1257 function to iterate over large DBM files.  Example:
1258
1259     # print out history file offsets
1260     dbmopen(%HIST,'/usr/lib/news/history',0666);
1261     while (($key,$val) = each %HIST) {
1262         print $key, ' = ', unpack('L',$val), "\n";
1263     }
1264     dbmclose(%HIST);
1265
1266 See also L<AnyDBM_File> for a more general description of the pros and
1267 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1268 rich implementation.
1269
1270 You can control which DBM library you use by loading that library
1271 before you call dbmopen():
1272
1273     use DB_File;
1274     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1275         or die "Can't open netscape history file: $!";
1276
1277 Portability issues: L<perlport/dbmopen>.
1278
1279 =item defined EXPR
1280 X<defined> X<undef> X<undefined>
1281
1282 =item defined
1283
1284 =for Pod::Functions test whether a value, variable, or function is defined
1285
1286 Returns a Boolean value telling whether EXPR has a value other than
1287 the undefined value C<undef>.  If EXPR is not present, C<$_> is
1288 checked.
1289
1290 Many operations return C<undef> to indicate failure, end of file,
1291 system error, uninitialized variable, and other exceptional
1292 conditions.  This function allows you to distinguish C<undef> from
1293 other values.  (A simple Boolean test will not distinguish among
1294 C<undef>, zero, the empty string, and C<"0">, which are all equally
1295 false.)  Note that since C<undef> is a valid scalar, its presence
1296 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1297 returns C<undef> when its argument is an empty array, I<or> when the
1298 element to return happens to be C<undef>.
1299
1300 You may also use C<defined(&func)> to check whether subroutine C<&func>
1301 has ever been defined.  The return value is unaffected by any forward
1302 declarations of C<&func>.  A subroutine that is not defined
1303 may still be callable: its package may have an C<AUTOLOAD> method that
1304 makes it spring into existence the first time that it is called; see
1305 L<perlsub>.
1306
1307 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1308 used to report whether memory for that aggregate had ever been
1309 allocated.  This behavior may disappear in future versions of Perl.
1310 You should instead use a simple test for size:
1311
1312     if (@an_array) { print "has array elements\n" }
1313     if (%a_hash)   { print "has hash members\n"   }
1314
1315 When used on a hash element, it tells you whether the value is defined,
1316 not whether the key exists in the hash.  Use L</exists> for the latter
1317 purpose.
1318
1319 Examples:
1320
1321     print if defined $switch{D};
1322     print "$val\n" while defined($val = pop(@ary));
1323     die "Can't readlink $sym: $!"
1324         unless defined($value = readlink $sym);
1325     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1326     $debugging = 0 unless defined $debugging;
1327
1328 Note:  Many folks tend to overuse C<defined> and are then surprised to
1329 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1330 defined values.  For example, if you say
1331
1332     "ab" =~ /a(.*)b/;
1333
1334 The pattern match succeeds and C<$1> is defined, although it
1335 matched "nothing".  It didn't really fail to match anything.  Rather, it
1336 matched something that happened to be zero characters long.  This is all
1337 very above-board and honest.  When a function returns an undefined value,
1338 it's an admission that it couldn't give you an honest answer.  So you
1339 should use C<defined> only when questioning the integrity of what
1340 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1341 what you want.
1342
1343 See also L</undef>, L</exists>, L</ref>.
1344
1345 =item delete EXPR
1346 X<delete>
1347
1348 =for Pod::Functions deletes a value from a hash
1349
1350 Given an expression that specifies an element or slice of a hash, C<delete>
1351 deletes the specified elements from that hash so that exists() on that element
1352 no longer returns true.  Setting a hash element to the undefined value does
1353 not remove its key, but deleting it does; see L</exists>.
1354
1355 In list context, returns the value or values deleted, or the last such
1356 element in scalar context.  The return list's length always matches that of
1357 the argument list: deleting non-existent elements returns the undefined value
1358 in their corresponding positions.
1359
1360 delete() may also be used on arrays and array slices, but its behavior is less
1361 straightforward.  Although exists() will return false for deleted entries,
1362 deleting array elements never changes indices of existing values; use shift()
1363 or splice() for that.  However, if all deleted elements fall at the end of an
1364 array, the array's size shrinks to the position of the highest element that
1365 still tests true for exists(), or to 0 if none do.
1366
1367 B<WARNING:> Calling delete on array values is deprecated and likely to
1368 be removed in a future version of Perl.
1369
1370 Deleting from C<%ENV> modifies the environment.  Deleting from a hash tied to
1371 a DBM file deletes the entry from the DBM file.  Deleting from a C<tied> hash
1372 or array may not necessarily return anything; it depends on the implementation
1373 of the C<tied> package's DELETE method, which may do whatever it pleases.
1374
1375 The C<delete local EXPR> construct localizes the deletion to the current
1376 block at run time.  Until the block exits, elements locally deleted
1377 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1378 of composite types">.
1379
1380     %hash = (foo => 11, bar => 22, baz => 33);
1381     $scalar = delete $hash{foo};         # $scalar is 11
1382     $scalar = delete @hash{qw(foo bar)}; # $scalar is 22
1383     @array  = delete @hash{qw(foo baz)}; # @array  is (undef,33)
1384
1385 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1386
1387     foreach $key (keys %HASH) {
1388         delete $HASH{$key};
1389     }
1390
1391     foreach $index (0 .. $#ARRAY) {
1392         delete $ARRAY[$index];
1393     }
1394
1395 And so do these:
1396
1397     delete @HASH{keys %HASH};
1398
1399     delete @ARRAY[0 .. $#ARRAY];
1400
1401 But both are slower than assigning the empty list
1402 or undefining %HASH or @ARRAY, which is the customary 
1403 way to empty out an aggregate:
1404
1405     %HASH = ();     # completely empty %HASH
1406     undef %HASH;    # forget %HASH ever existed
1407
1408     @ARRAY = ();    # completely empty @ARRAY
1409     undef @ARRAY;   # forget @ARRAY ever existed
1410
1411 The EXPR can be arbitrarily complicated provided its
1412 final operation is an element or slice of an aggregate:
1413
1414     delete $ref->[$x][$y]{$key};
1415     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1416
1417     delete $ref->[$x][$y][$index];
1418     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1419
1420 =item die LIST
1421 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1422
1423 =for Pod::Functions raise an exception or bail out
1424
1425 C<die> raises an exception.  Inside an C<eval> the error message is stuffed
1426 into C<$@> and the C<eval> is terminated with the undefined value.
1427 If the exception is outside of all enclosing C<eval>s, then the uncaught
1428 exception prints LIST to C<STDERR> and exits with a non-zero value.  If you
1429 need to exit the process with a specific exit code, see L</exit>.
1430
1431 Equivalent examples:
1432
1433     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1434     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1435
1436 If the last element of LIST does not end in a newline, the current
1437 script line number and input line number (if any) are also printed,
1438 and a newline is supplied.  Note that the "input line number" (also
1439 known as "chunk") is subject to whatever notion of "line" happens to
1440 be currently in effect, and is also available as the special variable
1441 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1442
1443 Hint: sometimes appending C<", stopped"> to your message will cause it
1444 to make better sense when the string C<"at foo line 123"> is appended.
1445 Suppose you are running script "canasta".
1446
1447     die "/etc/games is no good";
1448     die "/etc/games is no good, stopped";
1449
1450 produce, respectively
1451
1452     /etc/games is no good at canasta line 123.
1453     /etc/games is no good, stopped at canasta line 123.
1454
1455 If the output is empty and C<$@> already contains a value (typically from a
1456 previous eval) that value is reused after appending C<"\t...propagated">.
1457 This is useful for propagating exceptions:
1458
1459     eval { ... };
1460     die unless $@ =~ /Expected exception/;
1461
1462 If the output is empty and C<$@> contains an object reference that has a
1463 C<PROPAGATE> method, that method will be called with additional file
1464 and line number parameters.  The return value replaces the value in
1465 C<$@>;  i.e., as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1466 were called.
1467
1468 If C<$@> is empty then the string C<"Died"> is used.
1469
1470 If an uncaught exception results in interpreter exit, the exit code is
1471 determined from the values of C<$!> and C<$?> with this pseudocode:
1472
1473     exit $! if $!;              # errno
1474     exit $? >> 8 if $? >> 8;    # child exit status
1475     exit 255;                   # last resort
1476
1477 The intent is to squeeze as much possible information about the likely cause
1478 into the limited space of the system exit
1479 code.  However, as C<$!> is the value
1480 of C's C<errno>, which can be set by any system call, this means that the value
1481 of the exit code used by C<die> can be non-predictable, so should not be relied
1482 upon, other than to be non-zero.
1483
1484 You can also call C<die> with a reference argument, and if this is trapped
1485 within an C<eval>, C<$@> contains that reference.  This permits more
1486 elaborate exception handling using objects that maintain arbitrary state
1487 about the exception.  Such a scheme is sometimes preferable to matching
1488 particular string values of C<$@> with regular expressions.  Because C<$@> 
1489 is a global variable and C<eval> may be used within object implementations,
1490 be careful that analyzing the error object doesn't replace the reference in
1491 the global variable.  It's easiest to make a local copy of the reference
1492 before any manipulations.  Here's an example:
1493
1494     use Scalar::Util "blessed";
1495
1496     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1497     if (my $ev_err = $@) {
1498         if (blessed($ev_err)
1499             && $ev_err->isa("Some::Module::Exception")) {
1500             # handle Some::Module::Exception
1501         }
1502         else {
1503             # handle all other possible exceptions
1504         }
1505     }
1506
1507 Because Perl stringifies uncaught exception messages before display,
1508 you'll probably want to overload stringification operations on
1509 exception objects.  See L<overload> for details about that.
1510
1511 You can arrange for a callback to be run just before the C<die>
1512 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1513 handler is called with the error text and can change the error
1514 message, if it sees fit, by calling C<die> again.  See
1515 L<perlvar/%SIG> for details on setting C<%SIG> entries, and
1516 L<"eval BLOCK"> for some examples.  Although this feature was 
1517 to be run only right before your program was to exit, this is not
1518 currently so: the C<$SIG{__DIE__}> hook is currently called
1519 even inside eval()ed blocks/strings!  If one wants the hook to do
1520 nothing in such situations, put
1521
1522     die @_ if $^S;
1523
1524 as the first line of the handler (see L<perlvar/$^S>).  Because
1525 this promotes strange action at a distance, this counterintuitive
1526 behavior may be fixed in a future release.
1527
1528 See also exit(), warn(), and the Carp module.
1529
1530 =item do BLOCK
1531 X<do> X<block>
1532
1533 =for Pod::Functions turn a BLOCK into a TERM
1534
1535 Not really a function.  Returns the value of the last command in the
1536 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1537 C<until> loop modifier, executes the BLOCK once before testing the loop
1538 condition.  (On other statements the loop modifiers test the conditional
1539 first.)
1540
1541 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1542 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1543 See L<perlsyn> for alternative strategies.
1544
1545 =item do SUBROUTINE(LIST)
1546 X<do>
1547
1548 This form of subroutine call is deprecated.  SUBROUTINE can be a bareword,
1549 a scalar variable or a subroutine beginning with C<&>.
1550
1551 =item do EXPR
1552 X<do>
1553
1554 Uses the value of EXPR as a filename and executes the contents of the
1555 file as a Perl script.
1556
1557     do 'stat.pl';
1558
1559 is just like
1560
1561     eval `cat stat.pl`;
1562
1563 except that it's more efficient and concise, keeps track of the current
1564 filename for error messages, searches the C<@INC> directories, and updates
1565 C<%INC> if the file is found.  See L<perlvar/@INC> and L<perlvar/%INC> for
1566 these variables.  It also differs in that code evaluated with C<do FILENAME>
1567 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1568 same, however, in that it does reparse the file every time you call it,
1569 so you probably don't want to do this inside a loop.
1570
1571 If C<do> can read the file but cannot compile it, it returns C<undef> and sets
1572 an error message in C<$@>.  If C<do> cannot read the file, it returns undef
1573 and sets C<$!> to the error.  Always check C<$@> first, as compilation
1574 could fail in a way that also sets C<$!>.  If the file is successfully
1575 compiled, C<do> returns the value of the last expression evaluated.
1576
1577 Inclusion of library modules is better done with the
1578 C<use> and C<require> operators, which also do automatic error checking
1579 and raise an exception if there's a problem.
1580
1581 You might like to use C<do> to read in a program configuration
1582 file.  Manual error checking can be done this way:
1583
1584     # read in config files: system first, then user
1585     for $file ("/share/prog/defaults.rc",
1586                "$ENV{HOME}/.someprogrc")
1587     {
1588         unless ($return = do $file) {
1589             warn "couldn't parse $file: $@" if $@;
1590             warn "couldn't do $file: $!"    unless defined $return;
1591             warn "couldn't run $file"       unless $return;
1592         }
1593     }
1594
1595 =item dump LABEL
1596 X<dump> X<core> X<undump>
1597
1598 =item dump
1599
1600 =for Pod::Functions create an immediate core dump
1601
1602 This function causes an immediate core dump.  See also the B<-u>
1603 command-line switch in L<perlrun>, which does the same thing.
1604 Primarily this is so that you can use the B<undump> program (not
1605 supplied) to turn your core dump into an executable binary after
1606 having initialized all your variables at the beginning of the
1607 program.  When the new binary is executed it will begin by executing
1608 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1609 Think of it as a goto with an intervening core dump and reincarnation.
1610 If C<LABEL> is omitted, restarts the program from the top.
1611
1612 B<WARNING>: Any files opened at the time of the dump will I<not>
1613 be open any more when the program is reincarnated, with possible
1614 resulting confusion by Perl.
1615
1616 This function is now largely obsolete, mostly because it's very hard to
1617 convert a core file into an executable.  That's why you should now invoke
1618 it as C<CORE::dump()>, if you don't want to be warned against a possible
1619 typo.
1620
1621 Portability issues: L<perlport/dump>.
1622
1623 =item each HASH
1624 X<each> X<hash, iterator>
1625
1626 =item each ARRAY
1627 X<array, iterator>
1628
1629 =item each EXPR
1630
1631 =for Pod::Functions retrieve the next key/value pair from a hash
1632
1633 When called on a hash in list context, returns a 2-element list
1634 consisting of the key and value for the next element of a hash.  In Perl
1635 5.12 and later only, it will also return the index and value for the next
1636 element of an array so that you can iterate over it; older Perls consider
1637 this a syntax error.  When called in scalar context, returns only the key
1638 (not the value) in a hash, or the index in an array.
1639
1640 Hash entries are returned in an apparently random order.  The actual random
1641 order is subject to change in future versions of Perl, but it is
1642 guaranteed to be in the same order as either the C<keys> or C<values>
1643 function would produce on the same (unmodified) hash.  Since Perl
1644 5.8.2 the ordering can be different even between different runs of Perl
1645 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1646
1647 After C<each> has returned all entries from the hash or array, the next
1648 call to C<each> returns the empty list in list context and C<undef> in
1649 scalar context; the next call following I<that> one restarts iteration.
1650 Each hash or array has its own internal iterator, accessed by C<each>,
1651 C<keys>, and C<values>.  The iterator is implicitly reset when C<each> has
1652 reached the end as just described; it can be explicitly reset by calling
1653 C<keys> or C<values> on the hash or array.  If you add or delete a hash's
1654 elements while iterating over it, entries may be skipped or duplicated--so
1655 don't do that.  Exception: In the current implementation, it is always safe
1656 to delete the item most recently returned by C<each()>, so the following
1657 code works properly:
1658
1659         while (($key, $value) = each %hash) {
1660           print $key, "\n";
1661           delete $hash{$key};   # This is safe
1662         }
1663
1664 This prints out your environment like the printenv(1) program,
1665 but in a different order:
1666
1667     while (($key,$value) = each %ENV) {
1668         print "$key=$value\n";
1669     }
1670
1671 Starting with Perl 5.14, C<each> can take a scalar EXPR, which must hold
1672 reference to an unblessed hash or array.  The argument will be dereferenced
1673 automatically.  This aspect of C<each> is considered highly experimental.
1674 The exact behaviour may change in a future version of Perl.
1675
1676     while (($key,$value) = each $hashref) { ... }
1677
1678 To avoid confusing would-be users of your code who are running earlier
1679 versions of Perl with mysterious syntax errors, put this sort of thing at
1680 the top of your file to signal that your code will work I<only> on Perls of
1681 a recent vintage:
1682
1683     use 5.012;  # so keys/values/each work on arrays
1684     use 5.014;  # so keys/values/each work on scalars (experimental)
1685
1686 See also C<keys>, C<values>, and C<sort>.
1687
1688 =item eof FILEHANDLE
1689 X<eof>
1690 X<end of file>
1691 X<end-of-file>
1692
1693 =item eof ()
1694
1695 =item eof
1696
1697 =for Pod::Functions test a filehandle for its end
1698
1699 Returns 1 if the next read on FILEHANDLE will return end of file I<or> if
1700 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1701 gives the real filehandle.  (Note that this function actually
1702 reads a character and then C<ungetc>s it, so isn't useful in an
1703 interactive context.)  Do not read from a terminal file (or call
1704 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1705 as terminals may lose the end-of-file condition if you do.
1706
1707 An C<eof> without an argument uses the last file read.  Using C<eof()>
1708 with empty parentheses is different.  It refers to the pseudo file
1709 formed from the files listed on the command line and accessed via the
1710 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1711 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1712 used will cause C<@ARGV> to be examined to determine if input is
1713 available.   Similarly, an C<eof()> after C<< <> >> has returned
1714 end-of-file will assume you are processing another C<@ARGV> list,
1715 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1716 see L<perlop/"I/O Operators">.
1717
1718 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1719 detect the end of each file, whereas C<eof()> will detect the end 
1720 of the very last file only.  Examples:
1721
1722     # reset line numbering on each input file
1723     while (<>) {
1724         next if /^\s*#/;  # skip comments
1725         print "$.\t$_";
1726     } continue {
1727         close ARGV if eof;  # Not eof()!
1728     }
1729
1730     # insert dashes just before last line of last file
1731     while (<>) {
1732         if (eof()) {  # check for end of last file
1733             print "--------------\n";
1734         }
1735         print;
1736         last if eof();     # needed if we're reading from a terminal
1737     }
1738
1739 Practical hint: you almost never need to use C<eof> in Perl, because the
1740 input operators typically return C<undef> when they run out of data or 
1741 encounter an error.
1742
1743 =item eval EXPR
1744 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1745 X<error, handling> X<exception, handling>
1746
1747 =item eval BLOCK
1748
1749 =item eval
1750
1751 =for Pod::Functions catch exceptions or compile and run code
1752
1753 In the first form, the return value of EXPR is parsed and executed as if it
1754 were a little Perl program.  The value of the expression (which is itself
1755 determined within scalar context) is first parsed, and if there were no
1756 errors, executed as a block within the lexical context of the current Perl
1757 program.  This means, that in particular, any outer lexical variables are
1758 visible to it, and any package variable settings or subroutine and format
1759 definitions remain afterwards.
1760
1761 Note that the value is parsed every time the C<eval> executes.
1762 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1763 delay parsing and subsequent execution of the text of EXPR until run time.
1764
1765 If the C<unicode_eval> feature is enabled (which is the default under a
1766 C<use 5.16> or higher declaration), EXPR or C<$_> is treated as a string of
1767 characters, so C<use utf8> declarations have no effect, and source filters
1768 are forbidden.  In the absence of the C<unicode_eval> feature, the string
1769 will sometimes be treated as characters and sometimes as bytes, depending
1770 on the internal encoding, and source filters activated within the C<eval>
1771 exhibit the erratic, but historical, behaviour of affecting some outer file
1772 scope that is still compiling.  See also the L</evalbytes> keyword, which
1773 always treats its input as a byte stream and works properly with source
1774 filters, and the L<feature> pragma.
1775
1776 In the second form, the code within the BLOCK is parsed only once--at the
1777 same time the code surrounding the C<eval> itself was parsed--and executed
1778 within the context of the current Perl program.  This form is typically
1779 used to trap exceptions more efficiently than the first (see below), while
1780 also providing the benefit of checking the code within BLOCK at compile
1781 time.
1782
1783 The final semicolon, if any, may be omitted from the value of EXPR or within
1784 the BLOCK.
1785
1786 In both forms, the value returned is the value of the last expression
1787 evaluated inside the mini-program; a return statement may be also used, just
1788 as with subroutines.  The expression providing the return value is evaluated
1789 in void, scalar, or list context, depending on the context of the C<eval> 
1790 itself.  See L</wantarray> for more on how the evaluation context can be 
1791 determined.
1792
1793 If there is a syntax error or runtime error, or a C<die> statement is
1794 executed, C<eval> returns C<undef> in scalar context
1795 or an empty list in list context, and C<$@> is set to the error
1796 message.  (Prior to 5.16, a bug caused C<undef> to be returned
1797 in list context for syntax errors, but not for runtime errors.)
1798 If there was no error, C<$@> is set to the empty string.  A
1799 control flow operator like C<last> or C<goto> can bypass the setting of
1800 C<$@>.  Beware that using C<eval> neither silences Perl from printing
1801 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1802 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1803 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1804 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1805
1806 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1807 determining whether a particular feature (such as C<socket> or C<symlink>)
1808 is implemented.  It is also Perl's exception-trapping mechanism, where
1809 the die operator is used to raise exceptions.
1810
1811 If you want to trap errors when loading an XS module, some problems with
1812 the binary interface (such as Perl version skew) may be fatal even with
1813 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set.  See L<perlrun>.
1814
1815 If the code to be executed doesn't vary, you may use the eval-BLOCK
1816 form to trap run-time errors without incurring the penalty of
1817 recompiling each time.  The error, if any, is still returned in C<$@>.
1818 Examples:
1819
1820     # make divide-by-zero nonfatal
1821     eval { $answer = $a / $b; }; warn $@ if $@;
1822
1823     # same thing, but less efficient
1824     eval '$answer = $a / $b'; warn $@ if $@;
1825
1826     # a compile-time error
1827     eval { $answer = }; # WRONG
1828
1829     # a run-time error
1830     eval '$answer =';   # sets $@
1831
1832 Using the C<eval{}> form as an exception trap in libraries does have some
1833 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1834 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1835 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1836 as this example shows:
1837
1838     # a private exception trap for divide-by-zero
1839     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1840     warn $@ if $@;
1841
1842 This is especially significant, given that C<__DIE__> hooks can call
1843 C<die> again, which has the effect of changing their error messages:
1844
1845     # __DIE__ hooks may modify error messages
1846     {
1847        local $SIG{'__DIE__'} =
1848               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1849        eval { die "foo lives here" };
1850        print $@ if $@;                # prints "bar lives here"
1851     }
1852
1853 Because this promotes action at a distance, this counterintuitive behavior
1854 may be fixed in a future release.
1855
1856 With an C<eval>, you should be especially careful to remember what's
1857 being looked at when:
1858
1859     eval $x;        # CASE 1
1860     eval "$x";      # CASE 2
1861
1862     eval '$x';      # CASE 3
1863     eval { $x };    # CASE 4
1864
1865     eval "\$$x++";  # CASE 5
1866     $$x++;          # CASE 6
1867
1868 Cases 1 and 2 above behave identically: they run the code contained in
1869 the variable $x.  (Although case 2 has misleading double quotes making
1870 the reader wonder what else might be happening (nothing is).)  Cases 3
1871 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1872 does nothing but return the value of $x.  (Case 4 is preferred for
1873 purely visual reasons, but it also has the advantage of compiling at
1874 compile-time instead of at run-time.)  Case 5 is a place where
1875 normally you I<would> like to use double quotes, except that in this
1876 particular situation, you can just use symbolic references instead, as
1877 in case 6.
1878
1879 Before Perl 5.14, the assignment to C<$@> occurred before restoration 
1880 of localized variables, which means that for your code to run on older
1881 versions, a temporary is required if you want to mask some but not all
1882 errors:
1883
1884     # alter $@ on nefarious repugnancy only
1885     {
1886        my $e;
1887        {
1888          local $@; # protect existing $@
1889          eval { test_repugnancy() };
1890          # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only
1891          $@ =~ /nefarious/ and $e = $@;
1892        }
1893        die $e if defined $e
1894     }
1895
1896 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1897 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1898
1899 An C<eval ''> executed within the C<DB> package doesn't see the usual
1900 surrounding lexical scope, but rather the scope of the first non-DB piece
1901 of code that called it.  You don't normally need to worry about this unless
1902 you are writing a Perl debugger.
1903
1904 =item evalbytes EXPR
1905 X<evalbytes>
1906
1907 =item evalbytes
1908
1909 =for Pod::Functions +evalbytes similar to string eval, but intend to parse a bytestream
1910
1911 This function is like L</eval> with a string argument, except it always
1912 parses its argument, or C<$_> if EXPR is omitted, as a string of bytes.  A
1913 string containing characters whose ordinal value exceeds 255 results in an
1914 error.  Source filters activated within the evaluated code apply to the
1915 code itself.
1916
1917 This function is only available under the C<evalbytes> feature, a
1918 C<use v5.16> (or higher) declaration, or with a C<CORE::> prefix.  See
1919 L<feature> for more information.
1920
1921 =item exec LIST
1922 X<exec> X<execute>
1923
1924 =item exec PROGRAM LIST
1925
1926 =for Pod::Functions abandon this program to run another
1927
1928 The C<exec> function executes a system command I<and never returns>;
1929 use C<system> instead of C<exec> if you want it to return.  It fails and
1930 returns false only if the command does not exist I<and> it is executed
1931 directly instead of via your system's command shell (see below).
1932
1933 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1934 warns you if C<exec> is called in void context and if there is a following
1935 statement that isn't C<die>, C<warn>, or C<exit> (if C<-w> is set--but
1936 you always do that, right?).  If you I<really> want to follow an C<exec>
1937 with some other statement, you can use one of these styles to avoid the warning:
1938
1939     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1940     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1941
1942 If there is more than one argument in LIST, or if LIST is an array
1943 with more than one value, calls execvp(3) with the arguments in LIST.
1944 If there is only one scalar argument or an array with one element in it,
1945 the argument is checked for shell metacharacters, and if there are any,
1946 the entire argument is passed to the system's command shell for parsing
1947 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1948 If there are no shell metacharacters in the argument, it is split into
1949 words and passed directly to C<execvp>, which is more efficient.
1950 Examples:
1951
1952     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1953     exec "sort $outfile | uniq";
1954
1955 If you don't really want to execute the first argument, but want to lie
1956 to the program you are executing about its own name, you can specify
1957 the program you actually want to run as an "indirect object" (without a
1958 comma) in front of the LIST.  (This always forces interpretation of the
1959 LIST as a multivalued list, even if there is only a single scalar in
1960 the list.)  Example:
1961
1962     $shell = '/bin/csh';
1963     exec $shell '-sh';    # pretend it's a login shell
1964
1965 or, more directly,
1966
1967     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
1968
1969 When the arguments get executed via the system shell, results are
1970 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1971 for details.
1972
1973 Using an indirect object with C<exec> or C<system> is also more
1974 secure.  This usage (which also works fine with system()) forces
1975 interpretation of the arguments as a multivalued list, even if the
1976 list had just one argument.  That way you're safe from the shell
1977 expanding wildcards or splitting up words with whitespace in them.
1978
1979     @args = ( "echo surprise" );
1980
1981     exec @args;               # subject to shell escapes
1982                                 # if @args == 1
1983     exec { $args[0] } @args;  # safe even with one-arg list
1984
1985 The first version, the one without the indirect object, ran the I<echo>
1986 program, passing it C<"surprise"> an argument.  The second version didn't;
1987 it tried to run a program named I<"echo surprise">, didn't find it, and set
1988 C<$?> to a non-zero value indicating failure.
1989
1990 Beginning with v5.6.0, Perl attempts to flush all files opened for
1991 output before the exec, but this may not be supported on some platforms
1992 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1993 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1994 open handles to avoid lost output.
1995
1996 Note that C<exec> will not call your C<END> blocks, nor will it invoke
1997 C<DESTROY> methods on your objects.
1998
1999 Portability issues: L<perlport/exec>.
2000
2001 =item exists EXPR
2002 X<exists> X<autovivification>
2003
2004 =for Pod::Functions test whether a hash key is present
2005
2006 Given an expression that specifies an element of a hash, returns true if the
2007 specified element in the hash has ever been initialized, even if the
2008 corresponding value is undefined.
2009
2010     print "Exists\n"    if exists $hash{$key};
2011     print "Defined\n"   if defined $hash{$key};
2012     print "True\n"      if $hash{$key};
2013
2014 exists may also be called on array elements, but its behavior is much less
2015 obvious and is strongly tied to the use of L</delete> on arrays.  B<Be aware>
2016 that calling exists on array values is deprecated and likely to be removed in
2017 a future version of Perl.
2018
2019     print "Exists\n"    if exists $array[$index];
2020     print "Defined\n"   if defined $array[$index];
2021     print "True\n"      if $array[$index];
2022
2023 A hash or array element can be true only if it's defined and defined only if
2024 it exists, but the reverse doesn't necessarily hold true.
2025
2026 Given an expression that specifies the name of a subroutine,
2027 returns true if the specified subroutine has ever been declared, even
2028 if it is undefined.  Mentioning a subroutine name for exists or defined
2029 does not count as declaring it.  Note that a subroutine that does not
2030 exist may still be callable: its package may have an C<AUTOLOAD>
2031 method that makes it spring into existence the first time that it is
2032 called; see L<perlsub>.
2033
2034     print "Exists\n"  if exists &subroutine;
2035     print "Defined\n" if defined &subroutine;
2036
2037 Note that the EXPR can be arbitrarily complicated as long as the final
2038 operation is a hash or array key lookup or subroutine name:
2039
2040     if (exists $ref->{A}->{B}->{$key})  { }
2041     if (exists $hash{A}{B}{$key})       { }
2042
2043     if (exists $ref->{A}->{B}->[$ix])   { }
2044     if (exists $hash{A}{B}[$ix])        { }
2045
2046     if (exists &{$ref->{A}{B}{$key}})   { }
2047
2048 Although the most deeply nested array or hash element will not spring into
2049 existence just because its existence was tested, any intervening ones will.
2050 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
2051 into existence due to the existence test for the $key element above.
2052 This happens anywhere the arrow operator is used, including even here:
2053
2054     undef $ref;
2055     if (exists $ref->{"Some key"})    { }
2056     print $ref;  # prints HASH(0x80d3d5c)
2057
2058 This surprising autovivification in what does not at first--or even
2059 second--glance appear to be an lvalue context may be fixed in a future
2060 release.
2061
2062 Use of a subroutine call, rather than a subroutine name, as an argument
2063 to exists() is an error.
2064
2065     exists &sub;    # OK
2066     exists &sub();  # Error
2067
2068 =item exit EXPR
2069 X<exit> X<terminate> X<abort>
2070
2071 =item exit
2072
2073 =for Pod::Functions terminate this program
2074
2075 Evaluates EXPR and exits immediately with that value.    Example:
2076
2077     $ans = <STDIN>;
2078     exit 0 if $ans =~ /^[Xx]/;
2079
2080 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
2081 universally recognized values for EXPR are C<0> for success and C<1>
2082 for error; other values are subject to interpretation depending on the
2083 environment in which the Perl program is running.  For example, exiting
2084 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
2085 the mailer to return the item undelivered, but that's not true everywhere.
2086
2087 Don't use C<exit> to abort a subroutine if there's any chance that
2088 someone might want to trap whatever error happened.  Use C<die> instead,
2089 which can be trapped by an C<eval>.
2090
2091 The exit() function does not always exit immediately.  It calls any
2092 defined C<END> routines first, but these C<END> routines may not
2093 themselves abort the exit.  Likewise any object destructors that need to
2094 be called are called before the real exit.  C<END> routines and destructors
2095 can change the exit status by modifying C<$?>.  If this is a problem, you
2096 can call C<POSIX::_exit($status)> to avoid END and destructor processing.
2097 See L<perlmod> for details.
2098
2099 Portability issues: L<perlport/exit>.
2100
2101 =item exp EXPR
2102 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
2103
2104 =item exp
2105
2106 =for Pod::Functions raise I<e> to a power
2107
2108 Returns I<e> (the natural logarithm base) to the power of EXPR.
2109 If EXPR is omitted, gives C<exp($_)>.
2110
2111 =item fc EXPR
2112 X<fc> X<foldcase> X<casefold> X<fold-case> X<case-fold>
2113
2114 =item fc
2115
2116 =for Pod::Functions +fc return casefolded version of a string
2117
2118 Returns the casefolded version of EXPR.  This is the internal function
2119 implementing the C<\F> escape in double-quoted strings.
2120
2121 Casefolding is the process of mapping strings to a form where case
2122 differences are erased; comparing two strings in their casefolded
2123 form is effectively a way of asking if two strings are equal,
2124 regardless of case.
2125
2126 Roughly, if you ever found yourself writing this
2127
2128     lc($this) eq lc($that)    # Wrong!
2129         # or
2130     uc($this) eq uc($that)    # Also wrong!
2131         # or
2132     $this =~ /^\Q$that\E\z/i  # Right!
2133
2134 Now you can write
2135
2136     fc($this) eq fc($that)
2137
2138 And get the correct results.
2139
2140 Perl only implements the full form of casefolding,
2141 but you can access the simple folds using L<Unicode::UCD/casefold()> and
2142 L<Unicode::UCD/prop_invmap()>.
2143 For further information on casefolding, refer to
2144 the Unicode Standard, specifically sections 3.13 C<Default Case Operations>,
2145 4.2 C<Case-Normative>, and 5.18 C<Case Mappings>,
2146 available at L<http://www.unicode.org/versions/latest/>, as well as the
2147 Case Charts available at L<http://www.unicode.org/charts/case/>.
2148
2149 If EXPR is omitted, uses C<$_>.
2150
2151 This function behaves the same way under various pragma, such as in a locale,
2152 as L</lc> does.
2153
2154 While the Unicode Standard defines two additional forms of casefolding,
2155 one for Turkic languages and one that never maps one character into multiple
2156 characters, these are not provided by the Perl core; However, the CPAN module
2157 C<Unicode::Casing> may be used to provide an implementation.
2158
2159 This keyword is available only when the C<"fc"> feature is enabled,
2160 or when prefixed with C<CORE::>; See L<feature>. Alternately,
2161 include a C<use v5.16> or later to the current scope.
2162
2163 =item fcntl FILEHANDLE,FUNCTION,SCALAR
2164 X<fcntl>
2165
2166 =for Pod::Functions file control system call
2167
2168 Implements the fcntl(2) function.  You'll probably have to say
2169
2170     use Fcntl;
2171
2172 first to get the correct constant definitions.  Argument processing and
2173 value returned work just like C<ioctl> below.
2174 For example:
2175
2176     use Fcntl;
2177     fcntl($filehandle, F_GETFL, $packed_return_buffer)
2178         or die "can't fcntl F_GETFL: $!";
2179
2180 You don't have to check for C<defined> on the return from C<fcntl>.
2181 Like C<ioctl>, it maps a C<0> return from the system call into
2182 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
2183 in numeric context.  It is also exempt from the normal B<-w> warnings
2184 on improper numeric conversions.
2185
2186 Note that C<fcntl> raises an exception if used on a machine that
2187 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
2188 manpage to learn what functions are available on your system.
2189
2190 Here's an example of setting a filehandle named C<REMOTE> to be
2191 non-blocking at the system level.  You'll have to negotiate C<$|>
2192 on your own, though.
2193
2194     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2195
2196     $flags = fcntl(REMOTE, F_GETFL, 0)
2197                 or die "Can't get flags for the socket: $!\n";
2198
2199     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2200                 or die "Can't set flags for the socket: $!\n";
2201
2202 Portability issues: L<perlport/fcntl>.
2203
2204 =item __FILE__
2205 X<__FILE__>
2206
2207 =for Pod::Functions the name of the current source file
2208
2209 A special token that returns the name of the file in which it occurs.
2210
2211 =item fileno FILEHANDLE
2212 X<fileno>
2213
2214 =for Pod::Functions return file descriptor from filehandle
2215
2216 Returns the file descriptor for a filehandle, or undefined if the
2217 filehandle is not open.  If there is no real file descriptor at the OS
2218 level, as can happen with filehandles connected to memory objects via
2219 C<open> with a reference for the third argument, -1 is returned.
2220
2221 This is mainly useful for constructing
2222 bitmaps for C<select> and low-level POSIX tty-handling operations.
2223 If FILEHANDLE is an expression, the value is taken as an indirect
2224 filehandle, generally its name.
2225
2226 You can use this to find out whether two handles refer to the
2227 same underlying descriptor:
2228
2229     if (fileno(THIS) == fileno(THAT)) {
2230         print "THIS and THAT are dups\n";
2231     }
2232
2233 =item flock FILEHANDLE,OPERATION
2234 X<flock> X<lock> X<locking>
2235
2236 =for Pod::Functions lock an entire file with an advisory lock
2237
2238 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
2239 for success, false on failure.  Produces a fatal error if used on a
2240 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
2241 C<flock> is Perl's portable file-locking interface, although it locks
2242 entire files only, not records.
2243
2244 Two potentially non-obvious but traditional C<flock> semantics are
2245 that it waits indefinitely until the lock is granted, and that its locks
2246 are B<merely advisory>.  Such discretionary locks are more flexible, but
2247 offer fewer guarantees.  This means that programs that do not also use
2248 C<flock> may modify files locked with C<flock>.  See L<perlport>, 
2249 your port's specific documentation, and your system-specific local manpages
2250 for details.  It's best to assume traditional behavior if you're writing
2251 portable programs.  (But if you're not, you should as always feel perfectly
2252 free to write for your own system's idiosyncrasies (sometimes called
2253 "features").  Slavish adherence to portability concerns shouldn't get
2254 in the way of your getting your job done.)
2255
2256 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
2257 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
2258 you can use the symbolic names if you import them from the L<Fcntl> module,
2259 either individually, or as a group using the C<:flock> tag.  LOCK_SH
2260 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
2261 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
2262 LOCK_SH or LOCK_EX, then C<flock> returns immediately rather than blocking
2263 waiting for the lock; check the return status to see if you got it.
2264
2265 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
2266 before locking or unlocking it.
2267
2268 Note that the emulation built with lockf(3) doesn't provide shared
2269 locks, and it requires that FILEHANDLE be open with write intent.  These
2270 are the semantics that lockf(3) implements.  Most if not all systems
2271 implement lockf(3) in terms of fcntl(2) locking, though, so the
2272 differing semantics shouldn't bite too many people.
2273
2274 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
2275 be open with read intent to use LOCK_SH and requires that it be open
2276 with write intent to use LOCK_EX.
2277
2278 Note also that some versions of C<flock> cannot lock things over the
2279 network; you would need to use the more system-specific C<fcntl> for
2280 that.  If you like you can force Perl to ignore your system's flock(2)
2281 function, and so provide its own fcntl(2)-based emulation, by passing
2282 the switch C<-Ud_flock> to the F<Configure> program when you configure
2283 and build a new Perl.
2284
2285 Here's a mailbox appender for BSD systems.
2286
2287     # import LOCK_* and SEEK_END constants
2288     use Fcntl qw(:flock SEEK_END);
2289
2290     sub lock {
2291         my ($fh) = @_;
2292         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
2293
2294         # and, in case someone appended while we were waiting...
2295         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
2296     }
2297
2298     sub unlock {
2299         my ($fh) = @_;
2300         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
2301     }
2302
2303     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
2304         or die "Can't open mailbox: $!";
2305
2306     lock($mbox);
2307     print $mbox $msg,"\n\n";
2308     unlock($mbox);
2309
2310 On systems that support a real flock(2), locks are inherited across fork()
2311 calls, whereas those that must resort to the more capricious fcntl(2)
2312 function lose their locks, making it seriously harder to write servers.
2313
2314 See also L<DB_File> for other flock() examples.
2315
2316 Portability issues: L<perlport/flock>.
2317
2318 =item fork
2319 X<fork> X<child> X<parent>
2320
2321 =for Pod::Functions create a new process just like this one
2322
2323 Does a fork(2) system call to create a new process running the
2324 same program at the same point.  It returns the child pid to the
2325 parent process, C<0> to the child process, or C<undef> if the fork is
2326 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2327 are shared, while everything else is copied.  On most systems supporting
2328 fork(), great care has gone into making it extremely efficient (for
2329 example, using copy-on-write technology on data pages), making it the
2330 dominant paradigm for multitasking over the last few decades.
2331
2332 Beginning with v5.6.0, Perl attempts to flush all files opened for
2333 output before forking the child process, but this may not be supported
2334 on some platforms (see L<perlport>).  To be safe, you may need to set
2335 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2336 C<IO::Handle> on any open handles to avoid duplicate output.
2337
2338 If you C<fork> without ever waiting on your children, you will
2339 accumulate zombies.  On some systems, you can avoid this by setting
2340 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
2341 forking and reaping moribund children.
2342
2343 Note that if your forked child inherits system file descriptors like
2344 STDIN and STDOUT that are actually connected by a pipe or socket, even
2345 if you exit, then the remote server (such as, say, a CGI script or a
2346 backgrounded job launched from a remote shell) won't think you're done.
2347 You should reopen those to F</dev/null> if it's any issue.
2348
2349 On some platforms such as Windows, where the fork() system call is not available,
2350 Perl can be built to emulate fork() in the Perl interpreter.
2351 The emulation is designed, at the level of the Perl program,
2352 to be as compatible as possible with the "Unix" fork().
2353 However it has limitations that have to be considered in code intended to be portable.
2354 See L<perlfork> for more details.
2355
2356 Portability issues: L<perlport/fork>.
2357
2358 =item format
2359 X<format>
2360
2361 =for Pod::Functions declare a picture format with use by the write() function
2362
2363 Declare a picture format for use by the C<write> function.  For
2364 example:
2365
2366     format Something =
2367         Test: @<<<<<<<< @||||| @>>>>>
2368               $str,     $%,    '$' . int($num)
2369     .
2370
2371     $str = "widget";
2372     $num = $cost/$quantity;
2373     $~ = 'Something';
2374     write;
2375
2376 See L<perlform> for many details and examples.
2377
2378 =item formline PICTURE,LIST
2379 X<formline>
2380
2381 =for Pod::Functions internal function used for formats
2382
2383 This is an internal function used by C<format>s, though you may call it,
2384 too.  It formats (see L<perlform>) a list of values according to the
2385 contents of PICTURE, placing the output into the format output
2386 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2387 Eventually, when a C<write> is done, the contents of
2388 C<$^A> are written to some filehandle.  You could also read C<$^A>
2389 and then set C<$^A> back to C<"">.  Note that a format typically
2390 does one C<formline> per line of form, but the C<formline> function itself
2391 doesn't care how many newlines are embedded in the PICTURE.  This means
2392 that the C<~> and C<~~> tokens treat the entire PICTURE as a single line.
2393 You may therefore need to use multiple formlines to implement a single
2394 record format, just like the C<format> compiler.
2395
2396 Be careful if you put double quotes around the picture, because an C<@>
2397 character may be taken to mean the beginning of an array name.
2398 C<formline> always returns true.  See L<perlform> for other examples.
2399
2400 If you are trying to use this instead of C<write> to capture the output,
2401 you may find it easier to open a filehandle to a scalar
2402 (C<< open $fh, ">", \$output >>) and write to that instead.
2403
2404 =item getc FILEHANDLE
2405 X<getc> X<getchar> X<character> X<file, read>
2406
2407 =item getc
2408
2409 =for Pod::Functions get the next character from the filehandle
2410
2411 Returns the next character from the input file attached to FILEHANDLE,
2412 or the undefined value at end of file or if there was an error (in
2413 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2414 STDIN.  This is not particularly efficient.  However, it cannot be
2415 used by itself to fetch single characters without waiting for the user
2416 to hit enter.  For that, try something more like:
2417
2418     if ($BSD_STYLE) {
2419         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2420     }
2421     else {
2422         system "stty", '-icanon', 'eol', "\001";
2423     }
2424
2425     $key = getc(STDIN);
2426
2427     if ($BSD_STYLE) {
2428         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2429     }
2430     else {
2431         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2432     }
2433     print "\n";
2434
2435 Determination of whether $BSD_STYLE should be set
2436 is left as an exercise to the reader.
2437
2438 The C<POSIX::getattr> function can do this more portably on
2439 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2440 module from your nearest CPAN site; details on CPAN can be found under
2441 L<perlmodlib/CPAN>.
2442
2443 =item getlogin
2444 X<getlogin> X<login>
2445
2446 =for Pod::Functions return who logged in at this tty
2447
2448 This implements the C library function of the same name, which on most
2449 systems returns the current login from F</etc/utmp>, if any.  If it
2450 returns the empty string, use C<getpwuid>.
2451
2452     $login = getlogin || getpwuid($<) || "Kilroy";
2453
2454 Do not consider C<getlogin> for authentication: it is not as
2455 secure as C<getpwuid>.
2456
2457 Portability issues: L<perlport/getlogin>.
2458
2459 =item getpeername SOCKET
2460 X<getpeername> X<peer>
2461
2462 =for Pod::Functions find the other end of a socket connection
2463
2464 Returns the packed sockaddr address of the other end of the SOCKET
2465 connection.
2466
2467     use Socket;
2468     $hersockaddr    = getpeername(SOCK);
2469     ($port, $iaddr) = sockaddr_in($hersockaddr);
2470     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2471     $herstraddr     = inet_ntoa($iaddr);
2472
2473 =item getpgrp PID
2474 X<getpgrp> X<group>
2475
2476 =for Pod::Functions get process group
2477
2478 Returns the current process group for the specified PID.  Use
2479 a PID of C<0> to get the current process group for the
2480 current process.  Will raise an exception if used on a machine that
2481 doesn't implement getpgrp(2).  If PID is omitted, returns the process
2482 group of the current process.  Note that the POSIX version of C<getpgrp>
2483 does not accept a PID argument, so only C<PID==0> is truly portable.
2484
2485 Portability issues: L<perlport/getpgrp>.
2486
2487 =item getppid
2488 X<getppid> X<parent> X<pid>
2489
2490 =for Pod::Functions get parent process ID
2491
2492 Returns the process id of the parent process.
2493
2494 Note for Linux users: Between v5.8.1 and v5.16.0 Perl would work
2495 around non-POSIX thread semantics the minority of Linux systems (and
2496 Debian GNU/kFreeBSD systems) that used LinuxThreads, this emulation
2497 has since been removed. See the documentation for L<$$|perlvar/$$> for
2498 details.
2499
2500 Portability issues: L<perlport/getppid>.
2501
2502 =item getpriority WHICH,WHO
2503 X<getpriority> X<priority> X<nice>
2504
2505 =for Pod::Functions get current nice value
2506
2507 Returns the current priority for a process, a process group, or a user.
2508 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2509 machine that doesn't implement getpriority(2).
2510
2511 Portability issues: L<perlport/getpriority>.
2512
2513 =item getpwnam NAME
2514 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2515 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2516 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2517 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2518 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2519 X<endnetent> X<endprotoent> X<endservent> 
2520
2521 =for Pod::Functions get passwd record given user login name
2522
2523 =item getgrnam NAME
2524
2525 =for Pod::Functions get group record given group name
2526
2527 =item gethostbyname NAME
2528
2529 =for Pod::Functions get host record given name
2530
2531 =item getnetbyname NAME
2532
2533 =for Pod::Functions get networks record given name
2534
2535 =item getprotobyname NAME
2536
2537 =for Pod::Functions get protocol record given name
2538
2539 =item getpwuid UID
2540
2541 =for Pod::Functions get passwd record given user ID
2542
2543 =item getgrgid GID
2544
2545 =for Pod::Functions get group record given group user ID
2546
2547 =item getservbyname NAME,PROTO
2548
2549 =for Pod::Functions get services record given its name
2550
2551 =item gethostbyaddr ADDR,ADDRTYPE
2552
2553 =for Pod::Functions get host record given its address
2554
2555 =item getnetbyaddr ADDR,ADDRTYPE
2556
2557 =for Pod::Functions get network record given its address
2558
2559 =item getprotobynumber NUMBER
2560
2561 =for Pod::Functions get protocol record numeric protocol
2562
2563 =item getservbyport PORT,PROTO
2564
2565 =for Pod::Functions get services record given numeric port
2566
2567 =item getpwent
2568
2569 =for Pod::Functions get next passwd record
2570
2571 =item getgrent
2572
2573 =for Pod::Functions get next group record
2574
2575 =item gethostent
2576
2577 =for Pod::Functions get next hosts record
2578
2579 =item getnetent
2580
2581 =for Pod::Functions get next networks record
2582
2583 =item getprotoent
2584
2585 =for Pod::Functions get next protocols record
2586
2587 =item getservent
2588
2589 =for Pod::Functions get next services record
2590
2591 =item setpwent
2592
2593 =for Pod::Functions prepare passwd file for use
2594
2595 =item setgrent
2596
2597 =for Pod::Functions prepare group file for use
2598
2599 =item sethostent STAYOPEN
2600
2601 =for Pod::Functions prepare hosts file for use
2602
2603 =item setnetent STAYOPEN
2604
2605 =for Pod::Functions prepare networks file for use
2606
2607 =item setprotoent STAYOPEN
2608
2609 =for Pod::Functions prepare protocols file for use
2610
2611 =item setservent STAYOPEN
2612
2613 =for Pod::Functions prepare services file for use
2614
2615 =item endpwent
2616
2617 =for Pod::Functions be done using passwd file
2618
2619 =item endgrent
2620
2621 =for Pod::Functions be done using group file
2622
2623 =item endhostent
2624
2625 =for Pod::Functions be done using hosts file
2626
2627 =item endnetent
2628
2629 =for Pod::Functions be done using networks file
2630
2631 =item endprotoent
2632
2633 =for Pod::Functions be done using protocols file
2634
2635 =item endservent
2636
2637 =for Pod::Functions be done using services file
2638
2639 These routines are the same as their counterparts in the
2640 system C library.  In list context, the return values from the
2641 various get routines are as follows:
2642
2643     ($name,$passwd,$uid,$gid,
2644        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2645     ($name,$passwd,$gid,$members) = getgr*
2646     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2647     ($name,$aliases,$addrtype,$net) = getnet*
2648     ($name,$aliases,$proto) = getproto*
2649     ($name,$aliases,$port,$proto) = getserv*
2650
2651 (If the entry doesn't exist you get an empty list.)
2652
2653 The exact meaning of the $gcos field varies but it usually contains
2654 the real name of the user (as opposed to the login name) and other
2655 information pertaining to the user.  Beware, however, that in many
2656 system users are able to change this information and therefore it
2657 cannot be trusted and therefore the $gcos is tainted (see
2658 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2659 login shell, are also tainted, for the same reason.
2660
2661 In scalar context, you get the name, unless the function was a
2662 lookup by name, in which case you get the other thing, whatever it is.
2663 (If the entry doesn't exist you get the undefined value.)  For example:
2664
2665     $uid   = getpwnam($name);
2666     $name  = getpwuid($num);
2667     $name  = getpwent();
2668     $gid   = getgrnam($name);
2669     $name  = getgrgid($num);
2670     $name  = getgrent();
2671     #etc.
2672
2673 In I<getpw*()> the fields $quota, $comment, and $expire are special
2674 in that they are unsupported on many systems.  If the
2675 $quota is unsupported, it is an empty scalar.  If it is supported, it
2676 usually encodes the disk quota.  If the $comment field is unsupported,
2677 it is an empty scalar.  If it is supported it usually encodes some
2678 administrative comment about the user.  In some systems the $quota
2679 field may be $change or $age, fields that have to do with password
2680 aging.  In some systems the $comment field may be $class.  The $expire
2681 field, if present, encodes the expiration period of the account or the
2682 password.  For the availability and the exact meaning of these fields
2683 in your system, please consult getpwnam(3) and your system's 
2684 F<pwd.h> file.  You can also find out from within Perl what your
2685 $quota and $comment fields mean and whether you have the $expire field
2686 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2687 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2688 files are supported only if your vendor has implemented them in the
2689 intuitive fashion that calling the regular C library routines gets the
2690 shadow versions if you're running under privilege or if there exists
2691 the shadow(3) functions as found in System V (this includes Solaris
2692 and Linux).  Those systems that implement a proprietary shadow password
2693 facility are unlikely to be supported.
2694
2695 The $members value returned by I<getgr*()> is a space-separated list of
2696 the login names of the members of the group.
2697
2698 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2699 C, it will be returned to you via C<$?> if the function call fails.  The
2700 C<@addrs> value returned by a successful call is a list of raw
2701 addresses returned by the corresponding library call.  In the
2702 Internet domain, each address is four bytes long; you can unpack it
2703 by saying something like:
2704
2705     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2706
2707 The Socket library makes this slightly easier:
2708
2709     use Socket;
2710     $iaddr = inet_aton("127.1"); # or whatever address
2711     $name  = gethostbyaddr($iaddr, AF_INET);
2712
2713     # or going the other way
2714     $straddr = inet_ntoa($iaddr);
2715
2716 In the opposite way, to resolve a hostname to the IP address
2717 you can write this:
2718
2719     use Socket;
2720     $packed_ip = gethostbyname("www.perl.org");
2721     if (defined $packed_ip) {
2722         $ip_address = inet_ntoa($packed_ip);
2723     }
2724
2725 Make sure C<gethostbyname()> is called in SCALAR context and that
2726 its return value is checked for definedness.
2727
2728 The C<getprotobynumber> function, even though it only takes one argument,
2729 has the precedence of a list operator, so beware:
2730
2731     getprotobynumber $number eq 'icmp'   # WRONG
2732     getprotobynumber($number eq 'icmp')  # actually means this
2733     getprotobynumber($number) eq 'icmp'  # better this way
2734
2735 If you get tired of remembering which element of the return list
2736 contains which return value, by-name interfaces are provided
2737 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2738 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2739 and C<User::grent>.  These override the normal built-ins, supplying
2740 versions that return objects with the appropriate names
2741 for each field.  For example:
2742
2743    use File::stat;
2744    use User::pwent;
2745    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2746
2747 Even though it looks as though they're the same method calls (uid),
2748 they aren't, because a C<File::stat> object is different from
2749 a C<User::pwent> object.
2750
2751 Portability issues: L<perlport/getpwnam> to L<perlport/endservent>.
2752
2753 =item getsockname SOCKET
2754 X<getsockname>
2755
2756 =for Pod::Functions retrieve the sockaddr for a given socket
2757
2758 Returns the packed sockaddr address of this end of the SOCKET connection,
2759 in case you don't know the address because you have several different
2760 IPs that the connection might have come in on.
2761
2762     use Socket;
2763     $mysockaddr = getsockname(SOCK);
2764     ($port, $myaddr) = sockaddr_in($mysockaddr);
2765     printf "Connect to %s [%s]\n",
2766        scalar gethostbyaddr($myaddr, AF_INET),
2767        inet_ntoa($myaddr);
2768
2769 =item getsockopt SOCKET,LEVEL,OPTNAME
2770 X<getsockopt>
2771
2772 =for Pod::Functions get socket options on a given socket
2773
2774 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2775 Options may exist at multiple protocol levels depending on the socket
2776 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2777 C<Socket> module) will exist.  To query options at another level the
2778 protocol number of the appropriate protocol controlling the option
2779 should be supplied.  For example, to indicate that an option is to be
2780 interpreted by the TCP protocol, LEVEL should be set to the protocol
2781 number of TCP, which you can get using C<getprotobyname>.
2782
2783 The function returns a packed string representing the requested socket
2784 option, or C<undef> on error, with the reason for the error placed in
2785 C<$!>.  Just what is in the packed string depends on LEVEL and OPTNAME;
2786 consult getsockopt(2) for details.  A common case is that the option is an
2787 integer, in which case the result is a packed integer, which you can decode
2788 using C<unpack> with the C<i> (or C<I>) format.
2789
2790 Here's an example to test whether Nagle's algorithm is enabled on a socket:
2791
2792     use Socket qw(:all);
2793
2794     defined(my $tcp = getprotobyname("tcp"))
2795         or die "Could not determine the protocol number for tcp";
2796     # my $tcp = IPPROTO_TCP; # Alternative
2797     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2798         or die "getsockopt TCP_NODELAY: $!";
2799     my $nodelay = unpack("I", $packed);
2800     print "Nagle's algorithm is turned ",
2801            $nodelay ? "off\n" : "on\n";
2802
2803 Portability issues: L<perlport/getsockopt>.
2804
2805 =item glob EXPR
2806 X<glob> X<wildcard> X<filename, expansion> X<expand>
2807
2808 =item glob
2809
2810 =for Pod::Functions expand filenames using wildcards
2811
2812 In list context, returns a (possibly empty) list of filename expansions on
2813 the value of EXPR such as the standard Unix shell F</bin/csh> would do.  In
2814 scalar context, glob iterates through such filename expansions, returning
2815 undef when the list is exhausted.  This is the internal function
2816 implementing the C<< <*.c> >> operator, but you can use it directly.  If
2817 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2818 more detail in L<perlop/"I/O Operators">.
2819
2820 Note that C<glob> splits its arguments on whitespace and treats
2821 each segment as separate pattern.  As such, C<glob("*.c *.h")> 
2822 matches all files with a F<.c> or F<.h> extension.  The expression
2823 C<glob(".* *")> matches all files in the current working directory.
2824 If you want to glob filenames that might contain whitespace, you'll
2825 have to use extra quotes around the spacey filename to protect it.
2826 For example, to glob filenames that have an C<e> followed by a space
2827 followed by an C<f>, use either of:
2828
2829     @spacies = <"*e f*">;
2830     @spacies = glob '"*e f*"';
2831     @spacies = glob q("*e f*");
2832
2833 If you had to get a variable through, you could do this:
2834
2835     @spacies = glob "'*${var}e f*'";
2836     @spacies = glob qq("*${var}e f*");
2837
2838 If non-empty braces are the only wildcard characters used in the
2839 C<glob>, no filenames are matched, but potentially many strings
2840 are returned.  For example, this produces nine strings, one for
2841 each pairing of fruits and colors:
2842
2843     @many =  glob "{apple,tomato,cherry}={green,yellow,red}";
2844
2845 Beginning with v5.6.0, this operator is implemented using the standard
2846 C<File::Glob> extension.  See L<File::Glob> for details, including
2847 C<bsd_glob> which does not treat whitespace as a pattern separator.
2848
2849 Portability issues: L<perlport/glob>.
2850
2851 =item gmtime EXPR
2852 X<gmtime> X<UTC> X<Greenwich>
2853
2854 =item gmtime
2855
2856 =for Pod::Functions convert UNIX time into record or string using Greenwich time
2857
2858 Works just like L</localtime> but the returned values are
2859 localized for the standard Greenwich time zone.
2860
2861 Note: When called in list context, $isdst, the last value
2862 returned by gmtime, is always C<0>.  There is no
2863 Daylight Saving Time in GMT.
2864
2865 Portability issues: L<perlport/gmtime>.
2866
2867 =item goto LABEL
2868 X<goto> X<jump> X<jmp>
2869
2870 =item goto EXPR
2871
2872 =item goto &NAME
2873
2874 =for Pod::Functions create spaghetti code
2875
2876 The C<goto-LABEL> form finds the statement labeled with LABEL and
2877 resumes execution there.  It can't be used to get out of a block or
2878 subroutine given to C<sort>.  It can be used to go almost anywhere
2879 else within the dynamic scope, including out of subroutines, but it's
2880 usually better to use some other construct such as C<last> or C<die>.
2881 The author of Perl has never felt the need to use this form of C<goto>
2882 (in Perl, that is; C is another matter).  (The difference is that C
2883 does not offer named loops combined with loop control.  Perl does, and
2884 this replaces most structured uses of C<goto> in other languages.)
2885
2886 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2887 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2888 necessarily recommended if you're optimizing for maintainability:
2889
2890     goto ("FOO", "BAR", "GLARCH")[$i];
2891
2892 As shown in this example, C<goto-EXPR> is exempt from the "looks like a
2893 function" rule.  A pair of parentheses following it does not (necessarily)
2894 delimit its argument.  C<goto("NE")."XT"> is equivalent to C<goto NEXT>.
2895
2896 Use of C<goto-LABEL> or C<goto-EXPR> to jump into a construct is
2897 deprecated and will issue a warning.  Even then, it may not be used to
2898 go into any construct that requires initialization, such as a
2899 subroutine or a C<foreach> loop.  It also can't be used to go into a
2900 construct that is optimized away.
2901
2902 The C<goto-&NAME> form is quite different from the other forms of
2903 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2904 doesn't have the stigma associated with other gotos.  Instead, it
2905 exits the current subroutine (losing any changes set by local()) and
2906 immediately calls in its place the named subroutine using the current
2907 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2908 load another subroutine and then pretend that the other subroutine had
2909 been called in the first place (except that any modifications to C<@_>
2910 in the current subroutine are propagated to the other subroutine.)
2911 After the C<goto>, not even C<caller> will be able to tell that this
2912 routine was called first.
2913
2914 NAME needn't be the name of a subroutine; it can be a scalar variable
2915 containing a code reference or a block that evaluates to a code
2916 reference.
2917
2918 =item grep BLOCK LIST
2919 X<grep>
2920
2921 =item grep EXPR,LIST
2922
2923 =for Pod::Functions locate elements in a list test true against a given criterion
2924
2925 This is similar in spirit to, but not the same as, grep(1) and its
2926 relatives.  In particular, it is not limited to using regular expressions.
2927
2928 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2929 C<$_> to each element) and returns the list value consisting of those
2930 elements for which the expression evaluated to true.  In scalar
2931 context, returns the number of times the expression was true.
2932
2933     @foo = grep(!/^#/, @bar);    # weed out comments
2934
2935 or equivalently,
2936
2937     @foo = grep {!/^#/} @bar;    # weed out comments
2938
2939 Note that C<$_> is an alias to the list value, so it can be used to
2940 modify the elements of the LIST.  While this is useful and supported,
2941 it can cause bizarre results if the elements of LIST are not variables.
2942 Similarly, grep returns aliases into the original list, much as a for
2943 loop's index variable aliases the list elements.  That is, modifying an
2944 element of a list returned by grep (for example, in a C<foreach>, C<map>
2945 or another C<grep>) actually modifies the element in the original list.
2946 This is usually something to be avoided when writing clear code.
2947
2948 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2949 been declared with C<my $_>) then, in addition to being locally aliased to
2950 the list elements, C<$_> keeps being lexical inside the block; i.e., it
2951 can't be seen from the outside, avoiding any potential side-effects.
2952
2953 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2954
2955 =item hex EXPR
2956 X<hex> X<hexadecimal>
2957
2958 =item hex
2959
2960 =for Pod::Functions convert a string to a hexadecimal number
2961
2962 Interprets EXPR as a hex string and returns the corresponding value.
2963 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2964 L</oct>.)  If EXPR is omitted, uses C<$_>.
2965
2966     print hex '0xAf'; # prints '175'
2967     print hex 'aF';   # same
2968
2969 Hex strings may only represent integers.  Strings that would cause
2970 integer overflow trigger a warning.  Leading whitespace is not stripped,
2971 unlike oct().  To present something as hex, look into L</printf>,
2972 L</sprintf>, and L</unpack>.
2973
2974 =item import LIST
2975 X<import>
2976
2977 =for Pod::Functions patch a module's namespace into your own
2978
2979 There is no builtin C<import> function.  It is just an ordinary
2980 method (subroutine) defined (or inherited) by modules that wish to export
2981 names to another module.  The C<use> function calls the C<import> method
2982 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2983
2984 =item index STR,SUBSTR,POSITION
2985 X<index> X<indexOf> X<InStr>
2986
2987 =item index STR,SUBSTR
2988
2989 =for Pod::Functions find a substring within a string
2990
2991 The index function searches for one string within another, but without
2992 the wildcard-like behavior of a full regular-expression pattern match.
2993 It returns the position of the first occurrence of SUBSTR in STR at
2994 or after POSITION.  If POSITION is omitted, starts searching from the
2995 beginning of the string.  POSITION before the beginning of the string
2996 or after its end is treated as if it were the beginning or the end,
2997 respectively.  POSITION and the return value are based at zero.
2998 If the substring is not found, C<index> returns -1.
2999
3000 =item int EXPR
3001 X<int> X<integer> X<truncate> X<trunc> X<floor>
3002
3003 =item int
3004
3005 =for Pod::Functions get the integer portion of a number
3006
3007 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
3008 You should not use this function for rounding: one because it truncates
3009 towards C<0>, and two because machine representations of floating-point
3010 numbers can sometimes produce counterintuitive results.  For example,
3011 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
3012 because it's really more like -268.99999999999994315658 instead.  Usually,
3013 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
3014 functions will serve you better than will int().
3015
3016 =item ioctl FILEHANDLE,FUNCTION,SCALAR
3017 X<ioctl>
3018
3019 =for Pod::Functions system-dependent device control system call
3020
3021 Implements the ioctl(2) function.  You'll probably first have to say
3022
3023     require "sys/ioctl.ph";  # probably in
3024                              # $Config{archlib}/sys/ioctl.ph
3025
3026 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
3027 exist or doesn't have the correct definitions you'll have to roll your
3028 own, based on your C header files such as F<< <sys/ioctl.h> >>.
3029 (There is a Perl script called B<h2ph> that comes with the Perl kit that
3030 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
3031 written depending on the FUNCTION; a C pointer to the string value of SCALAR
3032 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
3033 has no string value but does have a numeric value, that value will be
3034 passed rather than a pointer to the string value.  To guarantee this to be
3035 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
3036 functions may be needed to manipulate the values of structures used by
3037 C<ioctl>.
3038
3039 The return value of C<ioctl> (and C<fcntl>) is as follows:
3040
3041     if OS returns:      then Perl returns:
3042         -1               undefined value
3043          0              string "0 but true"
3044     anything else           that number
3045
3046 Thus Perl returns true on success and false on failure, yet you can
3047 still easily determine the actual value returned by the operating
3048 system:
3049
3050     $retval = ioctl(...) || -1;
3051     printf "System returned %d\n", $retval;
3052
3053 The special string C<"0 but true"> is exempt from B<-w> complaints
3054 about improper numeric conversions.
3055
3056 Portability issues: L<perlport/ioctl>.
3057
3058 =item join EXPR,LIST
3059 X<join>
3060
3061 =for Pod::Functions join a list into a string using a separator
3062
3063 Joins the separate strings of LIST into a single string with fields
3064 separated by the value of EXPR, and returns that new string.  Example:
3065
3066     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
3067
3068 Beware that unlike C<split>, C<join> doesn't take a pattern as its
3069 first argument.  Compare L</split>.
3070
3071 =item keys HASH
3072 X<keys> X<key>
3073
3074 =item keys ARRAY
3075
3076 =item keys EXPR
3077
3078 =for Pod::Functions retrieve list of indices from a hash
3079
3080 Called in list context, returns a list consisting of all the keys of the
3081 named hash, or in Perl 5.12 or later only, the indices of an array.  Perl
3082 releases prior to 5.12 will produce a syntax error if you try to use an
3083 array argument.  In scalar context, returns the number of keys or indices.
3084
3085 The keys of a hash are returned in an apparently random order.  The actual
3086 random order is subject to change in future versions of Perl, but it
3087 is guaranteed to be the same order as either the C<values> or C<each>
3088 function produces (given that the hash has not been modified).  Since
3089 Perl 5.8.1 the ordering can be different even between different runs of
3090 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
3091 Attacks">).
3092
3093 As a side effect, calling keys() resets the internal iterator of the HASH or
3094 ARRAY (see L</each>).  In particular, calling keys() in void context resets
3095 the iterator with no other overhead.
3096
3097 Here is yet another way to print your environment:
3098
3099     @keys = keys %ENV;
3100     @values = values %ENV;
3101     while (@keys) {
3102         print pop(@keys), '=', pop(@values), "\n";
3103     }
3104
3105 or how about sorted by key:
3106
3107     foreach $key (sort(keys %ENV)) {
3108         print $key, '=', $ENV{$key}, "\n";
3109     }
3110
3111 The returned values are copies of the original keys in the hash, so
3112 modifying them will not affect the original hash.  Compare L</values>.
3113
3114 To sort a hash by value, you'll need to use a C<sort> function.
3115 Here's a descending numeric sort of a hash by its values:
3116
3117     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
3118         printf "%4d %s\n", $hash{$key}, $key;
3119     }
3120
3121 Used as an lvalue, C<keys> allows you to increase the number of hash buckets
3122 allocated for the given hash.  This can gain you a measure of efficiency if
3123 you know the hash is going to get big.  (This is similar to pre-extending
3124 an array by assigning a larger number to $#array.)  If you say
3125
3126     keys %hash = 200;
3127
3128 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
3129 in fact, since it rounds up to the next power of two.  These
3130 buckets will be retained even if you do C<%hash = ()>, use C<undef
3131 %hash> if you want to free the storage while C<%hash> is still in scope.
3132 You can't shrink the number of buckets allocated for the hash using
3133 C<keys> in this way (but you needn't worry about doing this by accident,
3134 as trying has no effect).  C<keys @array> in an lvalue context is a syntax
3135 error.
3136
3137 Starting with Perl 5.14, C<keys> can take a scalar EXPR, which must contain
3138 a reference to an unblessed hash or array.  The argument will be
3139 dereferenced automatically.  This aspect of C<keys> is considered highly
3140 experimental.  The exact behaviour may change in a future version of Perl.
3141
3142     for (keys $hashref) { ... }
3143     for (keys $obj->get_arrayref) { ... }
3144
3145 To avoid confusing would-be users of your code who are running earlier
3146 versions of Perl with mysterious syntax errors, put this sort of thing at
3147 the top of your file to signal that your code will work I<only> on Perls of
3148 a recent vintage:
3149
3150     use 5.012;  # so keys/values/each work on arrays
3151     use 5.014;  # so keys/values/each work on scalars (experimental)
3152
3153 See also C<each>, C<values>, and C<sort>.
3154
3155 =item kill SIGNAL, LIST
3156
3157 =item kill SIGNAL
3158 X<kill> X<signal>
3159
3160 =for Pod::Functions send a signal to a process or process group
3161
3162 Sends a signal to a list of processes.  Returns the number of
3163 processes successfully signaled (which is not necessarily the
3164 same as the number actually killed).
3165
3166     $cnt = kill 1, $child1, $child2;
3167     kill 9, @goners;
3168
3169 If SIGNAL is zero, no signal is sent to the process, but C<kill>
3170 checks whether it's I<possible> to send a signal to it (that
3171 means, to be brief, that the process is owned by the same user, or we are
3172 the super-user).  This is useful to check that a child process is still
3173 alive (even if only as a zombie) and hasn't changed its UID.  See
3174 L<perlport> for notes on the portability of this construct.
3175
3176 Unlike in the shell, if SIGNAL is negative, it kills process groups instead
3177 of processes.  That means you usually
3178 want to use positive not negative signals.
3179 You may also use a signal name in quotes.
3180
3181 The behavior of kill when a I<PROCESS> number is zero or negative depends on
3182 the operating system.  For example, on POSIX-conforming systems, zero will
3183 signal the current process group and -1 will signal all processes.
3184
3185 See L<perlipc/"Signals"> for more details.
3186
3187 On some platforms such as Windows where the fork() system call is not available.
3188 Perl can be built to emulate fork() at the interpreter level.
3189 This emulation has limitations related to kill that have to be considered,
3190 for code running on Windows and in code intended to be portable.
3191
3192 See L<perlfork> for more details.
3193
3194 If there is no I<LIST> of processes, no signal is sent, and the return
3195 value is 0.  This form is sometimes used, however, because it causes
3196 tainting checks to be run.  But see
3197 L<perlsec/Laundering and Detecting Tainted Data>.
3198
3199 Portability issues: L<perlport/kill>.
3200
3201 =item last LABEL
3202 X<last> X<break>
3203
3204 =item last
3205
3206 =for Pod::Functions exit a block prematurely
3207
3208 The C<last> command is like the C<break> statement in C (as used in
3209 loops); it immediately exits the loop in question.  If the LABEL is
3210 omitted, the command refers to the innermost enclosing loop.  The
3211 C<continue> block, if any, is not executed:
3212
3213     LINE: while (<STDIN>) {
3214         last LINE if /^$/;  # exit when done with header
3215         #...
3216     }
3217
3218 C<last> cannot be used to exit a block that returns a value such as
3219 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3220 a grep() or map() operation.
3221
3222 Note that a block by itself is semantically identical to a loop
3223 that executes once.  Thus C<last> can be used to effect an early
3224 exit out of such a block.
3225
3226 See also L</continue> for an illustration of how C<last>, C<next>, and
3227 C<redo> work.
3228
3229 =item lc EXPR
3230 X<lc> X<lowercase>
3231
3232 =item lc
3233
3234 =for Pod::Functions return lower-case version of a string
3235
3236 Returns a lowercased version of EXPR.  This is the internal function
3237 implementing the C<\L> escape in double-quoted strings.
3238
3239 If EXPR is omitted, uses C<$_>.
3240
3241 What gets returned depends on several factors:
3242
3243 =over
3244
3245 =item If C<use bytes> is in effect:
3246
3247 =over
3248
3249 =item On EBCDIC platforms
3250
3251 The results are what the C language system call C<tolower()> returns.
3252
3253 =item On ASCII platforms
3254
3255 The results follow ASCII semantics.  Only characters C<A-Z> change, to C<a-z>
3256 respectively.
3257
3258 =back
3259
3260 =item Otherwise, if C<use locale> (but not C<use locale ':not_characters'>) is in effect:
3261
3262 Respects current LC_CTYPE locale for code points < 256; and uses Unicode
3263 semantics for the remaining code points (this last can only happen if
3264 the UTF8 flag is also set).  See L<perllocale>.
3265
3266 A deficiency in this is that case changes that cross the 255/256
3267 boundary are not well-defined.  For example, the lower case of LATIN CAPITAL
3268 LETTER SHARP S (U+1E9E) in Unicode semantics is U+00DF (on ASCII
3269 platforms).   But under C<use locale>, the lower case of U+1E9E is
3270 itself, because 0xDF may not be LATIN SMALL LETTER SHARP S in the
3271 current locale, and Perl has no way of knowing if that character even
3272 exists in the locale, much less what code point it is.  Perl returns
3273 the input character unchanged, for all instances (and there aren't
3274 many) where the 255/256 boundary would otherwise be crossed.
3275
3276 =item Otherwise, If EXPR has the UTF8 flag set:
3277
3278 Unicode semantics are used for the case change.
3279
3280 =item Otherwise, if C<use feature 'unicode_strings'> or C<use locale ':not_characters'>) is in effect:
3281
3282 Unicode semantics are used for the case change.
3283
3284 =item Otherwise:
3285
3286 =over
3287
3288 =item On EBCDIC platforms
3289
3290 The results are what the C language system call C<tolower()> returns.
3291
3292 =item On ASCII platforms
3293
3294 ASCII semantics are used for the case change.  The lowercase of any character
3295 outside the ASCII range is the character itself.
3296
3297 =back
3298
3299 =back
3300
3301 =item lcfirst EXPR
3302 X<lcfirst> X<lowercase>
3303
3304 =item lcfirst
3305
3306 =for Pod::Functions return a string with just the next letter in lower case
3307
3308 Returns the value of EXPR with the first character lowercased.  This
3309 is the internal function implementing the C<\l> escape in
3310 double-quoted strings.
3311
3312 If EXPR is omitted, uses C<$_>.
3313
3314 This function behaves the same way under various pragmata, such as in a locale,
3315 as L</lc> does.
3316
3317 =item length EXPR
3318 X<length> X<size>
3319
3320 =item length
3321
3322 =for Pod::Functions return the number of bytes in a string
3323
3324 Returns the length in I<characters> of the value of EXPR.  If EXPR is
3325 omitted, returns the length of C<$_>.  If EXPR is undefined, returns
3326 C<undef>.
3327
3328 This function cannot be used on an entire array or hash to find out how
3329 many elements these have.  For that, use C<scalar @array> and C<scalar keys
3330 %hash>, respectively.
3331
3332 Like all Perl character operations, length() normally deals in logical
3333 characters, not physical bytes.  For how many bytes a string encoded as
3334 UTF-8 would take up, use C<length(Encode::encode_utf8(EXPR))> (you'll have
3335 to C<use Encode> first).  See L<Encode> and L<perlunicode>.
3336
3337 =item __LINE__
3338 X<__LINE__>
3339
3340 =for Pod::Functions the current source line number
3341
3342 A special token that compiles to the current line number.
3343
3344 =item link OLDFILE,NEWFILE
3345 X<link>
3346
3347 =for Pod::Functions create a hard link in the filesystem
3348
3349 Creates a new filename linked to the old filename.  Returns true for
3350 success, false otherwise.
3351
3352 Portability issues: L<perlport/link>.
3353
3354 =item listen SOCKET,QUEUESIZE
3355 X<listen>
3356
3357 =for Pod::Functions register your socket as a server
3358
3359 Does the same thing that the listen(2) system call does.  Returns true if
3360 it succeeded, false otherwise.  See the example in
3361 L<perlipc/"Sockets: Client/Server Communication">.
3362
3363 =item local EXPR
3364 X<local>
3365
3366 =for Pod::Functions create a temporary value for a global variable (dynamic scoping)
3367
3368 You really probably want to be using C<my> instead, because C<local> isn't
3369 what most people think of as "local".  See
3370 L<perlsub/"Private Variables via my()"> for details.
3371
3372 A local modifies the listed variables to be local to the enclosing
3373 block, file, or eval.  If more than one value is listed, the list must
3374 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
3375 for details, including issues with tied arrays and hashes.
3376
3377 The C<delete local EXPR> construct can also be used to localize the deletion
3378 of array/hash elements to the current block.
3379 See L<perlsub/"Localized deletion of elements of composite types">.
3380
3381 =item localtime EXPR
3382 X<localtime> X<ctime>
3383
3384 =item localtime
3385
3386 =for Pod::Functions convert UNIX time into record or string using local time
3387
3388 Converts a time as returned by the time function to a 9-element list
3389 with the time analyzed for the local time zone.  Typically used as
3390 follows:
3391
3392     #  0    1    2     3     4    5     6     7     8
3393     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
3394                                                 localtime(time);
3395
3396 All list elements are numeric and come straight out of the C `struct
3397 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
3398 of the specified time.
3399
3400 C<$mday> is the day of the month and C<$mon> the month in
3401 the range C<0..11>, with 0 indicating January and 11 indicating December.
3402 This makes it easy to get a month name from a list:
3403
3404     my @abbr = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
3405     print "$abbr[$mon] $mday";
3406     # $mon=9, $mday=18 gives "Oct 18"
3407
3408 C<$year> contains the number of years since 1900.  To get a 4-digit
3409 year write:
3410
3411     $year += 1900;
3412
3413 To get the last two digits of the year (e.g., "01" in 2001) do:
3414
3415     $year = sprintf("%02d", $year % 100);
3416
3417 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
3418 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
3419 (or C<0..365> in leap years.)
3420
3421 C<$isdst> is true if the specified time occurs during Daylight Saving
3422 Time, false otherwise.
3423
3424 If EXPR is omitted, C<localtime()> uses the current time (as returned
3425 by time(3)).
3426
3427 In scalar context, C<localtime()> returns the ctime(3) value:
3428
3429     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
3430
3431 The format of this scalar value is B<not> locale-dependent
3432 but built into Perl.  For GMT instead of local
3433 time use the L</gmtime> builtin.  See also the
3434 C<Time::Local> module (for converting seconds, minutes, hours, and such back to
3435 the integer value returned by time()), and the L<POSIX> module's strftime(3)
3436 and mktime(3) functions.
3437
3438 To get somewhat similar but locale-dependent date strings, set up your
3439 locale environment variables appropriately (please see L<perllocale>) and
3440 try for example:
3441
3442     use POSIX qw(strftime);
3443     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
3444     # or for GMT formatted appropriately for your locale:
3445     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
3446
3447 Note that the C<%a> and C<%b>, the short forms of the day of the week
3448 and the month of the year, may not necessarily be three characters wide.
3449
3450 The L<Time::gmtime> and L<Time::localtime> modules provide a convenient,
3451 by-name access mechanism to the gmtime() and localtime() functions,
3452 respectively.
3453
3454 For a comprehensive date and time representation look at the
3455 L<DateTime> module on CPAN.
3456
3457 Portability issues: L<perlport/localtime>.
3458
3459 =item lock THING
3460 X<lock>
3461
3462 =for Pod::Functions +5.005 get a thread lock on a variable, subroutine, or method
3463
3464 This function places an advisory lock on a shared variable or referenced
3465 object contained in I<THING> until the lock goes out of scope.
3466
3467 The value returned is the scalar itself, if the argument is a scalar, or a
3468 reference, if the argument is a hash, array or subroutine.
3469
3470 lock() is a "weak keyword" : this means that if you've defined a function
3471 by this name (before any calls to it), that function will be called
3472 instead.  If you are not under C<use threads::shared> this does nothing.
3473 See L<threads::shared>.
3474
3475 =item log EXPR
3476 X<log> X<logarithm> X<e> X<ln> X<base>
3477
3478 =item log
3479
3480 =for Pod::Functions retrieve the natural logarithm for a number
3481
3482 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
3483 returns the log of C<$_>.  To get the
3484 log of another base, use basic algebra:
3485 The base-N log of a number is equal to the natural log of that number
3486 divided by the natural log of N.  For example:
3487
3488     sub log10 {
3489         my $n = shift;
3490         return log($n)/log(10);
3491     }
3492
3493 See also L</exp> for the inverse operation.
3494
3495 =item lstat FILEHANDLE
3496 X<lstat>
3497
3498 =item lstat EXPR
3499
3500 =item lstat DIRHANDLE
3501
3502 =item lstat
3503
3504 =for Pod::Functions stat a symbolic link
3505
3506 Does the same thing as the C<stat> function (including setting the
3507 special C<_> filehandle) but stats a symbolic link instead of the file
3508 the symbolic link points to.  If symbolic links are unimplemented on
3509 your system, a normal C<stat> is done.  For much more detailed
3510 information, please see the documentation for C<stat>.
3511
3512 If EXPR is omitted, stats C<$_>.
3513
3514 Portability issues: L<perlport/lstat>.
3515
3516 =item m//
3517
3518 =for Pod::Functions match a string with a regular expression pattern
3519
3520 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
3521
3522 =item map BLOCK LIST
3523 X<map>
3524
3525 =item map EXPR,LIST
3526
3527 =for Pod::Functions apply a change to a list to get back a new list with the changes
3528
3529 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
3530 C<$_> to each element) and returns the list value composed of the
3531 results of each such evaluation.  In scalar context, returns the
3532 total number of elements so generated.  Evaluates BLOCK or EXPR in
3533 list context, so each element of LIST may produce zero, one, or
3534 more elements in the returned value.
3535
3536     @chars = map(chr, @numbers);
3537
3538 translates a list of numbers to the corresponding characters.
3539
3540     my @squares = map { $_ * $_ } @numbers;
3541
3542 translates a list of numbers to their squared values.
3543
3544     my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;
3545
3546 shows that number of returned elements can differ from the number of
3547 input elements.  To omit an element, return an empty list ().
3548 This could also be achieved by writing
3549
3550     my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;
3551
3552 which makes the intention more clear.
3553
3554 Map always returns a list, which can be
3555 assigned to a hash such that the elements
3556 become key/value pairs.  See L<perldata> for more details.
3557
3558     %hash = map { get_a_key_for($_) => $_ } @array;
3559
3560 is just a funny way to write
3561
3562     %hash = ();
3563     foreach (@array) {
3564         $hash{get_a_key_for($_)} = $_;
3565     }
3566
3567 Note that C<$_> is an alias to the list value, so it can be used to
3568 modify the elements of the LIST.  While this is useful and supported,
3569 it can cause bizarre results if the elements of LIST are not variables.
3570 Using a regular C<foreach> loop for this purpose would be clearer in
3571 most cases.  See also L</grep> for an array composed of those items of
3572 the original list for which the BLOCK or EXPR evaluates to true.
3573
3574 If C<$_> is lexical in the scope where the C<map> appears (because it has
3575 been declared with C<my $_>), then, in addition to being locally aliased to
3576 the list elements, C<$_> keeps being lexical inside the block; that is, it
3577 can't be seen from the outside, avoiding any potential side-effects.
3578
3579 C<{> starts both hash references and blocks, so C<map { ...> could be either
3580 the start of map BLOCK LIST or map EXPR, LIST.  Because Perl doesn't look
3581 ahead for the closing C<}> it has to take a guess at which it's dealing with
3582 based on what it finds just after the
3583 C<{>.  Usually it gets it right, but if it
3584 doesn't it won't realize something is wrong until it gets to the C<}> and
3585 encounters the missing (or unexpected) comma.  The syntax error will be
3586 reported close to the C<}>, but you'll need to change something near the C<{>
3587 such as using a unary C<+> to give Perl some help:
3588
3589     %hash = map {  "\L$_" => 1  } @array # perl guesses EXPR. wrong
3590     %hash = map { +"\L$_" => 1  } @array # perl guesses BLOCK. right
3591     %hash = map { ("\L$_" => 1) } @array # this also works
3592     %hash = map {  lc($_) => 1  } @array # as does this.
3593     %hash = map +( lc($_) => 1 ), @array # this is EXPR and works!
3594
3595     %hash = map  ( lc($_), 1 ),   @array # evaluates to (1, @array)
3596
3597 or to force an anon hash constructor use C<+{>:
3598
3599     @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs
3600                                            # comma at end
3601
3602 to get a list of anonymous hashes each with only one entry apiece.
3603
3604 =item mkdir FILENAME,MASK
3605 X<mkdir> X<md> X<directory, create>
3606
3607 =item mkdir FILENAME
3608
3609 =item mkdir
3610
3611 =for Pod::Functions create a directory
3612
3613 Creates the directory specified by FILENAME, with permissions
3614 specified by MASK (as modified by C<umask>).  If it succeeds it
3615 returns true; otherwise it returns false and sets C<$!> (errno).
3616 MASK defaults to 0777 if omitted, and FILENAME defaults
3617 to C<$_> if omitted.
3618
3619 In general, it is better to create directories with a permissive MASK
3620 and let the user modify that with their C<umask> than it is to supply
3621 a restrictive MASK and give the user no way to be more permissive.
3622 The exceptions to this rule are when the file or directory should be
3623 kept private (mail files, for instance).  The perlfunc(1) entry on
3624 C<umask> discusses the choice of MASK in more detail.
3625
3626 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
3627 number of trailing slashes.  Some operating and filesystems do not get
3628 this right, so Perl automatically removes all trailing slashes to keep
3629 everyone happy.
3630
3631 To recursively create a directory structure, look at
3632 the C<mkpath> function of the L<File::Path> module.
3633
3634 =item msgctl ID,CMD,ARG
3635 X<msgctl>
3636
3637 =for Pod::Functions SysV IPC message control operations
3638
3639 Calls the System V IPC function msgctl(2).  You'll probably have to say
3640
3641     use IPC::SysV;
3642
3643 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3644 then ARG must be a variable that will hold the returned C<msqid_ds>
3645 structure.  Returns like C<ioctl>: the undefined value for error,
3646 C<"0 but true"> for zero, or the actual return value otherwise.  See also
3647 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3648 C<IPC::Semaphore>.
3649
3650 Portability issues: L<perlport/msgctl>.
3651
3652 =item msgget KEY,FLAGS
3653 X<msgget>
3654
3655 =for Pod::Functions get SysV IPC message queue
3656
3657 Calls the System V IPC function msgget(2).  Returns the message queue
3658 id, or C<undef> on error.  See also
3659 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3660 C<IPC::Msg>.
3661
3662 Portability issues: L<perlport/msgget>.
3663
3664 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
3665 X<msgrcv>
3666
3667 =for Pod::Functions receive a SysV IPC message from a message queue
3668
3669 Calls the System V IPC function msgrcv to receive a message from
3670 message queue ID into variable VAR with a maximum message size of
3671 SIZE.  Note that when a message is received, the message type as a
3672 native long integer will be the first thing in VAR, followed by the
3673 actual message.  This packing may be opened with C<unpack("l! a*")>.
3674 Taints the variable.  Returns true if successful, false 
3675 on error.  See also L<perlipc/"SysV IPC"> and the documentation for
3676 C<IPC::SysV> and C<IPC::SysV::Msg>.
3677
3678 Portability issues: L<perlport/msgrcv>.
3679
3680 =item msgsnd ID,MSG,FLAGS
3681 X<msgsnd>
3682
3683 =for Pod::Functions send a SysV IPC message to a message queue
3684
3685 Calls the System V IPC function msgsnd to send the message MSG to the
3686 message queue ID.  MSG must begin with the native long integer message
3687 type, be followed by the length of the actual message, and then finally
3688 the message itself.  This kind of packing can be achieved with
3689 C<pack("l! a*", $type, $message)>.  Returns true if successful,
3690 false on error.  See also the C<IPC::SysV>
3691 and C<IPC::SysV::Msg> documentation.
3692
3693 Portability issues: L<perlport/msgsnd>.
3694
3695 =item my EXPR
3696 X<my>
3697
3698 =item my TYPE EXPR
3699
3700 =item my EXPR : ATTRS
3701
3702 =item my TYPE EXPR : ATTRS
3703
3704 =for Pod::Functions declare and assign a local variable (lexical scoping)
3705
3706 A C<my> declares the listed variables to be local (lexically) to the
3707 enclosing block, file, or C<eval>.  If more than one value is listed,
3708 the list must be placed in parentheses.
3709
3710 The exact semantics and interface of TYPE and ATTRS are still
3711 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
3712 and attributes are handled using the C<attributes> pragma, or starting
3713 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3714 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3715 L<attributes>, and L<Attribute::Handlers>.
3716
3717 =item next LABEL
3718 X<next> X<continue>
3719
3720 =item next
3721
3722 =for Pod::Functions iterate a block prematurely
3723
3724 The C<next> command is like the C<continue> statement in C; it starts
3725 the next iteration of the loop:
3726
3727     LINE: while (<STDIN>) {
3728         next LINE if /^#/;  # discard comments
3729         #...
3730     }
3731
3732 Note that if there were a C<continue> block on the above, it would get
3733 executed even on discarded lines.  If LABEL is omitted, the command
3734 refers to the innermost enclosing loop.
3735
3736 C<next> cannot be used to exit a block which returns a value such as
3737 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3738 a grep() or map() operation.
3739
3740 Note that a block by itself is semantically identical to a loop
3741 that executes once.  Thus C<next> will exit such a block early.
3742
3743 See also L</continue> for an illustration of how C<last>, C<next>, and
3744 C<redo> work.
3745
3746 =item no MODULE VERSION LIST
3747 X<no declarations>
3748 X<unimporting>
3749
3750 =item no MODULE VERSION
3751
3752 =item no MODULE LIST
3753
3754 =item no MODULE
3755
3756 =item no VERSION
3757
3758 =for Pod::Functions unimport some module symbols or semantics at compile time
3759
3760 See the C<use> function, of which C<no> is the opposite.
3761
3762 =item oct EXPR
3763 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3764
3765 =item oct
3766
3767 =for Pod::Functions convert a string to an octal number
3768
3769 Interprets EXPR as an octal string and returns the corresponding
3770 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3771 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3772 binary string.  Leading whitespace is ignored in all three cases.)
3773 The following will handle decimal, binary, octal, and hex in standard
3774 Perl notation:
3775
3776     $val = oct($val) if $val =~ /^0/;
3777
3778 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3779 in octal), use sprintf() or printf():
3780
3781     $dec_perms = (stat("filename"))[2] & 07777;
3782     $oct_perm_str = sprintf "%o", $perms;
3783
3784 The oct() function is commonly used when a string such as C<644> needs
3785 to be converted into a file mode, for example.  Although Perl 
3786 automatically converts strings into numbers as needed, this automatic
3787 conversion assumes base 10.
3788
3789 Leading white space is ignored without warning, as too are any trailing 
3790 non-digits, such as a decimal point (C<oct> only handles non-negative
3791 integers, not negative integers or floating point).
3792
3793 =item open FILEHANDLE,EXPR
3794 X<open> X<pipe> X<file, open> X<fopen>
3795
3796 =item open FILEHANDLE,MODE,EXPR
3797
3798 =item open FILEHANDLE,MODE,EXPR,LIST
3799
3800 =item open FILEHANDLE,MODE,REFERENCE
3801
3802 =item open FILEHANDLE
3803
3804 =for Pod::Functions open a file, pipe, or descriptor
3805
3806 Opens the file whose filename is given by EXPR, and associates it with
3807 FILEHANDLE.
3808
3809 Simple examples to open a file for reading:
3810
3811     open(my $fh, "<", "input.txt") 
3812         or die "cannot open < input.txt: $!";
3813
3814 and for writing:
3815
3816     open(my $fh, ">", "output.txt") 
3817         or die "cannot open > output.txt: $!";
3818
3819 (The following is a comprehensive reference to open(): for a gentler
3820 introduction you may consider L<perlopentut>.)
3821
3822 If FILEHANDLE is an undefined scalar variable (or array or hash element), a
3823 new filehandle is autovivified, meaning that the variable is assigned a
3824 reference to a newly allocated anonymous filehandle.  Otherwise if
3825 FILEHANDLE is an expression, its value is the real filehandle.  (This is
3826 considered a symbolic reference, so C<use strict "refs"> should I<not> be
3827 in effect.)
3828
3829 If EXPR is omitted, the global (package) scalar variable of the same
3830 name as the FILEHANDLE contains the filename.  (Note that lexical 
3831 variables--those declared with C<my> or C<state>--will not work for this
3832 purpose; so if you're using C<my> or C<state>, specify EXPR in your
3833 call to open.)
3834
3835 If three (or more) arguments are specified, the open mode (including
3836 optional encoding) in the second argument are distinct from the filename in
3837 the third.  If MODE is C<< < >> or nothing, the file is opened for input.
3838 If MODE is C<< > >>, the file is opened for output, with existing files
3839 first being truncated ("clobbered") and nonexisting files newly created.
3840 If MODE is C<<< >> >>>, the file is opened for appending, again being
3841 created if necessary.
3842
3843 You can put a C<+> in front of the C<< > >> or C<< < >> to
3844 indicate that you want both read and write access to the file; thus
3845 C<< +< >> is almost always preferred for read/write updates--the 
3846 C<< +> >> mode would clobber the file first.  You can't usually use
3847 either read-write mode for updating textfiles, since they have
3848 variable-length records.  See the B<-i> switch in L<perlrun> for a
3849 better approach.  The file is created with permissions of C<0666>
3850 modified by the process's C<umask> value.
3851
3852 These various prefixes correspond to the fopen(3) modes of C<r>,
3853 C<r+>, C<w>, C<w+>, C<a>, and C<a+>.
3854
3855 In the one- and two-argument forms of the call, the mode and filename
3856 should be concatenated (in that order), preferably separated by white
3857 space.  You can--but shouldn't--omit the mode in these forms when that mode
3858 is C<< < >>.  It is always safe to use the two-argument form of C<open> if
3859 the filename argument is a known literal.
3860
3861 For three or more arguments if MODE is C<|->, the filename is
3862 interpreted as a command to which output is to be piped, and if MODE
3863 is C<-|>, the filename is interpreted as a command that pipes
3864 output to us.  In the two-argument (and one-argument) form, one should
3865 replace dash (C<->) with the command.
3866 See L<perlipc/"Using open() for IPC"> for more examples of this.
3867 (You are not allowed to C<open> to a command that pipes both in I<and>
3868 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3869 L<perlipc/"Bidirectional Communication with Another Process"> for
3870 alternatives.)
3871
3872 In the form of pipe opens taking three or more arguments, if LIST is specified
3873 (extra arguments after the command name) then LIST becomes arguments
3874 to the command invoked if the platform supports it.  The meaning of
3875 C<open> with more than three arguments for non-pipe modes is not yet
3876 defined, but experimental "layers" may give extra LIST arguments
3877 meaning.
3878
3879 In the two-argument (and one-argument) form, opening C<< <- >> 
3880 or C<-> opens STDIN and opening C<< >- >> opens STDOUT.
3881
3882 You may (and usually should) use the three-argument form of open to specify
3883 I/O layers (sometimes referred to as "disciplines") to apply to the handle
3884 that affect how the input and output are processed (see L<open> and
3885 L<PerlIO> for more details).  For example:
3886
3887   open(my $fh, "<:encoding(UTF-8)", "filename")
3888     || die "can't open UTF-8 encoded filename: $!";
3889
3890 opens the UTF8-encoded file containing Unicode characters;
3891 see L<perluniintro>.  Note that if layers are specified in the
3892 three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>;
3893 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3894 Those layers will also be ignored if you specifying a colon with no name
3895 following it.  In that case the default layer for the operating system
3896 (:raw on Unix, :crlf on Windows) is used.
3897
3898 Open returns nonzero on success, the undefined value otherwise.  If
3899 the C<open> involved a pipe, the return value happens to be the pid of
3900 the subprocess.
3901
3902 If you're running Perl on a system that distinguishes between text
3903 files and binary files, then you should check out L</binmode> for tips
3904 for dealing with this.  The key distinction between systems that need
3905 C<binmode> and those that don't is their text file formats.  Systems
3906 like Unix, Mac OS, and Plan 9, that end lines with a single
3907 character and encode that character in C as C<"\n"> do not
3908 need C<binmode>.  The rest need it.
3909
3910 When opening a file, it's seldom a good idea to continue 
3911 if the request failed, so C<open> is frequently used with
3912 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3913 where you want to format a suitable error message (but there are
3914 modules that can help with that problem)) always check
3915 the return value from opening a file.  
3916
3917 As a special case the three-argument form with a read/write mode and the third
3918 argument being C<undef>:
3919
3920     open(my $tmp, "+>", undef) or die ...
3921
3922 opens a filehandle to an anonymous temporary file.  Also using C<< +< >>
3923 works for symmetry, but you really should consider writing something
3924 to the temporary file first.  You will need to seek() to do the
3925 reading.
3926
3927 Since v5.8.0, Perl has built using PerlIO by default.  Unless you've
3928 changed this (such as building Perl with C<Configure -Uuseperlio>), you can
3929 open filehandles directly to Perl scalars via:
3930
3931     open($fh, ">", \$variable) || ..
3932
3933 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
3934
3935     close STDOUT;
3936     open(STDOUT, ">", \$variable)
3937         or die "Can't open STDOUT: $!";
3938
3939 General examples:
3940
3941     $ARTICLE = 100;
3942     open(ARTICLE) or die "Can't find article $ARTICLE: $!\n";
3943     while (<ARTICLE>) {...
3944
3945     open(LOG, ">>/usr/spool/news/twitlog");  # (log is reserved)
3946     # if the open fails, output is discarded
3947
3948     open(my $dbase, "+<", "dbase.mine")      # open for update
3949         or die "Can't open 'dbase.mine' for update: $!";
3950
3951     open(my $dbase, "+<dbase.mine")          # ditto
3952         or die "Can't open 'dbase.mine' for update: $!";
3953
3954     open(ARTICLE, "-|", "caesar <$article")  # decrypt article
3955         or die "Can't start caesar: $!";
3956
3957     open(ARTICLE, "caesar <$article |")      # ditto
3958         or die "Can't start caesar: $!";
3959
3960     open(EXTRACT, "|sort >Tmp$$")            # $$ is our process id
3961         or die "Can't start sort: $!";
3962
3963     # in-memory files
3964     open(MEMORY, ">", \$var)
3965         or die "Can't open memory file: $!";
3966     print MEMORY "foo!\n";              # output will appear in $var
3967
3968     # process argument list of files along with any includes
3969
3970     foreach $file (@ARGV) {
3971         process($file, "fh00");
3972     }
3973
3974     sub process {
3975         my($filename, $input) = @_;
3976         $input++;    # this is a string increment
3977         unless (open($input, "<", $filename)) {
3978             print STDERR "Can't open $filename: $!\n";
3979             return;
3980         }
3981
3982         local $_;
3983         while (<$input>) {    # note use of indirection
3984             if (/^#include "(.*)"/) {
3985                 process($1, $input);
3986                 next;
3987             }
3988             #...          # whatever
3989         }
3990     }
3991
3992 See L<perliol> for detailed info on PerlIO.
3993
3994 You may also, in the Bourne shell tradition, specify an EXPR beginning
3995 with C<< >& >>, in which case the rest of the string is interpreted
3996 as the name of a filehandle (or file descriptor, if numeric) to be
3997 duped (as C<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3998 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3999 The mode you specify should match the mode of the original filehandle.
4000 (Duping a filehandle does not take into account any existing contents
4001 of IO buffers.)  If you use the three-argument
4002 form, then you can pass either a
4003 number, the name of a filehandle, or the normal "reference to a glob".
4004
4005 Here is a script that saves, redirects, and restores C<STDOUT> and
4006 C<STDERR> using various methods:
4007
4008     #!/usr/bin/perl
4009     open(my $oldout, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4010     open(OLDERR,     ">&", \*STDERR) or die "Can't dup STDERR: $!";
4011
4012     open(STDOUT, '>', "foo.out") or die "Can't redirect STDOUT: $!";
4013     open(STDERR, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4014
4015     select STDERR; $| = 1;  # make unbuffered
4016     select STDOUT; $| = 1;  # make unbuffered
4017
4018     print STDOUT "stdout 1\n";  # this works for
4019     print STDERR "stderr 1\n";  # subprocesses too
4020
4021     open(STDOUT, ">&", $oldout) or die "Can't dup \$oldout: $!";
4022     open(STDERR, ">&OLDERR")    or die "Can't dup OLDERR: $!";
4023
4024     print STDOUT "stdout 2\n";
4025     print STDERR "stderr 2\n";
4026
4027 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
4028 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
4029 that file descriptor (and not call C<dup(2)>); this is more
4030 parsimonious of file descriptors.  For example:
4031
4032     # open for input, reusing the fileno of $fd
4033     open(FILEHANDLE, "<&=$fd")
4034
4035 or
4036
4037     open(FILEHANDLE, "<&=", $fd)
4038
4039 or
4040
4041     # open for append, using the fileno of OLDFH
4042     open(FH, ">>&=", OLDFH)
4043
4044 or
4045
4046     open(FH, ">>&=OLDFH")
4047
4048 Being parsimonious on filehandles is also useful (besides being
4049 parsimonious) for example when something is dependent on file
4050 descriptors, like for example locking using flock().  If you do just
4051 C<< open(A, ">>&B") >>, the filehandle A will not have the same file
4052 descriptor as B, and therefore flock(A) will not flock(B) nor vice
4053 versa.  But with C<< open(A, ">>&=B") >>, the filehandles will share
4054 the same underlying system file descriptor.
4055
4056 Note that under Perls older than 5.8.0, Perl uses the standard C library's'
4057 fdopen() to implement the C<=> functionality.  On many Unix systems,
4058 fdopen() fails when file descriptors exceed a certain value, typically 255.
4059 For Perls 5.8.0 and later, PerlIO is (most often) the default.
4060
4061 You can see whether your Perl was built with PerlIO by running C<perl -V>
4062 and looking for the C<useperlio=> line.  If C<useperlio> is C<define>, you
4063 have PerlIO; otherwise you don't.
4064
4065 If you open a pipe on the command C<-> (that is, specify either C<|-> or C<-|>
4066 with the one- or two-argument forms of C<open>), 
4067 an implicit C<fork> is done, so C<open> returns twice: in the parent
4068 process it returns the pid
4069 of the child process, and in the child process it returns (a defined) C<0>.
4070 Use C<defined($pid)> or C<//> to determine whether the open was successful.
4071
4072 For example, use either
4073
4074     $child_pid = open(FROM_KID, "-|")   // die "can't fork: $!";
4075
4076 or
4077
4078     $child_pid = open(TO_KID,   "|-")   // die "can't fork: $!";
4079
4080 followed by 
4081
4082     if ($child_pid) {
4083         # am the parent:
4084         # either write TO_KID or else read FROM_KID
4085         ...
4086        waitpid $child_pid, 0;
4087     } else {
4088         # am the child; use STDIN/STDOUT normally
4089         ...
4090         exit;
4091     } 
4092
4093 The filehandle behaves normally for the parent, but I/O to that
4094 filehandle is piped from/to the STDOUT/STDIN of the child process.
4095 In the child process, the filehandle isn't opened--I/O happens from/to
4096 the new STDOUT/STDIN.  Typically this is used like the normal
4097 piped open when you want to exercise more control over just how the
4098 pipe command gets executed, such as when running setuid and
4099 you don't want to have to scan shell commands for metacharacters.
4100
4101 The following blocks are more or less equivalent:
4102
4103     open(FOO, "|tr '[a-z]' '[A-Z]'");
4104     open(FOO, "|-", "tr '[a-z]' '[A-Z]'");
4105     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
4106     open(FOO, "|-", "tr", '[a-z]', '[A-Z]');
4107
4108     open(FOO, "cat -n '$file'|");
4109     open(FOO, "-|", "cat -n '$file'");
4110     open(FOO, "-|") || exec "cat", "-n", $file;
4111     open(FOO, "-|", "cat", "-n", $file);
4112
4113 The last two examples in each block show the pipe as "list form", which is
4114 not yet supported on all platforms.  A good rule of thumb is that if
4115 your platform has a real C<fork()> (in other words, if your platform is
4116 Unix, including Linux and MacOS X), you can use the list form.  You would 
4117 want to use the list form of the pipe so you can pass literal arguments
4118 to the command without risk of the shell interpreting any shell metacharacters
4119 in them.  However, this also bars you from opening pipes to commands
4120 that intentionally contain shell metacharacters, such as:
4121
4122     open(FOO, "|cat -n | expand -4 | lpr")
4123         // die "Can't open pipeline to lpr: $!";
4124
4125 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
4126
4127 Beginning with v5.6.0, Perl will attempt to flush all files opened for
4128 output before any operation that may do a fork, but this may not be
4129 supported on some platforms (see L<perlport>).  To be safe, you may need
4130 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
4131 of C<IO::Handle> on any open handles.
4132
4133 On systems that support a close-on-exec flag on files, the flag will
4134 be set for the newly opened file descriptor as determined by the value
4135 of C<$^F>.  See L<perlvar/$^F>.
4136
4137 Closing any piped filehandle causes the parent process to wait for the
4138 child to finish, then returns the status value in C<$?> and
4139 C<${^CHILD_ERROR_NATIVE}>.
4140
4141 The filename passed to the one- and two-argument forms of open() will
4142 have leading and trailing whitespace deleted and normal
4143 redirection characters honored.  This property, known as "magic open",
4144 can often be used to good effect.  A user could specify a filename of
4145 F<"rsh cat file |">, or you could change certain filenames as needed:
4146
4147     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
4148     open(FH, $filename) or die "Can't open $filename: $!";
4149
4150 Use the three-argument form to open a file with arbitrary weird characters in it,
4151
4152     open(FOO, "<", $file)
4153         || die "can't open < $file: $!";
4154
4155 otherwise it's necessary to protect any leading and trailing whitespace:
4156
4157     $file =~ s#^(\s)#./$1#;
4158     open(FOO, "< $file\0")
4159         || die "open failed: $!";
4160
4161 (this may not work on some bizarre filesystems).  One should
4162 conscientiously choose between the I<magic> and I<three-argument> form
4163 of open():
4164
4165     open(IN, $ARGV[0]) || die "can't open $ARGV[0]: $!";
4166
4167 will allow the user to specify an argument of the form C<"rsh cat file |">,
4168 but will not work on a filename that happens to have a trailing space, while
4169
4170     open(IN, "<", $ARGV[0])
4171         || die "can't open < $ARGV[0]: $!";
4172
4173 will have exactly the opposite restrictions.
4174
4175 If you want a "real" C C<open> (see L<open(2)> on your system), then you
4176 should use the C<sysopen> function, which involves no such magic (but may
4177 use subtly different filemodes than Perl open(), which is mapped to C
4178 fopen()).  This is another way to protect your filenames from
4179 interpretation.  For example:
4180
4181     use IO::Handle;
4182     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
4183         or die "sysopen $path: $!";
4184     $oldfh = select(HANDLE); $| = 1; select($oldfh);
4185     print HANDLE "stuff $$\n";
4186     seek(HANDLE, 0, 0);
4187     print "File contains: ", <HANDLE>;
4188
4189 Using the constructor from the C<IO::Handle> package (or one of its
4190 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
4191 filehandles that have the scope of the variables used to hold them, then
4192 automatically (but silently) close once their reference counts become
4193 zero, typically at scope exit:
4194
4195     use IO::File;
4196     #...
4197     sub read_myfile_munged {
4198         my $ALL = shift;
4199         # or just leave it undef to autoviv
4200         my $handle = IO::File->new;
4201         open($handle, "<", "myfile") or die "myfile: $!";
4202         $first = <$handle>
4203             or return ();     # Automatically closed here.
4204         mung($first) or die "mung failed";  # Or here.
4205         return (first, <$handle>) if $ALL;  # Or here.
4206         return $first;                      # Or here.
4207     }
4208
4209 B<WARNING:> The previous example has a bug because the automatic
4210 close that happens when the refcount on C<handle> reaches zero does not
4211 properly detect and report failures.  I<Always> close the handle
4212 yourself and inspect the return value.
4213
4214     close($handle) 
4215         || warn "close failed: $!";
4216
4217 See L</seek> for some details about mixing reading and writing.
4218
4219 Portability issues: L<perlport/open>.
4220
4221 =item opendir DIRHANDLE,EXPR
4222 X<opendir>
4223
4224 =for Pod::Functions open a directory
4225
4226 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
4227 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
4228 DIRHANDLE may be an expression whose value can be used as an indirect
4229 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
4230 scalar variable (or array or hash element), the variable is assigned a
4231 reference to a new anonymous dirhandle; that is, it's autovivified.
4232 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
4233
4234 See the example at C<readdir>.
4235
4236 =item ord EXPR
4237 X<ord> X<encoding>
4238
4239 =item ord
4240
4241 =for Pod::Functions find a character's numeric representation
4242
4243 Returns the numeric value of the first character of EXPR.
4244 If EXPR is an empty string, returns 0.  If EXPR is omitted, uses C<$_>.
4245 (Note I<character>, not byte.)
4246
4247 For the reverse, see L</chr>.
4248 See L<perlunicode> for more about Unicode.
4249
4250 =item our EXPR
4251 X<our> X<global>
4252
4253 =item our TYPE EXPR
4254
4255 =item our EXPR : ATTRS
4256
4257 =item our TYPE EXPR : ATTRS
4258
4259 =for Pod::Functions +5.6.0 declare and assign a package variable (lexical scoping)
4260
4261 C<our> associates a simple name with a package variable in the current
4262 package for use within the current scope.  When C<use strict 'vars'> is in
4263 effect, C<our> lets you use declared global variables without qualifying
4264 them with package names, within the lexical scope of the C<our> declaration.
4265 In this way C<our> differs from C<use vars>, which is package-scoped.
4266
4267 Unlike C<my> or C<state>, which allocates storage for a variable and
4268 associates a simple name with that storage for use within the current
4269 scope, C<our> associates a simple name with a package (read: global)
4270 variable in the current package, for use within the current lexical scope.
4271 In other words, C<our> has the same scoping rules as C<my> or C<state>, but
4272 does not necessarily create a variable.
4273
4274 If more than one value is listed, the list must be placed
4275 in parentheses.
4276
4277     our $foo;
4278     our($bar, $baz);
4279
4280 An C<our> declaration declares a global variable that will be visible
4281 across its entire lexical scope, even across package boundaries.  The
4282 package in which the variable is entered is determined at the point
4283 of the declaration, not at the point of use.  This means the following
4284 behavior holds:
4285
4286     package Foo;
4287     our $bar;      # declares $Foo::bar for rest of lexical scope
4288     $bar = 20;
4289
4290     package Bar;
4291     print $bar;    # prints 20, as it refers to $Foo::bar
4292
4293 Multiple C<our> declarations with the same name in the same lexical
4294 scope are allowed if they are in different packages.  If they happen
4295 to be in the same package, Perl will emit warnings if you have asked
4296 for them, just like multiple C<my> declarations.  Unlike a second
4297 C<my> declaration, which will bind the name to a fresh variable, a
4298 second C<our> declaration in the same package, in the same scope, is
4299 merely redundant.
4300
4301     use warnings;
4302     package Foo;
4303     our $bar;      # declares $Foo::bar for rest of lexical scope
4304     $bar = 20;
4305
4306     package Bar;
4307     our $bar = 30; # declares $Bar::bar for rest of lexical scope
4308     print $bar;    # prints 30
4309
4310     our $bar;      # emits warning but has no other effect
4311     print $bar;    # still prints 30
4312
4313 An C<our> declaration may also have a list of attributes associated
4314 with it.
4315
4316 The exact semantics and interface of TYPE and ATTRS are still
4317 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
4318 and attributes are handled using the C<attributes> pragma, or, starting
4319 from Perl 5.8.0, also via the C<Attribute::Handlers> module.  See
4320 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
4321 L<attributes>, and L<Attribute::Handlers>.
4322
4323 =item pack TEMPLATE,LIST
4324 X<pack>
4325
4326 =for Pod::Functions convert a list into a binary representation
4327
4328 Takes a LIST of values and converts it into a string using the rules
4329 given by the TEMPLATE.  The resulting string is the concatenation of
4330 the converted values.  Typically, each converted value looks
4331 like its machine-level representation.  For example, on 32-bit machines
4332 an integer may be represented by a sequence of 4 bytes, which  will in
4333 Perl be presented as a string that's 4 characters long. 
4334
4335 See L<perlpacktut> for an introduction to this function.
4336
4337 The TEMPLATE is a sequence of characters that give the order and type
4338 of values, as follows:
4339
4340     a  A string with arbitrary binary data, will be null padded.
4341     A  A text (ASCII) string, will be space padded.
4342     Z  A null-terminated (ASCIZ) string, will be null padded.
4343
4344     b  A bit string (ascending bit order inside each byte,
4345        like vec()).
4346     B  A bit string (descending bit order inside each byte).
4347     h  A hex string (low nybble first).
4348     H  A hex string (high nybble first).
4349
4350     c  A signed char (8-bit) value.
4351     C  An unsigned char (octet) value.
4352     W  An unsigned char value (can be greater than 255).
4353
4354     s  A signed short (16-bit) value.
4355     S  An unsigned short value.
4356
4357     l  A signed long (32-bit) value.
4358     L  An unsigned long value.
4359
4360     q  A signed quad (64-bit) value.
4361     Q  An unsigned quad value.
4362          (Quads are available only if your system supports 64-bit
4363           integer values _and_ if Perl has been compiled to support
4364           those.  Raises an exception otherwise.)
4365
4366     i  A signed integer value.
4367     I  A unsigned integer value.
4368          (This 'integer' is _at_least_ 32 bits wide.  Its exact
4369           size depends on what a local C compiler calls 'int'.)
4370
4371     n  An unsigned short (16-bit) in "network" (big-endian) order.
4372     N  An unsigned long (32-bit) in "network" (big-endian) order.
4373     v  An unsigned short (16-bit) in "VAX" (little-endian) order.
4374     V  An unsigned long (32-bit) in "VAX" (little-endian) order.
4375
4376     j  A Perl internal signed integer value (IV).
4377     J  A Perl internal unsigned integer value (UV).
4378
4379     f  A single-precision float in native format.
4380     d  A double-precision float in native format.
4381
4382     F  A Perl internal floating-point value (NV) in native format
4383     D  A float of long-double precision in native format.
4384          (Long doubles are available only if your system supports
4385           long double values _and_ if Perl has been compiled to
4386           support those.  Raises an exception otherwise.)
4387
4388     p  A pointer to a null-terminated string.
4389     P  A pointer to a structure (fixed-length string).
4390
4391     u  A uuencoded string.
4392     U  A Unicode character number.  Encodes to a character in char-
4393        acter mode and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in
4394        byte mode.
4395
4396     w  A BER compressed integer (not an ASN.1 BER, see perlpacktut
4397        for details).  Its bytes represent an unsigned integer in
4398        base 128, most significant digit first, with as few digits
4399        as possible.  Bit eight (the high bit) is set on each byte
4400        except the last.
4401
4402     x  A null byte (a.k.a ASCII NUL, "\000", chr(0))
4403     X  Back up a byte.
4404     @  Null-fill or truncate to absolute position, counted from the
4405        start of the innermost ()-group.
4406     .  Null-fill or truncate to absolute position specified by
4407        the value.
4408     (  Start of a ()-group.
4409
4410 One or more modifiers below may optionally follow certain letters in the
4411 TEMPLATE (the second column lists letters for which the modifier is valid):
4412
4413     !   sSlLiI     Forces native (short, long, int) sizes instead
4414                    of fixed (16-/32-bit) sizes.
4415
4416         xX         Make x and X act as alignment commands.
4417
4418         nNvV       Treat integers as signed instead of unsigned.
4419
4420         @.         Specify position as byte offset in the internal
4421                    representation of the packed string.  Efficient
4422                    but dangerous.
4423
4424     >   sSiIlLqQ   Force big-endian byte-order on the type.
4425         jJfFdDpP   (The "big end" touches the construct.)
4426
4427     <   sSiIlLqQ   Force little-endian byte-order on the type.
4428         jJfFdDpP   (The "little end" touches the construct.)
4429
4430 The C<< > >> and C<< < >> modifiers can also be used on C<()> groups 
4431 to force a particular byte-order on all components in that group, 
4432 including all its subgroups.
4433
4434 The following rules apply:
4435
4436 =over 
4437
4438 =item *
4439
4440 Each letter may optionally be followed by a number indicating the repeat
4441 count.  A numeric repeat count may optionally be enclosed in brackets, as
4442 in C<pack("C[80]", @arr)>.  The repeat count gobbles that many values from
4443 the LIST when used with all format types other than C<a>, C<A>, C<Z>, C<b>,
4444 C<B>, C<h>, C<H>, C<@>, C<.>, C<x>, C<X>, and C<P>, where it means
4445 something else, described below.  Supplying a C<*> for the repeat count
4446 instead of a number means to use however many items are left, except for:
4447
4448 =over 
4449
4450 =item * 
4451
4452 C<@>, C<x>, and C<X>, where it is equivalent to C<0>.
4453
4454 =item * 
4455
4456 <.>, where it means relative to the start of the string.
4457
4458 =item * 
4459
4460 C<u>, where it is equivalent to 1 (or 45, which here is equivalent).
4461
4462 =back 
4463
4464 One can replace a numeric repeat count with a template letter enclosed in
4465 brackets to use the packed byte length of the bracketed template for the
4466 repeat count.
4467
4468 For example, the template C<x[L]> skips as many bytes as in a packed long,
4469 and the template C<"$t X[$t] $t"> unpacks twice whatever $t (when
4470 variable-expanded) unpacks.  If the template in brackets contains alignment
4471 commands (such as C<x![d]>), its packed length is calculated as if the
4472 start of the template had the maximal possible alignment.
4473
4474 When used with C<Z>, a C<*> as the repeat count is guaranteed to add a
4475 trailing null byte, so the resulting string is always one byte longer than
4476 the byte length of the item itself.
4477
4478 When used with C<@>, the repeat count represents an offset from the start
4479 of the innermost C<()> group.
4480
4481 When used with C<.>, the repeat count determines the starting position to
4482 calculate the value offset as follows:
4483
4484 =over 
4485
4486 =item *
4487
4488 If the repeat count is C<0>, it's relative to the current position.
4489
4490 =item *
4491
4492 If the repeat count is C<*>, the offset is relative to the start of the
4493 packed string.
4494
4495 =item *
4496
4497 And if it's an integer I<n>, the offset is relative to the start of the
4498 I<n>th innermost C<( )> group, or to the start of the string if I<n> is
4499 bigger then the group level.
4500
4501 =back
4502
4503 The repeat count for C<u> is interpreted as the maximal number of bytes
4504 to encode per line of output, with 0, 1 and 2 replaced by 45.  The repeat 
4505 count should not be more than 65.
4506
4507 =item *
4508
4509 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
4510 string of length count, padding with nulls or spaces as needed.  When
4511 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
4512 after the first null, and C<a> returns data with no stripping at all.
4513
4514 If the value to pack is too long, the result is truncated.  If it's too
4515 long and an explicit count is provided, C<Z> packs only C<$count-1> bytes,
4516 followed by a null byte.  Thus C<Z> always packs a trailing null, except
4517 when the count is 0.
4518
4519 =item *
4520
4521 Likewise, the C<b> and C<B> formats pack a string that's that many bits long.
4522 Each such format generates 1 bit of the result.  These are typically followed
4523 by a repeat count like C<B8> or C<B64>.
4524
4525 Each result bit is based on the least-significant bit of the corresponding
4526 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
4527 and C<"1"> generate bits 0 and 1, as do characters C<"\000"> and C<"\001">.
4528
4529 Starting from the beginning of the input string, each 8-tuple
4530 of characters is converted to 1 character of output.  With format C<b>,
4531 the first character of the 8-tuple determines the least-significant bit of a
4532 character; with format C<B>, it determines the most-significant bit of
4533 a character.
4534
4535 If the length of the input string is not evenly divisible by 8, the
4536 remainder is packed as if the input string were padded by null characters
4537 at the end.  Similarly during unpacking, "extra" bits are ignored.
4538
4539 If the input string is longer than needed, remaining characters are ignored.
4540
4541 A C<*> for the repeat count uses all characters of the input field.  
4542 On unpacking, bits are converted to a string of C<0>s and C<1>s.
4543
4544 =item *
4545
4546 The C<h> and C<H> formats pack a string that many nybbles (4-bit groups,
4547 representable as hexadecimal digits, C<"0".."9"> C<"a".."f">) long.
4548
4549 For each such format, pack() generates 4 bits of result.
4550 With non-alphabetical characters, the result is based on the 4 least-significant
4551 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
4552 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
4553 C<"\000"> and C<"\001">.  For characters C<"a".."f"> and C<"A".."F">, the result
4554 is compatible with the usual hexadecimal digits, so that C<"a"> and
4555 C<"A"> both generate the nybble C<0xA==10>.  Use only these specific hex 
4556 characters with this format.
4557
4558 Starting from the beginning of the template to pack(), each pair
4559 of characters is converted to 1 character of output.  With format C<h>, the
4560 first character of the pair determines the least-significant nybble of the
4561 output character; with format C<H>, it determines the most-significant
4562 nybble.
4563
4564 If the length of the input string is not even, it behaves as if padded by
4565 a null character at the end.  Similarly, "extra" nybbles are ignored during
4566 unpacking.
4567
4568 If the input string is longer than needed, extra characters are ignored.
4569
4570 A C<*> for the repeat count uses all characters of the input field.  For
4571 unpack(), nybbles are converted to a string of hexadecimal digits.
4572
4573 =item *
4574
4575 The C<p> format packs a pointer to a null-terminated string.  You are
4576 responsible for ensuring that the string is not a temporary value, as that
4577 could potentially get deallocated before you got around to using the packed
4578 result.  The C<P> format packs a pointer to a structure of the size indicated
4579 by the length.  A null pointer is created if the corresponding value for
4580 C<p> or C<P> is C<undef>; similarly with unpack(), where a null pointer
4581 unpacks into C<undef>.
4582
4583 If your system has a strange pointer size--meaning a pointer is neither as
4584 big as an int nor as big as a long--it may not be possible to pack or
4585 unpack pointers in big- or little-endian byte order.  Attempting to do
4586 so raises an exception.
4587
4588 =item *
4589
4590 The C</> template character allows packing and unpacking of a sequence of
4591 items where the packed structure contains a packed item count followed by
4592 the packed items themselves.  This is useful when the structure you're
4593 unpacking has encoded the sizes or repeat counts for some of its fields
4594 within the structure itself as separate fields.
4595
4596 For C<pack>, you write I<length-item>C</>I<sequence-item>, and the
4597 I<length-item> describes how the length value is packed.  Formats likely
4598 to be of most use are integer-packing ones like C<n> for Java strings,
4599 C<w> for ASN.1 or SNMP, and C<N> for Sun XDR.
4600
4601 For C<pack>, I<sequence-item> may have a repeat count, in which case
4602 the minimum of that and the number of available items is used as the argument
4603 for I<length-item>.  If it has no repeat count or uses a '*', the number
4604 of available items is used.
4605
4606 For C<unpack>, an internal stack of integer arguments unpacked so far is
4607 used.  You write C</>I<sequence-item> and the repeat count is obtained by
4608 popping off the last element from the stack.  The I<sequence-item> must not
4609 have a repeat count.
4610
4611 If I<sequence-item> refers to a string type (C<"A">, C<"a">, or C<"Z">),
4612 the I<length-item> is the string length, not the number of strings.  With
4613 an explicit repeat count for pack, the packed string is adjusted to that
4614 length.  For example:
4615
4616  This code:                             gives this result:
4617  
4618  unpack("W/a", "\004Gurusamy")          ("Guru")
4619  unpack("a3/A A*", "007 Bond  J ")      (" Bond", "J")
4620  unpack("a3 x2 /A A*", "007: Bond, J.") ("Bond, J", ".")
4621
4622  pack("n/a* w/a","hello,","world")     "\000\006hello,\005world"
4623  pack("a/W2", ord("a") .. ord("z"))    "2ab"
4624
4625 The I<length-item> is not returned explicitly from C<unpack>.
4626
4627 Supplying a count to the I<length-item> format letter is only useful with
4628 C<A>, C<a>, or C<Z>.  Packing with a I<length-item> of C<a> or C<Z> may
4629 introduce C<"\000"> characters, which Perl does not regard as legal in
4630 numeric strings.
4631
4632 =item *
4633
4634 The integer types C<s>, C<S>, C<l>, and C<L> may be
4635 followed by a C<!> modifier to specify native shorts or
4636 longs.  As shown in the example above, a bare C<l> means
4637 exactly 32 bits, although the native C<long> as seen by the local C compiler
4638 may be larger.  This is mainly an issue on 64-bit platforms.  You can
4639 see whether using C<!> makes any difference this way:
4640
4641     printf "format s is %d, s! is %d\n", 
4642         length pack("s"), length pack("s!");
4643
4644     printf "format l is %d, l! is %d\n", 
4645         length pack("l"), length pack("l!");
4646
4647
4648 C<i!> and C<I!> are also allowed, but only for completeness' sake:
4649 they are identical to C<i> and C<I>.
4650
4651 The actual sizes (in bytes) of native shorts, ints, longs, and long
4652 longs on the platform where Perl was built are also available from
4653 the command line:
4654
4655     $ perl -V:{short,int,long{,long}}size
4656     shortsize='2';
4657     intsize='4';
4658     longsize='4';
4659     longlongsize='8';
4660
4661 or programmatically via the C<Config> module:
4662
4663        use Config;
4664        print $Config{shortsize},    "\n";
4665        print $Config{intsize},      "\n";
4666        print $Config{longsize},     "\n";
4667        print $Config{longlongsize}, "\n";
4668
4669 C<$Config{longlongsize}> is undefined on systems without 
4670 long long support.
4671
4672 =item *
4673
4674 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J> are
4675 inherently non-portable between processors and operating systems because
4676 they obey native byteorder and endianness.  For example, a 4-byte integer
4677 0x12345678 (305419896 decimal) would be ordered natively (arranged in and
4678 handled by the CPU registers) into bytes as
4679
4680     0x12 0x34 0x56 0x78  # big-endian
4681     0x78 0x56 0x34 0x12  # little-endian
4682
4683 Basically, Intel and VAX CPUs are little-endian, while everybody else,
4684 including Motorola m68k/88k, PPC, Sparc, HP PA, Power, and Cray, are
4685 big-endian.  Alpha and MIPS can be either: Digital/Compaq uses (well, used) 
4686 them in little-endian mode, but SGI/Cray uses them in big-endian mode.
4687
4688 The names I<big-endian> and I<little-endian> are comic references to the
4689 egg-eating habits of the little-endian Lilliputians and the big-endian
4690 Blefuscudians from the classic Jonathan Swift satire, I<Gulliver's Travels>.
4691 This entered computer lingo via the paper "On Holy Wars and a Plea for
4692 Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980.
4693
4694 Some systems may have even weirder byte orders such as
4695
4696    0x56 0x78 0x12 0x34
4697    0x34 0x12 0x78 0x56
4698
4699 You can determine your system endianness with this incantation:
4700
4701    printf("%#02x ", $_) for unpack("W*", pack L=>0x12345678); 
4702
4703 The byteorder on the platform where Perl was built is also available
4704 via L<Config>:
4705
4706     use Config;
4707     print "$Config{byteorder}\n";
4708