This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Well defined $? and introduction of ${^CHILD_ERROR_NATIVE} [PATCH]
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 A named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over 4
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
140 C<umask>, C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<our>, C<prototype>,
204 C<qx>, C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
228 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<socket>, C<socketpair>,
238 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
239 C<times>, C<truncate>, C<umask>, C<unlink>,
240 C<utime>, C<wait>, C<waitpid>
241
242 For more information about the portability of these functions, see
243 L<perlport> and other available platform-specific documentation.
244
245 =head2 Alphabetical Listing of Perl Functions
246
247 =over 8
248
249 =item -X FILEHANDLE
250
251 =item -X EXPR
252
253 =item -X
254
255 A file test, where X is one of the letters listed below.  This unary
256 operator takes one argument, either a filename or a filehandle, and
257 tests the associated file to see if something is true about it.  If the
258 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
259 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
260 the undefined value if the file doesn't exist.  Despite the funny
261 names, precedence is the same as any other named unary operator, and
262 the argument may be parenthesized like any other unary operator.  The
263 operator may be any of:
264 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
265 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
266
267     -r  File is readable by effective uid/gid.
268     -w  File is writable by effective uid/gid.
269     -x  File is executable by effective uid/gid.
270     -o  File is owned by effective uid.
271
272     -R  File is readable by real uid/gid.
273     -W  File is writable by real uid/gid.
274     -X  File is executable by real uid/gid.
275     -O  File is owned by real uid.
276
277     -e  File exists.
278     -z  File has zero size (is empty).
279     -s  File has nonzero size (returns size in bytes).
280
281     -f  File is a plain file.
282     -d  File is a directory.
283     -l  File is a symbolic link.
284     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
285     -S  File is a socket.
286     -b  File is a block special file.
287     -c  File is a character special file.
288     -t  Filehandle is opened to a tty.
289
290     -u  File has setuid bit set.
291     -g  File has setgid bit set.
292     -k  File has sticky bit set.
293
294     -T  File is an ASCII text file (heuristic guess).
295     -B  File is a "binary" file (opposite of -T).
296
297     -M  Script start time minus file modification time, in days.
298     -A  Same for access time.
299     -C  Same for inode change time (Unix, may differ for other platforms)
300
301 Example:
302
303     while (<>) {
304         chomp;
305         next unless -f $_;      # ignore specials
306         #...
307     }
308
309 The interpretation of the file permission operators C<-r>, C<-R>,
310 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
311 of the file and the uids and gids of the user.  There may be other
312 reasons you can't actually read, write, or execute the file.  Such
313 reasons may be for example network filesystem access controls, ACLs
314 (access control lists), read-only filesystems, and unrecognized
315 executable formats.
316
317 Also note that, for the superuser on the local filesystems, the C<-r>,
318 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
319 if any execute bit is set in the mode.  Scripts run by the superuser
320 may thus need to do a stat() to determine the actual mode of the file,
321 or temporarily set their effective uid to something else.
322
323 If you are using ACLs, there is a pragma called C<filetest> that may
324 produce more accurate results than the bare stat() mode bits.
325 When under the C<use filetest 'access'> the above-mentioned filetests
326 will test whether the permission can (not) be granted using the
327 access() family of system calls.  Also note that the C<-x> and C<-X> may
328 under this pragma return true even if there are no execute permission
329 bits set (nor any extra execute permission ACLs).  This strangeness is
330 due to the underlying system calls' definitions.  Read the
331 documentation for the C<filetest> pragma for more information.
332
333 Note that C<-s/a/b/> does not do a negated substitution.  Saying
334 C<-exp($foo)> still works as expected, however--only single letters
335 following a minus are interpreted as file tests.
336
337 The C<-T> and C<-B> switches work as follows.  The first block or so of the
338 file is examined for odd characters such as strange control codes or
339 characters with the high bit set.  If too many strange characters (>30%)
340 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
341 containing null in the first block is considered a binary file.  If C<-T>
342 or C<-B> is used on a filehandle, the current IO buffer is examined
343 rather than the first block.  Both C<-T> and C<-B> return true on a null
344 file, or a file at EOF when testing a filehandle.  Because you have to
345 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
346 against the file first, as in C<next unless -f $file && -T $file>.
347
348 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
349 the special filehandle consisting of a solitary underline, then the stat
350 structure of the previous file test (or stat operator) is used, saving
351 a system call.  (This doesn't work with C<-t>, and you need to remember
352 that lstat() and C<-l> will leave values in the stat structure for the
353 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
354 a C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
355 Example:
356
357     print "Can do.\n" if -r $a || -w _ || -x _;
358
359     stat($filename);
360     print "Readable\n" if -r _;
361     print "Writable\n" if -w _;
362     print "Executable\n" if -x _;
363     print "Setuid\n" if -u _;
364     print "Setgid\n" if -g _;
365     print "Sticky\n" if -k _;
366     print "Text\n" if -T _;
367     print "Binary\n" if -B _;
368
369 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
370 test operators, in a way that C<-f -w -x $file> is equivalent to
371 C<-x $file && -w _ && -f _>. (This is only syntax fancy : if you use
372 the return value of C<-f $file> as an argument to another filetest
373 operator, no special magic will happen.)
374
375 =item abs VALUE
376
377 =item abs
378
379 Returns the absolute value of its argument.
380 If VALUE is omitted, uses C<$_>.
381
382 =item accept NEWSOCKET,GENERICSOCKET
383
384 Accepts an incoming socket connect, just as the accept(2) system call
385 does.  Returns the packed address if it succeeded, false otherwise.
386 See the example in L<perlipc/"Sockets: Client/Server Communication">.
387
388 On systems that support a close-on-exec flag on files, the flag will
389 be set for the newly opened file descriptor, as determined by the
390 value of $^F.  See L<perlvar/$^F>.
391
392 =item alarm SECONDS
393
394 =item alarm
395
396 Arranges to have a SIGALRM delivered to this process after the
397 specified number of wallclock seconds have elapsed.  If SECONDS is not
398 specified, the value stored in C<$_> is used. (On some machines,
399 unfortunately, the elapsed time may be up to one second less or more
400 than you specified because of how seconds are counted, and process
401 scheduling may delay the delivery of the signal even further.)
402
403 Only one timer may be counting at once.  Each call disables the
404 previous timer, and an argument of C<0> may be supplied to cancel the
405 previous timer without starting a new one.  The returned value is the
406 amount of time remaining on the previous timer.
407
408 For delays of finer granularity than one second, you may use Perl's
409 four-argument version of select() leaving the first three arguments
410 undefined, or you might be able to use the C<syscall> interface to
411 access setitimer(2) if your system supports it.  The Time::HiRes
412 module (from CPAN, and starting from Perl 5.8 part of the standard
413 distribution) may also prove useful.
414
415 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
416 (C<sleep> may be internally implemented in your system with C<alarm>)
417
418 If you want to use C<alarm> to time out a system call you need to use an
419 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
420 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
421 restart system calls on some systems.  Using C<eval>/C<die> always works,
422 modulo the caveats given in L<perlipc/"Signals">.
423
424     eval {
425         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
426         alarm $timeout;
427         $nread = sysread SOCKET, $buffer, $size;
428         alarm 0;
429     };
430     if ($@) {
431         die unless $@ eq "alarm\n";   # propagate unexpected errors
432         # timed out
433     }
434     else {
435         # didn't
436     }
437
438 For more information see L<perlipc>.
439
440 =item atan2 Y,X
441
442 Returns the arctangent of Y/X in the range -PI to PI.
443
444 For the tangent operation, you may use the C<Math::Trig::tan>
445 function, or use the familiar relation:
446
447     sub tan { sin($_[0]) / cos($_[0])  }
448
449 =item bind SOCKET,NAME
450
451 Binds a network address to a socket, just as the bind system call
452 does.  Returns true if it succeeded, false otherwise.  NAME should be a
453 packed address of the appropriate type for the socket.  See the examples in
454 L<perlipc/"Sockets: Client/Server Communication">.
455
456 =item binmode FILEHANDLE, LAYER
457
458 =item binmode FILEHANDLE
459
460 Arranges for FILEHANDLE to be read or written in "binary" or "text"
461 mode on systems where the run-time libraries distinguish between
462 binary and text files.  If FILEHANDLE is an expression, the value is
463 taken as the name of the filehandle.  Returns true on success,
464 otherwise it returns C<undef> and sets C<$!> (errno).
465
466 On some systems (in general, DOS and Windows-based systems) binmode()
467 is necessary when you're not working with a text file.  For the sake
468 of portability it is a good idea to always use it when appropriate,
469 and to never use it when it isn't appropriate.  Also, people can
470 set their I/O to be by default UTF-8 encoded Unicode, not bytes.
471
472 In other words: regardless of platform, use binmode() on binary data,
473 like for example images.
474
475 If LAYER is present it is a single string, but may contain multiple
476 directives. The directives alter the behaviour of the file handle.
477 When LAYER is present using binmode on text file makes sense.
478
479 If LAYER is omitted or specified as C<:raw> the filehandle is made
480 suitable for passing binary data. This includes turning off possible CRLF
481 translation and marking it as bytes (as opposed to Unicode characters).
482 Note that, despite what may be implied in I<"Programming Perl"> (the
483 Camel) or elsewhere, C<:raw> is I<not> the simply inverse of C<:crlf>
484 -- other layers which would affect binary nature of the stream are
485 I<also> disabled. See L<PerlIO>, L<perlrun> and the discussion about the
486 PERLIO environment variable.
487
488 The C<:bytes>, C<:crlf>, and C<:utf8>, and any other directives of the
489 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
490 establish default I/O layers.  See L<open>.
491
492 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
493 in "Programming Perl, 3rd Edition".  However, since the publishing of this
494 book, by many known as "Camel III", the consensus of the naming of this
495 functionality has moved from "discipline" to "layer".  All documentation
496 of this version of Perl therefore refers to "layers" rather than to
497 "disciplines".  Now back to the regularly scheduled documentation...>
498
499 To mark FILEHANDLE as UTF-8, use C<:utf8>.
500
501 In general, binmode() should be called after open() but before any I/O
502 is done on the filehandle.  Calling binmode() will normally flush any
503 pending buffered output data (and perhaps pending input data) on the
504 handle.  An exception to this is the C<:encoding> layer that
505 changes the default character encoding of the handle, see L<open>.
506 The C<:encoding> layer sometimes needs to be called in
507 mid-stream, and it doesn't flush the stream.  The C<:encoding>
508 also implicitly pushes on top of itself the C<:utf8> layer because
509 internally Perl will operate on UTF-8 encoded Unicode characters.
510
511 The operating system, device drivers, C libraries, and Perl run-time
512 system all work together to let the programmer treat a single
513 character (C<\n>) as the line terminator, irrespective of the external
514 representation.  On many operating systems, the native text file
515 representation matches the internal representation, but on some
516 platforms the external representation of C<\n> is made up of more than
517 one character.
518
519 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
520 character to end each line in the external representation of text (even
521 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
522 on Unix and most VMS files). In other systems like OS/2, DOS and the
523 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
524 but what's stored in text files are the two characters C<\cM\cJ>.  That
525 means that, if you don't use binmode() on these systems, C<\cM\cJ>
526 sequences on disk will be converted to C<\n> on input, and any C<\n> in
527 your program will be converted back to C<\cM\cJ> on output.  This is what
528 you want for text files, but it can be disastrous for binary files.
529
530 Another consequence of using binmode() (on some systems) is that
531 special end-of-file markers will be seen as part of the data stream.
532 For systems from the Microsoft family this means that if your binary
533 data contains C<\cZ>, the I/O subsystem will regard it as the end of
534 the file, unless you use binmode().
535
536 binmode() is not only important for readline() and print() operations,
537 but also when using read(), seek(), sysread(), syswrite() and tell()
538 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
539 in L<perlvar> for how to manually set your input and output
540 line-termination sequences.
541
542 =item bless REF,CLASSNAME
543
544 =item bless REF
545
546 This function tells the thingy referenced by REF that it is now an object
547 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
548 is used.  Because a C<bless> is often the last thing in a constructor,
549 it returns the reference for convenience.  Always use the two-argument
550 version if the function doing the blessing might be inherited by a
551 derived class.  See L<perltoot> and L<perlobj> for more about the blessing
552 (and blessings) of objects.
553
554 Consider always blessing objects in CLASSNAMEs that are mixed case.
555 Namespaces with all lowercase names are considered reserved for
556 Perl pragmata.  Builtin types have all uppercase names, so to prevent
557 confusion, you may wish to avoid such package names as well.  Make sure
558 that CLASSNAME is a true value.
559
560 See L<perlmod/"Perl Modules">.
561
562 =item caller EXPR
563
564 =item caller
565
566 Returns the context of the current subroutine call.  In scalar context,
567 returns the caller's package name if there is a caller, that is, if
568 we're in a subroutine or C<eval> or C<require>, and the undefined value
569 otherwise.  In list context, returns
570
571     ($package, $filename, $line) = caller;
572
573 With EXPR, it returns some extra information that the debugger uses to
574 print a stack trace.  The value of EXPR indicates how many call frames
575 to go back before the current one.
576
577     ($package, $filename, $line, $subroutine, $hasargs,
578     $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);
579
580 Here $subroutine may be C<(eval)> if the frame is not a subroutine
581 call, but an C<eval>.  In such a case additional elements $evaltext and
582 C<$is_require> are set: C<$is_require> is true if the frame is created by a
583 C<require> or C<use> statement, $evaltext contains the text of the
584 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
585 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
586 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
587 frame.)  $subroutine may also be C<(unknown)> if this particular
588 subroutine happens to have been deleted from the symbol table.
589 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
590 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
591 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
592 between versions of Perl, and are not meant for external use.
593
594 Furthermore, when called from within the DB package, caller returns more
595 detailed information: it sets the list variable C<@DB::args> to be the
596 arguments with which the subroutine was invoked.
597
598 Be aware that the optimizer might have optimized call frames away before
599 C<caller> had a chance to get the information.  That means that C<caller(N)>
600 might not return information about the call frame you expect it do, for
601 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
602 previous time C<caller> was called.
603
604 =item chdir EXPR
605
606 Changes the working directory to EXPR, if possible. If EXPR is omitted,
607 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
608 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
609 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
610 neither is set, C<chdir> does nothing. It returns true upon success,
611 false otherwise. See the example under C<die>.
612
613 =item chmod LIST
614
615 Changes the permissions of a list of files.  The first element of the
616 list must be the numerical mode, which should probably be an octal
617 number, and which definitely should I<not> be a string of octal digits:
618 C<0644> is okay, C<'0644'> is not.  Returns the number of files
619 successfully changed.  See also L</oct>, if all you have is a string.
620
621     $cnt = chmod 0755, 'foo', 'bar';
622     chmod 0755, @executables;
623     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
624                                              # --w----r-T
625     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
626     $mode = 0644;   chmod $mode, 'foo';      # this is best
627
628 You can also import the symbolic C<S_I*> constants from the Fcntl
629 module:
630
631     use Fcntl ':mode';
632
633     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
634     # This is identical to the chmod 0755 of the above example.
635
636 =item chomp VARIABLE
637
638 =item chomp( LIST )
639
640 =item chomp
641
642 This safer version of L</chop> removes any trailing string
643 that corresponds to the current value of C<$/> (also known as
644 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
645 number of characters removed from all its arguments.  It's often used to
646 remove the newline from the end of an input record when you're worried
647 that the final record may be missing its newline.  When in paragraph
648 mode (C<$/ = "">), it removes all trailing newlines from the string.
649 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
650 a reference to an integer or the like, see L<perlvar>) chomp() won't
651 remove anything.
652 If VARIABLE is omitted, it chomps C<$_>.  Example:
653
654     while (<>) {
655         chomp;  # avoid \n on last field
656         @array = split(/:/);
657         # ...
658     }
659
660 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
661
662 You can actually chomp anything that's an lvalue, including an assignment:
663
664     chomp($cwd = `pwd`);
665     chomp($answer = <STDIN>);
666
667 If you chomp a list, each element is chomped, and the total number of
668 characters removed is returned.
669
670 If the C<encoding> pragma is in scope then the lengths returned are
671 calculated from the length of C<$/> in Unicode characters, which is not
672 always the same as the length of C<$/> in the native encoding.
673
674 Note that parentheses are necessary when you're chomping anything
675 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
676 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
677 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
678 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
679 as C<chomp($a, $b)>.
680
681 =item chop VARIABLE
682
683 =item chop( LIST )
684
685 =item chop
686
687 Chops off the last character of a string and returns the character
688 chopped.  It is much more efficient than C<s/.$//s> because it neither
689 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
690 If VARIABLE is a hash, it chops the hash's values, but not its keys.
691
692 You can actually chop anything that's an lvalue, including an assignment.
693
694 If you chop a list, each element is chopped.  Only the value of the
695 last C<chop> is returned.
696
697 Note that C<chop> returns the last character.  To return all but the last
698 character, use C<substr($string, 0, -1)>.
699
700 See also L</chomp>.
701
702 =item chown LIST
703
704 Changes the owner (and group) of a list of files.  The first two
705 elements of the list must be the I<numeric> uid and gid, in that
706 order.  A value of -1 in either position is interpreted by most
707 systems to leave that value unchanged.  Returns the number of files
708 successfully changed.
709
710     $cnt = chown $uid, $gid, 'foo', 'bar';
711     chown $uid, $gid, @filenames;
712
713 Here's an example that looks up nonnumeric uids in the passwd file:
714
715     print "User: ";
716     chomp($user = <STDIN>);
717     print "Files: ";
718     chomp($pattern = <STDIN>);
719
720     ($login,$pass,$uid,$gid) = getpwnam($user)
721         or die "$user not in passwd file";
722
723     @ary = glob($pattern);      # expand filenames
724     chown $uid, $gid, @ary;
725
726 On most systems, you are not allowed to change the ownership of the
727 file unless you're the superuser, although you should be able to change
728 the group to any of your secondary groups.  On insecure systems, these
729 restrictions may be relaxed, but this is not a portable assumption.
730 On POSIX systems, you can detect this condition this way:
731
732     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
733     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
734
735 =item chr NUMBER
736
737 =item chr
738
739 Returns the character represented by that NUMBER in the character set.
740 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
741 chr(0x263a) is a Unicode smiley face.  Note that characters from 128
742 to 255 (inclusive) are by default not encoded in UTF-8 Unicode for
743 backward compatibility reasons (but see L<encoding>).
744
745 If NUMBER is omitted, uses C<$_>.
746
747 For the reverse, use L</ord>.
748
749 Note that under the C<bytes> pragma the NUMBER is masked to
750 the low eight bits.
751
752 See L<perlunicode> and L<encoding> for more about Unicode.
753
754 =item chroot FILENAME
755
756 =item chroot
757
758 This function works like the system call by the same name: it makes the
759 named directory the new root directory for all further pathnames that
760 begin with a C</> by your process and all its children.  (It doesn't
761 change your current working directory, which is unaffected.)  For security
762 reasons, this call is restricted to the superuser.  If FILENAME is
763 omitted, does a C<chroot> to C<$_>.
764
765 =item close FILEHANDLE
766
767 =item close
768
769 Closes the file or pipe associated with the file handle, returning
770 true only if IO buffers are successfully flushed and closes the system
771 file descriptor.  Closes the currently selected filehandle if the
772 argument is omitted.
773
774 You don't have to close FILEHANDLE if you are immediately going to do
775 another C<open> on it, because C<open> will close it for you.  (See
776 C<open>.)  However, an explicit C<close> on an input file resets the line
777 counter (C<$.>), while the implicit close done by C<open> does not.
778
779 If the file handle came from a piped open, C<close> will additionally
780 return false if one of the other system calls involved fails, or if the
781 program exits with non-zero status.  (If the only problem was that the
782 program exited non-zero, C<$!> will be set to C<0>.)  Closing a pipe
783 also waits for the process executing on the pipe to complete, in case you
784 want to look at the output of the pipe afterwards, and
785 implicitly puts the exit status value of that command into C<$?> and
786 C<${^CHILD_ERROR_NATIVE}>.
787
788 Prematurely closing the read end of a pipe (i.e. before the process
789 writing to it at the other end has closed it) will result in a
790 SIGPIPE being delivered to the writer.  If the other end can't
791 handle that, be sure to read all the data before closing the pipe.
792
793 Example:
794
795     open(OUTPUT, '|sort >foo')  # pipe to sort
796         or die "Can't start sort: $!";
797     #...                        # print stuff to output
798     close OUTPUT                # wait for sort to finish
799         or warn $! ? "Error closing sort pipe: $!"
800                    : "Exit status $? from sort";
801     open(INPUT, 'foo')          # get sort's results
802         or die "Can't open 'foo' for input: $!";
803
804 FILEHANDLE may be an expression whose value can be used as an indirect
805 filehandle, usually the real filehandle name.
806
807 =item closedir DIRHANDLE
808
809 Closes a directory opened by C<opendir> and returns the success of that
810 system call.
811
812 =item connect SOCKET,NAME
813
814 Attempts to connect to a remote socket, just as the connect system call
815 does.  Returns true if it succeeded, false otherwise.  NAME should be a
816 packed address of the appropriate type for the socket.  See the examples in
817 L<perlipc/"Sockets: Client/Server Communication">.
818
819 =item continue BLOCK
820
821 Actually a flow control statement rather than a function.  If there is a
822 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
823 C<foreach>), it is always executed just before the conditional is about to
824 be evaluated again, just like the third part of a C<for> loop in C.  Thus
825 it can be used to increment a loop variable, even when the loop has been
826 continued via the C<next> statement (which is similar to the C C<continue>
827 statement).
828
829 C<last>, C<next>, or C<redo> may appear within a C<continue>
830 block.  C<last> and C<redo> will behave as if they had been executed within
831 the main block.  So will C<next>, but since it will execute a C<continue>
832 block, it may be more entertaining.
833
834     while (EXPR) {
835         ### redo always comes here
836         do_something;
837     } continue {
838         ### next always comes here
839         do_something_else;
840         # then back the top to re-check EXPR
841     }
842     ### last always comes here
843
844 Omitting the C<continue> section is semantically equivalent to using an
845 empty one, logically enough.  In that case, C<next> goes directly back
846 to check the condition at the top of the loop.
847
848 =item cos EXPR
849
850 =item cos
851
852 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
853 takes cosine of C<$_>.
854
855 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
856 function, or use this relation:
857
858     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
859
860 =item crypt PLAINTEXT,SALT
861
862 Encrypts a string exactly like the crypt(3) function in the C library
863 (assuming that you actually have a version there that has not been
864 extirpated as a potential munition).  This can prove useful for checking
865 the password file for lousy passwords, amongst other things.  Only the
866 guys wearing white hats should do this.
867
868 Note that L<crypt|/crypt> is intended to be a one-way function, much like
869 breaking eggs to make an omelette.  There is no (known) corresponding
870 decrypt function (in other words, the crypt() is a one-way hash
871 function).  As a result, this function isn't all that useful for
872 cryptography.  (For that, see your nearby CPAN mirror.)
873
874 When verifying an existing encrypted string you should use the
875 encrypted text as the salt (like C<crypt($plain, $crypted) eq
876 $crypted>).  This allows your code to work with the standard L<crypt|/crypt>
877 and with more exotic implementations.  In other words, do not assume
878 anything about the returned string itself, or how many bytes in
879 the encrypted string matter.
880
881 Traditionally the result is a string of 13 bytes: two first bytes of
882 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
883 the first eight bytes of the encrypted string mattered, but
884 alternative hashing schemes (like MD5), higher level security schemes
885 (like C2), and implementations on non-UNIX platforms may produce
886 different strings.
887
888 When choosing a new salt create a random two character string whose
889 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
890 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
891 characters is just a recommendation; the characters allowed in
892 the salt depend solely on your system's crypt library, and Perl can't
893 restrict what salts C<crypt()> accepts.
894
895 Here's an example that makes sure that whoever runs this program knows
896 their own password:
897
898     $pwd = (getpwuid($<))[1];
899
900     system "stty -echo";
901     print "Password: ";
902     chomp($word = <STDIN>);
903     print "\n";
904     system "stty echo";
905
906     if (crypt($word, $pwd) ne $pwd) {
907         die "Sorry...\n";
908     } else {
909         print "ok\n";
910     }
911
912 Of course, typing in your own password to whoever asks you
913 for it is unwise.
914
915 The L<crypt|/crypt> function is unsuitable for encrypting large quantities
916 of data, not least of all because you can't get the information
917 back.  Look at the F<by-module/Crypt> and F<by-module/PGP> directories
918 on your favorite CPAN mirror for a slew of potentially useful
919 modules.
920
921 If using crypt() on a Unicode string (which I<potentially> has
922 characters with codepoints above 255), Perl tries to make sense
923 of the situation by trying to downgrade (a copy of the string)
924 the string back to an eight-bit byte string before calling crypt()
925 (on that copy).  If that works, good.  If not, crypt() dies with
926 C<Wide character in crypt>.
927
928 =item dbmclose HASH
929
930 [This function has been largely superseded by the C<untie> function.]
931
932 Breaks the binding between a DBM file and a hash.
933
934 =item dbmopen HASH,DBNAME,MASK
935
936 [This function has been largely superseded by the C<tie> function.]
937
938 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
939 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
940 argument is I<not> a filehandle, even though it looks like one).  DBNAME
941 is the name of the database (without the F<.dir> or F<.pag> extension if
942 any).  If the database does not exist, it is created with protection
943 specified by MASK (as modified by the C<umask>).  If your system supports
944 only the older DBM functions, you may perform only one C<dbmopen> in your
945 program.  In older versions of Perl, if your system had neither DBM nor
946 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
947 sdbm(3).
948
949 If you don't have write access to the DBM file, you can only read hash
950 variables, not set them.  If you want to test whether you can write,
951 either use file tests or try setting a dummy hash entry inside an C<eval>,
952 which will trap the error.
953
954 Note that functions such as C<keys> and C<values> may return huge lists
955 when used on large DBM files.  You may prefer to use the C<each>
956 function to iterate over large DBM files.  Example:
957
958     # print out history file offsets
959     dbmopen(%HIST,'/usr/lib/news/history',0666);
960     while (($key,$val) = each %HIST) {
961         print $key, ' = ', unpack('L',$val), "\n";
962     }
963     dbmclose(%HIST);
964
965 See also L<AnyDBM_File> for a more general description of the pros and
966 cons of the various dbm approaches, as well as L<DB_File> for a particularly
967 rich implementation.
968
969 You can control which DBM library you use by loading that library
970 before you call dbmopen():
971
972     use DB_File;
973     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
974         or die "Can't open netscape history file: $!";
975
976 =item defined EXPR
977
978 =item defined
979
980 Returns a Boolean value telling whether EXPR has a value other than
981 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
982 checked.
983
984 Many operations return C<undef> to indicate failure, end of file,
985 system error, uninitialized variable, and other exceptional
986 conditions.  This function allows you to distinguish C<undef> from
987 other values.  (A simple Boolean test will not distinguish among
988 C<undef>, zero, the empty string, and C<"0">, which are all equally
989 false.)  Note that since C<undef> is a valid scalar, its presence
990 doesn't I<necessarily> indicate an exceptional condition: C<pop>
991 returns C<undef> when its argument is an empty array, I<or> when the
992 element to return happens to be C<undef>.
993
994 You may also use C<defined(&func)> to check whether subroutine C<&func>
995 has ever been defined.  The return value is unaffected by any forward
996 declarations of C<&func>.  Note that a subroutine which is not defined
997 may still be callable: its package may have an C<AUTOLOAD> method that
998 makes it spring into existence the first time that it is called -- see
999 L<perlsub>.
1000
1001 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1002 used to report whether memory for that aggregate has ever been
1003 allocated.  This behavior may disappear in future versions of Perl.
1004 You should instead use a simple test for size:
1005
1006     if (@an_array) { print "has array elements\n" }
1007     if (%a_hash)   { print "has hash members\n"   }
1008
1009 When used on a hash element, it tells you whether the value is defined,
1010 not whether the key exists in the hash.  Use L</exists> for the latter
1011 purpose.
1012
1013 Examples:
1014
1015     print if defined $switch{'D'};
1016     print "$val\n" while defined($val = pop(@ary));
1017     die "Can't readlink $sym: $!"
1018         unless defined($value = readlink $sym);
1019     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1020     $debugging = 0 unless defined $debugging;
1021
1022 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1023 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1024 defined values.  For example, if you say
1025
1026     "ab" =~ /a(.*)b/;
1027
1028 The pattern match succeeds, and C<$1> is defined, despite the fact that it
1029 matched "nothing".  But it didn't really match nothing--rather, it
1030 matched something that happened to be zero characters long.  This is all
1031 very above-board and honest.  When a function returns an undefined value,
1032 it's an admission that it couldn't give you an honest answer.  So you
1033 should use C<defined> only when you're questioning the integrity of what
1034 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1035 what you want.
1036
1037 See also L</undef>, L</exists>, L</ref>.
1038
1039 =item delete EXPR
1040
1041 Given an expression that specifies a hash element, array element, hash slice,
1042 or array slice, deletes the specified element(s) from the hash or array.
1043 In the case of an array, if the array elements happen to be at the end,
1044 the size of the array will shrink to the highest element that tests
1045 true for exists() (or 0 if no such element exists).
1046
1047 Returns a list with the same number of elements as the number of elements
1048 for which deletion was attempted.  Each element of that list consists of
1049 either the value of the element deleted, or the undefined value.  In scalar
1050 context, this means that you get the value of the last element deleted (or
1051 the undefined value if that element did not exist).
1052
1053     %hash = (foo => 11, bar => 22, baz => 33);
1054     $scalar = delete $hash{foo};             # $scalar is 11
1055     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1056     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1057
1058 Deleting from C<%ENV> modifies the environment.  Deleting from
1059 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
1060 from a C<tie>d hash or array may not necessarily return anything.
1061
1062 Deleting an array element effectively returns that position of the array
1063 to its initial, uninitialized state.  Subsequently testing for the same
1064 element with exists() will return false.  Note that deleting array
1065 elements in the middle of an array will not shift the index of the ones
1066 after them down--use splice() for that.  See L</exists>.
1067
1068 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1069
1070     foreach $key (keys %HASH) {
1071         delete $HASH{$key};
1072     }
1073
1074     foreach $index (0 .. $#ARRAY) {
1075         delete $ARRAY[$index];
1076     }
1077
1078 And so do these:
1079
1080     delete @HASH{keys %HASH};
1081
1082     delete @ARRAY[0 .. $#ARRAY];
1083
1084 But both of these are slower than just assigning the empty list
1085 or undefining %HASH or @ARRAY:
1086
1087     %HASH = ();         # completely empty %HASH
1088     undef %HASH;        # forget %HASH ever existed
1089
1090     @ARRAY = ();        # completely empty @ARRAY
1091     undef @ARRAY;       # forget @ARRAY ever existed
1092
1093 Note that the EXPR can be arbitrarily complicated as long as the final
1094 operation is a hash element, array element,  hash slice, or array slice
1095 lookup:
1096
1097     delete $ref->[$x][$y]{$key};
1098     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1099
1100     delete $ref->[$x][$y][$index];
1101     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1102
1103 =item die LIST
1104
1105 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1106 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1107 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1108 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1109 an C<eval(),> the error message is stuffed into C<$@> and the
1110 C<eval> is terminated with the undefined value.  This makes
1111 C<die> the way to raise an exception.
1112
1113 Equivalent examples:
1114
1115     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1116     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1117
1118 If the last element of LIST does not end in a newline, the current
1119 script line number and input line number (if any) are also printed,
1120 and a newline is supplied.  Note that the "input line number" (also
1121 known as "chunk") is subject to whatever notion of "line" happens to
1122 be currently in effect, and is also available as the special variable
1123 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1124
1125 Hint: sometimes appending C<", stopped"> to your message will cause it
1126 to make better sense when the string C<"at foo line 123"> is appended.
1127 Suppose you are running script "canasta".
1128
1129     die "/etc/games is no good";
1130     die "/etc/games is no good, stopped";
1131
1132 produce, respectively
1133
1134     /etc/games is no good at canasta line 123.
1135     /etc/games is no good, stopped at canasta line 123.
1136
1137 See also exit(), warn(), and the Carp module.
1138
1139 If LIST is empty and C<$@> already contains a value (typically from a
1140 previous eval) that value is reused after appending C<"\t...propagated">.
1141 This is useful for propagating exceptions:
1142
1143     eval { ... };
1144     die unless $@ =~ /Expected exception/;
1145
1146 If LIST is empty and C<$@> contains an object reference that has a
1147 C<PROPAGATE> method, that method will be called with additional file
1148 and line number parameters.  The return value replaces the value in
1149 C<$@>.  ie. as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1150 were called.
1151
1152 If C<$@> is empty then the string C<"Died"> is used.
1153
1154 die() can also be called with a reference argument.  If this happens to be
1155 trapped within an eval(), $@ contains the reference.  This behavior permits
1156 a more elaborate exception handling implementation using objects that
1157 maintain arbitrary state about the nature of the exception.  Such a scheme
1158 is sometimes preferable to matching particular string values of $@ using
1159 regular expressions.  Here's an example:
1160
1161     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1162     if ($@) {
1163         if (ref($@) && UNIVERSAL::isa($@,"Some::Module::Exception")) {
1164             # handle Some::Module::Exception
1165         }
1166         else {
1167             # handle all other possible exceptions
1168         }
1169     }
1170
1171 Because perl will stringify uncaught exception messages before displaying
1172 them, you may want to overload stringification operations on such custom
1173 exception objects.  See L<overload> for details about that.
1174
1175 You can arrange for a callback to be run just before the C<die>
1176 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1177 handler will be called with the error text and can change the error
1178 message, if it sees fit, by calling C<die> again.  See
1179 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1180 L<"eval BLOCK"> for some examples.  Although this feature was meant
1181 to be run only right before your program was to exit, this is not
1182 currently the case--the C<$SIG{__DIE__}> hook is currently called
1183 even inside eval()ed blocks/strings!  If one wants the hook to do
1184 nothing in such situations, put
1185
1186         die @_ if $^S;
1187
1188 as the first line of the handler (see L<perlvar/$^S>).  Because
1189 this promotes strange action at a distance, this counterintuitive
1190 behavior may be fixed in a future release.
1191
1192 =item do BLOCK
1193
1194 Not really a function.  Returns the value of the last command in the
1195 sequence of commands indicated by BLOCK.  When modified by a loop
1196 modifier, executes the BLOCK once before testing the loop condition.
1197 (On other statements the loop modifiers test the conditional first.)
1198
1199 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1200 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1201 See L<perlsyn> for alternative strategies.
1202
1203 =item do SUBROUTINE(LIST)
1204
1205 A deprecated form of subroutine call.  See L<perlsub>.
1206
1207 =item do EXPR
1208
1209 Uses the value of EXPR as a filename and executes the contents of the
1210 file as a Perl script.
1211
1212     do 'stat.pl';
1213
1214 is just like
1215
1216     eval `cat stat.pl`;
1217
1218 except that it's more efficient and concise, keeps track of the current
1219 filename for error messages, searches the @INC directories, and updates
1220 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1221 variables.  It also differs in that code evaluated with C<do FILENAME>
1222 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1223 same, however, in that it does reparse the file every time you call it,
1224 so you probably don't want to do this inside a loop.
1225
1226 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1227 error.  If C<do> can read the file but cannot compile it, it
1228 returns undef and sets an error message in C<$@>.   If the file is
1229 successfully compiled, C<do> returns the value of the last expression
1230 evaluated.
1231
1232 Note that inclusion of library modules is better done with the
1233 C<use> and C<require> operators, which also do automatic error checking
1234 and raise an exception if there's a problem.
1235
1236 You might like to use C<do> to read in a program configuration
1237 file.  Manual error checking can be done this way:
1238
1239     # read in config files: system first, then user
1240     for $file ("/share/prog/defaults.rc",
1241                "$ENV{HOME}/.someprogrc")
1242    {
1243         unless ($return = do $file) {
1244             warn "couldn't parse $file: $@" if $@;
1245             warn "couldn't do $file: $!"    unless defined $return;
1246             warn "couldn't run $file"       unless $return;
1247         }
1248     }
1249
1250 =item dump LABEL
1251
1252 =item dump
1253
1254 This function causes an immediate core dump.  See also the B<-u>
1255 command-line switch in L<perlrun>, which does the same thing.
1256 Primarily this is so that you can use the B<undump> program (not
1257 supplied) to turn your core dump into an executable binary after
1258 having initialized all your variables at the beginning of the
1259 program.  When the new binary is executed it will begin by executing
1260 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1261 Think of it as a goto with an intervening core dump and reincarnation.
1262 If C<LABEL> is omitted, restarts the program from the top.
1263
1264 B<WARNING>: Any files opened at the time of the dump will I<not>
1265 be open any more when the program is reincarnated, with possible
1266 resulting confusion on the part of Perl.
1267
1268 This function is now largely obsolete, partly because it's very
1269 hard to convert a core file into an executable, and because the
1270 real compiler backends for generating portable bytecode and compilable
1271 C code have superseded it.  That's why you should now invoke it as
1272 C<CORE::dump()>, if you don't want to be warned against a possible
1273 typo.
1274
1275 If you're looking to use L<dump> to speed up your program, consider
1276 generating bytecode or native C code as described in L<perlcc>.  If
1277 you're just trying to accelerate a CGI script, consider using the
1278 C<mod_perl> extension to B<Apache>, or the CPAN module, CGI::Fast.
1279 You might also consider autoloading or selfloading, which at least
1280 make your program I<appear> to run faster.
1281
1282 =item each HASH
1283
1284 When called in list context, returns a 2-element list consisting of the
1285 key and value for the next element of a hash, so that you can iterate over
1286 it.  When called in scalar context, returns only the key for the next
1287 element in the hash.
1288
1289 Entries are returned in an apparently random order.  The actual random
1290 order is subject to change in future versions of perl, but it is
1291 guaranteed to be in the same order as either the C<keys> or C<values>
1292 function would produce on the same (unmodified) hash.  Since Perl
1293 5.8.1 the ordering is different even between different runs of Perl
1294 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1295
1296 When the hash is entirely read, a null array is returned in list context
1297 (which when assigned produces a false (C<0>) value), and C<undef> in
1298 scalar context.  The next call to C<each> after that will start iterating
1299 again.  There is a single iterator for each hash, shared by all C<each>,
1300 C<keys>, and C<values> function calls in the program; it can be reset by
1301 reading all the elements from the hash, or by evaluating C<keys HASH> or
1302 C<values HASH>.  If you add or delete elements of a hash while you're
1303 iterating over it, you may get entries skipped or duplicated, so
1304 don't.  Exception: It is always safe to delete the item most recently
1305 returned by C<each()>, which means that the following code will work:
1306
1307         while (($key, $value) = each %hash) {
1308           print $key, "\n";
1309           delete $hash{$key};   # This is safe
1310         }
1311
1312 The following prints out your environment like the printenv(1) program,
1313 only in a different order:
1314
1315     while (($key,$value) = each %ENV) {
1316         print "$key=$value\n";
1317     }
1318
1319 See also C<keys>, C<values> and C<sort>.
1320
1321 =item eof FILEHANDLE
1322
1323 =item eof ()
1324
1325 =item eof
1326
1327 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1328 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1329 gives the real filehandle.  (Note that this function actually
1330 reads a character and then C<ungetc>s it, so isn't very useful in an
1331 interactive context.)  Do not read from a terminal file (or call
1332 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1333 as terminals may lose the end-of-file condition if you do.
1334
1335 An C<eof> without an argument uses the last file read.  Using C<eof()>
1336 with empty parentheses is very different.  It refers to the pseudo file
1337 formed from the files listed on the command line and accessed via the
1338 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1339 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1340 used will cause C<@ARGV> to be examined to determine if input is
1341 available.   Similarly, an C<eof()> after C<< <> >> has returned
1342 end-of-file will assume you are processing another C<@ARGV> list,
1343 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1344 see L<perlop/"I/O Operators">.
1345
1346 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1347 detect the end of each file, C<eof()> will only detect the end of the
1348 last file.  Examples:
1349
1350     # reset line numbering on each input file
1351     while (<>) {
1352         next if /^\s*#/;        # skip comments
1353         print "$.\t$_";
1354     } continue {
1355         close ARGV  if eof;     # Not eof()!
1356     }
1357
1358     # insert dashes just before last line of last file
1359     while (<>) {
1360         if (eof()) {            # check for end of last file
1361             print "--------------\n";
1362         }
1363         print;
1364         last if eof();          # needed if we're reading from a terminal
1365     }
1366
1367 Practical hint: you almost never need to use C<eof> in Perl, because the
1368 input operators typically return C<undef> when they run out of data, or if
1369 there was an error.
1370
1371 =item eval EXPR
1372
1373 =item eval BLOCK
1374
1375 In the first form, the return value of EXPR is parsed and executed as if it
1376 were a little Perl program.  The value of the expression (which is itself
1377 determined within scalar context) is first parsed, and if there weren't any
1378 errors, executed in the lexical context of the current Perl program, so
1379 that any variable settings or subroutine and format definitions remain
1380 afterwards.  Note that the value is parsed every time the eval executes.
1381 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1382 delay parsing and subsequent execution of the text of EXPR until run time.
1383
1384 In the second form, the code within the BLOCK is parsed only once--at the
1385 same time the code surrounding the eval itself was parsed--and executed
1386 within the context of the current Perl program.  This form is typically
1387 used to trap exceptions more efficiently than the first (see below), while
1388 also providing the benefit of checking the code within BLOCK at compile
1389 time.
1390
1391 The final semicolon, if any, may be omitted from the value of EXPR or within
1392 the BLOCK.
1393
1394 In both forms, the value returned is the value of the last expression
1395 evaluated inside the mini-program; a return statement may be also used, just
1396 as with subroutines.  The expression providing the return value is evaluated
1397 in void, scalar, or list context, depending on the context of the eval itself.
1398 See L</wantarray> for more on how the evaluation context can be determined.
1399
1400 If there is a syntax error or runtime error, or a C<die> statement is
1401 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1402 error message.  If there was no error, C<$@> is guaranteed to be a null
1403 string.  Beware that using C<eval> neither silences perl from printing
1404 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1405 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1406 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1407 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1408
1409 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1410 determining whether a particular feature (such as C<socket> or C<symlink>)
1411 is implemented.  It is also Perl's exception trapping mechanism, where
1412 the die operator is used to raise exceptions.
1413
1414 If the code to be executed doesn't vary, you may use the eval-BLOCK
1415 form to trap run-time errors without incurring the penalty of
1416 recompiling each time.  The error, if any, is still returned in C<$@>.
1417 Examples:
1418
1419     # make divide-by-zero nonfatal
1420     eval { $answer = $a / $b; }; warn $@ if $@;
1421
1422     # same thing, but less efficient
1423     eval '$answer = $a / $b'; warn $@ if $@;
1424
1425     # a compile-time error
1426     eval { $answer = };                 # WRONG
1427
1428     # a run-time error
1429     eval '$answer =';   # sets $@
1430
1431 Due to the current arguably broken state of C<__DIE__> hooks, when using
1432 the C<eval{}> form as an exception trap in libraries, you may wish not
1433 to trigger any C<__DIE__> hooks that user code may have installed.
1434 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1435 as shown in this example:
1436
1437     # a very private exception trap for divide-by-zero
1438     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1439     warn $@ if $@;
1440
1441 This is especially significant, given that C<__DIE__> hooks can call
1442 C<die> again, which has the effect of changing their error messages:
1443
1444     # __DIE__ hooks may modify error messages
1445     {
1446        local $SIG{'__DIE__'} =
1447               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1448        eval { die "foo lives here" };
1449        print $@ if $@;                # prints "bar lives here"
1450     }
1451
1452 Because this promotes action at a distance, this counterintuitive behavior
1453 may be fixed in a future release.
1454
1455 With an C<eval>, you should be especially careful to remember what's
1456 being looked at when:
1457
1458     eval $x;            # CASE 1
1459     eval "$x";          # CASE 2
1460
1461     eval '$x';          # CASE 3
1462     eval { $x };        # CASE 4
1463
1464     eval "\$$x++";      # CASE 5
1465     $$x++;              # CASE 6
1466
1467 Cases 1 and 2 above behave identically: they run the code contained in
1468 the variable $x.  (Although case 2 has misleading double quotes making
1469 the reader wonder what else might be happening (nothing is).)  Cases 3
1470 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1471 does nothing but return the value of $x.  (Case 4 is preferred for
1472 purely visual reasons, but it also has the advantage of compiling at
1473 compile-time instead of at run-time.)  Case 5 is a place where
1474 normally you I<would> like to use double quotes, except that in this
1475 particular situation, you can just use symbolic references instead, as
1476 in case 6.
1477
1478 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1479 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1480
1481 Note that as a very special case, an C<eval ''> executed within the C<DB>
1482 package doesn't see the usual surrounding lexical scope, but rather the
1483 scope of the first non-DB piece of code that called it. You don't normally
1484 need to worry about this unless you are writing a Perl debugger.
1485
1486 =item exec LIST
1487
1488 =item exec PROGRAM LIST
1489
1490 The C<exec> function executes a system command I<and never returns>--
1491 use C<system> instead of C<exec> if you want it to return.  It fails and
1492 returns false only if the command does not exist I<and> it is executed
1493 directly instead of via your system's command shell (see below).
1494
1495 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1496 warns you if there is a following statement which isn't C<die>, C<warn>,
1497 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1498 I<really> want to follow an C<exec> with some other statement, you
1499 can use one of these styles to avoid the warning:
1500
1501     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1502     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1503
1504 If there is more than one argument in LIST, or if LIST is an array
1505 with more than one value, calls execvp(3) with the arguments in LIST.
1506 If there is only one scalar argument or an array with one element in it,
1507 the argument is checked for shell metacharacters, and if there are any,
1508 the entire argument is passed to the system's command shell for parsing
1509 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1510 If there are no shell metacharacters in the argument, it is split into
1511 words and passed directly to C<execvp>, which is more efficient.
1512 Examples:
1513
1514     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1515     exec "sort $outfile | uniq";
1516
1517 If you don't really want to execute the first argument, but want to lie
1518 to the program you are executing about its own name, you can specify
1519 the program you actually want to run as an "indirect object" (without a
1520 comma) in front of the LIST.  (This always forces interpretation of the
1521 LIST as a multivalued list, even if there is only a single scalar in
1522 the list.)  Example:
1523
1524     $shell = '/bin/csh';
1525     exec $shell '-sh';          # pretend it's a login shell
1526
1527 or, more directly,
1528
1529     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1530
1531 When the arguments get executed via the system shell, results will
1532 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1533 for details.
1534
1535 Using an indirect object with C<exec> or C<system> is also more
1536 secure.  This usage (which also works fine with system()) forces
1537 interpretation of the arguments as a multivalued list, even if the
1538 list had just one argument.  That way you're safe from the shell
1539 expanding wildcards or splitting up words with whitespace in them.
1540
1541     @args = ( "echo surprise" );
1542
1543     exec @args;               # subject to shell escapes
1544                                 # if @args == 1
1545     exec { $args[0] } @args;  # safe even with one-arg list
1546
1547 The first version, the one without the indirect object, ran the I<echo>
1548 program, passing it C<"surprise"> an argument.  The second version
1549 didn't--it tried to run a program literally called I<"echo surprise">,
1550 didn't find it, and set C<$?> to a non-zero value indicating failure.
1551
1552 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1553 output before the exec, but this may not be supported on some platforms
1554 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1555 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1556 open handles in order to avoid lost output.
1557
1558 Note that C<exec> will not call your C<END> blocks, nor will it call
1559 any C<DESTROY> methods in your objects.
1560
1561 =item exists EXPR
1562
1563 Given an expression that specifies a hash element or array element,
1564 returns true if the specified element in the hash or array has ever
1565 been initialized, even if the corresponding value is undefined.  The
1566 element is not autovivified if it doesn't exist.
1567
1568     print "Exists\n"    if exists $hash{$key};
1569     print "Defined\n"   if defined $hash{$key};
1570     print "True\n"      if $hash{$key};
1571
1572     print "Exists\n"    if exists $array[$index];
1573     print "Defined\n"   if defined $array[$index];
1574     print "True\n"      if $array[$index];
1575
1576 A hash or array element can be true only if it's defined, and defined if
1577 it exists, but the reverse doesn't necessarily hold true.
1578
1579 Given an expression that specifies the name of a subroutine,
1580 returns true if the specified subroutine has ever been declared, even
1581 if it is undefined.  Mentioning a subroutine name for exists or defined
1582 does not count as declaring it.  Note that a subroutine which does not
1583 exist may still be callable: its package may have an C<AUTOLOAD>
1584 method that makes it spring into existence the first time that it is
1585 called -- see L<perlsub>.
1586
1587     print "Exists\n"    if exists &subroutine;
1588     print "Defined\n"   if defined &subroutine;
1589
1590 Note that the EXPR can be arbitrarily complicated as long as the final
1591 operation is a hash or array key lookup or subroutine name:
1592
1593     if (exists $ref->{A}->{B}->{$key})  { }
1594     if (exists $hash{A}{B}{$key})       { }
1595
1596     if (exists $ref->{A}->{B}->[$ix])   { }
1597     if (exists $hash{A}{B}[$ix])        { }
1598
1599     if (exists &{$ref->{A}{B}{$key}})   { }
1600
1601 Although the deepest nested array or hash will not spring into existence
1602 just because its existence was tested, any intervening ones will.
1603 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1604 into existence due to the existence test for the $key element above.
1605 This happens anywhere the arrow operator is used, including even:
1606
1607     undef $ref;
1608     if (exists $ref->{"Some key"})      { }
1609     print $ref;             # prints HASH(0x80d3d5c)
1610
1611 This surprising autovivification in what does not at first--or even
1612 second--glance appear to be an lvalue context may be fixed in a future
1613 release.
1614
1615 Use of a subroutine call, rather than a subroutine name, as an argument
1616 to exists() is an error.
1617
1618     exists &sub;        # OK
1619     exists &sub();      # Error
1620
1621 =item exit EXPR
1622
1623 Evaluates EXPR and exits immediately with that value.    Example:
1624
1625     $ans = <STDIN>;
1626     exit 0 if $ans =~ /^[Xx]/;
1627
1628 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1629 universally recognized values for EXPR are C<0> for success and C<1>
1630 for error; other values are subject to interpretation depending on the
1631 environment in which the Perl program is running.  For example, exiting
1632 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1633 the mailer to return the item undelivered, but that's not true everywhere.
1634
1635 Don't use C<exit> to abort a subroutine if there's any chance that
1636 someone might want to trap whatever error happened.  Use C<die> instead,
1637 which can be trapped by an C<eval>.
1638
1639 The exit() function does not always exit immediately.  It calls any
1640 defined C<END> routines first, but these C<END> routines may not
1641 themselves abort the exit.  Likewise any object destructors that need to
1642 be called are called before the real exit.  If this is a problem, you
1643 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1644 See L<perlmod> for details.
1645
1646 =item exp EXPR
1647
1648 =item exp
1649
1650 Returns I<e> (the natural logarithm base) to the power of EXPR.
1651 If EXPR is omitted, gives C<exp($_)>.
1652
1653 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1654
1655 Implements the fcntl(2) function.  You'll probably have to say
1656
1657     use Fcntl;
1658
1659 first to get the correct constant definitions.  Argument processing and
1660 value return works just like C<ioctl> below.
1661 For example:
1662
1663     use Fcntl;
1664     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1665         or die "can't fcntl F_GETFL: $!";
1666
1667 You don't have to check for C<defined> on the return from C<fcntl>.
1668 Like C<ioctl>, it maps a C<0> return from the system call into
1669 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1670 in numeric context.  It is also exempt from the normal B<-w> warnings
1671 on improper numeric conversions.
1672
1673 Note that C<fcntl> will produce a fatal error if used on a machine that
1674 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1675 manpage to learn what functions are available on your system.
1676
1677 Here's an example of setting a filehandle named C<REMOTE> to be
1678 non-blocking at the system level.  You'll have to negotiate C<$|>
1679 on your own, though.
1680
1681     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1682
1683     $flags = fcntl(REMOTE, F_GETFL, 0)
1684                 or die "Can't get flags for the socket: $!\n";
1685
1686     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1687                 or die "Can't set flags for the socket: $!\n";
1688
1689 =item fileno FILEHANDLE
1690
1691 Returns the file descriptor for a filehandle, or undefined if the
1692 filehandle is not open.  This is mainly useful for constructing
1693 bitmaps for C<select> and low-level POSIX tty-handling operations.
1694 If FILEHANDLE is an expression, the value is taken as an indirect
1695 filehandle, generally its name.
1696
1697 You can use this to find out whether two handles refer to the
1698 same underlying descriptor:
1699
1700     if (fileno(THIS) == fileno(THAT)) {
1701         print "THIS and THAT are dups\n";
1702     }
1703
1704 (Filehandles connected to memory objects via new features of C<open> may
1705 return undefined even though they are open.)
1706
1707
1708 =item flock FILEHANDLE,OPERATION
1709
1710 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1711 for success, false on failure.  Produces a fatal error if used on a
1712 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1713 C<flock> is Perl's portable file locking interface, although it locks
1714 only entire files, not records.
1715
1716 Two potentially non-obvious but traditional C<flock> semantics are
1717 that it waits indefinitely until the lock is granted, and that its locks
1718 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1719 fewer guarantees.  This means that files locked with C<flock> may be
1720 modified by programs that do not also use C<flock>.  See L<perlport>,
1721 your port's specific documentation, or your system-specific local manpages
1722 for details.  It's best to assume traditional behavior if you're writing
1723 portable programs.  (But if you're not, you should as always feel perfectly
1724 free to write for your own system's idiosyncrasies (sometimes called
1725 "features").  Slavish adherence to portability concerns shouldn't get
1726 in the way of your getting your job done.)
1727
1728 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1729 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1730 you can use the symbolic names if you import them from the Fcntl module,
1731 either individually, or as a group using the ':flock' tag.  LOCK_SH
1732 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1733 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1734 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1735 waiting for the lock (check the return status to see if you got it).
1736
1737 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1738 before locking or unlocking it.
1739
1740 Note that the emulation built with lockf(3) doesn't provide shared
1741 locks, and it requires that FILEHANDLE be open with write intent.  These
1742 are the semantics that lockf(3) implements.  Most if not all systems
1743 implement lockf(3) in terms of fcntl(2) locking, though, so the
1744 differing semantics shouldn't bite too many people.
1745
1746 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1747 be open with read intent to use LOCK_SH and requires that it be open
1748 with write intent to use LOCK_EX.
1749
1750 Note also that some versions of C<flock> cannot lock things over the
1751 network; you would need to use the more system-specific C<fcntl> for
1752 that.  If you like you can force Perl to ignore your system's flock(2)
1753 function, and so provide its own fcntl(2)-based emulation, by passing
1754 the switch C<-Ud_flock> to the F<Configure> program when you configure
1755 perl.
1756
1757 Here's a mailbox appender for BSD systems.
1758
1759     use Fcntl ':flock'; # import LOCK_* constants
1760
1761     sub lock {
1762         flock(MBOX,LOCK_EX);
1763         # and, in case someone appended
1764         # while we were waiting...
1765         seek(MBOX, 0, 2);
1766     }
1767
1768     sub unlock {
1769         flock(MBOX,LOCK_UN);
1770     }
1771
1772     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1773             or die "Can't open mailbox: $!";
1774
1775     lock();
1776     print MBOX $msg,"\n\n";
1777     unlock();
1778
1779 On systems that support a real flock(), locks are inherited across fork()
1780 calls, whereas those that must resort to the more capricious fcntl()
1781 function lose the locks, making it harder to write servers.
1782
1783 See also L<DB_File> for other flock() examples.
1784
1785 =item fork
1786
1787 Does a fork(2) system call to create a new process running the
1788 same program at the same point.  It returns the child pid to the
1789 parent process, C<0> to the child process, or C<undef> if the fork is
1790 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1791 are shared, while everything else is copied.  On most systems supporting
1792 fork(), great care has gone into making it extremely efficient (for
1793 example, using copy-on-write technology on data pages), making it the
1794 dominant paradigm for multitasking over the last few decades.
1795
1796 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1797 output before forking the child process, but this may not be supported
1798 on some platforms (see L<perlport>).  To be safe, you may need to set
1799 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1800 C<IO::Handle> on any open handles in order to avoid duplicate output.
1801
1802 If you C<fork> without ever waiting on your children, you will
1803 accumulate zombies.  On some systems, you can avoid this by setting
1804 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1805 forking and reaping moribund children.
1806
1807 Note that if your forked child inherits system file descriptors like
1808 STDIN and STDOUT that are actually connected by a pipe or socket, even
1809 if you exit, then the remote server (such as, say, a CGI script or a
1810 backgrounded job launched from a remote shell) won't think you're done.
1811 You should reopen those to F</dev/null> if it's any issue.
1812
1813 =item format
1814
1815 Declare a picture format for use by the C<write> function.  For
1816 example:
1817
1818     format Something =
1819         Test: @<<<<<<<< @||||| @>>>>>
1820               $str,     $%,    '$' . int($num)
1821     .
1822
1823     $str = "widget";
1824     $num = $cost/$quantity;
1825     $~ = 'Something';
1826     write;
1827
1828 See L<perlform> for many details and examples.
1829
1830 =item formline PICTURE,LIST
1831
1832 This is an internal function used by C<format>s, though you may call it,
1833 too.  It formats (see L<perlform>) a list of values according to the
1834 contents of PICTURE, placing the output into the format output
1835 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1836 Eventually, when a C<write> is done, the contents of
1837 C<$^A> are written to some filehandle, but you could also read C<$^A>
1838 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1839 does one C<formline> per line of form, but the C<formline> function itself
1840 doesn't care how many newlines are embedded in the PICTURE.  This means
1841 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1842 You may therefore need to use multiple formlines to implement a single
1843 record format, just like the format compiler.
1844
1845 Be careful if you put double quotes around the picture, because an C<@>
1846 character may be taken to mean the beginning of an array name.
1847 C<formline> always returns true.  See L<perlform> for other examples.
1848
1849 =item getc FILEHANDLE
1850
1851 =item getc
1852
1853 Returns the next character from the input file attached to FILEHANDLE,
1854 or the undefined value at end of file, or if there was an error (in
1855 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
1856 STDIN.  This is not particularly efficient.  However, it cannot be
1857 used by itself to fetch single characters without waiting for the user
1858 to hit enter.  For that, try something more like:
1859
1860     if ($BSD_STYLE) {
1861         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1862     }
1863     else {
1864         system "stty", '-icanon', 'eol', "\001";
1865     }
1866
1867     $key = getc(STDIN);
1868
1869     if ($BSD_STYLE) {
1870         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1871     }
1872     else {
1873         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1874     }
1875     print "\n";
1876
1877 Determination of whether $BSD_STYLE should be set
1878 is left as an exercise to the reader.
1879
1880 The C<POSIX::getattr> function can do this more portably on
1881 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1882 module from your nearest CPAN site; details on CPAN can be found on
1883 L<perlmodlib/CPAN>.
1884
1885 =item getlogin
1886
1887 Implements the C library function of the same name, which on most
1888 systems returns the current login from F</etc/utmp>, if any.  If null,
1889 use C<getpwuid>.
1890
1891     $login = getlogin || getpwuid($<) || "Kilroy";
1892
1893 Do not consider C<getlogin> for authentication: it is not as
1894 secure as C<getpwuid>.
1895
1896 =item getpeername SOCKET
1897
1898 Returns the packed sockaddr address of other end of the SOCKET connection.
1899
1900     use Socket;
1901     $hersockaddr    = getpeername(SOCK);
1902     ($port, $iaddr) = sockaddr_in($hersockaddr);
1903     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1904     $herstraddr     = inet_ntoa($iaddr);
1905
1906 =item getpgrp PID
1907
1908 Returns the current process group for the specified PID.  Use
1909 a PID of C<0> to get the current process group for the
1910 current process.  Will raise an exception if used on a machine that
1911 doesn't implement getpgrp(2).  If PID is omitted, returns process
1912 group of current process.  Note that the POSIX version of C<getpgrp>
1913 does not accept a PID argument, so only C<PID==0> is truly portable.
1914
1915 =item getppid
1916
1917 Returns the process id of the parent process.
1918
1919 Note for Linux users: on Linux, the C functions C<getpid()> and
1920 C<getppid()> return different values from different threads. In order to
1921 be portable, this behavior is not reflected by the perl-level function
1922 C<getppid()>, that returns a consistent value across threads. If you want
1923 to call the underlying C<getppid()>, you may use the CPAN module
1924 C<Linux::Pid>.
1925
1926 =item getpriority WHICH,WHO
1927
1928 Returns the current priority for a process, a process group, or a user.
1929 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1930 machine that doesn't implement getpriority(2).
1931
1932 =item getpwnam NAME
1933
1934 =item getgrnam NAME
1935
1936 =item gethostbyname NAME
1937
1938 =item getnetbyname NAME
1939
1940 =item getprotobyname NAME
1941
1942 =item getpwuid UID
1943
1944 =item getgrgid GID
1945
1946 =item getservbyname NAME,PROTO
1947
1948 =item gethostbyaddr ADDR,ADDRTYPE
1949
1950 =item getnetbyaddr ADDR,ADDRTYPE
1951
1952 =item getprotobynumber NUMBER
1953
1954 =item getservbyport PORT,PROTO
1955
1956 =item getpwent
1957
1958 =item getgrent
1959
1960 =item gethostent
1961
1962 =item getnetent
1963
1964 =item getprotoent
1965
1966 =item getservent
1967
1968 =item setpwent
1969
1970 =item setgrent
1971
1972 =item sethostent STAYOPEN
1973
1974 =item setnetent STAYOPEN
1975
1976 =item setprotoent STAYOPEN
1977
1978 =item setservent STAYOPEN
1979
1980 =item endpwent
1981
1982 =item endgrent
1983
1984 =item endhostent
1985
1986 =item endnetent
1987
1988 =item endprotoent
1989
1990 =item endservent
1991
1992 These routines perform the same functions as their counterparts in the
1993 system library.  In list context, the return values from the
1994 various get routines are as follows:
1995
1996     ($name,$passwd,$uid,$gid,
1997        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1998     ($name,$passwd,$gid,$members) = getgr*
1999     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2000     ($name,$aliases,$addrtype,$net) = getnet*
2001     ($name,$aliases,$proto) = getproto*
2002     ($name,$aliases,$port,$proto) = getserv*
2003
2004 (If the entry doesn't exist you get a null list.)
2005
2006 The exact meaning of the $gcos field varies but it usually contains
2007 the real name of the user (as opposed to the login name) and other
2008 information pertaining to the user.  Beware, however, that in many
2009 system users are able to change this information and therefore it
2010 cannot be trusted and therefore the $gcos is tainted (see
2011 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2012 login shell, are also tainted, because of the same reason.
2013
2014 In scalar context, you get the name, unless the function was a
2015 lookup by name, in which case you get the other thing, whatever it is.
2016 (If the entry doesn't exist you get the undefined value.)  For example:
2017
2018     $uid   = getpwnam($name);
2019     $name  = getpwuid($num);
2020     $name  = getpwent();
2021     $gid   = getgrnam($name);
2022     $name  = getgrgid($num);
2023     $name  = getgrent();
2024     #etc.
2025
2026 In I<getpw*()> the fields $quota, $comment, and $expire are special
2027 cases in the sense that in many systems they are unsupported.  If the
2028 $quota is unsupported, it is an empty scalar.  If it is supported, it
2029 usually encodes the disk quota.  If the $comment field is unsupported,
2030 it is an empty scalar.  If it is supported it usually encodes some
2031 administrative comment about the user.  In some systems the $quota
2032 field may be $change or $age, fields that have to do with password
2033 aging.  In some systems the $comment field may be $class.  The $expire
2034 field, if present, encodes the expiration period of the account or the
2035 password.  For the availability and the exact meaning of these fields
2036 in your system, please consult your getpwnam(3) documentation and your
2037 F<pwd.h> file.  You can also find out from within Perl what your
2038 $quota and $comment fields mean and whether you have the $expire field
2039 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2040 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2041 files are only supported if your vendor has implemented them in the
2042 intuitive fashion that calling the regular C library routines gets the
2043 shadow versions if you're running under privilege or if there exists
2044 the shadow(3) functions as found in System V ( this includes Solaris
2045 and Linux.)  Those systems which implement a proprietary shadow password
2046 facility are unlikely to be supported.
2047
2048 The $members value returned by I<getgr*()> is a space separated list of
2049 the login names of the members of the group.
2050
2051 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2052 C, it will be returned to you via C<$?> if the function call fails.  The
2053 C<@addrs> value returned by a successful call is a list of the raw
2054 addresses returned by the corresponding system library call.  In the
2055 Internet domain, each address is four bytes long and you can unpack it
2056 by saying something like:
2057
2058     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2059
2060 The Socket library makes this slightly easier:
2061
2062     use Socket;
2063     $iaddr = inet_aton("127.1"); # or whatever address
2064     $name  = gethostbyaddr($iaddr, AF_INET);
2065
2066     # or going the other way
2067     $straddr = inet_ntoa($iaddr);
2068
2069 If you get tired of remembering which element of the return list
2070 contains which return value, by-name interfaces are provided
2071 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2072 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2073 and C<User::grent>.  These override the normal built-ins, supplying
2074 versions that return objects with the appropriate names
2075 for each field.  For example:
2076
2077    use File::stat;
2078    use User::pwent;
2079    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2080
2081 Even though it looks like they're the same method calls (uid),
2082 they aren't, because a C<File::stat> object is different from
2083 a C<User::pwent> object.
2084
2085 =item getsockname SOCKET
2086
2087 Returns the packed sockaddr address of this end of the SOCKET connection,
2088 in case you don't know the address because you have several different
2089 IPs that the connection might have come in on.
2090
2091     use Socket;
2092     $mysockaddr = getsockname(SOCK);
2093     ($port, $myaddr) = sockaddr_in($mysockaddr);
2094     printf "Connect to %s [%s]\n",
2095        scalar gethostbyaddr($myaddr, AF_INET),
2096        inet_ntoa($myaddr);
2097
2098 =item getsockopt SOCKET,LEVEL,OPTNAME
2099
2100 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2101 Options may exist at multiple protocol levels depending on the socket
2102 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2103 C<Socket> module) will exist. To query options at another level the
2104 protocol number of the appropriate protocol controlling the option
2105 should be supplied. For example, to indicate that an option is to be
2106 interpreted by the TCP protocol, LEVEL should be set to the protocol
2107 number of TCP, which you can get using getprotobyname.
2108
2109 The call returns a packed string representing the requested socket option,
2110 or C<undef> if there is an error (the error reason will be in $!). What
2111 exactly is in the packed string depends in the LEVEL and OPTNAME, consult
2112 your system documentation for details. A very common case however is that
2113 the option is an integer, in which case the result will be an packed
2114 integer which you can decode using unpack with the C<i> (or C<I>) format.
2115
2116 An example testing if Nagle's algorithm is turned on on a socket:
2117
2118     use Socket qw(:all);
2119
2120     defined(my $tcp = getprotobyname("tcp"))
2121         or die "Could not determine the protocol number for tcp";
2122     # my $tcp = IPPROTO_TCP; # Alternative
2123     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2124         or die "Could not query TCP_NODELAY socket option: $!";
2125     my $nodelay = unpack("I", $packed);
2126     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2127
2128
2129 =item glob EXPR
2130
2131 =item glob
2132
2133 In list context, returns a (possibly empty) list of filename expansions on
2134 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2135 scalar context, glob iterates through such filename expansions, returning
2136 undef when the list is exhausted. This is the internal function
2137 implementing the C<< <*.c> >> operator, but you can use it directly. If
2138 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2139 more detail in L<perlop/"I/O Operators">.
2140
2141 Beginning with v5.6.0, this operator is implemented using the standard
2142 C<File::Glob> extension.  See L<File::Glob> for details.
2143
2144 =item gmtime EXPR
2145
2146 Converts a time as returned by the time function to an 8-element list
2147 with the time localized for the standard Greenwich time zone.
2148 Typically used as follows:
2149
2150     #  0    1    2     3     4    5     6     7
2151     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) =
2152                                             gmtime(time);
2153
2154 All list elements are numeric, and come straight out of the C `struct
2155 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2156 specified time.  $mday is the day of the month, and $mon is the month
2157 itself, in the range C<0..11> with 0 indicating January and 11
2158 indicating December.  $year is the number of years since 1900.  That
2159 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2160 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2161 the year, in the range C<0..364> (or C<0..365> in leap years.)
2162
2163 Note that the $year element is I<not> simply the last two digits of
2164 the year.  If you assume it is, then you create non-Y2K-compliant
2165 programs--and you wouldn't want to do that, would you?
2166
2167 The proper way to get a complete 4-digit year is simply:
2168
2169         $year += 1900;
2170
2171 And to get the last two digits of the year (e.g., '01' in 2001) do:
2172
2173         $year = sprintf("%02d", $year % 100);
2174
2175 If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>).
2176
2177 In scalar context, C<gmtime()> returns the ctime(3) value:
2178
2179     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2180
2181 If you need local time instead of GMT use the L</localtime> builtin. 
2182 See also the C<timegm> function provided by the C<Time::Local> module,
2183 and the strftime(3) and mktime(3) functions available via the L<POSIX> module.
2184
2185 This scalar value is B<not> locale dependent (see L<perllocale>), but is
2186 instead a Perl builtin.  To get somewhat similar but locale dependent date
2187 strings, see the example in L</localtime>.
2188
2189 =item goto LABEL
2190
2191 =item goto EXPR
2192
2193 =item goto &NAME
2194
2195 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2196 execution there.  It may not be used to go into any construct that
2197 requires initialization, such as a subroutine or a C<foreach> loop.  It
2198 also can't be used to go into a construct that is optimized away,
2199 or to get out of a block or subroutine given to C<sort>.
2200 It can be used to go almost anywhere else within the dynamic scope,
2201 including out of subroutines, but it's usually better to use some other
2202 construct such as C<last> or C<die>.  The author of Perl has never felt the
2203 need to use this form of C<goto> (in Perl, that is--C is another matter).
2204 (The difference being that C does not offer named loops combined with
2205 loop control.  Perl does, and this replaces most structured uses of C<goto>
2206 in other languages.)
2207
2208 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2209 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2210 necessarily recommended if you're optimizing for maintainability:
2211
2212     goto ("FOO", "BAR", "GLARCH")[$i];
2213
2214 The C<goto-&NAME> form is quite different from the other forms of
2215 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2216 doesn't have the stigma associated with other gotos.  Instead, it
2217 exits the current subroutine (losing any changes set by local()) and
2218 immediately calls in its place the named subroutine using the current
2219 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2220 load another subroutine and then pretend that the other subroutine had
2221 been called in the first place (except that any modifications to C<@_>
2222 in the current subroutine are propagated to the other subroutine.)
2223 After the C<goto>, not even C<caller> will be able to tell that this
2224 routine was called first.
2225
2226 NAME needn't be the name of a subroutine; it can be a scalar variable
2227 containing a code reference, or a block which evaluates to a code
2228 reference.
2229
2230 =item grep BLOCK LIST
2231
2232 =item grep EXPR,LIST
2233
2234 This is similar in spirit to, but not the same as, grep(1) and its
2235 relatives.  In particular, it is not limited to using regular expressions.
2236
2237 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2238 C<$_> to each element) and returns the list value consisting of those
2239 elements for which the expression evaluated to true.  In scalar
2240 context, returns the number of times the expression was true.
2241
2242     @foo = grep(!/^#/, @bar);    # weed out comments
2243
2244 or equivalently,
2245
2246     @foo = grep {!/^#/} @bar;    # weed out comments
2247
2248 Note that C<$_> is an alias to the list value, so it can be used to
2249 modify the elements of the LIST.  While this is useful and supported,
2250 it can cause bizarre results if the elements of LIST are not variables.
2251 Similarly, grep returns aliases into the original list, much as a for
2252 loop's index variable aliases the list elements.  That is, modifying an
2253 element of a list returned by grep (for example, in a C<foreach>, C<map>
2254 or another C<grep>) actually modifies the element in the original list.
2255 This is usually something to be avoided when writing clear code.
2256
2257 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2258 been declared with C<my $_>) then, in addition the be locally aliased to
2259 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2260 can't be seen from the outside, avoiding any potential side-effects.
2261
2262 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2263
2264 =item hex EXPR
2265
2266 =item hex
2267
2268 Interprets EXPR as a hex string and returns the corresponding value.
2269 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2270 L</oct>.)  If EXPR is omitted, uses C<$_>.
2271
2272     print hex '0xAf'; # prints '175'
2273     print hex 'aF';   # same
2274
2275 Hex strings may only represent integers.  Strings that would cause
2276 integer overflow trigger a warning.  Leading whitespace is not stripped,
2277 unlike oct(). To present something as hex, look into L</printf>,
2278 L</sprintf>, or L</unpack>.
2279
2280 =item import
2281
2282 There is no builtin C<import> function.  It is just an ordinary
2283 method (subroutine) defined (or inherited) by modules that wish to export
2284 names to another module.  The C<use> function calls the C<import> method
2285 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2286
2287 =item index STR,SUBSTR,POSITION
2288
2289 =item index STR,SUBSTR
2290
2291 The index function searches for one string within another, but without
2292 the wildcard-like behavior of a full regular-expression pattern match.
2293 It returns the position of the first occurrence of SUBSTR in STR at
2294 or after POSITION.  If POSITION is omitted, starts searching from the
2295 beginning of the string.  The return value is based at C<0> (or whatever
2296 you've set the C<$[> variable to--but don't do that).  If the substring
2297 is not found, returns one less than the base, ordinarily C<-1>.
2298
2299 =item int EXPR
2300
2301 =item int
2302
2303 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2304 You should not use this function for rounding: one because it truncates
2305 towards C<0>, and two because machine representations of floating point
2306 numbers can sometimes produce counterintuitive results.  For example,
2307 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2308 because it's really more like -268.99999999999994315658 instead.  Usually,
2309 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2310 functions will serve you better than will int().
2311
2312 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2313
2314 Implements the ioctl(2) function.  You'll probably first have to say
2315
2316     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
2317
2318 to get the correct function definitions.  If F<ioctl.ph> doesn't
2319 exist or doesn't have the correct definitions you'll have to roll your
2320 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2321 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2322 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2323 written depending on the FUNCTION--a pointer to the string value of SCALAR
2324 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2325 has no string value but does have a numeric value, that value will be
2326 passed rather than a pointer to the string value.  To guarantee this to be
2327 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2328 functions may be needed to manipulate the values of structures used by
2329 C<ioctl>.
2330
2331 The return value of C<ioctl> (and C<fcntl>) is as follows:
2332
2333         if OS returns:          then Perl returns:
2334             -1                    undefined value
2335              0                  string "0 but true"
2336         anything else               that number
2337
2338 Thus Perl returns true on success and false on failure, yet you can
2339 still easily determine the actual value returned by the operating
2340 system:
2341
2342     $retval = ioctl(...) || -1;
2343     printf "System returned %d\n", $retval;
2344
2345 The special string C<"0 but true"> is exempt from B<-w> complaints
2346 about improper numeric conversions.
2347
2348 =item join EXPR,LIST
2349
2350 Joins the separate strings of LIST into a single string with fields
2351 separated by the value of EXPR, and returns that new string.  Example:
2352
2353     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2354
2355 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2356 first argument.  Compare L</split>.
2357
2358 =item keys HASH
2359
2360 Returns a list consisting of all the keys of the named hash.
2361 (In scalar context, returns the number of keys.)
2362
2363 The keys are returned in an apparently random order.  The actual
2364 random order is subject to change in future versions of perl, but it
2365 is guaranteed to be the same order as either the C<values> or C<each>
2366 function produces (given that the hash has not been modified).  Since
2367 Perl 5.8.1 the ordering is different even between different runs of
2368 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2369 Attacks">).
2370
2371 As a side effect, calling keys() resets the HASH's internal iterator,
2372 see L</each>. (In particular, calling keys() in void context resets
2373 the iterator with no other overhead.)
2374
2375 Here is yet another way to print your environment:
2376
2377     @keys = keys %ENV;
2378     @values = values %ENV;
2379     while (@keys) {
2380         print pop(@keys), '=', pop(@values), "\n";
2381     }
2382
2383 or how about sorted by key:
2384
2385     foreach $key (sort(keys %ENV)) {
2386         print $key, '=', $ENV{$key}, "\n";
2387     }
2388
2389 The returned values are copies of the original keys in the hash, so
2390 modifying them will not affect the original hash.  Compare L</values>.
2391
2392 To sort a hash by value, you'll need to use a C<sort> function.
2393 Here's a descending numeric sort of a hash by its values:
2394
2395     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2396         printf "%4d %s\n", $hash{$key}, $key;
2397     }
2398
2399 As an lvalue C<keys> allows you to increase the number of hash buckets
2400 allocated for the given hash.  This can gain you a measure of efficiency if
2401 you know the hash is going to get big.  (This is similar to pre-extending
2402 an array by assigning a larger number to $#array.)  If you say
2403
2404     keys %hash = 200;
2405
2406 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2407 in fact, since it rounds up to the next power of two.  These
2408 buckets will be retained even if you do C<%hash = ()>, use C<undef
2409 %hash> if you want to free the storage while C<%hash> is still in scope.
2410 You can't shrink the number of buckets allocated for the hash using
2411 C<keys> in this way (but you needn't worry about doing this by accident,
2412 as trying has no effect).
2413
2414 See also C<each>, C<values> and C<sort>.
2415
2416 =item kill SIGNAL, LIST
2417
2418 Sends a signal to a list of processes.  Returns the number of
2419 processes successfully signaled (which is not necessarily the
2420 same as the number actually killed).
2421
2422     $cnt = kill 1, $child1, $child2;
2423     kill 9, @goners;
2424
2425 If SIGNAL is zero, no signal is sent to the process.  This is a
2426 useful way to check that a child process is alive and hasn't changed
2427 its UID.  See L<perlport> for notes on the portability of this
2428 construct.
2429
2430 Unlike in the shell, if SIGNAL is negative, it kills
2431 process groups instead of processes.  (On System V, a negative I<PROCESS>
2432 number will also kill process groups, but that's not portable.)  That
2433 means you usually want to use positive not negative signals.  You may also
2434 use a signal name in quotes.
2435
2436 See L<perlipc/"Signals"> for more details.
2437
2438 =item last LABEL
2439
2440 =item last
2441
2442 The C<last> command is like the C<break> statement in C (as used in
2443 loops); it immediately exits the loop in question.  If the LABEL is
2444 omitted, the command refers to the innermost enclosing loop.  The
2445 C<continue> block, if any, is not executed:
2446
2447     LINE: while (<STDIN>) {
2448         last LINE if /^$/;      # exit when done with header
2449         #...
2450     }
2451
2452 C<last> cannot be used to exit a block which returns a value such as
2453 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2454 a grep() or map() operation.
2455
2456 Note that a block by itself is semantically identical to a loop
2457 that executes once.  Thus C<last> can be used to effect an early
2458 exit out of such a block.
2459
2460 See also L</continue> for an illustration of how C<last>, C<next>, and
2461 C<redo> work.
2462
2463 =item lc EXPR
2464
2465 =item lc
2466
2467 Returns a lowercased version of EXPR.  This is the internal function
2468 implementing the C<\L> escape in double-quoted strings.  Respects
2469 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2470 and L<perlunicode> for more details about locale and Unicode support.
2471
2472 If EXPR is omitted, uses C<$_>.
2473
2474 =item lcfirst EXPR
2475
2476 =item lcfirst
2477
2478 Returns the value of EXPR with the first character lowercased.  This
2479 is the internal function implementing the C<\l> escape in
2480 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2481 locale> in force.  See L<perllocale> and L<perlunicode> for more
2482 details about locale and Unicode support.
2483
2484 If EXPR is omitted, uses C<$_>.
2485
2486 =item length EXPR
2487
2488 =item length
2489
2490 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2491 omitted, returns length of C<$_>.  Note that this cannot be used on
2492 an entire array or hash to find out how many elements these have.
2493 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2494
2495 Note the I<characters>: if the EXPR is in Unicode, you will get the
2496 number of characters, not the number of bytes.  To get the length
2497 in bytes, use C<do { use bytes; length(EXPR) }>, see L<bytes>.
2498
2499 =item link OLDFILE,NEWFILE
2500
2501 Creates a new filename linked to the old filename.  Returns true for
2502 success, false otherwise.
2503
2504 =item listen SOCKET,QUEUESIZE
2505
2506 Does the same thing that the listen system call does.  Returns true if
2507 it succeeded, false otherwise.  See the example in
2508 L<perlipc/"Sockets: Client/Server Communication">.
2509
2510 =item local EXPR
2511
2512 You really probably want to be using C<my> instead, because C<local> isn't
2513 what most people think of as "local".  See
2514 L<perlsub/"Private Variables via my()"> for details.
2515
2516 A local modifies the listed variables to be local to the enclosing
2517 block, file, or eval.  If more than one value is listed, the list must
2518 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2519 for details, including issues with tied arrays and hashes.
2520
2521 =item localtime EXPR
2522
2523 =item localtime
2524
2525 Converts a time as returned by the time function to a 9-element list
2526 with the time analyzed for the local time zone.  Typically used as
2527 follows:
2528
2529     #  0    1    2     3     4    5     6     7     8
2530     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2531                                                 localtime(time);
2532
2533 All list elements are numeric, and come straight out of the C `struct
2534 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
2535 of the specified time.
2536
2537 C<$mday> is the day of the month, and C<$mon> is the month itself, in
2538 the range C<0..11> with 0 indicating January and 11 indicating December.
2539 This makes it easy to get a month name from a list:
2540
2541     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
2542     print "$abbr[$mon] $mday";
2543     # $mon=9, $mday=18 gives "Oct 18"
2544
2545 C<$year> is the number of years since 1900, not just the last two digits
2546 of the year.  That is, C<$year> is C<123> in year 2023.  The proper way
2547 to get a complete 4-digit year is simply:
2548
2549     $year += 1900;
2550
2551 To get the last two digits of the year (e.g., '01' in 2001) do:
2552
2553     $year = sprintf("%02d", $year % 100);
2554
2555 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
2556 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
2557 (or C<0..365> in leap years.)
2558
2559 C<$isdst> is true if the specified time occurs during Daylight Saving
2560 Time, false otherwise.
2561
2562 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2563
2564 In scalar context, C<localtime()> returns the ctime(3) value:
2565
2566     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2567
2568 This scalar value is B<not> locale dependent but is a Perl builtin. For GMT
2569 instead of local time use the L</gmtime> builtin. See also the
2570 C<Time::Local> module (to convert the second, minutes, hours, ... back to
2571 the integer value returned by time()), and the L<POSIX> module's strftime(3)
2572 and mktime(3) functions.
2573
2574 To get somewhat similar but locale dependent date strings, set up your
2575 locale environment variables appropriately (please see L<perllocale>) and
2576 try for example:
2577
2578     use POSIX qw(strftime);
2579     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2580     # or for GMT formatted appropriately for your locale:
2581     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2582
2583 Note that the C<%a> and C<%b>, the short forms of the day of the week
2584 and the month of the year, may not necessarily be three characters wide.
2585
2586 =item lock THING
2587
2588 This function places an advisory lock on a shared variable, or referenced
2589 object contained in I<THING> until the lock goes out of scope.
2590
2591 lock() is a "weak keyword" : this means that if you've defined a function
2592 by this name (before any calls to it), that function will be called
2593 instead. (However, if you've said C<use threads>, lock() is always a
2594 keyword.) See L<threads>.
2595
2596 =item log EXPR
2597
2598 =item log
2599
2600 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2601 returns log of C<$_>.  To get the log of another base, use basic algebra:
2602 The base-N log of a number is equal to the natural log of that number
2603 divided by the natural log of N.  For example:
2604
2605     sub log10 {
2606         my $n = shift;
2607         return log($n)/log(10);
2608     }
2609
2610 See also L</exp> for the inverse operation.
2611
2612 =item lstat EXPR
2613
2614 =item lstat
2615
2616 Does the same thing as the C<stat> function (including setting the
2617 special C<_> filehandle) but stats a symbolic link instead of the file
2618 the symbolic link points to.  If symbolic links are unimplemented on
2619 your system, a normal C<stat> is done.  For much more detailed
2620 information, please see the documentation for C<stat>.
2621
2622 If EXPR is omitted, stats C<$_>.
2623
2624 =item m//
2625
2626 The match operator.  See L<perlop>.
2627
2628 =item map BLOCK LIST
2629
2630 =item map EXPR,LIST
2631
2632 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2633 C<$_> to each element) and returns the list value composed of the
2634 results of each such evaluation.  In scalar context, returns the
2635 total number of elements so generated.  Evaluates BLOCK or EXPR in
2636 list context, so each element of LIST may produce zero, one, or
2637 more elements in the returned value.
2638
2639     @chars = map(chr, @nums);
2640
2641 translates a list of numbers to the corresponding characters.  And
2642
2643     %hash = map { getkey($_) => $_ } @array;
2644
2645 is just a funny way to write
2646
2647     %hash = ();
2648     foreach $_ (@array) {
2649         $hash{getkey($_)} = $_;
2650     }
2651
2652 Note that C<$_> is an alias to the list value, so it can be used to
2653 modify the elements of the LIST.  While this is useful and supported,
2654 it can cause bizarre results if the elements of LIST are not variables.
2655 Using a regular C<foreach> loop for this purpose would be clearer in
2656 most cases.  See also L</grep> for an array composed of those items of
2657 the original list for which the BLOCK or EXPR evaluates to true.
2658
2659 If C<$_> is lexical in the scope where the C<map> appears (because it has
2660 been declared with C<my $_>) then, in addition the be locally aliased to
2661 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2662 can't be seen from the outside, avoiding any potential side-effects.
2663
2664 C<{> starts both hash references and blocks, so C<map { ...> could be either
2665 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2666 ahead for the closing C<}> it has to take a guess at which its dealing with
2667 based what it finds just after the C<{>. Usually it gets it right, but if it
2668 doesn't it won't realize something is wrong until it gets to the C<}> and
2669 encounters the missing (or unexpected) comma. The syntax error will be
2670 reported close to the C<}> but you'll need to change something near the C<{>
2671 such as using a unary C<+> to give perl some help:
2672
2673     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2674     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2675     %hash = map { ("\L$_", 1) } @array  # this also works
2676     %hash = map {  lc($_), 1  } @array  # as does this.
2677     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2678
2679     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2680
2681 or to force an anon hash constructor use C<+{>
2682
2683    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2684
2685 and you get list of anonymous hashes each with only 1 entry.
2686
2687 =item mkdir FILENAME,MASK
2688
2689 =item mkdir FILENAME
2690
2691 =item mkdir
2692
2693 Creates the directory specified by FILENAME, with permissions
2694 specified by MASK (as modified by C<umask>).  If it succeeds it
2695 returns true, otherwise it returns false and sets C<$!> (errno).
2696 If omitted, MASK defaults to 0777. If omitted, FILENAME defaults
2697 to C<$_>.
2698
2699 In general, it is better to create directories with permissive MASK,
2700 and let the user modify that with their C<umask>, than it is to supply
2701 a restrictive MASK and give the user no way to be more permissive.
2702 The exceptions to this rule are when the file or directory should be
2703 kept private (mail files, for instance).  The perlfunc(1) entry on
2704 C<umask> discusses the choice of MASK in more detail.
2705
2706 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2707 number of trailing slashes.  Some operating and filesystems do not get
2708 this right, so Perl automatically removes all trailing slashes to keep
2709 everyone happy.
2710
2711 =item msgctl ID,CMD,ARG
2712
2713 Calls the System V IPC function msgctl(2).  You'll probably have to say
2714
2715     use IPC::SysV;
2716
2717 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2718 then ARG must be a variable which will hold the returned C<msqid_ds>
2719 structure.  Returns like C<ioctl>: the undefined value for error,
2720 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2721 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2722
2723 =item msgget KEY,FLAGS
2724
2725 Calls the System V IPC function msgget(2).  Returns the message queue
2726 id, or the undefined value if there is an error.  See also
2727 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2728
2729 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2730
2731 Calls the System V IPC function msgrcv to receive a message from
2732 message queue ID into variable VAR with a maximum message size of
2733 SIZE.  Note that when a message is received, the message type as a
2734 native long integer will be the first thing in VAR, followed by the
2735 actual message.  This packing may be opened with C<unpack("l! a*")>.
2736 Taints the variable.  Returns true if successful, or false if there is
2737 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2738 C<IPC::SysV::Msg> documentation.
2739
2740 =item msgsnd ID,MSG,FLAGS
2741
2742 Calls the System V IPC function msgsnd to send the message MSG to the
2743 message queue ID.  MSG must begin with the native long integer message
2744 type, and be followed by the length of the actual message, and finally
2745 the message itself.  This kind of packing can be achieved with
2746 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2747 or false if there is an error.  See also C<IPC::SysV>
2748 and C<IPC::SysV::Msg> documentation.
2749
2750 =item my EXPR
2751
2752 =item my TYPE EXPR
2753
2754 =item my EXPR : ATTRS
2755
2756 =item my TYPE EXPR : ATTRS
2757
2758 A C<my> declares the listed variables to be local (lexically) to the
2759 enclosing block, file, or C<eval>.  If more than one value is listed,
2760 the list must be placed in parentheses.
2761
2762 The exact semantics and interface of TYPE and ATTRS are still
2763 evolving.  TYPE is currently bound to the use of C<fields> pragma,
2764 and attributes are handled using the C<attributes> pragma, or starting
2765 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
2766 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
2767 L<attributes>, and L<Attribute::Handlers>.
2768
2769 =item next LABEL
2770
2771 =item next
2772
2773 The C<next> command is like the C<continue> statement in C; it starts
2774 the next iteration of the loop:
2775
2776     LINE: while (<STDIN>) {
2777         next LINE if /^#/;      # discard comments
2778         #...
2779     }
2780
2781 Note that if there were a C<continue> block on the above, it would get
2782 executed even on discarded lines.  If the LABEL is omitted, the command
2783 refers to the innermost enclosing loop.
2784
2785 C<next> cannot be used to exit a block which returns a value such as
2786 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2787 a grep() or map() operation.
2788
2789 Note that a block by itself is semantically identical to a loop
2790 that executes once.  Thus C<next> will exit such a block early.
2791
2792 See also L</continue> for an illustration of how C<last>, C<next>, and
2793 C<redo> work.
2794
2795 =item no Module VERSION LIST
2796
2797 =item no Module VERSION
2798
2799 =item no Module LIST
2800
2801 =item no Module
2802
2803 See the C<use> function, of which C<no> is the opposite.
2804
2805 =item oct EXPR
2806
2807 =item oct
2808
2809 Interprets EXPR as an octal string and returns the corresponding
2810 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2811 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2812 binary string.  Leading whitespace is ignored in all three cases.)
2813 The following will handle decimal, binary, octal, and hex in the standard
2814 Perl or C notation:
2815
2816     $val = oct($val) if $val =~ /^0/;
2817
2818 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2819 in octal), use sprintf() or printf():
2820
2821     $perms = (stat("filename"))[2] & 07777;
2822     $oct_perms = sprintf "%lo", $perms;
2823
2824 The oct() function is commonly used when a string such as C<644> needs
2825 to be converted into a file mode, for example. (Although perl will
2826 automatically convert strings into numbers as needed, this automatic
2827 conversion assumes base 10.)
2828
2829 =item open FILEHANDLE,EXPR
2830
2831 =item open FILEHANDLE,MODE,EXPR
2832
2833 =item open FILEHANDLE,MODE,EXPR,LIST
2834
2835 =item open FILEHANDLE,MODE,REFERENCE
2836
2837 =item open FILEHANDLE
2838
2839 Opens the file whose filename is given by EXPR, and associates it with
2840 FILEHANDLE.
2841
2842 (The following is a comprehensive reference to open(): for a gentler
2843 introduction you may consider L<perlopentut>.)
2844
2845 If FILEHANDLE is an undefined scalar variable (or array or hash element)
2846 the variable is assigned a reference to a new anonymous filehandle,
2847 otherwise if FILEHANDLE is an expression, its value is used as the name of
2848 the real filehandle wanted.  (This is considered a symbolic reference, so
2849 C<use strict 'refs'> should I<not> be in effect.)
2850
2851 If EXPR is omitted, the scalar variable of the same name as the
2852 FILEHANDLE contains the filename.  (Note that lexical variables--those
2853 declared with C<my>--will not work for this purpose; so if you're
2854 using C<my>, specify EXPR in your call to open.)
2855
2856 If three or more arguments are specified then the mode of opening and
2857 the file name are separate. If MODE is C<< '<' >> or nothing, the file
2858 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
2859 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
2860 the file is opened for appending, again being created if necessary.
2861
2862 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
2863 indicate that you want both read and write access to the file; thus
2864 C<< '+<' >> is almost always preferred for read/write updates--the C<<
2865 '+>' >> mode would clobber the file first.  You can't usually use
2866 either read-write mode for updating textfiles, since they have
2867 variable length records.  See the B<-i> switch in L<perlrun> for a
2868 better approach.  The file is created with permissions of C<0666>
2869 modified by the process' C<umask> value.
2870
2871 These various prefixes correspond to the fopen(3) modes of C<'r'>,
2872 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
2873
2874 In the 2-arguments (and 1-argument) form of the call the mode and
2875 filename should be concatenated (in this order), possibly separated by
2876 spaces.  It is possible to omit the mode in these forms if the mode is
2877 C<< '<' >>.
2878
2879 If the filename begins with C<'|'>, the filename is interpreted as a
2880 command to which output is to be piped, and if the filename ends with a
2881 C<'|'>, the filename is interpreted as a command which pipes output to
2882 us.  See L<perlipc/"Using open() for IPC">
2883 for more examples of this.  (You are not allowed to C<open> to a command
2884 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2885 and L<perlipc/"Bidirectional Communication with Another Process">
2886 for alternatives.)
2887
2888 For three or more arguments if MODE is C<'|-'>, the filename is
2889 interpreted as a command to which output is to be piped, and if MODE
2890 is C<'-|'>, the filename is interpreted as a command which pipes
2891 output to us.  In the 2-arguments (and 1-argument) form one should
2892 replace dash (C<'-'>) with the command.
2893 See L<perlipc/"Using open() for IPC"> for more examples of this.
2894 (You are not allowed to C<open> to a command that pipes both in I<and>
2895 out, but see L<IPC::Open2>, L<IPC::Open3>, and
2896 L<perlipc/"Bidirectional Communication"> for alternatives.)
2897
2898 In the three-or-more argument form of pipe opens, if LIST is specified
2899 (extra arguments after the command name) then LIST becomes arguments
2900 to the command invoked if the platform supports it.  The meaning of
2901 C<open> with more than three arguments for non-pipe modes is not yet
2902 specified. Experimental "layers" may give extra LIST arguments
2903 meaning.
2904
2905 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2906 and opening C<< '>-' >> opens STDOUT.
2907
2908 You may use the three-argument form of open to specify IO "layers"
2909 (sometimes also referred to as "disciplines") to be applied to the handle
2910 that affect how the input and output are processed (see L<open> and
2911 L<PerlIO> for more details). For example
2912
2913   open(FH, "<:utf8", "file")
2914
2915 will open the UTF-8 encoded file containing Unicode characters,
2916 see L<perluniintro>. (Note that if layers are specified in the
2917 three-arg form then default layers set by the C<open> pragma are
2918 ignored.)
2919
2920 Open returns nonzero upon success, the undefined value otherwise.  If
2921 the C<open> involved a pipe, the return value happens to be the pid of
2922 the subprocess.
2923
2924 If you're running Perl on a system that distinguishes between text
2925 files and binary files, then you should check out L</binmode> for tips
2926 for dealing with this.  The key distinction between systems that need
2927 C<binmode> and those that don't is their text file formats.  Systems
2928 like Unix, Mac OS, and Plan 9, which delimit lines with a single
2929 character, and which encode that character in C as C<"\n">, do not
2930 need C<binmode>.  The rest need it.
2931
2932 When opening a file, it's usually a bad idea to continue normal execution
2933 if the request failed, so C<open> is frequently used in connection with
2934 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2935 where you want to make a nicely formatted error message (but there are
2936 modules that can help with that problem)) you should always check
2937 the return value from opening a file.  The infrequent exception is when
2938 working with an unopened filehandle is actually what you want to do.
2939
2940 As a special case the 3 arg form with a read/write mode and the third
2941 argument being C<undef>:
2942
2943     open(TMP, "+>", undef) or die ...
2944
2945 opens a filehandle to an anonymous temporary file.  Also using "+<"
2946 works for symmetry, but you really should consider writing something
2947 to the temporary file first.  You will need to seek() to do the
2948 reading.
2949
2950 Since v5.8.0, perl has built using PerlIO by default.  Unless you've
2951 changed this (ie Configure -Uuseperlio), you can open file handles to
2952 "in memory" files held in Perl scalars via:
2953
2954     open($fh, '>', \$variable) || ..
2955
2956 Though if you try to re-open C<STDOUT> or C<STDERR> as an "in memory"
2957 file, you have to close it first:
2958
2959     close STDOUT;
2960     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
2961
2962 Examples:
2963
2964     $ARTICLE = 100;
2965     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2966     while (<ARTICLE>) {...
2967
2968     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
2969     # if the open fails, output is discarded
2970
2971     open(DBASE, '+<', 'dbase.mine')             # open for update
2972         or die "Can't open 'dbase.mine' for update: $!";
2973
2974     open(DBASE, '+<dbase.mine')                 # ditto
2975         or die "Can't open 'dbase.mine' for update: $!";
2976
2977     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
2978         or die "Can't start caesar: $!";
2979
2980     open(ARTICLE, "caesar <$article |")         # ditto
2981         or die "Can't start caesar: $!";
2982
2983     open(EXTRACT, "|sort >Tmp$$")               # $$ is our process id
2984         or die "Can't start sort: $!";
2985
2986     # in memory files
2987     open(MEMORY,'>', \$var)
2988         or die "Can't open memory file: $!";
2989     print MEMORY "foo!\n";                      # output will end up in $var
2990
2991     # process argument list of files along with any includes
2992
2993     foreach $file (@ARGV) {
2994         process($file, 'fh00');
2995     }
2996
2997     sub process {
2998         my($filename, $input) = @_;
2999         $input++;               # this is a string increment
3000         unless (open($input, $filename)) {
3001             print STDERR "Can't open $filename: $!\n";
3002             return;
3003         }
3004
3005         local $_;
3006         while (<$input>) {              # note use of indirection
3007             if (/^#include "(.*)"/) {
3008                 process($1, $input);
3009                 next;
3010             }
3011             #...                # whatever
3012         }
3013     }
3014
3015 See L<perliol> for detailed info on PerlIO.
3016
3017 You may also, in the Bourne shell tradition, specify an EXPR beginning
3018 with C<< '>&' >>, in which case the rest of the string is interpreted
3019 as the name of a filehandle (or file descriptor, if numeric) to be
3020 duped (as L<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3021 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3022 The mode you specify should match the mode of the original filehandle.
3023 (Duping a filehandle does not take into account any existing contents
3024 of IO buffers.) If you use the 3 arg form then you can pass either a
3025 number, the name of a filehandle or the normal "reference to a glob".
3026
3027 Here is a script that saves, redirects, and restores C<STDOUT> and
3028 C<STDERR> using various methods:
3029
3030     #!/usr/bin/perl
3031     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3032     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
3033
3034     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
3035     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3036
3037     select STDERR; $| = 1;      # make unbuffered
3038     select STDOUT; $| = 1;      # make unbuffered
3039
3040     print STDOUT "stdout 1\n";  # this works for
3041     print STDERR "stderr 1\n";  # subprocesses too
3042
3043     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
3044     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
3045
3046     print STDOUT "stdout 2\n";
3047     print STDERR "stderr 2\n";
3048
3049 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3050 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3051 that file descriptor (and not call L<dup(2)>); this is more
3052 parsimonious of file descriptors.  For example:
3053
3054     # open for input, reusing the fileno of $fd
3055     open(FILEHANDLE, "<&=$fd")
3056
3057 or
3058
3059     open(FILEHANDLE, "<&=", $fd)
3060
3061 or
3062
3063     # open for append, using the fileno of OLDFH
3064     open(FH, ">>&=", OLDFH)
3065
3066 or
3067
3068     open(FH, ">>&=OLDFH")
3069
3070 Being parsimonious on filehandles is also useful (besides being
3071 parsimonious) for example when something is dependent on file
3072 descriptors, like for example locking using flock().  If you do just
3073 C<< open(A, '>>&B') >>, the filehandle A will not have the same file
3074 descriptor as B, and therefore flock(A) will not flock(B), and vice
3075 versa.  But with C<< open(A, '>>&=B') >> the filehandles will share
3076 the same file descriptor.
3077
3078 Note that if you are using Perls older than 5.8.0, Perl will be using
3079 the standard C libraries' fdopen() to implement the "=" functionality.
3080 On many UNIX systems fdopen() fails when file descriptors exceed a
3081 certain value, typically 255.  For Perls 5.8.0 and later, PerlIO is
3082 most often the default.
3083
3084 You can see whether Perl has been compiled with PerlIO or not by
3085 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
3086 is C<define>, you have PerlIO, otherwise you don't.
3087
3088 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
3089 with 2-arguments (or 1-argument) form of open(), then
3090 there is an implicit fork done, and the return value of open is the pid
3091 of the child within the parent process, and C<0> within the child
3092 process.  (Use C<defined($pid)> to determine whether the open was successful.)
3093 The filehandle behaves normally for the parent, but i/o to that
3094 filehandle is piped from/to the STDOUT/STDIN of the child process.
3095 In the child process the filehandle isn't opened--i/o happens from/to
3096 the new STDOUT or STDIN.  Typically this is used like the normal
3097 piped open when you want to exercise more control over just how the
3098 pipe command gets executed, such as when you are running setuid, and
3099 don't want to have to scan shell commands for metacharacters.
3100 The following triples are more or less equivalent:
3101
3102     open(FOO, "|tr '[a-z]' '[A-Z]'");
3103     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
3104     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
3105     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
3106
3107     open(FOO, "cat -n '$file'|");
3108     open(FOO, '-|', "cat -n '$file'");
3109     open(FOO, '-|') || exec 'cat', '-n', $file;
3110     open(FOO, '-|', "cat", '-n', $file);
3111
3112 The last example in each block shows the pipe as "list form", which is
3113 not yet supported on all platforms.  A good rule of thumb is that if
3114 your platform has true C<fork()> (in other words, if your platform is
3115 UNIX) you can use the list form.
3116
3117 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3118
3119 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3120 output before any operation that may do a fork, but this may not be
3121 supported on some platforms (see L<perlport>).  To be safe, you may need
3122 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3123 of C<IO::Handle> on any open handles.
3124
3125 On systems that support a close-on-exec flag on files, the flag will
3126 be set for the newly opened file descriptor as determined by the value
3127 of $^F.  See L<perlvar/$^F>.
3128
3129 Closing any piped filehandle causes the parent process to wait for the
3130 child to finish, and returns the status value in C<$?> and
3131 C<${^CHILD_ERROR_NATIVE}>.
3132
3133 The filename passed to 2-argument (or 1-argument) form of open() will
3134 have leading and trailing whitespace deleted, and the normal
3135 redirection characters honored.  This property, known as "magic open",
3136 can often be used to good effect.  A user could specify a filename of
3137 F<"rsh cat file |">, or you could change certain filenames as needed:
3138
3139     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3140     open(FH, $filename) or die "Can't open $filename: $!";
3141
3142 Use 3-argument form to open a file with arbitrary weird characters in it,
3143
3144     open(FOO, '<', $file);
3145
3146 otherwise it's necessary to protect any leading and trailing whitespace:
3147
3148     $file =~ s#^(\s)#./$1#;
3149     open(FOO, "< $file\0");
3150
3151 (this may not work on some bizarre filesystems).  One should
3152 conscientiously choose between the I<magic> and 3-arguments form
3153 of open():
3154
3155     open IN, $ARGV[0];
3156
3157 will allow the user to specify an argument of the form C<"rsh cat file |">,
3158 but will not work on a filename which happens to have a trailing space, while
3159
3160     open IN, '<', $ARGV[0];
3161
3162 will have exactly the opposite restrictions.
3163
3164 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3165 should use the C<sysopen> function, which involves no such magic (but
3166 may use subtly different filemodes than Perl open(), which is mapped
3167 to C fopen()).  This is
3168 another way to protect your filenames from interpretation.  For example:
3169
3170     use IO::Handle;
3171     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3172         or die "sysopen $path: $!";
3173     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3174     print HANDLE "stuff $$\n";
3175     seek(HANDLE, 0, 0);
3176     print "File contains: ", <HANDLE>;
3177
3178 Using the constructor from the C<IO::Handle> package (or one of its
3179 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3180 filehandles that have the scope of whatever variables hold references to
3181 them, and automatically close whenever and however you leave that scope:
3182
3183     use IO::File;
3184     #...
3185     sub read_myfile_munged {
3186         my $ALL = shift;
3187         my $handle = new IO::File;
3188         open($handle, "myfile") or die "myfile: $!";
3189         $first = <$handle>
3190             or return ();     # Automatically closed here.
3191         mung $first or die "mung failed";       # Or here.
3192         return $first, <$handle> if $ALL;       # Or here.
3193         $first;                                 # Or here.
3194     }
3195
3196 See L</seek> for some details about mixing reading and writing.
3197
3198 =item opendir DIRHANDLE,EXPR
3199
3200 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3201 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3202 DIRHANDLE may be an expression whose value can be used as an indirect
3203 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3204 scalar variable (or array or hash element), the variable is assigned a
3205 reference to a new anonymous dirhandle.
3206 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3207
3208 =item ord EXPR
3209
3210 =item ord
3211
3212 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3213 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3214 uses C<$_>.
3215
3216 For the reverse, see L</chr>.
3217 See L<perlunicode> and L<encoding> for more about Unicode.
3218
3219 =item our EXPR
3220
3221 =item our EXPR TYPE
3222
3223 =item our EXPR : ATTRS
3224
3225 =item our TYPE EXPR : ATTRS
3226
3227 An C<our> declares the listed variables to be valid globals within
3228 the enclosing block, file, or C<eval>.  That is, it has the same
3229 scoping rules as a "my" declaration, but does not create a local
3230 variable.  If more than one value is listed, the list must be placed
3231 in parentheses.  The C<our> declaration has no semantic effect unless
3232 "use strict vars" is in effect, in which case it lets you use the
3233 declared global variable without qualifying it with a package name.
3234 (But only within the lexical scope of the C<our> declaration.  In this
3235 it differs from "use vars", which is package scoped.)
3236
3237 An C<our> declaration declares a global variable that will be visible
3238 across its entire lexical scope, even across package boundaries.  The
3239 package in which the variable is entered is determined at the point
3240 of the declaration, not at the point of use.  This means the following
3241 behavior holds:
3242
3243     package Foo;
3244     our $bar;           # declares $Foo::bar for rest of lexical scope
3245     $bar = 20;
3246
3247     package Bar;
3248     print $bar;         # prints 20
3249
3250 Multiple C<our> declarations in the same lexical scope are allowed
3251 if they are in different packages.  If they happened to be in the same
3252 package, Perl will emit warnings if you have asked for them.
3253
3254     use warnings;
3255     package Foo;
3256     our $bar;           # declares $Foo::bar for rest of lexical scope
3257     $bar = 20;
3258
3259     package Bar;
3260     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3261     print $bar;         # prints 30
3262
3263     our $bar;           # emits warning
3264
3265 An C<our> declaration may also have a list of attributes associated
3266 with it.
3267
3268 The exact semantics and interface of TYPE and ATTRS are still
3269 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3270 and attributes are handled using the C<attributes> pragma, or starting
3271 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3272 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3273 L<attributes>, and L<Attribute::Handlers>.
3274
3275 The only currently recognized C<our()> attribute is C<unique> which
3276 indicates that a single copy of the global is to be used by all
3277 interpreters should the program happen to be running in a
3278 multi-interpreter environment. (The default behaviour would be for
3279 each interpreter to have its own copy of the global.)  Examples:
3280
3281     our @EXPORT : unique = qw(foo);
3282     our %EXPORT_TAGS : unique = (bar => [qw(aa bb cc)]);
3283     our $VERSION : unique = "1.00";
3284
3285 Note that this attribute also has the effect of making the global
3286 readonly when the first new interpreter is cloned (for example,
3287 when the first new thread is created).
3288
3289 Multi-interpreter environments can come to being either through the
3290 fork() emulation on Windows platforms, or by embedding perl in a
3291 multi-threaded application.  The C<unique> attribute does nothing in
3292 all other environments.
3293
3294 Warning: the current implementation of this attribute operates on the
3295 typeglob associated with the variable; this means that C<our $x : unique>
3296 also has the effect of C<our @x : unique; our %x : unique>. This may be
3297 subject to change.
3298
3299 =item pack TEMPLATE,LIST
3300
3301 Takes a LIST of values and converts it into a string using the rules
3302 given by the TEMPLATE.  The resulting string is the concatenation of
3303 the converted values.  Typically, each converted value looks
3304 like its machine-level representation.  For example, on 32-bit machines
3305 an integer may be represented by a sequence of 4 bytes which will be 
3306 converted to a sequence of 4 characters.
3307
3308 The TEMPLATE is a sequence of characters that give the order and type
3309 of values, as follows:
3310
3311     a   A string with arbitrary binary data, will be null padded.
3312     A   A text (ASCII) string, will be space padded.
3313     Z   A null terminated (ASCIZ) string, will be null padded.
3314
3315     b   A bit string (ascending bit order inside each byte, like vec()).
3316     B   A bit string (descending bit order inside each byte).
3317     h   A hex string (low nybble first).
3318     H   A hex string (high nybble first).
3319
3320     c   A signed char (8-bit) value.
3321     C   An unsigned C char (octet) even under Unicode. Should normally not
3322         be used. See U and W instead.
3323     W   An unsigned char value (can be greater than 255).
3324
3325     s   A signed short (16-bit) value.
3326     S   An unsigned short value.
3327
3328     l   A signed long (32-bit) value.
3329     L   An unsigned long value.
3330
3331     q   A signed quad (64-bit) value.
3332     Q   An unsigned quad value.
3333           (Quads are available only if your system supports 64-bit
3334            integer values _and_ if Perl has been compiled to support those.
3335            Causes a fatal error otherwise.)
3336
3337     i   A signed integer value.
3338     I   A unsigned integer value.
3339           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3340            size depends on what a local C compiler calls 'int'.)
3341  
3342     n   An unsigned short (16-bit) in "network" (big-endian) order.
3343     N   An unsigned long (32-bit) in "network" (big-endian) order.
3344     v   An unsigned short (16-bit) in "VAX" (little-endian) order.
3345     V   An unsigned long (32-bit) in "VAX" (little-endian) order.
3346
3347     j   A Perl internal signed integer value (IV).
3348     J   A Perl internal unsigned integer value (UV).
3349
3350     f   A single-precision float in the native format.
3351     d   A double-precision float in the native format.
3352
3353     F   A Perl internal floating point value (NV) in the native format
3354     D   A long double-precision float in the native format.
3355           (Long doubles are available only if your system supports long
3356            double values _and_ if Perl has been compiled to support those.
3357            Causes a fatal error otherwise.)
3358
3359     p   A pointer to a null-terminated string.
3360     P   A pointer to a structure (fixed-length string).
3361
3362     u   A uuencoded string.
3363     U   A Unicode character number.  Encodes to UTF-8 internally
3364         (or UTF-EBCDIC in EBCDIC platforms).
3365
3366     w   A BER compressed integer (not an ASN.1 BER, see perlpacktut for
3367         details).  Its bytes represent an unsigned integer in base 128,
3368         most significant digit first, with as few digits as possible.  Bit
3369         eight (the high bit) is set on each byte except the last.
3370
3371     x   A null byte.
3372     X   Back up a byte.
3373     @   Null fill or truncate to absolute position, counted from the
3374         start of the innermost ()-group.
3375     .   Null fill or truncate to absolute position specified by value.
3376     (   Start of a ()-group.
3377
3378 Some letters in the TEMPLATE may optionally be followed by one or
3379 more of these modifiers (the second column lists the letters for
3380 which the modifier is valid):
3381
3382     !   sSlLiI     Forces native (short, long, int) sizes instead
3383                    of fixed (16-/32-bit) sizes.
3384
3385         xX         Make x and X act as alignment commands.
3386
3387         nNvV       Treat integers as signed instead of unsigned.
3388
3389         @.         Specify position as byte offset in the internal
3390                    representation of the packed string. Efficient but
3391                    dangerous.
3392
3393     >   sSiIlLqQ   Force big-endian byte-order on the type.
3394         jJfFdDpP   (The "big end" touches the construct.)
3395
3396     <   sSiIlLqQ   Force little-endian byte-order on the type.
3397         jJfFdDpP   (The "little end" touches the construct.)
3398
3399 The C<E<gt>> and C<E<lt>> modifiers can also be used on C<()>-groups,
3400 in which case they force a certain byte-order on all components of
3401 that group, including subgroups.
3402
3403 The following rules apply:
3404
3405 =over 8
3406
3407 =item *
3408
3409 Each letter may optionally be followed by a number giving a repeat
3410 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3411 C<H>, C<@>, C<.>, C<x>, C<X> and C<P> the pack function will gobble up
3412 that many values from the LIST.  A C<*> for the repeat count means to
3413 use however many items are left, except for C<@>, C<x>, C<X>, where it
3414 is equivalent to C<0>, for <.> where it means relative to string start
3415 and C<u>, where it is equivalent to 1 (or 45, which is the same).
3416 A numeric repeat count may optionally be enclosed in brackets, as in
3417 C<pack 'C[80]', @arr>.
3418
3419 One can replace the numeric repeat count by a template enclosed in brackets;
3420 then the packed length of this template in bytes is used as a count.
3421 For example, C<x[L]> skips a long (it skips the number of bytes in a long);
3422 the template C<$t X[$t] $t> unpack()s twice what $t unpacks.
3423 If the template in brackets contains alignment commands (such as C<x![d]>),
3424 its packed length is calculated as if the start of the template has the maximal
3425 possible alignment.
3426
3427 When used with C<Z>, C<*> results in the addition of a trailing null
3428 byte (so the packed result will be one longer than the byte C<length>
3429 of the item).
3430
3431 When used with C<@>, the repeat count represents an offset from the start
3432 of the innermost () group.
3433
3434 When used with C<.>, the repeat count is used to determine the starting
3435 position from where the value offset is calculated. If the repeat count
3436 is 0, it's relative to the current position. If the repeat count is C<*>,
3437 the offset is relative to the start of the packed string. And if its an
3438 integer C<n> the offset is relative to the start of the n-th innermost
3439 () group (or the start of the string if C<n> is bigger then the group
3440 level).
3441
3442 The repeat count for C<u> is interpreted as the maximal number of bytes
3443 to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat 
3444 count should not be more than 65.
3445
3446 =item *
3447
3448 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3449 string of length count, padding with nulls or spaces as necessary.  When
3450 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
3451 after the first null, and C<a> returns data verbatim.
3452
3453 If the value-to-pack is too long, it is truncated.  If too long and an
3454 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3455 by a null byte.  Thus C<Z> always packs a trailing null (except when the
3456 count is 0).
3457
3458 =item *
3459
3460 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3461 Each character of the input field of pack() generates 1 bit of the result.
3462 Each result bit is based on the least-significant bit of the corresponding
3463 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
3464 and C<"1"> generate bits 0 and 1, as do characters C<"\0"> and C<"\1">.
3465
3466 Starting from the beginning of the input string of pack(), each 8-tuple
3467 of characters is converted to 1 character of output.  With format C<b>
3468 the first character of the 8-tuple determines the least-significant bit of a
3469 character, and with format C<B> it determines the most-significant bit of
3470 a character.
3471
3472 If the length of the input string is not exactly divisible by 8, the
3473 remainder is packed as if the input string were padded by null characters
3474 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3475
3476 If the input string of pack() is longer than needed, extra characters are 
3477 ignored. A C<*> for the repeat count of pack() means to use all the 
3478 characters of the input field.  On unpack()ing the bits are converted to a 
3479 string of C<"0">s and C<"1">s.
3480
3481 =item *
3482
3483 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3484 representable as hexadecimal digits, 0-9a-f) long.
3485
3486 Each character of the input field of pack() generates 4 bits of the result.
3487 For non-alphabetical characters the result is based on the 4 least-significant
3488 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
3489 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3490 C<"\0"> and C<"\1">.  For characters C<"a".."f"> and C<"A".."F"> the result
3491 is compatible with the usual hexadecimal digits, so that C<"a"> and
3492 C<"A"> both generate the nybble C<0xa==10>.  The result for characters
3493 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3494
3495 Starting from the beginning of the input string of pack(), each pair
3496 of characters is converted to 1 character of output.  With format C<h> the
3497 first character of the pair determines the least-significant nybble of the
3498 output character, and with format C<H> it determines the most-significant
3499 nybble.
3500
3501 If the length of the input string is not even, it behaves as if padded
3502 by a null character at the end.  Similarly, during unpack()ing the "extra"
3503 nybbles are ignored.
3504
3505 If the input string of pack() is longer than needed, extra characters are
3506 ignored.
3507 A C<*> for the repeat count of pack() means to use all the characters of
3508 the input field.  On unpack()ing the nybbles are converted to a string
3509 of hexadecimal digits.
3510
3511 =item *
3512
3513 The C<p> type packs a pointer to a null-terminated string.  You are
3514 responsible for ensuring the string is not a temporary value (which can
3515 potentially get deallocated before you get around to using the packed result).
3516 The C<P> type packs a pointer to a structure of the size indicated by the
3517 length.  A NULL pointer is created if the corresponding value for C<p> or
3518 C<P> is C<undef>, similarly for unpack().
3519
3520 If your system has a strange pointer size (i.e. a pointer is neither as
3521 big as an int nor as big as a long), it may not be possible to pack or
3522 unpack pointers in big- or little-endian byte order.  Attempting to do
3523 so will result in a fatal error.
3524
3525 =item *
3526
3527 The C</> template character allows packing and unpacking of a sequence of
3528 items where the packed structure contains a packed item count followed by 
3529 the packed items themselves.
3530 You write I<length-item>C</>I<sequence-item>.
3531
3532 The I<length-item> can be any C<pack> template letter, and describes
3533 how the length value is packed.  The ones likely to be of most use are
3534 integer-packing ones like C<n> (for Java strings), C<w> (for ASN.1 or
3535 SNMP) and C<N> (for Sun XDR).
3536
3537 For C<pack>, the I<sequence-item> may have a repeat count, in which case
3538 the minimum of that and the number of available items is used as argument
3539 for the I<length-item>. If it has no repeat count or uses a '*', the number
3540 of available items is used. For C<unpack> the repeat count is always obtained
3541 by decoding the packed item count, and the I<sequence-item> must not have a
3542 repeat count.
3543
3544 If the I<sequence-item> refers to a string type (C<"A">, C<"a"> or C<"Z">),
3545 the I<length-item> is a string length, not a number of strings. If there is
3546 an explicit repeat count for pack, the packed string will be adjusted to that
3547 given length.
3548
3549     unpack 'W/a', "\04Gurusamy";        gives ('Guru')
3550     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond', 'J')
3551     pack 'n/a* w/a','hello,','world';   gives "\000\006hello,\005world"
3552     pack 'a/W2', ord('a') .. ord('z');  gives '2ab'
3553
3554 The I<length-item> is not returned explicitly from C<unpack>.
3555
3556 Adding a count to the I<length-item> letter is unlikely to do anything
3557 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3558 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3559 which Perl does not regard as legal in numeric strings.
3560
3561 =item *
3562
3563 The integer types C<s>, C<S>, C<l>, and C<L> may be
3564 followed by a C<!> modifier to signify native shorts or
3565 longs--as you can see from above for example a bare C<l> does mean
3566 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3567 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3568 see whether using C<!> makes any difference by
3569
3570         print length(pack("s")), " ", length(pack("s!")), "\n";
3571         print length(pack("l")), " ", length(pack("l!")), "\n";
3572
3573 C<i!> and C<I!> also work but only because of completeness;
3574 they are identical to C<i> and C<I>.
3575
3576 The actual sizes (in bytes) of native shorts, ints, longs, and long
3577 longs on the platform where Perl was built are also available via
3578 L<Config>:
3579
3580        use Config;
3581        print $Config{shortsize},    "\n";
3582        print $Config{intsize},      "\n";
3583        print $Config{longsize},     "\n";
3584        print $Config{longlongsize}, "\n";
3585
3586 (The C<$Config{longlongsize}> will be undefined if your system does
3587 not support long longs.)
3588
3589 =item *
3590
3591 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J>
3592 are inherently non-portable between processors and operating systems
3593 because they obey the native byteorder and endianness.  For example a
3594 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3595 (arranged in and handled by the CPU registers) into bytes as
3596
3597         0x12 0x34 0x56 0x78     # big-endian
3598         0x78 0x56 0x34 0x12     # little-endian
3599
3600 Basically, the Intel and VAX CPUs are little-endian, while everybody
3601 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3602 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3603 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3604 mode.
3605
3606 The names `big-endian' and `little-endian' are comic references to
3607 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3608 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3609 the egg-eating habits of the Lilliputians.
3610
3611 Some systems may have even weirder byte orders such as
3612
3613         0x56 0x78 0x12 0x34
3614         0x34 0x12 0x78 0x56
3615
3616 You can see your system's preference with
3617
3618         print join(" ", map { sprintf "%#02x", $_ }
3619                             unpack("W*",pack("L",0x12345678))), "\n";
3620
3621 The byteorder on the platform where Perl was built is also available
3622 via L<Config>:
3623
3624         use Config;
3625         print $Config{byteorder}, "\n";
3626
3627 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3628 and C<'87654321'> are big-endian.
3629
3630 If you want portable packed integers you can either use the formats
3631 C<n>, C<N>, C<v>, and C<V>, or you can use the C<E<gt>> and C<E<lt>>
3632 modifiers.  These modifiers are only available as of perl 5.9.2.
3633 See also L<perlport>.
3634
3635 =item *
3636
3637 All integer and floating point formats as well as C<p> and C<P> and
3638 C<()>-groups may be followed by the C<E<gt>> or C<E<lt>> modifiers
3639 to force big- or little- endian byte-order, respectively.
3640 This is especially useful, since C<n>, C<N>, C<v> and C<V> don't cover
3641 signed integers, 64-bit integers and floating point values.  However,
3642 there are some things to keep in mind.
3643
3644 Exchanging signed integers between different platforms only works
3645 if all platforms store them in the same format.  Most platforms store
3646 signed integers in two's complement, so usually this is not an issue.
3647
3648 The C<E<gt>> or C<E<lt>> modifiers can only be used on floating point
3649 formats on big- or little-endian machines.  Otherwise, attempting to
3650 do so will result in a fatal error.
3651
3652 Forcing big- or little-endian byte-order on floating point values for
3653 data exchange can only work if all platforms are using the same
3654 binary representation (e.g. IEEE floating point format).  Even if all
3655 platforms are using IEEE, there may be subtle differences.  Being able
3656 to use C<E<gt>> or C<E<lt>> on floating point values can be very useful,
3657 but also very dangerous if you don't know exactly what you're doing.
3658 It is definetely not a general way to portably store floating point
3659 values.
3660
3661 When using C<E<gt>> or C<E<lt>> on an C<()>-group, this will affect
3662 all types inside the group that accept the byte-order modifiers,
3663 including all subgroups.  It will silently be ignored for all other
3664 types.  You are not allowed to override the byte-order within a group
3665 that already has a byte-order modifier suffix.
3666
3667 =item *
3668
3669 Real numbers (floats and doubles) are in the native machine format only;
3670 due to the multiplicity of floating formats around, and the lack of a
3671 standard "network" representation, no facility for interchange has been
3672 made.  This means that packed floating point data written on one machine
3673 may not be readable on another - even if both use IEEE floating point
3674 arithmetic (as the endian-ness of the memory representation is not part
3675 of the IEEE spec).  See also L<perlport>.
3676
3677 If you know exactly what you're doing, you can use the C<E<gt>> or C<E<lt>>
3678 modifiers to force big- or little-endian byte-order on floating point values.
3679
3680 Note that Perl uses doubles (or long doubles, if configured) internally for
3681 all numeric calculation, and converting from double into float and thence back
3682 to double again will lose precision (i.e., C<unpack("f", pack("f", $foo)>)
3683 will not in general equal $foo).
3684
3685 =item *
3686
3687 Pack and unpack can operate in two modes, character mode (C<C0> mode) where
3688 the packed string is processed per character and UTF-8 mode (C<U0> mode)
3689 where the packed string is processed in its UTF-8-encoded Unicode form on
3690 a byte by byte basis. Character mode is the default unless the format string 
3691 starts with an C<U>. You can switch mode at any moment with an explicit 
3692 C<C0> or C<U0> in the format. A mode is in effect until the next mode switch 
3693 or until the end of the ()-group in which it was entered.
3694
3695 =item *
3696
3697 You must yourself do any alignment or padding by inserting for example
3698 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3699 could know where the characters are going to or coming from.  Therefore
3700 C<pack> (and C<unpack>) handle their output and input as flat
3701 sequences of characters.
3702
3703 =item *
3704
3705 A ()-group is a sub-TEMPLATE enclosed in parentheses.  A group may
3706 take a repeat count, both as postfix, and for unpack() also via the C</>
3707 template character. Within each repetition of a group, positioning with
3708 C<@> starts again at 0. Therefore, the result of
3709
3710     pack( '@1A((@2A)@3A)', 'a', 'b', 'c' )
3711
3712 is the string "\0a\0\0bc".
3713
3714 =item *
3715
3716 C<x> and C<X> accept C<!> modifier.  In this case they act as
3717 alignment commands: they jump forward/back to the closest position
3718 aligned at a multiple of C<count> characters. For example, to pack() or
3719 unpack() C's C<struct {char c; double d; char cc[2]}> one may need to
3720 use the template C<W x![d] d W[2]>; this assumes that doubles must be
3721 aligned on the double's size.
3722
3723 For alignment commands C<count> of 0 is equivalent to C<count> of 1;
3724 both result in no-ops.
3725
3726 =item *
3727
3728 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier. In this case they
3729 will represent signed 16-/32-bit integers in big-/little-endian order.
3730 This is only portable if all platforms sharing the packed data use the
3731 same binary representation for signed integers (e.g. all platforms are
3732 using two's complement representation).
3733
3734 =item *
3735
3736 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3737 White space may be used to separate pack codes from each other, but
3738 modifiers and a repeat count must follow immediately.
3739
3740 =item *
3741
3742 If TEMPLATE requires more arguments to pack() than actually given, pack()
3743 assumes additional C<""> arguments.  If TEMPLATE requires less arguments
3744 to pack() than actually given, extra arguments are ignored.
3745
3746 =back
3747
3748 Examples:
3749
3750     $foo = pack("WWWW",65,66,67,68);
3751     # foo eq "ABCD"
3752     $foo = pack("W4",65,66,67,68);
3753     # same thing
3754     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
3755     # same thing with Unicode circled letters.
3756     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3757     # same thing with Unicode circled letters. You don't get the UTF-8
3758     # bytes because the U at the start of the format caused a switch to
3759     # U0-mode, so the UTF-8 bytes get joined into characters
3760     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
3761     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
3762     # This is the UTF-8 encoding of the string in the previous example
3763
3764     $foo = pack("ccxxcc",65,66,67,68);
3765     # foo eq "AB\0\0CD"
3766
3767     # note: the above examples featuring "W" and "c" are true
3768     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3769     # and UTF-8.  In EBCDIC the first example would be
3770     # $foo = pack("WWWW",193,194,195,196);
3771
3772     $foo = pack("s2",1,2);
3773     # "\1\0\2\0" on little-endian
3774     # "\0\1\0\2" on big-endian
3775
3776     $foo = pack("a4","abcd","x","y","z");
3777     # "abcd"
3778
3779     $foo = pack("aaaa","abcd","x","y","z");
3780     # "axyz"
3781
3782     $foo = pack("a14","abcdefg");
3783     # "abcdefg\0\0\0\0\0\0\0"
3784
3785     $foo = pack("i9pl", gmtime);
3786     # a real struct tm (on my system anyway)
3787
3788     $utmp_template = "Z8 Z8 Z16 L";
3789     $utmp = pack($utmp_template, @utmp1);
3790     # a struct utmp (BSDish)
3791
3792     @utmp2 = unpack($utmp_template, $utmp);
3793     # "@utmp1" eq "@utmp2"
3794
3795     sub bintodec {
3796         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3797     }
3798
3799     $foo = pack('sx2l', 12, 34);
3800     # short 12, two zero bytes padding, long 34
3801     $bar = pack('s@4l', 12, 34);
3802     # short 12, zero fill to position 4, long 34
3803     # $foo eq $bar
3804     $baz = pack('s.l', 12, 4, 34);
3805     # short 12, zero fill to position 4, long 34
3806
3807     $foo = pack('nN', 42, 4711);
3808     # pack big-endian 16- and 32-bit unsigned integers
3809     $foo = pack('S>L>', 42, 4711);
3810     # exactly the same
3811     $foo = pack('s<l<', -42, 4711);
3812     # pack little-endian 16- and 32-bit signed integers
3813     $foo = pack('(sl)<', -42, 4711);
3814     # exactly the same
3815
3816 The same template may generally also be used in unpack().
3817
3818 =item package NAMESPACE
3819
3820 =item package
3821
3822 Declares the compilation unit as being in the given namespace.  The scope
3823 of the package declaration is from the declaration itself through the end
3824 of the enclosing block, file, or eval (the same as the C<my> operator).
3825 All further unqualified dynamic identifiers will be in this namespace.
3826 A package statement affects only dynamic variables--including those
3827 you've used C<local> on--but I<not> lexical variables, which are created
3828 with C<my>.  Typically it would be the first declaration in a file to
3829 be included by the C<require> or C<use> operator.  You can switch into a
3830 package in more than one place; it merely influences which symbol table
3831 is used by the compiler for the rest of that block.  You can refer to
3832 variables and filehandles in other packages by prefixing the identifier
3833 with the package name and a double colon:  C<$Package::Variable>.
3834 If the package name is null, the C<main> package as assumed.  That is,
3835 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3836 still seen in older code).
3837
3838 If NAMESPACE is omitted, then there is no current package, and all
3839 identifiers must be fully qualified or lexicals.  However, you are
3840 strongly advised not to make use of this feature. Its use can cause
3841 unexpected behaviour, even crashing some versions of Perl. It is
3842 deprecated, and will be removed from a future release.
3843
3844 See L<perlmod/"Packages"> for more information about packages, modules,
3845 and classes.  See L<perlsub> for other scoping issues.
3846
3847 =item pipe READHANDLE,WRITEHANDLE
3848
3849 Opens a pair of connected pipes like the corresponding system call.
3850 Note that if you set up a loop of piped processes, deadlock can occur
3851 unless you are very careful.  In addition, note that Perl's pipes use
3852 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3853 after each command, depending on the application.
3854
3855 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3856 for examples of such things.
3857
3858 On systems that support a close-on-exec flag on files, the flag will be set
3859 for the newly opened file descriptors as determined by the value of $^F.
3860 See L<perlvar/$^F>.
3861
3862 =item pop ARRAY
3863
3864 =item pop
3865
3866 Pops and returns the last value of the array, shortening the array by
3867 one element.  Has an effect similar to
3868
3869     $ARRAY[$#ARRAY--]
3870
3871 If there are no elements in the array, returns the undefined value
3872 (although this may happen at other times as well).  If ARRAY is
3873 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3874 array in subroutines, just like C<shift>.
3875
3876 =item pos SCALAR
3877
3878 =item pos
3879
3880 Returns the offset of where the last C<m//g> search left off for the variable
3881 in question (C<$_> is used when the variable is not specified).  Note that
3882 0 is a valid match offset, while C<undef> indicates that the search position
3883 is reset (usually due to match failure, but can also be because no match has
3884 yet been performed on the scalar). C<pos> directly accesses the location used
3885 by the regexp engine to store the offset, so assigning to C<pos> will change
3886 that offset, and so will also influence the C<\G> zero-width assertion in
3887 regular expressions. Because a failed C<m//gc> match doesn't reset the offset,
3888 the return from C<pos> won't change either in this case.  See L<perlre> and
3889 L<perlop>.
3890
3891 =item print FILEHANDLE LIST
3892
3893 =item print LIST
3894
3895 =item print
3896
3897 Prints a string or a list of strings.  Returns true if successful.
3898 FILEHANDLE may be a scalar variable name, in which case the variable
3899 contains the name of or a reference to the filehandle, thus introducing
3900 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3901 the next token is a term, it may be misinterpreted as an operator
3902 unless you interpose a C<+> or put parentheses around the arguments.)
3903 If FILEHANDLE is omitted, prints by default to standard output (or
3904 to the last selected output channel--see L</select>).  If LIST is
3905 also omitted, prints C<$_> to the currently selected output channel.
3906 To set the default output channel to something other than STDOUT
3907 use the select operation.  The current value of C<$,> (if any) is
3908 printed between each LIST item.  The current value of C<$\> (if
3909 any) is printed after the entire LIST has been printed.  Because
3910 print takes a LIST, anything in the LIST is evaluated in list
3911 context, and any subroutine that you call will have one or more of
3912 its expressions evaluated in list context.  Also be careful not to
3913 follow the print keyword with a left parenthesis unless you want
3914 the corresponding right parenthesis to terminate the arguments to
3915 the print--interpose a C<+> or put parentheses around all the
3916 arguments.
3917
3918 Note that if you're storing FILEHANDLES in an array or other expression,
3919 you will have to use a block returning its value instead:
3920
3921     print { $files[$i] } "stuff\n";
3922     print { $OK ? STDOUT : STDERR } "stuff\n";
3923
3924 =item printf FILEHANDLE FORMAT, LIST
3925
3926 =item printf FORMAT, LIST
3927
3928 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3929 (the output record separator) is not appended.  The first argument
3930 of the list will be interpreted as the C<printf> format. See C<sprintf>
3931 for an explanation of the format argument. If C<use locale> is in effect,
3932 the character used for the decimal point in formatted real numbers is
3933 affected by the LC_NUMERIC locale.  See L<perllocale>.
3934
3935 Don't fall into the trap of using a C<printf> when a simple
3936 C<print> would do.  The C<print> is more efficient and less
3937 error prone.
3938
3939 =item prototype FUNCTION
3940
3941 Returns the prototype of a function as a string (or C<undef> if the
3942 function has no prototype).  FUNCTION is a reference to, or the name of,
3943 the function whose prototype you want to retrieve.
3944
3945 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
3946 name for Perl builtin.  If the builtin is not I<overridable> (such as
3947 C<qw//>) or its arguments cannot be expressed by a prototype (such as
3948 C<system>) returns C<undef> because the builtin does not really behave
3949 like a Perl function.  Otherwise, the string describing the equivalent
3950 prototype is returned.
3951
3952 =item push ARRAY,LIST
3953
3954 Treats ARRAY as a stack, and pushes the values of LIST
3955 onto the end of ARRAY.  The length of ARRAY increases by the length of
3956 LIST.  Has the same effect as
3957
3958     for $value (LIST) {
3959         $ARRAY[++$#ARRAY] = $value;
3960     }
3961
3962 but is more efficient.  Returns the new number of elements in the array.
3963
3964 =item q/STRING/
3965
3966 =item qq/STRING/
3967
3968 =item qr/STRING/
3969
3970 =item qx/STRING/
3971
3972 =item qw/STRING/
3973
3974 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
3975
3976 =item quotemeta EXPR
3977
3978 =item quotemeta
3979
3980 Returns the value of EXPR with all non-"word"
3981 characters backslashed.  (That is, all characters not matching
3982 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
3983 returned string, regardless of any locale settings.)
3984 This is the internal function implementing
3985 the C<\Q> escape in double-quoted strings.
3986
3987 If EXPR is omitted, uses C<$_>.
3988
3989 =item rand EXPR
3990
3991 =item rand
3992
3993 Returns a random fractional number greater than or equal to C<0> and less
3994 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
3995 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
3996 also special-cased as C<1> - this has not been documented before perl 5.8.0
3997 and is subject to change in future versions of perl.  Automatically calls
3998 C<srand> unless C<srand> has already been called.  See also C<srand>.
3999
4000 Apply C<int()> to the value returned by C<rand()> if you want random
4001 integers instead of random fractional numbers.  For example,
4002
4003     int(rand(10))
4004
4005 returns a random integer between C<0> and C<9>, inclusive.
4006
4007 (Note: If your rand function consistently returns numbers that are too
4008 large or too small, then your version of Perl was probably compiled
4009 with the wrong number of RANDBITS.)
4010
4011 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
4012
4013 =item read FILEHANDLE,SCALAR,LENGTH
4014
4015 Attempts to read LENGTH I<characters> of data into variable SCALAR
4016 from the specified FILEHANDLE.  Returns the number of characters
4017 actually read, C<0> at end of file, or undef if there was an error (in
4018 the latter case C<$!> is also set).  SCALAR will be grown or shrunk 
4019 so that the last character actually read is the last character of the
4020 scalar after the read.
4021
4022 An OFFSET may be specified to place the read data at some place in the
4023 string other than the beginning.  A negative OFFSET specifies
4024 placement at that many characters counting backwards from the end of
4025 the string.  A positive OFFSET greater than the length of SCALAR
4026 results in the string being padded to the required size with C<"\0">
4027 bytes before the result of the read is appended.
4028
4029 The call is actually implemented in terms of either Perl's or system's
4030 fread() call.  To get a true read(2) system call, see C<sysread>.
4031
4032 Note the I<characters>: depending on the status of the filehandle,
4033 either (8-bit) bytes or characters are read.  By default all
4034 filehandles operate on bytes, but for example if the filehandle has
4035 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
4036 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4037 characters, not bytes.  Similarly for the C<:encoding> pragma:
4038 in that case pretty much any characters can be read.
4039
4040 =item readdir DIRHANDLE
4041
4042 Returns the next directory entry for a directory opened by C<opendir>.
4043 If used in list context, returns all the rest of the entries in the
4044 directory.  If there are no more entries, returns an undefined value in
4045 scalar context or a null list in list context.
4046
4047 If you're planning to filetest the return values out of a C<readdir>, you'd
4048 better prepend the directory in question.  Otherwise, because we didn't
4049 C<chdir> there, it would have been testing the wrong file.
4050
4051     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
4052     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
4053     closedir DIR;
4054
4055 =item readline EXPR
4056
4057 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
4058 context, each call reads and returns the next line, until end-of-file is
4059 reached, whereupon the subsequent call returns undef.  In list context,
4060 reads until end-of-file is reached and returns a list of lines.  Note that
4061 the notion of "line" used here is however you may have defined it
4062 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
4063
4064 When C<$/> is set to C<undef>, when readline() is in scalar
4065 context (i.e. file slurp mode), and when an empty file is read, it
4066 returns C<''> the first time, followed by C<undef> subsequently.
4067
4068 This is the internal function implementing the C<< <EXPR> >>
4069 operator, but you can use it directly.  The C<< <EXPR> >>
4070 operator is discussed in more detail in L<perlop/"I/O Operators">.
4071
4072     $line = <STDIN>;
4073     $line = readline(*STDIN);           # same thing
4074
4075 If readline encounters an operating system error, C<$!> will be set with the
4076 corresponding error message.  It can be helpful to check C<$!> when you are
4077 reading from filehandles you don't trust, such as a tty or a socket.  The
4078 following example uses the operator form of C<readline>, and takes the necessary
4079 steps to ensure that C<readline> was successful.
4080
4081     for (;;) {
4082         undef $!;
4083         unless (defined( $line = <> )) {
4084             die $! if $!;
4085             last; # reached EOF
4086         }
4087         # ...
4088     }
4089
4090 =item readlink EXPR
4091
4092 =item readlink
4093
4094 Returns the value of a symbolic link, if symbolic links are
4095 implemented.  If not, gives a fatal error.  If there is some system
4096 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
4097 omitted, uses C<$_>.
4098
4099 =item readpipe EXPR
4100
4101 EXPR is executed as a system command.
4102 The collected standard output of the command is returned.
4103 In scalar context, it comes back as a single (potentially
4104 multi-line) string.  In list context, returns a list of lines
4105 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
4106 This is the internal function implementing the C<qx/EXPR/>
4107 operator, but you can use it directly.  The C<qx/EXPR/>
4108 operator is discussed in more detail in L<perlop/"I/O Operators">.
4109
4110 =item recv SOCKET,SCALAR,LENGTH,FLAGS
4111
4112 Receives a message on a socket.  Attempts to receive LENGTH characters
4113 of data into variable SCALAR from the specified SOCKET filehandle.
4114 SCALAR will be grown or shrunk to the length actually read.  Takes the
4115 same flags as the system call of the same name.  Returns the address
4116 of the sender if SOCKET's protocol supports this; returns an empty
4117 string otherwise.  If there's an error, returns the undefined value.
4118 This call is actually implemented in terms of recvfrom(2) system call.
4119 See L<perlipc/"UDP: Message Passing"> for examples.
4120
4121 Note the I<characters>: depending on the status of the socket, either
4122 (8-bit) bytes or characters are received.  By default all sockets
4123 operate on bytes, but for example if the socket has been changed using
4124 binmode() to operate with the C<:utf8> I/O layer (see the C<open>
4125 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4126 characters, not bytes.  Similarly for the C<:encoding> pragma:
4127 in that case pretty much any characters can be read.
4128
4129 =item redo LABEL
4130
4131 =item redo
4132
4133 The C<redo> command restarts the loop block without evaluating the
4134 conditional again.  The C<continue> block, if any, is not executed.  If
4135 the LABEL is omitted, the command refers to the innermost enclosing
4136 loop.  This command is normally used by programs that want to lie to
4137 themselves about what was just input:
4138
4139     # a simpleminded Pascal comment stripper
4140     # (warning: assumes no { or } in strings)
4141     LINE: while (<STDIN>) {
4142         while (s|({.*}.*){.*}|$1 |) {}
4143         s|{.*}| |;
4144         if (s|{.*| |) {
4145             $front = $_;
4146             while (<STDIN>) {
4147                 if (/}/) {      # end of comment?
4148                     s|^|$front\{|;
4149                     redo LINE;
4150                 }
4151             }
4152         }
4153         print;
4154     }
4155
4156 C<redo> cannot be used to retry a block which returns a value such as
4157 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
4158 a grep() or map() operation.
4159
4160 Note that a block by itself is semantically identical to a loop
4161 that executes once.  Thus C<redo> inside such a block will effectively
4162 turn it into a looping construct.
4163
4164 See also L</continue> for an illustration of how C<last>, C<next>, and
4165 C<redo> work.
4166
4167 =item ref EXPR
4168
4169 =item ref
4170
4171 Returns a non-empty string if EXPR is a reference, the empty
4172 string otherwise. If EXPR
4173 is not specified, C<$_> will be used.  The value returned depends on the
4174 type of thing the reference is a reference to.
4175 Builtin types include:
4176
4177     SCALAR
4178     ARRAY
4179     HASH
4180     CODE
4181     REF
4182     GLOB
4183     LVALUE
4184
4185 If the referenced object has been blessed into a package, then that package
4186 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
4187
4188     if (ref($r) eq "HASH") {
4189         print "r is a reference to a hash.\n";
4190     }
4191     unless (ref($r)) {
4192         print "r is not a reference at all.\n";
4193     }
4194     if (UNIVERSAL::isa($r, "HASH")) {  # for subclassing
4195         print "r is a reference to something that isa hash.\n";
4196     }
4197
4198 See also L<perlref>.
4199
4200 =item rename OLDNAME,NEWNAME
4201
4202 Changes the name of a file; an existing file NEWNAME will be
4203 clobbered.  Returns true for success, false otherwise.
4204
4205 Behavior of this function varies wildly depending on your system
4206 implementation.  For example, it will usually not work across file system
4207 boundaries, even though the system I<mv> command sometimes compensates
4208 for this.  Other restrictions include whether it works on directories,
4209 open files, or pre-existing files.  Check L<perlport> and either the
4210 rename(2) manpage or equivalent system documentation for details.
4211
4212 =item require VERSION
4213
4214 =item require EXPR
4215
4216 =item require
4217
4218 Demands a version of Perl specified by VERSION, or demands some semantics
4219 specified by EXPR or by C<$_> if EXPR is not supplied.
4220
4221 VERSION may be either a numeric argument such as 5.006, which will be
4222 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
4223 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
4224 VERSION is greater than the version of the current Perl interpreter.
4225 Compare with L</use>, which can do a similar check at compile time.
4226
4227 Specifying VERSION as a literal of the form v5.6.1 should generally be
4228 avoided, because it leads to misleading error messages under earlier
4229 versions of Perl which do not support this syntax.  The equivalent numeric
4230 version should be used instead.
4231
4232     require v5.6.1;     # run time version check
4233     require 5.6.1;      # ditto
4234     require 5.006_001;  # ditto; preferred for backwards compatibility
4235
4236 Otherwise, demands that a library file be included if it hasn't already
4237 been included.  The file is included via the do-FILE mechanism, which is
4238 essentially just a variety of C<eval>.  Has semantics similar to the
4239 following subroutine:
4240
4241     sub require {
4242        my ($filename) = @_;
4243        if (exists $INC{$filename}) {
4244            return 1 if $INC{$filename};
4245            die "Compilation failed in require";
4246        }
4247        my ($realfilename,$result);
4248        ITER: {
4249            foreach $prefix (@INC) {
4250                $realfilename = "$prefix/$filename";
4251                if (-f $realfilename) {
4252                    $INC{$filename} = $realfilename;
4253                    $result = do $realfilename;
4254                    last ITER;
4255                }
4256            }
4257            die "Can't find $filename in \@INC";
4258        }
4259        if ($@) {
4260            $INC{$filename} = undef;
4261            die $@;
4262        } elsif (!$result) {
4263            delete $INC{$filename};
4264            die "$filename did not return true value";
4265        } else {
4266            return $result;
4267        }
4268     }
4269
4270 Note that the file will not be included twice under the same specified
4271 name.
4272
4273 The file must return true as the last statement to indicate
4274 successful execution of any initialization code, so it's customary to
4275 end such a file with C<1;> unless you're sure it'll return true
4276 otherwise.  But it's better just to put the C<1;>, in case you add more
4277 statements.
4278
4279 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
4280 replaces "F<::>" with "F</>" in the filename for you,
4281 to make it easy to load standard modules.  This form of loading of
4282 modules does not risk altering your namespace.
4283
4284 In other words, if you try this:
4285
4286         require Foo::Bar;    # a splendid bareword
4287
4288 The require function will actually look for the "F<Foo/Bar.pm>" file in the
4289 directories specified in the C<@INC> array.
4290
4291 But if you try this:
4292
4293         $class = 'Foo::Bar';
4294         require $class;      # $class is not a bareword
4295     #or
4296         require "Foo::Bar";  # not a bareword because of the ""
4297
4298 The require function will look for the "F<Foo::Bar>" file in the @INC array and
4299 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
4300
4301         eval "require $class";
4302
4303 Now that you understand how C<require> looks for files in the case of
4304 a bareword argument, there is a little extra functionality going on
4305 behind the scenes.  Before C<require> looks for a "F<.pm>" extension,
4306 it will first look for a filename with a "F<.pmc>" extension.  A file
4307 with this extension is assumed to be Perl bytecode generated by
4308 L<B::Bytecode|B::Bytecode>.  If this file is found, and its modification
4309 time is newer than a coinciding "F<.pm>" non-compiled file, it will be
4310 loaded in place of that non-compiled file ending in a "F<.pm>" extension.
4311
4312 You can also insert hooks into the import facility, by putting directly
4313 Perl code into the @INC array.  There are three forms of hooks: subroutine
4314 references, array references and blessed objects.
4315
4316 Subroutine references are the simplest case.  When the inclusion system
4317 walks through @INC and encounters a subroutine, this subroutine gets
4318 called with two parameters, the first being a reference to itself, and the
4319 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
4320 subroutine should return C<undef> or a filehandle, from which the file to
4321 include will be read.  If C<undef> is returned, C<require> will look at
4322 the remaining elements of @INC.
4323
4324 If the hook is an array reference, its first element must be a subroutine
4325 reference.  This subroutine is called as above, but the first parameter is
4326 the array reference.  This enables to pass indirectly some arguments to
4327 the subroutine.
4328
4329 In other words, you can write:
4330
4331     push @INC, \&my_sub;
4332     sub my_sub {
4333         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
4334         ...
4335     }
4336
4337 or:
4338
4339     push @INC, [ \&my_sub, $x, $y, ... ];
4340     sub my_sub {
4341         my ($arrayref, $filename) = @_;
4342         # Retrieve $x, $y, ...
4343         my @parameters = @$arrayref[1..$#$arrayref];
4344         ...
4345     }
4346
4347 If the hook is an object, it must provide an INC method, that will be
4348 called as above, the first parameter being the object itself.  (Note that
4349 you must fully qualify the sub's name, as it is always forced into package
4350 C<main>.)  Here is a typical code layout:
4351
4352     # In Foo.pm
4353     package Foo;
4354     sub new { ... }
4355     sub Foo::INC {
4356         my ($self, $filename) = @_;
4357         ...
4358     }
4359
4360     # In the main program
4361     push @INC, new Foo(...);
4362
4363 Note that these hooks are also permitted to set the %INC entry
4364 corresponding to the files they have loaded. See L<perlvar/%INC>.
4365
4366 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
4367
4368 =item reset EXPR
4369
4370 =item reset
4371
4372 Generally used in a C<continue> block at the end of a loop to clear
4373 variables and reset C<??> searches so that they work again.  The
4374 expression is interpreted as a list of single characters (hyphens
4375 allowed for ranges).  All variables and arrays beginning with one of
4376 those letters are reset to their pristine state.  If the expression is
4377 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
4378 only variables or searches in the current package.  Always returns
4379 1.  Examples:
4380
4381     reset 'X';          # reset all X variables
4382     reset 'a-z';        # reset lower case variables
4383     reset;              # just reset ?one-time? searches
4384
4385 Resetting C<"A-Z"> is not recommended because you'll wipe out your
4386 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
4387 variables--lexical variables are unaffected, but they clean themselves
4388 up on scope exit anyway, so you'll probably want to use them instead.
4389 See L</my>.
4390
4391 =item return EXPR
4392
4393 =item return
4394
4395 Returns from a subroutine, C<eval>, or C<do FILE> with the value
4396 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
4397 context, depending on how the return value will be used, and the context
4398 may vary from one execution to the next (see C<wantarray>).  If no EXPR
4399 is given, returns an empty list in list context, the undefined value in
4400 scalar context, and (of course) nothing at all in a void context.
4401
4402 (Note that in the absence of an explicit C<return>, a subroutine, eval,
4403 or do FILE will automatically return the value of the last expression
4404 evaluated.)
4405
4406 =item reverse LIST
4407
4408 In list context, returns a list value consisting of the elements
4409 of LIST in the opposite order.  In scalar context, concatenates the
4410 elements of LIST and returns a string value with all characters
4411 in the opposite order.
4412
4413     print reverse <>;           # line tac, last line first
4414
4415     undef $/;                   # for efficiency of <>
4416     print scalar reverse <>;    # character tac, last line tsrif
4417
4418 Used without arguments in scalar context, reverse() reverses C<$_>.
4419
4420 This operator is also handy for inverting a hash, although there are some
4421 caveats.  If a value is duplicated in the original hash, only one of those
4422 can be represented as a key in the inverted hash.  Also, this has to
4423 unwind one hash and build a whole new one, which may take some time
4424 on a large hash, such as from a DBM file.
4425
4426     %by_name = reverse %by_address;     # Invert the hash
4427
4428 =item rewinddir DIRHANDLE
4429
4430 Sets the current position to the beginning of the directory for the
4431 C<readdir> routine on DIRHANDLE.
4432
4433 =item rindex STR,SUBSTR,POSITION
4434
4435 =item rindex STR,SUBSTR
4436
4437 Works just like index() except that it returns the position of the LAST
4438 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
4439 last occurrence at or before that position.
4440
4441 =item rmdir FILENAME
4442
4443 =item rmdir
4444
4445 Deletes the directory specified by FILENAME if that directory is
4446 empty.  If it succeeds it returns true, otherwise it returns false and
4447 sets C<$!> (errno).  If FILENAME is omitted, uses C<$_>.
4448
4449 =item s///
4450
4451 The substitution operator.  See L<perlop>.
4452
4453 =item scalar EXPR
4454
4455 Forces EXPR to be interpreted in scalar context and returns the value
4456 of EXPR.
4457
4458     @counts = ( scalar @a, scalar @b, scalar @c );
4459
4460 There is no equivalent operator to force an expression to
4461 be interpolated in list context because in practice, this is never
4462 needed.  If you really wanted to do so, however, you could use
4463 the construction C<@{[ (some expression) ]}>, but usually a simple
4464 C<(some expression)> suffices.
4465
4466 Because C<scalar> is unary operator, if you accidentally use for EXPR a
4467 parenthesized list, this behaves as a scalar comma expression, evaluating
4468 all but the last element in void context and returning the final element
4469 evaluated in scalar context.  This is seldom what you want.
4470
4471 The following single statement:
4472
4473         print uc(scalar(&foo,$bar)),$baz;
4474
4475 is the moral equivalent of these two:
4476
4477         &foo;
4478         print(uc($bar),$baz);
4479
4480 See L<perlop> for more details on unary operators and the comma operator.
4481
4482 =item seek FILEHANDLE,POSITION,WHENCE
4483
4484 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
4485 FILEHANDLE may be an expression whose value gives the name of the
4486 filehandle.  The values for WHENCE are C<0> to set the new position
4487 I<in bytes> to POSITION, C<1> to set it to the current position plus
4488 POSITION, and C<2> to set it to EOF plus POSITION (typically
4489 negative).  For WHENCE you may use the constants C<SEEK_SET>,
4490 C<SEEK_CUR>, and C<SEEK_END> (start of the file, current position, end
4491 of the file) from the Fcntl module.  Returns C<1> upon success, C<0>
4492 otherwise.
4493
4494 Note the I<in bytes>: even if the filehandle has been set to
4495 operate on characters (for example by using the C<:utf8> open
4496 layer), tell() will return byte offsets, not character offsets
4497 (because implementing that would render seek() and tell() rather slow).
4498
4499 If you want to position file for C<sysread> or C<syswrite>, don't use
4500 C<seek>--buffering makes its effect on the file's system position
4501 unpredictable and non-portable.  Use C<sysseek> instead.
4502
4503 Due to the rules and rigors of ANSI C, on some systems you have to do a
4504 seek whenever you switch between reading and writing.  Amongst other
4505 things, this may have the effect of calling stdio's clearerr(3).
4506 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
4507
4508     seek(TEST,0,1);
4509
4510 This is also useful for applications emulating C<tail -f>.  Once you hit
4511 EOF on your read, and then sleep for a while, you might have to stick in a
4512 seek() to reset things.  The C<seek> doesn't change the current position,
4513 but it I<does> clear the end-of-file condition on the handle, so that the
4514 next C<< <FILE> >> makes Perl try again to read something.  We hope.
4515
4516 If that doesn't work (some IO implementations are particularly
4517 cantankerous), then you may need something more like this:
4518
4519     for (;;) {
4520         for ($curpos = tell(FILE); $_ = <FILE>;
4521              $curpos = tell(FILE)) {
4522             # search for some stuff and put it into files
4523         }
4524         sleep($for_a_while);
4525         seek(FILE, $curpos, 0);
4526     }
4527
4528 =item seekdir DIRHANDLE,POS
4529
4530 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
4531 must be a value returned by C<telldir>.  Has the same caveats about
4532 possible directory compaction as the corresponding system library
4533 routine.
4534
4535 =item select FILEHANDLE
4536
4537 =item select
4538
4539 Returns the currently selected filehandle.  Sets the current default
4540 filehandle for output, if FILEHANDLE is supplied.  This has two
4541 effects: first, a C<write> or a C<print> without a filehandle will
4542 default to this FILEHANDLE.  Second, references to variables related to
4543 output will refer to this output channel.  For example, if you have to
4544 set the top of form format for more than one output channel, you might
4545 do the following:
4546
4547     select(REPORT1);
4548     $^ = 'report1_top';
4549     select(REPORT2);
4550     $^ = 'report2_top';
4551
4552 FILEHANDLE may be an expression whose value gives the name of the
4553 actual filehandle.  Thus:
4554
4555     $oldfh = select(STDERR); $| = 1; select($oldfh);
4556
4557 Some programmers may prefer to think of filehandles as objects with
4558 methods, preferring to write the last example as:
4559
4560     use IO::Handle;
4561     STDERR->autoflush(1);
4562
4563 =item select RBITS,WBITS,EBITS,TIMEOUT
4564
4565 This calls the select(2) system call with the bit masks specified, which
4566 can be constructed using C<fileno> and C<vec>, along these lines:
4567
4568     $rin = $win = $ein = '';
4569     vec($rin,fileno(STDIN),1) = 1;
4570     vec($win,fileno(STDOUT),1) = 1;
4571     $ein = $rin | $win;
4572
4573 If you want to select on many filehandles you might wish to write a
4574 subroutine:
4575
4576     sub fhbits {
4577         my(@fhlist) = split(' ',$_[0]);
4578         my($bits);
4579         for (@fhlist) {
4580             vec($bits,fileno($_),1) = 1;
4581         }
4582         $bits;
4583     }
4584     $rin = fhbits('STDIN TTY SOCK');
4585
4586 The usual idiom is:
4587
4588     ($nfound,$timeleft) =
4589       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
4590
4591 or to block until something becomes ready just do this
4592
4593     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
4594
4595 Most systems do not bother to return anything useful in $timeleft, so
4596 calling select() in scalar context just returns $nfound.
4597
4598 Any of the bit masks can also be undef.  The timeout, if specified, is
4599 in seconds, which may be fractional.  Note: not all implementations are
4600 capable of returning the $timeleft.  If not, they always return
4601 $timeleft equal to the supplied $timeout.
4602
4603 You can effect a sleep of 250 milliseconds this way:
4604
4605     select(undef, undef, undef, 0.25);
4606
4607 Note that whether C<select> gets restarted after signals (say, SIGALRM)
4608 is implementation-dependent.  See also L<perlport> for notes on the
4609 portability of C<select>.
4610
4611 On error, C<select> returns C<undef> and sets C<$!>.
4612
4613 Note: on some Unixes, the select(2) system call may report a socket file
4614 descriptor as "ready for reading", when actually no data is available,
4615 thus a subsequent read blocks. It can be avoided using always the
4616 O_NONBLOCK flag on the socket. See select(2) and fcntl(2) for further
4617 details.
4618
4619 B<WARNING>: One should not attempt to mix buffered I/O (l