regen_perly.pl

   1 #!/usr/bin/perl
   2 #
   3 # regen_perly.pl, DAPM 12-Feb-04
   4 #
   5 # Copyright (c) 2004, 2005 Larry Wall
   6 #
   7 # Given an input file perly.y, run bison on it and produce
   8 # the following output files:
   9 #
  10 # perly.h       standard bison header file with minor doctoring of
  11 #               #line directives plus adding a #ifdef PERL_CORE
  12 #
  13 # perly.tab     the parser table C definitions extracted from the bison output
  14 #               plus an extra table generated by this script.
  15 #
  16 # perly.act     the action case statements extracted from the bison output
  17 #
  18 # Note that perly.c is *not* regenerated - this is now a static file which
  19 # is not dependent on perly.y any more.
  20 #
  21 # If a filename of the form foo.y is given on the command line, then
  22 # this is used instead as the basename for all the files mentioned
  23 # above.
  24 #
  25 # Note that temporary files of the form perlytmp.h and perlytmp.c are
  26 # created and then deleted during this process
  27 #
  28 # Note also that this script is intended to be run on a UNIX system;
  29 # it may work elsewhere but no specific attempt has been made to make it
  30 # portable.
  31
  32 sub usage { die "usage: $0 [ -b bison_executable ] [ file.y ]\n" }
  33
  34 use warnings;
  35 use strict;
  36
  37 BEGIN { require 'regen/regen_lib.pl'; }
  38
  39 my $bison = 'bison';
  40
  41 if (@ARGV >= 2 and $ARGV[0] eq '-b') {
  42     shift;
  43     $bison = shift;
  44 }
  45
  46 my $y_file = shift || 'perly.y';
  47
  48 usage unless @ARGV==0 && $y_file =~ /\.y$/;
  49
  50 (my $h_file    = $y_file) =~ s/\.y$/.h/;
  51 (my $act_file  = $y_file) =~ s/\.y$/.act/;
  52 (my $tab_file  = $y_file) =~ s/\.y$/.tab/;
  53 (my $tmpc_file = $y_file) =~ s/\.y$/tmp.c/;
  54 (my $tmph_file = $y_file) =~ s/\.y$/tmp.h/;
  55 my $new_h_file = "$h_file-new";
  56 my $new_act_file = "$act_file-new";
  57 my $new_tab_file = "$tab_file-new";
  58
  59 # the yytranslate[] table generated by bison is ASCII/EBCDIC sensitive
  60
  61 die "$0: must be run on an ASCII system\n" unless ord 'A' == 65;
  62
  63 # check for correct version number. The constraints are:
  64 #  * must be >= 1.24 to avoid licensing issues.
  65 #  * it must generate the yystos[] table. Version 1.28 doesn't generate
  66 #    this; 1.35+ does
  67 #  * Must produce output which is extractable by the regexes below
  68 #  * Must produce the right values.
  69 # These last two contstraints  may well be met by earlier versions, but
  70 # I simply haven't tested them yet. If it works for you, then modify
  71 # the test below to allow that version too. DAPM Feb 04.
  72
  73 my $version = `$bison -V`;
  74 unless ($version) { die <<EOF; }
  75 Could not find a version of bison in your path. Please install bison.
  76 EOF
  77
  78 unless ($version =~ /\b(1\.875[a-z]?|2\.[0134])\b/) { die <<EOF; }
  79
  80 You have the wrong version of bison in your path; currently 1.875
  81 2.0, 2.1, 2.3 or 2.4 is required.  Try installing
  82     http://ftp.gnu.org/gnu/bison/bison-2.4.1.tar.gz
  83 or similar.  Your bison identifies itself as:
  84
  85 $version
  86 EOF
  87
  88 # creates $tmpc_file and $tmph_file
  89 my_system("$bison -d -o $tmpc_file $y_file");
  90
  91 open CTMPFILE, $tmpc_file or die "Can't open $tmpc_file: $!\n";
  92 my $clines;
  93 { local $/; $clines = <CTMPFILE>; }
  94 die "failed to read $tmpc_file: length mismatch\n"
  95     unless length $clines == -s $tmpc_file;
  96 close CTMPFILE;
  97
  98 my ($actlines, $tablines) = extract($clines);
  99
 100 $tablines .= make_type_tab($y_file, $tablines);
 101
 102 chmod 0644, $new_act_file;
 103 open ACTFILE, ">$new_act_file" or die "can't open $new_act_file: $!\n";
 104 print ACTFILE $actlines;
 105 close ACTFILE;
 106 chmod 0444, $new_act_file;
 107
 108 chmod 0644, $new_tab_file;
 109 open TABFILE, ">$new_tab_file" or die "can't open $new_tab_file: $!\n";
 110 print TABFILE $tablines;
 111 close TABFILE;
 112 chmod 0444, $new_tab_file;
 113
 114 unlink $tmpc_file;
 115
 116 # Wrap PERL_CORE round the symbol definitions. Also,  the
 117 # C<#line 30 "perly.y"> confuses the Win32 resource compiler and the
 118 # C<#line 188 "perlytmp.h"> gets picked up by make depend, so remove them.
 119
 120 open TMPH_FILE, $tmph_file or die "Can't open $tmph_file: $!\n";
 121 chmod 0644, $new_h_file;
 122 open H_FILE, ">$new_h_file" or die "Can't open $new_h_file: $!\n";
 123 my $endcore_done = 0;
 124 # Token macros need to be generated manually on bison 2.4
 125 my $gather_tokens = ($version =~ /\b2\.4\b/ ? undef : 0);
 126 my $tokens;
 127 while (<TMPH_FILE>) {
 128     print H_FILE "#ifdef PERL_CORE\n" if $. == 1;
 129     if (!$endcore_done and /YYSTYPE_IS_DECLARED/) {
 130         print H_FILE "#endif /* PERL_CORE */\n";
 131         $endcore_done = 1;
 132     }
 133     next if /^#line \d+ ".*"/;
 134     if (not defined $gather_tokens) {
 135         $gather_tokens = 1 if /^\s* enum \s* yytokentype \s* \{/x;
 136     }
 137     elsif ($gather_tokens) {
 138         if (/^\# \s* endif/x) { # The #endif just after the end of the token enum
 139             $gather_tokens = 0;
 140             $_ .= "\n/* Tokens.  */\n$tokens";
 141         }
 142         else {
 143             my ($tok, $val) = /(\w+) \s* = \s* (\d+)/x;
 144             $tokens .= "#define $tok $val\n" if $tok;
 145         }
 146     }
 147     print H_FILE $_;
 148 }
 149 close TMPH_FILE;
 150 close H_FILE;
 151 chmod 0444, $new_h_file;
 152 unlink $tmph_file;
 153
 154 rename_if_different($new_h_file, $h_file);
 155 rename_if_different($new_tab_file, $tab_file);
 156 rename_if_different($new_act_file, $act_file);
 157
 158 exit 0;
 159
 160
 161 sub extract {
 162     my $clines = shift;
 163     my $tablines;
 164     my $actlines;
 165
 166     $clines =~ m@
 167         (?:
 168             ^/* YYFINAL[^\n]+\n         #optional comment
 169         )?
 170         \# \s* define \s* YYFINAL       # first #define
 171         .*?                             # other defines + most tables
 172         yystos\[\]\s*=                  # start of last table
 173         .*?
 174         }\s*;                           # end of last table
 175     @xms
 176         or die "Can't extract tables from $tmpc_file\n";
 177     $tablines = $&;
 178
 179
 180     $clines =~ m@
 181         switch \s* \( \s* \w+ \s* \) \s* { \s*
 182         (
 183             case \s* \d+ \s* :
 184             \s*
 185             (?: \s* /\* .*? \*/ \s* )*  # optional C-comments
 186             \s*
 187             \#line [^\n]+"\Q$y_file\E"
 188             .*?
 189         )
 190         }
 191         \s*
 192         (?: \s* /\* .*? \*/ \s* )*      # optional C-comments
 193         \s*
 194         (
 195             \#line[^\n]+\.c"
 196         |
 197             \#line[^\n]+\.simple"
 198         |
 199             YY_SYMBOL_PRINT
 200         )
 201     @xms
 202         or die "Can't extract actions from $tmpc_file\n";
 203     $actlines = $1;
 204
 205     # Remove extraneous comments from bison 2.4
 206     $actlines =~ s!\s* /\* \s* Line \s* \d+ \s* of \s* yacc\.c \s* \*/!!gx;
 207
 208     # C<#line 188 "perlytmp.c"> gets picked up by make depend, so remove them.
 209     $actlines =~ s/^#line \d+ "\Q$tmpc_file\E".*$//gm;
 210
 211     # convert yyvsp[nnn] into ps[nnn].val
 212
 213     $actlines =~ s/yyvsp\[(.*?)\]/ps[$1].val/g
 214         or die "Can't convert value stack name\n";
 215
 216     return $actlines. "\n", $tablines. "\n";
 217 }
 218
 219 # Generate a table, yy_type_tab[], that specifies for each token, what
 220 # type of value it holds.
 221 #
 222 # Read the .y file and extract a list of all the token names and
 223 # non-terminal names; then scan the string $tablines for the table yytname,
 224 # which gives the token index of each token/non-terminal; then use this to
 225 # create yy_type_tab.
 226 #
 227 # ie given (in perly.y),
 228 #
 229 #   %token <opval> A
 230 #   %token <ival>  B
 231 #   %type  <pval>  C
 232 #   %type  <opval> D
 233 #
 234 # and (in $tablines),
 235 #
 236 #   yytname[] = { "A" "B", "C", "D", "E" };
 237 #
 238 # then return
 239 #
 240 #    typedef enum { toketype_ival, toketype_opval, toketype_pval } toketypes;
 241 #
 242 #    static const toketypes yy_type_tab[]
 243 #          = { toketype_opval, toketype_ival, toketype_pval,
 244 #                toketype_opval, toketype_ival }
 245 #
 246 # where "E" has the default type. The default type is determined
 247 # by the __DEFAULT__ comment  next to the appropriate union member in
 248 # perly.y
 249
 250 sub make_type_tab {
 251     my ($y_file, $tablines) = @_;
 252     my %tokens;
 253     my %types;
 254     my $default_token;
 255     open my $fh, '<', $y_file or die "Can't open $y_file: $!\n";
 256     while (<$fh>) {
 257         if (/(\$\d+)\s*=/) {
 258             warn "$y_file:$.: dangerous assignment to $1: $_";
 259         }
 260
 261         if (/__DEFAULT__/) {
 262             m{(\w+) \s* ; \s* /\* \s* __DEFAULT__}x
 263                 or die "$y_file: can't parse __DEFAULT__ line: $_";
 264             die "$y_file: duplicate __DEFAULT__ line: $_"
 265                     if defined $default_token;
 266             $default_token = $1;
 267             next;
 268         }
 269
 270         next unless /^%(token|type)/;
 271         s/^%(token|type)\s+<(\w+)>\s+//
 272             or die "$y_file: unparseable token/type line: $_";
 273         $tokens{$_} = $2 for (split ' ', $_);
 274         $types{$2} = 1;
 275     }
 276     die "$y_file: no __DEFAULT__ token defined\n" unless $default_token;
 277     $types{$default_token} = 1;
 278
 279     $tablines =~ /^\Qstatic const char *const yytname[] =\E\n
 280             {\n
 281             (.*?)
 282             ^};
 283             /xsm
 284         or die "Can't extract yytname[] from table string\n";
 285     my $fields = $1;
 286     $fields =~ s{"([^"]+)"}
 287                 { "toketype_" .
 288                     (defined $tokens{$1} ? $tokens{$1} : $default_token)
 289                 }ge;
 290     $fields =~ s/, \s* 0 \s* $//x
 291         or die "make_type_tab: couldn't delete trailing ',0'\n";
 292
 293     return
 294           "\ntypedef enum {\n\t"
 295         . join(", ", map "toketype_$_", sort keys %types)
 296         . "\n} toketypes;\n\n"
 297         . "/* type of each token/terminal */\n"
 298         . "static const toketypes yy_type_tab[] =\n{\n"
 299         . $fields
 300         . "\n};\n";
 301 }
 302
 303
 304 sub my_system {
 305     system(@_);
 306     if ($? == -1) {
 307         die "failed to execute command '@_': $!\n";
 308     }
 309     elsif ($? & 127) {
 310         die sprintf "command '@_' died with signal %d\n",
 311             ($? & 127);
 312     }
 313     elsif ($? >> 8) {
 314         die sprintf "command '@_' exited with value %d\n", $? >> 8;
 315     }
 316 }