This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
More o' them pesky typos fixed
[perl5.git] / pod / perlref.pod
1 =head1 NAME
2
3 perlref - Perl references and nested data structures
4
5 =head1 DESCRIPTION
6
7 Before release 5 of Perl it was difficult to represent complex data
8 structures, because all references had to be symbolic, and even that was
9 difficult to do when you wanted to refer to a variable rather than a
10 symbol table entry.  Perl 5 not only makes it easier to use symbolic
11 references to variables, but lets you have "hard" references to any piece
12 of data.  Any scalar may hold a hard reference.  Since arrays and hashes
13 contain scalars, you can now easily build arrays of arrays, arrays of
14 hashes, hashes of arrays, arrays of hashes of functions, and so on.
15
16 Hard references are smart--they keep track of reference counts for you,
17 automatically freeing the thing referred to when its reference count
18 goes to zero.  If that thing happens to be an object, the object is
19 destructed.  See L<perlobj> for more about objects.  (In a sense,
20 everything in Perl is an object, but we usually reserve the word for
21 references to objects that have been officially "blessed" into a class package.)
22
23 A symbolic reference contains the name of a variable, just as a
24 symbolic link in the filesystem merely contains the name of a file.  
25 The C<*glob> notation is a kind of symbolic reference.  Hard references
26 are more like hard links in the file system: merely another way
27 at getting at the same underlying object, irrespective of its name.
28
29 "Hard" references are easy to use in Perl.  There is just one
30 overriding principle:  Perl does no implicit referencing or
31 dereferencing.  When a scalar is holding a reference, it always behaves
32 as a scalar.  It doesn't magically start being an array or a hash
33 unless you tell it so explicitly by dereferencing it.
34
35 References can be constructed several ways.
36
37 =over 4
38
39 =item 1.
40
41 By using the backslash operator on a variable, subroutine, or value.
42 (This works much like the & (address-of) operator works in C.)  Note
43 that this typically creates I<ANOTHER> reference to a variable, since
44 there's already a reference to the variable in the symbol table.  But
45 the symbol table reference might go away, and you'll still have the
46 reference that the backslash returned.  Here are some examples:
47
48     $scalarref = \$foo;
49     $arrayref  = \@ARGV;
50     $hashref   = \%ENV;
51     $coderef   = \&handler;
52     $globref   = \*STDOUT;
53
54
55 =item 2.
56
57 A reference to an anonymous array can be constructed using square
58 brackets:
59
60     $arrayref = [1, 2, ['a', 'b', 'c']];
61
62 Here we've constructed a reference to an anonymous array of three elements
63 whose final element is itself reference to another anonymous array of three
64 elements.  (The multidimensional syntax described later can be used to
65 access this.  For example, after the above, $arrayref-E<gt>[2][1] would have
66 the value "b".)
67
68 Note that taking a reference to an enumerated list is not the same
69 as using square brackets--instead it's the same as creating
70 a list of references!
71
72     @list = (\$a, \$b, \$c);  
73     @list = \($a, $b, $c);      # same thing!
74
75 =item 3.
76
77 A reference to an anonymous hash can be constructed using curly
78 brackets:
79
80     $hashref = {
81         'Adam'  => 'Eve',
82         'Clyde' => 'Bonnie',
83     };
84
85 Anonymous hash and array constructors can be intermixed freely to
86 produce as complicated a structure as you want.  The multidimensional
87 syntax described below works for these too.  The values above are
88 literals, but variables and expressions would work just as well, because
89 assignment operators in Perl (even within local() or my()) are executable
90 statements, not compile-time declarations.
91
92 Because curly brackets (braces) are used for several other things
93 including BLOCKs, you may occasionally have to disambiguate braces at the
94 beginning of a statement by putting a C<+> or a C<return> in front so
95 that Perl realizes the opening brace isn't starting a BLOCK.  The economy and
96 mnemonic value of using curlies is deemed worth this occasional extra
97 hassle.
98
99 For example, if you wanted a function to make a new hash and return a
100 reference to it, you have these options:
101
102     sub hashem {        { @_ } }   # silently wrong
103     sub hashem {       +{ @_ } }   # ok
104     sub hashem { return { @_ } }   # ok
105
106 =item 4.
107
108 A reference to an anonymous subroutine can be constructed by using
109 C<sub> without a subname:
110
111     $coderef = sub { print "Boink!\n" };
112
113 Note the presence of the semicolon.  Except for the fact that the code
114 inside isn't executed immediately, a C<sub {}> is not so much a
115 declaration as it is an operator, like C<do{}> or C<eval{}>.  (However, no
116 matter how many times you execute that line (unless you're in an
117 C<eval("...")>), C<$coderef> will still have a reference to the I<SAME>
118 anonymous subroutine.)
119
120 Anonymous subroutines act as closures with respect to my() variables,
121 that is, variables visible lexically within the current scope.  Closure
122 is a notion out of the Lisp world that says if you define an anonymous
123 function in a particular lexical context, it pretends to run in that
124 context even when it's called outside of the context.
125
126 In human terms, it's a funny way of passing arguments to a subroutine when
127 you define it as well as when you call it.  It's useful for setting up
128 little bits of code to run later, such as callbacks.  You can even
129 do object-oriented stuff with it, though Perl provides a different
130 mechanism to do that already--see L<perlobj>.
131
132 You can also think of closure as a way to write a subroutine template without
133 using eval.  (In fact, in version 5.000, eval was the I<only> way to get
134 closures.  You may wish to use "require 5.001" if you use closures.)
135
136 Here's a small example of how closures works:
137
138     sub newprint {
139         my $x = shift;
140         return sub { my $y = shift; print "$x, $y!\n"; };
141     }
142     $h = newprint("Howdy");
143     $g = newprint("Greetings");
144
145     # Time passes...
146
147     &$h("world");
148     &$g("earthlings");
149
150 This prints
151
152     Howdy, world!
153     Greetings, earthlings!
154
155 Note particularly that $x continues to refer to the value passed into
156 newprint() I<despite> the fact that the "my $x" has seemingly gone out of
157 scope by the time the anonymous subroutine runs.  That's what closure
158 is all about.
159
160 This only applies to lexical variables, by the way.  Dynamic variables
161 continue to work as they have always worked.  Closure is not something
162 that most Perl programmers need trouble themselves about to begin with.
163
164 =item 5.
165
166 References are often returned by special subroutines called constructors.
167 Perl objects are just references to a special kind of object that happens to know
168 which package it's associated with.  Constructors are just special
169 subroutines that know how to create that association.  They do so by
170 starting with an ordinary reference, and it remains an ordinary reference
171 even while it's also being an object.  Constructors are customarily
172 named new(), but don't have to be:
173
174     $objref = new Doggie (Tail => 'short', Ears => 'long');
175
176 =item 6.
177
178 References of the appropriate type can spring into existence if you
179 dereference them in a context that assumes they exist.  Since we haven't
180 talked about dereferencing yet, we can't show you any examples yet.
181
182 =item 7.
183
184 References to filehandles can be created by taking a reference to 
185 a typeglob.  This is currently the best way to pass filehandles into or
186 out of subroutines, or to store them in larger data structures.
187
188     splutter(\*STDOUT);
189     sub splutter {
190         my $fh = shift;
191         print $fh "her um well a hmmm\n";
192     }
193
194     $rec = get_rec(\*STDIN);
195     sub get_rec {
196         my $fh = shift;
197         return scalar <$fh>;
198     }
199
200 =back
201
202 That's it for creating references.  By now you're probably dying to
203 know how to use references to get back to your long-lost data.  There
204 are several basic methods.
205
206 =over 4
207
208 =item 1.
209
210 Anywhere you'd put an identifier as part of a variable or subroutine
211 name, you can replace the identifier with a simple scalar variable
212 containing a reference of the correct type:
213
214     $bar = $$scalarref;
215     push(@$arrayref, $filename);
216     $$arrayref[0] = "January";
217     $$hashref{"KEY"} = "VALUE";
218     &$coderef(1,2,3);
219     print $globref "output\n";
220
221 It's important to understand that we are specifically I<NOT> dereferencing
222 C<$arrayref[0]> or C<$hashref{"KEY"}> there.  The dereference of the
223 scalar variable happens I<BEFORE> it does any key lookups.  Anything more
224 complicated than a simple scalar variable must use methods 2 or 3 below.
225 However, a "simple scalar" includes an identifier that itself uses method
226 1 recursively.  Therefore, the following prints "howdy".
227
228     $refrefref = \\\"howdy";
229     print $$$$refrefref;
230
231 =item 2.
232
233 Anywhere you'd put an identifier as part of a variable or subroutine
234 name, you can replace the identifier with a BLOCK returning a reference
235 of the correct type.  In other words, the previous examples could be
236 written like this:
237
238     $bar = ${$scalarref};
239     push(@{$arrayref}, $filename);
240     ${$arrayref}[0] = "January";
241     ${$hashref}{"KEY"} = "VALUE";
242     &{$coderef}(1,2,3);
243     $globref->print("output\n");  # iff you use FileHandle
244
245 Admittedly, it's a little silly to use the curlies in this case, but
246 the BLOCK can contain any arbitrary expression, in particular,
247 subscripted expressions:
248
249     &{ $dispatch{$index} }(1,2,3);      # call correct routine 
250
251 Because of being able to omit the curlies for the simple case of C<$$x>,
252 people often make the mistake of viewing the dereferencing symbols as
253 proper operators, and wonder about their precedence.  If they were,
254 though, you could use parens instead of braces.  That's not the case.
255 Consider the difference below; case 0 is a short-hand version of case 1,
256 I<NOT> case 2:
257
258     $$hashref{"KEY"}   = "VALUE";       # CASE 0
259     ${$hashref}{"KEY"} = "VALUE";       # CASE 1
260     ${$hashref{"KEY"}} = "VALUE";       # CASE 2
261     ${$hashref->{"KEY"}} = "VALUE";     # CASE 3
262
263 Case 2 is also deceptive in that you're accessing a variable
264 called %hashref, not dereferencing through $hashref to the hash
265 it's presumably referencing.  That would be case 3.
266
267 =item 3.
268
269 The case of individual array elements arises often enough that it gets
270 cumbersome to use method 2.  As a form of syntactic sugar, the two
271 lines like that above can be written:
272
273     $arrayref->[0] = "January";
274     $hashref->{"KEY"} = "VALUE";
275
276 The left side of the array can be any expression returning a reference,
277 including a previous dereference.  Note that C<$array[$x]> is I<NOT> the
278 same thing as C<$array-E<gt>[$x]> here:
279
280     $array[$x]->{"foo"}->[0] = "January";
281
282 This is one of the cases we mentioned earlier in which references could
283 spring into existence when in an lvalue context.  Before this
284 statement, C<$array[$x]> may have been undefined.  If so, it's
285 automatically defined with a hash reference so that we can look up
286 C<{"foo"}> in it.  Likewise C<$array[$x]-E<gt>{"foo"}> will automatically get
287 defined with an array reference so that we can look up C<[0]> in it.
288
289 One more thing here.  The arrow is optional I<BETWEEN> brackets
290 subscripts, so you can shrink the above down to
291
292     $array[$x]{"foo"}[0] = "January";
293
294 Which, in the degenerate case of using only ordinary arrays, gives you
295 multidimensional arrays just like C's:
296
297     $score[$x][$y][$z] += 42;
298
299 Well, okay, not entirely like C's arrays, actually.  C doesn't know how
300 to grow its arrays on demand.  Perl does.
301
302 =item 4.
303
304 If a reference happens to be a reference to an object, then there are
305 probably methods to access the things referred to, and you should probably
306 stick to those methods unless you're in the class package that defines the
307 object's methods.  In other words, be nice, and don't violate the object's
308 encapsulation without a very good reason.  Perl does not enforce
309 encapsulation.  We are not totalitarians here.  We do expect some basic
310 civility though.
311
312 =back
313
314 The ref() operator may be used to determine what type of thing the
315 reference is pointing to.  See L<perlfunc>.
316
317 The bless() operator may be used to associate a reference with a package
318 functioning as an object class.  See L<perlobj>.
319
320 A typeglob may be dereferenced the same way a reference can, since
321 the dereference syntax always indicates the kind of reference desired.
322 So C<${*foo}> and C<${\$foo}> both indicate the same scalar variable.
323
324 Here's a trick for interpolating a subroutine call into a string:
325
326     print "My sub returned @{[mysub(1,2,3)]} that time.\n";
327
328 The way it works is that when the C<@{...}> is seen in the double-quoted
329 string, it's evaluated as a block.  The block creates a reference to an
330 anonymous array containing the results of the call to C<mysub(1,2,3)>.  So
331 the whole block returns a reference to an array, which is then
332 dereferenced by C<@{...}> and stuck into the double-quoted string. This
333 chicanery is also useful for arbitrary expressions:
334
335     print "That yeilds @{[$n + 5]} widgets\n";
336
337 =head2 Symbolic references
338
339 We said that references spring into existence as necessary if they are
340 undefined, but we didn't say what happens if a value used as a
341 reference is already defined, but I<ISN'T> a hard reference.  If you
342 use it as a reference in this case, it'll be treated as a symbolic
343 reference.  That is, the value of the scalar is taken to be the I<NAME>
344 of a variable, rather than a direct link to a (possibly) anonymous
345 value.
346
347 People frequently expect it to work like this.  So it does.
348
349     $name = "foo";
350     $$name = 1;                 # Sets $foo
351     ${$name} = 2;               # Sets $foo
352     ${$name x 2} = 3;           # Sets $foofoo
353     $name->[0] = 4;             # Sets $foo[0]
354     @$name = ();                # Clears @foo
355     &$name();                   # Calls &foo() (as in Perl 4)
356     $pack = "THAT";
357     ${"${pack}::$name"} = 5;    # Sets $THAT::foo without eval
358
359 This is very powerful, and slightly dangerous, in that it's possible
360 to intend (with the utmost sincerity) to use a hard reference, and
361 accidentally use a symbolic reference instead.  To protect against
362 that, you can say
363
364     use strict 'refs';
365
366 and then only hard references will be allowed for the rest of the enclosing
367 block.  An inner block may countermand that with 
368
369     no strict 'refs';
370
371 Only package variables are visible to symbolic references.  Lexical
372 variables (declared with my()) aren't in a symbol table, and thus are
373 invisible to this mechanism.  For example:
374
375     local($value) = 10;
376     $ref = \$value;
377     {
378         my $value = 20;
379         print $$ref;
380     } 
381
382 This will still print 10, not 20.  Remember that local() affects package
383 variables, which are all "global" to the package.
384
385 =head2 Not-so-symbolic references
386
387 A new feature contributing to readability in 5.001 is that the brackets
388 around a symbolic reference behave more like quotes, just as they
389 always have within a string.  That is,
390
391     $push = "pop on ";
392     print "${push}over";
393
394 has always meant to print "pop on over", despite the fact that push is
395 a reserved word.  This has been generalized to work the same outside
396 of quotes, so that
397
398     print ${push} . "over";
399
400 and even
401
402     print ${ push } . "over";
403
404 will have the same effect.  (This would have been a syntax error in
405 5.000, though Perl 4 allowed it in the spaceless form.)  Note that this
406 construct is I<not> considered to be a symbolic reference when you're
407 using strict refs:
408
409     use strict 'refs';
410     ${ bareword };      # Okay, means $bareword.
411     ${ "bareword" };    # Error, symbolic reference.
412
413 Similarly, because of all the subscripting that is done using single
414 words, we've applied the same rule to any bareword that is used for
415 subscripting a hash.  So now, instead of writing
416
417     $array{ "aaa" }{ "bbb" }{ "ccc" }
418
419 you can just write
420
421     $array{ aaa }{ bbb }{ ccc }
422
423 and not worry about whether the subscripts are reserved words.  In the
424 rare event that you do wish to do something like
425
426     $array{ shift }
427
428 you can force interpretation as a reserved word by adding anything that
429 makes it more than a bareword:
430
431     $array{ shift() }
432     $array{ +shift }
433     $array{ shift @_ }
434
435 The B<-w> switch will warn you if it interprets a reserved word as a string.
436 But it will no longer warn you about using lowercase words, since the
437 string is effectively quoted.
438
439 =head1 WARNING
440
441 You may not (usefully) use a reference as the key to a hash.  It will be
442 converted into a string:
443
444     $x{ \$a } = $a;
445
446 If you try to dereference the key, it won't do a hard dereference, and 
447 you won't accomplish what you're attemping.  You might want to do something
448 more like
449
450     $r = \@a;
451     $x{ $r } = $r;
452
453 And then at least you can use the values(), which will be
454 real refs, instead of the keys(), which won't.
455
456 =head1 SEE ALSO
457
458 Besides the obvious documents, source code can be instructive.
459 Some rather pathological examples of the use of references can be found
460 in the F<t/op/ref.t> regression test in the Perl source directory.
461
462 See also L<perldsc> and L<perllol> for how to use references to create
463 complex data structures, and L<perlobj> for how to use them to create
464 objects.