This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Skip most of FindExt's tests for troublesome configurations.
[perl5.git] / t / porting / FindExt.t
1 #!../miniperl -w
2
3 BEGIN {
4     @INC = qw(../win32 ../lib);
5     require './test.pl';
6     skip_all('FindExt not portable')
7         if $^O eq 'VMS';
8 }
9 use strict;
10 use Config;
11
12 # Test that Win32/FindExt.pm is consistent with Configure in determining the
13 # types of extensions.
14
15 if ($^O eq "MSWin32" && !defined $ENV{PERL_STATIC_EXT}) {
16     skip_all "PERL_STATIC_EXT must be set to the list of static extensions";
17 }
18
19 require FindExt;
20
21 FindExt::apply_config(\%Config);
22 FindExt::scan_ext("../$_")
23     foreach qw(cpan dist ext);
24 FindExt::set_static_extensions(split ' ', $^O eq 'MSWin32'
25                                ? $ENV{PERL_STATIC_EXT} : $Config{static_ext});
26
27 sub compare {
28     my ($desc, $want, @have) = @_;
29     $want = [sort split ' ', $want]
30         unless ref $want eq 'ARRAY';
31     local $::Level = $::Level + 1;
32     is(scalar @have, scalar @$want, "We find the same number of $desc");
33     is("@have", "@$want", "We find the same list of $desc");
34 }
35
36 unless (join (' ', sort split ' ', $Config{extensions})
37         eq join(' ', FindExt::extensions())) {
38     # There are various things that break our assumptions.
39     # If Encode is a static extension, then Configure has special case logic
40     # to add Encode/* as static extensions
41     # -Uusedl causes Encode to be a static extension, and drops building
42     # XS::APItest and XS::Typemap
43     # Any use of -Dnoextensions to choose not to build a extension
44
45     plan(tests => 2);
46     note("configured extension list doesn't match, so only minimal testing is possible");
47     compare('known_extensions', $Config{known_extensions},
48             FindExt::known_extensions());
49 } else {
50     # dynamic linking, and all possible extensions for this system were built,
51     # so can test everything.
52     plan(tests => 12);
53
54     compare('known_extensions', $Config{known_extensions},
55             FindExt::known_extensions());
56
57     # Config.pm and FindExt.pm make different choices about what should be built
58     my @config_built;
59     my @found_built;
60
61     foreach my $type (qw(static dynamic nonxs)) {
62         my @this_found = eval "FindExt::${type}_ext()";
63         push @found_built, @this_found;
64         push @config_built, split ' ', $Config{"${type}_ext"};
65         compare("${type}_ext", $Config{"${type}_ext"}, @this_found);
66     }
67
68     compare('"config" dynamic + static + nonxs', $Config{extensions},
69             sort @config_built);
70     compare('"found" dynamic + static + nonxs', [FindExt::extensions()],
71             sort @found_built);
72 }
73
74 # Local variables:
75 # cperl-indent-level: 4
76 # indent-tabs-mode: nil
77 # End:
78 #
79 # ex: set ts=8 sts=4 sw=4 et: