This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
perl@27437 fix File::Path::mkpath so that perl installs on VMS
[perl5.git] / lib / File / Path.pm
1 package File::Path;
2
3 =head1 NAME
4
5 File::Path - create or remove directory trees
6
7 =head1 SYNOPSIS
8
9     use File::Path;
10
11     mkpath(['/foo/bar/baz', 'blurfl/quux'], 1, 0711);
12     rmtree(['foo/bar/baz', 'blurfl/quux'], 1, 1);
13
14 =head1 DESCRIPTION
15
16 The C<mkpath> function provides a convenient way to create directories, even
17 if your C<mkdir> kernel call won't create more than one level of directory at
18 a time.  C<mkpath> takes three arguments:
19
20 =over 4
21
22 =item *
23
24 the name of the path to create, or a reference
25 to a list of paths to create,
26
27 =item *
28
29 a boolean value, which if TRUE will cause C<mkpath>
30 to print the name of each directory as it is created
31 (defaults to FALSE), and
32
33 =item *
34
35 the numeric mode to use when creating the directories
36 (defaults to 0777), to be modified by the current umask.
37
38 =back
39
40 It returns a list of all directories (including intermediates, determined
41 using the Unix '/' separator) created.
42
43 If a system error prevents a directory from being created, then the
44 C<mkpath> function throws a fatal error with C<Carp::croak>. This error
45 can be trapped with an C<eval> block:
46
47   eval { mkpath($dir) };
48   if ($@) {
49     print "Couldn't create $dir: $@";
50   }
51
52 Similarly, the C<rmtree> function provides a convenient way to delete a
53 subtree from the directory structure, much like the Unix command C<rm -r>.
54 C<rmtree> takes three arguments:
55
56 =over 4
57
58 =item *
59
60 the root of the subtree to delete, or a reference to
61 a list of roots.  All of the files and directories
62 below each root, as well as the roots themselves,
63 will be deleted.
64
65 =item *
66
67 a boolean value, which if TRUE will cause C<rmtree> to
68 print a message each time it examines a file, giving the
69 name of the file, and indicating whether it's using C<rmdir>
70 or C<unlink> to remove it, or that it's skipping it.
71 (defaults to FALSE)
72
73 =item *
74
75 a boolean value, which if TRUE will cause C<rmtree> to
76 skip any files to which you do not have delete access
77 (if running under VMS) or write access (if running
78 under another OS).  This will change in the future when
79 a criterion for 'delete permission' under OSs other
80 than VMS is settled.  (defaults to FALSE)
81
82 =back
83
84 It returns the number of files successfully deleted.  Symlinks are
85 simply deleted and not followed.
86
87 B<NOTE:> There are race conditions internal to the implementation of
88 C<rmtree> making it unsafe to use on directory trees which may be
89 altered or moved while C<rmtree> is running, and in particular on any
90 directory trees with any path components or subdirectories potentially
91 writable by untrusted users.
92
93 Additionally, if the third parameter is not TRUE and C<rmtree> is
94 interrupted, it may leave files and directories with permissions altered
95 to allow deletion (and older versions of this module would even set
96 files and directories to world-read/writable!)
97
98 Note also that the occurrence of errors in C<rmtree> can be determined I<only>
99 by trapping diagnostic messages using C<$SIG{__WARN__}>; it is not apparent
100 from the return value.
101
102 =head1 DIAGNOSTICS
103
104 =over 4
105
106 =item *
107
108 On Windows, if C<mkpath> gives you the warning: B<No such file or
109 directory>, this may mean that you've exceeded your filesystem's
110 maximum path length.
111
112 =back
113
114 =head1 AUTHORS
115
116 Tim Bunce <F<Tim.Bunce@ig.co.uk>> and
117 Charles Bailey <F<bailey@newman.upenn.edu>>
118
119 =cut
120
121 use 5.006;
122 use File::Basename ();
123 use Exporter ();
124 use strict;
125 use warnings;
126
127 our $VERSION = "1.08";
128 our @ISA = qw( Exporter );
129 our @EXPORT = qw( mkpath rmtree );
130
131 my $Is_VMS = $^O eq 'VMS';
132 my $Is_MacOS = $^O eq 'MacOS';
133
134 # These OSes complain if you want to remove a file that you have no
135 # write permission to:
136 my $force_writeable = ($^O eq 'os2' || $^O eq 'dos' || $^O eq 'MSWin32' ||
137                        $^O eq 'amigaos' || $^O eq 'MacOS' || $^O eq 'epoc');
138
139 sub carp {
140     require Carp;
141     goto &Carp::carp;
142 }
143
144 sub croak {
145     require Carp;
146     goto &Carp::croak;
147 }
148
149 sub mkpath {
150     my($paths, $verbose, $mode) = @_;
151     # $paths   -- either a path string or ref to list of paths
152     # $verbose -- optional print "mkdir $path" for each directory created
153     # $mode    -- optional permissions, defaults to 0777
154     local($")=$Is_MacOS ? ":" : "/";
155     $mode = 0777 unless defined($mode);
156     $paths = [$paths] unless ref $paths;
157     my(@created,$path);
158     foreach $path (@$paths) {
159         $path .= '/' if $^O eq 'os2' and $path =~ /^\w:\z/s; # feature of CRT 
160         # Logic wants Unix paths, so go with the flow.
161         if ($Is_VMS) {
162             next if $path eq '/';
163             $path = VMS::Filespec::unixify($path);
164         }
165         next if -d $path;
166         my $parent = File::Basename::dirname($path);
167         unless (-d $parent or $path eq $parent) {
168             push(@created,mkpath($parent, $verbose, $mode));
169         }
170         print "mkdir $path\n" if $verbose;
171         unless (mkdir($path,$mode)) {
172             my $e = $!;
173             # allow for another process to have created it meanwhile
174             $! = $e, croak ("mkdir $path: $e") unless -d $path;
175         }
176         push(@created, $path);
177     }
178     @created;
179 }
180
181 sub rmtree {
182     my($roots, $verbose, $safe) = @_;
183     my(@files);
184     my($count) = 0;
185     $verbose ||= 0;
186     $safe ||= 0;
187
188     if ( defined($roots) && length($roots) ) {
189       $roots = [$roots] unless ref $roots;
190     }
191     else {
192       carp ("No root path(s) specified\n");
193       return 0;
194     }
195
196     my($root);
197     foreach $root (@{$roots}) {
198         if ($Is_MacOS) {
199             $root = ":$root" if $root !~ /:/;
200             $root =~ s#([^:])\z#$1:#;
201         } else {
202             $root =~ s#/\z##;
203         }
204         (undef, undef, my $rp) = lstat $root or next;
205         $rp &= 07777;   # don't forget setuid, setgid, sticky bits
206         if ( -d _ ) {
207             # notabene: 0700 is for making readable in the first place,
208             # it's also intended to change it to writable in case we have
209             # to recurse in which case we are better than rm -rf for 
210             # subtrees with strange permissions
211             chmod($rp | 0700, ($Is_VMS ? VMS::Filespec::fileify($root) : $root))
212               or carp ("Can't make directory $root read+writeable: $!")
213                 unless $safe;
214
215             if (opendir my $d, $root) {
216                 no strict 'refs';
217                 if (!defined ${"\cTAINT"} or ${"\cTAINT"}) {
218                     # Blindly untaint dir names
219                     @files = map { /^(.*)$/s ; $1 } readdir $d;
220                 } else {
221                     @files = readdir $d;
222                 }
223                 closedir $d;
224             }
225             else {
226                 carp ("Can't read $root: $!");
227                 @files = ();
228             }
229
230             # Deleting large numbers of files from VMS Files-11 filesystems
231             # is faster if done in reverse ASCIIbetical order 
232             @files = reverse @files if $Is_VMS;
233             ($root = VMS::Filespec::unixify($root)) =~ s#\.dir\z## if $Is_VMS;
234             if ($Is_MacOS) {
235                 @files = map("$root$_", @files);
236             } else {
237                 @files = map("$root/$_", grep $_!~/^\.{1,2}\z/s,@files);
238             }
239             $count += rmtree(\@files,$verbose,$safe);
240             if ($safe &&
241                 ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
242                 print "skipped $root\n" if $verbose;
243                 next;
244             }
245             chmod $rp | 0700, $root
246               or carp ("Can't make directory $root writeable: $!")
247                 if $force_writeable;
248             print "rmdir $root\n" if $verbose;
249             if (rmdir $root) {
250                 ++$count;
251             }
252             else {
253                 carp ("Can't remove directory $root: $!");
254                 chmod($rp, ($Is_VMS ? VMS::Filespec::fileify($root) : $root))
255                     or carp("and can't restore permissions to "
256                             . sprintf("0%o",$rp) . "\n");
257             }
258         }
259         else { 
260             if ($safe &&
261                 ($Is_VMS ? !&VMS::Filespec::candelete($root)
262                          : !(-l $root || -w $root)))
263             {
264                 print "skipped $root\n" if $verbose;
265                 next;
266             }
267             chmod $rp | 0600, $root
268               or carp ("Can't make file $root writeable: $!")
269                 if $force_writeable;
270             print "unlink $root\n" if $verbose;
271             # delete all versions under VMS
272             for (;;) {
273                 unless (unlink $root) {
274                     carp ("Can't unlink file $root: $!");
275                     if ($force_writeable) {
276                         chmod $rp, $root
277                             or carp("and can't restore permissions to "
278                                     . sprintf("0%o",$rp) . "\n");
279                     }
280                     last;
281                 }
282                 ++$count;
283                 last unless $Is_VMS && lstat $root;
284             }
285         }
286     }
287
288     $count;
289 }
290
291 1;