installperl

   1 #!./perl -w
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '../lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8
   9     # This needs to be at BEGIN time, before any use of Config
  10     require './install_lib.pl';
  11 }
  12
  13 use strict;
  14 use vars qw($Is_VMS $Is_W32 $Is_OS2 $Is_Cygwin $Is_Darwin $Is_NetWare
  15             %opts $packlist);
  16 my ($dostrip, $versiononly, $force,
  17     $otherperls, $archname, $nwinstall, $nopods);
  18 # Not sure how easy it would be to refactor to remove the need for local $depth
  19 # below
  20 use vars qw /$depth/;
  21
  22 BEGIN {
  23     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  24 }
  25
  26 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  27
  28 use File::Find;
  29 use File::Compare;
  30 use File::Copy ();
  31 use File::Path ();
  32 use ExtUtils::Packlist;
  33 use Cwd;
  34
  35 if ($Is_NetWare) {
  36     $Is_W32 = 0;
  37     $scr_ext = '.pl';
  38 }
  39
  40 # override the ones in the rest of the script
  41 sub mkpath {
  42     File::Path::mkpath(@_) unless $opts{notify};
  43 }
  44
  45 my $mainperldir = "/usr/bin";
  46 my $exe_ext = $Config{exe_ext};
  47
  48 # Allow "make install PERLNAME=something_besides_perl":
  49 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  50
  51 # This is the base used for versioned names, like "perl5.6.0".
  52 # It's separate because a common use of $PERLNAME is to install
  53 # perl as "perl5", if that's used as base for versioned files you
  54 # get "perl55.6.0".
  55 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
  56                     ? $ENV{PERLNAME_VERBASE}
  57                     : $perl;
  58 my $dbg = '';
  59 my $ndbg = '';
  60 if ( $Is_VMS ) {
  61     if ( defined $Config{usevmsdebug} ) {
  62         if ( $Config{usevmsdebug} eq 'define' ) {
  63             $dbg = 'dbg';
  64             $ndbg = 'ndbg';
  65         }
  66     }
  67 }
  68
  69 $otherperls = 1;
  70 # This little hack simplifies making the code after the comment "Fetch some
  71 # frequently-used items from %Config" warning free. With $opts{destdir} always
  72 # defined, it's also possible to make the s/\Q$opts{destdir}\E unconditional.
  73
  74 $opts{destdir} = '';
  75 # Consider refactoring this to use Getopt::Long once Getopt::Long's planned
  76 # feature is implemented, to distinguish + and - options.
  77 while (@ARGV) {
  78     $opts{notify} = 1 if $ARGV[0] eq '-n';
  79     $dostrip = 1 if $ARGV[0] eq '-s';
  80     $versiononly = 1 if $ARGV[0] eq '-v';
  81     $versiononly = 0 if $ARGV[0] eq '+v';
  82     $opts{silent} = 1 if $ARGV[0] eq '-S';
  83     $otherperls = 0 if $ARGV[0] eq '-o';
  84     $force = 1 if $ARGV[0] eq '-f';
  85     $opts{verbose} = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
  86     $archname = 1 if $ARGV[0] eq '-A';
  87     $nwinstall = 1 if $ARGV[0] eq '-netware';
  88     $nopods = 1 if $ARGV[0] eq '-p';
  89     $opts{destdir} = $1 if $ARGV[0] =~ /^-?-destdir=(.*)$/;
  90     if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) {
  91         print <<"EOT";
  92 Usage $0: [switches]
  93   -n        Don't actually run any commands; just print them.
  94   -s        Run strip on installed binaries.
  95   -v        Only install perl as a binary with the version number in the name.
  96             (Override whatever config.sh says)
  97   +v        Install perl as "perl" and as a binary with the version number in
  98             the name.  (Override whatever config.sh says)
  99   -S        Silent mode.
 100   -f        Force installation (don't check if same version is there)
 101   -o        Skip checking for other copies of perl in your PATH.
 102   -V        Verbose mode.
 103   -A        Also install perl with the architecture's name in the perl binary's
 104             name.
 105   -p        Don't install the pod files. [This will break use diagnostics;]
 106   -netware  Install correctly on a Netware server.
 107   -destdir  Prefix installation directories by this string.
 108 EOT
 109         exit;
 110     }
 111     shift;
 112 }
 113
 114 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
 115 my (@scripts, @tolink);
 116 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
 117 while (<SCRIPTS>) {
 118     next if /^#/;
 119     next if /a2p/; # a2p is binary, to be installed separately
 120     chomp;
 121     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
 122         push @scripts, $1;
 123         push @tolink, [$1, $2];
 124     } else {
 125         push @scripts, $_;
 126     }
 127 }
 128 close SCRIPTS;
 129
 130 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
 131
 132 my @pods = $nopods ? () : (<pod/*.pod>, 'x2p/a2p.pod');
 133
 134 # Specify here any .pm files that are actually architecture-dependent.
 135 # (Those included with XS extensions under ext/ are automatically
 136 # added later.)
 137 # Now that the default privlib has the full perl version number included,
 138 # we no longer have to play the trick of sticking version-specific .pm
 139 # files under the archlib directory.
 140 my %archpms = (
 141     Config => 1,
 142     lib => 1,
 143     Cwd => 1,
 144 );
 145
 146 if ($^O eq 'dos') {
 147     push(@scripts,'djgpp/fixpmain');
 148     $archpms{config} = $archpms{filehand} = 1;
 149 }
 150
 151 if ((-e "testcompile") && (defined($ENV{'COMPILE'}))) {
 152     push(@scripts, map("$_.exe", @scripts));
 153 }
 154
 155 # Exclude nonxs extensions that are not architecture dependent
 156 my @nonxs = grep(!/^Errno$/, split(' ', $Config{'nonxs_ext'}));
 157
 158 my @ext_dirs = qw(cpan dist ext);
 159 foreach my $ext_dir (@ext_dirs) {
 160     find(sub {
 161         if (($File::Find::name =~ m{^$ext_dir\b(.*)/([^/]+)\.pm$}) &&
 162             ! grep { (my $dir = $_) =~ s/\//-/g;
 163                      $File::Find::name =~ /^$ext_dir\/$dir\// } @nonxs)
 164         {
 165             my($path, $modname) = ($1,$2);
 166
 167             # Change hyphenated name like Filter-Util-Call to nested
 168             # directory name Filter/Util/Call
 169             $path =~ s{-}{/}g;
 170
 171             # strip to optional "/lib", or remove trailing component
 172             $path =~ s{.*/lib\b}{} or $path =~ s{/[^/]*$}{};
 173
 174             # strip any leading /
 175             $path =~ s{^/}{};
 176
 177             # reconstitute canonical module name
 178             $modname = "$path/$modname" if length $path;
 179
 180             # remember it
 181             $archpms{$modname} = 1;
 182         }
 183     }, $ext_dir);
 184 }
 185
 186 # print "[$_]\n" for sort keys %archpms;
 187
 188 my $ver = $Config{version};
 189 my $release = substr($],0,3);   # Not used currently.
 190 my $patchlevel = substr($],3,2);
 191 die "Patchlevel of perl ($patchlevel)",
 192     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
 193         if $patchlevel != $Config{'PERL_VERSION'};
 194
 195 # Fetch some frequently-used items from %Config
 196 my $installbin = "$opts{destdir}$Config{installbin}";
 197 my $installscript = "$opts{destdir}$Config{installscript}";
 198 my $installprivlib = "$opts{destdir}$Config{installprivlib}";
 199 my $installarchlib = "$opts{destdir}$Config{installarchlib}";
 200 my $installsitelib = "$opts{destdir}$Config{installsitelib}";
 201 my $installsitearch = "$opts{destdir}$Config{installsitearch}";
 202 my $installman1dir = "$opts{destdir}$Config{installman1dir}";
 203 my $man1ext = $Config{man1ext};
 204 my $libperl = $Config{libperl};
 205 # Shared library and dynamic loading suffixes.
 206 my $so = $Config{so};
 207 my $dlext = $Config{dlext};
 208 my $dlsrc = $Config{dlsrc};
 209 if ($^O eq 'os390') {
 210     my $pwd;
 211     chomp($pwd=`pwd`);
 212     my $archlibexp = $Config{archlibexp};
 213     my $usedl = $Config{usedl};
 214     if ($usedl eq 'define') {
 215         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
 216     }
 217 }
 218
 219 if ($nwinstall) {
 220     # This is required only if we are installing on a NetWare server
 221     $installscript = $Config{installnwscripts};
 222     $installprivlib = $Config{installnwlib};
 223     $installarchlib = $Config{installnwlib};
 224     $installsitelib = $Config{installnwlib};
 225 }
 226
 227 my $binexp = $Config{binexp};
 228
 229 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 230     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 231               \$installarchlib, \$installsitelib, \$installsitearch,
 232               \$installman1dir ) {
 233         $$_ = unixify($$_);  $$_ =~ s:/$::;
 234     }
 235 }
 236
 237 # Do some quick sanity checks.
 238
 239    $installbin          || die "No installbin directory in config.sh\n";
 240 -d $installbin          || mkpath($installbin, $opts{verbose}, 0777);
 241 -d $installbin          || $opts{notify} || die "$installbin is not a directory\n";
 242 -w $installbin          || $opts{notify} || die "$installbin is not writable by you\n"
 243         unless $installbin =~ m#^/afs/# || $opts{notify};
 244
 245 if (!$Is_NetWare) {
 246 if (!$Is_VMS) {
 247 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 248 }
 249 else {
 250 -x $ndbg . 'perl' . $exe_ext    || die "${ndbg}perl$exe_ext isn't executable!\n";
 251     if ($dbg) {
 252         -x $dbg . 'perl' . $exe_ext     || die "${dbg}perl$exe_ext isn't executable!\n";
 253     }
 254 }
 255
 256 -f 't/rantests'         || $Is_W32
 257                         || warn "WARNING: You've never run 'make test' or",
 258                                 " some tests failed! (Installing anyway.)\n";
 259 } #if (!$Is_NetWare)
 260
 261 # This will be used to store the packlist
 262 $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 263
 264 if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin) {
 265     my $perldll;
 266
 267     if ($Is_Cygwin) {
 268         $perldll = $libperl;
 269     } else {
 270         $perldll = 'perl5'.$Config{patchlevel}.'.'.$dlext;
 271     }
 272
 273     if ($dlsrc ne "dl_none.xs") {
 274         -f $perldll || die "No perl DLL built\n";
 275     }
 276
 277     # Install the DLL
 278     safe_unlink("$installbin/$perldll");
 279     copy("$perldll", "$installbin/$perldll");
 280     chmod(0755, "$installbin/$perldll");
 281     $packlist->{"$installbin/$perldll"} = { type => 'file' };
 282 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
 283
 284 # First we install the version-numbered executables.
 285
 286 if ($Is_VMS) {
 287     safe_unlink("$installbin/perl_setup.com");
 288     copy("perl_setup.com", "$installbin/perl_setup.com");
 289     chmod(0755, "$installbin/perl_setup.com");
 290     safe_unlink("$installbin/$dbg$perl$exe_ext");
 291     copy("$dbg$perl$exe_ext", "$installbin/$dbg$perl$exe_ext");
 292     chmod(0755, "$installbin/$dbg$perl$exe_ext");
 293     safe_unlink("$installbin/$dbg${perl}shr$exe_ext");
 294     copy("$dbg${perl}shr$exe_ext", "$installbin/$dbg${perl}shr$exe_ext");
 295     chmod(0755, "$installbin/$dbg${perl}shr$exe_ext");
 296     if ($ndbg) {
 297         safe_unlink("$installbin/$ndbg$perl$exe_ext");
 298         copy("$ndbg$perl$exe_ext", "$installbin/$ndbg$perl$exe_ext");
 299         chmod(0755, "$installbin/$ndbg$perl$exe_ext");
 300         safe_unlink("$installbin/${dbg}a2p$exe_ext");
 301         copy("x2p/${dbg}a2p$exe_ext", "$installbin/${dbg}a2p$exe_ext");
 302         chmod(0755, "$installbin/${dbg}a2p$exe_ext");
 303     }
 304 }
 305 elsif ($^O eq 'mpeix') {
 306     # MPE lacks hard links and requires that executables with special
 307     # capabilities reside in the MPE namespace.
 308     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
 309     # Install the primary executable into the MPE namespace as perlpath.
 310     copy("perl$exe_ext", $Config{perlpath});
 311     chmod(0755, $Config{perlpath});
 312     # Create a backup copy with the version number.
 313     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
 314 }
 315 elsif ($^O ne 'dos') {
 316     if (!$Is_NetWare) {
 317         safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
 318         copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
 319         strip("$installbin/$perl_verbase$ver$exe_ext");
 320         chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
 321     }
 322     else {
 323         # If installing onto a NetWare server
 324         if ($nwinstall) {
 325             # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
 326             mkpath($Config{installnwsystem}, 1, 0777);
 327             copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
 328             copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
 329             copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
 330             copy("x2p\\a2p.nlm", $Config{installnwsystem});
 331             chmod(0755, "$Config{installnwsystem}\\perl.nlm");
 332             mkpath($Config{installnwlcgi}, 1, 0777);
 333             copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
 334         }
 335     } #if (!$Is_NetWare)
 336 }
 337 else {
 338     safe_unlink("$installbin/$perl.exe");
 339     copy("perl.exe", "$installbin/$perl.exe");
 340 }
 341
 342 # Install library files.
 343
 344 my ($do_installarchlib, $do_installprivlib) = (0, 0);
 345 my $vershort = ($Is_Cygwin and !$Config{usedevel}) ? substr($ver,0,-2) : $ver;
 346
 347 mkpath($installprivlib, $opts{verbose}, 0777);
 348 mkpath($installarchlib, $opts{verbose}, 0777);
 349 mkpath($installsitelib, $opts{verbose}, 0777) if ($installsitelib);
 350 mkpath($installsitearch, $opts{verbose}, 0777) if ($installsitearch);
 351
 352 if (chdir "lib") {
 353     $do_installarchlib = ! samepath($installarchlib, '.');
 354     $do_installprivlib = ! samepath($installprivlib, '.');
 355     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$vershort/);
 356
 357     if ($do_installarchlib || $do_installprivlib) {
 358         find(\&installlib, '.');
 359     }
 360     chdir ".." || die "Can't cd back to source directory: $!\n";
 361 }
 362 else {
 363     warn "Can't cd to lib to install lib files: $!\n";
 364 }
 365
 366 # Install header files and libraries.
 367 mkpath("$installarchlib/CORE", $opts{verbose}, 0777);
 368 my @corefiles;
 369 if ($Is_VMS) {  # We did core file selection during build
 370     my $coredir = "lib/$Config{archname}/$ver/CORE";
 371     $coredir =~ tr/./_/;
 372     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
 373 }
 374 elsif ($Is_Cygwin) { # On Cygwin symlink it to CORE to make Makefile happy
 375     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
 376     my $coredll = "$installarchlib/CORE/$libperl";
 377     safe_unlink($coredll);
 378     ( $Config{'d_link'} eq 'define' &&
 379       eval {
 380           CORE::link("$installbin/$libperl", $coredll);
 381           $packlist->{$coredll} = { from => "$installbin/$libperl",
 382                                     type => 'link' };
 383       }
 384     ) ||
 385     eval {
 386         symlink("$installbin/$libperl", $coredll);
 387         $packlist->{$coredll} = { from => "$installbin/$libperl",
 388                                   type => 'link' };
 389     } ||
 390     ( copy("$installbin/$libperl", $coredll) &&
 391       push(@corefiles, $coredll)
 392     )
 393 } else {
 394     # [als] hard-coded 'libperl' name... not good!
 395     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
 396
 397     # AIX needs perl.exp installed as well.
 398     push(@corefiles,'perl.exp') if $^O eq 'aix';
 399     if ($^O eq 'mpeix') {
 400         # MPE needs mpeixish.h installed as well.
 401         mkpath("$installarchlib/CORE/mpeix", $opts{verbose}, 0777);
 402         push(@corefiles,'mpeix/mpeixish.h');
 403     }
 404     # If they have built sperl.o...
 405     push(@corefiles,'sperl.o') if -f 'sperl.o';
 406 }
 407 foreach my $file (@corefiles) {
 408     # HP-UX (at least) needs to maintain execute permissions
 409     # on dynamically-loadable libraries. So we do it for all.
 410     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
 411         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
 412             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
 413             chmod(0555, "$installarchlib/CORE/$file");
 414         } else {
 415             chmod(0444, "$installarchlib/CORE/$file");
 416         }
 417     }
 418 }
 419
 420 # Install main perl executables
 421 # Make links to ordinary names if installbin directory isn't current directory.
 422
 423 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
 424     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 425     if ($^O eq 'mpeix') {
 426         # MPE doesn't support hard links, so use a symlink.
 427         # We don't want another cloned copy.
 428         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
 429     } elsif ($^O eq 'vos') {
 430         # VOS doesn't support hard links, so use a symlink.
 431         symlink("$installbin/$perl_verbase$ver$exe_ext",
 432                 "$installbin/$perl$exe_ext");
 433     } else {
 434         link("$installbin/$perl_verbase$ver$exe_ext",
 435                 "$installbin/$perl$exe_ext");
 436     }
 437 }
 438
 439 # For development purposes it can be very useful to have multiple perls
 440 # build for different "architectures" (eg threading or not) simultaneously.
 441 if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 442     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
 443     safe_unlink("$installbin/$archperl");
 444     if ($^O eq 'mpeix') {
 445         # MPE doesn't support hard links, so use a symlink.
 446         # We don't want another cloned copy.
 447         symlink($Config{perlpath}, "$installbin/$archperl");
 448     } elsif ($^O eq 'vos') {
 449         # VOS doesn't support hard links, so use a symlink.
 450         symlink("$installbin/$perl_verbase$ver$exe_ext",
 451                 "$installbin/$archperl");
 452     } else {
 453         link("$installbin/$perl_verbase$ver$exe_ext", "$installbin/$archperl");
 454     }
 455 }
 456
 457 # Offer to install perl in a "standard" location
 458
 459 my $mainperl_is_instperl = 0;
 460
 461 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
 462     !$versiononly && !$opts{notify} && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
 463         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 464     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 465     my($instperl)       = "$installbin/$perl$exe_ext";
 466     my($expinstperl)    = "$binexp/$perl$exe_ext";
 467
 468     # First make sure $usrbinperl is not already the same as the perl we
 469     # just installed.
 470     if (-x $usrbinperl) {
 471         # Try to be clever about mainperl being a symbolic link
 472         # to binexp/perl if binexp and installbin are different.
 473         $mainperl_is_instperl =
 474             samepath($usrbinperl, $instperl) ||
 475             samepath($usrbinperl, $expinstperl) ||
 476              (($binexp ne $installbin) &&
 477               (-l $usrbinperl) &&
 478               ((readlink $usrbinperl) eq $expinstperl));
 479     }
 480     if (! $mainperl_is_instperl) {
 481         unlink($usrbinperl);
 482         ( $Config{'d_link'} eq 'define' &&
 483           eval { CORE::link $instperl, $usrbinperl } )  ||
 484         eval { symlink $expinstperl, $usrbinperl }      ||
 485         copy($instperl, $usrbinperl);
 486
 487         $mainperl_is_instperl = 1;
 488     }
 489 }
 490
 491 # Make links to ordinary names if installbin directory isn't current directory.
 492 if (!$Is_NetWare && $dbg eq '') {
 493     if (! samepath($installbin, 'x2p')) {
 494         my $base = 'a2p';
 495         $base .= $ver if $versiononly;
 496         safe_unlink("$installbin/$base$exe_ext");
 497         copy("x2p/a2p$exe_ext", "$installbin/$base$exe_ext");
 498         strip("$installbin/$base$exe_ext");
 499         chmod(0755, "$installbin/$base$exe_ext");
 500     }
 501 }
 502
 503 # cppstdin is just a script, but it is architecture-dependent, so
 504 # it can't safely be shared.  Place it in $installbin.
 505 # Note that Configure doesn't build cppstin if it isn't needed, so
 506 # we skip this if cppstdin doesn't exist.
 507 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 508     safe_unlink("$installbin/cppstdin");
 509     copy("cppstdin", "$installbin/cppstdin");
 510     chmod(0755, "$installbin/cppstdin");
 511 }
 512
 513 sub script_alias {
 514     my ($installscript, $orig, $alias, $scr_ext) = @_;
 515
 516     safe_unlink("$installscript/$alias$scr_ext");
 517     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
 518         copy("$installscript/$orig$scr_ext",
 519              "$installscript/$alias$scr_ext");
 520     } elsif ($^O eq 'vos') {
 521         symlink("$installscript/$orig$scr_ext",
 522                 "$installscript/$alias$scr_ext");
 523     } else {
 524         link("$installscript/$orig$scr_ext",
 525              "$installscript/$alias$scr_ext");
 526     }
 527 }
 528
 529 # Install scripts.
 530 mkpath($installscript, $opts{verbose}, 0777);
 531 if ($versiononly) {
 532     for (@scripts) {
 533         (my $base = $_) =~ s#.*/##;
 534         $base .= $ver;
 535         copy($_,    "$installscript/$base");
 536         chmod(0755, "$installscript/$base");
 537     }
 538
 539     for (@tolink) {
 540         my ($from, $to) = map { "$_$ver" } @$_;
 541         (my $frbase = $from) =~ s#.*/##;
 542         (my $tobase = $to) =~ s#.*/##;
 543         script_alias($installscript, $frbase, $tobase, $scr_ext);
 544     }
 545 } else {
 546     for (@scripts) {
 547         (my $base = $_) =~ s#.*/##;
 548         copy($_, "$installscript/$base");
 549         chmod(0755, "$installscript/$base");
 550     }
 551
 552     for (@tolink) {
 553         my ($from, $to) = @$_;
 554         (my $frbase = $from) =~ s#.*/##;
 555         (my $tobase = $to) =~ s#.*/##;
 556         script_alias($installscript, $frbase, $tobase, $scr_ext);
 557     }
 558 }
 559
 560 # Install pod pages.  Where? I guess in $installprivlib/pod
 561 # ($installprivlib/pods for cygwin).
 562
 563 my $pod = ($Is_Cygwin || $Is_Darwin || $Is_VMS || $Is_W32) ? 'pods' : 'pod';
 564 if ( !$versiononly || ($installprivlib =~ m/\Q$vershort/)) {
 565     mkpath("${installprivlib}/$pod", $opts{verbose}, 0777);
 566
 567     for (@pods) {
 568         # $_ is a name like  pod/perl.pod
 569         (my $base = $_) =~ s#.*/##;
 570         copy_if_diff($_, "${installprivlib}/$pod/${base}");
 571     }
 572
 573 }
 574
 575 # Check to make sure there aren't other perls around in installer's
 576 # path.  This is probably UNIX-specific.  Check all absolute directories
 577 # in the path except for where public executables are supposed to live.
 578 # Also skip $mainperl if the user opted to have it be a link to the
 579 # installed perl.
 580
 581 if (!$versiononly && $otherperls) {
 582     my ($path, @path);
 583     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
 584     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 585     @path = split(/$dirsep/, $path);
 586     if ($Is_VMS) {
 587         my $i = 0;
 588         while (exists $ENV{'DCL$PATH' . $i}) {
 589             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 590             push(@path,$dir);
 591         }
 592     }
 593     my @otherperls;
 594     my %otherperls;
 595     for (@path) {
 596         next unless m,^/,;
 597         # Use &samepath here because some systems have other dirs linked
 598         # to $mainperldir (like SunOS)
 599         next unless -d;
 600         next if samepath($_, $binexp);
 601         next if samepath($_, cwd());
 602         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 603         my $otherperl = "$_/$perl$exe_ext";
 604         next if $otherperls{$otherperl}++;
 605         push(@otherperls, $otherperl)
 606             if (-x $otherperl && ! -d $otherperl);
 607     }
 608     if (@otherperls) {
 609         warn "\nWarning: $perl appears in your path in the following " .
 610             "locations beyond where\nwe just installed it:\n";
 611         for (@otherperls) {
 612             warn "    ", $_, "\n";
 613         }
 614         warn "\n";
 615     }
 616
 617 }
 618
 619 $packlist->write() unless $opts{notify};
 620 print "  Installation complete\n" if $opts{verbose};
 621
 622 exit 0;
 623
 624 ###############################################################################
 625
 626 # If these are needed elsewhere, move them into install_lib.pl rather than
 627 # copying them.
 628
 629 sub yn {
 630     my($prompt) = @_;
 631     my($answer);
 632     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 633     print STDERR $prompt;
 634     chop($answer = <STDIN>);
 635     $answer = $default if $answer =~ m/^\s*$/;
 636     ($answer =~ m/^[yY]/);
 637 }
 638
 639 sub safe_unlink {
 640     return if $opts{notify} or $Is_VMS;
 641     my @names = @_;
 642     foreach my $name (@names) {
 643         next unless -e $name;
 644         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
 645         print "  unlink $name\n" if $opts{verbose};
 646         next if CORE::unlink($name);
 647         warn "Couldn't unlink $name: $!\n";
 648         if ($! =~ /busy/i) {
 649             print "  mv $name $name.old\n" if $opts{verbose};
 650             safe_rename($name, "$name.old")
 651                 or warn "Couldn't rename $name: $!\n";
 652         }
 653     }
 654 }
 655
 656 sub safe_rename {
 657     my($from,$to) = @_;
 658     if (-f $to and not unlink($to)) {
 659         my($i);
 660         for ($i = 1; $i < 50; $i++) {
 661             last if rename($to, "$to.$i");
 662         }
 663         warn("Cannot rename to '$to.$i': $!"), return 0
 664            if $i >= 50; # Give up!
 665     }
 666     link($from,$to) || return 0;
 667     unlink($from);
 668 }
 669
 670 sub copy {
 671     my($from,$to) = @_;
 672
 673     my $xto = $to;
 674     $xto =~ s/^\Q$opts{destdir}\E//;
 675     print $opts{verbose} ? "  cp $from $xto\n" : "  $xto\n"
 676         unless $opts{silent};
 677     print "  creating new version of $xto\n"
 678         if $Is_VMS and -e $to and !$opts{silent};
 679     unless ($opts{notify} or File::Copy::copy($from, $to)) {
 680         # Might have been that F::C::c can't overwrite the target
 681         warn "Couldn't copy $from to $to: $!\n"
 682             unless -f $to and (chmod(0666, $to), unlink $to)
 683                    and File::Copy::copy($from, $to);
 684     }
 685     $packlist->{$xto} = { type => 'file' };
 686 }
 687
 688 sub installlib {
 689     my $dir = $File::Find::dir;
 690     $dir =~ s#^\.(?![^/])/?##;
 691     local($depth) = $dir ? "lib/$dir" : "lib";
 692
 693     my $name = $_;
 694
 695     # Ignore version control directories.
 696     if ($name =~ /^(?:CVS|RCS|SCCS|\.svn)\z/ and -d $name) {
 697         $File::Find::prune = 1;
 698         return;
 699     }
 700
 701     # ignore patch backups, RCS files, emacs backup & temp files and the
 702     # .exists files, .PL files, and test files.
 703     return if $name =~ m{\.orig$|\.rej$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.plc$|\.t$|^test\.pl$|^dbm_filter_util\.pl$|^filter-util\.pl$|^uupacktool\.pl$|^\.gitignore$} ||
 704               $dir  =~ m{/t(?:/|$)};
 705     # ignore the cpan script in lib/CPAN/bin, the instmodsh and xsubpp
 706     # scripts in lib/ExtUtils, the prove script in lib/Test/Harness,
 707     # the corelist script from lib/Module/CoreList/bin and ptar* in
 708     # lib/Archive/Tar/bin, the config_data script in lib/Module/Build/scripts
 709     # and zipdetails in cpan/IO-Compress/bin
 710     # (they're installed later with other utils)
 711     return if $name =~ /^(?:cpan|instmodsh|prove|corelist|ptar|cpan2dist|cpanp|cpanp-run-perl|ptardiff|ptargrep|config_data|zipdetails)\z/;
 712     # ignore the Makefiles
 713     return if $name =~ /^makefile$/i;
 714     # ignore the test extensions
 715     return if $dir =~ m{\bXS/(?:APItest|Typemap)\b};
 716     return if $name =~ m{\b(?:APItest|Typemap)\.pm$};
 717     # ignore the build support code
 718     return if $name =~ /\bbuildcustomize\.pl$/;
 719     # ignore the demo files
 720     return if $dir =~ /\b(?:demos?|eg)\b/;
 721     # ignore unneeded unicore files
 722     if ( $dir =~ /^unicore/ ) {
 723       if ( $name =~ /\.txt\z/ ) {
 724         # We can ignore most, but not all .txt files
 725         return unless $name =~ /\A(?:Blocks|CaseFolding|SpecialCasing|NamedSequences)\.txt\z/;
 726       }
 727       else {
 728         # TestProp only needed during testing
 729         return if $name =~ /\ATestProp.pl\z/;
 730         # we need version and *.pl files and can skip the rest
 731         return unless $name =~ /\A(?:version|\w+\.p[lm])\z/;
 732       }
 733     }
 734
 735     # ignore READMEs, MANIFESTs, INSTALL docs, META.ymls and change logs.
 736     # Changes.e2x and README.e2x are needed by enc2xs.
 737     return if $name =~ m{^(?:README(?:\.\w+)?)$} && $name ne 'README.e2x';
 738     return if $name =~ m{^(?:MANIFEST|META\.yml)$};
 739     return if $name =~ m{^(?:INSTALL|TODO|BUGS|CREDITS)$}i;
 740     return if $name =~ m{^change(?:s|log)(?:\.libnet)?$}i;
 741     return if $name =~ m{^(?:SIGNATURE|PAUSE200\d\.pub)$}; # CPAN files
 742     return if $name =~ m{^(?:NOTES|PATCHING)$}; # ExtUtils files
 743
 744     # if using a shared perl library then ignore:
 745     # - static library files [of statically linked extensions];
 746     # - import library files and export library files (only present on Win32
 747     #   anyway?) and empty bootstrap files [of dynamically linked extensions].
 748     return if $Config{useshrplib} eq 'true' and
 749              ($name =~ /$Config{_a}$/ or $name =~ /\.exp$/ or ($name =~ /\.bs$/ and -z $name));
 750
 751     $name = "$dir/$name" if $dir ne '';
 752
 753     return if $name eq 'ExtUtils/XSSymSet.pm' and !$Is_VMS;
 754
 755     my $installlib = $installprivlib;
 756     if ($dir =~ /^auto\// ||
 757           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 758           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare)) ||
 759           $name=~/^Config_(heavy|git)\.pl\z/
 760        ) {
 761         $installlib = $installarchlib;
 762         return unless $do_installarchlib;
 763     } else {
 764         return unless $do_installprivlib;
 765     }
 766
 767     if (-f $_) {
 768         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$])) {
 769             $installlib = $installprivlib;
 770             #We're installing *.al and *.ix files into $installprivlib,
 771             #but we have to delete old *.al and *.ix files from the 5.000
 772             #distribution:
 773             #This might not work because $archname might have changed.
 774             unlink("$installarchlib/$name");
 775         }
 776         my $xname = "$installlib/$name";
 777         $xname =~ s/^\Q$opts{destdir}\E//;
 778         $packlist->{$xname} = { type => 'file' };
 779         if ($force || compare($_, "$installlib/$name") || $opts{notify}) {
 780             unlink("$installlib/$name");
 781             mkpath("$installlib/$dir", $opts{verbose}, 0777);
 782             # HP-UX (at least) needs to maintain execute permissions
 783             # on dynamically-loaded libraries.
 784             if ($Is_NetWare && !$nwinstall) {
 785                 # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
 786                 # if copied will give problems when building new extensions.
 787                 # Has to be copied if we are installing on a NetWare server and hence
 788                 # the check !$nwinstall
 789                 if (!(/\.(?:nlp|nlm|bs)$/)) {
 790                     copy_if_diff($_, "$installlib/$name")
 791                         and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
 792                                   "$installlib/$name");
 793                 }
 794            } else {
 795                 if (copy_if_diff($_, "$installlib/$name")) {
 796                     if ($name =~ /\.(so|$dlext)$/o) {
 797                         strip("-S", "$installlib/$name") if $^O =~ /^(rhapsody|darwin)$/;
 798                         chmod(0555, "$installlib/$name");
 799                     } else {
 800                         strip("-S", "$installlib/$name")
 801                             if ($name =~ /\.a$/o and $^O =~ /^(rhapsody|darwin)$/);
 802                         chmod(0444, "$installlib/$name");
 803                     }
 804                 }
 805             } #if ($Is_NetWare)
 806         }
 807     }
 808 }
 809
 810 # Copy $from to $to, only if $from is different than $to.
 811 # Also preserve modification times for .a libraries.
 812 # On some systems, if you do
 813 #   ranlib libperl.a
 814 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 815 # and then try to link against the installed libperl.a, you might
 816 # get an error message to the effect that the symbol table is older
 817 # than the library.
 818 # Return true if copying occurred.
 819
 820 sub copy_if_diff {
 821     my($from,$to)=@_;
 822     return 1 if (($^O eq 'VMS') && (-d $from));
 823     my $xto = $to;
 824     $xto =~ s/^\Q$opts{destdir}\E//;
 825     my $perlpodbadsymlink;
 826     if ($from =~ m!^pod/perl[\w-]+\.pod$! &&
 827         -l $from &&
 828         ! -e $from) {
 829         # Some Linux implementations have problems traversing over
 830         # multiple symlinks (when going over NFS?) and fail to read
 831         # the symlink target.  Combine this with the fact that some
 832         # of the pod files (the perl$OS.pod) are symlinks (to ../README.$OS),
 833         # and you end up with those pods not getting installed.
 834         $perlpodbadsymlink = 1;
 835     }
 836     -f $from || $perlpodbadsymlink || warn "$0: $from not found";
 837     $packlist->{$xto} = { type => 'file' };
 838     if ($force || compare($from, $to) || $opts{notify}) {
 839         safe_unlink($to);   # In case we don't have write permissions.
 840         if ($opts{notify}) {
 841             $from = $depth . "/" . $from if $depth;
 842         }
 843         if ($perlpodbadsymlink && $from =~ m!^pod/perl(.+)\.pod$!) {
 844             $from = "README.$1";
 845         }
 846         copy($from, $to);
 847         # Restore timestamps if it's a .a library or for OS/2.
 848         if (!$opts{notify} && ($Is_OS2 || $to =~ /\.a$/)) {
 849             my ($atime, $mtime) = (stat $from)[8,9];
 850             utime $atime, $mtime, $to;
 851         }
 852         1;
 853     }
 854 }
 855
 856 sub strip
 857 {
 858     my(@args) = @_;
 859
 860     return unless $dostrip;
 861
 862     my @opts;
 863     while (@args && $args[0] =~ /^(-\w+)$/) {
 864         push @opts, shift @args;
 865     }
 866
 867     foreach my $file (@args) {
 868         if (-f $file) {
 869             if ($opts{verbose}) {
 870                 print "  strip " . join(' ', @opts);
 871                 print " " if (@opts);
 872                 print "$file\n";
 873             }
 874             system("strip", @opts, $file);
 875         } else {
 876             print "# file '$file' skipped\n" if $opts{verbose};
 877         }
 878     }
 879 }