This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Re: Should keys in pseudo-hashes -always- exist? [DOC PATCH]
[perl5.git] / pod / perlref.pod
1 =head1 NAME
2
3 perlref - Perl references and nested data structures
4
5 =head1 NOTE
6
7 This is complete documentation about all aspects of references.
8 For a shorter, tutorial introduction to just the essential features,
9 see L<perlreftut>.
10
11 =head1 DESCRIPTION
12
13 Before release 5 of Perl it was difficult to represent complex data
14 structures, because all references had to be symbolic--and even then
15 it was difficult to refer to a variable instead of a symbol table entry.
16 Perl now not only makes it easier to use symbolic references to variables,
17 but also lets you have "hard" references to any piece of data or code.
18 Any scalar may hold a hard reference.  Because arrays and hashes contain
19 scalars, you can now easily build arrays of arrays, arrays of hashes,
20 hashes of arrays, arrays of hashes of functions, and so on.
21
22 Hard references are smart--they keep track of reference counts for you,
23 automatically freeing the thing referred to when its reference count goes
24 to zero.  (Reference counts for values in self-referential or
25 cyclic data structures may not go to zero without a little help; see
26 L<perlobj/"Two-Phased Garbage Collection"> for a detailed explanation.)
27 If that thing happens to be an object, the object is destructed.  See
28 L<perlobj> for more about objects.  (In a sense, everything in Perl is an
29 object, but we usually reserve the word for references to objects that
30 have been officially "blessed" into a class package.)
31
32 Symbolic references are names of variables or other objects, just as a
33 symbolic link in a Unix filesystem contains merely the name of a file.
34 The C<*glob> notation is something of a of symbolic reference.  (Symbolic
35 references are sometimes called "soft references", but please don't call
36 them that; references are confusing enough without useless synonyms.)
37
38 In contrast, hard references are more like hard links in a Unix file
39 system: They are used to access an underlying object without concern for
40 what its (other) name is.  When the word "reference" is used without an
41 adjective, as in the following paragraph, it is usually talking about a
42 hard reference.
43
44 References are easy to use in Perl.  There is just one overriding
45 principle: Perl does no implicit referencing or dereferencing.  When a
46 scalar is holding a reference, it always behaves as a simple scalar.  It
47 doesn't magically start being an array or hash or subroutine; you have to
48 tell it explicitly to do so, by dereferencing it.
49
50 =head2 Making References
51
52 References can be created in several ways.
53
54 =over 4
55
56 =item 1.
57
58 By using the backslash operator on a variable, subroutine, or value.
59 (This works much like the & (address-of) operator in C.)  
60 This typically creates I<another> reference to a variable, because
61 there's already a reference to the variable in the symbol table.  But
62 the symbol table reference might go away, and you'll still have the
63 reference that the backslash returned.  Here are some examples:
64
65     $scalarref = \$foo;
66     $arrayref  = \@ARGV;
67     $hashref   = \%ENV;
68     $coderef   = \&handler;
69     $globref   = \*foo;
70
71 It isn't possible to create a true reference to an IO handle (filehandle
72 or dirhandle) using the backslash operator.  The most you can get is a
73 reference to a typeglob, which is actually a complete symbol table entry.
74 But see the explanation of the C<*foo{THING}> syntax below.  However,
75 you can still use type globs and globrefs as though they were IO handles.
76
77 =item 2.
78
79 A reference to an anonymous array can be created using square
80 brackets:
81
82     $arrayref = [1, 2, ['a', 'b', 'c']];
83
84 Here we've created a reference to an anonymous array of three elements
85 whose final element is itself a reference to another anonymous array of three
86 elements.  (The multidimensional syntax described later can be used to
87 access this.  For example, after the above, C<$arrayref-E<gt>[2][1]> would have
88 the value "b".)
89
90 Taking a reference to an enumerated list is not the same
91 as using square brackets--instead it's the same as creating
92 a list of references!
93
94     @list = (\$a, \@b, \%c);
95     @list = \($a, @b, %c);      # same thing!
96
97 As a special case, C<\(@foo)> returns a list of references to the contents
98 of C<@foo>, not a reference to C<@foo> itself.  Likewise for C<%foo>,
99 except that the key references are to copies (since the keys are just
100 strings rather than full-fledged scalars).
101
102 =item 3.
103
104 A reference to an anonymous hash can be created using curly
105 brackets:
106
107     $hashref = {
108         'Adam'  => 'Eve',
109         'Clyde' => 'Bonnie',
110     };
111
112 Anonymous hash and array composers like these can be intermixed freely to
113 produce as complicated a structure as you want.  The multidimensional
114 syntax described below works for these too.  The values above are
115 literals, but variables and expressions would work just as well, because
116 assignment operators in Perl (even within local() or my()) are executable
117 statements, not compile-time declarations.
118
119 Because curly brackets (braces) are used for several other things
120 including BLOCKs, you may occasionally have to disambiguate braces at the
121 beginning of a statement by putting a C<+> or a C<return> in front so
122 that Perl realizes the opening brace isn't starting a BLOCK.  The economy and
123 mnemonic value of using curlies is deemed worth this occasional extra
124 hassle.
125
126 For example, if you wanted a function to make a new hash and return a
127 reference to it, you have these options:
128
129     sub hashem {        { @_ } }   # silently wrong
130     sub hashem {       +{ @_ } }   # ok
131     sub hashem { return { @_ } }   # ok
132
133 On the other hand, if you want the other meaning, you can do this:
134
135     sub showem {        { @_ } }   # ambiguous (currently ok, but may change)
136     sub showem {       {; @_ } }   # ok
137     sub showem { { return @_ } }   # ok
138
139 The leading C<+{> and C<{;> always serve to disambiguate
140 the expression to mean either the HASH reference, or the BLOCK.
141
142 =item 4.
143
144 A reference to an anonymous subroutine can be created by using
145 C<sub> without a subname:
146
147     $coderef = sub { print "Boink!\n" };
148
149 Note the semicolon.  Except for the code
150 inside not being immediately executed, a C<sub {}> is not so much a
151 declaration as it is an operator, like C<do{}> or C<eval{}>.  (However, no
152 matter how many times you execute that particular line (unless you're in an
153 C<eval("...")>), $coderef will still have a reference to the I<same>
154 anonymous subroutine.)
155
156 Anonymous subroutines act as closures with respect to my() variables,
157 that is, variables lexically visible within the current scope.  Closure
158 is a notion out of the Lisp world that says if you define an anonymous
159 function in a particular lexical context, it pretends to run in that
160 context even when it's called outside the context.
161
162 In human terms, it's a funny way of passing arguments to a subroutine when
163 you define it as well as when you call it.  It's useful for setting up
164 little bits of code to run later, such as callbacks.  You can even
165 do object-oriented stuff with it, though Perl already provides a different
166 mechanism to do that--see L<perlobj>.
167
168 You might also think of closure as a way to write a subroutine
169 template without using eval().  Here's a small example of how
170 closures work:
171
172     sub newprint {
173         my $x = shift;
174         return sub { my $y = shift; print "$x, $y!\n"; };
175     }
176     $h = newprint("Howdy");
177     $g = newprint("Greetings");
178
179     # Time passes...
180
181     &$h("world");
182     &$g("earthlings");
183
184 This prints
185
186     Howdy, world!
187     Greetings, earthlings!
188
189 Note particularly that $x continues to refer to the value passed
190 into newprint() I<despite> "my $x" having gone out of scope by the
191 time the anonymous subroutine runs.  That's what a closure is all
192 about.
193
194 This applies only to lexical variables, by the way.  Dynamic variables
195 continue to work as they have always worked.  Closure is not something
196 that most Perl programmers need trouble themselves about to begin with.
197
198 =item 5.
199
200 References are often returned by special subroutines called constructors.
201 Perl objects are just references to a special type of object that happens to know
202 which package it's associated with.  Constructors are just special
203 subroutines that know how to create that association.  They do so by
204 starting with an ordinary reference, and it remains an ordinary reference
205 even while it's also being an object.  Constructors are often
206 named new() and called indirectly:
207
208     $objref = new Doggie (Tail => 'short', Ears => 'long');
209
210 But don't have to be:
211
212     $objref   = Doggie->new(Tail => 'short', Ears => 'long');
213
214     use Term::Cap;
215     $terminal = Term::Cap->Tgetent( { OSPEED => 9600 });
216
217     use Tk;
218     $main    = MainWindow->new();
219     $menubar = $main->Frame(-relief              => "raised",
220                             -borderwidth         => 2)
221
222 =item 6.
223
224 References of the appropriate type can spring into existence if you
225 dereference them in a context that assumes they exist.  Because we haven't
226 talked about dereferencing yet, we can't show you any examples yet.
227
228 =item 7.
229
230 A reference can be created by using a special syntax, lovingly known as
231 the *foo{THING} syntax.  *foo{THING} returns a reference to the THING
232 slot in *foo (which is the symbol table entry which holds everything
233 known as foo).
234
235     $scalarref = *foo{SCALAR};
236     $arrayref  = *ARGV{ARRAY};
237     $hashref   = *ENV{HASH};
238     $coderef   = *handler{CODE};
239     $ioref     = *STDIN{IO};
240     $globref   = *foo{GLOB};
241
242 All of these are self-explanatory except for C<*foo{IO}>.  It returns
243 the IO handle, used for file handles (L<perlfunc/open>), sockets
244 (L<perlfunc/socket> and L<perlfunc/socketpair>), and directory
245 handles (L<perlfunc/opendir>).  For compatibility with previous
246 versions of Perl, C<*foo{FILEHANDLE}> is a synonym for C<*foo{IO}>.
247
248 C<*foo{THING}> returns undef if that particular THING hasn't been used yet,
249 except in the case of scalars.  C<*foo{SCALAR}> returns a reference to an
250 anonymous scalar if $foo hasn't been used yet.  This might change in a
251 future release.
252
253 C<*foo{IO}> is an alternative to the C<*HANDLE> mechanism given in
254 L<perldata/"Typeglobs and Filehandles"> for passing filehandles
255 into or out of subroutines, or storing into larger data structures.
256 Its disadvantage is that it won't create a new filehandle for you.
257 Its advantage is that you have less risk of clobbering more than
258 you want to with a typeglob assignment.  (It still conflates file
259 and directory handles, though.)  However, if you assign the incoming
260 value to a scalar instead of a typeglob as we do in the examples
261 below, there's no risk of that happening.
262
263     splutter(*STDOUT);          # pass the whole glob
264     splutter(*STDOUT{IO});      # pass both file and dir handles
265
266     sub splutter {
267         my $fh = shift;
268         print $fh "her um well a hmmm\n";
269     }
270
271     $rec = get_rec(*STDIN);     # pass the whole glob
272     $rec = get_rec(*STDIN{IO}); # pass both file and dir handles
273
274     sub get_rec {
275         my $fh = shift;
276         return scalar <$fh>;
277     }
278
279 =back
280
281 =head2 Using References
282
283 That's it for creating references.  By now you're probably dying to
284 know how to use references to get back to your long-lost data.  There
285 are several basic methods.
286
287 =over 4
288
289 =item 1.
290
291 Anywhere you'd put an identifier (or chain of identifiers) as part
292 of a variable or subroutine name, you can replace the identifier with
293 a simple scalar variable containing a reference of the correct type:
294
295     $bar = $$scalarref;
296     push(@$arrayref, $filename);
297     $$arrayref[0] = "January";
298     $$hashref{"KEY"} = "VALUE";
299     &$coderef(1,2,3);
300     print $globref "output\n";
301
302 It's important to understand that we are specifically I<not> dereferencing
303 C<$arrayref[0]> or C<$hashref{"KEY"}> there.  The dereference of the
304 scalar variable happens I<before> it does any key lookups.  Anything more
305 complicated than a simple scalar variable must use methods 2 or 3 below.
306 However, a "simple scalar" includes an identifier that itself uses method
307 1 recursively.  Therefore, the following prints "howdy".
308
309     $refrefref = \\\"howdy";
310     print $$$$refrefref;
311
312 =item 2.
313
314 Anywhere you'd put an identifier (or chain of identifiers) as part of a
315 variable or subroutine name, you can replace the identifier with a
316 BLOCK returning a reference of the correct type.  In other words, the
317 previous examples could be written like this:
318
319     $bar = ${$scalarref};
320     push(@{$arrayref}, $filename);
321     ${$arrayref}[0] = "January";
322     ${$hashref}{"KEY"} = "VALUE";
323     &{$coderef}(1,2,3);
324     $globref->print("output\n");  # iff IO::Handle is loaded
325
326 Admittedly, it's a little silly to use the curlies in this case, but
327 the BLOCK can contain any arbitrary expression, in particular,
328 subscripted expressions:
329
330     &{ $dispatch{$index} }(1,2,3);      # call correct routine
331
332 Because of being able to omit the curlies for the simple case of C<$$x>,
333 people often make the mistake of viewing the dereferencing symbols as
334 proper operators, and wonder about their precedence.  If they were,
335 though, you could use parentheses instead of braces.  That's not the case.
336 Consider the difference below; case 0 is a short-hand version of case 1,
337 I<not> case 2:
338
339     $$hashref{"KEY"}   = "VALUE";       # CASE 0
340     ${$hashref}{"KEY"} = "VALUE";       # CASE 1
341     ${$hashref{"KEY"}} = "VALUE";       # CASE 2
342     ${$hashref->{"KEY"}} = "VALUE";     # CASE 3
343
344 Case 2 is also deceptive in that you're accessing a variable
345 called %hashref, not dereferencing through $hashref to the hash
346 it's presumably referencing.  That would be case 3.
347
348 =item 3.
349
350 Subroutine calls and lookups of individual array elements arise often
351 enough that it gets cumbersome to use method 2.  As a form of
352 syntactic sugar, the examples for method 2 may be written:
353
354     $arrayref->[0] = "January";   # Array element
355     $hashref->{"KEY"} = "VALUE";  # Hash element
356     $coderef->(1,2,3);            # Subroutine call
357
358 The left side of the arrow can be any expression returning a reference,
359 including a previous dereference.  Note that C<$array[$x]> is I<not> the
360 same thing as C<$array-E<gt>[$x]> here:
361
362     $array[$x]->{"foo"}->[0] = "January";
363
364 This is one of the cases we mentioned earlier in which references could
365 spring into existence when in an lvalue context.  Before this
366 statement, C<$array[$x]> may have been undefined.  If so, it's
367 automatically defined with a hash reference so that we can look up
368 C<{"foo"}> in it.  Likewise C<$array[$x]-E<gt>{"foo"}> will automatically get
369 defined with an array reference so that we can look up C<[0]> in it.
370 This process is called I<autovivification>.
371
372 One more thing here.  The arrow is optional I<between> brackets
373 subscripts, so you can shrink the above down to
374
375     $array[$x]{"foo"}[0] = "January";
376
377 Which, in the degenerate case of using only ordinary arrays, gives you
378 multidimensional arrays just like C's:
379
380     $score[$x][$y][$z] += 42;
381
382 Well, okay, not entirely like C's arrays, actually.  C doesn't know how
383 to grow its arrays on demand.  Perl does.
384
385 =item 4.
386
387 If a reference happens to be a reference to an object, then there are
388 probably methods to access the things referred to, and you should probably
389 stick to those methods unless you're in the class package that defines the
390 object's methods.  In other words, be nice, and don't violate the object's
391 encapsulation without a very good reason.  Perl does not enforce
392 encapsulation.  We are not totalitarians here.  We do expect some basic
393 civility though.
394
395 =back
396
397 Using a string or number as a reference produces a symbolic reference,
398 as explained above.  Using a reference as a number produces an
399 integer representing its storage location in memory.  The only
400 useful thing to be done with this is to compare two references
401 numerically to see whether they refer to the same location.
402
403     if ($ref1 == $ref2) {  # cheap numeric compare of references
404         print "refs 1 and 2 refer to the same thing\n";
405     }
406
407 Using a reference as a string produces both its referent's type,
408 including any package blessing as described in L<perlobj>, as well
409 as the numeric address expressed in hex.  The ref() operator returns
410 just the type of thing the reference is pointing to, without the
411 address.  See L<perlfunc/ref> for details and examples of its use.
412
413 The bless() operator may be used to associate the object a reference
414 points to with a package functioning as an object class.  See L<perlobj>.
415
416 A typeglob may be dereferenced the same way a reference can, because
417 the dereference syntax always indicates the type of reference desired.
418 So C<${*foo}> and C<${\$foo}> both indicate the same scalar variable.
419
420 Here's a trick for interpolating a subroutine call into a string:
421
422     print "My sub returned @{[mysub(1,2,3)]} that time.\n";
423
424 The way it works is that when the C<@{...}> is seen in the double-quoted
425 string, it's evaluated as a block.  The block creates a reference to an
426 anonymous array containing the results of the call to C<mysub(1,2,3)>.  So
427 the whole block returns a reference to an array, which is then
428 dereferenced by C<@{...}> and stuck into the double-quoted string. This
429 chicanery is also useful for arbitrary expressions:
430
431     print "That yields @{[$n + 5]} widgets\n";
432
433 =head2 Symbolic references
434
435 We said that references spring into existence as necessary if they are
436 undefined, but we didn't say what happens if a value used as a
437 reference is already defined, but I<isn't> a hard reference.  If you
438 use it as a reference, it'll be treated as a symbolic
439 reference.  That is, the value of the scalar is taken to be the I<name>
440 of a variable, rather than a direct link to a (possibly) anonymous
441 value.
442
443 People frequently expect it to work like this.  So it does.
444
445     $name = "foo";
446     $$name = 1;                 # Sets $foo
447     ${$name} = 2;               # Sets $foo
448     ${$name x 2} = 3;           # Sets $foofoo
449     $name->[0] = 4;             # Sets $foo[0]
450     @$name = ();                # Clears @foo
451     &$name();                   # Calls &foo() (as in Perl 4)
452     $pack = "THAT";
453     ${"${pack}::$name"} = 5;    # Sets $THAT::foo without eval
454
455 This is powerful, and slightly dangerous, in that it's possible
456 to intend (with the utmost sincerity) to use a hard reference, and
457 accidentally use a symbolic reference instead.  To protect against
458 that, you can say
459
460     use strict 'refs';
461
462 and then only hard references will be allowed for the rest of the enclosing
463 block.  An inner block may countermand that with
464
465     no strict 'refs';
466
467 Only package variables (globals, even if localized) are visible to
468 symbolic references.  Lexical variables (declared with my()) aren't in
469 a symbol table, and thus are invisible to this mechanism.  For example:
470
471     local $value = 10;
472     $ref = "value";
473     {
474         my $value = 20;
475         print $$ref;
476     }
477
478 This will still print 10, not 20.  Remember that local() affects package
479 variables, which are all "global" to the package.
480
481 =head2 Not-so-symbolic references
482
483 A new feature contributing to readability in perl version 5.001 is that the
484 brackets around a symbolic reference behave more like quotes, just as they
485 always have within a string.  That is,
486
487     $push = "pop on ";
488     print "${push}over";
489
490 has always meant to print "pop on over", even though push is
491 a reserved word.  This has been generalized to work the same outside
492 of quotes, so that
493
494     print ${push} . "over";
495
496 and even
497
498     print ${ push } . "over";
499
500 will have the same effect.  (This would have been a syntax error in
501 Perl 5.000, though Perl 4 allowed it in the spaceless form.)  This
502 construct is I<not> considered to be a symbolic reference when you're
503 using strict refs:
504
505     use strict 'refs';
506     ${ bareword };      # Okay, means $bareword.
507     ${ "bareword" };    # Error, symbolic reference.
508
509 Similarly, because of all the subscripting that is done using single
510 words, we've applied the same rule to any bareword that is used for
511 subscripting a hash.  So now, instead of writing
512
513     $array{ "aaa" }{ "bbb" }{ "ccc" }
514
515 you can write just
516
517     $array{ aaa }{ bbb }{ ccc }
518
519 and not worry about whether the subscripts are reserved words.  In the
520 rare event that you do wish to do something like
521
522     $array{ shift }
523
524 you can force interpretation as a reserved word by adding anything that
525 makes it more than a bareword:
526
527     $array{ shift() }
528     $array{ +shift }
529     $array{ shift @_ }
530
531 The B<-w> switch will warn you if it interprets a reserved word as a string.
532 But it will no longer warn you about using lowercase words, because the
533 string is effectively quoted.
534
535 =head2 Pseudo-hashes: Using an array as a hash
536
537 B<WARNING>:  This section describes an experimental feature.  Details may
538 change without notice in future versions.
539
540 Beginning with release 5.005 of Perl, you may use an array reference
541 in some contexts that would normally require a hash reference.  This
542 allows you to access array elements using symbolic names, as if they
543 were fields in a structure.
544
545 For this to work, the array must contain extra information.  The first
546 element of the array has to be a hash reference that maps field names
547 to array indices.  Here is an example:
548
549    $struct = [{foo => 1, bar => 2}, "FOO", "BAR"];
550
551    $struct->{foo};  # same as $struct->[1], i.e. "FOO"
552    $struct->{bar};  # same as $struct->[2], i.e. "BAR"
553
554    keys %$struct;   # will return ("foo", "bar") in some order
555    values %$struct; # will return ("FOO", "BAR") in same some order
556
557    while (my($k,$v) = each %$struct) {
558        print "$k => $v\n";
559    }
560
561 Perl will raise an exception if you try to delete keys from a pseudo-hash
562 or try to access nonexistent fields.  For better performance, Perl can also
563 do the translation from field names to array indices at compile time for
564 typed object references.  See L<fields>.
565
566 There are two ways to check for the existance of a key in a
567 pseudo-hash.  The first is to use exists().  This checks to see if the
568 given field has been used yet.  It acts this way to match the behavior
569 of a regular hash.  For instance:
570
571         $phash = [{foo =>, bar => 2, pants => 3}, 'FOO'];
572         $phash->{pants} = undef;
573
574         exists $phash->{foo};    # true, 'foo' was set in the declaration
575         exists $phash->{bar};    # false, 'bar' has not been used.
576         exists $phash->{pants};  # true, your 'pants' have been touched
577
578 The second is to use exists() on the hash reference sitting in the
579 first array element.  This checks to see if the given key is a valid
580 field in the pseudo-hash.
581
582         exists $phash->[0]{pants};      # true, 'pants' is a valid field
583         exists $phash->[0]{shoes};      # false, 'shoes' can't be used
584
585 =head2 Function Templates
586
587 As explained above, a closure is an anonymous function with access to the
588 lexical variables visible when that function was compiled.  It retains
589 access to those variables even though it doesn't get run until later,
590 such as in a signal handler or a Tk callback.
591
592 Using a closure as a function template allows us to generate many functions
593 that act similarly.  Suppose you wanted functions named after the colors
594 that generated HTML font changes for the various colors:
595
596     print "Be ", red("careful"), "with that ", green("light");
597
598 The red() and green() functions would be similar.  To create these,
599 we'll assign a closure to a typeglob of the name of the function we're
600 trying to build.  
601
602     @colors = qw(red blue green yellow orange purple violet);
603     for my $name (@colors) {
604         no strict 'refs';       # allow symbol table manipulation
605         *$name = *{uc $name} = sub { "<FONT COLOR='$name'>@_</FONT>" };
606     } 
607
608 Now all those different functions appear to exist independently.  You can
609 call red(), RED(), blue(), BLUE(), green(), etc.  This technique saves on
610 both compile time and memory use, and is less error-prone as well, since
611 syntax checks happen at compile time.  It's critical that any variables in
612 the anonymous subroutine be lexicals in order to create a proper closure.
613 That's the reasons for the C<my> on the loop iteration variable.
614
615 This is one of the only places where giving a prototype to a closure makes
616 much sense.  If you wanted to impose scalar context on the arguments of
617 these functions (probably not a wise idea for this particular example),
618 you could have written it this way instead:
619
620     *$name = sub ($) { "<FONT COLOR='$name'>$_[0]</FONT>" };
621
622 However, since prototype checking happens at compile time, the assignment
623 above happens too late to be of much use.  You could address this by
624 putting the whole loop of assignments within a BEGIN block, forcing it
625 to occur during compilation.
626
627 Access to lexicals that change over type--like those in the C<for> loop
628 above--only works with closures, not general subroutines.  In the general
629 case, then, named subroutines do not nest properly, although anonymous
630 ones do.  If you are accustomed to using nested subroutines in other
631 programming languages with their own private variables, you'll have to
632 work at it a bit in Perl.  The intuitive coding of this type of thing
633 incurs mysterious warnings about ``will not stay shared''.  For example,
634 this won't work:
635
636     sub outer {
637         my $x = $_[0] + 35;
638         sub inner { return $x * 19 }   # WRONG
639         return $x + inner();
640     } 
641
642 A work-around is the following:
643
644     sub outer {
645         my $x = $_[0] + 35;
646         local *inner = sub { return $x * 19 };
647         return $x + inner();
648     } 
649
650 Now inner() can only be called from within outer(), because of the
651 temporary assignments of the closure (anonymous subroutine).  But when
652 it does, it has normal access to the lexical variable $x from the scope
653 of outer().
654
655 This has the interesting effect of creating a function local to another
656 function, something not normally supported in Perl.
657
658 =head1 WARNING
659
660 You may not (usefully) use a reference as the key to a hash.  It will be
661 converted into a string:
662
663     $x{ \$a } = $a;
664
665 If you try to dereference the key, it won't do a hard dereference, and
666 you won't accomplish what you're attempting.  You might want to do something
667 more like
668
669     $r = \@a;
670     $x{ $r } = $r;
671
672 And then at least you can use the values(), which will be
673 real refs, instead of the keys(), which won't.
674
675 The standard Tie::RefHash module provides a convenient workaround to this.
676
677 =head1 SEE ALSO
678
679 Besides the obvious documents, source code can be instructive.
680 Some pathological examples of the use of references can be found
681 in the F<t/op/ref.t> regression test in the Perl source directory.
682
683 See also L<perldsc> and L<perllol> for how to use references to create
684 complex data structures, and L<perltoot>, L<perlobj>, and L<perlbot>
685 for how to use them to create objects.