This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
dfd6374378cc70d3bc349c5f29edcf957c9abb64
[perl5.git] / pod / perlfaq4.pod
1 =head1 NAME
2
3 perlfaq4 - Data Manipulation ($Revision: 1.49 $, $Date: 1999/05/23 20:37:49 $)
4
5 =head1 DESCRIPTION
6
7 The section of the FAQ answers questions related to the manipulation
8 of data as numbers, dates, strings, arrays, hashes, and miscellaneous
9 data issues.
10
11 =head1 Data: Numbers
12
13 =head2 Why am I getting long decimals (eg, 19.9499999999999) instead of the numbers I should be getting (eg, 19.95)?
14
15 The infinite set that a mathematician thinks of as the real numbers can
16 only be approximated on a computer, since the computer only has a finite
17 number of bits to store an infinite number of, um, numbers.
18
19 Internally, your computer represents floating-point numbers in binary.
20 Floating-point numbers read in from a file or appearing as literals
21 in your program are converted from their decimal floating-point
22 representation (eg, 19.95) to an internal binary representation.
23
24 However, 19.95 can't be precisely represented as a binary
25 floating-point number, just like 1/3 can't be exactly represented as a
26 decimal floating-point number.  The computer's binary representation
27 of 19.95, therefore, isn't exactly 19.95.
28
29 When a floating-point number gets printed, the binary floating-point
30 representation is converted back to decimal.  These decimal numbers
31 are displayed in either the format you specify with printf(), or the
32 current output format for numbers.  (See L<perlvar/"$#"> if you use
33 print.  C<$#> has a different default value in Perl5 than it did in
34 Perl4.  Changing C<$#> yourself is deprecated.)
35
36 This affects B<all> computer languages that represent decimal
37 floating-point numbers in binary, not just Perl.  Perl provides
38 arbitrary-precision decimal numbers with the Math::BigFloat module
39 (part of the standard Perl distribution), but mathematical operations
40 are consequently slower.
41
42 If precision is important, such as when dealing with money, it's good
43 to work with integers and then divide at the last possible moment.
44 For example, work in pennies (1995) instead of dollars and cents
45 (19.95) and divide by 100 at the end.
46
47 To get rid of the superfluous digits, just use a format (eg,
48 C<printf("%.2f", 19.95)>) to get the required precision.
49 See L<perlop/"Floating-point Arithmetic">.  
50
51 =head2 Why isn't my octal data interpreted correctly?
52
53 Perl only understands octal and hex numbers as such when they occur
54 as literals in your program.  Octal literals in perl must start with 
55 a leading "0" and hexadecimal literals must start with a leading "0x".
56 If they are read in from somewhere and assigned, no automatic 
57 conversion takes place.  You must explicitly use oct() or hex() if you 
58 want the values converted to decimal.  oct() interprets
59 both hex ("0x350") numbers and octal ones ("0350" or even without the
60 leading "0", like "377"), while hex() only converts hexadecimal ones,
61 with or without a leading "0x", like "0x255", "3A", "ff", or "deadbeef".
62 The inverse mapping from decimal to octal can be done with either the
63 "%o" or "%O" sprintf() formats.  To get from decimal to hex try either 
64 the "%x" or the "%X" formats to sprintf().
65
66 This problem shows up most often when people try using chmod(), mkdir(),
67 umask(), or sysopen(), which by widespread tradition typically take 
68 permissions in octal.
69
70     chmod(644,  $file); # WRONG
71     chmod(0644, $file); # right
72
73 Note the mistake in the first line was specifying the decimal literal 
74 644, rather than the intended octal literal 0644.  The problem can
75 be seen with:
76
77     printf("%#o",644); # prints 01204
78
79 Surely you had not intended C<chmod(01204, $file);> - did you?  If you
80 want to use numeric literals as arguments to chmod() et al. then please
81 try to express them as octal constants, that is with a leading zero and 
82 with the following digits restricted to the set 0..7.
83
84 =head2 Does Perl have a round() function?  What about ceil() and floor()?  Trig functions?
85
86 Remember that int() merely truncates toward 0.  For rounding to a
87 certain number of digits, sprintf() or printf() is usually the easiest
88 route.
89
90     printf("%.3f", 3.1415926535);       # prints 3.142
91
92 The POSIX module (part of the standard Perl distribution) implements
93 ceil(), floor(), and a number of other mathematical and trigonometric
94 functions.
95
96     use POSIX;
97     $ceil   = ceil(3.5);                        # 4
98     $floor  = floor(3.5);                       # 3
99
100 In 5.000 to 5.003 perls, trigonometry was done in the Math::Complex
101 module.  With 5.004, the Math::Trig module (part of the standard Perl
102 distribution) implements the trigonometric functions. Internally it
103 uses the Math::Complex module and some functions can break out from
104 the real axis into the complex plane, for example the inverse sine of
105 2.
106
107 Rounding in financial applications can have serious implications, and
108 the rounding method used should be specified precisely.  In these
109 cases, it probably pays not to trust whichever system rounding is
110 being used by Perl, but to instead implement the rounding function you
111 need yourself.
112
113 To see why, notice how you'll still have an issue on half-way-point
114 alternation:
115
116     for ($i = 0; $i < 1.01; $i += 0.05) { printf "%.1f ",$i}
117
118     0.0 0.1 0.1 0.2 0.2 0.2 0.3 0.3 0.4 0.4 0.5 0.5 0.6 0.7 0.7 
119     0.8 0.8 0.9 0.9 1.0 1.0
120
121 Don't blame Perl.  It's the same as in C.  IEEE says we have to do this.
122 Perl numbers whose absolute values are integers under 2**31 (on 32 bit
123 machines) will work pretty much like mathematical integers.  Other numbers
124 are not guaranteed.
125
126 =head2 How do I convert bits into ints?
127
128 To turn a string of 1s and 0s like C<10110110> into a scalar containing
129 its binary value, use the pack() and unpack() functions (documented in
130 L<perlfunc/"pack"> and L<perlfunc/"unpack">):
131
132     $decimal = unpack('c', pack('B8', '10110110'));
133
134 This packs the string C<10110110> into an eight bit binary structure.
135 This is then unpacked as a character, which returns its ordinal value.
136
137 This does the same thing:
138
139     $decimal = ord(pack('B8', '10110110'));
140
141 Here's an example of going the other way:
142
143     $binary_string = unpack('B*', "\x29");
144
145 =head2 Why doesn't & work the way I want it to?
146
147 The behavior of binary arithmetic operators depends on whether they're
148 used on numbers or strings.  The operators treat a string as a series
149 of bits and work with that (the string C<"3"> is the bit pattern
150 C<00110011>).  The operators work with the binary form of a number
151 (the number C<3> is treated as the bit pattern C<00000011>).
152
153 So, saying C<11 & 3> performs the "and" operation on numbers (yielding
154 C<1>).  Saying C<"11" & "3"> performs the "and" operation on strings
155 (yielding C<"1">).
156
157 Most problems with C<&> and C<|> arise because the programmer thinks
158 they have a number but really it's a string.  The rest arise because
159 the programmer says:
160
161     if ("\020\020" & "\101\101") {
162         # ...
163     }
164
165 but a string consisting of two null bytes (the result of C<"\020\020"
166 & "\101\101">) is not a false value in Perl.  You need:
167
168     if ( ("\020\020" & "\101\101") !~ /[^\000]/) {
169         # ...
170     }
171
172 =head2 How do I multiply matrices?
173
174 Use the Math::Matrix or Math::MatrixReal modules (available from CPAN)
175 or the PDL extension (also available from CPAN).
176
177 =head2 How do I perform an operation on a series of integers?
178
179 To call a function on each element in an array, and collect the
180 results, use:
181
182     @results = map { my_func($_) } @array;
183
184 For example:
185
186     @triple = map { 3 * $_ } @single;
187
188 To call a function on each element of an array, but ignore the
189 results:
190
191     foreach $iterator (@array) {
192         some_func($iterator);
193     }
194
195 To call a function on each integer in a (small) range, you B<can> use:
196
197     @results = map { some_func($_) } (5 .. 25);
198
199 but you should be aware that the C<..> operator creates an array of
200 all integers in the range.  This can take a lot of memory for large
201 ranges.  Instead use:
202
203     @results = ();
204     for ($i=5; $i < 500_005; $i++) {
205         push(@results, some_func($i));
206     }
207
208 This situation has been fixed in Perl5.005. Use of C<..> in a C<for>
209 loop will iterate over the range, without creating the entire range.
210
211     for my $i (5 .. 500_005) {
212         push(@results, some_func($i));
213     }
214
215 will not create a list of 500,000 integers.
216
217 =head2 How can I output Roman numerals?
218
219 Get the http://www.perl.com/CPAN/modules/by-module/Roman module.
220
221 =head2 Why aren't my random numbers random?
222
223 If you're using a version of Perl before 5.004, you must call C<srand>
224 once at the start of your program to seed the random number generator.
225 5.004 and later automatically call C<srand> at the beginning.  Don't
226 call C<srand> more than once--you make your numbers less random, rather
227 than more.
228
229 Computers are good at being predictable and bad at being random
230 (despite appearances caused by bugs in your programs :-).
231 http://www.perl.com/CPAN/doc/FMTEYEWTK/random , courtesy of Tom
232 Phoenix, talks more about this.  John von Neumann said, ``Anyone who
233 attempts to generate random numbers by deterministic means is, of
234 course, living in a state of sin.''
235
236 If you want numbers that are more random than C<rand> with C<srand>
237 provides, you should also check out the Math::TrulyRandom module from
238 CPAN.  It uses the imperfections in your system's timer to generate
239 random numbers, but this takes quite a while.  If you want a better
240 pseudorandom generator than comes with your operating system, look at
241 ``Numerical Recipes in C'' at http://www.nr.com/ .
242
243 =head1 Data: Dates
244
245 =head2 How do I find the week-of-the-year/day-of-the-year?
246
247 The day of the year is in the array returned by localtime() (see
248 L<perlfunc/"localtime">):
249
250     $day_of_year = (localtime(time()))[7];
251
252 or more legibly (in 5.7.1 or higher):
253
254     use Time::Piece;
255     $day_of_year = localtime->day_of_year();
256
257 You can find the week of the year by using Time::Piece's strftime():
258
259     $week_of_year = localtime->strftime("%U");
260     $iso_week = localtime->strftime("%V");
261
262 The difference between %U and %V is that %U assumes that the first day
263 of week 1 is the first Sunday of the year, whereas ISO 8601:1988 uses
264 the first week that has at least 4 days in the current year, and with
265 Monday as the first day of the week. You can also use %W, which will
266 return the week of the year with Monday as the first day of week 1. See
267 your strftime(3) man page for more details.
268
269 =head2 How do I find the current century or millennium?
270
271 Use the following simple functions:
272
273     sub get_century    { 
274         return int((((localtime(shift || time))[5] + 1999))/100);
275     } 
276     sub get_millennium { 
277         return 1+int((((localtime(shift || time))[5] + 1899))/1000);
278     } 
279
280 On some systems, you'll find that the POSIX module's strftime() function
281 has been extended in a non-standard way to use a C<%C> format, which they
282 sometimes claim is the "century".  It isn't, because on most such systems,
283 this is only the first two digits of the four-digit year, and thus cannot
284 be used to reliably determine the current century or millennium.
285
286 =head2 How can I compare two dates and find the difference?
287
288 If you're storing your dates as epoch seconds then simply subtract one
289 from the other.  If you've got a structured date (distinct year, day,
290 month, hour, minute, seconds values), then for reasons of accessibility,
291 simplicity, and efficiency, merely use either timelocal or timegm (from
292 the Time::Local module in the standard distribution) to reduce structured
293 dates to epoch seconds.  However, if you don't know the precise format of
294 your dates, then you should probably use either of the Date::Manip and
295 Date::Calc modules from CPAN before you go hacking up your own parsing
296 routine to handle arbitrary date formats.
297
298 Also note that the core module Time::Piece overloads the addition and
299 subtraction operators to provide date calculation options. See
300 L<Time::Piece/Date Calculations>.
301
302 =head2 How can I take a string and turn it into epoch seconds?
303
304 If it's a regular enough string that it always has the same format,
305 you can split it up and pass the parts to C<timelocal> in the standard
306 Time::Local module.  Otherwise, you should look into the Date::Calc
307 and Date::Manip modules from CPAN.
308
309 =head2 How can I find the Julian Day?
310
311 Use Time::Piece as follows:
312
313     use Time::Piece;
314     my $julian_day = localtime->julian_day;
315     my $mjd = localtime->mjd; # modified julian day
316
317 Before you immerse yourself too deeply in this, be sure to verify that
318 it is the I<Julian> Day you really want.  Are you interested in a way
319 of getting serial days so that you just can tell how many days they
320 are apart or so that you can do also other date arithmetic?  If you
321 are interested in performing date arithmetic, this can be done using
322 Time::Piece (standard module since Perl 5.8), or by modules
323 Date::Manip or Date::Calc.
324
325 There is too many details and much confusion on this issue to cover in
326 this FAQ, but the term is applied (correctly) to a calendar now
327 supplanted by the Gregorian Calendar, with the Julian Calendar failing
328 to adjust properly for leap years on centennial years (among other
329 annoyances).  The term is also used (incorrectly) to mean: [1] days in
330 the Gregorian Calendar; and [2] days since a particular starting time
331 or `epoch', usually 1970 in the Unix world and 1980 in the
332 MS-DOS/Windows world.  If you find that it is not the first meaning
333 that you really want, then check out the Date::Manip and Date::Calc
334 modules.  (Thanks to David Cassell for most of this text.)
335
336 =head2 How do I find yesterday's date?
337
338 The C<time()> function returns the current time in seconds since the
339 epoch.  Take twenty-four hours off that:
340
341     $yesterday = time() - ( 24 * 60 * 60 );
342
343 Then you can pass this to C<localtime()> and get the individual year,
344 month, day, hour, minute, seconds values.
345
346 Alternatively, you can use Time::Piece to subtract a day from the value
347 returned from C<localtime()>:
348
349     use Time::Piece;
350     use Time::Seconds; # imports seconds constants, like ONE_DAY
351     my $today = localtime();
352     my $yesterday = $today - ONE_DAY;
353
354 Note very carefully that the code above assumes that your days are
355 twenty-four hours each.  For most people, there are two days a year
356 when they aren't: the switch to and from summer time throws this off.
357 A solution to this issue is offered by Russ Allbery.
358
359     sub yesterday {
360         my $now  = defined $_[0] ? $_[0] : time;
361         my $then = $now - 60 * 60 * 24;
362         my $ndst = (localtime $now)[8] > 0;
363         my $tdst = (localtime $then)[8] > 0;
364         $then - ($tdst - $ndst) * 60 * 60;
365     }
366     # Should give you "this time yesterday" in seconds since epoch relative to
367     # the first argument or the current time if no argument is given and
368     # suitable for passing to localtime or whatever else you need to do with
369     # it.  $ndst is whether we're currently in daylight savings time; $tdst is
370     # whether the point 24 hours ago was in daylight savings time.  If $tdst
371     # and $ndst are the same, a boundary wasn't crossed, and the correction
372     # will subtract 0.  If $tdst is 1 and $ndst is 0, subtract an hour more
373     # from yesterday's time since we gained an extra hour while going off
374     # daylight savings time.  If $tdst is 0 and $ndst is 1, subtract a
375     # negative hour (add an hour) to yesterday's time since we lost an hour.
376     #
377     # All of this is because during those days when one switches off or onto
378     # DST, a "day" isn't 24 hours long; it's either 23 or 25.
379     #
380     # The explicit settings of $ndst and $tdst are necessary because localtime
381     # only says it returns the system tm struct, and the system tm struct at
382     # least on Solaris doesn't guarantee any particular positive value (like,
383     # say, 1) for isdst, just a positive value.  And that value can
384     # potentially be negative, if DST information isn't available (this sub
385     # just treats those cases like no DST).
386     #
387     # Note that between 2am and 3am on the day after the time zone switches
388     # off daylight savings time, the exact hour of "yesterday" corresponding
389     # to the current hour is not clearly defined.  Note also that if used
390     # between 2am and 3am the day after the change to daylight savings time,
391     # the result will be between 3am and 4am of the previous day; it's
392     # arguable whether this is correct.
393     #
394     # This sub does not attempt to deal with leap seconds (most things don't).
395     #
396     # Copyright relinquished 1999 by Russ Allbery <rra@stanford.edu>
397     # This code is in the public domain
398
399 =head2 Does Perl have a Year 2000 problem?  Is Perl Y2K compliant?
400
401 Short answer: No, Perl does not have a Year 2000 problem.  Yes, Perl is
402 Y2K compliant (whatever that means).  The programmers you've hired to
403 use it, however, probably are not.
404
405 Long answer: The question belies a true understanding of the issue.
406 Perl is just as Y2K compliant as your pencil--no more, and no less.
407 Can you use your pencil to write a non-Y2K-compliant memo?  Of course
408 you can.  Is that the pencil's fault?  Of course it isn't.
409
410 The date and time functions supplied with Perl (gmtime and localtime)
411 supply adequate information to determine the year well beyond 2000
412 (2038 is when trouble strikes for 32-bit machines).  The year returned
413 by these functions when used in a list context is the year minus 1900.
414 For years between 1910 and 1999 this I<happens> to be a 2-digit decimal
415 number. To avoid the year 2000 problem simply do not treat the year as
416 a 2-digit number.  It isn't.
417
418 When gmtime() and localtime() are used in scalar context they return
419 a timestamp string that contains a fully-expanded year.  For example,
420 C<$timestamp = gmtime(1005613200)> sets $timestamp to "Tue Nov 13 01:00:00
421 2001".  There's no year 2000 problem here.
422
423 That doesn't mean that Perl can't be used to create non-Y2K compliant
424 programs.  It can.  But so can your pencil.  It's the fault of the user,
425 not the language.  At the risk of inflaming the NRA: ``Perl doesn't
426 break Y2K, people do.''  See http://language.perl.com/news/y2k.html for
427 a longer exposition.
428
429 =head1 Data: Strings
430
431 =head2 How do I validate input?
432
433 The answer to this question is usually a regular expression, perhaps
434 with auxiliary logic.  See the more specific questions (numbers, mail
435 addresses, etc.) for details.
436
437 =head2 How do I unescape a string?
438
439 It depends just what you mean by ``escape''.  URL escapes are dealt
440 with in L<perlfaq9>.  Shell escapes with the backslash (C<\>)
441 character are removed with
442
443     s/\\(.)/$1/g;
444
445 This won't expand C<"\n"> or C<"\t"> or any other special escapes.
446
447 =head2 How do I remove consecutive pairs of characters?
448
449 To turn C<"abbcccd"> into C<"abccd">:
450
451     s/(.)\1/$1/g;       # add /s to include newlines
452
453 Here's a solution that turns "abbcccd" to "abcd":
454
455     y///cs;     # y == tr, but shorter :-)
456
457 =head2 How do I expand function calls in a string?
458
459 This is documented in L<perlref>.  In general, this is fraught with
460 quoting and readability problems, but it is possible.  To interpolate
461 a subroutine call (in list context) into a string:
462
463     print "My sub returned @{[mysub(1,2,3)]} that time.\n";
464
465 If you prefer scalar context, similar chicanery is also useful for
466 arbitrary expressions:
467
468     print "That yields ${\($n + 5)} widgets\n";
469
470 Version 5.004 of Perl had a bug that gave list context to the
471 expression in C<${...}>, but this is fixed in version 5.005.
472
473 See also ``How can I expand variables in text strings?'' in this
474 section of the FAQ.
475
476 =head2 How do I find matching/nesting anything?
477
478 This isn't something that can be done in one regular expression, no
479 matter how complicated.  To find something between two single
480 characters, a pattern like C</x([^x]*)x/> will get the intervening
481 bits in $1. For multiple ones, then something more like
482 C</alpha(.*?)omega/> would be needed.  But none of these deals with
483 nested patterns, nor can they.  For that you'll have to write a
484 parser.
485
486 If you are serious about writing a parser, there are a number of
487 modules or oddities that will make your life a lot easier.  There are
488 the CPAN modules Parse::RecDescent, Parse::Yapp, and Text::Balanced;
489 and the byacc program.   Starting from perl 5.8 the Text::Balanced
490 is part of the standard distribution.
491
492 One simple destructive, inside-out approach that you might try is to
493 pull out the smallest nesting parts one at a time:
494
495     while (s/BEGIN((?:(?!BEGIN)(?!END).)*)END//gs) {
496         # do something with $1
497     } 
498
499 A more complicated and sneaky approach is to make Perl's regular
500 expression engine do it for you.  This is courtesy Dean Inada, and
501 rather has the nature of an Obfuscated Perl Contest entry, but it
502 really does work:
503
504     # $_ contains the string to parse
505     # BEGIN and END are the opening and closing markers for the
506     # nested text.
507
508     @( = ('(','');
509     @) = (')','');
510     ($re=$_)=~s/((BEGIN)|(END)|.)/$)[!$3]\Q$1\E$([!$2]/gs;
511     @$ = (eval{/$re/},$@!~/unmatched/);
512     print join("\n",@$[0..$#$]) if( $$[-1] );
513
514 =head2 How do I reverse a string?
515
516 Use reverse() in scalar context, as documented in
517 L<perlfunc/reverse>.
518
519     $reversed = reverse $string;
520
521 =head2 How do I expand tabs in a string?
522
523 You can do it yourself:
524
525     1 while $string =~ s/\t+/' ' x (length($&) * 8 - length($`) % 8)/e;
526
527 Or you can just use the Text::Tabs module (part of the standard Perl
528 distribution).
529
530     use Text::Tabs;
531     @expanded_lines = expand(@lines_with_tabs);
532
533 =head2 How do I reformat a paragraph?
534
535 Use Text::Wrap (part of the standard Perl distribution):
536
537     use Text::Wrap;
538     print wrap("\t", '  ', @paragraphs);
539
540 The paragraphs you give to Text::Wrap should not contain embedded
541 newlines.  Text::Wrap doesn't justify the lines (flush-right).
542
543 =head2 How can I access/change the first N letters of a string?
544
545 There are many ways.  If you just want to grab a copy, use
546 substr():
547
548     $first_byte = substr($a, 0, 1);
549
550 If you want to modify part of a string, the simplest way is often to
551 use substr() as an lvalue:
552
553     substr($a, 0, 3) = "Tom";
554
555 Although those with a pattern matching kind of thought process will
556 likely prefer
557
558     $a =~ s/^.../Tom/;
559
560 =head2 How do I change the Nth occurrence of something?
561
562 You have to keep track of N yourself.  For example, let's say you want
563 to change the fifth occurrence of C<"whoever"> or C<"whomever"> into
564 C<"whosoever"> or C<"whomsoever">, case insensitively.  These
565 all assume that $_ contains the string to be altered.
566
567     $count = 0;
568     s{((whom?)ever)}{
569         ++$count == 5           # is it the 5th?
570             ? "${2}soever"      # yes, swap
571             : $1                # renege and leave it there
572     }ige;
573
574 In the more general case, you can use the C</g> modifier in a C<while>
575 loop, keeping count of matches.
576
577     $WANT = 3;
578     $count = 0;
579     $_ = "One fish two fish red fish blue fish";
580     while (/(\w+)\s+fish\b/gi) {
581         if (++$count == $WANT) {
582             print "The third fish is a $1 one.\n";
583         }
584     }
585
586 That prints out: C<"The third fish is a red one.">  You can also use a
587 repetition count and repeated pattern like this:
588
589     /(?:\w+\s+fish\s+){2}(\w+)\s+fish/i;
590
591 =head2 How can I count the number of occurrences of a substring within a string?
592
593 There are a number of ways, with varying efficiency.  If you want a
594 count of a certain single character (X) within a string, you can use the
595 C<tr///> function like so:
596
597     $string = "ThisXlineXhasXsomeXx'sXinXit";
598     $count = ($string =~ tr/X//);
599     print "There are $count X characters in the string";
600
601 This is fine if you are just looking for a single character.  However,
602 if you are trying to count multiple character substrings within a
603 larger string, C<tr///> won't work.  What you can do is wrap a while()
604 loop around a global pattern match.  For example, let's count negative
605 integers:
606
607     $string = "-9 55 48 -2 23 -76 4 14 -44";
608     while ($string =~ /-\d+/g) { $count++ }
609     print "There are $count negative numbers in the string";
610
611 =head2 How do I capitalize all the words on one line?
612
613 To make the first letter of each word upper case:
614
615         $line =~ s/\b(\w)/\U$1/g;
616
617 This has the strange effect of turning "C<don't do it>" into "C<Don'T
618 Do It>".  Sometimes you might want this.  Other times you might need a
619 more thorough solution (Suggested by brian d.  foy):
620
621     $string =~ s/ (
622                  (^\w)    #at the beginning of the line
623                    |      # or
624                  (\s\w)   #preceded by whitespace
625                    )
626                 /\U$1/xg;
627     $string =~ /([\w']+)/\u\L$1/g;
628
629 To make the whole line upper case:
630
631         $line = uc($line);
632
633 To force each word to be lower case, with the first letter upper case:
634
635         $line =~ s/(\w+)/\u\L$1/g;
636
637 You can (and probably should) enable locale awareness of those
638 characters by placing a C<use locale> pragma in your program.
639 See L<perllocale> for endless details on locales.
640
641 This is sometimes referred to as putting something into "title
642 case", but that's not quite accurate.  Consider the proper
643 capitalization of the movie I<Dr. Strangelove or: How I Learned to
644 Stop Worrying and Love the Bomb>, for example.
645
646 =head2 How can I split a [character] delimited string except when inside
647 [character]? (Comma-separated files)
648
649 Take the example case of trying to split a string that is comma-separated
650 into its different fields.  (We'll pretend you said comma-separated, not
651 comma-delimited, which is different and almost never what you mean.) You
652 can't use C<split(/,/)> because you shouldn't split if the comma is inside
653 quotes.  For example, take a data line like this:
654
655     SAR001,"","Cimetrix, Inc","Bob Smith","CAM",N,8,1,0,7,"Error, Core Dumped"
656
657 Due to the restriction of the quotes, this is a fairly complex
658 problem.  Thankfully, we have Jeffrey Friedl, author of a highly
659 recommended book on regular expressions, to handle these for us.  He
660 suggests (assuming your string is contained in $text):
661
662      @new = ();
663      push(@new, $+) while $text =~ m{
664          "([^\"\\]*(?:\\.[^\"\\]*)*)",?  # groups the phrase inside the quotes
665        | ([^,]+),?
666        | ,
667      }gx;
668      push(@new, undef) if substr($text,-1,1) eq ',';
669
670 If you want to represent quotation marks inside a
671 quotation-mark-delimited field, escape them with backslashes (eg,
672 C<"like \"this\"">.  Unescaping them is a task addressed earlier in
673 this section.
674
675 Alternatively, the Text::ParseWords module (part of the standard Perl
676 distribution) lets you say:
677
678     use Text::ParseWords;
679     @new = quotewords(",", 0, $text);
680
681 There's also a Text::CSV (Comma-Separated Values) module on CPAN.
682
683 =head2 How do I strip blank space from the beginning/end of a string?
684
685 Although the simplest approach would seem to be
686
687     $string =~ s/^\s*(.*?)\s*$/$1/;
688
689 not only is this unnecessarily slow and destructive, it also fails with
690 embedded newlines.  It is much faster to do this operation in two steps:
691
692     $string =~ s/^\s+//;
693     $string =~ s/\s+$//;
694
695 Or more nicely written as:
696
697     for ($string) {
698         s/^\s+//;
699         s/\s+$//;
700     }
701
702 This idiom takes advantage of the C<foreach> loop's aliasing
703 behavior to factor out common code.  You can do this
704 on several strings at once, or arrays, or even the 
705 values of a hash if you use a slice:
706
707     # trim whitespace in the scalar, the array, 
708     # and all the values in the hash
709     foreach ($scalar, @array, @hash{keys %hash}) {
710         s/^\s+//;
711         s/\s+$//;
712     }
713
714 =head2 How do I pad a string with blanks or pad a number with zeroes?
715
716 (This answer contributed by Uri Guttman, with kibitzing from
717 Bart Lateur.) 
718
719 In the following examples, C<$pad_len> is the length to which you wish
720 to pad the string, C<$text> or C<$num> contains the string to be padded,
721 and C<$pad_char> contains the padding character. You can use a single
722 character string constant instead of the C<$pad_char> variable if you
723 know what it is in advance. And in the same way you can use an integer in
724 place of C<$pad_len> if you know the pad length in advance.
725
726 The simplest method uses the C<sprintf> function. It can pad on the left
727 or right with blanks and on the left with zeroes and it will not
728 truncate the result. The C<pack> function can only pad strings on the
729 right with blanks and it will truncate the result to a maximum length of
730 C<$pad_len>.
731
732     # Left padding a string with blanks (no truncation):
733     $padded = sprintf("%${pad_len}s", $text);
734
735     # Right padding a string with blanks (no truncation):
736     $padded = sprintf("%-${pad_len}s", $text);
737
738     # Left padding a number with 0 (no truncation): 
739     $padded = sprintf("%0${pad_len}d", $num);
740
741     # Right padding a string with blanks using pack (will truncate):
742     $padded = pack("A$pad_len",$text);
743
744 If you need to pad with a character other than blank or zero you can use
745 one of the following methods.  They all generate a pad string with the
746 C<x> operator and combine that with C<$text>. These methods do
747 not truncate C<$text>.
748
749 Left and right padding with any character, creating a new string:
750
751     $padded = $pad_char x ( $pad_len - length( $text ) ) . $text;
752     $padded = $text . $pad_char x ( $pad_len - length( $text ) );
753
754 Left and right padding with any character, modifying C<$text> directly:
755
756     substr( $text, 0, 0 ) = $pad_char x ( $pad_len - length( $text ) );
757     $text .= $pad_char x ( $pad_len - length( $text ) );
758
759 =head2 How do I extract selected columns from a string?
760
761 Use substr() or unpack(), both documented in L<perlfunc>.
762 If you prefer thinking in terms of columns instead of widths, 
763 you can use this kind of thing:
764
765     # determine the unpack format needed to split Linux ps output
766     # arguments are cut columns
767     my $fmt = cut2fmt(8, 14, 20, 26, 30, 34, 41, 47, 59, 63, 67, 72);
768
769     sub cut2fmt { 
770         my(@positions) = @_;
771         my $template  = '';
772         my $lastpos   = 1;
773         for my $place (@positions) {
774             $template .= "A" . ($place - $lastpos) . " "; 
775             $lastpos   = $place;
776         }
777         $template .= "A*";
778         return $template;
779     }
780
781 =head2 How do I find the soundex value of a string?
782
783 Use the standard Text::Soundex module distributed with Perl.
784 Before you do so, you may want to determine whether `soundex' is in
785 fact what you think it is.  Knuth's soundex algorithm compresses words
786 into a small space, and so it does not necessarily distinguish between
787 two words which you might want to appear separately.  For example, the
788 last names `Knuth' and `Kant' are both mapped to the soundex code K530.
789 If Text::Soundex does not do what you are looking for, you might want
790 to consider the String::Approx module available at CPAN.
791
792 =head2 How can I expand variables in text strings?
793
794 Let's assume that you have a string like:
795
796     $text = 'this has a $foo in it and a $bar';
797
798 If those were both global variables, then this would
799 suffice:
800
801     $text =~ s/\$(\w+)/${$1}/g;  # no /e needed
802
803 But since they are probably lexicals, or at least, they could
804 be, you'd have to do this:
805
806     $text =~ s/(\$\w+)/$1/eeg;
807     die if $@;                  # needed /ee, not /e
808
809 It's probably better in the general case to treat those
810 variables as entries in some special hash.  For example:
811
812     %user_defs = ( 
813         foo  => 23,
814         bar  => 19,
815     );
816     $text =~ s/\$(\w+)/$user_defs{$1}/g;
817
818 See also ``How do I expand function calls in a string?'' in this section
819 of the FAQ.
820
821 =head2 What's wrong with always quoting "$vars"?
822
823 The problem is that those double-quotes force stringification--
824 coercing numbers and references into strings--even when you
825 don't want them to be strings.  Think of it this way: double-quote
826 expansion is used to produce new strings.  If you already 
827 have a string, why do you need more?
828
829 If you get used to writing odd things like these:
830
831     print "$var";       # BAD
832     $new = "$old";      # BAD
833     somefunc("$var");   # BAD
834
835 You'll be in trouble.  Those should (in 99.8% of the cases) be
836 the simpler and more direct:
837
838     print $var;
839     $new = $old;
840     somefunc($var);
841
842 Otherwise, besides slowing you down, you're going to break code when
843 the thing in the scalar is actually neither a string nor a number, but
844 a reference:
845
846     func(\@array);
847     sub func {
848         my $aref = shift;
849         my $oref = "$aref";  # WRONG
850     }
851
852 You can also get into subtle problems on those few operations in Perl
853 that actually do care about the difference between a string and a
854 number, such as the magical C<++> autoincrement operator or the
855 syscall() function.
856
857 Stringification also destroys arrays.  
858
859     @lines = `command`;
860     print "@lines";             # WRONG - extra blanks
861     print @lines;               # right
862
863 =head2 Why don't my <<HERE documents work?
864
865 Check for these three things:
866
867 =over 4
868
869 =item 1. There must be no space after the << part.
870
871 =item 2. There (probably) should be a semicolon at the end.
872
873 =item 3. You can't (easily) have any space in front of the tag.
874
875 =back
876
877 If you want to indent the text in the here document, you 
878 can do this:
879
880     # all in one
881     ($VAR = <<HERE_TARGET) =~ s/^\s+//gm;
882         your text
883         goes here
884     HERE_TARGET
885
886 But the HERE_TARGET must still be flush against the margin.
887 If you want that indented also, you'll have to quote 
888 in the indentation.
889
890     ($quote = <<'    FINIS') =~ s/^\s+//gm;
891             ...we will have peace, when you and all your works have
892             perished--and the works of your dark master to whom you
893             would deliver us. You are a liar, Saruman, and a corrupter
894             of men's hearts.  --Theoden in /usr/src/perl/taint.c
895         FINIS
896     $quote =~ s/\s*--/\n--/;
897
898 A nice general-purpose fixer-upper function for indented here documents
899 follows.  It expects to be called with a here document as its argument.
900 It looks to see whether each line begins with a common substring, and
901 if so, strips that substring off.  Otherwise, it takes the amount of leading
902 whitespace found on the first line and removes that much off each
903 subsequent line.
904
905     sub fix {
906         local $_ = shift;
907         my ($white, $leader);  # common whitespace and common leading string
908         if (/^\s*(?:([^\w\s]+)(\s*).*\n)(?:\s*\1\2?.*\n)+$/) {
909             ($white, $leader) = ($2, quotemeta($1));
910         } else {
911             ($white, $leader) = (/^(\s+)/, '');
912         }
913         s/^\s*?$leader(?:$white)?//gm;
914         return $_;
915     }
916
917 This works with leading special strings, dynamically determined:
918
919     $remember_the_main = fix<<'    MAIN_INTERPRETER_LOOP';
920         @@@ int
921         @@@ runops() {
922         @@@     SAVEI32(runlevel);
923         @@@     runlevel++;
924         @@@     while ( op = (*op->op_ppaddr)() );
925         @@@     TAINT_NOT;
926         @@@     return 0;
927         @@@ }
928     MAIN_INTERPRETER_LOOP
929
930 Or with a fixed amount of leading whitespace, with remaining
931 indentation correctly preserved:
932
933     $poem = fix<<EVER_ON_AND_ON;
934        Now far ahead the Road has gone,
935           And I must follow, if I can,
936        Pursuing it with eager feet,
937           Until it joins some larger way
938        Where many paths and errands meet.
939           And whither then? I cannot say.
940                 --Bilbo in /usr/src/perl/pp_ctl.c
941     EVER_ON_AND_ON
942
943 =head1 Data: Arrays
944
945 =head2 What is the difference between a list and an array?
946
947 An array has a changeable length.  A list does not.  An array is something
948 you can push or pop, while a list is a set of values.  Some people make
949 the distinction that a list is a value while an array is a variable.
950 Subroutines are passed and return lists, you put things into list
951 context, you initialize arrays with lists, and you foreach() across
952 a list.  C<@> variables are arrays, anonymous arrays are arrays, arrays
953 in scalar context behave like the number of elements in them, subroutines
954 access their arguments through the array C<@_>, and push/pop/shift only work
955 on arrays.
956
957 As a side note, there's no such thing as a list in scalar context.
958 When you say
959
960     $scalar = (2, 5, 7, 9);
961
962 you're using the comma operator in scalar context, so it uses the scalar
963 comma operator.  There never was a list there at all!  This causes the
964 last value to be returned: 9.
965
966 =head2 What is the difference between $array[1] and @array[1]?
967
968 The former is a scalar value; the latter an array slice, making
969 it a list with one (scalar) value.  You should use $ when you want a
970 scalar value (most of the time) and @ when you want a list with one
971 scalar value in it (very, very rarely; nearly never, in fact).
972
973 Sometimes it doesn't make a difference, but sometimes it does.
974 For example, compare:
975
976     $good[0] = `some program that outputs several lines`;
977
978 with
979
980     @bad[0]  = `same program that outputs several lines`;
981
982 The C<use warnings> pragma and the B<-w> flag will warn you about these 
983 matters.
984
985 =head2 How can I remove duplicate elements from a list or array?
986
987 There are several possible ways, depending on whether the array is
988 ordered and whether you wish to preserve the ordering.
989
990 =over 4
991
992 =item a)
993
994 If @in is sorted, and you want @out to be sorted:
995 (this assumes all true values in the array)
996
997     $prev = "not equal to $in[0]";
998     @out = grep($_ ne $prev && ($prev = $_, 1), @in);
999
1000 This is nice in that it doesn't use much extra memory, simulating
1001 uniq(1)'s behavior of removing only adjacent duplicates.  The ", 1"
1002 guarantees that the expression is true (so that grep picks it up)
1003 even if the $_ is 0, "", or undef.
1004
1005 =item b)
1006
1007 If you don't know whether @in is sorted:
1008
1009     undef %saw;
1010     @out = grep(!$saw{$_}++, @in);
1011
1012 =item c)
1013
1014 Like (b), but @in contains only small integers:
1015
1016     @out = grep(!$saw[$_]++, @in);
1017
1018 =item d)
1019
1020 A way to do (b) without any loops or greps:
1021
1022     undef %saw;
1023     @saw{@in} = ();
1024     @out = sort keys %saw;  # remove sort if undesired
1025
1026 =item e)
1027
1028 Like (d), but @in contains only small positive integers:
1029
1030     undef @ary;
1031     @ary[@in] = @in;
1032     @out = grep {defined} @ary;
1033
1034 =back
1035
1036 But perhaps you should have been using a hash all along, eh?
1037
1038 =head2 How can I tell whether a certain element is contained in a list or array?
1039
1040 Hearing the word "in" is an I<in>dication that you probably should have
1041 used a hash, not a list or array, to store your data.  Hashes are
1042 designed to answer this question quickly and efficiently.  Arrays aren't.
1043
1044 That being said, there are several ways to approach this.  If you
1045 are going to make this query many times over arbitrary string values,
1046 the fastest way is probably to invert the original array and keep an
1047 associative array lying about whose keys are the first array's values.
1048
1049     @blues = qw/azure cerulean teal turquoise lapis-lazuli/;
1050     undef %is_blue;
1051     for (@blues) { $is_blue{$_} = 1 }
1052
1053 Now you can check whether $is_blue{$some_color}.  It might have been a
1054 good idea to keep the blues all in a hash in the first place.
1055
1056 If the values are all small integers, you could use a simple indexed
1057 array.  This kind of an array will take up less space:
1058
1059     @primes = (2, 3, 5, 7, 11, 13, 17, 19, 23, 29, 31);
1060     undef @is_tiny_prime;
1061     for (@primes) { $is_tiny_prime[$_] = 1 }
1062     # or simply  @istiny_prime[@primes] = (1) x @primes;
1063
1064 Now you check whether $is_tiny_prime[$some_number].
1065
1066 If the values in question are integers instead of strings, you can save
1067 quite a lot of space by using bit strings instead:
1068
1069     @articles = ( 1..10, 150..2000, 2017 );
1070     undef $read;
1071     for (@articles) { vec($read,$_,1) = 1 }
1072
1073 Now check whether C<vec($read,$n,1)> is true for some C<$n>.
1074
1075 Please do not use
1076
1077     ($is_there) = grep $_ eq $whatever, @array;
1078
1079 or worse yet
1080
1081     ($is_there) = grep /$whatever/, @array;
1082
1083 These are slow (checks every element even if the first matches),
1084 inefficient (same reason), and potentially buggy (what if there are
1085 regex characters in $whatever?).  If you're only testing once, then
1086 use:
1087
1088     $is_there = 0;
1089     foreach $elt (@array) {
1090         if ($elt eq $elt_to_find) {
1091             $is_there = 1;
1092             last;
1093         }
1094     }
1095     if ($is_there) { ... }
1096
1097 =head2 How do I compute the difference of two arrays?  How do I compute the intersection of two arrays?
1098
1099 Use a hash.  Here's code to do both and more.  It assumes that
1100 each element is unique in a given array:
1101
1102     @union = @intersection = @difference = ();
1103     %count = ();
1104     foreach $element (@array1, @array2) { $count{$element}++ }
1105     foreach $element (keys %count) {
1106         push @union, $element;
1107         push @{ $count{$element} > 1 ? \@intersection : \@difference }, $element;
1108     }
1109
1110 Note that this is the I<symmetric difference>, that is, all elements in
1111 either A or in B but not in both.  Think of it as an xor operation.
1112
1113 =head2 How do I test whether two arrays or hashes are equal?
1114
1115 The following code works for single-level arrays.  It uses a stringwise
1116 comparison, and does not distinguish defined versus undefined empty
1117 strings.  Modify if you have other needs.
1118
1119     $are_equal = compare_arrays(\@frogs, \@toads);
1120
1121     sub compare_arrays {
1122         my ($first, $second) = @_;
1123         no warnings;  # silence spurious -w undef complaints
1124         return 0 unless @$first == @$second;
1125         for (my $i = 0; $i < @$first; $i++) {
1126             return 0 if $first->[$i] ne $second->[$i];
1127         }
1128         return 1;
1129     }
1130
1131 For multilevel structures, you may wish to use an approach more
1132 like this one.  It uses the CPAN module FreezeThaw:
1133
1134     use FreezeThaw qw(cmpStr);
1135     @a = @b = ( "this", "that", [ "more", "stuff" ] );
1136
1137     printf "a and b contain %s arrays\n",
1138         cmpStr(\@a, \@b) == 0 
1139             ? "the same" 
1140             : "different";
1141
1142 This approach also works for comparing hashes.  Here
1143 we'll demonstrate two different answers:
1144
1145     use FreezeThaw qw(cmpStr cmpStrHard);
1146
1147     %a = %b = ( "this" => "that", "extra" => [ "more", "stuff" ] );
1148     $a{EXTRA} = \%b;
1149     $b{EXTRA} = \%a;                    
1150
1151     printf "a and b contain %s hashes\n",
1152         cmpStr(\%a, \%b) == 0 ? "the same" : "different";
1153
1154     printf "a and b contain %s hashes\n",
1155         cmpStrHard(\%a, \%b) == 0 ? "the same" : "different";
1156
1157
1158 The first reports that both those the hashes contain the same data,
1159 while the second reports that they do not.  Which you prefer is left as
1160 an exercise to the reader.
1161
1162 =head2 How do I find the first array element for which a condition is true?
1163
1164 You can use this if you care about the index:
1165
1166     for ($i= 0; $i < @array; $i++) {
1167         if ($array[$i] eq "Waldo") {
1168             $found_index = $i;
1169             last;
1170         }
1171     }
1172
1173 Now C<$found_index> has what you want.
1174
1175 =head2 How do I handle linked lists?
1176
1177 In general, you usually don't need a linked list in Perl, since with
1178 regular arrays, you can push and pop or shift and unshift at either end,
1179 or you can use splice to add and/or remove arbitrary number of elements at
1180 arbitrary points.  Both pop and shift are both O(1) operations on Perl's
1181 dynamic arrays.  In the absence of shifts and pops, push in general
1182 needs to reallocate on the order every log(N) times, and unshift will
1183 need to copy pointers each time.
1184
1185 If you really, really wanted, you could use structures as described in
1186 L<perldsc> or L<perltoot> and do just what the algorithm book tells you
1187 to do.  For example, imagine a list node like this:
1188
1189     $node = {
1190         VALUE => 42,
1191         LINK  => undef,
1192     };
1193
1194 You could walk the list this way:
1195
1196     print "List: ";
1197     for ($node = $head;  $node; $node = $node->{LINK}) {
1198         print $node->{VALUE}, " ";
1199     }
1200     print "\n";
1201
1202 You could add to the list this way:
1203
1204     my ($head, $tail);
1205     $tail = append($head, 1);       # grow a new head
1206     for $value ( 2 .. 10 ) {
1207         $tail = append($tail, $value);
1208     }
1209
1210     sub append {
1211         my($list, $value) = @_;
1212         my $node = { VALUE => $value };
1213         if ($list) {
1214             $node->{LINK} = $list->{LINK};
1215             $list->{LINK} = $node;
1216         } else {
1217             $_[0] = $node;      # replace caller's version
1218         }
1219         return $node;
1220     }
1221
1222 But again, Perl's built-in are virtually always good enough.
1223
1224 =head2 How do I handle circular lists?
1225
1226 Circular lists could be handled in the traditional fashion with linked
1227 lists, or you could just do something like this with an array:
1228
1229     unshift(@array, pop(@array));  # the last shall be first
1230     push(@array, shift(@array));   # and vice versa
1231
1232 =head2 How do I shuffle an array randomly?
1233
1234 Use this:
1235
1236     # fisher_yates_shuffle( \@array ) : 
1237     # generate a random permutation of @array in place
1238     sub fisher_yates_shuffle {
1239         my $array = shift;
1240         my $i;
1241         for ($i = @$array; --$i; ) {
1242             my $j = int rand ($i+1);
1243             @$array[$i,$j] = @$array[$j,$i];
1244         }
1245     }
1246
1247     fisher_yates_shuffle( \@array );    # permutes @array in place
1248
1249 You've probably seen shuffling algorithms that work using splice,
1250 randomly picking another element to swap the current element with
1251
1252     srand;
1253     @new = ();
1254     @old = 1 .. 10;  # just a demo
1255     while (@old) {
1256         push(@new, splice(@old, rand @old, 1));
1257     }
1258
1259 This is bad because splice is already O(N), and since you do it N times,
1260 you just invented a quadratic algorithm; that is, O(N**2).  This does
1261 not scale, although Perl is so efficient that you probably won't notice
1262 this until you have rather largish arrays.
1263
1264 =head2 How do I process/modify each element of an array?
1265
1266 Use C<for>/C<foreach>:
1267
1268     for (@lines) {
1269         s/foo/bar/;     # change that word
1270         y/XZ/ZX/;       # swap those letters
1271     }
1272
1273 Here's another; let's compute spherical volumes:
1274
1275     for (@volumes = @radii) {   # @volumes has changed parts
1276         $_ **= 3;
1277         $_ *= (4/3) * 3.14159;  # this will be constant folded
1278     }
1279
1280 If you want to do the same thing to modify the values of the hash,
1281 you may not use the C<values> function, oddly enough.  You need a slice:
1282
1283     for $orbit ( @orbits{keys %orbits} ) {
1284         ($orbit **= 3) *= (4/3) * 3.14159; 
1285     }
1286
1287 =head2 How do I select a random element from an array?
1288
1289 Use the rand() function (see L<perlfunc/rand>):
1290
1291     # at the top of the program:
1292     srand;                      # not needed for 5.004 and later
1293
1294     # then later on
1295     $index   = rand @array;
1296     $element = $array[$index];
1297
1298 Make sure you I<only call srand once per program, if then>.
1299 If you are calling it more than once (such as before each 
1300 call to rand), you're almost certainly doing something wrong.
1301
1302 =head2 How do I permute N elements of a list?
1303
1304 Here's a little program that generates all permutations
1305 of all the words on each line of input.  The algorithm embodied
1306 in the permute() function should work on any list:
1307
1308     #!/usr/bin/perl -n
1309     # tsc-permute: permute each word of input
1310     permute([split], []);
1311     sub permute {
1312         my @items = @{ $_[0] };
1313         my @perms = @{ $_[1] };
1314         unless (@items) {
1315             print "@perms\n";
1316         } else {
1317             my(@newitems,@newperms,$i);
1318             foreach $i (0 .. $#items) {
1319                 @newitems = @items;
1320                 @newperms = @perms;
1321                 unshift(@newperms, splice(@newitems, $i, 1));
1322                 permute([@newitems], [@newperms]);
1323             }
1324         }
1325     }
1326
1327 =head2 How do I sort an array by (anything)?
1328
1329 Supply a comparison function to sort() (described in L<perlfunc/sort>):
1330
1331     @list = sort { $a <=> $b } @list;
1332
1333 The default sort function is cmp, string comparison, which would
1334 sort C<(1, 2, 10)> into C<(1, 10, 2)>.  C<< <=> >>, used above, is
1335 the numerical comparison operator.
1336
1337 If you have a complicated function needed to pull out the part you
1338 want to sort on, then don't do it inside the sort function.  Pull it
1339 out first, because the sort BLOCK can be called many times for the
1340 same element.  Here's an example of how to pull out the first word
1341 after the first number on each item, and then sort those words
1342 case-insensitively.
1343
1344     @idx = ();
1345     for (@data) {
1346         ($item) = /\d+\s*(\S+)/;
1347         push @idx, uc($item);
1348     }
1349     @sorted = @data[ sort { $idx[$a] cmp $idx[$b] } 0 .. $#idx ];
1350
1351 which could also be written this way, using a trick
1352 that's come to be known as the Schwartzian Transform:
1353
1354     @sorted = map  { $_->[0] }
1355               sort { $a->[1] cmp $b->[1] }
1356               map  { [ $_, uc( (/\d+\s*(\S+)/)[0]) ] } @data;
1357
1358 If you need to sort on several fields, the following paradigm is useful.
1359
1360     @sorted = sort { field1($a) <=> field1($b) ||
1361                      field2($a) cmp field2($b) ||
1362                      field3($a) cmp field3($b)
1363                    }     @data;
1364
1365 This can be conveniently combined with precalculation of keys as given
1366 above.
1367
1368 See http://www.perl.com/CPAN/doc/FMTEYEWTK/sort.html for more about
1369 this approach.
1370
1371 See also the question below on sorting hashes.
1372
1373 =head2 How do I manipulate arrays of bits?
1374
1375 Use pack() and unpack(), or else vec() and the bitwise operations.
1376
1377 For example, this sets $vec to have bit N set if $ints[N] was set:
1378
1379     $vec = '';
1380     foreach(@ints) { vec($vec,$_,1) = 1 }
1381
1382 And here's how, given a vector in $vec, you can
1383 get those bits into your @ints array:
1384
1385     sub bitvec_to_list {
1386         my $vec = shift;
1387         my @ints;
1388         # Find null-byte density then select best algorithm
1389         if ($vec =~ tr/\0// / length $vec > 0.95) {
1390             use integer;
1391             my $i;
1392             # This method is faster with mostly null-bytes
1393             while($vec =~ /[^\0]/g ) {
1394                 $i = -9 + 8 * pos $vec;
1395                 push @ints, $i if vec($vec, ++$i, 1);
1396                 push @ints, $i if vec($vec, ++$i, 1);
1397                 push @ints, $i if vec($vec, ++$i, 1);
1398                 push @ints, $i if vec($vec, ++$i, 1);
1399                 push @ints, $i if vec($vec, ++$i, 1);
1400                 push @ints, $i if vec($vec, ++$i, 1);
1401                 push @ints, $i if vec($vec, ++$i, 1);
1402                 push @ints, $i if vec($vec, ++$i, 1);
1403             }
1404         } else {
1405             # This method is a fast general algorithm
1406             use integer;
1407             my $bits = unpack "b*", $vec;
1408             push @ints, 0 if $bits =~ s/^(\d)// && $1;
1409             push @ints, pos $bits while($bits =~ /1/g);
1410         }
1411         return \@ints;
1412     }
1413
1414 This method gets faster the more sparse the bit vector is.
1415 (Courtesy of Tim Bunce and Winfried Koenig.)
1416
1417 Here's a demo on how to use vec():
1418
1419     # vec demo
1420     $vector = "\xff\x0f\xef\xfe";
1421     print "Ilya's string \\xff\\x0f\\xef\\xfe represents the number ", 
1422         unpack("N", $vector), "\n";
1423     $is_set = vec($vector, 23, 1);
1424     print "Its 23rd bit is ", $is_set ? "set" : "clear", ".\n";
1425     pvec($vector);
1426
1427     set_vec(1,1,1);
1428     set_vec(3,1,1);
1429     set_vec(23,1,1);
1430
1431     set_vec(3,1,3);
1432     set_vec(3,2,3);
1433     set_vec(3,4,3);
1434     set_vec(3,4,7);
1435     set_vec(3,8,3);
1436     set_vec(3,8,7);
1437
1438     set_vec(0,32,17);
1439     set_vec(1,32,17);
1440
1441     sub set_vec { 
1442         my ($offset, $width, $value) = @_;
1443         my $vector = '';
1444         vec($vector, $offset, $width) = $value;
1445         print "offset=$offset width=$width value=$value\n";
1446         pvec($vector);
1447     }
1448
1449     sub pvec {
1450         my $vector = shift;
1451         my $bits = unpack("b*", $vector);
1452         my $i = 0;
1453         my $BASE = 8;
1454
1455         print "vector length in bytes: ", length($vector), "\n";
1456         @bytes = unpack("A8" x length($vector), $bits);
1457         print "bits are: @bytes\n\n";
1458     } 
1459
1460 =head2 Why does defined() return true on empty arrays and hashes?
1461
1462 The short story is that you should probably only use defined on scalars or
1463 functions, not on aggregates (arrays and hashes).  See L<perlfunc/defined>
1464 in the 5.004 release or later of Perl for more detail.
1465
1466 =head1 Data: Hashes (Associative Arrays)
1467
1468 =head2 How do I process an entire hash?
1469
1470 Use the each() function (see L<perlfunc/each>) if you don't care
1471 whether it's sorted:
1472
1473     while ( ($key, $value) = each %hash) {
1474         print "$key = $value\n";
1475     }
1476
1477 If you want it sorted, you'll have to use foreach() on the result of
1478 sorting the keys as shown in an earlier question.
1479
1480 =head2 What happens if I add or remove keys from a hash while iterating over it?
1481
1482 Don't do that. :-)
1483
1484 [lwall] In Perl 4, you were not allowed to modify a hash at all while
1485 iterating over it.  In Perl 5 you can delete from it, but you still
1486 can't add to it, because that might cause a doubling of the hash table,
1487 in which half the entries get copied up to the new top half of the
1488 table, at which point you've totally bamboozled the iterator code.
1489 Even if the table doesn't double, there's no telling whether your new
1490 entry will be inserted before or after the current iterator position.
1491
1492 Either treasure up your changes and make them after the iterator finishes
1493 or use keys to fetch all the old keys at once, and iterate over the list
1494 of keys.
1495
1496 =head2 How do I look up a hash element by value?
1497
1498 Create a reverse hash:
1499
1500     %by_value = reverse %by_key;
1501     $key = $by_value{$value};
1502
1503 That's not particularly efficient.  It would be more space-efficient
1504 to use:
1505
1506     while (($key, $value) = each %by_key) {
1507         $by_value{$value} = $key;
1508     }
1509
1510 If your hash could have repeated values, the methods above will only find
1511 one of the associated keys.   This may or may not worry you.  If it does
1512 worry you, you can always reverse the hash into a hash of arrays instead:
1513
1514      while (($key, $value) = each %by_key) {
1515          push @{$key_list_by_value{$value}}, $key;
1516      }
1517
1518 =head2 How can I know how many entries are in a hash?
1519
1520 If you mean how many keys, then all you have to do is
1521 take the scalar sense of the keys() function:
1522
1523     $num_keys = scalar keys %hash;
1524
1525 The keys() function also resets the iterator, which in void context is
1526 faster for tied hashes than would be iterating through the whole 
1527 hash, one key-value pair at a time.
1528
1529 =head2 How do I sort a hash (optionally by value instead of key)?
1530
1531 Internally, hashes are stored in a way that prevents you from imposing
1532 an order on key-value pairs.  Instead, you have to sort a list of the
1533 keys or values:
1534
1535     @keys = sort keys %hash;    # sorted by key
1536     @keys = sort {
1537                     $hash{$a} cmp $hash{$b}
1538             } keys %hash;       # and by value
1539
1540 Here we'll do a reverse numeric sort by value, and if two keys are
1541 identical, sort by length of key, or if that fails, by straight ASCII
1542 comparison of the keys (well, possibly modified by your locale--see
1543 L<perllocale>).
1544
1545     @keys = sort {
1546                 $hash{$b} <=> $hash{$a}
1547                           ||
1548                 length($b) <=> length($a)
1549                           ||
1550                       $a cmp $b
1551     } keys %hash;
1552
1553 =head2 How can I always keep my hash sorted?
1554
1555 You can look into using the DB_File module and tie() using the
1556 $DB_BTREE hash bindings as documented in L<DB_File/"In Memory Databases">.
1557 The Tie::IxHash module from CPAN might also be instructive.
1558
1559 =head2 What's the difference between "delete" and "undef" with hashes?
1560
1561 Hashes are pairs of scalars: the first is the key, the second is the
1562 value.  The key will be coerced to a string, although the value can be
1563 any kind of scalar: string, number, or reference.  If a key C<$key> is
1564 present in the array, C<exists($key)> will return true.  The value for
1565 a given key can be C<undef>, in which case C<$array{$key}> will be
1566 C<undef> while C<$exists{$key}> will return true.  This corresponds to
1567 (C<$key>, C<undef>) being in the hash.
1568
1569 Pictures help...  here's the C<%ary> table:
1570
1571           keys  values
1572         +------+------+
1573         |  a   |  3   |
1574         |  x   |  7   |
1575         |  d   |  0   |
1576         |  e   |  2   |
1577         +------+------+
1578
1579 And these conditions hold
1580
1581         $ary{'a'}                       is true
1582         $ary{'d'}                       is false
1583         defined $ary{'d'}               is true
1584         defined $ary{'a'}               is true
1585         exists $ary{'a'}                is true (Perl5 only)
1586         grep ($_ eq 'a', keys %ary)     is true
1587
1588 If you now say
1589
1590         undef $ary{'a'}
1591
1592 your table now reads:
1593
1594
1595           keys  values
1596         +------+------+
1597         |  a   | undef|
1598         |  x   |  7   |
1599         |  d   |  0   |
1600         |  e   |  2   |
1601         +------+------+
1602
1603 and these conditions now hold; changes in caps:
1604
1605         $ary{'a'}                       is FALSE
1606         $ary{'d'}                       is false
1607         defined $ary{'d'}               is true
1608         defined $ary{'a'}               is FALSE
1609         exists $ary{'a'}                is true (Perl5 only)
1610         grep ($_ eq 'a', keys %ary)     is true
1611
1612 Notice the last two: you have an undef value, but a defined key!
1613
1614 Now, consider this:
1615
1616         delete $ary{'a'}
1617
1618 your table now reads:
1619
1620           keys  values
1621         +------+------+
1622         |  x   |  7   |
1623         |  d   |  0   |
1624         |  e   |  2   |
1625         +------+------+
1626
1627 and these conditions now hold; changes in caps:
1628
1629         $ary{'a'}                       is false
1630         $ary{'d'}                       is false
1631         defined $ary{'d'}               is true
1632         defined $ary{'a'}               is false
1633         exists $ary{'a'}                is FALSE (Perl5 only)
1634         grep ($_ eq 'a', keys %ary)     is FALSE
1635
1636 See, the whole entry is gone!
1637
1638 =head2 Why don't my tied hashes make the defined/exists distinction?
1639
1640 They may or may not implement the EXISTS() and DEFINED() methods
1641 differently.  For example, there isn't the concept of undef with hashes
1642 that are tied to DBM* files. This means the true/false tables above
1643 will give different results when used on such a hash.  It also means
1644 that exists and defined do the same thing with a DBM* file, and what
1645 they end up doing is not what they do with ordinary hashes.
1646
1647 =head2 How do I reset an each() operation part-way through?
1648
1649 Using C<keys %hash> in scalar context returns the number of keys in
1650 the hash I<and> resets the iterator associated with the hash.  You may
1651 need to do this if you use C<last> to exit a loop early so that when you
1652 re-enter it, the hash iterator has been reset.
1653
1654 =head2 How can I get the unique keys from two hashes?
1655
1656 First you extract the keys from the hashes into lists, then solve
1657 the "removing duplicates" problem described above.  For example:
1658
1659     %seen = ();
1660     for $element (keys(%foo), keys(%bar)) {
1661         $seen{$element}++;
1662     }
1663     @uniq = keys %seen;
1664
1665 Or more succinctly:
1666
1667     @uniq = keys %{{%foo,%bar}};
1668
1669 Or if you really want to save space:
1670
1671     %seen = ();
1672     while (defined ($key = each %foo)) {
1673         $seen{$key}++;
1674     }
1675     while (defined ($key = each %bar)) {
1676         $seen{$key}++;
1677     }
1678     @uniq = keys %seen;
1679
1680 =head2 How can I store a multidimensional array in a DBM file?
1681
1682 Either stringify the structure yourself (no fun), or else
1683 get the MLDBM (which uses Data::Dumper) module from CPAN and layer
1684 it on top of either DB_File or GDBM_File.
1685
1686 =head2 How can I make my hash remember the order I put elements into it?
1687
1688 Use the Tie::IxHash from CPAN.
1689
1690     use Tie::IxHash;
1691     tie(%myhash, Tie::IxHash);
1692     for ($i=0; $i<20; $i++) {
1693         $myhash{$i} = 2*$i;
1694     }
1695     @keys = keys %myhash;
1696     # @keys = (0,1,2,3,...)
1697
1698 =head2 Why does passing a subroutine an undefined element in a hash create it?
1699
1700 If you say something like:
1701
1702     somefunc($hash{"nonesuch key here"});
1703
1704 Then that element "autovivifies"; that is, it springs into existence
1705 whether you store something there or not.  That's because functions
1706 get scalars passed in by reference.  If somefunc() modifies C<$_[0]>,
1707 it has to be ready to write it back into the caller's version.
1708
1709 This has been fixed as of Perl5.004.
1710
1711 Normally, merely accessing a key's value for a nonexistent key does
1712 I<not> cause that key to be forever there.  This is different than
1713 awk's behavior.
1714
1715 =head2 How can I make the Perl equivalent of a C structure/C++ class/hash or array of hashes or arrays?
1716
1717 Usually a hash ref, perhaps like this:
1718
1719     $record = {
1720         NAME   => "Jason",
1721         EMPNO  => 132,
1722         TITLE  => "deputy peon",
1723         AGE    => 23,
1724         SALARY => 37_000,
1725         PALS   => [ "Norbert", "Rhys", "Phineas"],
1726     };
1727
1728 References are documented in L<perlref> and the upcoming L<perlreftut>.
1729 Examples of complex data structures are given in L<perldsc> and
1730 L<perllol>.  Examples of structures and object-oriented classes are
1731 in L<perltoot>.
1732
1733 =head2 How can I use a reference as a hash key?
1734
1735 You can't do this directly, but you could use the standard Tie::Refhash
1736 module distributed with Perl.
1737
1738 =head1 Data: Misc
1739
1740 =head2 How do I handle binary data correctly?
1741
1742 Perl is binary clean, so this shouldn't be a problem.  For example,
1743 this works fine (assuming the files are found):
1744
1745     if (`cat /vmunix` =~ /gzip/) {
1746         print "Your kernel is GNU-zip enabled!\n";
1747     }
1748
1749 On less elegant (read: Byzantine) systems, however, you have
1750 to play tedious games with "text" versus "binary" files.  See
1751 L<perlfunc/"binmode"> or L<perlopentut>.  Most of these ancient-thinking
1752 systems are curses out of Microsoft, who seem to be committed to putting
1753 the backward into backward compatibility.
1754
1755 If you're concerned about 8-bit ASCII data, then see L<perllocale>.
1756
1757 If you want to deal with multibyte characters, however, there are
1758 some gotchas.  See the section on Regular Expressions.
1759
1760 =head2 How do I determine whether a scalar is a number/whole/integer/float?
1761
1762 Assuming that you don't care about IEEE notations like "NaN" or
1763 "Infinity", you probably just want to use a regular expression.
1764
1765    if (/\D/)            { print "has nondigits\n" }
1766    if (/^\d+$/)         { print "is a whole number\n" }
1767    if (/^-?\d+$/)       { print "is an integer\n" }
1768    if (/^[+-]?\d+$/)    { print "is a +/- integer\n" }
1769    if (/^-?\d+\.?\d*$/) { print "is a real number\n" }
1770    if (/^-?(?:\d+(?:\.\d*)?|\.\d+)$/) { print "is a decimal number" }
1771    if (/^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/)
1772                         { print "a C float" }
1773
1774 If you're on a POSIX system, Perl's supports the C<POSIX::strtod>
1775 function.  Its semantics are somewhat cumbersome, so here's a C<getnum>
1776 wrapper function for more convenient access.  This function takes
1777 a string and returns the number it found, or C<undef> for input that
1778 isn't a C float.  The C<is_numeric> function is a front end to C<getnum>
1779 if you just want to say, ``Is this a float?''
1780
1781     sub getnum {
1782         use POSIX qw(strtod);
1783         my $str = shift;
1784         $str =~ s/^\s+//;
1785         $str =~ s/\s+$//;
1786         $! = 0;
1787         my($num, $unparsed) = strtod($str);
1788         if (($str eq '') || ($unparsed != 0) || $!) {
1789             return undef;
1790         } else {
1791             return $num;
1792         } 
1793     } 
1794
1795     sub is_numeric { defined getnum($_[0]) } 
1796
1797 Or you could check out the String::Scanf module on CPAN instead.  The
1798 POSIX module (part of the standard Perl distribution) provides the
1799 C<strtod> and C<strtol> for converting strings to double and longs,
1800 respectively.
1801
1802 =head2 How do I keep persistent data across program calls?
1803
1804 For some specific applications, you can use one of the DBM modules.
1805 See L<AnyDBM_File>.  More generically, you should consult the FreezeThaw,
1806 Storable, or Class::Eroot modules from CPAN.  Starting from Perl 5.8
1807 Storable is part of the standard distribution.  Here's one example using
1808 Storable's C<store> and C<retrieve> functions:
1809
1810     use Storable; 
1811     store(\%hash, "filename");
1812
1813     # later on...  
1814     $href = retrieve("filename");        # by ref
1815     %hash = %{ retrieve("filename") };   # direct to hash
1816
1817 =head2 How do I print out or copy a recursive data structure?
1818
1819 The Data::Dumper module on CPAN (or the 5.005 release of Perl) is great
1820 for printing out data structures.  The Storable module, found on CPAN,
1821 provides a function called C<dclone> that recursively copies its argument.
1822
1823     use Storable qw(dclone); 
1824     $r2 = dclone($r1);
1825
1826 Where $r1 can be a reference to any kind of data structure you'd like.
1827 It will be deeply copied.  Because C<dclone> takes and returns references,
1828 you'd have to add extra punctuation if you had a hash of arrays that
1829 you wanted to copy.
1830
1831     %newhash = %{ dclone(\%oldhash) };
1832
1833 =head2 How do I define methods for every class/object?
1834
1835 Use the UNIVERSAL class (see L<UNIVERSAL>).
1836
1837 =head2 How do I verify a credit card checksum?
1838
1839 Get the Business::CreditCard module from CPAN.
1840
1841 =head2 How do I pack arrays of doubles or floats for XS code?
1842
1843 The kgbpack.c code in the PGPLOT module on CPAN does just this.
1844 If you're doing a lot of float or double processing, consider using
1845 the PDL module from CPAN instead--it makes number-crunching easy.
1846
1847 =head1 AUTHOR AND COPYRIGHT
1848
1849 Copyright (c) 1997-1999 Tom Christiansen and Nathan Torkington.
1850 All rights reserved.
1851
1852 This documentation is free; you can redistribute it and/or modify it
1853 under the same terms as Perl itself.
1854
1855 Irrespective of its distribution, all code examples in this file
1856 are hereby placed into the public domain.  You are permitted and
1857 encouraged to use this code in your own programs for fun
1858 or for profit as you see fit.  A simple comment in the code giving
1859 credit would be courteous but is not required.