pod/perlrecharclass.pod

   1 =head1 NAME
   2 X<character class>
   3
   4 perlrecharclass - Perl Regular Expression Character Classes
   5
   6 =head1 DESCRIPTION
   7
   8 The top level documentation about Perl regular expressions
   9 is found in L<perlre>.
  10
  11 This manual page discusses the syntax and use of character
  12 classes in Perl regular expressions.
  13
  14 A character class is a way of denoting a set of characters
  15 in such a way that one character of the set is matched.
  16 It's important to remember that: matching a character class
  17 consumes exactly one character in the source string. (The source
  18 string is the string the regular expression is matched against.)
  19
  20 There are three types of character classes in Perl regular
  21 expressions: the dot, backslash sequences, and the form enclosed in square
  22 brackets.  Keep in mind, though, that often the term "character class" is used
  23 to mean just the bracketed form.  Certainly, most Perl documentation does that.
  24
  25 =head2 The dot
  26
  27 The dot (or period), C<.> is probably the most used, and certainly
  28 the most well-known character class. By default, a dot matches any
  29 character, except for the newline. The default can be changed to
  30 add matching the newline by using the I<single line> modifier: either
  31 for the entire regular expression with the C</s> modifier, or
  32 locally with C<(?s)>.  (The experimental C<\N> backslash sequence, described
  33 below, matches any character except newline without regard to the
  34 I<single line> modifier.)
  35
  36 Here are some examples:
  37
  38  "a"  =~  /./       # Match
  39  "."  =~  /./       # Match
  40  ""   =~  /./       # No match (dot has to match a character)
  41  "\n" =~  /./       # No match (dot does not match a newline)
  42  "\n" =~  /./s      # Match (global 'single line' modifier)
  43  "\n" =~  /(?s:.)/  # Match (local 'single line' modifier)
  44  "ab" =~  /^.$/     # No match (dot matches one character)
  45
  46 =head2 Backslash sequences
  47 X<\w> X<\W> X<\s> X<\S> X<\d> X<\D> X<\p> X<\P>
  48 X<\N> X<\v> X<\V> X<\h> X<\H>
  49 X<word> X<whitespace>
  50
  51 A backslash sequence is a sequence of characters, the first one of which is a
  52 backslash.  Perl ascribes special meaning to many such sequences, and some of
  53 these are character classes.  That is, they match a single character each,
  54 provided that the character belongs to the specific set of characters defined
  55 by the sequence.
  56
  57 Here's a list of the backslash sequences that are character classes.  They
  58 are discussed in more detail below.  (For the backslash sequences that aren't
  59 character classes, see L<perlrebackslash>.)
  60
  61  \d             Match a decimal digit character.
  62  \D             Match a non-decimal-digit character.
  63  \w             Match a "word" character.
  64  \W             Match a non-"word" character.
  65  \s             Match a whitespace character.
  66  \S             Match a non-whitespace character.
  67  \h             Match a horizontal whitespace character.
  68  \H             Match a character that isn't horizontal whitespace.
  69  \v             Match a vertical whitespace character.
  70  \V             Match a character that isn't vertical whitespace.
  71  \N             Match a character that isn't a newline.  Experimental.
  72  \pP, \p{Prop}  Match a character that has the given Unicode property.
  73  \PP, \P{Prop}  Match a character that doesn't have the Unicode property
  74
  75 =head3 Digits
  76
  77 C<\d> matches a single character considered to be a decimal I<digit>.
  78 What is considered a decimal digit depends on several factors, detailed
  79 below in L</Locale, EBCDIC, Unicode and UTF-8>.  If those factors
  80 indicate a Unicode interpretation, C<\d> not only matches the digits
  81 '0' - '9', but also Arabic, Devanagari, and digits from other languages.
  82 Otherwise, if a locale is in effect, it matches whatever characters that
  83 locale considers decimal digits.  Only when neither a Unicode interpretation
  84 nor locale prevails does C<\d> match only the digits '0' to '9' alone.
  85
  86 Unicode digits may cause some confusion, and some security issues.  In UTF-8
  87 strings, unless the C<"a"> regular expression modifier is specified,
  88 C<\d> matches the same characters matched by
  89 C<\p{General_Category=Decimal_Number}>, or synonymously,
  90 C<\p{General_Category=Digit}>.  Starting with Unicode version 4.1, this is the
  91 same set of characters matched by C<\p{Numeric_Type=Decimal}>.
  92
  93 But Unicode also has a different property with a similar name,
  94 C<\p{Numeric_Type=Digit}>, which matches a completely different set of
  95 characters.  These characters are things such as subscripts.
  96
  97 The design intent is for C<\d> to match all digits (and no other characters)
  98 that can be used with "normal" big-endian positional decimal syntax, whereby a
  99 sequence of such digits {N0, N1, N2, ...Nn} has the numeric value (...(N0 * 10
 100 + N1) * 10 + N2) * 10 ... + Nn).  In Unicode 5.2, the Tamil digits (U+0BE6 -
 101 U+0BEF) can also legally be used in old-style Tamil numbers in which they would
 102 appear no more than one in a row, separated by characters that mean "times 10",
 103 "times 100", etc.  (See L<http://www.unicode.org/notes/tn21>.)
 104
 105 Some non-European digits that C<\d> matches look like European ones, but
 106 have different values.  For example, BENGALI DIGIT FOUR (U+09EA) looks
 107 very much like an ASCII DIGIT EIGHT (U+0038).
 108
 109 It may be useful for security purposes for an application to require that all
 110 digits in a row be from the same script.  This can be checked by using
 111 L<Unicode::UCD/num()>.
 112
 113 Any character not matched by C<\d> is matched by C<\D>.
 114
 115 =head3 Word characters
 116
 117 A C<\w> matches a single alphanumeric character (an alphabetic character, or a
 118 decimal digit) or a connecting punctuation character, such as an
 119 underscore ("_").  It does not match a whole word.  To match a whole
 120 word, use C<\w+>.  This isn't the same thing as matching an English word, but
 121 in the ASCII range it is the same as a string of Perl-identifier
 122 characters.  What is considered a
 123 word character depends on several factors, detailed below in L</Locale,
 124 EBCDIC, Unicode and UTF-8>.  If those factors indicate a Unicode
 125 interpretation, C<\w> matches the characters considered word
 126 characters in the Unicode database. That is, it not only matches ASCII letters,
 127 but also Thai letters, Greek letters, etc.  This includes connector
 128 punctuation (like the underscore) which connect two words together, or
 129 diacritics, such as a C<COMBINING TILDE> and the modifier letters, which
 130 are generally used to add auxiliary markings to letters.   If a Unicode
 131 interpretation is not indicated, C<\w> matches those characters considered
 132 word characters by the current locale or EBCDIC code page.  Without a
 133 locale or EBCDIC code page, C<\w> matches the underscore and ASCII letters
 134 and digits.
 135
 136 There are a number of security issues with the full Unicode list of word
 137 characters.  See L<http://unicode.org/reports/tr36>.
 138
 139 Also, for a somewhat finer-grained set of characters that are in programming
 140 language identifiers beyond the ASCII range, you may wish to instead use the
 141 more customized Unicode properties, "ID_Start", ID_Continue", "XID_Start", and
 142 "XID_Continue".  See L<http://unicode.org/reports/tr31>.
 143
 144 Any character not matched by C<\w> is matched by C<\W>.
 145
 146 =head3 Whitespace
 147
 148 C<\s> matches any single character considered whitespace.  The exact
 149 set of characters matched by C<\s> depends on several factors, detailed
 150 below in L</Locale, EBCDIC, Unicode and UTF-8>.  If those factors
 151 indicate a Unicode interpretation, C<\s> matches what is considered
 152 whitespace in the Unicode database; the complete list is in the table
 153 below. Otherwise, if a locale or EBCDIC code page is in effect,
 154 C<\s> matches whatever is considered whitespace by the current locale or
 155 EBCDIC code page. Without a locale or EBCDIC code page, C<\s> matches
 156 the horizontal tab (C<\t>), the newline (C<\n>), the form feed (C<\f>),
 157 the carriage return (C<\r>), and the space.  (Note that it doesn't match
 158 the vertical tab, C<\cK>.)  Perhaps the most notable possible surprise
 159 is that C<\s> matches a non-breaking space B<only> if a Unicode
 160 interpretation is indicated, or the locale or EBCDIC code page that is
 161 in effect happens to have that character.
 162
 163 Any character not matched by C<\s> is matched by C<\S>.
 164
 165 C<\h> matches any character considered horizontal whitespace;
 166 this includes the space and tab characters and several others
 167 listed in the table below.  C<\H> matches any character
 168 not considered horizontal whitespace.
 169
 170 C<\v> matches any character considered vertical whitespace;
 171 this includes the carriage return and line feed characters (newline)
 172 plus several other characters, all listed in the table below.
 173 C<\V> matches any character not considered vertical whitespace.
 174
 175 C<\R> matches anything that can be considered a newline under Unicode
 176 rules. It's not a character class, as it can match a multi-character
 177 sequence. Therefore, it cannot be used inside a bracketed character
 178 class; use C<\v> instead (vertical whitespace).
 179 Details are discussed in L<perlrebackslash>.
 180
 181 Note that unlike C<\s>, C<\d> and C<\w>, C<\h> and C<\v> always match
 182 the same characters, without regard to other factors, such as whether the
 183 source string is in UTF-8 format.
 184
 185 One might think that C<\s> is equivalent to C<[\h\v]>. This is not true.  The
 186 vertical tab (C<"\x0b">) is not matched by C<\s>, it is however considered
 187 vertical whitespace. Furthermore, if the source string is not in UTF-8 format,
 188 and any locale or EBCDIC code page that is in effect doesn't include them, the
 189 next line (ASCII-platform C<"\x85">) and the no-break space (ASCII-platform
 190 C<"\xA0">) characters are not matched by C<\s>, but are by C<\v> and C<\h>
 191 respectively.  If the C<"a"> modifier is not in effect and the source
 192 string is in UTF-8 format, both the next line and the no-break space
 193 are matched by C<\s>.
 194
 195 The following table is a complete listing of characters matched by
 196 C<\s>, C<\h> and C<\v> as of Unicode 5.2.
 197
 198 The first column gives the code point of the character (in hex format),
 199 the second column gives the (Unicode) name. The third column indicates
 200 by which class(es) the character is matched (assuming no locale or EBCDIC code
 201 page is in effect that changes the C<\s> matching).
 202
 203  0x00009        CHARACTER TABULATION   h s
 204  0x0000a              LINE FEED (LF)    vs
 205  0x0000b             LINE TABULATION    v
 206  0x0000c              FORM FEED (FF)    vs
 207  0x0000d        CARRIAGE RETURN (CR)    vs
 208  0x00020                       SPACE   h s
 209  0x00085             NEXT LINE (NEL)    vs  [1]
 210  0x000a0              NO-BREAK SPACE   h s  [1]
 211  0x01680            OGHAM SPACE MARK   h s
 212  0x0180e   MONGOLIAN VOWEL SEPARATOR   h s
 213  0x02000                     EN QUAD   h s
 214  0x02001                     EM QUAD   h s
 215  0x02002                    EN SPACE   h s
 216  0x02003                    EM SPACE   h s
 217  0x02004          THREE-PER-EM SPACE   h s
 218  0x02005           FOUR-PER-EM SPACE   h s
 219  0x02006            SIX-PER-EM SPACE   h s
 220  0x02007                FIGURE SPACE   h s
 221  0x02008           PUNCTUATION SPACE   h s
 222  0x02009                  THIN SPACE   h s
 223  0x0200a                  HAIR SPACE   h s
 224  0x02028              LINE SEPARATOR    vs
 225  0x02029         PARAGRAPH SEPARATOR    vs
 226  0x0202f       NARROW NO-BREAK SPACE   h s
 227  0x0205f   MEDIUM MATHEMATICAL SPACE   h s
 228  0x03000           IDEOGRAPHIC SPACE   h s
 229
 230 =over 4
 231
 232 =item [1]
 233
 234 NEXT LINE and NO-BREAK SPACE only match C<\s> if the source string is in
 235 UTF-8 format and the C<"a"> modifier is not in effect, or if the locale
 236 or EBCDIC code page in effect includes them.
 237
 238 =back
 239
 240 It is worth noting that C<\d>, C<\w>, etc, match single characters, not
 241 complete numbers or words. To match a number (that consists of digits),
 242 use C<\d+>; to match a word, use C<\w+>.
 243
 244 =head3 \N
 245
 246 C<\N> is new in 5.12, and is experimental.  It, like the dot, matches any
 247 character that is not a newline. The difference is that C<\N> is not influenced
 248 by the I<single line> regular expression modifier (see L</The dot> above).  Note
 249 that the form C<\N{...}> may mean something completely different.  When the
 250 C<{...}> is a L<quantifier|perlre/Quantifiers>, it means to match a non-newline
 251 character that many times.  For example, C<\N{3}> means to match 3
 252 non-newlines; C<\N{5,}> means to match 5 or more non-newlines.  But if C<{...}>
 253 is not a legal quantifier, it is presumed to be a named character.  See
 254 L<charnames> for those.  For example, none of C<\N{COLON}>, C<\N{4F}>, and
 255 C<\N{F4}> contain legal quantifiers, so Perl will try to find characters whose
 256 names are respectively C<COLON>, C<4F>, and C<F4>.
 257
 258 =head3 Unicode Properties
 259
 260 C<\pP> and C<\p{Prop}> are character classes to match characters that fit given
 261 Unicode properties.  One letter property names can be used in the C<\pP> form,
 262 with the property name following the C<\p>, otherwise, braces are required.
 263 When using braces, there is a single form, which is just the property name
 264 enclosed in the braces, and a compound form which looks like C<\p{name=value}>,
 265 which means to match if the property "name" for the character has that particular
 266 "value".
 267 For instance, a match for a number can be written as C</\pN/> or as
 268 C</\p{Number}/>, or as C</\p{Number=True}/>.
 269 Lowercase letters are matched by the property I<Lowercase_Letter> which
 270 has as short form I<Ll>. They need the braces, so are written as C</\p{Ll}/> or
 271 C</\p{Lowercase_Letter}/>, or C</\p{General_Category=Lowercase_Letter}/>
 272 (the underscores are optional).
 273 C</\pLl/> is valid, but means something different.
 274 It matches a two character string: a letter (Unicode property C<\pL>),
 275 followed by a lowercase C<l>.
 276
 277 Note that almost all properties are immune to case-insensitive matching.
 278 That is, adding a C</i> regular expression modifier does not change what
 279 they match.  There are two sets affected.  The first set is
 280 C<Uppercase_Letter>,
 281 C<Lowercase_Letter>,
 282 and C<Titlecase_Letter>,
 283 all of which match C<Cased_Letter> under C</i> matching.
 284 The second set is
 285 C<Uppercase>,
 286 C<Lowercase>,
 287 and C<Titlecase>,
 288 all of which match C<Cased> under C</i> matching.
 289 (The difference between these sets is that some things, such as Roman
 290 Numerals, come in both upper and lower case so they are C<Cased>, but
 291 aren't considered to be letters, so they aren't C<Cased_Letter>s. They're
 292 actually C<Letter_Number>s.)
 293 This set also includes its subsets C<PosixUpper> and C<PosixLower>, both
 294 of which under C</i> matching match C<PosixAlpha>.
 295
 296 For more details on Unicode properties, see L<perlunicode/Unicode
 297 Character Properties>; for a
 298 complete list of possible properties, see
 299 L<perluniprops/Properties accessible through \p{} and \P{}>,
 300 which notes all forms that have C</i> differences.
 301 It is also possible to define your own properties. This is discussed in
 302 L<perlunicode/User-Defined Character Properties>.
 303
 304 =head4 Examples
 305
 306  "a"  =~  /\w/      # Match, "a" is a 'word' character.
 307  "7"  =~  /\w/      # Match, "7" is a 'word' character as well.
 308  "a"  =~  /\d/      # No match, "a" isn't a digit.
 309  "7"  =~  /\d/      # Match, "7" is a digit.
 310  " "  =~  /\s/      # Match, a space is whitespace.
 311  "a"  =~  /\D/      # Match, "a" is a non-digit.
 312  "7"  =~  /\D/      # No match, "7" is not a non-digit.
 313  " "  =~  /\S/      # No match, a space is not non-whitespace.
 314
 315  " "  =~  /\h/      # Match, space is horizontal whitespace.
 316  " "  =~  /\v/      # No match, space is not vertical whitespace.
 317  "\r" =~  /\v/      # Match, a return is vertical whitespace.
 318
 319  "a"  =~  /\pL/     # Match, "a" is a letter.
 320  "a"  =~  /\p{Lu}/  # No match, /\p{Lu}/ matches upper case letters.
 321
 322  "\x{0e0b}" =~ /\p{Thai}/  # Match, \x{0e0b} is the character
 323                            # 'THAI CHARACTER SO SO', and that's in
 324                            # Thai Unicode class.
 325  "a"  =~  /\P{Lao}/ # Match, as "a" is not a Laotian character.
 326
 327
 328 =head2 Bracketed Character Classes
 329
 330 The third form of character class you can use in Perl regular expressions
 331 is the bracketed character class.  In its simplest form, it lists the characters
 332 that may be matched, surrounded by square brackets, like this: C<[aeiou]>.
 333 This matches one of C<a>, C<e>, C<i>, C<o> or C<u>.  Like the other
 334 character classes, exactly one character is matched. To match
 335 a longer string consisting of characters mentioned in the character
 336 class, follow the character class with a L<quantifier|perlre/Quantifiers>.  For
 337 instance, C<[aeiou]+> matches one or more lowercase English vowels.
 338
 339 Repeating a character in a character class has no
 340 effect; it's considered to be in the set only once.
 341
 342 Examples:
 343
 344  "e"  =~  /[aeiou]/        # Match, as "e" is listed in the class.
 345  "p"  =~  /[aeiou]/        # No match, "p" is not listed in the class.
 346  "ae" =~  /^[aeiou]$/      # No match, a character class only matches
 347                            # a single character.
 348  "ae" =~  /^[aeiou]+$/     # Match, due to the quantifier.
 349
 350 =head3 Special Characters Inside a Bracketed Character Class
 351
 352 Most characters that are meta characters in regular expressions (that
 353 is, characters that carry a special meaning like C<.>, C<*>, or C<(>) lose
 354 their special meaning and can be used inside a character class without
 355 the need to escape them. For instance, C<[()]> matches either an opening
 356 parenthesis, or a closing parenthesis, and the parens inside the character
 357 class don't group or capture.
 358
 359 Characters that may carry a special meaning inside a character class are:
 360 C<\>, C<^>, C<->, C<[> and C<]>, and are discussed below. They can be
 361 escaped with a backslash, although this is sometimes not needed, in which
 362 case the backslash may be omitted.
 363
 364 The sequence C<\b> is special inside a bracketed character class. While
 365 outside the character class, C<\b> is an assertion indicating a point
 366 that does not have either two word characters or two non-word characters
 367 on either side, inside a bracketed character class, C<\b> matches a
 368 backspace character.
 369
 370 The sequences
 371 C<\a>,
 372 C<\c>,
 373 C<\e>,
 374 C<\f>,
 375 C<\n>,
 376 C<\N{I<NAME>}>,
 377 C<\N{U+I<hex char>}>,
 378 C<\r>,
 379 C<\t>,
 380 and
 381 C<\x>
 382 are also special and have the same meanings as they do outside a
 383 bracketed character class.  (However, inside a bracketed character
 384 class, if C<\N{I<NAME>}> expands to a sequence of characters, only the first
 385 one in the sequence is used, with a warning.)
 386
 387 Also, a backslash followed by two or three octal digits is considered an octal
 388 number.
 389
 390 A C<[> is not special inside a character class, unless it's the start of a
 391 POSIX character class (see L</POSIX Character Classes> below). It normally does
 392 not need escaping.
 393
 394 A C<]> is normally either the end of a POSIX character class (see
 395 L</POSIX Character Classes> below), or it signals the end of the bracketed
 396 character class.  If you want to include a C<]> in the set of characters, you
 397 must generally escape it.
 398
 399 However, if the C<]> is the I<first> (or the second if the first
 400 character is a caret) character of a bracketed character class, it
 401 does not denote the end of the class (as you cannot have an empty class)
 402 and is considered part of the set of characters that can be matched without
 403 escaping.
 404
 405 Examples:
 406
 407  "+"   =~ /[+?*]/     #  Match, "+" in a character class is not special.
 408  "\cH" =~ /[\b]/      #  Match, \b inside in a character class
 409                       #  is equivalent to a backspace.
 410  "]"   =~ /[][]/      #  Match, as the character class contains.
 411                       #  both [ and ].
 412  "[]"  =~ /[[]]/      #  Match, the pattern contains a character class
 413                       #  containing just ], and the character class is
 414                       #  followed by a ].
 415
 416 =head3 Character Ranges
 417
 418 It is not uncommon to want to match a range of characters. Luckily, instead
 419 of listing all characters in the range, one may use the hyphen (C<->).
 420 If inside a bracketed character class you have two characters separated
 421 by a hyphen, it's treated as if all characters between the two were in
 422 the class. For instance, C<[0-9]> matches any ASCII digit, and C<[a-m]>
 423 matches any lowercase letter from the first half of the old ASCII alphabet.
 424
 425 Note that the two characters on either side of the hyphen are not
 426 necessarily both letters or both digits. Any character is possible,
 427 although not advisable.  C<['-?]> contains a range of characters, but
 428 most people will not know which characters that means.  Furthermore,
 429 such ranges may lead to portability problems if the code has to run on
 430 a platform that uses a different character set, such as EBCDIC.
 431
 432 If a hyphen in a character class cannot syntactically be part of a range, for
 433 instance because it is the first or the last character of the character class,
 434 or if it immediately follows a range, the hyphen isn't special, and so is
 435 considered a character to be matched literally.  If you want a hyphen in
 436 your set of characters to be matched and its position in the class is such
 437 that it could be considered part of a range, you must escape that hyphen
 438 with a backslash.
 439
 440 Examples:
 441
 442  [a-z]       #  Matches a character that is a lower case ASCII letter.
 443  [a-fz]      #  Matches any letter between 'a' and 'f' (inclusive) or
 444              #  the letter 'z'.
 445  [-z]        #  Matches either a hyphen ('-') or the letter 'z'.
 446  [a-f-m]     #  Matches any letter between 'a' and 'f' (inclusive), the
 447              #  hyphen ('-'), or the letter 'm'.
 448  ['-?]       #  Matches any of the characters  '()*+,-./0123456789:;<=>?
 449              #  (But not on an EBCDIC platform).
 450
 451
 452 =head3 Negation
 453
 454 It is also possible to instead list the characters you do not want to
 455 match. You can do so by using a caret (C<^>) as the first character in the
 456 character class. For instance, C<[^a-z]> matches any character that is not a
 457 lowercase ASCII letter, which therefore includes almost a hundred thousand
 458 Unicode letters.
 459
 460 This syntax make the caret a special character inside a bracketed character
 461 class, but only if it is the first character of the class. So if you want
 462 the caret as one of the characters to match, either escape the caret or
 463 else not list it first.
 464
 465 Examples:
 466
 467  "e"  =~  /[^aeiou]/   #  No match, the 'e' is listed.
 468  "x"  =~  /[^aeiou]/   #  Match, as 'x' isn't a lowercase vowel.
 469  "^"  =~  /[^^]/       #  No match, matches anything that isn't a caret.
 470  "^"  =~  /[x^]/       #  Match, caret is not special here.
 471
 472 =head3 Backslash Sequences
 473
 474 You can put any backslash sequence character class (with the exception of
 475 C<\N> and C<\R>) inside a bracketed character class, and it will act just
 476 as if you had put all characters matched by the backslash sequence inside the
 477 character class. For instance, C<[a-f\d]> matches any decimal digit, or any
 478 of the lowercase letters between 'a' and 'f' inclusive.
 479
 480 C<\N> within a bracketed character class must be of the forms C<\N{I<name>}>
 481 or C<\N{U+I<hex char>}>, and NOT be the form that matches non-newlines,
 482 for the same reason that a dot C<.> inside a bracketed character class loses
 483 its special meaning: it matches nearly anything, which generally isn't what you
 484 want to happen.
 485
 486
 487 Examples:
 488
 489  /[\p{Thai}\d]/     # Matches a character that is either a Thai
 490                     # character, or a digit.
 491  /[^\p{Arabic}()]/  # Matches a character that is neither an Arabic
 492                     # character, nor a parenthesis.
 493
 494 Backslash sequence character classes cannot form one of the endpoints
 495 of a range.  Thus, you can't say:
 496
 497  /[\p{Thai}-\d]/     # Wrong!
 498
 499 =head3 POSIX Character Classes
 500 X<character class> X<\p> X<\p{}>
 501 X<alpha> X<alnum> X<ascii> X<blank> X<cntrl> X<digit> X<graph>
 502 X<lower> X<print> X<punct> X<space> X<upper> X<word> X<xdigit>
 503
 504 POSIX character classes have the form C<[:class:]>, where I<class> is
 505 name, and the C<[:> and C<:]> delimiters. POSIX character classes only appear
 506 I<inside> bracketed character classes, and are a convenient and descriptive
 507 way of listing a group of characters, though they can suffer from
 508 portability issues (see below and L<Locale, EBCDIC, Unicode and UTF-8>).
 509
 510 Be careful about the syntax,
 511
 512  # Correct:
 513  $string =~ /[[:alpha:]]/
 514
 515  # Incorrect (will warn):
 516  $string =~ /[:alpha:]/
 517
 518 The latter pattern would be a character class consisting of a colon,
 519 and the letters C<a>, C<l>, C<p> and C<h>.
 520 POSIX character classes can be part of a larger bracketed character class.
 521 For example,
 522
 523  [01[:alpha:]%]
 524
 525 is valid and matches '0', '1', any alphabetic character, and the percent sign.
 526
 527 Perl recognizes the following POSIX character classes:
 528
 529  alpha  Any alphabetical character ("[A-Za-z]").
 530  alnum  Any alphanumeric character. ("[A-Za-z0-9]")
 531  ascii  Any character in the ASCII character set.
 532  blank  A GNU extension, equal to a space or a horizontal tab ("\t").
 533  cntrl  Any control character.  See Note [2] below.
 534  digit  Any decimal digit ("[0-9]"), equivalent to "\d".
 535  graph  Any printable character, excluding a space.  See Note [3] below.
 536  lower  Any lowercase character ("[a-z]").
 537  print  Any printable character, including a space.  See Note [4] below.
 538  punct  Any graphical character excluding "word" characters.  Note [5].
 539  space  Any whitespace character. "\s" plus the vertical tab ("\cK").
 540  upper  Any uppercase character ("[A-Z]").
 541  word   A Perl extension ("[A-Za-z0-9_]"), equivalent to "\w".
 542  xdigit Any hexadecimal digit ("[0-9a-fA-F]").
 543
 544 Most POSIX character classes have two Unicode-style C<\p> property
 545 counterparts.  (They are not official Unicode properties, but Perl extensions
 546 derived from official Unicode properties.)  The table below shows the relation
 547 between POSIX character classes and these counterparts.
 548
 549 One counterpart, in the column labelled "ASCII-range Unicode" in
 550 the table, matches only characters in the ASCII character set.
 551
 552 The other counterpart, in the column labelled "Full-range Unicode", matches any
 553 appropriate characters in the full Unicode character set.  For example,
 554 C<\p{Alpha}> matches not just the ASCII alphabetic characters, but any
 555 character in the entire Unicode character set considered alphabetic.
 556 The column labelled "backslash sequence" is a (short) synonym for
 557 the Full-range Unicode form.
 558
 559 (Each of the counterparts has various synonyms as well.
 560 L<perluniprops/Properties accessible through \p{} and \P{}> lists all
 561 synonyms, plus all characters matched by each ASCII-range property.
 562 For example, C<\p{AHex}> is a synonym for C<\p{ASCII_Hex_Digit}>,
 563 and any C<\p> property name can be prefixed with "Is" such as C<\p{IsAlpha}>.)
 564
 565 Both the C<\p> forms are unaffected by any locale in effect, or whether
 566 the string is in UTF-8 format or not, or whether the platform is EBCDIC or not.
 567 In contrast, the POSIX character classes are affected, unless the
 568 regular expression is compiled with the C<"a"> modifier.  If the C<"a">
 569 modifier is not in effect, and the source string is in UTF-8 format, the
 570 POSIX classes behave like their "Full-range" Unicode counterparts.  If
 571 C<"a"> modifier is in effect; or the source string is not in UTF-8
 572 format, and no locale is in effect, and the platform is not EBCDIC, all
 573 the POSIX classes behave like their ASCII-range counterparts.
 574 Otherwise, they behave based on the rules of the locale or EBCDIC code
 575 page.
 576
 577 It is proposed to change this behavior in a future release of Perl so that the
 578 the UTF-8-ness of the source string will be irrelevant to the behavior of the
 579 POSIX character classes.  This means they will always behave in strict
 580 accordance with the official POSIX standard.  That is, if either locale or
 581 EBCDIC code page is present, they will behave in accordance with those; if
 582 absent, the classes will match only their ASCII-range counterparts.  If you
 583 wish to comment on this proposal, send email to C<perl5-porters@perl.org>.
 584
 585  [[:...:]]      ASCII-range          Full-range  backslash  Note
 586                  Unicode              Unicode     sequence
 587  -----------------------------------------------------
 588    alpha      \p{PosixAlpha}       \p{XPosixAlpha}
 589    alnum      \p{PosixAlnum}       \p{XPosixAlnum}
 590    ascii      \p{ASCII}
 591    blank      \p{PosixBlank}       \p{XPosixBlank}  \h      [1]
 592                                    or \p{HorizSpace}        [1]
 593    cntrl      \p{PosixCntrl}       \p{XPosixCntrl}          [2]
 594    digit      \p{PosixDigit}       \p{XPosixDigit}  \d
 595    graph      \p{PosixGraph}       \p{XPosixGraph}          [3]
 596    lower      \p{PosixLower}       \p{XPosixLower}
 597    print      \p{PosixPrint}       \p{XPosixPrint}          [4]
 598    punct      \p{PosixPunct}       \p{XPosixPunct}          [5]
 599               \p{PerlSpace}        \p{XPerlSpace}   \s      [6]
 600    space      \p{PosixSpace}       \p{XPosixSpace}          [6]
 601    upper      \p{PosixUpper}       \p{XPosixUpper}
 602    word       \p{PosixWord}        \p{XPosixWord}   \w
 603    xdigit     \p{ASCII_Hex_Digit}  \p{XPosixXDigit}
 604
 605 =over 4
 606
 607 =item [1]
 608
 609 C<\p{Blank}> and C<\p{HorizSpace}> are synonyms.
 610
 611 =item [2]
 612
 613 Control characters don't produce output as such, but instead usually control
 614 the terminal somehow: for example, newline and backspace are control characters.
 615 In the ASCII range, characters whose ordinals are between 0 and 31 inclusive,
 616 plus 127 (C<DEL>) are control characters.
 617
 618 On EBCDIC platforms, it is likely that the code page will define C<[[:cntrl:]]>
 619 to be the EBCDIC equivalents of the ASCII controls, plus the controls
 620 that in Unicode have ordinals from 128 through 159.
 621
 622 =item [3]
 623
 624 Any character that is I<graphical>, that is, visible. This class consists
 625 of all alphanumeric characters and all punctuation characters.
 626
 627 =item [4]
 628
 629 All printable characters, which is the set of all graphical characters
 630 plus those whitespace characters which are not also controls.
 631
 632 =item [5]
 633
 634 C<\p{PosixPunct}> and C<[[:punct:]]> in the ASCII range match all
 635 non-controls, non-alphanumeric, non-space characters:
 636 C<[-!"#$%&'()*+,./:;<=E<gt>?@[\\\]^_`{|}~]> (although if a locale is in effect,
 637 it could alter the behavior of C<[[:punct:]]>).
 638
 639 The similarly named property, C<\p{Punct}>, matches a somewhat different
 640 set in the ASCII range, namely
 641 C<[-!"#%&'()*,./:;?@[\\\]_{}]>.  That is, it is missing C<[$+E<lt>=E<gt>^`|~]>.
 642 This is because Unicode splits what POSIX considers to be punctuation into two
 643 categories, Punctuation and Symbols.
 644
 645 C<\p{XPosixPunct}> and (in Unicode mode) C<[[:punct:]]>, match what
 646 C<\p{PosixPunct}> matches in the ASCII range, plus what C<\p{Punct}>
 647 matches.  This is different than strictly matching according to
 648 C<\p{Punct}>.  Another way to say it is that
 649 for a UTF-8 string, C<[[:punct:]]> matches all characters that Unicode
 650 considers punctuation, plus all ASCII-range characters that Unicode
 651 considers symbols.
 652
 653 =item [6]
 654
 655 C<\p{SpacePerl}> and C<\p{Space}> differ only in that C<\p{Space}> additionally
 656 matches the vertical tab, C<\cK>.   Same for the two ASCII-only range forms.
 657
 658 =back
 659
 660 There are various other synonyms that can be used for these besides
 661 C<\p{HorizSpace}> and \C<\p{XPosixBlank}>.  For example,
 662 C<\p{PosixAlpha}> can be written as C<\p{Alpha}>.  All are listed
 663 in L<perluniprops/Properties accessible through \p{} and \P{}>.
 664
 665 =head4 Negation
 666 X<character class, negation>
 667
 668 A Perl extension to the POSIX character class is the ability to
 669 negate it. This is done by prefixing the class name with a caret (C<^>).
 670 Some examples:
 671
 672      POSIX         ASCII-range     Full-range  backslash
 673                     Unicode         Unicode    sequence
 674  -----------------------------------------------------
 675  [[:^digit:]]   \P{PosixDigit}  \P{XPosixDigit}   \D
 676  [[:^space:]]   \P{PosixSpace}  \P{XPosixSpace}
 677                 \P{PerlSpace}   \P{XPerlSpace}    \S
 678  [[:^word:]]    \P{PerlWord}    \P{XPosixWord}    \W
 679
 680 The backslash sequence can mean either ASCII- or Full-range Unicode,
 681 depending on various factors.  See L</Locale, EBCDIC, Unicode and UTF-8>
 682 below.
 683
 684 =head4 [= =] and [. .]
 685
 686 Perl recognizes the POSIX character classes C<[=class=]> and
 687 C<[.class.]>, but does not (yet?) support them.  Any attempt to use
 688 either construct raises an exception.
 689
 690 =head4 Examples
 691
 692  /[[:digit:]]/            # Matches a character that is a digit.
 693  /[01[:lower:]]/          # Matches a character that is either a
 694                           # lowercase letter, or '0' or '1'.
 695  /[[:digit:][:^xdigit:]]/ # Matches a character that can be anything
 696                           # except the letters 'a' to 'f'.  This is
 697                           # because the main character class is composed
 698                           # of two POSIX character classes that are ORed
 699                           # together, one that matches any digit, and
 700                           # the other that matches anything that isn't a
 701                           # hex digit.  The result matches all
 702                           # characters except the letters 'a' to 'f' and
 703                           # 'A' to 'F'.
 704
 705
 706 =head2 Locale, EBCDIC, Unicode and UTF-8
 707
 708 Some of the character classes have a somewhat different behaviour
 709 depending on the internal encoding of the source string, whether the regular
 710 expression is marked as having Unicode semantics, whatever locale is in
 711 effect, and whether the program is running on an EBCDIC platform.
 712
 713 C<\w>, C<\d>, C<\s> and the POSIX character classes (and their
 714 negations, including C<\W>, C<\D>, C<\S>) have this behaviour.  (Since
 715 the backslash sequences C<\b> and C<\B> are defined in terms of C<\w>
 716 and C<\W>, they also are affected.)
 717
 718 Starting in Perl 5.14, if the regular expression is compiled with the
 719 C<"a"> modifier, the behavior doesn't differ regardless of any other
 720 factors.  C<\d> matches the 10 digits 0-9; C<\D> any character but those
 721 10; C<\s>, exactly the five characters "[ \f\n\r\t]"; C<\w> only the 63
 722 characters "[A-Za-z0-9_]"; and the C<"[[:posix:]]"> classes only the
 723 appropriate ASCII characters, the same characters as are matched by the
 724 corresponding C<\p{}> property given in the "ASCII-range Unicode" column
 725 in the table above.  (The behavior of all of their complements follows
 726 the same paradigm.)
 727
 728 Otherwise, a regular expression is marked for Unicode semantics if it is
 729 encoded in utf8 (usually as a result of including a literal character
 730 whose code point is above 255), or if it contains a C<\N{U+...}> or
 731 C<\N{I<name>}> construct, or (starting in Perl 5.14) if it was compiled
 732 in the scope of a C<S<use feature "unicode_strings">> pragma and not in
 733 the scope of a C<S<use locale>> pragma, or has the C<"u"> regular
 734 expression modifier.
 735
 736 Note that one can specify C<"use re '/l'"> for example, for any regular
 737 expression modifier, and this has precedence over either of the
 738 C<S<use feature "unicode_strings">> or C<S<use locale>> pragmas.
 739
 740 The differences in behavior between locale and non-locale semantics
 741 can affect any character whose code point is 255 or less.  The
 742 differences in behavior between Unicode and non-Unicode semantics
 743 affects only ASCII platforms, and only when matching against characters
 744 whose code points are between 128 and 255 inclusive.  See
 745 L<perlunicode/The "Unicode Bug">.
 746
 747 For portability reasons, unless the C<"a"> modifier is specified,
 748 it may be better to not use C<\w>, C<\d>, C<\s> or the POSIX character
 749 classes and use the Unicode properties instead.
 750
 751 That way you can control whether you want matching of characters in
 752 the ASCII character set alone, or whether to match Unicode characters.
 753 C<S<use feature "unicode_strings">> allows seamless Unicode behavior
 754 no matter the internal encodings, but won't allow restricting
 755 to ASCII characters only.
 756
 757 =head4 Examples
 758
 759  $str =  "\xDF";      # $str is not in UTF-8 format.
 760  $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
 761  $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
 762  $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
 763  chop $str;
 764  $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
 765
 766 =cut