This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
df7a07ae9f05ea7b11c722e6d353aaa7539db615
[perl5.git] / cpan / perlfaq / lib / perlfaq7.pod
1 =head1 NAME
2
3 perlfaq7 - General Perl Language Issues
4
5 =head1 DESCRIPTION
6
7 This section deals with general Perl language issues that don't
8 clearly fit into any of the other sections.
9
10 =head2 Can I get a BNF/yacc/RE for the Perl language?
11
12 There is no BNF, but you can paw your way through the yacc grammar in
13 perly.y in the source distribution if you're particularly brave.  The
14 grammar relies on very smart tokenizing code, so be prepared to
15 venture into toke.c as well.
16
17 In the words of Chaim Frenkel: "Perl's grammar can not be reduced to BNF.
18 The work of parsing perl is distributed between yacc, the lexer, smoke
19 and mirrors."
20
21 =head2 What are all these $@%&* punctuation signs, and how do I know when to use them?
22
23 They are type specifiers, as detailed in L<perldata>:
24
25     $ for scalar values (number, string or reference)
26     @ for arrays
27     % for hashes (associative arrays)
28     & for subroutines (aka functions, procedures, methods)
29     * for all types of that symbol name.  In version 4 you used them like
30       pointers, but in modern perls you can just use references.
31
32 There are a couple of other symbols that
33 you're likely to encounter that aren't
34 really type specifiers:
35
36     <> are used for inputting a record from a filehandle.
37     \  takes a reference to something.
38
39 Note that <FILE> is I<neither> the type specifier for files
40 nor the name of the handle.  It is the C<< <> >> operator applied
41 to the handle FILE.  It reads one line (well, record--see
42 L<perlvar/$E<sol>>) from the handle FILE in scalar context, or I<all> lines
43 in list context.  When performing open, close, or any other operation
44 besides C<< <> >> on files, or even when talking about the handle, do
45 I<not> use the brackets.  These are correct: C<eof(FH)>, C<seek(FH, 0,
46 2)> and "copying from STDIN to FILE".
47
48 =head2 Do I always/never have to quote my strings or use semicolons and commas?
49
50 Normally, a bareword doesn't need to be quoted, but in most cases
51 probably should be (and must be under C<use strict>).  But a hash key
52 consisting of a simple word and the left-hand
53 operand to the C<< => >> operator both
54 count as though they were quoted:
55
56     This                    is like this
57     ------------            ---------------
58     $foo{line}              $foo{'line'}
59     bar => stuff            'bar' => stuff
60
61 The final semicolon in a block is optional, as is the final comma in a
62 list.  Good style (see L<perlstyle>) says to put them in except for
63 one-liners:
64
65     if ($whoops) { exit 1 }
66     @nums = (1, 2, 3);
67
68     if ($whoops) {
69         exit 1;
70     }
71
72     @lines = (
73         "There Beren came from mountains cold",
74         "And lost he wandered under leaves",
75     );
76
77 =head2 How do I skip some return values?
78
79 One way is to treat the return values as a list and index into it:
80
81     $dir = (getpwnam($user))[7];
82
83 Another way is to use undef as an element on the left-hand-side:
84
85     ($dev, $ino, undef, undef, $uid, $gid) = stat($file);
86
87 You can also use a list slice to select only the elements that
88 you need:
89
90     ($dev, $ino, $uid, $gid) = ( stat($file) )[0,1,4,5];
91
92 =head2 How do I temporarily block warnings?
93
94 If you are running Perl 5.6.0 or better, the C<use warnings> pragma
95 allows fine control of what warning are produced.
96 See L<perllexwarn> for more details.
97
98     {
99         no warnings;          # temporarily turn off warnings
100         $a = $b + $c;         # I know these might be undef
101     }
102
103 Additionally, you can enable and disable categories of warnings.
104 You turn off the categories you want to ignore and you can still
105 get other categories of warnings.  See L<perllexwarn> for the
106 complete details, including the category names and hierarchy.
107
108     {
109         no warnings 'uninitialized';
110         $a = $b + $c;
111     }
112
113 If you have an older version of Perl, the C<$^W> variable (documented
114 in L<perlvar>) controls runtime warnings for a block:
115
116     {
117         local $^W = 0;        # temporarily turn off warnings
118         $a = $b + $c;         # I know these might be undef
119     }
120
121 Note that like all the punctuation variables, you cannot currently
122 use my() on C<$^W>, only local().
123
124 =head2 What's an extension?
125
126 An extension is a way of calling compiled C code from Perl.  Reading
127 L<perlxstut> is a good place to learn more about extensions.
128
129 =head2 Why do Perl operators have different precedence than C operators?
130
131 Actually, they don't.  All C operators that Perl copies have the same
132 precedence in Perl as they do in C.  The problem is with operators that C
133 doesn't have, especially functions that give a list context to everything
134 on their right, eg. print, chmod, exec, and so on.  Such functions are
135 called "list operators" and appear as such in the precedence table in
136 L<perlop>.
137
138 A common mistake is to write:
139
140     unlink $file || die "snafu";
141
142 This gets interpreted as:
143
144     unlink ($file || die "snafu");
145
146 To avoid this problem, either put in extra parentheses or use the
147 super low precedence C<or> operator:
148
149     (unlink $file) || die "snafu";
150     unlink $file or die "snafu";
151
152 The "English" operators (C<and>, C<or>, C<xor>, and C<not>)
153 deliberately have precedence lower than that of list operators for
154 just such situations as the one above.
155
156 Another operator with surprising precedence is exponentiation.  It
157 binds more tightly even than unary minus, making C<-2**2> produce a
158 negative not a positive four.  It is also right-associating, meaning
159 that C<2**3**2> is two raised to the ninth power, not eight squared.
160
161 Although it has the same precedence as in C, Perl's C<?:> operator
162 produces an lvalue.  This assigns $x to either $a or $b, depending
163 on the trueness of $maybe:
164
165     ($maybe ? $a : $b) = $x;
166
167 =head2 How do I declare/create a structure?
168
169 In general, you don't "declare" a structure.  Just use a (probably
170 anonymous) hash reference.  See L<perlref> and L<perldsc> for details.
171 Here's an example:
172
173     $person = {};                   # new anonymous hash
174     $person->{AGE}  = 24;           # set field AGE to 24
175     $person->{NAME} = "Nat";        # set field NAME to "Nat"
176
177 If you're looking for something a bit more rigorous, try L<perltoot>.
178
179 =head2 How do I create a module?
180
181 (contributed by brian d foy)
182
183 L<perlmod>, L<perlmodlib>, L<perlmodstyle> explain modules
184 in all the gory details. L<perlnewmod> gives a brief
185 overview of the process along with a couple of suggestions
186 about style.
187
188 If you need to include C code or C library interfaces in
189 your module, you'll need h2xs.  h2xs will create the module
190 distribution structure and the initial interface files
191 you'll need.  L<perlxs> and L<perlxstut> explain the details.
192
193 If you don't need to use C code, other tools such as
194 ExtUtils::ModuleMaker and Module::Starter, can help you
195 create a skeleton module distribution.
196
197 You may also want to see Sam Tregar's "Writing Perl Modules
198 for CPAN" ( http://apress.com/book/bookDisplay.html?bID=14 )
199 which is the best hands-on guide to creating module
200 distributions.
201
202 =head2 How do I adopt or take over a module already on CPAN?
203
204 (contributed by brian d foy)
205
206 The easiest way to take over a module is to have the current
207 module maintainer either make you a co-maintainer or transfer
208 the module to you.
209
210 If you can't reach the author for some reason (e.g. email bounces),
211 the PAUSE admins at modules@perl.org can help. The PAUSE admins
212 treat each case individually.
213
214 =over 4
215
216 =item *
217
218 Get a login for the Perl Authors Upload Server (PAUSE) if you don't
219 already have one: http://pause.perl.org
220
221 =item *
222
223 Write to modules@perl.org explaining what you did to contact the
224 current maintainer. The PAUSE admins will also try to reach the
225 maintainer.
226
227 =item *
228
229 Post a public message in a heavily trafficked site announcing your
230 intention to take over the module.
231
232 =item *
233
234 Wait a bit. The PAUSE admins don't want to act too quickly in case
235 the current maintainer is on holiday. If there's no response to
236 private communication or the public post, a PAUSE admin can transfer
237 it to you.
238
239 =back
240
241 =head2 How do I create a class?
242 X<class, creation> X<package>
243
244 (contributed by brian d foy)
245
246 In Perl, a class is just a package, and methods are just subroutines.
247 Perl doesn't get more formal than that and lets you set up the package
248 just the way that you like it (that is, it doesn't set up anything for
249 you).
250
251 The Perl documentation has several tutorials that cover class
252 creation, including L<perlboot> (Barnyard Object Oriented Tutorial),
253 L<perltoot> (Tom's Object Oriented Tutorial), L<perlbot> (Bag o'
254 Object Tricks), and L<perlobj>.
255
256 =head2 How can I tell if a variable is tainted?
257
258 You can use the tainted() function of the Scalar::Util module, available
259 from CPAN (or included with Perl since release 5.8.0).
260 See also L<perlsec/"Laundering and Detecting Tainted Data">.
261
262 =head2 What's a closure?
263
264 Closures are documented in L<perlref>.
265
266 I<Closure> is a computer science term with a precise but
267 hard-to-explain meaning. Usually, closures are implemented in Perl as
268 anonymous subroutines with lasting references to lexical variables
269 outside their own scopes. These lexicals magically refer to the
270 variables that were around when the subroutine was defined (deep
271 binding).
272
273 Closures are most often used in programming languages where you can
274 have the return value of a function be itself a function, as you can
275 in Perl. Note that some languages provide anonymous functions but are
276 not capable of providing proper closures: the Python language, for
277 example.  For more information on closures, check out any textbook on
278 functional programming.  Scheme is a language that not only supports
279 but encourages closures.
280
281 Here's a classic non-closure function-generating function:
282
283     sub add_function_generator {
284         return sub { shift() + shift() };
285     }
286
287     $add_sub = add_function_generator();
288     $sum = $add_sub->(4,5);                # $sum is 9 now.
289
290 The anonymous subroutine returned by add_function_generator() isn't
291 technically a closure because it refers to no lexicals outside its own
292 scope.  Using a closure gives you a I<function template> with some
293 customization slots left out to be filled later.
294
295 Contrast this with the following make_adder() function, in which the
296 returned anonymous function contains a reference to a lexical variable
297 outside the scope of that function itself.  Such a reference requires
298 that Perl return a proper closure, thus locking in for all time the
299 value that the lexical had when the function was created.
300
301     sub make_adder {
302         my $addpiece = shift;
303         return sub { shift() + $addpiece };
304     }
305
306     $f1 = make_adder(20);
307     $f2 = make_adder(555);
308
309 Now C<&$f1($n)> is always 20 plus whatever $n you pass in, whereas
310 C<&$f2($n)> is always 555 plus whatever $n you pass in.  The $addpiece
311 in the closure sticks around.
312
313 Closures are often used for less esoteric purposes.  For example, when
314 you want to pass in a bit of code into a function:
315
316     my $line;
317     timeout( 30, sub { $line = <STDIN> } );
318
319 If the code to execute had been passed in as a string,
320 C<< '$line = <STDIN>' >>, there would have been no way for the
321 hypothetical timeout() function to access the lexical variable
322 $line back in its caller's scope.
323
324 Another use for a closure is to make a variable I<private> to a
325 named subroutine, e.g. a counter that gets initialized at creation
326 time of the sub and can only be modified from within the sub.
327 This is sometimes used with a BEGIN block in package files to make
328 sure a variable doesn't get meddled with during the lifetime of the
329 package:
330
331     BEGIN {
332         my $id = 0;
333         sub next_id { ++$id }
334     }
335
336 This is discussed in more detail in L<perlsub>; see the entry on
337 I<Persistent Private Variables>.
338
339 =head2 What is variable suicide and how can I prevent it?
340
341 This problem was fixed in perl 5.004_05, so preventing it means upgrading
342 your version of perl. ;)
343
344 Variable suicide is when you (temporarily or permanently) lose the value
345 of a variable.  It is caused by scoping through my() and local()
346 interacting with either closures or aliased foreach() iterator variables
347 and subroutine arguments.  It used to be easy to inadvertently lose a
348 variable's value this way, but now it's much harder.  Take this code:
349
350     my $f = 'foo';
351     sub T {
352         while ($i++ < 3) { my $f = $f; $f .= "bar"; print $f, "\n" }
353     }
354
355     T;
356     print "Finally $f\n";
357
358 If you are experiencing variable suicide, that C<my $f> in the subroutine
359 doesn't pick up a fresh copy of the C<$f> whose value is <foo>. The output
360 shows that inside the subroutine the value of C<$f> leaks through when it
361 shouldn't, as in this output:
362
363     foobar
364     foobarbar
365     foobarbarbar
366     Finally foo
367
368 The $f that has "bar" added to it three times should be a new C<$f>
369 C<my $f> should create a new lexical variable each time through the loop.
370 The expected output is:
371
372     foobar
373     foobar
374     foobar
375     Finally foo
376
377 =head2 How can I pass/return a {Function, FileHandle, Array, Hash, Method, Regex}?
378
379 You need to pass references to these objects.  See L<perlsub/"Pass by
380 Reference"> for this particular question, and L<perlref> for
381 information on references.
382
383 =over 4
384
385 =item Passing Variables and Functions
386
387 Regular variables and functions are quite easy to pass: just pass in a
388 reference to an existing or anonymous variable or function:
389
390     func( \$some_scalar );
391
392     func( \@some_array  );
393     func( [ 1 .. 10 ]   );
394
395     func( \%some_hash   );
396     func( { this => 10, that => 20 }   );
397
398     func( \&some_func   );
399     func( sub { $_[0] ** $_[1] }   );
400
401 =item Passing Filehandles
402
403 As of Perl 5.6, you can represent filehandles with scalar variables
404 which you treat as any other scalar.
405
406     open my $fh, $filename or die "Cannot open $filename! $!";
407     func( $fh );
408
409     sub func {
410         my $passed_fh = shift;
411
412         my $line = <$passed_fh>;
413     }
414
415 Before Perl 5.6, you had to use the C<*FH> or C<\*FH> notations.
416 These are "typeglobs"--see L<perldata/"Typeglobs and Filehandles">
417 and especially L<perlsub/"Pass by Reference"> for more information.
418
419 =item Passing Regexes
420
421 Here's an example of how to pass in a string and a regular expression
422 for it to match against. You construct the pattern with the C<qr//>
423 operator:
424
425     sub compare($$) {
426         my ($val1, $regex) = @_;
427         my $retval = $val1 =~ /$regex/;
428     return $retval;
429     }
430     $match = compare("old McDonald", qr/d.*D/i);
431
432 =item Passing Methods
433
434 To pass an object method into a subroutine, you can do this:
435
436     call_a_lot(10, $some_obj, "methname")
437     sub call_a_lot {
438         my ($count, $widget, $trick) = @_;
439         for (my $i = 0; $i < $count; $i++) {
440             $widget->$trick();
441         }
442     }
443
444 Or, you can use a closure to bundle up the object, its
445 method call, and arguments:
446
447     my $whatnot =  sub { $some_obj->obfuscate(@args) };
448     func($whatnot);
449     sub func {
450         my $code = shift;
451         &$code();
452     }
453
454 You could also investigate the can() method in the UNIVERSAL class
455 (part of the standard perl distribution).
456
457 =back
458
459 =head2 How do I create a static variable?
460
461 (contributed by brian d foy)
462
463 In Perl 5.10, declare the variable with C<state>. The C<state>
464 declaration creates the lexical variable that persists between calls
465 to the subroutine:
466
467     sub counter { state $count = 1; $counter++ }
468
469 You can fake a static variable by using a lexical variable which goes
470 out of scope. In this example, you define the subroutine C<counter>, and
471 it uses the lexical variable C<$count>. Since you wrap this in a BEGIN
472 block, C<$count> is defined at compile-time, but also goes out of
473 scope at the end of the BEGIN block. The BEGIN block also ensures that
474 the subroutine and the value it uses is defined at compile-time so the
475 subroutine is ready to use just like any other subroutine, and you can
476 put this code in the same place as other subroutines in the program
477 text (i.e. at the end of the code, typically). The subroutine
478 C<counter> still has a reference to the data, and is the only way you
479 can access the value (and each time you do, you increment the value).
480 The data in chunk of memory defined by C<$count> is private to
481 C<counter>.
482
483     BEGIN {
484         my $count = 1;
485         sub counter { $count++ }
486     }
487
488     my $start = counter();
489
490     .... # code that calls counter();
491
492     my $end = counter();
493
494 In the previous example, you created a function-private variable
495 because only one function remembered its reference. You could define
496 multiple functions while the variable is in scope, and each function
497 can share the "private" variable. It's not really "static" because you
498 can access it outside the function while the lexical variable is in
499 scope, and even create references to it. In this example,
500 C<increment_count> and C<return_count> share the variable. One
501 function adds to the value and the other simply returns the value.
502 They can both access C<$count>, and since it has gone out of scope,
503 there is no other way to access it.
504
505     BEGIN {
506         my $count = 1;
507         sub increment_count { $count++ }
508         sub return_count    { $count }
509     }
510
511 To declare a file-private variable, you still use a lexical variable.
512 A file is also a scope, so a lexical variable defined in the file
513 cannot be seen from any other file.
514
515 See L<perlsub/"Persistent Private Variables"> for more information.
516 The discussion of closures in L<perlref> may help you even though we
517 did not use anonymous subroutines in this answer. See
518 L<perlsub/"Persistent Private Variables"> for details.
519
520 =head2 What's the difference between dynamic and lexical (static) scoping?  Between local() and my()?
521
522 C<local($x)> saves away the old value of the global variable C<$x>
523 and assigns a new value for the duration of the subroutine I<which is
524 visible in other functions called from that subroutine>.  This is done
525 at run-time, so is called dynamic scoping.  local() always affects global
526 variables, also called package variables or dynamic variables.
527
528 C<my($x)> creates a new variable that is only visible in the current
529 subroutine.  This is done at compile-time, so it is called lexical or
530 static scoping.  my() always affects private variables, also called
531 lexical variables or (improperly) static(ly scoped) variables.
532
533 For instance:
534
535     sub visible {
536         print "var has value $var\n";
537     }
538
539     sub dynamic {
540         local $var = 'local';    # new temporary value for the still-global
541         visible();              #   variable called $var
542     }
543
544     sub lexical {
545         my $var = 'private';    # new private variable, $var
546         visible();              # (invisible outside of sub scope)
547     }
548
549     $var = 'global';
550
551     visible();              # prints global
552     dynamic();              # prints local
553     lexical();              # prints global
554
555 Notice how at no point does the value "private" get printed.  That's
556 because $var only has that value within the block of the lexical()
557 function, and it is hidden from the called subroutine.
558
559 In summary, local() doesn't make what you think of as private, local
560 variables.  It gives a global variable a temporary value.  my() is
561 what you're looking for if you want private variables.
562
563 See L<perlsub/"Private Variables via my()"> and
564 L<perlsub/"Temporary Values via local()"> for excruciating details.
565
566 =head2 How can I access a dynamic variable while a similarly named lexical is in scope?
567
568 If you know your package, you can just mention it explicitly, as in
569 $Some_Pack::var. Note that the notation $::var is B<not> the dynamic $var
570 in the current package, but rather the one in the "main" package, as
571 though you had written $main::var.
572
573     use vars '$var';
574     local $var = "global";
575     my    $var = "lexical";
576
577     print "lexical is $var\n";
578     print "global  is $main::var\n";
579
580 Alternatively you can use the compiler directive our() to bring a
581 dynamic variable into the current lexical scope.
582
583     require 5.006; # our() did not exist before 5.6
584     use vars '$var';
585
586     local $var = "global";
587     my $var    = "lexical";
588
589     print "lexical is $var\n";
590
591     {
592         our $var;
593         print "global  is $var\n";
594     }
595
596 =head2 What's the difference between deep and shallow binding?
597
598 In deep binding, lexical variables mentioned in anonymous subroutines
599 are the same ones that were in scope when the subroutine was created.
600 In shallow binding, they are whichever variables with the same names
601 happen to be in scope when the subroutine is called.  Perl always uses
602 deep binding of lexical variables (i.e., those created with my()).
603 However, dynamic variables (aka global, local, or package variables)
604 are effectively shallowly bound.  Consider this just one more reason
605 not to use them.  See the answer to L<"What's a closure?">.
606
607 =head2 Why doesn't "my($foo) = E<lt>FILEE<gt>;" work right?
608
609 C<my()> and C<local()> give list context to the right hand side
610 of C<=>.  The <FH> read operation, like so many of Perl's
611 functions and operators, can tell which context it was called in and
612 behaves appropriately.  In general, the scalar() function can help.
613 This function does nothing to the data itself (contrary to popular myth)
614 but rather tells its argument to behave in whatever its scalar fashion is.
615 If that function doesn't have a defined scalar behavior, this of course
616 doesn't help you (such as with sort()).
617
618 To enforce scalar context in this particular case, however, you need
619 merely omit the parentheses:
620
621     local($foo) = <FILE>;        # WRONG
622     local($foo) = scalar(<FILE>);   # ok
623     local $foo  = <FILE>;        # right
624
625 You should probably be using lexical variables anyway, although the
626 issue is the same here:
627
628     my($foo) = <FILE>;    # WRONG
629     my $foo  = <FILE>;    # right
630
631 =head2 How do I redefine a builtin function, operator, or method?
632
633 Why do you want to do that? :-)
634
635 If you want to override a predefined function, such as open(),
636 then you'll have to import the new definition from a different
637 module.  See L<perlsub/"Overriding Built-in Functions">.
638
639 If you want to overload a Perl operator, such as C<+> or C<**>,
640 then you'll want to use the C<use overload> pragma, documented
641 in L<overload>.
642
643 If you're talking about obscuring method calls in parent classes,
644 see L<perltoot/"Overridden Methods">.
645
646 =head2 What's the difference between calling a function as &foo and foo()?
647
648 (contributed by brian d foy)
649
650 Calling a subroutine as C<&foo> with no trailing parentheses ignores
651 the prototype of C<foo> and passes it the current value of the argument
652 list, C<@_>. Here's an example; the C<bar> subroutine calls C<&foo>,
653 which prints its arguments list:
654
655     sub bar { &foo }
656
657     sub foo { print "Args in foo are: @_\n" }
658
659     bar( qw( a b c ) );
660
661 When you call C<bar> with arguments, you see that C<foo> got the same C<@_>:
662
663     Args in foo are: a b c
664
665 Calling the subroutine with trailing parentheses, with or without arguments,
666 does not use the current C<@_> and respects the subroutine prototype. Changing
667 the example to put parentheses after the call to C<foo> changes the program:
668
669     sub bar { &foo() }
670
671     sub foo { print "Args in foo are: @_\n" }
672
673     bar( qw( a b c ) );
674
675 Now the output shows that C<foo> doesn't get the C<@_> from its caller.
676
677     Args in foo are:
678
679 The main use of the C<@_> pass-through feature is to write subroutines
680 whose main job it is to call other subroutines for you. For further
681 details, see L<perlsub>.
682
683 =head2 How do I create a switch or case statement?
684
685 In Perl 5.10, use the C<given-when> construct described in L<perlsyn>:
686
687     use 5.010;
688
689     given ( $string ) {
690         when( 'Fred' )        { say "I found Fred!" }
691         when( 'Barney' )      { say "I found Barney!" }
692         when( /Bamm-?Bamm/ )  { say "I found Bamm-Bamm!" }
693         default               { say "I don't recognize the name!" }
694     };
695
696 If one wants to use pure Perl and to be compatible with Perl versions
697 prior to 5.10, the general answer is to use C<if-elsif-else>:
698
699     for ($variable_to_test) {
700         if    (/pat1/)  { }     # do something
701         elsif (/pat2/)  { }     # do something else
702         elsif (/pat3/)  { }     # do something else
703         else            { }     # default
704     }
705
706 Here's a simple example of a switch based on pattern matching,
707 lined up in a way to make it look more like a switch statement.
708 We'll do a multiway conditional based on the type of reference stored
709 in $whatchamacallit:
710
711     SWITCH: for (ref $whatchamacallit) {
712
713         /^$/           && die "not a reference";
714
715         /SCALAR/       && do {
716                         print_scalar($$ref);
717                         last SWITCH;
718                       };
719
720         /ARRAY/        && do {
721                         print_array(@$ref);
722                         last SWITCH;
723                       };
724
725         /HASH/        && do {
726                         print_hash(%$ref);
727                         last SWITCH;
728                       };
729
730         /CODE/        && do {
731                         warn "can't print function ref";
732                         last SWITCH;
733                       };
734
735         # DEFAULT
736
737         warn "User defined type skipped";
738
739     }
740
741 See L<perlsyn> for other examples in this style.
742
743 Sometimes you should change the positions of the constant and the variable.
744 For example, let's say you wanted to test which of many answers you were
745 given, but in a case-insensitive way that also allows abbreviations.
746 You can use the following technique if the strings all start with
747 different characters or if you want to arrange the matches so that
748 one takes precedence over another, as C<"SEND"> has precedence over
749 C<"STOP"> here:
750
751     chomp($answer = <>);
752     if    ("SEND"  =~ /^\Q$answer/i) { print "Action is send\n"  }
753     elsif ("STOP"  =~ /^\Q$answer/i) { print "Action is stop\n"  }
754     elsif ("ABORT" =~ /^\Q$answer/i) { print "Action is abort\n" }
755     elsif ("LIST"  =~ /^\Q$answer/i) { print "Action is list\n"  }
756     elsif ("EDIT"  =~ /^\Q$answer/i) { print "Action is edit\n"  }
757
758 A totally different approach is to create a hash of function references.
759
760     my %commands = (
761         "happy" => \&joy,
762         "sad",  => \&sullen,
763         "done"  => sub { die "See ya!" },
764         "mad"   => \&angry,
765     );
766
767     print "How are you? ";
768     chomp($string = <STDIN>);
769     if ($commands{$string}) {
770         $commands{$string}->();
771     } else {
772         print "No such command: $string\n";
773     }
774
775 Starting from Perl 5.8, a source filter module, C<Switch>, can also be
776 used to get switch and case. Its use is now discouraged, because it's
777 not fully compatible with the native switch of Perl 5.10, and because,
778 as it's implemented as a source filter, it doesn't always work as intended
779 when complex syntax is involved.
780
781 =head2 How can I catch accesses to undefined variables, functions, or methods?
782
783 The AUTOLOAD method, discussed in L<perlsub/"Autoloading"> and
784 L<perltoot/"AUTOLOAD: Proxy Methods">, lets you capture calls to
785 undefined functions and methods.
786
787 When it comes to undefined variables that would trigger a warning
788 under C<use warnings>, you can promote the warning to an error.
789
790     use warnings FATAL => qw(uninitialized);
791
792 =head2 Why can't a method included in this same file be found?
793
794 Some possible reasons: your inheritance is getting confused, you've
795 misspelled the method name, or the object is of the wrong type.  Check
796 out L<perltoot> for details about any of the above cases.  You may
797 also use C<print ref($object)> to find out the class C<$object> was
798 blessed into.
799
800 Another possible reason for problems is that you've used the
801 indirect object syntax (eg, C<find Guru "Samy">) on a class name
802 before Perl has seen that such a package exists.  It's wisest to make
803 sure your packages are all defined before you start using them, which
804 will be taken care of if you use the C<use> statement instead of
805 C<require>.  If not, make sure to use arrow notation (eg.,
806 C<< Guru->find("Samy") >>) instead.  Object notation is explained in
807 L<perlobj>.
808
809 Make sure to read about creating modules in L<perlmod> and
810 the perils of indirect objects in L<perlobj/"Method Invocation">.
811
812 =head2 How can I find out my current or calling package?
813
814 (contributed by brian d foy)
815
816 To find the package you are currently in, use the special literal
817 C<__PACKAGE__>, as documented in L<perldata>. You can only use the
818 special literals as separate tokens, so you can't interpolate them
819 into strings like you can with variables:
820
821     my $current_package = __PACKAGE__;
822     print "I am in package $current_package\n";
823
824 If you want to find the package calling your code, perhaps to give better
825 diagnostics as L<Carp> does, use the C<caller> built-in:
826
827     sub foo {
828         my @args = ...;
829         my( $package, $filename, $line ) = caller;
830
831         print "I was called from package $package\n";
832         );
833
834 By default, your program starts in package C<main>, so you will
835 always be in some package.
836
837 This is different from finding out the package an object is blessed
838 into, which might not be the current package. For that, use C<blessed>
839 from L<Scalar::Util>, part of the Standard Library since Perl 5.8:
840
841     use Scalar::Util qw(blessed);
842     my $object_package = blessed( $object );
843
844 Most of the time, you shouldn't care what package an object is blessed
845 into, however, as long as it claims to inherit from that class:
846
847     my $is_right_class = eval { $object->isa( $package ) }; # true or false
848
849 And, with Perl 5.10 and later, you don't have to check for an
850 inheritance to see if the object can handle a role. For that, you can
851 use C<DOES>, which comes from C<UNIVERSAL>:
852
853     my $class_does_it = eval { $object->DOES( $role ) }; # true or false
854
855 You can safely replace C<isa> with C<DOES> (although the converse is not true).
856
857 =head2 How can I comment out a large block of Perl code?
858
859 (contributed by brian d foy)
860
861 The quick-and-dirty way to comment out more than one line of Perl is
862 to surround those lines with Pod directives. You have to put these
863 directives at the beginning of the line and somewhere where Perl
864 expects a new statement (so not in the middle of statements like the #
865 comments). You end the comment with C<=cut>, ending the Pod section:
866
867     =pod
868
869     my $object = NotGonnaHappen->new();
870
871     ignored_sub();
872
873     $wont_be_assigned = 37;
874
875     =cut
876
877 The quick-and-dirty method only works well when you don't plan to
878 leave the commented code in the source. If a Pod parser comes along,
879 you're multiline comment is going to show up in the Pod translation.
880 A better way hides it from Pod parsers as well.
881
882 The C<=begin> directive can mark a section for a particular purpose.
883 If the Pod parser doesn't want to handle it, it just ignores it. Label
884 the comments with C<comment>. End the comment using C<=end> with the
885 same label. You still need the C<=cut> to go back to Perl code from
886 the Pod comment:
887
888     =begin comment
889
890     my $object = NotGonnaHappen->new();
891
892     ignored_sub();
893
894     $wont_be_assigned = 37;
895
896     =end comment
897
898     =cut
899
900 For more information on Pod, check out L<perlpod> and L<perlpodspec>.
901
902 =head2 How do I clear a package?
903
904 Use this code, provided by Mark-Jason Dominus:
905
906     sub scrub_package {
907         no strict 'refs';
908         my $pack = shift;
909         die "Shouldn't delete main package"
910             if $pack eq "" || $pack eq "main";
911         my $stash = *{$pack . '::'}{HASH};
912         my $name;
913         foreach $name (keys %$stash) {
914             my $fullname = $pack . '::' . $name;
915             # Get rid of everything with that name.
916             undef $$fullname;
917             undef @$fullname;
918             undef %$fullname;
919             undef &$fullname;
920             undef *$fullname;
921         }
922     }
923
924 Or, if you're using a recent release of Perl, you can
925 just use the Symbol::delete_package() function instead.
926
927 =head2 How can I use a variable as a variable name?
928
929 Beginners often think they want to have a variable contain the name
930 of a variable.
931
932     $fred    = 23;
933     $varname = "fred";
934     ++$$varname;         # $fred now 24
935
936 This works I<sometimes>, but it is a very bad idea for two reasons.
937
938 The first reason is that this technique I<only works on global
939 variables>.  That means that if $fred is a lexical variable created
940 with my() in the above example, the code wouldn't work at all: you'd
941 accidentally access the global and skip right over the private lexical
942 altogether.  Global variables are bad because they can easily collide
943 accidentally and in general make for non-scalable and confusing code.
944
945 Symbolic references are forbidden under the C<use strict> pragma.
946 They are not true references and consequently are not reference-counted
947 or garbage-collected.
948
949 The other reason why using a variable to hold the name of another
950 variable is a bad idea is that the question often stems from a lack of
951 understanding of Perl data structures, particularly hashes.  By using
952 symbolic references, you are just using the package's symbol-table hash
953 (like C<%main::>) instead of a user-defined hash.  The solution is to
954 use your own hash or a real reference instead.
955
956     $USER_VARS{"fred"} = 23;
957     $varname = "fred";
958     $USER_VARS{$varname}++;  # not $$varname++
959
960 There we're using the %USER_VARS hash instead of symbolic references.
961 Sometimes this comes up in reading strings from the user with variable
962 references and wanting to expand them to the values of your perl
963 program's variables.  This is also a bad idea because it conflates the
964 program-addressable namespace and the user-addressable one.  Instead of
965 reading a string and expanding it to the actual contents of your program's
966 own variables:
967
968     $str = 'this has a $fred and $barney in it';
969     $str =~ s/(\$\w+)/$1/eeg;          # need double eval
970
971 it would be better to keep a hash around like %USER_VARS and have
972 variable references actually refer to entries in that hash:
973
974     $str =~ s/\$(\w+)/$USER_VARS{$1}/g;   # no /e here at all
975
976 That's faster, cleaner, and safer than the previous approach.  Of course,
977 you don't need to use a dollar sign.  You could use your own scheme to
978 make it less confusing, like bracketed percent symbols, etc.
979
980     $str = 'this has a %fred% and %barney% in it';
981     $str =~ s/%(\w+)%/$USER_VARS{$1}/g;   # no /e here at all
982
983 Another reason that folks sometimes think they want a variable to
984 contain the name of a variable is that they don't know how to build
985 proper data structures using hashes.  For example, let's say they
986 wanted two hashes in their program: %fred and %barney, and that they
987 wanted to use another scalar variable to refer to those by name.
988
989     $name = "fred";
990     $$name{WIFE} = "wilma";     # set %fred
991
992     $name = "barney";
993     $$name{WIFE} = "betty";    # set %barney
994
995 This is still a symbolic reference, and is still saddled with the
996 problems enumerated above.  It would be far better to write:
997
998     $folks{"fred"}{WIFE}   = "wilma";
999     $folks{"barney"}{WIFE} = "betty";
1000
1001 And just use a multilevel hash to start with.
1002
1003 The only times that you absolutely I<must> use symbolic references are
1004 when you really must refer to the symbol table.  This may be because it's
1005 something that one can't take a real reference to, such as a format name.
1006 Doing so may also be important for method calls, since these always go
1007 through the symbol table for resolution.
1008
1009 In those cases, you would turn off C<strict 'refs'> temporarily so you
1010 can play around with the symbol table.  For example:
1011
1012     @colors = qw(red blue green yellow orange purple violet);
1013     for my $name (@colors) {
1014         no strict 'refs';  # renege for the block
1015         *$name = sub { "<FONT COLOR='$name'>@_</FONT>" };
1016     }
1017
1018 All those functions (red(), blue(), green(), etc.) appear to be separate,
1019 but the real code in the closure actually was compiled only once.
1020
1021 So, sometimes you might want to use symbolic references to manipulate
1022 the symbol table directly.  This doesn't matter for formats, handles, and
1023 subroutines, because they are always global--you can't use my() on them.
1024 For scalars, arrays, and hashes, though--and usually for subroutines--
1025 you probably only want to use hard references.
1026
1027 =head2 What does "bad interpreter" mean?
1028
1029 (contributed by brian d foy)
1030
1031 The "bad interpreter" message comes from the shell, not perl.  The
1032 actual message may vary depending on your platform, shell, and locale
1033 settings.
1034
1035 If you see "bad interpreter - no such file or directory", the first
1036 line in your perl script (the "shebang" line) does not contain the
1037 right path to perl (or any other program capable of running scripts).
1038 Sometimes this happens when you move the script from one machine to
1039 another and each machine has a different path to perl--/usr/bin/perl
1040 versus /usr/local/bin/perl for instance. It may also indicate
1041 that the source machine has CRLF line terminators and the
1042 destination machine has LF only: the shell tries to find
1043 /usr/bin/perl<CR>, but can't.
1044
1045 If you see "bad interpreter: Permission denied", you need to make your
1046 script executable.
1047
1048 In either case, you should still be able to run the scripts with perl
1049 explicitly:
1050
1051     % perl script.pl
1052
1053 If you get a message like "perl: command not found", perl is not in
1054 your PATH, which might also mean that the location of perl is not
1055 where you expect it so you need to adjust your shebang line.
1056
1057 =head1 AUTHOR AND COPYRIGHT
1058
1059 Copyright (c) 1997-2010 Tom Christiansen, Nathan Torkington, and
1060 other authors as noted. All rights reserved.
1061
1062 This documentation is free; you can redistribute it and/or modify it
1063 under the same terms as Perl itself.
1064
1065 Irrespective of its distribution, all code examples in this file
1066 are hereby placed into the public domain.  You are permitted and
1067 encouraged to use this code in your own programs for fun
1068 or for profit as you see fit.  A simple comment in the code giving
1069 credit would be courteous but is not required.