This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Instead of muting symbol export error if under eval,
[perl5.git] / lib / Exporter / Heavy.pm
1 package Exporter::Heavy;
2
3 use strict;
4 no strict 'refs';
5
6 # On one line so MakeMaker will see it.
7 require Exporter;  our $VERSION = $Exporter::VERSION;
8 $Carp::Internal{"Exporter::Heavy"} = 1;
9 our $Verbose;
10
11 =head1 NAME
12
13 Exporter::Heavy - Exporter guts
14
15 =head1 SYNOPIS
16
17 (internal use only)
18
19 =head1 DESCRIPTION
20
21 No user-serviceable parts inside.
22
23 =cut
24
25 #
26 # We go to a lot of trouble not to 'require Carp' at file scope,
27 #  because Carp requires Exporter, and something has to give.
28 #
29
30 sub heavy_export {
31
32     # First make import warnings look like they're coming from the "use".
33     local $SIG{__WARN__} = sub {
34         my $text = shift;
35         if ($text =~ s/ at \S*Exporter\S*.pm line \d+.*\n//) {
36             require Carp;
37             local $Carp::CarpLevel = 1; # ignore package calling us too.
38             Carp::carp($text);
39         }
40         else {
41             warn $text;
42         }
43     };
44     local $SIG{__DIE__} = sub {
45         require Carp;
46         local $Carp::CarpLevel = 1;     # ignore package calling us too.
47         Carp::croak("$_[0]Illegal null symbol in \@${1}::EXPORT")
48             if $_[0] =~ /^Unable to create sub named "(.*?)::"/;
49     };
50
51     my($pkg, $callpkg, @imports) = @_;
52     my($type, $sym, $oops);
53     my($exports, $export_cache) = (\@{"${pkg}::EXPORT"},
54                                    \%{"${pkg}::EXPORT"});
55
56     if (@imports) {
57         if (!%$export_cache) {
58             s/^&// foreach @$exports;
59             @{$export_cache}{@$exports} = (1) x @$exports;
60             my $ok = \@{"${pkg}::EXPORT_OK"};
61             if (@$ok) {
62                 s/^&// foreach @$ok;
63                 @{$export_cache}{@$ok} = (1) x @$ok;
64             }
65         }
66
67         if ($imports[0] =~ m#^[/!:]#){
68             my $tagsref = \%{"${pkg}::EXPORT_TAGS"};
69             my $tagdata;
70             my %imports;
71             my($remove, $spec, @names, @allexports);
72             # negated first item implies starting with default set:
73             unshift @imports, ':DEFAULT' if $imports[0] =~ m/^!/;
74             foreach $spec (@imports){
75                 $remove = $spec =~ s/^!//;
76
77                 if ($spec =~ s/^://){
78                     if ($spec eq 'DEFAULT'){
79                         @names = @$exports;
80                     }
81                     elsif ($tagdata = $tagsref->{$spec}) {
82                         @names = @$tagdata;
83                     }
84                     else {
85                         warn qq["$spec" is not defined in %${pkg}::EXPORT_TAGS];
86                         ++$oops;
87                         next;
88                     }
89                 }
90                 elsif ($spec =~ m:^/(.*)/$:){
91                     my $patn = $1;
92                     @allexports = keys %$export_cache unless @allexports; # only do keys once
93                     @names = grep(/$patn/, @allexports); # not anchored by default
94                 }
95                 else {
96                     @names = ($spec); # is a normal symbol name
97                 }
98
99                 warn "Import ".($remove ? "del":"add").": @names "
100                     if $Verbose;
101
102                 if ($remove) {
103                    foreach $sym (@names) { delete $imports{$sym} } 
104                 }
105                 else {
106                     @imports{@names} = (1) x @names;
107                 }
108             }
109             @imports = keys %imports;
110         }
111
112         my @carp;
113         foreach $sym (@imports) {
114             if (!$export_cache->{$sym}) {
115                 if ($sym =~ m/^\d/) {
116                     $pkg->VERSION($sym); # inherit from UNIVERSAL
117                     # If the version number was the only thing specified
118                     # then we should act as if nothing was specified:
119                     if (@imports == 1) {
120                         @imports = @$exports;
121                         last;
122                     }
123                     # We need a way to emulate 'use Foo ()' but still
124                     # allow an easy version check: "use Foo 1.23, ''";
125                     if (@imports == 2 and !$imports[1]) {
126                         @imports = ();
127                         last;
128                     }
129                 } elsif ($sym !~ s/^&// || !$export_cache->{$sym}) {
130                     # accumulate the non-exports
131                     push @carp,
132                         qq["$sym" is not exported by the $pkg module\n];
133                     $oops++;
134                 }
135             }
136         }
137         if ($oops) {
138             require Carp;
139             Carp::croak("@{carp}Can't continue after import errors");
140         }
141     }
142     else {
143         @imports = @$exports;
144     }
145
146     my($fail, $fail_cache) = (\@{"${pkg}::EXPORT_FAIL"},
147                               \%{"${pkg}::EXPORT_FAIL"});
148
149     if (@$fail) {
150         if (!%$fail_cache) {
151             # Build cache of symbols. Optimise the lookup by adding
152             # barewords twice... both with and without a leading &.
153             # (Technique could be applied to $export_cache at cost of memory)
154             my @expanded = map { /^\w/ ? ($_, '&'.$_) : $_ } @$fail;
155             warn "${pkg}::EXPORT_FAIL cached: @expanded" if $Verbose;
156             @{$fail_cache}{@expanded} = (1) x @expanded;
157         }
158         my @failed;
159         foreach $sym (@imports) { push(@failed, $sym) if $fail_cache->{$sym} }
160         if (@failed) {
161             @failed = $pkg->export_fail(@failed);
162             foreach $sym (@failed) {
163                 require Carp;
164                 Carp::carp(qq["$sym" is not implemented by the $pkg module ],
165                         "on this architecture");
166             }
167             if (@failed) {
168                 require Carp;
169                 Carp::croak("Can't continue after import errors");
170             }
171         }
172     }
173
174     warn "Importing into $callpkg from $pkg: ",
175                 join(", ",sort @imports) if $Verbose;
176
177     foreach $sym (@imports) {
178         # shortcut for the common case of no type character
179         (*{"${callpkg}::$sym"} = \&{"${pkg}::$sym"}, next)
180             unless $sym =~ s/^(\W)//;
181         $type = $1;
182         *{"${callpkg}::$sym"} =
183             $type eq '&' ? \&{"${pkg}::$sym"} :
184             $type eq '$' ? \${"${pkg}::$sym"} :
185             $type eq '@' ? \@{"${pkg}::$sym"} :
186             $type eq '%' ? \%{"${pkg}::$sym"} :
187             $type eq '*' ?  *{"${pkg}::$sym"} :
188             do { require Carp; Carp::croak("Can't export symbol: $type$sym") };
189     }
190 }
191
192 sub heavy_export_to_level
193 {
194       my $pkg = shift;
195       my $level = shift;
196       (undef) = shift;                  # XXX redundant arg
197       my $callpkg = caller($level);
198       $pkg->export($callpkg, @_);
199 }
200
201 # Utility functions
202
203 sub _push_tags {
204     my($pkg, $var, $syms) = @_;
205     my @nontag = ();
206     my $export_tags = \%{"${pkg}::EXPORT_TAGS"};
207     push(@{"${pkg}::$var"},
208         map { $export_tags->{$_} ? @{$export_tags->{$_}} 
209                                  : scalar(push(@nontag,$_),$_) }
210                 (@$syms) ? @$syms : keys %$export_tags);
211     if (@nontag and $^W) {
212         # This may change to a die one day
213         require Carp;
214         Carp::carp(join(", ", @nontag)." are not tags of $pkg");
215     }
216 }
217
218
219 sub require_version {
220     my($self, $wanted) = @_;
221     my $pkg = ref $self || $self;
222     return ${pkg}->VERSION($wanted);
223 }
224
225 1;