This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
ddbed2e63cbae683e7e0cb51c8a0c216cce4d23f
[perl5.git] / t / comp / use.t
1 #!./perl
2
3 BEGIN {
4     chdir 't' if -d 't';
5     @INC = ('../lib', 'lib');
6     $INC{"feature.pm"} = 1; # so we don't attempt to load feature.pm
7 }
8
9 print "1..77\n";
10
11 # Can't require test.pl, as we're testing the use/require mechanism here.
12
13 my $test = 1;
14
15 sub _ok {
16     my ($type, $got, $expected, $name) = @_;
17
18     my $result;
19     if ($type eq 'is') {
20         $result = $got eq $expected;
21     } elsif ($type eq 'isnt') {
22         $result = $got ne $expected;
23     } elsif ($type eq 'like') {
24         $result = $got =~ $expected;
25     } else {
26         die "Unexpected type '$type'$name";
27     }
28     if ($result) {
29         if ($name) {
30             print "ok $test - $name\n";
31         } else {
32             print "ok $test\n";
33         }
34     } else {
35         if ($name) {
36             print "not ok $test - $name\n";
37         } else {
38             print "not ok $test\n";
39         }
40         my @caller = caller(1);
41         print "# Failed test at $caller[1] line $caller[2]\n";
42         print "# Got      '$got'\n";
43         if ($type eq 'is') {
44             print "# Expected '$expected'\n";
45         } elsif ($type eq 'isnt') {
46             print "# Expected not '$expected'\n";
47         } elsif ($type eq 'like') {
48             print "# Expected $expected\n";
49         }
50     }
51     $test = $test + 1;
52     $result;
53 }
54
55 sub like ($$;$) {
56     _ok ('like', @_);
57 }
58 sub is ($$;$) {
59     _ok ('is', @_);
60 }
61 sub isnt ($$;$) {
62     _ok ('isnt', @_);
63 }
64
65 eval "use 5";           # implicit semicolon
66 is ($@, '');
67
68 eval "use 5;";
69 is ($@, '');
70
71 eval "{use 5}";         # [perl #70884]
72 is ($@, '');
73
74 eval "{use 5   }";      # [perl #70884]
75 is ($@, '');
76
77 # new style version numbers
78
79 eval q{ use v5.5.630; };
80 is ($@, '');
81
82 eval q{ use 10.0.2; };
83 like ($@, qr/^Perl v10\.0\.2 required/);
84
85 eval "use 5.000";       # implicit semicolon
86 is ($@, '');
87
88 eval "use 5.000;";
89 is ($@, '');
90
91 eval "use 6.000;";
92 like ($@, qr/Perl v6\.0\.0 required--this is only \Q$^V\E, stopped/);
93
94 eval "no 6.000;";
95 is ($@, '');
96
97 eval "no 5.000;";
98 like ($@, qr/Perls since v5\.0\.0 too modern--this is \Q$^V\E, stopped/);
99
100 eval "use 5.6;";
101 like ($@, qr/Perl v5\.600\.0 required \(did you mean v5\.6\.0\?\)--this is only \Q$^V\E, stopped/);
102
103 eval "use 5.8;";
104 like ($@, qr/Perl v5\.800\.0 required \(did you mean v5\.8\.0\?\)--this is only \Q$^V\E, stopped/);
105
106 eval "use 5.9;";
107 like ($@, qr/Perl v5\.900\.0 required \(did you mean v5\.9\.0\?\)--this is only \Q$^V\E, stopped/);
108
109 eval "use 5.10;";
110 like ($@, qr/Perl v5\.100\.0 required \(did you mean v5\.10\.0\?\)--this is only \Q$^V\E, stopped/);
111
112 eval "use 5.11;";
113 like ($@, qr/Perl v5\.110\.0 required \(did you mean v5\.11\.0\?\)--this is only \Q$^V\E, stopped/);
114
115 eval sprintf "use %.6f;", $];
116 is ($@, '');
117
118
119 eval sprintf "use %.6f;", $] - 0.000001;
120 is ($@, '');
121
122 eval sprintf("use %.6f;", $] + 1);
123 like ($@, qr/Perl v6.\d+.\d+ required--this is only \Q$^V\E, stopped/);
124
125 eval sprintf "use %.6f;", $] + 0.00001;
126 like ($@, qr/Perl v5.\d+.\d+ required--this is only \Q$^V\E, stopped/);
127
128 # check that "use 5.11.0" (and higher) loads strictures
129 eval 'use 5.11.0; ${"foo"} = "bar";';
130 like ($@, qr/Can't use string \("foo"\) as a SCALAR ref while "strict refs" in use/);
131 # but that they can be disabled
132 eval 'use 5.11.0; no strict "refs"; ${"foo"} = "bar";';
133 is ($@, "");
134 # and they are properly scoped
135 eval '{use 5.11.0;} ${"foo"} = "bar";';
136 is ($@, "");
137 eval 'no strict; use 5.012; ${"foo"} = "bar"';
138 is $@, "", 'explicit "no strict" overrides later ver decl';
139 eval 'use strict; use 5.01; ${"foo"} = "bar"';
140 like $@, qr/^Can't use string/,
141     'explicit use strict overrides later use 5.01';
142 eval 'use strict "subs"; use 5.012; ${"foo"} = "bar"';
143 like $@, qr/^Can't use string/,
144     'explicit use strict "subs" does not stop ver decl from enabling refs';
145 eval 'use 5.012; use 5.01; ${"foo"} = "bar"';
146 is $@, "", 'use 5.01 overrides implicit strict from prev ver decl';
147
148
149 { use test_use }        # check that subparse saves pending tokens
150
151 local $test_use::VERSION = 1.0;
152
153 eval "use test_use 0.9";
154 is ($@, '');
155
156 eval "use test_use 1.0";
157 is ($@, '');
158
159 eval "use test_use 1.01";
160 isnt ($@, '');
161
162 eval "use test_use 0.9 qw(fred)";
163 is ($@, '');
164
165 is("@test_use::got", "fred");
166
167 eval "use test_use 1.0 qw(joe)";
168 is ($@, '');
169
170 is("@test_use::got", "joe");
171
172 eval "use test_use 1.01 qw(freda)";
173 isnt($@, '');
174
175 is("@test_use::got", "joe");
176
177 {
178     local $test_use::VERSION = 35.36;
179     eval "use test_use v33.55";
180     is ($@, '');
181
182     eval "use test_use v100.105";
183     like ($@, qr/test_use version v100.105.0 required--this is only version v35\.360\.0/);
184
185     eval "use test_use 33.55";
186     is ($@, '');
187
188     eval "use test_use 100.105";
189     like ($@, qr/test_use version 100.105 required--this is only version 35.36/);
190
191     local $test_use::VERSION = '35.36';
192     eval "use test_use v33.55";
193     like ($@, '');
194
195     eval "use test_use v100.105";
196     like ($@, qr/test_use version v100.105.0 required--this is only version v35\.360\.0/);
197
198     eval "use test_use 33.55";
199     is ($@, '');
200
201     eval "use test_use 100.105";
202     like ($@, qr/test_use version 100.105 required--this is only version 35.36/);
203
204     local $test_use::VERSION = v35.36;
205     eval "use test_use v33.55";
206     is ($@, '');
207
208     eval "use test_use v100.105";
209     like ($@, qr/test_use version v100.105.0 required--this is only version v35\.36\.0/);
210
211     eval "use test_use 33.55";
212     is ($@, '');
213
214     eval "use test_use 100.105";
215     like ($@, qr/test_use version 100.105 required--this is only version v35.36/);
216 }
217
218
219 {
220     # Regression test for patch 14937: 
221     #   Check that a .pm file with no package or VERSION doesn't core.
222     # (git commit 2658f4d9934aba5f8b23afcc078dc12b3a40223)
223     eval "use test_use_14937 3";
224     like ($@, qr/^test_use_14937 defines neither package nor VERSION--version check failed at/);
225 }
226
227 my @ver = split /\./, sprintf "%vd", $^V;
228
229 foreach my $index (-3..+3) {
230     foreach my $v (0, 1) {
231         my @parts = @ver;
232         if ($index) {
233             if ($index < 0) {
234                 # Jiggle one of the parts down
235                 --$parts[-$index - 1];
236                 if ($parts[-$index - 1] < 0) {
237                     # perl's version number ends with '.0'
238                     $parts[-$index - 1] = 0;
239                     $parts[-$index - 2] -= 2;
240                 }
241             } else {
242                 # Jiggle one of the parts up
243                 ++$parts[$index - 1];
244             }
245         }
246         my $v_version = sprintf "v%d.%d.%d", @parts;
247         my $version;
248         if ($v) {
249             $version = $v_version;
250         } else {
251             $version = $parts[0] + $parts[1] / 1000 + $parts[2] / 1000000;
252         }
253
254         eval "use $version";
255         if ($index > 0) {
256             # The future
257             like ($@,
258                   qr/Perl $v_version required--this is only \Q$^V\E, stopped/,
259                   "use $version");
260         } else {
261             # The present or past
262             is ($@, '', "use $version");
263         }
264
265         eval "no $version";
266         if ($index <= 0) {
267             # The present or past
268             like ($@,
269                   qr/Perls since $v_version too modern--this is \Q$^V\E, stopped/,
270                   "no $version");
271         } else {
272             # future
273             is ($@, '', "no $version");
274         }
275     }
276 }
277