This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Typo in perlre
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start or end of the string to matching the start or end of any
35 line anywhere within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as C</ms>, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If locale matching rules are in effect, the case map is taken from the
55 current
56 locale for code points less than 255, and from Unicode rules for larger
57 code points.  However, matches that would cross the Unicode
58 rules/non-Unicode rules boundary (ords 255/256) will not succeed.  See
59 L<perllocale>.
60
61 There are a number of Unicode characters that match multiple characters
62 under C</i>.  For example, C<LATIN SMALL LIGATURE FI>
63 should match the sequence C<fi>.  Perl is not
64 currently able to do this when the multiple characters are in the pattern and
65 are split between groupings, or when one or more are quantified.  Thus
66
67  "\N{LATIN SMALL LIGATURE FI}" =~ /fi/i;          # Matches
68  "\N{LATIN SMALL LIGATURE FI}" =~ /[fi][fi]/i;    # Doesn't match!
69  "\N{LATIN SMALL LIGATURE FI}" =~ /fi*/i;         # Doesn't match!
70
71  # The below doesn't match, and it isn't clear what $1 and $2 would
72  # be even if it did!!
73  "\N{LATIN SMALL LIGATURE FI}" =~ /(f)(i)/i;      # Doesn't match!
74
75 Perl doesn't match multiple characters in an inverted bracketed
76 character class, which otherwise could be highly confusing.  See
77 L<perlrecharclass/Negation>.
78
79 Another bug involves character classes that match both a sequence of
80 multiple characters, and an initial sub-string of that sequence.  For
81 example,
82
83  /[s\xDF]/i
84
85 should match both a single and a double "s", since C<\xDF> (on ASCII
86 platforms) matches "ss".  However, this bug
87 (L<[perl #89774]|https://rt.perl.org/rt3/Ticket/Display.html?id=89774>)
88 causes it to only match a single "s", even if the final larger match
89 fails, and matching the double "ss" would have succeeded.
90
91 Also, Perl matching doesn't fully conform to the current Unicode C</i>
92 recommendations, which ask that the matching be made upon the NFD
93 (Normalization Form Decomposed) of the text.  However, Unicode is
94 in the process of reconsidering and revising their recommendations.
95
96 =item x
97 X</x>
98
99 Extend your pattern's legibility by permitting whitespace and comments.
100 Details in L</"/x">
101
102 =item p
103 X</p> X<regex, preserve> X<regexp, preserve>
104
105 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
106 ${^POSTMATCH} are available for use after matching.
107
108 =item g and c
109 X</g> X</c>
110
111 Global matching, and keep the Current position after failed matching.
112 Unlike i, m, s and x, these two flags affect the way the regex is used
113 rather than the regex itself. See
114 L<perlretut/"Using regular expressions in Perl"> for further explanation
115 of the g and c modifiers.
116
117 =item a, d, l and u
118 X</a> X</d> X</l> X</u>
119
120 These modifiers, all new in 5.14, affect which character-set semantics
121 (Unicode, etc.) are used, as described below in
122 L</Character set modifiers>.
123
124 =back
125
126 Regular expression modifiers are usually written in documentation
127 as e.g., "the C</x> modifier", even though the delimiter
128 in question might not really be a slash.  The modifiers C</imsxadlup>
129 may also be embedded within the regular expression itself using
130 the C<(?...)> construct, see L</Extended Patterns> below.
131
132 =head3 /x
133
134 C</x> tells
135 the regular expression parser to ignore most whitespace that is neither
136 backslashed nor within a character class.  You can use this to break up
137 your regular expression into (slightly) more readable parts.  The C<#>
138 character is also treated as a metacharacter introducing a comment,
139 just as in ordinary Perl code.  This also means that if you want real
140 whitespace or C<#> characters in the pattern (outside a character
141 class, where they are unaffected by C</x>), then you'll either have to
142 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
143 hex, or C<\N{}> escapes.  Taken together, these features go a long way towards
144 making Perl's regular expressions more readable.  Note that you have to
145 be careful not to include the pattern delimiter in the comment--perl has
146 no way of knowing you did not intend to close the pattern early.  See
147 the C-comment deletion code in L<perlop>.  Also note that anything inside
148 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
149 space interpretation within a single multi-character construct.  For
150 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
151 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
152 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<?> and C<:>,
153 but can between the C<(> and C<?>.  Within any delimiters for such a
154 construct, allowed spaces are not affected by C</x>, and depend on the
155 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
156 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
157 in C<\p{...}> there can be spaces that follow the Unicode rules, for which see
158 L<perluniprops/Properties accessible through \p{} and \P{}>.
159 X</x>
160
161 =head3 Character set modifiers
162
163 C</d>, C</u>, C</a>, and C</l>, available starting in 5.14, are called
164 the character set modifiers; they affect the character set semantics
165 used for the regular expression.
166
167 The C</d>, C</u>, and C</l> modifiers are not likely to be of much use
168 to you, and so you need not worry about them very much.  They exist for
169 Perl's internal use, so that complex regular expression data structures
170 can be automatically serialized and later exactly reconstituted,
171 including all their nuances.  But, since Perl can't keep a secret, and
172 there may be rare instances where they are useful, they are documented
173 here.
174
175 The C</a> modifier, on the other hand, may be useful.  Its purpose is to
176 allow code that is to work mostly on ASCII data to not have to concern
177 itself with Unicode.
178
179 Briefly, C</l> sets the character set to that of whatever B<L>ocale is in
180 effect at the time of the execution of the pattern match.
181
182 C</u> sets the character set to B<U>nicode.
183
184 C</a> also sets the character set to Unicode, BUT adds several
185 restrictions for B<A>SCII-safe matching.
186
187 C</d> is the old, problematic, pre-5.14 B<D>efault character set
188 behavior.  Its only use is to force that old behavior.
189
190 At any given time, exactly one of these modifiers is in effect.  Their
191 existence allows Perl to keep the originally compiled behavior of a
192 regular expression, regardless of what rules are in effect when it is
193 actually executed.  And if it is interpolated into a larger regex, the
194 original's rules continue to apply to it, and only it.
195
196 The C</l> and C</u> modifiers are automatically selected for
197 regular expressions compiled within the scope of various pragmas,
198 and we recommend that in general, you use those pragmas instead of
199 specifying these modifiers explicitly.  For one thing, the modifiers
200 affect only pattern matching, and do not extend to even any replacement
201 done, whereas using the pragmas give consistent results for all
202 appropriate operations within their scopes.  For example,
203
204  s/foo/\Ubar/il
205
206 will match "foo" using the locale's rules for case-insensitive matching,
207 but the C</l> does not affect how the C<\U> operates.  Most likely you
208 want both of them to use locale rules.  To do this, instead compile the
209 regular expression within the scope of C<use locale>.  This both
210 implicitly adds the C</l> and applies locale rules to the C<\U>.   The
211 lesson is to C<use locale> and not C</l> explicitly.
212
213 Similarly, it would be better to use C<use feature 'unicode_strings'>
214 instead of,
215
216  s/foo/\Lbar/iu
217
218 to get Unicode rules, as the C<\L> in the former (but not necessarily
219 the latter) would also use Unicode rules.
220
221 More detail on each of the modifiers follows.  Most likely you don't
222 need to know this detail for C</l>, C</u>, and C</d>, and can skip ahead
223 to L<E<sol>a|/E<sol>a (and E<sol>aa)>.
224
225 =head4 /l
226
227 means to use the current locale's rules (see L<perllocale>) when pattern
228 matching.  For example, C<\w> will match the "word" characters of that
229 locale, and C<"/i"> case-insensitive matching will match according to
230 the locale's case folding rules.  The locale used will be the one in
231 effect at the time of execution of the pattern match.  This may not be
232 the same as the compilation-time locale, and can differ from one match
233 to another if there is an intervening call of the
234 L<setlocale() function|perllocale/The setlocale function>.
235
236 Perl only supports single-byte locales.  This means that code points
237 above 255 are treated as Unicode no matter what locale is in effect.
238 Under Unicode rules, there are a few case-insensitive matches that cross
239 the 255/256 boundary.  These are disallowed under C</l>.  For example,
240 0xFF (on ASCII platforms) does not caselessly match the character at
241 0x178, C<LATIN CAPITAL LETTER Y WITH DIAERESIS>, because 0xFF may not be
242 C<LATIN SMALL LETTER Y WITH DIAERESIS> in the current locale, and Perl
243 has no way of knowing if that character even exists in the locale, much
244 less what code point it is.
245
246 This modifier may be specified to be the default by C<use locale>, but
247 see L</Which character set modifier is in effect?>.
248 X</l>
249
250 =head4 /u
251
252 means to use Unicode rules when pattern matching.  On ASCII platforms,
253 this means that the code points between 128 and 255 take on their
254 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's).
255 (Otherwise Perl considers their meanings to be undefined.)  Thus,
256 under this modifier, the ASCII platform effectively becomes a Unicode
257 platform; and hence, for example, C<\w> will match any of the more than
258 100_000 word characters in Unicode.
259
260 Unlike most locales, which are specific to a language and country pair,
261 Unicode classifies all the characters that are letters I<somewhere> in
262 the world as
263 C<\w>.  For example, your locale might not think that C<LATIN SMALL
264 LETTER ETH> is a letter (unless you happen to speak Icelandic), but
265 Unicode does.  Similarly, all the characters that are decimal digits
266 somewhere in the world will match C<\d>; this is hundreds, not 10,
267 possible matches.  And some of those digits look like some of the 10
268 ASCII digits, but mean a different number, so a human could easily think
269 a number is a different quantity than it really is.  For example,
270 C<BENGALI DIGIT FOUR> (U+09EA) looks very much like an
271 C<ASCII DIGIT EIGHT> (U+0038).  And, C<\d+>, may match strings of digits
272 that are a mixture from different writing systems, creating a security
273 issue.  L<Unicode::UCD/num()> can be used to sort
274 this out.  Or the C</a> modifier can be used to force C<\d> to match
275 just the ASCII 0 through 9.
276
277 Also, under this modifier, case-insensitive matching works on the full
278 set of Unicode
279 characters.  The C<KELVIN SIGN>, for example matches the letters "k" and
280 "K"; and C<LATIN SMALL LIGATURE FF> matches the sequence "ff", which,
281 if you're not prepared, might make it look like a hexadecimal constant,
282 presenting another potential security issue.  See
283 L<http://unicode.org/reports/tr36> for a detailed discussion of Unicode
284 security issues.
285
286 On the EBCDIC platforms that Perl handles, the native character set is
287 equivalent to Latin-1.  Thus this modifier changes behavior only when
288 the C<"/i"> modifier is also specified, and it turns out it affects only
289 two characters, giving them full Unicode semantics: the C<MICRO SIGN>
290 will match the Greek capital and small letters C<MU>, otherwise not; and
291 the C<LATIN CAPITAL LETTER SHARP S> will match any of C<SS>, C<Ss>,
292 C<sS>, and C<ss>, otherwise not.
293
294 This modifier may be specified to be the default by C<use feature
295 'unicode_strings> or C<L<use 5.012|perlfunc/use VERSION>> (or higher),
296 but see L</Which character set modifier is in effect?>.
297 X</u>
298
299 =head4 /d
300
301 This modifier means to use the "Default" native rules of the platform
302 except when there is cause to use Unicode rules instead, as follows:
303
304 =over 4
305
306 =item 1
307
308 the target string is encoded in UTF-8; or
309
310 =item 2
311
312 the pattern is encoded in UTF-8; or
313
314 =item 3
315
316 the pattern explicitly mentions a code point that is above 255 (say by
317 C<\x{100}>); or
318
319 =item 4
320
321 the pattern uses a Unicode name (C<\N{...}>);  or
322
323 =item 5
324
325 the pattern uses a Unicode property (C<\p{...}>)
326
327 =back
328
329 Another mnemonic for this modifier is "Depends", as the rules actually
330 used depend on various things, and as a result you can get unexpected
331 results.  See L<perlunicode/The "Unicode Bug">.  The Unicode Bug has
332 become rather infamous, leading to yet another (printable) name for this
333 modifier, "Dodgy".
334
335 On ASCII platforms, the native rules are ASCII, and on EBCDIC platforms
336 (at least the ones that Perl handles), they are Latin-1.
337
338 Here are some examples of how that works on an ASCII platform:
339
340  $str =  "\xDF";      # $str is not in UTF-8 format.
341  $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
342  $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
343  $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
344  chop $str;
345  $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
346
347 This modifier is automatically selected by default when none of the
348 others are, so yet another name for it is "Default".
349
350 Because of the unexpected behaviors associated with this modifier, you
351 probably should only use it to maintain weird backward compatibilities.
352
353 =head4 /a (and /aa)
354
355 This modifier stands for ASCII-restrict (or ASCII-safe).  This modifier,
356 unlike the others, may be doubled-up to increase its effect.
357
358 When it appears singly, it causes the sequences C<\d>, C<\s>, C<\w>, and
359 the Posix character classes to match only in the ASCII range.  They thus
360 revert to their pre-5.6, pre-Unicode meanings.  Under C</a>,  C<\d>
361 always means precisely the digits C<"0"> to C<"9">; C<\s> means the five
362 characters C<[ \f\n\r\t]>; C<\w> means the 63 characters
363 C<[A-Za-z0-9_]>; and likewise, all the Posix classes such as
364 C<[[:print:]]> match only the appropriate ASCII-range characters.
365
366 This modifier is useful for people who only incidentally use Unicode,
367 and who do not wish to be burdened with its complexities and security
368 concerns.
369
370 With C</a>, one can write C<\d> with confidence that it will only match
371 ASCII characters, and should the need arise to match beyond ASCII, you
372 can instead use C<\p{Digit}> (or C<\p{Word}> for C<\w>).  There are
373 similar C<\p{...}> constructs that can match beyond ASCII both white
374 space (see L<perlrecharclass/Whitespace>), and Posix classes (see
375 L<perlrecharclass/POSIX Character Classes>).  Thus, this modifier
376 doesn't mean you can't use Unicode, it means that to get Unicode
377 matching you must explicitly use a construct (C<\p{}>, C<\P{}>) that
378 signals Unicode.
379
380 As you would expect, this modifier causes, for example, C<\D> to mean
381 the same thing as C<[^0-9]>; in fact, all non-ASCII characters match
382 C<\D>, C<\S>, and C<\W>.  C<\b> still means to match at the boundary
383 between C<\w> and C<\W>, using the C</a> definitions of them (similarly
384 for C<\B>).
385
386 Otherwise, C</a> behaves like the C</u> modifier, in that
387 case-insensitive matching uses Unicode semantics; for example, "k" will
388 match the Unicode C<\N{KELVIN SIGN}> under C</i> matching, and code
389 points in the Latin1 range, above ASCII will have Unicode rules when it
390 comes to case-insensitive matching.
391
392 To forbid ASCII/non-ASCII matches (like "k" with C<\N{KELVIN SIGN}>),
393 specify the "a" twice, for example C</aai> or C</aia>.  (The first
394 occurrence of "a" restricts the C<\d>, etc., and the second occurrence
395 adds the C</i> restrictions.)  But, note that code points outside the
396 ASCII range will use Unicode rules for C</i> matching, so the modifier
397 doesn't really restrict things to just ASCII; it just forbids the
398 intermixing of ASCII and non-ASCII.
399
400 To summarize, this modifier provides protection for applications that
401 don't wish to be exposed to all of Unicode.  Specifying it twice
402 gives added protection.
403
404 This modifier may be specified to be the default by C<use re '/a'>
405 or C<use re '/aa'>.  If you do so, you may actually have occasion to use
406 the C</u> modifier explictly if there are a few regular expressions
407 where you do want full Unicode rules (but even here, it's best if
408 everything were under feature C<"unicode_strings">, along with the
409 C<use re '/aa'>).  Also see L</Which character set modifier is in
410 effect?>.
411 X</a>
412 X</aa>
413
414 =head4 Which character set modifier is in effect?
415
416 Which of these modifiers is in effect at any given point in a regular
417 expression depends on a fairly complex set of interactions.  These have
418 been designed so that in general you don't have to worry about it, but
419 this section gives the gory details.  As
420 explained below in L</Extended Patterns> it is possible to explicitly
421 specify modifiers that apply only to portions of a regular expression.
422 The innermost always has priority over any outer ones, and one applying
423 to the whole expression has priority over any of the default settings that are
424 described in the remainder of this section.
425
426 The C<L<use re 'E<sol>foo'|re/"'/flags' mode">> pragma can be used to set
427 default modifiers (including these) for regular expressions compiled
428 within its scope.  This pragma has precedence over the other pragmas
429 listed below that also change the defaults.
430
431 Otherwise, C<L<use locale|perllocale>> sets the default modifier to C</l>;
432 and C<L<use feature 'unicode_strings|feature>> or
433 C<L<use 5.012|perlfunc/use VERSION>> (or higher) set the default to
434 C</u> when not in the same scope as either C<L<use locale|perllocale>>
435 or C<L<use bytes|bytes>>.  Unlike the mechanisms mentioned above, these
436 affect operations besides regular expressions pattern matching, and so
437 give more consistent results with other operators, including using
438 C<\U>, C<\l>, etc. in substitution replacements.
439
440 If none of the above apply, for backwards compatibility reasons, the
441 C</d> modifier is the one in effect by default.  As this can lead to
442 unexpected results, it is best to specify which other rule set should be
443 used.
444
445 =head4 Character set modifier behavior prior to Perl 5.14
446
447 Prior to 5.14, there were no explicit modifiers, but C</l> was implied
448 for regexes compiled within the scope of C<use locale>, and C</d> was
449 implied otherwise.  However, interpolating a regex into a larger regex
450 would ignore the original compilation in favor of whatever was in effect
451 at the time of the second compilation.  There were a number of
452 inconsistencies (bugs) with the C</d> modifier, where Unicode rules
453 would be used when inappropriate, and vice versa.  C<\p{}> did not imply
454 Unicode rules, and neither did all occurrences of C<\N{}>, until 5.12.
455
456 =head2 Regular Expressions
457
458 =head3 Metacharacters
459
460 The patterns used in Perl pattern matching evolved from those supplied in
461 the Version 8 regex routines.  (The routines are derived
462 (distantly) from Henry Spencer's freely redistributable reimplementation
463 of the V8 routines.)  See L<Version 8 Regular Expressions> for
464 details.
465
466 In particular the following metacharacters have their standard I<egrep>-ish
467 meanings:
468 X<metacharacter>
469 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
470
471
472     \        Quote the next metacharacter
473     ^        Match the beginning of the line
474     .        Match any character (except newline)
475     $        Match the end of the line (or before newline at the end)
476     |        Alternation
477     ()       Grouping
478     []       Bracketed Character class
479
480 By default, the "^" character is guaranteed to match only the
481 beginning of the string, the "$" character only the end (or before the
482 newline at the end), and Perl does certain optimizations with the
483 assumption that the string contains only one line.  Embedded newlines
484 will not be matched by "^" or "$".  You may, however, wish to treat a
485 string as a multi-line buffer, such that the "^" will match after any
486 newline within the string (except if the newline is the last character in
487 the string), and "$" will match before any newline.  At the
488 cost of a little more overhead, you can do this by using the /m modifier
489 on the pattern match operator.  (Older programs did this by setting C<$*>,
490 but this option was removed in perl 5.9.)
491 X<^> X<$> X</m>
492
493 To simplify multi-line substitutions, the "." character never matches a
494 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
495 the string is a single line--even if it isn't.
496 X<.> X</s>
497
498 =head3 Quantifiers
499
500 The following standard quantifiers are recognized:
501 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
502
503     *           Match 0 or more times
504     +           Match 1 or more times
505     ?           Match 1 or 0 times
506     {n}         Match exactly n times
507     {n,}        Match at least n times
508     {n,m}       Match at least n but not more than m times
509
510 (If a curly bracket occurs in any other context and does not form part of
511 a backslashed sequence like C<\x{...}>, it is treated
512 as a regular character.  In particular, the lower bound
513 is not optional.)  The "*" quantifier is equivalent to C<{0,}>, the "+"
514 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
515 to non-negative integral values less than a preset limit defined when perl is built.
516 This is usually 32766 on the most common platforms.  The actual limit can
517 be seen in the error message generated by code such as this:
518
519     $_ **= $_ , / {$_} / for 2 .. 42;
520
521 By default, a quantified subpattern is "greedy", that is, it will match as
522 many times as possible (given a particular starting location) while still
523 allowing the rest of the pattern to match.  If you want it to match the
524 minimum number of times possible, follow the quantifier with a "?".  Note
525 that the meanings don't change, just the "greediness":
526 X<metacharacter> X<greedy> X<greediness>
527 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
528
529     *?        Match 0 or more times, not greedily
530     +?        Match 1 or more times, not greedily
531     ??        Match 0 or 1 time, not greedily
532     {n}?      Match exactly n times, not greedily (redundant)
533     {n,}?     Match at least n times, not greedily
534     {n,m}?    Match at least n but not more than m times, not greedily
535
536 By default, when a quantified subpattern does not allow the rest of the
537 overall pattern to match, Perl will backtrack. However, this behaviour is
538 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
539 as well.
540
541  *+     Match 0 or more times and give nothing back
542  ++     Match 1 or more times and give nothing back
543  ?+     Match 0 or 1 time and give nothing back
544  {n}+   Match exactly n times and give nothing back (redundant)
545  {n,}+  Match at least n times and give nothing back
546  {n,m}+ Match at least n but not more than m times and give nothing back
547
548 For instance,
549
550    'aaaa' =~ /a++a/
551
552 will never match, as the C<a++> will gobble up all the C<a>'s in the
553 string and won't leave any for the remaining part of the pattern. This
554 feature can be extremely useful to give perl hints about where it
555 shouldn't backtrack. For instance, the typical "match a double-quoted
556 string" problem can be most efficiently performed when written as:
557
558    /"(?:[^"\\]++|\\.)*+"/
559
560 as we know that if the final quote does not match, backtracking will not
561 help. See the independent subexpression
562 L</C<< (?>pattern) >>> for more details;
563 possessive quantifiers are just syntactic sugar for that construct. For
564 instance the above example could also be written as follows:
565
566    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
567
568 =head3 Escape sequences
569
570 Because patterns are processed as double-quoted strings, the following
571 also work:
572
573  \t          tab                   (HT, TAB)
574  \n          newline               (LF, NL)
575  \r          return                (CR)
576  \f          form feed             (FF)
577  \a          alarm (bell)          (BEL)
578  \e          escape (think troff)  (ESC)
579  \cK         control char          (example: VT)
580  \x{}, \x00  character whose ordinal is the given hexadecimal number
581  \N{name}    named Unicode character or character sequence
582  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
583  \o{}, \000  character whose ordinal is the given octal number
584  \l          lowercase next char (think vi)
585  \u          uppercase next char (think vi)
586  \L          lowercase till \E (think vi)
587  \U          uppercase till \E (think vi)
588  \Q          quote (disable) pattern metacharacters till \E
589  \E          end either case modification or quoted section, think vi
590
591 Details are in L<perlop/Quote and Quote-like Operators>.
592
593 =head3 Character Classes and other Special Escapes
594
595 In addition, Perl defines the following:
596 X<\g> X<\k> X<\K> X<backreference>
597
598  Sequence   Note    Description
599   [...]     [1]  Match a character according to the rules of the
600                    bracketed character class defined by the "...".
601                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
602   [[:...:]] [2]  Match a character according to the rules of the POSIX
603                    character class "..." within the outer bracketed
604                    character class.  Example: [[:upper:]] matches any
605                    uppercase character.
606   \w        [3]  Match a "word" character (alphanumeric plus "_", plus
607                    other connector punctuation chars plus Unicode
608                    marks)
609   \W        [3]  Match a non-"word" character
610   \s        [3]  Match a whitespace character
611   \S        [3]  Match a non-whitespace character
612   \d        [3]  Match a decimal digit character
613   \D        [3]  Match a non-digit character
614   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
615   \PP       [3]  Match non-P
616   \X        [4]  Match Unicode "eXtended grapheme cluster"
617   \C             Match a single C-language char (octet) even if that is
618                    part of a larger UTF-8 character.  Thus it breaks up
619                    characters into their UTF-8 bytes, so you may end up
620                    with malformed pieces of UTF-8.  Unsupported in
621                    lookbehind.
622   \1        [5]  Backreference to a specific capture group or buffer.
623                    '1' may actually be any positive integer.
624   \g1       [5]  Backreference to a specific or previous group,
625   \g{-1}    [5]  The number may be negative indicating a relative
626                    previous group and may optionally be wrapped in
627                    curly brackets for safer parsing.
628   \g{name}  [5]  Named backreference
629   \k<name>  [5]  Named backreference
630   \K        [6]  Keep the stuff left of the \K, don't include it in $&
631   \N        [7]  Any character but \n (experimental).  Not affected by
632                    /s modifier
633   \v        [3]  Vertical whitespace
634   \V        [3]  Not vertical whitespace
635   \h        [3]  Horizontal whitespace
636   \H        [3]  Not horizontal whitespace
637   \R        [4]  Linebreak
638
639 =over 4
640
641 =item [1]
642
643 See L<perlrecharclass/Bracketed Character Classes> for details.
644
645 =item [2]
646
647 See L<perlrecharclass/POSIX Character Classes> for details.
648
649 =item [3]
650
651 See L<perlrecharclass/Backslash sequences> for details.
652
653 =item [4]
654
655 See L<perlrebackslash/Misc> for details.
656
657 =item [5]
658
659 See L</Capture groups> below for details.
660
661 =item [6]
662
663 See L</Extended Patterns> below for details.
664
665 =item [7]
666
667 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
668 character or character sequence whose name is C<NAME>; and similarly
669 when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode
670 code point is I<hex>.  Otherwise it matches any character but C<\n>.
671
672 =back
673
674 =head3 Assertions
675
676 Perl defines the following zero-width assertions:
677 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
678 X<regexp, zero-width assertion>
679 X<regular expression, zero-width assertion>
680 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
681
682     \b  Match a word boundary
683     \B  Match except at a word boundary
684     \A  Match only at beginning of string
685     \Z  Match only at end of string, or before newline at the end
686     \z  Match only at end of string
687     \G  Match only at pos() (e.g. at the end-of-match position
688         of prior m//g)
689
690 A word boundary (C<\b>) is a spot between two characters
691 that has a C<\w> on one side of it and a C<\W> on the other side
692 of it (in either order), counting the imaginary characters off the
693 beginning and end of the string as matching a C<\W>.  (Within
694 character classes C<\b> represents backspace rather than a word
695 boundary, just as it normally does in any double-quoted string.)
696 The C<\A> and C<\Z> are just like "^" and "$", except that they
697 won't match multiple times when the C</m> modifier is used, while
698 "^" and "$" will match at every internal line boundary.  To match
699 the actual end of the string and not ignore an optional trailing
700 newline, use C<\z>.
701 X<\b> X<\A> X<\Z> X<\z> X</m>
702
703 The C<\G> assertion can be used to chain global matches (using
704 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
705 It is also useful when writing C<lex>-like scanners, when you have
706 several patterns that you want to match against consequent substrings
707 of your string; see the previous reference.  The actual location
708 where C<\G> will match can also be influenced by using C<pos()> as
709 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
710 matches (see L</"Repeated Patterns Matching a Zero-length Substring">)
711 is modified somewhat, in that contents to the left of C<\G> are
712 not counted when determining the length of the match. Thus the following
713 will not match forever:
714 X<\G>
715
716      my $string = 'ABC';
717      pos($string) = 1;
718      while ($string =~ /(.\G)/g) {
719          print $1;
720      }
721
722 It will print 'A' and then terminate, as it considers the match to
723 be zero-width, and thus will not match at the same position twice in a
724 row.
725
726 It is worth noting that C<\G> improperly used can result in an infinite
727 loop. Take care when using patterns that include C<\G> in an alternation.
728
729 =head3 Capture groups
730
731 The bracketing construct C<( ... )> creates capture groups (also referred to as
732 capture buffers). To refer to the current contents of a group later on, within
733 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
734 for the second, and so on.
735 This is called a I<backreference>.
736 X<regex, capture buffer> X<regexp, capture buffer>
737 X<regex, capture group> X<regexp, capture group>
738 X<regular expression, capture buffer> X<backreference>
739 X<regular expression, capture group> X<backreference>
740 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
741 X<named capture buffer> X<regular expression, named capture buffer>
742 X<named capture group> X<regular expression, named capture group>
743 X<%+> X<$+{name}> X<< \k<name> >>
744 There is no limit to the number of captured substrings that you may use.
745 Groups are numbered with the leftmost open parenthesis being number 1, etc.  If
746 a group did not match, the associated backreference won't match either. (This
747 can happen if the group is optional, or in a different branch of an
748 alternation.)
749 You can omit the C<"g">, and write C<"\1">, etc, but there are some issues with
750 this form, described below.
751
752 You can also refer to capture groups relatively, by using a negative number, so
753 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
754 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
755 example:
756
757         /
758          (Y)            # group 1
759          (              # group 2
760             (X)         # group 3
761             \g{-1}      # backref to group 3
762             \g{-3}      # backref to group 1
763          )
764         /x
765
766 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
767 interpolate regexes into larger regexes and not have to worry about the
768 capture groups being renumbered.
769
770 You can dispense with numbers altogether and create named capture groups.
771 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
772 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
773 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
774 I<name> must not begin with a number, nor contain hyphens.
775 When different groups within the same pattern have the same name, any reference
776 to that name assumes the leftmost defined group.  Named groups count in
777 absolute and relative numbering, and so can also be referred to by those
778 numbers.
779 (It's possible to do things with named capture groups that would otherwise
780 require C<(??{})>.)
781
782 Capture group contents are dynamically scoped and available to you outside the
783 pattern until the end of the enclosing block or until the next successful
784 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
785 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
786 etc); or by name via the C<%+> hash, using C<"$+{I<name>}">.
787
788 Braces are required in referring to named capture groups, but are optional for
789 absolute or relative numbered ones.  Braces are safer when creating a regex by
790 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
791 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
792 is probably not what you intended.
793
794 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
795 there were no named nor relative numbered capture groups.  Absolute numbered
796 groups were referred to using C<\1>,
797 C<\2>, etc., and this notation is still
798 accepted (and likely always will be).  But it leads to some ambiguities if
799 there are more than 9 capture groups, as C<\10> could mean either the tenth
800 capture group, or the character whose ordinal in octal is 010 (a backspace in
801 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
802 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
803 a backreference only if at least 11 left parentheses have opened before it.
804 And so on.  C<\1> through C<\9> are always interpreted as backreferences.
805 There are several examples below that illustrate these perils.  You can avoid
806 the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups;
807 and for octal constants always using C<\o{}>, or for C<\077> and below, using 3
808 digits padded with leading zeros, since a leading zero implies an octal
809 constant.
810
811 The C<\I<digit>> notation also works in certain circumstances outside
812 the pattern.  See L</Warning on \1 Instead of $1> below for details.
813
814 Examples:
815
816     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
817
818     /(.)\g1/                        # find first doubled char
819          and print "'$1' is the first doubled character\n";
820
821     /(?<char>.)\k<char>/            # ... a different way
822          and print "'$+{char}' is the first doubled character\n";
823
824     /(?'char'.)\g1/                 # ... mix and match
825          and print "'$1' is the first doubled character\n";
826
827     if (/Time: (..):(..):(..)/) {   # parse out values
828         $hours = $1;
829         $minutes = $2;
830         $seconds = $3;
831     }
832
833     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
834     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
835     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
836     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
837
838     $a = '(.)\1';        # Creates problems when concatenated.
839     $b = '(.)\g{1}';     # Avoids the problems.
840     "aa" =~ /${a}/;      # True
841     "aa" =~ /${b}/;      # True
842     "aa0" =~ /${a}0/;    # False!
843     "aa0" =~ /${b}0/;    # True
844     "aa\x08" =~ /${a}0/;  # True!
845     "aa\x08" =~ /${b}0/;  # False
846
847 Several special variables also refer back to portions of the previous
848 match.  C<$+> returns whatever the last bracket match matched.
849 C<$&> returns the entire matched string.  (At one point C<$0> did
850 also, but now it returns the name of the program.)  C<$`> returns
851 everything before the matched string.  C<$'> returns everything
852 after the matched string. And C<$^N> contains whatever was matched by
853 the most-recently closed group (submatch). C<$^N> can be used in
854 extended patterns (see below), for example to assign a submatch to a
855 variable.
856 X<$+> X<$^N> X<$&> X<$`> X<$'>
857
858 These special variables, like the C<%+> hash and the numbered match variables
859 (C<$1>, C<$2>, C<$3>, etc.) are dynamically scoped
860 until the end of the enclosing block or until the next successful
861 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
862 X<$+> X<$^N> X<$&> X<$`> X<$'>
863 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
864
865 B<NOTE>: Failed matches in Perl do not reset the match variables,
866 which makes it easier to write code that tests for a series of more
867 specific cases and remembers the best match.
868
869 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
870 C<$'> anywhere in the program, it has to provide them for every
871 pattern match.  This may substantially slow your program.  Perl
872 uses the same mechanism to produce C<$1>, C<$2>, etc, so you also pay a
873 price for each pattern that contains capturing parentheses.  (To
874 avoid this cost while retaining the grouping behaviour, use the
875 extended regular expression C<(?: ... )> instead.)  But if you never
876 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
877 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
878 if you can, but if you can't (and some algorithms really appreciate
879 them), once you've used them once, use them at will, because you've
880 already paid the price.  As of 5.005, C<$&> is not so costly as the
881 other two.
882 X<$&> X<$`> X<$'>
883
884 As a workaround for this problem, Perl 5.10.0 introduces C<${^PREMATCH}>,
885 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
886 and C<$'>, B<except> that they are only guaranteed to be defined after a
887 successful match that was executed with the C</p> (preserve) modifier.
888 The use of these variables incurs no global performance penalty, unlike
889 their punctuation char equivalents, however at the trade-off that you
890 have to tell perl when you want to use them.
891 X</p> X<p modifier>
892
893 =head2 Quoting metacharacters
894
895 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
896 C<\w>, C<\n>.  Unlike some other regular expression languages, there
897 are no backslashed symbols that aren't alphanumeric.  So anything
898 that looks like \\, \(, \), \<, \>, \{, or \} is always
899 interpreted as a literal character, not a metacharacter.  This was
900 once used in a common idiom to disable or quote the special meanings
901 of regular expression metacharacters in a string that you want to
902 use for a pattern. Simply quote all non-"word" characters:
903
904     $pattern =~ s/(\W)/\\$1/g;
905
906 (If C<use locale> is set, then this depends on the current locale.)
907 Today it is more common to use the quotemeta() function or the C<\Q>
908 metaquoting escape sequence to disable all metacharacters' special
909 meanings like this:
910
911     /$unquoted\Q$quoted\E$unquoted/
912
913 Beware that if you put literal backslashes (those not inside
914 interpolated variables) between C<\Q> and C<\E>, double-quotish
915 backslash interpolation may lead to confusing results.  If you
916 I<need> to use literal backslashes within C<\Q...\E>,
917 consult L<perlop/"Gory details of parsing quoted constructs">.
918
919 =head2 Extended Patterns
920
921 Perl also defines a consistent extension syntax for features not
922 found in standard tools like B<awk> and
923 B<lex>.  The syntax for most of these is a
924 pair of parentheses with a question mark as the first thing within
925 the parentheses.  The character after the question mark indicates
926 the extension.
927
928 The stability of these extensions varies widely.  Some have been
929 part of the core language for many years.  Others are experimental
930 and may change without warning or be completely removed.  Check
931 the documentation on an individual feature to verify its current
932 status.
933
934 A question mark was chosen for this and for the minimal-matching
935 construct because 1) question marks are rare in older regular
936 expressions, and 2) whenever you see one, you should stop and
937 "question" exactly what is going on.  That's psychology....
938
939 =over 4
940
941 =item C<(?#text)>
942 X<(?#)>
943
944 A comment.  The text is ignored.  If the C</x> modifier enables
945 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
946 the comment as soon as it sees a C<)>, so there is no way to put a literal
947 C<)> in the comment.
948
949 =item C<(?adlupimsx-imsx)>
950
951 =item C<(?^alupimsx)>
952 X<(?)> X<(?^)>
953
954 One or more embedded pattern-match modifiers, to be turned on (or
955 turned off, if preceded by C<->) for the remainder of the pattern or
956 the remainder of the enclosing pattern group (if any).
957
958 This is particularly useful for dynamic patterns, such as those read in from a
959 configuration file, taken from an argument, or specified in a table
960 somewhere.  Consider the case where some patterns want to be
961 case-sensitive and some do not:  The case-insensitive ones merely need to
962 include C<(?i)> at the front of the pattern.  For example:
963
964     $pattern = "foobar";
965     if ( /$pattern/i ) { }
966
967     # more flexible:
968
969     $pattern = "(?i)foobar";
970     if ( /$pattern/ ) { }
971
972 These modifiers are restored at the end of the enclosing group. For example,
973
974     ( (?i) blah ) \s+ \g1
975
976 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
977 repetition of the previous word, assuming the C</x> modifier, and no C</i>
978 modifier outside this group.
979
980 These modifiers do not carry over into named subpatterns called in the
981 enclosing group. In other words, a pattern such as C<((?i)(?&NAME))> does not
982 change the case-sensitivity of the "NAME" pattern.
983
984 Any of these modifiers can be set to apply globally to all regular
985 expressions compiled within the scope of a C<use re>.  See
986 L<re/"'/flags' mode">.
987
988 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
989 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Flags (except
990 C<"d">) may follow the caret to override it.
991 But a minus sign is not legal with it.
992
993 Note that the C<a>, C<d>, C<l>, C<p>, and C<u> modifiers are special in
994 that they can only be enabled, not disabled, and the C<a>, C<d>, C<l>, and
995 C<u> modifiers are mutually exclusive: specifying one de-specifies the
996 others, and a maximum of one (or two C<a>'s) may appear in the
997 construct.  Thus, for
998 example, C<(?-p)> will warn when compiled under C<use warnings>;
999 C<(?-d:...)> and C<(?dl:...)> are fatal errors.
1000
1001 Note also that the C<p> modifier is special in that its presence
1002 anywhere in a pattern has a global effect.
1003
1004 =item C<(?:pattern)>
1005 X<(?:)>
1006
1007 =item C<(?adluimsx-imsx:pattern)>
1008
1009 =item C<(?^aluimsx:pattern)>
1010 X<(?^:)>
1011
1012 This is for clustering, not capturing; it groups subexpressions like
1013 "()", but doesn't make backreferences as "()" does.  So
1014
1015     @fields = split(/\b(?:a|b|c)\b/)
1016
1017 is like
1018
1019     @fields = split(/\b(a|b|c)\b/)
1020
1021 but doesn't spit out extra fields.  It's also cheaper not to capture
1022 characters if you don't need to.
1023
1024 Any letters between C<?> and C<:> act as flags modifiers as with
1025 C<(?adluimsx-imsx)>.  For example,
1026
1027     /(?s-i:more.*than).*million/i
1028
1029 is equivalent to the more verbose
1030
1031     /(?:(?s-i)more.*than).*million/i
1032
1033 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1034 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Any positive
1035 flags (except C<"d">) may follow the caret, so
1036
1037     (?^x:foo)
1038
1039 is equivalent to
1040
1041     (?x-ims:foo)
1042
1043 The caret tells Perl that this cluster doesn't inherit the flags of any
1044 surrounding pattern, but uses the system defaults (C<d-imsx>),
1045 modified by any flags specified.
1046
1047 The caret allows for simpler stringification of compiled regular
1048 expressions.  These look like
1049
1050     (?^:pattern)
1051
1052 with any non-default flags appearing between the caret and the colon.
1053 A test that looks at such stringification thus doesn't need to have the
1054 system default flags hard-coded in it, just the caret.  If new flags are
1055 added to Perl, the meaning of the caret's expansion will change to include
1056 the default for those flags, so the test will still work, unchanged.
1057
1058 Specifying a negative flag after the caret is an error, as the flag is
1059 redundant.
1060
1061 Mnemonic for C<(?^...)>:  A fresh beginning since the usual use of a caret is
1062 to match at the beginning.
1063
1064 =item C<(?|pattern)>
1065 X<(?|)> X<Branch reset>
1066
1067 This is the "branch reset" pattern, which has the special property
1068 that the capture groups are numbered from the same starting point
1069 in each alternation branch. It is available starting from perl 5.10.0.
1070
1071 Capture groups are numbered from left to right, but inside this
1072 construct the numbering is restarted for each branch.
1073
1074 The numbering within each branch will be as normal, and any groups
1075 following this construct will be numbered as though the construct
1076 contained only one branch, that being the one with the most capture
1077 groups in it.
1078
1079 This construct is useful when you want to capture one of a
1080 number of alternative matches.
1081
1082 Consider the following pattern.  The numbers underneath show in
1083 which group the captured content will be stored.
1084
1085
1086     # before  ---------------branch-reset----------- after        
1087     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
1088     # 1            2         2  3        2     3     4  
1089
1090 Be careful when using the branch reset pattern in combination with 
1091 named captures. Named captures are implemented as being aliases to 
1092 numbered groups holding the captures, and that interferes with the
1093 implementation of the branch reset pattern. If you are using named
1094 captures in a branch reset pattern, it's best to use the same names,
1095 in the same order, in each of the alternations:
1096
1097    /(?|  (?<a> x ) (?<b> y )
1098       |  (?<a> z ) (?<b> w )) /x
1099
1100 Not doing so may lead to surprises:
1101
1102   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
1103   say $+ {a};   # Prints '12'
1104   say $+ {b};   # *Also* prints '12'.
1105
1106 The problem here is that both the group named C<< a >> and the group
1107 named C<< b >> are aliases for the group belonging to C<< $1 >>.
1108
1109 =item Look-Around Assertions
1110 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
1111
1112 Look-around assertions are zero-width patterns which match a specific
1113 pattern without including it in C<$&>. Positive assertions match when
1114 their subpattern matches, negative assertions match when their subpattern
1115 fails. Look-behind matches text up to the current match position,
1116 look-ahead matches text following the current match position.
1117
1118 =over 4
1119
1120 =item C<(?=pattern)>
1121 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
1122
1123 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
1124 matches a word followed by a tab, without including the tab in C<$&>.
1125
1126 =item C<(?!pattern)>
1127 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
1128
1129 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
1130 matches any occurrence of "foo" that isn't followed by "bar".  Note
1131 however that look-ahead and look-behind are NOT the same thing.  You cannot
1132 use this for look-behind.
1133
1134 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
1135 will not do what you want.  That's because the C<(?!foo)> is just saying that
1136 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
1137 match.  Use look-behind instead (see below).
1138
1139 =item C<(?<=pattern)> C<\K>
1140 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
1141
1142 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
1143 matches a word that follows a tab, without including the tab in C<$&>.
1144 Works only for fixed-width look-behind.
1145
1146 There is a special form of this construct, called C<\K>, which causes the
1147 regex engine to "keep" everything it had matched prior to the C<\K> and
1148 not include it in C<$&>. This effectively provides variable-length
1149 look-behind. The use of C<\K> inside of another look-around assertion
1150 is allowed, but the behaviour is currently not well defined.
1151
1152 For various reasons C<\K> may be significantly more efficient than the
1153 equivalent C<< (?<=...) >> construct, and it is especially useful in
1154 situations where you want to efficiently remove something following
1155 something else in a string. For instance
1156
1157   s/(foo)bar/$1/g;
1158
1159 can be rewritten as the much more efficient
1160
1161   s/foo\Kbar//g;
1162
1163 =item C<(?<!pattern)>
1164 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
1165
1166 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
1167 matches any occurrence of "foo" that does not follow "bar".  Works
1168 only for fixed-width look-behind.
1169
1170 =back
1171
1172 =item C<(?'NAME'pattern)>
1173
1174 =item C<< (?<NAME>pattern) >>
1175 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
1176
1177 A named capture group. Identical in every respect to normal capturing
1178 parentheses C<()> but for the additional fact that the group
1179 can be referred to by name in various regular expression
1180 constructs (like C<\g{NAME}>) and can be accessed by name
1181 after a successful match via C<%+> or C<%->. See L<perlvar>
1182 for more details on the C<%+> and C<%-> hashes.
1183
1184 If multiple distinct capture groups have the same name then the
1185 $+{NAME} will refer to the leftmost defined group in the match.
1186
1187 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
1188
1189 B<NOTE:> While the notation of this construct is the same as the similar
1190 function in .NET regexes, the behavior is not. In Perl the groups are
1191 numbered sequentially regardless of being named or not. Thus in the
1192 pattern
1193
1194   /(x)(?<foo>y)(z)/
1195
1196 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
1197 the opposite which is what a .NET regex hacker might expect.
1198
1199 Currently NAME is restricted to simple identifiers only.
1200 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
1201 its Unicode extension (see L<utf8>),
1202 though it isn't extended by the locale (see L<perllocale>).
1203
1204 B<NOTE:> In order to make things easier for programmers with experience
1205 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
1206 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
1207 support the use of single quotes as a delimiter for the name.
1208
1209 =item C<< \k<NAME> >>
1210
1211 =item C<< \k'NAME' >>
1212
1213 Named backreference. Similar to numeric backreferences, except that
1214 the group is designated by name and not number. If multiple groups
1215 have the same name then it refers to the leftmost defined group in
1216 the current match.
1217
1218 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
1219 earlier in the pattern.
1220
1221 Both forms are equivalent.
1222
1223 B<NOTE:> In order to make things easier for programmers with experience
1224 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
1225 may be used instead of C<< \k<NAME> >>.
1226
1227 =item C<(?{ code })>
1228 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
1229
1230 B<WARNING>: This extended regular expression feature is considered
1231 experimental, and may be changed without notice. Code executed that
1232 has side effects may not perform identically from version to version
1233 due to the effect of future optimisations in the regex engine.
1234
1235 This zero-width assertion evaluates any embedded Perl code.  It
1236 always succeeds, and its C<code> is not interpolated.  Currently,
1237 the rules to determine where the C<code> ends are somewhat convoluted.
1238
1239 This feature can be used together with the special variable C<$^N> to
1240 capture the results of submatches in variables without having to keep
1241 track of the number of nested parentheses. For example:
1242
1243   $_ = "The brown fox jumps over the lazy dog";
1244   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
1245   print "color = $color, animal = $animal\n";
1246
1247 Inside the C<(?{...})> block, C<$_> refers to the string the regular
1248 expression is matching against. You can also use C<pos()> to know what is
1249 the current position of matching within this string.
1250
1251 The C<code> is properly scoped in the following sense: If the assertion
1252 is backtracked (compare L<"Backtracking">), all changes introduced after
1253 C<local>ization are undone, so that
1254
1255   $_ = 'a' x 8;
1256   m<
1257      (?{ $cnt = 0 })               # Initialize $cnt.
1258      (
1259        a
1260        (?{
1261            local $cnt = $cnt + 1;  # Update $cnt,
1262                                    # backtracking-safe.
1263        })
1264      )*
1265      aaaa
1266      (?{ $res = $cnt })            # On success copy to
1267                                    # non-localized location.
1268    >x;
1269
1270 will set C<$res = 4>.  Note that after the match, C<$cnt> returns to the globally
1271 introduced value, because the scopes that restrict C<local> operators
1272 are unwound.
1273
1274 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
1275 switch.  If I<not> used in this way, the result of evaluation of
1276 C<code> is put into the special variable C<$^R>.  This happens
1277 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
1278 inside the same regular expression.
1279
1280 The assignment to C<$^R> above is properly localized, so the old
1281 value of C<$^R> is restored if the assertion is backtracked; compare
1282 L<"Backtracking">.
1283
1284 For reasons of security, this construct is forbidden if the regular
1285 expression involves run-time interpolation of variables, unless the
1286 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
1287 variables contain results of the C<qr//> operator (see
1288 L<perlop/"qr/STRINGE<sol>msixpodual">).
1289
1290 This restriction is due to the wide-spread and remarkably convenient
1291 custom of using run-time determined strings as patterns.  For example:
1292
1293     $re = <>;
1294     chomp $re;
1295     $string =~ /$re/;
1296
1297 Before Perl knew how to execute interpolated code within a pattern,
1298 this operation was completely safe from a security point of view,
1299 although it could raise an exception from an illegal pattern.  If
1300 you turn on the C<use re 'eval'>, though, it is no longer secure,
1301 so you should only do so if you are also using taint checking.
1302 Better yet, use the carefully constrained evaluation within a Safe
1303 compartment.  See L<perlsec> for details about both these mechanisms.
1304
1305 B<WARNING>: Use of lexical (C<my>) variables in these blocks is
1306 broken. The result is unpredictable and will make perl unstable. The
1307 workaround is to use global (C<our>) variables.
1308
1309 B<WARNING>: In perl 5.12.x and earlier, the regex engine
1310 was not re-entrant, so interpolated code could not
1311 safely invoke the regex engine either directly with
1312 C<m//> or C<s///>), or indirectly with functions such as
1313 C<split>. Invoking the regex engine in these blocks would make perl
1314 unstable.
1315
1316 =item C<(??{ code })>
1317 X<(??{})>
1318 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1319
1320 B<WARNING>: This extended regular expression feature is considered
1321 experimental, and may be changed without notice. Code executed that
1322 has side effects may not perform identically from version to version
1323 due to the effect of future optimisations in the regex engine.
1324
1325 This is a "postponed" regular subexpression.  The C<code> is evaluated
1326 at run time, at the moment this subexpression may match.  The result
1327 of evaluation is considered a regular expression and matched as
1328 if it were inserted instead of this construct.  Note that this means
1329 that the contents of capture groups defined inside an eval'ed pattern
1330 are not available outside of the pattern, and vice versa, there is no
1331 way for the inner pattern returned from the code block to refer to a
1332 capture group defined outside.  (The code block itself can use C<$1>, etc.,
1333 to refer to the enclosing pattern's capture groups.)  Thus,
1334
1335     ('a' x 100)=~/(??{'(.)' x 100})/
1336
1337 B<will> match, it will B<not> set $1.
1338
1339 The C<code> is not interpolated.  As before, the rules to determine
1340 where the C<code> ends are currently somewhat convoluted.
1341
1342 The following pattern matches a parenthesized group:
1343
1344  $re = qr{
1345             \(
1346             (?:
1347                (?> [^()]+ )  # Non-parens without backtracking
1348              |
1349                (??{ $re })   # Group with matching parens
1350             )*
1351             \)
1352          }x;
1353
1354 See also C<(?PARNO)> for a different, more efficient way to accomplish
1355 the same task.
1356
1357 For reasons of security, this construct is forbidden if the regular
1358 expression involves run-time interpolation of variables, unless the
1359 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
1360 variables contain results of the C<qr//> operator (see
1361 L<perlop/"qrE<sol>STRINGE<sol>msixpodual">).
1362
1363 In perl 5.12.x and earlier, because the regex engine was not re-entrant,
1364 delayed code could not safely invoke the regex engine either directly with
1365 C<m//> or C<s///>), or indirectly with functions such as C<split>.
1366
1367 Recursing deeper than 50 times without consuming any input string will
1368 result in a fatal error.  The maximum depth is compiled into perl, so
1369 changing it requires a custom build.
1370
1371 =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
1372 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1373 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1374 X<regex, relative recursion>
1375
1376 Similar to C<(??{ code })> except it does not involve compiling any code,
1377 instead it treats the contents of a capture group as an independent
1378 pattern that must match at the current position.  Capture groups
1379 contained by the pattern will have the value as determined by the
1380 outermost recursion.
1381
1382 PARNO is a sequence of digits (not starting with 0) whose value reflects
1383 the paren-number of the capture group to recurse to. C<(?R)> recurses to
1384 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1385 C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
1386 to be relative, with negative numbers indicating preceding capture groups
1387 and positive ones following. Thus C<(?-1)> refers to the most recently
1388 declared group, and C<(?+1)> indicates the next group to be declared.
1389 Note that the counting for relative recursion differs from that of
1390 relative backreferences, in that with recursion unclosed groups B<are>
1391 included.
1392
1393 The following pattern matches a function foo() which may contain
1394 balanced parentheses as the argument.
1395
1396   $re = qr{ (                   # paren group 1 (full function)
1397               foo
1398               (                 # paren group 2 (parens)
1399                 \(
1400                   (             # paren group 3 (contents of parens)
1401                   (?:
1402                    (?> [^()]+ ) # Non-parens without backtracking
1403                   |
1404                    (?2)         # Recurse to start of paren group 2
1405                   )*
1406                   )
1407                 \)
1408               )
1409             )
1410           }x;
1411
1412 If the pattern was used as follows
1413
1414     'foo(bar(baz)+baz(bop))'=~/$re/
1415         and print "\$1 = $1\n",
1416                   "\$2 = $2\n",
1417                   "\$3 = $3\n";
1418
1419 the output produced should be the following:
1420
1421     $1 = foo(bar(baz)+baz(bop))
1422     $2 = (bar(baz)+baz(bop))
1423     $3 = bar(baz)+baz(bop)
1424
1425 If there is no corresponding capture group defined, then it is a
1426 fatal error.  Recursing deeper than 50 times without consuming any input
1427 string will also result in a fatal error.  The maximum depth is compiled
1428 into perl, so changing it requires a custom build.
1429
1430 The following shows how using negative indexing can make it
1431 easier to embed recursive patterns inside of a C<qr//> construct
1432 for later use:
1433
1434     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1435     if (/foo $parens \s+ + \s+ bar $parens/x) {
1436        # do something here...
1437     }
1438
1439 B<Note> that this pattern does not behave the same way as the equivalent
1440 PCRE or Python construct of the same form. In Perl you can backtrack into
1441 a recursed group, in PCRE and Python the recursed into group is treated
1442 as atomic. Also, modifiers are resolved at compile time, so constructs
1443 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1444 be processed.
1445
1446 =item C<(?&NAME)>
1447 X<(?&NAME)>
1448
1449 Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1450 parenthesis to recurse to is determined by name. If multiple parentheses have
1451 the same name, then it recurses to the leftmost.
1452
1453 It is an error to refer to a name that is not declared somewhere in the
1454 pattern.
1455
1456 B<NOTE:> In order to make things easier for programmers with experience
1457 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1458 may be used instead of C<< (?&NAME) >>.
1459
1460 =item C<(?(condition)yes-pattern|no-pattern)>
1461 X<(?()>
1462
1463 =item C<(?(condition)yes-pattern)>
1464
1465 Conditional expression. Matches C<yes-pattern> if C<condition> yields
1466 a true value, matches C<no-pattern> otherwise. A missing pattern always
1467 matches.
1468
1469 C<(condition)> should be either an integer in
1470 parentheses (which is valid if the corresponding pair of parentheses
1471 matched), a look-ahead/look-behind/evaluate zero-width assertion, a
1472 name in angle brackets or single quotes (which is valid if a group
1473 with the given name matched), or the special symbol (R) (true when
1474 evaluated inside of recursion or eval). Additionally the R may be
1475 followed by a number, (which will be true when evaluated when recursing
1476 inside of the appropriate group), or by C<&NAME>, in which case it will
1477 be true only when evaluated during recursion in the named group.
1478
1479 Here's a summary of the possible predicates:
1480
1481 =over 4
1482
1483 =item (1) (2) ...
1484
1485 Checks if the numbered capturing group has matched something.
1486
1487 =item (<NAME>) ('NAME')
1488
1489 Checks if a group with the given name has matched something.
1490
1491 =item (?=...) (?!...) (?<=...) (?<!...)
1492
1493 Checks whether the pattern matches (or does not match, for the '!'
1494 variants).
1495
1496 =item (?{ CODE })
1497
1498 Treats the return value of the code block as the condition.
1499
1500 =item (R)
1501
1502 Checks if the expression has been evaluated inside of recursion.
1503
1504 =item (R1) (R2) ...
1505
1506 Checks if the expression has been evaluated while executing directly
1507 inside of the n-th capture group. This check is the regex equivalent of
1508
1509   if ((caller(0))[3] eq 'subname') { ... }
1510
1511 In other words, it does not check the full recursion stack.
1512
1513 =item (R&NAME)
1514
1515 Similar to C<(R1)>, this predicate checks to see if we're executing
1516 directly inside of the leftmost group with a given name (this is the same
1517 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1518 stack, but only the name of the innermost active recursion.
1519
1520 =item (DEFINE)
1521
1522 In this case, the yes-pattern is never directly executed, and no
1523 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1524 See below for details.
1525
1526 =back
1527
1528 For example:
1529
1530     m{ ( \( )?
1531        [^()]+
1532        (?(1) \) )
1533      }x
1534
1535 matches a chunk of non-parentheses, possibly included in parentheses
1536 themselves.
1537
1538 A special form is the C<(DEFINE)> predicate, which never executes its
1539 yes-pattern directly, and does not allow a no-pattern. This allows one to
1540 define subpatterns which will be executed only by the recursion mechanism.
1541 This way, you can define a set of regular expression rules that can be
1542 bundled into any pattern you choose.
1543
1544 It is recommended that for this usage you put the DEFINE block at the
1545 end of the pattern, and that you name any subpatterns defined within it.
1546
1547 Also, it's worth noting that patterns defined this way probably will
1548 not be as efficient, as the optimiser is not very clever about
1549 handling them.
1550
1551 An example of how this might be used is as follows:
1552
1553   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1554    (?(DEFINE)
1555      (?<NAME_PAT>....)
1556      (?<ADRESS_PAT>....)
1557    )/x
1558
1559 Note that capture groups matched inside of recursion are not accessible
1560 after the recursion returns, so the extra layer of capturing groups is
1561 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1562 C<$+{NAME}> would be.
1563
1564 Finally, keep in mind that subpatterns created inside a DEFINE block
1565 count towards the absolute and relative number of captures, so this:
1566
1567     my @captures = "a" =~ /(.)                  # First capture
1568                            (?(DEFINE)
1569                                (?<EXAMPLE> 1 )  # Second capture
1570                            )/x;
1571     say scalar @captures;
1572
1573 Will output 2, not 1. This is particularly important if you intend to
1574 compile the definitions with the C<qr//> operator, and later
1575 interpolate them in another pattern.
1576
1577 =item C<< (?>pattern) >>
1578 X<backtrack> X<backtracking> X<atomic> X<possessive>
1579
1580 An "independent" subexpression, one which matches the substring
1581 that a I<standalone> C<pattern> would match if anchored at the given
1582 position, and it matches I<nothing other than this substring>.  This
1583 construct is useful for optimizations of what would otherwise be
1584 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1585 It may also be useful in places where the "grab all you can, and do not
1586 give anything back" semantic is desirable.
1587
1588 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1589 (anchored at the beginning of string, as above) will match I<all>
1590 characters C<a> at the beginning of string, leaving no C<a> for
1591 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1592 since the match of the subgroup C<a*> is influenced by the following
1593 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1594 C<a*ab> will match fewer characters than a standalone C<a*>, since
1595 this makes the tail match.
1596
1597 C<< (?>pattern) >> does not disable backtracking altogether once it has
1598 matched. It is still possible to backtrack past the construct, but not
1599 into it. So C<< ((?>a*)|(?>b*))ar >> will still match "bar".
1600
1601 An effect similar to C<< (?>pattern) >> may be achieved by writing
1602 C<(?=(pattern))\g{-1}>.  This matches the same substring as a standalone
1603 C<a+>, and the following C<\g{-1}> eats the matched string; it therefore
1604 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1605 (The difference between these two constructs is that the second one
1606 uses a capturing group, thus shifting ordinals of backreferences
1607 in the rest of a regular expression.)
1608
1609 Consider this pattern:
1610
1611     m{ \(
1612           (
1613             [^()]+           # x+
1614           |
1615             \( [^()]* \)
1616           )+
1617        \)
1618      }x
1619
1620 That will efficiently match a nonempty group with matching parentheses
1621 two levels deep or less.  However, if there is no such group, it
1622 will take virtually forever on a long string.  That's because there
1623 are so many different ways to split a long string into several
1624 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1625 to a subpattern of the above pattern.  Consider how the pattern
1626 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1627 seconds, but that each extra letter doubles this time.  This
1628 exponential performance will make it appear that your program has
1629 hung.  However, a tiny change to this pattern
1630
1631     m{ \(
1632           (
1633             (?> [^()]+ )        # change x+ above to (?> x+ )
1634           |
1635             \( [^()]* \)
1636           )+
1637        \)
1638      }x
1639
1640 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1641 this yourself would be a productive exercise), but finishes in a fourth
1642 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1643 however, that, when this construct is followed by a
1644 quantifier, it currently triggers a warning message under
1645 the C<use warnings> pragma or B<-w> switch saying it
1646 C<"matches null string many times in regex">.
1647
1648 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1649 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1650 This was only 4 times slower on a string with 1000000 C<a>s.
1651
1652 The "grab all you can, and do not give anything back" semantic is desirable
1653 in many situations where on the first sight a simple C<()*> looks like
1654 the correct solution.  Suppose we parse text with comments being delimited
1655 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1656 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1657 the comment delimiter, because it may "give up" some whitespace if
1658 the remainder of the pattern can be made to match that way.  The correct
1659 answer is either one of these:
1660
1661     (?>#[ \t]*)
1662     #[ \t]*(?![ \t])
1663
1664 For example, to grab non-empty comments into $1, one should use either
1665 one of these:
1666
1667     / (?> \# [ \t]* ) (        .+ ) /x;
1668     /     \# [ \t]*   ( [^ \t] .* ) /x;
1669
1670 Which one you pick depends on which of these expressions better reflects
1671 the above specification of comments.
1672
1673 In some literature this construct is called "atomic matching" or
1674 "possessive matching".
1675
1676 Possessive quantifiers are equivalent to putting the item they are applied
1677 to inside of one of these constructs. The following equivalences apply:
1678
1679     Quantifier Form     Bracketing Form
1680     ---------------     ---------------
1681     PAT*+               (?>PAT*)
1682     PAT++               (?>PAT+)
1683     PAT?+               (?>PAT?)
1684     PAT{min,max}+       (?>PAT{min,max})
1685
1686 =back
1687
1688 =head2 Special Backtracking Control Verbs
1689
1690 B<WARNING:> These patterns are experimental and subject to change or
1691 removal in a future version of Perl. Their usage in production code should
1692 be noted to avoid problems during upgrades.
1693
1694 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1695 otherwise stated the ARG argument is optional; in some cases, it is
1696 forbidden.
1697
1698 Any pattern containing a special backtracking verb that allows an argument
1699 has the special behaviour that when executed it sets the current package's
1700 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1701 rules apply:
1702
1703 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1704 verb pattern, if the verb was involved in the failure of the match. If the
1705 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1706 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1707 none. Also, the C<$REGMARK> variable will be set to FALSE.
1708
1709 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1710 the C<$REGMARK> variable will be set to the name of the last
1711 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1712 C<(*MARK:NAME)> verb below for more details.
1713
1714 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1715 and most other regex-related variables. They are not local to a scope, nor
1716 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1717 Use C<local> to localize changes to them to a specific scope if necessary.
1718
1719 If a pattern does not contain a special backtracking verb that allows an
1720 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1721
1722 =over 3
1723
1724 =item Verbs that take an argument
1725
1726 =over 4
1727
1728 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1729 X<(*PRUNE)> X<(*PRUNE:NAME)>
1730
1731 This zero-width pattern prunes the backtracking tree at the current point
1732 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1733 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1734 A may backtrack as necessary to match. Once it is reached, matching
1735 continues in B, which may also backtrack as necessary; however, should B
1736 not match, then no further backtracking will take place, and the pattern
1737 will fail outright at the current starting position.
1738
1739 The following example counts all the possible matching strings in a
1740 pattern (without actually matching any of them).
1741
1742     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1743     print "Count=$count\n";
1744
1745 which produces:
1746
1747     aaab
1748     aaa
1749     aa
1750     a
1751     aab
1752     aa
1753     a
1754     ab
1755     a
1756     Count=9
1757
1758 If we add a C<(*PRUNE)> before the count like the following
1759
1760     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1761     print "Count=$count\n";
1762
1763 we prevent backtracking and find the count of the longest matching string
1764 at each matching starting point like so:
1765
1766     aaab
1767     aab
1768     ab
1769     Count=3
1770
1771 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1772
1773 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1774 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1775 replaced with a C<< (?>pattern) >> with no functional difference; however,
1776 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1777 C<< (?>pattern) >> alone.
1778
1779 =item C<(*SKIP)> C<(*SKIP:NAME)>
1780 X<(*SKIP)>
1781
1782 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1783 failure it also signifies that whatever text that was matched leading up
1784 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1785 of this pattern. This effectively means that the regex engine "skips" forward
1786 to this position on failure and tries to match again, (assuming that
1787 there is sufficient room to match).
1788
1789 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1790 C<(*MARK:NAME)> was encountered while matching, then it is that position
1791 which is used as the "skip point". If no C<(*MARK)> of that name was
1792 encountered, then the C<(*SKIP)> operator has no effect. When used
1793 without a name the "skip point" is where the match point was when
1794 executing the (*SKIP) pattern.
1795
1796 Compare the following to the examples in C<(*PRUNE)>; note the string
1797 is twice as long:
1798
1799  'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1800  print "Count=$count\n";
1801
1802 outputs
1803
1804     aaab
1805     aaab
1806     Count=2
1807
1808 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1809 executed, the next starting point will be where the cursor was when the
1810 C<(*SKIP)> was executed.
1811
1812 =item C<(*MARK:NAME)> C<(*:NAME)>
1813 X<(*MARK)> X<(*MARK:NAME)> X<(*:NAME)>
1814
1815 This zero-width pattern can be used to mark the point reached in a string
1816 when a certain part of the pattern has been successfully matched. This
1817 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1818 forward to that point if backtracked into on failure. Any number of
1819 C<(*MARK)> patterns are allowed, and the NAME portion may be duplicated.
1820
1821 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1822 can be used to "label" a pattern branch, so that after matching, the
1823 program can determine which branches of the pattern were involved in the
1824 match.
1825
1826 When a match is successful, the C<$REGMARK> variable will be set to the
1827 name of the most recently executed C<(*MARK:NAME)> that was involved
1828 in the match.
1829
1830 This can be used to determine which branch of a pattern was matched
1831 without using a separate capture group for each branch, which in turn
1832 can result in a performance improvement, as perl cannot optimize
1833 C</(?:(x)|(y)|(z))/> as efficiently as something like
1834 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1835
1836 When a match has failed, and unless another verb has been involved in
1837 failing the match and has provided its own name to use, the C<$REGERROR>
1838 variable will be set to the name of the most recently executed
1839 C<(*MARK:NAME)>.
1840
1841 See L</(*SKIP)> for more details.
1842
1843 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1844
1845 =item C<(*THEN)> C<(*THEN:NAME)>
1846
1847 This is similar to the "cut group" operator C<::> from Perl 6.  Like
1848 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1849 failure, it causes the regex engine to try the next alternation in the
1850 innermost enclosing group (capturing or otherwise) that has alternations.
1851 The two branches of a C<(?(condition)yes-pattern|no-pattern)> do not
1852 count as an alternation, as far as C<(*THEN)> is concerned.
1853
1854 Its name comes from the observation that this operation combined with the
1855 alternation operator (C<|>) can be used to create what is essentially a
1856 pattern-based if/then/else block:
1857
1858   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1859
1860 Note that if this operator is used and NOT inside of an alternation then
1861 it acts exactly like the C<(*PRUNE)> operator.
1862
1863   / A (*PRUNE) B /
1864
1865 is the same as
1866
1867   / A (*THEN) B /
1868
1869 but
1870
1871   / ( A (*THEN) B | C (*THEN) D ) /
1872
1873 is not the same as
1874
1875   / ( A (*PRUNE) B | C (*PRUNE) D ) /
1876
1877 as after matching the A but failing on the B the C<(*THEN)> verb will
1878 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1879
1880 =back
1881
1882 =item Verbs without an argument
1883
1884 =over 4
1885
1886 =item C<(*COMMIT)>
1887 X<(*COMMIT)>
1888
1889 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1890 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1891 into on failure it causes the match to fail outright. No further attempts
1892 to find a valid match by advancing the start pointer will occur again.
1893 For example,
1894
1895  'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1896  print "Count=$count\n";
1897
1898 outputs
1899
1900     aaab
1901     Count=1
1902
1903 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1904 does not match, the regex engine will not try any further matching on the
1905 rest of the string.
1906
1907 =item C<(*FAIL)> C<(*F)>
1908 X<(*FAIL)> X<(*F)>
1909
1910 This pattern matches nothing and always fails. It can be used to force the
1911 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1912 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1913
1914 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1915
1916 =item C<(*ACCEPT)>
1917 X<(*ACCEPT)>
1918
1919 B<WARNING:> This feature is highly experimental. It is not recommended
1920 for production code.
1921
1922 This pattern matches nothing and causes the end of successful matching at
1923 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1924 whether there is actually more to match in the string. When inside of a
1925 nested pattern, such as recursion, or in a subpattern dynamically generated
1926 via C<(??{})>, only the innermost pattern is ended immediately.
1927
1928 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
1929 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1930 For instance:
1931
1932   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1933
1934 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1935 be set. If another branch in the inner parentheses was matched, such as in the
1936 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1937
1938 =back
1939
1940 =back
1941
1942 =head2 Backtracking
1943 X<backtrack> X<backtracking>
1944
1945 NOTE: This section presents an abstract approximation of regular
1946 expression behavior.  For a more rigorous (and complicated) view of
1947 the rules involved in selecting a match among possible alternatives,
1948 see L<Combining RE Pieces>.
1949
1950 A fundamental feature of regular expression matching involves the
1951 notion called I<backtracking>, which is currently used (when needed)
1952 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
1953 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
1954 internally, but the general principle outlined here is valid.
1955
1956 For a regular expression to match, the I<entire> regular expression must
1957 match, not just part of it.  So if the beginning of a pattern containing a
1958 quantifier succeeds in a way that causes later parts in the pattern to
1959 fail, the matching engine backs up and recalculates the beginning
1960 part--that's why it's called backtracking.
1961
1962 Here is an example of backtracking:  Let's say you want to find the
1963 word following "foo" in the string "Food is on the foo table.":
1964
1965     $_ = "Food is on the foo table.";
1966     if ( /\b(foo)\s+(\w+)/i ) {
1967         print "$2 follows $1.\n";
1968     }
1969
1970 When the match runs, the first part of the regular expression (C<\b(foo)>)
1971 finds a possible match right at the beginning of the string, and loads up
1972 $1 with "Foo".  However, as soon as the matching engine sees that there's
1973 no whitespace following the "Foo" that it had saved in $1, it realizes its
1974 mistake and starts over again one character after where it had the
1975 tentative match.  This time it goes all the way until the next occurrence
1976 of "foo". The complete regular expression matches this time, and you get
1977 the expected output of "table follows foo."
1978
1979 Sometimes minimal matching can help a lot.  Imagine you'd like to match
1980 everything between "foo" and "bar".  Initially, you write something
1981 like this:
1982
1983     $_ =  "The food is under the bar in the barn.";
1984     if ( /foo(.*)bar/ ) {
1985         print "got <$1>\n";
1986     }
1987
1988 Which perhaps unexpectedly yields:
1989
1990   got <d is under the bar in the >
1991
1992 That's because C<.*> was greedy, so you get everything between the
1993 I<first> "foo" and the I<last> "bar".  Here it's more effective
1994 to use minimal matching to make sure you get the text between a "foo"
1995 and the first "bar" thereafter.
1996
1997     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
1998   got <d is under the >
1999
2000 Here's another example. Let's say you'd like to match a number at the end
2001 of a string, and you also want to keep the preceding part of the match.
2002 So you write this:
2003
2004     $_ = "I have 2 numbers: 53147";
2005     if ( /(.*)(\d*)/ ) {                                # Wrong!
2006         print "Beginning is <$1>, number is <$2>.\n";
2007     }
2008
2009 That won't work at all, because C<.*> was greedy and gobbled up the
2010 whole string. As C<\d*> can match on an empty string the complete
2011 regular expression matched successfully.
2012
2013     Beginning is <I have 2 numbers: 53147>, number is <>.
2014
2015 Here are some variants, most of which don't work:
2016
2017     $_ = "I have 2 numbers: 53147";
2018     @pats = qw{
2019         (.*)(\d*)
2020         (.*)(\d+)
2021         (.*?)(\d*)
2022         (.*?)(\d+)
2023         (.*)(\d+)$
2024         (.*?)(\d+)$
2025         (.*)\b(\d+)$
2026         (.*\D)(\d+)$
2027     };
2028
2029     for $pat (@pats) {
2030         printf "%-12s ", $pat;
2031         if ( /$pat/ ) {
2032             print "<$1> <$2>\n";
2033         } else {
2034             print "FAIL\n";
2035         }
2036     }
2037
2038 That will print out:
2039
2040     (.*)(\d*)    <I have 2 numbers: 53147> <>
2041     (.*)(\d+)    <I have 2 numbers: 5314> <7>
2042     (.*?)(\d*)   <> <>
2043     (.*?)(\d+)   <I have > <2>
2044     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
2045     (.*?)(\d+)$  <I have 2 numbers: > <53147>
2046     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
2047     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
2048
2049 As you see, this can be a bit tricky.  It's important to realize that a
2050 regular expression is merely a set of assertions that gives a definition
2051 of success.  There may be 0, 1, or several different ways that the
2052 definition might succeed against a particular string.  And if there are
2053 multiple ways it might succeed, you need to understand backtracking to
2054 know which variety of success you will achieve.
2055
2056 When using look-ahead assertions and negations, this can all get even
2057 trickier.  Imagine you'd like to find a sequence of non-digits not
2058 followed by "123".  You might try to write that as
2059
2060     $_ = "ABC123";
2061     if ( /^\D*(?!123)/ ) {                # Wrong!
2062         print "Yup, no 123 in $_\n";
2063     }
2064
2065 But that isn't going to match; at least, not the way you're hoping.  It
2066 claims that there is no 123 in the string.  Here's a clearer picture of
2067 why that pattern matches, contrary to popular expectations:
2068
2069     $x = 'ABC123';
2070     $y = 'ABC445';
2071
2072     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
2073     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
2074
2075     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
2076     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
2077
2078 This prints
2079
2080     2: got ABC
2081     3: got AB
2082     4: got ABC
2083
2084 You might have expected test 3 to fail because it seems to a more
2085 general purpose version of test 1.  The important difference between
2086 them is that test 3 contains a quantifier (C<\D*>) and so can use
2087 backtracking, whereas test 1 will not.  What's happening is
2088 that you've asked "Is it true that at the start of $x, following 0 or more
2089 non-digits, you have something that's not 123?"  If the pattern matcher had
2090 let C<\D*> expand to "ABC", this would have caused the whole pattern to
2091 fail.
2092
2093 The search engine will initially match C<\D*> with "ABC".  Then it will
2094 try to match C<(?!123)> with "123", which fails.  But because
2095 a quantifier (C<\D*>) has been used in the regular expression, the
2096 search engine can backtrack and retry the match differently
2097 in the hope of matching the complete regular expression.
2098
2099 The pattern really, I<really> wants to succeed, so it uses the
2100 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
2101 time.  Now there's indeed something following "AB" that is not
2102 "123".  It's "C123", which suffices.
2103
2104 We can deal with this by using both an assertion and a negation.
2105 We'll say that the first part in $1 must be followed both by a digit
2106 and by something that's not "123".  Remember that the look-aheads
2107 are zero-width expressions--they only look, but don't consume any
2108 of the string in their match.  So rewriting this way produces what
2109 you'd expect; that is, case 5 will fail, but case 6 succeeds:
2110
2111     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
2112     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
2113
2114     6: got ABC
2115
2116 In other words, the two zero-width assertions next to each other work as though
2117 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
2118 matches only if you're at the beginning of the line AND the end of the
2119 line simultaneously.  The deeper underlying truth is that juxtaposition in
2120 regular expressions always means AND, except when you write an explicit OR
2121 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
2122 although the attempted matches are made at different positions because "a"
2123 is not a zero-width assertion, but a one-width assertion.
2124
2125 B<WARNING>: Particularly complicated regular expressions can take
2126 exponential time to solve because of the immense number of possible
2127 ways they can use backtracking to try for a match.  For example, without
2128 internal optimizations done by the regular expression engine, this will
2129 take a painfully long time to run:
2130
2131     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
2132
2133 And if you used C<*>'s in the internal groups instead of limiting them
2134 to 0 through 5 matches, then it would take forever--or until you ran
2135 out of stack space.  Moreover, these internal optimizations are not
2136 always applicable.  For example, if you put C<{0,5}> instead of C<*>
2137 on the external group, no current optimization is applicable, and the
2138 match takes a long time to finish.
2139
2140 A powerful tool for optimizing such beasts is what is known as an
2141 "independent group",
2142 which does not backtrack (see L</C<< (?>pattern) >>>).  Note also that
2143 zero-length look-ahead/look-behind assertions will not backtrack to make
2144 the tail match, since they are in "logical" context: only
2145 whether they match is considered relevant.  For an example
2146 where side-effects of look-ahead I<might> have influenced the
2147 following match, see L</C<< (?>pattern) >>>.
2148
2149 =head2 Version 8 Regular Expressions
2150 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
2151
2152 In case you're not familiar with the "regular" Version 8 regex
2153 routines, here are the pattern-matching rules not described above.
2154
2155 Any single character matches itself, unless it is a I<metacharacter>
2156 with a special meaning described here or above.  You can cause
2157 characters that normally function as metacharacters to be interpreted
2158 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
2159 character; "\\" matches a "\"). This escape mechanism is also required
2160 for the character used as the pattern delimiter.
2161
2162 A series of characters matches that series of characters in the target
2163 string, so the pattern C<blurfl> would match "blurfl" in the target
2164 string.
2165
2166 You can specify a character class, by enclosing a list of characters
2167 in C<[]>, which will match any character from the list.  If the
2168 first character after the "[" is "^", the class matches any character not
2169 in the list.  Within a list, the "-" character specifies a
2170 range, so that C<a-z> represents all characters between "a" and "z",
2171 inclusive.  If you want either "-" or "]" itself to be a member of a
2172 class, put it at the start of the list (possibly after a "^"), or
2173 escape it with a backslash.  "-" is also taken literally when it is
2174 at the end of the list, just before the closing "]".  (The
2175 following all specify the same class of three characters: C<[-az]>,
2176 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
2177 specifies a class containing twenty-six characters, even on EBCDIC-based
2178 character sets.)  Also, if you try to use the character
2179 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
2180 a range, the "-" is understood literally.
2181
2182 Note also that the whole range idea is rather unportable between
2183 character sets--and even within character sets they may cause results
2184 you probably didn't expect.  A sound principle is to use only ranges
2185 that begin from and end at either alphabetics of equal case ([a-e],
2186 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
2187 spell out the character sets in full.
2188
2189 Characters may be specified using a metacharacter syntax much like that
2190 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
2191 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
2192 of three octal digits, matches the character whose coded character set value
2193 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
2194 matches the character whose ordinal is I<nn>. The expression \cI<x>
2195 matches the character control-I<x>.  Finally, the "." metacharacter
2196 matches any character except "\n" (unless you use C</s>).
2197
2198 You can specify a series of alternatives for a pattern using "|" to
2199 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
2200 or "foe" in the target string (as would C<f(e|i|o)e>).  The
2201 first alternative includes everything from the last pattern delimiter
2202 ("(", "(?:", etc. or the beginning of the pattern) up to the first "|", and
2203 the last alternative contains everything from the last "|" to the next
2204 closing pattern delimiter.  That's why it's common practice to include
2205 alternatives in parentheses: to minimize confusion about where they
2206 start and end.
2207
2208 Alternatives are tried from left to right, so the first
2209 alternative found for which the entire expression matches, is the one that
2210 is chosen. This means that alternatives are not necessarily greedy. For
2211 example: when matching C<foo|foot> against "barefoot", only the "foo"
2212 part will match, as that is the first alternative tried, and it successfully
2213 matches the target string. (This might not seem important, but it is
2214 important when you are capturing matched text using parentheses.)
2215
2216 Also remember that "|" is interpreted as a literal within square brackets,
2217 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
2218
2219 Within a pattern, you may designate subpatterns for later reference
2220 by enclosing them in parentheses, and you may refer back to the
2221 I<n>th subpattern later in the pattern using the metacharacter
2222 \I<n> or \gI<n>.  Subpatterns are numbered based on the left to right order
2223 of their opening parenthesis.  A backreference matches whatever
2224 actually matched the subpattern in the string being examined, not
2225 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\g1\d*> will
2226 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
2227 1 matched "0x", even though the rule C<0|0x> could potentially match
2228 the leading 0 in the second number.
2229
2230 =head2 Warning on \1 Instead of $1
2231
2232 Some people get too used to writing things like:
2233
2234     $pattern =~ s/(\W)/\\\1/g;
2235
2236 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
2237 shocking the
2238 B<sed> addicts, but it's a dirty habit to get into.  That's because in
2239 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
2240 the usual double-quoted string means a control-A.  The customary Unix
2241 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
2242 of doing that, you get yourself into trouble if you then add an C</e>
2243 modifier.
2244
2245     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
2246
2247 Or if you try to do
2248
2249     s/(\d+)/\1000/;
2250
2251 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
2252 C<${1}000>.  The operation of interpolation should not be confused
2253 with the operation of matching a backreference.  Certainly they mean two
2254 different things on the I<left> side of the C<s///>.
2255
2256 =head2 Repeated Patterns Matching a Zero-length Substring
2257
2258 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
2259
2260 Regular expressions provide a terse and powerful programming language.  As
2261 with most other power tools, power comes together with the ability
2262 to wreak havoc.
2263
2264 A common abuse of this power stems from the ability to make infinite
2265 loops using regular expressions, with something as innocuous as:
2266
2267     'foo' =~ m{ ( o? )* }x;
2268
2269 The C<o?> matches at the beginning of C<'foo'>, and since the position
2270 in the string is not moved by the match, C<o?> would match again and again
2271 because of the C<*> quantifier.  Another common way to create a similar cycle
2272 is with the looping modifier C<//g>:
2273
2274     @matches = ( 'foo' =~ m{ o? }xg );
2275
2276 or
2277
2278     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
2279
2280 or the loop implied by split().
2281
2282 However, long experience has shown that many programming tasks may
2283 be significantly simplified by using repeated subexpressions that
2284 may match zero-length substrings.  Here's a simple example being:
2285
2286     @chars = split //, $string;           # // is not magic in split
2287     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
2288
2289 Thus Perl allows such constructs, by I<forcefully breaking
2290 the infinite loop>.  The rules for this are different for lower-level
2291 loops given by the greedy quantifiers C<*+{}>, and for higher-level
2292 ones like the C</g> modifier or split() operator.
2293
2294 The lower-level loops are I<interrupted> (that is, the loop is
2295 broken) when Perl detects that a repeated expression matched a
2296 zero-length substring.   Thus
2297
2298    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
2299
2300 is made equivalent to
2301
2302    m{ (?: NON_ZERO_LENGTH )* (?: ZERO_LENGTH )? }x;
2303
2304 For example, this program
2305
2306    #!perl -l
2307    "aaaaab" =~ /
2308      (?:
2309         a                 # non-zero
2310         |                 # or
2311        (?{print "hello"}) # print hello whenever this
2312                           #    branch is tried
2313        (?=(b))            # zero-width assertion
2314      )*  # any number of times
2315     /x;
2316    print $&;
2317    print $1;
2318
2319 prints
2320
2321    hello
2322    aaaaa
2323    b
2324
2325 Notice that "hello" is only printed once, as when Perl sees that the sixth
2326 iteration of the outermost C<(?:)*> matches a zero-length string, it stops
2327 the C<*>.
2328
2329 The higher-level loops preserve an additional state between iterations:
2330 whether the last match was zero-length.  To break the loop, the following
2331 match after a zero-length match is prohibited to have a length of zero.
2332 This prohibition interacts with backtracking (see L<"Backtracking">),
2333 and so the I<second best> match is chosen if the I<best> match is of
2334 zero length.
2335
2336 For example:
2337
2338     $_ = 'bar';
2339     s/\w??/<$&>/g;
2340
2341 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
2342 match given by non-greedy C<??> is the zero-length match, and the I<second
2343 best> match is what is matched by C<\w>.  Thus zero-length matches
2344 alternate with one-character-long matches.
2345
2346 Similarly, for repeated C<m/()/g> the second-best match is the match at the
2347 position one notch further in the string.
2348
2349 The additional state of being I<matched with zero-length> is associated with
2350 the matched string, and is reset by each assignment to pos().
2351 Zero-length matches at the end of the previous match are ignored
2352 during C<split>.
2353
2354 =head2 Combining RE Pieces
2355
2356 Each of the elementary pieces of regular expressions which were described
2357 before (such as C<ab> or C<\Z>) could match at most one substring
2358 at the given position of the input string.  However, in a typical regular
2359 expression these elementary pieces are combined into more complicated
2360 patterns using combining operators C<ST>, C<S|T>, C<S*> etc.
2361 (in these examples C<S> and C<T> are regular subexpressions).
2362
2363 Such combinations can include alternatives, leading to a problem of choice:
2364 if we match a regular expression C<a|ab> against C<"abc">, will it match
2365 substring C<"a"> or C<"ab">?  One way to describe which substring is
2366 actually matched is the concept of backtracking (see L<"Backtracking">).
2367 However, this description is too low-level and makes you think
2368 in terms of a particular implementation.
2369
2370 Another description starts with notions of "better"/"worse".  All the
2371 substrings which may be matched by the given regular expression can be
2372 sorted from the "best" match to the "worst" match, and it is the "best"
2373 match which is chosen.  This substitutes the question of "what is chosen?"
2374 by the question of "which matches are better, and which are worse?".
2375
2376 Again, for elementary pieces there is no such question, since at most
2377 one match at a given position is possible.  This section describes the
2378 notion of better/worse for combining operators.  In the description
2379 below C<S> and C<T> are regular subexpressions.
2380
2381 =over 4
2382
2383 =item C<ST>
2384
2385 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
2386 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
2387 which can be matched by C<T>.
2388
2389 If C<A> is a better match for C<S> than C<A'>, C<AB> is a better
2390 match than C<A'B'>.
2391
2392 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2393 C<B> is a better match for C<T> than C<B'>.
2394
2395 =item C<S|T>
2396
2397 When C<S> can match, it is a better match than when only C<T> can match.
2398
2399 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2400 two matches for C<T>.
2401
2402 =item C<S{REPEAT_COUNT}>
2403
2404 Matches as C<SSS...S> (repeated as many times as necessary).
2405
2406 =item C<S{min,max}>
2407
2408 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2409
2410 =item C<S{min,max}?>
2411
2412 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2413
2414 =item C<S?>, C<S*>, C<S+>
2415
2416 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2417
2418 =item C<S??>, C<S*?>, C<S+?>
2419
2420 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2421
2422 =item C<< (?>S) >>
2423
2424 Matches the best match for C<S> and only that.
2425
2426 =item C<(?=S)>, C<(?<=S)>
2427
2428 Only the best match for C<S> is considered.  (This is important only if
2429 C<S> has capturing parentheses, and backreferences are used somewhere
2430 else in the whole regular expression.)
2431
2432 =item C<(?!S)>, C<(?<!S)>
2433
2434 For this grouping operator there is no need to describe the ordering, since
2435 only whether or not C<S> can match is important.
2436
2437 =item C<(??{ EXPR })>, C<(?PARNO)>
2438
2439 The ordering is the same as for the regular expression which is
2440 the result of EXPR, or the pattern contained by capture group PARNO.
2441
2442 =item C<(?(condition)yes-pattern|no-pattern)>
2443
2444 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2445 already determined.  The ordering of the matches is the same as for the
2446 chosen subexpression.
2447
2448 =back
2449
2450 The above recipes describe the ordering of matches I<at a given position>.
2451 One more rule is needed to understand how a match is determined for the
2452 whole regular expression: a match at an earlier position is always better
2453 than a match at a later position.
2454
2455 =head2 Creating Custom RE Engines
2456
2457 As of Perl 5.10.0, one can create custom regular expression engines.  This
2458 is not for the faint of heart, as they have to plug in at the C level.  See
2459 L<perlreapi> for more details.
2460
2461 As an alternative, overloaded constants (see L<overload>) provide a simple
2462 way to extend the functionality of the RE engine, by substituting one
2463 pattern for another.
2464
2465 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2466 matches at a boundary between whitespace characters and non-whitespace
2467 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2468 at these positions, so we want to have each C<\Y|> in the place of the
2469 more complicated version.  We can create a module C<customre> to do
2470 this:
2471
2472     package customre;
2473     use overload;
2474
2475     sub import {
2476       shift;
2477       die "No argument to customre::import allowed" if @_;
2478       overload::constant 'qr' => \&convert;
2479     }
2480
2481     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2482
2483     # We must also take care of not escaping the legitimate \\Y|
2484     # sequence, hence the presence of '\\' in the conversion rules.
2485     my %rules = ( '\\' => '\\\\',
2486                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2487     sub convert {
2488       my $re = shift;
2489       $re =~ s{
2490                 \\ ( \\ | Y . )
2491               }
2492               { $rules{$1} or invalid($re,$1) }sgex;
2493       return $re;
2494     }
2495
2496 Now C<use customre> enables the new escape in constant regular
2497 expressions, i.e., those without any runtime variable interpolations.
2498 As documented in L<overload>, this conversion will work only over
2499 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2500 part of this regular expression needs to be converted explicitly
2501 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2502
2503     use customre;
2504     $re = <>;
2505     chomp $re;
2506     $re = customre::convert $re;
2507     /\Y|$re\Y|/;
2508
2509 =head2 PCRE/Python Support
2510
2511 As of Perl 5.10.0, Perl supports several Python/PCRE-specific extensions
2512 to the regex syntax. While Perl programmers are encouraged to use the
2513 Perl-specific syntax, the following are also accepted:
2514
2515 =over 4
2516
2517 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2518
2519 Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>.
2520
2521 =item C<< (?P=NAME) >>
2522
2523 Backreference to a named capture group. Equivalent to C<< \g{NAME} >>.
2524
2525 =item C<< (?P>NAME) >>
2526
2527 Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>.
2528
2529 =back
2530
2531 =head1 BUGS
2532
2533 Many regular expression constructs don't work on EBCDIC platforms.
2534
2535 There are a number of issues with regard to case-insensitive matching
2536 in Unicode rules.  See C<i> under L</Modifiers> above.
2537
2538 This document varies from difficult to understand to completely
2539 and utterly opaque.  The wandering prose riddled with jargon is
2540 hard to fathom in several places.
2541
2542 This document needs a rewrite that separates the tutorial content
2543 from the reference content.
2544
2545 =head1 SEE ALSO
2546
2547 L<perlrequick>.
2548
2549 L<perlretut>.
2550
2551 L<perlop/"Regexp Quote-Like Operators">.
2552
2553 L<perlop/"Gory details of parsing quoted constructs">.
2554
2555 L<perlfaq6>.
2556
2557 L<perlfunc/pos>.
2558
2559 L<perllocale>.
2560
2561 L<perlebcdic>.
2562
2563 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2564 by O'Reilly and Associates.